code.delx.au - gnu-emacs/blob - lisp/international/encoded-kb.el

   1 ;;; encoded-kb.el --- handler to input multibyte characters encoded somehow
   2
   3 ;; Copyright (C) 1995 Electrotechnical Laboratory, JAPAN.
   4 ;; Licensed to the Free Software Foundation.
   5 ;; Copyright (C) 2002 Free Software Foundation, Inc.
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (defconst encoded-kbd-mode-map (make-sparse-keymap)
  29   "Keymap for Encoded-kbd minor mode.")
  30
  31 ;; Subsidiary keymaps for handling ISO2022 escape sequences.
  32
  33 (defvar encoded-kbd-iso2022-esc-map
  34   (let ((map (make-sparse-keymap)))
  35     (define-key map "$" 'encoded-kbd-iso2022-esc-dollar-prefix)
  36     (define-key map "(" 'encoded-kbd-iso2022-designation-prefix)
  37     (define-key map ")" 'encoded-kbd-iso2022-designation-prefix)
  38     (define-key map "," 'encoded-kbd-iso2022-designation-prefix)
  39     (define-key map "-" 'encoded-kbd-iso2022-designation-prefix)
  40     map)
  41   "Keymap for handling ESC code in Encoded-kbd mode.")
  42 (fset 'encoded-kbd-iso2022-esc-prefix encoded-kbd-iso2022-esc-map)
  43
  44 (defvar encoded-kbd-iso2022-esc-dollar-map
  45   (let ((map (make-sparse-keymap)))
  46     (define-key map "(" 'encoded-kbd-iso2022-designation-prefix)
  47     (define-key map ")" 'encoded-kbd-iso2022-designation-prefix)
  48     (define-key map "," 'encoded-kbd-iso2022-designation-prefix)
  49     (define-key map "-" 'encoded-kbd-iso2022-designation-prefix)
  50     (define-key map "@" 'encoded-kbd-iso2022-designation)
  51     (define-key map "A" 'encoded-kbd-iso2022-designation)
  52     (define-key map "B" 'encoded-kbd-iso2022-designation)
  53     map)
  54   "Keymap for handling ESC $ sequence in Encoded-kbd mode.")
  55 (fset 'encoded-kbd-iso2022-esc-dollar-prefix
  56       encoded-kbd-iso2022-esc-dollar-map)
  57
  58 (defvar encoded-kbd-iso2022-designation-map
  59   (let ((map (make-sparse-keymap))
  60         (l charset-list)
  61         final-char)
  62     (while l
  63       (setq final-char (charset-iso-final-char (car l)))
  64       (if (> final-char 0)
  65           (define-key map (char-to-string final-char)
  66             'encoded-kbd-iso2022-designation))
  67       (setq l (cdr l)))
  68     map)
  69   "Keymap for handling ISO2022 designation sequence in Encoded-kbd mode.")
  70 (fset 'encoded-kbd-iso2022-designation-prefix
  71       encoded-kbd-iso2022-designation-map)
  72
  73 (defvar encoded-kbd-iso2022-non-ascii-map
  74   (let ((map (make-keymap))
  75         (i 32))
  76     (while (< i 128)
  77       (define-key map (char-to-string i) 'encoded-kbd-self-insert-iso2022-7bit)
  78       (setq i (1+ i)))
  79     (define-key map "\e" 'encoded-kbd-iso2022-esc-prefix)
  80     (setq i 160)
  81     (while (< i 256)
  82       (define-key map (vector i) 'encoded-kbd-handle-8bit)
  83       (setq i (1+ i)))
  84     map)
  85   "Keymap for handling non-ASCII character set in Encoded-kbd mode.")
  86
  87 ;; One of the symbols `sjis', `iso2022-7', `iso2022-8', or `big5' to
  88 ;; denote what kind of coding-system we are now handling in
  89 ;; Encoded-kbd mode.
  90 (defvar encoded-kbd-coding nil)
  91
  92 ;; Keep information of designation state of ISO2022 encoding.  When
  93 ;; Encoded-kbd mode is on, this is set to a vector of length 4, the
  94 ;; elements are character sets currently designated to graphic
  95 ;; registers 0 thru 3.
  96
  97 (defvar encoded-kbd-iso2022-designations nil)
  98 (put 'encoded-kbd-iso2022-designations 'permanent-local t)
  99
 100 ;; Keep information of invocation state of ISO2022 encoding.  When
 101 ;; Encoded-kbd mode is on, this is set to a vector of length 3,
 102 ;; graphic register numbers currently invoked to graphic plane 1 and
 103 ;; 2, and a single shifted graphic register number.
 104
 105 (defvar encoded-kbd-iso2022-invocations nil)
 106 (put 'encoded-kbd-iso2022-invocations 'permanent-local t)
 107
 108 (defun encoded-kbd-iso2022-designation ()
 109   "Do ISO2022 designation according to the current key in Encoded-kbd mode.
 110 The following key sequence may cause multilingual text insertion."
 111   (interactive)
 112   (let ((key-seq (this-command-keys))
 113         (prev-g0-charset (aref encoded-kbd-iso2022-designations
 114                                (aref encoded-kbd-iso2022-invocations 0)))
 115         intermediate-char final-char
 116         reg dimension chars charset)
 117     (if (= (length key-seq) 4)
 118         ;; ESC $ <intermediate-char> <final-char>
 119         (setq intermediate-char (aref key-seq 2)
 120               dimension 2
 121               chars (if (< intermediate-char ?,) 94 96)
 122               final-char (aref key-seq 3)
 123               reg (mod intermediate-char 4))
 124       (if (= (aref key-seq 1) ?$)
 125           ;; ESC $ <final-char>
 126           (setq dimension 2
 127                 chars 94
 128                 final-char (aref key-seq 2)
 129                 reg 0)
 130         ;; ESC <intermediate-char> <final-char>
 131         (setq intermediate-char (aref key-seq 1)
 132               dimension 1
 133               chars (if (< intermediate-char ?,) 94 96)
 134               final-char (aref key-seq 2)
 135               reg (mod intermediate-char 4))))
 136     (if (setq charset (iso-charset dimension chars final-char))
 137         (aset encoded-kbd-iso2022-designations reg charset)
 138       (error "Character set of DIMENSION %s, CHARS %s, FINAL-CHAR `%c' is not supported"
 139              dimension chars final-char))
 140
 141     (if (memq (aref encoded-kbd-iso2022-designations
 142                     (aref encoded-kbd-iso2022-invocations 0))
 143               '(ascii latin-jisx0201))
 144         ;; Graphic plane 0 (0x20..0x7f) is for ASCII.  We don't have
 145         ;; to handle characters in this range specially.
 146         (if (not (memq prev-g0-charset '(ascii latin-jisx0201)))
 147             ;; We must exit recursive edit now.
 148             (throw 'exit nil))
 149       ;; Graphic plane 0 is for non-ASCII.
 150       (if (memq prev-g0-charset '(ascii latin-jisx0201))
 151           ;; We must handle keys specially.
 152           (let ((overriding-local-map encoded-kbd-iso2022-non-ascii-map))
 153             (recursive-edit))))))
 154
 155 (defun encoded-kbd-handle-8bit ()
 156   "Handle an 8-bit character entered in Encoded-kbd mode."
 157   (interactive)
 158   (cond ((eq encoded-kbd-coding 'iso2022-7)
 159          (error "Can't handle the character code %d" last-command-char))
 160
 161         ((eq encoded-kbd-coding 'iso2022-8)
 162          (cond ((= last-command-char ?\216)
 163                 (aset encoded-kbd-iso2022-invocations 2 2))
 164
 165                ((= last-command-char ?\217)
 166                 (aset encoded-kbd-iso2022-invocations 2 3))
 167
 168                ((>= last-command-char ?\240)
 169                 (encoded-kbd-self-insert-iso2022-8bit 1))
 170
 171                (t
 172                 (error "Can't handle the character code %d"
 173                        last-command-char))))
 174
 175         ((eq encoded-kbd-coding 'sjis)
 176          (encoded-kbd-self-insert-sjis))
 177
 178         (t
 179          (encoded-kbd-self-insert-big5))))
 180
 181 (defun encoded-kbd-self-insert-iso2022-7bit ()
 182   (interactive)
 183   (let* ((charset (aref encoded-kbd-iso2022-designations
 184                         (or (aref encoded-kbd-iso2022-invocations 2)
 185                             (aref encoded-kbd-iso2022-invocations 0))))
 186          (char (if (= (charset-dimension charset) 1)
 187                    (make-char charset last-command-char)
 188                  (make-char charset last-command-char (read-char-exclusive)))))
 189     (aset encoded-kbd-iso2022-invocations 2 nil)
 190     (setq unread-command-events (cons char unread-command-events))))
 191
 192 (defun encoded-kbd-self-insert-iso2022-8bit (arg)
 193   (interactive "p")
 194   (cond
 195    ((= last-command-char ?\216)         ; SS2 (Single Shift 2)
 196     (aset encoded-kbd-iso2022-invocations 2 2))
 197    ((= last-command-char ?\217)         ; SS3 (Single Shift 3)
 198     (aset encoded-kbd-iso2022-invocations 2 3))
 199    (t
 200     (let* ((charset (aref encoded-kbd-iso2022-designations
 201                           (or (aref encoded-kbd-iso2022-invocations 2)
 202                               (aref encoded-kbd-iso2022-invocations 1))))
 203            (char (if (= (charset-dimension charset) 1)
 204                      (make-char charset last-command-char)
 205                    (make-char charset last-command-char
 206                               (read-char-exclusive)))))
 207       (aset encoded-kbd-iso2022-invocations 2 nil)
 208       ;; As simply setting unread-command-events may result in
 209       ;; infinite-loop for characters 160..255, this is a temporary
 210       ;; workaround until we found a better solution.
 211       (let ((last-command-char char))
 212         (self-insert-command arg))))))
 213
 214 (defun encoded-kbd-self-insert-sjis ()
 215   (interactive)
 216   (let ((char (if (or (< last-command-char ?\xA0) (>= last-command-char ?\xE0))
 217                   (decode-sjis-char (+ (ash last-command-char 8)
 218                                        (read-char-exclusive)))
 219                 (make-char 'katakana-jisx0201 last-command-char))))
 220     (setq unread-command-events (cons char unread-command-events))))
 221
 222 (defun encoded-kbd-self-insert-big5 ()
 223   (interactive)
 224   (let ((char (decode-big5-char (+ (ash last-command-char 8)
 225                                    (read-char-exclusive)))))
 226     (setq unread-command-events (cons char unread-command-events))))
 227
 228 (defun encoded-kbd-self-insert-ccl ()
 229   (interactive)
 230   (let ((str (char-to-string last-command-char))
 231         (ccl (coding-system-get (keyboard-coding-system) :ccl-decoder))
 232         (vec [nil nil nil nil nil nil nil nil nil])
 233         result)
 234     (while (= (length (setq result (ccl-execute-on-string ccl vec str t))) 0)
 235       (dotimes (i 9) (aset vec i nil))
 236       (setq str (format "%s%c" str (read-char-exclusive))))
 237     (setq unread-command-events
 238           (append result unread-command-events))))
 239
 240 (defun encoded-kbd-self-insert-charset (arg)
 241   (interactive "p")
 242   (let* ((charset-list
 243           (coding-system-get (keyboard-coding-system) :charset-list))
 244          (charset (car charset-list))
 245          ;; For the moment, we can assume that the length of CHARSET-LIST
 246          ;; is 1, and the dimension of CHARSET is 1.
 247          (c (decode-char charset last-command-char)))
 248     (unless c
 249       (error "Can't decode the code point %d by %s"
 250              last-command-char charset))
 251     ;; As simply setting unread-command-events may result in
 252     ;; infinite-loop for characters 160..255, this is a temporary
 253     ;; workaround until we found a better solution.
 254     (let ((last-command-char c))
 255       (self-insert-command arg))))
 256
 257 (defun encoded-kbd-setup-keymap (coding)
 258   ;; At first, reset the keymap.
 259   (setcdr encoded-kbd-mode-map nil)
 260   ;; Then setup the keymap according to the keyboard coding system.
 261   (cond
 262    ((eq encoded-kbd-coding 'charset)
 263     (let* ((charset (car (coding-system-get coding :charset-list)))
 264            (code-space (get-charset-property charset :code-space))
 265            (from (max (aref code-space 0) 128))
 266            (to (aref code-space 1)))
 267       (while (<= from to)
 268         (define-key encoded-kbd-mode-map
 269           (vector from) 'encoded-kbd-self-insert-charset)
 270         (setq from (1+ from)))))
 271
 272    ((eq encoded-kbd-coding 'sjis)
 273     (let ((i 128))
 274       (while (< i 256)
 275         (define-key encoded-kbd-mode-map
 276           (vector i) 'encoded-kbd-self-insert-sjis)
 277         (setq i (1+ i)))))
 278
 279    ((eq encoded-kbd-coding 'big5)
 280     (let ((i 161))
 281       (while (< i 255)
 282         (define-key encoded-kbd-mode-map
 283           (vector i) 'encoded-kbd-self-insert-big5)
 284         (setq i (1+ i)))))
 285
 286    ((eq encoded-kbd-coding 'iso2022-7)
 287     (define-key encoded-kbd-mode-map "\e" 'encoded-kbd-iso2022-esc-prefix))
 288
 289    ((eq encoded-kbd-coding 'iso2022-8)
 290     (define-key encoded-kbd-mode-map
 291       (vector ?\216) 'encoded-kbd-self-insert-iso2022-8bit)
 292     (define-key encoded-kbd-mode-map
 293       (vector ?\217) 'encoded-kbd-self-insert-iso2022-8bit)
 294     (let ((i 160))
 295       (while (< i 256)
 296         (define-key encoded-kbd-mode-map
 297           (vector i) 'encoded-kbd-self-insert-iso2022-8bit)
 298         (setq i (1+ i)))))
 299
 300    ((eq encoded-kbd-coding 'ccl)
 301     (let ((valid-codes (or (coding-system-get coding :valid)
 302                            '((128 . 255))))
 303           elt from to)
 304       (while valid-codes
 305         (setq elt (car valid-codes) valid-codes (cdr valid-codes))
 306         (if (consp elt)
 307             (setq from (car elt) to (cdr elt))
 308           (setq from (setq to elt)))
 309         (while (<= from to)
 310           (if (>= from 128)
 311               (define-key encoded-kbd-mode-map
 312                 (vector from) 'encoded-kbd-self-insert-ccl))
 313           (setq from (1+ from))))))
 314
 315    (t
 316     (error "Invalid value in encoded-kbd-coding: %s" encoded-kbd-coding))))
 317
 318
 319 ;; Input mode at the time Encoded-kbd mode is turned on is saved here.
 320 (defvar saved-input-mode nil)
 321
 322 (put 'encoded-kbd-mode 'permanent-local t)
 323 ;;;###autoload
 324 (define-minor-mode encoded-kbd-mode
 325   "Toggle Encoded-kbd minor mode.
 326 With arg, turn Encoded-kbd mode on if and only if arg is positive.
 327
 328 You should not turn this mode on manually, instead use the command
 329 \\[set-keyboard-coding-system] which turns on or off this mode
 330 automatically.
 331
 332 In Encoded-kbd mode, a text sent from keyboard is accepted
 333 as a multilingual text encoded in a coding system set by
 334 \\[set-keyboard-coding-system]."
 335   :global t
 336   ;; We must at first reset input-mode to the original.
 337   (if saved-input-mode (apply 'set-input-mode saved-input-mode))
 338   (if encoded-kbd-mode
 339       (let ((coding (keyboard-coding-system)))
 340         (setq saved-input-mode  (current-input-mode))
 341         (cond ((null coding)
 342                (setq encoded-kbd-mode nil)
 343                (error "No coding system for keyboard input is set"))
 344
 345               ((eq (coding-system-type coding) 'shift-jis)
 346                (set-input-mode
 347                 (nth 0 saved-input-mode) (nth 1 saved-input-mode)
 348                 'use-8th-bit (nth 3 saved-input-mode))
 349                (setq encoded-kbd-coding 'sjis))
 350
 351               ((eq (coding-system-type coding) 'iso-2022)
 352                (if (memq '7-bit (coding-system-get coding :flags))
 353                    (setq encoded-kbd-coding 'iso2022-7)
 354                  (set-input-mode
 355                   (nth 0 saved-input-mode) (nth 1 saved-input-mode)
 356                   'use-8th-bit (nth 3 saved-input-mode))
 357                  (setq encoded-kbd-coding 'iso2022-8))
 358                (setq encoded-kbd-iso2022-designations
 359                      (coding-system-get coding :designation))
 360                (setq encoded-kbd-iso2022-invocations (make-vector 3 nil))
 361                (aset encoded-kbd-iso2022-invocations 0 0)
 362                (aset encoded-kbd-iso2022-invocations 1 1))
 363
 364               ((eq (coding-system-type coding) 'big5)
 365                (set-input-mode
 366                 (nth 0 saved-input-mode) (nth 1 saved-input-mode)
 367                 'use-8th-bit (nth 3 saved-input-mode))
 368                (setq encoded-kbd-coding 'big5))
 369
 370               ((eq (coding-system-type coding) 'ccl)
 371                (set-input-mode
 372                 (nth 0 saved-input-mode) (nth 1 saved-input-mode)
 373                 'use-8th-bit (nth 3 saved-input-mode))
 374                (setq encoded-kbd-coding 'ccl))
 375
 376               ((and (eq (coding-system-type coding) 'charset)
 377                     (let* ((charset-list (coding-system-get coding
 378                                                             :charset-list))
 379                            (charset (car charset-list)))
 380                       (and (= (length charset-list) 1)
 381                            (= (charset-dimension charset) 1))))
 382                (set-input-mode
 383                 (nth 0 saved-input-mode) (nth 1 saved-input-mode)
 384                 'use-8th-bit (nth 3 saved-input-mode))
 385                (setq encoded-kbd-coding 'charset))
 386
 387               (t
 388                (setq encoded-kbd-mode nil)
 389                (error "Coding-system `%s' is not supported in Encoded-kbd mode"
 390                       (keyboard-coding-system))))
 391         (encoded-kbd-setup-keymap coding))))
 392
 393 ;;; encoded-kb.el ends here