code.delx.au - gnu-emacs/blob - lisp/progmodes/compile.el

   1 ;;; compile.el --- run compiler as inferior of Emacs, parse error messages
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4 ;;   2001, 2003, 2004  Free Software Foundation, Inc.
   5
   6 ;; Authors: Roland McGrath <roland@gnu.org>,
   7 ;;          Daniel Pfeiffer <occitan@esperanto.org>
   8 ;; Maintainer: FSF
   9 ;; Keywords: tools, processes
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package provides the compile facilities documented in the Emacs user's
  31 ;; manual.
  32
  33 ;; This mode uses some complex data-structures:
  34
  35 ;;   LOC (or location) is a list of (COLUMN LINE FILE-STRUCTURE)
  36
  37 ;; COLUMN and LINE are numbers parsed from an error message.  COLUMN and maybe
  38 ;; LINE will be nil for a message that doesn't contain them.  Then the
  39 ;; location refers to a indented beginning of line or beginning of file.
  40 ;; Once any location in some file has been jumped to, the list is extended to
  41 ;; (COLUMN LINE FILE-STRUCTURE MARKER . VISITED) for all LOCs pertaining to
  42 ;; that file.
  43 ;; MARKER initially points to LINE and COLUMN in a buffer visiting that file.
  44 ;; Being a marker it sticks to some text, when the buffer grows or shrinks
  45 ;; before that point.  VISITED is t if we have jumped there, else nil.
  46
  47 ;;   FILE-STRUCTURE is a list of
  48 ;;   ((FILENAME . DIRECTORY) FORMATS (LINE LOC ...) ...)
  49
  50 ;; FILENAME is a string parsed from an error message.  DIRECTORY is a string
  51 ;; obtained by following directory change messages.  DIRECTORY will be nil for
  52 ;; an absolute filename.  FORMATS is a list of formats to apply to FILENAME if
  53 ;; a file of that name can't be found.
  54 ;; The rest of the list is an alist of elements with LINE as key.  The keys
  55 ;; are either nil or line numbers.  If present, nil comes first, followed by
  56 ;; the numbers in decreasing order.  The LOCs for each line are again an alist
  57 ;; ordered the same way.  Note that the whole file structure is referenced in
  58 ;; every LOC.
  59
  60 ;;   MESSAGE is a list of (LOC TYPE END-LOC)
  61
  62 ;; TYPE is 0 for info or 1 for warning if the message matcher identified it as
  63 ;; such, 2 otherwise (for a real error).  END-LOC is a LOC pointing to the
  64 ;; other end, if the parsed message contained a range.  If the end of the
  65 ;; range didn't specify a COLUMN, it defaults to -1, meaning end of line.
  66 ;; These are the value of the `message' text-properties in the compilation
  67 ;; buffer.
  68
  69 ;;; Code:
  70
  71 (eval-when-compile (require 'cl))
  72
  73 (defgroup compilation nil
  74   "Run compiler as inferior of Emacs, parse error messages."
  75   :group 'tools
  76   :group 'processes)
  77
  78
  79 ;;;###autoload
  80 (defcustom compilation-mode-hook nil
  81   "*List of hook functions run by `compilation-mode' (see `run-hooks')."
  82   :type 'hook
  83   :group 'compilation)
  84
  85 ;;;###autoload
  86 (defcustom compilation-window-height nil
  87   "*Number of lines in a compilation window.  If nil, use Emacs default."
  88   :type '(choice (const :tag "Default" nil)
  89                  integer)
  90   :group 'compilation)
  91
  92 (defvar compilation-first-column 1
  93   "*This is how compilers number the first column, usually 1 or 0.")
  94
  95 (defvar compilation-parse-errors-filename-function nil
  96   "Function to call to post-process filenames while parsing error messages.
  97 It takes one arg FILENAME which is the name of a file as found
  98 in the compilation output, and should return a transformed file name.")
  99
 100 ;;;###autoload
 101 (defvar compilation-process-setup-function nil
 102   "*Function to call to customize the compilation process.
 103 This function is called immediately before the compilation process is
 104 started.  It can be used to set any variables or functions that are used
 105 while processing the output of the compilation process.  The function
 106 is called with variables `compilation-buffer' and `compilation-window'
 107 bound to the compilation buffer and window, respectively.")
 108
 109 ;;;###autoload
 110 (defvar compilation-buffer-name-function nil
 111   "Function to compute the name of a compilation buffer.
 112 The function receives one argument, the name of the major mode of the
 113 compilation buffer.  It should return a string.
 114 nil means compute the name with `(concat \"*\" (downcase major-mode) \"*\")'.")
 115
 116 ;;;###autoload
 117 (defvar compilation-finish-function nil
 118   "Function to call when a compilation process finishes.
 119 It is called with two arguments: the compilation buffer, and a string
 120 describing how the process finished.")
 121
 122 ;;;###autoload
 123 (defvar compilation-finish-functions nil
 124   "Functions to call when a compilation process finishes.
 125 Each function is called with two arguments: the compilation buffer,
 126 and a string describing how the process finished.")
 127
 128 (defvar compilation-in-progress nil
 129   "List of compilation processes now running.")
 130 (or (assq 'compilation-in-progress minor-mode-alist)
 131     (setq minor-mode-alist (cons '(compilation-in-progress " Compiling")
 132                                  minor-mode-alist)))
 133
 134 (defvar compilation-error "error"
 135   "Stem of message to print when no matches are found.")
 136
 137 (defvar compilation-arguments nil
 138   "Arguments that were given to `compilation-start'.")
 139
 140 (defvar compilation-num-errors-found)
 141
 142 (defconst compilation-error-regexp-alist-alist
 143   '((absoft
 144      "^\\(?:[Ee]rror on \\|[Ww]arning on\\( \\)\\)?[Ll]ine[ \t]+\\([0-9]+\\)[ \t]+\
 145 of[ \t]+\"?\\([a-zA-Z]?:?[^\":\n]+\\)\"?:" 3 2 nil (1))
 146
 147     (ada
 148      "\\(warning: .*\\)? at \\([^ \n]+\\):\\([0-9]+\\)$" 2 3 nil (1))
 149
 150     (aix
 151      " in line \\([0-9]+\\) of file \\([^ \n]+[^. \n]\\)\\.? " 2 1)
 152
 153     (ant
 154      "^[ \t]*\\[[^] \n]+\\][ \t]*\\([^: \n]+\\):\\([0-9]+\\):\\(?:\\([0-9]+\\):[0-9]+:[0-9]+:\\)?\
 155 \\( warning\\)?" 1 2 3 (4))
 156
 157     (bash
 158      "^\\([^: \n\t]+\\): line \\([0-9]+\\):" 1 2)
 159
 160     (borland
 161      "^\\(?:Error\\|Warnin\\(g\\)\\) \\(?:[FEW][0-9]+ \\)?\
 162 \\([a-zA-Z]?:?[^:( \t\n]+\\)\
 163  \\([0-9]+\\)\\(?:[) \t]\\|:[^0-9\n]\\)" 2 3 nil (1))
 164
 165     (caml
 166      "^ *File \\(\"?\\)\\([^,\" \n\t<>]+\\)\\1, lines? \\([0-9]+\\)-?\\([0-9]+\\)?\\(?:$\\|,\
 167 \\(?: characters? \\([0-9]+\\)-?\\([0-9]+\\)?:\\)?\\([ \n]Warning:\\)?\\)"
 168      2 (3 . 4) (5 . 6) (7))
 169
 170     (comma
 171      "^\"\\([^,\" \n\t]+\\)\", line \\([0-9]+\\)\
 172 \\(?:[(. pos]+\\([0-9]+\\))?\\)?[:.,; (-]\\( warning:\\|[-0-9 ]*(W)\\)?" 1 2 3 (4))
 173
 174     (edg-1
 175      "^\\([^ \n]+\\)(\\([0-9]+\\)): \\(?:error\\|warnin\\(g\\)\\|remar\\(k\\)\\)"
 176      1 2 nil (3 . 4))
 177     (edg-2
 178      "at line \\([0-9]+\\) of \"\\([^ \n]+\\)\"$"
 179      2 1 nil 0)
 180
 181     (epc
 182      "^Error [0-9]+ at (\\([0-9]+\\):\\([^)\n]+\\))" 2 1)
 183
 184     (ftnchek-file
 185      "^File \\(.+\\.f\\):$"
 186      1 nil nil 0)
 187     (ftnchek-line-file
 188      "\\(^Warning .* \\)?line \\([0-9]+\\)\\(?: col \\([0-9]+\\)\\)? file \\(.+\\.f\\)"
 189      4 2 3 (1) nil (1 'default nil t))
 190     (ftnchek-line
 191      "\\(?:^\\(Warning\\) .* \\)?line \\([0-9]+\\)\\(?: col \\([0-9]+\\)\\)?"
 192      nil 2 3 (1) nil (1 (compilation-face '(1)) nil t))
 193
 194     (iar
 195      "^\"\\(.*\\)\",\\([0-9]+\\)\\s-+\\(?:Error\\|Warnin\\(g\\)\\)\\[[0-9]+\\]:"
 196      1 2 nil (3))
 197
 198     (ibm
 199      "^\\([^( \n\t]+\\)(\\([0-9]+\\):\\([0-9]+\\)) :\
 200  \\(?:warnin\\(g\\)\\|informationa\\(l\\)\\)?" 1 2 3 (4 . 5))
 201
 202     ;; fixme: should be `mips'
 203     (irix
 204      "^[-[:alnum:]_/ ]+: \\(?:\\(?:[sS]evere\\|[eE]rror\\|[wW]arnin\\(g\\)\\|[iI]nf\\(o\\)\\)[0-9 ]*: \\)?\
 205 \\([^,\" \n\t]+\\)\\(?:, line\\|:\\) \\([0-9]+\\):" 3 4 nil (1 . 2))
 206
 207     (java
 208      "^\\(?:[ \t]+at \\|==[0-9]+== +\\(?:at\\|b\\(y\\)\\)\\).+(\\([^()\n]+\\):\\([0-9]+\\))$" 2 3 nil (1))
 209
 210     (jikes-file
 211      "^\\(?:Found\\|Issued\\) .* compiling \"\\(.+\\)\":$" 1 nil nil 0)
 212     (jikes-line
 213      "^ *\\([0-9]+\\)\\.[ \t]+.*\n +\\(<-*>\n\\*\\*\\* \\(?:Error\\|Warnin\\(g\\)\\)\\)"
 214      nil 1 nil 2 0
 215      (2 (compilation-face '(3))))
 216
 217     (gcc-include
 218      "^\\(?:In file included\\|                \\) from \
 219 \\(.+\\):\\([0-9]+\\)\\(?:\\(:\\)\\|\\(,\\)\\)?" 1 2 nil (3 . 4))
 220
 221     (gnu
 222      "^\\(?:[[:alpha:]][-[:alnum:].]+: ?\\)?\
 223 \\([/.]*[a-zA-Z]:?[^ \t\n:]*\\|{standard input}\\): ?\
 224 \\([0-9]+\\)\\([.:]?\\)\\([0-9]+\\)?\
 225 \\(?:-\\(?:\\([0-9]+\\)\\3\\)?\\.?\\([0-9]+\\)?\\)?:\
 226 \\(?: *\\(\\(?:Future\\|Runtime\\)?[Ww]arning\\|W:\\)\\|\
 227  *\\([Ii]nfo\\(?:\\>\\|rmationa?l?\\)\\|I:\\)\\)?"
 228      1 (2 . 5) (4 . 6) (7 . 8))
 229
 230     (lcc
 231      "^\\(?:E\\|\\(W\\)\\), \\([^(\n]+\\)(\\([0-9]+\\),[ \t]*\\([0-9]+\\)"
 232      2 3 4 (1))
 233
 234     (makepp
 235      "^makepp: \\(?:\\(?:warning\\(:\\).*?\\|\\(Scanning\\|[LR]e?l?oading makefile\\) \\|.*?\\)\
 236 `\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)'\\)"
 237      4 5 nil (1 . 2) 3
 238      ("`\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)'" nil nil
 239       (2 compilation-info-face)
 240       (3 compilation-line-face nil t)
 241       (1 (compilation-error-properties 2 3 nil nil nil 0 nil)
 242          append)))
 243
 244     ;; Should be lint-1, lint-2 (SysV lint)
 245     (mips-1
 246      " (\\([0-9]+\\)) in \\([^ \n]+\\)" 2 1)
 247     (mips-2
 248      " in \\([^()\n ]+\\)(\\([0-9]+\\))$" 1 2)
 249
 250     (msft
 251      "^\\(\\(?:[a-zA-Z]:\\)?[^:(\t\n]+\\)(\\([0-9]+\\)) \
 252 : \\(?:error\\|warnin\\(g\\)\\) C[0-9]+:" 1 2 nil (3))
 253
 254     (oracle
 255      "^\\(?:Semantic error\\|Error\\|PCC-[0-9]+:\\).* line \\([0-9]+\\)\
 256 \\(?:\\(?:,\\| at\\)? column \\([0-9]+\\)\\)?\
 257 \\(?:,\\| in\\| of\\)? file \\(.*?\\):?$"
 258      3 1 2)
 259
 260     (perl
 261      " at \\([^ \n]+\\) line \\([0-9]+\\)\\(?:[,.]\\|$\\)" 1 2)
 262
 263     (rxp
 264      "^\\(?:Error\\|Warnin\\(g\\)\\):.*\n.* line \\([0-9]+\\) char\
 265  \\([0-9]+\\) of file://\\(.+\\)"
 266      4 2 3 (1))
 267
 268     (sparc-pascal-file
 269      "^\\w\\w\\w \\w\\w\\w +[0-3]?[0-9] +[0-2][0-9]:[0-5][0-9]:[0-5][0-9]\
 270  [12][09][0-9][0-9] +\\(.*\\):$"
 271      1 nil nil 0)
 272     (sparc-pascal-line
 273      "^\\(\\(?:E\\|\\(w\\)\\) +[0-9]+\\) line \\([0-9]+\\) -  "
 274      nil 3 nil (2) nil (1 (compilation-face '(2))))
 275     (sparc-pascal-example
 276      "^ +\\([0-9]+\\) +.*\n\\(\\(?:e\\|\\(w\\)\\) [0-9]+\\)-+"
 277      nil 1 nil (3) nil (2 (compilation-face '(3))))
 278
 279     (sun
 280      ": \\(?:ERROR\\|WARNIN\\(G\\)\\|REMAR\\(K\\)\\) \\(?:[[:alnum:] ]+, \\)?\
 281 File = \\(.+\\), Line = \\([0-9]+\\)\\(?:, Column = \\([0-9]+\\)\\)?"
 282      3 4 5 (1 . 2))
 283
 284     (sun-ada
 285      "^\\([^, \n\t]+\\), line \\([0-9]+\\), char \\([0-9]+\\)[:., \(-]" 1 2 3)
 286
 287     (4bsd
 288      "\\(?:^\\|::  \\|\\S ( \\)\\(/[^ \n\t()]+\\)(\\([0-9]+\\))\
 289 \\(?:: \\(warning:\\)?\\|$\\| ),\\)" 1 2 nil (3)))
 290   "Alist of values for `compilation-error-regexp-alist'.")
 291
 292 (defcustom compilation-error-regexp-alist
 293   (mapcar 'car compilation-error-regexp-alist-alist)
 294   "Alist that specifies how to match errors in compiler output.
 295 Note that on Unix everything is a valid filename, so these
 296 matchers must make some common sense assumptions, which catch
 297 normal cases.  A shorter list will be lighter on resource usage.
 298
 299 Instead of an alist element, you can use a symbol, which is
 300 looked up in `compilation-error-regexp-alist-alist'.  You can see
 301 the predefined symbols and their effects in the file
 302 `etc/compilation.txt' (linked below if you are customizing this).
 303
 304 Each elt has the form (REGEXP FILE [LINE COLUMN TYPE HYPERLINK
 305 HIGHLIGHT...]).  If REGEXP matches, the FILE'th subexpression
 306 gives the file name, and the LINE'th subexpression gives the line
 307 number.  The COLUMN'th subexpression gives the column number on
 308 that line.
 309
 310 If FILE, LINE or COLUMN are nil or that index didn't match, that
 311 information is not present on the matched line.  In that case the
 312 file name is assumed to be the same as the previous one in the
 313 buffer, line number defaults to 1 and column defaults to
 314 beginning of line's indentation.
 315
 316 FILE can also have the form (FILE FORMAT...), where the FORMATs
 317 \(e.g. \"%s.c\") will be applied in turn to the recognized file
 318 name, until a file of that name is found.  Or FILE can also be a
 319 function to return the filename.
 320
 321 LINE can also be of the form (LINE . END-LINE) meaning a range
 322 of lines.  COLUMN can also be of the form (COLUMN . END-COLUMN)
 323 meaning a range of columns starting on LINE and ending on
 324 END-LINE, if that matched.
 325
 326 TYPE is 2 or nil for a real error or 1 for warning or 0 for info.
 327 TYPE can also be of the form (WARNING . INFO).  In that case this
 328 will be equivalent to 1 if the WARNING'th subexpression matched
 329 or else equivalent to 0 if the INFO'th subexpression matched.
 330 See `compilation-error-face', `compilation-warning-face',
 331 `compilation-info-face' and `compilation-skip-threshold'.
 332
 333 What matched the HYPERLINK'th subexpression has `mouse-face' and
 334 `compilation-message-face' applied.  If this is nil, the text
 335 matched by the whole REGEXP becomes the hyperlink.
 336
 337 Additional HIGHLIGHTs as described under `font-lock-keywords' can
 338 be added."
 339   :type `(set :menu-tag "Pick"
 340               ,@(mapcar (lambda (elt)
 341                           (list 'const (car elt)))
 342                         compilation-error-regexp-alist-alist))
 343   :link `(file-link :tag "example file"
 344                     ,(expand-file-name "compilation.txt" data-directory))
 345   :group 'compilation)
 346
 347 (defvar compilation-directory nil
 348   "Directory to restore to when doing `recompile'.")
 349
 350 (defvar compilation-directory-matcher
 351   '("\\(?:Entering\\|Leavin\\(g\\)\\) directory `\\(.+\\)'$" (2 . 1))
 352   "A list for tracking when directories are entered or left.
 353 Nil means not to track directories, e.g. if all file names are absolute.  The
 354 first element is the REGEXP matching these messages.  It can match any number
 355 of variants, e.g. different languages.  The remaining elements are all of the
 356 form (DIR .  LEAVE).  If for any one of these the DIR'th subexpression
 357 matches, that is a directory name.  If LEAVE is nil or the corresponding
 358 LEAVE'th subexpression doesn't match, this message is about going into another
 359 directory.  If it does match anything, this message is about going back to the
 360 directory we were in before the last entering message.  If you change this,
 361 you may also want to change `compilation-page-delimiter'.")
 362
 363 (defvar compilation-page-delimiter
 364   "^\\(?:\f\\|.*\\(?:Entering\\|Leaving\\) directory `.+'\n\\)+"
 365   "Value of `page-delimiter' in Compilation mode.")
 366
 367 (defvar compilation-mode-font-lock-keywords
 368    '(;; configure output lines.
 369      ("^[Cc]hecking \\(?:[Ff]or \\|[Ii]f \\|[Ww]hether \\(?:to \\)?\\)?\\(.+\\)\\.\\.\\. *\\(?:(cached) *\\)?\\(\\(yes\\(?: .+\\)?\\)\\|no\\|\\(.*\\)\\)$"
 370       (1 font-lock-variable-name-face)
 371       (2 (compilation-face '(4 . 3))))
 372      ;; Command output lines.  Recognize `make[n]:' lines too.
 373      ("^\\([[:alnum:]_/.+-]+\\)\\(\\[\\([0-9]+\\)\\]\\)?[ \t]*:"
 374       (1 font-lock-function-name-face) (3 compilation-line-face nil t))
 375      (" --?o\\(?:utfile\\|utput\\)?[= ]?\\(\\S +\\)" . 1)
 376      ("^Compilation finished" . compilation-info-face)
 377      ("^Compilation exited abnormally" . compilation-error-face))
 378    "Additional things to highlight in Compilation mode.
 379 This gets tacked on the end of the generated expressions.")
 380
 381 (defvar compilation-highlight-regexp t
 382   "Regexp matching part of visited source lines to highlight temporarily.
 383 Highlight entire line if t; don't highlight source lines if nil.")
 384
 385 (defvar compilation-highlight-overlay nil
 386   "Overlay used to temporarily highlight compilation matches.")
 387
 388 (defcustom compilation-error-screen-columns t
 389   "*If non-nil, column numbers in error messages are screen columns.
 390 Otherwise they are interpreted as character positions, with
 391 each character occupying one column.
 392 The default is to use screen columns, which requires that the compilation
 393 program and Emacs agree about the display width of the characters,
 394 especially the TAB character."
 395   :type 'boolean
 396   :group 'compilation
 397   :version "20.4")
 398
 399 (defcustom compilation-read-command t
 400   "*Non-nil means \\[compile] reads the compilation command to use.
 401 Otherwise, \\[compile] just uses the value of `compile-command'."
 402   :type 'boolean
 403   :group 'compilation)
 404
 405 ;;;###autoload
 406 (defcustom compilation-ask-about-save t
 407   "*Non-nil means \\[compile] asks which buffers to save before compiling.
 408 Otherwise, it saves all modified buffers without asking."
 409   :type 'boolean
 410   :group 'compilation)
 411
 412 ;;;###autoload
 413 (defcustom compilation-search-path '(nil)
 414   "*List of directories to search for source files named in error messages.
 415 Elements should be directory names, not file names of directories.
 416 nil as an element means to try the default directory."
 417   :type '(repeat (choice (const :tag "Default" nil)
 418                          (string :tag "Directory")))
 419   :group 'compilation)
 420
 421 (defcustom compile-command "make -k "
 422   "*Last shell command used to do a compilation; default for next compilation.
 423
 424 Sometimes it is useful for files to supply local values for this variable.
 425 You might also use mode hooks to specify it in certain modes, like this:
 426
 427     (add-hook 'c-mode-hook
 428        (lambda ()
 429          (unless (or (file-exists-p \"makefile\")
 430                      (file-exists-p \"Makefile\"))
 431            (set (make-local-variable 'compile-command)
 432                 (concat \"make -k \"
 433                         (file-name-sans-extension buffer-file-name))))))"
 434   :type 'string
 435   :group 'compilation)
 436
 437 ;; A weak per-compilation-buffer hash indexed by (FILENAME . DIRECTORY).  Each
 438 ;; value is a FILE-STRUCTURE as described above, with the car eq to the hash
 439 ;; key.  This holds the tree seen from root, for storing new nodes.
 440 (defvar compilation-locs ())
 441
 442 (defvar compilation-debug nil
 443   "*Set this to t before creating a *compilation* buffer.
 444 Then every error line will have a debug text property with the matcher that
 445 fit this line and the match data.  Use `describe-text-properties'.")
 446
 447 (defvar compilation-exit-message-function nil "\
 448 If non-nil, called when a compilation process dies to return a status message.
 449 This should be a function of three arguments: process status, exit status,
 450 and exit message; it returns a cons (MESSAGE . MODELINE) of the strings to
 451 write into the compilation buffer, and to put in its mode line.")
 452
 453 (defvar compilation-environment nil
 454   "*List of environment variables for compilation to inherit.
 455 Each element should be a string of the form ENVVARNAME=VALUE.
 456 This list is temporarily prepended to `process-environment' prior to
 457 starting the compilation process.")
 458
 459 ;; History of compile commands.
 460 (defvar compile-history nil)
 461
 462 (defface compilation-warning-face
 463   '((((class color) (min-colors 16)) (:foreground "Orange" :weight bold))
 464     (((class color)) (:foreground "cyan" :weight bold))
 465     (t (:weight bold)))
 466   "Face used to highlight compiler warnings."
 467   :group 'font-lock-highlighting-faces
 468   :version "21.4")
 469
 470 (defface compilation-info-face
 471   '((((class color) (min-colors 16) (background light))
 472      (:foreground "Green3" :weight bold))
 473     (((class color) (min-colors 16) (background dark))
 474      (:foreground "Green" :weight bold))
 475     (((class color)) (:foreground "green" :weight bold))
 476     (t (:weight bold)))
 477   "Face used to highlight compiler warnings."
 478   :group 'font-lock-highlighting-faces
 479   :version "21.4")
 480
 481 (defvar compilation-message-face nil
 482   "Face name to use for whole messages.
 483 Faces `compilation-error-face', `compilation-warning-face',
 484 `compilation-info-face', `compilation-line-face' and
 485 `compilation-column-face' get prepended to this, when applicable.")
 486
 487 (defvar compilation-error-face 'font-lock-warning-face
 488   "Face name to use for file name in error messages.")
 489
 490 (defvar compilation-warning-face 'compilation-warning-face
 491   "Face name to use for file name in warning messages.")
 492
 493 (defvar compilation-info-face 'compilation-info-face
 494   "Face name to use for file name in informational messages.")
 495
 496 (defvar compilation-line-face 'font-lock-variable-name-face
 497   "Face name to use for line number in message.")
 498
 499 (defvar compilation-column-face 'font-lock-type-face
 500   "Face name to use for column number in message.")
 501
 502 ;; same faces as dired uses
 503 (defvar compilation-enter-directory-face 'font-lock-function-name-face
 504   "Face name to use for column number in message.")
 505
 506 (defvar compilation-leave-directory-face 'font-lock-type-face
 507   "Face name to use for column number in message.")
 508
 509
 510
 511 ;; Used for compatibility with the old compile.el.
 512 (defvaralias 'compilation-last-buffer 'next-error-last-buffer)
 513 (defvar compilation-parsing-end (make-marker))
 514 (defvar compilation-parse-errors-function nil)
 515 (defvar compilation-error-list nil)
 516 (defvar compilation-old-error-list nil)
 517
 518 (defun compilation-face (type)
 519   (or (and (car type) (match-end (car type)) compilation-warning-face)
 520       (and (cdr type) (match-end (cdr type)) compilation-info-face)
 521       compilation-error-face))
 522
 523 (defun compilation-directory-properties (idx leave)
 524   (if leave (setq leave (match-end leave)))
 525   ;; find previous stack, and push onto it, or if `leave' pop it
 526   (let ((dir (previous-single-property-change (point) 'directory)))
 527     (setq dir (if dir (or (get-text-property (1- dir) 'directory)
 528                           (get-text-property dir 'directory))))
 529     `(face ,(if leave
 530                 compilation-leave-directory-face
 531               compilation-enter-directory-face)
 532       directory ,(if leave
 533                      (or (cdr dir)
 534                          '(nil))        ; nil only isn't a property-change
 535                    (cons (match-string-no-properties idx) dir))
 536       mouse-face highlight
 537       keymap compilation-button-map
 538       help-echo "mouse-2: visit current directory")))
 539
 540 ;; Data type `reverse-ordered-alist' retriever.  This function retrieves the
 541 ;; KEY element from the ALIST, creating it in the right position if not already
 542 ;; present. ALIST structure is
 543 ;; '(ANCHOR (KEY1 ...) (KEY2 ...)... (KEYn ALIST ...))
 544 ;; ANCHOR is ignored, but necessary so that elements can be inserted.  KEY1
 545 ;; may be nil.  The other KEYs are ordered backwards so that growing line
 546 ;; numbers can be inserted in front and searching can abort after half the
 547 ;; list on average.
 548 (eval-when-compile                  ;Don't keep it at runtime if not needed.
 549 (defmacro compilation-assq (key alist)
 550   `(let* ((l1 ,alist)
 551           (l2 (cdr l1)))
 552      (car (if (if (null ,key)
 553                   (if l2 (null (caar l2)))
 554                 (while (if l2 (if (caar l2) (< ,key (caar l2)) t))
 555                   (setq l1 l2
 556                         l2 (cdr l1)))
 557                 (if l2 (eq ,key (caar l2))))
 558               l2
 559             (setcdr l1 (cons (list ,key) l2)))))))
 560
 561
 562 ;; This function is the central driver, called when font-locking to gather
 563 ;; all information needed to later jump to corresponding source code.
 564 ;; Return a property list with all meta information on this error location.
 565 (defun compilation-error-properties (file line end-line col end-col type fmt)
 566   (unless (< (next-single-property-change (match-beginning 0) 'directory nil (point))
 567              (point))
 568     (if file
 569         (if (functionp file)
 570             (setq file (funcall file))
 571           (let (dir)
 572             (setq file (match-string-no-properties file))
 573             (unless (file-name-absolute-p file)
 574               (setq dir (previous-single-property-change (point) 'directory)
 575                     dir (if dir (or (get-text-property (1- dir) 'directory)
 576                                     (get-text-property dir 'directory)))))
 577             (setq file (cons file (car dir)))))
 578       ;; This message didn't mention one, get it from previous
 579       (setq file (previous-single-property-change (point) 'message)
 580             file (or (if file
 581                          (car (nth 2 (car (or (get-text-property (1- file) 'message)
 582                                          (get-text-property file 'message))))))
 583                      '("*unknown*"))))
 584     ;; All of these fields are optional, get them only if we have an index, and
 585     ;; it matched some part of the message.
 586     (and line
 587          (setq line (match-string-no-properties line))
 588          (setq line (string-to-number line)))
 589     (and end-line
 590          (setq end-line (match-string-no-properties end-line))
 591          (setq end-line (string-to-number end-line)))
 592     (if col
 593         (if (functionp col)
 594             (setq col (funcall col))
 595           (and
 596            (setq col (match-string-no-properties col))
 597            (setq col (- (string-to-number col) compilation-first-column)))))
 598     (if (and end-col (functionp end-col))
 599         (setq end-col (funcall end-col))
 600       (if (and end-col (setq end-col (match-string-no-properties end-col)))
 601           (setq end-col (- (string-to-number end-col) compilation-first-column -1))
 602         (if end-line (setq end-col -1))))
 603     (if (consp type)                    ; not a static type, check what it is.
 604         (setq type (or (and (car type) (match-end (car type)) 1)
 605                        (and (cdr type) (match-end (cdr type)) 0)
 606                        2)))
 607     (compilation-internal-error-properties file line end-line col end-col type fmt)))
 608
 609 (defun compilation-move-to-column (col screen)
 610   "Go to column COL on the current line.
 611 If SCREEN is non-nil, columns are screen columns, otherwise, they are
 612 just char-counts."
 613   (if screen
 614       (move-to-column col)
 615     (goto-char (min (+ (line-beginning-position) col) (line-end-position)))))
 616
 617 (defun compilation-internal-error-properties (file line end-line col end-col type fmt)
 618   "Get the meta-info that will be added as text-properties.
 619 LINE, END-LINE, COL, END-COL are integers or nil.
 620 TYPE can be 0, 1, or 2.
 621 FILE should be (ABSOLUTE-FILENAME) or (RELATIVE-FILENAME . DIRNAME) or nil."
 622   (unless file (setq file '("*unknown*")))
 623   (setq file (compilation-get-file-structure file fmt))
 624   ;; Get first already existing marker (if any has one, all have one).
 625   ;; Do this first, as the compilation-assq`s may create new nodes.
 626   (let* ((marker-line (car (cddr file)))        ; a line structure
 627          (marker (nth 3 (cadr marker-line)))    ; its marker
 628          (compilation-error-screen-columns compilation-error-screen-columns)
 629          end-marker loc end-loc)
 630     (if (not (and marker (marker-buffer marker)))
 631         (setq marker)                   ; no valid marker for this file
 632       (setq loc (or line 1))            ; normalize no linenumber to line 1
 633       (catch 'marker                    ; find nearest loc, at least one exists
 634         (dolist (x (nthcdr 3 file))     ; loop over remaining lines
 635           (if (> (car x) loc)           ; still bigger
 636               (setq marker-line x)
 637             (if (> (- (or (car marker-line) 1) loc)
 638                    (- loc (car x)))     ; current line is nearer
 639                 (setq marker-line x))
 640             (throw 'marker t))))
 641       (setq marker (nth 3 (cadr marker-line))
 642             marker-line (or (car marker-line) 1))
 643       (with-current-buffer (marker-buffer marker)
 644         (save-restriction
 645           (widen)
 646           (goto-char (marker-position marker))
 647           (when (or end-col end-line)
 648             (beginning-of-line (- (or end-line line) marker-line -1))
 649             (if (or (null end-col) (< end-col 0))
 650                 (end-of-line)
 651               (compilation-move-to-column
 652                end-col compilation-error-screen-columns))
 653             (setq end-marker (list (point-marker))))
 654           (beginning-of-line (if end-line
 655                                  (- line end-line -1)
 656                                (- loc marker-line -1)))
 657           (if col
 658               (compilation-move-to-column
 659                col compilation-error-screen-columns)
 660             (forward-to-indentation 0))
 661           (setq marker (list (point-marker))))))
 662
 663     (setq loc (compilation-assq line (cdr file)))
 664     (if end-line
 665         (setq end-loc (compilation-assq end-line (cdr file))
 666               end-loc (compilation-assq end-col end-loc))
 667       (if end-col                       ; use same line element
 668           (setq end-loc (compilation-assq end-col loc))))
 669     (setq loc (compilation-assq col loc))
 670     ;; If they are new, make the loc(s) reference the file they point to.
 671     (or (cdr loc) (setcdr loc `(,line ,file ,@marker)))
 672     (if end-loc
 673         (or (cdr end-loc) (setcdr end-loc `(,(or end-line line) ,file ,@end-marker))))
 674
 675     ;; Must start with face
 676     `(face ,compilation-message-face
 677            message (,loc ,type ,end-loc)
 678            ,@(if compilation-debug
 679                  `(debug (,(assoc (with-no-warnings matcher) font-lock-keywords)
 680                           ,@(match-data))))
 681            help-echo ,(if col
 682                           "mouse-2: visit this file, line and column"
 683                         (if line
 684                             "mouse-2: visit this file and line"
 685                           "mouse-2: visit this file"))
 686            keymap compilation-button-map
 687            mouse-face highlight)))
 688
 689 (defun compilation-mode-font-lock-keywords ()
 690   "Return expressions to highlight in Compilation mode."
 691   (if compilation-parse-errors-function
 692       ;; An old package!  Try the compatibility code.
 693       '((compilation-compat-parse-errors))
 694     (append
 695      ;; make directory tracking
 696      (if compilation-directory-matcher
 697          `((,(car compilation-directory-matcher)
 698             ,@(mapcar (lambda (elt)
 699                         `(,(car elt)
 700                           (compilation-directory-properties
 701                            ,(car elt) ,(cdr elt))
 702                           t))
 703                       (cdr compilation-directory-matcher)))))
 704
 705      ;; Compiler warning/error lines.
 706      (mapcar
 707       (lambda (item)
 708         (if (symbolp item)
 709             (setq item (cdr (assq item
 710                                   compilation-error-regexp-alist-alist))))
 711         (let ((file (nth 1 item))
 712               (line (nth 2 item))
 713               (col (nth 3 item))
 714               (type (nth 4 item))
 715               end-line end-col fmt)
 716           (if (consp file)      (setq fmt (cdr file)      file (car file)))
 717           (if (consp line)      (setq end-line (cdr line) line (car line)))
 718           (if (consp col)       (setq end-col (cdr col)   col (car col)))
 719
 720           (if (functionp line)
 721               ;; The old compile.el had here an undocumented hook that
 722               ;; allowed `line' to be a function that computed the actual
 723               ;; error location.  Let's do our best.
 724               `(,(car item)
 725                 (0 (compilation-compat-error-properties
 726                     (funcall ',line (cons (match-string ,file)
 727                                           (cons default-directory
 728                                                 ',(nthcdr 4 item)))
 729                              ,(if col `(match-string ,col)))))
 730                 (,file compilation-error-face t))
 731
 732             (unless (or (null (nth 5 item)) (integerp (nth 5 item)))
 733               (error "HYPERLINK should be an integer: %s" (nth 5 item)))
 734
 735             `(,(nth 0 item)
 736
 737               ,@(when (integerp file)
 738                   `((,file ,(if (consp type)
 739                                 `(compilation-face ',type)
 740                               (aref [compilation-info-face
 741                                      compilation-warning-face
 742                                      compilation-error-face]
 743                                     (or type 2))))))
 744
 745               ,@(when line
 746                   `((,line compilation-line-face nil t)))
 747               ,@(when end-line
 748                   `((,end-line compilation-line-face nil t)))
 749
 750               ,@(when (integerp col)
 751                   `((,col compilation-column-face nil t)))
 752               ,@(when (integerp end-col)
 753                   `((,end-col compilation-column-face nil t)))
 754
 755               ,@(nthcdr 6 item)
 756               (,(or (nth 5 item) 0)
 757                (compilation-error-properties ',file ,line ,end-line
 758                                              ,col ,end-col ',(or type 2)
 759                                              ',fmt)
 760                append)))))              ; for compilation-message-face
 761       compilation-error-regexp-alist)
 762
 763      compilation-mode-font-lock-keywords)))
 764
 765 \f
 766 ;;;###autoload
 767 (defun compile (command &optional comint)
 768   "Compile the program including the current buffer.  Default: run `make'.
 769 Runs COMMAND, a shell command, in a separate process asynchronously
 770 with output going to the buffer `*compilation*'.
 771
 772 If optional second arg COMINT is t the buffer will be in Comint mode with
 773 `compilation-shell-minor-mode'.
 774
 775 You can then use the command \\[next-error] to find the next error message
 776 and move to the source code that caused it.
 777
 778 Interactively, prompts for the command if `compilation-read-command' is
 779 non-nil; otherwise uses `compile-command'.  With prefix arg, always prompts.
 780 Additionally, with universal prefix arg, compilation buffer will be in
 781 comint mode, i.e. interactive.
 782
 783 To run more than one compilation at once, start one and rename
 784 the \`*compilation*' buffer to some other name with
 785 \\[rename-buffer].  Then start the next one.  On most systems,
 786 termination of the main compilation process kills its
 787 subprocesses.
 788
 789 The name used for the buffer is actually whatever is returned by
 790 the function in `compilation-buffer-name-function', so you can set that
 791 to a function that generates a unique name."
 792   (interactive
 793    (list
 794     (let ((command (eval compile-command)))
 795       (if (or compilation-read-command current-prefix-arg)
 796           (read-from-minibuffer "Compile command: "
 797                                 command nil nil
 798                                 (if (equal (car compile-history) command)
 799                                     '(compile-history . 1)
 800                                   'compile-history))
 801         command))
 802     (consp current-prefix-arg)))
 803   (unless (equal command (eval compile-command))
 804     (setq compile-command command))
 805   (save-some-buffers (not compilation-ask-about-save) nil)
 806   (setq compilation-directory default-directory)
 807   (compilation-start command comint))
 808
 809 ;; run compile with the default command line
 810 (defun recompile ()
 811   "Re-compile the program including the current buffer.
 812 If this is run in a Compilation mode buffer, re-use the arguments from the
 813 original use.  Otherwise, recompile using `compile-command'."
 814   (interactive)
 815   (save-some-buffers (not compilation-ask-about-save) nil)
 816   (let ((default-directory
 817           (or (and (not (eq major-mode (nth 1 compilation-arguments)))
 818                    compilation-directory)
 819               default-directory)))
 820     (apply 'compilation-start (or compilation-arguments
 821                                   `(,(eval compile-command))))))
 822
 823 (defcustom compilation-scroll-output nil
 824   "*Non-nil to scroll the *compilation* buffer window as output appears.
 825
 826 Setting it causes the Compilation mode commands to put point at the
 827 end of their output window so that the end of the output is always
 828 visible rather than the beginning."
 829   :type 'boolean
 830   :version "20.3"
 831   :group 'compilation)
 832
 833
 834 (defun compilation-buffer-name (mode-name name-function)
 835   "Return the name of a compilation buffer to use.
 836 If NAME-FUNCTION is non-nil, call it with one argument MODE-NAME
 837 to determine the buffer name.
 838 Likewise if `compilation-buffer-name-function' is non-nil.
 839 If current buffer is in Compilation mode for the same mode name
 840 return the name of the current buffer, so that it gets reused.
 841 Otherwise, construct a buffer name from MODE-NAME."
 842   (cond (name-function
 843          (funcall name-function mode-name))
 844         (compilation-buffer-name-function
 845          (funcall compilation-buffer-name-function mode-name))
 846         ((eq major-mode (nth 1 compilation-arguments))
 847          (buffer-name))
 848         (t
 849          (concat "*" (downcase mode-name) "*"))))
 850
 851 ;; This is a rough emulation of the old hack, until the transition to new
 852 ;; compile is complete.
 853 (defun compile-internal (command error-message
 854                                  &optional name-of-mode parser
 855                                  error-regexp-alist name-function
 856                                  enter-regexp-alist leave-regexp-alist
 857                                  file-regexp-alist nomessage-regexp-alist
 858                                  no-async highlight-regexp local-map)
 859   (if parser
 860       (error "Compile now works very differently, see `compilation-error-regexp-alist'"))
 861   (let ((compilation-error-regexp-alist
 862          (append file-regexp-alist (or error-regexp-alist
 863                                        compilation-error-regexp-alist)))
 864         (compilation-error (replace-regexp-in-string "^No more \\(.+\\)s\\.?"
 865                                                      "\\1" error-message)))
 866     (compilation-start command nil name-function highlight-regexp)))
 867 (make-obsolete 'compile-internal 'compilation-start)
 868
 869 (defun compilation-start (command &optional mode name-function highlight-regexp)
 870   "Run compilation command COMMAND (low level interface).
 871 If COMMAND starts with a cd command, that becomes the `default-directory'.
 872 The rest of the arguments are optional; for them, nil means use the default.
 873
 874 MODE is the major mode to set in the compilation buffer.  Mode
 875 may also be t meaning use `compilation-shell-minor-mode' under `comint-mode'.
 876 NAME-FUNCTION is a function called to name the buffer.
 877
 878 If HIGHLIGHT-REGEXP is non-nil, `next-error' will temporarily highlight
 879 the matching section of the visited source line; the default is to use the
 880 global value of `compilation-highlight-regexp'.
 881
 882 Returns the compilation buffer created."
 883   (or mode (setq mode 'compilation-mode))
 884   (let* ((name-of-mode
 885           (if (eq mode t)
 886               (prog1 "compilation" (require 'comint))
 887             (replace-regexp-in-string "-mode$" "" (symbol-name mode))))
 888          (thisdir default-directory)
 889          outwin outbuf)
 890     (with-current-buffer
 891         (setq outbuf
 892               (get-buffer-create
 893                (compilation-buffer-name name-of-mode name-function)))
 894       (let ((comp-proc (get-buffer-process (current-buffer))))
 895         (if comp-proc
 896             (if (or (not (eq (process-status comp-proc) 'run))
 897                     (yes-or-no-p
 898                      (format "A %s process is running; kill it? "
 899                              name-of-mode)))
 900                 (condition-case ()
 901                     (progn
 902                       (interrupt-process comp-proc)
 903                       (sit-for 1)
 904                       (delete-process comp-proc))
 905                   (error nil))
 906               (error "Cannot have two processes in `%s' at once"
 907                      (buffer-name)))))
 908       (buffer-disable-undo (current-buffer))
 909       ;; first transfer directory from where M-x compile was called
 910       (setq default-directory thisdir)
 911       ;; Make compilation buffer read-only.  The filter can still write it.
 912       ;; Clear out the compilation buffer.
 913       (let ((inhibit-read-only t)
 914             (default-directory thisdir))
 915         ;; Then evaluate a cd command if any, but don't perform it yet, else start-command
 916         ;; would do it again through the shell: (cd "..") AND sh -c "cd ..; make"
 917         (cd (if (string-match "^\\s *cd\\(?:\\s +\\(\\S +?\\)\\)?\\s *[;&\n]" command)
 918                 (if (match-end 1)
 919                     (match-string 1 command)
 920                   "~")
 921               default-directory))
 922         (erase-buffer)
 923         ;; output a mode setter, for saving and later reloading this buffer
 924         (insert "-*- mode: " name-of-mode
 925                 "; default-directory: " (prin1-to-string default-directory)
 926                 " -*-\n" command "\n")
 927         (setq thisdir default-directory))
 928       (set-buffer-modified-p nil))
 929     ;; If we're already in the compilation buffer, go to the end
 930     ;; of the buffer, so point will track the compilation output.
 931     (if (eq outbuf (current-buffer))
 932         (goto-char (point-max)))
 933     ;; Pop up the compilation buffer.
 934     (setq outwin (display-buffer outbuf nil t))
 935     (with-current-buffer outbuf
 936       (let ((process-environment
 937              (append
 938               compilation-environment
 939               (if (if (boundp 'system-uses-terminfo) ; `if' for compiler warning
 940                       system-uses-terminfo)
 941                   (list "TERM=dumb" "TERMCAP="
 942                         (format "COLUMNS=%d" (window-width)))
 943                 (list "TERM=emacs"
 944                       (format "TERMCAP=emacs:co#%d:tc=unknown:"
 945                               (window-width))))
 946               ;; Set the EMACS variable, but
 947               ;; don't override users' setting of $EMACS.
 948               (unless (getenv "EMACS") '("EMACS=t"))
 949               (copy-sequence process-environment))))
 950         (if (not (eq mode t))
 951             (funcall mode)
 952           (setq buffer-read-only nil)
 953           (with-no-warnings (comint-mode))
 954           (compilation-shell-minor-mode))
 955         (if highlight-regexp
 956             (set (make-local-variable 'compilation-highlight-regexp)
 957                  highlight-regexp))
 958         (set (make-local-variable 'compilation-arguments)
 959              (list command mode name-function highlight-regexp))
 960         (set (make-local-variable 'revert-buffer-function)
 961              'compilation-revert-buffer)
 962         (set-window-start outwin (point-min))
 963         (or (eq outwin (selected-window))
 964             (set-window-point outwin (if compilation-scroll-output
 965                                          (point)
 966                                        (point-min))))
 967         ;; The setup function is called before compilation-set-window-height
 968         ;; so it can set the compilation-window-height buffer locally.
 969         (if compilation-process-setup-function
 970             (funcall compilation-process-setup-function))
 971         (compilation-set-window-height outwin)
 972         ;; Start the compilation.
 973         (if (fboundp 'start-process)
 974             (let ((proc (if (eq mode t)
 975                             (get-buffer-process
 976                              (with-no-warnings
 977                               (comint-exec outbuf (downcase mode-name)
 978                                            shell-file-name nil `("-c" ,command))))
 979                           (start-process-shell-command (downcase mode-name)
 980                                                        outbuf command))))
 981               ;; Make the buffer's mode line show process state.
 982               (setq mode-line-process '(":%s"))
 983               (set-process-sentinel proc 'compilation-sentinel)
 984               (set-process-filter proc 'compilation-filter)
 985               (set-marker (process-mark proc) (point) outbuf)
 986               (setq compilation-in-progress
 987                     (cons proc compilation-in-progress)))
 988           ;; No asynchronous processes available.
 989           (message "Executing `%s'..." command)
 990           ;; Fake modeline display as if `start-process' were run.
 991           (setq mode-line-process ":run")
 992           (force-mode-line-update)
 993           (sit-for 0)                   ; Force redisplay
 994           (let ((status (call-process shell-file-name nil outbuf nil "-c"
 995                                       command)))
 996             (cond ((numberp status)
 997                    (compilation-handle-exit 'exit status
 998                                             (if (zerop status)
 999                                                 "finished\n"
1000                                               (format "\
1001 exited abnormally with code %d\n"
1002                                                       status))))
1003                   ((stringp status)
1004                    (compilation-handle-exit 'signal status
1005                                             (concat status "\n")))
1006                   (t
1007                    (compilation-handle-exit 'bizarre status status))))
1008           ;; Without async subprocesses, the buffer is not yet
1009           ;; fontified, so fontify it now.
1010           (let ((font-lock-verbose nil)) ; shut up font-lock messages
1011             (font-lock-fontify-buffer))
1012           (message "Executing `%s'...done" command)))
1013       ;; Now finally cd to where the shell started make/grep/...
1014       (setq default-directory thisdir))
1015     (if (buffer-local-value 'compilation-scroll-output outbuf)
1016         (save-selected-window
1017           (select-window outwin)
1018           (goto-char (point-max))))
1019     ;; Make it so the next C-x ` will use this buffer.
1020     (setq next-error-last-buffer outbuf)))
1021
1022 (defun compilation-set-window-height (window)
1023   "Set the height of WINDOW according to `compilation-window-height'."
1024   (let ((height (buffer-local-value 'compilation-window-height (window-buffer window))))
1025     (and height
1026          (= (window-width window) (frame-width (window-frame window)))
1027          ;; If window is alone in its frame, aside from a minibuffer,
1028          ;; don't change its height.
1029          (not (eq window (frame-root-window (window-frame window))))
1030          ;; Stef said that doing the saves in this order is safer:
1031          (save-excursion
1032            (save-selected-window
1033              (select-window window)
1034              (enlarge-window (- height (window-height))))))))
1035
1036 (defvar compilation-menu-map
1037   (let ((map (make-sparse-keymap "Errors")))
1038     (define-key map [stop-subjob]
1039       '("Stop Compilation" . kill-compilation))
1040     (define-key map [compilation-mode-separator2]
1041       '("----" . nil))
1042     (define-key map [compilation-first-error]
1043       '("First Error" . first-error))
1044     (define-key map [compilation-previous-error]
1045       '("Previous Error" . previous-error))
1046     (define-key map [compilation-next-error]
1047       '("Next Error" . next-error))
1048     map))
1049
1050 (defvar compilation-minor-mode-map
1051   (let ((map (make-sparse-keymap)))
1052     (define-key map [mouse-2] 'compile-goto-error)
1053     (define-key map "\C-c\C-c" 'compile-goto-error)
1054     (define-key map "\C-m" 'compile-goto-error)
1055     (define-key map "\C-c\C-k" 'kill-compilation)
1056     (define-key map "\M-n" 'compilation-next-error)
1057     (define-key map "\M-p" 'compilation-previous-error)
1058     (define-key map "\M-{" 'compilation-previous-file)
1059     (define-key map "\M-}" 'compilation-next-file)
1060     ;; Set up the menu-bar
1061     (define-key map [menu-bar compilation]
1062       (cons "Errors" compilation-menu-map))
1063     map)
1064   "Keymap for `compilation-minor-mode'.")
1065
1066 (defvar compilation-shell-minor-mode-map
1067   (let ((map (make-sparse-keymap)))
1068     (define-key map "\M-\C-m" 'compile-goto-error)
1069     (define-key map "\M-\C-n" 'compilation-next-error)
1070     (define-key map "\M-\C-p" 'compilation-previous-error)
1071     (define-key map "\M-{" 'compilation-previous-file)
1072     (define-key map "\M-}" 'compilation-next-file)
1073     ;; Set up the menu-bar
1074     (define-key map [menu-bar compilation]
1075       (cons "Errors" compilation-menu-map))
1076     map)
1077   "Keymap for `compilation-shell-minor-mode'.")
1078
1079 (defvar compilation-button-map
1080   (let ((map (make-sparse-keymap)))
1081     (define-key map [mouse-2] 'compile-goto-error)
1082     (define-key map "\C-m" 'compile-goto-error)
1083     map)
1084   "Keymap for compilation-message buttons.")
1085 (fset 'compilation-button-map compilation-button-map)
1086
1087 (defvar compilation-mode-map
1088   (let ((map (make-sparse-keymap)))
1089     (set-keymap-parent map compilation-minor-mode-map)
1090     (define-key map " " 'scroll-up)
1091     (define-key map "\^?" 'scroll-down)
1092     (define-key map "\C-c\C-f" 'next-error-follow-minor-mode)
1093
1094     ;; Set up the menu-bar
1095     (define-key map [menu-bar compilation]
1096       (cons "Compile" (make-sparse-keymap "Compile")))
1097     (define-key map [menu-bar compilation compilation-separator2]
1098       '("----" . nil))
1099     (define-key map [menu-bar compilation compilation-grep]
1100       '("Search Files (grep)" . grep))
1101     (define-key map [menu-bar compilation compilation-recompile]
1102       '("Recompile" . recompile))
1103     (define-key map [menu-bar compilation compilation-compile]
1104       '("Compile..." . compile))
1105     map)
1106   "Keymap for compilation log buffers.
1107 `compilation-minor-mode-map' is a parent of this.")
1108
1109 (put 'compilation-mode 'mode-class 'special)
1110
1111 (defvar compilation-skip-to-next-location t
1112   "*If non-nil, skip multiple error messages for the same source location.")
1113
1114 (defcustom compilation-skip-threshold 1
1115   "*Compilation motion commands skip less important messages.
1116 The value can be either 2 -- skip anything less than error, 1 --
1117 skip anything less than warning or 0 -- don't skip any messages.
1118 Note that all messages not positively identified as warning or
1119 info, are considered errors."
1120   :type '(choice (const :tag "Warnings and info" 2)
1121                  (const :tag "Info" 1)
1122                  (const :tag "None" 0))
1123   :group 'compilation
1124   :version "21.4")
1125
1126 (defcustom compilation-skip-visited nil
1127   "*Compilation motion commands skip visited messages if this is t.
1128 Visited messages are ones for which the file, line and column have been jumped
1129 to from the current content in the current compilation buffer, even if it was
1130 from a different message."
1131   :type 'boolean
1132   :group 'compilation
1133   :version "21.4")
1134
1135 ;;;###autoload
1136 (defun compilation-mode (&optional name-of-mode)
1137   "Major mode for compilation log buffers.
1138 \\<compilation-mode-map>To visit the source for a line-numbered error,
1139 move point to the error message line and type \\[compile-goto-error].
1140 To kill the compilation, type \\[kill-compilation].
1141
1142 Runs `compilation-mode-hook' with `run-hooks' (which see).
1143
1144 \\{compilation-mode-map}"
1145   (interactive)
1146   (kill-all-local-variables)
1147   (use-local-map compilation-mode-map)
1148   (setq major-mode 'compilation-mode
1149         mode-name (or name-of-mode "Compilation"))
1150   (set (make-local-variable 'page-delimiter)
1151        compilation-page-delimiter)
1152   (compilation-setup)
1153   (run-mode-hooks 'compilation-mode-hook))
1154
1155 (defmacro define-compilation-mode (mode name doc &rest body)
1156   "This is like `define-derived-mode' without the PARENT argument.
1157 The parent is always `compilation-mode' and the customizable `compilation-...'
1158 variables are also set from the name of the mode you have chosen, by replacing
1159 the fist word, e.g `compilation-scroll-output' from `grep-scroll-output' if that
1160 variable exists."
1161   (let ((mode-name (replace-regexp-in-string "-mode\\'" "" (symbol-name mode))))
1162     `(define-derived-mode ,mode compilation-mode ,name
1163        ,doc
1164        ,@(mapcar (lambda (v)
1165                    (setq v (cons v
1166                                  (intern-soft (replace-regexp-in-string
1167                                                "^compilation" mode-name
1168                                                (symbol-name v)))))
1169                    (and (cdr v)
1170                         (or (boundp (cdr v))
1171                             (if (boundp 'byte-compile-bound-variables)
1172                                 (memq (cdr v) byte-compile-bound-variables)))
1173                         `(set (make-local-variable ',(car v)) ,(cdr v))))
1174                  '(compilation-buffer-name-function
1175                    compilation-directory-matcher
1176                    compilation-error
1177                    compilation-error-regexp-alist
1178                    compilation-error-regexp-alist-alist
1179                    compilation-error-screen-columns
1180                    compilation-finish-function
1181                    compilation-finish-functions
1182                    compilation-first-column
1183                    compilation-mode-font-lock-keywords
1184                    compilation-page-delimiter
1185                    compilation-parse-errors-filename-function
1186                    compilation-process-setup-function
1187                    compilation-scroll-output
1188                    compilation-search-path
1189                    compilation-skip-threshold
1190                    compilation-window-height))
1191        ,@body)))
1192
1193 (defun compilation-revert-buffer (ignore-auto noconfirm)
1194   (if buffer-file-name
1195       (let (revert-buffer-function)
1196         (revert-buffer ignore-auto noconfirm))
1197     (if (or noconfirm (yes-or-no-p (format "Restart compilation? ")))
1198         (apply 'compilation-start compilation-arguments))))
1199
1200 (defvar compilation-current-error nil
1201   "Marker to the location from where the next error will be found.
1202 The global commands next/previous/first-error/goto-error use this.")
1203
1204 (defvar compilation-messages-start nil
1205   "Buffer position of the beginning of the compilation messages.
1206 If nil, use the beginning of buffer.")
1207
1208 ;; A function name can't be a hook, must be something with a value.
1209 (defconst compilation-turn-on-font-lock 'turn-on-font-lock)
1210
1211 (defun compilation-setup (&optional minor)
1212   "Prepare the buffer for the compilation parsing commands to work.
1213 Optional argument MINOR indicates this is called from
1214 `compilation-minor-mode'."
1215   (unless minor
1216     (setq buffer-read-only t))
1217   (make-local-variable 'compilation-current-error)
1218   (make-local-variable 'compilation-messages-start)
1219   (make-local-variable 'compilation-error-screen-columns)
1220   (make-local-variable 'overlay-arrow-position)
1221   ;; Note that compilation-next-error-function is for interfacing
1222   ;; with the next-error function in simple.el, and it's only
1223   ;; coincidentally named similarly to compilation-next-error.
1224   (setq next-error-function 'compilation-next-error-function)
1225   (set (make-local-variable 'font-lock-extra-managed-props)
1226        '(directory message help-echo mouse-face debug))
1227   (set (make-local-variable 'compilation-locs)
1228        (make-hash-table :test 'equal :weakness 'value))
1229   ;; lazy-lock would never find the message unless it's scrolled to.
1230   ;; jit-lock might fontify some things too late.
1231   (set (make-local-variable 'font-lock-support-mode) nil)
1232   (set (make-local-variable 'font-lock-maximum-size) nil)
1233   (let ((fld font-lock-defaults))
1234     (if (and minor fld)
1235         (font-lock-add-keywords nil (compilation-mode-font-lock-keywords))
1236       (setq font-lock-defaults '(compilation-mode-font-lock-keywords t)))
1237     (if minor
1238         (if font-lock-mode
1239             (if fld
1240                 (font-lock-fontify-buffer)
1241               (font-lock-change-mode)
1242               (turn-on-font-lock))
1243           (turn-on-font-lock))
1244       ;; maybe defer font-lock till after derived mode is set up
1245       (run-mode-hooks 'compilation-turn-on-font-lock))))
1246
1247 ;;;###autoload
1248 (define-minor-mode compilation-shell-minor-mode
1249   "Toggle compilation shell minor mode.
1250 With arg, turn compilation mode on if and only if arg is positive.
1251 In this minor mode, all the error-parsing commands of the
1252 Compilation major mode are available but bound to keys that don't
1253 collide with Shell mode.  See `compilation-mode'.
1254 Turning the mode on runs the normal hook `compilation-shell-minor-mode-hook'."
1255   nil " Shell-Compile"
1256   :group 'compilation
1257   (if compilation-shell-minor-mode
1258       (compilation-setup t)
1259     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1260     (font-lock-fontify-buffer)))
1261
1262 ;;;###autoload
1263 (define-minor-mode compilation-minor-mode
1264   "Toggle compilation minor mode.
1265 With arg, turn compilation mode on if and only if arg is positive.
1266 In this minor mode, all the error-parsing commands of the
1267 Compilation major mode are available.  See `compilation-mode'.
1268 Turning the mode on runs the normal hook `compilation-minor-mode-hook'."
1269   nil " Compilation"
1270   :group 'compilation
1271   (if compilation-minor-mode
1272       (compilation-setup t)
1273     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1274     (font-lock-fontify-buffer)))
1275
1276 (defun compilation-handle-exit (process-status exit-status msg)
1277   "Write MSG in the current buffer and hack its mode-line-process."
1278   (let ((inhibit-read-only t)
1279         (status (if compilation-exit-message-function
1280                     (funcall compilation-exit-message-function
1281                              process-status exit-status msg)
1282                   (cons msg exit-status)))
1283         (omax (point-max))
1284         (opoint (point)))
1285     ;; Record where we put the message, so we can ignore it later on.
1286     (goto-char omax)
1287     (insert ?\n mode-name " " (car status))
1288     (if (and (numberp compilation-window-height)
1289              (zerop compilation-window-height))
1290         (message "%s" (cdr status)))
1291     (if (bolp)
1292         (forward-char -1))
1293     (insert " at " (substring (current-time-string) 0 19))
1294     (goto-char (point-max))
1295     ;; Prevent that message from being recognized as a compilation error.
1296     (add-text-properties omax (point)
1297                          (append '(compilation-handle-exit t) nil))
1298     (setq mode-line-process (format ":%s [%s]" process-status (cdr status)))
1299     ;; Force mode line redisplay soon.
1300     (force-mode-line-update)
1301     (if (and opoint (< opoint omax))
1302         (goto-char opoint))
1303     (if compilation-finish-function
1304         (funcall compilation-finish-function (current-buffer) msg))
1305     (let ((functions compilation-finish-functions))
1306       (while functions
1307         (funcall (car functions) (current-buffer) msg)
1308         (setq functions (cdr functions))))))
1309
1310 ;; Called when compilation process changes state.
1311 (defun compilation-sentinel (proc msg)
1312   "Sentinel for compilation buffers."
1313   (if (memq (process-status proc) '(exit signal))
1314       (let ((buffer (process-buffer proc)))
1315         (if (null (buffer-name buffer))
1316             ;; buffer killed
1317             (set-process-buffer proc nil)
1318           (with-current-buffer buffer
1319             ;; Write something in the compilation buffer
1320             ;; and hack its mode line.
1321             (compilation-handle-exit (process-status proc)
1322                                      (process-exit-status proc)
1323                                      msg)
1324             ;; Since the buffer and mode line will show that the
1325             ;; process is dead, we can delete it now.  Otherwise it
1326             ;; will stay around until M-x list-processes.
1327             (delete-process proc)))
1328         (setq compilation-in-progress (delq proc compilation-in-progress)))))
1329
1330 (defun compilation-filter (proc string)
1331   "Process filter for compilation buffers.
1332 Just inserts the text, but uses `insert-before-markers'."
1333   (if (buffer-name (process-buffer proc))
1334       (with-current-buffer (process-buffer proc)
1335         (let ((inhibit-read-only t))
1336           (save-excursion
1337             (goto-char (process-mark proc))
1338             (insert-before-markers string)
1339             (run-hooks 'compilation-filter-hook))))))
1340
1341 ;;; test if a buffer is a compilation buffer, assuming we're in the buffer
1342 (defsubst compilation-buffer-internal-p ()
1343   "Test if inside a compilation buffer."
1344   (local-variable-p 'compilation-locs))
1345
1346 ;;; test if a buffer is a compilation buffer, using compilation-buffer-internal-p
1347 (defsubst compilation-buffer-p (buffer)
1348   "Test if BUFFER is a compilation buffer."
1349   (with-current-buffer buffer
1350     (compilation-buffer-internal-p)))
1351
1352 (defmacro compilation-loop (< property-change 1+ error)
1353   `(while (,< n 0)
1354       (or (setq pt (,property-change pt 'message))
1355           (error ,error compilation-error))
1356       ;; prop 'message usually has 2 changes, on and off, so re-search if off
1357       (or (setq msg (get-text-property pt 'message))
1358           (if (setq pt (,property-change pt 'message))
1359               (setq msg (get-text-property pt 'message)))
1360           (error ,error compilation-error))
1361       (or (< (cadr msg) compilation-skip-threshold)
1362           (if different-file
1363               (eq (prog1 last (setq last (nth 2 (car msg))))
1364                   last))
1365           (if compilation-skip-visited
1366               (nthcdr 4 (car msg)))
1367           (if compilation-skip-to-next-location
1368               (eq (car msg) loc))
1369           ;; count this message only if none of the above are true
1370           (setq n (,1+ n)))))
1371
1372 (defun compilation-next-error (n &optional different-file pt)
1373   "Move point to the next error in the compilation buffer.
1374 Prefix arg N says how many error messages to move forwards (or
1375 backwards, if negative).
1376 Does NOT find the source line like \\[next-error]."
1377   (interactive "p")
1378   (or (compilation-buffer-p (current-buffer))
1379       (error "Not in a compilation buffer"))
1380   (or pt (setq pt (point)))
1381   (let* ((msg (get-text-property pt 'message))
1382          (loc (car msg))
1383          last)
1384     (if (zerop n)
1385         (unless (or msg                 ; find message near here
1386                     (setq msg (get-text-property (max (1- pt) (point-min))
1387                                                  'message)))
1388           (setq pt (previous-single-property-change pt 'message nil
1389                                                     (line-beginning-position)))
1390           (unless (setq msg (get-text-property (max (1- pt) (point-min)) 'message))
1391             (setq pt (next-single-property-change pt 'message nil
1392                                                   (line-end-position)))
1393             (or (setq msg (get-text-property pt 'message))
1394                 (setq pt (point)))))
1395       (setq last (nth 2 (car msg)))
1396       (if (>= n 0)
1397           (compilation-loop > next-single-property-change 1-
1398                             (if (get-buffer-process (current-buffer))
1399                                 "No more %ss yet"
1400                               "Moved past last %s"))
1401         ;; Don't move "back" to message at or before point.
1402         ;; Pass an explicit (point-min) to make sure pt is non-nil.
1403         (setq pt (previous-single-property-change pt 'message nil (point-min)))
1404         (compilation-loop < previous-single-property-change 1+
1405                           "Moved back before first %s")))
1406     (goto-char pt)
1407     (or msg
1408         (error "No %s here" compilation-error))))
1409
1410 (defun compilation-previous-error (n)
1411   "Move point to the previous error in the compilation buffer.
1412 Prefix arg N says how many error messages to move backwards (or
1413 forwards, if negative).
1414 Does NOT find the source line like \\[previous-error]."
1415   (interactive "p")
1416   (compilation-next-error (- n)))
1417
1418 (defun compilation-next-file (n)
1419   "Move point to the next error for a different file than the current one.
1420 Prefix arg N says how many files to move forwards (or backwards, if negative)."
1421   (interactive "p")
1422   (compilation-next-error n t))
1423
1424 (defun compilation-previous-file (n)
1425   "Move point to the previous error for a different file than the current one.
1426 Prefix arg N says how many files to move backwards (or forwards, if negative)."
1427   (interactive "p")
1428   (compilation-next-file (- n)))
1429
1430 (defun kill-compilation ()
1431   "Kill the process made by the \\[compile] or \\[grep] commands."
1432   (interactive)
1433   (let ((buffer (compilation-find-buffer)))
1434     (if (get-buffer-process buffer)
1435         (interrupt-process (get-buffer-process buffer))
1436       (error "The compilation process is not running"))))
1437
1438 (defalias 'compile-mouse-goto-error 'compile-goto-error)
1439
1440 (defun compile-goto-error (&optional event)
1441   "Visit the source for the error message at point.
1442 Use this command in a compilation log buffer.  Sets the mark at point there."
1443   (interactive (list last-input-event))
1444   (if event (posn-set-point (event-end event)))
1445   (or (compilation-buffer-p (current-buffer))
1446       (error "Not in a compilation buffer"))
1447   (if (get-text-property (point) 'directory)
1448       (dired-other-window (car (get-text-property (point) 'directory)))
1449     (push-mark)
1450     (setq compilation-current-error (point))
1451     (next-error 0)))
1452
1453 ;; Return a compilation buffer.
1454 ;; If the current buffer is a compilation buffer, return it.
1455 ;; Otherwise, look for a compilation buffer and signal an error
1456 ;; if there are none.
1457 (defun compilation-find-buffer (&optional other-buffer)
1458   (next-error-find-buffer other-buffer 'compilation-buffer-internal-p))
1459
1460 ;;;###autoload
1461 (defun compilation-next-error-function (n &optional reset)
1462   (interactive "p")
1463   (set-buffer (compilation-find-buffer))
1464   (when reset
1465     (setq compilation-current-error nil))
1466   (let* ((columns compilation-error-screen-columns) ; buffer's local value
1467          (last 1)
1468          (loc (compilation-next-error (or n 1) nil
1469                                       (or compilation-current-error
1470                                           compilation-messages-start
1471                                           (point-min))))
1472          (end-loc (nth 2 loc))
1473          (marker (point-marker)))
1474     (setq compilation-current-error (point-marker)
1475           overlay-arrow-position
1476             (if (bolp)
1477                 compilation-current-error
1478               (copy-marker (line-beginning-position)))
1479           loc (car loc))
1480     ;; If loc contains no marker, no error in that file has been visited.  If
1481     ;; the marker is invalid the buffer has been killed.  So, recalculate all
1482     ;; markers for that file.
1483     (unless (and (nth 3 loc) (marker-buffer (nth 3 loc)))
1484       (with-current-buffer (compilation-find-file marker (caar (nth 2 loc))
1485                                                   (or (cdar (nth 2 loc))
1486                                                       default-directory))
1487         (save-restriction
1488           (widen)
1489           (goto-char (point-min))
1490           ;; Treat file's found lines in forward order, 1 by 1.
1491           (dolist (line (reverse (cddr (nth 2 loc))))
1492             (when (car line)            ; else this is a filename w/o a line#
1493               (beginning-of-line (- (car line) last -1))
1494               (setq last (car line)))
1495             ;; Treat line's found columns and store/update a marker for each.
1496             (dolist (col (cdr line))
1497               (if (car col)
1498                   (if (eq (car col) -1) ; special case for range end
1499                       (end-of-line)
1500                     (compilation-move-to-column (car col) columns))
1501                 (beginning-of-line)
1502                 (skip-chars-forward " \t"))
1503               (if (nth 3 col)
1504                   (set-marker (nth 3 col) (point))
1505                 (setcdr (nthcdr 2 col) `(,(point-marker)))))))))
1506     (compilation-goto-locus marker (nth 3 loc) (nth 3 end-loc))
1507     (setcdr (nthcdr 3 loc) t)))         ; Set this one as visited.
1508
1509 (defvar compilation-gcpro nil
1510   "Internal variable used to keep some values from being GC'd.")
1511 (make-variable-buffer-local 'compilation-gcpro)
1512
1513 (defun compilation-fake-loc (marker file &optional line col)
1514   "Preassociate MARKER with FILE.
1515 FILE should be ABSOLUTE-FILENAME or (RELATIVE-FILENAME . DIRNAME).
1516 This is useful when you compile temporary files, but want
1517 automatic translation of the messages to the real buffer from
1518 which the temporary file came.  This only works if done before a
1519 message about FILE appears!
1520
1521 Optional args LINE and COL default to 1 and beginning of
1522 indentation respectively.  The marker is expected to reflect
1523 this.  In the simplest case the marker points to the first line
1524 of the region that was saved to the temp file.
1525
1526 If you concatenate several regions into the temp file (e.g. a
1527 header with variable assignments and a code region), you must
1528 call this several times, once each for the last line of one
1529 region and the first line of the next region."
1530   (or (consp file) (setq file (list file)))
1531   (setq file (compilation-get-file-structure file))
1532   ;; Between the current call to compilation-fake-loc and the first occurrence
1533   ;; of an error message referring to `file', the data is only kept is the
1534   ;; weak hash-table compilation-locs, so we need to prevent this entry
1535   ;; in compilation-locs from being GC'd away.  --Stef
1536   (push file compilation-gcpro)
1537   (let ((loc (compilation-assq (or line 1) (cdr file))))
1538     (setq loc (compilation-assq col loc))
1539     (if (cdr loc)
1540         (setcdr (cddr loc) (list marker))
1541       (setcdr loc (list line file marker)))
1542     loc))
1543
1544 (defcustom compilation-context-lines 0
1545   "*Display this many lines of leading context before message.
1546 If nil, don't scroll the compilation output window."
1547   :type '(choice integer (const :tag "No window scrolling" nil))
1548   :group 'compilation
1549   :version "21.4")
1550
1551 (defsubst compilation-set-window (w mk)
1552   "Align the compilation output window W with marker MK near top."
1553   (if (integerp compilation-context-lines)
1554       (set-window-start w (save-excursion
1555                             (goto-char mk)
1556                             (beginning-of-line (- 1 compilation-context-lines))
1557                             (point))))
1558   (set-window-point w mk))
1559
1560 (defun compilation-goto-locus (msg mk end-mk)
1561   "Jump to an error corresponding to MSG at MK.
1562 All arguments are markers.  If END-MK is non-nil, mark is set there
1563 and overlay is highlighted between MK and END-MK."
1564   (if (eq (window-buffer (selected-window))
1565           (marker-buffer msg))
1566       ;; If the compilation buffer window is selected,
1567       ;; keep the compilation buffer in this window;
1568       ;; display the source in another window.
1569       (let ((pop-up-windows t))
1570         (pop-to-buffer (marker-buffer mk)))
1571     (if (window-dedicated-p (selected-window))
1572         (pop-to-buffer (marker-buffer mk))
1573       (switch-to-buffer (marker-buffer mk))))
1574   ;; If narrowing gets in the way of going to the right place, widen.
1575   (unless (eq (goto-char mk) (point))
1576     (widen)
1577     (goto-char mk))
1578   (if end-mk
1579       (push-mark end-mk t)
1580     (if mark-active (setq mark-active)))
1581   ;; If hideshow got in the way of
1582   ;; seeing the right place, open permanently.
1583   (dolist (ov (overlays-at (point)))
1584     (when (eq 'hs (overlay-get ov 'invisible))
1585       (delete-overlay ov)
1586       (goto-char mk)))
1587
1588   ;; Show compilation buffer in other window, scrolled to this error.
1589   (let* ((pop-up-windows t)
1590          ;; Use an existing window if it is in a visible frame.
1591          (w (or (get-buffer-window (marker-buffer msg) 'visible)
1592                 ;; Pop up a window.
1593                 (display-buffer (marker-buffer msg))))
1594          (highlight-regexp (with-current-buffer (marker-buffer msg)
1595                              ;; also do this while we change buffer
1596                              (compilation-set-window w msg)
1597                              compilation-highlight-regexp)))
1598     (compilation-set-window-height w)
1599
1600     (when highlight-regexp
1601       (unless compilation-highlight-overlay
1602         (setq compilation-highlight-overlay
1603               (make-overlay (point-min) (point-min)))
1604         (overlay-put compilation-highlight-overlay 'face 'next-error))
1605       (with-current-buffer (marker-buffer mk)
1606         (save-excursion
1607           (if end-mk (goto-char end-mk) (end-of-line))
1608           (let ((end (point)))
1609             (if mk (goto-char mk) (beginning-of-line))
1610             (if (and (stringp highlight-regexp)
1611                      (re-search-forward highlight-regexp end t))
1612                 (progn
1613                   (goto-char (match-beginning 0))
1614                   (move-overlay compilation-highlight-overlay
1615                                 (match-beginning 0) (match-end 0)
1616                                 (current-buffer)))
1617               (move-overlay compilation-highlight-overlay
1618                             (point) end (current-buffer)))
1619             (if (numberp next-error-highlight)
1620                 (sit-for next-error-highlight))
1621             (if (not (eq next-error-highlight t))
1622                 (delete-overlay compilation-highlight-overlay))))))
1623     (when (and (eq next-error-highlight 'fringe-arrow))
1624       (set (make-local-variable 'overlay-arrow-position)
1625            (copy-marker (line-beginning-position))))))
1626 \f
1627 (defun compilation-find-file (marker filename dir &rest formats)
1628   "Find a buffer for file FILENAME.
1629 Search the directories in `compilation-search-path'.
1630 A nil in `compilation-search-path' means to try the
1631 current directory, which is passed in DIR.
1632 If FILENAME is not found at all, ask the user where to find it.
1633 Pop up the buffer containing MARKER and scroll to MARKER if we ask the user."
1634   (or formats (setq formats '("%s")))
1635   (save-excursion
1636     (let ((dirs compilation-search-path)
1637           buffer thisdir fmts name)
1638       (if (file-name-absolute-p filename)
1639           ;; The file name is absolute.  Use its explicit directory as
1640           ;; the first in the search path, and strip it from FILENAME.
1641           (setq filename (abbreviate-file-name (expand-file-name filename))
1642                 dirs (cons (file-name-directory filename) dirs)
1643                 filename (file-name-nondirectory filename)))
1644       ;; Now search the path.
1645       (while (and dirs (null buffer))
1646         (setq thisdir (or (car dirs) dir)
1647               fmts formats)
1648         ;; For each directory, try each format string.
1649         (while (and fmts (null buffer))
1650           (setq name (expand-file-name (format (car fmts) filename) thisdir)
1651                 buffer (and (file-exists-p name)
1652                             (find-file-noselect name))
1653                 fmts (cdr fmts)))
1654         (setq dirs (cdr dirs)))
1655       (or buffer
1656           ;; The file doesn't exist.  Ask the user where to find it.
1657           (let ((pop-up-windows t))
1658             (compilation-set-window (display-buffer (marker-buffer marker))
1659                                     marker)
1660             (let ((name (expand-file-name
1661                          (read-file-name
1662                           (format "Find this error in: (default %s) "
1663                                   filename)
1664                           dir filename t))))
1665               (if (file-directory-p name)
1666                   (setq name (expand-file-name filename name)))
1667               (setq buffer (and (file-exists-p name)
1668                                 (find-file name))))))
1669       ;; Make intangible overlays tangible.
1670       (mapcar (function (lambda (ov)
1671                           (when (overlay-get ov 'intangible)
1672                             (overlay-put ov 'intangible nil))))
1673               (overlays-in (point-min) (point-max)))
1674       buffer)))
1675
1676 (defun compilation-get-file-structure (file &optional fmt)
1677   "Retrieve FILE's file-structure or create a new one.
1678 FILE should be (ABSOLUTE-FILENAME) or (RELATIVE-FILENAME . DIRNAME)."
1679
1680   (or (gethash file compilation-locs)
1681       ;; File was not previously encountered, at least not in the form passed.
1682       ;; Let's normalize it and look again.
1683       (let ((filename (car file))
1684             (default-directory (if (cdr file)
1685                                    (file-truename (cdr file))
1686                                  default-directory)))
1687
1688         ;; Check for a comint-file-name-prefix and prepend it if appropriate.
1689         ;; (This is very useful for compilation-minor-mode in an rlogin-mode
1690         ;; buffer.)
1691         (if (boundp 'comint-file-name-prefix)
1692             (if (file-name-absolute-p filename)
1693                 (setq filename
1694                       (concat (with-no-warnings comint-file-name-prefix) filename))
1695               (setq default-directory
1696                     (file-truename
1697                      (concat (with-no-warnings comint-file-name-prefix) default-directory)))))
1698
1699         ;; If compilation-parse-errors-filename-function is
1700         ;; defined, use it to process the filename.
1701         (when compilation-parse-errors-filename-function
1702           (setq filename
1703                 (funcall compilation-parse-errors-filename-function
1704                          filename)))
1705
1706         ;; Some compilers (e.g. Sun's java compiler, reportedly) produce bogus
1707         ;; file names like "./bar//foo.c" for file "bar/foo.c";
1708         ;; expand-file-name will collapse these into "/foo.c" and fail to find
1709         ;; the appropriate file.  So we look for doubled slashes in the file
1710         ;; name and fix them.
1711         (setq filename (command-line-normalize-file-name filename))
1712
1713         ;; Now eliminate any "..", because find-file would get them wrong.
1714         ;; Make relative and absolute filenames, with or without links, the
1715         ;; same.
1716         (setq filename
1717               (list (abbreviate-file-name
1718                      (file-truename (if (cdr file)
1719                                         (expand-file-name filename)
1720                                       filename)))))
1721
1722         ;; Store it for the possibly unnormalized name
1723         (puthash file
1724                  ;; Retrieve or create file-structure for normalized name
1725                  (or (gethash filename compilation-locs)
1726                      (puthash filename (list filename fmt) compilation-locs))
1727                  compilation-locs))))
1728
1729 (add-to-list 'debug-ignored-errors "^No more [-a-z ]+s yet$")
1730
1731 ;;; Compatibility with the old compile.el.
1732
1733 (defun compile-buffer-substring (n) (if n (match-string n)))
1734
1735 (defun compilation-compat-error-properties (err)
1736   "Map old-style error ERR to new-style message."
1737   ;; Old-style structure is (MARKER (FILE DIR) LINE COL) or
1738   ;; (MARKER . MARKER).
1739   (let ((dst (cdr err)))
1740     (if (markerp dst)
1741         ;; Must start with a face, for font-lock.
1742         `(face nil
1743           message ,(list (list nil nil nil dst) 2)
1744           help-echo "mouse-2: visit the source location"
1745           keymap compilation-button-map
1746           mouse-face highlight)
1747       ;; Too difficult to do it by hand: dispatch to the normal code.
1748       (let* ((file (pop dst))
1749              (line (pop dst))
1750              (col (pop dst))
1751              (filename (pop file))
1752              (dirname (pop file))
1753              (fmt (pop file)))
1754         (compilation-internal-error-properties
1755          (cons filename dirname) line nil col nil 2 fmt)))))
1756
1757 (defun compilation-compat-parse-errors (limit)
1758   (when compilation-parse-errors-function
1759     ;; FIXME: We should remove the rest of the compilation keywords
1760     ;; but we can't do that from here because font-lock is using
1761     ;; the value right now.  --stef
1762     (save-excursion
1763       (setq compilation-error-list nil)
1764       ;; Reset compilation-parsing-end each time because font-lock
1765       ;; might force us the re-parse many times (typically because
1766       ;; some code adds some text-property to the output that we
1767       ;; already parsed).  You might say "why reparse", well:
1768       ;; because font-lock has just removed the `message' property so
1769       ;; have to do it all over again.
1770       (if compilation-parsing-end
1771           (set-marker compilation-parsing-end (point))
1772         (setq compilation-parsing-end (point-marker)))
1773       (condition-case nil
1774           ;; Ignore any error: we're calling this function earlier than
1775           ;; in the old compile.el so things might not all be setup yet.
1776           (funcall compilation-parse-errors-function limit nil)
1777         (error nil))
1778       (dolist (err (if (listp compilation-error-list) compilation-error-list))
1779         (let* ((src (car err))
1780                (dst (cdr err))
1781                (loc (cond ((markerp dst) (list nil nil nil dst))
1782                           ((consp dst)
1783                            (list (nth 2 dst) (nth 1 dst)
1784                                  (cons (cdar dst) (caar dst)))))))
1785           (when loc
1786             (goto-char src)
1787             ;; (put-text-property src (line-end-position) 'font-lock-face 'font-lock-warning-face)
1788             (put-text-property src (line-end-position)
1789                                'message (list loc 2)))))))
1790   (goto-char limit)
1791   nil)
1792
1793 ;; Beware: this is not only compatiblity code.  New code stil uses it.  --Stef
1794 (defun compilation-forget-errors ()
1795   ;; In case we hit the same file/line specs, we want to recompute a new
1796   ;; marker for them, so flush our cache.
1797   (setq compilation-locs (make-hash-table :test 'equal :weakness 'value))
1798   (setq compilation-gcpro nil)
1799   ;; FIXME: the old code reset the directory-stack, so maybe we should
1800   ;; put a `directory change' marker of some sort, but where?  -stef
1801   ;;
1802   ;; FIXME: The old code moved compilation-current-error (which was
1803   ;; virtually represented by a mix of compilation-parsing-end and
1804   ;; compilation-error-list) to point-min, but that was only meaningful for
1805   ;; the internal uses of compilation-forget-errors: all calls from external
1806   ;; packages seem to be followed by a move of compilation-parsing-end to
1807   ;; something equivalent to point-max.  So we speculatively move
1808   ;; compilation-current-error to point-max (since the external package
1809   ;; won't know that it should do it).  --stef
1810   (setq compilation-current-error nil)
1811   (let* ((proc (get-buffer-process (current-buffer)))
1812          (mark (if proc (process-mark proc)))
1813          (pos (or mark (point-max))))
1814     (setq compilation-messages-start
1815           ;; In the future, ignore the text already present in the buffer.
1816           ;; Since many process filter functions insert before markers,
1817           ;; we need to put ours just before the insertion point rather
1818           ;; than at the insertion point.  If that's not possible, then
1819           ;; don't use a marker.  --Stef
1820           (if (> pos (point-min)) (copy-marker (1- pos)) pos))))
1821
1822 (provide 'compile)
1823
1824 ;; arch-tag: 12465727-7382-4f72-b234-79855a00dd8c
1825 ;;; compile.el ends here