code.delx.au - gnu-emacs/blob - lisp/progmodes/compile.el

   1 ;;; compile.el --- run compiler as inferior of Emacs, parse error messages
   2
   3 ;; Copyright (C) 1985, 86, 87, 93, 94, 95, 96, 97, 98, 1999, 2001, 03, 2004
   4 ;;  Free Software Foundation, Inc.
   5
   6 ;; Authors: Roland McGrath <roland@gnu.org>,
   7 ;;          Daniel Pfeiffer <occitan@esperanto.org>
   8 ;; Maintainer: FSF
   9 ;; Keywords: tools, processes
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package provides the compile facilities documented in the Emacs user's
  31 ;; manual.
  32
  33 ;; This mode uses some complex data-structures:
  34
  35 ;;   LOC (or location) is a list of (COLUMN LINE FILE-STRUCTURE)
  36
  37 ;; COLUMN and LINE are numbers parsed from an error message.  COLUMN and maybe
  38 ;; LINE will be nil for a message that doesn't contain them.  Then the
  39 ;; location refers to a indented beginning of line or beginning of file.
  40 ;; Once any location in some file has been jumped to, the list is extended to
  41 ;; (COLUMN LINE FILE-STRUCTURE MARKER . VISITED) for all LOCs pertaining to
  42 ;; that file.
  43 ;; MARKER initially points to LINE and COLUMN in a buffer visiting that file.
  44 ;; Being a marker it sticks to some text, when the buffer grows or shrinks
  45 ;; before that point.  VISITED is t if we have jumped there, else nil.
  46
  47 ;;   FILE-STRUCTURE is a list of
  48 ;;   ((FILENAME . DIRECTORY) FORMATS (LINE LOC ...) ...)
  49
  50 ;; FILENAME is a string parsed from an error message.  DIRECTORY is a string
  51 ;; obtained by following directory change messages.  DIRECTORY will be nil for
  52 ;; an absolute filename.  FORMATS is a list of formats to apply to FILENAME if
  53 ;; a file of that name can't be found.
  54 ;; The rest of the list is an alist of elements with LINE as key.  The keys
  55 ;; are either nil or line numbers.  If present, nil comes first, followed by
  56 ;; the numbers in decreasing order.  The LOCs for each line are again an alist
  57 ;; ordered the same way.  Note that the whole file structure is referenced in
  58 ;; every LOC.
  59
  60 ;;   MESSAGE is a list of (LOC TYPE END-LOC)
  61
  62 ;; TYPE is 0 for info or 1 for warning if the message matcher identified it as
  63 ;; such, 2 otherwise (for a real error).  END-LOC is a LOC pointing to the
  64 ;; other end, if the parsed message contained a range.  If the end of the
  65 ;; range didn't specify a COLUMN, it defaults to -1, meaning end of line.
  66 ;; These are the value of the `message' text-properties in the compilation
  67 ;; buffer.
  68
  69 ;;; Code:
  70
  71 (eval-when-compile (require 'cl))
  72
  73 (defgroup compilation nil
  74   "Run compiler as inferior of Emacs, parse error messages."
  75   :group 'tools
  76   :group 'processes)
  77
  78
  79 ;;;###autoload
  80 (defcustom compilation-mode-hook nil
  81   "*List of hook functions run by `compilation-mode' (see `run-hooks')."
  82   :type 'hook
  83   :group 'compilation)
  84
  85 ;;;###autoload
  86 (defcustom compilation-window-height nil
  87   "*Number of lines in a compilation window.  If nil, use Emacs default."
  88   :type '(choice (const :tag "Default" nil)
  89                  integer)
  90   :group 'compilation)
  91
  92 (defvar compilation-first-column 1
  93   "*This is how compilers number the first column, usually 1 or 0.")
  94
  95 (defvar compilation-parse-errors-filename-function nil
  96   "Function to call to post-process filenames while parsing error messages.
  97 It takes one arg FILENAME which is the name of a file as found
  98 in the compilation output, and should return a transformed file name.")
  99
 100 ;;;###autoload
 101 (defvar compilation-process-setup-function nil
 102   "*Function to call to customize the compilation process.
 103 This function is called immediately before the compilation process is
 104 started.  It can be used to set any variables or functions that are used
 105 while processing the output of the compilation process.  The function
 106 is called with variables `compilation-buffer' and `compilation-window'
 107 bound to the compilation buffer and window, respectively.")
 108
 109 ;;;###autoload
 110 (defvar compilation-buffer-name-function nil
 111   "Function to compute the name of a compilation buffer.
 112 The function receives one argument, the name of the major mode of the
 113 compilation buffer.  It should return a string.
 114 nil means compute the name with `(concat \"*\" (downcase major-mode) \"*\")'.")
 115
 116 ;;;###autoload
 117 (defvar compilation-finish-function nil
 118   "Function to call when a compilation process finishes.
 119 It is called with two arguments: the compilation buffer, and a string
 120 describing how the process finished.")
 121
 122 ;;;###autoload
 123 (defvar compilation-finish-functions nil
 124   "Functions to call when a compilation process finishes.
 125 Each function is called with two arguments: the compilation buffer,
 126 and a string describing how the process finished.")
 127
 128 (defvar compilation-in-progress nil
 129   "List of compilation processes now running.")
 130 (or (assq 'compilation-in-progress minor-mode-alist)
 131     (setq minor-mode-alist (cons '(compilation-in-progress " Compiling")
 132                                  minor-mode-alist)))
 133
 134 (defvar compilation-error "error"
 135   "Stem of message to print when no matches are found.")
 136
 137 (defvar compilation-arguments nil
 138   "Arguments that were given to `compilation-start'.")
 139
 140 (defvar compilation-num-errors-found)
 141
 142 (defconst compilation-error-regexp-alist-alist
 143   '((absoft
 144      "^\\(?:[Ee]rror on \\|[Ww]arning on\\( \\)\\)?[Ll]ine[ \t]+\\([0-9]+\\)[ \t]+\
 145 of[ \t]+\"?\\([a-zA-Z]?:?[^\":\n]+\\)\"?:" 3 2 nil (1))
 146
 147     (ada
 148      "\\(warning: .*\\)? at \\([^ \n]+\\):\\([0-9]+\\)$" 2 3 nil (1))
 149
 150     (aix
 151      " in line \\([0-9]+\\) of file \\([^ \n]+[^. \n]\\)\\.? " 2 1)
 152
 153     (ant
 154      "^[ \t]*\\[[^] \n]+\\][ \t]*\\([^: \n]+\\):\\([0-9]+\\):\\(?:\\([0-9]+\\):[0-9]+:[0-9]+:\\)?\
 155 \\( warning\\)?" 1 2 3 (4))
 156
 157     (bash
 158      "^\\([^: \n\t]+\\): line \\([0-9]+\\):" 1 2)
 159
 160     (borland
 161      "^\\(?:Error\\|Warnin\\(g\\)\\) \\(?:[FEW][0-9]+ \\)?\
 162 \\([a-zA-Z]?:?[^:( \t\n]+\\)\
 163  \\([0-9]+\\)\\(?:[) \t]\\|:[^0-9\n]\\)" 2 3 nil (1))
 164
 165     (caml
 166      "^ *File \\(\"?\\)\\([^,\" \n\t<>]+\\)\\1, lines? \\([0-9]+\\)-?\\([0-9]+\\)?\\(?:$\\|,\
 167 \\(?: characters? \\([0-9]+\\)-?\\([0-9]+\\)?:\\)?\\([ \n]Warning:\\)?\\)"
 168      2 (3 . 4) (5 . 6) (7))
 169
 170     (comma
 171      "^\"\\([^,\" \n\t]+\\)\", line \\([0-9]+\\)\
 172 \\(?:[(. pos]+\\([0-9]+\\))?\\)?[:.,; (-]\\( warning:\\|[-0-9 ]*(W)\\)?" 1 2 3 (4))
 173
 174     (edg-1
 175      "^\\([^ \n]+\\)(\\([0-9]+\\)): \\(?:error\\|warnin\\(g\\)\\|remar\\(k\\)\\)"
 176      1 2 nil (3 . 4))
 177     (edg-2
 178      "at line \\([0-9]+\\) of \"\\([^ \n]+\\)\"$"
 179      2 1 nil 0)
 180
 181     (epc
 182      "^Error [0-9]+ at (\\([0-9]+\\):\\([^)\n]+\\))" 2 1)
 183
 184     (iar
 185      "^\"\\(.*\\)\",\\([0-9]+\\)\\s-+\\(?:Error\\|Warnin\\(g\\)\\)\\[[0-9]+\\]:"
 186      1 2 nil (3))
 187
 188     (ibm
 189      "^\\([^( \n\t]+\\)(\\([0-9]+\\):\\([0-9]+\\)) :\
 190  \\(?:warnin\\(g\\)\\|informationa\\(l\\)\\)?" 1 2 3 (4 . 5))
 191
 192     ;; fixme: should be `mips'
 193     (irix
 194      "^[-[:alnum:]_/]+: \\(?:[sS]evere\\|[eE]rror\\|[wW]arnin\\(g\\)\\|[iI]nf\\(o\\)\\)[0-9 ]*:\
 195  \\([^,\" \n\t]+\\)\\(?:, line\\|:\\) \\([0-9]+\\):" 3 4 nil (1 . 2))
 196
 197     (java
 198      "^\\(?:[ \t]+at \\|==[0-9]+== +\\(?:at\\|b\\(y\\)\\)\\).+(\\([^()\n]+\\):\\([0-9]+\\))$" 2 3 nil (1))
 199
 200     (jikes-file
 201      "^\\(?:Found\\|Issued\\) .* compiling \"\\(.+\\)\":$" 1 nil nil 0)
 202     (jikes-line
 203      "^ *\\([0-9]+\\)\\.[ \t]+.*\n +\\(<-*>\n\\*\\*\\* \\(?:Error\\|Warnin\\(g\\)\\)\\)"
 204      nil 1 nil 2 0
 205      (2 (compilation-face '(3))))
 206
 207     (gcc-include
 208      "^\\(?:In file included\\|                \\) from \
 209 \\(.+\\):\\([0-9]+\\)\\(?:\\(:\\)\\|\\(,\\)\\)?" 1 2 nil (3 . 4))
 210
 211     (gnu
 212      "^\\(?:[[:alpha:]][-[:alnum:].]+: ?\\)?\
 213 \\([/.]*[a-zA-Z]:?[^ \t\n:]*\\|{standard input}\\): ?\
 214 \\([0-9]+\\)\\([.:]?\\)\\([0-9]+\\)?\
 215 \\(?:-\\(?:\\([0-9]+\\)\\3\\)?\\.?\\([0-9]+\\)?\\)?:\
 216 \\(?: *\\(\\(?:Future\\|Runtime\\)?[Ww]arning\\|W:\\)\\|\
 217  *\\([Ii]nfo\\(?:\\>\\|rmationa?l?\\)\\|I:\\)\\)?"
 218      1 (2 . 5) (4 . 6) (7 . 8))
 219
 220     (lcc
 221      "^\\(?:E\\|\\(W\\)\\), \\([^(\n]+\\)(\\([0-9]+\\),[ \t]*\\([0-9]+\\)"
 222      2 3 4 (1))
 223
 224     (makepp
 225      "^makepp: \\(?:\\(?:warning\\(:\\).*?\\|\\(Scanning\\|[LR]e?l?oading makefile\\) \\|.*?\\)\
 226 `\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)'\\)"
 227      4 5 nil (1 . 2) 3
 228      ("`\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)'" nil nil
 229       (2 compilation-info-face)
 230       (3 compilation-line-face nil t)
 231       (1 (compilation-error-properties 2 3 nil nil nil 0 nil)
 232          append)))
 233
 234     ;; Should be lint-1, lint-2 (SysV lint)
 235     (mips-1
 236      " (\\([0-9]+\\)) in \\([^ \n]+\\)" 2 1)
 237     (mips-2
 238      " in \\([^()\n ]+\\)(\\([0-9]+\\))$" 1 2)
 239
 240     (msft
 241      "^\\(\\(?:[a-zA-Z]:\\)?[^:(\t\n]+\\)(\\([0-9]+\\)) \
 242 : \\(?:error\\|warnin\\(g\\)\\) C[0-9]+:" 1 2 nil (3))
 243
 244     (oracle
 245      "^\\(?:Semantic error\\|Error\\|PCC-[0-9]+:\\).* line \\([0-9]+\\)\
 246 \\(?:\\(?:,\\| at\\)? column \\([0-9]+\\)\\)?\
 247 \\(?:,\\| in\\| of\\)? file \\(.*?\\):?$"
 248      3 1 2)
 249
 250     (perl
 251      " at \\([^ \n]+\\) line \\([0-9]+\\)\\(?:[,.]\\|$\\)" 1 2)
 252
 253     (rxp
 254      "^\\(?:Error\\|Warnin\\(g\\)\\):.*\n.* line \\([0-9]+\\) char\
 255  \\([0-9]+\\) of file://\\(.+\\)"
 256      4 2 3 (1))
 257
 258     (sparc-pascal-file
 259      "^\\w\\w\\w \\w\\w\\w +[0-3]?[0-9] +[0-2][0-9]:[0-5][0-9]:[0-5][0-9]\
 260  [12][09][0-9][0-9] +\\(.*\\):$"
 261      1 nil nil 0)
 262     (sparc-pascal-line
 263      "^\\(\\(?:E\\|\\(w\\)\\) +[0-9]+\\) line \\([0-9]+\\) -  "
 264      nil 3 nil (2) nil (1 (compilation-face '(2))))
 265     (sparc-pascal-example
 266      "^ +\\([0-9]+\\) +.*\n\\(\\(?:e\\|\\(w\\)\\) [0-9]+\\)-+"
 267      nil 1 nil (3) nil (2 (compilation-face '(3))))
 268
 269     (sun
 270      ": \\(?:ERROR\\|WARNIN\\(G\\)\\|REMAR\\(K\\)\\) \\(?:[[:alnum:] ]+, \\)?\
 271 File = \\(.+\\), Line = \\([0-9]+\\)\\(?:, Column = \\([0-9]+\\)\\)?"
 272      3 4 5 (1 . 2))
 273
 274     (sun-ada
 275      "^\\([^, \n\t]+\\), line \\([0-9]+\\), char \\([0-9]+\\)[:., \(-]" 1 2 3)
 276
 277     (4bsd
 278      "\\(?:^\\|::  \\|\\S ( \\)\\(/[^ \n\t()]+\\)(\\([0-9]+\\))\
 279 \\(?:: \\(warning:\\)?\\|$\\| ),\\)" 1 2 nil (3)))
 280   "Alist of values for `compilation-error-regexp-alist'.")
 281
 282 (defcustom compilation-error-regexp-alist
 283   (mapcar 'car compilation-error-regexp-alist-alist)
 284   "Alist that specifies how to match errors in compiler output.
 285 Note that on Unix everything is a valid filename, so these
 286 matchers must make some common sense assumptions, which catch
 287 normal cases.  A shorter list will be lighter on resource usage.
 288
 289 Instead of an alist element, you can use a symbol, which is
 290 looked up in `compilation-error-regexp-alist-alist'.  You can see
 291 the predefined symbols and their effects in the file
 292 `etc/compilation.txt' (linked below if you are customizing this).
 293
 294 Each elt has the form (REGEXP FILE [LINE COLUMN TYPE HYPERLINK
 295 HIGHLIGHT...]).  If REGEXP matches, the FILE'th subexpression
 296 gives the file name, and the LINE'th subexpression gives the line
 297 number.  The COLUMN'th subexpression gives the column number on
 298 that line.
 299
 300 If FILE, LINE or COLUMN are nil or that index didn't match, that
 301 information is not present on the matched line.  In that case the
 302 file name is assumed to be the same as the previous one in the
 303 buffer, line number defaults to 1 and column defaults to
 304 beginning of line's indentation.
 305
 306 FILE can also have the form (FILE FORMAT...), where the FORMATs
 307 \(e.g. \"%s.c\") will be applied in turn to the recognized file
 308 name, until a file of that name is found.  Or FILE can also be a
 309 function to return the filename.
 310
 311 LINE can also be of the form (LINE . END-LINE) meaning a range
 312 of lines.  COLUMN can also be of the form (COLUMN . END-COLUMN)
 313 meaning a range of columns starting on LINE and ending on
 314 END-LINE, if that matched.
 315
 316 TYPE is 2 or nil for a real error or 1 for warning or 0 for info.
 317 TYPE can also be of the form (WARNING . INFO).  In that case this
 318 will be equivalent to 1 if the WARNING'th subexpression matched
 319 or else equivalent to 0 if the INFO'th subexpression matched.
 320 See `compilation-error-face', `compilation-warning-face',
 321 `compilation-info-face' and `compilation-skip-threshold'.
 322
 323 What matched the HYPERLINK'th subexpression has `mouse-face' and
 324 `compilation-message-face' applied.  If this is nil, the text
 325 matched by the whole REGEXP becomes the hyperlink.
 326
 327 Additional HIGHLIGHTs as described under `font-lock-keywords' can
 328 be added."
 329   :type `(set :menu-tag "Pick"
 330               ,@(mapcar (lambda (elt)
 331                           (list 'const (car elt)))
 332                         compilation-error-regexp-alist-alist))
 333   :link `(file-link :tag "example file"
 334                     ,(expand-file-name "compilation.txt" data-directory))
 335   :group 'compilation)
 336
 337 (defvar compilation-directory nil
 338   "Directory to restore to when doing `recompile'.")
 339
 340 (defvar compilation-directory-matcher
 341   '("\\(?:Entering\\|Leavin\\(g\\)\\) directory `\\(.+\\)'$" (2 . 1))
 342   "A list for tracking when directories are entered or left.
 343 Nil means not to track directories, e.g. if all file names are absolute.  The
 344 first element is the REGEXP matching these messages.  It can match any number
 345 of variants, e.g. different languages.  The remaining elements are all of the
 346 form (DIR .  LEAVE).  If for any one of these the DIR'th subexpression
 347 matches, that is a directory name.  If LEAVE is nil or the corresponding
 348 LEAVE'th subexpression doesn't match, this message is about going into another
 349 directory.  If it does match anything, this message is about going back to the
 350 directory we were in before the last entering message.  If you change this,
 351 you may also want to change `compilation-page-delimiter'.")
 352
 353 (defvar compilation-page-delimiter
 354   "^\\(?:\f\\|.*\\(?:Entering\\|Leaving\\) directory `.+'\n\\)+"
 355   "Value of `page-delimiter' in Compilation mode.")
 356
 357 (defvar compilation-mode-font-lock-keywords
 358    '(;; configure output lines.
 359      ("^[Cc]hecking \\(?:[Ff]or \\|[Ii]f \\|[Ww]hether \\(?:to \\)?\\)?\\(.+\\)\\.\\.\\. *\\(?:(cached) *\\)?\\(\\(yes\\(?: .+\\)?\\)\\|no\\|\\(.*\\)\\)$"
 360       (1 font-lock-variable-name-face)
 361       (2 (compilation-face '(4 . 3))))
 362      ;; Command output lines.  Recognize `make[n]:' lines too.
 363      ("^\\([[:alnum:]_/.+-]+\\)\\(\\[\\([0-9]+\\)\\]\\)?[ \t]*:"
 364       (1 font-lock-function-name-face) (3 compilation-line-face nil t))
 365      (" --?o\\(?:utfile\\|utput\\)?[= ]?\\(\\S +\\)" . 1)
 366      ("^Compilation finished" . compilation-info-face)
 367      ("^Compilation exited abnormally" . compilation-error-face))
 368    "Additional things to highlight in Compilation mode.
 369 This gets tacked on the end of the generated expressions.")
 370
 371 (defvar compilation-highlight-regexp t
 372   "Regexp matching part of visited source lines to highlight temporarily.
 373 Highlight entire line if t; don't highlight source lines if nil.")
 374
 375 (defvar compilation-highlight-overlay nil
 376   "Overlay used to temporarily highlight compilation matches.")
 377
 378 (defcustom compilation-error-screen-columns t
 379   "*If non-nil, column numbers in error messages are screen columns.
 380 Otherwise they are interpreted as character positions, with
 381 each character occupying one column.
 382 The default is to use screen columns, which requires that the compilation
 383 program and Emacs agree about the display width of the characters,
 384 especially the TAB character."
 385   :type 'boolean
 386   :group 'compilation
 387   :version "20.4")
 388
 389 (defcustom compilation-read-command t
 390   "*Non-nil means \\[compile] reads the compilation command to use.
 391 Otherwise, \\[compile] just uses the value of `compile-command'."
 392   :type 'boolean
 393   :group 'compilation)
 394
 395 ;;;###autoload
 396 (defcustom compilation-ask-about-save t
 397   "*Non-nil means \\[compile] asks which buffers to save before compiling.
 398 Otherwise, it saves all modified buffers without asking."
 399   :type 'boolean
 400   :group 'compilation)
 401
 402 ;;;###autoload
 403 (defcustom compilation-search-path '(nil)
 404   "*List of directories to search for source files named in error messages.
 405 Elements should be directory names, not file names of directories.
 406 nil as an element means to try the default directory."
 407   :type '(repeat (choice (const :tag "Default" nil)
 408                          (string :tag "Directory")))
 409   :group 'compilation)
 410
 411 (defcustom compile-command "make -k "
 412   "*Last shell command used to do a compilation; default for next compilation.
 413
 414 Sometimes it is useful for files to supply local values for this variable.
 415 You might also use mode hooks to specify it in certain modes, like this:
 416
 417     (add-hook 'c-mode-hook
 418        (lambda ()
 419          (unless (or (file-exists-p \"makefile\")
 420                      (file-exists-p \"Makefile\"))
 421            (set (make-local-variable 'compile-command)
 422                 (concat \"make -k \"
 423                         (file-name-sans-extension buffer-file-name))))))"
 424   :type 'string
 425   :group 'compilation)
 426
 427 ;; A weak per-compilation-buffer hash indexed by (FILENAME . DIRECTORY).  Each
 428 ;; value is a FILE-STRUCTURE as described above, with the car eq to the hash
 429 ;; key.  This holds the tree seen from root, for storing new nodes.
 430 (defvar compilation-locs ())
 431
 432 (defvar compilation-debug nil
 433   "*Set this to t before creating a *compilation* buffer.
 434 Then every error line will have a debug text property with the matcher that
 435 fit this line and the match data.  Use `describe-text-properties'.")
 436
 437 (defvar compilation-exit-message-function nil "\
 438 If non-nil, called when a compilation process dies to return a status message.
 439 This should be a function of three arguments: process status, exit status,
 440 and exit message; it returns a cons (MESSAGE . MODELINE) of the strings to
 441 write into the compilation buffer, and to put in its mode line.")
 442
 443 (defvar compilation-environment nil
 444   "*List of environment variables for compilation to inherit.
 445 Each element should be a string of the form ENVVARNAME=VALUE.
 446 This list is temporarily prepended to `process-environment' prior to
 447 starting the compilation process.")
 448
 449 ;; History of compile commands.
 450 (defvar compile-history nil)
 451
 452 (defface compilation-warning-face
 453   '((((class color) (min-colors 16)) (:foreground "Orange" :weight bold))
 454     (((class color)) (:foreground "cyan" :weight bold))
 455     (t (:weight bold)))
 456   "Face used to highlight compiler warnings."
 457   :group 'font-lock-highlighting-faces
 458   :version "21.4")
 459
 460 (defface compilation-info-face
 461   '((((class color) (min-colors 16) (background light))
 462      (:foreground "Green3" :weight bold))
 463     (((class color) (min-colors 16) (background dark))
 464      (:foreground "Green" :weight bold))
 465     (((class color)) (:foreground "green" :weight bold))
 466     (t (:weight bold)))
 467   "Face used to highlight compiler warnings."
 468   :group 'font-lock-highlighting-faces
 469   :version "21.4")
 470
 471 (defvar compilation-message-face nil
 472   "Face name to use for whole messages.
 473 Faces `compilation-error-face', `compilation-warning-face',
 474 `compilation-info-face', `compilation-line-face' and
 475 `compilation-column-face' get prepended to this, when applicable.")
 476
 477 (defvar compilation-error-face 'font-lock-warning-face
 478   "Face name to use for file name in error messages.")
 479
 480 (defvar compilation-warning-face 'compilation-warning-face
 481   "Face name to use for file name in warning messages.")
 482
 483 (defvar compilation-info-face 'compilation-info-face
 484   "Face name to use for file name in informational messages.")
 485
 486 (defvar compilation-line-face 'font-lock-variable-name-face
 487   "Face name to use for line number in message.")
 488
 489 (defvar compilation-column-face 'font-lock-type-face
 490   "Face name to use for column number in message.")
 491
 492 ;; same faces as dired uses
 493 (defvar compilation-enter-directory-face 'font-lock-function-name-face
 494   "Face name to use for column number in message.")
 495
 496 (defvar compilation-leave-directory-face 'font-lock-type-face
 497   "Face name to use for column number in message.")
 498
 499
 500
 501 ;; Used for compatibility with the old compile.el.
 502 (defvaralias 'compilation-last-buffer 'next-error-last-buffer)
 503 (defvar compilation-parsing-end (make-marker))
 504 (defvar compilation-parse-errors-function nil)
 505 (defvar compilation-error-list nil)
 506 (defvar compilation-old-error-list nil)
 507
 508 (defun compilation-face (type)
 509   (or (and (car type) (match-end (car type)) compilation-warning-face)
 510       (and (cdr type) (match-end (cdr type)) compilation-info-face)
 511       compilation-error-face))
 512
 513 (defun compilation-directory-properties (idx leave)
 514   (if leave (setq leave (match-end leave)))
 515   ;; find previous stack, and push onto it, or if `leave' pop it
 516   (let ((dir (previous-single-property-change (point) 'directory)))
 517     (setq dir (if dir (or (get-text-property (1- dir) 'directory)
 518                           (get-text-property dir 'directory))))
 519     `(face ,(if leave
 520                 compilation-leave-directory-face
 521               compilation-enter-directory-face)
 522       directory ,(if leave
 523                      (or (cdr dir)
 524                          '(nil))        ; nil only isn't a property-change
 525                    (cons (match-string-no-properties idx) dir))
 526       mouse-face highlight
 527       keymap compilation-button-map
 528       help-echo "mouse-2: visit current directory")))
 529
 530 ;; Data type `reverse-ordered-alist' retriever.  This function retrieves the
 531 ;; KEY element from the ALIST, creating it in the right position if not already
 532 ;; present. ALIST structure is
 533 ;; '(ANCHOR (KEY1 ...) (KEY2 ...)... (KEYn ALIST ...))
 534 ;; ANCHOR is ignored, but necessary so that elements can be inserted.  KEY1
 535 ;; may be nil.  The other KEYs are ordered backwards so that growing line
 536 ;; numbers can be inserted in front and searching can abort after half the
 537 ;; list on average.
 538 (eval-when-compile                  ;Don't keep it at runtime if not needed.
 539 (defmacro compilation-assq (key alist)
 540   `(let* ((l1 ,alist)
 541           (l2 (cdr l1)))
 542      (car (if (if (null ,key)
 543                   (if l2 (null (caar l2)))
 544                 (while (if l2 (if (caar l2) (< ,key (caar l2)) t))
 545                   (setq l1 l2
 546                         l2 (cdr l1)))
 547                 (if l2 (eq ,key (caar l2))))
 548               l2
 549             (setcdr l1 (cons (list ,key) l2)))))))
 550
 551
 552 ;; This function is the central driver, called when font-locking to gather
 553 ;; all information needed to later jump to corresponding source code.
 554 ;; Return a property list with all meta information on this error location.
 555 (defun compilation-error-properties (file line end-line col end-col type fmt)
 556   (unless (< (next-single-property-change (match-beginning 0) 'directory nil (point))
 557              (point))
 558     (if file
 559         (if (functionp file)
 560             (setq file (funcall file))
 561           (let (dir)
 562             (setq file (match-string-no-properties file))
 563             (unless (file-name-absolute-p file)
 564               (setq dir (previous-single-property-change (point) 'directory)
 565                     dir (if dir (or (get-text-property (1- dir) 'directory)
 566                                     (get-text-property dir 'directory)))))
 567             (setq file (cons file (car dir)))))
 568       ;; This message didn't mention one, get it from previous
 569       (setq file (previous-single-property-change (point) 'message)
 570             file (or (if file
 571                          (car (nth 2 (car (or (get-text-property (1- file) 'message)
 572                                          (get-text-property file 'message))))))
 573                      '("*unknown*"))))
 574     ;; All of these fields are optional, get them only if we have an index, and
 575     ;; it matched some part of the message.
 576     (and line
 577          (setq line (match-string-no-properties line))
 578          (setq line (string-to-number line)))
 579     (and end-line
 580          (setq end-line (match-string-no-properties end-line))
 581          (setq end-line (string-to-number end-line)))
 582     (and col
 583          (setq col (match-string-no-properties col))
 584          (setq col (- (string-to-number col) compilation-first-column)))
 585     (if (and end-col (setq end-col (match-string-no-properties end-col)))
 586         (setq end-col (- (string-to-number end-col) compilation-first-column -1))
 587       (if end-line (setq end-col -1)))
 588     (if (consp type)                    ; not a static type, check what it is.
 589         (setq type (or (and (car type) (match-end (car type)) 1)
 590                        (and (cdr type) (match-end (cdr type)) 0)
 591                        2)))
 592     (compilation-internal-error-properties file line end-line col end-col type fmt)))
 593
 594 (defun compilation-internal-error-properties (file line end-line col end-col type fmt)
 595   "Get the meta-info that will be added as text-properties.
 596 LINE, END-LINE, COL, END-COL are integers or nil.
 597 TYPE can be 0, 1, or 2.
 598 FILE should be (ABSOLUTE-FILENAME) or (RELATIVE-FILENAME . DIRNAME) or nil."
 599   (unless file (setq file '("*unknown*")))
 600   (setq file (compilation-get-file-structure file fmt))
 601   ;; Get first already existing marker (if any has one, all have one).
 602   ;; Do this first, as the compilation-assq`s may create new nodes.
 603   (let* ((marker-line (car (cddr file)))        ; a line structure
 604          (marker (nth 3 (cadr marker-line)))    ; its marker
 605          (compilation-error-screen-columns compilation-error-screen-columns)
 606          end-marker loc end-loc)
 607     (if (not (and marker (marker-buffer marker)))
 608         (setq marker)                   ; no valid marker for this file
 609       (setq loc (or line 1))            ; normalize no linenumber to line 1
 610       (catch 'marker                    ; find nearest loc, at least one exists
 611         (dolist (x (nthcdr 3 file))     ; loop over remaining lines
 612           (if (> (car x) loc)           ; still bigger
 613               (setq marker-line x)
 614             (if (> (- (or (car marker-line) 1) loc)
 615                    (- loc (car x)))     ; current line is nearer
 616                 (setq marker-line x))
 617             (throw 'marker t))))
 618       (setq marker (nth 3 (cadr marker-line))
 619             marker-line (or (car marker-line) 1))
 620       (with-current-buffer (marker-buffer marker)
 621         (save-restriction
 622           (widen)
 623           (goto-char (marker-position marker))
 624           (when (or end-col end-line)
 625             (beginning-of-line (- (or end-line line) marker-line -1))
 626             (if (< end-col 0)
 627                 (end-of-line)
 628               (if compilation-error-screen-columns
 629                   (move-to-column end-col)
 630                 (forward-char end-col)))
 631             (setq end-marker (list (point-marker))))
 632           (beginning-of-line (if end-line
 633                                  (- end-line line -1)
 634                                (- loc marker-line -1)))
 635           (if col
 636               (if compilation-error-screen-columns
 637                   (move-to-column col)
 638                 (forward-char col))
 639             (forward-to-indentation 0))
 640           (setq marker (list (point-marker))))))
 641
 642     (setq loc (compilation-assq line (cdr file)))
 643     (if end-line
 644         (setq end-loc (compilation-assq end-line (cdr file))
 645               end-loc (compilation-assq end-col end-loc))
 646       (if end-col                       ; use same line element
 647           (setq end-loc (compilation-assq end-col loc))))
 648     (setq loc (compilation-assq col loc))
 649     ;; If they are new, make the loc(s) reference the file they point to.
 650     (or (cdr loc) (setcdr loc `(,line ,file ,@marker)))
 651     (if end-loc
 652         (or (cdr end-loc) (setcdr end-loc `(,(or end-line line) ,file ,@end-marker))))
 653
 654     ;; Must start with face
 655     `(face ,compilation-message-face
 656            message (,loc ,type ,end-loc)
 657            ,@(if compilation-debug
 658                  `(debug (,(assoc (with-no-warnings matcher) font-lock-keywords)
 659                           ,@(match-data))))
 660            help-echo ,(if col
 661                           "mouse-2: visit this file, line and column"
 662                         (if line
 663                             "mouse-2: visit this file and line"
 664                           "mouse-2: visit this file"))
 665            keymap compilation-button-map
 666            mouse-face highlight)))
 667
 668 (defun compilation-mode-font-lock-keywords ()
 669   "Return expressions to highlight in Compilation mode."
 670   (if compilation-parse-errors-function
 671       ;; An old package!  Try the compatibility code.
 672       '((compilation-compat-parse-errors))
 673     (append
 674      ;; make directory tracking
 675      (if compilation-directory-matcher
 676          `((,(car compilation-directory-matcher)
 677             ,@(mapcar (lambda (elt)
 678                         `(,(car elt)
 679                           (compilation-directory-properties
 680                            ,(car elt) ,(cdr elt))
 681                           t))
 682                       (cdr compilation-directory-matcher)))))
 683
 684      ;; Compiler warning/error lines.
 685      (mapcar
 686       (lambda (item)
 687         (if (symbolp item)
 688             (setq item (cdr (assq item
 689                                   compilation-error-regexp-alist-alist))))
 690         (let ((file (nth 1 item))
 691               (line (nth 2 item))
 692               (col (nth 3 item))
 693               (type (nth 4 item))
 694               end-line end-col fmt)
 695           (if (consp file)      (setq fmt (cdr file)      file (car file)))
 696           (if (consp line)      (setq end-line (cdr line) line (car line)))
 697           (if (consp col)       (setq end-col (cdr col)   col (car col)))
 698
 699           (if (functionp line)
 700               ;; The old compile.el had here an undocumented hook that
 701               ;; allowed `line' to be a function that computed the actual
 702               ;; error location.  Let's do our best.
 703               `(,(car item)
 704                 (0 (compilation-compat-error-properties
 705                     (funcall ',line (cons (match-string ,file)
 706                                           (cons default-directory
 707                                                 ',(nthcdr 4 item)))
 708                              ,(if col `(match-string ,col)))))
 709                 (,file compilation-error-face t))
 710
 711             (unless (or (null (nth 5 item)) (integerp (nth 5 item)))
 712               (error "HYPERLINK should be an integer: %s" (nth 5 item)))
 713
 714             `(,(nth 0 item)
 715
 716               ,@(when (integerp file)
 717                   `((,file ,(if (consp type)
 718                                 `(compilation-face ',type)
 719                               (aref [compilation-info-face
 720                                      compilation-warning-face
 721                                      compilation-error-face]
 722                                     (or type 2))))))
 723
 724               ,@(when line
 725                   `((,line compilation-line-face nil t)))
 726               ,@(when end-line
 727                   `((,end-line compilation-line-face nil t)))
 728
 729               ,@(when col
 730                   `((,col compilation-column-face nil t)))
 731               ,@(when end-col
 732                   `((,end-col compilation-column-face nil t)))
 733
 734               ,@(nthcdr 6 item)
 735               (,(or (nth 5 item) 0)
 736                (compilation-error-properties ',file ,line ,end-line
 737                                              ,col ,end-col ',(or type 2)
 738                                              ',fmt)
 739                append)))))              ; for compilation-message-face
 740       compilation-error-regexp-alist)
 741
 742      compilation-mode-font-lock-keywords)))
 743
 744 \f
 745 ;;;###autoload
 746 (defun compile (command &optional comint)
 747   "Compile the program including the current buffer.  Default: run `make'.
 748 Runs COMMAND, a shell command, in a separate process asynchronously
 749 with output going to the buffer `*compilation*'.
 750
 751 If optional second arg COMINT is t the buffer will be in Comint mode with
 752 `compilation-shell-minor-mode'.
 753
 754 You can then use the command \\[next-error] to find the next error message
 755 and move to the source code that caused it.
 756
 757 Interactively, prompts for the command if `compilation-read-command' is
 758 non-nil; otherwise uses `compile-command'.  With prefix arg, always prompts.
 759 Additionally, with universal prefix arg, compilation buffer will be in
 760 comint mode, i.e. interactive.
 761
 762 To run more than one compilation at once, start one and rename
 763 the \`*compilation*' buffer to some other name with
 764 \\[rename-buffer].  Then start the next one.  On most systems,
 765 termination of the main compilation process kills its
 766 subprocesses.
 767
 768 The name used for the buffer is actually whatever is returned by
 769 the function in `compilation-buffer-name-function', so you can set that
 770 to a function that generates a unique name."
 771   (interactive
 772    (list
 773     (if (or compilation-read-command current-prefix-arg)
 774         (read-from-minibuffer "Compile command: "
 775                               (eval compile-command) nil nil
 776                               '(compile-history . 1))
 777       (eval compile-command))
 778     (consp current-prefix-arg)))
 779   (unless (equal command (eval compile-command))
 780     (setq compile-command command))
 781   (save-some-buffers (not compilation-ask-about-save) nil)
 782   (setq compilation-directory default-directory)
 783   (compilation-start command comint))
 784
 785 ;; run compile with the default command line
 786 (defun recompile ()
 787   "Re-compile the program including the current buffer.
 788 If this is run in a Compilation mode buffer, re-use the arguments from the
 789 original use.  Otherwise, recompile using `compile-command'."
 790   (interactive)
 791   (save-some-buffers (not compilation-ask-about-save) nil)
 792   (let ((default-directory (or compilation-directory default-directory)))
 793     (apply 'compilation-start (or compilation-arguments
 794                                   `(,(eval compile-command))))))
 795
 796 (defcustom compilation-scroll-output nil
 797   "*Non-nil to scroll the *compilation* buffer window as output appears.
 798
 799 Setting it causes the Compilation mode commands to put point at the
 800 end of their output window so that the end of the output is always
 801 visible rather than the beginning."
 802   :type 'boolean
 803   :version "20.3"
 804   :group 'compilation)
 805
 806
 807 (defun compilation-buffer-name (mode-name name-function)
 808   "Return the name of a compilation buffer to use.
 809 If NAME-FUNCTION is non-nil, call it with one argument MODE-NAME
 810 to determine the buffer name.
 811 Likewise if `compilation-buffer-name-function' is non-nil.
 812 If current buffer is in Compilation mode for the same mode name
 813 return the name of the current buffer, so that it gets reused.
 814 Otherwise, construct a buffer name from MODE-NAME."
 815   (cond (name-function
 816          (funcall name-function mode-name))
 817         (compilation-buffer-name-function
 818          (funcall compilation-buffer-name-function mode-name))
 819         ((and (eq major-mode 'compilation-mode)
 820               (equal mode-name (nth 2 compilation-arguments)))
 821          (buffer-name))
 822         (t
 823          (concat "*" (downcase mode-name) "*"))))
 824
 825 ;; This is a rough emulation of the old hack, until the transition to new
 826 ;; compile is complete.
 827 (defun compile-internal (command error-message
 828                                  &optional name-of-mode parser
 829                                  error-regexp-alist name-function
 830                                  enter-regexp-alist leave-regexp-alist
 831                                  file-regexp-alist nomessage-regexp-alist
 832                                  no-async highlight-regexp local-map)
 833   (if parser
 834       (error "Compile now works very differently, see `compilation-error-regexp-alist'"))
 835   (let ((compilation-error-regexp-alist
 836          (append file-regexp-alist (or error-regexp-alist
 837                                        compilation-error-regexp-alist)))
 838         (compilation-error (replace-regexp-in-string "^No more \\(.+\\)s\\.?"
 839                                                      "\\1" error-message)))
 840     (compilation-start command nil name-function highlight-regexp)))
 841 (make-obsolete 'compile-internal 'compilation-start)
 842
 843 (defun compilation-start (command &optional mode name-function highlight-regexp)
 844   "Run compilation command COMMAND (low level interface).
 845 The rest of the arguments are optional; for them, nil means use the default.
 846
 847 MODE is the major mode to set in the compilation buffer.  Mode
 848 may also be t meaning use `compilation-shell-minor-mode' under `comint-mode'.
 849 NAME-FUNCTION is a function called to name the buffer.
 850
 851 If HIGHLIGHT-REGEXP is non-nil, `next-error' will temporarily highlight
 852 the matching section of the visited source line; the default is to use the
 853 global value of `compilation-highlight-regexp'.
 854
 855 Returns the compilation buffer created."
 856   (or mode (setq mode 'compilation-mode))
 857   (let ((name-of-mode
 858          (if (eq mode t)
 859              (prog1 "compilation" (require 'comint))
 860            (replace-regexp-in-string "-mode$" "" (symbol-name mode))))
 861         (process-environment
 862          (append
 863           compilation-environment
 864           (if (if (boundp 'system-uses-terminfo) ; `if' for compiler warning
 865                   system-uses-terminfo)
 866               (list "TERM=dumb" "TERMCAP="
 867                     (format "COLUMNS=%d" (window-width)))
 868             (list "TERM=emacs"
 869                   (format "TERMCAP=emacs:co#%d:tc=unknown:"
 870                           (window-width))))
 871           ;; Set the EMACS variable, but
 872           ;; don't override users' setting of $EMACS.
 873           (unless (getenv "EMACS") '("EMACS=t"))
 874           process-environment))
 875         (thisdir default-directory)
 876         outwin outbuf)
 877     (with-current-buffer
 878         (setq outbuf
 879               (get-buffer-create
 880                (compilation-buffer-name name-of-mode name-function)))
 881       (let ((comp-proc (get-buffer-process (current-buffer))))
 882         (if comp-proc
 883             (if (or (not (eq (process-status comp-proc) 'run))
 884                     (yes-or-no-p
 885                      (format "A %s process is running; kill it? "
 886                              name-of-mode)))
 887                 (condition-case ()
 888                     (progn
 889                       (interrupt-process comp-proc)
 890                       (sit-for 1)
 891                       (delete-process comp-proc))
 892                   (error nil))
 893               (error "Cannot have two processes in `%s' at once"
 894                      (buffer-name)))))
 895       ;; Clear out the compilation buffer and make it writable.
 896       ;; Change its default-directory to the directory where the compilation
 897       ;; will happen, and insert a `cd' command to indicate this.
 898       (setq buffer-read-only nil)
 899       (buffer-disable-undo (current-buffer))
 900       (erase-buffer)
 901       (buffer-enable-undo (current-buffer))
 902       (setq default-directory thisdir)
 903       ;; output a mode setter, for saving and later reloading this buffer
 904       (insert "cd " thisdir "   # -*-" name-of-mode
 905               "-*-\nEntering directory `" thisdir "'\n" command "\n")
 906       (set-buffer-modified-p nil))
 907     ;; If we're already in the compilation buffer, go to the end
 908     ;; of the buffer, so point will track the compilation output.
 909     (if (eq outbuf (current-buffer))
 910         (goto-char (point-max)))
 911     ;; Pop up the compilation buffer.
 912     (setq outwin (display-buffer outbuf nil t))
 913     (with-current-buffer outbuf
 914       (if (not (eq mode t))
 915           (funcall mode)
 916         (with-no-warnings (comint-mode))
 917         (compilation-shell-minor-mode))
 918       ;; In what way is it non-ergonomic ?  -stef
 919       ;; (toggle-read-only 1) ;;; Non-ergonomic.
 920       (if highlight-regexp
 921           (set (make-local-variable 'compilation-highlight-regexp)
 922                highlight-regexp))
 923       (set (make-local-variable 'compilation-arguments)
 924            (list command mode name-function highlight-regexp))
 925       (set (make-local-variable 'revert-buffer-function)
 926            'compilation-revert-buffer)
 927       (set-window-start outwin (point-min))
 928       (or (eq outwin (selected-window))
 929           (set-window-point outwin (if compilation-scroll-output
 930                                        (point)
 931                                      (point-min))))
 932       ;; The setup function is called before compilation-set-window-height
 933       ;; so it can set the compilation-window-height buffer locally.
 934       (if compilation-process-setup-function
 935           (funcall compilation-process-setup-function))
 936       (compilation-set-window-height outwin)
 937       ;; Start the compilation.
 938       (if (fboundp 'start-process)
 939           (let ((proc (if (eq mode t)
 940                           (get-buffer-process
 941                            (with-no-warnings
 942                             (comint-exec outbuf (downcase mode-name)
 943                                          shell-file-name nil `("-c" ,command))))
 944                         (start-process-shell-command (downcase mode-name)
 945                                                      outbuf command))))
 946             ;; Make the buffer's mode line show process state.
 947             (setq mode-line-process '(":%s"))
 948             (set-process-sentinel proc 'compilation-sentinel)
 949             (set-process-filter proc 'compilation-filter)
 950             (set-marker (process-mark proc) (point) outbuf)
 951             (setq compilation-in-progress
 952                   (cons proc compilation-in-progress)))
 953         ;; No asynchronous processes available.
 954         (message "Executing `%s'..." command)
 955         ;; Fake modeline display as if `start-process' were run.
 956         (setq mode-line-process ":run")
 957         (force-mode-line-update)
 958         (sit-for 0)                     ; Force redisplay
 959         (let ((status (call-process shell-file-name nil outbuf nil "-c"
 960                                     command)))
 961           (cond ((numberp status)
 962                  (compilation-handle-exit 'exit status
 963                                           (if (zerop status)
 964                                               "finished\n"
 965                                             (format "\
 966 exited abnormally with code %d\n"
 967                                                     status))))
 968                 ((stringp status)
 969                  (compilation-handle-exit 'signal status
 970                                           (concat status "\n")))
 971                 (t
 972                  (compilation-handle-exit 'bizarre status status))))
 973         ;; Without async subprocesses, the buffer is not yet
 974         ;; fontified, so fontify it now.
 975         (let ((font-lock-verbose nil))  ; shut up font-lock messages
 976           (font-lock-fontify-buffer))
 977         (message "Executing `%s'...done" command)))
 978     (if (buffer-local-value 'compilation-scroll-output outbuf)
 979         (save-selected-window
 980           (select-window outwin)
 981           (goto-char (point-max))))
 982     ;; Make it so the next C-x ` will use this buffer.
 983     (setq next-error-last-buffer outbuf)))
 984
 985 (defun compilation-set-window-height (window)
 986   "Set the height of WINDOW according to `compilation-window-height'."
 987   (let ((height (buffer-local-value 'compilation-window-height (window-buffer window))))
 988     (and height
 989          (= (window-width window) (frame-width (window-frame window)))
 990          ;; If window is alone in its frame, aside from a minibuffer,
 991          ;; don't change its height.
 992          (not (eq window (frame-root-window (window-frame window))))
 993          ;; Stef said that doing the saves in this order is safer:
 994          (save-excursion
 995            (save-selected-window
 996              (select-window window)
 997              (enlarge-window (- height (window-height))))))))
 998
 999 (defvar compilation-menu-map
1000   (let ((map (make-sparse-keymap "Errors")))
1001     (define-key map [stop-subjob]
1002       '("Stop Compilation" . kill-compilation))
1003     (define-key map [compilation-mode-separator2]
1004       '("----" . nil))
1005     (define-key map [compilation-first-error]
1006       '("First Error" . first-error))
1007     (define-key map [compilation-previous-error]
1008       '("Previous Error" . previous-error))
1009     (define-key map [compilation-next-error]
1010       '("Next Error" . next-error))
1011     map))
1012
1013 (defvar compilation-minor-mode-map
1014   (let ((map (make-sparse-keymap)))
1015     (define-key map [mouse-2] 'compile-goto-error)
1016     (define-key map "\C-c\C-c" 'compile-goto-error)
1017     (define-key map "\C-m" 'compile-goto-error)
1018     (define-key map "\C-c\C-k" 'kill-compilation)
1019     (define-key map "\M-n" 'compilation-next-error)
1020     (define-key map "\M-p" 'compilation-previous-error)
1021     (define-key map "\M-{" 'compilation-previous-file)
1022     (define-key map "\M-}" 'compilation-next-file)
1023     ;; Set up the menu-bar
1024     (define-key map [menu-bar compilation]
1025       (cons "Errors" compilation-menu-map))
1026     map)
1027   "Keymap for `compilation-minor-mode'.")
1028
1029 (defvar compilation-shell-minor-mode-map
1030   (let ((map (make-sparse-keymap)))
1031     (define-key map "\M-\C-m" 'compile-goto-error)
1032     (define-key map "\M-\C-n" 'compilation-next-error)
1033     (define-key map "\M-\C-p" 'compilation-previous-error)
1034     (define-key map "\M-{" 'compilation-previous-file)
1035     (define-key map "\M-}" 'compilation-next-file)
1036     ;; Set up the menu-bar
1037     (define-key map [menu-bar compilation]
1038       (cons "Errors" compilation-menu-map))
1039     map)
1040   "Keymap for `compilation-shell-minor-mode'.")
1041
1042 (defvar compilation-button-map
1043   (let ((map (make-sparse-keymap)))
1044     (define-key map [mouse-2] 'compile-goto-error)
1045     (define-key map "\C-m" 'compile-goto-error)
1046     map)
1047   "Keymap for compilation-message buttons.")
1048 (fset 'compilation-button-map compilation-button-map)
1049
1050 (defvar compilation-mode-map
1051   (let ((map (make-sparse-keymap)))
1052     (set-keymap-parent map compilation-minor-mode-map)
1053     (define-key map " " 'scroll-up)
1054     (define-key map "\^?" 'scroll-down)
1055
1056     ;; Set up the menu-bar
1057     (define-key map [menu-bar compilation]
1058       (cons "Compile" (make-sparse-keymap "Compile")))
1059     (define-key map [menu-bar compilation compilation-separator2]
1060       '("----" . nil))
1061     (define-key map [menu-bar compilation compilation-grep]
1062       '("Search Files (grep)" . grep))
1063     (define-key map [menu-bar compilation compilation-recompile]
1064       '("Recompile" . recompile))
1065     (define-key map [menu-bar compilation compilation-compile]
1066       '("Compile..." . compile))
1067     map)
1068   "Keymap for compilation log buffers.
1069 `compilation-minor-mode-map' is a parent of this.")
1070
1071 (put 'compilation-mode 'mode-class 'special)
1072
1073 (defvar compilation-skip-to-next-location t
1074   "*If non-nil, skip multiple error messages for the same source location.")
1075
1076 (defcustom compilation-skip-threshold 1
1077   "*Compilation motion commands skip less important messages.
1078 The value can be either 2 -- skip anything less than error, 1 --
1079 skip anything less than warning or 0 -- don't skip any messages.
1080 Note that all messages not positively identified as warning or
1081 info, are considered errors."
1082   :type '(choice (const :tag "Warnings and info" 2)
1083                  (const :tag "Info" 1)
1084                  (const :tag "None" 0))
1085   :group 'compilation
1086   :version "21.4")
1087
1088 (defcustom compilation-skip-visited nil
1089   "*Compilation motion commands skip visited messages if this is t.
1090 Visited messages are ones for which the file, line and column have been jumped
1091 to from the current content in the current compilation buffer, even if it was
1092 from a different message."
1093   :type 'boolean
1094   :group 'compilation
1095   :version "21.4")
1096
1097 ;;;###autoload
1098 (defun compilation-mode ()
1099   "Major mode for compilation log buffers.
1100 \\<compilation-mode-map>To visit the source for a line-numbered error,
1101 move point to the error message line and type \\[compile-goto-error].
1102 To kill the compilation, type \\[kill-compilation].
1103
1104 Runs `compilation-mode-hook' with `run-hooks' (which see)."
1105   (interactive)
1106   (kill-all-local-variables)
1107   (use-local-map compilation-mode-map)
1108   (setq major-mode 'compilation-mode
1109         mode-name "Compilation")
1110   (set (make-local-variable 'page-delimiter)
1111        compilation-page-delimiter)
1112   (compilation-setup)
1113   (run-mode-hooks 'compilation-mode-hook))
1114
1115 (defmacro define-compilation-mode (mode name doc &rest body)
1116   "This is like `define-derived-mode' without the PARENT argument.
1117 The parent is always `compilation-mode' and the customizable `compilation-...'
1118 variables are also set from the name of the mode you have chosen, by replacing
1119 the fist word, e.g `compilation-scroll-output' from `grep-scroll-output' if that
1120 variable exists."
1121   (let ((mode-name (replace-regexp-in-string "-mode\\'" "" (symbol-name mode))))
1122     `(define-derived-mode ,mode compilation-mode ,name
1123        ,doc
1124        ,@(mapcar (lambda (v)
1125                    (setq v (cons v
1126                                  (intern-soft (replace-regexp-in-string
1127                                                "^compilation" mode-name
1128                                                (symbol-name v)))))
1129                    (and (cdr v)
1130                         (or (boundp (cdr v))
1131                             (if (boundp 'byte-compile-bound-variables)
1132                                 (memq (cdr v) byte-compile-bound-variables)))
1133                         `(set (make-local-variable ',(car v)) ,(cdr v))))
1134                  '(compilation-buffer-name-function
1135                    compilation-directory-matcher
1136                    compilation-error
1137                    compilation-error-regexp-alist
1138                    compilation-error-regexp-alist-alist
1139                    compilation-error-screen-columns
1140                    compilation-finish-function
1141                    compilation-finish-functions
1142                    compilation-first-column
1143                    compilation-mode-font-lock-keywords
1144                    compilation-page-delimiter
1145                    compilation-parse-errors-filename-function
1146                    compilation-process-setup-function
1147                    compilation-scroll-output
1148                    compilation-search-path
1149                    compilation-skip-threshold
1150                    compilation-window-height))
1151        ,@body)))
1152
1153 (defun compilation-revert-buffer (ignore-auto noconfirm)
1154   (if buffer-file-name
1155       (let (revert-buffer-function)
1156         (revert-buffer ignore-auto noconfirm))
1157     (if (or noconfirm (yes-or-no-p (format "Restart compilation? ")))
1158         (apply 'compilation-start compilation-arguments))))
1159
1160 (defvar compilation-current-error nil
1161   "Marker to the location from where the next error will be found.
1162 The global commands next/previous/first-error/goto-error use this.")
1163
1164 (defvar compilation-messages-start nil
1165   "Buffer position of the beginning of the compilation messages.
1166 If nil, use the beginning of buffer.")
1167
1168 ;; A function name can't be a hook, must be something with a value.
1169 (defconst compilation-turn-on-font-lock 'turn-on-font-lock)
1170
1171 (defun compilation-setup (&optional minor)
1172   "Prepare the buffer for the compilation parsing commands to work.
1173 Optional argument MINOR indicates this is called from
1174 `compilation-minor-mode'."
1175   (make-local-variable 'compilation-current-error)
1176   (make-local-variable 'compilation-messages-start)
1177   (make-local-variable 'compilation-error-screen-columns)
1178   (make-local-variable 'overlay-arrow-position)
1179   ;; Note that compilation-next-error-function is for interfacing
1180   ;; with the next-error function in simple.el, and it's only
1181   ;; coincidentally named similarly to compilation-next-error.
1182   (setq next-error-function 'compilation-next-error-function)
1183   (set (make-local-variable 'font-lock-extra-managed-props)
1184        '(directory message help-echo mouse-face debug))
1185   (set (make-local-variable 'compilation-locs)
1186        (make-hash-table :test 'equal :weakness 'value))
1187   ;; lazy-lock would never find the message unless it's scrolled to.
1188   ;; jit-lock might fontify some things too late.
1189   (set (make-local-variable 'font-lock-support-mode) nil)
1190   (set (make-local-variable 'font-lock-maximum-size) nil)
1191   (let ((fld font-lock-defaults))
1192     (if (and minor fld)
1193         (font-lock-add-keywords nil (compilation-mode-font-lock-keywords))
1194       (setq font-lock-defaults '(compilation-mode-font-lock-keywords t)))
1195     (if minor
1196         (if font-lock-mode
1197             (if fld
1198                 (font-lock-fontify-buffer)
1199               (font-lock-change-mode)
1200               (turn-on-font-lock))
1201           (turn-on-font-lock))
1202       ;; maybe defer font-lock till after derived mode is set up
1203       (run-mode-hooks 'compilation-turn-on-font-lock))))
1204
1205 ;;;###autoload
1206 (define-minor-mode compilation-shell-minor-mode
1207   "Toggle compilation shell minor mode.
1208 With arg, turn compilation mode on if and only if arg is positive.
1209 In this minor mode, all the error-parsing commands of the
1210 Compilation major mode are available but bound to keys that don't
1211 collide with Shell mode.  See `compilation-mode'.
1212 Turning the mode on runs the normal hook `compilation-shell-minor-mode-hook'."
1213   nil " Shell-Compile"
1214   :group 'compilation
1215   (if compilation-shell-minor-mode
1216       (compilation-setup t)
1217     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1218     (font-lock-fontify-buffer)))
1219
1220 ;;;###autoload
1221 (define-minor-mode compilation-minor-mode
1222   "Toggle compilation minor mode.
1223 With arg, turn compilation mode on if and only if arg is positive.
1224 In this minor mode, all the error-parsing commands of the
1225 Compilation major mode are available.  See `compilation-mode'.
1226 Turning the mode on runs the normal hook `compilation-minor-mode-hook'."
1227   nil " Compilation"
1228   :group 'compilation
1229   (if compilation-minor-mode
1230       (compilation-setup t)
1231     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1232     (font-lock-fontify-buffer)))
1233
1234 (defun compilation-handle-exit (process-status exit-status msg)
1235   "Write MSG in the current buffer and hack its mode-line-process."
1236   (let ((buffer-read-only nil)
1237         (status (if compilation-exit-message-function
1238                     (funcall compilation-exit-message-function
1239                              process-status exit-status msg)
1240                   (cons msg exit-status)))
1241         (omax (point-max))
1242         (opoint (point)))
1243     ;; Record where we put the message, so we can ignore it later on.
1244     (goto-char omax)
1245     (insert ?\n mode-name " " (car status))
1246     (if (and (numberp compilation-window-height)
1247              (zerop compilation-window-height))
1248         (message "%s" (cdr status)))
1249     (if (bolp)
1250         (forward-char -1))
1251     (insert " at " (substring (current-time-string) 0 19))
1252     (goto-char (point-max))
1253     ;; Prevent that message from being recognized as a compilation error.
1254     (add-text-properties omax (point)
1255                          (append '(compilation-handle-exit t) nil))
1256     (setq mode-line-process (format ":%s [%s]" process-status (cdr status)))
1257     ;; Force mode line redisplay soon.
1258     (force-mode-line-update)
1259     (if (and opoint (< opoint omax))
1260         (goto-char opoint))
1261     (if compilation-finish-function
1262         (funcall compilation-finish-function (current-buffer) msg))
1263     (let ((functions compilation-finish-functions))
1264       (while functions
1265         (funcall (car functions) (current-buffer) msg)
1266         (setq functions (cdr functions))))))
1267
1268 ;; Called when compilation process changes state.
1269 (defun compilation-sentinel (proc msg)
1270   "Sentinel for compilation buffers."
1271   (if (memq (process-status proc) '(exit signal))
1272       (let ((buffer (process-buffer proc)))
1273         (if (null (buffer-name buffer))
1274             ;; buffer killed
1275             (set-process-buffer proc nil)
1276           (with-current-buffer buffer
1277             ;; Write something in the compilation buffer
1278             ;; and hack its mode line.
1279             (compilation-handle-exit (process-status proc)
1280                                      (process-exit-status proc)
1281                                      msg)
1282             ;; Since the buffer and mode line will show that the
1283             ;; process is dead, we can delete it now.  Otherwise it
1284             ;; will stay around until M-x list-processes.
1285             (delete-process proc)))
1286         (setq compilation-in-progress (delq proc compilation-in-progress)))))
1287
1288 (defun compilation-filter (proc string)
1289   "Process filter for compilation buffers.
1290 Just inserts the text, but uses `insert-before-markers'."
1291   (if (buffer-name (process-buffer proc))
1292       (with-current-buffer (process-buffer proc)
1293         (let ((inhibit-read-only t))
1294           (save-excursion
1295             (goto-char (process-mark proc))
1296             (insert-before-markers string)
1297             (run-hooks 'compilation-filter-hook))))))
1298
1299 ;;; test if a buffer is a compilation buffer, assuming we're in the buffer
1300 (defsubst compilation-buffer-internal-p ()
1301   "Test if inside a compilation buffer."
1302   (local-variable-p 'compilation-locs))
1303
1304 ;;; test if a buffer is a compilation buffer, using compilation-buffer-internal-p
1305 (defsubst compilation-buffer-p (buffer)
1306   "Test if BUFFER is a compilation buffer."
1307   (with-current-buffer buffer
1308     (compilation-buffer-internal-p)))
1309
1310 (defmacro compilation-loop (< property-change 1+ error)
1311   `(while (,< n 0)
1312       (or (setq pt (,property-change pt 'message))
1313           (error ,error compilation-error))
1314       ;; prop 'message usually has 2 changes, on and off, so re-search if off
1315       (or (setq msg (get-text-property pt 'message))
1316           (if (setq pt (,property-change pt 'message))
1317               (setq msg (get-text-property pt 'message)))
1318           (error ,error compilation-error))
1319       (or (< (cadr msg) compilation-skip-threshold)
1320           (if different-file
1321               (eq (prog1 last (setq last (nth 2 (car msg))))
1322                   last))
1323           (if compilation-skip-visited
1324               (nthcdr 4 (car msg)))
1325           (if compilation-skip-to-next-location
1326               (eq (car msg) loc))
1327           ;; count this message only if none of the above are true
1328           (setq n (,1+ n)))))
1329
1330 (defun compilation-next-error (n &optional different-file pt)
1331   "Move point to the next error in the compilation buffer.
1332 Prefix arg N says how many error messages to move forwards (or
1333 backwards, if negative).
1334 Does NOT find the source line like \\[next-error]."
1335   (interactive "p")
1336   (or (compilation-buffer-p (current-buffer))
1337       (error "Not in a compilation buffer"))
1338   (or pt (setq pt (point)))
1339   (let* ((msg (get-text-property pt 'message))
1340          (loc (car msg))
1341          last)
1342     (if (zerop n)
1343         (unless (or msg                 ; find message near here
1344                     (setq msg (get-text-property (max (1- pt) (point-min))
1345                                                  'message)))
1346           (setq pt (previous-single-property-change pt 'message nil
1347                                                     (line-beginning-position)))
1348           (unless (setq msg (get-text-property (max (1- pt) (point-min)) 'message))
1349             (setq pt (next-single-property-change pt 'message nil
1350                                                   (line-end-position)))
1351             (or (setq msg (get-text-property pt 'message))
1352                 (setq pt (point)))))
1353       (setq last (nth 2 (car msg)))
1354       (if (>= n 0)
1355           (compilation-loop > next-single-property-change 1-
1356                             (if (get-buffer-process (current-buffer))
1357                                 "No more %ss yet"
1358                               "Moved past last %s"))
1359         ;; Don't move "back" to message at or before point.
1360         ;; Pass an explicit (point-min) to make sure pt is non-nil.
1361         (setq pt (previous-single-property-change pt 'message nil (point-min)))
1362         (compilation-loop < previous-single-property-change 1+
1363                           "Moved back before first %s")))
1364     (goto-char pt)
1365     (or msg
1366         (error "No %s here" compilation-error))))
1367
1368 (defun compilation-previous-error (n)
1369   "Move point to the previous error in the compilation buffer.
1370 Prefix arg N says how many error messages to move backwards (or
1371 forwards, if negative).
1372 Does NOT find the source line like \\[previous-error]."
1373   (interactive "p")
1374   (compilation-next-error (- n)))
1375
1376 (defun compilation-next-file (n)
1377   "Move point to the next error for a different file than the current one.
1378 Prefix arg N says how many files to move forwards (or backwards, if negative)."
1379   (interactive "p")
1380   (compilation-next-error n t))
1381
1382 (defun compilation-previous-file (n)
1383   "Move point to the previous error for a different file than the current one.
1384 Prefix arg N says how many files to move backwards (or forwards, if negative)."
1385   (interactive "p")
1386   (compilation-next-file (- n)))
1387
1388 (defun kill-compilation ()
1389   "Kill the process made by the \\[compile] or \\[grep] commands."
1390   (interactive)
1391   (let ((buffer (compilation-find-buffer)))
1392     (if (get-buffer-process buffer)
1393         (interrupt-process (get-buffer-process buffer))
1394       (error "The compilation process is not running"))))
1395
1396 (defalias 'compile-mouse-goto-error 'compile-goto-error)
1397
1398 (defun compile-goto-error (&optional event)
1399   "Visit the source for the error message at point.
1400 Use this command in a compilation log buffer.  Sets the mark at point there."
1401   (interactive (list last-input-event))
1402   (if event (posn-set-point (event-end event)))
1403   (or (compilation-buffer-p (current-buffer))
1404       (error "Not in a compilation buffer"))
1405   (if (get-text-property (point) 'directory)
1406       (dired-other-window (car (get-text-property (point) 'directory)))
1407     (push-mark)
1408     (setq compilation-current-error (point))
1409     (next-error 0)))
1410
1411 ;; Return a compilation buffer.
1412 ;; If the current buffer is a compilation buffer, return it.
1413 ;; Otherwise, look for a compilation buffer and signal an error
1414 ;; if there are none.
1415 (defun compilation-find-buffer (&optional other-buffer)
1416   (next-error-find-buffer other-buffer 'compilation-buffer-internal-p))
1417
1418 ;;;###autoload
1419 (defun compilation-next-error-function (n &optional reset)
1420   (interactive "p")
1421   (set-buffer (compilation-find-buffer))
1422   (when reset
1423     (setq compilation-current-error nil))
1424   (let* ((columns compilation-error-screen-columns) ; buffer's local value
1425          (last 1)
1426          (loc (compilation-next-error (or n 1) nil
1427                                       (or compilation-current-error
1428                                           compilation-messages-start
1429                                           (point-min))))
1430          (end-loc (nth 2 loc))
1431          (marker (point-marker)))
1432     (setq compilation-current-error (point-marker)
1433           overlay-arrow-position
1434             (if (bolp)
1435                 compilation-current-error
1436               (copy-marker (line-beginning-position)))
1437           loc (car loc))
1438     ;; If loc contains no marker, no error in that file has been visited.  If
1439     ;; the marker is invalid the buffer has been killed.  So, recalculate all
1440     ;; markers for that file.
1441     (unless (and (nth 3 loc) (marker-buffer (nth 3 loc)))
1442       (with-current-buffer (compilation-find-file marker (caar (nth 2 loc))
1443                                                   (or (cdar (nth 2 loc))
1444                                                       default-directory))
1445         (save-restriction
1446           (widen)
1447           (goto-char (point-min))
1448           ;; Treat file's found lines in forward order, 1 by 1.
1449           (dolist (line (reverse (cddr (nth 2 loc))))
1450             (when (car line)            ; else this is a filename w/o a line#
1451               (beginning-of-line (- (car line) last -1))
1452               (setq last (car line)))
1453             ;; Treat line's found columns and store/update a marker for each.
1454             (dolist (col (cdr line))
1455               (if (car col)
1456                   (if (eq (car col) -1) ; special case for range end
1457                       (end-of-line)
1458                     (if columns
1459                         (move-to-column (car col))
1460                       (beginning-of-line)
1461                       (forward-char (car col))))
1462                 (beginning-of-line)
1463                 (skip-chars-forward " \t"))
1464               (if (nth 3 col)
1465                   (set-marker (nth 3 col) (point))
1466                 (setcdr (nthcdr 2 col) `(,(point-marker)))))))))
1467     (compilation-goto-locus marker (nth 3 loc) (nth 3 end-loc))
1468     (setcdr (nthcdr 3 loc) t)))         ; Set this one as visited.
1469
1470 (defvar compilation-gcpro nil
1471   "Internal variable used to keep some values from being GC'd.")
1472 (make-variable-buffer-local 'compilation-gcpro)
1473
1474 (defun compilation-fake-loc (marker file &optional line col)
1475   "Preassociate MARKER with FILE.
1476 FILE should be ABSOLUTE-FILENAME or (RELATIVE-FILENAME . DIRNAME).
1477 This is useful when you compile temporary files, but want
1478 automatic translation of the messages to the real buffer from
1479 which the temporary file came.  This only works if done before a
1480 message about FILE appears!
1481
1482 Optional args LINE and COL default to 1 and beginning of
1483 indentation respectively.  The marker is expected to reflect
1484 this.  In the simplest case the marker points to the first line
1485 of the region that was saved to the temp file.
1486
1487 If you concatenate several regions into the temp file (e.g. a
1488 header with variable assignments and a code region), you must
1489 call this several times, once each for the last line of one
1490 region and the first line of the next region."
1491   (or (consp file) (setq file (list file)))
1492   (setq file (compilation-get-file-structure file))
1493   ;; Between the current call to compilation-fake-loc and the first occurrence
1494   ;; of an error message referring to `file', the data is only kept is the
1495   ;; weak hash-table compilation-locs, so we need to prevent this entry
1496   ;; in compilation-locs from being GC'd away.  --Stef
1497   (push file compilation-gcpro)
1498   (let ((loc (compilation-assq (or line 1) (cdr file))))
1499     (setq loc (compilation-assq col loc))
1500     (if (cdr loc)
1501         (setcdr (cddr loc) (list marker))
1502       (setcdr loc (list line file marker)))
1503     loc))
1504
1505 (defcustom compilation-context-lines 0
1506   "*Display this many lines of leading context before message.
1507 If nil, don't scroll the compilation output window."
1508   :type '(choice integer (const :tag "No window scrolling" nil))
1509   :group 'compilation
1510   :version "21.4")
1511
1512 (defsubst compilation-set-window (w mk)
1513   "Align the compilation output window W with marker MK near top."
1514   (if (integerp compilation-context-lines)
1515       (set-window-start w (save-excursion
1516                             (goto-char mk)
1517                             (beginning-of-line (- 1 compilation-context-lines))
1518                             (point))))
1519   (set-window-point w mk))
1520
1521 (defun compilation-goto-locus (msg mk end-mk)
1522   "Jump to an error corresponding to MSG at MK.
1523 All arguments are markers.  If END-MK is non nil, mark is set there."
1524   (if (eq (window-buffer (selected-window))
1525           (marker-buffer msg))
1526       ;; If the compilation buffer window is selected,
1527       ;; keep the compilation buffer in this window;
1528       ;; display the source in another window.
1529       (let ((pop-up-windows t))
1530         (pop-to-buffer (marker-buffer mk)))
1531     (if (window-dedicated-p (selected-window))
1532         (pop-to-buffer (marker-buffer mk))
1533       (switch-to-buffer (marker-buffer mk))))
1534   ;; If narrowing gets in the way of going to the right place, widen.
1535   (unless (eq (goto-char mk) (point))
1536     (widen)
1537     (goto-char mk))
1538   (if end-mk
1539       (push-mark end-mk nil t)
1540     (if mark-active (setq mark-active)))
1541   ;; If hideshow got in the way of
1542   ;; seeing the right place, open permanently.
1543   (dolist (ov (overlays-at (point)))
1544     (when (eq 'hs (overlay-get ov 'invisible))
1545       (delete-overlay ov)
1546       (goto-char mk)))
1547
1548   ;; Show compilation buffer in other window, scrolled to this error.
1549   (let* ((pop-up-windows t)
1550          ;; Use an existing window if it is in a visible frame.
1551          (w (or (get-buffer-window (marker-buffer msg) 'visible)
1552                 ;; Pop up a window.
1553                 (display-buffer (marker-buffer msg))))
1554          (highlight-regexp (with-current-buffer (marker-buffer msg)
1555                              ;; also do this while we change buffer
1556                              (compilation-set-window w msg)
1557                              compilation-highlight-regexp)))
1558     (compilation-set-window-height w)
1559
1560     (when (and highlight-regexp
1561                (not (and end-mk transient-mark-mode)))
1562       (unless compilation-highlight-overlay
1563         (setq compilation-highlight-overlay
1564               (make-overlay (point-min) (point-min)))
1565         (overlay-put compilation-highlight-overlay 'face 'region))
1566       (with-current-buffer (marker-buffer mk)
1567         (save-excursion
1568           (end-of-line)
1569           (let ((end (point)))
1570             (beginning-of-line)
1571             (if (and (stringp highlight-regexp)
1572                      (re-search-forward highlight-regexp end t))
1573                 (progn
1574                   (goto-char (match-beginning 0))
1575                   (move-overlay compilation-highlight-overlay (match-beginning 0) (match-end 0)))
1576               (move-overlay compilation-highlight-overlay (point) end))
1577             (sit-for 0.5)
1578             (delete-overlay compilation-highlight-overlay)))))))
1579
1580 \f
1581 (defun compilation-find-file (marker filename dir &rest formats)
1582   "Find a buffer for file FILENAME.
1583 Search the directories in `compilation-search-path'.
1584 A nil in `compilation-search-path' means to try the
1585 current directory, which is passed in DIR.
1586 If FILENAME is not found at all, ask the user where to find it.
1587 Pop up the buffer containing MARKER and scroll to MARKER if we ask the user."
1588   (or formats (setq formats '("%s")))
1589   (save-excursion
1590     (let ((dirs compilation-search-path)
1591           buffer thisdir fmts name)
1592       (if (file-name-absolute-p filename)
1593           ;; The file name is absolute.  Use its explicit directory as
1594           ;; the first in the search path, and strip it from FILENAME.
1595           (setq filename (abbreviate-file-name (expand-file-name filename))
1596                 dirs (cons (file-name-directory filename) dirs)
1597                 filename (file-name-nondirectory filename)))
1598       ;; Now search the path.
1599       (while (and dirs (null buffer))
1600         (setq thisdir (or (car dirs) dir)
1601               fmts formats)
1602         ;; For each directory, try each format string.
1603         (while (and fmts (null buffer))
1604           (setq name (expand-file-name (format (car fmts) filename) thisdir)
1605                 buffer (and (file-exists-p name)
1606                             (find-file-noselect name))
1607                 fmts (cdr fmts)))
1608         (setq dirs (cdr dirs)))
1609       (or buffer
1610           ;; The file doesn't exist.  Ask the user where to find it.
1611           (let ((pop-up-windows t))
1612             (compilation-set-window (display-buffer (marker-buffer marker))
1613                                     marker)
1614             (let ((name (expand-file-name
1615                          (read-file-name
1616                           (format "Find this error in: (default %s) "
1617                                   filename)
1618                           dir filename t))))
1619               (if (file-directory-p name)
1620                   (setq name (expand-file-name filename name)))
1621               (setq buffer (and (file-exists-p name)
1622                                 (find-file name))))))
1623       ;; Make intangible overlays tangible.
1624       (mapcar (function (lambda (ov)
1625                           (when (overlay-get ov 'intangible)
1626                             (overlay-put ov 'intangible nil))))
1627               (overlays-in (point-min) (point-max)))
1628       buffer)))
1629
1630 (defun compilation-get-file-structure (file &optional fmt)
1631   "Retrieve FILE's file-structure or create a new one.
1632 FILE should be (ABSOLUTE-FILENAME) or (RELATIVE-FILENAME . DIRNAME)."
1633
1634   (or (gethash file compilation-locs)
1635       ;; File was not previously encountered, at least not in the form passed.
1636       ;; Let's normalize it and look again.
1637       (let ((filename (car file))
1638             (default-directory (if (cdr file)
1639                                    (file-truename (cdr file))
1640                                  default-directory)))
1641
1642         ;; Check for a comint-file-name-prefix and prepend it if appropriate.
1643         ;; (This is very useful for compilation-minor-mode in an rlogin-mode
1644         ;; buffer.)
1645         (if (boundp 'comint-file-name-prefix)
1646             (if (file-name-absolute-p filename)
1647                 (setq filename
1648                       (concat (with-no-warnings comint-file-name-prefix) filename))
1649               (setq default-directory
1650                     (file-truename
1651                      (concat (with-no-warnings comint-file-name-prefix) default-directory)))))
1652
1653         ;; If compilation-parse-errors-filename-function is
1654         ;; defined, use it to process the filename.
1655         (when compilation-parse-errors-filename-function
1656           (setq filename
1657                 (funcall compilation-parse-errors-filename-function
1658                          filename)))
1659
1660         ;; Some compilers (e.g. Sun's java compiler, reportedly) produce bogus
1661         ;; file names like "./bar//foo.c" for file "bar/foo.c";
1662         ;; expand-file-name will collapse these into "/foo.c" and fail to find
1663         ;; the appropriate file.  So we look for doubled slashes in the file
1664         ;; name and fix them.
1665         (setq filename (command-line-normalize-file-name filename))
1666
1667         ;; Now eliminate any "..", because find-file would get them wrong.
1668         ;; Make relative and absolute filenames, with or without links, the
1669         ;; same.
1670         (setq filename
1671               (list (abbreviate-file-name
1672                      (file-truename (if (cdr file)
1673                                         (expand-file-name filename)
1674                                       filename)))))
1675
1676         ;; Store it for the possibly unnormalized name
1677         (puthash file
1678                  ;; Retrieve or create file-structure for normalized name
1679                  (or (gethash filename compilation-locs)
1680                      (puthash filename (list filename fmt) compilation-locs))
1681                  compilation-locs))))
1682
1683 (add-to-list 'debug-ignored-errors "^No more [-a-z ]+s yet$")
1684
1685 ;;; Compatibility with the old compile.el.
1686
1687 (defun compile-buffer-substring (n) (if n (match-string n)))
1688
1689 (defun compilation-compat-error-properties (err)
1690   "Map old-style error ERR to new-style message."
1691   ;; Old-style structure is (MARKER (FILE DIR) LINE COL) or
1692   ;; (MARKER . MARKER).
1693   (let ((dst (cdr err)))
1694     (if (markerp dst)
1695         ;; Must start with a face, for font-lock.
1696         `(face nil
1697           message ,(list (list nil nil nil dst) 2)
1698           help-echo "mouse-2: visit the source location"
1699           keymap compilation-button-map
1700           mouse-face highlight)
1701       ;; Too difficult to do it by hand: dispatch to the normal code.
1702       (let* ((file (pop dst))
1703              (line (pop dst))
1704              (col (pop dst))
1705              (filename (pop file))
1706              (dirname (pop file))
1707              (fmt (pop file)))
1708         (compilation-internal-error-properties
1709          (cons filename dirname) line nil col nil 2 fmt)))))
1710
1711 (defun compilation-compat-parse-errors (limit)
1712   (when compilation-parse-errors-function
1713     ;; FIXME: We should remove the rest of the compilation keywords
1714     ;; but we can't do that from here because font-lock is using
1715     ;; the value right now.  --stef
1716     (save-excursion
1717       (setq compilation-error-list nil)
1718       ;; Reset compilation-parsing-end each time because font-lock
1719       ;; might force us the re-parse many times (typically because
1720       ;; some code adds some text-property to the output that we
1721       ;; already parsed).  You might say "why reparse", well:
1722       ;; because font-lock has just removed the `message' property so
1723       ;; have to do it all over again.
1724       (if compilation-parsing-end
1725           (set-marker compilation-parsing-end (point))
1726         (setq compilation-parsing-end (point-marker)))
1727       (condition-case nil
1728           ;; Ignore any error: we're calling this function earlier than
1729           ;; in the old compile.el so things might not all be setup yet.
1730           (funcall compilation-parse-errors-function limit nil)
1731         (error nil))
1732       (dolist (err (if (listp compilation-error-list) compilation-error-list))
1733         (let* ((src (car err))
1734                (dst (cdr err))
1735                (loc (cond ((markerp dst) (list nil nil nil dst))
1736                           ((consp dst)
1737                            (list (nth 2 dst) (nth 1 dst)
1738                                  (cons (cdar dst) (caar dst)))))))
1739           (when loc
1740             (goto-char src)
1741             ;; (put-text-property src (line-end-position) 'font-lock-face 'font-lock-warning-face)
1742             (put-text-property src (line-end-position)
1743                                'message (list loc 2)))))))
1744   (goto-char limit)
1745   nil)
1746
1747 ;; Beware: this is not only compatiblity code.  New code stil uses it.  --Stef
1748 (defun compilation-forget-errors ()
1749   ;; In case we hit the same file/line specs, we want to recompute a new
1750   ;; marker for them, so flush our cache.
1751   (setq compilation-locs (make-hash-table :test 'equal :weakness 'value))
1752   (setq compilation-gcpro nil)
1753   ;; FIXME: the old code reset the directory-stack, so maybe we should
1754   ;; put a `directory change' marker of some sort, but where?  -stef
1755   ;;
1756   ;; FIXME: The old code moved compilation-current-error (which was
1757   ;; virtually represented by a mix of compilation-parsing-end and
1758   ;; compilation-error-list) to point-min, but that was only meaningful for
1759   ;; the internal uses of compilation-forget-errors: all calls from external
1760   ;; packages seem to be followed by a move of compilation-parsing-end to
1761   ;; something equivalent to point-max.  So we speculatively move
1762   ;; compilation-current-error to point-max (since the external package
1763   ;; won't know that it should do it).  --stef
1764   (setq compilation-current-error nil)
1765   (let* ((proc (get-buffer-process (current-buffer)))
1766          (mark (if proc (process-mark proc)))
1767          (pos (or mark (point-max))))
1768     (setq compilation-messages-start
1769           ;; In the future, ignore the text already present in the buffer.
1770           ;; Since many process filter functions insert before markers,
1771           ;; we need to put ours just before the insertion point rather
1772           ;; than at the insertion point.  If that's not possible, then
1773           ;; don't use a marker.  --Stef
1774           (if (> pos (point-min)) (copy-marker (1- pos)) pos))))
1775
1776 (provide 'compile)
1777
1778 ;; arch-tag: 12465727-7382-4f72-b234-79855a00dd8c
1779 ;;; compile.el ends here