code.delx.au - gnu-emacs/blob - lisp/url/url-http.el

   1 ;;; url-http.el --- HTTP retrieval routines
   2
   3 ;; Copyright (C) 1999, 2001, 2004-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Bill Perry <wmperry@gnu.org>
   6 ;; Maintainer: emacs-devel@gnu.org
   7 ;; Keywords: comm, data, processes
   8
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'cl-lib)
  29 (require 'puny)
  30 (eval-when-compile
  31   (require 'subr-x))
  32
  33 (defvar url-callback-arguments)
  34 (defvar url-callback-function)
  35 (defvar url-current-object)
  36 (defvar url-http-after-change-function)
  37 (defvar url-http-chunked-counter)
  38 (defvar url-http-chunked-length)
  39 (defvar url-http-chunked-start)
  40 (defvar url-http-connection-opened)
  41 (defvar url-http-content-length)
  42 (defvar url-http-content-type)
  43 (defvar url-http-data)
  44 (defvar url-http-end-of-headers)
  45 (defvar url-http-extra-headers)
  46 (defvar url-http-noninteractive)
  47 (defvar url-http-method)
  48 (defvar url-http-no-retry)
  49 (defvar url-http-process)
  50 (defvar url-http-proxy)
  51 (defvar url-http-response-status)
  52 (defvar url-http-response-version)
  53 (defvar url-http-target-url)
  54 (defvar url-http-transfer-encoding)
  55 (defvar url-show-status)
  56
  57 (require 'url-gw)
  58 (require 'url-parse)
  59 (require 'url-cookie)
  60 (require 'mail-parse)
  61 (require 'url-auth)
  62 (require 'url)
  63 (autoload 'url-cache-create-filename "url-cache")
  64
  65 (defconst url-http-default-port 80 "Default HTTP port.")
  66 (defconst url-http-asynchronous-p t "HTTP retrievals are asynchronous.")
  67 (defalias 'url-http-expand-file-name 'url-default-expander)
  68
  69 (defvar url-http-real-basic-auth-storage nil)
  70 (defvar url-http-proxy-basic-auth-storage nil)
  71
  72 (defvar url-http-open-connections (make-hash-table :test 'equal
  73                                                    :size 17)
  74   "A hash table of all open network connections.")
  75
  76 (defvar url-http-version "1.1"
  77   "What version of HTTP we advertise, as a string.
  78 Valid values are 1.1 and 1.0.
  79 This is only useful when debugging the HTTP subsystem.
  80
  81 Setting this to 1.0 will tell servers not to send chunked encoding,
  82 and other HTTP/1.1 specific features.")
  83
  84 (defvar url-http-attempt-keepalives t
  85   "Whether to use a single TCP connection multiple times in HTTP.
  86 This is only useful when debugging the HTTP subsystem.  Setting to
  87 nil will explicitly close the connection to the server after every
  88 request.")
  89
  90 (defconst url-http-codes
  91   '((100 continue                        "Continue with request")
  92     (101 switching-protocols             "Switching protocols")
  93     (102 processing                      "Processing (Added by DAV)")
  94     (200 OK                              "OK")
  95     (201 created                         "Created")
  96     (202 accepted                        "Accepted")
  97     (203 non-authoritative               "Non-authoritative information")
  98     (204 no-content                      "No content")
  99     (205 reset-content                   "Reset content")
 100     (206 partial-content                 "Partial content")
 101     (207 multi-status                    "Multi-status (Added by DAV)")
 102     (300 multiple-choices                "Multiple choices")
 103     (301 moved-permanently               "Moved permanently")
 104     (302 found                           "Found")
 105     (303 see-other                       "See other")
 106     (304 not-modified                    "Not modified")
 107     (305 use-proxy                       "Use proxy")
 108     (307 temporary-redirect              "Temporary redirect")
 109     (400 bad-request                     "Bad Request")
 110     (401 unauthorized                    "Unauthorized")
 111     (402 payment-required                "Payment required")
 112     (403 forbidden                       "Forbidden")
 113     (404 not-found                       "Not found")
 114     (405 method-not-allowed              "Method not allowed")
 115     (406 not-acceptable                  "Not acceptable")
 116     (407 proxy-authentication-required   "Proxy authentication required")
 117     (408 request-timeout                 "Request time-out")
 118     (409 conflict                        "Conflict")
 119     (410 gone                            "Gone")
 120     (411 length-required                 "Length required")
 121     (412 precondition-failed             "Precondition failed")
 122     (413 request-entity-too-large        "Request entity too large")
 123     (414 request-uri-too-large           "Request-URI too large")
 124     (415 unsupported-media-type          "Unsupported media type")
 125     (416 requested-range-not-satisfiable "Requested range not satisfiable")
 126     (417 expectation-failed              "Expectation failed")
 127     (422 unprocessable-entity            "Unprocessable Entity (Added by DAV)")
 128     (423 locked                          "Locked")
 129     (424 failed-Dependency               "Failed Dependency")
 130     (500 internal-server-error           "Internal server error")
 131     (501 not-implemented                 "Not implemented")
 132     (502 bad-gateway                     "Bad gateway")
 133     (503 service-unavailable             "Service unavailable")
 134     (504 gateway-timeout                 "Gateway time-out")
 135     (505 http-version-not-supported      "HTTP version not supported")
 136     (507 insufficient-storage            "Insufficient storage"))
 137   "The HTTP return codes and their text.")
 138
 139 (defcustom url-user-agent (format "User-Agent: %sURL/%s\r\n"
 140                                   (if url-package-name
 141                                       (concat url-package-name "/"
 142                                               url-package-version " ")
 143                                     "") url-version)
 144   "User Agent used by the URL package."
 145   :type '(choice (string :tag "A static User-Agent string")
 146                  (function :tag "Call a function to get the User-Agent string"))
 147   :version "25.1"
 148   :group 'url)
 149
 150 ;(eval-when-compile
 151 ;; These are all macros so that they are hidden from external sight
 152 ;; when the file is byte-compiled.
 153 ;;
 154 ;; This allows us to expose just the entry points we want.
 155
 156 ;; These routines will allow us to implement persistent HTTP
 157 ;; connections.
 158 (defsubst url-http-debug (&rest args)
 159   (if quit-flag
 160       (let ((proc (get-buffer-process (current-buffer))))
 161         ;; The user hit C-g, honor it!  Some things can get in an
 162         ;; incredibly tight loop (chunked encoding)
 163         (if proc
 164             (progn
 165               (set-process-sentinel proc nil)
 166               (set-process-filter proc nil)))
 167         (error "Transfer interrupted!")))
 168   (apply 'url-debug 'http args))
 169
 170 (defun url-http-mark-connection-as-busy (host port proc)
 171   (url-http-debug "Marking connection as busy: %s:%d %S" host port proc)
 172   (set-process-query-on-exit-flag proc t)
 173   (puthash (cons host port)
 174               (delq proc (gethash (cons host port) url-http-open-connections))
 175               url-http-open-connections)
 176   proc)
 177
 178 (defun url-http-mark-connection-as-free (host port proc)
 179   (url-http-debug "Marking connection as free: %s:%d %S" host port proc)
 180   (when (memq (process-status proc) '(open run connect))
 181     (set-process-buffer proc nil)
 182     (set-process-sentinel proc 'url-http-idle-sentinel)
 183     (set-process-query-on-exit-flag proc nil)
 184     (puthash (cons host port)
 185              (cons proc (gethash (cons host port) url-http-open-connections))
 186              url-http-open-connections))
 187   nil)
 188
 189 (defun url-http-find-free-connection (host port &optional gateway-method)
 190   (let ((conns (gethash (cons host port) url-http-open-connections))
 191         (connection nil))
 192     (while (and conns (not connection))
 193       (if (not (memq (process-status (car conns)) '(run open connect)))
 194           (progn
 195             (url-http-debug "Cleaning up dead process: %s:%d %S"
 196                             host port (car conns))
 197             (url-http-idle-sentinel (car conns) nil))
 198         (setq connection (car conns))
 199         (url-http-debug "Found existing connection: %s:%d %S" host port connection))
 200       (pop conns))
 201     (if connection
 202         (url-http-debug "Reusing existing connection: %s:%d" host port)
 203       (url-http-debug "Contacting host: %s:%d" host port))
 204     (url-lazy-message "Contacting host: %s:%d" host port)
 205
 206     (unless connection
 207       (let ((buf (generate-new-buffer " *url-http-temp*")))
 208         ;; `url-open-stream' needs a buffer in which to do things
 209         ;; like authentication.  But we use another buffer afterwards.
 210         (unwind-protect
 211             (let ((proc (url-open-stream host buf host port gateway-method)))
 212               ;; url-open-stream might return nil.
 213               (when (processp proc)
 214                 ;; Drop the temp buffer link before killing the buffer.
 215                 (set-process-buffer proc nil)
 216                 (setq connection proc)))
 217           ;; If there was an error on connect, make sure we don't
 218           ;; get queried.
 219           (when (get-buffer-process buf)
 220             (set-process-query-on-exit-flag (get-buffer-process buf) nil))
 221           (kill-buffer buf))))
 222
 223     (if connection
 224         (url-http-mark-connection-as-busy host port connection))))
 225
 226 ;; Building an HTTP request
 227 (defun url-http-user-agent-string ()
 228   (if (or (eq url-privacy-level 'paranoid)
 229           (and (listp url-privacy-level)
 230                (memq 'agent url-privacy-level)))
 231       ""
 232     (if (functionp url-user-agent)
 233         (funcall url-user-agent)
 234       url-user-agent)))
 235
 236 (defun url-http-create-request (&optional ref-url)
 237   "Create an HTTP request for `url-http-target-url', referred to by REF-URL."
 238   (let* ((extra-headers)
 239          (request nil)
 240          (no-cache (cdr-safe (assoc "Pragma" url-http-extra-headers)))
 241          (using-proxy url-http-proxy)
 242          (proxy-auth (if (or (cdr-safe (assoc "Proxy-Authorization"
 243                                               url-http-extra-headers))
 244                              (not using-proxy))
 245                          nil
 246                        (let ((url-basic-auth-storage
 247                               'url-http-proxy-basic-auth-storage))
 248                          (url-get-authentication url-http-proxy nil 'any nil))))
 249          (real-fname (url-filename url-http-target-url))
 250          (host (url-host url-http-target-url))
 251          (auth (if (cdr-safe (assoc "Authorization" url-http-extra-headers))
 252                    nil
 253                  (url-get-authentication (or
 254                                           (and (boundp 'proxy-info)
 255                                                proxy-info)
 256                                           url-http-target-url) nil 'any nil))))
 257     (if (equal "" real-fname)
 258         (setq real-fname "/"))
 259     (setq no-cache (and no-cache (string-match "no-cache" no-cache)))
 260     (if auth
 261         (setq auth (concat "Authorization: " auth "\r\n")))
 262     (if proxy-auth
 263         (setq proxy-auth (concat "Proxy-Authorization: " proxy-auth "\r\n")))
 264
 265     ;; Protection against stupid values in the referrer
 266     (if (and ref-url (stringp ref-url) (or (string= ref-url "file:nil")
 267                                            (string= ref-url "")))
 268         (setq ref-url nil))
 269
 270     ;; We do not want to expose the referrer if the user is paranoid.
 271     (if (or (memq url-privacy-level '(low high paranoid))
 272             (and (listp url-privacy-level)
 273                  (memq 'lastloc url-privacy-level)))
 274         (setq ref-url nil))
 275
 276     ;; url-http-extra-headers contains an assoc-list of
 277     ;; header/value pairs that we need to put into the request.
 278     (setq extra-headers (mapconcat
 279                          (lambda (x)
 280                            (concat (car x) ": " (cdr x)))
 281                          url-http-extra-headers "\r\n"))
 282     (if (not (equal extra-headers ""))
 283         (setq extra-headers (concat extra-headers "\r\n")))
 284
 285     ;; This was done with a call to `format'.  Concatenating parts has
 286     ;; the advantage of keeping the parts of each header together and
 287     ;; allows us to elide null lines directly, at the cost of making
 288     ;; the layout less clear.
 289     (setq request
 290           ;; We used to concat directly, but if one of the strings happens
 291           ;; to being multibyte (even if it only contains pure ASCII) then
 292           ;; every string gets converted with `string-MAKE-multibyte' which
 293           ;; turns the 127-255 codes into things like latin-1 accented chars
 294           ;; (it would work right if it used `string-TO-multibyte' instead).
 295           ;; So to avoid the problem we force every string to be unibyte.
 296           (mapconcat
 297            ;; FIXME: Instead of `string-AS-unibyte' we'd want
 298            ;; `string-to-unibyte', so as to properly signal an error if one
 299            ;; of the strings contains a multibyte char.
 300            'string-as-unibyte
 301            (delq nil
 302             (list
 303              ;; The request
 304              (or url-http-method "GET") " "
 305              (if using-proxy (url-recreate-url url-http-target-url) real-fname)
 306              " HTTP/" url-http-version "\r\n"
 307              ;; Version of MIME we speak
 308              "MIME-Version: 1.0\r\n"
 309              ;; (maybe) Try to keep the connection open
 310              "Connection: " (if (or using-proxy
 311                                     (not url-http-attempt-keepalives))
 312                                 "close" "keep-alive") "\r\n"
 313                                 ;; HTTP extensions we support
 314              (if url-extensions-header
 315                  (format
 316                   "Extension: %s\r\n" url-extensions-header))
 317              ;; Who we want to talk to
 318              (if (/= (url-port url-http-target-url)
 319                      (url-scheme-get-property
 320                       (url-type url-http-target-url) 'default-port))
 321                  (format
 322                   "Host: %s:%d\r\n" (puny-encode-domain host)
 323                   (url-port url-http-target-url))
 324                (format "Host: %s\r\n" (puny-encode-domain host)))
 325              ;; Who its from
 326              (if url-personal-mail-address
 327                  (concat
 328                   "From: " url-personal-mail-address "\r\n"))
 329              ;; Encodings we understand
 330              (if (or url-mime-encoding-string
 331                      ;; MS-Windows loads zlib dynamically, so recheck
 332                      ;; in case they made it available since
 333                      ;; initialization in url-vars.el.
 334                      (and (eq 'system-type 'windows-nt)
 335                           (fboundp 'zlib-available-p)
 336                           (zlib-available-p)
 337                           (setq url-mime-encoding-string "gzip")))
 338                  (concat
 339                   "Accept-encoding: " url-mime-encoding-string "\r\n"))
 340              (if url-mime-charset-string
 341                  (concat
 342                   "Accept-charset: " url-mime-charset-string "\r\n"))
 343              ;; Languages we understand
 344              (if url-mime-language-string
 345                  (concat
 346                   "Accept-language: " url-mime-language-string "\r\n"))
 347              ;; Types we understand
 348              "Accept: " (or url-mime-accept-string "*/*") "\r\n"
 349              ;; User agent
 350              (url-http-user-agent-string)
 351              ;; Proxy Authorization
 352              proxy-auth
 353              ;; Authorization
 354              auth
 355              ;; Cookies
 356              (when (url-use-cookies url-http-target-url)
 357                (url-cookie-generate-header-lines
 358                 host real-fname
 359                 (equal "https" (url-type url-http-target-url))))
 360              ;; If-modified-since
 361              (if (and (not no-cache)
 362                       (member url-http-method '("GET" nil)))
 363                  (let ((tm (url-is-cached url-http-target-url)))
 364                    (if tm
 365                        (concat "If-modified-since: "
 366                                (url-get-normalized-date tm) "\r\n"))))
 367              ;; Whence we came
 368              (if ref-url (concat
 369                           "Referer: " ref-url "\r\n"))
 370              extra-headers
 371              ;; Length of data
 372              (if url-http-data
 373                  (concat
 374                   "Content-length: " (number-to-string
 375                                       (length url-http-data))
 376                   "\r\n"))
 377              ;; End request
 378              "\r\n"
 379              ;; Any data
 380              url-http-data))
 381            ""))
 382     (url-http-debug "Request is: \n%s" request)
 383     request))
 384
 385 ;; Parsing routines
 386 (defun url-http-clean-headers ()
 387   "Remove trailing \r from header lines.
 388 This allows us to use `mail-fetch-field', etc.
 389 Return the number of characters removed."
 390   (let ((end (marker-position url-http-end-of-headers)))
 391     (goto-char (point-min))
 392     (while (re-search-forward "\r$" url-http-end-of-headers t)
 393       (replace-match ""))
 394     (- end url-http-end-of-headers)))
 395
 396 (defun url-http-handle-authentication (proxy)
 397   (url-http-debug "Handling %s authentication" (if proxy "proxy" "normal"))
 398   (let ((auths (or (nreverse
 399                     (mail-fetch-field
 400                      (if proxy "proxy-authenticate" "www-authenticate")
 401                      nil nil t))
 402                   '("basic")))
 403         (type nil)
 404         (url (url-recreate-url url-current-object))
 405         (auth-url (url-recreate-url
 406                    (if (and proxy (boundp 'url-http-proxy))
 407                        url-http-proxy
 408                      url-current-object)))
 409         (url-basic-auth-storage (if proxy
 410                                     ;; Cheating, but who cares? :)
 411                                     'url-http-proxy-basic-auth-storage
 412                                   'url-http-real-basic-auth-storage))
 413         auth
 414         (strength 0))
 415
 416     ;; find strongest supported auth
 417     (dolist (this-auth auths)
 418       (setq this-auth (url-eat-trailing-space
 419                        (url-strip-leading-spaces
 420                         this-auth)))
 421       (let* ((this-type
 422               (downcase (if (string-match "[ \t]" this-auth)
 423                             (substring this-auth 0 (match-beginning 0))
 424                           this-auth)))
 425              (registered (url-auth-registered this-type))
 426              (this-strength (cddr registered)))
 427         (when (and registered (> this-strength strength))
 428           (setq auth this-auth
 429                 type this-type
 430                 strength this-strength))))
 431
 432     (if (not (url-auth-registered type))
 433         (progn
 434           (widen)
 435           (goto-char (point-max))
 436           (insert "<hr>Sorry, but I do not know how to handle " type
 437                   " authentication.  If you'd like to write it,"
 438                   " please use M-x report-emacs-bug RET.<hr>")
 439           ;; We used to set a `status' var (declared "special") but I can't
 440           ;; find the corresponding let-binding, so it's probably an error.
 441           ;; FIXME: Maybe it was supposed to set `success', i.e. to return t?
 442           ;; (setq status t)
 443           nil) ;; Not success yet.
 444
 445       (let* ((args (url-parse-args (subst-char-in-string ?, ?\; auth)))
 446              (auth (url-get-authentication auth-url
 447                                            (cdr-safe (assoc "realm" args))
 448                                            type t args)))
 449         (if (not auth)
 450             t                           ;Success.
 451           (push (cons (if proxy "Proxy-Authorization" "Authorization") auth)
 452                 url-http-extra-headers)
 453           (let ((url-request-method url-http-method)
 454                 (url-request-data url-http-data)
 455                 (url-request-extra-headers url-http-extra-headers))
 456             (url-retrieve-internal url url-callback-function
 457                                    url-callback-arguments))
 458           nil))))) ;; Not success yet.
 459
 460 (defun url-http-parse-response ()
 461   "Parse just the response code."
 462   (if (not url-http-end-of-headers)
 463       (error "Trying to parse HTTP response code in odd buffer: %s" (buffer-name)))
 464   (url-http-debug "url-http-parse-response called in (%s)" (buffer-name))
 465   (goto-char (point-min))
 466   (skip-chars-forward " \t\n")          ; Skip any blank crap
 467   (skip-chars-forward "HTTP/")          ; Skip HTTP Version
 468   (setq url-http-response-version
 469         (buffer-substring (point)
 470                           (progn
 471                             (skip-chars-forward "[0-9].")
 472                             (point))))
 473   (setq url-http-response-status (read (current-buffer))))
 474
 475 (defun url-http-handle-cookies ()
 476   "Handle all set-cookie / set-cookie2 headers in an HTTP response.
 477 The buffer must already be narrowed to the headers, so `mail-fetch-field' will
 478 work correctly."
 479   (let ((cookies (nreverse (mail-fetch-field "Set-Cookie" nil nil t)))
 480         (cookies2 (nreverse (mail-fetch-field "Set-Cookie2" nil nil t))))
 481     (and cookies (url-http-debug "Found %d Set-Cookie headers" (length cookies)))
 482     (and cookies2 (url-http-debug "Found %d Set-Cookie2 headers" (length cookies2)))
 483     (while cookies
 484       (url-cookie-handle-set-cookie (pop cookies)))
 485 ;;;     (while cookies2
 486 ;;;       (url-cookie-handle-set-cookie2 (pop cookies)))
 487     )
 488   )
 489
 490 (declare-function gnutls-peer-status "gnutls.c" (proc))
 491
 492 (defun url-http-parse-headers ()
 493  "Parse and handle HTTP specific headers.
 494 Return t if and only if the current buffer is still active and
 495 should be shown to the user."
 496   ;; The comments after each status code handled are taken from RFC
 497   ;; 2616 (HTTP/1.1)
 498   (url-http-mark-connection-as-free (url-host url-current-object)
 499                                     (url-port url-current-object)
 500                                     url-http-process)
 501   ;; Pass the https certificate on to the caller.
 502   (when (gnutls-available-p)
 503     (let ((status (gnutls-peer-status url-http-process)))
 504       (when (or status
 505                 (plist-get (car url-callback-arguments) :peer))
 506         (setcar url-callback-arguments
 507                 (plist-put (car url-callback-arguments)
 508                            :peer status)))))
 509   (if (or (not (boundp 'url-http-end-of-headers))
 510           (not url-http-end-of-headers))
 511       (error "Trying to parse headers in odd buffer: %s" (buffer-name)))
 512   (goto-char (point-min))
 513   (url-http-debug "url-http-parse-headers called in (%s)" (buffer-name))
 514   (url-http-parse-response)
 515   (mail-narrow-to-head)
 516   ;;(narrow-to-region (point-min) url-http-end-of-headers)
 517   (let ((connection (mail-fetch-field "Connection")))
 518     ;; In HTTP 1.0, keep the connection only if there is a
 519     ;; "Connection: keep-alive" header.
 520     ;; In HTTP 1.1 (and greater), keep the connection unless there is a
 521     ;; "Connection: close" header
 522     (cond
 523      ((string= url-http-response-version "1.0")
 524       (unless (and connection
 525                    (string= (downcase connection) "keep-alive"))
 526         (delete-process url-http-process)))
 527      (t
 528       (when (and connection
 529                  (string= (downcase connection) "close"))
 530         (delete-process url-http-process)))))
 531   (let* ((buffer (current-buffer))
 532          (class (/ url-http-response-status 100))
 533          (success nil)
 534          ;; other status symbols: jewelry and luxury cars
 535          (status-symbol (cadr (assq url-http-response-status url-http-codes))))
 536     (url-http-debug "Parsed HTTP headers: class=%d status=%d"
 537                     class url-http-response-status)
 538     (when (url-use-cookies url-http-target-url)
 539       (url-http-handle-cookies))
 540
 541     (pcase class
 542       ;; Classes of response codes
 543       ;;
 544       ;; 5xx = Server Error
 545       ;; 4xx = Client Error
 546       ;; 3xx = Redirection
 547       ;; 2xx = Successful
 548       ;; 1xx = Informational
 549       (1                                ; Information messages
 550        ;; 100 = Continue with request
 551        ;; 101 = Switching protocols
 552        ;; 102 = Processing (Added by DAV)
 553        (url-mark-buffer-as-dead buffer)
 554        (error "HTTP responses in class 1xx not supported (%d)"
 555               url-http-response-status))
 556       (2                                ; Success
 557        ;; 200 Ok
 558        ;; 201 Created
 559        ;; 202 Accepted
 560        ;; 203 Non-authoritative information
 561        ;; 204 No content
 562        ;; 205 Reset content
 563        ;; 206 Partial content
 564        ;; 207 Multi-status (Added by DAV)
 565        (pcase status-symbol
 566          ((or `no-content `reset-content)
 567           ;; No new data, just stay at the same document
 568           (url-mark-buffer-as-dead buffer))
 569          (_
 570           ;; Generic success for all others.  Store in the cache, and
 571           ;; mark it as successful.
 572           (widen)
 573           (if (and url-automatic-caching (equal url-http-method "GET"))
 574               (url-store-in-cache buffer))))
 575        (setq success t))
 576       (3                                ; Redirection
 577        ;; 300 Multiple choices
 578        ;; 301 Moved permanently
 579        ;; 302 Found
 580        ;; 303 See other
 581        ;; 304 Not modified
 582        ;; 305 Use proxy
 583        ;; 307 Temporary redirect
 584        (let ((redirect-uri (or (mail-fetch-field "Location")
 585                                (mail-fetch-field "URI"))))
 586          (pcase status-symbol
 587            (`multiple-choices       ; 300
 588             ;; Quoth the spec (section 10.3.1)
 589             ;; -------------------------------
 590             ;; The requested resource corresponds to any one of a set of
 591             ;; representations, each with its own specific location and
 592             ;; agent-driven negotiation information is being provided so
 593             ;; that the user can select a preferred representation and
 594             ;; redirect its request to that location.
 595             ;; [...]
 596             ;; If the server has a preferred choice of representation, it
 597             ;; SHOULD include the specific URI for that representation in
 598             ;; the Location field; user agents MAY use the Location field
 599             ;; value for automatic redirection.
 600             ;; -------------------------------
 601             ;; We do not support agent-driven negotiation, so we just
 602             ;; redirect to the preferred URI if one is provided.
 603             nil)
 604            ((or `moved-permanently `found `temporary-redirect) ; 301 302 307
 605             ;; If the 301|302 status code is received in response to a
 606             ;; request other than GET or HEAD, the user agent MUST NOT
 607             ;; automatically redirect the request unless it can be
 608             ;; confirmed by the user, since this might change the
 609             ;; conditions under which the request was issued.
 610             (unless (member url-http-method '("HEAD" "GET"))
 611               (setq redirect-uri nil)))
 612            (`see-other                  ; 303
 613             ;; The response to the request can be found under a different
 614             ;; URI and SHOULD be retrieved using a GET method on that
 615             ;; resource.
 616             (setq url-http-method "GET"
 617                   url-http-data nil))
 618            (`not-modified               ; 304
 619             ;; The 304 response MUST NOT contain a message-body.
 620             (url-http-debug "Extracting document from cache... (%s)"
 621                             (url-cache-create-filename (url-view-url t)))
 622             (url-cache-extract (url-cache-create-filename (url-view-url t)))
 623             (setq redirect-uri nil
 624                   success t))
 625            (`use-proxy                  ; 305
 626             ;; The requested resource MUST be accessed through the
 627             ;; proxy given by the Location field.  The Location field
 628             ;; gives the URI of the proxy.  The recipient is expected
 629             ;; to repeat this single request via the proxy.  305
 630             ;; responses MUST only be generated by origin servers.
 631             (error "Redirection thru a proxy server not supported: %s"
 632                    redirect-uri))
 633            (_
 634             ;; Treat everything like '300'
 635             nil))
 636          (when redirect-uri
 637            ;; Clean off any whitespace and/or <...> cruft.
 638            (if (string-match "\\([^ \t]+\\)[ \t]" redirect-uri)
 639                (setq redirect-uri (match-string 1 redirect-uri)))
 640            (if (string-match "^<\\(.*\\)>$" redirect-uri)
 641                (setq redirect-uri (match-string 1 redirect-uri)))
 642
 643            ;; Some stupid sites (like sourceforge) send a
 644            ;; non-fully-qualified URL (ie: /), which royally confuses
 645            ;; the URL library.
 646            (if (not (string-match url-nonrelative-link redirect-uri))
 647                ;; Be careful to use the real target URL, otherwise we may
 648                ;; compute the redirection relative to the URL of the proxy.
 649                (setq redirect-uri
 650                      (url-expand-file-name redirect-uri url-http-target-url)))
 651            ;; Do not automatically include an authorization header in the
 652            ;; redirect.  If needed it will be regenerated by the relevant
 653            ;; auth scheme when the new request happens.
 654            (setq url-http-extra-headers
 655                  (cl-remove "Authorization"
 656                             url-http-extra-headers :key 'car :test 'equal))
 657            (let ((url-request-method url-http-method)
 658                  (url-request-data url-http-data)
 659                  (url-request-extra-headers url-http-extra-headers))
 660              ;; Check existing number of redirects
 661              (if (or (< url-max-redirections 0)
 662                      (and (> url-max-redirections 0)
 663                           (let ((events (car url-callback-arguments))
 664                                 (old-redirects 0))
 665                             (while events
 666                               (if (eq (car events) :redirect)
 667                                   (setq old-redirects (1+ old-redirects)))
 668                               (and (setq events (cdr events))
 669                                    (setq events (cdr events))))
 670                             (< old-redirects url-max-redirections))))
 671                  ;; url-max-redirections hasn't been reached, so go
 672                  ;; ahead and redirect.
 673                  (progn
 674                    ;; Remember that the request was redirected.
 675                    (setf (car url-callback-arguments)
 676                          (nconc (list :redirect redirect-uri)
 677                                 (car url-callback-arguments)))
 678                    ;; Put in the current buffer a forwarding pointer to the new
 679                    ;; destination buffer.
 680                    ;; FIXME: This is a hack to fix url-retrieve-synchronously
 681                    ;; without changing the API.  Instead url-retrieve should
 682                    ;; either simply not return the "destination" buffer, or it
 683                    ;; should take an optional `dest-buf' argument.
 684                    (set (make-local-variable 'url-redirect-buffer)
 685                         (url-retrieve-internal
 686                          redirect-uri url-callback-function
 687                          url-callback-arguments
 688                          (url-silent url-current-object)
 689                          (not (url-use-cookies url-current-object))))
 690                    (url-mark-buffer-as-dead buffer))
 691                ;; We hit url-max-redirections, so issue an error and
 692                ;; stop redirecting.
 693                (url-http-debug "Maximum redirections reached")
 694                (setf (car url-callback-arguments)
 695                      (nconc (list :error (list 'error 'http-redirect-limit
 696                                                redirect-uri))
 697                             (car url-callback-arguments)))
 698                (setq success t))))))
 699       (4                                ; Client error
 700        ;; 400 Bad Request
 701        ;; 401 Unauthorized
 702        ;; 402 Payment required
 703        ;; 403 Forbidden
 704        ;; 404 Not found
 705        ;; 405 Method not allowed
 706        ;; 406 Not acceptable
 707        ;; 407 Proxy authentication required
 708        ;; 408 Request time-out
 709        ;; 409 Conflict
 710        ;; 410 Gone
 711        ;; 411 Length required
 712        ;; 412 Precondition failed
 713        ;; 413 Request entity too large
 714        ;; 414 Request-URI too large
 715        ;; 415 Unsupported media type
 716        ;; 416 Requested range not satisfiable
 717        ;; 417 Expectation failed
 718        ;; 422 Unprocessable Entity (Added by DAV)
 719        ;; 423 Locked
 720        ;; 424 Failed Dependency
 721        (setq success
 722              (pcase status-symbol
 723                (`unauthorized                   ; 401
 724                 ;; The request requires user authentication.  The response
 725                 ;; MUST include a WWW-Authenticate header field containing a
 726                 ;; challenge applicable to the requested resource.  The
 727                 ;; client MAY repeat the request with a suitable
 728                 ;; Authorization header field.
 729                 (url-http-handle-authentication nil))
 730                (`payment-required              ; 402
 731                 ;; This code is reserved for future use
 732                 (url-mark-buffer-as-dead buffer)
 733                 (error "Somebody wants you to give them money"))
 734                (`forbidden                      ; 403
 735                 ;; The server understood the request, but is refusing to
 736                 ;; fulfill it.  Authorization will not help and the request
 737                 ;; SHOULD NOT be repeated.
 738                 t)
 739                (`not-found                      ; 404
 740                 ;; Not found
 741                 t)
 742                (`method-not-allowed             ; 405
 743                 ;; The method specified in the Request-Line is not allowed
 744                 ;; for the resource identified by the Request-URI.  The
 745                 ;; response MUST include an Allow header containing a list of
 746                 ;; valid methods for the requested resource.
 747                 t)
 748                (`not-acceptable         ; 406
 749                 ;; The resource identified by the request is only capable of
 750                 ;; generating response entities which have content
 751                 ;; characteristics not acceptable according to the accept
 752                 ;; headers sent in the request.
 753                 t)
 754                (`proxy-authentication-required ; 407
 755                 ;; This code is similar to 401 (Unauthorized), but indicates
 756                 ;; that the client must first authenticate itself with the
 757                 ;; proxy.  The proxy MUST return a Proxy-Authenticate header
 758                 ;; field containing a challenge applicable to the proxy for
 759                 ;; the requested resource.
 760                 (url-http-handle-authentication t))
 761                (`request-timeout                ; 408
 762                 ;; The client did not produce a request within the time that
 763                 ;; the server was prepared to wait.  The client MAY repeat
 764                 ;; the request without modifications at any later time.
 765                 t)
 766                (`conflict                       ; 409
 767                 ;; The request could not be completed due to a conflict with
 768                 ;; the current state of the resource.  This code is only
 769                 ;; allowed in situations where it is expected that the user
 770                 ;; might be able to resolve the conflict and resubmit the
 771                 ;; request.  The response body SHOULD include enough
 772                 ;; information for the user to recognize the source of the
 773                 ;; conflict.
 774                 t)
 775                (`gone                          ; 410
 776                 ;; The requested resource is no longer available at the
 777                 ;; server and no forwarding address is known.
 778                 t)
 779                (`length-required                ; 411
 780                 ;; The server refuses to accept the request without a defined
 781                 ;; Content-Length.  The client MAY repeat the request if it
 782                 ;; adds a valid Content-Length header field containing the
 783                 ;; length of the message-body in the request message.
 784                 ;;
 785                 ;; NOTE - this will never happen because
 786                 ;; `url-http-create-request' automatically calculates the
 787                 ;; content-length.
 788                 t)
 789                (`precondition-failed            ; 412
 790                 ;; The precondition given in one or more of the
 791                 ;; request-header fields evaluated to false when it was
 792                 ;; tested on the server.
 793                 t)
 794                ((or `request-entity-too-large `request-uri-too-large) ; 413 414
 795                 ;; The server is refusing to process a request because the
 796                 ;; request entity|URI is larger than the server is willing or
 797                 ;; able to process.
 798                 t)
 799                (`unsupported-media-type ; 415
 800                 ;; The server is refusing to service the request because the
 801                 ;; entity of the request is in a format not supported by the
 802                 ;; requested resource for the requested method.
 803                 t)
 804                (`requested-range-not-satisfiable ; 416
 805                 ;; A server SHOULD return a response with this status code if
 806                 ;; a request included a Range request-header field, and none
 807                 ;; of the range-specifier values in this field overlap the
 808                 ;; current extent of the selected resource, and the request
 809                 ;; did not include an If-Range request-header field.
 810                 t)
 811                (`expectation-failed             ; 417
 812                 ;; The expectation given in an Expect request-header field
 813                 ;; could not be met by this server, or, if the server is a
 814                 ;; proxy, the server has unambiguous evidence that the
 815                 ;; request could not be met by the next-hop server.
 816                 t)
 817                (_
 818                 ;; The request could not be understood by the server due to
 819                 ;; malformed syntax.  The client SHOULD NOT repeat the
 820                 ;; request without modifications.
 821                 t)))
 822        ;; Tell the callback that an error occurred, and what the
 823        ;; status code was.
 824        (when success
 825          (setf (car url-callback-arguments)
 826                (nconc (list :error (list 'error 'http url-http-response-status))
 827                       (car url-callback-arguments)))))
 828       (5
 829        ;; 500 Internal server error
 830        ;; 501 Not implemented
 831        ;; 502 Bad gateway
 832        ;; 503 Service unavailable
 833        ;; 504 Gateway time-out
 834        ;; 505 HTTP version not supported
 835        ;; 507 Insufficient storage
 836        (setq success t)
 837        (pcase url-http-response-status
 838          (`not-implemented              ; 501
 839           ;; The server does not support the functionality required to
 840           ;; fulfill the request.
 841           nil)
 842          (`bad-gateway                  ; 502
 843           ;; The server, while acting as a gateway or proxy, received
 844           ;; an invalid response from the upstream server it accessed
 845           ;; in attempting to fulfill the request.
 846           nil)
 847          (`service-unavailable          ; 503
 848           ;; The server is currently unable to handle the request due
 849           ;; to a temporary overloading or maintenance of the server.
 850           ;; The implication is that this is a temporary condition
 851           ;; which will be alleviated after some delay.  If known, the
 852           ;; length of the delay MAY be indicated in a Retry-After
 853           ;; header.  If no Retry-After is given, the client SHOULD
 854           ;; handle the response as it would for a 500 response.
 855           nil)
 856          (`gateway-timeout              ; 504
 857           ;; The server, while acting as a gateway or proxy, did not
 858           ;; receive a timely response from the upstream server
 859           ;; specified by the URI (e.g. HTTP, FTP, LDAP) or some other
 860           ;; auxiliary server (e.g. DNS) it needed to access in
 861           ;; attempting to complete the request.
 862           nil)
 863          (`http-version-not-supported   ; 505
 864           ;; The server does not support, or refuses to support, the
 865           ;; HTTP protocol version that was used in the request
 866           ;; message.
 867           nil)
 868          (`insufficient-storage         ; 507 (DAV)
 869           ;; The method could not be performed on the resource
 870           ;; because the server is unable to store the representation
 871           ;; needed to successfully complete the request.  This
 872           ;; condition is considered to be temporary.  If the request
 873           ;; which received this status code was the result of a user
 874           ;; action, the request MUST NOT be repeated until it is
 875           ;; requested by a separate user action.
 876           nil))
 877        ;; Tell the callback that an error occurred, and what the
 878        ;; status code was.
 879        (when success
 880          (setf (car url-callback-arguments)
 881                (nconc (list :error (list 'error 'http url-http-response-status))
 882                       (car url-callback-arguments)))))
 883       (_
 884        (error "Unknown class of HTTP response code: %d (%d)"
 885               class url-http-response-status)))
 886     (if (not success)
 887         (url-mark-buffer-as-dead buffer)
 888       (url-handle-content-transfer-encoding))
 889     (url-http-debug "Finished parsing HTTP headers: %S" success)
 890     (widen)
 891     (goto-char (point-min))
 892     success))
 893
 894 (declare-function zlib-decompress-region "decompress.c" (start end))
 895
 896 (defun url-handle-content-transfer-encoding ()
 897   (let ((encoding (mail-fetch-field "content-encoding")))
 898     (when (and encoding
 899                (fboundp 'zlib-available-p)
 900                (zlib-available-p)
 901                (equal (downcase encoding) "gzip"))
 902       (save-restriction
 903         (widen)
 904         (goto-char (point-min))
 905         (when (search-forward "\n\n")
 906           (zlib-decompress-region (point) (point-max)))))))
 907
 908 ;; Miscellaneous
 909 (defun url-http-activate-callback ()
 910   "Activate callback specified when this buffer was created."
 911   (url-http-mark-connection-as-free (url-host url-current-object)
 912                                     (url-port url-current-object)
 913                                     url-http-process)
 914   (url-http-debug "Activating callback in buffer (%s): %S %S"
 915                   (buffer-name) url-callback-function url-callback-arguments)
 916   (apply url-callback-function url-callback-arguments))
 917
 918 ;; )
 919
 920 ;; These unfortunately cannot be macros... please ignore them!
 921 (defun url-http-idle-sentinel (proc why)
 922   "Remove (now defunct) process PROC from the list of open connections."
 923   (maphash (lambda (key val)
 924                 (if (memq proc val)
 925                     (puthash key (delq proc val) url-http-open-connections)))
 926               url-http-open-connections))
 927
 928 (defun url-http-end-of-document-sentinel (proc why)
 929   ;; Sentinel used to handle (i) terminated old HTTP/0.9 connections,
 930   ;; and (ii) closed connection due to reusing a HTTP connection which
 931   ;; we believed was still alive, but which the server closed on us.
 932   ;; We handle case (ii) by calling `url-http' again.
 933   (url-http-debug "url-http-end-of-document-sentinel in buffer (%s)"
 934                   (process-buffer proc))
 935   (url-http-idle-sentinel proc why)
 936   (when (buffer-name (process-buffer proc))
 937     (with-current-buffer (process-buffer proc)
 938       (goto-char (point-min))
 939       (cond ((not (looking-at "HTTP/"))
 940              (if url-http-no-retry
 941                  ;; HTTP/0.9 just gets passed back no matter what
 942                  (url-http-activate-callback)
 943                ;; Call `url-http' again if our connection expired.
 944                (erase-buffer)
 945                (let ((url-request-method url-http-method)
 946                      (url-request-extra-headers url-http-extra-headers)
 947                      (url-request-data url-http-data))
 948                  (url-http url-current-object url-callback-function
 949                            url-callback-arguments (current-buffer)))))
 950             ((url-http-parse-headers)
 951              (url-http-activate-callback))))))
 952
 953 (defun url-http-simple-after-change-function (st nd length)
 954   ;; Function used when we do NOT know how long the document is going to be
 955   ;; Just _very_ simple 'downloaded %d' type of info.
 956   (url-lazy-message "Reading %s..." (file-size-human-readable nd)))
 957
 958 (defun url-http-content-length-after-change-function (st nd length)
 959   "Function used when we DO know how long the document is going to be.
 960 More sophisticated percentage downloaded, etc.
 961 Also does minimal parsing of HTTP headers and will actually cause
 962 the callback to be triggered."
 963   (if url-http-content-type
 964       (url-display-percentage
 965        "Reading [%s]... %s of %s (%d%%)"
 966        (url-percentage (- nd url-http-end-of-headers)
 967                        url-http-content-length)
 968        url-http-content-type
 969        (file-size-human-readable (- nd url-http-end-of-headers))
 970        (file-size-human-readable url-http-content-length)
 971        (url-percentage (- nd url-http-end-of-headers)
 972                        url-http-content-length))
 973     (url-display-percentage
 974      "Reading... %s of %s (%d%%)"
 975      (url-percentage (- nd url-http-end-of-headers)
 976                      url-http-content-length)
 977      (file-size-human-readable (- nd url-http-end-of-headers))
 978      (file-size-human-readable url-http-content-length)
 979      (url-percentage (- nd url-http-end-of-headers)
 980                      url-http-content-length)))
 981
 982   (if (> (- nd url-http-end-of-headers) url-http-content-length)
 983       (progn
 984         ;; Found the end of the document!  Wheee!
 985         (url-display-percentage nil nil)
 986         (url-lazy-message "Reading... done.")
 987         (if (url-http-parse-headers)
 988             (url-http-activate-callback)))))
 989
 990 (defun url-http-chunked-encoding-after-change-function (st nd length)
 991   "Function used when dealing with 'chunked' encoding.
 992 Cannot give a sophisticated percentage, but we need a different
 993 function to look for the special 0-length chunk that signifies
 994 the end of the document."
 995   (save-excursion
 996     (goto-char st)
 997     (let ((read-next-chunk t)
 998           (case-fold-search t)
 999           (regexp nil)
1000           (no-initial-crlf nil))
1001       ;; We need to loop thru looking for more chunks even within
1002       ;; one after-change-function call.
1003       (while read-next-chunk
1004         (setq no-initial-crlf (= 0 url-http-chunked-counter))
1005         (if url-http-content-type
1006             (url-display-percentage nil
1007              "Reading [%s]... chunk #%d"
1008              url-http-content-type url-http-chunked-counter)
1009           (url-display-percentage nil
1010            "Reading... chunk #%d"
1011            url-http-chunked-counter))
1012         (url-http-debug "Reading chunk %d (%d %d %d)"
1013                         url-http-chunked-counter st nd length)
1014         (setq regexp (if no-initial-crlf
1015                          "\\([0-9a-z]+\\).*\r?\n"
1016                        "\r?\n\\([0-9a-z]+\\).*\r?\n"))
1017
1018         (if url-http-chunked-start
1019             ;; We know how long the chunk is supposed to be, skip over
1020             ;; leading crap if possible.
1021             (if (> nd (+ url-http-chunked-start url-http-chunked-length))
1022                 (progn
1023                   (url-http-debug "Got to the end of chunk #%d!"
1024                                   url-http-chunked-counter)
1025                   (goto-char (+ url-http-chunked-start
1026                                 url-http-chunked-length)))
1027               (url-http-debug "Still need %d bytes to hit end of chunk"
1028                               (- (+ url-http-chunked-start
1029                                     url-http-chunked-length)
1030                                  nd))
1031               (setq read-next-chunk nil)))
1032         (if (not read-next-chunk)
1033             (url-http-debug "Still spinning for next chunk...")
1034           (if no-initial-crlf (skip-chars-forward "\r\n"))
1035           (if (not (looking-at regexp))
1036               (progn
1037            ;; Must not have received the entirety of the chunk header,
1038                 ;; need to spin some more.
1039                 (url-http-debug "Did not see start of chunk @ %d!" (point))
1040                 (setq read-next-chunk nil))
1041             (add-text-properties (match-beginning 0) (match-end 0)
1042                                  (list 'start-open t
1043                                        'end-open t
1044                                        'chunked-encoding t
1045                                        'face 'cursor
1046                                        'invisible t))
1047             (setq url-http-chunked-length (string-to-number (buffer-substring
1048                                                              (match-beginning 1)
1049                                                              (match-end 1))
1050                                                             16)
1051                   url-http-chunked-counter (1+ url-http-chunked-counter)
1052                   url-http-chunked-start (set-marker
1053                                           (or url-http-chunked-start
1054                                               (make-marker))
1055                                           (match-end 0)))
1056 ;           (if (not url-http-debug)
1057                 (delete-region (match-beginning 0) (match-end 0));)
1058             (url-http-debug "Saw start of chunk %d (length=%d, start=%d"
1059                             url-http-chunked-counter url-http-chunked-length
1060                             (marker-position url-http-chunked-start))
1061             (if (= 0 url-http-chunked-length)
1062                 (progn
1063                   ;; Found the end of the document!  Wheee!
1064                   (url-http-debug "Saw end of stream chunk!")
1065                   (setq read-next-chunk nil)
1066                   (url-display-percentage nil nil)
1067                   ;; Every chunk, even the last 0-length one, is
1068                   ;; terminated by CRLF.  Skip it.
1069                   (when (looking-at "\r?\n")
1070                     (url-http-debug "Removing terminator of last chunk")
1071                     (delete-region (match-beginning 0) (match-end 0)))
1072                   (if (re-search-forward "^\r*$" nil t)
1073                       (url-http-debug "Saw end of trailers..."))
1074                   (if (url-http-parse-headers)
1075                       (url-http-activate-callback))))))))))
1076
1077 (defun url-http-wait-for-headers-change-function (st nd length)
1078   ;; This will wait for the headers to arrive and then splice in the
1079   ;; next appropriate after-change-function, etc.
1080   (url-http-debug "url-http-wait-for-headers-change-function (%s)"
1081                   (buffer-name))
1082   (let ((end-of-headers nil)
1083         (old-http nil)
1084         (process-buffer (current-buffer))
1085         (content-length nil))
1086     (when (not (bobp))
1087       (goto-char (point-min))
1088       (if (and (looking-at ".*\n")      ; have one line at least
1089                (not (looking-at "^HTTP/[1-9]\\.[0-9]")))
1090           ;; Not HTTP/x.y data, must be 0.9
1091           ;; God, I wish this could die.
1092           (setq end-of-headers t
1093                 url-http-end-of-headers 0
1094                 old-http t)
1095         ;; Blank line at end of headers.
1096         (when (re-search-forward "^\r?\n" nil t)
1097           (backward-char 1)
1098           ;; Saw the end of the headers
1099           (url-http-debug "Saw end of headers... (%s)" (buffer-name))
1100           (setq url-http-end-of-headers (set-marker (make-marker)
1101                                                     (point))
1102                 end-of-headers t)
1103           (setq nd (- nd (url-http-clean-headers)))))
1104
1105       (if (not end-of-headers)
1106           ;; Haven't seen the end of the headers yet, need to wait
1107           ;; for more data to arrive.
1108           nil
1109         (unless old-http
1110           (url-http-parse-response)
1111           (mail-narrow-to-head)
1112           (setq url-http-transfer-encoding (mail-fetch-field
1113                                             "transfer-encoding")
1114                 url-http-content-type (mail-fetch-field "content-type"))
1115           (if (mail-fetch-field "content-length")
1116               (setq url-http-content-length
1117                     (string-to-number (mail-fetch-field "content-length"))))
1118           (widen))
1119         (when url-http-transfer-encoding
1120           (setq url-http-transfer-encoding
1121                 (downcase url-http-transfer-encoding)))
1122
1123         (cond
1124          ((null url-http-response-status)
1125           ;; We got back a headerless malformed response from the
1126           ;; server.
1127           (url-http-activate-callback))
1128          ((or (= url-http-response-status 204)
1129               (= url-http-response-status 205))
1130           (url-http-debug "%d response must have headers only (%s)."
1131                           url-http-response-status (buffer-name))
1132           (when (url-http-parse-headers)
1133             (url-http-activate-callback)))
1134          ((string= "HEAD" url-http-method)
1135           ;; A HEAD request is _ALWAYS_ terminated by the header
1136           ;; information, regardless of any entity headers,
1137           ;; according to section 4.4 of the HTTP/1.1 draft.
1138           (url-http-debug "HEAD request must have headers only (%s)."
1139                           (buffer-name))
1140           (when (url-http-parse-headers)
1141             (url-http-activate-callback)))
1142          ((string= "CONNECT" url-http-method)
1143           ;; A CONNECT request is finished, but we cannot stick this
1144           ;; back on the free connection list
1145           (url-http-debug "CONNECT request must have headers only.")
1146           (when (url-http-parse-headers)
1147             (url-http-activate-callback)))
1148          ((equal url-http-response-status 304)
1149           ;; Only allowed to have a header section.  We have to handle
1150           ;; this here instead of in url-http-parse-headers because if
1151           ;; you have a cached copy of something without a known
1152           ;; content-length, and try to retrieve it from the cache, we'd
1153           ;; fall into the 'being dumb' section and wait for the
1154           ;; connection to terminate, which means we'd wait for 10
1155           ;; seconds for the keep-alives to time out on some servers.
1156           (when (url-http-parse-headers)
1157             (url-http-activate-callback)))
1158          (old-http
1159           ;; HTTP/0.9 always signaled end-of-connection by closing the
1160           ;; connection.
1161           (url-http-debug
1162            "Saw HTTP/0.9 response, connection closed means end of document.")
1163           (setq url-http-after-change-function
1164                 'url-http-simple-after-change-function))
1165          ((equal url-http-transfer-encoding "chunked")
1166           (url-http-debug "Saw chunked encoding.")
1167           (setq url-http-after-change-function
1168                 'url-http-chunked-encoding-after-change-function)
1169           (when (> nd url-http-end-of-headers)
1170             (url-http-debug
1171              "Calling initial chunked-encoding for extra data at end of headers")
1172             (url-http-chunked-encoding-after-change-function
1173              (marker-position url-http-end-of-headers) nd
1174              (- nd url-http-end-of-headers))))
1175          ((integerp url-http-content-length)
1176           (url-http-debug
1177            "Got a content-length, being smart about document end.")
1178           (setq url-http-after-change-function
1179                 'url-http-content-length-after-change-function)
1180           (cond
1181            ((= 0 url-http-content-length)
1182             ;; We got a NULL body!  Activate the callback
1183             ;; immediately!
1184             (url-http-debug
1185              "Got 0-length content-length, activating callback immediately.")
1186             (when (url-http-parse-headers)
1187               (url-http-activate-callback)))
1188            ((> nd url-http-end-of-headers)
1189             ;; Have some leftover data
1190             (url-http-debug "Calling initial content-length for extra data at end of headers")
1191             (url-http-content-length-after-change-function
1192              (marker-position url-http-end-of-headers)
1193              nd
1194              (- nd url-http-end-of-headers)))
1195            (t
1196             nil)))
1197          (t
1198           (url-http-debug "No content-length, being dumb.")
1199           (setq url-http-after-change-function
1200                 'url-http-simple-after-change-function)))))
1201     ;; We are still at the beginning of the buffer... must just be
1202     ;; waiting for a response.
1203     (url-http-debug "Spinning waiting for headers...")
1204     (when (eq process-buffer (current-buffer))
1205       (goto-char (point-max)))))
1206
1207 (defun url-http (url callback cbargs &optional retry-buffer gateway-method)
1208   "Retrieve URL via HTTP asynchronously.
1209 URL must be a parsed URL.  See `url-generic-parse-url' for details.
1210
1211 When retrieval is completed, execute the function CALLBACK,
1212 passing it an updated value of CBARGS as arguments.  The first
1213 element in CBARGS should be a plist describing what has happened
1214 so far during the request, as described in the docstring of
1215 `url-retrieve' (if in doubt, specify nil).  The current buffer
1216 then CALLBACK is executed is the retrieval buffer.
1217
1218 Optional arg RETRY-BUFFER, if non-nil, specifies the buffer of a
1219 previous `url-http' call, which is being re-attempted.
1220
1221 Optional arg GATEWAY-METHOD specifies the gateway to be used,
1222 overriding the value of `url-gateway-method'.
1223
1224 The return value of this function is the retrieval buffer."
1225   (cl-check-type url vector "Need a pre-parsed URL.")
1226   (let* ((host (url-host (or url-using-proxy url)))
1227          (port (url-port (or url-using-proxy url)))
1228          (nsm-noninteractive (or url-request-noninteractive
1229                                  (and (boundp 'url-http-noninteractive)
1230                                       url-http-noninteractive)))
1231          (connection (url-http-find-free-connection host port gateway-method))
1232          (buffer (or retry-buffer
1233                      (generate-new-buffer
1234                       (format " *http %s:%d*" host port)))))
1235     (if (not connection)
1236         ;; Failed to open the connection for some reason
1237         (progn
1238           (kill-buffer buffer)
1239           (setq buffer nil)
1240           (error "Could not create connection to %s:%d" host port))
1241       (with-current-buffer buffer
1242         (mm-disable-multibyte)
1243         (setq url-current-object url
1244               mode-line-format "%b [%s]")
1245
1246         (dolist (var '(url-http-end-of-headers
1247                        url-http-content-type
1248                        url-http-content-length
1249                        url-http-transfer-encoding
1250                        url-http-after-change-function
1251                        url-http-response-version
1252                        url-http-response-status
1253                        url-http-chunked-length
1254                        url-http-chunked-counter
1255                        url-http-chunked-start
1256                        url-callback-function
1257                        url-callback-arguments
1258                        url-show-status
1259                        url-http-process
1260                        url-http-method
1261                        url-http-extra-headers
1262                        url-http-noninteractive
1263                        url-http-data
1264                        url-http-target-url
1265                        url-http-no-retry
1266                        url-http-connection-opened
1267                        url-http-proxy))
1268           (set (make-local-variable var) nil))
1269
1270         (setq url-http-method (or url-request-method "GET")
1271               url-http-extra-headers url-request-extra-headers
1272               url-http-noninteractive url-request-noninteractive
1273               url-http-data url-request-data
1274               url-http-process connection
1275               url-http-chunked-length nil
1276               url-http-chunked-start nil
1277               url-http-chunked-counter 0
1278               url-callback-function callback
1279               url-callback-arguments cbargs
1280               url-http-after-change-function 'url-http-wait-for-headers-change-function
1281               url-http-target-url url-current-object
1282               url-http-no-retry retry-buffer
1283               url-http-connection-opened nil
1284               url-http-proxy url-using-proxy)
1285
1286         (set-process-buffer connection buffer)
1287         (set-process-filter connection 'url-http-generic-filter)
1288         (pcase (process-status connection)
1289           (`connect
1290            ;; Asynchronous connection
1291            (set-process-sentinel connection 'url-http-async-sentinel))
1292           (`failed
1293            ;; Asynchronous connection failed
1294            (error "Could not create connection to %s:%d" host port))
1295           (_
1296            (set-process-sentinel connection
1297                                  'url-http-end-of-document-sentinel)
1298            (process-send-string connection (url-http-create-request))))))
1299     buffer))
1300
1301 (defun url-http-async-sentinel (proc why)
1302   ;; We are performing an asynchronous connection, and a status change
1303   ;; has occurred.
1304   (when (buffer-name (process-buffer proc))
1305     (with-current-buffer (process-buffer proc)
1306       (cond
1307        (url-http-connection-opened
1308         (setq url-http-no-retry t)
1309         (url-http-end-of-document-sentinel proc why))
1310        ((string= (substring why 0 4) "open")
1311         (setq url-http-connection-opened t)
1312         (condition-case error
1313             (process-send-string proc (url-http-create-request))
1314           (file-error
1315            (setq url-http-connection-opened nil)
1316            (message "HTTP error: %s" error))))
1317        (t
1318         (setf (car url-callback-arguments)
1319               (nconc (list :error (list 'error 'connection-failed why
1320                                         :host (url-host (or url-http-proxy url-current-object))
1321                                         :service (url-port (or url-http-proxy url-current-object))))
1322                      (car url-callback-arguments)))
1323         (url-http-activate-callback))))))
1324
1325 ;; Since Emacs 19/20 does not allow you to change the
1326 ;; `after-change-functions' hook in the midst of running them, we fake
1327 ;; an after change by hooking into the process filter and inserting
1328 ;; the data ourselves.  This is slightly less efficient, but there
1329 ;; were tons of weird ways the after-change code was biting us in the
1330 ;; shorts.
1331 ;; FIXME this can probably be simplified since the above is no longer true.
1332 (defun url-http-generic-filter (proc data)
1333   ;; Sometimes we get a zero-length data chunk after the process has
1334   ;; been changed to 'free', which means it has no buffer associated
1335   ;; with it.  Do nothing if there is no buffer, or 0 length data.
1336   (and (process-buffer proc)
1337        (/= (length data) 0)
1338        (with-current-buffer (process-buffer proc)
1339          (url-http-debug "Calling after change function `%s' for `%S'" url-http-after-change-function proc)
1340          (funcall url-http-after-change-function
1341                   (point-max)
1342                   (progn
1343                     (goto-char (point-max))
1344                     (insert data)
1345                     (point-max))
1346                   (length data)))))
1347
1348 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1349 ;;; file-name-handler stuff from here on out
1350 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1351 (defalias 'url-http-symbol-value-in-buffer
1352   (if (fboundp 'symbol-value-in-buffer)
1353       'symbol-value-in-buffer
1354     (lambda (symbol buffer &optional unbound-value)
1355       "Return the value of SYMBOL in BUFFER, or UNBOUND-VALUE if it is unbound."
1356       (with-current-buffer buffer
1357         (if (not (boundp symbol))
1358             unbound-value
1359           (symbol-value symbol))))))
1360
1361 (defun url-http-head (url)
1362   (let ((url-request-method "HEAD")
1363         (url-request-data nil))
1364     (url-retrieve-synchronously url)))
1365
1366 (defun url-http-file-exists-p (url)
1367   (let ((buffer (url-http-head url)))
1368     (when buffer
1369       (let ((status (url-http-symbol-value-in-buffer 'url-http-response-status
1370                                                      buffer 500)))
1371         (prog1
1372             (and (integerp status)
1373                  (>= status 200) (< status 300))
1374           (kill-buffer buffer))))))
1375
1376 (defalias 'url-http-file-readable-p 'url-http-file-exists-p)
1377
1378 (defun url-http-head-file-attributes (url &optional id-format)
1379   (let ((buffer (url-http-head url)))
1380     (when buffer
1381       (prog1
1382           (list
1383            nil                          ;dir / link / normal file
1384            1                            ;number of links to file.
1385            0 0                          ;uid ; gid
1386            nil nil nil                  ;atime ; mtime ; ctime
1387            (url-http-symbol-value-in-buffer 'url-http-content-length
1388                                             buffer -1)
1389            (eval-when-compile (make-string 10 ?-))
1390            nil nil nil)          ;whether gid would change ; inode ; device.
1391         (kill-buffer buffer)))))
1392
1393 (declare-function url-dav-file-attributes "url-dav" (url &optional id-format))
1394
1395 (defun url-http-file-attributes (url &optional id-format)
1396   (if (url-dav-supported-p url)
1397       (url-dav-file-attributes url id-format)
1398     (url-http-head-file-attributes url id-format)))
1399
1400 (defun url-http-options (url)
1401   "Return a property list describing options available for URL.
1402 This list is retrieved using the `OPTIONS' HTTP method.
1403
1404 Property list members:
1405
1406 methods
1407   A list of symbols specifying what HTTP methods the resource
1408   supports.
1409
1410 dav
1411   A list of numbers specifying what DAV protocol/schema versions are
1412   supported.
1413
1414 dasl
1415   A list of supported DASL search types supported (string form)
1416
1417 ranges
1418   A list of the units available for use in partial document fetches.
1419
1420 p3p
1421   The `Platform For Privacy Protection' description for the resource.
1422   Currently this is just the raw header contents.  This is likely to
1423   change once P3P is formally supported by the URL package or
1424   Emacs/W3."
1425   (let* ((url-request-method "OPTIONS")
1426          (url-request-data nil)
1427          (buffer (url-retrieve-synchronously url))
1428          (header nil)
1429          (options nil))
1430     (when (and buffer (= 2 (/ (url-http-symbol-value-in-buffer
1431                                'url-http-response-status buffer 0) 100)))
1432       ;; Only parse the options if we got a 2xx response code!
1433       (with-current-buffer buffer
1434         (save-restriction
1435           (save-match-data
1436             (mail-narrow-to-head)
1437
1438             ;; Figure out what methods are supported.
1439             (when (setq header (mail-fetch-field "allow"))
1440               (setq options (plist-put
1441                              options 'methods
1442                              (mapcar 'intern (split-string header "[ ,]+")))))
1443
1444             ;; Check for DAV
1445             (when (setq header (mail-fetch-field "dav"))
1446               (setq options (plist-put
1447                              options 'dav
1448                              (delq 0
1449                                    (mapcar 'string-to-number
1450                                            (split-string header "[, ]+"))))))
1451
1452             ;; Now for DASL
1453             (when (setq header (mail-fetch-field "dasl"))
1454               (setq options (plist-put
1455                              options 'dasl
1456                              (split-string header "[, ]+"))))
1457
1458             ;; P3P - should get more detailed here.  FIXME
1459             (when (setq header (mail-fetch-field "p3p"))
1460               (setq options (plist-put options 'p3p header)))
1461
1462             ;; Check for whether they accept byte-range requests.
1463             (when (setq header (mail-fetch-field "accept-ranges"))
1464               (setq options (plist-put
1465                              options 'ranges
1466                              (delq 'none
1467                                    (mapcar 'intern
1468                                            (split-string header "[, ]+"))))))
1469             ))))
1470     (if buffer (kill-buffer buffer))
1471     options))
1472
1473 ;; HTTPS.  This used to be in url-https.el, but that file collides
1474 ;; with url-http.el on systems with 8-character file names.
1475 (require 'tls)
1476
1477 (defconst url-https-default-port 443 "Default HTTPS port.")
1478 (defconst url-https-asynchronous-p t "HTTPS retrievals are asynchronous.")
1479
1480 ;; FIXME what is the point of this alias being an autoload?
1481 ;; Trying to use it will not cause url-http to be loaded,
1482 ;; since the full alias just gets dumped into loaddefs.el.
1483
1484 ;;;###autoload (autoload 'url-default-expander "url-expand")
1485 ;;;###autoload
1486 (defalias 'url-https-expand-file-name 'url-default-expander)
1487
1488 (defmacro url-https-create-secure-wrapper (method args)
1489   `(defun ,(intern (format (if method "url-https-%s" "url-https") method)) ,args
1490     ,(format "HTTPS wrapper around `%s' call." (or method "url-http"))
1491     (,(intern (format (if method "url-http-%s" "url-http") method))
1492      ,@(remove '&rest (remove '&optional (append args (if method nil '(nil 'tls))))))))
1493
1494 ;;;###autoload (autoload 'url-https "url-http")
1495 (url-https-create-secure-wrapper nil (url callback cbargs))
1496 ;;;###autoload (autoload 'url-https-file-exists-p "url-http")
1497 (url-https-create-secure-wrapper file-exists-p (url))
1498 ;;;###autoload (autoload 'url-https-file-readable-p "url-http")
1499 (url-https-create-secure-wrapper file-readable-p (url))
1500 ;;;###autoload (autoload 'url-https-file-attributes "url-http")
1501 (url-https-create-secure-wrapper file-attributes (url &optional id-format))
1502
1503 (provide 'url-http)
1504
1505 ;;; url-http.el ends here