code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.61)
  25 AC_INIT(emacs, 23.0.60)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 if test "$with_hesiod" != no; then
  95   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  96 fi
  97
  98 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
  99
 100 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 101 if test "$with_sync_input" = yes; then
 102    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 103 fi
 104
 105 dnl FIXME currently it is not the last.
 106 dnl This should be the last --with option, because --with-x is
 107 dnl added later on when we find the path of X, and it's best to
 108 dnl keep them together visually.
 109 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 110  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 111 [         case "${withval}" in
 112             y | ye | yes )      val=gtk ;;
 113             n | no )            val=no  ;;
 114             l | lu | luc | luci | lucid )       val=lucid ;;
 115             a | at | ath | athe | athen | athena )      val=athena ;;
 116             m | mo | mot | moti | motif )       val=motif ;;
 117             g | gt | gtk  )     val=gtk ;;
 118             * )
 119 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 120 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 121 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 122             ;;
 123           esac
 124           with_x_toolkit=$val
 125 ])
 126
 127 dnl _ON results in a '--without' option in the --help output, so
 128 dnl the help text should refer to "don't compile", etc.
 129 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 130 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 131 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 132 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 133 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 134 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 135
 136 OPTION_DEFAULT_ON([freetype],[don't use Freetype for local font support])
 137 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 138 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 139 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 140
 141 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 142 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 143 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 144 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 145
 146 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 147 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 148
 149 ## For the times when you want to build Emacs but don't have
 150 ## a suitable makeinfo, and can live without the manuals.
 151 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 152 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 153
 154 dnl Can remove these in Emacs 24.
 155 AC_ARG_WITH([gtk],,
 156   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 157 specify a toolkit.])],,)
 158
 159 AC_ARG_WITH([gcc],,
 160   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 161 variable to specify a compiler.])],,)
 162
 163 AC_ARG_WITH([pkg-config-prog],dnl
 164 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 165                   [path to pkg-config for finding GTK and librsvg])])
 166 if test "X${with_pkg_config_prog}" != X; then
 167    if test "${with_pkg_config_prog}" != yes; then
 168       PKG_CONFIG="${with_pkg_config_prog}"
 169    fi
 170 fi
 171
 172 AC_ARG_WITH([gnustep-conf],dnl
 173 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 174 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 175   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 176 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 177      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 178
 179 AC_ARG_ENABLE(cocoa-experimental-ctrl-g,
 180 [AS_HELP_STRING([--enable-cocoa-experimental-ctrl-g],
 181                 [enable experimental improved ctrl-g recognition])],
 182    EN_COCOA_EXPERIMENTAL_CTRL_G=$enableval,
 183    EN_COCOA_EXPERIMENTAL_CTRL_G=no)
 184
 185 AC_ARG_ENABLE(ns-self-contained,
 186 [AS_HELP_STRING([--disable-ns-self-contained],
 187                 [disable self contained build under NeXTstep])],
 188    EN_NS_SELF_CONTAINED=$enableval,
 189    EN_NS_SELF_CONTAINED=yes)
 190
 191 AC_ARG_ENABLE(asserts,
 192 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 193       USE_XASSERTS=$enableval,
 194       USE_XASSERTS=no)
 195
 196 AC_ARG_ENABLE(maintainer-mode,
 197 [AS_HELP_STRING([--enable-maintainer-mode],
 198                 [enable make rules and dependencies not useful (and sometimes
 199                  confusing) to the casual installer])],
 200       USE_MAINTAINER_MODE=$enableval,
 201       USE_MAINTAINER_MODE=no)
 202 if test $USE_MAINTAINER_MODE = yes; then
 203   MAINT=
 204 else
 205   MAINT=#
 206 fi
 207 AC_SUBST(MAINT)
 208
 209 AC_ARG_ENABLE(locallisppath,
 210 [AS_HELP_STRING([--enable-locallisppath=PATH],
 211                 [directories Emacs should search for lisp files specific
 212                  to this site])],
 213 if test "${enableval}" = "no"; then
 214   locallisppath=
 215 elif test "${enableval}" != "yes"; then
 216   locallisppath=${enableval}
 217 fi)
 218
 219 #### Make srcdir absolute, if it isn't already.  It's important to
 220 #### avoid running the path through pwd unnecessarily, since pwd can
 221 #### give you automounter prefixes, which can go away.  We do all this
 222 #### so Emacs can find its files when run uninstalled.
 223 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 224 unset CDPATH
 225 case "${srcdir}" in
 226   /* ) ;;
 227   . )
 228     ## We may be able to use the $PWD environment variable to make this
 229     ## absolute.  But sometimes PWD is inaccurate.
 230     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 231     ## but that tested only for a well-formed and valid PWD,
 232     ## it did not object when PWD was well-formed and valid but just wrong.
 233     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 234     then
 235       srcdir="$PWD"
 236     else
 237       srcdir="`(cd ${srcdir}; pwd)`"
 238     fi
 239   ;;
 240   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 241 esac
 242
 243 #### Check if the source directory already has a configured system in it.
 244 if test `pwd` != `(cd ${srcdir} && pwd)` \
 245    && test -f "${srcdir}/src/config.h" ; then
 246   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 247    as a build directory right now; it has been configured in its own
 248    right.  To configure in another directory as well, you MUST
 249    use GNU make.  If you do not have GNU make, then you must
 250    now do `make distclean' in ${srcdir},
 251    and then run $0 again.]])
 252 fi
 253
 254 #### Given the configuration name, set machfile and opsysfile to the
 255 #### names of the m/*.h and s/*.h files we should use.
 256
 257 ### Canonicalize the configuration name.
 258
 259 AC_CANONICAL_HOST
 260 canonical=$host
 261 configuration=${host_alias-${build_alias-$host}}
 262
 263 dnl This used to use changequote, but, apart from `changequote is evil'
 264 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 265 dnl the great gob of text.  Thus it's not processed for possible expansion.
 266 dnl Just make sure the brackets remain balanced.
 267 dnl
 268 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 269 dnl indicated by comments.
 270 dnl quotation begins
 271 [
 272
 273 ### If you add support for a new configuration, add code to this
 274 ### switch statement to recognize your configuration name and select
 275 ### the appropriate operating system and machine description files.
 276
 277 ### You would hope that you could choose an m/*.h file pretty much
 278 ### based on the machine portion of the configuration name, and an s-
 279 ### file based on the operating system portion.  However, it turns out
 280 ### that each m/*.h file is pretty manufacturer-specific - for
 281 ### example mips.h is MIPS
 282 ### So we basically have to have a special case for each
 283 ### configuration name.
 284 ###
 285 ### As far as handling version numbers on operating systems is
 286 ### concerned, make sure things will fail in a fixable way.  If
 287 ### /etc/MACHINES doesn't say anything about version numbers, be
 288 ### prepared to handle anything reasonably.  If version numbers
 289 ### matter, be sure /etc/MACHINES says something about it.
 290 ###
 291 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 292 ### "System V Release 4"; he writes, "The old convention encouraged
 293 ### confusion between `system' and `release' levels'."
 294
 295 machine='' opsys='' unported=no
 296 case "${canonical}" in
 297
 298   ## FreeBSD ports
 299   *-*-freebsd* )
 300     opsys=freebsd
 301     case "${canonical}" in
 302       alpha*-*-freebsd*)        machine=alpha ;;
 303       arm*-*-freebsd*)          machine=arm ;;
 304       ia64-*-freebsd*)          machine=ia64 ;;
 305       sparc-*-freebsd*)         machine=sparc ;;
 306       sparc64-*-freebsd*)       machine=sparc ;;
 307       powerpc-*-freebsd*)       machine=macppc ;;
 308       i[3456]86-*-freebsd*)     machine=intel386 ;;
 309       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 310     esac
 311   ;;
 312
 313   ## FreeBSD kernel + glibc based userland
 314   *-*-kfreebsd*gnu* )
 315     opsys=gnu-kfreebsd
 316     case "${canonical}" in
 317       alpha*-*-kfreebsd*)       machine=alpha ;;
 318       ia64-*-kfreebsd*)         machine=ia64 ;;
 319       sparc-*-kfreebsd*)        machine=sparc ;;
 320       sparc64-*-kfreebsd*)      machine=sparc ;;
 321       powerpc-*-kfreebsd*)      machine=macppc ;;
 322       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 323       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 324     esac
 325   ;;
 326
 327   ## NetBSD ports
 328   *-*-netbsd* )
 329     opsys=netbsd
 330     if test -f /usr/lib/crti.o; then]
 331 dnl The close and open brackets here are because this section is quoted --
 332 dnl see the `changequote' comment above.
 333       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 334 [   fi
 335
 336     case "${canonical}" in
 337       alpha*-*-netbsd*) machine=alpha ;;
 338       i[3456]86-*-netbsd*) machine=intel386 ;;
 339       powerpc-*-netbsd*) machine=macppc ;;
 340       sparc*-*-netbsd*) machine=sparc ;;
 341       vax-*-netbsd*)    machine=vax ;;
 342       arm-*-netbsd*)    machine=arm ;;
 343       x86_64-*-netbsd*) machine=amdx86-64 ;;
 344       hppa-*-netbsd*)   machine=hp800 ;;
 345       m68k-*-netbsd*)   machine=m68k ;;
 346     esac
 347   ;;
 348
 349   ## OpenBSD ports
 350   *-*-openbsd* )
 351     opsys=openbsd
 352     case "${canonical}" in
 353       alpha*-*-openbsd*)        machine=alpha ;;
 354       arm-*-openbsd*)          machine=arm ;;
 355       i386-*-openbsd*)         machine=intel386 ;;
 356       powerpc-*-openbsd*)      machine=macppc ;;
 357       sparc*-*-openbsd*)       machine=sparc ;;
 358       vax-*-openbsd*)          machine=vax ;;
 359       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 360       hppa-*-openbsd*)         machine=hp800 ;;
 361     esac
 362   ;;
 363
 364   ## LynxOS ports
 365   *-*-lynxos* )
 366     opsys=lynxos
 367     case "${canonical}" in
 368       i[3456]86-*-lynxos*) machine=intel386 ;;
 369       powerpc-*-lynxos*) machine=powerpc ;;
 370     esac
 371   ;;
 372
 373   alpha*-*-linux-gnu* )
 374     machine=alpha opsys=gnu-linux
 375   ;;
 376
 377   arm*-*-linux-gnu* )
 378     machine=arm opsys=gnu-linux
 379   ;;
 380
 381   ## Apple Darwin / Mac OS X
 382   *-apple-darwin* )
 383     case "${canonical}" in
 384       i[3456]86-* )  machine=intel386 ;;
 385       powerpc-* )    machine=macppc ;;
 386       * )            unported=yes ;;
 387     esac
 388     opsys=darwin
 389     # Define CPP as follows to make autoconf work correctly.
 390     CPP="${CC-cc} -E -no-cpp-precomp"
 391     # Use fink packages if available.
 392     if test -d /sw/include && test -d /sw/lib; then
 393       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 394       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 395       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 396     fi
 397   ;;
 398
 399   ## HP 9000 series 700 and 800, running HP/UX
 400   hppa*-hp-hpux10.2* )
 401     machine=hp800 opsys=hpux10-20
 402   ;;
 403   hppa*-hp-hpux1[1-9]* )
 404     machine=hp800 opsys=hpux11
 405     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 406   ;;
 407
 408   hppa*-*-linux-gnu* )
 409     machine=hp800 opsys=gnu-linux
 410   ;;
 411
 412   ## IBM machines
 413   s390-*-linux-gnu* )
 414     machine=ibms390 opsys=gnu-linux
 415   ;;
 416   s390x-*-linux-gnu* )
 417     machine=ibms390x opsys=gnu-linux
 418   ;;
 419   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 420     machine=ibmrs6000 opsys=aix4-2
 421   ;;
 422   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 423     machine=ibmrs6000 opsys=aix4-2
 424   ;;
 425   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 426     machine=ibmrs6000 opsys=aix4-2
 427   ;;
 428   rs6000-ibm-aix5* | powerpc-ibm-aix6*  )
 429     machine=ibmrs6000 opsys=aix4-2
 430   ;;
 431
 432   ## Macintosh PowerPC
 433   powerpc*-*-linux-gnu* )
 434     machine=macppc opsys=gnu-linux
 435   ;;
 436
 437   ## Silicon Graphics machines
 438   ## Iris 4D
 439   mips-sgi-irix6.5 )
 440     machine=iris4d opsys=irix6-5
 441     # Without defining _LANGUAGE_C, things get masked out in the headers
 442     # so that, for instance, grepping for `free' in stdlib.h fails and
 443     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 444     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 445     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 446   ;;
 447
 448   ## Suns
 449   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 450     machine=sparc opsys=gnu-linux
 451   ;;
 452
 453   *-sun-solaris* \
 454     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 455     | x86_64-*-solaris2*    | x86_64-*-sunos5*    \
 456     | powerpc*-*-solaris2*  | rs6000-*-solaris2*)
 457     case "${canonical}" in
 458       i[3456]86-*-* )     machine=intel386 ;;
 459       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 460       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 461       sparc* )          machine=sparc ;;
 462       * )               unported=yes ;;
 463     esac
 464     case "${canonical}" in
 465       *-sunos5.3* | *-solaris2.3* )
 466                 opsys=sol2-3
 467                 NON_GNU_CPP=/usr/ccs/lib/cpp
 468                 ;;
 469       *-sunos5.4* | *-solaris2.4* )
 470                 opsys=sol2-4
 471                 NON_GNU_CPP=/usr/ccs/lib/cpp
 472                 RANLIB="ar -ts"
 473                 ;;
 474       *-sunos5.5* | *-solaris2.5* )
 475                 opsys=sol2-5
 476                 NON_GNU_CPP=/usr/ccs/lib/cpp
 477                 RANLIB="ar -ts"
 478                 ;;
 479       *-sunos5.6* | *-solaris2.6* )
 480                 opsys=sol2-6
 481                 NON_GNU_CPP=/usr/ccs/lib/cpp
 482                 RANLIB="ar -ts"
 483                 ;;
 484       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 485                 opsys=sol2-6
 486                 emacs_check_sunpro_c=yes
 487                 NON_GNU_CPP=/usr/ccs/lib/cpp
 488                 ;;
 489       *-sunos5* | *-solaris* )
 490                 opsys=sol2-10
 491                 emacs_check_sunpro_c=yes
 492                 NON_GNU_CPP=/usr/ccs/lib/cpp
 493                 ;;
 494     esac
 495     ## Watch out for a compiler that we know will not work.
 496     case "${canonical}" in
 497      *-solaris* | *-sunos5* )
 498                 if [ "x$CC" = x/usr/ucb/cc ]; then
 499                   ## /usr/ucb/cc doesn't work;
 500                   ## we should find some other compiler that does work.
 501                   unset CC
 502                 fi
 503                 ;;
 504       *) ;;
 505     esac
 506   ;;
 507
 508   ## Vaxen.
 509   vax-dec-* )
 510     machine=vax
 511     case "${canonical}" in
 512       *-vms* )                                          opsys=vms ;;
 513       * )                                               unported=yes
 514     esac
 515   ;;
 516
 517   ## IA-64
 518   ia64*-*-linux* )
 519     machine=ia64 opsys=gnu-linux
 520   ;;
 521
 522   ## Intel 386 machines where we don't care about the manufacturer
 523   i[3456]86-*-* )
 524     machine=intel386
 525     case "${canonical}" in
 526       *-cygwin )                opsys=cygwin ;;
 527       *-darwin* )               opsys=darwin
 528                                 CPP="${CC-cc} -E -no-cpp-precomp"
 529                                 ;;
 530       *-linux-gnu* )            opsys=gnu-linux ;;
 531       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 532       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 533       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 534       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 535     esac
 536   ;;
 537
 538   ## m68k Linux-based GNU system
 539   m68k-*-linux-gnu* )
 540     machine=m68k opsys=gnu-linux
 541   ;;
 542
 543   ## Mips Linux-based GNU system
 544   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 545     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 546     machine=mips opsys=gnu-linux
 547   ;;
 548
 549   ## AMD x86-64 Linux-based GNU system
 550   x86_64-*-linux-gnu* )
 551     machine=amdx86-64 opsys=gnu-linux
 552   ;;
 553
 554   ## Tensilica Xtensa Linux-based GNU system
 555   xtensa*-*-linux-gnu* )
 556     machine=xtensa opsys=gnu-linux
 557     ;;
 558
 559   ## SuperH Linux-based GNU system
 560   sh[34]*-*-linux-gnu* )
 561     machine=sh3 opsys=gnu-linux
 562   ;;
 563
 564   * )
 565     unported=yes
 566   ;;
 567 esac
 568
 569 ### If the code above didn't choose an operating system, just choose
 570 ### an operating system based on the configuration name.  You really
 571 ### only want to use this when you have no idea what the right
 572 ### operating system is; if you know what operating systems a machine
 573 ### runs, it's cleaner to make it explicit in the case statement
 574 ### above.
 575 if test x"${opsys}" = x; then
 576   case "${canonical}" in
 577     *-gnu* )                            opsys=gnu ;;
 578     *-sysv4.2uw* )                      opsys=unixware ;;
 579     *-sysv5uw* )                        opsys=unixware ;;
 580     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 581     *-sysv4.1* | *-sysvr4.1* )
 582         NON_GNU_CPP=/usr/lib/cpp
 583         opsys=usg5-4 ;;
 584     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 585         if [ x$NON_GNU_CPP = x ]; then
 586           if [ -f /usr/ccs/lib/cpp ]; then
 587             NON_GNU_CPP=/usr/ccs/lib/cpp
 588           else
 589             NON_GNU_CPP=/lib/cpp
 590           fi
 591         fi
 592         opsys=usg5-4-2 ;;
 593     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 594     * )
 595       unported=yes
 596     ;;
 597   esac
 598 fi
 599
 600 ]
 601 dnl quotation ends
 602
 603 if test $unported = yes; then
 604   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 605 Check `etc/MACHINES' for recognized configuration names.])
 606 fi
 607
 608 machfile="m/${machine}.h"
 609 opsysfile="s/${opsys}.h"
 610
 611
 612 #### Choose a compiler.
 613 test -n "$CC" && cc_specified=yes
 614
 615 # Save the value of CFLAGS that the user specified.
 616 SPECIFIED_CFLAGS="$CFLAGS"
 617
 618 dnl Sets GCC=yes if using gcc.
 619 AC_PROG_CC
 620
 621 # On Suns, sometimes $CPP names a directory.
 622 if test -n "$CPP" && test -d "$CPP"; then
 623   CPP=
 624 fi
 625
 626 ## If not using gcc, and on Solaris, and no CPP specified, see if
 627 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 628 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 629  test x"$CPP" = x; then
 630   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 631   AC_CACHE_VAL(emacs_cv_sunpro_c,
 632   [AC_TRY_LINK([],
 633 [#ifndef __SUNPRO_C
 634 fail;
 635 #endif
 636 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 637   AC_MSG_RESULT($emacs_cv_sunpro_c)
 638
 639   if test x"$emacs_cv_sunpro_c" = xyes; then
 640     NON_GNU_CPP="$CC -E -Xs"
 641   fi
 642 fi
 643
 644 #### Some systems specify a CPP to use unless we are using GCC.
 645 #### Now that we know whether we are using GCC, we can decide whether
 646 #### to use that one.
 647 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 648 then
 649   CPP="$NON_GNU_CPP"
 650 fi
 651
 652 #### Some systems specify a CC to use unless we are using GCC.
 653 #### Now that we know whether we are using GCC, we can decide whether
 654 #### to use that one.
 655 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 656   test x$cc_specified != xyes
 657 then
 658   CC="$NON_GNU_CC"
 659 fi
 660
 661 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 662 then
 663   CC="$CC $GCC_TEST_OPTIONS"
 664 fi
 665
 666 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 667 then
 668   CC="$CC $NON_GCC_TEST_OPTIONS"
 669 fi
 670
 671 dnl checks for Unix variants
 672 AC_USE_SYSTEM_EXTENSIONS
 673
 674 ### Use -Wno-pointer-sign if the compiler supports it
 675 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 676 SAVE_CFLAGS="$CFLAGS"
 677 CFLAGS="$CFLAGS -Wno-pointer-sign"
 678 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 679 if test $has_option = yes; then
 680    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 681 fi
 682 AC_MSG_RESULT($has_option)
 683 CFLAGS="$SAVE_CFLAGS"
 684 unset has_option
 685 unset SAVE_CFLAGS
 686
 687 #### Some other nice autoconf tests.
 688
 689 dnl checks for programs
 690 AC_PROG_LN_S
 691 AC_PROG_CPP
 692 AC_PROG_INSTALL
 693 if test "x$RANLIB" = x; then
 694   AC_PROG_RANLIB
 695 fi
 696 AC_PATH_PROG(INSTALL_INFO, install-info)
 697 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 698 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 699 dnl Don't use GZIP, which is used by gzip for additional parameters.
 700 AC_PATH_PROG(GZIP_PROG, gzip)
 701
 702
 703 ## Need makeinfo >= 4.6 (?) to build the manuals.
 704 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 705 dnl By this stage, configure has already checked for egrep and set EGREP,
 706 dnl or exited with an error if no egrep was found.
 707 if test "$MAKEINFO" != "no" && \
 708   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 709    MAKEINFO=no
 710 fi
 711
 712 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 713 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 714 ## therefore in the category of "special tools" not normally required, which
 715 ## configure does not have to check for (eg autoconf itself).
 716 ## In a CVS checkout on the other hand, the manuals are not included.
 717 ## So makeinfo is a requirement to build from CVS, and configure
 718 ## should test for it as it does for any other build requirement.
 719 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 720 ## with pre-built manuals, from a CVS checkout.
 721 if test "$MAKEINFO" = "no"; then
 722   if test "x${with_makeinfo}" = "xno"; then
 723     MAKEINFO=off
 724   elif ! test -e $srcdir/info/emacs; then
 725     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 726 source tree does not seem to have pre-built manuals in the `info' directory.
 727 Either install a suitable version of makeinfo, or re-run configure
 728 with the `--without-makeinfo' option to build without the manuals.] )
 729   fi
 730 fi
 731
 732 dnl Add our options to ac_link now, after it is set up.
 733
 734 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 735 then
 736   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 737 fi
 738
 739 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 740 then
 741   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 742 fi
 743
 744 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 745 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 746 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 747 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 748 dnl if not built to support GNU ld.
 749
 750 late_LDFLAGS=$LDFLAGS
 751 if test "$GCC" = yes; then
 752   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 753 else
 754   LDFLAGS="$LDFLAGS -znocombreloc"
 755 fi
 756
 757 AC_MSG_CHECKING([for -znocombreloc])
 758 AC_LINK_IFELSE([main(){return 0;}],
 759   [AC_MSG_RESULT(yes)],
 760   LDFLAGS=$late_LDFLAGS
 761   [AC_MSG_RESULT(no)])
 762
 763 #### Extract some information from the operating system and machine files.
 764
 765 AC_CHECKING([the machine- and system-dependent files to find out
 766  - which libraries the lib-src programs will want, and
 767  - whether the GNU malloc routines are usable])
 768
 769 ### First figure out CFLAGS (which we use for running the compiler here)
 770 ### and REAL_CFLAGS (which we use for real compilation).
 771 ### The two are the same except on a few systems, where they are made
 772 ### different to work around various lossages.  For example,
 773 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 774 ### as implying static linking.
 775
 776 ### If the CFLAGS env var is specified, we use that value
 777 ### instead of the default.
 778
 779 ### It's not important that this name contain the PID; you can't run
 780 ### two configures in the same directory and have anything work
 781 ### anyway.
 782 tempcname="conftest.c"
 783
 784 echo '
 785 #include "'${srcdir}'/src/'${opsysfile}'"
 786 #include "'${srcdir}'/src/'${machfile}'"
 787 #ifndef LIBS_MACHINE
 788 #define LIBS_MACHINE
 789 #endif
 790 #ifndef LIBS_SYSTEM
 791 #define LIBS_SYSTEM
 792 #endif
 793 #ifndef C_SWITCH_SYSTEM
 794 #define C_SWITCH_SYSTEM
 795 #endif
 796 #ifndef C_SWITCH_MACHINE
 797 #define C_SWITCH_MACHINE
 798 #endif
 799 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 800 configure___ c_switch_system=C_SWITCH_SYSTEM
 801 configure___ c_switch_machine=C_SWITCH_MACHINE
 802
 803 #ifndef LIB_X11_LIB
 804 #define LIB_X11_LIB -lX11
 805 #endif
 806
 807 #ifndef LIBX11_SYSTEM
 808 #define LIBX11_SYSTEM
 809 #endif
 810 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 811
 812 #ifdef UNEXEC
 813 configure___ unexec=UNEXEC
 814 #else
 815 configure___ unexec=unexec.o
 816 #endif
 817
 818 #ifdef SYSTEM_MALLOC
 819 configure___ system_malloc=yes
 820 #else
 821 configure___ system_malloc=no
 822 #endif
 823
 824 #ifdef USE_MMAP_FOR_BUFFERS
 825 configure___ use_mmap_for_buffers=yes
 826 #else
 827 configure___ use_mmap_for_buffers=no
 828 #endif
 829
 830 #ifndef C_DEBUG_SWITCH
 831 #define C_DEBUG_SWITCH -g
 832 #endif
 833
 834 #ifndef C_OPTIMIZE_SWITCH
 835 #ifdef __GNUC__
 836 #define C_OPTIMIZE_SWITCH -O2
 837 #else
 838 #define C_OPTIMIZE_SWITCH -O
 839 #endif
 840 #endif
 841
 842 #ifndef C_WARNINGS_SWITCH
 843 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 844 #endif
 845
 846 #ifndef LD_SWITCH_MACHINE
 847 #define LD_SWITCH_MACHINE
 848 #endif
 849
 850 #ifndef LD_SWITCH_SYSTEM
 851 #define LD_SWITCH_SYSTEM
 852 #endif
 853
 854 #ifndef LD_SWITCH_X_SITE_AUX
 855 #define LD_SWITCH_X_SITE_AUX
 856 #endif
 857
 858 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 859 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 860
 861 #ifdef THIS_IS_CONFIGURE
 862
 863 /* Get the CFLAGS for tests in configure.  */
 864 #ifdef __GNUC__
 865 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 866 #else
 867 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 868 #endif
 869
 870 #else /* not THIS_IS_CONFIGURE */
 871
 872 /* Get the CFLAGS for real compilation.  */
 873 #ifdef __GNUC__
 874 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
 875 #else
 876 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 877 #endif
 878
 879 #endif /* not THIS_IS_CONFIGURE */
 880 ' > ${tempcname}
 881
 882 # The value of CPP is a quoted variable reference, so we need to do this
 883 # to get its actual value...
 884 CPP=`eval "echo $CPP"`
 885 [eval `${CPP} -Isrc ${tempcname} \
 886        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 887 if test "x$SPECIFIED_CFLAGS" = x; then
 888   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 889          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 890 else
 891   REAL_CFLAGS="$CFLAGS"
 892 fi]
 893 rm ${tempcname}
 894
 895 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 896
 897 ### Make sure subsequent tests use flags consistent with the build flags.
 898
 899 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 900   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 901 else
 902   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 903 fi
 904
 905 dnl For AC_FUNC_GETLOADAVG, at least:
 906 AC_CONFIG_LIBOBJ_DIR(src)
 907
 908 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 909 AC_SYS_LARGEFILE
 910
 911
 912 ### The standard library on x86-64 and s390x GNU/Linux distributions can
 913 ### be located in either /usr/lib64 or /usr/lib.
 914 ### In some rare cases, /usr/lib64 exists but does not contain the
 915 ### relevant files (bug#1287).  Hence test for crtn.o.
 916 case "${canonical}" in
 917   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
 918     if test -e /usr/lib64/crtn.o; then
 919       AC_DEFINE(HAVE_LIB64_DIR, 1,
 920         [Define to 1 if the directory /usr/lib64 exists.])
 921 fi
 922 esac
 923
 924 dnl This function defintion taken from Gnome 2.0
 925 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
 926 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
 927 dnl also defines GSTUFF_PKG_ERRORS on error
 928 AC_DEFUN([PKG_CHECK_MODULES], [
 929   succeeded=no
 930
 931   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 932
 933   if test "$PKG_CONFIG" = "no" ; then
 934      ifelse([$4], , [AC_MSG_ERROR([
 935       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
 936   else
 937      PKG_CONFIG_MIN_VERSION=0.9.0
 938      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
 939         AC_MSG_CHECKING(for $2)
 940
 941         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
 942             AC_MSG_RESULT(yes)
 943             succeeded=yes
 944
 945             AC_MSG_CHECKING($1_CFLAGS)
 946             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
 947             AC_MSG_RESULT($$1_CFLAGS)
 948
 949             AC_MSG_CHECKING($1_LIBS)
 950             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
 951             AC_MSG_RESULT($$1_LIBS)
 952         else
 953             AC_MSG_RESULT(no)
 954             $1_CFLAGS=""
 955             $1_LIBS=""
 956             ## If we have a custom action on failure, don't print errors, but
 957             ## do set a variable so people can do so.
 958             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
 959             ifelse([$4], ,echo $$1_PKG_ERRORS,)
 960         fi
 961
 962         AC_SUBST($1_CFLAGS)
 963         AC_SUBST($1_LIBS)
 964      else
 965         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
 966         echo "*** See http://www.freedesktop.org/software/pkgconfig"
 967      fi
 968   fi
 969
 970   if test $succeeded = yes; then
 971      ifelse([$3], , :, [$3])
 972   else
 973      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
 974   fi
 975 ])
 976
 977
 978 if test "${with_sound}" != "no"; then
 979   # Sound support for GNU/Linux and the free BSDs.
 980   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
 981   # Emulation library used on NetBSD.
 982   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
 983   AC_SUBST(LIBSOUND)
 984
 985   ALSA_REQUIRED=1.0.0
 986   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
 987   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
 988   if test $HAVE_ALSA = yes; then
 989     SAVE_CFLAGS="$CFLAGS"
 990     SAVE_LDFLAGS="$LDFLAGS"
 991     CFLAGS="$ALSA_CFLAGS $CFLAGS"
 992     LDFLAGS="$ALSA_LIBS $LDFLAGS"
 993     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
 994                     emacs_alsa_normal=yes,
 995                     emacs_alsa_normal=no)
 996     if test "$emacs_alsa_normal" != yes; then
 997       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
 998                      [snd_lib_error_set_handler (0);],
 999                      emacs_alsa_subdir=yes,
1000                      emacs_alsa_subdir=no)
1001       if test "$emacs_alsa_subdir" != yes; then
1002         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1003       fi
1004       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1005     fi
1006
1007     CFLAGS="$SAVE_CFLAGS"
1008     LDFLAGS="$SAVE_LDFLAGS"
1009     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1010     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1011     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1012   fi
1013   AC_SUBST(CFLAGS_SOUND)
1014 fi
1015
1016 dnl checks for header files
1017 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1018   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1019   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1020   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1021   sys/utsname.h pwd.h)
1022
1023 AC_MSG_CHECKING(if personality LINUX32 can be set)
1024 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1025                emacs_cv_personality_linux32=yes,
1026                emacs_cv_personality_linux32=no)
1027 AC_MSG_RESULT($emacs_cv_personality_linux32)
1028
1029 if test $emacs_cv_personality_linux32 = yes; then
1030   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1031             [Define to 1 if personality LINUX32 can be set.])
1032 fi
1033
1034 dnl On Solaris 8 there's a compilation warning for term.h because
1035 dnl it doesn't define `bool'.
1036 AC_CHECK_HEADERS(term.h, , , -)
1037 AC_HEADER_STDC
1038 AC_HEADER_TIME
1039 AC_CHECK_DECLS([sys_siglist])
1040 if test $ac_cv_have_decl_sys_siglist != yes; then
1041   # For Tru64, at least:
1042   AC_CHECK_DECLS([__sys_siglist])
1043   if test $ac_cv_have_decl___sys_siglist = yes; then
1044     AC_DEFINE(sys_siglist, __sys_siglist,
1045               [Define to any substitute for sys_siglist.])
1046   fi
1047 fi
1048 AC_HEADER_SYS_WAIT
1049
1050 dnl Some systems have utime.h but don't declare the struct anyplace.
1051 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1052 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1053 #include <sys/time.h>
1054 #include <time.h>
1055 #else
1056 #ifdef HAVE_SYS_TIME_H
1057 #include <sys/time.h>
1058 #else
1059 #include <time.h>
1060 #endif
1061 #endif
1062 #ifdef HAVE_UTIME_H
1063 #include <utime.h>
1064 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1065   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1066 if test $emacs_cv_struct_utimbuf = yes; then
1067   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1068 fi
1069
1070 dnl checks for typedefs
1071 AC_TYPE_SIGNAL
1072
1073 dnl Check for speed_t typedef.
1074 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1075   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1076     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1077 if test $emacs_cv_speed_t = yes; then
1078   AC_DEFINE(HAVE_SPEED_T, 1,
1079            [Define to 1 if `speed_t' is declared by <termios.h>.])
1080 fi
1081
1082 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1083 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1084 #include <sys/time.h>
1085 #include <time.h>
1086 #else
1087 #ifdef HAVE_SYS_TIME_H
1088 #include <sys/time.h>
1089 #else
1090 #include <time.h>
1091 #endif
1092 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1093   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1094 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1095 if test $emacs_cv_struct_timeval = yes; then
1096   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1097 fi
1098
1099 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1100 AC_TRY_COMPILE([#include <math.h>],
1101 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1102   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1103 HAVE_EXCEPTION=$emacs_cv_struct_exception
1104 if test $emacs_cv_struct_exception != yes; then
1105   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1106 fi
1107
1108 AC_CHECK_HEADERS(sys/socket.h)
1109 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1110 #if HAVE_SYS_SOCKET_H
1111 #include <sys/socket.h>
1112 #endif])
1113
1114 dnl checks for structure members
1115 AC_STRUCT_TM
1116 AC_STRUCT_TIMEZONE
1117 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1118                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1119                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1120                 [#include <time.h>])
1121 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1122                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1123                   struct ifreq.ifr_addr], , ,
1124                  [AC_INCLUDES_DEFAULT
1125 #if HAVE_SYS_SOCKET_H
1126 #include <sys/socket.h>
1127 #endif
1128 #if HAVE_NET_IF_H
1129 #include <net/if.h>
1130 #endif])
1131
1132 dnl checks for compiler characteristics
1133
1134 dnl Testing __STDC__ to determine prototype support isn't good enough.
1135 dnl DEC C, for instance, doesn't define it with default options, and
1136 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1137 dnl and void *.
1138 AC_C_PROTOTYPES
1139 AC_C_VOLATILE
1140 AC_C_CONST
1141 dnl This isn't useful because we can't turn on use of `inline' unless
1142 dnl the compiler groks `extern inline'.
1143 dnl AC_C_INLINE
1144 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1145   [AC_TRY_COMPILE(, [void * foo;],
1146                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1147 if test $emacs_cv_void_star = yes; then
1148   AC_DEFINE(POINTER_TYPE, void)
1149 else
1150   AC_DEFINE(POINTER_TYPE, char)
1151 fi
1152 AH_TEMPLATE(POINTER_TYPE,
1153             [Define as `void' if your compiler accepts `void *'; otherwise
1154              define as `char'.])dnl
1155
1156
1157
1158 dnl This could be used for targets which can have both byte sexes.
1159 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1160 dnl AC_C_BIGENDIAN
1161
1162 dnl check for Make feature
1163 AC_PROG_MAKE_SET
1164
1165 dnl checks for operating system services
1166 AC_SYS_LONG_FILE_NAMES
1167
1168 #### Choose a window system.
1169
1170 AC_PATH_X
1171 if test "$no_x" = yes; then
1172   window_system=none
1173 else
1174   window_system=x11
1175 fi
1176
1177 ## Workaround for bug in autoconf <= 2.62.
1178 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1179 ## No need to do anything special for these standard directories.
1180 ## This is an experiment, take it out if it causes problems.
1181 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1182
1183    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1184
1185 fi
1186
1187 if test "${x_libraries}" != NONE; then
1188   if test -n "${x_libraries}"; then
1189     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1190     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1191   fi
1192   x_default_search_path=""
1193   x_search_path=${x_libraries}
1194   if test -z "${x_search_path}"; then
1195     x_search_path=/usr/lib
1196   fi
1197   for x_library in `echo ${x_search_path}: | \
1198                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1199     x_search_path="\
1200 ${x_library}/X11/%L/%T/%N%C%S:\
1201 ${x_library}/X11/%l/%T/%N%C%S:\
1202 ${x_library}/X11/%T/%N%C%S:\
1203 ${x_library}/X11/%L/%T/%N%S:\
1204 ${x_library}/X11/%l/%T/%N%S:\
1205 ${x_library}/X11/%T/%N%S"
1206     if test x"${x_default_search_path}" = x; then
1207       x_default_search_path=${x_search_path}
1208     else
1209       x_default_search_path="${x_search_path}:${x_default_search_path}"
1210     fi
1211   done
1212 fi
1213 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1214   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1215 fi
1216
1217 if test x"${x_includes}" = x; then
1218   bitmapdir=/usr/include/X11/bitmaps
1219 else
1220   # accumulate include directories that have X11 bitmap subdirectories
1221   bmd_acc="dummyval"
1222   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1223     if test -d "${bmd}/X11/bitmaps"; then
1224       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1225     fi
1226     if test -d "${bmd}/bitmaps"; then
1227       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1228     fi
1229   done
1230   if test ${bmd_acc} != "dummyval"; then
1231     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1232   fi
1233 fi
1234
1235 HAVE_NS=no
1236 NS_IMPL_COCOA=no
1237 NS_IMPL_GNUSTEP=no
1238 tmp_CPPFLAGS="$CPPFLAGS"
1239 tmp_CFLAGS="$CFLAGS"
1240 CPPFLAGS="$CPPFLAGS -x objective-c"
1241 CFLAGS="$CFLAGS -x objective-c"
1242 if test "${with_ns}" != no; then
1243   if test "${opsys}" = darwin; then
1244      NS_IMPL_COCOA=yes
1245      ns_appdir=`pwd`/nextstep/Emacs.app
1246      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1247      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1248      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1249   elif test -f $GNUSTEP_CONFIG_FILE; then
1250      NS_IMPL_GNUSTEP=yes
1251      ns_appdir=`pwd`/nextstep/Emacs.app
1252      ns_appbindir=`pwd`/nextstep/Emacs.app
1253      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1254      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1255      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1256      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1257      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1258      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1259      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1260      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1261      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1262      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1263   fi
1264   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1265                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1266   files are missing or cannot be compiled.])])
1267   NS_HAVE_NSINTEGER=yes
1268   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1269                                      [NSInteger i;])],
1270                     ns_have_nsinteger=yes,
1271                     ns_have_nsinteger=no)
1272   if test $ns_have_nsinteger = no; then
1273     NS_HAVE_NSINTEGER=no
1274   fi
1275 fi
1276 if test "${HAVE_NS}" = yes; then
1277   window_system=nextstep
1278   with_xft=no
1279   with_freetype=no
1280   # set up packaging dirs
1281   exec_prefix=${ns_appbindir}
1282   libexecdir=${ns_appbindir}/libexec
1283   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1284      prefix=${ns_appresdir}
1285   fi
1286 fi
1287 CFLAGS="$tmp_CFLAGS"
1288 CPPFLAGS="$tmp_CPPFLAGS"
1289
1290 case "${window_system}" in
1291   x11 )
1292     HAVE_X_WINDOWS=yes
1293     HAVE_X11=yes
1294     case "${with_x_toolkit}" in
1295       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1296       motif ) USE_X_TOOLKIT=MOTIF ;;
1297       gtk ) with_gtk=yes
1298 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1299 dnl USE_X_TOOLKIT is set.
1300             USE_X_TOOLKIT=none ;;
1301       no ) USE_X_TOOLKIT=none ;;
1302 dnl If user did not say whether to use a toolkit, make this decision later:
1303 dnl use the toolkit if we have gtk, or X11R5 or newer.
1304       * ) USE_X_TOOLKIT=maybe ;;
1305     esac
1306   ;;
1307   nextstep | none )
1308     HAVE_X_WINDOWS=no
1309     HAVE_X11=no
1310     USE_X_TOOLKIT=none
1311   ;;
1312 esac
1313
1314 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1315    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1316    if test "$HAVE_XSERVER" = true ||
1317       test -n "$DISPLAY" ||
1318       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1319         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1320 were found.  You should install the relevant development files for X
1321 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1322 sure you have development files for image handling, i.e.
1323 tiff, gif, jpeg, png and xpm.
1324 If you are sure you want Emacs compiled without X window support, pass
1325   --without-x
1326 to configure.])
1327    fi
1328 fi
1329
1330 ### If we're using X11, we should use the X menu package.
1331 HAVE_MENUS=no
1332 case ${HAVE_X11} in
1333   yes ) HAVE_MENUS=yes ;;
1334 esac
1335
1336 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1337 # Assume not, until told otherwise.
1338 GNU_MALLOC=yes
1339 doug_lea_malloc=yes
1340 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1341 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1342 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1343                emacs_cv_var___after_morecore_hook,
1344 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1345   emacs_cv_var___after_morecore_hook=yes,
1346   emacs_cv_var___after_morecore_hook=no)])
1347 if test $emacs_cv_var___after_morecore_hook = no; then
1348   doug_lea_malloc=no
1349 fi
1350 if test "${system_malloc}" = "yes"; then
1351   GNU_MALLOC=no
1352   GNU_MALLOC_reason="
1353     (The GNU allocators don't work with this system configuration.)"
1354 fi
1355 if test "$doug_lea_malloc" = "yes" ; then
1356   if test "$GNU_MALLOC" = yes ; then
1357     GNU_MALLOC_reason="
1358       (Using Doug Lea's new malloc from the GNU C Library.)"
1359   fi
1360   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1361             [Define to 1 if you are using the GNU C Library.])
1362 fi
1363
1364 if test x"${REL_ALLOC}" = x; then
1365   REL_ALLOC=${GNU_MALLOC}
1366 fi
1367
1368 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1369 dnl the system configuration file (s/*.h) to turn the use of mmap
1370 dnl in the relocating allocator on.
1371
1372 AC_FUNC_MMAP
1373 if test $use_mmap_for_buffers = yes; then
1374   REL_ALLOC=no
1375 fi
1376
1377 LIBS="$libsrc_libs $LIBS"
1378
1379 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1380 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1381 AC_CHECK_LIB(dnet, dnet_ntoa)
1382 dnl This causes -lresolv to get used in subsequent tests,
1383 dnl which causes failures on some systems such as HPUX 9.
1384 dnl AC_CHECK_LIB(resolv, gethostbyname)
1385
1386 dnl FIXME replace main with a function we actually want from this library.
1387 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1388
1389 AC_CHECK_LIB(pthreads, cma_open)
1390
1391 dnl Check for need for bigtoc support on IBM AIX
1392
1393 case ${host_os} in
1394 aix*)
1395   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1396     case $GCC in
1397     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1398     *) gdb_cv_bigtoc=-bbigtoc ;;
1399     esac
1400
1401     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1402     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1403   ])
1404   ;;
1405 esac
1406
1407 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1408 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1409 # REAL_CPPFLAGS later on.
1410
1411 REAL_CPPFLAGS="$CPPFLAGS"
1412
1413 if test "${HAVE_X11}" = "yes"; then
1414   DEFS="$C_SWITCH_X_SITE $DEFS"
1415   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1416   LIBS="$LIBX $LIBS"
1417   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1418   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1419
1420   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1421   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1422   # but it's more convenient here to set LD_RUN_PATH
1423   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1424   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1425     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1426     export LD_RUN_PATH
1427   fi
1428
1429   if test "${opsys}" = "gnu-linux"; then
1430     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1431     AC_TRY_LINK([],
1432      [XOpenDisplay ("foo");],
1433      [xlinux_first_failure=no],
1434      [xlinux_first_failure=yes])
1435     if test "${xlinux_first_failure}" = "yes"; then
1436       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1437       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1438       OLD_CPPFLAGS="$CPPFLAGS"
1439       OLD_LIBS="$LIBS"
1440       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1441       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1442       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1443       LIBS="$LIBS -b i486-linuxaout"
1444       AC_TRY_LINK([],
1445        [XOpenDisplay ("foo");],
1446        [xlinux_second_failure=no],
1447        [xlinux_second_failure=yes])
1448       if test "${xlinux_second_failure}" = "yes"; then
1449         # If we get the same failure with -b, there is no use adding -b.
1450         # So take it out.  This plays safe.
1451         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1452         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1453         CPPFLAGS="$OLD_CPPFLAGS"
1454         LIBS="$OLD_LIBS"
1455         AC_MSG_RESULT(no)
1456       else
1457         AC_MSG_RESULT(yes)
1458       fi
1459     else
1460       AC_MSG_RESULT(no)
1461     fi
1462   fi
1463
1464   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1465   # header files included from there.
1466   AC_MSG_CHECKING(for Xkb)
1467   AC_TRY_LINK([#include <X11/Xlib.h>
1468 #include <X11/XKBlib.h>],
1469         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1470         emacs_xkb=yes, emacs_xkb=no)
1471   AC_MSG_RESULT($emacs_xkb)
1472   if test $emacs_xkb = yes; then
1473     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1474   fi
1475
1476   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1477 XScreenNumberOfScreen XSetWMProtocols)
1478 fi
1479
1480 if test "${window_system}" = "x11"; then
1481   AC_MSG_CHECKING(X11 version 6)
1482   AC_CACHE_VAL(emacs_cv_x11_version_6,
1483   [AC_TRY_LINK([#include <X11/Xlib.h>],
1484 [#if XlibSpecificationRelease < 6
1485 fail;
1486 #endif
1487 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1488   if test $emacs_cv_x11_version_6 = yes; then
1489     AC_MSG_RESULT(6 or newer)
1490     AC_DEFINE(HAVE_X11R6, 1,
1491               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1492   else
1493     AC_MSG_RESULT(before 6)
1494   fi
1495 fi
1496
1497
1498 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1499 HAVE_RSVG=no
1500 if test "${HAVE_X11}" = "yes"; then
1501   if test "${with_rsvg}" != "no"; then
1502     RSVG_REQUIRED=2.0.0
1503     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1504
1505     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1506     AC_SUBST(RSVG_CFLAGS)
1507     AC_SUBST(RSVG_LIBS)
1508
1509     if test ".${RSVG_CFLAGS}" != "."; then
1510       HAVE_RSVG=yes
1511       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1512       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1513       LIBS="$RSVG_LIBS $LIBS"
1514     fi
1515   fi
1516 fi
1517
1518
1519 HAVE_GTK=no
1520 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1521   GLIB_REQUIRED=2.6
1522   GTK_REQUIRED=2.6
1523   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1524
1525   dnl Checks for libraries.
1526   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1527   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1528      AC_MSG_ERROR($GTK_PKG_ERRORS)
1529   fi
1530 fi
1531
1532
1533 if test x"$pkg_check_gtk" = xyes; then
1534
1535   AC_SUBST(GTK_CFLAGS)
1536   AC_SUBST(GTK_LIBS)
1537   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1538   CFLAGS="$CFLAGS $GTK_CFLAGS"
1539   LIBS="$GTK_LIBS $LIBS"
1540   dnl Try to compile a simple GTK program.
1541   GTK_COMPILES=no
1542   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1543   if test "${GTK_COMPILES}" != "yes"; then
1544     if test "$USE_X_TOOLKIT" != "maybe"; then
1545       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1546     fi
1547   else
1548     HAVE_GTK=yes
1549     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1550     USE_X_TOOLKIT=none
1551     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1552       :
1553     else
1554       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1555        closing open displays.  This is no problem if you just use
1556        one display, but if you use more than one and close one of them
1557        Emacs may crash.]])
1558       sleep 3
1559     fi
1560   fi
1561
1562 fi
1563
1564
1565 if test "${HAVE_GTK}" = "yes"; then
1566
1567   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1568   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1569   if test "$with_toolkit_scroll_bars" != no; then
1570     with_toolkit_scroll_bars=yes
1571   fi
1572
1573   dnl  Check if we can use multiple displays with this GTK version.
1574   dnl  If gdk_display_open exists, assume all others are there also.
1575   HAVE_GTK_MULTIDISPLAY=no
1576   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1577   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1578     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1579               [Define to 1 if GTK can handle more than one display.])
1580   fi
1581
1582   dnl  Check if we have the old file selection dialog.
1583   dnl  If gdk_display_open exists, assume all others are there also.
1584   HAVE_GTK_FILE_SELECTION=no
1585   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1586
1587   dnl  Check if we have the new file chooser dialog
1588   dnl  If gdk_display_open exists, assume all others are there also.
1589   HAVE_GTK_FILE_CHOOSER=no
1590   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1591
1592   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1593      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1594     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1595               [Define to 1 if GTK has both file selection and chooser dialog.])
1596   fi
1597
1598   dnl Check if pthreads are available.  Emacs only needs this when using
1599   dnl gtk_file_chooser under Gnome.
1600   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1601     HAVE_GTK_AND_PTHREAD=no
1602     AC_CHECK_HEADERS(pthread.h)
1603     if test "$ac_cv_header_pthread_h"; then
1604       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1605     fi
1606     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1607       case "${canonical}" in
1608         *-hpux*) ;;
1609         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1610       esac
1611       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1612                [Define to 1 if you have GTK and pthread (-lpthread).])
1613     fi
1614   fi
1615 fi
1616
1617 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1618 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1619 dnl also not configured.
1620 HAVE_DBUS=no
1621 if test "${with_dbus}" = "yes"; then
1622    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1623    if test "$HAVE_DBUS" = yes; then
1624       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1625    fi
1626 fi
1627
1628 dnl Do not put whitespace before the #include statements below.
1629 dnl Older compilers (eg sunos4 cc) choke on it.
1630 HAVE_XAW3D=no
1631 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1632   if test "$with_xaw3d" != no; then
1633     AC_MSG_CHECKING(for xaw3d)
1634     AC_CACHE_VAL(emacs_cv_xaw3d,
1635     [AC_TRY_LINK([
1636 #include <X11/Intrinsic.h>
1637 #include <X11/Xaw3d/Simple.h>],
1638       [],
1639       emacs_cv_xaw3d=yes,
1640       emacs_cv_xaw3d=no)])
1641   else
1642     emacs_cv_xaw3d=no
1643   fi
1644   if test $emacs_cv_xaw3d = yes; then
1645     AC_MSG_RESULT([yes; using Lucid toolkit])
1646     USE_X_TOOLKIT=LUCID
1647     HAVE_XAW3D=yes
1648     AC_DEFINE(HAVE_XAW3D, 1,
1649               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1650   else
1651     AC_MSG_RESULT(no)
1652     AC_MSG_CHECKING(for libXaw)
1653     AC_CACHE_VAL(emacs_cv_xaw,
1654     [AC_TRY_LINK([
1655 #include <X11/Intrinsic.h>
1656 #include <X11/Xaw/Simple.h>],
1657       [],
1658       emacs_cv_xaw=yes,
1659       emacs_cv_xaw=no)])
1660     if test $emacs_cv_xaw = yes; then
1661       AC_MSG_RESULT([yes; using Lucid toolkit])
1662       USE_X_TOOLKIT=LUCID
1663     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1664       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1665     else
1666       AC_MSG_RESULT([no; do not use toolkit by default])
1667       USE_X_TOOLKIT=none
1668     fi
1669   fi
1670 fi
1671
1672 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1673
1674 if test "${USE_X_TOOLKIT}" != "none"; then
1675   AC_MSG_CHECKING(X11 toolkit version)
1676   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1677   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1678 [#if XtSpecificationRelease < 6
1679 fail;
1680 #endif
1681 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1682   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1683   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1684     AC_MSG_RESULT(6 or newer)
1685     AC_DEFINE(HAVE_X11XTR6, 1,
1686               [Define to 1 if you have the X11R6 or newer version of Xt.])
1687   else
1688     AC_MSG_RESULT(before 6)
1689   fi
1690
1691 dnl If using toolkit, check whether libXmu.a exists.
1692 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1693   OLDLIBS="$LIBS"
1694   if test x$HAVE_X11XTR6 = xyes; then
1695     LIBS="-lXt -lSM -lICE $LIBS"
1696   else
1697     LIBS="-lXt $LIBS"
1698   fi
1699   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1700   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1701 fi
1702
1703 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1704 if test "${HAVE_X11}" = "yes"; then
1705   if test "${USE_X_TOOLKIT}" != "none"; then
1706     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1707   fi
1708 fi
1709
1710 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1711   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1712   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1713     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1714 int x = 5;
1715 #else
1716 Motif version prior to 2.1.
1717 #endif],
1718     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1719   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1720   if test $emacs_cv_motif_version_2_1 = yes; then
1721     HAVE_LIBXP=no
1722     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1723               [Define to 1 if you have Motif 2.1 or newer.])
1724     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1725     if test ${HAVE_LIBXP} = yes; then
1726       AC_DEFINE(HAVE_LIBXP, 1,
1727                 [Define to 1 if you have the Xp library (-lXp).])
1728     fi
1729   else
1730     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1731     # We put this in CFLAGS temporarily to precede other -I options
1732     # that might be in CFLAGS temporarily.
1733     # We put this in CPPFLAGS where it precedes the other -I options.
1734     OLD_CPPFLAGS=$CPPFLAGS
1735     OLD_CFLAGS=$CFLAGS
1736     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1737     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1738     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1739       [int x = 5;],
1740       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1741     if test $emacs_cv_lesstif = yes; then
1742       # Make sure this -I option remains in CPPFLAGS after it is set
1743       # back to REAL_CPPFLAGS.
1744       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1745       # have those other -I options anyway.  Ultimately, having this
1746       # directory ultimately in CPPFLAGS will be enough.
1747       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1748       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1749     else
1750       CFLAGS=$OLD_CFLAGS
1751       CPPFLAGS=$OLD_CPPFLAGS
1752     fi
1753   fi
1754 fi
1755
1756 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1757 dnl using Motif or Xaw3d is available, and unless
1758 dnl --with-toolkit-scroll-bars=no was specified.
1759
1760 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1761             [Define to 1 if we should use toolkit scroll bars.])dnl
1762 USE_TOOLKIT_SCROLL_BARS=no
1763 if test "${with_toolkit_scroll_bars}" != "no"; then
1764   if test "${USE_X_TOOLKIT}" != "none"; then
1765     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1766       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1767       HAVE_XAW3D=no
1768       USE_TOOLKIT_SCROLL_BARS=yes
1769     elif test "${HAVE_XAW3D}" = "yes"; then
1770       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1771       USE_TOOLKIT_SCROLL_BARS=yes
1772     fi
1773   elif test "${HAVE_GTK}" = "yes"; then
1774     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1775     USE_TOOLKIT_SCROLL_BARS=yes
1776   elif test "${HAVE_NS}" = "yes"; then
1777     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1778     USE_TOOLKIT_SCROLL_BARS=yes
1779   fi
1780 fi
1781
1782 dnl See if XIM is available.
1783 AC_TRY_COMPILE([
1784           #include <X11/Xlib.h>
1785           #include <X11/Xresource.h>],
1786          [XIMProc  callback;],
1787          [HAVE_XIM=yes
1788          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1789          HAVE_XIM=no)
1790
1791 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1792
1793 if test "${with_xim}" != "no"; then
1794   AC_DEFINE(USE_XIM, 1,
1795             [Define to 1 if we should use XIM, if it is available.])
1796 fi
1797
1798
1799 if test "${HAVE_XIM}" != "no"; then
1800   late_CFLAGS=$CFLAGS
1801   if test "$GCC" = yes; then
1802     CFLAGS="$CFLAGS --pedantic-errors"
1803   fi
1804   AC_TRY_COMPILE([
1805 #include <X11/Xlib.h>
1806 #include <X11/Xresource.h>],
1807 [Display *display;
1808 XrmDatabase db;
1809 char *res_name;
1810 char *res_class;
1811 XIMProc  callback;
1812 XPointer *client_data;
1813 #ifndef __GNUC__
1814 /* If we're not using GCC, it's probably not XFree86, and this is
1815    probably right, but we can't use something like --pedantic-errors.  */
1816 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1817                                            char*, XIMProc, XPointer*);
1818 #endif
1819 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1820    client_data);],
1821     [emacs_cv_arg6_star=yes])
1822   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1823          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1824 either XPointer or XPointer*.])dnl
1825   if test "$emacs_cv_arg6_star" = yes; then
1826     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1827   else
1828     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1829   fi
1830   CFLAGS=$late_CFLAGS
1831 fi
1832
1833 ### Start of font-backend section.
1834 PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
1835 test "${HAVE_FC}" = "no" && with_freetype=no
1836
1837 ## Use -lXft if available, unless `--with-freetype=no' nor `--with-xft=no'.
1838 HAVE_XFT=maybe
1839 if test "x${with_freetype}" = "xno" || test "x${with_x}" = "xno"; then
1840   with_xft="no";
1841 fi
1842 if test "x${with_xft}" != "xno"; then
1843
1844   PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1845   if test "$HAVE_XFT" != no; then
1846     OLD_CPPFLAGS="$CPPFLAGS"
1847     OLD_CFLAGS="$CFLAGS"
1848     OLD_LIBS="$LIBS"
1849     CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1850     CFLAGS="$CFLAGS $XFT_CFLAGS"
1851     LIBS="$XFT_LIBS $LIBS"
1852     AC_CHECK_HEADER(X11/Xft/Xft.h,
1853       AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1854
1855     if test "${HAVE_XFT}" = "yes"; then
1856       AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1857         AC_SUBST(XFT_LIBS)
1858       C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1859     else
1860       CPPFLAGS="$OLD_CPPFLAGS"
1861       CFLAGS="$OLD_CFLAGS"
1862       LIBS="$OLD_LIBS"
1863     fi                        # "${HAVE_XFT}" = "yes"
1864   fi                          # "$HAVE_XFT" != no
1865 fi                            # "x${with_xft}" != "xno"
1866
1867 dnl For the "Does Emacs use" message at the end.
1868 if test "$HAVE_XFT" != "yes"; then
1869    HAVE_XFT=no
1870 fi
1871
1872
1873 HAVE_FREETYPE=no
1874 ### Use -lfreetype if available, unless `--with-freetype=no'.
1875 if test "${HAVE_XFT}" = "yes"; then
1876   dnl As we use Xft, we anyway use freetype.
1877   dnl In this case, there's no need of additional CFLAGS and LIBS.
1878   HAVE_FREETYPE=yes
1879   FONTCONFIG_CFLAGS=
1880   FONTCONFIG_LIBS=
1881 elif test "x${with_freetype}" != "xno" && test "x${with_x}" != "xno"; then
1882
1883   PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes, HAVE_FREETYPE=no)
1884 fi
1885
1886 HAVE_LIBOTF=no
1887 if test "${HAVE_FREETYPE}" = "yes"; then
1888   AC_DEFINE(HAVE_FREETYPE, 1,
1889             [Define to 1 if using the freetype and fontconfig libraries.])
1890   if test "${with_libotf}" != "no"; then
1891     PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
1892                       HAVE_LIBOTF=no)
1893     if test "$HAVE_LIBOTF" = "yes"; then
1894       AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
1895       AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
1896                    HAVE_OTF_GET_VARIATION_GLYPHS=yes,
1897                    HAVE_OTF_GET_VARIATION_GLYPHS=no)
1898       if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
1899         AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
1900                   [Define to 1 if libotf has OTF_get_variation_glyphs.])
1901       fi
1902     fi
1903   fi
1904 dnl FIXME should there be an error if HAVE_FREETYPE != yes?
1905 dnl Does the new font backend require it, or can it work without it?
1906 fi
1907
1908 HAVE_M17N_FLT=no
1909 if test "${HAVE_LIBOTF}" = yes; then
1910   if test "${with_m17n_flt}" != "no"; then
1911     PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
1912     if test "$HAVE_M17N_FLT" = "yes"; then
1913       AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
1914     fi
1915   fi
1916 fi
1917
1918 AC_SUBST(FREETYPE_CFLAGS)
1919 AC_SUBST(FREETYPE_LIBS)
1920 AC_SUBST(FONTCONFIG_CFLAGS)
1921 AC_SUBST(FONTCONFIG_LIBS)
1922 AC_SUBST(LIBOTF_CFLAGS)
1923 AC_SUBST(LIBOTF_LIBS)
1924 AC_SUBST(M17N_FLT_CFLAGS)
1925 AC_SUBST(M17N_FLT_LIBS)
1926
1927 ### End of font-backend section.
1928
1929 ### Use -lXpm if available, unless `--with-xpm=no'.
1930 HAVE_XPM=no
1931 if test "${HAVE_X11}" = "yes"; then
1932   if test "${with_xpm}" != "no"; then
1933     AC_CHECK_HEADER(X11/xpm.h,
1934       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
1935     if test "${HAVE_XPM}" = "yes"; then
1936       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
1937       AC_EGREP_CPP(no_return_alloc_pixels,
1938       [#include "X11/xpm.h"
1939 #ifndef XpmReturnAllocPixels
1940 no_return_alloc_pixels
1941 #endif
1942       ], HAVE_XPM=no, HAVE_XPM=yes)
1943
1944       if test "${HAVE_XPM}" = "yes"; then
1945         AC_MSG_RESULT(yes)
1946       else
1947         AC_MSG_RESULT(no)
1948       fi
1949     fi
1950   fi
1951
1952   if test "${HAVE_XPM}" = "yes"; then
1953     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
1954   fi
1955 fi
1956
1957 ### Use -ljpeg if available, unless `--with-jpeg=no'.
1958 HAVE_JPEG=no
1959 if test "${HAVE_X11}" = "yes"; then
1960   if test "${with_jpeg}" != "no"; then
1961     dnl Checking for jpeglib.h can lose because of a redefinition of
1962     dnl  HAVE_STDLIB_H.
1963     AC_CHECK_HEADER(jerror.h,
1964       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
1965   fi
1966
1967   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
1968   if test "${HAVE_JPEG}" = "yes"; then
1969     AC_DEFINE(HAVE_JPEG)
1970     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
1971         [#include <jpeglib.h>
1972          version=JPEG_LIB_VERSION
1973 ],
1974         [AC_DEFINE(HAVE_JPEG)],
1975         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
1976         HAVE_JPEG=no])
1977   fi
1978 fi
1979
1980 ### Use -lpng if available, unless `--with-png=no'.
1981 HAVE_PNG=no
1982 if test "${HAVE_X11}" = "yes"; then
1983   if test "${with_png}" != "no"; then
1984     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
1985     # in /usr/include/libpng.
1986     AC_CHECK_HEADERS(png.h libpng/png.h)
1987     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
1988       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
1989     fi
1990   fi
1991
1992   if test "${HAVE_PNG}" = "yes"; then
1993     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
1994   fi
1995 fi
1996
1997 ### Use -ltiff if available, unless `--with-tiff=no'.
1998 HAVE_TIFF=no
1999 if test "${HAVE_X11}" = "yes"; then
2000   if test "${with_tiff}" != "no"; then
2001     AC_CHECK_HEADER(tiffio.h,
2002       [tifflibs="-lz -lm"
2003       # At least one tiff package requires the jpeg library.
2004       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2005       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2006   fi
2007
2008   if test "${HAVE_TIFF}" = "yes"; then
2009     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2010   fi
2011 fi
2012
2013 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2014 HAVE_GIF=no
2015 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2016   AC_CHECK_HEADER(gif_lib.h,
2017 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2018 # Earlier versions can crash Emacs.
2019     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2020
2021   if test "$HAVE_GIF" = yes; then
2022       ac_gif_lib_name="-lgif"
2023   fi
2024
2025 # If gif_lib.h but no libgif, try libungif.
2026   if test x"$try_libungif" = xyes; then
2027     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2028
2029     if test "$HAVE_GIF" = yes; then
2030       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2031       ac_gif_lib_name="-lungif"
2032     fi
2033   fi
2034
2035   if test "${HAVE_GIF}" = "yes"; then
2036     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2037   fi
2038 fi
2039
2040 dnl Check for required libraries.
2041 if test "${HAVE_X11}" = "yes"; then
2042   MISSING=""
2043   WITH_NO=""
2044   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2045     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2046   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2047     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2048   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2049     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2050   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2051     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2052   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2053     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2054
2055   if test "X${MISSING}" != X; then
2056     AC_MSG_ERROR([The following required libraries were not found:
2057     $MISSING
2058 Maybe some development libraries/packages are missing?
2059 If you don't want to link with them give
2060     $WITH_NO
2061 as options to configure])
2062   fi
2063 fi
2064
2065 ### Use -lgpm if available, unless `--with-gpm=no'.
2066 HAVE_GPM=no
2067 if test "${with_gpm}" != "no"; then
2068   AC_CHECK_HEADER(gpm.h,
2069     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2070 fi
2071
2072 if test "${HAVE_GPM}" = "yes"; then
2073   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2074 fi
2075
2076 dnl Check for malloc/malloc.h on darwin
2077 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2078
2079 ### Use NeXTstep API to implement GUI.
2080 if test "${HAVE_NS}" = "yes"; then
2081   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2082   if test "${NS_IMPL_COCOA}" = "yes"; then
2083     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2084     GNU_OBJC_CFLAGS=
2085     LIB_SRC_EXTRA_INSTALLABLES=mac-fix-env
2086   fi
2087   if test "${EN_COCOA_EXPERIMENTAL_CTRL_G}" = "yes"; then
2088     AC_DEFINE(COCOA_EXPERIMENTAL_CTRL_G, 1, [Define to 1 if you are trying experimental enhanced Ctrl-g support using NS windowing under MacOS X.])
2089   fi
2090   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2091     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2092     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2093   fi
2094   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2095     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2096   fi
2097   # We also have mouse menus.
2098   HAVE_MENUS=yes
2099 fi
2100
2101
2102 ### Use session management (-lSM -lICE) if available
2103 HAVE_X_SM=no
2104 if test "${HAVE_X11}" = "yes"; then
2105   AC_CHECK_HEADER(X11/SM/SMlib.h,
2106     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2107
2108   if test "${HAVE_X_SM}" = "yes"; then
2109     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2110     case "$LIBS" in
2111       *-lSM*) ;;
2112       *)      LIBS="-lSM -lICE $LIBS" ;;
2113     esac
2114   fi
2115 fi
2116
2117 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2118 AC_CACHE_CHECK(whether netdb declares h_errno,
2119                emacs_cv_netdb_declares_h_errno,
2120 [AC_TRY_LINK([#include <netdb.h>],
2121   [return h_errno;],
2122   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2123 if test $emacs_cv_netdb_declares_h_errno = yes; then
2124   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2125 fi
2126
2127 AC_FUNC_ALLOCA
2128
2129 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2130 dnl FIXME is there an autoconf test that does the right thing, without
2131 dnl needing to call A_M_E afterwards?
2132 if test x"$ac_cv_func_alloca_works" != xyes; then
2133    AC_MSG_ERROR( [a system implementation of alloca is required] )
2134 fi
2135
2136 # fmod, logb, and frexp are found in -lm on most systems.
2137 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2138 AC_CHECK_LIB(m, sqrt)
2139
2140 # Check for mail-locking functions in a "mail" library.  Probably this should
2141 # have the same check as for liblockfile below.
2142 AC_CHECK_LIB(mail, maillock)
2143 dnl Debian, at least:
2144 AC_CHECK_LIB(lockfile, maillock)
2145 # If we have the shared liblockfile, assume we must use it for mail
2146 # locking (e.g. Debian).  If we couldn't link against liblockfile
2147 # (no liblockfile.a installed), ensure that we don't need to.
2148 if test "$ac_cv_lib_lockfile_maillock" = no; then
2149   dnl This works for files generally, not just executables.
2150   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2151   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2152                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2153   if test $ac_cv_prog_liblockfile = yes; then
2154     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2155 This probably means that movemail could lose mail.
2156 There may be a `development' package to install containing liblockfile.])
2157   else :
2158   fi
2159 fi
2160 AC_CHECK_FUNCS(touchlock)
2161 AC_CHECK_HEADERS(maillock.h)
2162
2163 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2164 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2165 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2166 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2167 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2168 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2169 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2170 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2171 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2172 cfmakeraw cfsetspeed)
2173
2174 AC_CHECK_HEADERS(sys/un.h)
2175
2176 AC_FUNC_MKTIME
2177 if test "$ac_cv_func_working_mktime" = no; then
2178   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2179 fi
2180
2181 AC_FUNC_GETLOADAVG
2182
2183 AC_FUNC_FSEEKO
2184
2185 # Configure getopt.
2186 m4_include([m4/getopt.m4])
2187 gl_GETOPT_IFELSE([
2188   gl_GETOPT_SUBSTITUTE_HEADER
2189   gl_PREREQ_GETOPT
2190   GETOPTOBJS='getopt.o getopt1.o'
2191 ])
2192 AC_SUBST(GETOPTOBJS)
2193
2194 AC_FUNC_GETPGRP
2195
2196 AC_FUNC_STRFTIME
2197
2198 # UNIX98 PTYs.
2199 AC_CHECK_FUNCS(grantpt)
2200
2201 # PTY-related GNU extensions.
2202 AC_CHECK_FUNCS(getpt)
2203
2204 # Check this now, so that we will NOT find the above functions in ncurses.
2205 # That is because we have not set up to link ncurses in lib-src.
2206 # It's better to believe a function is not available
2207 # than to expect to find it in ncurses.
2208 AC_CHECK_LIB(ncurses, tparm)
2209
2210 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2211
2212 resolv=no
2213 AC_TRY_LINK([#include <netinet/in.h>
2214 #include <arpa/nameser.h>
2215 #include <resolv.h>],
2216     [return res_init();],
2217     have_res_init=yes, have_res_init=no)
2218 if test "$have_res_init" = no; then
2219   OLIBS="$LIBS"
2220   LIBS="$LIBS -lresolv"
2221   AC_MSG_CHECKING(for res_init with -lresolv)
2222   AC_TRY_LINK([#include <netinet/in.h>
2223 #include <arpa/nameser.h>
2224 #include <resolv.h>],
2225     [return res_init();],
2226     have_res_init=yes, have_res_init=no)
2227   AC_MSG_RESULT($have_res_init)
2228   if test "$have_res_init" = yes ; then
2229     resolv=yes
2230   fi
2231   LIBS="$OLIBS"
2232 fi
2233
2234 if test "$have_res_init" = yes; then
2235   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2236 fi
2237
2238 # Do we need the Hesiod library to provide the support routines?
2239 if test "$with_hesiod" != no ; then
2240   # Don't set $LIBS here -- see comments above.
2241   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2242      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2243                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2244   if test "$resolv" = yes ; then
2245     RESOLVLIB=-lresolv
2246   else
2247     RESOLVLIB=
2248   fi
2249   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2250         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2251                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2252         :, $RESOLVLIB)])
2253 fi
2254
2255 # Do we need libresolv (due to res_init or Hesiod)?
2256 if test "$resolv" = yes ; then
2257   AC_DEFINE(HAVE_LIBRESOLV, 1,
2258             [Define to 1 if you have the resolv library (-lresolv).])
2259 fi
2260
2261 # These tell us which Kerberos-related libraries to use.
2262 if test "${with_kerberos}" != no; then
2263   AC_CHECK_LIB(com_err, com_err)
2264   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2265   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2266   AC_CHECK_LIB(krb5, krb5_init_context)
2267   if test "${with_kerberos5}" = no; then
2268     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2269                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2270     AC_CHECK_LIB(krb4, krb_get_cred,,
2271                  [AC_CHECK_LIB(krb, krb_get_cred)])
2272   fi
2273
2274   if test "${with_kerberos5}" != no; then
2275     AC_CHECK_HEADERS(krb5.h,
2276       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2277                         [#include <krb5.h>])])
2278   else
2279     AC_CHECK_HEADERS(des.h,,
2280                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2281                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2282     AC_CHECK_HEADERS(krb.h,,
2283                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2284                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2285   fi
2286   AC_CHECK_HEADERS(com_err.h)
2287 fi
2288
2289 # Solaris requires -lintl if you want strerror (which calls dgettext)
2290 # to return localized messages.
2291 AC_CHECK_LIB(intl, dgettext)
2292
2293 AC_MSG_CHECKING(whether localtime caches TZ)
2294 AC_CACHE_VAL(emacs_cv_localtime_cache,
2295 [if test x$ac_cv_func_tzset = xyes; then
2296 AC_TRY_RUN([#include <time.h>
2297 extern char **environ;
2298 unset_TZ ()
2299 {
2300   char **from, **to;
2301   for (to = from = environ; (*to = *from); from++)
2302     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2303       to++;
2304 }
2305 char TZ_GMT0[] = "TZ=GMT0";
2306 char TZ_PST8[] = "TZ=PST8";
2307 main()
2308 {
2309   time_t now = time ((time_t *) 0);
2310   int hour_GMT0, hour_unset;
2311   if (putenv (TZ_GMT0) != 0)
2312     exit (1);
2313   hour_GMT0 = localtime (&now)->tm_hour;
2314   unset_TZ ();
2315   hour_unset = localtime (&now)->tm_hour;
2316   if (putenv (TZ_PST8) != 0)
2317     exit (1);
2318   if (localtime (&now)->tm_hour == hour_GMT0)
2319     exit (1);
2320   unset_TZ ();
2321   if (localtime (&now)->tm_hour != hour_unset)
2322     exit (1);
2323   exit (0);
2324 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2325 [# If we have tzset, assume the worst when cross-compiling.
2326 emacs_cv_localtime_cache=yes])
2327 else
2328         # If we lack tzset, report that localtime does not cache TZ,
2329         # since we can't invalidate the cache if we don't have tzset.
2330         emacs_cv_localtime_cache=no
2331 fi])dnl
2332 AC_MSG_RESULT($emacs_cv_localtime_cache)
2333 if test $emacs_cv_localtime_cache = yes; then
2334   AC_DEFINE(LOCALTIME_CACHE, 1,
2335             [Define to 1 if localtime caches TZ.])
2336 fi
2337
2338 if test "x$HAVE_TIMEVAL" = xyes; then
2339   AC_CHECK_FUNCS(gettimeofday)
2340   if test $ac_cv_func_gettimeofday = yes; then
2341     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2342                    emacs_cv_gettimeofday_two_arguments,
2343     [AC_TRY_COMPILE([
2344 #ifdef TIME_WITH_SYS_TIME
2345 #include <sys/time.h>
2346 #include <time.h>
2347 #else
2348 #ifdef HAVE_SYS_TIME_H
2349 #include <sys/time.h>
2350 #else
2351 #include <time.h>
2352 #endif
2353 #endif],
2354       [struct timeval time;
2355        gettimeofday (&time, 0);],
2356       emacs_cv_gettimeofday_two_arguments=yes,
2357       emacs_cv_gettimeofday_two_arguments=no)])
2358     if test $emacs_cv_gettimeofday_two_arguments = no; then
2359       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2360                 [Define to 1 if gettimeofday accepts only one argument.])
2361     fi
2362   fi
2363 fi
2364
2365 ok_so_far=yes
2366 AC_CHECK_FUNC(socket, , ok_so_far=no)
2367 if test $ok_so_far = yes; then
2368   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2369 fi
2370 if test $ok_so_far = yes; then
2371   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2372 fi
2373 if test $ok_so_far = yes; then
2374 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2375   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2376             [Define to 1 if you have inet sockets.])
2377 fi
2378
2379 AC_CHECK_HEADERS(sys/ioctl.h)
2380
2381 if test -f /usr/lpp/X11/bin/smt.exp; then
2382   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2383             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2384 fi
2385
2386 AC_MSG_CHECKING(whether system supports dynamic ptys)
2387 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2388   AC_MSG_RESULT(yes)
2389   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2390 else
2391   AC_MSG_RESULT(no)
2392 fi
2393
2394 AC_FUNC_FORK
2395
2396 dnl Adapted from Haible's version.
2397 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2398   [AC_TRY_LINK([#include <langinfo.h>],
2399     [char* cs = nl_langinfo(CODESET);],
2400     emacs_cv_langinfo_codeset=yes,
2401     emacs_cv_langinfo_codeset=no)
2402   ])
2403 if test $emacs_cv_langinfo_codeset = yes; then
2404   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2405     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2406 fi
2407
2408 AC_CHECK_TYPES(size_t)
2409
2410 AC_TYPE_MBSTATE_T
2411
2412 dnl Restrict could probably be used effectively other than in regex.c.
2413 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2414   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2415                   emacs_cv_c_restrict=yes,
2416                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2417                                   emacs_cv_c_restrict=__restrict,
2418                                   emacs_cv_c_restrict=no)])])
2419 case "$emacs_cv_c_restrict" in
2420   yes) emacs_restrict=restrict;;
2421   no) emacs_restrict="";;
2422   *) emacs_restrict="$emacs_cv_c_restrict";;
2423 esac
2424 if test "$emacs_restrict" != __restrict; then
2425   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2426     [Define to compiler's equivalent of C99 restrict keyword.
2427      Don't define if equivalent is `__restrict'.])
2428 fi
2429
2430 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2431   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2432                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2433 if test "$emacs_cv_c_restrict_arr" = yes; then
2434   AC_DEFINE(__restrict_arr, __restrict,
2435     [Define to compiler's equivalent of C99 restrict keyword in array
2436      declarations.  Define as empty for no equivalent.])
2437 fi
2438
2439 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2440 dnl how the tty code is related to POSIX and/or other versions of termios.
2441 dnl The following looks like a useful start.
2442 dnl
2443 dnl AC_SYS_POSIX_TERMIOS
2444 dnl if test $ac_cv_sys_posix_termios = yes; then
2445 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2446 dnl                                and macros for terminal control.])
2447 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2448 dnl fi
2449
2450 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2451
2452 # Set up the CFLAGS for real compilation, so we can substitute it.
2453 CFLAGS="$REAL_CFLAGS"
2454 CPPFLAGS="$REAL_CPPFLAGS"
2455
2456 #### Find out which version of Emacs this is.
2457 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2458          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2459 if test x"${version}" = x; then
2460   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2461 fi
2462
2463 ### Specify what sort of things we'll be editing into Makefile and config.h.
2464 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2465 AC_SUBST(version)
2466 AC_SUBST(configuration)
2467 AC_SUBST(canonical)
2468 AC_SUBST(srcdir)
2469 AC_SUBST(prefix)
2470 AC_SUBST(exec_prefix)
2471 AC_SUBST(bindir)
2472 AC_SUBST(datadir)
2473 AC_SUBST(sharedstatedir)
2474 AC_SUBST(libexecdir)
2475 AC_SUBST(mandir)
2476 AC_SUBST(infodir)
2477 AC_SUBST(lispdir)
2478 AC_SUBST(locallisppath)
2479 AC_SUBST(lisppath)
2480 AC_SUBST(x_default_search_path)
2481 AC_SUBST(etcdir)
2482 AC_SUBST(archlibdir)
2483 AC_SUBST(docdir)
2484 AC_SUBST(bitmapdir)
2485 AC_SUBST(gamedir)
2486 AC_SUBST(gameuser)
2487 AC_SUBST(c_switch_system)
2488 AC_SUBST(c_switch_machine)
2489 AC_SUBST(LD_SWITCH_X_SITE)
2490 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2491 AC_SUBST(C_SWITCH_X_SITE)
2492 AC_SUBST(CFLAGS)
2493 AC_SUBST(X_TOOLKIT_TYPE)
2494 AC_SUBST(machfile)
2495 AC_SUBST(opsysfile)
2496 AC_SUBST(GETLOADAVG_LIBS)
2497 AC_SUBST(ns_appdir)
2498 AC_SUBST(ns_appbindir)
2499 AC_SUBST(ns_appresdir)
2500 AC_SUBST(ns_appsrc)
2501 AC_SUBST(GNUSTEP_MAKEFILES)
2502 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2503 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2504 AC_SUBST(GNU_OBJC_CFLAGS)
2505 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2506
2507 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2508                    [Define to the canonical Emacs configuration name.])
2509 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2510                    [Define to the options passed to configure.])
2511 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2512                    [Define to the used machine dependent file.])
2513 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2514                    [Define to the used os dependent file.])
2515 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2516 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2517  may need to deal with X Windows.  For instance, if you've defined
2518  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2519  your loader can find on its own, you might want to add "-L/..." or
2520  something similar.])
2521 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2522                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2523                     in case it's needed (for Solaris, for example).])
2524 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2525 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2526  may need to deal with X Windows.  For instance, if you've defined
2527  HAVE_X_WINDOWS above and your X include files aren't in a place
2528  that your compiler can find on its own, you might want to add
2529  "-I/..." or something similar.])
2530 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2531                    [Define to the unexec source file name.])
2532
2533 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2534   AC_DEFINE(HAVE_X_WINDOWS, 1,
2535             [Define to 1 if you want to use the X window system.])
2536 fi
2537 if test "${USE_X_TOOLKIT}" != "none" ; then
2538   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2539   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2540     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2541   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2542     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2543   fi
2544 fi
2545 if test "${HAVE_X11}" = "yes" ; then
2546   AC_DEFINE(HAVE_X11, 1,
2547             [Define to 1 if you want to use version 11 of X windows.
2548              Otherwise, Emacs expects to use version 10.])
2549 fi
2550 if test "${HAVE_MENUS}" = "yes" ; then
2551   AC_DEFINE(HAVE_MENUS, 1,
2552             [Define to 1 if you have mouse menus.
2553              (This is automatic if you use X, but the option to specify it remains.)
2554              It is also defined with other window systems that support xmenu.c.])
2555 fi
2556 if test "${GNU_MALLOC}" = "yes" ; then
2557   AC_DEFINE(GNU_MALLOC, 1,
2558             [Define to 1 if you want to use the GNU memory allocator.])
2559 fi
2560 if test "${REL_ALLOC}" = "yes" ; then
2561   AC_DEFINE(REL_ALLOC, 1,
2562             [Define REL_ALLOC if you want to use the relocating allocator for
2563              buffer space.])
2564 fi
2565
2566
2567 AH_TOP([/* GNU Emacs site configuration template file.
2568    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2569      2006, 2007, 2008, 2009  Free Software Foundation, Inc.
2570
2571 This file is part of GNU Emacs.
2572
2573 GNU Emacs is free software: you can redistribute it and/or modify
2574 it under the terms of the GNU General Public License as published by
2575 the Free Software Foundation, either version 3 of the License, or
2576 (at your option) any later version.
2577
2578 GNU Emacs is distributed in the hope that it will be useful,
2579 but WITHOUT ANY WARRANTY; without even the implied warranty of
2580 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2581 GNU General Public License for more details.
2582
2583 You should have received a copy of the GNU General Public License
2584 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2585
2586
2587 /* No code in Emacs #includes config.h twice, but some bits of code
2588    intended to work with other packages as well (like gmalloc.c)
2589    think they can include it as many times as they like.  */
2590 #ifndef EMACS_CONFIG_H
2591 #define EMACS_CONFIG_H
2592 ])dnl
2593
2594 AH_BOTTOM([
2595 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2596 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2597 #define HAVE_WINDOW_SYSTEM
2598 #define HAVE_MOUSE
2599 #endif
2600
2601 /* Sadly for now, GNUstep dump does not work.  */
2602 #ifdef NS_IMPL_GNUSTEP
2603 #define CANNOT_DUMP
2604 #endif
2605
2606 /* Define AMPERSAND_FULL_NAME if you use the convention
2607    that & in the full name stands for the login id.  */
2608 /* Turned on June 1996 supposing nobody will mind it.  */
2609 #define AMPERSAND_FULL_NAME
2610
2611 /* Define HAVE_SOUND if we have sound support.  We know it works
2612    and compiles only on the specified platforms.   For others,
2613    it probably doesn't make sense to try.  */
2614
2615 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2616 #ifdef HAVE_MACHINE_SOUNDCARD_H
2617 #define HAVE_SOUND 1
2618 #endif
2619 #ifdef HAVE_SYS_SOUNDCARD_H
2620 #define HAVE_SOUND 1
2621 #endif
2622 #ifdef HAVE_SOUNDCARD_H
2623 #define HAVE_SOUND 1
2624 #endif
2625 #ifdef HAVE_ALSA
2626 #define HAVE_SOUND 1
2627 #endif
2628 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2629
2630 /* If using GNU, then support inline function declarations. */
2631 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2632    generally, because even if non-gcc compilers accept `inline', they
2633    may reject `extern inline'.  */
2634 #if defined (__GNUC__) && defined (OPTIMIZE)
2635 #define INLINE __inline__
2636 #else
2637 #define INLINE
2638 #endif
2639
2640 /* `subprocesses' should be defined if you want to
2641    have code for asynchronous subprocesses
2642    (as used in M-x compile and M-x shell).
2643    Only MSDOS does not support this (it overrides
2644    this in its config_opsysfile below).  */
2645
2646 #define subprocesses
2647
2648 /* Include the os and machine dependent files.  */
2649 #include config_opsysfile
2650 #include config_machfile
2651
2652 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2653   (There is probably a better place to do this, but right now the Cocoa
2654    side does this in s/darwin.h and we cannot
2655    parallel this exactly since GNUstep is multi-OS. */
2656 #ifdef HAVE_NS
2657 #define OTHER_FILES ns-app
2658 # ifdef NS_IMPL_GNUSTEP
2659 /* See also .m.o rule in Makefile.in */
2660 /* FIXME: are all these flags really needed?  Document here why.  */
2661 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2662 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2663 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2664 #  define SYSTEM_PURESIZE_EXTRA 30000
2665 # endif /* NS_IMPL_GNUSTEP */
2666 #endif /* HAVE_NS */
2667
2668 /* SIGTYPE is the macro we actually use.  */
2669 #ifndef SIGTYPE
2670 #define SIGTYPE RETSIGTYPE
2671 #endif
2672
2673 #ifdef emacs /* Don't do this for lib-src.  */
2674 /* Tell regex.c to use a type compatible with Emacs.  */
2675 #define RE_TRANSLATE_TYPE Lisp_Object
2676 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2677 #ifdef make_number
2678 /* If make_number is a macro, use it.  */
2679 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2680 #else
2681 /* If make_number is a function, avoid it.  */
2682 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2683 #endif
2684 #endif
2685
2686 /* Avoid link-time collision with system mktime if we will use our own.  */
2687 #if ! HAVE_MKTIME || BROKEN_MKTIME
2688 #define mktime emacs_mktime
2689 #endif
2690
2691 #define my_strftime nstrftime   /* for strftime.c */
2692
2693 /* The rest of the code currently tests the CPP symbol BSTRING.
2694    Override any claims made by the system-description files.
2695    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2696 #undef BSTRING
2697 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2698 #define BSTRING
2699 #endif
2700
2701 /* Some of the files of Emacs which are intended for use with other
2702    programs assume that if you have a config.h file, you must declare
2703    the type of getenv.
2704
2705    This declaration shouldn't appear when alloca.s or Makefile.in
2706    includes config.h.  */
2707 #ifndef NOT_C_CODE
2708 extern char *getenv ();
2709 #endif
2710
2711 /* These default definitions are good for almost all machines.
2712    The exceptions override them in m/MACHINE.h.  */
2713
2714 #ifndef BITS_PER_CHAR
2715 #define BITS_PER_CHAR 8
2716 #endif
2717
2718 #ifndef BITS_PER_SHORT
2719 #define BITS_PER_SHORT 16
2720 #endif
2721
2722 /* Note that lisp.h uses this in a preprocessor conditional, so it
2723    would not work to use sizeof.  That being so, we do all of them
2724    without sizeof, for uniformity's sake.  */
2725 #ifndef BITS_PER_INT
2726 #define BITS_PER_INT 32
2727 #endif
2728
2729 #ifndef BITS_PER_LONG
2730 #ifdef _LP64
2731 #define BITS_PER_LONG 64
2732 #else
2733 #define BITS_PER_LONG 32
2734 #endif
2735 #endif
2736
2737 /* Define if the compiler supports function prototypes.  It may do so
2738    but not define __STDC__ (e.g. DEC C by default) or may define it as
2739    zero.  */
2740 #undef PROTOTYPES
2741 /* For mktime.c:  */
2742 #ifndef __P
2743 # if defined PROTOTYPES
2744 #  define __P(args) args
2745 # else
2746 #  define __P(args) ()
2747 # endif  /* GCC.  */
2748 #endif /* __P */
2749
2750 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2751 #ifndef NOT_C_CODE
2752 #ifdef HAVE_STRING_H
2753 #include "string.h"
2754 #endif
2755 #ifdef HAVE_STRINGS_H
2756 #include "strings.h"  /* May be needed for bcopy & al. */
2757 #endif
2758 #ifdef HAVE_STDLIB_H
2759 #include <stdlib.h>
2760 #endif
2761 #ifndef __GNUC__
2762 # ifdef HAVE_ALLOCA_H
2763 #  include <alloca.h>
2764 # else /* AIX files deal with #pragma.  */
2765 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2766 char *alloca ();
2767 #  endif
2768 # endif /* HAVE_ALLOCA_H */
2769 #endif /* __GNUC__ */
2770 #ifndef HAVE_SIZE_T
2771 typedef unsigned size_t;
2772 #endif
2773 #endif /* NOT_C_CODE */
2774
2775 /* Define HAVE_X_I18N if we have usable i18n support.  */
2776
2777 #ifdef HAVE_X11R6
2778 #define HAVE_X_I18N
2779 #elif !defined X11R5_INHIBIT_I18N
2780 #define HAVE_X_I18N
2781 #endif
2782
2783 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2784
2785 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2786 #define HAVE_X11R6_XIM
2787 #endif
2788
2789 /* Should we enable expensive run-time checking of data types?  */
2790 #undef ENABLE_CHECKING
2791
2792 #if defined __GNUC__ && (__GNUC__ > 2 \
2793                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2794 #define NO_RETURN       __attribute__ ((__noreturn__))
2795 #else
2796 #define NO_RETURN       /* nothing */
2797 #endif
2798
2799 /* These won't be used automatically yet.  We also need to know, at least,
2800    that the stack is continuous.  */
2801 #ifdef __GNUC__
2802 #  ifndef GC_SETJMP_WORKS
2803   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2804      see NON_SAVING_SETJMP in the target descriptions.  */
2805   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2806      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2807      Fixme: Deal with SVR3.  */
2808 #    define GC_SETJMP_WORKS 1
2809 #  endif
2810 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2811 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2812 #  endif
2813 #endif
2814
2815 #ifndef HAVE_BCOPY
2816 #define bcopy(a,b,s) memcpy (b,a,s)
2817 #endif
2818 #ifndef HAVE_BZERO
2819 #define bzero(a,s) memset (a,0,s)
2820 #endif
2821 #ifndef HAVE_BCMP
2822 #define BCMP memcmp
2823 #endif
2824
2825 #endif /* EMACS_CONFIG_H */
2826
2827 /*
2828 Local Variables:
2829 mode: c
2830 End:
2831 */
2832 ])dnl
2833
2834 #### Report on what we decided to do.
2835 #### Report GTK as a toolkit, even if it doesn't use Xt.
2836 #### It makes printing result more understandable as using GTK sets
2837 #### toolkit_scroll_bars to yes by default.
2838 if test "${HAVE_GTK}" = "yes"; then
2839   USE_X_TOOLKIT=GTK
2840 fi
2841
2842 echo "
2843 Configured for \`${canonical}'.
2844
2845   Where should the build process find the source code?    ${srcdir}
2846   What operating system and machine description files should Emacs use?
2847         \`${opsysfile}' and \`${machfile}'
2848   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2849   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2850   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2851   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2852   What window system should Emacs use?                    ${window_system}
2853   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2854
2855 if test -n "${x_includes}"; then
2856 echo "  Where do we find X Windows header files?                ${x_includes}"
2857 else
2858 echo "  Where do we find X Windows header files?                Standard dirs"
2859 fi
2860 if test -n "${x_libraries}"; then
2861 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2862 else
2863 echo "  Where do we find X Windows libraries?                   Standard dirs"
2864 fi
2865
2866 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2867 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2868 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2869 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2870 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
2871 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2872 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
2873 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
2874 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
2875
2876 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
2877 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
2878 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
2879 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
2880
2881 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
2882 echo
2883
2884 if test $USE_XASSERTS = yes; then
2885    echo "  Compiling with asserts turned on."
2886    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
2887 fi
2888
2889 echo
2890
2891 if test "$USE_X_TOOLKIT" = GTK; then
2892   case "$canonical" in
2893   *cygwin*)
2894     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
2895   will probably get a crash on startup.  If this happens, please use another
2896   toolkit for Emacs.  See etc/PROBLEMS for more information."
2897   ;;
2898   esac
2899 fi
2900
2901 if test "$HAVE_NS" = "yes"; then
2902    echo
2903    echo "You must run \"make install\" in order to test the built application.
2904 The installed application will go to nextstep/Emacs.app and can be
2905 run or moved from there."
2906    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
2907       echo "The application will be fully self-contained."
2908     else
2909       echo "The lisp resources for the application will be installed under ${prefix}.
2910 You may need to run \"make install\" with sudo.  The application will fail
2911 to run if these resources are not installed."
2912    fi
2913    echo
2914 fi
2915
2916 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
2917   echo "D-Bus integration has been tested for GNU/Linux only."
2918   echo
2919 fi
2920
2921
2922 # Remove any trailing slashes in these variables.
2923 [test "${prefix}" != NONE &&
2924   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2925 test "${exec_prefix}" != NONE &&
2926   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
2927
2928 # Now get this: Some word that is part of the ${srcdir} directory name
2929 # or the ${configuration} value might, just might, happen to be an
2930 # identifier like `sun4' or `i386' or something, and be predefined by
2931 # the C preprocessor to some helpful value like 1, or maybe the empty
2932 # string.  Needless to say consequent macro substitutions are less
2933 # than conducive to the makefile finding the correct directory.
2934 [cpp_undefs="`echo $srcdir $configuration $canonical |
2935   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
2936   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
2937
2938 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
2939 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
2940 ## from Makefile.c can correctly provide the arg `-traditional' to the
2941 ## C preprocessor.
2942
2943 AC_EGREP_CPP(yes..yes,
2944         [yes..yes],
2945         CPP_NEED_TRADITIONAL=no,
2946         CPP_NEED_TRADITIONAL=yes)
2947
2948 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2949         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
2950         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
2951         lwlib/Makefile lisp/Makefile leim/Makefile, [
2952
2953 ### Make the necessary directories, if they don't exist.
2954 for dir in etc lisp ; do
2955   test -d ${dir} || mkdir ${dir}
2956 done
2957
2958 # Build src/Makefile from ${srcdir}/src/Makefile.c
2959 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2960 # This must be done after src/config.h is built, since we rely on that file.
2961
2962 echo creating src/epaths.h
2963 ${MAKE-make} epaths-force
2964
2965 # As of 2000-11-19, newest development versions of GNU cpp preprocess
2966 # `..' to `. .'  unless invoked with -traditional
2967
2968 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
2969   CPPFLAGS="$CPPFLAGS -traditional"
2970 fi
2971
2972 echo creating lib-src/Makefile
2973 ( cd lib-src
2974   rm -f junk.c junk1.c junk2.c
2975   sed -e '/start of cpp stuff/q' \
2976       < Makefile.c > junk1.c
2977   sed -e '1,/start of cpp stuff/d'\
2978       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2979       < Makefile.c > junk.c
2980   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2981       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2982   cat junk1.c junk2.c > Makefile.new
2983   rm -f junk.c junk1.c junk2.c
2984   chmod 444 Makefile.new
2985   mv -f Makefile.new Makefile
2986 )
2987
2988 echo creating src/Makefile
2989 ( cd src
2990   rm -f junk.c junk1.c junk2.c
2991   sed -e '/start of cpp stuff/q' \
2992       < Makefile.c > junk1.c
2993   sed -e '1,/start of cpp stuff/d'\
2994       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2995       < Makefile.c > junk.c
2996   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2997       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2998   cat junk1.c junk2.c > Makefile.new
2999   rm -f junk.c junk1.c junk2.c
3000   chmod 444 Makefile.new
3001   mv -f Makefile.new Makefile
3002 )
3003
3004 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3005   echo creating src/.gdbinit
3006   echo source $srcdir/src/.gdbinit > src/.gdbinit
3007 fi
3008
3009 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3010
3011 m4_if(dnl       Do not change this comment
3012    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3013 )dnl