code.delx.au - gnu-emacs/blob - test/automated/package-test.el

   1 ;;; package-test.el --- Tests for the Emacs package system
   2
   3 ;; Copyright (C) 2013-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Daniel Hackney <dan@haxney.org>
   6 ;; Version: 1.0
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; You may want to run this from a separate Emacs instance from your
  26 ;; main one, because a bug in the code below could mess with your
  27 ;; installed packages.
  28
  29 ;; Run this in a clean Emacs session using:
  30 ;;
  31 ;;     $ emacs -Q --batch -L . -l package-test.el -l ert -f ert-run-tests-batch-and-exit
  32
  33 ;;; Code:
  34
  35 (require 'package)
  36 (require 'ert)
  37 (require 'cl-lib)
  38
  39 (setq package-menu-async nil)
  40
  41 (defvar package-test-user-dir nil
  42   "Directory to use for installing packages during testing.")
  43
  44 (defvar package-test-file-dir (file-name-directory (or load-file-name
  45                                                        buffer-file-name))
  46   "Directory of the actual \"package-test.el\" file.")
  47
  48 (defvar simple-single-desc
  49   (package-desc-create :name 'simple-single
  50                        :version '(1 3)
  51                        :summary "A single-file package with no dependencies"
  52                        :kind 'single
  53                        :extras '((:url . "http://doodles.au")))
  54   "Expected `package-desc' parsed from simple-single-1.3.el.")
  55
  56 (defvar simple-depend-desc
  57   (package-desc-create :name 'simple-depend
  58                        :version '(1 0)
  59                        :summary "A single-file package with a dependency."
  60                        :kind 'single
  61                        :reqs '((simple-single (1 3))))
  62   "Expected `package-desc' parsed from simple-depend-1.0.el.")
  63
  64 (defvar multi-file-desc
  65   (package-desc-create :name 'multi-file
  66                        :version '(0 2 3)
  67                        :summary "Example of a multi-file tar package"
  68                        :kind 'tar
  69                        :extras '((:url . "http://puddles.li")))
  70   "Expected `package-desc' from \"multi-file-0.2.3.tar\".")
  71
  72 (defvar new-pkg-desc
  73   (package-desc-create :name 'new-pkg
  74                        :version '(1 0)
  75                        :kind 'single)
  76   "Expected `package-desc' parsed from new-pkg-1.0.el.")
  77
  78 (defvar simple-depend-desc-1
  79   (package-desc-create :name 'simple-depend-1
  80                        :version '(1 0)
  81                        :summary "A single-file package with a dependency."
  82                        :kind 'single
  83                        :reqs '((simple-depend (1 0))
  84                                (multi-file (0 1))))
  85   "`package-desc' used for testing dependencies.")
  86
  87 (defvar simple-depend-desc-2
  88   (package-desc-create :name 'simple-depend-2
  89                        :version '(1 0)
  90                        :summary "A single-file package with a dependency."
  91                        :kind 'single
  92                        :reqs '((simple-depend-1 (1 0))
  93                                (multi-file (0 1))))
  94   "`package-desc' used for testing dependencies.")
  95
  96 (defvar package-test-data-dir (expand-file-name "data/package" package-test-file-dir)
  97   "Base directory of package test files.")
  98
  99 (defvar package-test-fake-contents-file
 100   (expand-file-name "archive-contents" package-test-data-dir)
 101   "Path to a static copy of \"archive-contents\".")
 102
 103 (cl-defmacro with-package-test ((&optional &key file
 104                                            basedir
 105                                            install
 106                                            location
 107                                            update-news
 108                                            upload-base)
 109                                 &rest body)
 110   "Set up temporary locations and variables for testing."
 111   (declare (indent 1))
 112   `(let* ((package-test-user-dir (make-temp-file "pkg-test-user-dir-" t))
 113           (process-environment (cons (format "HOME=%s" package-test-user-dir)
 114                                      process-environment))
 115           (package-user-dir package-test-user-dir)
 116           (package-archives `(("gnu" . ,(or ,location package-test-data-dir))))
 117           (default-directory package-test-file-dir)
 118           abbreviated-home-dir
 119           package--initialized
 120           package-alist
 121           ,@(if update-news
 122                 '(package-update-news-on-upload t)
 123               (list (cl-gensym)))
 124           ,@(if upload-base
 125                 '((package-test-archive-upload-base (make-temp-file "pkg-archive-base-" t))
 126                   (package-archive-upload-base package-test-archive-upload-base))
 127               (list (cl-gensym)))) ;; Dummy value so `let' doesn't try to bind `nil'
 128      (unwind-protect
 129          (progn
 130            ,(if basedir `(cd ,basedir))
 131            (unless (file-directory-p package-user-dir)
 132              (mkdir package-user-dir))
 133            (cl-letf (((symbol-function 'yes-or-no-p) (lambda (&rest r) t))
 134                      ((symbol-function 'y-or-n-p)    (lambda (&rest r) t)))
 135              ,@(when install
 136                  `((package-initialize)
 137                    (package-refresh-contents)
 138                    (mapc 'package-install ,install)))
 139              (with-temp-buffer
 140                ,(if file
 141                     `(insert-file-contents ,file))
 142                ,@body)))
 143
 144        (when (file-directory-p package-test-user-dir)
 145          (delete-directory package-test-user-dir t))
 146
 147        (when (and (boundp 'package-test-archive-upload-base)
 148                   (file-directory-p package-test-archive-upload-base))
 149          (delete-directory package-test-archive-upload-base t)))))
 150
 151 (defmacro with-fake-help-buffer (&rest body)
 152   "Execute BODY in a temp buffer which is treated as the \"*Help*\" buffer."
 153   `(with-temp-buffer
 154     (help-mode)
 155     ;; Trick `help-buffer' into using the temp buffer.
 156     (let ((help-xref-following t))
 157       ,@body)))
 158
 159 (defun package-test-strip-version (dir)
 160   (replace-regexp-in-string "-pkg\\.el\\'" "" (package--description-file dir)))
 161
 162 (defun package-test-suffix-matches (base suffix-list)
 163   "Return file names matching BASE concatenated with each item in SUFFIX-LIST"
 164   (cl-mapcan
 165    '(lambda (item) (file-expand-wildcards (concat base item)))
 166    suffix-list))
 167
 168 (defvar tar-parse-info)
 169 (declare-function tar-header-name "tar-mode" (cl-x) t) ; defstruct
 170
 171 (defun package-test-search-tar-file (filename)
 172   "Search the current buffer's `tar-parse-info' variable for FILENAME.
 173
 174 Must called from within a `tar-mode' buffer."
 175   (cl-dolist (header tar-parse-info)
 176     (let ((tar-name (tar-header-name header)))
 177       (when (string= tar-name filename)
 178         (cl-return t)))))
 179
 180 (defun package-test-desc-version-string (desc)
 181   "Return the package version as a string."
 182   (package-version-join (package-desc-version desc)))
 183
 184 (ert-deftest package-test-desc-from-buffer ()
 185   "Parse an elisp buffer to get a `package-desc' object."
 186   (with-package-test (:basedir "data/package" :file "simple-single-1.3.el")
 187     (should (equal (package-buffer-info) simple-single-desc)))
 188   (with-package-test (:basedir "data/package" :file "simple-depend-1.0.el")
 189     (should (equal (package-buffer-info) simple-depend-desc)))
 190   (with-package-test (:basedir "data/package"
 191                                :file "multi-file-0.2.3.tar")
 192     (tar-mode)
 193     (should (equal (package-tar-file-info) multi-file-desc))))
 194
 195 (ert-deftest package-test-install-single ()
 196   "Install a single file without using an archive."
 197   (with-package-test (:basedir "data/package" :file "simple-single-1.3.el")
 198     (should (package-install-from-buffer))
 199     (package-initialize)
 200     (should (package-installed-p 'simple-single))
 201     (let* ((simple-pkg-dir (file-name-as-directory
 202                             (expand-file-name
 203                              "simple-single-1.3"
 204                              package-test-user-dir)))
 205            (autoloads-file (expand-file-name "simple-single-autoloads.el"
 206                                              simple-pkg-dir)))
 207       (should (file-directory-p simple-pkg-dir))
 208       (with-temp-buffer
 209         (insert-file-contents (expand-file-name "simple-single-pkg.el"
 210                                                 simple-pkg-dir))
 211         (should (string= (buffer-string)
 212                          (concat ";;; -*- no-byte-compile: t -*-\n"
 213                                  "(define-package \"simple-single\" \"1.3\" "
 214                                  "\"A single-file package "
 215                                  "with no dependencies\" 'nil "
 216                                  ":url \"http://doodles.au\""
 217                                  ")\n"))))
 218       (should (file-exists-p autoloads-file))
 219       (should-not (get-file-buffer autoloads-file)))))
 220
 221 (ert-deftest package-test-install-dependency ()
 222   "Install a package which includes a dependency."
 223   (with-package-test ()
 224     (package-initialize)
 225     (package-refresh-contents)
 226     (package-install 'simple-depend)
 227     (should (package-installed-p 'simple-single))
 228     (should (package-installed-p 'simple-depend))))
 229
 230 (ert-deftest package-test-install-two-dependencies ()
 231   "Install a package which includes a dependency."
 232   (with-package-test ()
 233     (package-initialize)
 234     (package-refresh-contents)
 235     (package-install 'simple-two-depend)
 236     (should (package-installed-p 'simple-single))
 237     (should (package-installed-p 'simple-depend))
 238     (should (package-installed-p 'simple-two-depend))))
 239
 240 (ert-deftest package-test-refresh-contents ()
 241   "Parse an \"archive-contents\" file."
 242   (with-package-test ()
 243     (package-initialize)
 244     (package-refresh-contents)
 245     (should (eq 4 (length package-archive-contents)))))
 246
 247 (ert-deftest package-test-install-single-from-archive ()
 248   "Install a single package from a package archive."
 249   (with-package-test ()
 250     (package-initialize)
 251     (package-refresh-contents)
 252     (package-install 'simple-single)))
 253
 254 (ert-deftest package-test-install-prioritized ()
 255   "Install a lower version from a higher-prioritized archive."
 256   (with-package-test ()
 257     (let* ((newer-version (expand-file-name "data/package/newer-versions"
 258                                             package-test-file-dir))
 259            (package-archives `(("older" . ,package-test-data-dir)
 260                                ("newer" . ,newer-version)))
 261            (package-archive-priorities '(("older" . 100))))
 262
 263       (package-initialize)
 264       (package-refresh-contents)
 265       (package-install 'simple-single)
 266
 267       (let ((installed (cadr (assq 'simple-single package-alist))))
 268         (should (version-list-= '(1 3)
 269                                 (package-desc-version installed)))))))
 270
 271 (ert-deftest package-test-install-multifile ()
 272   "Check properties of the installed multi-file package."
 273   (with-package-test (:basedir "data/package" :install '(multi-file))
 274     (let ((autoload-file
 275            (expand-file-name "multi-file-autoloads.el"
 276                              (expand-file-name
 277                               "multi-file-0.2.3"
 278                               package-test-user-dir)))
 279           (installed-files '("dir" "multi-file.info" "multi-file-sub.elc"
 280                              "multi-file-autoloads.el" "multi-file.elc"))
 281           (autoload-forms '("^(defvar multi-file-custom-var"
 282                             "^(custom-autoload 'multi-file-custom-var"
 283                             "^(autoload 'multi-file-mode"))
 284           (pkg-dir (file-name-as-directory
 285                     (expand-file-name
 286                      "multi-file-0.2.3"
 287                      package-test-user-dir))))
 288       (package-refresh-contents)
 289       (should (package-installed-p 'multi-file))
 290       (with-temp-buffer
 291         (insert-file-contents-literally autoload-file)
 292         (dolist (fn installed-files)
 293           (should (file-exists-p (expand-file-name fn pkg-dir))))
 294         (dolist (re autoload-forms)
 295           (goto-char (point-min))
 296           (should (re-search-forward re nil t)))))))
 297
 298 (ert-deftest package-test-update-listing ()
 299   "Ensure installed package status is updated."
 300   (with-package-test ()
 301     (let ((buf (package-list-packages)))
 302       (search-forward-regexp "^ +simple-single")
 303       (package-menu-mark-install)
 304       (package-menu-execute)
 305       (should (package-installed-p 'simple-single))
 306       (switch-to-buffer "*Packages*")
 307       (goto-char (point-min))
 308       (should (re-search-forward "^\\s-+simple-single\\s-+1.3\\s-+installed" nil t))
 309       (goto-char (point-min))
 310       (should-not (re-search-forward "^\\s-+simple-single\\s-+1.3\\s-+\\(available\\|new\\)" nil t))
 311       (kill-buffer buf))))
 312
 313 (ert-deftest package-test-update-archives ()
 314   "Test updating package archives."
 315   (with-package-test ()
 316     (let ((buf (package-list-packages)))
 317       (package-menu-refresh)
 318       (search-forward-regexp "^ +simple-single")
 319       (package-menu-mark-install)
 320       (package-menu-execute)
 321       (should (package-installed-p 'simple-single))
 322       (let ((package-test-data-dir
 323              (expand-file-name "data/package/newer-versions" package-test-file-dir)))
 324         (setq package-archives `(("gnu" . ,package-test-data-dir)))
 325         (package-menu-refresh)
 326
 327         ;; New version should be available and old version should be installed
 328         (goto-char (point-min))
 329         (should (re-search-forward "^\\s-+simple-single\\s-+1.4\\s-+available" nil t))
 330         (should (re-search-forward "^\\s-+simple-single\\s-+1.3\\s-+installed" nil t))
 331
 332         (goto-char (point-min))
 333         (should (re-search-forward "^\\s-+new-pkg\\s-+1.0\\s-+\\(available\\|new\\)" nil t))
 334
 335         (package-menu-mark-upgrades)
 336         (package-menu-execute)
 337         (package-menu-refresh)
 338         (should (package-installed-p 'simple-single '(1 4)))))))
 339
 340 (ert-deftest package-test-update-archives-async ()
 341   "Test updating package archives asynchronously."
 342   (skip-unless (executable-find "python2"))
 343   (with-package-test (:basedir
 344                       package-test-data-dir
 345                       :location "http://0.0.0.0:8000/")
 346     (let* ((package-menu-async t)
 347            (process (start-process
 348                      "package-server" "package-server-buffer"
 349                      (executable-find "python2")
 350                      (expand-file-name "package-test-server.py"))))
 351       (unwind-protect
 352           (progn
 353             (list-packages)
 354             (should package--downloads-in-progress)
 355             (should mode-line-process)
 356             (should-not (string= (format-mode-line mode-line-process) ""))
 357             (should-not
 358              (with-timeout (10 'timeout)
 359                (while package--downloads-in-progress
 360                  (accept-process-output nil 1))
 361                nil))
 362             (goto-char (point-min))
 363             (should
 364              (search-forward-regexp "^ +simple-single" nil t)))
 365         (kill-process process)))))
 366
 367 (ert-deftest package-test-describe-package ()
 368   "Test displaying help for a package."
 369
 370   (require 'finder-inf)
 371   ;; Built-in
 372   (with-fake-help-buffer
 373    (describe-package '5x5)
 374    (goto-char (point-min))
 375    (should (search-forward "5x5 is a built-in package." nil t))
 376    (should (search-forward "Status: Built-in." nil t))
 377    (should (search-forward "Summary: simple little puzzle game" nil t))
 378    (should (search-forward "The aim of 5x5" nil t)))
 379
 380   ;; Installed
 381   (with-package-test ()
 382     (package-initialize)
 383     (package-refresh-contents)
 384     (package-install 'simple-single)
 385     (with-fake-help-buffer
 386      (describe-package 'simple-single)
 387      (goto-char (point-min))
 388      (should (search-forward "simple-single is an installed package." nil t))
 389      (should (search-forward
 390               "Status: Installed in `~/simple-single-1.3/' (unsigned)."
 391               nil t))
 392      (should (search-forward "Version: 1.3" nil t))
 393      (should (search-forward "Summary: A single-file package with no dependencies"
 394                              nil t))
 395      (should (search-forward "Homepage: http://doodles.au" nil t))
 396      (should (re-search-forward "Keywords: \\[?frobnicate\\]?" nil t))
 397      ;; No description, though. Because at this point we don't know
 398      ;; what archive the package originated from, and we don't have
 399      ;; its readme file saved.
 400      )))
 401
 402 (ert-deftest package-test-describe-non-installed-package ()
 403   "Test displaying of the readme for non-installed package."
 404
 405   (with-package-test ()
 406     (package-initialize)
 407     (package-refresh-contents)
 408     (with-fake-help-buffer
 409      (describe-package 'simple-single)
 410      (goto-char (point-min))
 411      (should (search-forward "Homepage: http://doodles.au" nil t))
 412      (should (search-forward "This package provides a minor mode to frobnicate"
 413                              nil t)))))
 414
 415 (ert-deftest package-test-describe-non-installed-multi-file-package ()
 416   "Test displaying of the readme for non-installed multi-file package."
 417
 418   (with-package-test ()
 419     (package-initialize)
 420     (package-refresh-contents)
 421     (with-fake-help-buffer
 422      (describe-package 'multi-file)
 423      (goto-char (point-min))
 424      (should (search-forward "Homepage: http://puddles.li" nil t))
 425      (should (search-forward "This is a bare-bones readme file for the multi-file"
 426                              nil t)))))
 427
 428 (ert-deftest package-test-signed ()
 429   "Test verifying package signature."
 430   (skip-unless (ignore-errors
 431                  (let ((homedir (make-temp-file "package-test" t)))
 432                    (unwind-protect
 433                        (let ((process-environment
 434                               (cons (format "HOME=%s" homedir)
 435                                     process-environment)))
 436                          (epg-check-configuration (epg-configuration))
 437                          t)
 438                      (delete-directory homedir t)))))
 439   (let* ((keyring (expand-file-name "key.pub" package-test-data-dir))
 440          (package-test-data-dir
 441            (expand-file-name "data/package/signed" package-test-file-dir)))
 442     (with-package-test ()
 443       (package-initialize)
 444       (package-import-keyring keyring)
 445       (package-refresh-contents)
 446       (should (package-install 'signed-good))
 447       (should-error (package-install 'signed-bad))
 448       ;; Check if the installed package status is updated.
 449       (let ((buf (package-list-packages)))
 450         (package-menu-refresh)
 451         (should (re-search-forward
 452                  "^\\s-+signed-good\\s-+\\(\\S-+\\)\\s-+\\(\\S-+\\)\\s-"
 453                  nil t))
 454         (should (string-equal (match-string-no-properties 1) "1.0"))
 455         (should (string-equal (match-string-no-properties 2) "installed")))
 456       ;; Check if the package description is updated.
 457       (with-fake-help-buffer
 458        (describe-package 'signed-good)
 459        (goto-char (point-min))
 460        (should (re-search-forward "signed-good is an? \\(\\S-+\\) package." nil t))
 461        (should (string-equal (match-string-no-properties 1) "installed"))
 462        (should (search-forward
 463                 "Status: Installed in `~/signed-good-1.0/'."
 464                 nil t))))))
 465
 466
 467 \f
 468 ;;; Tests for package-x features.
 469
 470 (require 'package-x)
 471
 472 (defvar package-x-test--single-archive-entry-1-3
 473   (cons 'simple-single
 474         (package-make-ac-desc '(1 3) nil
 475                               "A single-file package with no dependencies"
 476                               'single
 477                               '((:url . "http://doodles.au"))))
 478   "Expected contents of the archive entry from the \"simple-single\" package.")
 479
 480 (defvar package-x-test--single-archive-entry-1-4
 481   (cons 'simple-single
 482         (package-make-ac-desc '(1 4) nil
 483                               "A single-file package with no dependencies"
 484                               'single
 485                               nil))
 486   "Expected contents of the archive entry from the updated \"simple-single\" package.")
 487
 488 (ert-deftest package-x-test-upload-buffer ()
 489   "Test creating an \"archive-contents\" file"
 490   (with-package-test (:basedir "data/package"
 491                                :file "simple-single-1.3.el"
 492                                :upload-base t)
 493     (package-upload-buffer)
 494     (should (file-exists-p (expand-file-name "archive-contents"
 495                                              package-archive-upload-base)))
 496     (should (file-exists-p (expand-file-name "simple-single-1.3.el"
 497                                              package-archive-upload-base)))
 498     (should (file-exists-p (expand-file-name "simple-single-readme.txt"
 499                                              package-archive-upload-base)))
 500
 501     (let (archive-contents)
 502       (with-temp-buffer
 503         (insert-file-contents
 504          (expand-file-name "archive-contents"
 505                            package-archive-upload-base))
 506         (setq archive-contents
 507               (package-read-from-string
 508                (buffer-substring (point-min) (point-max)))))
 509       (should (equal archive-contents
 510                      (list 1 package-x-test--single-archive-entry-1-3))))))
 511
 512 (ert-deftest package-x-test-upload-new-version ()
 513   "Test uploading a new version of a package"
 514   (with-package-test (:basedir "data/package"
 515                                :file "simple-single-1.3.el"
 516                                :upload-base t)
 517     (package-upload-buffer)
 518     (with-temp-buffer
 519       (insert-file-contents "newer-versions/simple-single-1.4.el")
 520       (package-upload-buffer))
 521
 522     (let (archive-contents)
 523       (with-temp-buffer
 524         (insert-file-contents
 525          (expand-file-name "archive-contents"
 526                            package-archive-upload-base))
 527         (setq archive-contents
 528               (package-read-from-string
 529                (buffer-substring (point-min) (point-max)))))
 530       (should (equal archive-contents
 531                      (list 1 package-x-test--single-archive-entry-1-4))))))
 532
 533 (ert-deftest package-test-get-deps ()
 534   "Test `package--get-deps' with complex structures."
 535   (let ((package-alist
 536          (mapcar (lambda (p) (list (package-desc-name p) p))
 537            (list simple-single-desc
 538                  simple-depend-desc
 539                  multi-file-desc
 540                  new-pkg-desc
 541                  simple-depend-desc-1
 542                  simple-depend-desc-2))))
 543     (should
 544      (equal (package--get-deps 'simple-depend)
 545             '(simple-single)))
 546     (should
 547      (equal (package--get-deps 'simple-depend 'indirect)
 548             nil))
 549     (should
 550      (equal (package--get-deps 'simple-depend 'direct)
 551             '(simple-single)))
 552     (should
 553      (equal (package--get-deps 'simple-depend-2)
 554             '(simple-depend-1 multi-file simple-depend simple-single)))
 555     (should
 556      (equal (package--get-deps 'simple-depend-2 'indirect)
 557             '(simple-depend multi-file simple-single)))
 558     (should
 559      (equal (package--get-deps 'simple-depend-2 'direct)
 560             '(simple-depend-1 multi-file)))))
 561
 562 (ert-deftest package-test-sort-by-dependence ()
 563   "Test `package--sort-by-dependence' with complex structures."
 564   (let ((package-alist
 565          (mapcar (lambda (p) (list (package-desc-name p) p))
 566            (list simple-single-desc
 567                  simple-depend-desc
 568                  multi-file-desc
 569                  new-pkg-desc
 570                  simple-depend-desc-1
 571                  simple-depend-desc-2)))
 572         (delete-list
 573          (list simple-single-desc
 574                simple-depend-desc
 575                multi-file-desc
 576                new-pkg-desc
 577                simple-depend-desc-1
 578                simple-depend-desc-2)))
 579     (should
 580      (equal (package--sort-by-dependence delete-list)
 581             (list simple-depend-desc-2 simple-depend-desc-1 new-pkg-desc
 582                   multi-file-desc simple-depend-desc simple-single-desc)))
 583     (should
 584      (equal (package--sort-by-dependence (reverse delete-list))
 585             (list new-pkg-desc simple-depend-desc-2 simple-depend-desc-1
 586                   multi-file-desc simple-depend-desc simple-single-desc)))))
 587
 588 (provide 'package-test)
 589
 590 ;;; package-test.el ends here