code.delx.au - gnu-emacs/blob - lisp/find-dired.el

   1 ;;; find-dired.el --- run a `find' command and dired the output
   2
   3 ;; Copyright (C) 1992, 1994-1995, 2000-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Roland McGrath <roland@gnu.org>,
   6 ;;         Sebastian Kremer <sk@thp.uni-koeln.de>
   7 ;; Maintainer: FSF
   8 ;; Keywords: unix
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'dired)
  30
  31 (defgroup find-dired nil
  32   "Run a `find' command and dired the output."
  33   :group 'dired
  34   :prefix "find-")
  35
  36 ;; FIXME this option does not really belong in this file, it's more general.
  37 ;; Eg cf some tests in grep.el.
  38 (defcustom find-exec-terminator
  39   (if (eq 0
  40           (ignore-errors
  41             (process-file find-program nil nil nil
  42                           null-device "-exec" "echo" "{}" "+")))
  43       "+"
  44     (shell-quote-argument ";"))
  45   "String that terminates \"find -exec COMMAND {} \".
  46 The value should include any needed quoting for the shell.
  47 Common values are \"+\" and \"\\\\;\", with the former more efficient
  48 than the latter."
  49   :version "24.1"
  50   :group 'find-dired
  51   :type 'string)
  52
  53 ;; find's -ls corresponds to these switches.
  54 ;; Note -b, at least GNU find quotes spaces etc. in filenames
  55 (defcustom find-ls-option
  56   (if (eq 0
  57           (ignore-errors
  58             (process-file find-program nil nil nil null-device "-ls")))
  59       (cons "-ls"
  60             (if (eq system-type 'berkeley-unix)
  61                 "-gilsb"
  62               "-dilsb"))
  63     (cons
  64      (format "-exec ls -ld {} %s" find-exec-terminator)
  65      "-ld"))
  66   "Description of the option to `find' to produce an `ls -l'-type listing.
  67 This is a cons of two strings (FIND-OPTION . LS-SWITCHES).  FIND-OPTION
  68 gives the option (or options) to `find' that produce the desired output.
  69 LS-SWITCHES is a list of `ls' switches to tell dired how to parse the output."
  70   :version "24.1"              ; add tests for -ls and -exec + support
  71   :type '(cons (string :tag "Find Option")
  72                (string :tag "Ls Switches"))
  73   :group 'find-dired)
  74
  75 (defcustom find-ls-subdir-switches
  76   (if (string-match "-[a-z]*b" (cdr find-ls-option))
  77       "-alb"
  78     "-al")
  79   "`ls' switches for inserting subdirectories in `*Find*' buffers.
  80 This should contain the \"-l\" switch.
  81 Use the \"-F\" or \"-b\" switches if and only if you also use
  82 them for `find-ls-option'."
  83   :version "24.1"                       ; add -b test
  84   :type 'string
  85   :group 'find-dired)
  86
  87 (defcustom find-grep-options
  88   (if (or (eq system-type 'berkeley-unix)
  89           (string-match "solaris2" system-configuration)
  90           (string-match "irix" system-configuration))
  91       "-s" "-q")
  92   "Option to grep to be as silent as possible.
  93 On Berkeley systems, this is `-s'; on Posix, and with GNU grep, `-q' does it.
  94 On other systems, the closest you can come is to use `-l'."
  95   :type 'string
  96   :group 'find-dired)
  97
  98 ;; This used to be autoloaded (see bug#4387).
  99 (defcustom find-name-arg
 100   (if read-file-name-completion-ignore-case
 101       "-iname"
 102     "-name")
 103   "Argument used to specify file name pattern.
 104 If `read-file-name-completion-ignore-case' is non-nil, -iname is used so that
 105 find also ignores case.  Otherwise, -name is used."
 106   :type 'string
 107   :group 'find-dired
 108   :version "22.2")
 109
 110 (defvar find-args nil
 111   "Last arguments given to `find' by \\[find-dired].")
 112
 113 ;; History of find-args values entered in the minibuffer.
 114 (defvar find-args-history nil)
 115
 116 (defvar dired-sort-inhibit)
 117
 118 ;;;###autoload
 119 (defun find-dired (dir args)
 120   "Run `find' and go into Dired mode on a buffer of the output.
 121 The command run (after changing into DIR) is essentially
 122
 123     find . \\( ARGS \\) -ls
 124
 125 except that the car of the variable `find-ls-option' specifies what to
 126 use in place of \"-ls\" as the final argument."
 127   (interactive (list (read-directory-name "Run find in directory: " nil "" t)
 128                      (read-string "Run find (with args): " find-args
 129                                   '(find-args-history . 1))))
 130   (let ((dired-buffers dired-buffers))
 131     ;; Expand DIR ("" means default-directory), and make sure it has a
 132     ;; trailing slash.
 133     (setq dir (file-name-as-directory (expand-file-name dir)))
 134     ;; Check that it's really a directory.
 135     (or (file-directory-p dir)
 136         (error "find-dired needs a directory: %s" dir))
 137     (switch-to-buffer (get-buffer-create "*Find*"))
 138
 139     ;; See if there's still a `find' running, and offer to kill
 140     ;; it first, if it is.
 141     (let ((find (get-buffer-process (current-buffer))))
 142       (when find
 143         (if (or (not (eq (process-status find) 'run))
 144                 (yes-or-no-p "A `find' process is running; kill it? "))
 145             (condition-case nil
 146                 (progn
 147                   (interrupt-process find)
 148                   (sit-for 1)
 149                   (delete-process find))
 150               (error nil))
 151           (error "Cannot have two processes in `%s' at once" (buffer-name)))))
 152
 153     (widen)
 154     (kill-all-local-variables)
 155     (setq buffer-read-only nil)
 156     (erase-buffer)
 157     (setq default-directory dir
 158           find-args args              ; save for next interactive call
 159           args (concat find-program " . "
 160                        (if (string= args "")
 161                            ""
 162                          (concat
 163                           (shell-quote-argument "(")
 164                           " " args " "
 165                           (shell-quote-argument ")")
 166                           " "))
 167                        (if (string-match "\\`\\(.*\\) {} \\(\\\\;\\|+\\)\\'"
 168                                          (car find-ls-option))
 169                            (format "%s %s %s"
 170                                    (match-string 1 (car find-ls-option))
 171                                    (shell-quote-argument "{}")
 172                                    find-exec-terminator)
 173                          (car find-ls-option))))
 174     ;; Start the find process.
 175     (shell-command (concat args "&") (current-buffer))
 176     ;; The next statement will bomb in classic dired (no optional arg allowed)
 177     (dired-mode dir (cdr find-ls-option))
 178     (let ((map (make-sparse-keymap)))
 179       (set-keymap-parent map (current-local-map))
 180       (define-key map "\C-c\C-k" 'kill-find)
 181       (use-local-map map))
 182     (make-local-variable 'dired-sort-inhibit)
 183     (setq dired-sort-inhibit t)
 184     (set (make-local-variable 'revert-buffer-function)
 185          `(lambda (ignore-auto noconfirm)
 186             (find-dired ,dir ,find-args)))
 187     ;; Set subdir-alist so that Tree Dired will work:
 188     (if (fboundp 'dired-simple-subdir-alist)
 189         ;; will work even with nested dired format (dired-nstd.el,v 1.15
 190         ;; and later)
 191         (dired-simple-subdir-alist)
 192       ;; else we have an ancient tree dired (or classic dired, where
 193       ;; this does no harm)
 194       (set (make-local-variable 'dired-subdir-alist)
 195            (list (cons default-directory (point-min-marker)))))
 196     (set (make-local-variable 'dired-subdir-switches) find-ls-subdir-switches)
 197     (setq buffer-read-only nil)
 198     ;; Subdir headlerline must come first because the first marker in
 199     ;; subdir-alist points there.
 200     (insert "  " dir ":\n")
 201     ;; Make second line a ``find'' line in analogy to the ``total'' or
 202     ;; ``wildcard'' line.
 203     (insert "  " args "\n")
 204     (setq buffer-read-only t)
 205     (let ((proc (get-buffer-process (current-buffer))))
 206       (set-process-filter proc (function find-dired-filter))
 207       (set-process-sentinel proc (function find-dired-sentinel))
 208       ;; Initialize the process marker; it is used by the filter.
 209       (move-marker (process-mark proc) 1 (current-buffer)))
 210     (setq mode-line-process '(":%s"))))
 211
 212 (defun kill-find ()
 213   "Kill the `find' process running in the current buffer."
 214   (interactive)
 215   (let ((find (get-buffer-process (current-buffer))))
 216     (and find (eq (process-status find) 'run)
 217          (eq (process-filter find) (function find-dired-filter))
 218          (condition-case nil
 219              (delete-process find)
 220            (error nil)))))
 221
 222 ;;;###autoload
 223 (defun find-name-dired (dir pattern)
 224   "Search DIR recursively for files matching the globbing pattern PATTERN,
 225 and run dired on those files.
 226 PATTERN is a shell wildcard (not an Emacs regexp) and need not be quoted.
 227 The command run (after changing into DIR) is
 228
 229     find . -name 'PATTERN' -ls"
 230   (interactive
 231    "DFind-name (directory): \nsFind-name (filename wildcard): ")
 232   (find-dired dir (concat find-name-arg " " (shell-quote-argument pattern))))
 233
 234 ;; This functionality suggested by
 235 ;; From: oblanc@watcgl.waterloo.edu (Olivier Blanc)
 236 ;; Subject: find-dired, lookfor-dired
 237 ;; Date: 10 May 91 17:50:00 GMT
 238 ;; Organization: University of Waterloo
 239
 240 (defalias 'lookfor-dired 'find-grep-dired)
 241 ;;;###autoload
 242 (defun find-grep-dired (dir regexp)
 243   "Find files in DIR containing a regexp REGEXP and start Dired on output.
 244 The command run (after changing into DIR) is
 245
 246   find . \\( -type f -exec `grep-program' `find-grep-options' \\
 247     -e REGEXP {} \\; \\) -ls
 248
 249 where the car of the variable `find-ls-option' specifies what to
 250 use in place of \"-ls\" as the final argument."
 251   ;; Doc used to say "Thus ARG can also contain additional grep options."
 252   ;; i) Presumably ARG == REGEXP?
 253   ;; ii) No it can't have options, since it gets shell-quoted.
 254   (interactive "DFind-grep (directory): \nsFind-grep (grep regexp): ")
 255   ;; find -exec doesn't allow shell i/o redirections in the command,
 256   ;; or we could use `grep -l >/dev/null'
 257   ;; We use -type f, not ! -type d, to avoid getting screwed
 258   ;; by FIFOs and devices.  I'm not sure what's best to do
 259   ;; about symlinks, so as far as I know this is not wrong.
 260   (find-dired dir
 261               (concat "-type f -exec " grep-program " " find-grep-options " -e "
 262                       (shell-quote-argument regexp)
 263                       " "
 264                       (shell-quote-argument "{}")
 265                       " "
 266                       ;; Doesn't work with "+".
 267                       (shell-quote-argument ";"))))
 268
 269 (defun find-dired-filter (proc string)
 270   ;; Filter for \\[find-dired] processes.
 271   (let ((buf (process-buffer proc))
 272         (inhibit-read-only t))
 273     (if (buffer-name buf)
 274         (with-current-buffer buf
 275           (save-excursion
 276             (save-restriction
 277               (widen)
 278               (let ((buffer-read-only nil)
 279                     (beg (point-max))
 280                     (l-opt (and (consp find-ls-option)
 281                                 (string-match "l" (cdr find-ls-option))))
 282                     (ls-regexp (concat "^ +[^ \t\r\n]+\\( +[^ \t\r\n]+\\) +"
 283                                        "[^ \t\r\n]+ +[^ \t\r\n]+\\( +[0-9]+\\)")))
 284                 (goto-char beg)
 285                 (insert string)
 286                 (goto-char beg)
 287                 (or (looking-at "^")
 288                     (forward-line 1))
 289                 (while (looking-at "^")
 290                   (insert "  ")
 291                   (forward-line 1))
 292                 ;; Convert ` ./FILE' to ` FILE'
 293                 ;; This would lose if the current chunk of output
 294                 ;; starts or ends within the ` ./', so back up a bit:
 295                 (goto-char (- beg 3))   ; no error if < 0
 296                 (while (search-forward " ./" nil t)
 297                   (delete-region (point) (- (point) 2)))
 298                 ;; Pad the number of links and file size.  This is a
 299                 ;; quick and dirty way of getting the columns to line up
 300                 ;; most of the time, but it's not foolproof.
 301                 (when l-opt
 302                   (goto-char beg)
 303                   (goto-char (line-beginning-position))
 304                   (while (re-search-forward ls-regexp nil t)
 305                     (replace-match (format "%4s" (match-string 1))
 306                                    nil nil nil 1)
 307                     (replace-match (format "%9s" (match-string 2))
 308                                    nil nil nil 2)
 309                     (forward-line 1)))
 310                 ;; Find all the complete lines in the unprocessed
 311                 ;; output and process it to add text properties.
 312                 (goto-char (point-max))
 313                 (if (search-backward "\n" (process-mark proc) t)
 314                     (progn
 315                       (dired-insert-set-properties (process-mark proc)
 316                                                    (1+ (point)))
 317                       (move-marker (process-mark proc) (1+ (point)))))))))
 318       ;; The buffer has been killed.
 319       (delete-process proc))))
 320
 321 (defun find-dired-sentinel (proc state)
 322   ;; Sentinel for \\[find-dired] processes.
 323   (let ((buf (process-buffer proc))
 324         (inhibit-read-only t))
 325     (if (buffer-name buf)
 326         (with-current-buffer buf
 327           (let ((buffer-read-only nil))
 328             (save-excursion
 329               (goto-char (point-max))
 330               (insert "\n  find " state)
 331               (forward-char -1)         ;Back up before \n at end of STATE.
 332               (insert " at " (substring (current-time-string) 0 19))
 333               (forward-char 1)
 334               (setq mode-line-process
 335                     (concat ":"
 336                             (symbol-name (process-status proc))))
 337               ;; Since the buffer and mode line will show that the
 338               ;; process is dead, we can delete it now.  Otherwise it
 339               ;; will stay around until M-x list-processes.
 340               (delete-process proc)
 341               (force-mode-line-update)))
 342           (message "find-dired %s finished." (current-buffer))))))
 343
 344 \f
 345 (provide 'find-dired)
 346
 347 ;;; find-dired.el ends here