code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the 'configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2016 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 25.1.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in "$@" CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140
 141 case $host in
 142  *-mingw*)
 143
 144   if test -z "$host_alias"; then
 145
 146       # No --host argument was given to 'configure'; therefore $host
 147       # was set to a default value based on the build platform.  But
 148       # this default value may be wrong if we are building from a
 149       # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
 150       # Therefore, we'll try to get the right host platform from the
 151       # compiler's target.
 152
 153       AC_MSG_CHECKING([the compiler's target])
 154       if test -z "$CC"; then
 155           cc=gcc
 156       else
 157           cc=$CC
 158       fi
 159       cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
 160       case "$cc_target" in
 161           *-*) host=$cc_target
 162               ;;
 163           "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
 164 Please explicitly provide --host.])
 165               ;;
 166           *) AC_MSG_WARN([Compiler reported non-standard target.
 167 Defaulting to $host.])
 168               ;;
 169       esac
 170       AC_MSG_RESULT([$host])
 171   fi
 172
 173   . $srcdir/nt/mingw-cfg.site
 174
 175   case $srcdir in
 176     /* | ?:*)
 177       # srcdir is an absolute path.  In this case, force the format
 178       # "/c/foo/bar", to simplify later conversions to native Windows
 179       # format ("c:/foo/bar").
 180       srcdir=`cd "${srcdir}" && pwd -W`
 181       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
 182       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
 183       ;;
 184   esac;;
 185 esac
 186
 187 canonical=$host
 188 configuration=${host_alias-${build_alias-$host}}
 189
 190 dnl Support for --program-prefix, --program-suffix and
 191 dnl --program-transform-name options
 192 AC_ARG_PROGRAM
 193
 194 dnl It is important that variables on the RHS not be expanded here,
 195 dnl hence the single quotes.  This is per the GNU coding standards, see
 196 dnl (autoconf) Installation Directory Variables
 197 dnl See also epaths.h below.
 198 lispdir='${datadir}/emacs/${version}/lisp'
 199 standardlisppath='${lispdir}'
 200 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 201 '${datadir}/emacs/site-lisp'
 202 lisppath='${locallisppath}:${standardlisppath}'
 203 etcdir='${datadir}/emacs/${version}/etc'
 204 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 205 etcdocdir='${datadir}/emacs/${version}/etc'
 206 gamedir='${localstatedir}/games/emacs'
 207
 208 dnl Special option to disable the most of other options.
 209 AC_ARG_WITH(all,
 210 [AS_HELP_STRING([--without-all],
 211                 [omit almost all features and build
 212                 small executable with minimal dependencies])],
 213   [with_features=$withval],
 214   [with_features=yes])
 215
 216 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 217 dnl Create a new --with option that defaults to being disabled.
 218 dnl NAME is the base name of the option.  The shell variable with_NAME
 219 dnl   will be set to either the user's value (if the option is
 220 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 221 dnl   option is not specified).  Note that the shell variable name is
 222 dnl   constructed as autoconf does, by replacing non-alphanumeric
 223 dnl   characters with "_".
 224 dnl HELP-STRING is the help text for the option.
 225 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 226   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 227     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 228 ])dnl
 229
 230 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 231 dnl Create a new --with option that defaults to $with_features.
 232 dnl NAME is the base name of the option.  The shell variable with_NAME
 233 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 234 dnl   'yes' (if the option is not specified).  Note that the shell
 235 dnl   variable name is constructed as autoconf does, by replacing
 236 dnl   non-alphanumeric characters with "_".
 237 dnl HELP-STRING is the help text for the option.
 238 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 239   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 240    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 241 ])dnl
 242
 243 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 244 if test "$with_pop" = yes; then
 245    AC_DEFINE(MAIL_USE_POP)
 246 fi
 247 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 248
 249 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 250 if test "$with_kerberos" != no; then
 251    AC_DEFINE(KERBEROS)
 252 fi
 253 AH_TEMPLATE(KERBEROS,
 254             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 255
 256 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 257 if test "${with_kerberos5}" != no; then
 258   if test "${with_kerberos}" = no; then
 259     with_kerberos=yes
 260     AC_DEFINE(KERBEROS)
 261   fi
 262   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 263 fi
 264
 265 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 266 dnl FIXME hesiod support may not be present, so it seems like an error
 267 dnl to define, or at least use, this unconditionally.
 268 if test "$with_hesiod" != no; then
 269   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 270 fi
 271
 272 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 273 if test "$with_mail_unlink" != no; then
 274    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 275 fi
 276
 277 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 278     [string giving default POP mail host])],
 279     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 280
 281 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 282   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 283 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
 284   [ case "${withval}" in
 285       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 286       *) AC_MSG_ERROR(['--with-sound=$withval' is invalid;
 287 this option's value should be 'yes', 'no', 'alsa', 'oss', or 'bsd-ossaudio'.])
 288       ;;
 289     esac
 290     with_sound=$val
 291   ],
 292   [with_sound=$with_features])
 293
 294 dnl FIXME currently it is not the last.
 295 dnl This should be the last --with option, because --with-x is
 296 dnl added later on when we find the file name of X, and it's best to
 297 dnl keep them together visually.
 298 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 299  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 300 [         case "${withval}" in
 301             y | ye | yes )      val=gtk ;;
 302             n | no )            val=no  ;;
 303             l | lu | luc | luci | lucid )       val=lucid ;;
 304             a | at | ath | athe | athen | athena )      val=athena ;;
 305             m | mo | mot | moti | motif )       val=motif ;;
 306             g | gt | gtk  )     val=gtk ;;
 307             gtk2  )     val=gtk2 ;;
 308             gtk3  )     val=gtk3 ;;
 309             * )
 310 AC_MSG_ERROR(['--with-x-toolkit=$withval' is invalid;
 311 this option's value should be 'yes', 'no', 'lucid', 'athena', 'motif', 'gtk',
 312 'gtk2' or 'gtk3'.  'yes' and 'gtk' are synonyms.
 313 'athena' and 'lucid' are synonyms.])
 314             ;;
 315           esac
 316           with_x_toolkit=$val
 317 ])
 318
 319 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit); allows buffer and string size up to 2GB on 32-bit hosts, at the cost of 10% to 30% slowdown of Lisp interpreter and larger memory footprint])
 320 if test "$with_wide_int" = yes; then
 321   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 322 fi
 323
 324 dnl _ON results in a '--without' option in the --help output, so
 325 dnl the help text should refer to "don't compile", etc.
 326 with_xpm_set=${with_xpm+set}
 327 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 328 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 329 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 330 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 331 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 332 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 333 OPTION_DEFAULT_ON([libsystemd],[don't compile with libsystemd support])
 334 OPTION_DEFAULT_OFF([cairo],[compile with Cairo drawing (experimental)])
 335 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 336 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 337
 338 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 339 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 340 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 341
 342 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 343 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 344 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 345 AC_ARG_WITH([ns],[AS_HELP_STRING([--with-ns],
 346 [use Nextstep (OS X Cocoa or GNUstep) windowing system.
 347 On by default on Mac OS X.])],[],[with_ns=maybe])
 348 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 349
 350 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 351 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 352 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 353 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 354 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 355 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 356 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 357 OPTION_DEFAULT_OFF([modules],[compile with dynamic modules support])
 358
 359 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 360  [use a file notification library (LIB one of: yes, inotify, kqueue, gfile, w32, no)])],
 361  [ case "${withval}" in
 362     y | ye | yes )      val=yes ;;
 363     n | no )            val=no  ;;
 364     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 365     k | kq | kqu | kque | kqueu | kqueue )      val=kqueue ;;
 366     g | gf | gfi | gfil | gfile )       val=gfile ;;
 367     w | w3 | w32 )      val=w32 ;;
 368     * ) AC_MSG_ERROR(['--with-file-notification=$withval' is invalid;
 369 this option's value should be 'yes', 'no', 'inotify', 'kqueue', 'gfile' or 'w32'.
 370 'yes' is a synonym for 'w32' on MS-Windows, for 'no' on Nextstep,
 371 otherwise for the first of 'inotify', 'kqueue' or 'gfile' that is usable.])
 372     ;;
 373    esac
 374    with_file_notification=$val
 375  ],
 376  [with_file_notification=$with_features])
 377
 378 OPTION_DEFAULT_OFF([xwidgets],
 379   [enable use of some gtk widgets in Emacs buffers (requires gtk3)])
 380
 381 ## For the times when you want to build Emacs but don't have
 382 ## a suitable makeinfo, and can live without the manuals.
 383 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 384 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 385
 386 ## This might be a 'configure' arg.
 387 AC_SUBST([ACLOCAL_PATH])
 388
 389 ## Makefile.in needs the cache file name.
 390 AC_SUBST(cache_file)
 391
 392 ## This is an option because I do not know if all info/man support
 393 ## compressed files, nor how to test if they do so.
 394 OPTION_DEFAULT_ON([compress-install],
 395   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 396 make GZIP_PROG= install])
 397
 398 AC_ARG_WITH(gameuser,dnl
 399 [AS_HELP_STRING([--with-gameuser=USER_OR_GROUP],
 400                 [user for shared game score files.
 401                 An argument prefixed by ':' specifies a group instead.])])
 402 gameuser=
 403 gamegroup=
 404 # We don't test if we can actually chown/chgrp here, because configure
 405 # may run without root privileges.  lib-src/Makefile.in will handle
 406 # any errors due to missing user/group gracefully.
 407 case ${with_gameuser} in
 408   no) ;;
 409   "" | yes) gamegroup=games ;;
 410   :*) gamegroup=${with_gameuser#:} ;;
 411   *) gameuser=${with_gameuser} ;;
 412 esac
 413
 414 AC_ARG_WITH([gnustep-conf],dnl
 415 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 416    [name of GNUstep configuration file to use on systems where the command
 417     'gnustep-config' does not work; default $GNUSTEP_CONFIG_FILE, or
 418     /etc/GNUstep/GNUstep.conf])])
 419 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 420   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 421 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 422      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 423
 424 AC_ARG_ENABLE(ns-self-contained,
 425 [AS_HELP_STRING([--disable-ns-self-contained],
 426                 [disable self contained build under NeXTstep])],
 427    EN_NS_SELF_CONTAINED=$enableval,
 428    EN_NS_SELF_CONTAINED=yes)
 429
 430 locallisppathset=no
 431 AC_ARG_ENABLE(locallisppath,
 432 [AS_HELP_STRING([--enable-locallisppath=PATH],
 433                 [directories Emacs should search for lisp files specific
 434                  to this site])],
 435 if test "${enableval}" = "no"; then
 436   locallisppath=
 437 elif test "${enableval}" != "yes"; then
 438   locallisppath=${enableval} locallisppathset=yes
 439 fi)
 440
 441 AC_ARG_ENABLE(checking,
 442 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 443                 [enable expensive run-time checks.  With LIST,
 444                  enable only specific categories of checks.
 445                  Categories are: all,yes,no.
 446                  Flags are: stringbytes, stringoverrun, stringfreelist,
 447                  xmallocoverrun, conslist, glyphs])],
 448 [ac_checking_flags="${enableval}"],[])
 449 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 450 for check in $ac_checking_flags
 451 do
 452         case $check in
 453         # these set all the flags to specific states
 454         yes)            ac_enable_checking=1 ;;
 455         no)             ac_enable_checking= ;
 456                         ac_gc_check_stringbytes= ;
 457                         ac_gc_check_string_overrun= ;
 458                         ac_gc_check_string_free_list= ;
 459                         ac_xmalloc_overrun= ;
 460                         ac_gc_check_cons_list= ;
 461                         ac_glyphs_debug= ;;
 462         all)            ac_enable_checking=1 ;
 463                         ac_gc_check_stringbytes=1 ;
 464                         ac_gc_check_string_overrun=1 ;
 465                         ac_gc_check_string_free_list=1 ;
 466                         ac_xmalloc_overrun=1 ;
 467                         ac_gc_check_cons_list=1 ;
 468                         ac_glyphs_debug=1 ;;
 469         # these enable particular checks
 470         stringbytes)    ac_gc_check_stringbytes=1 ;;
 471         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 472         stringfreelist) ac_gc_check_string_free_list=1 ;;
 473         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 474         conslist)       ac_gc_check_cons_list=1 ;;
 475         glyphs)         ac_glyphs_debug=1 ;;
 476         *)      AC_MSG_ERROR(unknown check category $check) ;;
 477         esac
 478 done
 479 IFS="$ac_save_IFS"
 480
 481 if test x$ac_enable_checking != x ; then
 482   AC_DEFINE(ENABLE_CHECKING, 1,
 483 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 484 fi
 485 if test x$ac_gc_check_stringbytes != x ; then
 486   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 487 [Define this temporarily to hunt a bug.  If defined, the size of
 488    strings is redundantly recorded in sdata structures so that it can
 489    be compared to the sizes recorded in Lisp strings.])
 490 fi
 491 if test x$ac_gc_check_string_overrun != x ; then
 492   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 493 [Define this to check for short string overrun.])
 494 fi
 495 if test x$ac_gc_check_string_free_list != x ; then
 496   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 497 [Define this to check the string free list.])
 498 fi
 499 if test x$ac_xmalloc_overrun != x ; then
 500   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 501 [Define this to check for malloc buffer overrun.])
 502 fi
 503 if test x$ac_gc_check_cons_list != x ; then
 504   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 505 [Define this to check for errors in cons list.])
 506 fi
 507 if test x$ac_glyphs_debug != x ; then
 508   AC_DEFINE(GLYPH_DEBUG, 1,
 509 [Define this to enable glyphs debugging code.])
 510 fi
 511
 512 AC_ARG_ENABLE(check-lisp-object-type,
 513 [AS_HELP_STRING([--enable-check-lisp-object-type],
 514                 [enable compile time checks for the Lisp_Object data type.
 515                 This is useful for development for catching certain types of bugs.])],
 516 if test "${enableval}" != "no"; then
 517    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 518    [Define this to enable compile time checks for the Lisp_Object data type.])
 519 fi)
 520
 521
 522 dnl The name of this option is unfortunate.  It predates, and has no
 523 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 524 dnl Actually, it stops it working.
 525 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 526 AC_ARG_ENABLE(profiling,
 527 [AS_HELP_STRING([--enable-profiling],
 528                 [build emacs with low-level, gprof profiling support.
 529                 Mainly useful for debugging Emacs itself.  May not work on
 530                 all platforms.  Stops profiler.el working.])],
 531 [ac_enable_profiling="${enableval}"],[])
 532 if test x$ac_enable_profiling != x ; then
 533    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 534 else
 535    PROFILING_CFLAGS=
 536 fi
 537 AC_SUBST(PROFILING_CFLAGS)
 538
 539 AC_ARG_ENABLE(autodepend,
 540 [AS_HELP_STRING([--enable-autodepend],
 541                 [automatically generate dependencies to .h-files.
 542                  Requires gcc, enabled if found.])],
 543 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 544
 545 AC_ARG_ENABLE(gtk-deprecation-warnings,
 546 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 547                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 548 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 549
 550 BUILD_DETAILS=
 551 AC_ARG_ENABLE([build-details],
 552   [AS_HELP_STRING([--disable-build-details],
 553                   [Make the build more deterministic by omitting host
 554                    names, time stamps, etc. from the output.])],
 555   [test "$enableval" = no && BUILD_DETAILS=--no-build-details])
 556 AC_SUBST([BUILD_DETAILS])
 557
 558 dnl This used to use changequote, but, apart from 'changequote is evil'
 559 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 560 dnl the great gob of text.  Thus it's not processed for possible expansion.
 561 dnl Just make sure the brackets remain balanced.
 562 dnl
 563 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 564 dnl indicated by comments.
 565 dnl quotation begins
 566 [
 567
 568 ### If you add support for a new configuration, add code to this
 569 ### switch statement to recognize your configuration name and select
 570 ### the appropriate opsys.
 571
 572 ### As far as handling version numbers on operating systems is
 573 ### concerned, make sure things will fail in a fixable way.  If
 574 ### /etc/MACHINES doesn't say anything about version numbers, be
 575 ### prepared to handle anything reasonably.  If version numbers
 576 ### matter, be sure /etc/MACHINES says something about it.
 577
 578 opsys='' unported=no
 579 case "${canonical}" in
 580
 581   ## GNU/Linux and similar ports
 582   *-*-linux* )
 583     opsys=gnu-linux
 584   ;;
 585
 586   ## FreeBSD ports
 587   *-*-freebsd* )
 588     opsys=freebsd
 589   ;;
 590
 591   ## DragonFly ports
 592   *-*-dragonfly* )
 593     opsys=dragonfly
 594   ;;
 595
 596   ## FreeBSD kernel + glibc based userland
 597   *-*-kfreebsd*gnu* )
 598     opsys=gnu-kfreebsd
 599   ;;
 600
 601   ## NetBSD ports
 602   *-*-netbsd* )
 603     opsys=netbsd
 604   ;;
 605
 606   ## OpenBSD ports
 607   *-*-openbsd* | *-*-mirbsd* )
 608     opsys=openbsd
 609   ;;
 610
 611   ## Apple Darwin / Mac OS X
 612   *-apple-darwin* )
 613     case "${canonical}" in
 614       *-apple-darwin[0-9].*) unported=yes ;;
 615       i[3456]86-* | x86_64-* )  ;;
 616       * )            unported=yes ;;
 617     esac
 618     opsys=darwin
 619     ## FIXME: Find a way to use Fink if available (Bug#11507).
 620   ;;
 621
 622   ## Chromium Native Client
 623   *-nacl )
 624     opsys=nacl
 625   ;;
 626
 627   ## Cygwin ports
 628   *-*-cygwin )
 629     opsys=cygwin
 630   ;;
 631
 632   ## HP 9000 series 700 and 800, running HP/UX
 633   hppa*-hp-hpux10.2* )
 634     opsys=hpux10-20
 635   ;;
 636   hppa*-hp-hpux1[1-9]* )
 637     opsys=hpux11
 638     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 639   ;;
 640
 641   ## IBM machines
 642   rs6000-ibm-aix4.[23]* )
 643     opsys=aix4-2
 644   ;;
 645   powerpc-ibm-aix4.[23]*  )
 646     opsys=aix4-2
 647   ;;
 648   rs6000-ibm-aix[56]* )
 649     opsys=aix4-2
 650   ;;
 651   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 652     opsys=aix4-2
 653   ;;
 654
 655   ## Suns
 656   *-sun-solaris* \
 657     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 658     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 659     case "${canonical}" in
 660       i[3456]86-*-* )   ;;
 661       amd64-*-*|x86_64-*-*) ;;
 662       sparc* )          ;;
 663       * )               unported=yes ;;
 664     esac
 665     case "${canonical}" in
 666       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 667                 opsys=sol2-10
 668                 emacs_check_sunpro_c=yes
 669                 ;;
 670       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 671       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 672       *-sunos5.6* | *-solaris2.6* )
 673                 opsys=sol2-6
 674                 RANLIB="ar -ts"
 675                 ;;
 676       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 677       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 678                 opsys=sol2-6
 679                 emacs_check_sunpro_c=yes
 680                 ;;
 681     esac
 682     ## Watch out for a compiler that we know will not work.
 683     case "${canonical}" in
 684      *-solaris* | *-sunos5* )
 685                 if [ "x$CC" = x/usr/ucb/cc ]; then
 686                   ## /usr/ucb/cc doesn't work;
 687                   ## we should find some other compiler that does work.
 688                   unset CC
 689                 fi
 690                 ;;
 691       *) ;;
 692     esac
 693   ;;
 694
 695   ## Intel 386 machines where we don't care about the manufacturer.
 696   i[3456]86-*-* )
 697     case "${canonical}" in
 698       *-darwin* )               opsys=darwin ;;
 699       *-mingw* )
 700                 opsys=mingw32
 701                 # MinGW overrides and adds some system headers in nt/inc.
 702                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 703                 ;;
 704       *-sysv4.2uw* )            opsys=unixware ;;
 705       *-sysv5uw* )              opsys=unixware ;;
 706       *-sysv5OpenUNIX* )        opsys=unixware ;;
 707       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 708     esac
 709   ;;
 710
 711   # MinGW64
 712   x86_64-*-* )
 713     case "${canonical}" in
 714       *-mingw* )
 715                 opsys=mingw32
 716                 # MinGW overrides and adds some system headers in nt/inc.
 717                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 718                 ;;
 719       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 720     esac
 721   ;;
 722
 723   * )
 724     unported=yes
 725   ;;
 726 esac
 727
 728 ### If the code above didn't choose an operating system, just choose
 729 ### an operating system based on the configuration name.  You really
 730 ### only want to use this when you have no idea what the right
 731 ### operating system is; if you know what operating systems a machine
 732 ### runs, it's cleaner to make it explicit in the case statement
 733 ### above.
 734 if test x"${opsys}" = x; then
 735   case "${canonical}" in
 736     *-gnu* )                            opsys=gnu ;;
 737     * )
 738       unported=yes
 739     ;;
 740   esac
 741 fi
 742
 743 ]
 744 dnl quotation ends
 745
 746 if test $unported = yes; then
 747   AC_MSG_ERROR([Emacs does not support '${canonical}' systems.
 748 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 749 Check 'etc/MACHINES' for recognized configuration names.])
 750 fi
 751
 752 #### Choose a compiler.
 753
 754 dnl Don't bother to test for C89.
 755 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 756
 757 dnl Sets GCC=yes if using gcc.
 758 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 759 if test -n "$XCRUN"; then
 760   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 761   test -n "$AR" && export AR
 762 fi
 763
 764 dnl Emacs needs C99 or later.
 765 gl_PROG_CC_C99
 766
 767 AM_PROG_CC_C_O
 768
 769 if test x$GCC = xyes; then
 770   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 771 fi
 772
 773 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 774 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 775 dnl that clash with MinGW.
 776 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 777
 778 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 779 AC_DEFUN([gl_CRYPTO_CHECK])
 780 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 781 # as we don't use them.
 782 AC_DEFUN([gl_FCNTL_O_FLAGS])
 783 # Avoid gnulib's test for pthread_sigmask.
 784 funcs=
 785 for func in $ac_func_list; do
 786   test $func = pthread_sigmask || AS_VAR_APPEND([funcs], [" $func"])
 787 done
 788 ac_func_list=$funcs
 789 # Use the system putenv even if it lacks GNU features, as we don't need them,
 790 # and the gnulib replacement runs afoul of a FreeBSD 10.1 bug; see Bug#19874.
 791 AC_CHECK_FUNCS_ONCE([putenv])
 792 AC_DEFUN([gl_FUNC_PUTENV],
 793   [test "$ac_cv_func_putenv" = yes || REPLACE_PUTENV=1])
 794
 795 # Initialize gnulib right after choosing the compiler.
 796 dnl Amongst other things, this sets AR and ARFLAGS.
 797 gl_EARLY
 798
 799 if test "$ac_test_CFLAGS" != set; then
 800   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 801   # if -g3 works and the user does not specify CFLAGS.
 802   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 803   case $CFLAGS in
 804     '-g')
 805       emacs_g3_CFLAGS='-g3';;
 806     '-g -O2')
 807       emacs_g3_CFLAGS='-g3 -O2';;
 808     *)
 809       emacs_g3_CFLAGS='';;
 810   esac
 811   if test -n "$emacs_g3_CFLAGS"; then
 812     emacs_save_CFLAGS=$CFLAGS
 813     CFLAGS=$emacs_g3_CFLAGS
 814     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 815       [emacs_cv_prog_cc_g3],
 816       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 817          [emacs_cv_prog_cc_g3=yes],
 818          [emacs_cv_prog_cc_g3=no])])
 819     if test $emacs_cv_prog_cc_g3 != yes; then
 820       CFLAGS=$emacs_save_CFLAGS
 821     fi
 822     if test $opsys = mingw32; then
 823       CFLAGS="$CFLAGS -gdwarf-2"
 824     fi
 825   fi
 826
 827   case $CFLAGS in
 828     *-O*) ;;
 829     *)
 830       # No optimization flag was inferred for this non-GCC compiler.
 831       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 832       emacs_save_CFLAGS=$CFLAGS
 833       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 834       CFLAGS=${CFLAGS}-O
 835       AC_CACHE_CHECK([whether $CC accepts -O],
 836         [emacs_cv_prog_cc_o],
 837         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 838            [emacs_cv_prog_cc_o=yes],
 839            [emacs_cv_prog_cc_o=no])])
 840       if test $emacs_cv_prog_cc_o != yes; then
 841         CFLAGS=$emacs_save_CFLAGS
 842       fi ;;
 843   esac
 844 fi
 845
 846 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 847 # ---------------------------------------------------------------------------
 848 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 849 # Otherwise, run RUN-IF-NOT-FOUND.
 850 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 851   [AC_PREPROC_IFELSE(
 852     [AC_LANG_PROGRAM(
 853       [[
 854 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 855 /* ok */
 856 #else
 857 # error "your version of gcc is older than $1.$2"
 858 #endif
 859       ]]),
 860     ], [$3], [$4])
 861   ]
 862 )
 863
 864 AC_ARG_ENABLE([gcc-warnings],
 865   [AS_HELP_STRING([--enable-gcc-warnings@<:@=TYPE@:>@],
 866                   [control generation of GCC warnings.  The TYPE 'yes'
 867                    means to fail if any warnings are issued; 'warn-only'
 868                    means issue warnings without failing (default for
 869                    developer builds); 'no' means disable warnings
 870                    (default for non-developer builds).])],
 871   [case $enableval in
 872      yes|no|warn-only) ;;
 873      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 874    esac
 875    gl_gcc_warnings=$enableval],
 876   [# By default, use 'warn-only' if it looks like the invoker of 'configure'
 877    # is a developer as opposed to a builder.  This is most likely true
 878    # if GCC is recent enough and there is a .git directory or file;
 879    # however, if there is also a .tarball-version file it is probably
 880    # just a release imported into Git for patch management.
 881    gl_gcc_warnings=no
 882    if test -e "$srcdir"/.git && test ! -f "$srcdir"/.tarball-version; then
 883      gl_GCC_VERSION_IFELSE([5], [3], [gl_gcc_warnings=warn-only])]
 884    fi
 885 )
 886
 887 # clang is unduly picky about some things.
 888 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 889   [AC_COMPILE_IFELSE(
 890      [AC_LANG_PROGRAM([[
 891           #ifndef __clang__
 892             error "not clang";
 893           #endif
 894         ]])],
 895      [emacs_cv_clang=yes],
 896      [emacs_cv_clang=no])])
 897
 898 # When compiling with GCC, prefer -isystem to -I when including system
 899 # include files, to avoid generating useless diagnostics for the files.
 900 AS_IF([test $gl_gcc_warnings = no],
 901  [
 902   isystem='-I'
 903   AS_IF([test "$emacs_cv_clang" = yes],
 904    [
 905      # Turn off some warnings if supported.
 906      gl_WARN_ADD([-Wno-switch])
 907      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 908      gl_WARN_ADD([-Wno-pointer-sign])
 909      gl_WARN_ADD([-Wno-string-plus-int])
 910      gl_WARN_ADD([-Wno-unknown-attributes])
 911    ])
 912  ],[
 913   isystem='-isystem '
 914
 915   # This, $nw, is the list of warnings we disable.
 916   nw=
 917
 918   case $with_x_toolkit in
 919     lucid | athena | motif)
 920        # Old toolkits mishandle 'const'.
 921        nw="$nw -Wwrite-strings"
 922        ;;
 923   esac
 924   AS_IF([test $gl_gcc_warnings = yes],
 925     [gl_WARN_ADD([-Werror], [WERROR_CFLAGS])])
 926   AC_SUBST([WERROR_CFLAGS])
 927
 928   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 929   nw="$nw -Woverlength-strings"     # Not a problem these days
 930   nw="$nw -Wformat-nonliteral"      # we do this a lot
 931   nw="$nw -Wvla"                    # Emacs uses <vla.h>.
 932   nw="$nw -Wswitch-default"         # Too many warnings for now
 933   nw="$nw -Wunused-const-variable=2" # lisp.h declares const objects.
 934   nw="$nw -Winline"                 # OK to ignore 'inline'
 935   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 936                                     # signed overflow has undefined behavior
 937   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 938   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 939   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 940
 941   # Emacs doesn't care about shadowing; see
 942   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 943   nw="$nw -Wshadow"
 944
 945   # Emacs's use of alloca inhibits protecting the stack.
 946   nw="$nw -Wstack-protector"
 947
 948   # Emacs's use of partly-const functions such as Fgnutls_available_p
 949   # make this option problematic.
 950   nw="$nw -Wsuggest-attribute=const"
 951
 952   # Emacs's use of partly-pure functions such as CHECK_TYPE make this
 953   # option problematic.
 954   nw="$nw -Wsuggest-attribute=pure"
 955
 956   # This part is merely for shortening the command line,
 957   # since -Wall implies -Wswitch.
 958   nw="$nw -Wswitch"
 959
 960   # This part is merely for shortening the command line,
 961   # since -Wno-FOO needs to be added below regardless.
 962   nw="$nw -Wmissing-field-initializers"
 963   nw="$nw -Wtype-limits"
 964   nw="$nw -Wunused-parameter"
 965
 966   if test $emacs_cv_clang = yes; then
 967     nw="$nw -Wcast-align"
 968   fi
 969
 970   # This causes too much noise in the MinGW build
 971   if test $opsys = mingw32; then
 972     nw="$nw -Wpointer-sign"
 973   fi
 974
 975   gl_MANYWARN_ALL_GCC([ws])
 976   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 977   for w in $ws; do
 978     gl_WARN_ADD([$w])
 979   done
 980   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 981   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 982   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 983   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 984   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 985   gl_WARN_ADD([-Wno-format-nonliteral])
 986
 987   # More things that clang is unduly picky about.
 988   if test $emacs_cv_clang = yes; then
 989     gl_WARN_ADD([-Wno-tautological-compare])
 990     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 991   fi
 992
 993   # This causes too much noise in the MinGW build
 994   if test $opsys = mingw32; then
 995     gl_WARN_ADD([-Wno-pointer-sign])
 996   fi
 997
 998   AC_DEFINE([GCC_LINT], [1], [Define to 1 if --enable-gcc-warnings.])
 999   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
1000   AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
1001   [/* Enable compile-time and run-time bounds-checking, and some warnings,
1002       without upsetting glibc 2.15+. */
1003    #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
1004         && defined __OPTIMIZE__ && __OPTIMIZE__)
1005    # define _FORTIFY_SOURCE 2
1006    #endif
1007   ])
1008
1009   # We use a slightly smaller set of warning options for lib/.
1010   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
1011   nw=
1012   nw="$nw -Wunused-macros"
1013
1014   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
1015   AC_SUBST([GNULIB_WARN_CFLAGS])
1016  ])
1017
1018 edit_cflags="
1019   s,///*,/,g
1020   s/^/ /
1021   s/ -I/ $isystem/g
1022   s/^ //
1023 "
1024
1025 AC_ARG_ENABLE(link-time-optimization,
1026 [AS_HELP_STRING([--enable-link-time-optimization],
1027                 [build emacs with link-time optimization.
1028                  This requires GCC 4.5.0 or later, or clang.
1029                  (Note that clang support is experimental - see INSTALL.)
1030                  It also makes Emacs harder to debug, and when we tried it
1031                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
1032                  recommended for typical use.])],
1033 if test "${enableval}" != "no"; then
1034    ac_lto_supported=no
1035    if test $emacs_cv_clang = yes; then
1036       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
1037       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
1038       if test -x "$GOLD_PLUGIN"; then
1039          LTO="-flto"
1040       fi
1041    elif test x$GCC = xyes; then
1042       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
1043       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
1044       if test x$CPUS != x; then
1045          LTO="-flto=$CPUS"
1046       else
1047          LTO="-flto"
1048       fi
1049    else
1050       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
1051    fi
1052    if test -z "$LTO"; then
1053       ac_lto_supported=no
1054    else
1055       old_CFLAGS=$CFLAGS
1056       CFLAGS="$CFLAGS $LTO"
1057       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1058          [ac_lto_supported=yes], [ac_lto_supported=no])
1059          CFLAGS="$old_CFLAGS"
1060    fi
1061    AC_MSG_RESULT([$ac_lto_supported])
1062    if test "$ac_lto_supported" = "yes"; then
1063       CFLAGS="$CFLAGS $LTO"
1064       if test x$emacs_cv_clang = xyes; then
1065          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
1066          # WARNING: 'ar --plugin ...' doesn't work without
1067          # command, so plugin name is appended to ARFLAGS.
1068          ARFLAGS="cru --plugin $GOLD_PLUGIN"
1069          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
1070       else
1071         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
1072         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
1073         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
1074         dnl dump core on Fedora 20, so play it safe for now.
1075         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
1076           [CFLAGS="$CFLAGS -ffat-lto-objects"])
1077       fi
1078    fi
1079 fi)
1080
1081 dnl Prefer silent make output.  For verbose output, use
1082 dnl 'configure --disable-silent-rules' or 'make V=1' .
1083 AM_SILENT_RULES([yes])
1084 dnl Port to Automake 1.11.
1085 dnl This section can be removed once we assume Automake 1.14 or later.
1086 : ${AM_V=$AM_DEFAULT_VERBOSITY}
1087 : ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
1088 AC_SUBST([AM_V])
1089 AM_SUBST_NOTMAKE([AM_V])
1090 AC_SUBST([AM_DEFAULT_V])
1091 AM_SUBST_NOTMAKE([AM_DEFAULT_V])
1092 AC_SUBST([AM_DEFAULT_VERBOSITY])
1093
1094 dnl Some other nice autoconf tests.
1095 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
1096 dnl AC_PROG_INSTALL
1097 dnl AC_PROG_MKDIR_P
1098 dnl if test "x$RANLIB" = x; then
1099 dnl   AC_PROG_RANLIB
1100 dnl fi
1101
1102
1103 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
1104 dnl can be made to directories.  This is not relevant for our usage, and
1105 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1106 dnl hosted on AFS, both examples where simple links work, but links to
1107 dnl directories fail.  We use a cut-down version instead.
1108 dnl AC_PROG_LN_S
1109
1110 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1111 rm -f conf$$ conf$$.file
1112
1113 LN_S_FILEONLY='cp -p'
1114
1115 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1116 dnl random program in the current directory.
1117 if (echo >conf$$.file) 2>/dev/null; then
1118   if ln -s conf$$.file conf$$ 2>/dev/null; then
1119     if test "$opsys" = "mingw32"; then
1120       LN_S_FILEONLY='/bin/ln -s'
1121     else
1122       LN_S_FILEONLY='ln -s'
1123     fi
1124   elif ln conf$$.file conf$$ 2>/dev/null; then
1125     if test "$opsys" = "mingw32"; then
1126       LN_S_FILEONLY=/bin/ln
1127     else
1128       LN_S_FILEONLY=ln
1129     fi
1130   fi
1131 fi
1132
1133 rm -f conf$$ conf$$.file
1134
1135 if test "$LN_S_FILEONLY" = "ln -s"; then
1136    AC_MSG_RESULT([yes])
1137 else
1138    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1139 fi
1140
1141 AC_SUBST(LN_S_FILEONLY)
1142
1143
1144 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1145 dnl doesn't support links to directories, as in "ln file dir".  But that
1146 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1147 dnl executables at "make install" time.
1148 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1149 dnl for more details.
1150 if test "$opsys" = "mingw32"; then
1151   LN_S="/bin/ln"
1152 fi
1153
1154 dnl On some Debian versions, "install-info" prints irritating messages
1155 dnl "This is not dpkg install-info anymore, but GNU install-info"
1156 dnl if called via an absolute file name.
1157 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1158 dnl Sadly some people may have an old ginstall-info installed on
1159 dnl non-Debian systems, so we can't use this.
1160 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1161 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1162
1163 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1164   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1165 dnl Don't use GZIP, which is used by gzip for additional parameters.
1166 AC_PATH_PROG(GZIP_PROG, gzip)
1167
1168 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1169    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1170
1171 PAXCTL_dumped=
1172 PAXCTL_notdumped=
1173 if test $opsys = gnu-linux; then
1174   if test "${SETFATTR+set}" != set; then
1175     AC_CACHE_CHECK([for setfattr],
1176       [emacs_cv_prog_setfattr],
1177       [touch conftest.tmp
1178        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1179          emacs_cv_prog_setfattr=yes
1180        else
1181          emacs_cv_prog_setfattr=no
1182        fi])
1183     if test "$emacs_cv_prog_setfattr" = yes; then
1184       PAXCTL_notdumped='$(SETFATTR) -n user.pax.flags -v er'
1185       SETFATTR=setfattr
1186     else
1187       SETFATTR=
1188     fi
1189     rm -f conftest.tmp
1190     AC_SUBST([SETFATTR])
1191   fi
1192 fi
1193 case $opsys,$PAXCTL_notdumped in
1194   gnu-linux, | netbsd,)
1195     AC_PATH_PROG([PAXCTL], [paxctl], [],
1196       [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1197     if test -n "$PAXCTL"; then
1198       if test "$opsys" = netbsd; then
1199         PAXCTL_dumped='$(PAXCTL) +a'
1200         PAXCTL_notdumped=$PAXCTL_dumped
1201       else
1202         AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1203         AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1204           [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then
1205              AC_MSG_RESULT([yes])
1206            else
1207              AC_MSG_RESULT([no])
1208              PAXCTL=
1209            fi])
1210         if test -n "$PAXCTL"; then
1211           PAXCTL_dumped='$(PAXCTL) -zex'
1212           PAXCTL_notdumped='$(PAXCTL) -r'
1213         fi
1214       fi
1215     fi;;
1216 esac
1217 AC_SUBST([PAXCTL_dumped])
1218 AC_SUBST([PAXCTL_notdumped])
1219
1220 ## Need makeinfo >= 4.7 (?) to build the manuals.
1221 if test "$MAKEINFO" != "no"; then
1222   if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
1223     MAKEINFO=makeinfo
1224   fi
1225   case `($MAKEINFO --version) 2>/dev/null` in
1226     *' (GNU texinfo) '4.[[7-9]]* | \
1227     *' (GNU texinfo) '4.[[1-9][0-9]]* | \
1228     *' (GNU texinfo) '[[5-9]]* | \
1229     *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1230     *) MAKEINFO=no;;
1231   esac
1232 fi
1233
1234 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1235 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1236 ## therefore in the category of "special tools" not normally required, which
1237 ## configure does not have to check for (eg autoconf itself).
1238 ## In a repository checkout on the other hand, the manuals are not included.
1239 ## So makeinfo is a requirement to build from the repository, and configure
1240 ## should test for it as it does for any other build requirement.
1241 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1242 ## with pre-built manuals, from a repository checkout.
1243 HAVE_MAKEINFO=yes
1244
1245 if test "$MAKEINFO" = "no"; then
1246   MAKEINFO=makeinfo
1247   if test "x${with_makeinfo}" = "xno"; then
1248     HAVE_MAKEINFO=no
1249   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1250     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1251 source tree does not seem to have pre-built manuals in the 'info' directory.
1252 Either install a suitable version of makeinfo, or re-run configure
1253 with the '--without-makeinfo' option to build without the manuals.] )
1254   fi
1255 fi
1256 AC_SUBST(HAVE_MAKEINFO)
1257
1258 if test $opsys = mingw32; then
1259    DOCMISC_W32=efaq-w32
1260 else
1261    DOCMISC_W32=
1262 fi
1263 AC_SUBST(DOCMISC_W32)
1264
1265 dnl Add our options to ac_link now, after it is set up.
1266
1267 if test x$GCC = xyes; then
1268   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1269     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1270 else
1271   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1272     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1273 fi
1274
1275 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1276 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1277 dnl Treat GCC specially since it just gives a non-fatal 'unrecognized option'
1278 dnl if not built to support GNU ld.
1279
1280 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1281 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1282 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1283 dnl   Eg "make LDFLAGS=... all" could run into problems,
1284 dnl   http://bugs.debian.org/684788
1285 dnl * unnecessary, since temacs is the only thing that actually needs it.
1286 dnl   Indeed this is where it was originally, prior to:
1287 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1288 late_LDFLAGS="$LDFLAGS"
1289 if test x$GCC = xyes; then
1290   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1291 else
1292   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1293 fi
1294
1295 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1296
1297 AC_MSG_CHECKING([for -znocombreloc])
1298 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1299   [AC_MSG_RESULT(yes)],
1300   LDFLAGS_NOCOMBRELOC=
1301   [AC_MSG_RESULT(no)])
1302
1303 LDFLAGS="$late_LDFLAGS"
1304
1305 AC_CACHE_CHECK([whether addresses are sanitized],
1306   [emacs_cv_sanitize_address],
1307   [AC_COMPILE_IFELSE(
1308      [AC_LANG_PROGRAM(
1309         [[#ifndef __has_feature
1310           #define __has_feature(f) 0
1311           #endif
1312           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1313           #else
1314            error "Addresses are not sanitized.";
1315           #endif
1316         ]])],
1317      [emacs_cv_sanitize_address=yes],
1318      [emacs_cv_sanitize_address=no])])
1319
1320 dnl The function dump-emacs will not be defined and temacs will do
1321 dnl (load "loadup") automatically unless told otherwise.
1322 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1323 case "$opsys" in
1324   nacl) CANNOT_DUMP=yes ;;
1325 esac
1326
1327 if test "$CANNOT_DUMP" = "yes"; then
1328   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1329 elif test "$emacs_cv_sanitize_address" = yes; then
1330   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1331 fi
1332
1333 AC_SUBST(CANNOT_DUMP)
1334
1335
1336 UNEXEC_OBJ=unexelf.o
1337 case "$opsys" in
1338   # MSDOS uses unexcoff.o
1339   aix4-2)
1340    UNEXEC_OBJ=unexaix.o
1341    ;;
1342   cygwin)
1343    UNEXEC_OBJ=unexcw.o
1344    ;;
1345   darwin)
1346    UNEXEC_OBJ=unexmacosx.o
1347    ;;
1348   hpux10-20 | hpux11)
1349    UNEXEC_OBJ=unexhp9k800.o
1350    ;;
1351   mingw32)
1352    UNEXEC_OBJ=unexw32.o
1353    ;;
1354   sol2-10)
1355    # Use the Solaris dldump() function, called from unexsol.c, to dump
1356    # emacs, instead of the generic ELF dump code found in unexelf.c.
1357    # The resulting binary has a complete symbol table, and is better
1358    # for debugging and other observability tools (debuggers, pstack, etc).
1359    #
1360    # If you encounter a problem using dldump(), please consider sending
1361    # a message to the OpenSolaris tools-linking mailing list:
1362    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1363    #
1364    # It is likely that dldump() works with older Solaris too, but this has
1365    # not been tested, so for now this change is for Solaris 10 or newer.
1366    UNEXEC_OBJ=unexsol.o
1367    ;;
1368 esac
1369
1370 LD_SWITCH_SYSTEM=
1371 case "$opsys" in
1372   freebsd|dragonfly)
1373    ## Let 'ld' find image libs and similar things in /usr/local/lib.
1374    ## The system compiler, GCC, has apparently been modified to not
1375    ## look there, contrary to what a stock GCC would do.
1376 ### It's not our place to do this.  See bug#10313#17.
1377 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1378       :
1379    ;;
1380
1381   gnu-linux)
1382    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1383    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1384    ;;
1385
1386   netbsd)
1387 ### It's not our place to do this.  See bug#10313#17.
1388 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1389       :
1390    ;;
1391
1392   openbsd)
1393    ## Han Boetes <han@boetes.org> says this is necessary,
1394    ## otherwise Emacs dumps core on elf systems.
1395    LD_SWITCH_SYSTEM="-Z"
1396    ;;
1397 esac
1398 AC_SUBST(LD_SWITCH_SYSTEM)
1399
1400 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1401
1402 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1403 ## which has not been defined yet.  When this was handled with cpp,
1404 ## it was expanded to null when configure sourced the s/*.h file.
1405 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1406 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1407 ## (or somesuch), but because it is supposed to go at the _front_
1408 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1409 ## Compare with the gnu-linux case below, which added to the end
1410 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1411 ## LD_SWITCH_SYSTEM_TEMACS.
1412 case "$opsys" in
1413   netbsd|openbsd)
1414    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1415 esac
1416
1417
1418 C_SWITCH_MACHINE=
1419 case $canonical in
1420  alpha*)
1421   AC_CHECK_DECL([__ELF__])
1422   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1423     ## With ELF, make sure that all common symbols get allocated to in the
1424     ## data section.  Otherwise, the dump of temacs may miss variables in
1425     ## the shared library that have been initialized.  For example, with
1426     ## GNU libc, __malloc_initialized would normally be resolved to the
1427     ## shared library's .bss section, which is fatal.
1428     if test "x$GCC" = "xyes"; then
1429       C_SWITCH_MACHINE="-fno-common"
1430     else
1431       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1432     fi
1433   else
1434       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1435       dnl albeit under the mistaken assumption that said file
1436       dnl was no longer used.
1437       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1438   fi
1439   ;;
1440 esac
1441 AC_SUBST(C_SWITCH_MACHINE)
1442
1443 AC_SUBST(UNEXEC_OBJ)
1444
1445 C_SWITCH_SYSTEM=
1446 ## Some programs in src produce warnings saying certain subprograms
1447 ## are too complex and need a MAXMEM value greater than 2000 for
1448 ## additional optimization.  --nils@exp-math.uni-essen.de
1449 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1450   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1451 if test "$opsys" = "mingw32"; then
1452   case "$canonical" in
1453     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1454     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1455   esac
1456 fi
1457 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1458 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1459 AC_SUBST(C_SWITCH_SYSTEM)
1460
1461
1462 LIBS_SYSTEM=
1463 case "$opsys" in
1464   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1465   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1466
1467   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1468
1469   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1470
1471   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1472
1473   ## Motif needs -lgen.
1474   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1475 esac
1476
1477 AC_SUBST(LIBS_SYSTEM)
1478
1479 ### Make sure subsequent tests use flags consistent with the build flags.
1480
1481 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1482   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1483 else
1484   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1485 fi
1486
1487 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1488 AC_DEFUN([AC_TYPE_SIZE_T])
1489 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1490 AC_DEFUN([AC_TYPE_UID_T])
1491
1492 # sqrt and other floating-point functions such as fmod and frexp
1493 # are found in -lm on many systems.
1494 OLD_LIBS=$LIBS
1495 AC_SEARCH_LIBS([sqrt], [m])
1496 if test "X$LIBS" = "X$OLD_LIBS"; then
1497   LIB_MATH=
1498 else
1499   LIB_MATH=$ac_cv_search_sqrt
1500 fi
1501 LIBS=$OLD_LIBS
1502
1503 dnl Current possibilities handled by sed (aix4-2 -> aix,
1504 dnl gnu-linux -> gnu/linux, etc.):
1505 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux.
1506 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1507 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1508
1509 case $opsys in
1510   cygwin )
1511     LIB_MATH=
1512     ;;
1513   darwin )
1514     ## Adding -lm confuses the dynamic linker, so omit it.
1515     LIB_MATH=
1516     ;;
1517   freebsd | dragonfly )
1518     SYSTEM_TYPE=berkeley-unix
1519     ;;
1520   gnu-linux | gnu-kfreebsd )
1521     ;;
1522   hpux10-20 | hpux11 )
1523     ;;
1524   mingw32 )
1525     LIB_MATH=
1526     SYSTEM_TYPE=windows-nt
1527     ;;
1528   dnl NB this may be adjusted below.
1529   netbsd | openbsd )
1530     SYSTEM_TYPE=berkeley-unix
1531     ;;
1532
1533   sol2* | unixware )
1534     SYSTEM_TYPE=usg-unix-v
1535     ;;
1536
1537 esac
1538
1539 AC_SUBST(LIB_MATH)
1540 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1541   [The type of system you are compiling for; sets 'system-type'.])
1542
1543
1544 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1545 pre_PKG_CONFIG_LIBS=$LIBS
1546
1547 PKG_PROG_PKG_CONFIG(0.9.0)
1548
1549 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1550 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1551 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1552 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1553 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1554 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1555 dnl actions.
1556 AC_DEFUN([EMACS_CHECK_MODULES],
1557   [PKG_CHECK_MODULES([$1], [$2],
1558      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1559       m4_default([$3], [HAVE_$1=yes])],
1560      [m4_default([$4], [HAVE_$1=no])])])
1561
1562 HAVE_SOUND=no
1563 if test "${with_sound}" != "no"; then
1564   # Sound support for GNU/Linux, the free BSDs, MinGW, and Cygwin.
1565   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1566     have_sound_header=yes, [], [
1567     #ifdef __MINGW32__
1568     #define WIN32_LEAN_AND_MEAN
1569     #include <windows.h>
1570     #endif
1571     ])
1572   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1573     AC_MSG_ERROR([OSS sound support requested but not found.])
1574
1575   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1576     # Emulation library used on NetBSD.
1577     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1578     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1579       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1580     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1581     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1582   fi
1583   AC_SUBST(LIBSOUND)
1584
1585   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1586     ALSA_REQUIRED=1.0.0
1587     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1588     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1589     if test $HAVE_ALSA = yes; then
1590       SAVE_CFLAGS="$CFLAGS"
1591       SAVE_LIBS="$LIBS"
1592       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1593       LIBS="$ALSA_LIBS $LIBS"
1594       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1595                       emacs_alsa_normal=yes,
1596                     emacs_alsa_normal=no)
1597       if test "$emacs_alsa_normal" != yes; then
1598         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1599                        [[snd_lib_error_set_handler (0);]])],
1600                        emacs_alsa_subdir=yes,
1601                      emacs_alsa_subdir=no)
1602         if test "$emacs_alsa_subdir" != yes; then
1603           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1604         fi
1605         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1606       fi
1607
1608       CFLAGS="$SAVE_CFLAGS"
1609       LIBS="$SAVE_LIBS"
1610       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1611       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1612       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1613     elif test "${with_sound}" = "alsa"; then
1614       AC_MSG_ERROR([ALSA sound support requested but not found.])
1615     fi
1616   fi                            dnl with_sound = alsa|yes
1617
1618   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1619   dnl compiles only on the specified platforms.  For others, it
1620   dnl probably doesn't make sense to try.
1621   dnl FIXME So surely we should bypass this whole section if not using
1622   dnl one of these platforms?
1623   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1624      case "$opsys" in
1625        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1626        dnl Adjust the --with-sound help text if you change this.
1627        gnu-linux|freebsd|netbsd|mingw32|cygwin)
1628          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1629          HAVE_SOUND=yes
1630          ;;
1631      esac
1632   fi
1633
1634   AC_SUBST(CFLAGS_SOUND)
1635 fi
1636
1637 dnl checks for header files
1638 AC_CHECK_HEADERS_ONCE(
1639   malloc.h
1640   sys/systeminfo.h
1641   sys/sysinfo.h
1642   coff.h pty.h
1643   sys/resource.h
1644   sys/utsname.h pwd.h utmp.h util.h)
1645
1646 AC_MSG_CHECKING(if personality LINUX32 can be set)
1647 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1648                emacs_cv_personality_linux32=yes,
1649                emacs_cv_personality_linux32=no)
1650 AC_MSG_RESULT($emacs_cv_personality_linux32)
1651
1652 if test $emacs_cv_personality_linux32 = yes; then
1653   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1654             [Define to 1 if personality LINUX32 can be set.])
1655 fi
1656
1657 # Note that Solaris has sys/sysinfo.h which defines struct
1658 # sysinfo as well.  To make sure that we're using GNU/Linux
1659 # sysinfo, we explicitly set one of its fields.
1660 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1661   AC_MSG_CHECKING([if Linux sysinfo may be used])
1662   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1663                                      [[struct sysinfo si;
1664                                        si.totalram = 0;
1665                                        sysinfo (&si)]])],
1666     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1667   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1668   if test $emacs_cv_linux_sysinfo = yes; then
1669     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1670     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1671                                        [[struct sysinfo si; return si.mem_unit]])],
1672       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1673                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1674   fi
1675 fi
1676
1677 dnl On Solaris 8 there's a compilation warning for term.h because
1678 dnl it doesn't define 'bool'.
1679 AC_CHECK_HEADERS(term.h, , , -)
1680 AC_HEADER_TIME
1681 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1682                                       ]])
1683 if test $ac_cv_have_decl_sys_siglist != yes; then
1684   # For Tru64, at least:
1685   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1686                                           ]])
1687 fi
1688 AC_HEADER_SYS_WAIT
1689
1690 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1691 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1692 #if HAVE_SYS_SOCKET_H
1693 #include <sys/socket.h>
1694 #endif])
1695 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1696 #if HAVE_SYS_SOCKET_H
1697 #include <sys/socket.h>
1698 #endif])
1699 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1700 #if HAVE_SYS_SOCKET_H
1701 #include <sys/socket.h>
1702 #endif])
1703
1704 dnl checks for structure members
1705 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1706                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1707                   struct ifreq.ifr_addr,
1708                   struct ifreq.ifr_addr.sa_len], , ,
1709                  [AC_INCLUDES_DEFAULT
1710 #if HAVE_SYS_SOCKET_H
1711 #include <sys/socket.h>
1712 #endif
1713 #if HAVE_NET_IF_H
1714 #include <net/if.h>
1715 #endif])
1716
1717 dnl Check for endianness.
1718 dnl AC_C_BIGENDIAN is done by gnulib.
1719
1720 dnl check for Make feature
1721
1722 AUTO_DEPEND=no
1723 dnl check if we have GCC and autodepend is on.
1724 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1725    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1726    SAVE_CFLAGS="$CFLAGS"
1727    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1728    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1729    CFLAGS="$SAVE_CFLAGS"
1730    test -f deps.d || ac_enable_autodepend=no
1731    rm -rf deps.d
1732    AC_MSG_RESULT([$ac_enable_autodepend])
1733    if test $ac_enable_autodepend = yes; then
1734       AUTO_DEPEND=yes
1735    fi
1736 fi
1737 AC_SUBST(AUTO_DEPEND)
1738
1739 dnl checks for operating system services
1740 AC_SYS_LONG_FILE_NAMES
1741
1742 #### Choose a window system.
1743
1744 ## We leave window_system equal to none if
1745 ## we end up building without one.  Any new window system should
1746 ## set window_system to an appropriate value and add objects to
1747 ## window-system-specific substs.
1748
1749 window_system=none
1750 AC_PATH_X
1751 if test "$no_x" != yes; then
1752   window_system=x11
1753 fi
1754
1755 LD_SWITCH_X_SITE_RPATH=
1756 if test "${x_libraries}" != NONE; then
1757   if test -n "${x_libraries}"; then
1758     LD_SWITCH_X_SITE=-L`AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -L/g'`
1759     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`
1760       AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -Wl,-rpath,/g'
1761     `
1762   fi
1763   x_default_search_path=""
1764   x_search_path=${x_libraries}
1765   if test -z "${x_search_path}"; then
1766     x_search_path=/usr/lib
1767   fi
1768   for x_library in `AS_ECHO(["$x_search_path:"]) | \
1769                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1770     x_search_path="\
1771 ${x_library}/X11/%L/%T/%N%C%S:\
1772 ${x_library}/X11/%l/%T/%N%C%S:\
1773 ${x_library}/X11/%T/%N%C%S:\
1774 ${x_library}/X11/%L/%T/%N%S:\
1775 ${x_library}/X11/%l/%T/%N%S:\
1776 ${x_library}/X11/%T/%N%S"
1777     if test x"${x_default_search_path}" = x; then
1778       x_default_search_path=${x_search_path}
1779     else
1780       x_default_search_path="${x_search_path}:${x_default_search_path}"
1781     fi
1782   done
1783 fi
1784 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1785
1786 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1787   C_SWITCH_X_SITE=$isystem`AS_ECHO(["$x_includes"]) | sed -e "s/:/ $isystem/g"`
1788 fi
1789
1790 if test x"${x_includes}" = x; then
1791   bitmapdir=/usr/include/X11/bitmaps
1792 else
1793   # accumulate include directories that have X11 bitmap subdirectories
1794   bmd_acc=
1795   for bmd in `AS_ECHO(["$x_includes"]) | sed -e 's/:/ /g'`; do
1796     if test -d "${bmd}/X11/bitmaps"; then
1797       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1798     fi
1799     if test -d "${bmd}/bitmaps"; then
1800       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1801     fi
1802   done
1803   bitmapdir=${bmd_acc#:}
1804 fi
1805
1806 test "${with_ns}" = maybe && test "${opsys}" != darwin && with_ns=no
1807 HAVE_NS=no
1808 NS_GNUSTEP_CONFIG=no
1809 NS_IMPL_COCOA=no
1810 NS_IMPL_GNUSTEP=no
1811 tmp_CPPFLAGS="$CPPFLAGS"
1812 tmp_CFLAGS="$CFLAGS"
1813 CPPFLAGS="$CPPFLAGS -x objective-c"
1814 CFLAGS="$CFLAGS -x objective-c"
1815 GNU_OBJC_CFLAGS=
1816 LIBS_GNUSTEP=
1817 if test "${with_ns}" != no; then
1818   if test "${opsys}" = darwin; then
1819      NS_IMPL_COCOA=yes
1820      ns_appdir=`pwd`/nextstep/Emacs.app
1821      ns_appbindir=${ns_appdir}/Contents/MacOS
1822      ns_appresdir=${ns_appdir}/Contents/Resources
1823      ns_appsrc=Cocoa/Emacs.base
1824      ns_fontfile=macfont.o
1825   elif flags=$( (gnustep-config --objc-flags) 2>/dev/null); then
1826      NS_IMPL_GNUSTEP=yes
1827      NS_GNUSTEP_CONFIG=yes
1828      GNU_OBJC_CFLAGS=$flags
1829      LIBS_GNUSTEP=$(gnustep-config --gui-libs) || exit
1830   elif test -f $GNUSTEP_CONFIG_FILE; then
1831      NS_IMPL_GNUSTEP=yes
1832      dnl FIXME sourcing this several times in subshells seems inefficient.
1833      GNUSTEP_SYSTEM_HEADERS=$(
1834        . $GNUSTEP_CONFIG_FILE
1835        AS_ECHO(["$GNUSTEP_SYSTEM_HEADERS"])
1836      )
1837      GNUSTEP_SYSTEM_LIBRARIES=$(
1838        . $GNUSTEP_CONFIG_FILE
1839        AS_ECHO(["$GNUSTEP_SYSTEM_LIBRARIES"])
1840      )
1841      dnl I seemed to need these as well with GNUstep-startup 0.25.
1842      GNUSTEP_LOCAL_HEADERS=$(
1843        . $GNUSTEP_CONFIG_FILE
1844        AS_ECHO(["$GNUSTEP_LOCAL_HEADERS"])
1845      )
1846      GNUSTEP_LOCAL_LIBRARIES=$(
1847        . $GNUSTEP_CONFIG_FILE
1848        AS_ECHO(["$GNUSTEP_LOCAL_LIBRARIES"])
1849      )
1850      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1851        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1852      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1853        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1854      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1855      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1856      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1857      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1858      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1859      dnl If they had chosen to either define it or not, we could have
1860      dnl just used AC_CHECK_DECL here.
1861      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1862        emacs_cv_objc_exceptions,
1863 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1864 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1865 1;
1866 #else
1867 fail;
1868 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1869      if test $emacs_cv_objc_exceptions = yes; then
1870        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1871        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1872          [Define if GNUstep uses ObjC exceptions.])
1873        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1874      fi
1875   fi
1876   if test $NS_IMPL_GNUSTEP = yes; then
1877      ns_appdir=`pwd`/nextstep/Emacs.app
1878      ns_appbindir=${ns_appdir}
1879      ns_appresdir=${ns_appdir}/Resources
1880      ns_appsrc=GNUstep/Emacs.base
1881      ns_fontfile=nsfont.o
1882   fi
1883
1884   dnl This is only used while we test the NS headers, it gets reset below.
1885   CPPFLAGS="$CPPFLAGS $GNU_OBJC_CFLAGS"
1886   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1887
1888   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1889                   [AC_MSG_ERROR([The include files (AppKit/AppKit.h etc) that
1890 are required for a Nextstep build are missing or cannot be compiled.
1891 Either fix this, or re-configure with the option '--without-ns'.])])
1892
1893   macfont_file=""
1894   if test "${NS_IMPL_COCOA}" = "yes"; then
1895     AC_MSG_CHECKING([for OSX 10.6 or newer])
1896     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1897                                      [
1898 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1899 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1060
1900  ; /* OK */
1901 #else
1902  error "OSX 10.6 or newer required";
1903 #endif
1904 #endif
1905                     ])],
1906                     ns_osx_have_106=yes,
1907                     ns_osx_have_106=no)
1908     AC_MSG_RESULT([$ns_osx_have_106])
1909
1910     if test $ns_osx_have_106 = no; then
1911        AC_MSG_ERROR([OSX 10.6 or newer is required]);
1912     fi
1913   fi
1914 fi
1915
1916 AC_SUBST(LIBS_GNUSTEP)
1917
1918 INSTALL_ARCH_INDEP_EXTRA=install-etc
1919 ns_self_contained=no
1920 NS_OBJ=
1921 NS_OBJC_OBJ=
1922 if test "${HAVE_NS}" = yes; then
1923   if test "$with_toolkit_scroll_bars" = "no"; then
1924     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1925   fi
1926
1927   window_system=nextstep
1928   # set up packaging dirs
1929   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1930      ns_self_contained=yes
1931      prefix=${ns_appresdir}
1932      exec_prefix=${ns_appbindir}
1933      dnl This one isn't really used, only archlibdir is.
1934      libexecdir="\${ns_appbindir}/libexec"
1935      archlibdir="\${ns_appbindir}/libexec"
1936      etcdocdir="\${ns_appresdir}/etc"
1937      etcdir="\${ns_appresdir}/etc"
1938      dnl FIXME maybe set datarootdir instead.
1939      dnl That would also get applications, icons, man.
1940      infodir="\${ns_appresdir}/info"
1941      mandir="\${ns_appresdir}/man"
1942      lispdir="\${ns_appresdir}/lisp"
1943      test "$locallisppathset" = no && locallisppath=""
1944      INSTALL_ARCH_INDEP_EXTRA=
1945   fi
1946
1947   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o $ns_fontfile"
1948 fi
1949 CFLAGS="$tmp_CFLAGS"
1950 CPPFLAGS="$tmp_CPPFLAGS"
1951 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1952 AC_SUBST(ns_self_contained)
1953 AC_SUBST(NS_OBJ)
1954 AC_SUBST(NS_OBJC_OBJ)
1955
1956 HAVE_W32=no
1957 W32_OBJ=
1958 W32_LIBS=
1959 EMACSRES=
1960 CLIENTRES=
1961 CLIENTW=
1962 W32_RES_LINK=
1963 EMACS_MANIFEST=
1964 UPDATE_MANIFEST=
1965 if test "${with_w32}" != no; then
1966   case "${opsys}" in
1967     cygwin)
1968       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1969              [AC_MSG_ERROR(['--with-w32' was specified, but windows.h
1970                    cannot be found.])])
1971     ;;
1972     mingw32)
1973     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1974     ;;
1975     *)
1976       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1977     ;;
1978   esac
1979 fi
1980
1981 if test "${opsys}" = "mingw32"; then
1982   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1983   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1984      #include <windows.h>
1985      #include <usp10.h>]],
1986    [[PIMAGE_NT_HEADERS pHeader;
1987      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1988    [emacs_cv_w32api=yes
1989     HAVE_W32=yes],
1990    emacs_cv_w32api=no)
1991   AC_MSG_RESULT($emacs_cv_w32api)
1992   if test "${emacs_cv_w32api}" = "no"; then
1993     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1994   fi
1995 fi
1996
1997 FIRSTFILE_OBJ=
1998 NTDIR=
1999 LIBS_ECLIENT=
2000 LIB_WSOCK32=
2001 NTLIB=
2002 CM_OBJ="cm.o"
2003 XARGS_LIMIT=
2004 if test "${HAVE_W32}" = "yes"; then
2005   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
2006   if test "$with_toolkit_scroll_bars" = "no"; then
2007     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for w32 build.])
2008   fi
2009   AC_CHECK_TOOL(WINDRES, [windres],
2010                 [AC_MSG_ERROR([No resource compiler found.])])
2011   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
2012   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
2013   EMACSRES="emacs.res"
2014   case "$canonical" in
2015     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
2016     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
2017   esac
2018   dnl Construct something of the form "24,4,0,0" with 4 components.
2019   comma_version=`echo "${PACKAGE_VERSION}.0.0" | sed -e 's/\./,/g' -e 's/^\([[^,]]*,[[^,]]*,[[^,]]*,[[^,]]*\).*/\1/'`
2020
2021   comma_space_version=`echo "$comma_version" | sed 's/,/, /g'`
2022   AC_SUBST(comma_version)
2023   AC_SUBST(comma_space_version)
2024   AC_CONFIG_FILES([nt/emacs.rc nt/emacsclient.rc])
2025   if test "${opsys}" = "cygwin"; then
2026     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
2027     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
2028     # Tell the linker that emacs.res is an object (which we compile from
2029     # the rc file), not a linker script.
2030     W32_RES_LINK="-Wl,emacs.res"
2031   else
2032     UPDATE_MANIFEST=update-game-score.exe.manifest
2033     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
2034     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
2035     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
2036     W32_RES_LINK="\$(EMACSRES)"
2037     CLIENTRES="emacsclient.res"
2038     CLIENTW="emacsclientw\$(EXEEXT)"
2039     FIRSTFILE_OBJ=firstfile.o
2040     NTDIR=nt
2041     CM_OBJ=
2042     LIBS_ECLIENT="-lcomctl32"
2043     LIB_WSOCK32="-lwsock32"
2044     NTLIB="ntlib.$ac_objext"
2045     XARGS_LIMIT="-s 10000"
2046   fi
2047 fi
2048 AC_SUBST(W32_OBJ)
2049 AC_SUBST(W32_LIBS)
2050 AC_SUBST(EMACSRES)
2051 AC_SUBST(EMACS_MANIFEST)
2052 AC_SUBST(UPDATE_MANIFEST)
2053 AC_SUBST(CLIENTRES)
2054 AC_SUBST(CLIENTW)
2055 AC_SUBST(W32_RES_LINK)
2056 AC_SUBST(FIRSTFILE_OBJ)
2057 AC_SUBST(NTDIR)
2058 AC_SUBST(CM_OBJ)
2059 AC_SUBST(LIBS_ECLIENT)
2060 AC_SUBST(LIB_WSOCK32)
2061 AC_SUBST(NTLIB)
2062 AC_SUBST(XARGS_LIMIT)
2063
2064 if test "${HAVE_W32}" = "yes"; then
2065   window_system=w32
2066   with_xft=no
2067 fi
2068
2069 ## $window_system is now set to the window system we will
2070 ## ultimately use.
2071
2072 term_header=
2073 HAVE_X_WINDOWS=no
2074 HAVE_X11=no
2075 USE_X_TOOLKIT=none
2076
2077 case "${window_system}" in
2078   x11 )
2079     HAVE_X_WINDOWS=yes
2080     HAVE_X11=yes
2081     term_header=xterm.h
2082     case "${with_x_toolkit}" in
2083       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
2084       motif ) USE_X_TOOLKIT=MOTIF ;;
2085       gtk ) with_gtk=yes
2086             term_header=gtkutil.h
2087 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
2088 dnl USE_X_TOOLKIT is set.
2089             USE_X_TOOLKIT=none ;;
2090       gtk2 ) with_gtk2=yes
2091              term_header=gtkutil.h
2092              USE_X_TOOLKIT=none ;;
2093       gtk3 ) with_gtk3=yes
2094              term_header=gtkutil.h
2095              USE_X_TOOLKIT=none ;;
2096       no ) USE_X_TOOLKIT=none ;;
2097 dnl If user did not say whether to use a toolkit, make this decision later:
2098 dnl use the toolkit if we have gtk, or X11R5 or newer.
2099       * ) USE_X_TOOLKIT=maybe ;;
2100     esac
2101   ;;
2102   nextstep )
2103     term_header=nsterm.h
2104   ;;
2105   w32 )
2106     term_header=w32term.h
2107   ;;
2108 esac
2109
2110 if test "$window_system" = none && test "X$with_x" != "Xno"; then
2111    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
2112    if test "$HAVE_XSERVER" = true ||
2113       test -n "$DISPLAY" ||
2114       {
2115         for emacs_libX11 in /usr/lib/libX11.*; do break; done
2116         test "$emacs_libX11" != '/usr/lib/libX11.*'
2117       }
2118    then
2119         AC_MSG_ERROR([You seem to be running X, but no X development libraries
2120 were found.  You should install the relevant development files for X
2121 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2122 sure you have development files for image handling, i.e.
2123 tiff, gif, jpeg, png and xpm.
2124 If you are sure you want Emacs compiled without X window support, pass
2125   --without-x
2126 to configure.])
2127    fi
2128 fi
2129
2130 # Does the opsystem file prohibit the use of the GNU malloc?
2131 # Assume not, until told otherwise.
2132 GNU_MALLOC=yes
2133
2134 AC_CACHE_CHECK(
2135   [whether malloc is Doug Lea style],
2136   [emacs_cv_var_doug_lea_malloc],
2137   [emacs_cv_var_doug_lea_malloc=no
2138    dnl Hooks do not work with address sanitization.
2139    if test "$emacs_cv_sanitize_address" != yes; then
2140      AC_LINK_IFELSE(
2141        [AC_LANG_PROGRAM(
2142           [[#include <malloc.h>
2143             static void hook (void) {}]],
2144           [[malloc_set_state (malloc_get_state ());
2145             __after_morecore_hook = hook;
2146             __malloc_initialize_hook = hook;]])],
2147        [emacs_cv_var_doug_lea_malloc=yes])
2148    fi])
2149 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2150
2151 system_malloc=$emacs_cv_sanitize_address
2152
2153 hybrid_malloc=
2154
2155 case "$opsys" in
2156   ## darwin ld insists on the use of malloc routines in the System framework.
2157   darwin | mingw32 | nacl | sol2-10) system_malloc=yes ;;
2158   cygwin) hybrid_malloc=yes;;
2159 esac
2160
2161 if test "${system_malloc}" != yes && test "${doug_lea_malloc}" != yes \
2162    && test "${UNEXEC_OBJ}" = unexelf.o; then
2163   hybrid_malloc=yes
2164 fi
2165
2166 GMALLOC_OBJ=
2167 HYBRID_MALLOC=
2168 if test "${system_malloc}" = "yes"; then
2169   AC_DEFINE([SYSTEM_MALLOC], 1,
2170     [Define to 1 to use the system memory allocator, even if it is not
2171      Doug Lea style.])
2172   GNU_MALLOC=no
2173   GNU_MALLOC_reason="
2174     (The GNU allocators don't work with this system configuration.)"
2175   VMLIMIT_OBJ=
2176 elif test "$hybrid_malloc" = yes; then
2177   AC_DEFINE(HYBRID_MALLOC, 1,
2178     [Define to use gmalloc before dumping and the system malloc after.])
2179   HYBRID_MALLOC=1
2180   GNU_MALLOC=
2181   GNU_MALLOC_reason="only before dumping"
2182   GMALLOC_OBJ=gmalloc.o
2183   VMLIMIT_OBJ=
2184 else
2185   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2186   VMLIMIT_OBJ=vm-limit.o
2187
2188   AC_CHECK_HEADERS([sys/vlimit.h])
2189   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2190     [AC_LINK_IFELSE(
2191        [AC_LANG_PROGRAM(
2192          [[extern char data_start[]; char ch;]],
2193          [[return data_start < &ch;]])],
2194        [emacs_cv_data_start=yes],
2195        [emacs_cv_data_start=no])])
2196   if test $emacs_cv_data_start = yes; then
2197     AC_DEFINE([HAVE_DATA_START], 1,
2198       [Define to 1 if data_start is the address of the start
2199        of the main data segment.])
2200   fi
2201 fi
2202 AC_SUBST([HYBRID_MALLOC])
2203 AM_CONDITIONAL([HYBRID_MALLOC_LIB], [test -n "$HYBRID_MALLOC"])
2204 AC_SUBST(GMALLOC_OBJ)
2205 AC_SUBST(VMLIMIT_OBJ)
2206
2207 if test "$doug_lea_malloc" = "yes" && test "$hybrid_malloc" != yes; then
2208   if test "$GNU_MALLOC" = yes ; then
2209     GNU_MALLOC_reason="
2210       (Using Doug Lea's new malloc from the GNU C Library.)"
2211   fi
2212   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2213     [Define to 1 if the system memory allocator is Doug Lea style,
2214      with malloc hooks and malloc_set_state.])
2215
2216   ## Use mmap directly for allocating larger buffers.
2217   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2218   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2219   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2220   case "$opsys" in
2221     mingw32|gnu*) REL_ALLOC=no ;;
2222   esac
2223 fi
2224
2225 if test x"${REL_ALLOC}" = x; then
2226   REL_ALLOC=${GNU_MALLOC}
2227 fi
2228
2229 use_mmap_for_buffers=no
2230 case "$opsys" in
2231   cygwin|mingw32) use_mmap_for_buffers=yes ;;
2232 esac
2233
2234 AC_FUNC_MMAP
2235 if test $use_mmap_for_buffers = yes; then
2236   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2237   REL_ALLOC=no
2238 fi
2239
2240 LIBS="$LIBS_SYSTEM $LIBS"
2241
2242 dnl FIXME replace main with a function we actually want from this library.
2243 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2244
2245 dnl Check for the POSIX thread library.
2246 LIB_PTHREAD=
2247 AC_CHECK_HEADERS_ONCE(pthread.h)
2248 if test "$ac_cv_header_pthread_h" && test "$opsys" != "mingw32"; then
2249   AC_CACHE_CHECK([for pthread library],
2250     [emacs_cv_pthread_lib],
2251     [emacs_cv_pthread_lib=no
2252      OLD_LIBS=$LIBS
2253      for emacs_pthread_lib in 'none needed' -lpthread; do
2254        case $emacs_pthread_lib in
2255          -*) LIBS="$OLD_LIBS $emacs_pthread_lib";;
2256        esac
2257        AC_LINK_IFELSE(
2258          [AC_LANG_PROGRAM(
2259             [[#include <pthread.h>
2260               #include <signal.h>
2261               sigset_t old_mask, new_mask;
2262               void noop (void) {}]],
2263             [[pthread_t th = pthread_self ();
2264               int status = 0;
2265               status += pthread_create (&th, 0, 0, 0);
2266               status += pthread_sigmask (SIG_BLOCK, &new_mask, &old_mask);
2267               status += pthread_kill (th, 0);
2268               #if ! (defined SYSTEM_MALLOC || defined HYBRID_MALLOC \
2269                      || defined DOUG_LEA_MALLOC)
2270               /* Test for pthread_atfork only if gmalloc uses it,
2271                  as older-style hosts like MirBSD 10 lack it.  */
2272               status += pthread_atfork (noop, noop, noop);
2273               #endif
2274               return status;]])],
2275          [emacs_cv_pthread_lib=$emacs_pthread_lib])
2276        LIBS=$OLD_LIBS
2277        if test "$emacs_cv_pthread_lib" != no; then
2278          break
2279        fi
2280      done])
2281   if test "$emacs_cv_pthread_lib" != no; then
2282     AC_DEFINE([HAVE_PTHREAD], 1, [Define to 1 if you have POSIX threads.])
2283     case $emacs_cv_pthread_lib in
2284       -*) LIB_PTHREAD=$emacs_cv_pthread_lib;;
2285     esac
2286     ac_cv_func_pthread_sigmask=yes
2287     # Some systems optimize for single-threaded programs by default, and
2288     # need special flags to disable these optimizations. For example, the
2289     # definition of 'errno' in <errno.h>.
2290     case $opsys in
2291       hpux* | sol*)
2292         AC_DEFINE([_REENTRANT], 1,
2293           [Define to 1 if your system requires this in multithreaded code.]);;
2294       aix4-2)
2295         AC_DEFINE([_THREAD_SAFE], 1,
2296           [Define to 1 if your system requires this in multithreaded code.]);;
2297     esac
2298   fi
2299 fi
2300 AC_SUBST([LIB_PTHREAD])
2301
2302 dnl Check for need for bigtoc support on IBM AIX
2303
2304 case ${host_os} in
2305 aix*)
2306   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2307     case $GCC in
2308     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2309     *) gdb_cv_bigtoc=-bbigtoc ;;
2310     esac
2311
2312     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2313     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2314   ])
2315   ;;
2316 esac
2317
2318 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2319 # is for the tests that follow.  We set them back later on.
2320
2321 REAL_CFLAGS="$CFLAGS"
2322 REAL_CPPFLAGS="$CPPFLAGS"
2323 REAL_LIBS="$LIBS"
2324
2325 if test "${HAVE_X11}" = "yes"; then
2326   DEFS="$C_SWITCH_X_SITE $DEFS"
2327   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2328   LIBS="-lX11 $LIBS"
2329   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2330   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2331
2332   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2333   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2334   # but it's more convenient here to set LD_RUN_PATH since this
2335   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2336   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2337     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2338     export LD_RUN_PATH
2339   fi
2340
2341   if test "${opsys}" = "gnu-linux"; then
2342     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2343     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2344      [[XOpenDisplay ("foo");]])],
2345      [xgnu_linux_first_failure=no],
2346      [xgnu_linux_first_failure=yes])
2347     if test "${xgnu_linux_first_failure}" = "yes"; then
2348       OLD_CPPFLAGS="$CPPFLAGS"
2349       OLD_LIBS="$LIBS"
2350       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2351       LIBS="$LIBS -b i486-linuxaout"
2352       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2353        [[XOpenDisplay ("foo");]])],
2354        [xgnu_linux_second_failure=no],
2355        [xgnu_linux_second_failure=yes])
2356       if test "${xgnu_linux_second_failure}" = "yes"; then
2357         # If we get the same failure with -b, there is no use adding -b.
2358         # So leave it out.  This plays safe.
2359         AC_MSG_RESULT(no)
2360       else
2361         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2362         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2363         AC_MSG_RESULT(yes)
2364       fi
2365       CPPFLAGS=$OLD_CPPFLAGS
2366       LIBS=$OLD_LIBS
2367     else
2368       AC_MSG_RESULT(no)
2369     fi
2370   fi
2371
2372   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2373   # header files included from there.
2374   AC_MSG_CHECKING(for Xkb)
2375   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2376 #include <X11/XKBlib.h>]],
2377         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2378         emacs_xkb=yes, emacs_xkb=no)
2379   AC_MSG_RESULT($emacs_xkb)
2380   if test $emacs_xkb = yes; then
2381     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2382   fi
2383
2384   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2385 XScreenNumberOfScreen)
2386 fi
2387
2388 if test "${window_system}" = "x11"; then
2389   AC_MSG_CHECKING(X11 version 6)
2390   AC_CACHE_VAL(emacs_cv_x11_version_6,
2391   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2392 [[#if XlibSpecificationRelease < 6
2393 fail;
2394 #endif
2395 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2396   if test $emacs_cv_x11_version_6 = yes; then
2397     AC_MSG_RESULT(6 or newer)
2398     AC_DEFINE(HAVE_X11R6, 1,
2399               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2400     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2401     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2402     ## XIM support.
2403     case "$opsys" in
2404       sol2-*) : ;;
2405       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2406            [Define if you have usable X11R6-style XIM support.])
2407          ;;
2408     esac
2409   else
2410     AC_MSG_RESULT(before 6)
2411   fi
2412 fi
2413
2414
2415 ### Use -lrsvg-2 if available, unless '--with-rsvg=no' is specified.
2416 HAVE_RSVG=no
2417 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2418   if test "${with_rsvg}" != "no"; then
2419     RSVG_REQUIRED=2.11.0
2420     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2421
2422     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2423     AC_SUBST(RSVG_CFLAGS)
2424     AC_SUBST(RSVG_LIBS)
2425
2426     if test $HAVE_RSVG = yes; then
2427       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2428       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2429       # Windows loads librsvg dynamically
2430       if test "${opsys}" = "mingw32"; then
2431         RSVG_LIBS=
2432       fi
2433     fi
2434   fi
2435 fi
2436
2437 HAVE_IMAGEMAGICK=no
2438 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2439   if test "${with_imagemagick}" != "no"; then
2440     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2441     ## 6.8.2 makes Emacs crash; see Bug#13867.
2442     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2443     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2444     AC_SUBST(IMAGEMAGICK_CFLAGS)
2445     AC_SUBST(IMAGEMAGICK_LIBS)
2446
2447     if test $HAVE_IMAGEMAGICK = yes; then
2448       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2449       OLD_CFLAGS=$CFLAGS
2450       OLD_LIBS=$LIBS
2451       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2452       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2453       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers MagickAutoOrientImage)
2454       CFLAGS=$OLD_CFLAGS
2455       LIBS=$OLD_LIBS
2456     fi
2457   fi
2458 fi
2459
2460 AC_CHECK_LIB(anl, getaddrinfo_a, HAVE_GETADDRINFO_A=yes)
2461 if test "${HAVE_GETADDRINFO_A}" = "yes"; then
2462   AC_DEFINE(HAVE_GETADDRINFO_A, 1,
2463 [Define to 1 if you have getaddrinfo_a for asynchronous DNS resolution.])
2464   GETADDRINFO_A_LIBS="-lanl"
2465   AC_SUBST(GETADDRINFO_A_LIBS)
2466 fi
2467
2468 HAVE_GTK=no
2469 GTK_OBJ=
2470 gtk_term_header=$term_header
2471 check_gtk2=no
2472 gtk3_pkg_errors=
2473 if test "${opsys}" != "mingw32"; then
2474   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2475     GLIB_REQUIRED=2.28
2476     GTK_REQUIRED=3.0
2477     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2478
2479     dnl Checks for libraries.
2480     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2481       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2482     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2483        AC_MSG_ERROR($GTK_PKG_ERRORS)
2484     fi
2485     if test "$pkg_check_gtk" = "yes"; then
2486        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2487        GTK_OBJ=emacsgtkfixed.o
2488        gtk_term_header=gtkutil.h
2489        USE_GTK_TOOLKIT="GTK3"
2490        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2491          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2492            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2493          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2494            [Define to 1 to disable Glib deprecation warnings.])
2495        fi
2496     else
2497        check_gtk2=yes
2498        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2499     fi
2500   fi
2501
2502   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2503     GLIB_REQUIRED=2.10
2504     GTK_REQUIRED=2.10
2505     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2506
2507     dnl Checks for libraries.
2508     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2509       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2510     if test "$pkg_check_gtk" = "no" &&
2511        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2512     then
2513       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2514     fi
2515     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2516   fi
2517 fi
2518
2519 OLD_CFLAGS=$CFLAGS
2520 OLD_LIBS=$LIBS
2521
2522 if test x"$pkg_check_gtk" = xyes; then
2523
2524   AC_SUBST(GTK_LIBS)
2525   CFLAGS="$CFLAGS $GTK_CFLAGS"
2526   LIBS="$GTK_LIBS $LIBS"
2527   dnl Try to compile a simple GTK program.
2528   AC_MSG_CHECKING([whether GTK compiles])
2529   GTK_COMPILES=no
2530   AC_LINK_IFELSE(
2531     [AC_LANG_PROGRAM(
2532        [[/* Check the Gtk and Glib APIs.  */
2533          #include <gtk/gtk.h>
2534          #include <glib-object.h>
2535          static void
2536          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2537          {}
2538        ]],
2539        [[
2540          GtkSettings *gs = 0;
2541          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2542             strict C prohibits this.  Use gtk_main_iteration to test that the
2543             libraries are there.  */
2544          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2545                                     0, 0, 0, G_CALLBACK (callback), 0))
2546            gtk_main_iteration ();
2547        ]])],
2548     [GTK_COMPILES=yes])
2549   AC_MSG_RESULT([$GTK_COMPILES])
2550   if test "${GTK_COMPILES}" != "yes"; then
2551     GTK_OBJ=
2552     if test "$USE_X_TOOLKIT" != "maybe"; then
2553       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2554     fi
2555   else
2556     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2557     HAVE_GTK=yes
2558     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2559     GTK_OBJ="gtkutil.o $GTK_OBJ"
2560     term_header=$gtk_term_header
2561     USE_X_TOOLKIT=none
2562     AC_MSG_WARN([[Your version of Gtk+ will have problems with
2563        closing open displays.  This is no problem if you just use
2564        one display, but if you use more than one and close one of them
2565        Emacs may crash.
2566        See http://bugzilla.gnome.org/show_bug.cgi?id=85715]])
2567     sleep 3
2568   fi
2569
2570 fi
2571 AC_SUBST(GTK_OBJ)
2572
2573
2574 if test "${HAVE_GTK}" = "yes"; then
2575
2576   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2577   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2578   if test "$with_toolkit_scroll_bars" != no; then
2579     with_toolkit_scroll_bars=yes
2580   fi
2581
2582   dnl  Check if we have the old file selection dialog declared and
2583   dnl  in the link library.  In 2.x it may be in the library,
2584   dnl  but not declared if deprecated featured has been selected out.
2585   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2586   HAVE_GTK_FILE_SELECTION=no
2587   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2588                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2589 #include <gtk/gtk.h>])
2590   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2591     AC_CHECK_FUNCS(gtk_file_selection_new)
2592   fi
2593
2594   dnl Same as above for gtk_handle_box.
2595   HAVE_GTK_HANDLE_BOX=no
2596   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2597                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2598 #include <gtk/gtk.h>])
2599   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2600     AC_CHECK_FUNCS(gtk_handle_box_new)
2601   fi
2602
2603   dnl Same as above for gtk_tearoff_menu_item.
2604   HAVE_GTK_TEAROFF_MENU_ITEM=no
2605   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2606                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2607 #include <gtk/gtk.h>])
2608   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2609     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2610   fi
2611
2612   dnl Check for functions introduced in 2.14 and later.
2613   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2614                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2615                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2616                  gtk_orientable_set_orientation \
2617                  gtk_window_set_has_resize_grip)
2618
2619  term_header=gtkutil.h
2620 fi
2621
2622
2623 dnl Enable xwidgets if GTK3 and WebKitGTK+ are available.
2624 HAVE_XWIDGETS=no
2625 XWIDGETS_OBJ=
2626 if test "$with_xwidgets" != "no"; then
2627   test "$USE_GTK_TOOLKIT" = "GTK3" && test "$window_system" != "none" ||
2628     AC_MSG_ERROR([xwidgets requested but gtk3 not used.])
2629
2630   WEBKIT_REQUIRED=1.4.0
2631   WEBKIT_MODULES="webkitgtk-3.0 >= $WEBKIT_REQUIRED"
2632   EMACS_CHECK_MODULES([WEBKIT], [$WEBKIT_MODULES])
2633   HAVE_XWIDGETS=$HAVE_WEBKIT
2634   test $HAVE_XWIDGETS = yes ||
2635     AC_MSG_ERROR([xwidgets requested but WebKitGTK+ not found.])
2636
2637   XWIDGETS_OBJ=xwidget.o
2638   AC_DEFINE([HAVE_XWIDGETS], 1, [Define to 1 if you have xwidgets support.])
2639 fi
2640 AC_SUBST(XWIDGETS_OBJ)
2641
2642 CFLAGS=$OLD_CFLAGS
2643 LIBS=$OLD_LIBS
2644
2645 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2646 dnl other platforms.
2647 HAVE_DBUS=no
2648 DBUS_OBJ=
2649 if test "${with_dbus}" = "yes"; then
2650    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2651    if test "$HAVE_DBUS" = yes; then
2652      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2653      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2654      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2655      dnl D-Bus 1.5.12.
2656      OLD_LIBS=$LIBS
2657      LIBS="$LIBS $DBUS_LIBS"
2658      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2659                     dbus_type_is_valid \
2660                     dbus_validate_bus_name \
2661                     dbus_validate_path \
2662                     dbus_validate_interface \
2663                     dbus_validate_member)
2664      LIBS=$OLD_LIBS
2665      DBUS_OBJ=dbusbind.o
2666    fi
2667 fi
2668 AC_SUBST(DBUS_CFLAGS)
2669 AC_SUBST(DBUS_LIBS)
2670 AC_SUBST(DBUS_OBJ)
2671
2672 dnl GSettings has been tested under GNU/Linux only.
2673 HAVE_GSETTINGS=no
2674 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2675    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2676    if test "$HAVE_GSETTINGS" = "yes"; then
2677       old_CFLAGS=$CFLAGS
2678       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2679       old_LIBS=$LIBS
2680       LIBS="$LIBS $GSETTINGS_LIBS"
2681       AC_MSG_CHECKING([whether GSettings is in gio])
2682       AC_LINK_IFELSE(
2683          [AC_LANG_PROGRAM(
2684              [[/* Check that gsettings really is present.  */
2685              #include <glib-object.h>
2686              #include <gio/gio.h>
2687              ]],
2688              [[
2689                GSettings *settings;
2690                GVariant *val = g_settings_get_value (settings, "");
2691              ]])],
2692          [], HAVE_GSETTINGS=no)
2693       AC_MSG_RESULT([$HAVE_GSETTINGS])
2694
2695       if test "$HAVE_GSETTINGS" = "yes"; then
2696         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2697         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2698         SETTINGS_LIBS="$GSETTINGS_LIBS"
2699       fi
2700       CFLAGS=$old_CFLAGS
2701       LIBS=$old_LIBS
2702    fi
2703 fi
2704
2705 dnl GConf has been tested under GNU/Linux only.
2706 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2707 HAVE_GCONF=no
2708 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2709    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2710    if test "$HAVE_GCONF" = yes; then
2711       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2712       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2713       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2714       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2715    fi
2716 fi
2717
2718 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2719     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2720     if test "$HAVE_GOBJECT" = "yes"; then
2721        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2722        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2723     fi
2724     SAVE_CFLAGS="$CFLAGS"
2725     SAVE_LIBS="$LIBS"
2726     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2727     LIBS="$SETTINGS_LIBS $LIBS"
2728     CFLAGS="$SAVE_CFLAGS"
2729     LIBS="$SAVE_LIBS"
2730 fi
2731 AC_SUBST(SETTINGS_CFLAGS)
2732 AC_SUBST(SETTINGS_LIBS)
2733
2734
2735 dnl SELinux is available for GNU/Linux only.
2736 HAVE_LIBSELINUX=no
2737 LIBSELINUX_LIBS=
2738 if test "${with_selinux}" = "yes"; then
2739    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2740    if test "$HAVE_LIBSELINUX" = yes; then
2741       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2742       LIBSELINUX_LIBS=-lselinux
2743    fi
2744 fi
2745 AC_SUBST(LIBSELINUX_LIBS)
2746
2747 HAVE_GNUTLS=no
2748 if test "${with_gnutls}" = "yes" ; then
2749   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2750     [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2751   if test "${HAVE_GNUTLS}" = "yes"; then
2752     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2753     EMACS_CHECK_MODULES([LIBGNUTLS3], [gnutls >= 3.0.0],
2754       [AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])], [])
2755   fi
2756
2757   # Windows loads GnuTLS dynamically
2758   if test "${opsys}" = "mingw32"; then
2759     LIBGNUTLS_LIBS=
2760   fi
2761 fi
2762
2763 AC_SUBST(LIBGNUTLS_LIBS)
2764 AC_SUBST(LIBGNUTLS_CFLAGS)
2765
2766 HAVE_LIBSYSTEMD=no
2767 if test "${with_libsystemd}" = "yes" ; then
2768   dnl This code has been tested with libsystemd 222 and later.
2769   dnl FIXME: Find the earliest version number for which Emacs should work,
2770   dnl and change '222' to that number.
2771   EMACS_CHECK_MODULES([LIBSYSTEMD], [libsystemd >= 222],
2772     [HAVE_LIBSYSTEMD=yes], [HAVE_LIBSYSTEMD=no])
2773   if test "${HAVE_LIBSYSTEMD}" = "yes"; then
2774     AC_DEFINE(HAVE_LIBSYSTEMD, 1, [Define if using libsystemd.])
2775   fi
2776 fi
2777
2778 AC_SUBST(LIBSYSTEMD_LIBS)
2779 AC_SUBST(LIBSYSTEMD_CFLAGS)
2780
2781 NOTIFY_OBJ=
2782 NOTIFY_SUMMARY=no
2783
2784 dnl MS Windows native file monitor is available for mingw32 only.
2785 case $with_file_notification,$opsys in
2786   w32,cygwin)
2787     AC_MSG_ERROR(['--with-file-notification=w32' was specified, but
2788     this is only supported on MS-Windows native and MinGW32 builds.
2789     Consider using gfile instead.])
2790     ;;
2791   w32,* | yes,mingw32)
2792     AC_CHECK_HEADER(windows.h)
2793     if test "$ac_cv_header_windows_h" = yes ; then
2794        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2795        NOTIFY_OBJ=w32notify.o
2796        NOTIFY_SUMMARY="yes (w32)"
2797     fi ;;
2798 esac
2799
2800 dnl inotify is available only on GNU/Linux.
2801 case $with_file_notification,$NOTIFY_OBJ in
2802   inotify, | yes,)
2803     AC_CHECK_HEADER(sys/inotify.h)
2804     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2805         AC_CHECK_FUNC(inotify_init1)
2806         if test "$ac_cv_func_inotify_init1" = yes; then
2807           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2808           NOTIFY_OBJ=inotify.o
2809           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2810        fi
2811     fi ;;
2812 esac
2813
2814 dnl kqueue is available on BSD-like systems.
2815 case $with_file_notification,$NOTIFY_OBJ in
2816   kqueue,* | yes,)
2817     EMACS_CHECK_MODULES([KQUEUE], [libkqueue])
2818     if test "$HAVE_KQUEUE" = "yes"; then
2819        AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2820        CPPFLAGS="$CPPFLAGS -I/usr/include/kqueue"
2821        NOTIFY_CFLAGS=$KQUEUE_CFLAGS
2822        NOTIFY_LIBS=$KQUEUE_LIBS
2823        NOTIFY_OBJ=kqueue.o
2824        NOTIFY_SUMMARY="yes -lkqueue"
2825     else
2826        AC_SEARCH_LIBS(kqueue, [])
2827        if test "$ac_cv_search_kqueue" != no; then
2828          AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2829          NOTIFY_OBJ=kqueue.o
2830          NOTIFY_SUMMARY="yes (kqueue)"
2831        fi
2832     fi ;;
2833 esac
2834
2835 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2836 dnl has been added in glib 2.24.  It has been tested under
2837 dnl GNU/Linux only.
2838 case $with_file_notification,$NOTIFY_OBJ in
2839   gfile,* | yes,)
2840     if test "${HAVE_NS}" = yes; then
2841        AC_MSG_ERROR(['--with-file-notification=gfile' is not supported in NextStep builds.
2842 Consider kqueue instead.])
2843     else
2844        EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2845        if test "$HAVE_GFILENOTIFY" = "yes"; then
2846           AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2847           NOTIFY_CFLAGS=$GFILENOTIFY_CFLAGS
2848           NOTIFY_LIBS=$GFILENOTIFY_LIBS
2849           NOTIFY_OBJ=gfilenotify.o
2850           NOTIFY_SUMMARY="yes -lgio (gfile)"
2851        fi
2852     fi ;;
2853 esac
2854
2855 case $with_file_notification,$NOTIFY_OBJ in
2856   yes,* | no,* | *,?*) ;;
2857   *) AC_MSG_ERROR([File notification '$with_file_notification' requested but requirements not found.]) ;;
2858 esac
2859
2860 if test -n "$NOTIFY_OBJ"; then
2861    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2862 fi
2863 AC_SUBST(NOTIFY_CFLAGS)
2864 AC_SUBST(NOTIFY_LIBS)
2865 AC_SUBST(NOTIFY_OBJ)
2866
2867 dnl Do not put whitespace before the #include statements below.
2868 dnl Older compilers (eg sunos4 cc) choke on it.
2869 HAVE_XAW3D=no
2870 LUCID_LIBW=
2871 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2872   if test "$with_xaw3d" != no; then
2873     AC_CACHE_VAL(emacs_cv_xaw3d,
2874     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2875 #include <X11/Intrinsic.h>
2876 #include <X11/Xaw3d/Simple.h>]],
2877       [[]])],
2878       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2879                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2880       emacs_cv_xaw3d=no)])
2881   else
2882     emacs_cv_xaw3d=no
2883   fi
2884   if test $emacs_cv_xaw3d = yes; then
2885     AC_MSG_CHECKING(for xaw3d)
2886     AC_MSG_RESULT([yes; using Lucid toolkit])
2887     USE_X_TOOLKIT=LUCID
2888     HAVE_XAW3D=yes
2889     LUCID_LIBW=-lXaw3d
2890     AC_DEFINE(HAVE_XAW3D, 1,
2891               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2892   else
2893     AC_MSG_CHECKING(for xaw3d)
2894     AC_MSG_RESULT(no)
2895     AC_MSG_CHECKING(for libXaw)
2896     AC_CACHE_VAL(emacs_cv_xaw,
2897     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2898 #include <X11/Intrinsic.h>
2899 #include <X11/Xaw/Simple.h>]],
2900       [[]])],
2901       emacs_cv_xaw=yes,
2902       emacs_cv_xaw=no)])
2903     if test $emacs_cv_xaw = yes; then
2904       AC_MSG_RESULT([yes; using Lucid toolkit])
2905       USE_X_TOOLKIT=LUCID
2906       LUCID_LIBW=-lXaw
2907     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2908       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2909     else
2910       AC_MSG_ERROR([No X toolkit could be found.
2911 If you are sure you want Emacs compiled without an X toolkit, pass
2912   --with-x-toolkit=no
2913 to configure.  Otherwise, install the development libraries for the toolkit
2914 that you want to use (e.g. Gtk+) and re-run configure.])
2915     fi
2916   fi
2917 fi
2918
2919 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2920
2921 LIBXTR6=
2922 LIBXMU=
2923 if test "${USE_X_TOOLKIT}" != "none"; then
2924   AC_MSG_CHECKING(X11 toolkit version)
2925   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2926   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2927 [[#if XtSpecificationRelease < 6
2928 fail;
2929 #endif
2930 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2931   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2932   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2933     AC_MSG_RESULT(6 or newer)
2934     AC_DEFINE(HAVE_X11XTR6, 1,
2935               [Define to 1 if you have the X11R6 or newer version of Xt.])
2936     LIBXTR6="-lSM -lICE"
2937     case "$opsys" in
2938       ## Use libw.a along with X11R6 Xt.
2939       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2940     esac
2941   else
2942     AC_MSG_RESULT(before 6)
2943   fi
2944
2945 dnl If using toolkit, check whether libXmu.a exists.
2946 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2947   OLDLIBS="$LIBS"
2948   if test x$HAVE_X11XTR6 = xyes; then
2949     OTHERLIBS='-lXt -lSM -lICE'
2950   else
2951     OTHERLIBS='-lXt'
2952   fi
2953   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2954   if test "X$LIBS" != "X$OLDLIBS"; then
2955     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2956   fi
2957   LIBS=$OLDLIBS
2958   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2959 fi
2960 AC_SUBST(LIBXTR6)
2961 AC_SUBST(LIBXMU)
2962
2963 LIBXP=
2964 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2965   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2966   if test -d /usr/include/openmotif; then
2967     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2968     emacs_cv_openmotif=yes
2969     case "$canonical" in
2970       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2971       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2972       ;;
2973       *)
2974       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2975     esac
2976   else
2977     emacs_cv_openmotif=no
2978   fi
2979   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2980   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2981     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2982 int x = 5;
2983 #else
2984 Motif version prior to 2.1.
2985 #endif]])],
2986     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2987   if test $emacs_cv_motif_version_2_1 = yes; then
2988     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2989     if test x$emacs_cv_openmotif = xyes; then
2990       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2991     fi
2992   else
2993     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2994     # We put this in CFLAGS temporarily to precede other -I options
2995     # that might be in CFLAGS temporarily.
2996     # We put this in CPPFLAGS where it precedes the other -I options.
2997     OLD_CPPFLAGS=$CPPFLAGS
2998     OLD_CFLAGS=$CFLAGS
2999     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
3000     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
3001     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
3002       [[int x = 5;]])],
3003       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
3004     if test $emacs_cv_lesstif = yes; then
3005       # Make sure this -I option remains in CPPFLAGS after it is set
3006       # back to REAL_CPPFLAGS.
3007       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
3008       # have those other -I options anyway.  Ultimately, having this
3009       # directory ultimately in CPPFLAGS will be enough.
3010       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
3011       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
3012     else
3013       CFLAGS=$OLD_CFLAGS
3014       CPPFLAGS=$OLD_CPPFLAGS
3015     fi
3016   fi
3017   AC_CHECK_HEADER([Xm/BulletinB.h], [],
3018     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
3019 fi
3020
3021 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
3022 dnl using Motif or Xaw3d is available, and unless
3023 dnl --with-toolkit-scroll-bars=no was specified.
3024
3025 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
3026             [Define to 1 if we should use toolkit scroll bars.])dnl
3027 USE_TOOLKIT_SCROLL_BARS=no
3028 if test "${with_toolkit_scroll_bars}" != "no"; then
3029   if test "${USE_X_TOOLKIT}" != "none"; then
3030     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
3031       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3032       HAVE_XAW3D=no
3033       USE_TOOLKIT_SCROLL_BARS=yes
3034     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
3035       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3036       USE_TOOLKIT_SCROLL_BARS=yes
3037     fi
3038   elif test "${HAVE_GTK}" = "yes"; then
3039     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3040     USE_TOOLKIT_SCROLL_BARS=yes
3041   elif test "${HAVE_NS}" = "yes"; then
3042     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3043     USE_TOOLKIT_SCROLL_BARS=yes
3044   elif test "${HAVE_W32}" = "yes"; then
3045     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3046     USE_TOOLKIT_SCROLL_BARS=yes
3047   fi
3048 fi
3049
3050 dnl See if XIM is available.
3051 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3052           #include <X11/Xlib.h>
3053           #include <X11/Xresource.h>]],
3054          [[XIMProc  callback;]])],
3055          [HAVE_XIM=yes
3056          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
3057          HAVE_XIM=no)
3058
3059 dnl '--with-xim' now controls only the initial value of use_xim at run time.
3060
3061 if test "${with_xim}" != "no"; then
3062   AC_DEFINE(USE_XIM, 1,
3063             [Define to 1 if we should use XIM, if it is available.])
3064 fi
3065
3066
3067 if test "${HAVE_XIM}" != "no"; then
3068   late_CFLAGS=$CFLAGS
3069   if test "$GCC" = yes; then
3070     CFLAGS="$CFLAGS --pedantic-errors"
3071   fi
3072   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3073 #include <X11/Xlib.h>
3074 #include <X11/Xresource.h>]],
3075 [[Display *display;
3076 XrmDatabase db;
3077 char *res_name;
3078 char *res_class;
3079 XIMProc  callback;
3080 XPointer *client_data;
3081 #ifndef __GNUC__
3082 /* If we're not using GCC, it's probably not XFree86, and this is
3083    probably right, but we can't use something like --pedantic-errors.  */
3084 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
3085                                            char*, XIMProc, XPointer*);
3086 #endif
3087 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
3088    client_data);]])],
3089     [emacs_cv_arg6_star=yes])
3090   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
3091          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
3092 either XPointer or XPointer*.])dnl
3093   if test "$emacs_cv_arg6_star" = yes; then
3094     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
3095   else
3096     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
3097   fi
3098   CFLAGS=$late_CFLAGS
3099 fi
3100
3101 ### Start of font-backend (under any platform) section.
3102 # (nothing here yet -- this is a placeholder)
3103 ### End of font-backend (under any platform) section.
3104
3105 ### Start of font-backend (under X11) section.
3106 if test "${HAVE_X11}" = "yes"; then
3107     ## Use -lXft if available, unless '--with-xft=no'.
3108     HAVE_XFT=maybe
3109     if test "x${with_x}" = "xno"; then
3110       with_xft="no";
3111     fi
3112
3113     if test "$with_xft" != no; then
3114       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
3115       with_xft=$HAVE_FONTCONFIG
3116     fi
3117
3118     if test "x${with_xft}" != "xno"; then
3119
3120       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
3121       ## Because xftfont.c uses XRenderQueryExtension, we also
3122       ## need to link to -lXrender.
3123       HAVE_XRENDER=no
3124       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
3125       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
3126         OLD_CPPFLAGS="$CPPFLAGS"
3127         OLD_CFLAGS="$CFLAGS"
3128         OLD_LIBS="$LIBS"
3129         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
3130         CFLAGS="$CFLAGS $XFT_CFLAGS"
3131         XFT_LIBS="-lXrender $XFT_LIBS"
3132         LIBS="$XFT_LIBS $LIBS"
3133         AC_CHECK_HEADER(X11/Xft/Xft.h,
3134           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
3135           [[#include <X11/X.h>]])
3136
3137         if test "${HAVE_XFT}" = "yes"; then
3138           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
3139             AC_SUBST(XFT_LIBS)
3140           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
3141         fi                        # "${HAVE_XFT}" = "yes"
3142         CPPFLAGS=$OLD_CPPFLAGS
3143         CFLAGS=$OLD_CFLAGS
3144         LIBS=$OLD_LIBS
3145       fi                          # "$HAVE_XFT" != no
3146     fi                            # "x${with_xft}" != "xno"
3147
3148     ## We used to allow building with FreeType and without Xft.
3149     ## However, the ftx font backend driver is not in good shape.
3150     if test "$HAVE_XFT" != "yes"; then
3151        dnl For the "Does Emacs use" message at the end.
3152        HAVE_XFT=no
3153        HAVE_FREETYPE=no
3154     else
3155        dnl Strict linkers fail with
3156        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
3157        dnl if -lfreetype is not specified.
3158        dnl The following is needed to set FREETYPE_LIBS.
3159        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
3160
3161        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
3162     fi
3163
3164     HAVE_LIBOTF=no
3165     if test "${HAVE_FREETYPE}" = "yes"; then
3166       AC_DEFINE(HAVE_FREETYPE, 1,
3167                 [Define to 1 if using the freetype and fontconfig libraries.])
3168       if test "${with_libotf}" != "no"; then
3169         EMACS_CHECK_MODULES([LIBOTF], [libotf])
3170         if test "$HAVE_LIBOTF" = "yes"; then
3171           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
3172           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
3173                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
3174                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
3175           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
3176             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
3177                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
3178           fi
3179         fi
3180       fi
3181     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
3182     dnl Does the new font backend require it, or can it work without it?
3183     fi
3184
3185     HAVE_M17N_FLT=no
3186     if test "${HAVE_LIBOTF}" = yes; then
3187       if test "${with_m17n_flt}" != "no"; then
3188         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
3189         if test "$HAVE_M17N_FLT" = "yes"; then
3190           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
3191         fi
3192       fi
3193     fi
3194 else
3195     HAVE_XFT=no
3196     HAVE_FREETYPE=no
3197     HAVE_LIBOTF=no
3198     HAVE_M17N_FLT=no
3199 fi
3200
3201 ### End of font-backend (under X11) section.
3202
3203 AC_SUBST(FREETYPE_CFLAGS)
3204 AC_SUBST(FREETYPE_LIBS)
3205 AC_SUBST(FONTCONFIG_CFLAGS)
3206 AC_SUBST(FONTCONFIG_LIBS)
3207 AC_SUBST(LIBOTF_CFLAGS)
3208 AC_SUBST(LIBOTF_LIBS)
3209 AC_SUBST(M17N_FLT_CFLAGS)
3210 AC_SUBST(M17N_FLT_LIBS)
3211
3212 HAVE_CAIRO=no
3213 if test "${HAVE_X11}" = "yes"; then
3214   if test "${with_cairo}" != "no"; then
3215     CAIRO_REQUIRED=1.12.0
3216     CAIRO_MODULE="cairo >= $CAIRO_REQUIRED"
3217     EMACS_CHECK_MODULES(CAIRO, $CAIRO_MODULE)
3218     if test $HAVE_CAIRO = yes; then
3219       AC_DEFINE(USE_CAIRO, 1, [Define to 1 if using cairo.])
3220     else
3221       AC_MSG_ERROR([cairo requested but not found.])
3222     fi
3223
3224     CFLAGS="$CFLAGS $CAIRO_CFLAGS"
3225     LIBS="$LIBS $CAIRO_LIBS"
3226     AC_SUBST(CAIRO_CFLAGS)
3227     AC_SUBST(CAIRO_LIBS)
3228   fi
3229 fi
3230
3231 if test "${HAVE_X11}" = "yes"; then
3232   AC_CHECK_HEADER(X11/Xlib-xcb.h,
3233     AC_CHECK_LIB(xcb, xcb_translate_coordinates, HAVE_XCB=yes))
3234   if test "${HAVE_XCB}" = "yes"; then
3235     AC_CHECK_LIB(X11-xcb, XGetXCBConnection, HAVE_X11_XCB=yes)
3236     if test "${HAVE_X11_XCB}" = "yes"; then
3237       AC_DEFINE(USE_XCB, 1,
3238 [Define to 1 if you have the XCB library and X11-XCB library for mixed
3239    X11/XCB programming.])
3240       XCB_LIBS="-lX11-xcb -lxcb"
3241       AC_SUBST(XCB_LIBS)
3242     fi
3243   fi
3244 fi
3245
3246 ### Use -lXpm if available, unless '--with-xpm=no'.
3247 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
3248 ### The Cygwin-w32 build uses <noX/xpm.h> instead of <X11/xpm.h>, so
3249 ### we need to set LDFLAGS accordingly.
3250 HAVE_XPM=no
3251 LIBXPM=
3252 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3253   if test "${with_xpm}" != "no"; then
3254     SAVE_LDFLAGS="$LDFLAGS"
3255     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3256     AC_CHECK_HEADER(noX/xpm.h,
3257       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3258     if test "${HAVE_XPM}" = "yes"; then
3259       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3260       AC_EGREP_CPP(no_return_alloc_pixels,
3261       [#include "noX/xpm.h"
3262 #ifndef XpmReturnAllocPixels
3263 no_return_alloc_pixels
3264 #endif
3265       ], HAVE_XPM=no, HAVE_XPM=yes)
3266
3267       if test "${HAVE_XPM}" = "yes"; then
3268         AC_MSG_RESULT(yes)
3269       else
3270         AC_MSG_RESULT(no)
3271         LDFLAGS="$SAVE_LDFLAGS"
3272       fi
3273     fi
3274   fi
3275
3276   if test "${HAVE_XPM}" = "yes"; then
3277     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3278     LIBXPM=-lXpm
3279   fi
3280 fi
3281
3282 if test "${HAVE_X11}" = "yes"; then
3283   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3284   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3285
3286   if test "${with_xpm}" != "no"; then
3287     AC_CHECK_HEADER(X11/xpm.h,
3288       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3289     if test "${HAVE_XPM}" = "yes"; then
3290       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3291       AC_EGREP_CPP(no_return_alloc_pixels,
3292       [#include "X11/xpm.h"
3293 #ifndef XpmReturnAllocPixels
3294 no_return_alloc_pixels
3295 #endif
3296       ], HAVE_XPM=no, HAVE_XPM=yes)
3297
3298       if test "${HAVE_XPM}" = "yes"; then
3299         AC_MSG_RESULT(yes)
3300       else
3301         AC_MSG_RESULT(no)
3302       fi
3303     fi
3304   fi
3305
3306   if test "${HAVE_XPM}" = "yes"; then
3307     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3308     LIBXPM=-lXpm
3309   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3310     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3311     LIBXPM=-lXpm
3312   fi
3313 fi
3314
3315 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3316 ### slightly different requirements wrt image libraries (it doesn't
3317 ### use -lXpm because it loads the xpm shared library dynamically at
3318 ### run time).
3319 if test "${opsys}" = "mingw32"; then
3320   if test "${with_xpm}" != "no"; then
3321     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3322 #define FOR_MSW 1])
3323   fi
3324
3325   if test "${HAVE_XPM}" = "yes"; then
3326     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3327   fi
3328 fi
3329
3330 AC_SUBST(LIBXPM)
3331
3332 ### Use -ljpeg if available, unless '--with-jpeg=no'.
3333 HAVE_JPEG=no
3334 LIBJPEG=
3335 if test "${with_jpeg}" != "no"; then
3336   AC_CACHE_CHECK([for jpeglib 6b or later],
3337     [emacs_cv_jpeglib],
3338     [OLD_LIBS=$LIBS
3339      for emacs_cv_jpeglib in yes -ljpeg no; do
3340        case $emacs_cv_jpeglib in
3341          yes) ;;
3342          no) break;;
3343          *) LIBS="$LIBS $emacs_cv_jpeglib";;
3344        esac
3345        AC_LINK_IFELSE(
3346          [AC_LANG_PROGRAM(
3347             [[#undef HAVE_STDLIB_H /* Avoid config.h/jpeglib.h collision.  */
3348               #include <stdio.h> /* jpeglib.h needs FILE and size_t.  */
3349               #include <jpeglib.h>
3350               #include <jerror.h>
3351               char verify[JPEG_LIB_VERSION < 62 ? -1 : 1];
3352               struct jpeg_decompress_struct cinfo;
3353             ]],
3354             [[
3355               jpeg_create_decompress (&cinfo);
3356               WARNMS (&cinfo, JWRN_JPEG_EOF);
3357               jpeg_destroy_decompress (&cinfo);
3358             ]])],
3359          [emacs_link_ok=yes],
3360          [emacs_link_ok=no])
3361        LIBS=$OLD_LIBS
3362        test $emacs_link_ok = yes && break
3363      done])
3364   if test "$emacs_cv_jpeglib" != no; then
3365     HAVE_JPEG=yes
3366     AC_DEFINE([HAVE_JPEG], 1,
3367       [Define to 1 if you have the jpeg library (typically -ljpeg).])
3368     ### mingw32 doesn't use -ljpeg, since it loads the library
3369     ### dynamically when needed, and doesn't want a run-time
3370     ### dependency on the jpeglib DLL.
3371     test "$emacs_cv_jpeglib" != yes && test "${opsys}" != "mingw32" \
3372     && LIBJPEG=$emacs_cv_jpeglib
3373   fi
3374 fi
3375 AC_SUBST(LIBJPEG)
3376
3377 HAVE_ZLIB=no
3378 LIBZ=
3379 if test "${with_zlib}" != "no"; then
3380   OLIBS=$LIBS
3381   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3382   LIBS=$OLIBS
3383   case $ac_cv_search_inflateEnd in
3384     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3385   esac
3386 fi
3387 if test "${HAVE_ZLIB}" = "yes"; then
3388   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3389   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3390   if test "${opsys}" = "mingw32"; then
3391      LIBZ=
3392   fi
3393 fi
3394 AC_SUBST(LIBZ)
3395
3396 ### Dynamic modules support
3397 LIBMODULES=
3398 HAVE_MODULES=no
3399 MODULES_OBJ=
3400 MODULES_SUFFIX=
3401 if test "${with_modules}" != "no"; then
3402   case $opsys in
3403     gnu|gnu-linux)
3404       LIBMODULES="-ldl"
3405       MODULES_SUFFIX=".so"
3406       HAVE_MODULES=yes
3407       ;;
3408     cygwin|mingw32)
3409       MODULES_SUFFIX=".dll"
3410       HAVE_MODULES=yes
3411       ;;
3412     darwin)
3413       MODULES_SUFFIX=".so"
3414       HAVE_MODULES=yes
3415       ;;
3416     *)
3417       # BSD systems have dlopen in libc.
3418       AC_CHECK_FUNC([dlopen],
3419         [MODULES_SUFFIX=".so"
3420          HAVE_MODULES=yes])
3421       ;;
3422   esac
3423
3424   if test "${HAVE_MODULES}" = no; then
3425     AC_MSG_ERROR([Dynamic modules are not supported on your system])
3426   else
3427     SAVE_LIBS=$LIBS
3428     LIBS="$LIBS $LIBMODULES"
3429     AC_CHECK_FUNCS([dladdr dlfunc])
3430     LIBS=$SAVE_LIBS
3431   fi
3432 fi
3433
3434 if test "${HAVE_MODULES}" = yes; then
3435    MODULES_OBJ="dynlib.o emacs-module.o"
3436    AC_DEFINE(HAVE_MODULES, 1, [Define to 1 if dynamic modules are enabled])
3437    AC_DEFINE_UNQUOTED(MODULES_SUFFIX, "$MODULES_SUFFIX",
3438      [System extension for dynamic libraries])
3439 fi
3440 AC_SUBST(MODULES_OBJ)
3441 AC_SUBST(LIBMODULES)
3442
3443 ### Use -lpng if available, unless '--with-png=no'.
3444 HAVE_PNG=no
3445 LIBPNG=
3446 PNG_CFLAGS=
3447 if test "${NS_IMPL_COCOA}" = yes; then
3448   : # Nothing to do
3449 elif test "${with_png}" != no; then
3450   # mingw32 loads the library dynamically.
3451   if test "$opsys" = mingw32; then
3452     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3453   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3454     AC_MSG_CHECKING([for png])
3455     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3456     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3457       # libpng-config does not work; configure by hand.
3458       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3459       # in /usr/include/libpng.
3460       if test -r /usr/include/libpng/png.h &&
3461          test ! -r /usr/include/png.h; then
3462         png_cflags=-I/usr/include/libpng
3463       else
3464         png_cflags=
3465       fi
3466       png_libs='-lpng'
3467     }
3468     SAVE_CFLAGS=$CFLAGS
3469     SAVE_LIBS=$LIBS
3470     CFLAGS="$CFLAGS $png_cflags"
3471     LIBS="$png_libs -lz -lm $LIBS"
3472     AC_LINK_IFELSE(
3473       [AC_LANG_PROGRAM([[#include <png.h>]],
3474          [[return !png_get_channels (0, 0);]])],
3475       [HAVE_PNG=yes
3476        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3477        LIBPNG=$png_libs
3478        # $LIBPNG requires explicit -lz in some cases.
3479        # We don't know what those cases are, exactly, so play it safe and
3480        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3481        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3482          LIBPNG="$LIBPNG -lz"
3483        fi])
3484     CFLAGS=$SAVE_CFLAGS
3485     LIBS=$SAVE_LIBS
3486     AC_MSG_RESULT([$HAVE_PNG])
3487   fi
3488 fi
3489 if test $HAVE_PNG = yes; then
3490   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3491
3492   SAVE_CFLAGS=$CFLAGS
3493   CFLAGS="$CFLAGS $PNG_CFLAGS"
3494   AC_CHECK_DECL([png_longjmp],
3495     [],
3496     [AC_DEFINE([PNG_DEPSTRUCT], [],
3497        [Define to empty to suppress deprecation warnings when building
3498         with --enable-gcc-warnings and with libpng versions before 1.5,
3499         which lack png_longjmp.])],
3500     [[#include <png.h>
3501     ]])
3502   CFLAGS=$SAVE_CFLAGS
3503 fi
3504 AC_SUBST(LIBPNG)
3505 AC_SUBST(PNG_CFLAGS)
3506
3507 ### Use -ltiff if available, unless '--with-tiff=no'.
3508 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3509 HAVE_TIFF=no
3510 LIBTIFF=
3511 if test "${opsys}" = "mingw32"; then
3512   if test "${with_tiff}" != "no"; then
3513     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3514   fi
3515   if test "${HAVE_TIFF}" = "yes"; then
3516     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3517   fi
3518 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3519   if test "${with_tiff}" != "no"; then
3520     AC_CHECK_HEADER(tiffio.h,
3521       [tifflibs="-lz -lm"
3522       # At least one tiff package requires the jpeg library.
3523       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3524       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3525   fi
3526
3527   if test "${HAVE_TIFF}" = "yes"; then
3528     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3529     dnl FIXME -lz -lm, as per libpng?
3530     LIBTIFF=-ltiff
3531   fi
3532 fi
3533 AC_SUBST(LIBTIFF)
3534
3535 ### Use -lgif or -lungif if available, unless '--with-gif=no'.
3536 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3537 HAVE_GIF=no
3538 LIBGIF=
3539 if test "${opsys}" = "mingw32"; then
3540   if test "${with_gif}" != "no"; then
3541     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3542   fi
3543   if test "${HAVE_GIF}" = "yes"; then
3544     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3545   fi
3546 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3547         || test "${HAVE_W32}" = "yes"; then
3548   AC_CHECK_HEADER(gif_lib.h,
3549 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3550 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3551     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3552         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3553
3554   if test "$HAVE_GIF" = yes; then
3555     LIBGIF=-lgif
3556   elif test "$HAVE_GIF" = maybe; then
3557 # If gif_lib.h but no libgif, try libungif.
3558     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3559     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3560   fi
3561
3562   if test "${HAVE_GIF}" = "yes"; then
3563     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3564   fi
3565 fi
3566 AC_SUBST(LIBGIF)
3567
3568 dnl Check for required libraries.
3569 if test "${HAVE_X11}" = "yes"; then
3570   MISSING=""
3571   WITH_NO=""
3572   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3573     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3574   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3575     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3576   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3577     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3578   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3579     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3580   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3581     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3582
3583   if test "X${MISSING}" != X; then
3584     AC_MSG_ERROR([The following required libraries were not found:
3585     $MISSING
3586 Maybe some development libraries/packages are missing?
3587 If you don't want to link with them give
3588     $WITH_NO
3589 as options to configure])
3590   fi
3591 fi
3592
3593 ### Use -lgpm if available, unless '--with-gpm=no'.
3594 HAVE_GPM=no
3595 LIBGPM=
3596 if test "${with_gpm}" != "no"; then
3597   AC_CHECK_HEADER(gpm.h,
3598     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3599
3600   if test "${HAVE_GPM}" = "yes"; then
3601     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3602     LIBGPM=-lgpm
3603   fi
3604 fi
3605 AC_SUBST(LIBGPM)
3606
3607 dnl Check for malloc/malloc.h on darwin
3608 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3609
3610 GNUSTEP_CFLAGS=
3611 ### Use NeXTstep API to implement GUI.
3612 if test "${HAVE_NS}" = "yes"; then
3613   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3614   if test "${NS_IMPL_COCOA}" = "yes"; then
3615     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3616   fi
3617   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3618     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3619     if test $NS_GNUSTEP_CONFIG != yes; then
3620       # See also .m.o rule in src/Makefile.in.  */
3621       # FIXME: are all these flags really needed?  Document here why.  */
3622       GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3623       ## Extra CFLAGS applied to src/*.m files.
3624       GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3625     fi
3626   fi
3627   OTHER_FILES=ns-app
3628 fi
3629
3630 ### Use session management (-lSM -lICE) if available
3631 HAVE_X_SM=no
3632 LIBXSM=
3633 if test "${HAVE_X11}" = "yes"; then
3634   AC_CHECK_HEADER(X11/SM/SMlib.h,
3635     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3636
3637   if test "${HAVE_X_SM}" = "yes"; then
3638     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3639     LIBXSM="-lSM -lICE"
3640   fi
3641 fi
3642 AC_SUBST(LIBXSM)
3643
3644 ### Use XRandr (-lXrandr) if available
3645 HAVE_XRANDR=no
3646 if test "${HAVE_X11}" = "yes"; then
3647   XRANDR_REQUIRED=1.2.2
3648   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3649   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3650   if test $HAVE_XRANDR = no; then
3651     # Test old way in case pkg-config doesn't have it (older machines).
3652     # Include Xrender.h by hand to work around bug in older Xrandr.h
3653     # (e.g. RHEL5) and silence (harmless) configure warning (bug#18465).
3654     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3655       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)],
3656       [], [AC_INCLUDES_DEFAULT
3657 #include <X11/extensions/Xrender.h>])
3658     if test $HAVE_XRANDR = yes; then
3659       XRANDR_LIBS=-lXrandr
3660     fi
3661   fi
3662   if test $HAVE_XRANDR = yes; then
3663     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3664   fi
3665 fi
3666 AC_SUBST(XRANDR_CFLAGS)
3667 AC_SUBST(XRANDR_LIBS)
3668
3669 ### Use Xinerama (-lXinerama) if available
3670 HAVE_XINERAMA=no
3671 if test "${HAVE_X11}" = "yes"; then
3672   XINERAMA_REQUIRED=1.0.2
3673   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3674   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3675   if test $HAVE_XINERAMA = no; then
3676     # Test old way in case pkg-config doesn't have it (older machines).
3677     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3678       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3679     if test $HAVE_XINERAMA = yes; then
3680       XINERAMA_LIBS=-lXinerama
3681     fi
3682   fi
3683   if test $HAVE_XINERAMA = yes; then
3684     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3685   fi
3686 fi
3687 AC_SUBST(XINERAMA_CFLAGS)
3688 AC_SUBST(XINERAMA_LIBS)
3689
3690 ### Use Xfixes (-lXfixes) if available
3691 HAVE_XFIXES=no
3692 if test "${HAVE_X11}" = "yes"; then
3693   XFIXES_REQUIRED=4.0.0
3694   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3695   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3696   if test $HAVE_XFIXES = no; then
3697     # Test old way in case pkg-config doesn't have it (older machines).
3698     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3699       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3700     if test $HAVE_XFIXES = yes; then
3701       XFIXES_LIBS=-lXfixes
3702     fi
3703   fi
3704   if test $HAVE_XFIXES = yes; then
3705     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3706   fi
3707 fi
3708 AC_SUBST(XFIXES_CFLAGS)
3709 AC_SUBST(XFIXES_LIBS)
3710
3711 ### Use libxml (-lxml2) if available
3712 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3713 HAVE_LIBXML2=no
3714 if test "${with_xml2}" != "no"; then
3715   ### I'm not sure what the version number should be, so I just guessed.
3716   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3717   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3718   if test "${HAVE_LIBXML2}" != "yes" && test "$opsys" = "darwin"; then
3719     SAVE_CPPFLAGS="$CPPFLAGS"
3720     if test -z "$xcsdkdir" -a -n "$XCRUN" -a ! -d /usr/include; then
3721       dnl /usr/include is not found.  Try Xcode SDK dir if it is sane.
3722       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
3723       case $xcsdkdir in
3724         *[[\\\"\#\$\&\'\`$am_lf\ \      ]]*)
3725         xcsdkdir="" ;;
3726       esac
3727     fi
3728     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3729     AC_CHECK_HEADER(libxml/HTMLparser.h,
3730       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3731                      [#include <libxml/HTMLparser.h>])])
3732     CPPFLAGS="$SAVE_CPPFLAGS"
3733     if test "${HAVE_LIBXML2}" = "yes"; then
3734       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3735       LIBXML2_LIBS="-lxml2"
3736     fi
3737   fi
3738   if test "${HAVE_LIBXML2}" = "yes"; then
3739     if test "${opsys}" != "mingw32"; then
3740       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no,
3741         [$LIBXML2_LIBS])
3742     else
3743       LIBXML2_LIBS=""
3744     fi
3745     if test "${HAVE_LIBXML2}" = "yes"; then
3746       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3747     else
3748       LIBXML2_LIBS=""
3749       LIBXML2_CFLAGS=""
3750     fi
3751   fi
3752 fi
3753 AC_SUBST(LIBXML2_LIBS)
3754 AC_SUBST(LIBXML2_CFLAGS)
3755
3756 # Check for mail-locking functions in a "mail" library.  Probably this should
3757 # have the same check as for liblockfile below.
3758 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3759 if test $have_mail = yes; then
3760   LIBS_MAIL=-lmail
3761   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the 'mail' library (-lmail).])
3762
3763   OLD_LIBS=$LIBS
3764   LIBS="$LIBS_MAIL $LIBS"
3765   AC_CHECK_FUNCS(touchlock)
3766   LIBS=$OLD_LIBS
3767 else
3768   LIBS_MAIL=
3769 fi
3770 dnl Debian, at least:
3771 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3772 if test $have_lockfile = yes; then
3773    LIBS_MAIL=-llockfile
3774    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the 'lockfile' library (-llockfile).])
3775 else
3776 # If we have the shared liblockfile, assume we must use it for mail
3777 # locking (e.g. Debian).  If we couldn't link against liblockfile
3778 # (no liblockfile.a installed), ensure that we don't need to.
3779   dnl This works for files generally, not just executables.
3780   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3781   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3782                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3783   if test $ac_cv_prog_liblockfile = yes; then
3784     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3785 This probably means that movemail could lose mail.
3786 There may be a 'development' package to install containing liblockfile.])
3787   fi
3788 fi
3789 AC_CHECK_HEADERS_ONCE(maillock.h)
3790 AC_SUBST(LIBS_MAIL)
3791
3792 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3793 ## interlock access to the mail spool.  The alternative is a lock file named
3794 ## /usr/spool/mail/$USER.lock.
3795 mail_lock=no
3796 case "$opsys" in
3797   aix4-2) mail_lock="lockf" ;;
3798
3799   gnu|freebsd|dragonfly|netbsd|openbsd|darwin) mail_lock="flock" ;;
3800
3801   ## On GNU/Linux systems, both methods are used by various mail programs.
3802   ## I assume most people are using newer mailers that have heard of flock.
3803   ## Change this if you need to.
3804   ## Debian contains a patch which says: "On Debian/GNU/Linux systems,
3805   ## configure gets the right answers, and that means *NOT* using flock.
3806   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3807   ## for details." and then uses '#ifdef DEBIAN'.  Unfortunately the
3808   ## Debian maintainer hasn't provided a clean fix for Emacs.
3809   ## movemail.c will use 'maillock' when MAILDIR, HAVE_LIBMAIL and
3810   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3811   ## correct logic.  -- fx
3812   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3813   ## liblockfile is a Free Software replacement for libmail, used on
3814   ## Debian systems and elsewhere. -rfr.
3815   gnu-*)
3816     mail_lock="flock"
3817     if test $have_mail = yes || test $have_lockfile = yes; then
3818       test $ac_cv_header_maillock_h = yes && mail_lock=no
3819     fi
3820     ;;
3821
3822   mingw32)
3823     mail_lock="none-needed" ;;
3824 esac
3825
3826 BLESSMAIL_TARGET=
3827 case "$mail_lock" in
3828   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3829
3830   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3831
3832   none-needed) ;;
3833
3834   *) BLESSMAIL_TARGET="need-blessmail" ;;
3835 esac
3836 AC_SUBST(BLESSMAIL_TARGET)
3837
3838 OLD_LIBS=$LIBS
3839 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3840 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3841 getrusage get_current_dir_name \
3842 lrand48 random rint \
3843 select getpagesize setlocale newlocale \
3844 getrlimit setrlimit shutdown \
3845 pthread_sigmask strsignal setitimer \
3846 sendto recvfrom getsockname getifaddrs freeifaddrs \
3847 gai_strerror sync \
3848 getpwent endpwent getgrent endgrent \
3849 cfmakeraw cfsetspeed copysign __executable_start log2)
3850 LIBS=$OLD_LIBS
3851
3852 dnl No need to check for posix_memalign if aligned_alloc works.
3853 AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3854 AC_CHECK_DECLS([aligned_alloc], [], [], [[#include <stdlib.h>]])
3855
3856 dnl Cannot use AC_CHECK_FUNCS
3857 AC_CACHE_CHECK([for __builtin_unwind_init],
3858                emacs_cv_func___builtin_unwind_init,
3859 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3860                 emacs_cv_func___builtin_unwind_init=yes,
3861                 emacs_cv_func___builtin_unwind_init=no)])
3862 if test $emacs_cv_func___builtin_unwind_init = yes; then
3863   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3864             [Define to 1 if you have the '__builtin_unwind_init' function.])
3865 fi
3866
3867 AC_CHECK_HEADERS_ONCE(sys/un.h)
3868
3869 AC_FUNC_FSEEKO
3870
3871 # UNIX98 PTYs.
3872 AC_CHECK_FUNCS(grantpt)
3873
3874 # PTY-related GNU extensions.
3875 AC_CHECK_FUNCS(getpt posix_openpt)
3876
3877 # Check this now, so that we will NOT find the above functions in ncurses.
3878 # That is because we have not set up to link ncurses in lib-src.
3879 # It's better to believe a function is not available
3880 # than to expect to find it in ncurses.
3881 # Also we need tputs and friends to be able to build at all.
3882 AC_MSG_CHECKING([for library containing tputs])
3883 # Run a test program that contains a call to tputs, a call that is
3884 # never executed.  This tests whether a pre-'main' dynamic linker
3885 # works with the library.  It's too much trouble to actually call
3886 # tputs in the test program, due to portability hassles.  When
3887 # cross-compiling, assume the test program will run if it links.
3888 AC_DEFUN([tputs_link_source], [
3889   AC_LANG_SOURCE(
3890      [[extern void tputs (const char *, int, int (*)(int));
3891        int main (int argc, char **argv)
3892        {
3893           if (argc == 10000)
3894             tputs (argv[0], 0, 0);
3895           return 0;
3896        }]])
3897 ])
3898 if test "${opsys}" = "mingw32"; then
3899   msg='none required'
3900 else
3901   # Maybe curses should be tried earlier?
3902   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3903   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3904     OLIBS=$LIBS
3905     if test -z "$tputs_library"; then
3906       LIBS_TERMCAP=
3907       msg='none required'
3908     else
3909       LIBS_TERMCAP=-l$tputs_library
3910       msg=$LIBS_TERMCAP
3911       LIBS="$LIBS_TERMCAP $LIBS"
3912     fi
3913     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3914       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3915     LIBS=$OLIBS
3916     if test "X$msg" != Xno; then
3917       break
3918     fi
3919   done
3920 fi
3921 AC_MSG_RESULT([$msg])
3922 if test "X$msg" = Xno; then
3923   AC_MSG_ERROR([The required function 'tputs' was not found in any library.
3924 The following libraries were tried (in order):
3925   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3926 Please try installing whichever of these libraries is most appropriate
3927 for your system, together with its header files.
3928 For example, a libncurses-dev(el) or similar package.])
3929 fi
3930
3931 ## Use termcap instead of terminfo?
3932 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3933 TERMINFO=yes
3934 ## FIXME?  In the cases below where we unconditionally set
3935 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3936 ## if that was found above to have tputs.
3937 ## Should we use the gnu* logic everywhere?
3938 case "$opsys" in
3939   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3940   ##  The ncurses library has been moved out of the System framework in
3941   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3942   ##  option to use it.
3943   darwin) LIBS_TERMCAP="-lncurses" ;;
3944
3945   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3946
3947   freebsd)
3948     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3949     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3950     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3951 [[#if __FreeBSD_version < 400000
3952 fail;
3953 #endif
3954 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3955
3956     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3957
3958     if test $emacs_cv_freebsd_terminfo = yes; then
3959       LIBS_TERMCAP="-lncurses"
3960     else
3961       TERMINFO=no
3962       LIBS_TERMCAP="-ltermcap"
3963     fi
3964     ;;
3965
3966   mingw32)
3967     TERMINFO=no
3968     LIBS_TERMCAP=
3969     ;;
3970
3971   netbsd)
3972     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3973       TERMINFO=no
3974       LIBS_TERMCAP="-ltermcap"
3975     fi
3976     ;;
3977
3978   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3979
3980   ## hpux: Make sure we get select from libc rather than from libcurses
3981   ##  because libcurses on HPUX 10.10 has a broken version of select.
3982   ##  We used to use -lc -lcurses, but this may be cleaner.
3983   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3984   # set that way, now it uses the default).  Isn't this a contradiction?
3985   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3986
3987 esac
3988
3989 TERMCAP_OBJ=tparam.o
3990 if test $TERMINFO = yes; then
3991   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3992   TERMCAP_OBJ=terminfo.o
3993 fi
3994 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3995   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3996 fi
3997 AC_SUBST(LIBS_TERMCAP)
3998 AC_SUBST(TERMCAP_OBJ)
3999
4000 # GNU/Linux-specific timer functions.
4001 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
4002   [AC_COMPILE_IFELSE(
4003      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
4004                       ]],
4005                       [[timerfd_create (CLOCK_REALTIME,
4006                                         TFD_CLOEXEC | TFD_NONBLOCK);
4007                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
4008      [emacs_cv_have_timerfd=yes],
4009      [emacs_cv_have_timerfd=no])])
4010 if test "$emacs_cv_have_timerfd" = yes; then
4011   AC_DEFINE([HAVE_TIMERFD], 1,
4012     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
4013 fi
4014
4015 # Alternate stack for signal handlers.
4016 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
4017                [emacs_cv_alternate_stack],
4018   [AC_COMPILE_IFELSE(
4019      [AC_LANG_PROGRAM([[#include <signal.h>
4020                       ]],
4021                       [[stack_t ss;
4022                         struct sigaction sa;
4023                         ss.ss_sp = malloc (SIGSTKSZ);
4024                         ss.ss_size = SIGSTKSZ;
4025                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
4026                         sigaltstack (&ss, 0);
4027                         sigaction (SIGSEGV, &sa, 0);]])],
4028      [emacs_cv_alternate_stack=yes],
4029      [emacs_cv_alternate_stack=no])])
4030
4031 # Do we need the Hesiod library to provide the support routines?
4032 dnl FIXME?  Should we be skipping this on Darwin too?
4033 LIBHESIOD=
4034 LIBRESOLV=
4035 if test "$with_hesiod" != no ; then
4036   # Don't set $LIBS here -- see comments above.  FIXME which comments?
4037   resolv=no
4038   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
4039      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
4040                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
4041   if test "$resolv" = yes ; then
4042     RESOLVLIB=-lresolv
4043   else
4044     RESOLVLIB=
4045   fi
4046   hesiod=no
4047   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
4048         hesiod=yes, :, $RESOLVLIB)])
4049
4050   if test x"$hesiod" = xyes; then
4051     LIBHESIOD=-lhesiod
4052     LIBRESOLV=$RESOLVLIB
4053   fi
4054 fi
4055 AC_SUBST(LIBHESIOD)
4056 AC_SUBST(LIBRESOLV)
4057
4058 # These tell us which Kerberos-related libraries to use.
4059 COM_ERRLIB=
4060 CRYPTOLIB=
4061 KRB5LIB=
4062 DESLIB=
4063 KRB4LIB=
4064
4065 if test "${with_kerberos}" != no; then
4066   OLD_LIBS=$LIBS
4067   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
4068   if test $have_com_err = yes; then
4069     COM_ERRLIB=-lcom_err
4070     LIBS="$COM_ERRLIB $LIBS"
4071   fi
4072   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
4073   if test $have_crypto = yes; then
4074     CRYPTOLIB=-lcrypto
4075     LIBS="$CRYPTOLIB $LIBS"
4076   fi
4077   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
4078   if test $have_k5crypto = yes; then
4079     CRYPTOLIB=-lk5crypto
4080     LIBS="$CRYPTOLIB $LIBS"
4081   fi
4082   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
4083   if test $have_krb5=yes; then
4084     KRB5LIB=-lkrb5
4085     LIBS="$KRB5LIB $LIBS"
4086   fi
4087   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
4088   if test "${with_kerberos5}" = no; then
4089     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
4090     if test $have_des425 = yes; then
4091       DESLIB=-ldes425
4092       LIBS="$DESLIB $LIBS"
4093     else
4094       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
4095       if test $have_des = yes; then
4096         DESLIB=-ldes
4097         LIBS="$DESLIB $LIBS"
4098       fi
4099     fi
4100     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
4101     if test $have_krb4 = yes; then
4102       KRB4LIB=-lkrb4
4103       LIBS="$KRB4LIB $LIBS"
4104     else
4105       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
4106       if test $have_krb = yes; then
4107         KRB4LIB=-lkrb
4108         LIBS="$KRB4LIB $LIBS"
4109       fi
4110     fi
4111   fi
4112
4113   if test "${with_kerberos5}" != no; then
4114     AC_CHECK_HEADERS(krb5.h,
4115       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
4116                         [#include <krb5.h>])])
4117   else
4118     AC_CHECK_HEADERS(krb.h,,
4119                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
4120                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
4121   fi
4122   AC_CHECK_HEADERS(com_err.h)
4123   LIBS=$OLD_LIBS
4124 fi
4125
4126 AC_SUBST(COM_ERRLIB)
4127 AC_SUBST(CRYPTOLIB)
4128 AC_SUBST(KRB5LIB)
4129 AC_SUBST(DESLIB)
4130 AC_SUBST(KRB4LIB)
4131
4132 AC_CHECK_HEADERS(valgrind/valgrind.h)
4133
4134 AC_CHECK_MEMBERS([struct unipair.unicode], [], [], [[#include <linux/kd.h>]])
4135
4136 AC_CHECK_FUNCS_ONCE(tzset)
4137
4138 ok_so_far=yes
4139 AC_CHECK_FUNC(socket, , ok_so_far=no)
4140 if test $ok_so_far = yes; then
4141   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
4142 fi
4143 if test $ok_so_far = yes; then
4144   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
4145 fi
4146 if test $ok_so_far = yes; then
4147 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
4148   AC_DEFINE(HAVE_INET_SOCKETS, 1,
4149             [Define to 1 if you have inet sockets.])
4150 fi
4151
4152 AC_FUNC_FORK
4153
4154 AC_CHECK_FUNCS(snprintf)
4155
4156 dnl Check for glib.  This differs from other library checks in that
4157 dnl Emacs need not link to glib unless some other library is already
4158 dnl linking to glib.  Although glib provides no facilities that Emacs
4159 dnl needs for its own purposes, when glib is present Emacs needs to
4160 dnl use primitives like g_main_context_query to avoid clashing with
4161 dnl glib at a low level.
4162 dnl
4163 dnl Check this late, since it depends on $GTK_CFLAGS etc.
4164 XGSELOBJ=
4165 OLDCFLAGS="$CFLAGS"
4166 OLDLIBS="$LIBS"
4167 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
4168 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
4169 CFLAGS="$CFLAGS $NOTIFY_CFLAGS $CAIRO_CFLAGS"
4170 LIBS="$LIBS $NOTIFY_LIBS $CAIRO_LIBS"
4171 AC_MSG_CHECKING([whether GLib is linked in])
4172 AC_LINK_IFELSE([AC_LANG_PROGRAM(
4173         [[#include <glib.h>
4174         ]],
4175         [[g_print ("Hello world");]])],
4176      [links_glib=yes],
4177      [links_glib=no])
4178 AC_MSG_RESULT([$links_glib])
4179 if test "${links_glib}" = "yes"; then
4180   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
4181   if test "$HAVE_NS" = no;then
4182     XGSELOBJ=xgselect.o
4183   fi
4184 fi
4185 CFLAGS="$OLDCFLAGS"
4186 LIBS="$OLDLIBS"
4187 AC_SUBST(XGSELOBJ)
4188
4189 dnl Adapted from Haible's version.
4190 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
4191   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
4192     [[char* cs = nl_langinfo(CODESET);]])],
4193     emacs_cv_langinfo_codeset=yes,
4194     emacs_cv_langinfo_codeset=no)
4195   ])
4196 if test $emacs_cv_langinfo_codeset = yes; then
4197   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
4198     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
4199 fi
4200
4201 AC_TYPE_MBSTATE_T
4202
4203 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
4204 dnl how the tty code is related to POSIX and/or other versions of termios.
4205 dnl The following looks like a useful start.
4206 dnl
4207 dnl AC_SYS_POSIX_TERMIOS
4208 dnl if test $ac_cv_sys_posix_termios = yes; then
4209 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
4210 dnl                                and macros for terminal control.])
4211 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
4212 dnl fi
4213
4214 dnl Turned on June 1996 supposing nobody will mind it.
4215 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
4216 if test "${opsys}" != "mingw32"; then
4217    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
4218      in the full name stands for the login id.])
4219 fi
4220
4221 dnl Everybody supports this, except MS.
4222 dnl Seems like the kind of thing we should be testing for, though.
4223 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4224 if test "${opsys}" != "mingw32"; then
4225   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4226 fi
4227
4228 dnl Everybody supports this, except MS-DOS.
4229 dnl Seems like the kind of thing we should be testing for, though.
4230 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4231 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4232   4.2-compatible sockets.])
4233
4234 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4235
4236 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4237   a null file, or a data sink.])
4238 if test "${opsys}" = "mingw32"; then
4239   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4240 else
4241   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4242 fi
4243
4244 if test "${opsys}" = "mingw32"; then
4245   SEPCHAR=';'
4246 else
4247   SEPCHAR=':'
4248 fi
4249 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4250 dnl This is for MinGW, and is used in test/Makefile.in.
4251 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4252 dnl decides that a command-line argument to be passed to a MinGW program
4253 dnl is a PATH-style list of directories.  But that heuristics plays it
4254 dnl safe, and only does the replacement when it is _absolutely_ sure it
4255 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4256 dnl which breaks in-tree builds.  So we do this manually instead.
4257 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4258 dnl be computed as ':' in MSYS Bash.
4259 AC_SUBST(SEPCHAR)
4260
4261 dnl Everybody supports this, except MS-DOS.
4262 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4263
4264 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4265
4266
4267 AC_DEFINE(DIRECTORY_SEP, ['/'],
4268   [Character that separates directories in a file name.])
4269
4270 if test "${opsys}" = "mingw32"; then
4271   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4272     [Returns true if character is a device separator.])
4273
4274   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4275     [Returns true if character is a directory separator.])
4276
4277   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4278     [Returns true if character is any form of separator.])
4279 else
4280   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4281     [Returns true if character is a device separator.])
4282
4283   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4284     [Returns true if character is a directory separator.])
4285
4286   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4287     [Returns true if character is any form of separator.])
4288 fi
4289
4290 if test "$USE_X_TOOLKIT" != "none"; then
4291   have_editres=yes
4292   case $opsys in
4293     hpux*)
4294       dnl Assar Westerlund <assar@sics.se> says this is necessary
4295       dnl for HP-UX 10.20, and that it works for HP-UX 0 as well.
4296       have_editres=no
4297     ;;
4298   esac
4299   if test "$have_editres" != no && test ! -z "$LIBXMU"; then
4300     OLDLIBS="$LIBS"
4301     dnl See libXmu.a check above.
4302     if test x$HAVE_X11XTR6 = xyes; then
4303       LIBS="-lXt -lSM -lICE $LIBXMU"
4304     else
4305       OTHERLIBS="-lXt -$LIBXMU"
4306     fi
4307     AC_TRY_LINK(
4308       [#include <X11/Intrinsic.h>
4309        #include <X11/Xmu/Editres.h>],
4310       [_XEditResCheckMessages (0, 0, 0, 0);],
4311       [AC_DEFINE([X_TOOLKIT_EDITRES], 1,
4312         [Define to 1 if we should use XEditRes.])])
4313     LIBS=$OLDLIBS
4314   fi
4315 fi
4316
4317 case $opsys in
4318   sol2* | unixware )
4319     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4320     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4321     dnl need the constant to dimension an array.  So wire in the appropriate
4322     dnl value here.
4323     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4324     ;;
4325 esac
4326
4327 emacs_broken_SIGIO=no
4328
4329 case $opsys in
4330   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4331   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4332   hpux* | nacl | openbsd | sol2* | unixware )
4333     emacs_broken_SIGIO=yes
4334     ;;
4335
4336   aix4-2)
4337     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4338     dnl the way this system works, libc functions that return malloced
4339     dnl memory use the libc malloc implementation. Calling xfree or
4340     dnl xrealloc on the results of such functions results in a crash.
4341     dnl
4342     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4343     dnl but that does not currently work on this system.
4344     dnl
4345     dnl It is possible to completely override the malloc implementation on
4346     dnl AIX, but that involves putting the malloc functions in a shared
4347     dnl library and setting the MALLOCTYPE environment variable to point to
4348     dnl that shared library.
4349     dnl
4350     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4351     dnl to avoid a crash just use the Emacs implementation for that function.
4352     dnl
4353     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4354     dnl of this file, so that we do not check for get_current_dir_name
4355     dnl on AIX.  But that might be fragile if something else ends
4356     dnl up testing for get_current_dir_name as a dependency.
4357     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4358       get_current_dir_name should not be used.])
4359     ;;
4360
4361   freebsd)
4362     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4363     dnl writes/reads on a PTY, read(2) returns bogus data:
4364     dnl
4365     dnl write(2)  1022 bytes
4366     dnl write(2)   954 bytes, get EAGAIN
4367     dnl read(2)   1024 bytes in process_read_output
4368     dnl read(2)     11 bytes in process_read_output
4369     dnl
4370     dnl That is, read(2) returns more bytes than have ever been written
4371     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4372     dnl successfully after processing (for example with CRs added if the
4373     dnl terminal is set up that way which it is here).  The same bytes will
4374     dnl be seen again in a later read(2), without the CRs.
4375     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4376       work around an issue when reading from a PTY.])
4377     ;;
4378 esac
4379
4380 case $opsys in
4381   gnu-* | sol2-10 )
4382     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4383     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4384   ;;
4385 esac
4386
4387 case $opsys in
4388   darwin | dragonfly | freebsd | netbsd | openbsd )
4389     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4390       close a pty to make it a controlling terminal (it is already a
4391       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4392   ;;
4393 esac
4394
4395 dnl FIXME Surely we can test for this rather than hard-code it.
4396 case $opsys in
4397   netbsd | openbsd) sound_device="/dev/audio" ;;
4398   *) sound_device="/dev/dsp" ;;
4399 esac
4400
4401 dnl Used in sound.c
4402 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4403   [Name of the default sound device.])
4404
4405
4406 dnl Emacs can read input using SIGIO and buffering characters itself,
4407 dnl or using CBREAK mode and making C-g cause SIGINT.
4408 dnl The choice is controlled by the variable interrupt_input.
4409 dnl
4410 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4411 dnl
4412 dnl Emacs uses the presence of the USABLE_SIGIO macro
4413 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4414 dnl INTERRUPT_INPUT to decide whether to use it by default.
4415 dnl
4416 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4417 dnl CBREAK mode has two disadvantages
4418 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4419 dnl I hear that in system V this problem does not exist.
4420 dnl 2) Control-G causes output to be discarded.
4421 dnl I do not know whether this can be fixed in system V.
4422 dnl
4423 dnl Another method of doing input is planned but not implemented.
4424 dnl It would have Emacs fork off a separate process
4425 dnl to read the input and send it to the true Emacs process
4426 dnl through a pipe.
4427 case $opsys in
4428   darwin | gnu-linux | gnu-kfreebsd )
4429     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4430   ;;
4431 esac
4432
4433
4434 dnl If the system's imake configuration file defines 'NeedWidePrototypes'
4435 dnl as 'NO', we must define NARROWPROTO manually.  Such a define is
4436 dnl generated in the Makefile generated by 'xmkmf'.  If we don't define
4437 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4438 dnl taking float or double parameters.
4439 case $opsys in
4440   cygwin|gnu|gnu-linux|gnu-kfreebsd|freebsd|netbsd|openbsd)
4441     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4442       file defines 'NeedWidePrototypes' as 'NO'.])
4443   ;;
4444 esac
4445
4446
4447 dnl Used in process.c, this must be a loop, even if it only runs once.
4448 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4449 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4450 dnl trying suffixes 0-16.
4451 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4452   first PTY, if PTYs are supported.])
4453 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4454 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4455   end of a PTY, if non-standard.])
4456 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4457   end of a PTY, if non-standard.])
4458
4459 case $opsys in
4460   aix4-2 )
4461     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4462     dnl You allocate a pty by opening /dev/ptc to get the master side.
4463     dnl To get the name of the slave side, you just ttyname() the master side.
4464     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4465     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4466     ;;
4467
4468   cygwin )
4469     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4470     dnl multi-line AC_DEFINEs are hard. :(
4471     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4472     AC_DEFINE(PTY_NAME_SPRINTF, [])
4473     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4474     ;;
4475
4476   gnu | openbsd )
4477     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4478     ;;
4479
4480   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd | darwin | nacl )
4481     dnl if HAVE_GRANTPT
4482     if test "x$ac_cv_func_grantpt" = xyes; then
4483       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4484       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4485       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4486       dnl to prevent sigchld_handler from intercepting the child's death.
4487       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4488       dnl if HAVE_POSIX_OPENPT
4489       if test "x$ac_cv_func_posix_openpt" = xyes; then
4490         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4491         AC_DEFINE(PTY_NAME_SPRINTF, [])
4492       dnl if HAVE_GETPT
4493       elif test "x$ac_cv_func_getpt" = xyes; then
4494         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4495         AC_DEFINE(PTY_NAME_SPRINTF, [])
4496       else
4497         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4498       fi
4499     else
4500       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4501     fi
4502     ;;
4503
4504   hpux*)
4505     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4506     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4507     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4508     ;;
4509
4510   sol2* )
4511     dnl On SysVr4, grantpt(3) forks a subprocess, so do not use
4512     dnl O_CLOEXEC when opening the pty, and keep the SIGCHLD handler
4513     dnl from intercepting that death.  If any child but grantpt's should die
4514     dnl within, it should be caught after sigrelse(2).
4515     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4516     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4517     ;;
4518
4519   unixware )
4520     dnl Comments are as per sol2*.
4521     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4522     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4523     ;;
4524 esac
4525
4526
4527 case $opsys in
4528   sol2* | unixware )
4529     dnl This change means that we don't loop through allocate_pty too
4530     dnl many times in the (rare) event of a failure.
4531     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4532     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4533     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4534     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (forkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (forkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (forkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4535     ;;
4536 esac
4537
4538
4539 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4540 "typing" a signal character on the pty.])
4541
4542 case $opsys in
4543   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4544   aix4-2 | cygwin | gnu | dragonfly | freebsd | netbsd | openbsd | darwin )
4545     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4546     ;;
4547
4548   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4549   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4550   gnu-linux | gnu-kfreebsd )
4551
4552     AC_MSG_CHECKING([for signals via characters])
4553     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4554 #include <linux/version.h>
4555 #if LINUX_VERSION_CODE < 0x20400
4556 # error "Linux version too old"
4557 #endif
4558       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4559
4560     AC_MSG_RESULT([$emacs_signals_via_chars])
4561     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4562     ;;
4563 esac
4564
4565
4566 AH_TEMPLATE(TAB3, [Undocumented.])
4567
4568 case $opsys in
4569   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4570
4571   gnu | dragonfly | freebsd | netbsd | openbsd )
4572     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4573     AC_DEFINE(TAB3, OXTABS)
4574     ;;
4575
4576   gnu-linux | gnu-kfreebsd )
4577     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4578 #ifndef __ia64__
4579 # error "not ia64"
4580 #endif
4581       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4582         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4583         [Mark a secondary stack, like the register stack on the ia64.]), [])
4584     ;;
4585
4586   hpux*)
4587     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4588       run_time_remap; for HPUX.])
4589     ;;
4590 esac
4591
4592
4593 dnl This won't be used automatically yet.  We also need to know, at least,
4594 dnl that the stack is continuous.
4595 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4596   registers relevant for conservative garbage collection in the jmp_buf.])
4597
4598
4599 case $opsys in
4600   dnl Not all the architectures are tested, but there are Debian packages
4601   dnl for SCM and/or Guile on them, so the technique must work.  See also
4602   dnl comments in alloc.c concerning setjmp and gcc.
4603   dnl Fixme: it's probably safe to just use the GCC conditional below.
4604   gnu-linux | gnu-kfreebsd )
4605     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4606 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4607   || defined __alpha__ || defined __mips__ || defined __s390__ \
4608   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4609   || defined __ia64__ || defined __sh__
4610 /* ok */
4611 #else
4612 # error "setjmp not known to work on this arch"
4613 #endif
4614     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4615     ;;
4616 esac
4617
4618
4619 if test x$GCC = xyes; then
4620    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4621    AC_DEFINE(GC_SETJMP_WORKS, 1)
4622 else
4623   case $opsys in
4624     aix* | dragonfly | freebsd | netbsd | openbsd | sol2* )
4625       AC_DEFINE(GC_SETJMP_WORKS, 1)
4626       ;;
4627   esac
4628 fi                              dnl GCC?
4629
4630 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4631 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4632   [AC_LINK_IFELSE(
4633      [AC_LANG_PROGRAM(
4634        [[#include <setjmp.h>
4635          #ifdef __MINGW32__
4636          # define _longjmp longjmp
4637          #endif
4638        ]],
4639        [[jmp_buf j;
4640          if (! _setjmp (j))
4641            _longjmp (j, 1);]])],
4642      [emacs_cv_func__setjmp=yes],
4643      [emacs_cv_func__setjmp=no])])
4644 if test $emacs_cv_func__setjmp = yes; then
4645   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4646 fi
4647
4648 # We need to preserve signal mask to handle C stack overflows.
4649 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4650   [AC_LINK_IFELSE(
4651      [AC_LANG_PROGRAM(
4652        [[#include <setjmp.h>
4653        ]],
4654        [[sigjmp_buf j;
4655          if (! sigsetjmp (j, 1))
4656            siglongjmp (j, 1);]])],
4657      [emacs_cv_func_sigsetjmp=yes],
4658      [emacs_cv_func_sigsetjmp=no])])
4659 if test $emacs_cv_func_sigsetjmp = yes; then
4660   AC_DEFINE([HAVE_SIGSETJMP], 1,
4661     [Define to 1 if sigsetjmp and siglongjmp work.])
4662 fi
4663
4664 case $emacs_cv_func_sigsetjmp,$emacs_cv_alternate_stack,$opsys in
4665   yes,yes,* | *,*,mingw32)
4666     AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4667       [Define to 1 if C stack overflow can be handled in some cases.]);;
4668 esac
4669
4670 case $opsys in
4671   sol2* | unixware )
4672     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4673     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4674     dnl and this is all we need.
4675     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4676     ;;
4677 esac
4678
4679
4680 case $opsys in
4681   hpux* | sol2* )
4682     dnl Used in xfaces.c.
4683     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4684       some systems, where it requires time.h.])
4685     ;;
4686 esac
4687
4688
4689 dnl Define symbols to identify the version of Unix this is.
4690 dnl Define all the symbols that apply correctly.
4691 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4692 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4693 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4694 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4695
4696 case $opsys in
4697   aix4-2)
4698     AC_DEFINE(USG, [])
4699     dnl This symbol should be defined on AIX Version 3  ???????
4700     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4701 #ifndef _AIX
4702 # error "_AIX not defined"
4703 #endif
4704     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4705     ;;
4706
4707   cygwin)
4708     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4709     ;;
4710
4711   darwin)
4712     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4713     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4714     dnl distinguish OS X from pure Darwin.
4715     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4716     ;;
4717
4718   gnu-linux | gnu-kfreebsd )
4719     AC_DEFINE(USG, [])
4720     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4721     ;;
4722
4723   hpux*)
4724     AC_DEFINE(USG, [])
4725     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4726     ;;
4727
4728   mingw32)
4729     AC_DEFINE(DOS_NT, [])
4730     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4731     if test "x$ac_enable_checking" != "x" ; then
4732       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4733     fi
4734     ;;
4735
4736   sol2*)
4737     AC_DEFINE(USG, [])
4738     AC_DEFINE(USG5_4, [])
4739     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4740     ;;
4741
4742   unixware)
4743     AC_DEFINE(USG, [])
4744     AC_DEFINE(USG5_4, [])
4745     ;;
4746 esac
4747
4748 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4749   [case $opsys in
4750      aix4-2 | nacl)
4751        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4752        emacs_cv_usable_FIONREAD=no
4753        ;;
4754
4755      mingw32)
4756        emacs_cv_usable_FIONREAD=yes
4757        ;;
4758
4759      *)
4760        AC_COMPILE_IFELSE(
4761          [AC_LANG_PROGRAM([[#include <sys/types.h>
4762                             #include <sys/ioctl.h>
4763                             #ifdef USG5_4
4764                             # include <sys/filio.h>
4765                             #endif
4766                           ]],
4767                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4768          [emacs_cv_usable_FIONREAD=yes],
4769          [emacs_cv_usable_FIONREAD=no])
4770        ;;
4771    esac])
4772 if test $emacs_cv_usable_FIONREAD = yes; then
4773   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4774
4775   if test $emacs_broken_SIGIO = no; then
4776     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4777       [AC_COMPILE_IFELSE(
4778          [AC_LANG_PROGRAM([[#include <fcntl.h>
4779                             #include <signal.h>
4780                           ]],
4781                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4782          [emacs_cv_usable_SIGIO=yes],
4783          [emacs_cv_usable_SIGIO=no])],
4784       [emacs_cv_usable_SIGIO=yes],
4785       [emacs_cv_usable_SIGIO=no])
4786     if test $emacs_cv_usable_SIGIO = yes; then
4787       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4788     fi
4789   fi
4790 fi
4791
4792 case $opsys in
4793   hpux11)
4794     dnl It works to open the pty's tty in the parent (Emacs), then
4795     dnl close and reopen it in the child.
4796     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4797       works to open a pty's tty in the parent process, then close and
4798       reopen it in the child.])
4799     ;;
4800
4801   sol2-10)
4802     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4803       on Solaris.])
4804     ;;
4805 esac
4806
4807 # Set up the CFLAGS for real compilation, so we can substitute it.
4808 CFLAGS="$REAL_CFLAGS"
4809 CPPFLAGS="$REAL_CPPFLAGS"
4810 LIBS="$REAL_LIBS"
4811
4812 ## Hack to detect a buggy GCC version.
4813 if test "$GCC" = yes && \
4814    $CC --version 2> /dev/null | grep 'gcc.* 4.5.0' >/dev/null; then
4815   case $CFLAGS in
4816     *-fno-optimize-sibling-calls*) ;;
4817     *-O@<:@23@:>@*)
4818       AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS.]);;
4819   esac
4820 fi
4821
4822 version=$PACKAGE_VERSION
4823
4824 copyright="Copyright (C) 2016 Free Software Foundation, Inc."
4825 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4826   [Short copyright string for this version of Emacs.])
4827 AC_SUBST(copyright)
4828
4829 ### Specify what sort of things we'll be editing into Makefile and config.h.
4830 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4831 AC_SUBST(version)
4832 AC_SUBST(configuration)
4833 ## Unused?
4834 AC_SUBST(canonical)
4835 AC_SUBST(srcdir)
4836 AC_SUBST(prefix)
4837 AC_SUBST(exec_prefix)
4838 AC_SUBST(bindir)
4839 AC_SUBST(datadir)
4840 AC_SUBST(sharedstatedir)
4841 AC_SUBST(libexecdir)
4842 AC_SUBST(mandir)
4843 AC_SUBST(infodir)
4844 AC_SUBST(lispdir)
4845 AC_SUBST(standardlisppath)
4846 AC_SUBST(locallisppath)
4847 AC_SUBST(lisppath)
4848 AC_SUBST(x_default_search_path)
4849 AC_SUBST(etcdir)
4850 AC_SUBST(archlibdir)
4851 AC_SUBST(etcdocdir)
4852 AC_SUBST(bitmapdir)
4853 AC_SUBST(gamedir)
4854 AC_SUBST(gameuser)
4855 AC_SUBST(gamegroup)
4856 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4857 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4858 ## end of LIBX_BASE, but nothing ever set it.
4859 AC_SUBST(LD_SWITCH_X_SITE)
4860 AC_SUBST(C_SWITCH_X_SITE)
4861 AC_SUBST(GNUSTEP_CFLAGS)
4862 AC_SUBST(CFLAGS)
4863 ## Used in lwlib/Makefile.in.
4864 AC_SUBST(X_TOOLKIT_TYPE)
4865 AC_SUBST(ns_appdir)
4866 AC_SUBST(ns_appbindir)
4867 AC_SUBST(ns_appresdir)
4868 AC_SUBST(ns_appsrc)
4869 AC_SUBST(GNU_OBJC_CFLAGS)
4870 AC_SUBST(OTHER_FILES)
4871
4872 if test -n "${term_header}"; then
4873     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4874         [Define to the header for the built-in window system.])
4875 fi
4876
4877 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4878                    [Define to the canonical Emacs configuration name.])
4879 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4880                    [Define to the options passed to configure.])
4881 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4882   define this to include extra configuration information.])
4883
4884 case $opsys in
4885   mingw32)
4886     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4887     ;;
4888 esac
4889
4890 XMENU_OBJ=
4891 XOBJ=
4892 FONT_OBJ=
4893 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4894   AC_DEFINE(HAVE_X_WINDOWS, 1,
4895             [Define to 1 if you want to use the X window system.])
4896   XMENU_OBJ=xmenu.o
4897   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4898   FONT_OBJ=xfont.o
4899   if test "$HAVE_CAIRO" = "yes"; then
4900     FONT_OBJ="ftfont.o ftcrfont.o"
4901   elif test "$HAVE_XFT" = "yes"; then
4902     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4903   elif test "$HAVE_FREETYPE" = "yes"; then
4904     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4905   fi
4906   AC_SUBST(FONT_OBJ)
4907 fi
4908 AC_SUBST(XMENU_OBJ)
4909 AC_SUBST(XOBJ)
4910 AC_SUBST(FONT_OBJ)
4911
4912 WIDGET_OBJ=
4913 MOTIF_LIBW=
4914 if test "${USE_X_TOOLKIT}" != "none" ; then
4915   WIDGET_OBJ=widget.o
4916   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4917   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4918     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4919   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4920     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4921     MOTIF_LIBW=-lXm
4922     case "$opsys" in
4923       gnu-linux)
4924         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4925         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4926         ;;
4927
4928       unixware)
4929         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4930         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4931         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4932         ;;
4933
4934       aix4-2)
4935         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4936         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4937         ;;
4938     esac
4939     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4940   fi
4941 fi
4942 AC_SUBST(WIDGET_OBJ)
4943
4944 TOOLKIT_LIBW=
4945 case "$USE_X_TOOLKIT" in
4946   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4947   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4948   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4949 esac
4950 if test "$HAVE_XWIDGETS" = "yes"; then
4951   TOOLKIT_LIBW="$TOOLKIT_LIBW -lXcomposite"
4952 fi
4953 AC_SUBST(TOOLKIT_LIBW)
4954
4955 if test "${opsys}" != "mingw32"; then
4956   if test "$USE_X_TOOLKIT" = "none"; then
4957     LIBXT_OTHER="\$(LIBXSM)"
4958   else
4959     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4960   fi
4961 fi
4962 AC_SUBST(LIBXT_OTHER)
4963
4964 if test "${HAVE_X11}" = "yes" ; then
4965   AC_DEFINE(HAVE_X11, 1,
4966             [Define to 1 if you want to use version 11 of X windows.])
4967   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4968 else
4969   LIBX_OTHER=
4970 fi
4971 AC_SUBST(LIBX_OTHER)
4972
4973 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4974   LIBXMENU=
4975 elif test "$USE_X_TOOLKIT" = none; then
4976   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4977 else
4978   LIBXMENU='$(lwlibdir)/liblw.a'
4979 fi
4980 AC_SUBST(LIBXMENU)
4981
4982 AC_CACHE_CHECK([for struct alignment],
4983   [emacs_cv_struct_alignment],
4984   [AC_COMPILE_IFELSE(
4985      [AC_LANG_PROGRAM([[#include <stddef.h>
4986                         struct __attribute__ ((aligned (8))) s { char c; };
4987                         struct t { char c; struct s s; };
4988                         char verify[offsetof (struct t, s) == 8 ? 1 : -1];
4989                       ]])],
4990      [emacs_cv_struct_alignment=yes],
4991      [emacs_cv_struct_alignment=no])])
4992 if test "$emacs_cv_struct_alignment" = yes; then
4993   AC_DEFINE([HAVE_STRUCT_ATTRIBUTE_ALIGNED], 1,
4994     [Define to 1 if 'struct __attribute__ ((aligned (N)))' aligns the
4995      structure to an N-byte boundary.])
4996 fi
4997
4998 if test "${GNU_MALLOC}" = "yes" ; then
4999   AC_DEFINE(GNU_MALLOC, 1,
5000             [Define to 1 if you want to use the GNU memory allocator.])
5001 fi
5002
5003 RALLOC_OBJ=
5004 if test "${REL_ALLOC}" = "yes" ; then
5005   AC_DEFINE(REL_ALLOC, 1,
5006             [Define REL_ALLOC if you want to use the relocating allocator for
5007              buffer space.])
5008
5009   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
5010 fi
5011 AC_SUBST(RALLOC_OBJ)
5012
5013 if test "$opsys" = "cygwin"; then
5014   CYGWIN_OBJ="cygw32.o"
5015   ## Cygwin differs because of its unexec().
5016   PRE_ALLOC_OBJ=
5017   POST_ALLOC_OBJ=lastfile.o
5018 elif test "$opsys" = "mingw32"; then
5019   CYGWIN_OBJ=
5020   PRE_ALLOC_OBJ=
5021   POST_ALLOC_OBJ=lastfile.o
5022 else
5023   CYGWIN_OBJ=
5024   PRE_ALLOC_OBJ=lastfile.o
5025   POST_ALLOC_OBJ=
5026 fi
5027 AC_SUBST(CYGWIN_OBJ)
5028 AC_SUBST(PRE_ALLOC_OBJ)
5029 AC_SUBST(POST_ALLOC_OBJ)
5030
5031 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
5032 dnl verbatim defined above.  The tricky name is apropos, as this hack
5033 dnl makes Fortify go sour!
5034 AH_VERBATIM([FORTIFY_SOUR],
5035 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
5036    The workaround disables some useful run-time checking, so it
5037    should be conditional to the platforms with the performance bug.
5038    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
5039 #if defined __APPLE__ && defined __GNUC__
5040 # ifndef _DONT_USE_CTYPE_INLINE_
5041 #  define _DONT_USE_CTYPE_INLINE_
5042 # endif
5043 # ifndef _FORTIFY_SOURCE
5044 #  define _FORTIFY_SOURCE 0
5045 # endif
5046 #endif
5047 ])
5048
5049 # If user asks to omit features, disable optional features that gnulib
5050 # might otherwise enable.
5051 if test "$with_features" = no && test "$enable_acl" != yes; then
5052   enable_acl=no
5053 fi
5054
5055 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
5056 # it temporarily reverts them to their pre-pkg-config values,
5057 # because gnulib needs to work with both src (which uses the
5058 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
5059 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
5060 # and it therefore needs to run in an environment where LIBS does not
5061 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
5062 # for some package unrelated to lib-src.
5063 SAVE_CFLAGS=$CFLAGS
5064 SAVE_LIBS=$LIBS
5065 CFLAGS=$pre_PKG_CONFIG_CFLAGS
5066 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
5067 gl_ASSERT_NO_GNULIB_POSIXCHECK
5068 gl_ASSERT_NO_GNULIB_TESTS
5069 gl_INIT
5070 CFLAGS=$SAVE_CFLAGS
5071 LIBS=$SAVE_LIBS
5072
5073 if test "${opsys}" = "mingw32"; then
5074   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
5075   # Remove unneeded switches from the value of CC that goes to Makefiles
5076   CC=`AS_ECHO(["$CC"]) | sed -e "s,$GCC_TEST_OPTIONS,,"`
5077 fi
5078
5079 case "$opsys" in
5080   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
5081
5082   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
5083
5084   darwin)
5085    ## The -headerpad option tells ld (see man page) to leave room at the
5086    ## end of the header for adding load commands.  Needed for dumping.
5087    ## 0x1000 is enough for roughly 52 load commands on the x86_64
5088    ## architecture (where they are 78 bytes each). The actual number of
5089    ## load commands added is not consistent but normally ranges from
5090    ## about 14 to about 34. Setting it high gets us plenty of slop and
5091    ## only costs about 1.5K of wasted binary space.
5092    headerpad_extra=1000
5093    if test "$HAVE_NS" = "yes"; then
5094      libs_nsgui="-framework AppKit"
5095      if test "$NS_IMPL_COCOA" = "yes"; then
5096         libs_nsgui="$libs_nsgui -framework IOKit"
5097      fi
5098    else
5099      libs_nsgui=
5100    fi
5101    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
5102
5103    ## This is here because src/Makefile.in did some extra fiddling around
5104    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
5105    ## LD_SWITCH_SYSTEM_TEMACS instead,
5106    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
5107      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
5108    ;;
5109
5110   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
5111   ## find X at run-time.
5112   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
5113   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
5114   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
5115   ## had different values in configure (in ac_link) and src/Makefile.in.
5116   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
5117   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
5118
5119   mingw32)
5120    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
5121    case "$canonical" in
5122      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5123      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5124    esac
5125    ;;
5126
5127   *) LD_SWITCH_SYSTEM_TEMACS= ;;
5128 esac
5129
5130 # -nopie fixes a temacs segfault on Gentoo, OpenBSD, and other systems
5131 # with "hardened" GCC configurations for some reason (Bug#18784).
5132 # We don't know why -nopie works, but not segfaulting is better than
5133 # segfaulting.  Use ac_c_werror_flag=yes when trying -nopie, otherwise
5134 # clang keeps warning that it does not understand -nopie, and pre-4.6
5135 # GCC has a similar problem (Bug#20338).
5136 AC_CACHE_CHECK([whether $CC accepts -nopie],
5137   [emacs_cv_prog_cc_nopie],
5138   [emacs_save_c_werror_flag=$ac_c_werror_flag
5139    emacs_save_LDFLAGS=$LDFLAGS
5140    ac_c_werror_flag=yes
5141    LDFLAGS="$LDFLAGS -nopie"
5142    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
5143      [emacs_cv_prog_cc_nopie=yes],
5144      [emacs_cv_prog_cc_nopie=no])
5145    ac_c_werror_flag=$emacs_save_c_werror_flag
5146    LDFLAGS=$emacs_save_LDFLAGS])
5147 if test "$emacs_cv_prog_cc_nopie" = yes; then
5148   LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -nopie"
5149 fi
5150
5151 if test x$ac_enable_profiling != x ; then
5152   case $opsys in
5153     *freebsd | gnu-linux) ;;
5154     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
5155   esac
5156 fi
5157
5158 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
5159
5160 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
5161
5162 ## Common for all window systems
5163 if test "$window_system" != "none"; then
5164   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
5165   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
5166   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
5167 fi
5168
5169 AC_SUBST(WINDOW_SYSTEM_OBJ)
5170
5171 AH_TOP([/* GNU Emacs site configuration template file.
5172
5173 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2016
5174   Free Software Foundation, Inc.
5175
5176 This file is part of GNU Emacs.
5177
5178 GNU Emacs is free software: you can redistribute it and/or modify
5179 it under the terms of the GNU General Public License as published by
5180 the Free Software Foundation, either version 3 of the License, or (at
5181 your option) any later version.
5182
5183 GNU Emacs is distributed in the hope that it will be useful,
5184 but WITHOUT ANY WARRANTY; without even the implied warranty of
5185 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
5186 GNU General Public License for more details.
5187
5188 You should have received a copy of the GNU General Public License
5189 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
5190
5191
5192 /* No code in Emacs #includes config.h twice, but some bits of code
5193    intended to work with other packages as well (like gmalloc.c)
5194    think they can include it as many times as they like.  */
5195 #ifndef EMACS_CONFIG_H
5196 #define EMACS_CONFIG_H
5197 ])dnl
5198
5199 AH_BOTTOM([#include <conf_post.h>
5200
5201 #endif /* EMACS_CONFIG_H */
5202
5203 /*
5204 Local Variables:
5205 mode: c
5206 End:
5207 */
5208 ])dnl
5209
5210 #### Report on what we decided to do.
5211 #### Report GTK as a toolkit, even if it doesn't use Xt.
5212 #### It makes printing result more understandable as using GTK sets
5213 #### toolkit_scroll_bars to yes by default.
5214 if test "${HAVE_GTK}" = "yes"; then
5215   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5216 fi
5217
5218 if test $USE_ACL -ne 0; then
5219   ACL_SUMMARY="yes $LIB_ACL"
5220 else
5221   ACL_SUMMARY=no
5222 fi
5223
5224 emacs_standard_dirs='Standard dirs'
5225 AS_ECHO(["
5226 Configured for '${canonical}'.
5227
5228   Where should the build process find the source code?    ${srcdir}
5229   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5230   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5231   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5232   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5233   What window system should Emacs use?                    ${window_system}
5234   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}
5235   Where do we find X Windows header files?                ${x_includes:-$emacs_standard_dirs}
5236   Where do we find X Windows libraries?                   ${x_libraries:-$emacs_standard_dirs}"])
5237
5238 optsep=
5239 emacs_config_features=
5240 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG CAIRO IMAGEMAGICK SOUND GPM DBUS \
5241   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5242   LIBOTF XFT ZLIB TOOLKIT_SCROLL_BARS X_TOOLKIT X11 NS MODULES \
5243   XWIDGETS LIBSYSTEMD CANNOT_DUMP; do
5244
5245     case $opt in
5246       CANNOT_DUMP) eval val=\${$opt} ;;
5247       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5248       TOOLKIT_SCROLL_BARS|X_TOOLKIT) eval val=\${USE_$opt} ;;
5249       *) eval val=\${HAVE_$opt} ;;
5250     esac
5251     case x$val in
5252       xno|xnone|x) continue ;;
5253     esac
5254     case $opt in
5255       X_TOOLKIT)
5256         case $val in
5257           GTK*|LUCID|MOTIF) opt=$val ;;
5258           *) continue ;;
5259         esac
5260       ;;
5261     esac
5262     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5263     optsep=' '
5264 done
5265 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5266   [Summary of some of the main features enabled by configure.])
5267
5268 AS_ECHO(["  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}
5269   Does Emacs use -lXpm?                                   ${HAVE_XPM}
5270   Does Emacs use -ljpeg?                                  ${HAVE_JPEG}
5271   Does Emacs use -ltiff?                                  ${HAVE_TIFF}
5272   Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF
5273   Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG
5274   Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}
5275   Does Emacs use cairo?                                   ${HAVE_CAIRO}
5276   Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}
5277   Does Emacs support sound?                               ${HAVE_SOUND}
5278   Does Emacs use -lgpm?                                   ${HAVE_GPM}
5279   Does Emacs use -ldbus?                                  ${HAVE_DBUS}
5280   Does Emacs use -lgconf?                                 ${HAVE_GCONF}
5281   Does Emacs use GSettings?                               ${HAVE_GSETTINGS}
5282   Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}
5283   Does Emacs use access control lists?                    ${ACL_SUMMARY}
5284   Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}
5285   Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}
5286   Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}
5287   Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}
5288   Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}
5289   Does Emacs use -lotf?                                   ${HAVE_LIBOTF}
5290   Does Emacs use -lxft?                                   ${HAVE_XFT}
5291   Does Emacs use -lsystemd?                               ${HAVE_LIBSYSTEMD}
5292   Does Emacs directly use zlib?                           ${HAVE_ZLIB}
5293   Does Emacs have dynamic modules support?                ${HAVE_MODULES}
5294   Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}
5295   Does Emacs support Xwidgets (requires gtk3)?            ${HAVE_XWIDGETS}
5296 "])
5297
5298 if test -n "${EMACSDATA}"; then
5299    AS_ECHO(["  Environment variable EMACSDATA set to:                  $EMACSDATA"])
5300 fi
5301 if test -n "${EMACSDOC}"; then
5302    AS_ECHO(["  Environment variable EMACSDOC set to:                   $EMACSDOC"])
5303 fi
5304
5305 echo
5306
5307 if test "$HAVE_NS" = "yes"; then
5308    echo
5309    AS_ECHO(["You must run \"${MAKE-make} install\" in order to test the built application.
5310 The installed application will go to nextstep/Emacs.app and can be
5311 run or moved from there."])
5312    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5313       echo "The application will be fully self-contained."
5314     else
5315       AS_ECHO(["The lisp resources for the application will be installed under ${prefix}.
5316 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5317 to run if these resources are not installed."])
5318    fi
5319    echo
5320 fi
5321
5322 if test "${opsys}" = "cygwin"; then
5323   case `uname -r` in
5324     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5325            echo
5326            ;;
5327   esac
5328 fi
5329
5330 # Remove any trailing slashes in these variables.
5331 case $prefix in
5332   */) prefix=`AS_DIRNAME(["$prefix."])`;;
5333 esac
5334 case $exec_prefix in
5335   */) exec_prefix=`AS_DIRNAME(["$exec_prefix."])`;;
5336 esac
5337
5338 if test "$HAVE_NS" = "yes"; then
5339   if test "$NS_IMPL_GNUSTEP" = yes; then
5340     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5341       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5342     ns_check_file=Resources/Info-gnustep.plist
5343   else
5344     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5345       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5346     ns_check_file=Contents/Info.plist
5347   fi
5348   AC_SUBST(ns_check_file)
5349 fi
5350
5351 dnl config.status treats $srcdir specially, so I think this is ok...
5352 AC_CONFIG_FILES([$srcdir/doc/man/emacs.1])
5353
5354 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5355 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5356 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5357 dnl (else you get "no 'Makefile.am' found for any configure output").
5358 dnl This will work, but you get a config.status that is not quite right
5359 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5360 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5361 dnl it seems better to just live with the duplication.
5362 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5363
5364 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5365        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5366        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5367        leim/Makefile nextstep/Makefile nt/Makefile])
5368
5369 dnl test/ is not present in release tarfiles.
5370 opt_makefile=test/Makefile
5371
5372 if test -f "$srcdir/$opt_makefile.in"; then
5373   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5374   dnl Again, it's best not to use a variable.  Though you can add
5375   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5376   AC_CONFIG_FILES([test/Makefile])
5377 fi
5378
5379
5380 dnl The admin/ directory used to be excluded from tarfiles.
5381 if test -d $srcdir/admin; then
5382   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/charsets/Makefile admin/unidata/Makefile admin/grammars/Makefile"
5383   AC_CONFIG_FILES([admin/charsets/Makefile])
5384   AC_CONFIG_FILES([admin/unidata/Makefile])
5385   AC_CONFIG_FILES([admin/grammars/Makefile])
5386 fi                              dnl -d admin
5387
5388
5389 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5390
5391 AC_SUBST(SUBDIR_MAKEFILES_IN)
5392
5393 dnl You might wonder (I did) why epaths.h is generated by running make,
5394 dnl rather than just letting configure generate it from epaths.in.
5395 dnl One reason is that the various paths are not fully expanded (see above);
5396 dnl eg gamedir=${prefix}/var/games/emacs.
5397 dnl Secondly, the GNU Coding standards require that one should be able
5398 dnl to run 'make prefix=/some/where/else' and override the values set
5399 dnl by configure.  This also explains the 'move-if-change' test and
5400 dnl the use of force in the 'epaths-force' rule in Makefile.in.
5401 AC_CONFIG_COMMANDS([src/epaths.h], [
5402 if test "${opsys}" = "mingw32"; then
5403   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5404 else
5405   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5406 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5407 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5408
5409 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5410 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5411 dnl or a symlink?
5412 AC_CONFIG_COMMANDS([src/.gdbinit], [
5413 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5414   AS_ECHO(["source $ac_abs_top_srcdir/src/.gdbinit"]) > src/.gdbinit
5415 fi
5416 ])
5417
5418 dnl Perhaps this would be better named doc-emacs-emacsver.texi?
5419 dnl See comments for etc-refcards-emacsver.tex.
5420 dnl Since we get a doc/emacs directory generated anyway, for the Makefile,
5421 dnl it is not quite the same.  But we are generating in $srcdir.
5422 AC_CONFIG_COMMANDS([doc/emacs/emacsver.texi], [
5423 ${MAKE-make} -s --no-print-directory -C doc/emacs doc-emacsver || \
5424 AC_MSG_ERROR(['doc/emacs/emacsver.texi' could not be made.])
5425 ])
5426
5427 dnl If we give this the more natural name, etc/refcards/emacsver.texi,
5428 dnl then a directory etc/refcards is created in the build directory,
5429 dnl which is probably harmless, but confusing (in out-of-tree builds).
5430 dnl (If we were to generate etc/refcards/Makefile, this might change.)
5431 dnl It is really $srcdir/etc/refcards/emacsver.tex that we generate.
5432 AC_CONFIG_COMMANDS([etc-refcards-emacsver.tex], [
5433 ${MAKE-make} -s MAKEFILE_NAME=do-not-make-Makefile etc-emacsver || \
5434 AC_MSG_ERROR(['etc/refcards/emacsver.tex' could not be made.])
5435 ])
5436
5437 AC_OUTPUT
5438
5439 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])