code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the 'configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2016 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 25.1.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in "$@" CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140
 141 case $host in
 142  *-mingw*)
 143
 144   if test -z "$host_alias"; then
 145
 146       # No --host argument was given to 'configure'; therefore $host
 147       # was set to a default value based on the build platform.  But
 148       # this default value may be wrong if we are building from a
 149       # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
 150       # Therefore, we'll try to get the right host platform from the
 151       # compiler's target.
 152
 153       AC_MSG_CHECKING([the compiler's target])
 154       if test -z "$CC"; then
 155           cc=gcc
 156       else
 157           cc=$CC
 158       fi
 159       cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
 160       case "$cc_target" in
 161           *-*) host=$cc_target
 162               ;;
 163           "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
 164 Please explicitly provide --host.])
 165               ;;
 166           *) AC_MSG_WARN([Compiler reported non-standard target.
 167 Defaulting to $host.])
 168               ;;
 169       esac
 170       AC_MSG_RESULT([$host])
 171   fi
 172
 173   . $srcdir/nt/mingw-cfg.site
 174
 175   case $srcdir in
 176     /* | ?:*)
 177       # srcdir is an absolute path.  In this case, force the format
 178       # "/c/foo/bar", to simplify later conversions to native Windows
 179       # format ("c:/foo/bar").
 180       srcdir=`cd "${srcdir}" && pwd -W`
 181       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
 182       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
 183       ;;
 184   esac;;
 185 esac
 186
 187 canonical=$host
 188 configuration=${host_alias-${build_alias-$host}}
 189
 190 dnl Support for --program-prefix, --program-suffix and
 191 dnl --program-transform-name options
 192 AC_ARG_PROGRAM
 193
 194 dnl It is important that variables on the RHS not be expanded here,
 195 dnl hence the single quotes.  This is per the GNU coding standards, see
 196 dnl (autoconf) Installation Directory Variables
 197 dnl See also epaths.h below.
 198 lispdir='${datadir}/emacs/${version}/lisp'
 199 standardlisppath='${lispdir}'
 200 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 201 '${datadir}/emacs/site-lisp'
 202 lisppath='${locallisppath}:${standardlisppath}'
 203 etcdir='${datadir}/emacs/${version}/etc'
 204 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 205 etcdocdir='${datadir}/emacs/${version}/etc'
 206 gamedir='${localstatedir}/games/emacs'
 207
 208 dnl Special option to disable the most of other options.
 209 AC_ARG_WITH(all,
 210 [AS_HELP_STRING([--without-all],
 211                 [omit almost all features and build
 212                 small executable with minimal dependencies])],
 213   [with_features=$withval],
 214   [with_features=yes])
 215
 216 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 217 dnl Create a new --with option that defaults to being disabled.
 218 dnl NAME is the base name of the option.  The shell variable with_NAME
 219 dnl   will be set to either the user's value (if the option is
 220 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 221 dnl   option is not specified).  Note that the shell variable name is
 222 dnl   constructed as autoconf does, by replacing non-alphanumeric
 223 dnl   characters with "_".
 224 dnl HELP-STRING is the help text for the option.
 225 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 226   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 227     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 228 ])dnl
 229
 230 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 231 dnl Create a new --with option that defaults to $with_features.
 232 dnl NAME is the base name of the option.  The shell variable with_NAME
 233 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 234 dnl   'yes' (if the option is not specified).  Note that the shell
 235 dnl   variable name is constructed as autoconf does, by replacing
 236 dnl   non-alphanumeric characters with "_".
 237 dnl HELP-STRING is the help text for the option.
 238 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 239   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 240    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 241 ])dnl
 242
 243 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 244 if test "$with_pop" = yes; then
 245    AC_DEFINE(MAIL_USE_POP)
 246 fi
 247 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 248
 249 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 250 if test "$with_kerberos" != no; then
 251    AC_DEFINE(KERBEROS)
 252 fi
 253 AH_TEMPLATE(KERBEROS,
 254             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 255
 256 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 257 if test "${with_kerberos5}" != no; then
 258   if test "${with_kerberos}" = no; then
 259     with_kerberos=yes
 260     AC_DEFINE(KERBEROS)
 261   fi
 262   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 263 fi
 264
 265 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 266 dnl FIXME hesiod support may not be present, so it seems like an error
 267 dnl to define, or at least use, this unconditionally.
 268 if test "$with_hesiod" != no; then
 269   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 270 fi
 271
 272 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 273 if test "$with_mail_unlink" != no; then
 274    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 275 fi
 276
 277 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 278     [string giving default POP mail host])],
 279     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 280
 281 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 282   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 283 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
 284   [ case "${withval}" in
 285       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 286       *) AC_MSG_ERROR(['--with-sound=$withval' is invalid;
 287 this option's value should be 'yes', 'no', 'alsa', 'oss', or 'bsd-ossaudio'.])
 288       ;;
 289     esac
 290     with_sound=$val
 291   ],
 292   [with_sound=$with_features])
 293
 294 dnl FIXME currently it is not the last.
 295 dnl This should be the last --with option, because --with-x is
 296 dnl added later on when we find the file name of X, and it's best to
 297 dnl keep them together visually.
 298 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 299  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 300 [         case "${withval}" in
 301             y | ye | yes )      val=gtk ;;
 302             n | no )            val=no  ;;
 303             l | lu | luc | luci | lucid )       val=lucid ;;
 304             a | at | ath | athe | athen | athena )      val=athena ;;
 305             m | mo | mot | moti | motif )       val=motif ;;
 306             g | gt | gtk  )     val=gtk ;;
 307             gtk2  )     val=gtk2 ;;
 308             gtk3  )     val=gtk3 ;;
 309             * )
 310 AC_MSG_ERROR(['--with-x-toolkit=$withval' is invalid;
 311 this option's value should be 'yes', 'no', 'lucid', 'athena', 'motif', 'gtk',
 312 'gtk2' or 'gtk3'.  'yes' and 'gtk' are synonyms.
 313 'athena' and 'lucid' are synonyms.])
 314             ;;
 315           esac
 316           with_x_toolkit=$val
 317 ])
 318
 319 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit); allows buffer and string size up to 2GB on 32-bit hosts, at the cost of 10% to 30% slowdown of Lisp interpreter and larger memory footprint])
 320 if test "$with_wide_int" = yes; then
 321   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 322 fi
 323
 324 dnl _ON results in a '--without' option in the --help output, so
 325 dnl the help text should refer to "don't compile", etc.
 326 with_xpm_set=${with_xpm+set}
 327 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 328 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 329 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 330 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 331 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 332 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 333 OPTION_DEFAULT_ON([libsystemd],[don't compile with libsystemd support])
 334 OPTION_DEFAULT_OFF([cairo],[compile with Cairo drawing (experimental)])
 335 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 336 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 337
 338 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 339 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 340 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 341
 342 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 343 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 344 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 345 AC_ARG_WITH([ns],[AS_HELP_STRING([--with-ns],
 346 [use Nextstep (OS X Cocoa or GNUstep) windowing system.
 347 On by default on Mac OS X.])],[],[with_ns=maybe])
 348 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 349
 350 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 351 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 352 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 353 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 354 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 355 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 356 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 357 OPTION_DEFAULT_OFF([modules],[compile with dynamic modules support])
 358
 359 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 360  [use a file notification library (LIB one of: yes, inotify, kqueue, gfile, w32, no)])],
 361  [ case "${withval}" in
 362     y | ye | yes )      val=yes ;;
 363     n | no )            val=no  ;;
 364     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 365     k | kq | kqu | kque | kqueu | kqueue )      val=kqueue ;;
 366     g | gf | gfi | gfil | gfile )       val=gfile ;;
 367     w | w3 | w32 )      val=w32 ;;
 368     * ) AC_MSG_ERROR(['--with-file-notification=$withval' is invalid;
 369 this option's value should be 'yes', 'no', 'inotify', 'kqueue', 'gfile' or 'w32'.
 370 'yes' is a synonym for 'w32' on MS-Windows, for 'no' on Nextstep,
 371 otherwise for the first of 'inotify', 'kqueue' or 'gfile' that is usable.])
 372     ;;
 373    esac
 374    with_file_notification=$val
 375  ],
 376  [with_file_notification=$with_features])
 377
 378 OPTION_DEFAULT_OFF([xwidgets],
 379   [enable use of some gtk widgets in Emacs buffers (requires gtk3)])
 380
 381 ## For the times when you want to build Emacs but don't have
 382 ## a suitable makeinfo, and can live without the manuals.
 383 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 384 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 385
 386 ## This might be a 'configure' arg.
 387 AC_SUBST([ACLOCAL_PATH])
 388
 389 ## Makefile.in needs the cache file name.
 390 AC_SUBST(cache_file)
 391
 392 ## This is an option because I do not know if all info/man support
 393 ## compressed files, nor how to test if they do so.
 394 OPTION_DEFAULT_ON([compress-install],
 395   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 396 make GZIP_PROG= install])
 397
 398 AC_ARG_WITH(gameuser,dnl
 399 [AS_HELP_STRING([--with-gameuser=USER_OR_GROUP],
 400                 [user for shared game score files.
 401                 An argument prefixed by ':' specifies a group instead.])])
 402 gameuser=
 403 gamegroup=
 404 # We don't test if we can actually chown/chgrp here, because configure
 405 # may run without root privileges.  lib-src/Makefile.in will handle
 406 # any errors due to missing user/group gracefully.
 407 case ${with_gameuser} in
 408   no) ;;
 409   "" | yes) gamegroup=games ;;
 410   :*) gamegroup=${with_gameuser#:} ;;
 411   *) gameuser=${with_gameuser} ;;
 412 esac
 413
 414 AC_ARG_WITH([gnustep-conf],dnl
 415 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 416    [name of GNUstep configuration file to use on systems where the command
 417     'gnustep-config' does not work; default $GNUSTEP_CONFIG_FILE, or
 418     /etc/GNUstep/GNUstep.conf])])
 419 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 420   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 421 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 422      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 423
 424 AC_ARG_ENABLE(ns-self-contained,
 425 [AS_HELP_STRING([--disable-ns-self-contained],
 426                 [disable self contained build under NeXTstep])],
 427    EN_NS_SELF_CONTAINED=$enableval,
 428    EN_NS_SELF_CONTAINED=yes)
 429
 430 locallisppathset=no
 431 AC_ARG_ENABLE(locallisppath,
 432 [AS_HELP_STRING([--enable-locallisppath=PATH],
 433                 [directories Emacs should search for lisp files specific
 434                  to this site])],
 435 if test "${enableval}" = "no"; then
 436   locallisppath=
 437 elif test "${enableval}" != "yes"; then
 438   locallisppath=${enableval} locallisppathset=yes
 439 fi)
 440
 441 AC_ARG_ENABLE(checking,
 442 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 443                 [enable expensive run-time checks.  With LIST,
 444                  enable only specific categories of checks.
 445                  Categories are: all,yes,no.
 446                  Flags are: stringbytes, stringoverrun, stringfreelist,
 447                  xmallocoverrun, conslist, glyphs])],
 448 [ac_checking_flags="${enableval}"],[])
 449 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 450 for check in $ac_checking_flags
 451 do
 452         case $check in
 453         # these set all the flags to specific states
 454         yes)            ac_enable_checking=1 ;;
 455         no)             ac_enable_checking= ;
 456                         ac_gc_check_stringbytes= ;
 457                         ac_gc_check_string_overrun= ;
 458                         ac_gc_check_string_free_list= ;
 459                         ac_xmalloc_overrun= ;
 460                         ac_gc_check_cons_list= ;
 461                         ac_glyphs_debug= ;;
 462         all)            ac_enable_checking=1 ;
 463                         ac_gc_check_stringbytes=1 ;
 464                         ac_gc_check_string_overrun=1 ;
 465                         ac_gc_check_string_free_list=1 ;
 466                         ac_xmalloc_overrun=1 ;
 467                         ac_gc_check_cons_list=1 ;
 468                         ac_glyphs_debug=1 ;;
 469         # these enable particular checks
 470         stringbytes)    ac_gc_check_stringbytes=1 ;;
 471         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 472         stringfreelist) ac_gc_check_string_free_list=1 ;;
 473         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 474         conslist)       ac_gc_check_cons_list=1 ;;
 475         glyphs)         ac_glyphs_debug=1 ;;
 476         *)      AC_MSG_ERROR(unknown check category $check) ;;
 477         esac
 478 done
 479 IFS="$ac_save_IFS"
 480
 481 if test x$ac_enable_checking != x ; then
 482   AC_DEFINE(ENABLE_CHECKING, 1,
 483 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 484 fi
 485 if test x$ac_gc_check_stringbytes != x ; then
 486   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 487 [Define this temporarily to hunt a bug.  If defined, the size of
 488    strings is redundantly recorded in sdata structures so that it can
 489    be compared to the sizes recorded in Lisp strings.])
 490 fi
 491 if test x$ac_gc_check_string_overrun != x ; then
 492   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 493 [Define this to check for short string overrun.])
 494 fi
 495 if test x$ac_gc_check_string_free_list != x ; then
 496   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 497 [Define this to check the string free list.])
 498 fi
 499 if test x$ac_xmalloc_overrun != x ; then
 500   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 501 [Define this to check for malloc buffer overrun.])
 502 fi
 503 if test x$ac_gc_check_cons_list != x ; then
 504   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 505 [Define this to check for errors in cons list.])
 506 fi
 507 if test x$ac_glyphs_debug != x ; then
 508   AC_DEFINE(GLYPH_DEBUG, 1,
 509 [Define this to enable glyphs debugging code.])
 510 fi
 511
 512 AC_ARG_ENABLE(check-lisp-object-type,
 513 [AS_HELP_STRING([--enable-check-lisp-object-type],
 514                 [enable compile time checks for the Lisp_Object data type.
 515                 This is useful for development for catching certain types of bugs.])],
 516 if test "${enableval}" != "no"; then
 517    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 518    [Define this to enable compile time checks for the Lisp_Object data type.])
 519 fi)
 520
 521
 522 dnl The name of this option is unfortunate.  It predates, and has no
 523 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 524 dnl Actually, it stops it working.
 525 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 526 AC_ARG_ENABLE(profiling,
 527 [AS_HELP_STRING([--enable-profiling],
 528                 [build emacs with low-level, gprof profiling support.
 529                 Mainly useful for debugging Emacs itself.  May not work on
 530                 all platforms.  Stops profiler.el working.])],
 531 [ac_enable_profiling="${enableval}"],[])
 532 if test x$ac_enable_profiling != x ; then
 533    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 534 else
 535    PROFILING_CFLAGS=
 536 fi
 537 AC_SUBST(PROFILING_CFLAGS)
 538
 539 AC_ARG_ENABLE(autodepend,
 540 [AS_HELP_STRING([--enable-autodepend],
 541                 [automatically generate dependencies to .h-files.
 542                  Requires gcc, enabled if found.])],
 543 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 544
 545 AC_ARG_ENABLE(gtk-deprecation-warnings,
 546 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 547                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 548 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 549
 550 BUILD_DETAILS=
 551 AC_ARG_ENABLE([build-details],
 552   [AS_HELP_STRING([--disable-build-details],
 553                   [Make the build more deterministic by omitting host
 554                    names, time stamps, etc. from the output.])],
 555   [test "$enableval" = no && BUILD_DETAILS=--no-build-details])
 556 AC_SUBST([BUILD_DETAILS])
 557
 558 dnl This used to use changequote, but, apart from 'changequote is evil'
 559 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 560 dnl the great gob of text.  Thus it's not processed for possible expansion.
 561 dnl Just make sure the brackets remain balanced.
 562 dnl
 563 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 564 dnl indicated by comments.
 565 dnl quotation begins
 566 [
 567
 568 ### If you add support for a new configuration, add code to this
 569 ### switch statement to recognize your configuration name and select
 570 ### the appropriate opsys.
 571
 572 ### As far as handling version numbers on operating systems is
 573 ### concerned, make sure things will fail in a fixable way.  If
 574 ### /etc/MACHINES doesn't say anything about version numbers, be
 575 ### prepared to handle anything reasonably.  If version numbers
 576 ### matter, be sure /etc/MACHINES says something about it.
 577
 578 opsys='' unported=no
 579 case "${canonical}" in
 580
 581   ## GNU/Linux and similar ports
 582   *-*-linux* )
 583     opsys=gnu-linux
 584   ;;
 585
 586   ## FreeBSD ports
 587   *-*-freebsd* )
 588     opsys=freebsd
 589   ;;
 590
 591   ## DragonFly ports
 592   *-*-dragonfly* )
 593     opsys=dragonfly
 594   ;;
 595
 596   ## FreeBSD kernel + glibc based userland
 597   *-*-kfreebsd*gnu* )
 598     opsys=gnu-kfreebsd
 599   ;;
 600
 601   ## NetBSD ports
 602   *-*-netbsd* )
 603     opsys=netbsd
 604   ;;
 605
 606   ## OpenBSD ports
 607   *-*-openbsd* | *-*-mirbsd* )
 608     opsys=openbsd
 609   ;;
 610
 611   ## Apple Darwin / Mac OS X
 612   *-apple-darwin* )
 613     case "${canonical}" in
 614       *-apple-darwin[0-9].*) unported=yes ;;
 615       i[3456]86-* | x86_64-* )  ;;
 616       * )            unported=yes ;;
 617     esac
 618     opsys=darwin
 619     ## FIXME: Find a way to use Fink if available (Bug#11507).
 620   ;;
 621
 622   ## Chromium Native Client
 623   *-nacl )
 624     opsys=nacl
 625   ;;
 626
 627   ## Cygwin ports
 628   *-*-cygwin )
 629     opsys=cygwin
 630   ;;
 631
 632   ## HP 9000 series 700 and 800, running HP/UX
 633   hppa*-hp-hpux10.2* )
 634     opsys=hpux10-20
 635   ;;
 636   hppa*-hp-hpux1[1-9]* )
 637     opsys=hpux11
 638     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 639   ;;
 640
 641   ## IBM machines
 642   rs6000-ibm-aix4.[23]* )
 643     opsys=aix4-2
 644   ;;
 645   powerpc-ibm-aix4.[23]*  )
 646     opsys=aix4-2
 647   ;;
 648   rs6000-ibm-aix[56]* )
 649     opsys=aix4-2
 650   ;;
 651   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 652     opsys=aix4-2
 653   ;;
 654
 655   ## Suns
 656   *-sun-solaris* \
 657     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 658     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 659     case "${canonical}" in
 660       i[3456]86-*-* )   ;;
 661       amd64-*-*|x86_64-*-*) ;;
 662       sparc* )          ;;
 663       * )               unported=yes ;;
 664     esac
 665     case "${canonical}" in
 666       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 667                 opsys=sol2-10
 668                 emacs_check_sunpro_c=yes
 669                 ;;
 670       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 671       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 672       *-sunos5.6* | *-solaris2.6* )
 673                 opsys=sol2-6
 674                 RANLIB="ar -ts"
 675                 ;;
 676       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 677       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 678                 opsys=sol2-6
 679                 emacs_check_sunpro_c=yes
 680                 ;;
 681     esac
 682     ## Watch out for a compiler that we know will not work.
 683     case "${canonical}" in
 684      *-solaris* | *-sunos5* )
 685                 if [ "x$CC" = x/usr/ucb/cc ]; then
 686                   ## /usr/ucb/cc doesn't work;
 687                   ## we should find some other compiler that does work.
 688                   unset CC
 689                 fi
 690                 ;;
 691       *) ;;
 692     esac
 693   ;;
 694
 695   ## Intel 386 machines where we don't care about the manufacturer.
 696   i[3456]86-*-* )
 697     case "${canonical}" in
 698       *-darwin* )               opsys=darwin ;;
 699       *-mingw* )
 700                 opsys=mingw32
 701                 # MinGW overrides and adds some system headers in nt/inc.
 702                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 703                 ;;
 704       *-sysv4.2uw* )            opsys=unixware ;;
 705       *-sysv5uw* )              opsys=unixware ;;
 706       *-sysv5OpenUNIX* )        opsys=unixware ;;
 707       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 708     esac
 709   ;;
 710
 711   # MinGW64
 712   x86_64-*-* )
 713     case "${canonical}" in
 714       *-mingw* )
 715                 opsys=mingw32
 716                 # MinGW overrides and adds some system headers in nt/inc.
 717                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 718                 ;;
 719       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 720     esac
 721   ;;
 722
 723   * )
 724     unported=yes
 725   ;;
 726 esac
 727
 728 ### If the code above didn't choose an operating system, just choose
 729 ### an operating system based on the configuration name.  You really
 730 ### only want to use this when you have no idea what the right
 731 ### operating system is; if you know what operating systems a machine
 732 ### runs, it's cleaner to make it explicit in the case statement
 733 ### above.
 734 if test x"${opsys}" = x; then
 735   case "${canonical}" in
 736     *-gnu* )                            opsys=gnu ;;
 737     * )
 738       unported=yes
 739     ;;
 740   esac
 741 fi
 742
 743 ]
 744 dnl quotation ends
 745
 746 if test $unported = yes; then
 747   AC_MSG_ERROR([Emacs does not support '${canonical}' systems.
 748 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 749 Check 'etc/MACHINES' for recognized configuration names.])
 750 fi
 751
 752 #### Choose a compiler.
 753
 754 dnl Don't bother to test for C89.
 755 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 756
 757 dnl Sets GCC=yes if using gcc.
 758 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 759 if test -n "$XCRUN"; then
 760   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 761   test -n "$AR" && export AR
 762 fi
 763
 764 dnl Emacs needs C99 or later.
 765 gl_PROG_CC_C99
 766
 767 AM_PROG_CC_C_O
 768
 769 if test x$GCC = xyes; then
 770   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 771 fi
 772
 773 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 774 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 775 dnl that clash with MinGW.
 776 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 777
 778 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 779 AC_DEFUN([gl_CRYPTO_CHECK])
 780 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 781 # as we don't use them.
 782 AC_DEFUN([gl_FCNTL_O_FLAGS])
 783 # Avoid gnulib's test for pthread_sigmask.
 784 funcs=
 785 for func in $ac_func_list; do
 786   test $func = pthread_sigmask || AS_VAR_APPEND([funcs], [" $func"])
 787 done
 788 ac_func_list=$funcs
 789 # Use the system putenv even if it lacks GNU features, as we don't need them,
 790 # and the gnulib replacement runs afoul of a FreeBSD 10.1 bug; see Bug#19874.
 791 AC_CHECK_FUNCS_ONCE([putenv])
 792 AC_DEFUN([gl_FUNC_PUTENV],
 793   [test "$ac_cv_func_putenv" = yes || REPLACE_PUTENV=1])
 794
 795 # Initialize gnulib right after choosing the compiler.
 796 dnl Amongst other things, this sets AR and ARFLAGS.
 797 gl_EARLY
 798
 799 if test "$ac_test_CFLAGS" != set; then
 800   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 801   # if -g3 works and the user does not specify CFLAGS.
 802   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 803   case $CFLAGS in
 804     '-g')
 805       emacs_g3_CFLAGS='-g3';;
 806     '-g -O2')
 807       emacs_g3_CFLAGS='-g3 -O2';;
 808     *)
 809       emacs_g3_CFLAGS='';;
 810   esac
 811   if test -n "$emacs_g3_CFLAGS"; then
 812     emacs_save_CFLAGS=$CFLAGS
 813     CFLAGS=$emacs_g3_CFLAGS
 814     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 815       [emacs_cv_prog_cc_g3],
 816       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 817          [emacs_cv_prog_cc_g3=yes],
 818          [emacs_cv_prog_cc_g3=no])])
 819     if test $emacs_cv_prog_cc_g3 != yes; then
 820       CFLAGS=$emacs_save_CFLAGS
 821     fi
 822     if test $opsys = mingw32; then
 823       CFLAGS="$CFLAGS -gdwarf-2"
 824     fi
 825   fi
 826
 827   case $CFLAGS in
 828     *-O*) ;;
 829     *)
 830       # No optimization flag was inferred for this non-GCC compiler.
 831       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 832       emacs_save_CFLAGS=$CFLAGS
 833       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 834       CFLAGS=${CFLAGS}-O
 835       AC_CACHE_CHECK([whether $CC accepts -O],
 836         [emacs_cv_prog_cc_o],
 837         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 838            [emacs_cv_prog_cc_o=yes],
 839            [emacs_cv_prog_cc_o=no])])
 840       if test $emacs_cv_prog_cc_o != yes; then
 841         CFLAGS=$emacs_save_CFLAGS
 842       fi ;;
 843   esac
 844 fi
 845
 846 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 847 # ---------------------------------------------------------------------------
 848 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 849 # Otherwise, run RUN-IF-NOT-FOUND.
 850 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 851   [AC_PREPROC_IFELSE(
 852     [AC_LANG_PROGRAM(
 853       [[
 854 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 855 /* ok */
 856 #else
 857 # error "your version of gcc is older than $1.$2"
 858 #endif
 859       ]]),
 860     ], [$3], [$4])
 861   ]
 862 )
 863
 864 AC_ARG_ENABLE([gcc-warnings],
 865   [AS_HELP_STRING([--enable-gcc-warnings@<:@=TYPE@:>@],
 866                   [control generation of GCC warnings.  The TYPE 'yes'
 867                    means to fail if any warnings are issued; 'warn-only'
 868                    means issue warnings without failing (default for
 869                    developer builds); 'no' means disable warnings
 870                    (default for non-developer builds).])],
 871   [case $enableval in
 872      yes|no|warn-only) ;;
 873      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 874    esac
 875    gl_gcc_warnings=$enableval],
 876   [# By default, use 'warn-only' if it looks like the invoker of 'configure'
 877    # is a developer as opposed to a builder.  This is most likely true
 878    # if GCC is recent enough and there is a .git directory or file;
 879    # however, if there is also a .tarball-version file it is probably
 880    # just a release imported into Git for patch management.
 881    gl_gcc_warnings=no
 882    if test -e "$srcdir"/.git && test ! -f "$srcdir"/.tarball-version; then
 883      gl_GCC_VERSION_IFELSE([5], [3], [gl_gcc_warnings=warn-only])]
 884    fi
 885 )
 886
 887 # clang is unduly picky about some things.
 888 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 889   [AC_COMPILE_IFELSE(
 890      [AC_LANG_PROGRAM([[
 891           #ifndef __clang__
 892             error "not clang";
 893           #endif
 894         ]])],
 895      [emacs_cv_clang=yes],
 896      [emacs_cv_clang=no])])
 897
 898 # When compiling with GCC, prefer -isystem to -I when including system
 899 # include files, to avoid generating useless diagnostics for the files.
 900 AS_IF([test $gl_gcc_warnings = no],
 901  [
 902   isystem='-I'
 903   AS_IF([test "$emacs_cv_clang" = yes],
 904    [
 905      # Turn off some warnings if supported.
 906      gl_WARN_ADD([-Wno-switch])
 907      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 908      gl_WARN_ADD([-Wno-pointer-sign])
 909      gl_WARN_ADD([-Wno-string-plus-int])
 910      gl_WARN_ADD([-Wno-unknown-attributes])
 911    ])
 912  ],[
 913   isystem='-isystem '
 914
 915   # This, $nw, is the list of warnings we disable.
 916   nw=
 917
 918   case $with_x_toolkit in
 919     lucid | athena | motif)
 920        # Old toolkits mishandle 'const'.
 921        nw="$nw -Wwrite-strings"
 922        ;;
 923   esac
 924   AS_IF([test $gl_gcc_warnings = yes],
 925     [gl_WARN_ADD([-Werror], [WERROR_CFLAGS])])
 926   AC_SUBST([WERROR_CFLAGS])
 927
 928   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 929   nw="$nw -Woverlength-strings"     # Not a problem these days
 930   nw="$nw -Wformat-nonliteral"      # we do this a lot
 931   nw="$nw -Wvla"                    # Emacs uses <vla.h>.
 932   nw="$nw -Wswitch-default"         # Too many warnings for now
 933   nw="$nw -Wunused-const-variable=2" # lisp.h declares const objects.
 934   nw="$nw -Winline"                 # OK to ignore 'inline'
 935   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 936                                     # signed overflow has undefined behavior
 937   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 938   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 939   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 940
 941   # Emacs doesn't care about shadowing; see
 942   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 943   nw="$nw -Wshadow"
 944
 945   # Emacs's use of alloca inhibits protecting the stack.
 946   nw="$nw -Wstack-protector"
 947
 948   # Emacs's use of partly-const functions such as Fgnutls_available_p
 949   # make this option problematic.
 950   nw="$nw -Wsuggest-attribute=const"
 951
 952   # Emacs's use of partly-pure functions such as CHECK_TYPE make this
 953   # option problematic.
 954   nw="$nw -Wsuggest-attribute=pure"
 955
 956   # This part is merely for shortening the command line,
 957   # since -Wall implies -Wswitch.
 958   nw="$nw -Wswitch"
 959
 960   # This part is merely for shortening the command line,
 961   # since -Wno-FOO needs to be added below regardless.
 962   nw="$nw -Wmissing-field-initializers"
 963   nw="$nw -Wtype-limits"
 964   nw="$nw -Wunused-parameter"
 965
 966   if test $emacs_cv_clang = yes; then
 967     nw="$nw -Wcast-align"
 968   fi
 969
 970   # This causes too much noise in the MinGW build
 971   if test $opsys = mingw32; then
 972     nw="$nw -Wpointer-sign"
 973   fi
 974
 975   gl_MANYWARN_ALL_GCC([ws])
 976   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 977   for w in $ws; do
 978     gl_WARN_ADD([$w])
 979   done
 980   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 981   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 982   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 983   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 984   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 985   gl_WARN_ADD([-Wno-format-nonliteral])
 986
 987   # More things that clang is unduly picky about.
 988   if test $emacs_cv_clang = yes; then
 989     gl_WARN_ADD([-Wno-tautological-compare])
 990     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 991   fi
 992
 993   # This causes too much noise in the MinGW build
 994   if test $opsys = mingw32; then
 995     gl_WARN_ADD([-Wno-pointer-sign])
 996   fi
 997
 998   AC_DEFINE([GCC_LINT], [1], [Define to 1 if --enable-gcc-warnings.])
 999   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
1000   AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
1001   [/* Enable compile-time and run-time bounds-checking, and some warnings,
1002       without upsetting glibc 2.15+. */
1003    #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
1004         && defined __OPTIMIZE__ && __OPTIMIZE__)
1005    # define _FORTIFY_SOURCE 2
1006    #endif
1007   ])
1008
1009   # We use a slightly smaller set of warning options for lib/.
1010   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
1011   nw=
1012   nw="$nw -Wunused-macros"
1013
1014   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
1015   AC_SUBST([GNULIB_WARN_CFLAGS])
1016  ])
1017
1018 edit_cflags="
1019   s,///*,/,g
1020   s/^/ /
1021   s/ -I/ $isystem/g
1022   s/^ //
1023 "
1024
1025 AC_ARG_ENABLE(link-time-optimization,
1026 [AS_HELP_STRING([--enable-link-time-optimization],
1027                 [build emacs with link-time optimization.
1028                  This requires GCC 4.5.0 or later, or clang.
1029                  (Note that clang support is experimental - see INSTALL.)
1030                  It also makes Emacs harder to debug, and when we tried it
1031                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
1032                  recommended for typical use.])],
1033 if test "${enableval}" != "no"; then
1034    ac_lto_supported=no
1035    if test $emacs_cv_clang = yes; then
1036       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
1037       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
1038       if test -x "$GOLD_PLUGIN"; then
1039          LTO="-flto"
1040       fi
1041    elif test x$GCC = xyes; then
1042       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
1043       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
1044       if test x$CPUS != x; then
1045          LTO="-flto=$CPUS"
1046       else
1047          LTO="-flto"
1048       fi
1049    else
1050       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
1051    fi
1052    if test -z "$LTO"; then
1053       ac_lto_supported=no
1054    else
1055       old_CFLAGS=$CFLAGS
1056       CFLAGS="$CFLAGS $LTO"
1057       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1058          [ac_lto_supported=yes], [ac_lto_supported=no])
1059          CFLAGS="$old_CFLAGS"
1060    fi
1061    AC_MSG_RESULT([$ac_lto_supported])
1062    if test "$ac_lto_supported" = "yes"; then
1063       CFLAGS="$CFLAGS $LTO"
1064       if test x$emacs_cv_clang = xyes; then
1065          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
1066          # WARNING: 'ar --plugin ...' doesn't work without
1067          # command, so plugin name is appended to ARFLAGS.
1068          ARFLAGS="cru --plugin $GOLD_PLUGIN"
1069          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
1070       else
1071         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
1072         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
1073         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
1074         dnl dump core on Fedora 20, so play it safe for now.
1075         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
1076           [CFLAGS="$CFLAGS -ffat-lto-objects"])
1077       fi
1078    fi
1079 fi)
1080
1081 dnl Prefer silent make output.  For verbose output, use
1082 dnl 'configure --disable-silent-rules' or 'make V=1' .
1083 AM_SILENT_RULES([yes])
1084 dnl Port to Automake 1.11.
1085 dnl This section can be removed once we assume Automake 1.14 or later.
1086 : ${AM_V=$AM_DEFAULT_VERBOSITY}
1087 : ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
1088 AC_SUBST([AM_V])
1089 AM_SUBST_NOTMAKE([AM_V])
1090 AC_SUBST([AM_DEFAULT_V])
1091 AM_SUBST_NOTMAKE([AM_DEFAULT_V])
1092 AC_SUBST([AM_DEFAULT_VERBOSITY])
1093
1094 dnl Some other nice autoconf tests.
1095 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
1096 dnl AC_PROG_INSTALL
1097 dnl AC_PROG_MKDIR_P
1098 dnl if test "x$RANLIB" = x; then
1099 dnl   AC_PROG_RANLIB
1100 dnl fi
1101
1102
1103 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
1104 dnl can be made to directories.  This is not relevant for our usage, and
1105 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1106 dnl hosted on AFS, both examples where simple links work, but links to
1107 dnl directories fail.  We use a cut-down version instead.
1108 dnl AC_PROG_LN_S
1109
1110 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1111 rm -f conf$$ conf$$.file
1112
1113 LN_S_FILEONLY='cp -p'
1114
1115 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1116 dnl random program in the current directory.
1117 if (echo >conf$$.file) 2>/dev/null; then
1118   if ln -s conf$$.file conf$$ 2>/dev/null; then
1119     if test "$opsys" = "mingw32"; then
1120       LN_S_FILEONLY='/bin/ln -s'
1121     else
1122       LN_S_FILEONLY='ln -s'
1123     fi
1124   elif ln conf$$.file conf$$ 2>/dev/null; then
1125     if test "$opsys" = "mingw32"; then
1126       LN_S_FILEONLY=/bin/ln
1127     else
1128       LN_S_FILEONLY=ln
1129     fi
1130   fi
1131 fi
1132
1133 rm -f conf$$ conf$$.file
1134
1135 if test "$LN_S_FILEONLY" = "ln -s"; then
1136    AC_MSG_RESULT([yes])
1137 else
1138    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1139 fi
1140
1141 AC_SUBST(LN_S_FILEONLY)
1142
1143
1144 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1145 dnl doesn't support links to directories, as in "ln file dir".  But that
1146 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1147 dnl executables at "make install" time.
1148 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1149 dnl for more details.
1150 if test "$opsys" = "mingw32"; then
1151   LN_S="/bin/ln"
1152 fi
1153
1154 dnl On some Debian versions, "install-info" prints irritating messages
1155 dnl "This is not dpkg install-info anymore, but GNU install-info"
1156 dnl if called via an absolute file name.
1157 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1158 dnl Sadly some people may have an old ginstall-info installed on
1159 dnl non-Debian systems, so we can't use this.
1160 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1161 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1162
1163 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1164   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1165 dnl Don't use GZIP, which is used by gzip for additional parameters.
1166 AC_PATH_PROG(GZIP_PROG, gzip)
1167
1168 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1169    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1170
1171 PAXCTL_dumped=
1172 PAXCTL_notdumped=
1173 if test $opsys = gnu-linux; then
1174   if test "${SETFATTR+set}" != set; then
1175     AC_CACHE_CHECK([for setfattr],
1176       [emacs_cv_prog_setfattr],
1177       [touch conftest.tmp
1178        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1179          emacs_cv_prog_setfattr=yes
1180        else
1181          emacs_cv_prog_setfattr=no
1182        fi])
1183     if test "$emacs_cv_prog_setfattr" = yes; then
1184       PAXCTL_notdumped='$(SETFATTR) -n user.pax.flags -v er'
1185       SETFATTR=setfattr
1186     else
1187       SETFATTR=
1188     fi
1189     rm -f conftest.tmp
1190     AC_SUBST([SETFATTR])
1191   fi
1192 fi
1193 case $opsys,$PAXCTL_notdumped in
1194   gnu-linux, | netbsd,)
1195     AC_PATH_PROG([PAXCTL], [paxctl], [],
1196       [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1197     if test -n "$PAXCTL"; then
1198       if test "$opsys" = netbsd; then
1199         PAXCTL_dumped='$(PAXCTL) +a'
1200         PAXCTL_notdumped=$PAXCTL_dumped
1201       else
1202         AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1203         AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1204           [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then
1205              AC_MSG_RESULT([yes])
1206            else
1207              AC_MSG_RESULT([no])
1208              PAXCTL=
1209            fi])
1210         if test -n "$PAXCTL"; then
1211           PAXCTL_dumped='$(PAXCTL) -zex'
1212           PAXCTL_notdumped='$(PAXCTL) -r'
1213         fi
1214       fi
1215     fi;;
1216 esac
1217 AC_SUBST([PAXCTL_dumped])
1218 AC_SUBST([PAXCTL_notdumped])
1219
1220 ## Need makeinfo >= 4.7 (?) to build the manuals.
1221 if test "$MAKEINFO" != "no"; then
1222   if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
1223     MAKEINFO=makeinfo
1224   fi
1225   case `($MAKEINFO --version) 2>/dev/null` in
1226     *' (GNU texinfo) '4.[[7-9]]* | \
1227     *' (GNU texinfo) '4.[[1-9][0-9]]* | \
1228     *' (GNU texinfo) '[[5-9]]* | \
1229     *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1230     *) MAKEINFO=no;;
1231   esac
1232 fi
1233
1234 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1235 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1236 ## therefore in the category of "special tools" not normally required, which
1237 ## configure does not have to check for (eg autoconf itself).
1238 ## In a repository checkout on the other hand, the manuals are not included.
1239 ## So makeinfo is a requirement to build from the repository, and configure
1240 ## should test for it as it does for any other build requirement.
1241 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1242 ## with pre-built manuals, from a repository checkout.
1243 HAVE_MAKEINFO=yes
1244
1245 if test "$MAKEINFO" = "no"; then
1246   MAKEINFO=makeinfo
1247   if test "x${with_makeinfo}" = "xno"; then
1248     HAVE_MAKEINFO=no
1249   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1250     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1251 source tree does not seem to have pre-built manuals in the 'info' directory.
1252 Either install a suitable version of makeinfo, or re-run configure
1253 with the '--without-makeinfo' option to build without the manuals.] )
1254   fi
1255 fi
1256 AC_SUBST(HAVE_MAKEINFO)
1257
1258 if test $opsys = mingw32; then
1259    DOCMISC_W32=efaq-w32
1260 else
1261    DOCMISC_W32=
1262 fi
1263 AC_SUBST(DOCMISC_W32)
1264
1265 dnl Add our options to ac_link now, after it is set up.
1266
1267 if test x$GCC = xyes; then
1268   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1269     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1270 else
1271   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1272     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1273 fi
1274
1275 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1276 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1277 dnl Treat GCC specially since it just gives a non-fatal 'unrecognized option'
1278 dnl if not built to support GNU ld.
1279
1280 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1281 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1282 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1283 dnl   Eg "make LDFLAGS=... all" could run into problems,
1284 dnl   http://bugs.debian.org/684788
1285 dnl * unnecessary, since temacs is the only thing that actually needs it.
1286 dnl   Indeed this is where it was originally, prior to:
1287 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1288 late_LDFLAGS="$LDFLAGS"
1289 if test x$GCC = xyes; then
1290   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1291 else
1292   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1293 fi
1294
1295 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1296
1297 AC_MSG_CHECKING([for -znocombreloc])
1298 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1299   [AC_MSG_RESULT(yes)],
1300   LDFLAGS_NOCOMBRELOC=
1301   [AC_MSG_RESULT(no)])
1302
1303 LDFLAGS="$late_LDFLAGS"
1304
1305 AC_CACHE_CHECK([whether addresses are sanitized],
1306   [emacs_cv_sanitize_address],
1307   [AC_COMPILE_IFELSE(
1308      [AC_LANG_PROGRAM(
1309         [[#ifndef __has_feature
1310           #define __has_feature(f) 0
1311           #endif
1312           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1313           #else
1314            error "Addresses are not sanitized.";
1315           #endif
1316         ]])],
1317      [emacs_cv_sanitize_address=yes],
1318      [emacs_cv_sanitize_address=no])])
1319
1320 dnl The function dump-emacs will not be defined and temacs will do
1321 dnl (load "loadup") automatically unless told otherwise.
1322 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1323 case "$opsys" in
1324   nacl) CANNOT_DUMP=yes ;;
1325 esac
1326
1327 if test "$CANNOT_DUMP" = "yes"; then
1328   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1329 elif test "$emacs_cv_sanitize_address" = yes; then
1330   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1331 fi
1332
1333 AC_SUBST(CANNOT_DUMP)
1334
1335
1336 UNEXEC_OBJ=unexelf.o
1337 case "$opsys" in
1338   # MSDOS uses unexcoff.o
1339   aix4-2)
1340    UNEXEC_OBJ=unexaix.o
1341    ;;
1342   cygwin)
1343    UNEXEC_OBJ=unexcw.o
1344    ;;
1345   darwin)
1346    UNEXEC_OBJ=unexmacosx.o
1347    ;;
1348   hpux10-20 | hpux11)
1349    UNEXEC_OBJ=unexhp9k800.o
1350    ;;
1351   mingw32)
1352    UNEXEC_OBJ=unexw32.o
1353    ;;
1354   sol2-10)
1355    # Use the Solaris dldump() function, called from unexsol.c, to dump
1356    # emacs, instead of the generic ELF dump code found in unexelf.c.
1357    # The resulting binary has a complete symbol table, and is better
1358    # for debugging and other observability tools (debuggers, pstack, etc).
1359    #
1360    # If you encounter a problem using dldump(), please consider sending
1361    # a message to the OpenSolaris tools-linking mailing list:
1362    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1363    #
1364    # It is likely that dldump() works with older Solaris too, but this has
1365    # not been tested, so for now this change is for Solaris 10 or newer.
1366    UNEXEC_OBJ=unexsol.o
1367    ;;
1368 esac
1369
1370 LD_SWITCH_SYSTEM=
1371 case "$opsys" in
1372   freebsd|dragonfly)
1373    ## Let 'ld' find image libs and similar things in /usr/local/lib.
1374    ## The system compiler, GCC, has apparently been modified to not
1375    ## look there, contrary to what a stock GCC would do.
1376 ### It's not our place to do this.  See bug#10313#17.
1377 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1378       :
1379    ;;
1380
1381   gnu-linux)
1382    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1383    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1384    ;;
1385
1386   netbsd)
1387 ### It's not our place to do this.  See bug#10313#17.
1388 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1389       :
1390    ;;
1391
1392   openbsd)
1393    ## Han Boetes <han@boetes.org> says this is necessary,
1394    ## otherwise Emacs dumps core on elf systems.
1395    LD_SWITCH_SYSTEM="-Z"
1396    ;;
1397 esac
1398 AC_SUBST(LD_SWITCH_SYSTEM)
1399
1400 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1401
1402 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1403 ## which has not been defined yet.  When this was handled with cpp,
1404 ## it was expanded to null when configure sourced the s/*.h file.
1405 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1406 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1407 ## (or somesuch), but because it is supposed to go at the _front_
1408 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1409 ## Compare with the gnu-linux case below, which added to the end
1410 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1411 ## LD_SWITCH_SYSTEM_TEMACS.
1412 case "$opsys" in
1413   netbsd|openbsd)
1414    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1415 esac
1416
1417
1418 C_SWITCH_MACHINE=
1419 case $canonical in
1420  alpha*)
1421   AC_CHECK_DECL([__ELF__])
1422   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1423     ## With ELF, make sure that all common symbols get allocated to in the
1424     ## data section.  Otherwise, the dump of temacs may miss variables in
1425     ## the shared library that have been initialized.  For example, with
1426     ## GNU libc, __malloc_initialized would normally be resolved to the
1427     ## shared library's .bss section, which is fatal.
1428     if test "x$GCC" = "xyes"; then
1429       C_SWITCH_MACHINE="-fno-common"
1430     else
1431       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1432     fi
1433   else
1434       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1435       dnl albeit under the mistaken assumption that said file
1436       dnl was no longer used.
1437       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1438   fi
1439   ;;
1440 esac
1441 AC_SUBST(C_SWITCH_MACHINE)
1442
1443 AC_SUBST(UNEXEC_OBJ)
1444
1445 C_SWITCH_SYSTEM=
1446 ## Some programs in src produce warnings saying certain subprograms
1447 ## are too complex and need a MAXMEM value greater than 2000 for
1448 ## additional optimization.  --nils@exp-math.uni-essen.de
1449 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1450   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1451 if test "$opsys" = "mingw32"; then
1452   case "$canonical" in
1453     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1454     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1455   esac
1456 fi
1457 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1458 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1459 AC_SUBST(C_SWITCH_SYSTEM)
1460
1461
1462 LIBS_SYSTEM=
1463 case "$opsys" in
1464   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1465   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1466
1467   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1468
1469   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1470
1471   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1472
1473   ## Motif needs -lgen.
1474   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1475 esac
1476
1477 AC_SUBST(LIBS_SYSTEM)
1478
1479 ### Make sure subsequent tests use flags consistent with the build flags.
1480
1481 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1482   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1483 else
1484   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1485 fi
1486
1487 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1488 AC_DEFUN([AC_TYPE_SIZE_T])
1489 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1490 AC_DEFUN([AC_TYPE_UID_T])
1491
1492 # sqrt and other floating-point functions such as fmod and frexp
1493 # are found in -lm on many systems.
1494 OLD_LIBS=$LIBS
1495 AC_SEARCH_LIBS([sqrt], [m])
1496 if test "X$LIBS" = "X$OLD_LIBS"; then
1497   LIB_MATH=
1498 else
1499   LIB_MATH=$ac_cv_search_sqrt
1500 fi
1501 LIBS=$OLD_LIBS
1502
1503 dnl Current possibilities handled by sed (aix4-2 -> aix,
1504 dnl gnu-linux -> gnu/linux, etc.):
1505 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux.
1506 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1507 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1508
1509 case $opsys in
1510   cygwin )
1511     LIB_MATH=
1512     ;;
1513   darwin )
1514     ## Adding -lm confuses the dynamic linker, so omit it.
1515     LIB_MATH=
1516     ;;
1517   freebsd | dragonfly )
1518     SYSTEM_TYPE=berkeley-unix
1519     ;;
1520   gnu-linux | gnu-kfreebsd )
1521     ;;
1522   hpux10-20 | hpux11 )
1523     ;;
1524   mingw32 )
1525     LIB_MATH=
1526     SYSTEM_TYPE=windows-nt
1527     ;;
1528   dnl NB this may be adjusted below.
1529   netbsd | openbsd )
1530     SYSTEM_TYPE=berkeley-unix
1531     ;;
1532
1533   sol2* | unixware )
1534     SYSTEM_TYPE=usg-unix-v
1535     ;;
1536
1537 esac
1538
1539 AC_SUBST(LIB_MATH)
1540 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1541   [The type of system you are compiling for; sets 'system-type'.])
1542
1543
1544 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1545 pre_PKG_CONFIG_LIBS=$LIBS
1546
1547 PKG_PROG_PKG_CONFIG(0.9.0)
1548
1549 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1550 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1551 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1552 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1553 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1554 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1555 dnl actions.
1556 AC_DEFUN([EMACS_CHECK_MODULES],
1557   [PKG_CHECK_MODULES([$1], [$2],
1558      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1559       m4_default([$3], [HAVE_$1=yes])],
1560      [m4_default([$4], [HAVE_$1=no])])])
1561
1562 HAVE_SOUND=no
1563 if test "${with_sound}" != "no"; then
1564   # Sound support for GNU/Linux, the free BSDs, MinGW, and Cygwin.
1565   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1566     have_sound_header=yes, [], [
1567     #ifdef __MINGW32__
1568     #define WIN32_LEAN_AND_MEAN
1569     #include <windows.h>
1570     #endif
1571     ])
1572   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1573     AC_MSG_ERROR([OSS sound support requested but not found.])
1574
1575   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1576     # Emulation library used on NetBSD.
1577     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1578     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1579       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1580     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1581     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1582   fi
1583   AC_SUBST(LIBSOUND)
1584
1585   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1586     ALSA_REQUIRED=1.0.0
1587     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1588     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1589     if test $HAVE_ALSA = yes; then
1590       SAVE_CFLAGS="$CFLAGS"
1591       SAVE_LIBS="$LIBS"
1592       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1593       LIBS="$ALSA_LIBS $LIBS"
1594       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1595                       emacs_alsa_normal=yes,
1596                     emacs_alsa_normal=no)
1597       if test "$emacs_alsa_normal" != yes; then
1598         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1599                        [[snd_lib_error_set_handler (0);]])],
1600                        emacs_alsa_subdir=yes,
1601                      emacs_alsa_subdir=no)
1602         if test "$emacs_alsa_subdir" != yes; then
1603           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1604         fi
1605         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1606       fi
1607
1608       CFLAGS="$SAVE_CFLAGS"
1609       LIBS="$SAVE_LIBS"
1610       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1611       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1612       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1613     elif test "${with_sound}" = "alsa"; then
1614       AC_MSG_ERROR([ALSA sound support requested but not found.])
1615     fi
1616   fi                            dnl with_sound = alsa|yes
1617
1618   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1619   dnl compiles only on the specified platforms.  For others, it
1620   dnl probably doesn't make sense to try.
1621   dnl FIXME So surely we should bypass this whole section if not using
1622   dnl one of these platforms?
1623   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1624      case "$opsys" in
1625        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1626        dnl Adjust the --with-sound help text if you change this.
1627        gnu-linux|freebsd|netbsd|mingw32|cygwin)
1628          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1629          HAVE_SOUND=yes
1630          ;;
1631      esac
1632   fi
1633
1634   AC_SUBST(CFLAGS_SOUND)
1635 fi
1636
1637 dnl checks for header files
1638 AC_CHECK_HEADERS_ONCE(
1639   malloc.h
1640   sys/systeminfo.h
1641   sys/sysinfo.h
1642   coff.h pty.h
1643   sys/resource.h
1644   sys/utsname.h pwd.h utmp.h util.h)
1645
1646 AC_CACHE_CHECK([for ADDR_NO_RANDOMIZE],
1647   [emacs_cv_personality_addr_no_randomize],
1648   [AC_COMPILE_IFELSE(
1649      [AC_LANG_PROGRAM([[#include <sys/personality.h>]],
1650                       [[personality (personality (0xffffffff)
1651                                      | ADDR_NO_RANDOMIZE)]])],
1652      [emacs_cv_personality_addr_no_randomize=yes],
1653      [emacs_cv_personality_addr_no_randomize=no])])
1654 if test $emacs_cv_personality_addr_no_randomize = yes; then
1655   AC_DEFINE([HAVE_PERSONALITY_ADDR_NO_RANDOMIZE], [1],
1656             [Define to 1 if personality flag ADDR_NO_RANDOMIZE exists.])
1657 fi
1658
1659 # Note that Solaris has sys/sysinfo.h which defines struct
1660 # sysinfo as well.  To make sure that we're using GNU/Linux
1661 # sysinfo, we explicitly set one of its fields.
1662 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1663   AC_MSG_CHECKING([if Linux sysinfo may be used])
1664   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1665                                      [[struct sysinfo si;
1666                                        si.totalram = 0;
1667                                        sysinfo (&si)]])],
1668     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1669   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1670   if test $emacs_cv_linux_sysinfo = yes; then
1671     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1672     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1673                                        [[struct sysinfo si; return si.mem_unit]])],
1674       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1675                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1676   fi
1677 fi
1678
1679 dnl On Solaris 8 there's a compilation warning for term.h because
1680 dnl it doesn't define 'bool'.
1681 AC_CHECK_HEADERS(term.h, , , -)
1682 AC_HEADER_TIME
1683 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1684                                       ]])
1685 if test $ac_cv_have_decl_sys_siglist != yes; then
1686   # For Tru64, at least:
1687   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1688                                           ]])
1689 fi
1690 AC_HEADER_SYS_WAIT
1691
1692 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1693 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1694 #if HAVE_SYS_SOCKET_H
1695 #include <sys/socket.h>
1696 #endif])
1697 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1698 #if HAVE_SYS_SOCKET_H
1699 #include <sys/socket.h>
1700 #endif])
1701 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1702 #if HAVE_SYS_SOCKET_H
1703 #include <sys/socket.h>
1704 #endif])
1705
1706 dnl checks for structure members
1707 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1708                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1709                   struct ifreq.ifr_addr,
1710                   struct ifreq.ifr_addr.sa_len], , ,
1711                  [AC_INCLUDES_DEFAULT
1712 #if HAVE_SYS_SOCKET_H
1713 #include <sys/socket.h>
1714 #endif
1715 #if HAVE_NET_IF_H
1716 #include <net/if.h>
1717 #endif])
1718
1719 dnl Check for endianness.
1720 dnl AC_C_BIGENDIAN is done by gnulib.
1721
1722 dnl check for Make feature
1723
1724 AUTO_DEPEND=no
1725 dnl check if we have GCC and autodepend is on.
1726 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1727    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1728    SAVE_CFLAGS="$CFLAGS"
1729    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1730    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1731    CFLAGS="$SAVE_CFLAGS"
1732    test -f deps.d || ac_enable_autodepend=no
1733    rm -rf deps.d
1734    AC_MSG_RESULT([$ac_enable_autodepend])
1735    if test $ac_enable_autodepend = yes; then
1736       AUTO_DEPEND=yes
1737    fi
1738 fi
1739 AC_SUBST(AUTO_DEPEND)
1740
1741 dnl checks for operating system services
1742 AC_SYS_LONG_FILE_NAMES
1743
1744 #### Choose a window system.
1745
1746 ## We leave window_system equal to none if
1747 ## we end up building without one.  Any new window system should
1748 ## set window_system to an appropriate value and add objects to
1749 ## window-system-specific substs.
1750
1751 window_system=none
1752 AC_PATH_X
1753 if test "$no_x" != yes; then
1754   window_system=x11
1755 fi
1756
1757 LD_SWITCH_X_SITE_RPATH=
1758 if test "${x_libraries}" != NONE; then
1759   if test -n "${x_libraries}"; then
1760     LD_SWITCH_X_SITE=-L`AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -L/g'`
1761     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`
1762       AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -Wl,-rpath,/g'
1763     `
1764   fi
1765   x_default_search_path=""
1766   x_search_path=${x_libraries}
1767   if test -z "${x_search_path}"; then
1768     x_search_path=/usr/lib
1769   fi
1770   for x_library in `AS_ECHO(["$x_search_path:"]) | \
1771                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1772     x_search_path="\
1773 ${x_library}/X11/%L/%T/%N%C%S:\
1774 ${x_library}/X11/%l/%T/%N%C%S:\
1775 ${x_library}/X11/%T/%N%C%S:\
1776 ${x_library}/X11/%L/%T/%N%S:\
1777 ${x_library}/X11/%l/%T/%N%S:\
1778 ${x_library}/X11/%T/%N%S"
1779     if test x"${x_default_search_path}" = x; then
1780       x_default_search_path=${x_search_path}
1781     else
1782       x_default_search_path="${x_search_path}:${x_default_search_path}"
1783     fi
1784   done
1785 fi
1786 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1787
1788 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1789   C_SWITCH_X_SITE=$isystem`AS_ECHO(["$x_includes"]) | sed -e "s/:/ $isystem/g"`
1790 fi
1791
1792 if test x"${x_includes}" = x; then
1793   bitmapdir=/usr/include/X11/bitmaps
1794 else
1795   # accumulate include directories that have X11 bitmap subdirectories
1796   bmd_acc=
1797   for bmd in `AS_ECHO(["$x_includes"]) | sed -e 's/:/ /g'`; do
1798     if test -d "${bmd}/X11/bitmaps"; then
1799       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1800     fi
1801     if test -d "${bmd}/bitmaps"; then
1802       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1803     fi
1804   done
1805   bitmapdir=${bmd_acc#:}
1806 fi
1807
1808 test "${with_ns}" = maybe && test "${opsys}" != darwin && with_ns=no
1809 HAVE_NS=no
1810 NS_GNUSTEP_CONFIG=no
1811 NS_IMPL_COCOA=no
1812 NS_IMPL_GNUSTEP=no
1813 tmp_CPPFLAGS="$CPPFLAGS"
1814 tmp_CFLAGS="$CFLAGS"
1815 CPPFLAGS="$CPPFLAGS -x objective-c"
1816 CFLAGS="$CFLAGS -x objective-c"
1817 GNU_OBJC_CFLAGS=
1818 LIBS_GNUSTEP=
1819 if test "${with_ns}" != no; then
1820   if test "${opsys}" = darwin; then
1821      NS_IMPL_COCOA=yes
1822      ns_appdir=`pwd`/nextstep/Emacs.app
1823      ns_appbindir=${ns_appdir}/Contents/MacOS
1824      ns_appresdir=${ns_appdir}/Contents/Resources
1825      ns_appsrc=Cocoa/Emacs.base
1826      ns_fontfile=macfont.o
1827   elif flags=$( (gnustep-config --objc-flags) 2>/dev/null); then
1828      NS_IMPL_GNUSTEP=yes
1829      NS_GNUSTEP_CONFIG=yes
1830      GNU_OBJC_CFLAGS=$flags
1831      LIBS_GNUSTEP=$(gnustep-config --gui-libs) || exit
1832   elif test -f $GNUSTEP_CONFIG_FILE; then
1833      NS_IMPL_GNUSTEP=yes
1834      dnl FIXME sourcing this several times in subshells seems inefficient.
1835      GNUSTEP_SYSTEM_HEADERS=$(
1836        . $GNUSTEP_CONFIG_FILE
1837        AS_ECHO(["$GNUSTEP_SYSTEM_HEADERS"])
1838      )
1839      GNUSTEP_SYSTEM_LIBRARIES=$(
1840        . $GNUSTEP_CONFIG_FILE
1841        AS_ECHO(["$GNUSTEP_SYSTEM_LIBRARIES"])
1842      )
1843      dnl I seemed to need these as well with GNUstep-startup 0.25.
1844      GNUSTEP_LOCAL_HEADERS=$(
1845        . $GNUSTEP_CONFIG_FILE
1846        AS_ECHO(["$GNUSTEP_LOCAL_HEADERS"])
1847      )
1848      GNUSTEP_LOCAL_LIBRARIES=$(
1849        . $GNUSTEP_CONFIG_FILE
1850        AS_ECHO(["$GNUSTEP_LOCAL_LIBRARIES"])
1851      )
1852      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1853        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1854      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1855        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1856      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1857      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1858      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1859      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1860      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1861      dnl If they had chosen to either define it or not, we could have
1862      dnl just used AC_CHECK_DECL here.
1863      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1864        emacs_cv_objc_exceptions,
1865 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1866 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1867 1;
1868 #else
1869 fail;
1870 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1871      if test $emacs_cv_objc_exceptions = yes; then
1872        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1873        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1874          [Define if GNUstep uses ObjC exceptions.])
1875        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1876      fi
1877   fi
1878   if test $NS_IMPL_GNUSTEP = yes; then
1879      ns_appdir=`pwd`/nextstep/Emacs.app
1880      ns_appbindir=${ns_appdir}
1881      ns_appresdir=${ns_appdir}/Resources
1882      ns_appsrc=GNUstep/Emacs.base
1883      ns_fontfile=nsfont.o
1884   fi
1885
1886   dnl This is only used while we test the NS headers, it gets reset below.
1887   CPPFLAGS="$CPPFLAGS $GNU_OBJC_CFLAGS"
1888   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1889
1890   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1891                   [AC_MSG_ERROR([The include files (AppKit/AppKit.h etc) that
1892 are required for a Nextstep build are missing or cannot be compiled.
1893 Either fix this, or re-configure with the option '--without-ns'.])])
1894
1895   macfont_file=""
1896   if test "${NS_IMPL_COCOA}" = "yes"; then
1897     AC_MSG_CHECKING([for OSX 10.6 or newer])
1898     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1899                                      [
1900 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1901 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1060
1902  ; /* OK */
1903 #else
1904  error "OSX 10.6 or newer required";
1905 #endif
1906 #endif
1907                     ])],
1908                     ns_osx_have_106=yes,
1909                     ns_osx_have_106=no)
1910     AC_MSG_RESULT([$ns_osx_have_106])
1911
1912     if test $ns_osx_have_106 = no; then
1913        AC_MSG_ERROR([OSX 10.6 or newer is required]);
1914     fi
1915   fi
1916 fi
1917
1918 AC_SUBST(LIBS_GNUSTEP)
1919
1920 INSTALL_ARCH_INDEP_EXTRA=install-etc
1921 ns_self_contained=no
1922 NS_OBJ=
1923 NS_OBJC_OBJ=
1924 if test "${HAVE_NS}" = yes; then
1925   if test "$with_toolkit_scroll_bars" = "no"; then
1926     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1927   fi
1928
1929   window_system=nextstep
1930   # set up packaging dirs
1931   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1932      ns_self_contained=yes
1933      prefix=${ns_appresdir}
1934      exec_prefix=${ns_appbindir}
1935      dnl This one isn't really used, only archlibdir is.
1936      libexecdir="\${ns_appbindir}/libexec"
1937      archlibdir="\${ns_appbindir}/libexec"
1938      etcdocdir="\${ns_appresdir}/etc"
1939      etcdir="\${ns_appresdir}/etc"
1940      dnl FIXME maybe set datarootdir instead.
1941      dnl That would also get applications, icons, man.
1942      infodir="\${ns_appresdir}/info"
1943      mandir="\${ns_appresdir}/man"
1944      lispdir="\${ns_appresdir}/lisp"
1945      test "$locallisppathset" = no && locallisppath=""
1946      INSTALL_ARCH_INDEP_EXTRA=
1947   fi
1948
1949   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o $ns_fontfile"
1950 fi
1951 CFLAGS="$tmp_CFLAGS"
1952 CPPFLAGS="$tmp_CPPFLAGS"
1953 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1954 AC_SUBST(ns_self_contained)
1955 AC_SUBST(NS_OBJ)
1956 AC_SUBST(NS_OBJC_OBJ)
1957
1958 HAVE_W32=no
1959 W32_OBJ=
1960 W32_LIBS=
1961 EMACSRES=
1962 CLIENTRES=
1963 CLIENTW=
1964 W32_RES_LINK=
1965 EMACS_MANIFEST=
1966 UPDATE_MANIFEST=
1967 if test "${with_w32}" != no; then
1968   case "${opsys}" in
1969     cygwin)
1970       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1971              [AC_MSG_ERROR(['--with-w32' was specified, but windows.h
1972                    cannot be found.])])
1973     ;;
1974     mingw32)
1975     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1976     ;;
1977     *)
1978       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1979     ;;
1980   esac
1981 fi
1982
1983 if test "${opsys}" = "mingw32"; then
1984   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1985   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1986      #include <windows.h>
1987      #include <usp10.h>]],
1988    [[PIMAGE_NT_HEADERS pHeader;
1989      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1990    [emacs_cv_w32api=yes
1991     HAVE_W32=yes],
1992    emacs_cv_w32api=no)
1993   AC_MSG_RESULT($emacs_cv_w32api)
1994   if test "${emacs_cv_w32api}" = "no"; then
1995     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1996   fi
1997 fi
1998
1999 FIRSTFILE_OBJ=
2000 NTDIR=
2001 LIBS_ECLIENT=
2002 LIB_WSOCK32=
2003 NTLIB=
2004 CM_OBJ="cm.o"
2005 XARGS_LIMIT=
2006 if test "${HAVE_W32}" = "yes"; then
2007   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
2008   if test "$with_toolkit_scroll_bars" = "no"; then
2009     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for w32 build.])
2010   fi
2011   AC_CHECK_TOOL(WINDRES, [windres],
2012                 [AC_MSG_ERROR([No resource compiler found.])])
2013   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
2014   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
2015   EMACSRES="emacs.res"
2016   case "$canonical" in
2017     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
2018     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
2019   esac
2020   dnl Construct something of the form "24,4,0,0" with 4 components.
2021   comma_version=`echo "${PACKAGE_VERSION}.0.0" | sed -e 's/\./,/g' -e 's/^\([[^,]]*,[[^,]]*,[[^,]]*,[[^,]]*\).*/\1/'`
2022
2023   comma_space_version=`echo "$comma_version" | sed 's/,/, /g'`
2024   AC_SUBST(comma_version)
2025   AC_SUBST(comma_space_version)
2026   AC_CONFIG_FILES([nt/emacs.rc nt/emacsclient.rc])
2027   if test "${opsys}" = "cygwin"; then
2028     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
2029     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
2030     # Tell the linker that emacs.res is an object (which we compile from
2031     # the rc file), not a linker script.
2032     W32_RES_LINK="-Wl,emacs.res"
2033   else
2034     UPDATE_MANIFEST=update-game-score.exe.manifest
2035     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
2036     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
2037     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
2038     W32_RES_LINK="\$(EMACSRES)"
2039     CLIENTRES="emacsclient.res"
2040     CLIENTW="emacsclientw\$(EXEEXT)"
2041     FIRSTFILE_OBJ=firstfile.o
2042     NTDIR=nt
2043     CM_OBJ=
2044     LIBS_ECLIENT="-lcomctl32"
2045     LIB_WSOCK32="-lwsock32"
2046     NTLIB="ntlib.$ac_objext"
2047     XARGS_LIMIT="-s 10000"
2048   fi
2049 fi
2050 AC_SUBST(W32_OBJ)
2051 AC_SUBST(W32_LIBS)
2052 AC_SUBST(EMACSRES)
2053 AC_SUBST(EMACS_MANIFEST)
2054 AC_SUBST(UPDATE_MANIFEST)
2055 AC_SUBST(CLIENTRES)
2056 AC_SUBST(CLIENTW)
2057 AC_SUBST(W32_RES_LINK)
2058 AC_SUBST(FIRSTFILE_OBJ)
2059 AC_SUBST(NTDIR)
2060 AC_SUBST(CM_OBJ)
2061 AC_SUBST(LIBS_ECLIENT)
2062 AC_SUBST(LIB_WSOCK32)
2063 AC_SUBST(NTLIB)
2064 AC_SUBST(XARGS_LIMIT)
2065
2066 if test "${HAVE_W32}" = "yes"; then
2067   window_system=w32
2068   with_xft=no
2069 fi
2070
2071 ## $window_system is now set to the window system we will
2072 ## ultimately use.
2073
2074 term_header=
2075 HAVE_X_WINDOWS=no
2076 HAVE_X11=no
2077 USE_X_TOOLKIT=none
2078
2079 case "${window_system}" in
2080   x11 )
2081     HAVE_X_WINDOWS=yes
2082     HAVE_X11=yes
2083     term_header=xterm.h
2084     case "${with_x_toolkit}" in
2085       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
2086       motif ) USE_X_TOOLKIT=MOTIF ;;
2087       gtk ) with_gtk=yes
2088             term_header=gtkutil.h
2089 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
2090 dnl USE_X_TOOLKIT is set.
2091             USE_X_TOOLKIT=none ;;
2092       gtk2 ) with_gtk2=yes
2093              term_header=gtkutil.h
2094              USE_X_TOOLKIT=none ;;
2095       gtk3 ) with_gtk3=yes
2096              term_header=gtkutil.h
2097              USE_X_TOOLKIT=none ;;
2098       no ) USE_X_TOOLKIT=none ;;
2099 dnl If user did not say whether to use a toolkit, make this decision later:
2100 dnl use the toolkit if we have gtk, or X11R5 or newer.
2101       * ) USE_X_TOOLKIT=maybe ;;
2102     esac
2103   ;;
2104   nextstep )
2105     term_header=nsterm.h
2106   ;;
2107   w32 )
2108     term_header=w32term.h
2109   ;;
2110 esac
2111
2112 if test "$window_system" = none && test "X$with_x" != "Xno"; then
2113    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
2114    if test "$HAVE_XSERVER" = true ||
2115       test -n "$DISPLAY" ||
2116       {
2117         for emacs_libX11 in /usr/lib/libX11.*; do break; done
2118         test "$emacs_libX11" != '/usr/lib/libX11.*'
2119       }
2120    then
2121         AC_MSG_ERROR([You seem to be running X, but no X development libraries
2122 were found.  You should install the relevant development files for X
2123 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2124 sure you have development files for image handling, i.e.
2125 tiff, gif, jpeg, png and xpm.
2126 If you are sure you want Emacs compiled without X window support, pass
2127   --without-x
2128 to configure.])
2129    fi
2130 fi
2131
2132 # Does the opsystem file prohibit the use of the GNU malloc?
2133 # Assume not, until told otherwise.
2134 GNU_MALLOC=yes
2135
2136 AC_CACHE_CHECK(
2137   [whether malloc is Doug Lea style],
2138   [emacs_cv_var_doug_lea_malloc],
2139   [emacs_cv_var_doug_lea_malloc=no
2140    dnl Hooks do not work with address sanitization.
2141    if test "$emacs_cv_sanitize_address" != yes; then
2142      AC_LINK_IFELSE(
2143        [AC_LANG_PROGRAM(
2144           [[#include <malloc.h>
2145             static void hook (void) {}]],
2146           [[malloc_set_state (malloc_get_state ());
2147             __after_morecore_hook = hook;
2148             __malloc_initialize_hook = hook;]])],
2149        [emacs_cv_var_doug_lea_malloc=yes])
2150    fi])
2151 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2152
2153 system_malloc=$emacs_cv_sanitize_address
2154
2155 hybrid_malloc=
2156
2157 case "$opsys" in
2158   ## darwin ld insists on the use of malloc routines in the System framework.
2159   darwin | mingw32 | nacl | sol2-10) system_malloc=yes ;;
2160   cygwin) hybrid_malloc=yes;;
2161 esac
2162
2163 if test "${system_malloc}" != yes && test "${doug_lea_malloc}" != yes \
2164    && test "${UNEXEC_OBJ}" = unexelf.o; then
2165   hybrid_malloc=yes
2166 fi
2167
2168 GMALLOC_OBJ=
2169 HYBRID_MALLOC=
2170 if test "${system_malloc}" = "yes"; then
2171   AC_DEFINE([SYSTEM_MALLOC], 1,
2172     [Define to 1 to use the system memory allocator, even if it is not
2173      Doug Lea style.])
2174   GNU_MALLOC=no
2175   GNU_MALLOC_reason="
2176     (The GNU allocators don't work with this system configuration.)"
2177   VMLIMIT_OBJ=
2178 elif test "$hybrid_malloc" = yes; then
2179   AC_DEFINE(HYBRID_MALLOC, 1,
2180     [Define to use gmalloc before dumping and the system malloc after.])
2181   HYBRID_MALLOC=1
2182   GNU_MALLOC=no
2183   GNU_MALLOC_reason=" (only before dumping)"
2184   GMALLOC_OBJ=gmalloc.o
2185   VMLIMIT_OBJ=
2186 else
2187   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2188   VMLIMIT_OBJ=vm-limit.o
2189
2190   AC_CHECK_HEADERS([sys/vlimit.h])
2191   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2192     [AC_LINK_IFELSE(
2193        [AC_LANG_PROGRAM(
2194          [[extern char data_start[]; char ch;]],
2195          [[return data_start < &ch;]])],
2196        [emacs_cv_data_start=yes],
2197        [emacs_cv_data_start=no])])
2198   if test $emacs_cv_data_start = yes; then
2199     AC_DEFINE([HAVE_DATA_START], 1,
2200       [Define to 1 if data_start is the address of the start
2201        of the main data segment.])
2202   fi
2203 fi
2204 AC_SUBST([HYBRID_MALLOC])
2205 AM_CONDITIONAL([HYBRID_MALLOC_LIB], [test -n "$HYBRID_MALLOC"])
2206 AC_SUBST(GMALLOC_OBJ)
2207 AC_SUBST(VMLIMIT_OBJ)
2208
2209 if test "$doug_lea_malloc" = "yes" && test "$hybrid_malloc" != yes; then
2210   if test "$GNU_MALLOC" = yes ; then
2211     GNU_MALLOC_reason="
2212       (Using Doug Lea's new malloc from the GNU C Library.)"
2213   fi
2214   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2215     [Define to 1 if the system memory allocator is Doug Lea style,
2216      with malloc hooks and malloc_set_state.])
2217
2218   ## Use mmap directly for allocating larger buffers.
2219   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2220   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2221   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2222   case "$opsys" in
2223     mingw32|gnu*) REL_ALLOC=no ;;
2224   esac
2225 fi
2226
2227 if test x"${REL_ALLOC}" = x; then
2228   REL_ALLOC=${GNU_MALLOC}
2229 fi
2230
2231 use_mmap_for_buffers=no
2232 case "$opsys" in
2233   cygwin|mingw32) use_mmap_for_buffers=yes ;;
2234 esac
2235
2236 AC_FUNC_MMAP
2237 if test $use_mmap_for_buffers = yes; then
2238   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2239   REL_ALLOC=no
2240 fi
2241
2242 LIBS="$LIBS_SYSTEM $LIBS"
2243
2244 dnl FIXME replace main with a function we actually want from this library.
2245 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2246
2247 dnl Check for the POSIX thread library.
2248 LIB_PTHREAD=
2249 AC_CHECK_HEADERS_ONCE(pthread.h)
2250 if test "$ac_cv_header_pthread_h" && test "$opsys" != "mingw32"; then
2251   AC_CACHE_CHECK([for pthread library],
2252     [emacs_cv_pthread_lib],
2253     [emacs_cv_pthread_lib=no
2254      OLD_LIBS=$LIBS
2255      for emacs_pthread_lib in 'none needed' -lpthread; do
2256        case $emacs_pthread_lib in
2257          -*) LIBS="$OLD_LIBS $emacs_pthread_lib";;
2258        esac
2259        AC_LINK_IFELSE(
2260          [AC_LANG_PROGRAM(
2261             [[#include <pthread.h>
2262               #include <signal.h>
2263               sigset_t old_mask, new_mask;
2264               void noop (void) {}]],
2265             [[pthread_t th = pthread_self ();
2266               int status = 0;
2267               status += pthread_create (&th, 0, 0, 0);
2268               status += pthread_sigmask (SIG_BLOCK, &new_mask, &old_mask);
2269               status += pthread_kill (th, 0);
2270               #if ! (defined SYSTEM_MALLOC || defined HYBRID_MALLOC \
2271                      || defined DOUG_LEA_MALLOC)
2272               /* Test for pthread_atfork only if gmalloc uses it,
2273                  as older-style hosts like MirBSD 10 lack it.  */
2274               status += pthread_atfork (noop, noop, noop);
2275               #endif
2276               return status;]])],
2277          [emacs_cv_pthread_lib=$emacs_pthread_lib])
2278        LIBS=$OLD_LIBS
2279        if test "$emacs_cv_pthread_lib" != no; then
2280          break
2281        fi
2282      done])
2283   if test "$emacs_cv_pthread_lib" != no; then
2284     AC_DEFINE([HAVE_PTHREAD], 1, [Define to 1 if you have POSIX threads.])
2285     case $emacs_cv_pthread_lib in
2286       -*) LIB_PTHREAD=$emacs_cv_pthread_lib;;
2287     esac
2288     ac_cv_func_pthread_sigmask=yes
2289     # Some systems optimize for single-threaded programs by default, and
2290     # need special flags to disable these optimizations. For example, the
2291     # definition of 'errno' in <errno.h>.
2292     case $opsys in
2293       hpux* | sol*)
2294         AC_DEFINE([_REENTRANT], 1,
2295           [Define to 1 if your system requires this in multithreaded code.]);;
2296       aix4-2)
2297         AC_DEFINE([_THREAD_SAFE], 1,
2298           [Define to 1 if your system requires this in multithreaded code.]);;
2299     esac
2300   fi
2301 fi
2302 AC_SUBST([LIB_PTHREAD])
2303
2304 dnl Check for need for bigtoc support on IBM AIX
2305
2306 case ${host_os} in
2307 aix*)
2308   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2309     case $GCC in
2310     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2311     *) gdb_cv_bigtoc=-bbigtoc ;;
2312     esac
2313
2314     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2315     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2316   ])
2317   ;;
2318 esac
2319
2320 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2321 # is for the tests that follow.  We set them back later on.
2322
2323 REAL_CFLAGS="$CFLAGS"
2324 REAL_CPPFLAGS="$CPPFLAGS"
2325 REAL_LIBS="$LIBS"
2326
2327 if test "${HAVE_X11}" = "yes"; then
2328   DEFS="$C_SWITCH_X_SITE $DEFS"
2329   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2330   LIBS="-lX11 $LIBS"
2331   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2332   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2333
2334   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2335   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2336   # but it's more convenient here to set LD_RUN_PATH since this
2337   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2338   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2339     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2340     export LD_RUN_PATH
2341   fi
2342
2343   if test "${opsys}" = "gnu-linux"; then
2344     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2345     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2346      [[XOpenDisplay ("foo");]])],
2347      [xgnu_linux_first_failure=no],
2348      [xgnu_linux_first_failure=yes])
2349     if test "${xgnu_linux_first_failure}" = "yes"; then
2350       OLD_CPPFLAGS="$CPPFLAGS"
2351       OLD_LIBS="$LIBS"
2352       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2353       LIBS="$LIBS -b i486-linuxaout"
2354       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2355        [[XOpenDisplay ("foo");]])],
2356        [xgnu_linux_second_failure=no],
2357        [xgnu_linux_second_failure=yes])
2358       if test "${xgnu_linux_second_failure}" = "yes"; then
2359         # If we get the same failure with -b, there is no use adding -b.
2360         # So leave it out.  This plays safe.
2361         AC_MSG_RESULT(no)
2362       else
2363         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2364         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2365         AC_MSG_RESULT(yes)
2366       fi
2367       CPPFLAGS=$OLD_CPPFLAGS
2368       LIBS=$OLD_LIBS
2369     else
2370       AC_MSG_RESULT(no)
2371     fi
2372   fi
2373
2374   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2375   # header files included from there.
2376   AC_MSG_CHECKING(for Xkb)
2377   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2378 #include <X11/XKBlib.h>]],
2379         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2380         emacs_xkb=yes, emacs_xkb=no)
2381   AC_MSG_RESULT($emacs_xkb)
2382   if test $emacs_xkb = yes; then
2383     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2384   fi
2385
2386   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2387 XScreenNumberOfScreen)
2388 fi
2389
2390 if test "${window_system}" = "x11"; then
2391   AC_MSG_CHECKING(X11 version 6)
2392   AC_CACHE_VAL(emacs_cv_x11_version_6,
2393   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2394 [[#if XlibSpecificationRelease < 6
2395 fail;
2396 #endif
2397 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2398   if test $emacs_cv_x11_version_6 = yes; then
2399     AC_MSG_RESULT(6 or newer)
2400     AC_DEFINE(HAVE_X11R6, 1,
2401               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2402     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2403     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2404     ## XIM support.
2405     case "$opsys" in
2406       sol2-*) : ;;
2407       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2408            [Define if you have usable X11R6-style XIM support.])
2409          ;;
2410     esac
2411   else
2412     AC_MSG_RESULT(before 6)
2413   fi
2414 fi
2415
2416
2417 ### Use -lrsvg-2 if available, unless '--with-rsvg=no' is specified.
2418 HAVE_RSVG=no
2419 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2420   if test "${with_rsvg}" != "no"; then
2421     RSVG_REQUIRED=2.11.0
2422     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2423
2424     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2425     AC_SUBST(RSVG_CFLAGS)
2426     AC_SUBST(RSVG_LIBS)
2427
2428     if test $HAVE_RSVG = yes; then
2429       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2430       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2431       # Windows loads librsvg dynamically
2432       if test "${opsys}" = "mingw32"; then
2433         RSVG_LIBS=
2434       fi
2435     fi
2436   fi
2437 fi
2438
2439 HAVE_IMAGEMAGICK=no
2440 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2441   if test "${with_imagemagick}" != "no"; then
2442     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2443     ## 6.8.2 makes Emacs crash; see Bug#13867.
2444     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2445     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2446     AC_SUBST(IMAGEMAGICK_CFLAGS)
2447     AC_SUBST(IMAGEMAGICK_LIBS)
2448
2449     if test $HAVE_IMAGEMAGICK = yes; then
2450       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2451       OLD_CFLAGS=$CFLAGS
2452       OLD_LIBS=$LIBS
2453       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2454       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2455       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers MagickAutoOrientImage)
2456       CFLAGS=$OLD_CFLAGS
2457       LIBS=$OLD_LIBS
2458     fi
2459   fi
2460 fi
2461
2462 AC_CHECK_LIB(anl, getaddrinfo_a, HAVE_GETADDRINFO_A=yes)
2463 if test "${HAVE_GETADDRINFO_A}" = "yes"; then
2464   AC_DEFINE(HAVE_GETADDRINFO_A, 1,
2465 [Define to 1 if you have getaddrinfo_a for asynchronous DNS resolution.])
2466   GETADDRINFO_A_LIBS="-lanl"
2467   AC_SUBST(GETADDRINFO_A_LIBS)
2468 fi
2469
2470 HAVE_GTK=no
2471 GTK_OBJ=
2472 gtk_term_header=$term_header
2473 check_gtk2=no
2474 gtk3_pkg_errors=
2475 if test "${opsys}" != "mingw32"; then
2476   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2477     GLIB_REQUIRED=2.28
2478     GTK_REQUIRED=3.0
2479     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2480
2481     dnl Checks for libraries.
2482     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2483       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2484     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2485        AC_MSG_ERROR($GTK_PKG_ERRORS)
2486     fi
2487     if test "$pkg_check_gtk" = "yes"; then
2488        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2489        GTK_OBJ=emacsgtkfixed.o
2490        gtk_term_header=gtkutil.h
2491        USE_GTK_TOOLKIT="GTK3"
2492        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2493          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2494            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2495          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2496            [Define to 1 to disable Glib deprecation warnings.])
2497        fi
2498     else
2499        check_gtk2=yes
2500        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2501     fi
2502   fi
2503
2504   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2505     GLIB_REQUIRED=2.10
2506     GTK_REQUIRED=2.10
2507     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2508
2509     dnl Checks for libraries.
2510     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2511       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2512     if test "$pkg_check_gtk" = "no" &&
2513        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2514     then
2515       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2516     fi
2517     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2518   fi
2519 fi
2520
2521 OLD_CFLAGS=$CFLAGS
2522 OLD_LIBS=$LIBS
2523
2524 if test x"$pkg_check_gtk" = xyes; then
2525
2526   AC_SUBST(GTK_LIBS)
2527   CFLAGS="$CFLAGS $GTK_CFLAGS"
2528   LIBS="$GTK_LIBS $LIBS"
2529   dnl Try to compile a simple GTK program.
2530   AC_MSG_CHECKING([whether GTK compiles])
2531   GTK_COMPILES=no
2532   AC_LINK_IFELSE(
2533     [AC_LANG_PROGRAM(
2534        [[/* Check the Gtk and Glib APIs.  */
2535          #include <gtk/gtk.h>
2536          #include <glib-object.h>
2537          static void
2538          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2539          {}
2540        ]],
2541        [[
2542          GtkSettings *gs = 0;
2543          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2544             strict C prohibits this.  Use gtk_main_iteration to test that the
2545             libraries are there.  */
2546          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2547                                     0, 0, 0, G_CALLBACK (callback), 0))
2548            gtk_main_iteration ();
2549        ]])],
2550     [GTK_COMPILES=yes])
2551   AC_MSG_RESULT([$GTK_COMPILES])
2552   if test "${GTK_COMPILES}" != "yes"; then
2553     GTK_OBJ=
2554     if test "$USE_X_TOOLKIT" != "maybe"; then
2555       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2556     fi
2557   else
2558     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2559     HAVE_GTK=yes
2560     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2561     GTK_OBJ="gtkutil.o $GTK_OBJ"
2562     term_header=$gtk_term_header
2563     USE_X_TOOLKIT=none
2564     AC_MSG_WARN([[Your version of Gtk+ will have problems with
2565        closing open displays.  This is no problem if you just use
2566        one display, but if you use more than one and close one of them
2567        Emacs may crash.
2568        See http://bugzilla.gnome.org/show_bug.cgi?id=85715]])
2569     sleep 3
2570   fi
2571
2572 fi
2573 AC_SUBST(GTK_OBJ)
2574
2575
2576 if test "${HAVE_GTK}" = "yes"; then
2577
2578   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2579   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2580   if test "$with_toolkit_scroll_bars" != no; then
2581     with_toolkit_scroll_bars=yes
2582   fi
2583
2584   dnl  Check if we have the old file selection dialog declared and
2585   dnl  in the link library.  In 2.x it may be in the library,
2586   dnl  but not declared if deprecated featured has been selected out.
2587   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2588   HAVE_GTK_FILE_SELECTION=no
2589   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2590                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2591 #include <gtk/gtk.h>])
2592   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2593     AC_CHECK_FUNCS(gtk_file_selection_new)
2594   fi
2595
2596   dnl Same as above for gtk_handle_box.
2597   HAVE_GTK_HANDLE_BOX=no
2598   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2599                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2600 #include <gtk/gtk.h>])
2601   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2602     AC_CHECK_FUNCS(gtk_handle_box_new)
2603   fi
2604
2605   dnl Same as above for gtk_tearoff_menu_item.
2606   HAVE_GTK_TEAROFF_MENU_ITEM=no
2607   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2608                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2609 #include <gtk/gtk.h>])
2610   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2611     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2612   fi
2613
2614   dnl Check for functions introduced in 2.14 and later.
2615   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2616                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2617                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2618                  gtk_orientable_set_orientation \
2619                  gtk_window_set_has_resize_grip)
2620
2621  term_header=gtkutil.h
2622 fi
2623
2624
2625 dnl Enable xwidgets if GTK3 and WebKitGTK+ are available.
2626 HAVE_XWIDGETS=no
2627 XWIDGETS_OBJ=
2628 if test "$with_xwidgets" != "no"; then
2629   test "$USE_GTK_TOOLKIT" = "GTK3" && test "$window_system" != "none" ||
2630     AC_MSG_ERROR([xwidgets requested but gtk3 not used.])
2631
2632   WEBKIT_REQUIRED=1.4.0
2633   WEBKIT_MODULES="webkitgtk-3.0 >= $WEBKIT_REQUIRED"
2634   EMACS_CHECK_MODULES([WEBKIT], [$WEBKIT_MODULES])
2635   HAVE_XWIDGETS=$HAVE_WEBKIT
2636   test $HAVE_XWIDGETS = yes ||
2637     AC_MSG_ERROR([xwidgets requested but WebKitGTK+ not found.])
2638
2639   XWIDGETS_OBJ=xwidget.o
2640   AC_DEFINE([HAVE_XWIDGETS], 1, [Define to 1 if you have xwidgets support.])
2641 fi
2642 AC_SUBST(XWIDGETS_OBJ)
2643
2644 CFLAGS=$OLD_CFLAGS
2645 LIBS=$OLD_LIBS
2646
2647 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2648 dnl other platforms.
2649 HAVE_DBUS=no
2650 DBUS_OBJ=
2651 if test "${with_dbus}" = "yes"; then
2652    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2653    if test "$HAVE_DBUS" = yes; then
2654      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2655      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2656      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2657      dnl D-Bus 1.5.12.
2658      OLD_LIBS=$LIBS
2659      LIBS="$LIBS $DBUS_LIBS"
2660      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2661                     dbus_type_is_valid \
2662                     dbus_validate_bus_name \
2663                     dbus_validate_path \
2664                     dbus_validate_interface \
2665                     dbus_validate_member)
2666      LIBS=$OLD_LIBS
2667      DBUS_OBJ=dbusbind.o
2668    fi
2669 fi
2670 AC_SUBST(DBUS_CFLAGS)
2671 AC_SUBST(DBUS_LIBS)
2672 AC_SUBST(DBUS_OBJ)
2673
2674 dnl GSettings has been tested under GNU/Linux only.
2675 HAVE_GSETTINGS=no
2676 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2677    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2678    if test "$HAVE_GSETTINGS" = "yes"; then
2679       old_CFLAGS=$CFLAGS
2680       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2681       old_LIBS=$LIBS
2682       LIBS="$LIBS $GSETTINGS_LIBS"
2683       AC_MSG_CHECKING([whether GSettings is in gio])
2684       AC_LINK_IFELSE(
2685          [AC_LANG_PROGRAM(
2686              [[/* Check that gsettings really is present.  */
2687              #include <glib-object.h>
2688              #include <gio/gio.h>
2689              ]],
2690              [[
2691                GSettings *settings;
2692                GVariant *val = g_settings_get_value (settings, "");
2693              ]])],
2694          [], HAVE_GSETTINGS=no)
2695       AC_MSG_RESULT([$HAVE_GSETTINGS])
2696
2697       if test "$HAVE_GSETTINGS" = "yes"; then
2698         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2699         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2700         SETTINGS_LIBS="$GSETTINGS_LIBS"
2701       fi
2702       CFLAGS=$old_CFLAGS
2703       LIBS=$old_LIBS
2704    fi
2705 fi
2706
2707 dnl GConf has been tested under GNU/Linux only.
2708 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2709 HAVE_GCONF=no
2710 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2711    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2712    if test "$HAVE_GCONF" = yes; then
2713       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2714       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2715       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2716       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2717    fi
2718 fi
2719
2720 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2721     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2722     if test "$HAVE_GOBJECT" = "yes"; then
2723        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2724        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2725     fi
2726     SAVE_CFLAGS="$CFLAGS"
2727     SAVE_LIBS="$LIBS"
2728     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2729     LIBS="$SETTINGS_LIBS $LIBS"
2730     CFLAGS="$SAVE_CFLAGS"
2731     LIBS="$SAVE_LIBS"
2732 fi
2733 AC_SUBST(SETTINGS_CFLAGS)
2734 AC_SUBST(SETTINGS_LIBS)
2735
2736
2737 dnl SELinux is available for GNU/Linux only.
2738 HAVE_LIBSELINUX=no
2739 LIBSELINUX_LIBS=
2740 if test "${with_selinux}" = "yes"; then
2741    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2742    if test "$HAVE_LIBSELINUX" = yes; then
2743       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2744       LIBSELINUX_LIBS=-lselinux
2745    fi
2746 fi
2747 AC_SUBST(LIBSELINUX_LIBS)
2748
2749 HAVE_GNUTLS=no
2750 if test "${with_gnutls}" = "yes" ; then
2751   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2752     [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2753   if test "${HAVE_GNUTLS}" = "yes"; then
2754     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2755     EMACS_CHECK_MODULES([LIBGNUTLS3], [gnutls >= 3.0.0],
2756       [AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])], [])
2757   fi
2758
2759   # Windows loads GnuTLS dynamically
2760   if test "${opsys}" = "mingw32"; then
2761     LIBGNUTLS_LIBS=
2762   fi
2763 fi
2764
2765 AC_SUBST(LIBGNUTLS_LIBS)
2766 AC_SUBST(LIBGNUTLS_CFLAGS)
2767
2768 HAVE_LIBSYSTEMD=no
2769 if test "${with_libsystemd}" = "yes" ; then
2770   dnl This code has been tested with libsystemd 222 and later.
2771   dnl FIXME: Find the earliest version number for which Emacs should work,
2772   dnl and change '222' to that number.
2773   EMACS_CHECK_MODULES([LIBSYSTEMD], [libsystemd >= 222],
2774     [HAVE_LIBSYSTEMD=yes], [HAVE_LIBSYSTEMD=no])
2775   if test "${HAVE_LIBSYSTEMD}" = "yes"; then
2776     AC_DEFINE(HAVE_LIBSYSTEMD, 1, [Define if using libsystemd.])
2777   fi
2778 fi
2779
2780 AC_SUBST(LIBSYSTEMD_LIBS)
2781 AC_SUBST(LIBSYSTEMD_CFLAGS)
2782
2783 NOTIFY_OBJ=
2784 NOTIFY_SUMMARY=no
2785
2786 dnl MS Windows native file monitor is available for mingw32 only.
2787 case $with_file_notification,$opsys in
2788   w32,cygwin)
2789     AC_MSG_ERROR(['--with-file-notification=w32' was specified, but
2790     this is only supported on MS-Windows native and MinGW32 builds.
2791     Consider using gfile instead.])
2792     ;;
2793   w32,* | yes,mingw32)
2794     AC_CHECK_HEADER(windows.h)
2795     if test "$ac_cv_header_windows_h" = yes ; then
2796        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2797        NOTIFY_OBJ=w32notify.o
2798        NOTIFY_SUMMARY="yes (w32)"
2799     fi ;;
2800 esac
2801
2802 dnl inotify is available only on GNU/Linux.
2803 case $with_file_notification,$NOTIFY_OBJ in
2804   inotify, | yes,)
2805     AC_CHECK_HEADER(sys/inotify.h)
2806     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2807         AC_CHECK_FUNC(inotify_init1)
2808         if test "$ac_cv_func_inotify_init1" = yes; then
2809           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2810           NOTIFY_OBJ=inotify.o
2811           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2812        fi
2813     fi ;;
2814 esac
2815
2816 dnl kqueue is available on BSD-like systems.
2817 case $with_file_notification,$NOTIFY_OBJ in
2818   kqueue,* | yes,)
2819     EMACS_CHECK_MODULES([KQUEUE], [libkqueue])
2820     if test "$HAVE_KQUEUE" = "yes"; then
2821        AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2822        CPPFLAGS="$CPPFLAGS -I/usr/include/kqueue"
2823        NOTIFY_CFLAGS=$KQUEUE_CFLAGS
2824        NOTIFY_LIBS=$KQUEUE_LIBS
2825        NOTIFY_OBJ=kqueue.o
2826        NOTIFY_SUMMARY="yes -lkqueue"
2827     else
2828        AC_SEARCH_LIBS(kqueue, [])
2829        if test "$ac_cv_search_kqueue" != no; then
2830          AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2831          NOTIFY_OBJ=kqueue.o
2832          NOTIFY_SUMMARY="yes (kqueue)"
2833        fi
2834     fi ;;
2835 esac
2836
2837 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2838 dnl has been added in glib 2.24.  It has been tested under
2839 dnl GNU/Linux only.
2840 case $with_file_notification,$NOTIFY_OBJ in
2841   gfile,* | yes,)
2842     if test "${HAVE_NS}" = yes; then
2843        AC_MSG_ERROR(['--with-file-notification=gfile' is not supported in NextStep builds.
2844 Consider kqueue instead.])
2845     else
2846        EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2847        if test "$HAVE_GFILENOTIFY" = "yes"; then
2848           AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2849           NOTIFY_CFLAGS=$GFILENOTIFY_CFLAGS
2850           NOTIFY_LIBS=$GFILENOTIFY_LIBS
2851           NOTIFY_OBJ=gfilenotify.o
2852           NOTIFY_SUMMARY="yes -lgio (gfile)"
2853        fi
2854     fi ;;
2855 esac
2856
2857 case $with_file_notification,$NOTIFY_OBJ in
2858   yes,* | no,* | *,?*) ;;
2859   *) AC_MSG_ERROR([File notification '$with_file_notification' requested but requirements not found.]) ;;
2860 esac
2861
2862 if test -n "$NOTIFY_OBJ"; then
2863    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2864 fi
2865 AC_SUBST(NOTIFY_CFLAGS)
2866 AC_SUBST(NOTIFY_LIBS)
2867 AC_SUBST(NOTIFY_OBJ)
2868
2869 dnl Do not put whitespace before the #include statements below.
2870 dnl Older compilers (eg sunos4 cc) choke on it.
2871 HAVE_XAW3D=no
2872 LUCID_LIBW=
2873 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2874   if test "$with_xaw3d" != no; then
2875     AC_CACHE_VAL(emacs_cv_xaw3d,
2876     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2877 #include <X11/Intrinsic.h>
2878 #include <X11/Xaw3d/Simple.h>]],
2879       [[]])],
2880       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2881                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2882       emacs_cv_xaw3d=no)])
2883   else
2884     emacs_cv_xaw3d=no
2885   fi
2886   if test $emacs_cv_xaw3d = yes; then
2887     AC_MSG_CHECKING(for xaw3d)
2888     AC_MSG_RESULT([yes; using Lucid toolkit])
2889     USE_X_TOOLKIT=LUCID
2890     HAVE_XAW3D=yes
2891     LUCID_LIBW=-lXaw3d
2892     AC_DEFINE(HAVE_XAW3D, 1,
2893               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2894   else
2895     AC_MSG_CHECKING(for xaw3d)
2896     AC_MSG_RESULT(no)
2897     AC_MSG_CHECKING(for libXaw)
2898     AC_CACHE_VAL(emacs_cv_xaw,
2899     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2900 #include <X11/Intrinsic.h>
2901 #include <X11/Xaw/Simple.h>]],
2902       [[]])],
2903       emacs_cv_xaw=yes,
2904       emacs_cv_xaw=no)])
2905     if test $emacs_cv_xaw = yes; then
2906       AC_MSG_RESULT([yes; using Lucid toolkit])
2907       USE_X_TOOLKIT=LUCID
2908       LUCID_LIBW=-lXaw
2909     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2910       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2911     else
2912       AC_MSG_ERROR([No X toolkit could be found.
2913 If you are sure you want Emacs compiled without an X toolkit, pass
2914   --with-x-toolkit=no
2915 to configure.  Otherwise, install the development libraries for the toolkit
2916 that you want to use (e.g. Gtk+) and re-run configure.])
2917     fi
2918   fi
2919 fi
2920
2921 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2922
2923 LIBXTR6=
2924 LIBXMU=
2925 if test "${USE_X_TOOLKIT}" != "none"; then
2926   AC_MSG_CHECKING(X11 toolkit version)
2927   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2928   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2929 [[#if XtSpecificationRelease < 6
2930 fail;
2931 #endif
2932 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2933   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2934   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2935     AC_MSG_RESULT(6 or newer)
2936     AC_DEFINE(HAVE_X11XTR6, 1,
2937               [Define to 1 if you have the X11R6 or newer version of Xt.])
2938     LIBXTR6="-lSM -lICE"
2939     case "$opsys" in
2940       ## Use libw.a along with X11R6 Xt.
2941       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2942     esac
2943   else
2944     AC_MSG_RESULT(before 6)
2945   fi
2946
2947 dnl If using toolkit, check whether libXmu.a exists.
2948 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2949   OLDLIBS="$LIBS"
2950   if test x$HAVE_X11XTR6 = xyes; then
2951     OTHERLIBS='-lXt -lSM -lICE'
2952   else
2953     OTHERLIBS='-lXt'
2954   fi
2955   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2956   if test "X$LIBS" != "X$OLDLIBS"; then
2957     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2958   fi
2959   LIBS=$OLDLIBS
2960   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2961 fi
2962 AC_SUBST(LIBXTR6)
2963 AC_SUBST(LIBXMU)
2964
2965 LIBXP=
2966 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2967   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2968   if test -d /usr/include/openmotif; then
2969     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2970     emacs_cv_openmotif=yes
2971     case "$canonical" in
2972       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2973       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2974       ;;
2975       *)
2976       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2977     esac
2978   else
2979     emacs_cv_openmotif=no
2980   fi
2981   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2982   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2983     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2984 int x = 5;
2985 #else
2986 Motif version prior to 2.1.
2987 #endif]])],
2988     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2989   if test $emacs_cv_motif_version_2_1 = yes; then
2990     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2991     if test x$emacs_cv_openmotif = xyes; then
2992       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2993     fi
2994   else
2995     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2996     # We put this in CFLAGS temporarily to precede other -I options
2997     # that might be in CFLAGS temporarily.
2998     # We put this in CPPFLAGS where it precedes the other -I options.
2999     OLD_CPPFLAGS=$CPPFLAGS
3000     OLD_CFLAGS=$CFLAGS
3001     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
3002     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
3003     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
3004       [[int x = 5;]])],
3005       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
3006     if test $emacs_cv_lesstif = yes; then
3007       # Make sure this -I option remains in CPPFLAGS after it is set
3008       # back to REAL_CPPFLAGS.
3009       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
3010       # have those other -I options anyway.  Ultimately, having this
3011       # directory ultimately in CPPFLAGS will be enough.
3012       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
3013       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
3014     else
3015       CFLAGS=$OLD_CFLAGS
3016       CPPFLAGS=$OLD_CPPFLAGS
3017     fi
3018   fi
3019   AC_CHECK_HEADER([Xm/BulletinB.h], [],
3020     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
3021 fi
3022
3023 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
3024 dnl using Motif or Xaw3d is available, and unless
3025 dnl --with-toolkit-scroll-bars=no was specified.
3026
3027 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
3028             [Define to 1 if we should use toolkit scroll bars.])dnl
3029 USE_TOOLKIT_SCROLL_BARS=no
3030 if test "${with_toolkit_scroll_bars}" != "no"; then
3031   if test "${USE_X_TOOLKIT}" != "none"; then
3032     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
3033       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3034       HAVE_XAW3D=no
3035       USE_TOOLKIT_SCROLL_BARS=yes
3036     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
3037       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3038       USE_TOOLKIT_SCROLL_BARS=yes
3039     fi
3040   elif test "${HAVE_GTK}" = "yes"; then
3041     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3042     USE_TOOLKIT_SCROLL_BARS=yes
3043   elif test "${HAVE_NS}" = "yes"; then
3044     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3045     USE_TOOLKIT_SCROLL_BARS=yes
3046   elif test "${HAVE_W32}" = "yes"; then
3047     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3048     USE_TOOLKIT_SCROLL_BARS=yes
3049   fi
3050 fi
3051
3052 dnl See if XIM is available.
3053 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3054           #include <X11/Xlib.h>
3055           #include <X11/Xresource.h>]],
3056          [[XIMProc  callback;]])],
3057          [HAVE_XIM=yes
3058          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
3059          HAVE_XIM=no)
3060
3061 dnl '--with-xim' now controls only the initial value of use_xim at run time.
3062
3063 if test "${with_xim}" != "no"; then
3064   AC_DEFINE(USE_XIM, 1,
3065             [Define to 1 if we should use XIM, if it is available.])
3066 fi
3067
3068
3069 if test "${HAVE_XIM}" != "no"; then
3070   late_CFLAGS=$CFLAGS
3071   if test "$GCC" = yes; then
3072     CFLAGS="$CFLAGS --pedantic-errors"
3073   fi
3074   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3075 #include <X11/Xlib.h>
3076 #include <X11/Xresource.h>]],
3077 [[Display *display;
3078 XrmDatabase db;
3079 char *res_name;
3080 char *res_class;
3081 XIMProc  callback;
3082 XPointer *client_data;
3083 #ifndef __GNUC__
3084 /* If we're not using GCC, it's probably not XFree86, and this is
3085    probably right, but we can't use something like --pedantic-errors.  */
3086 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
3087                                            char*, XIMProc, XPointer*);
3088 #endif
3089 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
3090    client_data);]])],
3091     [emacs_cv_arg6_star=yes])
3092   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
3093          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
3094 either XPointer or XPointer*.])dnl
3095   if test "$emacs_cv_arg6_star" = yes; then
3096     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
3097   else
3098     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
3099   fi
3100   CFLAGS=$late_CFLAGS
3101 fi
3102
3103 ### Start of font-backend (under any platform) section.
3104 # (nothing here yet -- this is a placeholder)
3105 ### End of font-backend (under any platform) section.
3106
3107 ### Start of font-backend (under X11) section.
3108 if test "${HAVE_X11}" = "yes"; then
3109     ## Use -lXft if available, unless '--with-xft=no'.
3110     HAVE_XFT=maybe
3111     if test "x${with_x}" = "xno"; then
3112       with_xft="no";
3113     fi
3114
3115     if test "$with_xft" != no; then
3116       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
3117       with_xft=$HAVE_FONTCONFIG
3118     fi
3119
3120     if test "x${with_xft}" != "xno"; then
3121
3122       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
3123       ## Because xftfont.c uses XRenderQueryExtension, we also
3124       ## need to link to -lXrender.
3125       HAVE_XRENDER=no
3126       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
3127       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
3128         OLD_CPPFLAGS="$CPPFLAGS"
3129         OLD_CFLAGS="$CFLAGS"
3130         OLD_LIBS="$LIBS"
3131         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
3132         CFLAGS="$CFLAGS $XFT_CFLAGS"
3133         XFT_LIBS="-lXrender $XFT_LIBS"
3134         LIBS="$XFT_LIBS $LIBS"
3135         AC_CHECK_HEADER(X11/Xft/Xft.h,
3136           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
3137           [[#include <X11/X.h>]])
3138
3139         if test "${HAVE_XFT}" = "yes"; then
3140           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
3141             AC_SUBST(XFT_LIBS)
3142           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
3143         fi                        # "${HAVE_XFT}" = "yes"
3144         CPPFLAGS=$OLD_CPPFLAGS
3145         CFLAGS=$OLD_CFLAGS
3146         LIBS=$OLD_LIBS
3147       fi                          # "$HAVE_XFT" != no
3148     fi                            # "x${with_xft}" != "xno"
3149
3150     ## We used to allow building with FreeType and without Xft.
3151     ## However, the ftx font backend driver is not in good shape.
3152     if test "$HAVE_XFT" != "yes"; then
3153        dnl For the "Does Emacs use" message at the end.
3154        HAVE_XFT=no
3155        HAVE_FREETYPE=no
3156     else
3157        dnl Strict linkers fail with
3158        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
3159        dnl if -lfreetype is not specified.
3160        dnl The following is needed to set FREETYPE_LIBS.
3161        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
3162
3163        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
3164     fi
3165
3166     HAVE_LIBOTF=no
3167     if test "${HAVE_FREETYPE}" = "yes"; then
3168       AC_DEFINE(HAVE_FREETYPE, 1,
3169                 [Define to 1 if using the freetype and fontconfig libraries.])
3170       if test "${with_libotf}" != "no"; then
3171         EMACS_CHECK_MODULES([LIBOTF], [libotf])
3172         if test "$HAVE_LIBOTF" = "yes"; then
3173           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
3174           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
3175                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
3176                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
3177           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
3178             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
3179                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
3180           fi
3181         fi
3182       fi
3183     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
3184     dnl Does the new font backend require it, or can it work without it?
3185     fi
3186
3187     HAVE_M17N_FLT=no
3188     if test "${HAVE_LIBOTF}" = yes; then
3189       if test "${with_m17n_flt}" != "no"; then
3190         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
3191         if test "$HAVE_M17N_FLT" = "yes"; then
3192           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
3193         fi
3194       fi
3195     fi
3196 else
3197     HAVE_XFT=no
3198     HAVE_FREETYPE=no
3199     HAVE_LIBOTF=no
3200     HAVE_M17N_FLT=no
3201 fi
3202
3203 ### End of font-backend (under X11) section.
3204
3205 AC_SUBST(FREETYPE_CFLAGS)
3206 AC_SUBST(FREETYPE_LIBS)
3207 AC_SUBST(FONTCONFIG_CFLAGS)
3208 AC_SUBST(FONTCONFIG_LIBS)
3209 AC_SUBST(LIBOTF_CFLAGS)
3210 AC_SUBST(LIBOTF_LIBS)
3211 AC_SUBST(M17N_FLT_CFLAGS)
3212 AC_SUBST(M17N_FLT_LIBS)
3213
3214 HAVE_CAIRO=no
3215 if test "${HAVE_X11}" = "yes"; then
3216   if test "${with_cairo}" != "no"; then
3217     CAIRO_REQUIRED=1.12.0
3218     CAIRO_MODULE="cairo >= $CAIRO_REQUIRED"
3219     EMACS_CHECK_MODULES(CAIRO, $CAIRO_MODULE)
3220     if test $HAVE_CAIRO = yes; then
3221       AC_DEFINE(USE_CAIRO, 1, [Define to 1 if using cairo.])
3222     else
3223       AC_MSG_ERROR([cairo requested but not found.])
3224     fi
3225
3226     CFLAGS="$CFLAGS $CAIRO_CFLAGS"
3227     LIBS="$LIBS $CAIRO_LIBS"
3228     AC_SUBST(CAIRO_CFLAGS)
3229     AC_SUBST(CAIRO_LIBS)
3230   fi
3231 fi
3232
3233 if test "${HAVE_X11}" = "yes"; then
3234   AC_CHECK_HEADER(X11/Xlib-xcb.h,
3235     AC_CHECK_LIB(xcb, xcb_translate_coordinates, HAVE_XCB=yes))
3236   if test "${HAVE_XCB}" = "yes"; then
3237     AC_CHECK_LIB(X11-xcb, XGetXCBConnection, HAVE_X11_XCB=yes)
3238     if test "${HAVE_X11_XCB}" = "yes"; then
3239       AC_DEFINE(USE_XCB, 1,
3240 [Define to 1 if you have the XCB library and X11-XCB library for mixed
3241    X11/XCB programming.])
3242       XCB_LIBS="-lX11-xcb -lxcb"
3243       AC_SUBST(XCB_LIBS)
3244     fi
3245   fi
3246 fi
3247
3248 ### Use -lXpm if available, unless '--with-xpm=no'.
3249 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
3250 ### The Cygwin-w32 build uses <noX/xpm.h> instead of <X11/xpm.h>, so
3251 ### we need to set LDFLAGS accordingly.
3252 HAVE_XPM=no
3253 LIBXPM=
3254 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3255   if test "${with_xpm}" != "no"; then
3256     SAVE_LDFLAGS="$LDFLAGS"
3257     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3258     AC_CHECK_HEADER(noX/xpm.h,
3259       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3260     if test "${HAVE_XPM}" = "yes"; then
3261       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3262       AC_EGREP_CPP(no_return_alloc_pixels,
3263       [#include "noX/xpm.h"
3264 #ifndef XpmReturnAllocPixels
3265 no_return_alloc_pixels
3266 #endif
3267       ], HAVE_XPM=no, HAVE_XPM=yes)
3268
3269       if test "${HAVE_XPM}" = "yes"; then
3270         AC_MSG_RESULT(yes)
3271       else
3272         AC_MSG_RESULT(no)
3273         LDFLAGS="$SAVE_LDFLAGS"
3274       fi
3275     fi
3276   fi
3277
3278   if test "${HAVE_XPM}" = "yes"; then
3279     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3280     LIBXPM=-lXpm
3281   fi
3282 fi
3283
3284 if test "${HAVE_X11}" = "yes"; then
3285   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3286   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3287
3288   if test "${with_xpm}" != "no"; then
3289     AC_CHECK_HEADER(X11/xpm.h,
3290       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3291     if test "${HAVE_XPM}" = "yes"; then
3292       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3293       AC_EGREP_CPP(no_return_alloc_pixels,
3294       [#include "X11/xpm.h"
3295 #ifndef XpmReturnAllocPixels
3296 no_return_alloc_pixels
3297 #endif
3298       ], HAVE_XPM=no, HAVE_XPM=yes)
3299
3300       if test "${HAVE_XPM}" = "yes"; then
3301         AC_MSG_RESULT(yes)
3302       else
3303         AC_MSG_RESULT(no)
3304       fi
3305     fi
3306   fi
3307
3308   if test "${HAVE_XPM}" = "yes"; then
3309     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3310     LIBXPM=-lXpm
3311   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3312     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3313     LIBXPM=-lXpm
3314   fi
3315 fi
3316
3317 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3318 ### slightly different requirements wrt image libraries (it doesn't
3319 ### use -lXpm because it loads the xpm shared library dynamically at
3320 ### run time).
3321 if test "${opsys}" = "mingw32"; then
3322   if test "${with_xpm}" != "no"; then
3323     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3324 #define FOR_MSW 1])
3325   fi
3326
3327   if test "${HAVE_XPM}" = "yes"; then
3328     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3329   fi
3330 fi
3331
3332 AC_SUBST(LIBXPM)
3333
3334 ### Use -ljpeg if available, unless '--with-jpeg=no'.
3335 HAVE_JPEG=no
3336 LIBJPEG=
3337 if test "${with_jpeg}" != "no"; then
3338   AC_CACHE_CHECK([for jpeglib 6b or later],
3339     [emacs_cv_jpeglib],
3340     [OLD_LIBS=$LIBS
3341      for emacs_cv_jpeglib in yes -ljpeg no; do
3342        case $emacs_cv_jpeglib in
3343          yes) ;;
3344          no) break;;
3345          *) LIBS="$LIBS $emacs_cv_jpeglib";;
3346        esac
3347        AC_LINK_IFELSE(
3348          [AC_LANG_PROGRAM(
3349             [[#undef HAVE_STDLIB_H /* Avoid config.h/jpeglib.h collision.  */
3350               #include <stdio.h> /* jpeglib.h needs FILE and size_t.  */
3351               #include <jpeglib.h>
3352               #include <jerror.h>
3353               char verify[JPEG_LIB_VERSION < 62 ? -1 : 1];
3354               struct jpeg_decompress_struct cinfo;
3355             ]],
3356             [[
3357               jpeg_create_decompress (&cinfo);
3358               WARNMS (&cinfo, JWRN_JPEG_EOF);
3359               jpeg_destroy_decompress (&cinfo);
3360             ]])],
3361          [emacs_link_ok=yes],
3362          [emacs_link_ok=no])
3363        LIBS=$OLD_LIBS
3364        test $emacs_link_ok = yes && break
3365      done])
3366   if test "$emacs_cv_jpeglib" != no; then
3367     HAVE_JPEG=yes
3368     AC_DEFINE([HAVE_JPEG], 1,
3369       [Define to 1 if you have the jpeg library (typically -ljpeg).])
3370     ### mingw32 doesn't use -ljpeg, since it loads the library
3371     ### dynamically when needed, and doesn't want a run-time
3372     ### dependency on the jpeglib DLL.
3373     test "$emacs_cv_jpeglib" != yes && test "${opsys}" != "mingw32" \
3374     && LIBJPEG=$emacs_cv_jpeglib
3375   fi
3376 fi
3377 AC_SUBST(LIBJPEG)
3378
3379 HAVE_ZLIB=no
3380 LIBZ=
3381 if test "${with_zlib}" != "no"; then
3382   OLIBS=$LIBS
3383   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3384   LIBS=$OLIBS
3385   case $ac_cv_search_inflateEnd in
3386     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3387   esac
3388 fi
3389 if test "${HAVE_ZLIB}" = "yes"; then
3390   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3391   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3392   if test "${opsys}" = "mingw32"; then
3393      LIBZ=
3394   fi
3395 fi
3396 AC_SUBST(LIBZ)
3397
3398 ### Dynamic modules support
3399 LIBMODULES=
3400 HAVE_MODULES=no
3401 MODULES_OBJ=
3402 MODULES_SUFFIX=
3403 if test "${with_modules}" != "no"; then
3404   case $opsys in
3405     gnu|gnu-linux)
3406       LIBMODULES="-ldl"
3407       MODULES_SUFFIX=".so"
3408       HAVE_MODULES=yes
3409       ;;
3410     cygwin|mingw32)
3411       MODULES_SUFFIX=".dll"
3412       HAVE_MODULES=yes
3413       ;;
3414     darwin)
3415       MODULES_SUFFIX=".so"
3416       HAVE_MODULES=yes
3417       ;;
3418     *)
3419       # BSD systems have dlopen in libc.
3420       AC_CHECK_FUNC([dlopen],
3421         [MODULES_SUFFIX=".so"
3422          HAVE_MODULES=yes])
3423       ;;
3424   esac
3425
3426   if test "${HAVE_MODULES}" = no; then
3427     AC_MSG_ERROR([Dynamic modules are not supported on your system])
3428   else
3429     SAVE_LIBS=$LIBS
3430     LIBS="$LIBS $LIBMODULES"
3431     AC_CHECK_FUNCS([dladdr dlfunc])
3432     LIBS=$SAVE_LIBS
3433   fi
3434 fi
3435
3436 if test "${HAVE_MODULES}" = yes; then
3437    MODULES_OBJ="dynlib.o emacs-module.o"
3438    AC_DEFINE(HAVE_MODULES, 1, [Define to 1 if dynamic modules are enabled])
3439    AC_DEFINE_UNQUOTED(MODULES_SUFFIX, "$MODULES_SUFFIX",
3440      [System extension for dynamic libraries])
3441 fi
3442 AC_SUBST(MODULES_OBJ)
3443 AC_SUBST(LIBMODULES)
3444
3445 ### Use -lpng if available, unless '--with-png=no'.
3446 HAVE_PNG=no
3447 LIBPNG=
3448 PNG_CFLAGS=
3449 if test "${NS_IMPL_COCOA}" = yes; then
3450   : # Nothing to do
3451 elif test "${with_png}" != no; then
3452   # mingw32 loads the library dynamically.
3453   if test "$opsys" = mingw32; then
3454     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3455   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3456     AC_MSG_CHECKING([for png])
3457     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3458     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3459       # libpng-config does not work; configure by hand.
3460       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3461       # in /usr/include/libpng.
3462       if test -r /usr/include/libpng/png.h &&
3463          test ! -r /usr/include/png.h; then
3464         png_cflags=-I/usr/include/libpng
3465       else
3466         png_cflags=
3467       fi
3468       png_libs='-lpng'
3469     }
3470     SAVE_CFLAGS=$CFLAGS
3471     SAVE_LIBS=$LIBS
3472     CFLAGS="$CFLAGS $png_cflags"
3473     LIBS="$png_libs -lz -lm $LIBS"
3474     AC_LINK_IFELSE(
3475       [AC_LANG_PROGRAM([[#include <png.h>]],
3476          [[return !png_get_channels (0, 0);]])],
3477       [HAVE_PNG=yes
3478        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3479        LIBPNG=$png_libs
3480        # $LIBPNG requires explicit -lz in some cases.
3481        # We don't know what those cases are, exactly, so play it safe and
3482        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3483        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3484          LIBPNG="$LIBPNG -lz"
3485        fi])
3486     CFLAGS=$SAVE_CFLAGS
3487     LIBS=$SAVE_LIBS
3488     AC_MSG_RESULT([$HAVE_PNG])
3489   fi
3490 fi
3491 if test $HAVE_PNG = yes; then
3492   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3493
3494   SAVE_CFLAGS=$CFLAGS
3495   CFLAGS="$CFLAGS $PNG_CFLAGS"
3496   AC_CHECK_DECL([png_longjmp],
3497     [],
3498     [AC_DEFINE([PNG_DEPSTRUCT], [],
3499        [Define to empty to suppress deprecation warnings when building
3500         with --enable-gcc-warnings and with libpng versions before 1.5,
3501         which lack png_longjmp.])],
3502     [[#include <png.h>
3503     ]])
3504   CFLAGS=$SAVE_CFLAGS
3505 fi
3506 AC_SUBST(LIBPNG)
3507 AC_SUBST(PNG_CFLAGS)
3508
3509 ### Use -ltiff if available, unless '--with-tiff=no'.
3510 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3511 HAVE_TIFF=no
3512 LIBTIFF=
3513 if test "${opsys}" = "mingw32"; then
3514   if test "${with_tiff}" != "no"; then
3515     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3516   fi
3517   if test "${HAVE_TIFF}" = "yes"; then
3518     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3519   fi
3520 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3521   if test "${with_tiff}" != "no"; then
3522     AC_CHECK_HEADER(tiffio.h,
3523       [tifflibs="-lz -lm"
3524       # At least one tiff package requires the jpeg library.
3525       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3526       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3527   fi
3528
3529   if test "${HAVE_TIFF}" = "yes"; then
3530     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3531     dnl FIXME -lz -lm, as per libpng?
3532     LIBTIFF=-ltiff
3533   fi
3534 fi
3535 AC_SUBST(LIBTIFF)
3536
3537 ### Use -lgif or -lungif if available, unless '--with-gif=no'.
3538 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3539 HAVE_GIF=no
3540 LIBGIF=
3541 if test "${opsys}" = "mingw32"; then
3542   if test "${with_gif}" != "no"; then
3543     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3544   fi
3545   if test "${HAVE_GIF}" = "yes"; then
3546     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3547   fi
3548 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3549         || test "${HAVE_W32}" = "yes"; then
3550   AC_CHECK_HEADER(gif_lib.h,
3551 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3552 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3553     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3554         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3555
3556   if test "$HAVE_GIF" = yes; then
3557     LIBGIF=-lgif
3558   elif test "$HAVE_GIF" = maybe; then
3559 # If gif_lib.h but no libgif, try libungif.
3560     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3561     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3562   fi
3563
3564   if test "${HAVE_GIF}" = "yes"; then
3565     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3566   fi
3567 fi
3568 AC_SUBST(LIBGIF)
3569
3570 dnl Check for required libraries.
3571 if test "${HAVE_X11}" = "yes"; then
3572   MISSING=""
3573   WITH_NO=""
3574   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3575     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3576   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3577     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3578   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3579     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3580   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3581     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3582   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3583     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3584
3585   if test "X${MISSING}" != X; then
3586     AC_MSG_ERROR([The following required libraries were not found:
3587     $MISSING
3588 Maybe some development libraries/packages are missing?
3589 If you don't want to link with them give
3590     $WITH_NO
3591 as options to configure])
3592   fi
3593 fi
3594
3595 ### Use -lgpm if available, unless '--with-gpm=no'.
3596 HAVE_GPM=no
3597 LIBGPM=
3598 if test "${with_gpm}" != "no"; then
3599   AC_CHECK_HEADER(gpm.h,
3600     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3601
3602   if test "${HAVE_GPM}" = "yes"; then
3603     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3604     LIBGPM=-lgpm
3605   fi
3606 fi
3607 AC_SUBST(LIBGPM)
3608
3609 dnl Check for malloc/malloc.h on darwin
3610 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3611
3612 GNUSTEP_CFLAGS=
3613 ### Use NeXTstep API to implement GUI.
3614 if test "${HAVE_NS}" = "yes"; then
3615   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3616   if test "${NS_IMPL_COCOA}" = "yes"; then
3617     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3618   fi
3619   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3620     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3621     if test $NS_GNUSTEP_CONFIG != yes; then
3622       # See also .m.o rule in src/Makefile.in.  */
3623       # FIXME: are all these flags really needed?  Document here why.  */
3624       GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3625       ## Extra CFLAGS applied to src/*.m files.
3626       GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3627     fi
3628   fi
3629   OTHER_FILES=ns-app
3630 fi
3631
3632 ### Use session management (-lSM -lICE) if available
3633 HAVE_X_SM=no
3634 LIBXSM=
3635 if test "${HAVE_X11}" = "yes"; then
3636   AC_CHECK_HEADER(X11/SM/SMlib.h,
3637     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3638
3639   if test "${HAVE_X_SM}" = "yes"; then
3640     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3641     LIBXSM="-lSM -lICE"
3642   fi
3643 fi
3644 AC_SUBST(LIBXSM)
3645
3646 ### Use XRandr (-lXrandr) if available
3647 HAVE_XRANDR=no
3648 if test "${HAVE_X11}" = "yes"; then
3649   XRANDR_REQUIRED=1.2.2
3650   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3651   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3652   if test $HAVE_XRANDR = no; then
3653     # Test old way in case pkg-config doesn't have it (older machines).
3654     # Include Xrender.h by hand to work around bug in older Xrandr.h
3655     # (e.g. RHEL5) and silence (harmless) configure warning (bug#18465).
3656     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3657       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)],
3658       [], [AC_INCLUDES_DEFAULT
3659 #include <X11/extensions/Xrender.h>])
3660     if test $HAVE_XRANDR = yes; then
3661       XRANDR_LIBS=-lXrandr
3662     fi
3663   fi
3664   if test $HAVE_XRANDR = yes; then
3665     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3666   fi
3667 fi
3668 AC_SUBST(XRANDR_CFLAGS)
3669 AC_SUBST(XRANDR_LIBS)
3670
3671 ### Use Xinerama (-lXinerama) if available
3672 HAVE_XINERAMA=no
3673 if test "${HAVE_X11}" = "yes"; then
3674   XINERAMA_REQUIRED=1.0.2
3675   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3676   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3677   if test $HAVE_XINERAMA = no; then
3678     # Test old way in case pkg-config doesn't have it (older machines).
3679     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3680       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3681     if test $HAVE_XINERAMA = yes; then
3682       XINERAMA_LIBS=-lXinerama
3683     fi
3684   fi
3685   if test $HAVE_XINERAMA = yes; then
3686     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3687   fi
3688 fi
3689 AC_SUBST(XINERAMA_CFLAGS)
3690 AC_SUBST(XINERAMA_LIBS)
3691
3692 ### Use Xfixes (-lXfixes) if available
3693 HAVE_XFIXES=no
3694 if test "${HAVE_X11}" = "yes"; then
3695   XFIXES_REQUIRED=4.0.0
3696   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3697   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3698   if test $HAVE_XFIXES = no; then
3699     # Test old way in case pkg-config doesn't have it (older machines).
3700     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3701       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3702     if test $HAVE_XFIXES = yes; then
3703       XFIXES_LIBS=-lXfixes
3704     fi
3705   fi
3706   if test $HAVE_XFIXES = yes; then
3707     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3708   fi
3709 fi
3710 AC_SUBST(XFIXES_CFLAGS)
3711 AC_SUBST(XFIXES_LIBS)
3712
3713 ### Use libxml (-lxml2) if available
3714 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3715 HAVE_LIBXML2=no
3716 if test "${with_xml2}" != "no"; then
3717   ### I'm not sure what the version number should be, so I just guessed.
3718   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3719   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3720   if test "${HAVE_LIBXML2}" != "yes" && test "$opsys" = "darwin"; then
3721     SAVE_CPPFLAGS="$CPPFLAGS"
3722     if test -z "$xcsdkdir" -a -n "$XCRUN" -a ! -d /usr/include; then
3723       dnl /usr/include is not found.  Try Xcode SDK dir if it is sane.
3724       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
3725       case $xcsdkdir in
3726         *[[\\\"\#\$\&\'\`$am_lf\ \      ]]*)
3727         xcsdkdir="" ;;
3728       esac
3729     fi
3730     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3731     AC_CHECK_HEADER(libxml/HTMLparser.h,
3732       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3733                      [#include <libxml/HTMLparser.h>])])
3734     CPPFLAGS="$SAVE_CPPFLAGS"
3735     if test "${HAVE_LIBXML2}" = "yes"; then
3736       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3737       LIBXML2_LIBS="-lxml2"
3738     fi
3739   fi
3740   if test "${HAVE_LIBXML2}" = "yes"; then
3741     if test "${opsys}" != "mingw32"; then
3742       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no,
3743         [$LIBXML2_LIBS])
3744     else
3745       LIBXML2_LIBS=""
3746     fi
3747     if test "${HAVE_LIBXML2}" = "yes"; then
3748       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3749     else
3750       LIBXML2_LIBS=""
3751       LIBXML2_CFLAGS=""
3752     fi
3753   fi
3754 fi
3755 AC_SUBST(LIBXML2_LIBS)
3756 AC_SUBST(LIBXML2_CFLAGS)
3757
3758 # Check for mail-locking functions in a "mail" library.  Probably this should
3759 # have the same check as for liblockfile below.
3760 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3761 if test $have_mail = yes; then
3762   LIBS_MAIL=-lmail
3763   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the 'mail' library (-lmail).])
3764
3765   OLD_LIBS=$LIBS
3766   LIBS="$LIBS_MAIL $LIBS"
3767   AC_CHECK_FUNCS(touchlock)
3768   LIBS=$OLD_LIBS
3769 else
3770   LIBS_MAIL=
3771 fi
3772 dnl Debian, at least:
3773 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3774 if test $have_lockfile = yes; then
3775    LIBS_MAIL=-llockfile
3776    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the 'lockfile' library (-llockfile).])
3777 else
3778 # If we have the shared liblockfile, assume we must use it for mail
3779 # locking (e.g. Debian).  If we couldn't link against liblockfile
3780 # (no liblockfile.a installed), ensure that we don't need to.
3781   dnl This works for files generally, not just executables.
3782   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3783   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3784                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3785   if test $ac_cv_prog_liblockfile = yes; then
3786     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3787 This probably means that movemail could lose mail.
3788 There may be a 'development' package to install containing liblockfile.])
3789   fi
3790 fi
3791 AC_CHECK_HEADERS_ONCE(maillock.h)
3792 AC_SUBST(LIBS_MAIL)
3793
3794 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3795 ## interlock access to the mail spool.  The alternative is a lock file named
3796 ## /usr/spool/mail/$USER.lock.
3797 mail_lock=no
3798 case "$opsys" in
3799   aix4-2) mail_lock="lockf" ;;
3800
3801   gnu|freebsd|dragonfly|netbsd|openbsd|darwin) mail_lock="flock" ;;
3802
3803   ## On GNU/Linux systems, both methods are used by various mail programs.
3804   ## I assume most people are using newer mailers that have heard of flock.
3805   ## Change this if you need to.
3806   ## Debian contains a patch which says: "On Debian/GNU/Linux systems,
3807   ## configure gets the right answers, and that means *NOT* using flock.
3808   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3809   ## for details." and then uses '#ifdef DEBIAN'.  Unfortunately the
3810   ## Debian maintainer hasn't provided a clean fix for Emacs.
3811   ## movemail.c will use 'maillock' when MAILDIR, HAVE_LIBMAIL and
3812   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3813   ## correct logic.  -- fx
3814   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3815   ## liblockfile is a Free Software replacement for libmail, used on
3816   ## Debian systems and elsewhere. -rfr.
3817   gnu-*)
3818     mail_lock="flock"
3819     if test $have_mail = yes || test $have_lockfile = yes; then
3820       test $ac_cv_header_maillock_h = yes && mail_lock=no
3821     fi
3822     ;;
3823
3824   mingw32)
3825     mail_lock="none-needed" ;;
3826 esac
3827
3828 BLESSMAIL_TARGET=
3829 case "$mail_lock" in
3830   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3831
3832   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3833
3834   none-needed) ;;
3835
3836   *) BLESSMAIL_TARGET="need-blessmail" ;;
3837 esac
3838 AC_SUBST(BLESSMAIL_TARGET)
3839
3840 OLD_LIBS=$LIBS
3841 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3842 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3843 getrusage get_current_dir_name \
3844 lrand48 random rint \
3845 select getpagesize setlocale newlocale \
3846 getrlimit setrlimit shutdown \
3847 pthread_sigmask strsignal setitimer \
3848 sendto recvfrom getsockname getifaddrs freeifaddrs \
3849 gai_strerror sync \
3850 getpwent endpwent getgrent endgrent \
3851 cfmakeraw cfsetspeed copysign __executable_start log2)
3852 LIBS=$OLD_LIBS
3853
3854 dnl No need to check for posix_memalign if aligned_alloc works.
3855 AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3856 AC_CHECK_DECLS([aligned_alloc], [], [], [[#include <stdlib.h>]])
3857
3858 dnl Cannot use AC_CHECK_FUNCS
3859 AC_CACHE_CHECK([for __builtin_unwind_init],
3860                emacs_cv_func___builtin_unwind_init,
3861 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3862                 emacs_cv_func___builtin_unwind_init=yes,
3863                 emacs_cv_func___builtin_unwind_init=no)])
3864 if test $emacs_cv_func___builtin_unwind_init = yes; then
3865   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3866             [Define to 1 if you have the '__builtin_unwind_init' function.])
3867 fi
3868
3869 AC_CHECK_HEADERS_ONCE(sys/un.h)
3870
3871 AC_FUNC_FSEEKO
3872
3873 # UNIX98 PTYs.
3874 AC_CHECK_FUNCS(grantpt)
3875
3876 # PTY-related GNU extensions.
3877 AC_CHECK_FUNCS(getpt posix_openpt)
3878
3879 # Check this now, so that we will NOT find the above functions in ncurses.
3880 # That is because we have not set up to link ncurses in lib-src.
3881 # It's better to believe a function is not available
3882 # than to expect to find it in ncurses.
3883 # Also we need tputs and friends to be able to build at all.
3884 AC_MSG_CHECKING([for library containing tputs])
3885 # Run a test program that contains a call to tputs, a call that is
3886 # never executed.  This tests whether a pre-'main' dynamic linker
3887 # works with the library.  It's too much trouble to actually call
3888 # tputs in the test program, due to portability hassles.  When
3889 # cross-compiling, assume the test program will run if it links.
3890 AC_DEFUN([tputs_link_source], [
3891   AC_LANG_SOURCE(
3892      [[extern void tputs (const char *, int, int (*)(int));
3893        int main (int argc, char **argv)
3894        {
3895           if (argc == 10000)
3896             tputs (argv[0], 0, 0);
3897           return 0;
3898        }]])
3899 ])
3900 if test "${opsys}" = "mingw32"; then
3901   msg='none required'
3902 else
3903   # Maybe curses should be tried earlier?
3904   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3905   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3906     OLIBS=$LIBS
3907     if test -z "$tputs_library"; then
3908       LIBS_TERMCAP=
3909       msg='none required'
3910     else
3911       LIBS_TERMCAP=-l$tputs_library
3912       msg=$LIBS_TERMCAP
3913       LIBS="$LIBS_TERMCAP $LIBS"
3914     fi
3915     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3916       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3917     LIBS=$OLIBS
3918     if test "X$msg" != Xno; then
3919       break
3920     fi
3921   done
3922 fi
3923 AC_MSG_RESULT([$msg])
3924 if test "X$msg" = Xno; then
3925   AC_MSG_ERROR([The required function 'tputs' was not found in any library.
3926 The following libraries were tried (in order):
3927   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3928 Please try installing whichever of these libraries is most appropriate
3929 for your system, together with its header files.
3930 For example, a libncurses-dev(el) or similar package.])
3931 fi
3932
3933 ## Use termcap instead of terminfo?
3934 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3935 TERMINFO=yes
3936 ## FIXME?  In the cases below where we unconditionally set
3937 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3938 ## if that was found above to have tputs.
3939 ## Should we use the gnu* logic everywhere?
3940 case "$opsys" in
3941   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3942   ##  The ncurses library has been moved out of the System framework in
3943   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3944   ##  option to use it.
3945   darwin) LIBS_TERMCAP="-lncurses" ;;
3946
3947   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3948
3949   freebsd)
3950     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3951     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3952     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3953 [[#if __FreeBSD_version < 400000
3954 fail;
3955 #endif
3956 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3957
3958     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3959
3960     if test $emacs_cv_freebsd_terminfo = yes; then
3961       LIBS_TERMCAP="-lncurses"
3962     else
3963       TERMINFO=no
3964       LIBS_TERMCAP="-ltermcap"
3965     fi
3966     ;;
3967
3968   mingw32)
3969     TERMINFO=no
3970     LIBS_TERMCAP=
3971     ;;
3972
3973   netbsd)
3974     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3975       TERMINFO=no
3976       LIBS_TERMCAP="-ltermcap"
3977     fi
3978     ;;
3979
3980   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3981
3982   ## hpux: Make sure we get select from libc rather than from libcurses
3983   ##  because libcurses on HPUX 10.10 has a broken version of select.
3984   ##  We used to use -lc -lcurses, but this may be cleaner.
3985   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3986   # set that way, now it uses the default).  Isn't this a contradiction?
3987   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3988
3989 esac
3990
3991 TERMCAP_OBJ=tparam.o
3992 if test $TERMINFO = yes; then
3993   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3994   TERMCAP_OBJ=terminfo.o
3995 fi
3996 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3997   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3998 fi
3999 AC_SUBST(LIBS_TERMCAP)
4000 AC_SUBST(TERMCAP_OBJ)
4001
4002 # GNU/Linux-specific timer functions.
4003 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
4004   [AC_COMPILE_IFELSE(
4005      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
4006                       ]],
4007                       [[timerfd_create (CLOCK_REALTIME,
4008                                         TFD_CLOEXEC | TFD_NONBLOCK);
4009                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
4010      [emacs_cv_have_timerfd=yes],
4011      [emacs_cv_have_timerfd=no])])
4012 if test "$emacs_cv_have_timerfd" = yes; then
4013   AC_DEFINE([HAVE_TIMERFD], 1,
4014     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
4015 fi
4016
4017 # Alternate stack for signal handlers.
4018 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
4019                [emacs_cv_alternate_stack],
4020   [AC_COMPILE_IFELSE(
4021      [AC_LANG_PROGRAM([[#include <signal.h>
4022                       ]],
4023                       [[stack_t ss;
4024                         struct sigaction sa;
4025                         ss.ss_sp = malloc (SIGSTKSZ);
4026                         ss.ss_size = SIGSTKSZ;
4027                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
4028                         sigaltstack (&ss, 0);
4029                         sigaction (SIGSEGV, &sa, 0);]])],
4030      [emacs_cv_alternate_stack=yes],
4031      [emacs_cv_alternate_stack=no])])
4032
4033 # Do we need the Hesiod library to provide the support routines?
4034 dnl FIXME?  Should we be skipping this on Darwin too?
4035 LIBHESIOD=
4036 LIBRESOLV=
4037 if test "$with_hesiod" != no ; then
4038   # Don't set $LIBS here -- see comments above.  FIXME which comments?
4039   resolv=no
4040   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
4041      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
4042                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
4043   if test "$resolv" = yes ; then
4044     RESOLVLIB=-lresolv
4045   else
4046     RESOLVLIB=
4047   fi
4048   hesiod=no
4049   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
4050         hesiod=yes, :, $RESOLVLIB)])
4051
4052   if test x"$hesiod" = xyes; then
4053     LIBHESIOD=-lhesiod
4054     LIBRESOLV=$RESOLVLIB
4055   fi
4056 fi
4057 AC_SUBST(LIBHESIOD)
4058 AC_SUBST(LIBRESOLV)
4059
4060 # These tell us which Kerberos-related libraries to use.
4061 COM_ERRLIB=
4062 CRYPTOLIB=
4063 KRB5LIB=
4064 DESLIB=
4065 KRB4LIB=
4066
4067 if test "${with_kerberos}" != no; then
4068   OLD_LIBS=$LIBS
4069   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
4070   if test $have_com_err = yes; then
4071     COM_ERRLIB=-lcom_err
4072     LIBS="$COM_ERRLIB $LIBS"
4073   fi
4074   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
4075   if test $have_crypto = yes; then
4076     CRYPTOLIB=-lcrypto
4077     LIBS="$CRYPTOLIB $LIBS"
4078   fi
4079   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
4080   if test $have_k5crypto = yes; then
4081     CRYPTOLIB=-lk5crypto
4082     LIBS="$CRYPTOLIB $LIBS"
4083   fi
4084   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
4085   if test $have_krb5=yes; then
4086     KRB5LIB=-lkrb5
4087     LIBS="$KRB5LIB $LIBS"
4088   fi
4089   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
4090   if test "${with_kerberos5}" = no; then
4091     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
4092     if test $have_des425 = yes; then
4093       DESLIB=-ldes425
4094       LIBS="$DESLIB $LIBS"
4095     else
4096       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
4097       if test $have_des = yes; then
4098         DESLIB=-ldes
4099         LIBS="$DESLIB $LIBS"
4100       fi
4101     fi
4102     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
4103     if test $have_krb4 = yes; then
4104       KRB4LIB=-lkrb4
4105       LIBS="$KRB4LIB $LIBS"
4106     else
4107       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
4108       if test $have_krb = yes; then
4109         KRB4LIB=-lkrb
4110         LIBS="$KRB4LIB $LIBS"
4111       fi
4112     fi
4113   fi
4114
4115   if test "${with_kerberos5}" != no; then
4116     AC_CHECK_HEADERS(krb5.h,
4117       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
4118                         [#include <krb5.h>])])
4119   else
4120     AC_CHECK_HEADERS(krb.h,,
4121                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
4122                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
4123   fi
4124   AC_CHECK_HEADERS(com_err.h)
4125   LIBS=$OLD_LIBS
4126 fi
4127
4128 AC_SUBST(COM_ERRLIB)
4129 AC_SUBST(CRYPTOLIB)
4130 AC_SUBST(KRB5LIB)
4131 AC_SUBST(DESLIB)
4132 AC_SUBST(KRB4LIB)
4133
4134 AC_CHECK_HEADERS(valgrind/valgrind.h)
4135
4136 AC_CHECK_MEMBERS([struct unipair.unicode], [], [], [[#include <linux/kd.h>]])
4137
4138 AC_CHECK_FUNCS_ONCE(tzset)
4139
4140 ok_so_far=yes
4141 AC_CHECK_FUNC(socket, , ok_so_far=no)
4142 if test $ok_so_far = yes; then
4143   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
4144 fi
4145 if test $ok_so_far = yes; then
4146   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
4147 fi
4148 if test $ok_so_far = yes; then
4149 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
4150   AC_DEFINE(HAVE_INET_SOCKETS, 1,
4151             [Define to 1 if you have inet sockets.])
4152 fi
4153
4154 AC_FUNC_FORK
4155
4156 AC_CHECK_FUNCS(snprintf)
4157
4158 dnl Check for glib.  This differs from other library checks in that
4159 dnl Emacs need not link to glib unless some other library is already
4160 dnl linking to glib.  Although glib provides no facilities that Emacs
4161 dnl needs for its own purposes, when glib is present Emacs needs to
4162 dnl use primitives like g_main_context_query to avoid clashing with
4163 dnl glib at a low level.
4164 dnl
4165 dnl Check this late, since it depends on $GTK_CFLAGS etc.
4166 XGSELOBJ=
4167 OLDCFLAGS="$CFLAGS"
4168 OLDLIBS="$LIBS"
4169 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
4170 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
4171 CFLAGS="$CFLAGS $NOTIFY_CFLAGS $CAIRO_CFLAGS"
4172 LIBS="$LIBS $NOTIFY_LIBS $CAIRO_LIBS"
4173 AC_MSG_CHECKING([whether GLib is linked in])
4174 AC_LINK_IFELSE([AC_LANG_PROGRAM(
4175         [[#include <glib.h>
4176         ]],
4177         [[g_print ("Hello world");]])],
4178      [links_glib=yes],
4179      [links_glib=no])
4180 AC_MSG_RESULT([$links_glib])
4181 if test "${links_glib}" = "yes"; then
4182   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
4183   if test "$HAVE_NS" = no;then
4184     XGSELOBJ=xgselect.o
4185   fi
4186 fi
4187 CFLAGS="$OLDCFLAGS"
4188 LIBS="$OLDLIBS"
4189 AC_SUBST(XGSELOBJ)
4190
4191 dnl Adapted from Haible's version.
4192 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
4193   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
4194     [[char* cs = nl_langinfo(CODESET);]])],
4195     emacs_cv_langinfo_codeset=yes,
4196     emacs_cv_langinfo_codeset=no)
4197   ])
4198 if test $emacs_cv_langinfo_codeset = yes; then
4199   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
4200     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
4201 fi
4202
4203 AC_TYPE_MBSTATE_T
4204
4205 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
4206 dnl how the tty code is related to POSIX and/or other versions of termios.
4207 dnl The following looks like a useful start.
4208 dnl
4209 dnl AC_SYS_POSIX_TERMIOS
4210 dnl if test $ac_cv_sys_posix_termios = yes; then
4211 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
4212 dnl                                and macros for terminal control.])
4213 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
4214 dnl fi
4215
4216 dnl Turned on June 1996 supposing nobody will mind it.
4217 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
4218 if test "${opsys}" != "mingw32"; then
4219    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
4220      in the full name stands for the login id.])
4221 fi
4222
4223 dnl Everybody supports this, except MS.
4224 dnl Seems like the kind of thing we should be testing for, though.
4225 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4226 if test "${opsys}" != "mingw32"; then
4227   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4228 fi
4229
4230 dnl Everybody supports this, except MS-DOS.
4231 dnl Seems like the kind of thing we should be testing for, though.
4232 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4233 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4234   4.2-compatible sockets.])
4235
4236 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4237
4238 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4239   a null file, or a data sink.])
4240 if test "${opsys}" = "mingw32"; then
4241   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4242 else
4243   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4244 fi
4245
4246 if test "${opsys}" = "mingw32"; then
4247   SEPCHAR=';'
4248 else
4249   SEPCHAR=':'
4250 fi
4251 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4252 dnl This is for MinGW, and is used in test/Makefile.in.
4253 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4254 dnl decides that a command-line argument to be passed to a MinGW program
4255 dnl is a PATH-style list of directories.  But that heuristics plays it
4256 dnl safe, and only does the replacement when it is _absolutely_ sure it
4257 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4258 dnl which breaks in-tree builds.  So we do this manually instead.
4259 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4260 dnl be computed as ':' in MSYS Bash.
4261 AC_SUBST(SEPCHAR)
4262
4263 dnl Everybody supports this, except MS-DOS.
4264 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4265
4266 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4267
4268
4269 AC_DEFINE(DIRECTORY_SEP, ['/'],
4270   [Character that separates directories in a file name.])
4271
4272 if test "${opsys}" = "mingw32"; then
4273   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4274     [Returns true if character is a device separator.])
4275
4276   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4277     [Returns true if character is a directory separator.])
4278
4279   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4280     [Returns true if character is any form of separator.])
4281 else
4282   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4283     [Returns true if character is a device separator.])
4284
4285   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4286     [Returns true if character is a directory separator.])
4287
4288   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4289     [Returns true if character is any form of separator.])
4290 fi
4291
4292 if test "$USE_X_TOOLKIT" != "none"; then
4293   have_editres=yes
4294   case $opsys in
4295     hpux*)
4296       dnl Assar Westerlund <assar@sics.se> says this is necessary
4297       dnl for HP-UX 10.20, and that it works for HP-UX 0 as well.
4298       have_editres=no
4299     ;;
4300   esac
4301   if test "$have_editres" != no && test ! -z "$LIBXMU"; then
4302     OLDLIBS="$LIBS"
4303     dnl See libXmu.a check above.
4304     if test x$HAVE_X11XTR6 = xyes; then
4305       LIBS="-lXt -lSM -lICE $LIBXMU"
4306     else
4307       OTHERLIBS="-lXt -$LIBXMU"
4308     fi
4309     AC_TRY_LINK(
4310       [#include <X11/Intrinsic.h>
4311        #include <X11/Xmu/Editres.h>],
4312       [_XEditResCheckMessages (0, 0, 0, 0);],
4313       [AC_DEFINE([X_TOOLKIT_EDITRES], 1,
4314         [Define to 1 if we should use XEditRes.])])
4315     LIBS=$OLDLIBS
4316   fi
4317 fi
4318
4319 case $opsys in
4320   sol2* | unixware )
4321     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4322     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4323     dnl need the constant to dimension an array.  So wire in the appropriate
4324     dnl value here.
4325     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4326     ;;
4327 esac
4328
4329 emacs_broken_SIGIO=no
4330
4331 case $opsys in
4332   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4333   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4334   hpux* | nacl | openbsd | sol2* | unixware )
4335     emacs_broken_SIGIO=yes
4336     ;;
4337
4338   aix4-2)
4339     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4340     dnl the way this system works, libc functions that return malloced
4341     dnl memory use the libc malloc implementation. Calling xfree or
4342     dnl xrealloc on the results of such functions results in a crash.
4343     dnl
4344     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4345     dnl but that does not currently work on this system.
4346     dnl
4347     dnl It is possible to completely override the malloc implementation on
4348     dnl AIX, but that involves putting the malloc functions in a shared
4349     dnl library and setting the MALLOCTYPE environment variable to point to
4350     dnl that shared library.
4351     dnl
4352     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4353     dnl to avoid a crash just use the Emacs implementation for that function.
4354     dnl
4355     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4356     dnl of this file, so that we do not check for get_current_dir_name
4357     dnl on AIX.  But that might be fragile if something else ends
4358     dnl up testing for get_current_dir_name as a dependency.
4359     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4360       get_current_dir_name should not be used.])
4361     ;;
4362
4363   freebsd)
4364     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4365     dnl writes/reads on a PTY, read(2) returns bogus data:
4366     dnl
4367     dnl write(2)  1022 bytes
4368     dnl write(2)   954 bytes, get EAGAIN
4369     dnl read(2)   1024 bytes in process_read_output
4370     dnl read(2)     11 bytes in process_read_output
4371     dnl
4372     dnl That is, read(2) returns more bytes than have ever been written
4373     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4374     dnl successfully after processing (for example with CRs added if the
4375     dnl terminal is set up that way which it is here).  The same bytes will
4376     dnl be seen again in a later read(2), without the CRs.
4377     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4378       work around an issue when reading from a PTY.])
4379     ;;
4380 esac
4381
4382 case $opsys in
4383   gnu-* | sol2-10 )
4384     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4385     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4386   ;;
4387 esac
4388
4389 case $opsys in
4390   darwin | dragonfly | freebsd | netbsd | openbsd )
4391     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4392       close a pty to make it a controlling terminal (it is already a
4393       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4394   ;;
4395 esac
4396
4397 dnl FIXME Surely we can test for this rather than hard-code it.
4398 case $opsys in
4399   netbsd | openbsd) sound_device="/dev/audio" ;;
4400   *) sound_device="/dev/dsp" ;;
4401 esac
4402
4403 dnl Used in sound.c
4404 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4405   [Name of the default sound device.])
4406
4407
4408 dnl Emacs can read input using SIGIO and buffering characters itself,
4409 dnl or using CBREAK mode and making C-g cause SIGINT.
4410 dnl The choice is controlled by the variable interrupt_input.
4411 dnl
4412 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4413 dnl
4414 dnl Emacs uses the presence of the USABLE_SIGIO macro
4415 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4416 dnl INTERRUPT_INPUT to decide whether to use it by default.
4417 dnl
4418 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4419 dnl CBREAK mode has two disadvantages
4420 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4421 dnl I hear that in system V this problem does not exist.
4422 dnl 2) Control-G causes output to be discarded.
4423 dnl I do not know whether this can be fixed in system V.
4424 dnl
4425 dnl Another method of doing input is planned but not implemented.
4426 dnl It would have Emacs fork off a separate process
4427 dnl to read the input and send it to the true Emacs process
4428 dnl through a pipe.
4429 case $opsys in
4430   darwin | gnu-linux | gnu-kfreebsd )
4431     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4432   ;;
4433 esac
4434
4435
4436 dnl If the system's imake configuration file defines 'NeedWidePrototypes'
4437 dnl as 'NO', we must define NARROWPROTO manually.  Such a define is
4438 dnl generated in the Makefile generated by 'xmkmf'.  If we don't define
4439 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4440 dnl taking float or double parameters.
4441 case $opsys in
4442   cygwin|gnu|gnu-linux|gnu-kfreebsd|freebsd|netbsd|openbsd)
4443     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4444       file defines 'NeedWidePrototypes' as 'NO'.])
4445   ;;
4446 esac
4447
4448
4449 dnl Used in process.c, this must be a loop, even if it only runs once.
4450 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4451 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4452 dnl trying suffixes 0-16.
4453 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4454   first PTY, if PTYs are supported.])
4455 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4456 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4457   end of a PTY, if non-standard.])
4458 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4459   end of a PTY, if non-standard.])
4460
4461 case $opsys in
4462   aix4-2 )
4463     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4464     dnl You allocate a pty by opening /dev/ptc to get the master side.
4465     dnl To get the name of the slave side, you just ttyname() the master side.
4466     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4467     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4468     ;;
4469
4470   cygwin )
4471     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4472     dnl multi-line AC_DEFINEs are hard. :(
4473     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4474     AC_DEFINE(PTY_NAME_SPRINTF, [])
4475     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4476     ;;
4477
4478   gnu | openbsd )
4479     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4480     ;;
4481
4482   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd | darwin | nacl )
4483     dnl if HAVE_GRANTPT
4484     if test "x$ac_cv_func_grantpt" = xyes; then
4485       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4486       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4487       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4488       dnl to prevent sigchld_handler from intercepting the child's death.
4489       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4490       dnl if HAVE_POSIX_OPENPT
4491       if test "x$ac_cv_func_posix_openpt" = xyes; then
4492         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4493         AC_DEFINE(PTY_NAME_SPRINTF, [])
4494       dnl if HAVE_GETPT
4495       elif test "x$ac_cv_func_getpt" = xyes; then
4496         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4497         AC_DEFINE(PTY_NAME_SPRINTF, [])
4498       else
4499         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4500       fi
4501     else
4502       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4503     fi
4504     ;;
4505
4506   hpux*)
4507     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4508     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4509     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4510     ;;
4511
4512   sol2* )
4513     dnl On SysVr4, grantpt(3) forks a subprocess, so do not use
4514     dnl O_CLOEXEC when opening the pty, and keep the SIGCHLD handler
4515     dnl from intercepting that death.  If any child but grantpt's should die
4516     dnl within, it should be caught after sigrelse(2).
4517     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4518     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4519     ;;
4520
4521   unixware )
4522     dnl Comments are as per sol2*.
4523     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4524     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4525     ;;
4526 esac
4527
4528
4529 case $opsys in
4530   sol2* | unixware )
4531     dnl This change means that we don't loop through allocate_pty too
4532     dnl many times in the (rare) event of a failure.
4533     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4534     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4535     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4536     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (forkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (forkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (forkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4537     ;;
4538 esac
4539
4540
4541 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4542 "typing" a signal character on the pty.])
4543
4544 case $opsys in
4545   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4546   aix4-2 | cygwin | gnu | dragonfly | freebsd | netbsd | openbsd | darwin )
4547     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4548     ;;
4549
4550   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4551   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4552   gnu-linux | gnu-kfreebsd )
4553
4554     AC_MSG_CHECKING([for signals via characters])
4555     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4556 #include <linux/version.h>
4557 #if LINUX_VERSION_CODE < 0x20400
4558 # error "Linux version too old"
4559 #endif
4560       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4561
4562     AC_MSG_RESULT([$emacs_signals_via_chars])
4563     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4564     ;;
4565 esac
4566
4567
4568 AH_TEMPLATE(TAB3, [Undocumented.])
4569
4570 case $opsys in
4571   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4572
4573   gnu | dragonfly | freebsd | netbsd | openbsd )
4574     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4575     AC_DEFINE(TAB3, OXTABS)
4576     ;;
4577
4578   gnu-linux | gnu-kfreebsd )
4579     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4580 #ifndef __ia64__
4581 # error "not ia64"
4582 #endif
4583       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4584         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4585         [Mark a secondary stack, like the register stack on the ia64.]), [])
4586     ;;
4587
4588   hpux*)
4589     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4590       run_time_remap; for HPUX.])
4591     ;;
4592 esac
4593
4594
4595 dnl This won't be used automatically yet.  We also need to know, at least,
4596 dnl that the stack is continuous.
4597 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4598   registers relevant for conservative garbage collection in the jmp_buf.])
4599
4600
4601 case $opsys in
4602   dnl Not all the architectures are tested, but there are Debian packages
4603   dnl for SCM and/or Guile on them, so the technique must work.  See also
4604   dnl comments in alloc.c concerning setjmp and gcc.
4605   dnl Fixme: it's probably safe to just use the GCC conditional below.
4606   gnu-linux | gnu-kfreebsd )
4607     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4608 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4609   || defined __alpha__ || defined __mips__ || defined __s390__ \
4610   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4611   || defined __ia64__ || defined __sh__
4612 /* ok */
4613 #else
4614 # error "setjmp not known to work on this arch"
4615 #endif
4616     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4617     ;;
4618 esac
4619
4620
4621 if test x$GCC = xyes; then
4622    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4623    AC_DEFINE(GC_SETJMP_WORKS, 1)
4624 else
4625   case $opsys in
4626     aix* | dragonfly | freebsd | netbsd | openbsd | sol2* )
4627       AC_DEFINE(GC_SETJMP_WORKS, 1)
4628       ;;
4629   esac
4630 fi                              dnl GCC?
4631
4632 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4633 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4634   [AC_LINK_IFELSE(
4635      [AC_LANG_PROGRAM(
4636        [[#include <setjmp.h>
4637          #ifdef __MINGW32__
4638          # define _longjmp longjmp
4639          #endif
4640        ]],
4641        [[jmp_buf j;
4642          if (! _setjmp (j))
4643            _longjmp (j, 1);]])],
4644      [emacs_cv_func__setjmp=yes],
4645      [emacs_cv_func__setjmp=no])])
4646 if test $emacs_cv_func__setjmp = yes; then
4647   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4648 fi
4649
4650 # We need to preserve signal mask to handle C stack overflows.
4651 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4652   [AC_LINK_IFELSE(
4653      [AC_LANG_PROGRAM(
4654        [[#include <setjmp.h>
4655        ]],
4656        [[sigjmp_buf j;
4657          if (! sigsetjmp (j, 1))
4658            siglongjmp (j, 1);]])],
4659      [emacs_cv_func_sigsetjmp=yes],
4660      [emacs_cv_func_sigsetjmp=no])])
4661 if test $emacs_cv_func_sigsetjmp = yes; then
4662   AC_DEFINE([HAVE_SIGSETJMP], 1,
4663     [Define to 1 if sigsetjmp and siglongjmp work.])
4664 fi
4665
4666 case $emacs_cv_func_sigsetjmp,$emacs_cv_alternate_stack,$opsys in
4667   yes,yes,* | *,*,mingw32)
4668     AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4669       [Define to 1 if C stack overflow can be handled in some cases.]);;
4670 esac
4671
4672 case $opsys in
4673   sol2* | unixware )
4674     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4675     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4676     dnl and this is all we need.
4677     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4678     ;;
4679 esac
4680
4681
4682 case $opsys in
4683   hpux* | sol2* )
4684     dnl Used in xfaces.c.
4685     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4686       some systems, where it requires time.h.])
4687     ;;
4688 esac
4689
4690
4691 dnl Define symbols to identify the version of Unix this is.
4692 dnl Define all the symbols that apply correctly.
4693 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4694 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4695 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4696 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4697
4698 case $opsys in
4699   aix4-2)
4700     AC_DEFINE(USG, [])
4701     dnl This symbol should be defined on AIX Version 3  ???????
4702     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4703 #ifndef _AIX
4704 # error "_AIX not defined"
4705 #endif
4706     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4707     ;;
4708
4709   cygwin)
4710     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4711     ;;
4712
4713   darwin)
4714     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4715     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4716     dnl distinguish OS X from pure Darwin.
4717     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4718     ;;
4719
4720   gnu-linux | gnu-kfreebsd )
4721     AC_DEFINE(USG, [])
4722     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4723     ;;
4724
4725   hpux*)
4726     AC_DEFINE(USG, [])
4727     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4728     ;;
4729
4730   mingw32)
4731     AC_DEFINE(DOS_NT, [])
4732     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4733     if test "x$ac_enable_checking" != "x" ; then
4734       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4735     fi
4736     ;;
4737
4738   sol2*)
4739     AC_DEFINE(USG, [])
4740     AC_DEFINE(USG5_4, [])
4741     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4742     ;;
4743
4744   unixware)
4745     AC_DEFINE(USG, [])
4746     AC_DEFINE(USG5_4, [])
4747     ;;
4748 esac
4749
4750 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4751   [case $opsys in
4752      aix4-2 | nacl)
4753        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4754        emacs_cv_usable_FIONREAD=no
4755        ;;
4756
4757      mingw32)
4758        emacs_cv_usable_FIONREAD=yes
4759        ;;
4760
4761      *)
4762        AC_COMPILE_IFELSE(
4763          [AC_LANG_PROGRAM([[#include <sys/types.h>
4764                             #include <sys/ioctl.h>
4765                             #ifdef USG5_4
4766                             # include <sys/filio.h>
4767                             #endif
4768                           ]],
4769                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4770          [emacs_cv_usable_FIONREAD=yes],
4771          [emacs_cv_usable_FIONREAD=no])
4772        ;;
4773    esac])
4774 if test $emacs_cv_usable_FIONREAD = yes; then
4775   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4776
4777   if test $emacs_broken_SIGIO = no; then
4778     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4779       [AC_COMPILE_IFELSE(
4780          [AC_LANG_PROGRAM([[#include <fcntl.h>
4781                             #include <signal.h>
4782                           ]],
4783                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4784          [emacs_cv_usable_SIGIO=yes],
4785          [emacs_cv_usable_SIGIO=no])],
4786       [emacs_cv_usable_SIGIO=yes],
4787       [emacs_cv_usable_SIGIO=no])
4788     if test $emacs_cv_usable_SIGIO = yes; then
4789       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4790     fi
4791   fi
4792 fi
4793
4794 case $opsys in
4795   hpux11)
4796     dnl It works to open the pty's tty in the parent (Emacs), then
4797     dnl close and reopen it in the child.
4798     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4799       works to open a pty's tty in the parent process, then close and
4800       reopen it in the child.])
4801     ;;
4802
4803   sol2-10)
4804     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4805       on Solaris.])
4806     ;;
4807 esac
4808
4809 # Set up the CFLAGS for real compilation, so we can substitute it.
4810 CFLAGS="$REAL_CFLAGS"
4811 CPPFLAGS="$REAL_CPPFLAGS"
4812 LIBS="$REAL_LIBS"
4813
4814 ## Hack to detect a buggy GCC version.
4815 if test "$GCC" = yes && \
4816    $CC --version 2> /dev/null | grep 'gcc.* 4.5.0' >/dev/null; then
4817   case $CFLAGS in
4818     *-fno-optimize-sibling-calls*) ;;
4819     *-O@<:@23@:>@*)
4820       AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS.]);;
4821   esac
4822 fi
4823
4824 version=$PACKAGE_VERSION
4825
4826 copyright="Copyright (C) 2016 Free Software Foundation, Inc."
4827 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4828   [Short copyright string for this version of Emacs.])
4829 AC_SUBST(copyright)
4830
4831 ### Specify what sort of things we'll be editing into Makefile and config.h.
4832 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4833 AC_SUBST(version)
4834 AC_SUBST(configuration)
4835 ## Unused?
4836 AC_SUBST(canonical)
4837 AC_SUBST(srcdir)
4838 AC_SUBST(prefix)
4839 AC_SUBST(exec_prefix)
4840 AC_SUBST(bindir)
4841 AC_SUBST(datadir)
4842 AC_SUBST(sharedstatedir)
4843 AC_SUBST(libexecdir)
4844 AC_SUBST(mandir)
4845 AC_SUBST(infodir)
4846 AC_SUBST(lispdir)
4847 AC_SUBST(standardlisppath)
4848 AC_SUBST(locallisppath)
4849 AC_SUBST(lisppath)
4850 AC_SUBST(x_default_search_path)
4851 AC_SUBST(etcdir)
4852 AC_SUBST(archlibdir)
4853 AC_SUBST(etcdocdir)
4854 AC_SUBST(bitmapdir)
4855 AC_SUBST(gamedir)
4856 AC_SUBST(gameuser)
4857 AC_SUBST(gamegroup)
4858 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4859 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4860 ## end of LIBX_BASE, but nothing ever set it.
4861 AC_SUBST(LD_SWITCH_X_SITE)
4862 AC_SUBST(C_SWITCH_X_SITE)
4863 AC_SUBST(GNUSTEP_CFLAGS)
4864 AC_SUBST(CFLAGS)
4865 ## Used in lwlib/Makefile.in.
4866 AC_SUBST(X_TOOLKIT_TYPE)
4867 AC_SUBST(ns_appdir)
4868 AC_SUBST(ns_appbindir)
4869 AC_SUBST(ns_appresdir)
4870 AC_SUBST(ns_appsrc)
4871 AC_SUBST(GNU_OBJC_CFLAGS)
4872 AC_SUBST(OTHER_FILES)
4873
4874 if test -n "${term_header}"; then
4875     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4876         [Define to the header for the built-in window system.])
4877 fi
4878
4879 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4880                    [Define to the canonical Emacs configuration name.])
4881 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4882                    [Define to the options passed to configure.])
4883 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4884   define this to include extra configuration information.])
4885
4886 case $opsys in
4887   mingw32)
4888     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4889     ;;
4890 esac
4891
4892 XMENU_OBJ=
4893 XOBJ=
4894 FONT_OBJ=
4895 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4896   AC_DEFINE(HAVE_X_WINDOWS, 1,
4897             [Define to 1 if you want to use the X window system.])
4898   XMENU_OBJ=xmenu.o
4899   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4900   FONT_OBJ=xfont.o
4901   if test "$HAVE_CAIRO" = "yes"; then
4902     FONT_OBJ="ftfont.o ftcrfont.o"
4903   elif test "$HAVE_XFT" = "yes"; then
4904     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4905   elif test "$HAVE_FREETYPE" = "yes"; then
4906     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4907   fi
4908   AC_SUBST(FONT_OBJ)
4909 fi
4910 AC_SUBST(XMENU_OBJ)
4911 AC_SUBST(XOBJ)
4912 AC_SUBST(FONT_OBJ)
4913
4914 WIDGET_OBJ=
4915 MOTIF_LIBW=
4916 if test "${USE_X_TOOLKIT}" != "none" ; then
4917   WIDGET_OBJ=widget.o
4918   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4919   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4920     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4921   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4922     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4923     MOTIF_LIBW=-lXm
4924     case "$opsys" in
4925       gnu-linux)
4926         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4927         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4928         ;;
4929
4930       unixware)
4931         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4932         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4933         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4934         ;;
4935
4936       aix4-2)
4937         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4938         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4939         ;;
4940     esac
4941     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4942   fi
4943 fi
4944 AC_SUBST(WIDGET_OBJ)
4945
4946 TOOLKIT_LIBW=
4947 case "$USE_X_TOOLKIT" in
4948   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4949   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4950   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4951 esac
4952 if test "$HAVE_XWIDGETS" = "yes"; then
4953   TOOLKIT_LIBW="$TOOLKIT_LIBW -lXcomposite"
4954 fi
4955 AC_SUBST(TOOLKIT_LIBW)
4956
4957 if test "${opsys}" != "mingw32"; then
4958   if test "$USE_X_TOOLKIT" = "none"; then
4959     LIBXT_OTHER="\$(LIBXSM)"
4960   else
4961     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4962   fi
4963 fi
4964 AC_SUBST(LIBXT_OTHER)
4965
4966 if test "${HAVE_X11}" = "yes" ; then
4967   AC_DEFINE(HAVE_X11, 1,
4968             [Define to 1 if you want to use version 11 of X windows.])
4969   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4970 else
4971   LIBX_OTHER=
4972 fi
4973 AC_SUBST(LIBX_OTHER)
4974
4975 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4976   LIBXMENU=
4977 elif test "$USE_X_TOOLKIT" = none; then
4978   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4979 else
4980   LIBXMENU='$(lwlibdir)/liblw.a'
4981 fi
4982 AC_SUBST(LIBXMENU)
4983
4984 AC_CACHE_CHECK([for struct alignment],
4985   [emacs_cv_struct_alignment],
4986   [AC_COMPILE_IFELSE(
4987      [AC_LANG_PROGRAM([[#include <stddef.h>
4988                         struct __attribute__ ((aligned (8))) s { char c; };
4989                         struct t { char c; struct s s; };
4990                         char verify[offsetof (struct t, s) == 8 ? 1 : -1];
4991                       ]])],
4992      [emacs_cv_struct_alignment=yes],
4993      [emacs_cv_struct_alignment=no])])
4994 if test "$emacs_cv_struct_alignment" = yes; then
4995   AC_DEFINE([HAVE_STRUCT_ATTRIBUTE_ALIGNED], 1,
4996     [Define to 1 if 'struct __attribute__ ((aligned (N)))' aligns the
4997      structure to an N-byte boundary.])
4998 fi
4999
5000 if test "${GNU_MALLOC}" = "yes" ; then
5001   AC_DEFINE(GNU_MALLOC, 1,
5002             [Define to 1 if you want to use the GNU memory allocator.])
5003 fi
5004
5005 RALLOC_OBJ=
5006 if test "${REL_ALLOC}" = "yes" ; then
5007   AC_DEFINE(REL_ALLOC, 1,
5008             [Define REL_ALLOC if you want to use the relocating allocator for
5009              buffer space.])
5010
5011   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
5012 fi
5013 AC_SUBST(RALLOC_OBJ)
5014
5015 if test "$opsys" = "cygwin"; then
5016   CYGWIN_OBJ="cygw32.o"
5017   ## Cygwin differs because of its unexec().
5018   PRE_ALLOC_OBJ=
5019   POST_ALLOC_OBJ=lastfile.o
5020 elif test "$opsys" = "mingw32"; then
5021   CYGWIN_OBJ=
5022   PRE_ALLOC_OBJ=
5023   POST_ALLOC_OBJ=lastfile.o
5024 else
5025   CYGWIN_OBJ=
5026   PRE_ALLOC_OBJ=lastfile.o
5027   POST_ALLOC_OBJ=
5028 fi
5029 AC_SUBST(CYGWIN_OBJ)
5030 AC_SUBST(PRE_ALLOC_OBJ)
5031 AC_SUBST(POST_ALLOC_OBJ)
5032
5033 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
5034 dnl verbatim defined above.  The tricky name is apropos, as this hack
5035 dnl makes Fortify go sour!
5036 AH_VERBATIM([FORTIFY_SOUR],
5037 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
5038    The workaround disables some useful run-time checking, so it
5039    should be conditional to the platforms with the performance bug.
5040    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
5041 #if defined __APPLE__ && defined __GNUC__
5042 # ifndef _DONT_USE_CTYPE_INLINE_
5043 #  define _DONT_USE_CTYPE_INLINE_
5044 # endif
5045 # ifndef _FORTIFY_SOURCE
5046 #  define _FORTIFY_SOURCE 0
5047 # endif
5048 #endif
5049 ])
5050
5051 # If user asks to omit features, disable optional features that gnulib
5052 # might otherwise enable.
5053 if test "$with_features" = no && test "$enable_acl" != yes; then
5054   enable_acl=no
5055 fi
5056
5057 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
5058 # it temporarily reverts them to their pre-pkg-config values,
5059 # because gnulib needs to work with both src (which uses the
5060 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
5061 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
5062 # and it therefore needs to run in an environment where LIBS does not
5063 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
5064 # for some package unrelated to lib-src.
5065 SAVE_CFLAGS=$CFLAGS
5066 SAVE_LIBS=$LIBS
5067 CFLAGS=$pre_PKG_CONFIG_CFLAGS
5068 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
5069 gl_ASSERT_NO_GNULIB_POSIXCHECK
5070 gl_ASSERT_NO_GNULIB_TESTS
5071 gl_INIT
5072 CFLAGS=$SAVE_CFLAGS
5073 LIBS=$SAVE_LIBS
5074
5075 if test "${opsys}" = "mingw32"; then
5076   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
5077   # Remove unneeded switches from the value of CC that goes to Makefiles
5078   CC=`AS_ECHO(["$CC"]) | sed -e "s,$GCC_TEST_OPTIONS,,"`
5079 fi
5080
5081 case "$opsys" in
5082   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
5083
5084   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
5085
5086   darwin)
5087    ## The -headerpad option tells ld (see man page) to leave room at the
5088    ## end of the header for adding load commands.  Needed for dumping.
5089    ## 0x1000 is enough for roughly 52 load commands on the x86_64
5090    ## architecture (where they are 78 bytes each). The actual number of
5091    ## load commands added is not consistent but normally ranges from
5092    ## about 14 to about 34. Setting it high gets us plenty of slop and
5093    ## only costs about 1.5K of wasted binary space.
5094    headerpad_extra=1000
5095    if test "$HAVE_NS" = "yes"; then
5096      libs_nsgui="-framework AppKit"
5097      if test "$NS_IMPL_COCOA" = "yes"; then
5098         libs_nsgui="$libs_nsgui -framework IOKit"
5099      fi
5100    else
5101      libs_nsgui=
5102    fi
5103    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
5104
5105    ## This is here because src/Makefile.in did some extra fiddling around
5106    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
5107    ## LD_SWITCH_SYSTEM_TEMACS instead,
5108    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
5109      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
5110    ;;
5111
5112   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
5113   ## find X at run-time.
5114   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
5115   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
5116   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
5117   ## had different values in configure (in ac_link) and src/Makefile.in.
5118   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
5119   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
5120
5121   mingw32)
5122    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
5123    case "$canonical" in
5124      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5125      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5126    esac
5127    ;;
5128
5129   *) LD_SWITCH_SYSTEM_TEMACS= ;;
5130 esac
5131
5132 # -nopie fixes a temacs segfault on Gentoo, OpenBSD, and other systems
5133 # with "hardened" GCC configurations for some reason (Bug#18784).
5134 # We don't know why -nopie works, but not segfaulting is better than
5135 # segfaulting.  Use ac_c_werror_flag=yes when trying -nopie, otherwise
5136 # clang keeps warning that it does not understand -nopie, and pre-4.6
5137 # GCC has a similar problem (Bug#20338).
5138 AC_CACHE_CHECK([whether $CC accepts -nopie],
5139   [emacs_cv_prog_cc_nopie],
5140   [emacs_save_c_werror_flag=$ac_c_werror_flag
5141    emacs_save_LDFLAGS=$LDFLAGS
5142    ac_c_werror_flag=yes
5143    LDFLAGS="$LDFLAGS -nopie"
5144    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
5145      [emacs_cv_prog_cc_nopie=yes],
5146      [emacs_cv_prog_cc_nopie=no])
5147    ac_c_werror_flag=$emacs_save_c_werror_flag
5148    LDFLAGS=$emacs_save_LDFLAGS])
5149 if test "$emacs_cv_prog_cc_nopie" = yes; then
5150   LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -nopie"
5151 fi
5152
5153 if test x$ac_enable_profiling != x ; then
5154   case $opsys in
5155     *freebsd | gnu-linux) ;;
5156     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
5157   esac
5158 fi
5159
5160 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
5161
5162 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
5163
5164 ## Common for all window systems
5165 if test "$window_system" != "none"; then
5166   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
5167   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
5168   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
5169 fi
5170
5171 AC_SUBST(WINDOW_SYSTEM_OBJ)
5172
5173 AH_TOP([/* GNU Emacs site configuration template file.
5174
5175 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2016
5176   Free Software Foundation, Inc.
5177
5178 This file is part of GNU Emacs.
5179
5180 GNU Emacs is free software: you can redistribute it and/or modify
5181 it under the terms of the GNU General Public License as published by
5182 the Free Software Foundation, either version 3 of the License, or (at
5183 your option) any later version.
5184
5185 GNU Emacs is distributed in the hope that it will be useful,
5186 but WITHOUT ANY WARRANTY; without even the implied warranty of
5187 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
5188 GNU General Public License for more details.
5189
5190 You should have received a copy of the GNU General Public License
5191 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
5192
5193
5194 /* No code in Emacs #includes config.h twice, but some bits of code
5195    intended to work with other packages as well (like gmalloc.c)
5196    think they can include it as many times as they like.  */
5197 #ifndef EMACS_CONFIG_H
5198 #define EMACS_CONFIG_H
5199 ])dnl
5200
5201 AH_BOTTOM([#include <conf_post.h>
5202
5203 #endif /* EMACS_CONFIG_H */
5204
5205 /*
5206 Local Variables:
5207 mode: c
5208 End:
5209 */
5210 ])dnl
5211
5212 #### Report on what we decided to do.
5213 #### Report GTK as a toolkit, even if it doesn't use Xt.
5214 #### It makes printing result more understandable as using GTK sets
5215 #### toolkit_scroll_bars to yes by default.
5216 if test "${HAVE_GTK}" = "yes"; then
5217   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5218 fi
5219
5220 if test $USE_ACL -ne 0; then
5221   ACL_SUMMARY="yes $LIB_ACL"
5222 else
5223   ACL_SUMMARY=no
5224 fi
5225
5226 emacs_standard_dirs='Standard dirs'
5227 AS_ECHO(["
5228 Configured for '${canonical}'.
5229
5230   Where should the build process find the source code?    ${srcdir}
5231   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5232   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5233   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5234   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5235   What window system should Emacs use?                    ${window_system}
5236   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}
5237   Where do we find X Windows header files?                ${x_includes:-$emacs_standard_dirs}
5238   Where do we find X Windows libraries?                   ${x_libraries:-$emacs_standard_dirs}"])
5239
5240 optsep=
5241 emacs_config_features=
5242 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG CAIRO IMAGEMAGICK SOUND GPM DBUS \
5243   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5244   LIBOTF XFT ZLIB TOOLKIT_SCROLL_BARS X_TOOLKIT X11 NS MODULES \
5245   XWIDGETS LIBSYSTEMD CANNOT_DUMP; do
5246
5247     case $opt in
5248       CANNOT_DUMP) eval val=\${$opt} ;;
5249       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5250       TOOLKIT_SCROLL_BARS|X_TOOLKIT) eval val=\${USE_$opt} ;;
5251       *) eval val=\${HAVE_$opt} ;;
5252     esac
5253     case x$val in
5254       xno|xnone|x) continue ;;
5255     esac
5256     case $opt in
5257       X_TOOLKIT)
5258         case $val in
5259           GTK*|LUCID|MOTIF) opt=$val ;;
5260           *) continue ;;
5261         esac
5262       ;;
5263     esac
5264     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5265     optsep=' '
5266 done
5267 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5268   [Summary of some of the main features enabled by configure.])
5269
5270 AS_ECHO(["  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}
5271   Does Emacs use -lXpm?                                   ${HAVE_XPM}
5272   Does Emacs use -ljpeg?                                  ${HAVE_JPEG}
5273   Does Emacs use -ltiff?                                  ${HAVE_TIFF}
5274   Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF
5275   Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG
5276   Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}
5277   Does Emacs use cairo?                                   ${HAVE_CAIRO}
5278   Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}
5279   Does Emacs support sound?                               ${HAVE_SOUND}
5280   Does Emacs use -lgpm?                                   ${HAVE_GPM}
5281   Does Emacs use -ldbus?                                  ${HAVE_DBUS}
5282   Does Emacs use -lgconf?                                 ${HAVE_GCONF}
5283   Does Emacs use GSettings?                               ${HAVE_GSETTINGS}
5284   Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}
5285   Does Emacs use access control lists?                    ${ACL_SUMMARY}
5286   Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}
5287   Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}
5288   Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}
5289   Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}
5290   Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}
5291   Does Emacs use -lotf?                                   ${HAVE_LIBOTF}
5292   Does Emacs use -lxft?                                   ${HAVE_XFT}
5293   Does Emacs use -lsystemd?                               ${HAVE_LIBSYSTEMD}
5294   Does Emacs directly use zlib?                           ${HAVE_ZLIB}
5295   Does Emacs have dynamic modules support?                ${HAVE_MODULES}
5296   Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}
5297   Does Emacs support Xwidgets (requires gtk3)?            ${HAVE_XWIDGETS}
5298 "])
5299
5300 if test -n "${EMACSDATA}"; then
5301    AS_ECHO(["  Environment variable EMACSDATA set to:                  $EMACSDATA"])
5302 fi
5303 if test -n "${EMACSDOC}"; then
5304    AS_ECHO(["  Environment variable EMACSDOC set to:                   $EMACSDOC"])
5305 fi
5306
5307 echo
5308
5309 if test "$HAVE_NS" = "yes"; then
5310    echo
5311    AS_ECHO(["You must run \"${MAKE-make} install\" in order to test the built application.
5312 The installed application will go to nextstep/Emacs.app and can be
5313 run or moved from there."])
5314    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5315       echo "The application will be fully self-contained."
5316     else
5317       AS_ECHO(["The lisp resources for the application will be installed under ${prefix}.
5318 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5319 to run if these resources are not installed."])
5320    fi
5321    echo
5322 fi
5323
5324 if test "${opsys}" = "cygwin"; then
5325   case `uname -r` in
5326     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5327            echo
5328            ;;
5329   esac
5330 fi
5331
5332 # Remove any trailing slashes in these variables.
5333 case $prefix in
5334   */) prefix=`AS_DIRNAME(["$prefix."])`;;
5335 esac
5336 case $exec_prefix in
5337   */) exec_prefix=`AS_DIRNAME(["$exec_prefix."])`;;
5338 esac
5339
5340 if test "$HAVE_NS" = "yes"; then
5341   if test "$NS_IMPL_GNUSTEP" = yes; then
5342     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5343       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5344     ns_check_file=Resources/Info-gnustep.plist
5345   else
5346     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5347       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5348     ns_check_file=Contents/Info.plist
5349   fi
5350   AC_SUBST(ns_check_file)
5351 fi
5352
5353 dnl config.status treats $srcdir specially, so I think this is ok...
5354 AC_CONFIG_FILES([$srcdir/doc/man/emacs.1])
5355
5356 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5357 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5358 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5359 dnl (else you get "no 'Makefile.am' found for any configure output").
5360 dnl This will work, but you get a config.status that is not quite right
5361 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5362 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5363 dnl it seems better to just live with the duplication.
5364 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5365
5366 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5367        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5368        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5369        leim/Makefile nextstep/Makefile nt/Makefile])
5370
5371 dnl test/ is not present in release tarfiles.
5372 opt_makefile=test/Makefile
5373
5374 if test -f "$srcdir/$opt_makefile.in"; then
5375   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5376   dnl Again, it's best not to use a variable.  Though you can add
5377   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5378   AC_CONFIG_FILES([test/Makefile])
5379 fi
5380
5381
5382 dnl The admin/ directory used to be excluded from tarfiles.
5383 if test -d $srcdir/admin; then
5384   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/charsets/Makefile admin/unidata/Makefile admin/grammars/Makefile"
5385   AC_CONFIG_FILES([admin/charsets/Makefile])
5386   AC_CONFIG_FILES([admin/unidata/Makefile])
5387   AC_CONFIG_FILES([admin/grammars/Makefile])
5388 fi                              dnl -d admin
5389
5390
5391 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5392
5393 AC_SUBST(SUBDIR_MAKEFILES_IN)
5394
5395 dnl You might wonder (I did) why epaths.h is generated by running make,
5396 dnl rather than just letting configure generate it from epaths.in.
5397 dnl One reason is that the various paths are not fully expanded (see above);
5398 dnl eg gamedir=${prefix}/var/games/emacs.
5399 dnl Secondly, the GNU Coding standards require that one should be able
5400 dnl to run 'make prefix=/some/where/else' and override the values set
5401 dnl by configure.  This also explains the 'move-if-change' test and
5402 dnl the use of force in the 'epaths-force' rule in Makefile.in.
5403 AC_CONFIG_COMMANDS([src/epaths.h], [
5404 if test "${opsys}" = "mingw32"; then
5405   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5406 else
5407   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5408 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5409 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5410
5411 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5412 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5413 dnl or a symlink?
5414 AC_CONFIG_COMMANDS([src/.gdbinit], [
5415 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5416   AS_ECHO(["source $ac_abs_top_srcdir/src/.gdbinit"]) > src/.gdbinit
5417 fi
5418 ])
5419
5420 dnl Perhaps this would be better named doc-emacs-emacsver.texi?
5421 dnl See comments for etc-refcards-emacsver.tex.
5422 dnl Since we get a doc/emacs directory generated anyway, for the Makefile,
5423 dnl it is not quite the same.  But we are generating in $srcdir.
5424 AC_CONFIG_COMMANDS([doc/emacs/emacsver.texi], [
5425 ${MAKE-make} -s --no-print-directory -C doc/emacs doc-emacsver || \
5426 AC_MSG_ERROR(['doc/emacs/emacsver.texi' could not be made.])
5427 ])
5428
5429 dnl If we give this the more natural name, etc/refcards/emacsver.texi,
5430 dnl then a directory etc/refcards is created in the build directory,
5431 dnl which is probably harmless, but confusing (in out-of-tree builds).
5432 dnl (If we were to generate etc/refcards/Makefile, this might change.)
5433 dnl It is really $srcdir/etc/refcards/emacsver.tex that we generate.
5434 AC_CONFIG_COMMANDS([etc-refcards-emacsver.tex], [
5435 ${MAKE-make} -s MAKEFILE_NAME=do-not-make-Makefile etc-emacsver || \
5436 AC_MSG_ERROR(['etc/refcards/emacsver.tex' could not be made.])
5437 ])
5438
5439 AC_OUTPUT
5440
5441 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])