code.delx.au - gnu-emacs/blob - lisp/man.el

   1 ;;; man.el --- browse UNIX manual pages  -*- coding: utf-8 -*-
   2
   3 ;; Copyright (C) 1993-1994, 1996-1997, 2001-2013 Free Software
   4 ;; Foundation, Inc.
   5
   6 ;; Author: Barry A. Warsaw <bwarsaw@cen.com>
   7 ;; Maintainer: FSF
   8 ;; Keywords: help
   9 ;; Adapted-By: ESR, pot
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; This code provides a function, `man', with which you can browse
  29 ;; UNIX manual pages.  Formatting is done in background so that you
  30 ;; can continue to use your Emacs while processing is going on.
  31 ;;
  32 ;; The mode also supports hypertext-like following of manual page SEE
  33 ;; ALSO references, and other features.  See below or do `?' in a
  34 ;; manual page buffer for details.
  35
  36 ;; ========== Credits and History ==========
  37 ;; In mid 1991, several people posted some interesting improvements to
  38 ;; man.el from the standard Emacs 18.57 distribution.  I liked many of
  39 ;; these, but wanted everything in one single package, so I decided
  40 ;; to incorporate them into a single manual browsing mode.  While
  41 ;; much of the code here has been rewritten, and some features added,
  42 ;; these folks deserve lots of credit for providing the initial
  43 ;; excellent packages on which this one is based.
  44
  45 ;; Nick Duffek <duffek@chaos.cs.brandeis.edu>, posted a very nice
  46 ;; improvement which retrieved and cleaned the manpages in a
  47 ;; background process, and which correctly deciphered such options as
  48 ;; man -k.
  49
  50 ;; Eric Rose <erose@jessica.stanford.edu>, submitted manual.el which
  51 ;; provided a very nice manual browsing mode.
  52
  53 ;; This package was available as `superman.el' from the LCD package
  54 ;; for some time before it was accepted into Emacs 19.  The entry
  55 ;; point and some other names have been changed to make it a drop-in
  56 ;; replacement for the old man.el package.
  57
  58 ;; Francesco Potorti` <pot@cnuce.cnr.it> cleaned it up thoroughly,
  59 ;; making it faster, more robust and more tolerant of different
  60 ;; systems' man idiosyncrasies.
  61
  62 ;; ========== Features ==========
  63 ;; + Runs "man" in the background and pipes the results through a
  64 ;;   series of sed and awk scripts so that all retrieving and cleaning
  65 ;;   is done in the background.  The cleaning commands are configurable.
  66 ;; + Syntax is the same as Un*x man
  67 ;; + Functionality is the same as Un*x man, including "man -k" and
  68 ;;   "man <section>", etc.
  69 ;; + Provides a manual browsing mode with keybindings for traversing
  70 ;;   the sections of a manpage, following references in the SEE ALSO
  71 ;;   section, and more.
  72 ;; + Multiple manpages created with the same man command are put into
  73 ;;   a narrowed buffer circular list.
  74
  75 ;; ============= TODO ===========
  76 ;; - Add a command for printing.
  77 ;; - The awk script deletes multiple blank lines.  This behavior does
  78 ;;   not allow to understand if there was indeed a blank line at the
  79 ;;   end or beginning of a page (after the header, or before the
  80 ;;   footer).  A different algorithm should be used.  It is easy to
  81 ;;   compute how many blank lines there are before and after the page
  82 ;;   headers, and after the page footer.  But it is possible to compute
  83 ;;   the number of blank lines before the page footer by heuristics
  84 ;;   only.  Is it worth doing?
  85 ;; - Allow a user option to mean that all the manpages should go in
  86 ;;   the same buffer, where they can be browsed with M-n and M-p.
  87
  88 \f
  89 ;;; Code:
  90
  91 (require 'ansi-color)
  92 (require 'button)
  93
  94 (defgroup man nil
  95   "Browse UNIX manual pages."
  96   :prefix "Man-"
  97   :group 'external
  98   :group 'help)
  99
 100 (defvar Man-notify)
 101
 102 (defcustom Man-filter-list nil
 103   "Manpage cleaning filter command phrases.
 104 This variable contains a list of the following form:
 105
 106 '((command-string phrase-string*)*)
 107
 108 Each phrase-string is concatenated onto the command-string to form a
 109 command filter.  The (standard) output (and standard error) of the Un*x
 110 man command is piped through each command filter in the order the
 111 commands appear in the association list.  The final output is placed in
 112 the manpage buffer."
 113   :type '(repeat (list (string :tag "Command String")
 114                        (repeat :inline t
 115                                (string :tag "Phrase String"))))
 116   :group 'man)
 117
 118 (defvar Man-uses-untabify-flag t
 119   "Non-nil means use `untabify' instead of `Man-untabify-command'.")
 120 (defvar Man-sed-script nil
 121   "Script for sed to nuke backspaces and ANSI codes from manpages.")
 122
 123 (defcustom Man-fontify-manpage-flag t
 124   "Non-nil means make up the manpage with fonts."
 125   :type 'boolean
 126   :group 'man)
 127
 128 (defface Man-overstrike
 129   '((t (:inherit bold)))
 130   "Face to use when fontifying overstrike."
 131   :group 'man
 132   :version "24.3")
 133
 134 (defface Man-underline
 135   '((t (:inherit underline)))
 136   "Face to use when fontifying underlining."
 137   :group 'man
 138   :version "24.3")
 139
 140 (defface Man-reverse
 141   '((t (:inherit highlight)))
 142   "Face to use when fontifying reverse video."
 143   :group 'man
 144   :version "24.3")
 145
 146 (defvar Man-ansi-color-map (let ((ansi-color-faces-vector
 147                                   [ default Man-overstrike default Man-underline
 148                                     Man-underline default default Man-reverse ]))
 149                              (ansi-color-make-color-map))
 150   "The value used here for `ansi-color-map'.")
 151
 152 ;; Use the value of the obsolete user option Man-notify, if set.
 153 (defcustom Man-notify-method (if (boundp 'Man-notify) Man-notify 'friendly)
 154   "Selects the behavior when manpage is ready.
 155 This variable may have one of the following values, where (sf) means
 156 that the frames are switched, so the manpage is displayed in the frame
 157 where the man command was called from:
 158
 159 newframe   -- put the manpage in its own frame (see `Man-frame-parameters')
 160 pushy      -- make the manpage the current buffer in the current window
 161 bully      -- make the manpage the current buffer and only window (sf)
 162 aggressive -- make the manpage the current buffer in the other window (sf)
 163 friendly   -- display manpage in the other window but don't make current (sf)
 164 polite     -- don't display manpage, but prints message and beep when ready
 165 quiet      -- like `polite', but don't beep
 166 meek       -- make no indication that the manpage is ready
 167
 168 Any other value of `Man-notify-method' is equivalent to `meek'."
 169   :type '(radio (const newframe) (const pushy) (const bully)
 170                 (const aggressive) (const friendly)
 171                 (const polite) (const quiet) (const meek))
 172   :group 'man)
 173
 174 (defcustom Man-width nil
 175   "Number of columns for which manual pages should be formatted.
 176 If nil, the width of the window selected at the moment of man
 177 invocation is used.  If non-nil, the width of the frame selected
 178 at the moment of man invocation is used.  The value also can be a
 179 positive integer."
 180   :type '(choice (const :tag "Window width" nil)
 181                  (const :tag "Frame width" t)
 182                  (integer :tag "Specific width" :value 65))
 183   :group 'man)
 184
 185 (defcustom Man-frame-parameters nil
 186   "Frame parameter list for creating a new frame for a manual page."
 187   :type 'sexp
 188   :group 'man)
 189
 190 (defcustom Man-downcase-section-letters-flag t
 191   "Non-nil means letters in sections are converted to lower case.
 192 Some Un*x man commands can't handle uppercase letters in sections, for
 193 example \"man 2V chmod\", but they are often displayed in the manpage
 194 with the upper case letter.  When this variable is t, the section
 195 letter (e.g., \"2V\") is converted to lowercase (e.g., \"2v\") before
 196 being sent to the man background process."
 197   :type 'boolean
 198   :group 'man)
 199
 200 (defcustom Man-circular-pages-flag t
 201   "Non-nil means the manpage list is treated as circular for traversal."
 202   :type 'boolean
 203   :group 'man)
 204
 205 (defcustom Man-section-translations-alist
 206   (list
 207    '("3C++" . "3")
 208    ;; Some systems have a real 3x man section, so let's comment this.
 209    ;; '("3X" . "3")                        ; Xlib man pages
 210    '("3X11" . "3")
 211    '("1-UCB" . ""))
 212   "Association list of bogus sections to real section numbers.
 213 Some manpages (e.g. the Sun C++ 2.1 manpages) have section numbers in
 214 their references which Un*x `man' does not recognize.  This
 215 association list is used to translate those sections, when found, to
 216 the associated section number."
 217   :type '(repeat (cons (string :tag "Bogus Section")
 218                        (string :tag "Real Section")))
 219   :group 'man)
 220
 221 ;; FIXME see comments at ffap-c-path.
 222 (defcustom Man-header-file-path
 223   (let ((arch (with-temp-buffer
 224                 (when (eq 0 (ignore-errors
 225                               (call-process "gcc" nil '(t nil) nil
 226                                             "-print-multiarch")))
 227                   (goto-char (point-min))
 228                   (buffer-substring (point) (line-end-position)))))
 229         (base '("/usr/include" "/usr/local/include")))
 230     (if (zerop (length arch))
 231         base
 232       (append base (list (expand-file-name arch "/usr/include")))))
 233   "C Header file search path used in Man."
 234   :version "24.1"                       ; add multiarch
 235   :type '(repeat string)
 236   :group 'man)
 237
 238 (defcustom Man-name-local-regexp (concat "^" (regexp-opt '("NOM" "NAME")) "$")
 239   "Regexp that matches the text that precedes the command's name.
 240 Used in `bookmark-set' to get the default bookmark name."
 241   :version "24.1"
 242   :type 'string :group 'bookmark)
 243
 244 (defcustom manual-program "man"
 245   "Program used by `man' to produce man pages."
 246   :type 'string
 247   :group 'man)
 248
 249 (defcustom Man-untabify-command "pr"
 250   "Program used by `man' for untabifying."
 251   :type 'string
 252   :group 'man)
 253
 254 (defcustom Man-untabify-command-args (list "-t" "-e")
 255   "List of arguments to be passed to `Man-untabify-command' (which see)."
 256   :type '(repeat string)
 257   :group 'man)
 258
 259 (defcustom Man-sed-command "sed"
 260   "Program used by `man' to process sed scripts."
 261   :type 'string
 262   :group 'man)
 263
 264 (defcustom Man-awk-command "awk"
 265   "Program used by `man' to process awk scripts."
 266   :type 'string
 267   :group 'man)
 268
 269 (defcustom Man-mode-hook nil
 270   "Hook run when Man mode is enabled."
 271   :type 'hook
 272   :group 'man)
 273
 274 (defcustom Man-cooked-hook nil
 275   "Hook run after removing backspaces but before `Man-mode' processing."
 276   :type 'hook
 277   :group 'man)
 278
 279 (defvar Man-name-regexp "[-a-zA-Z0-9_+][-a-zA-Z0-9_.:+]*"
 280   "Regular expression describing the name of a manpage (without section).")
 281
 282 (defvar Man-section-regexp "[0-9][a-zA-Z0-9+]*\\|[LNln]"
 283   "Regular expression describing a manpage section within parentheses.")
 284
 285 (defvar Man-page-header-regexp
 286   (if (string-match "-solaris2\\." system-configuration)
 287       (concat "^[-A-Za-z0-9_].*[ \t]\\(" Man-name-regexp
 288               "(\\(" Man-section-regexp "\\))\\)$")
 289     (concat "^[ \t]*\\(" Man-name-regexp
 290             "(\\(" Man-section-regexp "\\))\\).*\\1"))
 291   "Regular expression describing the heading of a page.")
 292
 293 (defvar Man-heading-regexp "^\\([A-Z][A-Z0-9 /-]+\\)$"
 294   "Regular expression describing a manpage heading entry.")
 295
 296 (defvar Man-see-also-regexp "SEE ALSO"
 297   "Regular expression for SEE ALSO heading (or your equivalent).
 298 This regexp should not start with a `^' character.")
 299
 300 ;; This used to have leading space [ \t]*, but was removed because it
 301 ;; causes false page splits on an occasional NAME with leading space
 302 ;; inside a manpage.  And `Man-heading-regexp' doesn't have [ \t]* anyway.
 303 (defvar Man-first-heading-regexp "^NAME$\\|^[ \t]*No manual entry fo.*$"
 304   "Regular expression describing first heading on a manpage.
 305 This regular expression should start with a `^' character.")
 306
 307 (defvar Man-reference-regexp
 308   (concat "\\(" Man-name-regexp
 309           "\\(\n[ \t]+" Man-name-regexp "\\)*\\)[ \t]*(\\("
 310           Man-section-regexp "\\))")
 311   "Regular expression describing a reference to another manpage.")
 312
 313 (defvar Man-apropos-regexp
 314   (concat "\\\[\\(" Man-name-regexp "\\)\\\][ \t]*(\\(" Man-section-regexp "\\))")
 315   "Regular expression describing a reference to manpages in \"man -k output\".")
 316
 317 (defvar Man-synopsis-regexp "SYNOPSIS"
 318   "Regular expression for SYNOPSIS heading (or your equivalent).
 319 This regexp should not start with a `^' character.")
 320
 321 (defvar Man-files-regexp "FILES\\>"
 322   ;; Add \> so as not to match mount(8)'s FILESYSTEM INDEPENDENT MOUNT OPTIONS.
 323   "Regular expression for FILES heading (or your equivalent).
 324 This regexp should not start with a `^' character.")
 325
 326 (defvar Man-include-regexp "#[ \t]*include[ \t]*"
 327   "Regular expression describing the #include (directive of cpp).")
 328
 329 (defvar Man-file-name-regexp "[^<>\", \t\n]+"
 330   "Regular expression describing <> in #include line (directive of cpp).")
 331
 332 (defvar Man-normal-file-prefix-regexp "[/~$]"
 333   "Regular expression describing a file path appeared in FILES section.")
 334
 335 (defvar Man-header-regexp
 336   (concat "\\(" Man-include-regexp "\\)"
 337           "[<\"]"
 338           "\\(" Man-file-name-regexp "\\)"
 339           "[>\"]")
 340   "Regular expression describing references to header files.")
 341
 342 (defvar Man-normal-file-regexp
 343   (concat Man-normal-file-prefix-regexp Man-file-name-regexp)
 344   "Regular expression describing references to normal files.")
 345
 346 ;; This includes the section as an optional part to catch hyphenated
 347 ;; references to manpages.
 348 (defvar Man-hyphenated-reference-regexp
 349   (concat "\\(" Man-name-regexp "\\)\\((\\(" Man-section-regexp "\\))\\)?")
 350   "Regular expression describing a reference in the SEE ALSO section.")
 351
 352 (defcustom Man-switches ""
 353   "Switches passed to the man command, as a single string.
 354 For example, the -a switch lets you see all the manpages for a
 355 specified subject, if your `man' program supports it."
 356   :type 'string
 357   :group 'man)
 358
 359 (defvar Man-specified-section-option
 360   (if (string-match "-solaris[0-9.]*$" system-configuration)
 361       "-s"
 362     "")
 363   "Option that indicates a specified a manual section name.")
 364
 365 (defvar Man-support-local-filenames 'auto-detect
 366   "Internal cache for the value of the function `Man-support-local-filenames'.
 367 `auto-detect' means the value is not yet determined.
 368 Otherwise, the value is whatever the function
 369 `Man-support-local-filenames' should return.")
 370
 371 \f
 372 ;; other variables and keymap initializations
 373 (defvar Man-original-frame)
 374 (make-variable-buffer-local 'Man-original-frame)
 375 (defvar Man-arguments)
 376 (make-variable-buffer-local 'Man-arguments)
 377 (put 'Man-arguments 'permanent-local t)
 378
 379 (defvar Man--sections nil)
 380 (make-variable-buffer-local 'Man--sections)
 381 (defvar Man--refpages nil)
 382 (make-variable-buffer-local 'Man--refpages)
 383 (defvar Man-page-list nil)
 384 (make-variable-buffer-local 'Man-page-list)
 385 (defvar Man-current-page 0)
 386 (make-variable-buffer-local 'Man-current-page)
 387 (defvar Man-page-mode-string "1 of 1")
 388 (make-variable-buffer-local 'Man-page-mode-string)
 389
 390 (defconst Man-sysv-sed-script "\
 391 /\b/ {  s/_\b//g
 392         s/\b_//g
 393         s/o\b+/o/g
 394         s/+\bo/o/g
 395         :ovstrk
 396         s/\\(.\\)\b\\1/\\1/g
 397         t ovstrk
 398         }
 399 /\e\\[[0-9][0-9]*m/ s///g"
 400   "Script for sysV-like sed to nuke backspaces and ANSI codes from manpages.")
 401
 402 (defconst Man-berkeley-sed-script "\
 403 /\b/ {  s/_\b//g\\
 404         s/\b_//g\\
 405         s/o\b+/o/g\\
 406         s/+\bo/o/g\\
 407         :ovstrk\\
 408         s/\\(.\\)\b\\1/\\1/g\\
 409         t ovstrk\\
 410         }\\
 411 /\e\\[[0-9][0-9]*m/ s///g"
 412   "Script for berkeley-like sed to nuke backspaces and ANSI codes from manpages.")
 413
 414 (defvar Man-topic-history nil "Topic read history.")
 415
 416 (defvar man-mode-syntax-table
 417   (let ((table (copy-syntax-table (standard-syntax-table))))
 418     (modify-syntax-entry ?. "w" table)
 419     (modify-syntax-entry ?_ "w" table)
 420     (modify-syntax-entry ?: "w" table)  ; for PDL::Primitive in Perl man pages
 421     table)
 422   "Syntax table used in Man mode buffers.")
 423
 424 (defvar Man-mode-map
 425   (let ((map (make-sparse-keymap)))
 426     (suppress-keymap map)
 427     (set-keymap-parent map button-buffer-map)
 428
 429     (define-key map [?\S-\ ] 'scroll-down-command)
 430     (define-key map " "    'scroll-up-command)
 431     (define-key map "\177" 'scroll-down-command)
 432     (define-key map "n"    'Man-next-section)
 433     (define-key map "p"    'Man-previous-section)
 434     (define-key map "\en"  'Man-next-manpage)
 435     (define-key map "\ep"  'Man-previous-manpage)
 436     (define-key map ">"    'end-of-buffer)
 437     (define-key map "<"    'beginning-of-buffer)
 438     (define-key map "."    'beginning-of-buffer)
 439     (define-key map "r"    'Man-follow-manual-reference)
 440     (define-key map "g"    'Man-goto-section)
 441     (define-key map "s"    'Man-goto-see-also-section)
 442     (define-key map "k"    'Man-kill)
 443     (define-key map "q"    'Man-quit)
 444     (define-key map "m"    'man)
 445     ;; Not all the man references get buttons currently.  The text in the
 446     ;; manual page can contain references to other man pages
 447     (define-key map "\r"   'man-follow)
 448     (define-key map "?"    'describe-mode)
 449     map)
 450   "Keymap for Man mode.")
 451
 452 ;; buttons
 453 (define-button-type 'Man-abstract-xref-man-page
 454   'follow-link t
 455   'help-echo "mouse-2, RET: display this man page"
 456   'func nil
 457   'action #'Man-xref-button-action)
 458
 459 (defun Man-xref-button-action (button)
 460   (let ((target (button-get button 'Man-target-string)))
 461     (funcall
 462      (button-get button 'func)
 463      (cond ((null target)
 464             (button-label button))
 465            ((functionp target)
 466             (funcall target (button-start button)))
 467            (t target)))))
 468
 469 (define-button-type 'Man-xref-man-page
 470   :supertype 'Man-abstract-xref-man-page
 471   'func 'man-follow)
 472
 473
 474 (define-button-type 'Man-xref-header-file
 475     'action (lambda (button)
 476               (let ((w (button-get button 'Man-target-string)))
 477                 (unless (Man-view-header-file w)
 478                   (error "Cannot find header file: %s" w))))
 479     'follow-link t
 480     'help-echo "mouse-2: display this header file")
 481
 482 (define-button-type 'Man-xref-normal-file
 483   'action (lambda (button)
 484             (let ((f (substitute-in-file-name
 485                       (button-get button 'Man-target-string))))
 486               (if (file-exists-p f)
 487                   (if (file-readable-p f)
 488                       (view-file f)
 489                     (error "Cannot read a file: %s" f))
 490                 (error "Cannot find a file: %s" f))))
 491   'follow-link t
 492   'help-echo "mouse-2: display this file")
 493
 494 \f
 495 ;; ======================================================================
 496 ;; utilities
 497
 498 (defun Man-init-defvars ()
 499   "Used for initializing variables based on display's color support.
 500 This is necessary if one wants to dump man.el with Emacs."
 501
 502   ;; Avoid possible error in call-process by using a directory that must exist.
 503   (let ((default-directory "/"))
 504     (setq Man-sed-script
 505           (cond
 506            (Man-fontify-manpage-flag
 507             nil)
 508            ((eq 0 (call-process Man-sed-command nil nil nil Man-sysv-sed-script))
 509             Man-sysv-sed-script)
 510            ((eq 0 (call-process Man-sed-command nil nil nil Man-berkeley-sed-script))
 511             Man-berkeley-sed-script)
 512            (t
 513             nil))))
 514
 515   (setq Man-filter-list
 516         ;; Avoid trailing nil which confuses customize.
 517         (apply 'list
 518          (cons
 519           Man-sed-command
 520           (if (eq system-type 'windows-nt)
 521               ;; Windows needs ".." quoting, not '..'.
 522               (list
 523                "-e \"/Reformatting page.  Wait/d\""
 524                "-e \"/Reformatting entry.  Wait/d\""
 525                "-e \"/^[ \t][ \t]*-[ \t][0-9]*[ \t]-[ \t]*Formatted:.*[0-9]$/d\""
 526                "-e \"/^[ \t]*Page[ \t][0-9]*.*(printed[ \t][0-9\\/]*)$/d\""
 527                "-e \"/^Printed[ \t][0-9].*[0-9]$/d\""
 528                "-e \"/^[ \t]*X[ \t]Version[ \t]1[01].*Release[ \t][0-9]/d\""
 529                "-e \"/^[A-Za-z].*Last[ \t]change:/d\""
 530                "-e \"/[ \t]*Copyright [0-9]* UNIX System Laboratories, Inc.$/d\""
 531                "-e \"/^[ \t]*Rev\\..*Page [0-9][0-9]*$/d\"")
 532             (list
 533              (if Man-sed-script
 534                  (concat "-e '" Man-sed-script "'")
 535                "")
 536              "-e '/^[\001-\032][\001-\032]*$/d'"
 537              "-e '/\e[789]/s///g'"
 538              "-e '/Reformatting page.  Wait/d'"
 539              "-e '/Reformatting entry.  Wait/d'"
 540              "-e '/^[ \t]*Hewlett-Packard[ \t]Company[ \t]*-[ \t][0-9]*[ \t]-/d'"
 541              "-e '/^[ \t]*Hewlett-Packard[ \t]*-[ \t][0-9]*[ \t]-.*$/d'"
 542              "-e '/^[ \t][ \t]*-[ \t][0-9]*[ \t]-[ \t]*Formatted:.*[0-9]$/d'"
 543              "-e '/^[ \t]*Page[ \t][0-9]*.*(printed[ \t][0-9\\/]*)$/d'"
 544              "-e '/^Printed[ \t][0-9].*[0-9]$/d'"
 545              "-e '/^[ \t]*X[ \t]Version[ \t]1[01].*Release[ \t][0-9]/d'"
 546              "-e '/^[A-Za-z].*Last[ \t]change:/d'"
 547              "-e '/^Sun[ \t]Release[ \t][0-9].*[0-9]$/d'"
 548              "-e '/[ \t]*Copyright [0-9]* UNIX System Laboratories, Inc.$/d'"
 549              "-e '/^[ \t]*Rev\\..*Page [0-9][0-9]*$/d'"
 550              )))
 551          ;; Windows doesn't support multi-line commands, so don't
 552          ;; invoke Awk there.
 553          (unless (eq system-type 'windows-nt)
 554            (cons
 555             Man-awk-command
 556             (list
 557              "'\n"
 558              "BEGIN { blankline=0; anonblank=0; }\n"
 559              "/^$/ { if (anonblank==0) next; }\n"
 560              "{ anonblank=1; }\n"
 561              "/^$/ { blankline++; next; }\n"
 562              "{ if (blankline>0) { print \"\"; blankline=0; } print $0; }\n"
 563              "'"
 564              )))
 565          (if (not Man-uses-untabify-flag)
 566              ;; The outer list will be stripped off by apply.
 567              (list (cons
 568                     Man-untabify-command
 569                     Man-untabify-command-args))
 570            )))
 571 )
 572
 573 (defsubst Man-make-page-mode-string ()
 574   "Formats part of the mode line for Man mode."
 575   (format "%s page %d of %d"
 576           (or (nth 2 (nth (1- Man-current-page) Man-page-list))
 577               "")
 578           Man-current-page
 579           (length Man-page-list)))
 580
 581 (defsubst Man-build-man-command ()
 582   "Builds the entire background manpage and cleaning command."
 583   (let ((command (concat manual-program " " Man-switches
 584                          (cond
 585                           ;; Already has %s
 586                           ((string-match "%s" manual-program) "")
 587                           ;; Stock MS-DOS shells cannot redirect stderr;
 588                           ;; `call-process' below sends it to /dev/null,
 589                           ;; so we don't need `2>' even with DOS shells
 590                           ;; which do support stderr redirection.
 591                           ((not (fboundp 'start-process)) " %s")
 592                           ((concat " %s 2>" null-device)))))
 593         (flist Man-filter-list))
 594     (while (and flist (car flist))
 595       (let ((pcom (car (car flist)))
 596             (pargs (cdr (car flist))))
 597         (setq command
 598               (concat command " | " pcom " "
 599                       (mapconcat (lambda (phrase)
 600                                    (if (not (stringp phrase))
 601                                        (error "Malformed Man-filter-list"))
 602                                    phrase)
 603                                  pargs " ")))
 604         (setq flist (cdr flist))))
 605     command))
 606
 607
 608 (defun Man-translate-cleanup (string)
 609   "Strip leading, trailing and middle spaces."
 610   (when (stringp string)
 611     ;;  Strip leading and trailing
 612     (if (string-match "^[ \t\f\r\n]*\\(.+[^ \t\f\r\n]\\)" string)
 613         (setq string (match-string 1 string)))
 614     ;; middle spaces
 615     (setq string (replace-regexp-in-string "[\t\r\n]" " " string))
 616     (setq string (replace-regexp-in-string "  +" " " string))
 617     string))
 618
 619 (defun Man-translate-references (ref)
 620   "Translates REF from \"chmod(2V)\" to \"2v chmod\" style.
 621 Leave it as is if already in that style.  Possibly downcase and
 622 translate the section (see the `Man-downcase-section-letters-flag'
 623 and the `Man-section-translations-alist' variables)."
 624   (let ((name "")
 625         (section "")
 626         (slist Man-section-translations-alist))
 627     (setq ref (Man-translate-cleanup ref))
 628     (cond
 629      ;; "chmod(2V)" case ?
 630      ((string-match (concat "^" Man-reference-regexp "$") ref)
 631       (setq name (replace-regexp-in-string "[\n\t ]" "" (match-string 1 ref))
 632             section (match-string 3 ref)))
 633      ;; "2v chmod" case ?
 634      ((string-match (concat "^\\(" Man-section-regexp
 635                             "\\) +\\(" Man-name-regexp "\\)$") ref)
 636       (setq name (match-string 2 ref)
 637             section (match-string 1 ref))))
 638     (if (string= name "")
 639         ref                             ; Return the reference as is
 640       (if Man-downcase-section-letters-flag
 641           (setq section (downcase section)))
 642       (while slist
 643         (let ((s1 (car (car slist)))
 644               (s2 (cdr (car slist))))
 645           (setq slist (cdr slist))
 646           (if Man-downcase-section-letters-flag
 647               (setq s1 (downcase s1)))
 648           (if (not (string= s1 section)) nil
 649             (setq section (if Man-downcase-section-letters-flag
 650                               (downcase s2)
 651                             s2)
 652                   slist nil))))
 653       (concat Man-specified-section-option section " " name))))
 654
 655 (defun Man-support-local-filenames ()
 656   "Return non-nil if the man command supports local filenames.
 657 Different man programs support this feature in different ways.
 658 The default Debian man program (\"man-db\") has a `--local-file'
 659 \(or `-l') option for this purpose.  The default Red Hat man
 660 program has no such option, but interprets any name containing
 661 a \"/\" as a local filename.  The function returns either `man-db'
 662 `man', or nil."
 663   (if (eq Man-support-local-filenames 'auto-detect)
 664       (setq Man-support-local-filenames
 665             (with-temp-buffer
 666               (let ((default-directory
 667                       ;; Ensure that `default-directory' exists and is readable.
 668                       (if (and (file-directory-p default-directory)
 669                                (file-readable-p default-directory))
 670                         default-directory
 671                         (expand-file-name "~/"))))
 672                 (ignore-errors
 673                   (call-process manual-program nil t nil "--help")))
 674               (cond ((search-backward "--local-file" nil 'move)
 675                      'man-db)
 676                     ;; This feature seems to be present in at least ver 1.4f,
 677                     ;; which is about 20 years old.
 678                     ;; I don't know if this version has an official name?
 679                     ((looking-at "^man, versione? [1-9]")
 680                      'man))))
 681     Man-support-local-filenames))
 682
 683 \f
 684 ;; ======================================================================
 685 ;; default man entry: get word near point
 686
 687 (defun Man-default-man-entry (&optional pos)
 688   "Guess default manual entry based on the text near position POS.
 689 POS defaults to `point'."
 690   (let (word start column distance)
 691     (save-excursion
 692       (when pos (goto-char pos))
 693       (setq pos (point))
 694       ;; The default title is the nearest entry-like object before or
 695       ;; after POS.
 696       (if (and (skip-chars-backward " \ta-zA-Z0-9+")
 697                (not (zerop (skip-chars-backward "(")))
 698                ;; Try to handle the special case where POS is on a
 699                ;; section number.
 700                (looking-at
 701                 (concat "([ \t]*\\(" Man-section-regexp "\\)[ \t]*)"))
 702                ;; We skipped a valid section number backwards, look at
 703                ;; preceding text.
 704                (or (and (skip-chars-backward ",; \t")
 705                         (not (zerop (skip-chars-backward "-a-zA-Z0-9._+:"))))
 706                    ;; Not a valid entry, move POS after closing paren.
 707                    (not (setq pos (match-end 0)))))
 708           ;; We have a candidate, make `start' record its starting
 709           ;; position.
 710           (setq start (point))
 711         ;; Otherwise look at char before POS.
 712         (goto-char pos)
 713         (if (not (zerop (skip-chars-backward "-a-zA-Z0-9._+:")))
 714             ;; Our candidate is just before or around POS.
 715             (setq start (point))
 716           ;; Otherwise record the current column and look backwards.
 717           (setq column (current-column))
 718           (skip-chars-backward ",; \t")
 719           ;; Record the distance traveled.
 720           (setq distance (- column (current-column)))
 721           (when (looking-back
 722                  (concat "([ \t]*\\(?:" Man-section-regexp "\\)[ \t]*)"))
 723             ;; Skip section number backwards.
 724             (goto-char (match-beginning 0))
 725             (skip-chars-backward " \t"))
 726           (if (not (zerop (skip-chars-backward "-a-zA-Z0-9._+:")))
 727               (progn
 728                 ;; We have a candidate before POS ...
 729                 (setq start (point))
 730                 (goto-char pos)
 731                 (if (and (skip-chars-forward ",; \t")
 732                          (< (- (current-column) column) distance)
 733                          (looking-at "[-a-zA-Z0-9._+:]"))
 734                     ;; ... but the one after POS is better.
 735                     (setq start (point))
 736                   ;; ... and anything after POS is worse.
 737                   (goto-char start)))
 738             ;; No candidate before POS.
 739             (goto-char pos)
 740             (skip-chars-forward ",; \t")
 741             (setq start (point)))))
 742       ;; We have found a suitable starting point, try to skip at least
 743       ;; one character.
 744       (skip-chars-forward "-a-zA-Z0-9._+:")
 745       (setq word (buffer-substring-no-properties start (point)))
 746       ;; If there is a continuation at the end of line, check the
 747       ;; following line too, eg:
 748       ;;     see this-
 749       ;;     command-here(1)
 750       ;; Note: This code gets executed iff our entry is after POS.
 751       (when (looking-at "[ \t\r\n]+\\([-a-zA-Z0-9._+:]+\\)([0-9])")
 752         (setq word (concat word (match-string-no-properties 1)))
 753         ;; Make sure the section number gets included by the code below.
 754         (goto-char (match-end 1)))
 755       (when (string-match "[._]+$" word)
 756         (setq word (substring word 0 (match-beginning 0))))
 757       ;; The following was commented out since the preceding code
 758       ;; should not produce a leading "*" in the first place.
 759 ;;;       ;; If looking at something like *strcat(... , remove the '*'
 760 ;;;       (when (string-match "^*" word)
 761 ;;;     (setq word (substring word 1)))
 762         (concat
 763          word
 764          (and (not (string-equal word ""))
 765               ;; If looking at something like ioctl(2) or brc(1M),
 766               ;; include the section number in the returned value.
 767               (looking-at
 768                (concat "[ \t]*([ \t]*\\(" Man-section-regexp "\\)[ \t]*)"))
 769               (format "(%s)" (match-string-no-properties 1)))))))
 770
 771 \f
 772 ;; ======================================================================
 773 ;; Top level command and background process sentinel
 774
 775 ;; For compatibility with older versions.
 776 ;;;###autoload
 777 (defalias 'manual-entry 'man)
 778
 779 (defvar Man-completion-cache nil
 780   ;; On my machine, "man -k" is so fast that a cache makes no sense,
 781   ;; but apparently that's not the case in all cases, so let's add a cache.
 782   "Cache of completion table of the form (PREFIX . TABLE).")
 783
 784 (defvar Man-man-k-use-anchor
 785   ;; man-db or man-1.*
 786   (memq system-type '(gnu gnu/linux gnu/kfreebsd))
 787   "If non-nil prepend ^ to the prefix passed to \"man -k\" for completion.
 788 The value should be nil if \"man -k ^PREFIX\" may omit some man
 789 pages whose names start with PREFIX.
 790
 791 Currently, the default value depends on `system-type' and is
 792 non-nil where the standard man programs are known to behave
 793 properly.  Setting the value to nil always gives correct results
 794 but computing the list of completions may take a bit longer.")
 795
 796 (defun Man-parse-man-k ()
 797   "Parse \"man -k\" output and return the list of page names.
 798
 799 The current buffer should contain the output of a command of the
 800 form \"man -k keyword\", which is traditionally also available with
 801 apropos(1).
 802
 803 While POSIX man(1p) is a bit vague about what to expect here,
 804 this function tries to parse some commonly used formats, which
 805 can be described in the following informal way, with square brackets
 806 indicating optional parts and whitespace being interpreted
 807 somewhat loosely.
 808
 809 foo[, bar [, ...]] [other stuff] (sec) - description
 810 foo(sec)[, bar(sec) [, ...]] [other stuff] - description
 811
 812 For more details and some regression tests, please see
 813 test/automated/man-tests.el in the emacs bzr repository."
 814   (goto-char (point-min))
 815   ;; See man-tests for data about which systems use which format (hopefully we
 816   ;; will be able to simplify the code if/when some of those formats aren't
 817   ;; used any more).
 818   (let (table)
 819     (while (search-forward-regexp "^\\([^ \t,\n]+\\)\\(.*?\\)\
 820 \\(?:[ \t]\\(([^ \t,\n]+?)\\)\\)?\\(?:[ \t]+- ?\\(.*\\)\\)?$" nil t)
 821       (let ((section (match-string 3))
 822             (description (match-string 4))
 823             (bound (match-end 2)))
 824         (goto-char (match-end 1))
 825         (while
 826             (progn
 827               ;; The first regexp grouping may already match the section
 828               ;; tacked on to the name, which is ok since for the formats we
 829               ;; claim to support the third (non-shy) grouping does not
 830               ;; match in this case, i.e., section is nil.
 831               (push (propertize (concat (match-string 1) section)
 832                                 'help-echo description)
 833                     table)
 834               (search-forward-regexp "\\=, *\\([^ \t,]+\\)" bound t)))))
 835     (nreverse table)))
 836
 837 (defun Man-completion-table (string pred action)
 838   (cond
 839    ;; This ends up returning t for pretty much any string, and hence leads to
 840    ;; spurious "complete but not unique" messages.  And since `man' doesn't
 841    ;; require-match anyway, there's not point being clever.
 842    ;;((eq action 'lambda) (not (string-match "([^)]*\\'" string)))
 843    ((equal string "-k")
 844     ;; Let SPC (minibuffer-complete-word) insert the space.
 845     (complete-with-action action '("-k ") string pred))
 846    (t
 847     (let ((table (cdr Man-completion-cache))
 848           (section nil)
 849           (prefix string))
 850       (when (string-match "\\`\\([[:digit:]].*?\\) " string)
 851         (setq section (match-string 1 string))
 852         (setq prefix (substring string (match-end 0))))
 853       (unless (and Man-completion-cache
 854                    (string-prefix-p (car Man-completion-cache) prefix))
 855         (with-temp-buffer
 856           (setq default-directory "/") ;; in case inherited doesn't exist
 857           ;; Actually for my `man' the arg is a regexp.
 858           ;; POSIX says it must be ERE and "man-db" seems to agree,
 859           ;; whereas under MacOSX it seems to be BRE-style and doesn't
 860           ;; accept backslashes at all.  Let's not bother to
 861           ;; quote anything.
 862           (let ((process-environment (copy-sequence process-environment)))
 863             (setenv "COLUMNS" "999") ;; don't truncate long names
 864             ;; manual-program might not even exist.  And since it's
 865             ;; run differently in Man-getpage-in-background, an error
 866             ;; here may not necessarily mean that we'll also get an
 867             ;; error later.
 868             (ignore-errors
 869               (call-process manual-program nil '(t nil) nil
 870                             "-k" (concat (when (or Man-man-k-use-anchor
 871                                                    (string-equal prefix ""))
 872                                            "^")
 873                                          prefix))))
 874           (setq table (Man-parse-man-k)))
 875         ;; Cache the table for later reuse.
 876         (setq Man-completion-cache (cons prefix table)))
 877       ;; The table may contain false positives since the match is made
 878       ;; by "man -k" not just on the manpage's name.
 879       (if section
 880           (let ((re (concat "(" (regexp-quote section) ")\\'")))
 881             (dolist (comp (prog1 table (setq table nil)))
 882               (if (string-match re comp)
 883                   (push (substring comp 0 (match-beginning 0)) table)))
 884             (completion-table-with-context (concat section " ") table
 885                                            prefix pred action))
 886         ;; If the current text looks like a possible section name,
 887         ;; then add a completion entry that just adds a space so SPC
 888         ;; can be used to insert a space.
 889         (if (string-match "\\`[[:digit:]]" string)
 890             (push (concat string " ") table))
 891         (let ((res (complete-with-action action table string pred)))
 892           ;; In case we're completing to a single name that exists in
 893           ;; several sections, the longest prefix will look like "foo(".
 894           (if (and (stringp res)
 895                    (string-match "([^(]*\\'" res)
 896                    ;; In case the paren was already in `prefix', don't
 897                    ;; remove it.
 898                    (> (match-beginning 0) (length prefix)))
 899               (substring res 0 (match-beginning 0))
 900             res)))))))
 901
 902 ;;;###autoload
 903 (defun man (man-args)
 904   "Get a Un*x manual page and put it in a buffer.
 905 This command is the top-level command in the man package.  It
 906 runs a Un*x command to retrieve and clean a manpage in the
 907 background and places the results in a `Man-mode' browsing
 908 buffer.  See variable `Man-notify-method' for what happens when
 909 the buffer is ready.  If a buffer already exists for this man
 910 page, it will display immediately.
 911
 912 For a manpage from a particular section, use either of the
 913 following.  \"cat(1)\" is how cross-references appear and is
 914 passed to man as \"1 cat\".
 915
 916     cat(1)
 917     1 cat
 918
 919 To see manpages from all sections related to a subject, use an
 920 \"all pages\" option (which might be \"-a\" if it's not the
 921 default), then step through with `Man-next-manpage' (\\<Man-mode-map>\\[Man-next-manpage]) etc.
 922 Add to `Man-switches' to make this option permanent.
 923
 924     -a chmod
 925
 926 An explicit filename can be given too.  Use -l if it might
 927 otherwise look like a page name.
 928
 929     /my/file/name.1.gz
 930     -l somefile.1
 931
 932 An \"apropos\" query with -k gives a buffer of matching page
 933 names or descriptions.  The pattern argument is usually an
 934 \"egrep\" style regexp.
 935
 936     -k pattern"
 937
 938   (interactive
 939    (list (let* ((default-entry (Man-default-man-entry))
 940                 ;; ignore case because that's friendly for bizarre
 941                 ;; caps things like the X11 function names and because
 942                 ;; "man" itself is case-insensitive on the command line
 943                 ;; so you're accustomed not to bother about the case
 944                 ;; ("man -k" is case-insensitive similarly, so the
 945                 ;; table has everything available to complete)
 946                 (completion-ignore-case t)
 947                 Man-completion-cache    ;Don't cache across calls.
 948                 (input (completing-read
 949                         (format "Manual entry%s"
 950                                 (if (string= default-entry "")
 951                                     ": "
 952                                   (format " (default %s): " default-entry)))
 953                         'Man-completion-table
 954                         nil nil nil 'Man-topic-history default-entry)))
 955            (if (string= input "")
 956                (error "No man args given")
 957              input))))
 958
 959   ;; Possibly translate the "subject(section)" syntax into the
 960   ;; "section subject" syntax and possibly downcase the section.
 961   (setq man-args (Man-translate-references man-args))
 962
 963   (Man-getpage-in-background man-args))
 964
 965 ;;;###autoload
 966 (defun man-follow (man-args)
 967   "Get a Un*x manual page of the item under point and put it in a buffer."
 968   (interactive (list (Man-default-man-entry)))
 969   (if (or (not man-args)
 970           (string= man-args ""))
 971       (error "No item under point")
 972     (man man-args)))
 973
 974 (defun Man-getpage-in-background (topic)
 975   "Use TOPIC to build and fire off the manpage and cleaning command.
 976 Return the buffer in which the manpage will appear."
 977   (let* ((man-args topic)
 978          (bufname (concat "*Man " man-args "*"))
 979          (buffer  (get-buffer bufname)))
 980     (if buffer
 981         (Man-notify-when-ready buffer)
 982       (require 'env)
 983       (message "Invoking %s %s in the background" manual-program man-args)
 984       (setq buffer (generate-new-buffer bufname))
 985       (with-current-buffer buffer
 986         (setq buffer-undo-list t)
 987         (setq Man-original-frame (selected-frame))
 988         (setq Man-arguments man-args))
 989       (let ((process-environment (copy-sequence process-environment))
 990             ;; The following is so Awk script gets \n intact
 991             ;; But don't prevent decoding of the outside.
 992             (coding-system-for-write 'raw-text-unix)
 993             ;; We must decode the output by a coding system that the
 994             ;; system's locale suggests in multibyte mode.
 995             (coding-system-for-read
 996              (if (default-value 'enable-multibyte-characters)
 997                  locale-coding-system 'raw-text-unix))
 998             ;; Avoid possible error by using a directory that always exists.
 999             (default-directory
1000               (if (and (file-directory-p default-directory)
1001                        (not (find-file-name-handler default-directory
1002                                                     'file-directory-p)))
1003                   default-directory
1004                 "/")))
1005         ;; Prevent any attempt to use display terminal fanciness.
1006         (setenv "TERM" "dumb")
1007         ;; In Debian Woody, at least, we get overlong lines under X
1008         ;; unless COLUMNS or MANWIDTH is set.  This isn't a problem on
1009         ;; a tty.  man(1) says:
1010         ;;        MANWIDTH
1011         ;;               If $MANWIDTH is set, its value is used as the  line
1012         ;;               length  for which manual pages should be formatted.
1013         ;;               If it is not set, manual pages  will  be  formatted
1014         ;;               with  a line length appropriate to the current ter-
1015         ;;               minal (using an ioctl(2) if available, the value of
1016         ;;               $COLUMNS,  or falling back to 80 characters if nei-
1017         ;;               ther is available).
1018         (when (or window-system
1019                   (not (or (getenv "MANWIDTH") (getenv "COLUMNS"))))
1020           ;; This isn't strictly correct, since we don't know how
1021           ;; the page will actually be displayed, but it seems
1022           ;; reasonable.
1023           (setenv "COLUMNS" (number-to-string
1024                              (cond
1025                               ((and (integerp Man-width) (> Man-width 0))
1026                                Man-width)
1027                               (Man-width (frame-width))
1028                               ((window-width))))))
1029         ;; Since man-db 2.4.3-1, man writes plain text with no escape
1030         ;; sequences when stdout is not a tty.  In 2.5.0, the following
1031         ;; env-var was added to allow control of this (see Debian Bug#340673).
1032         (setenv "MAN_KEEP_FORMATTING" "1")
1033         (if (fboundp 'start-process)
1034             (set-process-sentinel
1035              (start-process manual-program buffer
1036                             (if (memq system-type '(cygwin windows-nt))
1037                                 shell-file-name
1038                               "sh")
1039                             shell-command-switch
1040                             (format (Man-build-man-command) man-args))
1041              'Man-bgproc-sentinel)
1042           (let ((exit-status
1043                  (call-process shell-file-name nil (list buffer nil) nil
1044                                shell-command-switch
1045                                (format (Man-build-man-command) man-args)))
1046                 (msg ""))
1047             (or (and (numberp exit-status)
1048                      (= exit-status 0))
1049                 (and (numberp exit-status)
1050                      (setq msg
1051                            (format "exited abnormally with code %d"
1052                                    exit-status)))
1053                 (setq msg exit-status))
1054             (Man-bgproc-sentinel bufname msg)))))
1055     buffer))
1056
1057 (defun Man-notify-when-ready (man-buffer)
1058   "Notify the user when MAN-BUFFER is ready.
1059 See the variable `Man-notify-method' for the different notification behaviors."
1060   (let ((saved-frame (with-current-buffer man-buffer
1061                        Man-original-frame)))
1062     (pcase Man-notify-method
1063       (`newframe
1064        ;; Since we run asynchronously, perhaps while Emacs is waiting
1065        ;; for input, we must not leave a different buffer current.  We
1066        ;; can't rely on the editor command loop to reselect the
1067        ;; selected window's buffer.
1068        (save-excursion
1069          (let ((frame (make-frame Man-frame-parameters)))
1070            (set-window-buffer (frame-selected-window frame) man-buffer)
1071            (set-window-dedicated-p (frame-selected-window frame) t)
1072            (or (display-multi-frame-p frame)
1073                (select-frame frame)))))
1074       (`pushy
1075        (switch-to-buffer man-buffer))
1076       (`bully
1077        (and (frame-live-p saved-frame)
1078             (select-frame saved-frame))
1079        (pop-to-buffer man-buffer)
1080        (delete-other-windows))
1081       (`aggressive
1082        (and (frame-live-p saved-frame)
1083             (select-frame saved-frame))
1084        (pop-to-buffer man-buffer))
1085       (`friendly
1086        (and (frame-live-p saved-frame)
1087             (select-frame saved-frame))
1088        (display-buffer man-buffer 'not-this-window))
1089       (`polite
1090        (beep)
1091        (message "Manual buffer %s is ready" (buffer-name man-buffer)))
1092       (`quiet
1093        (message "Manual buffer %s is ready" (buffer-name man-buffer)))
1094       (_ ;; meek
1095        (message ""))
1096       )))
1097
1098 (defun Man-softhyphen-to-minus ()
1099   ;; \255 is SOFT HYPHEN in Latin-N.  Versions of Debian man, at
1100   ;; least, emit it even when not in a Latin-N locale.
1101   (unless (eq t (compare-strings "latin-" 0 nil
1102                                  current-language-environment 0 6 t))
1103     (goto-char (point-min))
1104     (let ((str "\255"))
1105       (if enable-multibyte-characters
1106           (setq str (string-as-multibyte str)))
1107       (while (search-forward str nil t) (replace-match "-")))))
1108
1109 (defun Man-fontify-manpage ()
1110   "Convert overstriking and underlining to the correct fonts.
1111 Same for the ANSI bold and normal escape sequences."
1112   (interactive)
1113   (message "Please wait: formatting the %s man page..." Man-arguments)
1114   (goto-char (point-min))
1115   ;; Fontify ANSI escapes.
1116   (let ((ansi-color-apply-face-function
1117          (lambda (beg end face)
1118            (when face
1119              (put-text-property beg end 'face face))))
1120         (ansi-color-map Man-ansi-color-map))
1121     (ansi-color-apply-on-region (point-min) (point-max)))
1122   ;; Other highlighting.
1123   (let ((buffer-undo-list t))
1124     (if (< (buffer-size) (position-bytes (point-max)))
1125         ;; Multibyte characters exist.
1126         (progn
1127           (goto-char (point-min))
1128           (while (search-forward "__\b\b" nil t)
1129             (backward-delete-char 4)
1130             (put-text-property (point) (1+ (point)) 'face 'Man-underline))
1131           (goto-char (point-min))
1132           (while (search-forward "\b\b__" nil t)
1133             (backward-delete-char 4)
1134             (put-text-property (1- (point)) (point) 'face 'Man-underline))))
1135     (goto-char (point-min))
1136     (while (search-forward "_\b" nil t)
1137       (backward-delete-char 2)
1138       (put-text-property (point) (1+ (point)) 'face 'Man-underline))
1139     (goto-char (point-min))
1140     (while (search-forward "\b_" nil t)
1141       (backward-delete-char 2)
1142       (put-text-property (1- (point)) (point) 'face 'Man-underline))
1143     (goto-char (point-min))
1144     (while (re-search-forward "\\(.\\)\\(\b+\\1\\)+" nil t)
1145       (replace-match "\\1")
1146       (put-text-property (1- (point)) (point) 'face 'Man-overstrike))
1147     (goto-char (point-min))
1148     (while (re-search-forward "o\b\\+\\|\\+\bo" nil t)
1149       (replace-match "o")
1150       (put-text-property (1- (point)) (point) 'face 'bold))
1151     (goto-char (point-min))
1152     (while (re-search-forward "[-|]\\(\b[-|]\\)+" nil t)
1153       (replace-match "+")
1154       (put-text-property (1- (point)) (point) 'face 'bold))
1155     ;; When the header is longer than the manpage name, groff tries to
1156     ;; condense it to a shorter line interspersed with ^H.  Remove ^H with
1157     ;; their preceding chars (but don't put Man-overstrike).  (Bug#5566)
1158     (goto-char (point-min))
1159     (while (re-search-forward ".\b" nil t) (backward-delete-char 2))
1160     (goto-char (point-min))
1161     ;; Try to recognize common forms of cross references.
1162     (Man-highlight-references)
1163     (Man-softhyphen-to-minus)
1164     (goto-char (point-min))
1165     (while (re-search-forward Man-heading-regexp nil t)
1166       (put-text-property (match-beginning 0)
1167                          (match-end 0)
1168                          'face 'Man-overstrike)))
1169   (message "%s man page formatted" (Man-page-from-arguments Man-arguments)))
1170
1171 (defun Man-highlight-references (&optional xref-man-type)
1172   "Highlight the references on mouse-over.
1173 References include items in the SEE ALSO section,
1174 header file (#include <foo.h>), and files in FILES.
1175 If optional argument XREF-MAN-TYPE is non-nil, it used as the
1176 button type for items in SEE ALSO section.  If it is nil, the
1177 default type, `Man-xref-man-page' is used for the buttons."
1178   ;; `Man-highlight-references' is used from woman.el, too.
1179   ;; woman.el doesn't set `Man-arguments'.
1180   (unless Man-arguments
1181     (setq Man-arguments ""))
1182   (if (string-match "-k " Man-arguments)
1183       (progn
1184         (Man-highlight-references0 nil Man-reference-regexp 1
1185                                    'Man-default-man-entry
1186                                    (or xref-man-type 'Man-xref-man-page))
1187         (Man-highlight-references0 nil Man-apropos-regexp 1
1188                                    'Man-default-man-entry
1189                                    (or xref-man-type 'Man-xref-man-page)))
1190     (Man-highlight-references0 Man-see-also-regexp Man-reference-regexp 1
1191                                'Man-default-man-entry
1192                                (or xref-man-type 'Man-xref-man-page))
1193     (Man-highlight-references0 Man-synopsis-regexp Man-header-regexp 0 2
1194                                'Man-xref-header-file)
1195     (Man-highlight-references0 Man-files-regexp Man-normal-file-regexp 0 0
1196                                'Man-xref-normal-file)))
1197
1198 (defun Man-highlight-references0 (start-section regexp button-pos target type)
1199   ;; Based on `Man-build-references-alist'
1200   (when (or (null start-section)
1201             (Man-find-section start-section))
1202     (let ((end (if start-section
1203                    (progn
1204                      (forward-line 1)
1205                      (back-to-indentation)
1206                      (save-excursion
1207                        (Man-next-section 1)
1208                        (point)))
1209                  (goto-char (point-min))
1210                  nil)))
1211       (while (re-search-forward regexp end t)
1212         ;; An overlay button is preferable because the underlying text
1213         ;; may have text property highlights (Bug#7881).
1214         (make-button
1215          (match-beginning button-pos)
1216          (match-end button-pos)
1217          'type type
1218          'Man-target-string (cond
1219                              ((numberp target)
1220                               (match-string target))
1221                              ((functionp target)
1222                               target)
1223                              (t nil)))))))
1224
1225 (defun Man-cleanup-manpage (&optional interactive)
1226   "Remove overstriking and underlining from the current buffer.
1227 Normally skip any jobs that should have been done by the sed script,
1228 but when called interactively, do those jobs even if the sed
1229 script would have done them."
1230   (interactive "p")
1231   (message "Please wait: cleaning up the %s man page..."
1232            Man-arguments)
1233   (if (or interactive (not Man-sed-script))
1234       (progn
1235         (goto-char (point-min))
1236         (while (search-forward "_\b" nil t) (backward-delete-char 2))
1237         (goto-char (point-min))
1238         (while (search-forward "\b_" nil t) (backward-delete-char 2))
1239         (goto-char (point-min))
1240         (while (re-search-forward "\\(.\\)\\(\b\\1\\)+" nil t)
1241           (replace-match "\\1"))
1242         (goto-char (point-min))
1243         (while (re-search-forward "\e\\[[0-9]+m" nil t) (replace-match ""))
1244         (goto-char (point-min))
1245         (while (re-search-forward "o\b\\+\\|\\+\bo" nil t) (replace-match "o"))
1246         ))
1247   (goto-char (point-min))
1248   (while (re-search-forward "[-|]\\(\b[-|]\\)+" nil t) (replace-match "+"))
1249   ;; When the header is longer than the manpage name, groff tries to
1250   ;; condense it to a shorter line interspersed with ^H.  Remove ^H with
1251   ;; their preceding chars (but don't put Man-overstrike).  (Bug#5566)
1252   (goto-char (point-min))
1253   (while (re-search-forward ".\b" nil t) (backward-delete-char 2))
1254   (Man-softhyphen-to-minus)
1255   (message "%s man page cleaned up" Man-arguments))
1256
1257 (defun Man-bgproc-sentinel (process msg)
1258   "Manpage background process sentinel.
1259 When manpage command is run asynchronously, PROCESS is the process
1260 object for the manpage command; when manpage command is run
1261 synchronously, PROCESS is the name of the buffer where the manpage
1262 command is run.  Second argument MSG is the exit message of the
1263 manpage command."
1264   (let ((Man-buffer (if (stringp process) (get-buffer process)
1265                       (process-buffer process)))
1266         (delete-buff nil)
1267         (err-mess nil))
1268
1269     (if (null (buffer-name Man-buffer)) ;; deleted buffer
1270         (or (stringp process)
1271             (set-process-buffer process nil))
1272
1273       (with-current-buffer Man-buffer
1274         (let ((case-fold-search nil))
1275           (goto-char (point-min))
1276           (cond ((or (looking-at "No \\(manual \\)*entry for")
1277                      (looking-at "[^\n]*: nothing appropriate$"))
1278                  (setq err-mess (buffer-substring (point)
1279                                                   (progn
1280                                                     (end-of-line) (point)))
1281                        delete-buff t))
1282
1283                 ;; "-k foo", successful exit, but no output (from man-db)
1284                 ;; ENHANCE-ME: share the check for -k with
1285                 ;; `Man-highlight-references'.  The \\s- bits here are
1286                 ;; meant to allow for multiple options with -k among them.
1287                 ((and (string-match "\\(\\`\\|\\s-\\)-k\\s-" Man-arguments)
1288                       (eq (process-status process) 'exit)
1289                       (= (process-exit-status process) 0)
1290                       (= (point-min) (point-max)))
1291                  (setq err-mess (format "%s: no matches" Man-arguments)
1292                        delete-buff t))
1293
1294                 ((or (stringp process)
1295                      (not (and (eq (process-status process) 'exit)
1296                                (= (process-exit-status process) 0))))
1297                  (or (zerop (length msg))
1298                      (progn
1299                        (setq err-mess
1300                              (concat (buffer-name Man-buffer)
1301                                      ": process "
1302                                      (let ((eos (1- (length msg))))
1303                                        (if (= (aref msg eos) ?\n)
1304                                            (substring msg 0 eos) msg))))
1305                        (goto-char (point-max))
1306                        (insert (format "\nprocess %s" msg))))
1307                  ))
1308         (if delete-buff
1309             (kill-buffer Man-buffer)
1310           (if Man-fontify-manpage-flag
1311               (Man-fontify-manpage)
1312             (Man-cleanup-manpage))
1313
1314           (run-hooks 'Man-cooked-hook)
1315           (Man-mode)
1316
1317           (if (not Man-page-list)
1318               (let ((args Man-arguments))
1319                 (kill-buffer (current-buffer))
1320                 (user-error "Can't find the %s manpage"
1321                             (Man-page-from-arguments args)))
1322             (set-buffer-modified-p nil))))
1323         ;; Restore case-fold-search before calling
1324         ;; Man-notify-when-ready because it may switch buffers.
1325
1326         (if (not delete-buff)
1327             (Man-notify-when-ready Man-buffer))
1328
1329         (if err-mess
1330             (error "%s" err-mess))
1331         ))))
1332
1333 (defun Man-page-from-arguments (args)
1334   ;; Skip arguments and only print the page name.
1335   (mapconcat
1336    'identity
1337    (delete nil
1338            (mapcar
1339             (lambda (elem)
1340               (and (not (string-match "^-" elem))
1341                    elem))
1342             (split-string args " ")))
1343    " "))
1344
1345 \f
1346 ;; ======================================================================
1347 ;; set up manual mode in buffer and build alists
1348
1349 (defvar bookmark-make-record-function)
1350
1351 (put 'Man-mode 'mode-class 'special)
1352
1353 (defun Man-mode ()
1354   "A mode for browsing Un*x manual pages.
1355
1356 The following man commands are available in the buffer.  Try
1357 \"\\[describe-key] <key> RET\" for more information:
1358
1359 \\[man]       Prompt to retrieve a new manpage.
1360 \\[Man-follow-manual-reference]       Retrieve reference in SEE ALSO section.
1361 \\[Man-next-manpage]   Jump to next manpage in circular list.
1362 \\[Man-previous-manpage]   Jump to previous manpage in circular list.
1363 \\[Man-next-section]       Jump to next manpage section.
1364 \\[Man-previous-section]       Jump to previous manpage section.
1365 \\[Man-goto-section]       Go to a manpage section.
1366 \\[Man-goto-see-also-section]       Jumps to the SEE ALSO manpage section.
1367 \\[Man-quit]       Deletes the manpage window, bury its buffer.
1368 \\[Man-kill]       Deletes the manpage window, kill its buffer.
1369 \\[describe-mode]       Prints this help text.
1370
1371 The following variables may be of some use.  Try
1372 \"\\[describe-variable] <variable-name> RET\" for more information:
1373
1374 `Man-notify-method'             What happens when manpage formatting is done.
1375 `Man-downcase-section-letters-flag' Force section letters to lower case.
1376 `Man-circular-pages-flag'       Treat multiple manpage list as circular.
1377 `Man-section-translations-alist' List of section numbers and their Un*x equiv.
1378 `Man-filter-list'               Background manpage filter command.
1379 `Man-mode-map'                  Keymap bindings for Man mode buffers.
1380 `Man-mode-hook'                 Normal hook run on entry to Man mode.
1381 `Man-section-regexp'            Regexp describing manpage section letters.
1382 `Man-heading-regexp'            Regexp describing section headers.
1383 `Man-see-also-regexp'           Regexp for SEE ALSO section (or your equiv).
1384 `Man-first-heading-regexp'      Regexp for first heading on a manpage.
1385 `Man-reference-regexp'          Regexp matching a references in SEE ALSO.
1386 `Man-switches'                  Background `man' command switches.
1387
1388 The following key bindings are currently in effect in the buffer:
1389 \\{Man-mode-map}"
1390   (interactive)
1391   (kill-all-local-variables)
1392   (setq major-mode 'Man-mode
1393         mode-name "Man"
1394         buffer-auto-save-file-name nil
1395         mode-line-buffer-identification
1396         (list (default-value 'mode-line-buffer-identification)
1397               " {" 'Man-page-mode-string "}")
1398         truncate-lines t
1399         buffer-read-only t)
1400   (buffer-disable-undo)
1401   (auto-fill-mode -1)
1402   (use-local-map Man-mode-map)
1403   (set-syntax-table man-mode-syntax-table)
1404   (setq imenu-generic-expression (list (list nil Man-heading-regexp 0)))
1405   (set (make-local-variable 'outline-regexp) Man-heading-regexp)
1406   (set (make-local-variable 'outline-level) (lambda () 1))
1407   (set (make-local-variable 'bookmark-make-record-function)
1408        'Man-bookmark-make-record)
1409   (Man-build-page-list)
1410   (Man-strip-page-headers)
1411   (Man-unindent)
1412   (Man-goto-page 1 t)
1413   (run-mode-hooks 'Man-mode-hook))
1414
1415 (defsubst Man-build-section-alist ()
1416   "Build the list of manpage sections."
1417   (setq Man--sections nil)
1418   (goto-char (point-min))
1419   (let ((case-fold-search nil))
1420     (while (re-search-forward Man-heading-regexp (point-max) t)
1421       (let ((section (match-string 1)))
1422         (unless (member section Man--sections)
1423           (push section Man--sections)))
1424       (forward-line 1))))
1425
1426 (defsubst Man-build-references-alist ()
1427   "Build the list of references (in the SEE ALSO section)."
1428   (setq Man--refpages nil)
1429   (save-excursion
1430     (if (Man-find-section Man-see-also-regexp)
1431         (let ((start (progn (forward-line 1) (point)))
1432               (end (progn
1433                      (Man-next-section 1)
1434                      (point)))
1435               hyphenated
1436               (runningpoint -1))
1437           (save-restriction
1438             (narrow-to-region start end)
1439             (goto-char (point-min))
1440             (back-to-indentation)
1441             (while (and (not (eobp)) (/= (point) runningpoint))
1442               (setq runningpoint (point))
1443               (if (re-search-forward Man-hyphenated-reference-regexp end t)
1444                   (let* ((word (match-string 0))
1445                          (len (1- (length word))))
1446                     (if hyphenated
1447                         (setq word (concat hyphenated word)
1448                               hyphenated nil
1449                               ;; Update len, in case a reference spans
1450                               ;; more than two lines (paranoia).
1451                               len (1- (length word))))
1452                     (if (memq (aref word len) '(?- ?))
1453                         (setq hyphenated (substring word 0 len)))
1454                     (and (string-match Man-reference-regexp word)
1455                          (not (member word Man--refpages))
1456                          (push word Man--refpages))))
1457               (skip-chars-forward " \t\n,"))))))
1458   (setq Man--refpages (nreverse Man--refpages)))
1459
1460 (defun Man-build-page-list ()
1461   "Build the list of separate manpages in the buffer."
1462   (setq Man-page-list nil)
1463   (let ((page-start (point-min))
1464         (page-end (point-max))
1465         (header ""))
1466     (goto-char page-start)
1467     ;; (switch-to-buffer (current-buffer))(debug)
1468     (while (not (eobp))
1469       (setq header
1470             (if (looking-at Man-page-header-regexp)
1471                 (match-string 1)
1472               nil))
1473       ;; Go past both the current and the next Man-first-heading-regexp
1474       (if (re-search-forward Man-first-heading-regexp nil 'move 2)
1475           (let ((p (progn (beginning-of-line) (point))))
1476             ;; We assume that the page header is delimited by blank
1477             ;; lines and that it contains at most one blank line.  So
1478             ;; if we back by three blank lines we will be sure to be
1479             ;; before the page header but not before the possible
1480             ;; previous page header.
1481             (search-backward "\n\n" nil t 3)
1482             (if (re-search-forward Man-page-header-regexp p 'move)
1483                 (beginning-of-line))))
1484       (setq page-end (point))
1485       (setq Man-page-list (append Man-page-list
1486                                   (list (list (copy-marker page-start)
1487                                               (copy-marker page-end)
1488                                               header))))
1489       (setq page-start page-end)
1490       )))
1491
1492 (defun Man-strip-page-headers ()
1493   "Strip all the page headers but the first from the manpage."
1494   (let ((inhibit-read-only t)
1495         (case-fold-search nil)
1496         (header ""))
1497     (dolist (page Man-page-list)
1498       (and (nth 2 page)
1499            (goto-char (car page))
1500            (re-search-forward Man-first-heading-regexp nil t)
1501            (setq header (buffer-substring (car page) (match-beginning 0)))
1502            ;; Since the awk script collapses all successive blank
1503            ;; lines into one, and since we don't want to get rid of
1504            ;; the fast awk script, one must choose between adding
1505            ;; spare blank lines between pages when there were none and
1506            ;; deleting blank lines at page boundaries when there were
1507            ;; some.  We choose the first, so we comment the following
1508            ;; line.
1509            ;; (setq header (concat "\n" header)))
1510            (while (search-forward header (nth 1 page) t)
1511              (replace-match ""))))))
1512
1513 (defun Man-unindent ()
1514   "Delete the leading spaces that indent the manpage."
1515   (let ((inhibit-read-only t)
1516         (case-fold-search nil))
1517     (dolist (page Man-page-list)
1518       (let ((indent "")
1519             (nindent 0))
1520         (narrow-to-region (car page) (car (cdr page)))
1521         (if Man-uses-untabify-flag
1522             ;; The space characters inserted by `untabify' inherit
1523             ;; sticky text properties, which is unnecessary and looks
1524             ;; ugly with underlining (Bug#11408).
1525             (let ((text-property-default-nonsticky
1526                    (cons '(face . t) text-property-default-nonsticky)))
1527               (untabify (point-min) (point-max))))
1528         (if (catch 'unindent
1529               (goto-char (point-min))
1530               (if (not (re-search-forward Man-first-heading-regexp nil t))
1531                   (throw 'unindent nil))
1532               (beginning-of-line)
1533               (setq indent (buffer-substring (point)
1534                                              (progn
1535                                                (skip-chars-forward " ")
1536                                                (point))))
1537               (setq nindent (length indent))
1538               (if (zerop nindent)
1539                   (throw 'unindent nil))
1540               (setq indent (concat indent "\\|$"))
1541               (goto-char (point-min))
1542               (while (not (eobp))
1543                 (if (looking-at indent)
1544                     (forward-line 1)
1545                   (throw 'unindent nil)))
1546               (goto-char (point-min)))
1547             (while (not (eobp))
1548               (or (eolp)
1549                   (delete-char nindent))
1550               (forward-line 1)))
1551         ))))
1552
1553 \f
1554 ;; ======================================================================
1555 ;; Man mode commands
1556
1557 (defun Man-next-section (n)
1558   "Move point to Nth next section (default 1)."
1559   (interactive "p")
1560   (let ((case-fold-search nil)
1561         (start (point)))
1562     (if (looking-at Man-heading-regexp)
1563         (forward-line 1))
1564     (if (re-search-forward Man-heading-regexp (point-max) t n)
1565         (beginning-of-line)
1566       (goto-char (point-max))
1567       ;; The last line doesn't belong to any section.
1568       (forward-line -1))
1569     ;; But don't move back from the starting point (can happen if `start'
1570     ;; is somewhere on the last line).
1571     (if (< (point) start) (goto-char start))))
1572
1573 (defun Man-previous-section (n)
1574   "Move point to Nth previous section (default 1)."
1575   (interactive "p")
1576   (let ((case-fold-search nil))
1577     (if (looking-at Man-heading-regexp)
1578         (forward-line -1))
1579     (if (re-search-backward Man-heading-regexp (point-min) t n)
1580         (beginning-of-line)
1581       (goto-char (point-min)))))
1582
1583 (defun Man-find-section (section)
1584   "Move point to SECTION if it exists, otherwise don't move point.
1585 Returns t if section is found, nil otherwise."
1586   (let ((curpos (point))
1587         (case-fold-search nil))
1588     (goto-char (point-min))
1589     (if (re-search-forward (concat "^" section) (point-max) t)
1590         (progn (beginning-of-line) t)
1591       (goto-char curpos)
1592       nil)
1593     ))
1594
1595 (defvar Man--last-section nil)
1596
1597 (defun Man-goto-section (section)
1598   "Move point to SECTION."
1599   (interactive
1600    (let* ((default (if (member Man--last-section Man--sections)
1601                        Man--last-section
1602                      (car Man--sections)))
1603           (completion-ignore-case t)
1604           (prompt (concat "Go to section (default " default "): "))
1605           (chosen (completing-read prompt Man--sections
1606                                    nil nil nil nil default)))
1607      (list chosen)))
1608   (setq Man--last-section section)
1609   (unless (Man-find-section section)
1610     (error "Section %s not found" section)))
1611
1612
1613 (defun Man-goto-see-also-section ()
1614   "Move point to the \"SEE ALSO\" section.
1615 Actually the section moved to is described by `Man-see-also-regexp'."
1616   (interactive)
1617   (if (not (Man-find-section Man-see-also-regexp))
1618       (error "%s" (concat "No " Man-see-also-regexp
1619                      " section found in the current manpage"))))
1620
1621 (defun Man-possibly-hyphenated-word ()
1622   "Return a possibly hyphenated word at point.
1623 If the word starts at the first non-whitespace column, and the
1624 previous line ends with a hyphen, return the last word on the previous
1625 line instead.  Thus, if a reference to \"tcgetpgrp(3V)\" is hyphenated
1626 as \"tcgetp-grp(3V)\", and point is at \"grp(3V)\", we return
1627 \"tcgetp-\" instead of \"grp\"."
1628   (save-excursion
1629     (skip-syntax-backward "w()")
1630     (skip-chars-forward " \t")
1631     (let ((beg (point))
1632           (word (current-word)))
1633       (when (eq beg (save-excursion
1634                       (back-to-indentation)
1635                       (point)))
1636         (end-of-line 0)
1637         (if (eq (char-before) ?-)
1638             (setq word (current-word))))
1639       word)))
1640
1641 (defvar Man--last-refpage nil)
1642
1643 (defun Man-follow-manual-reference (reference)
1644   "Get one of the manpages referred to in the \"SEE ALSO\" section.
1645 Specify which REFERENCE to use; default is based on word at point."
1646   (interactive
1647    (if (not Man--refpages)
1648        (error "There are no references in the current man page")
1649      (list
1650       (let* ((default (or
1651                        (car (all-completions
1652                              (let ((word
1653                                     (or (Man-possibly-hyphenated-word)
1654                                         "")))
1655                                ;; strip a trailing '-':
1656                                (if (string-match "-$" word)
1657                                    (substring word 0
1658                                               (match-beginning 0))
1659                                  word))
1660                              Man--refpages))
1661                        (if (member Man--last-refpage Man--refpages)
1662                            Man--last-refpage
1663                          (car Man--refpages))))
1664              (defaults
1665                (mapcar 'substring-no-properties
1666                        (cons default Man--refpages)))
1667              (prompt (concat "Refer to (default " default "): "))
1668              (chosen (completing-read prompt Man--refpages
1669                                       nil nil nil nil defaults)))
1670         chosen))))
1671   (if (not Man--refpages)
1672       (error "Can't find any references in the current manpage")
1673     (setq Man--last-refpage reference)
1674     (Man-getpage-in-background
1675      (Man-translate-references reference))))
1676
1677 (defun Man-kill ()
1678   "Kill the buffer containing the manpage."
1679   (interactive)
1680   (quit-window t))
1681
1682 (defun Man-quit ()
1683   "Bury the buffer containing the manpage."
1684   (interactive)
1685   (quit-window))
1686
1687 (defun Man-goto-page (page &optional noerror)
1688   "Go to the manual page on page PAGE."
1689   (interactive
1690    (if (not Man-page-list)
1691        (error "Not a man page buffer")
1692      (if (= (length Man-page-list) 1)
1693          (error "You're looking at the only manpage in the buffer")
1694        (list (read-minibuffer (format "Go to manpage [1-%d]: "
1695                                       (length Man-page-list)))))))
1696   (if (and (not Man-page-list) (not noerror))
1697       (error "Not a man page buffer"))
1698   (when Man-page-list
1699     (if (or (< page 1)
1700             (> page (length Man-page-list)))
1701         (user-error "No manpage %d found" page))
1702     (let* ((page-range (nth (1- page) Man-page-list))
1703            (page-start (car page-range))
1704            (page-end (car (cdr page-range))))
1705       (setq Man-current-page page
1706             Man-page-mode-string (Man-make-page-mode-string))
1707       (widen)
1708       (goto-char page-start)
1709       (narrow-to-region page-start page-end)
1710       (Man-build-section-alist)
1711       (Man-build-references-alist)
1712       (goto-char (point-min)))))
1713
1714
1715 (defun Man-next-manpage ()
1716   "Find the next manpage entry in the buffer."
1717   (interactive)
1718   (if (= (length Man-page-list) 1)
1719       (error "This is the only manpage in the buffer"))
1720   (if (< Man-current-page (length Man-page-list))
1721       (Man-goto-page (1+ Man-current-page))
1722     (if Man-circular-pages-flag
1723         (Man-goto-page 1)
1724       (error "You're looking at the last manpage in the buffer"))))
1725
1726 (defun Man-previous-manpage ()
1727   "Find the previous manpage entry in the buffer."
1728   (interactive)
1729   (if (= (length Man-page-list) 1)
1730       (error "This is the only manpage in the buffer"))
1731   (if (> Man-current-page 1)
1732       (Man-goto-page (1- Man-current-page))
1733     (if Man-circular-pages-flag
1734         (Man-goto-page (length Man-page-list))
1735       (error "You're looking at the first manpage in the buffer"))))
1736
1737 ;; Header file support
1738 (defun Man-view-header-file (file)
1739   "View a header file specified by FILE from `Man-header-file-path'."
1740   (let ((path Man-header-file-path)
1741         complete-path)
1742     (while path
1743       (setq complete-path (expand-file-name file (car path))
1744             path (cdr path))
1745       (if (file-readable-p complete-path)
1746           (progn (view-file complete-path)
1747                  (setq path nil))
1748         (setq complete-path nil)))
1749     complete-path))
1750
1751 ;;; Bookmark Man Support
1752 (declare-function bookmark-make-record-default
1753                   "bookmark" (&optional no-file no-context posn))
1754 (declare-function bookmark-prop-get "bookmark" (bookmark prop))
1755 (declare-function bookmark-default-handler "bookmark" (bmk))
1756 (declare-function bookmark-get-bookmark-record "bookmark" (bmk))
1757
1758 (defun Man-default-bookmark-title ()
1759   "Default bookmark name for Man or WoMan pages.
1760 Uses `Man-name-local-regexp'."
1761   (save-excursion
1762     (goto-char (point-min))
1763     (when (re-search-forward Man-name-local-regexp nil t)
1764       (skip-chars-forward "\n\t ")
1765       (buffer-substring-no-properties (point) (line-end-position)))))
1766
1767 (defun Man-bookmark-make-record ()
1768   "Make a bookmark entry for a Man buffer."
1769   `(,(Man-default-bookmark-title)
1770     ,@(bookmark-make-record-default 'no-file)
1771     (location . ,(concat "man " Man-arguments))
1772     (man-args . ,Man-arguments)
1773     (handler . Man-bookmark-jump)))
1774
1775 ;;;###autoload
1776 (defun Man-bookmark-jump (bookmark)
1777   "Default bookmark handler for Man buffers."
1778   (let* ((man-args (bookmark-prop-get bookmark 'man-args))
1779          ;; Let bookmark.el do the window handling.
1780          ;; This let-binding needs to be active during the call to both
1781          ;; Man-getpage-in-background and accept-process-output.
1782          (Man-notify-method 'meek)
1783          (buf (Man-getpage-in-background man-args))
1784          (proc (get-buffer-process buf)))
1785     (while (and proc (eq (process-status proc) 'run))
1786       (accept-process-output proc))
1787     (bookmark-default-handler
1788      `("" (buffer . ,buf) . ,(bookmark-get-bookmark-record bookmark)))))
1789
1790 \f
1791 ;; Init the man package variables, if not already done.
1792 (Man-init-defvars)
1793
1794 (provide 'man)
1795
1796 ;;; man.el ends here