code.delx.au - gnu-emacs/blob - lisp/mail/mailalias.el

   1 ;;; mailalias.el --- expand and complete mailing address aliases
   2
   3 ;; Copyright (C) 1985, 1987, 1995, 1996, 1997, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Basic functions for defining and expanding mail aliases.
  27 ;; These seal off the interface to the alias-definition parts of a
  28 ;; .mailrc file formatted for BSD's Mail or USL's mailx.
  29
  30 ;;; Code:
  31
  32 (require 'sendmail)
  33
  34 (defgroup mailalias nil
  35   "Expanding mail aliases."
  36   :group 'mail)
  37
  38 (defcustom mail-passwd-files '("/etc/passwd")
  39   "List of files from which to determine valid user names."
  40   :type '(repeat string)
  41   :group 'mailalias)
  42
  43 (defcustom mail-passwd-command nil
  44   "Shell command to retrieve text to add to `/etc/passwd', or nil."
  45   :type '(choice string (const nil))
  46   :group 'mailalias)
  47
  48 (defvar mail-directory-names t
  49   "Alist of mail address directory entries.
  50 When t this still needs to be initialized.")
  51
  52 (defvar mail-address-field-regexp
  53   "^\\(Resent-\\)?\\(To\\|From\\|CC\\|BCC\\|Reply-to\\):")
  54
  55 (defcustom mail-complete-alist
  56   ;; Don't use backquote here; we don't want backquote to get loaded
  57   ;; just because of loading this file.
  58   ;; Don't refer to mail-address-field-regexp here;
  59   ;; that confuses some things such as cus-dep.el.
  60   (cons '("^\\(Resent-\\)?\\(To\\|From\\|CC\\|BCC\\|Reply-to\\):"
  61           . (mail-get-names pattern))
  62         '(("Newsgroups:" . (if (boundp 'gnus-active-hashtb)
  63                                gnus-active-hashtb
  64                              (if (boundp news-group-article-assoc)
  65                                  news-group-article-assoc)))
  66           ("Followup-To:" . (mail-sentto-newsgroups))
  67           ;;("Distribution:" ???)
  68           ))
  69   "Alist of header field and expression to return alist for completion.
  70 The expression may reference the variable `pattern'
  71 which will hold the string being completed.
  72 If not on matching header, `mail-complete-function' gets called instead."
  73   :type 'alist
  74   :group 'mailalias)
  75 (put 'mail-complete-alist 'risky-local-variable t)
  76
  77 ;;;###autoload
  78 (defcustom mail-complete-style 'angles
  79   "Specifies how \\[mail-complete] formats the full name when it completes.
  80 If `nil', they contain just the return address like:
  81         king@grassland.com
  82 If `parens', they look like:
  83         king@grassland.com (Elvis Parsley)
  84 If `angles', they look like:
  85         Elvis Parsley <king@grassland.com>"
  86   :type '(choice (const angles) (const parens) (const nil))
  87   :group 'mailalias)
  88
  89 (defcustom mail-complete-function 'ispell-complete-word
  90   "Function to call when completing outside `mail-complete-alist'-header."
  91   :type '(choice function (const nil))
  92   :group 'mailalias)
  93
  94 (defcustom mail-directory-function nil
  95   "Function to get completions from directory service or nil for none.
  96 See `mail-directory-requery'."
  97   :type '(choice function (const nil))
  98   :group 'mailalias)
  99
 100 ;; This is for when the directory is huge, or changes frequently.
 101 (defcustom mail-directory-requery nil
 102   "When non-nil call `mail-directory-function' for each completion.
 103 In that case, one argument gets passed to the function, the partial string
 104 entered so far."
 105   :type 'boolean
 106   :group 'mailalias)
 107
 108 (defcustom mail-directory-process nil
 109   "Shell command to get the list of names from a mail directory.
 110 This value is used when the value of `mail-directory-function'
 111 is `mail-directory-process'.  The value should be a list
 112 of the form (COMMAND ARG ...), where each of the list elements
 113 is evaluated.  COMMAND should evaluate to a string.  When
 114 `mail-directory-requery' is non-nil, during evaluation of these
 115 elements, the variable `pattern' contains the partial input being
 116 completed.  `pattern' is nil when `mail-directory-requery' is nil.
 117
 118 The value might look like this:
 119
 120   '(remote-shell-program \"HOST\" \"-nl\" \"USER\" \"COMMAND\")
 121
 122 or like this:
 123
 124   '(remote-shell-program \"HOST\" \"-n\" \"COMMAND '^\" pattern \"'\")"
 125   :type 'sexp
 126   :group 'mailalias)
 127 (put 'mail-directory-process 'risky-local-variable t)
 128
 129 (defcustom mail-directory-stream nil
 130   "List of (HOST SERVICE) for stream connection to mail directory."
 131   :type 'sexp
 132   :group 'mailalias)
 133 (put 'mail-directory-stream 'risky-local-variable t)
 134
 135 (defcustom mail-directory-parser nil
 136   "How to interpret the output of `mail-directory-function'.
 137 Three types of values are possible:
 138
 139   - nil means to gather each line as one name
 140   - regexp means first \\(grouping\\) in successive matches is name
 141   - function called at beginning of buffer that returns an alist of names"
 142   :type '(choice (const nil) regexp function)
 143   :group 'mailalias)
 144 (put 'mail-directory-parser 'risky-local-variable t)
 145
 146 ;; Internal variables.
 147
 148 (defvar mail-names t
 149   "Alist of local users, aliases and directory entries as available.
 150 Elements have the form (MAILNAME) or (MAILNAME . FULLNAME).
 151 If the value means t, it means the real value should be calculated
 152 for the next use.  This is used in `mail-complete'.")
 153
 154 (defvar mail-local-names t
 155   "Alist of local users.
 156 When t this still needs to be initialized.")
 157 \f
 158
 159 ;; Called from sendmail-send-it, or similar functions,
 160 ;; only if some mail aliases are defined.
 161 ;;;###autoload
 162 (defun expand-mail-aliases (beg end &optional exclude)
 163   "Expand all mail aliases in suitable header fields found between BEG and END.
 164 If interactive, expand in header fields.
 165 Suitable header fields are `To', `From', `CC' and `BCC', `Reply-to', and
 166 their `Resent-' variants.
 167
 168 Optional second arg EXCLUDE may be a regular expression defining text to be
 169 removed from alias expansions."
 170   (interactive
 171    (save-excursion
 172      (list (goto-char (point-min))
 173            (mail-header-end))))
 174   (sendmail-sync-aliases)
 175   (when (eq mail-aliases t)
 176     (setq mail-aliases nil)
 177     (build-mail-aliases))
 178   (save-excursion
 179     (goto-char beg)
 180     (setq end (set-marker (make-marker) end))
 181     (let ((case-fold-search nil))
 182       (while (let ((case-fold-search t))
 183                (re-search-forward mail-address-field-regexp end t))
 184         (skip-chars-forward " \t")
 185         (let ((beg1 (point))
 186               end1 pos epos seplen
 187               ;; DISABLED-ALIASES records aliases temporarily disabled
 188               ;; while we scan text that resulted from expanding those aliases.
 189               ;; Each element is (ALIAS . TILL-WHEN), where TILL-WHEN
 190               ;; is where to reenable the alias (expressed as number of chars
 191               ;; counting from END1).
 192               (disabled-aliases nil))
 193           (re-search-forward "^[^ \t]" end 'move)
 194           (beginning-of-line)
 195           (skip-chars-backward " \t\n")
 196           (setq end1 (point-marker))
 197           (goto-char beg1)
 198           (while (< (point) end1)
 199             (setq pos (point))
 200             ;; Reenable any aliases which were disabled for ranges
 201             ;; that we have passed out of.
 202             (while (and disabled-aliases
 203                         (> pos (- end1 (cdr (car disabled-aliases)))))
 204               (setq disabled-aliases (cdr disabled-aliases)))
 205             ;; EPOS gets position of end of next name;
 206             ;; SEPLEN gets length of whitespace&separator that follows it.
 207             (if (re-search-forward "[ \t]*[\n,][ \t]*" end1 t)
 208                 (setq epos (match-beginning 0)
 209                       seplen (- (point) epos))
 210               (setq epos (marker-position end1) seplen 0))
 211             (let ((string (buffer-substring-no-properties pos epos))
 212                   translation)
 213               (if (and (not (assoc string disabled-aliases))
 214                        (setq translation (cdr (assoc string mail-aliases))))
 215                   (progn
 216                     ;; This name is an alias.  Disable it.
 217                     (setq disabled-aliases (cons (cons string (- end1 epos))
 218                                                  disabled-aliases))
 219                     ;; Replace the alias with its expansion
 220                     ;; then rescan the expansion for more aliases.
 221                     (goto-char pos)
 222                     (insert translation)
 223                     (when exclude
 224                       (let ((regexp (concat "\\b\\(" exclude "\\)\\b"))
 225                             (end (point-marker)))
 226                         (goto-char pos)
 227                         (while (re-search-forward regexp end t)
 228                           (replace-match ""))
 229                         (goto-char end)))
 230                     (delete-region (point) (+ (point) (- epos pos)))
 231                     (goto-char pos))
 232                 ;; Name is not an alias.  Skip to start of next name.
 233                 (goto-char epos)
 234                 (forward-char seplen))))
 235           (set-marker end1 nil)))
 236       (set-marker end nil))))
 237
 238 ;; Called by mail-setup, or similar functions, only if the file specified
 239 ;; by mail-personal-alias-file (usually `~/.mailrc') exists.
 240 (defun build-mail-aliases (&optional file)
 241   "Read mail aliases from personal aliases file and set `mail-aliases'.
 242 By default, this is the file specified by `mail-personal-alias-file'."
 243   (interactive
 244    (list
 245     (read-file-name (format "Read mail alias file (default %s): "
 246                             mail-personal-alias-file)
 247                     nil mail-personal-alias-file t)))
 248   (setq file (expand-file-name (or file mail-personal-alias-file)))
 249   ;; In case mail-aliases is t, make sure define-mail-alias
 250   ;; does not recursively call build-mail-aliases.
 251   (setq mail-aliases nil)
 252   (with-temp-buffer
 253     (while file
 254       (cond ((get-file-buffer file)
 255              (insert (with-current-buffer (get-file-buffer file)
 256                        (buffer-substring-no-properties
 257                         (point-min) (point-max)))))
 258             ((file-exists-p file) (insert-file-contents file))
 259             ((file-exists-p (setq file (expand-file-name file "~/")))
 260              (insert-file-contents file))
 261             (t (setq file nil)))
 262       (goto-char (point-min))
 263       ;; Delete comments from the contents.
 264       (while (search-forward "# " nil t)
 265         (let ((p (- (point) 2)))
 266           (end-of-line)
 267           (delete-region p (point))))
 268       ;; Don't lose if no final newline.
 269       (goto-char (point-max))
 270       (or (eq (preceding-char) ?\n) (newline))
 271       (goto-char (point-min))
 272       ;; handle "\\\n" continuation lines
 273       (while (not (eobp))
 274         (end-of-line)
 275         (if (= (preceding-char) ?\\)
 276             (progn (delete-char -1) (delete-char 1) (insert ?\ ))
 277           (forward-char 1)))
 278       (goto-char (point-min))
 279       ;; handle `source' directives -- Eddy/1994/May/25
 280       (cond ((re-search-forward "^source[ \t]+" nil t)
 281              (re-search-forward "\\S-+")
 282              (setq file (buffer-substring-no-properties
 283                          (match-beginning 0) (match-end 0)))
 284              (beginning-of-line)
 285              (insert "# ")   ; to ensure we don't re-process this file
 286              (beginning-of-line))
 287             (t (setq file nil))))
 288     (goto-char (point-min))
 289     (while (re-search-forward
 290             "^\\(a\\|alias\\|g\\|group\\)[ \t]+\\([^ \t\n]+\\)" nil t)
 291       (let* ((name (match-string 2))
 292              (start (progn (skip-chars-forward " \t") (point)))
 293              value)
 294         (end-of-line)
 295         (setq value (buffer-substring-no-properties start (point)))
 296         (unless (equal value "")
 297           (define-mail-alias name value t))))
 298     mail-aliases))
 299
 300 ;; Always autoloadable in case the user wants to define aliases
 301 ;; interactively or in .emacs.
 302 ;; define-mail-abbrev in mailabbrev.el duplicates much of this code.
 303 ;;;###autoload
 304 (defun define-mail-alias (name definition &optional from-mailrc-file)
 305   "Define NAME as a mail alias that translates to DEFINITION.
 306 This means that sending a message to NAME will actually send to DEFINITION.
 307
 308 Normally, the addresses in DEFINITION must be separated by commas.
 309 If FROM-MAILRC-FILE is non-nil, then addresses in DEFINITION
 310 can be separated by spaces; an address can contain spaces
 311 if it is quoted with double-quotes."
 312
 313   (interactive "sDefine mail alias: \nsDefine %s as mail alias for: ")
 314   ;; Read the defaults first, if we have not done so.
 315   ;; But not if we are doing that already right now.
 316   (unless from-mailrc-file
 317     (sendmail-sync-aliases))
 318   (if (eq mail-aliases t)
 319       (progn
 320         (setq mail-aliases nil)
 321         (if (file-exists-p mail-personal-alias-file)
 322             (build-mail-aliases))))
 323   ;; strip garbage from front and end
 324   (if (string-match "\\`[ \t\n,]+" definition)
 325       (setq definition (substring definition (match-end 0))))
 326   (if (string-match "[ \t\n,]+\\'" definition)
 327       (setq definition (substring definition 0 (match-beginning 0))))
 328
 329   (let* ((L (length definition))
 330          (start (if (> L 0) 0))
 331          end this-entry result tem)
 332     (while start
 333       (cond
 334        (from-mailrc-file
 335         ;; If we're reading from the mailrc file, addresses are
 336         ;; delimited by spaces, and addresses with embedded spaces are
 337         ;; surrounded by non-escaped double-quotes.
 338         (if (eq ?\" (aref definition start))
 339             (setq start (1+ start)
 340                   end (and (string-match
 341                             "[^\\]\\(\\([\\][\\]\\)*\\)\"[ \t,]*"
 342                             definition start)
 343                            (match-end 1)))
 344           (setq end (string-match "[ \t,]+" definition start)))
 345         ;; Extract the address and advance the loop past it.
 346         (setq this-entry (substring definition start end)
 347               start (and end (/= (match-end 0) L) (match-end 0)))
 348         ;; If the full name contains a problem character, quote it.
 349         (and (string-match "\\(.+?\\)[ \t]*\\(<.*>\\)" this-entry)
 350              (string-match "[^- !#$%&'*+/0-9=?A-Za-z^_`{|}~]"
 351                            (match-string 1 this-entry))
 352              (setq this-entry (replace-regexp-in-string
 353                                "\\(.+?\\)[ \t]*\\(<.*>\\)"
 354                                "\"\\1\" \\2"
 355                                this-entry))))
 356        ;; When we are not reading from .mailrc, addresses are
 357        ;; separated by commas.  Try to accept a rfc822-like syntax.
 358        ;; (Todo: extend rfc822.el to do the work for us.)
 359        ((equal (string-match
 360                 "[ \t,]*\\(\"\\(?:[^\"]\\|[^\\]\\(?:[\\][\\]\\)*\"\\)*\"[ \t]*\
 361 <[-.!#$%&'*+/0-9=?A-Za-z^_`{|}~@]+>\\)[ \t,]*"
 362                 definition start)
 363                start)
 364         ;; If an entry has a valid [ "foo bar" <foo@example.com> ]
 365         ;; form, use it literally .  This also allows commas in the
 366         ;; quoted string, e.g.  [ "foo bar, jr" <foo@example.com> ]
 367         (setq this-entry (match-string 1 definition)
 368               start (and (/= (match-end 0) L) (match-end 0))))
 369        (t
 370         ;; Otherwise, read the next address by looking for a comma.
 371         (setq end (string-match "[ \t\n,]*,[ \t\n]*" definition start))
 372         (setq this-entry (substring definition start end))
 373         ;; Advance the loop past this address.
 374         (setq start (and end (/= (match-end 0) L) (match-end 0)))
 375         ;; If the full name contains a problem character, quote it.
 376         (and (string-match "\\(.+?\\)[ \t]*\\(<.*>\\)" this-entry)
 377              (string-match "[^- !#$%&'*+/0-9=?A-Za-z^_`{|}~]"
 378                            (match-string 1 this-entry))
 379              (setq this-entry (replace-regexp-in-string
 380                                "\\(.+?\\)[ \t]*\\(<.*>\\)" "\"\\1\" \\2"
 381                                this-entry)))))
 382       (push this-entry result))
 383
 384     (setq definition (mapconcat (function identity)
 385                                 (nreverse result) ", "))
 386     (setq tem (assoc name mail-aliases))
 387     (if tem
 388         (rplacd tem definition)
 389       (setq mail-aliases (cons (cons name definition) mail-aliases)
 390             mail-names t))))
 391
 392 ;;;###autoload
 393 (defun mail-complete (arg)
 394   "Perform completion on header field or word preceding point.
 395 Completable headers are according to `mail-complete-alist'.  If none matches
 396 current header, calls `mail-complete-function' and passes prefix arg if any."
 397   (interactive "P")
 398   ;; Read the defaults first, if we have not done so.
 399   (sendmail-sync-aliases)
 400   (if (eq mail-aliases t)
 401       (progn
 402         (setq mail-aliases nil)
 403         (if (file-exists-p mail-personal-alias-file)
 404             (build-mail-aliases))))
 405   (let ((list mail-complete-alist))
 406     (if (and (< 0 (mail-header-end))
 407              (save-excursion
 408                (if (re-search-backward "^[^\t]" nil t)
 409                    (while list
 410                      (if (looking-at (car (car list)))
 411                          (setq arg (cdr (car list))
 412                                list ())
 413                        (setq list (cdr list)))))
 414                arg))
 415         (let* ((end (point))
 416                (beg (save-excursion
 417                       (skip-chars-backward "^ \t<,:")
 418                       (point)))
 419                (pattern (buffer-substring beg end))
 420                completion)
 421           (setq list (eval arg)
 422                 completion (try-completion pattern list))
 423           (cond ((eq completion t))
 424                 ((null completion)
 425                  (message "Can't find completion for \"%s\"" pattern)
 426                  (ding))
 427                 ((not (string= pattern completion))
 428                  (delete-region beg end)
 429                  (let ((alist-elt (assoc completion mail-names)))
 430                    (if (cdr alist-elt)
 431                        (cond ((eq mail-complete-style 'parens)
 432                               (insert completion " (" (cdr alist-elt) ")"))
 433                              ((eq mail-complete-style 'angles)
 434                               (insert (cdr alist-elt) " <" completion ">"))
 435                              (t
 436                               (insert completion)))
 437                      (insert completion))))
 438                 (t
 439                  (message "Making completion list...")
 440                  (with-output-to-temp-buffer "*Completions*"
 441                    (display-completion-list
 442                     (all-completions pattern list)))
 443                  (message "Making completion list...%s" "done"))))
 444       (funcall mail-complete-function arg))))
 445
 446 (defun mail-get-names (pattern)
 447   "Fetch local users and global mail addresses for completion.
 448 Consults `/etc/passwd' and a directory service if one is set up via
 449 `mail-directory-function'.
 450 PATTERN is the string we want to complete."
 451   (if (eq mail-local-names t)
 452       (with-current-buffer (generate-new-buffer " passwd")
 453         (let ((files mail-passwd-files))
 454           (while files
 455             (insert-file-contents (car files) nil nil nil t)
 456             (setq files (cdr files))))
 457         (if mail-passwd-command
 458             (call-process shell-file-name nil t nil
 459                           shell-command-switch mail-passwd-command))
 460         (goto-char (point-min))
 461         (setq mail-local-names nil)
 462         (while (not (eobp))
 463           ;;Recognize lines like
 464           ;;  nobody:*:65534:65534::/:
 465           ;;  +demo::::::/bin/csh
 466           ;;  +ethanb
 467           ;;while skipping
 468           ;;  +@SOFTWARE
 469           ;; The second \(...\) matches the user id.
 470           (if (looking-at "\\+?\\([^:@\n+]+\\):[^:\n]*:\\([^\n:]*\\):")
 471               (add-to-list 'mail-local-names
 472                            (cons (match-string 1)
 473                                  (user-full-name
 474                                   (string-to-number (match-string 2))))))
 475           (beginning-of-line 2))
 476         (kill-buffer (current-buffer))))
 477   (if (or (eq mail-names t)
 478           (eq mail-directory-names t))
 479       (let (directory)
 480         (and mail-directory-function
 481              (eq mail-directory-names t)
 482              (setq directory
 483                    (mail-directory (if mail-directory-requery pattern))))
 484         (or mail-directory-requery
 485             (setq mail-directory-names directory))
 486         (if (or directory
 487                 (eq mail-names t))
 488             (setq mail-names
 489                   (sort (append (if (consp mail-aliases)
 490                                     (mapcar
 491                                      (function (lambda (a) (list (car a))))
 492                                      mail-aliases))
 493                                 (if (consp mail-local-names)
 494                                     mail-local-names)
 495                                 (or directory
 496                                     (when (consp mail-directory-names)
 497                                       mail-directory-names)))
 498                         (lambda (a b)
 499                           ;; should cache downcased strings
 500                           (string< (downcase (car a))
 501                                    (downcase (car b)))))))))
 502   mail-names)
 503
 504
 505 (defun mail-directory (pattern)
 506   "Use mail-directory facility to get user names matching PATTERN.
 507 If PATTERN is nil, get all the defined user names.
 508 This function calls `mail-directory-function' to query the directory,
 509 then uses `mail-directory-parser' to parse the output it returns."
 510   (message "Querying directory...")
 511   (with-current-buffer (generate-new-buffer " *mail-directory*")
 512     (funcall mail-directory-function pattern)
 513     (goto-char (point-min))
 514     (let (directory)
 515       (if (stringp mail-directory-parser)
 516           (while (re-search-forward mail-directory-parser nil t)
 517             (setq directory
 518                   (cons (match-string 1) directory)))
 519         (if mail-directory-parser
 520             (setq directory (funcall mail-directory-parser))
 521           (while (not (eobp))
 522             (setq directory
 523                   (cons (buffer-substring (point)
 524                                           (progn
 525                                             (forward-line)
 526                                             (if (bolp)
 527                                                 (1- (point))
 528                                               (point))))
 529                         directory)))))
 530       (kill-buffer (current-buffer))
 531       (message "Querying directory...done")
 532       directory)))
 533
 534
 535 (defun mail-directory-process (pattern)
 536   "Run a shell command to output names in directory.
 537 See `mail-directory-process'."
 538   (when (consp mail-directory-process)
 539     (apply 'call-process (eval (car mail-directory-process)) nil t nil
 540            (mapcar 'eval (cdr mail-directory-process)))))
 541
 542 ;; This should handle a dialog.  Currently expects port to spit out names.
 543 (defun mail-directory-stream (pattern)
 544   "Open a stream to retrieve names in directory.
 545 See `mail-directory-stream'."
 546   (let (mailalias-done)
 547     (set-process-sentinel
 548      (apply 'open-network-stream "mailalias" (current-buffer)
 549             mail-directory-stream)
 550      (lambda (x y)
 551        (setq mailalias-done t)))
 552     (while (not mailalias-done)
 553       (sit-for .1))))
 554
 555 (defun mail-sentto-newsgroups ()
 556   "Return all entries from Newsgroups: header as completion alist."
 557   (save-excursion
 558     (if (mail-position-on-field "newsgroups" t)
 559         (let ((point (point))
 560               list)
 561           (while (< (skip-chars-backward "^:, \t\n") 0)
 562             (setq list `((,(buffer-substring (point) point))
 563                          ,@list))
 564             (skip-chars-backward ", \t\n")
 565             (setq point (point)))
 566           list))))
 567
 568 (provide 'mailalias)
 569
 570 ;;; mailalias.el ends here