code.delx.au - gnu-emacs/blob - test/automated/vc-tests.el

   1 ;;; vc-tests.el --- Tests of different backends of vc.el
   2
   3 ;; Copyright (C) 2014-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Michael Albinus <michael.albinus@gmx.de>
   6
   7 ;; This program is free software: you can redistribute it and/or
   8 ;; modify it under the terms of the GNU General Public License as
   9 ;; published by the Free Software Foundation, either version 3 of the
  10 ;; License, or (at your option) any later version.
  11 ;;
  12 ;; This program is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with this program.  If not, see `http://www.gnu.org/licenses/'.
  19
  20 ;;; Commentary:
  21
  22 ;; For every supported VC on the machine, different test cases are
  23 ;; generated automatically.
  24
  25 ;; Functions to be tested (see Commentary of vc.el).  Mandatory
  26 ;; functions are marked with `*', optional functions are marked with `-':
  27
  28 ;; BACKEND PROPERTIES
  29 ;;
  30 ;; * revision-granularity                                       DONE
  31
  32 ;; STATE-QUERYING FUNCTIONS
  33 ;;
  34 ;; * registered (file)                                          DONE
  35 ;; * state (file)                                               DONE
  36 ;; - dir-status (dir update-function)
  37 ;; - dir-status-files (dir files default-state update-function)
  38 ;; - dir-extra-headers (dir)
  39 ;; - dir-printer (fileinfo)
  40 ;; - status-fileinfo-extra (file)
  41 ;; * working-revision (file)                                    DONE
  42 ;; - latest-on-branch-p (file)
  43 ;; * checkout-model (files)                                     DONE
  44 ;; - mode-line-string (file)
  45
  46 ;; STATE-CHANGING FUNCTIONS
  47 ;;
  48 ;; * create-repo (backend)                                      DONE
  49 ;; * register (files &optional comment)                         DONE
  50 ;; - responsible-p (file)
  51 ;; - receive-file (file rev)
  52 ;; - unregister (file)                                          DONE
  53 ;; * checkin (files comment)
  54 ;; * find-revision (file rev buffer)
  55 ;; * checkout (file &optional rev)
  56 ;; * revert (file &optional contents-done)
  57 ;; - rollback (files)
  58 ;; - merge-file (file rev1 rev2)
  59 ;; - merge-branch ()
  60 ;; - merge-news (file)
  61 ;; - pull (prompt)
  62 ;; - steal-lock (file &optional revision)
  63 ;; - modify-change-comment (files rev comment)
  64 ;; - mark-resolved (files)
  65 ;; - find-admin-dir (file)
  66
  67 ;; HISTORY FUNCTIONS
  68 ;;
  69 ;; * print-log (files buffer &optional shortlog start-revision limit)
  70 ;; * log-outgoing (backend remote-location)
  71 ;; * log-incoming (backend remote-location)
  72 ;; - log-view-mode ()
  73 ;; - show-log-entry (revision)
  74 ;; - comment-history (file)
  75 ;; - update-changelog (files)
  76 ;; * diff (files &optional async rev1 rev2 buffer)
  77 ;; - revision-completion-table (files)
  78 ;; - annotate-command (file buf &optional rev)
  79 ;; - annotate-time ()
  80 ;; - annotate-current-time ()
  81 ;; - annotate-extract-revision-at-line ()
  82 ;; - region-history (FILE BUFFER LFROM LTO)
  83 ;; - region-history-mode ()
  84
  85 ;; TAG SYSTEM
  86 ;;
  87 ;; - create-tag (dir name branchp)
  88 ;; - retrieve-tag (dir name update)
  89
  90 ;; MISCELLANEOUS
  91 ;;
  92 ;; - make-version-backups-p (file)
  93 ;; - root (file)
  94 ;; - ignore (file &optional directory)
  95 ;; - ignore-completion-table
  96 ;; - previous-revision (file rev)
  97 ;; - next-revision (file rev)
  98 ;; - log-edit-mode ()
  99 ;; - check-headers ()
 100 ;; - delete-file (file)
 101 ;; - rename-file (old new)
 102 ;; - find-file-hook ()
 103 ;; - extra-menu ()
 104 ;; - extra-dir-menu ()
 105 ;; - conflicted-files (dir)
 106
 107 ;;; Code:
 108
 109 (require 'ert)
 110 (require 'vc)
 111
 112 ;; The working horses.
 113
 114 (defvar vc-test--cleanup-hook nil
 115   "Functions for cleanup at the end of an ert test.
 116 Don't set it globally, the functions shall be let-bound.")
 117
 118 (defun vc-test--revision-granularity-function (backend)
 119   "Run the `vc-revision-granularity' backend function."
 120   (funcall (intern (downcase (format "vc-%s-revision-granularity" backend)))))
 121
 122 (defun vc-test--create-repo-function (backend)
 123   "Run the `vc-create-repo' backend function.
 124 For backends which dont support it, it is emulated."
 125
 126   (cond
 127    ((eq backend 'CVS)
 128     (let ((tmp-dir
 129            (expand-file-name
 130             (make-temp-name "vc-test") temporary-file-directory)))
 131       (make-directory (expand-file-name "module" tmp-dir) 'parents)
 132       (make-directory (expand-file-name "CVSROOT" tmp-dir) 'parents)
 133       (if (not (fboundp 'w32-application-type))
 134           (shell-command-to-string (format "cvs -Q -d:local:%s co module"
 135                                            tmp-dir))
 136         (let ((cvs-prog (executable-find "cvs"))
 137               (tdir tmp-dir))
 138           ;; If CVS executable is an MSYS program, reformat the file
 139           ;; name of TMP-DIR to have the /d/foo/bar form supported by
 140           ;; MSYS programs.  (FIXME: What about Cygwin cvs.exe?)
 141           (if (eq (w32-application-type cvs-prog) 'msys)
 142               (setq tdir
 143                     (concat "/" (substring tmp-dir 0 1) (substring tmp-dir 2))))
 144           (shell-command-to-string (format "cvs -Q -d:local:%s co module"
 145                                            tdir))))
 146       (rename-file "module/CVS" default-directory)
 147       (delete-directory "module" 'recursive)
 148       ;; We must cleanup the "remote" CVS repo as well.
 149       (add-hook 'vc-test--cleanup-hook
 150                 `(lambda () (delete-directory ,tmp-dir 'recursive)))))
 151
 152    ((eq backend 'Arch)
 153     (let ((archive-name (format "%s--%s" user-mail-address (random))))
 154       (when (string-match
 155              "no arch user id set" (shell-command-to-string "tla my-id"))
 156         (shell-command-to-string
 157          (format "tla my-id \"<%s>\"" user-mail-address)))
 158       (shell-command-to-string
 159        (format "tla make-archive %s %s" archive-name default-directory))
 160       (shell-command-to-string
 161        (format "tla my-default-archive %s" archive-name))))
 162
 163    ((eq backend 'Mtn)
 164     (let ((archive-name "foo.mtn"))
 165       (shell-command-to-string
 166        (format
 167         "mtn db init --db=%s"
 168         (expand-file-name archive-name default-directory)))
 169       (shell-command-to-string
 170        (format "mtn --db=%s --branch=foo setup ." archive-name))))
 171
 172    (t (vc-create-repo backend))))
 173
 174 (defun vc-test--create-repo (backend)
 175   "Create a test repository in `default-directory', a temporary directory."
 176
 177   (let ((vc-handled-backends `(,backend))
 178         (default-directory
 179           (file-name-as-directory
 180            (expand-file-name
 181             (make-temp-name "vc-test") temporary-file-directory)))
 182         vc-test--cleanup-hook)
 183
 184     (unwind-protect
 185         (progn
 186           ;; Cleanup.
 187           (add-hook
 188            'vc-test--cleanup-hook
 189            `(lambda () (delete-directory ,default-directory 'recursive)))
 190
 191           ;; Check the revision granularity.
 192           (should (memq (vc-test--revision-granularity-function backend)
 193                         '(file repository)))
 194
 195           ;; Create empty repository.
 196           (make-directory default-directory)
 197           (should (file-directory-p default-directory))
 198           (vc-test--create-repo-function backend)
 199           (should (eq (vc-responsible-backend default-directory) backend)))
 200
 201       ;; Save exit.
 202       (ignore-errors (run-hooks 'vc-test--cleanup-hook)))))
 203
 204 ;; Why isn't there `vc-unregister'?
 205 (defun vc-test--unregister-function (backend file)
 206   "Run the `vc-unregister' backend function.
 207 For backends which dont support it, `vc-not-supported' is signalled."
 208
 209   (let ((symbol (intern (downcase (format "vc-%s-unregister" backend)))))
 210     (if (functionp symbol)
 211         (funcall symbol file)
 212       ;; CVS, SVN, SCCS, SRC and Mtn are not supported.
 213       (signal 'vc-not-supported (list 'unregister backend)))))
 214
 215 (defun vc-test--register (backend)
 216   "Register and unregister a file."
 217
 218   (let ((vc-handled-backends `(,backend))
 219         (default-directory
 220           (file-name-as-directory
 221            (expand-file-name
 222             (make-temp-name "vc-test") temporary-file-directory)))
 223         vc-test--cleanup-hook)
 224
 225     (unwind-protect
 226         (progn
 227           ;; Cleanup.
 228           (add-hook
 229            'vc-test--cleanup-hook
 230            `(lambda () (delete-directory ,default-directory 'recursive)))
 231
 232           ;; Create empty repository.
 233           (make-directory default-directory)
 234           (vc-test--create-repo-function backend)
 235
 236           (let ((tmp-name1 (expand-file-name "foo" default-directory))
 237                 (tmp-name2 "bla"))
 238             ;; Register files.  Check for it.
 239             (write-region "foo" nil tmp-name1 nil 'nomessage)
 240             (should (file-exists-p tmp-name1))
 241             (should-not (vc-registered tmp-name1))
 242             (write-region "bla" nil tmp-name2 nil 'nomessage)
 243             (should (file-exists-p tmp-name2))
 244             (should-not (vc-registered tmp-name2))
 245             (vc-register (list backend (list tmp-name1 tmp-name2)))
 246             (should (file-exists-p tmp-name1))
 247             (should (vc-registered tmp-name1))
 248             (should (file-exists-p tmp-name2))
 249             (should (vc-registered tmp-name2))
 250
 251             ;; Unregister the files.
 252             (condition-case err
 253                 (progn
 254                   (vc-test--unregister-function backend tmp-name1)
 255                   (should-not (vc-registered tmp-name1))
 256                   (vc-test--unregister-function backend tmp-name2)
 257                   (should-not (vc-registered tmp-name2)))
 258               ;; CVS, SVN, SCCS, SRC and Mtn are not supported.
 259               (vc-not-supported t))
 260             ;; The files shall still exist.
 261             (should (file-exists-p tmp-name1))
 262             (should (file-exists-p tmp-name2))))
 263
 264       ;; Save exit.
 265       (ignore-errors (run-hooks 'vc-test--cleanup-hook)))))
 266
 267 (defun vc-test--state (backend)
 268   "Check the different states of a file."
 269
 270   (let ((vc-handled-backends `(,backend))
 271         (default-directory
 272           (file-name-as-directory
 273            (expand-file-name
 274             (make-temp-name "vc-test") temporary-file-directory)))
 275         vc-test--cleanup-hook)
 276
 277     (unwind-protect
 278         (progn
 279           ;; Cleanup.
 280           (add-hook
 281            'vc-test--cleanup-hook
 282            `(lambda () (delete-directory ,default-directory 'recursive)))
 283
 284           ;; Create empty repository.  Check repository state.
 285           (make-directory default-directory)
 286           (vc-test--create-repo-function backend)
 287
 288           ;; nil: Hg Mtn RCS
 289           ;; added: Git
 290           ;; unregistered: CVS SCCS SRC
 291           ;; up-to-date: Bzr SVN
 292           (should (eq (vc-state default-directory)
 293                       (vc-state default-directory backend)))
 294           (should (memq (vc-state default-directory)
 295                         '(nil added unregistered up-to-date)))
 296
 297           (let ((tmp-name (expand-file-name "foo" default-directory)))
 298             ;; Check state of an empty file.
 299
 300             ;; nil: Hg Mtn SRC SVN
 301             ;; added: Git
 302             ;; unregistered: RCS SCCS
 303             ;; up-to-date: Bzr CVS
 304             (should (eq (vc-state tmp-name) (vc-state tmp-name backend)))
 305             (should (memq (vc-state tmp-name)
 306                           '(nil added unregistered up-to-date)))
 307
 308             ;; Write a new file.  Check state.
 309             (write-region "foo" nil tmp-name nil 'nomessage)
 310
 311             ;; nil: Mtn
 312             ;; added: Git
 313             ;; unregistered: Hg RCS SCCS SRC SVN
 314             ;; up-to-date: Bzr CVS
 315             (should (eq (vc-state tmp-name) (vc-state tmp-name backend)))
 316             (should (memq (vc-state tmp-name)
 317                           '(nil added unregistered up-to-date)))
 318
 319             ;; Register a file.  Check state.
 320             (vc-register
 321              (list backend (list (file-name-nondirectory tmp-name))))
 322
 323             ;; added: Git Mtn
 324             ;; unregistered: Hg RCS SCCS SRC SVN
 325             ;; up-to-date: Bzr CVS
 326             (should (eq (vc-state tmp-name) (vc-state tmp-name backend)))
 327             (should (memq (vc-state tmp-name) '(added unregistered up-to-date)))
 328
 329             ;; Unregister the file.  Check state.
 330             (condition-case nil
 331                 (progn
 332                   (vc-test--unregister-function backend tmp-name)
 333
 334                   ;; added: Git
 335                   ;; unregistered: Hg
 336                   ;; unsupported: CVS Mtn SCCS SRC SVN
 337                   ;; up-to-date: Bzr
 338                   (should (eq (vc-state tmp-name) (vc-state tmp-name backend)))
 339                   (should (memq (vc-state tmp-name)
 340                                 '(added unregistered up-to-date))))
 341               (vc-not-supported t))))
 342
 343       ;; Save exit.
 344       (ignore-errors (run-hooks 'vc-test--cleanup-hook)))))
 345
 346 (defun vc-test--working-revision (backend)
 347   "Check the working revision of a repository."
 348
 349   (let ((vc-handled-backends `(,backend))
 350         (default-directory
 351           (file-name-as-directory
 352            (expand-file-name
 353             (make-temp-name "vc-test") temporary-file-directory)))
 354         vc-test--cleanup-hook)
 355
 356     (unwind-protect
 357         (progn
 358           ;; Cleanup.
 359           (add-hook
 360            'vc-test--cleanup-hook
 361            `(lambda () (delete-directory ,default-directory 'recursive)))
 362
 363           ;; Create empty repository.  Check working revision of
 364           ;; repository, should be nil.
 365           (make-directory default-directory)
 366           (vc-test--create-repo-function backend)
 367
 368           ;; nil: CVS Mtn RCS SCCS
 369           ;; "0": Bzr Hg SRC SVN
 370           ;; "master": Git
 371           (should (eq (vc-working-revision default-directory)
 372                       (vc-working-revision default-directory backend)))
 373           (should
 374            (member
 375             (vc-working-revision default-directory) '(nil "0" "master")))
 376
 377           (let ((tmp-name (expand-file-name "foo" default-directory)))
 378             ;; Check initial working revision, should be nil until
 379             ;; it's registered.
 380
 381             ;; nil: CVS Mtn RCS SCCS SVN
 382             ;; "0": Bzr Hg SRC
 383             ;; "master": Git
 384             (should (eq (vc-working-revision tmp-name)
 385                         (vc-working-revision tmp-name backend)))
 386             (should
 387              (member (vc-working-revision tmp-name) '(nil "0" "master")))
 388
 389             ;; Write a new file.  Check working revision.
 390             (write-region "foo" nil tmp-name nil 'nomessage)
 391
 392             ;; nil: CVS Mtn RCS SCCS SVN
 393             ;; "0": Bzr Hg SRC
 394             ;; "master": Git
 395             (should (eq (vc-working-revision tmp-name)
 396                         (vc-working-revision tmp-name backend)))
 397             (should
 398              (member (vc-working-revision tmp-name) '(nil "0" "master")))
 399
 400             ;; Register a file.  Check working revision.
 401             (vc-register
 402              (list backend (list (file-name-nondirectory tmp-name))))
 403
 404             ;; nil: Mtn RCS SCCS
 405             ;; "0": Bzr CVS Hg SRC SVN
 406             ;; "master": Git
 407             (should (eq (vc-working-revision tmp-name)
 408                         (vc-working-revision tmp-name backend)))
 409             (should
 410              (member (vc-working-revision tmp-name) '(nil "0" "master")))
 411
 412             ;; Unregister the file.  Check working revision.
 413             (condition-case nil
 414                 (progn
 415                   (vc-test--unregister-function backend tmp-name)
 416
 417                   ;; nil: RCS
 418                   ;; "0": Bzr Hg
 419                   ;; "master": Git
 420                   ;; unsupported: CVS Mtn SCCS SRC SVN
 421                   (should (eq (vc-working-revision tmp-name)
 422                               (vc-working-revision tmp-name backend)))
 423                   (should
 424                    (member
 425                     (vc-working-revision tmp-name) '(nil "0" "master"))))
 426               (vc-not-supported t))))
 427
 428       ;; Save exit.
 429       (ignore-errors (run-hooks 'vc-test--cleanup-hook)))))
 430
 431 (defun vc-test--checkout-model (backend)
 432   "Check the checkout model of a repository."
 433
 434   (let ((vc-handled-backends `(,backend))
 435         (default-directory
 436           (file-name-as-directory
 437            (expand-file-name
 438             (make-temp-name "vc-test") temporary-file-directory)))
 439         vc-test--cleanup-hook)
 440
 441     (unwind-protect
 442         (progn
 443           ;; Cleanup.
 444           (add-hook
 445            'vc-test--cleanup-hook
 446            `(lambda () (delete-directory ,default-directory 'recursive)))
 447
 448           ;; Create empty repository.  Check repository checkout model.
 449           (make-directory default-directory)
 450           (vc-test--create-repo-function backend)
 451
 452           ;; Surprisingly, none of the backends returns 'announce.
 453           ;; nil: RCS
 454           ;; implicit: Bzr CVS Git Hg Mtn SRC SVN
 455           ;; locking: SCCS
 456           (should (memq (vc-checkout-model backend default-directory)
 457                         '(announce implicit locking)))
 458
 459           (let ((tmp-name (expand-file-name "foo" default-directory)))
 460             ;; Check checkout model of an empty file.
 461
 462             ;; nil: RCS
 463             ;; implicit: Bzr CVS Git Hg Mtn SRC SVN
 464             ;; locking: SCCS
 465             (should (memq (vc-checkout-model backend tmp-name)
 466                           '(announce implicit locking)))
 467
 468             ;; Write a new file.  Check checkout model.
 469             (write-region "foo" nil tmp-name nil 'nomessage)
 470
 471             ;; nil: RCS
 472             ;; implicit: Bzr CVS Git Hg Mtn SRC SVN
 473             ;; locking: SCCS
 474             (should (memq (vc-checkout-model backend tmp-name)
 475                           '(announce implicit locking)))
 476
 477             ;; Register a file.  Check checkout model.
 478             (vc-register
 479              (list backend (list (file-name-nondirectory tmp-name))))
 480
 481             ;; nil: RCS
 482             ;; implicit: Bzr CVS Git Hg Mtn SRC SVN
 483             ;; locking: SCCS
 484             (should (memq (vc-checkout-model backend tmp-name)
 485                           '(announce implicit locking)))
 486
 487             ;; Unregister the file.  Check checkout model.
 488             (condition-case nil
 489                 (progn
 490                   (vc-test--unregister-function backend tmp-name)
 491
 492                   ;; nil: RCS
 493                   ;; implicit: Bzr Git Hg
 494                   ;; unsupported: CVS Mtn SCCS SRC SVN
 495                   (should (memq (vc-checkout-model backend tmp-name)
 496                                 '(announce implicit locking))))
 497               (vc-not-supported t))))
 498
 499       ;; Save exit.
 500       (ignore-errors (run-hooks 'vc-test--cleanup-hook)))))
 501
 502 ;; Create the test cases.
 503
 504 (defun vc-test--rcs-enabled ()
 505   (executable-find "rcs"))
 506
 507 (defun vc-test--cvs-enabled ()
 508   (executable-find "cvs"))
 509
 510 (defvar vc-svn-program)
 511 (defun vc-test--svn-enabled ()
 512   (executable-find vc-svn-program))
 513
 514 (defun vc-test--sccs-enabled ()
 515   (executable-find "sccs"))
 516
 517 (defvar vc-src-program)
 518 (defun vc-test--src-enabled ()
 519   (executable-find vc-src-program))
 520
 521 (defvar vc-bzr-program)
 522 (defun vc-test--bzr-enabled ()
 523   (executable-find vc-bzr-program))
 524
 525 (defvar vc-git-program)
 526 (defun vc-test--git-enabled ()
 527   (executable-find vc-git-program))
 528
 529 (defvar vc-hg-program)
 530 (defun vc-test--hg-enabled ()
 531   (executable-find vc-hg-program))
 532
 533 (defvar vc-mtn-program)
 534 (defun vc-test--mtn-enabled ()
 535   (executable-find vc-mtn-program))
 536
 537 ;; Obsoleted.
 538 (defvar vc-arch-program)
 539 (defun vc-test--arch-enabled ()
 540   (executable-find vc-arch-program))
 541
 542 ;; Create the test cases.
 543 (dolist (backend vc-handled-backends)
 544   (let ((backend-string (downcase (symbol-name backend))))
 545     (require (intern (format "vc-%s" backend-string)))
 546     (eval
 547      ;; Check, whether the backend is supported.
 548      `(when (funcall ',(intern (format "vc-test--%s-enabled" backend-string)))
 549
 550         (ert-deftest
 551             ,(intern (format "vc-test-%s00-create-repo" backend-string)) ()
 552           ,(format "Check `vc-create-repo' for the %s backend."
 553                    backend-string)
 554           (vc-test--create-repo ',backend))
 555
 556         (ert-deftest
 557             ,(intern (format "vc-test-%s01-register" backend-string)) ()
 558           ,(format
 559             "Check `vc-register' and `vc-registered' for the %s backend."
 560             backend-string)
 561           (skip-unless
 562            (ert-test-passed-p
 563             (ert-test-most-recent-result
 564              (ert-get-test
 565               ',(intern
 566                  (format "vc-test-%s00-create-repo" backend-string))))))
 567           (vc-test--register ',backend))
 568
 569         (ert-deftest
 570             ,(intern (format "vc-test-%s02-state" backend-string)) ()
 571           ,(format "Check `vc-state' for the %s backend." backend-string)
 572           (skip-unless
 573            (ert-test-passed-p
 574             (ert-test-most-recent-result
 575              (ert-get-test
 576               ',(intern
 577                  (format "vc-test-%s01-register" backend-string))))))
 578           (vc-test--state ',backend))
 579
 580         (ert-deftest
 581             ,(intern (format "vc-test-%s03-working-revision" backend-string)) ()
 582           ,(format "Check `vc-working-revision' for the %s backend."
 583                    backend-string)
 584           (skip-unless
 585            (ert-test-passed-p
 586             (ert-test-most-recent-result
 587              (ert-get-test
 588               ',(intern
 589                  (format "vc-test-%s01-register" backend-string))))))
 590           (vc-test--working-revision ',backend))
 591
 592         (ert-deftest
 593             ,(intern (format "vc-test-%s04-checkout-model" backend-string)) ()
 594           ,(format "Check `vc-checkout-model' for the %s backend."
 595                    backend-string)
 596           ;; FIXME make this pass.
 597           :expected-result ,(if (equal backend 'RCS) :failed :passed)
 598           (skip-unless
 599            (ert-test-passed-p
 600             (ert-test-most-recent-result
 601              (ert-get-test
 602               ',(intern
 603                  (format "vc-test-%s01-register" backend-string))))))
 604           (vc-test--checkout-model ',backend))))))
 605
 606 (provide 'vc-tests)
 607 ;;; vc-tests.el ends here