code.delx.au - gnu-emacs/blob - lisp/loadhist.el

   1 ;;; loadhist.el --- lisp functions for working with feature groups
   2
   3 ;; Copyright (C) 1995, 1998, 2000, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Eric S. Raymond <esr@snark.thyrsus.com>
   7 ;; Maintainer: FSF
   8 ;; Keywords: internal
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; These functions exploit the load-history system variable.
  30 ;; Entry points include `unload-feature', `symbol-file', and
  31 ;; `feature-file', documented in the Emacs Lisp manual.
  32
  33 ;;; Code:
  34
  35 (eval-when-compile (require 'cl))
  36
  37 (defun feature-symbols (feature)
  38   "Return the file and list of definitions associated with FEATURE.
  39 The value is actually the element of `load-history'
  40 for the file that did (provide FEATURE)."
  41    (catch 'foundit
  42      (mapc (lambda (x)
  43              (if (member (cons 'provide feature) (cdr x))
  44                  (throw 'foundit x)))
  45            load-history)
  46      nil))
  47
  48 (defun feature-file (feature)
  49   "Return the file name from which a given FEATURE was loaded.
  50 Actually, return the load argument, if any; this is sometimes the name of a
  51 Lisp file without an extension.  If the feature came from an `eval-buffer' on
  52 a buffer with no associated file, or an `eval-region', return nil."
  53   (if (not (featurep feature))
  54       (error "%S is not a currently loaded feature" feature)
  55     (car (feature-symbols feature))))
  56
  57 (defun file-loadhist-lookup (file)
  58   "Return the `load-history' element for FILE.
  59 FILE can be a file name, or a library name.
  60 A library name is equivalent to the file name that `load-library' would load."
  61   ;; First look for FILE as given.
  62   (let ((symbols (assoc file load-history)))
  63     ;; Try converting a library name to an absolute file name.
  64     (and (null symbols)
  65          (let ((absname
  66                 (locate-file file load-path (get-load-suffixes))))
  67            (and absname (not (equal absname file))
  68                 (setq symbols (cdr (assoc absname load-history))))))
  69     symbols))
  70
  71 (defun file-provides (file)
  72   "Return the list of features provided by FILE as it was loaded.
  73 FILE can be a file name, or a library name.
  74 A library name is equivalent to the file name that `load-library' would load."
  75   (let ((symbols (file-loadhist-lookup file))
  76         provides)
  77     (mapc (lambda (x)
  78             (if (and (consp x) (eq (car x) 'provide))
  79                 (setq provides (cons (cdr x) provides))))
  80           symbols)
  81     provides))
  82
  83 (defun file-requires (file)
  84   "Return the list of features required by FILE as it was loaded.
  85 FILE can be a file name, or a library name.
  86 A library name is equivalent to the file name that `load-library' would load."
  87   (let ((symbols (file-loadhist-lookup file))
  88         requires)
  89     (mapc (lambda (x)
  90             (if (and (consp x) (eq (car x) 'require))
  91                 (setq requires (cons (cdr x) requires))))
  92           symbols)
  93     requires))
  94
  95 (defsubst file-set-intersect (p q)
  96   "Return the set intersection of two lists."
  97   (let ((ret nil))
  98     (dolist (x p ret)
  99       (if (memq x q) (setq ret (cons x ret))))
 100     ret))
 101
 102 (defun file-dependents (file)
 103   "Return the list of loaded libraries that depend on FILE.
 104 This can include FILE itself.
 105 FILE can be a file name, or a library name.
 106 A library name is equivalent to the file name that `load-library' would load."
 107   (let ((provides (file-provides file))
 108         (dependents nil))
 109     (dolist (x load-history dependents)
 110       (if (file-set-intersect provides (file-requires (car x)))
 111           (setq dependents (cons (car x) dependents))))
 112     dependents))
 113
 114 (defun read-feature (prompt)
 115   "Read a feature name \(string\) from the minibuffer.
 116 Prompt with PROMPT and completing from `features', and
 117 return the feature \(symbol\)."
 118   (intern (completing-read prompt
 119                            (mapcar (lambda (feature)
 120                                      (list (symbol-name feature)))
 121                                    features)
 122                            ;; Complete only features loaded from a file
 123                            #'(lambda (f) (feature-file (intern (car f))))
 124                            t)))
 125
 126 (defvaralias 'loadhist-hook-functions 'unload-feature-special-hooks)
 127 (defvar unload-feature-special-hooks
 128   '(after-change-functions
 129     after-insert-file-functions auto-fill-function
 130     before-change-functions blink-paren-function
 131     buffer-access-fontify-functions command-line-functions
 132     comment-indent-function kill-buffer-query-functions
 133     kill-emacs-query-functions lisp-indent-function
 134     mouse-position-function
 135     redisplay-end-trigger-functions temp-buffer-show-function
 136     window-scroll-functions window-size-change-functions
 137     write-region-annotate-functions)
 138   "A list of special hooks from Info node `(elisp)Standard Hooks'.
 139
 140 These are symbols with hook-type values whose names don't end in
 141 `-hook' or `-hooks', from which `unload-feature' tries to remove
 142 pertinent symbols.")
 143
 144 (defvar unload-hook-features-list nil
 145   "List of features of the package being unloaded.
 146
 147 This is meant to be used by FEATURE-unload-hook hooks, see the
 148 documentation of `unload-feature' for details.")
 149
 150 ;;;###autoload
 151 (defun unload-feature (feature &optional force)
 152   "Unload the library that provided FEATURE, restoring all its autoloads.
 153 If the feature is required by any other loaded code, and prefix arg FORCE
 154 is nil, raise an error.
 155
 156 This function tries to undo modifications made by the package to
 157 hooks.  Packages may define a hook FEATURE-unload-hook that is called
 158 instead of the normal heuristics for doing this.  Such a hook should
 159 undo all the relevant global state changes that may have been made by
 160 loading the package or executing functions in it.  It has access to
 161 the package's feature list (before anything is unbound) in the
 162 variable `unload-hook-features-list' and could remove features from it
 163 in the event that the package has done something normally-ill-advised,
 164 such as redefining an Emacs function."
 165   (interactive (list (read-feature "Feature: ") current-prefix-arg))
 166   (unless (featurep feature)
 167     (error "%s is not a currently loaded feature" (symbol-name feature)))
 168   (unless force
 169     (let* ((file (feature-file feature))
 170            (dependents (delete file (copy-sequence (file-dependents file)))))
 171       (when dependents
 172         (error "Loaded libraries %s depend on %s"
 173                (prin1-to-string dependents) file))))
 174   (let* ((unload-hook-features-list (feature-symbols feature))
 175          (file (pop unload-hook-features-list))
 176          (unload-hook (intern-soft (concat (symbol-name feature)
 177                                            "-unload-hook"))))
 178     ;; Try to avoid losing badly when hooks installed in critical
 179     ;; places go away.  (Some packages install things on
 180     ;; `kill-buffer-hook', `activate-menubar-hook' and the like.)
 181     ;; First off, provide a clean way for package FOO to arrange
 182     ;; this by adding hooks on the variable `FOO-unload-hook'.
 183     (if unload-hook
 184         (run-hooks unload-hook)
 185       ;; Otherwise, do our best.  Look through the obarray for symbols
 186       ;; which seem to be hook variables or special hook functions and
 187       ;; remove anything from them which matches the feature-symbols
 188       ;; about to get zapped.  Obviously this won't get anonymous
 189       ;; functions which the package might just have installed, and
 190       ;; there might be other important state, but this tactic
 191       ;; normally works.
 192       (mapatoms
 193        (lambda (x)
 194          (when (and (boundp x)
 195                     (or (and (consp (symbol-value x)) ; Random hooks.
 196                              (string-match "-hooks?\\'" (symbol-name x)))
 197                         (memq x unload-feature-special-hooks))) ; Known abnormal hooks etc.
 198            (dolist (y unload-hook-features-list)
 199              (when (and (eq (car-safe y) 'defun)
 200                         (not (get (cdr y) 'autoload)))
 201                (remove-hook x (cdr y)))))))
 202       ;; Remove any feature-symbols from auto-mode-alist as well.
 203       (dolist (y unload-hook-features-list)
 204         (when (and (eq (car-safe y) 'defun)
 205                    (not (get (cdr y) 'autoload)))
 206           (setq auto-mode-alist
 207                 (rassq-delete-all (cdr y) auto-mode-alist)))))
 208     (when (fboundp 'elp-restore-function) ; remove ELP stuff first
 209       (dolist (elt unload-hook-features-list)
 210         (when (symbolp elt)
 211           (elp-restore-function elt))))
 212     (dolist (x unload-hook-features-list)
 213       (if (consp x)
 214           (case (car x)
 215            ;; Remove any feature names that this file provided.
 216            (provide
 217             (setq features (delq (cdr x) features)))
 218            (defun
 219             (let ((fun (cdr x)))
 220               (when (fboundp fun)
 221                 (when (fboundp 'ad-unadvise)
 222                   (ad-unadvise fun))
 223                 (let ((aload (get fun 'autoload)))
 224                   (if aload
 225                       (fset fun (cons 'autoload aload))
 226                     (fmakunbound fun))))))
 227            ((t require) nil)
 228            (t (message "Unexpected element %s in load-history" x)))
 229         ;; Kill local values as much as possible.
 230         (dolist (buf (buffer-list))
 231           (with-current-buffer buf
 232             (if (and (boundp x) (timerp (symbol-value x)))
 233                 (cancel-timer (symbol-value x)))
 234             (kill-local-variable x)))
 235         (if (and (boundp x) (timerp (symbol-value x)))
 236             (cancel-timer (symbol-value x)))
 237         ;; Get rid of the default binding if we can.
 238         (unless (local-variable-if-set-p x)
 239           (makunbound x))))
 240     ;; Delete the load-history element for this file.
 241     (setq load-history (delq (assoc file load-history) load-history))))
 242
 243 (provide 'loadhist)
 244
 245 ;; arch-tag: 70bb846a-c413-4f01-bf88-78dba4ac0798
 246 ;;; loadhist.el ends here