code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 dnl Fairly arbitrary, older versions might work too.
  30 AM_INIT_AUTOMAKE(1.11)
  31
  32 dnl Support for --program-prefix, --program-suffix and
  33 dnl --program-transform-name options
  34 AC_ARG_PROGRAM
  35
  36 dnl It is important that variables on the RHS not be expanded here,
  37 dnl hence the single quotes.  This is per the GNU coding standards, see
  38 dnl (autoconf) Installation Directory Variables
  39 dnl See also epaths.h below.
  40 lispdir='${datadir}/emacs/${version}/lisp'
  41 leimdir='${datadir}/emacs/${version}/leim'
  42 standardlisppath='${lispdir}:${leimdir}'
  43 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  44 '${datadir}/emacs/site-lisp'
  45 lisppath='${locallisppath}:${standardlisppath}'
  46 etcdir='${datadir}/emacs/${version}/etc'
  47 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  48 docdir='${datadir}/emacs/${version}/etc'
  49 gamedir='${localstatedir}/games/emacs'
  50
  51 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  52 dnl Create a new --with option that defaults to being disabled.
  53 dnl NAME is the base name of the option.  The shell variable with_NAME
  54 dnl   will be set to either the user's value (if the option is
  55 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  56 dnl   option is not specified).  Note that the shell variable name is
  57 dnl   constructed as autoconf does, by replacing non-alphanumeric
  58 dnl   characters with "_".
  59 dnl HELP-STRING is the help text for the option.
  60 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  61   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  62     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  63 ])dnl
  64
  65 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  66 dnl Create a new --with option that defaults to being enabled.  NAME
  67 dnl   is the base name of the option.  The shell variable with_NAME
  68 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  69 dnl   'yes' (if the option is not specified).  Note that the shell
  70 dnl   variable name is constructed as autoconf does, by replacing
  71 dnl   non-alphanumeric characters with "_".
  72 dnl HELP-STRING is the help text for the option.
  73 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  74   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  75    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  76 ])dnl
  77
  78 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  79 if test "$with_pop" = yes; then
  80    AC_DEFINE(MAIL_USE_POP)
  81 fi
  82 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  85 if test "$with_kerberos" != no; then
  86    AC_DEFINE(KERBEROS)
  87 fi
  88 AH_TEMPLATE(KERBEROS,
  89             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  90
  91 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  92 if test "${with_kerberos5}" != no; then
  93   if test "${with_kerberos}" = no; then
  94     with_kerberos=yes
  95     AC_DEFINE(KERBEROS)
  96   fi
  97   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  98 fi
  99
 100 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 101 dnl FIXME hesiod support may not be present, so it seems like an error
 102 dnl to define, or at least use, this unconditionally.
 103 if test "$with_hesiod" != no; then
 104   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 105 fi
 106
 107 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 108 if test "$with_mmdf" != no; then
 109    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 110 fi
 111
 112 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 113 if test "$with_mail_unlink" != no; then
 114    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 115 fi
 116
 117 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 118     [string giving default POP mail host])],
 119     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 120
 121 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 122
 123 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 124 if test "$with_sync_input" = yes; then
 125    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 126 fi
 127
 128 dnl FIXME currently it is not the last.
 129 dnl This should be the last --with option, because --with-x is
 130 dnl added later on when we find the path of X, and it's best to
 131 dnl keep them together visually.
 132 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 133  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 134 [         case "${withval}" in
 135             y | ye | yes )      val=gtk ;;
 136             n | no )            val=no  ;;
 137             l | lu | luc | luci | lucid )       val=lucid ;;
 138             a | at | ath | athe | athen | athena )      val=athena ;;
 139             m | mo | mot | moti | motif )       val=motif ;;
 140             g | gt | gtk  )     val=gtk ;;
 141             gtk3  )     val=gtk3 ;;
 142             * )
 143 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 144 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 145 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 146             ;;
 147           esac
 148           with_x_toolkit=$val
 149 ])
 150
 151 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 152 if test "$with_wide_int" = yes; then
 153   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 154 fi
 155
 156 dnl _ON results in a '--without' option in the --help output, so
 157 dnl the help text should refer to "don't compile", etc.
 158 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 159 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 160 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 161 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 162 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 163 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 164 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 165 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 166
 167 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 168 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 169 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 170
 171 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 172 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 173 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 174 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 175
 176 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 177 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 178 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 179 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 180 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 181 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 182
 183 ## For the times when you want to build Emacs but don't have
 184 ## a suitable makeinfo, and can live without the manuals.
 185 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 186 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 187
 188 ## Makefile.in needs the cache file name.
 189 AC_SUBST(cache_file)
 190
 191 ## This is an option because I do not know if all info/man support
 192 ## compressed files, nor how to test if they do so.
 193 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 194 if test $with_compress_info = yes; then
 195    GZIP_INFO=yes
 196 else
 197    GZIP_INFO=
 198 fi
 199 AC_SUBST(GZIP_INFO)
 200
 201 AC_ARG_WITH([pkg-config-prog],dnl
 202 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 203                   [path to pkg-config for finding GTK and librsvg])])
 204 if test "X${with_pkg_config_prog}" != X; then
 205    if test "${with_pkg_config_prog}" != yes; then
 206       PKG_CONFIG="${with_pkg_config_prog}"
 207    fi
 208 fi
 209
 210 CRT_DIR=
 211 AC_ARG_WITH([crt-dir],dnl
 212 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 213 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 214 CRT_DIR="${with_crt_dir}"
 215
 216 AC_ARG_WITH(gameuser,dnl
 217 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 218 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 219   && gameuser="${with_gameuser}"
 220 test "X$gameuser" = X && gameuser=games
 221
 222 AC_ARG_WITH([gnustep-conf],dnl
 223 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 224 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 225   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 226 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 227      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 228
 229 AC_ARG_ENABLE(ns-self-contained,
 230 [AS_HELP_STRING([--disable-ns-self-contained],
 231                 [disable self contained build under NeXTstep])],
 232    EN_NS_SELF_CONTAINED=$enableval,
 233    EN_NS_SELF_CONTAINED=yes)
 234
 235 AC_ARG_ENABLE(locallisppath,
 236 [AS_HELP_STRING([--enable-locallisppath=PATH],
 237                 [directories Emacs should search for lisp files specific
 238                  to this site])],
 239 if test "${enableval}" = "no"; then
 240   locallisppath=
 241 elif test "${enableval}" != "yes"; then
 242   locallisppath=${enableval}
 243 fi)
 244
 245 AC_ARG_ENABLE(checking,
 246 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 247                 [enable expensive run-time checks.  With LIST,
 248                  enable only specific categories of checks.
 249                  Categories are: all,yes,no.
 250                  Flags are: stringbytes, stringoverrun, stringfreelist,
 251                  xmallocoverrun, conslist, glyphs])],
 252 [ac_checking_flags="${enableval}"],[])
 253 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 254 for check in $ac_checking_flags
 255 do
 256         case $check in
 257         # these set all the flags to specific states
 258         yes)            ac_enable_checking=1 ;;
 259         no)             ac_enable_checking= ;
 260                         ac_gc_check_stringbytes= ;
 261                         ac_gc_check_string_overrun= ;
 262                         ac_gc_check_string_free_list= ;
 263                         ac_xmalloc_overrun= ;
 264                         ac_gc_check_cons_list= ;
 265                         ac_glyphs_debug= ;;
 266         all)            ac_enable_checking=1 ;
 267                         ac_gc_check_stringbytes=1 ;
 268                         ac_gc_check_string_overrun=1 ;
 269                         ac_gc_check_string_free_list=1 ;
 270                         ac_xmalloc_overrun=1 ;
 271                         ac_gc_check_cons_list=1 ;
 272                         ac_glyphs_debug=1 ;;
 273         # these enable particular checks
 274         stringbytes)    ac_gc_check_stringbytes=1 ;;
 275         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 276         stringfreelist) ac_gc_check_string_free_list=1 ;;
 277         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 278         conslist)       ac_gc_check_cons_list=1 ;;
 279         glyphs)         ac_glyphs_debug=1 ;;
 280         *)      AC_MSG_ERROR(unknown check category $check) ;;
 281         esac
 282 done
 283 IFS="$ac_save_IFS"
 284
 285 if test x$ac_enable_checking != x ; then
 286   AC_DEFINE(ENABLE_CHECKING, 1,
 287 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 288 fi
 289 if test x$ac_gc_check_stringbytes != x ; then
 290   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 291 [Define this temporarily to hunt a bug.  If defined, the size of
 292    strings is redundantly recorded in sdata structures so that it can
 293    be compared to the sizes recorded in Lisp strings.])
 294 fi
 295 if test x$ac_gc_check_string_overrun != x ; then
 296   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 297 [Define this to check for short string overrun.])
 298 fi
 299 if test x$ac_gc_check_string_free_list != x ; then
 300   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 301 [Define this to check the string free list.])
 302 fi
 303 if test x$ac_xmalloc_overrun != x ; then
 304   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 305 [Define this to check for malloc buffer overrun.])
 306 fi
 307 if test x$ac_gc_check_cons_list != x ; then
 308   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 309 [Define this to check for errors in cons list.])
 310 fi
 311 if test x$ac_glyphs_debug != x ; then
 312   AC_DEFINE(GLYPH_DEBUG, 1,
 313 [Define this to enable glyphs debugging code.])
 314 fi
 315
 316 AC_ARG_ENABLE(check-lisp-object-type,
 317 [AS_HELP_STRING([--enable-check-lisp-object-type],
 318                 [enable compile time checks for the Lisp_Object data type.
 319                 This is useful for development for catching certain types of bugs.])],
 320 if test "${enableval}" != "no"; then
 321    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 322    [Define this to enable compile time checks for the Lisp_Object data type.])
 323 fi)
 324
 325
 326 AC_ARG_ENABLE(profiling,
 327 [AS_HELP_STRING([--enable-profiling],
 328                 [build emacs with profiling support.
 329                  This might not work on all platforms])],
 330 [ac_enable_profiling="${enableval}"],[])
 331 if test x$ac_enable_profiling != x ; then
 332    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 333 else
 334    PROFILING_CFLAGS=
 335 fi
 336 AC_SUBST(PROFILING_CFLAGS)
 337
 338 AC_ARG_ENABLE(autodepend,
 339 [AS_HELP_STRING([--enable-autodepend],
 340                 [automatically generate dependencies to .h-files.
 341                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 342                  found])],
 343 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 344
 345 #### Make srcdir absolute, if it isn't already.  It's important to
 346 #### avoid running the path through pwd unnecessarily, since pwd can
 347 #### give you automounter prefixes, which can go away.  We do all this
 348 #### so Emacs can find its files when run uninstalled.
 349 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 350 unset CDPATH
 351 case "${srcdir}" in
 352   /* ) ;;
 353   . )
 354     ## We may be able to use the $PWD environment variable to make this
 355     ## absolute.  But sometimes PWD is inaccurate.
 356     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 357     ## but that tested only for a well-formed and valid PWD,
 358     ## it did not object when PWD was well-formed and valid but just wrong.
 359     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 360     then
 361       srcdir="$PWD"
 362     else
 363       srcdir="`(cd ${srcdir}; pwd)`"
 364     fi
 365   ;;
 366   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 367 esac
 368
 369 ### Canonicalize the configuration name.
 370
 371 AC_CANONICAL_HOST
 372 canonical=$host
 373 configuration=${host_alias-${build_alias-$host}}
 374
 375 dnl This used to use changequote, but, apart from `changequote is evil'
 376 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 377 dnl the great gob of text.  Thus it's not processed for possible expansion.
 378 dnl Just make sure the brackets remain balanced.
 379 dnl
 380 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 381 dnl indicated by comments.
 382 dnl quotation begins
 383 [
 384
 385 ### If you add support for a new configuration, add code to this
 386 ### switch statement to recognize your configuration name and select
 387 ### the appropriate operating system file.
 388
 389 ### You would hope that you could choose an s/*.h
 390 ### file based on the operating system portion.  However, it turns out
 391 ### that each s/*.h file is pretty manufacturer-specific.
 392 ### So we basically have to have a special case for each
 393 ### configuration name.
 394 ###
 395 ### As far as handling version numbers on operating systems is
 396 ### concerned, make sure things will fail in a fixable way.  If
 397 ### /etc/MACHINES doesn't say anything about version numbers, be
 398 ### prepared to handle anything reasonably.  If version numbers
 399 ### matter, be sure /etc/MACHINES says something about it.
 400
 401 opsys='' unported=no
 402 case "${canonical}" in
 403
 404   ## GNU/Linux and similar ports
 405   *-*-linux* )
 406     opsys=gnu-linux
 407   ;;
 408
 409   ## FreeBSD ports
 410   *-*-freebsd* )
 411     opsys=freebsd
 412   ;;
 413
 414   ## FreeBSD kernel + glibc based userland
 415   *-*-kfreebsd*gnu* )
 416     opsys=gnu-kfreebsd
 417   ;;
 418
 419   ## NetBSD ports
 420   *-*-netbsd* )
 421     opsys=netbsd
 422   ;;
 423
 424   ## OpenBSD ports
 425   *-*-openbsd* )
 426     opsys=openbsd
 427   ;;
 428
 429   ## Apple Darwin / Mac OS X
 430   *-apple-darwin* )
 431     case "${canonical}" in
 432       i[3456]86-* )  ;;
 433       powerpc-* )    ;;
 434       x86_64-* )     ;;
 435       * )            unported=yes ;;
 436     esac
 437     opsys=darwin
 438     ## Use fink packages if available.
 439     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 440 ##    if test -d /sw/include && test -d /sw/lib; then
 441 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 442 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 443 ##    fi
 444   ;;
 445
 446   ## HP 9000 series 700 and 800, running HP/UX
 447   hppa*-hp-hpux10.2* )
 448     opsys=hpux10-20
 449   ;;
 450   hppa*-hp-hpux1[1-9]* )
 451     opsys=hpux11
 452     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 453   ;;
 454
 455   ## IBM machines
 456   rs6000-ibm-aix4.[23]* )
 457     opsys=aix4-2
 458   ;;
 459   powerpc-ibm-aix4.[23]*  )
 460     opsys=aix4-2
 461   ;;
 462   rs6000-ibm-aix[56]* )
 463     opsys=aix4-2
 464   ;;
 465   powerpc-ibm-aix[56]*  )
 466     opsys=aix4-2
 467   ;;
 468
 469   ## Silicon Graphics machines
 470   ## Iris 4D
 471   mips-sgi-irix6.5 )
 472     opsys=irix6-5
 473     # Without defining _LANGUAGE_C, things get masked out in the headers
 474     # so that, for instance, grepping for `free' in stdlib.h fails and
 475     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 476     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 477   ;;
 478
 479   ## Suns
 480   *-sun-solaris* \
 481     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 482     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 483     case "${canonical}" in
 484       i[3456]86-*-* )   ;;
 485       amd64-*-*|x86_64-*-*) ;;
 486       sparc* )          ;;
 487       * )               unported=yes ;;
 488     esac
 489     case "${canonical}" in
 490       *-sunos5.6* | *-solaris2.6* )
 491                 opsys=sol2-6
 492                 RANLIB="ar -ts"
 493                 ;;
 494       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 495                 opsys=sol2-6
 496                 emacs_check_sunpro_c=yes
 497                 ;;
 498       *-sunos5* | *-solaris* )
 499                 opsys=sol2-10
 500                 emacs_check_sunpro_c=yes
 501                 ;;
 502     esac
 503     ## Watch out for a compiler that we know will not work.
 504     case "${canonical}" in
 505      *-solaris* | *-sunos5* )
 506                 if [ "x$CC" = x/usr/ucb/cc ]; then
 507                   ## /usr/ucb/cc doesn't work;
 508                   ## we should find some other compiler that does work.
 509                   unset CC
 510                 fi
 511                 ;;
 512       *) ;;
 513     esac
 514   ;;
 515
 516   ## Intel 386 machines where we don't care about the manufacturer.
 517   i[3456]86-*-* )
 518     case "${canonical}" in
 519       *-cygwin )                opsys=cygwin ;;
 520       *-darwin* )               opsys=darwin ;;
 521       *-sysv4.2uw* )            opsys=unixware ;;
 522       *-sysv5uw* )              opsys=unixware ;;
 523       *-sysv5OpenUNIX* )        opsys=unixware ;;
 524       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 525     esac
 526   ;;
 527
 528   * )
 529     unported=yes
 530   ;;
 531 esac
 532
 533 ### If the code above didn't choose an operating system, just choose
 534 ### an operating system based on the configuration name.  You really
 535 ### only want to use this when you have no idea what the right
 536 ### operating system is; if you know what operating systems a machine
 537 ### runs, it's cleaner to make it explicit in the case statement
 538 ### above.
 539 if test x"${opsys}" = x; then
 540   case "${canonical}" in
 541     *-gnu* )                            opsys=gnu ;;
 542     * )
 543       unported=yes
 544     ;;
 545   esac
 546 fi
 547
 548 ]
 549 dnl quotation ends
 550
 551 if test $unported = yes; then
 552   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 553 Check `etc/MACHINES' for recognized configuration names.])
 554 fi
 555
 556
 557 #### Choose a compiler.
 558
 559 dnl Sets GCC=yes if using gcc.
 560 AC_PROG_CC
 561 AM_PROG_CC_C_O
 562
 563 if test x$GCC = xyes; then
 564   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 565 else
 566   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 567 fi
 568
 569 # Initialize gnulib right after choosing the compiler.
 570 gl_EARLY
 571
 572 AC_ARG_ENABLE([gcc-warnings],
 573   [AS_HELP_STRING([--enable-gcc-warnings],
 574                   [turn on lots of GCC warnings. This is intended for
 575                    developers, and may generate false alarms when used
 576                    with older or non-GNU development tools.])],
 577   [case $enableval in
 578      yes|no) ;;
 579      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 580    esac
 581    gl_gcc_warnings=$enableval],
 582   [gl_gcc_warnings=no]
 583 )
 584
 585 AC_ARG_ENABLE(link-time-optimization,
 586 [AS_HELP_STRING([--enable-link-time-optimization],
 587                 [build emacs with link-time optimization.
 588                  This is supported only for GCC since 4.5.0.])],
 589 if test "${enableval}" != "no"; then
 590    AC_MSG_CHECKING([whether link-time optimization is supported])
 591    ac_lto_supported=no
 592    if test x$GCC = xyes; then
 593       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 594       if test x$CPUS != x; then
 595          LTO="-flto=$CPUS"
 596       else
 597          LTO="-flto"
 598       fi
 599       old_CFLAGS=$CFLAGS
 600       CFLAGS="$CFLAGS $LTO"
 601       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 602         [ac_lto_supported=yes], [ac_lto_supported=no])
 603       CFLAGS="$old_CFLAGS"
 604    fi
 605    AC_MSG_RESULT([$ac_lto_supported])
 606    if test "$ac_lto_supported" = "yes"; then
 607       CFLAGS="$CFLAGS $LTO"
 608    fi
 609 fi)
 610
 611 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 612 # ------------------------------------------------
 613 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 614 # Otherwise, run RUN-IF-NOT-FOUND.
 615 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 616   [AC_PREPROC_IFELSE(
 617     [AC_LANG_PROGRAM(
 618       [[
 619 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 620 /* ok */
 621 #else
 622 # error "your version of gcc is older than $1.$2"
 623 #endif
 624       ]]),
 625     ], [$3], [$4])
 626   ]
 627 )
 628
 629 # When compiling with GCC, prefer -isystem to -I when including system
 630 # include files, to avoid generating useless diagnostics for the files.
 631 if test "$gl_gcc_warnings" != yes; then
 632   isystem='-I'
 633 else
 634   isystem='-isystem '
 635
 636   # This, $nw, is the list of warnings we disable.
 637   nw=
 638
 639   case $with_x_toolkit in
 640     lucid | athena | motif)
 641        # Old toolkits mishandle 'const'.
 642        nw="$nw -Wwrite-strings"
 643        ;;
 644     *)
 645        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 646        ;;
 647   esac
 648   AC_SUBST([WERROR_CFLAGS])
 649
 650   nw="$nw -Waggregate-return"       # anachronistic
 651   nw="$nw -Wlong-long"              # C90 is anachronistic
 652   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 653   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 654   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 655   nw="$nw -Wcast-qual"              # Too many warnings for now
 656   nw="$nw -Wconversion"             # Too many warnings for now
 657   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 658   nw="$nw -Wsign-conversion"        # Too many warnings for now
 659   nw="$nw -Woverlength-strings"     # Not a problem these days
 660   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 661   nw="$nw -Wunreachable-code"       # so buggy that it's now silently ignored
 662   nw="$nw -Wpadded"                 # Our structs are not padded
 663   nw="$nw -Wredundant-decls"        # we regularly (re)declare functions
 664   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 665   nw="$nw -Wformat-nonliteral"      # we do this a lot
 666   nw="$nw -Wvla"                    # warnings in gettext.h
 667   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 668   nw="$nw -Wswitch-enum"            # Too many warnings for now
 669   nw="$nw -Wswitch-default"         # Too many warnings for now
 670   nw="$nw -Wfloat-equal"            # warns about high-quality code
 671   nw="$nw -Winline"                 # OK to ignore 'inline'
 672   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 673   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 674
 675   # Emacs doesn't care about shadowing; see
 676   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 677   nw="$nw -Wshadow"
 678
 679   # The following lines should be removable at some point.
 680   nw="$nw -Wstack-protector"
 681   nw="$nw -Wstrict-overflow"
 682   nw="$nw -Wsuggest-attribute=pure"
 683
 684   gl_MANYWARN_ALL_GCC([ws])
 685   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 686   for w in $ws; do
 687     gl_WARN_ADD([$w])
 688   done
 689   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 690   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 691   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 692   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 693   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 694   gl_WARN_ADD([-Wno-format-nonliteral])
 695
 696   # In spite of excluding -Wlogical-op above, it is enabled, as of
 697   # gcc 4.5.0 20090517.
 698   gl_WARN_ADD([-Wno-logical-op])
 699
 700   gl_WARN_ADD([-fdiagnostics-show-option])
 701   gl_WARN_ADD([-funit-at-a-time])
 702
 703   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 704   AC_DEFINE([_FORTIFY_SOURCE], [2],
 705     [enable compile-time and run-time bounds-checking, and some warnings])
 706   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 707
 708   # We use a slightly smaller set of warning options for lib/.
 709   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 710   nw=
 711   nw="$nw -Wunused-macros"
 712
 713   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 714   AC_SUBST([GNULIB_WARN_CFLAGS])
 715 fi
 716
 717
 718
 719 dnl Some other nice autoconf tests.
 720 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 721 dnl AC_PROG_INSTALL
 722 dnl AC_PROG_MKDIR_P
 723 dnl if test "x$RANLIB" = x; then
 724 dnl   AC_PROG_RANLIB
 725 dnl fi
 726
 727 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 728   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 729 dnl Don't use GZIP, which is used by gzip for additional parameters.
 730 AC_PATH_PROG(GZIP_PROG, gzip)
 731
 732 if test $opsys = gnu-linux; then
 733   AC_PATH_PROG(PAXCTL, paxctl,,
 734     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 735   if test "X$PAXCTL" != X; then
 736     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
 737     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 738       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
 739       else AC_MSG_RESULT(no); PAXCTL=""; fi])
 740   fi
 741 fi
 742
 743 ## Need makeinfo >= 4.7 (?) to build the manuals.
 744 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 745 dnl By this stage, configure has already checked for egrep and set EGREP,
 746 dnl or exited with an error if no egrep was found.
 747 if test "$MAKEINFO" != "no" && \
 748   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 749    MAKEINFO=no
 750 fi
 751
 752 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 753 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 754 ## therefore in the category of "special tools" not normally required, which
 755 ## configure does not have to check for (eg autoconf itself).
 756 ## In a Bazaar checkout on the other hand, the manuals are not included.
 757 ## So makeinfo is a requirement to build from Bazaar, and configure
 758 ## should test for it as it does for any other build requirement.
 759 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 760 ## with pre-built manuals, from a Bazaar checkout.
 761 HAVE_MAKEINFO=yes
 762
 763 if test "$MAKEINFO" = "no"; then
 764   MAKEINFO=makeinfo
 765   if test "x${with_makeinfo}" = "xno"; then
 766     HAVE_MAKEINFO=no
 767   elif test ! -e $srcdir/info/emacs; then
 768     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 769 source tree does not seem to have pre-built manuals in the `info' directory.
 770 Either install a suitable version of makeinfo, or re-run configure
 771 with the `--without-makeinfo' option to build without the manuals.] )
 772   fi
 773 fi
 774 AC_SUBST(HAVE_MAKEINFO)
 775
 776 dnl Just so that there is only a single place we need to edit.
 777 INFO_EXT=.info
 778 INFO_OPTS=--no-split
 779 AC_SUBST(INFO_EXT)
 780 AC_SUBST(INFO_OPTS)
 781
 782 dnl Add our options to ac_link now, after it is set up.
 783
 784 if test x$GCC = xyes; then
 785   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 786     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 787 else
 788   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 789     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 790 fi
 791
 792 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 793 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 794 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 795 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 796 dnl if not built to support GNU ld.
 797
 798 late_LDFLAGS=$LDFLAGS
 799 if test x$GCC = xyes; then
 800   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 801 else
 802   LDFLAGS="$LDFLAGS -znocombreloc"
 803 fi
 804
 805 AC_MSG_CHECKING([for -znocombreloc])
 806 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 807   [AC_MSG_RESULT(yes)],
 808   LDFLAGS=$late_LDFLAGS
 809   [AC_MSG_RESULT(no)])
 810
 811
 812 dnl The function dump-emacs will not be defined and temacs will do
 813 dnl (load "loadup") automatically unless told otherwise.
 814 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 815 case "$opsys" in
 816   your-opsys-here) CANNOT_DUMP=yes ;;
 817 esac
 818
 819 test "$CANNOT_DUMP" = "yes" && \
 820   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 821
 822 AC_SUBST(CANNOT_DUMP)
 823
 824
 825 UNEXEC_OBJ=unexelf.o
 826 case "$opsys" in
 827   # MSDOS uses unexcoff.o
 828   # MSWindows uses unexw32.o
 829   aix4-2)
 830    UNEXEC_OBJ=unexaix.o
 831    ;;
 832   cygwin)
 833    UNEXEC_OBJ=unexcw.o
 834    ;;
 835   darwin)
 836    UNEXEC_OBJ=unexmacosx.o
 837    ;;
 838   hpux10-20 | hpux11)
 839    UNEXEC_OBJ=unexhp9k800.o
 840    ;;
 841   sol2-10)
 842    # Use the Solaris dldump() function, called from unexsol.c, to dump
 843    # emacs, instead of the generic ELF dump code found in unexelf.c.
 844    # The resulting binary has a complete symbol table, and is better
 845    # for debugging and other observability tools (debuggers, pstack, etc).
 846    #
 847    # If you encounter a problem using dldump(), please consider sending
 848    # a message to the OpenSolaris tools-linking mailing list:
 849    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 850    #
 851    # It is likely that dldump() works with older Solaris too, but this has
 852    # not been tested, so for now this change is for Solaris 10 or newer.
 853    UNEXEC_OBJ=unexsol.o
 854    ;;
 855 esac
 856
 857 LD_SWITCH_SYSTEM=
 858 case "$opsys" in
 859   freebsd)
 860    ## Let `ld' find image libs and similar things in /usr/local/lib.
 861    ## The system compiler, GCC, has apparently been modified to not
 862    ## look there, contrary to what a stock GCC would do.
 863 ### It's not our place to do this.  See bug#10313#17.
 864 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 865       :
 866    ;;
 867
 868   gnu-linux)
 869    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 870    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 871    ;;
 872
 873   netbsd)
 874 ### It's not our place to do this.  See bug#10313#17.
 875 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 876       :
 877    ;;
 878
 879   openbsd)
 880    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 881    ## otherwise Emacs dumps core on elf systems.
 882    LD_SWITCH_SYSTEM="-Z"
 883    ;;
 884 esac
 885 AC_SUBST(LD_SWITCH_SYSTEM)
 886
 887 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 888
 889 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 890 ## which has not been defined yet.  When this was handled with cpp,
 891 ## it was expanded to null when configure sourced the s/*.h file.
 892 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 893 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 894 ## (or somesuch), but because it is supposed to go at the _front_
 895 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 896 ## Compare with the gnu-linux case below, which added to the end
 897 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 898 ## LD_SWITCH_SYSTEM_TEMACS.
 899 case "$opsys" in
 900   netbsd|openbsd)
 901    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 902 esac
 903
 904
 905 C_SWITCH_MACHINE=
 906 case $canonical in
 907  alpha*)
 908   AC_CHECK_DECL([__ELF__])
 909   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 910     ## With ELF, make sure that all common symbols get allocated to in the
 911     ## data section.  Otherwise, the dump of temacs may miss variables in
 912     ## the shared library that have been initialized.  For example, with
 913     ## GNU libc, __malloc_initialized would normally be resolved to the
 914     ## shared library's .bss section, which is fatal.
 915     if test "x$GCC" = "xyes"; then
 916       C_SWITCH_MACHINE="-fno-common"
 917     else
 918       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 919     fi
 920   else
 921     UNEXEC_OBJ=unexalpha.o
 922   fi
 923   ;;
 924 esac
 925 AC_SUBST(C_SWITCH_MACHINE)
 926
 927 AC_SUBST(UNEXEC_OBJ)
 928
 929 C_SWITCH_SYSTEM=
 930 ## Some programs in src produce warnings saying certain subprograms
 931 ## are too complex and need a MAXMEM value greater than 2000 for
 932 ## additional optimization.  --nils@exp-math.uni-essen.de
 933 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 934   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 935 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 936 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 937 AC_SUBST(C_SWITCH_SYSTEM)
 938
 939
 940 LIBS_SYSTEM=
 941 case "$opsys" in
 942   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 943   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 944
 945   freebsd) LIBS_SYSTEM="-lutil" ;;
 946
 947   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 948
 949   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 950
 951   ## Motif needs -lgen.
 952   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 953 esac
 954 AC_SUBST(LIBS_SYSTEM)
 955
 956
 957 ### Make sure subsequent tests use flags consistent with the build flags.
 958
 959 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 960   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 961 else
 962   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 963 fi
 964
 965 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 966 AC_DEFUN([AC_TYPE_SIZE_T])
 967 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 968 AC_DEFUN([AC_TYPE_UID_T])
 969
 970
 971 LIB_MATH=-lm
 972 LIB_STANDARD=
 973 START_FILES=
 974 dnl Current possibilities handled by sed (aix4-2 -> aix,
 975 dnl gnu-linux -> gnu/linux, etc.):
 976 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
 977 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
 978 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
 979
 980 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
 981 case $opsys in
 982   cygwin )
 983     LIB_MATH=
 984     START_FILES='pre-crt0.o'
 985     ;;
 986   darwin )
 987     ## Adding -lm confuses the dynamic linker, so omit it.
 988     LIB_MATH=
 989     START_FILES='pre-crt0.o'
 990     ;;
 991   freebsd )
 992     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
 993     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
 994     SYSTEM_TYPE=berkeley-unix
 995     ;;
 996   gnu-linux | gnu-kfreebsd )
 997     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
 998     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
 999     ;;
