code.delx.au - gnu-emacs/blob - lisp/server.el

   1 ;;; server.el --- Lisp code for GNU Emacs running as server process.
   2
   3 ;; Copyright (C) 1986, 1987, 1992, 1994, 1995 Free Software Foundation, Inc.
   4
   5 ;; Author: William Sommerfeld <wesommer@athena.mit.edu>
   6 ;; Keywords: processes
   7
   8 ;; Changes by peck@sun.com and by rms.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  24 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; This Lisp code is run in Emacs when it is to operate as
  29 ;;; a server for other processes.
  30
  31 ;;; Load this library and do M-x server-edit to enable Emacs as a server.
  32 ;;; Emacs runs the program ../arch-lib/emacsserver as a subprocess
  33 ;;; for communication with clients.  If there are no client buffers to edit,
  34 ;;; server-edit acts like (switch-to-buffer (other-buffer))
  35
  36 ;;; When some other program runs "the editor" to edit a file,
  37 ;;; "the editor" can be the Emacs client program ../lib-src/emacsclient.
  38 ;;; This program transmits the file names to Emacs through
  39 ;;; the server subprocess, and Emacs visits them and lets you edit them.
  40
  41 ;;; Note that any number of clients may dispatch files to emacs to be edited.
  42
  43 ;;; When you finish editing a Server buffer, again call server-edit
  44 ;;; to mark that buffer as done for the client and switch to the next
  45 ;;; Server buffer.  When all the buffers for a client have been edited
  46 ;;; and exited with server-edit, the client "editor" will return
  47 ;;; to the program that invoked it.
  48
  49 ;;; Your editing commands and Emacs's display output go to and from
  50 ;;; the terminal in the usual way.  Thus, server operation is possible
  51 ;;; only when Emacs can talk to the terminal at the time you invoke
  52 ;;; the client.  This is possible in four cases:
  53
  54 ;;; 1. On a window system, where Emacs runs in one window and the
  55 ;;; program that wants to use "the editor" runs in another.
  56
  57 ;;; 2. On a multi-terminal system, where Emacs runs on one terminal and the
  58 ;;; program that wants to use "the editor" runs on another.
  59
  60 ;;; 3. When the program that wants to use "the editor" is running
  61 ;;; as a subprocess of Emacs.
  62
  63 ;;; 4. On a system with job control, when Emacs is suspended, the program
  64 ;;; that wants to use "the editor" will stop and display
  65 ;;; "Waiting for Emacs...".  It can then be suspended, and Emacs can be
  66 ;;; brought into the foreground for editing.  When done editing, Emacs is
  67 ;;; suspended again, and the client program is brought into the foreground.
  68
  69 ;;; The buffer local variable "server-buffer-clients" lists
  70 ;;; the clients who are waiting for this buffer to be edited.
  71 ;;; The global variable "server-clients" lists all the waiting clients,
  72 ;;; and which files are yet to be edited for each.
  73
  74 ;;; Code:
  75 \f
  76 (defvar server-program (expand-file-name "emacsserver" exec-directory)
  77   "*The program to use as the edit server.")
  78
  79 (defvar server-visit-hook nil
  80   "*List of hooks to call when visiting a file for the Emacs server.")
  81
  82 (defvar server-switch-hook nil
  83   "*List of hooks to call when switching to a buffer for the Emacs server.")
  84
  85 (defvar server-done-hook nil
  86   "*List of hooks to call when done editing a buffer for the Emacs server.")
  87
  88 (defvar server-process nil
  89   "the current server process")
  90
  91 (defvar server-previous-string "")
  92
  93 (defvar server-clients nil
  94   "List of current server clients.
  95 Each element is (CLIENTID BUFFERS...) where CLIENTID is a string
  96 that can be given to the server process to identify a client.
  97 When a buffer is marked as \"done\", it is removed from this list.")
  98
  99 (defvar server-buffer-clients nil
 100   "List of clientids for clients requesting editing of current buffer.")
 101 (make-variable-buffer-local 'server-buffer-clients)
 102 ;; Changing major modes should not erase this local.
 103 (put 'server-buffer-clients 'permanent-local t)
 104
 105 (defvar server-window nil
 106   "*The window to use for selecting Emacs server buffers.
 107 If nil, use the selected window.
 108 If it is a frame, use the frame's selected window.")
 109
 110 (defvar server-temp-file-regexp "^/tmp/Re\\|/draft$"
 111   "*Regexp which should match filenames of temporary files
 112 which are deleted and reused after each edit
 113 by the programs that invoke the emacs server.")
 114
 115 (or (assq 'server-buffer-clients minor-mode-alist)
 116     (setq minor-mode-alist (cons '(server-buffer-clients " Server") minor-mode-alist)))
 117
 118 ;; If a *server* buffer exists,
 119 ;; write STRING to it for logging purposes.
 120 (defun server-log (string)
 121   (if (get-buffer "*server*")
 122       (save-excursion
 123         (set-buffer "*server*")
 124         (goto-char (point-max))
 125         (insert string)
 126         (or (bobp) (newline)))))
 127
 128 (defun server-sentinel (proc msg)
 129   (cond ((eq (process-status proc) 'exit)
 130          (server-log (message "Server subprocess exited")))
 131         ((eq (process-status proc) 'signal)
 132          (server-log (message "Server subprocess killed")))))
 133
 134 ;;;###autoload
 135 (defun server-start (&optional leave-dead)
 136   "Allow this Emacs process to be a server for client processes.
 137 This starts a server communications subprocess through which
 138 client \"editors\" can send your editing commands to this Emacs job.
 139 To use the server, set up the program `emacsclient' in the
 140 Emacs distribution as your standard \"editor\".
 141
 142 Prefix arg means just kill any existing server communications subprocess."
 143   (interactive "P")
 144   ;; kill it dead!
 145   (if server-process
 146       (progn
 147         (set-process-sentinel server-process nil)
 148         (condition-case () (delete-process server-process) (error nil))))
 149   (condition-case () (delete-file "~/.emacs_server") (error nil))
 150   (condition-case ()
 151       (delete-file (format "/tmp/esrv%d-%s" (user-uid) (system-name)))
 152     (error nil))
 153   ;; If we already had a server, clear out associated status.
 154   (while server-clients
 155     (let ((buffer (nth 1 (car server-clients))))
 156       (server-buffer-done buffer)))
 157   (if leave-dead
 158       nil
 159     (if server-process
 160         (server-log (message "Restarting server")))
 161     ;; Using a pty is wasteful, and the separate session causes
 162     ;; annoyance sometimes (some systems kill idle sessions).
 163     (let ((process-connection-type nil))
 164       (setq server-process (start-process "server" nil server-program)))
 165     (set-process-sentinel server-process 'server-sentinel)
 166     (set-process-filter server-process 'server-process-filter)
 167     (process-kill-without-query server-process)))
 168 \f
 169 ;Process a request from the server to edit some files.
 170 ;Format of STRING is "Client: CLIENTID PATH PATH PATH... \n"
 171 (defun server-process-filter (proc string)
 172   (server-log string)
 173   (setq string (concat server-previous-string string))
 174   ;; If the input is multiple lines,
 175   ;; process each line individually.
 176   (while (string-match "\n" string)
 177     (let ((request (substring string 0 (match-beginning 0)))
 178           client
 179           (files nil)
 180           (lineno 1))
 181       ;; Remove this line from STRING.
 182       (setq string (substring string (match-end 0)))
 183       (if (string-match "^Error: " request)
 184           (message (concat "Server error: " (substring request (match-end 0))))
 185         (if (string-match "^Client: " request)
 186             (setq request (substring request (match-end 0))))
 187         (setq client (list (substring request 0 (string-match " " request))))
 188         (setq request (substring request (match-end 0)))
 189         (while (string-match "[^ ]+ " request)
 190           (let ((arg
 191                  (substring request (match-beginning 0) (1- (match-end 0)))))
 192             (setq request (substring request (match-end 0)))
 193             (if (string-match "\\`\\+[0-9]+\\'" arg)
 194                 (setq lineno (read (substring arg 1)))
 195               (setq files
 196                     (cons (list arg lineno)
 197                           files))
 198               (setq lineno 1))))
 199         (server-visit-files files client)
 200         ;; CLIENT is now a list (CLIENTNUM BUFFERS...)
 201         (setq server-clients (cons client server-clients))
 202         (server-switch-buffer (nth 1 client))
 203         (run-hooks 'server-switch-hook)
 204         (message (substitute-command-keys
 205                   "When done with a buffer, type \\[server-edit]")))))
 206   ;; Save for later any partial line that remains.
 207   (setq server-previous-string string))
 208
 209 (defun server-visit-files (files client)
 210   "Finds FILES and returns the list CLIENT with the buffers nconc'd.
 211 FILES is an alist whose elements are (FILENAME LINENUMBER)."
 212   ;; Bind last-nonmenu-event to force use of keyboard, not mouse, for queries.
 213   (let (client-record (last-nonmenu-event t) (obuf (current-buffer)))
 214     ;; Restore the current buffer afterward, but not using save-excursion,
 215     ;; because we don't want to save point in this buffer
 216     ;; if it happens to be one of those specified by the server.
 217     (unwind-protect
 218         (while files
 219           ;; If there is an existing buffer modified or the file is modified,
 220           ;; revert it.
 221           ;; If there is an existing buffer with deleted file, offer to write it.
 222           (let* ((filen (car (car files)))
 223                  (obuf (get-file-buffer filen)))
 224             (if (and obuf (set-buffer obuf))
 225                 (if (file-exists-p filen)
 226                     (if (or (not (verify-visited-file-modtime obuf))
 227                             (buffer-modified-p obuf))
 228                         (revert-buffer t nil))
 229                   (if (y-or-n-p
 230                        (concat "File no longer exists: "
 231                                filen
 232                                ", write buffer to file? "))
 233                       (write-file filen)))
 234               (set-buffer (find-file-noselect filen))
 235               (run-hooks 'server-visit-hook)))
 236           (goto-line (nth 1 (car files)))
 237           (setq server-buffer-clients (cons (car client) server-buffer-clients))
 238           (setq client-record (cons (current-buffer) client-record))
 239           (setq files (cdr files)))
 240       (set-buffer obuf))
 241     (nconc client client-record)))
 242 \f
 243 (defun server-buffer-done (buffer)
 244   "Mark BUFFER as \"done\" for its client(s).
 245 This buries the buffer, then returns a list of the form (NEXT-BUFFER KILLED).
 246 NEXT-BUFFER is another server buffer, as a suggestion for what to select next,
 247 or nil.  KILLED is t if we killed BUFFER (because it was a temp file)."
 248   (let ((running (eq (process-status server-process) 'run))
 249         (next-buffer nil)
 250         (killed nil)
 251         (old-clients server-clients))
 252     (while old-clients
 253       (let ((client (car old-clients)))
 254         (or next-buffer
 255             (setq next-buffer (nth 1 (memq buffer client))))
 256         (delq buffer client)
 257         ;; Delete all dead buffers from CLIENT.
 258         (let ((tail client))
 259           (while tail
 260             (and (bufferp (car tail))
 261                  (null (buffer-name (car tail)))
 262                  (delq (car tail) client))
 263             (setq tail (cdr tail))))
 264         ;; If client now has no pending buffers,
 265         ;; tell it that it is done, and forget it entirely.
 266         (if (cdr client) nil
 267           (if running
 268               (progn
 269                 (send-string server-process
 270                              (format "Close: %s Done\n" (car client)))
 271                 (server-log (format "Close: %s Done\n" (car client)))
 272                 ;; Don't send emacsserver two commands in close succession.
 273                 ;; It cannot handle that.
 274                 (sit-for 1)))
 275           (setq server-clients (delq client server-clients))))
 276       (setq old-clients (cdr old-clients)))
 277     (if (and (bufferp buffer) (buffer-name buffer))
 278         (progn
 279           (save-excursion
 280             (set-buffer buffer)
 281             (setq server-buffer-clients nil)
 282             (run-hooks 'server-done-hook))
 283           (if (server-temp-file-p buffer)
 284               (progn (kill-buffer buffer)
 285                      (setq killed t))
 286             (bury-buffer buffer))))
 287     (list next-buffer killed)))
 288
 289 (defun server-temp-file-p (buffer)
 290   "Return non-nil if BUFFER contains a file considered temporary.
 291 These are files whose names suggest they are repeatedly
 292 reused to pass information to another program.
 293
 294 The variable `server-temp-file-regexp' controls which filenames
 295 are considered temporary."
 296   (and (buffer-file-name buffer)
 297        (string-match server-temp-file-regexp (buffer-file-name buffer))))
 298
 299 (defun server-done ()
 300   "Offer to save current buffer, mark it as \"done\" for clients.
 301 This buries the buffer, then returns a list of the form (NEXT-BUFFER KILLED).
 302 NEXT-BUFFER is another server buffer, as a suggestion for what to select next,
 303 or nil.  KILLED is t if we killed the BUFFER (because it was a temp file)."
 304   (let ((buffer (current-buffer)))
 305     (if server-buffer-clients
 306         (progn
 307           (if (server-temp-file-p buffer)
 308               ;; For a temp file, save, and do make a non-numeric backup
 309               ;; (unless make-backup-files is nil).
 310               (let ((version-control nil)
 311                     (buffer-backed-up nil))
 312                 (save-buffer))
 313             (if (and (buffer-modified-p)
 314                      (y-or-n-p (concat "Save file " buffer-file-name "? ")))
 315                 (save-buffer buffer)))
 316           (server-buffer-done buffer)))))
 317
 318 ;; Ask before killing a server buffer.
 319 ;; It was suggested to release its client instead,
 320 ;; but I think that is dangerous--the client would proceed
 321 ;; using whatever is on disk in that file. -- rms.
 322 (defun server-kill-buffer-query-function ()
 323   (or (not server-buffer-clients)
 324       (yes-or-no-p (format "Buffer `%s' still has clients; kill it? "
 325                            (buffer-name (current-buffer))))))
 326
 327 (add-hook 'kill-buffer-query-functions
 328           'server-kill-buffer-query-function)
 329
 330 (defun server-kill-emacs-query-function ()
 331   (let (live-client
 332         (tail server-clients))
 333     ;; See if any clients have any buffers that are still alive.
 334     (while tail
 335       (if (memq t (mapcar 'stringp (mapcar 'buffer-name (cdr (car tail)))))
 336           (setq live-client t))
 337       (setq tail (cdr tail)))
 338     (or (not live-client)
 339         (yes-or-no-p "Server buffers still have clients; exit anyway? "))))
 340
 341 (add-hook 'kill-emacs-query-functions 'server-kill-emacs-query-function)
 342 \f
 343 (defun server-edit (&optional arg)
 344   "Switch to next server editing buffer; say \"Done\" for current buffer.
 345 If a server buffer is current, it is marked \"done\" and optionally saved.
 346 When all of a client's buffers are marked as \"done\", the client is notified.
 347
 348 Temporary files such as MH <draft> files are always saved and backed up,
 349 no questions asked.  (The variable `make-backup-files', if nil, still
 350 inhibits a backup; you can set it locally in a particular buffer to
 351 prevent a backup for it.)  The variable `server-temp-file-regexp' controls
 352 which filenames are considered temporary.
 353
 354 If invoked with a prefix argument, or if there is no server process running,
 355 starts server process and that is all.  Invoked by \\[server-edit]."
 356   (interactive "P")
 357   (if (or arg
 358           (not server-process)
 359           (memq (process-status server-process) '(signal exit)))
 360       (server-start nil)
 361     (apply 'server-switch-buffer (server-done))))
 362
 363 (defun server-switch-buffer (&optional next-buffer killed-one)
 364   "Switch to another buffer, preferably one that has a client.
 365 Arg NEXT-BUFFER is a suggestion; if it is a live buffer, use it."
 366   ;; KILLED-ONE is t in a recursive call
 367   ;; if we have already killed one temp-file server buffer.
 368   ;; This means we should avoid the final "switch to some other buffer"
 369   ;; since we've already effectively done that.
 370   (cond ((and (windowp server-window)
 371               (window-live-p server-window))
 372          (select-window server-window))
 373         ((framep server-window)
 374          (if (not (frame-live-p server-window))
 375              (setq server-window (make-frame)))
 376          (select-window (frame-selected-window server-window))))
 377   (if (window-minibuffer-p (selected-window))
 378       (select-window (next-window nil 'nomini 0)))
 379   ;; Move to a non-dedicated window, if we have one.
 380   (let ((last-window (previous-window nil 'nomini 0)))
 381     (while (and (window-dedicated-p (selected-window))
 382                 (not (eq last-window (selected-window))))
 383       (select-window (next-window nil 'nomini 0))))
 384   (set-window-dedicated-p (selected-window) nil)
 385   (if next-buffer
 386       (if (and (bufferp next-buffer)
 387                (buffer-name next-buffer))
 388           (switch-to-buffer next-buffer)
 389         ;; If NEXT-BUFFER is a dead buffer,
 390         ;; remove the server records for it
 391         ;; and try the next surviving server buffer.
 392         (apply 'server-switch-buffer
 393                (server-buffer-done next-buffer)))
 394     (if server-clients
 395         (server-switch-buffer (nth 1 (car server-clients)) killed-one)
 396       (if (not killed-one)
 397           (switch-to-buffer (other-buffer))))))
 398
 399 (global-set-key "\C-x#" 'server-edit)
 400 \f
 401 (provide 'server)
 402
 403 ;;; server.el ends here