code.delx.au - gnu-emacs/blob - lisp/emacs-lisp/cl-extra.el

   1 ;;; cl-extra.el --- Common Lisp features, part 2  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 1993, 2000-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Dave Gillespie <daveg@synaptics.com>
   6 ;; Keywords: extensions
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; These are extensions to Emacs Lisp that provide a degree of
  27 ;; Common Lisp compatibility, beyond what is already built-in
  28 ;; in Emacs Lisp.
  29 ;;
  30 ;; This package was written by Dave Gillespie; it is a complete
  31 ;; rewrite of Cesar Quiroz's original cl.el package of December 1986.
  32 ;;
  33 ;; Bug reports, comments, and suggestions are welcome!
  34
  35 ;; This file contains portions of the Common Lisp extensions
  36 ;; package which are autoloaded since they are relatively obscure.
  37
  38 ;;; Code:
  39
  40 (require 'cl-lib)
  41
  42 ;;; Type coercion.
  43
  44 ;;;###autoload
  45 (defun cl-coerce (x type)
  46   "Coerce OBJECT to type TYPE.
  47 TYPE is a Common Lisp type specifier.
  48 \n(fn OBJECT TYPE)"
  49   (cond ((eq type 'list) (if (listp x) x (append x nil)))
  50         ((eq type 'vector) (if (vectorp x) x (vconcat x)))
  51         ((eq type 'string) (if (stringp x) x (concat x)))
  52         ((eq type 'array) (if (arrayp x) x (vconcat x)))
  53         ((and (eq type 'character) (stringp x) (= (length x) 1)) (aref x 0))
  54         ((and (eq type 'character) (symbolp x))
  55          (cl-coerce (symbol-name x) type))
  56         ((eq type 'float) (float x))
  57         ((cl-typep x type) x)
  58         (t (error "Can't coerce %s to type %s" x type))))
  59
  60
  61 ;;; Predicates.
  62
  63 ;;;###autoload
  64 (defun cl-equalp (x y)
  65   "Return t if two Lisp objects have similar structures and contents.
  66 This is like `equal', except that it accepts numerically equal
  67 numbers of different types (float vs. integer), and also compares
  68 strings case-insensitively."
  69   (cond ((eq x y) t)
  70         ((stringp x)
  71          (and (stringp y) (= (length x) (length y))
  72               (or (string-equal x y)
  73                   (string-equal (downcase x) (downcase y))))) ;Lazy but simple!
  74         ((numberp x)
  75          (and (numberp y) (= x y)))
  76         ((consp x)
  77          (while (and (consp x) (consp y) (cl-equalp (car x) (car y)))
  78            (setq x (cdr x) y (cdr y)))
  79          (and (not (consp x)) (cl-equalp x y)))
  80         ((vectorp x)
  81          (and (vectorp y) (= (length x) (length y))
  82               (let ((i (length x)))
  83                 (while (and (>= (setq i (1- i)) 0)
  84                             (cl-equalp (aref x i) (aref y i))))
  85                 (< i 0))))
  86         (t (equal x y))))
  87
  88
  89 ;;; Control structures.
  90
  91 ;;;###autoload
  92 (defun cl--mapcar-many (cl-func cl-seqs)
  93   (if (cdr (cdr cl-seqs))
  94       (let* ((cl-res nil)
  95              (cl-n (apply 'min (mapcar 'length cl-seqs)))
  96              (cl-i 0)
  97              (cl-args (copy-sequence cl-seqs))
  98              cl-p1 cl-p2)
  99         (setq cl-seqs (copy-sequence cl-seqs))
 100         (while (< cl-i cl-n)
 101           (setq cl-p1 cl-seqs cl-p2 cl-args)
 102           (while cl-p1
 103             (setcar cl-p2
 104                     (if (consp (car cl-p1))
 105                         (prog1 (car (car cl-p1))
 106                           (setcar cl-p1 (cdr (car cl-p1))))
 107                       (aref (car cl-p1) cl-i)))
 108             (setq cl-p1 (cdr cl-p1) cl-p2 (cdr cl-p2)))
 109           (push (apply cl-func cl-args) cl-res)
 110           (setq cl-i (1+ cl-i)))
 111         (nreverse cl-res))
 112     (let ((cl-res nil)
 113           (cl-x (car cl-seqs))
 114           (cl-y (nth 1 cl-seqs)))
 115       (let ((cl-n (min (length cl-x) (length cl-y)))
 116             (cl-i -1))
 117         (while (< (setq cl-i (1+ cl-i)) cl-n)
 118           (push (funcall cl-func
 119                          (if (consp cl-x) (pop cl-x) (aref cl-x cl-i))
 120                          (if (consp cl-y) (pop cl-y) (aref cl-y cl-i)))
 121                 cl-res)))
 122       (nreverse cl-res))))
 123
 124 ;;;###autoload
 125 (defun cl-map (cl-type cl-func cl-seq &rest cl-rest)
 126   "Map a FUNCTION across one or more SEQUENCEs, returning a sequence.
 127 TYPE is the sequence type to return.
 128 \n(fn TYPE FUNCTION SEQUENCE...)"
 129   (let ((cl-res (apply 'cl-mapcar cl-func cl-seq cl-rest)))
 130     (and cl-type (cl-coerce cl-res cl-type))))
 131
 132 ;;;###autoload
 133 (defun cl-maplist (cl-func cl-list &rest cl-rest)
 134   "Map FUNCTION to each sublist of LIST or LISTs.
 135 Like `cl-mapcar', except applies to lists and their cdr's rather than to
 136 the elements themselves.
 137 \n(fn FUNCTION LIST...)"
 138   (if cl-rest
 139       (let ((cl-res nil)
 140             (cl-args (cons cl-list (copy-sequence cl-rest)))
 141             cl-p)
 142         (while (not (memq nil cl-args))
 143           (push (apply cl-func cl-args) cl-res)
 144           (setq cl-p cl-args)
 145           (while cl-p (setcar cl-p (cdr (pop cl-p)) )))
 146         (nreverse cl-res))
 147     (let ((cl-res nil))
 148       (while cl-list
 149         (push (funcall cl-func cl-list) cl-res)
 150         (setq cl-list (cdr cl-list)))
 151       (nreverse cl-res))))
 152
 153 ;;;###autoload
 154 (defun cl-mapc (cl-func cl-seq &rest cl-rest)
 155   "Like `cl-mapcar', but does not accumulate values returned by the function.
 156 \n(fn FUNCTION SEQUENCE...)"
 157   (if cl-rest
 158       (progn (apply 'cl-map nil cl-func cl-seq cl-rest)
 159              cl-seq)
 160     (mapc cl-func cl-seq)))
 161
 162 ;;;###autoload
 163 (defun cl-mapl (cl-func cl-list &rest cl-rest)
 164   "Like `cl-maplist', but does not accumulate values returned by the function.
 165 \n(fn FUNCTION LIST...)"
 166   (if cl-rest
 167       (apply 'cl-maplist cl-func cl-list cl-rest)
 168     (let ((cl-p cl-list))
 169       (while cl-p (funcall cl-func cl-p) (setq cl-p (cdr cl-p)))))
 170   cl-list)
 171
 172 ;;;###autoload
 173 (defun cl-mapcan (cl-func cl-seq &rest cl-rest)
 174   "Like `cl-mapcar', but nconc's together the values returned by the function.
 175 \n(fn FUNCTION SEQUENCE...)"
 176   (apply 'nconc (apply 'cl-mapcar cl-func cl-seq cl-rest)))
 177
 178 ;;;###autoload
 179 (defun cl-mapcon (cl-func cl-list &rest cl-rest)
 180   "Like `cl-maplist', but nconc's together the values returned by the function.
 181 \n(fn FUNCTION LIST...)"
 182   (apply 'nconc (apply 'cl-maplist cl-func cl-list cl-rest)))
 183
 184 ;;;###autoload
 185 (defun cl-some (cl-pred cl-seq &rest cl-rest)
 186   "Return true if PREDICATE is true of any element of SEQ or SEQs.
 187 If so, return the true (non-nil) value returned by PREDICATE.
 188 \n(fn PREDICATE SEQ...)"
 189   (if (or cl-rest (nlistp cl-seq))
 190       (catch 'cl-some
 191         (apply 'cl-map nil
 192                (function (lambda (&rest cl-x)
 193                            (let ((cl-res (apply cl-pred cl-x)))
 194                              (if cl-res (throw 'cl-some cl-res)))))
 195                cl-seq cl-rest) nil)
 196     (let ((cl-x nil))
 197       (while (and cl-seq (not (setq cl-x (funcall cl-pred (pop cl-seq))))))
 198       cl-x)))
 199
 200 ;;;###autoload
 201 (defun cl-every (cl-pred cl-seq &rest cl-rest)
 202   "Return true if PREDICATE is true of every element of SEQ or SEQs.
 203 \n(fn PREDICATE SEQ...)"
 204   (if (or cl-rest (nlistp cl-seq))
 205       (catch 'cl-every
 206         (apply 'cl-map nil
 207                (function (lambda (&rest cl-x)
 208                            (or (apply cl-pred cl-x) (throw 'cl-every nil))))
 209                cl-seq cl-rest) t)
 210     (while (and cl-seq (funcall cl-pred (car cl-seq)))
 211       (setq cl-seq (cdr cl-seq)))
 212     (null cl-seq)))
 213
 214 ;;;###autoload
 215 (defun cl-notany (cl-pred cl-seq &rest cl-rest)
 216   "Return true if PREDICATE is false of every element of SEQ or SEQs.
 217 \n(fn PREDICATE SEQ...)"
 218   (not (apply 'cl-some cl-pred cl-seq cl-rest)))
 219
 220 ;;;###autoload
 221 (defun cl-notevery (cl-pred cl-seq &rest cl-rest)
 222   "Return true if PREDICATE is false of some element of SEQ or SEQs.
 223 \n(fn PREDICATE SEQ...)"
 224   (not (apply 'cl-every cl-pred cl-seq cl-rest)))
 225
 226 ;;;###autoload
 227 (defun cl--map-keymap-recursively (cl-func-rec cl-map &optional cl-base)
 228   (or cl-base
 229       (setq cl-base (copy-sequence [0])))
 230   (map-keymap
 231    (function
 232     (lambda (cl-key cl-bind)
 233       (aset cl-base (1- (length cl-base)) cl-key)
 234       (if (keymapp cl-bind)
 235           (cl--map-keymap-recursively
 236            cl-func-rec cl-bind
 237            (vconcat cl-base (list 0)))
 238         (funcall cl-func-rec cl-base cl-bind))))
 239    cl-map))
 240
 241 ;;;###autoload
 242 (defun cl--map-intervals (cl-func &optional cl-what cl-prop cl-start cl-end)
 243   (or cl-what (setq cl-what (current-buffer)))
 244   (if (bufferp cl-what)
 245       (let (cl-mark cl-mark2 (cl-next t) cl-next2)
 246         (with-current-buffer cl-what
 247           (setq cl-mark (copy-marker (or cl-start (point-min))))
 248           (setq cl-mark2 (and cl-end (copy-marker cl-end))))
 249         (while (and cl-next (or (not cl-mark2) (< cl-mark cl-mark2)))
 250           (setq cl-next (if cl-prop (next-single-property-change
 251                                      cl-mark cl-prop cl-what)
 252                           (next-property-change cl-mark cl-what))
 253                 cl-next2 (or cl-next (with-current-buffer cl-what
 254                                        (point-max))))
 255           (funcall cl-func (prog1 (marker-position cl-mark)
 256                              (set-marker cl-mark cl-next2))
 257                    (if cl-mark2 (min cl-next2 cl-mark2) cl-next2)))
 258         (set-marker cl-mark nil) (if cl-mark2 (set-marker cl-mark2 nil)))
 259     (or cl-start (setq cl-start 0))
 260     (or cl-end (setq cl-end (length cl-what)))
 261     (while (< cl-start cl-end)
 262       (let ((cl-next (or (if cl-prop (next-single-property-change
 263                                       cl-start cl-prop cl-what)
 264                            (next-property-change cl-start cl-what))
 265                          cl-end)))
 266         (funcall cl-func cl-start (min cl-next cl-end))
 267         (setq cl-start cl-next)))))
 268
 269 ;;;###autoload
 270 (defun cl--map-overlays (cl-func &optional cl-buffer cl-start cl-end cl-arg)
 271   (or cl-buffer (setq cl-buffer (current-buffer)))
 272   (let (cl-ovl)
 273     (with-current-buffer cl-buffer
 274       (setq cl-ovl (overlay-lists))
 275       (if cl-start (setq cl-start (copy-marker cl-start)))
 276       (if cl-end (setq cl-end (copy-marker cl-end))))
 277     (setq cl-ovl (nconc (car cl-ovl) (cdr cl-ovl)))
 278     (while (and cl-ovl
 279                 (or (not (overlay-start (car cl-ovl)))
 280                     (and cl-end (>= (overlay-start (car cl-ovl)) cl-end))
 281                     (and cl-start (<= (overlay-end (car cl-ovl)) cl-start))
 282                     (not (funcall cl-func (car cl-ovl) cl-arg))))
 283       (setq cl-ovl (cdr cl-ovl)))
 284     (if cl-start (set-marker cl-start nil))
 285     (if cl-end (set-marker cl-end nil))))
 286
 287 ;;; Support for `setf'.
 288 ;;;###autoload
 289 (defun cl--set-frame-visible-p (frame val)
 290   (cond ((null val) (make-frame-invisible frame))
 291         ((eq val 'icon) (iconify-frame frame))
 292         (t (make-frame-visible frame)))
 293   val)
 294
 295
 296 ;;; Numbers.
 297
 298 ;;;###autoload
 299 (defun cl-gcd (&rest args)
 300   "Return the greatest common divisor of the arguments."
 301   (let ((a (abs (or (pop args) 0))))
 302     (while args
 303       (let ((b (abs (pop args))))
 304         (while (> b 0) (setq b (% a (setq a b))))))
 305     a))
 306
 307 ;;;###autoload
 308 (defun cl-lcm (&rest args)
 309   "Return the least common multiple of the arguments."
 310   (if (memq 0 args)
 311       0
 312     (let ((a (abs (or (pop args) 1))))
 313       (while args
 314         (let ((b (abs (pop args))))
 315           (setq a (* (/ a (cl-gcd a b)) b))))
 316       a)))
 317
 318 ;;;###autoload
 319 (defun cl-isqrt (x)
 320   "Return the integer square root of the argument."
 321   (if (and (integerp x) (> x 0))
 322       (let ((g (cond ((<= x 100) 10) ((<= x 10000) 100)
 323                      ((<= x 1000000) 1000) (t x)))
 324             g2)
 325         (while (< (setq g2 (/ (+ g (/ x g)) 2)) g)
 326           (setq g g2))
 327         g)
 328     (if (eq x 0) 0 (signal 'arith-error nil))))
 329
 330 ;;;###autoload
 331 (defun cl-floor (x &optional y)
 332   "Return a list of the floor of X and the fractional part of X.
 333 With two arguments, return floor and remainder of their quotient."
 334   (let ((q (floor x y)))
 335     (list q (- x (if y (* y q) q)))))
 336
 337 ;;;###autoload
 338 (defun cl-ceiling (x &optional y)
 339   "Return a list of the ceiling of X and the fractional part of X.
 340 With two arguments, return ceiling and remainder of their quotient."
 341   (let ((res (cl-floor x y)))
 342     (if (= (car (cdr res)) 0) res
 343       (list (1+ (car res)) (- (car (cdr res)) (or y 1))))))
 344
 345 ;;;###autoload
 346 (defun cl-truncate (x &optional y)
 347   "Return a list of the integer part of X and the fractional part of X.
 348 With two arguments, return truncation and remainder of their quotient."
 349   (if (eq (>= x 0) (or (null y) (>= y 0)))
 350       (cl-floor x y) (cl-ceiling x y)))
 351
 352 ;;;###autoload
 353 (defun cl-round (x &optional y)
 354   "Return a list of X rounded to the nearest integer and the remainder.
 355 With two arguments, return rounding and remainder of their quotient."
 356   (if y
 357       (if (and (integerp x) (integerp y))
 358           (let* ((hy (/ y 2))
 359                  (res (cl-floor (+ x hy) y)))
 360             (if (and (= (car (cdr res)) 0)
 361                      (= (+ hy hy) y)
 362                      (/= (% (car res) 2) 0))
 363                 (list (1- (car res)) hy)
 364               (list (car res) (- (car (cdr res)) hy))))
 365         (let ((q (round (/ x y))))
 366           (list q (- x (* q y)))))
 367     (if (integerp x) (list x 0)
 368       (let ((q (round x)))
 369         (list q (- x q))))))
 370
 371 ;;;###autoload
 372 (defun cl-mod (x y)
 373   "The remainder of X divided by Y, with the same sign as Y."
 374   (nth 1 (cl-floor x y)))
 375
 376 ;;;###autoload
 377 (defun cl-rem (x y)
 378   "The remainder of X divided by Y, with the same sign as X."
 379   (nth 1 (cl-truncate x y)))
 380
 381 ;;;###autoload
 382 (defun cl-signum (x)
 383   "Return 1 if X is positive, -1 if negative, 0 if zero."
 384   (cond ((> x 0) 1) ((< x 0) -1) (t 0)))
 385
 386 ;;;###autoload
 387 (cl-defun cl-parse-integer (string &key start end radix junk-allowed)
 388   "Parse integer from the substring of STRING from START to END.
 389 STRING may be surrounded by whitespace chars (chars with syntax ` ').
 390 Other non-digit chars are considered junk.
 391 RADIX is an integer between 2 and 36, the default is 10.  Signal
 392 an error if the substring between START and END cannot be parsed
 393 as an integer unless JUNK-ALLOWED is non-nil."
 394   (cl-check-type string string)
 395   (let* ((start (or start 0))
 396          (len   (length string))
 397          (end   (or end len))
 398          (radix (or radix 10)))
 399     (or (<= start end len)
 400         (error "Bad interval: [%d, %d)" start end))
 401     (cl-flet ((skip-whitespace ()
 402                 (while (and (< start end)
 403                             (= 32 (char-syntax (aref string start))))
 404                   (setq start (1+ start)))))
 405       (skip-whitespace)
 406       (let ((sign (cl-case (and (< start end) (aref string start))
 407                     (?+ (cl-incf start) +1)
 408                     (?- (cl-incf start) -1)
 409                     (t  +1)))
 410             digit sum)
 411         (while (and (< start end)
 412                     (setq digit (cl-digit-char-p (aref string start) radix)))
 413           (setq sum (+ (* (or sum 0) radix) digit)
 414                 start (1+ start)))
 415         (skip-whitespace)
 416         (cond ((and junk-allowed (null sum)) sum)
 417               (junk-allowed (* sign sum))
 418               ((or (/= start end) (null sum))
 419                (error "Not an integer string: `%s'" string))
 420               (t (* sign sum)))))))
 421
 422
 423 ;; Random numbers.
 424
 425 ;;;###autoload
 426 (defun cl-random (lim &optional state)
 427   "Return a random nonnegative number less than LIM, an integer or float.
 428 Optional second arg STATE is a random-state object."
 429   (or state (setq state cl--random-state))
 430   ;; Inspired by "ran3" from Numerical Recipes.  Additive congruential method.
 431   (let ((vec (aref state 3)))
 432     (if (integerp vec)
 433         (let ((i 0) (j (- 1357335 (% (abs vec) 1357333))) (k 1))
 434           (aset state 3 (setq vec (make-vector 55 nil)))
 435           (aset vec 0 j)
 436           (while (> (setq i (% (+ i 21) 55)) 0)
 437             (aset vec i (setq j (prog1 k (setq k (- j k))))))
 438           (while (< (setq i (1+ i)) 200) (cl-random 2 state))))
 439     (let* ((i (aset state 1 (% (1+ (aref state 1)) 55)))
 440            (j (aset state 2 (% (1+ (aref state 2)) 55)))
 441            (n (logand 8388607 (aset vec i (- (aref vec i) (aref vec j))))))
 442       (if (integerp lim)
 443           (if (<= lim 512) (% n lim)
 444             (if (> lim 8388607) (setq n (+ (lsh n 9) (cl-random 512 state))))
 445             (let ((mask 1023))
 446               (while (< mask (1- lim)) (setq mask (1+ (+ mask mask))))
 447               (if (< (setq n (logand n mask)) lim) n (cl-random lim state))))
 448         (* (/ n '8388608e0) lim)))))
 449
 450 ;;;###autoload
 451 (defun cl-make-random-state (&optional state)
 452   "Return a copy of random-state STATE, or of the internal state if omitted.
 453 If STATE is t, return a new state object seeded from the time of day."
 454   (cond ((null state) (cl-make-random-state cl--random-state))
 455         ((vectorp state) (copy-tree state t))
 456         ((integerp state) (vector 'cl--random-state-tag -1 30 state))
 457         (t (cl-make-random-state (cl--random-time)))))
 458
 459 ;;;###autoload
 460 (defun cl-random-state-p (object)
 461   "Return t if OBJECT is a random-state object."
 462   (and (vectorp object) (= (length object) 4)
 463        (eq (aref object 0) 'cl--random-state-tag)))
 464
 465
 466 ;; Implementation limits.
 467
 468 (defun cl--finite-do (func a b)
 469   (condition-case _
 470       (let ((res (funcall func a b)))   ; check for IEEE infinity
 471         (and (numberp res) (/= res (/ res 2)) res))
 472     (arith-error nil)))
 473
 474 ;;;###autoload
 475 (defun cl-float-limits ()
 476   "Initialize the Common Lisp floating-point parameters.
 477 This sets the values of: `cl-most-positive-float', `cl-most-negative-float',
 478 `cl-least-positive-float', `cl-least-negative-float', `cl-float-epsilon',
 479 `cl-float-negative-epsilon', `cl-least-positive-normalized-float', and
 480 `cl-least-negative-normalized-float'."
 481   (or cl-most-positive-float (not (numberp '2e1))
 482       (let ((x '2e0) y z)
 483         ;; Find maximum exponent (first two loops are optimizations)
 484         (while (cl--finite-do '* x x) (setq x (* x x)))
 485         (while (cl--finite-do '* x (/ x 2)) (setq x (* x (/ x 2))))
 486         (while (cl--finite-do '+ x x) (setq x (+ x x)))
 487         (setq z x y (/ x 2))
 488         ;; Now cl-fill in 1's in the mantissa.
 489         (while (and (cl--finite-do '+ x y) (/= (+ x y) x))
 490           (setq x (+ x y) y (/ y 2)))
 491         (setq cl-most-positive-float x
 492               cl-most-negative-float (- x))
 493         ;; Divide down until mantissa starts rounding.
 494         (setq x (/ x z) y (/ 16 z) x (* x y))
 495         (while (condition-case _ (and (= x (* (/ x 2) 2)) (> (/ y 2) 0))
 496                  (arith-error nil))
 497           (setq x (/ x 2) y (/ y 2)))
 498         (setq cl-least-positive-normalized-float y
 499               cl-least-negative-normalized-float (- y))
 500         ;; Divide down until value underflows to zero.
 501         (setq x (/ 1 z) y x)
 502         (while (condition-case _ (> (/ x 2) 0) (arith-error nil))
 503           (setq x (/ x 2)))
 504         (setq cl-least-positive-float x
 505               cl-least-negative-float (- x))
 506         (setq x '1e0)
 507         (while (/= (+ '1e0 x) '1e0) (setq x (/ x 2)))
 508         (setq cl-float-epsilon (* x 2))
 509         (setq x '1e0)
 510         (while (/= (- '1e0 x) '1e0) (setq x (/ x 2)))
 511         (setq cl-float-negative-epsilon (* x 2))))
 512   nil)
 513
 514
 515 ;;; Sequence functions.
 516
 517 ;;;###autoload
 518 (defun cl-subseq (seq start &optional end)
 519   "Return the subsequence of SEQ from START to END.
 520 If END is omitted, it defaults to the length of the sequence.
 521 If START or END is negative, it counts from the end."
 522   (declare (gv-setter
 523             (lambda (new)
 524               `(progn (cl-replace ,seq ,new :start1 ,start :end1 ,end)
 525                       ,new))))
 526   (if (stringp seq) (substring seq start end)
 527     (let (len)
 528       (and end (< end 0) (setq end (+ end (setq len (length seq)))))
 529       (if (< start 0) (setq start (+ start (or len (setq len (length seq))))))
 530       (cond ((listp seq)
 531              (if (> start 0) (setq seq (nthcdr start seq)))
 532              (if end
 533                  (let ((res nil))
 534                    (while (>= (setq end (1- end)) start)
 535                      (push (pop seq) res))
 536                    (nreverse res))
 537                (copy-sequence seq)))
 538             (t
 539              (or end (setq end (or len (length seq))))
 540              (let ((res (make-vector (max (- end start) 0) nil))
 541                    (i 0))
 542                (while (< start end)
 543                  (aset res i (aref seq start))
 544                  (setq i (1+ i) start (1+ start)))
 545                res))))))
 546
 547 ;;;###autoload
 548 (defun cl-concatenate (type &rest seqs)
 549   "Concatenate, into a sequence of type TYPE, the argument SEQUENCEs.
 550 \n(fn TYPE SEQUENCE...)"
 551   (cond ((eq type 'vector) (apply 'vconcat seqs))
 552         ((eq type 'string) (apply 'concat seqs))
 553         ((eq type 'list) (apply 'append (append seqs '(nil))))
 554         (t (error "Not a sequence type name: %s" type))))
 555
 556
 557 ;;; List functions.
 558
 559 ;;;###autoload
 560 (defun cl-revappend (x y)
 561   "Equivalent to (append (reverse X) Y)."
 562   (nconc (reverse x) y))
 563
 564 ;;;###autoload
 565 (defun cl-nreconc (x y)
 566   "Equivalent to (nconc (nreverse X) Y)."
 567   (nconc (nreverse x) y))
 568
 569 ;;;###autoload
 570 (defun cl-list-length (x)
 571   "Return the length of list X.  Return nil if list is circular."
 572   (let ((n 0) (fast x) (slow x))
 573     (while (and (cdr fast) (not (and (eq fast slow) (> n 0))))
 574       (setq n (+ n 2) fast (cdr (cdr fast)) slow (cdr slow)))
 575     (if fast (if (cdr fast) nil (1+ n)) n)))
 576
 577 ;;;###autoload
 578 (defun cl-tailp (sublist list)
 579   "Return true if SUBLIST is a tail of LIST."
 580   (while (and (consp list) (not (eq sublist list)))
 581     (setq list (cdr list)))
 582   (if (numberp sublist) (equal sublist list) (eq sublist list)))
 583
 584 ;;; Property lists.
 585
 586 ;;;###autoload
 587 (defun cl-get (sym tag &optional def)
 588   "Return the value of SYMBOL's PROPNAME property, or DEFAULT if none.
 589 \n(fn SYMBOL PROPNAME &optional DEFAULT)"
 590   (declare (compiler-macro cl--compiler-macro-get)
 591            (gv-setter (lambda (store) (ignore def) `(put ,sym ,tag ,store))))
 592   (or (get sym tag)
 593       (and def
 594            ;; Make sure `def' is really absent as opposed to set to nil.
 595            (let ((plist (symbol-plist sym)))
 596              (while (and plist (not (eq (car plist) tag)))
 597                (setq plist (cdr (cdr plist))))
 598              (if plist (car (cdr plist)) def)))))
 599 (autoload 'cl--compiler-macro-get "cl-macs")
 600
 601 ;;;###autoload
 602 (defun cl-getf (plist tag &optional def)
 603   "Search PROPLIST for property PROPNAME; return its value or DEFAULT.
 604 PROPLIST is a list of the sort returned by `symbol-plist'.
 605 \n(fn PROPLIST PROPNAME &optional DEFAULT)"
 606   (declare (gv-expander
 607             (lambda (do)
 608               (gv-letplace (getter setter) plist
 609                 (macroexp-let2* nil ((k tag) (d def))
 610                   (funcall do `(cl-getf ,getter ,k ,d)
 611                            (lambda (v)
 612                              (macroexp-let2 nil val v
 613                                `(progn
 614                                   ,(funcall setter
 615                                             `(cl--set-getf ,getter ,k ,val))
 616                                   ,val)))))))))
 617   (setplist '--cl-getf-symbol-- plist)
 618   (or (get '--cl-getf-symbol-- tag)
 619       ;; Originally we called cl-get here,
 620       ;; but that fails, because cl-get has a compiler macro
 621       ;; definition that uses getf!
 622       (when def
 623         ;; Make sure `def' is really absent as opposed to set to nil.
 624         (while (and plist (not (eq (car plist) tag)))
 625           (setq plist (cdr (cdr plist))))
 626         (if plist (car (cdr plist)) def))))
 627
 628 ;;;###autoload
 629 (defun cl--set-getf (plist tag val)
 630   (let ((p plist))
 631     (while (and p (not (eq (car p) tag))) (setq p (cdr (cdr p))))
 632     (if p (progn (setcar (cdr p) val) plist) (cl-list* tag val plist))))
 633
 634 ;;;###autoload
 635 (defun cl--do-remf (plist tag)
 636   (let ((p (cdr plist)))
 637     (while (and (cdr p) (not (eq (car (cdr p)) tag))) (setq p (cdr (cdr p))))
 638     (and (cdr p) (progn (setcdr p (cdr (cdr (cdr p)))) t))))
 639
 640 ;;;###autoload
 641 (defun cl-remprop (sym tag)
 642   "Remove from SYMBOL's plist the property PROPNAME and its value.
 643 \n(fn SYMBOL PROPNAME)"
 644   (let ((plist (symbol-plist sym)))
 645     (if (and plist (eq tag (car plist)))
 646         (progn (setplist sym (cdr (cdr plist))) t)
 647       (cl--do-remf plist tag))))
 648
 649 ;;; Streams.
 650
 651 ;;;###autoload
 652 (defun cl-fresh-line (&optional stream)
 653   "Output a newline unless already at the beginning of a line."
 654   (terpri stream 'ensure))
 655
 656 ;;; Some debugging aids.
 657
 658 (defun cl-prettyprint (form)
 659   "Insert a pretty-printed rendition of a Lisp FORM in current buffer."
 660   (let ((pt (point)) last)
 661     (insert "\n" (prin1-to-string form) "\n")
 662     (setq last (point))
 663     (goto-char (1+ pt))
 664     (while (search-forward "(quote " last t)
 665       (delete-char -7)
 666       (insert "'")
 667       (forward-sexp)
 668       (delete-char 1))
 669     (goto-char (1+ pt))
 670     (cl--do-prettyprint)))
 671
 672 (defun cl--do-prettyprint ()
 673   (skip-chars-forward " ")
 674   (if (looking-at "(")
 675       (let ((skip (or (looking-at "((") (looking-at "(prog")
 676                       (looking-at "(unwind-protect ")
 677                       (looking-at "(function (")
 678                       (looking-at "(cl--block-wrapper ")))
 679             (two (or (looking-at "(defun ") (looking-at "(defmacro ")))
 680             (let (or (looking-at "(let\\*? ") (looking-at "(while ")))
 681             (set (looking-at "(p?set[qf] ")))
 682         (if (or skip let
 683                 (progn
 684                   (forward-sexp)
 685                   (and (>= (current-column) 78) (progn (backward-sexp) t))))
 686             (let ((nl t))
 687               (forward-char 1)
 688               (cl--do-prettyprint)
 689               (or skip (looking-at ")") (cl--do-prettyprint))
 690               (or (not two) (looking-at ")") (cl--do-prettyprint))
 691               (while (not (looking-at ")"))
 692                 (if set (setq nl (not nl)))
 693                 (if nl (insert "\n"))
 694                 (lisp-indent-line)
 695                 (cl--do-prettyprint))
 696               (forward-char 1))))
 697     (forward-sexp)))
 698
 699 ;;;###autoload
 700 (defun cl-prettyexpand (form &optional full)
 701   "Expand macros in FORM and insert the pretty-printed result.
 702 Optional argument FULL non-nil means to expand all macros,
 703 including `cl-block' and `cl-eval-when'."
 704   (message "Expanding...")
 705   (let ((cl--compiling-file full)
 706         (byte-compile-macro-environment nil))
 707     (setq form (macroexpand-all form
 708                                 (and (not full) '((cl-block) (cl-eval-when)))))
 709     (message "Formatting...")
 710     (prog1 (cl-prettyprint form)
 711       (message ""))))
 712
 713
 714
 715 (run-hooks 'cl-extra-load-hook)
 716
 717 ;; Local variables:
 718 ;; byte-compile-dynamic: t
 719 ;; generated-autoload-file: "cl-loaddefs.el"
 720 ;; End:
 721
 722 (provide 'cl-extra)
 723 ;;; cl-extra.el ends here