1000   hpux10-20 | hpux11 )
1001     LIB_STANDARD=-lc
1002     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1003     ;;
1004   dnl NB this may be adjusted below.
1005   netbsd | openbsd )
1006     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1007     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1008     SYSTEM_TYPE=berkeley-unix
1009     ;;
1010
1011   sol2* | unixware )
1012     SYSTEM_TYPE=usg-unix-v
1013     ;;
1014
1015 esac
1016
1017 AC_SUBST(LIB_MATH)
1018 AC_SUBST(START_FILES)
1019 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1020   [The type of system you are compiling for; sets `system-type'.])
1021
1022 dnl Not all platforms use crtn.o files.  Check if the current one does.
1023 crt_files=
1024
1025 for file in x $LIB_STANDARD $START_FILES; do
1026   case "$file" in
1027     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1028   esac
1029 done
1030
1031 if test "x$crt_files" != x; then
1032
1033   ## If user specified a crt-dir, use that unconditionally.
1034   crt_gcc=no
1035
1036   if test "X$CRT_DIR" = "X"; then
1037
1038     CRT_DIR=/usr/lib            # default
1039
1040     case "$canonical" in
1041       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1042       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1043       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1044       ## For anything else (eg /usr/lib32), it is up the user to specify
1045       ## the location (bug#5655).
1046       ## Test for crtn.o, not just the directory, because sometimes the
1047       ## directory exists but does not have the relevant files (bug#1287).
1048       ## FIXME better to test for binary compatibility somehow.
1049       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1050       ;;
1051
1052       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1053     esac
1054
1055     case "$opsys" in
1056       hpux10-20) CRT_DIR=/lib ;;
1057     esac
1058
1059     test "x${GCC}" = xyes && crt_gcc=yes
1060
1061   fi                            # CRT_DIR = ""
1062
1063   crt_missing=
1064
1065   for file in $crt_files; do
1066
1067     ## If we're using gcc, try to determine it automatically by asking
1068     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1069     ## system-dependent default from above.]
1070     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1071
1072        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1073        case "$crt_file" in
1074          */*)
1075            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1076            ;;
1077        esac
1078     fi
1079
1080     dnl We expect all the files to be in a single directory, so after the
1081     dnl first there is no point asking gcc.
1082     crt_gcc=no
1083
1084     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1085   done                          # $crt_files
1086
1087   test "x$crt_missing" = x || \
1088     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1089 Try using the --with-crt-dir option.])
1090
1091 fi                              # crt_files != ""
1092
1093 AC_SUBST(CRT_DIR)
1094
1095 case $opsys in
1096   netbsd | openbsd )
1097     if test -f $CRT_DIR/crti.o; then
1098
1099         test -f $CRT_DIR/crtn.o || \
1100           AC_MSG_ERROR([Required file not found: crtn.o])
1101
1102         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1103         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1104     fi
1105     ;;
1106 esac
1107
1108
1109 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1110 pre_PKG_CONFIG_LIBS=$LIBS
1111
1112 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1113
1114 dnl This function definition taken from Gnome 2.0
1115 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1116 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1117 dnl also defines GSTUFF_PKG_ERRORS on error
1118 AC_DEFUN([PKG_CHECK_MODULES], [
1119   succeeded=no
1120
1121   if test "$PKG_CONFIG" = "no" ; then
1122      ifelse([$4], , [AC_MSG_ERROR([
1123       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1124   else
1125      PKG_CONFIG_MIN_VERSION=0.9.0
1126      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1127         AC_MSG_CHECKING(for $2)
1128
1129         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1130            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1131            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1132             edit_cflags="
1133               s,///*,/,g
1134               s/^/ /
1135               s/ -I/ $isystem/g
1136               s/^ //
1137             "
1138             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1139             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1140             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1141             succeeded=yes
1142         else
1143             AC_MSG_RESULT(no)
1144             $1_CFLAGS=""
1145             $1_LIBS=""
1146             ## If we have a custom action on failure, don't print errors, but
1147             ## do set a variable so people can do so.
1148             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1149             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1150         fi
1151
1152         AC_SUBST($1_CFLAGS)
1153         AC_SUBST($1_LIBS)
1154      else
1155         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1156         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1157      fi
1158   fi
1159
1160   if test $succeeded = yes; then
1161      ifelse([$3], , :, [$3])
1162   else
1163      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1164   fi
1165 ])
1166
1167
1168 if test "${with_sound}" != "no"; then
1169   # Sound support for GNU/Linux and the free BSDs.
1170   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1171     have_sound_header=yes)
1172   # Emulation library used on NetBSD.
1173   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1174   AC_SUBST(LIBSOUND)
1175
1176   ALSA_REQUIRED=1.0.0
1177   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1178   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1179   if test $HAVE_ALSA = yes; then
1180     SAVE_CFLAGS="$CFLAGS"
1181     SAVE_LIBS="$LIBS"
1182     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1183     LIBS="$ALSA_LIBS $LIBS"
1184     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1185                     emacs_alsa_normal=yes,
1186                     emacs_alsa_normal=no)
1187     if test "$emacs_alsa_normal" != yes; then
1188       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1189                      [[snd_lib_error_set_handler (0);]])],
1190                      emacs_alsa_subdir=yes,
1191                      emacs_alsa_subdir=no)
1192       if test "$emacs_alsa_subdir" != yes; then
1193         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1194       fi
1195       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1196     fi
1197
1198     CFLAGS="$SAVE_CFLAGS"
1199     LIBS="$SAVE_LIBS"
1200     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1201     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1202     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1203   fi
1204
1205   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1206   dnl compiles only on the specified platforms.  For others, it
1207   dnl probably doesn't make sense to try.
1208   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1209      case "$opsys" in
1210        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1211        gnu-linux|freebsd|netbsd)
1212          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1213          ;;
1214      esac
1215   fi
1216
1217   AC_SUBST(CFLAGS_SOUND)
1218 fi
1219
1220 dnl checks for header files
1221 AC_CHECK_HEADERS_ONCE(
1222   linux/version.h sys/systeminfo.h
1223   stdio_ext.h fcntl.h coff.h pty.h
1224   sys/vlimit.h sys/resource.h
1225   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1226
1227 AC_MSG_CHECKING(if personality LINUX32 can be set)
1228 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1229                emacs_cv_personality_linux32=yes,
1230                emacs_cv_personality_linux32=no)
1231 AC_MSG_RESULT($emacs_cv_personality_linux32)
1232
1233 if test $emacs_cv_personality_linux32 = yes; then
1234   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1235             [Define to 1 if personality LINUX32 can be set.])
1236 fi
1237
1238 dnl On Solaris 8 there's a compilation warning for term.h because
1239 dnl it doesn't define `bool'.
1240 AC_CHECK_HEADERS(term.h, , , -)
1241 AC_HEADER_TIME
1242 AC_CHECK_DECLS([sys_siglist])
1243 if test $ac_cv_have_decl_sys_siglist != yes; then
1244   # For Tru64, at least:
1245   AC_CHECK_DECLS([__sys_siglist])
1246   if test $ac_cv_have_decl___sys_siglist = yes; then
1247     AC_DEFINE(sys_siglist, __sys_siglist,
1248               [Define to any substitute for sys_siglist.])
1249   fi
1250 fi
1251 AC_HEADER_SYS_WAIT
1252
1253 dnl Check for speed_t typedef.
1254 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1255   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1256     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1257 if test $emacs_cv_speed_t = yes; then
1258   AC_DEFINE(HAVE_SPEED_T, 1,
1259            [Define to 1 if `speed_t' is declared by <termios.h>.])
1260 fi
1261
1262 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1263 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1264 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1265   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1266 HAVE_EXCEPTION=$emacs_cv_struct_exception
1267 dnl Define on Darwin so emacs symbols will not conflict with those
1268 dnl in the System framework.  Otherwise -prebind will not work.
1269 if test $emacs_cv_struct_exception != yes || test $opsys = darwin; then
1270   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1271 fi
1272
1273 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1274 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1275 #if HAVE_SYS_SOCKET_H
1276 #include <sys/socket.h>
1277 #endif])
1278 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1279 #if HAVE_SYS_SOCKET_H
1280 #include <sys/socket.h>
1281 #endif])
1282 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1283 #if HAVE_SYS_SOCKET_H
1284 #include <sys/socket.h>
1285 #endif])
1286
1287 dnl checks for structure members
1288 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1289                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1290                   struct ifreq.ifr_addr,
1291                   struct ifreq.ifr_addr.sa_len], , ,
1292                  [AC_INCLUDES_DEFAULT
1293 #if HAVE_SYS_SOCKET_H
1294 #include <sys/socket.h>
1295 #endif
1296 #if HAVE_NET_IF_H
1297 #include <net/if.h>
1298 #endif])
1299
1300 dnl Check for endianness.
1301 dnl AC_C_BIGENDIAN is done by gnulib.
1302
1303 dnl check for Make feature
1304 dnl AC_PROG_MAKE_SET is done by Automake.
1305
1306 DEPFLAGS=
1307 MKDEPDIR=":"
1308 deps_frag=deps.mk
1309 dnl check for GNU Make if we have GCC and autodepend is on.
1310 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1311    AC_MSG_CHECKING([whether we are using GNU Make])
1312    HAVE_GNU_MAKE=no
1313    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1314    if test "x$testval" != x; then
1315       HAVE_GNU_MAKE=yes
1316    else
1317       ac_enable_autodepend=no
1318    fi
1319    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1320    if test $HAVE_GNU_MAKE = yes; then
1321       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1322       SAVE_CFLAGS="$CFLAGS"
1323       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1324       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1325       CFLAGS="$SAVE_CFLAGS"
1326       test -f deps.d || ac_enable_autodepend=no
1327       rm -rf deps.d
1328       AC_MSG_RESULT([$ac_enable_autodepend])
1329    fi
1330    if test $ac_enable_autodepend = yes; then
1331       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1332       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1333       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1334       deps_frag=autodeps.mk
1335    fi
1336 fi
1337 deps_frag=$srcdir/src/$deps_frag
1338 AC_SUBST(MKDEPDIR)
1339 AC_SUBST(DEPFLAGS)
1340 AC_SUBST_FILE(deps_frag)
1341
1342
1343 lisp_frag=$srcdir/src/lisp.mk
1344 AC_SUBST_FILE(lisp_frag)
1345
1346
1347 dnl checks for operating system services
1348 AC_SYS_LONG_FILE_NAMES
1349
1350 #### Choose a window system.
1351
1352 AC_PATH_X
1353 if test "$no_x" = yes; then
1354   window_system=none
1355 else
1356   window_system=x11
1357 fi
1358
1359 LD_SWITCH_X_SITE_RPATH=
1360 if test "${x_libraries}" != NONE; then
1361   if test -n "${x_libraries}"; then
1362     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1363     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1364   fi
1365   x_default_search_path=""
1366   x_search_path=${x_libraries}
1367   if test -z "${x_search_path}"; then
1368     x_search_path=/usr/lib
1369   fi
1370   for x_library in `echo ${x_search_path}: | \
1371                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1372     x_search_path="\
1373 ${x_library}/X11/%L/%T/%N%C%S:\
1374 ${x_library}/X11/%l/%T/%N%C%S:\
1375 ${x_library}/X11/%T/%N%C%S:\
1376 ${x_library}/X11/%L/%T/%N%S:\
1377 ${x_library}/X11/%l/%T/%N%S:\
1378 ${x_library}/X11/%T/%N%S"
1379     if test x"${x_default_search_path}" = x; then
1380       x_default_search_path=${x_search_path}
1381     else
1382       x_default_search_path="${x_search_path}:${x_default_search_path}"
1383     fi
1384   done
1385 fi
1386 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1387
1388 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1389   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1390 fi
1391
1392 if test x"${x_includes}" = x; then
1393   bitmapdir=/usr/include/X11/bitmaps
1394 else
1395   # accumulate include directories that have X11 bitmap subdirectories
1396   bmd_acc="dummyval"
1397   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1398     if test -d "${bmd}/X11/bitmaps"; then
1399       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1400     fi
1401     if test -d "${bmd}/bitmaps"; then
1402       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1403     fi
1404   done
1405   if test ${bmd_acc} != "dummyval"; then
1406     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1407   fi
1408 fi
1409
1410 HAVE_NS=no
1411 NS_IMPL_COCOA=no
1412 NS_IMPL_GNUSTEP=no
1413 tmp_CPPFLAGS="$CPPFLAGS"
1414 tmp_CFLAGS="$CFLAGS"
1415 CPPFLAGS="$CPPFLAGS -x objective-c"
1416 CFLAGS="$CFLAGS -x objective-c"
1417 TEMACS_LDFLAGS2="\${LDFLAGS}"
1418 GNU_OBJC_CFLAGS=
1419 if test "${with_ns}" != no; then
1420   if test "${opsys}" = darwin; then
1421      NS_IMPL_COCOA=yes
1422      ns_appdir=`pwd`/nextstep/Emacs.app
1423      ns_appbindir=${ns_appdir}/Contents/MacOS
1424      ns_appresdir=${ns_appdir}/Contents/Resources
1425      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1426   elif test -f $GNUSTEP_CONFIG_FILE; then
1427      NS_IMPL_GNUSTEP=yes
1428      ns_appdir=`pwd`/nextstep/Emacs.app
1429      ns_appbindir=${ns_appdir}
1430      ns_appresdir=${ns_appdir}/Resources
1431      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1432      dnl FIXME sourcing this several times in subshells seems inefficient.
1433      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1434      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1435      dnl I seemed to need these as well with GNUstep-startup 0.25.
1436      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1437      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1438      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1439        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1440      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1441        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1442      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1443      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1444      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1445      LIB_STANDARD=
1446      START_FILES=
1447      TEMACS_LDFLAGS2=
1448      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1449      dnl If they had chosen to either define it or not, we could have
1450      dnl just used AC_CHECK_DECL here.
1451      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1452        emacs_cv_objc_exceptions,
1453 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1454 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1455 1;
1456 #else
1457 fail;
1458 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1459      if test $emacs_cv_objc_exceptions = yes; then
1460        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1461        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1462          [Define if GNUstep uses ObjC exceptions.])
1463        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1464      fi
1465   fi
1466
1467   dnl This is only used while we test the NS headers, it gets reset below.
1468   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1469
1470   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1471                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1472   files are missing or cannot be compiled.])])
1473   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1474                                      [NSInteger i;])],
1475                     ns_have_nsinteger=yes,
1476                     ns_have_nsinteger=no)
1477   if test $ns_have_nsinteger = yes; then
1478     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1479   fi
1480 fi
1481 AC_SUBST(TEMACS_LDFLAGS2)
1482
1483 INSTALL_ARCH_INDEP_EXTRA=install-etc
1484 ns_self_contained=no
1485 ns_frag=/dev/null
1486 NS_OBJ=
1487 NS_OBJC_OBJ=
1488 if test "${HAVE_NS}" = yes; then
1489   if test "$with_toolkit_scroll_bars" = "no"; then
1490     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1491   fi
1492
1493   window_system=nextstep
1494   with_xft=no
1495   # set up packaging dirs
1496   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1497      ns_self_contained=yes
1498      prefix=${ns_appresdir}
1499      exec_prefix=${ns_appbindir}
1500      dnl This one isn't really used, only archlibdir is.
1501      libexecdir="\${ns_appbindir}/libexec"
1502      archlibdir="\${ns_appbindir}/libexec"
1503      docdir="\${ns_appresdir}/etc"
1504      etcdir="\${ns_appresdir}/etc"
1505      dnl FIXME maybe set datarootdir instead.
1506      dnl That would also get applications, icons, man.
1507      infodir="\${ns_appresdir}/info"
1508      mandir="\${ns_appresdir}/man"
1509      lispdir="\${ns_appresdir}/lisp"
1510      leimdir="\${ns_appresdir}/leim"
1511      INSTALL_ARCH_INDEP_EXTRA=
1512   fi
1513   ns_frag=$srcdir/src/ns.mk
1514   NS_OBJ="fontset.o fringe.o image.o"
1515   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1516 fi
1517 CFLAGS="$tmp_CFLAGS"
1518 CPPFLAGS="$tmp_CPPFLAGS"
1519 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1520 AC_SUBST(ns_self_contained)
1521 AC_SUBST(NS_OBJ)
1522 AC_SUBST(NS_OBJC_OBJ)
1523 AC_SUBST(LIB_STANDARD)
1524 AC_SUBST_FILE(ns_frag)
1525
1526 case "${window_system}" in
1527   x11 )
1528     HAVE_X_WINDOWS=yes
1529     HAVE_X11=yes
1530     case "${with_x_toolkit}" in
1531       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1532       motif ) USE_X_TOOLKIT=MOTIF ;;
1533       gtk ) with_gtk=yes
1534 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1535 dnl USE_X_TOOLKIT is set.
1536             USE_X_TOOLKIT=none ;;
1537       gtk3 ) with_gtk3=yes
1538              USE_X_TOOLKIT=none ;;
1539       no ) USE_X_TOOLKIT=none ;;
1540 dnl If user did not say whether to use a toolkit, make this decision later:
1541 dnl use the toolkit if we have gtk, or X11R5 or newer.
1542       * ) USE_X_TOOLKIT=maybe ;;
1543     esac
1544   ;;
1545   nextstep | none )
1546     HAVE_X_WINDOWS=no
1547     HAVE_X11=no
1548     USE_X_TOOLKIT=none
1549   ;;
1550 esac
1551
1552 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1553    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1554    if test "$HAVE_XSERVER" = true ||
1555       test -n "$DISPLAY" ||
1556       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1557         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1558 were found.  You should install the relevant development files for X
1559 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1560 sure you have development files for image handling, i.e.
1561 tiff, gif, jpeg, png and xpm.
1562 If you are sure you want Emacs compiled without X window support, pass
1563   --without-x
1564 to configure.])
1565    fi
1566 fi
1567
1568 ### If we're using X11, we should use the X menu package.
1569 HAVE_MENUS=no
1570 case ${HAVE_X11} in
1571   yes ) HAVE_MENUS=yes ;;
1572 esac
1573
1574 # Does the opsystem file prohibit the use of the GNU malloc?
1575 # Assume not, until told otherwise.
1576 GNU_MALLOC=yes
1577
1578 AC_CACHE_CHECK(
1579   [whether malloc is Doug Lea style],
1580   [emacs_cv_var_doug_lea_malloc],
1581   [AC_LINK_IFELSE(
1582      [AC_LANG_PROGRAM(
1583         [[#include <malloc.h>
1584           static void hook (void) {}]],
1585         [[malloc_set_state (malloc_get_state ());
1586           __after_morecore_hook = hook;
1587           __malloc_initialize_hook = hook;]])],
1588      [emacs_cv_var_doug_lea_malloc=yes],
1589      [emacs_cv_var_doug_lea_malloc=no])])
1590 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1591
1592
1593 dnl See comments in aix4-2.h about maybe using system malloc there.
1594 system_malloc=no
1595 case "$opsys" in
1596   ## darwin ld insists on the use of malloc routines in the System framework.
1597   darwin|sol2-10) system_malloc=yes ;;
1598 esac
1599
1600 if test "${system_malloc}" = "yes"; then
1601   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1602   GNU_MALLOC=no
1603   GNU_MALLOC_reason="
1604     (The GNU allocators don't work with this system configuration.)"
1605   GMALLOC_OBJ=
1606   VMLIMIT_OBJ=
1607 else
1608   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1609   VMLIMIT_OBJ=vm-limit.o
1610 fi
1611 AC_SUBST(GMALLOC_OBJ)
1612 AC_SUBST(VMLIMIT_OBJ)
1613
1614 if test "$doug_lea_malloc" = "yes" ; then
1615   if test "$GNU_MALLOC" = yes ; then
1616     GNU_MALLOC_reason="
1617       (Using Doug Lea's new malloc from the GNU C Library.)"
1618   fi
1619   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1620             [Define to 1 if you are using the GNU C Library.])
1621
1622   ## Use mmap directly for allocating larger buffers.
1623   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1624   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1625   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1626   case "$opsys" in
1627     gnu*) REL_ALLOC=no ;;
1628   esac
1629 fi
1630
1631 if test x"${REL_ALLOC}" = x; then
1632   REL_ALLOC=${GNU_MALLOC}
1633 fi
1634
1635 use_mmap_for_buffers=no
1636 case "$opsys" in
1637   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1638 esac
1639
1640 AC_FUNC_MMAP
1641 if test $use_mmap_for_buffers = yes; then
1642   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1643   REL_ALLOC=no
1644 fi
1645
1646 LIBS="$LIBS_SYSTEM $LIBS"
1647
1648 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1649 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1650 AC_CHECK_LIB(dnet, dnet_ntoa)
1651 dnl This causes -lresolv to get used in subsequent tests,
1652 dnl which causes failures on some systems such as HPUX 9.
1653 dnl AC_CHECK_LIB(resolv, gethostbyname)
1654
1655 dnl FIXME replace main with a function we actually want from this library.
1656 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1657
1658 dnl Check if pthreads is available.
1659 LIB_PTHREAD=
1660 AC_CHECK_HEADERS_ONCE(pthread.h)
1661 if test "$ac_cv_header_pthread_h"; then
1662   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1663   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1664   dnl testing for pthread_self if Emacs uses gmalloc.c.
1665   if test "$GMALLOC_OBJ" = gmalloc.o; then
1666     emacs_pthread_function=pthread_atfork
1667   else
1668     emacs_pthread_function=pthread_self
1669   fi
1670   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1671 fi
1672 if test "$HAVE_PTHREAD" = yes; then
1673   case "${canonical}" in
1674     *-hpux*) ;;
1675     *) LIB_PTHREAD="-lpthread"
1676        LIBS="$LIB_PTHREAD $LIBS" ;;
1677   esac
1678   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1679 fi
1680 AC_SUBST([LIB_PTHREAD])
1681
1682 AC_CHECK_LIB(pthreads, cma_open)
1683
1684 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1685 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1686 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1687 ## added to LIBS in configure would never contain the pthreads part,
1688 ## but the value used in Makefiles might.  FIXME?
1689 ##
1690 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1691 ## be harmless on older versions of X where it happens to exist.
1692 test "$opsys" = "aix4-2" && \
1693   test $ac_cv_lib_pthreads_cma_open = yes && \
1694   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1695
1696 dnl Check for need for bigtoc support on IBM AIX
1697
1698 case ${host_os} in
1699 aix*)
1700   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1701     case $GCC in
1702     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1703     *) gdb_cv_bigtoc=-bbigtoc ;;
1704     esac
1705
1706     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1707     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1708   ])
1709   ;;
1710 esac
1711
1712 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1713 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1714 # REAL_CPPFLAGS later on.
1715
1716 REAL_CFLAGS="$CFLAGS"
1717 REAL_CPPFLAGS="$CPPFLAGS"
1718
1719 if test "${HAVE_X11}" = "yes"; then
1720   DEFS="$C_SWITCH_X_SITE $DEFS"
1721   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1722   LIBS="-lX11 $LIBS"
1723   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1724   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1725
1726   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1727   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1728   # but it's more convenient here to set LD_RUN_PATH since this
1729   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1730   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1731     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1732     export LD_RUN_PATH
1733   fi
1734
1735   if test "${opsys}" = "gnu-linux"; then
1736     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1737     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1738      [[XOpenDisplay ("foo");]])],
1739      [xgnu_linux_first_failure=no],
1740      [xgnu_linux_first_failure=yes])
1741     if test "${xgnu_linux_first_failure}" = "yes"; then
1742       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1743       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1744       OLD_CPPFLAGS="$CPPFLAGS"
1745       OLD_LIBS="$LIBS"
1746       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1747       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1748       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1749       LIBS="$LIBS -b i486-linuxaout"
1750       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1751        [[XOpenDisplay ("foo");]])],
1752        [xgnu_linux_second_failure=no],
1753        [xgnu_linux_second_failure=yes])
1754       if test "${xgnu_linux_second_failure}" = "yes"; then
1755         # If we get the same failure with -b, there is no use adding -b.
1756         # So take it out.  This plays safe.
1757         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1758         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1759         CPPFLAGS="$OLD_CPPFLAGS"
1760         LIBS="$OLD_LIBS"
1761         AC_MSG_RESULT(no)
1762       else
1763         AC_MSG_RESULT(yes)
1764       fi
1765     else
1766       AC_MSG_RESULT(no)
1767     fi
1768   fi
1769
1770   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1771   # header files included from there.
1772   AC_MSG_CHECKING(for Xkb)
1773   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1774 #include <X11/XKBlib.h>]],
1775         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1776         emacs_xkb=yes, emacs_xkb=no)
1777   AC_MSG_RESULT($emacs_xkb)
1778   if test $emacs_xkb = yes; then
1779     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1780   fi
1781
1782   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1783 XScreenNumberOfScreen)
1784 fi
1785
1786 if test "${window_system}" = "x11"; then
1787   AC_MSG_CHECKING(X11 version 6)
1788   AC_CACHE_VAL(emacs_cv_x11_version_6,
1789   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1790 [[#if XlibSpecificationRelease < 6
1791 fail;
1792 #endif
1793 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1794   if test $emacs_cv_x11_version_6 = yes; then
1795     AC_MSG_RESULT(6 or newer)
1796     AC_DEFINE(HAVE_X11R6, 1,
1797               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1798     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1799     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1800     ## XIM support.
1801     case "$opsys" in
1802       sol2-*) : ;;
1803       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1804            [Define if you have usable X11R6-style XIM support.])
1805          ;;
1806     esac
1807   else
1808     AC_MSG_RESULT(before 6)
1809   fi
1810 fi
1811
1812
1813 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1814 HAVE_RSVG=no
1815 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1816   if test "${with_rsvg}" != "no"; then
1817     RSVG_REQUIRED=2.11.0
1818     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1819
1820     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1821     AC_SUBST(RSVG_CFLAGS)
1822     AC_SUBST(RSVG_LIBS)
1823
1824     if test $HAVE_RSVG = yes; then
1825       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1826       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1827       LIBS="$RSVG_LIBS $LIBS"
1828     fi
1829   fi
1830 fi
1831
1832 HAVE_IMAGEMAGICK=no
1833 if test "${HAVE_X11}" = "yes"; then
1834   if test "${with_imagemagick}" != "no"; then
1835     ## 6.2.8 is the earliest version known to work, but earlier versions
1836     ## might work - let us know if you find one.
1837     ## 6.0.7 does not work.  See bug#7955.
1838     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1839     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1840     AC_SUBST(IMAGEMAGICK_CFLAGS)
1841     AC_SUBST(IMAGEMAGICK_LIBS)
1842
1843     if test $HAVE_IMAGEMAGICK = yes; then
1844       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1845       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1846       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1847       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
1848     fi
1849   fi
1850 fi
1851
1852
1853 HAVE_GTK=no
1854 GTK_OBJ=
1855 if test "${with_gtk3}" = "yes"; then
1856   GLIB_REQUIRED=2.28
1857   GTK_REQUIRED=3.0
1858   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1859
1860   dnl Checks for libraries.
1861   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1862   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1863      AC_MSG_ERROR($GTK_PKG_ERRORS)
1864   fi
1865   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1866   GTK_OBJ=emacsgtkfixed.o
1867 fi
1868
1869 if test "$pkg_check_gtk" != "yes"; then
1870   HAVE_GTK=no
1871 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1872   GLIB_REQUIRED=2.10
1873   GTK_REQUIRED=2.10
1874   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1875
1876   dnl Checks for libraries.
1877   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1878   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1879      AC_MSG_ERROR($GTK_PKG_ERRORS)
1880   fi
1881 fi
1882 fi
1883
1884 if test x"$pkg_check_gtk" = xyes; then
1885
1886   AC_SUBST(GTK_CFLAGS)
1887   AC_SUBST(GTK_LIBS)
1888   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1889   CFLAGS="$CFLAGS $GTK_CFLAGS"
1890   LIBS="$GTK_LIBS $LIBS"
1891   dnl Try to compile a simple GTK program.
1892   GTK_COMPILES=no
1893   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1894   if test "${GTK_COMPILES}" != "yes"; then
1895     if test "$USE_X_TOOLKIT" != "maybe"; then
1896       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1897     fi
1898   else
1899     HAVE_GTK=yes
1900     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1901     GTK_OBJ="gtkutil.o $GTK_OBJ"
1902     USE_X_TOOLKIT=none
1903     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1904       :
1905     else
1906       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1907        closing open displays.  This is no problem if you just use
1908        one display, but if you use more than one and close one of them
1909        Emacs may crash.]])
1910       sleep 3
1911     fi
1912   fi
1913
1914 fi
1915 AC_SUBST(GTK_OBJ)
1916
1917
1918 if test "${HAVE_GTK}" = "yes"; then
1919
1920   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1921   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1922   if test "$with_toolkit_scroll_bars" != no; then
1923     with_toolkit_scroll_bars=yes
1924   fi
1925
1926   dnl  Check if we have the old file selection dialog declared and
1927   dnl  in the link library.  In 2.x it may be in the library,
1928   dnl  but not declared if deprecated featured has been selected out.
1929   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1930   HAVE_GTK_FILE_SELECTION=no
1931   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1932                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1933 #include <gtk/gtk.h>])
1934   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1935     AC_CHECK_FUNCS(gtk_file_selection_new)
1936   fi
1937
1938
1939   dnl Check for functions introduced in 2.14 and later.
1940   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1941                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1942                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1943                  gtk_orientable_set_orientation \
1944                  gtk_window_set_has_resize_grip)
1945 fi
1946
1947 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1948 dnl other platforms.
1949 HAVE_DBUS=no
1950 DBUS_OBJ=
1951 if test "${with_dbus}" = "yes"; then
1952    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1953    if test "$HAVE_DBUS" = yes; then
1954      LIBS="$LIBS $DBUS_LIBS"
1955      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1956      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
1957      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
1958      dnl D-Bus 1.5.12.
1959      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
1960                     dbus_type_is_valid \
1961                     dbus_validate_bus_name \
1962                     dbus_validate_path \
1963                     dbus_validate_interface \
1964                     dbus_validate_member)
1965      DBUS_OBJ=dbusbind.o
1966    fi
1967 fi
1968 AC_SUBST(DBUS_OBJ)
1969
1970 dnl GSettings has been tested under GNU/Linux only.
1971 HAVE_GSETTINGS=no
1972 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
1973    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
1974    if test "$HAVE_GSETTINGS" = "yes"; then
1975       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
1976       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
1977       SETTINGS_LIBS="$GSETTINGS_LIBS"
1978    fi
1979 fi
1980
1981 dnl GConf has been tested under GNU/Linux only.
1982 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1983 HAVE_GCONF=no
1984 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1985    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1986    if test "$HAVE_GCONF" = yes; then
1987       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1988       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1989       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
1990       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
1991    fi
1992 fi
1993
1994 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
1995     SAVE_CFLAGS="$CFLAGS"
1996     SAVE_LIBS="$LIBS"
1997     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
1998     LIBS="$SETTINGS_LIBS $LIBS"
1999     AC_CHECK_FUNCS([g_type_init])
2000     CFLAGS="$SAVE_CFLAGS"
2001     LIBS="$SAVE_LIBS"
2002 fi
2003 AC_SUBST(SETTINGS_CFLAGS)
2004 AC_SUBST(SETTINGS_LIBS)
2005
2006
2007 dnl SELinux is available for GNU/Linux only.
2008 HAVE_LIBSELINUX=no
2009 LIBSELINUX_LIBS=
2010 if test "${with_selinux}" = "yes"; then
2011    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2012    if test "$HAVE_LIBSELINUX" = yes; then
2013       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2014       LIBSELINUX_LIBS=-lselinux
2015    fi
2016 fi
2017 AC_SUBST(LIBSELINUX_LIBS)
2018
2019 HAVE_GNUTLS=no
2020 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2021 if test "${with_gnutls}" = "yes" ; then
2022   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2023   if test "${HAVE_GNUTLS}" = "yes"; then
2024     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2025   fi
2026
2027   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2028   LIBS="$LIBGNUTLS_LIBS $LIBS"
2029   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2030
2031   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2032     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2033   fi
2034 fi
2035
2036 AC_SUBST(LIBGNUTLS_LIBS)
2037 AC_SUBST(LIBGNUTLS_CFLAGS)
2038
2039 dnl Do not put whitespace before the #include statements below.
2040 dnl Older compilers (eg sunos4 cc) choke on it.
2041 HAVE_XAW3D=no
2042 LUCID_LIBW=
2043 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2044   if test "$with_xaw3d" != no; then
2045     AC_MSG_CHECKING(for xaw3d)
2046     AC_CACHE_VAL(emacs_cv_xaw3d,
2047     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2048 #include <X11/Intrinsic.h>
2049 #include <X11/Xaw3d/Simple.h>]],
2050       [[]])],
2051       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2052                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2053       emacs_cv_xaw3d=no)])
2054   else
2055     emacs_cv_xaw3d=no
2056   fi
2057   if test $emacs_cv_xaw3d = yes; then
2058     AC_MSG_RESULT([yes; using Lucid toolkit])
2059     USE_X_TOOLKIT=LUCID
2060     HAVE_XAW3D=yes
2061     LUCID_LIBW=-lXaw3d
2062     AC_DEFINE(HAVE_XAW3D, 1,
2063               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2064   else
2065     AC_MSG_RESULT(no)
2066     AC_MSG_CHECKING(for libXaw)
2067     AC_CACHE_VAL(emacs_cv_xaw,
2068     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2069 #include <X11/Intrinsic.h>
2070 #include <X11/Xaw/Simple.h>]],
2071       [[]])],
2072       emacs_cv_xaw=yes,
2073       emacs_cv_xaw=no)])
2074     if test $emacs_cv_xaw = yes; then
2075       AC_MSG_RESULT([yes; using Lucid toolkit])
2076       USE_X_TOOLKIT=LUCID
2077       LUCID_LIBW=-lXaw
2078     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2079       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2080     else
2081       AC_MSG_ERROR([No X toolkit could be found.
2082 If you are sure you want Emacs compiled without an X toolkit, pass
2083   --with-x-toolkit=no
2084 to configure.  Otherwise, install the development libraries for the toolkit
2085 that you want to use (e.g. Gtk+) and re-run configure.])
2086     fi
2087   fi
2088 fi
2089
2090 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2091
2092 LIBXTR6=
2093 if test "${USE_X_TOOLKIT}" != "none"; then
2094   AC_MSG_CHECKING(X11 toolkit version)
2095   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2096   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2097 [[#if XtSpecificationRelease < 6
2098 fail;
2099 #endif
2100 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2101   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2102   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2103     AC_MSG_RESULT(6 or newer)
2104     AC_DEFINE(HAVE_X11XTR6, 1,
2105               [Define to 1 if you have the X11R6 or newer version of Xt.])
2106     LIBXTR6="-lSM -lICE"
2107     case "$opsys" in
2108       ## Use libw.a along with X11R6 Xt.
2109       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2110     esac
2111   else
2112     AC_MSG_RESULT(before 6)
2113   fi
2114
2115 dnl If using toolkit, check whether libXmu.a exists.
2116 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2117   OLDLIBS="$LIBS"
2118   if test x$HAVE_X11XTR6 = xyes; then
2119     LIBS="-lXt -lSM -lICE $LIBS"
2120   else
2121     LIBS="-lXt $LIBS"
2122   fi
2123   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2124   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2125   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2126 fi
2127 AC_SUBST(LIBXTR6)
2128
2129 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2130 dnl Why not just test for libxmu in the normal way?
2131 LIBXMU=-lXmu
2132 case $opsys in
2133   ## These systems don't supply Xmu.
2134   hpux* | aix4-2 )
2135     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2136     ;;
2137 esac
2138 AC_SUBST(LIBXMU)
2139
2140 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2141 if test "${HAVE_X11}" = "yes"; then
2142   if test "${USE_X_TOOLKIT}" != "none"; then
2143     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2144   fi
2145 fi
2146
2147 LIBXP=
2148 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2149   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2150   if test -d /usr/include/openmotif; then
2151     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2152     emacs_cv_openmotif=yes
2153     case "$canonical" in
2154       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2155       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2156       ;;
2157       *)
2158       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2159     esac
2160   else
2161     emacs_cv_openmotif=no
2162   fi
2163   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2164   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2165     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2166 int x = 5;
2167 #else
2168 Motif version prior to 2.1.
2169 #endif]])],
2170     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2171   if test $emacs_cv_motif_version_2_1 = yes; then
2172     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2173     if test x$emacs_cv_openmotif = xyes; then
2174       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2175     fi
2176   else
2177     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2178     # We put this in CFLAGS temporarily to precede other -I options
2179     # that might be in CFLAGS temporarily.
2180     # We put this in CPPFLAGS where it precedes the other -I options.
2181     OLD_CPPFLAGS=$CPPFLAGS
2182     OLD_CFLAGS=$CFLAGS
2183     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2184     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2185     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2186       [[int x = 5;]])],
2187       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2188     if test $emacs_cv_lesstif = yes; then
2189       # Make sure this -I option remains in CPPFLAGS after it is set
2190       # back to REAL_CPPFLAGS.
2191       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2192       # have those other -I options anyway.  Ultimately, having this
2193       # directory ultimately in CPPFLAGS will be enough.
2194       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2195       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2196     else
2197       CFLAGS=$OLD_CFLAGS
2198       CPPFLAGS=$OLD_CPPFLAGS
2199     fi
2200   fi
2201   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2202     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2203 fi
2204
2205 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2206 dnl using Motif or Xaw3d is available, and unless
2207 dnl --with-toolkit-scroll-bars=no was specified.
2208
2209 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2210             [Define to 1 if we should use toolkit scroll bars.])dnl
2211 USE_TOOLKIT_SCROLL_BARS=no
2212 if test "${with_toolkit_scroll_bars}" != "no"; then
2213   if test "${USE_X_TOOLKIT}" != "none"; then
2214     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2215       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2216       HAVE_XAW3D=no
2217       USE_TOOLKIT_SCROLL_BARS=yes
2218     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2219       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2220       USE_TOOLKIT_SCROLL_BARS=yes
2221     fi
2222   elif test "${HAVE_GTK}" = "yes"; then
2223     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2224     USE_TOOLKIT_SCROLL_BARS=yes
2225   elif test "${HAVE_NS}" = "yes"; then
2226     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2227     USE_TOOLKIT_SCROLL_BARS=yes
2228   fi
2229 fi
2230
2231 dnl See if XIM is available.
2232 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2233           #include <X11/Xlib.h>
2234           #include <X11/Xresource.h>]],
2235          [[XIMProc  callback;]])],
2236          [HAVE_XIM=yes
2237          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2238          HAVE_XIM=no)
2239
2240 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2241
2242 if test "${with_xim}" != "no"; then
2243   AC_DEFINE(USE_XIM, 1,
2244             [Define to 1 if we should use XIM, if it is available.])
2245 fi
2246
2247
2248 if test "${HAVE_XIM}" != "no"; then
2249   late_CFLAGS=$CFLAGS
2250   if test "$GCC" = yes; then
2251     CFLAGS="$CFLAGS --pedantic-errors"
2252   fi
2253   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2254 #include <X11/Xlib.h>
2255 #include <X11/Xresource.h>]],
2256 [[Display *display;
2257 XrmDatabase db;
2258 char *res_name;
2259 char *res_class;
2260 XIMProc  callback;
2261 XPointer *client_data;
2262 #ifndef __GNUC__
2263 /* If we're not using GCC, it's probably not XFree86, and this is
2264    probably right, but we can't use something like --pedantic-errors.  */
2265 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2266                                            char*, XIMProc, XPointer*);
2267 #endif
2268 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2269    client_data);]])],
2270     [emacs_cv_arg6_star=yes])
2271   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2272          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2273 either XPointer or XPointer*.])dnl
2274   if test "$emacs_cv_arg6_star" = yes; then
2275     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2276   else
2277     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2278   fi
2279   CFLAGS=$late_CFLAGS
2280 fi
2281
2282 ### Start of font-backend (under any platform) section.
2283 # (nothing here yet -- this is a placeholder)
2284 ### End of font-backend (under any platform) section.
2285
2286 ### Start of font-backend (under X11) section.
2287 if test "${HAVE_X11}" = "yes"; then
2288    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2289
2290    ## Use -lXft if available, unless `--with-xft=no'.
2291    HAVE_XFT=maybe
2292     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2293       with_xft="no";
2294     fi
2295     if test "x${with_xft}" != "xno"; then
2296
2297       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2298       ## Because xftfont.c uses XRenderQueryExtension, we also
2299       ## need to link to -lXrender.
2300       HAVE_XRENDER=no
2301       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2302       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2303         OLD_CPPFLAGS="$CPPFLAGS"
2304         OLD_CFLAGS="$CFLAGS"
2305         OLD_LIBS="$LIBS"
2306         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2307         CFLAGS="$CFLAGS $XFT_CFLAGS"
2308         XFT_LIBS="-lXrender $XFT_LIBS"
2309         LIBS="$XFT_LIBS $LIBS"
2310         AC_CHECK_HEADER(X11/Xft/Xft.h,
2311           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2312
2313         if test "${HAVE_XFT}" = "yes"; then
2314           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2315             AC_SUBST(XFT_LIBS)
2316           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2317         else
2318           CPPFLAGS="$OLD_CPPFLAGS"
2319           CFLAGS="$OLD_CFLAGS"
2320           LIBS="$OLD_LIBS"
2321         fi                        # "${HAVE_XFT}" = "yes"
2322       fi                          # "$HAVE_XFT" != no
2323     fi                            # "x${with_xft}" != "xno"
2324
2325     ## We used to allow building with FreeType and without Xft.
2326     ## However, the ftx font backend driver is not in good shape.
2327     if test "$HAVE_XFT" != "yes"; then
2328        dnl For the "Does Emacs use" message at the end.
2329        HAVE_XFT=no
2330        HAVE_FREETYPE=no
2331     else
2332        dnl Strict linkers fail with
2333        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2334        dnl if -lfreetype is not specified.
2335        dnl The following is needed to set FREETYPE_LIBS.
2336        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2337                          HAVE_FREETYPE=no)
2338
2339        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2340     fi
2341
2342     HAVE_LIBOTF=no
2343     if test "${HAVE_FREETYPE}" = "yes"; then
2344       AC_DEFINE(HAVE_FREETYPE, 1,
2345                 [Define to 1 if using the freetype and fontconfig libraries.])
2346       if test "${with_libotf}" != "no"; then
2347         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2348                           HAVE_LIBOTF=no)
2349         if test "$HAVE_LIBOTF" = "yes"; then
2350           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2351           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2352                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2353                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2354           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2355             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2356                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2357           fi
2358         fi
2359       fi
2360     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2361     dnl Does the new font backend require it, or can it work without it?
2362     fi
2363
2364     HAVE_M17N_FLT=no
2365     if test "${HAVE_LIBOTF}" = yes; then
2366       if test "${with_m17n_flt}" != "no"; then
2367         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2368         if test "$HAVE_M17N_FLT" = "yes"; then
2369           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2370         fi
2371       fi
2372     fi
2373 else
2374     HAVE_XFT=no
2375     HAVE_FREETYPE=no
2376     HAVE_LIBOTF=no
2377     HAVE_M17N_FLT=no
2378 fi
2379
2380 ### End of font-backend (under X11) section.
2381
2382 AC_SUBST(FREETYPE_CFLAGS)
2383 AC_SUBST(FREETYPE_LIBS)
2384 AC_SUBST(FONTCONFIG_CFLAGS)
2385 AC_SUBST(FONTCONFIG_LIBS)
2386 AC_SUBST(LIBOTF_CFLAGS)
2387 AC_SUBST(LIBOTF_LIBS)
2388 AC_SUBST(M17N_FLT_CFLAGS)
2389 AC_SUBST(M17N_FLT_LIBS)
2390
2391 ### Use -lXpm if available, unless `--with-xpm=no'.
2392 HAVE_XPM=no
2393 LIBXPM=
2394 if test "${HAVE_X11}" = "yes"; then
2395   if test "${with_xpm}" != "no"; then
2396     AC_CHECK_HEADER(X11/xpm.h,
2397       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2398     if test "${HAVE_XPM}" = "yes"; then
2399       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2400       AC_EGREP_CPP(no_return_alloc_pixels,
2401       [#include "X11/xpm.h"
2402 #ifndef XpmReturnAllocPixels
2403 no_return_alloc_pixels
2404 #endif
2405       ], HAVE_XPM=no, HAVE_XPM=yes)
2406
2407       if test "${HAVE_XPM}" = "yes"; then
2408         AC_MSG_RESULT(yes)
2409       else
2410         AC_MSG_RESULT(no)
2411       fi
2412     fi
2413   fi
2414
2415   if test "${HAVE_XPM}" = "yes"; then
2416     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2417     LIBXPM=-lXpm
2418   fi
2419 fi
2420 AC_SUBST(LIBXPM)
2421
2422 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2423 HAVE_JPEG=no
2424 LIBJPEG=
2425 if test "${HAVE_X11}" = "yes"; then
2426   if test "${with_jpeg}" != "no"; then
2427     dnl Checking for jpeglib.h can lose because of a redefinition of
2428     dnl  HAVE_STDLIB_H.
2429     AC_CHECK_HEADER(jerror.h,
2430       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2431   fi
2432
2433   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2434   if test "${HAVE_JPEG}" = "yes"; then
2435     AC_DEFINE(HAVE_JPEG)
2436     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2437         [#include <jpeglib.h>
2438          version=JPEG_LIB_VERSION
2439 ],
2440         [AC_DEFINE(HAVE_JPEG)],
2441         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2442         HAVE_JPEG=no])
2443   fi
2444   if test "${HAVE_JPEG}" = "yes"; then
2445     LIBJPEG=-ljpeg
2446   fi
2447 fi
2448 AC_SUBST(LIBJPEG)
2449
2450 ### Use -lpng if available, unless `--with-png=no'.
2451 HAVE_PNG=no
2452 LIBPNG=
2453 if test "${HAVE_X11}" = "yes"; then
2454   if test "${with_png}" != "no"; then
2455     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2456     # in /usr/include/libpng.
2457     AC_CHECK_HEADERS(png.h libpng/png.h, break)
2458     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2459       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2460     fi
2461   fi
2462
2463   if test "${HAVE_PNG}" = "yes"; then
2464     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2465     LIBPNG="-lpng -lz -lm"
2466
2467     AC_CHECK_DECL(png_longjmp,
2468       [],
2469       [AC_DEFINE(PNG_DEPSTRUCT, [],
2470          [Define to empty to suppress deprecation warnings when building
2471           with --enable-gcc-warnings and with libpng versions before 1.5,
2472           which lack png_longjmp.])],
2473       [[#ifdef HAVE_LIBPNG_PNG_H
2474         # include <libpng/png.h>
2475         #else
2476         # include <png.h>
2477         #endif
2478       ]])
2479   fi
2480 fi
2481 AC_SUBST(LIBPNG)
2482
2483 ### Use -ltiff if available, unless `--with-tiff=no'.
2484 HAVE_TIFF=no
2485 LIBTIFF=
2486 if test "${HAVE_X11}" = "yes"; then
2487   if test "${with_tiff}" != "no"; then
2488     AC_CHECK_HEADER(tiffio.h,
2489       [tifflibs="-lz -lm"
2490       # At least one tiff package requires the jpeg library.
2491       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2492       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2493   fi
2494
2495   if test "${HAVE_TIFF}" = "yes"; then
2496     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2497     dnl FIXME -lz -lm, as per libpng?
2498     LIBTIFF=-ltiff
2499   fi
2500 fi
2501 AC_SUBST(LIBTIFF)
2502
2503 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2504 HAVE_GIF=no
2505 LIBGIF=
2506 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2507   AC_CHECK_HEADER(gif_lib.h,
2508 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2509 # Earlier versions can crash Emacs.
2510     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2511
2512   if test "$HAVE_GIF" = yes; then
2513     LIBGIF=-lgif
2514   elif test "$HAVE_GIF" = maybe; then
2515 # If gif_lib.h but no libgif, try libungif.
2516     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2517     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2518   fi
2519
2520   if test "${HAVE_GIF}" = "yes"; then
2521     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2522   fi
2523 fi
2524 AC_SUBST(LIBGIF)
2525
2526 dnl Check for required libraries.
2527 if test "${HAVE_X11}" = "yes"; then
2528   MISSING=""
2529   WITH_NO=""
2530   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2531     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2532   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2533     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2534   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2535     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2536   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2537     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2538   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2539     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2540
2541   if test "X${MISSING}" != X; then
2542     AC_MSG_ERROR([The following required libraries were not found:
2543     $MISSING
2544 Maybe some development libraries/packages are missing?
2545 If you don't want to link with them give
2546     $WITH_NO
2547 as options to configure])
2548   fi
2549 fi
2550
2551 ### Use -lgpm if available, unless `--with-gpm=no'.
2552 HAVE_GPM=no
2553 LIBGPM=
2554 if test "${with_gpm}" != "no"; then
2555   AC_CHECK_HEADER(gpm.h,
2556     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2557
2558   if test "${HAVE_GPM}" = "yes"; then
2559     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2560     LIBGPM=-lgpm
2561   fi
2562 fi
2563 AC_SUBST(LIBGPM)
2564
2565 dnl Check for malloc/malloc.h on darwin
2566 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2567
2568 GNUSTEP_CFLAGS=
2569 ### Use NeXTstep API to implement GUI.
2570 if test "${HAVE_NS}" = "yes"; then
2571   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2572   if test "${NS_IMPL_COCOA}" = "yes"; then
2573     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2574   fi
2575   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2576     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2577     # See also .m.o rule in Makefile.in */
2578     # FIXME: are all these flags really needed?  Document here why.  */
2579     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2580     ## Extra CFLAGS applied to src/*.m files.
2581     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2582   fi
2583   # We also have mouse menus.
2584   HAVE_MENUS=yes
2585   OTHER_FILES=ns-app
2586 fi
2587
2588
2589 ### Use session management (-lSM -lICE) if available
2590 HAVE_X_SM=no
2591 LIBXSM=
2592 if test "${HAVE_X11}" = "yes"; then
2593   AC_CHECK_HEADER(X11/SM/SMlib.h,
2594     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2595
2596   if test "${HAVE_X_SM}" = "yes"; then
2597     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2598     LIBXSM="-lSM -lICE"
2599     case "$LIBS" in
2600       *-lSM*) ;;
2601       *)      LIBS="$LIBXSM $LIBS" ;;
2602     esac
2603   fi
2604 fi
2605 AC_SUBST(LIBXSM)
2606
2607 ### Use libxml (-lxml2) if available
2608 HAVE_LIBXML2=no
2609 if test "${with_xml2}" != "no"; then
2610   ### I'm not sure what the version number should be, so I just guessed.
2611   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2612   if test "${HAVE_LIBXML2}" = "yes"; then
2613     LIBS="$LIBXML2_LIBS $LIBS"
2614     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2615     if test "${HAVE_LIBXML2}" = "yes"; then
2616       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2617     else
2618       LIBXML2_LIBS=""
2619       LIBXML2_CFLAGS=""
2620     fi
2621   fi
2622 fi
2623 AC_SUBST(LIBXML2_LIBS)
2624 AC_SUBST(LIBXML2_CFLAGS)
2625
2626 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2627 AC_CACHE_CHECK(whether netdb declares h_errno,
2628                emacs_cv_netdb_declares_h_errno,
2629 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2630   [[return h_errno;]])],
2631   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2632 if test $emacs_cv_netdb_declares_h_errno = yes; then
2633   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2634 fi
2635
2636 # fmod, logb, and frexp are found in -lm on most systems.
2637 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2638 AC_CHECK_LIB(m, sqrt)
2639
2640 # Check for mail-locking functions in a "mail" library.  Probably this should
2641 # have the same check as for liblockfile below.
2642 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2643 if test $have_mail = yes; then
2644   LIBS_MAIL=-lmail
2645   LIBS="$LIBS_MAIL $LIBS"
2646   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2647 else
2648   LIBS_MAIL=
2649 fi
2650 dnl Debian, at least:
2651 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2652 if test $have_lockfile = yes; then
2653    LIBS_MAIL=-llockfile
2654    LIBS="$LIBS_MAIL $LIBS"
2655    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2656 else
2657 # If we have the shared liblockfile, assume we must use it for mail
2658 # locking (e.g. Debian).  If we couldn't link against liblockfile
2659 # (no liblockfile.a installed), ensure that we don't need to.
2660   dnl This works for files generally, not just executables.
2661   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2662   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2663                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2664   if test $ac_cv_prog_liblockfile = yes; then
2665     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2666 This probably means that movemail could lose mail.
2667 There may be a `development' package to install containing liblockfile.])
2668   fi
2669 fi
2670 AC_CHECK_HEADERS_ONCE(maillock.h)
2671 AC_SUBST(LIBS_MAIL)
2672
2673 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2674 ## interlock access to the mail spool.  The alternative is a lock file named
2675 ## /usr/spool/mail/$USER.lock.
2676 mail_lock=no
2677 case "$opsys" in
2678   aix4-2) mail_lock="lockf" ;;
2679
2680   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2681
2682   ## On GNU/Linux systems, both methods are used by various mail programs.
2683   ## I assume most people are using newer mailers that have heard of flock.
2684   ## Change this if you need to.
2685   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2686   ## configure gets the right answers, and that means *NOT* using flock.
2687   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2688   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2689   ## Debian maintainer hasn't provided a clean fix for Emacs.
2690   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2691   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2692   ## correct logic.  -- fx
2693   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2694   ## liblockfile is a Free Software replacement for libmail, used on
2695   ## Debian systems and elsewhere. -rfr.
2696   gnu-*)
2697     mail_lock="flock"
2698     if test $have_mail = yes || test $have_lockfile = yes; then
2699       test $ac_cv_header_maillock_h = yes && mail_lock=no
2700     fi
2701     ;;
2702 esac
2703
2704 BLESSMAIL_TARGET=
2705 case "$mail_lock" in
2706   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2707
2708   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2709
2710   *) BLESSMAIL_TARGET="need-blessmail" ;;
2711 esac
2712 AC_SUBST(BLESSMAIL_TARGET)
2713
2714
2715 AC_CHECK_FUNCS(gethostname \
2716 closedir getrusage get_current_dir_name \
2717 lrand48 logb frexp fmod cbrt setsid \
2718 fpathconf select euidaccess getpagesize setlocale \
2719 utimes getrlimit setrlimit setpgid getcwd shutdown getaddrinfo \
2720 __fpending strsignal setitimer \
2721 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
2722 gai_strerror mkstemp getline getdelim fsync sync \
2723 difftime posix_memalign \
2724 getpwent endpwent getgrent endgrent \
2725 touchlock \
2726 cfmakeraw cfsetspeed copysign __executable_start)
2727
2728 dnl getwd appears to be buggy on SVR4.2, so we don't use it.
2729 if test $opsys = unixware; then
2730   dnl In case some other test ends up checking for getwd.
2731   AC_DEFINE(BROKEN_GETWD, 1, [Define if getwd should not be used.])
2732 else
2733   AC_CHECK_FUNCS(getwd)
2734 fi
2735
2736 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
2737 ## has a broken `rint' in some library versions including math library
2738 ## version number A.09.05.
2739 ## You can fix the math library by installing patch number PHSS_4630.
2740 ## But we can fix it more reliably for Emacs by just not using rint.
2741 ## We also skip HAVE_RANDOM - see comments in src/conf_post.h.
2742 case $opsys in
2743    hpux*) : ;;
2744    *) AC_CHECK_FUNCS(random rint) ;;
2745 esac
2746
2747 dnl Cannot use AC_CHECK_FUNCS
2748 AC_CACHE_CHECK([for __builtin_unwind_init],
2749                emacs_cv_func___builtin_unwind_init,
2750 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2751                 emacs_cv_func___builtin_unwind_init=yes,
2752                 emacs_cv_func___builtin_unwind_init=no)])
2753 if test $emacs_cv_func___builtin_unwind_init = yes; then
2754   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2755             [Define to 1 if you have the `__builtin_unwind_init' function.])
2756 fi
2757
2758 AC_CHECK_HEADERS_ONCE(sys/un.h)
2759
2760 AC_FUNC_FSEEKO
2761
2762 AC_FUNC_GETPGRP
2763
2764 # UNIX98 PTYs.
2765 AC_CHECK_FUNCS(grantpt)
2766
2767 # PTY-related GNU extensions.
2768 AC_CHECK_FUNCS(getpt)
2769
2770 # Check this now, so that we will NOT find the above functions in ncurses.
2771 # That is because we have not set up to link ncurses in lib-src.
2772 # It's better to believe a function is not available
2773 # than to expect to find it in ncurses.
2774 # Also we need tputs and friends to be able to build at all.
2775 AC_MSG_CHECKING([for library containing tputs])
2776 # Run a test program that contains a call to tputs, a call that is
2777 # never executed.  This tests whether a pre-'main' dynamic linker
2778 # works with the library.  It's too much trouble to actually call
2779 # tputs in the test program, due to portability hassles.  When
2780 # cross-compiling, assume the test program will run if it links.
2781 AC_DEFUN([tputs_link_source], [
2782   AC_LANG_SOURCE(
2783      [[extern void tputs (const char *, int, int (*)(int));
2784        int main (int argc, char **argv)
2785        {
2786           if (argc == 10000)
2787             tputs (argv[0], 0, 0);
2788           return 0;
2789        }]])
2790 ])
2791 # Maybe curses should be tried earlier?
2792 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2793 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2794   OLIBS=$LIBS
2795   if test -z "$tputs_library"; then
2796     LIBS_TERMCAP=
2797     msg='none required'
2798   else
2799     LIBS_TERMCAP=-l$tputs_library
2800     msg=$LIBS_TERMCAP
2801     LIBS="$LIBS_TERMCAP $LIBS"
2802   fi
2803   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2804     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2805   LIBS=$OLIBS
2806   if test "X$msg" != Xno; then
2807     break
2808   fi
2809 done
2810 AC_MSG_RESULT([$msg])
2811 if test "X$msg" = Xno; then
2812   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2813 The following libraries were tried (in order):
2814   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2815 Please try installing whichever of these libraries is most appropriate
2816 for your system, together with its header files.
2817 For example, a libncurses-dev(el) or similar package.])
2818 fi
2819
2820 ## Use termcap instead of terminfo?
2821 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2822 TERMINFO=yes
2823 ## FIXME?  In the cases below where we unconditionally set
2824 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2825 ## if that was found above to have tputs.
2826 ## Should we use the gnu* logic everywhere?
2827 case "$opsys" in
2828   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2829   ##  The ncurses library has been moved out of the System framework in
2830   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2831   ##  option to use it.
2832   darwin) LIBS_TERMCAP="-lncurses" ;;
2833
2834   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2835
2836   freebsd)
2837     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2838     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2839     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2840 [[#if __FreeBSD_version < 400000
2841 fail;
2842 #endif
2843 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2844
2845     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2846
2847     if test $emacs_cv_freebsd_terminfo = yes; then
2848       LIBS_TERMCAP="-lncurses"
2849     else
2850       TERMINFO=no
2851       LIBS_TERMCAP="-ltermcap"
2852     fi
2853     ;;
2854
2855   netbsd)
2856     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2857       TERMINFO=no
2858       LIBS_TERMCAP="-ltermcap"
2859     fi
2860     ;;
2861
2862   openbsd) LIBS_TERMCAP="-lncurses" ;;
2863
2864   ## hpux: Make sure we get select from libc rather than from libcurses
2865   ##  because libcurses on HPUX 10.10 has a broken version of select.
2866   ##  We used to use -lc -lcurses, but this may be cleaner.
2867   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2868   # set that way, now it uses the default).  Isn't this a contradiction?
2869   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2870
2871 esac
2872
2873 TERMCAP_OBJ=tparam.o
2874 if test $TERMINFO = yes; then
2875   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2876   TERMCAP_OBJ=terminfo.o
2877 fi
2878 AC_SUBST(LIBS_TERMCAP)
2879 AC_SUBST(TERMCAP_OBJ)
2880
2881
2882 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2883 # On Darwin, res_init appears not to be useful: see bug#562 and
2884 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
2885 resolv=no
2886
2887 if test $opsys != darwin; then
2888
2889   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2890 #include <arpa/nameser.h>
2891 #include <resolv.h>]],
2892     [[return res_init();]])],
2893     have_res_init=yes, have_res_init=no)
2894   if test "$have_res_init" = no; then
2895     OLIBS="$LIBS"
2896     LIBS="$LIBS -lresolv"
2897     AC_MSG_CHECKING(for res_init with -lresolv)
2898     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2899 #include <arpa/nameser.h>
2900 #include <resolv.h>]],
2901       [[return res_init();]])],
2902       have_res_init=yes, have_res_init=no)
2903     AC_MSG_RESULT($have_res_init)
2904     if test "$have_res_init" = yes ; then
2905       resolv=yes
2906     fi
2907     LIBS="$OLIBS"
2908   fi
2909
2910   if test "$have_res_init" = yes; then
2911     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2912   fi
2913 fi                              dnl !darwin
2914
2915 # Do we need the Hesiod library to provide the support routines?
2916 dnl FIXME?  Should we be skipping this on Darwin too?
2917 LIBHESIOD=
2918 if test "$with_hesiod" != no ; then
2919   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2920   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2921      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2922                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2923   if test "$resolv" = yes ; then
2924     RESOLVLIB=-lresolv
2925   else
2926     RESOLVLIB=
2927   fi
2928   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2929         hesiod=yes, :, $RESOLVLIB)])
2930
2931   if test x"$hesiod" = xyes; then
2932     AC_DEFINE(HAVE_LIBHESIOD, 1,
2933               [Define to 1 if you have the hesiod library (-lhesiod).])
2934     LIBHESIOD=-lhesiod
2935   fi
2936 fi
2937 AC_SUBST(LIBHESIOD)
2938
2939 # Do we need libresolv (due to res_init or Hesiod)?
2940 if test "$resolv" = yes && test $opsys != darwin; then
2941   AC_DEFINE(HAVE_LIBRESOLV, 1,
2942             [Define to 1 if you have the resolv library (-lresolv).])
2943   LIBRESOLV=-lresolv
2944 else
2945   LIBRESOLV=
2946 fi
2947 AC_SUBST(LIBRESOLV)
2948
2949 # These tell us which Kerberos-related libraries to use.
2950 COM_ERRLIB=
2951 CRYPTOLIB=
2952 KRB5LIB=
2953 DESLIB=
2954 KRB4LIB=
2955
2956 if test "${with_kerberos}" != no; then
2957   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2958   if test $have_com_err = yes; then
2959     COM_ERRLIB=-lcom_err
2960     LIBS="$COM_ERRLIB $LIBS"
2961     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2962   fi
2963   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2964   if test $have_crypto = yes; then
2965     CRYPTOLIB=-lcrypto
2966     LIBS="$CRYPTOLIB $LIBS"
2967     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2968   fi
2969   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2970   if test $have_k5crypto = yes; then
2971     CRYPTOLIB=-lk5crypto
2972     LIBS="$CRYPTOLIB $LIBS"
2973     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2974   fi
2975   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2976   if test $have_krb5=yes; then
2977     KRB5LIB=-lkrb5
2978     LIBS="$KRB5LIB $LIBS"
2979     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2980   fi
2981   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2982   if test "${with_kerberos5}" = no; then
2983     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2984     if test $have_des425 = yes; then
2985       DESLIB=-ldes425
2986       LIBS="$DESLIB $LIBS"
2987       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2988     else
2989       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2990       if test $have_des = yes; then
2991         DESLIB=-ldes
2992         LIBS="$DESLIB $LIBS"
2993         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2994       fi
2995     fi
2996     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2997     if test $have_krb4 = yes; then
2998       KRB4LIB=-lkrb4
2999       LIBS="$KRB4LIB $LIBS"
3000       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
3001     else
3002       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3003       if test $have_krb = yes; then
3004         KRB4LIB=-lkrb
3005         LIBS="$KRB4LIB $LIBS"
3006         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
3007       fi
3008     fi
3009   fi
3010
3011   if test "${with_kerberos5}" != no; then
3012     AC_CHECK_HEADERS(krb5.h,
3013       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3014                         [#include <krb5.h>])])
3015   else
3016     AC_CHECK_HEADERS(des.h,,
3017                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3018                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3019     AC_CHECK_HEADERS(krb.h,,
3020                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3021                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3022   fi
3023   AC_CHECK_HEADERS(com_err.h)
3024 fi
3025
3026 AC_SUBST(COM_ERRLIB)
3027 AC_SUBST(CRYPTOLIB)
3028 AC_SUBST(KRB5LIB)
3029 AC_SUBST(DESLIB)
3030 AC_SUBST(KRB4LIB)
3031
3032 AC_CHECK_FUNCS_ONCE(tzset)
3033 AC_MSG_CHECKING(whether localtime caches TZ)
3034 AC_CACHE_VAL(emacs_cv_localtime_cache,
3035 [if test x$ac_cv_func_tzset = xyes; then
3036 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3037 char TZ_GMT0[] = "TZ=GMT0";
3038 char TZ_PST8[] = "TZ=PST8";
3039 main()
3040 {
3041   time_t now = time ((time_t *) 0);
3042   int hour_GMT0, hour_unset;
3043   if (putenv (TZ_GMT0) != 0)
3044     exit (1);
3045   hour_GMT0 = localtime (&now)->tm_hour;
3046   unsetenv("TZ");
3047   hour_unset = localtime (&now)->tm_hour;
3048   if (putenv (TZ_PST8) != 0)
3049     exit (1);
3050   if (localtime (&now)->tm_hour == hour_GMT0)
3051     exit (1);
3052   unsetenv("TZ");
3053   if (localtime (&now)->tm_hour != hour_unset)
3054     exit (1);
3055   exit (0);
3056 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3057 [# If we have tzset, assume the worst when cross-compiling.
3058 emacs_cv_localtime_cache=yes])
3059 else
3060         # If we lack tzset, report that localtime does not cache TZ,
3061         # since we can't invalidate the cache if we don't have tzset.
3062         emacs_cv_localtime_cache=no
3063 fi])dnl
3064 AC_MSG_RESULT($emacs_cv_localtime_cache)
3065 if test $emacs_cv_localtime_cache = yes; then
3066   AC_DEFINE(LOCALTIME_CACHE, 1,
3067             [Define to 1 if localtime caches TZ.])
3068 fi
3069
3070 ok_so_far=yes
3071 AC_CHECK_FUNC(socket, , ok_so_far=no)
3072 if test $ok_so_far = yes; then
3073   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3074 fi
3075 if test $ok_so_far = yes; then
3076   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3077 fi
3078 if test $ok_so_far = yes; then
3079 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3080   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3081             [Define to 1 if you have inet sockets.])
3082 fi
3083
3084 if test -f /usr/lpp/X11/bin/smt.exp; then
3085   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3086             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3087 fi
3088
3089 AC_MSG_CHECKING(whether system supports dynamic ptys)
3090 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3091   AC_MSG_RESULT(yes)
3092   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3093 else
3094   AC_MSG_RESULT(no)
3095 fi
3096
3097 AC_FUNC_FORK
3098
3099 AC_CHECK_FUNCS(snprintf)
3100
3101 dnl Adapted from Haible's version.
3102 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3103   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3104     [[char* cs = nl_langinfo(CODESET);]])],
3105     emacs_cv_langinfo_codeset=yes,
3106     emacs_cv_langinfo_codeset=no)
3107   ])
3108 if test $emacs_cv_langinfo_codeset = yes; then
3109   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3110     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3111 fi
3112
3113 AC_TYPE_MBSTATE_T
3114
3115 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3116   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3117                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3118 if test "$emacs_cv_c_restrict_arr" = yes; then
3119   AC_DEFINE(__restrict_arr, __restrict,
3120     [Define to compiler's equivalent of C99 restrict keyword in array
3121      declarations.  Define as empty for no equivalent.])
3122 fi
3123
3124 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3125 dnl how the tty code is related to POSIX and/or other versions of termios.
3126 dnl The following looks like a useful start.
3127 dnl
3128 dnl AC_SYS_POSIX_TERMIOS
3129 dnl if test $ac_cv_sys_posix_termios = yes; then
3130 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3131 dnl                                and macros for terminal control.])
3132 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3133 dnl fi
3134
3135 dnl Turned on June 1996 supposing nobody will mind it.
3136 AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3137   in the full name stands for the login id.])
3138
3139 dnl Every platform that uses configure (ie every non-MS platform)
3140 dnl supports this.  There is a create-lockfiles option you can
3141 dnl customize if you do not want the lock files to be written.
3142 dnl So it is not clear that this #define still needs to exist.
3143 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3144   so that Emacs can tell instantly when you try to modify a file that
3145   someone else has modified in his/her Emacs.])
3146
3147 AH_TEMPLATE(FLOAT_CHECK_DOMAIN, [Define if the float library doesn't
3148   handle errors by either setting errno, or signaling SIGFPE/SIGILL.])
3149
3150 AH_TEMPLATE(HAVE_INVERSE_HYPERBOLIC, [Define if you have the functions
3151   acosh, asinh, and atanh.])
3152
3153 dnl Everybody supports this, except MS.
3154 dnl Seems like the kind of thing we should be testing for, though.
3155 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3156 AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3157
3158 dnl Everybody supports this, except MS-DOS.
3159 dnl Seems like the kind of thing we should be testing for, though.
3160 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3161 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3162   4.2-compatible sockets.])
3163
3164 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3165
3166 AC_DEFINE(NULL_DEVICE, ["/dev/null"], [Name of the file to open to get
3167   a null file, or a data sink.])
3168
3169 AC_DEFINE(SEPCHAR, [':'], [Character that separates PATH elements.])
3170
3171 dnl Everybody supports this, except MS-DOS.
3172 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
3173
3174 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
3175
3176
3177 dnl Only used on MS platforms.
3178 AH_TEMPLATE(DEVICE_SEP, [Character that separates a device in a file name.])
3179
3180 AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
3181   [Returns true if character is a device separator.])
3182
3183 AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
3184   [Returns true if character is a directory separator.])
3185
3186 dnl On MS, this also accepts IS_DEVICE_SEP.
3187 AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
3188   [Returns true if character is any form of separator.])
3189
3190
3191 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3192
3193 case $opsys in
3194   aix4-2)
3195     dnl Unfortunately without libXmu we cannot support EditRes.
3196     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
3197       AC_DEFINE(NO_EDITRES, 1)
3198     fi
3199     ;;
3200
3201   hpux*)
3202     dnl Assar Westerlund <assar@sics.se> says this is necessary for
3203     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
3204     AC_DEFINE(NO_EDITRES, 1)
3205     ;;
3206 esac
3207
3208
3209 case $opsys in
3210   darwin | gnu | hpux* | *bsd )
3211     AC_DEFINE(NO_TERMIO, 1, [Define if termio.h should not be included.])
3212     ;;
3213
3214   irix6-5 | sol2* | unixware )
3215     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
3216     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
3217     dnl need the constant to dimension an array.  So wire in the appropriate
3218     dnl value here.
3219     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
3220     ;;
3221 esac
3222
3223
3224 case $opsys in
3225   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3226   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3227   hpux* | irix6-5 | openbsd | sol2* | unixware )
3228     AC_DEFINE(BROKEN_SIGIO, 1, [Define if SIGIO should not be used.])
3229     ;;
3230
3231   aix4-2)
3232     dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
3233     AC_DEFINE(BROKEN_FIONREAD, 1, [Define if FIONREAD should not be used.])
3234     dnl As we define BROKEN_FIONREAD, SIGIO will be undefined in systty.h.
3235     dnl But, on AIX, SIGAIO, SIGPTY, and SIGPOLL are defined as SIGIO,
3236     dnl which causes compilation error at init_signals in sysdep.c.
3237     dnl So, we define these macros so that syssignal.h detects them
3238     dnl and undefine SIGAIO, SIGPTY and SIGPOLL.
3239     AC_DEFINE(BROKEN_SIGAIO, 1, [Define if SIGAIO should not be used.])
3240     AC_DEFINE(BROKEN_SIGPOLL,1, [Define if SIGPOLL should not be used.])
3241     AC_DEFINE(BROKEN_SIGPTY, 1, [Define if SIGPTY should not be used.])
3242
3243     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
3244     dnl the way this system works, libc functions that return malloced
3245     dnl memory use the libc malloc implementation. Calling xfree or
3246     dnl xrealloc on the results of such functions results in a crash.
3247     dnl
3248     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
3249     dnl but that does not currently work on this system.
3250     dnl
3251     dnl It is possible to completely override the malloc implementation on
3252     dnl AIX, but that involves putting the malloc functions in a shared
3253     dnl library and setting the MALLOCTYPE environment variable to point to
3254     dnl that shared library.
3255     dnl
3256     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
3257     dnl to avoid a crash just use the Emacs implementation for that function.
3258     dnl
3259     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
3260     dnl of this file, so that we do not check for get_current_dir_name
3261     dnl on AIX.  But that might be fragile if something else ends
3262     dnl up testing for get_current_dir_name as a dependency.
3263     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
3264       get_current_dir_name should not be used.])
3265     ;;
3266
3267   freebsd)
3268     dnl Circumvent a bug in FreeBSD.  In the following sequence of
3269     dnl writes/reads on a PTY, read(2) returns bogus data:
3270     dnl
3271     dnl write(2)  1022 bytes
3272     dnl write(2)   954 bytes, get EAGAIN
3273     dnl read(2)   1024 bytes in process_read_output
3274     dnl read(2)     11 bytes in process_read_output
3275     dnl
3276     dnl That is, read(2) returns more bytes than have ever been written
3277     dnl successfully.  The 1033 bytes read are the 1022 bytes written
3278     dnl successfully after processing (for example with CRs added if the
3279     dnl terminal is set up that way which it is here).  The same bytes will
3280     dnl be seen again in a later read(2), without the CRs.
3281     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
3282       work around an issue when reading from a PTY.])
3283     ;;
3284
3285   dnl Define the following so emacs symbols will not conflict with those
3286   dnl in the System framework.  Otherwise -prebind will not work.
3287   darwin)
3288     AC_DEFINE(NO_ABORT, 1, [Do not define abort in emacs.c.])
3289     ;;
3290 esac
3291
3292 case $opsys in
3293   gnu-* | sol2-10 )
3294     dnl FIXME Can't we test if this exists (eg /proc/$$)?
3295     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3296   ;;
3297 esac
3298
3299 case $opsys in
3300   darwin | freebsd | netbsd | openbsd )
3301     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
3302       close a pty to make it a controlling terminal (it is already a
3303       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
3304   ;;
3305 esac
3306
3307 dnl FIXME Surely we can test for this rather than hard-code it.
3308 case $opsys in
3309   netbsd | openbsd) sound_device="/dev/audio" ;;
3310   *) sound_device="/dev/dsp" ;;
3311 esac
3312
3313 dnl Used in sound.c
3314 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
3315   [Name of the default sound device.])
3316
3317
3318 dnl Emacs can read input using SIGIO and buffering characters itself,
3319 dnl or using CBREAK mode and making C-g cause SIGINT.
3320 dnl The choice is controlled by the variable interrupt_input.
3321 dnl
3322 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
3323 dnl
3324 dnl Emacs uses the presence or absence of the SIGIO and BROKEN_SIGIO macros
3325 dnl to indicate whether or not signal-driven I/O is possible.  It uses
3326 dnl INTERRUPT_INPUT to decide whether to use it by default.
3327 dnl
3328 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
3329 dnl CBREAK mode has two disadvantages
3330 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
3331 dnl I hear that in system V this problem does not exist.
3332 dnl 2) Control-G causes output to be discarded.
3333 dnl I do not know whether this can be fixed in system V.
3334 dnl
3335 dnl Another method of doing input is planned but not implemented.
3336 dnl It would have Emacs fork off a separate process
3337 dnl to read the input and send it to the true Emacs process
3338 dnl through a pipe.
3339 case $opsys in
3340   darwin | gnu-linux | gnu-kfreebsd )
3341     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
3342   ;;
3343 esac
3344
3345
3346 dnl If the system's imake configuration file defines `NeedWidePrototypes'
3347 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
3348 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
3349 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
3350 dnl taking float or double parameters.
3351 case $opsys in
3352   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
3353     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
3354       file defines `NeedWidePrototypes' as `NO'.])
3355   ;;
3356 esac
3357
3358
3359 dnl Used in process.c, this must be a loop, even if it only runs once.
3360 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
3361 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
3362 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
3363 dnl trying suffixes 0-16.
3364 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
3365   first PTY, if PTYs are supported.])
3366 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
3367 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
3368   end of a PTY, if non-standard.])
3369 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
3370   end of a PTY, if non-standard.])
3371
3372 case $opsys in
3373   aix4-2 )
3374     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
3375     dnl You allocate a pty by opening /dev/ptc to get the master side.
3376     dnl To get the name of the slave side, you just ttyname() the master side.
3377     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
3378     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
3379     ;;
3380
3381   cygwin )
3382     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3383     dnl multi-line AC_DEFINEs are hard. :(
3384     AC_DEFINE(PTY_OPEN, [ do { int dummy; SIGMASKTYPE mask; mask = sigblock (sigmask (SIGCHLD)); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; sigsetmask (mask); if (fd >= 0) emacs_close (dummy); } while (0)])
3385     AC_DEFINE(PTY_NAME_SPRINTF, [])
3386     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3387     ;;
3388
3389   darwin )
3390     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3391     dnl Not used, because PTY_ITERATION is defined.
3392     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3393     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
3394     dnl But we don't have to block SIGCHLD because it is blocked in the
3395     dnl implementation of grantpt.
3396     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (0)])
3397     AC_DEFINE(PTY_NAME_SPRINTF, [])
3398     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3399     ;;
3400
3401   gnu | freebsd | netbsd | openbsd )
3402     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3403     ;;
3404
3405   gnu-linux | gnu-kfreebsd )
3406     dnl if HAVE_GRANTPT
3407     if test "x$ac_cv_func_grantpt" = xyes; then
3408       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
3409       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3410       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
3411       dnl to prevent sigchld_handler from intercepting the child's death.
3412       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname; sigblock (sigmask (SIGCHLD)); if (grantpt (fd) == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname(fd))) { sigunblock (sigmask (SIGCHLD)); close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); sigunblock (sigmask (SIGCHLD)); }])
3413       dnl if HAVE_GETPT
3414       if test "x$ac_cv_func_getpt" = xyes; then
3415         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
3416         AC_DEFINE(PTY_NAME_SPRINTF, [])
3417       else
3418         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3419       fi
3420     else
3421       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3422     fi
3423     ;;
3424
3425   hpux*)
3426     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3427     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
3428     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
3429     ;;
3430
3431   irix6-5 )
3432     dnl It looks like this cannot be right, because it is not a loop.
3433     dnl However, process.c actually does this:
3434     dnl # ifndef __sgi
3435     dnl   continue;
3436     dnl # else
3437     dnl   return -1;
3438     dnl # endif
3439     dnl which presumably makes it OK, since irix == sgi (?).
3440     dnl FIXME it seems like this special treatment is unnecessary?
3441     dnl Why can't irix use a single-trip loop like eg cygwin?
3442     AC_DEFINE(PTY_ITERATION, [])
3443     dnl Not used, because PTY_ITERATION is defined.
3444     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
3445     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
3446     dnl No need to get the pty name at all.
3447     AC_DEFINE(PTY_NAME_SPRINTF, [])
3448     dnl No need to use sprintf to get the tty name--we get that from _getpty.
3449     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3450     ;;
3451
3452   sol2* )
3453     dnl Uses sigblock/sigunblock rather than sighold/sigrelse,
3454     dnl which appear to be BSD4.1 specific.  It may also be appropriate
3455     dnl for SVR4.x (x<2) but I'm not sure.   fnf@cygnus.com
3456     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
3457     dnl from intercepting that death.  If any child but grantpt's should die
3458     dnl within, it should be caught after sigrelse(2).
3459     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; sigblock (sigmask (SIGCLD)); if (grantpt (fd) == -1) { emacs_close (fd); return -1; } sigunblock (sigmask (SIGCLD)); if (unlockpt (fd) == -1) { emacs_close (fd); return -1; } if (!(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3460     ;;
3461
3462   unixware )
3463     dnl Comments are as per sol2*.
3464     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; sigblock(sigmask(SIGCLD)); if (grantpt(fd) == -1) fatal("could not grant slave pty"); sigunblock(sigmask(SIGCLD)); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3465     ;;
3466 esac
3467
3468
3469 case $opsys in
3470   sol2* | unixware )
3471     dnl This change means that we don't loop through allocate_pty too
3472     dnl many times in the (rare) event of a failure.
3473     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
3474     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3475     dnl Push various streams modules onto a PTY channel.  Used in process.c.
3476     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
3477     ;;
3478 esac
3479
3480
3481 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
3482 "typing" a signal character on the pty.])
3483
3484 case $opsys in
3485   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
3486   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
3487   aix4-2 | cygwin | gnu | irix6-5 | freebsd | netbsd | openbsd )
3488     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3489     ;;
3490
3491   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
3492   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
3493   gnu-linux | gnu-kfreebsd )
3494
3495     AC_MSG_CHECKING([for signals via characters])
3496     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3497 #include <linux/version.h>
3498 #if LINUX_VERSION_CODE < 0x20400
3499 # error "Linux version too old"
3500 #endif
3501       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
3502
3503     AC_MSG_RESULT([$emacs_signals_via_chars])
3504     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3505     ;;
3506 esac
3507
3508
3509 dnl Used in dispnew.c
3510 AH_TEMPLATE(PENDING_OUTPUT_COUNT, [Number of chars of output in the
3511   buffer of a stdio stream.])
3512
3513 AC_MSG_CHECKING([whether we are using the GNU C library])
3514 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3515 #include <features.h>
3516 #ifndef __GNU_LIBRARY__
3517 # error "this is not the GNU C library"
3518 #endif
3519   ]], [[]])], emacs_glibc=yes, emacs_glibc=no)
3520 AC_MSG_RESULT([$emacs_glibc])
3521
3522 if test $emacs_glibc = yes; then
3523
3524   emacs_pending_output=unknown
3525
3526   case $opsys in
3527     gnu | gnu-linux | gnu-kfreebsd )
3528       AC_MSG_CHECKING([for style of pending output formalism])
3529       dnl In autoconf 2.67 and later, we could use a single test
3530       dnl since the preprocessed output is accessible in "conftest.i".
3531       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3532 #include <stdio.h>
3533 #if !defined (_IO_STDIO_H) && !defined (_STDIO_USES_IOSTREAM)
3534 # error "stdio definitions not found"
3535 #endif
3536         ]], [[]])], emacs_pending_output=new, [])
3537
3538       if test $emacs_pending_output = unknown; then
3539         case $opsys in
3540           gnu-linux | gnu-kfreebsd)
3541             AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3542 #include <stdio.h>
3543 #ifndef __UCLIBC__
3544 # error "not using uclibc"
3545 #endif
3546             ]], [[]])], emacs_pending_output=uclibc, emacs_pending_output=old)
3547             ;;
3548         esac
3549       fi
3550
3551       AC_MSG_RESULT([$emacs_pending_output])
3552
3553       case $emacs_pending_output in
3554         new)
3555           dnl New C libio names.
3556           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3557             [((FILE)->_IO_write_ptr - (FILE)->_IO_write_base)])
3558           ;;
3559         uclibc)
3560           dnl Using the uClibc library.
3561           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3562             [((FILE)->__bufpos - (FILE)->__bufstart)])
3563           ;;
3564         old)
3565           dnl Old C++ iostream names.
3566           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3567             [((FILE)->_pptr - (FILE)->_pbase)])
3568           ;;
3569       esac
3570     ;;
3571   esac                          dnl opsys
3572
3573   if test $emacs_pending_output = unknown; then
3574     AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->__bufp - (FILE)->__buffer)])
3575   fi
3576
3577 else                            dnl !emacs_glibc
3578
3579   case $opsys in
3580     cygwin | darwin | freebsd | netbsd | openbsd )
3581       AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->_p - (FILE)->_bf._base)])
3582       ;;
3583
3584     unixware)
3585       AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->__ptr - (FILE)->__base)])
3586       ;;
3587
3588     *)
3589       dnl HAVE_STDIO_EXT_H && HAVE___FPENDING
3590       if test x$ac_cv_header_stdio_ext_h = xyes && \
3591         test x$ac_cv_func___fpending = xyes; then
3592         AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [__fpending (FILE)])
3593         AC_DEFINE(DISPNEW_NEEDS_STDIO_EXT, 1,
3594           [Define if dispnew.c should include stdio_ext.h.])
3595       else
3596         AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->_ptr - (FILE)->_base)])
3597       fi
3598       ;;
3599   esac
3600 fi                              dnl emacs_glibc
3601
3602
3603 dnl Used in vm-limit.c
3604 AH_TEMPLATE(DATA_START, [Address of the start of the data segment.])
3605 dnl Used in lisp.h, emacs.c, mem-limits.h
3606 dnl NEWS.18 describes this as "a number which contains
3607 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
3608 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
3609 stored in a Lisp_Object.])
3610 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
3611
3612 case $opsys in
3613   gnu)
3614     dnl libc defines data_start.
3615     AC_DEFINE(DATA_START, [({ extern int data_start; (char *) &data_start; })])
3616     ;;
3617
3618   hpux*)
3619     dnl The data segment on this machine always starts at address 0x40000000.
3620     AC_DEFINE(DATA_START, [0x40000000])
3621     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
3622     ;;
3623   irix6-5)
3624     AC_DEFINE(DATA_START, [0x10000000])
3625     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
3626     ;;
3627 esac
3628
3629
3630 AH_TEMPLATE(ULIMIT_BREAK_VALUE, [Undocumented.])
3631 AH_TEMPLATE(TAB3, [Undocumented.])
3632
3633 case $opsys in
3634   darwin) AC_DEFINE(TAB3, OXTABS) ;;
3635
3636   gnu | freebsd | netbsd | openbsd )
3637     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
3638     AC_DEFINE(TAB3, OXTABS)
3639     ;;
3640
3641   gnu-linux | gnu-kfreebsd )
3642     dnl libc-linux/sysdeps/linux/i386/ulimit.c says that due to shared
3643     dnl library, we cannot get the maximum address for brk.
3644     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3645 #ifndef __i386__
3646 # error "not i386"
3647 #endif
3648       ]], [[]])], AC_DEFINE(ULIMIT_BREAK_VALUE, [(32*1024*1024)]), [])
3649
3650     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3651 #ifndef __ia64__
3652 # error "not ia64"
3653 #endif
3654       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
3655         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (0)],
3656         [Mark a secondary stack, like the register stack on the ia64.]), [])
3657     ;;
3658
3659   hpux*)
3660     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
3661       run_time_remap; for HPUX.])
3662     ;;
3663
3664   irix6-5)
3665     dnl Ulimit(UL_GMEMLIM) is busted...
3666     AC_DEFINE(ULIMIT_BREAK_VALUE, [0x14000000])
3667     ;;
3668 esac
3669
3670
3671 dnl These won't be used automatically yet.  We also need to know, at least,
3672 dnl that the stack is continuous.
3673 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
3674   registers relevant for conservative garbage collection in the jmp_buf.])
3675
3676 AH_TEMPLATE(GC_MARK_STACK, [Define to GC_USE_GCPROS_AS_BEFORE if
3677   conservative garbage collection is not known to work.])
3678
3679
3680 case $opsys in
3681   aix4-2 | hpux* | unixware)
3682     dnl Conservative garbage collection has not been tested, so for now
3683     dnl play it safe and stick with the old-fashioned way of marking.
3684     AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE])
3685     ;;
3686
3687   dnl Not all the architectures are tested, but there are Debian packages
3688   dnl for SCM and/or Guile on them, so the technique must work.  See also
3689   dnl comments in alloc.c concerning setjmp and gcc.
3690   dnl Fixme: it's probably safe to just use the GCC conditional below.
3691   gnu-linux | gnu-kfreebsd )
3692     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3693 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
3694   || defined __alpha__ || defined __mips__ || defined __s390__ \
3695   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
3696   || defined __ia64__ || defined __sh__
3697 /* ok */
3698 #else
3699 # error "setjmp not known to work on this arch"
3700 #endif
3701     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1),
3702       AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE]) )
3703     ;;
3704 esac
3705
3706
3707 if test x$GCC = xyes; then
3708    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
3709    AC_DEFINE(GC_SETJMP_WORKS, 1)
3710 else
3711   case $opsys in
3712     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
3713     freebsd | netbsd | openbsd | irix6-5 | sol2* )
3714       AC_DEFINE(GC_SETJMP_WORKS, 1)
3715       ;;
3716   esac
3717 fi                              dnl GCC?
3718
3719
3720 case $opsys in
3721   sol2* | unixware )
3722     dnl setjmp and longjmp can safely replace _setjmp and _longjmp,
3723     dnl but they will run more slowly.
3724     AC_DEFINE(_setjmp, setjmp, [Some platforms redefine this.])
3725     AC_DEFINE(_longjmp, longjmp, [Some platforms redefine this.])
3726     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
3727     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
3728     dnl and this is all we need.
3729     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
3730     ;;
3731 esac
3732
3733
3734 case $opsys in
3735   hpux* | sol2* )
3736     dnl Used in xfaces.c.
3737     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
3738       some systems, where it requires time.h.])
3739     ;;
3740
3741   netbsd | openbsd )
3742     dnl Greg A. Woods <woods@weird.com> says we must include signal.h
3743     dnl before syssignal.h is included, to work around interface conflicts
3744     dnl that are handled with CPP __RENAME() macro in signal.h.
3745     AC_DEFINE(SIGNAL_H_AHB, 1, [Define if AH_BOTTOM should include signal.h.])
3746     ;;
3747 esac
3748
3749
3750 dnl Define symbols to identify the version of Unix this is.
3751 dnl Define all the symbols that apply correctly.
3752 AH_TEMPLATE(BSD4_2, [Define if the system is compatible with BSD 4.2.])
3753 AH_TEMPLATE(BSD_SYSTEM, [Define if the system is compatible with BSD 4.2.])
3754 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
3755 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
3756 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
3757 AH_TEMPLATE(USG5, [Define if the system is compatible with System V.])
3758 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
3759
3760 case $opsys in
3761   aix4-2)
3762     AC_DEFINE(USG, [])
3763     AC_DEFINE(USG5, [])
3764     dnl This symbol should be defined on AIX Version 3  ???????
3765     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3766 #ifndef _AIX
3767 # error "_AIX not defined"
3768 #endif
3769     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
3770     ;;
3771
3772   cygwin)
3773     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
3774     ;;
3775
3776   darwin)
3777     dnl BSD4_3 and BSD4_4 are already defined in sys/param.h.
3778     AC_DEFINE(BSD4_2, [])
3779     AC_DEFINE(BSD_SYSTEM, [])
3780     dnl More specific than the above two.  We cannot use __APPLE__ as this
3781     dnl may not be defined on non-OSX Darwin, and we cannot define DARWIN
3782     dnl here because Panther and lower CoreFoundation.h uses DARWIN to
3783     dnl distinguish OS X from pure Darwin.
3784     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
3785     ;;
3786
3787   freebsd)
3788     AC_DEFINE(BSD4_2, [])
3789     dnl Hack to avoid calling AC_PREPROC_IFELSE multiple times.
3790     dnl Would not be needed with autoconf >= 2.67, where the
3791     dnl preprocessed output is accessible in "conftest.i".
3792     AC_DEFINE(BSD_SYSTEM_AHB, 1, [Define if AH_BOTTOM should change BSD_SYSTEM.])
3793     ;;
3794
3795   gnu | netbsd | openbsd )
3796     AC_DEFINE(BSD4_2, [])
3797     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3798 #ifndef BSD_SYSTEM
3799 # error "BSD_SYSTEM not defined"
3800 #endif
3801     ]], [[]])], [], AC_DEFINE(BSD_SYSTEM, 43) )
3802     ;;
3803
3804   gnu-linux | gnu-kfreebsd )
3805     AC_DEFINE(USG, [])
3806     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
3807     ;;
3808
3809   hpux*)
3810     AC_DEFINE(USG, [])
3811     AC_DEFINE(USG5, [])
3812     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
3813     ;;
3814
3815   irix6-5)
3816     AC_DEFINE(USG, [])
3817     AC_DEFINE(USG5, [])
3818     AC_DEFINE(USG5_4, [])
3819     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
3820     ;;
3821
3822   sol2*)
3823     AC_DEFINE(USG, [])
3824     AC_DEFINE(USG5, [])
3825     AC_DEFINE(USG5_4, [])
3826     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
3827     ;;
3828
3829   unixware)
3830     AC_DEFINE(USG, [])
3831     AC_DEFINE(USG5, [])
3832     AC_DEFINE(USG5_4, [])
3833     ;;
3834 esac
3835
3836
3837 case $opsys in
3838   dnl Emacs supplies its own malloc, but glib (part of Gtk+) calls
3839   dnl memalign and on Cygwin, that becomes the Cygwin-supplied memalign.
3840   dnl As malloc is not the Cygwin malloc, the Cygwin memalign always
3841   dnl returns ENOSYS.  A workaround is to set G_SLICE=always-malloc. */
3842   cygwin)
3843     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
3844       G_SLICE environment variable to "always-malloc" at startup, if
3845       using GTK.])
3846     ;;
3847
3848   hpux11)
3849     dnl See comments in sysdep.c:sys_signal.
3850     dnl SA_RESTART resets the timeout of `select' on hpux11.
3851     dnl Defining BROKEN_SA_RESTART is not the same as undef'ing SA_RESTART.
3852     AC_DEFINE(BROKEN_SA_RESTART, 1, [Define if SA_RESTART should only
3853       be used in batch mode.])
3854     dnl It works to open the pty's tty in the parent (Emacs), then
3855     dnl close and reopen it in the child.
3856     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
3857       works to open a pty's tty in the parent process, then close and
3858       reopen it in the child.])
3859     ;;
3860
3861   irix6-5)
3862     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
3863       use VSUSP instead of VSWTCH.])
3864     AC_DEFINE(SETPGRP_RELEASES_CTTY, 1, [Define if process.c:child_setup
3865       should not call setpgrp.])
3866     ;;
3867
3868   sol2-10)
3869     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
3870       on Solaris.])
3871     ;;
3872 esac
3873
3874 # Set up the CFLAGS for real compilation, so we can substitute it.
3875 CFLAGS="$REAL_CFLAGS"
3876 CPPFLAGS="$REAL_CPPFLAGS"
3877
3878 ## Hack to detect a buggy GCC version.
3879 if test "x$GCC" = xyes \
3880    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3881    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3882    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3883    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3884 fi
3885
3886 version=$PACKAGE_VERSION
3887
3888 ### Specify what sort of things we'll be editing into Makefile and config.h.
3889 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3890 AC_SUBST(version)
3891 AC_SUBST(configuration)
3892 ## Unused?
3893 AC_SUBST(canonical)
3894 AC_SUBST(srcdir)
3895 AC_SUBST(prefix)
3896 AC_SUBST(exec_prefix)
3897 AC_SUBST(bindir)
3898 AC_SUBST(datadir)
3899 AC_SUBST(sharedstatedir)
3900 AC_SUBST(libexecdir)
3901 AC_SUBST(mandir)
3902 AC_SUBST(infodir)
3903 AC_SUBST(lispdir)
3904 AC_SUBST(leimdir)
3905 AC_SUBST(standardlisppath)
3906 AC_SUBST(locallisppath)
3907 AC_SUBST(lisppath)
3908 AC_SUBST(x_default_search_path)
3909 AC_SUBST(etcdir)
3910 AC_SUBST(archlibdir)
3911 AC_SUBST(docdir)
3912 AC_SUBST(bitmapdir)
3913 AC_SUBST(gamedir)
3914 AC_SUBST(gameuser)
3915 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3916 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3917 ## end of LIBX_BASE, but nothing ever set it.
3918 AC_SUBST(LD_SWITCH_X_SITE)
3919 AC_SUBST(C_SWITCH_X_SITE)
3920 AC_SUBST(GNUSTEP_CFLAGS)
3921 AC_SUBST(CFLAGS)
3922 ## Used in lwlib/Makefile.in.
3923 AC_SUBST(X_TOOLKIT_TYPE)
3924 AC_SUBST(ns_appdir)
3925 AC_SUBST(ns_appbindir)
3926 AC_SUBST(ns_appresdir)
3927 AC_SUBST(ns_appsrc)
3928 AC_SUBST(GNU_OBJC_CFLAGS)
3929 AC_SUBST(OTHER_FILES)
3930
3931 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3932                    [Define to the canonical Emacs configuration name.])
3933 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3934                    [Define to the options passed to configure.])
3935 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
3936   define this to include extra configuration information.])
3937
3938 XMENU_OBJ=
3939 XOBJ=
3940 FONT_OBJ=
3941 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3942   AC_DEFINE(HAVE_X_WINDOWS, 1,
3943             [Define to 1 if you want to use the X window system.])
3944   XMENU_OBJ=xmenu.o
3945   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3946   FONT_OBJ=xfont.o
3947   if test "$HAVE_XFT" = "yes"; then
3948     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3949   elif test "$HAVE_FREETYPE" = "yes"; then
3950     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3951   fi
3952   AC_SUBST(FONT_OBJ)
3953 fi
3954 AC_SUBST(XMENU_OBJ)
3955 AC_SUBST(XOBJ)
3956 AC_SUBST(FONT_OBJ)
3957
3958 WIDGET_OBJ=
3959 MOTIF_LIBW=
3960 if test "${USE_X_TOOLKIT}" != "none" ; then
3961   WIDGET_OBJ=widget.o
3962   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3963   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3964     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3965   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3966     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3967     MOTIF_LIBW=-lXm
3968     case "$opsys" in
3969       gnu-linux)
3970         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3971         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3972         ;;
3973
3974       unixware)
3975         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3976         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3977         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3978         ;;
3979
3980       aix4-2)
3981         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3982         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3983         ;;
3984     esac
3985     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3986   fi
3987 fi
3988 AC_SUBST(WIDGET_OBJ)
3989
3990 TOOLKIT_LIBW=
3991 case "$USE_X_TOOLKIT" in
3992   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3993   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3994   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3995 esac
3996 AC_SUBST(TOOLKIT_LIBW)
3997
3998 if test "$USE_X_TOOLKIT" = "none"; then
3999   LIBXT_OTHER="\$(LIBXSM)"
4000   OLDXMENU_TARGET="really-oldXMenu"
4001 else
4002   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4003   OLDXMENU_TARGET="really-lwlib"
4004 fi
4005 AC_SUBST(LIBXT_OTHER)
4006
4007 ## The X Menu stuff is present in the X10 distribution, but missing
4008 ## from X11.  If we have X10, just use the installed library;
4009 ## otherwise, use our own copy.
4010 if test "${HAVE_X11}" = "yes" ; then
4011   AC_DEFINE(HAVE_X11, 1,
4012             [Define to 1 if you want to use version 11 of X windows.
4013              Otherwise, Emacs expects to use version 10.])
4014
4015   if test "$USE_X_TOOLKIT" = "none"; then
4016     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
4017   else
4018     OLDXMENU="\${lwlibdir}/liblw.a"
4019   fi
4020   LIBXMENU="\$(OLDXMENU)"
4021   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4022   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
4023 else
4024   ## For a syntactically valid Makefile; not actually used for anything.
4025   ## See comments in src/Makefile.in.
4026   OLDXMENU=nothing
4027   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
4028   if test "${HAVE_X_WINDOWS}" = "yes"; then
4029     LIBXMENU="-lXMenu"
4030   else
4031     LIBXMENU=
4032   fi
4033   LIBX_OTHER=
4034   OLDXMENU_DEPS=
4035 fi
4036
4037 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
4038   OLDXMENU_TARGET=
4039   OLDXMENU=nothing
4040   LIBXMENU=
4041   OLDXMENU_DEPS=
4042 fi
4043
4044 AC_SUBST(OLDXMENU_TARGET)
4045 AC_SUBST(OLDXMENU)
4046 AC_SUBST(LIBXMENU)
4047 AC_SUBST(LIBX_OTHER)
4048 AC_SUBST(OLDXMENU_DEPS)
4049
4050 if test "${HAVE_MENUS}" = "yes" ; then
4051   AC_DEFINE(HAVE_MENUS, 1,
4052             [Define to 1 if you have mouse menus.
4053              (This is automatic if you use X, but the option to specify it remains.)
4054              It is also defined with other window systems that support xmenu.c.])
4055 fi
4056
4057 if test "${GNU_MALLOC}" = "yes" ; then
4058   AC_DEFINE(GNU_MALLOC, 1,
4059             [Define to 1 if you want to use the GNU memory allocator.])
4060 fi
4061
4062 RALLOC_OBJ=
4063 if test "${REL_ALLOC}" = "yes" ; then
4064   AC_DEFINE(REL_ALLOC, 1,
4065             [Define REL_ALLOC if you want to use the relocating allocator for
4066              buffer space.])
4067
4068   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4069 fi
4070 AC_SUBST(RALLOC_OBJ)
4071
4072 if test "$opsys" = "cygwin"; then
4073   CYGWIN_OBJ="sheap.o"
4074   ## Cygwin differs because of its unexec().
4075   PRE_ALLOC_OBJ=
4076   POST_ALLOC_OBJ=lastfile.o
4077 else
4078   CYGWIN_OBJ=
4079   PRE_ALLOC_OBJ=lastfile.o
4080   POST_ALLOC_OBJ=
4081 fi
4082 AC_SUBST(CYGWIN_OBJ)
4083 AC_SUBST(PRE_ALLOC_OBJ)
4084 AC_SUBST(POST_ALLOC_OBJ)
4085
4086 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4087 # it temporarily reverts them to their pre-pkg-config values,
4088 # because gnulib needs to work with both src (which uses the
4089 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4090 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4091 # and it therefore needs to run in an environment where LIBS does not
4092 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4093 # for some package unrelated to lib-src.
4094 SAVE_CFLAGS=$CFLAGS
4095 SAVE_LIBS=$LIBS
4096 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4097 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4098 gl_ASSERT_NO_GNULIB_POSIXCHECK
4099 gl_ASSERT_NO_GNULIB_TESTS
4100 gl_INIT
4101 CFLAGS=$SAVE_CFLAGS
4102 LIBS=$SAVE_LIBS
4103
4104 case "$opsys" in
4105   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4106
4107   darwin)
4108    ## The -headerpad option tells ld (see man page) to leave room at the
4109    ## end of the header for adding load commands.  Needed for dumping.
4110    ## 0x690 is the total size of 30 segment load commands (at 56
4111    ## each); under Cocoa 31 commands are required.
4112    if test "$HAVE_NS" = "yes"; then
4113      libs_nsgui="-framework AppKit"
4114      headerpad_extra=6C8
4115    else
4116      libs_nsgui=
4117      headerpad_extra=690
4118    fi
4119    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4120
4121    ## This is here because src/Makefile.in did some extra fiddling around
4122    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
4123    ##   #ifndef LD_SWITCH_SYSTEM
4124    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
4125    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
4126    ## not using gcc, darwin.
4127    ## Because this was done in src/Makefile.in, the resulting part of
4128    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
4129    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
4130    ## rather than LD_SWITCH_SYSTEM.
4131    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4132      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4133    ;;
4134
4135   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4136   ## find X at run-time.
4137   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4138   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4139   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4140   ## had different values in configure (in ac_link) and src/Makefile.in.
4141   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4142   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4143
4144   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4145 esac
4146
4147 if test "$NS_IMPL_GNUSTEP" = "yes"; then
4148   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
4149 fi
4150
4151 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4152
4153
4154 LD_FIRSTFLAG=
4155 ORDINARY_LINK=
4156 case "$opsys" in
4157   ## gnu: GNU needs its own crt0.
4158   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
4159
4160   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
4161   ## library search parth, i.e. it won't search /usr/lib for libc and
4162   ## friends.  Using -nostartfiles instead avoids this problem, and
4163   ## will also work on earlier NetBSD releases.
4164   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
4165
4166   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
4167   ##   MkLinux/LinuxPPC needs this.
4168   ## s390x-* only supports opsys = gnu-linux so it can be added here.
4169   gnu-*)
4170     case "$canonical" in
4171       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
4172     esac
4173     ;;
4174 esac
4175
4176
4177 if test "x$ORDINARY_LINK" = "xyes"; then
4178
4179   LD_FIRSTFLAG=""
4180   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
4181
4182 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
4183 ## freebsd, gnu-* not on powerpc*|s390x*.
4184 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
4185
4186   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
4187   ## places that are difficult to figure out at make time.  Fortunately,
4188   ## these same versions allow you to pass arbitrary flags on to the
4189   ## linker, so there is no reason not to use it as a linker.
4190   ##
4191   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
4192   ## searching for libraries in its internal directories, so we have to
4193   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
4194   LD_FIRSTFLAG="-nostdlib"
4195 fi
4196
4197 ## FIXME? What setting of EDIT_LDFLAGS should this have?
4198 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
4199
4200 AC_SUBST(LD_FIRSTFLAG)
4201
4202
4203 ## FIXME? The logic here is not precisely the same as that above.
4204 ## There is no check here for a pre-defined LD_FIRSTFLAG.
4205 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
4206 LIB_GCC=
4207 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
4208
4209   case "$opsys" in
4210     freebsd|netbsd|openbsd) LIB_GCC= ;;
4211
4212     gnu-*)
4213       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
4214       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
4215       case $host_cpu in
4216       arm*)
4217         LIB_GCC="-lgcc_s"
4218         ;;
4219       *)
4220         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
4221         ## immediately undefine it again and redefine it to empty.
4222         ## Was the C_SWITCH_X_SITE part really necessary?
4223 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
4224         LIB_GCC=
4225         ;;
4226       esac
4227       ;;
4228
4229     ## Ask GCC where to find libgcc.a.
4230     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
4231   esac
4232 fi                              dnl if $GCC
4233 AC_SUBST(LIB_GCC)
4234
4235
4236 ## If we're using X11/GNUstep, define some consequences.
4237 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
4238   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4239   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
4240 fi
4241
4242
4243 AH_TOP([/* GNU Emacs site configuration template file.
4244
4245 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
4246   Free Software Foundation, Inc.
4247
4248 This file is part of GNU Emacs.
4249
4250 GNU Emacs is free software: you can redistribute it and/or modify
4251 it under the terms of the GNU General Public License as published by
4252 the Free Software Foundation, either version 3 of the License, or
4253 (at your option) any later version.
4254
4255 GNU Emacs is distributed in the hope that it will be useful,
4256 but WITHOUT ANY WARRANTY; without even the implied warranty of
4257 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4258 GNU General Public License for more details.
4259
4260 You should have received a copy of the GNU General Public License
4261 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4262
4263
4264 /* No code in Emacs #includes config.h twice, but some bits of code
4265    intended to work with other packages as well (like gmalloc.c)
4266    think they can include it as many times as they like.  */
4267 #ifndef EMACS_CONFIG_H
4268 #define EMACS_CONFIG_H
4269 ])dnl
4270
4271 AH_BOTTOM([#include <conf_post.h>
4272
4273 #endif /* EMACS_CONFIG_H */
4274
4275 /*
4276 Local Variables:
4277 mode: c
4278 End:
4279 */
4280 ])dnl
4281
4282 #### Report on what we decided to do.
4283 #### Report GTK as a toolkit, even if it doesn't use Xt.
4284 #### It makes printing result more understandable as using GTK sets
4285 #### toolkit_scroll_bars to yes by default.
4286 if test "${HAVE_GTK}" = "yes"; then
4287   if test "${with_gtk3}" = "yes"; then
4288     USE_X_TOOLKIT=GTK3
4289   else
4290     USE_X_TOOLKIT=GTK
4291   fi
4292 fi
4293
4294 echo "
4295 Configured for \`${canonical}'.
4296
4297   Where should the build process find the source code?    ${srcdir}
4298   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4299   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4300   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4301   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4302   What window system should Emacs use?                    ${window_system}
4303   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4304
4305 if test -n "${x_includes}"; then
4306 echo "  Where do we find X Windows header files?                ${x_includes}"
4307 else
4308 echo "  Where do we find X Windows header files?                Standard dirs"
4309 fi
4310 if test -n "${x_libraries}"; then
4311 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4312 else
4313 echo "  Where do we find X Windows libraries?                   Standard dirs"
4314 fi
4315
4316 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4317 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4318 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4319 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4320 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
4321 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
4322 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
4323 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
4324
4325 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
4326 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
4327 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
4328 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
4329 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
4330 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
4331 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
4332
4333 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
4334 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
4335 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
4336 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
4337
4338 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
4339 echo
4340
4341 if test -n "${EMACSDATA}"; then
4342    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
4343 fi
4344 if test -n "${EMACSDOC}"; then
4345    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
4346 fi
4347
4348 echo
4349
4350 if test "$HAVE_NS" = "yes"; then
4351    echo
4352    echo "You must run \"${MAKE-make} install\" in order to test the built application.
4353 The installed application will go to nextstep/Emacs.app and can be
4354 run or moved from there."
4355    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
4356       echo "The application will be fully self-contained."
4357     else
4358       echo "The lisp resources for the application will be installed under ${prefix}.
4359 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
4360 to run if these resources are not installed."
4361    fi
4362    echo
4363 fi
4364
4365 if test "${opsys}" = "cygwin"; then
4366   case `uname -r` in
4367     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
4368            echo
4369            ;;
4370   esac
4371 fi
4372
4373 # Remove any trailing slashes in these variables.
4374 [test "${prefix}" != NONE &&
4375   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
4376 test "${exec_prefix}" != NONE &&
4377   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
4378
4379 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
4380 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
4381 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
4382 dnl (else you get "no `Makefile.am' found for any configure output").
4383 dnl This will work, but you get a config.status that is not quite right
4384 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
4385 dnl That doesn't have any obvious consequences for Emacs, but on the whole
4386 dnl it seems better to just live with the duplication.
4387 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
4388
4389 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
4390        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
4391        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
4392        leim/Makefile])
4393
4394 dnl test/ is not present in release tarfiles.
4395 opt_makefile=test/automated/Makefile
4396
4397 if test -f $srcdir/${opt_makefile}.in; then
4398   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4399   dnl Again, it's best not to use a variable.  Though you can add
4400   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
4401   AC_CONFIG_FILES([test/automated/Makefile])
4402 fi
4403
4404
4405 dnl admin/ may or may not be present.
4406 opt_makefile=admin/unidata/Makefile
4407
4408 if test -f $srcdir/${opt_makefile}.in; then
4409   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4410   AC_CONFIG_FILES([admin/unidata/Makefile])
4411 fi
4412
4413
4414 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
4415
4416 AC_SUBST(SUBDIR_MAKEFILES_IN)
4417
4418 dnl Make the necessary directories, if they don't exist.
4419 AC_CONFIG_COMMANDS([mkdirs], [
4420 for dir in etc lisp ; do
4421   test -d ${dir} || mkdir ${dir}
4422 done
4423 ])
4424
4425 dnl You might wonder (I did) why epaths.h is generated by running make,
4426 dnl rather than just letting configure generate it from epaths.in.
4427 dnl One reason is that the various paths are not fully expanded (see above);
4428 dnl eg gamedir=${prefix}/var/games/emacs.
4429 dnl Secondly, the GNU Coding standards require that one should be able
4430 dnl to run `make prefix=/some/where/else' and override the values set
4431 dnl by configure.  This also explains the `move-if-change' test and
4432 dnl the use of force in the `epaths-force' rule in Makefile.in.
4433 AC_CONFIG_COMMANDS([epaths], [
4434 echo creating src/epaths.h
4435 ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
4436 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
4437
4438 AC_CONFIG_COMMANDS([gdbinit], [
4439 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
4440   echo creating src/.gdbinit
4441   echo source $srcdir/src/.gdbinit > src/.gdbinit
4442 fi
4443 ])
4444
4445 AC_OUTPUT