code.delx.au - gnu-emacs/blob - lisp/progmodes/compile.el

   1 ;;; compile.el --- run compiler as inferior of Emacs, parse error messages
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4 ;;   2001, 2002, 2003, 2004, 2005, 2006  Free Software Foundation, Inc.
   5
   6 ;; Authors: Roland McGrath <roland@gnu.org>,
   7 ;;          Daniel Pfeiffer <occitan@esperanto.org>
   8 ;; Maintainer: FSF
   9 ;; Keywords: tools, processes
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package provides the compile facilities documented in the Emacs user's
  31 ;; manual.
  32
  33 ;; This mode uses some complex data-structures:
  34
  35 ;;   LOC (or location) is a list of (COLUMN LINE FILE-STRUCTURE)
  36
  37 ;; COLUMN and LINE are numbers parsed from an error message.  COLUMN and maybe
  38 ;; LINE will be nil for a message that doesn't contain them.  Then the
  39 ;; location refers to a indented beginning of line or beginning of file.
  40 ;; Once any location in some file has been jumped to, the list is extended to
  41 ;; (COLUMN LINE FILE-STRUCTURE MARKER . VISITED) for all LOCs pertaining to
  42 ;; that file.
  43 ;; MARKER initially points to LINE and COLUMN in a buffer visiting that file.
  44 ;; Being a marker it sticks to some text, when the buffer grows or shrinks
  45 ;; before that point.  VISITED is t if we have jumped there, else nil.
  46
  47 ;;   FILE-STRUCTURE is a list of
  48 ;;   ((FILENAME . DIRECTORY) FORMATS (LINE LOC ...) ...)
  49
  50 ;; FILENAME is a string parsed from an error message.  DIRECTORY is a string
  51 ;; obtained by following directory change messages.  DIRECTORY will be nil for
  52 ;; an absolute filename.  FORMATS is a list of formats to apply to FILENAME if
  53 ;; a file of that name can't be found.
  54 ;; The rest of the list is an alist of elements with LINE as key.  The keys
  55 ;; are either nil or line numbers.  If present, nil comes first, followed by
  56 ;; the numbers in decreasing order.  The LOCs for each line are again an alist
  57 ;; ordered the same way.  Note that the whole file structure is referenced in
  58 ;; every LOC.
  59
  60 ;;   MESSAGE is a list of (LOC TYPE END-LOC)
  61
  62 ;; TYPE is 0 for info or 1 for warning if the message matcher identified it as
  63 ;; such, 2 otherwise (for a real error).  END-LOC is a LOC pointing to the
  64 ;; other end, if the parsed message contained a range.  If the end of the
  65 ;; range didn't specify a COLUMN, it defaults to -1, meaning end of line.
  66 ;; These are the value of the `message' text-properties in the compilation
  67 ;; buffer.
  68
  69 ;;; Code:
  70
  71 (eval-when-compile (require 'cl))
  72
  73 (defvar font-lock-extra-managed-props)
  74 (defvar font-lock-keywords)
  75 (defvar font-lock-maximum-size)
  76 (defvar font-lock-support-mode)
  77
  78
  79 (defgroup compilation nil
  80   "Run compiler as inferior of Emacs, parse error messages."
  81   :group 'tools
  82   :group 'processes)
  83
  84
  85 ;;;###autoload
  86 (defcustom compilation-mode-hook nil
  87   "*List of hook functions run by `compilation-mode' (see `run-mode-hooks')."
  88   :type 'hook
  89   :group 'compilation)
  90
  91 ;;;###autoload
  92 (defcustom compilation-window-height nil
  93   "*Number of lines in a compilation window.  If nil, use Emacs default."
  94   :type '(choice (const :tag "Default" nil)
  95                  integer)
  96   :group 'compilation)
  97
  98 (defvar compilation-first-column 1
  99   "*This is how compilers number the first column, usually 1 or 0.")
 100
 101 (defvar compilation-parse-errors-filename-function nil
 102   "Function to call to post-process filenames while parsing error messages.
 103 It takes one arg FILENAME which is the name of a file as found
 104 in the compilation output, and should return a transformed file name.")
 105
 106 ;;;###autoload
 107 (defvar compilation-process-setup-function nil
 108   "*Function to call to customize the compilation process.
 109 This function is called immediately before the compilation process is
 110 started.  It can be used to set any variables or functions that are used
 111 while processing the output of the compilation process.  The function
 112 is called with variables `compilation-buffer' and `compilation-window'
 113 bound to the compilation buffer and window, respectively.")
 114
 115 ;;;###autoload
 116 (defvar compilation-buffer-name-function nil
 117   "Function to compute the name of a compilation buffer.
 118 The function receives one argument, the name of the major mode of the
 119 compilation buffer.  It should return a string.
 120 nil means compute the name with `(concat \"*\" (downcase major-mode) \"*\")'.")
 121
 122 ;;;###autoload
 123 (defvar compilation-finish-function nil
 124   "Function to call when a compilation process finishes.
 125 It is called with two arguments: the compilation buffer, and a string
 126 describing how the process finished.")
 127
 128 (make-obsolete-variable 'compilation-finish-function
 129   "Use `compilation-finish-functions', but it works a little differently."
 130   "22.1")
 131
 132 ;;;###autoload
 133 (defvar compilation-finish-functions nil
 134   "Functions to call when a compilation process finishes.
 135 Each function is called with two arguments: the compilation buffer,
 136 and a string describing how the process finished.")
 137
 138 (defvar compilation-in-progress nil
 139   "List of compilation processes now running.")
 140 (or (assq 'compilation-in-progress minor-mode-alist)
 141     (setq minor-mode-alist (cons '(compilation-in-progress " Compiling")
 142                                  minor-mode-alist)))
 143
 144 (defvar compilation-error "error"
 145   "Stem of message to print when no matches are found.")
 146
 147 (defvar compilation-arguments nil
 148   "Arguments that were given to `compilation-start'.")
 149
 150 (defvar compilation-num-errors-found)
 151
 152 (defconst compilation-error-regexp-alist-alist
 153   '((absoft
 154      "^\\(?:[Ee]rror on \\|[Ww]arning on\\( \\)\\)?[Ll]ine[ \t]+\\([0-9]+\\)[ \t]+\
 155 of[ \t]+\"?\\([a-zA-Z]?:?[^\":\n]+\\)\"?:" 3 2 nil (1))
 156
 157     (ada
 158      "\\(warning: .*\\)? at \\([^ \n]+\\):\\([0-9]+\\)$" 2 3 nil (1))
 159
 160     (aix
 161      " in line \\([0-9]+\\) of file \\([^ \n]+[^. \n]\\)\\.? " 2 1)
 162
 163     (ant
 164      "^[ \t]*\\[[^] \n]+\\][ \t]*\\([^: \n]+\\):\\([0-9]+\\):\\(?:\\([0-9]+\\):[0-9]+:[0-9]+:\\)?\
 165 \\( warning\\)?" 1 2 3 (4))
 166
 167     (bash
 168      "^\\([^: \n\t]+\\): line \\([0-9]+\\):" 1 2)
 169
 170     (borland
 171      "^\\(?:Error\\|Warnin\\(g\\)\\) \\(?:[FEW][0-9]+ \\)?\
 172 \\([a-zA-Z]?:?[^:( \t\n]+\\)\
 173  \\([0-9]+\\)\\(?:[) \t]\\|:[^0-9\n]\\)" 2 3 nil (1))
 174
 175     (caml
 176      "^ *File \\(\"?\\)\\([^,\" \n\t<>]+\\)\\1, lines? \\([0-9]+\\)-?\\([0-9]+\\)?\\(?:$\\|,\
 177 \\(?: characters? \\([0-9]+\\)-?\\([0-9]+\\)?:\\)?\\([ \n]Warning:\\)?\\)"
 178      2 (3 . 4) (5 . 6) (7))
 179
 180     (comma
 181      "^\"\\([^,\" \n\t]+\\)\", line \\([0-9]+\\)\
 182 \\(?:[(. pos]+\\([0-9]+\\))?\\)?[:.,; (-]\\( warning:\\|[-0-9 ]*(W)\\)?" 1 2 3 (4))
 183
 184     (edg-1
 185      "^\\([^ \n]+\\)(\\([0-9]+\\)): \\(?:error\\|warnin\\(g\\)\\|remar\\(k\\)\\)"
 186      1 2 nil (3 . 4))
 187     (edg-2
 188      "at line \\([0-9]+\\) of \"\\([^ \n]+\\)\"$"
 189      2 1 nil 0)
 190
 191     (epc
 192      "^Error [0-9]+ at (\\([0-9]+\\):\\([^)\n]+\\))" 2 1)
 193
 194     (ftnchek
 195      "\\(^Warning .*\\)? line[ \n]\\([0-9]+\\)[ \n]\\(?:col \\([0-9]+\\)[ \n]\\)?file \\([^ :;\n]+\\)"
 196      4 2 3 (1))
 197
 198     (iar
 199      "^\"\\(.*\\)\",\\([0-9]+\\)\\s-+\\(?:Error\\|Warnin\\(g\\)\\)\\[[0-9]+\\]:"
 200      1 2 nil (3))
 201
 202     (ibm
 203      "^\\([^( \n\t]+\\)(\\([0-9]+\\):\\([0-9]+\\)) :\
 204  \\(?:warnin\\(g\\)\\|informationa\\(l\\)\\)?" 1 2 3 (4 . 5))
 205
 206     ;; fixme: should be `mips'
 207     (irix
 208      "^[-[:alnum:]_/ ]+: \\(?:\\(?:[sS]evere\\|[eE]rror\\|[wW]arnin\\(g\\)\\|[iI]nf\\(o\\)\\)[0-9 ]*: \\)?\
 209 \\([^,\" \n\t]+\\)\\(?:, line\\|:\\) \\([0-9]+\\):" 3 4 nil (1 . 2))
 210
 211     (java
 212      "^\\(?:[ \t]+at \\|==[0-9]+== +\\(?:at\\|b\\(y\\)\\)\\).+(\\([^()\n]+\\):\\([0-9]+\\))$" 2 3 nil (1))
 213
 214     (jikes-file
 215      "^\\(?:Found\\|Issued\\) .* compiling \"\\(.+\\)\":$" 1 nil nil 0)
 216     (jikes-line
 217      "^ *\\([0-9]+\\)\\.[ \t]+.*\n +\\(<-*>\n\\*\\*\\* \\(?:Error\\|Warnin\\(g\\)\\)\\)"
 218      nil 1 nil 2 0
 219      (2 (compilation-face '(3))))
 220
 221     (gnu
 222      ;; I have no idea what this first line is supposed to match, but it
 223      ;; makes things ambiguous with output such as "foo:344:50:blabla" since
 224      ;; the "foo" part can match this first line (in which case the file
 225      ;; name as "344").  To avoid this, the second line disallows filenames
 226      ;; exclusively composed of digits.  --Stef
 227      ;; Similarly, we get lots of false positives with messages including
 228      ;; times of the form "HH:MM:SS" where MM is taken as a line number, so
 229      ;; the last line tries to rule out message where the info after the
 230      ;; line number starts with "SS".  --Stef
 231      "^\\(?:[[:alpha:]][-[:alnum:].]+: ?\\)?\
 232 \\([0-9]*[^0-9\n]\\(?:[^\n ]\\| [^-\n]\\)*?\\): ?\
 233 \\([0-9]+\\)\\(?:\\([.:]\\)\\([0-9]+\\)\\)?\
 234 \\(?:-\\([0-9]+\\)?\\(?:\\3\\([0-9]+\\)\\)?\\)?:\
 235 \\(?: *\\(\\(?:Future\\|Runtime\\)?[Ww]arning\\|W:\\)\\|\
 236  *\\([Ii]nfo\\(?:\\>\\|rmationa?l?\\)\\|I:\\|instantiated from\\)\\|\
 237 \[0-9]?\\(?:[^0-9\n]\\|$\\)\\|[0-9][0-9][0-9]\\)"
 238      1 (2 . 5) (4 . 6) (7 . 8))
 239
 240     ;; The `gnu' style above can incorrectly match gcc's "In file
 241     ;; included from" message, so we process that first. -- cyd
 242     (gcc-include
 243      "^\\(?:In file included\\|                \\) from \
 244 \\(.+\\):\\([0-9]+\\)\\(?:\\(:\\)\\|\\(,\\)\\)?" 1 2 nil (3 . 4))
 245
 246     (lcc
 247      "^\\(?:E\\|\\(W\\)\\), \\([^(\n]+\\)(\\([0-9]+\\),[ \t]*\\([0-9]+\\)"
 248      2 3 4 (1))
 249
 250     (makepp
 251      "^makepp: \\(?:\\(?:warning\\(:\\).*?\\|\\(Scanning\\|[LR]e?l?oading makefile\\|Imported\\) \\|.*?\\)\
 252 `\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)['(]\\)"
 253      4 5 nil (1 . 2) 3
 254      ("`\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)['(]" nil nil
 255       (2 compilation-info-face)
 256       (3 compilation-line-face nil t)
 257       (1 (compilation-error-properties 2 3 nil nil nil 0 nil)
 258          append)))
 259
 260     ;; Should be lint-1, lint-2 (SysV lint)
 261     (mips-1
 262      " (\\([0-9]+\\)) in \\([^ \n]+\\)" 2 1)
 263     (mips-2
 264      " in \\([^()\n ]+\\)(\\([0-9]+\\))$" 1 2)
 265
 266     (msft
 267      "^\\([0-9]+>\\)?\\(\\(?:[a-zA-Z]:\\)?[^:(\t\n]+\\)(\\([0-9]+\\)) \
 268 : \\(?:error\\|warnin\\(g\\)\\) C[0-9]+:" 2 3 nil (4))
 269
 270     (oracle
 271      "^\\(?:Semantic error\\|Error\\|PCC-[0-9]+:\\).* line \\([0-9]+\\)\
 272 \\(?:\\(?:,\\| at\\)? column \\([0-9]+\\)\\)?\
 273 \\(?:,\\| in\\| of\\)? file \\(.*?\\):?$"
 274      3 1 2)
 275
 276     (perl
 277      " at \\([^ \n]+\\) line \\([0-9]+\\)\\(?:[,.]\\|$\\)" 1 2)
 278
 279     (rxp
 280      "^\\(?:Error\\|Warnin\\(g\\)\\):.*\n.* line \\([0-9]+\\) char\
 281  \\([0-9]+\\) of file://\\(.+\\)"
 282      4 2 3 (1))
 283
 284     (sparc-pascal-file
 285      "^\\w\\w\\w \\w\\w\\w +[0-3]?[0-9] +[0-2][0-9]:[0-5][0-9]:[0-5][0-9]\
 286  [12][09][0-9][0-9] +\\(.*\\):$"
 287      1 nil nil 0)
 288     (sparc-pascal-line
 289      "^\\(\\(?:E\\|\\(w\\)\\) +[0-9]+\\) line \\([0-9]+\\) -  "
 290      nil 3 nil (2) nil (1 (compilation-face '(2))))
 291     (sparc-pascal-example
 292      "^ +\\([0-9]+\\) +.*\n\\(\\(?:e\\|\\(w\\)\\) [0-9]+\\)-+"
 293      nil 1 nil (3) nil (2 (compilation-face '(3))))
 294
 295     (sun
 296      ": \\(?:ERROR\\|WARNIN\\(G\\)\\|REMAR\\(K\\)\\) \\(?:[[:alnum:] ]+, \\)?\
 297 File = \\(.+\\), Line = \\([0-9]+\\)\\(?:, Column = \\([0-9]+\\)\\)?"
 298      3 4 5 (1 . 2))
 299
 300     (sun-ada
 301      "^\\([^, \n\t]+\\), line \\([0-9]+\\), char \\([0-9]+\\)[:., \(-]" 1 2 3)
 302
 303     (4bsd
 304      "\\(?:^\\|::  \\|\\S ( \\)\\(/[^ \n\t()]+\\)(\\([0-9]+\\))\
 305 \\(?:: \\(warning:\\)?\\|$\\| ),\\)" 1 2 nil (3))
 306
 307     (gcov-file
 308      "^ *-: *\\(0\\):Source:\\(.+\\)$"
 309      2 1 nil 0 nil
 310      (1 compilation-line-face prepend) (2 compilation-info-face prepend))
 311     (gcov-header
 312      "^ *-: *\\(0\\):\\(?:Object\\|Graph\\|Data\\|Runs\\|Programs\\):.+$"
 313      nil 1 nil 0 nil
 314      (1 compilation-line-face prepend))
 315     ;; Underlines over all lines of gcov output are too uncomfortable to read.
 316     ;; However, hyperlinks embedded in the lines are useful.
 317     ;; So I put default face on the lines; and then put
 318     ;; compilation-*-face by manually to eliminate the underlines.
 319     ;; The hyperlinks are still effective.
 320     (gcov-nomark
 321      "^ *-: *\\([1-9]\\|[0-9]\\{2,\\}\\):.*$"
 322      nil 1 nil 0 nil
 323      (0 'default t)
 324      (1 compilation-line-face prepend))
 325     (gcov-called-line
 326      "^ *\\([0-9]+\\): *\\([0-9]+\\):.*$"
 327      nil 2 nil 0 nil
 328      (0 'default t)
 329      (1 compilation-info-face prepend) (2 compilation-line-face prepend))
 330     (gcov-never-called
 331      "^ *\\(#####\\): *\\([0-9]+\\):.*$"
 332      nil 2 nil 2 nil
 333      (0 'default t)
 334      (1 compilation-error-face prepend) (2 compilation-line-face prepend))
 335     )
 336   "Alist of values for `compilation-error-regexp-alist'.")
 337
 338 (defcustom compilation-error-regexp-alist
 339   (mapcar 'car compilation-error-regexp-alist-alist)
 340   "Alist that specifies how to match errors in compiler output.
 341 On GNU and Unix, any string is a valid filename, so these
 342 matchers must make some common sense assumptions, which catch
 343 normal cases.  A shorter list will be lighter on resource usage.
 344
 345 Instead of an alist element, you can use a symbol, which is
 346 looked up in `compilation-error-regexp-alist-alist'.  You can see
 347 the predefined symbols and their effects in the file
 348 `etc/compilation.txt' (linked below if you are customizing this).
 349
 350 Each elt has the form (REGEXP FILE [LINE COLUMN TYPE HYPERLINK
 351 HIGHLIGHT...]).  If REGEXP matches, the FILE'th subexpression
 352 gives the file name, and the LINE'th subexpression gives the line
 353 number.  The COLUMN'th subexpression gives the column number on
 354 that line.
 355
 356 If FILE, LINE or COLUMN are nil or that index didn't match, that
 357 information is not present on the matched line.  In that case the
 358 file name is assumed to be the same as the previous one in the
 359 buffer, line number defaults to 1 and column defaults to
 360 beginning of line's indentation.
 361
 362 FILE can also have the form (FILE FORMAT...), where the FORMATs
 363 \(e.g. \"%s.c\") will be applied in turn to the recognized file
 364 name, until a file of that name is found.  Or FILE can also be a
 365 function that returns (FILENAME) or (RELATIVE-FILENAME . DIRNAME).
 366 In the former case, FILENAME may be relative or absolute.
 367
 368 LINE can also be of the form (LINE . END-LINE) meaning a range
 369 of lines.  COLUMN can also be of the form (COLUMN . END-COLUMN)
 370 meaning a range of columns starting on LINE and ending on
 371 END-LINE, if that matched.
 372
 373 TYPE is 2 or nil for a real error or 1 for warning or 0 for info.
 374 TYPE can also be of the form (WARNING . INFO).  In that case this
 375 will be equivalent to 1 if the WARNING'th subexpression matched
 376 or else equivalent to 0 if the INFO'th subexpression matched.
 377 See `compilation-error-face', `compilation-warning-face',
 378 `compilation-info-face' and `compilation-skip-threshold'.
 379
 380 What matched the HYPERLINK'th subexpression has `mouse-face' and
 381 `compilation-message-face' applied.  If this is nil, the text
 382 matched by the whole REGEXP becomes the hyperlink.
 383
 384 Additional HIGHLIGHTs as described under `font-lock-keywords' can
 385 be added."
 386   :type `(set :menu-tag "Pick"
 387               ,@(mapcar (lambda (elt)
 388                           (list 'const (car elt)))
 389                         compilation-error-regexp-alist-alist))
 390   :link `(file-link :tag "example file"
 391                     ,(expand-file-name "compilation.txt" data-directory))
 392   :group 'compilation)
 393
 394 (defvar compilation-directory nil
 395   "Directory to restore to when doing `recompile'.")
 396
 397 (defvar compilation-directory-matcher
 398   '("\\(?:Entering\\|Leavin\\(g\\)\\) directory `\\(.+\\)'$" (2 . 1))
 399   "A list for tracking when directories are entered or left.
 400 Nil means not to track directories, e.g. if all file names are absolute.  The
 401 first element is the REGEXP matching these messages.  It can match any number
 402 of variants, e.g. different languages.  The remaining elements are all of the
 403 form (DIR .  LEAVE).  If for any one of these the DIR'th subexpression
 404 matches, that is a directory name.  If LEAVE is nil or the corresponding
 405 LEAVE'th subexpression doesn't match, this message is about going into another
 406 directory.  If it does match anything, this message is about going back to the
 407 directory we were in before the last entering message.  If you change this,
 408 you may also want to change `compilation-page-delimiter'.")
 409
 410 (defvar compilation-page-delimiter
 411   "^\\(?:\f\\|.*\\(?:Entering\\|Leaving\\) directory `.+'\n\\)+"
 412   "Value of `page-delimiter' in Compilation mode.")
 413
 414 (defvar compilation-mode-font-lock-keywords
 415    '(;; configure output lines.
 416      ("^[Cc]hecking \\(?:[Ff]or \\|[Ii]f \\|[Ww]hether \\(?:to \\)?\\)?\\(.+\\)\\.\\.\\. *\\(?:(cached) *\\)?\\(\\(yes\\(?: .+\\)?\\)\\|no\\|\\(.*\\)\\)$"
 417       (1 font-lock-variable-name-face)
 418       (2 (compilation-face '(4 . 3))))
 419      ;; Command output lines.  Recognize `make[n]:' lines too.
 420      ("^\\([[:alnum:]_/.+-]+\\)\\(\\[\\([0-9]+\\)\\]\\)?[ \t]*:"
 421       (1 font-lock-function-name-face) (3 compilation-line-face nil t))
 422      (" --?o\\(?:utfile\\|utput\\)?[= ]?\\(\\S +\\)" . 1)
 423      ("^Compilation \\(finished\\).*"
 424       (0 '(face nil message nil help-echo nil mouse-face nil) t)
 425       (1 compilation-info-face))
 426      ("^Compilation \\(exited abnormally\\|interrupt\\|killed\\|terminated\\|segmentation fault\\)\\(?:.*with code \\([0-9]+\\)\\)?.*"
 427       (0 '(face nil message nil help-echo nil mouse-face nil) t)
 428       (1 compilation-error-face)
 429       (2 compilation-error-face nil t)))
 430    "Additional things to highlight in Compilation mode.
 431 This gets tacked on the end of the generated expressions.")
 432
 433 (defvar compilation-highlight-regexp t
 434   "Regexp matching part of visited source lines to highlight temporarily.
 435 Highlight entire line if t; don't highlight source lines if nil.")
 436
 437 (defvar compilation-highlight-overlay nil
 438   "Overlay used to temporarily highlight compilation matches.")
 439
 440 (defcustom compilation-error-screen-columns t
 441   "*If non-nil, column numbers in error messages are screen columns.
 442 Otherwise they are interpreted as character positions, with
 443 each character occupying one column.
 444 The default is to use screen columns, which requires that the compilation
 445 program and Emacs agree about the display width of the characters,
 446 especially the TAB character."
 447   :type 'boolean
 448   :group 'compilation
 449   :version "20.4")
 450
 451 (defcustom compilation-read-command t
 452   "*Non-nil means \\[compile] reads the compilation command to use.
 453 Otherwise, \\[compile] just uses the value of `compile-command'."
 454   :type 'boolean
 455   :group 'compilation)
 456
 457 ;;;###autoload
 458 (defcustom compilation-ask-about-save t
 459   "*Non-nil means \\[compile] asks which buffers to save before compiling.
 460 Otherwise, it saves all modified buffers without asking."
 461   :type 'boolean
 462   :group 'compilation)
 463
 464 ;;;###autoload
 465 (defcustom compilation-search-path '(nil)
 466   "*List of directories to search for source files named in error messages.
 467 Elements should be directory names, not file names of directories.
 468 nil as an element means to try the default directory."
 469   :type '(repeat (choice (const :tag "Default" nil)
 470                          (string :tag "Directory")))
 471   :group 'compilation)
 472
 473 ;;;###autoload
 474 (defcustom compile-command "make -k "
 475   "*Last shell command used to do a compilation; default for next compilation.
 476
 477 Sometimes it is useful for files to supply local values for this variable.
 478 You might also use mode hooks to specify it in certain modes, like this:
 479
 480     (add-hook 'c-mode-hook
 481        (lambda ()
 482          (unless (or (file-exists-p \"makefile\")
 483                      (file-exists-p \"Makefile\"))
 484            (set (make-local-variable 'compile-command)
 485                 (concat \"make -k \"
 486                         (file-name-sans-extension buffer-file-name))))))"
 487   :type 'string
 488   :group 'compilation)
 489 ;;;###autoload(put 'compile-command 'safe-local-variable 'stringp)
 490
 491 ;;;###autoload
 492 (defcustom compilation-disable-input nil
 493   "*If non-nil, send end-of-file as compilation process input.
 494 This only affects platforms that support asynchronous processes (see
 495 `start-process'); synchronous compilation processes never accept input."
 496   :type 'boolean
 497   :group 'compilation
 498   :version "22.1")
 499
 500 ;; A weak per-compilation-buffer hash indexed by (FILENAME . DIRECTORY).  Each
 501 ;; value is a FILE-STRUCTURE as described above, with the car eq to the hash
 502 ;; key.  This holds the tree seen from root, for storing new nodes.
 503 (defvar compilation-locs ())
 504
 505 (defvar compilation-debug nil
 506   "*Set this to t before creating a *compilation* buffer.
 507 Then every error line will have a debug text property with the matcher that
 508 fit this line and the match data.  Use `describe-text-properties'.")
 509
 510 (defvar compilation-exit-message-function nil "\
 511 If non-nil, called when a compilation process dies to return a status message.
 512 This should be a function of three arguments: process status, exit status,
 513 and exit message; it returns a cons (MESSAGE . MODELINE) of the strings to
 514 write into the compilation buffer, and to put in its mode line.")
 515
 516 (defvar compilation-environment nil
 517   "*List of environment variables for compilation to inherit.
 518 Each element should be a string of the form ENVVARNAME=VALUE.
 519 This list is temporarily prepended to `process-environment' prior to
 520 starting the compilation process.")
 521
 522 ;; History of compile commands.
 523 (defvar compile-history nil)
 524
 525 (defface compilation-error
 526   '((t :inherit font-lock-warning-face))
 527   "Face used to highlight compiler errors."
 528   :group 'compilation
 529   :version "22.1")
 530
 531 (defface compilation-warning
 532   '((((class color) (min-colors 16)) (:foreground "Orange" :weight bold))
 533     (((class color)) (:foreground "cyan" :weight bold))
 534     (t (:weight bold)))
 535   "Face used to highlight compiler warnings."
 536   :group 'compilation
 537   :version "22.1")
 538
 539 (defface compilation-info
 540   '((((class color) (min-colors 16) (background light))
 541      (:foreground "Green3" :weight bold))
 542     (((class color) (min-colors 88) (background dark))
 543      (:foreground "Green1" :weight bold))
 544     (((class color) (min-colors 16) (background dark))
 545      (:foreground "Green" :weight bold))
 546     (((class color)) (:foreground "green" :weight bold))
 547     (t (:weight bold)))
 548   "Face used to highlight compiler information."
 549   :group 'compilation
 550   :version "22.1")
 551
 552 (defface compilation-line-number
 553   '((t :inherit font-lock-variable-name-face))
 554   "Face for displaying line numbers in compiler messages."
 555   :group 'compilation
 556   :version "22.1")
 557
 558 (defface compilation-column-number
 559   '((t :inherit font-lock-type-face))
 560   "Face for displaying column numbers in compiler messages."
 561   :group 'compilation
 562   :version "22.1")
 563
 564 (defcustom compilation-message-face 'underline
 565   "Face name to use for whole messages.
 566 Faces `compilation-error-face', `compilation-warning-face',
 567 `compilation-info-face', `compilation-line-face' and
 568 `compilation-column-face' get prepended to this, when applicable."
 569   :type 'face
 570   :group 'compilation
 571   :version "22.1")
 572
 573 (defvar compilation-error-face 'compilation-error
 574   "Face name to use for file name in error messages.")
 575
 576 (defvar compilation-warning-face 'compilation-warning
 577   "Face name to use for file name in warning messages.")
 578
 579 (defvar compilation-info-face 'compilation-info
 580   "Face name to use for file name in informational messages.")
 581
 582 (defvar compilation-line-face 'compilation-line-number
 583   "Face name to use for line numbers in compiler messages.")
 584
 585 (defvar compilation-column-face 'compilation-column-number
 586   "Face name to use for column numbers in compiler messages.")
 587
 588 ;; same faces as dired uses
 589 (defvar compilation-enter-directory-face 'font-lock-function-name-face
 590   "Face name to use for entering directory messages.")
 591
 592 (defvar compilation-leave-directory-face 'font-lock-type-face
 593   "Face name to use for leaving directory messages.")
 594
 595
 596
 597 ;; Used for compatibility with the old compile.el.
 598 (defvaralias 'compilation-last-buffer 'next-error-last-buffer)
 599 (defvar compilation-parsing-end (make-marker))
 600 (defvar compilation-parse-errors-function nil)
 601 (defvar compilation-error-list nil)
 602 (defvar compilation-old-error-list nil)
 603
 604 (defun compilation-face (type)
 605   (or (and (car type) (match-end (car type)) compilation-warning-face)
 606       (and (cdr type) (match-end (cdr type)) compilation-info-face)
 607       compilation-error-face))
 608
 609 ;; Internal function for calculating the text properties of a directory
 610 ;; change message.  The directory property is important, because it is
 611 ;; the stack of nested enter-messages.  Relative filenames on the following
 612 ;; lines are relative to the top of the stack.
 613 (defun compilation-directory-properties (idx leave)
 614   (if leave (setq leave (match-end leave)))
 615   ;; find previous stack, and push onto it, or if `leave' pop it
 616   (let ((dir (previous-single-property-change (point) 'directory)))
 617     (setq dir (if dir (or (get-text-property (1- dir) 'directory)
 618                           (get-text-property dir 'directory))))
 619     `(face ,(if leave
 620                 compilation-leave-directory-face
 621               compilation-enter-directory-face)
 622       directory ,(if leave
 623                      (or (cdr dir)
 624                          '(nil))        ; nil only isn't a property-change
 625                    (cons (match-string-no-properties idx) dir))
 626       mouse-face highlight
 627       keymap compilation-button-map
 628       help-echo "mouse-2: visit this directory")))
 629
 630 ;; Data type `reverse-ordered-alist' retriever.  This function retrieves the
 631 ;; KEY element from the ALIST, creating it in the right position if not already
 632 ;; present. ALIST structure is
 633 ;; '(ANCHOR (KEY1 ...) (KEY2 ...)... (KEYn ALIST ...))
 634 ;; ANCHOR is ignored, but necessary so that elements can be inserted.  KEY1
 635 ;; may be nil.  The other KEYs are ordered backwards so that growing line
 636 ;; numbers can be inserted in front and searching can abort after half the
 637 ;; list on average.
 638 (eval-when-compile                  ;Don't keep it at runtime if not needed.
 639 (defmacro compilation-assq (key alist)
 640   `(let* ((l1 ,alist)
 641           (l2 (cdr l1)))
 642      (car (if (if (null ,key)
 643                   (if l2 (null (caar l2)))
 644                 (while (if l2 (if (caar l2) (< ,key (caar l2)) t))
 645                   (setq l1 l2
 646                         l2 (cdr l1)))
 647                 (if l2 (eq ,key (caar l2))))
 648               l2
 649             (setcdr l1 (cons (list ,key) l2)))))))
 650
 651
 652 ;; This function is the central driver, called when font-locking to gather
 653 ;; all information needed to later jump to corresponding source code.
 654 ;; Return a property list with all meta information on this error location.
 655
 656 (defun compilation-error-properties (file line end-line col end-col type fmt)
 657   (unless (< (next-single-property-change (match-beginning 0) 'directory nil (point))
 658              (point))
 659     (if file
 660         (if (functionp file)
 661             (setq file (funcall file))
 662           (let (dir)
 663             (setq file (match-string-no-properties file))
 664             (unless (file-name-absolute-p file)
 665               (setq dir (previous-single-property-change (point) 'directory)
 666                     dir (if dir (or (get-text-property (1- dir) 'directory)
 667                                     (get-text-property dir 'directory)))))
 668             (setq file (cons file (car dir)))))
 669       ;; This message didn't mention one, get it from previous
 670       (let ((prev-pos
 671              ;; Find the previous message.
 672              (previous-single-property-change (point) 'message)))
 673         (if prev-pos
 674             ;; Get the file structure that belongs to it.
 675             (let* ((prev
 676                     (or (get-text-property (1- prev-pos) 'message)
 677                         (get-text-property prev-pos 'message)))
 678                    (prev-struct
 679                     (car (nth 2 (car prev)))))
 680               ;; Construct FILE . DIR from that.
 681               (if prev-struct
 682                   (setq file (cons (car prev-struct)
 683                                    (cadr prev-struct))))))
 684         (unless file
 685           (setq file '("*unknown*")))))
 686     ;; All of these fields are optional, get them only if we have an index, and
 687     ;; it matched some part of the message.
 688     (and line
 689          (setq line (match-string-no-properties line))
 690          (setq line (string-to-number line)))
 691     (and end-line
 692          (setq end-line (match-string-no-properties end-line))
 693          (setq end-line (string-to-number end-line)))
 694     (if col
 695         (if (functionp col)
 696             (setq col (funcall col))
 697           (and
 698            (setq col (match-string-no-properties col))
 699            (setq col (- (string-to-number col) compilation-first-column)))))
 700     (if (and end-col (functionp end-col))
 701         (setq end-col (funcall end-col))
 702       (if (and end-col (setq end-col (match-string-no-properties end-col)))
 703           (setq end-col (- (string-to-number end-col) compilation-first-column -1))
 704         (if end-line (setq end-col -1))))
 705     (if (consp type)                    ; not a static type, check what it is.
 706         (setq type (or (and (car type) (match-end (car type)) 1)
 707                        (and (cdr type) (match-end (cdr type)) 0)
 708                        2)))
 709     (compilation-internal-error-properties file line end-line col end-col type fmt)))
 710
 711 (defun compilation-move-to-column (col screen)
 712   "Go to column COL on the current line.
 713 If SCREEN is non-nil, columns are screen columns, otherwise, they are
 714 just char-counts."
 715   (if screen
 716       (move-to-column col)
 717     (goto-char (min (+ (line-beginning-position) col) (line-end-position)))))
 718
 719 (defun compilation-internal-error-properties (file line end-line col end-col type fmts)
 720   "Get the meta-info that will be added as text-properties.
 721 LINE, END-LINE, COL, END-COL are integers or nil.
 722 TYPE can be 0, 1, or 2, meaning error, warning, or just info.
 723 FILE should be (FILENAME) or (RELATIVE-FILENAME . DIRNAME) or nil.
 724 FMTS is a list of format specs for transforming the file name.
 725  (See `compilation-error-regexp-alist'.)"
 726   (unless file (setq file '("*unknown*")))
 727   (let* ((file-struct (compilation-get-file-structure file fmts))
 728          ;; Get first already existing marker (if any has one, all have one).
 729          ;; Do this first, as the compilation-assq`s may create new nodes.
 730          (marker-line (car (cddr file-struct))) ; a line structure
 731          (marker (nth 3 (cadr marker-line)))    ; its marker
 732          (compilation-error-screen-columns compilation-error-screen-columns)
 733          end-marker loc end-loc)
 734     (if (not (and marker (marker-buffer marker)))
 735         (setq marker nil)               ; no valid marker for this file
 736       (setq loc (or line 1))            ; normalize no linenumber to line 1
 737       (catch 'marker                    ; find nearest loc, at least one exists
 738         (dolist (x (nthcdr 3 file-struct))      ; loop over remaining lines
 739           (if (> (car x) loc)           ; still bigger
 740               (setq marker-line x)
 741             (if (> (- (or (car marker-line) 1) loc)
 742                    (- loc (car x)))     ; current line is nearer
 743                 (setq marker-line x))
 744             (throw 'marker t))))
 745       (setq marker (nth 3 (cadr marker-line))
 746             marker-line (or (car marker-line) 1))
 747       (with-current-buffer (marker-buffer marker)
 748         (save-excursion
 749           (save-restriction
 750             (widen)
 751             (goto-char (marker-position marker))
 752             (when (or end-col end-line)
 753               (beginning-of-line (- (or end-line line) marker-line -1))
 754               (if (or (null end-col) (< end-col 0))
 755                   (end-of-line)
 756                 (compilation-move-to-column
 757                  end-col compilation-error-screen-columns))
 758               (setq end-marker (list (point-marker))))
 759             (beginning-of-line (if end-line
 760                                    (- line end-line -1)
 761                                  (- loc marker-line -1)))
 762             (if col
 763                 (compilation-move-to-column
 764                  col compilation-error-screen-columns)
 765               (forward-to-indentation 0))
 766             (setq marker (list (point-marker)))))))
 767
 768     (setq loc (compilation-assq line (cdr file-struct)))
 769     (if end-line
 770         (setq end-loc (compilation-assq end-line (cdr file-struct))
 771               end-loc (compilation-assq end-col end-loc))
 772       (if end-col                       ; use same line element
 773           (setq end-loc (compilation-assq end-col loc))))
 774     (setq loc (compilation-assq col loc))
 775     ;; If they are new, make the loc(s) reference the file they point to.
 776     (or (cdr loc) (setcdr loc `(,line ,file-struct ,@marker)))
 777     (if end-loc
 778         (or (cdr end-loc)
 779             (setcdr end-loc `(,(or end-line line) ,file-struct ,@end-marker))))
 780
 781     ;; Must start with face
 782     `(face ,compilation-message-face
 783            message (,loc ,type ,end-loc)
 784            ,@(if compilation-debug
 785                  `(debug (,(assoc (with-no-warnings matcher) font-lock-keywords)
 786                           ,@(match-data))))
 787            help-echo ,(if col
 788                           "mouse-2: visit this file, line and column"
 789                         (if line
 790                             "mouse-2: visit this file and line"
 791                           "mouse-2: visit this file"))
 792            keymap compilation-button-map
 793            mouse-face highlight)))
 794
 795 (defun compilation-mode-font-lock-keywords ()
 796   "Return expressions to highlight in Compilation mode."
 797   (if compilation-parse-errors-function
 798       ;; An old package!  Try the compatibility code.
 799       '((compilation-compat-parse-errors))
 800     (append
 801      ;; make directory tracking
 802      (if compilation-directory-matcher
 803          `((,(car compilation-directory-matcher)
 804             ,@(mapcar (lambda (elt)
 805                         `(,(car elt)
 806                           (compilation-directory-properties
 807                            ,(car elt) ,(cdr elt))
 808                           t t))
 809                       (cdr compilation-directory-matcher)))))
 810
 811      ;; Compiler warning/error lines.
 812      (mapcar
 813       (lambda (item)
 814         (if (symbolp item)
 815             (setq item (cdr (assq item
 816                                   compilation-error-regexp-alist-alist))))
 817         (let ((file (nth 1 item))
 818               (line (nth 2 item))
 819               (col (nth 3 item))
 820               (type (nth 4 item))
 821               end-line end-col fmt)
 822           (if (consp file)      (setq fmt (cdr file)      file (car file)))
 823           (if (consp line)      (setq end-line (cdr line) line (car line)))
 824           (if (consp col)       (setq end-col (cdr col)   col (car col)))
 825
 826           (if (functionp line)
 827               ;; The old compile.el had here an undocumented hook that
 828               ;; allowed `line' to be a function that computed the actual
 829               ;; error location.  Let's do our best.
 830               `(,(car item)
 831                 (0 (save-match-data
 832                      (compilation-compat-error-properties
 833                       (funcall ',line (cons (match-string ,file)
 834                                             (cons default-directory
 835                                                   ',(nthcdr 4 item)))
 836                                ,(if col `(match-string ,col))))))
 837                 (,file compilation-error-face t))
 838
 839             (unless (or (null (nth 5 item)) (integerp (nth 5 item)))
 840               (error "HYPERLINK should be an integer: %s" (nth 5 item)))
 841
 842             `(,(nth 0 item)
 843
 844               ,@(when (integerp file)
 845                   `((,file ,(if (consp type)
 846                                 `(compilation-face ',type)
 847                               (aref [compilation-info-face
 848                                      compilation-warning-face
 849                                      compilation-error-face]
 850                                     (or type 2))))))
 851
 852               ,@(when line
 853                   `((,line compilation-line-face nil t)))
 854               ,@(when end-line
 855                   `((,end-line compilation-line-face nil t)))
 856
 857               ,@(when (integerp col)
 858                   `((,col compilation-column-face nil t)))
 859               ,@(when (integerp end-col)
 860                   `((,end-col compilation-column-face nil t)))
 861
 862               ,@(nthcdr 6 item)
 863               (,(or (nth 5 item) 0)
 864                (compilation-error-properties ',file ,line ,end-line
 865                                              ,col ,end-col ',(or type 2)
 866                                              ',fmt)
 867                append)))))              ; for compilation-message-face
 868       compilation-error-regexp-alist)
 869
 870      compilation-mode-font-lock-keywords)))
 871
 872 \f
 873 ;;;###autoload
 874 (defun compile (command &optional comint)
 875   "Compile the program including the current buffer.  Default: run `make'.
 876 Runs COMMAND, a shell command, in a separate process asynchronously
 877 with output going to the buffer `*compilation*'.
 878
 879 If optional second arg COMINT is t the buffer will be in Comint mode with
 880 `compilation-shell-minor-mode'.
 881
 882 You can then use the command \\[next-error] to find the next error message
 883 and move to the source code that caused it.
 884
 885 Interactively, prompts for the command if `compilation-read-command' is
 886 non-nil; otherwise uses `compile-command'.  With prefix arg, always prompts.
 887 Additionally, with universal prefix arg, compilation buffer will be in
 888 comint mode, i.e. interactive.
 889
 890 To run more than one compilation at once, start one and rename
 891 the \`*compilation*' buffer to some other name with
 892 \\[rename-buffer].  Then start the next one.  On most systems,
 893 termination of the main compilation process kills its
 894 subprocesses.
 895
 896 The name used for the buffer is actually whatever is returned by
 897 the function in `compilation-buffer-name-function', so you can set that
 898 to a function that generates a unique name."
 899   (interactive
 900    (list
 901     (let ((command (eval compile-command)))
 902       (if (or compilation-read-command current-prefix-arg)
 903           (read-from-minibuffer "Compile command: "
 904                                 command nil nil
 905                                 (if (equal (car compile-history) command)
 906                                     '(compile-history . 1)
 907                                   'compile-history))
 908         command))
 909     (consp current-prefix-arg)))
 910   (unless (equal command (eval compile-command))
 911     (setq compile-command command))
 912   (save-some-buffers (not compilation-ask-about-save) nil)
 913   (setq compilation-directory default-directory)
 914   (compilation-start command comint))
 915
 916 ;; run compile with the default command line
 917 (defun recompile ()
 918   "Re-compile the program including the current buffer.
 919 If this is run in a Compilation mode buffer, re-use the arguments from the
 920 original use.  Otherwise, recompile using `compile-command'."
 921   (interactive)
 922   (save-some-buffers (not compilation-ask-about-save) nil)
 923   (let ((default-directory
 924           (or (and (not (eq major-mode (nth 1 compilation-arguments)))
 925                    compilation-directory)
 926               default-directory)))
 927     (apply 'compilation-start (or compilation-arguments
 928                                   `(,(eval compile-command))))))
 929
 930 (defcustom compilation-scroll-output nil
 931   "*Non-nil to scroll the *compilation* buffer window as output appears.
 932
 933 Setting it causes the Compilation mode commands to put point at the
 934 end of their output window so that the end of the output is always
 935 visible rather than the beginning."
 936   :type 'boolean
 937   :version "20.3"
 938   :group 'compilation)
 939
 940
 941 (defun compilation-buffer-name (mode-name mode-command name-function)
 942   "Return the name of a compilation buffer to use.
 943 If NAME-FUNCTION is non-nil, call it with one argument MODE-NAME
 944 to determine the buffer name.
 945 Likewise if `compilation-buffer-name-function' is non-nil.
 946 If current buffer is the mode MODE-COMMAND,
 947 return the name of the current buffer, so that it gets reused.
 948 Otherwise, construct a buffer name from MODE-NAME."
 949   (cond (name-function
 950          (funcall name-function mode-name))
 951         (compilation-buffer-name-function
 952          (funcall compilation-buffer-name-function mode-name))
 953         ((and (eq mode-command major-mode)
 954               (eq major-mode (nth 1 compilation-arguments)))
 955          (buffer-name))
 956         (t
 957          (concat "*" (downcase mode-name) "*"))))
 958
 959 ;; This is a rough emulation of the old hack, until the transition to new
 960 ;; compile is complete.
 961 (defun compile-internal (command error-message
 962                                  &optional name-of-mode parser
 963                                  error-regexp-alist name-function
 964                                  enter-regexp-alist leave-regexp-alist
 965                                  file-regexp-alist nomessage-regexp-alist
 966                                  no-async highlight-regexp local-map)
 967   (if parser
 968       (error "Compile now works very differently, see `compilation-error-regexp-alist'"))
 969   (let ((compilation-error-regexp-alist
 970          (append file-regexp-alist (or error-regexp-alist
 971                                        compilation-error-regexp-alist)))
 972         (compilation-error (replace-regexp-in-string "^No more \\(.+\\)s\\.?"
 973                                                      "\\1" error-message)))
 974     (compilation-start command nil name-function highlight-regexp)))
 975 (make-obsolete 'compile-internal 'compilation-start)
 976
 977 ;;;###autoload
 978 (defun compilation-start (command &optional mode name-function highlight-regexp)
 979   "Run compilation command COMMAND (low level interface).
 980 If COMMAND starts with a cd command, that becomes the `default-directory'.
 981 The rest of the arguments are optional; for them, nil means use the default.
 982
 983 MODE is the major mode to set in the compilation buffer.  Mode
 984 may also be t meaning use `compilation-shell-minor-mode' under `comint-mode'.
 985 If NAME-FUNCTION is non-nil, call it with one argument (the mode name)
 986 to determine the buffer name.
 987
 988 If HIGHLIGHT-REGEXP is non-nil, `next-error' will temporarily highlight
 989 the matching section of the visited source line; the default is to use the
 990 global value of `compilation-highlight-regexp'.
 991
 992 Returns the compilation buffer created."
 993   (or mode (setq mode 'compilation-mode))
 994   (let* ((name-of-mode
 995           (if (eq mode t)
 996               (prog1 "compilation" (require 'comint))
 997             (replace-regexp-in-string "-mode$" "" (symbol-name mode))))
 998          (thisdir default-directory)
 999          outwin outbuf)
1000     (with-current-buffer
1001         (setq outbuf
1002               (get-buffer-create
1003                (compilation-buffer-name name-of-mode mode name-function)))
1004       (let ((comp-proc (get-buffer-process (current-buffer))))
1005         (if comp-proc
1006             (if (or (not (eq (process-status comp-proc) 'run))
1007                     (yes-or-no-p
1008                      (format "A %s process is running; kill it? "
1009                              name-of-mode)))
1010                 (condition-case ()
1011                     (progn
1012                       (interrupt-process comp-proc)
1013                       (sit-for 1)
1014                       (delete-process comp-proc))
1015                   (error nil))
1016               (error "Cannot have two processes in `%s' at once"
1017                      (buffer-name)))))
1018       (buffer-disable-undo (current-buffer))
1019       ;; first transfer directory from where M-x compile was called
1020       (setq default-directory thisdir)
1021       ;; Make compilation buffer read-only.  The filter can still write it.
1022       ;; Clear out the compilation buffer.
1023       (let ((inhibit-read-only t)
1024             (default-directory thisdir))
1025         ;; Then evaluate a cd command if any, but don't perform it yet, else start-command
1026         ;; would do it again through the shell: (cd "..") AND sh -c "cd ..; make"
1027         (cd (if (string-match "^\\s *cd\\(?:\\s +\\(\\S +?\\)\\)?\\s *[;&\n]" command)
1028                 (if (match-end 1)
1029                     (substitute-env-vars (match-string 1 command))
1030                   "~")
1031               default-directory))
1032         (erase-buffer)
1033         ;; Select the desired mode.
1034         (if (not (eq mode t))
1035             (funcall mode)
1036           (setq buffer-read-only nil)
1037           (with-no-warnings (comint-mode))
1038           (compilation-shell-minor-mode))
1039         (if highlight-regexp
1040             (set (make-local-variable 'compilation-highlight-regexp)
1041                  highlight-regexp))
1042         ;; Output a mode setter, for saving and later reloading this buffer.
1043         (insert "-*- mode: " name-of-mode
1044                 "; default-directory: " (prin1-to-string default-directory)
1045                 " -*-\n"
1046                 (format "%s started at %s\n\n"
1047                         mode-name
1048                         (substring (current-time-string) 0 19))
1049                 command "\n")
1050         (setq thisdir default-directory))
1051       (set-buffer-modified-p nil))
1052     ;; If we're already in the compilation buffer, go to the end
1053     ;; of the buffer, so point will track the compilation output.
1054     (if (eq outbuf (current-buffer))
1055         (goto-char (point-max)))
1056     ;; Pop up the compilation buffer.
1057     (setq outwin (display-buffer outbuf nil t))
1058     (with-current-buffer outbuf
1059       (let ((process-environment
1060              (append
1061               compilation-environment
1062               (if (if (boundp 'system-uses-terminfo) ; `if' for compiler warning
1063                       system-uses-terminfo)
1064                   (list "TERM=dumb" "TERMCAP="
1065                         (format "COLUMNS=%d" (window-width)))
1066                 (list "TERM=emacs"
1067                       (format "TERMCAP=emacs:co#%d:tc=unknown:"
1068                               (window-width))))
1069               ;; Set the EMACS variable, but
1070               ;; don't override users' setting of $EMACS.
1071               (unless (getenv "EMACS")
1072                 (list (concat "EMACS=" invocation-directory invocation-name)))
1073               (copy-sequence process-environment))))
1074         (set (make-local-variable 'compilation-arguments)
1075              (list command mode name-function highlight-regexp))
1076         (set (make-local-variable 'revert-buffer-function)
1077              'compilation-revert-buffer)
1078         (set-window-start outwin (point-min))
1079         (or (eq outwin (selected-window))
1080             (set-window-point outwin (if compilation-scroll-output
1081                                          (point)
1082                                        (point-min))))
1083         ;; The setup function is called before compilation-set-window-height
1084         ;; so it can set the compilation-window-height buffer locally.
1085         (if compilation-process-setup-function
1086             (funcall compilation-process-setup-function))
1087         (compilation-set-window-height outwin)
1088         ;; Start the compilation.
1089         (if (fboundp 'start-process)
1090             (let ((proc (if (eq mode t)
1091                             (get-buffer-process
1092                              (with-no-warnings
1093                               (comint-exec outbuf (downcase mode-name)
1094                                            shell-file-name nil `("-c" ,command))))
1095                           (start-process-shell-command (downcase mode-name)
1096                                                        outbuf command))))
1097               ;; Make the buffer's mode line show process state.
1098               (setq mode-line-process '(":%s"))
1099               (set-process-sentinel proc 'compilation-sentinel)
1100               (set-process-filter proc 'compilation-filter)
1101               (set-marker (process-mark proc) (point) outbuf)
1102               (when compilation-disable-input
1103                 (condition-case nil
1104                     (process-send-eof proc)
1105                   ;; The process may have exited already.
1106                   (error nil)))
1107               (setq compilation-in-progress
1108                     (cons proc compilation-in-progress)))
1109           ;; No asynchronous processes available.
1110           (message "Executing `%s'..." command)
1111           ;; Fake modeline display as if `start-process' were run.
1112           (setq mode-line-process ":run")
1113           (force-mode-line-update)
1114           (sit-for 0)                   ; Force redisplay
1115           (let* ((buffer-read-only nil) ; call-process needs to modify outbuf
1116                  (status (call-process shell-file-name nil outbuf nil "-c"
1117                                        command)))
1118             (cond ((numberp status)
1119                    (compilation-handle-exit 'exit status
1120                                             (if (zerop status)
1121                                                 "finished\n"
1122                                               (format "\
1123 exited abnormally with code %d\n"
1124                                                       status))))
1125                   ((stringp status)
1126                    (compilation-handle-exit 'signal status
1127                                             (concat status "\n")))
1128                   (t
1129                    (compilation-handle-exit 'bizarre status status))))
1130           ;; Without async subprocesses, the buffer is not yet
1131           ;; fontified, so fontify it now.
1132           (let ((font-lock-verbose nil)) ; shut up font-lock messages
1133             (font-lock-fontify-buffer))
1134           (set-buffer-modified-p nil)
1135           (message "Executing `%s'...done" command)))
1136       ;; Now finally cd to where the shell started make/grep/...
1137       (setq default-directory thisdir))
1138     (if (buffer-local-value 'compilation-scroll-output outbuf)
1139         (save-selected-window
1140           (select-window outwin)
1141           (goto-char (point-max))))
1142     ;; Make it so the next C-x ` will use this buffer.
1143     (setq next-error-last-buffer outbuf)))
1144
1145 (defun compilation-set-window-height (window)
1146   "Set the height of WINDOW according to `compilation-window-height'."
1147   (let ((height (buffer-local-value 'compilation-window-height (window-buffer window))))
1148     (and height
1149          (= (window-width window) (frame-width (window-frame window)))
1150          ;; If window is alone in its frame, aside from a minibuffer,
1151          ;; don't change its height.
1152          (not (eq window (frame-root-window (window-frame window))))
1153          ;; Stef said that doing the saves in this order is safer:
1154          (save-excursion
1155            (save-selected-window
1156              (select-window window)
1157              (enlarge-window (- height (window-height))))))))
1158
1159 (defvar compilation-menu-map
1160   (let ((map (make-sparse-keymap "Errors")))
1161     (define-key map [stop-subjob]
1162       '("Stop Compilation" . kill-compilation))
1163     (define-key map [compilation-mode-separator2]
1164       '("----" . nil))
1165     (define-key map [compilation-first-error]
1166       '("First Error" . first-error))
1167     (define-key map [compilation-previous-error]
1168       '("Previous Error" . previous-error))
1169     (define-key map [compilation-next-error]
1170       '("Next Error" . next-error))
1171     map))
1172
1173 (defvar compilation-minor-mode-map
1174   (let ((map (make-sparse-keymap)))
1175     (define-key map [mouse-2] 'compile-goto-error)
1176     (define-key map [follow-link] 'mouse-face)
1177     (define-key map "\C-c\C-c" 'compile-goto-error)
1178     (define-key map "\C-m" 'compile-goto-error)
1179     (define-key map "\C-c\C-k" 'kill-compilation)
1180     (define-key map "\M-n" 'compilation-next-error)
1181     (define-key map "\M-p" 'compilation-previous-error)
1182     (define-key map "\M-{" 'compilation-previous-file)
1183     (define-key map "\M-}" 'compilation-next-file)
1184     ;; Set up the menu-bar
1185     (define-key map [menu-bar compilation]
1186       (cons "Errors" compilation-menu-map))
1187     map)
1188   "Keymap for `compilation-minor-mode'.")
1189
1190 (defvar compilation-shell-minor-mode-map
1191   (let ((map (make-sparse-keymap)))
1192     (define-key map "\M-\C-m" 'compile-goto-error)
1193     (define-key map "\M-\C-n" 'compilation-next-error)
1194     (define-key map "\M-\C-p" 'compilation-previous-error)
1195     (define-key map "\M-{" 'compilation-previous-file)
1196     (define-key map "\M-}" 'compilation-next-file)
1197     ;; Set up the menu-bar
1198     (define-key map [menu-bar compilation]
1199       (cons "Errors" compilation-menu-map))
1200     map)
1201   "Keymap for `compilation-shell-minor-mode'.")
1202
1203 (defvar compilation-button-map
1204   (let ((map (make-sparse-keymap)))
1205     (define-key map [mouse-2] 'compile-goto-error)
1206     (define-key map [follow-link] 'mouse-face)
1207     (define-key map "\C-m" 'compile-goto-error)
1208     map)
1209   "Keymap for compilation-message buttons.")
1210 (fset 'compilation-button-map compilation-button-map)
1211
1212 (defvar compilation-mode-map
1213   (let ((map (make-sparse-keymap)))
1214     ;; Don't inherit from compilation-minor-mode-map,
1215     ;; because that introduces a menu bar item we don't want.
1216     ;; That confuses C-down-mouse-3.
1217     (define-key map [mouse-2] 'compile-goto-error)
1218     (define-key map [follow-link] 'mouse-face)
1219     (define-key map "\C-c\C-c" 'compile-goto-error)
1220     (define-key map "\C-m" 'compile-goto-error)
1221     (define-key map "\C-c\C-k" 'kill-compilation)
1222     (define-key map "\M-n" 'compilation-next-error)
1223     (define-key map "\M-p" 'compilation-previous-error)
1224     (define-key map "\M-{" 'compilation-previous-file)
1225     (define-key map "\M-}" 'compilation-next-file)
1226     (define-key map "\t" 'compilation-next-error)
1227     (define-key map [backtab] 'compilation-previous-error)
1228
1229     (define-key map " " 'scroll-up)
1230     (define-key map "\^?" 'scroll-down)
1231     (define-key map "\C-c\C-f" 'next-error-follow-minor-mode)
1232
1233     ;; Set up the menu-bar
1234     (let ((submap (make-sparse-keymap "Compile")))
1235       (define-key map [menu-bar compilation]
1236         (cons "Compile" submap))
1237       (set-keymap-parent submap compilation-menu-map))
1238     (define-key map [menu-bar compilation compilation-separator2]
1239       '("----" . nil))
1240     (define-key map [menu-bar compilation compilation-grep]
1241       '("Search Files (grep)..." . grep))
1242     (define-key map [menu-bar compilation compilation-recompile]
1243       '("Recompile" . recompile))
1244     (define-key map [menu-bar compilation compilation-compile]
1245       '("Compile..." . compile))
1246     map)
1247   "Keymap for compilation log buffers.
1248 `compilation-minor-mode-map' is a parent of this.")
1249
1250 (put 'compilation-mode 'mode-class 'special)
1251
1252 (defvar compilation-skip-to-next-location t
1253   "*If non-nil, skip multiple error messages for the same source location.")
1254
1255 (defcustom compilation-skip-threshold 1
1256   "*Compilation motion commands skip less important messages.
1257 The value can be either 2 -- skip anything less than error, 1 --
1258 skip anything less than warning or 0 -- don't skip any messages.
1259 Note that all messages not positively identified as warning or
1260 info, are considered errors."
1261   :type '(choice (const :tag "Warnings and info" 2)
1262                  (const :tag "Info" 1)
1263                  (const :tag "None" 0))
1264   :group 'compilation
1265   :version "22.1")
1266
1267 (defcustom compilation-skip-visited nil
1268   "*Compilation motion commands skip visited messages if this is t.
1269 Visited messages are ones for which the file, line and column have been jumped
1270 to from the current content in the current compilation buffer, even if it was
1271 from a different message."
1272   :type 'boolean
1273   :group 'compilation
1274   :version "22.1")
1275
1276 ;;;###autoload
1277 (defun compilation-mode (&optional name-of-mode)
1278   "Major mode for compilation log buffers.
1279 \\<compilation-mode-map>To visit the source for a line-numbered error,
1280 move point to the error message line and type \\[compile-goto-error].
1281 To kill the compilation, type \\[kill-compilation].
1282
1283 Runs `compilation-mode-hook' with `run-mode-hooks' (which see).
1284
1285 \\{compilation-mode-map}"
1286   (interactive)
1287   (kill-all-local-variables)
1288   (use-local-map compilation-mode-map)
1289   (setq major-mode 'compilation-mode
1290         mode-name (or name-of-mode "Compilation"))
1291   (set (make-local-variable 'page-delimiter)
1292        compilation-page-delimiter)
1293   (compilation-setup)
1294   (setq buffer-read-only t)
1295   (run-mode-hooks 'compilation-mode-hook))
1296
1297 (defmacro define-compilation-mode (mode name doc &rest body)
1298   "This is like `define-derived-mode' without the PARENT argument.
1299 The parent is always `compilation-mode' and the customizable `compilation-...'
1300 variables are also set from the name of the mode you have chosen,
1301 by replacing the first word, e.g `compilation-scroll-output' from
1302 `grep-scroll-output' if that variable exists."
1303   (let ((mode-name (replace-regexp-in-string "-mode\\'" "" (symbol-name mode))))
1304     `(define-derived-mode ,mode compilation-mode ,name
1305        ,doc
1306        ,@(mapcar (lambda (v)
1307                    (setq v (cons v
1308                                  (intern-soft (replace-regexp-in-string
1309                                                "^compilation" mode-name
1310                                                (symbol-name v)))))
1311                    (and (cdr v)
1312                         (or (boundp (cdr v))
1313                             (if (boundp 'byte-compile-bound-variables)
1314                                 (memq (cdr v) byte-compile-bound-variables)))
1315                         `(set (make-local-variable ',(car v)) ,(cdr v))))
1316                  '(compilation-buffer-name-function
1317                    compilation-directory-matcher
1318                    compilation-error
1319                    compilation-error-regexp-alist
1320                    compilation-error-regexp-alist-alist
1321                    compilation-error-screen-columns
1322                    compilation-finish-function
1323                    compilation-finish-functions
1324                    compilation-first-column
1325                    compilation-mode-font-lock-keywords
1326                    compilation-page-delimiter
1327                    compilation-parse-errors-filename-function
1328                    compilation-process-setup-function
1329                    compilation-scroll-output
1330                    compilation-search-path
1331                    compilation-skip-threshold
1332                    compilation-window-height))
1333        ,@body)))
1334
1335 (defun compilation-revert-buffer (ignore-auto noconfirm)
1336   (if buffer-file-name
1337       (let (revert-buffer-function)
1338         (revert-buffer ignore-auto noconfirm))
1339     (if (or noconfirm (yes-or-no-p (format "Restart compilation? ")))
1340         (apply 'compilation-start compilation-arguments))))
1341
1342 (defvar compilation-current-error nil
1343   "Marker to the location from where the next error will be found.
1344 The global commands next/previous/first-error/goto-error use this.")
1345
1346 (defvar compilation-messages-start nil
1347   "Buffer position of the beginning of the compilation messages.
1348 If nil, use the beginning of buffer.")
1349
1350 ;; A function name can't be a hook, must be something with a value.
1351 (defconst compilation-turn-on-font-lock 'turn-on-font-lock)
1352
1353 (defun compilation-setup (&optional minor)
1354   "Prepare the buffer for the compilation parsing commands to work.
1355 Optional argument MINOR indicates this is called from
1356 `compilation-minor-mode'."
1357   (make-local-variable 'compilation-current-error)
1358   (make-local-variable 'compilation-messages-start)
1359   (make-local-variable 'compilation-error-screen-columns)
1360   (make-local-variable 'overlay-arrow-position)
1361   (set (make-local-variable 'overlay-arrow-string) "")
1362   (setq next-error-overlay-arrow-position nil)
1363   (add-hook 'kill-buffer-hook
1364             (lambda () (setq next-error-overlay-arrow-position nil)) nil t)
1365   ;; Note that compilation-next-error-function is for interfacing
1366   ;; with the next-error function in simple.el, and it's only
1367   ;; coincidentally named similarly to compilation-next-error.
1368   (setq next-error-function 'compilation-next-error-function)
1369   (set (make-local-variable 'font-lock-extra-managed-props)
1370        '(directory message help-echo mouse-face debug))
1371   (set (make-local-variable 'compilation-locs)
1372        (make-hash-table :test 'equal :weakness 'value))
1373   ;; lazy-lock would never find the message unless it's scrolled to.
1374   ;; jit-lock might fontify some things too late.
1375   (set (make-local-variable 'font-lock-support-mode) nil)
1376   (set (make-local-variable 'font-lock-maximum-size) nil)
1377   (if minor
1378       (let ((fld font-lock-defaults))
1379         (font-lock-add-keywords nil (compilation-mode-font-lock-keywords))
1380         (if font-lock-mode
1381             (if fld
1382                 (font-lock-fontify-buffer)
1383               (font-lock-change-mode)
1384               (turn-on-font-lock))
1385           (turn-on-font-lock)))
1386     (setq font-lock-defaults '(compilation-mode-font-lock-keywords t))
1387     ;; maybe defer font-lock till after derived mode is set up
1388     (run-mode-hooks 'compilation-turn-on-font-lock)))
1389
1390 ;;;###autoload
1391 (define-minor-mode compilation-shell-minor-mode
1392   "Toggle compilation shell minor mode.
1393 With arg, turn compilation mode on if and only if arg is positive.
1394 In this minor mode, all the error-parsing commands of the
1395 Compilation major mode are available but bound to keys that don't
1396 collide with Shell mode.  See `compilation-mode'.
1397 Turning the mode on runs the normal hook `compilation-shell-minor-mode-hook'."
1398   nil " Shell-Compile"
1399   :group 'compilation
1400   (if compilation-shell-minor-mode
1401       (compilation-setup t)
1402     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1403     (font-lock-fontify-buffer)))
1404
1405 ;;;###autoload
1406 (define-minor-mode compilation-minor-mode
1407   "Toggle compilation minor mode.
1408 With arg, turn compilation mode on if and only if arg is positive.
1409 In this minor mode, all the error-parsing commands of the
1410 Compilation major mode are available.  See `compilation-mode'.
1411 Turning the mode on runs the normal hook `compilation-minor-mode-hook'."
1412   nil " Compilation"
1413   :group 'compilation
1414   (if compilation-minor-mode
1415       (compilation-setup t)
1416     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1417     (font-lock-fontify-buffer)))
1418
1419 (defun compilation-handle-exit (process-status exit-status msg)
1420   "Write MSG in the current buffer and hack its mode-line-process."
1421   (let ((inhibit-read-only t)
1422         (status (if compilation-exit-message-function
1423                     (funcall compilation-exit-message-function
1424                              process-status exit-status msg)
1425                   (cons msg exit-status)))
1426         (omax (point-max))
1427         (opoint (point)))
1428     ;; Record where we put the message, so we can ignore it later on.
1429     (goto-char omax)
1430     (insert ?\n mode-name " " (car status))
1431     (if (and (numberp compilation-window-height)
1432              (zerop compilation-window-height))
1433         (message "%s" (cdr status)))
1434     (if (bolp)
1435         (forward-char -1))
1436     (insert " at " (substring (current-time-string) 0 19))
1437     (goto-char (point-max))
1438     ;; Prevent that message from being recognized as a compilation error.
1439     (add-text-properties omax (point)
1440                          (append '(compilation-handle-exit t) nil))
1441     (setq mode-line-process (format ":%s [%s]" process-status (cdr status)))
1442     ;; Force mode line redisplay soon.
1443     (force-mode-line-update)
1444     (if (and opoint (< opoint omax))
1445         (goto-char opoint))
1446     (with-no-warnings
1447       (if compilation-finish-function
1448           (funcall compilation-finish-function (current-buffer) msg)))
1449     (let ((functions compilation-finish-functions))
1450       (while functions
1451         (funcall (car functions) (current-buffer) msg)
1452         (setq functions (cdr functions))))))
1453
1454 ;; Called when compilation process changes state.
1455 (defun compilation-sentinel (proc msg)
1456   "Sentinel for compilation buffers."
1457   (if (memq (process-status proc) '(exit signal))
1458       (let ((buffer (process-buffer proc)))
1459         (if (null (buffer-name buffer))
1460             ;; buffer killed
1461             (set-process-buffer proc nil)
1462           (with-current-buffer buffer
1463             ;; Write something in the compilation buffer
1464             ;; and hack its mode line.
1465             (compilation-handle-exit (process-status proc)
1466                                      (process-exit-status proc)
1467                                      msg)
1468             ;; Since the buffer and mode line will show that the
1469             ;; process is dead, we can delete it now.  Otherwise it
1470             ;; will stay around until M-x list-processes.
1471             (delete-process proc)))
1472         (setq compilation-in-progress (delq proc compilation-in-progress)))))
1473
1474 (defun compilation-filter (proc string)
1475   "Process filter for compilation buffers.
1476 Just inserts the text, but uses `insert-before-markers'."
1477   (if (buffer-name (process-buffer proc))
1478       (with-current-buffer (process-buffer proc)
1479         (let ((inhibit-read-only t))
1480           (save-excursion
1481             (goto-char (process-mark proc))
1482             (insert-before-markers string)
1483             (run-hooks 'compilation-filter-hook))))))
1484
1485 ;;; test if a buffer is a compilation buffer, assuming we're in the buffer
1486 (defsubst compilation-buffer-internal-p ()
1487   "Test if inside a compilation buffer."
1488   (local-variable-p 'compilation-locs))
1489
1490 ;;; test if a buffer is a compilation buffer, using compilation-buffer-internal-p
1491 (defsubst compilation-buffer-p (buffer)
1492   "Test if BUFFER is a compilation buffer."
1493   (with-current-buffer buffer
1494     (compilation-buffer-internal-p)))
1495
1496 (defmacro compilation-loop (< property-change 1+ error)
1497   `(while (,< n 0)
1498       (or (setq pt (,property-change pt 'message))
1499           (error ,error compilation-error))
1500       ;; prop 'message usually has 2 changes, on and off, so re-search if off
1501       (or (setq msg (get-text-property pt 'message))
1502           (if (setq pt (,property-change pt 'message))
1503               (setq msg (get-text-property pt 'message)))
1504           (error ,error compilation-error))
1505       (or (< (cadr msg) compilation-skip-threshold)
1506           (if different-file
1507               (eq (prog1 last (setq last (nth 2 (car msg))))
1508                   last))
1509           (if compilation-skip-visited
1510               (nthcdr 4 (car msg)))
1511           (if compilation-skip-to-next-location
1512               (eq (car msg) loc))
1513           ;; count this message only if none of the above are true
1514           (setq n (,1+ n)))))
1515
1516 (defun compilation-next-error (n &optional different-file pt)
1517   "Move point to the next error in the compilation buffer.
1518 Prefix arg N says how many error messages to move forwards (or
1519 backwards, if negative).
1520 Does NOT find the source line like \\[next-error]."
1521   (interactive "p")
1522   (or (compilation-buffer-p (current-buffer))
1523       (error "Not in a compilation buffer"))
1524   (or pt (setq pt (point)))
1525   (let* ((msg (get-text-property pt 'message))
1526          (loc (car msg))
1527          last)
1528     (if (zerop n)
1529         (unless (or msg                 ; find message near here
1530                     (setq msg (get-text-property (max (1- pt) (point-min))
1531                                                  'message)))
1532           (setq pt (previous-single-property-change pt 'message nil
1533                                                     (line-beginning-position)))
1534           (unless (setq msg (get-text-property (max (1- pt) (point-min)) 'message))
1535             (setq pt (next-single-property-change pt 'message nil
1536                                                   (line-end-position)))
1537             (or (setq msg (get-text-property pt 'message))
1538                 (setq pt (point)))))
1539       (setq last (nth 2 (car msg)))
1540       (if (>= n 0)
1541           (compilation-loop > next-single-property-change 1-
1542                             (if (get-buffer-process (current-buffer))
1543                                 "No more %ss yet"
1544                               "Moved past last %s"))
1545         ;; Don't move "back" to message at or before point.
1546         ;; Pass an explicit (point-min) to make sure pt is non-nil.
1547         (setq pt (previous-single-property-change pt 'message nil (point-min)))
1548         (compilation-loop < previous-single-property-change 1+
1549                           "Moved back before first %s")))
1550     (goto-char pt)
1551     (or msg
1552         (error "No %s here" compilation-error))))
1553
1554 (defun compilation-previous-error (n)
1555   "Move point to the previous error in the compilation buffer.
1556 Prefix arg N says how many error messages to move backwards (or
1557 forwards, if negative).
1558 Does NOT find the source line like \\[previous-error]."
1559   (interactive "p")
1560   (compilation-next-error (- n)))
1561
1562 (defun compilation-next-file (n)
1563   "Move point to the next error for a different file than the current one.
1564 Prefix arg N says how many files to move forwards (or backwards, if negative)."
1565   (interactive "p")
1566   (compilation-next-error n t))
1567
1568 (defun compilation-previous-file (n)
1569   "Move point to the previous error for a different file than the current one.
1570 Prefix arg N says how many files to move backwards (or forwards, if negative)."
1571   (interactive "p")
1572   (compilation-next-file (- n)))
1573
1574 (defun kill-compilation ()
1575   "Kill the process made by the \\[compile] or \\[grep] commands."
1576   (interactive)
1577   (let ((buffer (compilation-find-buffer)))
1578     (if (get-buffer-process buffer)
1579         (interrupt-process (get-buffer-process buffer))
1580       (error "The %s process is not running" (downcase mode-name)))))
1581
1582 (defalias 'compile-mouse-goto-error 'compile-goto-error)
1583
1584 (defun compile-goto-error (&optional event)
1585   "Visit the source for the error message at point.
1586 Use this command in a compilation log buffer.  Sets the mark at point there."
1587   (interactive (list last-input-event))
1588   (if event (posn-set-point (event-end event)))
1589   (or (compilation-buffer-p (current-buffer))
1590       (error "Not in a compilation buffer"))
1591   (if (get-text-property (point) 'directory)
1592       (dired-other-window (car (get-text-property (point) 'directory)))
1593     (push-mark)
1594     (setq compilation-current-error (point))
1595     (next-error-internal)))
1596
1597 ;; Return a compilation buffer.
1598 ;; If the current buffer is a compilation buffer, return it.
1599 ;; Otherwise, look for a compilation buffer and signal an error
1600 ;; if there are none.
1601 (defun compilation-find-buffer (&optional avoid-current)
1602   (next-error-find-buffer avoid-current 'compilation-buffer-internal-p))
1603
1604 ;;;###autoload
1605 (defun compilation-next-error-function (n &optional reset)
1606   "Advance to the next error message and visit the file where the error was.
1607 This is the value of `next-error-function' in Compilation buffers."
1608   (interactive "p")
1609   (when reset
1610     (setq compilation-current-error nil))
1611   (let* ((columns compilation-error-screen-columns) ; buffer's local value
1612          (last 1)
1613          (loc (compilation-next-error (or n 1) nil
1614                                       (or compilation-current-error
1615                                           compilation-messages-start
1616                                           (point-min))))
1617          (end-loc (nth 2 loc))
1618          (marker (point-marker)))
1619     (setq compilation-current-error (point-marker)
1620           overlay-arrow-position
1621             (if (bolp)
1622                 compilation-current-error
1623               (copy-marker (line-beginning-position)))
1624           loc (car loc))
1625     ;; If loc contains no marker, no error in that file has been visited.  If
1626     ;; the marker is invalid the buffer has been killed.  So, recalculate all
1627     ;; markers for that file.
1628     (unless (and (nth 3 loc) (marker-buffer (nth 3 loc)))
1629       (with-current-buffer (compilation-find-file marker (caar (nth 2 loc))
1630                                                   (cadr (car (nth 2 loc))))
1631         (save-restriction
1632           (widen)
1633           (goto-char (point-min))
1634           ;; Treat file's found lines in forward order, 1 by 1.
1635           (dolist (line (reverse (cddr (nth 2 loc))))
1636             (when (car line)            ; else this is a filename w/o a line#
1637               (beginning-of-line (- (car line) last -1))
1638               (setq last (car line)))
1639             ;; Treat line's found columns and store/update a marker for each.
1640             (dolist (col (cdr line))
1641               (if (car col)
1642                   (if (eq (car col) -1) ; special case for range end
1643                       (end-of-line)
1644                     (compilation-move-to-column (car col) columns))
1645                 (beginning-of-line)
1646                 (skip-chars-forward " \t"))
1647               (if (nth 3 col)
1648                   (set-marker (nth 3 col) (point))
1649                 (setcdr (nthcdr 2 col) `(,(point-marker)))))))))
1650     (compilation-goto-locus marker (nth 3 loc) (nth 3 end-loc))
1651     (setcdr (nthcdr 3 loc) t)))         ; Set this one as visited.
1652
1653 (defvar compilation-gcpro nil
1654   "Internal variable used to keep some values from being GC'd.")
1655 (make-variable-buffer-local 'compilation-gcpro)
1656
1657 (defun compilation-fake-loc (marker file &optional line col)
1658   "Preassociate MARKER with FILE.
1659 FILE should be ABSOLUTE-FILENAME or (RELATIVE-FILENAME . DIRNAME).
1660 This is useful when you compile temporary files, but want
1661 automatic translation of the messages to the real buffer from
1662 which the temporary file came.  This only works if done before a
1663 message about FILE appears!
1664
1665 Optional args LINE and COL default to 1 and beginning of
1666 indentation respectively.  The marker is expected to reflect
1667 this.  In the simplest case the marker points to the first line
1668 of the region that was saved to the temp file.
1669
1670 If you concatenate several regions into the temp file (e.g. a
1671 header with variable assignments and a code region), you must
1672 call this several times, once each for the last line of one
1673 region and the first line of the next region."
1674   (or (consp file) (setq file (list file)))
1675   (setq file (compilation-get-file-structure file))
1676   ;; Between the current call to compilation-fake-loc and the first occurrence
1677   ;; of an error message referring to `file', the data is only kept is the
1678   ;; weak hash-table compilation-locs, so we need to prevent this entry
1679   ;; in compilation-locs from being GC'd away.  --Stef
1680   (push file compilation-gcpro)
1681   (let ((loc (compilation-assq (or line 1) (cdr file))))
1682     (setq loc (compilation-assq col loc))
1683     (if (cdr loc)
1684         (setcdr (cddr loc) (list marker))
1685       (setcdr loc (list line file marker)))
1686     loc))
1687
1688 (defcustom compilation-context-lines nil
1689   "Display this many lines of leading context before the current message.
1690 If nil and the left fringe is displayed, don't scroll the
1691 compilation output window; an arrow in the left fringe points to
1692 the current message.  If nil and there is no left fringe, the message
1693 displays at the top of the window; there is no arrow."
1694   :type '(choice integer (const :tag "No window scrolling" nil))
1695   :group 'compilation
1696   :version "22.1")
1697
1698 (defsubst compilation-set-window (w mk)
1699   "Align the compilation output window W with marker MK near top."
1700   (if (integerp compilation-context-lines)
1701       (set-window-start w (save-excursion
1702                             (goto-char mk)
1703                             (beginning-of-line
1704                              (- 1 compilation-context-lines))
1705                             (point)))
1706     ;; If there is no left fringe.
1707     (if (equal (car (window-fringes)) 0)
1708         (set-window-start w (save-excursion
1709                               (goto-char mk)
1710                             (beginning-of-line 1)
1711                             (point)))))
1712     (set-window-point w mk))
1713
1714 (defvar next-error-highlight-timer)
1715
1716 (defun compilation-goto-locus (msg mk end-mk)
1717   "Jump to an error corresponding to MSG at MK.
1718 All arguments are markers.  If END-MK is non-nil, mark is set there
1719 and overlay is highlighted between MK and END-MK."
1720   ;; Show compilation buffer in other window, scrolled to this error.
1721   (let* ((from-compilation-buffer (eq (window-buffer (selected-window))
1722                                       (marker-buffer msg)))
1723          ;; Use an existing window if it is in a visible frame.
1724          (pre-existing (get-buffer-window (marker-buffer msg) 0))
1725          (w (if (and from-compilation-buffer pre-existing)
1726                 ;; Calling display-buffer here may end up (partly) hiding
1727                 ;; the error location if the two buffers are in two
1728                 ;; different frames.  So don't do it if it's not necessary.
1729                 pre-existing
1730               (let ((display-buffer-reuse-frames t)
1731                     (pop-up-windows t))
1732                 ;; Pop up a window.
1733                 (display-buffer (marker-buffer msg)))))
1734          (highlight-regexp (with-current-buffer (marker-buffer msg)
1735                              ;; also do this while we change buffer
1736                              (compilation-set-window w msg)
1737                              compilation-highlight-regexp)))
1738     ;; Ideally, the window-size should be passed to `display-buffer' (via
1739     ;; something like special-display-buffer) so it's only used when
1740     ;; creating a new window.
1741     (unless pre-existing (compilation-set-window-height w))
1742
1743     (if from-compilation-buffer
1744         ;; If the compilation buffer window was selected,
1745         ;; keep the compilation buffer in this window;
1746         ;; display the source in another window.
1747         (let ((pop-up-windows t))
1748           (pop-to-buffer (marker-buffer mk) 'other-window))
1749       (if (window-dedicated-p (selected-window))
1750           (pop-to-buffer (marker-buffer mk))
1751         (switch-to-buffer (marker-buffer mk))))
1752     ;; If narrowing gets in the way of going to the right place, widen.
1753     (unless (eq (goto-char mk) (point))
1754       (widen)
1755       (goto-char mk))
1756     (if end-mk
1757         (push-mark end-mk t)
1758       (if mark-active (setq mark-active)))
1759     ;; If hideshow got in the way of
1760     ;; seeing the right place, open permanently.
1761     (dolist (ov (overlays-at (point)))
1762       (when (eq 'hs (overlay-get ov 'invisible))
1763         (delete-overlay ov)
1764         (goto-char mk)))
1765
1766     (when highlight-regexp
1767       (if (timerp next-error-highlight-timer)
1768           (cancel-timer next-error-highlight-timer))
1769       (unless compilation-highlight-overlay
1770         (setq compilation-highlight-overlay
1771               (make-overlay (point-min) (point-min)))
1772         (overlay-put compilation-highlight-overlay 'face 'next-error))
1773       (with-current-buffer (marker-buffer mk)
1774         (save-excursion
1775           (if end-mk (goto-char end-mk) (end-of-line))
1776           (let ((end (point)))
1777             (if mk (goto-char mk) (beginning-of-line))
1778             (if (and (stringp highlight-regexp)
1779                      (re-search-forward highlight-regexp end t))
1780                 (progn
1781                   (goto-char (match-beginning 0))
1782                   (move-overlay compilation-highlight-overlay
1783                                 (match-beginning 0) (match-end 0)
1784                                 (current-buffer)))
1785               (move-overlay compilation-highlight-overlay
1786                             (point) end (current-buffer)))
1787             (if (or (eq next-error-highlight t)
1788                     (numberp next-error-highlight))
1789                 ;; We want highlighting: delete overlay on next input.
1790                 (add-hook 'pre-command-hook
1791                           'compilation-goto-locus-delete-o)
1792               ;; We don't want highlighting: delete overlay now.
1793               (delete-overlay compilation-highlight-overlay))
1794             ;; We want highlighting for a limited time:
1795             ;; set up a timer to delete it.
1796             (when (numberp next-error-highlight)
1797               (setq next-error-highlight-timer
1798                     (run-at-time next-error-highlight nil
1799                                  'compilation-goto-locus-delete-o)))))))
1800     (when (and (eq next-error-highlight 'fringe-arrow))
1801       ;; We want a fringe arrow (instead of highlighting).
1802       (setq next-error-overlay-arrow-position
1803             (copy-marker (line-beginning-position))))))
1804
1805 (defun compilation-goto-locus-delete-o ()
1806   (delete-overlay compilation-highlight-overlay)
1807   ;; Get rid of timer and hook that would try to do this again.
1808   (if (timerp next-error-highlight-timer)
1809       (cancel-timer next-error-highlight-timer))
1810   (remove-hook 'pre-command-hook
1811                'compilation-goto-locus-delete-o))
1812 \f
1813 (defun compilation-find-file (marker filename directory &rest formats)
1814   "Find a buffer for file FILENAME.
1815 Search the directories in `compilation-search-path'.
1816 A nil in `compilation-search-path' means to try the
1817 \"current\" directory, which is passed in DIRECTORY.
1818 If DIRECTORY. is relative, it is combined with `default-directory'.
1819 If DIRECTORY. is nil, that means use `default-directory'.
1820 If FILENAME is not found at all, ask the user where to find it.
1821 Pop up the buffer containing MARKER and scroll to MARKER if we ask the user."
1822   (or formats (setq formats '("%s")))
1823   (let ((dirs compilation-search-path)
1824         (spec-dir (if directory
1825                       (expand-file-name directory)
1826                     default-directory))
1827         buffer thisdir fmts name)
1828     (if (file-name-absolute-p filename)
1829         ;; The file name is absolute.  Use its explicit directory as
1830         ;; the first in the search path, and strip it from FILENAME.
1831         (setq filename (abbreviate-file-name (expand-file-name filename))
1832               dirs (cons (file-name-directory filename) dirs)
1833               filename (file-name-nondirectory filename)))
1834     ;; Now search the path.
1835     (while (and dirs (null buffer))
1836       (setq thisdir (or (car dirs) spec-dir)
1837             fmts formats)
1838       ;; For each directory, try each format string.
1839       (while (and fmts (null buffer))
1840         (setq name (expand-file-name (format (car fmts) filename) thisdir)
1841               buffer (and (file-exists-p name)
1842                           (find-file-noselect name))
1843               fmts (cdr fmts)))
1844       (setq dirs (cdr dirs)))
1845     (while (null buffer)    ;Repeat until the user selects an existing file.
1846       ;; The file doesn't exist.  Ask the user where to find it.
1847       (save-excursion            ;This save-excursion is probably not right.
1848         (let ((pop-up-windows t))
1849           (compilation-set-window (display-buffer (marker-buffer marker))
1850                                   marker)
1851           (let* ((name (read-file-name
1852                         (format "Find this %s in (default %s): "
1853                                 compilation-error filename)
1854                         spec-dir filename t nil
1855                         ;; Try to make sure the user can only select
1856                         ;; a valid answer.  This predicate may be ignored,
1857                         ;; tho, so we still have to double-check afterwards.
1858                         ;; TODO: We should probably fix read-file-name so
1859                         ;; that it never ignores this predicate, even when
1860                         ;; using popup dialog boxes.
1861                         (lambda (name)
1862                           (if (file-directory-p name)
1863                               (setq name (expand-file-name filename name)))
1864                           (file-exists-p name))))
1865                  (origname name))
1866             (cond
1867              ((not (file-exists-p name))
1868               (message "Cannot find file `%s'" name)
1869               (ding) (sit-for 2))
1870              ((and (file-directory-p name)
1871                    (not (file-exists-p
1872                          (setq name (expand-file-name filename name)))))
1873               (message "No `%s' in directory %s" filename origname)
1874               (ding) (sit-for 2))
1875              (t
1876               (setq buffer (find-file-noselect name))))))))
1877     ;; Make intangible overlays tangible.
1878     ;; This is weird: it's not even clear which is the current buffer,
1879     ;; so the code below can't be expected to DTRT here.  -- Stef
1880     (dolist (ov (overlays-in (point-min) (point-max)))
1881       (when (overlay-get ov 'intangible)
1882         (overlay-put ov 'intangible nil)))
1883     buffer))
1884
1885 (defun compilation-get-file-structure (file &optional fmt)
1886   "Retrieve FILE's file-structure or create a new one.
1887 FILE should be (FILENAME) or (RELATIVE-FILENAME . DIRNAME).
1888 In the former case, FILENAME may be relative or absolute.
1889
1890 The file-structure looks like this:
1891   (list (list FILENAME [DIR-FROM-PREV-MSG]) FMT LINE-STRUCT...)
1892 "
1893   (or (gethash file compilation-locs)
1894       ;; File was not previously encountered, at least not in the form passed.
1895       ;; Let's normalize it and look again.
1896       (let ((filename (car file))
1897             ;; Get the specified directory from FILE.
1898             (spec-directory (if (cdr file)
1899                                 (file-truename (cdr file)))))
1900
1901         ;; Check for a comint-file-name-prefix and prepend it if appropriate.
1902         ;; (This is very useful for compilation-minor-mode in an rlogin-mode
1903         ;; buffer.)
1904         (when (and (boundp 'comint-file-name-prefix)
1905                    (not (equal comint-file-name-prefix "")))
1906           (if (file-name-absolute-p filename)
1907               (setq filename
1908                     (concat comint-file-name-prefix filename))
1909             (if spec-directory
1910                 (setq spec-directory
1911                       (file-truename
1912                        (concat comint-file-name-prefix spec-directory))))))
1913
1914         ;; If compilation-parse-errors-filename-function is
1915         ;; defined, use it to process the filename.
1916         (when compilation-parse-errors-filename-function
1917           (setq filename
1918                 (funcall compilation-parse-errors-filename-function
1919                          filename)))
1920
1921         ;; Some compilers (e.g. Sun's java compiler, reportedly) produce bogus
1922         ;; file names like "./bar//foo.c" for file "bar/foo.c";
1923         ;; expand-file-name will collapse these into "/foo.c" and fail to find
1924         ;; the appropriate file.  So we look for doubled slashes in the file
1925         ;; name and fix them.
1926         (setq filename (command-line-normalize-file-name filename))
1927
1928         ;; Store it for the possibly unnormalized name
1929         (puthash file
1930                  ;; Retrieve or create file-structure for normalized name
1931                  (or (gethash (list filename) compilation-locs)
1932                      (puthash (list filename)
1933                               (list (list filename spec-directory) fmt)
1934                               compilation-locs))
1935                  compilation-locs))))
1936
1937 (add-to-list 'debug-ignored-errors "^No more [-a-z ]+s yet$")
1938
1939 ;;; Compatibility with the old compile.el.
1940
1941 (defun compile-buffer-substring (n) (if n (match-string n)))
1942
1943 (defun compilation-compat-error-properties (err)
1944   "Map old-style error ERR to new-style message."
1945   ;; Old-style structure is (MARKER (FILE DIR) LINE COL) or
1946   ;; (MARKER . MARKER).
1947   (let ((dst (cdr err)))
1948     (if (markerp dst)
1949         ;; Must start with a face, for font-lock.
1950         `(face nil
1951           message ,(list (list nil nil nil dst) 2)
1952           help-echo "mouse-2: visit the source location"
1953           keymap compilation-button-map
1954           mouse-face highlight)
1955       ;; Too difficult to do it by hand: dispatch to the normal code.
1956       (let* ((file (pop dst))
1957              (line (pop dst))
1958              (col (pop dst))
1959              (filename (pop file))
1960              (dirname (pop file))
1961              (fmt (pop file)))
1962         (compilation-internal-error-properties
1963          (cons filename dirname) line nil col nil 2 fmt)))))
1964
1965 (defun compilation-compat-parse-errors (limit)
1966   (when compilation-parse-errors-function
1967     ;; FIXME: We should remove the rest of the compilation keywords
1968     ;; but we can't do that from here because font-lock is using
1969     ;; the value right now.  --stef
1970     (save-excursion
1971       (setq compilation-error-list nil)
1972       ;; Reset compilation-parsing-end each time because font-lock
1973       ;; might force us the re-parse many times (typically because
1974       ;; some code adds some text-property to the output that we
1975       ;; already parsed).  You might say "why reparse", well:
1976       ;; because font-lock has just removed the `message' property so
1977       ;; have to do it all over again.
1978       (if compilation-parsing-end
1979           (set-marker compilation-parsing-end (point))
1980         (setq compilation-parsing-end (point-marker)))
1981       (condition-case nil
1982           ;; Ignore any error: we're calling this function earlier than
1983           ;; in the old compile.el so things might not all be setup yet.
1984           (funcall compilation-parse-errors-function limit nil)
1985         (error nil))
1986       (dolist (err (if (listp compilation-error-list) compilation-error-list))
1987         (let* ((src (car err))
1988                (dst (cdr err))
1989                (loc (cond ((markerp dst) (list nil nil nil dst))
1990                           ((consp dst)
1991                            (list (nth 2 dst) (nth 1 dst)
1992                                  (cons (cdar dst) (caar dst)))))))
1993           (when loc
1994             (goto-char src)
1995             ;; (put-text-property src (line-end-position) 'font-lock-face 'font-lock-warning-face)
1996             (put-text-property src (line-end-position)
1997                                'message (list loc 2)))))))
1998   (goto-char limit)
1999   nil)
2000
2001 ;; Beware: this is not only compatiblity code.  New code stil uses it.  --Stef
2002 (defun compilation-forget-errors ()
2003   ;; In case we hit the same file/line specs, we want to recompute a new
2004   ;; marker for them, so flush our cache.
2005   (setq compilation-locs (make-hash-table :test 'equal :weakness 'value))
2006   (setq compilation-gcpro nil)
2007   ;; FIXME: the old code reset the directory-stack, so maybe we should
2008   ;; put a `directory change' marker of some sort, but where?  -stef
2009   ;;
2010   ;; FIXME: The old code moved compilation-current-error (which was
2011   ;; virtually represented by a mix of compilation-parsing-end and
2012   ;; compilation-error-list) to point-min, but that was only meaningful for
2013   ;; the internal uses of compilation-forget-errors: all calls from external
2014   ;; packages seem to be followed by a move of compilation-parsing-end to
2015   ;; something equivalent to point-max.  So we speculatively move
2016   ;; compilation-current-error to point-max (since the external package
2017   ;; won't know that it should do it).  --stef
2018   (setq compilation-current-error nil)
2019   (let* ((proc (get-buffer-process (current-buffer)))
2020          (mark (if proc (process-mark proc)))
2021          (pos (or mark (point-max))))
2022     (setq compilation-messages-start
2023           ;; In the future, ignore the text already present in the buffer.
2024           ;; Since many process filter functions insert before markers,
2025           ;; we need to put ours just before the insertion point rather
2026           ;; than at the insertion point.  If that's not possible, then
2027           ;; don't use a marker.  --Stef
2028           (if (> pos (point-min)) (copy-marker (1- pos)) pos))))
2029
2030 ;;;###autoload
2031 (add-to-list 'auto-mode-alist '("\\.gcov\\'" . compilation-mode))
2032
2033 (provide 'compile)
2034
2035 ;; arch-tag: 12465727-7382-4f72-b234-79855a00dd8c
2036 ;;; compile.el ends here