code.delx.au - gnu-emacs/blob - lisp/progmodes/autoconf.el

   1 ;;; autoconf.el --- mode for editing Autoconf configure.in files
   2
   3 ;; Copyright (C) 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   4 ;; Free Software Foundation, Inc.
   5
   6 ;; Author: Dave Love <fx@gnu.org>
   7 ;; Keywords: languages
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Provides fairly minimal font-lock, imenu and indentation support
  27 ;; for editing configure.in files.  Only Autoconf syntax is processed.
  28 ;; There is no attempt to deal with shell text -- probably that will
  29 ;; always lose.
  30
  31 ;; This is specialized for configure.in files.  It doesn't inherit the
  32 ;; general M4 stuff from M4 mode.
  33
  34 ;; There is also an autoconf-mode.el in existence.  That appears to be
  35 ;; for editing the Autoconf M4 source, rather than configure.in files.
  36
  37 ;;; Code:
  38
  39 (defvar font-lock-syntactic-keywords)
  40
  41 (defvar autoconf-mode-map (make-sparse-keymap))
  42
  43 (defvar autoconf-mode-hook nil
  44   "Hook run by `autoconf-mode'.")
  45
  46 (defconst autoconf-definition-regexp
  47   "AC_\\(SUBST\\|DEFINE\\(_UNQUOTED\\)?\\)(\\[*\\(\\sw+\\)\\]*")
  48
  49 (defvar autoconf-font-lock-keywords
  50   `(("\\_<A[CHMS]_\\sw+" . font-lock-keyword-face)
  51     (,autoconf-definition-regexp
  52      3 font-lock-function-name-face)
  53     ;; Are any other M4 keywords really appropriate for configure.in,
  54     ;; given that we do `dnl'?
  55     ("changequote" . font-lock-keyword-face)))
  56
  57 (defvar autoconf-mode-syntax-table
  58   (let ((table (make-syntax-table)))
  59     (modify-syntax-entry ?\" "." table)
  60     (modify-syntax-entry ?\n ">" table)
  61     (modify-syntax-entry ?# "<" table)
  62     table))
  63
  64 (defvar autoconf-imenu-generic-expression
  65   (list (list nil autoconf-definition-regexp 3)))
  66
  67 ;; It's not clear how best to implement this.
  68 (defun autoconf-current-defun-function ()
  69   "Function to use for `add-log-current-defun-function' in Autoconf mode.
  70 This version looks back for an AC_DEFINE or AC_SUBST.  It will stop
  71 searching backwards at another AC_... command."
  72   (save-excursion
  73     (with-syntax-table (copy-syntax-table autoconf-mode-syntax-table)
  74       (modify-syntax-entry ?_ "w")
  75       (if (re-search-backward autoconf-definition-regexp
  76                               (save-excursion (beginning-of-defun) (point))
  77                               t)
  78           (match-string-no-properties 3)))))
  79
  80 ;;;###autoload
  81 (define-derived-mode autoconf-mode prog-mode "Autoconf"
  82   "Major mode for editing Autoconf configure.in files."
  83   (set (make-local-variable 'parens-require-spaces) nil) ; for M4 arg lists
  84   (set (make-local-variable 'defun-prompt-regexp)
  85        "^[ \t]*A[CM]_\\(\\sw\\|\\s_\\)+")
  86   (set (make-local-variable 'comment-start) "dnl ")
  87   (set (make-local-variable 'comment-start-skip) "\\(?:\\<dnl\\|#\\) +")
  88   (set (make-local-variable 'syntax-propertize-function)
  89        (syntax-propertize-rules ("\\<dnl\\>" (0 "<"))))
  90   (set (make-local-variable 'font-lock-defaults)
  91        `(autoconf-font-lock-keywords nil nil (("_" . "w"))))
  92   (set (make-local-variable 'imenu-generic-expression)
  93        autoconf-imenu-generic-expression)
  94   (set (make-local-variable 'imenu-syntax-alist) '(("_" . "w")))
  95   (set (make-local-variable 'indent-line-function) #'indent-relative)
  96   (set (make-local-variable 'add-log-current-defun-function)
  97         #'autoconf-current-defun-function))
  98
  99 (provide 'autoconf-mode)
 100 (provide 'autoconf)
 101
 102 ;; arch-tag: 4f44778f-2ab3-49a1-a103-f0acb9df2de4
 103 ;;; autoconf.el ends here