code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.3.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 dnl Fairly arbitrary, older versions might work too.
  30 AM_INIT_AUTOMAKE(1.11)
  31
  32 dnl Support for --program-prefix, --program-suffix and
  33 dnl --program-transform-name options
  34 AC_ARG_PROGRAM
  35
  36 dnl It is important that variables on the RHS not be expanded here,
  37 dnl hence the single quotes.  This is per the GNU coding standards, see
  38 dnl (autoconf) Installation Directory Variables
  39 dnl See also epaths.h below.
  40 lispdir='${datadir}/emacs/${version}/lisp'
  41 leimdir='${datadir}/emacs/${version}/leim'
  42 standardlisppath='${lispdir}:${leimdir}'
  43 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  44 '${datadir}/emacs/site-lisp'
  45 lisppath='${locallisppath}:${standardlisppath}'
  46 etcdir='${datadir}/emacs/${version}/etc'
  47 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  48 docdir='${datadir}/emacs/${version}/etc'
  49 gamedir='${localstatedir}/games/emacs'
  50
  51 dnl Special option to disable the most of other options.
  52 AC_ARG_WITH(all,
  53 [AS_HELP_STRING([--without-all],
  54                 [omit almost all features and build
  55                 small executable with minimal dependencies])],
  56   with_features=$withval,
  57   with_features=yes)
  58
  59 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  60 dnl Create a new --with option that defaults to being disabled.
  61 dnl NAME is the base name of the option.  The shell variable with_NAME
  62 dnl   will be set to either the user's value (if the option is
  63 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  64 dnl   option is not specified).  Note that the shell variable name is
  65 dnl   constructed as autoconf does, by replacing non-alphanumeric
  66 dnl   characters with "_".
  67 dnl HELP-STRING is the help text for the option.
  68 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  69   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  70     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  71 ])dnl
  72
  73 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  74 dnl Create a new --with option that defaults to $enable_features.
  75 dnl NAME is the base name of the option.  The shell variable with_NAME
  76 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  77 dnl   'yes' (if the option is not specified).  Note that the shell
  78 dnl   variable name is constructed as autoconf does, by replacing
  79 dnl   non-alphanumeric characters with "_".
  80 dnl HELP-STRING is the help text for the option.
  81 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  82   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  83    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
  84 ])dnl
  85
  86 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  87 if test "$with_pop" = yes; then
  88    AC_DEFINE(MAIL_USE_POP)
  89 fi
  90 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  91
  92 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  93 if test "$with_kerberos" != no; then
  94    AC_DEFINE(KERBEROS)
  95 fi
  96 AH_TEMPLATE(KERBEROS,
  97             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  98
  99 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 100 if test "${with_kerberos5}" != no; then
 101   if test "${with_kerberos}" = no; then
 102     with_kerberos=yes
 103     AC_DEFINE(KERBEROS)
 104   fi
 105   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 106 fi
 107
 108 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 109 dnl FIXME hesiod support may not be present, so it seems like an error
 110 dnl to define, or at least use, this unconditionally.
 111 if test "$with_hesiod" != no; then
 112   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 113 fi
 114
 115 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 116 if test "$with_mmdf" != no; then
 117    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 118 fi
 119
 120 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 121 if test "$with_mail_unlink" != no; then
 122    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 123 fi
 124
 125 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 126     [string giving default POP mail host])],
 127     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 128
 129 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 130
 131 dnl FIXME currently it is not the last.
 132 dnl This should be the last --with option, because --with-x is
 133 dnl added later on when we find the file name of X, and it's best to
 134 dnl keep them together visually.
 135 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 136  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 137 [         case "${withval}" in
 138             y | ye | yes )      val=gtk ;;
 139             n | no )            val=no  ;;
 140             l | lu | luc | luci | lucid )       val=lucid ;;
 141             a | at | ath | athe | athen | athena )      val=athena ;;
 142             m | mo | mot | moti | motif )       val=motif ;;
 143             g | gt | gtk  )     val=gtk ;;
 144             gtk2  )     val=gtk2 ;;
 145             gtk3  )     val=gtk3 ;;
 146             * )
 147 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 148 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
 149 `gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
 150 `athena' and `lucid' are synonyms.])
 151             ;;
 152           esac
 153           with_x_toolkit=$val
 154 ])
 155
 156 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 157 if test "$with_wide_int" = yes; then
 158   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 159 fi
 160
 161 dnl _ON results in a '--without' option in the --help output, so
 162 dnl the help text should refer to "don't compile", etc.
 163 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 164 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 165 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 166 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 167 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 168 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 169 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 170 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 171
 172 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 173 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 174 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 175
 176 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 177 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 178 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 179 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 180 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI])
 181
 182 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 183 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 184 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 185 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 186 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 187 OPTION_DEFAULT_ON([acl],[don't compile with ACL support])
 188 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 189 OPTION_DEFAULT_ON([inotify],[don't compile with inotify (file-watch) support])
 190
 191 ## For the times when you want to build Emacs but don't have
 192 ## a suitable makeinfo, and can live without the manuals.
 193 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 194 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 195
 196 ## Makefile.in needs the cache file name.
 197 AC_SUBST(cache_file)
 198
 199 ## This is an option because I do not know if all info/man support
 200 ## compressed files, nor how to test if they do so.
 201 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 202 if test $with_compress_info = yes; then
 203    GZIP_INFO=yes
 204 else
 205    GZIP_INFO=
 206 fi
 207 AC_SUBST(GZIP_INFO)
 208
 209 AC_ARG_WITH([pkg-config-prog],dnl
 210 [AS_HELP_STRING([--with-pkg-config-prog=FILENAME],
 211                   [file name of pkg-config for finding GTK and librsvg])])
 212 if test "X${with_pkg_config_prog}" != X; then
 213    if test "${with_pkg_config_prog}" != yes; then
 214       PKG_CONFIG="${with_pkg_config_prog}"
 215    fi
 216 fi
 217
 218 CRT_DIR=
 219 AC_ARG_WITH([crt-dir],dnl
 220 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 221 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 222 CRT_DIR="${with_crt_dir}"
 223
 224 AC_ARG_WITH(gameuser,dnl
 225 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 226 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 227   && gameuser="${with_gameuser}"
 228 test "X$gameuser" = X && gameuser=games
 229
 230 AC_ARG_WITH([gnustep-conf],dnl
 231 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 232    [name of GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 233 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 234   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 235 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 236      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 237
 238 AC_ARG_ENABLE(ns-self-contained,
 239 [AS_HELP_STRING([--disable-ns-self-contained],
 240                 [disable self contained build under NeXTstep])],
 241    EN_NS_SELF_CONTAINED=$enableval,
 242    EN_NS_SELF_CONTAINED=yes)
 243
 244 AC_ARG_ENABLE(locallisppath,
 245 [AS_HELP_STRING([--enable-locallisppath=PATH],
 246                 [directories Emacs should search for lisp files specific
 247                  to this site])],
 248 if test "${enableval}" = "no"; then
 249   locallisppath=
 250 elif test "${enableval}" != "yes"; then
 251   locallisppath=${enableval}
 252 fi)
 253
 254 AC_ARG_ENABLE(checking,
 255 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 256                 [enable expensive run-time checks.  With LIST,
 257                  enable only specific categories of checks.
 258                  Categories are: all,yes,no.
 259                  Flags are: stringbytes, stringoverrun, stringfreelist,
 260                  xmallocoverrun, conslist, glyphs])],
 261 [ac_checking_flags="${enableval}"],[])
 262 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 263 for check in $ac_checking_flags
 264 do
 265         case $check in
 266         # these set all the flags to specific states
 267         yes)            ac_enable_checking=1 ;;
 268         no)             ac_enable_checking= ;
 269                         ac_gc_check_stringbytes= ;
 270                         ac_gc_check_string_overrun= ;
 271                         ac_gc_check_string_free_list= ;
 272                         ac_xmalloc_overrun= ;
 273                         ac_gc_check_cons_list= ;
 274                         ac_glyphs_debug= ;;
 275         all)            ac_enable_checking=1 ;
 276                         ac_gc_check_stringbytes=1 ;
 277                         ac_gc_check_string_overrun=1 ;
 278                         ac_gc_check_string_free_list=1 ;
 279                         ac_xmalloc_overrun=1 ;
 280                         ac_gc_check_cons_list=1 ;
 281                         ac_glyphs_debug=1 ;;
 282         # these enable particular checks
 283         stringbytes)    ac_gc_check_stringbytes=1 ;;
 284         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 285         stringfreelist) ac_gc_check_string_free_list=1 ;;
 286         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 287         conslist)       ac_gc_check_cons_list=1 ;;
 288         glyphs)         ac_glyphs_debug=1 ;;
 289         *)      AC_MSG_ERROR(unknown check category $check) ;;
 290         esac
 291 done
 292 IFS="$ac_save_IFS"
 293
 294 if test x$ac_enable_checking != x ; then
 295   AC_DEFINE(ENABLE_CHECKING, 1,
 296 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 297 fi
 298 if test x$ac_gc_check_stringbytes != x ; then
 299   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 300 [Define this temporarily to hunt a bug.  If defined, the size of
 301    strings is redundantly recorded in sdata structures so that it can
 302    be compared to the sizes recorded in Lisp strings.])
 303 fi
 304 if test x$ac_gc_check_string_overrun != x ; then
 305   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 306 [Define this to check for short string overrun.])
 307 fi
 308 if test x$ac_gc_check_string_free_list != x ; then
 309   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 310 [Define this to check the string free list.])
 311 fi
 312 if test x$ac_xmalloc_overrun != x ; then
 313   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 314 [Define this to check for malloc buffer overrun.])
 315 fi
 316 if test x$ac_gc_check_cons_list != x ; then
 317   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 318 [Define this to check for errors in cons list.])
 319 fi
 320 if test x$ac_glyphs_debug != x ; then
 321   AC_DEFINE(GLYPH_DEBUG, 1,
 322 [Define this to enable glyphs debugging code.])
 323 fi
 324
 325 AC_ARG_ENABLE(check-lisp-object-type,
 326 [AS_HELP_STRING([--enable-check-lisp-object-type],
 327                 [enable compile time checks for the Lisp_Object data type.
 328                 This is useful for development for catching certain types of bugs.])],
 329 if test "${enableval}" != "no"; then
 330    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 331    [Define this to enable compile time checks for the Lisp_Object data type.])
 332 fi)
 333
 334
 335 dnl The name of this option is unfortunate.  It predates, and has no
 336 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 337 dnl Actually, it stops it working.
 338 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 339 AC_ARG_ENABLE(profiling,
 340 [AS_HELP_STRING([--enable-profiling],
 341                 [build emacs with low-level, gprof profiling support.
 342                 Mainly useful for debugging Emacs itself.  May not work on
 343                 all platforms.  Stops profiler.el working.])],
 344 [ac_enable_profiling="${enableval}"],[])
 345 if test x$ac_enable_profiling != x ; then
 346    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 347 else
 348    PROFILING_CFLAGS=
 349 fi
 350 AC_SUBST(PROFILING_CFLAGS)
 351
 352 AC_ARG_ENABLE(autodepend,
 353 [AS_HELP_STRING([--enable-autodepend],
 354                 [automatically generate dependencies to .h-files.
 355                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 356                  found])],
 357 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 358
 359 #### Make srcdir absolute, if it isn't already.  It's important to
 360 #### avoid running the file name through pwd unnecessarily, since pwd can
 361 #### give you automounter prefixes, which can go away.  We do all this
 362 #### so Emacs can find its files when run uninstalled.
 363 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 364 unset CDPATH
 365 case "${srcdir}" in
 366   /* ) ;;
 367   . )
 368     ## We may be able to use the $PWD environment variable to make this
 369     ## absolute.  But sometimes PWD is inaccurate.
 370     ## Note: we used to use $PWD at the end instead of `pwd`,
 371     ## but that tested only for a well-formed and valid PWD,
 372     ## it did not object when PWD was well-formed and valid but just wrong.
 373     if test ".$PWD" != "." && test ".`(cd "$PWD" ; sh -c pwd)`" = ".`pwd`"  ;
 374     then
 375       srcdir="$PWD"
 376     else
 377       srcdir=`(cd "$srcdir"; pwd)`
 378     fi
 379   ;;
 380   *  ) srcdir=`(cd "$srcdir"; pwd)` ;;
 381 esac
 382
 383 ### Canonicalize the configuration name.
 384
 385 AC_CANONICAL_HOST
 386 canonical=$host
 387 configuration=${host_alias-${build_alias-$host}}
 388
 389 dnl This used to use changequote, but, apart from `changequote is evil'
 390 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 391 dnl the great gob of text.  Thus it's not processed for possible expansion.
 392 dnl Just make sure the brackets remain balanced.
 393 dnl
 394 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 395 dnl indicated by comments.
 396 dnl quotation begins
 397 [
 398
 399 ### If you add support for a new configuration, add code to this
 400 ### switch statement to recognize your configuration name and select
 401 ### the appropriate operating system file.
 402
 403 ### You would hope that you could choose an s/*.h
 404 ### file based on the operating system portion.  However, it turns out
 405 ### that each s/*.h file is pretty manufacturer-specific.
 406 ### So we basically have to have a special case for each
 407 ### configuration name.
 408 ###
 409 ### As far as handling version numbers on operating systems is
 410 ### concerned, make sure things will fail in a fixable way.  If
 411 ### /etc/MACHINES doesn't say anything about version numbers, be
 412 ### prepared to handle anything reasonably.  If version numbers
 413 ### matter, be sure /etc/MACHINES says something about it.
 414
 415 opsys='' unported=no
 416 case "${canonical}" in
 417
 418   ## GNU/Linux and similar ports
 419   *-*-linux* )
 420     opsys=gnu-linux
 421   ;;
 422
 423   ## FreeBSD ports
 424   *-*-freebsd* )
 425     opsys=freebsd
 426   ;;
 427
 428   ## FreeBSD kernel + glibc based userland
 429   *-*-kfreebsd*gnu* )
 430     opsys=gnu-kfreebsd
 431   ;;
 432
 433   ## NetBSD ports
 434   *-*-netbsd* )
 435     opsys=netbsd
 436   ;;
 437
 438   ## OpenBSD ports
 439   *-*-openbsd* )
 440     opsys=openbsd
 441   ;;
 442
 443   ## Apple Darwin / Mac OS X
 444   *-apple-darwin* )
 445     case "${canonical}" in
 446       i[3456]86-* )  ;;
 447       powerpc-* )    ;;
 448       x86_64-* )     ;;
 449       * )            unported=yes ;;
 450     esac
 451     opsys=darwin
 452     ## Use fink packages if available.
 453     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 454 ##    if test -d /sw/include && test -d /sw/lib; then
 455 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 456 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 457 ##    fi
 458   ;;
 459
 460   ## HP 9000 series 700 and 800, running HP/UX
 461   hppa*-hp-hpux10.2* )
 462     opsys=hpux10-20
 463   ;;
 464   hppa*-hp-hpux1[1-9]* )
 465     opsys=hpux11
 466     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 467   ;;
 468
 469   ## IBM machines
 470   rs6000-ibm-aix4.[23]* )
 471     opsys=aix4-2
 472   ;;
 473   powerpc-ibm-aix4.[23]*  )
 474     opsys=aix4-2
 475   ;;
 476   rs6000-ibm-aix[56]* )
 477     opsys=aix4-2
 478   ;;
 479   powerpc-ibm-aix[56]*  )
 480     opsys=aix4-2
 481   ;;
 482
 483   ## Silicon Graphics machines
 484   ## Iris 4D
 485   mips-sgi-irix6.5 )
 486     opsys=irix6-5
 487     # Without defining _LANGUAGE_C, things get masked out in the headers
 488     # so that, for instance, grepping for `free' in stdlib.h fails and
 489     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 490     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 491   ;;
 492
 493   ## Suns
 494   *-sun-solaris* \
 495     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 496     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 497     case "${canonical}" in
 498       i[3456]86-*-* )   ;;
 499       amd64-*-*|x86_64-*-*) ;;
 500       sparc* )          ;;
 501       * )               unported=yes ;;
 502     esac
 503     case "${canonical}" in
 504       *-sunos5.6* | *-solaris2.6* )
 505                 opsys=sol2-6
 506                 RANLIB="ar -ts"
 507                 ;;
 508       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 509                 opsys=sol2-6
 510                 emacs_check_sunpro_c=yes
 511                 ;;
 512       *-sunos5* | *-solaris* )
 513                 opsys=sol2-10
 514                 emacs_check_sunpro_c=yes
 515                 ;;
 516     esac
 517     ## Watch out for a compiler that we know will not work.
 518     case "${canonical}" in
 519      *-solaris* | *-sunos5* )
 520                 if [ "x$CC" = x/usr/ucb/cc ]; then
 521                   ## /usr/ucb/cc doesn't work;
 522                   ## we should find some other compiler that does work.
 523                   unset CC
 524                 fi
 525                 ;;
 526       *) ;;
 527     esac
 528   ;;
 529
 530   ## Intel 386 machines where we don't care about the manufacturer.
 531   i[3456]86-*-* )
 532     case "${canonical}" in
 533       *-cygwin )                opsys=cygwin ;;
 534       *-darwin* )               opsys=darwin ;;
 535       *-sysv4.2uw* )            opsys=unixware ;;
 536       *-sysv5uw* )              opsys=unixware ;;
 537       *-sysv5OpenUNIX* )        opsys=unixware ;;
 538       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 539     esac
 540   ;;
 541
 542   * )
 543     unported=yes
 544   ;;
 545 esac
 546
 547 ### If the code above didn't choose an operating system, just choose
 548 ### an operating system based on the configuration name.  You really
 549 ### only want to use this when you have no idea what the right
 550 ### operating system is; if you know what operating systems a machine
 551 ### runs, it's cleaner to make it explicit in the case statement
 552 ### above.
 553 if test x"${opsys}" = x; then
 554   case "${canonical}" in
 555     *-gnu* )                            opsys=gnu ;;
 556     * )
 557       unported=yes
 558     ;;
 559   esac
 560 fi
 561
 562 ]
 563 dnl quotation ends
 564
 565 if test $unported = yes; then
 566   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 567 Check `etc/MACHINES' for recognized configuration names.])
 568 fi
 569
 570
 571 #### Choose a compiler.
 572
 573 dnl Sets GCC=yes if using gcc.
 574 AC_PROG_CC
 575 AM_PROG_CC_C_O
 576
 577 if test x$GCC = xyes; then
 578   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 579 else
 580   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 581 fi
 582
 583 # Avoid gnulib's tests for O_NOATIME and O_NOFOLLOW, as we don't use them.
 584 AC_DEFUN([gl_FCNTL_O_FLAGS])
 585 # Avoid gnulib's threadlib module, as we do threads our own way.
 586 AC_DEFUN([gl_THREADLIB])
 587
 588 # Initialize gnulib right after choosing the compiler.
 589 dnl Amongst other things, this sets AR and ARFLAGS.
 590 gl_EARLY
 591
 592 # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 593 # if -g3 works and the user does not specify CFLAGS.
 594 # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 595 if test "$ac_test_CFLAGS" != set; then
 596   case $CFLAGS in
 597     '-g')
 598       emacs_g3_CFLAGS='-g3';;
 599     '-g -O2')
 600       emacs_g3_CFLAGS='-g3 -O2';;
 601     *)
 602       emacs_g3_CFLAGS='';;
 603   esac
 604   if test -n "$emacs_g3_CFLAGS"; then
 605     emacs_save_CFLAGS=$CFLAGS
 606     CFLAGS=$emacs_g3_CFLAGS
 607     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 608       [emacs_cv_prog_cc_g3],
 609       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 610          [emacs_cv_prog_cc_g3=yes],
 611          [emacs_cv_prog_cc_g3=no])])
 612     if test $emacs_cv_prog_cc_g3 = yes; then
 613       CFLAGS=$emacs_g3_CFLAGS
 614     else
 615       CFLAGS=$emacs_save_CFLAGS
 616     fi
 617   fi
 618 fi
 619
 620 AC_ARG_ENABLE([gcc-warnings],
 621   [AS_HELP_STRING([--enable-gcc-warnings],
 622                   [turn on lots of GCC warnings. This is intended for
 623                    developers, and may generate false alarms when used
 624                    with older or non-GNU development tools.])],
 625   [case $enableval in
 626      yes|no) ;;
 627      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 628    esac
 629    gl_gcc_warnings=$enableval],
 630   [gl_gcc_warnings=no]
 631 )
 632
 633 AC_ARG_ENABLE(link-time-optimization,
 634 [AS_HELP_STRING([--enable-link-time-optimization],
 635                 [build emacs with link-time optimization.
 636                  This is supported only for GCC since 4.5.0.])],
 637 if test "${enableval}" != "no"; then
 638    AC_MSG_CHECKING([whether link-time optimization is supported])
 639    ac_lto_supported=no
 640    if test x$GCC = xyes; then
 641       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 642       if test x$CPUS != x; then
 643          LTO="-flto=$CPUS"
 644       else
 645          LTO="-flto"
 646       fi
 647       old_CFLAGS=$CFLAGS
 648       CFLAGS="$CFLAGS $LTO"
 649       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 650         [ac_lto_supported=yes], [ac_lto_supported=no])
 651       CFLAGS="$old_CFLAGS"
 652    fi
 653    AC_MSG_RESULT([$ac_lto_supported])
 654    if test "$ac_lto_supported" = "yes"; then
 655       CFLAGS="$CFLAGS $LTO"
 656    fi
 657 fi)
 658
 659 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 660 # ------------------------------------------------
 661 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 662 # Otherwise, run RUN-IF-NOT-FOUND.
 663 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 664   [AC_PREPROC_IFELSE(
 665     [AC_LANG_PROGRAM(
 666       [[
 667 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 668 /* ok */
 669 #else
 670 # error "your version of gcc is older than $1.$2"
 671 #endif
 672       ]]),
 673     ], [$3], [$4])
 674   ]
 675 )
 676
 677 # When compiling with GCC, prefer -isystem to -I when including system
 678 # include files, to avoid generating useless diagnostics for the files.
 679 if test "$gl_gcc_warnings" != yes; then
 680   isystem='-I'
 681 else
 682   isystem='-isystem '
 683
 684   # This, $nw, is the list of warnings we disable.
 685   nw=
 686
 687   case $with_x_toolkit in
 688     lucid | athena | motif)
 689        # Old toolkits mishandle 'const'.
 690        nw="$nw -Wwrite-strings"
 691        ;;
 692     *)
 693        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 694        ;;
 695   esac
 696   AC_SUBST([WERROR_CFLAGS])
 697
 698   nw="$nw -Waggregate-return"       # anachronistic
 699   nw="$nw -Wlong-long"              # C90 is anachronistic
 700   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 701   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 702   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 703   nw="$nw -Wcast-qual"              # Too many warnings for now
 704   nw="$nw -Wconversion"             # Too many warnings for now
 705   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 706   nw="$nw -Wsign-conversion"        # Too many warnings for now
 707   nw="$nw -Woverlength-strings"     # Not a problem these days
 708   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 709   nw="$nw -Wunreachable-code"       # so buggy that it's now silently ignored
 710   nw="$nw -Wpadded"                 # Our structs are not padded
 711   nw="$nw -Wredundant-decls"        # we regularly (re)declare functions
 712   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 713   nw="$nw -Wformat-nonliteral"      # we do this a lot
 714   nw="$nw -Wvla"                    # warnings in gettext.h
 715   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 716   nw="$nw -Wswitch-enum"            # Too many warnings for now
 717   nw="$nw -Wswitch-default"         # Too many warnings for now
 718   nw="$nw -Wfloat-equal"            # warns about high-quality code
 719   nw="$nw -Winline"                 # OK to ignore 'inline'
 720   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 721   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 722                                     # signed overflow has undefined behavior
 723   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 724   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 725
 726   # Emacs doesn't care about shadowing; see
 727   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 728   nw="$nw -Wshadow"
 729
 730   # Emacs's use of alloca inhibits protecting the stack.
 731   nw="$nw -Wstack-protector"
 732
 733   # The following line should be removable at some point.
 734   nw="$nw -Wsuggest-attribute=pure"
 735
 736   gl_MANYWARN_ALL_GCC([ws])
 737   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 738   for w in $ws; do
 739     gl_WARN_ADD([$w])
 740   done
 741   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 742   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 743   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 744   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 745   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 746   gl_WARN_ADD([-Wno-format-nonliteral])
 747
 748   # In spite of excluding -Wlogical-op above, it is enabled, as of
 749   # gcc 4.5.0 20090517.
 750   gl_WARN_ADD([-Wno-logical-op])
 751
 752   gl_WARN_ADD([-fdiagnostics-show-option])
 753   gl_WARN_ADD([-funit-at-a-time])
 754
 755   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 756   AH_VERBATIM([FORTIFY_SOURCE],
 757   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 758       without upsetting glibc 2.15+. */
 759    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 760    # define _FORTIFY_SOURCE 2
 761    #endif
 762   ])
 763   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 764
 765   # We use a slightly smaller set of warning options for lib/.
 766   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 767   nw=
 768   nw="$nw -Wunused-macros"
 769
 770   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 771   AC_SUBST([GNULIB_WARN_CFLAGS])
 772 fi
 773
 774
 775
 776 dnl Some other nice autoconf tests.
 777 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 778 dnl AC_PROG_INSTALL
 779 dnl AC_PROG_MKDIR_P
 780 dnl if test "x$RANLIB" = x; then
 781 dnl   AC_PROG_RANLIB
 782 dnl fi
 783 AC_PROG_LN_S
 784
 785 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 786   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 787 dnl Don't use GZIP, which is used by gzip for additional parameters.
 788 AC_PATH_PROG(GZIP_PROG, gzip)
 789
 790 if test $opsys = gnu-linux; then
 791   AC_PATH_PROG(PAXCTL, paxctl,,
 792     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 793   if test "X$PAXCTL" != X; then
 794     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
 795     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 796       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
 797       else AC_MSG_RESULT(no); PAXCTL=""; fi])
 798   fi
 799 fi
 800
 801 ## Need makeinfo >= 4.7 (?) to build the manuals.
 802 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 803 dnl By this stage, configure has already checked for egrep and set EGREP,
 804 dnl or exited with an error if no egrep was found.
 805 if test "$MAKEINFO" != "no"; then
 806   case `
 807     $MAKEINFO --version 2> /dev/null |
 808     $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'
 809   ` in
 810     '') MAKEINFO=no;;
 811   esac
 812 fi
 813
 814 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 815 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 816 ## therefore in the category of "special tools" not normally required, which
 817 ## configure does not have to check for (eg autoconf itself).
 818 ## In a Bazaar checkout on the other hand, the manuals are not included.
 819 ## So makeinfo is a requirement to build from Bazaar, and configure
 820 ## should test for it as it does for any other build requirement.
 821 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 822 ## with pre-built manuals, from a Bazaar checkout.
 823 HAVE_MAKEINFO=yes
 824
 825 if test "$MAKEINFO" = "no"; then
 826   MAKEINFO=makeinfo
 827   if test "x${with_makeinfo}" = "xno"; then
 828     HAVE_MAKEINFO=no
 829   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
 830     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 831 source tree does not seem to have pre-built manuals in the `info' directory.
 832 Either install a suitable version of makeinfo, or re-run configure
 833 with the `--without-makeinfo' option to build without the manuals.] )
 834   fi
 835 fi
 836 AC_SUBST(HAVE_MAKEINFO)
 837
 838 dnl Just so that there is only a single place we need to edit.
 839 INFO_EXT=.info
 840 INFO_OPTS=--no-split
 841 AC_SUBST(INFO_EXT)
 842 AC_SUBST(INFO_OPTS)
 843
 844 dnl Add our options to ac_link now, after it is set up.
 845
 846 if test x$GCC = xyes; then
 847   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 848     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 849 else
 850   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 851     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 852 fi
 853
 854 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 855 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 856 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 857 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 858 dnl if not built to support GNU ld.
 859
 860 late_LDFLAGS=$LDFLAGS
 861 if test x$GCC = xyes; then
 862   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 863 else
 864   LDFLAGS="$LDFLAGS -znocombreloc"
 865 fi
 866
 867 AC_MSG_CHECKING([for -znocombreloc])
 868 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 869   [AC_MSG_RESULT(yes)],
 870   LDFLAGS=$late_LDFLAGS
 871   [AC_MSG_RESULT(no)])
 872
 873
 874 dnl The function dump-emacs will not be defined and temacs will do
 875 dnl (load "loadup") automatically unless told otherwise.
 876 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 877 case "$opsys" in
 878   your-opsys-here) CANNOT_DUMP=yes ;;
 879 esac
 880
 881 test "$CANNOT_DUMP" = "yes" && \
 882   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 883
 884 AC_SUBST(CANNOT_DUMP)
 885
 886
 887 UNEXEC_OBJ=unexelf.o
 888 case "$opsys" in
 889   # MSDOS uses unexcoff.o
 890   # MSWindows uses unexw32.o
 891   aix4-2)
 892    UNEXEC_OBJ=unexaix.o
 893    ;;
 894   cygwin)
 895    UNEXEC_OBJ=unexcw.o
 896    ;;
 897   darwin)
 898    UNEXEC_OBJ=unexmacosx.o
 899    ;;
 900   hpux10-20 | hpux11)
 901    UNEXEC_OBJ=unexhp9k800.o
 902    ;;
 903   sol2-10)
 904    # Use the Solaris dldump() function, called from unexsol.c, to dump
 905    # emacs, instead of the generic ELF dump code found in unexelf.c.
 906    # The resulting binary has a complete symbol table, and is better
 907    # for debugging and other observability tools (debuggers, pstack, etc).
 908    #
 909    # If you encounter a problem using dldump(), please consider sending
 910    # a message to the OpenSolaris tools-linking mailing list:
 911    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 912    #
 913    # It is likely that dldump() works with older Solaris too, but this has
 914    # not been tested, so for now this change is for Solaris 10 or newer.
 915    UNEXEC_OBJ=unexsol.o
 916    ;;
 917 esac
 918
 919 LD_SWITCH_SYSTEM=
 920 case "$opsys" in
 921   freebsd)
 922    ## Let `ld' find image libs and similar things in /usr/local/lib.
 923    ## The system compiler, GCC, has apparently been modified to not
 924    ## look there, contrary to what a stock GCC would do.
 925 ### It's not our place to do this.  See bug#10313#17.
 926 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 927       :
 928    ;;
 929
 930   gnu-linux)
 931    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 932    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 933    ;;
 934
 935   netbsd)
 936 ### It's not our place to do this.  See bug#10313#17.
 937 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 938       :
 939    ;;
 940
 941   openbsd)
 942    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 943    ## otherwise Emacs dumps core on elf systems.
 944    LD_SWITCH_SYSTEM="-Z"
 945    ;;
 946 esac
 947 AC_SUBST(LD_SWITCH_SYSTEM)
 948
 949 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 950
 951 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 952 ## which has not been defined yet.  When this was handled with cpp,
 953 ## it was expanded to null when configure sourced the s/*.h file.
 954 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 955 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 956 ## (or somesuch), but because it is supposed to go at the _front_
 957 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 958 ## Compare with the gnu-linux case below, which added to the end
 959 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 960 ## LD_SWITCH_SYSTEM_TEMACS.
 961 case "$opsys" in
 962   netbsd|openbsd)
 963    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 964 esac
 965
 966
 967 C_SWITCH_MACHINE=
 968 case $canonical in
 969  alpha*)
 970   AC_CHECK_DECL([__ELF__])
 971   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 972     ## With ELF, make sure that all common symbols get allocated to in the
 973     ## data section.  Otherwise, the dump of temacs may miss variables in
 974     ## the shared library that have been initialized.  For example, with
 975     ## GNU libc, __malloc_initialized would normally be resolved to the
 976     ## shared library's .bss section, which is fatal.
 977     if test "x$GCC" = "xyes"; then
 978       C_SWITCH_MACHINE="-fno-common"
 979     else
 980       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 981     fi
 982   else
 983     UNEXEC_OBJ=unexalpha.o
 984   fi
 985   ;;
 986 esac
 987 AC_SUBST(C_SWITCH_MACHINE)
 988
 989 AC_SUBST(UNEXEC_OBJ)
 990
 991 C_SWITCH_SYSTEM=
 992 ## Some programs in src produce warnings saying certain subprograms
 993 ## are too complex and need a MAXMEM value greater than 2000 for
 994 ## additional optimization.  --nils@exp-math.uni-essen.de
 995 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 996   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 997 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 998 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 999 AC_SUBST(C_SWITCH_SYSTEM)
