code.delx.au - gnu-emacs/blob - lisp/ibuf-ext.el

   1 ;;; ibuf-ext.el --- extensions for ibuffer  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2000-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Colin Walters <walters@verbum.org>
   6 ;; Maintainer: John Paul Wallington <jpw@gnu.org>
   7 ;; Created: 2 Dec 2001
   8 ;; Keywords: buffer, convenience
   9 ;; Package: ibuffer
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; These functions should be automatically loaded when called, but you
  29 ;; can explicitly (require 'ibuf-ext) in your ~/.emacs to have them
  30 ;; preloaded.
  31
  32 ;;; Code:
  33
  34 (require 'ibuffer)
  35
  36 (eval-when-compile
  37   (require 'ibuf-macs)
  38   (require 'cl-lib))
  39
  40 ;;; Utility functions
  41 (defun ibuffer-delete-alist (key alist)
  42   "Delete all entries in ALIST that have a key equal to KEY."
  43   (let (entry)
  44     (while (setq entry (assoc key alist))
  45       (setq alist (delete entry alist)))
  46     alist))
  47
  48 ;; borrowed from Gnus
  49 (defun ibuffer-remove-duplicates (list)
  50   "Return a copy of LIST with duplicate elements removed."
  51   (let ((new nil)
  52         (tail list))
  53     (while tail
  54       (or (member (car tail) new)
  55           (setq new (cons (car tail) new)))
  56       (setq tail (cdr tail)))
  57     (nreverse new)))
  58
  59 (defun ibuffer-split-list (ibuffer-split-list-fn ibuffer-split-list-elts)
  60   (let ((hip-crowd nil)
  61         (lamers nil))
  62     (dolist (ibuffer-split-list-elt ibuffer-split-list-elts)
  63       (if (funcall ibuffer-split-list-fn ibuffer-split-list-elt)
  64           (push ibuffer-split-list-elt hip-crowd)
  65         (push ibuffer-split-list-elt lamers)))
  66     ;; Too bad Emacs Lisp doesn't have multiple values.
  67     (list (nreverse hip-crowd) (nreverse lamers))))
  68
  69 (defcustom ibuffer-never-show-predicates nil
  70   "A list of predicates (a regexp or function) for buffers not to display.
  71 If a regexp, then it will be matched against the buffer's name.
  72 If a function, it will be called with the buffer as an argument, and
  73 should return non-nil if this buffer should not be shown."
  74   :type '(repeat (choice regexp function))
  75   :require 'ibuf-ext
  76   :group 'ibuffer)
  77
  78 (defcustom ibuffer-always-show-predicates nil
  79   "A list of predicates (a regexp or function) for buffers to always display.
  80 If a regexp, then it will be matched against the buffer's name.
  81 If a function, it will be called with the buffer as an argument, and
  82 should return non-nil if this buffer should be shown.
  83 Note that buffers matching one of these predicates will be shown
  84 regardless of any active filters in this buffer."
  85   :type '(repeat (choice regexp function))
  86   :group 'ibuffer)
  87
  88 (defvar ibuffer-tmp-hide-regexps nil
  89   "A list of regexps which should match buffer names to not show.")
  90
  91 (defvar ibuffer-tmp-show-regexps nil
  92   "A list of regexps which should match buffer names to always show.")
  93
  94 (defvar ibuffer-auto-buffers-changed nil)
  95
  96 (defcustom ibuffer-saved-filters '(("gnus"
  97                                     ((or (mode . message-mode)
  98                                          (mode . mail-mode)
  99                                          (mode . gnus-group-mode)
 100                                          (mode . gnus-summary-mode)
 101                                          (mode . gnus-article-mode))))
 102                                    ("programming"
 103                                     ((or (mode . emacs-lisp-mode)
 104                                          (mode . cperl-mode)
 105                                          (mode . c-mode)
 106                                          (mode . java-mode)
 107                                          (mode . idl-mode)
 108                                          (mode . lisp-mode)))))
 109
 110   "An alist of filter qualifiers to switch between.
 111
 112 This variable should look like ((\"STRING\" QUALIFIERS)
 113                                 (\"STRING\" QUALIFIERS) ...), where
 114 QUALIFIERS is a list of the same form as
 115 `ibuffer-filtering-qualifiers'.
 116 See also the variables `ibuffer-filtering-qualifiers',
 117 `ibuffer-filtering-alist', and the functions
 118 `ibuffer-switch-to-saved-filters', `ibuffer-save-filters'."
 119   :type '(repeat sexp)
 120   :group 'ibuffer)
 121
 122 (defvar ibuffer-filtering-qualifiers nil
 123   "A list like (SYMBOL . QUALIFIER) which filters the current buffer list.
 124 See also `ibuffer-filtering-alist'.")
 125
 126 ;; This is now frobbed by `define-ibuffer-filter'.
 127 (defvar ibuffer-filtering-alist nil
 128   "An alist of (SYMBOL DESCRIPTION FUNCTION) which describes a filter.
 129
 130 You most likely do not want to modify this variable directly; see
 131 `define-ibuffer-filter'.
 132
 133 SYMBOL is the symbolic name of the filter.  DESCRIPTION is used when
 134 displaying information to the user.  FUNCTION is given a buffer and
 135 the value of the qualifier, and returns non-nil if and only if the
 136 buffer should be displayed.")
 137
 138 (defcustom ibuffer-filter-format-alist nil
 139   "An alist which has special formats used when a filter is active.
 140 The contents of this variable should look like:
 141  ((FILTER (FORMAT FORMAT ...)) (FILTER (FORMAT FORMAT ...)) ...)
 142
 143 For example, suppose that when you add a filter for buffers whose
 144 major mode is `emacs-lisp-mode', you only want to see the mark and the
 145 name of the buffer.  You could accomplish that by adding:
 146  (mode ((mark \" \" name)))
 147 to this variable."
 148   :type '(repeat (list :tag "Association" (symbol :tag "Filter")
 149                        (list :tag "Formats" (repeat (sexp :tag "Format")))))
 150   :group 'ibuffer)
 151
 152 (defvar ibuffer-cached-filter-formats nil)
 153 (defvar ibuffer-compiled-filter-formats nil)
 154
 155 (defvar ibuffer-filter-groups nil
 156   "A list like ((\"NAME\" ((SYMBOL . QUALIFIER) ...) ...) which groups buffers.
 157 The SYMBOL should be one from `ibuffer-filtering-alist'.
 158 The QUALIFIER should be the same as QUALIFIER in
 159 `ibuffer-filtering-qualifiers'.")
 160
 161 (defcustom ibuffer-show-empty-filter-groups t
 162   "If non-nil, then show the names of filter groups which are empty."
 163   :type 'boolean
 164   :group 'ibuffer)
 165
 166 (defcustom ibuffer-saved-filter-groups nil
 167   "An alist of filtering groups to switch between.
 168
 169 This variable should look like ((\"STRING\" QUALIFIERS)
 170                                 (\"STRING\" QUALIFIERS) ...), where
 171 QUALIFIERS is a list of the same form as
 172 `ibuffer-filtering-qualifiers'.
 173
 174 See also the variables `ibuffer-filter-groups',
 175 `ibuffer-filtering-qualifiers', `ibuffer-filtering-alist', and the
 176 functions `ibuffer-switch-to-saved-filter-groups',
 177 `ibuffer-save-filter-groups'."
 178   :type '(repeat sexp)
 179   :group 'ibuffer)
 180
 181 (defvar ibuffer-hidden-filter-groups nil
 182   "A list of filtering groups which are currently hidden.")
 183
 184 (defvar ibuffer-filter-group-kill-ring nil)
 185
 186 (defcustom ibuffer-old-time 72
 187   "The number of hours before a buffer is considered \"old\"."
 188   :type '(choice (const :tag "72 hours (3 days)" 72)
 189                  (const :tag "48 hours (2 days)" 48)
 190                  (const :tag "24 hours (1 day)" 24)
 191                  (integer :tag "hours"))
 192   :group 'ibuffer)
 193
 194 (defcustom ibuffer-save-with-custom t
 195   "If non-nil, then use Custom to save interactively changed variables.
 196 Currently, this only applies to `ibuffer-saved-filters' and
 197 `ibuffer-saved-filter-groups'."
 198   :type 'boolean
 199   :group 'ibuffer)
 200
 201 (defun ibuffer-ext-visible-p (buf all &optional ibuffer-buf)
 202   (or
 203    (ibuffer-buf-matches-predicates buf ibuffer-tmp-show-regexps)
 204    (and (not
 205          (or
 206           (ibuffer-buf-matches-predicates buf ibuffer-tmp-hide-regexps)
 207           (ibuffer-buf-matches-predicates buf ibuffer-never-show-predicates)))
 208         (or all
 209             (not
 210              (ibuffer-buf-matches-predicates buf ibuffer-maybe-show-predicates)))
 211         (or ibuffer-view-ibuffer
 212             (and ibuffer-buf
 213                  (not (eq ibuffer-buf buf))))
 214         (or
 215          (ibuffer-included-in-filters-p buf ibuffer-filtering-qualifiers)
 216          (ibuffer-buf-matches-predicates buf ibuffer-always-show-predicates)))))
 217
 218 ;;;###autoload
 219 (define-minor-mode ibuffer-auto-mode
 220   "Toggle use of Ibuffer's auto-update facility (Ibuffer Auto mode).
 221 With a prefix argument ARG, enable Ibuffer Auto mode if ARG is
 222 positive, and disable it otherwise.  If called from Lisp, enable
 223 the mode if ARG is omitted or nil."
 224   nil nil nil
 225   (unless (derived-mode-p 'ibuffer-mode)
 226     (error "This buffer is not in Ibuffer mode"))
 227   (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed) ; Initialize state vector
 228   (add-hook 'post-command-hook 'ibuffer-auto-update-changed))
 229
 230 (defun ibuffer-auto-update-changed ()
 231   (when (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed)
 232     (dolist (buf (buffer-list))
 233       (ignore-errors
 234         (with-current-buffer buf
 235           (when (and ibuffer-auto-mode
 236                      (derived-mode-p 'ibuffer-mode))
 237             (ibuffer-update nil t)))))))
 238
 239 ;;;###autoload
 240 (defun ibuffer-mouse-filter-by-mode (event)
 241   "Enable or disable filtering by the major mode chosen via mouse."
 242   (interactive "e")
 243   (ibuffer-interactive-filter-by-mode event))
 244
 245 ;;;###autoload
 246 (defun ibuffer-interactive-filter-by-mode (event-or-point)
 247   "Enable or disable filtering by the major mode at point."
 248   (interactive "d")
 249   (if (eventp event-or-point)
 250       (posn-set-point (event-end event-or-point))
 251     (goto-char event-or-point))
 252   (let ((buf (ibuffer-current-buffer)))
 253     (if (assq 'mode ibuffer-filtering-qualifiers)
 254         (setq ibuffer-filtering-qualifiers
 255               (ibuffer-delete-alist 'mode ibuffer-filtering-qualifiers))
 256       (ibuffer-push-filter (cons 'mode (buffer-local-value 'major-mode buf)))))
 257   (ibuffer-update nil t))
 258
 259 ;;;###autoload
 260 (defun ibuffer-mouse-toggle-filter-group (event)
 261   "Toggle the display status of the filter group chosen with the mouse."
 262   (interactive "e")
 263   (ibuffer-toggle-filter-group-1 (save-excursion
 264                                    (mouse-set-point event)
 265                                    (point))))
 266
 267 ;;;###autoload
 268 (defun ibuffer-toggle-filter-group ()
 269   "Toggle the display status of the filter group on this line."
 270   (interactive)
 271   (ibuffer-toggle-filter-group-1 (point)))
 272
 273 (defun ibuffer-toggle-filter-group-1 (posn)
 274   (let ((name (get-text-property posn 'ibuffer-filter-group-name)))
 275     (unless (stringp name)
 276       (error "No filtering group name present"))
 277     (if (member name ibuffer-hidden-filter-groups)
 278         (setq ibuffer-hidden-filter-groups
 279               (delete name ibuffer-hidden-filter-groups))
 280       (push name ibuffer-hidden-filter-groups))
 281     (ibuffer-update nil t)))
 282
 283 ;;;###autoload
 284 (defun ibuffer-forward-filter-group (&optional count)
 285   "Move point forwards by COUNT filtering groups."
 286   (interactive "P")
 287   (unless count
 288     (setq count 1))
 289   (when (> count 0)
 290     (when (get-text-property (point) 'ibuffer-filter-group-name)
 291       (goto-char (next-single-property-change
 292                   (point) 'ibuffer-filter-group-name
 293                   nil (point-max))))
 294     (goto-char (next-single-property-change
 295                 (point) 'ibuffer-filter-group-name
 296                 nil (point-max)))
 297     (ibuffer-forward-filter-group (1- count)))
 298   (ibuffer-forward-line 0))
 299
 300 ;;;###autoload
 301 (defun ibuffer-backward-filter-group (&optional count)
 302   "Move point backwards by COUNT filtering groups."
 303   (interactive "P")
 304   (unless count
 305     (setq count 1))
 306   (when (> count 0)
 307     (when (get-text-property (point) 'ibuffer-filter-group-name)
 308       (goto-char (previous-single-property-change
 309                   (point) 'ibuffer-filter-group-name
 310                   nil (point-min))))
 311     (goto-char (previous-single-property-change
 312                 (point) 'ibuffer-filter-group-name
 313                 nil (point-min)))
 314     (ibuffer-backward-filter-group (1- count)))
 315   (when (= (point) (point-min))
 316     (goto-char (point-max))
 317     (ibuffer-backward-filter-group 1))
 318   (ibuffer-forward-line 0))
 319
 320 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe "ibuf-ext")
 321 (define-ibuffer-op shell-command-pipe (command)
 322   "Pipe the contents of each marked buffer to shell command COMMAND."
 323   (:interactive "sPipe to shell command: "
 324    :opstring "Shell command executed on"
 325    :modifier-p nil)
 326   (shell-command-on-region
 327    (point-min) (point-max) command
 328    (get-buffer-create "* ibuffer-shell-output*")))
 329
 330 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe-replace "ibuf-ext")
 331 (define-ibuffer-op shell-command-pipe-replace (command)
 332   "Replace the contents of marked buffers with output of pipe to COMMAND."
 333   (:interactive "sPipe to shell command (replace): "
 334    :opstring "Buffer contents replaced in"
 335    :active-opstring "replace buffer contents in"
 336    :dangerous t
 337    :modifier-p t)
 338   (with-current-buffer buf
 339     (shell-command-on-region (point-min) (point-max)
 340                              command nil t)))
 341
 342 ;;;###autoload (autoload 'ibuffer-do-shell-command-file "ibuf-ext")
 343 (define-ibuffer-op shell-command-file (command)
 344   "Run shell command COMMAND separately on files of marked buffers."
 345   (:interactive "sShell command on buffer's file: "
 346    :opstring "Shell command executed on"
 347    :modifier-p nil)
 348   (shell-command (concat command " "
 349                          (shell-quote-argument
 350                           (or buffer-file-name
 351                               (let ((file
 352                                      (make-temp-file
 353                                       (substring
 354                                        (buffer-name) 0
 355                                        (min 10 (length (buffer-name)))))))
 356                                 (write-region nil nil file nil 0)
 357                                 file))))))
 358
 359 ;;;###autoload (autoload 'ibuffer-do-eval "ibuf-ext")
 360 (define-ibuffer-op eval (form)
 361   "Evaluate FORM in each of the buffers.
 362 Does not display the buffer during evaluation. See
 363 `ibuffer-do-view-and-eval' for that."
 364   (:interactive
 365    (list
 366     (read-from-minibuffer
 367      "Eval in buffers (form): "
 368      nil read-expression-map t 'read-expression-history))
 369    :opstring "evaluated in"
 370    :modifier-p :maybe)
 371   (eval form))
 372
 373 ;;;###autoload (autoload 'ibuffer-do-view-and-eval "ibuf-ext")
 374 (define-ibuffer-op view-and-eval (form)
 375   "Evaluate FORM while displaying each of the marked buffers.
 376 To evaluate a form without viewing the buffer, see `ibuffer-do-eval'."
 377   (:interactive
 378    (list
 379     (read-from-minibuffer
 380      "Eval viewing in buffers (form): "
 381      nil read-expression-map t 'read-expression-history))
 382    :opstring "evaluated in"
 383    :complex t
 384    :modifier-p :maybe)
 385   (let ((ibuffer-buf (current-buffer)))
 386     (unwind-protect
 387         (progn
 388           (switch-to-buffer buf)
 389           (eval form))
 390       (switch-to-buffer ibuffer-buf))))
 391
 392 ;;;###autoload (autoload 'ibuffer-do-rename-uniquely "ibuf-ext")
 393 (define-ibuffer-op rename-uniquely ()
 394   "Rename marked buffers as with `rename-uniquely'."
 395   (:opstring "renamed"
 396    :modifier-p t)
 397   (rename-uniquely))
 398
 399 ;;;###autoload (autoload 'ibuffer-do-revert "ibuf-ext")
 400 (define-ibuffer-op revert ()
 401   "Revert marked buffers as with `revert-buffer'."
 402   (:dangerous t
 403    :opstring "reverted"
 404    :active-opstring "revert"
 405    :modifier-p :maybe)
 406   (revert-buffer t t))
 407
 408 ;;;###autoload (autoload 'ibuffer-do-isearch "ibuf-ext")
 409 (define-ibuffer-op ibuffer-do-isearch ()
 410   "Perform a `isearch-forward' in marked buffers."
 411   (:interactive ()
 412    :opstring "searched in"
 413    :complex t
 414    :modifier-p :maybe)
 415   (multi-isearch-buffers (ibuffer-get-marked-buffers)))
 416
 417 ;;;###autoload (autoload 'ibuffer-do-isearch-regexp "ibuf-ext")
 418 (define-ibuffer-op ibuffer-do-isearch-regexp ()
 419   "Perform a `isearch-forward-regexp' in marked buffers."
 420   (:interactive ()
 421    :opstring "searched regexp in"
 422    :complex t
 423    :modifier-p :maybe)
 424   (multi-isearch-buffers-regexp (ibuffer-get-marked-buffers)))
 425
 426 ;;;###autoload (autoload 'ibuffer-do-replace-regexp "ibuf-ext")
 427 (define-ibuffer-op replace-regexp (from-str to-str)
 428   "Perform a `replace-regexp' in marked buffers."
 429   (:interactive
 430    (let* ((from-str (read-from-minibuffer "Replace regexp: "))
 431           (to-str (read-from-minibuffer (concat "Replace " from-str
 432                                                 " with: "))))
 433      (list from-str to-str))
 434    :opstring "replaced in"
 435    :complex t
 436    :modifier-p :maybe)
 437   (save-window-excursion
 438     (switch-to-buffer buf)
 439     (save-excursion
 440       (goto-char (point-min))
 441       (let ((case-fold-search ibuffer-case-fold-search))
 442         (while (re-search-forward from-str nil t)
 443           (replace-match to-str))))
 444     t))
 445
 446 ;;;###autoload (autoload 'ibuffer-do-query-replace "ibuf-ext")
 447 (define-ibuffer-op query-replace (&rest args)
 448   "Perform a `query-replace' in marked buffers."
 449   (:interactive
 450    (query-replace-read-args "Query replace" t t)
 451    :opstring "replaced in"
 452    :complex t
 453    :modifier-p :maybe)
 454   (save-window-excursion
 455     (switch-to-buffer buf)
 456     (save-excursion
 457       (let ((case-fold-search ibuffer-case-fold-search))
 458         (goto-char (point-min))
 459         (apply #'query-replace args)))
 460     t))
 461
 462 ;;;###autoload (autoload 'ibuffer-do-query-replace-regexp "ibuf-ext")
 463 (define-ibuffer-op query-replace-regexp (&rest args)
 464   "Perform a `query-replace-regexp' in marked buffers."
 465   (:interactive
 466    (query-replace-read-args "Query replace regexp" t t)
 467    :opstring "replaced in"
 468    :complex t
 469    :modifier-p :maybe)
 470   (save-window-excursion
 471     (switch-to-buffer buf)
 472     (save-excursion
 473       (let ((case-fold-search ibuffer-case-fold-search))
 474         (goto-char (point-min))
 475         (apply #'query-replace-regexp args)))
 476     t))
 477
 478 ;;;###autoload (autoload 'ibuffer-do-print "ibuf-ext")
 479 (define-ibuffer-op print ()
 480   "Print marked buffers as with `print-buffer'."
 481   (:opstring "printed"
 482    :modifier-p nil)
 483   (print-buffer))
 484
 485 ;;;###autoload
 486 (defun ibuffer-included-in-filters-p (buf filters)
 487   (not
 488    (memq nil ;; a filter will return nil if it failed
 489          (mapcar
 490           ;; filter should be like (TYPE . QUALIFIER), or
 491           ;; (or (TYPE . QUALIFIER) (TYPE . QUALIFIER) ...)
 492           #'(lambda (qual)
 493               (ibuffer-included-in-filter-p buf qual))
 494           filters))))
 495
 496 (defun ibuffer-included-in-filter-p (buf filter)
 497   (if (eq (car filter) 'not)
 498       (not (ibuffer-included-in-filter-p-1 buf (cdr filter)))
 499     (ibuffer-included-in-filter-p-1 buf filter)))
 500
 501 (defun ibuffer-included-in-filter-p-1 (buf filter)
 502   (not
 503    (not
 504     (pcase (car filter)
 505       (`or
 506        (memq t (mapcar #'(lambda (x)
 507                            (ibuffer-included-in-filter-p buf x))
 508                        (cdr filter))))
 509       (`saved
 510        (let ((data
 511               (assoc (cdr filter)
 512                      ibuffer-saved-filters)))
 513          (unless data
 514            (ibuffer-filter-disable t)
 515            (error "Unknown saved filter %s" (cdr filter)))
 516          (ibuffer-included-in-filters-p buf (cadr data))))
 517       (_
 518        (pcase-let ((`(,_type ,_desc ,func)
 519                     (assq (car filter) ibuffer-filtering-alist)))
 520          (unless func
 521            (ibuffer-filter-disable t)
 522            (error "Undefined filter %s" (car filter)))
 523          (funcall func buf (cdr filter))))))))
 524
 525 (defun ibuffer-generate-filter-groups (bmarklist &optional noempty nodefault)
 526   (let ((filter-group-alist (if nodefault
 527                                 ibuffer-filter-groups
 528                               (append ibuffer-filter-groups
 529                                       (list (cons "Default" nil))))))
 530     ;; (dolist (hidden ibuffer-hidden-filter-groups)
 531     ;;   (setq filter-group-alist (ibuffer-delete-alist
 532     ;;                             hidden filter-group-alist)))
 533     (let ((vec (make-vector (length filter-group-alist) nil))
 534           (i 0))
 535       (dolist (filtergroup filter-group-alist)
 536         (let ((filterset (cdr filtergroup)))
 537           (cl-multiple-value-bind (hip-crowd lamers)
 538               (cl-values-list
 539                (ibuffer-split-list (lambda (bufmark)
 540                                      (ibuffer-included-in-filters-p (car bufmark)
 541                                                                     filterset))
 542                                    bmarklist))
 543             (aset vec i hip-crowd)
 544             (cl-incf i)
 545             (setq bmarklist lamers))))
 546       (let (ret)
 547         (dotimes (j i)
 548           (let ((bufs (aref vec j)))
 549             (unless (and noempty (null bufs))
 550               (push (cons (car (nth j filter-group-alist))
 551                           bufs)
 552                     ret))))
 553         ret))))
 554
 555 ;;;###autoload
 556 (defun ibuffer-filters-to-filter-group (name)
 557   "Make the current filters into a filtering group."
 558   (interactive "sName for filtering group: ")
 559   (when (null ibuffer-filtering-qualifiers)
 560     (error "No filters in effect"))
 561   (push (cons name ibuffer-filtering-qualifiers) ibuffer-filter-groups)
 562   (ibuffer-filter-disable))
 563
 564 ;;;###autoload
 565 (defun ibuffer-set-filter-groups-by-mode ()
 566   "Set the current filter groups to filter by mode."
 567   (interactive)
 568   (setq ibuffer-filter-groups
 569         (mapcar (lambda (mode)
 570                   (cons (format "%s" mode) `((mode . ,mode))))
 571                 (let ((modes
 572                        (ibuffer-remove-duplicates
 573                         (mapcar (lambda (buf)
 574                                   (buffer-local-value 'major-mode buf))
 575                                 (buffer-list)))))
 576                   (if ibuffer-view-ibuffer
 577                       modes
 578                     (delq 'ibuffer-mode modes)))))
 579   (ibuffer-update nil t))
 580
 581 ;;;###autoload
 582 (defun ibuffer-pop-filter-group ()
 583   "Remove the first filter group."
 584   (interactive)
 585   (when (null ibuffer-filter-groups)
 586     (error "No filter groups active"))
 587   (setq ibuffer-hidden-filter-groups
 588         (delete (pop ibuffer-filter-groups)
 589                 ibuffer-hidden-filter-groups))
 590   (ibuffer-update nil t))
 591
 592 (defun ibuffer-read-filter-group-name (msg &optional nodefault noerror)
 593   (when (and (not noerror) (null ibuffer-filter-groups))
 594     (error "No filter groups active"))
 595   ;; `ibuffer-generate-filter-groups' returns all non-hidden filter
 596   ;; groups, possibly excluding empty groups or Default.
 597   ;; We add `ibuffer-hidden-filter-groups' to the list, excluding
 598   ;; Default if necessary.
 599   (completing-read msg (nconc
 600                         (ibuffer-generate-filter-groups
 601                          (ibuffer-current-state-list)
 602                          (not ibuffer-show-empty-filter-groups)
 603                          nodefault)
 604                         (if nodefault
 605                             (remove "Default" ibuffer-hidden-filter-groups)
 606                           ibuffer-hidden-filter-groups))
 607                    nil t))
 608
 609 ;;;###autoload
 610 (defun ibuffer-decompose-filter-group (group)
 611   "Decompose the filter group GROUP into active filters."
 612   (interactive
 613    (list (ibuffer-read-filter-group-name "Decompose filter group: " t)))
 614   (let ((data (cdr (assoc group ibuffer-filter-groups))))
 615     (setq ibuffer-filter-groups (ibuffer-delete-alist
 616                                  group ibuffer-filter-groups)
 617           ibuffer-filtering-qualifiers data))
 618   (ibuffer-update nil t))
 619
 620 ;;;###autoload
 621 (defun ibuffer-clear-filter-groups ()
 622   "Remove all filter groups."
 623   (interactive)
 624   (setq ibuffer-filter-groups nil
 625         ibuffer-hidden-filter-groups nil)
 626   (ibuffer-update nil t))
 627
 628 (defun ibuffer-current-filter-groups-with-position ()
 629   (save-excursion
 630     (goto-char (point-min))
 631     (let ((pos nil)
 632           (result nil))
 633       (while (and (not (eobp))
 634                   (setq pos (next-single-property-change
 635                              (point) 'ibuffer-filter-group-name)))
 636         (goto-char pos)
 637         (push (cons (get-text-property (point) 'ibuffer-filter-group-name)
 638                     pos)
 639               result)
 640         (goto-char (next-single-property-change
 641                     pos 'ibuffer-filter-group-name)))
 642       (nreverse result))))
 643
 644 ;;;###autoload
 645 (defun ibuffer-jump-to-filter-group (name)
 646   "Move point to the filter group whose name is NAME."
 647   (interactive
 648    (list (ibuffer-read-filter-group-name "Jump to filter group: ")))
 649   (ibuffer-aif (assoc name (ibuffer-current-filter-groups-with-position))
 650       (goto-char (cdr it))
 651     (error "No filter group with name %s" name)))
 652
 653 ;;;###autoload
 654 (defun ibuffer-kill-filter-group (name)
 655   "Kill the filter group named NAME.
 656 The group will be added to `ibuffer-filter-group-kill-ring'."
 657   (interactive (list (ibuffer-read-filter-group-name "Kill filter group: " t)))
 658   (when (equal name "Default")
 659     (error "Can't kill default filter group"))
 660   (ibuffer-aif (assoc name ibuffer-filter-groups)
 661       (progn
 662         (push (copy-tree it) ibuffer-filter-group-kill-ring)
 663         (setq ibuffer-filter-groups (ibuffer-delete-alist
 664                                      name ibuffer-filter-groups))
 665         (setq ibuffer-hidden-filter-groups
 666               (delete name ibuffer-hidden-filter-groups)))
 667     (error "No filter group with name \"%s\"" name))
 668   (ibuffer-update nil t))
 669
 670 ;;;###autoload
 671 (defun ibuffer-kill-line (&optional arg interactive-p)
 672   "Kill the filter group at point.
 673 See also `ibuffer-kill-filter-group'."
 674   (interactive "P\np")
 675   (ibuffer-aif (save-excursion
 676                  (ibuffer-forward-line 0)
 677                  (get-text-property (point) 'ibuffer-filter-group-name))
 678       (progn
 679         (ibuffer-kill-filter-group it))
 680       (funcall (if interactive-p #'call-interactively #'funcall)
 681                #'kill-line arg)))
 682
 683 (defun ibuffer-insert-filter-group-before (newgroup group)
 684   (let* ((found nil)
 685          (pos (let ((groups (mapcar #'car ibuffer-filter-groups))
 686                     (res 0))
 687                 (while groups
 688                   (if (equal (car groups) group)
 689                       (setq found t
 690                             groups nil)
 691                     (cl-incf res)
 692                     (setq groups (cdr groups))))
 693                 res)))
 694     (cond ((not found)
 695            (setq ibuffer-filter-groups
 696                  (nconc ibuffer-filter-groups (list newgroup))))
 697           ((zerop pos)
 698            (push newgroup ibuffer-filter-groups))
 699           (t
 700            (let ((cell (nthcdr pos ibuffer-filter-groups)))
 701              (setf (cdr cell) (cons (car cell) (cdr cell)))
 702              (setf (car cell) newgroup))))))
 703
 704 ;;;###autoload
 705 (defun ibuffer-yank ()
 706   "Yank the last killed filter group before group at point."
 707   (interactive)
 708   (ibuffer-yank-filter-group
 709    (or (get-text-property (point) 'ibuffer-filter-group-name)
 710        (get-text-property (point) 'ibuffer-filter-group)
 711        (error "No filter group at point"))))
 712
 713 ;;;###autoload
 714 (defun ibuffer-yank-filter-group (name)
 715   "Yank the last killed filter group before group named NAME."
 716   (interactive (list (ibuffer-read-filter-group-name
 717                         "Yank filter group before group: ")))
 718   (unless ibuffer-filter-group-kill-ring
 719     (error "The Ibuffer filter group kill-ring is empty"))
 720   (save-excursion
 721     (ibuffer-forward-line 0)
 722     (ibuffer-insert-filter-group-before (pop ibuffer-filter-group-kill-ring)
 723                                         name))
 724   (ibuffer-update nil t))
 725
 726 ;;;###autoload
 727 (defun ibuffer-save-filter-groups (name groups)
 728   "Save all active filter groups GROUPS as NAME.
 729 They are added to `ibuffer-saved-filter-groups'.  Interactively,
 730 prompt for NAME, and use the current filters."
 731   (interactive
 732    (if (null ibuffer-filter-groups)
 733        (error "No filter groups active")
 734      (list
 735       (read-from-minibuffer "Save current filter groups as: ")
 736       ibuffer-filter-groups)))
 737   (ibuffer-aif (assoc name ibuffer-saved-filter-groups)
 738       (setcdr it groups)
 739     (push (cons name groups) ibuffer-saved-filter-groups))
 740   (ibuffer-maybe-save-stuff))
 741
 742 ;;;###autoload
 743 (defun ibuffer-delete-saved-filter-groups (name)
 744   "Delete saved filter groups with NAME.
 745 They are removed from `ibuffer-saved-filter-groups'."
 746   (interactive
 747    (list
 748     (if (null ibuffer-saved-filter-groups)
 749         (error "No saved filter groups")
 750       (completing-read "Delete saved filter group: "
 751                        ibuffer-saved-filter-groups nil t))))
 752   (setq ibuffer-saved-filter-groups
 753         (ibuffer-delete-alist name ibuffer-saved-filter-groups))
 754   (ibuffer-maybe-save-stuff)
 755   (ibuffer-update nil t))
 756
 757 ;;;###autoload
 758 (defun ibuffer-switch-to-saved-filter-groups (name)
 759   "Set this buffer's filter groups to saved version with NAME.
 760 The value from `ibuffer-saved-filter-groups' is used."
 761   (interactive
 762    (list
 763     (cond ((null ibuffer-saved-filter-groups)
 764            (error "No saved filters"))
 765           ;; `ibuffer-saved-filter-groups' is a user variable that defaults
 766           ;; to nil.  We assume that with one element in this list the user
 767           ;; knows what she wants.  See bug#12331.
 768           ((null (cdr ibuffer-saved-filter-groups))
 769            (caar ibuffer-saved-filter-groups))
 770           (t
 771            (completing-read "Switch to saved filter group: "
 772                             ibuffer-saved-filter-groups nil t)))))
 773   (setq ibuffer-filter-groups (cdr (assoc name ibuffer-saved-filter-groups))
 774         ibuffer-hidden-filter-groups nil)
 775   (ibuffer-update nil t))
 776
 777 ;;;###autoload
 778 (defun ibuffer-filter-disable (&optional delete-filter-groups)
 779   "Disable all filters currently in effect in this buffer.
 780 With optional arg DELETE-FILTER-GROUPS non-nil, delete all filter
 781 group definitions by setting `ibuffer-filter-groups' to nil."
 782   (interactive)
 783   (setq ibuffer-filtering-qualifiers nil)
 784   (if delete-filter-groups
 785       (setq ibuffer-filter-groups nil))
 786   (let ((buf (ibuffer-current-buffer)))
 787     (ibuffer-update nil t)
 788     (when buf
 789       (ibuffer-jump-to-buffer (buffer-name buf)))))
 790
 791 ;;;###autoload
 792 (defun ibuffer-pop-filter ()
 793   "Remove the top filter in this buffer."
 794   (interactive)
 795   (when (null ibuffer-filtering-qualifiers)
 796     (error "No filters in effect"))
 797   (pop ibuffer-filtering-qualifiers)
 798   (let ((buf (ibuffer-current-buffer)))
 799     (ibuffer-update nil t)
 800     (when buf
 801       (ibuffer-jump-to-buffer (buffer-name buf)))))
 802
 803 (defun ibuffer-push-filter (qualifier)
 804   "Add QUALIFIER to `ibuffer-filtering-qualifiers'."
 805   (push qualifier ibuffer-filtering-qualifiers))
 806
 807 ;;;###autoload
 808 (defun ibuffer-decompose-filter ()
 809   "Separate the top compound filter (OR, NOT, or SAVED) in this buffer.
 810
 811 This means that the topmost filter on the filtering stack, which must
 812 be a complex filter like (OR [name: foo] [mode: bar-mode]), will be
 813 turned into two separate filters [name: foo] and [mode: bar-mode]."
 814   (interactive)
 815   (when (null ibuffer-filtering-qualifiers)
 816     (error "No filters in effect"))
 817   (let ((lim (pop ibuffer-filtering-qualifiers)))
 818     (pcase (car lim)
 819       (`or
 820        (setq ibuffer-filtering-qualifiers (append
 821                                           (cdr lim)
 822                                           ibuffer-filtering-qualifiers)))
 823       (`saved
 824        (let ((data
 825               (assoc (cdr lim)
 826                      ibuffer-saved-filters)))
 827          (unless data
 828            (ibuffer-filter-disable)
 829            (error "Unknown saved filter %s" (cdr lim)))
 830          (setq ibuffer-filtering-qualifiers (append
 831                                             (cadr data)
 832                                             ibuffer-filtering-qualifiers))))
 833       (`not
 834        (push (cdr lim)
 835              ibuffer-filtering-qualifiers))
 836       (_
 837        (error "Filter type %s is not compound" (car lim)))))
 838   (ibuffer-update nil t))
 839
 840 ;;;###autoload
 841 (defun ibuffer-exchange-filters ()
 842   "Exchange the top two filters on the stack in this buffer."
 843   (interactive)
 844   (when (< (length ibuffer-filtering-qualifiers)
 845            2)
 846     (error "Need two filters to exchange"))
 847   (let ((first (pop ibuffer-filtering-qualifiers))
 848         (second (pop ibuffer-filtering-qualifiers)))
 849     (push first ibuffer-filtering-qualifiers)
 850     (push second ibuffer-filtering-qualifiers))
 851   (ibuffer-update nil t))
 852
 853 ;;;###autoload
 854 (defun ibuffer-negate-filter ()
 855   "Negate the sense of the top filter in the current buffer."
 856   (interactive)
 857   (when (null ibuffer-filtering-qualifiers)
 858     (error "No filters in effect"))
 859   (let ((lim (pop ibuffer-filtering-qualifiers)))
 860     (push (if (eq (car lim) 'not)
 861               (cdr lim)
 862             (cons 'not lim))
 863           ibuffer-filtering-qualifiers))
 864   (ibuffer-update nil t))
 865
 866 ;;;###autoload
 867 (defun ibuffer-or-filter (&optional reverse)
 868   "Replace the top two filters in this buffer with their logical OR.
 869 If optional argument REVERSE is non-nil, instead break the top OR
 870 filter into parts."
 871   (interactive "P")
 872   (if reverse
 873       (progn
 874         (when (or (null ibuffer-filtering-qualifiers)
 875                   (not (eq 'or (caar ibuffer-filtering-qualifiers))))
 876           (error "Top filter is not an OR"))
 877         (let ((lim (pop ibuffer-filtering-qualifiers)))
 878           (setq ibuffer-filtering-qualifiers
 879                 (nconc (cdr lim) ibuffer-filtering-qualifiers))))
 880     (when (< (length ibuffer-filtering-qualifiers) 2)
 881       (error "Need two filters to OR"))
 882     ;; If the second filter is an OR, just add to it.
 883     (let ((first (pop ibuffer-filtering-qualifiers))
 884           (second (pop ibuffer-filtering-qualifiers)))
 885       (if (eq 'or (car second))
 886           (push (nconc (list 'or first) (cdr second))
 887                 ibuffer-filtering-qualifiers)
 888         (push (list 'or first second)
 889               ibuffer-filtering-qualifiers))))
 890   (ibuffer-update nil t))
 891
 892 (defun ibuffer-maybe-save-stuff ()
 893   (when ibuffer-save-with-custom
 894     (if (fboundp 'customize-save-variable)
 895         (progn
 896           (customize-save-variable 'ibuffer-saved-filters
 897                                    ibuffer-saved-filters)
 898           (customize-save-variable 'ibuffer-saved-filter-groups
 899                                    ibuffer-saved-filter-groups))
 900       (message "Not saved permanently: Customize not available"))))
 901
 902 ;;;###autoload
 903 (defun ibuffer-save-filters (name filters)
 904   "Save FILTERS in this buffer with name NAME in `ibuffer-saved-filters'.
 905 Interactively, prompt for NAME, and use the current filters."
 906   (interactive
 907    (if (null ibuffer-filtering-qualifiers)
 908        (error "No filters currently in effect")
 909      (list
 910       (read-from-minibuffer "Save current filters as: ")
 911       ibuffer-filtering-qualifiers)))
 912   (ibuffer-aif (assoc name ibuffer-saved-filters)
 913       (setcdr it filters)
 914     (push (list name filters) ibuffer-saved-filters))
 915   (ibuffer-maybe-save-stuff))
 916
 917 ;;;###autoload
 918 (defun ibuffer-delete-saved-filters (name)
 919   "Delete saved filters with NAME from `ibuffer-saved-filters'."
 920   (interactive
 921    (list
 922     (if (null ibuffer-saved-filters)
 923         (error "No saved filters")
 924       (completing-read "Delete saved filters: "
 925                        ibuffer-saved-filters nil t))))
 926   (setq ibuffer-saved-filters
 927         (ibuffer-delete-alist name ibuffer-saved-filters))
 928   (ibuffer-maybe-save-stuff)
 929   (ibuffer-update nil t))
 930
 931 ;;;###autoload
 932 (defun ibuffer-add-saved-filters (name)
 933   "Add saved filters from `ibuffer-saved-filters' to this buffer's filters."
 934   (interactive
 935    (list
 936     (if (null ibuffer-saved-filters)
 937         (error "No saved filters")
 938       (completing-read "Add saved filters: "
 939                        ibuffer-saved-filters nil t))))
 940   (push (cons 'saved name) ibuffer-filtering-qualifiers)
 941   (ibuffer-update nil t))
 942
 943 ;;;###autoload
 944 (defun ibuffer-switch-to-saved-filters (name)
 945   "Set this buffer's filters to filters with NAME from `ibuffer-saved-filters'."
 946   (interactive
 947    (list
 948     (if (null ibuffer-saved-filters)
 949         (error "No saved filters")
 950       (completing-read "Switch to saved filters: "
 951                        ibuffer-saved-filters nil t))))
 952   (setq ibuffer-filtering-qualifiers (list (cons 'saved name)))
 953   (ibuffer-update nil t))
 954
 955 (defun ibuffer-format-filter-group-data (filter)
 956   (if (equal filter "Default")
 957       ""
 958     (concat "Filter:" (mapconcat #'ibuffer-format-qualifier
 959                                  (cdr (assq filter ibuffer-filter-groups))
 960                                  " "))))
 961
 962 (defun ibuffer-format-qualifier (qualifier)
 963   (if (eq (car-safe qualifier) 'not)
 964       (concat " [NOT" (ibuffer-format-qualifier-1 (cdr qualifier)) "]")
 965     (ibuffer-format-qualifier-1 qualifier)))
 966
 967 (defun ibuffer-format-qualifier-1 (qualifier)
 968   (pcase (car qualifier)
 969     (`saved
 970      (concat " [filter: " (cdr qualifier) "]"))
 971     (`or
 972      (concat " [OR" (mapconcat #'ibuffer-format-qualifier
 973                                (cdr qualifier) "") "]"))
 974     (_
 975      (let ((type (assq (car qualifier) ibuffer-filtering-alist)))
 976        (unless qualifier
 977          (error "Ibuffer: bad qualifier %s" qualifier))
 978        (concat " [" (cadr type) ": " (format "%s]" (cdr qualifier)))))))
 979
 980
 981 (defun ibuffer-list-buffer-modes (&optional include-parents)
 982   "Create a completion table of buffer modes currently in use.
 983 If INCLUDE-PARENTS is non-nil then include parent modes."
 984   (let ((modes))
 985     (dolist (buf (buffer-list))
 986       (let ((this-mode (buffer-local-value 'major-mode buf)))
 987         (while (and this-mode (not (memq this-mode modes)))
 988           (push this-mode modes)
 989           (setq this-mode (and include-parents
 990                                (get this-mode 'derived-mode-parent))))))
 991     (mapcar #'symbol-name modes)))
 992
 993
 994 ;;; Extra operation definitions
 995
 996 ;;;###autoload (autoload 'ibuffer-filter-by-mode "ibuf-ext")
 997 (define-ibuffer-filter mode
 998   "Toggle current view to buffers with major mode QUALIFIER."
 999   (:description "major mode"
1000    :reader
1001    (let* ((buf (ibuffer-current-buffer))
1002           (default (if (and buf (buffer-live-p buf))
1003                        (symbol-name (buffer-local-value
1004                                      'major-mode buf)))))
1005      (intern
1006       (completing-read
1007        (if default
1008            (format "Filter by major mode (default %s): " default)
1009          "Filter by major mode: ")
1010        obarray
1011        #'(lambda (e)
1012            (string-match "-mode\\'" (symbol-name e)))
1013        t nil nil default))))
1014   (eq qualifier (buffer-local-value 'major-mode buf)))
1015
1016 ;;;###autoload (autoload 'ibuffer-filter-by-used-mode "ibuf-ext")
1017 (define-ibuffer-filter used-mode
1018   "Toggle current view to buffers with major mode QUALIFIER.
1019 Called interactively, this function allows selection of modes
1020 currently used by buffers."
1021   (:description "major mode in use"
1022    :reader
1023    (let* ((buf (ibuffer-current-buffer))
1024           (default (if (and buf (buffer-live-p buf))
1025                        (symbol-name (buffer-local-value
1026                                      'major-mode buf)))))
1027      (intern
1028       (completing-read
1029        (if default
1030            (format "Filter by major mode (default %s): " default)
1031          "Filter by major mode: ")
1032        (ibuffer-list-buffer-modes) nil t nil nil default))))
1033   (eq qualifier (buffer-local-value 'major-mode buf)))
1034
1035 ;;;###autoload (autoload 'ibuffer-filter-by-derived-mode "ibuf-ext")
1036 (define-ibuffer-filter derived-mode
1037     "Toggle current view to buffers whose major mode inherits from QUALIFIER."
1038   (:description "derived mode"
1039                 :reader
1040                 (intern
1041                  (completing-read "Filter by derived mode: "
1042                                   (ibuffer-list-buffer-modes t)
1043                                   nil t)))
1044   (with-current-buffer buf (derived-mode-p qualifier)))
1045
1046 ;;;###autoload (autoload 'ibuffer-filter-by-name "ibuf-ext")
1047 (define-ibuffer-filter name
1048   "Toggle current view to buffers with name matching QUALIFIER."
1049   (:description "buffer name"
1050    :reader (read-from-minibuffer "Filter by name (regexp): "))
1051   (string-match qualifier (buffer-name buf)))
1052
1053 ;;;###autoload (autoload 'ibuffer-filter-by-filename "ibuf-ext")
1054 (define-ibuffer-filter filename
1055   "Toggle current view to buffers with filename matching QUALIFIER."
1056   (:description "filename"
1057    :reader (read-from-minibuffer "Filter by filename (regexp): "))
1058   (ibuffer-awhen (with-current-buffer buf (ibuffer-buffer-file-name))
1059     (string-match qualifier it)))
1060
1061 ;;;###autoload (autoload 'ibuffer-filter-by-size-gt  "ibuf-ext")
1062 (define-ibuffer-filter size-gt
1063   "Toggle current view to buffers with size greater than QUALIFIER."
1064   (:description "size greater than"
1065    :reader
1066    (string-to-number (read-from-minibuffer "Filter by size greater than: ")))
1067   (> (with-current-buffer buf (buffer-size))
1068      qualifier))
1069
1070 ;;;###autoload (autoload 'ibuffer-filter-by-size-lt  "ibuf-ext")
1071 (define-ibuffer-filter size-lt
1072    "Toggle current view to buffers with size less than QUALIFIER."
1073   (:description "size less than"
1074    :reader
1075    (string-to-number (read-from-minibuffer "Filter by size less than: ")))
1076   (< (with-current-buffer buf (buffer-size))
1077      qualifier))
1078
1079 ;;;###autoload (autoload 'ibuffer-filter-by-content "ibuf-ext")
1080 (define-ibuffer-filter content
1081    "Toggle current view to buffers whose contents match QUALIFIER."
1082   (:description "content"
1083    :reader (read-from-minibuffer "Filter by content (regexp): "))
1084   (with-current-buffer buf
1085     (save-excursion
1086       (goto-char (point-min))
1087       (re-search-forward qualifier nil t))))
1088
1089 ;;;###autoload (autoload 'ibuffer-filter-by-predicate "ibuf-ext")
1090 (define-ibuffer-filter predicate
1091    "Toggle current view to buffers for which QUALIFIER returns non-nil."
1092   (:description "predicate"
1093    :reader (read-minibuffer "Filter by predicate (form): "))
1094   (with-current-buffer buf
1095     (eval qualifier)))
1096
1097 ;;; Sorting
1098
1099 ;;;###autoload
1100 (defun ibuffer-toggle-sorting-mode ()
1101   "Toggle the current sorting mode.
1102 Default sorting modes are:
1103  Recency - the last time the buffer was viewed
1104  Name - the name of the buffer
1105  Major Mode - the name of the major mode of the buffer
1106  Size - the size of the buffer"
1107   (interactive)
1108   (let ((modes (mapcar #'car ibuffer-sorting-functions-alist)))
1109     (cl-pushnew 'recency modes)
1110     (setq modes (sort modes #'string-lessp))
1111     (let ((next (or (car-safe (cdr-safe (memq ibuffer-sorting-mode modes)))
1112                     (car modes))))
1113       (setq ibuffer-sorting-mode next)
1114       (message "Sorting by %s" next)))
1115   (ibuffer-redisplay t))
1116
1117 ;;;###autoload
1118 (defun ibuffer-invert-sorting ()
1119   "Toggle whether or not sorting is in reverse order."
1120   (interactive)
1121   (setq ibuffer-sorting-reversep (not ibuffer-sorting-reversep))
1122   (message "Sorting order %s"
1123            (if ibuffer-sorting-reversep
1124                "reversed"
1125              "normal"))
1126   (ibuffer-redisplay t))
1127
1128 ;;;###autoload (autoload 'ibuffer-do-sort-by-major-mode "ibuf-ext")
1129 (define-ibuffer-sorter major-mode
1130   "Sort the buffers by major modes.
1131 Ordering is lexicographic."
1132   (:description "major mode")
1133   (string-lessp (downcase
1134                  (symbol-name (buffer-local-value 'major-mode (car a))))
1135                 (downcase
1136                  (symbol-name (buffer-local-value 'major-mode (car b))))))
1137
1138 ;;;###autoload (autoload 'ibuffer-do-sort-by-mode-name "ibuf-ext")
1139 (define-ibuffer-sorter mode-name
1140   "Sort the buffers by their mode name.
1141 Ordering is lexicographic."
1142   (:description "major mode name")
1143   (string-lessp (downcase
1144                  (with-current-buffer
1145                      (car a)
1146                    (format-mode-line mode-name)))
1147                 (downcase
1148                  (with-current-buffer
1149                      (car b)
1150                    (format-mode-line mode-name)))))
1151
1152 ;;;###autoload (autoload 'ibuffer-do-sort-by-alphabetic "ibuf-ext")
1153 (define-ibuffer-sorter alphabetic
1154   "Sort the buffers by their names.
1155 Ordering is lexicographic."
1156   (:description "buffer name")
1157   (string-lessp
1158    (buffer-name (car a))
1159    (buffer-name (car b))))
1160
1161 ;;;###autoload (autoload 'ibuffer-do-sort-by-size "ibuf-ext")
1162 (define-ibuffer-sorter size
1163  "Sort the buffers by their size."
1164   (:description "size")
1165   (< (with-current-buffer (car a)
1166        (buffer-size))
1167      (with-current-buffer (car b)
1168        (buffer-size))))
1169
1170 ;;;###autoload (autoload 'ibuffer-do-sort-by-filename/process "ibuf-ext")
1171 (define-ibuffer-sorter filename/process
1172  "Sort the buffers by their file name/process name."
1173   (:description "file name")
1174   (string-lessp
1175    ;; FIXME: For now just compare the file name and the process name
1176    ;; (if it exists).  Is there a better way to do this?
1177    (or (buffer-file-name (car a))
1178        (let ((pr-a (get-buffer-process (car a))))
1179          (and (processp pr-a) (process-name pr-a))))
1180    (or (buffer-file-name (car b))
1181        (let ((pr-b (get-buffer-process (car b))))
1182          (and (processp pr-b) (process-name pr-b))))))
1183
1184 ;;; Functions to emulate bs.el
1185
1186 ;;;###autoload
1187 (defun ibuffer-bs-show ()
1188   "Emulate `bs-show' from the bs.el package."
1189   (interactive)
1190   (ibuffer t "*Ibuffer-bs*" '((filename . ".*")) nil t)
1191   (define-key (current-local-map) "a" 'ibuffer-bs-toggle-all))
1192
1193 (defun ibuffer-bs-toggle-all ()
1194   "Emulate `bs-toggle-show-all' from the bs.el package."
1195   (interactive)
1196   (if ibuffer-filtering-qualifiers
1197       (ibuffer-pop-filter)
1198     (progn (ibuffer-push-filter '(filename . ".*"))
1199            (ibuffer-update nil t))))
1200
1201 ;;; Handy functions
1202
1203 ;;;###autoload
1204 (defun ibuffer-add-to-tmp-hide (regexp)
1205   "Add REGEXP to `ibuffer-tmp-hide-regexps'.
1206 This means that buffers whose name matches REGEXP will not be shown
1207 for this Ibuffer session."
1208   (interactive
1209    (list
1210     (read-from-minibuffer "Never show buffers matching: "
1211                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1212   (push regexp ibuffer-tmp-hide-regexps))
1213
1214 ;;;###autoload
1215 (defun ibuffer-add-to-tmp-show (regexp)
1216   "Add REGEXP to `ibuffer-tmp-show-regexps'.
1217 This means that buffers whose name matches REGEXP will always be shown
1218 for this Ibuffer session."
1219   (interactive
1220    (list
1221     (read-from-minibuffer "Always show buffers matching: "
1222                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1223   (push regexp ibuffer-tmp-show-regexps))
1224
1225 ;;;###autoload
1226 (defun ibuffer-forward-next-marked (&optional count mark direction)
1227   "Move forward by COUNT marked buffers (default 1).
1228
1229 If MARK is non-nil, it should be a character denoting the type of mark
1230 to move by.  The default is `ibuffer-marked-char'.
1231
1232 If DIRECTION is non-nil, it should be an integer; negative integers
1233 mean move backwards, non-negative integers mean move forwards."
1234   (interactive "P")
1235   (unless count
1236     (setq count 1))
1237   (unless mark
1238     (setq mark ibuffer-marked-char))
1239   (unless direction
1240     (setq direction 1))
1241   ;; Skip the title
1242   (ibuffer-forward-line 0)
1243   (let ((opos (point)))
1244     (ibuffer-forward-line direction)
1245     (while (not (or (= (point) opos)
1246                     (eq (ibuffer-current-mark) mark)))
1247       (ibuffer-forward-line direction))
1248     (when (and (= (point) opos)
1249                (not (eq (ibuffer-current-mark) mark)))
1250       (error "No buffers with mark %c" mark))))
1251
1252 ;;;###autoload
1253 (defun ibuffer-backwards-next-marked (&optional count mark)
1254    "Move backwards by COUNT marked buffers (default 1).
1255
1256 If MARK is non-nil, it should be a character denoting the type of mark
1257 to move by.  The default is `ibuffer-marked-char'."
1258    (interactive "P")
1259    (ibuffer-forward-next-marked count mark -1))
1260
1261 ;;;###autoload
1262 (defun ibuffer-do-kill-lines ()
1263   "Hide all of the currently marked lines."
1264   (interactive)
1265   (if (= (ibuffer-count-marked-lines) 0)
1266       (message "No buffers marked; use 'm' to mark a buffer")
1267     (let ((count
1268            (ibuffer-map-marked-lines
1269             #'(lambda (_buf _mark)
1270                 'kill))))
1271       (message "Killed %s lines" count))))
1272
1273 ;;;###autoload
1274 (defun ibuffer-jump-to-buffer (name)
1275   "Move point to the buffer whose name is NAME.
1276
1277 If called interactively, prompt for a buffer name and go to the
1278 corresponding line in the Ibuffer buffer.  If said buffer is in a
1279 hidden group filter, open it.
1280
1281 If `ibuffer-jump-offer-only-visible-buffers' is non-nil, only offer
1282 visible buffers in the completion list.  Calling the command with
1283 a prefix argument reverses the meaning of that variable."
1284   (interactive (list
1285                 (let ((only-visible ibuffer-jump-offer-only-visible-buffers))
1286                   (when current-prefix-arg
1287                     (setq only-visible (not only-visible)))
1288                   (if only-visible
1289                       (let ((table (mapcar #'(lambda (x)
1290                                                (buffer-name (car x)))
1291                                            (ibuffer-current-state-list))))
1292                         (when (null table)
1293                           (error "No buffers!"))
1294                         (completing-read "Jump to buffer: "
1295                                          table nil t))
1296                     (read-buffer "Jump to buffer: " nil t)))))
1297   (when (not (string= "" name))
1298     (let (buf-point)
1299       ;; Blindly search for our buffer: it is very likely that it is
1300       ;; not in a hidden filter group.
1301       (ibuffer-map-lines #'(lambda (buf _marks)
1302                              (when (string= (buffer-name buf) name)
1303                                (setq buf-point (point))
1304                                nil))
1305                          t nil)
1306       (when (and
1307              (null buf-point)
1308              (not (null ibuffer-hidden-filter-groups)))
1309         ;; We did not find our buffer.  It must be in a hidden filter
1310         ;; group, so go through all hidden filter groups to find it.
1311         (catch 'found
1312           (dolist (group ibuffer-hidden-filter-groups)
1313             (ibuffer-jump-to-filter-group group)
1314             (ibuffer-toggle-filter-group)
1315             (ibuffer-map-lines #'(lambda (buf _marks)
1316                                    (when (string= (buffer-name buf) name)
1317                                      (setq buf-point (point))
1318                                      nil))
1319                                t group)
1320             (if buf-point
1321                 (throw 'found nil)
1322               (ibuffer-toggle-filter-group)))))
1323       (if (null buf-point)
1324           ;; Still not found even though we expanded all hidden filter
1325           ;; groups: that must be because it's hidden by predicate:
1326           ;; we won't bother trying to display it.
1327           (error "No buffer with name %s" name)
1328         (goto-char buf-point)))))
1329
1330 (declare-function diff-sentinel "diff"
1331                   (code &optional old-temp-file new-temp-file))
1332
1333 (defun ibuffer-diff-buffer-with-file-1 (buffer)
1334   (let ((bufferfile (buffer-local-value 'buffer-file-name buffer))
1335         (tempfile (make-temp-file "buffer-content-")))
1336     (when bufferfile
1337       (unwind-protect
1338           (progn
1339             (with-current-buffer buffer
1340               (write-region nil nil tempfile nil 'nomessage))
1341             (let* ((old (expand-file-name bufferfile))
1342                    (new (expand-file-name tempfile))
1343                    (oldtmp (file-local-copy old))
1344                    (newtmp (file-local-copy new))
1345                    (switches diff-switches)
1346                    (command
1347                     (mapconcat
1348                      'identity
1349                      `(,diff-command
1350                        ;; Use explicitly specified switches
1351                        ,@(if (listp switches) switches (list switches))
1352                        ,@(if (or old new)
1353                              (list "-L" (shell-quote-argument old)
1354                                    "-L" (shell-quote-argument
1355                                          (format "Buffer %s" (buffer-name buffer)))))
1356                        ,(shell-quote-argument (or oldtmp old))
1357                        ,(shell-quote-argument (or newtmp new)))
1358                      " ")))
1359               (let ((inhibit-read-only t))
1360                 (insert command "\n")
1361                 (diff-sentinel
1362                  (call-process shell-file-name nil
1363                                (current-buffer) nil
1364                                shell-command-switch command))
1365                 (insert "\n")))))
1366       (sit-for 0)
1367       (when (file-exists-p tempfile)
1368         (delete-file tempfile)))))
1369
1370 ;;;###autoload
1371 (defun ibuffer-diff-with-file ()
1372   "View the differences between marked buffers and their associated files.
1373 If no buffers are marked, use buffer at point.
1374 This requires the external program \"diff\" to be in your `exec-path'."
1375   (interactive)
1376   (require 'diff)
1377   (let ((marked-bufs (ibuffer-get-marked-buffers)))
1378     (when (null marked-bufs)
1379       (setq marked-bufs (list (ibuffer-current-buffer t))))
1380     (with-current-buffer (get-buffer-create "*Ibuffer Diff*")
1381       (setq buffer-read-only nil)
1382       (buffer-disable-undo (current-buffer))
1383       (erase-buffer)
1384       (buffer-enable-undo (current-buffer))
1385       (diff-mode)
1386       (dolist (buf marked-bufs)
1387         (unless (buffer-live-p buf)
1388           (error "Buffer %s has been killed" buf))
1389         (ibuffer-diff-buffer-with-file-1 buf))
1390       (setq buffer-read-only t)))
1391   (switch-to-buffer "*Ibuffer Diff*"))
1392
1393 ;;;###autoload
1394 (defun ibuffer-copy-filename-as-kill (&optional arg)
1395   "Copy filenames of marked buffers into the kill ring.
1396
1397 The names are separated by a space.
1398 If a buffer has no filename, it is ignored.
1399
1400 With no prefix arg, use the filename sans its directory of each marked file.
1401 With a zero prefix arg, use the complete filename of each marked file.
1402 With \\[universal-argument], use the filename of each marked file relative
1403 to `ibuffer-default-directory' if non-nil, otherwise `default-directory'.
1404
1405 You can then feed the file name(s) to other commands with \\[yank]."
1406   (interactive "p")
1407   (if (zerop (ibuffer-count-marked-lines))
1408       (message "No buffers marked; use 'm' to mark a buffer")
1409     (let ((ibuffer-copy-filename-as-kill-result "")
1410           (type (cond ((or (null arg) (zerop arg))
1411                        'full)
1412                       ((= arg 4)
1413                        'relative)
1414                       (t
1415                        'name))))
1416       (ibuffer-map-marked-lines
1417        #'(lambda (buf _mark)
1418            (setq ibuffer-copy-filename-as-kill-result
1419                  (concat ibuffer-copy-filename-as-kill-result
1420                          (let ((name (buffer-file-name buf)))
1421                            (cond (name
1422                                   (concat
1423                                    (pcase type
1424                                      (`full
1425                                       name)
1426                                      (`relative
1427                                       (file-relative-name
1428                                        name (or ibuffer-default-directory
1429                                                 default-directory)))
1430                                      (_
1431                                       (file-name-nondirectory name))) " "))
1432                                  (t "")))))))
1433       (when (not (zerop (length ibuffer-copy-filename-as-kill-result)))
1434         (setq ibuffer-copy-filename-as-kill-result
1435               (substring ibuffer-copy-filename-as-kill-result 0 -1)))
1436       (kill-new ibuffer-copy-filename-as-kill-result))))
1437
1438 (defun ibuffer-mark-on-buffer (func &optional ibuffer-mark-on-buffer-mark group)
1439   (let ((count
1440          (ibuffer-map-lines
1441           #'(lambda (buf _mark)
1442               (when (funcall func buf)
1443                 (ibuffer-set-mark-1 (or ibuffer-mark-on-buffer-mark
1444                                         ibuffer-marked-char))
1445                 t))
1446           nil
1447           group)))
1448     (ibuffer-redisplay t)
1449     (unless (eq ibuffer-mark-on-buffer-mark ?\s)
1450       (message "Marked %s buffers" count))))
1451
1452 ;;;###autoload
1453 (defun ibuffer-mark-by-name-regexp (regexp)
1454   "Mark all buffers whose name matches REGEXP."
1455   (interactive "sMark by name (regexp): ")
1456   (ibuffer-mark-on-buffer
1457    #'(lambda (buf)
1458        (string-match regexp (buffer-name buf)))))
1459
1460 ;;;###autoload
1461 (defun ibuffer-mark-by-mode-regexp (regexp)
1462   "Mark all buffers whose major mode matches REGEXP."
1463   (interactive "sMark by major mode (regexp): ")
1464   (ibuffer-mark-on-buffer
1465    #'(lambda (buf)
1466        (with-current-buffer buf
1467          (string-match regexp (format-mode-line mode-name nil nil buf))))))
1468
1469 ;;;###autoload
1470 (defun ibuffer-mark-by-file-name-regexp (regexp)
1471   "Mark all buffers whose file name matches REGEXP."
1472   (interactive "sMark by file name (regexp): ")
1473   (ibuffer-mark-on-buffer
1474    #'(lambda (buf)
1475        (let ((name (or (buffer-file-name buf)
1476                        (with-current-buffer buf
1477                          (and
1478                           (boundp 'dired-directory)
1479                           (stringp dired-directory)
1480                           dired-directory)))))
1481          (when name
1482            (string-match regexp name))))))
1483
1484 ;;;###autoload
1485 (defun ibuffer-mark-by-mode (mode)
1486   "Mark all buffers whose major mode equals MODE."
1487   (interactive
1488    (let* ((buf (ibuffer-current-buffer))
1489           (default (if (and buf (buffer-live-p buf))
1490                        (symbol-name (buffer-local-value
1491                                      'major-mode buf)))))
1492      (list (intern
1493             (completing-read
1494              (if default
1495                  (format "Mark by major mode (default %s): " default)
1496                "Mark by major mode: ")
1497              (ibuffer-list-buffer-modes) nil t nil nil default)))))
1498   (ibuffer-mark-on-buffer
1499    #'(lambda (buf)
1500        (eq (buffer-local-value 'major-mode buf) mode))))
1501
1502 ;;;###autoload
1503 (defun ibuffer-mark-modified-buffers ()
1504   "Mark all modified buffers."
1505   (interactive)
1506   (ibuffer-mark-on-buffer
1507    #'(lambda (buf) (buffer-modified-p buf))))
1508
1509 ;;;###autoload
1510 (defun ibuffer-mark-unsaved-buffers ()
1511   "Mark all modified buffers that have an associated file."
1512   (interactive)
1513   (ibuffer-mark-on-buffer
1514    #'(lambda (buf) (and (buffer-local-value 'buffer-file-name buf)
1515                         (buffer-modified-p buf)))))
1516
1517 ;;;###autoload
1518 (defun ibuffer-mark-dissociated-buffers ()
1519   "Mark all buffers whose associated file does not exist."
1520   (interactive)
1521   (ibuffer-mark-on-buffer
1522    #'(lambda (buf)
1523        (with-current-buffer buf
1524          (or
1525           (and buffer-file-name
1526                (not (file-exists-p buffer-file-name)))
1527           (and (eq major-mode 'dired-mode)
1528                (boundp 'dired-directory)
1529                (stringp dired-directory)
1530                (not (file-exists-p (file-name-directory dired-directory)))))))))
1531
1532 ;;;###autoload
1533 (defun ibuffer-mark-help-buffers ()
1534   "Mark buffers whose major mode is in variable `ibuffer-help-buffer-modes'."
1535   (interactive)
1536   (ibuffer-mark-on-buffer
1537    #'(lambda (buf)
1538        (with-current-buffer buf
1539          (memq major-mode ibuffer-help-buffer-modes)))))
1540
1541 ;;;###autoload
1542 (defun ibuffer-mark-compressed-file-buffers ()
1543   "Mark buffers whose associated file is compressed."
1544   (interactive)
1545   (ibuffer-mark-on-buffer
1546    #'(lambda (buf)
1547        (with-current-buffer buf
1548          (and buffer-file-name
1549               (string-match ibuffer-compressed-file-name-regexp
1550                            buffer-file-name))))))
1551
1552 ;;;###autoload
1553 (defun ibuffer-mark-old-buffers ()
1554   "Mark buffers which have not been viewed in `ibuffer-old-time' hours."
1555   (interactive)
1556   (ibuffer-mark-on-buffer
1557    #'(lambda (buf)
1558        (with-current-buffer buf
1559          ;; hacked from midnight.el
1560          (when buffer-display-time
1561            (let* ((now (float-time))
1562                   (then (float-time buffer-display-time)))
1563              (> (- now then) (* 60 60 ibuffer-old-time))))))))
1564
1565 ;;;###autoload
1566 (defun ibuffer-mark-special-buffers ()
1567   "Mark all buffers whose name begins and ends with `*'."
1568   (interactive)
1569   (ibuffer-mark-on-buffer
1570    #'(lambda (buf) (string-match "^\\*.+\\*$"
1571                                  (buffer-name buf)))))
1572
1573 ;;;###autoload
1574 (defun ibuffer-mark-read-only-buffers ()
1575   "Mark all read-only buffers."
1576   (interactive)
1577   (ibuffer-mark-on-buffer
1578    #'(lambda (buf) (buffer-local-value 'buffer-read-only buf))))
1579
1580 ;;;###autoload
1581 (defun ibuffer-mark-dired-buffers ()
1582   "Mark all `dired' buffers."
1583   (interactive)
1584   (ibuffer-mark-on-buffer
1585    #'(lambda (buf) (eq (buffer-local-value 'major-mode buf) 'dired-mode))))
1586
1587 ;;;###autoload
1588 (defun ibuffer-do-occur (regexp &optional nlines)
1589   "View lines which match REGEXP in all marked buffers.
1590 Optional argument NLINES says how many lines of context to display: it
1591 defaults to one."
1592   (interactive (occur-read-primary-args))
1593   (if (or (not (integerp nlines))
1594           (< nlines 0))
1595       (setq nlines 0))
1596   (when (zerop (ibuffer-count-marked-lines))
1597     (ibuffer-set-mark ibuffer-marked-char))
1598   (let ((ibuffer-do-occur-bufs nil))
1599     ;; Accumulate a list of marked buffers
1600     (ibuffer-map-marked-lines
1601      #'(lambda (buf _mark)
1602          (push buf ibuffer-do-occur-bufs)))
1603     (occur-1 regexp nlines ibuffer-do-occur-bufs)))
1604
1605 (provide 'ibuf-ext)
1606
1607 ;; Local Variables:
1608 ;; generated-autoload-file: "ibuffer-loaddefs.el"
1609 ;; End:
1610
1611 ;;; ibuf-ext.el ends here