code.delx.au - gnu-emacs/blob - lisp/url/url-cookie.el

   1 ;;; url-cookie.el --- URL cookie support
   2
   3 ;; Copyright (C) 1996-1999, 2004-2011  Free Software Foundation, Inc.
   4
   5 ;; Keywords: comm, data, processes, hypermedia
   6
   7 ;; This file is part of GNU Emacs.
   8 ;;
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 (require 'url-util)
  27 (require 'url-parse)
  28
  29 (eval-when-compile (require 'cl))       ; defstruct
  30
  31 (defgroup url-cookie nil
  32   "URL cookies."
  33   :prefix "url-"
  34   :prefix "url-cookie-"
  35   :group 'url)
  36
  37 ;; A cookie is stored internally as a vector of 7 slots
  38 ;; [ cookie NAME VALUE EXPIRES LOCALPART DOMAIN SECURE ]
  39
  40 (defstruct (url-cookie
  41             (:constructor url-cookie-create)
  42             (:copier nil)
  43             ;; For compatibility with a previous version which did not use
  44             ;; defstruct, and also in order to make sure that the printed
  45             ;; representation does not depend on CL internals, we use an
  46             ;; explicitly managed tag.
  47             (:type vector))
  48   (tag 'cookie :read-only t)
  49   name value expires localpart domain secure)
  50
  51 (defvar url-cookie-storage nil         "Where cookies are stored.")
  52 (defvar url-cookie-secure-storage nil  "Where secure cookies are stored.")
  53 (defcustom url-cookie-file nil
  54   "File where cookies are stored on disk."
  55   :type '(choice (const :tag "Default" :value nil) file)
  56   :group 'url-file
  57   :group 'url-cookie)
  58
  59 (defcustom url-cookie-confirmation nil
  60   "If non-nil, confirmation by the user is required to accept HTTP cookies."
  61   :type 'boolean
  62   :group 'url-cookie)
  63
  64 (defcustom url-cookie-multiple-line nil
  65   "If nil, HTTP requests put all cookies for the server on one line.
  66 Some web servers, such as http://www.hotmail.com/, only accept cookies
  67 when they are on one line.  This is broken behavior, but just try
  68 telling Microsoft that."
  69   :type 'boolean
  70   :group 'url-cookie)
  71
  72 (defvar url-cookies-changed-since-last-save nil
  73   "Whether the cookies list has changed since the last save operation.")
  74
  75 (defun url-cookie-parse-file (&optional fname)
  76   "Load FNAME, default `url-cookie-file'."
  77   ;; It's completely normal for the cookies file not to exist yet.
  78   (load (or fname url-cookie-file) t t))
  79
  80 (declare-function url-cookie-p "url-cookie" t t) ; defstruct
  81
  82 (defun url-cookie-clean-up (&optional secure)
  83   (let ((var (if secure 'url-cookie-secure-storage 'url-cookie-storage))
  84         new new-cookies)
  85     (dolist (cur (symbol-value var))
  86       (setq new-cookies nil)
  87       (dolist (cur-cookie (cdr cur))
  88         (or (not (url-cookie-p cur-cookie))
  89             (url-cookie-expired-p cur-cookie)
  90             (null (url-cookie-expires cur-cookie))
  91             (setq new-cookies (cons cur-cookie new-cookies))))
  92       (when new-cookies
  93         (setcdr cur new-cookies)
  94         (setq new (cons cur new))))
  95     (set var new)))
  96
  97 (defun url-cookie-write-file (&optional fname)
  98   (when url-cookies-changed-since-last-save
  99     (or fname (setq fname (expand-file-name url-cookie-file)))
 100     (if (condition-case nil
 101             (progn
 102               (url-make-private-file fname)
 103               nil)
 104           (error t))
 105         (message "Error accessing cookie file `%s'" fname)
 106     (url-cookie-clean-up)
 107     (url-cookie-clean-up t)
 108     (with-temp-buffer
 109       (insert ";; Emacs-W3 HTTP cookies file\n"
 110               ";; Automatically generated file!!! DO NOT EDIT!!!\n\n"
 111               "(setq url-cookie-storage\n '")
 112       (pp url-cookie-storage (current-buffer))
 113       (insert ")\n(setq url-cookie-secure-storage\n '")
 114       (pp url-cookie-secure-storage (current-buffer))
 115       (insert ")\n")
 116       (insert "\f\n;; Local Variables:\n"
 117               ";; version-control: never\n"
 118               ";; no-byte-compile: t\n"
 119               ";; End:\n")
 120       (set (make-local-variable 'version-control) 'never)
 121       (write-file fname))
 122     (setq url-cookies-changed-since-last-save nil))))
 123
 124 (defun url-cookie-store (name value &optional expires domain localpart secure)
 125   "Store a cookie."
 126   (let ((storage (if secure url-cookie-secure-storage url-cookie-storage))
 127         tmp found-domain)
 128     ;; First, look for a matching domain.
 129     (if (setq found-domain (assoc domain storage))
 130         ;; Need to either stick the new cookie in existing domain storage
 131         ;; or possibly replace an existing cookie if the names match.
 132         (unless (dolist (cur (setq storage (cdr found-domain)) tmp)
 133                   (and (equal localpart (url-cookie-localpart cur))
 134                        (equal name (url-cookie-name cur))
 135                        (progn
 136                          (setf (url-cookie-expires cur) expires)
 137                          (setf (url-cookie-value cur) value)
 138                          (setq tmp t))))
 139           ;; New cookie.
 140           (setcdr found-domain (cons
 141                                 (url-cookie-create :name name
 142                                                    :value value
 143                                                    :expires expires
 144                                                    :domain domain
 145                                                    :localpart localpart
 146                                                    :secure secure)
 147                                 (cdr found-domain))))
 148       ;; Need to add a new top-level domain.
 149       (setq tmp (url-cookie-create :name name
 150                                    :value value
 151                                    :expires expires
 152                                    :domain domain
 153                                    :localpart localpart
 154                                    :secure secure))
 155       (cond (storage
 156              (setcdr storage (cons (list domain tmp) (cdr storage))))
 157             (secure
 158              (setq url-cookie-secure-storage (list (list domain tmp))))
 159             (t
 160              (setq url-cookie-storage (list (list domain tmp))))))))
 161
 162 (defun url-cookie-expired-p (cookie)
 163   "Return non-nil if COOKIE is expired."
 164   (let ((exp (url-cookie-expires cookie)))
 165     (and exp (> (float-time) (float-time (date-to-time exp))))))
 166
 167 (defun url-cookie-retrieve (host &optional localpart secure)
 168   "Retrieve all cookies for a specified HOST and LOCALPART."
 169   (let ((storage (if secure
 170                      (append url-cookie-secure-storage url-cookie-storage)
 171                    url-cookie-storage))
 172         (case-fold-search t)
 173         cookies retval localpart-match)
 174     (dolist (cur storage)
 175       (setq cookies (cdr cur))
 176       (if (and (car cur)
 177                (string-match
 178                 (concat "^.*"
 179                         (regexp-quote
 180                          ;; Remove the dot from wildcard domains
 181                          ;; before matching.
 182                          (if (eq ?. (aref (car cur) 0))
 183                              (substring (car cur) 1)
 184                            (car cur)))
 185                         "$") host))
 186           ;; The domains match - a possible hit!
 187           (dolist (cur cookies)
 188             (and (if (and (stringp
 189                            (setq localpart-match (url-cookie-localpart cur)))
 190                           (stringp localpart))
 191                      (string-match (concat "^" (regexp-quote localpart-match))
 192                                    localpart)
 193                    (equal localpart localpart-match))
 194                  (not (url-cookie-expired-p cur))
 195                  (setq retval (cons cur retval))))))
 196     retval))
 197
 198 (defun url-cookie-generate-header-lines (host localpart secure)
 199   (let ((cookies (url-cookie-retrieve host localpart secure))
 200         retval chunk)
 201     ;; Have to sort this for sending most specific cookies first.
 202     (setq cookies (and cookies
 203                        (sort cookies
 204                              (lambda (x y)
 205                                (> (length (url-cookie-localpart x))
 206                                   (length (url-cookie-localpart y)))))))
 207     (dolist (cur cookies)
 208       (setq chunk (format "%s=%s" (url-cookie-name cur) (url-cookie-value cur))
 209             retval (if (and url-cookie-multiple-line
 210                             (< 80 (+ (length retval) (length chunk) 4)))
 211                        (concat retval "\r\nCookie: " chunk)
 212                      (if retval
 213                          (concat retval "; " chunk)
 214                        (concat "Cookie: " chunk)))))
 215     (if retval
 216         (concat retval "\r\n")
 217       "")))
 218
 219 (defvar url-cookie-two-dot-domains
 220   (concat "\\.\\("
 221    (mapconcat 'identity (list "com" "edu" "net" "org" "gov" "mil" "int")
 222               "\\|")
 223    "\\)$")
 224   "A regexp of top level domains that only require two matching
 225 '.'s in the domain name in order to set a cookie.")
 226
 227 (defcustom url-cookie-trusted-urls nil
 228   "A list of regular expressions matching URLs to always accept cookies from."
 229   :type '(repeat regexp)
 230   :group 'url-cookie)
 231
 232 (defcustom url-cookie-untrusted-urls nil
 233   "A list of regular expressions matching URLs to never accept cookies from."
 234   :type '(repeat regexp)
 235   :group 'url-cookie)
 236
 237 (defun url-cookie-host-can-set-p (host domain)
 238   (let ((numdots 0)
 239         (last nil)
 240         (case-fold-search t)
 241         (mindots 3))
 242     (while (setq last (string-match "\\." domain last))
 243       (setq numdots (1+ numdots)
 244             last (1+ last)))
 245     (if (string-match url-cookie-two-dot-domains domain)
 246         (setq mindots 2))
 247     (cond
 248      ((string= host domain)             ; Apparently netscape lets you do this
 249       t)
 250      ((>= numdots mindots)              ; We have enough dots in domain name
 251       ;; Need to check and make sure the host is actually _in_ the
 252       ;; domain it wants to set a cookie for though.
 253       (string-match (concat (regexp-quote
 254                              ;; Remove the dot from wildcard domains
 255                              ;; before matching.
 256                              (if (eq ?. (aref domain 0))
 257                                  (substring domain 1)
 258                                domain))
 259                             "$") host))
 260      (t
 261       nil))))
 262
 263 (defun url-cookie-handle-set-cookie (str)
 264   (setq url-cookies-changed-since-last-save t)
 265   (let* ((args (url-parse-args str t))
 266          (case-fold-search t)
 267          (secure (and (assoc-string "secure" args t) t))
 268          (domain (or (cdr-safe (assoc-string "domain" args t))
 269                      (url-host url-current-object)))
 270          (current-url (url-view-url t))
 271          (trusted url-cookie-trusted-urls)
 272          (untrusted url-cookie-untrusted-urls)
 273          (expires (cdr-safe (assoc-string "expires" args t)))
 274          (localpart (or (cdr-safe (assoc-string "path" args t))
 275                         (file-name-directory
 276                          (url-filename url-current-object))))
 277          (rest nil))
 278     (dolist (this args)
 279       (or (member (downcase (car this)) '("secure" "domain" "expires" "path"))
 280           (setq rest (cons this rest))))
 281
 282     ;; Sometimes we get dates that the timezone package cannot handle very
 283     ;; gracefully - take care of this here, instead of in url-cookie-expired-p
 284     ;; to speed things up.
 285     (and expires
 286          (string-match
 287           (concat "^[^,]+, +\\(..\\)-\\(...\\)-\\(..\\) +"
 288                   "\\(..:..:..\\) +\\[*\\([^\]]+\\)\\]*$")
 289           expires)
 290          (setq expires (concat (match-string 1 expires) " "
 291                                (match-string 2 expires) " "
 292                                (match-string 3 expires) " "
 293                                (match-string 4 expires) " ["
 294                                (match-string 5 expires) "]")))
 295
 296     ;; This one is for older Emacs/XEmacs variants that don't
 297     ;; understand this format without tenths of a second in it.
 298     ;; Wednesday, 30-Dec-2037 16:00:00 GMT
 299     ;;       - vs -
 300     ;; Wednesday, 30-Dec-2037 16:00:00.00 GMT
 301     (and expires
 302          (string-match
 303           "\\([0-9]+\\)-\\([A-Za-z]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)\\(\\.[0-9]+\\)*[ \t]+\\([-+a-zA-Z0-9]+\\)"
 304           expires)
 305          (setq expires (concat (match-string 1 expires) "-"     ; day
 306                                (match-string 2 expires) "-"     ; month
 307                                (match-string 3 expires) " "     ; year
 308                                (match-string 4 expires) ".00 " ; hour:minutes:seconds
 309                                (match-string 6 expires)))) ":" ; timezone
 310
 311     (while (consp trusted)
 312       (if (string-match (car trusted) current-url)
 313           (setq trusted (- (match-end 0) (match-beginning 0)))
 314         (pop trusted)))
 315     (while (consp untrusted)
 316       (if (string-match (car untrusted) current-url)
 317           (setq untrusted (- (match-end 0) (match-beginning 0)))
 318         (pop untrusted)))
 319     (and trusted untrusted
 320          ;; Choose the more specific match.
 321          (set (if (> trusted untrusted) 'untrusted 'trusted) nil))
 322     (cond
 323      (untrusted
 324       ;; The site was explicity marked as untrusted by the user.
 325       nil)
 326      ((or (eq url-privacy-level 'paranoid)
 327           (and (listp url-privacy-level) (memq 'cookies url-privacy-level)))
 328       ;; User never wants cookies.
 329       nil)
 330      ((and url-cookie-confirmation
 331            (not trusted)
 332            (save-window-excursion
 333              (with-output-to-temp-buffer "*Cookie Warning*"
 334                (mapcar
 335                 (lambda (x)
 336                   (princ (format "%s - %s" (car x) (cdr x)))) rest))
 337              (prog1
 338                  (not (funcall url-confirmation-func
 339                                (format "Allow %s to set these cookies? "
 340                                        (url-host url-current-object))))
 341                (if (get-buffer "*Cookie Warning*")
 342                    (kill-buffer "*Cookie Warning*")))))
 343       ;; User wants to be asked, and declined.
 344       nil)
 345      ((url-cookie-host-can-set-p (url-host url-current-object) domain)
 346       ;; Cookie is accepted by the user, and passes our security checks.
 347       (dolist (cur rest)
 348         (url-cookie-store (car cur) (cdr cur) expires domain localpart secure)))
 349      (t
 350       (url-lazy-message "%s tried to set a cookie for domain %s - rejected."
 351                         (url-host url-current-object) domain)))))
 352
 353 (defvar url-cookie-timer nil)
 354
 355 (defcustom url-cookie-save-interval 3600
 356   "The number of seconds between automatic saves of cookies.
 357 Default is 1 hour.  Note that if you change this variable outside of
 358 the `customize' interface after `url-do-setup' has been run, you need
 359 to run the `url-cookie-setup-save-timer' function manually."
 360   :set #'(lambda (var val)
 361            (set-default var val)
 362            (if (bound-and-true-p url-setup-done)
 363                (url-cookie-setup-save-timer)))
 364   :type 'integer
 365   :group 'url-cookie)
 366
 367 (defun url-cookie-setup-save-timer ()
 368   "Reset the cookie saver timer."
 369   (interactive)
 370   (ignore-errors (cancel-timer url-cookie-timer))
 371   (setq url-cookie-timer nil)
 372   (if url-cookie-save-interval
 373       (setq url-cookie-timer (run-at-time url-cookie-save-interval
 374                                           url-cookie-save-interval
 375                                           #'url-cookie-write-file))))
 376
 377 (provide 'url-cookie)
 378
 379 ;;; url-cookie.el ends here