code.delx.au - gnu-emacs/blob - lisp/double.el

   1 ;;; double.el --- support for keyboard remapping with double clicking
   2
   3 ;; Copyright (C) 1994, 1997, 1998 Free Software Foundation, Inc.
   4
   5 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   6 ;; Keywords: i18n
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This mode is intended for use with languages that adds a small
  28 ;; number of extra letters not available on the keyboard.
  29 ;;
  30 ;; Examples includes Scandinavian and German with an US keyboard.
  31 ;;
  32 ;; The idea is that certain keys are overloaded.  When you press it
  33 ;; once it will insert one string, and when you press it twice the
  34 ;; string will be replaced by another.  This can be used for mapping
  35 ;; keys on a US keyboard to generate characters according to the local
  36 ;; keyboard convention when pressed once, and according to US keyboard
  37 ;; convention when pressed twice.
  38 ;;
  39 ;; To use this mode, you must define the variable `double-map' and
  40 ;; then enable double mode with `M-x double-mode'.  Read the
  41 ;; documentation for both of them.
  42 ;;
  43 ;; The default mapping is for getting Danish/Norwegian keyboard layout
  44 ;; using ISO Latin 1 on a US keyboard.
  45 ;;
  46 ;; Important node: While I would like to hear comments, bug reports,
  47 ;; suggestions, please do @strong{not} expect me to put other mappings
  48 ;; than the default into this file.  There are billions and billions
  49 ;; of such mappings, and just supporting the most common would
  50 ;; increase the size of this nice small file manyfold.
  51
  52 ;;; Code:
  53
  54 (defgroup double nil
  55   "Remap keyboard, but get original by typing the same key twice."
  56   :group 'i18n)
  57
  58 (defcustom double-map
  59   '((?\; "\346" ";")
  60     (?\' "\370" "'")
  61     (?\[ "\345" "[")
  62     (?\: "\306" ":")
  63     (?\" "\330" "\"")
  64     (?\{ "\305" "{"))
  65   "Alist of key translations activated by double mode.
  66
  67 Each entry is a list with three elements:
  68 1. The key activating the translation.
  69 2. The string to be inserted when the key is pressed once.
  70 3. The string to be inserted when the key is pressed twice."
  71   :group 'double
  72   :type '(repeat (list (character :tag "Key")
  73                        (string :tag "Once")
  74                        (string :tag "Twice"))))
  75
  76 (defcustom double-prefix-only t
  77   "*Non-nil means that Double mode mapping only works for prefix keys.
  78 That is, for any key `X' in `double-map', `X' alone will be mapped
  79 but not `C-u X' or `ESC X' since the X is not the prefix key."
  80   :group 'double
  81   :type 'boolean)
  82
  83 ;;; Read Event
  84
  85 (defvar double-last-event nil)
  86 ;; The last key that generated a double key event.
  87
  88 (defun double-read-event (prompt)
  89   ;; Read an event
  90   (if isearch-mode (isearch-update))
  91   (if prompt
  92       (prog2 (message "%s%c" prompt double-last-event)
  93           (read-event)
  94         (message ""))
  95     (read-event)))
  96
  97 (global-set-key [ignore] '(lambda () (interactive)))
  98
  99 (or (boundp 'isearch-mode-map)
 100     (load-library "isearch"))
 101
 102 (define-key isearch-mode-map [ignore]
 103   (function (lambda () (interactive) (isearch-update))))
 104
 105 (defun double-translate-key (prompt)
 106   ;; Translate input events using double map.
 107   (let ((key last-input-char))
 108     (cond (unread-command-events
 109            ;; Artificial event, ignore it.
 110            (vector key))
 111           ((and double-prefix-only
 112                 (> (length (this-command-keys)) 1))
 113            ;; This is not a prefix key, ignore it.
 114            (vector key))
 115           ((eq key 'magic-start)
 116            ;; End of generated event.  See if he will repeat it...
 117            (let ((new (double-read-event prompt))
 118                  (entry (assoc double-last-event double-map)))
 119              (force-window-update (selected-window))
 120              (if (eq new double-last-event)
 121                  (progn
 122                    (setq unread-command-events
 123                          (append (make-list (1- (length (nth 1 entry)))
 124                                             127)
 125                                  (nth 2 entry)
 126                                  '(magic-end)))
 127                    (vector 127))
 128                (setq unread-command-events (list new))
 129                [ignore])))
 130           ((eq key 'magic-end)
 131            ;; End of double event.  Ignore.
 132            [ignore])
 133           (t
 134            ;; New key.
 135            (let ((exp (nth 1 (assoc key double-map))))
 136              (setq double-last-event key)
 137              (setq unread-command-events
 138                    (append (substring exp 1) '(magic-start)))
 139              (vector (aref exp 0)))))))
 140
 141 ;;; Key Translation Map
 142
 143 (defun double-setup (enable-flag)
 144   (if enable-flag
 145       (progn
 146         ;; Set up key-translation-map as indicated by `double-map'.
 147         ;; XXX I don't think global-key-translation-map should be made local here. -- Lorentey
 148         (kill-local-variable 'global-key-translation-map)
 149         (make-local-variable 'global-key-translation-map)
 150         (setq global-key-translation-map (if (keymapp global-key-translation-map)
 151                                              (copy-keymap global-key-translation-map)
 152                                            (make-sparse-keymap)))
 153         (mapcar (function (lambda (entry)
 154                             (define-key global-key-translation-map
 155                               (vector (nth 0 entry))
 156                               'double-translate-key)))
 157                 (append double-map '((magic-start) (magic-end)))))
 158     (kill-local-variable 'global-key-translation-map)))
 159
 160 ;;; Mode
 161
 162 ;;;###autoload
 163 (defcustom double-mode nil
 164   "Toggle Double mode.
 165 Setting this variable directly does not take effect;
 166 use either \\[customize] or the function `double-mode'."
 167   :set (lambda (symbol value)
 168          (double-mode (if value 1 0)))
 169   :initialize 'custom-initialize-default
 170   :link '(emacs-commentary-link "double")
 171   :type 'boolean
 172   :require 'double
 173   :group 'double)
 174 (make-variable-buffer-local 'double-mode)
 175
 176 (or (assq 'double-mode minor-mode-alist)
 177     (setq minor-mode-alist
 178           (cons '(double-mode " Double") minor-mode-alist)))
 179
 180 ;; This feature seemed useless and it confused describe-mode,
 181 ;;  so I deleted it.
 182 ;;;(defvar double-mode-name "Double")
 183 ;;;;; Name of current double mode.
 184 ;;; (make-variable-buffer-local 'double-mode-name)
 185
 186 ;;;###autoload
 187 (defun double-mode (arg)
 188   "Toggle Double mode.
 189 With prefix arg, turn Double mode on iff arg is positive.
 190
 191 When Double mode is on, some keys will insert different strings
 192 when pressed twice.  See variable `double-map' for details."
 193   (interactive "P")
 194   (if (or (and (null arg) double-mode)
 195           (<= (prefix-numeric-value arg) 0))
 196       ;; Turn it off
 197       (if double-mode
 198           (progn
 199             (let ((double-map))
 200               (double-setup nil))
 201             (setq double-mode nil)
 202             (force-mode-line-update)))
 203     ;;Turn it on
 204     (if double-mode
 205         ()
 206       (double-setup t)
 207       (setq double-mode t)
 208       (force-mode-line-update))))
 209
 210 (provide 'double)
 211
 212 ;;; arch-tag: 2e170036-44cb-4493-bc32-ada0a4395221
 213 ;;; double.el ends here