code.delx.au - gnu-emacs/blob - lisp/international/mule-util.el

   1 ;;; mule-util.el --- utility functions for mulitilingual environment (mule)
   2
   3 ;; Copyright (C) 1995 Electrotechnical Laboratory, JAPAN.
   4 ;; Licensed to the Free Software Foundation.
   5 ;; Copyright (C) 2002 Free Software Foundation, Inc.
   6
   7 ;; Keywords: mule, multilingual
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 ;;; String manipulations while paying attention to multibyte
  31 ;;; characters.
  32
  33 ;;;###autoload
  34 (defun string-to-sequence (string type)
  35   "Convert STRING to a sequence of TYPE which contains characters in STRING.
  36 TYPE should be `list' or `vector'."
  37 ;;;  (let ((len (length string))
  38 ;;;        (i 0)
  39 ;;;        val)
  40     (cond ((eq type 'list)
  41            ;; Applicable post-Emacs 20.2 and asymptotically ~10 times
  42            ;; faster than the code below:
  43            (append string nil))
  44 ;;;        (setq val (make-list len 0))
  45 ;;;        (let ((l val))
  46 ;;;          (while (< i len)
  47 ;;;            (setcar l (aref string i))
  48 ;;;            (setq l (cdr l) i (1+ i))))))
  49           ((eq type 'vector)
  50            ;; As above.
  51            (vconcat string))
  52 ;;;        (setq val (make-vector len 0))
  53 ;;;        (while (< i len)
  54 ;;;          (aset val i (aref string i))
  55 ;;;          (setq i (1+ i))))
  56           (t
  57            (error "Invalid type: %s" type)))
  58 ;;;    val)
  59 )
  60 (make-obsolete 'string-to-sequence
  61                "Use `string-to-list' or `string-to-vector'"
  62                "21.3")
  63
  64 ;;;###autoload
  65 (defsubst string-to-list (string)
  66   "Return a list of characters in STRING."
  67   (append string nil))
  68
  69 ;;;###autoload
  70 (defsubst string-to-vector (string)
  71   "Return a vector of characters in STRING."
  72   (vconcat string))
  73
  74 ;;;###autoload
  75 (defun store-substring (string idx obj)
  76   "Embed OBJ (string or character) at index IDX of STRING."
  77   (if (integerp obj)
  78       (aset string idx obj)
  79     (let ((len1 (length obj))
  80           (len2 (length string))
  81           (i 0))
  82       (while (< i len1)
  83         (aset string (+ idx i) (aref obj i))
  84         (setq i (1+ i)))))
  85   string)
  86
  87 ;;;###autoload
  88 (defun truncate-string-to-width (str end-column &optional start-column padding)
  89   "Truncate string STR to end at column END-COLUMN.
  90 The optional 3rd arg START-COLUMN, if non-nil, specifies
  91 the starting column; that means to return the characters occupying
  92 columns START-COLUMN ... END-COLUMN of STR.
  93
  94 The optional 4th arg PADDING, if non-nil, specifies a padding character
  95 to add at the end of the result if STR doesn't reach column END-COLUMN,
  96 or if END-COLUMN comes in the middle of a character in STR.
  97 PADDING is also added at the beginning of the result
  98 if column START-COLUMN appears in the middle of a character in STR.
  99
 100 If PADDING is nil, no padding is added in these cases, so
 101 the resulting string may be narrower than END-COLUMN."
 102   (or start-column
 103       (setq start-column 0))
 104   (let ((len (length str))
 105         (idx 0)
 106         (column 0)
 107         (head-padding "") (tail-padding "")
 108         ch last-column last-idx from-idx)
 109     (condition-case nil
 110         (while (< column start-column)
 111           (setq ch (aref str idx)
 112                 column (+ column (char-width ch))
 113                 idx (1+ idx)))
 114       (args-out-of-range (setq idx len)))
 115     (if (< column start-column)
 116         (if padding (make-string end-column padding) "")
 117       (if (and padding (> column start-column))
 118           (setq head-padding (make-string (- column start-column) padding)))
 119       (setq from-idx idx)
 120       (if (< end-column column)
 121           (setq idx from-idx)
 122         (condition-case nil
 123             (while (< column end-column)
 124               (setq last-column column
 125                     last-idx idx
 126                     ch (aref str idx)
 127                     column (+ column (char-width ch))
 128                     idx (1+ idx)))
 129           (args-out-of-range (setq idx len)))
 130         (if (> column end-column)
 131             (setq column last-column idx last-idx))
 132         (if (and padding (< column end-column))
 133             (setq tail-padding (make-string (- end-column column) padding))))
 134       (setq str (substring str from-idx idx))
 135       (if padding
 136           (concat head-padding str tail-padding)
 137         str))))
 138
 139 ;;; For backward compatibility ...
 140 ;;;###autoload
 141 (defalias 'truncate-string 'truncate-string-to-width)
 142 (make-obsolete 'truncate-string 'truncate-string-to-width "20.1")
 143 \f
 144 ;;; Nested alist handler.  Nested alist is alist whose elements are
 145 ;;; also nested alist.
 146
 147 ;;;###autoload
 148 (defsubst nested-alist-p (obj)
 149   "Return t if OBJ is a nested alist.
 150
 151 Nested alist is a list of the form (ENTRY . BRANCHES), where ENTRY is
 152 any Lisp object, and BRANCHES is a list of cons cells of the form
 153 (KEY-ELEMENT . NESTED-ALIST).
 154
 155 You can use a nested alist to store any Lisp object (ENTRY) for a key
 156 sequence KEYSEQ, where KEYSEQ is a sequence of KEY-ELEMENT.  KEYSEQ
 157 can be a string, a vector, or a list."
 158   (and obj (listp obj) (listp (cdr obj))))
 159
 160 ;;;###autoload
 161 (defun set-nested-alist (keyseq entry alist &optional len branches)
 162   "Set ENTRY for KEYSEQ in a nested alist ALIST.
 163 Optional 4th arg LEN non-nil means the first LEN elements in KEYSEQ
 164  is considered.
 165 Optional argument BRANCHES if non-nil is branches for a keyseq
 166 longer than KEYSEQ.
 167 See the documentation of `nested-alist-p' for more detail."
 168   (or (nested-alist-p alist)
 169       (error "Invalid argument %s" alist))
 170   (let ((islist (listp keyseq))
 171         (len (or len (length keyseq)))
 172         (i 0)
 173         key-elt slot)
 174     (while (< i len)
 175       (if (null (nested-alist-p alist))
 176           (error "Keyseq %s is too long for this nested alist" keyseq))
 177       (setq key-elt (if islist (nth i keyseq) (aref keyseq i)))
 178       (setq slot (assoc key-elt (cdr alist)))
 179       (if (null slot)
 180           (progn
 181             (setq slot (cons key-elt (list t)))
 182             (setcdr alist (cons slot (cdr alist)))))
 183       (setq alist (cdr slot))
 184       (setq i (1+ i)))
 185     (setcar alist entry)
 186     (if branches
 187         (setcdr (last alist) branches))))
 188
 189 ;;;###autoload
 190 (defun lookup-nested-alist (keyseq alist &optional len start nil-for-too-long)
 191   "Look up key sequence KEYSEQ in nested alist ALIST.  Return the definition.
 192 Optional 1st argument LEN specifies the length of KEYSEQ.
 193 Optional 2nd argument START specifies index of the starting key.
 194 The returned value is normally a nested alist of which
 195 car part is the entry for KEYSEQ.
 196 If ALIST is not deep enough for KEYSEQ, return number which is
 197  how many key elements at the front of KEYSEQ it takes
 198  to reach a leaf in ALIST.
 199 Optional 3rd argument NIL-FOR-TOO-LONG non-nil means return nil
 200  even if ALIST is not deep enough."
 201   (or (nested-alist-p alist)
 202       (error "Invalid argument %s" alist))
 203   (or len
 204       (setq len (length keyseq)))
 205   (let ((i (or start 0)))
 206     (if (catch 'lookup-nested-alist-tag
 207           (if (listp keyseq)
 208               (while (< i len)
 209                 (if (setq alist (cdr (assoc (nth i keyseq) (cdr alist))))
 210                     (setq i (1+ i))
 211                   (throw 'lookup-nested-alist-tag t))))
 212           (while (< i len)
 213             (if (setq alist (cdr (assoc (aref keyseq i) (cdr alist))))
 214                 (setq i (1+ i))
 215               (throw 'lookup-nested-alist-tag t))))
 216         ;; KEYSEQ is too long.
 217         (if nil-for-too-long nil i)
 218       alist)))
 219
 220 \f
 221 ;; Coding system related functions.
 222
 223 ;;;###autoload
 224 (defun coding-system-eol-type-mnemonic (coding-system)
 225   "Return the string indicating end-of-line format of CODING-SYSTEM."
 226   (let* ((eol-type (coding-system-eol-type coding-system))
 227          (val (cond ((vectorp eol-type) eol-mnemonic-undecided)
 228                     ((eq eol-type 0) eol-mnemonic-unix)
 229                     ((eq eol-type 1) eol-mnemonic-dos)
 230                     ((eq eol-type 2) eol-mnemonic-mac)
 231                     (t "-"))))
 232     (if (stringp val)
 233         val
 234       (char-to-string val))))
 235
 236 ;;;###autoload
 237 (defun coding-system-post-read-conversion (coding-system)
 238   "Return the value of CODING-SYSTEM's `post-read-conversion' property."
 239   (coding-system-get coding-system :post-read-conversion))
 240
 241 ;;;###autoload
 242 (defun coding-system-pre-write-conversion (coding-system)
 243   "Return the value of CODING-SYSTEM's `pre-write-conversion' property."
 244   (coding-system-get coding-system :pre-write-conversion))
 245
 246 ;;;###autoload
 247 (defun coding-system-translation-table-for-decode (coding-system)
 248   "Return the value of CODING-SYSTEM's `translation-table-for-decode' property."
 249   (coding-system-get coding-system :decode-translation-table))
 250
 251 ;;;###autoload
 252 (defun coding-system-translation-table-for-encode (coding-system)
 253   "Return the value of CODING-SYSTEM's `translation-table-for-encode' property."
 254   (coding-system-get coding-system :encode-translation-table))
 255
 256 ;;;###autoload
 257 (defun coding-system-equal (coding-system-1 coding-system-2)
 258   "Return t if and only if CODING-SYSTEM-1 and CODING-SYSTEM-2 are identical.
 259 Two coding systems are identical if two symbols are equal
 260 or one is an alias of the other."
 261   (or (eq coding-system-1 coding-system-2)
 262       (and (equal (coding-system-plist coding-system-1)
 263                   (coding-system-plist coding-system-2))
 264            (let ((eol-type-1 (coding-system-eol-type coding-system-1))
 265                  (eol-type-2 (coding-system-eol-type coding-system-2)))
 266              (or (eq eol-type-1 eol-type-2)
 267                  (and (vectorp eol-type-1) (vectorp eol-type-2)))))))
 268
 269 ;;;###autoload
 270 (defmacro detect-coding-with-priority (from to priority-list)
 271   "Detect a coding system of the text between FROM and TO with PRIORITY-LIST.
 272 PRIORITY-LIST is an alist of coding categories vs the corresponding
 273 coding systems ordered by priority."
 274   `(with-coding-priority (mapcar #'cdr ,priority-list)
 275      (detect-coding-region ,from ,to)))
 276 (make-obsolete 'detect-coding-with-priority
 277                "Use with-coding-priority and detect-coding-region" "22.1")
 278
 279 ;;;###autoload
 280 (defun detect-coding-with-language-environment (from to lang-env)
 281   "Detect a coding system of the text between FROM and TO with LANG-ENV.
 282 The detection takes into account the coding system priorities for the
 283 language environment LANG-ENV."
 284   (let ((coding-priority (get-language-info lang-env 'coding-priority)))
 285     (if coding-priority
 286         (with-coding-priority coding-priority
 287           (detect-coding-region from to)))))
 288
 289 ;;;###autoload
 290 (defmacro with-coding-priority (coding-systems &rest body)
 291   "Execute BODY like `progn' with CODING-SYSTEMS at the front of priority list.
 292 CODING-SYSTEMS is a list of coding systems.  See
 293 `set-coding-priority'.  This affects the implicit sorting of lists of
 294 coding sysems returned by operations such as `find-coding-systems-region'."
 295   (let ((current (make-symbol "current")))
 296   `(let ((,current (coding-system-priority-list)))
 297      (apply #'set-coding-system-priority ,coding-systems)
 298      (unwind-protect
 299          (progn ,@body)
 300        (apply #'set-coding-system-priority ,current)))))
 301 (put 'with-coding-priority 'lisp-indent-function 1)
 302 (put 'with-coding-priority 'edebug-form-spec t)
 303 \f
 304 (provide 'mule-util)
 305
 306 ;;; mule-util.el ends here