code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the 'configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2016 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 25.1.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in "$@" CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140
 141 case $host in
 142  *-mingw*)
 143
 144   if test -z "$host_alias"; then
 145
 146       # No --host argument was given to 'configure'; therefore $host
 147       # was set to a default value based on the build platform.  But
 148       # this default value may be wrong if we are building from a
 149       # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
 150       # Therefore, we'll try to get the right host platform from the
 151       # compiler's target.
 152
 153       AC_MSG_CHECKING([the compiler's target])
 154       if test -z "$CC"; then
 155           cc=gcc
 156       else
 157           cc=$CC
 158       fi
 159       cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
 160       case "$cc_target" in
 161           *-*) host=$cc_target
 162               ;;
 163           "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
 164 Please explicitly provide --host.])
 165               ;;
 166           *) AC_MSG_WARN([Compiler reported non-standard target.
 167 Defaulting to $host.])
 168               ;;
 169       esac
 170       AC_MSG_RESULT([$host])
 171   fi
 172
 173   . $srcdir/nt/mingw-cfg.site
 174
 175   case $srcdir in
 176     /* | ?:*)
 177       # srcdir is an absolute path.  In this case, force the format
 178       # "/c/foo/bar", to simplify later conversions to native Windows
 179       # format ("c:/foo/bar").
 180       srcdir=`cd "${srcdir}" && pwd -W`
 181       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
 182       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
 183       ;;
 184   esac;;
 185 esac
 186
 187 canonical=$host
 188 configuration=${host_alias-${build_alias-$host}}
 189
 190 dnl Support for --program-prefix, --program-suffix and
 191 dnl --program-transform-name options
 192 AC_ARG_PROGRAM
 193
 194 dnl It is important that variables on the RHS not be expanded here,
 195 dnl hence the single quotes.  This is per the GNU coding standards, see
 196 dnl (autoconf) Installation Directory Variables
 197 dnl See also epaths.h below.
 198 lispdir='${datadir}/emacs/${version}/lisp'
 199 standardlisppath='${lispdir}'
 200 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 201 '${datadir}/emacs/site-lisp'
 202 lisppath='${locallisppath}:${standardlisppath}'
 203 etcdir='${datadir}/emacs/${version}/etc'
 204 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 205 etcdocdir='${datadir}/emacs/${version}/etc'
 206 gamedir='${localstatedir}/games/emacs'
 207
 208 dnl Special option to disable the most of other options.
 209 AC_ARG_WITH(all,
 210 [AS_HELP_STRING([--without-all],
 211                 [omit almost all features and build
 212                 small executable with minimal dependencies])],
 213   [with_features=$withval],
 214   [with_features=yes])
 215
 216 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 217 dnl Create a new --with option that defaults to being disabled.
 218 dnl NAME is the base name of the option.  The shell variable with_NAME
 219 dnl   will be set to either the user's value (if the option is
 220 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 221 dnl   option is not specified).  Note that the shell variable name is
 222 dnl   constructed as autoconf does, by replacing non-alphanumeric
 223 dnl   characters with "_".
 224 dnl HELP-STRING is the help text for the option.
 225 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 226   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 227     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 228 ])dnl
 229
 230 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 231 dnl Create a new --with option that defaults to $with_features.
 232 dnl NAME is the base name of the option.  The shell variable with_NAME
 233 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 234 dnl   'yes' (if the option is not specified).  Note that the shell
 235 dnl   variable name is constructed as autoconf does, by replacing
 236 dnl   non-alphanumeric characters with "_".
 237 dnl HELP-STRING is the help text for the option.
 238 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 239   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 240    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 241 ])dnl
 242
 243 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 244 if test "$with_pop" = yes; then
 245    AC_DEFINE(MAIL_USE_POP)
 246 fi
 247 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 248
 249 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 250 if test "$with_kerberos" != no; then
 251    AC_DEFINE(KERBEROS)
 252 fi
 253 AH_TEMPLATE(KERBEROS,
 254             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 255
 256 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 257 if test "${with_kerberos5}" != no; then
 258   if test "${with_kerberos}" = no; then
 259     with_kerberos=yes
 260     AC_DEFINE(KERBEROS)
 261   fi
 262   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 263 fi
 264
 265 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 266 dnl FIXME hesiod support may not be present, so it seems like an error
 267 dnl to define, or at least use, this unconditionally.
 268 if test "$with_hesiod" != no; then
 269   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 270 fi
 271
 272 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 273 if test "$with_mail_unlink" != no; then
 274    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 275 fi
 276
 277 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 278     [string giving default POP mail host])],
 279     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 280
 281 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 282   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 283 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
 284   [ case "${withval}" in
 285       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 286       *) AC_MSG_ERROR(['--with-sound=$withval' is invalid;
 287 this option's value should be 'yes', 'no', 'alsa', 'oss', or 'bsd-ossaudio'.])
 288       ;;
 289     esac
 290     with_sound=$val
 291   ],
 292   [with_sound=$with_features])
 293
 294 dnl FIXME currently it is not the last.
 295 dnl This should be the last --with option, because --with-x is
 296 dnl added later on when we find the file name of X, and it's best to
 297 dnl keep them together visually.
 298 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 299  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 300 [         case "${withval}" in
 301             y | ye | yes )      val=gtk ;;
 302             n | no )            val=no  ;;
 303             l | lu | luc | luci | lucid )       val=lucid ;;
 304             a | at | ath | athe | athen | athena )      val=athena ;;
 305             m | mo | mot | moti | motif )       val=motif ;;
 306             g | gt | gtk  )     val=gtk ;;
 307             gtk2  )     val=gtk2 ;;
 308             gtk3  )     val=gtk3 ;;
 309             * )
 310 AC_MSG_ERROR(['--with-x-toolkit=$withval' is invalid;
 311 this option's value should be 'yes', 'no', 'lucid', 'athena', 'motif', 'gtk',
 312 'gtk2' or 'gtk3'.  'yes' and 'gtk' are synonyms.
 313 'athena' and 'lucid' are synonyms.])
 314             ;;
 315           esac
 316           with_x_toolkit=$val
 317 ])
 318
 319 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit); allows buffer and string size up to 2GB on 32-bit hosts, at the cost of 10% to 30% slowdown of Lisp interpreter and larger memory footprint])
 320 if test "$with_wide_int" = yes; then
 321   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 322 fi
 323
 324 dnl _ON results in a '--without' option in the --help output, so
 325 dnl the help text should refer to "don't compile", etc.
 326 with_xpm_set=${with_xpm+set}
 327 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 328 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 329 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 330 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 331 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 332 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 333 OPTION_DEFAULT_OFF([cairo],[compile with Cairo drawing (experimental)])
 334 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 335 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 336
 337 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 338 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 339 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 340
 341 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 342 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 343 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 344 AC_ARG_WITH([ns],[AS_HELP_STRING([--with-ns],
 345 [use Nextstep (OS X Cocoa or GNUstep) windowing system.
 346 On by default on Mac OS X.])],[],[with_ns=maybe])
 347 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 348
 349 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 350 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 351 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 352 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 353 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 354 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 355 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 356 OPTION_DEFAULT_OFF([modules],[compile with dynamic modules support])
 357
 358 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 359  [use a file notification library (LIB one of: yes, inotify, kqueue, gfile, w32, no)])],
 360  [ case "${withval}" in
 361     y | ye | yes )      val=yes ;;
 362     n | no )            val=no  ;;
 363     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 364     k | kq | kqu | kque | kqueu | kqueue )      val=kqueue ;;
 365     g | gf | gfi | gfil | gfile )       val=gfile ;;
 366     w | w3 | w32 )      val=w32 ;;
 367     * ) AC_MSG_ERROR(['--with-file-notification=$withval' is invalid;
 368 this option's value should be 'yes', 'no', 'inotify', 'kqueue', 'gfile' or 'w32'.
 369 'yes' is a synonym for 'w32' on MS-Windows, for 'no' on Nextstep,
 370 otherwise for the first of 'inotify', 'kqueue' or 'gfile' that is usable.])
 371     ;;
 372    esac
 373    with_file_notification=$val
 374  ],
 375  [with_file_notification=$with_features])
 376
 377 OPTION_DEFAULT_OFF([xwidgets],
 378   [enable use of some gtk widgets in Emacs buffers (requires gtk3)])
 379
 380 ## For the times when you want to build Emacs but don't have
 381 ## a suitable makeinfo, and can live without the manuals.
 382 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 383 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 384
 385 ## This might be a 'configure' arg.
 386 AC_SUBST([ACLOCAL_PATH])
 387
 388 ## Makefile.in needs the cache file name.
 389 AC_SUBST(cache_file)
 390
 391 ## This is an option because I do not know if all info/man support
 392 ## compressed files, nor how to test if they do so.
 393 OPTION_DEFAULT_ON([compress-install],
 394   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 395 make GZIP_PROG= install])
 396
 397 AC_ARG_WITH(gameuser,dnl
 398 [AS_HELP_STRING([--with-gameuser=USER_OR_GROUP],
 399                 [user for shared game score files.
 400                 An argument prefixed by ':' specifies a group instead.])])
 401 gameuser=
 402 gamegroup=
 403 # We don't test if we can actually chown/chgrp here, because configure
 404 # may run without root privileges.  lib-src/Makefile.in will handle
 405 # any errors due to missing user/group gracefully.
 406 case ${with_gameuser} in
 407   no) ;;
 408   "" | yes) gamegroup=games ;;
 409   :*) gamegroup=${with_gameuser#:} ;;
 410   *) gameuser=${with_gameuser} ;;
 411 esac
 412
 413 AC_ARG_WITH([gnustep-conf],dnl
 414 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 415    [name of GNUstep configuration file to use on systems where the command
 416     'gnustep-config' does not work; default $GNUSTEP_CONFIG_FILE, or
 417     /etc/GNUstep/GNUstep.conf])])
 418 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 419   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 420 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 421      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 422
 423 AC_ARG_ENABLE(ns-self-contained,
 424 [AS_HELP_STRING([--disable-ns-self-contained],
 425                 [disable self contained build under NeXTstep])],
 426    EN_NS_SELF_CONTAINED=$enableval,
 427    EN_NS_SELF_CONTAINED=yes)
 428
 429 locallisppathset=no
 430 AC_ARG_ENABLE(locallisppath,
 431 [AS_HELP_STRING([--enable-locallisppath=PATH],
 432                 [directories Emacs should search for lisp files specific
 433                  to this site])],
 434 if test "${enableval}" = "no"; then
 435   locallisppath=
 436 elif test "${enableval}" != "yes"; then
 437   locallisppath=${enableval} locallisppathset=yes
 438 fi)
 439
 440 AC_ARG_ENABLE(checking,
 441 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 442                 [enable expensive run-time checks.  With LIST,
 443                  enable only specific categories of checks.
 444                  Categories are: all,yes,no.
 445                  Flags are: stringbytes, stringoverrun, stringfreelist,
 446                  xmallocoverrun, conslist, glyphs])],
 447 [ac_checking_flags="${enableval}"],[])
 448 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 449 for check in $ac_checking_flags
 450 do
 451         case $check in
 452         # these set all the flags to specific states
 453         yes)            ac_enable_checking=1 ;;
 454         no)             ac_enable_checking= ;
 455                         ac_gc_check_stringbytes= ;
 456                         ac_gc_check_string_overrun= ;
 457                         ac_gc_check_string_free_list= ;
 458                         ac_xmalloc_overrun= ;
 459                         ac_gc_check_cons_list= ;
 460                         ac_glyphs_debug= ;;
 461         all)            ac_enable_checking=1 ;
 462                         ac_gc_check_stringbytes=1 ;
 463                         ac_gc_check_string_overrun=1 ;
 464                         ac_gc_check_string_free_list=1 ;
 465                         ac_xmalloc_overrun=1 ;
 466                         ac_gc_check_cons_list=1 ;
 467                         ac_glyphs_debug=1 ;;
 468         # these enable particular checks
 469         stringbytes)    ac_gc_check_stringbytes=1 ;;
 470         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 471         stringfreelist) ac_gc_check_string_free_list=1 ;;
 472         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 473         conslist)       ac_gc_check_cons_list=1 ;;
 474         glyphs)         ac_glyphs_debug=1 ;;
 475         *)      AC_MSG_ERROR(unknown check category $check) ;;
 476         esac
 477 done
 478 IFS="$ac_save_IFS"
 479
 480 if test x$ac_enable_checking != x ; then
 481   AC_DEFINE(ENABLE_CHECKING, 1,
 482 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 483 fi
 484 if test x$ac_gc_check_stringbytes != x ; then
 485   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 486 [Define this temporarily to hunt a bug.  If defined, the size of
 487    strings is redundantly recorded in sdata structures so that it can
 488    be compared to the sizes recorded in Lisp strings.])
 489 fi
 490 if test x$ac_gc_check_string_overrun != x ; then
 491   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 492 [Define this to check for short string overrun.])
 493 fi
 494 if test x$ac_gc_check_string_free_list != x ; then
 495   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 496 [Define this to check the string free list.])
 497 fi
 498 if test x$ac_xmalloc_overrun != x ; then
 499   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 500 [Define this to check for malloc buffer overrun.])
 501 fi
 502 if test x$ac_gc_check_cons_list != x ; then
 503   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 504 [Define this to check for errors in cons list.])
 505 fi
 506 if test x$ac_glyphs_debug != x ; then
 507   AC_DEFINE(GLYPH_DEBUG, 1,
 508 [Define this to enable glyphs debugging code.])
 509 fi
 510
 511 AC_ARG_ENABLE(check-lisp-object-type,
 512 [AS_HELP_STRING([--enable-check-lisp-object-type],
 513                 [enable compile time checks for the Lisp_Object data type.
 514                 This is useful for development for catching certain types of bugs.])],
 515 if test "${enableval}" != "no"; then
 516    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 517    [Define this to enable compile time checks for the Lisp_Object data type.])
 518 fi)
 519
 520
 521 dnl The name of this option is unfortunate.  It predates, and has no
 522 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 523 dnl Actually, it stops it working.
 524 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 525 AC_ARG_ENABLE(profiling,
 526 [AS_HELP_STRING([--enable-profiling],
 527                 [build emacs with low-level, gprof profiling support.
 528                 Mainly useful for debugging Emacs itself.  May not work on
 529                 all platforms.  Stops profiler.el working.])],
 530 [ac_enable_profiling="${enableval}"],[])
 531 if test x$ac_enable_profiling != x ; then
 532    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 533 else
 534    PROFILING_CFLAGS=
 535 fi
 536 AC_SUBST(PROFILING_CFLAGS)
 537
 538 AC_ARG_ENABLE(autodepend,
 539 [AS_HELP_STRING([--enable-autodepend],
 540                 [automatically generate dependencies to .h-files.
 541                  Requires gcc, enabled if found.])],
 542 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 543
 544 AC_ARG_ENABLE(gtk-deprecation-warnings,
 545 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 546                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 547 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 548
 549 dnl This used to use changequote, but, apart from 'changequote is evil'
 550 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 551 dnl the great gob of text.  Thus it's not processed for possible expansion.
 552 dnl Just make sure the brackets remain balanced.
 553 dnl
 554 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 555 dnl indicated by comments.
 556 dnl quotation begins
 557 [
 558
 559 ### If you add support for a new configuration, add code to this
 560 ### switch statement to recognize your configuration name and select
 561 ### the appropriate opsys.
 562
 563 ### As far as handling version numbers on operating systems is
 564 ### concerned, make sure things will fail in a fixable way.  If
 565 ### /etc/MACHINES doesn't say anything about version numbers, be
 566 ### prepared to handle anything reasonably.  If version numbers
 567 ### matter, be sure /etc/MACHINES says something about it.
 568
 569 opsys='' unported=no
 570 case "${canonical}" in
 571
 572   ## GNU/Linux and similar ports
 573   *-*-linux* )
 574     opsys=gnu-linux
 575   ;;
 576
 577   ## FreeBSD ports
 578   *-*-freebsd* )
 579     opsys=freebsd
 580   ;;
 581
 582   ## DragonFly ports
 583   *-*-dragonfly* )
 584     opsys=dragonfly
 585   ;;
 586
 587   ## FreeBSD kernel + glibc based userland
 588   *-*-kfreebsd*gnu* )
 589     opsys=gnu-kfreebsd
 590   ;;
 591
 592   ## NetBSD ports
 593   *-*-netbsd* )
 594     opsys=netbsd
 595   ;;
 596
 597   ## OpenBSD ports
 598   *-*-openbsd* | *-*-mirbsd* )
 599     opsys=openbsd
 600   ;;
 601
 602   ## Apple Darwin / Mac OS X
 603   *-apple-darwin* )
 604     case "${canonical}" in
 605       *-apple-darwin[0-9].*) unported=yes ;;
 606       i[3456]86-* | x86_64-* )  ;;
 607       * )            unported=yes ;;
 608     esac
 609     opsys=darwin
 610     ## Use fink packages if available.
 611     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 612 ##    if test -d /sw/include && test -d /sw/lib; then
 613 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 614 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 615 ##    fi
 616   ;;
 617
 618   ## Chromium Native Client
 619   *-nacl )
 620     opsys=nacl
 621   ;;
 622
 623   ## Cygwin ports
 624   *-*-cygwin )
 625     opsys=cygwin
 626   ;;
 627
 628   ## HP 9000 series 700 and 800, running HP/UX
 629   hppa*-hp-hpux10.2* )
 630     opsys=hpux10-20
 631   ;;
 632   hppa*-hp-hpux1[1-9]* )
 633     opsys=hpux11
 634     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 635   ;;
 636
 637   ## IBM machines
 638   rs6000-ibm-aix4.[23]* )
 639     opsys=aix4-2
 640   ;;
 641   powerpc-ibm-aix4.[23]*  )
 642     opsys=aix4-2
 643   ;;
 644   rs6000-ibm-aix[56]* )
 645     opsys=aix4-2
 646   ;;
 647   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 648     opsys=aix4-2
 649   ;;
 650
 651   ## Silicon Graphics machines
 652   ## Iris 4D
 653   mips-sgi-irix6.5 )
 654     opsys=irix6-5
 655     # Without defining _LANGUAGE_C, things get masked out in the headers
 656     # so that, for instance, grepping for 'free' in stdlib.h fails and
 657     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 658     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 659   ;;
 660
 661   ## Suns
 662   *-sun-solaris* \
 663     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 664     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 665     case "${canonical}" in
 666       i[3456]86-*-* )   ;;
 667       amd64-*-*|x86_64-*-*) ;;
 668       sparc* )          ;;
 669       * )               unported=yes ;;
 670     esac
 671     case "${canonical}" in
 672       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 673                 opsys=sol2-10
 674                 emacs_check_sunpro_c=yes
 675                 ;;
 676       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 677       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 678       *-sunos5.6* | *-solaris2.6* )
 679                 opsys=sol2-6
 680                 RANLIB="ar -ts"
 681                 ;;
 682       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 683       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 684                 opsys=sol2-6
 685                 emacs_check_sunpro_c=yes
 686                 ;;
 687     esac
 688     ## Watch out for a compiler that we know will not work.
 689     case "${canonical}" in
 690      *-solaris* | *-sunos5* )
 691                 if [ "x$CC" = x/usr/ucb/cc ]; then
 692                   ## /usr/ucb/cc doesn't work;
 693                   ## we should find some other compiler that does work.
 694                   unset CC
 695                 fi
 696                 ;;
 697       *) ;;
 698     esac
 699   ;;
 700
 701   ## Intel 386 machines where we don't care about the manufacturer.
 702   i[3456]86-*-* )
 703     case "${canonical}" in
 704       *-darwin* )               opsys=darwin ;;
 705       *-mingw* )
 706                 opsys=mingw32
 707                 # MinGW overrides and adds some system headers in nt/inc.
 708                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 709                 ;;
 710       *-sysv4.2uw* )            opsys=unixware ;;
 711       *-sysv5uw* )              opsys=unixware ;;
 712       *-sysv5OpenUNIX* )        opsys=unixware ;;
 713       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 714     esac
 715   ;;
 716
 717   # MinGW64
 718   x86_64-*-* )
 719     case "${canonical}" in
 720       *-mingw* )
 721                 opsys=mingw32
 722                 # MinGW overrides and adds some system headers in nt/inc.
 723                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 724                 ;;
 725       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 726     esac
 727   ;;
 728
 729   * )
 730     unported=yes
 731   ;;
 732 esac
 733
 734 ### If the code above didn't choose an operating system, just choose
 735 ### an operating system based on the configuration name.  You really
 736 ### only want to use this when you have no idea what the right
 737 ### operating system is; if you know what operating systems a machine
 738 ### runs, it's cleaner to make it explicit in the case statement
 739 ### above.
 740 if test x"${opsys}" = x; then
 741   case "${canonical}" in
 742     *-gnu* )                            opsys=gnu ;;
 743     * )
 744       unported=yes
 745     ;;
 746   esac
 747 fi
 748
 749 ]
 750 dnl quotation ends
 751
 752 if test $unported = yes; then
 753   AC_MSG_ERROR([Emacs does not support '${canonical}' systems.
 754 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 755 Check 'etc/MACHINES' for recognized configuration names.])
 756 fi
 757
 758 #### Choose a compiler.
 759
 760 dnl Don't bother to test for C89.
 761 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 762
 763 dnl Sets GCC=yes if using gcc.
 764 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 765 if test -n "$XCRUN"; then
 766   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 767   test -n "$AR" && export AR
 768 fi
 769
 770 dnl Emacs needs C99 or later.
 771 gl_PROG_CC_C99
 772
 773 AM_PROG_CC_C_O
 774
 775 if test x$GCC = xyes; then
 776   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 777 else
 778   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 779 fi
 780
 781 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 782 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 783 dnl that clash with MinGW.
 784 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 785
 786 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 787 AC_DEFUN([gl_CRYPTO_CHECK])
 788 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 789 # as we don't use them.
 790 AC_DEFUN([gl_FCNTL_O_FLAGS])
 791 # Avoid gnulib's test for pthread_sigmask.
 792 funcs=
 793 for func in $ac_func_list; do
 794   test $func = pthread_sigmask || AS_VAR_APPEND([funcs], [" $func"])
 795 done
 796 ac_func_list=$funcs
 797 # Use the system putenv even if it lacks GNU features, as we don't need them,
 798 # and the gnulib replacement runs afoul of a FreeBSD 10.1 bug; see Bug#19874.
 799 AC_CHECK_FUNCS_ONCE([putenv])
 800 AC_DEFUN([gl_FUNC_PUTENV],
 801   [test "$ac_cv_func_putenv" = yes || REPLACE_PUTENV=1])
 802
 803 # Initialize gnulib right after choosing the compiler.
 804 dnl Amongst other things, this sets AR and ARFLAGS.
 805 gl_EARLY
 806
 807 if test "$ac_test_CFLAGS" != set; then
 808   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 809   # if -g3 works and the user does not specify CFLAGS.
 810   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 811   case $CFLAGS in
 812     '-g')
 813       emacs_g3_CFLAGS='-g3';;
 814     '-g -O2')
 815       emacs_g3_CFLAGS='-g3 -O2';;
 816     *)
 817       emacs_g3_CFLAGS='';;
 818   esac
 819   if test -n "$emacs_g3_CFLAGS"; then
 820     emacs_save_CFLAGS=$CFLAGS
 821     CFLAGS=$emacs_g3_CFLAGS
 822     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 823       [emacs_cv_prog_cc_g3],
 824       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 825          [emacs_cv_prog_cc_g3=yes],
 826          [emacs_cv_prog_cc_g3=no])])
 827     if test $emacs_cv_prog_cc_g3 != yes; then
 828       CFLAGS=$emacs_save_CFLAGS
 829     fi
 830     if test $opsys = mingw32; then
 831       CFLAGS="$CFLAGS -gdwarf-2"
 832     fi
 833   fi
 834
 835   case $CFLAGS in
 836     *-O*) ;;
 837     *)
 838       # No optimization flag was inferred for this non-GCC compiler.
 839       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 840       emacs_save_CFLAGS=$CFLAGS
 841       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 842       CFLAGS=${CFLAGS}-O
 843       AC_CACHE_CHECK([whether $CC accepts -O],
 844         [emacs_cv_prog_cc_o],
 845         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 846            [emacs_cv_prog_cc_o=yes],
 847            [emacs_cv_prog_cc_o=no])])
 848       if test $emacs_cv_prog_cc_o != yes; then
 849         CFLAGS=$emacs_save_CFLAGS
 850       fi ;;
 851   esac
 852 fi
 853
 854 AC_ARG_ENABLE([gcc-warnings],
 855   [AS_HELP_STRING([--enable-gcc-warnings],
 856                   [turn on lots of GCC warnings/errors. This is intended for
 857                    developers, and may generate false alarms when used
 858                    with older or non-GNU development tools.])],
 859   [case $enableval in
 860      yes|no) ;;
 861      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 862    esac
 863    gl_gcc_warnings=$enableval],
 864   [gl_gcc_warnings=no]
 865 )
 866
 867 # clang is unduly picky about some things.
 868 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 869   [AC_COMPILE_IFELSE(
 870      [AC_LANG_PROGRAM([[
 871           #ifndef __clang__
 872             error "not clang";
 873           #endif
 874         ]])],
 875      [emacs_cv_clang=yes],
 876      [emacs_cv_clang=no])])
 877
 878 # When compiling with GCC, prefer -isystem to -I when including system
 879 # include files, to avoid generating useless diagnostics for the files.
 880 if test "$gl_gcc_warnings" != yes; then
 881   isystem='-I'
 882   if test "$emacs_cv_clang" = yes
 883   then
 884      # Turn off some warnings if supported.
 885      gl_WARN_ADD([-Wno-switch])
 886      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 887      gl_WARN_ADD([-Wno-pointer-sign])
 888      gl_WARN_ADD([-Wno-string-plus-int])
 889      gl_WARN_ADD([-Wno-unknown-attributes])
 890   fi
 891 else
 892   isystem='-isystem '
 893
 894   # This, $nw, is the list of warnings we disable.
 895   nw=
 896
 897   case $with_x_toolkit in
 898     lucid | athena | motif)
 899        # Old toolkits mishandle 'const'.
 900        nw="$nw -Wwrite-strings"
 901        ;;
 902     *)
 903        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 904        ;;
 905   esac
 906   AC_SUBST([WERROR_CFLAGS])
 907
 908   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 909   nw="$nw -Woverlength-strings"     # Not a problem these days
 910   nw="$nw -Wformat-nonliteral"      # we do this a lot
 911   nw="$nw -Wvla"                    # Emacs uses <vla.h>.
 912   nw="$nw -Wswitch-default"         # Too many warnings for now
 913   nw="$nw -Winline"                 # OK to ignore 'inline'
 914   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 915   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 916                                     # signed overflow has undefined behavior
 917   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 918   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 919   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 920
 921   # Emacs doesn't care about shadowing; see
 922   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 923   nw="$nw -Wshadow"
 924
 925   # Emacs's use of alloca inhibits protecting the stack.
 926   nw="$nw -Wstack-protector"
 927
 928   # Emacs's use of partly-const functions such as Fgnutls_available_p
 929   # make this option problematic.
 930   nw="$nw -Wsuggest-attribute=const"
 931
 932   # Emacs's use of partly-pure functions such as CHECK_TYPE make this
 933   # option problematic.
 934   nw="$nw -Wsuggest-attribute=pure"
 935
 936   # This part is merely for shortening the command line,
 937   # since -Wall implies -Wswitch.
 938   nw="$nw -Wswitch"
 939
 940   # This part is merely for shortening the command line,
 941   # since -Wno-FOO needs to be added below regardless.
 942   nw="$nw -Wmissing-field-initializers"
 943   nw="$nw -Wtype-limits"
 944   nw="$nw -Wunused-parameter"
 945
 946   if test $emacs_cv_clang = yes; then
 947     nw="$nw -Wcast-align"
 948   fi
 949
 950   gl_MANYWARN_ALL_GCC([ws])
 951   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 952   for w in $ws; do
 953     gl_WARN_ADD([$w])
 954   done
 955   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 956   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 957   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 958   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 959   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 960   gl_WARN_ADD([-Wno-format-nonliteral])
 961
 962   # More things that clang is unduly picky about.
 963   if test $emacs_cv_clang = yes; then
 964     gl_WARN_ADD([-Wno-format-extra-args])
 965     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 966     gl_WARN_ADD([-Wno-unused-command-line-argument])
 967     gl_WARN_ADD([-Wno-unused-value])
 968   fi
 969
 970   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 971   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 972   AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
 973   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 974       without upsetting glibc 2.15+. */
 975    #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
 976         && defined __OPTIMIZE__ && __OPTIMIZE__)
 977    # define _FORTIFY_SOURCE 2
 978    #endif
 979   ])
 980
 981   # We use a slightly smaller set of warning options for lib/.
 982   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 983   nw=
 984   nw="$nw -Wunused-macros"
 985
 986   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 987   AC_SUBST([GNULIB_WARN_CFLAGS])
 988 fi
 989
 990 edit_cflags="
 991   s,///*,/,g
 992   s/^/ /
 993   s/ -I/ $isystem/g
 994   s/^ //
 995 "
 996
 997 AC_ARG_ENABLE(link-time-optimization,
 998 [AS_HELP_STRING([--enable-link-time-optimization],
 999                 [build emacs with link-time optimization.
1000                  This requires GCC 4.5.0 or later, or clang.
1001                  (Note that clang support is experimental - see INSTALL.)
1002                  It also makes Emacs harder to debug, and when we tried it
1003                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
1004                  recommended for typical use.])],
1005 if test "${enableval}" != "no"; then
1006    ac_lto_supported=no
1007    if test $emacs_cv_clang = yes; then
1008       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
1009       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
1010       if test -x "$GOLD_PLUGIN"; then
1011          LTO="-flto"
1012       fi
1013    elif test x$GCC = xyes; then
1014       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
1015       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
1016       if test x$CPUS != x; then
1017          LTO="-flto=$CPUS"
1018       else
1019          LTO="-flto"
1020       fi
1021    else
1022       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
1023    fi
1024    if test -z "$LTO"; then
1025       ac_lto_supported=no
1026    else
1027       old_CFLAGS=$CFLAGS
1028       CFLAGS="$CFLAGS $LTO"
1029       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1030          [ac_lto_supported=yes], [ac_lto_supported=no])
1031          CFLAGS="$old_CFLAGS"
1032    fi
1033    AC_MSG_RESULT([$ac_lto_supported])
1034    if test "$ac_lto_supported" = "yes"; then
1035       CFLAGS="$CFLAGS $LTO"
1036       if test x$emacs_cv_clang = xyes; then
1037          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
1038          # WARNING: 'ar --plugin ...' doesn't work without
1039          # command, so plugin name is appended to ARFLAGS.
1040          ARFLAGS="cru --plugin $GOLD_PLUGIN"
1041          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
1042       else
1043         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
1044         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
1045         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
1046         dnl dump core on Fedora 20, so play it safe for now.
1047         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
1048           [CFLAGS="$CFLAGS -ffat-lto-objects"])
1049       fi
1050    fi
1051 fi)
1052
1053 dnl Prefer silent make output.  For verbose output, use
1054 dnl 'configure --disable-silent-rules' or 'make V=1' .
1055 AM_SILENT_RULES([yes])
1056 dnl Port to Automake 1.11.
1057 dnl This section can be removed once we assume Automake 1.14 or later.
1058 : ${AM_V=$AM_DEFAULT_VERBOSITY}
1059 : ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
1060 AC_SUBST([AM_V])
1061 AM_SUBST_NOTMAKE([AM_V])
1062 AC_SUBST([AM_DEFAULT_V])
1063 AM_SUBST_NOTMAKE([AM_DEFAULT_V])
1064 AC_SUBST([AM_DEFAULT_VERBOSITY])
1065
1066 dnl Some other nice autoconf tests.
1067 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
1068 dnl AC_PROG_INSTALL
1069 dnl AC_PROG_MKDIR_P
1070 dnl if test "x$RANLIB" = x; then
1071 dnl   AC_PROG_RANLIB
1072 dnl fi
1073
1074
1075 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
1076 dnl can be made to directories.  This is not relevant for our usage, and
1077 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1078 dnl hosted on AFS, both examples where simple links work, but links to
1079 dnl directories fail.  We use a cut-down version instead.
1080 dnl AC_PROG_LN_S
1081
1082 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1083 rm -f conf$$ conf$$.file
1084
1085 LN_S_FILEONLY='cp -p'
1086
1087 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1088 dnl random program in the current directory.
1089 if (echo >conf$$.file) 2>/dev/null; then
1090   if ln -s conf$$.file conf$$ 2>/dev/null; then
1091     if test "$opsys" = "mingw32"; then
1092       LN_S_FILEONLY='/bin/ln -s'
1093     else
1094       LN_S_FILEONLY='ln -s'
1095     fi
1096   elif ln conf$$.file conf$$ 2>/dev/null; then
1097     if test "$opsys" = "mingw32"; then
1098       LN_S_FILEONLY=/bin/ln
1099     else
1100       LN_S_FILEONLY=ln
1101     fi
1102   fi
1103 fi
1104
1105 rm -f conf$$ conf$$.file
1106
1107 if test "$LN_S_FILEONLY" = "ln -s"; then
1108    AC_MSG_RESULT([yes])
1109 else
1110    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1111 fi
1112
1113 AC_SUBST(LN_S_FILEONLY)
1114
1115
1116 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1117 dnl doesn't support links to directories, as in "ln file dir".  But that
1118 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1119 dnl executables at "make install" time.
1120 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1121 dnl for more details.
1122 if test "$opsys" = "mingw32"; then
1123   LN_S="/bin/ln"
1124 fi
1125
1126 dnl On some Debian versions, "install-info" prints irritating messages
1127 dnl "This is not dpkg install-info anymore, but GNU install-info"
1128 dnl if called via an absolute file name.
1129 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1130 dnl Sadly some people may have an old ginstall-info installed on
1131 dnl non-Debian systems, so we can't use this.
1132 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1133 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1134
1135 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1136   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1137 dnl Don't use GZIP, which is used by gzip for additional parameters.
1138 AC_PATH_PROG(GZIP_PROG, gzip)
1139
1140 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1141    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1142
1143 if test $opsys = gnu-linux; then
1144   AC_PATH_PROG(PAXCTL, paxctl,,
1145     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1146   if test "X$PAXCTL" != X; then
1147     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1148     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1149       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
1150       else AC_MSG_RESULT(no); PAXCTL=""; fi])
1151   fi
1152
1153   if test "${SETFATTR+set}" != set; then
1154     AC_CACHE_CHECK([for setfattr],
1155       [emacs_cv_prog_setfattr],
1156       [touch conftest.tmp
1157        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1158          emacs_cv_prog_setfattr=yes
1159        else
1160          emacs_cv_prog_setfattr=no
1161        fi])
1162     if test "$emacs_cv_prog_setfattr" = yes; then
1163       SETFATTR=setfattr
1164     else
1165       SETFATTR=
1166     fi
1167     rm -f conftest.tmp
1168     AC_SUBST([SETFATTR])
1169   fi
1170 fi
1171
1172 ## Need makeinfo >= 4.7 (?) to build the manuals.
1173 if test "$MAKEINFO" != "no"; then
1174   if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
1175     MAKEINFO=makeinfo
1176   fi
1177   case `($MAKEINFO --version) 2>/dev/null` in
1178     *' (GNU texinfo) '4.[[7-9]]* | \
1179     *' (GNU texinfo) '4.[[1-9][0-9]]* | \
1180     *' (GNU texinfo) '[[5-9]]* | \
1181     *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1182     *) MAKEINFO=no;;
1183   esac
1184 fi
1185
1186 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1187 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1188 ## therefore in the category of "special tools" not normally required, which
1189 ## configure does not have to check for (eg autoconf itself).
1190 ## In a repository checkout on the other hand, the manuals are not included.
1191 ## So makeinfo is a requirement to build from the repository, and configure
1192 ## should test for it as it does for any other build requirement.
1193 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1194 ## with pre-built manuals, from a repository checkout.
1195 HAVE_MAKEINFO=yes
1196
1197 if test "$MAKEINFO" = "no"; then
1198   MAKEINFO=makeinfo
1199   if test "x${with_makeinfo}" = "xno"; then
1200     HAVE_MAKEINFO=no
1201   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1202     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1203 source tree does not seem to have pre-built manuals in the 'info' directory.
1204 Either install a suitable version of makeinfo, or re-run configure
1205 with the '--without-makeinfo' option to build without the manuals.] )
1206   fi
1207 fi
1208 AC_SUBST(HAVE_MAKEINFO)
1209
1210 if test $opsys = mingw32; then
1211    DOCMISC_W32=efaq-w32
1212 else
1213    DOCMISC_W32=
1214 fi
1215 AC_SUBST(DOCMISC_W32)
1216
1217 dnl Add our options to ac_link now, after it is set up.
1218
1219 if test x$GCC = xyes; then
1220   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1221     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1222 else
1223   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1224     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1225 fi
1226
1227 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1228 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1229 dnl (Don't use '-z nocombreloc' as -z takes no arg on Irix.)
1230 dnl Treat GCC specially since it just gives a non-fatal 'unrecognized option'
1231 dnl if not built to support GNU ld.
1232
1233 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1234 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1235 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1236 dnl   Eg "make LDFLAGS=... all" could run into problems,
1237 dnl   http://bugs.debian.org/684788
1238 dnl * unnecessary, since temacs is the only thing that actually needs it.
1239 dnl   Indeed this is where it was originally, prior to:
1240 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1241 late_LDFLAGS="$LDFLAGS"
1242 if test x$GCC = xyes; then
1243   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1244 else
1245   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1246 fi
1247
1248 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1249
1250 AC_MSG_CHECKING([for -znocombreloc])
1251 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1252   [AC_MSG_RESULT(yes)],
1253   LDFLAGS_NOCOMBRELOC=
1254   [AC_MSG_RESULT(no)])
1255
1256 LDFLAGS="$late_LDFLAGS"
1257
1258 AC_CACHE_CHECK([whether addresses are sanitized],
1259   [emacs_cv_sanitize_address],
1260   [AC_COMPILE_IFELSE(
1261      [AC_LANG_PROGRAM(
1262         [[#ifndef __has_feature
1263           #define __has_feature(f) 0
1264           #endif
1265           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1266           #else
1267            error "Addresses are not sanitized.";
1268           #endif
1269         ]])],
1270      [emacs_cv_sanitize_address=yes],
1271      [emacs_cv_sanitize_address=no])])
1272
1273 dnl The function dump-emacs will not be defined and temacs will do
1274 dnl (load "loadup") automatically unless told otherwise.
1275 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1276 case "$opsys" in
1277   nacl) CANNOT_DUMP=yes ;;
1278 esac
1279
1280 if test "$CANNOT_DUMP" = "yes"; then
1281   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1282 elif test "$emacs_cv_sanitize_address" = yes; then
1283   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1284 fi
1285
1286 AC_SUBST(CANNOT_DUMP)
1287
1288
1289 UNEXEC_OBJ=unexelf.o
1290 case "$opsys" in
1291   # MSDOS uses unexcoff.o
1292   aix4-2)
1293    UNEXEC_OBJ=unexaix.o
1294    ;;
1295   cygwin)
1296    UNEXEC_OBJ=unexcw.o
1297    ;;
1298   darwin)
1299    UNEXEC_OBJ=unexmacosx.o
1300    ;;
1301   hpux10-20 | hpux11)
1302    UNEXEC_OBJ=unexhp9k800.o
1303    ;;
1304   mingw32)
1305    UNEXEC_OBJ=unexw32.o
1306    ;;
1307   sol2-10)
1308    # Use the Solaris dldump() function, called from unexsol.c, to dump
1309    # emacs, instead of the generic ELF dump code found in unexelf.c.
1310    # The resulting binary has a complete symbol table, and is better
1311    # for debugging and other observability tools (debuggers, pstack, etc).
1312    #
1313    # If you encounter a problem using dldump(), please consider sending
1314    # a message to the OpenSolaris tools-linking mailing list:
1315    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1316    #
1317    # It is likely that dldump() works with older Solaris too, but this has
1318    # not been tested, so for now this change is for Solaris 10 or newer.
1319    UNEXEC_OBJ=unexsol.o
1320    ;;
1321 esac
1322
1323 LD_SWITCH_SYSTEM=
1324 case "$opsys" in
1325   freebsd|dragonfly)
1326    ## Let 'ld' find image libs and similar things in /usr/local/lib.
1327    ## The system compiler, GCC, has apparently been modified to not
1328    ## look there, contrary to what a stock GCC would do.
1329 ### It's not our place to do this.  See bug#10313#17.
1330 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1331       :
1332    ;;
1333
1334   gnu-linux)
1335    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1336    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1337    ;;
1338
1339   netbsd)
1340 ### It's not our place to do this.  See bug#10313#17.
1341 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1342       :
1343    ;;
1344
1345   openbsd)
1346    ## Han Boetes <han@boetes.org> says this is necessary,
1347    ## otherwise Emacs dumps core on elf systems.
1348    LD_SWITCH_SYSTEM="-Z"
1349    ;;
1350 esac
1351 AC_SUBST(LD_SWITCH_SYSTEM)
1352
1353 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1354
1355 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1356 ## which has not been defined yet.  When this was handled with cpp,
1357 ## it was expanded to null when configure sourced the s/*.h file.
1358 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1359 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1360 ## (or somesuch), but because it is supposed to go at the _front_
1361 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1362 ## Compare with the gnu-linux case below, which added to the end
1363 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1364 ## LD_SWITCH_SYSTEM_TEMACS.
1365 case "$opsys" in
1366   netbsd|openbsd)
1367    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1368 esac
1369
1370
1371 C_SWITCH_MACHINE=
1372 case $canonical in
1373  alpha*)
1374   AC_CHECK_DECL([__ELF__])
1375   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1376     ## With ELF, make sure that all common symbols get allocated to in the
1377     ## data section.  Otherwise, the dump of temacs may miss variables in
1378     ## the shared library that have been initialized.  For example, with
1379     ## GNU libc, __malloc_initialized would normally be resolved to the
1380     ## shared library's .bss section, which is fatal.
1381     if test "x$GCC" = "xyes"; then
1382       C_SWITCH_MACHINE="-fno-common"
1383     else
1384       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1385     fi
1386   else
1387       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1388       dnl albeit under the mistaken assumption that said file
1389       dnl was no longer used.
1390       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1391   fi
1392   ;;
1393 esac
1394 AC_SUBST(C_SWITCH_MACHINE)
1395
1396 AC_SUBST(UNEXEC_OBJ)
1397
1398 C_SWITCH_SYSTEM=
1399 ## Some programs in src produce warnings saying certain subprograms
1400 ## are too complex and need a MAXMEM value greater than 2000 for
1401 ## additional optimization.  --nils@exp-math.uni-essen.de
1402 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1403   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1404 if test "$opsys" = "mingw32"; then
1405   case "$canonical" in
1406     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1407     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1408   esac
1409 fi
1410 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1411 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1412 AC_SUBST(C_SWITCH_SYSTEM)
1413
1414
1415 LIBS_SYSTEM=
1416 case "$opsys" in
1417   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1418   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1419
1420   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1421
1422   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1423
1424   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1425
1426   ## Motif needs -lgen.
1427   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1428 esac
1429
1430 AC_SUBST(LIBS_SYSTEM)
1431
1432 ### Make sure subsequent tests use flags consistent with the build flags.
1433
1434 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1435   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1436 else
1437   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1438 fi
1439
1440 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1441 AC_DEFUN([AC_TYPE_SIZE_T])
1442 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1443 AC_DEFUN([AC_TYPE_UID_T])
1444
1445 # sqrt and other floating-point functions such as fmod and frexp
1446 # are found in -lm on many systems.
1447 OLD_LIBS=$LIBS
1448 AC_SEARCH_LIBS([sqrt], [m])
1449 if test "X$LIBS" = "X$OLD_LIBS"; then
1450   LIB_MATH=
1451 else
1452   LIB_MATH=$ac_cv_search_sqrt
1453 fi
1454 LIBS=$OLD_LIBS
1455
1456 dnl Current possibilities handled by sed (aix4-2 -> aix,
1457 dnl gnu-linux -> gnu/linux, etc.):
1458 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1459 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1460 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1461
1462 case $opsys in
1463   cygwin )
1464     LIB_MATH=
1465     ;;
1466   darwin )
1467     ## Adding -lm confuses the dynamic linker, so omit it.
1468     LIB_MATH=
1469     ;;
1470   freebsd | dragonfly )
1471     SYSTEM_TYPE=berkeley-unix
1472     ;;
1473   gnu-linux | gnu-kfreebsd )
1474     ;;
1475   hpux10-20 | hpux11 )
1476     ;;
1477   mingw32 )
1478     LIB_MATH=
1479     SYSTEM_TYPE=windows-nt
1480     ;;
1481   dnl NB this may be adjusted below.
1482   netbsd | openbsd )
1483     SYSTEM_TYPE=berkeley-unix
1484     ;;
1485
1486   sol2* | unixware )
1487     SYSTEM_TYPE=usg-unix-v
1488     ;;
1489
1490 esac
1491
1492 AC_SUBST(LIB_MATH)
1493 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1494   [The type of system you are compiling for; sets 'system-type'.])
1495
1496
1497 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1498 pre_PKG_CONFIG_LIBS=$LIBS
1499
1500 PKG_PROG_PKG_CONFIG(0.9.0)
1501
1502 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1503 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1504 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1505 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1506 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1507 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1508 dnl actions.
1509 AC_DEFUN([EMACS_CHECK_MODULES],
1510   [PKG_CHECK_MODULES([$1], [$2],
1511      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1512       m4_default([$3], [HAVE_$1=yes])],
1513      [m4_default([$4], [HAVE_$1=no])])])
1514
1515 HAVE_SOUND=no
1516 if test "${with_sound}" != "no"; then
1517   # Sound support for GNU/Linux, the free BSDs, MinGW, and Cygwin.
1518   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1519     have_sound_header=yes, [], [
1520     #ifdef __MINGW32__
1521     #define WIN32_LEAN_AND_MEAN
1522     #include <windows.h>
1523     #endif
1524     ])
1525   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1526     AC_MSG_ERROR([OSS sound support requested but not found.])
1527
1528   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1529     # Emulation library used on NetBSD.
1530     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1531     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1532       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1533     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1534     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1535   fi
1536   AC_SUBST(LIBSOUND)
1537
1538   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1539     ALSA_REQUIRED=1.0.0
1540     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1541     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1542     if test $HAVE_ALSA = yes; then
1543       SAVE_CFLAGS="$CFLAGS"
1544       SAVE_LIBS="$LIBS"
1545       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1546       LIBS="$ALSA_LIBS $LIBS"
1547       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1548                       emacs_alsa_normal=yes,
1549                     emacs_alsa_normal=no)
1550       if test "$emacs_alsa_normal" != yes; then
1551         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1552                        [[snd_lib_error_set_handler (0);]])],
1553                        emacs_alsa_subdir=yes,
1554                      emacs_alsa_subdir=no)
1555         if test "$emacs_alsa_subdir" != yes; then
1556           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1557         fi
1558         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1559       fi
1560
1561       CFLAGS="$SAVE_CFLAGS"
1562       LIBS="$SAVE_LIBS"
1563       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1564       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1565       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1566     elif test "${with_sound}" = "alsa"; then
1567       AC_MSG_ERROR([ALSA sound support requested but not found.])
1568     fi
1569   fi                            dnl with_sound = alsa|yes
1570
1571   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1572   dnl compiles only on the specified platforms.  For others, it
1573   dnl probably doesn't make sense to try.
1574   dnl FIXME So surely we should bypass this whole section if not using
1575   dnl one of these platforms?
1576   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1577      case "$opsys" in
1578        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1579        dnl Adjust the --with-sound help text if you change this.
1580        gnu-linux|freebsd|netbsd|mingw32|cygwin)
1581          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1582          HAVE_SOUND=yes
1583          ;;
1584      esac
1585   fi
1586
1587   AC_SUBST(CFLAGS_SOUND)
1588 fi
1589
1590 dnl checks for header files
1591 AC_CHECK_HEADERS_ONCE(
1592   malloc.h
1593   sys/systeminfo.h
1594   sys/sysinfo.h
1595   coff.h pty.h
1596   sys/resource.h
1597   sys/utsname.h pwd.h utmp.h util.h)
1598
1599 AC_MSG_CHECKING(if personality LINUX32 can be set)
1600 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1601                emacs_cv_personality_linux32=yes,
1602                emacs_cv_personality_linux32=no)
1603 AC_MSG_RESULT($emacs_cv_personality_linux32)
1604
1605 if test $emacs_cv_personality_linux32 = yes; then
1606   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1607             [Define to 1 if personality LINUX32 can be set.])
1608 fi
1609
1610 # Note that Solaris has sys/sysinfo.h which defines struct
1611 # sysinfo as well.  To make sure that we're using GNU/Linux
1612 # sysinfo, we explicitly set one of its fields.
1613 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1614   AC_MSG_CHECKING([if Linux sysinfo may be used])
1615   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1616                                      [[struct sysinfo si;
1617                                        si.totalram = 0;
1618                                        sysinfo (&si)]])],
1619     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1620   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1621   if test $emacs_cv_linux_sysinfo = yes; then
1622     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1623     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1624                                        [[struct sysinfo si; return si.mem_unit]])],
1625       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1626                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1627   fi
1628 fi
1629
1630 dnl On Solaris 8 there's a compilation warning for term.h because
1631 dnl it doesn't define 'bool'.
1632 AC_CHECK_HEADERS(term.h, , , -)
1633 AC_HEADER_TIME
1634 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1635                                       ]])
1636 if test $ac_cv_have_decl_sys_siglist != yes; then
1637   # For Tru64, at least:
1638   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1639                                           ]])
1640 fi
1641 AC_HEADER_SYS_WAIT
1642
1643 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1644 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1645 #if HAVE_SYS_SOCKET_H
1646 #include <sys/socket.h>
1647 #endif])
1648 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1649 #if HAVE_SYS_SOCKET_H
1650 #include <sys/socket.h>
1651 #endif])
1652 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1653 #if HAVE_SYS_SOCKET_H
1654 #include <sys/socket.h>
1655 #endif])
1656
1657 dnl checks for structure members
1658 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1659                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1660                   struct ifreq.ifr_addr,
1661                   struct ifreq.ifr_addr.sa_len], , ,
1662                  [AC_INCLUDES_DEFAULT
1663 #if HAVE_SYS_SOCKET_H
1664 #include <sys/socket.h>
1665 #endif
1666 #if HAVE_NET_IF_H
1667 #include <net/if.h>
1668 #endif])
1669
1670 dnl Check for endianness.
1671 dnl AC_C_BIGENDIAN is done by gnulib.
1672
1673 dnl check for Make feature
1674
1675 AUTO_DEPEND=no
1676 dnl check if we have GCC and autodepend is on.
1677 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1678    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1679    SAVE_CFLAGS="$CFLAGS"
1680    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1681    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1682    CFLAGS="$SAVE_CFLAGS"
1683    test -f deps.d || ac_enable_autodepend=no
1684    rm -rf deps.d
1685    AC_MSG_RESULT([$ac_enable_autodepend])
1686    if test $ac_enable_autodepend = yes; then
1687       AUTO_DEPEND=yes
1688    fi
1689 fi
1690 AC_SUBST(AUTO_DEPEND)
1691
1692 dnl checks for operating system services
1693 AC_SYS_LONG_FILE_NAMES
1694
1695 #### Choose a window system.
1696
1697 ## We leave window_system equal to none if
1698 ## we end up building without one.  Any new window system should
1699 ## set window_system to an appropriate value and add objects to
1700 ## window-system-specific substs.
1701
1702 window_system=none
1703 AC_PATH_X
1704 if test "$no_x" != yes; then
1705   window_system=x11
1706 fi
1707
1708 LD_SWITCH_X_SITE_RPATH=
1709 if test "${x_libraries}" != NONE; then
1710   if test -n "${x_libraries}"; then
1711     LD_SWITCH_X_SITE=-L`AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -L/g'`
1712     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`
1713       AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -Wl,-rpath,/g'
1714     `
1715   fi
1716   x_default_search_path=""
1717   x_search_path=${x_libraries}
1718   if test -z "${x_search_path}"; then
1719     x_search_path=/usr/lib
1720   fi
1721   for x_library in `AS_ECHO(["$x_search_path:"]) | \
1722                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1723     x_search_path="\
1724 ${x_library}/X11/%L/%T/%N%C%S:\
1725 ${x_library}/X11/%l/%T/%N%C%S:\
1726 ${x_library}/X11/%T/%N%C%S:\
1727 ${x_library}/X11/%L/%T/%N%S:\
1728 ${x_library}/X11/%l/%T/%N%S:\
1729 ${x_library}/X11/%T/%N%S"
1730     if test x"${x_default_search_path}" = x; then
1731       x_default_search_path=${x_search_path}
1732     else
1733       x_default_search_path="${x_search_path}:${x_default_search_path}"
1734     fi
1735   done
1736 fi
1737 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1738
1739 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1740   C_SWITCH_X_SITE=$isystem`AS_ECHO(["$x_includes"]) | sed -e "s/:/ $isystem/g"`
1741 fi
1742
1743 if test x"${x_includes}" = x; then
1744   bitmapdir=/usr/include/X11/bitmaps
1745 else
1746   # accumulate include directories that have X11 bitmap subdirectories
1747   bmd_acc=
1748   for bmd in `AS_ECHO(["$x_includes"]) | sed -e 's/:/ /g'`; do
1749     if test -d "${bmd}/X11/bitmaps"; then
1750       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1751     fi
1752     if test -d "${bmd}/bitmaps"; then
1753       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1754     fi
1755   done
1756   bitmapdir=${bmd_acc#:}
1757 fi
1758
1759 test "${with_ns}" = maybe && test "${opsys}" != darwin && with_ns=no
1760 HAVE_NS=no
1761 NS_GNUSTEP_CONFIG=no
1762 NS_IMPL_COCOA=no
1763 NS_IMPL_GNUSTEP=no
1764 tmp_CPPFLAGS="$CPPFLAGS"
1765 tmp_CFLAGS="$CFLAGS"
1766 CPPFLAGS="$CPPFLAGS -x objective-c"
1767 CFLAGS="$CFLAGS -x objective-c"
1768 GNU_OBJC_CFLAGS=
1769 LIBS_GNUSTEP=
1770 if test "${with_ns}" != no; then
1771   if test "${opsys}" = darwin; then
1772      NS_IMPL_COCOA=yes
1773      ns_appdir=`pwd`/nextstep/Emacs.app
1774      ns_appbindir=${ns_appdir}/Contents/MacOS
1775      ns_appresdir=${ns_appdir}/Contents/Resources
1776      ns_appsrc=Cocoa/Emacs.base
1777      ns_fontfile=macfont.o
1778   elif flags=$( (gnustep-config --objc-flags) 2>/dev/null); then
1779      NS_IMPL_GNUSTEP=yes
1780      NS_GNUSTEP_CONFIG=yes
1781      GNU_OBJC_CFLAGS=$flags
1782      LIBS_GNUSTEP=$(gnustep-config --gui-libs) || exit
1783   elif test -f $GNUSTEP_CONFIG_FILE; then
1784      NS_IMPL_GNUSTEP=yes
1785      dnl FIXME sourcing this several times in subshells seems inefficient.
1786      GNUSTEP_SYSTEM_HEADERS=$(
1787        . $GNUSTEP_CONFIG_FILE
1788        AS_ECHO(["$GNUSTEP_SYSTEM_HEADERS"])
1789      )
1790      GNUSTEP_SYSTEM_LIBRARIES=$(
1791        . $GNUSTEP_CONFIG_FILE
1792        AS_ECHO(["$GNUSTEP_SYSTEM_LIBRARIES"])
1793      )
1794      dnl I seemed to need these as well with GNUstep-startup 0.25.
1795      GNUSTEP_LOCAL_HEADERS=$(
1796        . $GNUSTEP_CONFIG_FILE
1797        AS_ECHO(["$GNUSTEP_LOCAL_HEADERS"])
1798      )
1799      GNUSTEP_LOCAL_LIBRARIES=$(
1800        . $GNUSTEP_CONFIG_FILE
1801        AS_ECHO(["$GNUSTEP_LOCAL_LIBRARIES"])
1802      )
1803      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1804        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1805      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1806        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1807      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1808      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1809      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1810      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1811      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1812      dnl If they had chosen to either define it or not, we could have
1813      dnl just used AC_CHECK_DECL here.
1814      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1815        emacs_cv_objc_exceptions,
1816 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1817 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1818 1;
1819 #else
1820 fail;
1821 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1822      if test $emacs_cv_objc_exceptions = yes; then
1823        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1824        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1825          [Define if GNUstep uses ObjC exceptions.])
1826        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1827      fi
1828   fi
1829   if test $NS_IMPL_GNUSTEP = yes; then
1830      ns_appdir=`pwd`/nextstep/Emacs.app
1831      ns_appbindir=${ns_appdir}
1832      ns_appresdir=${ns_appdir}/Resources
1833      ns_appsrc=GNUstep/Emacs.base
1834      ns_fontfile=nsfont.o
1835   fi
1836
1837   dnl This is only used while we test the NS headers, it gets reset below.
1838   CPPFLAGS="$CPPFLAGS $GNU_OBJC_CFLAGS"
1839   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1840
1841   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1842                   [AC_MSG_ERROR([The include files (AppKit/AppKit.h etc) that
1843 are required for a Nextstep build are missing or cannot be compiled.
1844 Either fix this, or re-configure with the option '--without-ns'.])])
1845
1846   macfont_file=""
1847   if test "${NS_IMPL_COCOA}" = "yes"; then
1848     AC_MSG_CHECKING([for OSX 10.6 or newer])
1849     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1850                                      [
1851 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1852 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1060
1853  ; /* OK */
1854 #else
1855  error "OSX 10.6 or newer required";
1856 #endif
1857 #endif
1858                     ])],
1859                     ns_osx_have_106=yes,
1860                     ns_osx_have_106=no)
1861     AC_MSG_RESULT([$ns_osx_have_106])
1862
1863     if test $ns_osx_have_106 = no; then
1864        AC_MSG_ERROR([OSX 10.6 or newer is required]);
1865     fi
1866   fi
1867 fi
1868
1869 AC_SUBST(LIBS_GNUSTEP)
1870
1871 INSTALL_ARCH_INDEP_EXTRA=install-etc
1872 ns_self_contained=no
1873 NS_OBJ=
1874 NS_OBJC_OBJ=
1875 if test "${HAVE_NS}" = yes; then
1876   if test "$with_toolkit_scroll_bars" = "no"; then
1877     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1878   fi
1879
1880   window_system=nextstep
1881   # set up packaging dirs
1882   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1883      ns_self_contained=yes
1884      prefix=${ns_appresdir}
1885      exec_prefix=${ns_appbindir}
1886      dnl This one isn't really used, only archlibdir is.
1887      libexecdir="\${ns_appbindir}/libexec"
1888      archlibdir="\${ns_appbindir}/libexec"
1889      etcdocdir="\${ns_appresdir}/etc"
1890      etcdir="\${ns_appresdir}/etc"
1891      dnl FIXME maybe set datarootdir instead.
1892      dnl That would also get applications, icons, man.
1893      infodir="\${ns_appresdir}/info"
1894      mandir="\${ns_appresdir}/man"
1895      lispdir="\${ns_appresdir}/lisp"
1896      test "$locallisppathset" = no && locallisppath=""
1897      INSTALL_ARCH_INDEP_EXTRA=
1898   fi
1899
1900   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o $ns_fontfile"
1901 fi
1902 CFLAGS="$tmp_CFLAGS"
1903 CPPFLAGS="$tmp_CPPFLAGS"
1904 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1905 AC_SUBST(ns_self_contained)
1906 AC_SUBST(NS_OBJ)
1907 AC_SUBST(NS_OBJC_OBJ)
1908
1909 HAVE_W32=no
1910 W32_OBJ=
1911 W32_LIBS=
1912 EMACSRES=
1913 CLIENTRES=
1914 CLIENTW=
1915 W32_RES_LINK=
1916 EMACS_MANIFEST=
1917 UPDATE_MANIFEST=
1918 if test "${with_w32}" != no; then
1919   case "${opsys}" in
1920     cygwin)
1921       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1922              [AC_MSG_ERROR(['--with-w32' was specified, but windows.h
1923                    cannot be found.])])
1924     ;;
1925     mingw32)
1926     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1927     ;;
1928     *)
1929       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1930     ;;
1931   esac
1932 fi
1933
1934 if test "${opsys}" = "mingw32"; then
1935   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1936   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1937      #include <windows.h>
1938      #include <usp10.h>]],
1939    [[PIMAGE_NT_HEADERS pHeader;
1940      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1941    [emacs_cv_w32api=yes
1942     HAVE_W32=yes],
1943    emacs_cv_w32api=no)
1944   AC_MSG_RESULT($emacs_cv_w32api)
1945   if test "${emacs_cv_w32api}" = "no"; then
1946     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1947   fi
1948 fi
1949
1950 FIRSTFILE_OBJ=
1951 NTDIR=
1952 LIBS_ECLIENT=
1953 LIB_WSOCK32=
1954 NTLIB=
1955 CM_OBJ="cm.o"
1956 XARGS_LIMIT=
1957 if test "${HAVE_W32}" = "yes"; then
1958   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1959   if test "$with_toolkit_scroll_bars" = "no"; then
1960     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for w32 build.])
1961   fi
1962   AC_CHECK_TOOL(WINDRES, [windres],
1963                 [AC_MSG_ERROR([No resource compiler found.])])
1964   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1965   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1966   EMACSRES="emacs.res"
1967   case "$canonical" in
1968     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1969     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1970   esac
1971   dnl Construct something of the form "24,4,0,0" with 4 components.
1972   comma_version=`echo "${PACKAGE_VERSION}.0.0" | sed -e 's/\./,/g' -e 's/^\([[^,]]*,[[^,]]*,[[^,]]*,[[^,]]*\).*/\1/'`
1973
1974   comma_space_version=`echo "$comma_version" | sed 's/,/, /g'`
1975   AC_SUBST(comma_version)
1976   AC_SUBST(comma_space_version)
1977   AC_CONFIG_FILES([nt/emacs.rc nt/emacsclient.rc])
1978   if test "${opsys}" = "cygwin"; then
1979     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1980     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1981     # Tell the linker that emacs.res is an object (which we compile from
1982     # the rc file), not a linker script.
1983     W32_RES_LINK="-Wl,emacs.res"
1984   else
1985     UPDATE_MANIFEST=update-game-score.exe.manifest
1986     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1987     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1988     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1989     W32_RES_LINK="\$(EMACSRES)"
1990     CLIENTRES="emacsclient.res"
1991     CLIENTW="emacsclientw\$(EXEEXT)"
1992     FIRSTFILE_OBJ=firstfile.o
1993     NTDIR=nt
1994     CM_OBJ=
1995     LIBS_ECLIENT="-lcomctl32"
1996     LIB_WSOCK32="-lwsock32"
1997     NTLIB="ntlib.$ac_objext"
1998     XARGS_LIMIT="-s 10000"
1999   fi
2000 fi
2001 AC_SUBST(W32_OBJ)
2002 AC_SUBST(W32_LIBS)
2003 AC_SUBST(EMACSRES)
2004 AC_SUBST(EMACS_MANIFEST)
2005 AC_SUBST(UPDATE_MANIFEST)
2006 AC_SUBST(CLIENTRES)
2007 AC_SUBST(CLIENTW)
2008 AC_SUBST(W32_RES_LINK)
2009 AC_SUBST(FIRSTFILE_OBJ)
2010 AC_SUBST(NTDIR)
2011 AC_SUBST(CM_OBJ)
2012 AC_SUBST(LIBS_ECLIENT)
2013 AC_SUBST(LIB_WSOCK32)
2014 AC_SUBST(NTLIB)
2015 AC_SUBST(XARGS_LIMIT)
2016
2017 if test "${HAVE_W32}" = "yes"; then
2018   window_system=w32
2019   with_xft=no
2020 fi
2021
2022 ## $window_system is now set to the window system we will
2023 ## ultimately use.
2024
2025 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
2026    # Too many warnings for now.
2027    nw=
2028    nw="$nw -Wsuggest-attribute=noreturn"
2029    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
2030
2031    gl_WARN_ADD([-Wno-unused-variable])
2032    gl_WARN_ADD([-Wno-unused-but-set-variable])
2033    gl_WARN_ADD([-Wno-unused-but-set-parameter])
2034 fi
2035
2036 term_header=
2037 HAVE_X_WINDOWS=no
2038 HAVE_X11=no
2039 USE_X_TOOLKIT=none
2040
2041 case "${window_system}" in
2042   x11 )
2043     HAVE_X_WINDOWS=yes
2044     HAVE_X11=yes
2045     term_header=xterm.h
2046     case "${with_x_toolkit}" in
2047       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
2048       motif ) USE_X_TOOLKIT=MOTIF ;;
2049       gtk ) with_gtk=yes
2050             term_header=gtkutil.h
2051 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
2052 dnl USE_X_TOOLKIT is set.
2053             USE_X_TOOLKIT=none ;;
2054       gtk2 ) with_gtk2=yes
2055              term_header=gtkutil.h
2056              USE_X_TOOLKIT=none ;;
2057       gtk3 ) with_gtk3=yes
2058              term_header=gtkutil.h
2059              USE_X_TOOLKIT=none ;;
2060       no ) USE_X_TOOLKIT=none ;;
2061 dnl If user did not say whether to use a toolkit, make this decision later:
2062 dnl use the toolkit if we have gtk, or X11R5 or newer.
2063       * ) USE_X_TOOLKIT=maybe ;;
2064     esac
2065   ;;
2066   nextstep )
2067     term_header=nsterm.h
2068   ;;
2069   w32 )
2070     term_header=w32term.h
2071   ;;
2072 esac
2073
2074 if test "$window_system" = none && test "X$with_x" != "Xno"; then
2075    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
2076    if test "$HAVE_XSERVER" = true ||
2077       test -n "$DISPLAY" ||
2078       {
2079         for emacs_libX11 in /usr/lib/libX11.*; do break; done
2080         test "$emacs_libX11" != '/usr/lib/libX11.*'
2081       }
2082    then
2083         AC_MSG_ERROR([You seem to be running X, but no X development libraries
2084 were found.  You should install the relevant development files for X
2085 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2086 sure you have development files for image handling, i.e.
2087 tiff, gif, jpeg, png and xpm.
2088 If you are sure you want Emacs compiled without X window support, pass
2089   --without-x
2090 to configure.])
2091    fi
2092 fi
2093
2094 # Does the opsystem file prohibit the use of the GNU malloc?
2095 # Assume not, until told otherwise.
2096 GNU_MALLOC=yes
2097
2098 AC_CACHE_CHECK(
2099   [whether malloc is Doug Lea style],
2100   [emacs_cv_var_doug_lea_malloc],
2101   [emacs_cv_var_doug_lea_malloc=no
2102    dnl Hooks do not work with address sanitization.
2103    if test "$emacs_cv_sanitize_address" != yes; then
2104      AC_LINK_IFELSE(
2105        [AC_LANG_PROGRAM(
2106           [[#include <malloc.h>
2107             static void hook (void) {}]],
2108           [[malloc_set_state (malloc_get_state ());
2109             __after_morecore_hook = hook;
2110             __malloc_initialize_hook = hook;]])],
2111        [emacs_cv_var_doug_lea_malloc=yes])
2112    fi])
2113 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2114
2115 system_malloc=$emacs_cv_sanitize_address
2116
2117 hybrid_malloc=
2118
2119 case "$opsys" in
2120   ## darwin ld insists on the use of malloc routines in the System framework.
2121   darwin | mingw32 | nacl | sol2-10) system_malloc=yes ;;
2122   cygwin) hybrid_malloc=yes;;
2123 esac
2124
2125 if test "${system_malloc}" != yes && test "${doug_lea_malloc}" != yes \
2126    && test "${UNEXEC_OBJ}" = unexelf.o; then
2127   hybrid_malloc=yes
2128 fi
2129
2130 GMALLOC_OBJ=
2131 HYBRID_MALLOC=
2132 if test "${system_malloc}" = "yes"; then
2133   AC_DEFINE([SYSTEM_MALLOC], 1,
2134     [Define to 1 to use the system memory allocator, even if it is not
2135      Doug Lea style.])
2136   GNU_MALLOC=no
2137   GNU_MALLOC_reason="
2138     (The GNU allocators don't work with this system configuration.)"
2139   VMLIMIT_OBJ=
2140 elif test "$hybrid_malloc" = yes; then
2141   AC_DEFINE(HYBRID_MALLOC, 1,
2142     [Define to use gmalloc before dumping and the system malloc after.])
2143   HYBRID_MALLOC=1
2144   GNU_MALLOC=
2145   GNU_MALLOC_reason="only before dumping"
2146   GMALLOC_OBJ=gmalloc.o
2147   VMLIMIT_OBJ=
2148 else
2149   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2150   VMLIMIT_OBJ=vm-limit.o
2151
2152   AC_CHECK_HEADERS([sys/vlimit.h])
2153   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2154     [AC_LINK_IFELSE(
2155        [AC_LANG_PROGRAM(
2156          [[extern char data_start[]; char ch;]],
2157          [[return data_start < &ch;]])],
2158        [emacs_cv_data_start=yes],
2159        [emacs_cv_data_start=no])])
2160   if test $emacs_cv_data_start = yes; then
2161     AC_DEFINE([HAVE_DATA_START], 1,
2162       [Define to 1 if data_start is the address of the start
2163        of the main data segment.])
2164   fi
2165 fi
2166 AC_SUBST([HYBRID_MALLOC])
2167 AM_CONDITIONAL([HYBRID_MALLOC_LIB], [test -n "$HYBRID_MALLOC"])
2168 AC_SUBST(GMALLOC_OBJ)
2169 AC_SUBST(VMLIMIT_OBJ)
2170
2171 if test "$doug_lea_malloc" = "yes" && test "$hybrid_malloc" != yes; then
2172   if test "$GNU_MALLOC" = yes ; then
2173     GNU_MALLOC_reason="
2174       (Using Doug Lea's new malloc from the GNU C Library.)"
2175   fi
2176   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2177     [Define to 1 if the system memory allocator is Doug Lea style,
2178      with malloc hooks and malloc_set_state.])
2179
2180   ## Use mmap directly for allocating larger buffers.
2181   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2182   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2183   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2184   case "$opsys" in
2185     mingw32|gnu*) REL_ALLOC=no ;;
2186   esac
2187 fi
2188
2189 if test x"${REL_ALLOC}" = x; then
2190   REL_ALLOC=${GNU_MALLOC}
2191 fi
2192
2193 use_mmap_for_buffers=no
2194 case "$opsys" in
2195   cygwin|mingw32|irix6-5) use_mmap_for_buffers=yes ;;
2196 esac
2197
2198 AC_FUNC_MMAP
2199 if test $use_mmap_for_buffers = yes; then
2200   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2201   REL_ALLOC=no
2202 fi
2203
2204 LIBS="$LIBS_SYSTEM $LIBS"
2205
2206 dnl FIXME replace main with a function we actually want from this library.
2207 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2208
2209 dnl Check for the POSIX thread library.
2210 LIB_PTHREAD=
2211 AC_CHECK_HEADERS_ONCE(pthread.h)
2212 if test "$ac_cv_header_pthread_h" && test "$opsys" != "mingw32"; then
2213   AC_CACHE_CHECK([for pthread library],
2214     [emacs_cv_pthread_lib],
2215     [emacs_cv_pthread_lib=no
2216      OLD_LIBS=$LIBS
2217      for emacs_pthread_lib in 'none needed' -lpthread; do
2218        case $emacs_pthread_lib in
2219          -*) LIBS="$OLD_LIBS $emacs_pthread_lib";;
2220        esac
2221        AC_LINK_IFELSE(
2222          [AC_LANG_PROGRAM(
2223             [[#include <pthread.h>
2224               #include <signal.h>
2225               sigset_t old_mask, new_mask;
2226               void noop (void) {}]],
2227             [[pthread_t th = pthread_self ();
2228               int status = 0;
2229               status += pthread_create (&th, 0, 0, 0);
2230               status += pthread_sigmask (SIG_BLOCK, &new_mask, &old_mask);
2231               status += pthread_kill (th, 0);
2232               #if ! (defined SYSTEM_MALLOC || defined HYBRID_MALLOC \
2233                      || defined DOUG_LEA_MALLOC)
2234               /* Test for pthread_atfork only if gmalloc uses it,
2235                  as older-style hosts like MirBSD 10 lack it.  */
2236               status += pthread_atfork (noop, noop, noop);
2237               #endif
2238               return status;]])],
2239          [emacs_cv_pthread_lib=$emacs_pthread_lib])
2240        LIBS=$OLD_LIBS
2241        if test "$emacs_cv_pthread_lib" != no; then
2242          break
2243        fi
2244      done])
2245   if test "$emacs_cv_pthread_lib" != no; then
2246     AC_DEFINE([HAVE_PTHREAD], 1, [Define to 1 if you have POSIX threads.])
2247     case $emacs_cv_pthread_lib in
2248       -*) LIB_PTHREAD=$emacs_cv_pthread_lib;;
2249     esac
2250     ac_cv_func_pthread_sigmask=yes
2251     # Some systems optimize for single-threaded programs by default, and
2252     # need special flags to disable these optimizations. For example, the
2253     # definition of 'errno' in <errno.h>.
2254     case $opsys in
2255       hpux* | sol*)
2256         AC_DEFINE([_REENTRANT], 1,
2257           [Define to 1 if your system requires this in multithreaded code.]);;
2258       aix4-2)
2259         AC_DEFINE([_THREAD_SAFE], 1,
2260           [Define to 1 if your system requires this in multithreaded code.]);;
2261     esac
2262   fi
2263 fi
2264 AC_SUBST([LIB_PTHREAD])
2265
2266 dnl Check for need for bigtoc support on IBM AIX
2267
2268 case ${host_os} in
2269 aix*)
2270   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2271     case $GCC in
2272     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2273     *) gdb_cv_bigtoc=-bbigtoc ;;
2274     esac
2275
2276     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2277     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2278   ])
2279   ;;
2280 esac
2281
2282 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2283 # is for the tests that follow.  We set them back later on.
2284
2285 REAL_CFLAGS="$CFLAGS"
2286 REAL_CPPFLAGS="$CPPFLAGS"
2287 REAL_LIBS="$LIBS"
2288
2289 if test "${HAVE_X11}" = "yes"; then
2290   DEFS="$C_SWITCH_X_SITE $DEFS"
2291   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2292   LIBS="-lX11 $LIBS"
2293   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2294   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2295
2296   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2297   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2298   # but it's more convenient here to set LD_RUN_PATH since this
2299   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2300   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2301     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2302     export LD_RUN_PATH
2303   fi
2304
2305   if test "${opsys}" = "gnu-linux"; then
2306     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2307     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2308      [[XOpenDisplay ("foo");]])],
2309      [xgnu_linux_first_failure=no],
2310      [xgnu_linux_first_failure=yes])
2311     if test "${xgnu_linux_first_failure}" = "yes"; then
2312       OLD_CPPFLAGS="$CPPFLAGS"
2313       OLD_LIBS="$LIBS"
2314       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2315       LIBS="$LIBS -b i486-linuxaout"
2316       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2317        [[XOpenDisplay ("foo");]])],
2318        [xgnu_linux_second_failure=no],
2319        [xgnu_linux_second_failure=yes])
2320       if test "${xgnu_linux_second_failure}" = "yes"; then
2321         # If we get the same failure with -b, there is no use adding -b.
2322         # So leave it out.  This plays safe.
2323         AC_MSG_RESULT(no)
2324       else
2325         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2326         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2327         AC_MSG_RESULT(yes)
2328       fi
2329       CPPFLAGS=$OLD_CPPFLAGS
2330       LIBS=$OLD_LIBS
2331     else
2332       AC_MSG_RESULT(no)
2333     fi
2334   fi
2335
2336   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2337   # header files included from there.
2338   AC_MSG_CHECKING(for Xkb)
2339   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2340 #include <X11/XKBlib.h>]],
2341         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2342         emacs_xkb=yes, emacs_xkb=no)
2343   AC_MSG_RESULT($emacs_xkb)
2344   if test $emacs_xkb = yes; then
2345     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2346   fi
2347
2348   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2349 XScreenNumberOfScreen)
2350 fi
2351
2352 if test "${window_system}" = "x11"; then
2353   AC_MSG_CHECKING(X11 version 6)
2354   AC_CACHE_VAL(emacs_cv_x11_version_6,
2355   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2356 [[#if XlibSpecificationRelease < 6
2357 fail;
2358 #endif
2359 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2360   if test $emacs_cv_x11_version_6 = yes; then
2361     AC_MSG_RESULT(6 or newer)
2362     AC_DEFINE(HAVE_X11R6, 1,
2363               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2364     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2365     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2366     ## XIM support.
2367     case "$opsys" in
2368       sol2-*) : ;;
2369       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2370            [Define if you have usable X11R6-style XIM support.])
2371          ;;
2372     esac
2373   else
2374     AC_MSG_RESULT(before 6)
2375   fi
2376 fi
2377
2378
2379 ### Use -lrsvg-2 if available, unless '--with-rsvg=no' is specified.
2380 HAVE_RSVG=no
2381 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2382   if test "${with_rsvg}" != "no"; then
2383     RSVG_REQUIRED=2.11.0
2384     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2385
2386     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2387     AC_SUBST(RSVG_CFLAGS)
2388     AC_SUBST(RSVG_LIBS)
2389
2390     if test $HAVE_RSVG = yes; then
2391       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2392       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2393       # Windows loads librsvg dynamically
2394       if test "${opsys}" = "mingw32"; then
2395         RSVG_LIBS=
2396       fi
2397     fi
2398   fi
2399 fi
2400
2401 HAVE_IMAGEMAGICK=no
2402 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2403   if test "${with_imagemagick}" != "no"; then
2404     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2405     ## 6.8.2 makes Emacs crash; see Bug#13867.
2406     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2407     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2408     AC_SUBST(IMAGEMAGICK_CFLAGS)
2409     AC_SUBST(IMAGEMAGICK_LIBS)
2410
2411     if test $HAVE_IMAGEMAGICK = yes; then
2412       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2413       OLD_CFLAGS=$CFLAGS
2414       OLD_LIBS=$LIBS
2415       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2416       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2417       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers MagickAutoOrientImage)
2418       CFLAGS=$OLD_CFLAGS
2419       LIBS=$OLD_LIBS
2420     fi
2421   fi
2422 fi
2423
2424
2425 HAVE_GTK=no
2426 GTK_OBJ=
2427 gtk_term_header=$term_header
2428 check_gtk2=no
2429 gtk3_pkg_errors=
2430 if test "${opsys}" != "mingw32"; then
2431   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2432     GLIB_REQUIRED=2.28
2433     GTK_REQUIRED=3.0
2434     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2435
2436     dnl Checks for libraries.
2437     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2438       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2439     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2440        AC_MSG_ERROR($GTK_PKG_ERRORS)
2441     fi
2442     if test "$pkg_check_gtk" = "yes"; then
2443        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2444        GTK_OBJ=emacsgtkfixed.o
2445        gtk_term_header=gtkutil.h
2446        USE_GTK_TOOLKIT="GTK3"
2447        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2448          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2449            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2450          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2451            [Define to 1 to disable Glib deprecation warnings.])
2452        fi
2453     else
2454        check_gtk2=yes
2455        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2456     fi
2457   fi
2458
2459   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2460     GLIB_REQUIRED=2.10
2461     GTK_REQUIRED=2.10
2462     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2463
2464     dnl Checks for libraries.
2465     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2466       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2467     if test "$pkg_check_gtk" = "no" &&
2468        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2469     then
2470       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2471     fi
2472     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2473   fi
2474 fi
2475
2476 OLD_CFLAGS=$CFLAGS
2477 OLD_LIBS=$LIBS
2478
2479 if test x"$pkg_check_gtk" = xyes; then
2480
2481   AC_SUBST(GTK_LIBS)
2482   CFLAGS="$CFLAGS $GTK_CFLAGS"
2483   LIBS="$GTK_LIBS $LIBS"
2484   dnl Try to compile a simple GTK program.
2485   AC_MSG_CHECKING([whether GTK compiles])
2486   GTK_COMPILES=no
2487   AC_LINK_IFELSE(
2488     [AC_LANG_PROGRAM(
2489        [[/* Check the Gtk and Glib APIs.  */
2490          #include <gtk/gtk.h>
2491          #include <glib-object.h>
2492          static void
2493          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2494          {}
2495        ]],
2496        [[
2497          GtkSettings *gs = 0;
2498          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2499             strict C prohibits this.  Use gtk_main_iteration to test that the
2500             libraries are there.  */
2501          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2502                                     0, 0, 0, G_CALLBACK (callback), 0))
2503            gtk_main_iteration ();
2504        ]])],
2505     [GTK_COMPILES=yes])
2506   AC_MSG_RESULT([$GTK_COMPILES])
2507   if test "${GTK_COMPILES}" != "yes"; then
2508     GTK_OBJ=
2509     if test "$USE_X_TOOLKIT" != "maybe"; then
2510       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2511     fi
2512   else
2513     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2514     HAVE_GTK=yes
2515     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2516     GTK_OBJ="gtkutil.o $GTK_OBJ"
2517     term_header=$gtk_term_header
2518     USE_X_TOOLKIT=none
2519     AC_MSG_WARN([[Your version of Gtk+ will have problems with
2520        closing open displays.  This is no problem if you just use
2521        one display, but if you use more than one and close one of them
2522        Emacs may crash.
2523        See http://bugzilla.gnome.org/show_bug.cgi?id=85715]])
2524     sleep 3
2525   fi
2526
2527 fi
2528 AC_SUBST(GTK_OBJ)
2529
2530
2531 if test "${HAVE_GTK}" = "yes"; then
2532
2533   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2534   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2535   if test "$with_toolkit_scroll_bars" != no; then
2536     with_toolkit_scroll_bars=yes
2537   fi
2538
2539   dnl  Check if we have the old file selection dialog declared and
2540   dnl  in the link library.  In 2.x it may be in the library,
2541   dnl  but not declared if deprecated featured has been selected out.
2542   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2543   HAVE_GTK_FILE_SELECTION=no
2544   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2545                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2546 #include <gtk/gtk.h>])
2547   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2548     AC_CHECK_FUNCS(gtk_file_selection_new)
2549   fi
2550
2551   dnl Same as above for gtk_handle_box.
2552   HAVE_GTK_HANDLE_BOX=no
2553   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2554                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2555 #include <gtk/gtk.h>])
2556   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2557     AC_CHECK_FUNCS(gtk_handle_box_new)
2558   fi
2559
2560   dnl Same as above for gtk_tearoff_menu_item.
2561   HAVE_GTK_TEAROFF_MENU_ITEM=no
2562   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2563                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2564 #include <gtk/gtk.h>])
2565   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2566     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2567   fi
2568
2569   dnl Check for functions introduced in 2.14 and later.
2570   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2571                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2572                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2573                  gtk_orientable_set_orientation \
2574                  gtk_window_set_has_resize_grip)
2575
2576  term_header=gtkutil.h
2577 fi
2578
2579
2580 dnl Enable xwidgets if GTK3 and WebKitGTK+ are available.
2581 HAVE_XWIDGETS=no
2582 XWIDGETS_OBJ=
2583 if test "$with_xwidgets" != "no"; then
2584   test "$USE_GTK_TOOLKIT" = "GTK3" && test "$window_system" != "none" ||
2585     AC_MSG_ERROR([xwidgets requested but gtk3 not used.])
2586
2587   WEBKIT_REQUIRED=1.4.0
2588   WEBKIT_MODULES="webkitgtk-3.0 >= $WEBKIT_REQUIRED"
2589   EMACS_CHECK_MODULES([WEBKIT], [$WEBKIT_MODULES])
2590   HAVE_XWIDGETS=$HAVE_WEBKIT
2591   test $HAVE_XWIDGETS = yes ||
2592     AC_MSG_ERROR([xwidgets requested but WebKitGTK+ not found.])
2593
2594   XWIDGETS_OBJ=xwidget.o
2595   AC_DEFINE([HAVE_XWIDGETS], 1, [Define to 1 if you have xwidgets support.])
2596 fi
2597 AC_SUBST(XWIDGETS_OBJ)
2598
2599 CFLAGS=$OLD_CFLAGS
2600 LIBS=$OLD_LIBS
2601
2602 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2603 dnl other platforms.
2604 HAVE_DBUS=no
2605 DBUS_OBJ=
2606 if test "${with_dbus}" = "yes"; then
2607    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2608    if test "$HAVE_DBUS" = yes; then
2609      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2610      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2611      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2612      dnl D-Bus 1.5.12.
2613      OLD_LIBS=$LIBS
2614      LIBS="$LIBS $DBUS_LIBS"
2615      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2616                     dbus_type_is_valid \
2617                     dbus_validate_bus_name \
2618                     dbus_validate_path \
2619                     dbus_validate_interface \
2620                     dbus_validate_member)
2621      LIBS=$OLD_LIBS
2622      DBUS_OBJ=dbusbind.o
2623    fi
2624 fi
2625 AC_SUBST(DBUS_CFLAGS)
2626 AC_SUBST(DBUS_LIBS)
2627 AC_SUBST(DBUS_OBJ)
2628
2629 dnl GSettings has been tested under GNU/Linux only.
2630 HAVE_GSETTINGS=no
2631 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2632    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2633    if test "$HAVE_GSETTINGS" = "yes"; then
2634       old_CFLAGS=$CFLAGS
2635       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2636       old_LIBS=$LIBS
2637       LIBS="$LIBS $GSETTINGS_LIBS"
2638       AC_MSG_CHECKING([whether GSettings is in gio])
2639       AC_LINK_IFELSE(
2640          [AC_LANG_PROGRAM(
2641              [[/* Check that gsettings really is present.  */
2642              #include <glib-object.h>
2643              #include <gio/gio.h>
2644              ]],
2645              [[
2646                GSettings *settings;
2647                GVariant *val = g_settings_get_value (settings, "");
2648              ]])],
2649          [], HAVE_GSETTINGS=no)
2650       AC_MSG_RESULT([$HAVE_GSETTINGS])
2651
2652       if test "$HAVE_GSETTINGS" = "yes"; then
2653         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2654         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2655         SETTINGS_LIBS="$GSETTINGS_LIBS"
2656       fi
2657       CFLAGS=$old_CFLAGS
2658       LIBS=$old_LIBS
2659    fi
2660 fi
2661
2662 dnl GConf has been tested under GNU/Linux only.
2663 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2664 HAVE_GCONF=no
2665 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2666    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2667    if test "$HAVE_GCONF" = yes; then
2668       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2669       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2670       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2671       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2672    fi
2673 fi
2674
2675 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2676     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2677     if test "$HAVE_GOBJECT" = "yes"; then
2678        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2679        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2680     fi
2681     SAVE_CFLAGS="$CFLAGS"
2682     SAVE_LIBS="$LIBS"
2683     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2684     LIBS="$SETTINGS_LIBS $LIBS"
2685     CFLAGS="$SAVE_CFLAGS"
2686     LIBS="$SAVE_LIBS"
2687 fi
2688 AC_SUBST(SETTINGS_CFLAGS)
2689 AC_SUBST(SETTINGS_LIBS)
2690
2691
2692 dnl SELinux is available for GNU/Linux only.
2693 HAVE_LIBSELINUX=no
2694 LIBSELINUX_LIBS=
2695 if test "${with_selinux}" = "yes"; then
2696    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2697    if test "$HAVE_LIBSELINUX" = yes; then
2698       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2699       LIBSELINUX_LIBS=-lselinux
2700    fi
2701 fi
2702 AC_SUBST(LIBSELINUX_LIBS)
2703
2704 HAVE_GNUTLS=no
2705 if test "${with_gnutls}" = "yes" ; then
2706   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2707     [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2708   if test "${HAVE_GNUTLS}" = "yes"; then
2709     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2710     EMACS_CHECK_MODULES([LIBGNUTLS3], [gnutls >= 3.0.0],
2711       [AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])], [])
2712   fi
2713
2714   # Windows loads GnuTLS dynamically
2715   if test "${opsys}" = "mingw32"; then
2716     LIBGNUTLS_LIBS=
2717   fi
2718 fi
2719
2720 AC_SUBST(LIBGNUTLS_LIBS)
2721 AC_SUBST(LIBGNUTLS_CFLAGS)
2722
2723 NOTIFY_OBJ=
2724 NOTIFY_SUMMARY=no
2725
2726 dnl MS Windows native file monitor is available for mingw32 only.
2727 case $with_file_notification,$opsys in
2728   w32,cygwin)
2729     AC_MSG_ERROR(['--with-file-notification=w32' was specified, but
2730     this is only supported on MS-Windows native and MinGW32 builds.
2731     Consider using gfile instead.])
2732     ;;
2733   w32,* | yes,mingw32)
2734     AC_CHECK_HEADER(windows.h)
2735     if test "$ac_cv_header_windows_h" = yes ; then
2736        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2737        NOTIFY_OBJ=w32notify.o
2738        NOTIFY_SUMMARY="yes (w32)"
2739     fi ;;
2740 esac
2741
2742 dnl inotify is available only on GNU/Linux.
2743 case $with_file_notification,$NOTIFY_OBJ in
2744   inotify, | yes,)
2745     AC_CHECK_HEADER(sys/inotify.h)
2746     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2747         AC_CHECK_FUNC(inotify_init1)
2748         if test "$ac_cv_func_inotify_init1" = yes; then
2749           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2750           NOTIFY_OBJ=inotify.o
2751           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2752        fi
2753     fi ;;
2754 esac
2755
2756 dnl kqueue is available on BSD-like systems.
2757 case $with_file_notification,$NOTIFY_OBJ in
2758   kqueue,* | yes,)
2759     EMACS_CHECK_MODULES([KQUEUE], [libkqueue])
2760     if test "$HAVE_KQUEUE" = "yes"; then
2761        AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2762        CPPFLAGS="$CPPFLAGS -I/usr/include/kqueue"
2763        NOTIFY_CFLAGS=$KQUEUE_CFLAGS
2764        NOTIFY_LIBS=$KQUEUE_LIBS
2765        NOTIFY_OBJ=kqueue.o
2766        NOTIFY_SUMMARY="yes -lkqueue"
2767     else
2768        AC_SEARCH_LIBS(kqueue, [])
2769        if test "$ac_cv_search_kqueue" != no; then
2770          AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2771          NOTIFY_OBJ=kqueue.o
2772          NOTIFY_SUMMARY="yes (kqueue)"
2773        fi
2774     fi ;;
2775 esac
2776
2777 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2778 dnl has been added in glib 2.24.  It has been tested under
2779 dnl GNU/Linux only.
2780 case $with_file_notification,$NOTIFY_OBJ in
2781   gfile,* | yes,)
2782     if test "${HAVE_NS}" = yes; then
2783        AC_MSG_ERROR(['--with-file-notification=gfile' is not supported in NextStep builds.
2784 Consider kqueue instead.])
2785     else
2786        EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2787        if test "$HAVE_GFILENOTIFY" = "yes"; then
2788           AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2789           NOTIFY_CFLAGS=$GFILENOTIFY_CFLAGS
2790           NOTIFY_LIBS=$GFILENOTIFY_LIBS
2791           NOTIFY_OBJ=gfilenotify.o
2792           NOTIFY_SUMMARY="yes -lgio (gfile)"
2793        fi
2794     fi ;;
2795 esac
2796
2797 case $with_file_notification,$NOTIFY_OBJ in
2798   yes,* | no,* | *,?*) ;;
2799   *) AC_MSG_ERROR([File notification '$with_file_notification' requested but requirements not found.]) ;;
2800 esac
2801
2802 if test -n "$NOTIFY_OBJ"; then
2803    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2804 fi
2805 AC_SUBST(NOTIFY_CFLAGS)
2806 AC_SUBST(NOTIFY_LIBS)
2807 AC_SUBST(NOTIFY_OBJ)
2808
2809 dnl Do not put whitespace before the #include statements below.
2810 dnl Older compilers (eg sunos4 cc) choke on it.
2811 HAVE_XAW3D=no
2812 LUCID_LIBW=
2813 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2814   if test "$with_xaw3d" != no; then
2815     AC_CACHE_VAL(emacs_cv_xaw3d,
2816     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2817 #include <X11/Intrinsic.h>
2818 #include <X11/Xaw3d/Simple.h>]],
2819       [[]])],
2820       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2821                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2822       emacs_cv_xaw3d=no)])
2823   else
2824     emacs_cv_xaw3d=no
2825   fi
2826   if test $emacs_cv_xaw3d = yes; then
2827     AC_MSG_CHECKING(for xaw3d)
2828     AC_MSG_RESULT([yes; using Lucid toolkit])
2829     USE_X_TOOLKIT=LUCID
2830     HAVE_XAW3D=yes
2831     LUCID_LIBW=-lXaw3d
2832     AC_DEFINE(HAVE_XAW3D, 1,
2833               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2834   else
2835     AC_MSG_CHECKING(for xaw3d)
2836     AC_MSG_RESULT(no)
2837     AC_MSG_CHECKING(for libXaw)
2838     AC_CACHE_VAL(emacs_cv_xaw,
2839     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2840 #include <X11/Intrinsic.h>
2841 #include <X11/Xaw/Simple.h>]],
2842       [[]])],
2843       emacs_cv_xaw=yes,
2844       emacs_cv_xaw=no)])
2845     if test $emacs_cv_xaw = yes; then
2846       AC_MSG_RESULT([yes; using Lucid toolkit])
2847       USE_X_TOOLKIT=LUCID
2848       LUCID_LIBW=-lXaw
2849     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2850       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2851     else
2852       AC_MSG_ERROR([No X toolkit could be found.
2853 If you are sure you want Emacs compiled without an X toolkit, pass
2854   --with-x-toolkit=no
2855 to configure.  Otherwise, install the development libraries for the toolkit
2856 that you want to use (e.g. Gtk+) and re-run configure.])
2857     fi
2858   fi
2859 fi
2860
2861 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2862
2863 LIBXTR6=
2864 LIBXMU=
2865 if test "${USE_X_TOOLKIT}" != "none"; then
2866   AC_MSG_CHECKING(X11 toolkit version)
2867   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2868   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2869 [[#if XtSpecificationRelease < 6
2870 fail;
2871 #endif
2872 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2873   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2874   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2875     AC_MSG_RESULT(6 or newer)
2876     AC_DEFINE(HAVE_X11XTR6, 1,
2877               [Define to 1 if you have the X11R6 or newer version of Xt.])
2878     LIBXTR6="-lSM -lICE"
2879     case "$opsys" in
2880       ## Use libw.a along with X11R6 Xt.
2881       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2882     esac
2883   else
2884     AC_MSG_RESULT(before 6)
2885   fi
2886
2887 dnl If using toolkit, check whether libXmu.a exists.
2888 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2889   OLDLIBS="$LIBS"
2890   if test x$HAVE_X11XTR6 = xyes; then
2891     OTHERLIBS='-lXt -lSM -lICE'
2892   else
2893     OTHERLIBS='-lXt'
2894   fi
2895   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2896   if test "X$LIBS" != "X$OLDLIBS"; then
2897     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2898   fi
2899   LIBS=$OLDLIBS
2900   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2901 fi
2902 AC_SUBST(LIBXTR6)
2903 AC_SUBST(LIBXMU)
2904
2905 LIBXP=
2906 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2907   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2908   if test -d /usr/include/openmotif; then
2909     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2910     emacs_cv_openmotif=yes
2911     case "$canonical" in
2912       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2913       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2914       ;;
2915       *)
2916       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2917     esac
2918   else
2919     emacs_cv_openmotif=no
2920   fi
2921   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2922   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2923     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2924 int x = 5;
2925 #else
2926 Motif version prior to 2.1.
2927 #endif]])],
2928     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2929   if test $emacs_cv_motif_version_2_1 = yes; then
2930     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2931     if test x$emacs_cv_openmotif = xyes; then
2932       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2933     fi
2934   else
2935     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2936     # We put this in CFLAGS temporarily to precede other -I options
2937     # that might be in CFLAGS temporarily.
2938     # We put this in CPPFLAGS where it precedes the other -I options.
2939     OLD_CPPFLAGS=$CPPFLAGS
2940     OLD_CFLAGS=$CFLAGS
2941     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2942     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2943     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2944       [[int x = 5;]])],
2945       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2946     if test $emacs_cv_lesstif = yes; then
2947       # Make sure this -I option remains in CPPFLAGS after it is set
2948       # back to REAL_CPPFLAGS.
2949       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2950       # have those other -I options anyway.  Ultimately, having this
2951       # directory ultimately in CPPFLAGS will be enough.
2952       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2953       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2954     else
2955       CFLAGS=$OLD_CFLAGS
2956       CPPFLAGS=$OLD_CPPFLAGS
2957     fi
2958   fi
2959   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2960     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2961 fi
2962
2963 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2964 dnl using Motif or Xaw3d is available, and unless
2965 dnl --with-toolkit-scroll-bars=no was specified.
2966
2967 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2968             [Define to 1 if we should use toolkit scroll bars.])dnl
2969 USE_TOOLKIT_SCROLL_BARS=no
2970 if test "${with_toolkit_scroll_bars}" != "no"; then
2971   if test "${USE_X_TOOLKIT}" != "none"; then
2972     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2973       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2974       HAVE_XAW3D=no
2975       USE_TOOLKIT_SCROLL_BARS=yes
2976     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2977       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2978       USE_TOOLKIT_SCROLL_BARS=yes
2979     fi
2980   elif test "${HAVE_GTK}" = "yes"; then
2981     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2982     USE_TOOLKIT_SCROLL_BARS=yes
2983   elif test "${HAVE_NS}" = "yes"; then
2984     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2985     USE_TOOLKIT_SCROLL_BARS=yes
2986   elif test "${HAVE_W32}" = "yes"; then
2987     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2988     USE_TOOLKIT_SCROLL_BARS=yes
2989   fi
2990 fi
2991
2992 dnl See if XIM is available.
2993 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2994           #include <X11/Xlib.h>
2995           #include <X11/Xresource.h>]],
2996          [[XIMProc  callback;]])],
2997          [HAVE_XIM=yes
2998          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2999          HAVE_XIM=no)
3000
3001 dnl '--with-xim' now controls only the initial value of use_xim at run time.
3002
3003 if test "${with_xim}" != "no"; then
3004   AC_DEFINE(USE_XIM, 1,
3005             [Define to 1 if we should use XIM, if it is available.])
3006 fi
3007
3008
3009 if test "${HAVE_XIM}" != "no"; then
3010   late_CFLAGS=$CFLAGS
3011   if test "$GCC" = yes; then
3012     CFLAGS="$CFLAGS --pedantic-errors"
3013   fi
3014   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3015 #include <X11/Xlib.h>
3016 #include <X11/Xresource.h>]],
3017 [[Display *display;
3018 XrmDatabase db;
3019 char *res_name;
3020 char *res_class;
3021 XIMProc  callback;
3022 XPointer *client_data;
3023 #ifndef __GNUC__
3024 /* If we're not using GCC, it's probably not XFree86, and this is
3025    probably right, but we can't use something like --pedantic-errors.  */
3026 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
3027                                            char*, XIMProc, XPointer*);
3028 #endif
3029 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
3030    client_data);]])],
3031     [emacs_cv_arg6_star=yes])
3032   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
3033          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
3034 either XPointer or XPointer*.])dnl
3035   if test "$emacs_cv_arg6_star" = yes; then
3036     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
3037   else
3038     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
3039   fi
3040   CFLAGS=$late_CFLAGS
3041 fi
3042
3043 ### Start of font-backend (under any platform) section.
3044 # (nothing here yet -- this is a placeholder)
3045 ### End of font-backend (under any platform) section.
3046
3047 ### Start of font-backend (under X11) section.
3048 if test "${HAVE_X11}" = "yes"; then
3049     ## Use -lXft if available, unless '--with-xft=no'.
3050     HAVE_XFT=maybe
3051     if test "x${with_x}" = "xno"; then
3052       with_xft="no";
3053     fi
3054
3055     if test "$with_xft" != no; then
3056       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
3057       with_xft=$HAVE_FONTCONFIG
3058     fi
3059
3060     if test "x${with_xft}" != "xno"; then
3061
3062       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
3063       ## Because xftfont.c uses XRenderQueryExtension, we also
3064       ## need to link to -lXrender.
3065       HAVE_XRENDER=no
3066       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
3067       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
3068         OLD_CPPFLAGS="$CPPFLAGS"
3069         OLD_CFLAGS="$CFLAGS"
3070         OLD_LIBS="$LIBS"
3071         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
3072         CFLAGS="$CFLAGS $XFT_CFLAGS"
3073         XFT_LIBS="-lXrender $XFT_LIBS"
3074         LIBS="$XFT_LIBS $LIBS"
3075         AC_CHECK_HEADER(X11/Xft/Xft.h,
3076           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
3077           [[#include <X11/X.h>]])
3078
3079         if test "${HAVE_XFT}" = "yes"; then
3080           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
3081             AC_SUBST(XFT_LIBS)
3082           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
3083         fi                        # "${HAVE_XFT}" = "yes"
3084         CPPFLAGS=$OLD_CPPFLAGS
3085         CFLAGS=$OLD_CFLAGS
3086         LIBS=$OLD_LIBS
3087       fi                          # "$HAVE_XFT" != no
3088     fi                            # "x${with_xft}" != "xno"
3089
3090     ## We used to allow building with FreeType and without Xft.
3091     ## However, the ftx font backend driver is not in good shape.
3092     if test "$HAVE_XFT" != "yes"; then
3093        dnl For the "Does Emacs use" message at the end.
3094        HAVE_XFT=no
3095        HAVE_FREETYPE=no
3096     else
3097        dnl Strict linkers fail with
3098        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
3099        dnl if -lfreetype is not specified.
3100        dnl The following is needed to set FREETYPE_LIBS.
3101        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
3102
3103        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
3104     fi
3105
3106     HAVE_LIBOTF=no
3107     if test "${HAVE_FREETYPE}" = "yes"; then
3108       AC_DEFINE(HAVE_FREETYPE, 1,
3109                 [Define to 1 if using the freetype and fontconfig libraries.])
3110       if test "${with_libotf}" != "no"; then
3111         EMACS_CHECK_MODULES([LIBOTF], [libotf])
3112         if test "$HAVE_LIBOTF" = "yes"; then
3113           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
3114           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
3115                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
3116                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
3117           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
3118             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
3119                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
3120           fi
3121         fi
3122       fi
3123     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
3124     dnl Does the new font backend require it, or can it work without it?
3125     fi
3126
3127     HAVE_M17N_FLT=no
3128     if test "${HAVE_LIBOTF}" = yes; then
3129       if test "${with_m17n_flt}" != "no"; then
3130         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
3131         if test "$HAVE_M17N_FLT" = "yes"; then
3132           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
3133         fi
3134       fi
3135     fi
3136 else
3137     HAVE_XFT=no
3138     HAVE_FREETYPE=no
3139     HAVE_LIBOTF=no
3140     HAVE_M17N_FLT=no
3141 fi
3142
3143 ### End of font-backend (under X11) section.
3144
3145 AC_SUBST(FREETYPE_CFLAGS)
3146 AC_SUBST(FREETYPE_LIBS)
3147 AC_SUBST(FONTCONFIG_CFLAGS)
3148 AC_SUBST(FONTCONFIG_LIBS)
3149 AC_SUBST(LIBOTF_CFLAGS)
3150 AC_SUBST(LIBOTF_LIBS)
3151 AC_SUBST(M17N_FLT_CFLAGS)
3152 AC_SUBST(M17N_FLT_LIBS)
3153
3154 HAVE_CAIRO=no
3155 if test "${HAVE_X11}" = "yes"; then
3156   if test "${with_cairo}" != "no"; then
3157     CAIRO_REQUIRED=1.12.0
3158     CAIRO_MODULE="cairo >= $CAIRO_REQUIRED"
3159     EMACS_CHECK_MODULES(CAIRO, $CAIRO_MODULE)
3160     if test $HAVE_CAIRO = yes; then
3161       AC_DEFINE(USE_CAIRO, 1, [Define to 1 if using cairo.])
3162     else
3163       AC_MSG_ERROR([cairo requested but not found.])
3164     fi
3165
3166     CFLAGS="$CFLAGS $CAIRO_CFLAGS"
3167     LIBS="$LIBS $CAIRO_LIBS"
3168     AC_SUBST(CAIRO_CFLAGS)
3169     AC_SUBST(CAIRO_LIBS)
3170   fi
3171 fi
3172
3173 if test "${HAVE_X11}" = "yes"; then
3174   AC_CHECK_HEADER(X11/Xlib-xcb.h,
3175     AC_CHECK_LIB(xcb, xcb_translate_coordinates, HAVE_XCB=yes))
3176   if test "${HAVE_XCB}" = "yes"; then
3177     AC_CHECK_LIB(X11-xcb, XGetXCBConnection, HAVE_X11_XCB=yes)
3178     if test "${HAVE_X11_XCB}" = "yes"; then
3179       AC_DEFINE(USE_XCB, 1,
3180 [Define to 1 if you have the XCB library and X11-XCB library for mixed
3181    X11/XCB programming.])
3182       XCB_LIBS="-lX11-xcb -lxcb"
3183       AC_SUBST(XCB_LIBS)
3184     fi
3185   fi
3186 fi
3187
3188 ### Use -lXpm if available, unless '--with-xpm=no'.
3189 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
3190 ### In the Cygwin-w32 build, we need to use /usr/include/noX/X11/xpm.h
3191 ### rather than /usr/include/X11/xpm.h, so we set CPPFLAGS (and
3192 ### LDFLAGS) accordingly.
3193 HAVE_XPM=no
3194 LIBXPM=
3195 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3196   if test "${with_xpm}" != "no"; then
3197     SAVE_CPPFLAGS="$CPPFLAGS"
3198     SAVE_LDFLAGS="$LDFLAGS"
3199     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
3200     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3201     AC_CHECK_HEADER(X11/xpm.h,
3202       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3203     if test "${HAVE_XPM}" = "yes"; then
3204       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3205       AC_EGREP_CPP(no_return_alloc_pixels,
3206       [#include "X11/xpm.h"
3207 #ifndef XpmReturnAllocPixels
3208 no_return_alloc_pixels
3209 #endif
3210       ], HAVE_XPM=no, HAVE_XPM=yes)
3211
3212       if test "${HAVE_XPM}" = "yes"; then
3213         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3214         AC_MSG_RESULT(yes)
3215       else
3216         AC_MSG_RESULT(no)
3217         CPPFLAGS="$SAVE_CPPFLAGS"
3218         LDFLAGS="$SAVE_LDFLAGS"
3219       fi
3220     fi
3221   fi
3222
3223   if test "${HAVE_XPM}" = "yes"; then
3224     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3225     LIBXPM=-lXpm
3226   fi
3227 fi
3228
3229 if test "${HAVE_X11}" = "yes"; then
3230   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3231   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3232
3233   if test "${with_xpm}" != "no"; then
3234     AC_CHECK_HEADER(X11/xpm.h,
3235       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3236     if test "${HAVE_XPM}" = "yes"; then
3237       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3238       AC_EGREP_CPP(no_return_alloc_pixels,
3239       [#include "X11/xpm.h"
3240 #ifndef XpmReturnAllocPixels
3241 no_return_alloc_pixels
3242 #endif
3243       ], HAVE_XPM=no, HAVE_XPM=yes)
3244
3245       if test "${HAVE_XPM}" = "yes"; then
3246         AC_MSG_RESULT(yes)
3247       else
3248         AC_MSG_RESULT(no)
3249       fi
3250     fi
3251   fi
3252
3253   if test "${HAVE_XPM}" = "yes"; then
3254     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3255     LIBXPM=-lXpm
3256   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3257     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3258     LIBXPM=-lXpm
3259   fi
3260 fi
3261
3262 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3263 ### slightly different requirements wrt image libraries (it doesn't
3264 ### use -lXpm because it loads the xpm shared library dynamically at
3265 ### run time).
3266 if test "${opsys}" = "mingw32"; then
3267   if test "${with_xpm}" != "no"; then
3268     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3269 #define FOR_MSW 1])
3270   fi
3271
3272   if test "${HAVE_XPM}" = "yes"; then
3273     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3274   fi
3275 fi
3276
3277 AC_SUBST(LIBXPM)
3278
3279 ### Use -ljpeg if available, unless '--with-jpeg=no'.
3280 HAVE_JPEG=no
3281 LIBJPEG=
3282 if test "${with_jpeg}" != "no"; then
3283   AC_CACHE_CHECK([for jpeglib 6b or later],
3284     [emacs_cv_jpeglib],
3285     [OLD_LIBS=$LIBS
3286      for emacs_cv_jpeglib in yes -ljpeg no; do
3287        case $emacs_cv_jpeglib in
3288          yes) ;;
3289          no) break;;
3290          *) LIBS="$LIBS $emacs_cv_jpeglib";;
3291        esac
3292        AC_LINK_IFELSE(
3293          [AC_LANG_PROGRAM(
3294             [[#undef HAVE_STDLIB_H /* Avoid config.h/jpeglib.h collision.  */
3295               #include <stdio.h> /* jpeglib.h needs FILE and size_t.  */
3296               #include <jpeglib.h>
3297               #include <jerror.h>
3298               char verify[JPEG_LIB_VERSION < 62 ? -1 : 1];
3299               struct jpeg_decompress_struct cinfo;
3300             ]],
3301             [[
3302               jpeg_create_decompress (&cinfo);
3303               WARNMS (&cinfo, JWRN_JPEG_EOF);
3304               jpeg_destroy_decompress (&cinfo);
3305             ]])],
3306          [emacs_link_ok=yes],
3307          [emacs_link_ok=no])
3308        LIBS=$OLD_LIBS
3309        test $emacs_link_ok = yes && break
3310      done])
3311   if test "$emacs_cv_jpeglib" != no; then
3312     HAVE_JPEG=yes
3313     AC_DEFINE([HAVE_JPEG], 1,
3314       [Define to 1 if you have the jpeg library (typically -ljpeg).])
3315     ### mingw32 doesn't use -ljpeg, since it loads the library
3316     ### dynamically when needed, and doesn't want a run-time
3317     ### dependency on the jpeglib DLL.
3318     test "$emacs_cv_jpeglib" != yes && test "${opsys}" != "mingw32" \
3319     && LIBJPEG=$emacs_cv_jpeglib
3320   fi
3321 fi
3322 AC_SUBST(LIBJPEG)
3323
3324 HAVE_ZLIB=no
3325 LIBZ=
3326 if test "${with_zlib}" != "no"; then
3327   OLIBS=$LIBS
3328   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3329   LIBS=$OLIBS
3330   case $ac_cv_search_inflateEnd in
3331     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3332   esac
3333 fi
3334 if test "${HAVE_ZLIB}" = "yes"; then
3335   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3336   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3337   if test "${opsys}" = "mingw32"; then
3338      LIBZ=
3339   fi
3340 fi
3341 AC_SUBST(LIBZ)
3342
3343 ### Dynamic modules support
3344 LIBMODULES=
3345 HAVE_MODULES=no
3346 MODULES_OBJ=
3347 MODULES_SUFFIX=
3348 if test "${with_modules}" != "no"; then
3349   if test "$opsys" = "gnu-linux"; then
3350     LIBMODULES="-ldl"
3351     MODULES_SUFFIX=".so"
3352     HAVE_MODULES=yes
3353   elif test "$opsys" = "cygwin"; then
3354     MODULES_SUFFIX=".dll"
3355     HAVE_MODULES=yes
3356   elif test "$opsys" = "darwin"; then
3357     MODULES_SUFFIX=".so"
3358     HAVE_MODULES=yes
3359   elif test "$opsys" = "mingw32"; then
3360     MODULES_SUFFIX=".dll"
3361     HAVE_MODULES=yes
3362   else
3363     # BSD system have dlopen in the libc
3364     AC_CHECK_FUNC(dlopen, [MODULES_SUFFIX=".so"]
3365                           [HAVE_MODULES=yes], [])
3366   fi
3367
3368   if test "${HAVE_MODULES}" = no; then
3369     AC_MSG_ERROR([Dynamic modules are not supported on your system])
3370   else
3371     SAVE_LIBS=$LIBS
3372     LIBS="$LIBS $LIBMODULES"
3373     AC_CHECK_FUNCS([dladdr dlfunc])
3374     LIBS=$SAVE_LIBS
3375   fi
3376 fi
3377
3378 if test "${HAVE_MODULES}" = yes; then
3379    MODULES_OBJ="dynlib.o emacs-module.o"
3380    AC_DEFINE(HAVE_MODULES, 1, [Define to 1 if dynamic modules are enabled])
3381    AC_DEFINE_UNQUOTED(MODULES_SUFFIX, "$MODULES_SUFFIX",
3382      [System extension for dynamic libraries])
3383 fi
3384 AC_SUBST(MODULES_OBJ)
3385 AC_SUBST(LIBMODULES)
3386
3387 ### Use -lpng if available, unless '--with-png=no'.
3388 HAVE_PNG=no
3389 LIBPNG=
3390 PNG_CFLAGS=
3391 if test "${NS_IMPL_COCOA}" = yes; then
3392   : # Nothing to do
3393 elif test "${with_png}" != no; then
3394   # mingw32 loads the library dynamically.
3395   if test "$opsys" = mingw32; then
3396     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3397   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3398     AC_MSG_CHECKING([for png])
3399     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3400     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3401       # libpng-config does not work; configure by hand.
3402       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3403       # in /usr/include/libpng.
3404       if test -r /usr/include/libpng/png.h &&
3405          test ! -r /usr/include/png.h; then
3406         png_cflags=-I/usr/include/libpng
3407       else
3408         png_cflags=
3409       fi
3410       png_libs='-lpng'
3411     }
3412     SAVE_CFLAGS=$CFLAGS
3413     SAVE_LIBS=$LIBS
3414     CFLAGS="$CFLAGS $png_cflags"
3415     LIBS="$png_libs -lz -lm $LIBS"
3416     AC_LINK_IFELSE(
3417       [AC_LANG_PROGRAM([[#include <png.h>]],
3418          [[return !png_get_channels (0, 0);]])],
3419       [HAVE_PNG=yes
3420        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3421        LIBPNG=$png_libs
3422        # $LIBPNG requires explicit -lz in some cases.
3423        # We don't know what those cases are, exactly, so play it safe and
3424        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3425        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3426          LIBPNG="$LIBPNG -lz"
3427        fi])
3428     CFLAGS=$SAVE_CFLAGS
3429     LIBS=$SAVE_LIBS
3430     AC_MSG_RESULT([$HAVE_PNG])
3431   fi
3432 fi
3433 if test $HAVE_PNG = yes; then
3434   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3435
3436   SAVE_CFLAGS=$CFLAGS
3437   CFLAGS="$CFLAGS $PNG_CFLAGS"
3438   AC_CHECK_DECL([png_longjmp],
3439     [],
3440     [AC_DEFINE([PNG_DEPSTRUCT], [],
3441        [Define to empty to suppress deprecation warnings when building
3442         with --enable-gcc-warnings and with libpng versions before 1.5,
3443         which lack png_longjmp.])],
3444     [[#include <png.h>
3445     ]])
3446   CFLAGS=$SAVE_CFLAGS
3447 fi
3448 AC_SUBST(LIBPNG)
3449 AC_SUBST(PNG_CFLAGS)
3450
3451 ### Use -ltiff if available, unless '--with-tiff=no'.
3452 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3453 HAVE_TIFF=no
3454 LIBTIFF=
3455 if test "${opsys}" = "mingw32"; then
3456   if test "${with_tiff}" != "no"; then
3457     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3458   fi
3459   if test "${HAVE_TIFF}" = "yes"; then
3460     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3461   fi
3462 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3463   if test "${with_tiff}" != "no"; then
3464     AC_CHECK_HEADER(tiffio.h,
3465       [tifflibs="-lz -lm"
3466       # At least one tiff package requires the jpeg library.
3467       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3468       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3469   fi
3470
3471   if test "${HAVE_TIFF}" = "yes"; then
3472     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3473     dnl FIXME -lz -lm, as per libpng?
3474     LIBTIFF=-ltiff
3475   fi
3476 fi
3477 AC_SUBST(LIBTIFF)
3478
3479 ### Use -lgif or -lungif if available, unless '--with-gif=no'.
3480 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3481 HAVE_GIF=no
3482 LIBGIF=
3483 if test "${opsys}" = "mingw32"; then
3484   if test "${with_gif}" != "no"; then
3485     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3486   fi
3487   if test "${HAVE_GIF}" = "yes"; then
3488     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3489   fi
3490 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3491         || test "${HAVE_W32}" = "yes"; then
3492   AC_CHECK_HEADER(gif_lib.h,
3493 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3494 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3495     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3496         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3497
3498   if test "$HAVE_GIF" = yes; then
3499     LIBGIF=-lgif
3500   elif test "$HAVE_GIF" = maybe; then
3501 # If gif_lib.h but no libgif, try libungif.
3502     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3503     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3504   fi
3505
3506   if test "${HAVE_GIF}" = "yes"; then
3507     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3508   fi
3509 fi
3510 AC_SUBST(LIBGIF)
3511
3512 dnl Check for required libraries.
3513 if test "${HAVE_X11}" = "yes"; then
3514   MISSING=""
3515   WITH_NO=""
3516   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3517     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3518   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3519     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3520   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3521     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3522   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3523     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3524   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3525     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3526
3527   if test "X${MISSING}" != X; then
3528     AC_MSG_ERROR([The following required libraries were not found:
3529     $MISSING
3530 Maybe some development libraries/packages are missing?
3531 If you don't want to link with them give
3532     $WITH_NO
3533 as options to configure])
3534   fi
3535 fi
3536
3537 ### Use -lgpm if available, unless '--with-gpm=no'.
3538 HAVE_GPM=no
3539 LIBGPM=
3540 if test "${with_gpm}" != "no"; then
3541   AC_CHECK_HEADER(gpm.h,
3542     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3543
3544   if test "${HAVE_GPM}" = "yes"; then
3545     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3546     LIBGPM=-lgpm
3547   fi
3548 fi
3549 AC_SUBST(LIBGPM)
3550
3551 dnl Check for malloc/malloc.h on darwin
3552 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3553
3554 GNUSTEP_CFLAGS=
3555 ### Use NeXTstep API to implement GUI.
3556 if test "${HAVE_NS}" = "yes"; then
3557   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3558   if test "${NS_IMPL_COCOA}" = "yes"; then
3559     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3560   fi
3561   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3562     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3563     if test $NS_GNUSTEP_CONFIG != yes; then
3564       # See also .m.o rule in src/Makefile.in.  */
3565       # FIXME: are all these flags really needed?  Document here why.  */
3566       GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3567       ## Extra CFLAGS applied to src/*.m files.
3568       GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3569     fi
3570   fi
3571   OTHER_FILES=ns-app
3572 fi
3573
3574 ### Use session management (-lSM -lICE) if available
3575 HAVE_X_SM=no
3576 LIBXSM=
3577 if test "${HAVE_X11}" = "yes"; then
3578   AC_CHECK_HEADER(X11/SM/SMlib.h,
3579     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3580
3581   if test "${HAVE_X_SM}" = "yes"; then
3582     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3583     LIBXSM="-lSM -lICE"
3584   fi
3585 fi
3586 AC_SUBST(LIBXSM)
3587
3588 ### Use XRandr (-lXrandr) if available
3589 HAVE_XRANDR=no
3590 if test "${HAVE_X11}" = "yes"; then
3591   XRANDR_REQUIRED=1.2.2
3592   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3593   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3594   if test $HAVE_XRANDR = no; then
3595     # Test old way in case pkg-config doesn't have it (older machines).
3596     # Include Xrender.h by hand to work around bug in older Xrandr.h
3597     # (e.g. RHEL5) and silence (harmless) configure warning (bug#18465).
3598     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3599       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)],
3600       [], [AC_INCLUDES_DEFAULT
3601 #include <X11/extensions/Xrender.h>])
3602     if test $HAVE_XRANDR = yes; then
3603       XRANDR_LIBS=-lXrandr
3604     fi
3605   fi
3606   if test $HAVE_XRANDR = yes; then
3607     SAVE_CFLAGS="$CFLAGS"
3608     SAVE_LIBS="$LIBS"
3609     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3610     LIBS="$XRANDR_LIBS $LIBS"
3611     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3612     CFLAGS="$SAVE_CFLAGS"
3613     LIBS="$SAVE_LIBS"
3614
3615     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3616   fi
3617 fi
3618 AC_SUBST(XRANDR_CFLAGS)
3619 AC_SUBST(XRANDR_LIBS)
3620
3621 ### Use Xinerama (-lXinerama) if available
3622 HAVE_XINERAMA=no
3623 if test "${HAVE_X11}" = "yes"; then
3624   XINERAMA_REQUIRED=1.0.2
3625   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3626   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3627   if test $HAVE_XINERAMA = no; then
3628     # Test old way in case pkg-config doesn't have it (older machines).
3629     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3630       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3631     if test $HAVE_XINERAMA = yes; then
3632       XINERAMA_LIBS=-lXinerama
3633     fi
3634   fi
3635   if test $HAVE_XINERAMA = yes; then
3636     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3637   fi
3638 fi
3639 AC_SUBST(XINERAMA_CFLAGS)
3640 AC_SUBST(XINERAMA_LIBS)
3641
3642 ### Use Xfixes (-lXfixes) if available
3643 HAVE_XFIXES=no
3644 if test "${HAVE_X11}" = "yes"; then
3645   XFIXES_REQUIRED=4.0.0
3646   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3647   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3648   if test $HAVE_XFIXES = no; then
3649     # Test old way in case pkg-config doesn't have it (older machines).
3650     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3651       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3652     if test $HAVE_XFIXES = yes; then
3653       XFIXES_LIBS=-lXfixes
3654     fi
3655   fi
3656   if test $HAVE_XFIXES = yes; then
3657     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3658   fi
3659 fi
3660 AC_SUBST(XFIXES_CFLAGS)
3661 AC_SUBST(XFIXES_LIBS)
3662
3663 ### Use libxml (-lxml2) if available
3664 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3665 HAVE_LIBXML2=no
3666 if test "${with_xml2}" != "no"; then
3667   ### I'm not sure what the version number should be, so I just guessed.
3668   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3669   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3670   if test "${HAVE_LIBXML2}" != "yes" && test "$opsys" = "darwin"; then
3671     SAVE_CPPFLAGS="$CPPFLAGS"
3672     if test -z "$xcsdkdir" -a -n "$XCRUN" -a ! -d /usr/include; then
3673       dnl /usr/include is not found.  Try Xcode SDK dir if it is sane.
3674       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
3675       case $xcsdkdir in
3676         *[[\\\"\#\$\&\'\`$am_lf\ \      ]]*)
3677         xcsdkdir="" ;;
3678       esac
3679     fi
3680     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3681     AC_CHECK_HEADER(libxml/HTMLparser.h,
3682       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3683                      [#include <libxml/HTMLparser.h>])])
3684     CPPFLAGS="$SAVE_CPPFLAGS"
3685     if test "${HAVE_LIBXML2}" = "yes"; then
3686       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3687       LIBXML2_LIBS="-lxml2"
3688     fi
3689   fi
3690   if test "${HAVE_LIBXML2}" = "yes"; then
3691     if test "${opsys}" != "mingw32"; then
3692       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no,
3693         [$LIBXML2_LIBS])
3694     else
3695       LIBXML2_LIBS=""
3696     fi
3697     if test "${HAVE_LIBXML2}" = "yes"; then
3698       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3699     else
3700       LIBXML2_LIBS=""
3701       LIBXML2_CFLAGS=""
3702     fi
3703   fi
3704 fi
3705 AC_SUBST(LIBXML2_LIBS)
3706 AC_SUBST(LIBXML2_CFLAGS)
3707
3708 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3709 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3710 if test "${opsys}" = "mingw32"; then
3711   emacs_cv_netdb_declares_h_errno=yes
3712 fi
3713 AC_CACHE_CHECK(whether netdb declares h_errno,
3714                emacs_cv_netdb_declares_h_errno,
3715 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3716   [[return h_errno;]])],
3717   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3718 if test $emacs_cv_netdb_declares_h_errno = yes; then
3719   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3720 fi
3721
3722 # Check for mail-locking functions in a "mail" library.  Probably this should
3723 # have the same check as for liblockfile below.
3724 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3725 if test $have_mail = yes; then
3726   LIBS_MAIL=-lmail
3727   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the 'mail' library (-lmail).])
3728
3729   OLD_LIBS=$LIBS
3730   LIBS="$LIBS_MAIL $LIBS"
3731   AC_CHECK_FUNCS(touchlock)
3732   LIBS=$OLD_LIBS
3733 else
3734   LIBS_MAIL=
3735 fi
3736 dnl Debian, at least:
3737 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3738 if test $have_lockfile = yes; then
3739    LIBS_MAIL=-llockfile
3740    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the 'lockfile' library (-llockfile).])
3741 else
3742 # If we have the shared liblockfile, assume we must use it for mail
3743 # locking (e.g. Debian).  If we couldn't link against liblockfile
3744 # (no liblockfile.a installed), ensure that we don't need to.
3745   dnl This works for files generally, not just executables.
3746   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3747   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3748                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3749   if test $ac_cv_prog_liblockfile = yes; then
3750     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3751 This probably means that movemail could lose mail.
3752 There may be a 'development' package to install containing liblockfile.])
3753   fi
3754 fi
3755 AC_CHECK_HEADERS_ONCE(maillock.h)
3756 AC_SUBST(LIBS_MAIL)
3757
3758 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3759 ## interlock access to the mail spool.  The alternative is a lock file named
3760 ## /usr/spool/mail/$USER.lock.
3761 mail_lock=no
3762 case "$opsys" in
3763   aix4-2) mail_lock="lockf" ;;
3764
3765   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3766
3767   ## On GNU/Linux systems, both methods are used by various mail programs.
3768   ## I assume most people are using newer mailers that have heard of flock.
3769   ## Change this if you need to.
3770   ## Debian contains a patch which says: "On Debian/GNU/Linux systems,
3771   ## configure gets the right answers, and that means *NOT* using flock.
3772   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3773   ## for details." and then uses '#ifdef DEBIAN'.  Unfortunately the
3774   ## Debian maintainer hasn't provided a clean fix for Emacs.
3775   ## movemail.c will use 'maillock' when MAILDIR, HAVE_LIBMAIL and
3776   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3777   ## correct logic.  -- fx
3778   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3779   ## liblockfile is a Free Software replacement for libmail, used on
3780   ## Debian systems and elsewhere. -rfr.
3781   gnu-*)
3782     mail_lock="flock"
3783     if test $have_mail = yes || test $have_lockfile = yes; then
3784       test $ac_cv_header_maillock_h = yes && mail_lock=no
3785     fi
3786     ;;
3787
3788   mingw32)
3789     mail_lock="none-needed" ;;
3790 esac
3791
3792 BLESSMAIL_TARGET=
3793 case "$mail_lock" in
3794   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3795
3796   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3797
3798   none-needed) ;;
3799
3800   *) BLESSMAIL_TARGET="need-blessmail" ;;
3801 esac
3802 AC_SUBST(BLESSMAIL_TARGET)
3803
3804 OLD_LIBS=$LIBS
3805 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3806 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3807 getrusage get_current_dir_name \
3808 lrand48 random rint \
3809 select getpagesize setlocale newlocale \
3810 getrlimit setrlimit shutdown getaddrinfo \
3811 pthread_sigmask strsignal setitimer \
3812 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3813 gai_strerror sync \
3814 getpwent endpwent getgrent endgrent \
3815 cfmakeraw cfsetspeed copysign __executable_start log2)
3816 LIBS=$OLD_LIBS
3817
3818 dnl No need to check for posix_memalign if aligned_alloc works.
3819 AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3820 AC_CHECK_DECLS([aligned_alloc], [], [], [[#include <stdlib.h>]])
3821
3822 dnl Cannot use AC_CHECK_FUNCS
3823 AC_CACHE_CHECK([for __builtin_unwind_init],
3824                emacs_cv_func___builtin_unwind_init,
3825 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3826                 emacs_cv_func___builtin_unwind_init=yes,
3827                 emacs_cv_func___builtin_unwind_init=no)])
3828 if test $emacs_cv_func___builtin_unwind_init = yes; then
3829   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3830             [Define to 1 if you have the '__builtin_unwind_init' function.])
3831 fi
3832
3833 AC_CHECK_HEADERS_ONCE(sys/un.h)
3834
3835 AC_FUNC_FSEEKO
3836
3837 # UNIX98 PTYs.
3838 AC_CHECK_FUNCS(grantpt)
3839
3840 # PTY-related GNU extensions.
3841 AC_CHECK_FUNCS(getpt posix_openpt)
3842
3843 # Check this now, so that we will NOT find the above functions in ncurses.
3844 # That is because we have not set up to link ncurses in lib-src.
3845 # It's better to believe a function is not available
3846 # than to expect to find it in ncurses.
3847 # Also we need tputs and friends to be able to build at all.
3848 AC_MSG_CHECKING([for library containing tputs])
3849 # Run a test program that contains a call to tputs, a call that is
3850 # never executed.  This tests whether a pre-'main' dynamic linker
3851 # works with the library.  It's too much trouble to actually call
3852 # tputs in the test program, due to portability hassles.  When
3853 # cross-compiling, assume the test program will run if it links.
3854 AC_DEFUN([tputs_link_source], [
3855   AC_LANG_SOURCE(
3856      [[extern void tputs (const char *, int, int (*)(int));
3857        int main (int argc, char **argv)
3858        {
3859           if (argc == 10000)
3860             tputs (argv[0], 0, 0);
3861           return 0;
3862        }]])
3863 ])
3864 if test "${opsys}" = "mingw32"; then
3865   msg='none required'
3866 else
3867   # Maybe curses should be tried earlier?
3868   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3869   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3870     OLIBS=$LIBS
3871     if test -z "$tputs_library"; then
3872       LIBS_TERMCAP=
3873       msg='none required'
3874     else
3875       LIBS_TERMCAP=-l$tputs_library
3876       msg=$LIBS_TERMCAP
3877       LIBS="$LIBS_TERMCAP $LIBS"
3878     fi
3879     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3880       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3881     LIBS=$OLIBS
3882     if test "X$msg" != Xno; then
3883       break
3884     fi
3885   done
3886 fi
3887 AC_MSG_RESULT([$msg])
3888 if test "X$msg" = Xno; then
3889   AC_MSG_ERROR([The required function 'tputs' was not found in any library.
3890 The following libraries were tried (in order):
3891   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3892 Please try installing whichever of these libraries is most appropriate
3893 for your system, together with its header files.
3894 For example, a libncurses-dev(el) or similar package.])
3895 fi
3896
3897 ## Use termcap instead of terminfo?
3898 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3899 TERMINFO=yes
3900 ## FIXME?  In the cases below where we unconditionally set
3901 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3902 ## if that was found above to have tputs.
3903 ## Should we use the gnu* logic everywhere?
3904 case "$opsys" in
3905   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3906   ##  The ncurses library has been moved out of the System framework in
3907   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3908   ##  option to use it.
3909   darwin) LIBS_TERMCAP="-lncurses" ;;
3910
3911   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3912
3913   freebsd)
3914     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3915     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3916     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3917 [[#if __FreeBSD_version < 400000
3918 fail;
3919 #endif
3920 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3921
3922     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3923
3924     if test $emacs_cv_freebsd_terminfo = yes; then
3925       LIBS_TERMCAP="-lncurses"
3926     else
3927       TERMINFO=no
3928       LIBS_TERMCAP="-ltermcap"
3929     fi
3930     ;;
3931
3932   mingw32)
3933     TERMINFO=no
3934     LIBS_TERMCAP=
3935     ;;
3936
3937   netbsd)
3938     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3939       TERMINFO=no
3940       LIBS_TERMCAP="-ltermcap"
3941     fi
3942     ;;
3943
3944   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3945
3946   ## hpux: Make sure we get select from libc rather than from libcurses
3947   ##  because libcurses on HPUX 10.10 has a broken version of select.
3948   ##  We used to use -lc -lcurses, but this may be cleaner.
3949   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3950   # set that way, now it uses the default).  Isn't this a contradiction?
3951   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3952
3953 esac
3954
3955 TERMCAP_OBJ=tparam.o
3956 if test $TERMINFO = yes; then
3957   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3958   TERMCAP_OBJ=terminfo.o
3959 fi
3960 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3961   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3962 fi
3963 AC_SUBST(LIBS_TERMCAP)
3964 AC_SUBST(TERMCAP_OBJ)
3965
3966 # GNU/Linux-specific timer functions.
3967 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
3968   [AC_COMPILE_IFELSE(
3969      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
3970                       ]],
3971                       [[timerfd_create (CLOCK_REALTIME,
3972                                         TFD_CLOEXEC | TFD_NONBLOCK);
3973                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
3974      [emacs_cv_have_timerfd=yes],
3975      [emacs_cv_have_timerfd=no])])
3976 if test "$emacs_cv_have_timerfd" = yes; then
3977   AC_DEFINE([HAVE_TIMERFD], 1,
3978     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
3979 fi
3980
3981 # Alternate stack for signal handlers.
3982 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
3983                [emacs_cv_alternate_stack],
3984   [AC_COMPILE_IFELSE(
3985      [AC_LANG_PROGRAM([[#include <signal.h>
3986                       ]],
3987                       [[stack_t ss;
3988                         struct sigaction sa;
3989                         ss.ss_sp = malloc (SIGSTKSZ);
3990                         ss.ss_size = SIGSTKSZ;
3991                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
3992                         sigaltstack (&ss, 0);
3993                         sigaction (SIGSEGV, &sa, 0);]])],
3994      [emacs_cv_alternate_stack=yes],
3995      [emacs_cv_alternate_stack=no])])
3996
3997 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3998 # On Darwin, res_init appears not to be useful: see bug#562 and
3999 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
4000 resolv=no
4001
4002 if test $opsys != darwin; then
4003
4004   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
4005 #include <arpa/nameser.h>
4006 #include <resolv.h>]],
4007     [[return res_init();]])],
4008     have_res_init=yes, have_res_init=no)
4009   if test "$have_res_init" = no; then
4010     OLIBS="$LIBS"
4011     LIBS="$LIBS -lresolv"
4012     AC_MSG_CHECKING(for res_init with -lresolv)
4013     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
4014 #include <arpa/nameser.h>
4015 #include <resolv.h>]],
4016       [[return res_init();]])],
4017       have_res_init=yes, have_res_init=no)
4018     AC_MSG_RESULT($have_res_init)
4019     if test "$have_res_init" = yes ; then
4020       resolv=yes
4021     fi
4022     LIBS="$OLIBS"
4023   fi
4024
4025   if test "$have_res_init" = yes; then
4026     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
4027   fi
4028 fi                              dnl !darwin
4029
4030 # Do we need the Hesiod library to provide the support routines?
4031 dnl FIXME?  Should we be skipping this on Darwin too?
4032 LIBHESIOD=
4033 if test "$with_hesiod" != no ; then
4034   # Don't set $LIBS here -- see comments above.  FIXME which comments?
4035   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
4036      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
4037                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
4038   if test "$resolv" = yes ; then
4039     RESOLVLIB=-lresolv
4040   else
4041     RESOLVLIB=
4042   fi
4043   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
4044         hesiod=yes, :, $RESOLVLIB)])
4045
4046   if test x"$hesiod" = xyes; then
4047     LIBHESIOD=-lhesiod
4048   fi
4049 fi
4050 AC_SUBST(LIBHESIOD)
4051
4052 # Do we need libresolv (due to res_init or Hesiod)?
4053 if test "$resolv" = yes && test $opsys != darwin; then
4054   LIBRESOLV=-lresolv
4055 else
4056   LIBRESOLV=
4057 fi
4058 AC_SUBST(LIBRESOLV)
4059
4060 # These tell us which Kerberos-related libraries to use.
4061 COM_ERRLIB=
4062 CRYPTOLIB=
4063 KRB5LIB=
4064 DESLIB=
4065 KRB4LIB=
4066
4067 if test "${with_kerberos}" != no; then
4068   OLD_LIBS=$LIBS
4069   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
4070   if test $have_com_err = yes; then
4071     COM_ERRLIB=-lcom_err
4072     LIBS="$COM_ERRLIB $LIBS"
4073   fi
4074   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
4075   if test $have_crypto = yes; then
4076     CRYPTOLIB=-lcrypto
4077     LIBS="$CRYPTOLIB $LIBS"
4078   fi
4079   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
4080   if test $have_k5crypto = yes; then
4081     CRYPTOLIB=-lk5crypto
4082     LIBS="$CRYPTOLIB $LIBS"
4083   fi
4084   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
4085   if test $have_krb5=yes; then
4086     KRB5LIB=-lkrb5
4087     LIBS="$KRB5LIB $LIBS"
4088   fi
4089   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
4090   if test "${with_kerberos5}" = no; then
4091     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
4092     if test $have_des425 = yes; then
4093       DESLIB=-ldes425
4094       LIBS="$DESLIB $LIBS"
4095     else
4096       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
4097       if test $have_des = yes; then
4098         DESLIB=-ldes
4099         LIBS="$DESLIB $LIBS"
4100       fi
4101     fi
4102     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
4103     if test $have_krb4 = yes; then
4104       KRB4LIB=-lkrb4
4105       LIBS="$KRB4LIB $LIBS"
4106     else
4107       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
4108       if test $have_krb = yes; then
4109         KRB4LIB=-lkrb
4110         LIBS="$KRB4LIB $LIBS"
4111       fi
4112     fi
4113   fi
4114
4115   if test "${with_kerberos5}" != no; then
4116     AC_CHECK_HEADERS(krb5.h,
4117       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
4118                         [#include <krb5.h>])])
4119   else
4120     AC_CHECK_HEADERS(krb.h,,
4121                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
4122                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
4123   fi
4124   AC_CHECK_HEADERS(com_err.h)
4125   LIBS=$OLD_LIBS
4126 fi
4127
4128 AC_SUBST(COM_ERRLIB)
4129 AC_SUBST(CRYPTOLIB)
4130 AC_SUBST(KRB5LIB)
4131 AC_SUBST(DESLIB)
4132 AC_SUBST(KRB4LIB)
4133
4134 AC_CHECK_HEADERS(valgrind/valgrind.h)
4135
4136 AC_CHECK_MEMBERS([struct unipair.unicode], [], [], [[#include <linux/kd.h>]])
4137
4138 AC_CHECK_FUNCS_ONCE(tzset)
4139
4140 ok_so_far=yes
4141 AC_CHECK_FUNC(socket, , ok_so_far=no)
4142 if test $ok_so_far = yes; then
4143   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
4144 fi
4145 if test $ok_so_far = yes; then
4146   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
4147 fi
4148 if test $ok_so_far = yes; then
4149 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
4150   AC_DEFINE(HAVE_INET_SOCKETS, 1,
4151             [Define to 1 if you have inet sockets.])
4152 fi
4153
4154 AC_FUNC_FORK
4155
4156 AC_CHECK_FUNCS(snprintf)
4157
4158 dnl Check for glib.  This differs from other library checks in that
4159 dnl Emacs need not link to glib unless some other library is already
4160 dnl linking to glib.  Although glib provides no facilities that Emacs
4161 dnl needs for its own purposes, when glib is present Emacs needs to
4162 dnl use primitives like g_main_context_query to avoid clashing with
4163 dnl glib at a low level.
4164 dnl
4165 dnl Check this late, since it depends on $GTK_CFLAGS etc.
4166 XGSELOBJ=
4167 OLDCFLAGS="$CFLAGS"
4168 OLDLIBS="$LIBS"
4169 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
4170 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
4171 CFLAGS="$CFLAGS $NOTIFY_CFLAGS $CAIRO_CFLAGS"
4172 LIBS="$LIBS $NOTIFY_LIBS $CAIRO_LIBS"
4173 AC_MSG_CHECKING([whether GLib is linked in])
4174 AC_LINK_IFELSE([AC_LANG_PROGRAM(
4175         [[#include <glib.h>
4176         ]],
4177         [[g_print ("Hello world");]])],
4178      [links_glib=yes],
4179      [links_glib=no])
4180 AC_MSG_RESULT([$links_glib])
4181 if test "${links_glib}" = "yes"; then
4182   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
4183   if test "$HAVE_NS" = no;then
4184     XGSELOBJ=xgselect.o
4185   fi
4186 fi
4187 CFLAGS="$OLDCFLAGS"
4188 LIBS="$OLDLIBS"
4189 AC_SUBST(XGSELOBJ)
4190
4191 dnl Adapted from Haible's version.
4192 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
4193   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
4194     [[char* cs = nl_langinfo(CODESET);]])],
4195     emacs_cv_langinfo_codeset=yes,
4196     emacs_cv_langinfo_codeset=no)
4197   ])
4198 if test $emacs_cv_langinfo_codeset = yes; then
4199   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
4200     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
4201 fi
4202
4203 AC_TYPE_MBSTATE_T
4204
4205 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
4206 dnl how the tty code is related to POSIX and/or other versions of termios.
4207 dnl The following looks like a useful start.
4208 dnl
4209 dnl AC_SYS_POSIX_TERMIOS
4210 dnl if test $ac_cv_sys_posix_termios = yes; then
4211 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
4212 dnl                                and macros for terminal control.])
4213 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
4214 dnl fi
4215
4216 dnl Turned on June 1996 supposing nobody will mind it.
4217 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
4218 if test "${opsys}" != "mingw32"; then
4219    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
4220      in the full name stands for the login id.])
4221 fi
4222
4223 dnl Everybody supports this, except MS.
4224 dnl Seems like the kind of thing we should be testing for, though.
4225 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4226 if test "${opsys}" != "mingw32"; then
4227   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4228 fi
4229
4230 dnl Everybody supports this, except MS-DOS.
4231 dnl Seems like the kind of thing we should be testing for, though.
4232 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4233 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4234   4.2-compatible sockets.])
4235
4236 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4237
4238 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4239   a null file, or a data sink.])
4240 if test "${opsys}" = "mingw32"; then
4241   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4242 else
4243   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4244 fi
4245
4246 if test "${opsys}" = "mingw32"; then
4247   SEPCHAR=';'
4248 else
4249   SEPCHAR=':'
4250 fi
4251 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4252 dnl This is for MinGW, and is used in test/Makefile.in.
4253 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4254 dnl decides that a command-line argument to be passed to a MinGW program
4255 dnl is a PATH-style list of directories.  But that heuristics plays it
4256 dnl safe, and only does the replacement when it is _absolutely_ sure it
4257 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4258 dnl which breaks in-tree builds.  So we do this manually instead.
4259 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4260 dnl be computed as ':' in MSYS Bash.
4261 AC_SUBST(SEPCHAR)
4262
4263 dnl Everybody supports this, except MS-DOS.
4264 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4265
4266 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4267
4268
4269 AC_DEFINE(DIRECTORY_SEP, ['/'],
4270   [Character that separates directories in a file name.])
4271
4272 if test "${opsys}" = "mingw32"; then
4273   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4274     [Returns true if character is a device separator.])
4275
4276   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4277     [Returns true if character is a directory separator.])
4278
4279   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4280     [Returns true if character is any form of separator.])
4281 else
4282   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4283     [Returns true if character is a device separator.])
4284
4285   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4286     [Returns true if character is a directory separator.])
4287
4288   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4289     [Returns true if character is any form of separator.])
4290 fi
4291
4292 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4293
4294 case $opsys in
4295   aix4-2)
4296     dnl Unfortunately without libXmu we cannot support EditRes.
4297     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4298       AC_DEFINE(NO_EDITRES, 1)
4299     fi
4300     ;;
4301
4302   hpux*)
4303     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4304     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4305     AC_DEFINE(NO_EDITRES, 1)
4306     ;;
4307 esac
4308
4309
4310 case $opsys in
4311   irix6-5 | sol2* | unixware )
4312     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4313     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4314     dnl need the constant to dimension an array.  So wire in the appropriate
4315     dnl value here.
4316     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4317     ;;
4318 esac
4319
4320 emacs_broken_SIGIO=no
4321
4322 case $opsys in
4323   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4324   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4325   hpux* | irix6-5 | nacl | openbsd | sol2* | unixware )
4326     emacs_broken_SIGIO=yes
4327     ;;
4328
4329   aix4-2)
4330     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4331     dnl the way this system works, libc functions that return malloced
4332     dnl memory use the libc malloc implementation. Calling xfree or
4333     dnl xrealloc on the results of such functions results in a crash.
4334     dnl
4335     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4336     dnl but that does not currently work on this system.
4337     dnl
4338     dnl It is possible to completely override the malloc implementation on
4339     dnl AIX, but that involves putting the malloc functions in a shared
4340     dnl library and setting the MALLOCTYPE environment variable to point to
4341     dnl that shared library.
4342     dnl
4343     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4344     dnl to avoid a crash just use the Emacs implementation for that function.
4345     dnl
4346     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4347     dnl of this file, so that we do not check for get_current_dir_name
4348     dnl on AIX.  But that might be fragile if something else ends
4349     dnl up testing for get_current_dir_name as a dependency.
4350     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4351       get_current_dir_name should not be used.])
4352     ;;
4353
4354   freebsd)
4355     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4356     dnl writes/reads on a PTY, read(2) returns bogus data:
4357     dnl
4358     dnl write(2)  1022 bytes
4359     dnl write(2)   954 bytes, get EAGAIN
4360     dnl read(2)   1024 bytes in process_read_output
4361     dnl read(2)     11 bytes in process_read_output
4362     dnl
4363     dnl That is, read(2) returns more bytes than have ever been written
4364     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4365     dnl successfully after processing (for example with CRs added if the
4366     dnl terminal is set up that way which it is here).  The same bytes will
4367     dnl be seen again in a later read(2), without the CRs.
4368     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4369       work around an issue when reading from a PTY.])
4370     ;;
4371 esac
4372
4373 case $opsys in
4374   gnu-* | sol2-10 )
4375     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4376     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4377   ;;
4378 esac
4379
4380 case $opsys in
4381   darwin | dragonfly | freebsd | netbsd | openbsd )
4382     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4383       close a pty to make it a controlling terminal (it is already a
4384       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4385   ;;
4386 esac
4387
4388 dnl FIXME Surely we can test for this rather than hard-code it.
4389 case $opsys in
4390   netbsd | openbsd) sound_device="/dev/audio" ;;
4391   *) sound_device="/dev/dsp" ;;
4392 esac
4393
4394 dnl Used in sound.c
4395 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4396   [Name of the default sound device.])
4397
4398
4399 dnl Emacs can read input using SIGIO and buffering characters itself,
4400 dnl or using CBREAK mode and making C-g cause SIGINT.
4401 dnl The choice is controlled by the variable interrupt_input.
4402 dnl
4403 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4404 dnl
4405 dnl Emacs uses the presence of the USABLE_SIGIO macro
4406 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4407 dnl INTERRUPT_INPUT to decide whether to use it by default.
4408 dnl
4409 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4410 dnl CBREAK mode has two disadvantages
4411 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4412 dnl I hear that in system V this problem does not exist.
4413 dnl 2) Control-G causes output to be discarded.
4414 dnl I do not know whether this can be fixed in system V.
4415 dnl
4416 dnl Another method of doing input is planned but not implemented.
4417 dnl It would have Emacs fork off a separate process
4418 dnl to read the input and send it to the true Emacs process
4419 dnl through a pipe.
4420 case $opsys in
4421   darwin | gnu-linux | gnu-kfreebsd )
4422     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4423   ;;
4424 esac
4425
4426
4427 dnl If the system's imake configuration file defines 'NeedWidePrototypes'
4428 dnl as 'NO', we must define NARROWPROTO manually.  Such a define is
4429 dnl generated in the Makefile generated by 'xmkmf'.  If we don't define
4430 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4431 dnl taking float or double parameters.
4432 case $opsys in
4433   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4434     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4435       file defines 'NeedWidePrototypes' as 'NO'.])
4436   ;;
4437 esac
4438
4439
4440 dnl Used in process.c, this must be a loop, even if it only runs once.
4441 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4442 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4443 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4444 dnl trying suffixes 0-16.
4445 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4446   first PTY, if PTYs are supported.])
4447 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4448 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4449   end of a PTY, if non-standard.])
4450 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4451   end of a PTY, if non-standard.])
4452
4453 case $opsys in
4454   aix4-2 )
4455     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4456     dnl You allocate a pty by opening /dev/ptc to get the master side.
4457     dnl To get the name of the slave side, you just ttyname() the master side.
4458     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4459     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4460     ;;
4461
4462   cygwin )
4463     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4464     dnl multi-line AC_DEFINEs are hard. :(
4465     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4466     AC_DEFINE(PTY_NAME_SPRINTF, [])
4467     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4468     ;;
4469
4470   gnu | openbsd )
4471     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4472     ;;
4473
4474   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd | darwin | nacl )
4475     dnl if HAVE_GRANTPT
4476     if test "x$ac_cv_func_grantpt" = xyes; then
4477       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4478       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4479       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4480       dnl to prevent sigchld_handler from intercepting the child's death.
4481       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4482       dnl if HAVE_POSIX_OPENPT
4483       if test "x$ac_cv_func_posix_openpt" = xyes; then
4484         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4485         AC_DEFINE(PTY_NAME_SPRINTF, [])
4486       dnl if HAVE_GETPT
4487       elif test "x$ac_cv_func_getpt" = xyes; then
4488         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4489         AC_DEFINE(PTY_NAME_SPRINTF, [])
4490       else
4491         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4492       fi
4493     else
4494       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4495     fi
4496     ;;
4497
4498   hpux*)
4499     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4500     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4501     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4502     ;;
4503
4504   irix6-5 )
4505     dnl It looks like this cannot be right, because it is not a loop.
4506     dnl However, process.c actually does this:
4507     dnl # ifndef __sgi
4508     dnl   continue;
4509     dnl # else
4510     dnl   return -1;
4511     dnl # endif
4512     dnl which presumably makes it OK, since irix == sgi (?).
4513     dnl FIXME it seems like this special treatment is unnecessary?
4514     dnl Why can't irix use a single-trip loop like eg cygwin?
4515     AC_DEFINE(PTY_ITERATION, [])
4516     dnl Not used, because PTY_ITERATION is defined.
4517     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4518     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4519     dnl No need to get the pty name at all.
4520     AC_DEFINE(PTY_NAME_SPRINTF, [])
4521     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4522     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4523     ;;
4524
4525   sol2* )
4526     dnl On SysVr4, grantpt(3) forks a subprocess, so do not use
4527     dnl O_CLOEXEC when opening the pty, and keep the SIGCHLD handler
4528     dnl from intercepting that death.  If any child but grantpt's should die
4529     dnl within, it should be caught after sigrelse(2).
4530     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4531     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4532     ;;
4533
4534   unixware )
4535     dnl Comments are as per sol2*.
4536     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4537     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4538     ;;
4539 esac
4540
4541
4542 case $opsys in
4543   sol2* | unixware )
4544     dnl This change means that we don't loop through allocate_pty too
4545     dnl many times in the (rare) event of a failure.
4546     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4547     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4548     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4549     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (forkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (forkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (forkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4550     ;;
4551 esac
4552
4553
4554 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4555 "typing" a signal character on the pty.])
4556
4557 case $opsys in
4558   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4559   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4560   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4561     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4562     ;;
4563
4564   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4565   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4566   gnu-linux | gnu-kfreebsd )
4567
4568     AC_MSG_CHECKING([for signals via characters])
4569     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4570 #include <linux/version.h>
4571 #if LINUX_VERSION_CODE < 0x20400
4572 # error "Linux version too old"
4573 #endif
4574       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4575
4576     AC_MSG_RESULT([$emacs_signals_via_chars])
4577     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4578     ;;
4579 esac
4580
4581
4582 AH_TEMPLATE(TAB3, [Undocumented.])
4583
4584 case $opsys in
4585   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4586
4587   gnu | dragonfly | freebsd | netbsd | openbsd )
4588     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4589     AC_DEFINE(TAB3, OXTABS)
4590     ;;
4591
4592   gnu-linux | gnu-kfreebsd )
4593     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4594 #ifndef __ia64__
4595 # error "not ia64"
4596 #endif
4597       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4598         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4599         [Mark a secondary stack, like the register stack on the ia64.]), [])
4600     ;;
4601
4602   hpux*)
4603     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4604       run_time_remap; for HPUX.])
4605     ;;
4606 esac
4607
4608
4609 dnl This won't be used automatically yet.  We also need to know, at least,
4610 dnl that the stack is continuous.
4611 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4612   registers relevant for conservative garbage collection in the jmp_buf.])
4613
4614
4615 case $opsys in
4616   dnl Not all the architectures are tested, but there are Debian packages
4617   dnl for SCM and/or Guile on them, so the technique must work.  See also
4618   dnl comments in alloc.c concerning setjmp and gcc.
4619   dnl Fixme: it's probably safe to just use the GCC conditional below.
4620   gnu-linux | gnu-kfreebsd )
4621     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4622 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4623   || defined __alpha__ || defined __mips__ || defined __s390__ \
4624   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4625   || defined __ia64__ || defined __sh__
4626 /* ok */
4627 #else
4628 # error "setjmp not known to work on this arch"
4629 #endif
4630     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4631     ;;
4632 esac
4633
4634
4635 if test x$GCC = xyes; then
4636    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4637    AC_DEFINE(GC_SETJMP_WORKS, 1)
4638 else
4639   case $opsys in
4640     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4641     aix* | dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4642       AC_DEFINE(GC_SETJMP_WORKS, 1)
4643       ;;
4644   esac
4645 fi                              dnl GCC?
4646
4647 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4648 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4649   [AC_LINK_IFELSE(
4650      [AC_LANG_PROGRAM(
4651        [[#include <setjmp.h>
4652          #ifdef __MINGW32__
4653          # define _longjmp longjmp
4654          #endif
4655        ]],
4656        [[jmp_buf j;
4657          if (! _setjmp (j))
4658            _longjmp (j, 1);]])],
4659      [emacs_cv_func__setjmp=yes],
4660      [emacs_cv_func__setjmp=no])])
4661 if test $emacs_cv_func__setjmp = yes; then
4662   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4663 fi
4664
4665 # We need to preserve signal mask to handle C stack overflows.
4666 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4667   [AC_LINK_IFELSE(
4668      [AC_LANG_PROGRAM(
4669        [[#include <setjmp.h>
4670        ]],
4671        [[sigjmp_buf j;
4672          if (! sigsetjmp (j, 1))
4673            siglongjmp (j, 1);]])],
4674      [emacs_cv_func_sigsetjmp=yes],
4675      [emacs_cv_func_sigsetjmp=no])])
4676 if test $emacs_cv_func_sigsetjmp = yes; then
4677   AC_DEFINE([HAVE_SIGSETJMP], 1,
4678     [Define to 1 if sigsetjmp and siglongjmp work.])
4679 fi
4680
4681 case $emacs_cv_func_sigsetjmp,$emacs_cv_alternate_stack,$opsys in
4682   yes,yes,* | *,*,mingw32)
4683     AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4684       [Define to 1 if C stack overflow can be handled in some cases.]);;
4685 esac
4686
4687 case $opsys in
4688   sol2* | unixware )
4689     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4690     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4691     dnl and this is all we need.
4692     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4693     ;;
4694 esac
4695
4696
4697 case $opsys in
4698   hpux* | sol2* )
4699     dnl Used in xfaces.c.
4700     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4701       some systems, where it requires time.h.])
4702     ;;
4703 esac
4704
4705
4706 dnl Define symbols to identify the version of Unix this is.
4707 dnl Define all the symbols that apply correctly.
4708 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4709 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4710 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4711 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4712
4713 case $opsys in
4714   aix4-2)
4715     AC_DEFINE(USG, [])
4716     dnl This symbol should be defined on AIX Version 3  ???????
4717     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4718 #ifndef _AIX
4719 # error "_AIX not defined"
4720 #endif
4721     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4722     ;;
4723
4724   cygwin)
4725     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4726     ;;
4727
4728   darwin)
4729     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4730     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4731     dnl distinguish OS X from pure Darwin.
4732     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4733     ;;
4734
4735   gnu-linux | gnu-kfreebsd )
4736     AC_DEFINE(USG, [])
4737     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4738     ;;
4739
4740   hpux*)
4741     AC_DEFINE(USG, [])
4742     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4743     ;;
4744
4745   irix6-5)
4746     AC_DEFINE(USG, [])
4747     AC_DEFINE(USG5_4, [])
4748     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4749     ;;
4750
4751   mingw32)
4752     AC_DEFINE(DOS_NT, [])
4753     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4754     if test "x$ac_enable_checking" != "x" ; then
4755       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4756     fi
4757     ;;
4758
4759   sol2*)
4760     AC_DEFINE(USG, [])
4761     AC_DEFINE(USG5_4, [])
4762     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4763     ;;
4764
4765   unixware)
4766     AC_DEFINE(USG, [])
4767     AC_DEFINE(USG5_4, [])
4768     ;;
4769 esac
4770
4771 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4772   [case $opsys in
4773      aix4-2 | nacl)
4774        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4775        emacs_cv_usable_FIONREAD=no
4776        ;;
4777
4778      mingw32)
4779        emacs_cv_usable_FIONREAD=yes
4780        ;;
4781
4782      *)
4783        AC_COMPILE_IFELSE(
4784          [AC_LANG_PROGRAM([[#include <sys/types.h>
4785                             #include <sys/ioctl.h>
4786                             #ifdef USG5_4
4787                             # include <sys/filio.h>
4788                             #endif
4789                           ]],
4790                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4791          [emacs_cv_usable_FIONREAD=yes],
4792          [emacs_cv_usable_FIONREAD=no])
4793        ;;
4794    esac])
4795 if test $emacs_cv_usable_FIONREAD = yes; then
4796   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4797
4798   if test $emacs_broken_SIGIO = no; then
4799     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4800       [AC_COMPILE_IFELSE(
4801          [AC_LANG_PROGRAM([[#include <fcntl.h>
4802                             #include <signal.h>
4803                           ]],
4804                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4805          [emacs_cv_usable_SIGIO=yes],
4806          [emacs_cv_usable_SIGIO=no])],
4807       [emacs_cv_usable_SIGIO=yes],
4808       [emacs_cv_usable_SIGIO=no])
4809     if test $emacs_cv_usable_SIGIO = yes; then
4810       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4811     fi
4812   fi
4813 fi
4814
4815 case $opsys in
4816   hpux11)
4817     dnl It works to open the pty's tty in the parent (Emacs), then
4818     dnl close and reopen it in the child.
4819     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4820       works to open a pty's tty in the parent process, then close and
4821       reopen it in the child.])
4822     ;;
4823
4824   irix6-5)
4825     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4826       use VSUSP instead of VSWTCH.])
4827     ;;
4828
4829   sol2-10)
4830     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4831       on Solaris.])
4832     ;;
4833 esac
4834
4835 # Set up the CFLAGS for real compilation, so we can substitute it.
4836 CFLAGS="$REAL_CFLAGS"
4837 CPPFLAGS="$REAL_CPPFLAGS"
4838 LIBS="$REAL_LIBS"
4839
4840 ## Hack to detect a buggy GCC version.
4841 if test "$GCC" = yes && \
4842    $CC --version 2> /dev/null | grep 'gcc.* 4.5.0' >/dev/null; then
4843   case $CFLAGS in
4844     *-fno-optimize-sibling-calls*) ;;
4845     *-O@<:@23@:>@*)
4846       AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS.]);;
4847   esac
4848 fi
4849
4850 version=$PACKAGE_VERSION
4851
4852 copyright="Copyright (C) 2016 Free Software Foundation, Inc."
4853 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4854   [Short copyright string for this version of Emacs.])
4855 AC_SUBST(copyright)
4856
4857 ### Specify what sort of things we'll be editing into Makefile and config.h.
4858 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4859 AC_SUBST(version)
4860 AC_SUBST(configuration)
4861 ## Unused?
4862 AC_SUBST(canonical)
4863 AC_SUBST(srcdir)
4864 AC_SUBST(prefix)
4865 AC_SUBST(exec_prefix)
4866 AC_SUBST(bindir)
4867 AC_SUBST(datadir)
4868 AC_SUBST(sharedstatedir)
4869 AC_SUBST(libexecdir)
4870 AC_SUBST(mandir)
4871 AC_SUBST(infodir)
4872 AC_SUBST(lispdir)
4873 AC_SUBST(standardlisppath)
4874 AC_SUBST(locallisppath)
4875 AC_SUBST(lisppath)
4876 AC_SUBST(x_default_search_path)
4877 AC_SUBST(etcdir)
4878 AC_SUBST(archlibdir)
4879 AC_SUBST(etcdocdir)
4880 AC_SUBST(bitmapdir)
4881 AC_SUBST(gamedir)
4882 AC_SUBST(gameuser)
4883 AC_SUBST(gamegroup)
4884 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4885 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4886 ## end of LIBX_BASE, but nothing ever set it.
4887 AC_SUBST(LD_SWITCH_X_SITE)
4888 AC_SUBST(C_SWITCH_X_SITE)
4889 AC_SUBST(GNUSTEP_CFLAGS)
4890 AC_SUBST(CFLAGS)
4891 ## Used in lwlib/Makefile.in.
4892 AC_SUBST(X_TOOLKIT_TYPE)
4893 AC_SUBST(ns_appdir)
4894 AC_SUBST(ns_appbindir)
4895 AC_SUBST(ns_appresdir)
4896 AC_SUBST(ns_appsrc)
4897 AC_SUBST(GNU_OBJC_CFLAGS)
4898 AC_SUBST(OTHER_FILES)
4899
4900 if test -n "${term_header}"; then
4901     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4902         [Define to the header for the built-in window system.])
4903 fi
4904
4905 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4906                    [Define to the canonical Emacs configuration name.])
4907 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4908                    [Define to the options passed to configure.])
4909 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4910   define this to include extra configuration information.])
4911
4912 case $opsys in
4913   mingw32)
4914     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4915     ;;
4916 esac
4917
4918 XMENU_OBJ=
4919 XOBJ=
4920 FONT_OBJ=
4921 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4922   AC_DEFINE(HAVE_X_WINDOWS, 1,
4923             [Define to 1 if you want to use the X window system.])
4924   XMENU_OBJ=xmenu.o
4925   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4926   FONT_OBJ=xfont.o
4927   if test "$HAVE_CAIRO" = "yes"; then
4928     FONT_OBJ="ftfont.o ftcrfont.o"
4929   elif test "$HAVE_XFT" = "yes"; then
4930     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4931   elif test "$HAVE_FREETYPE" = "yes"; then
4932     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4933   fi
4934   AC_SUBST(FONT_OBJ)
4935 fi
4936 AC_SUBST(XMENU_OBJ)
4937 AC_SUBST(XOBJ)
4938 AC_SUBST(FONT_OBJ)
4939
4940 WIDGET_OBJ=
4941 MOTIF_LIBW=
4942 if test "${USE_X_TOOLKIT}" != "none" ; then
4943   WIDGET_OBJ=widget.o
4944   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4945   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4946     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4947   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4948     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4949     MOTIF_LIBW=-lXm
4950     case "$opsys" in
4951       gnu-linux)
4952         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4953         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4954         ;;
4955
4956       unixware)
4957         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4958         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4959         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4960         ;;
4961
4962       aix4-2)
4963         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4964         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4965         ;;
4966     esac
4967     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4968   fi
4969 fi
4970 AC_SUBST(WIDGET_OBJ)
4971
4972 TOOLKIT_LIBW=
4973 case "$USE_X_TOOLKIT" in
4974   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4975   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4976   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4977 esac
4978 if test "$HAVE_XWIDGETS" = "yes"; then
4979   TOOLKIT_LIBW="$TOOLKIT_LIBW -lXcomposite"
4980 fi
4981 AC_SUBST(TOOLKIT_LIBW)
4982
4983 if test "${opsys}" != "mingw32"; then
4984   if test "$USE_X_TOOLKIT" = "none"; then
4985     LIBXT_OTHER="\$(LIBXSM)"
4986   else
4987     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4988   fi
4989 fi
4990 AC_SUBST(LIBXT_OTHER)
4991
4992 if test "${HAVE_X11}" = "yes" ; then
4993   AC_DEFINE(HAVE_X11, 1,
4994             [Define to 1 if you want to use version 11 of X windows.])
4995   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4996 else
4997   LIBX_OTHER=
4998 fi
4999 AC_SUBST(LIBX_OTHER)
5000
5001 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
5002   LIBXMENU=
5003 elif test "$USE_X_TOOLKIT" = none; then
5004   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
5005 else
5006   LIBXMENU='$(lwlibdir)/liblw.a'
5007 fi
5008 AC_SUBST(LIBXMENU)
5009
5010 AC_CACHE_CHECK([for struct alignment],
5011   [emacs_cv_struct_alignment],
5012   [AC_COMPILE_IFELSE(
5013      [AC_LANG_PROGRAM([[#include <stddef.h>
5014                         struct __attribute__ ((aligned (8))) s { char c; };
5015                         struct t { char c; struct s s; };
5016                         char verify[offsetof (struct t, s) == 8 ? 1 : -1];
5017                       ]])],
5018      [emacs_cv_struct_alignment=yes],
5019      [emacs_cv_struct_alignment=no])])
5020 if test "$emacs_cv_struct_alignment" = yes; then
5021   AC_DEFINE([HAVE_STRUCT_ATTRIBUTE_ALIGNED], 1,
5022     [Define to 1 if 'struct __attribute__ ((aligned (N)))' aligns the
5023      structure to an N-byte boundary.])
5024 fi
5025
5026 if test "${GNU_MALLOC}" = "yes" ; then
5027   AC_DEFINE(GNU_MALLOC, 1,
5028             [Define to 1 if you want to use the GNU memory allocator.])
5029 fi
5030
5031 RALLOC_OBJ=
5032 if test "${REL_ALLOC}" = "yes" ; then
5033   AC_DEFINE(REL_ALLOC, 1,
5034             [Define REL_ALLOC if you want to use the relocating allocator for
5035              buffer space.])
5036
5037   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
5038 fi
5039 AC_SUBST(RALLOC_OBJ)
5040
5041 if test "$opsys" = "cygwin"; then
5042   CYGWIN_OBJ="cygw32.o"
5043   ## Cygwin differs because of its unexec().
5044   PRE_ALLOC_OBJ=
5045   POST_ALLOC_OBJ=lastfile.o
5046 elif test "$opsys" = "mingw32"; then
5047   CYGWIN_OBJ=
5048   PRE_ALLOC_OBJ=
5049   POST_ALLOC_OBJ=lastfile.o
5050 else
5051   CYGWIN_OBJ=
5052   PRE_ALLOC_OBJ=lastfile.o
5053   POST_ALLOC_OBJ=
5054 fi
5055 AC_SUBST(CYGWIN_OBJ)
5056 AC_SUBST(PRE_ALLOC_OBJ)
5057 AC_SUBST(POST_ALLOC_OBJ)
5058
5059 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
5060 dnl verbatim defined above.  The tricky name is apropos, as this hack
5061 dnl makes Fortify go sour!
5062 AH_VERBATIM([FORTIFY_SOUR],
5063 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
5064    The workaround disables some useful run-time checking, so it
5065    should be conditional to the platforms with the performance bug.
5066    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
5067 #if defined __APPLE__ && defined __GNUC__
5068 # ifndef _DONT_USE_CTYPE_INLINE_
5069 #  define _DONT_USE_CTYPE_INLINE_
5070 # endif
5071 # ifndef _FORTIFY_SOURCE
5072 #  define _FORTIFY_SOURCE 0
5073 # endif
5074 #endif
5075 ])
5076
5077 # If user asks to omit features, disable optional features that gnulib
5078 # might otherwise enable.
5079 if test "$with_features" = no && test "$enable_acl" != yes; then
5080   enable_acl=no
5081 fi
5082
5083 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
5084 # it temporarily reverts them to their pre-pkg-config values,
5085 # because gnulib needs to work with both src (which uses the
5086 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
5087 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
5088 # and it therefore needs to run in an environment where LIBS does not
5089 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
5090 # for some package unrelated to lib-src.
5091 SAVE_CFLAGS=$CFLAGS
5092 SAVE_LIBS=$LIBS
5093 CFLAGS=$pre_PKG_CONFIG_CFLAGS
5094 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
5095 gl_ASSERT_NO_GNULIB_POSIXCHECK
5096 gl_ASSERT_NO_GNULIB_TESTS
5097 gl_INIT
5098 CFLAGS=$SAVE_CFLAGS
5099 LIBS=$SAVE_LIBS
5100
5101 if test "${opsys}" = "mingw32"; then
5102   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
5103   # Remove unneeded switches from the value of CC that goes to Makefiles
5104   CC=`AS_ECHO(["$CC"]) | sed -e "s,$GCC_TEST_OPTIONS,,"`
5105 fi
5106
5107 case "$opsys" in
5108   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
5109
5110   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
5111
5112   darwin)
5113    ## The -headerpad option tells ld (see man page) to leave room at the
5114    ## end of the header for adding load commands.  Needed for dumping.
5115    ## 0x1000 is enough for roughly 52 load commands on the x86_64
5116    ## architecture (where they are 78 bytes each). The actual number of
5117    ## load commands added is not consistent but normally ranges from
5118    ## about 14 to about 34. Setting it high gets us plenty of slop and
5119    ## only costs about 1.5K of wasted binary space.
5120    headerpad_extra=1000
5121    if test "$HAVE_NS" = "yes"; then
5122      libs_nsgui="-framework AppKit"
5123      if test "$NS_IMPL_COCOA" = "yes"; then
5124         libs_nsgui="$libs_nsgui -framework IOKit"
5125      fi
5126    else
5127      libs_nsgui=
5128    fi
5129    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
5130
5131    ## This is here because src/Makefile.in did some extra fiddling around
5132    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
5133    ## LD_SWITCH_SYSTEM_TEMACS instead,
5134    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
5135      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
5136    ;;
5137
5138   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
5139   ## find X at run-time.
5140   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
5141   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
5142   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
5143   ## had different values in configure (in ac_link) and src/Makefile.in.
5144   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
5145   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
5146
5147   mingw32)
5148    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
5149    case "$canonical" in
5150      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5151      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5152    esac
5153    ;;
5154
5155   *) LD_SWITCH_SYSTEM_TEMACS= ;;
5156 esac
5157
5158 # -nopie fixes a temacs segfault on Gentoo, OpenBSD, and other systems
5159 # with "hardened" GCC configurations for some reason (Bug#18784).
5160 # We don't know why -nopie works, but not segfaulting is better than
5161 # segfaulting.  Use ac_c_werror_flag=yes when trying -nopie, otherwise
5162 # clang keeps warning that it does not understand -nopie, and pre-4.6
5163 # GCC has a similar problem (Bug#20338).
5164 AC_CACHE_CHECK([whether $CC accepts -nopie],
5165   [emacs_cv_prog_cc_nopie],
5166   [emacs_save_c_werror_flag=$ac_c_werror_flag
5167    emacs_save_LDFLAGS=$LDFLAGS
5168    ac_c_werror_flag=yes
5169    LDFLAGS="$LDFLAGS -nopie"
5170    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
5171      [emacs_cv_prog_cc_nopie=yes],
5172      [emacs_cv_prog_cc_nopie=no])
5173    ac_c_werror_flag=$emacs_save_c_werror_flag
5174    LDFLAGS=$emacs_save_LDFLAGS])
5175 if test "$emacs_cv_prog_cc_nopie" = yes; then
5176   LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -nopie"
5177 fi
5178
5179 if test x$ac_enable_profiling != x ; then
5180   case $opsys in
5181     *freebsd | gnu-linux) ;;
5182     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
5183   esac
5184 fi
5185
5186 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
5187
5188 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
5189
5190 ## Common for all window systems
5191 if test "$window_system" != "none"; then
5192   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
5193   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
5194   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
5195 fi
5196
5197 AC_SUBST(WINDOW_SYSTEM_OBJ)
5198
5199 AH_TOP([/* GNU Emacs site configuration template file.
5200
5201 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2016
5202   Free Software Foundation, Inc.
5203
5204 This file is part of GNU Emacs.
5205
5206 GNU Emacs is free software: you can redistribute it and/or modify
5207 it under the terms of the GNU General Public License as published by
5208 the Free Software Foundation, either version 3 of the License, or
5209 (at your option) any later version.
5210
5211 GNU Emacs is distributed in the hope that it will be useful,
5212 but WITHOUT ANY WARRANTY; without even the implied warranty of
5213 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
5214 GNU General Public License for more details.
5215
5216 You should have received a copy of the GNU General Public License
5217 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
5218
5219
5220 /* No code in Emacs #includes config.h twice, but some bits of code
5221    intended to work with other packages as well (like gmalloc.c)
5222    think they can include it as many times as they like.  */
5223 #ifndef EMACS_CONFIG_H
5224 #define EMACS_CONFIG_H
5225 ])dnl
5226
5227 AH_BOTTOM([#include <conf_post.h>
5228
5229 #endif /* EMACS_CONFIG_H */
5230
5231 /*
5232 Local Variables:
5233 mode: c
5234 End:
5235 */
5236 ])dnl
5237
5238 #### Report on what we decided to do.
5239 #### Report GTK as a toolkit, even if it doesn't use Xt.
5240 #### It makes printing result more understandable as using GTK sets
5241 #### toolkit_scroll_bars to yes by default.
5242 if test "${HAVE_GTK}" = "yes"; then
5243   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5244 fi
5245
5246 if test $USE_ACL -ne 0; then
5247   ACL_SUMMARY="yes $LIB_ACL"
5248 else
5249   ACL_SUMMARY=no
5250 fi
5251
5252 emacs_standard_dirs='Standard dirs'
5253 AS_ECHO(["
5254 Configured for '${canonical}'.
5255
5256   Where should the build process find the source code?    ${srcdir}
5257   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5258   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5259   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5260   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5261   What window system should Emacs use?                    ${window_system}
5262   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}
5263   Where do we find X Windows header files?                ${x_includes:-$emacs_standard_dirs}
5264   Where do we find X Windows libraries?                   ${x_libraries:-$emacs_standard_dirs}"])
5265
5266 optsep=
5267 emacs_config_features=
5268 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG CAIRO IMAGEMAGICK SOUND GPM DBUS \
5269   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5270   LIBOTF XFT ZLIB TOOLKIT_SCROLL_BARS X_TOOLKIT X11 NS MODULES \
5271   XWIDGETS; do
5272
5273     case $opt in
5274       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5275       TOOLKIT_SCROLL_BARS|X_TOOLKIT) eval val=\${USE_$opt} ;;
5276       *) eval val=\${HAVE_$opt} ;;
5277     esac
5278     case x$val in
5279       xno|xnone|x) continue ;;
5280     esac
5281     case $opt in
5282       X_TOOLKIT)
5283         case $val in
5284           GTK*|LUCID|MOTIF) opt=$val ;;
5285           *) continue ;;
5286         esac
5287       ;;
5288     esac
5289     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5290     optsep=' '
5291 done
5292 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5293   [Summary of some of the main features enabled by configure.])
5294
5295 AS_ECHO(["  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}
5296   Does Emacs use -lXpm?                                   ${HAVE_XPM}
5297   Does Emacs use -ljpeg?                                  ${HAVE_JPEG}
5298   Does Emacs use -ltiff?                                  ${HAVE_TIFF}
5299   Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF
5300   Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG
5301   Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}
5302   Does Emacs use cairo?                                   ${HAVE_CAIRO}
5303   Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}
5304   Does Emacs support sound?                               ${HAVE_SOUND}
5305   Does Emacs use -lgpm?                                   ${HAVE_GPM}
5306   Does Emacs use -ldbus?                                  ${HAVE_DBUS}
5307   Does Emacs use -lgconf?                                 ${HAVE_GCONF}
5308   Does Emacs use GSettings?                               ${HAVE_GSETTINGS}
5309   Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}
5310   Does Emacs use access control lists?                    ${ACL_SUMMARY}
5311   Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}
5312   Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}
5313   Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}
5314   Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}
5315   Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}
5316   Does Emacs use -lotf?                                   ${HAVE_LIBOTF}
5317   Does Emacs use -lxft?                                   ${HAVE_XFT}
5318   Does Emacs directly use zlib?                           ${HAVE_ZLIB}
5319   Does Emacs have dynamic modules support?                ${HAVE_MODULES}
5320   Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}
5321   Does Emacs support Xwidgets (requires gtk3)?            ${HAVE_XWIDGETS}
5322 "])
5323
5324 if test -n "${EMACSDATA}"; then
5325    AS_ECHO(["  Environment variable EMACSDATA set to:                  $EMACSDATA"])
5326 fi
5327 if test -n "${EMACSDOC}"; then
5328    AS_ECHO(["  Environment variable EMACSDOC set to:                   $EMACSDOC"])
5329 fi
5330
5331 echo
5332
5333 if test "$HAVE_NS" = "yes"; then
5334    echo
5335    AS_ECHO(["You must run \"${MAKE-make} install\" in order to test the built application.
5336 The installed application will go to nextstep/Emacs.app and can be
5337 run or moved from there."])
5338    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5339       echo "The application will be fully self-contained."
5340     else
5341       AS_ECHO(["The lisp resources for the application will be installed under ${prefix}.
5342 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5343 to run if these resources are not installed."])
5344    fi
5345    echo
5346 fi
5347
5348 if test "${opsys}" = "cygwin"; then
5349   case `uname -r` in
5350     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5351            echo
5352            ;;
5353   esac
5354 fi
5355
5356 # Remove any trailing slashes in these variables.
5357 case $prefix in
5358   */) prefix=`AS_DIRNAME(["$prefix."])`;;
5359 esac
5360 case $exec_prefix in
5361   */) exec_prefix=`AS_DIRNAME(["$exec_prefix."])`;;
5362 esac
5363
5364 if test "$HAVE_NS" = "yes"; then
5365   if test "$NS_IMPL_GNUSTEP" = yes; then
5366     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5367       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5368     ns_check_file=Resources/Info-gnustep.plist
5369   else
5370     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5371       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5372     ns_check_file=Contents/Info.plist
5373   fi
5374   AC_SUBST(ns_check_file)
5375 fi
5376
5377 dnl config.status treats $srcdir specially, so I think this is ok...
5378 AC_CONFIG_FILES([$srcdir/doc/man/emacs.1])
5379
5380 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5381 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5382 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5383 dnl (else you get "no 'Makefile.am' found for any configure output").
5384 dnl This will work, but you get a config.status that is not quite right
5385 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5386 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5387 dnl it seems better to just live with the duplication.
5388 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5389
5390 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5391        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5392        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5393        leim/Makefile nextstep/Makefile nt/Makefile])
5394
5395 dnl test/ is not present in release tarfiles.
5396 opt_makefile=test/Makefile
5397
5398 if test -f "$srcdir/$opt_makefile.in"; then
5399   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5400   dnl Again, it's best not to use a variable.  Though you can add
5401   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5402   AC_CONFIG_FILES([test/Makefile])
5403 fi
5404
5405
5406 dnl The admin/ directory used to be excluded from tarfiles.
5407 if test -d $srcdir/admin; then
5408   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/charsets/Makefile admin/unidata/Makefile admin/grammars/Makefile"
5409   AC_CONFIG_FILES([admin/charsets/Makefile])
5410   AC_CONFIG_FILES([admin/unidata/Makefile])
5411   AC_CONFIG_FILES([admin/grammars/Makefile])
5412 fi                              dnl -d admin
5413
5414
5415 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5416
5417 AC_SUBST(SUBDIR_MAKEFILES_IN)
5418
5419 dnl You might wonder (I did) why epaths.h is generated by running make,
5420 dnl rather than just letting configure generate it from epaths.in.
5421 dnl One reason is that the various paths are not fully expanded (see above);
5422 dnl eg gamedir=${prefix}/var/games/emacs.
5423 dnl Secondly, the GNU Coding standards require that one should be able
5424 dnl to run 'make prefix=/some/where/else' and override the values set
5425 dnl by configure.  This also explains the 'move-if-change' test and
5426 dnl the use of force in the 'epaths-force' rule in Makefile.in.
5427 AC_CONFIG_COMMANDS([src/epaths.h], [
5428 if test "${opsys}" = "mingw32"; then
5429   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5430 else
5431   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5432 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5433 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5434
5435 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5436 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5437 dnl or a symlink?
5438 AC_CONFIG_COMMANDS([src/.gdbinit], [
5439 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5440   AS_ECHO(["source $ac_abs_top_srcdir/src/.gdbinit"]) > src/.gdbinit
5441 fi
5442 ])
5443
5444 dnl Perhaps this would be better named doc-emacs-emacsver.texi?
5445 dnl See comments for etc-refcards-emacsver.tex.
5446 dnl Since we get a doc/emacs directory generated anyway, for the Makefile,
5447 dnl it is not quite the same.  But we are generating in $srcdir.
5448 AC_CONFIG_COMMANDS([doc/emacs/emacsver.texi], [
5449 ${MAKE-make} -s --no-print-directory -C doc/emacs doc-emacsver || \
5450 AC_MSG_ERROR(['doc/emacs/emacsver.texi' could not be made.])
5451 ])
5452
5453 dnl If we give this the more natural name, etc/refcards/emacsver.texi,
5454 dnl then a directory etc/refcards is created in the build directory,
5455 dnl which is probably harmless, but confusing (in out-of-tree builds).
5456 dnl (If we were to generate etc/refcards/Makefile, this might change.)
5457 dnl It is really $srcdir/etc/refcards/emacsver.tex that we generate.
5458 AC_CONFIG_COMMANDS([etc-refcards-emacsver.tex], [
5459 ${MAKE-make} -s MAKEFILE_NAME=do-not-make-Makefile etc-emacsver || \
5460 AC_MSG_ERROR(['etc/refcards/emacsver.tex' could not be made.])
5461 ])
5462
5463 AC_OUTPUT
5464
5465 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])