code.delx.au - gnu-emacs/blob - lisp/avoid.el

   1 ;;; avoid.el --- make mouse pointer stay out of the way of editing
   2
   3 ;; Copyright (C) 1993, 1994, 2000, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Boris Goldowsky <boris@gnu.org>
   7 ;; Keywords: mouse
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; For those who are annoyed by the mouse pointer obscuring text,
  29 ;; this mode moves the mouse pointer - either just a little out of
  30 ;; the way, or all the way to the corner of the frame.
  31 ;; To use, load or evaluate this file and type M-x mouse-avoidance-mode .
  32 ;; To set up permanently, put the following in your .emacs:
  33 ;;
  34 ;; (if (display-mouse-p) (mouse-avoidance-mode 'animate))
  35 ;;
  36 ;; Other legitimate alternatives include
  37 ;; `banish', `exile', `jump', `cat-and-mouse', and `proteus'.
  38 ;; They do somewhat different things.
  39 ;; See the documentation for function `mouse-avoidance-mode' for
  40 ;; details of the different modes.
  41 ;;
  42 ;; For added silliness, make the animatee animate...
  43 ;; put something similar to the following into your .emacs:
  44 ;;
  45 ;; (if (eq window-system 'x)
  46 ;;     (mouse-avoidance-set-pointer-shape
  47 ;;           (eval (nth (random 4)
  48 ;;                      '(x-pointer-man x-pointer-spider
  49 ;;                        x-pointer-gobbler x-pointer-gumby)))))
  50 ;;
  51 ;; For completely random pointer shape, replace the setq above with:
  52 ;; (setq x-pointer-shape (mouse-avoidance-random-shape))
  53 ;;
  54 ;; Bugs / Warnings / To-Do:
  55 ;;
  56 ;; - Using this code does slow Emacs down.  "banish" mode shouldn't
  57 ;;   be too bad, and on my workstation even "animate" is reasonable.
  58 ;;
  59 ;; - It ought to find out where any overlapping frames are and avoid them,
  60 ;;   rather than always raising the frame.
  61
  62 ;; Credits:
  63 ;; This code was helped by all those who contributed suggestions,
  64 ;;   fixes, and additions
  65 ;; Joe Harrington (and his advisor), for the original inspiration.
  66 ;; Ken Manheimer, for dreaming up the Protean mode.
  67 ;; Richard Stallman, for the awful cat-and-mouse pun, among other things.
  68 ;; Mike Williams, Denis Howe, Bill Benedetto, Chris Moore, Don Morris,
  69 ;; Simon Marshall, and M.S. Ashton, for their feedback.
  70
  71 ;;; Code:
  72
  73 (provide 'avoid)
  74
  75 (defgroup avoid nil
  76   "Make mouse pointer stay out of the way of editing."
  77   :prefix "mouse-avoidance-"
  78   :group 'mouse)
  79
  80 ;;;###autoload
  81 (defcustom mouse-avoidance-mode nil
  82   "Activate mouse avoidance mode.
  83 See function `mouse-avoidance-mode' for possible values.
  84 Setting this variable directly does not take effect;
  85 use either \\[customize] or the function `mouse-avoidance-mode'."
  86   :set (lambda (symbol value)
  87          ;; 'none below prevents toggling when value is nil.
  88          (mouse-avoidance-mode (or value 'none)))
  89   :initialize 'custom-initialize-default
  90   :type '(choice (const :tag "none" nil) (const banish) (const jump)
  91                  (const animate) (const exile) (const proteus)
  92                  )
  93   :group 'avoid
  94   :require 'avoid
  95   :version "20.3")
  96
  97
  98 (defcustom mouse-avoidance-nudge-dist 15
  99   "*Average distance that mouse will be moved when approached by cursor.
 100 Only applies in Mouse-Avoidance mode `jump' and its derivatives.
 101 For best results make this larger than `mouse-avoidance-threshold'."
 102   :type 'integer
 103   :group 'avoid)
 104
 105 (defcustom mouse-avoidance-nudge-var 10
 106   "*Variability of `mouse-avoidance-nudge-dist' (which see)."
 107   :type 'integer
 108   :group 'avoid)
 109
 110 (defcustom mouse-avoidance-animation-delay .01
 111   "Delay between animation steps, in seconds."
 112   :type 'number
 113   :group 'avoid)
 114
 115 (defcustom mouse-avoidance-threshold 5
 116   "*Mouse-pointer's flight distance.
 117 If the cursor gets closer than this, the mouse pointer will move away.
 118 Only applies in mouse-avoidance-modes `animate' and `jump'."
 119   :type 'integer
 120   :group 'avoid)
 121
 122 ;; Internal variables
 123 (defvar mouse-avoidance-state nil)
 124 (defvar mouse-avoidance-pointer-shapes nil)
 125 (defvar mouse-avoidance-n-pointer-shapes 0)
 126 (defvar mouse-avoidance-old-pointer-shape nil)
 127 (defvar mouse-avoidance-animating-pointer nil)
 128
 129 ;; This timer is used to run something when Emacs is idle.
 130 (defvar mouse-avoidance-timer nil)
 131
 132 ;;; Functions:
 133
 134 (defsubst mouse-avoidance-set-pointer-shape (shape)
 135   "Set the shape of the mouse pointer to SHAPE."
 136   (when (boundp 'x-pointer-shape)
 137     (setq x-pointer-shape shape)
 138     (set-mouse-color nil)))
 139
 140 (defun mouse-avoidance-point-position ()
 141   "Return the position of point as (FRAME X . Y).
 142 Analogous to `mouse-position'."
 143   (let ((edges (window-inside-edges))
 144         (x-y (posn-x-y (posn-at-point))))
 145     (cons (selected-frame)
 146           (cons (+ (car edges)
 147                    (/ (car x-y) (frame-char-width)))
 148                 (+ (car (cdr edges))
 149                    (/ (cdr x-y) (frame-char-height)))))))
 150
 151 ;(defun mouse-avoidance-point-position-test ()
 152 ;  (interactive)
 153 ;  (message (format "point=%s mouse=%s"
 154 ;                  (cdr (mouse-avoidance-point-position))
 155 ;                  (cdr (mouse-position)))))
 156
 157 (defun mouse-avoidance-set-mouse-position (pos)
 158   ;; Carefully set mouse position to given position (X . Y)
 159   ;; Ideally, should check if X,Y is in the current frame, and if not,
 160   ;; leave the mouse where it was.  However, this is currently
 161   ;; difficult to do, so we just raise the frame to avoid frame switches.
 162   ;; Returns t if it moved the mouse.
 163   (let ((f (selected-frame)))
 164     (raise-frame f)
 165     (set-mouse-position f (car pos) (cdr pos))
 166     t))
 167
 168 (defun mouse-avoidance-too-close-p (mouse)
 169   "Return t if mouse pointer and point cursor are too close.
 170 MOUSE is the current mouse position as returned by `mouse-position'.
 171 Acceptable distance is defined by `mouse-avoidance-threshold'."
 172   (let* ((frame (car mouse))
 173          (mouse-y (cdr (cdr mouse)))
 174          (tool-bar-lines (frame-parameter nil 'tool-bar-lines)))
 175     (or tool-bar-lines
 176         (setq tool-bar-lines 0))
 177     (if (and mouse-y (< mouse-y tool-bar-lines))
 178         nil
 179       (let ((point (mouse-avoidance-point-position))
 180             (mouse-x (car (cdr mouse))))
 181         (and (eq frame (car point))
 182              (not (null mouse-x))
 183              (< (abs (- mouse-x (car (cdr point))))
 184                 mouse-avoidance-threshold)
 185              (< (abs (- mouse-y (cdr (cdr point))))
 186                 mouse-avoidance-threshold))))))
 187
 188 (defun mouse-avoidance-banish-destination ()
 189   "The position to which Mouse-Avoidance mode `banish' moves the mouse.
 190 You can redefine this if you want the mouse banished to a different corner."
 191   (let* ((pos (window-edges)))
 192     (cons (- (nth 2 pos) 2)
 193           (nth 1 pos))))
 194
 195 (defun mouse-avoidance-banish-mouse ()
 196   ;; Put the mouse pointer in the upper-right corner of the current frame.
 197   (mouse-avoidance-set-mouse-position (mouse-avoidance-banish-destination)))
 198
 199 (defsubst mouse-avoidance-delta (cur delta dist var min max)
 200   ;; Decide how far to move in either dimension.
 201   ;; Args are the CURRENT location, the desired DELTA for
 202   ;; warp-conservation, the DISTANCE we like to move, the VARIABILITY
 203   ;; in distance allowed, and the MIN and MAX possible window positions.
 204   ;; Returns something as close to DELTA as possible within the constraints.
 205   (let ((L1 (max (- min cur) (+ (- dist) (- var))))
 206         (R1                  (+ (- dist)    var ))
 207         (L2                  (+    dist  (- var)))
 208         (R2 (min (- max cur) (+    dist     var))))
 209     (if (< R1 (- min cur)) (setq L1 nil R1 nil))
 210     (if (> L2 (- max cur)) (setq L2 nil R2 nil))
 211     (cond ((and L1 (< delta L1)) L1)
 212           ((and R1 (< delta R1)) delta)
 213           ((and R1 (< delta 0)) R1)
 214           ((and L2 (< delta L2)) L2)
 215           ((and R2 (< delta R2)) delta)
 216           (R2)
 217           ((or R1 L2))
 218           (t 0))))
 219
 220 (defun mouse-avoidance-nudge-mouse ()
 221   ;; Push the mouse a little way away, possibly animating the move.
 222   ;; For these modes, state keeps track of the total offset that we've
 223   ;; accumulated, and tries to keep it close to zero.
 224   (let* ((cur (mouse-position))
 225          (cur-frame (car cur))
 226          (cur-pos (cdr cur))
 227          (pos (window-edges))
 228          (wleft (pop pos))
 229          (wtop (pop pos))
 230          (wright (pop pos))
 231          (wbot (pop pos))
 232          (deltax (mouse-avoidance-delta
 233                   (car cur-pos) (- (random mouse-avoidance-nudge-var)
 234                                    (car mouse-avoidance-state))
 235                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 236                   wleft (1- wright)))
 237          (deltay (mouse-avoidance-delta
 238                   (cdr cur-pos) (- (random mouse-avoidance-nudge-var)
 239                                    (cdr mouse-avoidance-state))
 240                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 241                   wtop (1- wbot))))
 242     (setq mouse-avoidance-state
 243           (cons (+ (car mouse-avoidance-state) deltax)
 244                 (+ (cdr mouse-avoidance-state) deltay)))
 245     (if (or (eq mouse-avoidance-mode 'animate)
 246             (eq mouse-avoidance-mode 'proteus))
 247         (let ((i 0.0)
 248               (incr (max .1 (/ 1.0 mouse-avoidance-nudge-dist))))
 249           (setq mouse-avoidance-animating-pointer t)
 250           (while (<= i 1)
 251             (mouse-avoidance-set-mouse-position
 252              (cons (+ (car cur-pos) (round (* i deltax)))
 253                    (+ (cdr cur-pos) (round (* i deltay)))))
 254             (setq i (+ i incr))
 255             (if (eq mouse-avoidance-mode 'proteus)
 256                 (mouse-avoidance-set-pointer-shape
 257                  (mouse-avoidance-random-shape)))
 258             (sit-for mouse-avoidance-animation-delay))
 259           (setq mouse-avoidance-animating-pointer nil))
 260       (mouse-avoidance-set-mouse-position (cons (+ (car (cdr cur)) deltax)
 261                                                 (+ (cdr (cdr cur)) deltay))))))
 262
 263 (defun mouse-avoidance-random-shape ()
 264   "Return a random cursor shape.
 265 This assumes that any variable whose name begins with x-pointer- and
 266 has an integer value is a valid cursor shape.  You might want to
 267 redefine this function to suit your own tastes."
 268   (if (null mouse-avoidance-pointer-shapes)
 269       (progn
 270         (setq mouse-avoidance-pointer-shapes
 271               (mapcar (lambda (x) (symbol-value (intern x)))
 272                       (all-completions "x-pointer-" obarray
 273                                        (lambda (x)
 274                                           (and (boundp x)
 275                                                (integerp (symbol-value x)))))))
 276         (setq mouse-avoidance-n-pointer-shapes
 277               (length mouse-avoidance-pointer-shapes))))
 278   (nth (random mouse-avoidance-n-pointer-shapes)
 279        mouse-avoidance-pointer-shapes))
 280
 281 (defun mouse-avoidance-ignore-p ()
 282   (let ((mp (mouse-position)))
 283     (or executing-kbd-macro            ; don't check inside macro
 284         (null (cadr mp))               ; don't move unless in an Emacs frame
 285         (not (eq (car mp) (selected-frame)))
 286         ;; Don't do anything if last event was a mouse event.
 287         ;; FIXME: this code fails in the case where the mouse was moved
 288         ;; since the last key-press but without generating any event.
 289         (and (consp last-input-event)
 290              (symbolp (car last-input-event))
 291              (let ((modifiers (event-modifiers (car last-input-event))))
 292                (or (memq (car last-input-event)
 293                          '(mouse-movement scroll-bar-movement
 294                            select-window switch-frame))
 295                    (memq 'click modifiers)
 296                    (memq 'double modifiers)
 297                    (memq 'triple modifiers)
 298                    (memq 'drag modifiers)
 299                    (memq 'down modifiers)))))))
 300
 301 (defun mouse-avoidance-banish ()
 302   (if (not (mouse-avoidance-ignore-p))
 303       (mouse-avoidance-banish-mouse)))
 304
 305 (defun mouse-avoidance-exile ()
 306   ;; For exile mode, the state is nil when the mouse is in its normal
 307   ;; position, and set to the old mouse-position when the mouse is in exile.
 308   (if (not (mouse-avoidance-ignore-p))
 309       (let ((mp (mouse-position)))
 310         (cond ((and (not mouse-avoidance-state)
 311                     (mouse-avoidance-too-close-p mp))
 312                (setq mouse-avoidance-state mp)
 313                (mouse-avoidance-banish-mouse))
 314               ((and mouse-avoidance-state
 315                     (not (mouse-avoidance-too-close-p mouse-avoidance-state)))
 316                (if (and (eq (car mp) (selected-frame))
 317                         (equal (cdr mp) (mouse-avoidance-banish-destination)))
 318                    (mouse-avoidance-set-mouse-position
 319                     ;; move back only if user has not moved mouse
 320                     (cdr mouse-avoidance-state)))
 321                ;; but clear state anyway, to be ready for another move
 322                (setq mouse-avoidance-state nil))))))
 323
 324 (defun mouse-avoidance-fancy ()
 325   ;; Used for the "fancy" modes, ie jump et al.
 326   (if (and (not mouse-avoidance-animating-pointer)
 327            (not (mouse-avoidance-ignore-p))
 328            (mouse-avoidance-too-close-p (mouse-position)))
 329       (let ((old-pos (mouse-position)))
 330         (mouse-avoidance-nudge-mouse)
 331         (if (not (eq (selected-frame) (car old-pos)))
 332             ;; This should never happen.
 333             (apply 'set-mouse-position old-pos)))))
 334
 335 ;;;###autoload
 336 (defun mouse-avoidance-mode (&optional mode)
 337   "Set cursor avoidance mode to MODE.
 338 MODE should be one of the symbols `banish', `exile', `jump', `animate',
 339 `cat-and-mouse', `proteus', or `none'.
 340
 341 If MODE is nil, toggle mouse avoidance between `none' and `banish'
 342 modes.  Positive numbers and symbols other than the above are treated
 343 as equivalent to `banish'; negative numbers and `-' are equivalent to `none'.
 344
 345 Effects of the different modes:
 346  * banish: Move the mouse to the upper-right corner on any keypress.
 347  * exile: Move the mouse to the corner only if the cursor gets too close,
 348      and allow it to return once the cursor is out of the way.
 349  * jump: If the cursor gets too close to the mouse, displace the mouse
 350      a random distance & direction.
 351  * animate: As `jump', but shows steps along the way for illusion of motion.
 352  * cat-and-mouse: Same as `animate'.
 353  * proteus: As `animate', but changes the shape of the mouse pointer too.
 354
 355 Whenever the mouse is moved, the frame is also raised.
 356
 357 \(see `mouse-avoidance-threshold' for definition of \"too close\",
 358 and `mouse-avoidance-nudge-dist' and `mouse-avoidance-nudge-var' for
 359 definition of \"random distance\".)"
 360   (interactive
 361    (list (intern (completing-read
 362                   "Select cursor avoidance technique (SPACE for list): "
 363                   '(("banish") ("exile") ("jump") ("animate")
 364                     ("cat-and-mouse") ("proteus") ("none"))
 365                   nil t))))
 366   (if (eq mode 'cat-and-mouse)
 367       (setq mode 'animate))
 368   (if mouse-avoidance-timer
 369       (cancel-timer mouse-avoidance-timer))
 370   (setq mouse-avoidance-timer nil)
 371
 372   ;; Restore pointer shape if necessary
 373   (if (eq mouse-avoidance-mode 'proteus)
 374       (mouse-avoidance-set-pointer-shape mouse-avoidance-old-pointer-shape))
 375
 376   ;; Do additional setup depending on version of mode requested
 377   (cond ((eq mode 'none)
 378          (setq mouse-avoidance-mode nil))
 379         ((or (eq mode 'jump)
 380              (eq mode 'animate)
 381              (eq mode 'proteus))
 382          (setq mouse-avoidance-timer
 383                (run-with-idle-timer 0.1 t 'mouse-avoidance-fancy))
 384          (setq mouse-avoidance-mode mode
 385                mouse-avoidance-state (cons 0 0)
 386                mouse-avoidance-old-pointer-shape
 387                (and (boundp 'x-pointer-shape) x-pointer-shape)))
 388         ((eq mode 'exile)
 389          (setq mouse-avoidance-timer
 390                (run-with-idle-timer 0.1 t 'mouse-avoidance-exile))
 391          (setq mouse-avoidance-mode mode
 392                mouse-avoidance-state nil))
 393         ((or (eq mode 'banish)
 394              (eq mode t)
 395              (and (null mode) (null mouse-avoidance-mode))
 396              (and mode (> (prefix-numeric-value mode) 0)))
 397          (setq mouse-avoidance-timer
 398                (run-with-idle-timer 0.1 t 'mouse-avoidance-banish))
 399          (setq mouse-avoidance-mode 'banish))
 400         (t (setq mouse-avoidance-mode nil)))
 401   (force-mode-line-update))
 402
 403 ;; Most people who use avoid mode leave it on all the time, so it's not
 404 ;; very informative to announce it in the mode line.
 405 ;;(or (assq 'mouse-avoidance-mode minor-mode-alist)
 406 ;;    (setq minor-mode-alist (cons '(mouse-avoidance-mode " Avoid")
 407 ;;                               minor-mode-alist)))
 408
 409 ;; Needed for custom.
 410 (if mouse-avoidance-mode
 411     (mouse-avoidance-mode mouse-avoidance-mode))
 412
 413 ;; arch-tag: 64ad4ef8-a870-4183-8d96-3aa93b7a6800
 414 ;;; avoid.el ends here