1000
1001
1002 LIBS_SYSTEM=
1003 case "$opsys" in
1004   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1005   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1006
1007   freebsd) LIBS_SYSTEM="-lutil" ;;
1008
1009   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1010
1011   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1012
1013   ## Motif needs -lgen.
1014   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1015 esac
1016 AC_SUBST(LIBS_SYSTEM)
1017
1018
1019 ### Make sure subsequent tests use flags consistent with the build flags.
1020
1021 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1022   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1023 else
1024   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1025 fi
1026
1027 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1028 AC_DEFUN([AC_TYPE_SIZE_T])
1029 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1030 AC_DEFUN([AC_TYPE_UID_T])
1031
1032
1033 LIB_MATH=-lm
1034 LIB_STANDARD=
1035 START_FILES=
1036 dnl Current possibilities handled by sed (aix4-2 -> aix,
1037 dnl gnu-linux -> gnu/linux, etc.):
1038 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1039 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1040 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1041
1042 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
1043 case $opsys in
1044   cygwin )
1045     LIB_MATH=
1046     START_FILES='pre-crt0.o'
1047     ;;
1048   darwin )
1049     ## Adding -lm confuses the dynamic linker, so omit it.
1050     LIB_MATH=
1051     START_FILES='pre-crt0.o'
1052     ;;
1053   freebsd )
1054     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1055     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1056     SYSTEM_TYPE=berkeley-unix
1057     ;;
1058   gnu-linux | gnu-kfreebsd )
1059     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1060     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1061     ;;
1062   hpux10-20 | hpux11 )
1063     LIB_STANDARD=-lc
1064     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1065     ;;
1066   dnl NB this may be adjusted below.
1067   netbsd | openbsd )
1068     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1069     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1070     SYSTEM_TYPE=berkeley-unix
1071     ;;
1072
1073   sol2* | unixware )
1074     SYSTEM_TYPE=usg-unix-v
1075     ;;
1076
1077 esac
1078
1079 AC_SUBST(LIB_MATH)
1080 AC_SUBST(START_FILES)
1081 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1082   [The type of system you are compiling for; sets `system-type'.])
1083
1084 dnl Not all platforms use crtn.o files.  Check if the current one does.
1085 crt_files=
1086
1087 for file in x $LIB_STANDARD $START_FILES; do
1088   case "$file" in
1089     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1090   esac
1091 done
1092
1093 if test "x$crt_files" != x; then
1094
1095   ## If user specified a crt-dir, use that unconditionally.
1096   crt_gcc=no
1097
1098   if test "X$CRT_DIR" = "X"; then
1099
1100     CRT_DIR=/usr/lib            # default
1101
1102     case "$canonical" in
1103       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1104       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1105       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1106       ## For anything else (eg /usr/lib32), it is up the user to specify
1107       ## the location (bug#5655).
1108       ## Test for crtn.o, not just the directory, because sometimes the
1109       ## directory exists but does not have the relevant files (bug#1287).
1110       ## FIXME better to test for binary compatibility somehow.
1111       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1112       ;;
1113
1114       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1115     esac
1116
1117     case "$opsys" in
1118       hpux10-20) CRT_DIR=/lib ;;
1119     esac
1120
1121     test "x${GCC}" = xyes && crt_gcc=yes
1122
1123   fi                            # CRT_DIR = ""
1124
1125   crt_missing=
1126
1127   for file in $crt_files; do
1128
1129     ## If we're using gcc, try to determine it automatically by asking
1130     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1131     ## system-dependent default from above.]
1132     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1133
1134        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1135        case "$crt_file" in
1136          */*)
1137            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1138            ;;
1139        esac
1140     fi
1141
1142     dnl We expect all the files to be in a single directory, so after the
1143     dnl first there is no point asking gcc.
1144     crt_gcc=no
1145
1146     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1147   done                          # $crt_files
1148
1149   test "x$crt_missing" = x || \
1150     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1151 Try using the --with-crt-dir option.])
1152
1153 fi                              # crt_files != ""
1154
1155 AC_SUBST(CRT_DIR)
1156
1157 case $opsys in
1158   netbsd | openbsd )
1159     if test -f $CRT_DIR/crti.o; then
1160
1161         test -f $CRT_DIR/crtn.o || \
1162           AC_MSG_ERROR([Required file not found: crtn.o])
1163
1164         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1165         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1166     fi
1167     ;;
1168 esac
1169
1170
1171 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1172 pre_PKG_CONFIG_LIBS=$LIBS
1173
1174 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1175
1176 dnl This function definition taken from Gnome 2.0
1177 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1178 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1179 dnl also defines GSTUFF_PKG_ERRORS on error
1180 AC_DEFUN([PKG_CHECK_MODULES], [
1181   succeeded=no
1182
1183   if test "$PKG_CONFIG" = "no" ; then
1184      ifelse([$4], , [AC_MSG_ERROR([
1185       *** The pkg-config script could not be found. Make sure it is in your path, or give the full name of pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1186   else
1187      PKG_CONFIG_MIN_VERSION=0.9.0
1188      if "$PKG_CONFIG" --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1189         AC_MSG_CHECKING(for $2)
1190
1191         if "$PKG_CONFIG" --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1192            $1_CFLAGS=`"$PKG_CONFIG" --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1193            $1_LIBS=`"$PKG_CONFIG" --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1194             edit_cflags="
1195               s,///*,/,g
1196               s/^/ /
1197               s/ -I/ $isystem/g
1198               s/^ //
1199             "
1200             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1201             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1202             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1203             succeeded=yes
1204         else
1205             AC_MSG_RESULT(no)
1206             $1_CFLAGS=""
1207             $1_LIBS=""
1208             ## If we have a custom action on failure, don't print errors, but
1209             ## do set a variable so people can do so.  Do it in a subshell
1210             ## to capture any diagnostics in invoking pkg-config.
1211             $1_PKG_ERRORS=`("$PKG_CONFIG" --print-errors "$2") 2>&1`
1212             ifelse([$4], ,echo "$$1_PKG_ERRORS",)
1213         fi
1214
1215         AC_SUBST($1_CFLAGS)
1216         AC_SUBST($1_LIBS)
1217      else
1218         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1219         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1220      fi
1221   fi
1222
1223   if test $succeeded = yes; then
1224      ifelse([$3], , :, [$3])
1225   else
1226      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1227   fi
1228 ])
1229
1230
1231 if test "${with_sound}" != "no"; then
1232   # Sound support for GNU/Linux and the free BSDs.
1233   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1234     have_sound_header=yes)
1235   # Emulation library used on NetBSD.
1236   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1237   AC_SUBST(LIBSOUND)
1238
1239   ALSA_REQUIRED=1.0.0
1240   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1241   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1242   if test $HAVE_ALSA = yes; then
1243     SAVE_CFLAGS="$CFLAGS"
1244     SAVE_LIBS="$LIBS"
1245     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1246     LIBS="$ALSA_LIBS $LIBS"
1247     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1248                     emacs_alsa_normal=yes,
1249                     emacs_alsa_normal=no)
1250     if test "$emacs_alsa_normal" != yes; then
1251       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1252                      [[snd_lib_error_set_handler (0);]])],
1253                      emacs_alsa_subdir=yes,
1254                      emacs_alsa_subdir=no)
1255       if test "$emacs_alsa_subdir" != yes; then
1256         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1257       fi
1258       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1259     fi
1260
1261     CFLAGS="$SAVE_CFLAGS"
1262     LIBS="$SAVE_LIBS"
1263     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1264     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1265     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1266   fi
1267
1268   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1269   dnl compiles only on the specified platforms.  For others, it
1270   dnl probably doesn't make sense to try.
1271   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1272      case "$opsys" in
1273        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1274        gnu-linux|freebsd|netbsd)
1275          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1276          ;;
1277      esac
1278   fi
1279
1280   AC_SUBST(CFLAGS_SOUND)
1281 fi
1282
1283 dnl checks for header files
1284 AC_CHECK_HEADERS_ONCE(
1285   linux/version.h sys/systeminfo.h
1286   coff.h pty.h
1287   sys/vlimit.h sys/resource.h
1288   sys/utsname.h pwd.h utmp.h util.h)
1289
1290 AC_MSG_CHECKING(if personality LINUX32 can be set)
1291 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1292                emacs_cv_personality_linux32=yes,
1293                emacs_cv_personality_linux32=no)
1294 AC_MSG_RESULT($emacs_cv_personality_linux32)
1295
1296 if test $emacs_cv_personality_linux32 = yes; then
1297   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1298             [Define to 1 if personality LINUX32 can be set.])
1299 fi
1300
1301 dnl On Solaris 8 there's a compilation warning for term.h because
1302 dnl it doesn't define `bool'.
1303 AC_CHECK_HEADERS(term.h, , , -)
1304 AC_HEADER_TIME
1305 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1306                                       ]])
1307 if test $ac_cv_have_decl_sys_siglist != yes; then
1308   # For Tru64, at least:
1309   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1310                                           ]])
1311   if test $ac_cv_have_decl___sys_siglist = yes; then
1312     AC_DEFINE(sys_siglist, __sys_siglist,
1313               [Define to any substitute for sys_siglist.])
1314   fi
1315 fi
1316 AC_HEADER_SYS_WAIT
1317
1318 dnl Check for speed_t typedef.
1319 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1320   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1321     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1322 if test $emacs_cv_speed_t = yes; then
1323   AC_DEFINE(HAVE_SPEED_T, 1,
1324            [Define to 1 if `speed_t' is declared by <termios.h>.])
1325 fi
1326
1327 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1328 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1329 #if HAVE_SYS_SOCKET_H
1330 #include <sys/socket.h>
1331 #endif])
1332 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1333 #if HAVE_SYS_SOCKET_H
1334 #include <sys/socket.h>
1335 #endif])
1336 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1337 #if HAVE_SYS_SOCKET_H
1338 #include <sys/socket.h>
1339 #endif])
1340
1341 dnl checks for structure members
1342 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1343                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1344                   struct ifreq.ifr_addr,
1345                   struct ifreq.ifr_addr.sa_len], , ,
1346                  [AC_INCLUDES_DEFAULT
1347 #if HAVE_SYS_SOCKET_H
1348 #include <sys/socket.h>
1349 #endif
1350 #if HAVE_NET_IF_H
1351 #include <net/if.h>
1352 #endif])
1353
1354 dnl Check for endianness.
1355 dnl AC_C_BIGENDIAN is done by gnulib.
1356
1357 dnl check for Make feature
1358 dnl AC_PROG_MAKE_SET is done by Automake.
1359
1360 DEPFLAGS=
1361 MKDEPDIR=":"
1362 deps_frag=deps.mk
1363 dnl check for GNU Make if we have GCC and autodepend is on.
1364 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1365    AC_MSG_CHECKING([whether we are using GNU Make])
1366    HAVE_GNU_MAKE=no
1367    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1368    if test "x$testval" != x; then
1369       HAVE_GNU_MAKE=yes
1370    else
1371       ac_enable_autodepend=no
1372    fi
1373    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1374    if test $HAVE_GNU_MAKE = yes; then
1375       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1376       SAVE_CFLAGS="$CFLAGS"
1377       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1378       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1379       CFLAGS="$SAVE_CFLAGS"
1380       test -f deps.d || ac_enable_autodepend=no
1381       rm -rf deps.d
1382       AC_MSG_RESULT([$ac_enable_autodepend])
1383    fi
1384    if test $ac_enable_autodepend = yes; then
1385       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1386       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1387       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1388       deps_frag=autodeps.mk
1389    fi
1390 fi
1391 deps_frag=$srcdir/src/$deps_frag
1392 AC_SUBST(MKDEPDIR)
1393 AC_SUBST(DEPFLAGS)
1394 AC_SUBST_FILE(deps_frag)
1395
1396
1397 lisp_frag=$srcdir/src/lisp.mk
1398 AC_SUBST_FILE(lisp_frag)
1399
1400
1401 dnl checks for operating system services
1402 AC_SYS_LONG_FILE_NAMES
1403
1404 #### Choose a window system.
1405
1406 ## We leave window_system equal to none if
1407 ## we end up building without one.  Any new window system should
1408 ## set window_system to an appropriate value and add objects to
1409 ## window-system-specific substs.
1410
1411 window_system=none
1412 AC_PATH_X
1413 if test "$no_x" != yes; then
1414   window_system=x11
1415 fi
1416
1417 LD_SWITCH_X_SITE_RPATH=
1418 if test "${x_libraries}" != NONE; then
1419   if test -n "${x_libraries}"; then
1420     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1421     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1422   fi
1423   x_default_search_path=""
1424   x_search_path=${x_libraries}
1425   if test -z "${x_search_path}"; then
1426     x_search_path=/usr/lib
1427   fi
1428   for x_library in `echo ${x_search_path}: | \
1429                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1430     x_search_path="\
1431 ${x_library}/X11/%L/%T/%N%C%S:\
1432 ${x_library}/X11/%l/%T/%N%C%S:\
1433 ${x_library}/X11/%T/%N%C%S:\
1434 ${x_library}/X11/%L/%T/%N%S:\
1435 ${x_library}/X11/%l/%T/%N%S:\
1436 ${x_library}/X11/%T/%N%S"
1437     if test x"${x_default_search_path}" = x; then
1438       x_default_search_path=${x_search_path}
1439     else
1440       x_default_search_path="${x_search_path}:${x_default_search_path}"
1441     fi
1442   done
1443 fi
1444 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1445
1446 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1447   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1448 fi
1449
1450 if test x"${x_includes}" = x; then
1451   bitmapdir=/usr/include/X11/bitmaps
1452 else
1453   # accumulate include directories that have X11 bitmap subdirectories
1454   bmd_acc="dummyval"
1455   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1456     if test -d "${bmd}/X11/bitmaps"; then
1457       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1458     fi
1459     if test -d "${bmd}/bitmaps"; then
1460       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1461     fi
1462   done
1463   if test ${bmd_acc} != "dummyval"; then
1464     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1465   fi
1466 fi
1467
1468 HAVE_NS=no
1469 NS_IMPL_COCOA=no
1470 NS_IMPL_GNUSTEP=no
1471 tmp_CPPFLAGS="$CPPFLAGS"
1472 tmp_CFLAGS="$CFLAGS"
1473 CPPFLAGS="$CPPFLAGS -x objective-c"
1474 CFLAGS="$CFLAGS -x objective-c"
1475 TEMACS_LDFLAGS2="\${LDFLAGS}"
1476 GNU_OBJC_CFLAGS=
1477 if test "${with_ns}" != no; then
1478   if test "${opsys}" = darwin; then
1479      NS_IMPL_COCOA=yes
1480      ns_appdir=`pwd`/nextstep/Emacs.app
1481      ns_appbindir=${ns_appdir}/Contents/MacOS
1482      ns_appresdir=${ns_appdir}/Contents/Resources
1483      ns_appsrc=Cocoa/Emacs.base
1484   elif test -f $GNUSTEP_CONFIG_FILE; then
1485      NS_IMPL_GNUSTEP=yes
1486      ns_appdir=`pwd`/nextstep/Emacs.app
1487      ns_appbindir=${ns_appdir}
1488      ns_appresdir=${ns_appdir}/Resources
1489      ns_appsrc=GNUstep/Emacs.base
1490      dnl FIXME sourcing this several times in subshells seems inefficient.
1491      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1492      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1493      dnl I seemed to need these as well with GNUstep-startup 0.25.
1494      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1495      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1496      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1497        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1498      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1499        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1500      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1501      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1502      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1503      LIB_STANDARD=
1504      START_FILES=
1505      TEMACS_LDFLAGS2=
1506      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1507      dnl If they had chosen to either define it or not, we could have
1508      dnl just used AC_CHECK_DECL here.
1509      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1510        emacs_cv_objc_exceptions,
1511 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1512 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1513 1;
1514 #else
1515 fail;
1516 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1517      if test $emacs_cv_objc_exceptions = yes; then
1518        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1519        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1520          [Define if GNUstep uses ObjC exceptions.])
1521        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1522      fi
1523   fi
1524
1525   dnl This is only used while we test the NS headers, it gets reset below.
1526   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1527
1528   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1529                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1530   files are missing or cannot be compiled.])])
1531
1532   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1533                                      [
1534 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1535 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1040
1536  ; /* OK */
1537 #else
1538 #error "OSX 10.4 or newer required"
1539 #endif
1540 #endif
1541                     ])],
1542                     ns_osx_have_104=yes,
1543                     ns_osx_have_104=no)
1544   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1545                                      [NSInteger i;])],
1546                     ns_have_nsinteger=yes,
1547                     ns_have_nsinteger=no)
1548   if test $ns_osx_have_104 = no; then
1549      AC_MSG_ERROR([`OSX 10.4 or newer is required']);
1550   fi
1551   if test $ns_have_nsinteger = yes; then
1552     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1553   fi
1554 fi
1555
1556 AC_SUBST(TEMACS_LDFLAGS2)
1557
1558 INSTALL_ARCH_INDEP_EXTRA=install-etc
1559 ns_self_contained=no
1560 NS_OBJ=
1561 NS_OBJC_OBJ=
1562 if test "${HAVE_NS}" = yes; then
1563   if test "$with_toolkit_scroll_bars" = "no"; then
1564     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1565   fi
1566
1567   window_system=nextstep
1568   # set up packaging dirs
1569   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1570      ns_self_contained=yes
1571      prefix=${ns_appresdir}
1572      exec_prefix=${ns_appbindir}
1573      dnl This one isn't really used, only archlibdir is.
1574      libexecdir="\${ns_appbindir}/libexec"
1575      archlibdir="\${ns_appbindir}/libexec"
1576      docdir="\${ns_appresdir}/etc"
1577      etcdir="\${ns_appresdir}/etc"
1578      dnl FIXME maybe set datarootdir instead.
1579      dnl That would also get applications, icons, man.
1580      infodir="\${ns_appresdir}/info"
1581      mandir="\${ns_appresdir}/man"
1582      lispdir="\${ns_appresdir}/lisp"
1583      leimdir="\${ns_appresdir}/leim"
1584      INSTALL_ARCH_INDEP_EXTRA=
1585   fi
1586   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1587 fi
1588 CFLAGS="$tmp_CFLAGS"
1589 CPPFLAGS="$tmp_CPPFLAGS"
1590 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1591 AC_SUBST(ns_self_contained)
1592 AC_SUBST(NS_OBJ)
1593 AC_SUBST(NS_OBJC_OBJ)
1594 AC_SUBST(LIB_STANDARD)
1595
1596 HAVE_W32=no
1597 W32_OBJ=
1598 W32_LIBS=
1599 W32_RES=
1600 W32_RES_LINK=
1601 if test "${with_w32}" != no; then
1602   if test "${opsys}" != "cygwin"; then
1603     AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin.])
1604   fi
1605   AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1606                   [AC_MSG_ERROR([`--with-w32' was specified, but windows.h
1607                   cannot be found.])])
1608   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1609   AC_CHECK_TOOL(WINDRES, [windres],
1610                 [AC_MSG_ERROR([No resource compiler found.])])
1611   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1612   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1613   W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1614   W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1615   W32_RES="emacs.res"
1616   # Tell the linker that emacs.res is an object (which we compile from
1617   # the rc file), not a linker script.
1618   W32_RES_LINK="-Wl,-bpe-i386 -Wl,emacs.res"
1619 fi
1620 AC_SUBST(W32_OBJ)
1621 AC_SUBST(W32_LIBS)
1622 AC_SUBST(W32_RES)
1623 AC_SUBST(W32_RES_LINK)
1624
1625 if test "${HAVE_W32}" = "yes"; then
1626   window_system=w32
1627   with_xft=no
1628 fi
1629
1630 ## $window_system is now set to the window system we will
1631 ## ultimately use.
1632
1633 term_header=
1634 HAVE_X_WINDOWS=no
1635 HAVE_X11=no
1636 USE_X_TOOLKIT=none
1637
1638 case "${window_system}" in
1639   x11 )
1640     HAVE_X_WINDOWS=yes
1641     HAVE_X11=yes
1642     term_header=xterm.h
1643     case "${with_x_toolkit}" in
1644       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1645       motif ) USE_X_TOOLKIT=MOTIF ;;
1646       gtk ) with_gtk=yes
1647             term_header=gtkutil.h
1648 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1649 dnl USE_X_TOOLKIT is set.
1650             USE_X_TOOLKIT=none ;;
1651       gtk2 ) with_gtk2=yes
1652              term_header=gtkutil.h
1653              USE_X_TOOLKIT=none ;;
1654       gtk3 ) with_gtk3=yes
1655              term_header=gtkutil.h
1656              USE_X_TOOLKIT=none ;;
1657       no ) USE_X_TOOLKIT=none ;;
1658 dnl If user did not say whether to use a toolkit, make this decision later:
1659 dnl use the toolkit if we have gtk, or X11R5 or newer.
1660       * ) USE_X_TOOLKIT=maybe ;;
1661     esac
1662   ;;
1663   nextstep )
1664     term_header=nsterm.h
1665   ;;
1666   w32 )
1667     term_header=w32term.h
1668   ;;
1669 esac
1670
1671 if test -n "${term_header}"; then
1672     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
1673         [Define to the header for the built-in window system.])
1674 fi
1675
1676 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1677    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1678    if test "$HAVE_XSERVER" = true ||
1679       test -n "$DISPLAY" ||
1680       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1681         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1682 were found.  You should install the relevant development files for X
1683 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1684 sure you have development files for image handling, i.e.
1685 tiff, gif, jpeg, png and xpm.
1686 If you are sure you want Emacs compiled without X window support, pass
1687   --without-x
1688 to configure.])
1689    fi
1690 fi
1691
1692 ### If we're using X11, we should use the X menu package.
1693 HAVE_MENUS=no
1694 case ${HAVE_X11} in
1695   yes ) HAVE_MENUS=yes ;;
1696 esac
1697
1698 # Does the opsystem file prohibit the use of the GNU malloc?
1699 # Assume not, until told otherwise.
1700 GNU_MALLOC=yes
1701
1702 AC_CACHE_CHECK(
1703   [whether malloc is Doug Lea style],
1704   [emacs_cv_var_doug_lea_malloc],
1705   [AC_LINK_IFELSE(
1706      [AC_LANG_PROGRAM(
1707         [[#include <malloc.h>
1708           static void hook (void) {}]],
1709         [[malloc_set_state (malloc_get_state ());
1710           __after_morecore_hook = hook;
1711           __malloc_initialize_hook = hook;]])],
1712      [emacs_cv_var_doug_lea_malloc=yes],
1713      [emacs_cv_var_doug_lea_malloc=no])])
1714 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1715
1716
1717 dnl See comments in aix4-2.h about maybe using system malloc there.
1718 system_malloc=no
1719 case "$opsys" in
1720   ## darwin ld insists on the use of malloc routines in the System framework.
1721   darwin|sol2-10) system_malloc=yes ;;
1722 esac
1723
1724 if test "${system_malloc}" = "yes"; then
1725   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1726   GNU_MALLOC=no
1727   GNU_MALLOC_reason="
1728     (The GNU allocators don't work with this system configuration.)"
1729   GMALLOC_OBJ=
1730   VMLIMIT_OBJ=
1731 else
1732   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1733   VMLIMIT_OBJ=vm-limit.o
1734 fi
1735 AC_SUBST(GMALLOC_OBJ)
1736 AC_SUBST(VMLIMIT_OBJ)
1737
1738 if test "$doug_lea_malloc" = "yes" ; then
1739   if test "$GNU_MALLOC" = yes ; then
1740     GNU_MALLOC_reason="
1741       (Using Doug Lea's new malloc from the GNU C Library.)"
1742   fi
1743   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1744             [Define to 1 if you are using the GNU C Library.])
1745
1746   ## Use mmap directly for allocating larger buffers.
1747   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1748   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1749   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1750   case "$opsys" in
1751     gnu*) REL_ALLOC=no ;;
1752   esac
1753 fi
1754
1755 if test x"${REL_ALLOC}" = x; then
1756   REL_ALLOC=${GNU_MALLOC}
1757 fi
1758
1759 use_mmap_for_buffers=no
1760 case "$opsys" in
1761   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1762 esac
1763
1764 AC_FUNC_MMAP
1765 if test $use_mmap_for_buffers = yes; then
1766   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1767   REL_ALLOC=no
1768 fi
1769
1770 LIBS="$LIBS_SYSTEM $LIBS"
1771
1772 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1773 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1774 AC_CHECK_LIB(dnet, dnet_ntoa)
1775 dnl This causes -lresolv to get used in subsequent tests,
1776 dnl which causes failures on some systems such as HPUX 9.
1777 dnl AC_CHECK_LIB(resolv, gethostbyname)
1778
1779 dnl FIXME replace main with a function we actually want from this library.
1780 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1781
1782 dnl Check if pthreads is available.
1783 LIB_PTHREAD=
1784 AC_CHECK_HEADERS_ONCE(pthread.h)
1785 if test "$ac_cv_header_pthread_h"; then
1786   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1787   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1788   dnl testing for pthread_self if Emacs uses gmalloc.c.
1789   if test "$GMALLOC_OBJ" = gmalloc.o; then
1790     emacs_pthread_function=pthread_atfork
1791   else
1792     emacs_pthread_function=pthread_self
1793   fi
1794   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1795 fi
1796 if test "$HAVE_PTHREAD" = yes; then
1797   case "${canonical}" in
1798     *-hpux*) ;;
1799     *) LIB_PTHREAD="-lpthread"
1800        LIBS="$LIB_PTHREAD $LIBS" ;;
1801   esac
1802   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1803 fi
1804 AC_SUBST([LIB_PTHREAD])
1805
1806 AC_CHECK_LIB(pthreads, cma_open)
1807
1808 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1809 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1810 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1811 ## added to LIBS in configure would never contain the pthreads part,
1812 ## but the value used in Makefiles might.  FIXME?
1813 ##
1814 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1815 ## be harmless on older versions of X where it happens to exist.
1816 test "$opsys" = "aix4-2" && \
1817   test $ac_cv_lib_pthreads_cma_open = yes && \
1818   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1819
1820 dnl Check for need for bigtoc support on IBM AIX
1821
1822 case ${host_os} in
1823 aix*)
1824   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1825     case $GCC in
1826     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1827     *) gdb_cv_bigtoc=-bbigtoc ;;
1828     esac
1829
1830     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1831     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1832   ])
1833   ;;
1834 esac
1835
1836 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1837 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1838 # REAL_CPPFLAGS later on.
1839
1840 REAL_CFLAGS="$CFLAGS"
1841 REAL_CPPFLAGS="$CPPFLAGS"
1842
1843 if test "${HAVE_X11}" = "yes"; then
1844   DEFS="$C_SWITCH_X_SITE $DEFS"
1845   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1846   LIBS="-lX11 $LIBS"
1847   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1848   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1849
1850   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1851   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1852   # but it's more convenient here to set LD_RUN_PATH since this
1853   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1854   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1855     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1856     export LD_RUN_PATH
1857   fi
1858
1859   if test "${opsys}" = "gnu-linux"; then
1860     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1861     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1862      [[XOpenDisplay ("foo");]])],
1863      [xgnu_linux_first_failure=no],
1864      [xgnu_linux_first_failure=yes])
1865     if test "${xgnu_linux_first_failure}" = "yes"; then
1866       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1867       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1868       OLD_CPPFLAGS="$CPPFLAGS"
1869       OLD_LIBS="$LIBS"
1870       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1871       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1872       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1873       LIBS="$LIBS -b i486-linuxaout"
1874       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1875        [[XOpenDisplay ("foo");]])],
1876        [xgnu_linux_second_failure=no],
1877        [xgnu_linux_second_failure=yes])
1878       if test "${xgnu_linux_second_failure}" = "yes"; then
1879         # If we get the same failure with -b, there is no use adding -b.
1880         # So take it out.  This plays safe.
1881         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1882         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1883         CPPFLAGS="$OLD_CPPFLAGS"
1884         LIBS="$OLD_LIBS"
1885         AC_MSG_RESULT(no)
1886       else
1887         AC_MSG_RESULT(yes)
1888       fi
1889     else
1890       AC_MSG_RESULT(no)
1891     fi
1892   fi
1893
1894   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1895   # header files included from there.
1896   AC_MSG_CHECKING(for Xkb)
1897   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1898 #include <X11/XKBlib.h>]],
1899         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1900         emacs_xkb=yes, emacs_xkb=no)
1901   AC_MSG_RESULT($emacs_xkb)
1902   if test $emacs_xkb = yes; then
1903     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1904   fi
1905
1906   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1907 XScreenNumberOfScreen)
1908 fi
1909
1910 if test "${window_system}" = "x11"; then
1911   AC_MSG_CHECKING(X11 version 6)
1912   AC_CACHE_VAL(emacs_cv_x11_version_6,
1913   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1914 [[#if XlibSpecificationRelease < 6
1915 fail;
1916 #endif
1917 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1918   if test $emacs_cv_x11_version_6 = yes; then
1919     AC_MSG_RESULT(6 or newer)
1920     AC_DEFINE(HAVE_X11R6, 1,
1921               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1922     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1923     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1924     ## XIM support.
1925     case "$opsys" in
1926       sol2-*) : ;;
1927       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1928            [Define if you have usable X11R6-style XIM support.])
1929          ;;
1930     esac
1931   else
1932     AC_MSG_RESULT(before 6)
1933   fi
1934 fi
1935
1936
1937 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1938 HAVE_RSVG=no
1939 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1940   if test "${with_rsvg}" != "no"; then
1941     RSVG_REQUIRED=2.11.0
1942     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1943
1944     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1945     AC_SUBST(RSVG_CFLAGS)
1946     AC_SUBST(RSVG_LIBS)
1947
1948     if test $HAVE_RSVG = yes; then
1949       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1950       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1951       LIBS="$RSVG_LIBS $LIBS"
1952     fi
1953   fi
1954 fi
1955
1956 HAVE_IMAGEMAGICK=no
1957 if test "${HAVE_X11}" = "yes"; then
1958   if test "${with_imagemagick}" != "no"; then
1959     ## 6.2.8 is the earliest version known to work, but earlier versions
1960     ## might work - let us know if you find one.
1961     ## 6.0.7 does not work.  See bug#7955.
1962     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1963     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1964     AC_SUBST(IMAGEMAGICK_CFLAGS)
1965     AC_SUBST(IMAGEMAGICK_LIBS)
1966
1967     if test $HAVE_IMAGEMAGICK = yes; then
1968       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1969       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1970       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1971       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
1972     fi
1973   fi
1974 fi
1975
1976
1977 HAVE_GTK=no
1978 GTK_OBJ=
1979 check_gtk2=no
1980 gtk3_pkg_errors=
1981 if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1982   GLIB_REQUIRED=2.28
1983   GTK_REQUIRED=3.0
1984   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1985
1986   dnl Checks for libraries.
1987   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1988   if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
1989      AC_MSG_ERROR($GTK_PKG_ERRORS)
1990   fi
1991   if test "$pkg_check_gtk" = "yes"; then
1992      AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1993      GTK_OBJ=emacsgtkfixed.o
1994      term_header=gtkutil.h
1995      USE_GTK_TOOLKIT="GTK3"
1996   else
1997      check_gtk2=yes
1998      gtk3_pkg_errors="$GTK_PKG_ERRORS "
1999   fi
2000 fi
2001
2002 if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2003   GLIB_REQUIRED=2.10
2004   GTK_REQUIRED=2.10
2005   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2006
2007   dnl Checks for libraries.
2008   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2009   if test "$pkg_check_gtk" = "no" &&
2010      { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2011   then
2012     AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2013   fi
2014   test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2015 fi
2016
2017 if test x"$pkg_check_gtk" = xyes; then
2018
2019   AC_SUBST(GTK_CFLAGS)
2020   AC_SUBST(GTK_LIBS)
2021   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2022   CFLAGS="$CFLAGS $GTK_CFLAGS"
2023   LIBS="$GTK_LIBS $LIBS"
2024   dnl Try to compile a simple GTK program.
2025   GTK_COMPILES=no
2026   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
2027   if test "${GTK_COMPILES}" != "yes"; then
2028     if test "$USE_X_TOOLKIT" != "maybe"; then
2029       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2030     fi
2031   else
2032     HAVE_GTK=yes
2033     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2034     GTK_OBJ="gtkutil.o $GTK_OBJ"
2035     USE_X_TOOLKIT=none
2036     if "$PKG_CONFIG" --atleast-version=2.10 gtk+-2.0; then
2037       :
2038     else
2039       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2040        closing open displays.  This is no problem if you just use
2041        one display, but if you use more than one and close one of them
2042        Emacs may crash.]])
2043       sleep 3
2044     fi
2045   fi
2046
2047 fi
2048 AC_SUBST(GTK_OBJ)
2049
2050
2051 if test "${HAVE_GTK}" = "yes"; then
2052
2053   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2054   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2055   if test "$with_toolkit_scroll_bars" != no; then
2056     with_toolkit_scroll_bars=yes
2057   fi
2058
2059   dnl  Check if we have the old file selection dialog declared and
2060   dnl  in the link library.  In 2.x it may be in the library,
2061   dnl  but not declared if deprecated featured has been selected out.
2062   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2063   HAVE_GTK_FILE_SELECTION=no
2064   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2065                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2066 #include <gtk/gtk.h>])
2067   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2068     AC_CHECK_FUNCS(gtk_file_selection_new)
2069   fi
2070
2071
2072   dnl Check for functions introduced in 2.14 and later.
2073   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2074                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2075                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2076                  gtk_orientable_set_orientation \
2077                  gtk_window_set_has_resize_grip)
2078
2079  term_header=gtkutil.h
2080 fi
2081
2082 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2083 dnl other platforms.
2084 HAVE_DBUS=no
2085 DBUS_OBJ=
2086 if test "${with_dbus}" = "yes"; then
2087    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2088    if test "$HAVE_DBUS" = yes; then
2089      LIBS="$LIBS $DBUS_LIBS"
2090      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2091      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2092      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2093      dnl D-Bus 1.5.12.
2094      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2095                     dbus_type_is_valid \
2096                     dbus_validate_bus_name \
2097                     dbus_validate_path \
2098                     dbus_validate_interface \
2099                     dbus_validate_member)
2100      DBUS_OBJ=dbusbind.o
2101    fi
2102 fi
2103 AC_SUBST(DBUS_OBJ)
2104
2105 dnl GSettings has been tested under GNU/Linux only.
2106 HAVE_GSETTINGS=no
2107 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2108    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2109    if test "$HAVE_GSETTINGS" = "yes"; then
2110       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2111       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2112       SETTINGS_LIBS="$GSETTINGS_LIBS"
2113    fi
2114 fi
2115
2116 dnl GConf has been tested under GNU/Linux only.
2117 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2118 HAVE_GCONF=no
2119 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2120    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2121    if test "$HAVE_GCONF" = yes; then
2122       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2123       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2124       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2125       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2126    fi
2127 fi
2128
2129 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2130     PKG_CHECK_MODULES(GOBJECT, gobject-2.0 >= 2.0, HAVE_GOBJECT=yes, HAVE_GOBJECT=no)
2131     if test "$HAVE_GOBJECT" = "yes"; then
2132        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2133        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2134     fi
2135     SAVE_CFLAGS="$CFLAGS"
2136     SAVE_LIBS="$LIBS"
2137     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2138     LIBS="$SETTINGS_LIBS $LIBS"
2139     AC_CHECK_FUNCS([g_type_init])
2140     CFLAGS="$SAVE_CFLAGS"
2141     LIBS="$SAVE_LIBS"
2142 fi
2143 AC_SUBST(SETTINGS_CFLAGS)
2144 AC_SUBST(SETTINGS_LIBS)
2145
2146
2147 dnl SELinux is available for GNU/Linux only.
2148 HAVE_LIBSELINUX=no
2149 LIBSELINUX_LIBS=
2150 if test "${with_selinux}" = "yes"; then
2151    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2152    if test "$HAVE_LIBSELINUX" = yes; then
2153       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2154       LIBSELINUX_LIBS=-lselinux
2155    fi
2156 fi
2157 AC_SUBST(LIBSELINUX_LIBS)
2158
2159 HAVE_GNUTLS=no
2160 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2161 if test "${with_gnutls}" = "yes" ; then
2162   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2163   if test "${HAVE_GNUTLS}" = "yes"; then
2164     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2165   fi
2166
2167   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2168   LIBS="$LIBGNUTLS_LIBS $LIBS"
2169   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2170
2171   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2172     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2173   fi
2174 fi
2175
2176 AC_SUBST(LIBGNUTLS_LIBS)
2177 AC_SUBST(LIBGNUTLS_CFLAGS)
2178
2179 dnl inotify is only available on GNU/Linux.
2180 if test "${with_inotify}" = "yes"; then
2181    AC_CHECK_HEADERS(sys/inotify.h)
2182    if test "$ac_cv_header_sys_inotify_h" = yes ; then
2183      AC_CHECK_FUNC(inotify_init1)
2184    fi
2185 fi
2186 if test "$ac_cv_func_inotify_init1" = yes; then
2187   AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2188 fi
2189
2190 dnl POSIX ACL support: provided by libacl on GNU/Linux, by libc on FreeBSD.
2191 HAVE_POSIX_ACL=no
2192 LIBACL_LIBS=
2193 if test "${with_acl}" = "yes"; then
2194   AC_CHECK_LIB([acl], [acl_set_file], HAVE_POSIX_ACL=yes, HAVE_POSIX_ACL=no)
2195   if test "$HAVE_POSIX_ACL" = yes; then
2196     AC_DEFINE(HAVE_POSIX_ACL, 1, [Define to 1 if using POSIX ACL support.])
2197     LIBACL_LIBS=-lacl
2198   else
2199     AC_CHECK_FUNC(acl_set_file, HAVE_POSIX_ACL=yes, HAVE_POSIX_ACL=no)
2200     if test "$HAVE_POSIX_ACL" = yes; then
2201       AC_DEFINE(HAVE_POSIX_ACL, 1, [Define to 1 if using POSIX ACL support.])
2202     fi
2203  fi
2204 fi
2205 AC_SUBST(LIBACL_LIBS)
2206
2207 dnl Do not put whitespace before the #include statements below.
2208 dnl Older compilers (eg sunos4 cc) choke on it.
2209 HAVE_XAW3D=no
2210 LUCID_LIBW=
2211 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2212   if test "$with_xaw3d" != no; then
2213     AC_CACHE_VAL(emacs_cv_xaw3d,
2214     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2215 #include <X11/Intrinsic.h>
2216 #include <X11/Xaw3d/Simple.h>]],
2217       [[]])],
2218       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2219                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2220       emacs_cv_xaw3d=no)])
2221   else
2222     emacs_cv_xaw3d=no
2223   fi
2224   if test $emacs_cv_xaw3d = yes; then
2225     AC_MSG_CHECKING(for xaw3d)
2226     AC_MSG_RESULT([yes; using Lucid toolkit])
2227     USE_X_TOOLKIT=LUCID
2228     HAVE_XAW3D=yes
2229     LUCID_LIBW=-lXaw3d
2230     AC_DEFINE(HAVE_XAW3D, 1,
2231               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2232   else
2233     AC_MSG_CHECKING(for xaw3d)
2234     AC_MSG_RESULT(no)
2235     AC_MSG_CHECKING(for libXaw)
2236     AC_CACHE_VAL(emacs_cv_xaw,
2237     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2238 #include <X11/Intrinsic.h>
2239 #include <X11/Xaw/Simple.h>]],
2240       [[]])],
2241       emacs_cv_xaw=yes,
2242       emacs_cv_xaw=no)])
2243     if test $emacs_cv_xaw = yes; then
2244       AC_MSG_RESULT([yes; using Lucid toolkit])
2245       USE_X_TOOLKIT=LUCID
2246       LUCID_LIBW=-lXaw
2247     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2248       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2249     else
2250       AC_MSG_ERROR([No X toolkit could be found.
2251 If you are sure you want Emacs compiled without an X toolkit, pass
2252   --with-x-toolkit=no
2253 to configure.  Otherwise, install the development libraries for the toolkit
2254 that you want to use (e.g. Gtk+) and re-run configure.])
2255     fi
2256   fi
2257 fi
2258
2259 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2260
2261 LIBXTR6=
2262 if test "${USE_X_TOOLKIT}" != "none"; then
2263   AC_MSG_CHECKING(X11 toolkit version)
2264   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2265   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2266 [[#if XtSpecificationRelease < 6
2267 fail;
2268 #endif
2269 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2270   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2271   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2272     AC_MSG_RESULT(6 or newer)
2273     AC_DEFINE(HAVE_X11XTR6, 1,
2274               [Define to 1 if you have the X11R6 or newer version of Xt.])
2275     LIBXTR6="-lSM -lICE"
2276     case "$opsys" in
2277       ## Use libw.a along with X11R6 Xt.
2278       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2279     esac
2280   else
2281     AC_MSG_RESULT(before 6)
2282   fi
2283
2284 dnl If using toolkit, check whether libXmu.a exists.
2285 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2286   OLDLIBS="$LIBS"
2287   if test x$HAVE_X11XTR6 = xyes; then
2288     LIBS="-lXt -lSM -lICE $LIBS"
2289   else
2290     LIBS="-lXt $LIBS"
2291   fi
2292   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2293   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2294   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2295 fi
2296 AC_SUBST(LIBXTR6)
2297
2298 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2299 dnl Why not just test for libxmu in the normal way?
2300 LIBXMU=-lXmu
2301 case $opsys in
2302   ## These systems don't supply Xmu.
2303   hpux* | aix4-2 )
2304     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2305     ;;
2306 esac
2307 AC_SUBST(LIBXMU)
2308
2309 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2310 if test "${HAVE_X11}" = "yes"; then
2311   if test "${USE_X_TOOLKIT}" != "none"; then
2312     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2313   fi
2314 fi
2315
2316 LIBXP=
2317 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2318   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2319   if test -d /usr/include/openmotif; then
2320     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2321     emacs_cv_openmotif=yes
2322     case "$canonical" in
2323       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2324       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2325       ;;
2326       *)
2327       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2328     esac
2329   else
2330     emacs_cv_openmotif=no
2331   fi
2332   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2333   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2334     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2335 int x = 5;
2336 #else
2337 Motif version prior to 2.1.
2338 #endif]])],
2339     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2340   if test $emacs_cv_motif_version_2_1 = yes; then
2341     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2342     if test x$emacs_cv_openmotif = xyes; then
2343       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2344     fi
2345   else
2346     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2347     # We put this in CFLAGS temporarily to precede other -I options
2348     # that might be in CFLAGS temporarily.
2349     # We put this in CPPFLAGS where it precedes the other -I options.
2350     OLD_CPPFLAGS=$CPPFLAGS
2351     OLD_CFLAGS=$CFLAGS
2352     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2353     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2354     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2355       [[int x = 5;]])],
2356       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2357     if test $emacs_cv_lesstif = yes; then
2358       # Make sure this -I option remains in CPPFLAGS after it is set
2359       # back to REAL_CPPFLAGS.
2360       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2361       # have those other -I options anyway.  Ultimately, having this
2362       # directory ultimately in CPPFLAGS will be enough.
2363       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2364       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2365     else
2366       CFLAGS=$OLD_CFLAGS
2367       CPPFLAGS=$OLD_CPPFLAGS
2368     fi
2369   fi
2370   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2371     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2372 fi
2373
2374 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2375 dnl using Motif or Xaw3d is available, and unless
2376 dnl --with-toolkit-scroll-bars=no was specified.
2377
2378 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2379             [Define to 1 if we should use toolkit scroll bars.])dnl
2380 USE_TOOLKIT_SCROLL_BARS=no
2381 if test "${with_toolkit_scroll_bars}" != "no"; then
2382   if test "${USE_X_TOOLKIT}" != "none"; then
2383     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2384       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2385       HAVE_XAW3D=no
2386       USE_TOOLKIT_SCROLL_BARS=yes
2387     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2388       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2389       USE_TOOLKIT_SCROLL_BARS=yes
2390     fi
2391   elif test "${HAVE_GTK}" = "yes"; then
2392     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2393     USE_TOOLKIT_SCROLL_BARS=yes
2394   elif test "${HAVE_NS}" = "yes"; then
2395     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2396     USE_TOOLKIT_SCROLL_BARS=yes
2397   elif test "${HAVE_W32}" = "yes"; then
2398     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2399     USE_TOOLKIT_SCROLL_BARS=yes
2400   fi
2401 fi
2402
2403 dnl See if XIM is available.
2404 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2405           #include <X11/Xlib.h>
2406           #include <X11/Xresource.h>]],
2407          [[XIMProc  callback;]])],
2408          [HAVE_XIM=yes
2409          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2410          HAVE_XIM=no)
2411
2412 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2413
2414 if test "${with_xim}" != "no"; then
2415   AC_DEFINE(USE_XIM, 1,
2416             [Define to 1 if we should use XIM, if it is available.])
2417 fi
2418
2419
2420 if test "${HAVE_XIM}" != "no"; then
2421   late_CFLAGS=$CFLAGS
2422   if test "$GCC" = yes; then
2423     CFLAGS="$CFLAGS --pedantic-errors"
2424   fi
2425   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2426 #include <X11/Xlib.h>
2427 #include <X11/Xresource.h>]],
2428 [[Display *display;
2429 XrmDatabase db;
2430 char *res_name;
2431 char *res_class;
2432 XIMProc  callback;
2433 XPointer *client_data;
2434 #ifndef __GNUC__
2435 /* If we're not using GCC, it's probably not XFree86, and this is
2436    probably right, but we can't use something like --pedantic-errors.  */
2437 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2438                                            char*, XIMProc, XPointer*);
2439 #endif
2440 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2441    client_data);]])],
2442     [emacs_cv_arg6_star=yes])
2443   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2444          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2445 either XPointer or XPointer*.])dnl
2446   if test "$emacs_cv_arg6_star" = yes; then
2447     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2448   else
2449     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2450   fi
2451   CFLAGS=$late_CFLAGS
2452 fi
2453
2454 ### Start of font-backend (under any platform) section.
2455 # (nothing here yet -- this is a placeholder)
2456 ### End of font-backend (under any platform) section.
2457
2458 ### Start of font-backend (under X11) section.
2459 if test "${HAVE_X11}" = "yes"; then
2460    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2461
2462    ## Use -lXft if available, unless `--with-xft=no'.
2463    HAVE_XFT=maybe
2464     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2465       with_xft="no";
2466     fi
2467     if test "x${with_xft}" != "xno"; then
2468
2469       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2470       ## Because xftfont.c uses XRenderQueryExtension, we also
2471       ## need to link to -lXrender.
2472       HAVE_XRENDER=no
2473       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2474       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2475         OLD_CPPFLAGS="$CPPFLAGS"
2476         OLD_CFLAGS="$CFLAGS"
2477         OLD_LIBS="$LIBS"
2478         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2479         CFLAGS="$CFLAGS $XFT_CFLAGS"
2480         XFT_LIBS="-lXrender $XFT_LIBS"
2481         LIBS="$XFT_LIBS $LIBS"
2482         AC_CHECK_HEADER(X11/Xft/Xft.h,
2483           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2484
2485         if test "${HAVE_XFT}" = "yes"; then
2486           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2487             AC_SUBST(XFT_LIBS)
2488           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2489         else
2490           CPPFLAGS="$OLD_CPPFLAGS"
2491           CFLAGS="$OLD_CFLAGS"
2492           LIBS="$OLD_LIBS"
2493         fi                        # "${HAVE_XFT}" = "yes"
2494       fi                          # "$HAVE_XFT" != no
2495     fi                            # "x${with_xft}" != "xno"
2496
2497     ## We used to allow building with FreeType and without Xft.
2498     ## However, the ftx font backend driver is not in good shape.
2499     if test "$HAVE_XFT" != "yes"; then
2500        dnl For the "Does Emacs use" message at the end.
2501        HAVE_XFT=no
2502        HAVE_FREETYPE=no
2503     else
2504        dnl Strict linkers fail with
2505        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2506        dnl if -lfreetype is not specified.
2507        dnl The following is needed to set FREETYPE_LIBS.
2508        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2509                          HAVE_FREETYPE=no)
2510
2511        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2512     fi
2513
2514     HAVE_LIBOTF=no
2515     if test "${HAVE_FREETYPE}" = "yes"; then
2516       AC_DEFINE(HAVE_FREETYPE, 1,
2517                 [Define to 1 if using the freetype and fontconfig libraries.])
2518       if test "${with_libotf}" != "no"; then
2519         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2520                           HAVE_LIBOTF=no)
2521         if test "$HAVE_LIBOTF" = "yes"; then
2522           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2523           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2524                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2525                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2526           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2527             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2528                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2529           fi
2530         fi
2531       fi
2532     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2533     dnl Does the new font backend require it, or can it work without it?
2534     fi
2535
2536     HAVE_M17N_FLT=no
2537     if test "${HAVE_LIBOTF}" = yes; then
2538       if test "${with_m17n_flt}" != "no"; then
2539         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2540         if test "$HAVE_M17N_FLT" = "yes"; then
2541           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2542         fi
2543       fi
2544     fi
2545 else
2546     HAVE_XFT=no
2547     HAVE_FREETYPE=no
2548     HAVE_LIBOTF=no
2549     HAVE_M17N_FLT=no
2550 fi
2551
2552 ### End of font-backend (under X11) section.
2553
2554 AC_SUBST(FREETYPE_CFLAGS)
2555 AC_SUBST(FREETYPE_LIBS)
2556 AC_SUBST(FONTCONFIG_CFLAGS)
2557 AC_SUBST(FONTCONFIG_LIBS)
2558 AC_SUBST(LIBOTF_CFLAGS)
2559 AC_SUBST(LIBOTF_LIBS)
2560 AC_SUBST(M17N_FLT_CFLAGS)
2561 AC_SUBST(M17N_FLT_LIBS)
2562
2563 ### Use -lXpm if available, unless `--with-xpm=no'.
2564 HAVE_XPM=no
2565 LIBXPM=
2566
2567 if test "${HAVE_W32}" = "yes"; then
2568   if test "${with_xpm}" != "no"; then
2569     SAVE_CPPFLAGS="$CPPFLAGS"
2570     SAVE_LDFLAGS="$LDFLAGS"
2571     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
2572     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
2573     AC_CHECK_HEADER(X11/xpm.h,
2574       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
2575     if test "${HAVE_XPM}" = "yes"; then
2576       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2577       AC_EGREP_CPP(no_return_alloc_pixels,
2578       [#include "X11/xpm.h"
2579 #ifndef XpmReturnAllocPixels
2580 no_return_alloc_pixels
2581 #endif
2582       ], HAVE_XPM=no, HAVE_XPM=yes)
2583
2584       if test "${HAVE_XPM}" = "yes"; then
2585         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
2586         AC_MSG_RESULT(yes)
2587       else
2588         AC_MSG_RESULT(no)
2589         CPPFLAGS="$SAVE_CPPFLAGS"
2590         LDFLAGS="$SAVE_LDFLAGS"
2591       fi
2592     fi
2593   fi
2594
2595   if test "${HAVE_XPM}" = "yes"; then
2596     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2597     LIBXPM=-lXpm
2598   fi
2599 fi
2600
2601 if test "${HAVE_X11}" = "yes"; then
2602   if test "${with_xpm}" != "no"; then
2603     AC_CHECK_HEADER(X11/xpm.h,
2604       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2605     if test "${HAVE_XPM}" = "yes"; then
2606       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2607       AC_EGREP_CPP(no_return_alloc_pixels,
2608       [#include "X11/xpm.h"
2609 #ifndef XpmReturnAllocPixels
2610 no_return_alloc_pixels
2611 #endif
2612       ], HAVE_XPM=no, HAVE_XPM=yes)
2613
2614       if test "${HAVE_XPM}" = "yes"; then
2615         AC_MSG_RESULT(yes)
2616       else
2617         AC_MSG_RESULT(no)
2618       fi
2619     fi
2620   fi
2621
2622   if test "${HAVE_XPM}" = "yes"; then
2623     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2624     LIBXPM=-lXpm
2625   fi
2626 fi
2627
2628 AC_SUBST(LIBXPM)
2629
2630 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2631 HAVE_JPEG=no
2632 LIBJPEG=
2633 if test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2634   if test "${with_jpeg}" != "no"; then
2635     dnl Checking for jpeglib.h can lose because of a redefinition of
2636     dnl  HAVE_STDLIB_H.
2637     AC_CHECK_HEADER(jerror.h,
2638       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2639   fi
2640
2641   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2642   if test "${HAVE_JPEG}" = "yes"; then
2643     AC_DEFINE(HAVE_JPEG)
2644     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2645         [#include <jpeglib.h>
2646          version=JPEG_LIB_VERSION
2647 ],
2648         [AC_DEFINE(HAVE_JPEG)],
2649         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2650         HAVE_JPEG=no])
2651   fi
2652   if test "${HAVE_JPEG}" = "yes"; then
2653     LIBJPEG=-ljpeg
2654   fi
2655 fi
2656 AC_SUBST(LIBJPEG)
2657
2658 ### Use -lpng if available, unless `--with-png=no'.
2659 HAVE_PNG=no
2660 LIBPNG=
2661 if test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2662   if test "${with_png}" != "no"; then
2663     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2664     # in /usr/include/libpng.
2665     AC_CHECK_HEADERS(png.h libpng/png.h, break)
2666     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2667       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2668     fi
2669   fi
2670
2671   if test "${HAVE_PNG}" = "yes"; then
2672     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2673     LIBPNG="-lpng -lz -lm"
2674
2675     AC_CHECK_DECL(png_longjmp,
2676       [],
2677       [AC_DEFINE(PNG_DEPSTRUCT, [],
2678          [Define to empty to suppress deprecation warnings when building
2679           with --enable-gcc-warnings and with libpng versions before 1.5,
2680           which lack png_longjmp.])],
2681       [[#ifdef HAVE_LIBPNG_PNG_H
2682         # include <libpng/png.h>
2683         #else
2684         # include <png.h>
2685         #endif
2686       ]])
2687   fi
2688 fi
2689 AC_SUBST(LIBPNG)
2690
2691 ### Use -ltiff if available, unless `--with-tiff=no'.
2692 HAVE_TIFF=no
2693 LIBTIFF=
2694 if test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2695   if test "${with_tiff}" != "no"; then
2696     AC_CHECK_HEADER(tiffio.h,
2697       [tifflibs="-lz -lm"
2698       # At least one tiff package requires the jpeg library.
2699       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2700       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2701   fi
2702
2703   if test "${HAVE_TIFF}" = "yes"; then
2704     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2705     dnl FIXME -lz -lm, as per libpng?
2706     LIBTIFF=-ltiff
2707   fi
2708 fi
2709 AC_SUBST(LIBTIFF)
2710
2711 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2712 HAVE_GIF=no
2713 LIBGIF=
2714 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
2715         || test "${HAVE_W32}" = "yes"; then
2716   AC_CHECK_HEADER(gif_lib.h,
2717 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2718 # Earlier versions can crash Emacs.
2719     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2720
2721   if test "$HAVE_GIF" = yes; then
2722     LIBGIF=-lgif
2723   elif test "$HAVE_GIF" = maybe; then
2724 # If gif_lib.h but no libgif, try libungif.
2725     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2726     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2727   fi
2728
2729   if test "${HAVE_GIF}" = "yes"; then
2730     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2731   fi
2732 fi
2733 AC_SUBST(LIBGIF)
2734
2735 dnl Check for required libraries.
2736 if test "${HAVE_X11}" = "yes"; then
2737   MISSING=""
2738   WITH_NO=""
2739   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2740     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2741   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2742     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2743   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2744     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2745   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2746     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2747   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2748     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2749
2750   if test "X${MISSING}" != X; then
2751     AC_MSG_ERROR([The following required libraries were not found:
2752     $MISSING
2753 Maybe some development libraries/packages are missing?
2754 If you don't want to link with them give
2755     $WITH_NO
2756 as options to configure])
2757   fi
2758 fi
2759
2760 ### Use -lgpm if available, unless `--with-gpm=no'.
2761 HAVE_GPM=no
2762 LIBGPM=
2763 if test "${with_gpm}" != "no"; then
2764   AC_CHECK_HEADER(gpm.h,
2765     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2766
2767   if test "${HAVE_GPM}" = "yes"; then
2768     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2769     LIBGPM=-lgpm
2770   fi
2771 fi
2772 AC_SUBST(LIBGPM)
2773
2774 dnl Check for malloc/malloc.h on darwin
2775 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2776
2777 GNUSTEP_CFLAGS=
2778 ### Use NeXTstep API to implement GUI.
2779 if test "${HAVE_NS}" = "yes"; then
2780   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2781   if test "${NS_IMPL_COCOA}" = "yes"; then
2782     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2783   fi
2784   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2785     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2786     # See also .m.o rule in Makefile.in */
2787     # FIXME: are all these flags really needed?  Document here why.  */
2788     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2789     ## Extra CFLAGS applied to src/*.m files.
2790     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2791   fi
2792   # We also have mouse menus.
2793   HAVE_MENUS=yes
2794   OTHER_FILES=ns-app
2795 fi
2796
2797 if test "${HAVE_W32}" = "yes"; then
2798   HAVE_MENUS=yes
2799 fi
2800
2801 ### Use session management (-lSM -lICE) if available
2802 HAVE_X_SM=no
2803 LIBXSM=
2804 if test "${HAVE_X11}" = "yes"; then
2805   AC_CHECK_HEADER(X11/SM/SMlib.h,
2806     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2807
2808   if test "${HAVE_X_SM}" = "yes"; then
2809     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2810     LIBXSM="-lSM -lICE"
2811     case "$LIBS" in
2812       *-lSM*) ;;
2813       *)      LIBS="$LIBXSM $LIBS" ;;
2814     esac
2815   fi
2816 fi
2817 AC_SUBST(LIBXSM)
2818
2819 ### Use libxml (-lxml2) if available
2820 HAVE_LIBXML2=no
2821 if test "${with_xml2}" != "no"; then
2822   ### I'm not sure what the version number should be, so I just guessed.
2823   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2824   if test "${HAVE_LIBXML2}" = "yes"; then
2825     LIBS="$LIBXML2_LIBS $LIBS"
2826     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2827     if test "${HAVE_LIBXML2}" = "yes"; then
2828       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2829     else
2830       LIBXML2_LIBS=""
2831       LIBXML2_CFLAGS=""
2832     fi
2833   fi
2834 fi
2835 AC_SUBST(LIBXML2_LIBS)
2836 AC_SUBST(LIBXML2_CFLAGS)
2837
2838 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2839 AC_CACHE_CHECK(whether netdb declares h_errno,
2840                emacs_cv_netdb_declares_h_errno,
2841 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2842   [[return h_errno;]])],
2843   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2844 if test $emacs_cv_netdb_declares_h_errno = yes; then
2845   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2846 fi
2847
2848 # sqrt and other floating-point functions such as fmod and frexp
2849 # are found in -lm on most systems.
2850 AC_CHECK_LIB(m, sqrt)
2851
2852 # Check for mail-locking functions in a "mail" library.  Probably this should
2853 # have the same check as for liblockfile below.
2854 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2855 if test $have_mail = yes; then
2856   LIBS_MAIL=-lmail
2857   LIBS="$LIBS_MAIL $LIBS"
2858   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2859 else
2860   LIBS_MAIL=
2861 fi
2862 dnl Debian, at least:
2863 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2864 if test $have_lockfile = yes; then
2865    LIBS_MAIL=-llockfile
2866    LIBS="$LIBS_MAIL $LIBS"
2867    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2868 else
2869 # If we have the shared liblockfile, assume we must use it for mail
2870 # locking (e.g. Debian).  If we couldn't link against liblockfile
2871 # (no liblockfile.a installed), ensure that we don't need to.
2872   dnl This works for files generally, not just executables.
2873   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2874   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2875                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2876   if test $ac_cv_prog_liblockfile = yes; then
2877     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2878 This probably means that movemail could lose mail.
2879 There may be a `development' package to install containing liblockfile.])
2880   fi
2881 fi
2882 AC_CHECK_HEADERS_ONCE(maillock.h)
2883 AC_SUBST(LIBS_MAIL)
2884
2885 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2886 ## interlock access to the mail spool.  The alternative is a lock file named
2887 ## /usr/spool/mail/$USER.lock.
2888 mail_lock=no
2889 case "$opsys" in
2890   aix4-2) mail_lock="lockf" ;;
2891
2892   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2893
2894   ## On GNU/Linux systems, both methods are used by various mail programs.
2895   ## I assume most people are using newer mailers that have heard of flock.
2896   ## Change this if you need to.
2897   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2898   ## configure gets the right answers, and that means *NOT* using flock.
2899   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2900   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2901   ## Debian maintainer hasn't provided a clean fix for Emacs.
2902   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2903   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2904   ## correct logic.  -- fx
2905   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2906   ## liblockfile is a Free Software replacement for libmail, used on
2907   ## Debian systems and elsewhere. -rfr.
2908   gnu-*)
2909     mail_lock="flock"
2910     if test $have_mail = yes || test $have_lockfile = yes; then
2911       test $ac_cv_header_maillock_h = yes && mail_lock=no
2912     fi
2913     ;;
2914 esac
2915
2916 BLESSMAIL_TARGET=
2917 case "$mail_lock" in
2918   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2919
2920   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2921
2922   *) BLESSMAIL_TARGET="need-blessmail" ;;
2923 esac
2924 AC_SUBST(BLESSMAIL_TARGET)
2925
2926
2927 AC_CHECK_FUNCS(gethostname \
2928 getrusage get_current_dir_name \
2929 lrand48 \
2930 select getpagesize setlocale \
2931 utimes getrlimit setrlimit shutdown getaddrinfo \
2932 strsignal setitimer \
2933 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
2934 gai_strerror mkstemp getline getdelim fsync sync \
2935 difftime posix_memalign \
2936 getpwent endpwent getgrent endgrent \
2937 touchlock \
2938 cfmakeraw cfsetspeed copysign __executable_start)
2939
2940 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
2941 ## has a broken `rint' in some library versions including math library
2942 ## version number A.09.05.
2943 ## You can fix the math library by installing patch number PHSS_4630.
2944 ## But we can fix it more reliably for Emacs by just not using rint.
2945 ## We also skip HAVE_RANDOM - see comments in src/conf_post.h.
2946 case $opsys in
2947    hpux*) : ;;
2948    *) AC_CHECK_FUNCS(random rint) ;;
2949 esac
2950
2951 dnl Cannot use AC_CHECK_FUNCS
2952 AC_CACHE_CHECK([for __builtin_unwind_init],
2953                emacs_cv_func___builtin_unwind_init,
2954 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2955                 emacs_cv_func___builtin_unwind_init=yes,
2956                 emacs_cv_func___builtin_unwind_init=no)])
2957 if test $emacs_cv_func___builtin_unwind_init = yes; then
2958   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2959             [Define to 1 if you have the `__builtin_unwind_init' function.])
2960 fi
2961
2962 AC_CHECK_HEADERS_ONCE(sys/un.h)
2963
2964 AC_FUNC_FSEEKO
2965
2966 # UNIX98 PTYs.
2967 AC_CHECK_FUNCS(grantpt)
2968
2969 # PTY-related GNU extensions.
2970 AC_CHECK_FUNCS(getpt posix_openpt)
2971
2972 # Check this now, so that we will NOT find the above functions in ncurses.
2973 # That is because we have not set up to link ncurses in lib-src.
2974 # It's better to believe a function is not available
2975 # than to expect to find it in ncurses.
2976 # Also we need tputs and friends to be able to build at all.
2977 AC_MSG_CHECKING([for library containing tputs])
2978 # Run a test program that contains a call to tputs, a call that is
2979 # never executed.  This tests whether a pre-'main' dynamic linker
2980 # works with the library.  It's too much trouble to actually call
2981 # tputs in the test program, due to portability hassles.  When
2982 # cross-compiling, assume the test program will run if it links.
2983 AC_DEFUN([tputs_link_source], [
2984   AC_LANG_SOURCE(
2985      [[extern void tputs (const char *, int, int (*)(int));
2986        int main (int argc, char **argv)
2987        {
2988           if (argc == 10000)
2989             tputs (argv[0], 0, 0);
2990           return 0;
2991        }]])
2992 ])
2993 # Maybe curses should be tried earlier?
2994 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2995 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2996   OLIBS=$LIBS
2997   if test -z "$tputs_library"; then
2998     LIBS_TERMCAP=
2999     msg='none required'
3000   else
3001     LIBS_TERMCAP=-l$tputs_library
3002     msg=$LIBS_TERMCAP
3003     LIBS="$LIBS_TERMCAP $LIBS"
3004   fi
3005   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3006     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3007   LIBS=$OLIBS
3008   if test "X$msg" != Xno; then
3009     break
3010   fi
3011 done
3012 AC_MSG_RESULT([$msg])
3013 if test "X$msg" = Xno; then
3014   AC_MSG_ERROR([The required function `tputs' was not found in any library.
3015 The following libraries were tried (in order):
3016   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3017 Please try installing whichever of these libraries is most appropriate
3018 for your system, together with its header files.
3019 For example, a libncurses-dev(el) or similar package.])
3020 fi
3021
3022 ## Use termcap instead of terminfo?
3023 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3024 TERMINFO=yes
3025 ## FIXME?  In the cases below where we unconditionally set
3026 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3027 ## if that was found above to have tputs.
3028 ## Should we use the gnu* logic everywhere?
3029 case "$opsys" in
3030   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3031   ##  The ncurses library has been moved out of the System framework in
3032   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3033   ##  option to use it.
3034   darwin) LIBS_TERMCAP="-lncurses" ;;
3035
3036   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3037
3038   freebsd)
3039     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3040     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3041     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3042 [[#if __FreeBSD_version < 400000
3043 fail;
3044 #endif
3045 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3046
3047     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3048
3049     if test $emacs_cv_freebsd_terminfo = yes; then
3050       LIBS_TERMCAP="-lncurses"
3051     else
3052       TERMINFO=no
3053       LIBS_TERMCAP="-ltermcap"
3054     fi
3055     ;;
3056
3057   netbsd)
3058     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3059       TERMINFO=no
3060       LIBS_TERMCAP="-ltermcap"
3061     fi
3062     ;;
3063
3064   openbsd) LIBS_TERMCAP="-lncurses" ;;
3065
3066   ## hpux: Make sure we get select from libc rather than from libcurses
3067   ##  because libcurses on HPUX 10.10 has a broken version of select.
3068   ##  We used to use -lc -lcurses, but this may be cleaner.
3069   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3070   # set that way, now it uses the default).  Isn't this a contradiction?
3071   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3072
3073 esac
3074
3075 TERMCAP_OBJ=tparam.o
3076 if test $TERMINFO = yes; then
3077   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3078   TERMCAP_OBJ=terminfo.o
3079 fi
3080 AC_SUBST(LIBS_TERMCAP)
3081 AC_SUBST(TERMCAP_OBJ)
3082
3083
3084 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3085 # On Darwin, res_init appears not to be useful: see bug#562 and
3086 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3087 resolv=no
3088
3089 if test $opsys != darwin; then
3090
3091   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3092 #include <arpa/nameser.h>
3093 #include <resolv.h>]],
3094     [[return res_init();]])],
3095     have_res_init=yes, have_res_init=no)
3096   if test "$have_res_init" = no; then
3097     OLIBS="$LIBS"
3098     LIBS="$LIBS -lresolv"
3099     AC_MSG_CHECKING(for res_init with -lresolv)
3100     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3101 #include <arpa/nameser.h>
3102 #include <resolv.h>]],
3103       [[return res_init();]])],
3104       have_res_init=yes, have_res_init=no)
3105     AC_MSG_RESULT($have_res_init)
3106     if test "$have_res_init" = yes ; then
3107       resolv=yes
3108     fi
3109     LIBS="$OLIBS"
3110   fi
3111
3112   if test "$have_res_init" = yes; then
3113     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3114   fi
3115 fi                              dnl !darwin
3116
3117 # Do we need the Hesiod library to provide the support routines?
3118 dnl FIXME?  Should we be skipping this on Darwin too?
3119 LIBHESIOD=
3120 if test "$with_hesiod" != no ; then
3121   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3122   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3123      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3124                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3125   if test "$resolv" = yes ; then
3126     RESOLVLIB=-lresolv
3127   else
3128     RESOLVLIB=
3129   fi
3130   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3131         hesiod=yes, :, $RESOLVLIB)])
3132
3133   if test x"$hesiod" = xyes; then
3134     AC_DEFINE(HAVE_LIBHESIOD, 1,
3135               [Define to 1 if you have the hesiod library (-lhesiod).])
3136     LIBHESIOD=-lhesiod
3137   fi
3138 fi
3139 AC_SUBST(LIBHESIOD)
3140
3141 # Do we need libresolv (due to res_init or Hesiod)?
3142 if test "$resolv" = yes && test $opsys != darwin; then
3143   AC_DEFINE(HAVE_LIBRESOLV, 1,
3144             [Define to 1 if you have the resolv library (-lresolv).])
3145   LIBRESOLV=-lresolv
3146 else
3147   LIBRESOLV=
3148 fi
3149 AC_SUBST(LIBRESOLV)
3150
3151 # These tell us which Kerberos-related libraries to use.
3152 COM_ERRLIB=
3153 CRYPTOLIB=
3154 KRB5LIB=
3155 DESLIB=
3156 KRB4LIB=
3157
3158 if test "${with_kerberos}" != no; then
3159   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3160   if test $have_com_err = yes; then
3161     COM_ERRLIB=-lcom_err
3162     LIBS="$COM_ERRLIB $LIBS"
3163     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
3164   fi
3165   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3166   if test $have_crypto = yes; then
3167     CRYPTOLIB=-lcrypto
3168     LIBS="$CRYPTOLIB $LIBS"
3169     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
3170   fi
3171   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3172   if test $have_k5crypto = yes; then
3173     CRYPTOLIB=-lk5crypto
3174     LIBS="$CRYPTOLIB $LIBS"
3175     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
3176   fi
3177   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3178   if test $have_krb5=yes; then
3179     KRB5LIB=-lkrb5
3180     LIBS="$KRB5LIB $LIBS"
3181     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
3182   fi
3183   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3184   if test "${with_kerberos5}" = no; then
3185     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3186     if test $have_des425 = yes; then
3187       DESLIB=-ldes425
3188       LIBS="$DESLIB $LIBS"
3189       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
3190     else
3191       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3192       if test $have_des = yes; then
3193         DESLIB=-ldes
3194         LIBS="$DESLIB $LIBS"
3195         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
3196       fi
3197     fi
3198     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3199     if test $have_krb4 = yes; then
3200       KRB4LIB=-lkrb4
3201       LIBS="$KRB4LIB $LIBS"
3202       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
3203     else
3204       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3205       if test $have_krb = yes; then
3206         KRB4LIB=-lkrb
3207         LIBS="$KRB4LIB $LIBS"
3208         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
3209       fi
3210     fi
3211   fi
3212
3213   if test "${with_kerberos5}" != no; then
3214     AC_CHECK_HEADERS(krb5.h,
3215       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3216                         [#include <krb5.h>])])
3217   else
3218     AC_CHECK_HEADERS(des.h,,
3219                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3220                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3221     AC_CHECK_HEADERS(krb.h,,
3222                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3223                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3224   fi
3225   AC_CHECK_HEADERS(com_err.h)
3226 fi
3227
3228 AC_SUBST(COM_ERRLIB)
3229 AC_SUBST(CRYPTOLIB)
3230 AC_SUBST(KRB5LIB)
3231 AC_SUBST(DESLIB)
3232 AC_SUBST(KRB4LIB)
3233
3234 AC_CHECK_FUNCS_ONCE(tzset)
3235 AC_MSG_CHECKING(whether localtime caches TZ)
3236 AC_CACHE_VAL(emacs_cv_localtime_cache,
3237 [if test x$ac_cv_func_tzset = xyes; then
3238 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3239 char TZ_GMT0[] = "TZ=GMT0";
3240 char TZ_PST8[] = "TZ=PST8";
3241 main()
3242 {
3243   time_t now = time ((time_t *) 0);
3244   int hour_GMT0, hour_unset;
3245   if (putenv (TZ_GMT0) != 0)
3246     exit (1);
3247   hour_GMT0 = localtime (&now)->tm_hour;
3248   unsetenv("TZ");
3249   hour_unset = localtime (&now)->tm_hour;
3250   if (putenv (TZ_PST8) != 0)
3251     exit (1);
3252   if (localtime (&now)->tm_hour == hour_GMT0)
3253     exit (1);
3254   unsetenv("TZ");
3255   if (localtime (&now)->tm_hour != hour_unset)
3256     exit (1);
3257   exit (0);
3258 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3259 [# If we have tzset, assume the worst when cross-compiling.
3260 emacs_cv_localtime_cache=yes])
3261 else
3262         # If we lack tzset, report that localtime does not cache TZ,
3263         # since we can't invalidate the cache if we don't have tzset.
3264         emacs_cv_localtime_cache=no
3265 fi])dnl
3266 AC_MSG_RESULT($emacs_cv_localtime_cache)
3267 if test $emacs_cv_localtime_cache = yes; then
3268   AC_DEFINE(LOCALTIME_CACHE, 1,
3269             [Define to 1 if localtime caches TZ.])
3270 fi
3271
3272 ok_so_far=yes
3273 AC_CHECK_FUNC(socket, , ok_so_far=no)
3274 if test $ok_so_far = yes; then
3275   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3276 fi
3277 if test $ok_so_far = yes; then
3278   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3279 fi
3280 if test $ok_so_far = yes; then
3281 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3282   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3283             [Define to 1 if you have inet sockets.])
3284 fi
3285
3286 if test -f /usr/lpp/X11/bin/smt.exp; then
3287   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3288             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3289 fi
3290
3291 AC_MSG_CHECKING(whether system supports dynamic ptys)
3292 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3293   AC_MSG_RESULT(yes)
3294   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3295 else
3296   AC_MSG_RESULT(no)
3297 fi
3298
3299 dnl Check for a Solaris 2.4 vfork bug that Autoconf misses (through 2.69).
3300 dnl This can be removed once we assume Autoconf 2.70.
3301 case $canonical in
3302   *-solaris2.4 | *-solaris2.4.*)
3303     dnl Disable the Autoconf-generated vfork test.
3304     : ${ac_cv_func_vfork_works=no};;
3305 esac
3306
3307 AC_FUNC_FORK
3308
3309 AC_CHECK_FUNCS(snprintf)
3310
3311 dnl Adapted from Haible's version.
3312 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3313   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3314     [[char* cs = nl_langinfo(CODESET);]])],
3315     emacs_cv_langinfo_codeset=yes,
3316     emacs_cv_langinfo_codeset=no)
3317   ])
3318 if test $emacs_cv_langinfo_codeset = yes; then
3319   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3320     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3321 fi
3322
3323 AC_TYPE_MBSTATE_T
3324
3325 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3326   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3327                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3328 if test "$emacs_cv_c_restrict_arr" = yes; then
3329   AC_DEFINE(__restrict_arr, __restrict,
3330     [Define to compiler's equivalent of C99 restrict keyword in array
3331      declarations.  Define as empty for no equivalent.])
3332 fi
3333
3334 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3335 dnl how the tty code is related to POSIX and/or other versions of termios.
3336 dnl The following looks like a useful start.
3337 dnl
3338 dnl AC_SYS_POSIX_TERMIOS
3339 dnl if test $ac_cv_sys_posix_termios = yes; then
3340 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3341 dnl                                and macros for terminal control.])
3342 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3343 dnl fi
3344
3345 dnl Turned on June 1996 supposing nobody will mind it.
3346 AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3347   in the full name stands for the login id.])
3348
3349 dnl Every platform that uses configure (ie every non-MS platform)
3350 dnl supports this.  There is a create-lockfiles option you can
3351 dnl customize if you do not want the lock files to be written.
3352 dnl So it is not clear that this #define still needs to exist.
3353 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3354   so that Emacs can tell instantly when you try to modify a file that
3355   someone else has modified in his/her Emacs.])
3356
3357 dnl Everybody supports this, except MS.
3358 dnl Seems like the kind of thing we should be testing for, though.
3359 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3360 AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3361
3362 dnl Everybody supports this, except MS-DOS.
3363 dnl Seems like the kind of thing we should be testing for, though.
3364 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3365 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3366   4.2-compatible sockets.])
3367
3368 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3369
3370 AC_DEFINE(NULL_DEVICE, ["/dev/null"], [Name of the file to open to get
3371   a null file, or a data sink.])
3372
3373 AC_DEFINE(SEPCHAR, [':'], [Character that separates PATH elements.])
3374
3375 dnl Everybody supports this, except MS-DOS.
3376 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
3377
3378 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
3379
3380
3381 AC_DEFINE(DIRECTORY_SEP, ['/'],
3382   [Character that separates directories in a file name.])
3383
3384 dnl Only used on MS platforms.
3385 AH_TEMPLATE(DEVICE_SEP, [Character that separates a device in a file name.])
3386
3387 AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
3388   [Returns true if character is a device separator.])
3389
3390 AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
3391   [Returns true if character is a directory separator.])
3392
3393 dnl On MS, this also accepts IS_DEVICE_SEP.
3394 AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
3395   [Returns true if character is any form of separator.])
3396
3397
3398 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3399
3400 case $opsys in
3401   aix4-2)
3402     dnl Unfortunately without libXmu we cannot support EditRes.
3403     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
3404       AC_DEFINE(NO_EDITRES, 1)
3405     fi
3406     ;;
3407
3408   hpux*)
3409     dnl Assar Westerlund <assar@sics.se> says this is necessary for
3410     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
3411     AC_DEFINE(NO_EDITRES, 1)
3412     ;;
3413 esac
3414
3415
3416 case $opsys in
3417   irix6-5 | sol2* | unixware )
3418     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
3419     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
3420     dnl need the constant to dimension an array.  So wire in the appropriate
3421     dnl value here.
3422     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
3423     ;;
3424 esac
3425
3426 emacs_broken_SIGIO=no
3427
3428 case $opsys in
3429   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3430   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3431   hpux* | irix6-5 | openbsd | sol2* | unixware )
3432     emacs_broken_SIGIO=yes
3433     ;;
3434
3435   aix4-2)
3436     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
3437     dnl the way this system works, libc functions that return malloced
3438     dnl memory use the libc malloc implementation. Calling xfree or
3439     dnl xrealloc on the results of such functions results in a crash.
3440     dnl
3441     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
3442     dnl but that does not currently work on this system.
3443     dnl
3444     dnl It is possible to completely override the malloc implementation on
3445     dnl AIX, but that involves putting the malloc functions in a shared
3446     dnl library and setting the MALLOCTYPE environment variable to point to
3447     dnl that shared library.
3448     dnl
3449     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
3450     dnl to avoid a crash just use the Emacs implementation for that function.
3451     dnl
3452     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
3453     dnl of this file, so that we do not check for get_current_dir_name
3454     dnl on AIX.  But that might be fragile if something else ends
3455     dnl up testing for get_current_dir_name as a dependency.
3456     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
3457       get_current_dir_name should not be used.])
3458     ;;
3459
3460   freebsd)
3461     dnl Circumvent a bug in FreeBSD.  In the following sequence of
3462     dnl writes/reads on a PTY, read(2) returns bogus data:
3463     dnl
3464     dnl write(2)  1022 bytes
3465     dnl write(2)   954 bytes, get EAGAIN
3466     dnl read(2)   1024 bytes in process_read_output
3467     dnl read(2)     11 bytes in process_read_output
3468     dnl
3469     dnl That is, read(2) returns more bytes than have ever been written
3470     dnl successfully.  The 1033 bytes read are the 1022 bytes written
3471     dnl successfully after processing (for example with CRs added if the
3472     dnl terminal is set up that way which it is here).  The same bytes will
3473     dnl be seen again in a later read(2), without the CRs.
3474     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
3475       work around an issue when reading from a PTY.])
3476     ;;
3477 esac
3478
3479 case $opsys in
3480   gnu-* | sol2-10 )
3481     dnl FIXME Can't we test if this exists (eg /proc/$$)?
3482     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3483   ;;
3484 esac
3485
3486 case $opsys in
3487   darwin | freebsd | netbsd | openbsd )
3488     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
3489       close a pty to make it a controlling terminal (it is already a
3490       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
3491   ;;
3492 esac
3493
3494 dnl FIXME Surely we can test for this rather than hard-code it.
3495 case $opsys in
3496   netbsd | openbsd) sound_device="/dev/audio" ;;
3497   *) sound_device="/dev/dsp" ;;
3498 esac
3499
3500 dnl Used in sound.c
3501 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
3502   [Name of the default sound device.])
3503
3504
3505 dnl Emacs can read input using SIGIO and buffering characters itself,
3506 dnl or using CBREAK mode and making C-g cause SIGINT.
3507 dnl The choice is controlled by the variable interrupt_input.
3508 dnl
3509 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
3510 dnl
3511 dnl Emacs uses the presence of the USABLE_SIGIO macro
3512 dnl to indicate whether or not signal-driven I/O is possible.  It uses
3513 dnl INTERRUPT_INPUT to decide whether to use it by default.
3514 dnl
3515 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
3516 dnl CBREAK mode has two disadvantages
3517 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
3518 dnl I hear that in system V this problem does not exist.
3519 dnl 2) Control-G causes output to be discarded.
3520 dnl I do not know whether this can be fixed in system V.
3521 dnl
3522 dnl Another method of doing input is planned but not implemented.
3523 dnl It would have Emacs fork off a separate process
3524 dnl to read the input and send it to the true Emacs process
3525 dnl through a pipe.
3526 case $opsys in
3527   darwin | gnu-linux | gnu-kfreebsd )
3528     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
3529   ;;
3530 esac
3531
3532
3533 dnl If the system's imake configuration file defines `NeedWidePrototypes'
3534 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
3535 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
3536 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
3537 dnl taking float or double parameters.
3538 case $opsys in
3539   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
3540     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
3541       file defines `NeedWidePrototypes' as `NO'.])
3542   ;;
3543 esac
3544
3545
3546 dnl Used in process.c, this must be a loop, even if it only runs once.
3547 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
3548 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
3549 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
3550 dnl trying suffixes 0-16.
3551 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
3552   first PTY, if PTYs are supported.])
3553 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
3554 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
3555   end of a PTY, if non-standard.])
3556 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
3557   end of a PTY, if non-standard.])
3558
3559 case $opsys in
3560   aix4-2 )
3561     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
3562     dnl You allocate a pty by opening /dev/ptc to get the master side.
3563     dnl To get the name of the slave side, you just ttyname() the master side.
3564     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
3565     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
3566     ;;
3567
3568   cygwin )
3569     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3570     dnl multi-line AC_DEFINEs are hard. :(
3571     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (0)])
3572     AC_DEFINE(PTY_NAME_SPRINTF, [])
3573     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3574     ;;
3575
3576   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
3577   darwin )
3578     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3579     dnl Not used, because PTY_ITERATION is defined.
3580     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3581     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
3582     dnl But we don't have to block SIGCHLD because it is blocked in the
3583     dnl implementation of grantpt.
3584     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (0)])
3585     AC_DEFINE(PTY_NAME_SPRINTF, [])
3586     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3587     ;;
3588
3589   gnu | openbsd )
3590     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3591     ;;
3592
3593   gnu-linux | gnu-kfreebsd | freebsd | netbsd )
3594     dnl if HAVE_GRANTPT
3595     if test "x$ac_cv_func_grantpt" = xyes; then
3596       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
3597       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3598       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
3599       dnl to prevent sigchld_handler from intercepting the child's death.
3600       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3601       dnl if HAVE_POSIX_OPENPT
3602       if test "x$ac_cv_func_posix_openpt" = xyes; then
3603         AC_DEFINE(PTY_OPEN, [fd = posix_openpt (O_RDWR | O_NOCTTY)])
3604         AC_DEFINE(PTY_NAME_SPRINTF, [])
3605       dnl if HAVE_GETPT
3606       elif test "x$ac_cv_func_getpt" = xyes; then
3607         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
3608         AC_DEFINE(PTY_NAME_SPRINTF, [])
3609       else
3610         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3611       fi
3612     else
3613       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3614     fi
3615     ;;
3616
3617   hpux*)
3618     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3619     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
3620     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
3621     ;;
3622
3623   irix6-5 )
3624     dnl It looks like this cannot be right, because it is not a loop.
3625     dnl However, process.c actually does this:
3626     dnl # ifndef __sgi
3627     dnl   continue;
3628     dnl # else
3629     dnl   return -1;
3630     dnl # endif
3631     dnl which presumably makes it OK, since irix == sgi (?).
3632     dnl FIXME it seems like this special treatment is unnecessary?
3633     dnl Why can't irix use a single-trip loop like eg cygwin?
3634     AC_DEFINE(PTY_ITERATION, [])
3635     dnl Not used, because PTY_ITERATION is defined.
3636     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
3637     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
3638     dnl No need to get the pty name at all.
3639     AC_DEFINE(PTY_NAME_SPRINTF, [])
3640     dnl No need to use sprintf to get the tty name--we get that from _getpty.
3641     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3642     ;;
3643
3644   sol2* )
3645     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
3646     dnl from intercepting that death.  If any child but grantpt's should die
3647     dnl within, it should be caught after sigrelse(2).
3648     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3649     ;;
3650
3651   unixware )
3652     dnl Comments are as per sol2*.
3653     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3654     ;;
3655 esac
3656
3657
3658 case $opsys in
3659   sol2* | unixware )
3660     dnl This change means that we don't loop through allocate_pty too
3661     dnl many times in the (rare) event of a failure.
3662     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
3663     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3664     dnl Push various streams modules onto a PTY channel.  Used in process.c.
3665     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
3666     ;;
3667 esac
3668
3669
3670 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
3671 "typing" a signal character on the pty.])
3672
3673 case $opsys in
3674   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
3675   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
3676   aix4-2 | cygwin | gnu | irix6-5 | freebsd | netbsd | openbsd | darwin )
3677     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3678     ;;
3679
3680   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
3681   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
3682   gnu-linux | gnu-kfreebsd )
3683
3684     AC_MSG_CHECKING([for signals via characters])
3685     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3686 #include <linux/version.h>
3687 #if LINUX_VERSION_CODE < 0x20400
3688 # error "Linux version too old"
3689 #endif
3690       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
3691
3692     AC_MSG_RESULT([$emacs_signals_via_chars])
3693     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3694     ;;
3695 esac
3696
3697
3698 dnl Used in vm-limit.c
3699 AH_TEMPLATE(DATA_START, [Address of the start of the data segment.])
3700 dnl Used in lisp.h, emacs.c, mem-limits.h
3701 dnl NEWS.18 describes this as "a number which contains
3702 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
3703 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
3704 stored in a Lisp_Object.])
3705 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
3706
3707 case $opsys in
3708   gnu)
3709     dnl libc defines data_start.
3710     AC_DEFINE(DATA_START, [({ extern int data_start; (char *) &data_start; })])
3711     ;;
3712
3713   hpux*)
3714     dnl The data segment on this machine always starts at address 0x40000000.
3715     AC_DEFINE(DATA_START, [0x40000000])
3716     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
3717     ;;
3718   irix6-5)
3719     AC_DEFINE(DATA_START, [0x10000000])
3720     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
3721     ;;
3722 esac
3723
3724
3725 AH_TEMPLATE(TAB3, [Undocumented.])
3726
3727 case $opsys in
3728   darwin) AC_DEFINE(TAB3, OXTABS) ;;
3729
3730   gnu | freebsd | netbsd | openbsd )
3731     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
3732     AC_DEFINE(TAB3, OXTABS)
3733     ;;
3734
3735   gnu-linux | gnu-kfreebsd )
3736     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3737 #ifndef __ia64__
3738 # error "not ia64"
3739 #endif
3740       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
3741         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (0)],
3742         [Mark a secondary stack, like the register stack on the ia64.]), [])
3743     ;;
3744
3745   hpux*)
3746     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
3747       run_time_remap; for HPUX.])
3748     ;;
3749 esac
3750
3751
3752 dnl These won't be used automatically yet.  We also need to know, at least,
3753 dnl that the stack is continuous.
3754 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
3755   registers relevant for conservative garbage collection in the jmp_buf.])
3756
3757 AH_TEMPLATE(GC_MARK_STACK, [Define to GC_USE_GCPROS_AS_BEFORE if
3758   conservative garbage collection is not known to work.])
3759
3760
3761 case $opsys in
3762   aix4-2 | hpux* | unixware)
3763     dnl Conservative garbage collection has not been tested, so for now
3764     dnl play it safe and stick with the old-fashioned way of marking.
3765     AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE])
3766     ;;
3767
3768   dnl Not all the architectures are tested, but there are Debian packages
3769   dnl for SCM and/or Guile on them, so the technique must work.  See also
3770   dnl comments in alloc.c concerning setjmp and gcc.
3771   dnl Fixme: it's probably safe to just use the GCC conditional below.
3772   gnu-linux | gnu-kfreebsd )
3773     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3774 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
3775   || defined __alpha__ || defined __mips__ || defined __s390__ \
3776   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
3777   || defined __ia64__ || defined __sh__
3778 /* ok */
3779 #else
3780 # error "setjmp not known to work on this arch"
3781 #endif
3782     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1),
3783       AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE]) )
3784     ;;
3785 esac
3786
3787
3788 if test x$GCC = xyes; then
3789    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
3790    AC_DEFINE(GC_SETJMP_WORKS, 1)
3791 else
3792   case $opsys in
3793     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
3794     freebsd | netbsd | openbsd | irix6-5 | sol2* )
3795       AC_DEFINE(GC_SETJMP_WORKS, 1)
3796       ;;
3797   esac
3798 fi                              dnl GCC?
3799
3800 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
3801   [AC_LINK_IFELSE(
3802      [AC_LANG_PROGRAM(
3803        [[#include <setjmp.h>
3804        ]],
3805        [[jmp_buf j;
3806          if (! _setjmp (j))
3807            _longjmp (j, 1);]])],
3808      [emacs_cv_func__setjmp=yes],
3809      [emacs_cv_func__setjmp=no])])
3810 if test $emacs_cv_func__setjmp = yes; then
3811   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
3812 else
3813   AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
3814     [AC_LINK_IFELSE(
3815        [AC_LANG_PROGRAM(
3816          [[#include <setjmp.h>
3817          ]],
3818          [[sigjmp_buf j;
3819            if (! sigsetjmp (j, 1))
3820              siglongjmp (j, 1);]])],
3821        [emacs_cv_func_sigsetjmp=yes],
3822        [emacs_cv_func_sigsetjmp=no])])
3823   if test $emacs_cv_func_sigsetjmp = yes; then
3824     AC_DEFINE([HAVE_SIGSETJMP], 1,
3825       [Define to 1 if sigsetjmp and siglongjmp work.
3826        The value of this symbol is irrelevant if HAVE__SETJMP is defined.])
3827   fi
3828 fi
3829
3830 case $opsys in
3831   sol2* | unixware )
3832     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
3833     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
3834     dnl and this is all we need.
3835     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
3836     ;;
3837 esac
3838
3839
3840 case $opsys in
3841   hpux* | sol2* )
3842     dnl Used in xfaces.c.
3843     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
3844       some systems, where it requires time.h.])
3845     ;;
3846 esac
3847
3848
3849 dnl Define symbols to identify the version of Unix this is.
3850 dnl Define all the symbols that apply correctly.
3851 AH_TEMPLATE(BSD_SYSTEM, [Define if the system is compatible with BSD 4.2.])
3852 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
3853 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
3854 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
3855 AH_TEMPLATE(USG5, [Define if the system is compatible with System V.])
3856 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
3857
3858 case $opsys in
3859   aix4-2)
3860     AC_DEFINE(USG, [])
3861     AC_DEFINE(USG5, [])
3862     dnl This symbol should be defined on AIX Version 3  ???????
3863     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3864 #ifndef _AIX
3865 # error "_AIX not defined"
3866 #endif
3867     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
3868     ;;
3869
3870   cygwin)
3871     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
3872     ;;
3873
3874   darwin)
3875     dnl BSD4_3 and BSD4_4 are already defined in sys/param.h.
3876     AC_DEFINE(BSD_SYSTEM, [])
3877     dnl More specific than the above two.  We cannot use __APPLE__ as this
3878     dnl may not be defined on non-OSX Darwin, and we cannot define DARWIN
3879     dnl here because Panther and lower CoreFoundation.h uses DARWIN to
3880     dnl distinguish OS X from pure Darwin.
3881     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
3882     ;;
3883
3884   freebsd)
3885     dnl Hack to avoid calling AC_PREPROC_IFELSE multiple times.
3886     dnl Would not be needed with autoconf >= 2.67, where the
3887     dnl preprocessed output is accessible in "conftest.i".
3888     AC_DEFINE(BSD_SYSTEM_AHB, 1, [Define if AH_BOTTOM should change BSD_SYSTEM.])
3889     ;;
3890
3891   gnu | netbsd | openbsd )
3892     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3893 #ifndef BSD_SYSTEM
3894 # error "BSD_SYSTEM not defined"
3895 #endif
3896     ]], [[]])], [], AC_DEFINE(BSD_SYSTEM, 43) )
3897     ;;
3898
3899   gnu-linux | gnu-kfreebsd )
3900     AC_DEFINE(USG, [])
3901     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
3902     ;;
3903
3904   hpux*)
3905     AC_DEFINE(USG, [])
3906     AC_DEFINE(USG5, [])
3907     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
3908     ;;
3909
3910   irix6-5)
3911     AC_DEFINE(USG, [])
3912     AC_DEFINE(USG5, [])
3913     AC_DEFINE(USG5_4, [])
3914     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
3915     ;;
3916
3917   sol2*)
3918     AC_DEFINE(USG, [])
3919     AC_DEFINE(USG5, [])
3920     AC_DEFINE(USG5_4, [])
3921     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
3922     ;;
3923
3924   unixware)
3925     AC_DEFINE(USG, [])
3926     AC_DEFINE(USG5, [])
3927     AC_DEFINE(USG5_4, [])
3928     ;;
3929 esac
3930
3931 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
3932   [case $opsys in
3933      aix4-2)
3934        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
3935        emacs_cv_usable_FIONREAD=no
3936        ;;
3937
3938      *)
3939        AC_COMPILE_IFELSE(
3940          [AC_LANG_PROGRAM([[#include <sys/types.h>
3941                             #include <sys/ioctl.h>
3942                             #ifdef USG5_4
3943                             # include <sys/filio.h>
3944                             #endif
3945                           ]],
3946                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
3947          [emacs_cv_usable_FIONREAD=yes],
3948          [emacs_cv_usable_FIONREAD=no])
3949        ;;
3950    esac])
3951 if test $emacs_cv_usable_FIONREAD = yes; then
3952   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
3953
3954   if test $emacs_broken_SIGIO = no; then
3955     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
3956       [AC_COMPILE_IFELSE(
3957          [AC_LANG_PROGRAM([[#include <fcntl.h>
3958                             #include <signal.h>
3959                           ]],
3960                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
3961          [emacs_cv_usable_SIGIO=yes],
3962          [emacs_cv_usable_SIGIO=no])],
3963       [emacs_cv_usable_SIGIO=yes],
3964       [emacs_cv_usable_SIGIO=no])
3965     if test $emacs_cv_usable_SIGIO = yes; then
3966       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
3967     fi
3968   fi
3969 fi
3970
3971
3972 case $opsys in
3973   dnl Emacs supplies its own malloc, but glib (part of Gtk+) calls
3974   dnl memalign and on Cygwin, that becomes the Cygwin-supplied memalign.
3975   dnl As malloc is not the Cygwin malloc, the Cygwin memalign always
3976   dnl returns ENOSYS.  A workaround is to set G_SLICE=always-malloc. */
3977   cygwin)
3978     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
3979       G_SLICE environment variable to "always-malloc" at startup, if
3980       using GTK.])
3981     ;;
3982
3983   hpux11)
3984     dnl It works to open the pty's tty in the parent (Emacs), then
3985     dnl close and reopen it in the child.
3986     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
3987       works to open a pty's tty in the parent process, then close and
3988       reopen it in the child.])
3989     ;;
3990
3991   irix6-5)
3992     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
3993       use VSUSP instead of VSWTCH.])
3994     ;;
3995
3996   sol2-10)
3997     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
3998       on Solaris.])
3999     ;;
4000 esac
4001
4002 # Set up the CFLAGS for real compilation, so we can substitute it.
4003 CFLAGS="$REAL_CFLAGS"
4004 CPPFLAGS="$REAL_CPPFLAGS"
4005
4006 ## Hack to detect a buggy GCC version.
4007 if test "x$GCC" = xyes \
4008    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4009    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4010    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4011    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4012 fi
4013
4014 version=$PACKAGE_VERSION
4015
4016 copyright="Copyright (C) 2012 Free Software Foundation, Inc."
4017 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4018   [Short copyright string for this version of Emacs.])
4019 AC_SUBST(copyright)
4020
4021 ### Specify what sort of things we'll be editing into Makefile and config.h.
4022 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4023 AC_SUBST(version)
4024 AC_SUBST(configuration)
4025 ## Unused?
4026 AC_SUBST(canonical)
4027 AC_SUBST(srcdir)
4028 AC_SUBST(prefix)
4029 AC_SUBST(exec_prefix)
4030 AC_SUBST(bindir)
4031 AC_SUBST(datadir)
4032 AC_SUBST(sharedstatedir)
4033 AC_SUBST(libexecdir)
4034 AC_SUBST(mandir)
4035 AC_SUBST(infodir)
4036 AC_SUBST(lispdir)
4037 AC_SUBST(leimdir)
4038 AC_SUBST(standardlisppath)
4039 AC_SUBST(locallisppath)
4040 AC_SUBST(lisppath)
4041 AC_SUBST(x_default_search_path)
4042 AC_SUBST(etcdir)
4043 AC_SUBST(archlibdir)
4044 AC_SUBST(docdir)
4045 AC_SUBST(bitmapdir)
4046 AC_SUBST(gamedir)
4047 AC_SUBST(gameuser)
4048 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4049 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4050 ## end of LIBX_BASE, but nothing ever set it.
4051 AC_SUBST(LD_SWITCH_X_SITE)
4052 AC_SUBST(C_SWITCH_X_SITE)
4053 AC_SUBST(GNUSTEP_CFLAGS)
4054 AC_SUBST(CFLAGS)
4055 ## Used in lwlib/Makefile.in.
4056 AC_SUBST(X_TOOLKIT_TYPE)
4057 AC_SUBST(ns_appdir)
4058 AC_SUBST(ns_appbindir)
4059 AC_SUBST(ns_appresdir)
4060 AC_SUBST(ns_appsrc)
4061 AC_SUBST(GNU_OBJC_CFLAGS)
4062 AC_SUBST(OTHER_FILES)
4063
4064 if test -n "${term_header}"; then
4065     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4066         [Define to the header for the built-in window system.])
4067 fi
4068
4069 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4070                    [Define to the canonical Emacs configuration name.])
4071 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
4072                    [Define to the options passed to configure.])
4073 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4074   define this to include extra configuration information.])
4075
4076 XMENU_OBJ=
4077 XOBJ=
4078 FONT_OBJ=
4079 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4080   AC_DEFINE(HAVE_X_WINDOWS, 1,
4081             [Define to 1 if you want to use the X window system.])
4082   XMENU_OBJ=xmenu.o
4083   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o xgselect.o"
4084   FONT_OBJ=xfont.o
4085   if test "$HAVE_XFT" = "yes"; then
4086     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4087   elif test "$HAVE_FREETYPE" = "yes"; then
4088     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4089   fi
4090   AC_SUBST(FONT_OBJ)
4091 fi
4092 AC_SUBST(XMENU_OBJ)
4093 AC_SUBST(XOBJ)
4094 AC_SUBST(FONT_OBJ)
4095
4096 WIDGET_OBJ=
4097 MOTIF_LIBW=
4098 if test "${USE_X_TOOLKIT}" != "none" ; then
4099   WIDGET_OBJ=widget.o
4100   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4101   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4102     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4103   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4104     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4105     MOTIF_LIBW=-lXm
4106     case "$opsys" in
4107       gnu-linux)
4108         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4109         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4110         ;;
4111
4112       unixware)
4113         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4114         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4115         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4116         ;;
4117
4118       aix4-2)
4119         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4120         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4121         ;;
4122     esac
4123     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4124   fi
4125 fi
4126 AC_SUBST(WIDGET_OBJ)
4127
4128 TOOLKIT_LIBW=
4129 case "$USE_X_TOOLKIT" in
4130   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4131   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4132   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4133 esac
4134 AC_SUBST(TOOLKIT_LIBW)
4135
4136 if test "$USE_X_TOOLKIT" = "none"; then
4137   LIBXT_OTHER="\$(LIBXSM)"
4138   OLDXMENU_TARGET="really-oldXMenu"
4139 else
4140   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4141   OLDXMENU_TARGET="really-lwlib"
4142 fi
4143 AC_SUBST(LIBXT_OTHER)
4144
4145 ## The X Menu stuff is present in the X10 distribution, but missing
4146 ## from X11.  If we have X10, just use the installed library;
4147 ## otherwise, use our own copy.
4148 if test "${HAVE_X11}" = "yes" ; then
4149   AC_DEFINE(HAVE_X11, 1,
4150             [Define to 1 if you want to use version 11 of X windows.
4151              Otherwise, Emacs expects to use version 10.])
4152
4153   if test "$USE_X_TOOLKIT" = "none"; then
4154     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
4155   else
4156     OLDXMENU="\${lwlibdir}/liblw.a"
4157   fi
4158   LIBXMENU="\$(OLDXMENU)"
4159   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4160   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
4161 else
4162   ## For a syntactically valid Makefile; not actually used for anything.
4163   ## See comments in src/Makefile.in.
4164   OLDXMENU=nothing
4165   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
4166   if test "${HAVE_X_WINDOWS}" = "yes"; then
4167     LIBXMENU="-lXMenu"
4168   else
4169     LIBXMENU=
4170   fi
4171   LIBX_OTHER=
4172   OLDXMENU_DEPS=
4173 fi
4174
4175 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
4176   OLDXMENU_TARGET=
4177   OLDXMENU=nothing
4178   LIBXMENU=
4179   OLDXMENU_DEPS=
4180 fi
4181
4182 AC_SUBST(OLDXMENU_TARGET)
4183 AC_SUBST(OLDXMENU)
4184 AC_SUBST(LIBXMENU)
4185 AC_SUBST(LIBX_OTHER)
4186 AC_SUBST(OLDXMENU_DEPS)
4187
4188 if test "${HAVE_MENUS}" = "yes" ; then
4189   AC_DEFINE(HAVE_MENUS, 1,
4190             [Define to 1 if you have mouse menus.
4191              (This is automatic if you use X, but the option to specify it remains.)
4192              It is also defined with other window systems that support xmenu.c.])
4193 fi
4194
4195 if test "${GNU_MALLOC}" = "yes" ; then
4196   AC_DEFINE(GNU_MALLOC, 1,
4197             [Define to 1 if you want to use the GNU memory allocator.])
4198 fi
4199
4200 RALLOC_OBJ=
4201 if test "${REL_ALLOC}" = "yes" ; then
4202   AC_DEFINE(REL_ALLOC, 1,
4203             [Define REL_ALLOC if you want to use the relocating allocator for
4204              buffer space.])
4205
4206   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4207 fi
4208 AC_SUBST(RALLOC_OBJ)
4209
4210 if test "$opsys" = "cygwin"; then
4211   CYGWIN_OBJ="sheap.o cygw32.o"
4212   ## Cygwin differs because of its unexec().
4213   PRE_ALLOC_OBJ=
4214   POST_ALLOC_OBJ=lastfile.o
4215 else
4216   CYGWIN_OBJ=
4217   PRE_ALLOC_OBJ=lastfile.o
4218   POST_ALLOC_OBJ=
4219 fi
4220 AC_SUBST(CYGWIN_OBJ)
4221 AC_SUBST(PRE_ALLOC_OBJ)
4222 AC_SUBST(POST_ALLOC_OBJ)
4223
4224 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4225 # it temporarily reverts them to their pre-pkg-config values,
4226 # because gnulib needs to work with both src (which uses the
4227 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4228 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4229 # and it therefore needs to run in an environment where LIBS does not
4230 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4231 # for some package unrelated to lib-src.
4232 SAVE_CFLAGS=$CFLAGS
4233 SAVE_LIBS=$LIBS
4234 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4235 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4236 gl_ASSERT_NO_GNULIB_POSIXCHECK
4237 gl_ASSERT_NO_GNULIB_TESTS
4238 gl_INIT
4239 CFLAGS=$SAVE_CFLAGS
4240 LIBS=$SAVE_LIBS
4241
4242 case "$opsys" in
4243   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4244
4245   darwin)
4246    ## The -headerpad option tells ld (see man page) to leave room at the
4247    ## end of the header for adding load commands.  Needed for dumping.
4248    ## 0x690 is the total size of 30 segment load commands (at 56
4249    ## each); under Cocoa 31 commands are required.
4250    if test "$HAVE_NS" = "yes"; then
4251      libs_nsgui="-framework AppKit"
4252      headerpad_extra=6C8
4253    else
4254      libs_nsgui=
4255      headerpad_extra=690
4256    fi
4257    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4258
4259    ## This is here because src/Makefile.in did some extra fiddling around
4260    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
4261    ##   #ifndef LD_SWITCH_SYSTEM
4262    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
4263    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
4264    ## not using gcc, darwin.
4265    ## Because this was done in src/Makefile.in, the resulting part of
4266    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
4267    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
4268    ## rather than LD_SWITCH_SYSTEM.
4269    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4270      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4271    ;;
4272
4273   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4274   ## find X at run-time.
4275   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4276   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4277   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4278   ## had different values in configure (in ac_link) and src/Makefile.in.
4279   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4280   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4281
4282   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4283 esac
4284
4285 if test "$NS_IMPL_GNUSTEP" = "yes"; then
4286   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
4287 fi
4288
4289 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4290
4291
4292 LD_FIRSTFLAG=
4293 ORDINARY_LINK=
4294 case "$opsys" in
4295   ## gnu: GNU needs its own crt0.
4296   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
4297
4298   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
4299   ## library search parth, i.e. it won't search /usr/lib for libc and
4300   ## friends.  Using -nostartfiles instead avoids this problem, and
4301   ## will also work on earlier NetBSD releases.
4302   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
4303
4304   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
4305   ##   MkLinux/LinuxPPC needs this.
4306   ## s390x-* only supports opsys = gnu-linux so it can be added here.
4307   gnu-*)
4308     case "$canonical" in
4309       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
4310     esac
4311     ;;
4312 esac
4313
4314
4315 if test "x$ORDINARY_LINK" = "xyes"; then
4316
4317   LD_FIRSTFLAG=""
4318   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
4319
4320 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
4321 ## freebsd, gnu-* not on powerpc*|s390x*.
4322 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
4323
4324   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
4325   ## places that are difficult to figure out at make time.  Fortunately,
4326   ## these same versions allow you to pass arbitrary flags on to the
4327   ## linker, so there is no reason not to use it as a linker.
4328   ##
4329   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
4330   ## searching for libraries in its internal directories, so we have to
4331   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
4332   LD_FIRSTFLAG="-nostdlib"
4333 fi
4334
4335 ## FIXME? What setting of EDIT_LDFLAGS should this have?
4336 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
4337
4338 AC_SUBST(LD_FIRSTFLAG)
4339
4340
4341 ## FIXME? The logic here is not precisely the same as that above.
4342 ## There is no check here for a pre-defined LD_FIRSTFLAG.
4343 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
4344 LIB_GCC=
4345 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
4346
4347   case "$opsys" in
4348     freebsd|netbsd|openbsd) LIB_GCC= ;;
4349
4350     gnu-*)
4351       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
4352       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
4353       case $host_cpu in
4354       arm*)
4355         LIB_GCC="-lgcc_s"
4356         ;;
4357       *)
4358         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
4359         ## immediately undefine it again and redefine it to empty.
4360         ## Was the C_SWITCH_X_SITE part really necessary?
4361 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
4362         LIB_GCC=
4363         ;;
4364       esac
4365       ;;
4366
4367     ## Ask GCC where to find libgcc.a.
4368     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
4369   esac
4370 fi                              dnl if $GCC
4371 AC_SUBST(LIB_GCC)
4372
4373 ## Common for all window systems
4374 if test "$window_system" != "none"; then
4375   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4376   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4377 fi
4378
4379 AC_SUBST(WINDOW_SYSTEM_OBJ)
4380
4381 AH_TOP([/* GNU Emacs site configuration template file.
4382
4383 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
4384   Free Software Foundation, Inc.
4385
4386 This file is part of GNU Emacs.
4387
4388 GNU Emacs is free software: you can redistribute it and/or modify
4389 it under the terms of the GNU General Public License as published by
4390 the Free Software Foundation, either version 3 of the License, or
4391 (at your option) any later version.
4392
4393 GNU Emacs is distributed in the hope that it will be useful,
4394 but WITHOUT ANY WARRANTY; without even the implied warranty of
4395 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4396 GNU General Public License for more details.
4397
4398 You should have received a copy of the GNU General Public License
4399 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4400
4401
4402 /* No code in Emacs #includes config.h twice, but some bits of code
4403    intended to work with other packages as well (like gmalloc.c)
4404    think they can include it as many times as they like.  */
4405 #ifndef EMACS_CONFIG_H
4406 #define EMACS_CONFIG_H
4407 ])dnl
4408
4409 AH_BOTTOM([#include <conf_post.h>
4410
4411 #endif /* EMACS_CONFIG_H */
4412
4413 /*
4414 Local Variables:
4415 mode: c
4416 End:
4417 */
4418 ])dnl
4419
4420 #### Report on what we decided to do.
4421 #### Report GTK as a toolkit, even if it doesn't use Xt.
4422 #### It makes printing result more understandable as using GTK sets
4423 #### toolkit_scroll_bars to yes by default.
4424 if test "${HAVE_GTK}" = "yes"; then
4425   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
4426 fi
4427
4428 echo "
4429 Configured for \`${canonical}'.
4430
4431   Where should the build process find the source code?    ${srcdir}
4432   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4433   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4434   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4435   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4436   What window system should Emacs use?                    ${window_system}
4437   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4438
4439 if test -n "${x_includes}"; then
4440 echo "  Where do we find X Windows header files?                ${x_includes}"
4441 else
4442 echo "  Where do we find X Windows header files?                Standard dirs"
4443 fi
4444 if test -n "${x_libraries}"; then
4445 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4446 else
4447 echo "  Where do we find X Windows libraries?                   Standard dirs"
4448 fi
4449
4450 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4451 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4452 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4453 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4454 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
4455 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
4456 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
4457 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
4458
4459 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
4460 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
4461 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
4462 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
4463 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
4464 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
4465 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
4466
4467 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
4468 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
4469 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
4470 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
4471
4472 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
4473 echo
4474
4475 if test -n "${EMACSDATA}"; then
4476    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
4477 fi
4478 if test -n "${EMACSDOC}"; then
4479    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
4480 fi
4481
4482 echo
4483
4484 if test "$HAVE_NS" = "yes"; then
4485    echo
4486    echo "You must run \"${MAKE-make} install\" in order to test the built application.
4487 The installed application will go to nextstep/Emacs.app and can be
4488 run or moved from there."
4489    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
4490       echo "The application will be fully self-contained."
4491     else
4492       echo "The lisp resources for the application will be installed under ${prefix}.
4493 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
4494 to run if these resources are not installed."
4495    fi
4496    echo
4497 fi
4498
4499 if test "${opsys}" = "cygwin"; then
4500   case `uname -r` in
4501     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
4502            echo
4503            ;;
4504   esac
4505 fi
4506
4507 # Remove any trailing slashes in these variables.
4508 [test "${prefix}" != NONE &&
4509   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
4510 test "${exec_prefix}" != NONE &&
4511   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
4512
4513 if test "$HAVE_NS" = "yes"; then
4514   if test "$NS_IMPL_GNUSTEP" = yes; then
4515     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
4516       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
4517   else
4518     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
4519       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
4520   fi
4521 fi
4522
4523 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
4524 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
4525 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
4526 dnl (else you get "no `Makefile.am' found for any configure output").
4527 dnl This will work, but you get a config.status that is not quite right
4528 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
4529 dnl That doesn't have any obvious consequences for Emacs, but on the whole
4530 dnl it seems better to just live with the duplication.
4531 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile"
4532
4533 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
4534        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
4535        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
4536        leim/Makefile nextstep/Makefile])
4537
4538 dnl test/ is not present in release tarfiles.
4539 opt_makefile=test/automated/Makefile
4540
4541 if test -f "$srcdir/$opt_makefile.in"; then
4542   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4543   dnl Again, it's best not to use a variable.  Though you can add
4544   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
4545   AC_CONFIG_FILES([test/automated/Makefile])
4546 fi
4547
4548
4549 dnl admin/ may or may not be present.
4550 opt_makefile=admin/unidata/Makefile
4551
4552 if test -f "$srcdir/$opt_makefile.in"; then
4553   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4554   AC_CONFIG_FILES([admin/unidata/Makefile])
4555 fi
4556
4557
4558 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
4559
4560 AC_SUBST(SUBDIR_MAKEFILES_IN)
4561
4562 dnl Make the necessary directories, if they don't exist.
4563 AC_CONFIG_COMMANDS([mkdirs], [
4564 for dir in etc lisp ; do
4565   test -d ${dir} || mkdir ${dir}
4566 done
4567 ])
4568
4569 dnl You might wonder (I did) why epaths.h is generated by running make,
4570 dnl rather than just letting configure generate it from epaths.in.
4571 dnl One reason is that the various paths are not fully expanded (see above);
4572 dnl eg gamedir=${prefix}/var/games/emacs.
4573 dnl Secondly, the GNU Coding standards require that one should be able
4574 dnl to run `make prefix=/some/where/else' and override the values set
4575 dnl by configure.  This also explains the `move-if-change' test and
4576 dnl the use of force in the `epaths-force' rule in Makefile.in.
4577 AC_CONFIG_COMMANDS([epaths], [
4578 echo creating src/epaths.h
4579 ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
4580 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
4581
4582 AC_CONFIG_COMMANDS([gdbinit], [
4583 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
4584   echo creating src/.gdbinit
4585   echo "source $srcdir/src/.gdbinit" > src/.gdbinit
4586 fi
4587 ])
4588
4589 AC_OUTPUT