code.delx.au - gnu-emacs/blob - lisp/xwidget.el

   1 ;;; xwidget.el --- api functions for xwidgets  -*- lexical-binding: t -*-
   2 ;;
   3 ;; Copyright (C) 2011-2016 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Joakim Verona (joakim@verona.se)
   6 ;;
   7 ;; This file is part of GNU Emacs.
   8 ;;
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21 ;;
  22 ;; --------------------------------------------------------------------
  23
  24 ;;; Commentary:
  25 ;;
  26 ;; See xwidget.c for more api functions.
  27
  28 ;; TODO this breaks compilation when we don't have xwidgets.
  29 ;;(require 'xwidget-internal)
  30
  31 ;;; Code:
  32
  33 (require 'cl-lib)
  34 (require 'bookmark)
  35
  36 (defcustom xwidget-webkit-scroll-behaviour 'native
  37   "Scroll behaviour of the webkit instance.
  38 'native or 'image."
  39   :version "25.1"
  40   :group 'frames   ; TODO add xwidgets group if more options are added
  41   :type '(choice (const native) (const image)))
  42
  43 (declare-function make-xwidget "xwidget.c"
  44                   (beg end type title width height arguments &optional buffer))
  45 (declare-function xwidget-set-adjustment "xwidget.c"
  46                   (xwidget axis relative value))
  47 (declare-function xwidget-buffer "xwidget.c" (xwidget))
  48 (declare-function xwidget-webkit-get-title "xwidget.c" (xwidget))
  49 (declare-function xwidget-size-request "xwidget.c" (xwidget))
  50 (declare-function xwidget-resize "xwidget.c" (xwidget new-width new-height))
  51 (declare-function xwidget-webkit-execute-script "xwidget.c" (xwidget script))
  52 (declare-function xwidget-webkit-goto-uri "xwidget.c" (xwidget uri))
  53 (declare-function xwidget-plist "xwidget.c" (xwidget))
  54 (declare-function set-xwidget-plist "xwidget.c" (xwidget plist))
  55 (declare-function xwidget-view-window "xwidget.c" (xwidget-view))
  56 (declare-function xwidget-view-model "xwidget.c" (xwidget-view))
  57 (declare-function delete-xwidget-view "xwidget.c" (xwidget-view))
  58 (declare-function get-buffer-xwidgets "xwidget.c" (buffer))
  59
  60 (defun xwidget-insert (pos type title width height &optional args)
  61   "Insert an xwidget at POS.
  62 given ID, TYPE, TITLE WIDTH and
  63 HEIGHT in the current buffer.
  64
  65 Return ID
  66
  67 see `make-xwidget' for types suitable for TYPE.
  68 Optional argument ARGS usage depends on the xwidget."
  69   (goto-char pos)
  70   (let ((id (make-xwidget (point) (point)
  71                           type title width height args)))
  72     (put-text-property (point) (+ 1 (point))
  73                        'display (list 'xwidget ':xwidget id))
  74     id))
  75
  76 (defun xwidget-at (pos)
  77   "Return xwidget at POS."
  78   ;; TODO this function is a bit tedious because the C layer isn't well
  79   ;; protected yet and xwidgetp apparently doesn't work yet.
  80   (let* ((disp (get-text-property pos 'display))
  81          (xw (car (cdr (cdr  disp)))))
  82     ;;(if ( xwidgetp  xw) xw nil)
  83     (if (equal 'xwidget (car disp)) xw)))
  84
  85
  86
  87 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  88 ;;; webkit support
  89 (require 'browse-url)
  90 (require 'image-mode);;for some image-mode alike functionality
  91
  92 ;;;###autoload
  93 (defun xwidget-webkit-browse-url (url &optional new-session)
  94   "Ask xwidget-webkit to browse URL.
  95 NEW-SESSION specifies whether to create a new xwidget-webkit session.  URL
  96 defaults to the string looking like a url around the cursor position."
  97   (interactive (progn
  98                  (require 'browse-url)
  99                  (browse-url-interactive-arg "xwidget-webkit URL: "
 100                                              ;;( xwidget-webkit-current-url)
 101                                              )))
 102   (when (stringp url)
 103     (if new-session
 104         (xwidget-webkit-new-session url)
 105       (xwidget-webkit-goto-url url))))
 106
 107 ;;todo.
 108 ;; - check that the webkit support is compiled in
 109 (defvar xwidget-webkit-mode-map
 110   (let ((map (make-sparse-keymap)))
 111     (define-key map "g" 'xwidget-webkit-browse-url)
 112     (define-key map "a" 'xwidget-webkit-adjust-size-dispatch)
 113     (define-key map "b" 'xwidget-webkit-back )
 114     (define-key map "r" 'xwidget-webkit-reload )
 115     (define-key map "t" (lambda () (interactive) (message "o")) )
 116     (define-key map "\C-m" 'xwidget-webkit-insert-string)
 117     (define-key map "w" 'xwidget-webkit-current-url)
 118
 119     ;;similar to image mode bindings
 120     (define-key map (kbd "SPC")                 'xwidget-webkit-scroll-up)
 121     (define-key map (kbd "DEL")                 'xwidget-webkit-scroll-down)
 122
 123     (define-key map [remap scroll-up]           'xwidget-webkit-scroll-up)
 124     (define-key map [remap scroll-up-command]   'xwidget-webkit-scroll-up)
 125
 126     (define-key map [remap scroll-down]         'xwidget-webkit-scroll-down)
 127     (define-key map [remap scroll-down-command] 'xwidget-webkit-scroll-down)
 128
 129     (define-key map [remap forward-char]        'xwidget-webkit-scroll-forward)
 130     (define-key map [remap backward-char]       'xwidget-webkit-scroll-backward)
 131     (define-key map [remap right-char]          'xwidget-webkit-scroll-forward)
 132     (define-key map [remap left-char]           'xwidget-webkit-scroll-backward)
 133     ;; (define-key map [remap previous-line]          'image-previous-line)
 134     ;; (define-key map [remap next-line]              'image-next-line)
 135
 136     ;; (define-key map [remap move-beginning-of-line] 'image-bol)
 137     ;; (define-key map [remap move-end-of-line]       'image-eol)
 138     ;; (define-key map [remap beginning-of-buffer]    'image-bob)
 139     ;; (define-key map [remap end-of-buffer]          'image-eob)
 140     map)
 141   "Keymap for `xwidget-webkit-mode'.")
 142
 143 (defun xwidget-webkit-scroll-up ()
 144   "Scroll webkit up,either native or like image mode."
 145   (interactive)
 146   (if (eq xwidget-webkit-scroll-behaviour 'native)
 147       (xwidget-set-adjustment (xwidget-webkit-last-session) 'vertical t 50)
 148     (image-scroll-up)))
 149
 150 (defun xwidget-webkit-scroll-down ()
 151   "Scroll webkit down,either native or like image mode."
 152   (interactive)
 153   (if (eq xwidget-webkit-scroll-behaviour 'native)
 154       (xwidget-set-adjustment (xwidget-webkit-last-session) 'vertical t -50)
 155     (image-scroll-down)))
 156
 157 (defun xwidget-webkit-scroll-forward ()
 158   "Scroll webkit forward,either native or like image mode."
 159   (interactive)
 160   (if (eq xwidget-webkit-scroll-behaviour 'native)
 161       (xwidget-set-adjustment (xwidget-webkit-last-session) 'horizontal t 50)
 162     (xwidget-webkit-scroll-forward)))
 163
 164 (defun xwidget-webkit-scroll-backward ()
 165   "Scroll webkit backward,either native or like image mode."
 166   (interactive)
 167   (if (eq xwidget-webkit-scroll-behaviour 'native)
 168       (xwidget-set-adjustment (xwidget-webkit-last-session) 'horizontal t -50)
 169     (xwidget-webkit-scroll-backward)))
 170
 171
 172 ;; The xwidget event needs to go into a higher level handler
 173 ;; since the xwidget can generate an event even if it's offscreen.
 174 ;; TODO this needs to use callbacks and consider different xwidget event types.
 175 (define-key (current-global-map) [xwidget-event] 'xwidget-event-handler)
 176 (defun xwidget-log ( &rest msg)
 177   "Log MSG to a buffer."
 178   (let ( (buf  (get-buffer-create "*xwidget-log*")))
 179     (save-excursion
 180       (buffer-disable-undo buf)
 181       (set-buffer buf)
 182       (insert (apply  'format msg))
 183       (insert "\n"))))
 184
 185 (defun xwidget-event-handler ()
 186   "Receive xwidget event."
 187   (interactive)
 188   (xwidget-log "stuff happened to xwidget %S" last-input-event)
 189   (let*
 190       ((xwidget-event-type (nth 1 last-input-event))
 191        (xwidget (nth 2 last-input-event))
 192        ;;(xwidget-callback (xwidget-get xwidget 'callback))
 193        ;;TODO stopped working for some reason
 194        )
 195     ;;(funcall  xwidget-callback xwidget xwidget-event-type)
 196     (message "xw callback %s" xwidget)
 197     (funcall  'xwidget-webkit-callback xwidget xwidget-event-type)))
 198
 199 (defun xwidget-webkit-callback (xwidget xwidget-event-type)
 200   "Callback for xwidgets.
 201 XWIDGET instance, XWIDGET-EVENT-TYPE depends on the originating xwidget."
 202   (save-excursion
 203     (cond ((buffer-live-p (xwidget-buffer xwidget))
 204            (set-buffer (xwidget-buffer xwidget))
 205            (let* ((strarg  (nth 3 last-input-event)))
 206              (cond ((eq xwidget-event-type 'document-load-finished)
 207                     (xwidget-log "webkit finished loading: '%s'"
 208                                  (xwidget-webkit-get-title xwidget))
 209                     ;;TODO - check the native/internal scroll
 210                     ;;(xwidget-adjust-size-to-content xwidget)
 211                     (xwidget-webkit-adjust-size-dispatch) ;;TODO xwidget arg
 212                     (rename-buffer (format "*xwidget webkit: %s *"
 213                                            (xwidget-webkit-get-title xwidget)))
 214                     (pop-to-buffer (current-buffer)))
 215                    ((eq xwidget-event-type
 216                         'navigation-policy-decision-requested)
 217                     (if (string-match ".*#\\(.*\\)" strarg)
 218                         (xwidget-webkit-show-id-or-named-element
 219                          xwidget
 220                          (match-string 1 strarg))))
 221                    (t (xwidget-log "unhandled event:%s" xwidget-event-type)))))
 222           (t (xwidget-log
 223               "error: callback called for xwidget with dead buffer")))))
 224
 225 (defvar bookmark-make-record-function)
 226 (define-derived-mode xwidget-webkit-mode
 227   special-mode "xwidget-webkit" "xwidget webkit view mode"
 228   (setq buffer-read-only t)
 229   (setq-local bookmark-make-record-function
 230               #'xwidget-webkit-bookmark-make-record)
 231   ;; Keep track of [vh]scroll when switching buffers
 232   (image-mode-setup-winprops))
 233
 234 (defun xwidget-webkit-bookmark-make-record ()
 235 "Integrate Emacs bookmarks with the webkit xwidget."
 236   (nconc (bookmark-make-record-default t t)
 237          `((page     . ,(xwidget-webkit-current-url))
 238            (handler  . (lambda (bmk) (browse-url
 239                                       (bookmark-prop-get bmk 'page)))))))
 240
 241
 242 (defvar xwidget-webkit-last-session-buffer nil)
 243
 244 (defun xwidget-webkit-last-session ()
 245   "Last active webkit, or nil."
 246   (if (buffer-live-p xwidget-webkit-last-session-buffer)
 247       (with-current-buffer xwidget-webkit-last-session-buffer
 248         (xwidget-at 1))
 249     nil))
 250
 251 (defun xwidget-webkit-current-session ()
 252   "Either the webkit in the current buffer, or the last one used.
 253 The latter might be nil."
 254   (if (xwidget-at 1)
 255       (xwidget-at 1)
 256     (xwidget-webkit-last-session)))
 257
 258 (defun xwidget-adjust-size-to-content (xw)
 259   "Resize XW to content."
 260   ;; xwidgets doesn't support widgets that have their own opinions about
 261   ;; size well, yet this reads the desired size and resizes the emacs
 262   ;; allocated area accordingly.
 263   (let ((size (xwidget-size-request xw)))
 264     (xwidget-resize xw (car size) (cadr size))))
 265
 266
 267 (defvar xwidget-webkit-activeelement-js"
 268 function findactiveelement(doc){
 269 //alert(doc.activeElement.value);
 270    if(doc.activeElement.value != undefined){
 271       return doc.activeElement;
 272    }else{
 273         // recurse over the child documents:
 274         var frames = doc.getElementsByTagName('frame');
 275         for (var i = 0; i < frames.length; i++)
 276         {
 277                 var d = frames[i].contentDocument;
 278                  var rv = findactiveelement(d);
 279                  if(rv != undefined){
 280                     return rv;
 281                  }
 282         }
 283     }
 284     return undefined;
 285 };
 286
 287
 288 "
 289
 290   "javascript that finds the active element."
 291   ;; Yes it's ugly, because:
 292   ;; - there is apparently no way to find the active frame other than recursion
 293   ;; - the js "for each" construct misbehaved on the "frames" collection
 294   ;; - a window with no frameset still has frames.length == 1, but
 295   ;; frames[0].document.activeElement != document.activeElement
 296   ;;TODO the activeelement type needs to be examined, for iframe, etc.
 297   )
 298
 299 (defun xwidget-webkit-insert-string (xw str)
 300   "Insert string in the active field in the webkit.
 301 Argument XW webkit.
 302 Argument STR string."
 303   ;; Read out the string in the field first and provide for edit.
 304   (interactive
 305    (let* ((xww (xwidget-webkit-current-session))
 306
 307           (field-value
 308            (progn
 309              (xwidget-webkit-execute-script xww xwidget-webkit-activeelement-js)
 310              (xwidget-webkit-execute-script-rv
 311               xww
 312               "findactiveelement(document).value;" )))
 313           (field-type (xwidget-webkit-execute-script-rv
 314                        xww
 315                        "findactiveelement(document).type;" )))
 316      (list xww
 317            (cond ((equal "text" field-type)
 318                   (read-string "text:" field-value))
 319                  ((equal "password" field-type)
 320                   (read-passwd "password:" nil field-value))
 321                  ((equal "textarea" field-type)
 322                   (xwidget-webkit-begin-edit-textarea xww field-value))))))
 323   (xwidget-webkit-execute-script
 324    xw
 325    (format "findactiveelement(document).value='%s'" str)))
 326
 327 (defvar xwidget-xwbl)
 328 (defun xwidget-webkit-begin-edit-textarea (xw text)
 329   "Start editing of a webkit text area.
 330 XW is the xwidget identifier, TEXT is retrieved from the webkit."
 331   (switch-to-buffer
 332    (generate-new-buffer "textarea"))
 333
 334   (set (make-local-variable 'xwidget-xwbl) xw)
 335   (insert text))
 336
 337 (defun xwidget-webkit-end-edit-textarea ()
 338     "End editing of a webkit text area."
 339   (interactive)
 340   (goto-char (point-min))
 341   (while (search-forward "\n" nil t)
 342     (replace-match "\\n" nil t))
 343   (xwidget-webkit-execute-script
 344    xwidget-xwbl
 345    (format "findactiveelement(document).value='%s'"
 346            (buffer-substring (point-min) (point-max))))
 347   ;;TODO convert linefeed to \n
 348   )
 349
 350 (defun xwidget-webkit-show-named-element (xw element-name)
 351   "Make named-element show.  for instance an anchor.
 352 Argument XW is the xwidget.
 353 Argument ELEMENT-NAME is the element name to display in the webkit xwidget."
 354   (interactive (list (xwidget-webkit-current-session)
 355                      (read-string "element name:")))
 356   ;;TODO since an xwidget is an Emacs object, it is not trivial to do
 357   ;; some things that are taken for granted in a normal browser.
 358   ;; scrolling an anchor/named-element into view is one such thing.
 359   ;; This function implements a proof-of-concept for this.  Problems
 360   ;; remaining: - The selected window is scrolled but this is not
 361   ;; always correct - This needs to be interfaced into browse-url
 362   ;; somehow.  The tricky part is that we need to do this in two steps:
 363   ;; A: load the base url, wait for load signal to arrive B: navigate
 364   ;; to the anchor when the base url is finished rendering
 365
 366   ;; This part figures out the Y coordinate of the element
 367   (let ((y (string-to-number
 368             (xwidget-webkit-execute-script-rv
 369              xw
 370              (format
 371               "document.getElementsByName('%s')[0].getBoundingClientRect().top"
 372               element-name)
 373              0))))
 374     ;; Now we need to tell emacs to scroll the element into view.
 375     (xwidget-log "scroll: %d" y)
 376     (set-window-vscroll (selected-window) y t)))
 377
 378 (defun xwidget-webkit-show-id-element (xw element-id)
 379   "Make id-element show.  for instance an anchor.
 380 Argument XW is the webkit xwidget.
 381 Argument ELEMENT-ID is the id of the element to show."
 382   (interactive (list (xwidget-webkit-current-session)
 383                      (read-string "element id:")))
 384   (let ((y (string-to-number
 385             (xwidget-webkit-execute-script-rv
 386              xw
 387              (format "document.getElementById('%s').getBoundingClientRect().top"
 388                      element-id)
 389              0))))
 390     ;; Now we need to tell emacs to scroll the element into view.
 391     (xwidget-log "scroll: %d" y)
 392     (set-window-vscroll (selected-window) y t)))
 393
 394 (defun xwidget-webkit-show-id-or-named-element (xw element-id)
 395   "Make id-element show.  for instance an anchor.
 396 Argument XW is the webkit xwidget.
 397 Argument ELEMENT-ID is either a name or an element id."
 398   (interactive (list (xwidget-webkit-current-session)
 399                      (read-string "element id:")))
 400   (let* ((y1 (string-to-number
 401               (xwidget-webkit-execute-script-rv
 402                xw
 403                (format "document.getElementsByName('%s')[0].getBoundingClientRect().top" element-id)
 404                "0")))
 405          (y2 (string-to-number
 406               (xwidget-webkit-execute-script-rv
 407                xw
 408                (format "document.getElementById('%s').getBoundingClientRect().top" element-id)
 409                                                 "0")))
 410          (y3 (max y1 y2)))
 411     ;; Now we need to tell emacs to scroll the element into view.
 412     (xwidget-log "scroll: %d" y3)
 413     (set-window-vscroll (selected-window) y3 t)))
 414
 415 (defun xwidget-webkit-adjust-size-to-content ()
 416   "Adjust webkit to content size."
 417   (interactive)
 418   (xwidget-adjust-size-to-content (xwidget-webkit-current-session)))
 419
 420 (defun xwidget-webkit-adjust-size-dispatch ()
 421   "Adjust size according to mode."
 422   (interactive)
 423   (if (eq xwidget-webkit-scroll-behaviour 'native)
 424       (xwidget-webkit-adjust-size-to-window)
 425     (xwidget-webkit-adjust-size-to-content))
 426   ;; The recenter is intended to correct a visual glitch.
 427   ;; It errors out if the buffer isn't visible, but then we don't get
 428   ;; the glitch, so silence errors.
 429   (ignore-errors
 430     (recenter-top-bottom))
 431   )
 432
 433 (defun xwidget-webkit-adjust-size-to-window ()
 434   "Adjust webkit to window."
 435   (interactive)
 436   (xwidget-resize ( xwidget-webkit-current-session) (window-pixel-width)
 437                   (window-pixel-height)))
 438
 439 (defun xwidget-webkit-adjust-size (w h)
 440   "Manually set webkit size.
 441 Argument W width.
 442 Argument H height."
 443   ;; TODO shouldn't be tied to the webkit xwidget
 444   (interactive "nWidth:\nnHeight:\n")
 445   (xwidget-resize ( xwidget-webkit-current-session) w h))
 446
 447 (defun xwidget-webkit-fit-width ()
 448   "Adjust width of webkit to window width."
 449   (interactive)
 450   (xwidget-webkit-adjust-size (- (nth 2 (window-inside-pixel-edges))
 451                                  (car (window-inside-pixel-edges)))
 452                               1000))
 453
 454 (defun xwidget-webkit-new-session (url)
 455   "Create a new webkit session buffer with URL."
 456   (let*
 457       ((bufname (generate-new-buffer-name "*xwidget-webkit*"))
 458        xw)
 459     (setq xwidget-webkit-last-session-buffer (switch-to-buffer
 460                                               (get-buffer-create bufname)))
 461     (insert " 'a' adjusts the xwidget size.")
 462     (setq xw (xwidget-insert 1 'webkit-osr  bufname 1000 1000))
 463     (xwidget-put xw 'callback 'xwidget-webkit-callback)
 464     (xwidget-webkit-mode)
 465     (xwidget-webkit-goto-uri (xwidget-webkit-last-session) url )))
 466
 467
 468 (defun xwidget-webkit-goto-url (url)
 469   "Goto URL."
 470   (if (xwidget-webkit-current-session)
 471       (progn
 472         (xwidget-webkit-goto-uri (xwidget-webkit-current-session) url))
 473     (xwidget-webkit-new-session url)))
 474
 475 (defun xwidget-webkit-back ()
 476   "Back in history."
 477   (interactive)
 478   (xwidget-webkit-execute-script (xwidget-webkit-current-session)
 479                                  "history.go(-1);"))
 480
 481 (defun xwidget-webkit-reload ()
 482   "Reload current url."
 483   (interactive)
 484   (xwidget-webkit-execute-script (xwidget-webkit-current-session)
 485                                  "history.go(0);"))
 486
 487 (defun xwidget-webkit-current-url ()
 488   "Get the webkit url.  place it on kill ring."
 489   (interactive)
 490   (let* ((rv (xwidget-webkit-execute-script-rv (xwidget-webkit-current-session)
 491                                                "document.URL"))
 492          (url (kill-new (or rv ""))))
 493     (message "url: %s" url )
 494     url))
 495
 496 (defun xwidget-webkit-execute-script-rv (xw script &optional default)
 497   "Same as 'xwidget-webkit-execute-script' but but with return value.
 498 XW is the webkit instance.  SCRIPT is the script to execute.
 499 DEFAULT is the defaultreturn value."
 500   ;; Notice the ugly "title" hack.  It is needed because the Webkit
 501   ;; API at the time of writing didn't support returning values.  This
 502   ;; is a wrapper for the title hack so it's easy to remove should
 503   ;; Webkit someday support JS return values or we find some other way
 504   ;; to access the DOM.
 505
 506   ;; Reset webkit title.  Not very nice.
 507   (let* ((emptytag "titlecantbewhitespaceohthehorror")
 508          title)
 509     (xwidget-webkit-execute-script xw (format "document.title=\"%s\";"
 510                                               (or default emptytag)))
 511     (xwidget-webkit-execute-script xw (format "document.title=%s;" script))
 512     (setq title (xwidget-webkit-get-title xw))
 513     (if (equal emptytag title)
 514         (setq title ""))
 515     (unless title
 516       (setq title default))
 517     title))
 518
 519 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 520 (defun xwidget-webkit-get-selection ()
 521   "Get the webkit selection."
 522   (xwidget-webkit-execute-script-rv (xwidget-webkit-current-session)
 523                                     "window.getSelection().toString();"))
 524
 525 (defun xwidget-webkit-copy-selection-as-kill ()
 526   "Get the webkit selection and put it on the kill ring."
 527   (interactive)
 528   (kill-new (xwidget-webkit-get-selection)))
 529
 530
 531 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 532 ;; Xwidget plist management (similar to the process plist functions)
 533
 534 (defun xwidget-get (xwidget propname)
 535   "Return the value of XWIDGET' PROPNAME property.
 536 This is the last value stored with `(xwidget-put XWIDGET PROPNAME VALUE)'."
 537   (plist-get (xwidget-plist xwidget) propname))
 538
 539 (defun xwidget-put (xwidget propname value)
 540   "Change XWIDGET' PROPNAME property to VALUE.
 541 It can be retrieved with `(xwidget-get XWIDGET PROPNAME)'."
 542   (set-xwidget-plist xwidget
 543                      (plist-put (xwidget-plist xwidget) propname value)))
 544
 545
 546 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 547
 548 (defvar xwidget-view-list)              ; xwidget.c
 549 (defvar xwidget-list)                   ; xwidget.c
 550
 551 (defun xwidget-delete-zombies ()
 552   "Helper for `xwidget-cleanup'."
 553   (dolist (xwidget-view xwidget-view-list)
 554     (when (or (not (window-live-p (xwidget-view-window xwidget-view)))
 555               (not (memq (xwidget-view-model xwidget-view)
 556                          xwidget-list)))
 557       (delete-xwidget-view xwidget-view))))
 558
 559 (defun xwidget-cleanup ()
 560   "Delete zombie xwidgets."
 561   ;; During development it was sometimes easy to wind up with zombie
 562   ;; xwidget instances.
 563   ;; This function tries to implement a workaround should it occur again.
 564   (interactive)
 565   ;; Kill xviews that should have been deleted but still linger.
 566   (xwidget-delete-zombies)
 567   ;; Redraw display otherwise ghost of zombies will remain to haunt the screen
 568   (redraw-display))
 569
 570 ;; This would have felt better in C, but this seems to work well in
 571 ;; practice though.
 572 (if (featurep 'xwidget-internal)
 573     (add-hook 'window-configuration-change-hook 'xwidget-delete-zombies))
 574
 575 (defun xwidget-kill-buffer-query-function ()
 576   "Ask before killing a buffer that has xwidgets."
 577   (let ((xwidgets (get-buffer-xwidgets (current-buffer))))
 578     (or (not xwidgets)
 579         (not (memq t (mapcar 'xwidget-query-on-exit-flag xwidgets)))
 580         (yes-or-no-p
 581          (format "Buffer %S has xwidgets; kill it? "
 582                  (buffer-name (current-buffer)))))))
 583
 584 (if (featurep 'xwidget-internal)
 585     (add-hook 'kill-buffer-query-functions 'xwidget-kill-buffer-query-function))
 586
 587 (provide 'xwidget)
 588
 589 ;;; xwidget.el ends here