code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the 'configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2016 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 25.1.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in "$@" CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140
 141 case $host in
 142  *-mingw*)
 143
 144   if test -z "$host_alias"; then
 145
 146       # No --host argument was given to 'configure'; therefore $host
 147       # was set to a default value based on the build platform.  But
 148       # this default value may be wrong if we are building from a
 149       # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
 150       # Therefore, we'll try to get the right host platform from the
 151       # compiler's target.
 152
 153       AC_MSG_CHECKING([the compiler's target])
 154       if test -z "$CC"; then
 155           cc=gcc
 156       else
 157           cc=$CC
 158       fi
 159       cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
 160       case "$cc_target" in
 161           *-*) host=$cc_target
 162               ;;
 163           "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
 164 Please explicitly provide --host.])
 165               ;;
 166           *) AC_MSG_WARN([Compiler reported non-standard target.
 167 Defaulting to $host.])
 168               ;;
 169       esac
 170       AC_MSG_RESULT([$host])
 171   fi
 172
 173   . $srcdir/nt/mingw-cfg.site
 174
 175   case $srcdir in
 176     /* | ?:*)
 177       # srcdir is an absolute path.  In this case, force the format
 178       # "/c/foo/bar", to simplify later conversions to native Windows
 179       # format ("c:/foo/bar").
 180       srcdir=`cd "${srcdir}" && pwd -W`
 181       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
 182       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
 183       ;;
 184   esac;;
 185 esac
 186
 187 canonical=$host
 188 configuration=${host_alias-${build_alias-$host}}
 189
 190 dnl Support for --program-prefix, --program-suffix and
 191 dnl --program-transform-name options
 192 AC_ARG_PROGRAM
 193
 194 dnl It is important that variables on the RHS not be expanded here,
 195 dnl hence the single quotes.  This is per the GNU coding standards, see
 196 dnl (autoconf) Installation Directory Variables
 197 dnl See also epaths.h below.
 198 lispdir='${datadir}/emacs/${version}/lisp'
 199 standardlisppath='${lispdir}'
 200 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 201 '${datadir}/emacs/site-lisp'
 202 lisppath='${locallisppath}:${standardlisppath}'
 203 etcdir='${datadir}/emacs/${version}/etc'
 204 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 205 etcdocdir='${datadir}/emacs/${version}/etc'
 206 gamedir='${localstatedir}/games/emacs'
 207
 208 dnl Special option to disable the most of other options.
 209 AC_ARG_WITH(all,
 210 [AS_HELP_STRING([--without-all],
 211                 [omit almost all features and build
 212                 small executable with minimal dependencies])],
 213   [with_features=$withval],
 214   [with_features=yes])
 215
 216 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 217 dnl Create a new --with option that defaults to being disabled.
 218 dnl NAME is the base name of the option.  The shell variable with_NAME
 219 dnl   will be set to either the user's value (if the option is
 220 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 221 dnl   option is not specified).  Note that the shell variable name is
 222 dnl   constructed as autoconf does, by replacing non-alphanumeric
 223 dnl   characters with "_".
 224 dnl HELP-STRING is the help text for the option.
 225 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 226   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 227     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 228 ])dnl
 229
 230 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 231 dnl Create a new --with option that defaults to $with_features.
 232 dnl NAME is the base name of the option.  The shell variable with_NAME
 233 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 234 dnl   'yes' (if the option is not specified).  Note that the shell
 235 dnl   variable name is constructed as autoconf does, by replacing
 236 dnl   non-alphanumeric characters with "_".
 237 dnl HELP-STRING is the help text for the option.
 238 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 239   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 240    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 241 ])dnl
 242
 243 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 244 if test "$with_pop" = yes; then
 245    AC_DEFINE(MAIL_USE_POP)
 246 fi
 247 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 248
 249 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 250 if test "$with_kerberos" != no; then
 251    AC_DEFINE(KERBEROS)
 252 fi
 253 AH_TEMPLATE(KERBEROS,
 254             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 255
 256 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 257 if test "${with_kerberos5}" != no; then
 258   if test "${with_kerberos}" = no; then
 259     with_kerberos=yes
 260     AC_DEFINE(KERBEROS)
 261   fi
 262   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 263 fi
 264
 265 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 266 dnl FIXME hesiod support may not be present, so it seems like an error
 267 dnl to define, or at least use, this unconditionally.
 268 if test "$with_hesiod" != no; then
 269   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 270 fi
 271
 272 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 273 if test "$with_mail_unlink" != no; then
 274    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 275 fi
 276
 277 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 278     [string giving default POP mail host])],
 279     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 280
 281 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 282   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 283 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
 284   [ case "${withval}" in
 285       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 286       *) AC_MSG_ERROR(['--with-sound=$withval' is invalid;
 287 this option's value should be 'yes', 'no', 'alsa', 'oss', or 'bsd-ossaudio'.])
 288       ;;
 289     esac
 290     with_sound=$val
 291   ],
 292   [with_sound=$with_features])
 293
 294 dnl FIXME currently it is not the last.
 295 dnl This should be the last --with option, because --with-x is
 296 dnl added later on when we find the file name of X, and it's best to
 297 dnl keep them together visually.
 298 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 299  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 300 [         case "${withval}" in
 301             y | ye | yes )      val=gtk ;;
 302             n | no )            val=no  ;;
 303             l | lu | luc | luci | lucid )       val=lucid ;;
 304             a | at | ath | athe | athen | athena )      val=athena ;;
 305             m | mo | mot | moti | motif )       val=motif ;;
 306             g | gt | gtk  )     val=gtk ;;
 307             gtk2  )     val=gtk2 ;;
 308             gtk3  )     val=gtk3 ;;
 309             * )
 310 AC_MSG_ERROR(['--with-x-toolkit=$withval' is invalid;
 311 this option's value should be 'yes', 'no', 'lucid', 'athena', 'motif', 'gtk',
 312 'gtk2' or 'gtk3'.  'yes' and 'gtk' are synonyms.
 313 'athena' and 'lucid' are synonyms.])
 314             ;;
 315           esac
 316           with_x_toolkit=$val
 317 ])
 318
 319 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit); allows buffer and string size up to 2GB on 32-bit hosts, at the cost of 10% to 30% slowdown of Lisp interpreter and larger memory footprint])
 320 if test "$with_wide_int" = yes; then
 321   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 322 fi
 323
 324 dnl _ON results in a '--without' option in the --help output, so
 325 dnl the help text should refer to "don't compile", etc.
 326 with_xpm_set=${with_xpm+set}
 327 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 328 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 329 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 330 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 331 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 332 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 333 OPTION_DEFAULT_ON([libsystemd],[don't compile with libsystemd support])
 334 OPTION_DEFAULT_OFF([cairo],[compile with Cairo drawing (experimental)])
 335 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 336 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 337
 338 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 339 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 340 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 341
 342 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 343 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 344 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 345 AC_ARG_WITH([ns],[AS_HELP_STRING([--with-ns],
 346 [use Nextstep (OS X Cocoa or GNUstep) windowing system.
 347 On by default on Mac OS X.])],[],[with_ns=maybe])
 348 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 349
 350 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 351 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 352 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 353 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 354 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 355 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 356 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 357 OPTION_DEFAULT_OFF([modules],[compile with dynamic modules support])
 358
 359 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 360  [use a file notification library (LIB one of: yes, inotify, kqueue, gfile, w32, no)])],
 361  [ case "${withval}" in
 362     y | ye | yes )      val=yes ;;
 363     n | no )            val=no  ;;
 364     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 365     k | kq | kqu | kque | kqueu | kqueue )      val=kqueue ;;
 366     g | gf | gfi | gfil | gfile )       val=gfile ;;
 367     w | w3 | w32 )      val=w32 ;;
 368     * ) AC_MSG_ERROR(['--with-file-notification=$withval' is invalid;
 369 this option's value should be 'yes', 'no', 'inotify', 'kqueue', 'gfile' or 'w32'.
 370 'yes' is a synonym for 'w32' on MS-Windows, for 'no' on Nextstep,
 371 otherwise for the first of 'inotify', 'kqueue' or 'gfile' that is usable.])
 372     ;;
 373    esac
 374    with_file_notification=$val
 375  ],
 376  [with_file_notification=$with_features])
 377
 378 OPTION_DEFAULT_OFF([xwidgets],
 379   [enable use of some gtk widgets in Emacs buffers (requires gtk3)])
 380
 381 ## For the times when you want to build Emacs but don't have
 382 ## a suitable makeinfo, and can live without the manuals.
 383 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 384 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 385
 386 ## This might be a 'configure' arg.
 387 AC_SUBST([ACLOCAL_PATH])
 388
 389 ## Makefile.in needs the cache file name.
 390 AC_SUBST(cache_file)
 391
 392 ## This is an option because I do not know if all info/man support
 393 ## compressed files, nor how to test if they do so.
 394 OPTION_DEFAULT_ON([compress-install],
 395   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 396 make GZIP_PROG= install])
 397
 398 AC_ARG_WITH(gameuser,dnl
 399 [AS_HELP_STRING([--with-gameuser=USER_OR_GROUP],
 400                 [user for shared game score files.
 401                 An argument prefixed by ':' specifies a group instead.])])
 402 gameuser=
 403 gamegroup=
 404 # We don't test if we can actually chown/chgrp here, because configure
 405 # may run without root privileges.  lib-src/Makefile.in will handle
 406 # any errors due to missing user/group gracefully.
 407 case ${with_gameuser} in
 408   no) ;;
 409   "" | yes) gamegroup=games ;;
 410   :*) gamegroup=${with_gameuser#:} ;;
 411   *) gameuser=${with_gameuser} ;;
 412 esac
 413
 414 AC_ARG_WITH([gnustep-conf],dnl
 415 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 416    [name of GNUstep configuration file to use on systems where the command
 417     'gnustep-config' does not work; default $GNUSTEP_CONFIG_FILE, or
 418     /etc/GNUstep/GNUstep.conf])])
 419 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 420   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 421 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 422      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 423
 424 AC_ARG_ENABLE(ns-self-contained,
 425 [AS_HELP_STRING([--disable-ns-self-contained],
 426                 [disable self contained build under NeXTstep])],
 427    EN_NS_SELF_CONTAINED=$enableval,
 428    EN_NS_SELF_CONTAINED=yes)
 429
 430 locallisppathset=no
 431 AC_ARG_ENABLE(locallisppath,
 432 [AS_HELP_STRING([--enable-locallisppath=PATH],
 433                 [directories Emacs should search for lisp files specific
 434                  to this site])],
 435 if test "${enableval}" = "no"; then
 436   locallisppath=
 437 elif test "${enableval}" != "yes"; then
 438   locallisppath=${enableval} locallisppathset=yes
 439 fi)
 440
 441 AC_ARG_ENABLE(checking,
 442 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 443                 [enable expensive run-time checks.  With LIST,
 444                  enable only specific categories of checks.
 445                  Categories are: all,yes,no.
 446                  Flags are: stringbytes, stringoverrun, stringfreelist,
 447                  xmallocoverrun, conslist, glyphs])],
 448 [ac_checking_flags="${enableval}"],[])
 449 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 450 for check in $ac_checking_flags
 451 do
 452         case $check in
 453         # these set all the flags to specific states
 454         yes)            ac_enable_checking=1 ;;
 455         no)             ac_enable_checking= ;
 456                         ac_gc_check_stringbytes= ;
 457                         ac_gc_check_string_overrun= ;
 458                         ac_gc_check_string_free_list= ;
 459                         ac_xmalloc_overrun= ;
 460                         ac_gc_check_cons_list= ;
 461                         ac_glyphs_debug= ;;
 462         all)            ac_enable_checking=1 ;
 463                         ac_gc_check_stringbytes=1 ;
 464                         ac_gc_check_string_overrun=1 ;
 465                         ac_gc_check_string_free_list=1 ;
 466                         ac_xmalloc_overrun=1 ;
 467                         ac_gc_check_cons_list=1 ;
 468                         ac_glyphs_debug=1 ;;
 469         # these enable particular checks
 470         stringbytes)    ac_gc_check_stringbytes=1 ;;
 471         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 472         stringfreelist) ac_gc_check_string_free_list=1 ;;
 473         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 474         conslist)       ac_gc_check_cons_list=1 ;;
 475         glyphs)         ac_glyphs_debug=1 ;;
 476         *)      AC_MSG_ERROR(unknown check category $check) ;;
 477         esac
 478 done
 479 IFS="$ac_save_IFS"
 480
 481 if test x$ac_enable_checking != x ; then
 482   AC_DEFINE(ENABLE_CHECKING, 1,
 483 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 484 fi
 485 if test x$ac_gc_check_stringbytes != x ; then
 486   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 487 [Define this temporarily to hunt a bug.  If defined, the size of
 488    strings is redundantly recorded in sdata structures so that it can
 489    be compared to the sizes recorded in Lisp strings.])
 490 fi
 491 if test x$ac_gc_check_string_overrun != x ; then
 492   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 493 [Define this to check for short string overrun.])
 494 fi
 495 if test x$ac_gc_check_string_free_list != x ; then
 496   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 497 [Define this to check the string free list.])
 498 fi
 499 if test x$ac_xmalloc_overrun != x ; then
 500   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 501 [Define this to check for malloc buffer overrun.])
 502 fi
 503 if test x$ac_gc_check_cons_list != x ; then
 504   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 505 [Define this to check for errors in cons list.])
 506 fi
 507 if test x$ac_glyphs_debug != x ; then
 508   AC_DEFINE(GLYPH_DEBUG, 1,
 509 [Define this to enable glyphs debugging code.])
 510 fi
 511
 512 AC_ARG_ENABLE(check-lisp-object-type,
 513 [AS_HELP_STRING([--enable-check-lisp-object-type],
 514                 [enable compile time checks for the Lisp_Object data type.
 515                 This is useful for development for catching certain types of bugs.])],
 516 if test "${enableval}" != "no"; then
 517    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 518    [Define this to enable compile time checks for the Lisp_Object data type.])
 519 fi)
 520
 521
 522 dnl The name of this option is unfortunate.  It predates, and has no
 523 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 524 dnl Actually, it stops it working.
 525 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 526 AC_ARG_ENABLE(profiling,
 527 [AS_HELP_STRING([--enable-profiling],
 528                 [build emacs with low-level, gprof profiling support.
 529                 Mainly useful for debugging Emacs itself.  May not work on
 530                 all platforms.  Stops profiler.el working.])],
 531 [ac_enable_profiling="${enableval}"],[])
 532 if test x$ac_enable_profiling != x ; then
 533    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 534 else
 535    PROFILING_CFLAGS=
 536 fi
 537 AC_SUBST(PROFILING_CFLAGS)
 538
 539 AC_ARG_ENABLE(autodepend,
 540 [AS_HELP_STRING([--enable-autodepend],
 541                 [automatically generate dependencies to .h-files.
 542                  Requires gcc, enabled if found.])],
 543 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 544
 545 AC_ARG_ENABLE(gtk-deprecation-warnings,
 546 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 547                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 548 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 549
 550 BUILD_DETAILS=
 551 AC_ARG_ENABLE([build-details],
 552   [AS_HELP_STRING([--disable-build-details],
 553                   [Make the build more deterministic by omitting host
 554                    names, time stamps, etc. from the output.])],
 555   [test "$enableval" = no && BUILD_DETAILS=--no-build-details])
 556 AC_SUBST([BUILD_DETAILS])
 557
 558 dnl This used to use changequote, but, apart from 'changequote is evil'
 559 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 560 dnl the great gob of text.  Thus it's not processed for possible expansion.
 561 dnl Just make sure the brackets remain balanced.
 562 dnl
 563 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 564 dnl indicated by comments.
 565 dnl quotation begins
 566 [
 567
 568 ### If you add support for a new configuration, add code to this
 569 ### switch statement to recognize your configuration name and select
 570 ### the appropriate opsys.
 571
 572 ### As far as handling version numbers on operating systems is
 573 ### concerned, make sure things will fail in a fixable way.  If
 574 ### /etc/MACHINES doesn't say anything about version numbers, be
 575 ### prepared to handle anything reasonably.  If version numbers
 576 ### matter, be sure /etc/MACHINES says something about it.
 577
 578 opsys='' unported=no
 579 case "${canonical}" in
 580
 581   ## GNU/Linux and similar ports
 582   *-*-linux* )
 583     opsys=gnu-linux
 584   ;;
 585
 586   ## FreeBSD ports
 587   *-*-freebsd* )
 588     opsys=freebsd
 589   ;;
 590
 591   ## DragonFly ports
 592   *-*-dragonfly* )
 593     opsys=dragonfly
 594   ;;
 595
 596   ## FreeBSD kernel + glibc based userland
 597   *-*-kfreebsd*gnu* )
 598     opsys=gnu-kfreebsd
 599   ;;
 600
 601   ## NetBSD ports
 602   *-*-netbsd* )
 603     opsys=netbsd
 604   ;;
 605
 606   ## OpenBSD ports
 607   *-*-openbsd* | *-*-mirbsd* )
 608     opsys=openbsd
 609   ;;
 610
 611   ## Apple Darwin / Mac OS X
 612   *-apple-darwin* )
 613     case "${canonical}" in
 614       *-apple-darwin[0-9].*) unported=yes ;;
 615       i[3456]86-* | x86_64-* )  ;;
 616       * )            unported=yes ;;
 617     esac
 618     opsys=darwin
 619     ## FIXME: Find a way to use Fink if available (Bug#11507).
 620   ;;
 621
 622   ## Chromium Native Client
 623   *-nacl )
 624     opsys=nacl
 625   ;;
 626
 627   ## Cygwin ports
 628   *-*-cygwin )
 629     opsys=cygwin
 630   ;;
 631
 632   ## HP 9000 series 700 and 800, running HP/UX
 633   hppa*-hp-hpux10.2* )
 634     opsys=hpux10-20
 635   ;;
 636   hppa*-hp-hpux1[1-9]* )
 637     opsys=hpux11
 638     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 639   ;;
 640
 641   ## IBM machines
 642   rs6000-ibm-aix4.[23]* )
 643     opsys=aix4-2
 644   ;;
 645   powerpc-ibm-aix4.[23]*  )
 646     opsys=aix4-2
 647   ;;
 648   rs6000-ibm-aix[56]* )
 649     opsys=aix4-2
 650   ;;
 651   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 652     opsys=aix4-2
 653   ;;
 654
 655   ## Suns
 656   *-sun-solaris* \
 657     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 658     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 659     case "${canonical}" in
 660       i[3456]86-*-* )   ;;
 661       amd64-*-*|x86_64-*-*) ;;
 662       sparc* )          ;;
 663       * )               unported=yes ;;
 664     esac
 665     case "${canonical}" in
 666       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 667                 opsys=sol2-10
 668                 emacs_check_sunpro_c=yes
 669                 ;;
 670       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 671       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 672       *-sunos5.6* | *-solaris2.6* )
 673                 opsys=sol2-6
 674                 RANLIB="ar -ts"
 675                 ;;
 676       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 677       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 678                 opsys=sol2-6
 679                 emacs_check_sunpro_c=yes
 680                 ;;
 681     esac
 682     ## Watch out for a compiler that we know will not work.
 683     case "${canonical}" in
 684      *-solaris* | *-sunos5* )
 685                 if [ "x$CC" = x/usr/ucb/cc ]; then
 686                   ## /usr/ucb/cc doesn't work;
 687                   ## we should find some other compiler that does work.
 688                   unset CC
 689                 fi
 690                 ;;
 691       *) ;;
 692     esac
 693   ;;
 694
 695   ## Intel 386 machines where we don't care about the manufacturer.
 696   i[3456]86-*-* )
 697     case "${canonical}" in
 698       *-darwin* )               opsys=darwin ;;
 699       *-mingw* )
 700                 opsys=mingw32
 701                 # MinGW overrides and adds some system headers in nt/inc.
 702                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 703                 ;;
 704       *-sysv4.2uw* )            opsys=unixware ;;
 705       *-sysv5uw* )              opsys=unixware ;;
 706       *-sysv5OpenUNIX* )        opsys=unixware ;;
 707       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 708     esac
 709   ;;
 710
 711   # MinGW64
 712   x86_64-*-* )
 713     case "${canonical}" in
 714       *-mingw* )
 715                 opsys=mingw32
 716                 # MinGW overrides and adds some system headers in nt/inc.
 717                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 718                 ;;
 719       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 720     esac
 721   ;;
 722
 723   * )
 724     unported=yes
 725   ;;
 726 esac
 727
 728 ### If the code above didn't choose an operating system, just choose
 729 ### an operating system based on the configuration name.  You really
 730 ### only want to use this when you have no idea what the right
 731 ### operating system is; if you know what operating systems a machine
 732 ### runs, it's cleaner to make it explicit in the case statement
 733 ### above.
 734 if test x"${opsys}" = x; then
 735   case "${canonical}" in
 736     *-gnu* )                            opsys=gnu ;;
 737     * )
 738       unported=yes
 739     ;;
 740   esac
 741 fi
 742
 743 ]
 744 dnl quotation ends
 745
 746 if test $unported = yes; then
 747   AC_MSG_ERROR([Emacs does not support '${canonical}' systems.
 748 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 749 Check 'etc/MACHINES' for recognized configuration names.])
 750 fi
 751
 752 #### Choose a compiler.
 753
 754 dnl Don't bother to test for C89.
 755 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 756
 757 dnl Sets GCC=yes if using gcc.
 758 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 759 if test -n "$XCRUN"; then
 760   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 761   test -n "$AR" && export AR
 762 fi
 763
 764 dnl Emacs needs C99 or later.
 765 gl_PROG_CC_C99
 766
 767 AM_PROG_CC_C_O
 768
 769 if test x$GCC = xyes; then
 770   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 771 fi
 772
 773 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 774 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 775 dnl that clash with MinGW.
 776 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 777
 778 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 779 AC_DEFUN([gl_CRYPTO_CHECK])
 780 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 781 # as we don't use them.
 782 AC_DEFUN([gl_FCNTL_O_FLAGS])
 783 # Avoid gnulib's test for pthread_sigmask.
 784 funcs=
 785 for func in $ac_func_list; do
 786   test $func = pthread_sigmask || AS_VAR_APPEND([funcs], [" $func"])
 787 done
 788 ac_func_list=$funcs
 789 # Use the system putenv even if it lacks GNU features, as we don't need them,
 790 # and the gnulib replacement runs afoul of a FreeBSD 10.1 bug; see Bug#19874.
 791 AC_CHECK_FUNCS_ONCE([putenv])
 792 AC_DEFUN([gl_FUNC_PUTENV],
 793   [test "$ac_cv_func_putenv" = yes || REPLACE_PUTENV=1])
 794
 795 # Initialize gnulib right after choosing the compiler.
 796 dnl Amongst other things, this sets AR and ARFLAGS.
 797 gl_EARLY
 798
 799 if test "$ac_test_CFLAGS" != set; then
 800   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 801   # if -g3 works and the user does not specify CFLAGS.
 802   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 803   case $CFLAGS in
 804     '-g')
 805       emacs_g3_CFLAGS='-g3';;
 806     '-g -O2')
 807       emacs_g3_CFLAGS='-g3 -O2';;
 808     *)
 809       emacs_g3_CFLAGS='';;
 810   esac
 811   if test -n "$emacs_g3_CFLAGS"; then
 812     emacs_save_CFLAGS=$CFLAGS
 813     CFLAGS=$emacs_g3_CFLAGS
 814     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 815       [emacs_cv_prog_cc_g3],
 816       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 817          [emacs_cv_prog_cc_g3=yes],
 818          [emacs_cv_prog_cc_g3=no])])
 819     if test $emacs_cv_prog_cc_g3 != yes; then
 820       CFLAGS=$emacs_save_CFLAGS
 821     fi
 822     if test $opsys = mingw32; then
 823       CFLAGS="$CFLAGS -gdwarf-2"
 824     fi
 825   fi
 826
 827   case $CFLAGS in
 828     *-O*) ;;
 829     *)
 830       # No optimization flag was inferred for this non-GCC compiler.
 831       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 832       emacs_save_CFLAGS=$CFLAGS
 833       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 834       CFLAGS=${CFLAGS}-O
 835       AC_CACHE_CHECK([whether $CC accepts -O],
 836         [emacs_cv_prog_cc_o],
 837         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 838            [emacs_cv_prog_cc_o=yes],
 839            [emacs_cv_prog_cc_o=no])])
 840       if test $emacs_cv_prog_cc_o != yes; then
 841         CFLAGS=$emacs_save_CFLAGS
 842       fi ;;
 843   esac
 844 fi
 845
 846 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 847 # ---------------------------------------------------------------------------
 848 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 849 # Otherwise, run RUN-IF-NOT-FOUND.
 850 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 851   [AC_PREPROC_IFELSE(
 852     [AC_LANG_PROGRAM(
 853       [[
 854 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 855 /* ok */
 856 #else
 857 # error "your version of gcc is older than $1.$2"
 858 #endif
 859       ]]),
 860     ], [$3], [$4])
 861   ]
 862 )
 863
 864 AC_ARG_ENABLE([gcc-warnings],
 865   [AS_HELP_STRING([--enable-gcc-warnings@<:@=TYPE@:>@],
 866                   [control generation of GCC warnings.  The TYPE 'yes'
 867                    means to fail if any warnings are issued; 'warn-only'
 868                    means issue warnings without failing (default for
 869                    developer builds); 'no' means disable warnings
 870                    (default for non-developer builds).])],
 871   [case $enableval in
 872      yes|no|warn-only) ;;
 873      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 874    esac
 875    gl_gcc_warnings=$enableval],
 876   [# By default, use 'warn-only' if it looks like the invoker of 'configure'
 877    # is a developer as opposed to a builder.  This is most likely true
 878    # if GCC is recent enough and there is a .git directory or file;
 879    # however, if there is also a .tarball-version file it is probably
 880    # just a release imported into Git for patch management.
 881    gl_gcc_warnings=no
 882    if test -e "$srcdir"/.git && test ! -f "$srcdir"/.tarball-version; then
 883      gl_GCC_VERSION_IFELSE([5], [3], [gl_gcc_warnings=warn-only])]
 884    fi
 885 )
 886
 887 # clang is unduly picky about some things.
 888 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 889   [AC_COMPILE_IFELSE(
 890      [AC_LANG_PROGRAM([[
 891           #ifndef __clang__
 892             error "not clang";
 893           #endif
 894         ]])],
 895      [emacs_cv_clang=yes],
 896      [emacs_cv_clang=no])])
 897
 898 # When compiling with GCC, prefer -isystem to -I when including system
 899 # include files, to avoid generating useless diagnostics for the files.
 900 AS_IF([test $gl_gcc_warnings = no],
 901  [
 902   isystem='-I'
 903   AS_IF([test "$emacs_cv_clang" = yes],
 904    [
 905      # Turn off some warnings if supported.
 906      gl_WARN_ADD([-Wno-switch])
 907      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 908      gl_WARN_ADD([-Wno-pointer-sign])
 909      gl_WARN_ADD([-Wno-string-plus-int])
 910      gl_WARN_ADD([-Wno-unknown-attributes])
 911    ])
 912  ],[
 913   isystem='-isystem '
 914
 915   # This, $nw, is the list of warnings we disable.
 916   nw=
 917
 918   case $with_x_toolkit in
 919     lucid | athena | motif)
 920        # Old toolkits mishandle 'const'.
 921        nw="$nw -Wwrite-strings"
 922        ;;
 923   esac
 924   AS_IF([test $gl_gcc_warnings = yes],
 925     [gl_WARN_ADD([-Werror], [WERROR_CFLAGS])])
 926   AC_SUBST([WERROR_CFLAGS])
 927
 928   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 929   nw="$nw -Woverlength-strings"     # Not a problem these days
 930   nw="$nw -Wformat-nonliteral"      # we do this a lot
 931   nw="$nw -Wvla"                    # Emacs uses <vla.h>.
 932   nw="$nw -Wswitch-default"         # Too many warnings for now
 933   nw="$nw -Winline"                 # OK to ignore 'inline'
 934   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 935                                     # signed overflow has undefined behavior
 936   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 937   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 938   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 939
 940   # Emacs doesn't care about shadowing; see
 941   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 942   nw="$nw -Wshadow"
 943
 944   # Emacs's use of alloca inhibits protecting the stack.
 945   nw="$nw -Wstack-protector"
 946
 947   # Emacs's use of partly-const functions such as Fgnutls_available_p
 948   # make this option problematic.
 949   nw="$nw -Wsuggest-attribute=const"
 950
 951   # Emacs's use of partly-pure functions such as CHECK_TYPE make this
 952   # option problematic.
 953   nw="$nw -Wsuggest-attribute=pure"
 954
 955   # This part is merely for shortening the command line,
 956   # since -Wall implies -Wswitch.
 957   nw="$nw -Wswitch"
 958
 959   # This part is merely for shortening the command line,
 960   # since -Wno-FOO needs to be added below regardless.
 961   nw="$nw -Wmissing-field-initializers"
 962   nw="$nw -Wtype-limits"
 963   nw="$nw -Wunused-parameter"
 964
 965   if test $emacs_cv_clang = yes; then
 966     nw="$nw -Wcast-align"
 967   fi
 968
 969   gl_MANYWARN_ALL_GCC([ws])
 970   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 971   for w in $ws; do
 972     gl_WARN_ADD([$w])
 973   done
 974   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 975   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 976   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 977   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 978   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 979   gl_WARN_ADD([-Wno-format-nonliteral])
 980
 981   # More things that clang is unduly picky about.
 982   if test $emacs_cv_clang = yes; then
 983     gl_WARN_ADD([-Wno-format-extra-args])
 984     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 985     gl_WARN_ADD([-Wno-unused-command-line-argument])
 986     gl_WARN_ADD([-Wno-unused-value])
 987   fi
 988
 989   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 990   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 991   AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
 992   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 993       without upsetting glibc 2.15+. */
 994    #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
 995         && defined __OPTIMIZE__ && __OPTIMIZE__)
 996    # define _FORTIFY_SOURCE 2
 997    #endif
 998   ])
 999
