code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2015 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.5.50)
  26
  27 dnl We get MINGW64 with MSYS2
  28 if test "x$MSYSTEM" = "xMINGW32" -o "x$MSYSTEM" = "xMINGW64"
  29 then
  30   . $srcdir/nt/mingw-cfg.site
  31
  32   case $srcdir in
  33     /* | ?:*)
  34       # srcdir is an absolute path.  In this case, force the format
  35       # "/c/foo/bar", to simplify later conversions to native Windows
  36       # format ("c:/foo/bar")
  37       srcdir=`cd "${srcdir}" && pwd -W`
  38       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
  39       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
  40       ;;
  41   esac
  42 fi
  43
  44 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  45 dnl and then quoted again for a C string.  Separate options with spaces.
  46 dnl Add some environment variables, if they were passed via the environment
  47 dnl rather than on the command-line.
  48 emacs_config_options=
  49 optsep=
  50 dnl This is the documented way to record the args passed to configure,
  51 dnl rather than $ac_configure_args.
  52 for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do
  53   case $opt in
  54     -n | --no-create | --no-recursion)
  55       continue ;;
  56     CFLAGS | CPPFLAGS | LDFLAGS)
  57       eval 'test "${'$opt'+set}" = set' || continue
  58       case " $*" in
  59         *" $opt="*) continue ;;
  60       esac
  61       eval opt=$opt=\$$opt ;;
  62   esac
  63
  64   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  65   case $opt in
  66     *[["$emacs_shell_specials"]]*)
  67       case $opt in
  68         *\'*)
  69           emacs_quote_apostrophes="s/'/'\\\\''/g"
  70           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  71       esac
  72       opt="'$opt'"
  73       case $opt in
  74         *[['"\\']]*)
  75           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  76           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  77       esac ;;
  78   esac
  79   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  80   optsep=' '
  81 done
  82
  83 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  84 AC_CONFIG_SRCDIR(src/lisp.h)
  85 AC_CONFIG_AUX_DIR(build-aux)
  86
  87 xcsdkdir=
  88 AC_CHECK_PROGS(XCRUN, [xcrun])
  89 if test -n "$XCRUN"; then
  90   if test -z "$MAKE"; then
  91     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  92     dnl SET_MAKE and with the usual MAKE variable that 'make' itself uses.
  93     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  94     if test -z "$MAKE_PROG"; then
  95       MAKE="$XCRUN MAKE"
  96       export MAKE
  97       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  98     fi
  99   fi
 100 fi
 101
 102 dnl Fairly arbitrary, older versions might work too.
 103 AM_INIT_AUTOMAKE(1.11)
 104
 105 dnl Support for --program-prefix, --program-suffix and
 106 dnl --program-transform-name options
 107 AC_ARG_PROGRAM
 108
 109 dnl It is important that variables on the RHS not be expanded here,
 110 dnl hence the single quotes.  This is per the GNU coding standards, see
 111 dnl (autoconf) Installation Directory Variables
 112 dnl See also epaths.h below.
 113 lispdir='${datadir}/emacs/${version}/lisp'
 114 standardlisppath='${lispdir}'
 115 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 116 '${datadir}/emacs/site-lisp'
 117 lisppath='${locallisppath}:${standardlisppath}'
 118 etcdir='${datadir}/emacs/${version}/etc'
 119 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 120 etcdocdir='${datadir}/emacs/${version}/etc'
 121 gamedir='${localstatedir}/games/emacs'
 122
 123 dnl Special option to disable the most of other options.
 124 AC_ARG_WITH(all,
 125 [AS_HELP_STRING([--without-all],
 126                 [omit almost all features and build
 127                 small executable with minimal dependencies])],
 128   [with_features=$withval],
 129   [with_features=yes])
 130
 131 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 132 dnl Create a new --with option that defaults to being disabled.
 133 dnl NAME is the base name of the option.  The shell variable with_NAME
 134 dnl   will be set to either the user's value (if the option is
 135 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 136 dnl   option is not specified).  Note that the shell variable name is
 137 dnl   constructed as autoconf does, by replacing non-alphanumeric
 138 dnl   characters with "_".
 139 dnl HELP-STRING is the help text for the option.
 140 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 141   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 142     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 143 ])dnl
 144
 145 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 146 dnl Create a new --with option that defaults to $with_features.
 147 dnl NAME is the base name of the option.  The shell variable with_NAME
 148 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 149 dnl   'yes' (if the option is not specified).  Note that the shell
 150 dnl   variable name is constructed as autoconf does, by replacing
 151 dnl   non-alphanumeric characters with "_".
 152 dnl HELP-STRING is the help text for the option.
 153 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 154   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 155    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 156 ])dnl
 157
 158 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 159 if test "$with_pop" = yes; then
 160    AC_DEFINE(MAIL_USE_POP)
 161 fi
 162 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 163
 164 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 165 if test "$with_kerberos" != no; then
 166    AC_DEFINE(KERBEROS)
 167 fi
 168 AH_TEMPLATE(KERBEROS,
 169             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 170
 171 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 172 if test "${with_kerberos5}" != no; then
 173   if test "${with_kerberos}" = no; then
 174     with_kerberos=yes
 175     AC_DEFINE(KERBEROS)
 176   fi
 177   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 178 fi
 179
 180 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 181 dnl FIXME hesiod support may not be present, so it seems like an error
 182 dnl to define, or at least use, this unconditionally.
 183 if test "$with_hesiod" != no; then
 184   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 185 fi
 186
 187 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 188 if test "$with_mmdf" != no; then
 189    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 190 fi
 191
 192 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 193 if test "$with_mail_unlink" != no; then
 194    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 195 fi
 196
 197 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 198     [string giving default POP mail host])],
 199     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 200
 201 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 202   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 203 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW.])],
 204   [ case "${withval}" in
 205       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 206       *) AC_MSG_ERROR([`--with-sound=$withval' is invalid;
 207 this option's value should be `yes', `no', `alsa', `oss', or `bsd-ossaudio'.])
 208       ;;
 209     esac
 210     with_sound=$val
 211   ],
 212   [with_sound=$with_features])
 213
 214 dnl FIXME currently it is not the last.
 215 dnl This should be the last --with option, because --with-x is
 216 dnl added later on when we find the file name of X, and it's best to
 217 dnl keep them together visually.
 218 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 219  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 220 [         case "${withval}" in
 221             y | ye | yes )      val=gtk ;;
 222             n | no )            val=no  ;;
 223             l | lu | luc | luci | lucid )       val=lucid ;;
 224             a | at | ath | athe | athen | athena )      val=athena ;;
 225             m | mo | mot | moti | motif )       val=motif ;;
 226             g | gt | gtk  )     val=gtk ;;
 227             gtk2  )     val=gtk2 ;;
 228             gtk3  )     val=gtk3 ;;
 229             * )
 230 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 231 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
 232 `gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
 233 `athena' and `lucid' are synonyms.])
 234             ;;
 235           esac
 236           with_x_toolkit=$val
 237 ])
 238
 239 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 240 if test "$with_wide_int" = yes; then
 241   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 242 fi
 243
 244 dnl _ON results in a '--without' option in the --help output, so
 245 dnl the help text should refer to "don't compile", etc.
 246 with_xpm_set=${with_xpm+set}
 247 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 248 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 249 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 250 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 251 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 252 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 253 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 254 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 255
 256 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 257 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 258 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 259
 260 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 261 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 262 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 263 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 264 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 265
 266 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 267 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 268 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 269 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 270 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 271 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 272 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 273
 274 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 275  [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
 276  [ case "${withval}" in
 277     y | ye | yes )      val=yes ;;
 278     n | no )            val=no  ;;
 279     g | gf | gfi | gfil | gfile )       val=gfile ;;
 280     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 281     w | w3 | w32 )      val=w32 ;;
 282     * ) AC_MSG_ERROR([`--with-file-notification=$withval' is invalid;
 283 this option's value should be `yes', `no', `gfile', `inotify' or `w32'.
 284 `yes' is a synonym for `w32' on MS-Windows, for `no' on Nextstep,
 285 otherwise for the first of `gfile' or `inotify' that is usable.])
 286     ;;
 287    esac
 288    with_file_notification=$val
 289  ],
 290  [with_file_notification=$with_features])
 291
 292 ## For the times when you want to build Emacs but don't have
 293 ## a suitable makeinfo, and can live without the manuals.
 294 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 295 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 296
 297 ## Makefile.in needs the cache file name.
 298 AC_SUBST(cache_file)
 299
 300 ## This is an option because I do not know if all info/man support
 301 ## compressed files, nor how to test if they do so.
 302 OPTION_DEFAULT_ON([compress-install],
 303   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 304 make GZIP_PROG= install])
 305
 306 AC_ARG_WITH([pkg-config-prog],dnl
 307 [AS_HELP_STRING([--with-pkg-config-prog=FILENAME],
 308                   [file name of pkg-config for finding GTK and librsvg])])
 309 if test "X${with_pkg_config_prog}" != X; then
 310    if test "${with_pkg_config_prog}" != yes; then
 311       PKG_CONFIG="${with_pkg_config_prog}"
 312    fi
 313 fi
 314
 315 AC_ARG_WITH(gameuser,dnl
 316 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 317 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 318   && gameuser="${with_gameuser}"
 319 test "X$gameuser" = X && gameuser=games
 320
 321 AC_ARG_WITH([gnustep-conf],dnl
 322 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 323    [name of GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 324 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 325   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 326 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 327      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 328
 329 AC_ARG_ENABLE(ns-self-contained,
 330 [AS_HELP_STRING([--disable-ns-self-contained],
 331                 [disable self contained build under NeXTstep])],
 332    EN_NS_SELF_CONTAINED=$enableval,
 333    EN_NS_SELF_CONTAINED=yes)
 334
 335 AC_ARG_ENABLE(locallisppath,
 336 [AS_HELP_STRING([--enable-locallisppath=PATH],
 337                 [directories Emacs should search for lisp files specific
 338                  to this site])],
 339 if test "${enableval}" = "no"; then
 340   locallisppath=
 341 elif test "${enableval}" != "yes"; then
 342   locallisppath=${enableval}
 343 fi)
 344
 345 AC_ARG_ENABLE(checking,
 346 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 347                 [enable expensive run-time checks.  With LIST,
 348                  enable only specific categories of checks.
 349                  Categories are: all,yes,no.
 350                  Flags are: stringbytes, stringoverrun, stringfreelist,
 351                  xmallocoverrun, conslist, glyphs])],
 352 [ac_checking_flags="${enableval}"],[])
 353 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 354 for check in $ac_checking_flags
 355 do
 356         case $check in
 357         # these set all the flags to specific states
 358         yes)            ac_enable_checking=1 ;;
 359         no)             ac_enable_checking= ;
 360                         ac_gc_check_stringbytes= ;
 361                         ac_gc_check_string_overrun= ;
 362                         ac_gc_check_string_free_list= ;
 363                         ac_xmalloc_overrun= ;
 364                         ac_gc_check_cons_list= ;
 365                         ac_glyphs_debug= ;;
 366         all)            ac_enable_checking=1 ;
 367                         ac_gc_check_stringbytes=1 ;
 368                         ac_gc_check_string_overrun=1 ;
 369                         ac_gc_check_string_free_list=1 ;
 370                         ac_xmalloc_overrun=1 ;
 371                         ac_gc_check_cons_list=1 ;
 372                         ac_glyphs_debug=1 ;;
 373         # these enable particular checks
 374         stringbytes)    ac_gc_check_stringbytes=1 ;;
 375         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 376         stringfreelist) ac_gc_check_string_free_list=1 ;;
 377         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 378         conslist)       ac_gc_check_cons_list=1 ;;
 379         glyphs)         ac_glyphs_debug=1 ;;
 380         *)      AC_MSG_ERROR(unknown check category $check) ;;
 381         esac
 382 done
 383 IFS="$ac_save_IFS"
 384
 385 if test x$ac_enable_checking != x ; then
 386   AC_DEFINE(ENABLE_CHECKING, 1,
 387 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 388 fi
 389 if test x$ac_gc_check_stringbytes != x ; then
 390   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 391 [Define this temporarily to hunt a bug.  If defined, the size of
 392    strings is redundantly recorded in sdata structures so that it can
 393    be compared to the sizes recorded in Lisp strings.])
 394 fi
 395 if test x$ac_gc_check_string_overrun != x ; then
 396   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 397 [Define this to check for short string overrun.])
 398 fi
 399 if test x$ac_gc_check_string_free_list != x ; then
 400   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 401 [Define this to check the string free list.])
 402 fi
 403 if test x$ac_xmalloc_overrun != x ; then
 404   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 405 [Define this to check for malloc buffer overrun.])
 406 fi
 407 if test x$ac_gc_check_cons_list != x ; then
 408   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 409 [Define this to check for errors in cons list.])
 410 fi
 411 if test x$ac_glyphs_debug != x ; then
 412   AC_DEFINE(GLYPH_DEBUG, 1,
 413 [Define this to enable glyphs debugging code.])
 414 fi
 415
 416 AC_ARG_ENABLE(check-lisp-object-type,
 417 [AS_HELP_STRING([--enable-check-lisp-object-type],
 418                 [enable compile time checks for the Lisp_Object data type.
 419                 This is useful for development for catching certain types of bugs.])],
 420 if test "${enableval}" != "no"; then
 421    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 422    [Define this to enable compile time checks for the Lisp_Object data type.])
 423 fi)
 424
 425
 426 dnl The name of this option is unfortunate.  It predates, and has no
 427 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 428 dnl Actually, it stops it working.
 429 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 430 AC_ARG_ENABLE(profiling,
 431 [AS_HELP_STRING([--enable-profiling],
 432                 [build emacs with low-level, gprof profiling support.
 433                 Mainly useful for debugging Emacs itself.  May not work on
 434                 all platforms.  Stops profiler.el working.])],
 435 [ac_enable_profiling="${enableval}"],[])
 436 if test x$ac_enable_profiling != x ; then
 437    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 438 else
 439    PROFILING_CFLAGS=
 440 fi
 441 AC_SUBST(PROFILING_CFLAGS)
 442
 443 AC_ARG_ENABLE(autodepend,
 444 [AS_HELP_STRING([--enable-autodepend],
 445                 [automatically generate dependencies to .h-files.
 446                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 447                  found])],
 448 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 449
 450 AC_ARG_ENABLE(gtk-deprecation-warnings,
 451 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 452                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 453 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 454
 455 ### Canonicalize the configuration name.
 456
 457 AC_CANONICAL_HOST
 458 canonical=$host
 459 configuration=${host_alias-${build_alias-$host}}
 460
 461 dnl This used to use changequote, but, apart from `changequote is evil'
 462 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 463 dnl the great gob of text.  Thus it's not processed for possible expansion.
 464 dnl Just make sure the brackets remain balanced.
 465 dnl
 466 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 467 dnl indicated by comments.
 468 dnl quotation begins
 469 [
 470
 471 ### If you add support for a new configuration, add code to this
 472 ### switch statement to recognize your configuration name and select
 473 ### the appropriate opsys.
 474
 475 ### As far as handling version numbers on operating systems is
 476 ### concerned, make sure things will fail in a fixable way.  If
 477 ### /etc/MACHINES doesn't say anything about version numbers, be
 478 ### prepared to handle anything reasonably.  If version numbers
 479 ### matter, be sure /etc/MACHINES says something about it.
 480
 481 opsys='' unported=no
 482 case "${canonical}" in
 483
 484   ## GNU/Linux and similar ports
 485   *-*-linux* )
 486     opsys=gnu-linux
 487   ;;
 488
 489   ## FreeBSD ports
 490   *-*-freebsd* )
 491     opsys=freebsd
 492   ;;
 493
 494   ## DragonFly ports
 495   *-*-dragonfly* )
 496     opsys=dragonfly
 497   ;;
 498
 499   ## FreeBSD kernel + glibc based userland
 500   *-*-kfreebsd*gnu* )
 501     opsys=gnu-kfreebsd
 502   ;;
 503
 504   ## NetBSD ports
 505   *-*-netbsd* )
 506     opsys=netbsd
 507   ;;
 508
 509   ## OpenBSD ports
 510   *-*-openbsd* | *-*-mirbsd* )
 511     opsys=openbsd
 512   ;;
 513
 514   ## Apple Darwin / Mac OS X
 515   *-apple-darwin* )
 516     case "${canonical}" in
 517       i[3456]86-* )  ;;
 518       powerpc-* )    ;;
 519       x86_64-* )     ;;
 520       * )            unported=yes ;;
 521     esac
 522     opsys=darwin
 523     ## Use fink packages if available.
 524     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 525 ##    if test -d /sw/include && test -d /sw/lib; then
 526 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 527 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 528 ##    fi
 529   ;;
 530
 531   ## Cygwin ports
 532   *-*-cygwin )
 533     opsys=cygwin
 534   ;;
 535
 536   ## HP 9000 series 700 and 800, running HP/UX
 537   hppa*-hp-hpux10.2* )
 538     opsys=hpux10-20
 539   ;;
 540   hppa*-hp-hpux1[1-9]* )
 541     opsys=hpux11
 542     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 543   ;;
 544
 545   ## IBM machines
 546   rs6000-ibm-aix4.[23]* )
 547     opsys=aix4-2
 548   ;;
 549   powerpc-ibm-aix4.[23]*  )
 550     opsys=aix4-2
 551   ;;
 552   rs6000-ibm-aix[56]* )
 553     opsys=aix4-2
 554   ;;
 555   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 556     opsys=aix4-2
 557   ;;
 558
 559   ## Silicon Graphics machines
 560   ## Iris 4D
 561   mips-sgi-irix6.5 )
 562     opsys=irix6-5
 563     # Without defining _LANGUAGE_C, things get masked out in the headers
 564     # so that, for instance, grepping for `free' in stdlib.h fails and
 565     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 566     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 567   ;;
 568
 569   ## Suns
 570   *-sun-solaris* \
 571     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 572     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 573     case "${canonical}" in
 574       i[3456]86-*-* )   ;;
 575       amd64-*-*|x86_64-*-*) ;;
 576       sparc* )          ;;
 577       * )               unported=yes ;;
 578     esac
 579     case "${canonical}" in
 580       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 581                 opsys=sol2-10
 582                 emacs_check_sunpro_c=yes
 583                 ;;
 584       *-sunos5.6* | *-solaris2.6* )
 585                 opsys=sol2-6
 586                 RANLIB="ar -ts"
 587                 ;;
 588       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 589                 opsys=sol2-6
 590                 emacs_check_sunpro_c=yes
 591                 ;;
 592     esac
 593     ## Watch out for a compiler that we know will not work.
 594     case "${canonical}" in
 595      *-solaris* | *-sunos5* )
 596                 if [ "x$CC" = x/usr/ucb/cc ]; then
 597                   ## /usr/ucb/cc doesn't work;
 598                   ## we should find some other compiler that does work.
 599                   unset CC
 600                 fi
 601                 ;;
 602       *) ;;
 603     esac
 604   ;;
 605
 606   ## Intel 386 machines where we don't care about the manufacturer.
 607   i[3456]86-*-* )
 608     case "${canonical}" in
 609       *-darwin* )               opsys=darwin ;;
 610       *-mingw32 )
 611                 opsys=mingw32
 612                 # MinGW overrides and adds some system headers in nt/inc.
 613                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 614                 ;;
 615       *-sysv4.2uw* )            opsys=unixware ;;
 616       *-sysv5uw* )              opsys=unixware ;;
 617       *-sysv5OpenUNIX* )        opsys=unixware ;;
 618       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 619     esac
 620   ;;
 621
 622   # MinGW64
 623   x86_64-*-* )
 624     case "${canonical}" in
 625       *-mingw32 )
 626                 opsys=mingw32
 627                 # MinGW overrides and adds some system headers in nt/inc.
 628                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 629                 ;;
 630       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 631     esac
 632   ;;
 633
 634   * )
 635     unported=yes
 636   ;;
 637 esac
 638
 639 ### If the code above didn't choose an operating system, just choose
 640 ### an operating system based on the configuration name.  You really
 641 ### only want to use this when you have no idea what the right
 642 ### operating system is; if you know what operating systems a machine
 643 ### runs, it's cleaner to make it explicit in the case statement
 644 ### above.
 645 if test x"${opsys}" = x; then
 646   case "${canonical}" in
 647     *-gnu* )                            opsys=gnu ;;
 648     * )
 649       unported=yes
 650     ;;
 651   esac
 652 fi
 653
 654 ]
 655 dnl quotation ends
 656
 657 if test $unported = yes; then
 658   AC_MSG_ERROR([Emacs does not support `${canonical}' systems.
 659 If you think it should, please send a report to bug-gnu-emacs@gnu.org.
 660 Check `etc/MACHINES' for recognized configuration names.])
 661 fi
 662
 663
 664 #### Choose a compiler.
 665
 666 dnl Sets GCC=yes if using gcc.
 667 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 668 if test -n "$XCRUN"; then
 669   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 670   test -n "$AR" && export AR
 671 fi
 672
 673 AM_PROG_CC_C_O
 674
 675 if test x$GCC = xyes; then
 676   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 677 else
 678   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 679 fi
 680
 681 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 682 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 683 dnl that clash with MinGW.
 684 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 685
 686 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 687 AC_DEFUN([gl_CRYPTO_CHECK])
 688 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 689 # as we don't use them.
 690 AC_DEFUN([gl_FCNTL_O_FLAGS])
 691 # Avoid gnulib's threadlib module, as we do threads our own way.
 692 AC_DEFUN([gl_THREADLIB])
 693
 694 # Initialize gnulib right after choosing the compiler.
 695 dnl Amongst other things, this sets AR and ARFLAGS.
 696 gl_EARLY
 697
 698 if test "$ac_test_CFLAGS" != set; then
 699   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 700   # if -g3 works and the user does not specify CFLAGS.
 701   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 702   case $CFLAGS in
 703     '-g')
 704       emacs_g3_CFLAGS='-g3';;
 705     '-g -O2')
 706       emacs_g3_CFLAGS='-g3 -O2';;
 707     *)
 708       emacs_g3_CFLAGS='';;
 709   esac
 710   if test -n "$emacs_g3_CFLAGS"; then
 711     emacs_save_CFLAGS=$CFLAGS
 712     CFLAGS=$emacs_g3_CFLAGS
 713     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 714       [emacs_cv_prog_cc_g3],
 715       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 716          [emacs_cv_prog_cc_g3=yes],
 717          [emacs_cv_prog_cc_g3=no])])
 718     if test $emacs_cv_prog_cc_g3 != yes; then
 719       CFLAGS=$emacs_save_CFLAGS
 720     fi
 721     if test $opsys = mingw32; then
 722       CFLAGS="$CFLAGS -gdwarf-2"
 723     fi
 724   fi
 725
 726   case $CFLAGS in
 727     *-O*) ;;
 728     *)
 729       # No optimization flag was inferred for this non-GCC compiler.
 730       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 731       emacs_save_CFLAGS=$CFLAGS
 732       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 733       CFLAGS=${CFLAGS}-O
 734       AC_CACHE_CHECK([whether $CC accepts -O],
 735         [emacs_cv_prog_cc_o],
 736         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 737            [emacs_cv_prog_cc_o=yes],
 738            [emacs_cv_prog_cc_o=no])])
 739       if test $emacs_cv_prog_cc_o != yes; then
 740         CFLAGS=$emacs_save_CFLAGS
 741       fi ;;
 742   esac
 743 fi
 744
 745 AC_ARG_ENABLE([gcc-warnings],
 746   [AS_HELP_STRING([--enable-gcc-warnings],
 747                   [turn on lots of GCC warnings/errors. This is intended for
 748                    developers, and may generate false alarms when used
 749                    with older or non-GNU development tools.])],
 750   [case $enableval in
 751      yes|no) ;;
 752      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 753    esac
 754    gl_gcc_warnings=$enableval],
 755   [gl_gcc_warnings=no]
 756 )
 757
 758 AC_ARG_ENABLE(link-time-optimization,
 759 [AS_HELP_STRING([--enable-link-time-optimization],
 760                 [build emacs with link-time optimization.
 761                  This requires GCC 4.5.0 or later.
 762                  It also makes Emacs harder to debug, and when we tried it
 763                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
 764                  recommended for typical use.])],
 765 if test "${enableval}" != "no"; then
 766    AC_MSG_CHECKING([whether link-time optimization is supported])
 767    ac_lto_supported=no
 768    if test x$GCC = xyes; then
 769       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 770       if test x$CPUS != x; then
 771          LTO="-flto=$CPUS"
 772       else
 773          LTO="-flto"
 774       fi
 775       old_CFLAGS=$CFLAGS
 776       CFLAGS="$CFLAGS $LTO"
 777       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 778         [ac_lto_supported=yes], [ac_lto_supported=no])
 779       CFLAGS="$old_CFLAGS"
 780    fi
 781    AC_MSG_RESULT([$ac_lto_supported])
 782    if test "$ac_lto_supported" = "yes"; then
 783       CFLAGS="$CFLAGS $LTO"
 784       dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
 785       dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
 786       dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
 787       dnl dump core on Fedora 20, so play it safe for now.
 788       gl_COMPILER_OPTION_IF([-ffat-lto-objects],
 789         [CFLAGS="$CFLAGS -ffat-lto-objects"])
 790    fi
 791 fi)
 792
 793 # clang is unduly picky about some things.
 794 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 795   [AC_COMPILE_IFELSE(
 796      [AC_LANG_PROGRAM([[
 797           #ifndef __clang__
 798             error "not clang";
 799           #endif
 800         ]])],
 801      [emacs_cv_clang=yes],
 802      [emacs_cv_clang=no])])
 803
 804 # When compiling with GCC, prefer -isystem to -I when including system
 805 # include files, to avoid generating useless diagnostics for the files.
 806 if test "$gl_gcc_warnings" != yes; then
 807   isystem='-I'
 808   if test "$emacs_cv_clang" = yes
 809   then
 810      # Turn off some warnings if supported.
 811      gl_WARN_ADD([-Wno-switch])
 812      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 813      gl_WARN_ADD([-Wno-pointer-sign])
 814   fi
 815 else
 816   isystem='-isystem '
 817
 818   # This, $nw, is the list of warnings we disable.
 819   nw=
 820
 821   case $with_x_toolkit in
 822     lucid | athena | motif)
 823        # Old toolkits mishandle 'const'.
 824        nw="$nw -Wwrite-strings"
 825        ;;
 826     *)
 827        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 828        ;;
 829   esac
 830   AC_SUBST([WERROR_CFLAGS])
 831
 832   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 833   nw="$nw -Woverlength-strings"     # Not a problem these days
 834   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 835   nw="$nw -Wformat-nonliteral"      # we do this a lot
 836   nw="$nw -Wvla"                    # warnings in gettext.h
 837   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 838   nw="$nw -Wswitch-default"         # Too many warnings for now
 839   nw="$nw -Winline"                 # OK to ignore 'inline'
 840   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 841   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 842                                     # signed overflow has undefined behavior
 843   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 844   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 845   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 846
 847   # Emacs doesn't care about shadowing; see
 848   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 849   nw="$nw -Wshadow"
 850
 851   # Emacs's use of alloca inhibits protecting the stack.
 852   nw="$nw -Wstack-protector"
 853
 854   # The following line should be removable at some point.
 855   nw="$nw -Wsuggest-attribute=pure"
 856
 857   # This part is merely for shortening the command line,
 858   # since -Wno-FOO needs to be added below regardless.
 859   nw="$nw -Wmissing-field-initializers"
 860   nw="$nw -Wswitch"
 861   nw="$nw -Wtype-limits"
 862   nw="$nw -Wunused-parameter"
 863
 864   if test $emacs_cv_clang = yes; then
 865     nw="$nw -Wcast-align"
 866   fi
 867
 868   gl_MANYWARN_ALL_GCC([ws])
 869   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 870   for w in $ws; do
 871     gl_WARN_ADD([$w])
 872   done
 873   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 874   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 875   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 876   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 877   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 878   gl_WARN_ADD([-Wno-format-nonliteral])
 879
 880   # In spite of excluding -Wlogical-op above, it is enabled, as of
 881   # gcc 4.5.0 20090517.
 882   gl_WARN_ADD([-Wno-logical-op])
 883
 884   # More things that clang is unduly picky about.
 885   if test $emacs_cv_clang = yes; then
 886     gl_WARN_ADD([-Wno-format-extra-args])
 887     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 888     gl_WARN_ADD([-Wno-unused-command-line-argument])
 889     gl_WARN_ADD([-Wno-unused-value])
 890   fi
 891
 892   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 893   AH_VERBATIM([FORTIFY_SOURCE],
 894   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 895       without upsetting glibc 2.15+. */
 896    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 897    # define _FORTIFY_SOURCE 2
 898    #endif
 899   ])
 900   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 901
 902   # We use a slightly smaller set of warning options for lib/.
 903   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 904   nw=
 905   nw="$nw -Wunused-macros"
 906
 907   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 908   AC_SUBST([GNULIB_WARN_CFLAGS])
 909 fi
 910
 911 edit_cflags="
 912   s,///*,/,g
 913   s/^/ /
 914   s/ -I/ $isystem/g
 915   s/^ //
 916 "
 917
 918
 919 dnl Some other nice autoconf tests.
 920 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 921 dnl AC_PROG_INSTALL
 922 dnl AC_PROG_MKDIR_P
 923 dnl if test "x$RANLIB" = x; then
 924 dnl   AC_PROG_RANLIB
 925 dnl fi
 926
 927
 928 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
 929 dnl can be made to directories.  This is not relevant for our usage, and
 930 dnl excludes some cases that work fine for us.  Eg MS Windows or files
 931 dnl hosted on AFS, both examples where simple links work, but links to
 932 dnl directories fail.  We use a cut-down version instead.
 933 dnl AC_PROG_LN_S
 934
 935 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
 936 rm -f conf$$ conf$$.file
 937
 938 LN_S_FILEONLY='cp -p'
 939
 940 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
 941 dnl random program in the current directory.
 942 if (echo >conf$$.file) 2>/dev/null; then
 943   if ln -s conf$$.file conf$$ 2>/dev/null; then
 944     if test "$opsys" = "mingw32"; then
 945       LN_S_FILEONLY='/bin/ln -s'
 946     else
 947       LN_S_FILEONLY='ln -s'
 948     fi
 949   elif ln conf$$.file conf$$ 2>/dev/null; then
 950     if test "$opsys" = "mingw32"; then
 951       LN_S_FILEONLY=/bin/ln
 952     else
 953       LN_S_FILEONLY=ln
 954     fi
 955   fi
 956 fi
 957
 958 rm -f conf$$ conf$$.file
 959
 960 if test "$LN_S_FILEONLY" = "ln -s"; then
 961    AC_MSG_RESULT([yes])
 962 else
 963    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
 964 fi
 965
 966 AC_SUBST(LN_S_FILEONLY)
 967
 968
 969 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
 970 dnl doesn't support links to directories, as in "ln file dir".  But that
 971 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
 972 dnl executables at "make install" time.
 973 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
 974 dnl for more details.
 975 if test "$opsys" = "mingw32"; then
 976   LN_S="/bin/ln"
 977 fi
 978
 979 dnl On some Debian versions, "install-info" prints irritating messages
 980 dnl "This is not dpkg install-info anymore, but GNU install-info"
 981 dnl if called via an absolute file name.
 982 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
 983 dnl Sadly some people may have an old ginstall-info installed on
 984 dnl non-Debian systems, so we can't use this.
 985 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
 986 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 987
 988 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 989   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 990 dnl Don't use GZIP, which is used by gzip for additional parameters.
 991 AC_PATH_PROG(GZIP_PROG, gzip)
 992
 993 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
 994    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
 995
 996 if test $opsys = gnu-linux; then
 997   AC_PATH_PROG(PAXCTL, paxctl,,
 998     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 999   if test "X$PAXCTL" != X; then
1000     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1001     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1002       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
1003       else AC_MSG_RESULT(no); PAXCTL=""; fi])
1004   fi
1005
1006   if test "${SETFATTR+set}" != set; then
1007     AC_CACHE_CHECK([for setfattr],
1008       [emacs_cv_prog_setfattr],
1009       [touch conftest.tmp
1010        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1011          emacs_cv_prog_setfattr=yes
1012        else
1013          emacs_cv_prog_setfattr=no
1014        fi])
1015     if test "$emacs_cv_prog_setfattr" = yes; then
1016       SETFATTR=setfattr
1017     else
1018       SETFATTR=
1019     fi
1020     rm -f conftest.tmp
1021     AC_SUBST([SETFATTR])
1022   fi
1023 fi
1024
1025 ## Need makeinfo >= 4.7 (?) to build the manuals.
1026 AC_PATH_PROG(MAKEINFO, makeinfo, no)
1027 dnl By this stage, configure has already checked for egrep and set EGREP,
1028 dnl or exited with an error if no egrep was found.
1029 if test "$MAKEINFO" != "no"; then
1030   case `
1031     $MAKEINFO --version 2> /dev/null |
1032     $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'
1033   ` in
1034     '') MAKEINFO=no;;
1035   esac
1036 fi
1037
1038 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1039 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1040 ## therefore in the category of "special tools" not normally required, which
1041 ## configure does not have to check for (eg autoconf itself).
1042 ## In a repository checkout on the other hand, the manuals are not included.
1043 ## So makeinfo is a requirement to build from the repository, and configure
1044 ## should test for it as it does for any other build requirement.
1045 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1046 ## with pre-built manuals, from a repository checkout.
1047 HAVE_MAKEINFO=yes
1048
1049 if test "$MAKEINFO" = "no"; then
1050   MAKEINFO=makeinfo
1051   if test "x${with_makeinfo}" = "xno"; then
1052     HAVE_MAKEINFO=no
1053   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1054     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1055 source tree does not seem to have pre-built manuals in the `info' directory.
1056 Either install a suitable version of makeinfo, or re-run configure
1057 with the `--without-makeinfo' option to build without the manuals.] )
1058   fi
1059 fi
1060 AC_SUBST(HAVE_MAKEINFO)
1061
1062 dnl Just so that there is only a single place we need to edit.
1063 INFO_EXT=.info
1064 INFO_OPTS=--no-split
1065 AC_SUBST(INFO_EXT)
1066 AC_SUBST(INFO_OPTS)
1067
1068 if test $opsys = mingw32; then
1069    DOCMISC_W32=efaq-w32
1070 else
1071    DOCMISC_W32=
1072 fi
1073 AC_SUBST(DOCMISC_W32)
1074
1075 dnl Add our options to ac_link now, after it is set up.
1076
1077 if test x$GCC = xyes; then
1078   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1079     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1080 else
1081   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1082     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1083 fi
1084
1085 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1086 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1087 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
1088 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
1089 dnl if not built to support GNU ld.
1090
1091 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1092 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1093 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1094 dnl   Eg "make LDFLAGS=... all" could run into problems,
1095 dnl   http://bugs.debian.org/684788
1096 dnl * unnecessary, since temacs is the only thing that actually needs it.
1097 dnl   Indeed this is where it was originally, prior to:
1098 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1099 late_LDFLAGS="$LDFLAGS"
1100 if test x$GCC = xyes; then
1101   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1102 else
1103   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1104 fi
1105
1106 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1107
1108 AC_MSG_CHECKING([for -znocombreloc])
1109 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1110   [AC_MSG_RESULT(yes)],
1111   LDFLAGS_NOCOMBRELOC=
1112   [AC_MSG_RESULT(no)])
1113
1114 LDFLAGS="$late_LDFLAGS"
1115
1116 AC_CACHE_CHECK([whether addresses are sanitized],
1117   [emacs_cv_sanitize_address],
1118   [AC_COMPILE_IFELSE(
1119      [AC_LANG_PROGRAM(
1120         [[#ifndef __has_feature
1121           #define __has_feature(f) 0
1122           #endif
1123           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1124           #else
1125            error "Addresses are not sanitized.";
1126           #endif
1127         ]])],
1128      [emacs_cv_sanitize_address=yes],
1129      [emacs_cv_sanitize_address=no])])
1130
1131 dnl The function dump-emacs will not be defined and temacs will do
1132 dnl (load "loadup") automatically unless told otherwise.
1133 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1134 case "$opsys" in
1135   your-opsys-here) CANNOT_DUMP=yes ;;
1136 esac
1137
1138 if test "$CANNOT_DUMP" = "yes"; then
1139   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1140 elif test "$emacs_cv_sanitize_address" = yes; then
1141   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1142 fi
1143
1144 AC_SUBST(CANNOT_DUMP)
1145
1146
1147 UNEXEC_OBJ=unexelf.o
1148 case "$opsys" in
1149   # MSDOS uses unexcoff.o
1150   aix4-2)
1151    UNEXEC_OBJ=unexaix.o
1152    ;;
1153   cygwin)
1154    UNEXEC_OBJ=unexcw.o
1155    ;;
1156   darwin)
1157    UNEXEC_OBJ=unexmacosx.o
1158    ;;
1159   hpux10-20 | hpux11)
1160    UNEXEC_OBJ=unexhp9k800.o
1161    ;;
1162   mingw32)
1163    UNEXEC_OBJ=unexw32.o
1164    ;;
1165   sol2-10)
1166    # Use the Solaris dldump() function, called from unexsol.c, to dump
1167    # emacs, instead of the generic ELF dump code found in unexelf.c.
1168    # The resulting binary has a complete symbol table, and is better
1169    # for debugging and other observability tools (debuggers, pstack, etc).
1170    #
1171    # If you encounter a problem using dldump(), please consider sending
1172    # a message to the OpenSolaris tools-linking mailing list:
1173    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1174    #
1175    # It is likely that dldump() works with older Solaris too, but this has
1176    # not been tested, so for now this change is for Solaris 10 or newer.
1177    UNEXEC_OBJ=unexsol.o
1178    ;;
1179 esac
1180
1181 LD_SWITCH_SYSTEM=
1182 case "$opsys" in
1183   freebsd|dragonfly)
1184    ## Let `ld' find image libs and similar things in /usr/local/lib.
1185    ## The system compiler, GCC, has apparently been modified to not
1186    ## look there, contrary to what a stock GCC would do.
1187 ### It's not our place to do this.  See bug#10313#17.
1188 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1189       :
1190    ;;
1191
1192   gnu-linux)
1193    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1194    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1195    ;;
1196
1197   netbsd)
1198 ### It's not our place to do this.  See bug#10313#17.
1199 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1200       :
1201    ;;
1202
1203   openbsd)
1204    ## Han Boetes <han@boetes.org> says this is necessary,
1205    ## otherwise Emacs dumps core on elf systems.
1206    LD_SWITCH_SYSTEM="-Z"
1207    ;;
1208 esac
1209 AC_SUBST(LD_SWITCH_SYSTEM)
1210
1211 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1212
1213 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1214 ## which has not been defined yet.  When this was handled with cpp,
1215 ## it was expanded to null when configure sourced the s/*.h file.
1216 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1217 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1218 ## (or somesuch), but because it is supposed to go at the _front_
1219 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1220 ## Compare with the gnu-linux case below, which added to the end
1221 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1222 ## LD_SWITCH_SYSTEM_TEMACS.
1223 case "$opsys" in
1224   netbsd|openbsd)
1225    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1226 esac
1227
1228
1229 C_SWITCH_MACHINE=
1230 case $canonical in
1231  alpha*)
1232   AC_CHECK_DECL([__ELF__])
1233   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1234     ## With ELF, make sure that all common symbols get allocated to in the
1235     ## data section.  Otherwise, the dump of temacs may miss variables in
1236     ## the shared library that have been initialized.  For example, with
1237     ## GNU libc, __malloc_initialized would normally be resolved to the
1238     ## shared library's .bss section, which is fatal.
1239     if test "x$GCC" = "xyes"; then
1240       C_SWITCH_MACHINE="-fno-common"
1241     else
1242       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1243     fi
1244   else
1245       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1246       dnl albeit under the mistaken assumption that said file
1247       dnl was no longer used.
1248       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1249   fi
1250   ;;
1251 esac
1252 AC_SUBST(C_SWITCH_MACHINE)
1253
1254 AC_SUBST(UNEXEC_OBJ)
1255
1256 C_SWITCH_SYSTEM=
1257 ## Some programs in src produce warnings saying certain subprograms
1258 ## are too complex and need a MAXMEM value greater than 2000 for
1259 ## additional optimization.  --nils@exp-math.uni-essen.de
1260 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1261   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1262 if test "$opsys" = "mingw32"; then
1263   case "$canonical" in
1264     x86_64-*-mingw32) C_SWITCH_SYSTEM="-mtune=generic" ;;
1265     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1266   esac
1267 fi
1268 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1269 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1270 AC_SUBST(C_SWITCH_SYSTEM)
1271
1272
1273 LIBS_SYSTEM=
1274 case "$opsys" in
1275   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1276   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1277
1278   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1279
1280   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1281
1282   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1283
1284   ## Motif needs -lgen.
1285   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1286 esac
1287
1288 AC_SUBST(LIBS_SYSTEM)
1289
1290 ### Make sure subsequent tests use flags consistent with the build flags.
1291
1292 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1293   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1294 else
1295   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1296 fi
1297
1298 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1299 AC_DEFUN([AC_TYPE_SIZE_T])
1300 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1301 AC_DEFUN([AC_TYPE_UID_T])
1302
1303
1304 LIB_MATH=-lm
1305 dnl Current possibilities handled by sed (aix4-2 -> aix,
1306 dnl gnu-linux -> gnu/linux, etc.):
1307 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1308 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1309 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1310
1311 case $opsys in
1312   cygwin )
1313     LIB_MATH=
1314     ;;
1315   darwin )
1316     ## Adding -lm confuses the dynamic linker, so omit it.
1317     LIB_MATH=
1318     ;;
1319   freebsd | dragonfly )
1320     SYSTEM_TYPE=berkeley-unix
1321     ;;
1322   gnu-linux | gnu-kfreebsd )
1323     ;;
1324   hpux10-20 | hpux11 )
1325     ;;
1326   mingw32 )
1327     LIB_MATH=
1328     SYSTEM_TYPE=windows-nt
1329     ;;
1330   dnl NB this may be adjusted below.
1331   netbsd | openbsd )
1332     SYSTEM_TYPE=berkeley-unix
1333     ;;
1334
1335   sol2* | unixware )
1336     SYSTEM_TYPE=usg-unix-v
1337     ;;
1338
1339 esac
1340
1341 AC_SUBST(LIB_MATH)
1342 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1343   [The type of system you are compiling for; sets `system-type'.])
1344
1345
1346 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1347 pre_PKG_CONFIG_LIBS=$LIBS
1348
1349 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1350
1351 dnl This function definition taken from Gnome 2.0
1352 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1353 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1354 dnl also defines GSTUFF_PKG_ERRORS on error
1355 AC_DEFUN([PKG_CHECK_MODULES], [
1356   succeeded=no
1357
1358   if test "$PKG_CONFIG" = "no" ; then
1359      ifelse([$4], , [AC_MSG_ERROR([
1360       *** The pkg-config script could not be found. Make sure it is in your path, or give the full name of pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1361   else
1362      PKG_CONFIG_MIN_VERSION=0.9.0
1363      if "$PKG_CONFIG" --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1364         AC_MSG_CHECKING(for $2)
1365
1366         if "$PKG_CONFIG" --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1367            $1_CFLAGS=`"$PKG_CONFIG" --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1368            $1_LIBS=`"$PKG_CONFIG" --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1369             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1370             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1371             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1372             succeeded=yes
1373         else
1374             AC_MSG_RESULT(no)
1375             $1_CFLAGS=""
1376             $1_LIBS=""
1377             ## If we have a custom action on failure, don't print errors, but
1378             ## do set a variable so people can do so.  Do it in a subshell
1379             ## to capture any diagnostics in invoking pkg-config.
1380             $1_PKG_ERRORS=`("$PKG_CONFIG" --print-errors "$2") 2>&1`
1381             ifelse([$4], ,echo "$$1_PKG_ERRORS",)
1382         fi
1383
1384         AC_SUBST($1_CFLAGS)
1385         AC_SUBST($1_LIBS)
1386      else
1387         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1388         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1389      fi
1390   fi
1391
1392   if test $succeeded = yes; then
1393      ifelse([$3], , :, [$3])
1394   else
1395      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1396   fi
1397 ])
1398
1399 HAVE_SOUND=no
1400 if test "${with_sound}" != "no"; then
1401   # Sound support for GNU/Linux, the free BSDs, and MinGW.
1402   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1403     have_sound_header=yes, [], [
1404     #ifdef __MINGW32__
1405     #define WIN32_LEAN_AND_MEAN
1406     #include <windows.h>
1407     #endif
1408     ])
1409   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1410     AC_MSG_ERROR([OSS sound support requested but not found.])
1411
1412   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1413     # Emulation library used on NetBSD.
1414     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1415     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1416       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1417     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1418     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1419   fi
1420   AC_SUBST(LIBSOUND)
1421
1422   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1423     ALSA_REQUIRED=1.0.0
1424     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1425     PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1426     if test $HAVE_ALSA = yes; then
1427       SAVE_CFLAGS="$CFLAGS"
1428       SAVE_LIBS="$LIBS"
1429       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1430       LIBS="$ALSA_LIBS $LIBS"
1431       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1432                       emacs_alsa_normal=yes,
1433                     emacs_alsa_normal=no)
1434       if test "$emacs_alsa_normal" != yes; then
1435         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1436                        [[snd_lib_error_set_handler (0);]])],
1437                        emacs_alsa_subdir=yes,
1438                      emacs_alsa_subdir=no)
1439         if test "$emacs_alsa_subdir" != yes; then
1440           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1441         fi
1442         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1443       fi
1444
1445       CFLAGS="$SAVE_CFLAGS"
1446       LIBS="$SAVE_LIBS"
1447       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1448       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1449       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1450     elif test "${with_sound}" = "alsa"; then
1451       AC_MSG_ERROR([ALSA sound support requested but not found.])
1452     fi
1453   fi                            dnl with_sound = alsa|yes
1454
1455   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1456   dnl compiles only on the specified platforms.  For others, it
1457   dnl probably doesn't make sense to try.
1458   dnl FIXME So surely we should bypass this whole section if not using
1459   dnl one of these platforms?
1460   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1461      case "$opsys" in
1462        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1463        dnl Adjust the --with-sound help text if you change this.
1464        gnu-linux|freebsd|netbsd|mingw32)
1465          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1466          HAVE_SOUND=yes
1467          ;;
1468      esac
1469   fi
1470
1471   AC_SUBST(CFLAGS_SOUND)
1472 fi
1473
1474 dnl checks for header files
1475 AC_CHECK_HEADERS_ONCE(
1476   sys/systeminfo.h
1477   coff.h pty.h
1478   sys/resource.h
1479   sys/utsname.h pwd.h utmp.h util.h)
1480
1481 AC_MSG_CHECKING(if personality LINUX32 can be set)
1482 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1483                emacs_cv_personality_linux32=yes,
1484                emacs_cv_personality_linux32=no)
1485 AC_MSG_RESULT($emacs_cv_personality_linux32)
1486
1487 if test $emacs_cv_personality_linux32 = yes; then
1488   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1489             [Define to 1 if personality LINUX32 can be set.])
1490 fi
1491
1492 dnl On Solaris 8 there's a compilation warning for term.h because
1493 dnl it doesn't define `bool'.
1494 AC_CHECK_HEADERS(term.h, , , -)
1495 AC_HEADER_TIME
1496 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1497                                       ]])
1498 if test $ac_cv_have_decl_sys_siglist != yes; then
1499   # For Tru64, at least:
1500   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1501                                           ]])
1502 fi
1503 AC_HEADER_SYS_WAIT
1504
1505 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1506 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1507 #if HAVE_SYS_SOCKET_H
1508 #include <sys/socket.h>
1509 #endif])
1510 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1511 #if HAVE_SYS_SOCKET_H
1512 #include <sys/socket.h>
1513 #endif])
1514 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1515 #if HAVE_SYS_SOCKET_H
1516 #include <sys/socket.h>
1517 #endif])
1518
1519 dnl checks for structure members
1520 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1521                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1522                   struct ifreq.ifr_addr,
1523                   struct ifreq.ifr_addr.sa_len], , ,
1524                  [AC_INCLUDES_DEFAULT
1525 #if HAVE_SYS_SOCKET_H
1526 #include <sys/socket.h>
1527 #endif
1528 #if HAVE_NET_IF_H
1529 #include <net/if.h>
1530 #endif])
1531
1532 dnl Check for endianness.
1533 dnl AC_C_BIGENDIAN is done by gnulib.
1534
1535 dnl check for Make feature
1536 dnl AC_PROG_MAKE_SET is done by Automake.
1537
1538 DEPFLAGS=
1539 MKDEPDIR=":"
1540 deps_frag=deps.mk
1541 dnl check for GNU Make if we have GCC and autodepend is on.
1542 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1543    AC_MSG_CHECKING([whether we are using GNU Make])
1544    HAVE_GNU_MAKE=no
1545    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1546    if test "x$testval" != x; then
1547       HAVE_GNU_MAKE=yes
1548    else
1549       ac_enable_autodepend=no
1550    fi
1551    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1552    if test $HAVE_GNU_MAKE = yes; then
1553       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1554       SAVE_CFLAGS="$CFLAGS"
1555       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1556       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1557       CFLAGS="$SAVE_CFLAGS"
1558       test -f deps.d || ac_enable_autodepend=no
1559       rm -rf deps.d
1560       AC_MSG_RESULT([$ac_enable_autodepend])
1561    fi
1562    if test $ac_enable_autodepend = yes; then
1563       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1564       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1565       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1566       deps_frag=autodeps.mk
1567    fi
1568 fi
1569 deps_frag=$srcdir/src/$deps_frag
1570 AC_SUBST(MKDEPDIR)
1571 AC_SUBST(DEPFLAGS)
1572 AC_SUBST_FILE(deps_frag)
1573
1574
1575 lisp_frag=$srcdir/src/lisp.mk
1576 AC_SUBST_FILE(lisp_frag)
1577
1578
1579 dnl checks for operating system services
1580 AC_SYS_LONG_FILE_NAMES
1581
1582 #### Choose a window system.
1583
1584 ## We leave window_system equal to none if
1585 ## we end up building without one.  Any new window system should
1586 ## set window_system to an appropriate value and add objects to
1587 ## window-system-specific substs.
1588
1589 window_system=none
1590 AC_PATH_X
1591 if test "$no_x" != yes; then
1592   window_system=x11
1593 fi
1594
1595 LD_SWITCH_X_SITE_RPATH=
1596 if test "${x_libraries}" != NONE; then
1597   if test -n "${x_libraries}"; then
1598     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1599     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1600   fi
1601   x_default_search_path=""
1602   x_search_path=${x_libraries}
1603   if test -z "${x_search_path}"; then
1604     x_search_path=/usr/lib
1605   fi
1606   for x_library in `echo ${x_search_path}: | \
1607                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1608     x_search_path="\
1609 ${x_library}/X11/%L/%T/%N%C%S:\
1610 ${x_library}/X11/%l/%T/%N%C%S:\
1611 ${x_library}/X11/%T/%N%C%S:\
1612 ${x_library}/X11/%L/%T/%N%S:\
1613 ${x_library}/X11/%l/%T/%N%S:\
1614 ${x_library}/X11/%T/%N%S"
1615     if test x"${x_default_search_path}" = x; then
1616       x_default_search_path=${x_search_path}
1617     else
1618       x_default_search_path="${x_search_path}:${x_default_search_path}"
1619     fi
1620   done
1621 fi
1622 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1623
1624 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1625   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1626 fi
1627
1628 if test x"${x_includes}" = x; then
1629   bitmapdir=/usr/include/X11/bitmaps
1630 else
1631   # accumulate include directories that have X11 bitmap subdirectories
1632   bmd_acc="dummyval"
1633   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1634     if test -d "${bmd}/X11/bitmaps"; then
1635       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1636     fi
1637     if test -d "${bmd}/bitmaps"; then
1638       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1639     fi
1640   done
1641   if test ${bmd_acc} != "dummyval"; then
1642     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1643   fi
1644 fi
1645
1646 HAVE_NS=no
1647 NS_IMPL_COCOA=no
1648 NS_IMPL_GNUSTEP=no
1649 tmp_CPPFLAGS="$CPPFLAGS"
1650 tmp_CFLAGS="$CFLAGS"
1651 CPPFLAGS="$CPPFLAGS -x objective-c"
1652 CFLAGS="$CFLAGS -x objective-c"
1653 GNU_OBJC_CFLAGS=
1654 LIBS_GNUSTEP=
1655 if test "${with_ns}" != no; then
1656   if test "${opsys}" = darwin; then
1657      NS_IMPL_COCOA=yes
1658      ns_appdir=`pwd`/nextstep/Emacs.app
1659      ns_appbindir=${ns_appdir}/Contents/MacOS
1660      ns_appresdir=${ns_appdir}/Contents/Resources
1661      ns_appsrc=Cocoa/Emacs.base
1662   elif test -f $GNUSTEP_CONFIG_FILE; then
1663      NS_IMPL_GNUSTEP=yes
1664      ns_appdir=`pwd`/nextstep/Emacs.app
1665      ns_appbindir=${ns_appdir}
1666      ns_appresdir=${ns_appdir}/Resources
1667      ns_appsrc=GNUstep/Emacs.base
1668      dnl FIXME sourcing this several times in subshells seems inefficient.
1669      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1670      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1671      dnl I seemed to need these as well with GNUstep-startup 0.25.
1672      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1673      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1674      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1675        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1676      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1677        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1678      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1679      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1680      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1681      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1682      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1683      dnl If they had chosen to either define it or not, we could have
1684      dnl just used AC_CHECK_DECL here.
1685      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1686        emacs_cv_objc_exceptions,
1687 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1688 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1689 1;
1690 #else
1691 fail;
1692 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1693      if test $emacs_cv_objc_exceptions = yes; then
1694        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1695        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1696          [Define if GNUstep uses ObjC exceptions.])
1697        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1698      fi
1699   fi
1700
1701   dnl This is only used while we test the NS headers, it gets reset below.
1702   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1703
1704   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1705                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1706   files are missing or cannot be compiled.])])
1707
1708   macfont_file=""
1709   if test "${NS_IMPL_COCOA}" = "yes"; then
1710     AC_MSG_CHECKING([for OSX 10.4 or newer])
1711     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1712                                      [
1713 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1714 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1040
1715  ; /* OK */
1716 #else
1717  error "OSX 10.4 or newer required";
1718 #endif
1719 #endif
1720                     ])],
1721                     ns_osx_have_104=yes,
1722                     ns_osx_have_104=no)
1723     AC_MSG_RESULT([$ns_osx_have_104])
1724
1725     if test $ns_osx_have_104 = no; then
1726        AC_MSG_ERROR([`OSX 10.4 or newer is required']);
1727     fi
1728     AC_MSG_CHECKING([for OSX 10.5 or newer])
1729     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1730                                      [
1731 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1732 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1050
1733  ; /* OK */
1734 #else
1735  error "OSX 10.5 not found";
1736 #endif
1737 #endif
1738                     ])],
1739                     ns_osx_have_105=yes,
1740                     ns_osx_have_105=no)
1741     AC_MSG_RESULT([$ns_osx_have_105])
1742     if test $ns_osx_have_105 = yes; then
1743       macfont_file="macfont.o"
1744     fi
1745   fi
1746   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1747                                      [NSInteger i;])],
1748                     ns_have_nsinteger=yes,
1749                     ns_have_nsinteger=no)
1750   if test $ns_have_nsinteger = yes; then
1751     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1752   fi
1753 fi
1754
1755 AC_SUBST(LIBS_GNUSTEP)
1756
1757 INSTALL_ARCH_INDEP_EXTRA=install-etc
1758 ns_self_contained=no
1759 NS_OBJ=
1760 NS_OBJC_OBJ=
1761 if test "${HAVE_NS}" = yes; then
1762   if test "$with_toolkit_scroll_bars" = "no"; then
1763     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1764   fi
1765
1766   window_system=nextstep
1767   # set up packaging dirs
1768   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1769      ns_self_contained=yes
1770      prefix=${ns_appresdir}
1771      exec_prefix=${ns_appbindir}
1772      dnl This one isn't really used, only archlibdir is.
1773      libexecdir="\${ns_appbindir}/libexec"
1774      archlibdir="\${ns_appbindir}/libexec"
1775      etcdocdir="\${ns_appresdir}/etc"
1776      etcdir="\${ns_appresdir}/etc"
1777      dnl FIXME maybe set datarootdir instead.
1778      dnl That would also get applications, icons, man.
1779      infodir="\${ns_appresdir}/info"
1780      mandir="\${ns_appresdir}/man"
1781      lispdir="\${ns_appresdir}/lisp"
1782      INSTALL_ARCH_INDEP_EXTRA=
1783   fi
1784
1785   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o $macfont_file"
1786 fi
1787 CFLAGS="$tmp_CFLAGS"
1788 CPPFLAGS="$tmp_CPPFLAGS"
1789 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1790 AC_SUBST(ns_self_contained)
1791 AC_SUBST(NS_OBJ)
1792 AC_SUBST(NS_OBJC_OBJ)
1793
1794 HAVE_W32=no
1795 W32_OBJ=
1796 W32_LIBS=
1797 EMACSRES=
1798 CLIENTRES=
1799 CLIENTW=
1800 W32_RES_LINK=
1801 EMACS_MANIFEST=
1802 UPDATE_MANIFEST=
1803 if test "${with_w32}" != no; then
1804   case "${opsys}" in
1805     cygwin)
1806       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1807              [AC_MSG_ERROR([`--with-w32' was specified, but windows.h
1808                    cannot be found.])])
1809     ;;
1810     mingw32)
1811     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1812     ;;
1813     *)
1814       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1815     ;;
1816   esac
1817 fi
1818
1819 if test "${opsys}" = "mingw32"; then
1820   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1821   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1822      #include <windows.h>
1823      #include <usp10.h>]],
1824    [[PIMAGE_NT_HEADERS pHeader;
1825      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1826    [emacs_cv_w32api=yes
1827     HAVE_W32=yes],
1828    emacs_cv_w32api=no)
1829   AC_MSG_RESULT($emacs_cv_w32api)
1830   if test "${emacs_cv_w32api}" = "no"; then
1831     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1832   fi
1833 fi
1834
1835 FIRSTFILE_OBJ=
1836 NTDIR=
1837 LIBS_ECLIENT=
1838 LIB_WSOCK32=
1839 NTLIB=
1840 CM_OBJ="cm.o"
1841 XARGS_LIMIT=
1842 if test "${HAVE_W32}" = "yes"; then
1843   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1844   if test "$with_toolkit_scroll_bars" = "no"; then
1845     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for w32 build.])
1846   fi
1847   AC_CHECK_TOOL(WINDRES, [windres],
1848                 [AC_MSG_ERROR([No resource compiler found.])])
1849   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1850   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1851   EMACSRES="emacs.res"
1852   case "$canonical" in
1853     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1854     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1855   esac
1856   if test "${opsys}" = "cygwin"; then
1857     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1858     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1859     # Tell the linker that emacs.res is an object (which we compile from
1860     # the rc file), not a linker script.
1861     W32_RES_LINK="-Wl,emacs.res"
1862   else
1863     UPDATE_MANIFEST=update-game-score.exe.manifest
1864     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1865     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1866     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1867     W32_RES_LINK="\$(EMACSRES)"
1868     CLIENTRES="emacsclient.res"
1869     CLIENTW="emacsclientw\$(EXEEXT)"
1870     FIRSTFILE_OBJ=firstfile.o
1871     NTDIR=nt
1872     CM_OBJ=
1873     LIBS_ECLIENT="-lcomctl32"
1874     LIB_WSOCK32="-lwsock32"
1875     NTLIB="ntlib.$ac_objext"
1876     XARGS_LIMIT="-s 10000"
1877   fi
1878 fi
1879 AC_SUBST(W32_OBJ)
1880 AC_SUBST(W32_LIBS)
1881 AC_SUBST(EMACSRES)
1882 AC_SUBST(EMACS_MANIFEST)
1883 AC_SUBST(UPDATE_MANIFEST)
1884 AC_SUBST(CLIENTRES)
1885 AC_SUBST(CLIENTW)
1886 AC_SUBST(W32_RES_LINK)
1887 AC_SUBST(FIRSTFILE_OBJ)
1888 AC_SUBST(NTDIR)
1889 AC_SUBST(CM_OBJ)
1890 AC_SUBST(LIBS_ECLIENT)
1891 AC_SUBST(LIB_WSOCK32)
1892 AC_SUBST(NTLIB)
1893 AC_SUBST(XARGS_LIMIT)
1894
1895 if test "${HAVE_W32}" = "yes"; then
1896   window_system=w32
1897   with_xft=no
1898 fi
1899
1900 ## $window_system is now set to the window system we will
1901 ## ultimately use.
1902
1903 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
1904    # Too many warnings for now.
1905    nw=
1906    nw="$nw -Wsuggest-attribute=const"
1907    nw="$nw -Wsuggest-attribute=noreturn"
1908    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
1909
1910    gl_WARN_ADD([-Wno-unused-variable])
1911    gl_WARN_ADD([-Wno-unused-but-set-variable])
1912    gl_WARN_ADD([-Wno-unused-but-set-parameter])
1913 fi
1914
1915 term_header=
1916 HAVE_X_WINDOWS=no
1917 HAVE_X11=no
1918 USE_X_TOOLKIT=none
1919
1920 case "${window_system}" in
1921   x11 )
1922     HAVE_X_WINDOWS=yes
1923     HAVE_X11=yes
1924     term_header=xterm.h
1925     case "${with_x_toolkit}" in
1926       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1927       motif ) USE_X_TOOLKIT=MOTIF ;;
1928       gtk ) with_gtk=yes
1929             term_header=gtkutil.h
1930 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1931 dnl USE_X_TOOLKIT is set.
1932             USE_X_TOOLKIT=none ;;
1933       gtk2 ) with_gtk2=yes
1934              term_header=gtkutil.h
1935              USE_X_TOOLKIT=none ;;
1936       gtk3 ) with_gtk3=yes
1937              term_header=gtkutil.h
1938              USE_X_TOOLKIT=none ;;
1939       no ) USE_X_TOOLKIT=none ;;
1940 dnl If user did not say whether to use a toolkit, make this decision later:
1941 dnl use the toolkit if we have gtk, or X11R5 or newer.
1942       * ) USE_X_TOOLKIT=maybe ;;
1943     esac
1944   ;;
1945   nextstep )
1946     term_header=nsterm.h
1947   ;;
1948   w32 )
1949     term_header=w32term.h
1950   ;;
1951 esac
1952
1953 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1954    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1955    if test "$HAVE_XSERVER" = true ||
1956       test -n "$DISPLAY" ||
1957       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1958         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1959 were found.  You should install the relevant development files for X
1960 and for the toolkit you want, such as Gtk+ or Motif.  Also make
1961 sure you have development files for image handling, i.e.
1962 tiff, gif, jpeg, png and xpm.
1963 If you are sure you want Emacs compiled without X window support, pass
1964   --without-x
1965 to configure.])
1966    fi
1967 fi
1968
1969 # Does the opsystem file prohibit the use of the GNU malloc?
1970 # Assume not, until told otherwise.
1971 GNU_MALLOC=yes
1972
1973 AC_CACHE_CHECK(
1974   [whether malloc is Doug Lea style],
1975   [emacs_cv_var_doug_lea_malloc],
1976   [emacs_cv_var_doug_lea_malloc=no
1977    dnl Hooks do not work with address sanitization.
1978    if test "$emacs_cv_sanitize_address" != yes; then
1979      AC_LINK_IFELSE(
1980        [AC_LANG_PROGRAM(
1981           [[#include <malloc.h>
1982             static void hook (void) {}]],
1983           [[malloc_set_state (malloc_get_state ());
1984             __after_morecore_hook = hook;
1985             __malloc_initialize_hook = hook;]])],
1986        [emacs_cv_var_doug_lea_malloc=yes])])
1987    fi
1988 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1989
1990 system_malloc=$emacs_cv_sanitize_address
1991 case "$opsys" in
1992   ## darwin ld insists on the use of malloc routines in the System framework.
1993   darwin|sol2-10) system_malloc=yes ;;
1994 esac
1995
1996 GMALLOC_OBJ=
1997 if test "${system_malloc}" = "yes"; then
1998   AC_DEFINE([SYSTEM_MALLOC], 1,
1999     [Define to 1 to use the system memory allocator, even if it is not
2000      Doug Lea style.])
2001   GNU_MALLOC=no
2002   GNU_MALLOC_reason="
2003     (The GNU allocators don't work with this system configuration.)"
2004   VMLIMIT_OBJ=
2005 else
2006   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2007   VMLIMIT_OBJ=vm-limit.o
2008
2009   AC_CHECK_HEADERS([sys/vlimit.h])
2010   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2011     [AC_LINK_IFELSE(
2012        [AC_LANG_PROGRAM(
2013          [[extern char data_start[]; char ch;]],
2014          [[return data_start < &ch;]])],
2015        [emacs_cv_data_start=yes],
2016        [emacs_cv_data_start=no])])
2017   if test $emacs_cv_data_start = yes; then
2018     AC_DEFINE([HAVE_DATA_START], 1,
2019       [Define to 1 if data_start is the address of the start
2020        of the main data segment.])
2021   fi
2022 fi
2023 AC_SUBST(GMALLOC_OBJ)
2024 AC_SUBST(VMLIMIT_OBJ)
2025
2026 if test "$doug_lea_malloc" = "yes" ; then
2027   if test "$GNU_MALLOC" = yes ; then
2028     GNU_MALLOC_reason="
2029       (Using Doug Lea's new malloc from the GNU C Library.)"
2030   fi
2031   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2032     [Define to 1 if the system memory allocator is Doug Lea style,
2033      with malloc hooks and malloc_set_state.])
2034
2035   ## Use mmap directly for allocating larger buffers.
2036   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2037   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2038   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2039   case "$opsys" in
2040     gnu*) REL_ALLOC=no ;;
2041   esac
2042 fi
2043
2044 if test x"${REL_ALLOC}" = x; then
2045   REL_ALLOC=${GNU_MALLOC}
2046 fi
2047
2048 use_mmap_for_buffers=no
2049 case "$opsys" in
2050   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
2051 esac
2052
2053 AC_FUNC_MMAP
2054 if test $use_mmap_for_buffers = yes; then
2055   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2056   REL_ALLOC=no
2057 fi
2058
2059 LIBS="$LIBS_SYSTEM $LIBS"
2060
2061 dnl If found, this adds -ldnet to LIBS, which Autoconf uses for checks.
2062 AC_CHECK_LIB(dnet, dnet_ntoa)
2063 dnl This causes -lresolv to get used in subsequent tests,
2064 dnl which causes failures on some systems such as HPUX 9.
2065 dnl AC_CHECK_LIB(resolv, gethostbyname)
2066
2067 dnl FIXME replace main with a function we actually want from this library.
2068 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2069
2070 dnl Check if pthreads is available.
2071 LIB_PTHREAD=
2072 AC_CHECK_HEADERS_ONCE(pthread.h)
2073 if test "$ac_cv_header_pthread_h"; then
2074   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
2075   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
2076   dnl testing for pthread_self if Emacs uses gmalloc.c.
2077   if test "$GMALLOC_OBJ" = gmalloc.o; then
2078     emacs_pthread_function=pthread_atfork
2079   else
2080     emacs_pthread_function=pthread_self
2081   fi
2082   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
2083 fi
2084 if test "$HAVE_PTHREAD" = yes; then
2085   case "${canonical}" in
2086     *-hpux*) ;;
2087     *) LIB_PTHREAD="-lpthread"
2088        LIBS="$LIB_PTHREAD $LIBS" ;;
2089   esac
2090   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
2091
2092   # Some systems optimize for single-threaded programs by default, and
2093   # need special flags to disable these optimizations. For example, the
2094   # definition of 'errno' in <errno.h>.
2095   case $opsys in
2096     sol*)
2097       AC_DEFINE([_REENTRANT], 1,
2098         [Define to 1 if your system requires this in multithreaded code.]);;
2099     aix4-2)
2100       AC_DEFINE([_THREAD_SAFE], 1,
2101         [Define to 1 if your system requires this in multithreaded code.]);;
2102   esac
2103 fi
2104 AC_SUBST([LIB_PTHREAD])
2105
2106 AC_CHECK_LIB(pthreads, cma_open)
2107
2108 ## Note: when using cpp in s/aix4.2.h, this definition depended on
2109 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
2110 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
2111 ## added to LIBS in configure would never contain the pthreads part,
2112 ## but the value used in Makefiles might.  FIXME?
2113 ##
2114 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
2115 ## be harmless on older versions of X where it happens to exist.
2116 test "$opsys" = "aix4-2" && \
2117   test $ac_cv_lib_pthreads_cma_open = yes && \
2118   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
2119
2120 dnl Check for need for bigtoc support on IBM AIX
2121
2122 case ${host_os} in
2123 aix*)
2124   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2125     case $GCC in
2126     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2127     *) gdb_cv_bigtoc=-bbigtoc ;;
2128     esac
2129
2130     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2131     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2132   ])
2133   ;;
2134 esac
2135
2136 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
2137 # used for the tests that follow.  We set them back to REAL_CFLAGS and
2138 # REAL_CPPFLAGS later on.
2139
2140 REAL_CFLAGS="$CFLAGS"
2141 REAL_CPPFLAGS="$CPPFLAGS"
2142
2143 if test "${HAVE_X11}" = "yes"; then
2144   DEFS="$C_SWITCH_X_SITE $DEFS"
2145   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2146   LIBS="-lX11 $LIBS"
2147   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2148   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2149
2150   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2151   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2152   # but it's more convenient here to set LD_RUN_PATH since this
2153   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2154   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2155     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2156     export LD_RUN_PATH
2157   fi
2158
2159   if test "${opsys}" = "gnu-linux"; then
2160     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2161     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2162      [[XOpenDisplay ("foo");]])],
2163      [xgnu_linux_first_failure=no],
2164      [xgnu_linux_first_failure=yes])
2165     if test "${xgnu_linux_first_failure}" = "yes"; then
2166       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
2167       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
2168       OLD_CPPFLAGS="$CPPFLAGS"
2169       OLD_LIBS="$LIBS"
2170       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2171       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2172       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2173       LIBS="$LIBS -b i486-linuxaout"
2174       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2175        [[XOpenDisplay ("foo");]])],
2176        [xgnu_linux_second_failure=no],
2177        [xgnu_linux_second_failure=yes])
2178       if test "${xgnu_linux_second_failure}" = "yes"; then
2179         # If we get the same failure with -b, there is no use adding -b.
2180         # So take it out.  This plays safe.
2181         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
2182         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
2183         CPPFLAGS="$OLD_CPPFLAGS"
2184         LIBS="$OLD_LIBS"
2185         AC_MSG_RESULT(no)
2186       else
2187         AC_MSG_RESULT(yes)
2188       fi
2189     else
2190       AC_MSG_RESULT(no)
2191     fi
2192   fi
2193
2194   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2195   # header files included from there.
2196   AC_MSG_CHECKING(for Xkb)
2197   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2198 #include <X11/XKBlib.h>]],
2199         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2200         emacs_xkb=yes, emacs_xkb=no)
2201   AC_MSG_RESULT($emacs_xkb)
2202   if test $emacs_xkb = yes; then
2203     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2204   fi
2205
2206   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2207 XScreenNumberOfScreen)
2208 fi
2209
2210 if test "${window_system}" = "x11"; then
2211   AC_MSG_CHECKING(X11 version 6)
2212   AC_CACHE_VAL(emacs_cv_x11_version_6,
2213   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2214 [[#if XlibSpecificationRelease < 6
2215 fail;
2216 #endif
2217 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2218   if test $emacs_cv_x11_version_6 = yes; then
2219     AC_MSG_RESULT(6 or newer)
2220     AC_DEFINE(HAVE_X11R6, 1,
2221               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2222     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2223     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2224     ## XIM support.
2225     case "$opsys" in
2226       sol2-*) : ;;
2227       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2228            [Define if you have usable X11R6-style XIM support.])
2229          ;;
2230     esac
2231   else
2232     AC_MSG_RESULT(before 6)
2233   fi
2234 fi
2235
2236
2237 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
2238 HAVE_RSVG=no
2239 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2240   if test "${with_rsvg}" != "no"; then
2241     RSVG_REQUIRED=2.11.0
2242     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2243
2244     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
2245     AC_SUBST(RSVG_CFLAGS)
2246     AC_SUBST(RSVG_LIBS)
2247
2248     if test $HAVE_RSVG = yes; then
2249       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2250       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2251       # Windows loads librsvg dynamically
2252       if test "${opsys}" = "mingw32"; then
2253         RSVG_LIBS=
2254       fi
2255       LIBS="$RSVG_LIBS $LIBS"
2256     fi
2257   fi
2258 fi
2259
2260 HAVE_IMAGEMAGICK=no
2261 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2262   if test "${with_imagemagick}" != "no"; then
2263     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2264     ## 6.8.2 makes Emacs crash; see Bug#13867.
2265     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2266     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
2267     AC_SUBST(IMAGEMAGICK_CFLAGS)
2268     AC_SUBST(IMAGEMAGICK_LIBS)
2269
2270     if test $HAVE_IMAGEMAGICK = yes; then
2271       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2272       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2273       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2274       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2275     fi
2276   fi
2277 fi
2278
2279
2280 HAVE_GTK=no
2281 GTK_OBJ=
2282 gtk_term_header=$term_header
2283 check_gtk2=no
2284 gtk3_pkg_errors=
2285 if test "${opsys}" != "mingw32"; then
2286   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2287     GLIB_REQUIRED=2.28
2288     GTK_REQUIRED=3.0
2289     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2290
2291     dnl Checks for libraries.
2292     PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2293     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2294        AC_MSG_ERROR($GTK_PKG_ERRORS)
2295     fi
2296     if test "$pkg_check_gtk" = "yes"; then
2297        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2298        GTK_OBJ=emacsgtkfixed.o
2299        gtk_term_header=gtkutil.h
2300        USE_GTK_TOOLKIT="GTK3"
2301        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2302          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2303            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2304          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2305            [Define to 1 to disable Glib deprecation warnings.])
2306        fi
2307     else
2308        check_gtk2=yes
2309        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2310     fi
2311   fi
2312
2313   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2314     GLIB_REQUIRED=2.10
2315     GTK_REQUIRED=2.10
2316     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2317
2318     dnl Checks for libraries.
2319     PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2320     if test "$pkg_check_gtk" = "no" &&
2321        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2322     then
2323       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2324     fi
2325     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2326   fi
2327 fi
2328
2329 if test x"$pkg_check_gtk" = xyes; then
2330
2331   AC_SUBST(GTK_LIBS)
2332   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2333   CFLAGS="$CFLAGS $GTK_CFLAGS"
2334   LIBS="$GTK_LIBS $LIBS"
2335   dnl Try to compile a simple GTK program.
2336   AC_MSG_CHECKING([whether GTK compiles])
2337   GTK_COMPILES=no
2338   AC_LINK_IFELSE(
2339     [AC_LANG_PROGRAM(
2340        [[/* Check the Gtk and Glib APIs.  */
2341          #include <gtk/gtk.h>
2342          #include <glib-object.h>
2343          static void
2344          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2345          {}
2346        ]],
2347        [[
2348          GtkSettings *gs = 0;
2349          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2350             strict C prohibits this.  Use gtk_main_iteration to test that the
2351             libraries are there.  */
2352          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2353                                     0, 0, 0, G_CALLBACK (callback), 0))
2354            gtk_main_iteration ();
2355        ]])],
2356     [GTK_COMPILES=yes])
2357   AC_MSG_RESULT([$GTK_COMPILES])
2358   if test "${GTK_COMPILES}" != "yes"; then
2359     GTK_OBJ=
2360     if test "$USE_X_TOOLKIT" != "maybe"; then
2361       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2362     fi
2363   else
2364     HAVE_GTK=yes
2365     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2366     GTK_OBJ="gtkutil.o $GTK_OBJ"
2367     term_header=$gtk_term_header
2368     USE_X_TOOLKIT=none
2369     if "$PKG_CONFIG" --atleast-version=2.10 gtk+-2.0; then
2370       :
2371     else
2372       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2373        closing open displays.  This is no problem if you just use
2374        one display, but if you use more than one and close one of them
2375        Emacs may crash.]])
2376       sleep 3
2377     fi
2378   fi
2379
2380 fi
2381 AC_SUBST(GTK_OBJ)
2382
2383
2384 if test "${HAVE_GTK}" = "yes"; then
2385
2386   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2387   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2388   if test "$with_toolkit_scroll_bars" != no; then
2389     with_toolkit_scroll_bars=yes
2390   fi
2391
2392   dnl  Check if we have the old file selection dialog declared and
2393   dnl  in the link library.  In 2.x it may be in the library,
2394   dnl  but not declared if deprecated featured has been selected out.
2395   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2396   HAVE_GTK_FILE_SELECTION=no
2397   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2398                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2399 #include <gtk/gtk.h>])
2400   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2401     AC_CHECK_FUNCS(gtk_file_selection_new)
2402   fi
2403
2404   dnl Same as above for gtk_handle_box.
2405   HAVE_GTK_HANDLE_BOX=no
2406   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2407                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2408 #include <gtk/gtk.h>])
2409   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2410     AC_CHECK_FUNCS(gtk_handle_box_new)
2411   fi
2412
2413   dnl Same as above for gtk_tearoff_menu_item.
2414   HAVE_GTK_TEAROFF_MENU_ITEM=no
2415   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2416                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2417 #include <gtk/gtk.h>])
2418   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2419     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2420   fi
2421
2422   dnl Check for functions introduced in 2.14 and later.
2423   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2424                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2425                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2426                  gtk_orientable_set_orientation \
2427                  gtk_window_set_has_resize_grip)
2428
2429  term_header=gtkutil.h
2430 fi
2431
2432 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2433 dnl other platforms.
2434 HAVE_DBUS=no
2435 DBUS_OBJ=
2436 if test "${with_dbus}" = "yes"; then
2437    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2438    if test "$HAVE_DBUS" = yes; then
2439      LIBS="$LIBS $DBUS_LIBS"
2440      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2441      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2442      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2443      dnl D-Bus 1.5.12.
2444      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2445                     dbus_type_is_valid \
2446                     dbus_validate_bus_name \
2447                     dbus_validate_path \
2448                     dbus_validate_interface \
2449                     dbus_validate_member)
2450      DBUS_OBJ=dbusbind.o
2451    fi
2452 fi
2453 AC_SUBST(DBUS_OBJ)
2454
2455 dnl GSettings has been tested under GNU/Linux only.
2456 HAVE_GSETTINGS=no
2457 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2458    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2459    if test "$HAVE_GSETTINGS" = "yes"; then
2460       old_CFLAGS=$CFLAGS
2461       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2462       old_LIBS=$LIBS
2463       LIBS="$LIBS $GSETTINGS_LIBS"
2464       AC_MSG_CHECKING([whether GSettings is in gio])
2465       AC_LINK_IFELSE(
2466          [AC_LANG_PROGRAM(
2467              [[/* Check that gsettings really is present.  */
2468              #include <glib-object.h>
2469              #include <gio/gio.h>
2470              ]],
2471              [[
2472                GSettings *settings;
2473                GVariant *val = g_settings_get_value (settings, "");
2474              ]])],
2475          [], HAVE_GSETTINGS=no)
2476       AC_MSG_RESULT([$HAVE_GSETTINGS])
2477
2478       if test "$HAVE_GSETTINGS" = "yes"; then
2479         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2480         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2481         SETTINGS_LIBS="$GSETTINGS_LIBS"
2482       fi
2483       CFLAGS=$old_CFLAGS
2484       LIBS=$old_LIBS
2485    fi
2486 fi
2487
2488 dnl GConf has been tested under GNU/Linux only.
2489 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2490 HAVE_GCONF=no
2491 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2492    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2493    if test "$HAVE_GCONF" = yes; then
2494       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2495       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2496       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2497       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2498    fi
2499 fi
2500
2501 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2502     PKG_CHECK_MODULES(GOBJECT, gobject-2.0 >= 2.0, HAVE_GOBJECT=yes, HAVE_GOBJECT=no)
2503     if test "$HAVE_GOBJECT" = "yes"; then
2504        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2505        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2506     fi
2507     SAVE_CFLAGS="$CFLAGS"
2508     SAVE_LIBS="$LIBS"
2509     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2510     LIBS="$SETTINGS_LIBS $LIBS"
2511     CFLAGS="$SAVE_CFLAGS"
2512     LIBS="$SAVE_LIBS"
2513 fi
2514 AC_SUBST(SETTINGS_CFLAGS)
2515 AC_SUBST(SETTINGS_LIBS)
2516
2517
2518 dnl SELinux is available for GNU/Linux only.
2519 HAVE_LIBSELINUX=no
2520 LIBSELINUX_LIBS=
2521 if test "${with_selinux}" = "yes"; then
2522    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2523    if test "$HAVE_LIBSELINUX" = yes; then
2524       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2525       LIBSELINUX_LIBS=-lselinux
2526    fi
2527 fi
2528 AC_SUBST(LIBSELINUX_LIBS)
2529
2530 HAVE_GNUTLS=no
2531 HAVE_GNUTLS3=no
2532 if test "${with_gnutls}" = "yes" ; then
2533   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.0.0], HAVE_GNUTLS3=yes, HAVE_GNUTLS3=no)
2534   if test "${HAVE_GNUTLS3}" = "yes"; then
2535     AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])
2536     HAVE_GNUTLS="yes"
2537   else
2538     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2539   fi
2540   if test "${HAVE_GNUTLS}" = "yes"; then
2541     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2542   fi
2543
2544   # Windows loads GnuTLS dynamically
2545   if test "${opsys}" = "mingw32"; then
2546     LIBGNUTLS_LIBS=
2547   fi
2548 fi
2549
2550 AC_SUBST(LIBGNUTLS_LIBS)
2551 AC_SUBST(LIBGNUTLS_CFLAGS)
2552
2553 NOTIFY_OBJ=
2554 NOTIFY_SUMMARY=no
2555
2556 dnl FIXME?  Don't auto-detect on NS, but do allow someone to specify
2557 dnl a particular library.  This doesn't make much sense?
2558 if test "${with_ns}" = yes && test ${with_file_notification} = yes; then
2559   with_file_notification=no
2560 fi
2561
2562 dnl MS Windows native file monitor is available for mingw32 only.
2563 case $with_file_notification,$opsys in
2564   w32,* | yes,mingw32)
2565     AC_CHECK_HEADER(windows.h)
2566     if test "$ac_cv_header_windows_h" = yes ; then
2567        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2568        NOTIFY_OBJ=w32notify.o
2569        NOTIFY_SUMMARY="yes (w32)"
2570     fi ;;
2571 esac
2572
2573 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2574 dnl has been added in glib 2.24.  It has been tested under
2575 dnl GNU/Linux only.  We take precedence over inotify, but this makes
2576 dnl only sense when glib has been compiled with inotify support.  How
2577 dnl to check?
2578 case $with_file_notification,$NOTIFY_OBJ in
2579   gfile, | yes,)
2580     PKG_CHECK_MODULES(GFILENOTIFY, gio-2.0 >= 2.24, HAVE_GFILENOTIFY=yes, HAVE_GFILENOTIFY=no)
2581     if test "$HAVE_GFILENOTIFY" = "yes"; then
2582        AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2583        NOTIFY_OBJ=gfilenotify.o
2584        NOTIFY_SUMMARY="yes -lgio (gfile)"
2585     fi ;;
2586 esac
2587
2588 dnl inotify is only available on GNU/Linux.
2589 case $with_file_notification,$NOTIFY_OBJ in
2590   inotify, | yes,)
2591     AC_CHECK_HEADER(sys/inotify.h)
2592     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2593         AC_CHECK_FUNC(inotify_init1)
2594         if test "$ac_cv_func_inotify_init1" = yes; then
2595           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2596           NOTIFY_OBJ=inotify.o
2597           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2598        fi
2599     fi ;;
2600 esac
2601
2602 case $with_file_notification,$NOTIFY_OBJ in
2603   yes,* | no,* | *,?*) ;;
2604   *) AC_MSG_ERROR([File notification `$with_file_notification' requested but requirements not found.]) ;;
2605 esac
2606
2607 if test -n "$NOTIFY_OBJ"; then
2608    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2609 fi
2610 AC_SUBST(NOTIFY_OBJ)
2611 AC_SUBST(GFILENOTIFY_CFLAGS)
2612 AC_SUBST(GFILENOTIFY_LIBS)
2613
2614 dnl Do not put whitespace before the #include statements below.
2615 dnl Older compilers (eg sunos4 cc) choke on it.
2616 HAVE_XAW3D=no
2617 LUCID_LIBW=
2618 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2619   if test "$with_xaw3d" != no; then
2620     AC_CACHE_VAL(emacs_cv_xaw3d,
2621     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2622 #include <X11/Intrinsic.h>
2623 #include <X11/Xaw3d/Simple.h>]],
2624       [[]])],
2625       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2626                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2627       emacs_cv_xaw3d=no)])
2628   else
2629     emacs_cv_xaw3d=no
2630   fi
2631   if test $emacs_cv_xaw3d = yes; then
2632     AC_MSG_CHECKING(for xaw3d)
2633     AC_MSG_RESULT([yes; using Lucid toolkit])
2634     USE_X_TOOLKIT=LUCID
2635     HAVE_XAW3D=yes
2636     LUCID_LIBW=-lXaw3d
2637     AC_DEFINE(HAVE_XAW3D, 1,
2638               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2639   else
2640     AC_MSG_CHECKING(for xaw3d)
2641     AC_MSG_RESULT(no)
2642     AC_MSG_CHECKING(for libXaw)
2643     AC_CACHE_VAL(emacs_cv_xaw,
2644     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2645 #include <X11/Intrinsic.h>
2646 #include <X11/Xaw/Simple.h>]],
2647       [[]])],
2648       emacs_cv_xaw=yes,
2649       emacs_cv_xaw=no)])
2650     if test $emacs_cv_xaw = yes; then
2651       AC_MSG_RESULT([yes; using Lucid toolkit])
2652       USE_X_TOOLKIT=LUCID
2653       LUCID_LIBW=-lXaw
2654     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2655       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2656     else
2657       AC_MSG_ERROR([No X toolkit could be found.
2658 If you are sure you want Emacs compiled without an X toolkit, pass
2659   --with-x-toolkit=no
2660 to configure.  Otherwise, install the development libraries for the toolkit
2661 that you want to use (e.g. Gtk+) and re-run configure.])
2662     fi
2663   fi
2664 fi
2665
2666 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2667
2668 LIBXTR6=
2669 if test "${USE_X_TOOLKIT}" != "none"; then
2670   AC_MSG_CHECKING(X11 toolkit version)
2671   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2672   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2673 [[#if XtSpecificationRelease < 6
2674 fail;
2675 #endif
2676 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2677   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2678   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2679     AC_MSG_RESULT(6 or newer)
2680     AC_DEFINE(HAVE_X11XTR6, 1,
2681               [Define to 1 if you have the X11R6 or newer version of Xt.])
2682     LIBXTR6="-lSM -lICE"
2683     case "$opsys" in
2684       ## Use libw.a along with X11R6 Xt.
2685       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2686     esac
2687   else
2688     AC_MSG_RESULT(before 6)
2689   fi
2690
2691 dnl If using toolkit, check whether libXmu.a exists.
2692 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2693   OLDLIBS="$LIBS"
2694   if test x$HAVE_X11XTR6 = xyes; then
2695     LIBS="-lXt -lSM -lICE $LIBS"
2696   else
2697     LIBS="-lXt $LIBS"
2698   fi
2699   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2700   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2701   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2702 fi
2703 AC_SUBST(LIBXTR6)
2704
2705 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2706 dnl Why not just test for libxmu in the normal way?
2707 LIBXMU=-lXmu
2708 case $opsys in
2709   ## These systems don't supply Xmu.
2710   hpux* | aix4-2 )
2711     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2712     ;;
2713   mingw32 )
2714     LIBXMU=
2715     ;;
2716 esac
2717 AC_SUBST(LIBXMU)
2718
2719 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2720 if test "${HAVE_X11}" = "yes"; then
2721   if test "${USE_X_TOOLKIT}" != "none"; then
2722     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2723   fi
2724 fi
2725
2726 LIBXP=
2727 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2728   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2729   if test -d /usr/include/openmotif; then
2730     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2731     emacs_cv_openmotif=yes
2732     case "$canonical" in
2733       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2734       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2735       ;;
2736       *)
2737       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2738     esac
2739   else
2740     emacs_cv_openmotif=no
2741   fi
2742   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2743   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2744     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2745 int x = 5;
2746 #else
2747 Motif version prior to 2.1.
2748 #endif]])],
2749     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2750   if test $emacs_cv_motif_version_2_1 = yes; then
2751     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2752     if test x$emacs_cv_openmotif = xyes; then
2753       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2754     fi
2755   else
2756     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2757     # We put this in CFLAGS temporarily to precede other -I options
2758     # that might be in CFLAGS temporarily.
2759     # We put this in CPPFLAGS where it precedes the other -I options.
2760     OLD_CPPFLAGS=$CPPFLAGS
2761     OLD_CFLAGS=$CFLAGS
2762     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2763     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2764     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2765       [[int x = 5;]])],
2766       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2767     if test $emacs_cv_lesstif = yes; then
2768       # Make sure this -I option remains in CPPFLAGS after it is set
2769       # back to REAL_CPPFLAGS.
2770       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2771       # have those other -I options anyway.  Ultimately, having this
2772       # directory ultimately in CPPFLAGS will be enough.
2773       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2774       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2775     else
2776       CFLAGS=$OLD_CFLAGS
2777       CPPFLAGS=$OLD_CPPFLAGS
2778     fi
2779   fi
2780   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2781     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2782 fi
2783
2784 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2785 dnl using Motif or Xaw3d is available, and unless
2786 dnl --with-toolkit-scroll-bars=no was specified.
2787
2788 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2789             [Define to 1 if we should use toolkit scroll bars.])dnl
2790 USE_TOOLKIT_SCROLL_BARS=no
2791 if test "${with_toolkit_scroll_bars}" != "no"; then
2792   if test "${USE_X_TOOLKIT}" != "none"; then
2793     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2794       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2795       HAVE_XAW3D=no
2796       USE_TOOLKIT_SCROLL_BARS=yes
2797     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2798       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2799       USE_TOOLKIT_SCROLL_BARS=yes
2800     fi
2801   elif test "${HAVE_GTK}" = "yes"; then
2802     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2803     USE_TOOLKIT_SCROLL_BARS=yes
2804   elif test "${HAVE_NS}" = "yes"; then
2805     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2806     USE_TOOLKIT_SCROLL_BARS=yes
2807   elif test "${HAVE_W32}" = "yes"; then
2808     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2809     USE_TOOLKIT_SCROLL_BARS=yes
2810   fi
2811 fi
2812
2813 dnl See if XIM is available.
2814 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2815           #include <X11/Xlib.h>
2816           #include <X11/Xresource.h>]],
2817          [[XIMProc  callback;]])],
2818          [HAVE_XIM=yes
2819          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2820          HAVE_XIM=no)
2821
2822 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2823
2824 if test "${with_xim}" != "no"; then
2825   AC_DEFINE(USE_XIM, 1,
2826             [Define to 1 if we should use XIM, if it is available.])
2827 fi
2828
2829
2830 if test "${HAVE_XIM}" != "no"; then
2831   late_CFLAGS=$CFLAGS
2832   if test "$GCC" = yes; then
2833     CFLAGS="$CFLAGS --pedantic-errors"
2834   fi
2835   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2836 #include <X11/Xlib.h>
2837 #include <X11/Xresource.h>]],
2838 [[Display *display;
2839 XrmDatabase db;
2840 char *res_name;
2841 char *res_class;
2842 XIMProc  callback;
2843 XPointer *client_data;
2844 #ifndef __GNUC__
2845 /* If we're not using GCC, it's probably not XFree86, and this is
2846    probably right, but we can't use something like --pedantic-errors.  */
2847 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2848                                            char*, XIMProc, XPointer*);
2849 #endif
2850 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2851    client_data);]])],
2852     [emacs_cv_arg6_star=yes])
2853   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2854          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2855 either XPointer or XPointer*.])dnl
2856   if test "$emacs_cv_arg6_star" = yes; then
2857     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2858   else
2859     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2860   fi
2861   CFLAGS=$late_CFLAGS
2862 fi
2863
2864 ### Start of font-backend (under any platform) section.
2865 # (nothing here yet -- this is a placeholder)
2866 ### End of font-backend (under any platform) section.
2867
2868 ### Start of font-backend (under X11) section.
2869 if test "${HAVE_X11}" = "yes"; then
2870    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2871
2872    ## Use -lXft if available, unless `--with-xft=no'.
2873    HAVE_XFT=maybe
2874     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2875       with_xft="no";
2876     fi
2877     if test "x${with_xft}" != "xno"; then
2878
2879       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2880       ## Because xftfont.c uses XRenderQueryExtension, we also
2881       ## need to link to -lXrender.
2882       HAVE_XRENDER=no
2883       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2884       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2885         OLD_CPPFLAGS="$CPPFLAGS"
2886         OLD_CFLAGS="$CFLAGS"
2887         OLD_LIBS="$LIBS"
2888         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2889         CFLAGS="$CFLAGS $XFT_CFLAGS"
2890         XFT_LIBS="-lXrender $XFT_LIBS"
2891         LIBS="$XFT_LIBS $LIBS"
2892         AC_CHECK_HEADER(X11/Xft/Xft.h,
2893           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
2894           [[#include <X11/X.h>]])
2895
2896         if test "${HAVE_XFT}" = "yes"; then
2897           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2898             AC_SUBST(XFT_LIBS)
2899           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2900         else
2901           CPPFLAGS="$OLD_CPPFLAGS"
2902           CFLAGS="$OLD_CFLAGS"
2903           LIBS="$OLD_LIBS"
2904         fi                        # "${HAVE_XFT}" = "yes"
2905       fi                          # "$HAVE_XFT" != no
2906     fi                            # "x${with_xft}" != "xno"
2907
2908     ## We used to allow building with FreeType and without Xft.
2909     ## However, the ftx font backend driver is not in good shape.
2910     if test "$HAVE_XFT" != "yes"; then
2911        dnl For the "Does Emacs use" message at the end.
2912        HAVE_XFT=no
2913        HAVE_FREETYPE=no
2914     else
2915        dnl Strict linkers fail with
2916        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2917        dnl if -lfreetype is not specified.
2918        dnl The following is needed to set FREETYPE_LIBS.
2919        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2920                          HAVE_FREETYPE=no)
2921
2922        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2923     fi
2924
2925     HAVE_LIBOTF=no
2926     if test "${HAVE_FREETYPE}" = "yes"; then
2927       AC_DEFINE(HAVE_FREETYPE, 1,
2928                 [Define to 1 if using the freetype and fontconfig libraries.])
2929       if test "${with_libotf}" != "no"; then
2930         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2931                           HAVE_LIBOTF=no)
2932         if test "$HAVE_LIBOTF" = "yes"; then
2933           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2934           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2935                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2936                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2937           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2938             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2939                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2940           fi
2941         fi
2942       fi
2943     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2944     dnl Does the new font backend require it, or can it work without it?
2945     fi
2946
2947     HAVE_M17N_FLT=no
2948     if test "${HAVE_LIBOTF}" = yes; then
2949       if test "${with_m17n_flt}" != "no"; then
2950         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2951         if test "$HAVE_M17N_FLT" = "yes"; then
2952           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2953         fi
2954       fi
2955     fi
2956 else
2957     HAVE_XFT=no
2958     HAVE_FREETYPE=no
2959     HAVE_LIBOTF=no
2960     HAVE_M17N_FLT=no
2961 fi
2962
2963 ### End of font-backend (under X11) section.
2964
2965 AC_SUBST(FREETYPE_CFLAGS)
2966 AC_SUBST(FREETYPE_LIBS)
2967 AC_SUBST(FONTCONFIG_CFLAGS)
2968 AC_SUBST(FONTCONFIG_LIBS)
2969 AC_SUBST(LIBOTF_CFLAGS)
2970 AC_SUBST(LIBOTF_LIBS)
2971 AC_SUBST(M17N_FLT_CFLAGS)
2972 AC_SUBST(M17N_FLT_LIBS)
2973
2974 ### Use -lXpm if available, unless `--with-xpm=no'.
2975 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
2976 ### In the Cygwin-w32 build, we need to use /usr/include/noX/X11/xpm.h
2977 ### rather than /usr/include/X11/xpm.h, so we set CPPFLAGS (and
2978 ### LDFLAGS) accordingly.
2979 HAVE_XPM=no
2980 LIBXPM=
2981 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
2982   if test "${with_xpm}" != "no"; then
2983     SAVE_CPPFLAGS="$CPPFLAGS"
2984     SAVE_LDFLAGS="$LDFLAGS"
2985     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
2986     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
2987     AC_CHECK_HEADER(X11/xpm.h,
2988       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
2989     if test "${HAVE_XPM}" = "yes"; then
2990       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2991       AC_EGREP_CPP(no_return_alloc_pixels,
2992       [#include "X11/xpm.h"
2993 #ifndef XpmReturnAllocPixels
2994 no_return_alloc_pixels
2995 #endif
2996       ], HAVE_XPM=no, HAVE_XPM=yes)
2997
2998       if test "${HAVE_XPM}" = "yes"; then
2999         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3000         AC_MSG_RESULT(yes)
3001       else
3002         AC_MSG_RESULT(no)
3003         CPPFLAGS="$SAVE_CPPFLAGS"
3004         LDFLAGS="$SAVE_LDFLAGS"
3005       fi
3006     fi
3007   fi
3008
3009   if test "${HAVE_XPM}" = "yes"; then
3010     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3011     LIBXPM=-lXpm
3012   fi
3013 fi
3014
3015 if test "${HAVE_X11}" = "yes"; then
3016   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3017   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3018
3019   if test "${with_xpm}" != "no"; then
3020     AC_CHECK_HEADER(X11/xpm.h,
3021       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3022     if test "${HAVE_XPM}" = "yes"; then
3023       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3024       AC_EGREP_CPP(no_return_alloc_pixels,
3025       [#include "X11/xpm.h"
3026 #ifndef XpmReturnAllocPixels
3027 no_return_alloc_pixels
3028 #endif
3029       ], HAVE_XPM=no, HAVE_XPM=yes)
3030
3031       if test "${HAVE_XPM}" = "yes"; then
3032         AC_MSG_RESULT(yes)
3033       else
3034         AC_MSG_RESULT(no)
3035       fi
3036     fi
3037   fi
3038
3039   if test "${HAVE_XPM}" = "yes"; then
3040     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3041     LIBXPM=-lXpm
3042   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3043     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3044     LIBXPM=-lXpm
3045   fi
3046 fi
3047
3048 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3049 ### slightly different requirements wrt image libraries (it doesn't
3050 ### use -lXpm because it loads the xpm shared library dynamically at
3051 ### run time).
3052 if test "${opsys}" = "mingw32"; then
3053   if test "${with_xpm}" != "no"; then
3054     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3055 #define FOR_MSW 1])
3056   fi
3057
3058   if test "${HAVE_XPM}" = "yes"; then
3059     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3060   fi
3061 fi
3062
3063 AC_SUBST(LIBXPM)
3064
3065 ### Use -ljpeg if available, unless `--with-jpeg=no'.
3066 ### mingw32 doesn't use -ljpeg, since it loads the library dynamically.
3067 HAVE_JPEG=no
3068 LIBJPEG=
3069 if test "${opsys}" = "mingw32"; then
3070   if test "${with_jpeg}" != "no"; then
3071     dnl Checking for jpeglib.h can lose because of a redefinition of
3072     dnl HAVE_STDLIB_H.
3073     AC_CHECK_HEADER(jerror.h, HAVE_JPEG=yes, HAVE_JPEG=no)
3074   fi
3075   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3076   if test "${HAVE_JPEG}" = "yes"; then
3077     AC_DEFINE(HAVE_JPEG)
3078     AC_EGREP_CPP([version 6b or later],
3079         [#include <jpeglib.h>
3080          #if JPEG_LIB_VERSION >= 62
3081          version 6b or later
3082          #endif
3083         ],
3084         [AC_DEFINE(HAVE_JPEG)],
3085         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3086         HAVE_JPEG=no])
3087   fi
3088 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3089   if test "${with_jpeg}" != "no"; then
3090     dnl Checking for jpeglib.h can lose because of a redefinition of
3091     dnl  HAVE_STDLIB_H.
3092     AC_CHECK_HEADER(jerror.h,
3093       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
3094   fi
3095
3096   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3097   if test "${HAVE_JPEG}" = "yes"; then
3098     AC_DEFINE(HAVE_JPEG)
3099     AC_EGREP_CPP([version 6b or later],
3100         [#include <jpeglib.h>
3101          #if JPEG_LIB_VERSION >= 62
3102          version 6b or later
3103          #endif
3104         ],
3105         [AC_DEFINE(HAVE_JPEG)],
3106         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3107         HAVE_JPEG=no])
3108   fi
3109   if test "${HAVE_JPEG}" = "yes"; then
3110     LIBJPEG=-ljpeg
3111   fi
3112 fi
3113 AC_SUBST(LIBJPEG)
3114
3115 ### Use -lpng if available, unless `--with-png=no'.
3116 ### mingw32 doesn't use -lpng, since it loads the library dynamically.
3117 HAVE_PNG=no
3118 LIBPNG=
3119 if test "${opsys}" = "mingw32"; then
3120   if test "${with_png}" != "no"; then
3121     AC_CHECK_HEADER(png.h, HAVE_PNG=yes, HAVE_PNG=no)
3122   fi
3123   if test "${HAVE_PNG}" = "yes"; then
3124     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
3125
3126     AC_CHECK_DECL(png_longjmp,
3127       [],
3128       [AC_DEFINE(PNG_DEPSTRUCT, [],
3129          [Define to empty to suppress deprecation warnings when building
3130           with --enable-gcc-warnings and with libpng versions before 1.5,
3131           which lack png_longjmp.])],
3132       [[#ifdef HAVE_LIBPNG_PNG_H
3133         # include <libpng/png.h>
3134         #else
3135         # include <png.h>
3136         #endif
3137       ]])
3138   fi
3139 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3140   if test "${with_png}" != "no"; then
3141     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3142     # in /usr/include/libpng.
3143     AC_CHECK_HEADERS(png.h libpng/png.h, break)
3144     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
3145       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
3146     fi
3147   fi
3148
3149   if test "${HAVE_PNG}" = "yes"; then
3150     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library.])
3151
3152     dnl Some systems, eg NetBSD 6, only provide eg "libpng16", not "libpng".
3153     lpng=`libpng-config --libs 2> /dev/null`
3154     case $lpng in
3155       -l*) : ;;
3156       *) lpng="-lpng" ;;
3157     esac
3158     LIBPNG="$lpng -lz -lm"
3159
3160     AC_CHECK_DECL(png_longjmp,
3161       [],
3162       [AC_DEFINE(PNG_DEPSTRUCT, [],
3163          [Define to empty to suppress deprecation warnings when building
3164           with --enable-gcc-warnings and with libpng versions before 1.5,
3165           which lack png_longjmp.])],
3166       [[#ifdef HAVE_LIBPNG_PNG_H
3167         # include <libpng/png.h>
3168         #else
3169         # include <png.h>
3170         #endif
3171       ]])
3172   fi
3173 fi
3174 AC_SUBST(LIBPNG)
3175
3176 HAVE_ZLIB=no
3177 LIBZ=
3178 if test "${with_zlib}" != "no"; then
3179   OLIBS=$LIBS
3180   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3181   LIBS=$OLIBS
3182   case $ac_cv_search_inflateEnd in
3183     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3184   esac
3185 fi
3186 if test "${HAVE_ZLIB}" = "yes"; then
3187   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3188   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3189   if test "${opsys}" = "mingw32"; then
3190      LIBZ=
3191   fi
3192 fi
3193 AC_SUBST(LIBZ)
3194
3195
3196 ### Use -ltiff if available, unless `--with-tiff=no'.
3197 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3198 HAVE_TIFF=no
3199 LIBTIFF=
3200 if test "${opsys}" = "mingw32"; then
3201   if test "${with_tiff}" != "no"; then
3202     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3203   fi
3204   if test "${HAVE_TIFF}" = "yes"; then
3205     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3206   fi
3207 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3208   if test "${with_tiff}" != "no"; then
3209     AC_CHECK_HEADER(tiffio.h,
3210       [tifflibs="-lz -lm"
3211       # At least one tiff package requires the jpeg library.
3212       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3213       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3214   fi
3215
3216   if test "${HAVE_TIFF}" = "yes"; then
3217     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3218     dnl FIXME -lz -lm, as per libpng?
3219     LIBTIFF=-ltiff
3220   fi
3221 fi
3222 AC_SUBST(LIBTIFF)
3223
3224 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
3225 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3226 HAVE_GIF=no
3227 LIBGIF=
3228 if test "${opsys}" = "mingw32"; then
3229   if test "${with_gif}" != "no"; then
3230     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3231   fi
3232   if test "${HAVE_GIF}" = "yes"; then
3233     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3234   fi
3235 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3236         || test "${HAVE_W32}" = "yes"; then
3237   AC_CHECK_HEADER(gif_lib.h,
3238 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3239 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3240     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3241         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3242
3243   if test "$HAVE_GIF" = yes; then
3244     LIBGIF=-lgif
3245   elif test "$HAVE_GIF" = maybe; then
3246 # If gif_lib.h but no libgif, try libungif.
3247     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3248     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3249   fi
3250
3251   if test "${HAVE_GIF}" = "yes"; then
3252     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3253   fi
3254 fi
3255 AC_SUBST(LIBGIF)
3256
3257 dnl Check for required libraries.
3258 if test "${HAVE_X11}" = "yes"; then
3259   MISSING=""
3260   WITH_NO=""
3261   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3262     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3263   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3264     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3265   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3266     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3267   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3268     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3269   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3270     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3271
3272   if test "X${MISSING}" != X; then
3273     AC_MSG_ERROR([The following required libraries were not found:
3274     $MISSING
3275 Maybe some development libraries/packages are missing?
3276 If you don't want to link with them give
3277     $WITH_NO
3278 as options to configure])
3279   fi
3280 fi
3281
3282 ### Use -lgpm if available, unless `--with-gpm=no'.
3283 HAVE_GPM=no
3284 LIBGPM=
3285 if test "${with_gpm}" != "no"; then
3286   AC_CHECK_HEADER(gpm.h,
3287     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3288
3289   if test "${HAVE_GPM}" = "yes"; then
3290     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3291     LIBGPM=-lgpm
3292   fi
3293 fi
3294 AC_SUBST(LIBGPM)
3295
3296 dnl Check for malloc/malloc.h on darwin
3297 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3298
3299 GNUSTEP_CFLAGS=
3300 ### Use NeXTstep API to implement GUI.
3301 if test "${HAVE_NS}" = "yes"; then
3302   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3303   if test "${NS_IMPL_COCOA}" = "yes"; then
3304     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3305   fi
3306   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3307     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3308     # See also .m.o rule in Makefile.in */
3309     # FIXME: are all these flags really needed?  Document here why.  */
3310     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3311     ## Extra CFLAGS applied to src/*.m files.
3312     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3313   fi
3314   OTHER_FILES=ns-app
3315 fi
3316
3317 ### Use session management (-lSM -lICE) if available
3318 HAVE_X_SM=no
3319 LIBXSM=
3320 if test "${HAVE_X11}" = "yes"; then
3321   AC_CHECK_HEADER(X11/SM/SMlib.h,
3322     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3323
3324   if test "${HAVE_X_SM}" = "yes"; then
3325     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3326     LIBXSM="-lSM -lICE"
3327     case "$LIBS" in
3328       *-lSM*) ;;
3329       *)      LIBS="$LIBXSM $LIBS" ;;
3330     esac
3331   fi
3332 fi
3333 AC_SUBST(LIBXSM)
3334
3335 ### Use XRandr (-lXrandr) if available
3336 HAVE_XRANDR=no
3337 if test "${HAVE_X11}" = "yes"; then
3338   XRANDR_REQUIRED=1.2.2
3339   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3340   PKG_CHECK_MODULES(XRANDR, $XRANDR_MODULES, HAVE_XRANDR=yes, HAVE_XRANDR=no)
3341   if test $HAVE_XRANDR = no; then
3342     # Test old way in case pkg-config doesn't have it (older machines).
3343     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3344       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)])
3345     if test $HAVE_XRANDR = yes; then
3346       XRANDR_LIBS=-lXrandr
3347       AC_SUBST(XRANDR_LIBS)
3348     fi
3349   fi
3350   if test $HAVE_XRANDR = yes; then
3351     SAVE_CFLAGS="$CFLAGS"
3352     SAVE_LIBS="$LIBS"
3353     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3354     LIBS="$XRANDR_LIBS $LIBS"
3355     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3356     CFLAGS="$SAVE_CFLAGS"
3357     LIBS="$SAVE_LIBS"
3358
3359     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3360   fi
3361 fi
3362
3363 ### Use Xinerama (-lXinerama) if available
3364 HAVE_XINERAMA=no
3365 if test "${HAVE_X11}" = "yes"; then
3366   XINERAMA_REQUIRED=1.0.2
3367   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3368   PKG_CHECK_MODULES(XINERAMA, $XINERAMA_MODULES, HAVE_XINERAMA=yes,
3369                     HAVE_XINERAMA=no)
3370   if test $HAVE_XINERAMA = no; then
3371     # Test old way in case pkg-config doesn't have it (older machines).
3372     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3373       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3374     if test $HAVE_XINERAMA = yes; then
3375       XINERAMA_LIBS=-lXinerama
3376       AC_SUBST(XINERAMA_LIBS)
3377     fi
3378   fi
3379   if test $HAVE_XINERAMA = yes; then
3380     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3381   fi
3382 fi
3383
3384
3385 ### Use libxml (-lxml2) if available
3386 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3387 HAVE_LIBXML2=no
3388 if test "${with_xml2}" != "no"; then
3389   ### I'm not sure what the version number should be, so I just guessed.
3390   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
3391   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3392   if test "${HAVE_LIBXML2}" != "yes" -a "$opsys" = "darwin"; then
3393     SAVE_CPPFLAGS="$CPPFLAGS"
3394     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3395     AC_CHECK_HEADER(libxml/HTMLparser.h,
3396       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3397                      [#include <libxml/HTMLparser.h>])])
3398     CPPFLAGS="$SAVE_CPPFLAGS"
3399     if test "${HAVE_LIBXML2}" = "yes"; then
3400       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3401       LIBXML2_LIBS="-lxml2"
3402     fi
3403   fi
3404   if test "${HAVE_LIBXML2}" = "yes"; then
3405     if test "${opsys}" != "mingw32"; then
3406       LIBS="$LIBXML2_LIBS $LIBS"
3407       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
3408     else
3409       LIBXML2_LIBS=""
3410     fi
3411     if test "${HAVE_LIBXML2}" = "yes"; then
3412       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3413     else
3414       LIBXML2_LIBS=""
3415       LIBXML2_CFLAGS=""
3416     fi
3417   fi
3418 fi
3419 AC_SUBST(LIBXML2_LIBS)
3420 AC_SUBST(LIBXML2_CFLAGS)
3421
3422 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3423 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3424 if test "${opsys}" = "mingw32"; then
3425   emacs_cv_netdb_declares_h_errno=yes
3426 fi
3427 AC_CACHE_CHECK(whether netdb declares h_errno,
3428                emacs_cv_netdb_declares_h_errno,
3429 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3430   [[return h_errno;]])],
3431   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3432 if test $emacs_cv_netdb_declares_h_errno = yes; then
3433   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3434 fi
3435
3436 # sqrt and other floating-point functions such as fmod and frexp
3437 # are found in -lm on most systems, but mingw32 doesn't use -lm.
3438 if test "${opsys}" != "mingw32"; then
3439   AC_CHECK_LIB(m, sqrt)
3440 fi
3441
3442 # Check for mail-locking functions in a "mail" library.  Probably this should
3443 # have the same check as for liblockfile below.
3444 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3445 if test $have_mail = yes; then
3446   LIBS_MAIL=-lmail
3447   LIBS="$LIBS_MAIL $LIBS"
3448   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
3449 else
3450   LIBS_MAIL=
3451 fi
3452 dnl Debian, at least:
3453 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3454 if test $have_lockfile = yes; then
3455    LIBS_MAIL=-llockfile
3456    LIBS="$LIBS_MAIL $LIBS"
3457    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
3458 else
3459 # If we have the shared liblockfile, assume we must use it for mail
3460 # locking (e.g. Debian).  If we couldn't link against liblockfile
3461 # (no liblockfile.a installed), ensure that we don't need to.
3462   dnl This works for files generally, not just executables.
3463   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3464   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3465                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3466   if test $ac_cv_prog_liblockfile = yes; then
3467     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3468 This probably means that movemail could lose mail.
3469 There may be a `development' package to install containing liblockfile.])
3470   fi
3471 fi
3472 AC_CHECK_HEADERS_ONCE(maillock.h)
3473 AC_SUBST(LIBS_MAIL)
3474
3475 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3476 ## interlock access to the mail spool.  The alternative is a lock file named
3477 ## /usr/spool/mail/$USER.lock.
3478 mail_lock=no
3479 case "$opsys" in
3480   aix4-2) mail_lock="lockf" ;;
3481
3482   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3483
3484   ## On GNU/Linux systems, both methods are used by various mail programs.
3485   ## I assume most people are using newer mailers that have heard of flock.
3486   ## Change this if you need to.
3487   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
3488   ## configure gets the right answers, and that means *NOT* using flock.
3489   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3490   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
3491   ## Debian maintainer hasn't provided a clean fix for Emacs.
3492   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
3493   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3494   ## correct logic.  -- fx
3495   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3496   ## liblockfile is a Free Software replacement for libmail, used on
3497   ## Debian systems and elsewhere. -rfr.
3498   gnu-*)
3499     mail_lock="flock"
3500     if test $have_mail = yes || test $have_lockfile = yes; then
3501       test $ac_cv_header_maillock_h = yes && mail_lock=no
3502     fi
3503     ;;
3504
3505   mingw32)
3506     mail_lock="none-needed" ;;
3507 esac
3508
3509 BLESSMAIL_TARGET=
3510 case "$mail_lock" in
3511   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3512
3513   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3514
3515   none-needed) ;;
3516
3517   *) BLESSMAIL_TARGET="need-blessmail" ;;
3518 esac
3519 AC_SUBST(BLESSMAIL_TARGET)
3520
3521
3522 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3523 getrusage get_current_dir_name \
3524 lrand48 \
3525 select getpagesize setlocale \
3526 getrlimit setrlimit shutdown getaddrinfo \
3527 strsignal setitimer \
3528 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3529 gai_strerror getline getdelim sync \
3530 getpwent endpwent getgrent endgrent \
3531 touchlock \
3532 cfmakeraw cfsetspeed copysign __executable_start log2)
3533
3534 dnl No need to check for aligned_alloc and posix_memalign if using
3535 dnl gmalloc.o, as it supplies them.  Don't use these functions on
3536 dnl Darwin as they are incompatible with unexmacosx.c.
3537 if test -z "$GMALLOC_OBJ" && test "$opsys" != darwin; then
3538   AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3539 fi
3540
3541 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
3542 ## has a broken `rint' in some library versions including math library
3543 ## version number A.09.05.
3544 ## You can fix the math library by installing patch number PHSS_4630.
3545 ## But we can fix it more reliably for Emacs by just not using rint.
3546 ## We also skip HAVE_RANDOM - see comments in src/conf_post.h.
3547 case $opsys in
3548    hpux*) : ;;
3549    *) AC_CHECK_FUNCS(random rint) ;;
3550 esac
3551
3552 dnl Cannot use AC_CHECK_FUNCS
3553 AC_CACHE_CHECK([for __builtin_unwind_init],
3554                emacs_cv_func___builtin_unwind_init,
3555 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3556                 emacs_cv_func___builtin_unwind_init=yes,
3557                 emacs_cv_func___builtin_unwind_init=no)])
3558 if test $emacs_cv_func___builtin_unwind_init = yes; then
3559   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3560             [Define to 1 if you have the `__builtin_unwind_init' function.])
3561 fi
3562
3563 AC_CHECK_HEADERS_ONCE(sys/un.h)
3564
3565 AC_FUNC_FSEEKO
3566
3567 # UNIX98 PTYs.
3568 AC_CHECK_FUNCS(grantpt)
3569
3570 # PTY-related GNU extensions.
3571 AC_CHECK_FUNCS(getpt posix_openpt)
3572
3573 # Check this now, so that we will NOT find the above functions in ncurses.
3574 # That is because we have not set up to link ncurses in lib-src.
3575 # It's better to believe a function is not available
3576 # than to expect to find it in ncurses.
3577 # Also we need tputs and friends to be able to build at all.
3578 AC_MSG_CHECKING([for library containing tputs])
3579 # Run a test program that contains a call to tputs, a call that is
3580 # never executed.  This tests whether a pre-'main' dynamic linker
3581 # works with the library.  It's too much trouble to actually call
3582 # tputs in the test program, due to portability hassles.  When
3583 # cross-compiling, assume the test program will run if it links.
3584 AC_DEFUN([tputs_link_source], [
3585   AC_LANG_SOURCE(
3586      [[extern void tputs (const char *, int, int (*)(int));
3587        int main (int argc, char **argv)
3588        {
3589           if (argc == 10000)
3590             tputs (argv[0], 0, 0);
3591           return 0;
3592        }]])
3593 ])
3594 if test "${opsys}" = "mingw32"; then
3595   msg='none required'
3596 else
3597   # Maybe curses should be tried earlier?
3598   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3599   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3600     OLIBS=$LIBS
3601     if test -z "$tputs_library"; then
3602       LIBS_TERMCAP=
3603       msg='none required'
3604     else
3605       LIBS_TERMCAP=-l$tputs_library
3606       msg=$LIBS_TERMCAP
3607       LIBS="$LIBS_TERMCAP $LIBS"
3608     fi
3609     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3610       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3611     LIBS=$OLIBS
3612     if test "X$msg" != Xno; then
3613       break
3614     fi
3615   done
3616 fi
3617 AC_MSG_RESULT([$msg])
3618 if test "X$msg" = Xno; then
3619   AC_MSG_ERROR([The required function `tputs' was not found in any library.
3620 The following libraries were tried (in order):
3621   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3622 Please try installing whichever of these libraries is most appropriate
3623 for your system, together with its header files.
3624 For example, a libncurses-dev(el) or similar package.])
3625 fi
3626
3627 ## Use termcap instead of terminfo?
3628 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3629 TERMINFO=yes
3630 ## FIXME?  In the cases below where we unconditionally set
3631 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3632 ## if that was found above to have tputs.
3633 ## Should we use the gnu* logic everywhere?
3634 case "$opsys" in
3635   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3636   ##  The ncurses library has been moved out of the System framework in
3637   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3638   ##  option to use it.
3639   darwin) LIBS_TERMCAP="-lncurses" ;;
3640
3641   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3642
3643   freebsd)
3644     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3645     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3646     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3647 [[#if __FreeBSD_version < 400000
3648 fail;
3649 #endif
3650 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3651
3652     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3653
3654     if test $emacs_cv_freebsd_terminfo = yes; then
3655       LIBS_TERMCAP="-lncurses"
3656     else
3657       TERMINFO=no
3658       LIBS_TERMCAP="-ltermcap"
3659     fi
3660     ;;
3661
3662   mingw32)
3663     TERMINFO=no
3664     LIBS_TERMCAP=
3665     ;;
3666
3667   netbsd)
3668     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3669       TERMINFO=no
3670       LIBS_TERMCAP="-ltermcap"
3671     fi
3672     ;;
3673
3674   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3675
3676   ## hpux: Make sure we get select from libc rather than from libcurses
3677   ##  because libcurses on HPUX 10.10 has a broken version of select.
3678   ##  We used to use -lc -lcurses, but this may be cleaner.
3679   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3680   # set that way, now it uses the default).  Isn't this a contradiction?
3681   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3682
3683 esac
3684
3685 TERMCAP_OBJ=tparam.o
3686 if test $TERMINFO = yes; then
3687   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3688   TERMCAP_OBJ=terminfo.o
3689 fi
3690 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3691   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3692 fi
3693 AC_SUBST(LIBS_TERMCAP)
3694 AC_SUBST(TERMCAP_OBJ)
3695
3696
3697 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3698 # On Darwin, res_init appears not to be useful: see bug#562 and
3699 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3700 resolv=no
3701
3702 if test $opsys != darwin; then
3703
3704   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3705 #include <arpa/nameser.h>
3706 #include <resolv.h>]],
3707     [[return res_init();]])],
3708     have_res_init=yes, have_res_init=no)
3709   if test "$have_res_init" = no; then
3710     OLIBS="$LIBS"
3711     LIBS="$LIBS -lresolv"
3712     AC_MSG_CHECKING(for res_init with -lresolv)
3713     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3714 #include <arpa/nameser.h>
3715 #include <resolv.h>]],
3716       [[return res_init();]])],
3717       have_res_init=yes, have_res_init=no)
3718     AC_MSG_RESULT($have_res_init)
3719     if test "$have_res_init" = yes ; then
3720       resolv=yes
3721     fi
3722     LIBS="$OLIBS"
3723   fi
3724
3725   if test "$have_res_init" = yes; then
3726     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3727   fi
3728 fi                              dnl !darwin
3729
3730 # Do we need the Hesiod library to provide the support routines?
3731 dnl FIXME?  Should we be skipping this on Darwin too?
3732 LIBHESIOD=
3733 if test "$with_hesiod" != no ; then
3734   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3735   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3736      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3737                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3738   if test "$resolv" = yes ; then
3739     RESOLVLIB=-lresolv
3740   else
3741     RESOLVLIB=
3742   fi
3743   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3744         hesiod=yes, :, $RESOLVLIB)])
3745
3746   if test x"$hesiod" = xyes; then
3747     LIBHESIOD=-lhesiod
3748   fi
3749 fi
3750 AC_SUBST(LIBHESIOD)
3751
3752 # Do we need libresolv (due to res_init or Hesiod)?
3753 if test "$resolv" = yes && test $opsys != darwin; then
3754   LIBRESOLV=-lresolv
3755 else
3756   LIBRESOLV=
3757 fi
3758 AC_SUBST(LIBRESOLV)
3759
3760 # These tell us which Kerberos-related libraries to use.
3761 COM_ERRLIB=
3762 CRYPTOLIB=
3763 KRB5LIB=
3764 DESLIB=
3765 KRB4LIB=
3766
3767 if test "${with_kerberos}" != no; then
3768   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3769   if test $have_com_err = yes; then
3770     COM_ERRLIB=-lcom_err
3771     LIBS="$COM_ERRLIB $LIBS"
3772   fi
3773   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3774   if test $have_crypto = yes; then
3775     CRYPTOLIB=-lcrypto
3776     LIBS="$CRYPTOLIB $LIBS"
3777   fi
3778   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3779   if test $have_k5crypto = yes; then
3780     CRYPTOLIB=-lk5crypto
3781     LIBS="$CRYPTOLIB $LIBS"
3782   fi
3783   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3784   if test $have_krb5=yes; then
3785     KRB5LIB=-lkrb5
3786     LIBS="$KRB5LIB $LIBS"
3787   fi
3788   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3789   if test "${with_kerberos5}" = no; then
3790     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3791     if test $have_des425 = yes; then
3792       DESLIB=-ldes425
3793       LIBS="$DESLIB $LIBS"
3794     else
3795       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3796       if test $have_des = yes; then
3797         DESLIB=-ldes
3798         LIBS="$DESLIB $LIBS"
3799       fi
3800     fi
3801     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3802     if test $have_krb4 = yes; then
3803       KRB4LIB=-lkrb4
3804       LIBS="$KRB4LIB $LIBS"
3805     else
3806       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3807       if test $have_krb = yes; then
3808         KRB4LIB=-lkrb
3809         LIBS="$KRB4LIB $LIBS"
3810       fi
3811     fi
3812   fi
3813
3814   if test "${with_kerberos5}" != no; then
3815     AC_CHECK_HEADERS(krb5.h,
3816       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3817                         [#include <krb5.h>])])
3818   else
3819     AC_CHECK_HEADERS(krb.h,,
3820                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3821                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3822   fi
3823   AC_CHECK_HEADERS(com_err.h)
3824 fi
3825
3826 AC_SUBST(COM_ERRLIB)
3827 AC_SUBST(CRYPTOLIB)
3828 AC_SUBST(KRB5LIB)
3829 AC_SUBST(DESLIB)
3830 AC_SUBST(KRB4LIB)
3831
3832 AC_CHECK_HEADERS(valgrind/valgrind.h)
3833
3834 AC_CHECK_FUNCS_ONCE(tzset)
3835 AC_MSG_CHECKING(whether localtime caches TZ)
3836 AC_CACHE_VAL(emacs_cv_localtime_cache,
3837 [if test x$ac_cv_func_tzset = xyes; then
3838 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3839 char TZ_GMT0[] = "TZ=GMT0";
3840 char TZ_PST8[] = "TZ=PST8";
3841 main()
3842 {
3843   time_t now = time ((time_t *) 0);
3844   int hour_GMT0, hour_unset;
3845   if (putenv (TZ_GMT0) != 0)
3846     exit (1);
3847   hour_GMT0 = localtime (&now)->tm_hour;
3848   unsetenv("TZ");
3849   hour_unset = localtime (&now)->tm_hour;
3850   if (putenv (TZ_PST8) != 0)
3851     exit (1);
3852   if (localtime (&now)->tm_hour == hour_GMT0)
3853     exit (1);
3854   unsetenv("TZ");
3855   if (localtime (&now)->tm_hour != hour_unset)
3856     exit (1);
3857   exit (0);
3858 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3859 [# If we have tzset, assume the worst when cross-compiling.
3860 emacs_cv_localtime_cache=yes])
3861 else
3862         # If we lack tzset, report that localtime does not cache TZ,
3863         # since we can't invalidate the cache if we don't have tzset.
3864         emacs_cv_localtime_cache=no
3865 fi])dnl
3866 AC_MSG_RESULT($emacs_cv_localtime_cache)
3867 if test $emacs_cv_localtime_cache = yes; then
3868   AC_DEFINE(LOCALTIME_CACHE, 1,
3869             [Define to 1 if localtime caches TZ.])
3870 fi
3871
3872 ok_so_far=yes
3873 AC_CHECK_FUNC(socket, , ok_so_far=no)
3874 if test $ok_so_far = yes; then
3875   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3876 fi
3877 if test $ok_so_far = yes; then
3878   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3879 fi
3880 if test $ok_so_far = yes; then
3881 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3882   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3883             [Define to 1 if you have inet sockets.])
3884 fi
3885
3886 dnl Check for a Solaris 2.4 vfork bug that Autoconf misses (through 2.69).
3887 dnl This can be removed once we assume Autoconf 2.70.
3888 case $canonical in
3889   *-solaris2.4 | *-solaris2.4.*)
3890     dnl Disable the Autoconf-generated vfork test.
3891     : ${ac_cv_func_vfork_works=no};;
3892 esac
3893
3894 AC_FUNC_FORK
3895
3896 AC_CHECK_FUNCS(snprintf)
3897
3898 dnl Check this late.  It depends on what other libraries (lrsvg, Gtk+ etc)
3899 dnl Emacs uses.
3900 XGSELOBJ=
3901 OLDCFLAGS="$CFLAGS"
3902 OLDLIBS="$LIBS"
3903 CFLAGS="$CFLAGS $GFILENOTIFY_CFLAGS"
3904 LIBS="$LIBS $GFILENOTIFY_LIBS"
3905 AC_MSG_CHECKING([whether GLib is linked in])
3906 AC_LINK_IFELSE([AC_LANG_PROGRAM(
3907         [[#include <glib.h>
3908         ]],
3909         [[g_print ("Hello world");]])],
3910      [links_glib=yes],
3911      [links_glib=no])
3912 AC_MSG_RESULT([$links_glib])
3913 if test "${links_glib}" = "yes"; then
3914   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
3915   if test "$HAVE_NS" = no;then
3916     XGSELOBJ=xgselect.o
3917   fi
3918 fi
3919 CFLAGS="$OLDCFLAGS"
3920 LIBS="$OLDLIBS"
3921 AC_SUBST(XGSELOBJ)
3922
3923 dnl Adapted from Haible's version.
3924 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3925   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3926     [[char* cs = nl_langinfo(CODESET);]])],
3927     emacs_cv_langinfo_codeset=yes,
3928     emacs_cv_langinfo_codeset=no)
3929   ])
3930 if test $emacs_cv_langinfo_codeset = yes; then
3931   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3932     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3933 fi
3934
3935 AC_TYPE_MBSTATE_T
3936
3937 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3938   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3939                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3940 if test "$emacs_cv_c_restrict_arr" = yes; then
3941   AC_DEFINE(__restrict_arr, __restrict,
3942     [Define to compiler's equivalent of C99 restrict keyword in array
3943      declarations.  Define as empty for no equivalent.])
3944 fi
3945
3946 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3947 dnl how the tty code is related to POSIX and/or other versions of termios.
3948 dnl The following looks like a useful start.
3949 dnl
3950 dnl AC_SYS_POSIX_TERMIOS
3951 dnl if test $ac_cv_sys_posix_termios = yes; then
3952 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3953 dnl                                and macros for terminal control.])
3954 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3955 dnl fi
3956
3957 dnl Turned on June 1996 supposing nobody will mind it.
3958 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
3959 if test "${opsys}" != "mingw32"; then
3960    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3961      in the full name stands for the login id.])
3962 fi
3963
3964 dnl Every platform that uses configure supports this.
3965 dnl There is a create-lockfiles option you can
3966 dnl customize if you do not want the lock files to be written.
3967 dnl So it is not clear that this #define still needs to exist.
3968 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3969   so that Emacs can tell instantly when you try to modify a file that
3970   someone else has modified in his/her Emacs.])
3971
3972 dnl Everybody supports this, except MS.
3973 dnl Seems like the kind of thing we should be testing for, though.
3974 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3975 if test "${opsys}" != "mingw32"; then
3976   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3977 fi
3978
3979 dnl Everybody supports this, except MS-DOS.
3980 dnl Seems like the kind of thing we should be testing for, though.
3981 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3982 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3983   4.2-compatible sockets.])
3984
3985 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3986
3987 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
3988   a null file, or a data sink.])
3989 if test "${opsys}" = "mingw32"; then
3990   AC_DEFINE(NULL_DEVICE, ["NUL:"])
3991 else
3992   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
3993 fi
3994
3995 if test "${opsys}" = "mingw32"; then
3996   SEPCHAR=';'
3997 else
3998   SEPCHAR=':'
3999 fi
4000 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4001 dnl This is for MinGW, and is used in test/automated/Makefile.in.
4002 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4003 dnl decides that a command-line argument to be passed to a MinGW program
4004 dnl is a PATH-style list of directories.  But that heuristics plays it
4005 dnl safe, and only does the replacement when it is _absolutely_ sure it
4006 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4007 dnl which breaks in-tree builds.  So we do this manually instead.
4008 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4009 dnl be computed as ':' in MSYS Bash.
4010 AC_SUBST(SEPCHAR)
4011
4012 dnl Everybody supports this, except MS-DOS.
4013 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4014
4015 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4016
4017
4018 AC_DEFINE(DIRECTORY_SEP, ['/'],
4019   [Character that separates directories in a file name.])
4020
4021 if test "${opsys}" = "mingw32"; then
4022   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4023     [Returns true if character is a device separator.])
4024
4025   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4026     [Returns true if character is a directory separator.])
4027
4028   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4029     [Returns true if character is any form of separator.])
4030 else
4031   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4032     [Returns true if character is a device separator.])
4033
4034   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4035     [Returns true if character is a directory separator.])
4036
4037   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4038     [Returns true if character is any form of separator.])
4039 fi
4040
4041 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4042
4043 case $opsys in
4044   aix4-2)
4045     dnl Unfortunately without libXmu we cannot support EditRes.
4046     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
4047       AC_DEFINE(NO_EDITRES, 1)
4048     fi
4049     ;;
4050
4051   hpux*)
4052     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4053     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4054     AC_DEFINE(NO_EDITRES, 1)
4055     ;;
4056 esac
4057
4058
4059 case $opsys in
4060   irix6-5 | sol2* | unixware )
4061     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4062     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4063     dnl need the constant to dimension an array.  So wire in the appropriate
4064     dnl value here.
4065     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4066     ;;
4067 esac
4068
4069 emacs_broken_SIGIO=no
4070
4071 case $opsys in
4072   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4073   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4074   hpux* | irix6-5 | openbsd | sol2* | unixware )
4075     emacs_broken_SIGIO=yes
4076     ;;
4077
4078   aix4-2)
4079     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4080     dnl the way this system works, libc functions that return malloced
4081     dnl memory use the libc malloc implementation. Calling xfree or
4082     dnl xrealloc on the results of such functions results in a crash.
4083     dnl
4084     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4085     dnl but that does not currently work on this system.
4086     dnl
4087     dnl It is possible to completely override the malloc implementation on
4088     dnl AIX, but that involves putting the malloc functions in a shared
4089     dnl library and setting the MALLOCTYPE environment variable to point to
4090     dnl that shared library.
4091     dnl
4092     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4093     dnl to avoid a crash just use the Emacs implementation for that function.
4094     dnl
4095     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4096     dnl of this file, so that we do not check for get_current_dir_name
4097     dnl on AIX.  But that might be fragile if something else ends
4098     dnl up testing for get_current_dir_name as a dependency.
4099     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4100       get_current_dir_name should not be used.])
4101     ;;
4102
4103   freebsd)
4104     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4105     dnl writes/reads on a PTY, read(2) returns bogus data:
4106     dnl
4107     dnl write(2)  1022 bytes
4108     dnl write(2)   954 bytes, get EAGAIN
4109     dnl read(2)   1024 bytes in process_read_output
4110     dnl read(2)     11 bytes in process_read_output
4111     dnl
4112     dnl That is, read(2) returns more bytes than have ever been written
4113     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4114     dnl successfully after processing (for example with CRs added if the
4115     dnl terminal is set up that way which it is here).  The same bytes will
4116     dnl be seen again in a later read(2), without the CRs.
4117     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4118       work around an issue when reading from a PTY.])
4119     ;;
4120 esac
4121
4122 case $opsys in
4123   gnu-* | sol2-10 )
4124     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4125     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4126   ;;
4127 esac
4128
4129 case $opsys in
4130   darwin | dragonfly | freebsd | netbsd | openbsd )
4131     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4132       close a pty to make it a controlling terminal (it is already a
4133       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4134   ;;
4135 esac
4136
4137 dnl FIXME Surely we can test for this rather than hard-code it.
4138 case $opsys in
4139   netbsd | openbsd) sound_device="/dev/audio" ;;
4140   *) sound_device="/dev/dsp" ;;
4141 esac
4142
4143 dnl Used in sound.c
4144 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4145   [Name of the default sound device.])
4146
4147
4148 dnl Emacs can read input using SIGIO and buffering characters itself,
4149 dnl or using CBREAK mode and making C-g cause SIGINT.
4150 dnl The choice is controlled by the variable interrupt_input.
4151 dnl
4152 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4153 dnl
4154 dnl Emacs uses the presence of the USABLE_SIGIO macro
4155 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4156 dnl INTERRUPT_INPUT to decide whether to use it by default.
4157 dnl
4158 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4159 dnl CBREAK mode has two disadvantages
4160 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4161 dnl I hear that in system V this problem does not exist.
4162 dnl 2) Control-G causes output to be discarded.
4163 dnl I do not know whether this can be fixed in system V.
4164 dnl
4165 dnl Another method of doing input is planned but not implemented.
4166 dnl It would have Emacs fork off a separate process
4167 dnl to read the input and send it to the true Emacs process
4168 dnl through a pipe.
4169 case $opsys in
4170   darwin | gnu-linux | gnu-kfreebsd )
4171     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4172   ;;
4173 esac
4174
4175
4176 dnl If the system's imake configuration file defines `NeedWidePrototypes'
4177 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
4178 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
4179 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4180 dnl taking float or double parameters.
4181 case $opsys in
4182   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4183     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4184       file defines `NeedWidePrototypes' as `NO'.])
4185   ;;
4186 esac
4187
4188
4189 dnl Used in process.c, this must be a loop, even if it only runs once.
4190 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4191 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4192 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4193 dnl trying suffixes 0-16.
4194 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4195   first PTY, if PTYs are supported.])
4196 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4197 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4198   end of a PTY, if non-standard.])
4199 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4200   end of a PTY, if non-standard.])
4201
4202 case $opsys in
4203   aix4-2 )
4204     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4205     dnl You allocate a pty by opening /dev/ptc to get the master side.
4206     dnl To get the name of the slave side, you just ttyname() the master side.
4207     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4208     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4209     ;;
4210
4211   cygwin )
4212     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4213     dnl multi-line AC_DEFINEs are hard. :(
4214     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4215     AC_DEFINE(PTY_NAME_SPRINTF, [])
4216     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4217     ;;
4218
4219   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
4220   darwin )
4221     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4222     dnl Not used, because PTY_ITERATION is defined.
4223     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4224     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
4225     dnl But we don't have to block SIGCHLD because it is blocked in the
4226     dnl implementation of grantpt.
4227     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (false)])
4228     AC_DEFINE(PTY_NAME_SPRINTF, [])
4229     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4230     ;;
4231
4232   gnu | openbsd )
4233     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4234     ;;
4235
4236   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd )
4237     dnl if HAVE_GRANTPT
4238     if test "x$ac_cv_func_grantpt" = xyes; then
4239       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4240       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4241       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4242       dnl to prevent sigchld_handler from intercepting the child's death.
4243       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4244       dnl if HAVE_POSIX_OPENPT
4245       if test "x$ac_cv_func_posix_openpt" = xyes; then
4246         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4247         AC_DEFINE(PTY_NAME_SPRINTF, [])
4248       dnl if HAVE_GETPT
4249       elif test "x$ac_cv_func_getpt" = xyes; then
4250         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4251         AC_DEFINE(PTY_NAME_SPRINTF, [])
4252       else
4253         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4254       fi
4255     else
4256       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4257     fi
4258     ;;
4259
4260   hpux*)
4261     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4262     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4263     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4264     ;;
4265
4266   irix6-5 )
4267     dnl It looks like this cannot be right, because it is not a loop.
4268     dnl However, process.c actually does this:
4269     dnl # ifndef __sgi
4270     dnl   continue;
4271     dnl # else
4272     dnl   return -1;
4273     dnl # endif
4274     dnl which presumably makes it OK, since irix == sgi (?).
4275     dnl FIXME it seems like this special treatment is unnecessary?
4276     dnl Why can't irix use a single-trip loop like eg cygwin?
4277     AC_DEFINE(PTY_ITERATION, [])
4278     dnl Not used, because PTY_ITERATION is defined.
4279     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4280     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4281     dnl No need to get the pty name at all.
4282     AC_DEFINE(PTY_NAME_SPRINTF, [])
4283     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4284     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4285     ;;
4286
4287   sol2* )
4288     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
4289     dnl from intercepting that death.  If any child but grantpt's should die
4290     dnl within, it should be caught after sigrelse(2).
4291     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4292     ;;
4293
4294   unixware )
4295     dnl Comments are as per sol2*.
4296     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4297     ;;
4298 esac
4299
4300
4301 case $opsys in
4302   sol2* | unixware )
4303     dnl This change means that we don't loop through allocate_pty too
4304     dnl many times in the (rare) event of a failure.
4305     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4306     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4307     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4308     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4309     ;;
4310 esac
4311
4312
4313 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4314 "typing" a signal character on the pty.])
4315
4316 case $opsys in
4317   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4318   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4319   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4320     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4321     ;;
4322
4323   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4324   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4325   gnu-linux | gnu-kfreebsd )
4326
4327     AC_MSG_CHECKING([for signals via characters])
4328     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4329 #include <linux/version.h>
4330 #if LINUX_VERSION_CODE < 0x20400
4331 # error "Linux version too old"
4332 #endif
4333       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4334
4335     AC_MSG_RESULT([$emacs_signals_via_chars])
4336     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4337     ;;
4338 esac
4339
4340
4341 dnl Used in lisp.h, emacs.c, vm-limit.c
4342 dnl NEWS.18 describes this as "a number which contains
4343 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
4344 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
4345 stored in a Lisp_Object.])
4346 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
4347
4348 case $opsys in
4349   aix*)
4350     dnl This works with 32-bit executables; Emacs doesn't support 64-bit.
4351     AC_DEFINE(DATA_SEG_BITS, [0x20000000])
4352     ;;
4353   hpux*)
4354     dnl The data segment on this machine always starts at address 0x40000000.
4355     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
4356     ;;
4357   irix6-5)
4358     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
4359     ;;
4360 esac
4361
4362
4363 AH_TEMPLATE(TAB3, [Undocumented.])
4364
4365 case $opsys in
4366   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4367
4368   gnu | dragonfly | freebsd | netbsd | openbsd )
4369     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4370     AC_DEFINE(TAB3, OXTABS)
4371     ;;
4372
4373   gnu-linux | gnu-kfreebsd )
4374     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4375 #ifndef __ia64__
4376 # error "not ia64"
4377 #endif
4378       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4379         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4380         [Mark a secondary stack, like the register stack on the ia64.]), [])
4381     ;;
4382
4383   hpux*)
4384     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4385       run_time_remap; for HPUX.])
4386     ;;
4387 esac
4388
4389
4390 dnl This won't be used automatically yet.  We also need to know, at least,
4391 dnl that the stack is continuous.
4392 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4393   registers relevant for conservative garbage collection in the jmp_buf.])
4394
4395
4396 case $opsys in
4397   dnl Not all the architectures are tested, but there are Debian packages
4398   dnl for SCM and/or Guile on them, so the technique must work.  See also
4399   dnl comments in alloc.c concerning setjmp and gcc.
4400   dnl Fixme: it's probably safe to just use the GCC conditional below.
4401   gnu-linux | gnu-kfreebsd )
4402     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4403 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4404   || defined __alpha__ || defined __mips__ || defined __s390__ \
4405   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4406   || defined __ia64__ || defined __sh__
4407 /* ok */
4408 #else
4409 # error "setjmp not known to work on this arch"
4410 #endif
4411     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4412     ;;
4413 esac
4414
4415
4416 if test x$GCC = xyes; then
4417    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4418    AC_DEFINE(GC_SETJMP_WORKS, 1)
4419 else
4420   case $opsys in
4421     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4422     aix* | dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4423       AC_DEFINE(GC_SETJMP_WORKS, 1)
4424       ;;
4425   esac
4426 fi                              dnl GCC?
4427
4428 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4429 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4430   [AC_LINK_IFELSE(
4431      [AC_LANG_PROGRAM(
4432        [[#include <setjmp.h>
4433          #ifdef __MINGW32__
4434          # define _longjmp longjmp
4435          #endif
4436        ]],
4437        [[jmp_buf j;
4438          if (! _setjmp (j))
4439            _longjmp (j, 1);]])],
4440      [emacs_cv_func__setjmp=yes],
4441      [emacs_cv_func__setjmp=no])])
4442 if test $emacs_cv_func__setjmp = yes; then
4443   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4444 else
4445   AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4446     [AC_LINK_IFELSE(
4447        [AC_LANG_PROGRAM(
4448          [[#include <setjmp.h>
4449          ]],
4450          [[sigjmp_buf j;
4451            if (! sigsetjmp (j, 1))
4452              siglongjmp (j, 1);]])],
4453        [emacs_cv_func_sigsetjmp=yes],
4454        [emacs_cv_func_sigsetjmp=no])])
4455   if test $emacs_cv_func_sigsetjmp = yes; then
4456     AC_DEFINE([HAVE_SIGSETJMP], 1,
4457       [Define to 1 if sigsetjmp and siglongjmp work.
4458        The value of this symbol is irrelevant if HAVE__SETJMP is defined.])
4459   fi
4460 fi
4461
4462 case $opsys in
4463   sol2* | unixware )
4464     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4465     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4466     dnl and this is all we need.
4467     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4468     ;;
4469 esac
4470
4471
4472 case $opsys in
4473   hpux* | sol2* )
4474     dnl Used in xfaces.c.
4475     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4476       some systems, where it requires time.h.])
4477     ;;
4478 esac
4479
4480
4481 dnl Define symbols to identify the version of Unix this is.
4482 dnl Define all the symbols that apply correctly.
4483 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4484 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4485 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4486 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4487
4488 case $opsys in
4489   aix4-2)
4490     AC_DEFINE(USG, [])
4491     dnl This symbol should be defined on AIX Version 3  ???????
4492     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4493 #ifndef _AIX
4494 # error "_AIX not defined"
4495 #endif
4496     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4497     ;;
4498
4499   cygwin)
4500     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4501     ;;
4502
4503   darwin)
4504     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4505     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4506     dnl distinguish OS X from pure Darwin.
4507     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4508     ;;
4509
4510   gnu-linux | gnu-kfreebsd )
4511     AC_DEFINE(USG, [])
4512     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4513     ;;
4514
4515   hpux*)
4516     AC_DEFINE(USG, [])
4517     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4518     ;;
4519
4520   irix6-5)
4521     AC_DEFINE(USG, [])
4522     AC_DEFINE(USG5_4, [])
4523     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4524     ;;
4525
4526   mingw32)
4527     AC_DEFINE(DOS_NT, [])
4528     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4529     if test "x$ac_enable_checking" != "x" ; then
4530       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4531     fi
4532     ;;
4533
4534   sol2*)
4535     AC_DEFINE(USG, [])
4536     AC_DEFINE(USG5_4, [])
4537     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4538     ;;
4539
4540   unixware)
4541     AC_DEFINE(USG, [])
4542     AC_DEFINE(USG5_4, [])
4543     ;;
4544 esac
4545
4546 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4547   [case $opsys in
4548      aix4-2)
4549        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4550        emacs_cv_usable_FIONREAD=no
4551        ;;
4552
4553      mingw32)
4554        emacs_cv_usable_FIONREAD=yes
4555        ;;
4556
4557      *)
4558        AC_COMPILE_IFELSE(
4559          [AC_LANG_PROGRAM([[#include <sys/types.h>
4560                             #include <sys/ioctl.h>
4561                             #ifdef USG5_4
4562                             # include <sys/filio.h>
4563                             #endif
4564                           ]],
4565                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4566          [emacs_cv_usable_FIONREAD=yes],
4567          [emacs_cv_usable_FIONREAD=no])
4568        ;;
4569    esac])
4570 if test $emacs_cv_usable_FIONREAD = yes; then
4571   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4572
4573   if test $emacs_broken_SIGIO = no; then
4574     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4575       [AC_COMPILE_IFELSE(
4576          [AC_LANG_PROGRAM([[#include <fcntl.h>
4577                             #include <signal.h>
4578                           ]],
4579                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4580          [emacs_cv_usable_SIGIO=yes],
4581          [emacs_cv_usable_SIGIO=no])],
4582       [emacs_cv_usable_SIGIO=yes],
4583       [emacs_cv_usable_SIGIO=no])
4584     if test $emacs_cv_usable_SIGIO = yes; then
4585       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4586     fi
4587   fi
4588 fi
4589
4590
4591 case $opsys in
4592   dnl Emacs supplies its own malloc, but glib calls posix_memalign,
4593   dnl and on Cygwin prior to version 1.7.24 that becomes the
4594   dnl Cygwin-supplied posix_memalign.  As malloc is not the Cygwin
4595   dnl malloc, the Cygwin posix_memalign always returns ENOSYS.  A
4596   dnl workaround is to set G_SLICE=always-malloc.  This is no longer
4597   dnl needed starting with cygwin-1.7.24, and it is no longer
4598   dnl effective starting with glib-2.36. */
4599   cygwin)
4600     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
4601       G_SLICE environment variable to "always-malloc" at startup.])
4602     ;;
4603
4604   hpux11)
4605     dnl It works to open the pty's tty in the parent (Emacs), then
4606     dnl close and reopen it in the child.
4607     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4608       works to open a pty's tty in the parent process, then close and
4609       reopen it in the child.])
4610     ;;
4611
4612   irix6-5)
4613     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4614       use VSUSP instead of VSWTCH.])
4615     ;;
4616
4617   sol2-10)
4618     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4619       on Solaris.])
4620     ;;
4621 esac
4622
4623 # Set up the CFLAGS for real compilation, so we can substitute it.
4624 CFLAGS="$REAL_CFLAGS"
4625 CPPFLAGS="$REAL_CPPFLAGS"
4626
4627 ## Hack to detect a buggy GCC version.
4628 if test "x$GCC" = xyes \
4629    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4630    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4631    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4632    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4633 fi
4634
4635 version=$PACKAGE_VERSION
4636
4637 copyright="Copyright (C) 2015 Free Software Foundation, Inc."
4638 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4639   [Short copyright string for this version of Emacs.])
4640 AC_SUBST(copyright)
4641
4642 ### Specify what sort of things we'll be editing into Makefile and config.h.
4643 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4644 AC_SUBST(version)
4645 AC_SUBST(configuration)
4646 ## Unused?
4647 AC_SUBST(canonical)
4648 AC_SUBST(srcdir)
4649 AC_SUBST(prefix)
4650 AC_SUBST(exec_prefix)
4651 AC_SUBST(bindir)
4652 AC_SUBST(datadir)
4653 AC_SUBST(sharedstatedir)
4654 AC_SUBST(libexecdir)
4655 AC_SUBST(mandir)
4656 AC_SUBST(infodir)
4657 AC_SUBST(lispdir)
4658 AC_SUBST(standardlisppath)
4659 AC_SUBST(locallisppath)
4660 AC_SUBST(lisppath)
4661 AC_SUBST(x_default_search_path)
4662 AC_SUBST(etcdir)
4663 AC_SUBST(archlibdir)
4664 AC_SUBST(etcdocdir)
4665 AC_SUBST(bitmapdir)
4666 AC_SUBST(gamedir)
4667 AC_SUBST(gameuser)
4668 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4669 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4670 ## end of LIBX_BASE, but nothing ever set it.
4671 AC_SUBST(LD_SWITCH_X_SITE)
4672 AC_SUBST(C_SWITCH_X_SITE)
4673 AC_SUBST(GNUSTEP_CFLAGS)
4674 AC_SUBST(CFLAGS)
4675 ## Used in lwlib/Makefile.in.
4676 AC_SUBST(X_TOOLKIT_TYPE)
4677 AC_SUBST(ns_appdir)
4678 AC_SUBST(ns_appbindir)
4679 AC_SUBST(ns_appresdir)
4680 AC_SUBST(ns_appsrc)
4681 AC_SUBST(GNU_OBJC_CFLAGS)
4682 AC_SUBST(OTHER_FILES)
4683
4684 if test -n "${term_header}"; then
4685     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4686         [Define to the header for the built-in window system.])
4687 fi
4688
4689 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4690                    [Define to the canonical Emacs configuration name.])
4691 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4692                    [Define to the options passed to configure.])
4693 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4694   define this to include extra configuration information.])
4695
4696 case $opsys in
4697   mingw32)
4698     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4699     ;;
4700 esac
4701
4702 XMENU_OBJ=
4703 XOBJ=
4704 FONT_OBJ=
4705 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4706   AC_DEFINE(HAVE_X_WINDOWS, 1,
4707             [Define to 1 if you want to use the X window system.])
4708   XMENU_OBJ=xmenu.o
4709   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4710   FONT_OBJ=xfont.o
4711   if test "$HAVE_XFT" = "yes"; then
4712     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4713   elif test "$HAVE_FREETYPE" = "yes"; then
4714     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4715   fi
4716   AC_SUBST(FONT_OBJ)
4717 fi
4718 AC_SUBST(XMENU_OBJ)
4719 AC_SUBST(XOBJ)
4720 AC_SUBST(FONT_OBJ)
4721
4722 WIDGET_OBJ=
4723 MOTIF_LIBW=
4724 if test "${USE_X_TOOLKIT}" != "none" ; then
4725   WIDGET_OBJ=widget.o
4726   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4727   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4728     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4729   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4730     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4731     MOTIF_LIBW=-lXm
4732     case "$opsys" in
4733       gnu-linux)
4734         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4735         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4736         ;;
4737
4738       unixware)
4739         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4740         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4741         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4742         ;;
4743
4744       aix4-2)
4745         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4746         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4747         ;;
4748     esac
4749     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4750   fi
4751 fi
4752 AC_SUBST(WIDGET_OBJ)
4753
4754 TOOLKIT_LIBW=
4755 case "$USE_X_TOOLKIT" in
4756   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4757   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4758   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4759 esac
4760 AC_SUBST(TOOLKIT_LIBW)
4761
4762 if test "${opsys}" != "mingw32"; then
4763   if test "$USE_X_TOOLKIT" = "none"; then
4764     LIBXT_OTHER="\$(LIBXSM)"
4765   else
4766     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4767   fi
4768 fi
4769 AC_SUBST(LIBXT_OTHER)
4770
4771 if test "${HAVE_X11}" = "yes" ; then
4772   AC_DEFINE(HAVE_X11, 1,
4773             [Define to 1 if you want to use version 11 of X windows.])
4774   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4775 else
4776   LIBX_OTHER=
4777 fi
4778 AC_SUBST(LIBX_OTHER)
4779
4780 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4781   LIBXMENU=
4782 elif test "$USE_X_TOOLKIT" = none; then
4783   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4784 else
4785   LIBXMENU='$(lwlibdir)/liblw.a'
4786 fi
4787 AC_SUBST(LIBXMENU)
4788
4789 if test "${GNU_MALLOC}" = "yes" ; then
4790   AC_DEFINE(GNU_MALLOC, 1,
4791             [Define to 1 if you want to use the GNU memory allocator.])
4792 fi
4793
4794 RALLOC_OBJ=
4795 if test "${REL_ALLOC}" = "yes" ; then
4796   AC_DEFINE(REL_ALLOC, 1,
4797             [Define REL_ALLOC if you want to use the relocating allocator for
4798              buffer space.])
4799
4800   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4801 fi
4802 AC_SUBST(RALLOC_OBJ)
4803
4804 if test "$opsys" = "cygwin"; then
4805   CYGWIN_OBJ="sheap.o cygw32.o"
4806   ## Cygwin differs because of its unexec().
4807   PRE_ALLOC_OBJ=
4808   POST_ALLOC_OBJ=lastfile.o
4809 elif test "$opsys" = "mingw32"; then
4810   CYGWIN_OBJ=
4811   PRE_ALLOC_OBJ=
4812   POST_ALLOC_OBJ=lastfile.o
4813 else
4814   CYGWIN_OBJ=
4815   PRE_ALLOC_OBJ=lastfile.o
4816   POST_ALLOC_OBJ=
4817 fi
4818 AC_SUBST(CYGWIN_OBJ)
4819 AC_SUBST(PRE_ALLOC_OBJ)
4820 AC_SUBST(POST_ALLOC_OBJ)
4821
4822 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
4823 dnl verbatim defined above.  The tricky name is apropos, as this hack
4824 dnl makes Fortify go sour!
4825 AH_VERBATIM([FORTIFY_SOUR],
4826 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
4827    The workaround disables some useful run-time checking, so it
4828    should be conditional to the platforms with the performance bug.
4829    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
4830 #if defined __APPLE__ && defined __GNUC__
4831 # ifndef _DONT_USE_CTYPE_INLINE_
4832 #  define _DONT_USE_CTYPE_INLINE_
4833 # endif
4834 # ifndef _FORTIFY_SOURCE
4835 #  define _FORTIFY_SOURCE 0
4836 # endif
4837 #endif
4838 ])
4839
4840 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4841 # it temporarily reverts them to their pre-pkg-config values,
4842 # because gnulib needs to work with both src (which uses the
4843 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4844 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4845 # and it therefore needs to run in an environment where LIBS does not
4846 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4847 # for some package unrelated to lib-src.
4848 SAVE_CFLAGS=$CFLAGS
4849 SAVE_LIBS=$LIBS
4850 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4851 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4852 gl_ASSERT_NO_GNULIB_POSIXCHECK
4853 gl_ASSERT_NO_GNULIB_TESTS
4854 gl_INIT
4855 CFLAGS=$SAVE_CFLAGS
4856 LIBS=$SAVE_LIBS
4857
4858 if test "${opsys}" = "mingw32"; then
4859   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
4860   # Remove unneeded switches from the value of CC that goes to Makefiles
4861   CC=`echo $CC | sed -e "s,$GCC_TEST_OPTIONS,,"`
4862 fi
4863
4864 case "$opsys" in
4865   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4866
4867   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
4868
4869   darwin)
4870    ## The -headerpad option tells ld (see man page) to leave room at the
4871    ## end of the header for adding load commands.  Needed for dumping.
4872    ## 0x1000 is enough for roughly 52 load commands on the x86_64
4873    ## architecture (where they are 78 bytes each). The actual number of
4874    ## load commands added is not consistent but normally ranges from
4875    ## about 14 to about 34. Setting it high gets us plenty of slop and
4876    ## only costs about 1.5K of wasted binary space.
4877    headerpad_extra=1000
4878    if test "$HAVE_NS" = "yes"; then
4879      libs_nsgui="-framework AppKit"
4880      if test "$NS_IMPL_COCOA" = "yes"; then
4881         libs_nsgui="$libs_nsgui -framework IOKit"
4882      fi
4883    else
4884      libs_nsgui=
4885    fi
4886    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4887
4888    ## This is here because src/Makefile.in did some extra fiddling around
4889    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
4890    ## LD_SWITCH_SYSTEM_TEMACS instead,
4891    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4892      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4893    ;;
4894
4895   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4896   ## find X at run-time.
4897   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4898   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4899   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4900   ## had different values in configure (in ac_link) and src/Makefile.in.
4901   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4902   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4903
4904   mingw32)
4905    ## MinGW64 does not prepend an underscore to symbols, so we must
4906    ## pass a different -entry switch to linker.  FIXME: It is better
4907    ## to make the entry points the same by changing unexw32.c.
4908    case "$canonical" in
4909      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4910      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4911    esac
4912    ;;
4913
4914   openbsd) LD_SWITCH_SYSTEM_TEMACS='-nopie' ;;
4915
4916   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4917 esac
4918
4919 if test x$ac_enable_profiling != x ; then
4920   case $opsys in
4921     *freebsd | gnu-linux) ;;
4922     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
4923   esac
4924 fi
4925
4926 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
4927
4928 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4929
4930 ## MinGW-specific post-link processing of temacs.
4931 TEMACS_POST_LINK=":"
4932 ADDSECTION=
4933 EMACS_HEAPSIZE=
4934 if test "${opsys}" = "mingw32"; then
4935   TEMACS_POST_LINK="\$(MINGW_TEMACS_POST_LINK)"
4936   ADDSECTION="../nt/addsection\$(EXEEXT)"
4937   ## Preload heap size of temacs.exe in MB.
4938   case "$canonical" in
4939     x86_64-*-*) EMACS_HEAPSIZE=42 ;;
4940     *) EMACS_HEAPSIZE=27 ;;
4941   esac
4942 fi
4943
4944 AC_SUBST(ADDSECTION)
4945 AC_SUBST(TEMACS_POST_LINK)
4946 AC_SUBST(EMACS_HEAPSIZE)
4947
4948 ## Common for all window systems
4949 if test "$window_system" != "none"; then
4950   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4951   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4952 fi
4953
4954 AC_SUBST(WINDOW_SYSTEM_OBJ)
4955
4956 AH_TOP([/* GNU Emacs site configuration template file.
4957
4958 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2015
4959   Free Software Foundation, Inc.
4960
4961 This file is part of GNU Emacs.
4962
4963 GNU Emacs is free software: you can redistribute it and/or modify
4964 it under the terms of the GNU General Public License as published by
4965 the Free Software Foundation, either version 3 of the License, or
4966 (at your option) any later version.
4967
4968 GNU Emacs is distributed in the hope that it will be useful,
4969 but WITHOUT ANY WARRANTY; without even the implied warranty of
4970 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4971 GNU General Public License for more details.
4972
4973 You should have received a copy of the GNU General Public License
4974 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4975
4976
4977 /* No code in Emacs #includes config.h twice, but some bits of code
4978    intended to work with other packages as well (like gmalloc.c)
4979    think they can include it as many times as they like.  */
4980 #ifndef EMACS_CONFIG_H
4981 #define EMACS_CONFIG_H
4982 ])dnl
4983
4984 AH_BOTTOM([#include <conf_post.h>
4985
4986 #endif /* EMACS_CONFIG_H */
4987
4988 /*
4989 Local Variables:
4990 mode: c
4991 End:
4992 */
4993 ])dnl
4994
4995 #### Report on what we decided to do.
4996 #### Report GTK as a toolkit, even if it doesn't use Xt.
4997 #### It makes printing result more understandable as using GTK sets
4998 #### toolkit_scroll_bars to yes by default.
4999 if test "${HAVE_GTK}" = "yes"; then
5000   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5001 fi
5002
5003 if test $USE_ACL -ne 0; then
5004   acl_summary="yes $LIB_ACL"
5005 else
5006   acl_summary=no
5007 fi
5008
5009 echo "
5010 Configured for \`${canonical}'.
5011
5012   Where should the build process find the source code?    ${srcdir}
5013   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5014   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5015   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5016   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5017   What window system should Emacs use?                    ${window_system}
5018   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
5019
5020 if test -n "${x_includes}"; then
5021 echo "  Where do we find X Windows header files?                ${x_includes}"
5022 else
5023 echo "  Where do we find X Windows header files?                Standard dirs"
5024 fi
5025 if test -n "${x_libraries}"; then
5026 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
5027 else
5028 echo "  Where do we find X Windows libraries?                   Standard dirs"
5029 fi
5030
5031 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
5032 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
5033 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
5034 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
5035 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
5036 echo "  Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG"
5037 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
5038 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
5039
5040 echo "  Does Emacs support sound?                               ${HAVE_SOUND}"
5041
5042 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
5043 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
5044 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
5045 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
5046 echo "  Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}"
5047 echo "  Does Emacs use access control lists?                    ${acl_summary}"
5048 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
5049 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
5050 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
5051
5052 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
5053 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
5054 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
5055 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
5056 echo "  Does Emacs directly use zlib?                           ${HAVE_ZLIB}"
5057
5058 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
5059 echo
5060
5061 if test -n "${EMACSDATA}"; then
5062    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
5063 fi
5064 if test -n "${EMACSDOC}"; then
5065    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
5066 fi
5067
5068 echo
5069
5070 if test "$HAVE_NS" = "yes"; then
5071    echo
5072    echo "You must run \"${MAKE-make} install\" in order to test the built application.
5073 The installed application will go to nextstep/Emacs.app and can be
5074 run or moved from there."
5075    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5076       echo "The application will be fully self-contained."
5077     else
5078       echo "The lisp resources for the application will be installed under ${prefix}.
5079 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5080 to run if these resources are not installed."
5081    fi
5082    echo
5083 fi
5084
5085 if test "${opsys}" = "cygwin"; then
5086   case `uname -r` in
5087     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5088            echo
5089            ;;
5090   esac
5091 fi
5092
5093 # Remove any trailing slashes in these variables.
5094 [test "${prefix}" != NONE &&
5095   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
5096 test "${exec_prefix}" != NONE &&
5097   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
5098
5099 if test "$HAVE_NS" = "yes"; then
5100   if test "$NS_IMPL_GNUSTEP" = yes; then
5101     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5102       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5103     ns_check_file=Resources/Info-gnustep.plist
5104   else
5105     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5106       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5107     ns_check_file=Contents/Info.plist
5108   fi
5109   AC_SUBST(ns_check_file)
5110 fi
5111
5112 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5113 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5114 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5115 dnl (else you get "no `Makefile.am' found for any configure output").
5116 dnl This will work, but you get a config.status that is not quite right
5117 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5118 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5119 dnl it seems better to just live with the duplication.
5120 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5121
5122 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5123        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5124        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5125        leim/Makefile nextstep/Makefile nt/Makefile])
5126
5127 dnl test/ is not present in release tarfiles.
5128 opt_makefile=test/automated/Makefile
5129
5130 if test -f "$srcdir/$opt_makefile.in"; then
5131   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5132   dnl Again, it's best not to use a variable.  Though you can add
5133   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5134   AC_CONFIG_FILES([test/automated/Makefile])
5135 fi
5136
5137
5138 dnl The admin/ directory used to be excluded from tarfiles.
5139 if test -d $srcdir/admin; then
5140   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/unidata/Makefile admin/grammars/Makefile"
5141   AC_CONFIG_FILES([admin/unidata/Makefile])
5142   AC_CONFIG_FILES([admin/grammars/Makefile])
5143 fi                              dnl -d admin
5144
5145
5146 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5147
5148 AC_SUBST(SUBDIR_MAKEFILES_IN)
5149
5150 dnl You might wonder (I did) why epaths.h is generated by running make,
5151 dnl rather than just letting configure generate it from epaths.in.
5152 dnl One reason is that the various paths are not fully expanded (see above);
5153 dnl eg gamedir=${prefix}/var/games/emacs.
5154 dnl Secondly, the GNU Coding standards require that one should be able
5155 dnl to run `make prefix=/some/where/else' and override the values set
5156 dnl by configure.  This also explains the `move-if-change' test and
5157 dnl the use of force in the `epaths-force' rule in Makefile.in.
5158 AC_CONFIG_COMMANDS([src/epaths.h], [
5159 if test "${opsys}" = "mingw32"; then
5160   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5161 else
5162   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5163 fi
5164 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5165
5166 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5167 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5168 dnl or a symlink?
5169 AC_CONFIG_COMMANDS([src/.gdbinit], [
5170 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5171   echo "source $ac_abs_top_srcdir/src/.gdbinit" > src/.gdbinit
5172 fi
5173 ])
5174
5175 AC_OUTPUT