code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.61)
  25 AC_INIT(emacs, 23.0.92)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 if test "$with_hesiod" != no; then
  95   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  96 fi
  97
  98 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
  99
 100 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 101 if test "$with_sync_input" = yes; then
 102    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 103 fi
 104
 105 dnl FIXME currently it is not the last.
 106 dnl This should be the last --with option, because --with-x is
 107 dnl added later on when we find the path of X, and it's best to
 108 dnl keep them together visually.
 109 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 110  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 111 [         case "${withval}" in
 112             y | ye | yes )      val=gtk ;;
 113             n | no )            val=no  ;;
 114             l | lu | luc | luci | lucid )       val=lucid ;;
 115             a | at | ath | athe | athen | athena )      val=athena ;;
 116             m | mo | mot | moti | motif )       val=motif ;;
 117             g | gt | gtk  )     val=gtk ;;
 118             * )
 119 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 120 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 121 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 122             ;;
 123           esac
 124           with_x_toolkit=$val
 125 ])
 126
 127 dnl _ON results in a '--without' option in the --help output, so
 128 dnl the help text should refer to "don't compile", etc.
 129 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 130 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 131 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 132 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 133 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 134 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 135
 136 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 137 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 138 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 139
 140 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 141 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 142 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 143 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 144
 145 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 146 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 147
 148 ## For the times when you want to build Emacs but don't have
 149 ## a suitable makeinfo, and can live without the manuals.
 150 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 151 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 152
 153 dnl Can remove these in Emacs 24.
 154 AC_ARG_WITH([gtk],,
 155   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 156 specify a toolkit.])],,)
 157
 158 AC_ARG_WITH([gcc],,
 159   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 160 variable to specify a compiler.])],,)
 161
 162 AC_ARG_WITH([pkg-config-prog],dnl
 163 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 164                   [path to pkg-config for finding GTK and librsvg])])
 165 if test "X${with_pkg_config_prog}" != X; then
 166    if test "${with_pkg_config_prog}" != yes; then
 167       PKG_CONFIG="${with_pkg_config_prog}"
 168    fi
 169 fi
 170
 171 AC_ARG_WITH([gnustep-conf],dnl
 172 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 173 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 174   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 175 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 176      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 177
 178 AC_ARG_ENABLE(ns-self-contained,
 179 [AS_HELP_STRING([--disable-ns-self-contained],
 180                 [disable self contained build under NeXTstep])],
 181    EN_NS_SELF_CONTAINED=$enableval,
 182    EN_NS_SELF_CONTAINED=yes)
 183
 184 AC_ARG_ENABLE(asserts,
 185 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 186       USE_XASSERTS=$enableval,
 187       USE_XASSERTS=no)
 188
 189 AC_ARG_ENABLE(maintainer-mode,
 190 [AS_HELP_STRING([--enable-maintainer-mode],
 191                 [enable make rules and dependencies not useful (and sometimes
 192                  confusing) to the casual installer])],
 193       USE_MAINTAINER_MODE=$enableval,
 194       USE_MAINTAINER_MODE=no)
 195 if test $USE_MAINTAINER_MODE = yes; then
 196   MAINT=
 197 else
 198   MAINT=#
 199 fi
 200 AC_SUBST(MAINT)
 201
 202 AC_ARG_ENABLE(locallisppath,
 203 [AS_HELP_STRING([--enable-locallisppath=PATH],
 204                 [directories Emacs should search for lisp files specific
 205                  to this site])],
 206 if test "${enableval}" = "no"; then
 207   locallisppath=
 208 elif test "${enableval}" != "yes"; then
 209   locallisppath=${enableval}
 210 fi)
 211
 212 #### Make srcdir absolute, if it isn't already.  It's important to
 213 #### avoid running the path through pwd unnecessarily, since pwd can
 214 #### give you automounter prefixes, which can go away.  We do all this
 215 #### so Emacs can find its files when run uninstalled.
 216 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 217 unset CDPATH
 218 case "${srcdir}" in
 219   /* ) ;;
 220   . )
 221     ## We may be able to use the $PWD environment variable to make this
 222     ## absolute.  But sometimes PWD is inaccurate.
 223     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 224     ## but that tested only for a well-formed and valid PWD,
 225     ## it did not object when PWD was well-formed and valid but just wrong.
 226     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 227     then
 228       srcdir="$PWD"
 229     else
 230       srcdir="`(cd ${srcdir}; pwd)`"
 231     fi
 232   ;;
 233   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 234 esac
 235
 236 #### Check if the source directory already has a configured system in it.
 237 if test `pwd` != `(cd ${srcdir} && pwd)` \
 238    && test -f "${srcdir}/src/config.h" ; then
 239   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 240    as a build directory right now; it has been configured in its own
 241    right.  To configure in another directory as well, you MUST
 242    use GNU make.  If you do not have GNU make, then you must
 243    now do `make distclean' in ${srcdir},
 244    and then run $0 again.]])
 245 fi
 246
 247 #### Given the configuration name, set machfile and opsysfile to the
 248 #### names of the m/*.h and s/*.h files we should use.
 249
 250 ### Canonicalize the configuration name.
 251
 252 AC_CANONICAL_HOST
 253 canonical=$host
 254 configuration=${host_alias-${build_alias-$host}}
 255
 256 dnl This used to use changequote, but, apart from `changequote is evil'
 257 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 258 dnl the great gob of text.  Thus it's not processed for possible expansion.
 259 dnl Just make sure the brackets remain balanced.
 260 dnl
 261 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 262 dnl indicated by comments.
 263 dnl quotation begins
 264 [
 265
 266 ### If you add support for a new configuration, add code to this
 267 ### switch statement to recognize your configuration name and select
 268 ### the appropriate operating system and machine description files.
 269
 270 ### You would hope that you could choose an m/*.h file pretty much
 271 ### based on the machine portion of the configuration name, and an s-
 272 ### file based on the operating system portion.  However, it turns out
 273 ### that each m/*.h file is pretty manufacturer-specific - for
 274 ### example mips.h is MIPS
 275 ### So we basically have to have a special case for each
 276 ### configuration name.
 277 ###
 278 ### As far as handling version numbers on operating systems is
 279 ### concerned, make sure things will fail in a fixable way.  If
 280 ### /etc/MACHINES doesn't say anything about version numbers, be
 281 ### prepared to handle anything reasonably.  If version numbers
 282 ### matter, be sure /etc/MACHINES says something about it.
 283 ###
 284 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 285 ### "System V Release 4"; he writes, "The old convention encouraged
 286 ### confusion between `system' and `release' levels'."
 287
 288 machine='' opsys='' unported=no
 289 case "${canonical}" in
 290
 291   ## FreeBSD ports
 292   *-*-freebsd* )
 293     opsys=freebsd
 294     case "${canonical}" in
 295       alpha*-*-freebsd*)        machine=alpha ;;
 296       arm*-*-freebsd*)          machine=arm ;;
 297       ia64-*-freebsd*)          machine=ia64 ;;
 298       sparc-*-freebsd*)         machine=sparc ;;
 299       sparc64-*-freebsd*)       machine=sparc ;;
 300       powerpc-*-freebsd*)       machine=macppc ;;
 301       i[3456]86-*-freebsd*)     machine=intel386 ;;
 302       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 303     esac
 304   ;;
 305
 306   ## FreeBSD kernel + glibc based userland
 307   *-*-kfreebsd*gnu* )
 308     opsys=gnu-kfreebsd
 309     case "${canonical}" in
 310       alpha*-*-kfreebsd*)       machine=alpha ;;
 311       ia64-*-kfreebsd*)         machine=ia64 ;;
 312       sparc-*-kfreebsd*)        machine=sparc ;;
 313       sparc64-*-kfreebsd*)      machine=sparc ;;
 314       powerpc-*-kfreebsd*)      machine=macppc ;;
 315       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 316       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 317     esac
 318   ;;
 319
 320   ## NetBSD ports
 321   *-*-netbsd* )
 322     opsys=netbsd
 323     if test -f /usr/lib/crti.o; then]
 324 dnl The close and open brackets here are because this section is quoted --
 325 dnl see the `changequote' comment above.
 326       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 327 [   fi
 328
 329     case "${canonical}" in
 330       alpha*-*-netbsd*) machine=alpha ;;
 331       i[3456]86-*-netbsd*) machine=intel386 ;;
 332       powerpc-*-netbsd*) machine=macppc ;;
 333       sparc*-*-netbsd*) machine=sparc ;;
 334       vax-*-netbsd*)    machine=vax ;;
 335       arm-*-netbsd*)    machine=arm ;;
 336       x86_64-*-netbsd*) machine=amdx86-64 ;;
 337       hppa-*-netbsd*)   machine=hp800 ;;
 338       m68k-*-netbsd*)   machine=m68k ;;
 339     esac
 340   ;;
 341
 342   ## OpenBSD ports
 343   *-*-openbsd* )
 344     opsys=openbsd
 345     case "${canonical}" in
 346       alpha*-*-openbsd*)        machine=alpha ;;
 347       arm-*-openbsd*)          machine=arm ;;
 348       i386-*-openbsd*)         machine=intel386 ;;
 349       powerpc-*-openbsd*)      machine=macppc ;;
 350       sparc*-*-openbsd*)       machine=sparc ;;
 351       vax-*-openbsd*)          machine=vax ;;
 352       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 353       hppa-*-openbsd*)         machine=hp800 ;;
 354     esac
 355   ;;
 356
 357   ## LynxOS ports
 358   *-*-lynxos* )
 359     opsys=lynxos
 360     case "${canonical}" in
 361       i[3456]86-*-lynxos*) machine=intel386 ;;
 362       powerpc-*-lynxos*) machine=powerpc ;;
 363     esac
 364   ;;
 365
 366   alpha*-*-linux-gnu* )
 367     machine=alpha opsys=gnu-linux
 368   ;;
 369
 370   arm*-*-linux-gnu* )
 371     machine=arm opsys=gnu-linux
 372   ;;
 373
 374   ## Apple Darwin / Mac OS X
 375   *-apple-darwin* )
 376     case "${canonical}" in
 377       i[3456]86-* )  machine=intel386 ;;
 378       powerpc-* )    machine=macppc ;;
 379       * )            unported=yes ;;
 380     esac
 381     opsys=darwin
 382     # Define CPP as follows to make autoconf work correctly.
 383     CPP="${CC-cc} -E -no-cpp-precomp"
 384     # Use fink packages if available.
 385     if test -d /sw/include && test -d /sw/lib; then
 386       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 387       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 388       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 389     fi
 390   ;;
 391
 392   ## HP 9000 series 700 and 800, running HP/UX
 393   hppa*-hp-hpux10.2* )
 394     machine=hp800 opsys=hpux10-20
 395   ;;
 396   hppa*-hp-hpux1[1-9]* )
 397     machine=hp800 opsys=hpux11
 398     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 399   ;;
 400
 401   hppa*-*-linux-gnu* )
 402     machine=hp800 opsys=gnu-linux
 403   ;;
 404
 405   ## IBM machines
 406   s390-*-linux-gnu* )
 407     machine=ibms390 opsys=gnu-linux
 408   ;;
 409   s390x-*-linux-gnu* )
 410     machine=ibms390x opsys=gnu-linux
 411   ;;
 412   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 413     machine=ibmrs6000 opsys=aix4-2
 414   ;;
 415   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 416     machine=ibmrs6000 opsys=aix4-2
 417   ;;
 418   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 419     machine=ibmrs6000 opsys=aix4-2
 420   ;;
 421   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 422     machine=ibmrs6000 opsys=aix4-2
 423   ;;
 424
 425   ## Macintosh PowerPC
 426   powerpc*-*-linux-gnu* )
 427     machine=macppc opsys=gnu-linux
 428   ;;
 429
 430   ## Silicon Graphics machines
 431   ## Iris 4D
 432   mips-sgi-irix6.5 )
 433     machine=iris4d opsys=irix6-5
 434     # Without defining _LANGUAGE_C, things get masked out in the headers
 435     # so that, for instance, grepping for `free' in stdlib.h fails and
 436     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 437     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 438     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 439   ;;
 440
 441   ## Suns
 442   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 443     machine=sparc opsys=gnu-linux
 444   ;;
 445
 446   *-sun-solaris* \
 447     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 448     | x86_64-*-solaris2*    | x86_64-*-sunos5*    \
 449     | powerpc*-*-solaris2*  | rs6000-*-solaris2*)
 450     case "${canonical}" in
 451       i[3456]86-*-* )     machine=intel386 ;;
 452       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 453       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 454       sparc* )          machine=sparc ;;
 455       * )               unported=yes ;;
 456     esac
 457     case "${canonical}" in
 458       *-sunos5.3* | *-solaris2.3* )
 459                 opsys=sol2-3
 460                 NON_GNU_CPP=/usr/ccs/lib/cpp
 461                 ;;
 462       *-sunos5.4* | *-solaris2.4* )
 463                 opsys=sol2-4
 464                 NON_GNU_CPP=/usr/ccs/lib/cpp
 465                 RANLIB="ar -ts"
 466                 ;;
 467       *-sunos5.5* | *-solaris2.5* )
 468                 opsys=sol2-5
 469                 NON_GNU_CPP=/usr/ccs/lib/cpp
 470                 RANLIB="ar -ts"
 471                 ;;
 472       *-sunos5.6* | *-solaris2.6* )
 473                 opsys=sol2-6
 474                 NON_GNU_CPP=/usr/ccs/lib/cpp
 475                 RANLIB="ar -ts"
 476                 ;;
 477       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 478                 opsys=sol2-6
 479                 emacs_check_sunpro_c=yes
 480                 NON_GNU_CPP=/usr/ccs/lib/cpp
 481                 ;;
 482       *-sunos5* | *-solaris* )
 483                 opsys=sol2-10
 484                 emacs_check_sunpro_c=yes
 485                 NON_GNU_CPP=/usr/ccs/lib/cpp
 486                 ;;
 487     esac
 488     ## Watch out for a compiler that we know will not work.
 489     case "${canonical}" in
 490      *-solaris* | *-sunos5* )
 491                 if [ "x$CC" = x/usr/ucb/cc ]; then
 492                   ## /usr/ucb/cc doesn't work;
 493                   ## we should find some other compiler that does work.
 494                   unset CC
 495                 fi
 496                 ;;
 497       *) ;;
 498     esac
 499   ;;
 500
 501   ## Vaxen.
 502   vax-dec-* )
 503     machine=vax
 504     case "${canonical}" in
 505       *-vms* )                                          opsys=vms ;;
 506       * )                                               unported=yes
 507     esac
 508   ;;
 509
 510   ## IA-64
 511   ia64*-*-linux* )
 512     machine=ia64 opsys=gnu-linux
 513   ;;
 514
 515   ## Intel 386 machines where we don't care about the manufacturer
 516   i[3456]86-*-* )
 517     machine=intel386
 518     case "${canonical}" in
 519       *-cygwin )                opsys=cygwin ;;
 520       *-darwin* )               opsys=darwin
 521                                 CPP="${CC-cc} -E -no-cpp-precomp"
 522                                 ;;
 523       *-linux-gnu* )            opsys=gnu-linux ;;
 524       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 525       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 526       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 527       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 528     esac
 529   ;;
 530
 531   ## m68k Linux-based GNU system
 532   m68k-*-linux-gnu* )
 533     machine=m68k opsys=gnu-linux
 534   ;;
 535
 536   ## Mips Linux-based GNU system
 537   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 538     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 539     machine=mips opsys=gnu-linux
 540   ;;
 541
 542   ## AMD x86-64 Linux-based GNU system
 543   x86_64-*-linux-gnu* )
 544     machine=amdx86-64 opsys=gnu-linux
 545   ;;
 546
 547   ## Tensilica Xtensa Linux-based GNU system
 548   xtensa*-*-linux-gnu* )
 549     machine=xtensa opsys=gnu-linux
 550     ;;
 551
 552   ## SuperH Linux-based GNU system
 553   sh[34]*-*-linux-gnu* )
 554     machine=sh3 opsys=gnu-linux
 555   ;;
 556
 557   * )
 558     unported=yes
 559   ;;
 560 esac
 561
 562 ### If the code above didn't choose an operating system, just choose
 563 ### an operating system based on the configuration name.  You really
 564 ### only want to use this when you have no idea what the right
 565 ### operating system is; if you know what operating systems a machine
 566 ### runs, it's cleaner to make it explicit in the case statement
 567 ### above.
 568 if test x"${opsys}" = x; then
 569   case "${canonical}" in
 570     *-gnu* )                            opsys=gnu ;;
 571     *-sysv4.2uw* )                      opsys=unixware ;;
 572     *-sysv5uw* )                        opsys=unixware ;;
 573     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 574     *-sysv4.1* | *-sysvr4.1* )
 575         NON_GNU_CPP=/usr/lib/cpp
 576         opsys=usg5-4 ;;
 577     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 578         if [ x$NON_GNU_CPP = x ]; then
 579           if [ -f /usr/ccs/lib/cpp ]; then
 580             NON_GNU_CPP=/usr/ccs/lib/cpp
 581           else
 582             NON_GNU_CPP=/lib/cpp
 583           fi
 584         fi
 585         opsys=usg5-4-2 ;;
 586     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 587     * )
 588       unported=yes
 589     ;;
 590   esac
 591 fi
 592
 593 ]
 594 dnl quotation ends
 595
 596 if test $unported = yes; then
 597   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 598 Check `etc/MACHINES' for recognized configuration names.])
 599 fi
 600
 601 machfile="m/${machine}.h"
 602 opsysfile="s/${opsys}.h"
 603
 604
 605 #### Choose a compiler.
 606 test -n "$CC" && cc_specified=yes
 607
 608 # Save the value of CFLAGS that the user specified.
 609 SPECIFIED_CFLAGS="$CFLAGS"
 610
 611 dnl Sets GCC=yes if using gcc.
 612 AC_PROG_CC
 613
 614 # On Suns, sometimes $CPP names a directory.
 615 if test -n "$CPP" && test -d "$CPP"; then
 616   CPP=
 617 fi
 618
 619 ## If not using gcc, and on Solaris, and no CPP specified, see if
 620 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 621 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 622  test x"$CPP" = x; then
 623   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 624   AC_CACHE_VAL(emacs_cv_sunpro_c,
 625   [AC_TRY_LINK([],
 626 [#ifndef __SUNPRO_C
 627 fail;
 628 #endif
 629 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 630   AC_MSG_RESULT($emacs_cv_sunpro_c)
 631
 632   if test x"$emacs_cv_sunpro_c" = xyes; then
 633     NON_GNU_CPP="$CC -E -Xs"
 634   fi
 635 fi
 636
 637 #### Some systems specify a CPP to use unless we are using GCC.
 638 #### Now that we know whether we are using GCC, we can decide whether
 639 #### to use that one.
 640 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 641 then
 642   CPP="$NON_GNU_CPP"
 643 fi
 644
 645 #### Some systems specify a CC to use unless we are using GCC.
 646 #### Now that we know whether we are using GCC, we can decide whether
 647 #### to use that one.
 648 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 649   test x$cc_specified != xyes
 650 then
 651   CC="$NON_GNU_CC"
 652 fi
 653
 654 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 655 then
 656   CC="$CC $GCC_TEST_OPTIONS"
 657 fi
 658
 659 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 660 then
 661   CC="$CC $NON_GCC_TEST_OPTIONS"
 662 fi
 663
 664 dnl checks for Unix variants
 665 AC_USE_SYSTEM_EXTENSIONS
 666
 667 ### Use -Wno-pointer-sign if the compiler supports it
 668 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 669 SAVE_CFLAGS="$CFLAGS"
 670 CFLAGS="$CFLAGS -Wno-pointer-sign"
 671 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 672 if test $has_option = yes; then
 673    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 674 fi
 675 AC_MSG_RESULT($has_option)
 676 CFLAGS="$SAVE_CFLAGS"
 677 unset has_option
 678 unset SAVE_CFLAGS
 679
 680 #### Some other nice autoconf tests.
 681
 682 dnl checks for programs
 683 AC_PROG_LN_S
 684 AC_PROG_CPP
 685 AC_PROG_INSTALL
 686 if test "x$RANLIB" = x; then
 687   AC_PROG_RANLIB
 688 fi
 689 AC_PATH_PROG(INSTALL_INFO, install-info)
 690 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 691 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 692 dnl Don't use GZIP, which is used by gzip for additional parameters.
 693 AC_PATH_PROG(GZIP_PROG, gzip)
 694
 695
 696 ## Need makeinfo >= 4.6 (?) to build the manuals.
 697 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 698 dnl By this stage, configure has already checked for egrep and set EGREP,
 699 dnl or exited with an error if no egrep was found.
 700 if test "$MAKEINFO" != "no" && \
 701   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 702    MAKEINFO=no
 703 fi
 704
 705 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 706 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 707 ## therefore in the category of "special tools" not normally required, which
 708 ## configure does not have to check for (eg autoconf itself).
 709 ## In a CVS checkout on the other hand, the manuals are not included.
 710 ## So makeinfo is a requirement to build from CVS, and configure
 711 ## should test for it as it does for any other build requirement.
 712 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 713 ## with pre-built manuals, from a CVS checkout.
 714 if test "$MAKEINFO" = "no"; then
 715   if test "x${with_makeinfo}" = "xno"; then
 716     MAKEINFO=off
 717   elif ! test -e $srcdir/info/emacs; then
 718     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 719 source tree does not seem to have pre-built manuals in the `info' directory.
 720 Either install a suitable version of makeinfo, or re-run configure
 721 with the `--without-makeinfo' option to build without the manuals.] )
 722   fi
 723 fi
 724
 725 dnl Add our options to ac_link now, after it is set up.
 726
 727 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 728 then
 729   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 730 fi
 731
 732 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 733 then
 734   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 735 fi
 736
 737 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 738 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 739 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 740 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 741 dnl if not built to support GNU ld.
 742
 743 late_LDFLAGS=$LDFLAGS
 744 if test "$GCC" = yes; then
 745   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 746 else
 747   LDFLAGS="$LDFLAGS -znocombreloc"
 748 fi
 749
 750 AC_MSG_CHECKING([for -znocombreloc])
 751 AC_LINK_IFELSE([main(){return 0;}],
 752   [AC_MSG_RESULT(yes)],
 753   LDFLAGS=$late_LDFLAGS
 754   [AC_MSG_RESULT(no)])
 755
 756 #### Extract some information from the operating system and machine files.
 757
 758 AC_CHECKING([the machine- and system-dependent files to find out
 759  - which libraries the lib-src programs will want, and
 760  - whether the GNU malloc routines are usable])
 761
 762 ### First figure out CFLAGS (which we use for running the compiler here)
 763 ### and REAL_CFLAGS (which we use for real compilation).
 764 ### The two are the same except on a few systems, where they are made
 765 ### different to work around various lossages.  For example,
 766 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 767 ### as implying static linking.
 768
 769 ### If the CFLAGS env var is specified, we use that value
 770 ### instead of the default.
 771
 772 ### It's not important that this name contain the PID; you can't run
 773 ### two configures in the same directory and have anything work
 774 ### anyway.
 775 tempcname="conftest.c"
 776
 777 echo '
 778 #include "'${srcdir}'/src/'${opsysfile}'"
 779 #include "'${srcdir}'/src/'${machfile}'"
 780 #ifndef LIBS_MACHINE
 781 #define LIBS_MACHINE
 782 #endif
 783 #ifndef LIBS_SYSTEM
 784 #define LIBS_SYSTEM
 785 #endif
 786 #ifndef C_SWITCH_SYSTEM
 787 #define C_SWITCH_SYSTEM
 788 #endif
 789 #ifndef C_SWITCH_MACHINE
 790 #define C_SWITCH_MACHINE
 791 #endif
 792 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 793 configure___ c_switch_system=C_SWITCH_SYSTEM
 794 configure___ c_switch_machine=C_SWITCH_MACHINE
 795
 796 #ifndef LIB_X11_LIB
 797 #define LIB_X11_LIB -lX11
 798 #endif
 799
 800 #ifndef LIBX11_SYSTEM
 801 #define LIBX11_SYSTEM
 802 #endif
 803 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 804
 805 #ifdef UNEXEC
 806 configure___ unexec=UNEXEC
 807 #else
 808 configure___ unexec=unexec.o
 809 #endif
 810
 811 #ifdef SYSTEM_MALLOC
 812 configure___ system_malloc=yes
 813 #else
 814 configure___ system_malloc=no
 815 #endif
 816
 817 #ifdef USE_MMAP_FOR_BUFFERS
 818 configure___ use_mmap_for_buffers=yes
 819 #else
 820 configure___ use_mmap_for_buffers=no
 821 #endif
 822
 823 #ifndef C_DEBUG_SWITCH
 824 #define C_DEBUG_SWITCH -g
 825 #endif
 826
 827 #ifndef C_OPTIMIZE_SWITCH
 828 #ifdef __GNUC__
 829 #define C_OPTIMIZE_SWITCH -O2
 830 #else
 831 #define C_OPTIMIZE_SWITCH -O
 832 #endif
 833 #endif
 834
 835 #ifndef C_WARNINGS_SWITCH
 836 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 837 #endif
 838
 839 #ifndef LD_SWITCH_MACHINE
 840 #define LD_SWITCH_MACHINE
 841 #endif
 842
 843 #ifndef LD_SWITCH_SYSTEM
 844 #define LD_SWITCH_SYSTEM
 845 #endif
 846
 847 #ifndef LD_SWITCH_X_SITE_AUX
 848 #define LD_SWITCH_X_SITE_AUX
 849 #endif
 850
 851 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 852 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 853
 854 #ifdef THIS_IS_CONFIGURE
 855
 856 /* Get the CFLAGS for tests in configure.  */
 857 #ifdef __GNUC__
 858 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 859 #else
 860 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 861 #endif
 862
 863 #else /* not THIS_IS_CONFIGURE */
 864
 865 /* Get the CFLAGS for real compilation.  */
 866 #ifdef __GNUC__
 867 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
 868 #else
 869 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 870 #endif
 871
 872 #endif /* not THIS_IS_CONFIGURE */
 873 ' > ${tempcname}
 874
 875 # The value of CPP is a quoted variable reference, so we need to do this
 876 # to get its actual value...
 877 CPP=`eval "echo $CPP"`
 878 [eval `${CPP} -Isrc ${tempcname} \
 879        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 880 if test "x$SPECIFIED_CFLAGS" = x; then
 881   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 882          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 883 else
 884   REAL_CFLAGS="$CFLAGS"
 885 fi]
 886 rm ${tempcname}
 887
 888 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 889
 890 ### Make sure subsequent tests use flags consistent with the build flags.
 891
 892 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 893   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 894 else
 895   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 896 fi
 897
 898 dnl For AC_FUNC_GETLOADAVG, at least:
 899 AC_CONFIG_LIBOBJ_DIR(src)
 900
 901 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 902 AC_SYS_LARGEFILE
 903
 904
 905 ### The standard library on x86-64 and s390x GNU/Linux distributions can
 906 ### be located in either /usr/lib64 or /usr/lib.
 907 ### In some rare cases, /usr/lib64 exists but does not contain the
 908 ### relevant files (bug#1287).  Hence test for crtn.o.
 909 case "${canonical}" in
 910   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
 911     if test -e /usr/lib64/crtn.o; then
 912       AC_DEFINE(HAVE_LIB64_DIR, 1,
 913         [Define to 1 if the directory /usr/lib64 exists.])
 914 fi
 915 esac
 916
 917 dnl This function defintion taken from Gnome 2.0
 918 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
 919 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
 920 dnl also defines GSTUFF_PKG_ERRORS on error
 921 AC_DEFUN([PKG_CHECK_MODULES], [
 922   succeeded=no
 923
 924   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 925
 926   if test "$PKG_CONFIG" = "no" ; then
 927      ifelse([$4], , [AC_MSG_ERROR([
 928       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
 929   else
 930      PKG_CONFIG_MIN_VERSION=0.9.0
 931      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
 932         AC_MSG_CHECKING(for $2)
 933
 934         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
 935             AC_MSG_RESULT(yes)
 936             succeeded=yes
 937
 938             AC_MSG_CHECKING($1_CFLAGS)
 939             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
 940             AC_MSG_RESULT($$1_CFLAGS)
 941
 942             AC_MSG_CHECKING($1_LIBS)
 943             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
 944             AC_MSG_RESULT($$1_LIBS)
 945         else
 946             AC_MSG_RESULT(no)
 947             $1_CFLAGS=""
 948             $1_LIBS=""
 949             ## If we have a custom action on failure, don't print errors, but
 950             ## do set a variable so people can do so.
 951             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
 952             ifelse([$4], ,echo $$1_PKG_ERRORS,)
 953         fi
 954
 955         AC_SUBST($1_CFLAGS)
 956         AC_SUBST($1_LIBS)
 957      else
 958         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
 959         echo "*** See http://www.freedesktop.org/software/pkgconfig"
 960      fi
 961   fi
 962
 963   if test $succeeded = yes; then
 964      ifelse([$3], , :, [$3])
 965   else
 966      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
 967   fi
 968 ])
 969
 970
 971 if test "${with_sound}" != "no"; then
 972   # Sound support for GNU/Linux and the free BSDs.
 973   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
 974   # Emulation library used on NetBSD.
 975   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
 976   AC_SUBST(LIBSOUND)
 977
 978   ALSA_REQUIRED=1.0.0
 979   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
 980   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
 981   if test $HAVE_ALSA = yes; then
 982     SAVE_CFLAGS="$CFLAGS"
 983     SAVE_LDFLAGS="$LDFLAGS"
 984     CFLAGS="$ALSA_CFLAGS $CFLAGS"
 985     LDFLAGS="$ALSA_LIBS $LDFLAGS"
 986     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
 987                     emacs_alsa_normal=yes,
 988                     emacs_alsa_normal=no)
 989     if test "$emacs_alsa_normal" != yes; then
 990       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
 991                      [snd_lib_error_set_handler (0);],
 992                      emacs_alsa_subdir=yes,
 993                      emacs_alsa_subdir=no)
 994       if test "$emacs_alsa_subdir" != yes; then
 995         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
 996       fi
 997       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
 998     fi
 999
1000     CFLAGS="$SAVE_CFLAGS"
1001     LDFLAGS="$SAVE_LDFLAGS"
1002     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1003     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1004     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1005   fi
1006   AC_SUBST(CFLAGS_SOUND)
1007 fi
1008
1009 dnl checks for header files
1010 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1011   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1012   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1013   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1014   sys/utsname.h pwd.h)
1015
1016 AC_MSG_CHECKING(if personality LINUX32 can be set)
1017 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1018                emacs_cv_personality_linux32=yes,
1019                emacs_cv_personality_linux32=no)
1020 AC_MSG_RESULT($emacs_cv_personality_linux32)
1021
1022 if test $emacs_cv_personality_linux32 = yes; then
1023   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1024             [Define to 1 if personality LINUX32 can be set.])
1025 fi
1026
1027 dnl On Solaris 8 there's a compilation warning for term.h because
1028 dnl it doesn't define `bool'.
1029 AC_CHECK_HEADERS(term.h, , , -)
1030 AC_HEADER_STDC
1031 AC_HEADER_TIME
1032 AC_CHECK_DECLS([sys_siglist])
1033 if test $ac_cv_have_decl_sys_siglist != yes; then
1034   # For Tru64, at least:
1035   AC_CHECK_DECLS([__sys_siglist])
1036   if test $ac_cv_have_decl___sys_siglist = yes; then
1037     AC_DEFINE(sys_siglist, __sys_siglist,
1038               [Define to any substitute for sys_siglist.])
1039   fi
1040 fi
1041 AC_HEADER_SYS_WAIT
1042
1043 dnl Some systems have utime.h but don't declare the struct anyplace.
1044 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1045 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1046 #include <sys/time.h>
1047 #include <time.h>
1048 #else
1049 #ifdef HAVE_SYS_TIME_H
1050 #include <sys/time.h>
1051 #else
1052 #include <time.h>
1053 #endif
1054 #endif
1055 #ifdef HAVE_UTIME_H
1056 #include <utime.h>
1057 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1058   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1059 if test $emacs_cv_struct_utimbuf = yes; then
1060   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1061 fi
1062
1063 dnl checks for typedefs
1064 AC_TYPE_SIGNAL
1065
1066 dnl Check for speed_t typedef.
1067 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1068   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1069     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1070 if test $emacs_cv_speed_t = yes; then
1071   AC_DEFINE(HAVE_SPEED_T, 1,
1072            [Define to 1 if `speed_t' is declared by <termios.h>.])
1073 fi
1074
1075 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1076 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1077 #include <sys/time.h>
1078 #include <time.h>
1079 #else
1080 #ifdef HAVE_SYS_TIME_H
1081 #include <sys/time.h>
1082 #else
1083 #include <time.h>
1084 #endif
1085 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1086   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1087 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1088 if test $emacs_cv_struct_timeval = yes; then
1089   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1090 fi
1091
1092 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1093 AC_TRY_COMPILE([#include <math.h>],
1094 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1095   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1096 HAVE_EXCEPTION=$emacs_cv_struct_exception
1097 if test $emacs_cv_struct_exception != yes; then
1098   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1099 fi
1100
1101 AC_CHECK_HEADERS(sys/socket.h)
1102 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1103 #if HAVE_SYS_SOCKET_H
1104 #include <sys/socket.h>
1105 #endif])
1106
1107 dnl checks for structure members
1108 AC_STRUCT_TM
1109 AC_STRUCT_TIMEZONE
1110 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1111                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1112                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1113                 [#include <time.h>])
1114 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1115                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1116                   struct ifreq.ifr_addr], , ,
1117                  [AC_INCLUDES_DEFAULT
1118 #if HAVE_SYS_SOCKET_H
1119 #include <sys/socket.h>
1120 #endif
1121 #if HAVE_NET_IF_H
1122 #include <net/if.h>
1123 #endif])
1124
1125 dnl checks for compiler characteristics
1126
1127 dnl Testing __STDC__ to determine prototype support isn't good enough.
1128 dnl DEC C, for instance, doesn't define it with default options, and
1129 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1130 dnl and void *.
1131 AC_C_PROTOTYPES
1132 AC_C_VOLATILE
1133 AC_C_CONST
1134 dnl This isn't useful because we can't turn on use of `inline' unless
1135 dnl the compiler groks `extern inline'.
1136 dnl AC_C_INLINE
1137 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1138   [AC_TRY_COMPILE(, [void * foo;],
1139                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1140 if test $emacs_cv_void_star = yes; then
1141   AC_DEFINE(POINTER_TYPE, void)
1142 else
1143   AC_DEFINE(POINTER_TYPE, char)
1144 fi
1145 AH_TEMPLATE(POINTER_TYPE,
1146             [Define as `void' if your compiler accepts `void *'; otherwise
1147              define as `char'.])dnl
1148
1149
1150
1151 dnl This could be used for targets which can have both byte sexes.
1152 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1153 dnl AC_C_BIGENDIAN
1154
1155 dnl check for Make feature
1156 AC_PROG_MAKE_SET
1157
1158 dnl checks for operating system services
1159 AC_SYS_LONG_FILE_NAMES
1160
1161 #### Choose a window system.
1162
1163 AC_PATH_X
1164 if test "$no_x" = yes; then
1165   window_system=none
1166 else
1167   window_system=x11
1168 fi
1169
1170 ## Workaround for bug in autoconf <= 2.62.
1171 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1172 ## No need to do anything special for these standard directories.
1173 ## This is an experiment, take it out if it causes problems.
1174 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1175
1176    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1177
1178 fi
1179
1180 if test "${x_libraries}" != NONE; then
1181   if test -n "${x_libraries}"; then
1182     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1183     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1184   fi
1185   x_default_search_path=""
1186   x_search_path=${x_libraries}
1187   if test -z "${x_search_path}"; then
1188     x_search_path=/usr/lib
1189   fi
1190   for x_library in `echo ${x_search_path}: | \
1191                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1192     x_search_path="\
1193 ${x_library}/X11/%L/%T/%N%C%S:\
1194 ${x_library}/X11/%l/%T/%N%C%S:\
1195 ${x_library}/X11/%T/%N%C%S:\
1196 ${x_library}/X11/%L/%T/%N%S:\
1197 ${x_library}/X11/%l/%T/%N%S:\
1198 ${x_library}/X11/%T/%N%S"
1199     if test x"${x_default_search_path}" = x; then
1200       x_default_search_path=${x_search_path}
1201     else
1202       x_default_search_path="${x_search_path}:${x_default_search_path}"
1203     fi
1204   done
1205 fi
1206 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1207   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1208 fi
1209
1210 if test x"${x_includes}" = x; then
1211   bitmapdir=/usr/include/X11/bitmaps
1212 else
1213   # accumulate include directories that have X11 bitmap subdirectories
1214   bmd_acc="dummyval"
1215   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1216     if test -d "${bmd}/X11/bitmaps"; then
1217       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1218     fi
1219     if test -d "${bmd}/bitmaps"; then
1220       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1221     fi
1222   done
1223   if test ${bmd_acc} != "dummyval"; then
1224     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1225   fi
1226 fi
1227
1228 HAVE_NS=no
1229 NS_IMPL_COCOA=no
1230 NS_IMPL_GNUSTEP=no
1231 tmp_CPPFLAGS="$CPPFLAGS"
1232 tmp_CFLAGS="$CFLAGS"
1233 CPPFLAGS="$CPPFLAGS -x objective-c"
1234 CFLAGS="$CFLAGS -x objective-c"
1235 if test "${with_ns}" != no; then
1236   if test "${opsys}" = darwin; then
1237      NS_IMPL_COCOA=yes
1238      ns_appdir=`pwd`/nextstep/Emacs.app
1239      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1240      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1241      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1242   elif test -f $GNUSTEP_CONFIG_FILE; then
1243      NS_IMPL_GNUSTEP=yes
1244      ns_appdir=`pwd`/nextstep/Emacs.app
1245      ns_appbindir=`pwd`/nextstep/Emacs.app
1246      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1247      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1248      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1249      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1250      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1251      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1252      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1253      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1254      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1255      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1256   fi
1257   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1258                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1259   files are missing or cannot be compiled.])])
1260   NS_HAVE_NSINTEGER=yes
1261   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1262                                      [NSInteger i;])],
1263                     ns_have_nsinteger=yes,
1264                     ns_have_nsinteger=no)
1265   if test $ns_have_nsinteger = no; then
1266     NS_HAVE_NSINTEGER=no
1267   fi
1268 fi
1269 if test "${HAVE_NS}" = yes; then
1270   window_system=nextstep
1271   with_xft=no
1272   # set up packaging dirs
1273   exec_prefix=${ns_appbindir}
1274   libexecdir=${ns_appbindir}/libexec
1275   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1276      prefix=${ns_appresdir}
1277   fi
1278 fi
1279 CFLAGS="$tmp_CFLAGS"
1280 CPPFLAGS="$tmp_CPPFLAGS"
1281
1282 case "${window_system}" in
1283   x11 )
1284     HAVE_X_WINDOWS=yes
1285     HAVE_X11=yes
1286     case "${with_x_toolkit}" in
1287       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1288       motif ) USE_X_TOOLKIT=MOTIF ;;
1289       gtk ) with_gtk=yes
1290 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1291 dnl USE_X_TOOLKIT is set.
1292             USE_X_TOOLKIT=none ;;
1293       no ) USE_X_TOOLKIT=none ;;
1294 dnl If user did not say whether to use a toolkit, make this decision later:
1295 dnl use the toolkit if we have gtk, or X11R5 or newer.
1296       * ) USE_X_TOOLKIT=maybe ;;
1297     esac
1298   ;;
1299   nextstep | none )
1300     HAVE_X_WINDOWS=no
1301     HAVE_X11=no
1302     USE_X_TOOLKIT=none
1303   ;;
1304 esac
1305
1306 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1307    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1308    if test "$HAVE_XSERVER" = true ||
1309       test -n "$DISPLAY" ||
1310       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1311         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1312 were found.  You should install the relevant development files for X
1313 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1314 sure you have development files for image handling, i.e.
1315 tiff, gif, jpeg, png and xpm.
1316 If you are sure you want Emacs compiled without X window support, pass
1317   --without-x
1318 to configure.])
1319    fi
1320 fi
1321
1322 ### If we're using X11, we should use the X menu package.
1323 HAVE_MENUS=no
1324 case ${HAVE_X11} in
1325   yes ) HAVE_MENUS=yes ;;
1326 esac
1327
1328 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1329 # Assume not, until told otherwise.
1330 GNU_MALLOC=yes
1331 doug_lea_malloc=yes
1332 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1333 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1334 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1335                emacs_cv_var___after_morecore_hook,
1336 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1337   emacs_cv_var___after_morecore_hook=yes,
1338   emacs_cv_var___after_morecore_hook=no)])
1339 if test $emacs_cv_var___after_morecore_hook = no; then
1340   doug_lea_malloc=no
1341 fi
1342 if test "${system_malloc}" = "yes"; then
1343   GNU_MALLOC=no
1344   GNU_MALLOC_reason="
1345     (The GNU allocators don't work with this system configuration.)"
1346 fi
1347 if test "$doug_lea_malloc" = "yes" ; then
1348   if test "$GNU_MALLOC" = yes ; then
1349     GNU_MALLOC_reason="
1350       (Using Doug Lea's new malloc from the GNU C Library.)"
1351   fi
1352   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1353             [Define to 1 if you are using the GNU C Library.])
1354 fi
1355
1356 if test x"${REL_ALLOC}" = x; then
1357   REL_ALLOC=${GNU_MALLOC}
1358 fi
1359
1360 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1361 dnl the system configuration file (s/*.h) to turn the use of mmap
1362 dnl in the relocating allocator on.
1363
1364 AC_FUNC_MMAP
1365 if test $use_mmap_for_buffers = yes; then
1366   REL_ALLOC=no
1367 fi
1368
1369 LIBS="$libsrc_libs $LIBS"
1370
1371 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1372 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1373 AC_CHECK_LIB(dnet, dnet_ntoa)
1374 dnl This causes -lresolv to get used in subsequent tests,
1375 dnl which causes failures on some systems such as HPUX 9.
1376 dnl AC_CHECK_LIB(resolv, gethostbyname)
1377
1378 dnl FIXME replace main with a function we actually want from this library.
1379 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1380
1381 AC_CHECK_LIB(pthreads, cma_open)
1382
1383 dnl Check for need for bigtoc support on IBM AIX
1384
1385 case ${host_os} in
1386 aix*)
1387   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1388     case $GCC in
1389     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1390     *) gdb_cv_bigtoc=-bbigtoc ;;
1391     esac
1392
1393     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1394     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1395   ])
1396   ;;
1397 esac
1398
1399 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1400 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1401 # REAL_CPPFLAGS later on.
1402
1403 REAL_CPPFLAGS="$CPPFLAGS"
1404
1405 if test "${HAVE_X11}" = "yes"; then
1406   DEFS="$C_SWITCH_X_SITE $DEFS"
1407   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1408   LIBS="$LIBX $LIBS"
1409   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1410   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1411
1412   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1413   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1414   # but it's more convenient here to set LD_RUN_PATH
1415   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1416   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1417     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1418     export LD_RUN_PATH
1419   fi
1420
1421   if test "${opsys}" = "gnu-linux"; then
1422     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1423     AC_TRY_LINK([],
1424      [XOpenDisplay ("foo");],
1425      [xlinux_first_failure=no],
1426      [xlinux_first_failure=yes])
1427     if test "${xlinux_first_failure}" = "yes"; then
1428       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1429       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1430       OLD_CPPFLAGS="$CPPFLAGS"
1431       OLD_LIBS="$LIBS"
1432       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1433       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1434       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1435       LIBS="$LIBS -b i486-linuxaout"
1436       AC_TRY_LINK([],
1437        [XOpenDisplay ("foo");],
1438        [xlinux_second_failure=no],
1439        [xlinux_second_failure=yes])
1440       if test "${xlinux_second_failure}" = "yes"; then
1441         # If we get the same failure with -b, there is no use adding -b.
1442         # So take it out.  This plays safe.
1443         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1444         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1445         CPPFLAGS="$OLD_CPPFLAGS"
1446         LIBS="$OLD_LIBS"
1447         AC_MSG_RESULT(no)
1448       else
1449         AC_MSG_RESULT(yes)
1450       fi
1451     else
1452       AC_MSG_RESULT(no)
1453     fi
1454   fi
1455
1456   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1457   # header files included from there.
1458   AC_MSG_CHECKING(for Xkb)
1459   AC_TRY_LINK([#include <X11/Xlib.h>
1460 #include <X11/XKBlib.h>],
1461         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1462         emacs_xkb=yes, emacs_xkb=no)
1463   AC_MSG_RESULT($emacs_xkb)
1464   if test $emacs_xkb = yes; then
1465     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1466   fi
1467
1468   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1469 XScreenNumberOfScreen XSetWMProtocols)
1470 fi
1471
1472 if test "${window_system}" = "x11"; then
1473   AC_MSG_CHECKING(X11 version 6)
1474   AC_CACHE_VAL(emacs_cv_x11_version_6,
1475   [AC_TRY_LINK([#include <X11/Xlib.h>],
1476 [#if XlibSpecificationRelease < 6
1477 fail;
1478 #endif
1479 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1480   if test $emacs_cv_x11_version_6 = yes; then
1481     AC_MSG_RESULT(6 or newer)
1482     AC_DEFINE(HAVE_X11R6, 1,
1483               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1484   else
1485     AC_MSG_RESULT(before 6)
1486   fi
1487 fi
1488
1489
1490 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1491 HAVE_RSVG=no
1492 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1493   if test "${with_rsvg}" != "no"; then
1494     RSVG_REQUIRED=2.11.0
1495     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1496
1497     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1498     AC_SUBST(RSVG_CFLAGS)
1499     AC_SUBST(RSVG_LIBS)
1500
1501     if test ".${RSVG_CFLAGS}" != "."; then
1502       HAVE_RSVG=yes
1503       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1504       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1505       LIBS="$RSVG_LIBS $LIBS"
1506     fi
1507   fi
1508 fi
1509
1510
1511 HAVE_GTK=no
1512 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1513   GLIB_REQUIRED=2.6
1514   GTK_REQUIRED=2.6
1515   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1516
1517   dnl Checks for libraries.
1518   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1519   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1520      AC_MSG_ERROR($GTK_PKG_ERRORS)
1521   fi
1522 fi
1523
1524
1525 if test x"$pkg_check_gtk" = xyes; then
1526
1527   AC_SUBST(GTK_CFLAGS)
1528   AC_SUBST(GTK_LIBS)
1529   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1530   CFLAGS="$CFLAGS $GTK_CFLAGS"
1531   LIBS="$GTK_LIBS $LIBS"
1532   dnl Try to compile a simple GTK program.
1533   GTK_COMPILES=no
1534   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1535   if test "${GTK_COMPILES}" != "yes"; then
1536     if test "$USE_X_TOOLKIT" != "maybe"; then
1537       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1538     fi
1539   else
1540     HAVE_GTK=yes
1541     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1542     USE_X_TOOLKIT=none
1543     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1544       :
1545     else
1546       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1547        closing open displays.  This is no problem if you just use
1548        one display, but if you use more than one and close one of them
1549        Emacs may crash.]])
1550       sleep 3
1551     fi
1552   fi
1553
1554 fi
1555
1556
1557 if test "${HAVE_GTK}" = "yes"; then
1558
1559   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1560   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1561   if test "$with_toolkit_scroll_bars" != no; then
1562     with_toolkit_scroll_bars=yes
1563   fi
1564
1565   dnl  Check if we can use multiple displays with this GTK version.
1566   dnl  If gdk_display_open exists, assume all others are there also.
1567   HAVE_GTK_MULTIDISPLAY=no
1568   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1569   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1570     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1571               [Define to 1 if GTK can handle more than one display.])
1572   fi
1573
1574   dnl  Check if we have the old file selection dialog declared and
1575   dnl  in the link library.  In 2.x it may be in the library,
1576   dnl  but not declared if deprecated featured has been selected out.
1577   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1578   HAVE_GTK_FILE_SELECTION=no
1579   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1580                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1581 #include <gtk/gtk.h>])
1582   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1583     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1584                    HAVE_GTK_FILE_SELECTION=no)
1585   fi
1586
1587   dnl  Check if we have the new file chooser dialog
1588   HAVE_GTK_FILE_CHOOSER=no
1589   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1590                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1591 #include <gtk/gtk.h>])
1592   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1593     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1594                    HAVE_GTK_FILE_CHOOSER=no)
1595   fi
1596
1597   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1598      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1599     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1600               [Define to 1 if GTK has both file selection and chooser dialog.])
1601   fi
1602
1603   dnl Check if pthreads are available.  Emacs only needs this when using
1604   dnl gtk_file_chooser under Gnome.
1605   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1606     HAVE_GTK_AND_PTHREAD=no
1607     AC_CHECK_HEADERS(pthread.h)
1608     if test "$ac_cv_header_pthread_h"; then
1609       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1610     fi
1611     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1612       case "${canonical}" in
1613         *-hpux*) ;;
1614         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1615       esac
1616       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1617                [Define to 1 if you have GTK and pthread (-lpthread).])
1618     fi
1619   fi
1620 fi
1621
1622 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1623 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1624 dnl also not configured.
1625 HAVE_DBUS=no
1626 if test "${with_dbus}" = "yes"; then
1627    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1628    if test "$HAVE_DBUS" = yes; then
1629       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1630    fi
1631 fi
1632
1633 dnl Do not put whitespace before the #include statements below.
1634 dnl Older compilers (eg sunos4 cc) choke on it.
1635 HAVE_XAW3D=no
1636 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1637   if test "$with_xaw3d" != no; then
1638     AC_MSG_CHECKING(for xaw3d)
1639     AC_CACHE_VAL(emacs_cv_xaw3d,
1640     [AC_TRY_LINK([
1641 #include <X11/Intrinsic.h>
1642 #include <X11/Xaw3d/Simple.h>],
1643       [],
1644       emacs_cv_xaw3d=yes,
1645       emacs_cv_xaw3d=no)])
1646   else
1647     emacs_cv_xaw3d=no
1648   fi
1649   if test $emacs_cv_xaw3d = yes; then
1650     AC_MSG_RESULT([yes; using Lucid toolkit])
1651     USE_X_TOOLKIT=LUCID
1652     HAVE_XAW3D=yes
1653     AC_DEFINE(HAVE_XAW3D, 1,
1654               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1655   else
1656     AC_MSG_RESULT(no)
1657     AC_MSG_CHECKING(for libXaw)
1658     AC_CACHE_VAL(emacs_cv_xaw,
1659     [AC_TRY_LINK([
1660 #include <X11/Intrinsic.h>
1661 #include <X11/Xaw/Simple.h>],
1662       [],
1663       emacs_cv_xaw=yes,
1664       emacs_cv_xaw=no)])
1665     if test $emacs_cv_xaw = yes; then
1666       AC_MSG_RESULT([yes; using Lucid toolkit])
1667       USE_X_TOOLKIT=LUCID
1668     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1669       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1670     else
1671       AC_MSG_RESULT([no; do not use toolkit by default])
1672       USE_X_TOOLKIT=none
1673     fi
1674   fi
1675 fi
1676
1677 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1678
1679 if test "${USE_X_TOOLKIT}" != "none"; then
1680   AC_MSG_CHECKING(X11 toolkit version)
1681   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1682   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1683 [#if XtSpecificationRelease < 6
1684 fail;
1685 #endif
1686 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1687   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1688   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1689     AC_MSG_RESULT(6 or newer)
1690     AC_DEFINE(HAVE_X11XTR6, 1,
1691               [Define to 1 if you have the X11R6 or newer version of Xt.])
1692   else
1693     AC_MSG_RESULT(before 6)
1694   fi
1695
1696 dnl If using toolkit, check whether libXmu.a exists.
1697 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1698   OLDLIBS="$LIBS"
1699   if test x$HAVE_X11XTR6 = xyes; then
1700     LIBS="-lXt -lSM -lICE $LIBS"
1701   else
1702     LIBS="-lXt $LIBS"
1703   fi
1704   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1705   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1706 fi
1707
1708 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1709 if test "${HAVE_X11}" = "yes"; then
1710   if test "${USE_X_TOOLKIT}" != "none"; then
1711     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1712   fi
1713 fi
1714
1715 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1716   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1717   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1718     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1719 int x = 5;
1720 #else
1721 Motif version prior to 2.1.
1722 #endif],
1723     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1724   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1725   if test $emacs_cv_motif_version_2_1 = yes; then
1726     HAVE_LIBXP=no
1727     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1728               [Define to 1 if you have Motif 2.1 or newer.])
1729     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1730     if test ${HAVE_LIBXP} = yes; then
1731       AC_DEFINE(HAVE_LIBXP, 1,
1732                 [Define to 1 if you have the Xp library (-lXp).])
1733     fi
1734   else
1735     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1736     # We put this in CFLAGS temporarily to precede other -I options
1737     # that might be in CFLAGS temporarily.
1738     # We put this in CPPFLAGS where it precedes the other -I options.
1739     OLD_CPPFLAGS=$CPPFLAGS
1740     OLD_CFLAGS=$CFLAGS
1741     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1742     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1743     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1744       [int x = 5;],
1745       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1746     if test $emacs_cv_lesstif = yes; then
1747       # Make sure this -I option remains in CPPFLAGS after it is set
1748       # back to REAL_CPPFLAGS.
1749       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1750       # have those other -I options anyway.  Ultimately, having this
1751       # directory ultimately in CPPFLAGS will be enough.
1752       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1753       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1754     else
1755       CFLAGS=$OLD_CFLAGS
1756       CPPFLAGS=$OLD_CPPFLAGS
1757     fi
1758   fi
1759 fi
1760
1761 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1762 dnl using Motif or Xaw3d is available, and unless
1763 dnl --with-toolkit-scroll-bars=no was specified.
1764
1765 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1766             [Define to 1 if we should use toolkit scroll bars.])dnl
1767 USE_TOOLKIT_SCROLL_BARS=no
1768 if test "${with_toolkit_scroll_bars}" != "no"; then
1769   if test "${USE_X_TOOLKIT}" != "none"; then
1770     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1771       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1772       HAVE_XAW3D=no
1773       USE_TOOLKIT_SCROLL_BARS=yes
1774     elif test "${HAVE_XAW3D}" = "yes"; then
1775       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1776       USE_TOOLKIT_SCROLL_BARS=yes
1777     fi
1778   elif test "${HAVE_GTK}" = "yes"; then
1779     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1780     USE_TOOLKIT_SCROLL_BARS=yes
1781   elif test "${HAVE_NS}" = "yes"; then
1782     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1783     USE_TOOLKIT_SCROLL_BARS=yes
1784   fi
1785 fi
1786
1787 dnl See if XIM is available.
1788 AC_TRY_COMPILE([
1789           #include <X11/Xlib.h>
1790           #include <X11/Xresource.h>],
1791          [XIMProc  callback;],
1792          [HAVE_XIM=yes
1793          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1794          HAVE_XIM=no)
1795
1796 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1797
1798 if test "${with_xim}" != "no"; then
1799   AC_DEFINE(USE_XIM, 1,
1800             [Define to 1 if we should use XIM, if it is available.])
1801 fi
1802
1803
1804 if test "${HAVE_XIM}" != "no"; then
1805   late_CFLAGS=$CFLAGS
1806   if test "$GCC" = yes; then
1807     CFLAGS="$CFLAGS --pedantic-errors"
1808   fi
1809   AC_TRY_COMPILE([
1810 #include <X11/Xlib.h>
1811 #include <X11/Xresource.h>],
1812 [Display *display;
1813 XrmDatabase db;
1814 char *res_name;
1815 char *res_class;
1816 XIMProc  callback;
1817 XPointer *client_data;
1818 #ifndef __GNUC__
1819 /* If we're not using GCC, it's probably not XFree86, and this is
1820    probably right, but we can't use something like --pedantic-errors.  */
1821 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1822                                            char*, XIMProc, XPointer*);
1823 #endif
1824 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1825    client_data);],
1826     [emacs_cv_arg6_star=yes])
1827   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1828          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1829 either XPointer or XPointer*.])dnl
1830   if test "$emacs_cv_arg6_star" = yes; then
1831     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1832   else
1833     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1834   fi
1835   CFLAGS=$late_CFLAGS
1836 fi
1837
1838 ### Start of font-backend (under any platform) section.
1839 # (nothing here yet -- this is a placeholder)
1840 ### End of font-backend (under any platform) section.
1841
1842 ### Start of font-backend (under X11) section.
1843 if test "${HAVE_X11}" = "yes"; then
1844    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
1845
1846    ## Use -lXft if available, unless `--with-xft=no'.
1847    HAVE_XFT=maybe
1848     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
1849       with_xft="no";
1850     fi
1851     if test "x${with_xft}" != "xno"; then
1852
1853       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1854       if test "$HAVE_XFT" != no; then
1855         OLD_CPPFLAGS="$CPPFLAGS"
1856         OLD_CFLAGS="$CFLAGS"
1857         OLD_LIBS="$LIBS"
1858         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1859         CFLAGS="$CFLAGS $XFT_CFLAGS"
1860         LIBS="$XFT_LIBS $LIBS"
1861         AC_CHECK_HEADER(X11/Xft/Xft.h,
1862           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1863
1864         if test "${HAVE_XFT}" = "yes"; then
1865           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1866             AC_SUBST(XFT_LIBS)
1867           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1868         else
1869           CPPFLAGS="$OLD_CPPFLAGS"
1870           CFLAGS="$OLD_CFLAGS"
1871           LIBS="$OLD_LIBS"
1872         fi                        # "${HAVE_XFT}" = "yes"
1873       fi                          # "$HAVE_XFT" != no
1874     fi                            # "x${with_xft}" != "xno"
1875
1876     dnl For the "Does Emacs use" message at the end.
1877     if test "$HAVE_XFT" != "yes"; then
1878        HAVE_XFT=no
1879     fi
1880
1881
1882     HAVE_FREETYPE=no
1883     ### Use -lfreetype if available, unless `--with-freetype=no'.
1884     if test "${HAVE_XFT}" = "yes"; then
1885       dnl As we use Xft, we anyway use freetype.
1886       dnl In this case, there's no need of additional CFLAGS and LIBS.
1887       HAVE_FREETYPE=yes
1888       FONTCONFIG_CFLAGS=
1889       FONTCONFIG_LIBS=
1890     fi
1891
1892     HAVE_LIBOTF=no
1893     if test "${HAVE_FREETYPE}" = "yes"; then
1894       AC_DEFINE(HAVE_FREETYPE, 1,
1895                 [Define to 1 if using the freetype and fontconfig libraries.])
1896       if test "${with_libotf}" != "no"; then
1897         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
1898                           HAVE_LIBOTF=no)
1899         if test "$HAVE_LIBOTF" = "yes"; then
1900           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
1901           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
1902                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
1903                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
1904           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
1905             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
1906                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
1907           fi
1908         fi
1909       fi
1910     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
1911     dnl Does the new font backend require it, or can it work without it?
1912     fi
1913
1914     HAVE_M17N_FLT=no
1915     if test "${HAVE_LIBOTF}" = yes; then
1916       if test "${with_m17n_flt}" != "no"; then
1917         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
1918         if test "$HAVE_M17N_FLT" = "yes"; then
1919           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
1920         fi
1921       fi
1922     fi
1923 else
1924     HAVE_XFT=no
1925     HAVE_FREETYPE=no
1926     HAVE_LIBOTF=no
1927     HAVE_M17N_FLT=no
1928 fi
1929 ### End of font-backend (under X11) section.
1930
1931 AC_SUBST(FREETYPE_CFLAGS)
1932 AC_SUBST(FREETYPE_LIBS)
1933 AC_SUBST(FONTCONFIG_CFLAGS)
1934 AC_SUBST(FONTCONFIG_LIBS)
1935 AC_SUBST(LIBOTF_CFLAGS)
1936 AC_SUBST(LIBOTF_LIBS)
1937 AC_SUBST(M17N_FLT_CFLAGS)
1938 AC_SUBST(M17N_FLT_LIBS)
1939
1940 ### Use -lXpm if available, unless `--with-xpm=no'.
1941 HAVE_XPM=no
1942 if test "${HAVE_X11}" = "yes"; then
1943   if test "${with_xpm}" != "no"; then
1944     AC_CHECK_HEADER(X11/xpm.h,
1945       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
1946     if test "${HAVE_XPM}" = "yes"; then
1947       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
1948       AC_EGREP_CPP(no_return_alloc_pixels,
1949       [#include "X11/xpm.h"
1950 #ifndef XpmReturnAllocPixels
1951 no_return_alloc_pixels
1952 #endif
1953       ], HAVE_XPM=no, HAVE_XPM=yes)
1954
1955       if test "${HAVE_XPM}" = "yes"; then
1956         AC_MSG_RESULT(yes)
1957       else
1958         AC_MSG_RESULT(no)
1959       fi
1960     fi
1961   fi
1962
1963   if test "${HAVE_XPM}" = "yes"; then
1964     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
1965   fi
1966 fi
1967
1968 ### Use -ljpeg if available, unless `--with-jpeg=no'.
1969 HAVE_JPEG=no
1970 if test "${HAVE_X11}" = "yes"; then
1971   if test "${with_jpeg}" != "no"; then
1972     dnl Checking for jpeglib.h can lose because of a redefinition of
1973     dnl  HAVE_STDLIB_H.
1974     AC_CHECK_HEADER(jerror.h,
1975       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
1976   fi
1977
1978   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
1979   if test "${HAVE_JPEG}" = "yes"; then
1980     AC_DEFINE(HAVE_JPEG)
1981     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
1982         [#include <jpeglib.h>
1983          version=JPEG_LIB_VERSION
1984 ],
1985         [AC_DEFINE(HAVE_JPEG)],
1986         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
1987         HAVE_JPEG=no])
1988   fi
1989 fi
1990
1991 ### Use -lpng if available, unless `--with-png=no'.
1992 HAVE_PNG=no
1993 if test "${HAVE_X11}" = "yes"; then
1994   if test "${with_png}" != "no"; then
1995     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
1996     # in /usr/include/libpng.
1997     AC_CHECK_HEADERS(png.h libpng/png.h)
1998     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
1999       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2000     fi
2001   fi
2002
2003   if test "${HAVE_PNG}" = "yes"; then
2004     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2005   fi
2006 fi
2007
2008 ### Use -ltiff if available, unless `--with-tiff=no'.
2009 HAVE_TIFF=no
2010 if test "${HAVE_X11}" = "yes"; then
2011   if test "${with_tiff}" != "no"; then
2012     AC_CHECK_HEADER(tiffio.h,
2013       [tifflibs="-lz -lm"
2014       # At least one tiff package requires the jpeg library.
2015       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2016       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2017   fi
2018
2019   if test "${HAVE_TIFF}" = "yes"; then
2020     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2021   fi
2022 fi
2023
2024 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2025 HAVE_GIF=no
2026 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2027   AC_CHECK_HEADER(gif_lib.h,
2028 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2029 # Earlier versions can crash Emacs.
2030     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2031
2032   if test "$HAVE_GIF" = yes; then
2033       ac_gif_lib_name="-lgif"
2034   fi
2035
2036 # If gif_lib.h but no libgif, try libungif.
2037   if test x"$try_libungif" = xyes; then
2038     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2039
2040     if test "$HAVE_GIF" = yes; then
2041       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2042       ac_gif_lib_name="-lungif"
2043     fi
2044   fi
2045
2046   if test "${HAVE_GIF}" = "yes"; then
2047     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2048   fi
2049 fi
2050
2051 dnl Check for required libraries.
2052 if test "${HAVE_X11}" = "yes"; then
2053   MISSING=""
2054   WITH_NO=""
2055   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2056     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2057   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2058     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2059   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2060     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2061   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2062     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2063   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2064     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2065
2066   if test "X${MISSING}" != X; then
2067     AC_MSG_ERROR([The following required libraries were not found:
2068     $MISSING
2069 Maybe some development libraries/packages are missing?
2070 If you don't want to link with them give
2071     $WITH_NO
2072 as options to configure])
2073   fi
2074 fi
2075
2076 ### Use -lgpm if available, unless `--with-gpm=no'.
2077 HAVE_GPM=no
2078 if test "${with_gpm}" != "no"; then
2079   AC_CHECK_HEADER(gpm.h,
2080     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2081 fi
2082
2083 if test "${HAVE_GPM}" = "yes"; then
2084   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2085 fi
2086
2087 dnl Check for malloc/malloc.h on darwin
2088 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2089
2090 ### Use NeXTstep API to implement GUI.
2091 if test "${HAVE_NS}" = "yes"; then
2092   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2093   if test "${NS_IMPL_COCOA}" = "yes"; then
2094     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2095     GNU_OBJC_CFLAGS=
2096     LIB_SRC_EXTRA_INSTALLABLES=mac-fix-env
2097   fi
2098   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2099     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2100     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2101   fi
2102   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2103     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2104   fi
2105   # We also have mouse menus.
2106   HAVE_MENUS=yes
2107 fi
2108
2109
2110 ### Use session management (-lSM -lICE) if available
2111 HAVE_X_SM=no
2112 if test "${HAVE_X11}" = "yes"; then
2113   AC_CHECK_HEADER(X11/SM/SMlib.h,
2114     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2115
2116   if test "${HAVE_X_SM}" = "yes"; then
2117     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2118     case "$LIBS" in
2119       *-lSM*) ;;
2120       *)      LIBS="-lSM -lICE $LIBS" ;;
2121     esac
2122   fi
2123 fi
2124
2125 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2126 AC_CACHE_CHECK(whether netdb declares h_errno,
2127                emacs_cv_netdb_declares_h_errno,
2128 [AC_TRY_LINK([#include <netdb.h>],
2129   [return h_errno;],
2130   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2131 if test $emacs_cv_netdb_declares_h_errno = yes; then
2132   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2133 fi
2134
2135 AC_FUNC_ALLOCA
2136
2137 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2138 dnl FIXME is there an autoconf test that does the right thing, without
2139 dnl needing to call A_M_E afterwards?
2140 if test x"$ac_cv_func_alloca_works" != xyes; then
2141    AC_MSG_ERROR( [a system implementation of alloca is required] )
2142 fi
2143
2144 # fmod, logb, and frexp are found in -lm on most systems.
2145 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2146 AC_CHECK_LIB(m, sqrt)
2147
2148 # Check for mail-locking functions in a "mail" library.  Probably this should
2149 # have the same check as for liblockfile below.
2150 AC_CHECK_LIB(mail, maillock)
2151 dnl Debian, at least:
2152 AC_CHECK_LIB(lockfile, maillock)
2153 # If we have the shared liblockfile, assume we must use it for mail
2154 # locking (e.g. Debian).  If we couldn't link against liblockfile
2155 # (no liblockfile.a installed), ensure that we don't need to.
2156 if test "$ac_cv_lib_lockfile_maillock" = no; then
2157   dnl This works for files generally, not just executables.
2158   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2159   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2160                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2161   if test $ac_cv_prog_liblockfile = yes; then
2162     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2163 This probably means that movemail could lose mail.
2164 There may be a `development' package to install containing liblockfile.])
2165   else :
2166   fi
2167 fi
2168 AC_CHECK_FUNCS(touchlock)
2169 AC_CHECK_HEADERS(maillock.h)
2170
2171 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2172 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2173 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2174 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2175 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2176 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2177 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2178 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2179 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2180 cfmakeraw cfsetspeed)
2181
2182 AC_CHECK_HEADERS(sys/un.h)
2183
2184 AC_FUNC_MKTIME
2185 if test "$ac_cv_func_working_mktime" = no; then
2186   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2187 fi
2188
2189 AC_FUNC_GETLOADAVG
2190
2191 AC_FUNC_FSEEKO
2192
2193 # Configure getopt.
2194 m4_include([m4/getopt.m4])
2195 gl_GETOPT_IFELSE([
2196   gl_GETOPT_SUBSTITUTE_HEADER
2197   gl_PREREQ_GETOPT
2198   GETOPTOBJS='getopt.o getopt1.o'
2199 ])
2200 AC_SUBST(GETOPTOBJS)
2201
2202 AC_FUNC_GETPGRP
2203
2204 AC_FUNC_STRFTIME
2205
2206 # UNIX98 PTYs.
2207 AC_CHECK_FUNCS(grantpt)
2208
2209 # PTY-related GNU extensions.
2210 AC_CHECK_FUNCS(getpt)
2211
2212 # Check this now, so that we will NOT find the above functions in ncurses.
2213 # That is because we have not set up to link ncurses in lib-src.
2214 # It's better to believe a function is not available
2215 # than to expect to find it in ncurses.
2216 AC_CHECK_LIB(ncurses, tparm)
2217
2218 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2219
2220 resolv=no
2221 AC_TRY_LINK([#include <netinet/in.h>
2222 #include <arpa/nameser.h>
2223 #include <resolv.h>],
2224     [return res_init();],
2225     have_res_init=yes, have_res_init=no)
2226 if test "$have_res_init" = no; then
2227   OLIBS="$LIBS"
2228   LIBS="$LIBS -lresolv"
2229   AC_MSG_CHECKING(for res_init with -lresolv)
2230   AC_TRY_LINK([#include <netinet/in.h>
2231 #include <arpa/nameser.h>
2232 #include <resolv.h>],
2233     [return res_init();],
2234     have_res_init=yes, have_res_init=no)
2235   AC_MSG_RESULT($have_res_init)
2236   if test "$have_res_init" = yes ; then
2237     resolv=yes
2238   fi
2239   LIBS="$OLIBS"
2240 fi
2241
2242 if test "$have_res_init" = yes; then
2243   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2244 fi
2245
2246 # Do we need the Hesiod library to provide the support routines?
2247 if test "$with_hesiod" != no ; then
2248   # Don't set $LIBS here -- see comments above.
2249   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2250      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2251                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2252   if test "$resolv" = yes ; then
2253     RESOLVLIB=-lresolv
2254   else
2255     RESOLVLIB=
2256   fi
2257   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2258         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2259                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2260         :, $RESOLVLIB)])
2261 fi
2262
2263 # Do we need libresolv (due to res_init or Hesiod)?
2264 if test "$resolv" = yes ; then
2265   AC_DEFINE(HAVE_LIBRESOLV, 1,
2266             [Define to 1 if you have the resolv library (-lresolv).])
2267 fi
2268
2269 # These tell us which Kerberos-related libraries to use.
2270 if test "${with_kerberos}" != no; then
2271   AC_CHECK_LIB(com_err, com_err)
2272   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2273   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2274   AC_CHECK_LIB(krb5, krb5_init_context)
2275   if test "${with_kerberos5}" = no; then
2276     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2277                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2278     AC_CHECK_LIB(krb4, krb_get_cred,,
2279                  [AC_CHECK_LIB(krb, krb_get_cred)])
2280   fi
2281
2282   if test "${with_kerberos5}" != no; then
2283     AC_CHECK_HEADERS(krb5.h,
2284       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2285                         [#include <krb5.h>])])
2286   else
2287     AC_CHECK_HEADERS(des.h,,
2288                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2289                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2290     AC_CHECK_HEADERS(krb.h,,
2291                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2292                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2293   fi
2294   AC_CHECK_HEADERS(com_err.h)
2295 fi
2296
2297 # Solaris requires -lintl if you want strerror (which calls dgettext)
2298 # to return localized messages.
2299 AC_CHECK_LIB(intl, dgettext)
2300
2301 AC_MSG_CHECKING(whether localtime caches TZ)
2302 AC_CACHE_VAL(emacs_cv_localtime_cache,
2303 [if test x$ac_cv_func_tzset = xyes; then
2304 AC_TRY_RUN([#include <time.h>
2305 extern char **environ;
2306 unset_TZ ()
2307 {
2308   char **from, **to;
2309   for (to = from = environ; (*to = *from); from++)
2310     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2311       to++;
2312 }
2313 char TZ_GMT0[] = "TZ=GMT0";
2314 char TZ_PST8[] = "TZ=PST8";
2315 main()
2316 {
2317   time_t now = time ((time_t *) 0);
2318   int hour_GMT0, hour_unset;
2319   if (putenv (TZ_GMT0) != 0)
2320     exit (1);
2321   hour_GMT0 = localtime (&now)->tm_hour;
2322   unset_TZ ();
2323   hour_unset = localtime (&now)->tm_hour;
2324   if (putenv (TZ_PST8) != 0)
2325     exit (1);
2326   if (localtime (&now)->tm_hour == hour_GMT0)
2327     exit (1);
2328   unset_TZ ();
2329   if (localtime (&now)->tm_hour != hour_unset)
2330     exit (1);
2331   exit (0);
2332 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2333 [# If we have tzset, assume the worst when cross-compiling.
2334 emacs_cv_localtime_cache=yes])
2335 else
2336         # If we lack tzset, report that localtime does not cache TZ,
2337         # since we can't invalidate the cache if we don't have tzset.
2338         emacs_cv_localtime_cache=no
2339 fi])dnl
2340 AC_MSG_RESULT($emacs_cv_localtime_cache)
2341 if test $emacs_cv_localtime_cache = yes; then
2342   AC_DEFINE(LOCALTIME_CACHE, 1,
2343             [Define to 1 if localtime caches TZ.])
2344 fi
2345
2346 if test "x$HAVE_TIMEVAL" = xyes; then
2347   AC_CHECK_FUNCS(gettimeofday)
2348   if test $ac_cv_func_gettimeofday = yes; then
2349     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2350                    emacs_cv_gettimeofday_two_arguments,
2351     [AC_TRY_COMPILE([
2352 #ifdef TIME_WITH_SYS_TIME
2353 #include <sys/time.h>
2354 #include <time.h>
2355 #else
2356 #ifdef HAVE_SYS_TIME_H
2357 #include <sys/time.h>
2358 #else
2359 #include <time.h>
2360 #endif
2361 #endif],
2362       [struct timeval time;
2363        gettimeofday (&time, 0);],
2364       emacs_cv_gettimeofday_two_arguments=yes,
2365       emacs_cv_gettimeofday_two_arguments=no)])
2366     if test $emacs_cv_gettimeofday_two_arguments = no; then
2367       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2368                 [Define to 1 if gettimeofday accepts only one argument.])
2369     fi
2370   fi
2371 fi
2372
2373 ok_so_far=yes
2374 AC_CHECK_FUNC(socket, , ok_so_far=no)
2375 if test $ok_so_far = yes; then
2376   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2377 fi
2378 if test $ok_so_far = yes; then
2379   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2380 fi
2381 if test $ok_so_far = yes; then
2382 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2383   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2384             [Define to 1 if you have inet sockets.])
2385 fi
2386
2387 AC_CHECK_HEADERS(sys/ioctl.h)
2388
2389 if test -f /usr/lpp/X11/bin/smt.exp; then
2390   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2391             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2392 fi
2393
2394 AC_MSG_CHECKING(whether system supports dynamic ptys)
2395 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2396   AC_MSG_RESULT(yes)
2397   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2398 else
2399   AC_MSG_RESULT(no)
2400 fi
2401
2402 AC_FUNC_FORK
2403
2404 dnl Adapted from Haible's version.
2405 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2406   [AC_TRY_LINK([#include <langinfo.h>],
2407     [char* cs = nl_langinfo(CODESET);],
2408     emacs_cv_langinfo_codeset=yes,
2409     emacs_cv_langinfo_codeset=no)
2410   ])
2411 if test $emacs_cv_langinfo_codeset = yes; then
2412   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2413     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2414 fi
2415
2416 AC_CHECK_TYPES(size_t)
2417
2418 AC_TYPE_MBSTATE_T
2419
2420 dnl Restrict could probably be used effectively other than in regex.c.
2421 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2422   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2423                   emacs_cv_c_restrict=yes,
2424                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2425                                   emacs_cv_c_restrict=__restrict,
2426                                   emacs_cv_c_restrict=no)])])
2427 case "$emacs_cv_c_restrict" in
2428   yes) emacs_restrict=restrict;;
2429   no) emacs_restrict="";;
2430   *) emacs_restrict="$emacs_cv_c_restrict";;
2431 esac
2432 if test "$emacs_restrict" != __restrict; then
2433   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2434     [Define to compiler's equivalent of C99 restrict keyword.
2435      Don't define if equivalent is `__restrict'.])
2436 fi
2437
2438 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2439   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2440                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2441 if test "$emacs_cv_c_restrict_arr" = yes; then
2442   AC_DEFINE(__restrict_arr, __restrict,
2443     [Define to compiler's equivalent of C99 restrict keyword in array
2444      declarations.  Define as empty for no equivalent.])
2445 fi
2446
2447 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2448 dnl how the tty code is related to POSIX and/or other versions of termios.
2449 dnl The following looks like a useful start.
2450 dnl
2451 dnl AC_SYS_POSIX_TERMIOS
2452 dnl if test $ac_cv_sys_posix_termios = yes; then
2453 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2454 dnl                                and macros for terminal control.])
2455 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2456 dnl fi
2457
2458 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2459
2460 # Set up the CFLAGS for real compilation, so we can substitute it.
2461 CFLAGS="$REAL_CFLAGS"
2462 CPPFLAGS="$REAL_CPPFLAGS"
2463
2464 #### Find out which version of Emacs this is.
2465 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2466          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2467 if test x"${version}" = x; then
2468   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2469 fi
2470
2471 ### Specify what sort of things we'll be editing into Makefile and config.h.
2472 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2473 AC_SUBST(version)
2474 AC_SUBST(configuration)
2475 AC_SUBST(canonical)
2476 AC_SUBST(srcdir)
2477 AC_SUBST(prefix)
2478 AC_SUBST(exec_prefix)
2479 AC_SUBST(bindir)
2480 AC_SUBST(datadir)
2481 AC_SUBST(sharedstatedir)
2482 AC_SUBST(libexecdir)
2483 AC_SUBST(mandir)
2484 AC_SUBST(infodir)
2485 AC_SUBST(lispdir)
2486 AC_SUBST(locallisppath)
2487 AC_SUBST(lisppath)
2488 AC_SUBST(x_default_search_path)
2489 AC_SUBST(etcdir)
2490 AC_SUBST(archlibdir)
2491 AC_SUBST(docdir)
2492 AC_SUBST(bitmapdir)
2493 AC_SUBST(gamedir)
2494 AC_SUBST(gameuser)
2495 AC_SUBST(c_switch_system)
2496 AC_SUBST(c_switch_machine)
2497 AC_SUBST(LD_SWITCH_X_SITE)
2498 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2499 AC_SUBST(C_SWITCH_X_SITE)
2500 AC_SUBST(CFLAGS)
2501 AC_SUBST(X_TOOLKIT_TYPE)
2502 AC_SUBST(machfile)
2503 AC_SUBST(opsysfile)
2504 AC_SUBST(GETLOADAVG_LIBS)
2505 AC_SUBST(ns_appdir)
2506 AC_SUBST(ns_appbindir)
2507 AC_SUBST(ns_appresdir)
2508 AC_SUBST(ns_appsrc)
2509 AC_SUBST(GNUSTEP_MAKEFILES)
2510 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2511 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2512 AC_SUBST(GNU_OBJC_CFLAGS)
2513 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2514
2515 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2516                    [Define to the canonical Emacs configuration name.])
2517 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2518                    [Define to the options passed to configure.])
2519 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2520                    [Define to the used machine dependent file.])
2521 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2522                    [Define to the used os dependent file.])
2523 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2524 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2525  may need to deal with X Windows.  For instance, if you've defined
2526  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2527  your loader can find on its own, you might want to add "-L/..." or
2528  something similar.])
2529 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2530                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2531                     in case it's needed (for Solaris, for example).])
2532 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2533 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2534  may need to deal with X Windows.  For instance, if you've defined
2535  HAVE_X_WINDOWS above and your X include files aren't in a place
2536  that your compiler can find on its own, you might want to add
2537  "-I/..." or something similar.])
2538 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2539                    [Define to the unexec source file name.])
2540
2541 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2542   AC_DEFINE(HAVE_X_WINDOWS, 1,
2543             [Define to 1 if you want to use the X window system.])
2544 fi
2545 if test "${USE_X_TOOLKIT}" != "none" ; then
2546   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2547   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2548     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2549   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2550     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2551   fi
2552 fi
2553 if test "${HAVE_X11}" = "yes" ; then
2554   AC_DEFINE(HAVE_X11, 1,
2555             [Define to 1 if you want to use version 11 of X windows.
2556              Otherwise, Emacs expects to use version 10.])
2557 fi
2558 if test "${HAVE_MENUS}" = "yes" ; then
2559   AC_DEFINE(HAVE_MENUS, 1,
2560             [Define to 1 if you have mouse menus.
2561              (This is automatic if you use X, but the option to specify it remains.)
2562              It is also defined with other window systems that support xmenu.c.])
2563 fi
2564 if test "${GNU_MALLOC}" = "yes" ; then
2565   AC_DEFINE(GNU_MALLOC, 1,
2566             [Define to 1 if you want to use the GNU memory allocator.])
2567 fi
2568 if test "${REL_ALLOC}" = "yes" ; then
2569   AC_DEFINE(REL_ALLOC, 1,
2570             [Define REL_ALLOC if you want to use the relocating allocator for
2571              buffer space.])
2572 fi
2573
2574
2575 AH_TOP([/* GNU Emacs site configuration template file.
2576    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2577      2006, 2007, 2008, 2009  Free Software Foundation, Inc.
2578
2579 This file is part of GNU Emacs.
2580
2581 GNU Emacs is free software: you can redistribute it and/or modify
2582 it under the terms of the GNU General Public License as published by
2583 the Free Software Foundation, either version 3 of the License, or
2584 (at your option) any later version.
2585
2586 GNU Emacs is distributed in the hope that it will be useful,
2587 but WITHOUT ANY WARRANTY; without even the implied warranty of
2588 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2589 GNU General Public License for more details.
2590
2591 You should have received a copy of the GNU General Public License
2592 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2593
2594
2595 /* No code in Emacs #includes config.h twice, but some bits of code
2596    intended to work with other packages as well (like gmalloc.c)
2597    think they can include it as many times as they like.  */
2598 #ifndef EMACS_CONFIG_H
2599 #define EMACS_CONFIG_H
2600 ])dnl
2601
2602 AH_BOTTOM([
2603 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2604 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2605 #define HAVE_WINDOW_SYSTEM
2606 #define HAVE_MOUSE
2607 #endif
2608
2609 /* Sadly for now, GNUstep dump does not work.  */
2610 #ifdef NS_IMPL_GNUSTEP
2611 #define CANNOT_DUMP
2612 #endif
2613
2614 /* Define AMPERSAND_FULL_NAME if you use the convention
2615    that & in the full name stands for the login id.  */
2616 /* Turned on June 1996 supposing nobody will mind it.  */
2617 #define AMPERSAND_FULL_NAME
2618
2619 /* Define HAVE_SOUND if we have sound support.  We know it works
2620    and compiles only on the specified platforms.   For others,
2621    it probably doesn't make sense to try.  */
2622
2623 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2624 #ifdef HAVE_MACHINE_SOUNDCARD_H
2625 #define HAVE_SOUND 1
2626 #endif
2627 #ifdef HAVE_SYS_SOUNDCARD_H
2628 #define HAVE_SOUND 1
2629 #endif
2630 #ifdef HAVE_SOUNDCARD_H
2631 #define HAVE_SOUND 1
2632 #endif
2633 #ifdef HAVE_ALSA
2634 #define HAVE_SOUND 1
2635 #endif
2636 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2637
2638 /* If using GNU, then support inline function declarations. */
2639 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2640    generally, because even if non-gcc compilers accept `inline', they
2641    may reject `extern inline'.  */
2642 #if defined (__GNUC__) && defined (OPTIMIZE)
2643 #define INLINE __inline__
2644 #else
2645 #define INLINE
2646 #endif
2647
2648 /* `subprocesses' should be defined if you want to
2649    have code for asynchronous subprocesses
2650    (as used in M-x compile and M-x shell).
2651    Only MSDOS does not support this (it overrides
2652    this in its config_opsysfile below).  */
2653
2654 #define subprocesses
2655
2656 /* Include the os and machine dependent files.  */
2657 #include config_opsysfile
2658 #include config_machfile
2659
2660 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2661   (There is probably a better place to do this, but right now the Cocoa
2662    side does this in s/darwin.h and we cannot
2663    parallel this exactly since GNUstep is multi-OS. */
2664 #ifdef HAVE_NS
2665 #define OTHER_FILES ns-app
2666 # ifdef NS_IMPL_GNUSTEP
2667 /* See also .m.o rule in Makefile.in */
2668 /* FIXME: are all these flags really needed?  Document here why.  */
2669 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2670 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2671 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2672 #  define SYSTEM_PURESIZE_EXTRA 30000
2673 # endif /* NS_IMPL_GNUSTEP */
2674 #endif /* HAVE_NS */
2675
2676 /* SIGTYPE is the macro we actually use.  */
2677 #ifndef SIGTYPE
2678 #define SIGTYPE RETSIGTYPE
2679 #endif
2680
2681 #ifdef emacs /* Don't do this for lib-src.  */
2682 /* Tell regex.c to use a type compatible with Emacs.  */
2683 #define RE_TRANSLATE_TYPE Lisp_Object
2684 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2685 #ifdef make_number
2686 /* If make_number is a macro, use it.  */
2687 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2688 #else
2689 /* If make_number is a function, avoid it.  */
2690 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2691 #endif
2692 #endif
2693
2694 /* Avoid link-time collision with system mktime if we will use our own.  */
2695 #if ! HAVE_MKTIME || BROKEN_MKTIME
2696 #define mktime emacs_mktime
2697 #endif
2698
2699 #define my_strftime nstrftime   /* for strftime.c */
2700
2701 /* The rest of the code currently tests the CPP symbol BSTRING.
2702    Override any claims made by the system-description files.
2703    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2704 #undef BSTRING
2705 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2706 #define BSTRING
2707 #endif
2708
2709 /* Some of the files of Emacs which are intended for use with other
2710    programs assume that if you have a config.h file, you must declare
2711    the type of getenv.
2712
2713    This declaration shouldn't appear when alloca.s or Makefile.in
2714    includes config.h.  */
2715 #ifndef NOT_C_CODE
2716 extern char *getenv ();
2717 #endif
2718
2719 /* These default definitions are good for almost all machines.
2720    The exceptions override them in m/MACHINE.h.  */
2721
2722 #ifndef BITS_PER_CHAR
2723 #define BITS_PER_CHAR 8
2724 #endif
2725
2726 #ifndef BITS_PER_SHORT
2727 #define BITS_PER_SHORT 16
2728 #endif
2729
2730 /* Note that lisp.h uses this in a preprocessor conditional, so it
2731    would not work to use sizeof.  That being so, we do all of them
2732    without sizeof, for uniformity's sake.  */
2733 #ifndef BITS_PER_INT
2734 #define BITS_PER_INT 32
2735 #endif
2736
2737 #ifndef BITS_PER_LONG
2738 #ifdef _LP64
2739 #define BITS_PER_LONG 64
2740 #else
2741 #define BITS_PER_LONG 32
2742 #endif
2743 #endif
2744
2745 /* Define if the compiler supports function prototypes.  It may do so
2746    but not define __STDC__ (e.g. DEC C by default) or may define it as
2747    zero.  */
2748 #undef PROTOTYPES
2749 /* For mktime.c:  */
2750 #ifndef __P
2751 # if defined PROTOTYPES
2752 #  define __P(args) args
2753 # else
2754 #  define __P(args) ()
2755 # endif  /* GCC.  */
2756 #endif /* __P */
2757
2758 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2759 #ifndef NOT_C_CODE
2760 #ifdef HAVE_STRING_H
2761 #include "string.h"
2762 #endif
2763 #ifdef HAVE_STRINGS_H
2764 #include "strings.h"  /* May be needed for bcopy & al. */
2765 #endif
2766 #ifdef HAVE_STDLIB_H
2767 #include <stdlib.h>
2768 #endif
2769 #ifndef __GNUC__
2770 # ifdef HAVE_ALLOCA_H
2771 #  include <alloca.h>
2772 # else /* AIX files deal with #pragma.  */
2773 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2774 char *alloca ();
2775 #  endif
2776 # endif /* HAVE_ALLOCA_H */
2777 #endif /* __GNUC__ */
2778 #ifndef HAVE_SIZE_T
2779 typedef unsigned size_t;
2780 #endif
2781 #endif /* NOT_C_CODE */
2782
2783 /* Define HAVE_X_I18N if we have usable i18n support.  */
2784
2785 #ifdef HAVE_X11R6
2786 #define HAVE_X_I18N
2787 #elif !defined X11R5_INHIBIT_I18N
2788 #define HAVE_X_I18N
2789 #endif
2790
2791 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2792
2793 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2794 #define HAVE_X11R6_XIM
2795 #endif
2796
2797 /* Should we enable expensive run-time checking of data types?  */
2798 #undef ENABLE_CHECKING
2799
2800 #if defined __GNUC__ && (__GNUC__ > 2 \
2801                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2802 #define NO_RETURN       __attribute__ ((__noreturn__))
2803 #else
2804 #define NO_RETURN       /* nothing */
2805 #endif
2806
2807 /* These won't be used automatically yet.  We also need to know, at least,
2808    that the stack is continuous.  */
2809 #ifdef __GNUC__
2810 #  ifndef GC_SETJMP_WORKS
2811   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2812      see NON_SAVING_SETJMP in the target descriptions.  */
2813   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2814      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2815      Fixme: Deal with SVR3.  */
2816 #    define GC_SETJMP_WORKS 1
2817 #  endif
2818 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2819 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2820 #  endif
2821 #endif
2822
2823 #ifndef HAVE_BCOPY
2824 #define bcopy(a,b,s) memcpy (b,a,s)
2825 #endif
2826 #ifndef HAVE_BZERO
2827 #define bzero(a,s) memset (a,0,s)
2828 #endif
2829 #ifndef HAVE_BCMP
2830 #define BCMP memcmp
2831 #endif
2832
2833 #endif /* EMACS_CONFIG_H */
2834
2835 /*
2836 Local Variables:
2837 mode: c
2838 End:
2839 */
2840 ])dnl
2841
2842 #### Report on what we decided to do.
2843 #### Report GTK as a toolkit, even if it doesn't use Xt.
2844 #### It makes printing result more understandable as using GTK sets
2845 #### toolkit_scroll_bars to yes by default.
2846 if test "${HAVE_GTK}" = "yes"; then
2847   USE_X_TOOLKIT=GTK
2848 fi
2849
2850 echo "
2851 Configured for \`${canonical}'.
2852
2853   Where should the build process find the source code?    ${srcdir}
2854   What operating system and machine description files should Emacs use?
2855         \`${opsysfile}' and \`${machfile}'
2856   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2857   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2858   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2859   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2860   What window system should Emacs use?                    ${window_system}
2861   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2862
2863 if test -n "${x_includes}"; then
2864 echo "  Where do we find X Windows header files?                ${x_includes}"
2865 else
2866 echo "  Where do we find X Windows header files?                Standard dirs"
2867 fi
2868 if test -n "${x_libraries}"; then
2869 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2870 else
2871 echo "  Where do we find X Windows libraries?                   Standard dirs"
2872 fi
2873
2874 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2875 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2876 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2877 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2878 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
2879 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2880 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
2881 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
2882 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
2883
2884 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
2885 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
2886 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
2887 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
2888
2889 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
2890 echo
2891
2892 if test $USE_XASSERTS = yes; then
2893    echo "  Compiling with asserts turned on."
2894    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
2895 fi
2896
2897 echo
2898
2899 if test "$USE_X_TOOLKIT" = GTK; then
2900   case "$canonical" in
2901   *cygwin*)
2902     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
2903   will probably get a crash on startup.  If this happens, please use another
2904   toolkit for Emacs.  See etc/PROBLEMS for more information."
2905   ;;
2906   esac
2907 fi
2908
2909 if test "$HAVE_NS" = "yes"; then
2910    echo
2911    echo "You must run \"make install\" in order to test the built application.
2912 The installed application will go to nextstep/Emacs.app and can be
2913 run or moved from there."
2914    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
2915       echo "The application will be fully self-contained."
2916     else
2917       echo "The lisp resources for the application will be installed under ${prefix}.
2918 You may need to run \"make install\" with sudo.  The application will fail
2919 to run if these resources are not installed."
2920    fi
2921    echo
2922 fi
2923
2924 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
2925   echo "D-Bus integration has been tested for GNU/Linux only."
2926   echo
2927 fi
2928
2929
2930 # Remove any trailing slashes in these variables.
2931 [test "${prefix}" != NONE &&
2932   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2933 test "${exec_prefix}" != NONE &&
2934   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
2935
2936 # Now get this: Some word that is part of the ${srcdir} directory name
2937 # or the ${configuration} value might, just might, happen to be an
2938 # identifier like `sun4' or `i386' or something, and be predefined by
2939 # the C preprocessor to some helpful value like 1, or maybe the empty
2940 # string.  Needless to say consequent macro substitutions are less
2941 # than conducive to the makefile finding the correct directory.
2942 [cpp_undefs="`echo $srcdir $configuration $canonical |
2943   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
2944   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
2945
2946 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
2947 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
2948 ## from Makefile.c can correctly provide the arg `-traditional' to the
2949 ## C preprocessor.
2950
2951 AC_EGREP_CPP(yes..yes,
2952         [yes..yes],
2953         CPP_NEED_TRADITIONAL=no,
2954         CPP_NEED_TRADITIONAL=yes)
2955
2956 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2957         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
2958         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
2959         lwlib/Makefile lisp/Makefile leim/Makefile, [
2960
2961 ### Make the necessary directories, if they don't exist.
2962 for dir in etc lisp ; do
2963   test -d ${dir} || mkdir ${dir}
2964 done
2965
2966 # Build src/Makefile from ${srcdir}/src/Makefile.c
2967 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2968 # This must be done after src/config.h is built, since we rely on that file.
2969
2970 echo creating src/epaths.h
2971 ${MAKE-make} epaths-force
2972
2973 # As of 2000-11-19, newest development versions of GNU cpp preprocess
2974 # `..' to `. .'  unless invoked with -traditional
2975
2976 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
2977   CPPFLAGS="$CPPFLAGS -traditional"
2978 fi
2979
2980 echo creating lib-src/Makefile
2981 ( cd lib-src
2982   rm -f junk.c junk1.c junk2.c
2983   sed -e '/start of cpp stuff/q' \
2984       < Makefile.c > junk1.c
2985   sed -e '1,/start of cpp stuff/d'\
2986       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2987       < Makefile.c > junk.c
2988   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2989       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2990   cat junk1.c junk2.c > Makefile.new
2991   rm -f junk.c junk1.c junk2.c
2992   chmod 444 Makefile.new
2993   mv -f Makefile.new Makefile
2994 )
2995
2996 echo creating src/Makefile
2997 ( cd src
2998   rm -f junk.c junk1.c junk2.c
2999   sed -e '/start of cpp stuff/q' \
3000       < Makefile.c > junk1.c
3001   sed -e '1,/start of cpp stuff/d'\
3002       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3003       < Makefile.c > junk.c
3004   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3005       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3006   cat junk1.c junk2.c > Makefile.new
3007   rm -f junk.c junk1.c junk2.c
3008   chmod 444 Makefile.new
3009   mv -f Makefile.new Makefile
3010 )
3011
3012 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3013   echo creating src/.gdbinit
3014   echo source $srcdir/src/.gdbinit > src/.gdbinit
3015 fi
3016
3017 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3018
3019 m4_if(dnl       Do not change this comment
3020    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3021 )dnl