code.delx.au - gnu-emacs/blob - lisp/play/yow.el

   1 ;;; yow.el --- quote random zippyisms
   2
   3 ;; Copyright (C) 1993-1995, 2000-2012  Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Author: Richard Mlynarik
   7 ;; Keywords: games
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Important pinheadery for GNU Emacs.
  27 ;;
  28 ;; See cookie1.el for implementation.  Note --- the `n' argument of yow
  29 ;; from the 18.xx implementation is no longer; we only support *random*
  30 ;; random access now.
  31
  32 ;;; Code:
  33
  34 (require 'cookie1)
  35
  36 (defgroup yow nil
  37   "Quote random zippyisms."
  38   :prefix "yow-"
  39   :group 'games)
  40
  41 (defcustom yow-file (concat data-directory "yow.lines")
  42    "File containing pertinent pinhead phrases."
  43   :type 'file
  44   :group 'yow)
  45
  46 (defconst yow-load-message "Am I CONSING yet?...")
  47 (defconst yow-after-load-message "I have SEEN the CONSING!!")
  48
  49 ;;;###autoload
  50 (defun yow (&optional insert display)
  51   "Return or display a random Zippy quotation.  With prefix arg, insert it."
  52   (interactive "P\np")
  53   (let ((yow (cookie yow-file yow-load-message yow-after-load-message)))
  54     (cond (insert
  55            (insert yow))
  56           ((not display)
  57            yow)
  58           (t
  59            (message "%s" yow)))))
  60
  61 (defsubst read-zippyism (prompt &optional require-match)
  62   "Read a Zippyism from the minibuffer with completion, prompting with PROMPT.
  63 If optional second arg is non-nil, require input to match a completion."
  64   (read-cookie prompt yow-file yow-load-message yow-after-load-message
  65                require-match))
  66
  67 ;;;###autoload
  68 (defun insert-zippyism (&optional zippyism)
  69   "Prompt with completion for a known Zippy quotation, and insert it at point."
  70   (interactive (list (read-zippyism "Pinhead wisdom: " t)))
  71   (insert zippyism))
  72
  73 ;;;###autoload
  74 (defun apropos-zippy (regexp)
  75   "Return a list of all Zippy quotes matching REGEXP.
  76 If called interactively, display a list of matches."
  77   (interactive "sApropos Zippy (regexp): ")
  78   ;; Make sure yows are loaded
  79   (cookie yow-file yow-load-message yow-after-load-message)
  80   (let* ((case-fold-search t)
  81          (cookie-table-symbol (intern yow-file cookie-cache))
  82          (string-table (symbol-value cookie-table-symbol))
  83          (matches nil)
  84          (len (length string-table))
  85          (i 0))
  86     (save-match-data
  87       (while (< i len)
  88         (and (string-match regexp (aref string-table i))
  89              (setq matches (cons (aref string-table i) matches)))
  90         (setq i (1+ i))))
  91     (and matches
  92          (setq matches (sort matches 'string-lessp)))
  93     (and (called-interactively-p 'interactive)
  94          (cond ((null matches)
  95                 (message "No matches found."))
  96                (t
  97                 (let ((l matches))
  98                   (with-output-to-temp-buffer "*Zippy Apropos*"
  99                     (while l
 100                       (princ (car l))
 101                       (setq l (cdr l))
 102                       (and l (princ "\n\n")))
 103                     (help-print-return-message))))))
 104     matches))
 105
 106 \f
 107 ;; Yowza!! Feed zippy quotes to the doctor. Watch results.
 108 ;; fun, fun, fun. Entertainment for hours...
 109 ;;
 110 ;; written by Kayvan Aghaiepour
 111
 112 (declare-function doctor-ret-or-read "doctor" (arg))
 113
 114 ;;;###autoload
 115 (defun psychoanalyze-pinhead ()
 116   "Zippy goes to the analyst."
 117   (interactive)
 118   (doctor)                              ; start the psychotherapy
 119   (message "")
 120   (switch-to-buffer "*doctor*")
 121   (sit-for 0)
 122   (while (not (input-pending-p))
 123     (insert (yow))
 124     (sit-for 0)
 125     (doctor-ret-or-read 1)
 126     (doctor-ret-or-read 1)))
 127
 128 (provide 'yow)
 129
 130 ;;; yow.el ends here