code.delx.au - gnu-emacs/blob - lisp/version.el

   1 ;;; version.el --- record version number of Emacs
   2
   3 ;; Copyright (C) 1985, 1992, 1994-1995, 1999-2016 Free Software
   4 ;; Foundation, Inc.
   5
   6 ;; Maintainer: emacs-devel@gnu.org
   7 ;; Keywords: internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (defconst emacs-major-version
  30   (progn (string-match "^[0-9]+" emacs-version)
  31          (string-to-number (match-string 0 emacs-version)))
  32   "Major version number of this version of Emacs.
  33 This variable first existed in version 19.23.")
  34
  35 (defconst emacs-minor-version
  36   (progn (string-match "^[0-9]+\\.\\([0-9]+\\)" emacs-version)
  37          (string-to-number (match-string 1 emacs-version)))
  38   "Minor version number of this version of Emacs.
  39 This variable first existed in version 19.23.")
  40
  41 (defconst emacs-build-system (system-name)
  42   "Name of the system on which Emacs was built, or nil if not available.")
  43
  44 (defconst emacs-build-time (if emacs-build-system (current-time))
  45   "Time at which Emacs was dumped out, or nil if not available.")
  46
  47 (defvar motif-version-string)
  48 (defvar gtk-version-string)
  49 (defvar ns-version-string)
  50 (defvar cairo-version-string)
  51
  52 (defun emacs-version (&optional here)
  53   "Return string describing the version of Emacs that is running.
  54 If optional argument HERE is non-nil, insert string at point.
  55 Don't use this function in programs to choose actions according
  56 to the system configuration; look at `system-configuration' instead."
  57   (interactive "P")
  58   (let ((version-string
  59          (format "GNU Emacs %s (%s%s%s%s)%s"
  60                  emacs-version
  61                  system-configuration
  62                  (cond ((featurep 'motif)
  63                         (concat ", " (substring motif-version-string 4)))
  64                        ((featurep 'gtk)
  65                         (concat ", GTK+ Version " gtk-version-string))
  66                        ((featurep 'x-toolkit) ", X toolkit")
  67                        ((featurep 'ns)
  68                         (format ", NS %s" ns-version-string))
  69                        (t ""))
  70                  (if (featurep 'cairo)
  71                      (format ", cairo version %s" cairo-version-string)
  72                    "")
  73                  (if (and (boundp 'x-toolkit-scroll-bars)
  74                           (memq x-toolkit-scroll-bars '(xaw xaw3d)))
  75                      (format ", %s scroll bars"
  76                              (capitalize (symbol-name x-toolkit-scroll-bars)))
  77                    "")
  78                  (if emacs-build-time
  79                      (format-time-string (concat
  80                                           (if (called-interactively-p
  81                                                'interactive)
  82                                               "" "\n")
  83                                           " of %Y-%m-%d")
  84                                          emacs-build-time)
  85                    ""))))
  86     (if here
  87         (insert version-string)
  88       (if (called-interactively-p 'interactive)
  89           (message "%s" version-string)
  90         version-string))))
  91
  92 ;; We hope that this alias is easier for people to find.
  93 (defalias 'version 'emacs-version)
  94
  95 ;; Set during dumping, this is a defvar so that it can be setq'd.
  96 (defvar emacs-repository-version nil
  97   "String giving the repository revision from which this Emacs was built.
  98 Value is nil if Emacs was not built from a repository checkout,
  99 or if we could not determine the revision.")
 100
 101 (define-obsolete-variable-alias 'emacs-bzr-version
 102                                 'emacs-repository-version "24.4")
 103
 104 (define-obsolete-function-alias 'emacs-bzr-get-version
 105                                 'emacs-repository-get-version "24.4")
 106
 107 (defun emacs-repository-version-git (dir)
 108   "Ask git itself for the version information for directory DIR."
 109   (message "Waiting for git...")
 110   (with-temp-buffer
 111     (let ((default-directory (file-name-as-directory dir)))
 112       (and (eq 0
 113                (with-demoted-errors "Error running git rev-parse: %S"
 114                  (call-process "git" nil '(t nil) nil "rev-parse" "HEAD")))
 115            (progn (goto-char (point-min))
 116                   (looking-at "[0-9a-fA-F]\\{40\\}"))
 117            (match-string 0)))))
 118
 119 (defun emacs-repository--version-git-1 (file dir)
 120   "Internal subroutine of `emacs-repository-get-version'."
 121   (when (file-readable-p file)
 122     (with-temp-buffer
 123       (insert-file-contents file)
 124       (cond ((looking-at "[0-9a-fA-F]\\{40\\}")
 125              (match-string 0))
 126             ((looking-at "ref: \\(.*\\)")
 127              (emacs-repository--version-git-1
 128               (expand-file-name (match-string 1) dir)
 129               dir))))))
 130
 131 (defun emacs-repository-get-version (&optional dir external)
 132   "Try to return as a string the repository revision of the Emacs sources.
 133 The format of the returned string is dependent on the VCS in use.
 134 Value is nil if the sources do not seem to be under version
 135 control, or if we could not determine the revision.  Note that
 136 this reports on the current state of the sources, which may not
 137 correspond to the running Emacs.
 138
 139 Optional argument DIR is a directory to use instead of `source-directory'.
 140 Optional argument EXTERNAL non-nil means to just ask the VCS itself,
 141 if the sources appear to be under version control.  Otherwise only ask
 142 the VCS if we cannot find any information ourselves."
 143   (or dir (setq dir source-directory))
 144   (let* ((base-dir (expand-file-name ".git" dir))
 145          (in-main-worktree (file-directory-p base-dir))
 146          (in-linked-worktree nil)
 147          sub-dir)
 148     ;; If the sources are in a linked worktree, .git is a file that points to
 149     ;; the location of the main worktree and the repo's administrative files.
 150     (when (and (not in-main-worktree)
 151                (file-regular-p base-dir)
 152                (file-readable-p base-dir))
 153       (with-temp-buffer
 154         (insert-file-contents base-dir)
 155         (when (looking-at "gitdir: \\(.*\.git\\)\\(.*\\)$")
 156           (setq base-dir (match-string 1)
 157                 sub-dir (concat base-dir (match-string 2))
 158                 in-linked-worktree t))))
 159     ;; We've found a worktree, either main or linked.
 160     (when (or in-main-worktree in-linked-worktree)
 161       (if external
 162           (emacs-repository-version-git dir)
 163         (or (if in-linked-worktree
 164                 (emacs-repository--version-git-1
 165                  (expand-file-name "HEAD" sub-dir) base-dir)
 166               (let ((files '("HEAD" "refs/heads/master"))
 167                     file rev)
 168                 (while (and (not rev)
 169                             (setq file (car files)))
 170                   (setq file (expand-file-name file base-dir)
 171                         files (cdr files)
 172                         rev (emacs-repository--version-git-1 file base-dir)))
 173                 rev))
 174             ;; AFAICS this doesn't work during dumping (bug#20799).
 175             (emacs-repository-version-git dir))))))
 176
 177 ;; We put version info into the executable in the form that `ident' uses.
 178 (purecopy (concat "\n$Id: " (subst-char-in-string ?\n ?\s (emacs-version))
 179                   " $\n"))
 180
 181 ;;; version.el ends here