code.delx.au - gnu-emacs/blob - lisp/tar-mode.el

   1 ;;; tar-mode.el --- simple editing of tar files from GNU emacs
   2
   3 ;; Copyright (C) 1990, 1991, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4 ;;   2000, 2001, 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Jamie Zawinski <jwz@lucid.com>
   7 ;; Maintainer: FSF
   8 ;; Created: 04 Apr 1990
   9 ;; Keywords: unix
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package attempts to make dealing with Unix 'tar' archives easier.
  31 ;; When this code is loaded, visiting a file whose name ends in '.tar' will
  32 ;; cause the contents of that archive file to be displayed in a Dired-like
  33 ;; listing.  It is then possible to use the customary Dired keybindings to
  34 ;; extract sub-files from that archive, either by reading them into their own
  35 ;; editor buffers, or by copying them directly to arbitrary files on disk.
  36 ;; It is also possible to delete sub-files from within the tar file and write
  37 ;; the modified archive back to disk, or to edit sub-files within the archive
  38 ;; and re-insert the modified files into the archive.  See the documentation
  39 ;; string of tar-mode for more info.
  40
  41 ;; This code now understands the extra fields that GNU tar adds to tar files.
  42
  43 ;; This interacts correctly with "uncompress.el" in the Emacs library,
  44 ;; which you get with
  45 ;;
  46 ;;  (autoload 'uncompress-while-visiting "uncompress")
  47 ;;  (setq auto-mode-alist (cons '("\\.Z$" . uncompress-while-visiting)
  48 ;;                         auto-mode-alist))
  49 ;;
  50 ;; Do not attempt to use tar-mode.el with crypt.el, you will lose.
  51
  52 ;;    ***************   TO DO   ***************
  53 ;;
  54 ;; o  chmod should understand "a+x,og-w".
  55 ;;
  56 ;; o  It's not possible to add a NEW file to a tar archive; not that
  57 ;;    important, but still...
  58 ;;
  59 ;; o  The code is less efficient that it could be - in a lot of places, I
  60 ;;    pull a 512-character string out of the buffer and parse it, when I could
  61 ;;    be parsing it in place, not garbaging a string.  Should redo that.
  62 ;;
  63 ;; o  I'd like a command that searches for a string/regexp in every subfile
  64 ;;    of an archive, where <esc> would leave you in a subfile-edit buffer.
  65 ;;    (Like the Meta-R command of the Zmacs mail reader.)
  66 ;;
  67 ;; o  Sometimes (but not always) reverting the tar-file buffer does not
  68 ;;    re-grind the listing, and you are staring at the binary tar data.
  69 ;;    Typing 'g' again immediately after that will always revert and re-grind
  70 ;;    it, though.  I have no idea why this happens.
  71 ;;
  72 ;; o  Tar-mode interacts poorly with crypt.el and zcat.el because the tar
  73 ;;    write-file-hook actually writes the file.  Instead it should remove the
  74 ;;    header (and conspire to put it back afterwards) so that other write-file
  75 ;;    hooks which frob the buffer have a chance to do their dirty work.  There
  76 ;;    might be a problem if the tar write-file-hook does not come *first* on
  77 ;;    the list.
  78 ;;
  79 ;; o  Block files, sparse files, continuation files, and the various header
  80 ;;    types aren't editable.  Actually I don't know that they work at all.
  81
  82 ;; Rationale:
  83
  84 ;; Why does tar-mode edit the file itself instead of using tar?
  85
  86 ;; That means that you can edit tar files which you don't have room for
  87 ;; on your local disk.
  88
  89 ;; I don't know about recent features in gnu tar, but old versions of tar
  90 ;; can't replace a file in the middle of a tar file with a new version.
  91 ;; Tar-mode can.  I don't think tar can do things like chmod the subfiles.
  92 ;; An implementation which involved unpacking and repacking the file into
  93 ;; some scratch directory would be very wasteful, and wouldn't be able to
  94 ;; preserve the file owners.
  95
  96 ;;; Code:
  97
  98 (defgroup tar nil
  99   "Simple editing of tar files."
 100   :prefix "tar-"
 101   :group 'data)
 102
 103 (defcustom tar-anal-blocksize 20
 104   "The blocksize of tar files written by Emacs, or nil, meaning don't care.
 105 The blocksize of a tar file is not really the size of the blocks; rather, it is
 106 the number of blocks written with one system call.  When tarring to a tape,
 107 this is the size of the *tape* blocks, but when writing to a file, it doesn't
 108 matter much.  The only noticeable difference is that if a tar file does not
 109 have a blocksize of 20, tar will tell you that; all this really controls is
 110 how many null padding bytes go on the end of the tar file."
 111   :type '(choice integer (const nil))
 112   :group 'tar)
 113
 114 (defcustom tar-update-datestamp nil
 115   "Non-nil means Tar mode should play fast and loose with sub-file datestamps.
 116 If this is true, then editing and saving a tar file entry back into its
 117 tar file will update its datestamp.  If false, the datestamp is unchanged.
 118 You may or may not want this - it is good in that you can tell when a file
 119 in a tar archive has been changed, but it is bad for the same reason that
 120 editing a file in the tar archive at all is bad - the changed version of
 121 the file never exists on disk."
 122   :type 'boolean
 123   :group 'tar)
 124
 125 (defcustom tar-mode-show-date nil
 126   "Non-nil means Tar mode should show the date/time of each subfile.
 127 This information is useful, but it takes screen space away from file names."
 128   :type 'boolean
 129   :group 'tar)
 130
 131 (defvar tar-parse-info nil)
 132 ;; Be sure that this variable holds byte position, not char position.
 133 (defvar tar-header-offset nil)
 134 (defvar tar-superior-buffer nil)
 135 (defvar tar-superior-descriptor nil)
 136 (defvar tar-subfile-mode nil)
 137
 138 (put 'tar-parse-info 'permanent-local t)
 139 (put 'tar-header-offset 'permanent-local t)
 140 (put 'tar-superior-buffer 'permanent-local t)
 141 (put 'tar-superior-descriptor 'permanent-local t)
 142 \f
 143 (defmacro tar-setf (form val)
 144   "A mind-numbingly simple implementation of setf."
 145   (let ((mform (macroexpand form (and (boundp 'byte-compile-macro-environment)
 146                                       byte-compile-macro-environment))))
 147     (cond ((symbolp mform) (list 'setq mform val))
 148           ((not (consp mform)) (error "can't setf %s" form))
 149           ((eq (car mform) 'aref)
 150            (list 'aset (nth 1 mform) (nth 2 mform) val))
 151           ((eq (car mform) 'car)
 152            (list 'setcar (nth 1 mform) val))
 153           ((eq (car mform) 'cdr)
 154            (list 'setcdr (nth 1 mform) val))
 155           (t (error "don't know how to setf %s" form)))))
 156 \f
 157 ;;; down to business.
 158
 159 (defmacro make-tar-header (name mode uid git size date ck lt ln
 160                            magic uname gname devmaj devmin)
 161   (list 'vector name mode uid git size date ck lt ln
 162         magic uname gname devmaj devmin))
 163
 164 (defmacro tar-header-name (x) (list 'aref x 0))
 165 (defmacro tar-header-mode (x) (list 'aref x 1))
 166 (defmacro tar-header-uid  (x) (list 'aref x 2))
 167 (defmacro tar-header-gid  (x) (list 'aref x 3))
 168 (defmacro tar-header-size (x) (list 'aref x 4))
 169 (defmacro tar-header-date (x) (list 'aref x 5))
 170 (defmacro tar-header-checksum  (x) (list 'aref x 6))
 171 (defmacro tar-header-link-type (x) (list 'aref x 7))
 172 (defmacro tar-header-link-name (x) (list 'aref x 8))
 173 (defmacro tar-header-magic (x) (list 'aref x 9))
 174 (defmacro tar-header-uname (x) (list 'aref x 10))
 175 (defmacro tar-header-gname (x) (list 'aref x 11))
 176 (defmacro tar-header-dmaj (x) (list 'aref x 12))
 177 (defmacro tar-header-dmin (x) (list 'aref x 13))
 178
 179 (defmacro make-tar-desc (data-start tokens)
 180   (list 'cons data-start tokens))
 181
 182 (defmacro tar-desc-data-start (x) (list 'car x))
 183 (defmacro tar-desc-tokens     (x) (list 'cdr x))
 184
 185 (defconst tar-name-offset 0)
 186 (defconst tar-mode-offset (+ tar-name-offset 100))
 187 (defconst tar-uid-offset  (+ tar-mode-offset 8))
 188 (defconst tar-gid-offset  (+ tar-uid-offset 8))
 189 (defconst tar-size-offset (+ tar-gid-offset 8))
 190 (defconst tar-time-offset (+ tar-size-offset 12))
 191 (defconst tar-chk-offset  (+ tar-time-offset 12))
 192 (defconst tar-linkp-offset (+ tar-chk-offset 8))
 193 (defconst tar-link-offset (+ tar-linkp-offset 1))
 194 ;;; GNU-tar specific slots.
 195 (defconst tar-magic-offset (+ tar-link-offset 100))
 196 (defconst tar-uname-offset (+ tar-magic-offset 8))
 197 (defconst tar-gname-offset (+ tar-uname-offset 32))
 198 (defconst tar-dmaj-offset (+ tar-gname-offset 32))
 199 (defconst tar-dmin-offset (+ tar-dmaj-offset 8))
 200 (defconst tar-end-offset (+ tar-dmin-offset 8))
 201
 202 (defun tar-header-block-tokenize (string)
 203   "Return a `tar-header' structure.
 204 This is a list of name, mode, uid, gid, size,
 205 write-date, checksum, link-type, and link-name."
 206   (cond ((< (length string) 512) nil)
 207         (;(some 'plusp string)           ; <-- oops, massive cycle hog!
 208          (or (not (= 0 (aref string 0))) ; This will do.
 209              (not (= 0 (aref string 101))))
 210          (let* ((name-end (1- tar-mode-offset))
 211                 (link-end (1- tar-magic-offset))
 212                 (uname-end (1- tar-gname-offset))
 213                 (gname-end (1- tar-dmaj-offset))
 214                 (link-p (aref string tar-linkp-offset))
 215                 (magic-str (substring string tar-magic-offset (1- tar-uname-offset)))
 216                 (uname-valid-p (or (string= "ustar  " magic-str) (string= "GNUtar " magic-str)))
 217                 name linkname
 218                 (nulsexp   "[^\000]*\000"))
 219            (when (string-match nulsexp string tar-name-offset)
 220              (setq name-end (min name-end (1- (match-end 0)))))
 221            (when (string-match nulsexp string tar-link-offset)
 222              (setq link-end (min link-end (1- (match-end 0)))))
 223            (when (string-match nulsexp string tar-uname-offset)
 224              (setq uname-end (min uname-end (1- (match-end 0)))))
 225            (when (string-match nulsexp string tar-gname-offset)
 226              (setq gname-end (min gname-end (1- (match-end 0)))))
 227            (setq name (substring string tar-name-offset name-end)
 228                  link-p (if (or (= link-p 0) (= link-p ?0))
 229                             nil
 230                           (- link-p ?0)))
 231            (setq linkname (substring string tar-link-offset link-end))
 232            (if default-enable-multibyte-characters
 233                (setq name
 234                      (decode-coding-string name
 235                                            (or file-name-coding-system
 236                                                default-file-name-coding-system
 237                                                'undecided))
 238                      linkname
 239                      (decode-coding-string linkname
 240                                            (or file-name-coding-system
 241                                                default-file-name-coding-system
 242                                                'undecided))))
 243            (if (and (null link-p) (string-match "/\\'" name)) (setq link-p 5)) ; directory
 244            (make-tar-header
 245              name
 246              (tar-parse-octal-integer string tar-mode-offset tar-uid-offset)
 247              (tar-parse-octal-integer string tar-uid-offset tar-gid-offset)
 248              (tar-parse-octal-integer string tar-gid-offset tar-size-offset)
 249              (tar-parse-octal-integer string tar-size-offset tar-time-offset)
 250              (tar-parse-octal-long-integer string tar-time-offset tar-chk-offset)
 251              (tar-parse-octal-integer string tar-chk-offset tar-linkp-offset)
 252              link-p
 253              linkname
 254              uname-valid-p
 255              (and uname-valid-p (substring string tar-uname-offset uname-end))
 256              (and uname-valid-p (substring string tar-gname-offset gname-end))
 257              (tar-parse-octal-integer string tar-dmaj-offset tar-dmin-offset)
 258              (tar-parse-octal-integer string tar-dmin-offset tar-end-offset)
 259              )))
 260         (t 'empty-tar-block)))
 261
 262
 263 (defun tar-parse-octal-integer (string &optional start end)
 264   (if (null start) (setq start 0))
 265   (if (null end) (setq end (length string)))
 266   (if (= (aref string start) 0)
 267       0
 268     (let ((n 0))
 269       (while (< start end)
 270         (setq n (if (< (aref string start) ?0) n
 271                   (+ (* n 8) (- (aref string start) ?0)))
 272               start (1+ start)))
 273       n)))
 274
 275 (defun tar-parse-octal-long-integer (string &optional start end)
 276   (if (null start) (setq start 0))
 277   (if (null end) (setq end (length string)))
 278   (if (= (aref string start) 0)
 279       (list 0 0)
 280     (let ((lo 0)
 281           (hi 0))
 282       (while (< start end)
 283         (if (>= (aref string start) ?0)
 284             (setq lo (+ (* lo 8) (- (aref string start) ?0))
 285                   hi (+ (* hi 8) (ash lo -16))
 286                   lo (logand lo 65535)))
 287         (setq start (1+ start)))
 288       (list hi lo))))
 289
 290 (defun tar-parse-octal-integer-safe (string)
 291   (if (zerop (length string)) (error "empty string"))
 292   (mapc (lambda (c)
 293           (if (or (< c ?0) (> c ?7))
 294               (error "`%c' is not an octal digit" c)))
 295         string)
 296   (tar-parse-octal-integer string))
 297
 298
 299 (defun tar-header-block-checksum (string)
 300   "Compute and return a tar-acceptable checksum for this block."
 301   (let* ((chk-field-start tar-chk-offset)
 302          (chk-field-end (+ chk-field-start 8))
 303          (sum 0)
 304          (i 0))
 305     ;; Add up all of the characters except the ones in the checksum field.
 306     ;; Add that field as if it were filled with spaces.
 307     (while (< i chk-field-start)
 308       (setq sum (+ sum (aref string i))
 309             i (1+ i)))
 310     (setq i chk-field-end)
 311     (while (< i 512)
 312       (setq sum (+ sum (aref string i))
 313             i (1+ i)))
 314     (+ sum (* 32 8))))
 315
 316 (defun tar-header-block-check-checksum (hblock desired-checksum file-name)
 317   "Beep and print a warning if the checksum doesn't match."
 318   (if (not (= desired-checksum (tar-header-block-checksum hblock)))
 319       (progn (beep) (message "Invalid checksum for file %s!" file-name))))
 320
 321 (defun tar-clip-time-string (time)
 322   (let ((str (current-time-string time)))
 323     (concat " " (substring str 4 16) (substring str 19 24))))
 324
 325 (defun tar-grind-file-mode (mode)
 326   "Construct a `-rw--r--r--' string indicating MODE.
 327 MODE should be an integer which is a file mode value."
 328   (string
 329    (if (zerop (logand 256 mode)) ?- ?r)
 330    (if (zerop (logand 128 mode)) ?- ?w)
 331    (if (zerop (logand 1024 mode)) (if (zerop (logand  64 mode)) ?- ?x) ?s)
 332    (if (zerop (logand  32 mode)) ?- ?r)
 333    (if (zerop (logand  16 mode)) ?- ?w)
 334    (if (zerop (logand 2048 mode)) (if (zerop (logand   8 mode)) ?- ?x) ?s)
 335    (if (zerop (logand   4 mode)) ?- ?r)
 336    (if (zerop (logand   2 mode)) ?- ?w)
 337    (if (zerop (logand   1 mode)) ?- ?x)))
 338
 339 (defun tar-header-block-summarize (tar-hblock &optional mod-p)
 340   "Return a line similar to the output of `tar -vtf'."
 341   (let ((name (tar-header-name tar-hblock))
 342         (mode (tar-header-mode tar-hblock))
 343         (uid (tar-header-uid tar-hblock))
 344         (gid (tar-header-gid tar-hblock))
 345         (uname (tar-header-uname tar-hblock))
 346         (gname (tar-header-gname tar-hblock))
 347         (size (tar-header-size tar-hblock))
 348         (time (tar-header-date tar-hblock))
 349         ;; (ck (tar-header-checksum tar-hblock))
 350         (type (tar-header-link-type tar-hblock))
 351         (link-name (tar-header-link-name tar-hblock)))
 352     (format "%c%c%s%8s/%-8s%7s%s %s%s"
 353             (if mod-p ?* ? )
 354             (cond ((or (eq type nil) (eq type 0)) ?-)
 355                   ((eq type 1) ?h)      ; link
 356                   ((eq type 2) ?l)      ; symlink
 357                   ((eq type 3) ?c)      ; char special
 358                   ((eq type 4) ?b)      ; block special
 359                   ((eq type 5) ?d)      ; directory
 360                   ((eq type 6) ?p)      ; FIFO/pipe
 361                   ((eq type 20) ?*)     ; directory listing
 362                   ((eq type 28) ?L)     ; next has longname
 363                   ((eq type 29) ?M)     ; multivolume continuation
 364                   ((eq type 35) ?S)     ; sparse
 365                   ((eq type 38) ?V)     ; volume header
 366                   (t ?\ )
 367                   )
 368             (tar-grind-file-mode mode)
 369             (if (= 0 (length uname)) uid uname)
 370             (if (= 0 (length gname)) gid gname)
 371             size
 372             (if tar-mode-show-date (tar-clip-time-string time) "")
 373             (propertize name
 374                         'mouse-face 'highlight
 375                         'help-echo "mouse-2: extract this file into a buffer")
 376             (if (or (eq type 1) (eq type 2))
 377                 (concat (if (= type 1) " ==> " " --> ") link-name)
 378               ""))))
 379
 380 (defun tar-untar-buffer ()
 381   "Extract all archive members in the tar-file into the current directory."
 382   (interactive)
 383   (let ((multibyte enable-multibyte-characters))
 384     (unwind-protect
 385         (save-restriction
 386           (widen)
 387           (set-buffer-multibyte nil)
 388           (dolist (descriptor tar-parse-info)
 389             (let* ((tokens (tar-desc-tokens descriptor))
 390                    (name (tar-header-name tokens))
 391                    (dir (file-name-directory name))
 392                    (start (+ (tar-desc-data-start descriptor)
 393                              (- tar-header-offset (point-min))))
 394                    (end (+ start (tar-header-size tokens))))
 395               (unless (file-directory-p name)
 396                 (message "Extracting %s" name)
 397                 (if (and dir (not (file-exists-p dir)))
 398                     (make-directory dir t))
 399                 (unless (file-directory-p name)
 400                   (write-region start end name))
 401                 (set-file-modes name (tar-header-mode tokens))))))
 402       (set-buffer-multibyte multibyte))))
 403
 404 (defun tar-summarize-buffer ()
 405   "Parse the contents of the tar file in the current buffer.
 406 Place a dired-like listing on the front;
 407 then narrow to it, so that only that listing
 408 is visible (and the real data of the buffer is hidden)."
 409   (let ((modified (buffer-modified-p)))
 410     (set-buffer-multibyte nil)
 411     (let* ((result '())
 412            (pos (point-min))
 413            (progress-reporter
 414             (make-progress-reporter "Parsing tar file..."
 415                                     (point-min) (max 1 (- (buffer-size) 1024))))
 416            tokens)
 417       (while (and (<= (+ pos 512) (point-max))
 418                   (not (eq 'empty-tar-block
 419                            (setq tokens
 420                                  (tar-header-block-tokenize
 421                                   (buffer-substring pos (+ pos 512)))))))
 422         (setq pos (+ pos 512))
 423         (progress-reporter-update progress-reporter pos)
 424         (if (eq (tar-header-link-type tokens) 20)
 425             ;; Foo.  There's an extra empty block after these.
 426             (setq pos (+ pos 512)))
 427         (let ((size (tar-header-size tokens)))
 428           (if (< size 0)
 429               (error "%s has size %s - corrupted"
 430                      (tar-header-name tokens) size))
 431                                         ;
 432                                         ; This is just too slow.  Don't really need it anyway....
 433                                         ;(tar-header-block-check-checksum
 434                                         ;  hblock (tar-header-block-checksum hblock)
 435                                         ;  (tar-header-name tokens))
 436
 437           (push (make-tar-desc pos tokens) result)
 438
 439           (and (null (tar-header-link-type tokens))
 440                (> size 0)
 441                (setq pos
 442                      (+ pos 512 (ash (ash (1- size) -9) 9)) ; this works
 443                                         ;(+ pos (+ size (- 512 (rem (1- size) 512)))) ; this doesn't
 444                      ))))
 445       (make-local-variable 'tar-parse-info)
 446       (setq tar-parse-info (nreverse result))
 447       ;; A tar file should end with a block or two of nulls,
 448       ;; but let's not get a fatal error if it doesn't.
 449       (if (eq tokens 'empty-tar-block)
 450           (progress-reporter-done progress-reporter)
 451         (message "Warning: premature EOF parsing tar file")))
 452     (set-buffer-multibyte default-enable-multibyte-characters)
 453     (goto-char (point-min))
 454     (let ((inhibit-read-only t))
 455       ;; Collect summary lines and insert them all at once since tar files
 456       ;; can be pretty big.
 457       (let ((total-summaries
 458              (mapconcat
 459               (lambda (tar-desc)
 460                 (tar-header-block-summarize (tar-desc-tokens tar-desc)))
 461               tar-parse-info
 462               "\n")))
 463         (insert total-summaries "\n"))
 464       (narrow-to-region (point-min) (point))
 465       (set (make-local-variable 'tar-header-offset) (position-bytes (point)))
 466       (goto-char (point-min))
 467       (restore-buffer-modified-p modified))))
 468 \f
 469 (defvar tar-mode-map
 470   (let ((map (make-keymap)))
 471     (suppress-keymap map)
 472     (define-key map " " 'tar-next-line)
 473     (define-key map "C" 'tar-copy)
 474     (define-key map "d" 'tar-flag-deleted)
 475     (define-key map "\^D" 'tar-flag-deleted)
 476     (define-key map "e" 'tar-extract)
 477     (define-key map "f" 'tar-extract)
 478     (define-key map "\C-m" 'tar-extract)
 479     (define-key map [mouse-2] 'tar-mouse-extract)
 480     (define-key map "g" 'revert-buffer)
 481     (define-key map "h" 'describe-mode)
 482     (define-key map "n" 'tar-next-line)
 483     (define-key map "\^N" 'tar-next-line)
 484     (define-key map [down] 'tar-next-line)
 485     (define-key map "o" 'tar-extract-other-window)
 486     (define-key map "p" 'tar-previous-line)
 487     (define-key map "q" 'quit-window)
 488     (define-key map "\^P" 'tar-previous-line)
 489     (define-key map [up] 'tar-previous-line)
 490     (define-key map "R" 'tar-rename-entry)
 491     (define-key map "u" 'tar-unflag)
 492     (define-key map "v" 'tar-view)
 493     (define-key map "x" 'tar-expunge)
 494     (define-key map "\177" 'tar-unflag-backwards)
 495     (define-key map "E" 'tar-extract-other-window)
 496     (define-key map "M" 'tar-chmod-entry)
 497     (define-key map "G" 'tar-chgrp-entry)
 498     (define-key map "O" 'tar-chown-entry)
 499
 500     ;; Make menu bar items.
 501
 502     ;; Get rid of the Edit menu bar item to save space.
 503     (define-key map [menu-bar edit] 'undefined)
 504
 505     (define-key map [menu-bar immediate]
 506       (cons "Immediate" (make-sparse-keymap "Immediate")))
 507
 508     (define-key map [menu-bar immediate view]
 509       '("View This File" . tar-view))
 510     (define-key map [menu-bar immediate display]
 511       '("Display in Other Window" . tar-display-other-window))
 512     (define-key map [menu-bar immediate find-file-other-window]
 513       '("Find in Other Window" . tar-extract-other-window))
 514     (define-key map [menu-bar immediate find-file]
 515       '("Find This File" . tar-extract))
 516
 517     (define-key map [menu-bar mark]
 518       (cons "Mark" (make-sparse-keymap "Mark")))
 519
 520     (define-key map [menu-bar mark unmark-all]
 521       '("Unmark All" . tar-clear-modification-flags))
 522     (define-key map [menu-bar mark deletion]
 523       '("Flag" . tar-flag-deleted))
 524     (define-key map [menu-bar mark unmark]
 525       '("Unflag" . tar-unflag))
 526
 527     (define-key map [menu-bar operate]
 528       (cons "Operate" (make-sparse-keymap "Operate")))
 529
 530     (define-key map [menu-bar operate chown]
 531       '("Change Owner..." . tar-chown-entry))
 532     (define-key map [menu-bar operate chgrp]
 533       '("Change Group..." . tar-chgrp-entry))
 534     (define-key map [menu-bar operate chmod]
 535       '("Change Mode..." . tar-chmod-entry))
 536     (define-key map [menu-bar operate rename]
 537       '("Rename to..." . tar-rename-entry))
 538     (define-key map [menu-bar operate copy]
 539       '("Copy to..." . tar-copy))
 540     (define-key map [menu-bar operate expunge]
 541       '("Expunge Marked Files" . tar-expunge))
 542
 543     map)
 544   "Local keymap for Tar mode listings.")
 545
 546 \f
 547 ;; tar mode is suitable only for specially formatted data.
 548 (put 'tar-mode 'mode-class 'special)
 549 (put 'tar-subfile-mode 'mode-class 'special)
 550
 551 ;;;###autoload
 552 (define-derived-mode tar-mode nil "Tar"
 553   "Major mode for viewing a tar file as a dired-like listing of its contents.
 554 You can move around using the usual cursor motion commands.
 555 Letters no longer insert themselves.
 556 Type `e' to pull a file out of the tar file and into its own buffer;
 557 or click mouse-2 on the file's line in the Tar mode buffer.
 558 Type `c' to copy an entry from the tar file into another file on disk.
 559
 560 If you edit a sub-file of this archive (as with the `e' command) and
 561 save it with \\[save-buffer], the contents of that buffer will be
 562 saved back into the tar-file buffer; in this way you can edit a file
 563 inside of a tar archive without extracting it and re-archiving it.
 564
 565 See also: variables `tar-update-datestamp' and `tar-anal-blocksize'.
 566 \\{tar-mode-map}"
 567   ;; this is not interactive because you shouldn't be turning this
 568   ;; mode on and off.  You can corrupt things that way.
 569   ;; rms: with permanent locals, it should now be possible to make this work
 570   ;; interactively in some reasonable fashion.
 571   (make-local-variable 'tar-header-offset)
 572   (make-local-variable 'tar-parse-info)
 573   (set (make-local-variable 'require-final-newline) nil) ; binary data, dude...
 574   (set (make-local-variable 'revert-buffer-function) 'tar-mode-revert)
 575   (set (make-local-variable 'local-enable-local-variables) nil)
 576   (set (make-local-variable 'next-line-add-newlines) nil)
 577   ;; Prevent loss of data when saving the file.
 578   (set (make-local-variable 'file-precious-flag) t)
 579   (auto-save-mode 0)
 580   (set (make-local-variable 'write-contents-functions) '(tar-mode-write-file))
 581   (buffer-disable-undo)
 582   (widen)
 583   (if (and (boundp 'tar-header-offset) tar-header-offset)
 584       (narrow-to-region (point-min) (byte-to-position tar-header-offset))
 585     (tar-summarize-buffer)
 586     (tar-next-line 0)))
 587
 588
 589 (defun tar-subfile-mode (p)
 590   "Minor mode for editing an element of a tar-file.
 591 This mode arranges for \"saving\" this buffer to write the data
 592 into the tar-file buffer that it came from.  The changes will actually
 593 appear on disk when you save the tar-file's buffer."
 594   (interactive "P")
 595   (or (and (boundp 'tar-superior-buffer) tar-superior-buffer)
 596       (error "This buffer is not an element of a tar file"))
 597   ;; Don't do this, because it is redundant and wastes mode line space.
 598   ;;  (or (assq 'tar-subfile-mode minor-mode-alist)
 599   ;;      (setq minor-mode-alist (append minor-mode-alist
 600   ;;                                 (list '(tar-subfile-mode " TarFile")))))
 601   (make-local-variable 'tar-subfile-mode)
 602   (setq tar-subfile-mode
 603         (if (null p)
 604             (not tar-subfile-mode)
 605             (> (prefix-numeric-value p) 0)))
 606   (cond (tar-subfile-mode
 607          (add-hook 'write-file-functions 'tar-subfile-save-buffer nil t)
 608          ;; turn off auto-save.
 609          (auto-save-mode -1)
 610          (setq buffer-auto-save-file-name nil)
 611          (run-hooks 'tar-subfile-mode-hook))
 612         (t
 613          (remove-hook 'write-file-functions 'tar-subfile-save-buffer t))))
 614
 615
 616 ;; Revert the buffer and recompute the dired-like listing.
 617 (defun tar-mode-revert (&optional no-auto-save no-confirm)
 618   (let ((revert-buffer-function nil)
 619         (old-offset tar-header-offset)
 620         success)
 621     (setq tar-header-offset nil)
 622     (unwind-protect
 623         (and (revert-buffer t no-confirm)
 624              (progn (widen)
 625                     (setq success t)
 626                     (tar-mode)))
 627       ;; If the revert was canceled,
 628       ;; put back the old value of tar-header-offset.
 629       (or success
 630           (setq tar-header-offset old-offset)))))
 631
 632
 633 (defun tar-next-line (arg)
 634   "Move cursor vertically down ARG lines and to the start of the filename."
 635   (interactive "p")
 636   (forward-line arg)
 637   (if (eobp) nil (forward-char (if tar-mode-show-date 54 36))))
 638
 639 (defun tar-previous-line (arg)
 640   "Move cursor vertically up ARG lines and to the start of the filename."
 641   (interactive "p")
 642   (tar-next-line (- arg)))
 643
 644 (defun tar-current-descriptor (&optional noerror)
 645   "Return the tar-descriptor of the current line, or signals an error."
 646   ;; I wish lines had plists, like in ZMACS...
 647   (or (nth (count-lines (point-min)
 648                         (save-excursion (beginning-of-line) (point)))
 649            tar-parse-info)
 650       (if noerror
 651           nil
 652           (error "This line does not describe a tar-file entry"))))
 653
 654 (defun tar-get-descriptor ()
 655   (let* ((descriptor (tar-current-descriptor))
 656          (tokens (tar-desc-tokens descriptor))
 657          (size (tar-header-size tokens))
 658          (link-p (tar-header-link-type tokens)))
 659     (if link-p
 660         (error "This is a %s, not a real file"
 661                (cond ((eq link-p 5) "directory")
 662                      ((eq link-p 20) "tar directory header")
 663                      ((eq link-p 28) "next has longname")
 664                      ((eq link-p 29) "multivolume-continuation")
 665                      ((eq link-p 35) "sparse entry")
 666                      ((eq link-p 38) "volume header")
 667                      (t "link"))))
 668     (if (zerop size) (error "This is a zero-length file"))
 669     descriptor))
 670
 671 (defun tar-mouse-extract (event)
 672   "Extract a file whose tar directory line you click on."
 673   (interactive "e")
 674   (save-excursion
 675     (set-buffer (window-buffer (posn-window (event-end event))))
 676     (save-excursion
 677       (goto-char (posn-point (event-end event)))
 678       ;; Just make sure this doesn't get an error.
 679       (tar-get-descriptor)))
 680   (select-window (posn-window (event-end event)))
 681   (goto-char (posn-point (event-end event)))
 682   (tar-extract))
 683
 684 (defun tar-extract (&optional other-window-p)
 685   "In Tar mode, extract this entry of the tar file into its own buffer."
 686   (interactive)
 687   (let* ((view-p (eq other-window-p 'view))
 688          (descriptor (tar-get-descriptor))
 689          (tokens (tar-desc-tokens descriptor))
 690          (name (tar-header-name tokens))
 691          (size (tar-header-size tokens))
 692          (start (+ (tar-desc-data-start descriptor)
 693                    (- tar-header-offset (point-min))))
 694          (end (+ start size)))
 695     (let* ((tar-buffer (current-buffer))
 696            (tar-buffer-multibyte enable-multibyte-characters)
 697            (tarname (buffer-name))
 698            (bufname (concat (file-name-nondirectory name)
 699                             " ("
 700                              tarname
 701                              ")"))
 702            (read-only-p (or buffer-read-only view-p))
 703            (new-buffer-file-name (expand-file-name
 704                                   ;; `:' is not allowed on Windows
 705                                   (concat tarname "!" name)))
 706            (buffer (get-file-buffer new-buffer-file-name))
 707            (just-created nil))
 708       (unless buffer
 709         (setq buffer (generate-new-buffer bufname))
 710         (setq bufname (buffer-name buffer))
 711         (setq just-created t)
 712         (unwind-protect
 713             (progn
 714               (widen)
 715               (set-buffer-multibyte nil)
 716               (save-excursion
 717                 (set-buffer buffer)
 718                 (let ((buffer-undo-list t))
 719                   (if enable-multibyte-characters
 720                       (progn
 721                         ;; We must avoid unibyte->multibyte conversion.
 722                         (set-buffer-multibyte nil)
 723                         (insert-buffer-substring tar-buffer start end)
 724                         (set-buffer-multibyte t))
 725                     (insert-buffer-substring tar-buffer start end))
 726                   (goto-char (point-min))
 727                   (setq buffer-file-name new-buffer-file-name)
 728                   (setq buffer-file-truename
 729                         (abbreviate-file-name buffer-file-name))
 730                   ;; We need to mimic the parts of insert-file-contents
 731                   ;; which determine the coding-system and decode the text.
 732                   (let ((coding
 733                          (or coding-system-for-read
 734                              (and set-auto-coding-function
 735                                   (save-excursion
 736                                     (funcall set-auto-coding-function
 737                                              name (- (point-max) (point)))))
 738                              (car (find-operation-coding-system
 739                                    'insert-file-contents name t))))
 740                         (multibyte enable-multibyte-characters)
 741                         (detected (detect-coding-region
 742                                    (point-min)
 743                                    (min (+ (point-min) 16384) (point-max)) t)))
 744                     (if coding
 745                         (or (numberp (coding-system-eol-type coding))
 746                             (vectorp (coding-system-eol-type detected))
 747                             (setq coding (coding-system-change-eol-conversion
 748                                           coding
 749                                           (coding-system-eol-type detected))))
 750                       (setq coding
 751                             (find-new-buffer-file-coding-system detected)))
 752                     (if (or (eq coding 'no-conversion)
 753                             (eq (coding-system-type coding) 5))
 754                         (setq multibyte (set-buffer-multibyte nil)))
 755                     (or multibyte
 756                         (setq coding
 757                               (coding-system-change-text-conversion
 758                                coding 'raw-text)))
 759                     (decode-coding-region (point-min) (point-max) coding)
 760                     (set-buffer-file-coding-system coding))
 761                   ;; Set the default-directory to the dir of the
 762                   ;; superior buffer.
 763                   (setq default-directory
 764                         (save-excursion
 765                           (set-buffer tar-buffer)
 766                           default-directory))
 767                   (normal-mode)  ; pick a mode.
 768                   (rename-buffer bufname)
 769                   (make-local-variable 'tar-superior-buffer)
 770                   (make-local-variable 'tar-superior-descriptor)
 771                   (setq tar-superior-buffer tar-buffer)
 772                   (setq tar-superior-descriptor descriptor)
 773                   (setq buffer-read-only read-only-p)
 774                   (set-buffer-modified-p nil))
 775                 (tar-subfile-mode 1))
 776               (set-buffer tar-buffer))
 777           (narrow-to-region (point-min) tar-header-offset)
 778           (set-buffer-multibyte tar-buffer-multibyte)))
 779       (if view-p
 780           (view-buffer buffer (and just-created 'kill-buffer))
 781         (if (eq other-window-p 'display)
 782             (display-buffer buffer)
 783           (if other-window-p
 784               (switch-to-buffer-other-window buffer)
 785             (switch-to-buffer buffer)))))))
 786
 787
 788 (defun tar-extract-other-window ()
 789   "In Tar mode, find this entry of the tar file in another window."
 790   (interactive)
 791   (tar-extract t))
 792
 793 (defun tar-display-other-window ()
 794   "In Tar mode, display this entry of the tar file in another window."
 795   (interactive)
 796   (tar-extract 'display))
 797
 798 (defun tar-view ()
 799   "In Tar mode, view the tar file entry on this line."
 800   (interactive)
 801   (tar-extract 'view))
 802
 803
 804 (defun tar-read-file-name (&optional prompt)
 805   "Read a file name with this line's entry as the default."
 806   (or prompt (setq prompt "Copy to: "))
 807   (let* ((default-file (expand-file-name
 808                         (tar-header-name (tar-desc-tokens
 809                                           (tar-current-descriptor)))))
 810          (target (expand-file-name
 811                   (read-file-name prompt
 812                                   (file-name-directory default-file)
 813                                   default-file nil))))
 814     (if (or (string= "" (file-name-nondirectory target))
 815             (file-directory-p target))
 816         (setq target (concat (if (string-match "/$" target)
 817                                  (substring target 0 (1- (match-end 0)))
 818                                  target)
 819                              "/"
 820                              (file-name-nondirectory default-file))))
 821     target))
 822
 823
 824 (defun tar-copy (&optional to-file)
 825   "In Tar mode, extract this entry of the tar file into a file on disk.
 826 If TO-FILE is not supplied, it is prompted for, defaulting to the name of
 827 the current tar-entry."
 828   (interactive (list (tar-read-file-name)))
 829   (let* ((descriptor (tar-get-descriptor))
 830          (tokens (tar-desc-tokens descriptor))
 831          (name (tar-header-name tokens))
 832          (size (tar-header-size tokens))
 833          (start (+ (tar-desc-data-start descriptor)
 834                    (- tar-header-offset (point-min))))
 835          (end (+ start size))
 836          (multibyte enable-multibyte-characters)
 837          (inhibit-file-name-handlers inhibit-file-name-handlers)
 838          (inhibit-file-name-operation inhibit-file-name-operation))
 839     (save-restriction
 840       (widen)
 841       ;; Inhibit compressing a subfile again if *both* name and
 842       ;; to-file are handled by jka-compr
 843       (if (and (eq (find-file-name-handler name 'write-region) 'jka-compr-handler)
 844                (eq (find-file-name-handler to-file 'write-region) 'jka-compr-handler))
 845           (setq inhibit-file-name-handlers
 846                 (cons 'jka-compr-handler
 847                       (and (eq inhibit-file-name-operation 'write-region)
 848                            inhibit-file-name-handlers))
 849                 inhibit-file-name-operation 'write-region))
 850       (unwind-protect
 851           (let ((coding-system-for-write 'no-conversion))
 852             (set-buffer-multibyte nil)
 853             (write-region start end to-file nil nil nil t))
 854         (set-buffer-multibyte multibyte)))
 855     (message "Copied tar entry %s to %s" name to-file)))
 856
 857 (defun tar-flag-deleted (p &optional unflag)
 858   "In Tar mode, mark this sub-file to be deleted from the tar file.
 859 With a prefix argument, mark that many files."
 860   (interactive "p")
 861   (beginning-of-line)
 862   (dotimes (i (abs p))
 863     (if (tar-current-descriptor unflag) ; barf if we're not on an entry-line.
 864         (progn
 865           (delete-char 1)
 866           (insert (if unflag " " "D"))))
 867     (forward-line (if (< p 0) -1 1)))
 868   (if (eobp) nil (forward-char 36)))
 869
 870 (defun tar-unflag (p)
 871   "In Tar mode, un-mark this sub-file if it is marked to be deleted.
 872 With a prefix argument, un-mark that many files forward."
 873   (interactive "p")
 874   (tar-flag-deleted p t))
 875
 876 (defun tar-unflag-backwards (p)
 877   "In Tar mode, un-mark this sub-file if it is marked to be deleted.
 878 With a prefix argument, un-mark that many files backward."
 879   (interactive "p")
 880   (tar-flag-deleted (- p) t))
 881
 882
 883 ;; When this function is called, it is sure that the buffer is unibyte.
 884 (defun tar-expunge-internal ()
 885   "Expunge the tar-entry specified by the current line."
 886   (let* ((descriptor (tar-current-descriptor))
 887          (tokens (tar-desc-tokens descriptor))
 888          ;; (line (tar-desc-data-start descriptor))
 889          (name (tar-header-name tokens))
 890          (size (tar-header-size tokens))
 891          (link-p (tar-header-link-type tokens))
 892          (start (tar-desc-data-start descriptor))
 893          (following-descs (cdr (memq descriptor tar-parse-info))))
 894     (if link-p (setq size 0)) ; size lies for hard-links.
 895     ;;
 896     ;; delete the current line...
 897     (beginning-of-line)
 898     (let ((line-start (point)))
 899       (end-of-line) (forward-char)
 900       ;; decrement the header-pointer to be in sync...
 901       (setq tar-header-offset (- tar-header-offset (- (point) line-start)))
 902       (delete-region line-start (point)))
 903     ;;
 904     ;; delete the data pointer...
 905     (setq tar-parse-info (delq descriptor tar-parse-info))
 906     ;;
 907     ;; delete the data from inside the file...
 908     (widen)
 909     (let* ((data-start (+ start (- tar-header-offset (point-min)) -512))
 910            (data-end (+ data-start 512 (ash (ash (+ size 511) -9) 9))))
 911       (delete-region data-start data-end)
 912       ;;
 913       ;; and finally, decrement the start-pointers of all following
 914       ;; entries in the archive.  This is a pig when deleting a bunch
 915       ;; of files at once - we could optimize this to only do the
 916       ;; iteration over the files that remain, or only iterate up to
 917       ;; the next file to be deleted.
 918       (let ((data-length (- data-end data-start)))
 919         (dolist (desc following-descs)
 920           (tar-setf (tar-desc-data-start desc)
 921                     (- (tar-desc-data-start desc) data-length))))
 922       ))
 923   (narrow-to-region (point-min) tar-header-offset))
 924
 925
 926 (defun tar-expunge (&optional noconfirm)
 927   "In Tar mode, delete all the archived files flagged for deletion.
 928 This does not modify the disk image; you must save the tar file itself
 929 for this to be permanent."
 930   (interactive)
 931   (if (or noconfirm
 932           (y-or-n-p "Expunge files marked for deletion? "))
 933       (let ((n 0)
 934             (multibyte enable-multibyte-characters))
 935         (save-excursion
 936           (widen)
 937           (set-buffer-multibyte nil)
 938           (goto-char (point-min))
 939           (while (not (eobp))
 940             (if (looking-at "D")
 941                 (progn (tar-expunge-internal)
 942                        (setq n (1+ n)))
 943                 (forward-line 1)))
 944           ;; after doing the deletions, add any padding that may be necessary.
 945           (tar-pad-to-blocksize)
 946           (widen)
 947           (set-buffer-multibyte multibyte)
 948           (narrow-to-region (point-min) tar-header-offset))
 949         (if (zerop n)
 950             (message "Nothing to expunge.")
 951             (message "%s files expunged.  Be sure to save this buffer." n)))))
 952
 953
 954 (defun tar-clear-modification-flags ()
 955   "Remove the stars at the beginning of each line."
 956   (interactive)
 957   (save-excursion
 958     (goto-char (point-min))
 959     (while (< (position-bytes (point)) tar-header-offset)
 960       (if (not (eq (following-char) ?\ ))
 961           (progn (delete-char 1) (insert " ")))
 962       (forward-line 1))))
 963
 964
 965 (defun tar-chown-entry (new-uid)
 966   "Change the user-id associated with this entry in the tar file.
 967 If this tar file was written by GNU tar, then you will be able to edit
 968 the user id as a string; otherwise, you must edit it as a number.
 969 You can force editing as a number by calling this with a prefix arg.
 970 This does not modify the disk image; you must save the tar file itself
 971 for this to be permanent."
 972   (interactive (list
 973                  (let ((tokens (tar-desc-tokens (tar-current-descriptor))))
 974                    (if (or current-prefix-arg
 975                            (not (tar-header-magic tokens)))
 976                        (let (n)
 977                          (while (not (numberp (setq n (read-minibuffer
 978                                                         "New UID number: "
 979                                                         (format "%s" (tar-header-uid tokens)))))))
 980                          n)
 981                        (read-string "New UID string: " (tar-header-uname tokens))))))
 982   (cond ((stringp new-uid)
 983          (tar-setf (tar-header-uname (tar-desc-tokens (tar-current-descriptor)))
 984                    new-uid)
 985          (tar-alter-one-field tar-uname-offset (concat new-uid "\000")))
 986         (t
 987          (tar-setf (tar-header-uid (tar-desc-tokens (tar-current-descriptor)))
 988                    new-uid)
 989          (tar-alter-one-field tar-uid-offset
 990            (concat (substring (format "%6o" new-uid) 0 6) "\000 ")))))
 991
 992
 993 (defun tar-chgrp-entry (new-gid)
 994   "Change the group-id associated with this entry in the tar file.
 995 If this tar file was written by GNU tar, then you will be able to edit
 996 the group id as a string; otherwise, you must edit it as a number.
 997 You can force editing as a number by calling this with a prefix arg.
 998 This does not modify the disk image; you must save the tar file itself
 999 for this to be permanent."
1000   (interactive (list
1001                  (let ((tokens (tar-desc-tokens (tar-current-descriptor))))
1002                    (if (or current-prefix-arg
1003                            (not (tar-header-magic tokens)))
1004                        (let (n)
1005                          (while (not (numberp (setq n (read-minibuffer
1006                                                         "New GID number: "
1007                                                         (format "%s" (tar-header-gid tokens)))))))
1008                          n)
1009                        (read-string "New GID string: " (tar-header-gname tokens))))))
1010   (cond ((stringp new-gid)
1011          (tar-setf (tar-header-gname (tar-desc-tokens (tar-current-descriptor)))
1012                    new-gid)
1013          (tar-alter-one-field tar-gname-offset
1014            (concat new-gid "\000")))
1015         (t
1016          (tar-setf (tar-header-gid (tar-desc-tokens (tar-current-descriptor)))
1017                    new-gid)
1018          (tar-alter-one-field tar-gid-offset
1019            (concat (substring (format "%6o" new-gid) 0 6) "\000 ")))))
1020
1021 (defun tar-rename-entry (new-name)
1022   "Change the name associated with this entry in the tar file.
1023 This does not modify the disk image; you must save the tar file itself
1024 for this to be permanent."
1025   (interactive
1026     (list (read-string "New name: "
1027             (tar-header-name (tar-desc-tokens (tar-current-descriptor))))))
1028   (if (string= "" new-name) (error "zero length name"))
1029   (if (> (length new-name) 98) (error "name too long"))
1030   (tar-setf (tar-header-name (tar-desc-tokens (tar-current-descriptor)))
1031             new-name)
1032   (if (multibyte-string-p new-name)
1033       (setq new-name (encode-coding-string new-name
1034                                            (or file-name-coding-system
1035                                                default-file-name-coding-system))))
1036   (tar-alter-one-field 0
1037     (substring (concat new-name (make-string 99 0)) 0 99)))
1038
1039
1040 (defun tar-chmod-entry (new-mode)
1041   "Change the protection bits associated with this entry in the tar file.
1042 This does not modify the disk image; you must save the tar file itself
1043 for this to be permanent."
1044   (interactive (list (tar-parse-octal-integer-safe
1045                        (read-string "New protection (octal): "))))
1046   (tar-setf (tar-header-mode (tar-desc-tokens (tar-current-descriptor)))
1047             new-mode)
1048   (tar-alter-one-field tar-mode-offset
1049     (concat (substring (format "%6o" new-mode) 0 6) "\000 ")))
1050
1051
1052 (defun tar-alter-one-field (data-position new-data-string)
1053   (let* ((descriptor (tar-current-descriptor))
1054          (tokens (tar-desc-tokens descriptor))
1055          (multibyte enable-multibyte-characters))
1056     (unwind-protect
1057         (save-excursion
1058           ;;
1059           ;; update the header-line.
1060           (beginning-of-line)
1061           (let ((p (point)))
1062             (forward-line 1)
1063             (delete-region p (point))
1064             (insert (tar-header-block-summarize tokens) "\n")
1065             (setq tar-header-offset (position-bytes (point-max))))
1066
1067           (widen)
1068           (set-buffer-multibyte nil)
1069           (let* ((start (+ (tar-desc-data-start descriptor)
1070                            (- tar-header-offset (point-min))
1071                            -512)))
1072             ;;
1073             ;; delete the old field and insert a new one.
1074             (goto-char (+ start data-position))
1075             (delete-region (point) (+ (point) (length new-data-string))) ; <--
1076             (insert new-data-string) ; <--
1077             ;;
1078             ;; compute a new checksum and insert it.
1079             (let ((chk (tar-header-block-checksum
1080                         (buffer-substring start (+ start 512)))))
1081               (goto-char (+ start tar-chk-offset))
1082               (delete-region (point) (+ (point) 8))
1083               (insert (format "%6o" chk))
1084               (insert 0)
1085               (insert ? )
1086               (tar-setf (tar-header-checksum tokens) chk)
1087               ;;
1088               ;; ok, make sure we didn't botch it.
1089               (tar-header-block-check-checksum
1090                 (buffer-substring start (+ start 512))
1091                 chk (tar-header-name tokens))
1092               )))
1093       (narrow-to-region (point-min) tar-header-offset)
1094       (set-buffer-multibyte multibyte)
1095       (tar-next-line 0))))
1096
1097
1098 (defun tar-octal-time (timeval)
1099   ;; Format a timestamp as 11 octal digits.  Ghod, I hope this works...
1100   (let ((hibits (car timeval)) (lobits (car (cdr timeval))))
1101     (format "%05o%01o%05o"
1102             (lsh hibits -2)
1103             (logior (lsh (logand 3 hibits) 1)
1104                     (if (> (logand lobits 32768) 0) 1 0))
1105             (logand 32767 lobits)
1106             )))
1107
1108 (defun tar-subfile-save-buffer ()
1109   "In tar subfile mode, save this buffer into its parent tar-file buffer.
1110 This doesn't write anything to disk; you must save the parent tar-file buffer
1111 to make your changes permanent."
1112   (interactive)
1113   (if (not (and (boundp 'tar-superior-buffer) tar-superior-buffer))
1114     (error "This buffer has no superior tar file buffer"))
1115   (if (not (and (boundp 'tar-superior-descriptor) tar-superior-descriptor))
1116     (error "This buffer doesn't have an index into its superior tar file!"))
1117   (save-excursion
1118   (let ((subfile (current-buffer))
1119         (subfile-multibyte enable-multibyte-characters)
1120         (coding buffer-file-coding-system)
1121         (descriptor tar-superior-descriptor)
1122         subfile-size)
1123     ;; We must make the current buffer unibyte temporarily to avoid
1124     ;; multibyte->unibyte conversion in `insert-buffer-substring'.
1125     (set-buffer-multibyte nil)
1126     (setq subfile-size (buffer-size))
1127     (set-buffer tar-superior-buffer)
1128     (let* ((tokens (tar-desc-tokens descriptor))
1129            (start (tar-desc-data-start descriptor))
1130            (name (tar-header-name tokens))
1131            (size (tar-header-size tokens))
1132            (size-pad (ash (ash (+ size 511) -9) 9))
1133            (head (memq descriptor tar-parse-info))
1134            (following-descs (cdr head))
1135            (tar-buffer-multibyte enable-multibyte-characters))
1136       (if (not head)
1137         (error "Can't find this tar file entry in its parent tar file!"))
1138       (unwind-protect
1139        (save-excursion
1140         (widen)
1141         (set-buffer-multibyte nil)
1142         ;; delete the old data...
1143         (let* ((data-start (+ start (- tar-header-offset (point-min))))
1144                (data-end (+ data-start (ash (ash (+ size 511) -9) 9))))
1145           (delete-region data-start data-end)
1146           ;; insert the new data...
1147           (goto-char data-start)
1148           (insert-buffer-substring subfile)
1149           (setq subfile-size
1150                 (encode-coding-region
1151                  data-start (+ data-start subfile-size) coding))
1152           ;;
1153           ;; pad the new data out to a multiple of 512...
1154           (let ((subfile-size-pad (ash (ash (+ subfile-size 511) -9) 9)))
1155             (goto-char (+ data-start subfile-size))
1156             (insert (make-string (- subfile-size-pad subfile-size) 0))
1157             ;;
1158             ;; update the data pointer of this and all following files...
1159             (tar-setf (tar-header-size tokens) subfile-size)
1160             (let ((difference (- subfile-size-pad size-pad)))
1161               (dolist (desc following-descs)
1162                 (tar-setf (tar-desc-data-start desc)
1163                           (+ (tar-desc-data-start desc) difference))))
1164             ;;
1165             ;; Update the size field in the header block.
1166             (let ((header-start (- data-start 512)))
1167               (goto-char (+ header-start tar-size-offset))
1168               (delete-region (point) (+ (point) 12))
1169               (insert (format "%11o" subfile-size))
1170               (insert ? )
1171               ;;
1172               ;; Maybe update the datestamp.
1173               (if (not tar-update-datestamp)
1174                   nil
1175                 (goto-char (+ header-start tar-time-offset))
1176                 (delete-region (point) (+ (point) 12))
1177                 (insert (tar-octal-time (current-time)))
1178                 (insert ? ))
1179               ;;
1180               ;; compute a new checksum and insert it.
1181               (let ((chk (tar-header-block-checksum
1182                           (buffer-substring header-start data-start))))
1183                 (goto-char (+ header-start tar-chk-offset))
1184                 (delete-region (point) (+ (point) 8))
1185                 (insert (format "%6o" chk))
1186                 (insert 0)
1187                 (insert ? )
1188                 (tar-setf (tar-header-checksum tokens) chk)))
1189             ;;
1190             ;; alter the descriptor-line...
1191             ;;
1192             (let ((position (- (length tar-parse-info) (length head))))
1193               (goto-char (point-min))
1194               (next-line position)
1195               (beginning-of-line)
1196               (let ((p (point))
1197                     after
1198                     (m (set-marker (make-marker) tar-header-offset)))
1199                 (forward-line 1)
1200                 (setq after (point))
1201                 ;; Insert the new text after the old, before deleting,
1202                 ;; to preserve the window start.
1203                 (let ((line (tar-header-block-summarize tokens t)))
1204                   (insert-before-markers (string-as-unibyte line) "\n"))
1205                 (delete-region p after)
1206                 (setq tar-header-offset (marker-position m)))
1207               )))
1208         ;; after doing the insertion, add any final padding that may be necessary.
1209         (tar-pad-to-blocksize))
1210        (narrow-to-region (point-min) tar-header-offset)
1211        (set-buffer-multibyte tar-buffer-multibyte)))
1212     (set-buffer-modified-p t)   ; mark the tar file as modified
1213     (tar-next-line 0)
1214     (set-buffer subfile)
1215     ;; Restore the buffer multibyteness.
1216     (set-buffer-multibyte subfile-multibyte)
1217     (set-buffer-modified-p nil) ; mark the tar subfile as unmodified
1218     (message "Saved into tar-buffer `%s'.  Be sure to save that buffer!"
1219              (buffer-name tar-superior-buffer))
1220     ;; Prevent basic-save-buffer from changing our coding-system.
1221     (setq last-coding-system-used buffer-file-coding-system)
1222     ;; Prevent ordinary saving from happening.
1223     t)))
1224
1225
1226 ;; When this function is called, it is sure that the buffer is unibyte.
1227 (defun tar-pad-to-blocksize ()
1228   "If we are being anal about tar file blocksizes, fix up the current buffer.
1229 Leaves the region wide."
1230   (if (null tar-anal-blocksize)
1231       nil
1232     (widen)
1233     (let* ((last-desc (nth (1- (length tar-parse-info)) tar-parse-info))
1234            (start (tar-desc-data-start last-desc))
1235            (tokens (tar-desc-tokens last-desc))
1236            (link-p (tar-header-link-type tokens))
1237            (size (if link-p 0 (tar-header-size tokens)))
1238            (data-end (+ start size))
1239            (bbytes (ash tar-anal-blocksize 9))
1240            (pad-to (+ bbytes (* bbytes (/ (- data-end (point-min)) bbytes))))
1241            (inhibit-read-only t) ; ##
1242            )
1243       ;; If the padding after the last data is too long, delete some;
1244       ;; else insert some until we are padded out to the right number of blocks.
1245       ;;
1246       (let ((goal-end (+ (or tar-header-offset 0) pad-to)))
1247         (if (> (point-max) goal-end)
1248             (delete-region goal-end (point-max))
1249           (goto-char (point-max))
1250           (insert (make-string (- goal-end (point-max)) ?\0)))))))
1251
1252
1253 ;; Used in write-file-hook to write tar-files out correctly.
1254 (defun tar-mode-write-file ()
1255   (unwind-protect
1256       (save-excursion
1257         (widen)
1258         ;; Doing this here confuses things - the region gets left too wide!
1259         ;; I suppose this is run in a context where changing the buffer is bad.
1260         ;; (tar-pad-to-blocksize)
1261         ;; tar-header-offset turns out to be null for files fetched with W3,
1262         ;; at least.
1263         (let ((coding-system-for-write 'no-conversion))
1264           (write-region (if tar-header-offset
1265                             (byte-to-position tar-header-offset)
1266                           (point-min))
1267                         (point-max)
1268                         buffer-file-name nil t))
1269         (tar-clear-modification-flags)
1270         (set-buffer-modified-p nil))
1271     (narrow-to-region (point-min) (byte-to-position tar-header-offset)))
1272   ;; Return t because we've written the file.
1273   t)
1274 \f
1275 (provide 'tar-mode)
1276
1277 ;; arch-tag: 8a585a4a-340e-42c2-89e7-d3b1013a4b78
1278 ;;; tar-mode.el ends here