code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the 'configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2016 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 25.1.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in "$@" CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140
 141 case $host in
 142  *-mingw*)
 143
 144   if test -z "$host_alias"; then
 145
 146       # No --host argument was given to 'configure'; therefore $host
 147       # was set to a default value based on the build platform.  But
 148       # this default value may be wrong if we are building from a
 149       # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
 150       # Therefore, we'll try to get the right host platform from the
 151       # compiler's target.
 152
 153       AC_MSG_CHECKING([the compiler's target])
 154       if test -z "$CC"; then
 155           cc=gcc
 156       else
 157           cc=$CC
 158       fi
 159       cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
 160       case "$cc_target" in
 161           *-*) host=$cc_target
 162               ;;
 163           "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
 164 Please explicitly provide --host.])
 165               ;;
 166           *) AC_MSG_WARN([Compiler reported non-standard target.
 167 Defaulting to $host.])
 168               ;;
 169       esac
 170       AC_MSG_RESULT([$host])
 171   fi
 172
 173   . $srcdir/nt/mingw-cfg.site
 174
 175   case $srcdir in
 176     /* | ?:*)
 177       # srcdir is an absolute path.  In this case, force the format
 178       # "/c/foo/bar", to simplify later conversions to native Windows
 179       # format ("c:/foo/bar").
 180       srcdir=`cd "${srcdir}" && pwd -W`
 181       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
 182       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
 183       ;;
 184   esac;;
 185 esac
 186
 187 canonical=$host
 188 configuration=${host_alias-${build_alias-$host}}
 189
 190 dnl Support for --program-prefix, --program-suffix and
 191 dnl --program-transform-name options
 192 AC_ARG_PROGRAM
 193
 194 dnl It is important that variables on the RHS not be expanded here,
 195 dnl hence the single quotes.  This is per the GNU coding standards, see
 196 dnl (autoconf) Installation Directory Variables
 197 dnl See also epaths.h below.
 198 lispdir='${datadir}/emacs/${version}/lisp'
 199 standardlisppath='${lispdir}'
 200 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 201 '${datadir}/emacs/site-lisp'
 202 lisppath='${locallisppath}:${standardlisppath}'
 203 etcdir='${datadir}/emacs/${version}/etc'
 204 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 205 etcdocdir='${datadir}/emacs/${version}/etc'
 206 gamedir='${localstatedir}/games/emacs'
 207
 208 dnl Special option to disable the most of other options.
 209 AC_ARG_WITH(all,
 210 [AS_HELP_STRING([--without-all],
 211                 [omit almost all features and build
 212                 small executable with minimal dependencies])],
 213   [with_features=$withval],
 214   [with_features=yes])
 215
 216 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 217 dnl Create a new --with option that defaults to being disabled.
 218 dnl NAME is the base name of the option.  The shell variable with_NAME
 219 dnl   will be set to either the user's value (if the option is
 220 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 221 dnl   option is not specified).  Note that the shell variable name is
 222 dnl   constructed as autoconf does, by replacing non-alphanumeric
 223 dnl   characters with "_".
 224 dnl HELP-STRING is the help text for the option.
 225 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 226   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 227     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 228 ])dnl
 229
 230 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 231 dnl Create a new --with option that defaults to $with_features.
 232 dnl NAME is the base name of the option.  The shell variable with_NAME
 233 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 234 dnl   'yes' (if the option is not specified).  Note that the shell
 235 dnl   variable name is constructed as autoconf does, by replacing
 236 dnl   non-alphanumeric characters with "_".
 237 dnl HELP-STRING is the help text for the option.
 238 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 239   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 240    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 241 ])dnl
 242
 243 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 244 if test "$with_pop" = yes; then
 245    AC_DEFINE(MAIL_USE_POP)
 246 fi
 247 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 248
 249 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 250 if test "$with_kerberos" != no; then
 251    AC_DEFINE(KERBEROS)
 252 fi
 253 AH_TEMPLATE(KERBEROS,
 254             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 255
 256 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 257 if test "${with_kerberos5}" != no; then
 258   if test "${with_kerberos}" = no; then
 259     with_kerberos=yes
 260     AC_DEFINE(KERBEROS)
 261   fi
 262   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 263 fi
 264
 265 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 266 dnl FIXME hesiod support may not be present, so it seems like an error
 267 dnl to define, or at least use, this unconditionally.
 268 if test "$with_hesiod" != no; then
 269   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 270 fi
 271
 272 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 273 if test "$with_mail_unlink" != no; then
 274    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 275 fi
 276
 277 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 278     [string giving default POP mail host])],
 279     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 280
 281 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 282   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 283 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
 284   [ case "${withval}" in
 285       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 286       *) AC_MSG_ERROR(['--with-sound=$withval' is invalid;
 287 this option's value should be 'yes', 'no', 'alsa', 'oss', or 'bsd-ossaudio'.])
 288       ;;
 289     esac
 290     with_sound=$val
 291   ],
 292   [with_sound=$with_features])
 293
 294 dnl FIXME currently it is not the last.
 295 dnl This should be the last --with option, because --with-x is
 296 dnl added later on when we find the file name of X, and it's best to
 297 dnl keep them together visually.
 298 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 299  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 300 [         case "${withval}" in
 301             y | ye | yes )      val=gtk ;;
 302             n | no )            val=no  ;;
 303             l | lu | luc | luci | lucid )       val=lucid ;;
 304             a | at | ath | athe | athen | athena )      val=athena ;;
 305             m | mo | mot | moti | motif )       val=motif ;;
 306             g | gt | gtk  )     val=gtk ;;
 307             gtk2  )     val=gtk2 ;;
 308             gtk3  )     val=gtk3 ;;
 309             * )
 310 AC_MSG_ERROR(['--with-x-toolkit=$withval' is invalid;
 311 this option's value should be 'yes', 'no', 'lucid', 'athena', 'motif', 'gtk',
 312 'gtk2' or 'gtk3'.  'yes' and 'gtk' are synonyms.
 313 'athena' and 'lucid' are synonyms.])
 314             ;;
 315           esac
 316           with_x_toolkit=$val
 317 ])
 318
 319 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit); allows buffer and string size up to 2GB on 32-bit hosts, at the cost of 10% to 30% slowdown of Lisp interpreter and larger memory footprint])
 320 if test "$with_wide_int" = yes; then
 321   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 322 fi
 323
 324 dnl _ON results in a '--without' option in the --help output, so
 325 dnl the help text should refer to "don't compile", etc.
 326 with_xpm_set=${with_xpm+set}
 327 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 328 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 329 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 330 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 331 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 332 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 333 OPTION_DEFAULT_ON([libsystemd],[don't compile with libsystemd support])
 334 OPTION_DEFAULT_OFF([cairo],[compile with Cairo drawing (experimental)])
 335 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 336 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 337
 338 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 339 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 340 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 341
 342 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 343 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 344 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 345 AC_ARG_WITH([ns],[AS_HELP_STRING([--with-ns],
 346 [use Nextstep (OS X Cocoa or GNUstep) windowing system.
 347 On by default on Mac OS X.])],[],[with_ns=maybe])
 348 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 349
 350 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 351 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 352 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 353 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 354 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 355 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 356 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 357 OPTION_DEFAULT_OFF([modules],[compile with dynamic modules support])
 358
 359 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 360  [use a file notification library (LIB one of: yes, inotify, kqueue, gfile, w32, no)])],
 361  [ case "${withval}" in
 362     y | ye | yes )      val=yes ;;
 363     n | no )            val=no  ;;
 364     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 365     k | kq | kqu | kque | kqueu | kqueue )      val=kqueue ;;
 366     g | gf | gfi | gfil | gfile )       val=gfile ;;
 367     w | w3 | w32 )      val=w32 ;;
 368     * ) AC_MSG_ERROR(['--with-file-notification=$withval' is invalid;
 369 this option's value should be 'yes', 'no', 'inotify', 'kqueue', 'gfile' or 'w32'.
 370 'yes' is a synonym for 'w32' on MS-Windows, for 'no' on Nextstep,
 371 otherwise for the first of 'inotify', 'kqueue' or 'gfile' that is usable.])
 372     ;;
 373    esac
 374    with_file_notification=$val
 375  ],
 376  [with_file_notification=$with_features])
 377
 378 OPTION_DEFAULT_OFF([xwidgets],
 379   [enable use of some gtk widgets in Emacs buffers (requires gtk3)])
 380
 381 ## For the times when you want to build Emacs but don't have
 382 ## a suitable makeinfo, and can live without the manuals.
 383 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 384 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 385
 386 ## This might be a 'configure' arg.
 387 AC_SUBST([ACLOCAL_PATH])
 388
 389 ## Makefile.in needs the cache file name.
 390 AC_SUBST(cache_file)
 391
 392 ## This is an option because I do not know if all info/man support
 393 ## compressed files, nor how to test if they do so.
 394 OPTION_DEFAULT_ON([compress-install],
 395   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 396 make GZIP_PROG= install])
 397
 398 AC_ARG_WITH(gameuser,dnl
 399 [AS_HELP_STRING([--with-gameuser=USER_OR_GROUP],
 400                 [user for shared game score files.
 401                 An argument prefixed by ':' specifies a group instead.])])
 402 gameuser=
 403 gamegroup=
 404 # We don't test if we can actually chown/chgrp here, because configure
 405 # may run without root privileges.  lib-src/Makefile.in will handle
 406 # any errors due to missing user/group gracefully.
 407 case ${with_gameuser} in
 408   no) ;;
 409   "" | yes) gamegroup=games ;;
 410   :*) gamegroup=${with_gameuser#:} ;;
 411   *) gameuser=${with_gameuser} ;;
 412 esac
 413
 414 AC_ARG_WITH([gnustep-conf],dnl
 415 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 416    [name of GNUstep configuration file to use on systems where the command
 417     'gnustep-config' does not work; default $GNUSTEP_CONFIG_FILE, or
 418     /etc/GNUstep/GNUstep.conf])])
 419 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 420   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 421 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 422      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 423
 424 AC_ARG_ENABLE(ns-self-contained,
 425 [AS_HELP_STRING([--disable-ns-self-contained],
 426                 [disable self contained build under NeXTstep])],
 427    EN_NS_SELF_CONTAINED=$enableval,
 428    EN_NS_SELF_CONTAINED=yes)
 429
 430 locallisppathset=no
 431 AC_ARG_ENABLE(locallisppath,
 432 [AS_HELP_STRING([--enable-locallisppath=PATH],
 433                 [directories Emacs should search for lisp files specific
 434                  to this site])],
 435 if test "${enableval}" = "no"; then
 436   locallisppath=
 437 elif test "${enableval}" != "yes"; then
 438   locallisppath=${enableval} locallisppathset=yes
 439 fi)
 440
 441 AC_ARG_ENABLE(checking,
 442 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 443                 [enable expensive run-time checks.  With LIST,
 444                  enable only specific categories of checks.
 445                  Categories are: all,yes,no.
 446                  Flags are: stringbytes, stringoverrun, stringfreelist,
 447                  xmallocoverrun, conslist, glyphs])],
 448 [ac_checking_flags="${enableval}"],[])
 449 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 450 for check in $ac_checking_flags
 451 do
 452         case $check in
 453         # these set all the flags to specific states
 454         yes)            ac_enable_checking=1 ;;
 455         no)             ac_enable_checking= ;
 456                         ac_gc_check_stringbytes= ;
 457                         ac_gc_check_string_overrun= ;
 458                         ac_gc_check_string_free_list= ;
 459                         ac_xmalloc_overrun= ;
 460                         ac_gc_check_cons_list= ;
 461                         ac_glyphs_debug= ;;
 462         all)            ac_enable_checking=1 ;
 463                         ac_gc_check_stringbytes=1 ;
 464                         ac_gc_check_string_overrun=1 ;
 465                         ac_gc_check_string_free_list=1 ;
 466                         ac_xmalloc_overrun=1 ;
 467                         ac_gc_check_cons_list=1 ;
 468                         ac_glyphs_debug=1 ;;
 469         # these enable particular checks
 470         stringbytes)    ac_gc_check_stringbytes=1 ;;
 471         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 472         stringfreelist) ac_gc_check_string_free_list=1 ;;
 473         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 474         conslist)       ac_gc_check_cons_list=1 ;;
 475         glyphs)         ac_glyphs_debug=1 ;;
 476         *)      AC_MSG_ERROR(unknown check category $check) ;;
 477         esac
 478 done
 479 IFS="$ac_save_IFS"
 480
 481 if test x$ac_enable_checking != x ; then
 482   AC_DEFINE(ENABLE_CHECKING, 1,
 483 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 484 fi
 485 if test x$ac_gc_check_stringbytes != x ; then
 486   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 487 [Define this temporarily to hunt a bug.  If defined, the size of
 488    strings is redundantly recorded in sdata structures so that it can
 489    be compared to the sizes recorded in Lisp strings.])
 490 fi
 491 if test x$ac_gc_check_string_overrun != x ; then
 492   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 493 [Define this to check for short string overrun.])
 494 fi
 495 if test x$ac_gc_check_string_free_list != x ; then
 496   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 497 [Define this to check the string free list.])
 498 fi
 499 if test x$ac_xmalloc_overrun != x ; then
 500   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 501 [Define this to check for malloc buffer overrun.])
 502 fi
 503 if test x$ac_gc_check_cons_list != x ; then
 504   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 505 [Define this to check for errors in cons list.])
 506 fi
 507 if test x$ac_glyphs_debug != x ; then
 508   AC_DEFINE(GLYPH_DEBUG, 1,
 509 [Define this to enable glyphs debugging code.])
 510 fi
 511
 512 AC_ARG_ENABLE(check-lisp-object-type,
 513 [AS_HELP_STRING([--enable-check-lisp-object-type],
 514                 [enable compile time checks for the Lisp_Object data type.
 515                 This is useful for development for catching certain types of bugs.])],
 516 if test "${enableval}" != "no"; then
 517    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 518    [Define this to enable compile time checks for the Lisp_Object data type.])
 519 fi)
 520
 521
 522 dnl The name of this option is unfortunate.  It predates, and has no
 523 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 524 dnl Actually, it stops it working.
 525 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 526 AC_ARG_ENABLE(profiling,
 527 [AS_HELP_STRING([--enable-profiling],
 528                 [build emacs with low-level, gprof profiling support.
 529                 Mainly useful for debugging Emacs itself.  May not work on
 530                 all platforms.  Stops profiler.el working.])],
 531 [ac_enable_profiling="${enableval}"],[])
 532 if test x$ac_enable_profiling != x ; then
 533    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 534 else
 535    PROFILING_CFLAGS=
 536 fi
 537 AC_SUBST(PROFILING_CFLAGS)
 538
 539 AC_ARG_ENABLE(autodepend,
 540 [AS_HELP_STRING([--enable-autodepend],
 541                 [automatically generate dependencies to .h-files.
 542                  Requires gcc, enabled if found.])],
 543 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 544
 545 AC_ARG_ENABLE(gtk-deprecation-warnings,
 546 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 547                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 548 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 549
 550 BUILD_DETAILS=
 551 AC_ARG_ENABLE([build-details],
 552   [AS_HELP_STRING([--disable-build-details],
 553                   [Make the build more deterministic by omitting host
 554                    names, time stamps, etc. from the output.])],
 555   [test "$enableval" = no && BUILD_DETAILS=--no-build-details])
 556 AC_SUBST([BUILD_DETAILS])
 557
 558 dnl This used to use changequote, but, apart from 'changequote is evil'
 559 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 560 dnl the great gob of text.  Thus it's not processed for possible expansion.
 561 dnl Just make sure the brackets remain balanced.
 562 dnl
 563 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 564 dnl indicated by comments.
 565 dnl quotation begins
 566 [
 567
 568 ### If you add support for a new configuration, add code to this
 569 ### switch statement to recognize your configuration name and select
 570 ### the appropriate opsys.
 571
 572 ### As far as handling version numbers on operating systems is
 573 ### concerned, make sure things will fail in a fixable way.  If
 574 ### /etc/MACHINES doesn't say anything about version numbers, be
 575 ### prepared to handle anything reasonably.  If version numbers
 576 ### matter, be sure /etc/MACHINES says something about it.
 577
 578 opsys='' unported=no
 579 case "${canonical}" in
 580
 581   ## GNU/Linux and similar ports
 582   *-*-linux* )
 583     opsys=gnu-linux
 584   ;;
 585
 586   ## FreeBSD ports
 587   *-*-freebsd* )
 588     opsys=freebsd
 589   ;;
 590
 591   ## DragonFly ports
 592   *-*-dragonfly* )
 593     opsys=dragonfly
 594   ;;
 595
 596   ## FreeBSD kernel + glibc based userland
 597   *-*-kfreebsd*gnu* )
 598     opsys=gnu-kfreebsd
 599   ;;
 600
 601   ## NetBSD ports
 602   *-*-netbsd* )
 603     opsys=netbsd
 604   ;;
 605
 606   ## OpenBSD ports
 607   *-*-openbsd* | *-*-mirbsd* )
 608     opsys=openbsd
 609   ;;
 610
 611   ## Apple Darwin / Mac OS X
 612   *-apple-darwin* )
 613     case "${canonical}" in
 614       *-apple-darwin[0-9].*) unported=yes ;;
 615       i[3456]86-* | x86_64-* )  ;;
 616       * )            unported=yes ;;
 617     esac
 618     opsys=darwin
 619     ## FIXME: Find a way to use Fink if available (Bug#11507).
 620   ;;
 621
 622   ## Chromium Native Client
 623   *-nacl )
 624     opsys=nacl
 625   ;;
 626
 627   ## Cygwin ports
 628   *-*-cygwin )
 629     opsys=cygwin
 630   ;;
 631
 632   ## HP 9000 series 700 and 800, running HP/UX
 633   hppa*-hp-hpux10.2* )
 634     opsys=hpux10-20
 635   ;;
 636   hppa*-hp-hpux1[1-9]* )
 637     opsys=hpux11
 638     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 639   ;;
 640
 641   ## IBM machines
 642   rs6000-ibm-aix4.[23]* )
 643     opsys=aix4-2
 644   ;;
 645   powerpc-ibm-aix4.[23]*  )
 646     opsys=aix4-2
 647   ;;
 648   rs6000-ibm-aix[56]* )
 649     opsys=aix4-2
 650   ;;
 651   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 652     opsys=aix4-2
 653   ;;
 654
 655   ## Suns
 656   *-sun-solaris* \
 657     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 658     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 659     case "${canonical}" in
 660       i[3456]86-*-* )   ;;
 661       amd64-*-*|x86_64-*-*) ;;
 662       sparc* )          ;;
 663       * )               unported=yes ;;
 664     esac
 665     case "${canonical}" in
 666       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 667                 opsys=sol2-10
 668                 emacs_check_sunpro_c=yes
 669                 ;;
 670       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 671       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 672       *-sunos5.6* | *-solaris2.6* )
 673                 opsys=sol2-6
 674                 RANLIB="ar -ts"
 675                 ;;
 676       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 677       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 678                 opsys=sol2-6
 679                 emacs_check_sunpro_c=yes
 680                 ;;
 681     esac
 682     ## Watch out for a compiler that we know will not work.
 683     case "${canonical}" in
 684      *-solaris* | *-sunos5* )
 685                 if [ "x$CC" = x/usr/ucb/cc ]; then
 686                   ## /usr/ucb/cc doesn't work;
 687                   ## we should find some other compiler that does work.
 688                   unset CC
 689                 fi
 690                 ;;
 691       *) ;;
 692     esac
 693   ;;
 694
 695   ## Intel 386 machines where we don't care about the manufacturer.
 696   i[3456]86-*-* )
 697     case "${canonical}" in
 698       *-darwin* )               opsys=darwin ;;
 699       *-mingw* )
 700                 opsys=mingw32
 701                 # MinGW overrides and adds some system headers in nt/inc.
 702                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 703                 ;;
 704       *-sysv4.2uw* )            opsys=unixware ;;
 705       *-sysv5uw* )              opsys=unixware ;;
 706       *-sysv5OpenUNIX* )        opsys=unixware ;;
 707       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 708     esac
 709   ;;
 710
 711   # MinGW64
 712   x86_64-*-* )
 713     case "${canonical}" in
 714       *-mingw* )
 715                 opsys=mingw32
 716                 # MinGW overrides and adds some system headers in nt/inc.
 717                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 718                 ;;
 719       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 720     esac
 721   ;;
 722
 723   * )
 724     unported=yes
 725   ;;
 726 esac
 727
 728 ### If the code above didn't choose an operating system, just choose
 729 ### an operating system based on the configuration name.  You really
 730 ### only want to use this when you have no idea what the right
 731 ### operating system is; if you know what operating systems a machine
 732 ### runs, it's cleaner to make it explicit in the case statement
 733 ### above.
 734 if test x"${opsys}" = x; then
 735   case "${canonical}" in
 736     *-gnu* )                            opsys=gnu ;;
 737     * )
 738       unported=yes
 739     ;;
 740   esac
 741 fi
 742
 743 ]
 744 dnl quotation ends
 745
 746 if test $unported = yes; then
 747   AC_MSG_ERROR([Emacs does not support '${canonical}' systems.
 748 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 749 Check 'etc/MACHINES' for recognized configuration names.])
 750 fi
 751
 752 #### Choose a compiler.
 753
 754 dnl Don't bother to test for C89.
 755 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 756
 757 dnl Sets GCC=yes if using gcc.
 758 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 759 if test -n "$XCRUN"; then
 760   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 761   test -n "$AR" && export AR
 762 fi
 763
 764 dnl Emacs needs C99 or later.
 765 gl_PROG_CC_C99
 766
 767 AM_PROG_CC_C_O
 768
 769 if test x$GCC = xyes; then
 770   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 771 fi
 772
 773 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 774 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 775 dnl that clash with MinGW.
 776 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 777
 778 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 779 AC_DEFUN([gl_CRYPTO_CHECK])
 780 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 781 # as we don't use them.
 782 AC_DEFUN([gl_FCNTL_O_FLAGS])
 783 # Avoid gnulib's test for pthread_sigmask.
 784 funcs=
 785 for func in $ac_func_list; do
 786   test $func = pthread_sigmask || AS_VAR_APPEND([funcs], [" $func"])
 787 done
 788 ac_func_list=$funcs
 789 # Use the system putenv even if it lacks GNU features, as we don't need them,
 790 # and the gnulib replacement runs afoul of a FreeBSD 10.1 bug; see Bug#19874.
 791 AC_CHECK_FUNCS_ONCE([putenv])
 792 AC_DEFUN([gl_FUNC_PUTENV],
 793   [test "$ac_cv_func_putenv" = yes || REPLACE_PUTENV=1])
 794
 795 # Initialize gnulib right after choosing the compiler.
 796 dnl Amongst other things, this sets AR and ARFLAGS.
 797 gl_EARLY
 798
 799 if test "$ac_test_CFLAGS" != set; then
 800   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 801   # if -g3 works and the user does not specify CFLAGS.
 802   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 803   case $CFLAGS in
 804     '-g')
 805       emacs_g3_CFLAGS='-g3';;
 806     '-g -O2')
 807       emacs_g3_CFLAGS='-g3 -O2';;
 808     *)
 809       emacs_g3_CFLAGS='';;
 810   esac
 811   if test -n "$emacs_g3_CFLAGS"; then
 812     emacs_save_CFLAGS=$CFLAGS
 813     CFLAGS=$emacs_g3_CFLAGS
 814     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 815       [emacs_cv_prog_cc_g3],
 816       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 817          [emacs_cv_prog_cc_g3=yes],
 818          [emacs_cv_prog_cc_g3=no])])
 819     if test $emacs_cv_prog_cc_g3 != yes; then
 820       CFLAGS=$emacs_save_CFLAGS
 821     fi
 822     if test $opsys = mingw32; then
 823       CFLAGS="$CFLAGS -gdwarf-2"
 824     fi
 825   fi
 826
 827   case $CFLAGS in
 828     *-O*) ;;
 829     *)
 830       # No optimization flag was inferred for this non-GCC compiler.
 831       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 832       emacs_save_CFLAGS=$CFLAGS
 833       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 834       CFLAGS=${CFLAGS}-O
 835       AC_CACHE_CHECK([whether $CC accepts -O],
 836         [emacs_cv_prog_cc_o],
 837         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 838            [emacs_cv_prog_cc_o=yes],
 839            [emacs_cv_prog_cc_o=no])])
 840       if test $emacs_cv_prog_cc_o != yes; then
 841         CFLAGS=$emacs_save_CFLAGS
 842       fi ;;
 843   esac
 844 fi
 845
 846 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 847 # ---------------------------------------------------------------------------
 848 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 849 # Otherwise, run RUN-IF-NOT-FOUND.
 850 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 851   [AC_PREPROC_IFELSE(
 852     [AC_LANG_PROGRAM(
 853       [[
 854 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 855 /* ok */
 856 #else
 857 # error "your version of gcc is older than $1.$2"
 858 #endif
 859       ]]),
 860     ], [$3], [$4])
 861   ]
 862 )
 863
 864 AC_ARG_ENABLE([gcc-warnings],
 865   [AS_HELP_STRING([--enable-gcc-warnings@<:@=TYPE@:>@],
 866                   [control generation of GCC warnings.  The TYPE 'yes'
 867                    means to fail if any warnings are issued; 'warn-only'
 868                    means issue warnings without failing (default for
 869                    developer builds); 'no' means disable warnings
 870                    (default for non-developer builds).])],
 871   [case $enableval in
 872      yes|no|warn-only) ;;
 873      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 874    esac
 875    gl_gcc_warnings=$enableval],
 876   [# By default, use 'warn-only' if it looks like the invoker of 'configure'
 877    # is a developer as opposed to a builder.  This is most likely true
 878    # if GCC is recent enough and there is a .git directory or file;
 879    # however, if there is also a .tarball-version file it is probably
 880    # just a release imported into Git for patch management.
 881    gl_gcc_warnings=no
 882    if test -e "$srcdir"/.git && test ! -f "$srcdir"/.tarball-version; then
 883      gl_GCC_VERSION_IFELSE([5], [3], [gl_gcc_warnings=warn-only])]
 884    fi
 885 )
 886
 887 # clang is unduly picky about some things.
 888 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 889   [AC_COMPILE_IFELSE(
 890      [AC_LANG_PROGRAM([[
 891           #ifndef __clang__
 892             error "not clang";
 893           #endif
 894         ]])],
 895      [emacs_cv_clang=yes],
 896      [emacs_cv_clang=no])])
 897
 898 # When compiling with GCC, prefer -isystem to -I when including system
 899 # include files, to avoid generating useless diagnostics for the files.
 900 AS_IF([test $gl_gcc_warnings = no],
 901  [
 902   isystem='-I'
 903   AS_IF([test "$emacs_cv_clang" = yes],
 904    [
 905      # Turn off some warnings if supported.
 906      gl_WARN_ADD([-Wno-switch])
 907      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 908      gl_WARN_ADD([-Wno-pointer-sign])
 909      gl_WARN_ADD([-Wno-string-plus-int])
 910      gl_WARN_ADD([-Wno-unknown-attributes])
 911    ])
 912  ],[
 913   isystem='-isystem '
 914
 915   # This, $nw, is the list of warnings we disable.
 916   nw=
 917
 918   case $with_x_toolkit in
 919     lucid | athena | motif)
 920        # Old toolkits mishandle 'const'.
 921        nw="$nw -Wwrite-strings"
 922        ;;
 923   esac
 924   AS_IF([test $gl_gcc_warnings = yes],
 925     [gl_WARN_ADD([-Werror], [WERROR_CFLAGS])])
 926   AC_SUBST([WERROR_CFLAGS])
 927
 928   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 929   nw="$nw -Woverlength-strings"     # Not a problem these days
 930   nw="$nw -Wformat-nonliteral"      # we do this a lot
 931   nw="$nw -Wvla"                    # Emacs uses <vla.h>.
 932   nw="$nw -Wswitch-default"         # Too many warnings for now
 933   nw="$nw -Wunused-const-variable=2" # lisp.h declares const objects.
 934   nw="$nw -Winline"                 # OK to ignore 'inline'
 935   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 936                                     # signed overflow has undefined behavior
 937   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 938   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 939   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 940
 941   # Emacs doesn't care about shadowing; see
 942   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 943   nw="$nw -Wshadow"
 944
 945   # Emacs's use of alloca inhibits protecting the stack.
 946   nw="$nw -Wstack-protector"
 947
 948   # Emacs's use of partly-const functions such as Fgnutls_available_p
 949   # make this option problematic.
 950   nw="$nw -Wsuggest-attribute=const"
 951
 952   # Emacs's use of partly-pure functions such as CHECK_TYPE make this
 953   # option problematic.
 954   nw="$nw -Wsuggest-attribute=pure"
 955
 956   # This part is merely for shortening the command line,
 957   # since -Wall implies -Wswitch.
 958   nw="$nw -Wswitch"
 959
 960   # This part is merely for shortening the command line,
 961   # since -Wno-FOO needs to be added below regardless.
 962   nw="$nw -Wmissing-field-initializers"
 963   nw="$nw -Wtype-limits"
 964   nw="$nw -Wunused-parameter"
 965
 966   if test $emacs_cv_clang = yes; then
 967     nw="$nw -Wcast-align"
 968   fi
 969
 970   # This causes too much noise in the MinGW build
 971   if test $opsys = mingw32; then
 972     nw="$nw -Wpointer-sign"
 973   fi
 974
 975   gl_MANYWARN_ALL_GCC([ws])
 976   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 977   for w in $ws; do
 978     gl_WARN_ADD([$w])
 979   done
 980   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 981   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 982   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 983   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 984   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 985   gl_WARN_ADD([-Wno-format-nonliteral])
 986
 987   # More things that clang is unduly picky about.
 988   if test $emacs_cv_clang = yes; then
 989     gl_WARN_ADD([-Wno-format-extra-args])
 990     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 991     gl_WARN_ADD([-Wno-unused-command-line-argument])
 992     gl_WARN_ADD([-Wno-unused-value])
 993   fi
 994
 995   # This causes too much noise in the MinGW build
 996   if test $opsys = mingw32; then
 997     gl_WARN_ADD([-Wno-pointer-sign])
 998   fi
 999
1000   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
1001   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
1002   AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
1003   [/* Enable compile-time and run-time bounds-checking, and some warnings,
1004       without upsetting glibc 2.15+. */
1005    #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
1006         && defined __OPTIMIZE__ && __OPTIMIZE__)
1007    # define _FORTIFY_SOURCE 2
1008    #endif
1009   ])
1010
1011   # We use a slightly smaller set of warning options for lib/.
1012   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
1013   nw=
1014   nw="$nw -Wunused-macros"
1015
1016   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
1017   AC_SUBST([GNULIB_WARN_CFLAGS])
1018  ])
1019
1020 edit_cflags="
1021   s,///*,/,g
1022   s/^/ /
1023   s/ -I/ $isystem/g
1024   s/^ //
1025 "
1026
1027 AC_ARG_ENABLE(link-time-optimization,
1028 [AS_HELP_STRING([--enable-link-time-optimization],
1029                 [build emacs with link-time optimization.
1030                  This requires GCC 4.5.0 or later, or clang.
1031                  (Note that clang support is experimental - see INSTALL.)
1032                  It also makes Emacs harder to debug, and when we tried it
1033                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
1034                  recommended for typical use.])],
1035 if test "${enableval}" != "no"; then
1036    ac_lto_supported=no
1037    if test $emacs_cv_clang = yes; then
1038       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
1039       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
1040       if test -x "$GOLD_PLUGIN"; then
1041          LTO="-flto"
1042       fi
1043    elif test x$GCC = xyes; then
1044       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
1045       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
1046       if test x$CPUS != x; then
1047          LTO="-flto=$CPUS"
1048       else
1049          LTO="-flto"
1050       fi
1051    else
1052       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
1053    fi
1054    if test -z "$LTO"; then
1055       ac_lto_supported=no
1056    else
1057       old_CFLAGS=$CFLAGS
1058       CFLAGS="$CFLAGS $LTO"
1059       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1060          [ac_lto_supported=yes], [ac_lto_supported=no])
1061          CFLAGS="$old_CFLAGS"
1062    fi
1063    AC_MSG_RESULT([$ac_lto_supported])
1064    if test "$ac_lto_supported" = "yes"; then
1065       CFLAGS="$CFLAGS $LTO"
1066       if test x$emacs_cv_clang = xyes; then
1067          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
1068          # WARNING: 'ar --plugin ...' doesn't work without
1069          # command, so plugin name is appended to ARFLAGS.
1070          ARFLAGS="cru --plugin $GOLD_PLUGIN"
1071          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
1072       else
1073         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
1074         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
1075         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
1076         dnl dump core on Fedora 20, so play it safe for now.
1077         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
1078           [CFLAGS="$CFLAGS -ffat-lto-objects"])
1079       fi
1080    fi
1081 fi)
1082
1083 dnl Prefer silent make output.  For verbose output, use
1084 dnl 'configure --disable-silent-rules' or 'make V=1' .
1085 AM_SILENT_RULES([yes])
1086 dnl Port to Automake 1.11.
1087 dnl This section can be removed once we assume Automake 1.14 or later.
1088 : ${AM_V=$AM_DEFAULT_VERBOSITY}
1089 : ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
1090 AC_SUBST([AM_V])
1091 AM_SUBST_NOTMAKE([AM_V])
1092 AC_SUBST([AM_DEFAULT_V])
1093 AM_SUBST_NOTMAKE([AM_DEFAULT_V])
1094 AC_SUBST([AM_DEFAULT_VERBOSITY])
1095
1096 dnl Some other nice autoconf tests.
1097 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
1098 dnl AC_PROG_INSTALL
1099 dnl AC_PROG_MKDIR_P
1100 dnl if test "x$RANLIB" = x; then
1101 dnl   AC_PROG_RANLIB
1102 dnl fi
1103
1104
1105 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
1106 dnl can be made to directories.  This is not relevant for our usage, and
1107 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1108 dnl hosted on AFS, both examples where simple links work, but links to
1109 dnl directories fail.  We use a cut-down version instead.
1110 dnl AC_PROG_LN_S
1111
1112 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1113 rm -f conf$$ conf$$.file
1114
1115 LN_S_FILEONLY='cp -p'
1116
1117 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1118 dnl random program in the current directory.
1119 if (echo >conf$$.file) 2>/dev/null; then
1120   if ln -s conf$$.file conf$$ 2>/dev/null; then
1121     if test "$opsys" = "mingw32"; then
1122       LN_S_FILEONLY='/bin/ln -s'
1123     else
1124       LN_S_FILEONLY='ln -s'
1125     fi
1126   elif ln conf$$.file conf$$ 2>/dev/null; then
1127     if test "$opsys" = "mingw32"; then
1128       LN_S_FILEONLY=/bin/ln
1129     else
1130       LN_S_FILEONLY=ln
1131     fi
1132   fi
1133 fi
1134
1135 rm -f conf$$ conf$$.file
1136
1137 if test "$LN_S_FILEONLY" = "ln -s"; then
1138    AC_MSG_RESULT([yes])
1139 else
1140    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1141 fi
1142
1143 AC_SUBST(LN_S_FILEONLY)
1144
1145
1146 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1147 dnl doesn't support links to directories, as in "ln file dir".  But that
1148 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1149 dnl executables at "make install" time.
1150 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1151 dnl for more details.
1152 if test "$opsys" = "mingw32"; then
1153   LN_S="/bin/ln"
1154 fi
1155
1156 dnl On some Debian versions, "install-info" prints irritating messages
1157 dnl "This is not dpkg install-info anymore, but GNU install-info"
1158 dnl if called via an absolute file name.
1159 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1160 dnl Sadly some people may have an old ginstall-info installed on
1161 dnl non-Debian systems, so we can't use this.
1162 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1163 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1164
1165 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1166   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1167 dnl Don't use GZIP, which is used by gzip for additional parameters.
1168 AC_PATH_PROG(GZIP_PROG, gzip)
1169
1170 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1171    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1172
1173 PAXCTL_dumped=
1174 PAXCTL_notdumped=
1175 if test $opsys = gnu-linux; then
1176   if test "${SETFATTR+set}" != set; then
1177     AC_CACHE_CHECK([for setfattr],
1178       [emacs_cv_prog_setfattr],
1179       [touch conftest.tmp
1180        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1181          emacs_cv_prog_setfattr=yes
1182        else
1183          emacs_cv_prog_setfattr=no
1184        fi])
1185     if test "$emacs_cv_prog_setfattr" = yes; then
1186       PAXCTL_notdumped='$(SETFATTR) -n user.pax.flags -v er'
1187       SETFATTR=setfattr
1188     else
1189       SETFATTR=
1190     fi
1191     rm -f conftest.tmp
1192     AC_SUBST([SETFATTR])
1193   fi
1194 fi
1195 case $opsys,$PAXCTL_notdumped in
1196   gnu-linux, | netbsd,)
1197     AC_PATH_PROG([PAXCTL], [paxctl], [],
1198       [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1199     if test -n "$PAXCTL"; then
1200       if test "$opsys" = netbsd; then
1201         PAXCTL_dumped='$(PAXCTL) +a'
1202         PAXCTL_notdumped=$PAXCTL_dumped
1203       else
1204         AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1205         AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1206           [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then
1207              AC_MSG_RESULT([yes])
1208            else
1209              AC_MSG_RESULT([no])
1210              PAXCTL=
1211            fi])
1212         if test -n "$PAXCTL"; then
1213           PAXCTL_dumped='$(PAXCTL) -zex'
1214           PAXCTL_notdumped='$(PAXCTL) -r'
1215         fi
1216       fi
1217     fi;;
1218 esac
1219 AC_SUBST([PAXCTL_dumped])
1220 AC_SUBST([PAXCTL_notdumped])
1221
1222 ## Need makeinfo >= 4.7 (?) to build the manuals.
1223 if test "$MAKEINFO" != "no"; then
1224   if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
1225     MAKEINFO=makeinfo
1226   fi
1227   case `($MAKEINFO --version) 2>/dev/null` in
1228     *' (GNU texinfo) '4.[[7-9]]* | \
1229     *' (GNU texinfo) '4.[[1-9][0-9]]* | \
1230     *' (GNU texinfo) '[[5-9]]* | \
1231     *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1232     *) MAKEINFO=no;;
1233   esac
1234 fi
1235
1236 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1237 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1238 ## therefore in the category of "special tools" not normally required, which
1239 ## configure does not have to check for (eg autoconf itself).
1240 ## In a repository checkout on the other hand, the manuals are not included.
1241 ## So makeinfo is a requirement to build from the repository, and configure
1242 ## should test for it as it does for any other build requirement.
1243 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1244 ## with pre-built manuals, from a repository checkout.
1245 HAVE_MAKEINFO=yes
1246
1247 if test "$MAKEINFO" = "no"; then
1248   MAKEINFO=makeinfo
1249   if test "x${with_makeinfo}" = "xno"; then
1250     HAVE_MAKEINFO=no
1251   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1252     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1253 source tree does not seem to have pre-built manuals in the 'info' directory.
1254 Either install a suitable version of makeinfo, or re-run configure
1255 with the '--without-makeinfo' option to build without the manuals.] )
1256   fi
1257 fi
1258 AC_SUBST(HAVE_MAKEINFO)
1259
1260 if test $opsys = mingw32; then
1261    DOCMISC_W32=efaq-w32
1262 else
1263    DOCMISC_W32=
1264 fi
1265 AC_SUBST(DOCMISC_W32)
1266
1267 dnl Add our options to ac_link now, after it is set up.
1268
1269 if test x$GCC = xyes; then
1270   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1271     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1272 else
1273   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1274     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1275 fi
1276
1277 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1278 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1279 dnl Treat GCC specially since it just gives a non-fatal 'unrecognized option'
1280 dnl if not built to support GNU ld.
1281
1282 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1283 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1284 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1285 dnl   Eg "make LDFLAGS=... all" could run into problems,
1286 dnl   http://bugs.debian.org/684788
1287 dnl * unnecessary, since temacs is the only thing that actually needs it.
1288 dnl   Indeed this is where it was originally, prior to:
1289 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1290 late_LDFLAGS="$LDFLAGS"
1291 if test x$GCC = xyes; then
1292   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1293 else
1294   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1295 fi
1296
1297 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1298
1299 AC_MSG_CHECKING([for -znocombreloc])
1300 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1301   [AC_MSG_RESULT(yes)],
1302   LDFLAGS_NOCOMBRELOC=
1303   [AC_MSG_RESULT(no)])
1304
1305 LDFLAGS="$late_LDFLAGS"
1306
1307 AC_CACHE_CHECK([whether addresses are sanitized],
1308   [emacs_cv_sanitize_address],
1309   [AC_COMPILE_IFELSE(
1310      [AC_LANG_PROGRAM(
1311         [[#ifndef __has_feature
1312           #define __has_feature(f) 0
1313           #endif
1314           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1315           #else
1316            error "Addresses are not sanitized.";
1317           #endif
1318         ]])],
1319      [emacs_cv_sanitize_address=yes],
1320      [emacs_cv_sanitize_address=no])])
1321
1322 dnl The function dump-emacs will not be defined and temacs will do
1323 dnl (load "loadup") automatically unless told otherwise.
1324 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1325 case "$opsys" in
1326   nacl) CANNOT_DUMP=yes ;;
1327 esac
1328
1329 if test "$CANNOT_DUMP" = "yes"; then
1330   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1331 elif test "$emacs_cv_sanitize_address" = yes; then
1332   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1333 fi
1334
1335 AC_SUBST(CANNOT_DUMP)
1336
1337
1338 UNEXEC_OBJ=unexelf.o
1339 case "$opsys" in
1340   # MSDOS uses unexcoff.o
1341   aix4-2)
1342    UNEXEC_OBJ=unexaix.o
1343    ;;
1344   cygwin)
1345    UNEXEC_OBJ=unexcw.o
1346    ;;
1347   darwin)
1348    UNEXEC_OBJ=unexmacosx.o
1349    ;;
1350   hpux10-20 | hpux11)
1351    UNEXEC_OBJ=unexhp9k800.o
1352    ;;
1353   mingw32)
1354    UNEXEC_OBJ=unexw32.o
1355    ;;
1356   sol2-10)
1357    # Use the Solaris dldump() function, called from unexsol.c, to dump
1358    # emacs, instead of the generic ELF dump code found in unexelf.c.
1359    # The resulting binary has a complete symbol table, and is better
1360    # for debugging and other observability tools (debuggers, pstack, etc).
1361    #
1362    # If you encounter a problem using dldump(), please consider sending
1363    # a message to the OpenSolaris tools-linking mailing list:
1364    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1365    #
1366    # It is likely that dldump() works with older Solaris too, but this has
1367    # not been tested, so for now this change is for Solaris 10 or newer.
1368    UNEXEC_OBJ=unexsol.o
1369    ;;
1370 esac
1371
1372 LD_SWITCH_SYSTEM=
1373 case "$opsys" in
1374   freebsd|dragonfly)
1375    ## Let 'ld' find image libs and similar things in /usr/local/lib.
1376    ## The system compiler, GCC, has apparently been modified to not
1377    ## look there, contrary to what a stock GCC would do.
1378 ### It's not our place to do this.  See bug#10313#17.
1379 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1380       :
1381    ;;
1382
1383   gnu-linux)
1384    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1385    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1386    ;;
1387
1388   netbsd)
1389 ### It's not our place to do this.  See bug#10313#17.
1390 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1391       :
1392    ;;
1393
1394   openbsd)
1395    ## Han Boetes <han@boetes.org> says this is necessary,
1396    ## otherwise Emacs dumps core on elf systems.
1397    LD_SWITCH_SYSTEM="-Z"
1398    ;;
1399 esac
1400 AC_SUBST(LD_SWITCH_SYSTEM)
1401
1402 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1403
1404 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1405 ## which has not been defined yet.  When this was handled with cpp,
1406 ## it was expanded to null when configure sourced the s/*.h file.
1407 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1408 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1409 ## (or somesuch), but because it is supposed to go at the _front_
1410 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1411 ## Compare with the gnu-linux case below, which added to the end
1412 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1413 ## LD_SWITCH_SYSTEM_TEMACS.
1414 case "$opsys" in
1415   netbsd|openbsd)
1416    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1417 esac
1418
1419
1420 C_SWITCH_MACHINE=
1421 case $canonical in
1422  alpha*)
1423   AC_CHECK_DECL([__ELF__])
1424   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1425     ## With ELF, make sure that all common symbols get allocated to in the
1426     ## data section.  Otherwise, the dump of temacs may miss variables in
1427     ## the shared library that have been initialized.  For example, with
1428     ## GNU libc, __malloc_initialized would normally be resolved to the
1429     ## shared library's .bss section, which is fatal.
1430     if test "x$GCC" = "xyes"; then
1431       C_SWITCH_MACHINE="-fno-common"
1432     else
1433       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1434     fi
1435   else
1436       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1437       dnl albeit under the mistaken assumption that said file
1438       dnl was no longer used.
1439       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1440   fi
1441   ;;
1442 esac
1443 AC_SUBST(C_SWITCH_MACHINE)
1444
1445 AC_SUBST(UNEXEC_OBJ)
1446
1447 C_SWITCH_SYSTEM=
1448 ## Some programs in src produce warnings saying certain subprograms
1449 ## are too complex and need a MAXMEM value greater than 2000 for
1450 ## additional optimization.  --nils@exp-math.uni-essen.de
1451 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1452   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1453 if test "$opsys" = "mingw32"; then
1454   case "$canonical" in
1455     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1456     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1457   esac
1458 fi
1459 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1460 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1461 AC_SUBST(C_SWITCH_SYSTEM)
1462
1463
1464 LIBS_SYSTEM=
1465 case "$opsys" in
1466   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1467   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1468
1469   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1470
1471   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1472
1473   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1474
1475   ## Motif needs -lgen.
1476   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1477 esac
1478
1479 AC_SUBST(LIBS_SYSTEM)
1480
1481 ### Make sure subsequent tests use flags consistent with the build flags.
1482
1483 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1484   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1485 else
1486   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1487 fi
1488
1489 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1490 AC_DEFUN([AC_TYPE_SIZE_T])
1491 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1492 AC_DEFUN([AC_TYPE_UID_T])
1493
1494 # sqrt and other floating-point functions such as fmod and frexp
1495 # are found in -lm on many systems.
1496 OLD_LIBS=$LIBS
1497 AC_SEARCH_LIBS([sqrt], [m])
1498 if test "X$LIBS" = "X$OLD_LIBS"; then
1499   LIB_MATH=
1500 else
1501   LIB_MATH=$ac_cv_search_sqrt
1502 fi
1503 LIBS=$OLD_LIBS
1504
1505 dnl Current possibilities handled by sed (aix4-2 -> aix,
1506 dnl gnu-linux -> gnu/linux, etc.):
1507 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux.
1508 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1509 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1510
1511 case $opsys in
1512   cygwin )
1513     LIB_MATH=
1514     ;;
1515   darwin )
1516     ## Adding -lm confuses the dynamic linker, so omit it.
1517     LIB_MATH=
1518     ;;
1519   freebsd | dragonfly )
1520     SYSTEM_TYPE=berkeley-unix
1521     ;;
1522   gnu-linux | gnu-kfreebsd )
1523     ;;
1524   hpux10-20 | hpux11 )
1525     ;;
1526   mingw32 )
1527     LIB_MATH=
1528     SYSTEM_TYPE=windows-nt
1529     ;;
1530   dnl NB this may be adjusted below.
1531   netbsd | openbsd )
1532     SYSTEM_TYPE=berkeley-unix
1533     ;;
1534
1535   sol2* | unixware )
1536     SYSTEM_TYPE=usg-unix-v
1537     ;;
1538
1539 esac
1540
1541 AC_SUBST(LIB_MATH)
1542 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1543   [The type of system you are compiling for; sets 'system-type'.])
1544
1545
1546 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1547 pre_PKG_CONFIG_LIBS=$LIBS
1548
1549 PKG_PROG_PKG_CONFIG(0.9.0)
1550
1551 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1552 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1553 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1554 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1555 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1556 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1557 dnl actions.
1558 AC_DEFUN([EMACS_CHECK_MODULES],
1559   [PKG_CHECK_MODULES([$1], [$2],
1560      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1561       m4_default([$3], [HAVE_$1=yes])],
1562      [m4_default([$4], [HAVE_$1=no])])])
1563
1564 HAVE_SOUND=no
1565 if test "${with_sound}" != "no"; then
1566   # Sound support for GNU/Linux, the free BSDs, MinGW, and Cygwin.
1567   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1568     have_sound_header=yes, [], [
1569     #ifdef __MINGW32__
1570     #define WIN32_LEAN_AND_MEAN
1571     #include <windows.h>
1572     #endif
1573     ])
1574   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1575     AC_MSG_ERROR([OSS sound support requested but not found.])
1576
1577   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1578     # Emulation library used on NetBSD.
1579     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1580     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1581       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1582     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1583     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1584   fi
1585   AC_SUBST(LIBSOUND)
1586
1587   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1588     ALSA_REQUIRED=1.0.0
1589     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1590     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1591     if test $HAVE_ALSA = yes; then
1592       SAVE_CFLAGS="$CFLAGS"
1593       SAVE_LIBS="$LIBS"
1594       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1595       LIBS="$ALSA_LIBS $LIBS"
1596       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1597                       emacs_alsa_normal=yes,
1598                     emacs_alsa_normal=no)
1599       if test "$emacs_alsa_normal" != yes; then
1600         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1601                        [[snd_lib_error_set_handler (0);]])],
1602                        emacs_alsa_subdir=yes,
1603                      emacs_alsa_subdir=no)
1604         if test "$emacs_alsa_subdir" != yes; then
1605           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1606         fi
1607         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1608       fi
1609
1610       CFLAGS="$SAVE_CFLAGS"
1611       LIBS="$SAVE_LIBS"
1612       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1613       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1614       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1615     elif test "${with_sound}" = "alsa"; then
1616       AC_MSG_ERROR([ALSA sound support requested but not found.])
1617     fi
1618   fi                            dnl with_sound = alsa|yes
1619
1620   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1621   dnl compiles only on the specified platforms.  For others, it
1622   dnl probably doesn't make sense to try.
1623   dnl FIXME So surely we should bypass this whole section if not using
1624   dnl one of these platforms?
1625   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1626      case "$opsys" in
1627        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1628        dnl Adjust the --with-sound help text if you change this.
1629        gnu-linux|freebsd|netbsd|mingw32|cygwin)
1630          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1631          HAVE_SOUND=yes
1632          ;;
1633      esac
1634   fi
1635
1636   AC_SUBST(CFLAGS_SOUND)
1637 fi
1638
1639 dnl checks for header files
1640 AC_CHECK_HEADERS_ONCE(
1641   malloc.h
1642   sys/systeminfo.h
1643   sys/sysinfo.h
1644   coff.h pty.h
1645   sys/resource.h
1646   sys/utsname.h pwd.h utmp.h util.h)
1647
1648 AC_MSG_CHECKING(if personality LINUX32 can be set)
1649 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1650                emacs_cv_personality_linux32=yes,
1651                emacs_cv_personality_linux32=no)
1652 AC_MSG_RESULT($emacs_cv_personality_linux32)
1653
1654 if test $emacs_cv_personality_linux32 = yes; then
1655   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1656             [Define to 1 if personality LINUX32 can be set.])
1657 fi
1658
1659 # Note that Solaris has sys/sysinfo.h which defines struct
1660 # sysinfo as well.  To make sure that we're using GNU/Linux
1661 # sysinfo, we explicitly set one of its fields.
1662 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1663   AC_MSG_CHECKING([if Linux sysinfo may be used])
1664   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1665                                      [[struct sysinfo si;
1666                                        si.totalram = 0;
1667                                        sysinfo (&si)]])],
1668     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1669   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1670   if test $emacs_cv_linux_sysinfo = yes; then
1671     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1672     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1673                                        [[struct sysinfo si; return si.mem_unit]])],
1674       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1675                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1676   fi
1677 fi
1678
1679 dnl On Solaris 8 there's a compilation warning for term.h because
1680 dnl it doesn't define 'bool'.
1681 AC_CHECK_HEADERS(term.h, , , -)
1682 AC_HEADER_TIME
1683 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1684                                       ]])
1685 if test $ac_cv_have_decl_sys_siglist != yes; then
1686   # For Tru64, at least:
1687   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1688                                           ]])
1689 fi
1690 AC_HEADER_SYS_WAIT
1691
1692 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1693 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1694 #if HAVE_SYS_SOCKET_H
1695 #include <sys/socket.h>
1696 #endif])
1697 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1698 #if HAVE_SYS_SOCKET_H
1699 #include <sys/socket.h>
1700 #endif])
1701 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1702 #if HAVE_SYS_SOCKET_H
1703 #include <sys/socket.h>
1704 #endif])
1705
1706 dnl checks for structure members
1707 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1708                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1709                   struct ifreq.ifr_addr,
1710                   struct ifreq.ifr_addr.sa_len], , ,
1711                  [AC_INCLUDES_DEFAULT
1712 #if HAVE_SYS_SOCKET_H
1713 #include <sys/socket.h>
1714 #endif
1715 #if HAVE_NET_IF_H
1716 #include <net/if.h>
1717 #endif])
1718
1719 dnl Check for endianness.
1720 dnl AC_C_BIGENDIAN is done by gnulib.
1721
1722 dnl check for Make feature
1723
1724 AUTO_DEPEND=no
1725 dnl check if we have GCC and autodepend is on.
1726 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1727    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1728    SAVE_CFLAGS="$CFLAGS"
1729    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1730    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1731    CFLAGS="$SAVE_CFLAGS"
1732    test -f deps.d || ac_enable_autodepend=no
1733    rm -rf deps.d
1734    AC_MSG_RESULT([$ac_enable_autodepend])
1735    if test $ac_enable_autodepend = yes; then
1736       AUTO_DEPEND=yes
1737    fi
1738 fi
1739 AC_SUBST(AUTO_DEPEND)
1740
1741 dnl checks for operating system services
1742 AC_SYS_LONG_FILE_NAMES
1743
1744 #### Choose a window system.
1745
1746 ## We leave window_system equal to none if
1747 ## we end up building without one.  Any new window system should
1748 ## set window_system to an appropriate value and add objects to
1749 ## window-system-specific substs.
1750
1751 window_system=none
1752 AC_PATH_X
1753 if test "$no_x" != yes; then
1754   window_system=x11
1755 fi
1756
1757 LD_SWITCH_X_SITE_RPATH=
1758 if test "${x_libraries}" != NONE; then
1759   if test -n "${x_libraries}"; then
1760     LD_SWITCH_X_SITE=-L`AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -L/g'`
1761     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`
1762       AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -Wl,-rpath,/g'
1763     `
1764   fi
1765   x_default_search_path=""
1766   x_search_path=${x_libraries}
1767   if test -z "${x_search_path}"; then
1768     x_search_path=/usr/lib
1769   fi
1770   for x_library in `AS_ECHO(["$x_search_path:"]) | \
1771                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1772     x_search_path="\
1773 ${x_library}/X11/%L/%T/%N%C%S:\
1774 ${x_library}/X11/%l/%T/%N%C%S:\
1775 ${x_library}/X11/%T/%N%C%S:\
1776 ${x_library}/X11/%L/%T/%N%S:\
1777 ${x_library}/X11/%l/%T/%N%S:\
1778 ${x_library}/X11/%T/%N%S"
1779     if test x"${x_default_search_path}" = x; then
1780       x_default_search_path=${x_search_path}
1781     else
1782       x_default_search_path="${x_search_path}:${x_default_search_path}"
1783     fi
1784   done
1785 fi
1786 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1787
1788 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1789   C_SWITCH_X_SITE=$isystem`AS_ECHO(["$x_includes"]) | sed -e "s/:/ $isystem/g"`
1790 fi
1791
1792 if test x"${x_includes}" = x; then
1793   bitmapdir=/usr/include/X11/bitmaps
1794 else
1795   # accumulate include directories that have X11 bitmap subdirectories
1796   bmd_acc=
1797   for bmd in `AS_ECHO(["$x_includes"]) | sed -e 's/:/ /g'`; do
1798     if test -d "${bmd}/X11/bitmaps"; then
1799       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1800     fi
1801     if test -d "${bmd}/bitmaps"; then
1802       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1803     fi
1804   done
1805   bitmapdir=${bmd_acc#:}
1806 fi
1807
1808 test "${with_ns}" = maybe && test "${opsys}" != darwin && with_ns=no
1809 HAVE_NS=no
1810 NS_GNUSTEP_CONFIG=no
1811 NS_IMPL_COCOA=no
1812 NS_IMPL_GNUSTEP=no
1813 tmp_CPPFLAGS="$CPPFLAGS"
1814 tmp_CFLAGS="$CFLAGS"
1815 CPPFLAGS="$CPPFLAGS -x objective-c"
1816 CFLAGS="$CFLAGS -x objective-c"
1817 GNU_OBJC_CFLAGS=
1818 LIBS_GNUSTEP=
1819 if test "${with_ns}" != no; then
1820   if test "${opsys}" = darwin; then
1821      NS_IMPL_COCOA=yes
1822      ns_appdir=`pwd`/nextstep/Emacs.app
1823      ns_appbindir=${ns_appdir}/Contents/MacOS
1824      ns_appresdir=${ns_appdir}/Contents/Resources
1825      ns_appsrc=Cocoa/Emacs.base
1826      ns_fontfile=macfont.o
1827   elif flags=$( (gnustep-config --objc-flags) 2>/dev/null); then
1828      NS_IMPL_GNUSTEP=yes
1829      NS_GNUSTEP_CONFIG=yes
1830      GNU_OBJC_CFLAGS=$flags
1831      LIBS_GNUSTEP=$(gnustep-config --gui-libs) || exit
1832   elif test -f $GNUSTEP_CONFIG_FILE; then
1833      NS_IMPL_GNUSTEP=yes
1834      dnl FIXME sourcing this several times in subshells seems inefficient.
1835      GNUSTEP_SYSTEM_HEADERS=$(
1836        . $GNUSTEP_CONFIG_FILE
1837        AS_ECHO(["$GNUSTEP_SYSTEM_HEADERS"])
1838      )
1839      GNUSTEP_SYSTEM_LIBRARIES=$(
1840        . $GNUSTEP_CONFIG_FILE
1841        AS_ECHO(["$GNUSTEP_SYSTEM_LIBRARIES"])
1842      )
1843      dnl I seemed to need these as well with GNUstep-startup 0.25.
1844      GNUSTEP_LOCAL_HEADERS=$(
1845        . $GNUSTEP_CONFIG_FILE
1846        AS_ECHO(["$GNUSTEP_LOCAL_HEADERS"])
1847      )
1848      GNUSTEP_LOCAL_LIBRARIES=$(
1849        . $GNUSTEP_CONFIG_FILE
1850        AS_ECHO(["$GNUSTEP_LOCAL_LIBRARIES"])
1851      )
1852      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1853        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1854      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1855        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1856      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1857      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1858      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1859      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1860      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1861      dnl If they had chosen to either define it or not, we could have
1862      dnl just used AC_CHECK_DECL here.
1863      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1864        emacs_cv_objc_exceptions,
1865 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1866 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1867 1;
1868 #else
1869 fail;
1870 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1871      if test $emacs_cv_objc_exceptions = yes; then
1872        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1873        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1874          [Define if GNUstep uses ObjC exceptions.])
1875        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1876      fi
1877   fi
1878   if test $NS_IMPL_GNUSTEP = yes; then
1879      ns_appdir=`pwd`/nextstep/Emacs.app
1880      ns_appbindir=${ns_appdir}
1881      ns_appresdir=${ns_appdir}/Resources
1882      ns_appsrc=GNUstep/Emacs.base
1883      ns_fontfile=nsfont.o
1884   fi
1885
1886   dnl This is only used while we test the NS headers, it gets reset below.
1887   CPPFLAGS="$CPPFLAGS $GNU_OBJC_CFLAGS"
1888   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1889
1890   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1891                   [AC_MSG_ERROR([The include files (AppKit/AppKit.h etc) that
1892 are required for a Nextstep build are missing or cannot be compiled.
1893 Either fix this, or re-configure with the option '--without-ns'.])])
1894
1895   macfont_file=""
1896   if test "${NS_IMPL_COCOA}" = "yes"; then
1897     AC_MSG_CHECKING([for OSX 10.6 or newer])
1898     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1899                                      [
1900 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1901 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1060
1902  ; /* OK */
1903 #else
1904  error "OSX 10.6 or newer required";
1905 #endif
1906 #endif
1907                     ])],
1908                     ns_osx_have_106=yes,
1909                     ns_osx_have_106=no)
1910     AC_MSG_RESULT([$ns_osx_have_106])
1911
1912     if test $ns_osx_have_106 = no; then
1913        AC_MSG_ERROR([OSX 10.6 or newer is required]);
1914     fi
1915   fi
1916 fi
1917
1918 AC_SUBST(LIBS_GNUSTEP)
1919
1920 INSTALL_ARCH_INDEP_EXTRA=install-etc
1921 ns_self_contained=no
1922 NS_OBJ=
1923 NS_OBJC_OBJ=
1924 if test "${HAVE_NS}" = yes; then
1925   if test "$with_toolkit_scroll_bars" = "no"; then
1926     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1927   fi
1928
1929   window_system=nextstep
1930   # set up packaging dirs
1931   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1932      ns_self_contained=yes
1933      prefix=${ns_appresdir}
1934      exec_prefix=${ns_appbindir}
1935      dnl This one isn't really used, only archlibdir is.
1936      libexecdir="\${ns_appbindir}/libexec"
1937      archlibdir="\${ns_appbindir}/libexec"
1938      etcdocdir="\${ns_appresdir}/etc"
1939      etcdir="\${ns_appresdir}/etc"
1940      dnl FIXME maybe set datarootdir instead.
1941      dnl That would also get applications, icons, man.
1942      infodir="\${ns_appresdir}/info"
1943      mandir="\${ns_appresdir}/man"
1944      lispdir="\${ns_appresdir}/lisp"
1945      test "$locallisppathset" = no && locallisppath=""
1946      INSTALL_ARCH_INDEP_EXTRA=
1947   fi
1948
1949   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o $ns_fontfile"
1950 fi
1951 CFLAGS="$tmp_CFLAGS"
1952 CPPFLAGS="$tmp_CPPFLAGS"
1953 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1954 AC_SUBST(ns_self_contained)
1955 AC_SUBST(NS_OBJ)
1956 AC_SUBST(NS_OBJC_OBJ)
1957
1958 HAVE_W32=no
1959 W32_OBJ=
1960 W32_LIBS=
1961 EMACSRES=
1962 CLIENTRES=
1963 CLIENTW=
1964 W32_RES_LINK=
1965 EMACS_MANIFEST=
1966 UPDATE_MANIFEST=
1967 if test "${with_w32}" != no; then
1968   case "${opsys}" in
1969     cygwin)
1970       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1971              [AC_MSG_ERROR(['--with-w32' was specified, but windows.h
1972                    cannot be found.])])
1973     ;;
1974     mingw32)
1975     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1976     ;;
1977     *)
1978       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1979     ;;
1980   esac
1981 fi
1982
1983 if test "${opsys}" = "mingw32"; then
1984   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1985   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1986      #include <windows.h>
1987      #include <usp10.h>]],
1988    [[PIMAGE_NT_HEADERS pHeader;
1989      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1990    [emacs_cv_w32api=yes
1991     HAVE_W32=yes],
1992    emacs_cv_w32api=no)
1993   AC_MSG_RESULT($emacs_cv_w32api)
1994   if test "${emacs_cv_w32api}" = "no"; then
1995     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1996   fi
1997 fi
1998
1999 FIRSTFILE_OBJ=
2000 NTDIR=
2001 LIBS_ECLIENT=
2002 LIB_WSOCK32=
2003 NTLIB=
2004 CM_OBJ="cm.o"
2005 XARGS_LIMIT=
2006 if test "${HAVE_W32}" = "yes"; then
2007   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
2008   if test "$with_toolkit_scroll_bars" = "no"; then
2009     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for w32 build.])
2010   fi
2011   AC_CHECK_TOOL(WINDRES, [windres],
2012                 [AC_MSG_ERROR([No resource compiler found.])])
2013   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
2014   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
2015   EMACSRES="emacs.res"
2016   case "$canonical" in
2017     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
2018     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
2019   esac
2020   dnl Construct something of the form "24,4,0,0" with 4 components.
2021   comma_version=`echo "${PACKAGE_VERSION}.0.0" | sed -e 's/\./,/g' -e 's/^\([[^,]]*,[[^,]]*,[[^,]]*,[[^,]]*\).*/\1/'`
2022
2023   comma_space_version=`echo "$comma_version" | sed 's/,/, /g'`
2024   AC_SUBST(comma_version)
2025   AC_SUBST(comma_space_version)
2026   AC_CONFIG_FILES([nt/emacs.rc nt/emacsclient.rc])
2027   if test "${opsys}" = "cygwin"; then
2028     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
2029     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
2030     # Tell the linker that emacs.res is an object (which we compile from
2031     # the rc file), not a linker script.
2032     W32_RES_LINK="-Wl,emacs.res"
2033   else
2034     UPDATE_MANIFEST=update-game-score.exe.manifest
2035     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
2036     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
2037     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
2038     W32_RES_LINK="\$(EMACSRES)"
2039     CLIENTRES="emacsclient.res"
2040     CLIENTW="emacsclientw\$(EXEEXT)"
2041     FIRSTFILE_OBJ=firstfile.o
2042     NTDIR=nt
2043     CM_OBJ=
2044     LIBS_ECLIENT="-lcomctl32"
2045     LIB_WSOCK32="-lwsock32"
2046     NTLIB="ntlib.$ac_objext"
2047     XARGS_LIMIT="-s 10000"
2048   fi
2049 fi
2050 AC_SUBST(W32_OBJ)
2051 AC_SUBST(W32_LIBS)
2052 AC_SUBST(EMACSRES)
2053 AC_SUBST(EMACS_MANIFEST)
2054 AC_SUBST(UPDATE_MANIFEST)
2055 AC_SUBST(CLIENTRES)
2056 AC_SUBST(CLIENTW)
2057 AC_SUBST(W32_RES_LINK)
2058 AC_SUBST(FIRSTFILE_OBJ)
2059 AC_SUBST(NTDIR)
2060 AC_SUBST(CM_OBJ)
2061 AC_SUBST(LIBS_ECLIENT)
2062 AC_SUBST(LIB_WSOCK32)
2063 AC_SUBST(NTLIB)
2064 AC_SUBST(XARGS_LIMIT)
2065
2066 if test "${HAVE_W32}" = "yes"; then
2067   window_system=w32
2068   with_xft=no
2069 fi
2070
2071 ## $window_system is now set to the window system we will
2072 ## ultimately use.
2073
2074 term_header=
2075 HAVE_X_WINDOWS=no
2076 HAVE_X11=no
2077 USE_X_TOOLKIT=none
2078
2079 case "${window_system}" in
2080   x11 )
2081     HAVE_X_WINDOWS=yes
2082     HAVE_X11=yes
2083     term_header=xterm.h
2084     case "${with_x_toolkit}" in
2085       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
2086       motif ) USE_X_TOOLKIT=MOTIF ;;
2087       gtk ) with_gtk=yes
2088             term_header=gtkutil.h
2089 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
2090 dnl USE_X_TOOLKIT is set.
2091             USE_X_TOOLKIT=none ;;
2092       gtk2 ) with_gtk2=yes
2093              term_header=gtkutil.h
2094              USE_X_TOOLKIT=none ;;
2095       gtk3 ) with_gtk3=yes
2096              term_header=gtkutil.h
2097              USE_X_TOOLKIT=none ;;
2098       no ) USE_X_TOOLKIT=none ;;
2099 dnl If user did not say whether to use a toolkit, make this decision later:
2100 dnl use the toolkit if we have gtk, or X11R5 or newer.
2101       * ) USE_X_TOOLKIT=maybe ;;
2102     esac
2103   ;;
2104   nextstep )
2105     term_header=nsterm.h
2106   ;;
2107   w32 )
2108     term_header=w32term.h
2109   ;;
2110 esac
2111
2112 if test "$window_system" = none && test "X$with_x" != "Xno"; then
2113    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
2114    if test "$HAVE_XSERVER" = true ||
2115       test -n "$DISPLAY" ||
2116       {
2117         for emacs_libX11 in /usr/lib/libX11.*; do break; done
2118         test "$emacs_libX11" != '/usr/lib/libX11.*'
2119       }
2120    then
2121         AC_MSG_ERROR([You seem to be running X, but no X development libraries
2122 were found.  You should install the relevant development files for X
2123 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2124 sure you have development files for image handling, i.e.
2125 tiff, gif, jpeg, png and xpm.
2126 If you are sure you want Emacs compiled without X window support, pass
2127   --without-x
2128 to configure.])
2129    fi
2130 fi
2131
2132 # Does the opsystem file prohibit the use of the GNU malloc?
2133 # Assume not, until told otherwise.
2134 GNU_MALLOC=yes
2135
2136 AC_CACHE_CHECK(
2137   [whether malloc is Doug Lea style],
2138   [emacs_cv_var_doug_lea_malloc],
2139   [emacs_cv_var_doug_lea_malloc=no
2140    dnl Hooks do not work with address sanitization.
2141    if test "$emacs_cv_sanitize_address" != yes; then
2142      AC_LINK_IFELSE(
2143        [AC_LANG_PROGRAM(
2144           [[#include <malloc.h>
2145             static void hook (void) {}]],
2146           [[malloc_set_state (malloc_get_state ());
2147             __after_morecore_hook = hook;
2148             __malloc_initialize_hook = hook;]])],
2149        [emacs_cv_var_doug_lea_malloc=yes])
2150    fi])
2151 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2152
2153 system_malloc=$emacs_cv_sanitize_address
2154
2155 hybrid_malloc=
2156
2157 case "$opsys" in
2158   ## darwin ld insists on the use of malloc routines in the System framework.
2159   darwin | mingw32 | nacl | sol2-10) system_malloc=yes ;;
2160   cygwin) hybrid_malloc=yes;;
2161 esac
2162
2163 if test "${system_malloc}" != yes && test "${doug_lea_malloc}" != yes \
2164    && test "${UNEXEC_OBJ}" = unexelf.o; then
2165   hybrid_malloc=yes
2166 fi
2167
2168 GMALLOC_OBJ=
2169 HYBRID_MALLOC=
2170 if test "${system_malloc}" = "yes"; then
2171   AC_DEFINE([SYSTEM_MALLOC], 1,
2172     [Define to 1 to use the system memory allocator, even if it is not
2173      Doug Lea style.])
2174   GNU_MALLOC=no
2175   GNU_MALLOC_reason="
2176     (The GNU allocators don't work with this system configuration.)"
2177   VMLIMIT_OBJ=
2178 elif test "$hybrid_malloc" = yes; then
2179   AC_DEFINE(HYBRID_MALLOC, 1,
2180     [Define to use gmalloc before dumping and the system malloc after.])
2181   HYBRID_MALLOC=1
2182   GNU_MALLOC=
2183   GNU_MALLOC_reason="only before dumping"
2184   GMALLOC_OBJ=gmalloc.o
2185   VMLIMIT_OBJ=
2186 else
2187   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2188   VMLIMIT_OBJ=vm-limit.o
2189
2190   AC_CHECK_HEADERS([sys/vlimit.h])
2191   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2192     [AC_LINK_IFELSE(
2193        [AC_LANG_PROGRAM(
2194          [[extern char data_start[]; char ch;]],
2195          [[return data_start < &ch;]])],
2196        [emacs_cv_data_start=yes],
2197        [emacs_cv_data_start=no])])
2198   if test $emacs_cv_data_start = yes; then
2199     AC_DEFINE([HAVE_DATA_START], 1,
2200       [Define to 1 if data_start is the address of the start
2201        of the main data segment.])
2202   fi
2203 fi
2204 AC_SUBST([HYBRID_MALLOC])
2205 AM_CONDITIONAL([HYBRID_MALLOC_LIB], [test -n "$HYBRID_MALLOC"])
2206 AC_SUBST(GMALLOC_OBJ)
2207 AC_SUBST(VMLIMIT_OBJ)
2208
2209 if test "$doug_lea_malloc" = "yes" && test "$hybrid_malloc" != yes; then
2210   if test "$GNU_MALLOC" = yes ; then
2211     GNU_MALLOC_reason="
2212       (Using Doug Lea's new malloc from the GNU C Library.)"
2213   fi
2214   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2215     [Define to 1 if the system memory allocator is Doug Lea style,
2216      with malloc hooks and malloc_set_state.])
2217
2218   ## Use mmap directly for allocating larger buffers.
2219   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2220   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2221   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2222   case "$opsys" in
2223     mingw32|gnu*) REL_ALLOC=no ;;
2224   esac
2225 fi
2226
2227 if test x"${REL_ALLOC}" = x; then
2228   REL_ALLOC=${GNU_MALLOC}
2229 fi
2230
2231 use_mmap_for_buffers=no
2232 case "$opsys" in
2233   cygwin|mingw32) use_mmap_for_buffers=yes ;;
2234 esac
2235
2236 AC_FUNC_MMAP
2237 if test $use_mmap_for_buffers = yes; then
2238   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2239   REL_ALLOC=no
2240 fi
2241
2242 LIBS="$LIBS_SYSTEM $LIBS"
2243
2244 dnl FIXME replace main with a function we actually want from this library.
2245 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2246
2247 dnl Check for the POSIX thread library.
2248 LIB_PTHREAD=
2249 AC_CHECK_HEADERS_ONCE(pthread.h)
2250 if test "$ac_cv_header_pthread_h" && test "$opsys" != "mingw32"; then
2251   AC_CACHE_CHECK([for pthread library],
2252     [emacs_cv_pthread_lib],
2253     [emacs_cv_pthread_lib=no
2254      OLD_LIBS=$LIBS
2255      for emacs_pthread_lib in 'none needed' -lpthread; do
2256        case $emacs_pthread_lib in
2257          -*) LIBS="$OLD_LIBS $emacs_pthread_lib";;
2258        esac
2259        AC_LINK_IFELSE(
2260          [AC_LANG_PROGRAM(
2261             [[#include <pthread.h>
2262               #include <signal.h>
2263               sigset_t old_mask, new_mask;
2264               void noop (void) {}]],
2265             [[pthread_t th = pthread_self ();
2266               int status = 0;
2267               status += pthread_create (&th, 0, 0, 0);
2268               status += pthread_sigmask (SIG_BLOCK, &new_mask, &old_mask);
2269               status += pthread_kill (th, 0);
2270               #if ! (defined SYSTEM_MALLOC || defined HYBRID_MALLOC \
2271                      || defined DOUG_LEA_MALLOC)
2272               /* Test for pthread_atfork only if gmalloc uses it,
2273                  as older-style hosts like MirBSD 10 lack it.  */
2274               status += pthread_atfork (noop, noop, noop);
2275               #endif
2276               return status;]])],
2277          [emacs_cv_pthread_lib=$emacs_pthread_lib])
2278        LIBS=$OLD_LIBS
2279        if test "$emacs_cv_pthread_lib" != no; then
2280          break
2281        fi
2282      done])
2283   if test "$emacs_cv_pthread_lib" != no; then
2284     AC_DEFINE([HAVE_PTHREAD], 1, [Define to 1 if you have POSIX threads.])
2285     case $emacs_cv_pthread_lib in
2286       -*) LIB_PTHREAD=$emacs_cv_pthread_lib;;
2287     esac
2288     ac_cv_func_pthread_sigmask=yes
2289     # Some systems optimize for single-threaded programs by default, and
2290     # need special flags to disable these optimizations. For example, the
2291     # definition of 'errno' in <errno.h>.
2292     case $opsys in
2293       hpux* | sol*)
2294         AC_DEFINE([_REENTRANT], 1,
2295           [Define to 1 if your system requires this in multithreaded code.]);;
2296       aix4-2)
2297         AC_DEFINE([_THREAD_SAFE], 1,
2298           [Define to 1 if your system requires this in multithreaded code.]);;
2299     esac
2300   fi
2301 fi
2302 AC_SUBST([LIB_PTHREAD])
2303
2304 dnl Check for need for bigtoc support on IBM AIX
2305
2306 case ${host_os} in
2307 aix*)
2308   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2309     case $GCC in
2310     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2311     *) gdb_cv_bigtoc=-bbigtoc ;;
2312     esac
2313
2314     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2315     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2316   ])
2317   ;;
2318 esac
2319
2320 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2321 # is for the tests that follow.  We set them back later on.
2322
2323 REAL_CFLAGS="$CFLAGS"
2324 REAL_CPPFLAGS="$CPPFLAGS"
2325 REAL_LIBS="$LIBS"
2326
2327 if test "${HAVE_X11}" = "yes"; then
2328   DEFS="$C_SWITCH_X_SITE $DEFS"
2329   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2330   LIBS="-lX11 $LIBS"
2331   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2332   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2333
2334   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2335   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2336   # but it's more convenient here to set LD_RUN_PATH since this
2337   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2338   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2339     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2340     export LD_RUN_PATH
2341   fi
2342
2343   if test "${opsys}" = "gnu-linux"; then
2344     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2345     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2346      [[XOpenDisplay ("foo");]])],
2347      [xgnu_linux_first_failure=no],
2348      [xgnu_linux_first_failure=yes])
2349     if test "${xgnu_linux_first_failure}" = "yes"; then
2350       OLD_CPPFLAGS="$CPPFLAGS"
2351       OLD_LIBS="$LIBS"
2352       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2353       LIBS="$LIBS -b i486-linuxaout"
2354       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2355        [[XOpenDisplay ("foo");]])],
2356        [xgnu_linux_second_failure=no],
2357        [xgnu_linux_second_failure=yes])
2358       if test "${xgnu_linux_second_failure}" = "yes"; then
2359         # If we get the same failure with -b, there is no use adding -b.
2360         # So leave it out.  This plays safe.
2361         AC_MSG_RESULT(no)
2362       else
2363         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2364         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2365         AC_MSG_RESULT(yes)
2366       fi
2367       CPPFLAGS=$OLD_CPPFLAGS
2368       LIBS=$OLD_LIBS
2369     else
2370       AC_MSG_RESULT(no)
2371     fi
2372   fi
2373
2374   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2375   # header files included from there.
2376   AC_MSG_CHECKING(for Xkb)
2377   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2378 #include <X11/XKBlib.h>]],
2379         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2380         emacs_xkb=yes, emacs_xkb=no)
2381   AC_MSG_RESULT($emacs_xkb)
2382   if test $emacs_xkb = yes; then
2383     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2384   fi
2385
2386   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2387 XScreenNumberOfScreen)
2388 fi
2389
2390 if test "${window_system}" = "x11"; then
2391   AC_MSG_CHECKING(X11 version 6)
2392   AC_CACHE_VAL(emacs_cv_x11_version_6,
2393   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2394 [[#if XlibSpecificationRelease < 6
2395 fail;
2396 #endif
2397 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2398   if test $emacs_cv_x11_version_6 = yes; then
2399     AC_MSG_RESULT(6 or newer)
2400     AC_DEFINE(HAVE_X11R6, 1,
2401               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2402     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2403     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2404     ## XIM support.
2405     case "$opsys" in
2406       sol2-*) : ;;
2407       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2408            [Define if you have usable X11R6-style XIM support.])
2409          ;;
2410     esac
2411   else
2412     AC_MSG_RESULT(before 6)
2413   fi
2414 fi
2415
2416
2417 ### Use -lrsvg-2 if available, unless '--with-rsvg=no' is specified.
2418 HAVE_RSVG=no
2419 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2420   if test "${with_rsvg}" != "no"; then
2421     RSVG_REQUIRED=2.11.0
2422     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2423
2424     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2425     AC_SUBST(RSVG_CFLAGS)
2426     AC_SUBST(RSVG_LIBS)
2427
2428     if test $HAVE_RSVG = yes; then
2429       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2430       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2431       # Windows loads librsvg dynamically
2432       if test "${opsys}" = "mingw32"; then
2433         RSVG_LIBS=
2434       fi
2435     fi
2436   fi
2437 fi
2438
2439 HAVE_IMAGEMAGICK=no
2440 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2441   if test "${with_imagemagick}" != "no"; then
2442     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2443     ## 6.8.2 makes Emacs crash; see Bug#13867.
2444     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2445     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2446     AC_SUBST(IMAGEMAGICK_CFLAGS)
2447     AC_SUBST(IMAGEMAGICK_LIBS)
2448
2449     if test $HAVE_IMAGEMAGICK = yes; then
2450       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2451       OLD_CFLAGS=$CFLAGS
2452       OLD_LIBS=$LIBS
2453       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2454       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2455       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers MagickAutoOrientImage)
2456       CFLAGS=$OLD_CFLAGS
2457       LIBS=$OLD_LIBS
2458     fi
2459   fi
2460 fi
2461
2462 AC_CHECK_LIB(anl, getaddrinfo_a, HAVE_GETADDRINFO_A=yes)
2463 if test "${HAVE_GETADDRINFO_A}" = "yes"; then
2464   AC_DEFINE(HAVE_GETADDRINFO_A, 1,
2465 [Define to 1 if you have getaddrinfo_a for asynchronous DNS resolution.])
2466   GETADDRINFO_A_LIBS="-lanl"
2467   AC_SUBST(GETADDRINFO_A_LIBS)
2468 fi
2469
2470 HAVE_GTK=no
2471 GTK_OBJ=
2472 gtk_term_header=$term_header
2473 check_gtk2=no
2474 gtk3_pkg_errors=
2475 if test "${opsys}" != "mingw32"; then
2476   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2477     GLIB_REQUIRED=2.28
2478     GTK_REQUIRED=3.0
2479     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2480
2481     dnl Checks for libraries.
2482     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2483       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2484     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2485        AC_MSG_ERROR($GTK_PKG_ERRORS)
2486     fi
2487     if test "$pkg_check_gtk" = "yes"; then
2488        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2489        GTK_OBJ=emacsgtkfixed.o
2490        gtk_term_header=gtkutil.h
2491        USE_GTK_TOOLKIT="GTK3"
2492        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2493          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2494            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2495          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2496            [Define to 1 to disable Glib deprecation warnings.])
2497        fi
2498     else
2499        check_gtk2=yes
2500        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2501     fi
2502   fi
2503
2504   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2505     GLIB_REQUIRED=2.10
2506     GTK_REQUIRED=2.10
2507     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2508
2509     dnl Checks for libraries.
2510     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2511       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2512     if test "$pkg_check_gtk" = "no" &&
2513        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2514     then
2515       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2516     fi
2517     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2518   fi
2519 fi
2520
2521 OLD_CFLAGS=$CFLAGS
2522 OLD_LIBS=$LIBS
2523
2524 if test x"$pkg_check_gtk" = xyes; then
2525
2526   AC_SUBST(GTK_LIBS)
2527   CFLAGS="$CFLAGS $GTK_CFLAGS"
2528   LIBS="$GTK_LIBS $LIBS"
2529   dnl Try to compile a simple GTK program.
2530   AC_MSG_CHECKING([whether GTK compiles])
2531   GTK_COMPILES=no
2532   AC_LINK_IFELSE(
2533     [AC_LANG_PROGRAM(
2534        [[/* Check the Gtk and Glib APIs.  */
2535          #include <gtk/gtk.h>
2536          #include <glib-object.h>
2537          static void
2538          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2539          {}
2540        ]],
2541        [[
2542          GtkSettings *gs = 0;
2543          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2544             strict C prohibits this.  Use gtk_main_iteration to test that the
2545             libraries are there.  */
2546          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2547                                     0, 0, 0, G_CALLBACK (callback), 0))
2548            gtk_main_iteration ();
2549        ]])],
2550     [GTK_COMPILES=yes])
2551   AC_MSG_RESULT([$GTK_COMPILES])
2552   if test "${GTK_COMPILES}" != "yes"; then
2553     GTK_OBJ=
2554     if test "$USE_X_TOOLKIT" != "maybe"; then
2555       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2556     fi
2557   else
2558     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2559     HAVE_GTK=yes
2560     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2561     GTK_OBJ="gtkutil.o $GTK_OBJ"
2562     term_header=$gtk_term_header
2563     USE_X_TOOLKIT=none
2564     AC_MSG_WARN([[Your version of Gtk+ will have problems with
2565        closing open displays.  This is no problem if you just use
2566        one display, but if you use more than one and close one of them
2567        Emacs may crash.
2568        See http://bugzilla.gnome.org/show_bug.cgi?id=85715]])
2569     sleep 3
2570   fi
2571
2572 fi
2573 AC_SUBST(GTK_OBJ)
2574
2575
2576 if test "${HAVE_GTK}" = "yes"; then
2577
2578   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2579   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2580   if test "$with_toolkit_scroll_bars" != no; then
2581     with_toolkit_scroll_bars=yes
2582   fi
2583
2584   dnl  Check if we have the old file selection dialog declared and
2585   dnl  in the link library.  In 2.x it may be in the library,
2586   dnl  but not declared if deprecated featured has been selected out.
2587   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2588   HAVE_GTK_FILE_SELECTION=no
2589   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2590                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2591 #include <gtk/gtk.h>])
2592   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2593     AC_CHECK_FUNCS(gtk_file_selection_new)
2594   fi
2595
2596   dnl Same as above for gtk_handle_box.
2597   HAVE_GTK_HANDLE_BOX=no
2598   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2599                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2600 #include <gtk/gtk.h>])
2601   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2602     AC_CHECK_FUNCS(gtk_handle_box_new)
2603   fi
2604
2605   dnl Same as above for gtk_tearoff_menu_item.
2606   HAVE_GTK_TEAROFF_MENU_ITEM=no
2607   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2608                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2609 #include <gtk/gtk.h>])
2610   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2611     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2612   fi
2613
2614   dnl Check for functions introduced in 2.14 and later.
2615   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2616                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2617                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2618                  gtk_orientable_set_orientation \
2619                  gtk_window_set_has_resize_grip)
2620
2621  term_header=gtkutil.h
2622 fi
2623
2624
2625 dnl Enable xwidgets if GTK3 and WebKitGTK+ are available.
2626 HAVE_XWIDGETS=no
2627 XWIDGETS_OBJ=
2628 if test "$with_xwidgets" != "no"; then
2629   test "$USE_GTK_TOOLKIT" = "GTK3" && test "$window_system" != "none" ||
2630     AC_MSG_ERROR([xwidgets requested but gtk3 not used.])
2631
2632   WEBKIT_REQUIRED=1.4.0
2633   WEBKIT_MODULES="webkitgtk-3.0 >= $WEBKIT_REQUIRED"
2634   EMACS_CHECK_MODULES([WEBKIT], [$WEBKIT_MODULES])
2635   HAVE_XWIDGETS=$HAVE_WEBKIT
2636   test $HAVE_XWIDGETS = yes ||
2637     AC_MSG_ERROR([xwidgets requested but WebKitGTK+ not found.])
2638
2639   XWIDGETS_OBJ=xwidget.o
2640   AC_DEFINE([HAVE_XWIDGETS], 1, [Define to 1 if you have xwidgets support.])
2641 fi
2642 AC_SUBST(XWIDGETS_OBJ)
2643
2644 CFLAGS=$OLD_CFLAGS
2645 LIBS=$OLD_LIBS
2646
2647 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2648 dnl other platforms.
2649 HAVE_DBUS=no
2650 DBUS_OBJ=
2651 if test "${with_dbus}" = "yes"; then
2652    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2653    if test "$HAVE_DBUS" = yes; then
2654      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2655      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2656      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2657      dnl D-Bus 1.5.12.
2658      OLD_LIBS=$LIBS
2659      LIBS="$LIBS $DBUS_LIBS"
2660      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2661                     dbus_type_is_valid \
2662                     dbus_validate_bus_name \
2663                     dbus_validate_path \
2664                     dbus_validate_interface \
2665                     dbus_validate_member)
2666      LIBS=$OLD_LIBS
2667      DBUS_OBJ=dbusbind.o
2668    fi
2669 fi
2670 AC_SUBST(DBUS_CFLAGS)
2671 AC_SUBST(DBUS_LIBS)
2672 AC_SUBST(DBUS_OBJ)
2673
2674 dnl GSettings has been tested under GNU/Linux only.
2675 HAVE_GSETTINGS=no
2676 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2677    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2678    if test "$HAVE_GSETTINGS" = "yes"; then
2679       old_CFLAGS=$CFLAGS
2680       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2681       old_LIBS=$LIBS
2682       LIBS="$LIBS $GSETTINGS_LIBS"
2683       AC_MSG_CHECKING([whether GSettings is in gio])
2684       AC_LINK_IFELSE(
2685          [AC_LANG_PROGRAM(
2686              [[/* Check that gsettings really is present.  */
2687              #include <glib-object.h>
2688              #include <gio/gio.h>
2689              ]],
2690              [[
2691                GSettings *settings;
2692                GVariant *val = g_settings_get_value (settings, "");
2693              ]])],
2694          [], HAVE_GSETTINGS=no)
2695       AC_MSG_RESULT([$HAVE_GSETTINGS])
2696
2697       if test "$HAVE_GSETTINGS" = "yes"; then
2698         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2699         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2700         SETTINGS_LIBS="$GSETTINGS_LIBS"
2701       fi
2702       CFLAGS=$old_CFLAGS
2703       LIBS=$old_LIBS
2704    fi
2705 fi
2706
2707 dnl GConf has been tested under GNU/Linux only.
2708 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2709 HAVE_GCONF=no
2710 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2711    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2712    if test "$HAVE_GCONF" = yes; then
2713       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2714       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2715       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2716       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2717    fi
2718 fi
2719
2720 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2721     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2722     if test "$HAVE_GOBJECT" = "yes"; then
2723        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2724        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2725     fi
2726     SAVE_CFLAGS="$CFLAGS"
2727     SAVE_LIBS="$LIBS"
2728     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2729     LIBS="$SETTINGS_LIBS $LIBS"
2730     CFLAGS="$SAVE_CFLAGS"
2731     LIBS="$SAVE_LIBS"
2732 fi
2733 AC_SUBST(SETTINGS_CFLAGS)
2734 AC_SUBST(SETTINGS_LIBS)
2735
2736
2737 dnl SELinux is available for GNU/Linux only.
2738 HAVE_LIBSELINUX=no
2739 LIBSELINUX_LIBS=
2740 if test "${with_selinux}" = "yes"; then
2741    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2742    if test "$HAVE_LIBSELINUX" = yes; then
2743       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2744       LIBSELINUX_LIBS=-lselinux
2745    fi
2746 fi
2747 AC_SUBST(LIBSELINUX_LIBS)
2748
2749 HAVE_GNUTLS=no
2750 if test "${with_gnutls}" = "yes" ; then
2751   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2752     [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2753   if test "${HAVE_GNUTLS}" = "yes"; then
2754     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2755     EMACS_CHECK_MODULES([LIBGNUTLS3], [gnutls >= 3.0.0],
2756       [AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])], [])
2757   fi
2758
2759   # Windows loads GnuTLS dynamically
2760   if test "${opsys}" = "mingw32"; then
2761     LIBGNUTLS_LIBS=
2762   fi
2763 fi
2764
2765 AC_SUBST(LIBGNUTLS_LIBS)
2766 AC_SUBST(LIBGNUTLS_CFLAGS)
2767
2768 HAVE_LIBSYSTEMD=no
2769 if test "${with_libsystemd}" = "yes" ; then
2770   dnl This code has been tested with libsystemd 222 and later.
2771   dnl FIXME: Find the earliest version number for which Emacs should work,
2772   dnl and change '222' to that number.
2773   EMACS_CHECK_MODULES([LIBSYSTEMD], [libsystemd >= 222],
2774     [HAVE_LIBSYSTEMD=yes], [HAVE_LIBSYSTEMD=no])
2775   if test "${HAVE_LIBSYSTEMD}" = "yes"; then
2776     AC_DEFINE(HAVE_LIBSYSTEMD, 1, [Define if using libsystemd.])
2777   fi
2778 fi
2779
2780 AC_SUBST(LIBSYSTEMD_LIBS)
2781 AC_SUBST(LIBSYSTEMD_CFLAGS)
2782
2783 NOTIFY_OBJ=
2784 NOTIFY_SUMMARY=no
2785
2786 dnl MS Windows native file monitor is available for mingw32 only.
2787 case $with_file_notification,$opsys in
2788   w32,cygwin)
2789     AC_MSG_ERROR(['--with-file-notification=w32' was specified, but
2790     this is only supported on MS-Windows native and MinGW32 builds.
2791     Consider using gfile instead.])
2792     ;;
2793   w32,* | yes,mingw32)
2794     AC_CHECK_HEADER(windows.h)
2795     if test "$ac_cv_header_windows_h" = yes ; then
2796        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2797        NOTIFY_OBJ=w32notify.o
2798        NOTIFY_SUMMARY="yes (w32)"
2799     fi ;;
2800 esac
2801
2802 dnl inotify is available only on GNU/Linux.
2803 case $with_file_notification,$NOTIFY_OBJ in
2804   inotify, | yes,)
2805     AC_CHECK_HEADER(sys/inotify.h)
2806     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2807         AC_CHECK_FUNC(inotify_init1)
2808         if test "$ac_cv_func_inotify_init1" = yes; then
2809           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2810           NOTIFY_OBJ=inotify.o
2811           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2812        fi
2813     fi ;;
2814 esac
2815
2816 dnl kqueue is available on BSD-like systems.
2817 case $with_file_notification,$NOTIFY_OBJ in
2818   kqueue,* | yes,)
2819     EMACS_CHECK_MODULES([KQUEUE], [libkqueue])
2820     if test "$HAVE_KQUEUE" = "yes"; then
2821        AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2822        CPPFLAGS="$CPPFLAGS -I/usr/include/kqueue"
2823        NOTIFY_CFLAGS=$KQUEUE_CFLAGS
2824        NOTIFY_LIBS=$KQUEUE_LIBS
2825        NOTIFY_OBJ=kqueue.o
2826        NOTIFY_SUMMARY="yes -lkqueue"
2827     else
2828        AC_SEARCH_LIBS(kqueue, [])
2829        if test "$ac_cv_search_kqueue" != no; then
2830          AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2831          NOTIFY_OBJ=kqueue.o
2832          NOTIFY_SUMMARY="yes (kqueue)"
2833        fi
2834     fi ;;
2835 esac
2836
2837 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2838 dnl has been added in glib 2.24.  It has been tested under
2839 dnl GNU/Linux only.
2840 case $with_file_notification,$NOTIFY_OBJ in
2841   gfile,* | yes,)
2842     if test "${HAVE_NS}" = yes; then
2843        AC_MSG_ERROR(['--with-file-notification=gfile' is not supported in NextStep builds.
2844 Consider kqueue instead.])
2845     else
2846        EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2847        if test "$HAVE_GFILENOTIFY" = "yes"; then
2848           AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2849           NOTIFY_CFLAGS=$GFILENOTIFY_CFLAGS
2850           NOTIFY_LIBS=$GFILENOTIFY_LIBS
2851           NOTIFY_OBJ=gfilenotify.o
2852           NOTIFY_SUMMARY="yes -lgio (gfile)"
2853        fi
2854     fi ;;
2855 esac
2856
2857 case $with_file_notification,$NOTIFY_OBJ in
2858   yes,* | no,* | *,?*) ;;
2859   *) AC_MSG_ERROR([File notification '$with_file_notification' requested but requirements not found.]) ;;
2860 esac
2861
2862 if test -n "$NOTIFY_OBJ"; then
2863    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2864 fi
2865 AC_SUBST(NOTIFY_CFLAGS)
2866 AC_SUBST(NOTIFY_LIBS)
2867 AC_SUBST(NOTIFY_OBJ)
2868
2869 dnl Do not put whitespace before the #include statements below.
2870 dnl Older compilers (eg sunos4 cc) choke on it.
2871 HAVE_XAW3D=no
2872 LUCID_LIBW=
2873 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2874   if test "$with_xaw3d" != no; then
2875     AC_CACHE_VAL(emacs_cv_xaw3d,
2876     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2877 #include <X11/Intrinsic.h>
2878 #include <X11/Xaw3d/Simple.h>]],
2879       [[]])],
2880       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2881                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2882       emacs_cv_xaw3d=no)])
2883   else
2884     emacs_cv_xaw3d=no
2885   fi
2886   if test $emacs_cv_xaw3d = yes; then
2887     AC_MSG_CHECKING(for xaw3d)
2888     AC_MSG_RESULT([yes; using Lucid toolkit])
2889     USE_X_TOOLKIT=LUCID
2890     HAVE_XAW3D=yes
2891     LUCID_LIBW=-lXaw3d
2892     AC_DEFINE(HAVE_XAW3D, 1,
2893               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2894   else
2895     AC_MSG_CHECKING(for xaw3d)
2896     AC_MSG_RESULT(no)
2897     AC_MSG_CHECKING(for libXaw)
2898     AC_CACHE_VAL(emacs_cv_xaw,
2899     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2900 #include <X11/Intrinsic.h>
2901 #include <X11/Xaw/Simple.h>]],
2902       [[]])],
2903       emacs_cv_xaw=yes,
2904       emacs_cv_xaw=no)])
2905     if test $emacs_cv_xaw = yes; then
2906       AC_MSG_RESULT([yes; using Lucid toolkit])
2907       USE_X_TOOLKIT=LUCID
2908       LUCID_LIBW=-lXaw
2909     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2910       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2911     else
2912       AC_MSG_ERROR([No X toolkit could be found.
2913 If you are sure you want Emacs compiled without an X toolkit, pass
2914   --with-x-toolkit=no
2915 to configure.  Otherwise, install the development libraries for the toolkit
2916 that you want to use (e.g. Gtk+) and re-run configure.])
2917     fi
2918   fi
2919 fi
2920
2921 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2922
2923 LIBXTR6=
2924 LIBXMU=
2925 if test "${USE_X_TOOLKIT}" != "none"; then
2926   AC_MSG_CHECKING(X11 toolkit version)
2927   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2928   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2929 [[#if XtSpecificationRelease < 6
2930 fail;
2931 #endif
2932 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2933   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2934   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2935     AC_MSG_RESULT(6 or newer)
2936     AC_DEFINE(HAVE_X11XTR6, 1,
2937               [Define to 1 if you have the X11R6 or newer version of Xt.])
2938     LIBXTR6="-lSM -lICE"
2939     case "$opsys" in
2940       ## Use libw.a along with X11R6 Xt.
2941       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2942     esac
2943   else
2944     AC_MSG_RESULT(before 6)
2945   fi
2946
2947 dnl If using toolkit, check whether libXmu.a exists.
2948 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2949   OLDLIBS="$LIBS"
2950   if test x$HAVE_X11XTR6 = xyes; then
2951     OTHERLIBS='-lXt -lSM -lICE'
2952   else
2953     OTHERLIBS='-lXt'
2954   fi
2955   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2956   if test "X$LIBS" != "X$OLDLIBS"; then
2957     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2958   fi
2959   LIBS=$OLDLIBS
2960   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2961 fi
2962 AC_SUBST(LIBXTR6)
2963 AC_SUBST(LIBXMU)
2964
2965 LIBXP=
2966 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2967   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2968   if test -d /usr/include/openmotif; then
2969     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2970     emacs_cv_openmotif=yes
2971     case "$canonical" in
2972       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2973       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2974       ;;
2975       *)
2976       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2977     esac
2978   else
2979     emacs_cv_openmotif=no
2980   fi
2981   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2982   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2983     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2984 int x = 5;
2985 #else
2986 Motif version prior to 2.1.
2987 #endif]])],
2988     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2989   if test $emacs_cv_motif_version_2_1 = yes; then
2990     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2991     if test x$emacs_cv_openmotif = xyes; then
2992       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2993     fi
2994   else
2995     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2996     # We put this in CFLAGS temporarily to precede other -I options
2997     # that might be in CFLAGS temporarily.
2998     # We put this in CPPFLAGS where it precedes the other -I options.
2999     OLD_CPPFLAGS=$CPPFLAGS
3000     OLD_CFLAGS=$CFLAGS
3001     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
3002     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
3003     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
3004       [[int x = 5;]])],
3005       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
3006     if test $emacs_cv_lesstif = yes; then
3007       # Make sure this -I option remains in CPPFLAGS after it is set
3008       # back to REAL_CPPFLAGS.
3009       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
3010       # have those other -I options anyway.  Ultimately, having this
3011       # directory ultimately in CPPFLAGS will be enough.
3012       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
3013       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
3014     else
3015       CFLAGS=$OLD_CFLAGS
3016       CPPFLAGS=$OLD_CPPFLAGS
3017     fi
3018   fi
3019   AC_CHECK_HEADER([Xm/BulletinB.h], [],
3020     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
3021 fi
3022
3023 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
3024 dnl using Motif or Xaw3d is available, and unless
3025 dnl --with-toolkit-scroll-bars=no was specified.
3026
3027 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
3028             [Define to 1 if we should use toolkit scroll bars.])dnl
3029 USE_TOOLKIT_SCROLL_BARS=no
3030 if test "${with_toolkit_scroll_bars}" != "no"; then
3031   if test "${USE_X_TOOLKIT}" != "none"; then
3032     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
3033       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3034       HAVE_XAW3D=no
3035       USE_TOOLKIT_SCROLL_BARS=yes
3036     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
3037       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3038       USE_TOOLKIT_SCROLL_BARS=yes
3039     fi
3040   elif test "${HAVE_GTK}" = "yes"; then
3041     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3042     USE_TOOLKIT_SCROLL_BARS=yes
3043   elif test "${HAVE_NS}" = "yes"; then
3044     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3045     USE_TOOLKIT_SCROLL_BARS=yes
3046   elif test "${HAVE_W32}" = "yes"; then
3047     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3048     USE_TOOLKIT_SCROLL_BARS=yes
3049   fi
3050 fi
3051
3052 dnl See if XIM is available.
3053 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3054           #include <X11/Xlib.h>
3055           #include <X11/Xresource.h>]],
3056          [[XIMProc  callback;]])],
3057          [HAVE_XIM=yes
3058          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
3059          HAVE_XIM=no)
3060
3061 dnl '--with-xim' now controls only the initial value of use_xim at run time.
3062
3063 if test "${with_xim}" != "no"; then
3064   AC_DEFINE(USE_XIM, 1,
3065             [Define to 1 if we should use XIM, if it is available.])
3066 fi
3067
3068
3069 if test "${HAVE_XIM}" != "no"; then
3070   late_CFLAGS=$CFLAGS
3071   if test "$GCC" = yes; then
3072     CFLAGS="$CFLAGS --pedantic-errors"
3073   fi
3074   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3075 #include <X11/Xlib.h>
3076 #include <X11/Xresource.h>]],
3077 [[Display *display;
3078 XrmDatabase db;
3079 char *res_name;
3080 char *res_class;
3081 XIMProc  callback;
3082 XPointer *client_data;
3083 #ifndef __GNUC__
3084 /* If we're not using GCC, it's probably not XFree86, and this is
3085    probably right, but we can't use something like --pedantic-errors.  */
3086 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
3087                                            char*, XIMProc, XPointer*);
3088 #endif
3089 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
3090    client_data);]])],
3091     [emacs_cv_arg6_star=yes])
3092   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
3093          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
3094 either XPointer or XPointer*.])dnl
3095   if test "$emacs_cv_arg6_star" = yes; then
3096     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
3097   else
3098     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
3099   fi
3100   CFLAGS=$late_CFLAGS
3101 fi
3102
3103 ### Start of font-backend (under any platform) section.
3104 # (nothing here yet -- this is a placeholder)
3105 ### End of font-backend (under any platform) section.
3106
3107 ### Start of font-backend (under X11) section.
3108 if test "${HAVE_X11}" = "yes"; then
3109     ## Use -lXft if available, unless '--with-xft=no'.
3110     HAVE_XFT=maybe
3111     if test "x${with_x}" = "xno"; then
3112       with_xft="no";
3113     fi
3114
3115     if test "$with_xft" != no; then
3116       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
3117       with_xft=$HAVE_FONTCONFIG
3118     fi
3119
3120     if test "x${with_xft}" != "xno"; then
3121
3122       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
3123       ## Because xftfont.c uses XRenderQueryExtension, we also
3124       ## need to link to -lXrender.
3125       HAVE_XRENDER=no
3126       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
3127       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
3128         OLD_CPPFLAGS="$CPPFLAGS"
3129         OLD_CFLAGS="$CFLAGS"
3130         OLD_LIBS="$LIBS"
3131         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
3132         CFLAGS="$CFLAGS $XFT_CFLAGS"
3133         XFT_LIBS="-lXrender $XFT_LIBS"
3134         LIBS="$XFT_LIBS $LIBS"
3135         AC_CHECK_HEADER(X11/Xft/Xft.h,
3136           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
3137           [[#include <X11/X.h>]])
3138
3139         if test "${HAVE_XFT}" = "yes"; then
3140           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
3141             AC_SUBST(XFT_LIBS)
3142           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
3143         fi                        # "${HAVE_XFT}" = "yes"
3144         CPPFLAGS=$OLD_CPPFLAGS
3145         CFLAGS=$OLD_CFLAGS
3146         LIBS=$OLD_LIBS
3147       fi                          # "$HAVE_XFT" != no
3148     fi                            # "x${with_xft}" != "xno"
3149
3150     ## We used to allow building with FreeType and without Xft.
3151     ## However, the ftx font backend driver is not in good shape.
3152     if test "$HAVE_XFT" != "yes"; then
3153        dnl For the "Does Emacs use" message at the end.
3154        HAVE_XFT=no
3155        HAVE_FREETYPE=no
3156     else
3157        dnl Strict linkers fail with
3158        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
3159        dnl if -lfreetype is not specified.
3160        dnl The following is needed to set FREETYPE_LIBS.
3161        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
3162
3163        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
3164     fi
3165
3166     HAVE_LIBOTF=no
3167     if test "${HAVE_FREETYPE}" = "yes"; then
3168       AC_DEFINE(HAVE_FREETYPE, 1,
3169                 [Define to 1 if using the freetype and fontconfig libraries.])
3170       if test "${with_libotf}" != "no"; then
3171         EMACS_CHECK_MODULES([LIBOTF], [libotf])
3172         if test "$HAVE_LIBOTF" = "yes"; then
3173           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
3174           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
3175                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
3176                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
3177           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
3178             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
3179                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
3180           fi
3181         fi
3182       fi
3183     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
3184     dnl Does the new font backend require it, or can it work without it?
3185     fi
3186
3187     HAVE_M17N_FLT=no
3188     if test "${HAVE_LIBOTF}" = yes; then
3189       if test "${with_m17n_flt}" != "no"; then
3190         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
3191         if test "$HAVE_M17N_FLT" = "yes"; then
3192           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
3193         fi
3194       fi
3195     fi
3196 else
3197     HAVE_XFT=no
3198     HAVE_FREETYPE=no
3199     HAVE_LIBOTF=no
3200     HAVE_M17N_FLT=no
3201 fi
3202
3203 ### End of font-backend (under X11) section.
3204
3205 AC_SUBST(FREETYPE_CFLAGS)
3206 AC_SUBST(FREETYPE_LIBS)
3207 AC_SUBST(FONTCONFIG_CFLAGS)
3208 AC_SUBST(FONTCONFIG_LIBS)
3209 AC_SUBST(LIBOTF_CFLAGS)
3210 AC_SUBST(LIBOTF_LIBS)
3211 AC_SUBST(M17N_FLT_CFLAGS)
3212 AC_SUBST(M17N_FLT_LIBS)
3213
3214 HAVE_CAIRO=no
3215 if test "${HAVE_X11}" = "yes"; then
3216   if test "${with_cairo}" != "no"; then
3217     CAIRO_REQUIRED=1.12.0
3218     CAIRO_MODULE="cairo >= $CAIRO_REQUIRED"
3219     EMACS_CHECK_MODULES(CAIRO, $CAIRO_MODULE)
3220     if test $HAVE_CAIRO = yes; then
3221       AC_DEFINE(USE_CAIRO, 1, [Define to 1 if using cairo.])
3222     else
3223       AC_MSG_ERROR([cairo requested but not found.])
3224     fi
3225
3226     CFLAGS="$CFLAGS $CAIRO_CFLAGS"
3227     LIBS="$LIBS $CAIRO_LIBS"
3228     AC_SUBST(CAIRO_CFLAGS)
3229     AC_SUBST(CAIRO_LIBS)
3230   fi
3231 fi
3232
3233 if test "${HAVE_X11}" = "yes"; then
3234   AC_CHECK_HEADER(X11/Xlib-xcb.h,
3235     AC_CHECK_LIB(xcb, xcb_translate_coordinates, HAVE_XCB=yes))
3236   if test "${HAVE_XCB}" = "yes"; then
3237     AC_CHECK_LIB(X11-xcb, XGetXCBConnection, HAVE_X11_XCB=yes)
3238     if test "${HAVE_X11_XCB}" = "yes"; then
3239       AC_DEFINE(USE_XCB, 1,
3240 [Define to 1 if you have the XCB library and X11-XCB library for mixed
3241    X11/XCB programming.])
3242       XCB_LIBS="-lX11-xcb -lxcb"
3243       AC_SUBST(XCB_LIBS)
3244     fi
3245   fi
3246 fi
3247
3248 ### Use -lXpm if available, unless '--with-xpm=no'.
3249 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
3250 ### In the Cygwin-w32 build, we need to use /usr/include/noX/X11/xpm.h
3251 ### rather than /usr/include/X11/xpm.h, so we set CPPFLAGS (and
3252 ### LDFLAGS) accordingly.
3253 HAVE_XPM=no
3254 LIBXPM=
3255 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3256   if test "${with_xpm}" != "no"; then
3257     SAVE_CPPFLAGS="$CPPFLAGS"
3258     SAVE_LDFLAGS="$LDFLAGS"
3259     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
3260     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3261     AC_CHECK_HEADER(X11/xpm.h,
3262       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3263     if test "${HAVE_XPM}" = "yes"; then
3264       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3265       AC_EGREP_CPP(no_return_alloc_pixels,
3266       [#include "X11/xpm.h"
3267 #ifndef XpmReturnAllocPixels
3268 no_return_alloc_pixels
3269 #endif
3270       ], HAVE_XPM=no, HAVE_XPM=yes)
3271
3272       if test "${HAVE_XPM}" = "yes"; then
3273         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3274         AC_MSG_RESULT(yes)
3275       else
3276         AC_MSG_RESULT(no)
3277         CPPFLAGS="$SAVE_CPPFLAGS"
3278         LDFLAGS="$SAVE_LDFLAGS"
3279       fi
3280     fi
3281   fi
3282
3283   if test "${HAVE_XPM}" = "yes"; then
3284     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3285     LIBXPM=-lXpm
3286   fi
3287 fi
3288
3289 if test "${HAVE_X11}" = "yes"; then
3290   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3291   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3292
3293   if test "${with_xpm}" != "no"; then
3294     AC_CHECK_HEADER(X11/xpm.h,
3295       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3296     if test "${HAVE_XPM}" = "yes"; then
3297       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3298       AC_EGREP_CPP(no_return_alloc_pixels,
3299       [#include "X11/xpm.h"
3300 #ifndef XpmReturnAllocPixels
3301 no_return_alloc_pixels
3302 #endif
3303       ], HAVE_XPM=no, HAVE_XPM=yes)
3304
3305       if test "${HAVE_XPM}" = "yes"; then
3306         AC_MSG_RESULT(yes)
3307       else
3308         AC_MSG_RESULT(no)
3309       fi
3310     fi
3311   fi
3312
3313   if test "${HAVE_XPM}" = "yes"; then
3314     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3315     LIBXPM=-lXpm
3316   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3317     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3318     LIBXPM=-lXpm
3319   fi
3320 fi
3321
3322 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3323 ### slightly different requirements wrt image libraries (it doesn't
3324 ### use -lXpm because it loads the xpm shared library dynamically at
3325 ### run time).
3326 if test "${opsys}" = "mingw32"; then
3327   if test "${with_xpm}" != "no"; then
3328     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3329 #define FOR_MSW 1])
3330   fi
3331
3332   if test "${HAVE_XPM}" = "yes"; then
3333     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3334   fi
3335 fi
3336
3337 AC_SUBST(LIBXPM)
3338
3339 ### Use -ljpeg if available, unless '--with-jpeg=no'.
3340 HAVE_JPEG=no
3341 LIBJPEG=
3342 if test "${with_jpeg}" != "no"; then
3343   AC_CACHE_CHECK([for jpeglib 6b or later],
3344     [emacs_cv_jpeglib],
3345     [OLD_LIBS=$LIBS
3346      for emacs_cv_jpeglib in yes -ljpeg no; do
3347        case $emacs_cv_jpeglib in
3348          yes) ;;
3349          no) break;;
3350          *) LIBS="$LIBS $emacs_cv_jpeglib";;
3351        esac
3352        AC_LINK_IFELSE(
3353          [AC_LANG_PROGRAM(
3354             [[#undef HAVE_STDLIB_H /* Avoid config.h/jpeglib.h collision.  */
3355               #include <stdio.h> /* jpeglib.h needs FILE and size_t.  */
3356               #include <jpeglib.h>
3357               #include <jerror.h>
3358               char verify[JPEG_LIB_VERSION < 62 ? -1 : 1];
3359               struct jpeg_decompress_struct cinfo;
3360             ]],
3361             [[
3362               jpeg_create_decompress (&cinfo);
3363               WARNMS (&cinfo, JWRN_JPEG_EOF);
3364               jpeg_destroy_decompress (&cinfo);
3365             ]])],
3366          [emacs_link_ok=yes],
3367          [emacs_link_ok=no])
3368        LIBS=$OLD_LIBS
3369        test $emacs_link_ok = yes && break
3370      done])
3371   if test "$emacs_cv_jpeglib" != no; then
3372     HAVE_JPEG=yes
3373     AC_DEFINE([HAVE_JPEG], 1,
3374       [Define to 1 if you have the jpeg library (typically -ljpeg).])
3375     ### mingw32 doesn't use -ljpeg, since it loads the library
3376     ### dynamically when needed, and doesn't want a run-time
3377     ### dependency on the jpeglib DLL.
3378     test "$emacs_cv_jpeglib" != yes && test "${opsys}" != "mingw32" \
3379     && LIBJPEG=$emacs_cv_jpeglib
3380   fi
3381 fi
3382 AC_SUBST(LIBJPEG)
3383
3384 HAVE_ZLIB=no
3385 LIBZ=
3386 if test "${with_zlib}" != "no"; then
3387   OLIBS=$LIBS
3388   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3389   LIBS=$OLIBS
3390   case $ac_cv_search_inflateEnd in
3391     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3392   esac
3393 fi
3394 if test "${HAVE_ZLIB}" = "yes"; then
3395   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3396   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3397   if test "${opsys}" = "mingw32"; then
3398      LIBZ=
3399   fi
3400 fi
3401 AC_SUBST(LIBZ)
3402
3403 ### Dynamic modules support
3404 LIBMODULES=
3405 HAVE_MODULES=no
3406 MODULES_OBJ=
3407 MODULES_SUFFIX=
3408 if test "${with_modules}" != "no"; then
3409   case $opsys in
3410     gnu|gnu-linux)
3411       LIBMODULES="-ldl"
3412       MODULES_SUFFIX=".so"
3413       HAVE_MODULES=yes
3414       ;;
3415     cygwin|mingw32)
3416       MODULES_SUFFIX=".dll"
3417       HAVE_MODULES=yes
3418       ;;
3419     darwin)
3420       MODULES_SUFFIX=".so"
3421       HAVE_MODULES=yes
3422       ;;
3423     *)
3424       # BSD systems have dlopen in libc.
3425       AC_CHECK_FUNC([dlopen],
3426         [MODULES_SUFFIX=".so"
3427          HAVE_MODULES=yes])
3428       ;;
3429   esac
3430
3431   if test "${HAVE_MODULES}" = no; then
3432     AC_MSG_ERROR([Dynamic modules are not supported on your system])
3433   else
3434     SAVE_LIBS=$LIBS
3435     LIBS="$LIBS $LIBMODULES"
3436     AC_CHECK_FUNCS([dladdr dlfunc])
3437     LIBS=$SAVE_LIBS
3438   fi
3439 fi
3440
3441 if test "${HAVE_MODULES}" = yes; then
3442    MODULES_OBJ="dynlib.o emacs-module.o"
3443    AC_DEFINE(HAVE_MODULES, 1, [Define to 1 if dynamic modules are enabled])
3444    AC_DEFINE_UNQUOTED(MODULES_SUFFIX, "$MODULES_SUFFIX",
3445      [System extension for dynamic libraries])
3446 fi
3447 AC_SUBST(MODULES_OBJ)
3448 AC_SUBST(LIBMODULES)
3449
3450 ### Use -lpng if available, unless '--with-png=no'.
3451 HAVE_PNG=no
3452 LIBPNG=
3453 PNG_CFLAGS=
3454 if test "${NS_IMPL_COCOA}" = yes; then
3455   : # Nothing to do
3456 elif test "${with_png}" != no; then
3457   # mingw32 loads the library dynamically.
3458   if test "$opsys" = mingw32; then
3459     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3460   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3461     AC_MSG_CHECKING([for png])
3462     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3463     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3464       # libpng-config does not work; configure by hand.
3465       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3466       # in /usr/include/libpng.
3467       if test -r /usr/include/libpng/png.h &&
3468          test ! -r /usr/include/png.h; then
3469         png_cflags=-I/usr/include/libpng
3470       else
3471         png_cflags=
3472       fi
3473       png_libs='-lpng'
3474     }
3475     SAVE_CFLAGS=$CFLAGS
3476     SAVE_LIBS=$LIBS
3477     CFLAGS="$CFLAGS $png_cflags"
3478     LIBS="$png_libs -lz -lm $LIBS"
3479     AC_LINK_IFELSE(
3480       [AC_LANG_PROGRAM([[#include <png.h>]],
3481          [[return !png_get_channels (0, 0);]])],
3482       [HAVE_PNG=yes
3483        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3484        LIBPNG=$png_libs
3485        # $LIBPNG requires explicit -lz in some cases.
3486        # We don't know what those cases are, exactly, so play it safe and
3487        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3488        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3489          LIBPNG="$LIBPNG -lz"
3490        fi])
3491     CFLAGS=$SAVE_CFLAGS
3492     LIBS=$SAVE_LIBS
3493     AC_MSG_RESULT([$HAVE_PNG])
3494   fi
3495 fi
3496 if test $HAVE_PNG = yes; then
3497   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3498
3499   SAVE_CFLAGS=$CFLAGS
3500   CFLAGS="$CFLAGS $PNG_CFLAGS"
3501   AC_CHECK_DECL([png_longjmp],
3502     [],
3503     [AC_DEFINE([PNG_DEPSTRUCT], [],
3504        [Define to empty to suppress deprecation warnings when building
3505         with --enable-gcc-warnings and with libpng versions before 1.5,
3506         which lack png_longjmp.])],
3507     [[#include <png.h>
3508     ]])
3509   CFLAGS=$SAVE_CFLAGS
3510 fi
3511 AC_SUBST(LIBPNG)
3512 AC_SUBST(PNG_CFLAGS)
3513
3514 ### Use -ltiff if available, unless '--with-tiff=no'.
3515 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3516 HAVE_TIFF=no
3517 LIBTIFF=
3518 if test "${opsys}" = "mingw32"; then
3519   if test "${with_tiff}" != "no"; then
3520     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3521   fi
3522   if test "${HAVE_TIFF}" = "yes"; then
3523     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3524   fi
3525 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3526   if test "${with_tiff}" != "no"; then
3527     AC_CHECK_HEADER(tiffio.h,
3528       [tifflibs="-lz -lm"
3529       # At least one tiff package requires the jpeg library.
3530       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3531       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3532   fi
3533
3534   if test "${HAVE_TIFF}" = "yes"; then
3535     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3536     dnl FIXME -lz -lm, as per libpng?
3537     LIBTIFF=-ltiff
3538   fi
3539 fi
3540 AC_SUBST(LIBTIFF)
3541
3542 ### Use -lgif or -lungif if available, unless '--with-gif=no'.
3543 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3544 HAVE_GIF=no
3545 LIBGIF=
3546 if test "${opsys}" = "mingw32"; then
3547   if test "${with_gif}" != "no"; then
3548     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3549   fi
3550   if test "${HAVE_GIF}" = "yes"; then
3551     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3552   fi
3553 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3554         || test "${HAVE_W32}" = "yes"; then
3555   AC_CHECK_HEADER(gif_lib.h,
3556 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3557 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3558     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3559         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3560
3561   if test "$HAVE_GIF" = yes; then
3562     LIBGIF=-lgif
3563   elif test "$HAVE_GIF" = maybe; then
3564 # If gif_lib.h but no libgif, try libungif.
3565     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3566     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3567   fi
3568
3569   if test "${HAVE_GIF}" = "yes"; then
3570     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3571   fi
3572 fi
3573 AC_SUBST(LIBGIF)
3574
3575 dnl Check for required libraries.
3576 if test "${HAVE_X11}" = "yes"; then
3577   MISSING=""
3578   WITH_NO=""
3579   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3580     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3581   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3582     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3583   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3584     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3585   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3586     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3587   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3588     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3589
3590   if test "X${MISSING}" != X; then
3591     AC_MSG_ERROR([The following required libraries were not found:
3592     $MISSING
3593 Maybe some development libraries/packages are missing?
3594 If you don't want to link with them give
3595     $WITH_NO
3596 as options to configure])
3597   fi
3598 fi
3599
3600 ### Use -lgpm if available, unless '--with-gpm=no'.
3601 HAVE_GPM=no
3602 LIBGPM=
3603 if test "${with_gpm}" != "no"; then
3604   AC_CHECK_HEADER(gpm.h,
3605     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3606
3607   if test "${HAVE_GPM}" = "yes"; then
3608     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3609     LIBGPM=-lgpm
3610   fi
3611 fi
3612 AC_SUBST(LIBGPM)
3613
3614 dnl Check for malloc/malloc.h on darwin
3615 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3616
3617 GNUSTEP_CFLAGS=
3618 ### Use NeXTstep API to implement GUI.
3619 if test "${HAVE_NS}" = "yes"; then
3620   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3621   if test "${NS_IMPL_COCOA}" = "yes"; then
3622     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3623   fi
3624   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3625     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3626     if test $NS_GNUSTEP_CONFIG != yes; then
3627       # See also .m.o rule in src/Makefile.in.  */
3628       # FIXME: are all these flags really needed?  Document here why.  */
3629       GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3630       ## Extra CFLAGS applied to src/*.m files.
3631       GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3632     fi
3633   fi
3634   OTHER_FILES=ns-app
3635 fi
3636
3637 ### Use session management (-lSM -lICE) if available
3638 HAVE_X_SM=no
3639 LIBXSM=
3640 if test "${HAVE_X11}" = "yes"; then
3641   AC_CHECK_HEADER(X11/SM/SMlib.h,
3642     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3643
3644   if test "${HAVE_X_SM}" = "yes"; then
3645     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3646     LIBXSM="-lSM -lICE"
3647   fi
3648 fi
3649 AC_SUBST(LIBXSM)
3650
3651 ### Use XRandr (-lXrandr) if available
3652 HAVE_XRANDR=no
3653 if test "${HAVE_X11}" = "yes"; then
3654   XRANDR_REQUIRED=1.2.2
3655   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3656   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3657   if test $HAVE_XRANDR = no; then
3658     # Test old way in case pkg-config doesn't have it (older machines).
3659     # Include Xrender.h by hand to work around bug in older Xrandr.h
3660     # (e.g. RHEL5) and silence (harmless) configure warning (bug#18465).
3661     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3662       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)],
3663       [], [AC_INCLUDES_DEFAULT
3664 #include <X11/extensions/Xrender.h>])
3665     if test $HAVE_XRANDR = yes; then
3666       XRANDR_LIBS=-lXrandr
3667     fi
3668   fi
3669   if test $HAVE_XRANDR = yes; then
3670     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3671   fi
3672 fi
3673 AC_SUBST(XRANDR_CFLAGS)
3674 AC_SUBST(XRANDR_LIBS)
3675
3676 ### Use Xinerama (-lXinerama) if available
3677 HAVE_XINERAMA=no
3678 if test "${HAVE_X11}" = "yes"; then
3679   XINERAMA_REQUIRED=1.0.2
3680   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3681   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3682   if test $HAVE_XINERAMA = no; then
3683     # Test old way in case pkg-config doesn't have it (older machines).
3684     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3685       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3686     if test $HAVE_XINERAMA = yes; then
3687       XINERAMA_LIBS=-lXinerama
3688     fi
3689   fi
3690   if test $HAVE_XINERAMA = yes; then
3691     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3692   fi
3693 fi
3694 AC_SUBST(XINERAMA_CFLAGS)
3695 AC_SUBST(XINERAMA_LIBS)
3696
3697 ### Use Xfixes (-lXfixes) if available
3698 HAVE_XFIXES=no
3699 if test "${HAVE_X11}" = "yes"; then
3700   XFIXES_REQUIRED=4.0.0
3701   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3702   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3703   if test $HAVE_XFIXES = no; then
3704     # Test old way in case pkg-config doesn't have it (older machines).
3705     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3706       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3707     if test $HAVE_XFIXES = yes; then
3708       XFIXES_LIBS=-lXfixes
3709     fi
3710   fi
3711   if test $HAVE_XFIXES = yes; then
3712     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3713   fi
3714 fi
3715 AC_SUBST(XFIXES_CFLAGS)
3716 AC_SUBST(XFIXES_LIBS)
3717
3718 ### Use libxml (-lxml2) if available
3719 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3720 HAVE_LIBXML2=no
3721 if test "${with_xml2}" != "no"; then
3722   ### I'm not sure what the version number should be, so I just guessed.
3723   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3724   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3725   if test "${HAVE_LIBXML2}" != "yes" && test "$opsys" = "darwin"; then
3726     SAVE_CPPFLAGS="$CPPFLAGS"
3727     if test -z "$xcsdkdir" -a -n "$XCRUN" -a ! -d /usr/include; then
3728       dnl /usr/include is not found.  Try Xcode SDK dir if it is sane.
3729       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
3730       case $xcsdkdir in
3731         *[[\\\"\#\$\&\'\`$am_lf\ \      ]]*)
3732         xcsdkdir="" ;;
3733       esac
3734     fi
3735     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3736     AC_CHECK_HEADER(libxml/HTMLparser.h,
3737       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3738                      [#include <libxml/HTMLparser.h>])])
3739     CPPFLAGS="$SAVE_CPPFLAGS"
3740     if test "${HAVE_LIBXML2}" = "yes"; then
3741       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3742       LIBXML2_LIBS="-lxml2"
3743     fi
3744   fi
3745   if test "${HAVE_LIBXML2}" = "yes"; then
3746     if test "${opsys}" != "mingw32"; then
3747       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no,
3748         [$LIBXML2_LIBS])
3749     else
3750       LIBXML2_LIBS=""
3751     fi
3752     if test "${HAVE_LIBXML2}" = "yes"; then
3753       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3754     else
3755       LIBXML2_LIBS=""
3756       LIBXML2_CFLAGS=""
3757     fi
3758   fi
3759 fi
3760 AC_SUBST(LIBXML2_LIBS)
3761 AC_SUBST(LIBXML2_CFLAGS)
3762
3763 # Check for mail-locking functions in a "mail" library.  Probably this should
3764 # have the same check as for liblockfile below.
3765 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3766 if test $have_mail = yes; then
3767   LIBS_MAIL=-lmail
3768   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the 'mail' library (-lmail).])
3769
3770   OLD_LIBS=$LIBS
3771   LIBS="$LIBS_MAIL $LIBS"
3772   AC_CHECK_FUNCS(touchlock)
3773   LIBS=$OLD_LIBS
3774 else
3775   LIBS_MAIL=
3776 fi
3777 dnl Debian, at least:
3778 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3779 if test $have_lockfile = yes; then
3780    LIBS_MAIL=-llockfile
3781    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the 'lockfile' library (-llockfile).])
3782 else
3783 # If we have the shared liblockfile, assume we must use it for mail
3784 # locking (e.g. Debian).  If we couldn't link against liblockfile
3785 # (no liblockfile.a installed), ensure that we don't need to.
3786   dnl This works for files generally, not just executables.
3787   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3788   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3789                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3790   if test $ac_cv_prog_liblockfile = yes; then
3791     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3792 This probably means that movemail could lose mail.
3793 There may be a 'development' package to install containing liblockfile.])
3794   fi
3795 fi
3796 AC_CHECK_HEADERS_ONCE(maillock.h)
3797 AC_SUBST(LIBS_MAIL)
3798
3799 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3800 ## interlock access to the mail spool.  The alternative is a lock file named
3801 ## /usr/spool/mail/$USER.lock.
3802 mail_lock=no
3803 case "$opsys" in
3804   aix4-2) mail_lock="lockf" ;;
3805
3806   gnu|freebsd|dragonfly|netbsd|openbsd|darwin) mail_lock="flock" ;;
3807
3808   ## On GNU/Linux systems, both methods are used by various mail programs.
3809   ## I assume most people are using newer mailers that have heard of flock.
3810   ## Change this if you need to.
3811   ## Debian contains a patch which says: "On Debian/GNU/Linux systems,
3812   ## configure gets the right answers, and that means *NOT* using flock.
3813   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3814   ## for details." and then uses '#ifdef DEBIAN'.  Unfortunately the
3815   ## Debian maintainer hasn't provided a clean fix for Emacs.
3816   ## movemail.c will use 'maillock' when MAILDIR, HAVE_LIBMAIL and
3817   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3818   ## correct logic.  -- fx
3819   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3820   ## liblockfile is a Free Software replacement for libmail, used on
3821   ## Debian systems and elsewhere. -rfr.
3822   gnu-*)
3823     mail_lock="flock"
3824     if test $have_mail = yes || test $have_lockfile = yes; then
3825       test $ac_cv_header_maillock_h = yes && mail_lock=no
3826     fi
3827     ;;
3828
3829   mingw32)
3830     mail_lock="none-needed" ;;
3831 esac
3832
3833 BLESSMAIL_TARGET=
3834 case "$mail_lock" in
3835   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3836
3837   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3838
3839   none-needed) ;;
3840
3841   *) BLESSMAIL_TARGET="need-blessmail" ;;
3842 esac
3843 AC_SUBST(BLESSMAIL_TARGET)
3844
3845 OLD_LIBS=$LIBS
3846 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3847 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3848 getrusage get_current_dir_name \
3849 lrand48 random rint \
3850 select getpagesize setlocale newlocale \
3851 getrlimit setrlimit shutdown \
3852 pthread_sigmask strsignal setitimer \
3853 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3854 gai_strerror sync \
3855 getpwent endpwent getgrent endgrent \
3856 cfmakeraw cfsetspeed copysign __executable_start log2)
3857 LIBS=$OLD_LIBS
3858
3859 dnl No need to check for posix_memalign if aligned_alloc works.
3860 AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3861 AC_CHECK_DECLS([aligned_alloc], [], [], [[#include <stdlib.h>]])
3862
3863 dnl Cannot use AC_CHECK_FUNCS
3864 AC_CACHE_CHECK([for __builtin_unwind_init],
3865                emacs_cv_func___builtin_unwind_init,
3866 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3867                 emacs_cv_func___builtin_unwind_init=yes,
3868                 emacs_cv_func___builtin_unwind_init=no)])
3869 if test $emacs_cv_func___builtin_unwind_init = yes; then
3870   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3871             [Define to 1 if you have the '__builtin_unwind_init' function.])
3872 fi
3873
3874 AC_CHECK_HEADERS_ONCE(sys/un.h)
3875
3876 AC_FUNC_FSEEKO
3877
3878 # UNIX98 PTYs.
3879 AC_CHECK_FUNCS(grantpt)
3880
3881 # PTY-related GNU extensions.
3882 AC_CHECK_FUNCS(getpt posix_openpt)
3883
3884 # Check this now, so that we will NOT find the above functions in ncurses.
3885 # That is because we have not set up to link ncurses in lib-src.
3886 # It's better to believe a function is not available
3887 # than to expect to find it in ncurses.
3888 # Also we need tputs and friends to be able to build at all.
3889 AC_MSG_CHECKING([for library containing tputs])
3890 # Run a test program that contains a call to tputs, a call that is
3891 # never executed.  This tests whether a pre-'main' dynamic linker
3892 # works with the library.  It's too much trouble to actually call
3893 # tputs in the test program, due to portability hassles.  When
3894 # cross-compiling, assume the test program will run if it links.
3895 AC_DEFUN([tputs_link_source], [
3896   AC_LANG_SOURCE(
3897      [[extern void tputs (const char *, int, int (*)(int));
3898        int main (int argc, char **argv)
3899        {
3900           if (argc == 10000)
3901             tputs (argv[0], 0, 0);
3902           return 0;
3903        }]])
3904 ])
3905 if test "${opsys}" = "mingw32"; then
3906   msg='none required'
3907 else
3908   # Maybe curses should be tried earlier?
3909   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3910   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3911     OLIBS=$LIBS
3912     if test -z "$tputs_library"; then
3913       LIBS_TERMCAP=
3914       msg='none required'
3915     else
3916       LIBS_TERMCAP=-l$tputs_library
3917       msg=$LIBS_TERMCAP
3918       LIBS="$LIBS_TERMCAP $LIBS"
3919     fi
3920     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3921       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3922     LIBS=$OLIBS
3923     if test "X$msg" != Xno; then
3924       break
3925     fi
3926   done
3927 fi
3928 AC_MSG_RESULT([$msg])
3929 if test "X$msg" = Xno; then
3930   AC_MSG_ERROR([The required function 'tputs' was not found in any library.
3931 The following libraries were tried (in order):
3932   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3933 Please try installing whichever of these libraries is most appropriate
3934 for your system, together with its header files.
3935 For example, a libncurses-dev(el) or similar package.])
3936 fi
3937
3938 ## Use termcap instead of terminfo?
3939 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3940 TERMINFO=yes
3941 ## FIXME?  In the cases below where we unconditionally set
3942 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3943 ## if that was found above to have tputs.
3944 ## Should we use the gnu* logic everywhere?
3945 case "$opsys" in
3946   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3947   ##  The ncurses library has been moved out of the System framework in
3948   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3949   ##  option to use it.
3950   darwin) LIBS_TERMCAP="-lncurses" ;;
3951
3952   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3953
3954   freebsd)
3955     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3956     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3957     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3958 [[#if __FreeBSD_version < 400000
3959 fail;
3960 #endif
3961 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3962
3963     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3964
3965     if test $emacs_cv_freebsd_terminfo = yes; then
3966       LIBS_TERMCAP="-lncurses"
3967     else
3968       TERMINFO=no
3969       LIBS_TERMCAP="-ltermcap"
3970     fi
3971     ;;
3972
3973   mingw32)
3974     TERMINFO=no
3975     LIBS_TERMCAP=
3976     ;;
3977
3978   netbsd)
3979     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3980       TERMINFO=no
3981       LIBS_TERMCAP="-ltermcap"
3982     fi
3983     ;;
3984
3985   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3986
3987   ## hpux: Make sure we get select from libc rather than from libcurses
3988   ##  because libcurses on HPUX 10.10 has a broken version of select.
3989   ##  We used to use -lc -lcurses, but this may be cleaner.
3990   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3991   # set that way, now it uses the default).  Isn't this a contradiction?
3992   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3993
3994 esac
3995
3996 TERMCAP_OBJ=tparam.o
3997 if test $TERMINFO = yes; then
3998   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3999   TERMCAP_OBJ=terminfo.o
4000 fi
4001 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
4002   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
4003 fi
4004 AC_SUBST(LIBS_TERMCAP)
4005 AC_SUBST(TERMCAP_OBJ)
4006
4007 # GNU/Linux-specific timer functions.
4008 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
4009   [AC_COMPILE_IFELSE(
4010      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
4011                       ]],
4012                       [[timerfd_create (CLOCK_REALTIME,
4013                                         TFD_CLOEXEC | TFD_NONBLOCK);
4014                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
4015      [emacs_cv_have_timerfd=yes],
4016      [emacs_cv_have_timerfd=no])])
4017 if test "$emacs_cv_have_timerfd" = yes; then
4018   AC_DEFINE([HAVE_TIMERFD], 1,
4019     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
4020 fi
4021
4022 # Alternate stack for signal handlers.
4023 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
4024                [emacs_cv_alternate_stack],
4025   [AC_COMPILE_IFELSE(
4026      [AC_LANG_PROGRAM([[#include <signal.h>
4027                       ]],
4028                       [[stack_t ss;
4029                         struct sigaction sa;
4030                         ss.ss_sp = malloc (SIGSTKSZ);
4031                         ss.ss_size = SIGSTKSZ;
4032                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
4033                         sigaltstack (&ss, 0);
4034                         sigaction (SIGSEGV, &sa, 0);]])],
4035      [emacs_cv_alternate_stack=yes],
4036      [emacs_cv_alternate_stack=no])])
4037
4038 # Do we need the Hesiod library to provide the support routines?
4039 dnl FIXME?  Should we be skipping this on Darwin too?
4040 LIBHESIOD=
4041 LIBRESOLV=
4042 if test "$with_hesiod" != no ; then
4043   # Don't set $LIBS here -- see comments above.  FIXME which comments?
4044   resolv=no
4045   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
4046      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
4047                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
4048   if test "$resolv" = yes ; then
4049     RESOLVLIB=-lresolv
4050   else
4051     RESOLVLIB=
4052   fi
4053   hesiod=no
4054   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
4055         hesiod=yes, :, $RESOLVLIB)])
4056
4057   if test x"$hesiod" = xyes; then
4058     LIBHESIOD=-lhesiod
4059     LIBRESOLV=$RESOLVLIB
4060   fi
4061 fi
4062 AC_SUBST(LIBHESIOD)
4063 AC_SUBST(LIBRESOLV)
4064
4065 # These tell us which Kerberos-related libraries to use.
4066 COM_ERRLIB=
4067 CRYPTOLIB=
4068 KRB5LIB=
4069 DESLIB=
4070 KRB4LIB=
4071
4072 if test "${with_kerberos}" != no; then
4073   OLD_LIBS=$LIBS
4074   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
4075   if test $have_com_err = yes; then
4076     COM_ERRLIB=-lcom_err
4077     LIBS="$COM_ERRLIB $LIBS"
4078   fi
4079   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
4080   if test $have_crypto = yes; then
4081     CRYPTOLIB=-lcrypto
4082     LIBS="$CRYPTOLIB $LIBS"
4083   fi
4084   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
4085   if test $have_k5crypto = yes; then
4086     CRYPTOLIB=-lk5crypto
4087     LIBS="$CRYPTOLIB $LIBS"
4088   fi
4089   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
4090   if test $have_krb5=yes; then
4091     KRB5LIB=-lkrb5
4092     LIBS="$KRB5LIB $LIBS"
4093   fi
4094   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
4095   if test "${with_kerberos5}" = no; then
4096     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
4097     if test $have_des425 = yes; then
4098       DESLIB=-ldes425
4099       LIBS="$DESLIB $LIBS"
4100     else
4101       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
4102       if test $have_des = yes; then
4103         DESLIB=-ldes
4104         LIBS="$DESLIB $LIBS"
4105       fi
4106     fi
4107     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
4108     if test $have_krb4 = yes; then
4109       KRB4LIB=-lkrb4
4110       LIBS="$KRB4LIB $LIBS"
4111     else
4112       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
4113       if test $have_krb = yes; then
4114         KRB4LIB=-lkrb
4115         LIBS="$KRB4LIB $LIBS"
4116       fi
4117     fi
4118   fi
4119
4120   if test "${with_kerberos5}" != no; then
4121     AC_CHECK_HEADERS(krb5.h,
4122       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
4123                         [#include <krb5.h>])])
4124   else
4125     AC_CHECK_HEADERS(krb.h,,
4126                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
4127                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
4128   fi
4129   AC_CHECK_HEADERS(com_err.h)
4130   LIBS=$OLD_LIBS
4131 fi
4132
4133 AC_SUBST(COM_ERRLIB)
4134 AC_SUBST(CRYPTOLIB)
4135 AC_SUBST(KRB5LIB)
4136 AC_SUBST(DESLIB)
4137 AC_SUBST(KRB4LIB)
4138
4139 AC_CHECK_HEADERS(valgrind/valgrind.h)
4140
4141 AC_CHECK_MEMBERS([struct unipair.unicode], [], [], [[#include <linux/kd.h>]])
4142
4143 AC_CHECK_FUNCS_ONCE(tzset)
4144
4145 ok_so_far=yes
4146 AC_CHECK_FUNC(socket, , ok_so_far=no)
4147 if test $ok_so_far = yes; then
4148   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
4149 fi
4150 if test $ok_so_far = yes; then
4151   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
4152 fi
4153 if test $ok_so_far = yes; then
4154 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
4155   AC_DEFINE(HAVE_INET_SOCKETS, 1,
4156             [Define to 1 if you have inet sockets.])
4157 fi
4158
4159 AC_FUNC_FORK
4160
4161 AC_CHECK_FUNCS(snprintf)
4162
4163 dnl Check for glib.  This differs from other library checks in that
4164 dnl Emacs need not link to glib unless some other library is already
4165 dnl linking to glib.  Although glib provides no facilities that Emacs
4166 dnl needs for its own purposes, when glib is present Emacs needs to
4167 dnl use primitives like g_main_context_query to avoid clashing with
4168 dnl glib at a low level.
4169 dnl
4170 dnl Check this late, since it depends on $GTK_CFLAGS etc.
4171 XGSELOBJ=
4172 OLDCFLAGS="$CFLAGS"
4173 OLDLIBS="$LIBS"
4174 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
4175 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
4176 CFLAGS="$CFLAGS $NOTIFY_CFLAGS $CAIRO_CFLAGS"
4177 LIBS="$LIBS $NOTIFY_LIBS $CAIRO_LIBS"
4178 AC_MSG_CHECKING([whether GLib is linked in])
4179 AC_LINK_IFELSE([AC_LANG_PROGRAM(
4180         [[#include <glib.h>
4181         ]],
4182         [[g_print ("Hello world");]])],
4183      [links_glib=yes],
4184      [links_glib=no])
4185 AC_MSG_RESULT([$links_glib])
4186 if test "${links_glib}" = "yes"; then
4187   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
4188   if test "$HAVE_NS" = no;then
4189     XGSELOBJ=xgselect.o
4190   fi
4191 fi
4192 CFLAGS="$OLDCFLAGS"
4193 LIBS="$OLDLIBS"
4194 AC_SUBST(XGSELOBJ)
4195
4196 dnl Adapted from Haible's version.
4197 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
4198   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
4199     [[char* cs = nl_langinfo(CODESET);]])],
4200     emacs_cv_langinfo_codeset=yes,
4201     emacs_cv_langinfo_codeset=no)
4202   ])
4203 if test $emacs_cv_langinfo_codeset = yes; then
4204   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
4205     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
4206 fi
4207
4208 AC_TYPE_MBSTATE_T
4209
4210 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
4211 dnl how the tty code is related to POSIX and/or other versions of termios.
4212 dnl The following looks like a useful start.
4213 dnl
4214 dnl AC_SYS_POSIX_TERMIOS
4215 dnl if test $ac_cv_sys_posix_termios = yes; then
4216 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
4217 dnl                                and macros for terminal control.])
4218 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
4219 dnl fi
4220
4221 dnl Turned on June 1996 supposing nobody will mind it.
4222 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
4223 if test "${opsys}" != "mingw32"; then
4224    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
4225      in the full name stands for the login id.])
4226 fi
4227
4228 dnl Everybody supports this, except MS.
4229 dnl Seems like the kind of thing we should be testing for, though.
4230 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4231 if test "${opsys}" != "mingw32"; then
4232   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4233 fi
4234
4235 dnl Everybody supports this, except MS-DOS.
4236 dnl Seems like the kind of thing we should be testing for, though.
4237 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4238 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4239   4.2-compatible sockets.])
4240
4241 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4242
4243 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4244   a null file, or a data sink.])
4245 if test "${opsys}" = "mingw32"; then
4246   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4247 else
4248   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4249 fi
4250
4251 if test "${opsys}" = "mingw32"; then
4252   SEPCHAR=';'
4253 else
4254   SEPCHAR=':'
4255 fi
4256 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4257 dnl This is for MinGW, and is used in test/Makefile.in.
4258 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4259 dnl decides that a command-line argument to be passed to a MinGW program
4260 dnl is a PATH-style list of directories.  But that heuristics plays it
4261 dnl safe, and only does the replacement when it is _absolutely_ sure it
4262 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4263 dnl which breaks in-tree builds.  So we do this manually instead.
4264 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4265 dnl be computed as ':' in MSYS Bash.
4266 AC_SUBST(SEPCHAR)
4267
4268 dnl Everybody supports this, except MS-DOS.
4269 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4270
4271 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4272
4273
4274 AC_DEFINE(DIRECTORY_SEP, ['/'],
4275   [Character that separates directories in a file name.])
4276
4277 if test "${opsys}" = "mingw32"; then
4278   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4279     [Returns true if character is a device separator.])
4280
4281   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4282     [Returns true if character is a directory separator.])
4283
4284   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4285     [Returns true if character is any form of separator.])
4286 else
4287   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4288     [Returns true if character is a device separator.])
4289
4290   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4291     [Returns true if character is a directory separator.])
4292
4293   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4294     [Returns true if character is any form of separator.])
4295 fi
4296
4297 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4298
4299 case $opsys in
4300   aix4-2)
4301     dnl Unfortunately without libXmu we cannot support EditRes.
4302     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4303       AC_DEFINE(NO_EDITRES, 1)
4304     fi
4305     ;;
4306
4307   hpux*)
4308     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4309     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4310     AC_DEFINE(NO_EDITRES, 1)
4311     ;;
4312 esac
4313
4314
4315 case $opsys in
4316   sol2* | unixware )
4317     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4318     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4319     dnl need the constant to dimension an array.  So wire in the appropriate
4320     dnl value here.
4321     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4322     ;;
4323 esac
4324
4325 emacs_broken_SIGIO=no
4326
4327 case $opsys in
4328   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4329   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4330   hpux* | nacl | openbsd | sol2* | unixware )
4331     emacs_broken_SIGIO=yes
4332     ;;
4333
4334   aix4-2)
4335     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4336     dnl the way this system works, libc functions that return malloced
4337     dnl memory use the libc malloc implementation. Calling xfree or
4338     dnl xrealloc on the results of such functions results in a crash.
4339     dnl
4340     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4341     dnl but that does not currently work on this system.
4342     dnl
4343     dnl It is possible to completely override the malloc implementation on
4344     dnl AIX, but that involves putting the malloc functions in a shared
4345     dnl library and setting the MALLOCTYPE environment variable to point to
4346     dnl that shared library.
4347     dnl
4348     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4349     dnl to avoid a crash just use the Emacs implementation for that function.
4350     dnl
4351     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4352     dnl of this file, so that we do not check for get_current_dir_name
4353     dnl on AIX.  But that might be fragile if something else ends
4354     dnl up testing for get_current_dir_name as a dependency.
4355     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4356       get_current_dir_name should not be used.])
4357     ;;
4358
4359   freebsd)
4360     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4361     dnl writes/reads on a PTY, read(2) returns bogus data:
4362     dnl
4363     dnl write(2)  1022 bytes
4364     dnl write(2)   954 bytes, get EAGAIN
4365     dnl read(2)   1024 bytes in process_read_output
4366     dnl read(2)     11 bytes in process_read_output
4367     dnl
4368     dnl That is, read(2) returns more bytes than have ever been written
4369     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4370     dnl successfully after processing (for example with CRs added if the
4371     dnl terminal is set up that way which it is here).  The same bytes will
4372     dnl be seen again in a later read(2), without the CRs.
4373     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4374       work around an issue when reading from a PTY.])
4375     ;;
4376 esac
4377
4378 case $opsys in
4379   gnu-* | sol2-10 )
4380     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4381     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4382   ;;
4383 esac
4384
4385 case $opsys in
4386   darwin | dragonfly | freebsd | netbsd | openbsd )
4387     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4388       close a pty to make it a controlling terminal (it is already a
4389       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4390   ;;
4391 esac
4392
4393 dnl FIXME Surely we can test for this rather than hard-code it.
4394 case $opsys in
4395   netbsd | openbsd) sound_device="/dev/audio" ;;
4396   *) sound_device="/dev/dsp" ;;
4397 esac
4398
4399 dnl Used in sound.c
4400 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4401   [Name of the default sound device.])
4402
4403
4404 dnl Emacs can read input using SIGIO and buffering characters itself,
4405 dnl or using CBREAK mode and making C-g cause SIGINT.
4406 dnl The choice is controlled by the variable interrupt_input.
4407 dnl
4408 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4409 dnl
4410 dnl Emacs uses the presence of the USABLE_SIGIO macro
4411 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4412 dnl INTERRUPT_INPUT to decide whether to use it by default.
4413 dnl
4414 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4415 dnl CBREAK mode has two disadvantages
4416 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4417 dnl I hear that in system V this problem does not exist.
4418 dnl 2) Control-G causes output to be discarded.
4419 dnl I do not know whether this can be fixed in system V.
4420 dnl
4421 dnl Another method of doing input is planned but not implemented.
4422 dnl It would have Emacs fork off a separate process
4423 dnl to read the input and send it to the true Emacs process
4424 dnl through a pipe.
4425 case $opsys in
4426   darwin | gnu-linux | gnu-kfreebsd )
4427     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4428   ;;
4429 esac
4430
4431
4432 dnl If the system's imake configuration file defines 'NeedWidePrototypes'
4433 dnl as 'NO', we must define NARROWPROTO manually.  Such a define is
4434 dnl generated in the Makefile generated by 'xmkmf'.  If we don't define
4435 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4436 dnl taking float or double parameters.
4437 case $opsys in
4438   cygwin|gnu|gnu-linux|gnu-kfreebsd|freebsd|netbsd|openbsd)
4439     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4440       file defines 'NeedWidePrototypes' as 'NO'.])
4441   ;;
4442 esac
4443
4444
4445 dnl Used in process.c, this must be a loop, even if it only runs once.
4446 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4447 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4448 dnl trying suffixes 0-16.
4449 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4450   first PTY, if PTYs are supported.])
4451 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4452 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4453   end of a PTY, if non-standard.])
4454 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4455   end of a PTY, if non-standard.])
4456
4457 case $opsys in
4458   aix4-2 )
4459     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4460     dnl You allocate a pty by opening /dev/ptc to get the master side.
4461     dnl To get the name of the slave side, you just ttyname() the master side.
4462     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4463     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4464     ;;
4465
4466   cygwin )
4467     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4468     dnl multi-line AC_DEFINEs are hard. :(
4469     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4470     AC_DEFINE(PTY_NAME_SPRINTF, [])
4471     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4472     ;;
4473
4474   gnu | openbsd )
4475     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4476     ;;
4477
4478   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd | darwin | nacl )
4479     dnl if HAVE_GRANTPT
4480     if test "x$ac_cv_func_grantpt" = xyes; then
4481       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4482       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4483       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4484       dnl to prevent sigchld_handler from intercepting the child's death.
4485       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4486       dnl if HAVE_POSIX_OPENPT
4487       if test "x$ac_cv_func_posix_openpt" = xyes; then
4488         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4489         AC_DEFINE(PTY_NAME_SPRINTF, [])
4490       dnl if HAVE_GETPT
4491       elif test "x$ac_cv_func_getpt" = xyes; then
4492         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4493         AC_DEFINE(PTY_NAME_SPRINTF, [])
4494       else
4495         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4496       fi
4497     else
4498       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4499     fi
4500     ;;
4501
4502   hpux*)
4503     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4504     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4505     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4506     ;;
4507
4508   sol2* )
4509     dnl On SysVr4, grantpt(3) forks a subprocess, so do not use
4510     dnl O_CLOEXEC when opening the pty, and keep the SIGCHLD handler
4511     dnl from intercepting that death.  If any child but grantpt's should die
4512     dnl within, it should be caught after sigrelse(2).
4513     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4514     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4515     ;;
4516
4517   unixware )
4518     dnl Comments are as per sol2*.
4519     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4520     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4521     ;;
4522 esac
4523
4524
4525 case $opsys in
4526   sol2* | unixware )
4527     dnl This change means that we don't loop through allocate_pty too
4528     dnl many times in the (rare) event of a failure.
4529     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4530     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4531     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4532     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (forkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (forkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (forkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4533     ;;
4534 esac
4535
4536
4537 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4538 "typing" a signal character on the pty.])
4539
4540 case $opsys in
4541   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4542   aix4-2 | cygwin | gnu | dragonfly | freebsd | netbsd | openbsd | darwin )
4543     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4544     ;;
4545
4546   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4547   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4548   gnu-linux | gnu-kfreebsd )
4549
4550     AC_MSG_CHECKING([for signals via characters])
4551     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4552 #include <linux/version.h>
4553 #if LINUX_VERSION_CODE < 0x20400
4554 # error "Linux version too old"
4555 #endif
4556       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4557
4558     AC_MSG_RESULT([$emacs_signals_via_chars])
4559     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4560     ;;
4561 esac
4562
4563
4564 AH_TEMPLATE(TAB3, [Undocumented.])
4565
4566 case $opsys in
4567   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4568
4569   gnu | dragonfly | freebsd | netbsd | openbsd )
4570     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4571     AC_DEFINE(TAB3, OXTABS)
4572     ;;
4573
4574   gnu-linux | gnu-kfreebsd )
4575     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4576 #ifndef __ia64__
4577 # error "not ia64"
4578 #endif
4579       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4580         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4581         [Mark a secondary stack, like the register stack on the ia64.]), [])
4582     ;;
4583
4584   hpux*)
4585     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4586       run_time_remap; for HPUX.])
4587     ;;
4588 esac
4589
4590
4591 dnl This won't be used automatically yet.  We also need to know, at least,
4592 dnl that the stack is continuous.
4593 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4594   registers relevant for conservative garbage collection in the jmp_buf.])
4595
4596
4597 case $opsys in
4598   dnl Not all the architectures are tested, but there are Debian packages
4599   dnl for SCM and/or Guile on them, so the technique must work.  See also
4600   dnl comments in alloc.c concerning setjmp and gcc.
4601   dnl Fixme: it's probably safe to just use the GCC conditional below.
4602   gnu-linux | gnu-kfreebsd )
4603     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4604 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4605   || defined __alpha__ || defined __mips__ || defined __s390__ \
4606   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4607   || defined __ia64__ || defined __sh__
4608 /* ok */
4609 #else
4610 # error "setjmp not known to work on this arch"
4611 #endif
4612     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4613     ;;
4614 esac
4615
4616
4617 if test x$GCC = xyes; then
4618    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4619    AC_DEFINE(GC_SETJMP_WORKS, 1)
4620 else
4621   case $opsys in
4622     aix* | dragonfly | freebsd | netbsd | openbsd | sol2* )
4623       AC_DEFINE(GC_SETJMP_WORKS, 1)
4624       ;;
4625   esac
4626 fi                              dnl GCC?
4627
4628 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4629 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4630   [AC_LINK_IFELSE(
4631      [AC_LANG_PROGRAM(
4632        [[#include <setjmp.h>
4633          #ifdef __MINGW32__
4634          # define _longjmp longjmp
4635          #endif
4636        ]],
4637        [[jmp_buf j;
4638          if (! _setjmp (j))
4639            _longjmp (j, 1);]])],
4640      [emacs_cv_func__setjmp=yes],
4641      [emacs_cv_func__setjmp=no])])
4642 if test $emacs_cv_func__setjmp = yes; then
4643   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4644 fi
4645
4646 # We need to preserve signal mask to handle C stack overflows.
4647 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4648   [AC_LINK_IFELSE(
4649      [AC_LANG_PROGRAM(
4650        [[#include <setjmp.h>
4651        ]],
4652        [[sigjmp_buf j;
4653          if (! sigsetjmp (j, 1))
4654            siglongjmp (j, 1);]])],
4655      [emacs_cv_func_sigsetjmp=yes],
4656      [emacs_cv_func_sigsetjmp=no])])
4657 if test $emacs_cv_func_sigsetjmp = yes; then
4658   AC_DEFINE([HAVE_SIGSETJMP], 1,
4659     [Define to 1 if sigsetjmp and siglongjmp work.])
4660 fi
4661
4662 case $emacs_cv_func_sigsetjmp,$emacs_cv_alternate_stack,$opsys in
4663   yes,yes,* | *,*,mingw32)
4664     AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4665       [Define to 1 if C stack overflow can be handled in some cases.]);;
4666 esac
4667
4668 case $opsys in
4669   sol2* | unixware )
4670     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4671     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4672     dnl and this is all we need.
4673     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4674     ;;
4675 esac
4676
4677
4678 case $opsys in
4679   hpux* | sol2* )
4680     dnl Used in xfaces.c.
4681     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4682       some systems, where it requires time.h.])
4683     ;;
4684 esac
4685
4686
4687 dnl Define symbols to identify the version of Unix this is.
4688 dnl Define all the symbols that apply correctly.
4689 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4690 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4691 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4692 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4693
4694 case $opsys in
4695   aix4-2)
4696     AC_DEFINE(USG, [])
4697     dnl This symbol should be defined on AIX Version 3  ???????
4698     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4699 #ifndef _AIX
4700 # error "_AIX not defined"
4701 #endif
4702     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4703     ;;
4704
4705   cygwin)
4706     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4707     ;;
4708
4709   darwin)
4710     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4711     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4712     dnl distinguish OS X from pure Darwin.
4713     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4714     ;;
4715
4716   gnu-linux | gnu-kfreebsd )
4717     AC_DEFINE(USG, [])
4718     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4719     ;;
4720
4721   hpux*)
4722     AC_DEFINE(USG, [])
4723     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4724     ;;
4725
4726   mingw32)
4727     AC_DEFINE(DOS_NT, [])
4728     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4729     if test "x$ac_enable_checking" != "x" ; then
4730       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4731     fi
4732     ;;
4733
4734   sol2*)
4735     AC_DEFINE(USG, [])
4736     AC_DEFINE(USG5_4, [])
4737     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4738     ;;
4739
4740   unixware)
4741     AC_DEFINE(USG, [])
4742     AC_DEFINE(USG5_4, [])
4743     ;;
4744 esac
4745
4746 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4747   [case $opsys in
4748      aix4-2 | nacl)
4749        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4750        emacs_cv_usable_FIONREAD=no
4751        ;;
4752
4753      mingw32)
4754        emacs_cv_usable_FIONREAD=yes
4755        ;;
4756
4757      *)
4758        AC_COMPILE_IFELSE(
4759          [AC_LANG_PROGRAM([[#include <sys/types.h>
4760                             #include <sys/ioctl.h>
4761                             #ifdef USG5_4
4762                             # include <sys/filio.h>
4763                             #endif
4764                           ]],
4765                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4766          [emacs_cv_usable_FIONREAD=yes],
4767          [emacs_cv_usable_FIONREAD=no])
4768        ;;
4769    esac])
4770 if test $emacs_cv_usable_FIONREAD = yes; then
4771   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4772
4773   if test $emacs_broken_SIGIO = no; then
4774     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4775       [AC_COMPILE_IFELSE(
4776          [AC_LANG_PROGRAM([[#include <fcntl.h>
4777                             #include <signal.h>
4778                           ]],
4779                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4780          [emacs_cv_usable_SIGIO=yes],
4781          [emacs_cv_usable_SIGIO=no])],
4782       [emacs_cv_usable_SIGIO=yes],
4783       [emacs_cv_usable_SIGIO=no])
4784     if test $emacs_cv_usable_SIGIO = yes; then
4785       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4786     fi
4787   fi
4788 fi
4789
4790 case $opsys in
4791   hpux11)
4792     dnl It works to open the pty's tty in the parent (Emacs), then
4793     dnl close and reopen it in the child.
4794     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4795       works to open a pty's tty in the parent process, then close and
4796       reopen it in the child.])
4797     ;;
4798
4799   sol2-10)
4800     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4801       on Solaris.])
4802     ;;
4803 esac
4804
4805 # Set up the CFLAGS for real compilation, so we can substitute it.
4806 CFLAGS="$REAL_CFLAGS"
4807 CPPFLAGS="$REAL_CPPFLAGS"
4808 LIBS="$REAL_LIBS"
4809
4810 ## Hack to detect a buggy GCC version.
4811 if test "$GCC" = yes && \
4812    $CC --version 2> /dev/null | grep 'gcc.* 4.5.0' >/dev/null; then
4813   case $CFLAGS in
4814     *-fno-optimize-sibling-calls*) ;;
4815     *-O@<:@23@:>@*)
4816       AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS.]);;
4817   esac
4818 fi
4819
4820 version=$PACKAGE_VERSION
4821
4822 copyright="Copyright (C) 2016 Free Software Foundation, Inc."
4823 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4824   [Short copyright string for this version of Emacs.])
4825 AC_SUBST(copyright)
4826
4827 ### Specify what sort of things we'll be editing into Makefile and config.h.
4828 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4829 AC_SUBST(version)
4830 AC_SUBST(configuration)
4831 ## Unused?
4832 AC_SUBST(canonical)
4833 AC_SUBST(srcdir)
4834 AC_SUBST(prefix)
4835 AC_SUBST(exec_prefix)
4836 AC_SUBST(bindir)
4837 AC_SUBST(datadir)
4838 AC_SUBST(sharedstatedir)
4839 AC_SUBST(libexecdir)
4840 AC_SUBST(mandir)
4841 AC_SUBST(infodir)
4842 AC_SUBST(lispdir)
4843 AC_SUBST(standardlisppath)
4844 AC_SUBST(locallisppath)
4845 AC_SUBST(lisppath)
4846 AC_SUBST(x_default_search_path)
4847 AC_SUBST(etcdir)
4848 AC_SUBST(archlibdir)
4849 AC_SUBST(etcdocdir)
4850 AC_SUBST(bitmapdir)
4851 AC_SUBST(gamedir)
4852 AC_SUBST(gameuser)
4853 AC_SUBST(gamegroup)
4854 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4855 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4856 ## end of LIBX_BASE, but nothing ever set it.
4857 AC_SUBST(LD_SWITCH_X_SITE)
4858 AC_SUBST(C_SWITCH_X_SITE)
4859 AC_SUBST(GNUSTEP_CFLAGS)
4860 AC_SUBST(CFLAGS)
4861 ## Used in lwlib/Makefile.in.
4862 AC_SUBST(X_TOOLKIT_TYPE)
4863 AC_SUBST(ns_appdir)
4864 AC_SUBST(ns_appbindir)
4865 AC_SUBST(ns_appresdir)
4866 AC_SUBST(ns_appsrc)
4867 AC_SUBST(GNU_OBJC_CFLAGS)
4868 AC_SUBST(OTHER_FILES)
4869
4870 if test -n "${term_header}"; then
4871     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4872         [Define to the header for the built-in window system.])
4873 fi
4874
4875 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4876                    [Define to the canonical Emacs configuration name.])
4877 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4878                    [Define to the options passed to configure.])
4879 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4880   define this to include extra configuration information.])
4881
4882 case $opsys in
4883   mingw32)
4884     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4885     ;;
4886 esac
4887
4888 XMENU_OBJ=
4889 XOBJ=
4890 FONT_OBJ=
4891 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4892   AC_DEFINE(HAVE_X_WINDOWS, 1,
4893             [Define to 1 if you want to use the X window system.])
4894   XMENU_OBJ=xmenu.o
4895   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4896   FONT_OBJ=xfont.o
4897   if test "$HAVE_CAIRO" = "yes"; then
4898     FONT_OBJ="ftfont.o ftcrfont.o"
4899   elif test "$HAVE_XFT" = "yes"; then
4900     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4901   elif test "$HAVE_FREETYPE" = "yes"; then
4902     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4903   fi
4904   AC_SUBST(FONT_OBJ)
4905 fi
4906 AC_SUBST(XMENU_OBJ)
4907 AC_SUBST(XOBJ)
4908 AC_SUBST(FONT_OBJ)
4909
4910 WIDGET_OBJ=
4911 MOTIF_LIBW=
4912 if test "${USE_X_TOOLKIT}" != "none" ; then
4913   WIDGET_OBJ=widget.o
4914   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4915   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4916     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4917   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4918     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4919     MOTIF_LIBW=-lXm
4920     case "$opsys" in
4921       gnu-linux)
4922         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4923         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4924         ;;
4925
4926       unixware)
4927         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4928         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4929         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4930         ;;
4931
4932       aix4-2)
4933         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4934         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4935         ;;
4936     esac
4937     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4938   fi
4939 fi
4940 AC_SUBST(WIDGET_OBJ)
4941
4942 TOOLKIT_LIBW=
4943 case "$USE_X_TOOLKIT" in
4944   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4945   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4946   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4947 esac
4948 if test "$HAVE_XWIDGETS" = "yes"; then
4949   TOOLKIT_LIBW="$TOOLKIT_LIBW -lXcomposite"
4950 fi
4951 AC_SUBST(TOOLKIT_LIBW)
4952
4953 if test "${opsys}" != "mingw32"; then
4954   if test "$USE_X_TOOLKIT" = "none"; then
4955     LIBXT_OTHER="\$(LIBXSM)"
4956   else
4957     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4958   fi
4959 fi
4960 AC_SUBST(LIBXT_OTHER)
4961
4962 if test "${HAVE_X11}" = "yes" ; then
4963   AC_DEFINE(HAVE_X11, 1,
4964             [Define to 1 if you want to use version 11 of X windows.])
4965   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4966 else
4967   LIBX_OTHER=
4968 fi
4969 AC_SUBST(LIBX_OTHER)
4970
4971 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4972   LIBXMENU=
4973 elif test "$USE_X_TOOLKIT" = none; then
4974   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4975 else
4976   LIBXMENU='$(lwlibdir)/liblw.a'
4977 fi
4978 AC_SUBST(LIBXMENU)
4979
4980 AC_CACHE_CHECK([for struct alignment],
4981   [emacs_cv_struct_alignment],
4982   [AC_COMPILE_IFELSE(
4983      [AC_LANG_PROGRAM([[#include <stddef.h>
4984                         struct __attribute__ ((aligned (8))) s { char c; };
4985                         struct t { char c; struct s s; };
4986                         char verify[offsetof (struct t, s) == 8 ? 1 : -1];
4987                       ]])],
4988      [emacs_cv_struct_alignment=yes],
4989      [emacs_cv_struct_alignment=no])])
4990 if test "$emacs_cv_struct_alignment" = yes; then
4991   AC_DEFINE([HAVE_STRUCT_ATTRIBUTE_ALIGNED], 1,
4992     [Define to 1 if 'struct __attribute__ ((aligned (N)))' aligns the
4993      structure to an N-byte boundary.])
4994 fi
4995
4996 if test "${GNU_MALLOC}" = "yes" ; then
4997   AC_DEFINE(GNU_MALLOC, 1,
4998             [Define to 1 if you want to use the GNU memory allocator.])
4999 fi
5000
5001 RALLOC_OBJ=
5002 if test "${REL_ALLOC}" = "yes" ; then
5003   AC_DEFINE(REL_ALLOC, 1,
5004             [Define REL_ALLOC if you want to use the relocating allocator for
5005              buffer space.])
5006
5007   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
5008 fi
5009 AC_SUBST(RALLOC_OBJ)
5010
5011 if test "$opsys" = "cygwin"; then
5012   CYGWIN_OBJ="cygw32.o"
5013   ## Cygwin differs because of its unexec().
5014   PRE_ALLOC_OBJ=
5015   POST_ALLOC_OBJ=lastfile.o
5016 elif test "$opsys" = "mingw32"; then
5017   CYGWIN_OBJ=
5018   PRE_ALLOC_OBJ=
5019   POST_ALLOC_OBJ=lastfile.o
5020 else
5021   CYGWIN_OBJ=
5022   PRE_ALLOC_OBJ=lastfile.o
5023   POST_ALLOC_OBJ=
5024 fi
5025 AC_SUBST(CYGWIN_OBJ)
5026 AC_SUBST(PRE_ALLOC_OBJ)
5027 AC_SUBST(POST_ALLOC_OBJ)
5028
5029 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
5030 dnl verbatim defined above.  The tricky name is apropos, as this hack
5031 dnl makes Fortify go sour!
5032 AH_VERBATIM([FORTIFY_SOUR],
5033 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
5034    The workaround disables some useful run-time checking, so it
5035    should be conditional to the platforms with the performance bug.
5036    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
5037 #if defined __APPLE__ && defined __GNUC__
5038 # ifndef _DONT_USE_CTYPE_INLINE_
5039 #  define _DONT_USE_CTYPE_INLINE_
5040 # endif
5041 # ifndef _FORTIFY_SOURCE
5042 #  define _FORTIFY_SOURCE 0
5043 # endif
5044 #endif
5045 ])
5046
5047 # If user asks to omit features, disable optional features that gnulib
5048 # might otherwise enable.
5049 if test "$with_features" = no && test "$enable_acl" != yes; then
5050   enable_acl=no
5051 fi
5052
5053 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
5054 # it temporarily reverts them to their pre-pkg-config values,
5055 # because gnulib needs to work with both src (which uses the
5056 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
5057 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
5058 # and it therefore needs to run in an environment where LIBS does not
5059 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
5060 # for some package unrelated to lib-src.
5061 SAVE_CFLAGS=$CFLAGS
5062 SAVE_LIBS=$LIBS
5063 CFLAGS=$pre_PKG_CONFIG_CFLAGS
5064 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
5065 gl_ASSERT_NO_GNULIB_POSIXCHECK
5066 gl_ASSERT_NO_GNULIB_TESTS
5067 gl_INIT
5068 CFLAGS=$SAVE_CFLAGS
5069 LIBS=$SAVE_LIBS
5070
5071 if test "${opsys}" = "mingw32"; then
5072   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
5073   # Remove unneeded switches from the value of CC that goes to Makefiles
5074   CC=`AS_ECHO(["$CC"]) | sed -e "s,$GCC_TEST_OPTIONS,,"`
5075 fi
5076
5077 case "$opsys" in
5078   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
5079
5080   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
5081
5082   darwin)
5083    ## The -headerpad option tells ld (see man page) to leave room at the
5084    ## end of the header for adding load commands.  Needed for dumping.
5085    ## 0x1000 is enough for roughly 52 load commands on the x86_64
5086    ## architecture (where they are 78 bytes each). The actual number of
5087    ## load commands added is not consistent but normally ranges from
5088    ## about 14 to about 34. Setting it high gets us plenty of slop and
5089    ## only costs about 1.5K of wasted binary space.
5090    headerpad_extra=1000
5091    if test "$HAVE_NS" = "yes"; then
5092      libs_nsgui="-framework AppKit"
5093      if test "$NS_IMPL_COCOA" = "yes"; then
5094         libs_nsgui="$libs_nsgui -framework IOKit"
5095      fi
5096    else
5097      libs_nsgui=
5098    fi
5099    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
5100
5101    ## This is here because src/Makefile.in did some extra fiddling around
5102    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
5103    ## LD_SWITCH_SYSTEM_TEMACS instead,
5104    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
5105      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
5106    ;;
5107
5108   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
5109   ## find X at run-time.
5110   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
5111   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
5112   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
5113   ## had different values in configure (in ac_link) and src/Makefile.in.
5114   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
5115   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
5116
5117   mingw32)
5118    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
5119    case "$canonical" in
5120      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5121      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5122    esac
5123    ;;
5124
5125   *) LD_SWITCH_SYSTEM_TEMACS= ;;
5126 esac
5127
5128 # -nopie fixes a temacs segfault on Gentoo, OpenBSD, and other systems
5129 # with "hardened" GCC configurations for some reason (Bug#18784).
5130 # We don't know why -nopie works, but not segfaulting is better than
5131 # segfaulting.  Use ac_c_werror_flag=yes when trying -nopie, otherwise
5132 # clang keeps warning that it does not understand -nopie, and pre-4.6
5133 # GCC has a similar problem (Bug#20338).
5134 AC_CACHE_CHECK([whether $CC accepts -nopie],
5135   [emacs_cv_prog_cc_nopie],
5136   [emacs_save_c_werror_flag=$ac_c_werror_flag
5137    emacs_save_LDFLAGS=$LDFLAGS
5138    ac_c_werror_flag=yes
5139    LDFLAGS="$LDFLAGS -nopie"
5140    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
5141      [emacs_cv_prog_cc_nopie=yes],
5142      [emacs_cv_prog_cc_nopie=no])
5143    ac_c_werror_flag=$emacs_save_c_werror_flag
5144    LDFLAGS=$emacs_save_LDFLAGS])
5145 if test "$emacs_cv_prog_cc_nopie" = yes; then
5146   LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -nopie"
5147 fi
5148
5149 if test x$ac_enable_profiling != x ; then
5150   case $opsys in
5151     *freebsd | gnu-linux) ;;
5152     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
5153   esac
5154 fi
5155
5156 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
5157
5158 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
5159
5160 ## Common for all window systems
5161 if test "$window_system" != "none"; then
5162   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
5163   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
5164   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
5165 fi
5166
5167 AC_SUBST(WINDOW_SYSTEM_OBJ)
5168
5169 AH_TOP([/* GNU Emacs site configuration template file.
5170
5171 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2016
5172   Free Software Foundation, Inc.
5173
5174 This file is part of GNU Emacs.
5175
5176 GNU Emacs is free software: you can redistribute it and/or modify
5177 it under the terms of the GNU General Public License as published by
5178 the Free Software Foundation, either version 3 of the License, or (at
5179 your option) any later version.
5180
5181 GNU Emacs is distributed in the hope that it will be useful,
5182 but WITHOUT ANY WARRANTY; without even the implied warranty of
5183 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
5184 GNU General Public License for more details.
5185
5186 You should have received a copy of the GNU General Public License
5187 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
5188
5189
5190 /* No code in Emacs #includes config.h twice, but some bits of code
5191    intended to work with other packages as well (like gmalloc.c)
5192    think they can include it as many times as they like.  */
5193 #ifndef EMACS_CONFIG_H
5194 #define EMACS_CONFIG_H
5195 ])dnl
5196
5197 AH_BOTTOM([#include <conf_post.h>
5198
5199 #endif /* EMACS_CONFIG_H */
5200
5201 /*
5202 Local Variables:
5203 mode: c
5204 End:
5205 */
5206 ])dnl
5207
5208 #### Report on what we decided to do.
5209 #### Report GTK as a toolkit, even if it doesn't use Xt.
5210 #### It makes printing result more understandable as using GTK sets
5211 #### toolkit_scroll_bars to yes by default.
5212 if test "${HAVE_GTK}" = "yes"; then
5213   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5214 fi
5215
5216 if test $USE_ACL -ne 0; then
5217   ACL_SUMMARY="yes $LIB_ACL"
5218 else
5219   ACL_SUMMARY=no
5220 fi
5221
5222 emacs_standard_dirs='Standard dirs'
5223 AS_ECHO(["
5224 Configured for '${canonical}'.
5225
5226   Where should the build process find the source code?    ${srcdir}
5227   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5228   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5229   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5230   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5231   What window system should Emacs use?                    ${window_system}
5232   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}
5233   Where do we find X Windows header files?                ${x_includes:-$emacs_standard_dirs}
5234   Where do we find X Windows libraries?                   ${x_libraries:-$emacs_standard_dirs}"])
5235
5236 optsep=
5237 emacs_config_features=
5238 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG CAIRO IMAGEMAGICK SOUND GPM DBUS \
5239   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5240   LIBOTF XFT ZLIB TOOLKIT_SCROLL_BARS X_TOOLKIT X11 NS MODULES \
5241   XWIDGETS LIBSYSTEMD; do
5242
5243     case $opt in
5244       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5245       TOOLKIT_SCROLL_BARS|X_TOOLKIT) eval val=\${USE_$opt} ;;
5246       *) eval val=\${HAVE_$opt} ;;
5247     esac
5248     case x$val in
5249       xno|xnone|x) continue ;;
5250     esac
5251     case $opt in
5252       X_TOOLKIT)
5253         case $val in
5254           GTK*|LUCID|MOTIF) opt=$val ;;
5255           *) continue ;;
5256         esac
5257       ;;
5258     esac
5259     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5260     optsep=' '
5261 done
5262 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5263   [Summary of some of the main features enabled by configure.])
5264
5265 AS_ECHO(["  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}
5266   Does Emacs use -lXpm?                                   ${HAVE_XPM}
5267   Does Emacs use -ljpeg?                                  ${HAVE_JPEG}
5268   Does Emacs use -ltiff?                                  ${HAVE_TIFF}
5269   Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF
5270   Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG
5271   Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}
5272   Does Emacs use cairo?                                   ${HAVE_CAIRO}
5273   Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}
5274   Does Emacs support sound?                               ${HAVE_SOUND}
5275   Does Emacs use -lgpm?                                   ${HAVE_GPM}
5276   Does Emacs use -ldbus?                                  ${HAVE_DBUS}
5277   Does Emacs use -lgconf?                                 ${HAVE_GCONF}
5278   Does Emacs use GSettings?                               ${HAVE_GSETTINGS}
5279   Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}
5280   Does Emacs use access control lists?                    ${ACL_SUMMARY}
5281   Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}
5282   Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}
5283   Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}
5284   Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}
5285   Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}
5286   Does Emacs use -lotf?                                   ${HAVE_LIBOTF}
5287   Does Emacs use -lxft?                                   ${HAVE_XFT}
5288   Does Emacs use -lsystemd?                               ${HAVE_LIBSYSTEMD}
5289   Does Emacs directly use zlib?                           ${HAVE_ZLIB}
5290   Does Emacs have dynamic modules support?                ${HAVE_MODULES}
5291   Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}
5292   Does Emacs support Xwidgets (requires gtk3)?            ${HAVE_XWIDGETS}
5293 "])
5294
5295 if test -n "${EMACSDATA}"; then
5296    AS_ECHO(["  Environment variable EMACSDATA set to:                  $EMACSDATA"])
5297 fi
5298 if test -n "${EMACSDOC}"; then
5299    AS_ECHO(["  Environment variable EMACSDOC set to:                   $EMACSDOC"])
5300 fi
5301
5302 echo
5303
5304 if test "$HAVE_NS" = "yes"; then
5305    echo
5306    AS_ECHO(["You must run \"${MAKE-make} install\" in order to test the built application.
5307 The installed application will go to nextstep/Emacs.app and can be
5308 run or moved from there."])
5309    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5310       echo "The application will be fully self-contained."
5311     else
5312       AS_ECHO(["The lisp resources for the application will be installed under ${prefix}.
5313 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5314 to run if these resources are not installed."])
5315    fi
5316    echo
5317 fi
5318
5319 if test "${opsys}" = "cygwin"; then
5320   case `uname -r` in
5321     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5322            echo
5323            ;;
5324   esac
5325 fi
5326
5327 # Remove any trailing slashes in these variables.
5328 case $prefix in
5329   */) prefix=`AS_DIRNAME(["$prefix."])`;;
5330 esac
5331 case $exec_prefix in
5332   */) exec_prefix=`AS_DIRNAME(["$exec_prefix."])`;;
5333 esac
5334
5335 if test "$HAVE_NS" = "yes"; then
5336   if test "$NS_IMPL_GNUSTEP" = yes; then
5337     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5338       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5339     ns_check_file=Resources/Info-gnustep.plist
5340   else
5341     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5342       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5343     ns_check_file=Contents/Info.plist
5344   fi
5345   AC_SUBST(ns_check_file)
5346 fi
5347
5348 dnl config.status treats $srcdir specially, so I think this is ok...
5349 AC_CONFIG_FILES([$srcdir/doc/man/emacs.1])
5350
5351 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5352 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5353 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5354 dnl (else you get "no 'Makefile.am' found for any configure output").
5355 dnl This will work, but you get a config.status that is not quite right
5356 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5357 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5358 dnl it seems better to just live with the duplication.
5359 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5360
5361 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5362        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5363        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5364        leim/Makefile nextstep/Makefile nt/Makefile])
5365
5366 dnl test/ is not present in release tarfiles.
5367 opt_makefile=test/Makefile
5368
5369 if test -f "$srcdir/$opt_makefile.in"; then
5370   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5371   dnl Again, it's best not to use a variable.  Though you can add
5372   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5373   AC_CONFIG_FILES([test/Makefile])
5374 fi
5375
5376
5377 dnl The admin/ directory used to be excluded from tarfiles.
5378 if test -d $srcdir/admin; then
5379   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/charsets/Makefile admin/unidata/Makefile admin/grammars/Makefile"
5380   AC_CONFIG_FILES([admin/charsets/Makefile])
5381   AC_CONFIG_FILES([admin/unidata/Makefile])
5382   AC_CONFIG_FILES([admin/grammars/Makefile])
5383 fi                              dnl -d admin
5384
5385
5386 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5387
5388 AC_SUBST(SUBDIR_MAKEFILES_IN)
5389
5390 dnl You might wonder (I did) why epaths.h is generated by running make,
5391 dnl rather than just letting configure generate it from epaths.in.
5392 dnl One reason is that the various paths are not fully expanded (see above);
5393 dnl eg gamedir=${prefix}/var/games/emacs.
5394 dnl Secondly, the GNU Coding standards require that one should be able
5395 dnl to run 'make prefix=/some/where/else' and override the values set
5396 dnl by configure.  This also explains the 'move-if-change' test and
5397 dnl the use of force in the 'epaths-force' rule in Makefile.in.
5398 AC_CONFIG_COMMANDS([src/epaths.h], [
5399 if test "${opsys}" = "mingw32"; then
5400   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5401 else
5402   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5403 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5404 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5405
5406 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5407 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5408 dnl or a symlink?
5409 AC_CONFIG_COMMANDS([src/.gdbinit], [
5410 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5411   AS_ECHO(["source $ac_abs_top_srcdir/src/.gdbinit"]) > src/.gdbinit
5412 fi
5413 ])
5414
5415 dnl Perhaps this would be better named doc-emacs-emacsver.texi?
5416 dnl See comments for etc-refcards-emacsver.tex.
5417 dnl Since we get a doc/emacs directory generated anyway, for the Makefile,
5418 dnl it is not quite the same.  But we are generating in $srcdir.
5419 AC_CONFIG_COMMANDS([doc/emacs/emacsver.texi], [
5420 ${MAKE-make} -s --no-print-directory -C doc/emacs doc-emacsver || \
5421 AC_MSG_ERROR(['doc/emacs/emacsver.texi' could not be made.])
5422 ])
5423
5424 dnl If we give this the more natural name, etc/refcards/emacsver.texi,
5425 dnl then a directory etc/refcards is created in the build directory,
5426 dnl which is probably harmless, but confusing (in out-of-tree builds).
5427 dnl (If we were to generate etc/refcards/Makefile, this might change.)
5428 dnl It is really $srcdir/etc/refcards/emacsver.tex that we generate.
5429 AC_CONFIG_COMMANDS([etc-refcards-emacsver.tex], [
5430 ${MAKE-make} -s MAKEFILE_NAME=do-not-make-Makefile etc-emacsver || \
5431 AC_MSG_ERROR(['etc/refcards/emacsver.tex' could not be made.])
5432 ])
5433
5434 AC_OUTPUT
5435
5436 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])