code.delx.au - gnu-emacs/blob - lisp/progmodes/compile.el

   1 ;;; compile.el --- run compiler as inferior of Emacs, parse error messages
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4 ;;   2001, 2003, 2004  Free Software Foundation, Inc.
   5
   6 ;; Authors: Roland McGrath <roland@gnu.org>,
   7 ;;          Daniel Pfeiffer <occitan@esperanto.org>
   8 ;; Maintainer: FSF
   9 ;; Keywords: tools, processes
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package provides the compile facilities documented in the Emacs user's
  31 ;; manual.
  32
  33 ;; This mode uses some complex data-structures:
  34
  35 ;;   LOC (or location) is a list of (COLUMN LINE FILE-STRUCTURE)
  36
  37 ;; COLUMN and LINE are numbers parsed from an error message.  COLUMN and maybe
  38 ;; LINE will be nil for a message that doesn't contain them.  Then the
  39 ;; location refers to a indented beginning of line or beginning of file.
  40 ;; Once any location in some file has been jumped to, the list is extended to
  41 ;; (COLUMN LINE FILE-STRUCTURE MARKER . VISITED) for all LOCs pertaining to
  42 ;; that file.
  43 ;; MARKER initially points to LINE and COLUMN in a buffer visiting that file.
  44 ;; Being a marker it sticks to some text, when the buffer grows or shrinks
  45 ;; before that point.  VISITED is t if we have jumped there, else nil.
  46
  47 ;;   FILE-STRUCTURE is a list of
  48 ;;   ((FILENAME . DIRECTORY) FORMATS (LINE LOC ...) ...)
  49
  50 ;; FILENAME is a string parsed from an error message.  DIRECTORY is a string
  51 ;; obtained by following directory change messages.  DIRECTORY will be nil for
  52 ;; an absolute filename.  FORMATS is a list of formats to apply to FILENAME if
  53 ;; a file of that name can't be found.
  54 ;; The rest of the list is an alist of elements with LINE as key.  The keys
  55 ;; are either nil or line numbers.  If present, nil comes first, followed by
  56 ;; the numbers in decreasing order.  The LOCs for each line are again an alist
  57 ;; ordered the same way.  Note that the whole file structure is referenced in
  58 ;; every LOC.
  59
  60 ;;   MESSAGE is a list of (LOC TYPE END-LOC)
  61
  62 ;; TYPE is 0 for info or 1 for warning if the message matcher identified it as
  63 ;; such, 2 otherwise (for a real error).  END-LOC is a LOC pointing to the
  64 ;; other end, if the parsed message contained a range.  If the end of the
  65 ;; range didn't specify a COLUMN, it defaults to -1, meaning end of line.
  66 ;; These are the value of the `message' text-properties in the compilation
  67 ;; buffer.
  68
  69 ;;; Code:
  70
  71 (eval-when-compile (require 'cl))
  72
  73 (defgroup compilation nil
  74   "Run compiler as inferior of Emacs, parse error messages."
  75   :group 'tools
  76   :group 'processes)
  77
  78
  79 ;;;###autoload
  80 (defcustom compilation-mode-hook nil
  81   "*List of hook functions run by `compilation-mode' (see `run-hooks')."
  82   :type 'hook
  83   :group 'compilation)
  84
  85 ;;;###autoload
  86 (defcustom compilation-window-height nil
  87   "*Number of lines in a compilation window.  If nil, use Emacs default."
  88   :type '(choice (const :tag "Default" nil)
  89                  integer)
  90   :group 'compilation)
  91
  92 (defvar compilation-first-column 1
  93   "*This is how compilers number the first column, usually 1 or 0.")
  94
  95 (defvar compilation-parse-errors-filename-function nil
  96   "Function to call to post-process filenames while parsing error messages.
  97 It takes one arg FILENAME which is the name of a file as found
  98 in the compilation output, and should return a transformed file name.")
  99
 100 ;;;###autoload
 101 (defvar compilation-process-setup-function nil
 102   "*Function to call to customize the compilation process.
 103 This function is called immediately before the compilation process is
 104 started.  It can be used to set any variables or functions that are used
 105 while processing the output of the compilation process.  The function
 106 is called with variables `compilation-buffer' and `compilation-window'
 107 bound to the compilation buffer and window, respectively.")
 108
 109 ;;;###autoload
 110 (defvar compilation-buffer-name-function nil
 111   "Function to compute the name of a compilation buffer.
 112 The function receives one argument, the name of the major mode of the
 113 compilation buffer.  It should return a string.
 114 nil means compute the name with `(concat \"*\" (downcase major-mode) \"*\")'.")
 115
 116 ;;;###autoload
 117 (defvar compilation-finish-function nil
 118   "Function to call when a compilation process finishes.
 119 It is called with two arguments: the compilation buffer, and a string
 120 describing how the process finished.")
 121
 122 ;;;###autoload
 123 (defvar compilation-finish-functions nil
 124   "Functions to call when a compilation process finishes.
 125 Each function is called with two arguments: the compilation buffer,
 126 and a string describing how the process finished.")
 127
 128 (defvar compilation-in-progress nil
 129   "List of compilation processes now running.")
 130 (or (assq 'compilation-in-progress minor-mode-alist)
 131     (setq minor-mode-alist (cons '(compilation-in-progress " Compiling")
 132                                  minor-mode-alist)))
 133
 134 (defvar compilation-error "error"
 135   "Stem of message to print when no matches are found.")
 136
 137 (defvar compilation-arguments nil
 138   "Arguments that were given to `compilation-start'.")
 139
 140 (defvar compilation-num-errors-found)
 141
 142 (defconst compilation-error-regexp-alist-alist
 143   '((absoft
 144      "^\\(?:[Ee]rror on \\|[Ww]arning on\\( \\)\\)?[Ll]ine[ \t]+\\([0-9]+\\)[ \t]+\
 145 of[ \t]+\"?\\([a-zA-Z]?:?[^\":\n]+\\)\"?:" 3 2 nil (1))
 146
 147     (ada
 148      "\\(warning: .*\\)? at \\([^ \n]+\\):\\([0-9]+\\)$" 2 3 nil (1))
 149
 150     (aix
 151      " in line \\([0-9]+\\) of file \\([^ \n]+[^. \n]\\)\\.? " 2 1)
 152
 153     (ant
 154      "^[ \t]*\\[[^] \n]+\\][ \t]*\\([^: \n]+\\):\\([0-9]+\\):\\(?:\\([0-9]+\\):[0-9]+:[0-9]+:\\)?\
 155 \\( warning\\)?" 1 2 3 (4))
 156
 157     (bash
 158      "^\\([^: \n\t]+\\): line \\([0-9]+\\):" 1 2)
 159
 160     (borland
 161      "^\\(?:Error\\|Warnin\\(g\\)\\) \\(?:[FEW][0-9]+ \\)?\
 162 \\([a-zA-Z]?:?[^:( \t\n]+\\)\
 163  \\([0-9]+\\)\\(?:[) \t]\\|:[^0-9\n]\\)" 2 3 nil (1))
 164
 165     (caml
 166      "^ *File \\(\"?\\)\\([^,\" \n\t<>]+\\)\\1, lines? \\([0-9]+\\)-?\\([0-9]+\\)?\\(?:$\\|,\
 167 \\(?: characters? \\([0-9]+\\)-?\\([0-9]+\\)?:\\)?\\([ \n]Warning:\\)?\\)"
 168      2 (3 . 4) (5 . 6) (7))
 169
 170     (comma
 171      "^\"\\([^,\" \n\t]+\\)\", line \\([0-9]+\\)\
 172 \\(?:[(. pos]+\\([0-9]+\\))?\\)?[:.,; (-]\\( warning:\\|[-0-9 ]*(W)\\)?" 1 2 3 (4))
 173
 174     (edg-1
 175      "^\\([^ \n]+\\)(\\([0-9]+\\)): \\(?:error\\|warnin\\(g\\)\\|remar\\(k\\)\\)"
 176      1 2 nil (3 . 4))
 177     (edg-2
 178      "at line \\([0-9]+\\) of \"\\([^ \n]+\\)\"$"
 179      2 1 nil 0)
 180
 181     (epc
 182      "^Error [0-9]+ at (\\([0-9]+\\):\\([^)\n]+\\))" 2 1)
 183
 184     (ftnchek-file
 185      "^File \\(.+\\.f\\):$"
 186      1 nil nil 0)
 187     (ftnchek-line-file
 188      "\\(^Warning .* \\)?line \\([0-9]+\\)\\(?: col \\([0-9]+\\)\\)? file \\(.+\\.f\\)"
 189      4 2 3 (1) nil (1 'default nil t))
 190     (ftnchek-line
 191      "\\(?:^\\(Warning\\) .* \\)?line \\([0-9]+\\)\\(?: col \\([0-9]+\\)\\)?"
 192      nil 2 3 (1) nil (1 (compilation-face '(1)) nil t))
 193
 194     (iar
 195      "^\"\\(.*\\)\",\\([0-9]+\\)\\s-+\\(?:Error\\|Warnin\\(g\\)\\)\\[[0-9]+\\]:"
 196      1 2 nil (3))
 197
 198     (ibm
 199      "^\\([^( \n\t]+\\)(\\([0-9]+\\):\\([0-9]+\\)) :\
 200  \\(?:warnin\\(g\\)\\|informationa\\(l\\)\\)?" 1 2 3 (4 . 5))
 201
 202     ;; fixme: should be `mips'
 203     (irix
 204      "^[-[:alnum:]_/ ]+: \\(?:\\(?:[sS]evere\\|[eE]rror\\|[wW]arnin\\(g\\)\\|[iI]nf\\(o\\)\\)[0-9 ]*: \\)?\
 205 \\([^,\" \n\t]+\\)\\(?:, line\\|:\\) \\([0-9]+\\):" 3 4 nil (1 . 2))
 206
 207     (java
 208      "^\\(?:[ \t]+at \\|==[0-9]+== +\\(?:at\\|b\\(y\\)\\)\\).+(\\([^()\n]+\\):\\([0-9]+\\))$" 2 3 nil (1))
 209
 210     (jikes-file
 211      "^\\(?:Found\\|Issued\\) .* compiling \"\\(.+\\)\":$" 1 nil nil 0)
 212     (jikes-line
 213      "^ *\\([0-9]+\\)\\.[ \t]+.*\n +\\(<-*>\n\\*\\*\\* \\(?:Error\\|Warnin\\(g\\)\\)\\)"
 214      nil 1 nil 2 0
 215      (2 (compilation-face '(3))))
 216
 217     (gcc-include
 218      "^\\(?:In file included\\|                \\) from \
 219 \\(.+\\):\\([0-9]+\\)\\(?:\\(:\\)\\|\\(,\\)\\)?" 1 2 nil (3 . 4))
 220
 221     (gnu
 222      "^\\(?:[[:alpha:]][-[:alnum:].]+: ?\\)?\
 223 \\([/.]*[a-zA-Z]:?[^ \t\n:]*\\|{standard input}\\): ?\
 224 \\([0-9]+\\)\\([.:]?\\)\\([0-9]+\\)?\
 225 \\(?:-\\(?:\\([0-9]+\\)\\3\\)?\\.?\\([0-9]+\\)?\\)?:\
 226 \\(?: *\\(\\(?:Future\\|Runtime\\)?[Ww]arning\\|W:\\)\\|\
 227  *\\([Ii]nfo\\(?:\\>\\|rmationa?l?\\)\\|I:\\)\\)?"
 228      1 (2 . 5) (4 . 6) (7 . 8))
 229
 230     (lcc
 231      "^\\(?:E\\|\\(W\\)\\), \\([^(\n]+\\)(\\([0-9]+\\),[ \t]*\\([0-9]+\\)"
 232      2 3 4 (1))
 233
 234     (makepp
 235      "^makepp: \\(?:\\(?:warning\\(:\\).*?\\|\\(Scanning\\|[LR]e?l?oading makefile\\) \\|.*?\\)\
 236 `\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)'\\)"
 237      4 5 nil (1 . 2) 3
 238      ("`\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)'" nil nil
 239       (2 compilation-info-face)
 240       (3 compilation-line-face nil t)
 241       (1 (compilation-error-properties 2 3 nil nil nil 0 nil)
 242          append)))
 243
 244     ;; Should be lint-1, lint-2 (SysV lint)
 245     (mips-1
 246      " (\\([0-9]+\\)) in \\([^ \n]+\\)" 2 1)
 247     (mips-2
 248      " in \\([^()\n ]+\\)(\\([0-9]+\\))$" 1 2)
 249
 250     (msft
 251      "^\\(\\(?:[a-zA-Z]:\\)?[^:(\t\n]+\\)(\\([0-9]+\\)) \
 252 : \\(?:error\\|warnin\\(g\\)\\) C[0-9]+:" 1 2 nil (3))
 253
 254     (oracle
 255      "^\\(?:Semantic error\\|Error\\|PCC-[0-9]+:\\).* line \\([0-9]+\\)\
 256 \\(?:\\(?:,\\| at\\)? column \\([0-9]+\\)\\)?\
 257 \\(?:,\\| in\\| of\\)? file \\(.*?\\):?$"
 258      3 1 2)
 259
 260     (perl
 261      " at \\([^ \n]+\\) line \\([0-9]+\\)\\(?:[,.]\\|$\\)" 1 2)
 262
 263     (rxp
 264      "^\\(?:Error\\|Warnin\\(g\\)\\):.*\n.* line \\([0-9]+\\) char\
 265  \\([0-9]+\\) of file://\\(.+\\)"
 266      4 2 3 (1))
 267
 268     (sparc-pascal-file
 269      "^\\w\\w\\w \\w\\w\\w +[0-3]?[0-9] +[0-2][0-9]:[0-5][0-9]:[0-5][0-9]\
 270  [12][09][0-9][0-9] +\\(.*\\):$"
 271      1 nil nil 0)
 272     (sparc-pascal-line
 273      "^\\(\\(?:E\\|\\(w\\)\\) +[0-9]+\\) line \\([0-9]+\\) -  "
 274      nil 3 nil (2) nil (1 (compilation-face '(2))))
 275     (sparc-pascal-example
 276      "^ +\\([0-9]+\\) +.*\n\\(\\(?:e\\|\\(w\\)\\) [0-9]+\\)-+"
 277      nil 1 nil (3) nil (2 (compilation-face '(3))))
 278
 279     (sun
 280      ": \\(?:ERROR\\|WARNIN\\(G\\)\\|REMAR\\(K\\)\\) \\(?:[[:alnum:] ]+, \\)?\
 281 File = \\(.+\\), Line = \\([0-9]+\\)\\(?:, Column = \\([0-9]+\\)\\)?"
 282      3 4 5 (1 . 2))
 283
 284     (sun-ada
 285      "^\\([^, \n\t]+\\), line \\([0-9]+\\), char \\([0-9]+\\)[:., \(-]" 1 2 3)
 286
 287     (4bsd
 288      "\\(?:^\\|::  \\|\\S ( \\)\\(/[^ \n\t()]+\\)(\\([0-9]+\\))\
 289 \\(?:: \\(warning:\\)?\\|$\\| ),\\)" 1 2 nil (3)))
 290   "Alist of values for `compilation-error-regexp-alist'.")
 291
 292 (defcustom compilation-error-regexp-alist
 293   (mapcar 'car compilation-error-regexp-alist-alist)
 294   "Alist that specifies how to match errors in compiler output.
 295 Note that on Unix everything is a valid filename, so these
 296 matchers must make some common sense assumptions, which catch
 297 normal cases.  A shorter list will be lighter on resource usage.
 298
 299 Instead of an alist element, you can use a symbol, which is
 300 looked up in `compilation-error-regexp-alist-alist'.  You can see
 301 the predefined symbols and their effects in the file
 302 `etc/compilation.txt' (linked below if you are customizing this).
 303
 304 Each elt has the form (REGEXP FILE [LINE COLUMN TYPE HYPERLINK
 305 HIGHLIGHT...]).  If REGEXP matches, the FILE'th subexpression
 306 gives the file name, and the LINE'th subexpression gives the line
 307 number.  The COLUMN'th subexpression gives the column number on
 308 that line.
 309
 310 If FILE, LINE or COLUMN are nil or that index didn't match, that
 311 information is not present on the matched line.  In that case the
 312 file name is assumed to be the same as the previous one in the
 313 buffer, line number defaults to 1 and column defaults to
 314 beginning of line's indentation.
 315
 316 FILE can also have the form (FILE FORMAT...), where the FORMATs
 317 \(e.g. \"%s.c\") will be applied in turn to the recognized file
 318 name, until a file of that name is found.  Or FILE can also be a
 319 function to return the filename.
 320
 321 LINE can also be of the form (LINE . END-LINE) meaning a range
 322 of lines.  COLUMN can also be of the form (COLUMN . END-COLUMN)
 323 meaning a range of columns starting on LINE and ending on
 324 END-LINE, if that matched.
 325
 326 TYPE is 2 or nil for a real error or 1 for warning or 0 for info.
 327 TYPE can also be of the form (WARNING . INFO).  In that case this
 328 will be equivalent to 1 if the WARNING'th subexpression matched
 329 or else equivalent to 0 if the INFO'th subexpression matched.
 330 See `compilation-error-face', `compilation-warning-face',
 331 `compilation-info-face' and `compilation-skip-threshold'.
 332
 333 What matched the HYPERLINK'th subexpression has `mouse-face' and
 334 `compilation-message-face' applied.  If this is nil, the text
 335 matched by the whole REGEXP becomes the hyperlink.
 336
 337 Additional HIGHLIGHTs as described under `font-lock-keywords' can
 338 be added."
 339   :type `(set :menu-tag "Pick"
 340               ,@(mapcar (lambda (elt)
 341                           (list 'const (car elt)))
 342                         compilation-error-regexp-alist-alist))
 343   :link `(file-link :tag "example file"
 344                     ,(expand-file-name "compilation.txt" data-directory))
 345   :group 'compilation)
 346
 347 (defvar compilation-directory nil
 348   "Directory to restore to when doing `recompile'.")
 349
 350 (defvar compilation-directory-matcher
 351   '("\\(?:Entering\\|Leavin\\(g\\)\\) directory `\\(.+\\)'$" (2 . 1))
 352   "A list for tracking when directories are entered or left.
 353 Nil means not to track directories, e.g. if all file names are absolute.  The
 354 first element is the REGEXP matching these messages.  It can match any number
 355 of variants, e.g. different languages.  The remaining elements are all of the
 356 form (DIR .  LEAVE).  If for any one of these the DIR'th subexpression
 357 matches, that is a directory name.  If LEAVE is nil or the corresponding
 358 LEAVE'th subexpression doesn't match, this message is about going into another
 359 directory.  If it does match anything, this message is about going back to the
 360 directory we were in before the last entering message.  If you change this,
 361 you may also want to change `compilation-page-delimiter'.")
 362
 363 (defvar compilation-page-delimiter
 364   "^\\(?:\f\\|.*\\(?:Entering\\|Leaving\\) directory `.+'\n\\)+"
 365   "Value of `page-delimiter' in Compilation mode.")
 366
 367 (defvar compilation-mode-font-lock-keywords
 368    '(;; configure output lines.
 369      ("^[Cc]hecking \\(?:[Ff]or \\|[Ii]f \\|[Ww]hether \\(?:to \\)?\\)?\\(.+\\)\\.\\.\\. *\\(?:(cached) *\\)?\\(\\(yes\\(?: .+\\)?\\)\\|no\\|\\(.*\\)\\)$"
 370       (1 font-lock-variable-name-face)
 371       (2 (compilation-face '(4 . 3))))
 372      ;; Command output lines.  Recognize `make[n]:' lines too.
 373      ("^\\([[:alnum:]_/.+-]+\\)\\(\\[\\([0-9]+\\)\\]\\)?[ \t]*:"
 374       (1 font-lock-function-name-face) (3 compilation-line-face nil t))
 375      (" --?o\\(?:utfile\\|utput\\)?[= ]?\\(\\S +\\)" . 1)
 376      ("^Compilation finished" . compilation-info-face)
 377      ("^Compilation exited abnormally" . compilation-error-face))
 378    "Additional things to highlight in Compilation mode.
 379 This gets tacked on the end of the generated expressions.")
 380
 381 (defvar compilation-highlight-regexp t
 382   "Regexp matching part of visited source lines to highlight temporarily.
 383 Highlight entire line if t; don't highlight source lines if nil.")
 384
 385 (defvar compilation-highlight-overlay nil
 386   "Overlay used to temporarily highlight compilation matches.")
 387
 388 (defcustom compilation-error-screen-columns t
 389   "*If non-nil, column numbers in error messages are screen columns.
 390 Otherwise they are interpreted as character positions, with
 391 each character occupying one column.
 392 The default is to use screen columns, which requires that the compilation
 393 program and Emacs agree about the display width of the characters,
 394 especially the TAB character."
 395   :type 'boolean
 396   :group 'compilation
 397   :version "20.4")
 398
 399 (defcustom compilation-read-command t
 400   "*Non-nil means \\[compile] reads the compilation command to use.
 401 Otherwise, \\[compile] just uses the value of `compile-command'."
 402   :type 'boolean
 403   :group 'compilation)
 404
 405 ;;;###autoload
 406 (defcustom compilation-ask-about-save t
 407   "*Non-nil means \\[compile] asks which buffers to save before compiling.
 408 Otherwise, it saves all modified buffers without asking."
 409   :type 'boolean
 410   :group 'compilation)
 411
 412 ;;;###autoload
 413 (defcustom compilation-search-path '(nil)
 414   "*List of directories to search for source files named in error messages.
 415 Elements should be directory names, not file names of directories.
 416 nil as an element means to try the default directory."
 417   :type '(repeat (choice (const :tag "Default" nil)
 418                          (string :tag "Directory")))
 419   :group 'compilation)
 420
 421 (defcustom compile-command "make -k "
 422   "*Last shell command used to do a compilation; default for next compilation.
 423
 424 Sometimes it is useful for files to supply local values for this variable.
 425 You might also use mode hooks to specify it in certain modes, like this:
 426
 427     (add-hook 'c-mode-hook
 428        (lambda ()
 429          (unless (or (file-exists-p \"makefile\")
 430                      (file-exists-p \"Makefile\"))
 431            (set (make-local-variable 'compile-command)
 432                 (concat \"make -k \"
 433                         (file-name-sans-extension buffer-file-name))))))"
 434   :type 'string
 435   :group 'compilation)
 436
 437 ;; A weak per-compilation-buffer hash indexed by (FILENAME . DIRECTORY).  Each
 438 ;; value is a FILE-STRUCTURE as described above, with the car eq to the hash
 439 ;; key.  This holds the tree seen from root, for storing new nodes.
 440 (defvar compilation-locs ())
 441
 442 (defvar compilation-debug nil
 443   "*Set this to t before creating a *compilation* buffer.
 444 Then every error line will have a debug text property with the matcher that
 445 fit this line and the match data.  Use `describe-text-properties'.")
 446
 447 (defvar compilation-exit-message-function nil "\
 448 If non-nil, called when a compilation process dies to return a status message.
 449 This should be a function of three arguments: process status, exit status,
 450 and exit message; it returns a cons (MESSAGE . MODELINE) of the strings to
 451 write into the compilation buffer, and to put in its mode line.")
 452
 453 (defvar compilation-environment nil
 454   "*List of environment variables for compilation to inherit.
 455 Each element should be a string of the form ENVVARNAME=VALUE.
 456 This list is temporarily prepended to `process-environment' prior to
 457 starting the compilation process.")
 458
 459 ;; History of compile commands.
 460 (defvar compile-history nil)
 461
 462 (defface compilation-warning-face
 463   '((((class color) (min-colors 16)) (:foreground "Orange" :weight bold))
 464     (((class color)) (:foreground "cyan" :weight bold))
 465     (t (:weight bold)))
 466   "Face used to highlight compiler warnings."
 467   :group 'font-lock-highlighting-faces
 468   :version "21.4")
 469
 470 (defface compilation-info-face
 471   '((((class color) (min-colors 16) (background light))
 472      (:foreground "Green3" :weight bold))
 473     (((class color) (min-colors 16) (background dark))
 474      (:foreground "Green" :weight bold))
 475     (((class color)) (:foreground "green" :weight bold))
 476     (t (:weight bold)))
 477   "Face used to highlight compiler warnings."
 478   :group 'font-lock-highlighting-faces
 479   :version "21.4")
 480
 481 (defvar compilation-message-face nil
 482   "Face name to use for whole messages.
 483 Faces `compilation-error-face', `compilation-warning-face',
 484 `compilation-info-face', `compilation-line-face' and
 485 `compilation-column-face' get prepended to this, when applicable.")
 486
 487 (defvar compilation-error-face 'font-lock-warning-face
 488   "Face name to use for file name in error messages.")
 489
 490 (defvar compilation-warning-face 'compilation-warning-face
 491   "Face name to use for file name in warning messages.")
 492
 493 (defvar compilation-info-face 'compilation-info-face
 494   "Face name to use for file name in informational messages.")
 495
 496 (defvar compilation-line-face 'font-lock-variable-name-face
 497   "Face name to use for line number in message.")
 498
 499 (defvar compilation-column-face 'font-lock-type-face
 500   "Face name to use for column number in message.")
 501
 502 ;; same faces as dired uses
 503 (defvar compilation-enter-directory-face 'font-lock-function-name-face
 504   "Face name to use for column number in message.")
 505
 506 (defvar compilation-leave-directory-face 'font-lock-type-face
 507   "Face name to use for column number in message.")
 508
 509
 510
 511 ;; Used for compatibility with the old compile.el.
 512 (defvaralias 'compilation-last-buffer 'next-error-last-buffer)
 513 (defvar compilation-parsing-end (make-marker))
 514 (defvar compilation-parse-errors-function nil)
 515 (defvar compilation-error-list nil)
 516 (defvar compilation-old-error-list nil)
 517
 518 (defun compilation-face (type)
 519   (or (and (car type) (match-end (car type)) compilation-warning-face)
 520       (and (cdr type) (match-end (cdr type)) compilation-info-face)
 521       compilation-error-face))
 522
 523 (defun compilation-directory-properties (idx leave)
 524   (if leave (setq leave (match-end leave)))
 525   ;; find previous stack, and push onto it, or if `leave' pop it
 526   (let ((dir (previous-single-property-change (point) 'directory)))
 527     (setq dir (if dir (or (get-text-property (1- dir) 'directory)
 528                           (get-text-property dir 'directory))))
 529     `(face ,(if leave
 530                 compilation-leave-directory-face
 531               compilation-enter-directory-face)
 532       directory ,(if leave
 533                      (or (cdr dir)
 534                          '(nil))        ; nil only isn't a property-change
 535                    (cons (match-string-no-properties idx) dir))
 536       mouse-face highlight
 537       keymap compilation-button-map
 538       help-echo "mouse-2: visit current directory")))
 539
 540 ;; Data type `reverse-ordered-alist' retriever.  This function retrieves the
 541 ;; KEY element from the ALIST, creating it in the right position if not already
 542 ;; present. ALIST structure is
 543 ;; '(ANCHOR (KEY1 ...) (KEY2 ...)... (KEYn ALIST ...))
 544 ;; ANCHOR is ignored, but necessary so that elements can be inserted.  KEY1
 545 ;; may be nil.  The other KEYs are ordered backwards so that growing line
 546 ;; numbers can be inserted in front and searching can abort after half the
 547 ;; list on average.
 548 (eval-when-compile                  ;Don't keep it at runtime if not needed.
 549 (defmacro compilation-assq (key alist)
 550   `(let* ((l1 ,alist)
 551           (l2 (cdr l1)))
 552      (car (if (if (null ,key)
 553                   (if l2 (null (caar l2)))
 554                 (while (if l2 (if (caar l2) (< ,key (caar l2)) t))
 555                   (setq l1 l2
 556                         l2 (cdr l1)))
 557                 (if l2 (eq ,key (caar l2))))
 558               l2
 559             (setcdr l1 (cons (list ,key) l2)))))))
 560
 561
 562 ;; This function is the central driver, called when font-locking to gather
 563 ;; all information needed to later jump to corresponding source code.
 564 ;; Return a property list with all meta information on this error location.
 565 (defun compilation-error-properties (file line end-line col end-col type fmt)
 566   (unless (< (next-single-property-change (match-beginning 0) 'directory nil (point))
 567              (point))
 568     (if file
 569         (if (functionp file)
 570             (setq file (funcall file))
 571           (let (dir)
 572             (setq file (match-string-no-properties file))
 573             (unless (file-name-absolute-p file)
 574               (setq dir (previous-single-property-change (point) 'directory)
 575                     dir (if dir (or (get-text-property (1- dir) 'directory)
 576                                     (get-text-property dir 'directory)))))
 577             (setq file (cons file (car dir)))))
 578       ;; This message didn't mention one, get it from previous
 579       (setq file (previous-single-property-change (point) 'message)
 580             file (or (if file
 581                          (car (nth 2 (car (or (get-text-property (1- file) 'message)
 582                                          (get-text-property file 'message))))))
 583                      '("*unknown*"))))
 584     ;; All of these fields are optional, get them only if we have an index, and
 585     ;; it matched some part of the message.
 586     (and line
 587          (setq line (match-string-no-properties line))
 588          (setq line (string-to-number line)))
 589     (and end-line
 590          (setq end-line (match-string-no-properties end-line))
 591          (setq end-line (string-to-number end-line)))
 592     (if col
 593         (if (functionp col)
 594             (setq col (funcall col))
 595           (and
 596            (setq col (match-string-no-properties col))
 597            (setq col (- (string-to-number col) compilation-first-column)))))
 598     (if (and end-col (functionp end-col))
 599         (setq end-col (funcall end-col))
 600       (if (and end-col (setq end-col (match-string-no-properties end-col)))
 601           (setq end-col (- (string-to-number end-col) compilation-first-column -1))
 602         (if end-line (setq end-col -1))))
 603     (if (consp type)                    ; not a static type, check what it is.
 604         (setq type (or (and (car type) (match-end (car type)) 1)
 605                        (and (cdr type) (match-end (cdr type)) 0)
 606                        2)))
 607     (compilation-internal-error-properties file line end-line col end-col type fmt)))
 608
 609 (defun compilation-internal-error-properties (file line end-line col end-col type fmt)
 610   "Get the meta-info that will be added as text-properties.
 611 LINE, END-LINE, COL, END-COL are integers or nil.
 612 TYPE can be 0, 1, or 2.
 613 FILE should be (ABSOLUTE-FILENAME) or (RELATIVE-FILENAME . DIRNAME) or nil."
 614   (unless file (setq file '("*unknown*")))
 615   (setq file (compilation-get-file-structure file fmt))
 616   ;; Get first already existing marker (if any has one, all have one).
 617   ;; Do this first, as the compilation-assq`s may create new nodes.
 618   (let* ((marker-line (car (cddr file)))        ; a line structure
 619          (marker (nth 3 (cadr marker-line)))    ; its marker
 620          (compilation-error-screen-columns compilation-error-screen-columns)
 621          end-marker loc end-loc)
 622     (if (not (and marker (marker-buffer marker)))
 623         (setq marker)                   ; no valid marker for this file
 624       (setq loc (or line 1))            ; normalize no linenumber to line 1
 625       (catch 'marker                    ; find nearest loc, at least one exists
 626         (dolist (x (nthcdr 3 file))     ; loop over remaining lines
 627           (if (> (car x) loc)           ; still bigger
 628               (setq marker-line x)
 629             (if (> (- (or (car marker-line) 1) loc)
 630                    (- loc (car x)))     ; current line is nearer
 631                 (setq marker-line x))
 632             (throw 'marker t))))
 633       (setq marker (nth 3 (cadr marker-line))
 634             marker-line (or (car marker-line) 1))
 635       (with-current-buffer (marker-buffer marker)
 636         (save-restriction
 637           (widen)
 638           (goto-char (marker-position marker))
 639           (when (or end-col end-line)
 640             (beginning-of-line (- (or end-line line) marker-line -1))
 641             (if (or (null end-col) (< end-col 0))
 642                 (end-of-line)
 643               (if compilation-error-screen-columns
 644                   (move-to-column end-col)
 645                 (forward-char end-col)))
 646             (setq end-marker (list (point-marker))))
 647           (beginning-of-line (if end-line
 648                                  (- line end-line -1)
 649                                (- loc marker-line -1)))
 650           (if col
 651               (if compilation-error-screen-columns
 652                   (move-to-column col)
 653                 (forward-char col))
 654             (forward-to-indentation 0))
 655           (setq marker (list (point-marker))))))
 656
 657     (setq loc (compilation-assq line (cdr file)))
 658     (if end-line
 659         (setq end-loc (compilation-assq end-line (cdr file))
 660               end-loc (compilation-assq end-col end-loc))
 661       (if end-col                       ; use same line element
 662           (setq end-loc (compilation-assq end-col loc))))
 663     (setq loc (compilation-assq col loc))
 664     ;; If they are new, make the loc(s) reference the file they point to.
 665     (or (cdr loc) (setcdr loc `(,line ,file ,@marker)))
 666     (if end-loc
 667         (or (cdr end-loc) (setcdr end-loc `(,(or end-line line) ,file ,@end-marker))))
 668
 669     ;; Must start with face
 670     `(face ,compilation-message-face
 671            message (,loc ,type ,end-loc)
 672            ,@(if compilation-debug
 673                  `(debug (,(assoc (with-no-warnings matcher) font-lock-keywords)
 674                           ,@(match-data))))
 675            help-echo ,(if col
 676                           "mouse-2: visit this file, line and column"
 677                         (if line
 678                             "mouse-2: visit this file and line"
 679                           "mouse-2: visit this file"))
 680            keymap compilation-button-map
 681            mouse-face highlight)))
 682
 683 (defun compilation-mode-font-lock-keywords ()
 684   "Return expressions to highlight in Compilation mode."
 685   (if compilation-parse-errors-function
 686       ;; An old package!  Try the compatibility code.
 687       '((compilation-compat-parse-errors))
 688     (append
 689      ;; make directory tracking
 690      (if compilation-directory-matcher
 691          `((,(car compilation-directory-matcher)
 692             ,@(mapcar (lambda (elt)
 693                         `(,(car elt)
 694                           (compilation-directory-properties
 695                            ,(car elt) ,(cdr elt))
 696                           t))
 697                       (cdr compilation-directory-matcher)))))
 698
 699      ;; Compiler warning/error lines.
 700      (mapcar
 701       (lambda (item)
 702         (if (symbolp item)
 703             (setq item (cdr (assq item
 704                                   compilation-error-regexp-alist-alist))))
 705         (let ((file (nth 1 item))
 706               (line (nth 2 item))
 707               (col (nth 3 item))
 708               (type (nth 4 item))
 709               end-line end-col fmt)
 710           (if (consp file)      (setq fmt (cdr file)      file (car file)))
 711           (if (consp line)      (setq end-line (cdr line) line (car line)))
 712           (if (consp col)       (setq end-col (cdr col)   col (car col)))
 713
 714           (if (functionp line)
 715               ;; The old compile.el had here an undocumented hook that
 716               ;; allowed `line' to be a function that computed the actual
 717               ;; error location.  Let's do our best.
 718               `(,(car item)
 719                 (0 (compilation-compat-error-properties
 720                     (funcall ',line (cons (match-string ,file)
 721                                           (cons default-directory
 722                                                 ',(nthcdr 4 item)))
 723                              ,(if col `(match-string ,col)))))
 724                 (,file compilation-error-face t))
 725
 726             (unless (or (null (nth 5 item)) (integerp (nth 5 item)))
 727               (error "HYPERLINK should be an integer: %s" (nth 5 item)))
 728
 729             `(,(nth 0 item)
 730
 731               ,@(when (integerp file)
 732                   `((,file ,(if (consp type)
 733                                 `(compilation-face ',type)
 734                               (aref [compilation-info-face
 735                                      compilation-warning-face
 736                                      compilation-error-face]
 737                                     (or type 2))))))
 738
 739               ,@(when line
 740                   `((,line compilation-line-face nil t)))
 741               ,@(when end-line
 742                   `((,end-line compilation-line-face nil t)))
 743
 744               ,@(when (integerp col)
 745                   `((,col compilation-column-face nil t)))
 746               ,@(when (integerp end-col)
 747                   `((,end-col compilation-column-face nil t)))
 748
 749               ,@(nthcdr 6 item)
 750               (,(or (nth 5 item) 0)
 751                (compilation-error-properties ',file ,line ,end-line
 752                                              ,col ,end-col ',(or type 2)
 753                                              ',fmt)
 754                append)))))              ; for compilation-message-face
 755       compilation-error-regexp-alist)
 756
 757      compilation-mode-font-lock-keywords)))
 758
 759 \f
 760 ;;;###autoload
 761 (defun compile (command &optional comint)
 762   "Compile the program including the current buffer.  Default: run `make'.
 763 Runs COMMAND, a shell command, in a separate process asynchronously
 764 with output going to the buffer `*compilation*'.
 765
 766 If optional second arg COMINT is t the buffer will be in Comint mode with
 767 `compilation-shell-minor-mode'.
 768
 769 You can then use the command \\[next-error] to find the next error message
 770 and move to the source code that caused it.
 771
 772 Interactively, prompts for the command if `compilation-read-command' is
 773 non-nil; otherwise uses `compile-command'.  With prefix arg, always prompts.
 774 Additionally, with universal prefix arg, compilation buffer will be in
 775 comint mode, i.e. interactive.
 776
 777 To run more than one compilation at once, start one and rename
 778 the \`*compilation*' buffer to some other name with
 779 \\[rename-buffer].  Then start the next one.  On most systems,
 780 termination of the main compilation process kills its
 781 subprocesses.
 782
 783 The name used for the buffer is actually whatever is returned by
 784 the function in `compilation-buffer-name-function', so you can set that
 785 to a function that generates a unique name."
 786   (interactive
 787    (list
 788     (let ((command (eval compile-command)))
 789       (if (or compilation-read-command current-prefix-arg)
 790           (read-from-minibuffer "Compile command: "
 791                                 command nil nil
 792                                 (if (equal (car compile-history) command)
 793                                     '(compile-history . 1)
 794                                   'compile-history))
 795         command))
 796     (consp current-prefix-arg)))
 797   (unless (equal command (eval compile-command))
 798     (setq compile-command command))
 799   (save-some-buffers (not compilation-ask-about-save) nil)
 800   (setq compilation-directory default-directory)
 801   (compilation-start command comint))
 802
 803 ;; run compile with the default command line
 804 (defun recompile ()
 805   "Re-compile the program including the current buffer.
 806 If this is run in a Compilation mode buffer, re-use the arguments from the
 807 original use.  Otherwise, recompile using `compile-command'."
 808   (interactive)
 809   (save-some-buffers (not compilation-ask-about-save) nil)
 810   (let ((default-directory
 811           (or (and (not (eq major-mode (nth 1 compilation-arguments)))
 812                    compilation-directory)
 813               default-directory)))
 814     (apply 'compilation-start (or compilation-arguments
 815                                   `(,(eval compile-command))))))
 816
 817 (defcustom compilation-scroll-output nil
 818   "*Non-nil to scroll the *compilation* buffer window as output appears.
 819
 820 Setting it causes the Compilation mode commands to put point at the
 821 end of their output window so that the end of the output is always
 822 visible rather than the beginning."
 823   :type 'boolean
 824   :version "20.3"
 825   :group 'compilation)
 826
 827
 828 (defun compilation-buffer-name (mode-name name-function)
 829   "Return the name of a compilation buffer to use.
 830 If NAME-FUNCTION is non-nil, call it with one argument MODE-NAME
 831 to determine the buffer name.
 832 Likewise if `compilation-buffer-name-function' is non-nil.
 833 If current buffer is in Compilation mode for the same mode name
 834 return the name of the current buffer, so that it gets reused.
 835 Otherwise, construct a buffer name from MODE-NAME."
 836   (cond (name-function
 837          (funcall name-function mode-name))
 838         (compilation-buffer-name-function
 839          (funcall compilation-buffer-name-function mode-name))
 840         ((eq major-mode (nth 1 compilation-arguments))
 841          (buffer-name))
 842         (t
 843          (concat "*" (downcase mode-name) "*"))))
 844
 845 ;; This is a rough emulation of the old hack, until the transition to new
 846 ;; compile is complete.
 847 (defun compile-internal (command error-message
 848                                  &optional name-of-mode parser
 849                                  error-regexp-alist name-function
 850                                  enter-regexp-alist leave-regexp-alist
 851                                  file-regexp-alist nomessage-regexp-alist
 852                                  no-async highlight-regexp local-map)
 853   (if parser
 854       (error "Compile now works very differently, see `compilation-error-regexp-alist'"))
 855   (let ((compilation-error-regexp-alist
 856          (append file-regexp-alist (or error-regexp-alist
 857                                        compilation-error-regexp-alist)))
 858         (compilation-error (replace-regexp-in-string "^No more \\(.+\\)s\\.?"
 859                                                      "\\1" error-message)))
 860     (compilation-start command nil name-function highlight-regexp)))
 861 (make-obsolete 'compile-internal 'compilation-start)
 862
 863 (defun compilation-start (command &optional mode name-function highlight-regexp)
 864   "Run compilation command COMMAND (low level interface).
 865 If COMMAND starts with a cd command, that becomes the `default-directory'.
 866 The rest of the arguments are optional; for them, nil means use the default.
 867
 868 MODE is the major mode to set in the compilation buffer.  Mode
 869 may also be t meaning use `compilation-shell-minor-mode' under `comint-mode'.
 870 NAME-FUNCTION is a function called to name the buffer.
 871
 872 If HIGHLIGHT-REGEXP is non-nil, `next-error' will temporarily highlight
 873 the matching section of the visited source line; the default is to use the
 874 global value of `compilation-highlight-regexp'.
 875
 876 Returns the compilation buffer created."
 877   (or mode (setq mode 'compilation-mode))
 878   (let* ((name-of-mode
 879           (if (eq mode t)
 880               (prog1 "compilation" (require 'comint))
 881             (replace-regexp-in-string "-mode$" "" (symbol-name mode))))
 882          (thisdir default-directory)
 883          outwin outbuf)
 884     (with-current-buffer
 885         (setq outbuf
 886               (get-buffer-create
 887                (compilation-buffer-name name-of-mode name-function)))
 888       (let ((comp-proc (get-buffer-process (current-buffer))))
 889         (if comp-proc
 890             (if (or (not (eq (process-status comp-proc) 'run))
 891                     (yes-or-no-p
 892                      (format "A %s process is running; kill it? "
 893                              name-of-mode)))
 894                 (condition-case ()
 895                     (progn
 896                       (interrupt-process comp-proc)
 897                       (sit-for 1)
 898                       (delete-process comp-proc))
 899                   (error nil))
 900               (error "Cannot have two processes in `%s' at once"
 901                      (buffer-name)))))
 902       (buffer-disable-undo (current-buffer))
 903       ;; first transfer directory from where M-x compile was called
 904       (setq default-directory thisdir)
 905       ;; Make compilation buffer read-only.  The filter can still write it.
 906       ;; Clear out the compilation buffer.
 907       (let ((inhibit-read-only t)
 908             (default-directory thisdir))
 909         ;; Then evaluate a cd command if any, but don't perform it yet, else start-command
 910         ;; would do it again through the shell: (cd "..") AND sh -c "cd ..; make"
 911         (cd (if (string-match "^\\s *cd\\(?:\\s +\\(\\S +?\\)\\)?\\s *[;&\n]" command)
 912                 (if (match-end 1)
 913                     (match-string 1 command)
 914                   "~")
 915               default-directory))
 916         (erase-buffer)
 917         ;; output a mode setter, for saving and later reloading this buffer
 918         (insert "-*- mode: " name-of-mode
 919                 "; default-directory: " (prin1-to-string default-directory)
 920                 " -*-\n" command "\n")
 921         (setq thisdir default-directory))
 922       (set-buffer-modified-p nil))
 923     ;; If we're already in the compilation buffer, go to the end
 924     ;; of the buffer, so point will track the compilation output.
 925     (if (eq outbuf (current-buffer))
 926         (goto-char (point-max)))
 927     ;; Pop up the compilation buffer.
 928     (setq outwin (display-buffer outbuf nil t))
 929     (with-current-buffer outbuf
 930       (let ((process-environment
 931              (append
 932               compilation-environment
 933               (if (if (boundp 'system-uses-terminfo) ; `if' for compiler warning
 934                       system-uses-terminfo)
 935                   (list "TERM=dumb" "TERMCAP="
 936                         (format "COLUMNS=%d" (window-width)))
 937                 (list "TERM=emacs"
 938                       (format "TERMCAP=emacs:co#%d:tc=unknown:"
 939                               (window-width))))
 940               ;; Set the EMACS variable, but
 941               ;; don't override users' setting of $EMACS.
 942               (unless (getenv "EMACS") '("EMACS=t"))
 943               (copy-sequence process-environment))))
 944         (if (not (eq mode t))
 945             (funcall mode)
 946           (setq buffer-read-only nil)
 947           (with-no-warnings (comint-mode))
 948           (compilation-shell-minor-mode))
 949         (if highlight-regexp
 950             (set (make-local-variable 'compilation-highlight-regexp)
 951                  highlight-regexp))
 952         (set (make-local-variable 'compilation-arguments)
 953              (list command mode name-function highlight-regexp))
 954         (set (make-local-variable 'revert-buffer-function)
 955              'compilation-revert-buffer)
 956         (set-window-start outwin (point-min))
 957         (or (eq outwin (selected-window))
 958             (set-window-point outwin (if compilation-scroll-output
 959                                          (point)
 960                                        (point-min))))
 961         ;; The setup function is called before compilation-set-window-height
 962         ;; so it can set the compilation-window-height buffer locally.
 963         (if compilation-process-setup-function
 964             (funcall compilation-process-setup-function))
 965         (compilation-set-window-height outwin)
 966         ;; Start the compilation.
 967         (if (fboundp 'start-process)
 968             (let ((proc (if (eq mode t)
 969                             (get-buffer-process
 970                              (with-no-warnings
 971                               (comint-exec outbuf (downcase mode-name)
 972                                            shell-file-name nil `("-c" ,command))))
 973                           (start-process-shell-command (downcase mode-name)
 974                                                        outbuf command))))
 975               ;; Make the buffer's mode line show process state.
 976               (setq mode-line-process '(":%s"))
 977               (set-process-sentinel proc 'compilation-sentinel)
 978               (set-process-filter proc 'compilation-filter)
 979               (set-marker (process-mark proc) (point) outbuf)
 980               (setq compilation-in-progress
 981                     (cons proc compilation-in-progress)))
 982           ;; No asynchronous processes available.
 983           (message "Executing `%s'..." command)
 984           ;; Fake modeline display as if `start-process' were run.
 985           (setq mode-line-process ":run")
 986           (force-mode-line-update)
 987           (sit-for 0)                   ; Force redisplay
 988           (let ((status (call-process shell-file-name nil outbuf nil "-c"
 989                                       command)))
 990             (cond ((numberp status)
 991                    (compilation-handle-exit 'exit status
 992                                             (if (zerop status)
 993                                                 "finished\n"
 994                                               (format "\
 995 exited abnormally with code %d\n"
 996                                                       status))))
 997                   ((stringp status)
 998                    (compilation-handle-exit 'signal status
 999                                             (concat status "\n")))
1000                   (t
1001                    (compilation-handle-exit 'bizarre status status))))
1002           ;; Without async subprocesses, the buffer is not yet
1003           ;; fontified, so fontify it now.
1004           (let ((font-lock-verbose nil)) ; shut up font-lock messages
1005             (font-lock-fontify-buffer))
1006           (message "Executing `%s'...done" command)))
1007       ;; Now finally cd to where the shell started make/grep/...
1008       (setq default-directory thisdir))
1009     (if (buffer-local-value 'compilation-scroll-output outbuf)
1010         (save-selected-window
1011           (select-window outwin)
1012           (goto-char (point-max))))
1013     ;; Make it so the next C-x ` will use this buffer.
1014     (setq next-error-last-buffer outbuf)))
1015
1016 (defun compilation-set-window-height (window)
1017   "Set the height of WINDOW according to `compilation-window-height'."
1018   (let ((height (buffer-local-value 'compilation-window-height (window-buffer window))))
1019     (and height
1020          (= (window-width window) (frame-width (window-frame window)))
1021          ;; If window is alone in its frame, aside from a minibuffer,
1022          ;; don't change its height.
1023          (not (eq window (frame-root-window (window-frame window))))
1024          ;; Stef said that doing the saves in this order is safer:
1025          (save-excursion
1026            (save-selected-window
1027              (select-window window)
1028              (enlarge-window (- height (window-height))))))))
1029
1030 (defvar compilation-menu-map
1031   (let ((map (make-sparse-keymap "Errors")))
1032     (define-key map [stop-subjob]
1033       '("Stop Compilation" . kill-compilation))
1034     (define-key map [compilation-mode-separator2]
1035       '("----" . nil))
1036     (define-key map [compilation-first-error]
1037       '("First Error" . first-error))
1038     (define-key map [compilation-previous-error]
1039       '("Previous Error" . previous-error))
1040     (define-key map [compilation-next-error]
1041       '("Next Error" . next-error))
1042     map))
1043
1044 (defvar compilation-minor-mode-map
1045   (let ((map (make-sparse-keymap)))
1046     (define-key map [mouse-2] 'compile-goto-error)
1047     (define-key map "\C-c\C-c" 'compile-goto-error)
1048     (define-key map "\C-m" 'compile-goto-error)
1049     (define-key map "\C-c\C-k" 'kill-compilation)
1050     (define-key map "\M-n" 'compilation-next-error)
1051     (define-key map "\M-p" 'compilation-previous-error)
1052     (define-key map "\M-{" 'compilation-previous-file)
1053     (define-key map "\M-}" 'compilation-next-file)
1054     ;; Set up the menu-bar
1055     (define-key map [menu-bar compilation]
1056       (cons "Errors" compilation-menu-map))
1057     map)
1058   "Keymap for `compilation-minor-mode'.")
1059
1060 (defvar compilation-shell-minor-mode-map
1061   (let ((map (make-sparse-keymap)))
1062     (define-key map "\M-\C-m" 'compile-goto-error)
1063     (define-key map "\M-\C-n" 'compilation-next-error)
1064     (define-key map "\M-\C-p" 'compilation-previous-error)
1065     (define-key map "\M-{" 'compilation-previous-file)
1066     (define-key map "\M-}" 'compilation-next-file)
1067     ;; Set up the menu-bar
1068     (define-key map [menu-bar compilation]
1069       (cons "Errors" compilation-menu-map))
1070     map)
1071   "Keymap for `compilation-shell-minor-mode'.")
1072
1073 (defvar compilation-button-map
1074   (let ((map (make-sparse-keymap)))
1075     (define-key map [mouse-2] 'compile-goto-error)
1076     (define-key map "\C-m" 'compile-goto-error)
1077     map)
1078   "Keymap for compilation-message buttons.")
1079 (fset 'compilation-button-map compilation-button-map)
1080
1081 (defvar compilation-mode-map
1082   (let ((map (make-sparse-keymap)))
1083     (set-keymap-parent map compilation-minor-mode-map)
1084     (define-key map " " 'scroll-up)
1085     (define-key map "\^?" 'scroll-down)
1086     (define-key map "\C-c\C-f" 'next-error-follow-minor-mode)
1087
1088     ;; Set up the menu-bar
1089     (define-key map [menu-bar compilation]
1090       (cons "Compile" (make-sparse-keymap "Compile")))
1091     (define-key map [menu-bar compilation compilation-separator2]
1092       '("----" . nil))
1093     (define-key map [menu-bar compilation compilation-grep]
1094       '("Search Files (grep)" . grep))
1095     (define-key map [menu-bar compilation compilation-recompile]
1096       '("Recompile" . recompile))
1097     (define-key map [menu-bar compilation compilation-compile]
1098       '("Compile..." . compile))
1099     map)
1100   "Keymap for compilation log buffers.
1101 `compilation-minor-mode-map' is a parent of this.")
1102
1103 (put 'compilation-mode 'mode-class 'special)
1104
1105 (defvar compilation-skip-to-next-location t
1106   "*If non-nil, skip multiple error messages for the same source location.")
1107
1108 (defcustom compilation-skip-threshold 1
1109   "*Compilation motion commands skip less important messages.
1110 The value can be either 2 -- skip anything less than error, 1 --
1111 skip anything less than warning or 0 -- don't skip any messages.
1112 Note that all messages not positively identified as warning or
1113 info, are considered errors."
1114   :type '(choice (const :tag "Warnings and info" 2)
1115                  (const :tag "Info" 1)
1116                  (const :tag "None" 0))
1117   :group 'compilation
1118   :version "21.4")
1119
1120 (defcustom compilation-skip-visited nil
1121   "*Compilation motion commands skip visited messages if this is t.
1122 Visited messages are ones for which the file, line and column have been jumped
1123 to from the current content in the current compilation buffer, even if it was
1124 from a different message."
1125   :type 'boolean
1126   :group 'compilation
1127   :version "21.4")
1128
1129 ;;;###autoload
1130 (defun compilation-mode (&optional name-of-mode)
1131   "Major mode for compilation log buffers.
1132 \\<compilation-mode-map>To visit the source for a line-numbered error,
1133 move point to the error message line and type \\[compile-goto-error].
1134 To kill the compilation, type \\[kill-compilation].
1135
1136 Runs `compilation-mode-hook' with `run-hooks' (which see).
1137
1138 \\{compilation-mode-map}"
1139   (interactive)
1140   (kill-all-local-variables)
1141   (use-local-map compilation-mode-map)
1142   (setq major-mode 'compilation-mode
1143         mode-name (or name-of-mode "Compilation"))
1144   (set (make-local-variable 'page-delimiter)
1145        compilation-page-delimiter)
1146   (compilation-setup)
1147   (run-mode-hooks 'compilation-mode-hook))
1148
1149 (defmacro define-compilation-mode (mode name doc &rest body)
1150   "This is like `define-derived-mode' without the PARENT argument.
1151 The parent is always `compilation-mode' and the customizable `compilation-...'
1152 variables are also set from the name of the mode you have chosen, by replacing
1153 the fist word, e.g `compilation-scroll-output' from `grep-scroll-output' if that
1154 variable exists."
1155   (let ((mode-name (replace-regexp-in-string "-mode\\'" "" (symbol-name mode))))
1156     `(define-derived-mode ,mode compilation-mode ,name
1157        ,doc
1158        ,@(mapcar (lambda (v)
1159                    (setq v (cons v
1160                                  (intern-soft (replace-regexp-in-string
1161                                                "^compilation" mode-name
1162                                                (symbol-name v)))))
1163                    (and (cdr v)
1164                         (or (boundp (cdr v))
1165                             (if (boundp 'byte-compile-bound-variables)
1166                                 (memq (cdr v) byte-compile-bound-variables)))
1167                         `(set (make-local-variable ',(car v)) ,(cdr v))))
1168                  '(compilation-buffer-name-function
1169                    compilation-directory-matcher
1170                    compilation-error
1171                    compilation-error-regexp-alist
1172                    compilation-error-regexp-alist-alist
1173                    compilation-error-screen-columns
1174                    compilation-finish-function
1175                    compilation-finish-functions
1176                    compilation-first-column
1177                    compilation-mode-font-lock-keywords
1178                    compilation-page-delimiter
1179                    compilation-parse-errors-filename-function
1180                    compilation-process-setup-function
1181                    compilation-scroll-output
1182                    compilation-search-path
1183                    compilation-skip-threshold
1184                    compilation-window-height))
1185        ,@body)))
1186
1187 (defun compilation-revert-buffer (ignore-auto noconfirm)
1188   (if buffer-file-name
1189       (let (revert-buffer-function)
1190         (revert-buffer ignore-auto noconfirm))
1191     (if (or noconfirm (yes-or-no-p (format "Restart compilation? ")))
1192         (apply 'compilation-start compilation-arguments))))
1193
1194 (defvar compilation-current-error nil
1195   "Marker to the location from where the next error will be found.
1196 The global commands next/previous/first-error/goto-error use this.")
1197
1198 (defvar compilation-messages-start nil
1199   "Buffer position of the beginning of the compilation messages.
1200 If nil, use the beginning of buffer.")
1201
1202 ;; A function name can't be a hook, must be something with a value.
1203 (defconst compilation-turn-on-font-lock 'turn-on-font-lock)
1204
1205 (defun compilation-setup (&optional minor)
1206   "Prepare the buffer for the compilation parsing commands to work.
1207 Optional argument MINOR indicates this is called from
1208 `compilation-minor-mode'."
1209   (unless minor
1210     (setq buffer-read-only t))
1211   (make-local-variable 'compilation-current-error)
1212   (make-local-variable 'compilation-messages-start)
1213   (make-local-variable 'compilation-error-screen-columns)
1214   (make-local-variable 'overlay-arrow-position)
1215   ;; Note that compilation-next-error-function is for interfacing
1216   ;; with the next-error function in simple.el, and it's only
1217   ;; coincidentally named similarly to compilation-next-error.
1218   (setq next-error-function 'compilation-next-error-function)
1219   (set (make-local-variable 'font-lock-extra-managed-props)
1220        '(directory message help-echo mouse-face debug))
1221   (set (make-local-variable 'compilation-locs)
1222        (make-hash-table :test 'equal :weakness 'value))
1223   ;; lazy-lock would never find the message unless it's scrolled to.
1224   ;; jit-lock might fontify some things too late.
1225   (set (make-local-variable 'font-lock-support-mode) nil)
1226   (set (make-local-variable 'font-lock-maximum-size) nil)
1227   (let ((fld font-lock-defaults))
1228     (if (and minor fld)
1229         (font-lock-add-keywords nil (compilation-mode-font-lock-keywords))
1230       (setq font-lock-defaults '(compilation-mode-font-lock-keywords t)))
1231     (if minor
1232         (if font-lock-mode
1233             (if fld
1234                 (font-lock-fontify-buffer)
1235               (font-lock-change-mode)
1236               (turn-on-font-lock))
1237           (turn-on-font-lock))
1238       ;; maybe defer font-lock till after derived mode is set up
1239       (run-mode-hooks 'compilation-turn-on-font-lock))))
1240
1241 ;;;###autoload
1242 (define-minor-mode compilation-shell-minor-mode
1243   "Toggle compilation shell minor mode.
1244 With arg, turn compilation mode on if and only if arg is positive.
1245 In this minor mode, all the error-parsing commands of the
1246 Compilation major mode are available but bound to keys that don't
1247 collide with Shell mode.  See `compilation-mode'.
1248 Turning the mode on runs the normal hook `compilation-shell-minor-mode-hook'."
1249   nil " Shell-Compile"
1250   :group 'compilation
1251   (if compilation-shell-minor-mode
1252       (compilation-setup t)
1253     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1254     (font-lock-fontify-buffer)))
1255
1256 ;;;###autoload
1257 (define-minor-mode compilation-minor-mode
1258   "Toggle compilation minor mode.
1259 With arg, turn compilation mode on if and only if arg is positive.
1260 In this minor mode, all the error-parsing commands of the
1261 Compilation major mode are available.  See `compilation-mode'.
1262 Turning the mode on runs the normal hook `compilation-minor-mode-hook'."
1263   nil " Compilation"
1264   :group 'compilation
1265   (if compilation-minor-mode
1266       (compilation-setup t)
1267     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1268     (font-lock-fontify-buffer)))
1269
1270 (defun compilation-handle-exit (process-status exit-status msg)
1271   "Write MSG in the current buffer and hack its mode-line-process."
1272   (let ((inhibit-read-only t)
1273         (status (if compilation-exit-message-function
1274                     (funcall compilation-exit-message-function
1275                              process-status exit-status msg)
1276                   (cons msg exit-status)))
1277         (omax (point-max))
1278         (opoint (point)))
1279     ;; Record where we put the message, so we can ignore it later on.
1280     (goto-char omax)
1281     (insert ?\n mode-name " " (car status))
1282     (if (and (numberp compilation-window-height)
1283              (zerop compilation-window-height))
1284         (message "%s" (cdr status)))
1285     (if (bolp)
1286         (forward-char -1))
1287     (insert " at " (substring (current-time-string) 0 19))
1288     (goto-char (point-max))
1289     ;; Prevent that message from being recognized as a compilation error.
1290     (add-text-properties omax (point)
1291                          (append '(compilation-handle-exit t) nil))
1292     (setq mode-line-process (format ":%s [%s]" process-status (cdr status)))
1293     ;; Force mode line redisplay soon.
1294     (force-mode-line-update)
1295     (if (and opoint (< opoint omax))
1296         (goto-char opoint))
1297     (if compilation-finish-function
1298         (funcall compilation-finish-function (current-buffer) msg))
1299     (let ((functions compilation-finish-functions))
1300       (while functions
1301         (funcall (car functions) (current-buffer) msg)
1302         (setq functions (cdr functions))))))
1303
1304 ;; Called when compilation process changes state.
1305 (defun compilation-sentinel (proc msg)
1306   "Sentinel for compilation buffers."
1307   (if (memq (process-status proc) '(exit signal))
1308       (let ((buffer (process-buffer proc)))
1309         (if (null (buffer-name buffer))
1310             ;; buffer killed
1311             (set-process-buffer proc nil)
1312           (with-current-buffer buffer
1313             ;; Write something in the compilation buffer
1314             ;; and hack its mode line.
1315             (compilation-handle-exit (process-status proc)
1316                                      (process-exit-status proc)
1317                                      msg)
1318             ;; Since the buffer and mode line will show that the
1319             ;; process is dead, we can delete it now.  Otherwise it
1320             ;; will stay around until M-x list-processes.
1321             (delete-process proc)))
1322         (setq compilation-in-progress (delq proc compilation-in-progress)))))
1323
1324 (defun compilation-filter (proc string)
1325   "Process filter for compilation buffers.
1326 Just inserts the text, but uses `insert-before-markers'."
1327   (if (buffer-name (process-buffer proc))
1328       (with-current-buffer (process-buffer proc)
1329         (let ((inhibit-read-only t))
1330           (save-excursion
1331             (goto-char (process-mark proc))
1332             (insert-before-markers string)
1333             (run-hooks 'compilation-filter-hook))))))
1334
1335 ;;; test if a buffer is a compilation buffer, assuming we're in the buffer
1336 (defsubst compilation-buffer-internal-p ()
1337   "Test if inside a compilation buffer."
1338   (local-variable-p 'compilation-locs))
1339
1340 ;;; test if a buffer is a compilation buffer, using compilation-buffer-internal-p
1341 (defsubst compilation-buffer-p (buffer)
1342   "Test if BUFFER is a compilation buffer."
1343   (with-current-buffer buffer
1344     (compilation-buffer-internal-p)))
1345
1346 (defmacro compilation-loop (< property-change 1+ error)
1347   `(while (,< n 0)
1348       (or (setq pt (,property-change pt 'message))
1349           (error ,error compilation-error))
1350       ;; prop 'message usually has 2 changes, on and off, so re-search if off
1351       (or (setq msg (get-text-property pt 'message))
1352           (if (setq pt (,property-change pt 'message))
1353               (setq msg (get-text-property pt 'message)))
1354           (error ,error compilation-error))
1355       (or (< (cadr msg) compilation-skip-threshold)
1356           (if different-file
1357               (eq (prog1 last (setq last (nth 2 (car msg))))
1358                   last))
1359           (if compilation-skip-visited
1360               (nthcdr 4 (car msg)))
1361           (if compilation-skip-to-next-location
1362               (eq (car msg) loc))
1363           ;; count this message only if none of the above are true
1364           (setq n (,1+ n)))))
1365
1366 (defun compilation-next-error (n &optional different-file pt)
1367   "Move point to the next error in the compilation buffer.
1368 Prefix arg N says how many error messages to move forwards (or
1369 backwards, if negative).
1370 Does NOT find the source line like \\[next-error]."
1371   (interactive "p")
1372   (or (compilation-buffer-p (current-buffer))
1373       (error "Not in a compilation buffer"))
1374   (or pt (setq pt (point)))
1375   (let* ((msg (get-text-property pt 'message))
1376          (loc (car msg))
1377          last)
1378     (if (zerop n)
1379         (unless (or msg                 ; find message near here
1380                     (setq msg (get-text-property (max (1- pt) (point-min))
1381                                                  'message)))
1382           (setq pt (previous-single-property-change pt 'message nil
1383                                                     (line-beginning-position)))
1384           (unless (setq msg (get-text-property (max (1- pt) (point-min)) 'message))
1385             (setq pt (next-single-property-change pt 'message nil
1386                                                   (line-end-position)))
1387             (or (setq msg (get-text-property pt 'message))
1388                 (setq pt (point)))))
1389       (setq last (nth 2 (car msg)))
1390       (if (>= n 0)
1391           (compilation-loop > next-single-property-change 1-
1392                             (if (get-buffer-process (current-buffer))
1393                                 "No more %ss yet"
1394                               "Moved past last %s"))
1395         ;; Don't move "back" to message at or before point.
1396         ;; Pass an explicit (point-min) to make sure pt is non-nil.
1397         (setq pt (previous-single-property-change pt 'message nil (point-min)))
1398         (compilation-loop < previous-single-property-change 1+
1399                           "Moved back before first %s")))
1400     (goto-char pt)
1401     (or msg
1402         (error "No %s here" compilation-error))))
1403
1404 (defun compilation-previous-error (n)
1405   "Move point to the previous error in the compilation buffer.
1406 Prefix arg N says how many error messages to move backwards (or
1407 forwards, if negative).
1408 Does NOT find the source line like \\[previous-error]."
1409   (interactive "p")
1410   (compilation-next-error (- n)))
1411
1412 (defun compilation-next-file (n)
1413   "Move point to the next error for a different file than the current one.
1414 Prefix arg N says how many files to move forwards (or backwards, if negative)."
1415   (interactive "p")
1416   (compilation-next-error n t))
1417
1418 (defun compilation-previous-file (n)
1419   "Move point to the previous error for a different file than the current one.
1420 Prefix arg N says how many files to move backwards (or forwards, if negative)."
1421   (interactive "p")
1422   (compilation-next-file (- n)))
1423
1424 (defun kill-compilation ()
1425   "Kill the process made by the \\[compile] or \\[grep] commands."
1426   (interactive)
1427   (let ((buffer (compilation-find-buffer)))
1428     (if (get-buffer-process buffer)
1429         (interrupt-process (get-buffer-process buffer))
1430       (error "The compilation process is not running"))))
1431
1432 (defalias 'compile-mouse-goto-error 'compile-goto-error)
1433
1434 (defun compile-goto-error (&optional event)
1435   "Visit the source for the error message at point.
1436 Use this command in a compilation log buffer.  Sets the mark at point there."
1437   (interactive (list last-input-event))
1438   (if event (posn-set-point (event-end event)))
1439   (or (compilation-buffer-p (current-buffer))
1440       (error "Not in a compilation buffer"))
1441   (if (get-text-property (point) 'directory)
1442       (dired-other-window (car (get-text-property (point) 'directory)))
1443     (push-mark)
1444     (setq compilation-current-error (point))
1445     (next-error 0)))
1446
1447 ;; Return a compilation buffer.
1448 ;; If the current buffer is a compilation buffer, return it.
1449 ;; Otherwise, look for a compilation buffer and signal an error
1450 ;; if there are none.
1451 (defun compilation-find-buffer (&optional other-buffer)
1452   (next-error-find-buffer other-buffer 'compilation-buffer-internal-p))
1453
1454 ;;;###autoload
1455 (defun compilation-next-error-function (n &optional reset)
1456   (interactive "p")
1457   (set-buffer (compilation-find-buffer))
1458   (when reset
1459     (setq compilation-current-error nil))
1460   (let* ((columns compilation-error-screen-columns) ; buffer's local value
1461          (last 1)
1462          (loc (compilation-next-error (or n 1) nil
1463                                       (or compilation-current-error
1464                                           compilation-messages-start
1465                                           (point-min))))
1466          (end-loc (nth 2 loc))
1467          (marker (point-marker)))
1468     (setq compilation-current-error (point-marker)
1469           overlay-arrow-position
1470             (if (bolp)
1471                 compilation-current-error
1472               (copy-marker (line-beginning-position)))
1473           loc (car loc))
1474     ;; If loc contains no marker, no error in that file has been visited.  If
1475     ;; the marker is invalid the buffer has been killed.  So, recalculate all
1476     ;; markers for that file.
1477     (unless (and (nth 3 loc) (marker-buffer (nth 3 loc)))
1478       (with-current-buffer (compilation-find-file marker (caar (nth 2 loc))
1479                                                   (or (cdar (nth 2 loc))
1480                                                       default-directory))
1481         (save-restriction
1482           (widen)
1483           (goto-char (point-min))
1484           ;; Treat file's found lines in forward order, 1 by 1.
1485           (dolist (line (reverse (cddr (nth 2 loc))))
1486             (when (car line)            ; else this is a filename w/o a line#
1487               (beginning-of-line (- (car line) last -1))
1488               (setq last (car line)))
1489             ;; Treat line's found columns and store/update a marker for each.
1490             (dolist (col (cdr line))
1491               (if (car col)
1492                   (if (eq (car col) -1) ; special case for range end
1493                       (end-of-line)
1494                     (if columns
1495                         (move-to-column (car col))
1496                       (beginning-of-line)
1497                       (forward-char (car col))))
1498                 (beginning-of-line)
1499                 (skip-chars-forward " \t"))
1500               (if (nth 3 col)
1501                   (set-marker (nth 3 col) (point))
1502                 (setcdr (nthcdr 2 col) `(,(point-marker)))))))))
1503     (compilation-goto-locus marker (nth 3 loc) (nth 3 end-loc))
1504     (setcdr (nthcdr 3 loc) t)))         ; Set this one as visited.
1505
1506 (defvar compilation-gcpro nil
1507   "Internal variable used to keep some values from being GC'd.")
1508 (make-variable-buffer-local 'compilation-gcpro)
1509
1510 (defun compilation-fake-loc (marker file &optional line col)
1511   "Preassociate MARKER with FILE.
1512 FILE should be ABSOLUTE-FILENAME or (RELATIVE-FILENAME . DIRNAME).
1513 This is useful when you compile temporary files, but want
1514 automatic translation of the messages to the real buffer from
1515 which the temporary file came.  This only works if done before a
1516 message about FILE appears!
1517
1518 Optional args LINE and COL default to 1 and beginning of
1519 indentation respectively.  The marker is expected to reflect
1520 this.  In the simplest case the marker points to the first line
1521 of the region that was saved to the temp file.
1522
1523 If you concatenate several regions into the temp file (e.g. a
1524 header with variable assignments and a code region), you must
1525 call this several times, once each for the last line of one
1526 region and the first line of the next region."
1527   (or (consp file) (setq file (list file)))
1528   (setq file (compilation-get-file-structure file))
1529   ;; Between the current call to compilation-fake-loc and the first occurrence
1530   ;; of an error message referring to `file', the data is only kept is the
1531   ;; weak hash-table compilation-locs, so we need to prevent this entry
1532   ;; in compilation-locs from being GC'd away.  --Stef
1533   (push file compilation-gcpro)
1534   (let ((loc (compilation-assq (or line 1) (cdr file))))
1535     (setq loc (compilation-assq col loc))
1536     (if (cdr loc)
1537         (setcdr (cddr loc) (list marker))
1538       (setcdr loc (list line file marker)))
1539     loc))
1540
1541 (defcustom compilation-context-lines 0
1542   "*Display this many lines of leading context before message.
1543 If nil, don't scroll the compilation output window."
1544   :type '(choice integer (const :tag "No window scrolling" nil))
1545   :group 'compilation
1546   :version "21.4")
1547
1548 (defsubst compilation-set-window (w mk)
1549   "Align the compilation output window W with marker MK near top."
1550   (if (integerp compilation-context-lines)
1551       (set-window-start w (save-excursion
1552                             (goto-char mk)
1553                             (beginning-of-line (- 1 compilation-context-lines))
1554                             (point))))
1555   (set-window-point w mk))
1556
1557 (defun compilation-goto-locus (msg mk end-mk)
1558   "Jump to an error corresponding to MSG at MK.
1559 All arguments are markers.  If END-MK is non-nil, mark is set there
1560 and overlay is highlighted between MK and END-MK."
1561   (if (eq (window-buffer (selected-window))
1562           (marker-buffer msg))
1563       ;; If the compilation buffer window is selected,
1564       ;; keep the compilation buffer in this window;
1565       ;; display the source in another window.
1566       (let ((pop-up-windows t))
1567         (pop-to-buffer (marker-buffer mk)))
1568     (if (window-dedicated-p (selected-window))
1569         (pop-to-buffer (marker-buffer mk))
1570       (switch-to-buffer (marker-buffer mk))))
1571   ;; If narrowing gets in the way of going to the right place, widen.
1572   (unless (eq (goto-char mk) (point))
1573     (widen)
1574     (goto-char mk))
1575   (if end-mk
1576       (push-mark end-mk t)
1577     (if mark-active (setq mark-active)))
1578   ;; If hideshow got in the way of
1579   ;; seeing the right place, open permanently.
1580   (dolist (ov (overlays-at (point)))
1581     (when (eq 'hs (overlay-get ov 'invisible))
1582       (delete-overlay ov)
1583       (goto-char mk)))
1584
1585   ;; Show compilation buffer in other window, scrolled to this error.
1586   (let* ((pop-up-windows t)
1587          ;; Use an existing window if it is in a visible frame.
1588          (w (or (get-buffer-window (marker-buffer msg) 'visible)
1589                 ;; Pop up a window.
1590                 (display-buffer (marker-buffer msg))))
1591          (highlight-regexp (with-current-buffer (marker-buffer msg)
1592                              ;; also do this while we change buffer
1593                              (compilation-set-window w msg)
1594                              compilation-highlight-regexp)))
1595     (compilation-set-window-height w)
1596
1597     (when highlight-regexp
1598       (unless compilation-highlight-overlay
1599         (setq compilation-highlight-overlay
1600               (make-overlay (point-min) (point-min)))
1601         (overlay-put compilation-highlight-overlay 'face 'next-error))
1602       (with-current-buffer (marker-buffer mk)
1603         (save-excursion
1604           (if end-mk (goto-char end-mk) (end-of-line))
1605           (let ((end (point)))
1606             (if mk (goto-char mk) (beginning-of-line))
1607             (if (and (stringp highlight-regexp)
1608                      (re-search-forward highlight-regexp end t))
1609                 (progn
1610                   (goto-char (match-beginning 0))
1611                   (move-overlay compilation-highlight-overlay
1612                                 (match-beginning 0) (match-end 0)
1613                                 (current-buffer)))
1614               (move-overlay compilation-highlight-overlay
1615                             (point) end (current-buffer)))
1616             (if (numberp next-error-highlight)
1617                 (sit-for next-error-highlight))
1618             (if (not (eq next-error-highlight t))
1619                 (delete-overlay compilation-highlight-overlay))))))
1620     (when (and (eq next-error-highlight 'fringe-arrow))
1621       (set (make-local-variable 'overlay-arrow-position)
1622            (copy-marker (line-beginning-position))))))
1623 \f
1624 (defun compilation-find-file (marker filename dir &rest formats)
1625   "Find a buffer for file FILENAME.
1626 Search the directories in `compilation-search-path'.
1627 A nil in `compilation-search-path' means to try the
1628 current directory, which is passed in DIR.
1629 If FILENAME is not found at all, ask the user where to find it.
1630 Pop up the buffer containing MARKER and scroll to MARKER if we ask the user."
1631   (or formats (setq formats '("%s")))
1632   (save-excursion
1633     (let ((dirs compilation-search-path)
1634           buffer thisdir fmts name)
1635       (if (file-name-absolute-p filename)
1636           ;; The file name is absolute.  Use its explicit directory as
1637           ;; the first in the search path, and strip it from FILENAME.
1638           (setq filename (abbreviate-file-name (expand-file-name filename))
1639                 dirs (cons (file-name-directory filename) dirs)
1640                 filename (file-name-nondirectory filename)))
1641       ;; Now search the path.
1642       (while (and dirs (null buffer))
1643         (setq thisdir (or (car dirs) dir)
1644               fmts formats)
1645         ;; For each directory, try each format string.
1646         (while (and fmts (null buffer))
1647           (setq name (expand-file-name (format (car fmts) filename) thisdir)
1648                 buffer (and (file-exists-p name)
1649                             (find-file-noselect name))
1650                 fmts (cdr fmts)))
1651         (setq dirs (cdr dirs)))
1652       (or buffer
1653           ;; The file doesn't exist.  Ask the user where to find it.
1654           (let ((pop-up-windows t))
1655             (compilation-set-window (display-buffer (marker-buffer marker))
1656                                     marker)
1657             (let ((name (expand-file-name
1658                          (read-file-name
1659                           (format "Find this error in: (default %s) "
1660                                   filename)
1661                           dir filename t))))
1662               (if (file-directory-p name)
1663                   (setq name (expand-file-name filename name)))
1664               (setq buffer (and (file-exists-p name)
1665                                 (find-file name))))))
1666       ;; Make intangible overlays tangible.
1667       (mapcar (function (lambda (ov)
1668                           (when (overlay-get ov 'intangible)
1669                             (overlay-put ov 'intangible nil))))
1670               (overlays-in (point-min) (point-max)))
1671       buffer)))
1672
1673 (defun compilation-get-file-structure (file &optional fmt)
1674   "Retrieve FILE's file-structure or create a new one.
1675 FILE should be (ABSOLUTE-FILENAME) or (RELATIVE-FILENAME . DIRNAME)."
1676
1677   (or (gethash file compilation-locs)
1678       ;; File was not previously encountered, at least not in the form passed.
1679       ;; Let's normalize it and look again.
1680       (let ((filename (car file))
1681             (default-directory (if (cdr file)
1682                                    (file-truename (cdr file))
1683                                  default-directory)))
1684
1685         ;; Check for a comint-file-name-prefix and prepend it if appropriate.
1686         ;; (This is very useful for compilation-minor-mode in an rlogin-mode
1687         ;; buffer.)
1688         (if (boundp 'comint-file-name-prefix)
1689             (if (file-name-absolute-p filename)
1690                 (setq filename
1691                       (concat (with-no-warnings comint-file-name-prefix) filename))
1692               (setq default-directory
1693                     (file-truename
1694                      (concat (with-no-warnings comint-file-name-prefix) default-directory)))))
1695
1696         ;; If compilation-parse-errors-filename-function is
1697         ;; defined, use it to process the filename.
1698         (when compilation-parse-errors-filename-function
1699           (setq filename
1700                 (funcall compilation-parse-errors-filename-function
1701                          filename)))
1702
1703         ;; Some compilers (e.g. Sun's java compiler, reportedly) produce bogus
1704         ;; file names like "./bar//foo.c" for file "bar/foo.c";
1705         ;; expand-file-name will collapse these into "/foo.c" and fail to find
1706         ;; the appropriate file.  So we look for doubled slashes in the file
1707         ;; name and fix them.
1708         (setq filename (command-line-normalize-file-name filename))
1709
1710         ;; Now eliminate any "..", because find-file would get them wrong.
1711         ;; Make relative and absolute filenames, with or without links, the
1712         ;; same.
1713         (setq filename
1714               (list (abbreviate-file-name
1715                      (file-truename (if (cdr file)
1716                                         (expand-file-name filename)
1717                                       filename)))))
1718
1719         ;; Store it for the possibly unnormalized name
1720         (puthash file
1721                  ;; Retrieve or create file-structure for normalized name
1722                  (or (gethash filename compilation-locs)
1723                      (puthash filename (list filename fmt) compilation-locs))
1724                  compilation-locs))))
1725
1726 (add-to-list 'debug-ignored-errors "^No more [-a-z ]+s yet$")
1727
1728 ;;; Compatibility with the old compile.el.
1729
1730 (defun compile-buffer-substring (n) (if n (match-string n)))
1731
1732 (defun compilation-compat-error-properties (err)
1733   "Map old-style error ERR to new-style message."
1734   ;; Old-style structure is (MARKER (FILE DIR) LINE COL) or
1735   ;; (MARKER . MARKER).
1736   (let ((dst (cdr err)))
1737     (if (markerp dst)
1738         ;; Must start with a face, for font-lock.
1739         `(face nil
1740           message ,(list (list nil nil nil dst) 2)
1741           help-echo "mouse-2: visit the source location"
1742           keymap compilation-button-map
1743           mouse-face highlight)
1744       ;; Too difficult to do it by hand: dispatch to the normal code.
1745       (let* ((file (pop dst))
1746              (line (pop dst))
1747              (col (pop dst))
1748              (filename (pop file))
1749              (dirname (pop file))
1750              (fmt (pop file)))
1751         (compilation-internal-error-properties
1752          (cons filename dirname) line nil col nil 2 fmt)))))
1753
1754 (defun compilation-compat-parse-errors (limit)
1755   (when compilation-parse-errors-function
1756     ;; FIXME: We should remove the rest of the compilation keywords
1757     ;; but we can't do that from here because font-lock is using
1758     ;; the value right now.  --stef
1759     (save-excursion
1760       (setq compilation-error-list nil)
1761       ;; Reset compilation-parsing-end each time because font-lock
1762       ;; might force us the re-parse many times (typically because
1763       ;; some code adds some text-property to the output that we
1764       ;; already parsed).  You might say "why reparse", well:
1765       ;; because font-lock has just removed the `message' property so
1766       ;; have to do it all over again.
1767       (if compilation-parsing-end
1768           (set-marker compilation-parsing-end (point))
1769         (setq compilation-parsing-end (point-marker)))
1770       (condition-case nil
1771           ;; Ignore any error: we're calling this function earlier than
1772           ;; in the old compile.el so things might not all be setup yet.
1773           (funcall compilation-parse-errors-function limit nil)
1774         (error nil))
1775       (dolist (err (if (listp compilation-error-list) compilation-error-list))
1776         (let* ((src (car err))
1777                (dst (cdr err))
1778                (loc (cond ((markerp dst) (list nil nil nil dst))
1779                           ((consp dst)
1780                            (list (nth 2 dst) (nth 1 dst)
1781                                  (cons (cdar dst) (caar dst)))))))
1782           (when loc
1783             (goto-char src)
1784             ;; (put-text-property src (line-end-position) 'font-lock-face 'font-lock-warning-face)
1785             (put-text-property src (line-end-position)
1786                                'message (list loc 2)))))))
1787   (goto-char limit)
1788   nil)
1789
1790 ;; Beware: this is not only compatiblity code.  New code stil uses it.  --Stef
1791 (defun compilation-forget-errors ()
1792   ;; In case we hit the same file/line specs, we want to recompute a new
1793   ;; marker for them, so flush our cache.
1794   (setq compilation-locs (make-hash-table :test 'equal :weakness 'value))
1795   (setq compilation-gcpro nil)
1796   ;; FIXME: the old code reset the directory-stack, so maybe we should
1797   ;; put a `directory change' marker of some sort, but where?  -stef
1798   ;;
1799   ;; FIXME: The old code moved compilation-current-error (which was
1800   ;; virtually represented by a mix of compilation-parsing-end and
1801   ;; compilation-error-list) to point-min, but that was only meaningful for
1802   ;; the internal uses of compilation-forget-errors: all calls from external
1803   ;; packages seem to be followed by a move of compilation-parsing-end to
1804   ;; something equivalent to point-max.  So we speculatively move
1805   ;; compilation-current-error to point-max (since the external package
1806   ;; won't know that it should do it).  --stef
1807   (setq compilation-current-error nil)
1808   (let* ((proc (get-buffer-process (current-buffer)))
1809          (mark (if proc (process-mark proc)))
1810          (pos (or mark (point-max))))
1811     (setq compilation-messages-start
1812           ;; In the future, ignore the text already present in the buffer.
1813           ;; Since many process filter functions insert before markers,
1814           ;; we need to put ours just before the insertion point rather
1815           ;; than at the insertion point.  If that's not possible, then
1816           ;; don't use a marker.  --Stef
1817           (if (> pos (point-min)) (copy-marker (1- pos)) pos))))
1818
1819 (provide 'compile)
1820
1821 ;; arch-tag: 12465727-7382-4f72-b234-79855a00dd8c
1822 ;;; compile.el ends here