code.delx.au - gnu-emacs/blob - lisp/erc/erc-backend.el

   1 ;;; erc-backend.el --- Backend network communication for ERC
   2
   3 ;; Copyright (C) 2004-2014 Free Software Foundation, Inc.
   4
   5 ;; Filename: erc-backend.el
   6 ;; Author: Lawrence Mitchell <wence@gmx.li>
   7 ;; Maintainer: emacs-devel@gnu.org
   8 ;; Created: 2004-05-7
   9 ;; Keywords: IRC chat client internet
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; This file defines backend network communication handlers for ERC.
  29 ;;
  30 ;; How things work:
  31 ;;
  32 ;; You define a new handler with `define-erc-response-handler'.  This
  33 ;; defines a function, a corresponding hook variable, and populates a
  34 ;; global hash table `erc-server-responses' with a map from response
  35 ;; to hook variable.  See the function documentation for more
  36 ;; information.
  37 ;;
  38 ;; Upon receiving a line from the server, `erc-parse-server-response'
  39 ;; is called on it.
  40 ;;
  41 ;; A line generally looks like:
  42 ;;
  43 ;; LINE := ':' SENDER ' ' COMMAND ' ' (COMMAND-ARGS ' ')* ':' CONTENTS
  44 ;; SENDER := Not ':' | ' '
  45 ;; COMMAND := Not ':' | ' '
  46 ;; COMMAND-ARGS := Not ':' | ' '
  47 ;;
  48 ;; This gets parsed and stuffed into an `erc-response' struct.  You
  49 ;; can access the fields of the struct with:
  50 ;;
  51 ;; COMMAND --- `erc-response.command'
  52 ;; COMMAND-ARGS --- `erc-response.command-args'
  53 ;; CONTENTS --- `erc-response.contents'
  54 ;; SENDER --- `erc-response.sender'
  55 ;; LINE --- `erc-response.unparsed'
  56 ;;
  57 ;; WARNING, WARNING!!
  58 ;; It's probably not a good idea to destructively modify the list
  59 ;; of command-args in your handlers, since other functions down the
  60 ;; line may well need to access the arguments too.
  61 ;;
  62 ;; That is, unless you're /absolutely/ sure that your handler doesn't
  63 ;; invoke some other function that needs to use COMMAND-ARGS, don't do
  64 ;; something like
  65 ;;
  66 ;; (while (erc-response.command-args parsed)
  67 ;;   (let ((a (pop (erc-response.command-args parsed))))
  68 ;;     ...))
  69 ;;
  70 ;; The parsed response is handed over to
  71 ;; `erc-handle-parsed-server-response', which checks whether it should
  72 ;; carry out duplicate suppression, and then runs `erc-call-hooks'.
  73 ;; `erc-call-hooks' retrieves the relevant hook variable from
  74 ;; `erc-server-responses' and runs it.
  75 ;;
  76 ;; Most handlers then destructure the parsed response in some way
  77 ;; (depending on what the handler is, the arguments have different
  78 ;; meanings), and generally display something, usually using
  79 ;; `erc-display-message'.
  80
  81 ;;; TODO:
  82
  83 ;; o Generalize the display-line code so that we can use it to
  84 ;;   display the stuff we send, as well as the stuff we receive.
  85 ;;   Then, move all display-related code into another backend-like
  86 ;;   file, erc-display.el, say.
  87 ;;
  88 ;; o Clean up the handlers using new display code (has to be written
  89 ;;   first).
  90
  91 ;;; History:
  92
  93 ;; 2004/05/10 -- Handler bodies taken out of erc.el and ported to new
  94 ;;               interface.
  95
  96 ;; 2005-08-13 -- Moved sending commands from erc.el.
  97
  98 ;;; Code:
  99
 100 (require 'erc-compat)
 101 (eval-when-compile (require 'cl-lib))
 102 ;; There's a fairly strong mutual dependency between erc.el and erc-backend.el.
 103 ;; Luckily, erc.el does not need erc-backend.el for macroexpansion whereas the
 104 ;; reverse is true:
 105 (provide 'erc-backend)
 106 (require 'erc)
 107
 108 ;;;; Variables and options
 109
 110 (defvar erc-server-responses (make-hash-table :test #'equal)
 111   "Hashtable mapping server responses to their handler hooks.")
 112
 113 (cl-defstruct (erc-response (:conc-name erc-response.))
 114   (unparsed "" :type string)
 115   (sender "" :type string)
 116   (command "" :type string)
 117   (command-args '() :type list)
 118   (contents "" :type string))
 119
 120 ;;; User data
 121
 122 (defvar erc-server-current-nick nil
 123   "Nickname on the current server.
 124 Use `erc-current-nick' to access this.")
 125 (make-variable-buffer-local 'erc-server-current-nick)
 126
 127 ;;; Server attributes
 128
 129 (defvar erc-server-process nil
 130   "The process object of the corresponding server connection.")
 131 (make-variable-buffer-local 'erc-server-process)
 132
 133 (defvar erc-session-server nil
 134   "The server name used to connect to for this session.")
 135 (make-variable-buffer-local 'erc-session-server)
 136
 137 (defvar erc-session-connector nil
 138   "The function used to connect to this session (nil for the default).")
 139 (make-variable-buffer-local 'erc-session-connector)
 140
 141 (defvar erc-session-port nil
 142   "The port used to connect to.")
 143 (make-variable-buffer-local 'erc-session-port)
 144
 145 (defvar erc-server-announced-name nil
 146   "The name the server announced to use.")
 147 (make-variable-buffer-local 'erc-server-announced-name)
 148
 149 (defvar erc-server-version nil
 150   "The name and version of the server's ircd.")
 151 (make-variable-buffer-local 'erc-server-version)
 152
 153 (defvar erc-server-parameters nil
 154   "Alist listing the supported server parameters.
 155
 156 This is only set if the server sends 005 messages saying what is
 157 supported on the server.
 158
 159 Entries are of the form:
 160   (PARAMETER . VALUE)
 161 or
 162   (PARAMETER) if no value is provided.
 163
 164 Some examples of possible parameters sent by servers:
 165 CHANMODES=b,k,l,imnpst - list of supported channel modes
 166 CHANNELLEN=50 - maximum length of channel names
 167 CHANTYPES=#&!+ - supported channel prefixes
 168 CHARMAPPING=rfc1459 - character mapping used for nickname and channels
 169 KICKLEN=160 - maximum allowed kick message length
 170 MAXBANS=30 - maximum number of bans per channel
 171 MAXCHANNELS=10 - maximum number of channels allowed to join
 172 NETWORK=EFnet -  the network identifier
 173 NICKLEN=9 - maximum allowed length of nicknames
 174 PREFIX=(ov)@+ - list of channel modes and the user prefixes if user has mode
 175 RFC2812 - server supports RFC 2812 features
 176 SILENCE=10 - supports the SILENCE command, maximum allowed number of entries
 177 TOPICLEN=160 - maximum allowed topic length
 178 WALLCHOPS - supports sending messages to all operators in a channel")
 179 (make-variable-buffer-local 'erc-server-parameters)
 180
 181 ;;; Server and connection state
 182
 183 (defvar erc-server-ping-timer-alist nil
 184   "Mapping of server buffers to their specific ping timer.")
 185
 186 (defvar erc-server-connected nil
 187   "Non-nil if the current buffer has been used by ERC to establish
 188 an IRC connection.
 189
 190 If you wish to determine whether an IRC connection is currently
 191 active, use the `erc-server-process-alive' function instead.")
 192 (make-variable-buffer-local 'erc-server-connected)
 193
 194 (defvar erc-server-reconnect-count 0
 195   "Number of times we have failed to reconnect to the current server.")
 196 (make-variable-buffer-local 'erc-server-reconnect-count)
 197
 198 (defvar erc-server-quitting nil
 199   "Non-nil if the user requests a quit.")
 200 (make-variable-buffer-local 'erc-server-quitting)
 201
 202 (defvar erc-server-reconnecting nil
 203   "Non-nil if the user requests an explicit reconnect, and the
 204 current IRC process is still alive.")
 205 (make-variable-buffer-local 'erc-server-reconnecting)
 206
 207 (defvar erc-server-timed-out nil
 208   "Non-nil if the IRC server failed to respond to a ping.")
 209 (make-variable-buffer-local 'erc-server-timed-out)
 210
 211 (defvar erc-server-banned nil
 212   "Non-nil if the user is denied access because of a server ban.")
 213 (make-variable-buffer-local 'erc-server-banned)
 214
 215 (defvar erc-server-error-occurred nil
 216   "Non-nil if the user triggers some server error.")
 217 (make-variable-buffer-local 'erc-server-error-occurred)
 218
 219 (defvar erc-server-lines-sent nil
 220   "Line counter.")
 221 (make-variable-buffer-local 'erc-server-lines-sent)
 222
 223 (defvar erc-server-last-peers '(nil . nil)
 224   "Last peers used, both sender and receiver.
 225 Those are used for /MSG destination shortcuts.")
 226 (make-variable-buffer-local 'erc-server-last-peers)
 227
 228 (defvar erc-server-last-sent-time nil
 229   "Time the message was sent.
 230 This is useful for flood protection.")
 231 (make-variable-buffer-local 'erc-server-last-sent-time)
 232
 233 (defvar erc-server-last-ping-time nil
 234   "Time the last ping was sent.
 235 This is useful for flood protection.")
 236 (make-variable-buffer-local 'erc-server-last-ping-time)
 237
 238 (defvar erc-server-last-received-time nil
 239   "Time the last message was received from the server.
 240 This is useful for detecting hung connections.")
 241 (make-variable-buffer-local 'erc-server-last-received-time)
 242
 243 (defvar erc-server-lag nil
 244   "Calculated server lag time in seconds.
 245 This variable is only set in a server buffer.")
 246 (make-variable-buffer-local 'erc-server-lag)
 247
 248 (defvar erc-server-filter-data nil
 249   "The data that arrived from the server
 250 but has not been processed yet.")
 251 (make-variable-buffer-local 'erc-server-filter-data)
 252
 253 (defvar erc-server-duplicates (make-hash-table :test 'equal)
 254   "Internal variable used to track duplicate messages.")
 255 (make-variable-buffer-local 'erc-server-duplicates)
 256
 257 ;; From Circe
 258 (defvar erc-server-processing-p nil
 259   "Non-nil when we're currently processing a message.
 260
 261 When ERC receives a private message, it sets up a new buffer for
 262 this query.  These in turn, though, do start flyspell. This
 263 involves starting an external process, in which case Emacs will
 264 wait - and when it waits, it does accept other stuff from, say,
 265 network exceptions.  So, if someone sends you two messages
 266 quickly after each other, ispell is started for the first, but
 267 might take long enough for the second message to be processed
 268 first.")
 269 (make-variable-buffer-local 'erc-server-processing-p)
 270
 271 (defvar erc-server-flood-last-message 0
 272   "When we sent the last message.
 273 See `erc-server-flood-margin' for an explanation of the flood
 274 protection algorithm.")
 275 (make-variable-buffer-local 'erc-server-flood-last-message)
 276
 277 (defvar erc-server-flood-queue nil
 278   "The queue of messages waiting to be sent to the server.
 279 See `erc-server-flood-margin' for an explanation of the flood
 280 protection algorithm.")
 281 (make-variable-buffer-local 'erc-server-flood-queue)
 282
 283 (defvar erc-server-flood-timer nil
 284   "The timer to resume sending.")
 285 (make-variable-buffer-local 'erc-server-flood-timer)
 286
 287 ;;; IRC protocol and misc options
 288
 289 (defgroup erc-server nil
 290   "Parameters for dealing with IRC servers."
 291   :group 'erc)
 292
 293 (defcustom erc-server-auto-reconnect t
 294   "Non-nil means that ERC will attempt to reestablish broken connections.
 295
 296 Reconnection will happen automatically for any unexpected disconnection."
 297   :group 'erc-server
 298   :type 'boolean)
 299
 300 (defcustom erc-server-reconnect-attempts 2
 301   "The number of times that ERC will attempt to reestablish a
 302 broken connection, or t to always attempt to reconnect.
 303
 304 This only has an effect if `erc-server-auto-reconnect' is non-nil."
 305   :group 'erc-server
 306   :type '(choice (const :tag "Always reconnect" t)
 307                  integer))
 308
 309 (defcustom erc-server-reconnect-timeout 1
 310   "The amount of time, in seconds, that ERC will wait between
 311 successive reconnect attempts.
 312
 313 If a key is pressed while ERC is waiting, it will stop waiting."
 314   :group 'erc-server
 315   :type 'number)
 316
 317 (defcustom erc-split-line-length 440
 318   "The maximum length of a single message.
 319 If a message exceeds this size, it is broken into multiple ones.
 320
 321 IRC allows for lines up to 512 bytes. Two of them are CR LF.
 322 And a typical message looks like this:
 323
 324   :nicky!uhuser@host212223.dialin.fnordisp.net PRIVMSG #lazybastards :Hello!
 325
 326 You can limit here the maximum length of the \"Hello!\" part.
 327 Good luck."
 328   :type 'integer
 329   :group 'erc-server)
 330
 331 (defcustom erc-coding-system-precedence '(utf-8 undecided)
 332   "List of coding systems to be preferred when receiving a string from the server.
 333 This will only be consulted if the coding system in
 334 `erc-server-coding-system' is `undecided'."
 335   :group 'erc-server
 336   :version "24.1"
 337   :type '(repeat coding-system))
 338
 339 (defcustom erc-server-coding-system (if (and (fboundp 'coding-system-p)
 340                                              (coding-system-p 'undecided)
 341                                              (coding-system-p 'utf-8))
 342                                         '(utf-8 . undecided)
 343                                       nil)
 344   "The default coding system for incoming and outgoing text.
 345 This is either a coding system, a cons, a function, or nil.
 346
 347 If a cons, the encoding system for outgoing text is in the car
 348 and the decoding system for incoming text is in the cdr. The most
 349 interesting use for this is to put `undecided' in the cdr. This
 350 means that `erc-coding-system-precedence' will be consulted, and the
 351 first match there will be used.
 352
 353 If a function, it is called with the argument `target' and should
 354 return a coding system or a cons as described above.
 355
 356 If you need to send non-ASCII text to people not using a client that
 357 does decoding on its own, you must tell ERC what encoding to use.
 358 Emacs cannot guess it, since it does not know what the people on the
 359 other end of the line are using."
 360   :group 'erc-server
 361   :type '(choice (const :tag "None" nil)
 362                  coding-system
 363                  (cons (coding-system :tag "encoding" :value utf-8)
 364                        (coding-system :tag "decoding" :value undecided))
 365                  function))
 366
 367 (defcustom erc-encoding-coding-alist nil
 368   "Alist of target regexp and coding-system pairs to use.
 369 This overrides `erc-server-coding-system' depending on the
 370 current target as returned by `erc-default-target'.
 371
 372 Example: If you know that the channel #linux-ru uses the coding-system
 373 `cyrillic-koi8', then add '(\"#linux-ru\" . cyrillic-koi8) to the
 374 alist."
 375   :group 'erc-server
 376   :type '(repeat (cons (string :tag "Target")
 377                        coding-system)))
 378
 379 (defcustom erc-server-connect-function 'open-network-stream
 380   "Function used to initiate a connection.
 381 It should take same arguments as `open-network-stream' does."
 382   :group 'erc-server
 383   :type 'function)
 384
 385 (defcustom erc-server-prevent-duplicates '("301")
 386   "Either nil or a list of strings.
 387 Each string is a IRC message type, like PRIVMSG or NOTICE.
 388 All Message types in that list of subjected to duplicate prevention."
 389   :type '(choice (const nil) (list string))
 390   :group 'erc-server)
 391
 392 (defcustom erc-server-duplicate-timeout 60
 393   "The time allowed in seconds between duplicate messages.
 394
 395 If two identical messages arrive within this value of one another, the second
 396 isn't displayed."
 397   :type 'integer
 398   :group 'erc-server)
 399
 400 (defcustom erc-server-timestamp-format "%Y-%m-%d %T"
 401   "Timestamp format used with server response messages.
 402 This string is processed using `format-time-string'."
 403   :version "24.3"
 404   :type 'string
 405   :group 'erc-server)
 406
 407 ;;; Flood-related
 408
 409 ;; Most of this is courtesy of Jorgen Schaefer and Circe
 410 ;; (http://www.nongnu.org/circe)
 411
 412 (defcustom erc-server-flood-margin 10
 413   "A margin on how much excess data we send.
 414 The flood protection algorithm of ERC works like the one
 415 detailed in RFC 2813, section 5.8 \"Flood control of clients\".
 416
 417   * If `erc-server-flood-last-message' is less than the current
 418     time, set it equal.
 419   * While `erc-server-flood-last-message' is less than
 420     `erc-server-flood-margin' seconds ahead of the current
 421     time, send a message, and increase
 422     `erc-server-flood-last-message' by
 423     `erc-server-flood-penalty' for each message."
 424   :type 'integer
 425   :group 'erc-server)
 426
 427 (defcustom erc-server-flood-penalty 3
 428   "How much we penalize a message.
 429 See `erc-server-flood-margin' for an explanation of the flood
 430 protection algorithm."
 431   :type 'integer
 432   :group 'erc-server)
 433
 434 ;; Ping handling
 435
 436 (defcustom erc-server-send-ping-interval 30
 437   "Interval of sending pings to the server, in seconds.
 438 If this is set to nil, pinging the server is disabled."
 439   :group 'erc-server
 440   :type '(choice (const :tag "Disabled" nil)
 441                  (integer :tag "Seconds")))
 442
 443 (defcustom erc-server-send-ping-timeout 120
 444   "If the time between ping and response is greater than this, reconnect.
 445 The time is in seconds.
 446
 447 This must be greater than or equal to the value for
 448 `erc-server-send-ping-interval'.
 449
 450 If this is set to nil, never try to reconnect."
 451   :group 'erc-server
 452   :type '(choice (const :tag "Disabled" nil)
 453                  (integer :tag "Seconds")))
 454
 455 (defvar erc-server-ping-handler nil
 456   "This variable holds the periodic ping timer.")
 457 (make-variable-buffer-local 'erc-server-ping-handler)
 458
 459 ;;;; Helper functions
 460
 461 ;; From Circe
 462 (defun erc-split-line (longline)
 463   "Return a list of lines which are not too long for IRC.
 464 The length is specified in `erc-split-line-length'.
 465
 466 Currently this is called by `erc-send-input'."
 467   (if (< (length longline)
 468          erc-split-line-length)
 469       (list longline)
 470     (with-temp-buffer
 471       (insert longline)
 472       (let ((fill-column erc-split-line-length))
 473         (fill-region (point-min) (point-max)
 474                      nil t))
 475       (split-string (buffer-string) "\n"))))
 476
 477 ;; Used by CTCP functions
 478 (defun erc-upcase-first-word (str)
 479   "Upcase the first word in STR."
 480   (with-temp-buffer
 481     (insert str)
 482     (goto-char (point-min))
 483     (upcase-word 1)
 484     (buffer-string)))
 485
 486 (defun erc-server-setup-periodical-ping (buffer)
 487   "Set up a timer to periodically ping the current server.
 488 The current buffer is given by BUFFER."
 489   (with-current-buffer buffer
 490     (and erc-server-ping-handler (erc-cancel-timer erc-server-ping-handler))
 491     (when erc-server-send-ping-interval
 492       (setq erc-server-ping-handler (run-with-timer
 493                                      4 erc-server-send-ping-interval
 494                                      #'erc-server-send-ping
 495                                      buffer))
 496       (setq erc-server-ping-timer-alist (cons (cons buffer
 497                                                     erc-server-ping-handler)
 498                                               erc-server-ping-timer-alist)))))
 499
 500 (defun erc-server-process-alive (&optional buffer)
 501   "Return non-nil when BUFFER has an `erc-server-process' open or running."
 502   (with-current-buffer (or buffer (current-buffer))
 503     (and erc-server-process
 504          (processp erc-server-process)
 505          (memq (process-status erc-server-process) '(run open)))))
 506
 507 ;;;; Connecting to a server
 508
 509 (defun erc-server-connect (server port buffer)
 510   "Perform the connection and login using the specified SERVER and PORT.
 511 We will store server variables in the buffer given by BUFFER."
 512   (let ((msg (erc-format-message 'connect ?S server ?p port)))
 513     (message "%s" msg)
 514     (let ((process (funcall erc-server-connect-function
 515                             (format "erc-%s-%s" server port)
 516                             nil server port)))
 517       (unless (processp process)
 518         (error "Connection attempt failed"))
 519       (message "%s...done" msg)
 520       ;; Misc server variables
 521       (with-current-buffer buffer
 522         (setq erc-server-process process)
 523         (setq erc-server-quitting nil)
 524         (setq erc-server-reconnecting nil)
 525         (setq erc-server-timed-out nil)
 526         (setq erc-server-banned nil)
 527         (setq erc-server-error-occurred nil)
 528         (let ((time (erc-current-time)))
 529           (setq erc-server-last-sent-time time)
 530           (setq erc-server-last-ping-time time)
 531           (setq erc-server-last-received-time time))
 532         (setq erc-server-lines-sent 0)
 533         ;; last peers (sender and receiver)
 534         (setq erc-server-last-peers '(nil . nil)))
 535       ;; we do our own encoding and decoding
 536       (when (fboundp 'set-process-coding-system)
 537         (set-process-coding-system process 'raw-text))
 538       ;; process handlers
 539       (set-process-sentinel process 'erc-process-sentinel)
 540       (set-process-filter process 'erc-server-filter-function)
 541       (set-process-buffer process buffer)))
 542   (erc-log "\n\n\n********************************************\n")
 543   (message "%s" (erc-format-message
 544             'login ?n
 545             (with-current-buffer buffer (erc-current-nick))))
 546   ;; wait with script loading until we receive a confirmation (first
 547   ;; MOTD line)
 548   (if (eq erc-server-connect-function 'open-network-stream-nowait)
 549       ;; it's a bit unclear otherwise that it's attempting to establish a
 550       ;; connection
 551       (erc-display-message nil nil buffer "Opening connection..\n")
 552     (erc-login)))
 553
 554 (defun erc-server-reconnect ()
 555 "Reestablish the current IRC connection.
 556 Make sure you are in an ERC buffer when running this."
 557   (let ((buffer (erc-server-buffer)))
 558     (unless (buffer-live-p buffer)
 559       (if (eq major-mode 'erc-mode)
 560           (setq buffer (current-buffer))
 561         (error "Reconnect must be run from an ERC buffer")))
 562     (with-current-buffer buffer
 563       (erc-update-mode-line)
 564       (erc-set-active-buffer (current-buffer))
 565       (setq erc-server-last-sent-time 0)
 566       (setq erc-server-lines-sent 0)
 567       (let ((erc-server-connect-function (or erc-session-connector
 568                                              'open-network-stream)))
 569         (erc-open erc-session-server erc-session-port erc-server-current-nick
 570                   erc-session-user-full-name t erc-session-password)))))
 571
 572 (defun erc-server-filter-function (process string)
 573   "The process filter for the ERC server."
 574   (with-current-buffer (process-buffer process)
 575     (setq erc-server-last-received-time (erc-current-time))
 576     ;; If you think this is written in a weird way - please refer to the
 577     ;; docstring of `erc-server-processing-p'
 578     (if erc-server-processing-p
 579         (setq erc-server-filter-data
 580               (if erc-server-filter-data
 581                   (concat erc-server-filter-data string)
 582                 string))
 583       ;; This will be true even if another process is spawned!
 584       (let ((erc-server-processing-p t))
 585         (setq erc-server-filter-data (if erc-server-filter-data
 586                                            (concat erc-server-filter-data
 587                                                    string)
 588                                          string))
 589         (while (and erc-server-filter-data
 590                     (string-match "[\n\r]+" erc-server-filter-data))
 591           (let ((line (substring erc-server-filter-data
 592                                  0 (match-beginning 0))))
 593             (setq erc-server-filter-data
 594                   (if (= (match-end 0)
 595                          (length erc-server-filter-data))
 596                       nil
 597                     (substring erc-server-filter-data
 598                                (match-end 0))))
 599             (erc-log-irc-protocol line nil)
 600             (erc-parse-server-response process line)))))))
 601
 602 (defsubst erc-server-reconnect-p (event)
 603   "Return non-nil if ERC should attempt to reconnect automatically.
 604 EVENT is the message received from the closed connection process."
 605   (or erc-server-reconnecting
 606       (and erc-server-auto-reconnect
 607            (not erc-server-banned)
 608            (not erc-server-error-occurred)
 609            ;; make sure we don't infinitely try to reconnect, unless the
 610            ;; user wants that
 611            (or (eq erc-server-reconnect-attempts t)
 612                (and (integerp erc-server-reconnect-attempts)
 613                     (< erc-server-reconnect-count
 614                        erc-server-reconnect-attempts)))
 615            (or erc-server-timed-out
 616                (not (string-match "^deleted" event)))
 617            ;; open-network-stream-nowait error for connection refused
 618            (not (string-match "^failed with code 111" event)))))
 619
 620 (defun erc-process-sentinel-2 (event buffer)
 621   "Called when `erc-process-sentinel-1' has detected an unexpected disconnect."
 622   (if (not (buffer-live-p buffer))
 623       (erc-update-mode-line)
 624     (with-current-buffer buffer
 625       (let ((reconnect-p (erc-server-reconnect-p event)))
 626         (erc-display-message nil 'error (current-buffer)
 627                              (if reconnect-p 'disconnected
 628                                'disconnected-noreconnect))
 629         (if (not reconnect-p)
 630             ;; terminate, do not reconnect
 631             (progn
 632               (erc-display-message nil 'error (current-buffer)
 633                                    'terminated ?e event)
 634               ;; Update mode line indicators
 635               (erc-update-mode-line)
 636               (set-buffer-modified-p nil))
 637           ;; reconnect
 638           (condition-case err
 639               (progn
 640                 (setq erc-server-reconnecting nil)
 641                 (erc-server-reconnect)
 642                 (setq erc-server-reconnect-count 0))
 643             (error (when (buffer-live-p buffer)
 644                      (set-buffer buffer)
 645                      (if (integerp erc-server-reconnect-attempts)
 646                          (setq erc-server-reconnect-count
 647                                (1+ erc-server-reconnect-count))
 648                        (message "%s ... %s"
 649                                 "Reconnecting until we succeed"
 650                                 "kill the ERC server buffer to stop"))
 651                      (if (numberp erc-server-reconnect-timeout)
 652                          (run-at-time erc-server-reconnect-timeout nil
 653                                       #'erc-process-sentinel-2
 654                                       event buffer)
 655                        (error (concat "`erc-server-reconnect-timeout`"
 656                                       " must be a number")))))))))))
 657
 658 (defun erc-process-sentinel-1 (event buffer)
 659   "Called when `erc-process-sentinel' has decided that we're disconnecting.
 660 Determine whether user has quit or whether erc has been terminated.
 661 Conditionally try to reconnect and take appropriate action."
 662   (with-current-buffer buffer
 663     (if erc-server-quitting
 664         ;; normal quit
 665         (progn
 666           (erc-display-message nil 'error (current-buffer) 'finished)
 667           ;; Update mode line indicators
 668           (erc-update-mode-line)
 669           ;; Kill server buffer if user wants it
 670           (set-buffer-modified-p nil)
 671           (when erc-kill-server-buffer-on-quit
 672             (kill-buffer (current-buffer))))
 673       ;; unexpected disconnect
 674       (erc-process-sentinel-2 event buffer))))
 675
 676 (defun erc-process-sentinel (cproc event)
 677   "Sentinel function for ERC process."
 678   (let ((buf (process-buffer cproc)))
 679     (when (buffer-live-p buf)
 680       (with-current-buffer buf
 681         (erc-log (format
 682                   "SENTINEL: proc: %S    status: %S  event: %S (quitting: %S)"
 683                   cproc (process-status cproc) event erc-server-quitting))
 684         (if (string-match "^open" event)
 685             ;; newly opened connection (no wait)
 686             (erc-login)
 687           ;; assume event is 'failed
 688           (erc-with-all-buffers-of-server cproc nil
 689                                           (setq erc-server-connected nil))
 690           (when erc-server-ping-handler
 691             (progn (erc-cancel-timer erc-server-ping-handler)
 692                    (setq erc-server-ping-handler nil)))
 693           (run-hook-with-args 'erc-disconnected-hook
 694                               (erc-current-nick) (system-name) "")
 695           ;; Remove the prompt
 696           (goto-char (or (marker-position erc-input-marker) (point-max)))
 697           (forward-line 0)
 698           (erc-remove-text-properties-region (point) (point-max))
 699           (delete-region (point) (point-max))
 700           ;; Decide what to do with the buffer
 701           ;; Restart if disconnected
 702           (erc-process-sentinel-1 event buf))))))
 703
 704 ;;;; Sending messages
 705
 706 (defun erc-coding-system-for-target (target)
 707   "Return the coding system or cons cell appropriate for TARGET.
 708 This is determined via `erc-encoding-coding-alist' or
 709 `erc-server-coding-system'."
 710   (unless target (setq target (erc-default-target)))
 711   (or (when target
 712         (let ((case-fold-search t))
 713           (catch 'match
 714             (dolist (pat erc-encoding-coding-alist)
 715               (when (string-match (car pat) target)
 716                 (throw 'match (cdr pat)))))))
 717       (and (functionp erc-server-coding-system)
 718            (funcall erc-server-coding-system target))
 719       erc-server-coding-system))
 720
 721 (defun erc-decode-string-from-target (str target)
 722   "Decode STR as appropriate for TARGET.
 723 This is indicated by `erc-encoding-coding-alist', defaulting to the value of
 724 `erc-server-coding-system'."
 725   (unless (stringp str)
 726     (setq str ""))
 727   (let ((coding (erc-coding-system-for-target target)))
 728     (when (consp coding)
 729       (setq coding (cdr coding)))
 730     (when (eq coding 'undecided)
 731       (let ((codings (detect-coding-string str))
 732             (precedence erc-coding-system-precedence))
 733         (while (and precedence
 734                     (not (memq (car precedence) codings)))
 735           (pop precedence))
 736         (when precedence
 737           (setq coding (car precedence)))))
 738     (erc-decode-coding-string str coding)))
 739
 740 ;; proposed name, not used by anything yet
 741 (defun erc-send-line (text display-fn)
 742   "Send TEXT to the current server.  Wrapping and flood control apply.
 743 Use DISPLAY-FN to show the results."
 744   (mapc (lambda (line)
 745           (erc-server-send line)
 746           (funcall display-fn))
 747         (erc-split-line text)))
 748
 749 ;; From Circe, with modifications
 750 (defun erc-server-send (string &optional forcep target)
 751   "Send STRING to the current server.
 752 If FORCEP is non-nil, no flood protection is done - the string is
 753 sent directly. This might cause the messages to arrive in a wrong
 754 order.
 755
 756 If TARGET is specified, look up encoding information for that
 757 channel in `erc-encoding-coding-alist' or
 758 `erc-server-coding-system'.
 759
 760 See `erc-server-flood-margin' for an explanation of the flood
 761 protection algorithm."
 762   (erc-log (concat "erc-server-send: " string "(" (buffer-name) ")"))
 763   (setq erc-server-last-sent-time (erc-current-time))
 764   (let ((encoding (erc-coding-system-for-target target)))
 765     (when (consp encoding)
 766       (setq encoding (car encoding)))
 767     (if (erc-server-process-alive)
 768         (erc-with-server-buffer
 769           (let ((str (concat string "\r\n")))
 770             (if forcep
 771                 (progn
 772                   (setq erc-server-flood-last-message
 773                         (+ erc-server-flood-penalty
 774                            erc-server-flood-last-message))
 775                   (erc-log-irc-protocol str 'outbound)
 776                   (condition-case err
 777                       (progn
 778                         ;; Set encoding just before sending the string
 779                         (when (fboundp 'set-process-coding-system)
 780                           (set-process-coding-system erc-server-process
 781                                                      'raw-text encoding))
 782                         (process-send-string erc-server-process str))
 783                     ;; See `erc-server-send-queue' for full
 784                     ;; explanation of why we need this condition-case
 785                     (error nil)))
 786               (setq erc-server-flood-queue
 787                     (append erc-server-flood-queue
 788                             (list (cons str encoding))))
 789               (erc-server-send-queue (current-buffer))))
 790           t)
 791       (message "ERC: No process running")
 792       nil)))
 793
 794 (defun erc-server-send-ping (buf)
 795   "Send a ping to the IRC server buffer in BUF.
 796 Additionally, detect whether the IRC process has hung."
 797   (if (buffer-live-p buf)
 798       (with-current-buffer buf
 799         (if (and erc-server-send-ping-timeout
 800                  (>
 801                   (erc-time-diff (erc-current-time)
 802                                  erc-server-last-received-time)
 803                   erc-server-send-ping-timeout))
 804             (progn
 805               ;; if the process is hung, kill it
 806               (setq erc-server-timed-out t)
 807               (delete-process erc-server-process))
 808           (erc-server-send (format "PING %.0f" (erc-current-time)))))
 809     ;; remove timer if the server buffer has been killed
 810     (let ((timer (assq buf erc-server-ping-timer-alist)))
 811       (when timer
 812         (erc-cancel-timer (cdr timer))
 813         (setcdr timer nil)))))
 814
 815 ;; From Circe
 816 (defun erc-server-send-queue (buffer)
 817   "Send messages in `erc-server-flood-queue'.
 818 See `erc-server-flood-margin' for an explanation of the flood
 819 protection algorithm."
 820   (with-current-buffer buffer
 821     (let ((now (erc-current-time)))
 822       (when erc-server-flood-timer
 823         (erc-cancel-timer erc-server-flood-timer)
 824         (setq erc-server-flood-timer nil))
 825       (when (< erc-server-flood-last-message
 826                now)
 827         (setq erc-server-flood-last-message now))
 828       (while (and erc-server-flood-queue
 829                   (< erc-server-flood-last-message
 830                      (+ now erc-server-flood-margin)))
 831         (let ((msg (caar erc-server-flood-queue))
 832               (encoding (cdar erc-server-flood-queue)))
 833           (setq erc-server-flood-queue (cdr erc-server-flood-queue)
 834                 erc-server-flood-last-message
 835                 (+ erc-server-flood-last-message
 836                    erc-server-flood-penalty))
 837           (erc-log-irc-protocol msg 'outbound)
 838           (erc-log (concat "erc-server-send-queue: "
 839                            msg "(" (buffer-name buffer) ")"))
 840           (when (erc-server-process-alive)
 841             (condition-case err
 842                 ;; Set encoding just before sending the string
 843                 (progn
 844                   (when (fboundp 'set-process-coding-system)
 845                     (set-process-coding-system erc-server-process
 846                                                'raw-text encoding))
 847                   (process-send-string erc-server-process msg))
 848               ;; Sometimes the send can occur while the process is
 849               ;; being killed, which results in a weird SIGPIPE error.
 850               ;; Catch this and ignore it.
 851               (error nil)))))
 852       (when erc-server-flood-queue
 853         (setq erc-server-flood-timer
 854               (run-at-time (+ 0.2 erc-server-flood-penalty)
 855                            nil #'erc-server-send-queue buffer))))))
 856
 857 (defun erc-message (message-command line &optional force)
 858   "Send LINE to the server as a privmsg or a notice.
 859 MESSAGE-COMMAND should be either \"PRIVMSG\" or \"NOTICE\".
 860 If the target is \",\", the last person you've got a message from will
 861 be used. If the target is \".\", the last person you've sent a message
 862 to will be used."
 863   (cond
 864    ((string-match "^\\s-*\\(\\S-+\\) ?\\(.*\\)" line)
 865     (let ((tgt (match-string 1 line))
 866           (s (match-string 2 line)))
 867       (erc-log (format "cmd: MSG(%s): [%s] %s" message-command tgt s))
 868       (cond
 869        ((string= tgt ",")
 870         (if (car erc-server-last-peers)
 871             (setq tgt (car erc-server-last-peers))
 872           (setq tgt nil)))
 873        ((string= tgt ".")
 874         (if (cdr erc-server-last-peers)
 875             (setq tgt (cdr erc-server-last-peers))
 876           (setq tgt nil))))
 877       (cond
 878        (tgt
 879         (setcdr erc-server-last-peers tgt)
 880         (erc-server-send (format "%s %s :%s" message-command tgt s)
 881                          force))
 882        (t
 883         (erc-display-message nil 'error (current-buffer) 'no-target))))
 884     t)
 885    (t nil)))
 886
 887 ;;; CTCP
 888
 889 (defun erc-send-ctcp-message (tgt l &optional force)
 890   "Send CTCP message L to TGT.
 891
 892 If TGT is nil the message is not sent.
 893 The command must contain neither a prefix nor a trailing `\\n'.
 894
 895 See also `erc-server-send'."
 896   (let ((l (erc-upcase-first-word l)))
 897     (cond
 898      (tgt
 899       (erc-log (format "erc-send-CTCP-message: [%s] %s" tgt l))
 900       (erc-server-send (format "PRIVMSG %s :\C-a%s\C-a" tgt l)
 901                        force)))))
 902
 903 (defun erc-send-ctcp-notice (tgt l &optional force)
 904   "Send CTCP notice L to TGT.
 905
 906 If TGT is nil the message is not sent.
 907 The command must contain neither a prefix nor a trailing `\\n'.
 908
 909 See also `erc-server-send'."
 910   (let ((l (erc-upcase-first-word l)))
 911     (cond
 912      (tgt
 913       (erc-log (format "erc-send-CTCP-notice: [%s] %s" tgt l))
 914       (erc-server-send (format "NOTICE %s :\C-a%s\C-a" tgt l)
 915                        force)))))
 916
 917 ;;;; Handling responses
 918
 919 (defun erc-parse-server-response (proc string)
 920   "Parse and act upon a complete line from an IRC server.
 921 PROC is the process (connection) from which STRING was received.
 922 PROCs `process-buffer' is `current-buffer' when this function is called."
 923   (unless (string= string "") ;; Ignore empty strings
 924     (save-match-data
 925       (let ((posn (if (eq (aref string 0) ?:)
 926                       (string-match " " string)
 927                     0))
 928             (msg (make-erc-response :unparsed string)))
 929
 930         (setf (erc-response.sender msg)
 931               (if (eq posn 0)
 932                   erc-session-server
 933                 (substring string 1 posn)))
 934
 935         (setf (erc-response.command msg)
 936               (let* ((bposn (string-match "[^ \n]" string posn))
 937                      (eposn (string-match " " string bposn)))
 938                 (setq posn (and eposn
 939                                 (string-match "[^ \n]" string eposn)))
 940                 (substring string bposn eposn)))
 941
 942         (while (and posn
 943                     (not (eq (aref string posn) ?:)))
 944           (push (let* ((bposn posn)
 945                        (eposn (string-match " " string bposn)))
 946                   (setq posn (and eposn
 947                                   (string-match "[^ \n]" string eposn)))
 948                   (substring string bposn eposn))
 949                 (erc-response.command-args msg)))
 950         (when posn
 951       (let ((str (substring string (1+ posn))))
 952         (push str (erc-response.command-args msg))))
 953
 954     (setf (erc-response.contents msg)
 955           (car (erc-response.command-args msg)))
 956
 957     (setf (erc-response.command-args msg)
 958           (nreverse (erc-response.command-args msg)))
 959
 960     (erc-decode-parsed-server-response msg)
 961
 962     (erc-handle-parsed-server-response proc msg)))))
 963
 964 (defun erc-decode-parsed-server-response (parsed-response)
 965   "Decode a pre-parsed PARSED-RESPONSE before it can be handled.
 966
 967 If there is a channel name in `erc-response.command-args', decode
 968 `erc-response' according to this channel name and
 969 `erc-encoding-coding-alist', or use `erc-server-coding-system'
 970 for decoding."
 971   (let ((args (erc-response.command-args parsed-response))
 972         (decode-target nil)
 973         (decoded-args ()))
 974     (dolist (arg args nil)
 975       (when (string-match "^[#&].*" arg)
 976         (setq decode-target arg)))
 977     (when (stringp decode-target)
 978       (setq decode-target (erc-decode-string-from-target decode-target nil)))
 979     (setf (erc-response.unparsed parsed-response)
 980           (erc-decode-string-from-target
 981            (erc-response.unparsed parsed-response)
 982            decode-target))
 983     (setf (erc-response.sender parsed-response)
 984           (erc-decode-string-from-target
 985            (erc-response.sender parsed-response)
 986            decode-target))
 987     (setf (erc-response.command parsed-response)
 988           (erc-decode-string-from-target
 989            (erc-response.command parsed-response)
 990            decode-target))
 991     (dolist (arg (nreverse args) nil)
 992       (push (erc-decode-string-from-target arg decode-target)
 993             decoded-args))
 994     (setf (erc-response.command-args parsed-response) decoded-args)
 995     (setf (erc-response.contents parsed-response)
 996           (erc-decode-string-from-target
 997            (erc-response.contents parsed-response)
 998            decode-target))))
 999
1000 (defun erc-handle-parsed-server-response (process parsed-response)
1001   "Handle a pre-parsed PARSED-RESPONSE from PROCESS.
1002
1003 Hands off to helper functions via `erc-call-hooks'."
1004   (if (member (erc-response.command parsed-response)
1005               erc-server-prevent-duplicates)
1006       (let ((m (erc-response.unparsed parsed-response)))
1007         ;; duplicate suppression
1008         (if (< (or (gethash m erc-server-duplicates) 0)
1009                (- (erc-current-time) erc-server-duplicate-timeout))
1010             (erc-call-hooks process parsed-response))
1011         (puthash m (erc-current-time) erc-server-duplicates))
1012     ;; Hand off to the relevant handler.
1013     (erc-call-hooks process parsed-response)))
1014
1015 (defun erc-get-hook (command)
1016   "Return the hook variable associated with COMMAND.
1017
1018 See also `erc-server-responses'."
1019   (gethash (format (if (numberp command) "%03i" "%s") command)
1020            erc-server-responses))
1021
1022 (defun erc-call-hooks (process message)
1023   "Call hooks associated with MESSAGE in PROCESS.
1024
1025 Finds hooks by looking in the `erc-server-responses' hashtable."
1026   (let ((hook (or (erc-get-hook (erc-response.command message))
1027                   'erc-default-server-functions)))
1028     (run-hook-with-args-until-success hook process message)
1029     (erc-with-server-buffer
1030       (run-hook-with-args 'erc-timer-hook (erc-current-time)))))
1031
1032 (add-hook 'erc-default-server-functions 'erc-handle-unknown-server-response)
1033
1034 (defun erc-handle-unknown-server-response (proc parsed)
1035   "Display unknown server response's message."
1036   (let ((line (concat (erc-response.sender parsed)
1037                       " "
1038                       (erc-response.command parsed)
1039                       " "
1040                       (mapconcat 'identity (erc-response.command-args parsed)
1041                                  " "))))
1042     (erc-display-message parsed 'notice proc line)))
1043
1044
1045 (put 'define-erc-response-handler 'edebug-form-spec
1046      '(&define :name erc-response-handler
1047                (name &rest name)
1048                &optional sexp sexp def-body))
1049
1050 (cl-defmacro define-erc-response-handler ((name &rest aliases)
1051                                         &optional extra-fn-doc extra-var-doc
1052                                         &rest fn-body)
1053   "Define an ERC handler hook/function pair.
1054 NAME is the response name as sent by the server (see the IRC RFC for
1055 meanings).
1056
1057 This creates:
1058  - a hook variable `erc-server-NAME-functions' initialized to `erc-server-NAME'.
1059  - a function `erc-server-NAME' with body FN-BODY.
1060
1061 If ALIASES is non-nil, each alias in ALIASES is `defalias'ed to
1062 `erc-server-NAME'.
1063 Alias hook variables are created as `erc-server-ALIAS-functions' and
1064 initialized to the same default value as `erc-server-NAME-functions'.
1065
1066 FN-BODY is the body of `erc-server-NAME' it may refer to the two
1067 function arguments PROC and PARSED.
1068
1069 If EXTRA-FN-DOC is non-nil, it is inserted at the beginning of the
1070 defined function's docstring.
1071
1072 If EXTRA-VAR-DOC is non-nil, it is inserted at the beginning of the
1073 defined variable's docstring.
1074
1075 As an example:
1076
1077   (define-erc-response-handler (311 WHOIS WI)
1078     \"Some non-generic function documentation.\"
1079     \"Some non-generic variable documentation.\"
1080     (do-stuff-with-whois proc parsed))
1081
1082 Would expand to:
1083
1084   (prog2
1085       (defvar erc-server-311-functions 'erc-server-311
1086         \"Some non-generic variable documentation.
1087
1088   Hook called upon receiving a 311 server response.
1089   Each function is called with two arguments, the process associated
1090   with the response and the parsed response.
1091   See also `erc-server-311'.\")
1092
1093       (defun erc-server-311 (proc parsed)
1094         \"Some non-generic function documentation.
1095
1096   Handler for a 311 server response.
1097   PROC is the server process which returned the response.
1098   PARSED is the actual response as an `erc-response' struct.
1099   If you want to add responses don't modify this function, but rather
1100   add things to `erc-server-311-functions' instead.\"
1101         (do-stuff-with-whois proc parsed))
1102
1103     (puthash \"311\" 'erc-server-311-functions erc-server-responses)
1104     (puthash \"WHOIS\" 'erc-server-WHOIS-functions erc-server-responses)
1105     (puthash \"WI\" 'erc-server-WI-functions erc-server-responses)
1106
1107     (defalias 'erc-server-WHOIS 'erc-server-311)
1108     (defvar erc-server-WHOIS-functions 'erc-server-311
1109       \"Some non-generic variable documentation.
1110
1111   Hook called upon receiving a WHOIS server response.
1112
1113   Each function is called with two arguments, the process associated
1114   with the response and the parsed response.  If the function returns
1115   non-nil, stop processing the hook.  Otherwise, continue.
1116
1117   See also `erc-server-311'.\")
1118
1119     (defalias 'erc-server-WI 'erc-server-311)
1120     (defvar erc-server-WI-functions 'erc-server-311
1121       \"Some non-generic variable documentation.
1122
1123   Hook called upon receiving a WI server response.
1124   Each function is called with two arguments, the process associated
1125   with the response and the parsed response.  If the function returns
1126   non-nil, stop processing the hook.  Otherwise, continue.
1127
1128   See also `erc-server-311'.\"))
1129
1130 \(fn (NAME &rest ALIASES) &optional EXTRA-FN-DOC EXTRA-VAR-DOC &rest FN-BODY)"
1131   (if (numberp name) (setq name (intern (format "%03i" name))))
1132   (setq aliases (mapcar (lambda (a)
1133                           (if (numberp a)
1134                               (format "%03i" a)
1135                             a))
1136                         aliases))
1137   (let* ((hook-name (intern (format "erc-server-%s-functions" name)))
1138          (fn-name (intern (format "erc-server-%s" name)))
1139          (hook-doc (format "%sHook called upon receiving a %%s server response.
1140 Each function is called with two arguments, the process associated
1141 with the response and the parsed response.  If the function returns
1142 non-nil, stop processing the hook.  Otherwise, continue.
1143
1144 See also `%s'."
1145                            (if extra-var-doc
1146                                (concat extra-var-doc "\n\n")
1147                              "")
1148                            fn-name))
1149          (fn-doc (format "%sHandler for a %s server response.
1150 PROC is the server process which returned the response.
1151 PARSED is the actual response as an `erc-response' struct.
1152 If you want to add responses don't modify this function, but rather
1153 add things to `%s' instead."
1154                          (if extra-fn-doc
1155                              (concat extra-fn-doc "\n\n")
1156                            "")
1157                          name hook-name))
1158          (fn-alternates
1159           (cl-loop for alias in aliases
1160                    collect (intern (format "erc-server-%s" alias))))
1161          (var-alternates
1162           (cl-loop for alias in aliases
1163                    collect (intern (format "erc-server-%s-functions" alias)))))
1164     `(prog2
1165          ;; Normal hook variable.
1166          (defvar ,hook-name ',fn-name ,(format hook-doc name))
1167          ;; Handler function
1168          (defun ,fn-name (proc parsed)
1169            ,fn-doc
1170            ,@fn-body)
1171
1172        ;; Make find-function and find-variable find them
1173        (put ',fn-name 'definition-name ',name)
1174        (put ',hook-name 'definition-name ',name)
1175
1176        ;; Hashtable map of responses to hook variables
1177        ,@(cl-loop for response in (cons name aliases)
1178                   for var in (cons hook-name var-alternates)
1179                   collect `(puthash ,(format "%s" response) ',var
1180                                     erc-server-responses))
1181        ;; Alternates.
1182        ;; Functions are defaliased, hook variables are defvared so we
1183        ;; can add hooks to one alias, but not another.
1184        ,@(cl-loop for fn in fn-alternates
1185                   for var in var-alternates
1186                   for a in aliases
1187                   nconc (list `(defalias ',fn ',fn-name)
1188                               `(defvar ,var ',fn-name ,(format hook-doc a))
1189                               `(put ',var 'definition-name ',hook-name))))))
1190
1191 (define-erc-response-handler (ERROR)
1192   "Handle an ERROR command from the server." nil
1193   (setq erc-server-error-occurred t)
1194   (erc-display-message
1195    parsed 'error nil 'ERROR
1196    ?s (erc-response.sender parsed) ?c (erc-response.contents parsed)))
1197
1198 (define-erc-response-handler (INVITE)
1199   "Handle invitation messages."
1200   nil
1201   (let ((target (car (erc-response.command-args parsed)))
1202         (chnl (erc-response.contents parsed)))
1203     (pcase-let ((`(,nick ,login ,host)
1204                  (erc-parse-user (erc-response.sender parsed))))
1205       (setq erc-invitation chnl)
1206       (when (string= target (erc-current-nick))
1207         (erc-display-message
1208          parsed 'notice 'active
1209          'INVITE ?n nick ?u login ?h host ?c chnl)))))
1210
1211 (define-erc-response-handler (JOIN)
1212   "Handle join messages."
1213   nil
1214   (let ((chnl (erc-response.contents parsed))
1215         (buffer nil))
1216     (pcase-let ((`(,nick ,login ,host)
1217                  (erc-parse-user (erc-response.sender parsed))))
1218       ;; strip the stupid combined JOIN facility (IRC 2.9)
1219       (if (string-match "^\\(.*\\)?\^g.*$" chnl)
1220           (setq chnl (match-string 1 chnl)))
1221       (save-excursion
1222         (let* ((str (cond
1223                      ;; If I have joined a channel
1224                      ((erc-current-nick-p nick)
1225                       (setq buffer (erc-open erc-session-server erc-session-port
1226                                              nick erc-session-user-full-name
1227                                              nil nil
1228                                              (list chnl) chnl
1229                                              erc-server-process))
1230                       (when buffer
1231                         (set-buffer buffer)
1232                         (erc-add-default-channel chnl)
1233                         (erc-server-send (format "MODE %s" chnl)))
1234                       (erc-with-buffer (chnl proc)
1235                         (erc-channel-begin-receiving-names))
1236                       (erc-update-mode-line)
1237                       (run-hooks 'erc-join-hook)
1238                       (erc-make-notice
1239                        (erc-format-message 'JOIN-you ?c chnl)))
1240                      (t
1241                       (setq buffer (erc-get-buffer chnl proc))
1242                       (erc-make-notice
1243                        (erc-format-message
1244                         'JOIN ?n nick ?u login ?h host ?c chnl))))))
1245           (when buffer (set-buffer buffer))
1246           (erc-update-channel-member chnl nick nick t nil nil nil nil nil host login)
1247           ;; on join, we want to stay in the new channel buffer
1248           ;;(set-buffer ob)
1249           (erc-display-message parsed nil buffer str))))))
1250
1251 (define-erc-response-handler (KICK)
1252   "Handle kick messages received from the server." nil
1253   (let* ((ch (nth 0 (erc-response.command-args parsed)))
1254          (tgt (nth 1 (erc-response.command-args parsed)))
1255          (reason (erc-trim-string (erc-response.contents parsed)))
1256          (buffer (erc-get-buffer ch proc)))
1257     (pcase-let ((`(,nick ,login ,host)
1258                  (erc-parse-user (erc-response.sender parsed))))
1259       (erc-remove-channel-member buffer tgt)
1260       (cond
1261        ((string= tgt (erc-current-nick))
1262         (erc-display-message
1263          parsed 'notice buffer
1264          'KICK-you ?n nick ?u login ?h host ?c ch ?r reason)
1265         (run-hook-with-args 'erc-kick-hook buffer)
1266         (erc-with-buffer
1267             (buffer)
1268           (erc-remove-channel-users))
1269         (erc-delete-default-channel ch buffer)
1270         (erc-update-mode-line buffer))
1271        ((string= nick (erc-current-nick))
1272         (erc-display-message
1273          parsed 'notice buffer
1274          'KICK-by-you ?k tgt ?c ch ?r reason))
1275        (t (erc-display-message
1276              parsed 'notice buffer
1277              'KICK ?k tgt ?n nick ?u login ?h host ?c ch ?r reason))))))
1278
1279 (define-erc-response-handler (MODE)
1280   "Handle server mode changes." nil
1281   (let ((tgt (car (erc-response.command-args parsed)))
1282         (mode (mapconcat 'identity (cdr (erc-response.command-args parsed))
1283                          " ")))
1284     (pcase-let ((`(,nick ,login ,host)
1285                  (erc-parse-user (erc-response.sender parsed))))
1286       (erc-log (format "MODE: %s -> %s: %s" nick tgt mode))
1287       ;; dirty hack
1288       (let ((buf (cond ((erc-channel-p tgt)
1289                         (erc-get-buffer tgt proc))
1290                        ((string= tgt (erc-current-nick)) nil)
1291                        ((erc-active-buffer) (erc-active-buffer))
1292                        (t (erc-get-buffer tgt)))))
1293         (with-current-buffer (or buf
1294                                  (current-buffer))
1295           (erc-update-modes tgt mode nick host login))
1296           (if (or (string= login "") (string= host ""))
1297               (erc-display-message parsed 'notice buf
1298                                    'MODE-nick ?n nick
1299                                    ?t tgt ?m mode)
1300             (erc-display-message parsed 'notice buf
1301                                  'MODE ?n nick ?u login
1302                                  ?h host ?t tgt ?m mode)))
1303       (erc-banlist-update proc parsed))))
1304
1305 (define-erc-response-handler (NICK)
1306   "Handle nick change messages." nil
1307   (let ((nn (erc-response.contents parsed))
1308         bufs)
1309     (pcase-let ((`(,nick ,login ,host)
1310                  (erc-parse-user (erc-response.sender parsed))))
1311       (setq bufs (erc-buffer-list-with-nick nick proc))
1312       (erc-log (format "NICK: %s -> %s" nick nn))
1313       ;; if we had a query with this user, make sure future messages will be
1314       ;; sent to the correct nick. also add to bufs, since the user will want
1315       ;; to see the nick change in the query, and if it's a newly begun query,
1316       ;; erc-channel-users won't contain it
1317       (erc-buffer-filter
1318        (lambda ()
1319          (when (equal (erc-default-target) nick)
1320            (setq erc-default-recipients
1321                  (cons nn (cdr erc-default-recipients)))
1322            (rename-buffer nn t)         ; bug#12002
1323            (erc-update-mode-line)
1324            (add-to-list 'bufs (current-buffer)))))
1325       (erc-update-user-nick nick nn host nil nil login)
1326       (cond
1327        ((string= nick (erc-current-nick))
1328         (add-to-list 'bufs (erc-server-buffer))
1329         (erc-set-current-nick nn)
1330         (erc-update-mode-line)
1331         (setq erc-nick-change-attempt-count 0)
1332         (setq erc-default-nicks (if (consp erc-nick) erc-nick (list erc-nick)))
1333         (erc-display-message
1334          parsed 'notice bufs
1335          'NICK-you ?n nick ?N nn)
1336         (run-hook-with-args 'erc-nick-changed-functions nn nick))
1337        (t
1338         (erc-handle-user-status-change 'nick (list nick login host) (list nn))
1339         (erc-display-message parsed 'notice bufs 'NICK ?n nick
1340                              ?u login ?h host ?N nn))))))
1341
1342 (define-erc-response-handler (PART)
1343   "Handle part messages." nil
1344   (let* ((chnl (car (erc-response.command-args parsed)))
1345          (reason (erc-trim-string (erc-response.contents parsed)))
1346          (buffer (erc-get-buffer chnl proc)))
1347     (pcase-let ((`(,nick ,login ,host)
1348                  (erc-parse-user (erc-response.sender parsed))))
1349       (erc-remove-channel-member buffer nick)
1350       (erc-display-message parsed 'notice buffer
1351                            'PART ?n nick ?u login
1352                            ?h host ?c chnl ?r (or reason ""))
1353       (when (string= nick (erc-current-nick))
1354         (run-hook-with-args 'erc-part-hook buffer)
1355         (erc-with-buffer
1356             (buffer)
1357           (erc-remove-channel-users))
1358         (erc-delete-default-channel chnl buffer)
1359         (erc-update-mode-line buffer)
1360         (when erc-kill-buffer-on-part
1361           (kill-buffer buffer))))))
1362
1363 (define-erc-response-handler (PING)
1364   "Handle ping messages." nil
1365   (let ((pinger (car (erc-response.command-args parsed))))
1366     (erc-log (format "PING: %s" pinger))
1367     ;; ping response to the server MUST be forced, or you can lose big
1368     (erc-server-send (format "PONG :%s" pinger) t)
1369     (when erc-verbose-server-ping
1370       (erc-display-message
1371        parsed 'error proc
1372        'PING ?s (erc-time-diff erc-server-last-ping-time (erc-current-time))))
1373     (setq erc-server-last-ping-time (erc-current-time))))
1374
1375 (define-erc-response-handler (PONG)
1376   "Handle pong messages." nil
1377   (let ((time (string-to-number (erc-response.contents parsed))))
1378     (when (> time 0)
1379       (setq erc-server-lag (erc-time-diff time (erc-current-time)))
1380       (when erc-verbose-server-ping
1381         (erc-display-message
1382          parsed 'notice proc 'PONG
1383          ?h (car (erc-response.command-args parsed)) ?i erc-server-lag
1384          ?s (if (/= erc-server-lag 1) "s" "")))
1385       (erc-update-mode-line))))
1386
1387 (define-erc-response-handler (PRIVMSG NOTICE)
1388   "Handle private messages, including messages in channels." nil
1389   (let ((sender-spec (erc-response.sender parsed))
1390         (cmd (erc-response.command parsed))
1391         (tgt (car (erc-response.command-args parsed)))
1392         (msg (erc-response.contents parsed)))
1393     (if (or (erc-ignored-user-p sender-spec)
1394             (erc-ignored-reply-p msg tgt proc))
1395         (when erc-minibuffer-ignored
1396           (message "Ignored %s from %s to %s" cmd sender-spec tgt))
1397       (let* ((sndr (erc-parse-user sender-spec))
1398              (nick (nth 0 sndr))
1399              (login (nth 1 sndr))
1400              (host (nth 2 sndr))
1401              (msgp (string= cmd "PRIVMSG"))
1402              (noticep (string= cmd "NOTICE"))
1403              ;; S.B. downcase *both* tgt and current nick
1404              (privp (erc-current-nick-p tgt))
1405              s buffer
1406              fnick)
1407         (setf (erc-response.contents parsed) msg)
1408         (setq buffer (erc-get-buffer (if privp nick tgt) proc))
1409         (when buffer
1410           (with-current-buffer buffer
1411             ;; update the chat partner info.  Add to the list if private
1412             ;; message.  We will accumulate private identities indefinitely
1413             ;; at this point.
1414             (erc-update-channel-member (if privp nick tgt) nick nick
1415                                        privp nil nil nil nil nil host login nil nil t)
1416             (let ((cdata (erc-get-channel-user nick)))
1417               (setq fnick (funcall erc-format-nick-function
1418                                    (car cdata) (cdr cdata))))))
1419         (cond
1420          ((erc-is-message-ctcp-p msg)
1421           (setq s (if msgp
1422                       (erc-process-ctcp-query proc parsed nick login host)
1423                     (erc-process-ctcp-reply proc parsed nick login host
1424                                             (match-string 1 msg)))))
1425          (t
1426           (setcar erc-server-last-peers nick)
1427           (setq s (erc-format-privmessage
1428                    (or fnick nick) msg
1429                    ;; If buffer is a query buffer,
1430                    ;; format the nick as for a channel.
1431                    (and (not (and buffer
1432                                   (erc-query-buffer-p buffer)
1433                                   erc-format-query-as-channel-p))
1434                         privp)
1435                    msgp))))
1436         (when s
1437           (if (and noticep privp)
1438               (progn
1439                 (run-hook-with-args 'erc-echo-notice-always-hook
1440                                     s parsed buffer nick)
1441                 (run-hook-with-args-until-success
1442                  'erc-echo-notice-hook s parsed buffer nick))
1443             (erc-display-message parsed nil buffer s)))
1444         (when (string= cmd "PRIVMSG")
1445           (erc-auto-query proc parsed))))))
1446
1447 ;; FIXME: need clean way of specifying extra hooks in
1448 ;; define-erc-response-handler.
1449 (add-hook 'erc-server-PRIVMSG-functions 'erc-auto-query)
1450
1451 (define-erc-response-handler (QUIT)
1452   "Another user has quit IRC." nil
1453   (let ((reason (erc-response.contents parsed))
1454         bufs)
1455     (pcase-let ((`(,nick ,login ,host)
1456                  (erc-parse-user (erc-response.sender parsed))))
1457       (setq bufs (erc-buffer-list-with-nick nick proc))
1458       (erc-remove-user nick)
1459       (setq reason (erc-wash-quit-reason reason nick login host))
1460       (erc-display-message parsed 'notice bufs
1461                            'QUIT ?n nick ?u login
1462                            ?h host ?r reason))))
1463
1464 (define-erc-response-handler (TOPIC)
1465   "The channel topic has changed." nil
1466   (let* ((ch (car (erc-response.command-args parsed)))
1467          (topic (erc-trim-string (erc-response.contents parsed)))
1468          (time (format-time-string erc-server-timestamp-format
1469                                    (current-time))))
1470     (pcase-let ((`(,nick ,login ,host)
1471                  (erc-parse-user (erc-response.sender parsed))))
1472       (erc-update-channel-member ch nick nick nil nil nil nil nil nil host login)
1473       (erc-update-channel-topic ch (format "%s\C-o (%s, %s)" topic nick time))
1474       (erc-display-message parsed 'notice (erc-get-buffer ch proc)
1475                            'TOPIC ?n nick ?u login ?h host
1476                            ?c ch ?T topic))))
1477
1478 (define-erc-response-handler (WALLOPS)
1479   "Display a WALLOPS message." nil
1480   (let ((message (erc-response.contents parsed)))
1481     (pcase-let ((`(,nick ,login ,host)
1482                  (erc-parse-user (erc-response.sender parsed))))
1483       (erc-display-message
1484        parsed 'notice nil
1485        'WALLOPS ?n nick ?m message))))
1486
1487 (define-erc-response-handler (001)
1488   "Set `erc-server-current-nick' to reflect server settings and display the welcome message."
1489   nil
1490   (erc-set-current-nick (car (erc-response.command-args parsed)))
1491   (erc-update-mode-line)                ; needed here?
1492   (setq erc-nick-change-attempt-count 0)
1493   (setq erc-default-nicks (if (consp erc-nick) erc-nick (list erc-nick)))
1494   (erc-display-message
1495    parsed 'notice 'active (erc-response.contents parsed)))
1496
1497 (define-erc-response-handler (MOTD 002 003 371 372 374 375)
1498   "Display the server's message of the day." nil
1499   (erc-handle-login)
1500   (erc-display-message
1501    parsed 'notice (if erc-server-connected 'active proc)
1502    (erc-response.contents parsed)))
1503
1504 (define-erc-response-handler (376 422)
1505   "End of MOTD/MOTD is missing." nil
1506   (erc-server-MOTD proc parsed)
1507   (erc-connection-established proc parsed))
1508
1509 (define-erc-response-handler (004)
1510   "Display the server's identification." nil
1511   (pcase-let ((`(,server-name ,server-version)
1512                (cdr (erc-response.command-args parsed))))
1513     (setq erc-server-version server-version)
1514     (setq erc-server-announced-name server-name)
1515     (erc-update-mode-line-buffer (process-buffer proc))
1516     (erc-display-message
1517      parsed 'notice proc
1518      's004 ?s server-name ?v server-version
1519      ?U (nth 3 (erc-response.command-args parsed))
1520      ?C (nth 4 (erc-response.command-args parsed)))))
1521
1522 (define-erc-response-handler (005)
1523   "Set the variable `erc-server-parameters' and display the received message.
1524
1525 According to RFC 2812, suggests alternate servers on the network.
1526 Many servers, however, use this code to show which parameters they have set,
1527 for example, the network identifier, maximum allowed topic length, whether
1528 certain commands are accepted and more.  See documentation for
1529 `erc-server-parameters' for more information on the parameters sent.
1530
1531 A server may send more than one 005 message."
1532   nil
1533   (let ((line (mapconcat 'identity
1534                          (setf (erc-response.command-args parsed)
1535                                (cdr (erc-response.command-args parsed)))
1536                          " ")))
1537     (while (erc-response.command-args parsed)
1538       (let ((section (pop (erc-response.command-args parsed))))
1539         ;; fill erc-server-parameters
1540         (when (string-match "^\\([A-Z]+\\)\=\\(.*\\)$\\|^\\([A-Z]+\\)$"
1541                             section)
1542           (add-to-list 'erc-server-parameters
1543                        `(,(or (match-string 1 section)
1544                               (match-string 3 section))
1545                          .
1546                          ,(match-string 2 section))))))
1547     (erc-display-message parsed 'notice proc line)))
1548
1549 (define-erc-response-handler (221)
1550   "Display the current user modes." nil
1551   (let* ((nick (car (erc-response.command-args parsed)))
1552          (modes (mapconcat 'identity
1553                            (cdr (erc-response.command-args parsed)) " ")))
1554     (erc-set-modes nick modes)
1555     (erc-display-message parsed 'notice 'active 's221 ?n nick ?m modes)))
1556
1557 (define-erc-response-handler (252)
1558   "Display the number of IRC operators online." nil
1559   (erc-display-message parsed 'notice 'active 's252
1560                        ?i (cadr (erc-response.command-args parsed))))
1561
1562 (define-erc-response-handler (253)
1563   "Display the number of unknown connections." nil
1564   (erc-display-message parsed 'notice 'active 's253
1565                        ?i (cadr (erc-response.command-args parsed))))
1566
1567 (define-erc-response-handler (254)
1568   "Display the number of channels formed." nil
1569   (erc-display-message parsed 'notice 'active 's254
1570                        ?i (cadr (erc-response.command-args parsed))))
1571
1572 (define-erc-response-handler (250 251 255 256 257 258 259 265 266 377 378)
1573   "Generic display of server messages as notices.
1574
1575 See `erc-display-server-message'." nil
1576   (erc-display-server-message proc parsed))
1577
1578 (define-erc-response-handler (275)
1579   "Display secure connection message." nil
1580   (pcase-let ((`(,nick ,user ,message)
1581                (cdr (erc-response.command-args parsed))))
1582     (erc-display-message
1583      parsed 'notice 'active 's275
1584      ?n nick
1585      ?m (mapconcat 'identity (cddr (erc-response.command-args parsed))
1586                    " "))))
1587
1588 (define-erc-response-handler (290)
1589   "Handle dancer-ircd CAPAB messages." nil nil)
1590
1591 (define-erc-response-handler (301)
1592   "AWAY notice." nil
1593   (erc-display-message parsed 'notice 'active 's301
1594                        ?n (cadr (erc-response.command-args parsed))
1595                        ?r (erc-response.contents parsed)))
1596
1597 (define-erc-response-handler (303)
1598   "ISON reply" nil
1599   (erc-display-message parsed 'notice 'active 's303
1600                        ?n (cadr (erc-response.command-args parsed))))
1601
1602 (define-erc-response-handler (305)
1603   "Return from AWAYness." nil
1604   (erc-process-away proc nil)
1605   (erc-display-message parsed 'notice 'active
1606                        's305 ?m (erc-response.contents parsed)))
1607
1608 (define-erc-response-handler (306)
1609   "Set AWAYness." nil
1610   (erc-process-away proc t)
1611   (erc-display-message parsed 'notice 'active
1612                        's306 ?m (erc-response.contents parsed)))
1613
1614 (define-erc-response-handler (307)
1615   "Display nick-identified message." nil
1616   (pcase-let ((`(,nick ,user ,message)
1617                (cdr (erc-response.command-args parsed))))
1618     (erc-display-message
1619      parsed 'notice 'active 's307
1620      ?n nick
1621      ?m (mapconcat 'identity (cddr (erc-response.command-args parsed))
1622                    " "))))
1623
1624 (define-erc-response-handler (311 314)
1625   "WHOIS/WHOWAS notices." nil
1626   (let ((fname (erc-response.contents parsed))
1627         (catalog-entry (intern (format "s%s" (erc-response.command parsed)))))
1628     (pcase-let ((`(,nick ,user ,host)
1629                  (cdr (erc-response.command-args parsed))))
1630       (erc-update-user-nick nick nick host nil fname user)
1631       (erc-display-message
1632        parsed 'notice 'active catalog-entry
1633        ?n nick ?f fname ?u user ?h host))))
1634
1635 (define-erc-response-handler (312)
1636   "Server name response in WHOIS." nil
1637   (pcase-let ((`(,nick ,server-host)
1638               (cdr (erc-response.command-args parsed))))
1639     (erc-display-message
1640      parsed 'notice 'active 's312
1641      ?n nick ?s server-host ?c (erc-response.contents parsed))))
1642
1643 (define-erc-response-handler (313)
1644   "IRC Operator response in WHOIS." nil
1645   (erc-display-message
1646    parsed 'notice 'active 's313
1647    ?n (cadr (erc-response.command-args parsed))))
1648
1649 (define-erc-response-handler (315 318 323 369)
1650   ;; 315 - End of WHO
1651   ;; 318 - End of WHOIS list
1652   ;; 323 - End of channel LIST
1653   ;; 369 - End of WHOWAS
1654   "End of WHO/WHOIS/LIST/WHOWAS notices." nil
1655   (ignore proc parsed))
1656
1657 (define-erc-response-handler (317)
1658   "IDLE notice." nil
1659   (pcase-let ((`(,nick ,seconds-idle ,on-since ,time)
1660                (cdr (erc-response.command-args parsed))))
1661     (setq time (when on-since
1662                  (format-time-string erc-server-timestamp-format
1663                                      (erc-string-to-emacs-time on-since))))
1664     (erc-update-user-nick nick nick nil nil nil
1665                           (and time (format "on since %s" time)))
1666     (if time
1667         (erc-display-message
1668          parsed 'notice 'active 's317-on-since
1669          ?n nick ?i (erc-sec-to-time (string-to-number seconds-idle)) ?t time)
1670       (erc-display-message
1671        parsed 'notice 'active 's317
1672        ?n nick ?i (erc-sec-to-time (string-to-number seconds-idle))))))
1673
1674 (define-erc-response-handler (319)
1675   "Channel names in WHOIS response." nil
1676   (erc-display-message
1677    parsed 'notice 'active 's319
1678    ?n (cadr (erc-response.command-args parsed))
1679    ?c (erc-response.contents parsed)))
1680
1681 (define-erc-response-handler (320)
1682   "Identified user in WHOIS." nil
1683   (erc-display-message
1684    parsed 'notice 'active 's320
1685    ?n (cadr (erc-response.command-args parsed))))
1686
1687 (define-erc-response-handler (321)
1688   "LIST header." nil
1689   (setq erc-channel-list nil))
1690
1691 (defun erc-server-321-message (proc parsed)
1692   "Display a message for the 321 event."
1693   (erc-display-message parsed 'notice proc 's321)
1694   nil)
1695 (add-hook 'erc-server-321-functions 'erc-server-321-message t)
1696
1697 (define-erc-response-handler (322)
1698   "LIST notice." nil
1699   (let ((topic (erc-response.contents parsed)))
1700     (pcase-let ((`(,channel ,num-users)
1701                  (cdr (erc-response.command-args parsed))))
1702       (add-to-list 'erc-channel-list (list channel))
1703       (erc-update-channel-topic channel topic))))
1704
1705 (defun erc-server-322-message (proc parsed)
1706   "Display a message for the 322 event."
1707   (let ((topic (erc-response.contents parsed)))
1708     (pcase-let ((`(,channel ,num-users)
1709                  (cdr (erc-response.command-args parsed))))
1710       (erc-display-message
1711        parsed 'notice proc 's322
1712        ?c channel ?u num-users ?t (or topic "")))))
1713 (add-hook 'erc-server-322-functions 'erc-server-322-message t)
1714
1715 (define-erc-response-handler (324)
1716   "Channel or nick modes." nil
1717   (let ((channel (cadr (erc-response.command-args parsed)))
1718         (modes (mapconcat 'identity (cddr (erc-response.command-args parsed))
1719                           " ")))
1720     (erc-set-modes channel modes)
1721     (erc-display-message
1722      parsed 'notice (erc-get-buffer channel proc)
1723      's324 ?c channel ?m modes)))
1724
1725 (define-erc-response-handler (328)
1726   "Channel URL (on freenode network)." nil
1727   (let ((channel (cadr (erc-response.command-args parsed)))
1728         (url (erc-response.contents parsed)))
1729     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1730                          's328 ?c channel ?u url)))
1731
1732 (define-erc-response-handler (329)
1733   "Channel creation date." nil
1734   (let ((channel (cadr (erc-response.command-args parsed)))
1735         (time (erc-string-to-emacs-time
1736                (nth 2 (erc-response.command-args parsed)))))
1737     (erc-display-message
1738      parsed 'notice (erc-get-buffer channel proc)
1739      's329 ?c channel ?t (format-time-string erc-server-timestamp-format
1740                                              time))))
1741
1742 (define-erc-response-handler (330)
1743   "Nick is authed as (on Quakenet network)." nil
1744   ;; FIXME: I don't know what the magic numbers mean.  Mummy, make
1745   ;; the magic numbers go away.
1746   ;; No seriously, I have no clue about the format of this command,
1747   ;; and don't sit on Quakenet, so can't test.  Originally we had:
1748   ;; nick == (aref parsed 3)
1749   ;; authaccount == (aref parsed 4)
1750   ;; authmsg == (aref parsed 5)
1751   ;; The guesses below are, well, just that. -- Lawrence 2004/05/10
1752   (let ((nick (cadr (erc-response.command-args parsed)))
1753         (authaccount (nth 2 (erc-response.command-args parsed)))
1754         (authmsg (erc-response.contents parsed)))
1755     (erc-display-message parsed 'notice 'active 's330
1756                          ?n nick ?a authmsg ?i authaccount)))
1757
1758 (define-erc-response-handler (331)
1759   "No topic set for channel." nil
1760   (let ((channel (cadr (erc-response.command-args parsed)))
1761         (topic (erc-response.contents parsed)))
1762     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1763                          's331 ?c channel)))
1764
1765 (define-erc-response-handler (332)
1766   "TOPIC notice." nil
1767   (let ((channel (cadr (erc-response.command-args parsed)))
1768         (topic (erc-response.contents parsed)))
1769     (erc-update-channel-topic channel topic)
1770     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1771                          's332 ?c channel ?T topic)))
1772
1773 (define-erc-response-handler (333)
1774   "Who set the topic, and when." nil
1775   (pcase-let ((`(,channel ,nick ,time)
1776                (cdr (erc-response.command-args parsed))))
1777     (setq time (format-time-string erc-server-timestamp-format
1778                                    (erc-string-to-emacs-time time)))
1779     (erc-update-channel-topic channel
1780                               (format "\C-o (%s, %s)" nick time)
1781                               'append)
1782     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1783                          's333 ?c channel ?n nick ?t time)))
1784
1785 (define-erc-response-handler (341)
1786   "Let user know when an INVITE attempt has been sent successfully."
1787   nil
1788   (pcase-let ((`(,nick ,channel)
1789                (cdr (erc-response.command-args parsed))))
1790     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1791                          's341 ?n nick ?c channel)))
1792
1793 (define-erc-response-handler (352)
1794   "WHO notice." nil
1795   (pcase-let ((`(,channel ,user ,host ,server ,nick ,away-flag)
1796                (cdr (erc-response.command-args parsed))))
1797     (let ((full-name (erc-response.contents parsed))
1798           hopcount)
1799       (when (string-match "\\(^[0-9]+ \\)\\(.*\\)$" full-name)
1800         (setq hopcount (match-string 1 full-name))
1801         (setq full-name (match-string 2 full-name)))
1802       (erc-update-channel-member channel nick nick nil nil nil nil nil nil host user full-name)
1803       (erc-display-message parsed 'notice 'active 's352
1804                            ?c channel ?n nick ?a away-flag
1805                            ?u user ?h host ?f full-name))))
1806
1807 (define-erc-response-handler (353)
1808   "NAMES notice." nil
1809   (let ((channel (nth 2 (erc-response.command-args parsed)))
1810         (users (erc-response.contents parsed)))
1811     (erc-display-message parsed 'notice (or (erc-get-buffer channel proc)
1812                                             'active)
1813                          's353 ?c channel ?u users)
1814     (erc-with-buffer (channel proc)
1815       (erc-channel-receive-names users))))
1816
1817 (define-erc-response-handler (366)
1818   "End of NAMES." nil
1819   (erc-with-buffer ((cadr (erc-response.command-args parsed)) proc)
1820     (erc-channel-end-receiving-names)))
1821
1822 (define-erc-response-handler (367)
1823   "Channel ban list entries." nil
1824   (pcase-let ((`(,channel ,banmask ,setter ,time)
1825                (cdr (erc-response.command-args parsed))))
1826     ;; setter and time are not standard
1827     (if setter
1828         (erc-display-message parsed 'notice 'active 's367-set-by
1829                              ?c channel
1830                              ?b banmask
1831                              ?s setter
1832                              ?t (or time ""))
1833       (erc-display-message parsed 'notice 'active 's367
1834                            ?c channel
1835                            ?b banmask))))
1836
1837 (define-erc-response-handler (368)
1838   "End of channel ban list." nil
1839   (let ((channel (cadr (erc-response.command-args parsed))))
1840     (erc-display-message parsed 'notice 'active 's368
1841                          ?c channel)))
1842
1843 (define-erc-response-handler (379)
1844   "Forwarding to another channel." nil
1845   ;; FIXME: Yet more magic numbers in original code, I'm guessing this
1846   ;; command takes two arguments, and doesn't have any "contents". --
1847   ;; Lawrence 2004/05/10
1848   (pcase-let ((`(,from ,to)
1849                (cdr (erc-response.command-args parsed))))
1850     (erc-display-message parsed 'notice 'active
1851                          's379 ?c from ?f to)))
1852
1853 (define-erc-response-handler (391)
1854   "Server's time string." nil
1855   (erc-display-message
1856    parsed 'notice 'active
1857    's391 ?s (cadr (erc-response.command-args parsed))
1858    ?t (nth 2 (erc-response.command-args parsed))))
1859
1860 (define-erc-response-handler (401)
1861   "No such nick/channel." nil
1862   (let ((nick/channel (cadr (erc-response.command-args parsed))))
1863     (when erc-whowas-on-nosuchnick
1864       (erc-log (format "cmd: WHOWAS: %s" nick/channel))
1865       (erc-server-send (format "WHOWAS %s 1" nick/channel)))
1866     (erc-display-message parsed '(notice error) 'active
1867                          's401 ?n nick/channel)))
1868
1869 (define-erc-response-handler (403)
1870   "No such channel." nil
1871   (erc-display-message parsed '(notice error) 'active
1872                        's403 ?c (cadr (erc-response.command-args parsed))))
1873
1874 (define-erc-response-handler (404)
1875   "Cannot send to channel." nil
1876   (erc-display-message parsed '(notice error) 'active
1877                        's404 ?c (cadr (erc-response.command-args parsed))))
1878
1879
1880 (define-erc-response-handler (405)
1881   "Can't join that many channels." nil
1882   (erc-display-message parsed '(notice error) 'active
1883                        's405 ?c (cadr (erc-response.command-args parsed))))
1884
1885 (define-erc-response-handler (406)
1886   "No such nick." nil
1887   (erc-display-message parsed '(notice error) 'active
1888                        's406 ?n (cadr (erc-response.command-args parsed))))
1889
1890 (define-erc-response-handler (412)
1891   "No text to send." nil
1892   (erc-display-message parsed '(notice error) 'active 's412))
1893
1894 (define-erc-response-handler (421)
1895   "Unknown command." nil
1896   (erc-display-message parsed '(notice error) 'active 's421
1897                        ?c (cadr (erc-response.command-args parsed))))
1898
1899 (define-erc-response-handler (432)
1900   "Bad nick." nil
1901   (erc-display-message parsed '(notice error) 'active 's432
1902                        ?n (cadr (erc-response.command-args parsed))))
1903
1904 (define-erc-response-handler (433)
1905   "Login-time \"nick in use\"." nil
1906   (erc-nickname-in-use (cadr (erc-response.command-args parsed))
1907                        "already in use"))
1908
1909 (define-erc-response-handler (437)
1910   "Nick temporarily unavailable (on IRCnet)." nil
1911   (let ((nick/channel (cadr (erc-response.command-args parsed))))
1912     (unless (erc-channel-p nick/channel)
1913       (erc-nickname-in-use nick/channel "temporarily unavailable"))))
1914
1915 (define-erc-response-handler (442)
1916   "Not on channel." nil
1917   (erc-display-message parsed '(notice error) 'active 's442
1918                        ?c (cadr (erc-response.command-args parsed))))
1919
1920 (define-erc-response-handler (461)
1921   "Not enough parameters for command." nil
1922   (erc-display-message parsed '(notice error)  'active 's461
1923                        ?c (cadr (erc-response.command-args parsed))
1924                        ?m (erc-response.contents parsed)))
1925
1926 (define-erc-response-handler (465)
1927   "You are banned from this server." nil
1928   (setq erc-server-banned t)
1929   ;; show the server's message, as a reason might be provided
1930   (erc-display-error-notice
1931    parsed
1932    (erc-response.contents parsed)))
1933
1934 (define-erc-response-handler (474)
1935   "Banned from channel errors." nil
1936   (erc-display-message parsed '(notice error) nil
1937                        (intern (format "s%s"
1938                                        (erc-response.command parsed)))
1939                        ?c (cadr (erc-response.command-args parsed))))
1940
1941 (define-erc-response-handler (475)
1942   "Channel key needed." nil
1943   (erc-display-message parsed '(notice error) nil 's475
1944                        ?c (cadr (erc-response.command-args parsed)))
1945   (when erc-prompt-for-channel-key
1946     (let ((channel (cadr (erc-response.command-args parsed)))
1947           (key (read-from-minibuffer
1948                 (format "Channel %s is mode +k.  Enter key (RET to cancel): "
1949                         (cadr (erc-response.command-args parsed))))))
1950       (when (and key (> (length key) 0))
1951           (erc-cmd-JOIN channel key)))))
1952
1953 (define-erc-response-handler (477)
1954   "Channel doesn't support modes." nil
1955   (let ((channel (cadr (erc-response.command-args parsed)))
1956         (message (erc-response.contents parsed)))
1957     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1958                          (format "%s: %s" channel message))))
1959
1960 (define-erc-response-handler (482)
1961   "You need to be a channel operator to do that." nil
1962   (let ((channel (cadr (erc-response.command-args parsed)))
1963         (message (erc-response.contents parsed)))
1964     (erc-display-message parsed '(error notice) 'active 's482
1965                          ?c channel ?m message)))
1966
1967 (define-erc-response-handler (671)
1968   "Secure connection response in WHOIS." nil
1969   (let ((nick (cadr (erc-response.command-args parsed)))
1970         (securemsg (erc-response.contents parsed)))
1971     (erc-display-message parsed 'notice 'active 's671
1972                          ?n nick ?a securemsg)))
1973
1974 (define-erc-response-handler (431 445 446 451 462 463 464 481 483 484 485
1975                                   491 501 502)
1976   ;; 431 - No nickname given
1977   ;; 445 - SUMMON has been disabled
1978   ;; 446 - USERS has been disabled
1979   ;; 451 - You have not registered
1980   ;; 462 - Unauthorized command (already registered)
1981   ;; 463 - Your host isn't among the privileged
1982   ;; 464 - Password incorrect
1983   ;; 481 - Need IRCop privileges
1984   ;; 483 - You can't kill a server!
1985   ;; 484 - Your connection is restricted!
1986   ;; 485 - You're not the original channel operator
1987   ;; 491 - No O-lines for your host
1988   ;; 501 - Unknown MODE flag
1989   ;; 502 - Cannot change mode for other users
1990   "Generic display of server error messages.
1991
1992 See `erc-display-error-notice'." nil
1993   (erc-display-error-notice
1994    parsed
1995    (intern (format "s%s" (erc-response.command parsed)))))
1996
1997 ;; FIXME: These are yet to be implemented, they're just stubs for now
1998 ;; -- Lawrence 2004/05/12
1999
2000 ;; response numbers left here for reference
2001
2002 ;; (define-erc-response-handler (323 364 365 381 382 392 393 394 395
2003 ;;                               200 201 202 203 204 205 206 208 209 211 212 213
2004 ;;                               214 215 216 217 218 219 241 242 243 244 249 261
2005 ;;                               262 302 342 351 402 407 409 411 413 414 415
2006 ;;                               423 424 436 441 443 444 467 471 472 473 KILL)
2007 ;;   nil nil
2008 ;;   (ignore proc parsed))
2009
2010 (provide 'erc-backend)
2011
2012 ;;; erc-backend.el ends here
2013 ;; Local Variables:
2014 ;; indent-tabs-mode: nil
2015 ;; End: