code.delx.au - gnu-emacs/blob - lisp/vc/vc-rcs.el

   1 ;;; vc-rcs.el --- support for RCS version-control  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1992-2015 Free Software Foundation, Inc.
   4
   5 ;; Author:     FSF (see vc.el for full credits)
   6 ;; Maintainer: Andre Spiegel <spiegel@gnu.org>
   7 ;; Package: vc
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; See vc.el
  27
  28 ;; Some features will not work with ancient RCS versions.  Where
  29 ;; appropriate, VC finds out which version you have, and allows or
  30 ;; disallows those features.
  31
  32 ;; You can support the RCS -x option by customizing vc-rcs-master-templates.
  33
  34 ;;; Code:
  35
  36 ;;;
  37 ;;; Customization options
  38 ;;;
  39
  40 (eval-when-compile
  41   (require 'cl-lib)
  42   (require 'vc))
  43
  44 (defgroup vc-rcs nil
  45   "VC RCS backend."
  46   :version "24.1"
  47   :group 'vc)
  48
  49 (defcustom vc-rcs-release nil
  50   "The release number of your RCS installation, as a string.
  51 If nil, VC itself computes this value when it is first needed."
  52   :type '(choice (const :tag "Auto" nil)
  53                  (string :tag "Specified")
  54                  (const :tag "Unknown" unknown))
  55   :group 'vc-rcs)
  56
  57 (defcustom vc-rcs-register-switches nil
  58   "Switches for registering a file in RCS.
  59 A string or list of strings passed to the checkin program by
  60 \\[vc-register].  If nil, use the value of `vc-register-switches'.
  61 If t, use no switches."
  62   :type '(choice (const :tag "Unspecified" nil)
  63                  (const :tag "None" t)
  64                  (string :tag "Argument String")
  65                  (repeat :tag "Argument List" :value ("") string))
  66   :version "21.1"
  67   :group 'vc-rcs)
  68
  69 (defcustom vc-rcs-diff-switches nil
  70   "String or list of strings specifying switches for RCS diff under VC.
  71 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
  72   :type '(choice (const :tag "Unspecified" nil)
  73                  (const :tag "None" t)
  74                  (string :tag "Argument String")
  75                  (repeat :tag "Argument List" :value ("") string))
  76   :version "21.1"
  77   :group 'vc-rcs)
  78
  79 (defcustom vc-rcs-header '("$Id\ $")
  80   "Header keywords to be inserted by `vc-insert-headers'."
  81   :type '(repeat string)
  82   :version "24.1"     ; no longer consult the obsolete vc-header-alist
  83   :group 'vc-rcs)
  84
  85 (defcustom vc-rcsdiff-knows-brief nil
  86   "Indicates whether rcsdiff understands the --brief option.
  87 The value is either `yes', `no', or nil.  If it is nil, VC tries
  88 to use --brief and sets this variable to remember whether it worked."
  89   :type '(choice (const :tag "Work out" nil) (const yes) (const no))
  90   :group 'vc-rcs)
  91
  92 ;; This needs to be autoloaded because vc-rcs-registered uses it (via
  93 ;; vc-default-registered), and vc-hooks needs to be able to check
  94 ;; for a registered backend without loading every backend.
  95 ;;;###autoload
  96 (defcustom vc-rcs-master-templates
  97   (purecopy '("%sRCS/%s,v" "%s%s,v" "%sRCS/%s"))
  98   "Where to look for RCS master files.
  99 For a description of possible values, see `vc-check-master-templates'."
 100   :type '(choice (const :tag "Use standard RCS file names"
 101                         '("%sRCS/%s,v" "%s%s,v" "%sRCS/%s"))
 102                  (repeat :tag "User-specified"
 103                          (choice string
 104                                  function)))
 105   :version "21.1"
 106   :group 'vc-rcs)
 107
 108 \f
 109 ;;; Properties of the backend
 110
 111 (defun vc-rcs-revision-granularity () 'file)
 112
 113 (defun vc-rcs-checkout-model (files)
 114   "RCS-specific version of `vc-checkout-model'."
 115   (let ((file (if (consp files) (car files) files))
 116         result)
 117     (when vc-consult-headers
 118       (vc-file-setprop file 'vc-checkout-model nil)
 119       (vc-rcs-consult-headers file)
 120       (setq result (vc-file-getprop file 'vc-checkout-model)))
 121     (or result
 122         (progn (vc-rcs-fetch-master-state file)
 123                (vc-file-getprop file 'vc-checkout-model)))))
 124
 125 ;;;
 126 ;;; State-querying functions
 127 ;;;
 128
 129 ;; The autoload cookie below places vc-rcs-registered directly into
 130 ;; loaddefs.el, so that vc-rcs.el does not need to be loaded for
 131 ;; every file that is visited.
 132 ;;;###autoload
 133 (progn
 134 (defun vc-rcs-registered (f) (vc-default-registered 'RCS f)))
 135
 136 (defun vc-rcs-state (file)
 137   "Implementation of `vc-state' for RCS."
 138   (if (not (vc-rcs-registered file))
 139       'unregistered
 140     (or (boundp 'vc-rcs-headers-result)
 141         (and vc-consult-headers
 142              (vc-rcs-consult-headers file)))
 143     (let ((state
 144            ;; vc-working-revision might not be known; in that case the
 145            ;; property is nil.  vc-rcs-fetch-master-state knows how to
 146            ;; handle that.
 147            (vc-rcs-fetch-master-state file
 148                                       (vc-file-getprop file
 149                                                        'vc-working-revision))))
 150       (if (not (eq state 'up-to-date))
 151           state
 152         (if (vc-rcs-workfile-unchanged-p file)
 153             'up-to-date
 154           (if (eq (vc-rcs-checkout-model (list file)) 'locking)
 155               'unlocked-changes
 156             'edited))))))
 157
 158 (autoload 'vc-expand-dirs "vc")
 159
 160 (defun vc-rcs-dir-status-files (dir files update-function)
 161   (if (not files) (setq files (vc-expand-dirs (list dir) 'RCS)))
 162   (let ((result nil))
 163     (dolist (file files)
 164       (let ((state (vc-state file))
 165             (frel (file-relative-name file)))
 166         (when (and (eq (vc-backend file) 'RCS)
 167                    (not (eq state 'up-to-date)))
 168           (push (list frel state) result))))
 169     (funcall update-function result)))
 170
 171 (defun vc-rcs-working-revision (file)
 172   "RCS-specific version of `vc-working-revision'."
 173   (or (and vc-consult-headers
 174            (vc-rcs-consult-headers file)
 175            (vc-file-getprop file 'vc-working-revision))
 176       (progn
 177         (vc-rcs-fetch-master-state file)
 178         (vc-file-getprop file 'vc-working-revision))))
 179
 180 (autoload 'vc-master-name "vc-filewise")
 181
 182 (defun vc-rcs-latest-on-branch-p (file &optional version)
 183   "Return non-nil if workfile version of FILE is the latest on its branch.
 184 When VERSION is given, perform check for that version."
 185   (unless version (setq version (vc-working-revision file)))
 186   (with-temp-buffer
 187     (string= version
 188              (if (vc-rcs-trunk-p version)
 189                  (progn
 190                    ;; Compare VERSION to the head version number.
 191                    (vc-insert-file (vc-master-name file) "^[0-9]")
 192                    (vc-parse-buffer "^head[ \t\n]+\\([^;]+\\);" 1))
 193                ;; If we are not on the trunk, we need to examine the
 194                ;; whole current branch.
 195                (vc-insert-file (vc-master-name file) "^desc")
 196                (vc-rcs-find-most-recent-rev (vc-branch-part version))))))
 197
 198 (defun vc-rcs-workfile-unchanged-p (file)
 199   "Has FILE remained unchanged since last checkout?"
 200   ;; Try to use rcsdiff --brief.  If rcsdiff does not understand that,
 201   ;; do a double take and remember the fact for the future
 202   (let* ((version (concat "-r" (vc-working-revision file)))
 203          (status (if (eq vc-rcsdiff-knows-brief 'no)
 204                      (vc-do-command "*vc*" 1 "rcsdiff" file version)
 205                    (vc-do-command "*vc*" 2 "rcsdiff" file "--brief" version))))
 206     (if (eq status 2)
 207         (if (not vc-rcsdiff-knows-brief)
 208             (setq vc-rcsdiff-knows-brief 'no
 209                   status (vc-do-command "*vc*" 1 "rcsdiff" file version))
 210           (error "rcsdiff failed"))
 211       (if (not vc-rcsdiff-knows-brief) (setq vc-rcsdiff-knows-brief 'yes)))
 212     ;; The workfile is unchanged if rcsdiff found no differences.
 213     (zerop status)))
 214
 215 \f
 216 ;;;
 217 ;;; State-changing functions
 218 ;;;
 219
 220 (defun vc-rcs-create-repo ()
 221   "Create a new RCS repository."
 222   ;; RCS is totally file-oriented, so all we have to do is make the directory.
 223   (make-directory "RCS"))
 224
 225 (autoload 'vc-switches "vc")
 226
 227 (defun vc-rcs-register (files &optional comment)
 228   "Register FILES into the RCS version-control system.
 229 Automatically retrieve a read-only version of the file with keywords expanded.
 230 COMMENT can be used to provide an initial description for each FILES.
 231 Passes either `vc-rcs-register-switches' or `vc-register-switches'
 232 to the RCS command."
 233   (let (subdir name)
 234     (dolist (file files)
 235       (and (not (file-exists-p
 236                  (setq subdir (expand-file-name "RCS"
 237                                                 (file-name-directory file)))))
 238            (not (directory-files (file-name-directory file)
 239                                  nil ".*,v$" t))
 240            (yes-or-no-p "Create RCS subdirectory? ")
 241            (make-directory subdir))
 242       (apply #'vc-do-command "*vc*" 0 "ci" file
 243              ;; if available, use the secure registering option
 244              (and (vc-rcs-release-p "5.6.4") "-i")
 245              "-u"
 246              ;; Some old MS-Windows ports of RCS crash when "ci -i" is
 247              ;; invoked without -t; indulge them.
 248              (concat "-t-" (or comment ""))
 249              (vc-switches 'RCS 'register))
 250       ;; parse output to find master file name and workfile version
 251       (with-current-buffer "*vc*"
 252         (goto-char (point-min))
 253         (if (not (setq name
 254                        (if (looking-at (concat "^\\(.*\\)  <--  "
 255                                                (file-name-nondirectory file)))
 256                            (match-string 1))))
 257             ;; if we couldn't find the master name,
 258             ;; run vc-rcs-registered to get it
 259             ;; (will be stored into the vc-master-name property)
 260             (vc-rcs-registered file)
 261           (vc-file-setprop file 'vc-master-name
 262                            (if (file-name-absolute-p name)
 263                                name
 264                              (expand-file-name
 265                               name
 266                               (file-name-directory file))))))
 267       (vc-file-setprop file 'vc-working-revision
 268                        (if (re-search-forward
 269                             "^initial revision: \\([0-9.]+\\).*\n"
 270                             nil t)
 271                            (match-string 1))))))
 272
 273 (defun vc-rcs-responsible-p (file)
 274   "Return non-nil if RCS thinks it would be responsible for registering FILE."
 275   ;; TODO: check for all the patterns in vc-rcs-master-templates
 276   (file-directory-p (expand-file-name "RCS"
 277                                       (if (file-directory-p file)
 278                                           file
 279                                         (file-name-directory file)))))
 280
 281 (defun vc-rcs-receive-file (file rev)
 282   "Implementation of receive-file for RCS."
 283   (let ((checkout-model (vc-rcs-checkout-model (list file))))
 284     (vc-rcs-register file "")
 285     (when (eq checkout-model 'implicit)
 286       (vc-rcs-set-non-strict-locking file))
 287     (vc-rcs-set-default-branch file (concat rev ".1"))))
 288
 289 (defun vc-rcs-unregister (file)
 290   "Unregister FILE from RCS.
 291 If this leaves the RCS subdirectory empty, ask the user
 292 whether to remove it."
 293   (unless (memq (vc-state file) '(nil unregistered))
 294     (let* ((master (vc-master-name file))
 295            (dir (file-name-directory master))
 296            (backup-info (find-backup-file-name master)))
 297       (if (not backup-info)
 298           (delete-file master)
 299         (rename-file master (car backup-info) 'ok-if-already-exists)
 300         (dolist (f (cdr backup-info)) (ignore-errors (delete-file f))))
 301       (and (string= (file-name-nondirectory (directory-file-name dir)) "RCS")
 302            ;; check whether RCS dir is empty, i.e. it does not
 303            ;; contain any files except "." and ".."
 304            (not (directory-files dir nil
 305                                  "^\\([^.]\\|\\.[^.]\\|\\.\\.[^.]\\).*"))
 306            (yes-or-no-p (format "Directory %s is empty; remove it? " dir))
 307            (delete-directory dir)))))
 308
 309 (defun vc-rcs-checkin (files comment &optional rev)
 310   "RCS-specific version of `vc-backend-checkin'."
 311   (let ((switches (vc-switches 'RCS 'checkin)))
 312     ;; Now operate on the files
 313     (dolist (file (vc-expand-dirs files 'RCS))
 314       (let ((old-version (vc-working-revision file)) new-version
 315             (default-branch (vc-file-getprop file 'vc-rcs-default-branch)))
 316         ;; Force branch creation if an appropriate
 317         ;; default branch has been set.
 318         (and (not rev)
 319              default-branch
 320              (string-match (concat "^" (regexp-quote old-version) "\\.")
 321                            default-branch)
 322              (setq rev default-branch)
 323              (setq switches (cons "-f" switches)))
 324         (if (and (not rev) old-version)
 325             (setq rev (vc-branch-part old-version)))
 326         (apply #'vc-do-command "*vc*" 0 "ci" (vc-master-name file)
 327                ;; if available, use the secure check-in option
 328                (and (vc-rcs-release-p "5.6.4") "-j")
 329                (concat "-u" rev)
 330                (concat "-m" comment)
 331                switches)
 332         (vc-file-setprop file 'vc-working-revision nil)
 333
 334         ;; determine the new workfile version
 335         (set-buffer "*vc*")
 336         (goto-char (point-min))
 337         (when (or (re-search-forward
 338                    "new revision: \\([0-9.]+\\);" nil t)
 339                   (re-search-forward
 340                    "reverting to previous revision \\([0-9.]+\\)" nil t))
 341           (setq new-version (match-string 1))
 342           (vc-file-setprop file 'vc-working-revision new-version))
 343
 344         ;; if we got to a different branch, adjust the default
 345         ;; branch accordingly
 346         (cond
 347          ((and old-version new-version
 348                (not (string= (vc-branch-part old-version)
 349                              (vc-branch-part new-version))))
 350           (vc-rcs-set-default-branch file
 351                                      (if (vc-rcs-trunk-p new-version) nil
 352                                        (vc-branch-part new-version)))
 353           ;; If this is an old (pre-1992!) RCS release, we might have
 354           ;; to remove a remaining lock.
 355           (if (not (vc-rcs-release-p "5.6.2"))
 356               ;; exit status of 1 is also accepted.
 357               ;; It means that the lock was removed before.
 358               (vc-do-command "*vc*" 1 "rcs" (vc-master-name file)
 359                              (concat "-u" old-version)))))))))
 360
 361 (defun vc-rcs-find-revision (file rev buffer)
 362   (apply #'vc-do-command
 363          (or buffer "*vc*") 0 "co" (vc-master-name file)
 364          "-q" ;; suppress diagnostic output
 365          (concat "-p" rev)
 366          (vc-switches 'RCS 'checkout)))
 367
 368 (defun vc-rcs-checkout (file &optional rev)
 369   "Retrieve a copy of a saved version of FILE.  If FILE is a directory,
 370 attempt the checkout for all registered files beneath it."
 371   (if (file-directory-p file)
 372       (mapc 'vc-rcs-checkout (vc-expand-dirs (list file) 'RCS))
 373     (let ((file-buffer (get-file-buffer file))
 374           switches)
 375       (message "Checking out %s..." file)
 376       (save-excursion
 377         ;; Change buffers to get local value of vc-checkout-switches.
 378         (if file-buffer (set-buffer file-buffer))
 379         (setq switches (vc-switches 'RCS 'checkout))
 380         ;; Save this buffer's default-directory
 381         ;; and use save-excursion to make sure it is restored
 382         ;; in the same buffer it was saved in.
 383         (let ((default-directory default-directory))
 384           (save-excursion
 385             ;; Adjust the default-directory so that the check-out creates
 386             ;; the file in the right place.
 387             (setq default-directory (file-name-directory file))
 388             (let (new-version)
 389               ;; if we should go to the head of the trunk,
 390               ;; clear the default branch first
 391               (and rev (string= rev "")
 392                    (vc-rcs-set-default-branch file nil))
 393               ;; now do the checkout
 394               (apply #'vc-do-command
 395                      "*vc*" 0 "co" (vc-master-name file)
 396                      ;; If locking is not strict, force to overwrite
 397                      ;; the writable workfile.
 398                      (if (eq (vc-rcs-checkout-model (list file)) 'implicit) "-f")
 399                      "-l"
 400                      (if (stringp rev)
 401                          ;; a literal revision was specified
 402                          (concat "-r" rev)
 403                        (let ((workrev (vc-working-revision file)))
 404                          (if workrev
 405                              (concat "-r"
 406                                      (if (not rev)
 407                                          ;; no revision specified:
 408                                          ;; use current workfile version
 409                                          workrev
 410                                        ;; REV is t ...
 411                                        (if (not (vc-rcs-trunk-p workrev))
 412                                            ;; ... go to head of current branch
 413                                            (vc-branch-part workrev)
 414                                          ;; ... go to head of trunk
 415                                          (vc-rcs-set-default-branch file
 416                                                                   nil)
 417                                        ""))))))
 418                    switches)
 419             ;; determine the new workfile version
 420             (with-current-buffer "*vc*"
 421               (setq new-version
 422                     (vc-parse-buffer "^revision \\([0-9.]+\\).*\n" 1)))
 423             (vc-file-setprop file 'vc-working-revision new-version)
 424             ;; if necessary, adjust the default branch
 425             (and rev (not (string= rev ""))
 426                  (vc-rcs-set-default-branch
 427                   file
 428                   (if (vc-rcs-latest-on-branch-p file new-version)
 429                       (if (vc-rcs-trunk-p new-version) nil
 430                         (vc-branch-part new-version))
 431                     new-version)))))
 432         (message "Checking out %s...done" file))))))
 433
 434 (defun vc-rcs-revert (file &optional _contents-done)
 435   "Revert FILE to the version it was based on.  If FILE is a directory,
 436 revert all registered files beneath it."
 437   (if (file-directory-p file)
 438       (mapc 'vc-rcs-revert (vc-expand-dirs (list file) 'RCS))
 439     (vc-do-command "*vc*" 0 "co" (vc-master-name file) "-f"
 440                    (concat (if (eq (vc-state file) 'edited) "-u" "-r")
 441                            (vc-working-revision file)))))
 442
 443 (defun vc-rcs-merge-file (file)
 444   "Accept a file merge request, prompting for revisions."
 445   (let* ((first-revision
 446         (vc-read-revision
 447          (concat "Merge " file " from branch or revision: ")
 448          (list file)
 449          'RCS))
 450         second-revision)
 451     (cond
 452      ((string= first-revision "")
 453       (error "A starting RCS revision is required"))
 454      (t
 455       (if (not (vc-branch-p first-revision))
 456          (setq second-revision
 457                (vc-read-revision
 458                 "Second RCS revision: "
 459                 (list file) 'RCS nil
 460                 (concat (vc-branch-part first-revision) ".")))
 461        ;; We want to merge an entire branch.  Set revisions
 462        ;; accordingly, so that vc-rcs-merge understands us.
 463        (setq second-revision first-revision)
 464        ;; first-revision must be the starting point of the branch
 465        (setq first-revision (vc-branch-part first-revision)))))
 466     (vc-rcs-merge file first-revision second-revision)))
 467
 468 (defun vc-rcs-merge (file first-version &optional second-version)
 469   "Merge changes into current working copy of FILE.
 470 The changes are between FIRST-VERSION and SECOND-VERSION."
 471   (vc-do-command "*vc*" 1 "rcsmerge" (vc-master-name file)
 472                  "-kk"                  ; ignore keyword conflicts
 473                  (concat "-r" first-version)
 474                  (if second-version (concat "-r" second-version))))
 475
 476 (defun vc-rcs-steal-lock (file &optional rev)
 477   "Steal the lock on the current workfile for FILE and revision REV.
 478 If FILE is a directory, steal the lock on all registered files beneath it.
 479 Needs RCS 5.6.2 or later for -M."
 480   (if (file-directory-p file)
 481       (mapc 'vc-rcs-steal-lock (vc-expand-dirs (list file) 'RCS))
 482     (vc-do-command "*vc*" 0 "rcs" (vc-master-name file) "-M" (concat "-u" rev))
 483     ;; Do a real checkout after stealing the lock, so that we see
 484     ;; expanded headers.
 485     (vc-do-command "*vc*" 0 "co" (vc-master-name file) "-f" (concat "-l" rev))
 486     ;; Must clear any headers here because they wouldn't
 487     ;; show that the file is locked now.
 488     (let* ((filename (or file buffer-file-name))
 489            (visited (find-buffer-visiting filename)))
 490       (if visited
 491           (let ((context (vc-buffer-context)))
 492             ;; save-excursion may be able to relocate point and mark
 493             ;; properly.  If it fails, vc-restore-buffer-context
 494             ;; will give it a second try.
 495             (save-excursion
 496               (vc-rcs-clear-headers))
 497             (vc-restore-buffer-context context))
 498         (set-buffer (find-file-noselect filename))
 499         (vc-rcs-clear-headers)
 500         (kill-buffer filename)))))
 501
 502 (defun vc-rcs-modify-change-comment (files rev comment)
 503   "Modify the change comments change on FILES on a specified REV.  If FILE is a
 504 directory the operation is applied to all registered files beneath it."
 505   (dolist (file (vc-expand-dirs files 'RCS))
 506     (vc-do-command "*vc*" 0 "rcs" (vc-master-name file)
 507                    (concat "-m" rev ":" comment))))
 508
 509 \f
 510 ;;;
 511 ;;; History functions
 512 ;;;
 513
 514 (defun vc-rcs-print-log-cleanup ()
 515   (let ((inhibit-read-only t))
 516     (goto-char (point-max))
 517     (forward-line -1)
 518     (while (looking-at "=*\n")
 519       (delete-char (- (match-end 0) (match-beginning 0)))
 520       (forward-line -1))
 521     (goto-char (point-min))
 522     (when (looking-at "[\b\t\n\v\f\r ]+")
 523       (delete-char (- (match-end 0) (match-beginning 0))))))
 524
 525 (defun vc-rcs-print-log (files buffer &optional _shortlog
 526                                _start-revision-ignored limit)
 527   "Print commit log associated with FILES into specified BUFFER.
 528 Remaining arguments are ignored.
 529 If FILE is a directory the operation is applied to all registered
 530 files beneath it."
 531   (vc-do-command (or buffer "*vc*") 0 "rlog"
 532                  (mapcar 'vc-master-name (vc-expand-dirs files 'RCS)))
 533   (with-current-buffer (or buffer "*vc*")
 534     (vc-rcs-print-log-cleanup))
 535   (when limit 'limit-unsupported))
 536
 537 (defun vc-rcs-diff (files &optional oldvers newvers buffer async)
 538   "Get a difference report using RCS between two sets of files."
 539   (apply #'vc-do-command (or buffer "*vc-diff*")
 540          (if async 'async 1)
 541          "rcsdiff" (vc-expand-dirs files 'RCS)
 542          (append (list "-q"
 543                        (and oldvers (concat "-r" oldvers))
 544                        (and newvers (concat "-r" newvers)))
 545                  (vc-switches 'RCS 'diff))))
 546
 547 (defun vc-rcs-find-admin-dir (file)
 548   "Return the administrative directory of FILE."
 549   (vc-find-root file "RCS"))
 550
 551 (defun vc-rcs-comment-history (file)
 552   "Return a string with all log entries stored in BACKEND for FILE."
 553   (with-current-buffer "*vc*"
 554     ;; Has to be written this way, this function is used by the CVS backend too
 555     (vc-call-backend (vc-backend file) 'print-log (list file))
 556     ;; Remove cruft
 557     (let ((separator (concat "^-+\nrevision [0-9.]+\ndate: .*\n"
 558                              "\\(branches: .*;\n\\)?"
 559                              "\\(\\*\\*\\* empty log message \\*\\*\\*\n\\)?")))
 560       (goto-char (point-max)) (forward-line -1)
 561       (while (looking-at "=*\n")
 562         (delete-char (- (match-end 0) (match-beginning 0)))
 563         (forward-line -1))
 564       (goto-char (point-min))
 565       (if (looking-at "[\b\t\n\v\f\r ]+")
 566           (delete-char (- (match-end 0) (match-beginning 0))))
 567       (goto-char (point-min))
 568       (re-search-forward separator nil t)
 569       (delete-region (point-min) (point))
 570       (while (re-search-forward separator nil t)
 571         (delete-region (match-beginning 0) (match-end 0))))
 572     ;; Return the de-crufted comment list
 573     (buffer-string)))
 574
 575 (defun vc-rcs-annotate-command (file buffer &optional revision)
 576   "Annotate FILE, inserting the results in BUFFER.
 577 Optional arg REVISION is a revision to annotate from."
 578   (vc-setup-buffer buffer)
 579   ;; Aside from the "head revision on the trunk", the instructions for
 580   ;; each revision on the trunk are an ordered list of kill and insert
 581   ;; commands necessary to go from the chronologically-following
 582   ;; revision to this one.  That is, associated with revision N are
 583   ;; edits that applied to revision N+1 would result in revision N.
 584   ;;
 585   ;; On a branch, however, (some) things are inverted: the commands
 586   ;; listed are those necessary to go from the chronologically-preceding
 587   ;; revision to this one.  That is, associated with revision N are
 588   ;; edits that applied to revision N-1 would result in revision N.
 589   ;;
 590   ;; So, to get per-line history info, we apply reverse-chronological
 591   ;; edits, starting with the head revision on the trunk, all the way
 592   ;; back through the initial revision (typically "1.1" or similar),
 593   ;; then apply forward-chronological edits -- keeping track of which
 594   ;; revision is associated with each inserted line -- until we reach
 595   ;; the desired revision for display (which may be either on the trunk
 596   ;; or on a branch).
 597   (let* ((tree (with-temp-buffer
 598                  (insert-file-contents (vc-rcs-registered file))
 599                  (vc-rcs-parse)))
 600          (revisions (cdr (assq 'revisions tree)))
 601          ;; The revision N whose instructions we currently are processing.
 602          (cur (cdr (assq 'head (cdr (assq 'headers tree)))))
 603          ;; Alist from the parse tree for N.
 604          (meta (cdr (assoc cur revisions)))
 605          ;; Point and temporary string, respectively.
 606          p s
 607          ;; "Next-branch list".  Nil means the desired revision to
 608          ;; display lives on the trunk.  Non-nil means it lives on a
 609          ;; branch, in which case the value is a list of revision pairs
 610          ;; (PARENT . CHILD), the first PARENT being on the trunk, that
 611          ;; links each series of revisions in the path from the initial
 612          ;; revision to the desired revision to display.
 613          nbls
 614          ;; "Path-accumulate-predicate plus revision/date/author".
 615          ;; Until set, forward-chronological edits are not accumulated.
 616          ;; Once set, its value (updated every revision) is used for
 617          ;; the text property `:vc-rcs-r/d/a' for inserts during
 618          ;; processing of forward-chronological instructions for N.
 619          ;; See internal func `r/d/a'.
 620          prda
 621          ;; List of forward-chronological instructions, each of the
 622          ;; form: (POS . ACTION), where POS is a buffer position.  If
 623          ;; ACTION is a string, it is inserted, otherwise it is taken as
 624          ;; the number of characters to be deleted.
 625          path
 626          ;; N+1.  When `cur' is "", this is the initial revision.
 627          pre)
 628     (unless revision
 629       (setq revision cur))
 630     (unless (assoc revision revisions)
 631       (error "No such revision: %s" revision))
 632     ;; Find which branches (if any) must be included in the edits.
 633     (let ((par revision)
 634           bpt kids)
 635       (while (setq bpt (vc-branch-part par)
 636                    par (vc-branch-part bpt))
 637         (setq kids (cdr (assq 'branches (cdr (assoc par revisions)))))
 638         ;; A branchpoint may have multiple children.  Find the right one.
 639         (while (not (string= bpt (vc-branch-part (car kids))))
 640           (setq kids (cdr kids)))
 641         (push (cons par (car kids)) nbls)))
 642     ;; Start with the full text.
 643     (set-buffer buffer)
 644     (insert (cdr (assq 'text meta)))
 645     ;; Apply reverse-chronological edits on the trunk, computing and
 646     ;; accumulating forward-chronological edits after some point, for
 647     ;; later.
 648     (cl-flet ((r/d/a () (vector pre
 649                                 (cdr (assq 'date meta))
 650                                 (cdr (assq 'author meta)))))
 651       (while (when (setq pre cur cur (cdr (assq 'next meta)))
 652                (not (string= "" cur)))
 653         (setq
 654          ;; Start accumulating the forward-chronological edits when N+1
 655          ;; on the trunk is either the desired revision to display, or
 656          ;; the appropriate branchpoint for it.  Do this before
 657          ;; updating `meta' since `r/d/a' uses N+1's `meta' value.
 658          prda (when (or prda (string= (if nbls (caar nbls) revision) pre))
 659                 (r/d/a))
 660          meta (cdr (assoc cur revisions)))
 661         ;; Edits in the parse tree specify a line number (in the buffer
 662         ;; *BEFORE* editing occurs) to start from, but line numbers
 663         ;; change as a result of edits.  To DTRT, we apply edits in
 664         ;; order of descending buffer position so that edits further
 665         ;; down in the buffer occur first w/o corrupting specified
 666         ;; buffer positions of edits occurring towards the beginning of
 667         ;; the buffer.  In this way we avoid using markers.  A pleasant
 668         ;; property of this approach is ability to push instructions
 669         ;; onto `path' directly, w/o need to maintain rev boundaries.
 670         (dolist (insn (cdr (assq :insn meta)))
 671           (goto-char (point-min))
 672           (forward-line (1- (pop insn)))
 673           (setq p (point))
 674           (pcase (pop insn)
 675             (`k (setq s (buffer-substring-no-properties
 676                          p (progn (forward-line (car insn))
 677                                   (point))))
 678                 (when prda
 679                   (push `(,p . ,(propertize s :vc-rcs-r/d/a prda)) path))
 680                 (delete-region p (point)))
 681             (`i (setq s (car insn))
 682                 (when prda
 683                   (push `(,p . ,(length s)) path))
 684                 (insert s)))))
 685       ;; For the initial revision, setting `:vc-rcs-r/d/a' directly is
 686       ;; equivalent to pushing an insert instruction (of the entire buffer
 687       ;; contents) onto `path' then erasing the buffer, but less wasteful.
 688       (put-text-property (point-min) (point-max) :vc-rcs-r/d/a (r/d/a))
 689       ;; Now apply the forward-chronological edits for the trunk.
 690       (dolist (insn path)
 691         (goto-char (pop insn))
 692         (if (stringp insn)
 693             (insert insn)
 694           (delete-char insn)))
 695       ;; Now apply the forward-chronological edits (directly from the
 696       ;; parse-tree) for the branch(es), if necessary.  We re-use vars
 697       ;; `pre' and `meta' for the sake of internal func `r/d/a'.
 698       (while nbls
 699         (setq pre (cdr (pop nbls)))
 700         (while (progn
 701                  (setq meta (cdr (assoc pre revisions))
 702                        prda nil)
 703                  (dolist (insn (cdr (assq :insn meta)))
 704                    (goto-char (point-min))
 705                    (forward-line (1- (pop insn)))
 706                    (pcase (pop insn)
 707                      (`k (delete-region
 708                           (point) (progn (forward-line (car insn))
 709                                          (point))))
 710                      (`i (insert (propertize
 711                                   (car insn)
 712                                   :vc-rcs-r/d/a
 713                                   (or prda (setq prda (r/d/a))))))))
 714                  (prog1 (not (string= (if nbls (caar nbls) revision) pre))
 715                    (setq pre (cdr (assq 'next meta)))))))))
 716   ;; Lastly, for each line, insert at bol nicely-formatted history info.
 717   ;; We do two passes to collect summary information used to minimize
 718   ;; the annotation's usage of screen real-estate: (1) Consider rendered
 719   ;; width of revision plus author together as a unit; and (2) Omit
 720   ;; author entirely if all authors are the same as the user.
 721   (let ((ht (make-hash-table :test 'eq))
 722         (me (user-login-name))
 723         (maxw 0)
 724         (all-me t)
 725         rda w a)
 726     (goto-char (point-max))
 727     (while (not (bobp))
 728       (forward-line -1)
 729       (setq rda (get-text-property (point) :vc-rcs-r/d/a))
 730       (unless (gethash rda ht)
 731         (setq a (aref rda 2)
 732               all-me (and all-me (string= a me)))
 733         (puthash rda (setq w (+ (length (aref rda 0))
 734                                 (length a)))
 735                  ht)
 736         (setq maxw (max w maxw))))
 737     (let ((padding (make-string maxw 32)))
 738       (cl-flet ((pad (w) (substring-no-properties padding w))
 739                 (render (rda &rest ls)
 740                         (propertize
 741                          (apply #'concat
 742                                 (format-time-string "%Y-%m-%d" (aref rda 1))
 743                                 "  "
 744                                 (aref rda 0)
 745                                 ls)
 746                          :vc-annotate-prefix t
 747                          :vc-rcs-r/d/a rda)))
 748         (maphash
 749          (if all-me
 750              (lambda (rda w)
 751                (puthash rda (render rda (pad w) ": ") ht))
 752            (lambda (rda w)
 753              (puthash rda (render rda " " (pad w) " " (aref rda 2) ": ") ht)))
 754          ht)))
 755     (while (not (eobp))
 756       (insert (gethash (get-text-property (point) :vc-rcs-r/d/a) ht))
 757       (forward-line 1))))
 758
 759 (declare-function vc-annotate-convert-time "vc-annotate" (&optional time))
 760
 761 (defun vc-rcs-annotate-current-time ()
 762   "Return the current time, based at midnight of the current day, and
 763 encoded as fractional days."
 764   (vc-annotate-convert-time
 765    (apply #'encode-time 0 0 0 (nthcdr 3 (decode-time)))))
 766
 767 (defun vc-rcs-annotate-time ()
 768   "Return the time of the next annotation (as fraction of days)
 769 systime, or nil if there is none.  Also, reposition point."
 770   (unless (eobp)
 771     (prog1 (vc-annotate-convert-time
 772             (aref (get-text-property (point) :vc-rcs-r/d/a) 1))
 773       (goto-char (next-single-property-change (point) :vc-annotate-prefix)))))
 774
 775 (defun vc-rcs-annotate-extract-revision-at-line ()
 776   (aref (get-text-property (point) :vc-rcs-r/d/a) 0))
 777
 778 \f
 779 ;;;
 780 ;;; Tag system
 781 ;;;
 782
 783 (autoload 'vc-tag-precondition "vc")
 784 (declare-function vc-file-tree-walk "vc" (dirname func &rest args))
 785
 786 (defun vc-rcs-create-tag (dir name branchp)
 787   (when branchp
 788     (error "RCS backend does not support module branches"))
 789   (let ((result (vc-tag-precondition dir)))
 790     (if (stringp result)
 791         (error "File %s is not up-to-date" result)
 792       (vc-file-tree-walk
 793        dir
 794        (lambda (f)
 795          (vc-do-command "*vc*" 0 "rcs" (vc-master-name f) (concat "-n" name ":")))))))
 796
 797 \f
 798 ;;;
 799 ;;; Miscellaneous
 800 ;;;
 801
 802 (defun vc-rcs-trunk-p (rev)
 803   "Return t if REV is a revision on the trunk."
 804   (not (eq nil (string-match "\\`[0-9]+\\.[0-9]+\\'" rev))))
 805
 806 (defun vc-rcs-minor-part (rev)
 807   "Return the minor revision number of a revision number REV."
 808   (string-match "[0-9]+\\'" rev)
 809   (substring rev (match-beginning 0) (match-end 0)))
 810
 811 (defun vc-rcs-previous-revision (_file rev)
 812   "Return the revision number immediately preceding REV for FILE,
 813 or nil if there is no previous revision.  This default
 814 implementation works for MAJOR.MINOR-style revision numbers as
 815 used by RCS and CVS."
 816   (let ((branch (vc-branch-part rev))
 817         (minor-num (string-to-number (vc-rcs-minor-part rev))))
 818     (when branch
 819       (if (> minor-num 1)
 820           ;; revision does probably not start a branch or release
 821           (concat branch "." (number-to-string (1- minor-num)))
 822         (if (vc-rcs-trunk-p rev)
 823             ;; we are at the beginning of the trunk --
 824             ;; don't know anything to return here
 825             nil
 826           ;; we are at the beginning of a branch --
 827           ;; return revision of starting point
 828           (vc-branch-part branch))))))
 829
 830 (defun vc-rcs-next-revision (file rev)
 831   "Return the revision number immediately following REV for FILE,
 832 or nil if there is no next revision.  This default implementation
 833 works for MAJOR.MINOR-style revision numbers as used by RCS
 834 and CVS."
 835   (when (not (string= rev (vc-working-revision file)))
 836     (let ((branch (vc-branch-part rev))
 837           (minor-num (string-to-number (vc-rcs-minor-part rev))))
 838       (concat branch "." (number-to-string (1+ minor-num))))))
 839
 840 ;; You might think that this should be distributed with RCS, but
 841 ;; apparently not.  CVS sometimes provides a version of it.
 842 ;; http://lists.gnu.org/archive/html/emacs-devel/2014-05/msg00288.html
 843 (defvar vc-rcs-rcs2log-program
 844   (let (exe)
 845     (cond ((file-executable-p
 846             (setq exe (expand-file-name "rcs2log" exec-directory)))
 847            exe)
 848           ;; In the unlikely event that someone is running an
 849           ;; uninstalled Emacs and wants to do something RCS-related.
 850           ((file-executable-p
 851             (setq exe (expand-file-name "lib-src/rcs2log" source-directory)))
 852            exe)
 853           (t "rcs2log")))
 854   "Path to the `rcs2log' program (normally in `exec-directory').")
 855
 856 (autoload 'vc-buffer-sync "vc-dispatcher")
 857
 858 (defun vc-rcs-update-changelog (files)
 859   "Default implementation of update-changelog.
 860 Uses `rcs2log' which only works for RCS and CVS."
 861   ;; FIXME: We (c|sh)ould add support for cvs2cl
 862   (let ((odefault default-directory)
 863         (changelog (find-change-log))
 864         ;; Presumably not portable to non-Unixy systems, along with rcs2log:
 865         (tempfile (make-temp-file
 866                    (expand-file-name "vc"
 867                                      (or small-temporary-file-directory
 868                                          temporary-file-directory))))
 869         (login-name (or user-login-name
 870                         (format "uid%d" (number-to-string (user-uid)))))
 871         (full-name (or add-log-full-name
 872                        (user-full-name)
 873                        (user-login-name)
 874                        (format "uid%d" (number-to-string (user-uid)))))
 875         (mailing-address (or add-log-mailing-address
 876                              user-mail-address)))
 877     (find-file-other-window changelog)
 878     (barf-if-buffer-read-only)
 879     (vc-buffer-sync)
 880     (undo-boundary)
 881     (goto-char (point-min))
 882     (push-mark)
 883     (message "Computing change log entries...")
 884     (message "Computing change log entries... %s"
 885              (unwind-protect
 886                  (progn
 887                    (setq default-directory odefault)
 888                    (if (eq 0 (apply #'call-process vc-rcs-rcs2log-program
 889                                     nil (list t tempfile) nil
 890                                     "-c" changelog
 891                                     "-u" (concat login-name
 892                                                  "\t" full-name
 893                                                  "\t" mailing-address)
 894                                     (mapcar
 895                                      (lambda (f)
 896                                        (file-relative-name
 897                                         (expand-file-name f odefault)))
 898                                      files)))
 899                        "done"
 900                      (pop-to-buffer (get-buffer-create "*vc*"))
 901                      (erase-buffer)
 902                      (insert-file-contents tempfile)
 903                      "failed"))
 904                (setq default-directory (file-name-directory changelog))
 905                (delete-file tempfile)))))
 906
 907 (defun vc-rcs-check-headers ()
 908   "Check if the current file has any headers in it."
 909   (save-excursion
 910     (goto-char (point-min))
 911          (re-search-forward "\\$[A-Za-z\300-\326\330-\366\370-\377]+\
 912 \\(: [\t -#%-\176\240-\377]*\\)?\\$" nil t)))
 913
 914 (defun vc-rcs-clear-headers ()
 915   "Clear RCS header value parts."
 916   (let ((case-fold-search nil))
 917     (goto-char (point-min))
 918     (while (re-search-forward
 919             (concat "\\$\\(Author\\|Date\\|Header\\|Id\\|Locker\\|Name\\|"
 920                     "RCSfile\\|Revision\\|Source\\|State\\): [^$\n]+\\$")
 921             nil t)
 922       (replace-match "$\\1$"))))
 923
 924 (autoload 'vc-rename-master "vc-filewise")
 925
 926 (defun vc-rcs-rename-file (old new)
 927   ;; Just move the master file (using vc-rcs-master-templates).
 928   (vc-rename-master (vc-master-name old) new vc-rcs-master-templates))
 929
 930 (defun vc-rcs-find-file-hook ()
 931   ;; If the file is locked by some other user, make
 932   ;; the buffer read-only.  Like this, even root
 933   ;; cannot modify a file that someone else has locked.
 934   (and (stringp (vc-state buffer-file-name 'RCS))
 935        (setq buffer-read-only t)))
 936
 937 \f
 938 ;;;
 939 ;;; Internal functions
 940 ;;;
 941
 942 (defun vc-rcs-workfile-is-newer (file)
 943   "Return non-nil if FILE is newer than its RCS master.
 944 This likely means that FILE has been changed with respect
 945 to its master version."
 946   (let ((file-time (nth 5 (file-attributes file)))
 947         (master-time (nth 5 (file-attributes (vc-master-name file)))))
 948     (or (> (nth 0 file-time) (nth 0 master-time))
 949         (and (= (nth 0 file-time) (nth 0 master-time))
 950              (> (nth 1 file-time) (nth 1 master-time))))))
 951
 952 (defun vc-rcs-find-most-recent-rev (branch)
 953   "Find most recent revision on BRANCH."
 954   (goto-char (point-min))
 955   (let ((latest-rev -1) value)
 956     (while (re-search-forward (concat "^\\(" (regexp-quote branch)
 957                                       "\\.\\([0-9]+\\)\\)\ndate[ \t]+[0-9.]+;")
 958                               nil t)
 959       (let ((rev (string-to-number (match-string 2))))
 960         (when (< latest-rev rev)
 961           (setq latest-rev rev)
 962           (setq value (match-string 1)))))
 963     (or value
 964         (vc-branch-part branch))))
 965
 966 (defun vc-rcs-fetch-master-state (file &optional working-revision)
 967   "Compute the master file's idea of the state of FILE.
 968 If a WORKING-REVISION is given, compute the state of that version,
 969 otherwise determine the workfile version based on the master file.
 970 This function sets the properties `vc-working-revision' and
 971 `vc-checkout-model' to their correct values, based on the master
 972 file."
 973   (when (and (file-regular-p file) (vc-master-name file))
 974     (with-temp-buffer
 975       (if (or (not (vc-insert-file (vc-master-name file) "^[0-9]"))
 976               (progn (goto-char (point-min))
 977                      (not (looking-at "^head[ \t\n]+[^;]+;$"))))
 978           (error "File %s is not an RCS master file" (vc-master-name file)))
 979       (let ((workfile-is-latest nil)
 980             (default-branch (vc-parse-buffer "^branch[ \t\n]+\\([^;]*\\);" 1)))
 981         (vc-file-setprop file 'vc-rcs-default-branch default-branch)
 982         (unless working-revision
 983           ;; Workfile version not known yet.  Determine that first.  It
 984           ;; is either the head of the trunk, the head of the default
 985           ;; branch, or the "default branch" itself, if that is a full
 986           ;; revision number.
 987           (cond
 988            ;; no default branch
 989            ((or (not default-branch) (string= "" default-branch))
 990             (setq working-revision
 991                   (vc-parse-buffer "^head[ \t\n]+\\([^;]+\\);" 1))
 992             (setq workfile-is-latest t))
 993            ;; default branch is actually a revision
 994            ((string-match "^[0-9]+\\.[0-9]+\\(\\.[0-9]+\\.[0-9]+\\)*$"
 995                           default-branch)
 996             (setq working-revision default-branch))
 997            ;; else, search for the head of the default branch
 998            (t (vc-insert-file (vc-master-name file) "^desc")
 999               (setq working-revision
1000                     (vc-rcs-find-most-recent-rev default-branch))
1001               (setq workfile-is-latest t)))
1002           (vc-file-setprop file 'vc-working-revision working-revision))
1003         ;; Check strict locking
1004         (goto-char (point-min))
1005         (vc-file-setprop file 'vc-checkout-model
1006                          (if (re-search-forward ";[ \t\n]*strict;" nil t)
1007                              'locking 'implicit))
1008         ;; Compute state of workfile version
1009         (goto-char (point-min))
1010         (let ((locking-user
1011                (vc-parse-buffer (concat "^locks[ \t\n]+[^;]*[ \t\n]+\\([^:]+\\):"
1012                                         (regexp-quote working-revision)
1013                                         "[^0-9.]")
1014                                 1)))
1015           (cond
1016            ;; not locked
1017            ((not locking-user)
1018             (if (or workfile-is-latest
1019                     (vc-rcs-latest-on-branch-p file working-revision))
1020                 ;; workfile version is latest on branch
1021                 'up-to-date
1022               ;; workfile version is not latest on branch
1023               'needs-update))
1024            ;; locked by the calling user
1025            ((and (stringp locking-user)
1026                  (string= locking-user (vc-user-login-name file)))
1027             ;; Don't call `vc-rcs-checkout-model' to avoid inf-looping.
1028             (if (or (eq (vc-file-getprop file 'vc-checkout-model) 'locking)
1029                     workfile-is-latest
1030                     (vc-rcs-latest-on-branch-p file working-revision))
1031                 'edited
1032               ;; Locking is not used for the file, but the owner does
1033               ;; have a lock, and there is a higher version on the current
1034               ;; branch.  Not sure if this can occur, and if it is right
1035               ;; to use `needs-merge' in this case.
1036               'needs-merge))
1037            ;; locked by somebody else
1038            ((stringp locking-user)
1039             locking-user)
1040            (t
1041             (error "Error getting state of RCS file"))))))))
1042
1043 (defun vc-rcs-consult-headers (file)
1044   "Search for RCS headers in FILE, and set properties accordingly.
1045
1046 Returns: nil            if no headers were found
1047          'rev           if a workfile revision was found
1048          'rev-and-lock  if revision and lock info was found"
1049   (cond
1050    ((not (get-file-buffer file)) nil)
1051    ((let (status version)
1052       (with-current-buffer (get-file-buffer file)
1053         (save-excursion
1054           (goto-char (point-min))
1055           (cond
1056            ;; search for $Id or $Header
1057            ;; -------------------------
1058            ;; The `\ 's below avoid an RCS 5.7 bug when checking in this file.
1059            ((or (and (search-forward "$Id\ : " nil t)
1060                      (looking-at "[^ ]+ \\([0-9.]+\\) "))
1061                 (and (progn (goto-char (point-min))
1062                             (search-forward "$Header\ : " nil t))
1063                      (looking-at "[^ ]+ \\([0-9.]+\\) ")))
1064             (goto-char (match-end 0))
1065             ;; if found, store the revision number ...
1066             (setq version (match-string-no-properties 1))
1067             ;; ... and check for the locking state
1068             (cond
1069              ((looking-at
1070                (concat "[0-9]+[/-][01][0-9][/-][0-3][0-9] "              ; date
1071                  "[0-2][0-9]:[0-5][0-9]+:[0-6][0-9]+\\([+-][0-9:]+\\)? " ; time
1072                        "[^ ]+ [^ ]+ "))                        ; author & state
1073               (goto-char (match-end 0)) ; [0-6] in regexp handles leap seconds
1074               (cond
1075                ;; unlocked revision
1076                ((looking-at "\\$")
1077                 ;;(setq locking-user 'none)
1078                 (setq status 'rev-and-lock))
1079                ;; revision is locked by some user
1080                ((looking-at "\\([^ ]+\\) \\$")
1081                 ;;(setq locking-user (match-string-no-properties 1))
1082                 (setq status 'rev-and-lock))
1083                ;; everything else: false
1084                (nil)))
1085              ;; unexpected information in
1086              ;; keyword string --> quit
1087              (nil)))
1088            ;; search for $Revision
1089            ;; --------------------
1090            ((re-search-forward (concat "\\$"
1091                                        "Revision: \\([0-9.]+\\) \\$")
1092                                nil t)
1093             ;; if found, store the revision number ...
1094             (setq version (match-string-no-properties 1))
1095             ;; and see if there's any lock information
1096             (goto-char (point-min))
1097             (if (re-search-forward (concat "\\$" "Locker:") nil t)
1098                 (cond ((looking-at " \\([^ ]+\\) \\$")
1099                        ;;(setq locking-user (match-string-no-properties 1))
1100                        (setq status 'rev-and-lock))
1101                       ((looking-at " *\\$")
1102                        ;;(setq locking-user 'none)
1103                        (setq status 'rev-and-lock))
1104                       (t
1105                        ;;(setq locking-user 'none)
1106                        (setq status 'rev-and-lock)))
1107               (setq status 'rev)))
1108            ;; else: nothing found
1109            ;; -------------------
1110            (t nil))))
1111      (if status (vc-file-setprop file 'vc-working-revision version))
1112      status))))
1113
1114 (defun vc-release-greater-or-equal (r1 r2)
1115   "Compare release numbers, represented as strings.
1116 Release components are assumed cardinal numbers, not decimal fractions
1117 \(5.10 is a higher release than 5.9).  Omitted fields are considered
1118 lower \(5.6.7 is earlier than 5.6.7.1).  Comparison runs till the end
1119 of the string is found, or a non-numeric component shows up \(5.6.7 is
1120 earlier than \"5.6.7 beta\", which is probably not what you want in
1121 some cases).  This code is suitable for existing RCS release numbers.
1122 CVS releases are handled reasonably, too \(1.3 < 1.4* < 1.5)."
1123   (let (v1 v2 i1 i2)
1124     (catch 'done
1125       (or (and (string-match "^\\.?\\([0-9]+\\)" r1)
1126                (setq i1 (match-end 0))
1127                (setq v1 (string-to-number (match-string 1 r1)))
1128                (or (and (string-match "^\\.?\\([0-9]+\\)" r2)
1129                         (setq i2 (match-end 0))
1130                         (setq v2 (string-to-number (match-string 1 r2)))
1131                         (if (> v1 v2) (throw 'done t)
1132                           (if (< v1 v2) (throw 'done nil)
1133                             (throw 'done
1134                                    (vc-release-greater-or-equal
1135                                     (substring r1 i1)
1136                                     (substring r2 i2)))))))
1137                    (throw 'done t)))
1138           (or (and (string-match "^\\.?\\([0-9]+\\)" r2)
1139                    (throw 'done nil))
1140               (throw 'done t)))))
1141
1142 (defun vc-rcs-release-p (release)
1143   "Return t if we have RELEASE or better."
1144   (let ((installation (vc-rcs-system-release)))
1145     (if (and installation
1146              (not (eq installation 'unknown)))
1147         (vc-release-greater-or-equal installation release))))
1148
1149 (defun vc-rcs-system-release ()
1150   "Return the RCS release installed on this system, as a string.
1151 Return symbol `unknown' if the release cannot be deducted.  The user can
1152 override this using variable `vc-rcs-release'.
1153
1154 If the user has not set variable `vc-rcs-release' and it is nil,
1155 variable `vc-rcs-release' is set to the returned value."
1156   (or vc-rcs-release
1157       (setq vc-rcs-release
1158             (or (and (zerop (vc-do-command "*vc*" nil "rcs" nil "-V"))
1159                      (with-current-buffer (get-buffer "*vc*")
1160                        (vc-parse-buffer "^RCS version \\([0-9.]+ *.*\\)" 1)))
1161                 'unknown))))
1162
1163 (defun vc-rcs-set-non-strict-locking (file)
1164   (vc-do-command "*vc*" 0 "rcs" file "-U")
1165   (vc-file-setprop file 'vc-checkout-model 'implicit)
1166   (set-file-modes file (logior (file-modes file) 128)))
1167
1168 (defun vc-rcs-set-default-branch (file branch)
1169   (vc-do-command "*vc*" 0 "rcs" (vc-master-name file) (concat "-b" branch))
1170   (vc-file-setprop file 'vc-rcs-default-branch branch))
1171
1172 (defun vc-rcs-parse (&optional buffer)
1173   "Parse current buffer, presumed to be in RCS-style masterfile format.
1174 Optional arg BUFFER specifies another buffer to parse.  Return an alist
1175 of two elements, w/ keys `headers' and `revisions' and values in turn
1176 sub-alists.  For `headers', the values unless otherwise specified are
1177 strings and the keys are:
1178
1179   desc     -- description
1180   head     -- latest revision
1181   branch   -- the branch the \"head revision\" lies on;
1182               absent if the head revision lies on the trunk
1183   access   -- ???
1184   symbols  -- sub-alist of (SYMBOL . REVISION) elements
1185   locks    -- if file is checked out, something like \"ttn:1.7\"
1186   strict   -- t if \"strict locking\" is in effect, otherwise nil
1187   comment  -- may be absent; typically something like \"# \" or \"; \"
1188   expand   -- may be absent; ???
1189
1190 For `revisions', the car is REVISION (string), the cdr a sub-alist,
1191 with string values (unless otherwise specified) and keys:
1192
1193   date     -- a time value (like that returned by `encode-time'); as a
1194               special case, a year value less than 100 is augmented by 1900
1195   author   -- username
1196   state    -- typically \"Exp\" or \"Rel\"
1197   branches -- list of revisions that begin branches from this revision
1198   next     -- on the trunk: the chronologically-preceding revision, or \"\";
1199               on a branch: the chronologically-following revision, or \"\"
1200   log      -- change log entry
1201   text     -- for the head revision on the trunk, the body of the file;
1202               other revisions have `:insn' instead
1203   :insn    -- for non-head revisions, a list of parsed instructions
1204               in one of two forms, in both cases START meaning \"first
1205               go to line START\":
1206                - `(START k COUNT)' -- kill COUNT lines
1207                - `(START i TEXT)'  -- insert TEXT (a string)
1208               The list is in descending order by START.
1209
1210 The `:insn' key is a keyword to distinguish it as a vc-rcs.el extension."
1211   (setq buffer (get-buffer (or buffer (current-buffer))))
1212   (set-buffer buffer)
1213   ;; An RCS masterfile can be viewed as containing four regular (for the
1214   ;; most part) sections: (a) the "headers", (b) the "rev headers", (c)
1215   ;; the "description" and (d) the "rev bodies", in that order.  In the
1216   ;; returned alist (see docstring), elements from (b) and (d) are
1217   ;; combined pairwise to form the "revisions", while those from (a) and
1218   ;; (c) are simply combined to form the "headers".
1219   ;;
1220   ;; Loosely speaking, each section contains a series of alternating
1221   ;; "tags" and "printed representations".  In the (b) and (d), many
1222   ;; such series can appear, and a revision number on a line by itself
1223   ;; precedes the series of tags and printed representations associated
1224   ;; with it.
1225   ;;
1226   ;; In (a) and (b), the printed representations (with the exception of
1227   ;; the `comment' tag in the headers) terminate with a semicolon, which
1228   ;; is NOT part of the "value" finally associated with the tag.  All
1229   ;; other printed representations are in "@@-format"; there is an "@",
1230   ;; the middle part (to be translated into the value), another "@" and
1231   ;; a newline.  Each "@@" in the middle part indicates the position of
1232   ;; a single "@" (and consequently the requirement of an additional
1233   ;; initial step when translating to the value).
1234   ;;
1235   ;; Parser state includes vars that collect parts of the return value...
1236   (let ((desc nil) (headers nil) (revs nil)
1237         ;; ... as well as vars that support a single-pass, tag-assisted,
1238         ;; minimal-data-copying scan.  Basically -- skirting around the
1239         ;; grouping by revision required in (b) and (d) -- we repeatedly
1240         ;; and context-sensitively read a tag (that MUST be present),
1241         ;; determine the bounds of the printed representation, translate
1242         ;; it into a value, and push the tag plus value onto one of the
1243         ;; collection vars.  Finally, we return the parse tree
1244         ;; incorporating the values of the collection vars (see "rv").
1245         ;;
1246         ;; A symbol or string to keep track of context (for error messages).
1247         context
1248         ;; A symbol, the current tag.
1249         tok
1250         ;; Region (begin and end buffer positions) of the printed
1251         ;; representation for the current tag.
1252         b e
1253         ;; A list of buffer positions where "@@" can be found within the
1254         ;; printed representation region.  For each location, we push two
1255         ;; elements onto the list, 1+ and 2+ the location, respectively,
1256         ;; with the 2+ appearing at the head.  In this way, the expression
1257         ;;   `(,e ,@@-holes ,b)
1258         ;; describes regions that can be concatenated (in reverse order)
1259         ;; to "de-@@-format" the printed representation as the first step
1260         ;; to translating it into some value.  See internal func `gather'.
1261         @-holes)
1262     (cl-flet*
1263         ((sw () (skip-chars-forward " \t\n")) ; i.e., `[:space:]'
1264          (at (tag) (save-excursion (eq tag (read buffer))))
1265          (to-eol () (buffer-substring-no-properties
1266                      (point) (progn (forward-line 1)
1267                                     (1- (point)))))
1268          (to-semi () (setq b (point)
1269                            e (progn (search-forward ";")
1270                                     (1- (point)))))
1271          (to-one@ () (setq @-holes nil
1272                            b (progn (search-forward "@") (point))
1273                            e (progn (while (and (search-forward "@")
1274                                                 (= ?@ (char-after)))
1275                                       (push (point) @-holes)
1276                                       (forward-char 1)
1277                                       (push (point) @-holes))
1278                                     (1- (point)))))
1279          (tok+val (set-b+e name &optional proc)
1280                   (unless (eq name (setq tok (read buffer)))
1281                     (error "Missing `%s' while parsing %s" name context))
1282                   (sw)
1283                   (funcall set-b+e)
1284                   (cons tok (if proc
1285                                 (funcall proc)
1286                               (buffer-substring-no-properties b e))))
1287          (k-semi (name &optional proc) (tok+val #'to-semi name proc))
1288          (gather (b e @-holes)
1289                  (let ((pairs `(,e ,@@-holes ,b))
1290                        acc)
1291                    (while pairs
1292                      (push (buffer-substring-no-properties
1293                             (cadr pairs) (car pairs))
1294                            acc)
1295                      (setq pairs (cddr pairs)))
1296                    (apply #'concat acc)))
1297          (gather1 () (gather b e @-holes))
1298          (k-one@ (name &optional later)
1299                  (tok+val #'to-one@ name (if later (lambda () t) #'gather1))))
1300       (save-excursion
1301         (goto-char (point-min))
1302         ;; headers
1303         (setq context 'headers)
1304         (cl-flet ((hpush (name &optional proc)
1305                          (push (k-semi name proc) headers)))
1306           (hpush 'head)
1307           (when (at 'branch)
1308             (hpush 'branch))
1309           (hpush 'access)
1310           (hpush 'symbols
1311                  (lambda ()
1312                    (mapcar (lambda (together)
1313                              (let ((two (split-string together ":")))
1314                                (setcar two (intern (car two)))
1315                                (setcdr two (cadr two))
1316                                two))
1317                            (split-string
1318                             (buffer-substring-no-properties b e)))))
1319           (hpush 'locks))
1320         (push `(strict . ,(when (at 'strict)
1321                             (search-forward ";")
1322                             t))
1323               headers)
1324         (when (at 'comment)
1325           (push (k-one@ 'comment) headers)
1326           (search-forward ";"))
1327         (when (at 'expand)
1328           (push (k-one@ 'expand) headers)
1329           (search-forward ";"))
1330         (setq headers (nreverse headers))
1331         ;; rev headers
1332         (sw) (setq context 'rev-headers)
1333         (while (looking-at "[0-9]")
1334           (push `(,(to-eol)
1335                   ,(k-semi 'date
1336                            (lambda ()
1337                              (let ((ls (mapcar 'string-to-number
1338                                                (split-string
1339                                                 (buffer-substring-no-properties
1340                                                  b e)
1341                                                 "\\."))))
1342                                ;; Hack the year -- verified to be the
1343                                ;; same algorithm used in RCS 5.7.
1344                                (when (< (car ls) 100)
1345                                  (setcar ls (+ 1900 (car ls))))
1346                                (apply #'encode-time (nreverse ls)))))
1347                   ,@(mapcar #'k-semi '(author state))
1348                   ,(k-semi 'branches
1349                            (lambda ()
1350                              (split-string
1351                               (buffer-substring-no-properties b e))))
1352                   ,(k-semi 'next))
1353                 revs)
1354           (sw))
1355         (setq revs (nreverse revs))
1356         ;; desc
1357         (sw) (setq context 'desc
1358                    desc (k-one@ 'desc))
1359         ;; rev bodies
1360         (let (acc
1361               ;; Element of `revs' that initially holds only header info.
1362               ;; "Pairwise combination" occurs when we add body info.
1363               rev
1364               ;; Components of the editing commands (aside from the actual
1365               ;; text) that comprise the `text' printed representations
1366               ;; (not including the "head" revision).
1367               cmd start act
1368               ;; Ascending (reversed) `@-holes' which the internal func
1369               ;; `incg' pops to effect incremental gathering.
1370               asc
1371               ;; Function to extract text (for the `a' command), either
1372               ;; `incg' or `buffer-substring-no-properties'.  (This is
1373               ;; for speed; strictly speaking, it is sufficient to use
1374               ;; only the former since it behaves identically to the
1375               ;; latter in the absence of "@@".)
1376               sub)
1377           (cl-flet ((incg (beg end)
1378                           (let ((b beg) (e end) @-holes)
1379                             (while (and asc (< (car asc) e))
1380                               (push (pop asc) @-holes)
1381                               (push (pop asc) @-holes))
1382                             ;; Self-deprecate when work is done.
1383                             ;; Folding many dimensions into one.
1384                             ;; Thanks B.Mandelbrot, for complex sum.
1385                             ;; O beauteous math! --the Unvexed Bum
1386                             (unless asc
1387                               (setq sub #'buffer-substring-no-properties))
1388                             (gather b e @-holes))))
1389             (while (and (sw)
1390                         (not (eobp))
1391                         (setq context (to-eol)
1392                               rev (or (assoc context revs)
1393                                       (error "Rev `%s' has body but no head"
1394                                              context))))
1395               (push (k-one@ 'log) (cdr rev))
1396               ;; For rev body `text' tags, delay translation slightly...
1397               (push (k-one@ 'text t) (cdr rev))
1398               ;; ... until we decide which tag and value is appropriate to
1399               ;; collect.  For the "head" revision, compute the value of the
1400               ;; `text' printed representation by simple `gather'.  For all
1401               ;; other revisions, replace the `text' tag+value with `:insn'
1402               ;; plus value, always scanning in-place.
1403               (if (string= context (cdr (assq 'head headers)))
1404                   (setcdr (cadr rev) (gather b e @-holes))
1405                 (if @-holes
1406                     (setq asc (nreverse @-holes)
1407                           sub #'incg)
1408                   (setq sub #'buffer-substring-no-properties))
1409                 (goto-char b)
1410                 (setq acc nil)
1411                 (while (< (point) e)
1412                   (forward-char 1)
1413                   (setq cmd (char-before)
1414                         start (read (current-buffer))
1415                         act (read (current-buffer)))
1416                   (forward-char 1)
1417                   (push (pcase cmd
1418                           (?d
1419                            ;; `d' means "delete lines".
1420                            ;; For Emacs spirit, we use `k' for "kill".
1421                            `(,start k ,act))
1422                           (?a
1423                            ;; `a' means "append after this line" but
1424                            ;; internally we normalize it so that START
1425                            ;; specifies the actual line for insert, thus
1426                            ;; requiring less hair in the realization algs.
1427                            ;; For Emacs spirit, we use `i' for "insert".
1428                            `(,(1+ start) i
1429                              ,(funcall sub (point) (progn (forward-line act)
1430                                                           (point)))))
1431                           (_ (error "Bad command `%c' in `text' for rev `%s'"
1432                                     cmd context)))
1433                         acc))
1434                 (goto-char (1+ e))
1435                 (setcar (cdr rev) (cons :insn acc)))))))
1436       ;; rv
1437       `((headers ,desc ,@headers)
1438         (revisions ,@revs)))))
1439
1440 (provide 'vc-rcs)
1441
1442 ;;; vc-rcs.el ends here