code.delx.au - gnu-emacs/blob - lisp/progmodes/compile.el

   1 ;;; compile.el --- run compiler as inferior of Emacs, parse error messages
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4 ;;   2001, 2002, 2003, 2004, 2005  Free Software Foundation, Inc.
   5
   6 ;; Authors: Roland McGrath <roland@gnu.org>,
   7 ;;          Daniel Pfeiffer <occitan@esperanto.org>
   8 ;; Maintainer: FSF
   9 ;; Keywords: tools, processes
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package provides the compile facilities documented in the Emacs user's
  31 ;; manual.
  32
  33 ;; This mode uses some complex data-structures:
  34
  35 ;;   LOC (or location) is a list of (COLUMN LINE FILE-STRUCTURE)
  36
  37 ;; COLUMN and LINE are numbers parsed from an error message.  COLUMN and maybe
  38 ;; LINE will be nil for a message that doesn't contain them.  Then the
  39 ;; location refers to a indented beginning of line or beginning of file.
  40 ;; Once any location in some file has been jumped to, the list is extended to
  41 ;; (COLUMN LINE FILE-STRUCTURE MARKER . VISITED) for all LOCs pertaining to
  42 ;; that file.
  43 ;; MARKER initially points to LINE and COLUMN in a buffer visiting that file.
  44 ;; Being a marker it sticks to some text, when the buffer grows or shrinks
  45 ;; before that point.  VISITED is t if we have jumped there, else nil.
  46
  47 ;;   FILE-STRUCTURE is a list of
  48 ;;   ((FILENAME . DIRECTORY) FORMATS (LINE LOC ...) ...)
  49
  50 ;; FILENAME is a string parsed from an error message.  DIRECTORY is a string
  51 ;; obtained by following directory change messages.  DIRECTORY will be nil for
  52 ;; an absolute filename.  FORMATS is a list of formats to apply to FILENAME if
  53 ;; a file of that name can't be found.
  54 ;; The rest of the list is an alist of elements with LINE as key.  The keys
  55 ;; are either nil or line numbers.  If present, nil comes first, followed by
  56 ;; the numbers in decreasing order.  The LOCs for each line are again an alist
  57 ;; ordered the same way.  Note that the whole file structure is referenced in
  58 ;; every LOC.
  59
  60 ;;   MESSAGE is a list of (LOC TYPE END-LOC)
  61
  62 ;; TYPE is 0 for info or 1 for warning if the message matcher identified it as
  63 ;; such, 2 otherwise (for a real error).  END-LOC is a LOC pointing to the
  64 ;; other end, if the parsed message contained a range.  If the end of the
  65 ;; range didn't specify a COLUMN, it defaults to -1, meaning end of line.
  66 ;; These are the value of the `message' text-properties in the compilation
  67 ;; buffer.
  68
  69 ;;; Code:
  70
  71 (eval-when-compile (require 'cl))
  72
  73 (defvar font-lock-extra-managed-props)
  74 (defvar font-lock-keywords)
  75 (defvar font-lock-maximum-size)
  76 (defvar font-lock-support-mode)
  77
  78
  79 (defgroup compilation nil
  80   "Run compiler as inferior of Emacs, parse error messages."
  81   :group 'tools
  82   :group 'processes)
  83
  84
  85 ;;;###autoload
  86 (defcustom compilation-mode-hook nil
  87   "*List of hook functions run by `compilation-mode' (see `run-mode-hooks')."
  88   :type 'hook
  89   :group 'compilation)
  90
  91 ;;;###autoload
  92 (defcustom compilation-window-height nil
  93   "*Number of lines in a compilation window.  If nil, use Emacs default."
  94   :type '(choice (const :tag "Default" nil)
  95                  integer)
  96   :group 'compilation)
  97
  98 (defvar compilation-first-column 1
  99   "*This is how compilers number the first column, usually 1 or 0.")
 100
 101 (defvar compilation-parse-errors-filename-function nil
 102   "Function to call to post-process filenames while parsing error messages.
 103 It takes one arg FILENAME which is the name of a file as found
 104 in the compilation output, and should return a transformed file name.")
 105
 106 ;;;###autoload
 107 (defvar compilation-process-setup-function nil
 108   "*Function to call to customize the compilation process.
 109 This function is called immediately before the compilation process is
 110 started.  It can be used to set any variables or functions that are used
 111 while processing the output of the compilation process.  The function
 112 is called with variables `compilation-buffer' and `compilation-window'
 113 bound to the compilation buffer and window, respectively.")
 114
 115 ;;;###autoload
 116 (defvar compilation-buffer-name-function nil
 117   "Function to compute the name of a compilation buffer.
 118 The function receives one argument, the name of the major mode of the
 119 compilation buffer.  It should return a string.
 120 nil means compute the name with `(concat \"*\" (downcase major-mode) \"*\")'.")
 121
 122 ;;;###autoload
 123 (defvar compilation-finish-function nil
 124   "Function to call when a compilation process finishes.
 125 It is called with two arguments: the compilation buffer, and a string
 126 describing how the process finished.")
 127
 128 (make-obsolete-variable 'compilation-finish-function
 129   "Use `compilation-finish-functions', but it works a little differently."
 130   "22.1")
 131
 132 ;;;###autoload
 133 (defvar compilation-finish-functions nil
 134   "Functions to call when a compilation process finishes.
 135 Each function is called with two arguments: the compilation buffer,
 136 and a string describing how the process finished.")
 137
 138 (defvar compilation-in-progress nil
 139   "List of compilation processes now running.")
 140 (or (assq 'compilation-in-progress minor-mode-alist)
 141     (setq minor-mode-alist (cons '(compilation-in-progress " Compiling")
 142                                  minor-mode-alist)))
 143
 144 (defvar compilation-error "error"
 145   "Stem of message to print when no matches are found.")
 146
 147 (defvar compilation-arguments nil
 148   "Arguments that were given to `compilation-start'.")
 149
 150 (defvar compilation-num-errors-found)
 151
 152 (defconst compilation-error-regexp-alist-alist
 153   '((absoft
 154      "^\\(?:[Ee]rror on \\|[Ww]arning on\\( \\)\\)?[Ll]ine[ \t]+\\([0-9]+\\)[ \t]+\
 155 of[ \t]+\"?\\([a-zA-Z]?:?[^\":\n]+\\)\"?:" 3 2 nil (1))
 156
 157     (ada
 158      "\\(warning: .*\\)? at \\([^ \n]+\\):\\([0-9]+\\)$" 2 3 nil (1))
 159
 160     (aix
 161      " in line \\([0-9]+\\) of file \\([^ \n]+[^. \n]\\)\\.? " 2 1)
 162
 163     (ant
 164      "^[ \t]*\\[[^] \n]+\\][ \t]*\\([^: \n]+\\):\\([0-9]+\\):\\(?:\\([0-9]+\\):[0-9]+:[0-9]+:\\)?\
 165 \\( warning\\)?" 1 2 3 (4))
 166
 167     (bash
 168      "^\\([^: \n\t]+\\): line \\([0-9]+\\):" 1 2)
 169
 170     (borland
 171      "^\\(?:Error\\|Warnin\\(g\\)\\) \\(?:[FEW][0-9]+ \\)?\
 172 \\([a-zA-Z]?:?[^:( \t\n]+\\)\
 173  \\([0-9]+\\)\\(?:[) \t]\\|:[^0-9\n]\\)" 2 3 nil (1))
 174
 175     (caml
 176      "^ *File \\(\"?\\)\\([^,\" \n\t<>]+\\)\\1, lines? \\([0-9]+\\)-?\\([0-9]+\\)?\\(?:$\\|,\
 177 \\(?: characters? \\([0-9]+\\)-?\\([0-9]+\\)?:\\)?\\([ \n]Warning:\\)?\\)"
 178      2 (3 . 4) (5 . 6) (7))
 179
 180     (comma
 181      "^\"\\([^,\" \n\t]+\\)\", line \\([0-9]+\\)\
 182 \\(?:[(. pos]+\\([0-9]+\\))?\\)?[:.,; (-]\\( warning:\\|[-0-9 ]*(W)\\)?" 1 2 3 (4))
 183
 184     (edg-1
 185      "^\\([^ \n]+\\)(\\([0-9]+\\)): \\(?:error\\|warnin\\(g\\)\\|remar\\(k\\)\\)"
 186      1 2 nil (3 . 4))
 187     (edg-2
 188      "at line \\([0-9]+\\) of \"\\([^ \n]+\\)\"$"
 189      2 1 nil 0)
 190
 191     (epc
 192      "^Error [0-9]+ at (\\([0-9]+\\):\\([^)\n]+\\))" 2 1)
 193
 194     (ftnchek
 195      "\\(^Warning .*\\)? line[ \n]\\([0-9]+\\)[ \n]\\(?:col \\([0-9]+\\)[ \n]\\)?file \\([^ :;\n]+\\)"
 196      4 2 3 (1))
 197
 198     (iar
 199      "^\"\\(.*\\)\",\\([0-9]+\\)\\s-+\\(?:Error\\|Warnin\\(g\\)\\)\\[[0-9]+\\]:"
 200      1 2 nil (3))
 201
 202     (ibm
 203      "^\\([^( \n\t]+\\)(\\([0-9]+\\):\\([0-9]+\\)) :\
 204  \\(?:warnin\\(g\\)\\|informationa\\(l\\)\\)?" 1 2 3 (4 . 5))
 205
 206     ;; fixme: should be `mips'
 207     (irix
 208      "^[-[:alnum:]_/ ]+: \\(?:\\(?:[sS]evere\\|[eE]rror\\|[wW]arnin\\(g\\)\\|[iI]nf\\(o\\)\\)[0-9 ]*: \\)?\
 209 \\([^,\" \n\t]+\\)\\(?:, line\\|:\\) \\([0-9]+\\):" 3 4 nil (1 . 2))
 210
 211     (java
 212      "^\\(?:[ \t]+at \\|==[0-9]+== +\\(?:at\\|b\\(y\\)\\)\\).+(\\([^()\n]+\\):\\([0-9]+\\))$" 2 3 nil (1))
 213
 214     (jikes-file
 215      "^\\(?:Found\\|Issued\\) .* compiling \"\\(.+\\)\":$" 1 nil nil 0)
 216     (jikes-line
 217      "^ *\\([0-9]+\\)\\.[ \t]+.*\n +\\(<-*>\n\\*\\*\\* \\(?:Error\\|Warnin\\(g\\)\\)\\)"
 218      nil 1 nil 2 0
 219      (2 (compilation-face '(3))))
 220
 221     (gcc-include
 222      "^\\(?:In file included\\|                \\) from \
 223 \\(.+\\):\\([0-9]+\\)\\(?:\\(:\\)\\|\\(,\\)\\)?" 1 2 nil (3 . 4))
 224
 225     (gnu
 226      "^\\(?:[[:alpha:]][-[:alnum:].]+: ?\\)?\
 227 \\([/.]*[a-zA-Z]:?[^ \t\n:]*\\|{standard input}\\): ?\
 228 \\([0-9]+\\)\\([.:]?\\)\\([0-9]+\\)?\
 229 \\(?:-\\(?:\\([0-9]+\\)\\3\\)?\\.?\\([0-9]+\\)?\\)?:\
 230 \\(?: *\\(\\(?:Future\\|Runtime\\)?[Ww]arning\\|W:\\)\\|\
 231  *\\([Ii]nfo\\(?:\\>\\|rmationa?l?\\)\\|I:\\)\\)?"
 232      1 (2 . 5) (4 . 6) (7 . 8))
 233
 234     (lcc
 235      "^\\(?:E\\|\\(W\\)\\), \\([^(\n]+\\)(\\([0-9]+\\),[ \t]*\\([0-9]+\\)"
 236      2 3 4 (1))
 237
 238     (makepp
 239      "^makepp: \\(?:\\(?:warning\\(:\\).*?\\|\\(Scanning\\|[LR]e?l?oading makefile\\) \\|.*?\\)\
 240 `\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)['(]\\)"
 241      4 5 nil (1 . 2) 3
 242      ("`\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)['(]" nil nil
 243       (2 compilation-info-face)
 244       (3 compilation-line-face nil t)
 245       (1 (compilation-error-properties 2 3 nil nil nil 0 nil)
 246          append)))
 247
 248     ;; Should be lint-1, lint-2 (SysV lint)
 249     (mips-1
 250      " (\\([0-9]+\\)) in \\([^ \n]+\\)" 2 1)
 251     (mips-2
 252      " in \\([^()\n ]+\\)(\\([0-9]+\\))$" 1 2)
 253
 254     (msft
 255      "^\\([0-9]+>\\)?\\(\\(?:[a-zA-Z]:\\)?[^:(\t\n]+\\)(\\([0-9]+\\)) \
 256 : \\(?:error\\|warnin\\(g\\)\\) C[0-9]+:" 2 3 nil (4))
 257
 258     (oracle
 259      "^\\(?:Semantic error\\|Error\\|PCC-[0-9]+:\\).* line \\([0-9]+\\)\
 260 \\(?:\\(?:,\\| at\\)? column \\([0-9]+\\)\\)?\
 261 \\(?:,\\| in\\| of\\)? file \\(.*?\\):?$"
 262      3 1 2)
 263
 264     (perl
 265      " at \\([^ \n]+\\) line \\([0-9]+\\)\\(?:[,.]\\|$\\)" 1 2)
 266
 267     (rxp
 268      "^\\(?:Error\\|Warnin\\(g\\)\\):.*\n.* line \\([0-9]+\\) char\
 269  \\([0-9]+\\) of file://\\(.+\\)"
 270      4 2 3 (1))
 271
 272     (sparc-pascal-file
 273      "^\\w\\w\\w \\w\\w\\w +[0-3]?[0-9] +[0-2][0-9]:[0-5][0-9]:[0-5][0-9]\
 274  [12][09][0-9][0-9] +\\(.*\\):$"
 275      1 nil nil 0)
 276     (sparc-pascal-line
 277      "^\\(\\(?:E\\|\\(w\\)\\) +[0-9]+\\) line \\([0-9]+\\) -  "
 278      nil 3 nil (2) nil (1 (compilation-face '(2))))
 279     (sparc-pascal-example
 280      "^ +\\([0-9]+\\) +.*\n\\(\\(?:e\\|\\(w\\)\\) [0-9]+\\)-+"
 281      nil 1 nil (3) nil (2 (compilation-face '(3))))
 282
 283     (sun
 284      ": \\(?:ERROR\\|WARNIN\\(G\\)\\|REMAR\\(K\\)\\) \\(?:[[:alnum:] ]+, \\)?\
 285 File = \\(.+\\), Line = \\([0-9]+\\)\\(?:, Column = \\([0-9]+\\)\\)?"
 286      3 4 5 (1 . 2))
 287
 288     (sun-ada
 289      "^\\([^, \n\t]+\\), line \\([0-9]+\\), char \\([0-9]+\\)[:., \(-]" 1 2 3)
 290
 291     (4bsd
 292      "\\(?:^\\|::  \\|\\S ( \\)\\(/[^ \n\t()]+\\)(\\([0-9]+\\))\
 293 \\(?:: \\(warning:\\)?\\|$\\| ),\\)" 1 2 nil (3))
 294
 295     (gcov-file
 296      "^ +-:    \\(0\\):Source:\\(.+\\)$" 2 1 nil 0)
 297     (gcov-bb-file
 298      "^ +-:    \\(0\\):Object:\\(?:.+\\)$" nil 1 nil 0)
 299     (gcov-never-called-line
 300      "^ +\\(#####\\): +\\([0-9]+\\):.+$" nil 2 nil 2 nil
 301      (1 compilation-error-face))
 302     (gcov-called-line
 303      "^ +[-0-9]+: +\\([1-9]\\|[0-9]\\{2,\\}\\):.*$" nil 1 nil 0)
 304 )
 305   "Alist of values for `compilation-error-regexp-alist'.")
 306
 307 (defcustom compilation-error-regexp-alist
 308   (mapcar 'car compilation-error-regexp-alist-alist)
 309   "Alist that specifies how to match errors in compiler output.
 310 On GNU and Unix, any string is a valid filename, so these
 311 matchers must make some common sense assumptions, which catch
 312 normal cases.  A shorter list will be lighter on resource usage.
 313
 314 Instead of an alist element, you can use a symbol, which is
 315 looked up in `compilation-error-regexp-alist-alist'.  You can see
 316 the predefined symbols and their effects in the file
 317 `etc/compilation.txt' (linked below if you are customizing this).
 318
 319 Each elt has the form (REGEXP FILE [LINE COLUMN TYPE HYPERLINK
 320 HIGHLIGHT...]).  If REGEXP matches, the FILE'th subexpression
 321 gives the file name, and the LINE'th subexpression gives the line
 322 number.  The COLUMN'th subexpression gives the column number on
 323 that line.
 324
 325 If FILE, LINE or COLUMN are nil or that index didn't match, that
 326 information is not present on the matched line.  In that case the
 327 file name is assumed to be the same as the previous one in the
 328 buffer, line number defaults to 1 and column defaults to
 329 beginning of line's indentation.
 330
 331 FILE can also have the form (FILE FORMAT...), where the FORMATs
 332 \(e.g. \"%s.c\") will be applied in turn to the recognized file
 333 name, until a file of that name is found.  Or FILE can also be a
 334 function to return the filename.
 335
 336 LINE can also be of the form (LINE . END-LINE) meaning a range
 337 of lines.  COLUMN can also be of the form (COLUMN . END-COLUMN)
 338 meaning a range of columns starting on LINE and ending on
 339 END-LINE, if that matched.
 340
 341 TYPE is 2 or nil for a real error or 1 for warning or 0 for info.
 342 TYPE can also be of the form (WARNING . INFO).  In that case this
 343 will be equivalent to 1 if the WARNING'th subexpression matched
 344 or else equivalent to 0 if the INFO'th subexpression matched.
 345 See `compilation-error-face', `compilation-warning-face',
 346 `compilation-info-face' and `compilation-skip-threshold'.
 347
 348 What matched the HYPERLINK'th subexpression has `mouse-face' and
 349 `compilation-message-face' applied.  If this is nil, the text
 350 matched by the whole REGEXP becomes the hyperlink.
 351
 352 Additional HIGHLIGHTs as described under `font-lock-keywords' can
 353 be added."
 354   :type `(set :menu-tag "Pick"
 355               ,@(mapcar (lambda (elt)
 356                           (list 'const (car elt)))
 357                         compilation-error-regexp-alist-alist))
 358   :link `(file-link :tag "example file"
 359                     ,(expand-file-name "compilation.txt" data-directory))
 360   :group 'compilation)
 361
 362 (defvar compilation-directory nil
 363   "Directory to restore to when doing `recompile'.")
 364
 365 (defvar compilation-directory-matcher
 366   '("\\(?:Entering\\|Leavin\\(g\\)\\) directory `\\(.+\\)'$" (2 . 1))
 367   "A list for tracking when directories are entered or left.
 368 Nil means not to track directories, e.g. if all file names are absolute.  The
 369 first element is the REGEXP matching these messages.  It can match any number
 370 of variants, e.g. different languages.  The remaining elements are all of the
 371 form (DIR .  LEAVE).  If for any one of these the DIR'th subexpression
 372 matches, that is a directory name.  If LEAVE is nil or the corresponding
 373 LEAVE'th subexpression doesn't match, this message is about going into another
 374 directory.  If it does match anything, this message is about going back to the
 375 directory we were in before the last entering message.  If you change this,
 376 you may also want to change `compilation-page-delimiter'.")
 377
 378 (defvar compilation-page-delimiter
 379   "^\\(?:\f\\|.*\\(?:Entering\\|Leaving\\) directory `.+'\n\\)+"
 380   "Value of `page-delimiter' in Compilation mode.")
 381
 382 (defvar compilation-mode-font-lock-keywords
 383    '(;; configure output lines.
 384      ("^[Cc]hecking \\(?:[Ff]or \\|[Ii]f \\|[Ww]hether \\(?:to \\)?\\)?\\(.+\\)\\.\\.\\. *\\(?:(cached) *\\)?\\(\\(yes\\(?: .+\\)?\\)\\|no\\|\\(.*\\)\\)$"
 385       (1 font-lock-variable-name-face)
 386       (2 (compilation-face '(4 . 3))))
 387      ;; Command output lines.  Recognize `make[n]:' lines too.
 388      ("^\\([[:alnum:]_/.+-]+\\)\\(\\[\\([0-9]+\\)\\]\\)?[ \t]*:"
 389       (1 font-lock-function-name-face) (3 compilation-line-face nil t))
 390      (" --?o\\(?:utfile\\|utput\\)?[= ]?\\(\\S +\\)" . 1)
 391      ("^Compilation \\(finished\\)"
 392       (1 compilation-info-face))
 393      ("^Compilation \\(exited abnormally\\|interrupt\\|killed\\|terminated\\)\\(?:.*with code \\([0-9]+\\)\\)?"
 394       (1 compilation-error-face)
 395       (2 compilation-error-face nil t)))
 396    "Additional things to highlight in Compilation mode.
 397 This gets tacked on the end of the generated expressions.")
 398
 399 (defvar compilation-highlight-regexp t
 400   "Regexp matching part of visited source lines to highlight temporarily.
 401 Highlight entire line if t; don't highlight source lines if nil.")
 402
 403 (defvar compilation-highlight-overlay nil
 404   "Overlay used to temporarily highlight compilation matches.")
 405
 406 (defcustom compilation-error-screen-columns t
 407   "*If non-nil, column numbers in error messages are screen columns.
 408 Otherwise they are interpreted as character positions, with
 409 each character occupying one column.
 410 The default is to use screen columns, which requires that the compilation
 411 program and Emacs agree about the display width of the characters,
 412 especially the TAB character."
 413   :type 'boolean
 414   :group 'compilation
 415   :version "20.4")
 416
 417 (defcustom compilation-read-command t
 418   "*Non-nil means \\[compile] reads the compilation command to use.
 419 Otherwise, \\[compile] just uses the value of `compile-command'."
 420   :type 'boolean
 421   :group 'compilation)
 422
 423 ;;;###autoload
 424 (defcustom compilation-ask-about-save t
 425   "*Non-nil means \\[compile] asks which buffers to save before compiling.
 426 Otherwise, it saves all modified buffers without asking."
 427   :type 'boolean
 428   :group 'compilation)
 429
 430 ;;;###autoload
 431 (defcustom compilation-search-path '(nil)
 432   "*List of directories to search for source files named in error messages.
 433 Elements should be directory names, not file names of directories.
 434 nil as an element means to try the default directory."
 435   :type '(repeat (choice (const :tag "Default" nil)
 436                          (string :tag "Directory")))
 437   :group 'compilation)
 438
 439 ;;;###autoload
 440 (defcustom compile-command "make -k "
 441   "*Last shell command used to do a compilation; default for next compilation.
 442
 443 Sometimes it is useful for files to supply local values for this variable.
 444 You might also use mode hooks to specify it in certain modes, like this:
 445
 446     (add-hook 'c-mode-hook
 447        (lambda ()
 448          (unless (or (file-exists-p \"makefile\")
 449                      (file-exists-p \"Makefile\"))
 450            (set (make-local-variable 'compile-command)
 451                 (concat \"make -k \"
 452                         (file-name-sans-extension buffer-file-name))))))"
 453   :type 'string
 454   :group 'compilation)
 455
 456 ;;;###autoload
 457 (defcustom compilation-disable-input nil
 458   "*If non-nil, send end-of-file as compilation process input.
 459 This only affects platforms that support asynchronous processes (see
 460 `start-process'); synchronous compilation processes never accept input."
 461   :type 'boolean
 462   :group 'compilation
 463   :version "22.1")
 464
 465 ;; A weak per-compilation-buffer hash indexed by (FILENAME . DIRECTORY).  Each
 466 ;; value is a FILE-STRUCTURE as described above, with the car eq to the hash
 467 ;; key.  This holds the tree seen from root, for storing new nodes.
 468 (defvar compilation-locs ())
 469
 470 (defvar compilation-debug nil
 471   "*Set this to t before creating a *compilation* buffer.
 472 Then every error line will have a debug text property with the matcher that
 473 fit this line and the match data.  Use `describe-text-properties'.")
 474
 475 (defvar compilation-exit-message-function nil "\
 476 If non-nil, called when a compilation process dies to return a status message.
 477 This should be a function of three arguments: process status, exit status,
 478 and exit message; it returns a cons (MESSAGE . MODELINE) of the strings to
 479 write into the compilation buffer, and to put in its mode line.")
 480
 481 (defvar compilation-environment nil
 482   "*List of environment variables for compilation to inherit.
 483 Each element should be a string of the form ENVVARNAME=VALUE.
 484 This list is temporarily prepended to `process-environment' prior to
 485 starting the compilation process.")
 486
 487 ;; History of compile commands.
 488 (defvar compile-history nil)
 489
 490 (defface compilation-error
 491   '((t :inherit font-lock-warning-face))
 492   "Face used to highlight compiler errors."
 493   :group 'compilation
 494   :version "22.1")
 495
 496 (defface compilation-warning
 497   '((((class color) (min-colors 16)) (:foreground "Orange" :weight bold))
 498     (((class color)) (:foreground "cyan" :weight bold))
 499     (t (:weight bold)))
 500   "Face used to highlight compiler warnings."
 501   :group 'compilation
 502   :version "22.1")
 503
 504 (defface compilation-info
 505   '((((class color) (min-colors 16) (background light))
 506      (:foreground "Green3" :weight bold))
 507     (((class color) (min-colors 88) (background dark))
 508      (:foreground "Green1" :weight bold))
 509     (((class color) (min-colors 16) (background dark))
 510      (:foreground "Green" :weight bold))
 511     (((class color)) (:foreground "green" :weight bold))
 512     (t (:weight bold)))
 513   "Face used to highlight compiler information."
 514   :group 'compilation
 515   :version "22.1")
 516
 517 (defface compilation-line-number
 518   '((t :inherit font-lock-variable-name-face))
 519   "Face for displaying line numbers in compiler messages."
 520   :group 'compilation
 521   :version "22.1")
 522
 523 (defface compilation-column-number
 524   '((t :inherit font-lock-type-face))
 525   "Face for displaying column numbers in compiler messages."
 526   :group 'compilation
 527   :version "22.1")
 528
 529 (defvar compilation-message-face 'underline
 530   "Face name to use for whole messages.
 531 Faces `compilation-error-face', `compilation-warning-face',
 532 `compilation-info-face', `compilation-line-face' and
 533 `compilation-column-face' get prepended to this, when applicable.")
 534
 535 (defvar compilation-error-face 'compilation-error
 536   "Face name to use for file name in error messages.")
 537
 538 (defvar compilation-warning-face 'compilation-warning
 539   "Face name to use for file name in warning messages.")
 540
 541 (defvar compilation-info-face 'compilation-info
 542   "Face name to use for file name in informational messages.")
 543
 544 (defvar compilation-line-face 'compilation-line-number
 545   "Face name to use for line numbers in compiler messages.")
 546
 547 (defvar compilation-column-face 'compilation-column-number
 548   "Face name to use for column numbers in compiler messages.")
 549
 550 ;; same faces as dired uses
 551 (defvar compilation-enter-directory-face 'font-lock-function-name-face
 552   "Face name to use for entering directory messages.")
 553
 554 (defvar compilation-leave-directory-face 'font-lock-type-face
 555   "Face name to use for leaving directory messages.")
 556
 557
 558
 559 ;; Used for compatibility with the old compile.el.
 560 (defvaralias 'compilation-last-buffer 'next-error-last-buffer)
 561 (defvar compilation-parsing-end (make-marker))
 562 (defvar compilation-parse-errors-function nil)
 563 (defvar compilation-error-list nil)
 564 (defvar compilation-old-error-list nil)
 565
 566 (defun compilation-face (type)
 567   (or (and (car type) (match-end (car type)) compilation-warning-face)
 568       (and (cdr type) (match-end (cdr type)) compilation-info-face)
 569       compilation-error-face))
 570
 571 ;; Internal function for calculating the text properties of a directory
 572 ;; change message.  The directory property is important, because it is
 573 ;; the stack of nested enter-messages.  Relative filenames on the following
 574 ;; lines are relative to the top of the stack.
 575 (defun compilation-directory-properties (idx leave)
 576   (if leave (setq leave (match-end leave)))
 577   ;; find previous stack, and push onto it, or if `leave' pop it
 578   (let ((dir (previous-single-property-change (point) 'directory)))
 579     (setq dir (if dir (or (get-text-property (1- dir) 'directory)
 580                           (get-text-property dir 'directory))))
 581     `(face ,(if leave
 582                 compilation-leave-directory-face
 583               compilation-enter-directory-face)
 584       directory ,(if leave
 585                      (or (cdr dir)
 586                          '(nil))        ; nil only isn't a property-change
 587                    (cons (match-string-no-properties idx) dir))
 588       mouse-face highlight
 589       keymap compilation-button-map
 590       help-echo "mouse-2: visit current directory")))
 591
 592 ;; Data type `reverse-ordered-alist' retriever.  This function retrieves the
 593 ;; KEY element from the ALIST, creating it in the right position if not already
 594 ;; present. ALIST structure is
 595 ;; '(ANCHOR (KEY1 ...) (KEY2 ...)... (KEYn ALIST ...))
 596 ;; ANCHOR is ignored, but necessary so that elements can be inserted.  KEY1
 597 ;; may be nil.  The other KEYs are ordered backwards so that growing line
 598 ;; numbers can be inserted in front and searching can abort after half the
 599 ;; list on average.
 600 (eval-when-compile                  ;Don't keep it at runtime if not needed.
 601 (defmacro compilation-assq (key alist)
 602   `(let* ((l1 ,alist)
 603           (l2 (cdr l1)))
 604      (car (if (if (null ,key)
 605                   (if l2 (null (caar l2)))
 606                 (while (if l2 (if (caar l2) (< ,key (caar l2)) t))
 607                   (setq l1 l2
 608                         l2 (cdr l1)))
 609                 (if l2 (eq ,key (caar l2))))
 610               l2
 611             (setcdr l1 (cons (list ,key) l2)))))))
 612
 613
 614 ;; This function is the central driver, called when font-locking to gather
 615 ;; all information needed to later jump to corresponding source code.
 616 ;; Return a property list with all meta information on this error location.
 617
 618 (defun compilation-error-properties (file line end-line col end-col type fmt)
 619   (unless (< (next-single-property-change (match-beginning 0) 'directory nil (point))
 620              (point))
 621     (if file
 622         (if (functionp file)
 623             (setq file (funcall file))
 624           (let (dir)
 625             (setq file (match-string-no-properties file))
 626             (unless (file-name-absolute-p file)
 627               (setq dir (previous-single-property-change (point) 'directory)
 628                     dir (if dir (or (get-text-property (1- dir) 'directory)
 629                                     (get-text-property dir 'directory)))))
 630             (setq file (cons file (car dir)))))
 631       ;; This message didn't mention one, get it from previous
 632       (let ((prev-pos
 633              ;; Find the previous message.
 634              (previous-single-property-change (point) 'message)))
 635         (if prev-pos
 636             ;; Get the file structure that belongs to it.
 637             (let* ((prev
 638                     (or (get-text-property (1- prev-pos) 'message)
 639                         (get-text-property prev-pos 'message)))
 640                    (prev-struct
 641                     (car (nth 2 (car prev)))))
 642               ;; Construct FILE . DIR from that.
 643               (if prev-struct
 644                   (setq file (cons (car prev-struct)
 645                                    (cadr prev-struct))))))
 646         (unless file
 647           (setq file '("*unknown*")))))
 648     ;; All of these fields are optional, get them only if we have an index, and
 649     ;; it matched some part of the message.
 650     (and line
 651          (setq line (match-string-no-properties line))
 652          (setq line (string-to-number line)))
 653     (and end-line
 654          (setq end-line (match-string-no-properties end-line))
 655          (setq end-line (string-to-number end-line)))
 656     (if col
 657         (if (functionp col)
 658             (setq col (funcall col))
 659           (and
 660            (setq col (match-string-no-properties col))
 661            (setq col (- (string-to-number col) compilation-first-column)))))
 662     (if (and end-col (functionp end-col))
 663         (setq end-col (funcall end-col))
 664       (if (and end-col (setq end-col (match-string-no-properties end-col)))
 665           (setq end-col (- (string-to-number end-col) compilation-first-column -1))
 666         (if end-line (setq end-col -1))))
 667     (if (consp type)                    ; not a static type, check what it is.
 668         (setq type (or (and (car type) (match-end (car type)) 1)
 669                        (and (cdr type) (match-end (cdr type)) 0)
 670                        2)))
 671     (compilation-internal-error-properties file line end-line col end-col type fmt)))
 672
 673 (defun compilation-move-to-column (col screen)
 674   "Go to column COL on the current line.
 675 If SCREEN is non-nil, columns are screen columns, otherwise, they are
 676 just char-counts."
 677   (if screen
 678       (move-to-column col)
 679     (goto-char (min (+ (line-beginning-position) col) (line-end-position)))))
 680
 681 (defun compilation-internal-error-properties (file line end-line col end-col type fmts)
 682   "Get the meta-info that will be added as text-properties.
 683 LINE, END-LINE, COL, END-COL are integers or nil.
 684 TYPE can be 0, 1, or 2, meaning error, warning, or just info.
 685 FILE should be (FILENAME) or (RELATIVE-FILENAME . DIRNAME) or nil.
 686 FMTS is a list of format specs for transforming the file name.
 687  (See `compilation-error-regexp-alist'.)"
 688   (unless file (setq file '("*unknown*")))
 689   (let* ((file-struct (compilation-get-file-structure file fmts))
 690          ;; Get first already existing marker (if any has one, all have one).
 691          ;; Do this first, as the compilation-assq`s may create new nodes.
 692          (marker-line (car (cddr file-struct))) ; a line structure
 693          (marker (nth 3 (cadr marker-line)))    ; its marker
 694          (compilation-error-screen-columns compilation-error-screen-columns)
 695          end-marker loc end-loc)
 696     (if (not (and marker (marker-buffer marker)))
 697         (setq marker nil)               ; no valid marker for this file
 698       (setq loc (or line 1))            ; normalize no linenumber to line 1
 699       (catch 'marker                    ; find nearest loc, at least one exists
 700         (dolist (x (nthcdr 3 file-struct))      ; loop over remaining lines
 701           (if (> (car x) loc)           ; still bigger
 702               (setq marker-line x)
 703             (if (> (- (or (car marker-line) 1) loc)
 704                    (- loc (car x)))     ; current line is nearer
 705                 (setq marker-line x))
 706             (throw 'marker t))))
 707       (setq marker (nth 3 (cadr marker-line))
 708             marker-line (or (car marker-line) 1))
 709       (with-current-buffer (marker-buffer marker)
 710         (save-excursion
 711           (save-restriction
 712             (widen)
 713             (goto-char (marker-position marker))
 714             (when (or end-col end-line)
 715               (beginning-of-line (- (or end-line line) marker-line -1))
 716               (if (or (null end-col) (< end-col 0))
 717                   (end-of-line)
 718                 (compilation-move-to-column
 719                  end-col compilation-error-screen-columns))
 720               (setq end-marker (list (point-marker))))
 721             (beginning-of-line (if end-line
 722                                    (- line end-line -1)
 723                                  (- loc marker-line -1)))
 724             (if col
 725                 (compilation-move-to-column
 726                  col compilation-error-screen-columns)
 727               (forward-to-indentation 0))
 728             (setq marker (list (point-marker)))))))
 729
 730     (setq loc (compilation-assq line (cdr file-struct)))
 731     (if end-line
 732         (setq end-loc (compilation-assq end-line (cdr file-struct))
 733               end-loc (compilation-assq end-col end-loc))
 734       (if end-col                       ; use same line element
 735           (setq end-loc (compilation-assq end-col loc))))
 736     (setq loc (compilation-assq col loc))
 737     ;; If they are new, make the loc(s) reference the file they point to.
 738     (or (cdr loc) (setcdr loc `(,line ,file-struct ,@marker)))
 739     (if end-loc
 740         (or (cdr end-loc)
 741             (setcdr end-loc `(,(or end-line line) ,file-struct ,@end-marker))))
 742
 743     ;; Must start with face
 744     `(face ,compilation-message-face
 745            message (,loc ,type ,end-loc)
 746            ,@(if compilation-debug
 747                  `(debug (,(assoc (with-no-warnings matcher) font-lock-keywords)
 748                           ,@(match-data))))
 749            help-echo ,(if col
 750                           "mouse-2: visit this file, line and column"
 751                         (if line
 752                             "mouse-2: visit this file and line"
 753                           "mouse-2: visit this file"))
 754            keymap compilation-button-map
 755            mouse-face highlight)))
 756
 757 (defun compilation-mode-font-lock-keywords ()
 758   "Return expressions to highlight in Compilation mode."
 759   (if compilation-parse-errors-function
 760       ;; An old package!  Try the compatibility code.
 761       '((compilation-compat-parse-errors))
 762     (append
 763      ;; make directory tracking
 764      (if compilation-directory-matcher
 765          `((,(car compilation-directory-matcher)
 766             ,@(mapcar (lambda (elt)
 767                         `(,(car elt)
 768                           (compilation-directory-properties
 769                            ,(car elt) ,(cdr elt))
 770                           t t))
 771                       (cdr compilation-directory-matcher)))))
 772
 773      ;; Compiler warning/error lines.
 774      (mapcar
 775       (lambda (item)
 776         (if (symbolp item)
 777             (setq item (cdr (assq item
 778                                   compilation-error-regexp-alist-alist))))
 779         (let ((file (nth 1 item))
 780               (line (nth 2 item))
 781               (col (nth 3 item))
 782               (type (nth 4 item))
 783               end-line end-col fmt)
 784           (if (consp file)      (setq fmt (cdr file)      file (car file)))
 785           (if (consp line)      (setq end-line (cdr line) line (car line)))
 786           (if (consp col)       (setq end-col (cdr col)   col (car col)))
 787
 788           (if (functionp line)
 789               ;; The old compile.el had here an undocumented hook that
 790               ;; allowed `line' to be a function that computed the actual
 791               ;; error location.  Let's do our best.
 792               `(,(car item)
 793                 (0 (save-match-data
 794                      (compilation-compat-error-properties
 795                       (funcall ',line (cons (match-string ,file)
 796                                             (cons default-directory
 797                                                   ',(nthcdr 4 item)))
 798                                ,(if col `(match-string ,col))))))
 799                 (,file compilation-error-face t))
 800
 801             (unless (or (null (nth 5 item)) (integerp (nth 5 item)))
 802               (error "HYPERLINK should be an integer: %s" (nth 5 item)))
 803
 804             `(,(nth 0 item)
 805
 806               ,@(when (integerp file)
 807                   `((,file ,(if (consp type)
 808                                 `(compilation-face ',type)
 809                               (aref [compilation-info-face
 810                                      compilation-warning-face
 811                                      compilation-error-face]
 812                                     (or type 2))))))
 813
 814               ,@(when line
 815                   `((,line compilation-line-face nil t)))
 816               ,@(when end-line
 817                   `((,end-line compilation-line-face nil t)))
 818
 819               ,@(when (integerp col)
 820                   `((,col compilation-column-face nil t)))
 821               ,@(when (integerp end-col)
 822                   `((,end-col compilation-column-face nil t)))
 823
 824               ,@(nthcdr 6 item)
 825               (,(or (nth 5 item) 0)
 826                (compilation-error-properties ',file ,line ,end-line
 827                                              ,col ,end-col ',(or type 2)
 828                                              ',fmt)
 829                append)))))              ; for compilation-message-face
 830       compilation-error-regexp-alist)
 831
 832      compilation-mode-font-lock-keywords)))
 833
 834 \f
 835 ;;;###autoload
 836 (defun compile (command &optional comint)
 837   "Compile the program including the current buffer.  Default: run `make'.
 838 Runs COMMAND, a shell command, in a separate process asynchronously
 839 with output going to the buffer `*compilation*'.
 840
 841 If optional second arg COMINT is t the buffer will be in Comint mode with
 842 `compilation-shell-minor-mode'.
 843
 844 You can then use the command \\[next-error] to find the next error message
 845 and move to the source code that caused it.
 846
 847 Interactively, prompts for the command if `compilation-read-command' is
 848 non-nil; otherwise uses `compile-command'.  With prefix arg, always prompts.
 849 Additionally, with universal prefix arg, compilation buffer will be in
 850 comint mode, i.e. interactive.
 851
 852 To run more than one compilation at once, start one and rename
 853 the \`*compilation*' buffer to some other name with
 854 \\[rename-buffer].  Then start the next one.  On most systems,
 855 termination of the main compilation process kills its
 856 subprocesses.
 857
 858 The name used for the buffer is actually whatever is returned by
 859 the function in `compilation-buffer-name-function', so you can set that
 860 to a function that generates a unique name."
 861   (interactive
 862    (list
 863     (let ((command (eval compile-command)))
 864       (if (or compilation-read-command current-prefix-arg)
 865           (read-from-minibuffer "Compile command: "
 866                                 command nil nil
 867                                 (if (equal (car compile-history) command)
 868                                     '(compile-history . 1)
 869                                   'compile-history))
 870         command))
 871     (consp current-prefix-arg)))
 872   (unless (equal command (eval compile-command))
 873     (setq compile-command command))
 874   (save-some-buffers (not compilation-ask-about-save) nil)
 875   (setq compilation-directory default-directory)
 876   (compilation-start command comint))
 877
 878 ;; run compile with the default command line
 879 (defun recompile ()
 880   "Re-compile the program including the current buffer.
 881 If this is run in a Compilation mode buffer, re-use the arguments from the
 882 original use.  Otherwise, recompile using `compile-command'."
 883   (interactive)
 884   (save-some-buffers (not compilation-ask-about-save) nil)
 885   (let ((default-directory
 886           (or (and (not (eq major-mode (nth 1 compilation-arguments)))
 887                    compilation-directory)
 888               default-directory)))
 889     (apply 'compilation-start (or compilation-arguments
 890                                   `(,(eval compile-command))))))
 891
 892 (defcustom compilation-scroll-output nil
 893   "*Non-nil to scroll the *compilation* buffer window as output appears.
 894
 895 Setting it causes the Compilation mode commands to put point at the
 896 end of their output window so that the end of the output is always
 897 visible rather than the beginning."
 898   :type 'boolean
 899   :version "20.3"
 900   :group 'compilation)
 901
 902
 903 (defun compilation-buffer-name (mode-name mode-command name-function)
 904   "Return the name of a compilation buffer to use.
 905 If NAME-FUNCTION is non-nil, call it with one argument MODE-NAME
 906 to determine the buffer name.
 907 Likewise if `compilation-buffer-name-function' is non-nil.
 908 If current buffer is the mode MODE-COMMAND,
 909 return the name of the current buffer, so that it gets reused.
 910 Otherwise, construct a buffer name from MODE-NAME."
 911   (cond (name-function
 912          (funcall name-function mode-name))
 913         (compilation-buffer-name-function
 914          (funcall compilation-buffer-name-function mode-name))
 915         ((and (eq mode-command major-mode)
 916               (eq major-mode (nth 1 compilation-arguments)))
 917          (buffer-name))
 918         (t
 919          (concat "*" (downcase mode-name) "*"))))
 920
 921 ;; This is a rough emulation of the old hack, until the transition to new
 922 ;; compile is complete.
 923 (defun compile-internal (command error-message
 924                                  &optional name-of-mode parser
 925                                  error-regexp-alist name-function
 926                                  enter-regexp-alist leave-regexp-alist
 927                                  file-regexp-alist nomessage-regexp-alist
 928                                  no-async highlight-regexp local-map)
 929   (if parser
 930       (error "Compile now works very differently, see `compilation-error-regexp-alist'"))
 931   (let ((compilation-error-regexp-alist
 932          (append file-regexp-alist (or error-regexp-alist
 933                                        compilation-error-regexp-alist)))
 934         (compilation-error (replace-regexp-in-string "^No more \\(.+\\)s\\.?"
 935                                                      "\\1" error-message)))
 936     (compilation-start command nil name-function highlight-regexp)))
 937 (make-obsolete 'compile-internal 'compilation-start)
 938
 939 ;;;###autoload
 940 (defun compilation-start (command &optional mode name-function highlight-regexp)
 941   "Run compilation command COMMAND (low level interface).
 942 If COMMAND starts with a cd command, that becomes the `default-directory'.
 943 The rest of the arguments are optional; for them, nil means use the default.
 944
 945 MODE is the major mode to set in the compilation buffer.  Mode
 946 may also be t meaning use `compilation-shell-minor-mode' under `comint-mode'.
 947 If NAME-FUNCTION is non-nil, call it with one argument (the mode name)
 948 to determine the buffer name.
 949
 950 If HIGHLIGHT-REGEXP is non-nil, `next-error' will temporarily highlight
 951 the matching section of the visited source line; the default is to use the
 952 global value of `compilation-highlight-regexp'.
 953
 954 Returns the compilation buffer created."
 955   (or mode (setq mode 'compilation-mode))
 956   (let* ((name-of-mode
 957           (if (eq mode t)
 958               (prog1 "compilation" (require 'comint))
 959             (replace-regexp-in-string "-mode$" "" (symbol-name mode))))
 960          (thisdir default-directory)
 961          outwin outbuf)
 962     (with-current-buffer
 963         (setq outbuf
 964               (get-buffer-create
 965                (compilation-buffer-name name-of-mode mode name-function)))
 966       (let ((comp-proc (get-buffer-process (current-buffer))))
 967         (if comp-proc
 968             (if (or (not (eq (process-status comp-proc) 'run))
 969                     (yes-or-no-p
 970                      (format "A %s process is running; kill it? "
 971                              name-of-mode)))
 972                 (condition-case ()
 973                     (progn
 974                       (interrupt-process comp-proc)
 975                       (sit-for 1)
 976                       (delete-process comp-proc))
 977                   (error nil))
 978               (error "Cannot have two processes in `%s' at once"
 979                      (buffer-name)))))
 980       (buffer-disable-undo (current-buffer))
 981       ;; first transfer directory from where M-x compile was called
 982       (setq default-directory thisdir)
 983       ;; Make compilation buffer read-only.  The filter can still write it.
 984       ;; Clear out the compilation buffer.
 985       (let ((inhibit-read-only t)
 986             (default-directory thisdir))
 987         ;; Then evaluate a cd command if any, but don't perform it yet, else start-command
 988         ;; would do it again through the shell: (cd "..") AND sh -c "cd ..; make"
 989         (cd (if (string-match "^\\s *cd\\(?:\\s +\\(\\S +?\\)\\)?\\s *[;&\n]" command)
 990                 (if (match-end 1)
 991                     (substitute-env-vars (match-string 1 command))
 992                   "~")
 993               default-directory))
 994         (erase-buffer)
 995         ;; Select the desired mode.
 996         (if (not (eq mode t))
 997             (funcall mode)
 998           (setq buffer-read-only nil)
 999           (with-no-warnings (comint-mode))
1000           (compilation-shell-minor-mode))
1001         (if highlight-regexp
1002             (set (make-local-variable 'compilation-highlight-regexp)
1003                  highlight-regexp))
1004         ;; Output a mode setter, for saving and later reloading this buffer.
1005         (insert "-*- mode: " name-of-mode
1006                 "; default-directory: " (prin1-to-string default-directory)
1007                 " -*-\n"
1008                 (format "%s started at %s\n\n"
1009                         mode-name
1010                         (substring (current-time-string) 0 19))
1011                 command "\n")
1012         (setq thisdir default-directory))
1013       (set-buffer-modified-p nil))
1014     ;; If we're already in the compilation buffer, go to the end
1015     ;; of the buffer, so point will track the compilation output.
1016     (if (eq outbuf (current-buffer))
1017         (goto-char (point-max)))
1018     ;; Pop up the compilation buffer.
1019     (setq outwin (display-buffer outbuf nil t))
1020     (with-current-buffer outbuf
1021       (let ((process-environment
1022              (append
1023               compilation-environment
1024               (if (if (boundp 'system-uses-terminfo) ; `if' for compiler warning
1025                       system-uses-terminfo)
1026                   (list "TERM=dumb" "TERMCAP="
1027                         (format "COLUMNS=%d" (window-width)))
1028                 (list "TERM=emacs"
1029                       (format "TERMCAP=emacs:co#%d:tc=unknown:"
1030                               (window-width))))
1031               ;; Set the EMACS variable, but
1032               ;; don't override users' setting of $EMACS.
1033               (unless (getenv "EMACS") '("EMACS=t"))
1034               (copy-sequence process-environment))))
1035         (set (make-local-variable 'compilation-arguments)
1036              (list command mode name-function highlight-regexp))
1037         (set (make-local-variable 'revert-buffer-function)
1038              'compilation-revert-buffer)
1039         (set-window-start outwin (point-min))
1040         (or (eq outwin (selected-window))
1041             (set-window-point outwin (if compilation-scroll-output
1042                                          (point)
1043                                        (point-min))))
1044         ;; The setup function is called before compilation-set-window-height
1045         ;; so it can set the compilation-window-height buffer locally.
1046         (if compilation-process-setup-function
1047             (funcall compilation-process-setup-function))
1048         (compilation-set-window-height outwin)
1049         ;; Start the compilation.
1050         (if (fboundp 'start-process)
1051             (let ((proc (if (eq mode t)
1052                             (get-buffer-process
1053                              (with-no-warnings
1054                               (comint-exec outbuf (downcase mode-name)
1055                                            shell-file-name nil `("-c" ,command))))
1056                           (start-process-shell-command (downcase mode-name)
1057                                                        outbuf command))))
1058               ;; Make the buffer's mode line show process state.
1059               (setq mode-line-process '(":%s"))
1060               (set-process-sentinel proc 'compilation-sentinel)
1061               (set-process-filter proc 'compilation-filter)
1062               (set-marker (process-mark proc) (point) outbuf)
1063               (when compilation-disable-input
1064                 (condition-case nil
1065                     (process-send-eof proc)
1066                   ;; The process may have exited already.
1067                   (error nil)))
1068               (setq compilation-in-progress
1069                     (cons proc compilation-in-progress)))
1070           ;; No asynchronous processes available.
1071           (message "Executing `%s'..." command)
1072           ;; Fake modeline display as if `start-process' were run.
1073           (setq mode-line-process ":run")
1074           (force-mode-line-update)
1075           (sit-for 0)                   ; Force redisplay
1076           (let* ((buffer-read-only nil) ; call-process needs to modify outbuf
1077                  (status (call-process shell-file-name nil outbuf nil "-c"
1078                                        command)))
1079             (cond ((numberp status)
1080                    (compilation-handle-exit 'exit status
1081                                             (if (zerop status)
1082                                                 "finished\n"
1083                                               (format "\
1084 exited abnormally with code %d\n"
1085                                                       status))))
1086                   ((stringp status)
1087                    (compilation-handle-exit 'signal status
1088                                             (concat status "\n")))
1089                   (t
1090                    (compilation-handle-exit 'bizarre status status))))
1091           ;; Without async subprocesses, the buffer is not yet
1092           ;; fontified, so fontify it now.
1093           (let ((font-lock-verbose nil)) ; shut up font-lock messages
1094             (font-lock-fontify-buffer))
1095           (set-buffer-modified-p nil)
1096           (message "Executing `%s'...done" command)))
1097       ;; Now finally cd to where the shell started make/grep/...
1098       (setq default-directory thisdir))
1099     (if (buffer-local-value 'compilation-scroll-output outbuf)
1100         (save-selected-window
1101           (select-window outwin)
1102           (goto-char (point-max))))
1103     ;; Make it so the next C-x ` will use this buffer.
1104     (setq next-error-last-buffer outbuf)))
1105
1106 (defun compilation-set-window-height (window)
1107   "Set the height of WINDOW according to `compilation-window-height'."
1108   (let ((height (buffer-local-value 'compilation-window-height (window-buffer window))))
1109     (and height
1110          (= (window-width window) (frame-width (window-frame window)))
1111          ;; If window is alone in its frame, aside from a minibuffer,
1112          ;; don't change its height.
1113          (not (eq window (frame-root-window (window-frame window))))
1114          ;; Stef said that doing the saves in this order is safer:
1115          (save-excursion
1116            (save-selected-window
1117              (select-window window)
1118              (enlarge-window (- height (window-height))))))))
1119
1120 (defvar compilation-menu-map
1121   (let ((map (make-sparse-keymap "Errors")))
1122     (define-key map [stop-subjob]
1123       '("Stop Compilation" . kill-compilation))
1124     (define-key map [compilation-mode-separator2]
1125       '("----" . nil))
1126     (define-key map [compilation-first-error]
1127       '("First Error" . first-error))
1128     (define-key map [compilation-previous-error]
1129       '("Previous Error" . previous-error))
1130     (define-key map [compilation-next-error]
1131       '("Next Error" . next-error))
1132     map))
1133
1134 (defvar compilation-minor-mode-map
1135   (let ((map (make-sparse-keymap)))
1136     (define-key map [mouse-2] 'compile-goto-error)
1137     (define-key map [follow-link] 'mouse-face)
1138     (define-key map "\C-c\C-c" 'compile-goto-error)
1139     (define-key map "\C-m" 'compile-goto-error)
1140     (define-key map "\C-c\C-k" 'kill-compilation)
1141     (define-key map "\M-n" 'compilation-next-error)
1142     (define-key map "\M-p" 'compilation-previous-error)
1143     (define-key map "\M-{" 'compilation-previous-file)
1144     (define-key map "\M-}" 'compilation-next-file)
1145     ;; Set up the menu-bar
1146     (define-key map [menu-bar compilation]
1147       (cons "Errors" compilation-menu-map))
1148     map)
1149   "Keymap for `compilation-minor-mode'.")
1150
1151 (defvar compilation-shell-minor-mode-map
1152   (let ((map (make-sparse-keymap)))
1153     (define-key map "\M-\C-m" 'compile-goto-error)
1154     (define-key map "\M-\C-n" 'compilation-next-error)
1155     (define-key map "\M-\C-p" 'compilation-previous-error)
1156     (define-key map "\M-{" 'compilation-previous-file)
1157     (define-key map "\M-}" 'compilation-next-file)
1158     ;; Set up the menu-bar
1159     (define-key map [menu-bar compilation]
1160       (cons "Errors" compilation-menu-map))
1161     map)
1162   "Keymap for `compilation-shell-minor-mode'.")
1163
1164 (defvar compilation-button-map
1165   (let ((map (make-sparse-keymap)))
1166     (define-key map [mouse-2] 'compile-goto-error)
1167     (define-key map [follow-link] 'mouse-face)
1168     (define-key map "\C-m" 'compile-goto-error)
1169     map)
1170   "Keymap for compilation-message buttons.")
1171 (fset 'compilation-button-map compilation-button-map)
1172
1173 (defvar compilation-mode-map
1174   (let ((map (make-sparse-keymap)))
1175     ;; Don't inherit from compilation-minor-mode-map,
1176     ;; because that introduces a menu bar item we don't want.
1177     ;; That confuses C-down-mouse-3.
1178     (define-key map [mouse-2] 'compile-goto-error)
1179     (define-key map [follow-link] 'mouse-face)
1180     (define-key map "\C-c\C-c" 'compile-goto-error)
1181     (define-key map "\C-m" 'compile-goto-error)
1182     (define-key map "\C-c\C-k" 'kill-compilation)
1183     (define-key map "\M-n" 'compilation-next-error)
1184     (define-key map "\M-p" 'compilation-previous-error)
1185     (define-key map "\M-{" 'compilation-previous-file)
1186     (define-key map "\M-}" 'compilation-next-file)
1187     (define-key map "\t" 'compilation-next-error)
1188     (define-key map [backtab] 'compilation-previous-error)
1189
1190     (define-key map " " 'scroll-up)
1191     (define-key map "\^?" 'scroll-down)
1192     (define-key map "\C-c\C-f" 'next-error-follow-minor-mode)
1193
1194     ;; Set up the menu-bar
1195     (let ((submap (make-sparse-keymap "Compile")))
1196       (define-key map [menu-bar compilation]
1197         (cons "Compile" submap))
1198       (set-keymap-parent submap compilation-menu-map))
1199     (define-key map [menu-bar compilation compilation-separator2]
1200       '("----" . nil))
1201     (define-key map [menu-bar compilation compilation-grep]
1202       '("Search Files (grep)..." . grep))
1203     (define-key map [menu-bar compilation compilation-recompile]
1204       '("Recompile" . recompile))
1205     (define-key map [menu-bar compilation compilation-compile]
1206       '("Compile..." . compile))
1207     map)
1208   "Keymap for compilation log buffers.
1209 `compilation-minor-mode-map' is a parent of this.")
1210
1211 (put 'compilation-mode 'mode-class 'special)
1212
1213 (defvar compilation-skip-to-next-location t
1214   "*If non-nil, skip multiple error messages for the same source location.")
1215
1216 (defcustom compilation-skip-threshold 1
1217   "*Compilation motion commands skip less important messages.
1218 The value can be either 2 -- skip anything less than error, 1 --
1219 skip anything less than warning or 0 -- don't skip any messages.
1220 Note that all messages not positively identified as warning or
1221 info, are considered errors."
1222   :type '(choice (const :tag "Warnings and info" 2)
1223                  (const :tag "Info" 1)
1224                  (const :tag "None" 0))
1225   :group 'compilation
1226   :version "22.1")
1227
1228 (defcustom compilation-skip-visited nil
1229   "*Compilation motion commands skip visited messages if this is t.
1230 Visited messages are ones for which the file, line and column have been jumped
1231 to from the current content in the current compilation buffer, even if it was
1232 from a different message."
1233   :type 'boolean
1234   :group 'compilation
1235   :version "22.1")
1236
1237 ;;;###autoload
1238 (defun compilation-mode (&optional name-of-mode)
1239   "Major mode for compilation log buffers.
1240 \\<compilation-mode-map>To visit the source for a line-numbered error,
1241 move point to the error message line and type \\[compile-goto-error].
1242 To kill the compilation, type \\[kill-compilation].
1243
1244 Runs `compilation-mode-hook' with `run-mode-hooks' (which see).
1245
1246 \\{compilation-mode-map}"
1247   (interactive)
1248   (kill-all-local-variables)
1249   (use-local-map compilation-mode-map)
1250   (setq major-mode 'compilation-mode
1251         mode-name (or name-of-mode "Compilation"))
1252   (set (make-local-variable 'page-delimiter)
1253        compilation-page-delimiter)
1254   (compilation-setup)
1255   (setq buffer-read-only t)
1256   (run-mode-hooks 'compilation-mode-hook))
1257
1258 (defmacro define-compilation-mode (mode name doc &rest body)
1259   "This is like `define-derived-mode' without the PARENT argument.
1260 The parent is always `compilation-mode' and the customizable `compilation-...'
1261 variables are also set from the name of the mode you have chosen,
1262 by replacing the first word, e.g `compilation-scroll-output' from
1263 `grep-scroll-output' if that variable exists."
1264   (let ((mode-name (replace-regexp-in-string "-mode\\'" "" (symbol-name mode))))
1265     `(define-derived-mode ,mode compilation-mode ,name
1266        ,doc
1267        ,@(mapcar (lambda (v)
1268                    (setq v (cons v
1269                                  (intern-soft (replace-regexp-in-string
1270                                                "^compilation" mode-name
1271                                                (symbol-name v)))))
1272                    (and (cdr v)
1273                         (or (boundp (cdr v))
1274                             (if (boundp 'byte-compile-bound-variables)
1275                                 (memq (cdr v) byte-compile-bound-variables)))
1276                         `(set (make-local-variable ',(car v)) ,(cdr v))))
1277                  '(compilation-buffer-name-function
1278                    compilation-directory-matcher
1279                    compilation-error
1280                    compilation-error-regexp-alist
1281                    compilation-error-regexp-alist-alist
1282                    compilation-error-screen-columns
1283                    compilation-finish-function
1284                    compilation-finish-functions
1285                    compilation-first-column
1286                    compilation-mode-font-lock-keywords
1287                    compilation-page-delimiter
1288                    compilation-parse-errors-filename-function
1289                    compilation-process-setup-function
1290                    compilation-scroll-output
1291                    compilation-search-path
1292                    compilation-skip-threshold
1293                    compilation-window-height))
1294        ,@body)))
1295
1296 (defun compilation-revert-buffer (ignore-auto noconfirm)
1297   (if buffer-file-name
1298       (let (revert-buffer-function)
1299         (revert-buffer ignore-auto noconfirm))
1300     (if (or noconfirm (yes-or-no-p (format "Restart compilation? ")))
1301         (apply 'compilation-start compilation-arguments))))
1302
1303 (defvar compilation-current-error nil
1304   "Marker to the location from where the next error will be found.
1305 The global commands next/previous/first-error/goto-error use this.")
1306
1307 (defvar compilation-messages-start nil
1308   "Buffer position of the beginning of the compilation messages.
1309 If nil, use the beginning of buffer.")
1310
1311 ;; A function name can't be a hook, must be something with a value.
1312 (defconst compilation-turn-on-font-lock 'turn-on-font-lock)
1313
1314 (defun compilation-setup (&optional minor)
1315   "Prepare the buffer for the compilation parsing commands to work.
1316 Optional argument MINOR indicates this is called from
1317 `compilation-minor-mode'."
1318   (make-local-variable 'compilation-current-error)
1319   (make-local-variable 'compilation-messages-start)
1320   (make-local-variable 'compilation-error-screen-columns)
1321   (make-local-variable 'overlay-arrow-position)
1322   (set (make-local-variable 'overlay-arrow-string) "")
1323   (setq next-error-overlay-arrow-position nil)
1324   (add-hook 'kill-buffer-hook
1325             (lambda () (setq next-error-overlay-arrow-position nil)) nil t)
1326   ;; Note that compilation-next-error-function is for interfacing
1327   ;; with the next-error function in simple.el, and it's only
1328   ;; coincidentally named similarly to compilation-next-error.
1329   (setq next-error-function 'compilation-next-error-function)
1330   (set (make-local-variable 'font-lock-extra-managed-props)
1331        '(directory message help-echo mouse-face debug))
1332   (set (make-local-variable 'compilation-locs)
1333        (make-hash-table :test 'equal :weakness 'value))
1334   ;; lazy-lock would never find the message unless it's scrolled to.
1335   ;; jit-lock might fontify some things too late.
1336   (set (make-local-variable 'font-lock-support-mode) nil)
1337   (set (make-local-variable 'font-lock-maximum-size) nil)
1338   (let ((fld font-lock-defaults))
1339     (if (and minor fld)
1340         (font-lock-add-keywords nil (compilation-mode-font-lock-keywords))
1341       (setq font-lock-defaults '(compilation-mode-font-lock-keywords t)))
1342     (if minor
1343         (if font-lock-mode
1344             (if fld
1345                 (font-lock-fontify-buffer)
1346               (font-lock-change-mode)
1347               (turn-on-font-lock))
1348           (turn-on-font-lock))
1349       ;; maybe defer font-lock till after derived mode is set up
1350       (run-mode-hooks 'compilation-turn-on-font-lock))))
1351
1352 ;;;###autoload
1353 (define-minor-mode compilation-shell-minor-mode
1354   "Toggle compilation shell minor mode.
1355 With arg, turn compilation mode on if and only if arg is positive.
1356 In this minor mode, all the error-parsing commands of the
1357 Compilation major mode are available but bound to keys that don't
1358 collide with Shell mode.  See `compilation-mode'.
1359 Turning the mode on runs the normal hook `compilation-shell-minor-mode-hook'."
1360   nil " Shell-Compile"
1361   :group 'compilation
1362   (if compilation-shell-minor-mode
1363       (compilation-setup t)
1364     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1365     (font-lock-fontify-buffer)))
1366
1367 ;;;###autoload
1368 (define-minor-mode compilation-minor-mode
1369   "Toggle compilation minor mode.
1370 With arg, turn compilation mode on if and only if arg is positive.
1371 In this minor mode, all the error-parsing commands of the
1372 Compilation major mode are available.  See `compilation-mode'.
1373 Turning the mode on runs the normal hook `compilation-minor-mode-hook'."
1374   nil " Compilation"
1375   :group 'compilation
1376   (if compilation-minor-mode
1377       (compilation-setup t)
1378     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1379     (font-lock-fontify-buffer)))
1380
1381 (defun compilation-handle-exit (process-status exit-status msg)
1382   "Write MSG in the current buffer and hack its mode-line-process."
1383   (let ((inhibit-read-only t)
1384         (status (if compilation-exit-message-function
1385                     (funcall compilation-exit-message-function
1386                              process-status exit-status msg)
1387                   (cons msg exit-status)))
1388         (omax (point-max))
1389         (opoint (point)))
1390     ;; Record where we put the message, so we can ignore it later on.
1391     (goto-char omax)
1392     (insert ?\n mode-name " " (car status))
1393     (if (and (numberp compilation-window-height)
1394              (zerop compilation-window-height))
1395         (message "%s" (cdr status)))
1396     (if (bolp)
1397         (forward-char -1))
1398     (insert " at " (substring (current-time-string) 0 19))
1399     (goto-char (point-max))
1400     ;; Prevent that message from being recognized as a compilation error.
1401     (add-text-properties omax (point)
1402                          (append '(compilation-handle-exit t) nil))
1403     (setq mode-line-process (format ":%s [%s]" process-status (cdr status)))
1404     ;; Force mode line redisplay soon.
1405     (force-mode-line-update)
1406     (if (and opoint (< opoint omax))
1407         (goto-char opoint))
1408     (with-no-warnings
1409       (if compilation-finish-function
1410           (funcall compilation-finish-function (current-buffer) msg)))
1411     (let ((functions compilation-finish-functions))
1412       (while functions
1413         (funcall (car functions) (current-buffer) msg)
1414         (setq functions (cdr functions))))))
1415
1416 ;; Called when compilation process changes state.
1417 (defun compilation-sentinel (proc msg)
1418   "Sentinel for compilation buffers."
1419   (if (memq (process-status proc) '(exit signal))
1420       (let ((buffer (process-buffer proc)))
1421         (if (null (buffer-name buffer))
1422             ;; buffer killed
1423             (set-process-buffer proc nil)
1424           (with-current-buffer buffer
1425             ;; Write something in the compilation buffer
1426             ;; and hack its mode line.
1427             (compilation-handle-exit (process-status proc)
1428                                      (process-exit-status proc)
1429                                      msg)
1430             ;; Since the buffer and mode line will show that the
1431             ;; process is dead, we can delete it now.  Otherwise it
1432             ;; will stay around until M-x list-processes.
1433             (delete-process proc)))
1434         (setq compilation-in-progress (delq proc compilation-in-progress)))))
1435
1436 (defun compilation-filter (proc string)
1437   "Process filter for compilation buffers.
1438 Just inserts the text, but uses `insert-before-markers'."
1439   (if (buffer-name (process-buffer proc))
1440       (with-current-buffer (process-buffer proc)
1441         (let ((inhibit-read-only t))
1442           (save-excursion
1443             (goto-char (process-mark proc))
1444             (insert-before-markers string)
1445             (run-hooks 'compilation-filter-hook))))))
1446
1447 ;;; test if a buffer is a compilation buffer, assuming we're in the buffer
1448 (defsubst compilation-buffer-internal-p ()
1449   "Test if inside a compilation buffer."
1450   (local-variable-p 'compilation-locs))
1451
1452 ;;; test if a buffer is a compilation buffer, using compilation-buffer-internal-p
1453 (defsubst compilation-buffer-p (buffer)
1454   "Test if BUFFER is a compilation buffer."
1455   (with-current-buffer buffer
1456     (compilation-buffer-internal-p)))
1457
1458 (defmacro compilation-loop (< property-change 1+ error)
1459   `(while (,< n 0)
1460       (or (setq pt (,property-change pt 'message))
1461           (error ,error compilation-error))
1462       ;; prop 'message usually has 2 changes, on and off, so re-search if off
1463       (or (setq msg (get-text-property pt 'message))
1464           (if (setq pt (,property-change pt 'message))
1465               (setq msg (get-text-property pt 'message)))
1466           (error ,error compilation-error))
1467       (or (< (cadr msg) compilation-skip-threshold)
1468           (if different-file
1469               (eq (prog1 last (setq last (nth 2 (car msg))))
1470                   last))
1471           (if compilation-skip-visited
1472               (nthcdr 4 (car msg)))
1473           (if compilation-skip-to-next-location
1474               (eq (car msg) loc))
1475           ;; count this message only if none of the above are true
1476           (setq n (,1+ n)))))
1477
1478 (defun compilation-next-error (n &optional different-file pt)
1479   "Move point to the next error in the compilation buffer.
1480 Prefix arg N says how many error messages to move forwards (or
1481 backwards, if negative).
1482 Does NOT find the source line like \\[next-error]."
1483   (interactive "p")
1484   (or (compilation-buffer-p (current-buffer))
1485       (error "Not in a compilation buffer"))
1486   (or pt (setq pt (point)))
1487   (let* ((msg (get-text-property pt 'message))
1488          (loc (car msg))
1489          last)
1490     (if (zerop n)
1491         (unless (or msg                 ; find message near here
1492                     (setq msg (get-text-property (max (1- pt) (point-min))
1493                                                  'message)))
1494           (setq pt (previous-single-property-change pt 'message nil
1495                                                     (line-beginning-position)))
1496           (unless (setq msg (get-text-property (max (1- pt) (point-min)) 'message))
1497             (setq pt (next-single-property-change pt 'message nil
1498                                                   (line-end-position)))
1499             (or (setq msg (get-text-property pt 'message))
1500                 (setq pt (point)))))
1501       (setq last (nth 2 (car msg)))
1502       (if (>= n 0)
1503           (compilation-loop > next-single-property-change 1-
1504                             (if (get-buffer-process (current-buffer))
1505                                 "No more %ss yet"
1506                               "Moved past last %s"))
1507         ;; Don't move "back" to message at or before point.
1508         ;; Pass an explicit (point-min) to make sure pt is non-nil.
1509         (setq pt (previous-single-property-change pt 'message nil (point-min)))
1510         (compilation-loop < previous-single-property-change 1+
1511                           "Moved back before first %s")))
1512     (goto-char pt)
1513     (or msg
1514         (error "No %s here" compilation-error))))
1515
1516 (defun compilation-previous-error (n)
1517   "Move point to the previous error in the compilation buffer.
1518 Prefix arg N says how many error messages to move backwards (or
1519 forwards, if negative).
1520 Does NOT find the source line like \\[previous-error]."
1521   (interactive "p")
1522   (compilation-next-error (- n)))
1523
1524 (defun compilation-next-file (n)
1525   "Move point to the next error for a different file than the current one.
1526 Prefix arg N says how many files to move forwards (or backwards, if negative)."
1527   (interactive "p")
1528   (compilation-next-error n t))
1529
1530 (defun compilation-previous-file (n)
1531   "Move point to the previous error for a different file than the current one.
1532 Prefix arg N says how many files to move backwards (or forwards, if negative)."
1533   (interactive "p")
1534   (compilation-next-file (- n)))
1535
1536 (defun kill-compilation ()
1537   "Kill the process made by the \\[compile] or \\[grep] commands."
1538   (interactive)
1539   (let ((buffer (compilation-find-buffer)))
1540     (if (get-buffer-process buffer)
1541         (interrupt-process (get-buffer-process buffer))
1542       (error "The %s process is not running" (downcase mode-name)))))
1543
1544 (defalias 'compile-mouse-goto-error 'compile-goto-error)
1545
1546 (defun compile-goto-error (&optional event)
1547   "Visit the source for the error message at point.
1548 Use this command in a compilation log buffer.  Sets the mark at point there."
1549   (interactive (list last-input-event))
1550   (if event (posn-set-point (event-end event)))
1551   (or (compilation-buffer-p (current-buffer))
1552       (error "Not in a compilation buffer"))
1553   (if (get-text-property (point) 'directory)
1554       (dired-other-window (car (get-text-property (point) 'directory)))
1555     (push-mark)
1556     (setq compilation-current-error (point))
1557     (next-error-internal)))
1558
1559 ;; Return a compilation buffer.
1560 ;; If the current buffer is a compilation buffer, return it.
1561 ;; Otherwise, look for a compilation buffer and signal an error
1562 ;; if there are none.
1563 (defun compilation-find-buffer (&optional avoid-current)
1564   (next-error-find-buffer avoid-current 'compilation-buffer-internal-p))
1565
1566 ;;;###autoload
1567 (defun compilation-next-error-function (n &optional reset)
1568   "Advance to the next error message and visit the file where the error was.
1569 This is the value of `next-error-function' in Compilation buffers."
1570   (interactive "p")
1571   (when reset
1572     (setq compilation-current-error nil))
1573   (let* ((columns compilation-error-screen-columns) ; buffer's local value
1574          (last 1)
1575          (loc (compilation-next-error (or n 1) nil
1576                                       (or compilation-current-error
1577                                           compilation-messages-start
1578                                           (point-min))))
1579          (end-loc (nth 2 loc))
1580          (marker (point-marker)))
1581     (setq compilation-current-error (point-marker)
1582           overlay-arrow-position
1583             (if (bolp)
1584                 compilation-current-error
1585               (copy-marker (line-beginning-position)))
1586           loc (car loc))
1587     ;; If loc contains no marker, no error in that file has been visited.  If
1588     ;; the marker is invalid the buffer has been killed.  So, recalculate all
1589     ;; markers for that file.
1590     (unless (and (nth 3 loc) (marker-buffer (nth 3 loc)))
1591       (with-current-buffer (compilation-find-file marker (caar (nth 2 loc))
1592                                                   (cadr (car (nth 2 loc))))
1593         (save-restriction
1594           (widen)
1595           (goto-char (point-min))
1596           ;; Treat file's found lines in forward order, 1 by 1.
1597           (dolist (line (reverse (cddr (nth 2 loc))))
1598             (when (car line)            ; else this is a filename w/o a line#
1599               (beginning-of-line (- (car line) last -1))
1600               (setq last (car line)))
1601             ;; Treat line's found columns and store/update a marker for each.
1602             (dolist (col (cdr line))
1603               (if (car col)
1604                   (if (eq (car col) -1) ; special case for range end
1605                       (end-of-line)
1606                     (compilation-move-to-column (car col) columns))
1607                 (beginning-of-line)
1608                 (skip-chars-forward " \t"))
1609               (if (nth 3 col)
1610                   (set-marker (nth 3 col) (point))
1611                 (setcdr (nthcdr 2 col) `(,(point-marker)))))))))
1612     (compilation-goto-locus marker (nth 3 loc) (nth 3 end-loc))
1613     (setcdr (nthcdr 3 loc) t)))         ; Set this one as visited.
1614
1615 (defvar compilation-gcpro nil
1616   "Internal variable used to keep some values from being GC'd.")
1617 (make-variable-buffer-local 'compilation-gcpro)
1618
1619 (defun compilation-fake-loc (marker file &optional line col)
1620   "Preassociate MARKER with FILE.
1621 FILE should be ABSOLUTE-FILENAME or (RELATIVE-FILENAME . DIRNAME).
1622 This is useful when you compile temporary files, but want
1623 automatic translation of the messages to the real buffer from
1624 which the temporary file came.  This only works if done before a
1625 message about FILE appears!
1626
1627 Optional args LINE and COL default to 1 and beginning of
1628 indentation respectively.  The marker is expected to reflect
1629 this.  In the simplest case the marker points to the first line
1630 of the region that was saved to the temp file.
1631
1632 If you concatenate several regions into the temp file (e.g. a
1633 header with variable assignments and a code region), you must
1634 call this several times, once each for the last line of one
1635 region and the first line of the next region."
1636   (or (consp file) (setq file (list file)))
1637   (setq file (compilation-get-file-structure file))
1638   ;; Between the current call to compilation-fake-loc and the first occurrence
1639   ;; of an error message referring to `file', the data is only kept is the
1640   ;; weak hash-table compilation-locs, so we need to prevent this entry
1641   ;; in compilation-locs from being GC'd away.  --Stef
1642   (push file compilation-gcpro)
1643   (let ((loc (compilation-assq (or line 1) (cdr file))))
1644     (setq loc (compilation-assq col loc))
1645     (if (cdr loc)
1646         (setcdr (cddr loc) (list marker))
1647       (setcdr loc (list line file marker)))
1648     loc))
1649
1650 (defcustom compilation-context-lines nil
1651   "Display this many lines of leading context before the current message.
1652 If nil and the left fringe is displayed, don't scroll the
1653 compilation output window; an arrow in the left fringe points to
1654 the current message.  If nil and there is no left fringe, the message
1655 displays at the top of the window; there is no arrow."
1656   :type '(choice integer (const :tag "No window scrolling" nil))
1657   :group 'compilation
1658   :version "22.1")
1659
1660 (defsubst compilation-set-window (w mk)
1661   "Align the compilation output window W with marker MK near top."
1662   (if (integerp compilation-context-lines)
1663       (set-window-start w (save-excursion
1664                             (goto-char mk)
1665                             (beginning-of-line
1666                              (- 1 compilation-context-lines))
1667                             (point)))
1668     ;; If there is no left fringe.
1669     (if (equal (car (window-fringes)) 0)
1670         (set-window-start w (save-excursion
1671                               (goto-char mk)
1672                             (beginning-of-line 1)
1673                             (point)))))
1674     (set-window-point w mk))
1675
1676 (defvar next-error-highlight-timer)
1677
1678 (defun compilation-goto-locus (msg mk end-mk)
1679   "Jump to an error corresponding to MSG at MK.
1680 All arguments are markers.  If END-MK is non-nil, mark is set there
1681 and overlay is highlighted between MK and END-MK."
1682   ;; Show compilation buffer in other window, scrolled to this error.
1683   (let* ((from-compilation-buffer (eq (window-buffer (selected-window))
1684                                       (marker-buffer msg)))
1685          ;; Use an existing window if it is in a visible frame.
1686          (pre-existing (get-buffer-window (marker-buffer msg) 0))
1687          (w (if (and from-compilation-buffer pre-existing)
1688                 ;; Calling display-buffer here may end up (partly) hiding
1689                 ;; the error location if the two buffers are in two
1690                 ;; different frames.  So don't do it if it's not necessary.
1691                 pre-existing
1692               (let ((display-buffer-reuse-frames t)
1693                     (pop-up-windows t))
1694                 ;; Pop up a window.
1695                 (display-buffer (marker-buffer msg)))))
1696          (highlight-regexp (with-current-buffer (marker-buffer msg)
1697                              ;; also do this while we change buffer
1698                              (compilation-set-window w msg)
1699                              compilation-highlight-regexp)))
1700     ;; Ideally, the window-size should be passed to `display-buffer' (via
1701     ;; something like special-display-buffer) so it's only used when
1702     ;; creating a new window.
1703     (unless pre-existing (compilation-set-window-height w))
1704
1705     (if from-compilation-buffer
1706         ;; If the compilation buffer window was selected,
1707         ;; keep the compilation buffer in this window;
1708         ;; display the source in another window.
1709         (let ((pop-up-windows t))
1710           (pop-to-buffer (marker-buffer mk) 'other-window))
1711       (if (window-dedicated-p (selected-window))
1712           (pop-to-buffer (marker-buffer mk))
1713         (switch-to-buffer (marker-buffer mk))))
1714     ;; If narrowing gets in the way of going to the right place, widen.
1715     (unless (eq (goto-char mk) (point))
1716       (widen)
1717       (goto-char mk))
1718     (if end-mk
1719         (push-mark end-mk t)
1720       (if mark-active (setq mark-active)))
1721     ;; If hideshow got in the way of
1722     ;; seeing the right place, open permanently.
1723     (dolist (ov (overlays-at (point)))
1724       (when (eq 'hs (overlay-get ov 'invisible))
1725         (delete-overlay ov)
1726         (goto-char mk)))
1727
1728     (when highlight-regexp
1729       (if (timerp next-error-highlight-timer)
1730           (cancel-timer next-error-highlight-timer))
1731       (unless compilation-highlight-overlay
1732         (setq compilation-highlight-overlay
1733               (make-overlay (point-min) (point-min)))
1734         (overlay-put compilation-highlight-overlay 'face 'next-error))
1735       (with-current-buffer (marker-buffer mk)
1736         (save-excursion
1737           (if end-mk (goto-char end-mk) (end-of-line))
1738           (let ((end (point)))
1739             (if mk (goto-char mk) (beginning-of-line))
1740             (if (and (stringp highlight-regexp)
1741                      (re-search-forward highlight-regexp end t))
1742                 (progn
1743                   (goto-char (match-beginning 0))
1744                   (move-overlay compilation-highlight-overlay
1745                                 (match-beginning 0) (match-end 0)
1746                                 (current-buffer)))
1747               (move-overlay compilation-highlight-overlay
1748                             (point) end (current-buffer)))
1749             (if (numberp next-error-highlight)
1750                 (setq next-error-highlight-timer
1751                       (run-at-time next-error-highlight nil 'delete-overlay
1752                                    compilation-highlight-overlay)))
1753             (if (not (or (eq next-error-highlight t)
1754                          (numberp next-error-highlight)))
1755                 (delete-overlay compilation-highlight-overlay))))))
1756     (when (and (eq next-error-highlight 'fringe-arrow))
1757       (setq next-error-overlay-arrow-position
1758             (copy-marker (line-beginning-position))))))
1759
1760 \f
1761 (defun compilation-find-file (marker filename directory &rest formats)
1762   "Find a buffer for file FILENAME.
1763 Search the directories in `compilation-search-path'.
1764 A nil in `compilation-search-path' means to try the
1765 \"current\" directory, which is passed in DIRECTORY.
1766 If DIRECTORY. is relative, it is combined with `default-directory'.
1767 If DIRECTORY. is nil, that means use `default-directory'.
1768 If FILENAME is not found at all, ask the user where to find it.
1769 Pop up the buffer containing MARKER and scroll to MARKER if we ask the user."
1770   (or formats (setq formats '("%s")))
1771   (save-excursion
1772     (let ((dirs compilation-search-path)
1773           (spec-dir (if directory
1774                         (expand-file-name directory)
1775                       default-directory))
1776           buffer thisdir fmts name)
1777       (if (file-name-absolute-p filename)
1778           ;; The file name is absolute.  Use its explicit directory as
1779           ;; the first in the search path, and strip it from FILENAME.
1780           (setq filename (abbreviate-file-name (expand-file-name filename))
1781                 dirs (cons (file-name-directory filename) dirs)
1782                 filename (file-name-nondirectory filename)))
1783       ;; Now search the path.
1784       (while (and dirs (null buffer))
1785         (setq thisdir (or (car dirs) spec-dir)
1786               fmts formats)
1787         ;; For each directory, try each format string.
1788         (while (and fmts (null buffer))
1789           (setq name (expand-file-name (format (car fmts) filename) thisdir)
1790                 buffer (and (file-exists-p name)
1791                             (find-file-noselect name))
1792                 fmts (cdr fmts)))
1793         (setq dirs (cdr dirs)))
1794       (or buffer
1795           ;; The file doesn't exist.  Ask the user where to find it.
1796           (let ((pop-up-windows t))
1797             (compilation-set-window (display-buffer (marker-buffer marker))
1798                                     marker)
1799             (let ((name (expand-file-name
1800                          (read-file-name
1801                           (format "Find this %s in (default %s): "
1802                                   compilation-error filename)
1803                           spec-dir filename t))))
1804               (if (file-directory-p name)
1805                   (setq name (expand-file-name filename name)))
1806               (setq buffer (and (file-exists-p name)
1807                                 (find-file name))))))
1808       ;; Make intangible overlays tangible.
1809       (mapcar (function (lambda (ov)
1810                           (when (overlay-get ov 'intangible)
1811                             (overlay-put ov 'intangible nil))))
1812               (overlays-in (point-min) (point-max)))
1813       buffer)))
1814
1815 (defun compilation-get-file-structure (file &optional fmt)
1816   "Retrieve FILE's file-structure or create a new one.
1817 FILE should be (FILENAME) or (RELATIVE-FILENAME . DIRNAME).
1818 In the former case, FILENAME may be relative or absolute.
1819
1820 The file-structure looks like this:
1821   (list (list FILENAME [DIR-FROM-PREV-MSG]) FMT LINE-STRUCT...)
1822 "
1823   (or (gethash file compilation-locs)
1824       ;; File was not previously encountered, at least not in the form passed.
1825       ;; Let's normalize it and look again.
1826       (let ((filename (car file))
1827             ;; Get the specified directory from FILE.
1828             (spec-directory (if (cdr file)
1829                                 (file-truename (cdr file)))))
1830
1831         ;; Check for a comint-file-name-prefix and prepend it if appropriate.
1832         ;; (This is very useful for compilation-minor-mode in an rlogin-mode
1833         ;; buffer.)
1834         (when (and (boundp 'comint-file-name-prefix)
1835                    (not (equal comint-file-name-prefix "")))
1836           (if (file-name-absolute-p filename)
1837               (setq filename
1838                     (concat comint-file-name-prefix filename))
1839             (if spec-directory
1840                 (setq spec-directory
1841                       (file-truename
1842                        (concat comint-file-name-prefix spec-directory))))))
1843
1844         ;; If compilation-parse-errors-filename-function is
1845         ;; defined, use it to process the filename.
1846         (when compilation-parse-errors-filename-function
1847           (setq filename
1848                 (funcall compilation-parse-errors-filename-function
1849                          filename)))
1850
1851         ;; Some compilers (e.g. Sun's java compiler, reportedly) produce bogus
1852         ;; file names like "./bar//foo.c" for file "bar/foo.c";
1853         ;; expand-file-name will collapse these into "/foo.c" and fail to find
1854         ;; the appropriate file.  So we look for doubled slashes in the file
1855         ;; name and fix them.
1856         (setq filename (command-line-normalize-file-name filename))
1857
1858         ;; Store it for the possibly unnormalized name
1859         (puthash file
1860                  ;; Retrieve or create file-structure for normalized name
1861                  (or (gethash (list filename) compilation-locs)
1862                      (puthash (list filename)
1863                               (list (list filename spec-directory) fmt)
1864                               compilation-locs))
1865                  compilation-locs))))
1866
1867 (add-to-list 'debug-ignored-errors "^No more [-a-z ]+s yet$")
1868
1869 ;;; Compatibility with the old compile.el.
1870
1871 (defun compile-buffer-substring (n) (if n (match-string n)))
1872
1873 (defun compilation-compat-error-properties (err)
1874   "Map old-style error ERR to new-style message."
1875   ;; Old-style structure is (MARKER (FILE DIR) LINE COL) or
1876   ;; (MARKER . MARKER).
1877   (let ((dst (cdr err)))
1878     (if (markerp dst)
1879         ;; Must start with a face, for font-lock.
1880         `(face nil
1881           message ,(list (list nil nil nil dst) 2)
1882           help-echo "mouse-2: visit the source location"
1883           keymap compilation-button-map
1884           mouse-face highlight)
1885       ;; Too difficult to do it by hand: dispatch to the normal code.
1886       (let* ((file (pop dst))
1887              (line (pop dst))
1888              (col (pop dst))
1889              (filename (pop file))
1890              (dirname (pop file))
1891              (fmt (pop file)))
1892         (compilation-internal-error-properties
1893          (cons filename dirname) line nil col nil 2 fmt)))))
1894
1895 (defun compilation-compat-parse-errors (limit)
1896   (when compilation-parse-errors-function
1897     ;; FIXME: We should remove the rest of the compilation keywords
1898     ;; but we can't do that from here because font-lock is using
1899     ;; the value right now.  --stef
1900     (save-excursion
1901       (setq compilation-error-list nil)
1902       ;; Reset compilation-parsing-end each time because font-lock
1903       ;; might force us the re-parse many times (typically because
1904       ;; some code adds some text-property to the output that we
1905       ;; already parsed).  You might say "why reparse", well:
1906       ;; because font-lock has just removed the `message' property so
1907       ;; have to do it all over again.
1908       (if compilation-parsing-end
1909           (set-marker compilation-parsing-end (point))
1910         (setq compilation-parsing-end (point-marker)))
1911       (condition-case nil
1912           ;; Ignore any error: we're calling this function earlier than
1913           ;; in the old compile.el so things might not all be setup yet.
1914           (funcall compilation-parse-errors-function limit nil)
1915         (error nil))
1916       (dolist (err (if (listp compilation-error-list) compilation-error-list))
1917         (let* ((src (car err))
1918                (dst (cdr err))
1919                (loc (cond ((markerp dst) (list nil nil nil dst))
1920                           ((consp dst)
1921                            (list (nth 2 dst) (nth 1 dst)
1922                                  (cons (cdar dst) (caar dst)))))))
1923           (when loc
1924             (goto-char src)
1925             ;; (put-text-property src (line-end-position) 'font-lock-face 'font-lock-warning-face)
1926             (put-text-property src (line-end-position)
1927                                'message (list loc 2)))))))
1928   (goto-char limit)
1929   nil)
1930
1931 ;; Beware: this is not only compatiblity code.  New code stil uses it.  --Stef
1932 (defun compilation-forget-errors ()
1933   ;; In case we hit the same file/line specs, we want to recompute a new
1934   ;; marker for them, so flush our cache.
1935   (setq compilation-locs (make-hash-table :test 'equal :weakness 'value))
1936   (setq compilation-gcpro nil)
1937   ;; FIXME: the old code reset the directory-stack, so maybe we should
1938   ;; put a `directory change' marker of some sort, but where?  -stef
1939   ;;
1940   ;; FIXME: The old code moved compilation-current-error (which was
1941   ;; virtually represented by a mix of compilation-parsing-end and
1942   ;; compilation-error-list) to point-min, but that was only meaningful for
1943   ;; the internal uses of compilation-forget-errors: all calls from external
1944   ;; packages seem to be followed by a move of compilation-parsing-end to
1945   ;; something equivalent to point-max.  So we speculatively move
1946   ;; compilation-current-error to point-max (since the external package
1947   ;; won't know that it should do it).  --stef
1948   (setq compilation-current-error nil)
1949   (let* ((proc (get-buffer-process (current-buffer)))
1950          (mark (if proc (process-mark proc)))
1951          (pos (or mark (point-max))))
1952     (setq compilation-messages-start
1953           ;; In the future, ignore the text already present in the buffer.
1954           ;; Since many process filter functions insert before markers,
1955           ;; we need to put ours just before the insertion point rather
1956           ;; than at the insertion point.  If that's not possible, then
1957           ;; don't use a marker.  --Stef
1958           (if (> pos (point-min)) (copy-marker (1- pos)) pos))))
1959
1960 ;;;###autoload
1961 (add-to-list 'auto-mode-alist '("\\.gcov\\'" . compilation-mode))
1962
1963 (provide 'compile)
1964
1965 ;; arch-tag: 12465727-7382-4f72-b234-79855a00dd8c
1966 ;;; compile.el ends here