1000   # We use a slightly smaller set of warning options for lib/.
1001   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
1002   nw=
1003   nw="$nw -Wunused-macros"
1004
1005   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
1006   AC_SUBST([GNULIB_WARN_CFLAGS])
1007  ])
1008
1009 edit_cflags="
1010   s,///*,/,g
1011   s/^/ /
1012   s/ -I/ $isystem/g
1013   s/^ //
1014 "
1015
1016 AC_ARG_ENABLE(link-time-optimization,
1017 [AS_HELP_STRING([--enable-link-time-optimization],
1018                 [build emacs with link-time optimization.
1019                  This requires GCC 4.5.0 or later, or clang.
1020                  (Note that clang support is experimental - see INSTALL.)
1021                  It also makes Emacs harder to debug, and when we tried it
1022                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
1023                  recommended for typical use.])],
1024 if test "${enableval}" != "no"; then
1025    ac_lto_supported=no
1026    if test $emacs_cv_clang = yes; then
1027       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
1028       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
1029       if test -x "$GOLD_PLUGIN"; then
1030          LTO="-flto"
1031       fi
1032    elif test x$GCC = xyes; then
1033       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
1034       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
1035       if test x$CPUS != x; then
1036          LTO="-flto=$CPUS"
1037       else
1038          LTO="-flto"
1039       fi
1040    else
1041       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
1042    fi
1043    if test -z "$LTO"; then
1044       ac_lto_supported=no
1045    else
1046       old_CFLAGS=$CFLAGS
1047       CFLAGS="$CFLAGS $LTO"
1048       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1049          [ac_lto_supported=yes], [ac_lto_supported=no])
1050          CFLAGS="$old_CFLAGS"
1051    fi
1052    AC_MSG_RESULT([$ac_lto_supported])
1053    if test "$ac_lto_supported" = "yes"; then
1054       CFLAGS="$CFLAGS $LTO"
1055       if test x$emacs_cv_clang = xyes; then
1056          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
1057          # WARNING: 'ar --plugin ...' doesn't work without
1058          # command, so plugin name is appended to ARFLAGS.
1059          ARFLAGS="cru --plugin $GOLD_PLUGIN"
1060          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
1061       else
1062         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
1063         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
1064         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
1065         dnl dump core on Fedora 20, so play it safe for now.
1066         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
1067           [CFLAGS="$CFLAGS -ffat-lto-objects"])
1068       fi
1069    fi
1070 fi)
1071
1072 dnl Prefer silent make output.  For verbose output, use
1073 dnl 'configure --disable-silent-rules' or 'make V=1' .
1074 AM_SILENT_RULES([yes])
1075 dnl Port to Automake 1.11.
1076 dnl This section can be removed once we assume Automake 1.14 or later.
1077 : ${AM_V=$AM_DEFAULT_VERBOSITY}
1078 : ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
1079 AC_SUBST([AM_V])
1080 AM_SUBST_NOTMAKE([AM_V])
1081 AC_SUBST([AM_DEFAULT_V])
1082 AM_SUBST_NOTMAKE([AM_DEFAULT_V])
1083 AC_SUBST([AM_DEFAULT_VERBOSITY])
1084
1085 dnl Some other nice autoconf tests.
1086 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
1087 dnl AC_PROG_INSTALL
1088 dnl AC_PROG_MKDIR_P
1089 dnl if test "x$RANLIB" = x; then
1090 dnl   AC_PROG_RANLIB
1091 dnl fi
1092
1093
1094 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
1095 dnl can be made to directories.  This is not relevant for our usage, and
1096 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1097 dnl hosted on AFS, both examples where simple links work, but links to
1098 dnl directories fail.  We use a cut-down version instead.
1099 dnl AC_PROG_LN_S
1100
1101 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1102 rm -f conf$$ conf$$.file
1103
1104 LN_S_FILEONLY='cp -p'
1105
1106 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1107 dnl random program in the current directory.
1108 if (echo >conf$$.file) 2>/dev/null; then
1109   if ln -s conf$$.file conf$$ 2>/dev/null; then
1110     if test "$opsys" = "mingw32"; then
1111       LN_S_FILEONLY='/bin/ln -s'
1112     else
1113       LN_S_FILEONLY='ln -s'
1114     fi
1115   elif ln conf$$.file conf$$ 2>/dev/null; then
1116     if test "$opsys" = "mingw32"; then
1117       LN_S_FILEONLY=/bin/ln
1118     else
1119       LN_S_FILEONLY=ln
1120     fi
1121   fi
1122 fi
1123
1124 rm -f conf$$ conf$$.file
1125
1126 if test "$LN_S_FILEONLY" = "ln -s"; then
1127    AC_MSG_RESULT([yes])
1128 else
1129    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1130 fi
1131
1132 AC_SUBST(LN_S_FILEONLY)
1133
1134
1135 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1136 dnl doesn't support links to directories, as in "ln file dir".  But that
1137 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1138 dnl executables at "make install" time.
1139 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1140 dnl for more details.
1141 if test "$opsys" = "mingw32"; then
1142   LN_S="/bin/ln"
1143 fi
1144
1145 dnl On some Debian versions, "install-info" prints irritating messages
1146 dnl "This is not dpkg install-info anymore, but GNU install-info"
1147 dnl if called via an absolute file name.
1148 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1149 dnl Sadly some people may have an old ginstall-info installed on
1150 dnl non-Debian systems, so we can't use this.
1151 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1152 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1153
1154 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1155   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1156 dnl Don't use GZIP, which is used by gzip for additional parameters.
1157 AC_PATH_PROG(GZIP_PROG, gzip)
1158
1159 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1160    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1161
1162 PAXCTL_dumped=
1163 PAXCTL_notdumped=
1164 if test $opsys = gnu-linux; then
1165   if test "${SETFATTR+set}" != set; then
1166     AC_CACHE_CHECK([for setfattr],
1167       [emacs_cv_prog_setfattr],
1168       [touch conftest.tmp
1169        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1170          emacs_cv_prog_setfattr=yes
1171        else
1172          emacs_cv_prog_setfattr=no
1173        fi])
1174     if test "$emacs_cv_prog_setfattr" = yes; then
1175       PAXCTL_notdumped='$(SETFATTR) -n user.pax.flags -v er'
1176       SETFATTR=setfattr
1177     else
1178       SETFATTR=
1179     fi
1180     rm -f conftest.tmp
1181     AC_SUBST([SETFATTR])
1182   fi
1183 fi
1184 case $opsys,$PAXCTL_notdumped in
1185   gnu-linux, | netbsd,)
1186     AC_PATH_PROG([PAXCTL], [paxctl], [],
1187       [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1188     if test -n "$PAXCTL"; then
1189       if test "$opsys" = netbsd; then
1190         PAXCTL_dumped='$(PAXCTL) +a'
1191         PAXCTL_notdumped=$PAXCTL_dumped
1192       else
1193         AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1194         AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1195           [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then
1196              AC_MSG_RESULT([yes])
1197            else
1198              AC_MSG_RESULT([no])
1199              PAXCTL=
1200            fi])
1201         if test -n "$PAXCTL"; then
1202           PAXCTL_dumped='$(PAXCTL) -zex'
1203           PAXCTL_notdumped='$(PAXCTL) -r'
1204         fi
1205       fi
1206     fi;;
1207 esac
1208 AC_SUBST([PAXCTL_dumped])
1209 AC_SUBST([PAXCTL_notdumped])
1210
1211 ## Need makeinfo >= 4.7 (?) to build the manuals.
1212 if test "$MAKEINFO" != "no"; then
1213   if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
1214     MAKEINFO=makeinfo
1215   fi
1216   case `($MAKEINFO --version) 2>/dev/null` in
1217     *' (GNU texinfo) '4.[[7-9]]* | \
1218     *' (GNU texinfo) '4.[[1-9][0-9]]* | \
1219     *' (GNU texinfo) '[[5-9]]* | \
1220     *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1221     *) MAKEINFO=no;;
1222   esac
1223 fi
1224
1225 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1226 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1227 ## therefore in the category of "special tools" not normally required, which
1228 ## configure does not have to check for (eg autoconf itself).
1229 ## In a repository checkout on the other hand, the manuals are not included.
1230 ## So makeinfo is a requirement to build from the repository, and configure
1231 ## should test for it as it does for any other build requirement.
1232 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1233 ## with pre-built manuals, from a repository checkout.
1234 HAVE_MAKEINFO=yes
1235
1236 if test "$MAKEINFO" = "no"; then
1237   MAKEINFO=makeinfo
1238   if test "x${with_makeinfo}" = "xno"; then
1239     HAVE_MAKEINFO=no
1240   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1241     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1242 source tree does not seem to have pre-built manuals in the 'info' directory.
1243 Either install a suitable version of makeinfo, or re-run configure
1244 with the '--without-makeinfo' option to build without the manuals.] )
1245   fi
1246 fi
1247 AC_SUBST(HAVE_MAKEINFO)
1248
1249 if test $opsys = mingw32; then
1250    DOCMISC_W32=efaq-w32
1251 else
1252    DOCMISC_W32=
1253 fi
1254 AC_SUBST(DOCMISC_W32)
1255
1256 dnl Add our options to ac_link now, after it is set up.
1257
1258 if test x$GCC = xyes; then
1259   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1260     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1261 else
1262   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1263     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1264 fi
1265
1266 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1267 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1268 dnl Treat GCC specially since it just gives a non-fatal 'unrecognized option'
1269 dnl if not built to support GNU ld.
1270
1271 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1272 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1273 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1274 dnl   Eg "make LDFLAGS=... all" could run into problems,
1275 dnl   http://bugs.debian.org/684788
1276 dnl * unnecessary, since temacs is the only thing that actually needs it.
1277 dnl   Indeed this is where it was originally, prior to:
1278 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1279 late_LDFLAGS="$LDFLAGS"
1280 if test x$GCC = xyes; then
1281   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1282 else
1283   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1284 fi
1285
1286 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1287
1288 AC_MSG_CHECKING([for -znocombreloc])
1289 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1290   [AC_MSG_RESULT(yes)],
1291   LDFLAGS_NOCOMBRELOC=
1292   [AC_MSG_RESULT(no)])
1293
1294 LDFLAGS="$late_LDFLAGS"
1295
1296 AC_CACHE_CHECK([whether addresses are sanitized],
1297   [emacs_cv_sanitize_address],
1298   [AC_COMPILE_IFELSE(
1299      [AC_LANG_PROGRAM(
1300         [[#ifndef __has_feature
1301           #define __has_feature(f) 0
1302           #endif
1303           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1304           #else
1305            error "Addresses are not sanitized.";
1306           #endif
1307         ]])],
1308      [emacs_cv_sanitize_address=yes],
1309      [emacs_cv_sanitize_address=no])])
1310
1311 dnl The function dump-emacs will not be defined and temacs will do
1312 dnl (load "loadup") automatically unless told otherwise.
1313 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1314 case "$opsys" in
1315   nacl) CANNOT_DUMP=yes ;;
1316 esac
1317
1318 if test "$CANNOT_DUMP" = "yes"; then
1319   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1320 elif test "$emacs_cv_sanitize_address" = yes; then
1321   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1322 fi
1323
1324 AC_SUBST(CANNOT_DUMP)
1325
1326
1327 UNEXEC_OBJ=unexelf.o
1328 case "$opsys" in
1329   # MSDOS uses unexcoff.o
1330   aix4-2)
1331    UNEXEC_OBJ=unexaix.o
1332    ;;
1333   cygwin)
1334    UNEXEC_OBJ=unexcw.o
1335    ;;
1336   darwin)
1337    UNEXEC_OBJ=unexmacosx.o
1338    ;;
1339   hpux10-20 | hpux11)
1340    UNEXEC_OBJ=unexhp9k800.o
1341    ;;
1342   mingw32)
1343    UNEXEC_OBJ=unexw32.o
1344    ;;
1345   sol2-10)
1346    # Use the Solaris dldump() function, called from unexsol.c, to dump
1347    # emacs, instead of the generic ELF dump code found in unexelf.c.
1348    # The resulting binary has a complete symbol table, and is better
1349    # for debugging and other observability tools (debuggers, pstack, etc).
1350    #
1351    # If you encounter a problem using dldump(), please consider sending
1352    # a message to the OpenSolaris tools-linking mailing list:
1353    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1354    #
1355    # It is likely that dldump() works with older Solaris too, but this has
1356    # not been tested, so for now this change is for Solaris 10 or newer.
1357    UNEXEC_OBJ=unexsol.o
1358    ;;
1359 esac
1360
1361 LD_SWITCH_SYSTEM=
1362 case "$opsys" in
1363   freebsd|dragonfly)
1364    ## Let 'ld' find image libs and similar things in /usr/local/lib.
1365    ## The system compiler, GCC, has apparently been modified to not
1366    ## look there, contrary to what a stock GCC would do.
1367 ### It's not our place to do this.  See bug#10313#17.
1368 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1369       :
1370    ;;
1371
1372   gnu-linux)
1373    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1374    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1375    ;;
1376
1377   netbsd)
1378 ### It's not our place to do this.  See bug#10313#17.
1379 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1380       :
1381    ;;
1382
1383   openbsd)
1384    ## Han Boetes <han@boetes.org> says this is necessary,
1385    ## otherwise Emacs dumps core on elf systems.
1386    LD_SWITCH_SYSTEM="-Z"
1387    ;;
1388 esac
1389 AC_SUBST(LD_SWITCH_SYSTEM)
1390
1391 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1392
1393 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1394 ## which has not been defined yet.  When this was handled with cpp,
1395 ## it was expanded to null when configure sourced the s/*.h file.
1396 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1397 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1398 ## (or somesuch), but because it is supposed to go at the _front_
1399 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1400 ## Compare with the gnu-linux case below, which added to the end
1401 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1402 ## LD_SWITCH_SYSTEM_TEMACS.
1403 case "$opsys" in
1404   netbsd|openbsd)
1405    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1406 esac
1407
1408
1409 C_SWITCH_MACHINE=
1410 case $canonical in
1411  alpha*)
1412   AC_CHECK_DECL([__ELF__])
1413   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1414     ## With ELF, make sure that all common symbols get allocated to in the
1415     ## data section.  Otherwise, the dump of temacs may miss variables in
1416     ## the shared library that have been initialized.  For example, with
1417     ## GNU libc, __malloc_initialized would normally be resolved to the
1418     ## shared library's .bss section, which is fatal.
1419     if test "x$GCC" = "xyes"; then
1420       C_SWITCH_MACHINE="-fno-common"
1421     else
1422       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1423     fi
1424   else
1425       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1426       dnl albeit under the mistaken assumption that said file
1427       dnl was no longer used.
1428       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1429   fi
1430   ;;
1431 esac
1432 AC_SUBST(C_SWITCH_MACHINE)
1433
1434 AC_SUBST(UNEXEC_OBJ)
1435
1436 C_SWITCH_SYSTEM=
1437 ## Some programs in src produce warnings saying certain subprograms
1438 ## are too complex and need a MAXMEM value greater than 2000 for
1439 ## additional optimization.  --nils@exp-math.uni-essen.de
1440 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1441   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1442 if test "$opsys" = "mingw32"; then
1443   case "$canonical" in
1444     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1445     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1446   esac
1447 fi
1448 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1449 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1450 AC_SUBST(C_SWITCH_SYSTEM)
1451
1452
1453 LIBS_SYSTEM=
1454 case "$opsys" in
1455   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1456   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1457
1458   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1459
1460   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1461
1462   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1463
1464   ## Motif needs -lgen.
1465   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1466 esac
1467
1468 AC_SUBST(LIBS_SYSTEM)
1469
1470 ### Make sure subsequent tests use flags consistent with the build flags.
1471
1472 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1473   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1474 else
1475   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1476 fi
1477
1478 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1479 AC_DEFUN([AC_TYPE_SIZE_T])
1480 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1481 AC_DEFUN([AC_TYPE_UID_T])
1482
1483 # sqrt and other floating-point functions such as fmod and frexp
1484 # are found in -lm on many systems.
1485 OLD_LIBS=$LIBS
1486 AC_SEARCH_LIBS([sqrt], [m])
1487 if test "X$LIBS" = "X$OLD_LIBS"; then
1488   LIB_MATH=
1489 else
1490   LIB_MATH=$ac_cv_search_sqrt
1491 fi
1492 LIBS=$OLD_LIBS
1493
1494 dnl Current possibilities handled by sed (aix4-2 -> aix,
1495 dnl gnu-linux -> gnu/linux, etc.):
1496 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux.
1497 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1498 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1499
1500 case $opsys in
1501   cygwin )
1502     LIB_MATH=
1503     ;;
1504   darwin )
1505     ## Adding -lm confuses the dynamic linker, so omit it.
1506     LIB_MATH=
1507     ;;
1508   freebsd | dragonfly )
1509     SYSTEM_TYPE=berkeley-unix
1510     ;;
1511   gnu-linux | gnu-kfreebsd )
1512     ;;
1513   hpux10-20 | hpux11 )
1514     ;;
1515   mingw32 )
1516     LIB_MATH=
1517     SYSTEM_TYPE=windows-nt
1518     ;;
1519   dnl NB this may be adjusted below.
1520   netbsd | openbsd )
1521     SYSTEM_TYPE=berkeley-unix
1522     ;;
1523
1524   sol2* | unixware )
1525     SYSTEM_TYPE=usg-unix-v
1526     ;;
1527
1528 esac
1529
1530 AC_SUBST(LIB_MATH)
1531 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1532   [The type of system you are compiling for; sets 'system-type'.])
1533
1534
1535 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1536 pre_PKG_CONFIG_LIBS=$LIBS
1537
1538 PKG_PROG_PKG_CONFIG(0.9.0)
1539
1540 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1541 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1542 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1543 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1544 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1545 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1546 dnl actions.
1547 AC_DEFUN([EMACS_CHECK_MODULES],
1548   [PKG_CHECK_MODULES([$1], [$2],
1549      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1550       m4_default([$3], [HAVE_$1=yes])],
1551      [m4_default([$4], [HAVE_$1=no])])])
1552
1553 HAVE_SOUND=no
1554 if test "${with_sound}" != "no"; then
1555   # Sound support for GNU/Linux, the free BSDs, MinGW, and Cygwin.
1556   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1557     have_sound_header=yes, [], [
1558     #ifdef __MINGW32__
1559     #define WIN32_LEAN_AND_MEAN
1560     #include <windows.h>
1561     #endif
1562     ])
1563   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1564     AC_MSG_ERROR([OSS sound support requested but not found.])
1565
1566   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1567     # Emulation library used on NetBSD.
1568     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1569     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1570       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1571     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1572     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1573   fi
1574   AC_SUBST(LIBSOUND)
1575
1576   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1577     ALSA_REQUIRED=1.0.0
1578     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1579     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1580     if test $HAVE_ALSA = yes; then
1581       SAVE_CFLAGS="$CFLAGS"
1582       SAVE_LIBS="$LIBS"
1583       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1584       LIBS="$ALSA_LIBS $LIBS"
1585       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1586                       emacs_alsa_normal=yes,
1587                     emacs_alsa_normal=no)
1588       if test "$emacs_alsa_normal" != yes; then
1589         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1590                        [[snd_lib_error_set_handler (0);]])],
1591                        emacs_alsa_subdir=yes,
1592                      emacs_alsa_subdir=no)
1593         if test "$emacs_alsa_subdir" != yes; then
1594           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1595         fi
1596         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1597       fi
1598
1599       CFLAGS="$SAVE_CFLAGS"
1600       LIBS="$SAVE_LIBS"
1601       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1602       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1603       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1604     elif test "${with_sound}" = "alsa"; then
1605       AC_MSG_ERROR([ALSA sound support requested but not found.])
1606     fi
1607   fi                            dnl with_sound = alsa|yes
1608
1609   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1610   dnl compiles only on the specified platforms.  For others, it
1611   dnl probably doesn't make sense to try.
1612   dnl FIXME So surely we should bypass this whole section if not using
1613   dnl one of these platforms?
1614   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1615      case "$opsys" in
1616        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1617        dnl Adjust the --with-sound help text if you change this.
1618        gnu-linux|freebsd|netbsd|mingw32|cygwin)
1619          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1620          HAVE_SOUND=yes
1621          ;;
1622      esac
1623   fi
1624
1625   AC_SUBST(CFLAGS_SOUND)
1626 fi
1627
1628 dnl checks for header files
1629 AC_CHECK_HEADERS_ONCE(
1630   malloc.h
1631   sys/systeminfo.h
1632   sys/sysinfo.h
1633   coff.h pty.h
1634   sys/resource.h
1635   sys/utsname.h pwd.h utmp.h util.h)
1636
1637 AC_MSG_CHECKING(if personality LINUX32 can be set)
1638 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1639                emacs_cv_personality_linux32=yes,
1640                emacs_cv_personality_linux32=no)
1641 AC_MSG_RESULT($emacs_cv_personality_linux32)
1642
1643 if test $emacs_cv_personality_linux32 = yes; then
1644   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1645             [Define to 1 if personality LINUX32 can be set.])
1646 fi
1647
1648 # Note that Solaris has sys/sysinfo.h which defines struct
1649 # sysinfo as well.  To make sure that we're using GNU/Linux
1650 # sysinfo, we explicitly set one of its fields.
1651 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1652   AC_MSG_CHECKING([if Linux sysinfo may be used])
1653   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1654                                      [[struct sysinfo si;
1655                                        si.totalram = 0;
1656                                        sysinfo (&si)]])],
1657     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1658   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1659   if test $emacs_cv_linux_sysinfo = yes; then
1660     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1661     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1662                                        [[struct sysinfo si; return si.mem_unit]])],
1663       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1664                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1665   fi
1666 fi
1667
1668 dnl On Solaris 8 there's a compilation warning for term.h because
1669 dnl it doesn't define 'bool'.
1670 AC_CHECK_HEADERS(term.h, , , -)
1671 AC_HEADER_TIME
1672 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1673                                       ]])
1674 if test $ac_cv_have_decl_sys_siglist != yes; then
1675   # For Tru64, at least:
1676   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1677                                           ]])
1678 fi
1679 AC_HEADER_SYS_WAIT
1680
1681 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1682 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1683 #if HAVE_SYS_SOCKET_H
1684 #include <sys/socket.h>
1685 #endif])
1686 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1687 #if HAVE_SYS_SOCKET_H
1688 #include <sys/socket.h>
1689 #endif])
1690 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1691 #if HAVE_SYS_SOCKET_H
1692 #include <sys/socket.h>
1693 #endif])
1694
1695 dnl checks for structure members
1696 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1697                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1698                   struct ifreq.ifr_addr,
1699                   struct ifreq.ifr_addr.sa_len], , ,
1700                  [AC_INCLUDES_DEFAULT
1701 #if HAVE_SYS_SOCKET_H
1702 #include <sys/socket.h>
1703 #endif
1704 #if HAVE_NET_IF_H
1705 #include <net/if.h>
1706 #endif])
1707
1708 dnl Check for endianness.
1709 dnl AC_C_BIGENDIAN is done by gnulib.
1710
1711 dnl check for Make feature
1712
1713 AUTO_DEPEND=no
1714 dnl check if we have GCC and autodepend is on.
1715 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1716    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1717    SAVE_CFLAGS="$CFLAGS"
1718    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1719    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1720    CFLAGS="$SAVE_CFLAGS"
1721    test -f deps.d || ac_enable_autodepend=no
1722    rm -rf deps.d
1723    AC_MSG_RESULT([$ac_enable_autodepend])
1724    if test $ac_enable_autodepend = yes; then
1725       AUTO_DEPEND=yes
1726    fi
1727 fi
1728 AC_SUBST(AUTO_DEPEND)
1729
1730 dnl checks for operating system services
1731 AC_SYS_LONG_FILE_NAMES
1732
1733 #### Choose a window system.
1734
1735 ## We leave window_system equal to none if
1736 ## we end up building without one.  Any new window system should
1737 ## set window_system to an appropriate value and add objects to
1738 ## window-system-specific substs.
1739
1740 window_system=none
1741 AC_PATH_X
1742 if test "$no_x" != yes; then
1743   window_system=x11
1744 fi
1745
1746 LD_SWITCH_X_SITE_RPATH=
1747 if test "${x_libraries}" != NONE; then
1748   if test -n "${x_libraries}"; then
1749     LD_SWITCH_X_SITE=-L`AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -L/g'`
1750     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`
1751       AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -Wl,-rpath,/g'
1752     `
1753   fi
1754   x_default_search_path=""
1755   x_search_path=${x_libraries}
1756   if test -z "${x_search_path}"; then
1757     x_search_path=/usr/lib
1758   fi
1759   for x_library in `AS_ECHO(["$x_search_path:"]) | \
1760                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1761     x_search_path="\
1762 ${x_library}/X11/%L/%T/%N%C%S:\
1763 ${x_library}/X11/%l/%T/%N%C%S:\
1764 ${x_library}/X11/%T/%N%C%S:\
1765 ${x_library}/X11/%L/%T/%N%S:\
1766 ${x_library}/X11/%l/%T/%N%S:\
1767 ${x_library}/X11/%T/%N%S"
1768     if test x"${x_default_search_path}" = x; then
1769       x_default_search_path=${x_search_path}
1770     else
1771       x_default_search_path="${x_search_path}:${x_default_search_path}"
1772     fi
1773   done
1774 fi
1775 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1776
1777 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1778   C_SWITCH_X_SITE=$isystem`AS_ECHO(["$x_includes"]) | sed -e "s/:/ $isystem/g"`
1779 fi
1780
1781 if test x"${x_includes}" = x; then
1782   bitmapdir=/usr/include/X11/bitmaps
1783 else
1784   # accumulate include directories that have X11 bitmap subdirectories
1785   bmd_acc=
1786   for bmd in `AS_ECHO(["$x_includes"]) | sed -e 's/:/ /g'`; do
1787     if test -d "${bmd}/X11/bitmaps"; then
1788       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1789     fi
1790     if test -d "${bmd}/bitmaps"; then
1791       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1792     fi
1793   done
1794   bitmapdir=${bmd_acc#:}
1795 fi
1796
1797 test "${with_ns}" = maybe && test "${opsys}" != darwin && with_ns=no
1798 HAVE_NS=no
1799 NS_GNUSTEP_CONFIG=no
1800 NS_IMPL_COCOA=no
1801 NS_IMPL_GNUSTEP=no
1802 tmp_CPPFLAGS="$CPPFLAGS"
1803 tmp_CFLAGS="$CFLAGS"
1804 CPPFLAGS="$CPPFLAGS -x objective-c"
1805 CFLAGS="$CFLAGS -x objective-c"
1806 GNU_OBJC_CFLAGS=
1807 LIBS_GNUSTEP=
1808 if test "${with_ns}" != no; then
1809   if test "${opsys}" = darwin; then
1810      NS_IMPL_COCOA=yes
1811      ns_appdir=`pwd`/nextstep/Emacs.app
1812      ns_appbindir=${ns_appdir}/Contents/MacOS
1813      ns_appresdir=${ns_appdir}/Contents/Resources
1814      ns_appsrc=Cocoa/Emacs.base
1815      ns_fontfile=macfont.o
1816   elif flags=$( (gnustep-config --objc-flags) 2>/dev/null); then
1817      NS_IMPL_GNUSTEP=yes
1818      NS_GNUSTEP_CONFIG=yes
1819      GNU_OBJC_CFLAGS=$flags
1820      LIBS_GNUSTEP=$(gnustep-config --gui-libs) || exit
1821   elif test -f $GNUSTEP_CONFIG_FILE; then
1822      NS_IMPL_GNUSTEP=yes
1823      dnl FIXME sourcing this several times in subshells seems inefficient.
1824      GNUSTEP_SYSTEM_HEADERS=$(
1825        . $GNUSTEP_CONFIG_FILE
1826        AS_ECHO(["$GNUSTEP_SYSTEM_HEADERS"])
1827      )
1828      GNUSTEP_SYSTEM_LIBRARIES=$(
1829        . $GNUSTEP_CONFIG_FILE
1830        AS_ECHO(["$GNUSTEP_SYSTEM_LIBRARIES"])
1831      )
1832      dnl I seemed to need these as well with GNUstep-startup 0.25.
1833      GNUSTEP_LOCAL_HEADERS=$(
1834        . $GNUSTEP_CONFIG_FILE
1835        AS_ECHO(["$GNUSTEP_LOCAL_HEADERS"])
1836      )
1837      GNUSTEP_LOCAL_LIBRARIES=$(
1838        . $GNUSTEP_CONFIG_FILE
1839        AS_ECHO(["$GNUSTEP_LOCAL_LIBRARIES"])
1840      )
1841      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1842        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1843      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1844        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1845      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1846      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1847      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1848      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1849      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1850      dnl If they had chosen to either define it or not, we could have
1851      dnl just used AC_CHECK_DECL here.
1852      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1853        emacs_cv_objc_exceptions,
1854 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1855 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1856 1;
1857 #else
1858 fail;
1859 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1860      if test $emacs_cv_objc_exceptions = yes; then
1861        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1862        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1863          [Define if GNUstep uses ObjC exceptions.])
1864        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1865      fi
1866   fi
1867   if test $NS_IMPL_GNUSTEP = yes; then
1868      ns_appdir=`pwd`/nextstep/Emacs.app
1869      ns_appbindir=${ns_appdir}
1870      ns_appresdir=${ns_appdir}/Resources
1871      ns_appsrc=GNUstep/Emacs.base
1872      ns_fontfile=nsfont.o
1873   fi
1874
1875   dnl This is only used while we test the NS headers, it gets reset below.
1876   CPPFLAGS="$CPPFLAGS $GNU_OBJC_CFLAGS"
1877   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1878
1879   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1880                   [AC_MSG_ERROR([The include files (AppKit/AppKit.h etc) that
1881 are required for a Nextstep build are missing or cannot be compiled.
1882 Either fix this, or re-configure with the option '--without-ns'.])])
1883
1884   macfont_file=""
1885   if test "${NS_IMPL_COCOA}" = "yes"; then
1886     AC_MSG_CHECKING([for OSX 10.6 or newer])
1887     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1888                                      [
1889 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1890 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1060
1891  ; /* OK */
1892 #else
1893  error "OSX 10.6 or newer required";
1894 #endif
1895 #endif
1896                     ])],
1897                     ns_osx_have_106=yes,
1898                     ns_osx_have_106=no)
1899     AC_MSG_RESULT([$ns_osx_have_106])
1900
1901     if test $ns_osx_have_106 = no; then
1902        AC_MSG_ERROR([OSX 10.6 or newer is required]);
1903     fi
1904   fi
1905 fi
1906
1907 AC_SUBST(LIBS_GNUSTEP)
1908
1909 INSTALL_ARCH_INDEP_EXTRA=install-etc
1910 ns_self_contained=no
1911 NS_OBJ=
1912 NS_OBJC_OBJ=
1913 if test "${HAVE_NS}" = yes; then
1914   if test "$with_toolkit_scroll_bars" = "no"; then
1915     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1916   fi
1917
1918   window_system=nextstep
1919   # set up packaging dirs
1920   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1921      ns_self_contained=yes
1922      prefix=${ns_appresdir}
1923      exec_prefix=${ns_appbindir}
1924      dnl This one isn't really used, only archlibdir is.
1925      libexecdir="\${ns_appbindir}/libexec"
1926      archlibdir="\${ns_appbindir}/libexec"
1927      etcdocdir="\${ns_appresdir}/etc"
1928      etcdir="\${ns_appresdir}/etc"
1929      dnl FIXME maybe set datarootdir instead.
1930      dnl That would also get applications, icons, man.
1931      infodir="\${ns_appresdir}/info"
1932      mandir="\${ns_appresdir}/man"
1933      lispdir="\${ns_appresdir}/lisp"
1934      test "$locallisppathset" = no && locallisppath=""
1935      INSTALL_ARCH_INDEP_EXTRA=
1936   fi
1937
1938   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o $ns_fontfile"
1939 fi
1940 CFLAGS="$tmp_CFLAGS"
1941 CPPFLAGS="$tmp_CPPFLAGS"
1942 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1943 AC_SUBST(ns_self_contained)
1944 AC_SUBST(NS_OBJ)
1945 AC_SUBST(NS_OBJC_OBJ)
1946
1947 HAVE_W32=no
1948 W32_OBJ=
1949 W32_LIBS=
1950 EMACSRES=
1951 CLIENTRES=
1952 CLIENTW=
1953 W32_RES_LINK=
1954 EMACS_MANIFEST=
1955 UPDATE_MANIFEST=
1956 if test "${with_w32}" != no; then
1957   case "${opsys}" in
1958     cygwin)
1959       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1960              [AC_MSG_ERROR(['--with-w32' was specified, but windows.h
1961                    cannot be found.])])
1962     ;;
1963     mingw32)
1964     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1965     ;;
1966     *)
1967       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1968     ;;
1969   esac
1970 fi
1971
1972 if test "${opsys}" = "mingw32"; then
1973   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1974   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1975      #include <windows.h>
1976      #include <usp10.h>]],
1977    [[PIMAGE_NT_HEADERS pHeader;
1978      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1979    [emacs_cv_w32api=yes
1980     HAVE_W32=yes],
1981    emacs_cv_w32api=no)
1982   AC_MSG_RESULT($emacs_cv_w32api)
1983   if test "${emacs_cv_w32api}" = "no"; then
1984     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1985   fi
1986 fi
1987
1988 FIRSTFILE_OBJ=
1989 NTDIR=
1990 LIBS_ECLIENT=
1991 LIB_WSOCK32=
1992 NTLIB=
1993 CM_OBJ="cm.o"
1994 XARGS_LIMIT=
1995 if test "${HAVE_W32}" = "yes"; then
1996   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1997   if test "$with_toolkit_scroll_bars" = "no"; then
1998     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for w32 build.])
1999   fi
2000   AC_CHECK_TOOL(WINDRES, [windres],
2001                 [AC_MSG_ERROR([No resource compiler found.])])
2002   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
2003   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
2004   EMACSRES="emacs.res"
2005   case "$canonical" in
2006     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
2007     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
2008   esac
2009   dnl Construct something of the form "24,4,0,0" with 4 components.
2010   comma_version=`echo "${PACKAGE_VERSION}.0.0" | sed -e 's/\./,/g' -e 's/^\([[^,]]*,[[^,]]*,[[^,]]*,[[^,]]*\).*/\1/'`
2011
2012   comma_space_version=`echo "$comma_version" | sed 's/,/, /g'`
2013   AC_SUBST(comma_version)
2014   AC_SUBST(comma_space_version)
2015   AC_CONFIG_FILES([nt/emacs.rc nt/emacsclient.rc])
2016   if test "${opsys}" = "cygwin"; then
2017     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
2018     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
2019     # Tell the linker that emacs.res is an object (which we compile from
2020     # the rc file), not a linker script.
2021     W32_RES_LINK="-Wl,emacs.res"
2022   else
2023     UPDATE_MANIFEST=update-game-score.exe.manifest
2024     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
2025     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
2026     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
2027     W32_RES_LINK="\$(EMACSRES)"
2028     CLIENTRES="emacsclient.res"
2029     CLIENTW="emacsclientw\$(EXEEXT)"
2030     FIRSTFILE_OBJ=firstfile.o
2031     NTDIR=nt
2032     CM_OBJ=
2033     LIBS_ECLIENT="-lcomctl32"
2034     LIB_WSOCK32="-lwsock32"
2035     NTLIB="ntlib.$ac_objext"
2036     XARGS_LIMIT="-s 10000"
2037   fi
2038 fi
2039 AC_SUBST(W32_OBJ)
2040 AC_SUBST(W32_LIBS)
2041 AC_SUBST(EMACSRES)
2042 AC_SUBST(EMACS_MANIFEST)
2043 AC_SUBST(UPDATE_MANIFEST)
2044 AC_SUBST(CLIENTRES)
2045 AC_SUBST(CLIENTW)
2046 AC_SUBST(W32_RES_LINK)
2047 AC_SUBST(FIRSTFILE_OBJ)
2048 AC_SUBST(NTDIR)
2049 AC_SUBST(CM_OBJ)
2050 AC_SUBST(LIBS_ECLIENT)
2051 AC_SUBST(LIB_WSOCK32)
2052 AC_SUBST(NTLIB)
2053 AC_SUBST(XARGS_LIMIT)
2054
2055 if test "${HAVE_W32}" = "yes"; then
2056   window_system=w32
2057   with_xft=no
2058 fi
2059
2060 ## $window_system is now set to the window system we will
2061 ## ultimately use.
2062
2063 term_header=
2064 HAVE_X_WINDOWS=no
2065 HAVE_X11=no
2066 USE_X_TOOLKIT=none
2067
2068 case "${window_system}" in
2069   x11 )
2070     HAVE_X_WINDOWS=yes
2071     HAVE_X11=yes
2072     term_header=xterm.h
2073     case "${with_x_toolkit}" in
2074       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
2075       motif ) USE_X_TOOLKIT=MOTIF ;;
2076       gtk ) with_gtk=yes
2077             term_header=gtkutil.h
2078 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
2079 dnl USE_X_TOOLKIT is set.
2080             USE_X_TOOLKIT=none ;;
2081       gtk2 ) with_gtk2=yes
2082              term_header=gtkutil.h
2083              USE_X_TOOLKIT=none ;;
2084       gtk3 ) with_gtk3=yes
2085              term_header=gtkutil.h
2086              USE_X_TOOLKIT=none ;;
2087       no ) USE_X_TOOLKIT=none ;;
2088 dnl If user did not say whether to use a toolkit, make this decision later:
2089 dnl use the toolkit if we have gtk, or X11R5 or newer.
2090       * ) USE_X_TOOLKIT=maybe ;;
2091     esac
2092   ;;
2093   nextstep )
2094     term_header=nsterm.h
2095   ;;
2096   w32 )
2097     term_header=w32term.h
2098   ;;
2099 esac
2100
2101 if test "$window_system" = none && test "X$with_x" != "Xno"; then
2102    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
2103    if test "$HAVE_XSERVER" = true ||
2104       test -n "$DISPLAY" ||
2105       {
2106         for emacs_libX11 in /usr/lib/libX11.*; do break; done
2107         test "$emacs_libX11" != '/usr/lib/libX11.*'
2108       }
2109    then
2110         AC_MSG_ERROR([You seem to be running X, but no X development libraries
2111 were found.  You should install the relevant development files for X
2112 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2113 sure you have development files for image handling, i.e.
2114 tiff, gif, jpeg, png and xpm.
2115 If you are sure you want Emacs compiled without X window support, pass
2116   --without-x
2117 to configure.])
2118    fi
2119 fi
2120
2121 # Does the opsystem file prohibit the use of the GNU malloc?
2122 # Assume not, until told otherwise.
2123 GNU_MALLOC=yes
2124
2125 AC_CACHE_CHECK(
2126   [whether malloc is Doug Lea style],
2127   [emacs_cv_var_doug_lea_malloc],
2128   [emacs_cv_var_doug_lea_malloc=no
2129    dnl Hooks do not work with address sanitization.
2130    if test "$emacs_cv_sanitize_address" != yes; then
2131      AC_LINK_IFELSE(
2132        [AC_LANG_PROGRAM(
2133           [[#include <malloc.h>
2134             static void hook (void) {}]],
2135           [[malloc_set_state (malloc_get_state ());
2136             __after_morecore_hook = hook;
2137             __malloc_initialize_hook = hook;]])],
2138        [emacs_cv_var_doug_lea_malloc=yes])
2139    fi])
2140 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2141
2142 system_malloc=$emacs_cv_sanitize_address
2143
2144 hybrid_malloc=
2145
2146 case "$opsys" in
2147   ## darwin ld insists on the use of malloc routines in the System framework.
2148   darwin | mingw32 | nacl | sol2-10) system_malloc=yes ;;
2149   cygwin) hybrid_malloc=yes;;
2150 esac
2151
2152 if test "${system_malloc}" != yes && test "${doug_lea_malloc}" != yes \
2153    && test "${UNEXEC_OBJ}" = unexelf.o; then
2154   hybrid_malloc=yes
2155 fi
2156
2157 GMALLOC_OBJ=
2158 HYBRID_MALLOC=
2159 if test "${system_malloc}" = "yes"; then
2160   AC_DEFINE([SYSTEM_MALLOC], 1,
2161     [Define to 1 to use the system memory allocator, even if it is not
2162      Doug Lea style.])
2163   GNU_MALLOC=no
2164   GNU_MALLOC_reason="
2165     (The GNU allocators don't work with this system configuration.)"
2166   VMLIMIT_OBJ=
2167 elif test "$hybrid_malloc" = yes; then
2168   AC_DEFINE(HYBRID_MALLOC, 1,
2169     [Define to use gmalloc before dumping and the system malloc after.])
2170   HYBRID_MALLOC=1
2171   GNU_MALLOC=
2172   GNU_MALLOC_reason="only before dumping"
2173   GMALLOC_OBJ=gmalloc.o
2174   VMLIMIT_OBJ=
2175 else
2176   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2177   VMLIMIT_OBJ=vm-limit.o
2178
2179   AC_CHECK_HEADERS([sys/vlimit.h])
2180   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2181     [AC_LINK_IFELSE(
2182        [AC_LANG_PROGRAM(
2183          [[extern char data_start[]; char ch;]],
2184          [[return data_start < &ch;]])],
2185        [emacs_cv_data_start=yes],
2186        [emacs_cv_data_start=no])])
2187   if test $emacs_cv_data_start = yes; then
2188     AC_DEFINE([HAVE_DATA_START], 1,
2189       [Define to 1 if data_start is the address of the start
2190        of the main data segment.])
2191   fi
2192 fi
2193 AC_SUBST([HYBRID_MALLOC])
2194 AM_CONDITIONAL([HYBRID_MALLOC_LIB], [test -n "$HYBRID_MALLOC"])
2195 AC_SUBST(GMALLOC_OBJ)
2196 AC_SUBST(VMLIMIT_OBJ)
2197
2198 if test "$doug_lea_malloc" = "yes" && test "$hybrid_malloc" != yes; then
2199   if test "$GNU_MALLOC" = yes ; then
2200     GNU_MALLOC_reason="
2201       (Using Doug Lea's new malloc from the GNU C Library.)"
2202   fi
2203   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2204     [Define to 1 if the system memory allocator is Doug Lea style,
2205      with malloc hooks and malloc_set_state.])
2206
2207   ## Use mmap directly for allocating larger buffers.
2208   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2209   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2210   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2211   case "$opsys" in
2212     mingw32|gnu*) REL_ALLOC=no ;;
2213   esac
2214 fi
2215
2216 if test x"${REL_ALLOC}" = x; then
2217   REL_ALLOC=${GNU_MALLOC}
2218 fi
2219
2220 use_mmap_for_buffers=no
2221 case "$opsys" in
2222   cygwin|mingw32) use_mmap_for_buffers=yes ;;
2223 esac
2224
2225 AC_FUNC_MMAP
2226 if test $use_mmap_for_buffers = yes; then
2227   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2228   REL_ALLOC=no
2229 fi
2230
2231 LIBS="$LIBS_SYSTEM $LIBS"
2232
2233 dnl FIXME replace main with a function we actually want from this library.
2234 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2235
2236 dnl Check for the POSIX thread library.
2237 LIB_PTHREAD=
2238 AC_CHECK_HEADERS_ONCE(pthread.h)
2239 if test "$ac_cv_header_pthread_h" && test "$opsys" != "mingw32"; then
2240   AC_CACHE_CHECK([for pthread library],
2241     [emacs_cv_pthread_lib],
2242     [emacs_cv_pthread_lib=no
2243      OLD_LIBS=$LIBS
2244      for emacs_pthread_lib in 'none needed' -lpthread; do
2245        case $emacs_pthread_lib in
2246          -*) LIBS="$OLD_LIBS $emacs_pthread_lib";;
2247        esac
2248        AC_LINK_IFELSE(
2249          [AC_LANG_PROGRAM(
2250             [[#include <pthread.h>
2251               #include <signal.h>
2252               sigset_t old_mask, new_mask;
2253               void noop (void) {}]],
2254             [[pthread_t th = pthread_self ();
2255               int status = 0;
2256               status += pthread_create (&th, 0, 0, 0);
2257               status += pthread_sigmask (SIG_BLOCK, &new_mask, &old_mask);
2258               status += pthread_kill (th, 0);
2259               #if ! (defined SYSTEM_MALLOC || defined HYBRID_MALLOC \
2260                      || defined DOUG_LEA_MALLOC)
2261               /* Test for pthread_atfork only if gmalloc uses it,
2262                  as older-style hosts like MirBSD 10 lack it.  */
2263               status += pthread_atfork (noop, noop, noop);
2264               #endif
2265               return status;]])],
2266          [emacs_cv_pthread_lib=$emacs_pthread_lib])
2267        LIBS=$OLD_LIBS
2268        if test "$emacs_cv_pthread_lib" != no; then
2269          break
2270        fi
2271      done])
2272   if test "$emacs_cv_pthread_lib" != no; then
2273     AC_DEFINE([HAVE_PTHREAD], 1, [Define to 1 if you have POSIX threads.])
2274     case $emacs_cv_pthread_lib in
2275       -*) LIB_PTHREAD=$emacs_cv_pthread_lib;;
2276     esac
2277     ac_cv_func_pthread_sigmask=yes
2278     # Some systems optimize for single-threaded programs by default, and
2279     # need special flags to disable these optimizations. For example, the
2280     # definition of 'errno' in <errno.h>.
2281     case $opsys in
2282       hpux* | sol*)
2283         AC_DEFINE([_REENTRANT], 1,
2284           [Define to 1 if your system requires this in multithreaded code.]);;
2285       aix4-2)
2286         AC_DEFINE([_THREAD_SAFE], 1,
2287           [Define to 1 if your system requires this in multithreaded code.]);;
2288     esac
2289   fi
2290 fi
2291 AC_SUBST([LIB_PTHREAD])
2292
2293 dnl Check for need for bigtoc support on IBM AIX
2294
2295 case ${host_os} in
2296 aix*)
2297   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2298     case $GCC in
2299     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2300     *) gdb_cv_bigtoc=-bbigtoc ;;
2301     esac
2302
2303     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2304     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2305   ])
2306   ;;
2307 esac
2308
2309 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2310 # is for the tests that follow.  We set them back later on.
2311
2312 REAL_CFLAGS="$CFLAGS"
2313 REAL_CPPFLAGS="$CPPFLAGS"
2314 REAL_LIBS="$LIBS"
2315
2316 if test "${HAVE_X11}" = "yes"; then
2317   DEFS="$C_SWITCH_X_SITE $DEFS"
2318   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2319   LIBS="-lX11 $LIBS"
2320   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2321   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2322
2323   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2324   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2325   # but it's more convenient here to set LD_RUN_PATH since this
2326   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2327   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2328     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2329     export LD_RUN_PATH
2330   fi
2331
2332   if test "${opsys}" = "gnu-linux"; then
2333     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2334     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2335      [[XOpenDisplay ("foo");]])],
2336      [xgnu_linux_first_failure=no],
2337      [xgnu_linux_first_failure=yes])
2338     if test "${xgnu_linux_first_failure}" = "yes"; then
2339       OLD_CPPFLAGS="$CPPFLAGS"
2340       OLD_LIBS="$LIBS"
2341       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2342       LIBS="$LIBS -b i486-linuxaout"
2343       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2344        [[XOpenDisplay ("foo");]])],
2345        [xgnu_linux_second_failure=no],
2346        [xgnu_linux_second_failure=yes])
2347       if test "${xgnu_linux_second_failure}" = "yes"; then
2348         # If we get the same failure with -b, there is no use adding -b.
2349         # So leave it out.  This plays safe.
2350         AC_MSG_RESULT(no)
2351       else
2352         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2353         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2354         AC_MSG_RESULT(yes)
2355       fi
2356       CPPFLAGS=$OLD_CPPFLAGS
2357       LIBS=$OLD_LIBS
2358     else
2359       AC_MSG_RESULT(no)
2360     fi
2361   fi
2362
2363   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2364   # header files included from there.
2365   AC_MSG_CHECKING(for Xkb)
2366   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2367 #include <X11/XKBlib.h>]],
2368         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2369         emacs_xkb=yes, emacs_xkb=no)
2370   AC_MSG_RESULT($emacs_xkb)
2371   if test $emacs_xkb = yes; then
2372     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2373   fi
2374
2375   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2376 XScreenNumberOfScreen)
2377 fi
2378
2379 if test "${window_system}" = "x11"; then
2380   AC_MSG_CHECKING(X11 version 6)
2381   AC_CACHE_VAL(emacs_cv_x11_version_6,
2382   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2383 [[#if XlibSpecificationRelease < 6
2384 fail;
2385 #endif
2386 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2387   if test $emacs_cv_x11_version_6 = yes; then
2388     AC_MSG_RESULT(6 or newer)
2389     AC_DEFINE(HAVE_X11R6, 1,
2390               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2391     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2392     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2393     ## XIM support.
2394     case "$opsys" in
2395       sol2-*) : ;;
2396       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2397            [Define if you have usable X11R6-style XIM support.])
2398          ;;
2399     esac
2400   else
2401     AC_MSG_RESULT(before 6)
2402   fi
2403 fi
2404
2405
2406 ### Use -lrsvg-2 if available, unless '--with-rsvg=no' is specified.
2407 HAVE_RSVG=no
2408 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2409   if test "${with_rsvg}" != "no"; then
2410     RSVG_REQUIRED=2.11.0
2411     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2412
2413     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2414     AC_SUBST(RSVG_CFLAGS)
2415     AC_SUBST(RSVG_LIBS)
2416
2417     if test $HAVE_RSVG = yes; then
2418       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2419       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2420       # Windows loads librsvg dynamically
2421       if test "${opsys}" = "mingw32"; then
2422         RSVG_LIBS=
2423       fi
2424     fi
2425   fi
2426 fi
2427
2428 HAVE_IMAGEMAGICK=no
2429 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2430   if test "${with_imagemagick}" != "no"; then
2431     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2432     ## 6.8.2 makes Emacs crash; see Bug#13867.
2433     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2434     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2435     AC_SUBST(IMAGEMAGICK_CFLAGS)
2436     AC_SUBST(IMAGEMAGICK_LIBS)
2437
2438     if test $HAVE_IMAGEMAGICK = yes; then
2439       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2440       OLD_CFLAGS=$CFLAGS
2441       OLD_LIBS=$LIBS
2442       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2443       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2444       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers MagickAutoOrientImage)
2445       CFLAGS=$OLD_CFLAGS
2446       LIBS=$OLD_LIBS
2447     fi
2448   fi
2449 fi
2450
2451 AC_CHECK_LIB(anl, getaddrinfo_a, HAVE_GETADDRINFO_A=yes)
2452 if test "${HAVE_GETADDRINFO_A}" = "yes"; then
2453   AC_DEFINE(HAVE_GETADDRINFO_A, 1,
2454 [Define to 1 if you have getaddrinfo_a for asynchronous DNS resolution.])
2455   GETADDRINFO_A_LIBS="-lanl"
2456   AC_SUBST(GETADDRINFO_A_LIBS)
2457 fi
2458
2459 HAVE_GTK=no
2460 GTK_OBJ=
2461 gtk_term_header=$term_header
2462 check_gtk2=no
2463 gtk3_pkg_errors=
2464 if test "${opsys}" != "mingw32"; then
2465   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2466     GLIB_REQUIRED=2.28
2467     GTK_REQUIRED=3.0
2468     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2469
2470     dnl Checks for libraries.
2471     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2472       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2473     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2474        AC_MSG_ERROR($GTK_PKG_ERRORS)
2475     fi
2476     if test "$pkg_check_gtk" = "yes"; then
2477        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2478        GTK_OBJ=emacsgtkfixed.o
2479        gtk_term_header=gtkutil.h
2480        USE_GTK_TOOLKIT="GTK3"
2481        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2482          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2483            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2484          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2485            [Define to 1 to disable Glib deprecation warnings.])
2486        fi
2487     else
2488        check_gtk2=yes
2489        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2490     fi
2491   fi
2492
2493   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2494     GLIB_REQUIRED=2.10
2495     GTK_REQUIRED=2.10
2496     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2497
2498     dnl Checks for libraries.
2499     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2500       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2501     if test "$pkg_check_gtk" = "no" &&
2502        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2503     then
2504       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2505     fi
2506     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2507   fi
2508 fi
2509
2510 OLD_CFLAGS=$CFLAGS
2511 OLD_LIBS=$LIBS
2512
2513 if test x"$pkg_check_gtk" = xyes; then
2514
2515   AC_SUBST(GTK_LIBS)
2516   CFLAGS="$CFLAGS $GTK_CFLAGS"
2517   LIBS="$GTK_LIBS $LIBS"
2518   dnl Try to compile a simple GTK program.
2519   AC_MSG_CHECKING([whether GTK compiles])
2520   GTK_COMPILES=no
2521   AC_LINK_IFELSE(
2522     [AC_LANG_PROGRAM(
2523        [[/* Check the Gtk and Glib APIs.  */
2524          #include <gtk/gtk.h>
2525          #include <glib-object.h>
2526          static void
2527          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2528          {}
2529        ]],
2530        [[
2531          GtkSettings *gs = 0;
2532          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2533             strict C prohibits this.  Use gtk_main_iteration to test that the
2534             libraries are there.  */
2535          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2536                                     0, 0, 0, G_CALLBACK (callback), 0))
2537            gtk_main_iteration ();
2538        ]])],
2539     [GTK_COMPILES=yes])
2540   AC_MSG_RESULT([$GTK_COMPILES])
2541   if test "${GTK_COMPILES}" != "yes"; then
2542     GTK_OBJ=
2543     if test "$USE_X_TOOLKIT" != "maybe"; then
2544       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2545     fi
2546   else
2547     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2548     HAVE_GTK=yes
2549     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2550     GTK_OBJ="gtkutil.o $GTK_OBJ"
2551     term_header=$gtk_term_header
2552     USE_X_TOOLKIT=none
2553     AC_MSG_WARN([[Your version of Gtk+ will have problems with
2554        closing open displays.  This is no problem if you just use
2555        one display, but if you use more than one and close one of them
2556        Emacs may crash.
2557        See http://bugzilla.gnome.org/show_bug.cgi?id=85715]])
2558     sleep 3
2559   fi
2560
2561 fi
2562 AC_SUBST(GTK_OBJ)
2563
2564
2565 if test "${HAVE_GTK}" = "yes"; then
2566
2567   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2568   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2569   if test "$with_toolkit_scroll_bars" != no; then
2570     with_toolkit_scroll_bars=yes
2571   fi
2572
2573   dnl  Check if we have the old file selection dialog declared and
2574   dnl  in the link library.  In 2.x it may be in the library,
2575   dnl  but not declared if deprecated featured has been selected out.
2576   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2577   HAVE_GTK_FILE_SELECTION=no
2578   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2579                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2580 #include <gtk/gtk.h>])
2581   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2582     AC_CHECK_FUNCS(gtk_file_selection_new)
2583   fi
2584
2585   dnl Same as above for gtk_handle_box.
2586   HAVE_GTK_HANDLE_BOX=no
2587   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2588                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2589 #include <gtk/gtk.h>])
2590   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2591     AC_CHECK_FUNCS(gtk_handle_box_new)
2592   fi
2593
2594   dnl Same as above for gtk_tearoff_menu_item.
2595   HAVE_GTK_TEAROFF_MENU_ITEM=no
2596   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2597                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2598 #include <gtk/gtk.h>])
2599   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2600     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2601   fi
2602
2603   dnl Check for functions introduced in 2.14 and later.
2604   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2605                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2606                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2607                  gtk_orientable_set_orientation \
2608                  gtk_window_set_has_resize_grip)
2609
2610  term_header=gtkutil.h
2611 fi
2612
2613
2614 dnl Enable xwidgets if GTK3 and WebKitGTK+ are available.
2615 HAVE_XWIDGETS=no
2616 XWIDGETS_OBJ=
2617 if test "$with_xwidgets" != "no"; then
2618   test "$USE_GTK_TOOLKIT" = "GTK3" && test "$window_system" != "none" ||
2619     AC_MSG_ERROR([xwidgets requested but gtk3 not used.])
2620
2621   WEBKIT_REQUIRED=1.4.0
2622   WEBKIT_MODULES="webkitgtk-3.0 >= $WEBKIT_REQUIRED"
2623   EMACS_CHECK_MODULES([WEBKIT], [$WEBKIT_MODULES])
2624   HAVE_XWIDGETS=$HAVE_WEBKIT
2625   test $HAVE_XWIDGETS = yes ||
2626     AC_MSG_ERROR([xwidgets requested but WebKitGTK+ not found.])
2627
2628   XWIDGETS_OBJ=xwidget.o
2629   AC_DEFINE([HAVE_XWIDGETS], 1, [Define to 1 if you have xwidgets support.])
2630 fi
2631 AC_SUBST(XWIDGETS_OBJ)
2632
2633 CFLAGS=$OLD_CFLAGS
2634 LIBS=$OLD_LIBS
2635
2636 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2637 dnl other platforms.
2638 HAVE_DBUS=no
2639 DBUS_OBJ=
2640 if test "${with_dbus}" = "yes"; then
2641    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2642    if test "$HAVE_DBUS" = yes; then
2643      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2644      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2645      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2646      dnl D-Bus 1.5.12.
2647      OLD_LIBS=$LIBS
2648      LIBS="$LIBS $DBUS_LIBS"
2649      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2650                     dbus_type_is_valid \
2651                     dbus_validate_bus_name \
2652                     dbus_validate_path \
2653                     dbus_validate_interface \
2654                     dbus_validate_member)
2655      LIBS=$OLD_LIBS
2656      DBUS_OBJ=dbusbind.o
2657    fi
2658 fi
2659 AC_SUBST(DBUS_CFLAGS)
2660 AC_SUBST(DBUS_LIBS)
2661 AC_SUBST(DBUS_OBJ)
2662
2663 dnl GSettings has been tested under GNU/Linux only.
2664 HAVE_GSETTINGS=no
2665 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2666    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2667    if test "$HAVE_GSETTINGS" = "yes"; then
2668       old_CFLAGS=$CFLAGS
2669       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2670       old_LIBS=$LIBS
2671       LIBS="$LIBS $GSETTINGS_LIBS"
2672       AC_MSG_CHECKING([whether GSettings is in gio])
2673       AC_LINK_IFELSE(
2674          [AC_LANG_PROGRAM(
2675              [[/* Check that gsettings really is present.  */
2676              #include <glib-object.h>
2677              #include <gio/gio.h>
2678              ]],
2679              [[
2680                GSettings *settings;
2681                GVariant *val = g_settings_get_value (settings, "");
2682              ]])],
2683          [], HAVE_GSETTINGS=no)
2684       AC_MSG_RESULT([$HAVE_GSETTINGS])
2685
2686       if test "$HAVE_GSETTINGS" = "yes"; then
2687         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2688         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2689         SETTINGS_LIBS="$GSETTINGS_LIBS"
2690       fi
2691       CFLAGS=$old_CFLAGS
2692       LIBS=$old_LIBS
2693    fi
2694 fi
2695
2696 dnl GConf has been tested under GNU/Linux only.
2697 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2698 HAVE_GCONF=no
2699 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2700    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2701    if test "$HAVE_GCONF" = yes; then
2702       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2703       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2704       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2705       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2706    fi
2707 fi
2708
2709 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2710     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2711     if test "$HAVE_GOBJECT" = "yes"; then
2712        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2713        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2714     fi
2715     SAVE_CFLAGS="$CFLAGS"
2716     SAVE_LIBS="$LIBS"
2717     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2718     LIBS="$SETTINGS_LIBS $LIBS"
2719     CFLAGS="$SAVE_CFLAGS"
2720     LIBS="$SAVE_LIBS"
2721 fi
2722 AC_SUBST(SETTINGS_CFLAGS)
2723 AC_SUBST(SETTINGS_LIBS)
2724
2725
2726 dnl SELinux is available for GNU/Linux only.
2727 HAVE_LIBSELINUX=no
2728 LIBSELINUX_LIBS=
2729 if test "${with_selinux}" = "yes"; then
2730    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2731    if test "$HAVE_LIBSELINUX" = yes; then
2732       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2733       LIBSELINUX_LIBS=-lselinux
2734    fi
2735 fi
2736 AC_SUBST(LIBSELINUX_LIBS)
2737
2738 HAVE_GNUTLS=no
2739 if test "${with_gnutls}" = "yes" ; then
2740   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2741     [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2742   if test "${HAVE_GNUTLS}" = "yes"; then
2743     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2744     EMACS_CHECK_MODULES([LIBGNUTLS3], [gnutls >= 3.0.0],
2745       [AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])], [])
2746   fi
2747
2748   # Windows loads GnuTLS dynamically
2749   if test "${opsys}" = "mingw32"; then
2750     LIBGNUTLS_LIBS=
2751   fi
2752 fi
2753
2754 AC_SUBST(LIBGNUTLS_LIBS)
2755 AC_SUBST(LIBGNUTLS_CFLAGS)
2756
2757 HAVE_LIBSYSTEMD=no
2758 if test "${with_libsystemd}" = "yes" ; then
2759   dnl This code has been tested with libsystemd 222 and later.
2760   dnl FIXME: Find the earliest version number for which Emacs should work,
2761   dnl and change '222' to that number.
2762   EMACS_CHECK_MODULES([LIBSYSTEMD], [libsystemd >= 222],
2763     [HAVE_LIBSYSTEMD=yes], [HAVE_LIBSYSTEMD=no])
2764   if test "${HAVE_LIBSYSTEMD}" = "yes"; then
2765     AC_DEFINE(HAVE_LIBSYSTEMD, 1, [Define if using libsystemd.])
2766   fi
2767 fi
2768
2769 AC_SUBST(LIBSYSTEMD_LIBS)
2770 AC_SUBST(LIBSYSTEMD_CFLAGS)
2771
2772 NOTIFY_OBJ=
2773 NOTIFY_SUMMARY=no
2774
2775 dnl MS Windows native file monitor is available for mingw32 only.
2776 case $with_file_notification,$opsys in
2777   w32,cygwin)
2778     AC_MSG_ERROR(['--with-file-notification=w32' was specified, but
2779     this is only supported on MS-Windows native and MinGW32 builds.
2780     Consider using gfile instead.])
2781     ;;
2782   w32,* | yes,mingw32)
2783     AC_CHECK_HEADER(windows.h)
2784     if test "$ac_cv_header_windows_h" = yes ; then
2785        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2786        NOTIFY_OBJ=w32notify.o
2787        NOTIFY_SUMMARY="yes (w32)"
2788     fi ;;
2789 esac
2790
2791 dnl inotify is available only on GNU/Linux.
2792 case $with_file_notification,$NOTIFY_OBJ in
2793   inotify, | yes,)
2794     AC_CHECK_HEADER(sys/inotify.h)
2795     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2796         AC_CHECK_FUNC(inotify_init1)
2797         if test "$ac_cv_func_inotify_init1" = yes; then
2798           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2799           NOTIFY_OBJ=inotify.o
2800           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2801        fi
2802     fi ;;
2803 esac
2804
2805 dnl kqueue is available on BSD-like systems.
2806 case $with_file_notification,$NOTIFY_OBJ in
2807   kqueue,* | yes,)
2808     EMACS_CHECK_MODULES([KQUEUE], [libkqueue])
2809     if test "$HAVE_KQUEUE" = "yes"; then
2810        AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2811        CPPFLAGS="$CPPFLAGS -I/usr/include/kqueue"
2812        NOTIFY_CFLAGS=$KQUEUE_CFLAGS
2813        NOTIFY_LIBS=$KQUEUE_LIBS
2814        NOTIFY_OBJ=kqueue.o
2815        NOTIFY_SUMMARY="yes -lkqueue"
2816     else
2817        AC_SEARCH_LIBS(kqueue, [])
2818        if test "$ac_cv_search_kqueue" != no; then
2819          AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2820          NOTIFY_OBJ=kqueue.o
2821          NOTIFY_SUMMARY="yes (kqueue)"
2822        fi
2823     fi ;;
2824 esac
2825
2826 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2827 dnl has been added in glib 2.24.  It has been tested under
2828 dnl GNU/Linux only.
2829 case $with_file_notification,$NOTIFY_OBJ in
2830   gfile,* | yes,)
2831     if test "${HAVE_NS}" = yes; then
2832        AC_MSG_ERROR(['--with-file-notification=gfile' is not supported in NextStep builds.
2833 Consider kqueue instead.])
2834     else
2835        EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2836        if test "$HAVE_GFILENOTIFY" = "yes"; then
2837           AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2838           NOTIFY_CFLAGS=$GFILENOTIFY_CFLAGS
2839           NOTIFY_LIBS=$GFILENOTIFY_LIBS
2840           NOTIFY_OBJ=gfilenotify.o
2841           NOTIFY_SUMMARY="yes -lgio (gfile)"
2842        fi
2843     fi ;;
2844 esac
2845
2846 case $with_file_notification,$NOTIFY_OBJ in
2847   yes,* | no,* | *,?*) ;;
2848   *) AC_MSG_ERROR([File notification '$with_file_notification' requested but requirements not found.]) ;;
2849 esac
2850
2851 if test -n "$NOTIFY_OBJ"; then
2852    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2853 fi
2854 AC_SUBST(NOTIFY_CFLAGS)
2855 AC_SUBST(NOTIFY_LIBS)
2856 AC_SUBST(NOTIFY_OBJ)
2857
2858 dnl Do not put whitespace before the #include statements below.
2859 dnl Older compilers (eg sunos4 cc) choke on it.
2860 HAVE_XAW3D=no
2861 LUCID_LIBW=
2862 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2863   if test "$with_xaw3d" != no; then
2864     AC_CACHE_VAL(emacs_cv_xaw3d,
2865     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2866 #include <X11/Intrinsic.h>
2867 #include <X11/Xaw3d/Simple.h>]],
2868       [[]])],
2869       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2870                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2871       emacs_cv_xaw3d=no)])
2872   else
2873     emacs_cv_xaw3d=no
2874   fi
2875   if test $emacs_cv_xaw3d = yes; then
2876     AC_MSG_CHECKING(for xaw3d)
2877     AC_MSG_RESULT([yes; using Lucid toolkit])
2878     USE_X_TOOLKIT=LUCID
2879     HAVE_XAW3D=yes
2880     LUCID_LIBW=-lXaw3d
2881     AC_DEFINE(HAVE_XAW3D, 1,
2882               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2883   else
2884     AC_MSG_CHECKING(for xaw3d)
2885     AC_MSG_RESULT(no)
2886     AC_MSG_CHECKING(for libXaw)
2887     AC_CACHE_VAL(emacs_cv_xaw,
2888     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2889 #include <X11/Intrinsic.h>
2890 #include <X11/Xaw/Simple.h>]],
2891       [[]])],
2892       emacs_cv_xaw=yes,
2893       emacs_cv_xaw=no)])
2894     if test $emacs_cv_xaw = yes; then
2895       AC_MSG_RESULT([yes; using Lucid toolkit])
2896       USE_X_TOOLKIT=LUCID
2897       LUCID_LIBW=-lXaw
2898     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2899       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2900     else
2901       AC_MSG_ERROR([No X toolkit could be found.
2902 If you are sure you want Emacs compiled without an X toolkit, pass
2903   --with-x-toolkit=no
2904 to configure.  Otherwise, install the development libraries for the toolkit
2905 that you want to use (e.g. Gtk+) and re-run configure.])
2906     fi
2907   fi
2908 fi
2909
2910 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2911
2912 LIBXTR6=
2913 LIBXMU=
2914 if test "${USE_X_TOOLKIT}" != "none"; then
2915   AC_MSG_CHECKING(X11 toolkit version)
2916   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2917   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2918 [[#if XtSpecificationRelease < 6
2919 fail;
2920 #endif
2921 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2922   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2923   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2924     AC_MSG_RESULT(6 or newer)
2925     AC_DEFINE(HAVE_X11XTR6, 1,
2926               [Define to 1 if you have the X11R6 or newer version of Xt.])
2927     LIBXTR6="-lSM -lICE"
2928     case "$opsys" in
2929       ## Use libw.a along with X11R6 Xt.
2930       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2931     esac
2932   else
2933     AC_MSG_RESULT(before 6)
2934   fi
2935
2936 dnl If using toolkit, check whether libXmu.a exists.
2937 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2938   OLDLIBS="$LIBS"
2939   if test x$HAVE_X11XTR6 = xyes; then
2940     OTHERLIBS='-lXt -lSM -lICE'
2941   else
2942     OTHERLIBS='-lXt'
2943   fi
2944   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2945   if test "X$LIBS" != "X$OLDLIBS"; then
2946     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2947   fi
2948   LIBS=$OLDLIBS
2949   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2950 fi
2951 AC_SUBST(LIBXTR6)
2952 AC_SUBST(LIBXMU)
2953
2954 LIBXP=
2955 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2956   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2957   if test -d /usr/include/openmotif; then
2958     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2959     emacs_cv_openmotif=yes
2960     case "$canonical" in
2961       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2962       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2963       ;;
2964       *)
2965       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2966     esac
2967   else
2968     emacs_cv_openmotif=no
2969   fi
2970   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2971   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2972     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2973 int x = 5;
2974 #else
2975 Motif version prior to 2.1.
2976 #endif]])],
2977     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2978   if test $emacs_cv_motif_version_2_1 = yes; then
2979     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2980     if test x$emacs_cv_openmotif = xyes; then
2981       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2982     fi
2983   else
2984     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2985     # We put this in CFLAGS temporarily to precede other -I options
2986     # that might be in CFLAGS temporarily.
2987     # We put this in CPPFLAGS where it precedes the other -I options.
2988     OLD_CPPFLAGS=$CPPFLAGS
2989     OLD_CFLAGS=$CFLAGS
2990     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2991     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2992     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2993       [[int x = 5;]])],
2994       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2995     if test $emacs_cv_lesstif = yes; then
2996       # Make sure this -I option remains in CPPFLAGS after it is set
2997       # back to REAL_CPPFLAGS.
2998       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2999       # have those other -I options anyway.  Ultimately, having this
3000       # directory ultimately in CPPFLAGS will be enough.
3001       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
3002       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
3003     else
3004       CFLAGS=$OLD_CFLAGS
3005       CPPFLAGS=$OLD_CPPFLAGS
3006     fi
3007   fi
3008   AC_CHECK_HEADER([Xm/BulletinB.h], [],
3009     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
3010 fi
3011
3012 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
3013 dnl using Motif or Xaw3d is available, and unless
3014 dnl --with-toolkit-scroll-bars=no was specified.
3015
3016 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
3017             [Define to 1 if we should use toolkit scroll bars.])dnl
3018 USE_TOOLKIT_SCROLL_BARS=no
3019 if test "${with_toolkit_scroll_bars}" != "no"; then
3020   if test "${USE_X_TOOLKIT}" != "none"; then
3021     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
3022       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3023       HAVE_XAW3D=no
3024       USE_TOOLKIT_SCROLL_BARS=yes
3025     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
3026       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3027       USE_TOOLKIT_SCROLL_BARS=yes
3028     fi
3029   elif test "${HAVE_GTK}" = "yes"; then
3030     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3031     USE_TOOLKIT_SCROLL_BARS=yes
3032   elif test "${HAVE_NS}" = "yes"; then
3033     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3034     USE_TOOLKIT_SCROLL_BARS=yes
3035   elif test "${HAVE_W32}" = "yes"; then
3036     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3037     USE_TOOLKIT_SCROLL_BARS=yes
3038   fi
3039 fi
3040
3041 dnl See if XIM is available.
3042 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3043           #include <X11/Xlib.h>
3044           #include <X11/Xresource.h>]],
3045          [[XIMProc  callback;]])],
3046          [HAVE_XIM=yes
3047          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
3048          HAVE_XIM=no)
3049
3050 dnl '--with-xim' now controls only the initial value of use_xim at run time.
3051
3052 if test "${with_xim}" != "no"; then
3053   AC_DEFINE(USE_XIM, 1,
3054             [Define to 1 if we should use XIM, if it is available.])
3055 fi
3056
3057
3058 if test "${HAVE_XIM}" != "no"; then
3059   late_CFLAGS=$CFLAGS
3060   if test "$GCC" = yes; then
3061     CFLAGS="$CFLAGS --pedantic-errors"
3062   fi
3063   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3064 #include <X11/Xlib.h>
3065 #include <X11/Xresource.h>]],
3066 [[Display *display;
3067 XrmDatabase db;
3068 char *res_name;
3069 char *res_class;
3070 XIMProc  callback;
3071 XPointer *client_data;
3072 #ifndef __GNUC__
3073 /* If we're not using GCC, it's probably not XFree86, and this is
3074    probably right, but we can't use something like --pedantic-errors.  */
3075 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
3076                                            char*, XIMProc, XPointer*);
3077 #endif
3078 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
3079    client_data);]])],
3080     [emacs_cv_arg6_star=yes])
3081   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
3082          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
3083 either XPointer or XPointer*.])dnl
3084   if test "$emacs_cv_arg6_star" = yes; then
3085     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
3086   else
3087     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
3088   fi
3089   CFLAGS=$late_CFLAGS
3090 fi
3091
3092 ### Start of font-backend (under any platform) section.
3093 # (nothing here yet -- this is a placeholder)
3094 ### End of font-backend (under any platform) section.
3095
3096 ### Start of font-backend (under X11) section.
3097 if test "${HAVE_X11}" = "yes"; then
3098     ## Use -lXft if available, unless '--with-xft=no'.
3099     HAVE_XFT=maybe
3100     if test "x${with_x}" = "xno"; then
3101       with_xft="no";
3102     fi
3103
3104     if test "$with_xft" != no; then
3105       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
3106       with_xft=$HAVE_FONTCONFIG
3107     fi
3108
3109     if test "x${with_xft}" != "xno"; then
3110
3111       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
3112       ## Because xftfont.c uses XRenderQueryExtension, we also
3113       ## need to link to -lXrender.
3114       HAVE_XRENDER=no
3115       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
3116       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
3117         OLD_CPPFLAGS="$CPPFLAGS"
3118         OLD_CFLAGS="$CFLAGS"
3119         OLD_LIBS="$LIBS"
3120         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
3121         CFLAGS="$CFLAGS $XFT_CFLAGS"
3122         XFT_LIBS="-lXrender $XFT_LIBS"
3123         LIBS="$XFT_LIBS $LIBS"
3124         AC_CHECK_HEADER(X11/Xft/Xft.h,
3125           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
3126           [[#include <X11/X.h>]])
3127
3128         if test "${HAVE_XFT}" = "yes"; then
3129           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
3130             AC_SUBST(XFT_LIBS)
3131           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
3132         fi                        # "${HAVE_XFT}" = "yes"
3133         CPPFLAGS=$OLD_CPPFLAGS
3134         CFLAGS=$OLD_CFLAGS
3135         LIBS=$OLD_LIBS
3136       fi                          # "$HAVE_XFT" != no
3137     fi                            # "x${with_xft}" != "xno"
3138
3139     ## We used to allow building with FreeType and without Xft.
3140     ## However, the ftx font backend driver is not in good shape.
3141     if test "$HAVE_XFT" != "yes"; then
3142        dnl For the "Does Emacs use" message at the end.
3143        HAVE_XFT=no
3144        HAVE_FREETYPE=no
3145     else
3146        dnl Strict linkers fail with
3147        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
3148        dnl if -lfreetype is not specified.
3149        dnl The following is needed to set FREETYPE_LIBS.
3150        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
3151
3152        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
3153     fi
3154
3155     HAVE_LIBOTF=no
3156     if test "${HAVE_FREETYPE}" = "yes"; then
3157       AC_DEFINE(HAVE_FREETYPE, 1,
3158                 [Define to 1 if using the freetype and fontconfig libraries.])
3159       if test "${with_libotf}" != "no"; then
3160         EMACS_CHECK_MODULES([LIBOTF], [libotf])
3161         if test "$HAVE_LIBOTF" = "yes"; then
3162           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
3163           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
3164                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
3165                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
3166           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
3167             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
3168                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
3169           fi
3170         fi
3171       fi
3172     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
3173     dnl Does the new font backend require it, or can it work without it?
3174     fi
3175
3176     HAVE_M17N_FLT=no
3177     if test "${HAVE_LIBOTF}" = yes; then
3178       if test "${with_m17n_flt}" != "no"; then
3179         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
3180         if test "$HAVE_M17N_FLT" = "yes"; then
3181           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
3182         fi
3183       fi
3184     fi
3185 else
3186     HAVE_XFT=no
3187     HAVE_FREETYPE=no
3188     HAVE_LIBOTF=no
3189     HAVE_M17N_FLT=no
3190 fi
3191
3192 ### End of font-backend (under X11) section.
3193
3194 AC_SUBST(FREETYPE_CFLAGS)
3195 AC_SUBST(FREETYPE_LIBS)
3196 AC_SUBST(FONTCONFIG_CFLAGS)
3197 AC_SUBST(FONTCONFIG_LIBS)
3198 AC_SUBST(LIBOTF_CFLAGS)
3199 AC_SUBST(LIBOTF_LIBS)
3200 AC_SUBST(M17N_FLT_CFLAGS)
3201 AC_SUBST(M17N_FLT_LIBS)
3202
3203 HAVE_CAIRO=no
3204 if test "${HAVE_X11}" = "yes"; then
3205   if test "${with_cairo}" != "no"; then
3206     CAIRO_REQUIRED=1.12.0
3207     CAIRO_MODULE="cairo >= $CAIRO_REQUIRED"
3208     EMACS_CHECK_MODULES(CAIRO, $CAIRO_MODULE)
3209     if test $HAVE_CAIRO = yes; then
3210       AC_DEFINE(USE_CAIRO, 1, [Define to 1 if using cairo.])
3211     else
3212       AC_MSG_ERROR([cairo requested but not found.])
3213     fi
3214
3215     CFLAGS="$CFLAGS $CAIRO_CFLAGS"
3216     LIBS="$LIBS $CAIRO_LIBS"
3217     AC_SUBST(CAIRO_CFLAGS)
3218     AC_SUBST(CAIRO_LIBS)
3219   fi
3220 fi
3221
3222 if test "${HAVE_X11}" = "yes"; then
3223   AC_CHECK_HEADER(X11/Xlib-xcb.h,
3224     AC_CHECK_LIB(xcb, xcb_translate_coordinates, HAVE_XCB=yes))
3225   if test "${HAVE_XCB}" = "yes"; then
3226     AC_CHECK_LIB(X11-xcb, XGetXCBConnection, HAVE_X11_XCB=yes)
3227     if test "${HAVE_X11_XCB}" = "yes"; then
3228       AC_DEFINE(USE_XCB, 1,
3229 [Define to 1 if you have the XCB library and X11-XCB library for mixed
3230    X11/XCB programming.])
3231       XCB_LIBS="-lX11-xcb -lxcb"
3232       AC_SUBST(XCB_LIBS)
3233     fi
3234   fi
3235 fi
3236
3237 ### Use -lXpm if available, unless '--with-xpm=no'.
3238 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
3239 ### In the Cygwin-w32 build, we need to use /usr/include/noX/X11/xpm.h
3240 ### rather than /usr/include/X11/xpm.h, so we set CPPFLAGS (and
3241 ### LDFLAGS) accordingly.
3242 HAVE_XPM=no
3243 LIBXPM=
3244 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3245   if test "${with_xpm}" != "no"; then
3246     SAVE_CPPFLAGS="$CPPFLAGS"
3247     SAVE_LDFLAGS="$LDFLAGS"
3248     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
3249     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3250     AC_CHECK_HEADER(X11/xpm.h,
3251       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3252     if test "${HAVE_XPM}" = "yes"; then
3253       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3254       AC_EGREP_CPP(no_return_alloc_pixels,
3255       [#include "X11/xpm.h"
3256 #ifndef XpmReturnAllocPixels
3257 no_return_alloc_pixels
3258 #endif
3259       ], HAVE_XPM=no, HAVE_XPM=yes)
3260
3261       if test "${HAVE_XPM}" = "yes"; then
3262         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3263         AC_MSG_RESULT(yes)
3264       else
3265         AC_MSG_RESULT(no)
3266         CPPFLAGS="$SAVE_CPPFLAGS"
3267         LDFLAGS="$SAVE_LDFLAGS"
3268       fi
3269     fi
3270   fi
3271
3272   if test "${HAVE_XPM}" = "yes"; then
3273     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3274     LIBXPM=-lXpm
3275   fi
3276 fi
3277
3278 if test "${HAVE_X11}" = "yes"; then
3279   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3280   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3281
3282   if test "${with_xpm}" != "no"; then
3283     AC_CHECK_HEADER(X11/xpm.h,
3284       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3285     if test "${HAVE_XPM}" = "yes"; then
3286       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3287       AC_EGREP_CPP(no_return_alloc_pixels,
3288       [#include "X11/xpm.h"
3289 #ifndef XpmReturnAllocPixels
3290 no_return_alloc_pixels
3291 #endif
3292       ], HAVE_XPM=no, HAVE_XPM=yes)
3293
3294       if test "${HAVE_XPM}" = "yes"; then
3295         AC_MSG_RESULT(yes)
3296       else
3297         AC_MSG_RESULT(no)
3298       fi
3299     fi
3300   fi
3301
3302   if test "${HAVE_XPM}" = "yes"; then
3303     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3304     LIBXPM=-lXpm
3305   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3306     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3307     LIBXPM=-lXpm
3308   fi
3309 fi
3310
3311 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3312 ### slightly different requirements wrt image libraries (it doesn't
3313 ### use -lXpm because it loads the xpm shared library dynamically at
3314 ### run time).
3315 if test "${opsys}" = "mingw32"; then
3316   if test "${with_xpm}" != "no"; then
3317     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3318 #define FOR_MSW 1])
3319   fi
3320
3321   if test "${HAVE_XPM}" = "yes"; then
3322     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3323   fi
3324 fi
3325
3326 AC_SUBST(LIBXPM)
3327
3328 ### Use -ljpeg if available, unless '--with-jpeg=no'.
3329 HAVE_JPEG=no
3330 LIBJPEG=
3331 if test "${with_jpeg}" != "no"; then
3332   AC_CACHE_CHECK([for jpeglib 6b or later],
3333     [emacs_cv_jpeglib],
3334     [OLD_LIBS=$LIBS
3335      for emacs_cv_jpeglib in yes -ljpeg no; do
3336        case $emacs_cv_jpeglib in
3337          yes) ;;
3338          no) break;;
3339          *) LIBS="$LIBS $emacs_cv_jpeglib";;
3340        esac
3341        AC_LINK_IFELSE(
3342          [AC_LANG_PROGRAM(
3343             [[#undef HAVE_STDLIB_H /* Avoid config.h/jpeglib.h collision.  */
3344               #include <stdio.h> /* jpeglib.h needs FILE and size_t.  */
3345               #include <jpeglib.h>
3346               #include <jerror.h>
3347               char verify[JPEG_LIB_VERSION < 62 ? -1 : 1];
3348               struct jpeg_decompress_struct cinfo;
3349             ]],
3350             [[
3351               jpeg_create_decompress (&cinfo);
3352               WARNMS (&cinfo, JWRN_JPEG_EOF);
3353               jpeg_destroy_decompress (&cinfo);
3354             ]])],
3355          [emacs_link_ok=yes],
3356          [emacs_link_ok=no])
3357        LIBS=$OLD_LIBS
3358        test $emacs_link_ok = yes && break
3359      done])
3360   if test "$emacs_cv_jpeglib" != no; then
3361     HAVE_JPEG=yes
3362     AC_DEFINE([HAVE_JPEG], 1,
3363       [Define to 1 if you have the jpeg library (typically -ljpeg).])
3364     ### mingw32 doesn't use -ljpeg, since it loads the library
3365     ### dynamically when needed, and doesn't want a run-time
3366     ### dependency on the jpeglib DLL.
3367     test "$emacs_cv_jpeglib" != yes && test "${opsys}" != "mingw32" \
3368     && LIBJPEG=$emacs_cv_jpeglib
3369   fi
3370 fi
3371 AC_SUBST(LIBJPEG)
3372
3373 HAVE_ZLIB=no
3374 LIBZ=
3375 if test "${with_zlib}" != "no"; then
3376   OLIBS=$LIBS
3377   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3378   LIBS=$OLIBS
3379   case $ac_cv_search_inflateEnd in
3380     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3381   esac
3382 fi
3383 if test "${HAVE_ZLIB}" = "yes"; then
3384   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3385   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3386   if test "${opsys}" = "mingw32"; then
3387      LIBZ=
3388   fi
3389 fi
3390 AC_SUBST(LIBZ)
3391
3392 ### Dynamic modules support
3393 LIBMODULES=
3394 HAVE_MODULES=no
3395 MODULES_OBJ=
3396 MODULES_SUFFIX=
3397 if test "${with_modules}" != "no"; then
3398   case $opsys in
3399     gnu|gnu-linux)
3400       LIBMODULES="-ldl"
3401       MODULES_SUFFIX=".so"
3402       HAVE_MODULES=yes
3403       ;;
3404     cygwin|mingw32)
3405       MODULES_SUFFIX=".dll"
3406       HAVE_MODULES=yes
3407       ;;
3408     darwin)
3409       MODULES_SUFFIX=".so"
3410       HAVE_MODULES=yes
3411       ;;
3412     *)
3413       # BSD systems have dlopen in libc.
3414       AC_CHECK_FUNC([dlopen],
3415         [MODULES_SUFFIX=".so"
3416          HAVE_MODULES=yes])
3417       ;;
3418   esac
3419
3420   if test "${HAVE_MODULES}" = no; then
3421     AC_MSG_ERROR([Dynamic modules are not supported on your system])
3422   else
3423     SAVE_LIBS=$LIBS
3424     LIBS="$LIBS $LIBMODULES"
3425     AC_CHECK_FUNCS([dladdr dlfunc])
3426     LIBS=$SAVE_LIBS
3427   fi
3428 fi
3429
3430 if test "${HAVE_MODULES}" = yes; then
3431    MODULES_OBJ="dynlib.o emacs-module.o"
3432    AC_DEFINE(HAVE_MODULES, 1, [Define to 1 if dynamic modules are enabled])
3433    AC_DEFINE_UNQUOTED(MODULES_SUFFIX, "$MODULES_SUFFIX",
3434      [System extension for dynamic libraries])
3435 fi
3436 AC_SUBST(MODULES_OBJ)
3437 AC_SUBST(LIBMODULES)
3438
3439 ### Use -lpng if available, unless '--with-png=no'.
3440 HAVE_PNG=no
3441 LIBPNG=
3442 PNG_CFLAGS=
3443 if test "${NS_IMPL_COCOA}" = yes; then
3444   : # Nothing to do
3445 elif test "${with_png}" != no; then
3446   # mingw32 loads the library dynamically.
3447   if test "$opsys" = mingw32; then
3448     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3449   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3450     AC_MSG_CHECKING([for png])
3451     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3452     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3453       # libpng-config does not work; configure by hand.
3454       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3455       # in /usr/include/libpng.
3456       if test -r /usr/include/libpng/png.h &&
3457          test ! -r /usr/include/png.h; then
3458         png_cflags=-I/usr/include/libpng
3459       else
3460         png_cflags=
3461       fi
3462       png_libs='-lpng'
3463     }
3464     SAVE_CFLAGS=$CFLAGS
3465     SAVE_LIBS=$LIBS
3466     CFLAGS="$CFLAGS $png_cflags"
3467     LIBS="$png_libs -lz -lm $LIBS"
3468     AC_LINK_IFELSE(
3469       [AC_LANG_PROGRAM([[#include <png.h>]],
3470          [[return !png_get_channels (0, 0);]])],
3471       [HAVE_PNG=yes
3472        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3473        LIBPNG=$png_libs
3474        # $LIBPNG requires explicit -lz in some cases.
3475        # We don't know what those cases are, exactly, so play it safe and
3476        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3477        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3478          LIBPNG="$LIBPNG -lz"
3479        fi])
3480     CFLAGS=$SAVE_CFLAGS
3481     LIBS=$SAVE_LIBS
3482     AC_MSG_RESULT([$HAVE_PNG])
3483   fi
3484 fi
3485 if test $HAVE_PNG = yes; then
3486   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3487
3488   SAVE_CFLAGS=$CFLAGS
3489   CFLAGS="$CFLAGS $PNG_CFLAGS"
3490   AC_CHECK_DECL([png_longjmp],
3491     [],
3492     [AC_DEFINE([PNG_DEPSTRUCT], [],
3493        [Define to empty to suppress deprecation warnings when building
3494         with --enable-gcc-warnings and with libpng versions before 1.5,
3495         which lack png_longjmp.])],
3496     [[#include <png.h>
3497     ]])
3498   CFLAGS=$SAVE_CFLAGS
3499 fi
3500 AC_SUBST(LIBPNG)
3501 AC_SUBST(PNG_CFLAGS)
3502
3503 ### Use -ltiff if available, unless '--with-tiff=no'.
3504 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3505 HAVE_TIFF=no
3506 LIBTIFF=
3507 if test "${opsys}" = "mingw32"; then
3508   if test "${with_tiff}" != "no"; then
3509     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3510   fi
3511   if test "${HAVE_TIFF}" = "yes"; then
3512     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3513   fi
3514 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3515   if test "${with_tiff}" != "no"; then
3516     AC_CHECK_HEADER(tiffio.h,
3517       [tifflibs="-lz -lm"
3518       # At least one tiff package requires the jpeg library.
3519       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3520       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3521   fi
3522
3523   if test "${HAVE_TIFF}" = "yes"; then
3524     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3525     dnl FIXME -lz -lm, as per libpng?
3526     LIBTIFF=-ltiff
3527   fi
3528 fi
3529 AC_SUBST(LIBTIFF)
3530
3531 ### Use -lgif or -lungif if available, unless '--with-gif=no'.
3532 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3533 HAVE_GIF=no
3534 LIBGIF=
3535 if test "${opsys}" = "mingw32"; then
3536   if test "${with_gif}" != "no"; then
3537     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3538   fi
3539   if test "${HAVE_GIF}" = "yes"; then
3540     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3541   fi
3542 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3543         || test "${HAVE_W32}" = "yes"; then
3544   AC_CHECK_HEADER(gif_lib.h,
3545 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3546 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3547     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3548         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3549
3550   if test "$HAVE_GIF" = yes; then
3551     LIBGIF=-lgif
3552   elif test "$HAVE_GIF" = maybe; then
3553 # If gif_lib.h but no libgif, try libungif.
3554     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3555     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3556   fi
3557
3558   if test "${HAVE_GIF}" = "yes"; then
3559     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3560   fi
3561 fi
3562 AC_SUBST(LIBGIF)
3563
3564 dnl Check for required libraries.
3565 if test "${HAVE_X11}" = "yes"; then
3566   MISSING=""
3567   WITH_NO=""
3568   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3569     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3570   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3571     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3572   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3573     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3574   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3575     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3576   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3577     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3578
3579   if test "X${MISSING}" != X; then
3580     AC_MSG_ERROR([The following required libraries were not found:
3581     $MISSING
3582 Maybe some development libraries/packages are missing?
3583 If you don't want to link with them give
3584     $WITH_NO
3585 as options to configure])
3586   fi
3587 fi
3588
3589 ### Use -lgpm if available, unless '--with-gpm=no'.
3590 HAVE_GPM=no
3591 LIBGPM=
3592 if test "${with_gpm}" != "no"; then
3593   AC_CHECK_HEADER(gpm.h,
3594     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3595
3596   if test "${HAVE_GPM}" = "yes"; then
3597     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3598     LIBGPM=-lgpm
3599   fi
3600 fi
3601 AC_SUBST(LIBGPM)
3602
3603 dnl Check for malloc/malloc.h on darwin
3604 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3605
3606 GNUSTEP_CFLAGS=
3607 ### Use NeXTstep API to implement GUI.
3608 if test "${HAVE_NS}" = "yes"; then
3609   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3610   if test "${NS_IMPL_COCOA}" = "yes"; then
3611     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3612   fi
3613   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3614     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3615     if test $NS_GNUSTEP_CONFIG != yes; then
3616       # See also .m.o rule in src/Makefile.in.  */
3617       # FIXME: are all these flags really needed?  Document here why.  */
3618       GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3619       ## Extra CFLAGS applied to src/*.m files.
3620       GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3621     fi
3622   fi
3623   OTHER_FILES=ns-app
3624 fi
3625
3626 ### Use session management (-lSM -lICE) if available
3627 HAVE_X_SM=no
3628 LIBXSM=
3629 if test "${HAVE_X11}" = "yes"; then
3630   AC_CHECK_HEADER(X11/SM/SMlib.h,
3631     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3632
3633   if test "${HAVE_X_SM}" = "yes"; then
3634     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3635     LIBXSM="-lSM -lICE"
3636   fi
3637 fi
3638 AC_SUBST(LIBXSM)
3639
3640 ### Use XRandr (-lXrandr) if available
3641 HAVE_XRANDR=no
3642 if test "${HAVE_X11}" = "yes"; then
3643   XRANDR_REQUIRED=1.2.2
3644   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3645   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3646   if test $HAVE_XRANDR = no; then
3647     # Test old way in case pkg-config doesn't have it (older machines).
3648     # Include Xrender.h by hand to work around bug in older Xrandr.h
3649     # (e.g. RHEL5) and silence (harmless) configure warning (bug#18465).
3650     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3651       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)],
3652       [], [AC_INCLUDES_DEFAULT
3653 #include <X11/extensions/Xrender.h>])
3654     if test $HAVE_XRANDR = yes; then
3655       XRANDR_LIBS=-lXrandr
3656     fi
3657   fi
3658   if test $HAVE_XRANDR = yes; then
3659     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3660   fi
3661 fi
3662 AC_SUBST(XRANDR_CFLAGS)
3663 AC_SUBST(XRANDR_LIBS)
3664
3665 ### Use Xinerama (-lXinerama) if available
3666 HAVE_XINERAMA=no
3667 if test "${HAVE_X11}" = "yes"; then
3668   XINERAMA_REQUIRED=1.0.2
3669   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3670   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3671   if test $HAVE_XINERAMA = no; then
3672     # Test old way in case pkg-config doesn't have it (older machines).
3673     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3674       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3675     if test $HAVE_XINERAMA = yes; then
3676       XINERAMA_LIBS=-lXinerama
3677     fi
3678   fi
3679   if test $HAVE_XINERAMA = yes; then
3680     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3681   fi
3682 fi
3683 AC_SUBST(XINERAMA_CFLAGS)
3684 AC_SUBST(XINERAMA_LIBS)
3685
3686 ### Use Xfixes (-lXfixes) if available
3687 HAVE_XFIXES=no
3688 if test "${HAVE_X11}" = "yes"; then
3689   XFIXES_REQUIRED=4.0.0
3690   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3691   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3692   if test $HAVE_XFIXES = no; then
3693     # Test old way in case pkg-config doesn't have it (older machines).
3694     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3695       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3696     if test $HAVE_XFIXES = yes; then
3697       XFIXES_LIBS=-lXfixes
3698     fi
3699   fi
3700   if test $HAVE_XFIXES = yes; then
3701     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3702   fi
3703 fi
3704 AC_SUBST(XFIXES_CFLAGS)
3705 AC_SUBST(XFIXES_LIBS)
3706
3707 ### Use libxml (-lxml2) if available
3708 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3709 HAVE_LIBXML2=no
3710 if test "${with_xml2}" != "no"; then
3711   ### I'm not sure what the version number should be, so I just guessed.
3712   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3713   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3714   if test "${HAVE_LIBXML2}" != "yes" && test "$opsys" = "darwin"; then
3715     SAVE_CPPFLAGS="$CPPFLAGS"
3716     if test -z "$xcsdkdir" -a -n "$XCRUN" -a ! -d /usr/include; then
3717       dnl /usr/include is not found.  Try Xcode SDK dir if it is sane.
3718       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
3719       case $xcsdkdir in
3720         *[[\\\"\#\$\&\'\`$am_lf\ \      ]]*)
3721         xcsdkdir="" ;;
3722       esac
3723     fi
3724     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3725     AC_CHECK_HEADER(libxml/HTMLparser.h,
3726       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3727                      [#include <libxml/HTMLparser.h>])])
3728     CPPFLAGS="$SAVE_CPPFLAGS"
3729     if test "${HAVE_LIBXML2}" = "yes"; then
3730       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3731       LIBXML2_LIBS="-lxml2"
3732     fi
3733   fi
3734   if test "${HAVE_LIBXML2}" = "yes"; then
3735     if test "${opsys}" != "mingw32"; then
3736       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no,
3737         [$LIBXML2_LIBS])
3738     else
3739       LIBXML2_LIBS=""
3740     fi
3741     if test "${HAVE_LIBXML2}" = "yes"; then
3742       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3743     else
3744       LIBXML2_LIBS=""
3745       LIBXML2_CFLAGS=""
3746     fi
3747   fi
3748 fi
3749 AC_SUBST(LIBXML2_LIBS)
3750 AC_SUBST(LIBXML2_CFLAGS)
3751
3752 # Check for mail-locking functions in a "mail" library.  Probably this should
3753 # have the same check as for liblockfile below.
3754 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3755 if test $have_mail = yes; then
3756   LIBS_MAIL=-lmail
3757   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the 'mail' library (-lmail).])
3758
3759   OLD_LIBS=$LIBS
3760   LIBS="$LIBS_MAIL $LIBS"
3761   AC_CHECK_FUNCS(touchlock)
3762   LIBS=$OLD_LIBS
3763 else
3764   LIBS_MAIL=
3765 fi
3766 dnl Debian, at least:
3767 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3768 if test $have_lockfile = yes; then
3769    LIBS_MAIL=-llockfile
3770    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the 'lockfile' library (-llockfile).])
3771 else
3772 # If we have the shared liblockfile, assume we must use it for mail
3773 # locking (e.g. Debian).  If we couldn't link against liblockfile
3774 # (no liblockfile.a installed), ensure that we don't need to.
3775   dnl This works for files generally, not just executables.
3776   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3777   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3778                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3779   if test $ac_cv_prog_liblockfile = yes; then
3780     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3781 This probably means that movemail could lose mail.
3782 There may be a 'development' package to install containing liblockfile.])
3783   fi
3784 fi
3785 AC_CHECK_HEADERS_ONCE(maillock.h)
3786 AC_SUBST(LIBS_MAIL)
3787
3788 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3789 ## interlock access to the mail spool.  The alternative is a lock file named
3790 ## /usr/spool/mail/$USER.lock.
3791 mail_lock=no
3792 case "$opsys" in
3793   aix4-2) mail_lock="lockf" ;;
3794
3795   gnu|freebsd|dragonfly|netbsd|openbsd|darwin) mail_lock="flock" ;;
3796
3797   ## On GNU/Linux systems, both methods are used by various mail programs.
3798   ## I assume most people are using newer mailers that have heard of flock.
3799   ## Change this if you need to.
3800   ## Debian contains a patch which says: "On Debian/GNU/Linux systems,
3801   ## configure gets the right answers, and that means *NOT* using flock.
3802   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3803   ## for details." and then uses '#ifdef DEBIAN'.  Unfortunately the
3804   ## Debian maintainer hasn't provided a clean fix for Emacs.
3805   ## movemail.c will use 'maillock' when MAILDIR, HAVE_LIBMAIL and
3806   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3807   ## correct logic.  -- fx
3808   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3809   ## liblockfile is a Free Software replacement for libmail, used on
3810   ## Debian systems and elsewhere. -rfr.
3811   gnu-*)
3812     mail_lock="flock"
3813     if test $have_mail = yes || test $have_lockfile = yes; then
3814       test $ac_cv_header_maillock_h = yes && mail_lock=no
3815     fi
3816     ;;
3817
3818   mingw32)
3819     mail_lock="none-needed" ;;
3820 esac
3821
3822 BLESSMAIL_TARGET=
3823 case "$mail_lock" in
3824   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3825
3826   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3827
3828   none-needed) ;;
3829
3830   *) BLESSMAIL_TARGET="need-blessmail" ;;
3831 esac
3832 AC_SUBST(BLESSMAIL_TARGET)
3833
3834 OLD_LIBS=$LIBS
3835 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3836 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3837 getrusage get_current_dir_name \
3838 lrand48 random rint \
3839 select getpagesize setlocale newlocale \
3840 getrlimit setrlimit shutdown \
3841 pthread_sigmask strsignal setitimer \
3842 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3843 gai_strerror sync \
3844 getpwent endpwent getgrent endgrent \
3845 cfmakeraw cfsetspeed copysign __executable_start log2)
3846 LIBS=$OLD_LIBS
3847
3848 dnl No need to check for posix_memalign if aligned_alloc works.
3849 AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3850 AC_CHECK_DECLS([aligned_alloc], [], [], [[#include <stdlib.h>]])
3851
3852 dnl Cannot use AC_CHECK_FUNCS
3853 AC_CACHE_CHECK([for __builtin_unwind_init],
3854                emacs_cv_func___builtin_unwind_init,
3855 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3856                 emacs_cv_func___builtin_unwind_init=yes,
3857                 emacs_cv_func___builtin_unwind_init=no)])
3858 if test $emacs_cv_func___builtin_unwind_init = yes; then
3859   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3860             [Define to 1 if you have the '__builtin_unwind_init' function.])
3861 fi
3862
3863 AC_CHECK_HEADERS_ONCE(sys/un.h)
3864
3865 AC_FUNC_FSEEKO
3866
3867 # UNIX98 PTYs.
3868 AC_CHECK_FUNCS(grantpt)
3869
3870 # PTY-related GNU extensions.
3871 AC_CHECK_FUNCS(getpt posix_openpt)
3872
3873 # Check this now, so that we will NOT find the above functions in ncurses.
3874 # That is because we have not set up to link ncurses in lib-src.
3875 # It's better to believe a function is not available
3876 # than to expect to find it in ncurses.
3877 # Also we need tputs and friends to be able to build at all.
3878 AC_MSG_CHECKING([for library containing tputs])
3879 # Run a test program that contains a call to tputs, a call that is
3880 # never executed.  This tests whether a pre-'main' dynamic linker
3881 # works with the library.  It's too much trouble to actually call
3882 # tputs in the test program, due to portability hassles.  When
3883 # cross-compiling, assume the test program will run if it links.
3884 AC_DEFUN([tputs_link_source], [
3885   AC_LANG_SOURCE(
3886      [[extern void tputs (const char *, int, int (*)(int));
3887        int main (int argc, char **argv)
3888        {
3889           if (argc == 10000)
3890             tputs (argv[0], 0, 0);
3891           return 0;
3892        }]])
3893 ])
3894 if test "${opsys}" = "mingw32"; then
3895   msg='none required'
3896 else
3897   # Maybe curses should be tried earlier?
3898   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3899   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3900     OLIBS=$LIBS
3901     if test -z "$tputs_library"; then
3902       LIBS_TERMCAP=
3903       msg='none required'
3904     else
3905       LIBS_TERMCAP=-l$tputs_library
3906       msg=$LIBS_TERMCAP
3907       LIBS="$LIBS_TERMCAP $LIBS"
3908     fi
3909     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3910       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3911     LIBS=$OLIBS
3912     if test "X$msg" != Xno; then
3913       break
3914     fi
3915   done
3916 fi
3917 AC_MSG_RESULT([$msg])
3918 if test "X$msg" = Xno; then
3919   AC_MSG_ERROR([The required function 'tputs' was not found in any library.
3920 The following libraries were tried (in order):
3921   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3922 Please try installing whichever of these libraries is most appropriate
3923 for your system, together with its header files.
3924 For example, a libncurses-dev(el) or similar package.])
3925 fi
3926
3927 ## Use termcap instead of terminfo?
3928 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3929 TERMINFO=yes
3930 ## FIXME?  In the cases below where we unconditionally set
3931 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3932 ## if that was found above to have tputs.
3933 ## Should we use the gnu* logic everywhere?
3934 case "$opsys" in
3935   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3936   ##  The ncurses library has been moved out of the System framework in
3937   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3938   ##  option to use it.
3939   darwin) LIBS_TERMCAP="-lncurses" ;;
3940
3941   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3942
3943   freebsd)
3944     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3945     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3946     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3947 [[#if __FreeBSD_version < 400000
3948 fail;
3949 #endif
3950 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3951
3952     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3953
3954     if test $emacs_cv_freebsd_terminfo = yes; then
3955       LIBS_TERMCAP="-lncurses"
3956     else
3957       TERMINFO=no
3958       LIBS_TERMCAP="-ltermcap"
3959     fi
3960     ;;
3961
3962   mingw32)
3963     TERMINFO=no
3964     LIBS_TERMCAP=
3965     ;;
3966
3967   netbsd)
3968     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3969       TERMINFO=no
3970       LIBS_TERMCAP="-ltermcap"
3971     fi
3972     ;;
3973
3974   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3975
3976   ## hpux: Make sure we get select from libc rather than from libcurses
3977   ##  because libcurses on HPUX 10.10 has a broken version of select.
3978   ##  We used to use -lc -lcurses, but this may be cleaner.
3979   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3980   # set that way, now it uses the default).  Isn't this a contradiction?
3981   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3982
3983 esac
3984
3985 TERMCAP_OBJ=tparam.o
3986 if test $TERMINFO = yes; then
3987   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3988   TERMCAP_OBJ=terminfo.o
3989 fi
3990 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3991   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3992 fi
3993 AC_SUBST(LIBS_TERMCAP)
3994 AC_SUBST(TERMCAP_OBJ)
3995
3996 # GNU/Linux-specific timer functions.
3997 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
3998   [AC_COMPILE_IFELSE(
3999      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
4000                       ]],
4001                       [[timerfd_create (CLOCK_REALTIME,
4002                                         TFD_CLOEXEC | TFD_NONBLOCK);
4003                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
4004      [emacs_cv_have_timerfd=yes],
4005      [emacs_cv_have_timerfd=no])])
4006 if test "$emacs_cv_have_timerfd" = yes; then
4007   AC_DEFINE([HAVE_TIMERFD], 1,
4008     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
4009 fi
4010
4011 # Alternate stack for signal handlers.
4012 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
4013                [emacs_cv_alternate_stack],
4014   [AC_COMPILE_IFELSE(
4015      [AC_LANG_PROGRAM([[#include <signal.h>
4016                       ]],
4017                       [[stack_t ss;
4018                         struct sigaction sa;
4019                         ss.ss_sp = malloc (SIGSTKSZ);
4020                         ss.ss_size = SIGSTKSZ;
4021                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
4022                         sigaltstack (&ss, 0);
4023                         sigaction (SIGSEGV, &sa, 0);]])],
4024      [emacs_cv_alternate_stack=yes],
4025      [emacs_cv_alternate_stack=no])])
4026
4027 # Do we need the Hesiod library to provide the support routines?
4028 dnl FIXME?  Should we be skipping this on Darwin too?
4029 LIBHESIOD=
4030 LIBRESOLV=
4031 if test "$with_hesiod" != no ; then
4032   # Don't set $LIBS here -- see comments above.  FIXME which comments?
4033   resolv=no
4034   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
4035      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
4036                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
4037   if test "$resolv" = yes ; then
4038     RESOLVLIB=-lresolv
4039   else
4040     RESOLVLIB=
4041   fi
4042   hesiod=no
4043   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
4044         hesiod=yes, :, $RESOLVLIB)])
4045
4046   if test x"$hesiod" = xyes; then
4047     LIBHESIOD=-lhesiod
4048     LIBRESOLV=$RESOLVLIB
4049   fi
4050 fi
4051 AC_SUBST(LIBHESIOD)
4052 AC_SUBST(LIBRESOLV)
4053
4054 # These tell us which Kerberos-related libraries to use.
4055 COM_ERRLIB=
4056 CRYPTOLIB=
4057 KRB5LIB=
4058 DESLIB=
4059 KRB4LIB=
4060
4061 if test "${with_kerberos}" != no; then
4062   OLD_LIBS=$LIBS
4063   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
4064   if test $have_com_err = yes; then
4065     COM_ERRLIB=-lcom_err
4066     LIBS="$COM_ERRLIB $LIBS"
4067   fi
4068   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
4069   if test $have_crypto = yes; then
4070     CRYPTOLIB=-lcrypto
4071     LIBS="$CRYPTOLIB $LIBS"
4072   fi
4073   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
4074   if test $have_k5crypto = yes; then
4075     CRYPTOLIB=-lk5crypto
4076     LIBS="$CRYPTOLIB $LIBS"
4077   fi
4078   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
4079   if test $have_krb5=yes; then
4080     KRB5LIB=-lkrb5
4081     LIBS="$KRB5LIB $LIBS"
4082   fi
4083   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
4084   if test "${with_kerberos5}" = no; then
4085     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
4086     if test $have_des425 = yes; then
4087       DESLIB=-ldes425
4088       LIBS="$DESLIB $LIBS"
4089     else
4090       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
4091       if test $have_des = yes; then
4092         DESLIB=-ldes
4093         LIBS="$DESLIB $LIBS"
4094       fi
4095     fi
4096     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
4097     if test $have_krb4 = yes; then
4098       KRB4LIB=-lkrb4
4099       LIBS="$KRB4LIB $LIBS"
4100     else
4101       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
4102       if test $have_krb = yes; then
4103         KRB4LIB=-lkrb
4104         LIBS="$KRB4LIB $LIBS"
4105       fi
4106     fi
4107   fi
4108
4109   if test "${with_kerberos5}" != no; then
4110     AC_CHECK_HEADERS(krb5.h,
4111       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
4112                         [#include <krb5.h>])])
4113   else
4114     AC_CHECK_HEADERS(krb.h,,
4115                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
4116                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
4117   fi
4118   AC_CHECK_HEADERS(com_err.h)
4119   LIBS=$OLD_LIBS
4120 fi
4121
4122 AC_SUBST(COM_ERRLIB)
4123 AC_SUBST(CRYPTOLIB)
4124 AC_SUBST(KRB5LIB)
4125 AC_SUBST(DESLIB)
4126 AC_SUBST(KRB4LIB)
4127
4128 AC_CHECK_HEADERS(valgrind/valgrind.h)
4129
4130 AC_CHECK_MEMBERS([struct unipair.unicode], [], [], [[#include <linux/kd.h>]])
4131
4132 AC_CHECK_FUNCS_ONCE(tzset)
4133
4134 ok_so_far=yes
4135 AC_CHECK_FUNC(socket, , ok_so_far=no)
4136 if test $ok_so_far = yes; then
4137   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
4138 fi
4139 if test $ok_so_far = yes; then
4140   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
4141 fi
4142 if test $ok_so_far = yes; then
4143 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
4144   AC_DEFINE(HAVE_INET_SOCKETS, 1,
4145             [Define to 1 if you have inet sockets.])
4146 fi
4147
4148 AC_FUNC_FORK
4149
4150 AC_CHECK_FUNCS(snprintf)
4151
4152 dnl Check for glib.  This differs from other library checks in that
4153 dnl Emacs need not link to glib unless some other library is already
4154 dnl linking to glib.  Although glib provides no facilities that Emacs
4155 dnl needs for its own purposes, when glib is present Emacs needs to
4156 dnl use primitives like g_main_context_query to avoid clashing with
4157 dnl glib at a low level.
4158 dnl
4159 dnl Check this late, since it depends on $GTK_CFLAGS etc.
4160 XGSELOBJ=
4161 OLDCFLAGS="$CFLAGS"
4162 OLDLIBS="$LIBS"
4163 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
4164 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
4165 CFLAGS="$CFLAGS $NOTIFY_CFLAGS $CAIRO_CFLAGS"
4166 LIBS="$LIBS $NOTIFY_LIBS $CAIRO_LIBS"
4167 AC_MSG_CHECKING([whether GLib is linked in])
4168 AC_LINK_IFELSE([AC_LANG_PROGRAM(
4169         [[#include <glib.h>
4170         ]],
4171         [[g_print ("Hello world");]])],
4172      [links_glib=yes],
4173      [links_glib=no])
4174 AC_MSG_RESULT([$links_glib])
4175 if test "${links_glib}" = "yes"; then
4176   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
4177   if test "$HAVE_NS" = no;then
4178     XGSELOBJ=xgselect.o
4179   fi
4180 fi
4181 CFLAGS="$OLDCFLAGS"
4182 LIBS="$OLDLIBS"
4183 AC_SUBST(XGSELOBJ)
4184
4185 dnl Adapted from Haible's version.
4186 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
4187   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
4188     [[char* cs = nl_langinfo(CODESET);]])],
4189     emacs_cv_langinfo_codeset=yes,
4190     emacs_cv_langinfo_codeset=no)
4191   ])
4192 if test $emacs_cv_langinfo_codeset = yes; then
4193   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
4194     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
4195 fi
4196
4197 AC_TYPE_MBSTATE_T
4198
4199 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
4200 dnl how the tty code is related to POSIX and/or other versions of termios.
4201 dnl The following looks like a useful start.
4202 dnl
4203 dnl AC_SYS_POSIX_TERMIOS
4204 dnl if test $ac_cv_sys_posix_termios = yes; then
4205 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
4206 dnl                                and macros for terminal control.])
4207 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
4208 dnl fi
4209
4210 dnl Turned on June 1996 supposing nobody will mind it.
4211 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
4212 if test "${opsys}" != "mingw32"; then
4213    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
4214      in the full name stands for the login id.])
4215 fi
4216
4217 dnl Everybody supports this, except MS.
4218 dnl Seems like the kind of thing we should be testing for, though.
4219 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4220 if test "${opsys}" != "mingw32"; then
4221   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4222 fi
4223
4224 dnl Everybody supports this, except MS-DOS.
4225 dnl Seems like the kind of thing we should be testing for, though.
4226 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4227 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4228   4.2-compatible sockets.])
4229
4230 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4231
4232 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4233   a null file, or a data sink.])
4234 if test "${opsys}" = "mingw32"; then
4235   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4236 else
4237   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4238 fi
4239
4240 if test "${opsys}" = "mingw32"; then
4241   SEPCHAR=';'
4242 else
4243   SEPCHAR=':'
4244 fi
4245 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4246 dnl This is for MinGW, and is used in test/Makefile.in.
4247 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4248 dnl decides that a command-line argument to be passed to a MinGW program
4249 dnl is a PATH-style list of directories.  But that heuristics plays it
4250 dnl safe, and only does the replacement when it is _absolutely_ sure it
4251 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4252 dnl which breaks in-tree builds.  So we do this manually instead.
4253 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4254 dnl be computed as ':' in MSYS Bash.
4255 AC_SUBST(SEPCHAR)
4256
4257 dnl Everybody supports this, except MS-DOS.
4258 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4259
4260 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4261
4262
4263 AC_DEFINE(DIRECTORY_SEP, ['/'],
4264   [Character that separates directories in a file name.])
4265
4266 if test "${opsys}" = "mingw32"; then
4267   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4268     [Returns true if character is a device separator.])
4269
4270   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4271     [Returns true if character is a directory separator.])
4272
4273   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4274     [Returns true if character is any form of separator.])
4275 else
4276   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4277     [Returns true if character is a device separator.])
4278
4279   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4280     [Returns true if character is a directory separator.])
4281
4282   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4283     [Returns true if character is any form of separator.])
4284 fi
4285
4286 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4287
4288 case $opsys in
4289   aix4-2)
4290     dnl Unfortunately without libXmu we cannot support EditRes.
4291     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4292       AC_DEFINE(NO_EDITRES, 1)
4293     fi
4294     ;;
4295
4296   hpux*)
4297     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4298     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4299     AC_DEFINE(NO_EDITRES, 1)
4300     ;;
4301 esac
4302
4303
4304 case $opsys in
4305   sol2* | unixware )
4306     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4307     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4308     dnl need the constant to dimension an array.  So wire in the appropriate
4309     dnl value here.
4310     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4311     ;;
4312 esac
4313
4314 emacs_broken_SIGIO=no
4315
4316 case $opsys in
4317   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4318   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4319   hpux* | nacl | openbsd | sol2* | unixware )
4320     emacs_broken_SIGIO=yes
4321     ;;
4322
4323   aix4-2)
4324     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4325     dnl the way this system works, libc functions that return malloced
4326     dnl memory use the libc malloc implementation. Calling xfree or
4327     dnl xrealloc on the results of such functions results in a crash.
4328     dnl
4329     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4330     dnl but that does not currently work on this system.
4331     dnl
4332     dnl It is possible to completely override the malloc implementation on
4333     dnl AIX, but that involves putting the malloc functions in a shared
4334     dnl library and setting the MALLOCTYPE environment variable to point to
4335     dnl that shared library.
4336     dnl
4337     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4338     dnl to avoid a crash just use the Emacs implementation for that function.
4339     dnl
4340     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4341     dnl of this file, so that we do not check for get_current_dir_name
4342     dnl on AIX.  But that might be fragile if something else ends
4343     dnl up testing for get_current_dir_name as a dependency.
4344     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4345       get_current_dir_name should not be used.])
4346     ;;
4347
4348   freebsd)
4349     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4350     dnl writes/reads on a PTY, read(2) returns bogus data:
4351     dnl
4352     dnl write(2)  1022 bytes
4353     dnl write(2)   954 bytes, get EAGAIN
4354     dnl read(2)   1024 bytes in process_read_output
4355     dnl read(2)     11 bytes in process_read_output
4356     dnl
4357     dnl That is, read(2) returns more bytes than have ever been written
4358     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4359     dnl successfully after processing (for example with CRs added if the
4360     dnl terminal is set up that way which it is here).  The same bytes will
4361     dnl be seen again in a later read(2), without the CRs.
4362     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4363       work around an issue when reading from a PTY.])
4364     ;;
4365 esac
4366
4367 case $opsys in
4368   gnu-* | sol2-10 )
4369     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4370     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4371   ;;
4372 esac
4373
4374 case $opsys in
4375   darwin | dragonfly | freebsd | netbsd | openbsd )
4376     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4377       close a pty to make it a controlling terminal (it is already a
4378       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4379   ;;
4380 esac
4381
4382 dnl FIXME Surely we can test for this rather than hard-code it.
4383 case $opsys in
4384   netbsd | openbsd) sound_device="/dev/audio" ;;
4385   *) sound_device="/dev/dsp" ;;
4386 esac
4387
4388 dnl Used in sound.c
4389 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4390   [Name of the default sound device.])
4391
4392
4393 dnl Emacs can read input using SIGIO and buffering characters itself,
4394 dnl or using CBREAK mode and making C-g cause SIGINT.
4395 dnl The choice is controlled by the variable interrupt_input.
4396 dnl
4397 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4398 dnl
4399 dnl Emacs uses the presence of the USABLE_SIGIO macro
4400 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4401 dnl INTERRUPT_INPUT to decide whether to use it by default.
4402 dnl
4403 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4404 dnl CBREAK mode has two disadvantages
4405 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4406 dnl I hear that in system V this problem does not exist.
4407 dnl 2) Control-G causes output to be discarded.
4408 dnl I do not know whether this can be fixed in system V.
4409 dnl
4410 dnl Another method of doing input is planned but not implemented.
4411 dnl It would have Emacs fork off a separate process
4412 dnl to read the input and send it to the true Emacs process
4413 dnl through a pipe.
4414 case $opsys in
4415   darwin | gnu-linux | gnu-kfreebsd )
4416     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4417   ;;
4418 esac
4419
4420
4421 dnl If the system's imake configuration file defines 'NeedWidePrototypes'
4422 dnl as 'NO', we must define NARROWPROTO manually.  Such a define is
4423 dnl generated in the Makefile generated by 'xmkmf'.  If we don't define
4424 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4425 dnl taking float or double parameters.
4426 case $opsys in
4427   cygwin|gnu|gnu-linux|gnu-kfreebsd|freebsd|netbsd|openbsd)
4428     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4429       file defines 'NeedWidePrototypes' as 'NO'.])
4430   ;;
4431 esac
4432
4433
4434 dnl Used in process.c, this must be a loop, even if it only runs once.
4435 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4436 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4437 dnl trying suffixes 0-16.
4438 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4439   first PTY, if PTYs are supported.])
4440 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4441 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4442   end of a PTY, if non-standard.])
4443 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4444   end of a PTY, if non-standard.])
4445
4446 case $opsys in
4447   aix4-2 )
4448     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4449     dnl You allocate a pty by opening /dev/ptc to get the master side.
4450     dnl To get the name of the slave side, you just ttyname() the master side.
4451     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4452     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4453     ;;
4454
4455   cygwin )
4456     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4457     dnl multi-line AC_DEFINEs are hard. :(
4458     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4459     AC_DEFINE(PTY_NAME_SPRINTF, [])
4460     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4461     ;;
4462
4463   gnu | openbsd )
4464     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4465     ;;
4466
4467   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd | darwin | nacl )
4468     dnl if HAVE_GRANTPT
4469     if test "x$ac_cv_func_grantpt" = xyes; then
4470       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4471       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4472       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4473       dnl to prevent sigchld_handler from intercepting the child's death.
4474       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4475       dnl if HAVE_POSIX_OPENPT
4476       if test "x$ac_cv_func_posix_openpt" = xyes; then
4477         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4478         AC_DEFINE(PTY_NAME_SPRINTF, [])
4479       dnl if HAVE_GETPT
4480       elif test "x$ac_cv_func_getpt" = xyes; then
4481         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4482         AC_DEFINE(PTY_NAME_SPRINTF, [])
4483       else
4484         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4485       fi
4486     else
4487       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4488     fi
4489     ;;
4490
4491   hpux*)
4492     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4493     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4494     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4495     ;;
4496
4497   sol2* )
4498     dnl On SysVr4, grantpt(3) forks a subprocess, so do not use
4499     dnl O_CLOEXEC when opening the pty, and keep the SIGCHLD handler
4500     dnl from intercepting that death.  If any child but grantpt's should die
4501     dnl within, it should be caught after sigrelse(2).
4502     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4503     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4504     ;;
4505
4506   unixware )
4507     dnl Comments are as per sol2*.
4508     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4509     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4510     ;;
4511 esac
4512
4513
4514 case $opsys in
4515   sol2* | unixware )
4516     dnl This change means that we don't loop through allocate_pty too
4517     dnl many times in the (rare) event of a failure.
4518     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4519     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4520     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4521     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (forkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (forkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (forkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4522     ;;
4523 esac
4524
4525
4526 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4527 "typing" a signal character on the pty.])
4528
4529 case $opsys in
4530   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4531   aix4-2 | cygwin | gnu | dragonfly | freebsd | netbsd | openbsd | darwin )
4532     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4533     ;;
4534
4535   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4536   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4537   gnu-linux | gnu-kfreebsd )
4538
4539     AC_MSG_CHECKING([for signals via characters])
4540     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4541 #include <linux/version.h>
4542 #if LINUX_VERSION_CODE < 0x20400
4543 # error "Linux version too old"
4544 #endif
4545       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4546
4547     AC_MSG_RESULT([$emacs_signals_via_chars])
4548     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4549     ;;
4550 esac
4551
4552
4553 AH_TEMPLATE(TAB3, [Undocumented.])
4554
4555 case $opsys in
4556   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4557
4558   gnu | dragonfly | freebsd | netbsd | openbsd )
4559     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4560     AC_DEFINE(TAB3, OXTABS)
4561     ;;
4562
4563   gnu-linux | gnu-kfreebsd )
4564     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4565 #ifndef __ia64__
4566 # error "not ia64"
4567 #endif
4568       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4569         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4570         [Mark a secondary stack, like the register stack on the ia64.]), [])
4571     ;;
4572
4573   hpux*)
4574     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4575       run_time_remap; for HPUX.])
4576     ;;
4577 esac
4578
4579
4580 dnl This won't be used automatically yet.  We also need to know, at least,
4581 dnl that the stack is continuous.
4582 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4583   registers relevant for conservative garbage collection in the jmp_buf.])
4584
4585
4586 case $opsys in
4587   dnl Not all the architectures are tested, but there are Debian packages
4588   dnl for SCM and/or Guile on them, so the technique must work.  See also
4589   dnl comments in alloc.c concerning setjmp and gcc.
4590   dnl Fixme: it's probably safe to just use the GCC conditional below.
4591   gnu-linux | gnu-kfreebsd )
4592     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4593 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4594   || defined __alpha__ || defined __mips__ || defined __s390__ \
4595   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4596   || defined __ia64__ || defined __sh__
4597 /* ok */
4598 #else
4599 # error "setjmp not known to work on this arch"
4600 #endif
4601     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4602     ;;
4603 esac
4604
4605
4606 if test x$GCC = xyes; then
4607    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4608    AC_DEFINE(GC_SETJMP_WORKS, 1)
4609 else
4610   case $opsys in
4611     aix* | dragonfly | freebsd | netbsd | openbsd | sol2* )
4612       AC_DEFINE(GC_SETJMP_WORKS, 1)
4613       ;;
4614   esac
4615 fi                              dnl GCC?
4616
4617 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4618 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4619   [AC_LINK_IFELSE(
4620      [AC_LANG_PROGRAM(
4621        [[#include <setjmp.h>
4622          #ifdef __MINGW32__
4623          # define _longjmp longjmp
4624          #endif
4625        ]],
4626        [[jmp_buf j;
4627          if (! _setjmp (j))
4628            _longjmp (j, 1);]])],
4629      [emacs_cv_func__setjmp=yes],
4630      [emacs_cv_func__setjmp=no])])
4631 if test $emacs_cv_func__setjmp = yes; then
4632   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4633 fi
4634
4635 # We need to preserve signal mask to handle C stack overflows.
4636 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4637   [AC_LINK_IFELSE(
4638      [AC_LANG_PROGRAM(
4639        [[#include <setjmp.h>
4640        ]],
4641        [[sigjmp_buf j;
4642          if (! sigsetjmp (j, 1))
4643            siglongjmp (j, 1);]])],
4644      [emacs_cv_func_sigsetjmp=yes],
4645      [emacs_cv_func_sigsetjmp=no])])
4646 if test $emacs_cv_func_sigsetjmp = yes; then
4647   AC_DEFINE([HAVE_SIGSETJMP], 1,
4648     [Define to 1 if sigsetjmp and siglongjmp work.])
4649 fi
4650
4651 case $emacs_cv_func_sigsetjmp,$emacs_cv_alternate_stack,$opsys in
4652   yes,yes,* | *,*,mingw32)
4653     AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4654       [Define to 1 if C stack overflow can be handled in some cases.]);;
4655 esac
4656
4657 case $opsys in
4658   sol2* | unixware )
4659     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4660     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4661     dnl and this is all we need.
4662     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4663     ;;
4664 esac
4665
4666
4667 case $opsys in
4668   hpux* | sol2* )
4669     dnl Used in xfaces.c.
4670     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4671       some systems, where it requires time.h.])
4672     ;;
4673 esac
4674
4675
4676 dnl Define symbols to identify the version of Unix this is.
4677 dnl Define all the symbols that apply correctly.
4678 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4679 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4680 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4681 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4682
4683 case $opsys in
4684   aix4-2)
4685     AC_DEFINE(USG, [])
4686     dnl This symbol should be defined on AIX Version 3  ???????
4687     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4688 #ifndef _AIX
4689 # error "_AIX not defined"
4690 #endif
4691     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4692     ;;
4693
4694   cygwin)
4695     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4696     ;;
4697
4698   darwin)
4699     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4700     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4701     dnl distinguish OS X from pure Darwin.
4702     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4703     ;;
4704
4705   gnu-linux | gnu-kfreebsd )
4706     AC_DEFINE(USG, [])
4707     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4708     ;;
4709
4710   hpux*)
4711     AC_DEFINE(USG, [])
4712     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4713     ;;
4714
4715   mingw32)
4716     AC_DEFINE(DOS_NT, [])
4717     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4718     if test "x$ac_enable_checking" != "x" ; then
4719       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4720     fi
4721     ;;
4722
4723   sol2*)
4724     AC_DEFINE(USG, [])
4725     AC_DEFINE(USG5_4, [])
4726     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4727     ;;
4728
4729   unixware)
4730     AC_DEFINE(USG, [])
4731     AC_DEFINE(USG5_4, [])
4732     ;;
4733 esac
4734
4735 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4736   [case $opsys in
4737      aix4-2 | nacl)
4738        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4739        emacs_cv_usable_FIONREAD=no
4740        ;;
4741
4742      mingw32)
4743        emacs_cv_usable_FIONREAD=yes
4744        ;;
4745
4746      *)
4747        AC_COMPILE_IFELSE(
4748          [AC_LANG_PROGRAM([[#include <sys/types.h>
4749                             #include <sys/ioctl.h>
4750                             #ifdef USG5_4
4751                             # include <sys/filio.h>
4752                             #endif
4753                           ]],
4754                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4755          [emacs_cv_usable_FIONREAD=yes],
4756          [emacs_cv_usable_FIONREAD=no])
4757        ;;
4758    esac])
4759 if test $emacs_cv_usable_FIONREAD = yes; then
4760   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4761
4762   if test $emacs_broken_SIGIO = no; then
4763     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4764       [AC_COMPILE_IFELSE(
4765          [AC_LANG_PROGRAM([[#include <fcntl.h>
4766                             #include <signal.h>
4767                           ]],
4768                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4769          [emacs_cv_usable_SIGIO=yes],
4770          [emacs_cv_usable_SIGIO=no])],
4771       [emacs_cv_usable_SIGIO=yes],
4772       [emacs_cv_usable_SIGIO=no])
4773     if test $emacs_cv_usable_SIGIO = yes; then
4774       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4775     fi
4776   fi
4777 fi
4778
4779 case $opsys in
4780   hpux11)
4781     dnl It works to open the pty's tty in the parent (Emacs), then
4782     dnl close and reopen it in the child.
4783     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4784       works to open a pty's tty in the parent process, then close and
4785       reopen it in the child.])
4786     ;;
4787
4788   sol2-10)
4789     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4790       on Solaris.])
4791     ;;
4792 esac
4793
4794 # Set up the CFLAGS for real compilation, so we can substitute it.
4795 CFLAGS="$REAL_CFLAGS"
4796 CPPFLAGS="$REAL_CPPFLAGS"
4797 LIBS="$REAL_LIBS"
4798
4799 ## Hack to detect a buggy GCC version.
4800 if test "$GCC" = yes && \
4801    $CC --version 2> /dev/null | grep 'gcc.* 4.5.0' >/dev/null; then
4802   case $CFLAGS in
4803     *-fno-optimize-sibling-calls*) ;;
4804     *-O@<:@23@:>@*)
4805       AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS.]);;
4806   esac
4807 fi
4808
4809 version=$PACKAGE_VERSION
4810
4811 copyright="Copyright (C) 2016 Free Software Foundation, Inc."
4812 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4813   [Short copyright string for this version of Emacs.])
4814 AC_SUBST(copyright)
4815
4816 ### Specify what sort of things we'll be editing into Makefile and config.h.
4817 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4818 AC_SUBST(version)
4819 AC_SUBST(configuration)
4820 ## Unused?
4821 AC_SUBST(canonical)
4822 AC_SUBST(srcdir)
4823 AC_SUBST(prefix)
4824 AC_SUBST(exec_prefix)
4825 AC_SUBST(bindir)
4826 AC_SUBST(datadir)
4827 AC_SUBST(sharedstatedir)
4828 AC_SUBST(libexecdir)
4829 AC_SUBST(mandir)
4830 AC_SUBST(infodir)
4831 AC_SUBST(lispdir)
4832 AC_SUBST(standardlisppath)
4833 AC_SUBST(locallisppath)
4834 AC_SUBST(lisppath)
4835 AC_SUBST(x_default_search_path)
4836 AC_SUBST(etcdir)
4837 AC_SUBST(archlibdir)
4838 AC_SUBST(etcdocdir)
4839 AC_SUBST(bitmapdir)
4840 AC_SUBST(gamedir)
4841 AC_SUBST(gameuser)
4842 AC_SUBST(gamegroup)
4843 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4844 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4845 ## end of LIBX_BASE, but nothing ever set it.
4846 AC_SUBST(LD_SWITCH_X_SITE)
4847 AC_SUBST(C_SWITCH_X_SITE)
4848 AC_SUBST(GNUSTEP_CFLAGS)
4849 AC_SUBST(CFLAGS)
4850 ## Used in lwlib/Makefile.in.
4851 AC_SUBST(X_TOOLKIT_TYPE)
4852 AC_SUBST(ns_appdir)
4853 AC_SUBST(ns_appbindir)
4854 AC_SUBST(ns_appresdir)
4855 AC_SUBST(ns_appsrc)
4856 AC_SUBST(GNU_OBJC_CFLAGS)
4857 AC_SUBST(OTHER_FILES)
4858
4859 if test -n "${term_header}"; then
4860     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4861         [Define to the header for the built-in window system.])
4862 fi
4863
4864 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4865                    [Define to the canonical Emacs configuration name.])
4866 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4867                    [Define to the options passed to configure.])
4868 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4869   define this to include extra configuration information.])
4870
4871 case $opsys in
4872   mingw32)
4873     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4874     ;;
4875 esac
4876
4877 XMENU_OBJ=
4878 XOBJ=
4879 FONT_OBJ=
4880 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4881   AC_DEFINE(HAVE_X_WINDOWS, 1,
4882             [Define to 1 if you want to use the X window system.])
4883   XMENU_OBJ=xmenu.o
4884   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4885   FONT_OBJ=xfont.o
4886   if test "$HAVE_CAIRO" = "yes"; then
4887     FONT_OBJ="ftfont.o ftcrfont.o"
4888   elif test "$HAVE_XFT" = "yes"; then
4889     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4890   elif test "$HAVE_FREETYPE" = "yes"; then
4891     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4892   fi
4893   AC_SUBST(FONT_OBJ)
4894 fi
4895 AC_SUBST(XMENU_OBJ)
4896 AC_SUBST(XOBJ)
4897 AC_SUBST(FONT_OBJ)
4898
4899 WIDGET_OBJ=
4900 MOTIF_LIBW=
4901 if test "${USE_X_TOOLKIT}" != "none" ; then
4902   WIDGET_OBJ=widget.o
4903   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4904   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4905     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4906   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4907     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4908     MOTIF_LIBW=-lXm
4909     case "$opsys" in
4910       gnu-linux)
4911         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4912         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4913         ;;
4914
4915       unixware)
4916         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4917         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4918         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4919         ;;
4920
4921       aix4-2)
4922         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4923         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4924         ;;
4925     esac
4926     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4927   fi
4928 fi
4929 AC_SUBST(WIDGET_OBJ)
4930
4931 TOOLKIT_LIBW=
4932 case "$USE_X_TOOLKIT" in
4933   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4934   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4935   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4936 esac
4937 if test "$HAVE_XWIDGETS" = "yes"; then
4938   TOOLKIT_LIBW="$TOOLKIT_LIBW -lXcomposite"
4939 fi
4940 AC_SUBST(TOOLKIT_LIBW)
4941
4942 if test "${opsys}" != "mingw32"; then
4943   if test "$USE_X_TOOLKIT" = "none"; then
4944     LIBXT_OTHER="\$(LIBXSM)"
4945   else
4946     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4947   fi
4948 fi
4949 AC_SUBST(LIBXT_OTHER)
4950
4951 if test "${HAVE_X11}" = "yes" ; then
4952   AC_DEFINE(HAVE_X11, 1,
4953             [Define to 1 if you want to use version 11 of X windows.])
4954   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4955 else
4956   LIBX_OTHER=
4957 fi
4958 AC_SUBST(LIBX_OTHER)
4959
4960 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4961   LIBXMENU=
4962 elif test "$USE_X_TOOLKIT" = none; then
4963   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4964 else
4965   LIBXMENU='$(lwlibdir)/liblw.a'
4966 fi
4967 AC_SUBST(LIBXMENU)
4968
4969 AC_CACHE_CHECK([for struct alignment],
4970   [emacs_cv_struct_alignment],
4971   [AC_COMPILE_IFELSE(
4972      [AC_LANG_PROGRAM([[#include <stddef.h>
4973                         struct __attribute__ ((aligned (8))) s { char c; };
4974                         struct t { char c; struct s s; };
4975                         char verify[offsetof (struct t, s) == 8 ? 1 : -1];
4976                       ]])],
4977      [emacs_cv_struct_alignment=yes],
4978      [emacs_cv_struct_alignment=no])])
4979 if test "$emacs_cv_struct_alignment" = yes; then
4980   AC_DEFINE([HAVE_STRUCT_ATTRIBUTE_ALIGNED], 1,
4981     [Define to 1 if 'struct __attribute__ ((aligned (N)))' aligns the
4982      structure to an N-byte boundary.])
4983 fi
4984
4985 if test "${GNU_MALLOC}" = "yes" ; then
4986   AC_DEFINE(GNU_MALLOC, 1,
4987             [Define to 1 if you want to use the GNU memory allocator.])
4988 fi
4989
4990 RALLOC_OBJ=
4991 if test "${REL_ALLOC}" = "yes" ; then
4992   AC_DEFINE(REL_ALLOC, 1,
4993             [Define REL_ALLOC if you want to use the relocating allocator for
4994              buffer space.])
4995
4996   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4997 fi
4998 AC_SUBST(RALLOC_OBJ)
4999
5000 if test "$opsys" = "cygwin"; then
5001   CYGWIN_OBJ="cygw32.o"
5002   ## Cygwin differs because of its unexec().
5003   PRE_ALLOC_OBJ=
5004   POST_ALLOC_OBJ=lastfile.o
5005 elif test "$opsys" = "mingw32"; then
5006   CYGWIN_OBJ=
5007   PRE_ALLOC_OBJ=
5008   POST_ALLOC_OBJ=lastfile.o
5009 else
5010   CYGWIN_OBJ=
5011   PRE_ALLOC_OBJ=lastfile.o
5012   POST_ALLOC_OBJ=
5013 fi
5014 AC_SUBST(CYGWIN_OBJ)
5015 AC_SUBST(PRE_ALLOC_OBJ)
5016 AC_SUBST(POST_ALLOC_OBJ)
5017
5018 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
5019 dnl verbatim defined above.  The tricky name is apropos, as this hack
5020 dnl makes Fortify go sour!
5021 AH_VERBATIM([FORTIFY_SOUR],
5022 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
5023    The workaround disables some useful run-time checking, so it
5024    should be conditional to the platforms with the performance bug.
5025    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
5026 #if defined __APPLE__ && defined __GNUC__
5027 # ifndef _DONT_USE_CTYPE_INLINE_
5028 #  define _DONT_USE_CTYPE_INLINE_
5029 # endif
5030 # ifndef _FORTIFY_SOURCE
5031 #  define _FORTIFY_SOURCE 0
5032 # endif
5033 #endif
5034 ])
5035
5036 # If user asks to omit features, disable optional features that gnulib
5037 # might otherwise enable.
5038 if test "$with_features" = no && test "$enable_acl" != yes; then
5039   enable_acl=no
5040 fi
5041
5042 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
5043 # it temporarily reverts them to their pre-pkg-config values,
5044 # because gnulib needs to work with both src (which uses the
5045 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
5046 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
5047 # and it therefore needs to run in an environment where LIBS does not
5048 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
5049 # for some package unrelated to lib-src.
5050 SAVE_CFLAGS=$CFLAGS
5051 SAVE_LIBS=$LIBS
5052 CFLAGS=$pre_PKG_CONFIG_CFLAGS
5053 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
5054 gl_ASSERT_NO_GNULIB_POSIXCHECK
5055 gl_ASSERT_NO_GNULIB_TESTS
5056 gl_INIT
5057 CFLAGS=$SAVE_CFLAGS
5058 LIBS=$SAVE_LIBS
5059
5060 if test "${opsys}" = "mingw32"; then
5061   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
5062   # Remove unneeded switches from the value of CC that goes to Makefiles
5063   CC=`AS_ECHO(["$CC"]) | sed -e "s,$GCC_TEST_OPTIONS,,"`
5064 fi
5065
5066 case "$opsys" in
5067   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
5068
5069   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
5070
5071   darwin)
5072    ## The -headerpad option tells ld (see man page) to leave room at the
5073    ## end of the header for adding load commands.  Needed for dumping.
5074    ## 0x1000 is enough for roughly 52 load commands on the x86_64
5075    ## architecture (where they are 78 bytes each). The actual number of
5076    ## load commands added is not consistent but normally ranges from
5077    ## about 14 to about 34. Setting it high gets us plenty of slop and
5078    ## only costs about 1.5K of wasted binary space.
5079    headerpad_extra=1000
5080    if test "$HAVE_NS" = "yes"; then
5081      libs_nsgui="-framework AppKit"
5082      if test "$NS_IMPL_COCOA" = "yes"; then
5083         libs_nsgui="$libs_nsgui -framework IOKit"
5084      fi
5085    else
5086      libs_nsgui=
5087    fi
5088    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
5089
5090    ## This is here because src/Makefile.in did some extra fiddling around
5091    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
5092    ## LD_SWITCH_SYSTEM_TEMACS instead,
5093    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
5094      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
5095    ;;
5096
5097   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
5098   ## find X at run-time.
5099   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
5100   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
5101   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
5102   ## had different values in configure (in ac_link) and src/Makefile.in.
5103   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
5104   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
5105
5106   mingw32)
5107    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
5108    case "$canonical" in
5109      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5110      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5111    esac
5112    ;;
5113
5114   *) LD_SWITCH_SYSTEM_TEMACS= ;;
5115 esac
5116
5117 # -nopie fixes a temacs segfault on Gentoo, OpenBSD, and other systems
5118 # with "hardened" GCC configurations for some reason (Bug#18784).
5119 # We don't know why -nopie works, but not segfaulting is better than
5120 # segfaulting.  Use ac_c_werror_flag=yes when trying -nopie, otherwise
5121 # clang keeps warning that it does not understand -nopie, and pre-4.6
5122 # GCC has a similar problem (Bug#20338).
5123 AC_CACHE_CHECK([whether $CC accepts -nopie],
5124   [emacs_cv_prog_cc_nopie],
5125   [emacs_save_c_werror_flag=$ac_c_werror_flag
5126    emacs_save_LDFLAGS=$LDFLAGS
5127    ac_c_werror_flag=yes
5128    LDFLAGS="$LDFLAGS -nopie"
5129    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
5130      [emacs_cv_prog_cc_nopie=yes],
5131      [emacs_cv_prog_cc_nopie=no])
5132    ac_c_werror_flag=$emacs_save_c_werror_flag
5133    LDFLAGS=$emacs_save_LDFLAGS])
5134 if test "$emacs_cv_prog_cc_nopie" = yes; then
5135   LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -nopie"
5136 fi
5137
5138 if test x$ac_enable_profiling != x ; then
5139   case $opsys in
5140     *freebsd | gnu-linux) ;;
5141     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
5142   esac
5143 fi
5144
5145 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
5146
5147 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
5148
5149 ## Common for all window systems
5150 if test "$window_system" != "none"; then
5151   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
5152   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
5153   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
5154 fi
5155
5156 AC_SUBST(WINDOW_SYSTEM_OBJ)
5157
5158 AH_TOP([/* GNU Emacs site configuration template file.
5159
5160 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2016
5161   Free Software Foundation, Inc.
5162
5163 This file is part of GNU Emacs.
5164
5165 GNU Emacs is free software: you can redistribute it and/or modify
5166 it under the terms of the GNU General Public License as published by
5167 the Free Software Foundation, either version 3 of the License, or (at
5168 your option) any later version.
5169
5170 GNU Emacs is distributed in the hope that it will be useful,
5171 but WITHOUT ANY WARRANTY; without even the implied warranty of
5172 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
5173 GNU General Public License for more details.
5174
5175 You should have received a copy of the GNU General Public License
5176 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
5177
5178
5179 /* No code in Emacs #includes config.h twice, but some bits of code
5180    intended to work with other packages as well (like gmalloc.c)
5181    think they can include it as many times as they like.  */
5182 #ifndef EMACS_CONFIG_H
5183 #define EMACS_CONFIG_H
5184 ])dnl
5185
5186 AH_BOTTOM([#include <conf_post.h>
5187
5188 #endif /* EMACS_CONFIG_H */
5189
5190 /*
5191 Local Variables:
5192 mode: c
5193 End:
5194 */
5195 ])dnl
5196
5197 #### Report on what we decided to do.
5198 #### Report GTK as a toolkit, even if it doesn't use Xt.
5199 #### It makes printing result more understandable as using GTK sets
5200 #### toolkit_scroll_bars to yes by default.
5201 if test "${HAVE_GTK}" = "yes"; then
5202   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5203 fi
5204
5205 if test $USE_ACL -ne 0; then
5206   ACL_SUMMARY="yes $LIB_ACL"
5207 else
5208   ACL_SUMMARY=no
5209 fi
5210
5211 emacs_standard_dirs='Standard dirs'
5212 AS_ECHO(["
5213 Configured for '${canonical}'.
5214
5215   Where should the build process find the source code?    ${srcdir}
5216   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5217   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5218   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5219   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5220   What window system should Emacs use?                    ${window_system}
5221   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}
5222   Where do we find X Windows header files?                ${x_includes:-$emacs_standard_dirs}
5223   Where do we find X Windows libraries?                   ${x_libraries:-$emacs_standard_dirs}"])
5224
5225 optsep=
5226 emacs_config_features=
5227 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG CAIRO IMAGEMAGICK SOUND GPM DBUS \
5228   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5229   LIBOTF XFT ZLIB TOOLKIT_SCROLL_BARS X_TOOLKIT X11 NS MODULES \
5230   XWIDGETS LIBSYSTEMD; do
5231
5232     case $opt in
5233       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5234       TOOLKIT_SCROLL_BARS|X_TOOLKIT) eval val=\${USE_$opt} ;;
5235       *) eval val=\${HAVE_$opt} ;;
5236     esac
5237     case x$val in
5238       xno|xnone|x) continue ;;
5239     esac
5240     case $opt in
5241       X_TOOLKIT)
5242         case $val in
5243           GTK*|LUCID|MOTIF) opt=$val ;;
5244           *) continue ;;
5245         esac
5246       ;;
5247     esac
5248     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5249     optsep=' '
5250 done
5251 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5252   [Summary of some of the main features enabled by configure.])
5253
5254 AS_ECHO(["  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}
5255   Does Emacs use -lXpm?                                   ${HAVE_XPM}
5256   Does Emacs use -ljpeg?                                  ${HAVE_JPEG}
5257   Does Emacs use -ltiff?                                  ${HAVE_TIFF}
5258   Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF
5259   Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG
5260   Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}
5261   Does Emacs use cairo?                                   ${HAVE_CAIRO}
5262   Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}
5263   Does Emacs support sound?                               ${HAVE_SOUND}
5264   Does Emacs use -lgpm?                                   ${HAVE_GPM}
5265   Does Emacs use -ldbus?                                  ${HAVE_DBUS}
5266   Does Emacs use -lgconf?                                 ${HAVE_GCONF}
5267   Does Emacs use GSettings?                               ${HAVE_GSETTINGS}
5268   Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}
5269   Does Emacs use access control lists?                    ${ACL_SUMMARY}
5270   Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}
5271   Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}
5272   Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}
5273   Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}
5274   Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}
5275   Does Emacs use -lotf?                                   ${HAVE_LIBOTF}
5276   Does Emacs use -lxft?                                   ${HAVE_XFT}
5277   Does Emacs use -lsystemd?                               ${HAVE_LIBSYSTEMD}
5278   Does Emacs directly use zlib?                           ${HAVE_ZLIB}
5279   Does Emacs have dynamic modules support?                ${HAVE_MODULES}
5280   Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}
5281   Does Emacs support Xwidgets (requires gtk3)?            ${HAVE_XWIDGETS}
5282 "])
5283
5284 if test -n "${EMACSDATA}"; then
5285    AS_ECHO(["  Environment variable EMACSDATA set to:                  $EMACSDATA"])
5286 fi
5287 if test -n "${EMACSDOC}"; then
5288    AS_ECHO(["  Environment variable EMACSDOC set to:                   $EMACSDOC"])
5289 fi
5290
5291 echo
5292
5293 if test "$HAVE_NS" = "yes"; then
5294    echo
5295    AS_ECHO(["You must run \"${MAKE-make} install\" in order to test the built application.
5296 The installed application will go to nextstep/Emacs.app and can be
5297 run or moved from there."])
5298    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5299       echo "The application will be fully self-contained."
5300     else
5301       AS_ECHO(["The lisp resources for the application will be installed under ${prefix}.
5302 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5303 to run if these resources are not installed."])
5304    fi
5305    echo
5306 fi
5307
5308 if test "${opsys}" = "cygwin"; then
5309   case `uname -r` in
5310     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5311            echo
5312            ;;
5313   esac
5314 fi
5315
5316 # Remove any trailing slashes in these variables.
5317 case $prefix in
5318   */) prefix=`AS_DIRNAME(["$prefix."])`;;
5319 esac
5320 case $exec_prefix in
5321   */) exec_prefix=`AS_DIRNAME(["$exec_prefix."])`;;
5322 esac
5323
5324 if test "$HAVE_NS" = "yes"; then
5325   if test "$NS_IMPL_GNUSTEP" = yes; then
5326     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5327       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5328     ns_check_file=Resources/Info-gnustep.plist
5329   else
5330     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5331       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5332     ns_check_file=Contents/Info.plist
5333   fi
5334   AC_SUBST(ns_check_file)
5335 fi
5336
5337 dnl config.status treats $srcdir specially, so I think this is ok...
5338 AC_CONFIG_FILES([$srcdir/doc/man/emacs.1])
5339
5340 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5341 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5342 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5343 dnl (else you get "no 'Makefile.am' found for any configure output").
5344 dnl This will work, but you get a config.status that is not quite right
5345 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5346 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5347 dnl it seems better to just live with the duplication.
5348 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5349
5350 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5351        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5352        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5353        leim/Makefile nextstep/Makefile nt/Makefile])
5354
5355 dnl test/ is not present in release tarfiles.
5356 opt_makefile=test/Makefile
5357
5358 if test -f "$srcdir/$opt_makefile.in"; then
5359   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5360   dnl Again, it's best not to use a variable.  Though you can add
5361   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5362   AC_CONFIG_FILES([test/Makefile])
5363 fi
5364
5365
5366 dnl The admin/ directory used to be excluded from tarfiles.
5367 if test -d $srcdir/admin; then
5368   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/charsets/Makefile admin/unidata/Makefile admin/grammars/Makefile"
5369   AC_CONFIG_FILES([admin/charsets/Makefile])
5370   AC_CONFIG_FILES([admin/unidata/Makefile])
5371   AC_CONFIG_FILES([admin/grammars/Makefile])
5372 fi                              dnl -d admin
5373
5374
5375 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5376
5377 AC_SUBST(SUBDIR_MAKEFILES_IN)
5378
5379 dnl You might wonder (I did) why epaths.h is generated by running make,
5380 dnl rather than just letting configure generate it from epaths.in.
5381 dnl One reason is that the various paths are not fully expanded (see above);
5382 dnl eg gamedir=${prefix}/var/games/emacs.
5383 dnl Secondly, the GNU Coding standards require that one should be able
5384 dnl to run 'make prefix=/some/where/else' and override the values set
5385 dnl by configure.  This also explains the 'move-if-change' test and
5386 dnl the use of force in the 'epaths-force' rule in Makefile.in.
5387 AC_CONFIG_COMMANDS([src/epaths.h], [
5388 if test "${opsys}" = "mingw32"; then
5389   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5390 else
5391   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5392 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5393 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5394
5395 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5396 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5397 dnl or a symlink?
5398 AC_CONFIG_COMMANDS([src/.gdbinit], [
5399 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5400   AS_ECHO(["source $ac_abs_top_srcdir/src/.gdbinit"]) > src/.gdbinit
5401 fi
5402 ])
5403
5404 dnl Perhaps this would be better named doc-emacs-emacsver.texi?
5405 dnl See comments for etc-refcards-emacsver.tex.
5406 dnl Since we get a doc/emacs directory generated anyway, for the Makefile,
5407 dnl it is not quite the same.  But we are generating in $srcdir.
5408 AC_CONFIG_COMMANDS([doc/emacs/emacsver.texi], [
5409 ${MAKE-make} -s --no-print-directory -C doc/emacs doc-emacsver || \
5410 AC_MSG_ERROR(['doc/emacs/emacsver.texi' could not be made.])
5411 ])
5412
5413 dnl If we give this the more natural name, etc/refcards/emacsver.texi,
5414 dnl then a directory etc/refcards is created in the build directory,
5415 dnl which is probably harmless, but confusing (in out-of-tree builds).
5416 dnl (If we were to generate etc/refcards/Makefile, this might change.)
5417 dnl It is really $srcdir/etc/refcards/emacsver.tex that we generate.
5418 AC_CONFIG_COMMANDS([etc-refcards-emacsver.tex], [
5419 ${MAKE-make} -s MAKEFILE_NAME=do-not-make-Makefile etc-emacsver || \
5420 AC_MSG_ERROR(['etc/refcards/emacsver.tex' could not be made.])
5421 ])
5422
5423 AC_OUTPUT
5424
5425 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])