code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.3.50)
  26 dnl This is the documented way to record the args passed to configure,
  27 dnl rather than $ac_configure_args.
  28 emacs_config_options="$@"
  29 AC_CONFIG_HEADER(src/config.h:src/config.in)
  30 AC_CONFIG_SRCDIR(src/lisp.h)
  31 AC_CONFIG_AUX_DIR(build-aux)
  32 dnl Fairly arbitrary, older versions might work too.
  33 AM_INIT_AUTOMAKE(1.11)
  34
  35 dnl Support for --program-prefix, --program-suffix and
  36 dnl --program-transform-name options
  37 AC_ARG_PROGRAM
  38
  39 dnl It is important that variables on the RHS not be expanded here,
  40 dnl hence the single quotes.  This is per the GNU coding standards, see
  41 dnl (autoconf) Installation Directory Variables
  42 dnl See also epaths.h below.
  43 lispdir='${datadir}/emacs/${version}/lisp'
  44 leimdir='${datadir}/emacs/${version}/leim'
  45 standardlisppath='${lispdir}:${leimdir}'
  46 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  47 '${datadir}/emacs/site-lisp'
  48 lisppath='${locallisppath}:${standardlisppath}'
  49 etcdir='${datadir}/emacs/${version}/etc'
  50 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  51 docdir='${datadir}/emacs/${version}/etc'
  52 gamedir='${localstatedir}/games/emacs'
  53
  54 dnl Special option to disable the most of other options.
  55 AC_ARG_WITH(all,
  56 [AS_HELP_STRING([--without-all],
  57                 [omit almost all features and build
  58                 small executable with minimal dependencies])],
  59   with_features=$withval,
  60   with_features=yes)
  61
  62 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  63 dnl Create a new --with option that defaults to being disabled.
  64 dnl NAME is the base name of the option.  The shell variable with_NAME
  65 dnl   will be set to either the user's value (if the option is
  66 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  67 dnl   option is not specified).  Note that the shell variable name is
  68 dnl   constructed as autoconf does, by replacing non-alphanumeric
  69 dnl   characters with "_".
  70 dnl HELP-STRING is the help text for the option.
  71 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  72   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  73     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  74 ])dnl
  75
  76 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  77 dnl Create a new --with option that defaults to $enable_features.
  78 dnl NAME is the base name of the option.  The shell variable with_NAME
  79 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  80 dnl   'yes' (if the option is not specified).  Note that the shell
  81 dnl   variable name is constructed as autoconf does, by replacing
  82 dnl   non-alphanumeric characters with "_".
  83 dnl HELP-STRING is the help text for the option.
  84 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  85   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  86    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
  87 ])dnl
  88
  89 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  90 if test "$with_pop" = yes; then
  91    AC_DEFINE(MAIL_USE_POP)
  92 fi
  93 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  94
  95 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  96 if test "$with_kerberos" != no; then
  97    AC_DEFINE(KERBEROS)
  98 fi
  99 AH_TEMPLATE(KERBEROS,
 100             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 101
 102 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 103 if test "${with_kerberos5}" != no; then
 104   if test "${with_kerberos}" = no; then
 105     with_kerberos=yes
 106     AC_DEFINE(KERBEROS)
 107   fi
 108   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 109 fi
 110
 111 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 112 dnl FIXME hesiod support may not be present, so it seems like an error
 113 dnl to define, or at least use, this unconditionally.
 114 if test "$with_hesiod" != no; then
 115   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 116 fi
 117
 118 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 119 if test "$with_mmdf" != no; then
 120    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 121 fi
 122
 123 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 124 if test "$with_mail_unlink" != no; then
 125    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 126 fi
 127
 128 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 129     [string giving default POP mail host])],
 130     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 131
 132 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 133
 134 dnl FIXME currently it is not the last.
 135 dnl This should be the last --with option, because --with-x is
 136 dnl added later on when we find the file name of X, and it's best to
 137 dnl keep them together visually.
 138 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 139  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 140 [         case "${withval}" in
 141             y | ye | yes )      val=gtk ;;
 142             n | no )            val=no  ;;
 143             l | lu | luc | luci | lucid )       val=lucid ;;
 144             a | at | ath | athe | athen | athena )      val=athena ;;
 145             m | mo | mot | moti | motif )       val=motif ;;
 146             g | gt | gtk  )     val=gtk ;;
 147             gtk2  )     val=gtk2 ;;
 148             gtk3  )     val=gtk3 ;;
 149             * )
 150 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 151 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
 152 `gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
 153 `athena' and `lucid' are synonyms.])
 154             ;;
 155           esac
 156           with_x_toolkit=$val
 157 ])
 158
 159 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 160 if test "$with_wide_int" = yes; then
 161   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 162 fi
 163
 164 dnl _ON results in a '--without' option in the --help output, so
 165 dnl the help text should refer to "don't compile", etc.
 166 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 167 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 168 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 169 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 170 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 171 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 172 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 173 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 174
 175 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 176 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 177 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 178
 179 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 180 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 181 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 182 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 183 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI])
 184
 185 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 186 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 187 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 188 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 189 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 190 OPTION_DEFAULT_ON([acl],[don't compile with ACL support])
 191 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 192 OPTION_DEFAULT_ON([inotify],[don't compile with inotify (file-watch) support])
 193
 194 ## For the times when you want to build Emacs but don't have
 195 ## a suitable makeinfo, and can live without the manuals.
 196 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 197 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 198
 199 ## Makefile.in needs the cache file name.
 200 AC_SUBST(cache_file)
 201
 202 ## This is an option because I do not know if all info/man support
 203 ## compressed files, nor how to test if they do so.
 204 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 205 if test $with_compress_info = yes; then
 206    GZIP_INFO=yes
 207 else
 208    GZIP_INFO=
 209 fi
 210 AC_SUBST(GZIP_INFO)
 211
 212 AC_ARG_WITH([pkg-config-prog],dnl
 213 [AS_HELP_STRING([--with-pkg-config-prog=FILENAME],
 214                   [file name of pkg-config for finding GTK and librsvg])])
 215 if test "X${with_pkg_config_prog}" != X; then
 216    if test "${with_pkg_config_prog}" != yes; then
 217       PKG_CONFIG="${with_pkg_config_prog}"
 218    fi
 219 fi
 220
 221 CRT_DIR=
 222 AC_ARG_WITH([crt-dir],dnl
 223 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 224 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 225 CRT_DIR="${with_crt_dir}"
 226
 227 AC_ARG_WITH(gameuser,dnl
 228 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 229 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 230   && gameuser="${with_gameuser}"
 231 test "X$gameuser" = X && gameuser=games
 232
 233 AC_ARG_WITH([gnustep-conf],dnl
 234 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 235    [name of GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 236 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 237   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 238 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 239      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 240
 241 AC_ARG_ENABLE(ns-self-contained,
 242 [AS_HELP_STRING([--disable-ns-self-contained],
 243                 [disable self contained build under NeXTstep])],
 244    EN_NS_SELF_CONTAINED=$enableval,
 245    EN_NS_SELF_CONTAINED=yes)
 246
 247 AC_ARG_ENABLE(locallisppath,
 248 [AS_HELP_STRING([--enable-locallisppath=PATH],
 249                 [directories Emacs should search for lisp files specific
 250                  to this site])],
 251 if test "${enableval}" = "no"; then
 252   locallisppath=
 253 elif test "${enableval}" != "yes"; then
 254   locallisppath=${enableval}
 255 fi)
 256
 257 AC_ARG_ENABLE(checking,
 258 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 259                 [enable expensive run-time checks.  With LIST,
 260                  enable only specific categories of checks.
 261                  Categories are: all,yes,no.
 262                  Flags are: stringbytes, stringoverrun, stringfreelist,
 263                  xmallocoverrun, conslist, glyphs])],
 264 [ac_checking_flags="${enableval}"],[])
 265 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 266 for check in $ac_checking_flags
 267 do
 268         case $check in
 269         # these set all the flags to specific states
 270         yes)            ac_enable_checking=1 ;;
 271         no)             ac_enable_checking= ;
 272                         ac_gc_check_stringbytes= ;
 273                         ac_gc_check_string_overrun= ;
 274                         ac_gc_check_string_free_list= ;
 275                         ac_xmalloc_overrun= ;
 276                         ac_gc_check_cons_list= ;
 277                         ac_glyphs_debug= ;;
 278         all)            ac_enable_checking=1 ;
 279                         ac_gc_check_stringbytes=1 ;
 280                         ac_gc_check_string_overrun=1 ;
 281                         ac_gc_check_string_free_list=1 ;
 282                         ac_xmalloc_overrun=1 ;
 283                         ac_gc_check_cons_list=1 ;
 284                         ac_glyphs_debug=1 ;;
 285         # these enable particular checks
 286         stringbytes)    ac_gc_check_stringbytes=1 ;;
 287         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 288         stringfreelist) ac_gc_check_string_free_list=1 ;;
 289         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 290         conslist)       ac_gc_check_cons_list=1 ;;
 291         glyphs)         ac_glyphs_debug=1 ;;
 292         *)      AC_MSG_ERROR(unknown check category $check) ;;
 293         esac
 294 done
 295 IFS="$ac_save_IFS"
 296
 297 if test x$ac_enable_checking != x ; then
 298   AC_DEFINE(ENABLE_CHECKING, 1,
 299 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 300 fi
 301 if test x$ac_gc_check_stringbytes != x ; then
 302   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 303 [Define this temporarily to hunt a bug.  If defined, the size of
 304    strings is redundantly recorded in sdata structures so that it can
 305    be compared to the sizes recorded in Lisp strings.])
 306 fi
 307 if test x$ac_gc_check_string_overrun != x ; then
 308   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 309 [Define this to check for short string overrun.])
 310 fi
 311 if test x$ac_gc_check_string_free_list != x ; then
 312   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 313 [Define this to check the string free list.])
 314 fi
 315 if test x$ac_xmalloc_overrun != x ; then
 316   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 317 [Define this to check for malloc buffer overrun.])
 318 fi
 319 if test x$ac_gc_check_cons_list != x ; then
 320   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 321 [Define this to check for errors in cons list.])
 322 fi
 323 if test x$ac_glyphs_debug != x ; then
 324   AC_DEFINE(GLYPH_DEBUG, 1,
 325 [Define this to enable glyphs debugging code.])
 326 fi
 327
 328 AC_ARG_ENABLE(check-lisp-object-type,
 329 [AS_HELP_STRING([--enable-check-lisp-object-type],
 330                 [enable compile time checks for the Lisp_Object data type.
 331                 This is useful for development for catching certain types of bugs.])],
 332 if test "${enableval}" != "no"; then
 333    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 334    [Define this to enable compile time checks for the Lisp_Object data type.])
 335 fi)
 336
 337
 338 dnl The name of this option is unfortunate.  It predates, and has no
 339 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 340 dnl Actually, it stops it working.
 341 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 342 AC_ARG_ENABLE(profiling,
 343 [AS_HELP_STRING([--enable-profiling],
 344                 [build emacs with low-level, gprof profiling support.
 345                 Mainly useful for debugging Emacs itself.  May not work on
 346                 all platforms.  Stops profiler.el working.])],
 347 [ac_enable_profiling="${enableval}"],[])
 348 if test x$ac_enable_profiling != x ; then
 349    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 350 else
 351    PROFILING_CFLAGS=
 352 fi
 353 AC_SUBST(PROFILING_CFLAGS)
 354
 355 AC_ARG_ENABLE(autodepend,
 356 [AS_HELP_STRING([--enable-autodepend],
 357                 [automatically generate dependencies to .h-files.
 358                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 359                  found])],
 360 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 361
 362 #### Make srcdir absolute, if it isn't already.  It's important to
 363 #### avoid running the file name through pwd unnecessarily, since pwd can
 364 #### give you automounter prefixes, which can go away.  We do all this
 365 #### so Emacs can find its files when run uninstalled.
 366 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 367 unset CDPATH
 368 case "${srcdir}" in
 369   /* ) ;;
 370   . )
 371     ## We may be able to use the $PWD environment variable to make this
 372     ## absolute.  But sometimes PWD is inaccurate.
 373     ## Note: we used to use $PWD at the end instead of `pwd`,
 374     ## but that tested only for a well-formed and valid PWD,
 375     ## it did not object when PWD was well-formed and valid but just wrong.
 376     if test ".$PWD" != "." && test ".`(cd "$PWD" ; sh -c pwd)`" = ".`pwd`"  ;
 377     then
 378       srcdir="$PWD"
 379     else
 380       srcdir=`(cd "$srcdir"; pwd)`
 381     fi
 382   ;;
 383   *  ) srcdir=`(cd "$srcdir"; pwd)` ;;
 384 esac
 385
 386 ### Canonicalize the configuration name.
 387
 388 AC_CANONICAL_HOST
 389 canonical=$host
 390 configuration=${host_alias-${build_alias-$host}}
 391
 392 dnl This used to use changequote, but, apart from `changequote is evil'
 393 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 394 dnl the great gob of text.  Thus it's not processed for possible expansion.
 395 dnl Just make sure the brackets remain balanced.
 396 dnl
 397 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 398 dnl indicated by comments.
 399 dnl quotation begins
 400 [
 401
 402 ### If you add support for a new configuration, add code to this
 403 ### switch statement to recognize your configuration name and select
 404 ### the appropriate operating system file.
 405
 406 ### You would hope that you could choose an s/*.h
 407 ### file based on the operating system portion.  However, it turns out
 408 ### that each s/*.h file is pretty manufacturer-specific.
 409 ### So we basically have to have a special case for each
 410 ### configuration name.
 411 ###
 412 ### As far as handling version numbers on operating systems is
 413 ### concerned, make sure things will fail in a fixable way.  If
 414 ### /etc/MACHINES doesn't say anything about version numbers, be
 415 ### prepared to handle anything reasonably.  If version numbers
 416 ### matter, be sure /etc/MACHINES says something about it.
 417
 418 opsys='' unported=no
 419 case "${canonical}" in
 420
 421   ## GNU/Linux and similar ports
 422   *-*-linux* )
 423     opsys=gnu-linux
 424   ;;
 425
 426   ## FreeBSD ports
 427   *-*-freebsd* )
 428     opsys=freebsd
 429   ;;
 430
 431   ## FreeBSD kernel + glibc based userland
 432   *-*-kfreebsd*gnu* )
 433     opsys=gnu-kfreebsd
 434   ;;
 435
 436   ## NetBSD ports
 437   *-*-netbsd* )
 438     opsys=netbsd
 439   ;;
 440
 441   ## OpenBSD ports
 442   *-*-openbsd* )
 443     opsys=openbsd
 444   ;;
 445
 446   ## Apple Darwin / Mac OS X
 447   *-apple-darwin* )
 448     case "${canonical}" in
 449       i[3456]86-* )  ;;
 450       powerpc-* )    ;;
 451       x86_64-* )     ;;
 452       * )            unported=yes ;;
 453     esac
 454     opsys=darwin
 455     ## Use fink packages if available.
 456     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 457 ##    if test -d /sw/include && test -d /sw/lib; then
 458 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 459 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 460 ##    fi
 461   ;;
 462
 463   ## HP 9000 series 700 and 800, running HP/UX
 464   hppa*-hp-hpux10.2* )
 465     opsys=hpux10-20
 466   ;;
 467   hppa*-hp-hpux1[1-9]* )
 468     opsys=hpux11
 469     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 470   ;;
 471
 472   ## IBM machines
 473   rs6000-ibm-aix4.[23]* )
 474     opsys=aix4-2
 475   ;;
 476   powerpc-ibm-aix4.[23]*  )
 477     opsys=aix4-2
 478   ;;
 479   rs6000-ibm-aix[56]* )
 480     opsys=aix4-2
 481   ;;
 482   powerpc-ibm-aix[56]*  )
 483     opsys=aix4-2
 484   ;;
 485
 486   ## Silicon Graphics machines
 487   ## Iris 4D
 488   mips-sgi-irix6.5 )
 489     opsys=irix6-5
 490     # Without defining _LANGUAGE_C, things get masked out in the headers
 491     # so that, for instance, grepping for `free' in stdlib.h fails and
 492     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 493     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 494   ;;
 495
 496   ## Suns
 497   *-sun-solaris* \
 498     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 499     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 500     case "${canonical}" in
 501       i[3456]86-*-* )   ;;
 502       amd64-*-*|x86_64-*-*) ;;
 503       sparc* )          ;;
 504       * )               unported=yes ;;
 505     esac
 506     case "${canonical}" in
 507       *-sunos5.6* | *-solaris2.6* )
 508                 opsys=sol2-6
 509                 RANLIB="ar -ts"
 510                 ;;
 511       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 512                 opsys=sol2-6
 513                 emacs_check_sunpro_c=yes
 514                 ;;
 515       *-sunos5* | *-solaris* )
 516                 opsys=sol2-10
 517                 emacs_check_sunpro_c=yes
 518                 ;;
 519     esac
 520     ## Watch out for a compiler that we know will not work.
 521     case "${canonical}" in
 522      *-solaris* | *-sunos5* )
 523                 if [ "x$CC" = x/usr/ucb/cc ]; then
 524                   ## /usr/ucb/cc doesn't work;
 525                   ## we should find some other compiler that does work.
 526                   unset CC
 527                 fi
 528                 ;;
 529       *) ;;
 530     esac
 531   ;;
 532
 533   ## Intel 386 machines where we don't care about the manufacturer.
 534   i[3456]86-*-* )
 535     case "${canonical}" in
 536       *-cygwin )                opsys=cygwin ;;
 537       *-darwin* )               opsys=darwin ;;
 538       *-sysv4.2uw* )            opsys=unixware ;;
 539       *-sysv5uw* )              opsys=unixware ;;
 540       *-sysv5OpenUNIX* )        opsys=unixware ;;
 541       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 542     esac
 543   ;;
 544
 545   * )
 546     unported=yes
 547   ;;
 548 esac
 549
 550 ### If the code above didn't choose an operating system, just choose
 551 ### an operating system based on the configuration name.  You really
 552 ### only want to use this when you have no idea what the right
 553 ### operating system is; if you know what operating systems a machine
 554 ### runs, it's cleaner to make it explicit in the case statement
 555 ### above.
 556 if test x"${opsys}" = x; then
 557   case "${canonical}" in
 558     *-gnu* )                            opsys=gnu ;;
 559     * )
 560       unported=yes
 561     ;;
 562   esac
 563 fi
 564
 565 ]
 566 dnl quotation ends
 567
 568 if test $unported = yes; then
 569   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 570 Check `etc/MACHINES' for recognized configuration names.])
 571 fi
 572
 573
 574 #### Choose a compiler.
 575
 576 dnl Sets GCC=yes if using gcc.
 577 AC_PROG_CC
 578 AM_PROG_CC_C_O
 579
 580 if test x$GCC = xyes; then
 581   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 582 else
 583   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 584 fi
 585
 586 # Avoid gnulib's tests for O_NOATIME and O_NOFOLLOW, as we don't use them.
 587 AC_DEFUN([gl_FCNTL_O_FLAGS])
 588 # Avoid gnulib's threadlib module, as we do threads our own way.
 589 AC_DEFUN([gl_THREADLIB])
 590
 591 # Initialize gnulib right after choosing the compiler.
 592 dnl Amongst other things, this sets AR and ARFLAGS.
 593 gl_EARLY
 594
 595 # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 596 # if -g3 works and the user does not specify CFLAGS.
 597 # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 598 if test "$ac_test_CFLAGS" != set; then
 599   case $CFLAGS in
 600     '-g')
 601       emacs_g3_CFLAGS='-g3';;
 602     '-g -O2')
 603       emacs_g3_CFLAGS='-g3 -O2';;
 604     *)
 605       emacs_g3_CFLAGS='';;
 606   esac
 607   if test -n "$emacs_g3_CFLAGS"; then
 608     emacs_save_CFLAGS=$CFLAGS
 609     CFLAGS=$emacs_g3_CFLAGS
 610     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 611       [emacs_cv_prog_cc_g3],
 612       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 613          [emacs_cv_prog_cc_g3=yes],
 614          [emacs_cv_prog_cc_g3=no])])
 615     if test $emacs_cv_prog_cc_g3 = yes; then
 616       CFLAGS=$emacs_g3_CFLAGS
 617     else
 618       CFLAGS=$emacs_save_CFLAGS
 619     fi
 620   fi
 621 fi
 622
 623 AC_ARG_ENABLE([gcc-warnings],
 624   [AS_HELP_STRING([--enable-gcc-warnings],
 625                   [turn on lots of GCC warnings. This is intended for
 626                    developers, and may generate false alarms when used
 627                    with older or non-GNU development tools.])],
 628   [case $enableval in
 629      yes|no) ;;
 630      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 631    esac
 632    gl_gcc_warnings=$enableval],
 633   [gl_gcc_warnings=no]
 634 )
 635
 636 AC_ARG_ENABLE(link-time-optimization,
 637 [AS_HELP_STRING([--enable-link-time-optimization],
 638                 [build emacs with link-time optimization.
 639                  This is supported only for GCC since 4.5.0.])],
 640 if test "${enableval}" != "no"; then
 641    AC_MSG_CHECKING([whether link-time optimization is supported])
 642    ac_lto_supported=no
 643    if test x$GCC = xyes; then
 644       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 645       if test x$CPUS != x; then
 646          LTO="-flto=$CPUS"
 647       else
 648          LTO="-flto"
 649       fi
 650       old_CFLAGS=$CFLAGS
 651       CFLAGS="$CFLAGS $LTO"
 652       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 653         [ac_lto_supported=yes], [ac_lto_supported=no])
 654       CFLAGS="$old_CFLAGS"
 655    fi
 656    AC_MSG_RESULT([$ac_lto_supported])
 657    if test "$ac_lto_supported" = "yes"; then
 658       CFLAGS="$CFLAGS $LTO"
 659    fi
 660 fi)
 661
 662 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 663 # ------------------------------------------------
 664 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 665 # Otherwise, run RUN-IF-NOT-FOUND.
 666 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 667   [AC_PREPROC_IFELSE(
 668     [AC_LANG_PROGRAM(
 669       [[
 670 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 671 /* ok */
 672 #else
 673 # error "your version of gcc is older than $1.$2"
 674 #endif
 675       ]]),
 676     ], [$3], [$4])
 677   ]
 678 )
 679
 680 # When compiling with GCC, prefer -isystem to -I when including system
 681 # include files, to avoid generating useless diagnostics for the files.
 682 if test "$gl_gcc_warnings" != yes; then
 683   isystem='-I'
 684 else
 685   isystem='-isystem '
 686
 687   # This, $nw, is the list of warnings we disable.
 688   nw=
 689
 690   case $with_x_toolkit in
 691     lucid | athena | motif)
 692        # Old toolkits mishandle 'const'.
 693        nw="$nw -Wwrite-strings"
 694        ;;
 695     *)
 696        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 697        ;;
 698   esac
 699   AC_SUBST([WERROR_CFLAGS])
 700
 701   nw="$nw -Waggregate-return"       # anachronistic
 702   nw="$nw -Wlong-long"              # C90 is anachronistic
 703   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 704   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 705   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 706   nw="$nw -Wcast-qual"              # Too many warnings for now
 707   nw="$nw -Wconversion"             # Too many warnings for now
 708   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 709   nw="$nw -Wsign-conversion"        # Too many warnings for now
 710   nw="$nw -Woverlength-strings"     # Not a problem these days
 711   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 712   nw="$nw -Wunreachable-code"       # so buggy that it's now silently ignored
 713   nw="$nw -Wpadded"                 # Our structs are not padded
 714   nw="$nw -Wredundant-decls"        # we regularly (re)declare functions
 715   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 716   nw="$nw -Wformat-nonliteral"      # we do this a lot
 717   nw="$nw -Wvla"                    # warnings in gettext.h
 718   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 719   nw="$nw -Wswitch-enum"            # Too many warnings for now
 720   nw="$nw -Wswitch-default"         # Too many warnings for now
 721   nw="$nw -Wfloat-equal"            # warns about high-quality code
 722   nw="$nw -Winline"                 # OK to ignore 'inline'
 723   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 724   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 725                                     # signed overflow has undefined behavior
 726   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 727   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 728
 729   # Emacs doesn't care about shadowing; see
 730   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 731   nw="$nw -Wshadow"
 732
 733   # Emacs's use of alloca inhibits protecting the stack.
 734   nw="$nw -Wstack-protector"
 735
 736   # The following line should be removable at some point.
 737   nw="$nw -Wsuggest-attribute=pure"
 738
 739   gl_MANYWARN_ALL_GCC([ws])
 740   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 741   for w in $ws; do
 742     gl_WARN_ADD([$w])
 743   done
 744   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 745   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 746   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 747   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 748   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 749   gl_WARN_ADD([-Wno-format-nonliteral])
 750
 751   # In spite of excluding -Wlogical-op above, it is enabled, as of
 752   # gcc 4.5.0 20090517.
 753   gl_WARN_ADD([-Wno-logical-op])
 754
 755   gl_WARN_ADD([-fdiagnostics-show-option])
 756   gl_WARN_ADD([-funit-at-a-time])
 757
 758   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 759   AH_VERBATIM([FORTIFY_SOURCE],
 760   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 761       without upsetting glibc 2.15+. */
 762    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 763    # define _FORTIFY_SOURCE 2
 764    #endif
 765   ])
 766   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 767
 768   # We use a slightly smaller set of warning options for lib/.
 769   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 770   nw=
 771   nw="$nw -Wunused-macros"
 772
 773   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 774   AC_SUBST([GNULIB_WARN_CFLAGS])
 775 fi
 776
 777
 778
 779 dnl Some other nice autoconf tests.
 780 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 781 dnl AC_PROG_INSTALL
 782 dnl AC_PROG_MKDIR_P
 783 dnl if test "x$RANLIB" = x; then
 784 dnl   AC_PROG_RANLIB
 785 dnl fi
 786 AC_PROG_LN_S
 787
 788 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 789   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 790 dnl Don't use GZIP, which is used by gzip for additional parameters.
 791 AC_PATH_PROG(GZIP_PROG, gzip)
 792
 793 if test $opsys = gnu-linux; then
 794   AC_PATH_PROG(PAXCTL, paxctl,,
 795     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 796   if test "X$PAXCTL" != X; then
 797     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
 798     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 799       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
 800       else AC_MSG_RESULT(no); PAXCTL=""; fi])
 801   fi
 802 fi
 803
 804 ## Need makeinfo >= 4.7 (?) to build the manuals.
 805 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 806 dnl By this stage, configure has already checked for egrep and set EGREP,
 807 dnl or exited with an error if no egrep was found.
 808 if test "$MAKEINFO" != "no"; then
 809   case `
 810     $MAKEINFO --version 2> /dev/null |
 811     $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'
 812   ` in
 813     '') MAKEINFO=no;;
 814   esac
 815 fi
 816
 817 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 818 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 819 ## therefore in the category of "special tools" not normally required, which
 820 ## configure does not have to check for (eg autoconf itself).
 821 ## In a Bazaar checkout on the other hand, the manuals are not included.
 822 ## So makeinfo is a requirement to build from Bazaar, and configure
 823 ## should test for it as it does for any other build requirement.
 824 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 825 ## with pre-built manuals, from a Bazaar checkout.
 826 HAVE_MAKEINFO=yes
 827
 828 if test "$MAKEINFO" = "no"; then
 829   MAKEINFO=makeinfo
 830   if test "x${with_makeinfo}" = "xno"; then
 831     HAVE_MAKEINFO=no
 832   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
 833     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 834 source tree does not seem to have pre-built manuals in the `info' directory.
 835 Either install a suitable version of makeinfo, or re-run configure
 836 with the `--without-makeinfo' option to build without the manuals.] )
 837   fi
 838 fi
 839 AC_SUBST(HAVE_MAKEINFO)
 840
 841 dnl Just so that there is only a single place we need to edit.
 842 INFO_EXT=.info
 843 INFO_OPTS=--no-split
 844 AC_SUBST(INFO_EXT)
 845 AC_SUBST(INFO_OPTS)
 846
 847 dnl Add our options to ac_link now, after it is set up.
 848
 849 if test x$GCC = xyes; then
 850   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 851     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 852 else
 853   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 854     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 855 fi
 856
 857 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 858 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 859 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 860 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 861 dnl if not built to support GNU ld.
 862
 863 late_LDFLAGS=$LDFLAGS
 864 if test x$GCC = xyes; then
 865   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 866 else
 867   LDFLAGS="$LDFLAGS -znocombreloc"
 868 fi
 869
 870 AC_MSG_CHECKING([for -znocombreloc])
 871 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 872   [AC_MSG_RESULT(yes)],
 873   LDFLAGS=$late_LDFLAGS
 874   [AC_MSG_RESULT(no)])
 875
 876
 877 dnl The function dump-emacs will not be defined and temacs will do
 878 dnl (load "loadup") automatically unless told otherwise.
 879 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 880 case "$opsys" in
 881   your-opsys-here) CANNOT_DUMP=yes ;;
 882 esac
 883
 884 test "$CANNOT_DUMP" = "yes" && \
 885   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 886
 887 AC_SUBST(CANNOT_DUMP)
 888
 889
 890 UNEXEC_OBJ=unexelf.o
 891 case "$opsys" in
 892   # MSDOS uses unexcoff.o
 893   # MSWindows uses unexw32.o
 894   aix4-2)
 895    UNEXEC_OBJ=unexaix.o
 896    ;;
 897   cygwin)
 898    UNEXEC_OBJ=unexcw.o
 899    ;;
 900   darwin)
 901    UNEXEC_OBJ=unexmacosx.o
 902    ;;
 903   hpux10-20 | hpux11)
 904    UNEXEC_OBJ=unexhp9k800.o
 905    ;;
 906   sol2-10)
 907    # Use the Solaris dldump() function, called from unexsol.c, to dump
 908    # emacs, instead of the generic ELF dump code found in unexelf.c.
 909    # The resulting binary has a complete symbol table, and is better
 910    # for debugging and other observability tools (debuggers, pstack, etc).
 911    #
 912    # If you encounter a problem using dldump(), please consider sending
 913    # a message to the OpenSolaris tools-linking mailing list:
 914    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 915    #
 916    # It is likely that dldump() works with older Solaris too, but this has
 917    # not been tested, so for now this change is for Solaris 10 or newer.
 918    UNEXEC_OBJ=unexsol.o
 919    ;;
 920 esac
 921
 922 LD_SWITCH_SYSTEM=
 923 case "$opsys" in
 924   freebsd)
 925    ## Let `ld' find image libs and similar things in /usr/local/lib.
 926    ## The system compiler, GCC, has apparently been modified to not
 927    ## look there, contrary to what a stock GCC would do.
 928 ### It's not our place to do this.  See bug#10313#17.
 929 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 930       :
 931    ;;
 932
 933   gnu-linux)
 934    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 935    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 936    ;;
 937
 938   netbsd)
 939 ### It's not our place to do this.  See bug#10313#17.
 940 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 941       :
 942    ;;
 943
 944   openbsd)
 945    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 946    ## otherwise Emacs dumps core on elf systems.
 947    LD_SWITCH_SYSTEM="-Z"
 948    ;;
 949 esac
 950 AC_SUBST(LD_SWITCH_SYSTEM)
 951
 952 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 953
 954 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 955 ## which has not been defined yet.  When this was handled with cpp,
 956 ## it was expanded to null when configure sourced the s/*.h file.
 957 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 958 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 959 ## (or somesuch), but because it is supposed to go at the _front_
 960 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 961 ## Compare with the gnu-linux case below, which added to the end
 962 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 963 ## LD_SWITCH_SYSTEM_TEMACS.
 964 case "$opsys" in
 965   netbsd|openbsd)
 966    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 967 esac
 968
 969
 970 C_SWITCH_MACHINE=
 971 case $canonical in
 972  alpha*)
 973   AC_CHECK_DECL([__ELF__])
 974   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 975     ## With ELF, make sure that all common symbols get allocated to in the
 976     ## data section.  Otherwise, the dump of temacs may miss variables in
 977     ## the shared library that have been initialized.  For example, with
 978     ## GNU libc, __malloc_initialized would normally be resolved to the
 979     ## shared library's .bss section, which is fatal.
 980     if test "x$GCC" = "xyes"; then
 981       C_SWITCH_MACHINE="-fno-common"
 982     else
 983       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 984     fi
 985   else
 986     UNEXEC_OBJ=unexalpha.o
 987   fi
 988   ;;
 989 esac
 990 AC_SUBST(C_SWITCH_MACHINE)
 991
 992 AC_SUBST(UNEXEC_OBJ)
 993
 994 C_SWITCH_SYSTEM=
 995 ## Some programs in src produce warnings saying certain subprograms
 996 ## are too complex and need a MAXMEM value greater than 2000 for
 997 ## additional optimization.  --nils@exp-math.uni-essen.de
 998 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 999   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1000 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1001 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1002 AC_SUBST(C_SWITCH_SYSTEM)
1003
1004
1005 LIBS_SYSTEM=
1006 case "$opsys" in
1007   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1008   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1009
1010   freebsd) LIBS_SYSTEM="-lutil" ;;
1011
1012   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1013
1014   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1015
1016   ## Motif needs -lgen.
1017   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1018 esac
1019 AC_SUBST(LIBS_SYSTEM)
1020
1021
1022 ### Make sure subsequent tests use flags consistent with the build flags.
1023
1024 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1025   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1026 else
1027   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1028 fi
1029
1030 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1031 AC_DEFUN([AC_TYPE_SIZE_T])
1032 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1033 AC_DEFUN([AC_TYPE_UID_T])
1034
1035
1036 LIB_MATH=-lm
1037 LIB_STANDARD=
1038 START_FILES=
1039 dnl Current possibilities handled by sed (aix4-2 -> aix,
1040 dnl gnu-linux -> gnu/linux, etc.):
1041 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1042 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1043 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1044
1045 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
1046 case $opsys in
1047   cygwin )
1048     LIB_MATH=
1049     START_FILES='pre-crt0.o'
1050     ;;
1051   darwin )
1052     ## Adding -lm confuses the dynamic linker, so omit it.
1053     LIB_MATH=
1054     START_FILES='pre-crt0.o'
1055     ;;
1056   freebsd )
1057     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1058     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1059     SYSTEM_TYPE=berkeley-unix
1060     ;;
1061   gnu-linux | gnu-kfreebsd )
1062     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1063     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1064     ;;
1065   hpux10-20 | hpux11 )
1066     LIB_STANDARD=-lc
1067     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1068     ;;
1069   dnl NB this may be adjusted below.
1070   netbsd | openbsd )
1071     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1072     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1073     SYSTEM_TYPE=berkeley-unix
1074     ;;
1075
1076   sol2* | unixware )
1077     SYSTEM_TYPE=usg-unix-v
1078     ;;
1079
1080 esac
1081
1082 AC_SUBST(LIB_MATH)
1083 AC_SUBST(START_FILES)
1084 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1085   [The type of system you are compiling for; sets `system-type'.])
1086
1087 dnl Not all platforms use crtn.o files.  Check if the current one does.
1088 crt_files=
1089
1090 for file in x $LIB_STANDARD $START_FILES; do
1091   case "$file" in
1092     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1093   esac
1094 done
1095
1096 if test "x$crt_files" != x; then
1097
1098   ## If user specified a crt-dir, use that unconditionally.
1099   crt_gcc=no
1100
1101   if test "X$CRT_DIR" = "X"; then
1102
1103     CRT_DIR=/usr/lib            # default
1104
1105     case "$canonical" in
1106       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1107       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1108       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1109       ## For anything else (eg /usr/lib32), it is up the user to specify
1110       ## the location (bug#5655).
1111       ## Test for crtn.o, not just the directory, because sometimes the
1112       ## directory exists but does not have the relevant files (bug#1287).
1113       ## FIXME better to test for binary compatibility somehow.
1114       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1115       ;;
1116
1117       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1118     esac
1119
1120     case "$opsys" in
1121       hpux10-20) CRT_DIR=/lib ;;
1122     esac
1123
1124     test "x${GCC}" = xyes && crt_gcc=yes
1125
1126   fi                            # CRT_DIR = ""
1127
1128   crt_missing=
1129
1130   for file in $crt_files; do
1131
1132     ## If we're using gcc, try to determine it automatically by asking
1133     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1134     ## system-dependent default from above.]
1135     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1136
1137        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1138        case "$crt_file" in
1139          */*)
1140            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1141            ;;
1142        esac
1143     fi
1144
1145     dnl We expect all the files to be in a single directory, so after the
1146     dnl first there is no point asking gcc.
1147     crt_gcc=no
1148
1149     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1150   done                          # $crt_files
1151
1152   test "x$crt_missing" = x || \
1153     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1154 Try using the --with-crt-dir option.])
1155
1156 fi                              # crt_files != ""
1157
1158 AC_SUBST(CRT_DIR)
1159
1160 case $opsys in
1161   netbsd | openbsd )
1162     if test -f $CRT_DIR/crti.o; then
1163
1164         test -f $CRT_DIR/crtn.o || \
1165           AC_MSG_ERROR([Required file not found: crtn.o])
1166
1167         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1168         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1169     fi
1170     ;;
1171 esac
1172
1173
1174 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1175 pre_PKG_CONFIG_LIBS=$LIBS
1176
1177 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1178
1179 dnl This function definition taken from Gnome 2.0
1180 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1181 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1182 dnl also defines GSTUFF_PKG_ERRORS on error
1183 AC_DEFUN([PKG_CHECK_MODULES], [
1184   succeeded=no
1185
1186   if test "$PKG_CONFIG" = "no" ; then
1187      ifelse([$4], , [AC_MSG_ERROR([
1188       *** The pkg-config script could not be found. Make sure it is in your path, or give the full name of pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1189   else
1190      PKG_CONFIG_MIN_VERSION=0.9.0
1191      if "$PKG_CONFIG" --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1192         AC_MSG_CHECKING(for $2)
1193
1194         if "$PKG_CONFIG" --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1195            $1_CFLAGS=`"$PKG_CONFIG" --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1196            $1_LIBS=`"$PKG_CONFIG" --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1197             edit_cflags="
1198               s,///*,/,g
1199               s/^/ /
1200               s/ -I/ $isystem/g
1201               s/^ //
1202             "
1203             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1204             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1205             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1206             succeeded=yes
1207         else
1208             AC_MSG_RESULT(no)
1209             $1_CFLAGS=""
1210             $1_LIBS=""
1211             ## If we have a custom action on failure, don't print errors, but
1212             ## do set a variable so people can do so.  Do it in a subshell
1213             ## to capture any diagnostics in invoking pkg-config.
1214             $1_PKG_ERRORS=`("$PKG_CONFIG" --print-errors "$2") 2>&1`
1215             ifelse([$4], ,echo "$$1_PKG_ERRORS",)
1216         fi
1217
1218         AC_SUBST($1_CFLAGS)
1219         AC_SUBST($1_LIBS)
1220      else
1221         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1222         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1223      fi
1224   fi
1225
1226   if test $succeeded = yes; then
1227      ifelse([$3], , :, [$3])
1228   else
1229      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1230   fi
1231 ])
1232
1233
1234 if test "${with_sound}" != "no"; then
1235   # Sound support for GNU/Linux and the free BSDs.
1236   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1237     have_sound_header=yes)
1238   # Emulation library used on NetBSD.
1239   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1240   AC_SUBST(LIBSOUND)
1241
1242   ALSA_REQUIRED=1.0.0
1243   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1244   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1245   if test $HAVE_ALSA = yes; then
1246     SAVE_CFLAGS="$CFLAGS"
1247     SAVE_LIBS="$LIBS"
1248     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1249     LIBS="$ALSA_LIBS $LIBS"
1250     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1251                     emacs_alsa_normal=yes,
1252                     emacs_alsa_normal=no)
1253     if test "$emacs_alsa_normal" != yes; then
1254       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1255                      [[snd_lib_error_set_handler (0);]])],
1256                      emacs_alsa_subdir=yes,
1257                      emacs_alsa_subdir=no)
1258       if test "$emacs_alsa_subdir" != yes; then
1259         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1260       fi
1261       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1262     fi
1263
1264     CFLAGS="$SAVE_CFLAGS"
1265     LIBS="$SAVE_LIBS"
1266     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1267     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1268     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1269   fi
1270
1271   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1272   dnl compiles only on the specified platforms.  For others, it
1273   dnl probably doesn't make sense to try.
1274   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1275      case "$opsys" in
1276        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1277        gnu-linux|freebsd|netbsd)
1278          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1279          ;;
1280      esac
1281   fi
1282
1283   AC_SUBST(CFLAGS_SOUND)
1284 fi
1285
1286 dnl checks for header files
1287 AC_CHECK_HEADERS_ONCE(
1288   linux/version.h sys/systeminfo.h
1289   coff.h pty.h
1290   sys/vlimit.h sys/resource.h
1291   sys/utsname.h pwd.h utmp.h util.h)
1292
1293 AC_MSG_CHECKING(if personality LINUX32 can be set)
1294 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1295                emacs_cv_personality_linux32=yes,
1296                emacs_cv_personality_linux32=no)
1297 AC_MSG_RESULT($emacs_cv_personality_linux32)
1298
1299 if test $emacs_cv_personality_linux32 = yes; then
1300   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1301             [Define to 1 if personality LINUX32 can be set.])
1302 fi
1303
1304 dnl On Solaris 8 there's a compilation warning for term.h because
1305 dnl it doesn't define `bool'.
1306 AC_CHECK_HEADERS(term.h, , , -)
1307 AC_HEADER_TIME
1308 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1309                                       ]])
1310 if test $ac_cv_have_decl_sys_siglist != yes; then
1311   # For Tru64, at least:
1312   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1313                                           ]])
1314   if test $ac_cv_have_decl___sys_siglist = yes; then
1315     AC_DEFINE(sys_siglist, __sys_siglist,
1316               [Define to any substitute for sys_siglist.])
1317   fi
1318 fi
1319 AC_HEADER_SYS_WAIT
1320
1321 dnl Check for speed_t typedef.
1322 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1323   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1324     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1325 if test $emacs_cv_speed_t = yes; then
1326   AC_DEFINE(HAVE_SPEED_T, 1,
1327            [Define to 1 if `speed_t' is declared by <termios.h>.])
1328 fi
1329
1330 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1331 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1332 #if HAVE_SYS_SOCKET_H
1333 #include <sys/socket.h>
1334 #endif])
1335 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1336 #if HAVE_SYS_SOCKET_H
1337 #include <sys/socket.h>
1338 #endif])
1339 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1340 #if HAVE_SYS_SOCKET_H
1341 #include <sys/socket.h>
1342 #endif])
1343
1344 dnl checks for structure members
1345 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1346                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1347                   struct ifreq.ifr_addr,
1348                   struct ifreq.ifr_addr.sa_len], , ,
1349                  [AC_INCLUDES_DEFAULT
1350 #if HAVE_SYS_SOCKET_H
1351 #include <sys/socket.h>
1352 #endif
1353 #if HAVE_NET_IF_H
1354 #include <net/if.h>
1355 #endif])
1356
1357 dnl Check for endianness.
1358 dnl AC_C_BIGENDIAN is done by gnulib.
1359
1360 dnl check for Make feature
1361 dnl AC_PROG_MAKE_SET is done by Automake.
1362
1363 DEPFLAGS=
1364 MKDEPDIR=":"
1365 deps_frag=deps.mk
1366 dnl check for GNU Make if we have GCC and autodepend is on.
1367 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1368    AC_MSG_CHECKING([whether we are using GNU Make])
1369    HAVE_GNU_MAKE=no
1370    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1371    if test "x$testval" != x; then
1372       HAVE_GNU_MAKE=yes
1373    else
1374       ac_enable_autodepend=no
1375    fi
1376    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1377    if test $HAVE_GNU_MAKE = yes; then
1378       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1379       SAVE_CFLAGS="$CFLAGS"
1380       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1381       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1382       CFLAGS="$SAVE_CFLAGS"
1383       test -f deps.d || ac_enable_autodepend=no
1384       rm -rf deps.d
1385       AC_MSG_RESULT([$ac_enable_autodepend])
1386    fi
1387    if test $ac_enable_autodepend = yes; then
1388       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1389       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1390       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1391       deps_frag=autodeps.mk
1392    fi
1393 fi
1394 deps_frag=$srcdir/src/$deps_frag
1395 AC_SUBST(MKDEPDIR)
1396 AC_SUBST(DEPFLAGS)
1397 AC_SUBST_FILE(deps_frag)
1398
1399
1400 lisp_frag=$srcdir/src/lisp.mk
1401 AC_SUBST_FILE(lisp_frag)
1402
1403
1404 dnl checks for operating system services
1405 AC_SYS_LONG_FILE_NAMES
1406
1407 #### Choose a window system.
1408
1409 ## We leave window_system equal to none if
1410 ## we end up building without one.  Any new window system should
1411 ## set window_system to an appropriate value and add objects to
1412 ## window-system-specific substs.
1413
1414 window_system=none
1415 AC_PATH_X
1416 if test "$no_x" != yes; then
1417   window_system=x11
1418 fi
1419
1420 LD_SWITCH_X_SITE_RPATH=
1421 if test "${x_libraries}" != NONE; then
1422   if test -n "${x_libraries}"; then
1423     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1424     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1425   fi
1426   x_default_search_path=""
1427   x_search_path=${x_libraries}
1428   if test -z "${x_search_path}"; then
1429     x_search_path=/usr/lib
1430   fi
1431   for x_library in `echo ${x_search_path}: | \
1432                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1433     x_search_path="\
1434 ${x_library}/X11/%L/%T/%N%C%S:\
1435 ${x_library}/X11/%l/%T/%N%C%S:\
1436 ${x_library}/X11/%T/%N%C%S:\
1437 ${x_library}/X11/%L/%T/%N%S:\
1438 ${x_library}/X11/%l/%T/%N%S:\
1439 ${x_library}/X11/%T/%N%S"
1440     if test x"${x_default_search_path}" = x; then
1441       x_default_search_path=${x_search_path}
1442     else
1443       x_default_search_path="${x_search_path}:${x_default_search_path}"
1444     fi
1445   done
1446 fi
1447 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1448
1449 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1450   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1451 fi
1452
1453 if test x"${x_includes}" = x; then
1454   bitmapdir=/usr/include/X11/bitmaps
1455 else
1456   # accumulate include directories that have X11 bitmap subdirectories
1457   bmd_acc="dummyval"
1458   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1459     if test -d "${bmd}/X11/bitmaps"; then
1460       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1461     fi
1462     if test -d "${bmd}/bitmaps"; then
1463       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1464     fi
1465   done
1466   if test ${bmd_acc} != "dummyval"; then
1467     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1468   fi
1469 fi
1470
1471 HAVE_NS=no
1472 NS_IMPL_COCOA=no
1473 NS_IMPL_GNUSTEP=no
1474 tmp_CPPFLAGS="$CPPFLAGS"
1475 tmp_CFLAGS="$CFLAGS"
1476 CPPFLAGS="$CPPFLAGS -x objective-c"
1477 CFLAGS="$CFLAGS -x objective-c"
1478 GNU_OBJC_CFLAGS=
1479 LIBS_GNUSTEP=
1480 if test "${with_ns}" != no; then
1481   if test "${opsys}" = darwin; then
1482      NS_IMPL_COCOA=yes
1483      ns_appdir=`pwd`/nextstep/Emacs.app
1484      ns_appbindir=${ns_appdir}/Contents/MacOS
1485      ns_appresdir=${ns_appdir}/Contents/Resources
1486      ns_appsrc=Cocoa/Emacs.base
1487   elif test -f $GNUSTEP_CONFIG_FILE; then
1488      NS_IMPL_GNUSTEP=yes
1489      ns_appdir=`pwd`/nextstep/Emacs.app
1490      ns_appbindir=${ns_appdir}
1491      ns_appresdir=${ns_appdir}/Resources
1492      ns_appsrc=GNUstep/Emacs.base
1493      dnl FIXME sourcing this several times in subshells seems inefficient.
1494      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1495      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1496      dnl I seemed to need these as well with GNUstep-startup 0.25.
1497      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1498      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1499      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1500        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1501      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1502        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1503      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1504      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1505      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1506      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1507      LIB_STANDARD=
1508      START_FILES=
1509      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1510      dnl If they had chosen to either define it or not, we could have
1511      dnl just used AC_CHECK_DECL here.
1512      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1513        emacs_cv_objc_exceptions,
1514 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1515 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1516 1;
1517 #else
1518 fail;
1519 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1520      if test $emacs_cv_objc_exceptions = yes; then
1521        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1522        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1523          [Define if GNUstep uses ObjC exceptions.])
1524        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1525      fi
1526   fi
1527
1528   dnl This is only used while we test the NS headers, it gets reset below.
1529   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1530
1531   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1532                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1533   files are missing or cannot be compiled.])])
1534
1535   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1536                                      [
1537 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1538 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1040
1539  ; /* OK */
1540 #else
1541 #error "OSX 10.4 or newer required"
1542 #endif
1543 #endif
1544                     ])],
1545                     ns_osx_have_104=yes,
1546                     ns_osx_have_104=no)
1547   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1548                                      [NSInteger i;])],
1549                     ns_have_nsinteger=yes,
1550                     ns_have_nsinteger=no)
1551   if test $ns_osx_have_104 = no; then
1552      AC_MSG_ERROR([`OSX 10.4 or newer is required']);
1553   fi
1554   if test $ns_have_nsinteger = yes; then
1555     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1556   fi
1557 fi
1558
1559 AC_SUBST(LIBS_GNUSTEP)
1560
1561 INSTALL_ARCH_INDEP_EXTRA=install-etc
1562 ns_self_contained=no
1563 NS_OBJ=
1564 NS_OBJC_OBJ=
1565 if test "${HAVE_NS}" = yes; then
1566   if test "$with_toolkit_scroll_bars" = "no"; then
1567     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1568   fi
1569
1570   window_system=nextstep
1571   # set up packaging dirs
1572   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1573      ns_self_contained=yes
1574      prefix=${ns_appresdir}
1575      exec_prefix=${ns_appbindir}
1576      dnl This one isn't really used, only archlibdir is.
1577      libexecdir="\${ns_appbindir}/libexec"
1578      archlibdir="\${ns_appbindir}/libexec"
1579      docdir="\${ns_appresdir}/etc"
1580      etcdir="\${ns_appresdir}/etc"
1581      dnl FIXME maybe set datarootdir instead.
1582      dnl That would also get applications, icons, man.
1583      infodir="\${ns_appresdir}/info"
1584      mandir="\${ns_appresdir}/man"
1585      lispdir="\${ns_appresdir}/lisp"
1586      leimdir="\${ns_appresdir}/leim"
1587      INSTALL_ARCH_INDEP_EXTRA=
1588   fi
1589   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1590 fi
1591 CFLAGS="$tmp_CFLAGS"
1592 CPPFLAGS="$tmp_CPPFLAGS"
1593 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1594 AC_SUBST(ns_self_contained)
1595 AC_SUBST(NS_OBJ)
1596 AC_SUBST(NS_OBJC_OBJ)
1597 AC_SUBST(LIB_STANDARD)
1598
1599 HAVE_W32=no
1600 W32_OBJ=
1601 W32_LIBS=
1602 W32_RES=
1603 W32_RES_LINK=
1604 if test "${with_w32}" != no; then
1605   if test "${opsys}" != "cygwin"; then
1606     AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin.])
1607   fi
1608   AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1609                   [AC_MSG_ERROR([`--with-w32' was specified, but windows.h
1610                   cannot be found.])])
1611   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1612   AC_CHECK_TOOL(WINDRES, [windres],
1613                 [AC_MSG_ERROR([No resource compiler found.])])
1614   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1615   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1616   W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1617   W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1618   W32_RES="emacs.res"
1619   # Tell the linker that emacs.res is an object (which we compile from
1620   # the rc file), not a linker script.
1621   W32_RES_LINK="-Wl,-bpe-i386 -Wl,emacs.res"
1622 fi
1623 AC_SUBST(W32_OBJ)
1624 AC_SUBST(W32_LIBS)
1625 AC_SUBST(W32_RES)
1626 AC_SUBST(W32_RES_LINK)
1627
1628 if test "${HAVE_W32}" = "yes"; then
1629   window_system=w32
1630   with_xft=no
1631 fi
1632
1633 ## $window_system is now set to the window system we will
1634 ## ultimately use.
1635
1636 term_header=
1637 HAVE_X_WINDOWS=no
1638 HAVE_X11=no
1639 USE_X_TOOLKIT=none
1640
1641 case "${window_system}" in
1642   x11 )
1643     HAVE_X_WINDOWS=yes
1644     HAVE_X11=yes
1645     term_header=xterm.h
1646     case "${with_x_toolkit}" in
1647       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1648       motif ) USE_X_TOOLKIT=MOTIF ;;
1649       gtk ) with_gtk=yes
1650             term_header=gtkutil.h
1651 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1652 dnl USE_X_TOOLKIT is set.
1653             USE_X_TOOLKIT=none ;;
1654       gtk2 ) with_gtk2=yes
1655              term_header=gtkutil.h
1656              USE_X_TOOLKIT=none ;;
1657       gtk3 ) with_gtk3=yes
1658              term_header=gtkutil.h
1659              USE_X_TOOLKIT=none ;;
1660       no ) USE_X_TOOLKIT=none ;;
1661 dnl If user did not say whether to use a toolkit, make this decision later:
1662 dnl use the toolkit if we have gtk, or X11R5 or newer.
1663       * ) USE_X_TOOLKIT=maybe ;;
1664     esac
1665   ;;
1666   nextstep )
1667     term_header=nsterm.h
1668   ;;
1669   w32 )
1670     term_header=w32term.h
1671   ;;
1672 esac
1673
1674 if test -n "${term_header}"; then
1675     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
1676         [Define to the header for the built-in window system.])
1677 fi
1678
1679 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1680    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1681    if test "$HAVE_XSERVER" = true ||
1682       test -n "$DISPLAY" ||
1683       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1684         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1685 were found.  You should install the relevant development files for X
1686 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1687 sure you have development files for image handling, i.e.
1688 tiff, gif, jpeg, png and xpm.
1689 If you are sure you want Emacs compiled without X window support, pass
1690   --without-x
1691 to configure.])
1692    fi
1693 fi
1694
1695 ### If we're using X11, we should use the X menu package.
1696 HAVE_MENUS=no
1697 case ${HAVE_X11} in
1698   yes ) HAVE_MENUS=yes ;;
1699 esac
1700
1701 # Does the opsystem file prohibit the use of the GNU malloc?
1702 # Assume not, until told otherwise.
1703 GNU_MALLOC=yes
1704
1705 AC_CACHE_CHECK(
1706   [whether malloc is Doug Lea style],
1707   [emacs_cv_var_doug_lea_malloc],
1708   [AC_LINK_IFELSE(
1709      [AC_LANG_PROGRAM(
1710         [[#include <malloc.h>
1711           static void hook (void) {}]],
1712         [[malloc_set_state (malloc_get_state ());
1713           __after_morecore_hook = hook;
1714           __malloc_initialize_hook = hook;]])],
1715      [emacs_cv_var_doug_lea_malloc=yes],
1716      [emacs_cv_var_doug_lea_malloc=no])])
1717 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1718
1719
1720 dnl See comments in aix4-2.h about maybe using system malloc there.
1721 system_malloc=no
1722 case "$opsys" in
1723   ## darwin ld insists on the use of malloc routines in the System framework.
1724   darwin|sol2-10) system_malloc=yes ;;
1725 esac
1726
1727 if test "${system_malloc}" = "yes"; then
1728   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1729   GNU_MALLOC=no
1730   GNU_MALLOC_reason="
1731     (The GNU allocators don't work with this system configuration.)"
1732   GMALLOC_OBJ=
1733   VMLIMIT_OBJ=
1734 else
1735   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1736   VMLIMIT_OBJ=vm-limit.o
1737 fi
1738 AC_SUBST(GMALLOC_OBJ)
1739 AC_SUBST(VMLIMIT_OBJ)
1740
1741 if test "$doug_lea_malloc" = "yes" ; then
1742   if test "$GNU_MALLOC" = yes ; then
1743     GNU_MALLOC_reason="
1744       (Using Doug Lea's new malloc from the GNU C Library.)"
1745   fi
1746   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1747             [Define to 1 if you are using the GNU C Library.])
1748
1749   ## Use mmap directly for allocating larger buffers.
1750   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1751   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1752   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1753   case "$opsys" in
1754     gnu*) REL_ALLOC=no ;;
1755   esac
1756 fi
1757
1758 if test x"${REL_ALLOC}" = x; then
1759   REL_ALLOC=${GNU_MALLOC}
1760 fi
1761
1762 use_mmap_for_buffers=no
1763 case "$opsys" in
1764   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1765 esac
1766
1767 AC_FUNC_MMAP
1768 if test $use_mmap_for_buffers = yes; then
1769   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1770   REL_ALLOC=no
1771 fi
1772
1773 LIBS="$LIBS_SYSTEM $LIBS"
1774
1775 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1776 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1777 AC_CHECK_LIB(dnet, dnet_ntoa)
1778 dnl This causes -lresolv to get used in subsequent tests,
1779 dnl which causes failures on some systems such as HPUX 9.
1780 dnl AC_CHECK_LIB(resolv, gethostbyname)
1781
1782 dnl FIXME replace main with a function we actually want from this library.
1783 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1784
1785 dnl Check if pthreads is available.
1786 LIB_PTHREAD=
1787 AC_CHECK_HEADERS_ONCE(pthread.h)
1788 if test "$ac_cv_header_pthread_h"; then
1789   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1790   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1791   dnl testing for pthread_self if Emacs uses gmalloc.c.
1792   if test "$GMALLOC_OBJ" = gmalloc.o; then
1793     emacs_pthread_function=pthread_atfork
1794   else
1795     emacs_pthread_function=pthread_self
1796   fi
1797   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1798 fi
1799 if test "$HAVE_PTHREAD" = yes; then
1800   case "${canonical}" in
1801     *-hpux*) ;;
1802     *) LIB_PTHREAD="-lpthread"
1803        LIBS="$LIB_PTHREAD $LIBS" ;;
1804   esac
1805   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1806 fi
1807 AC_SUBST([LIB_PTHREAD])
1808
1809 AC_CHECK_LIB(pthreads, cma_open)
1810
1811 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1812 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1813 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1814 ## added to LIBS in configure would never contain the pthreads part,
1815 ## but the value used in Makefiles might.  FIXME?
1816 ##
1817 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1818 ## be harmless on older versions of X where it happens to exist.
1819 test "$opsys" = "aix4-2" && \
1820   test $ac_cv_lib_pthreads_cma_open = yes && \
1821   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1822
1823 dnl Check for need for bigtoc support on IBM AIX
1824
1825 case ${host_os} in
1826 aix*)
1827   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1828     case $GCC in
1829     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1830     *) gdb_cv_bigtoc=-bbigtoc ;;
1831     esac
1832
1833     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1834     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1835   ])
1836   ;;
1837 esac
1838
1839 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1840 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1841 # REAL_CPPFLAGS later on.
1842
1843 REAL_CFLAGS="$CFLAGS"
1844 REAL_CPPFLAGS="$CPPFLAGS"
1845
1846 if test "${HAVE_X11}" = "yes"; then
1847   DEFS="$C_SWITCH_X_SITE $DEFS"
1848   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1849   LIBS="-lX11 $LIBS"
1850   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1851   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1852
1853   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1854   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1855   # but it's more convenient here to set LD_RUN_PATH since this
1856   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1857   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1858     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1859     export LD_RUN_PATH
1860   fi
1861
1862   if test "${opsys}" = "gnu-linux"; then
1863     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1864     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1865      [[XOpenDisplay ("foo");]])],
1866      [xgnu_linux_first_failure=no],
1867      [xgnu_linux_first_failure=yes])
1868     if test "${xgnu_linux_first_failure}" = "yes"; then
1869       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1870       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1871       OLD_CPPFLAGS="$CPPFLAGS"
1872       OLD_LIBS="$LIBS"
1873       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1874       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1875       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1876       LIBS="$LIBS -b i486-linuxaout"
1877       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1878        [[XOpenDisplay ("foo");]])],
1879        [xgnu_linux_second_failure=no],
1880        [xgnu_linux_second_failure=yes])
1881       if test "${xgnu_linux_second_failure}" = "yes"; then
1882         # If we get the same failure with -b, there is no use adding -b.
1883         # So take it out.  This plays safe.
1884         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1885         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1886         CPPFLAGS="$OLD_CPPFLAGS"
1887         LIBS="$OLD_LIBS"
1888         AC_MSG_RESULT(no)
1889       else
1890         AC_MSG_RESULT(yes)
1891       fi
1892     else
1893       AC_MSG_RESULT(no)
1894     fi
1895   fi
1896
1897   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1898   # header files included from there.
1899   AC_MSG_CHECKING(for Xkb)
1900   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1901 #include <X11/XKBlib.h>]],
1902         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1903         emacs_xkb=yes, emacs_xkb=no)
1904   AC_MSG_RESULT($emacs_xkb)
1905   if test $emacs_xkb = yes; then
1906     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1907   fi
1908
1909   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1910 XScreenNumberOfScreen)
1911 fi
1912
1913 if test "${window_system}" = "x11"; then
1914   AC_MSG_CHECKING(X11 version 6)
1915   AC_CACHE_VAL(emacs_cv_x11_version_6,
1916   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1917 [[#if XlibSpecificationRelease < 6
1918 fail;
1919 #endif
1920 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1921   if test $emacs_cv_x11_version_6 = yes; then
1922     AC_MSG_RESULT(6 or newer)
1923     AC_DEFINE(HAVE_X11R6, 1,
1924               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1925     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1926     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1927     ## XIM support.
1928     case "$opsys" in
1929       sol2-*) : ;;
1930       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1931            [Define if you have usable X11R6-style XIM support.])
1932          ;;
1933     esac
1934   else
1935     AC_MSG_RESULT(before 6)
1936   fi
1937 fi
1938
1939
1940 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1941 HAVE_RSVG=no
1942 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1943   if test "${with_rsvg}" != "no"; then
1944     RSVG_REQUIRED=2.11.0
1945     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1946
1947     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1948     AC_SUBST(RSVG_CFLAGS)
1949     AC_SUBST(RSVG_LIBS)
1950
1951     if test $HAVE_RSVG = yes; then
1952       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1953       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1954       LIBS="$RSVG_LIBS $LIBS"
1955     fi
1956   fi
1957 fi
1958
1959 HAVE_IMAGEMAGICK=no
1960 if test "${HAVE_X11}" = "yes"; then
1961   if test "${with_imagemagick}" != "no"; then
1962     ## 6.2.8 is the earliest version known to work, but earlier versions
1963     ## might work - let us know if you find one.
1964     ## 6.0.7 does not work.  See bug#7955.
1965     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1966     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1967     AC_SUBST(IMAGEMAGICK_CFLAGS)
1968     AC_SUBST(IMAGEMAGICK_LIBS)
1969
1970     if test $HAVE_IMAGEMAGICK = yes; then
1971       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1972       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1973       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1974       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
1975     fi
1976   fi
1977 fi
1978
1979
1980 HAVE_GTK=no
1981 GTK_OBJ=
1982 check_gtk2=no
1983 gtk3_pkg_errors=
1984 if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1985   GLIB_REQUIRED=2.28
1986   GTK_REQUIRED=3.0
1987   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1988
1989   dnl Checks for libraries.
1990   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1991   if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
1992      AC_MSG_ERROR($GTK_PKG_ERRORS)
1993   fi
1994   if test "$pkg_check_gtk" = "yes"; then
1995      AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1996      GTK_OBJ=emacsgtkfixed.o
1997      term_header=gtkutil.h
1998      USE_GTK_TOOLKIT="GTK3"
1999   else
2000      check_gtk2=yes
2001      gtk3_pkg_errors="$GTK_PKG_ERRORS "
2002   fi
2003 fi
2004
2005 if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2006   GLIB_REQUIRED=2.10
2007   GTK_REQUIRED=2.10
2008   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2009
2010   dnl Checks for libraries.
2011   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2012   if test "$pkg_check_gtk" = "no" &&
2013      { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2014   then
2015     AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2016   fi
2017   test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2018 fi
2019
2020 if test x"$pkg_check_gtk" = xyes; then
2021
2022   AC_SUBST(GTK_CFLAGS)
2023   AC_SUBST(GTK_LIBS)
2024   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2025   CFLAGS="$CFLAGS $GTK_CFLAGS"
2026   LIBS="$GTK_LIBS $LIBS"
2027   dnl Try to compile a simple GTK program.
2028   GTK_COMPILES=no
2029   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
2030   if test "${GTK_COMPILES}" != "yes"; then
2031     if test "$USE_X_TOOLKIT" != "maybe"; then
2032       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2033     fi
2034   else
2035     HAVE_GTK=yes
2036     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2037     GTK_OBJ="gtkutil.o $GTK_OBJ"
2038     USE_X_TOOLKIT=none
2039     if "$PKG_CONFIG" --atleast-version=2.10 gtk+-2.0; then
2040       :
2041     else
2042       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2043        closing open displays.  This is no problem if you just use
2044        one display, but if you use more than one and close one of them
2045        Emacs may crash.]])
2046       sleep 3
2047     fi
2048   fi
2049
2050 fi
2051 AC_SUBST(GTK_OBJ)
2052
2053
2054 if test "${HAVE_GTK}" = "yes"; then
2055
2056   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2057   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2058   if test "$with_toolkit_scroll_bars" != no; then
2059     with_toolkit_scroll_bars=yes
2060   fi
2061
2062   dnl  Check if we have the old file selection dialog declared and
2063   dnl  in the link library.  In 2.x it may be in the library,
2064   dnl  but not declared if deprecated featured has been selected out.
2065   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2066   HAVE_GTK_FILE_SELECTION=no
2067   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2068                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2069 #include <gtk/gtk.h>])
2070   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2071     AC_CHECK_FUNCS(gtk_file_selection_new)
2072   fi
2073
2074
2075   dnl Check for functions introduced in 2.14 and later.
2076   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2077                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2078                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2079                  gtk_orientable_set_orientation \
2080                  gtk_window_set_has_resize_grip)
2081
2082  term_header=gtkutil.h
2083 fi
2084
2085 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2086 dnl other platforms.
2087 HAVE_DBUS=no
2088 DBUS_OBJ=
2089 if test "${with_dbus}" = "yes"; then
2090    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2091    if test "$HAVE_DBUS" = yes; then
2092      LIBS="$LIBS $DBUS_LIBS"
2093      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2094      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2095      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2096      dnl D-Bus 1.5.12.
2097      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2098                     dbus_type_is_valid \
2099                     dbus_validate_bus_name \
2100                     dbus_validate_path \
2101                     dbus_validate_interface \
2102                     dbus_validate_member)
2103      DBUS_OBJ=dbusbind.o
2104    fi
2105 fi
2106 AC_SUBST(DBUS_OBJ)
2107
2108 dnl GSettings has been tested under GNU/Linux only.
2109 HAVE_GSETTINGS=no
2110 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2111    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2112    if test "$HAVE_GSETTINGS" = "yes"; then
2113       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2114       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2115       SETTINGS_LIBS="$GSETTINGS_LIBS"
2116    fi
2117 fi
2118
2119 dnl GConf has been tested under GNU/Linux only.
2120 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2121 HAVE_GCONF=no
2122 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2123    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2124    if test "$HAVE_GCONF" = yes; then
2125       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2126       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2127       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2128       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2129    fi
2130 fi
2131
2132 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2133     PKG_CHECK_MODULES(GOBJECT, gobject-2.0 >= 2.0, HAVE_GOBJECT=yes, HAVE_GOBJECT=no)
2134     if test "$HAVE_GOBJECT" = "yes"; then
2135        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2136        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2137     fi
2138     SAVE_CFLAGS="$CFLAGS"
2139     SAVE_LIBS="$LIBS"
2140     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2141     LIBS="$SETTINGS_LIBS $LIBS"
2142     AC_CHECK_FUNCS([g_type_init])
2143     CFLAGS="$SAVE_CFLAGS"
2144     LIBS="$SAVE_LIBS"
2145 fi
2146 AC_SUBST(SETTINGS_CFLAGS)
2147 AC_SUBST(SETTINGS_LIBS)
2148
2149
2150 dnl SELinux is available for GNU/Linux only.
2151 HAVE_LIBSELINUX=no
2152 LIBSELINUX_LIBS=
2153 if test "${with_selinux}" = "yes"; then
2154    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2155    if test "$HAVE_LIBSELINUX" = yes; then
2156       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2157       LIBSELINUX_LIBS=-lselinux
2158    fi
2159 fi
2160 AC_SUBST(LIBSELINUX_LIBS)
2161
2162 HAVE_GNUTLS=no
2163 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2164 if test "${with_gnutls}" = "yes" ; then
2165   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2166   if test "${HAVE_GNUTLS}" = "yes"; then
2167     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2168   fi
2169
2170   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2171   LIBS="$LIBGNUTLS_LIBS $LIBS"
2172   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2173
2174   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2175     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2176   fi
2177 fi
2178
2179 AC_SUBST(LIBGNUTLS_LIBS)
2180 AC_SUBST(LIBGNUTLS_CFLAGS)
2181
2182 dnl inotify is only available on GNU/Linux.
2183 if test "${with_inotify}" = "yes"; then
2184    AC_CHECK_HEADERS(sys/inotify.h)
2185    if test "$ac_cv_header_sys_inotify_h" = yes ; then
2186      AC_CHECK_FUNC(inotify_init1)
2187    fi
2188 fi
2189 if test "$ac_cv_func_inotify_init1" = yes; then
2190   AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2191 fi
2192
2193 dnl POSIX ACL support: provided by libacl on GNU/Linux, by libc on FreeBSD.
2194 HAVE_POSIX_ACL=no
2195 LIBACL_LIBS=
2196 if test "${with_acl}" = "yes"; then
2197   AC_CHECK_LIB([acl], [acl_set_file], HAVE_POSIX_ACL=yes, HAVE_POSIX_ACL=no)
2198   if test "$HAVE_POSIX_ACL" = yes; then
2199     AC_DEFINE(HAVE_POSIX_ACL, 1, [Define to 1 if using POSIX ACL support.])
2200     LIBACL_LIBS=-lacl
2201   else
2202     AC_CHECK_FUNC(acl_set_file, HAVE_POSIX_ACL=yes, HAVE_POSIX_ACL=no)
2203     if test "$HAVE_POSIX_ACL" = yes; then
2204       AC_DEFINE(HAVE_POSIX_ACL, 1, [Define to 1 if using POSIX ACL support.])
2205     fi
2206  fi
2207 fi
2208 AC_SUBST(LIBACL_LIBS)
2209
2210 dnl Do not put whitespace before the #include statements below.
2211 dnl Older compilers (eg sunos4 cc) choke on it.
2212 HAVE_XAW3D=no
2213 LUCID_LIBW=
2214 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2215   if test "$with_xaw3d" != no; then
2216     AC_CACHE_VAL(emacs_cv_xaw3d,
2217     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2218 #include <X11/Intrinsic.h>
2219 #include <X11/Xaw3d/Simple.h>]],
2220       [[]])],
2221       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2222                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2223       emacs_cv_xaw3d=no)])
2224   else
2225     emacs_cv_xaw3d=no
2226   fi
2227   if test $emacs_cv_xaw3d = yes; then
2228     AC_MSG_CHECKING(for xaw3d)
2229     AC_MSG_RESULT([yes; using Lucid toolkit])
2230     USE_X_TOOLKIT=LUCID
2231     HAVE_XAW3D=yes
2232     LUCID_LIBW=-lXaw3d
2233     AC_DEFINE(HAVE_XAW3D, 1,
2234               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2235   else
2236     AC_MSG_CHECKING(for xaw3d)
2237     AC_MSG_RESULT(no)
2238     AC_MSG_CHECKING(for libXaw)
2239     AC_CACHE_VAL(emacs_cv_xaw,
2240     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2241 #include <X11/Intrinsic.h>
2242 #include <X11/Xaw/Simple.h>]],
2243       [[]])],
2244       emacs_cv_xaw=yes,
2245       emacs_cv_xaw=no)])
2246     if test $emacs_cv_xaw = yes; then
2247       AC_MSG_RESULT([yes; using Lucid toolkit])
2248       USE_X_TOOLKIT=LUCID
2249       LUCID_LIBW=-lXaw
2250     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2251       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2252     else
2253       AC_MSG_ERROR([No X toolkit could be found.
2254 If you are sure you want Emacs compiled without an X toolkit, pass
2255   --with-x-toolkit=no
2256 to configure.  Otherwise, install the development libraries for the toolkit
2257 that you want to use (e.g. Gtk+) and re-run configure.])
2258     fi
2259   fi
2260 fi
2261
2262 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2263
2264 LIBXTR6=
2265 if test "${USE_X_TOOLKIT}" != "none"; then
2266   AC_MSG_CHECKING(X11 toolkit version)
2267   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2268   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2269 [[#if XtSpecificationRelease < 6
2270 fail;
2271 #endif
2272 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2273   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2274   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2275     AC_MSG_RESULT(6 or newer)
2276     AC_DEFINE(HAVE_X11XTR6, 1,
2277               [Define to 1 if you have the X11R6 or newer version of Xt.])
2278     LIBXTR6="-lSM -lICE"
2279     case "$opsys" in
2280       ## Use libw.a along with X11R6 Xt.
2281       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2282     esac
2283   else
2284     AC_MSG_RESULT(before 6)
2285   fi
2286
2287 dnl If using toolkit, check whether libXmu.a exists.
2288 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2289   OLDLIBS="$LIBS"
2290   if test x$HAVE_X11XTR6 = xyes; then
2291     LIBS="-lXt -lSM -lICE $LIBS"
2292   else
2293     LIBS="-lXt $LIBS"
2294   fi
2295   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2296   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2297   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2298 fi
2299 AC_SUBST(LIBXTR6)
2300
2301 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2302 dnl Why not just test for libxmu in the normal way?
2303 LIBXMU=-lXmu
2304 case $opsys in
2305   ## These systems don't supply Xmu.
2306   hpux* | aix4-2 )
2307     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2308     ;;
2309 esac
2310 AC_SUBST(LIBXMU)
2311
2312 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2313 if test "${HAVE_X11}" = "yes"; then
2314   if test "${USE_X_TOOLKIT}" != "none"; then
2315     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2316   fi
2317 fi
2318
2319 LIBXP=
2320 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2321   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2322   if test -d /usr/include/openmotif; then
2323     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2324     emacs_cv_openmotif=yes
2325     case "$canonical" in
2326       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2327       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2328       ;;
2329       *)
2330       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2331     esac
2332   else
2333     emacs_cv_openmotif=no
2334   fi
2335   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2336   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2337     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2338 int x = 5;
2339 #else
2340 Motif version prior to 2.1.
2341 #endif]])],
2342     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2343   if test $emacs_cv_motif_version_2_1 = yes; then
2344     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2345     if test x$emacs_cv_openmotif = xyes; then
2346       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2347     fi
2348   else
2349     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2350     # We put this in CFLAGS temporarily to precede other -I options
2351     # that might be in CFLAGS temporarily.
2352     # We put this in CPPFLAGS where it precedes the other -I options.
2353     OLD_CPPFLAGS=$CPPFLAGS
2354     OLD_CFLAGS=$CFLAGS
2355     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2356     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2357     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2358       [[int x = 5;]])],
2359       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2360     if test $emacs_cv_lesstif = yes; then
2361       # Make sure this -I option remains in CPPFLAGS after it is set
2362       # back to REAL_CPPFLAGS.
2363       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2364       # have those other -I options anyway.  Ultimately, having this
2365       # directory ultimately in CPPFLAGS will be enough.
2366       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2367       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2368     else
2369       CFLAGS=$OLD_CFLAGS
2370       CPPFLAGS=$OLD_CPPFLAGS
2371     fi
2372   fi
2373   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2374     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2375 fi
2376
2377 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2378 dnl using Motif or Xaw3d is available, and unless
2379 dnl --with-toolkit-scroll-bars=no was specified.
2380
2381 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2382             [Define to 1 if we should use toolkit scroll bars.])dnl
2383 USE_TOOLKIT_SCROLL_BARS=no
2384 if test "${with_toolkit_scroll_bars}" != "no"; then
2385   if test "${USE_X_TOOLKIT}" != "none"; then
2386     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2387       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2388       HAVE_XAW3D=no
2389       USE_TOOLKIT_SCROLL_BARS=yes
2390     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2391       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2392       USE_TOOLKIT_SCROLL_BARS=yes
2393     fi
2394   elif test "${HAVE_GTK}" = "yes"; then
2395     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2396     USE_TOOLKIT_SCROLL_BARS=yes
2397   elif test "${HAVE_NS}" = "yes"; then
2398     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2399     USE_TOOLKIT_SCROLL_BARS=yes
2400   elif test "${HAVE_W32}" = "yes"; then
2401     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2402     USE_TOOLKIT_SCROLL_BARS=yes
2403   fi
2404 fi
2405
2406 dnl See if XIM is available.
2407 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2408           #include <X11/Xlib.h>
2409           #include <X11/Xresource.h>]],
2410          [[XIMProc  callback;]])],
2411          [HAVE_XIM=yes
2412          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2413          HAVE_XIM=no)
2414
2415 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2416
2417 if test "${with_xim}" != "no"; then
2418   AC_DEFINE(USE_XIM, 1,
2419             [Define to 1 if we should use XIM, if it is available.])
2420 fi
2421
2422
2423 if test "${HAVE_XIM}" != "no"; then
2424   late_CFLAGS=$CFLAGS
2425   if test "$GCC" = yes; then
2426     CFLAGS="$CFLAGS --pedantic-errors"
2427   fi
2428   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2429 #include <X11/Xlib.h>
2430 #include <X11/Xresource.h>]],
2431 [[Display *display;
2432 XrmDatabase db;
2433 char *res_name;
2434 char *res_class;
2435 XIMProc  callback;
2436 XPointer *client_data;
2437 #ifndef __GNUC__
2438 /* If we're not using GCC, it's probably not XFree86, and this is
2439    probably right, but we can't use something like --pedantic-errors.  */
2440 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2441                                            char*, XIMProc, XPointer*);
2442 #endif
2443 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2444    client_data);]])],
2445     [emacs_cv_arg6_star=yes])
2446   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2447          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2448 either XPointer or XPointer*.])dnl
2449   if test "$emacs_cv_arg6_star" = yes; then
2450     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2451   else
2452     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2453   fi
2454   CFLAGS=$late_CFLAGS
2455 fi
2456
2457 ### Start of font-backend (under any platform) section.
2458 # (nothing here yet -- this is a placeholder)
2459 ### End of font-backend (under any platform) section.
2460
2461 ### Start of font-backend (under X11) section.
2462 if test "${HAVE_X11}" = "yes"; then
2463    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2464
2465    ## Use -lXft if available, unless `--with-xft=no'.
2466    HAVE_XFT=maybe
2467     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2468       with_xft="no";
2469     fi
2470     if test "x${with_xft}" != "xno"; then
2471
2472       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2473       ## Because xftfont.c uses XRenderQueryExtension, we also
2474       ## need to link to -lXrender.
2475       HAVE_XRENDER=no
2476       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2477       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2478         OLD_CPPFLAGS="$CPPFLAGS"
2479         OLD_CFLAGS="$CFLAGS"
2480         OLD_LIBS="$LIBS"
2481         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2482         CFLAGS="$CFLAGS $XFT_CFLAGS"
2483         XFT_LIBS="-lXrender $XFT_LIBS"
2484         LIBS="$XFT_LIBS $LIBS"
2485         AC_CHECK_HEADER(X11/Xft/Xft.h,
2486           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2487
2488         if test "${HAVE_XFT}" = "yes"; then
2489           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2490             AC_SUBST(XFT_LIBS)
2491           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2492         else
2493           CPPFLAGS="$OLD_CPPFLAGS"
2494           CFLAGS="$OLD_CFLAGS"
2495           LIBS="$OLD_LIBS"
2496         fi                        # "${HAVE_XFT}" = "yes"
2497       fi                          # "$HAVE_XFT" != no
2498     fi                            # "x${with_xft}" != "xno"
2499
2500     ## We used to allow building with FreeType and without Xft.
2501     ## However, the ftx font backend driver is not in good shape.
2502     if test "$HAVE_XFT" != "yes"; then
2503        dnl For the "Does Emacs use" message at the end.
2504        HAVE_XFT=no
2505        HAVE_FREETYPE=no
2506     else
2507        dnl Strict linkers fail with
2508        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2509        dnl if -lfreetype is not specified.
2510        dnl The following is needed to set FREETYPE_LIBS.
2511        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2512                          HAVE_FREETYPE=no)
2513
2514        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2515     fi
2516
2517     HAVE_LIBOTF=no
2518     if test "${HAVE_FREETYPE}" = "yes"; then
2519       AC_DEFINE(HAVE_FREETYPE, 1,
2520                 [Define to 1 if using the freetype and fontconfig libraries.])
2521       if test "${with_libotf}" != "no"; then
2522         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2523                           HAVE_LIBOTF=no)
2524         if test "$HAVE_LIBOTF" = "yes"; then
2525           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2526           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2527                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2528                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2529           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2530             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2531                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2532           fi
2533         fi
2534       fi
2535     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2536     dnl Does the new font backend require it, or can it work without it?
2537     fi
2538
2539     HAVE_M17N_FLT=no
2540     if test "${HAVE_LIBOTF}" = yes; then
2541       if test "${with_m17n_flt}" != "no"; then
2542         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2543         if test "$HAVE_M17N_FLT" = "yes"; then
2544           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2545         fi
2546       fi
2547     fi
2548 else
2549     HAVE_XFT=no
2550     HAVE_FREETYPE=no
2551     HAVE_LIBOTF=no
2552     HAVE_M17N_FLT=no
2553 fi
2554
2555 ### End of font-backend (under X11) section.
2556
2557 AC_SUBST(FREETYPE_CFLAGS)
2558 AC_SUBST(FREETYPE_LIBS)
2559 AC_SUBST(FONTCONFIG_CFLAGS)
2560 AC_SUBST(FONTCONFIG_LIBS)
2561 AC_SUBST(LIBOTF_CFLAGS)
2562 AC_SUBST(LIBOTF_LIBS)
2563 AC_SUBST(M17N_FLT_CFLAGS)
2564 AC_SUBST(M17N_FLT_LIBS)
2565
2566 ### Use -lXpm if available, unless `--with-xpm=no'.
2567 HAVE_XPM=no
2568 LIBXPM=
2569
2570 if test "${HAVE_W32}" = "yes"; then
2571   if test "${with_xpm}" != "no"; then
2572     SAVE_CPPFLAGS="$CPPFLAGS"
2573     SAVE_LDFLAGS="$LDFLAGS"
2574     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
2575     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
2576     AC_CHECK_HEADER(X11/xpm.h,
2577       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
2578     if test "${HAVE_XPM}" = "yes"; then
2579       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2580       AC_EGREP_CPP(no_return_alloc_pixels,
2581       [#include "X11/xpm.h"
2582 #ifndef XpmReturnAllocPixels
2583 no_return_alloc_pixels
2584 #endif
2585       ], HAVE_XPM=no, HAVE_XPM=yes)
2586
2587       if test "${HAVE_XPM}" = "yes"; then
2588         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
2589         AC_MSG_RESULT(yes)
2590       else
2591         AC_MSG_RESULT(no)
2592         CPPFLAGS="$SAVE_CPPFLAGS"
2593         LDFLAGS="$SAVE_LDFLAGS"
2594       fi
2595     fi
2596   fi
2597
2598   if test "${HAVE_XPM}" = "yes"; then
2599     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2600     LIBXPM=-lXpm
2601   fi
2602 fi
2603
2604 if test "${HAVE_X11}" = "yes"; then
2605   if test "${with_xpm}" != "no"; then
2606     AC_CHECK_HEADER(X11/xpm.h,
2607       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2608     if test "${HAVE_XPM}" = "yes"; then
2609       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2610       AC_EGREP_CPP(no_return_alloc_pixels,
2611       [#include "X11/xpm.h"
2612 #ifndef XpmReturnAllocPixels
2613 no_return_alloc_pixels
2614 #endif
2615       ], HAVE_XPM=no, HAVE_XPM=yes)
2616
2617       if test "${HAVE_XPM}" = "yes"; then
2618         AC_MSG_RESULT(yes)
2619       else
2620         AC_MSG_RESULT(no)
2621       fi
2622     fi
2623   fi
2624
2625   if test "${HAVE_XPM}" = "yes"; then
2626     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2627     LIBXPM=-lXpm
2628   fi
2629 fi
2630
2631 AC_SUBST(LIBXPM)
2632
2633 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2634 HAVE_JPEG=no
2635 LIBJPEG=
2636 if test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2637   if test "${with_jpeg}" != "no"; then
2638     dnl Checking for jpeglib.h can lose because of a redefinition of
2639     dnl  HAVE_STDLIB_H.
2640     AC_CHECK_HEADER(jerror.h,
2641       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2642   fi
2643
2644   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2645   if test "${HAVE_JPEG}" = "yes"; then
2646     AC_DEFINE(HAVE_JPEG)
2647     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2648         [#include <jpeglib.h>
2649          version=JPEG_LIB_VERSION
2650 ],
2651         [AC_DEFINE(HAVE_JPEG)],
2652         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2653         HAVE_JPEG=no])
2654   fi
2655   if test "${HAVE_JPEG}" = "yes"; then
2656     LIBJPEG=-ljpeg
2657   fi
2658 fi
2659 AC_SUBST(LIBJPEG)
2660
2661 ### Use -lpng if available, unless `--with-png=no'.
2662 HAVE_PNG=no
2663 LIBPNG=
2664 if test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2665   if test "${with_png}" != "no"; then
2666     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2667     # in /usr/include/libpng.
2668     AC_CHECK_HEADERS(png.h libpng/png.h, break)
2669     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2670       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2671     fi
2672   fi
2673
2674   if test "${HAVE_PNG}" = "yes"; then
2675     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2676     LIBPNG="-lpng -lz -lm"
2677
2678     AC_CHECK_DECL(png_longjmp,
2679       [],
2680       [AC_DEFINE(PNG_DEPSTRUCT, [],
2681          [Define to empty to suppress deprecation warnings when building
2682           with --enable-gcc-warnings and with libpng versions before 1.5,
2683           which lack png_longjmp.])],
2684       [[#ifdef HAVE_LIBPNG_PNG_H
2685         # include <libpng/png.h>
2686         #else
2687         # include <png.h>
2688         #endif
2689       ]])
2690   fi
2691 fi
2692 AC_SUBST(LIBPNG)
2693
2694 ### Use -ltiff if available, unless `--with-tiff=no'.
2695 HAVE_TIFF=no
2696 LIBTIFF=
2697 if test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2698   if test "${with_tiff}" != "no"; then
2699     AC_CHECK_HEADER(tiffio.h,
2700       [tifflibs="-lz -lm"
2701       # At least one tiff package requires the jpeg library.
2702       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2703       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2704   fi
2705
2706   if test "${HAVE_TIFF}" = "yes"; then
2707     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2708     dnl FIXME -lz -lm, as per libpng?
2709     LIBTIFF=-ltiff
2710   fi
2711 fi
2712 AC_SUBST(LIBTIFF)
2713
2714 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2715 HAVE_GIF=no
2716 LIBGIF=
2717 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
2718         || test "${HAVE_W32}" = "yes"; then
2719   AC_CHECK_HEADER(gif_lib.h,
2720 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2721 # Earlier versions can crash Emacs.
2722     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2723
2724   if test "$HAVE_GIF" = yes; then
2725     LIBGIF=-lgif
2726   elif test "$HAVE_GIF" = maybe; then
2727 # If gif_lib.h but no libgif, try libungif.
2728     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2729     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2730   fi
2731
2732   if test "${HAVE_GIF}" = "yes"; then
2733     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2734   fi
2735 fi
2736 AC_SUBST(LIBGIF)
2737
2738 dnl Check for required libraries.
2739 if test "${HAVE_X11}" = "yes"; then
2740   MISSING=""
2741   WITH_NO=""
2742   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2743     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2744   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2745     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2746   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2747     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2748   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2749     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2750   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2751     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2752
2753   if test "X${MISSING}" != X; then
2754     AC_MSG_ERROR([The following required libraries were not found:
2755     $MISSING
2756 Maybe some development libraries/packages are missing?
2757 If you don't want to link with them give
2758     $WITH_NO
2759 as options to configure])
2760   fi
2761 fi
2762
2763 ### Use -lgpm if available, unless `--with-gpm=no'.
2764 HAVE_GPM=no
2765 LIBGPM=
2766 if test "${with_gpm}" != "no"; then
2767   AC_CHECK_HEADER(gpm.h,
2768     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2769
2770   if test "${HAVE_GPM}" = "yes"; then
2771     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2772     LIBGPM=-lgpm
2773   fi
2774 fi
2775 AC_SUBST(LIBGPM)
2776
2777 dnl Check for malloc/malloc.h on darwin
2778 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2779
2780 GNUSTEP_CFLAGS=
2781 ### Use NeXTstep API to implement GUI.
2782 if test "${HAVE_NS}" = "yes"; then
2783   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2784   if test "${NS_IMPL_COCOA}" = "yes"; then
2785     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2786   fi
2787   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2788     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2789     # See also .m.o rule in Makefile.in */
2790     # FIXME: are all these flags really needed?  Document here why.  */
2791     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2792     ## Extra CFLAGS applied to src/*.m files.
2793     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2794   fi
2795   # We also have mouse menus.
2796   HAVE_MENUS=yes
2797   OTHER_FILES=ns-app
2798 fi
2799
2800 if test "${HAVE_W32}" = "yes"; then
2801   HAVE_MENUS=yes
2802 fi
2803
2804 ### Use session management (-lSM -lICE) if available
2805 HAVE_X_SM=no
2806 LIBXSM=
2807 if test "${HAVE_X11}" = "yes"; then
2808   AC_CHECK_HEADER(X11/SM/SMlib.h,
2809     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2810
2811   if test "${HAVE_X_SM}" = "yes"; then
2812     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2813     LIBXSM="-lSM -lICE"
2814     case "$LIBS" in
2815       *-lSM*) ;;
2816       *)      LIBS="$LIBXSM $LIBS" ;;
2817     esac
2818   fi
2819 fi
2820 AC_SUBST(LIBXSM)
2821
2822 ### Use libxml (-lxml2) if available
2823 HAVE_LIBXML2=no
2824 if test "${with_xml2}" != "no"; then
2825   ### I'm not sure what the version number should be, so I just guessed.
2826   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2827   if test "${HAVE_LIBXML2}" = "yes"; then
2828     LIBS="$LIBXML2_LIBS $LIBS"
2829     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2830     if test "${HAVE_LIBXML2}" = "yes"; then
2831       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2832     else
2833       LIBXML2_LIBS=""
2834       LIBXML2_CFLAGS=""
2835     fi
2836   fi
2837 fi
2838 AC_SUBST(LIBXML2_LIBS)
2839 AC_SUBST(LIBXML2_CFLAGS)
2840
2841 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2842 AC_CACHE_CHECK(whether netdb declares h_errno,
2843                emacs_cv_netdb_declares_h_errno,
2844 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2845   [[return h_errno;]])],
2846   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2847 if test $emacs_cv_netdb_declares_h_errno = yes; then
2848   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2849 fi
2850
2851 # sqrt and other floating-point functions such as fmod and frexp
2852 # are found in -lm on most systems.
2853 AC_CHECK_LIB(m, sqrt)
2854
2855 # Check for mail-locking functions in a "mail" library.  Probably this should
2856 # have the same check as for liblockfile below.
2857 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2858 if test $have_mail = yes; then
2859   LIBS_MAIL=-lmail
2860   LIBS="$LIBS_MAIL $LIBS"
2861   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2862 else
2863   LIBS_MAIL=
2864 fi
2865 dnl Debian, at least:
2866 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2867 if test $have_lockfile = yes; then
2868    LIBS_MAIL=-llockfile
2869    LIBS="$LIBS_MAIL $LIBS"
2870    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2871 else
2872 # If we have the shared liblockfile, assume we must use it for mail
2873 # locking (e.g. Debian).  If we couldn't link against liblockfile
2874 # (no liblockfile.a installed), ensure that we don't need to.
2875   dnl This works for files generally, not just executables.
2876   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2877   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2878                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2879   if test $ac_cv_prog_liblockfile = yes; then
2880     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2881 This probably means that movemail could lose mail.
2882 There may be a `development' package to install containing liblockfile.])
2883   fi
2884 fi
2885 AC_CHECK_HEADERS_ONCE(maillock.h)
2886 AC_SUBST(LIBS_MAIL)
2887
2888 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2889 ## interlock access to the mail spool.  The alternative is a lock file named
2890 ## /usr/spool/mail/$USER.lock.
2891 mail_lock=no
2892 case "$opsys" in
2893   aix4-2) mail_lock="lockf" ;;
2894
2895   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2896
2897   ## On GNU/Linux systems, both methods are used by various mail programs.
2898   ## I assume most people are using newer mailers that have heard of flock.
2899   ## Change this if you need to.
2900   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2901   ## configure gets the right answers, and that means *NOT* using flock.
2902   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2903   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2904   ## Debian maintainer hasn't provided a clean fix for Emacs.
2905   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2906   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2907   ## correct logic.  -- fx
2908   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2909   ## liblockfile is a Free Software replacement for libmail, used on
2910   ## Debian systems and elsewhere. -rfr.
2911   gnu-*)
2912     mail_lock="flock"
2913     if test $have_mail = yes || test $have_lockfile = yes; then
2914       test $ac_cv_header_maillock_h = yes && mail_lock=no
2915     fi
2916     ;;
2917 esac
2918
2919 BLESSMAIL_TARGET=
2920 case "$mail_lock" in
2921   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2922
2923   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2924
2925   *) BLESSMAIL_TARGET="need-blessmail" ;;
2926 esac
2927 AC_SUBST(BLESSMAIL_TARGET)
2928
2929
2930 AC_CHECK_FUNCS(gethostname \
2931 getrusage get_current_dir_name \
2932 lrand48 \
2933 select getpagesize setlocale \
2934 utimes getrlimit setrlimit shutdown getaddrinfo \
2935 strsignal setitimer \
2936 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
2937 gai_strerror mkstemp getline getdelim fsync sync \
2938 difftime posix_memalign \
2939 getpwent endpwent getgrent endgrent \
2940 touchlock \
2941 cfmakeraw cfsetspeed copysign __executable_start)
2942
2943 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
2944 ## has a broken `rint' in some library versions including math library
2945 ## version number A.09.05.
2946 ## You can fix the math library by installing patch number PHSS_4630.
2947 ## But we can fix it more reliably for Emacs by just not using rint.
2948 ## We also skip HAVE_RANDOM - see comments in src/conf_post.h.
2949 case $opsys in
2950    hpux*) : ;;
2951    *) AC_CHECK_FUNCS(random rint) ;;
2952 esac
2953
2954 dnl Cannot use AC_CHECK_FUNCS
2955 AC_CACHE_CHECK([for __builtin_unwind_init],
2956                emacs_cv_func___builtin_unwind_init,
2957 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2958                 emacs_cv_func___builtin_unwind_init=yes,
2959                 emacs_cv_func___builtin_unwind_init=no)])
2960 if test $emacs_cv_func___builtin_unwind_init = yes; then
2961   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2962             [Define to 1 if you have the `__builtin_unwind_init' function.])
2963 fi
2964
2965 AC_CHECK_HEADERS_ONCE(sys/un.h)
2966
2967 AC_FUNC_FSEEKO
2968
2969 # UNIX98 PTYs.
2970 AC_CHECK_FUNCS(grantpt)
2971
2972 # PTY-related GNU extensions.
2973 AC_CHECK_FUNCS(getpt posix_openpt)
2974
2975 # Check this now, so that we will NOT find the above functions in ncurses.
2976 # That is because we have not set up to link ncurses in lib-src.
2977 # It's better to believe a function is not available
2978 # than to expect to find it in ncurses.
2979 # Also we need tputs and friends to be able to build at all.
2980 AC_MSG_CHECKING([for library containing tputs])
2981 # Run a test program that contains a call to tputs, a call that is
2982 # never executed.  This tests whether a pre-'main' dynamic linker
2983 # works with the library.  It's too much trouble to actually call
2984 # tputs in the test program, due to portability hassles.  When
2985 # cross-compiling, assume the test program will run if it links.
2986 AC_DEFUN([tputs_link_source], [
2987   AC_LANG_SOURCE(
2988      [[extern void tputs (const char *, int, int (*)(int));
2989        int main (int argc, char **argv)
2990        {
2991           if (argc == 10000)
2992             tputs (argv[0], 0, 0);
2993           return 0;
2994        }]])
2995 ])
2996 # Maybe curses should be tried earlier?
2997 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2998 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2999   OLIBS=$LIBS
3000   if test -z "$tputs_library"; then
3001     LIBS_TERMCAP=
3002     msg='none required'
3003   else
3004     LIBS_TERMCAP=-l$tputs_library
3005     msg=$LIBS_TERMCAP
3006     LIBS="$LIBS_TERMCAP $LIBS"
3007   fi
3008   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3009     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3010   LIBS=$OLIBS
3011   if test "X$msg" != Xno; then
3012     break
3013   fi
3014 done
3015 AC_MSG_RESULT([$msg])
3016 if test "X$msg" = Xno; then
3017   AC_MSG_ERROR([The required function `tputs' was not found in any library.
3018 The following libraries were tried (in order):
3019   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3020 Please try installing whichever of these libraries is most appropriate
3021 for your system, together with its header files.
3022 For example, a libncurses-dev(el) or similar package.])
3023 fi
3024
3025 ## Use termcap instead of terminfo?
3026 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3027 TERMINFO=yes
3028 ## FIXME?  In the cases below where we unconditionally set
3029 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3030 ## if that was found above to have tputs.
3031 ## Should we use the gnu* logic everywhere?
3032 case "$opsys" in
3033   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3034   ##  The ncurses library has been moved out of the System framework in
3035   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3036   ##  option to use it.
3037   darwin) LIBS_TERMCAP="-lncurses" ;;
3038
3039   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3040
3041   freebsd)
3042     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3043     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3044     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3045 [[#if __FreeBSD_version < 400000
3046 fail;
3047 #endif
3048 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3049
3050     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3051
3052     if test $emacs_cv_freebsd_terminfo = yes; then
3053       LIBS_TERMCAP="-lncurses"
3054     else
3055       TERMINFO=no
3056       LIBS_TERMCAP="-ltermcap"
3057     fi
3058     ;;
3059
3060   netbsd)
3061     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3062       TERMINFO=no
3063       LIBS_TERMCAP="-ltermcap"
3064     fi
3065     ;;
3066
3067   openbsd) LIBS_TERMCAP="-lncurses" ;;
3068
3069   ## hpux: Make sure we get select from libc rather than from libcurses
3070   ##  because libcurses on HPUX 10.10 has a broken version of select.
3071   ##  We used to use -lc -lcurses, but this may be cleaner.
3072   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3073   # set that way, now it uses the default).  Isn't this a contradiction?
3074   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3075
3076 esac
3077
3078 TERMCAP_OBJ=tparam.o
3079 if test $TERMINFO = yes; then
3080   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3081   TERMCAP_OBJ=terminfo.o
3082 fi
3083 AC_SUBST(LIBS_TERMCAP)
3084 AC_SUBST(TERMCAP_OBJ)
3085
3086
3087 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3088 # On Darwin, res_init appears not to be useful: see bug#562 and
3089 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3090 resolv=no
3091
3092 if test $opsys != darwin; then
3093
3094   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3095 #include <arpa/nameser.h>
3096 #include <resolv.h>]],
3097     [[return res_init();]])],
3098     have_res_init=yes, have_res_init=no)
3099   if test "$have_res_init" = no; then
3100     OLIBS="$LIBS"
3101     LIBS="$LIBS -lresolv"
3102     AC_MSG_CHECKING(for res_init with -lresolv)
3103     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3104 #include <arpa/nameser.h>
3105 #include <resolv.h>]],
3106       [[return res_init();]])],
3107       have_res_init=yes, have_res_init=no)
3108     AC_MSG_RESULT($have_res_init)
3109     if test "$have_res_init" = yes ; then
3110       resolv=yes
3111     fi
3112     LIBS="$OLIBS"
3113   fi
3114
3115   if test "$have_res_init" = yes; then
3116     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3117   fi
3118 fi                              dnl !darwin
3119
3120 # Do we need the Hesiod library to provide the support routines?
3121 dnl FIXME?  Should we be skipping this on Darwin too?
3122 LIBHESIOD=
3123 if test "$with_hesiod" != no ; then
3124   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3125   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3126      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3127                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3128   if test "$resolv" = yes ; then
3129     RESOLVLIB=-lresolv
3130   else
3131     RESOLVLIB=
3132   fi
3133   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3134         hesiod=yes, :, $RESOLVLIB)])
3135
3136   if test x"$hesiod" = xyes; then
3137     AC_DEFINE(HAVE_LIBHESIOD, 1,
3138               [Define to 1 if you have the hesiod library (-lhesiod).])
3139     LIBHESIOD=-lhesiod
3140   fi
3141 fi
3142 AC_SUBST(LIBHESIOD)
3143
3144 # Do we need libresolv (due to res_init or Hesiod)?
3145 if test "$resolv" = yes && test $opsys != darwin; then
3146   AC_DEFINE(HAVE_LIBRESOLV, 1,
3147             [Define to 1 if you have the resolv library (-lresolv).])
3148   LIBRESOLV=-lresolv
3149 else
3150   LIBRESOLV=
3151 fi
3152 AC_SUBST(LIBRESOLV)
3153
3154 # These tell us which Kerberos-related libraries to use.
3155 COM_ERRLIB=
3156 CRYPTOLIB=
3157 KRB5LIB=
3158 DESLIB=
3159 KRB4LIB=
3160
3161 if test "${with_kerberos}" != no; then
3162   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3163   if test $have_com_err = yes; then
3164     COM_ERRLIB=-lcom_err
3165     LIBS="$COM_ERRLIB $LIBS"
3166     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
3167   fi
3168   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3169   if test $have_crypto = yes; then
3170     CRYPTOLIB=-lcrypto
3171     LIBS="$CRYPTOLIB $LIBS"
3172     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
3173   fi
3174   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3175   if test $have_k5crypto = yes; then
3176     CRYPTOLIB=-lk5crypto
3177     LIBS="$CRYPTOLIB $LIBS"
3178     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
3179   fi
3180   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3181   if test $have_krb5=yes; then
3182     KRB5LIB=-lkrb5
3183     LIBS="$KRB5LIB $LIBS"
3184     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
3185   fi
3186   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3187   if test "${with_kerberos5}" = no; then
3188     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3189     if test $have_des425 = yes; then
3190       DESLIB=-ldes425
3191       LIBS="$DESLIB $LIBS"
3192       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
3193     else
3194       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3195       if test $have_des = yes; then
3196         DESLIB=-ldes
3197         LIBS="$DESLIB $LIBS"
3198         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
3199       fi
3200     fi
3201     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3202     if test $have_krb4 = yes; then
3203       KRB4LIB=-lkrb4
3204       LIBS="$KRB4LIB $LIBS"
3205       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
3206     else
3207       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3208       if test $have_krb = yes; then
3209         KRB4LIB=-lkrb
3210         LIBS="$KRB4LIB $LIBS"
3211         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
3212       fi
3213     fi
3214   fi
3215
3216   if test "${with_kerberos5}" != no; then
3217     AC_CHECK_HEADERS(krb5.h,
3218       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3219                         [#include <krb5.h>])])
3220   else
3221     AC_CHECK_HEADERS(des.h,,
3222                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3223                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3224     AC_CHECK_HEADERS(krb.h,,
3225                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3226                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3227   fi
3228   AC_CHECK_HEADERS(com_err.h)
3229 fi
3230
3231 AC_SUBST(COM_ERRLIB)
3232 AC_SUBST(CRYPTOLIB)
3233 AC_SUBST(KRB5LIB)
3234 AC_SUBST(DESLIB)
3235 AC_SUBST(KRB4LIB)
3236
3237 AC_CHECK_FUNCS_ONCE(tzset)
3238 AC_MSG_CHECKING(whether localtime caches TZ)
3239 AC_CACHE_VAL(emacs_cv_localtime_cache,
3240 [if test x$ac_cv_func_tzset = xyes; then
3241 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3242 char TZ_GMT0[] = "TZ=GMT0";
3243 char TZ_PST8[] = "TZ=PST8";
3244 main()
3245 {
3246   time_t now = time ((time_t *) 0);
3247   int hour_GMT0, hour_unset;
3248   if (putenv (TZ_GMT0) != 0)
3249     exit (1);
3250   hour_GMT0 = localtime (&now)->tm_hour;
3251   unsetenv("TZ");
3252   hour_unset = localtime (&now)->tm_hour;
3253   if (putenv (TZ_PST8) != 0)
3254     exit (1);
3255   if (localtime (&now)->tm_hour == hour_GMT0)
3256     exit (1);
3257   unsetenv("TZ");
3258   if (localtime (&now)->tm_hour != hour_unset)
3259     exit (1);
3260   exit (0);
3261 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3262 [# If we have tzset, assume the worst when cross-compiling.
3263 emacs_cv_localtime_cache=yes])
3264 else
3265         # If we lack tzset, report that localtime does not cache TZ,
3266         # since we can't invalidate the cache if we don't have tzset.
3267         emacs_cv_localtime_cache=no
3268 fi])dnl
3269 AC_MSG_RESULT($emacs_cv_localtime_cache)
3270 if test $emacs_cv_localtime_cache = yes; then
3271   AC_DEFINE(LOCALTIME_CACHE, 1,
3272             [Define to 1 if localtime caches TZ.])
3273 fi
3274
3275 ok_so_far=yes
3276 AC_CHECK_FUNC(socket, , ok_so_far=no)
3277 if test $ok_so_far = yes; then
3278   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3279 fi
3280 if test $ok_so_far = yes; then
3281   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3282 fi
3283 if test $ok_so_far = yes; then
3284 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3285   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3286             [Define to 1 if you have inet sockets.])
3287 fi
3288
3289 if test -f /usr/lpp/X11/bin/smt.exp; then
3290   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3291             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3292 fi
3293
3294 AC_MSG_CHECKING(whether system supports dynamic ptys)
3295 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3296   AC_MSG_RESULT(yes)
3297   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3298 else
3299   AC_MSG_RESULT(no)
3300 fi
3301
3302 dnl Check for a Solaris 2.4 vfork bug that Autoconf misses (through 2.69).
3303 dnl This can be removed once we assume Autoconf 2.70.
3304 case $canonical in
3305   *-solaris2.4 | *-solaris2.4.*)
3306     dnl Disable the Autoconf-generated vfork test.
3307     : ${ac_cv_func_vfork_works=no};;
3308 esac
3309
3310 AC_FUNC_FORK
3311
3312 AC_CHECK_FUNCS(snprintf)
3313
3314 dnl Adapted from Haible's version.
3315 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3316   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3317     [[char* cs = nl_langinfo(CODESET);]])],
3318     emacs_cv_langinfo_codeset=yes,
3319     emacs_cv_langinfo_codeset=no)
3320   ])
3321 if test $emacs_cv_langinfo_codeset = yes; then
3322   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3323     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3324 fi
3325
3326 AC_TYPE_MBSTATE_T
3327
3328 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3329   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3330                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3331 if test "$emacs_cv_c_restrict_arr" = yes; then
3332   AC_DEFINE(__restrict_arr, __restrict,
3333     [Define to compiler's equivalent of C99 restrict keyword in array
3334      declarations.  Define as empty for no equivalent.])
3335 fi
3336
3337 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3338 dnl how the tty code is related to POSIX and/or other versions of termios.
3339 dnl The following looks like a useful start.
3340 dnl
3341 dnl AC_SYS_POSIX_TERMIOS
3342 dnl if test $ac_cv_sys_posix_termios = yes; then
3343 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3344 dnl                                and macros for terminal control.])
3345 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3346 dnl fi
3347
3348 dnl Turned on June 1996 supposing nobody will mind it.
3349 AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3350   in the full name stands for the login id.])
3351
3352 dnl Every platform that uses configure (ie every non-MS platform)
3353 dnl supports this.  There is a create-lockfiles option you can
3354 dnl customize if you do not want the lock files to be written.
3355 dnl So it is not clear that this #define still needs to exist.
3356 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3357   so that Emacs can tell instantly when you try to modify a file that
3358   someone else has modified in his/her Emacs.])
3359
3360 dnl Everybody supports this, except MS.
3361 dnl Seems like the kind of thing we should be testing for, though.
3362 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3363 AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3364
3365 dnl Everybody supports this, except MS-DOS.
3366 dnl Seems like the kind of thing we should be testing for, though.
3367 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3368 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3369   4.2-compatible sockets.])
3370
3371 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3372
3373 AC_DEFINE(NULL_DEVICE, ["/dev/null"], [Name of the file to open to get
3374   a null file, or a data sink.])
3375
3376 AC_DEFINE(SEPCHAR, [':'], [Character that separates PATH elements.])
3377
3378 dnl Everybody supports this, except MS-DOS.
3379 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
3380
3381 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
3382
3383
3384 AC_DEFINE(DIRECTORY_SEP, ['/'],
3385   [Character that separates directories in a file name.])
3386
3387 dnl Only used on MS platforms.
3388 AH_TEMPLATE(DEVICE_SEP, [Character that separates a device in a file name.])
3389
3390 AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
3391   [Returns true if character is a device separator.])
3392
3393 AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
3394   [Returns true if character is a directory separator.])
3395
3396 dnl On MS, this also accepts IS_DEVICE_SEP.
3397 AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
3398   [Returns true if character is any form of separator.])
3399
3400
3401 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3402
3403 case $opsys in
3404   aix4-2)
3405     dnl Unfortunately without libXmu we cannot support EditRes.
3406     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
3407       AC_DEFINE(NO_EDITRES, 1)
3408     fi
3409     ;;
3410
3411   hpux*)
3412     dnl Assar Westerlund <assar@sics.se> says this is necessary for
3413     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
3414     AC_DEFINE(NO_EDITRES, 1)
3415     ;;
3416 esac
3417
3418
3419 case $opsys in
3420   irix6-5 | sol2* | unixware )
3421     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
3422     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
3423     dnl need the constant to dimension an array.  So wire in the appropriate
3424     dnl value here.
3425     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
3426     ;;
3427 esac
3428
3429 emacs_broken_SIGIO=no
3430
3431 case $opsys in
3432   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3433   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3434   hpux* | irix6-5 | openbsd | sol2* | unixware )
3435     emacs_broken_SIGIO=yes
3436     ;;
3437
3438   aix4-2)
3439     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
3440     dnl the way this system works, libc functions that return malloced
3441     dnl memory use the libc malloc implementation. Calling xfree or
3442     dnl xrealloc on the results of such functions results in a crash.
3443     dnl
3444     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
3445     dnl but that does not currently work on this system.
3446     dnl
3447     dnl It is possible to completely override the malloc implementation on
3448     dnl AIX, but that involves putting the malloc functions in a shared
3449     dnl library and setting the MALLOCTYPE environment variable to point to
3450     dnl that shared library.
3451     dnl
3452     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
3453     dnl to avoid a crash just use the Emacs implementation for that function.
3454     dnl
3455     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
3456     dnl of this file, so that we do not check for get_current_dir_name
3457     dnl on AIX.  But that might be fragile if something else ends
3458     dnl up testing for get_current_dir_name as a dependency.
3459     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
3460       get_current_dir_name should not be used.])
3461     ;;
3462
3463   freebsd)
3464     dnl Circumvent a bug in FreeBSD.  In the following sequence of
3465     dnl writes/reads on a PTY, read(2) returns bogus data:
3466     dnl
3467     dnl write(2)  1022 bytes
3468     dnl write(2)   954 bytes, get EAGAIN
3469     dnl read(2)   1024 bytes in process_read_output
3470     dnl read(2)     11 bytes in process_read_output
3471     dnl
3472     dnl That is, read(2) returns more bytes than have ever been written
3473     dnl successfully.  The 1033 bytes read are the 1022 bytes written
3474     dnl successfully after processing (for example with CRs added if the
3475     dnl terminal is set up that way which it is here).  The same bytes will
3476     dnl be seen again in a later read(2), without the CRs.
3477     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
3478       work around an issue when reading from a PTY.])
3479     ;;
3480 esac
3481
3482 case $opsys in
3483   gnu-* | sol2-10 )
3484     dnl FIXME Can't we test if this exists (eg /proc/$$)?
3485     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3486   ;;
3487 esac
3488
3489 case $opsys in
3490   darwin | freebsd | netbsd | openbsd )
3491     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
3492       close a pty to make it a controlling terminal (it is already a
3493       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
3494   ;;
3495 esac
3496
3497 dnl FIXME Surely we can test for this rather than hard-code it.
3498 case $opsys in
3499   netbsd | openbsd) sound_device="/dev/audio" ;;
3500   *) sound_device="/dev/dsp" ;;
3501 esac
3502
3503 dnl Used in sound.c
3504 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
3505   [Name of the default sound device.])
3506
3507
3508 dnl Emacs can read input using SIGIO and buffering characters itself,
3509 dnl or using CBREAK mode and making C-g cause SIGINT.
3510 dnl The choice is controlled by the variable interrupt_input.
3511 dnl
3512 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
3513 dnl
3514 dnl Emacs uses the presence of the USABLE_SIGIO macro
3515 dnl to indicate whether or not signal-driven I/O is possible.  It uses
3516 dnl INTERRUPT_INPUT to decide whether to use it by default.
3517 dnl
3518 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
3519 dnl CBREAK mode has two disadvantages
3520 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
3521 dnl I hear that in system V this problem does not exist.
3522 dnl 2) Control-G causes output to be discarded.
3523 dnl I do not know whether this can be fixed in system V.
3524 dnl
3525 dnl Another method of doing input is planned but not implemented.
3526 dnl It would have Emacs fork off a separate process
3527 dnl to read the input and send it to the true Emacs process
3528 dnl through a pipe.
3529 case $opsys in
3530   darwin | gnu-linux | gnu-kfreebsd )
3531     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
3532   ;;
3533 esac
3534
3535
3536 dnl If the system's imake configuration file defines `NeedWidePrototypes'
3537 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
3538 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
3539 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
3540 dnl taking float or double parameters.
3541 case $opsys in
3542   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
3543     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
3544       file defines `NeedWidePrototypes' as `NO'.])
3545   ;;
3546 esac
3547
3548
3549 dnl Used in process.c, this must be a loop, even if it only runs once.
3550 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
3551 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
3552 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
3553 dnl trying suffixes 0-16.
3554 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
3555   first PTY, if PTYs are supported.])
3556 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
3557 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
3558   end of a PTY, if non-standard.])
3559 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
3560   end of a PTY, if non-standard.])
3561
3562 case $opsys in
3563   aix4-2 )
3564     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
3565     dnl You allocate a pty by opening /dev/ptc to get the master side.
3566     dnl To get the name of the slave side, you just ttyname() the master side.
3567     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
3568     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
3569     ;;
3570
3571   cygwin )
3572     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3573     dnl multi-line AC_DEFINEs are hard. :(
3574     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (0)])
3575     AC_DEFINE(PTY_NAME_SPRINTF, [])
3576     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3577     ;;
3578
3579   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
3580   darwin )
3581     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3582     dnl Not used, because PTY_ITERATION is defined.
3583     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3584     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
3585     dnl But we don't have to block SIGCHLD because it is blocked in the
3586     dnl implementation of grantpt.
3587     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (0)])
3588     AC_DEFINE(PTY_NAME_SPRINTF, [])
3589     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3590     ;;
3591
3592   gnu | openbsd )
3593     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3594     ;;
3595
3596   gnu-linux | gnu-kfreebsd | freebsd | netbsd )
3597     dnl if HAVE_GRANTPT
3598     if test "x$ac_cv_func_grantpt" = xyes; then
3599       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
3600       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3601       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
3602       dnl to prevent sigchld_handler from intercepting the child's death.
3603       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3604       dnl if HAVE_POSIX_OPENPT
3605       if test "x$ac_cv_func_posix_openpt" = xyes; then
3606         AC_DEFINE(PTY_OPEN, [fd = posix_openpt (O_RDWR | O_NOCTTY)])
3607         AC_DEFINE(PTY_NAME_SPRINTF, [])
3608       dnl if HAVE_GETPT
3609       elif test "x$ac_cv_func_getpt" = xyes; then
3610         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
3611         AC_DEFINE(PTY_NAME_SPRINTF, [])
3612       else
3613         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3614       fi
3615     else
3616       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3617     fi
3618     ;;
3619
3620   hpux*)
3621     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3622     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
3623     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
3624     ;;
3625
3626   irix6-5 )
3627     dnl It looks like this cannot be right, because it is not a loop.
3628     dnl However, process.c actually does this:
3629     dnl # ifndef __sgi
3630     dnl   continue;
3631     dnl # else
3632     dnl   return -1;
3633     dnl # endif
3634     dnl which presumably makes it OK, since irix == sgi (?).
3635     dnl FIXME it seems like this special treatment is unnecessary?
3636     dnl Why can't irix use a single-trip loop like eg cygwin?
3637     AC_DEFINE(PTY_ITERATION, [])
3638     dnl Not used, because PTY_ITERATION is defined.
3639     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
3640     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
3641     dnl No need to get the pty name at all.
3642     AC_DEFINE(PTY_NAME_SPRINTF, [])
3643     dnl No need to use sprintf to get the tty name--we get that from _getpty.
3644     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3645     ;;
3646
3647   sol2* )
3648     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
3649     dnl from intercepting that death.  If any child but grantpt's should die
3650     dnl within, it should be caught after sigrelse(2).
3651     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3652     ;;
3653
3654   unixware )
3655     dnl Comments are as per sol2*.
3656     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3657     ;;
3658 esac
3659
3660
3661 case $opsys in
3662   sol2* | unixware )
3663     dnl This change means that we don't loop through allocate_pty too
3664     dnl many times in the (rare) event of a failure.
3665     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
3666     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3667     dnl Push various streams modules onto a PTY channel.  Used in process.c.
3668     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
3669     ;;
3670 esac
3671
3672
3673 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
3674 "typing" a signal character on the pty.])
3675
3676 case $opsys in
3677   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
3678   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
3679   aix4-2 | cygwin | gnu | irix6-5 | freebsd | netbsd | openbsd | darwin )
3680     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3681     ;;
3682
3683   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
3684   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
3685   gnu-linux | gnu-kfreebsd )
3686
3687     AC_MSG_CHECKING([for signals via characters])
3688     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3689 #include <linux/version.h>
3690 #if LINUX_VERSION_CODE < 0x20400
3691 # error "Linux version too old"
3692 #endif
3693       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
3694
3695     AC_MSG_RESULT([$emacs_signals_via_chars])
3696     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3697     ;;
3698 esac
3699
3700
3701 dnl Used in vm-limit.c
3702 AH_TEMPLATE(DATA_START, [Address of the start of the data segment.])
3703 dnl Used in lisp.h, emacs.c, mem-limits.h
3704 dnl NEWS.18 describes this as "a number which contains
3705 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
3706 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
3707 stored in a Lisp_Object.])
3708 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
3709
3710 case $opsys in
3711   gnu)
3712     dnl libc defines data_start.
3713     AC_DEFINE(DATA_START, [({ extern int data_start; (char *) &data_start; })])
3714     ;;
3715
3716   hpux*)
3717     dnl The data segment on this machine always starts at address 0x40000000.
3718     AC_DEFINE(DATA_START, [0x40000000])
3719     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
3720     ;;
3721   irix6-5)
3722     AC_DEFINE(DATA_START, [0x10000000])
3723     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
3724     ;;
3725 esac
3726
3727
3728 AH_TEMPLATE(TAB3, [Undocumented.])
3729
3730 case $opsys in
3731   darwin) AC_DEFINE(TAB3, OXTABS) ;;
3732
3733   gnu | freebsd | netbsd | openbsd )
3734     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
3735     AC_DEFINE(TAB3, OXTABS)
3736     ;;
3737
3738   gnu-linux | gnu-kfreebsd )
3739     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3740 #ifndef __ia64__
3741 # error "not ia64"
3742 #endif
3743       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
3744         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (0)],
3745         [Mark a secondary stack, like the register stack on the ia64.]), [])
3746     ;;
3747
3748   hpux*)
3749     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
3750       run_time_remap; for HPUX.])
3751     ;;
3752 esac
3753
3754
3755 dnl These won't be used automatically yet.  We also need to know, at least,
3756 dnl that the stack is continuous.
3757 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
3758   registers relevant for conservative garbage collection in the jmp_buf.])
3759
3760 AH_TEMPLATE(GC_MARK_STACK, [Define to GC_USE_GCPROS_AS_BEFORE if
3761   conservative garbage collection is not known to work.])
3762
3763
3764 case $opsys in
3765   aix4-2 | hpux* | unixware)
3766     dnl Conservative garbage collection has not been tested, so for now
3767     dnl play it safe and stick with the old-fashioned way of marking.
3768     AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE])
3769     ;;
3770
3771   dnl Not all the architectures are tested, but there are Debian packages
3772   dnl for SCM and/or Guile on them, so the technique must work.  See also
3773   dnl comments in alloc.c concerning setjmp and gcc.
3774   dnl Fixme: it's probably safe to just use the GCC conditional below.
3775   gnu-linux | gnu-kfreebsd )
3776     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3777 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
3778   || defined __alpha__ || defined __mips__ || defined __s390__ \
3779   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
3780   || defined __ia64__ || defined __sh__
3781 /* ok */
3782 #else
3783 # error "setjmp not known to work on this arch"
3784 #endif
3785     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1),
3786       AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE]) )
3787     ;;
3788 esac
3789
3790
3791 if test x$GCC = xyes; then
3792    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
3793    AC_DEFINE(GC_SETJMP_WORKS, 1)
3794 else
3795   case $opsys in
3796     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
3797     freebsd | netbsd | openbsd | irix6-5 | sol2* )
3798       AC_DEFINE(GC_SETJMP_WORKS, 1)
3799       ;;
3800   esac
3801 fi                              dnl GCC?
3802
3803 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
3804   [AC_LINK_IFELSE(
3805      [AC_LANG_PROGRAM(
3806        [[#include <setjmp.h>
3807        ]],
3808        [[jmp_buf j;
3809          if (! _setjmp (j))
3810            _longjmp (j, 1);]])],
3811      [emacs_cv_func__setjmp=yes],
3812      [emacs_cv_func__setjmp=no])])
3813 if test $emacs_cv_func__setjmp = yes; then
3814   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
3815 else
3816   AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
3817     [AC_LINK_IFELSE(
3818        [AC_LANG_PROGRAM(
3819          [[#include <setjmp.h>
3820          ]],
3821          [[sigjmp_buf j;
3822            if (! sigsetjmp (j, 1))
3823              siglongjmp (j, 1);]])],
3824        [emacs_cv_func_sigsetjmp=yes],
3825        [emacs_cv_func_sigsetjmp=no])])
3826   if test $emacs_cv_func_sigsetjmp = yes; then
3827     AC_DEFINE([HAVE_SIGSETJMP], 1,
3828       [Define to 1 if sigsetjmp and siglongjmp work.
3829        The value of this symbol is irrelevant if HAVE__SETJMP is defined.])
3830   fi
3831 fi
3832
3833 case $opsys in
3834   sol2* | unixware )
3835     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
3836     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
3837     dnl and this is all we need.
3838     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
3839     ;;
3840 esac
3841
3842
3843 case $opsys in
3844   hpux* | sol2* )
3845     dnl Used in xfaces.c.
3846     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
3847       some systems, where it requires time.h.])
3848     ;;
3849 esac
3850
3851
3852 dnl Define symbols to identify the version of Unix this is.
3853 dnl Define all the symbols that apply correctly.
3854 AH_TEMPLATE(BSD_SYSTEM, [Define if the system is compatible with BSD 4.2.])
3855 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
3856 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
3857 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
3858 AH_TEMPLATE(USG5, [Define if the system is compatible with System V.])
3859 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
3860
3861 case $opsys in
3862   aix4-2)
3863     AC_DEFINE(USG, [])
3864     AC_DEFINE(USG5, [])
3865     dnl This symbol should be defined on AIX Version 3  ???????
3866     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3867 #ifndef _AIX
3868 # error "_AIX not defined"
3869 #endif
3870     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
3871     ;;
3872
3873   cygwin)
3874     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
3875     ;;
3876
3877   darwin)
3878     dnl BSD4_3 and BSD4_4 are already defined in sys/param.h.
3879     AC_DEFINE(BSD_SYSTEM, [])
3880     dnl More specific than the above two.  We cannot use __APPLE__ as this
3881     dnl may not be defined on non-OSX Darwin, and we cannot define DARWIN
3882     dnl here because Panther and lower CoreFoundation.h uses DARWIN to
3883     dnl distinguish OS X from pure Darwin.
3884     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
3885     ;;
3886
3887   freebsd)
3888     dnl Hack to avoid calling AC_PREPROC_IFELSE multiple times.
3889     dnl Would not be needed with autoconf >= 2.67, where the
3890     dnl preprocessed output is accessible in "conftest.i".
3891     AC_DEFINE(BSD_SYSTEM_AHB, 1, [Define if AH_BOTTOM should change BSD_SYSTEM.])
3892     ;;
3893
3894   gnu | netbsd | openbsd )
3895     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3896 #ifndef BSD_SYSTEM
3897 # error "BSD_SYSTEM not defined"
3898 #endif
3899     ]], [[]])], [], AC_DEFINE(BSD_SYSTEM, 43) )
3900     ;;
3901
3902   gnu-linux | gnu-kfreebsd )
3903     AC_DEFINE(USG, [])
3904     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
3905     ;;
3906
3907   hpux*)
3908     AC_DEFINE(USG, [])
3909     AC_DEFINE(USG5, [])
3910     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
3911     ;;
3912
3913   irix6-5)
3914     AC_DEFINE(USG, [])
3915     AC_DEFINE(USG5, [])
3916     AC_DEFINE(USG5_4, [])
3917     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
3918     ;;
3919
3920   sol2*)
3921     AC_DEFINE(USG, [])
3922     AC_DEFINE(USG5, [])
3923     AC_DEFINE(USG5_4, [])
3924     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
3925     ;;
3926
3927   unixware)
3928     AC_DEFINE(USG, [])
3929     AC_DEFINE(USG5, [])
3930     AC_DEFINE(USG5_4, [])
3931     ;;
3932 esac
3933
3934 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
3935   [case $opsys in
3936      aix4-2)
3937        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
3938        emacs_cv_usable_FIONREAD=no
3939        ;;
3940
3941      *)
3942        AC_COMPILE_IFELSE(
3943          [AC_LANG_PROGRAM([[#include <sys/types.h>
3944                             #include <sys/ioctl.h>
3945                             #ifdef USG5_4
3946                             # include <sys/filio.h>
3947                             #endif
3948                           ]],
3949                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
3950          [emacs_cv_usable_FIONREAD=yes],
3951          [emacs_cv_usable_FIONREAD=no])
3952        ;;
3953    esac])
3954 if test $emacs_cv_usable_FIONREAD = yes; then
3955   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
3956
3957   if test $emacs_broken_SIGIO = no; then
3958     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
3959       [AC_COMPILE_IFELSE(
3960          [AC_LANG_PROGRAM([[#include <fcntl.h>
3961                             #include <signal.h>
3962                           ]],
3963                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
3964          [emacs_cv_usable_SIGIO=yes],
3965          [emacs_cv_usable_SIGIO=no])],
3966       [emacs_cv_usable_SIGIO=yes],
3967       [emacs_cv_usable_SIGIO=no])
3968     if test $emacs_cv_usable_SIGIO = yes; then
3969       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
3970     fi
3971   fi
3972 fi
3973
3974
3975 case $opsys in
3976   dnl Emacs supplies its own malloc, but glib (part of Gtk+) calls
3977   dnl memalign and on Cygwin, that becomes the Cygwin-supplied memalign.
3978   dnl As malloc is not the Cygwin malloc, the Cygwin memalign always
3979   dnl returns ENOSYS.  A workaround is to set G_SLICE=always-malloc. */
3980   cygwin)
3981     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
3982       G_SLICE environment variable to "always-malloc" at startup, if
3983       using GTK.])
3984     ;;
3985
3986   hpux11)
3987     dnl It works to open the pty's tty in the parent (Emacs), then
3988     dnl close and reopen it in the child.
3989     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
3990       works to open a pty's tty in the parent process, then close and
3991       reopen it in the child.])
3992     ;;
3993
3994   irix6-5)
3995     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
3996       use VSUSP instead of VSWTCH.])
3997     ;;
3998
3999   sol2-10)
4000     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4001       on Solaris.])
4002     ;;
4003 esac
4004
4005 # Set up the CFLAGS for real compilation, so we can substitute it.
4006 CFLAGS="$REAL_CFLAGS"
4007 CPPFLAGS="$REAL_CPPFLAGS"
4008
4009 ## Hack to detect a buggy GCC version.
4010 if test "x$GCC" = xyes \
4011    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4012    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4013    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4014    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4015 fi
4016
4017 version=$PACKAGE_VERSION
4018
4019 copyright="Copyright (C) 2012 Free Software Foundation, Inc."
4020 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4021   [Short copyright string for this version of Emacs.])
4022 AC_SUBST(copyright)
4023
4024 ### Specify what sort of things we'll be editing into Makefile and config.h.
4025 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4026 AC_SUBST(version)
4027 AC_SUBST(configuration)
4028 ## Unused?
4029 AC_SUBST(canonical)
4030 AC_SUBST(srcdir)
4031 AC_SUBST(prefix)
4032 AC_SUBST(exec_prefix)
4033 AC_SUBST(bindir)
4034 AC_SUBST(datadir)
4035 AC_SUBST(sharedstatedir)
4036 AC_SUBST(libexecdir)
4037 AC_SUBST(mandir)
4038 AC_SUBST(infodir)
4039 AC_SUBST(lispdir)
4040 AC_SUBST(leimdir)
4041 AC_SUBST(standardlisppath)
4042 AC_SUBST(locallisppath)
4043 AC_SUBST(lisppath)
4044 AC_SUBST(x_default_search_path)
4045 AC_SUBST(etcdir)
4046 AC_SUBST(archlibdir)
4047 AC_SUBST(docdir)
4048 AC_SUBST(bitmapdir)
4049 AC_SUBST(gamedir)
4050 AC_SUBST(gameuser)
4051 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4052 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4053 ## end of LIBX_BASE, but nothing ever set it.
4054 AC_SUBST(LD_SWITCH_X_SITE)
4055 AC_SUBST(C_SWITCH_X_SITE)
4056 AC_SUBST(GNUSTEP_CFLAGS)
4057 AC_SUBST(CFLAGS)
4058 ## Used in lwlib/Makefile.in.
4059 AC_SUBST(X_TOOLKIT_TYPE)
4060 AC_SUBST(ns_appdir)
4061 AC_SUBST(ns_appbindir)
4062 AC_SUBST(ns_appresdir)
4063 AC_SUBST(ns_appsrc)
4064 AC_SUBST(GNU_OBJC_CFLAGS)
4065 AC_SUBST(OTHER_FILES)
4066
4067 if test -n "${term_header}"; then
4068     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4069         [Define to the header for the built-in window system.])
4070 fi
4071
4072 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4073                    [Define to the canonical Emacs configuration name.])
4074 dnl Replace any embedded " characters (bug#13274).
4075 emacs_config_options=`echo "$emacs_config_options" | sed -e "s/\"/'/g"`
4076 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4077                    [Define to the options passed to configure.])
4078 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4079   define this to include extra configuration information.])
4080
4081 XMENU_OBJ=
4082 XOBJ=
4083 FONT_OBJ=
4084 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4085   AC_DEFINE(HAVE_X_WINDOWS, 1,
4086             [Define to 1 if you want to use the X window system.])
4087   XMENU_OBJ=xmenu.o
4088   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o xgselect.o"
4089   FONT_OBJ=xfont.o
4090   if test "$HAVE_XFT" = "yes"; then
4091     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4092   elif test "$HAVE_FREETYPE" = "yes"; then
4093     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4094   fi
4095   AC_SUBST(FONT_OBJ)
4096 fi
4097 AC_SUBST(XMENU_OBJ)
4098 AC_SUBST(XOBJ)
4099 AC_SUBST(FONT_OBJ)
4100
4101 WIDGET_OBJ=
4102 MOTIF_LIBW=
4103 if test "${USE_X_TOOLKIT}" != "none" ; then
4104   WIDGET_OBJ=widget.o
4105   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4106   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4107     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4108   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4109     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4110     MOTIF_LIBW=-lXm
4111     case "$opsys" in
4112       gnu-linux)
4113         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4114         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4115         ;;
4116
4117       unixware)
4118         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4119         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4120         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4121         ;;
4122
4123       aix4-2)
4124         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4125         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4126         ;;
4127     esac
4128     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4129   fi
4130 fi
4131 AC_SUBST(WIDGET_OBJ)
4132
4133 TOOLKIT_LIBW=
4134 case "$USE_X_TOOLKIT" in
4135   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4136   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4137   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4138 esac
4139 AC_SUBST(TOOLKIT_LIBW)
4140
4141 if test "$USE_X_TOOLKIT" = "none"; then
4142   LIBXT_OTHER="\$(LIBXSM)"
4143   OLDXMENU_TARGET="really-oldXMenu"
4144 else
4145   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4146   OLDXMENU_TARGET="really-lwlib"
4147 fi
4148 AC_SUBST(LIBXT_OTHER)
4149
4150 ## The X Menu stuff is present in the X10 distribution, but missing
4151 ## from X11.  If we have X10, just use the installed library;
4152 ## otherwise, use our own copy.
4153 if test "${HAVE_X11}" = "yes" ; then
4154   AC_DEFINE(HAVE_X11, 1,
4155             [Define to 1 if you want to use version 11 of X windows.
4156              Otherwise, Emacs expects to use version 10.])
4157
4158   if test "$USE_X_TOOLKIT" = "none"; then
4159     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
4160   else
4161     OLDXMENU="\${lwlibdir}/liblw.a"
4162   fi
4163   LIBXMENU="\$(OLDXMENU)"
4164   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4165   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
4166 else
4167   ## For a syntactically valid Makefile; not actually used for anything.
4168   ## See comments in src/Makefile.in.
4169   OLDXMENU=nothing
4170   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
4171   if test "${HAVE_X_WINDOWS}" = "yes"; then
4172     LIBXMENU="-lXMenu"
4173   else
4174     LIBXMENU=
4175   fi
4176   LIBX_OTHER=
4177   OLDXMENU_DEPS=
4178 fi
4179
4180 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
4181   OLDXMENU_TARGET=
4182   OLDXMENU=nothing
4183   LIBXMENU=
4184   OLDXMENU_DEPS=
4185 fi
4186
4187 AC_SUBST(OLDXMENU_TARGET)
4188 AC_SUBST(OLDXMENU)
4189 AC_SUBST(LIBXMENU)
4190 AC_SUBST(LIBX_OTHER)
4191 AC_SUBST(OLDXMENU_DEPS)
4192
4193 if test "${HAVE_MENUS}" = "yes" ; then
4194   AC_DEFINE(HAVE_MENUS, 1,
4195             [Define to 1 if you have mouse menus.
4196              (This is automatic if you use X, but the option to specify it remains.)
4197              It is also defined with other window systems that support xmenu.c.])
4198 fi
4199
4200 if test "${GNU_MALLOC}" = "yes" ; then
4201   AC_DEFINE(GNU_MALLOC, 1,
4202             [Define to 1 if you want to use the GNU memory allocator.])
4203 fi
4204
4205 RALLOC_OBJ=
4206 if test "${REL_ALLOC}" = "yes" ; then
4207   AC_DEFINE(REL_ALLOC, 1,
4208             [Define REL_ALLOC if you want to use the relocating allocator for
4209              buffer space.])
4210
4211   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4212 fi
4213 AC_SUBST(RALLOC_OBJ)
4214
4215 if test "$opsys" = "cygwin"; then
4216   CYGWIN_OBJ="sheap.o cygw32.o"
4217   ## Cygwin differs because of its unexec().
4218   PRE_ALLOC_OBJ=
4219   POST_ALLOC_OBJ=lastfile.o
4220 else
4221   CYGWIN_OBJ=
4222   PRE_ALLOC_OBJ=lastfile.o
4223   POST_ALLOC_OBJ=
4224 fi
4225 AC_SUBST(CYGWIN_OBJ)
4226 AC_SUBST(PRE_ALLOC_OBJ)
4227 AC_SUBST(POST_ALLOC_OBJ)
4228
4229 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4230 # it temporarily reverts them to their pre-pkg-config values,
4231 # because gnulib needs to work with both src (which uses the
4232 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4233 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4234 # and it therefore needs to run in an environment where LIBS does not
4235 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4236 # for some package unrelated to lib-src.
4237 SAVE_CFLAGS=$CFLAGS
4238 SAVE_LIBS=$LIBS
4239 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4240 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4241 gl_ASSERT_NO_GNULIB_POSIXCHECK
4242 gl_ASSERT_NO_GNULIB_TESTS
4243 gl_INIT
4244 CFLAGS=$SAVE_CFLAGS
4245 LIBS=$SAVE_LIBS
4246
4247 case "$opsys" in
4248   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4249
4250   darwin)
4251    ## The -headerpad option tells ld (see man page) to leave room at the
4252    ## end of the header for adding load commands.  Needed for dumping.
4253    ## 0x690 is the total size of 30 segment load commands (at 56
4254    ## each); under Cocoa 31 commands are required.
4255    if test "$HAVE_NS" = "yes"; then
4256      libs_nsgui="-framework AppKit"
4257      headerpad_extra=6C8
4258    else
4259      libs_nsgui=
4260      headerpad_extra=690
4261    fi
4262    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4263
4264    ## This is here because src/Makefile.in did some extra fiddling around
4265    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
4266    ##   #ifndef LD_SWITCH_SYSTEM
4267    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
4268    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
4269    ## not using gcc, darwin.
4270    ## Because this was done in src/Makefile.in, the resulting part of
4271    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
4272    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
4273    ## rather than LD_SWITCH_SYSTEM.
4274    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4275      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4276    ;;
4277
4278   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4279   ## find X at run-time.
4280   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4281   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4282   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4283   ## had different values in configure (in ac_link) and src/Makefile.in.
4284   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4285   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4286
4287   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4288 esac
4289
4290 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4291
4292
4293 LD_FIRSTFLAG=
4294 ORDINARY_LINK=
4295 case "$opsys" in
4296   ## gnu: GNU needs its own crt0.
4297   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
4298
4299   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
4300   ## library search parth, i.e. it won't search /usr/lib for libc and
4301   ## friends.  Using -nostartfiles instead avoids this problem, and
4302   ## will also work on earlier NetBSD releases.
4303   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
4304
4305   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
4306   ##   MkLinux/LinuxPPC needs this.
4307   ## s390x-* only supports opsys = gnu-linux so it can be added here.
4308   gnu-*)
4309     case "$canonical" in
4310       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
4311     esac
4312     ;;
4313 esac
4314
4315
4316 if test "x$ORDINARY_LINK" = "xyes"; then
4317
4318   LD_FIRSTFLAG=""
4319   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
4320
4321 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
4322 ## freebsd, gnu-* not on powerpc*|s390x*.
4323 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
4324
4325   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
4326   ## places that are difficult to figure out at make time.  Fortunately,
4327   ## these same versions allow you to pass arbitrary flags on to the
4328   ## linker, so there is no reason not to use it as a linker.
4329   ##
4330   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
4331   ## searching for libraries in its internal directories, so we have to
4332   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
4333   LD_FIRSTFLAG="-nostdlib"
4334 fi
4335
4336 ## FIXME? What setting of EDIT_LDFLAGS should this have?
4337 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
4338
4339 AC_SUBST(LD_FIRSTFLAG)
4340
4341
4342 ## FIXME? The logic here is not precisely the same as that above.
4343 ## There is no check here for a pre-defined LD_FIRSTFLAG.
4344 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
4345 LIB_GCC=
4346 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
4347
4348   case "$opsys" in
4349     freebsd|netbsd|openbsd) LIB_GCC= ;;
4350
4351     gnu-*)
4352       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
4353       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
4354       case $host_cpu in
4355       arm*)
4356         LIB_GCC="-lgcc_s"
4357         ;;
4358       *)
4359         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
4360         ## immediately undefine it again and redefine it to empty.
4361         ## Was the C_SWITCH_X_SITE part really necessary?
4362 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
4363         LIB_GCC=
4364         ;;
4365       esac
4366       ;;
4367
4368     ## Ask GCC where to find libgcc.a.
4369     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
4370   esac
4371 fi                              dnl if $GCC
4372 AC_SUBST(LIB_GCC)
4373
4374 ## Common for all window systems
4375 if test "$window_system" != "none"; then
4376   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4377   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4378 fi
4379
4380 AC_SUBST(WINDOW_SYSTEM_OBJ)
4381
4382 AH_TOP([/* GNU Emacs site configuration template file.
4383
4384 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
4385   Free Software Foundation, Inc.
4386
4387 This file is part of GNU Emacs.
4388
4389 GNU Emacs is free software: you can redistribute it and/or modify
4390 it under the terms of the GNU General Public License as published by
4391 the Free Software Foundation, either version 3 of the License, or
4392 (at your option) any later version.
4393
4394 GNU Emacs is distributed in the hope that it will be useful,
4395 but WITHOUT ANY WARRANTY; without even the implied warranty of
4396 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4397 GNU General Public License for more details.
4398
4399 You should have received a copy of the GNU General Public License
4400 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4401
4402
4403 /* No code in Emacs #includes config.h twice, but some bits of code
4404    intended to work with other packages as well (like gmalloc.c)
4405    think they can include it as many times as they like.  */
4406 #ifndef EMACS_CONFIG_H
4407 #define EMACS_CONFIG_H
4408 ])dnl
4409
4410 AH_BOTTOM([#include <conf_post.h>
4411
4412 #endif /* EMACS_CONFIG_H */
4413
4414 /*
4415 Local Variables:
4416 mode: c
4417 End:
4418 */
4419 ])dnl
4420
4421 #### Report on what we decided to do.
4422 #### Report GTK as a toolkit, even if it doesn't use Xt.
4423 #### It makes printing result more understandable as using GTK sets
4424 #### toolkit_scroll_bars to yes by default.
4425 if test "${HAVE_GTK}" = "yes"; then
4426   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
4427 fi
4428
4429 echo "
4430 Configured for \`${canonical}'.
4431
4432   Where should the build process find the source code?    ${srcdir}
4433   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4434   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4435   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4436   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4437   What window system should Emacs use?                    ${window_system}
4438   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4439
4440 if test -n "${x_includes}"; then
4441 echo "  Where do we find X Windows header files?                ${x_includes}"
4442 else
4443 echo "  Where do we find X Windows header files?                Standard dirs"
4444 fi
4445 if test -n "${x_libraries}"; then
4446 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4447 else
4448 echo "  Where do we find X Windows libraries?                   Standard dirs"
4449 fi
4450
4451 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4452 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4453 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4454 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4455 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
4456 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
4457 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
4458 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
4459
4460 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
4461 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
4462 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
4463 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
4464 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
4465 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
4466 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
4467
4468 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
4469 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
4470 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
4471 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
4472
4473 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
4474 echo
4475
4476 if test -n "${EMACSDATA}"; then
4477    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
4478 fi
4479 if test -n "${EMACSDOC}"; then
4480    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
4481 fi
4482
4483 echo
4484
4485 if test "$HAVE_NS" = "yes"; then
4486    echo
4487    echo "You must run \"${MAKE-make} install\" in order to test the built application.
4488 The installed application will go to nextstep/Emacs.app and can be
4489 run or moved from there."
4490    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
4491       echo "The application will be fully self-contained."
4492     else
4493       echo "The lisp resources for the application will be installed under ${prefix}.
4494 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
4495 to run if these resources are not installed."
4496    fi
4497    echo
4498 fi
4499
4500 if test "${opsys}" = "cygwin"; then
4501   case `uname -r` in
4502     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
4503            echo
4504            ;;
4505   esac
4506 fi
4507
4508 # Remove any trailing slashes in these variables.
4509 [test "${prefix}" != NONE &&
4510   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
4511 test "${exec_prefix}" != NONE &&
4512   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
4513
4514 if test "$HAVE_NS" = "yes"; then
4515   if test "$NS_IMPL_GNUSTEP" = yes; then
4516     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
4517       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
4518   else
4519     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
4520       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
4521   fi
4522 fi
4523
4524 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
4525 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
4526 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
4527 dnl (else you get "no `Makefile.am' found for any configure output").
4528 dnl This will work, but you get a config.status that is not quite right
4529 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
4530 dnl That doesn't have any obvious consequences for Emacs, but on the whole
4531 dnl it seems better to just live with the duplication.
4532 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile"
4533
4534 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
4535        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
4536        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
4537        leim/Makefile nextstep/Makefile])
4538
4539 dnl test/ is not present in release tarfiles.
4540 opt_makefile=test/automated/Makefile
4541
4542 if test -f "$srcdir/$opt_makefile.in"; then
4543   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4544   dnl Again, it's best not to use a variable.  Though you can add
4545   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
4546   AC_CONFIG_FILES([test/automated/Makefile])
4547 fi
4548
4549
4550 dnl admin/ may or may not be present.
4551 opt_makefile=admin/unidata/Makefile
4552
4553 if test -f "$srcdir/$opt_makefile.in"; then
4554   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4555   AC_CONFIG_FILES([admin/unidata/Makefile])
4556 fi
4557
4558
4559 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
4560
4561 AC_SUBST(SUBDIR_MAKEFILES_IN)
4562
4563 dnl Make the necessary directories, if they don't exist.
4564 AC_CONFIG_COMMANDS([mkdirs], [
4565 for dir in etc lisp ; do
4566   test -d ${dir} || mkdir ${dir}
4567 done
4568 ])
4569
4570 dnl You might wonder (I did) why epaths.h is generated by running make,
4571 dnl rather than just letting configure generate it from epaths.in.
4572 dnl One reason is that the various paths are not fully expanded (see above);
4573 dnl eg gamedir=${prefix}/var/games/emacs.
4574 dnl Secondly, the GNU Coding standards require that one should be able
4575 dnl to run `make prefix=/some/where/else' and override the values set
4576 dnl by configure.  This also explains the `move-if-change' test and
4577 dnl the use of force in the `epaths-force' rule in Makefile.in.
4578 AC_CONFIG_COMMANDS([epaths], [
4579 echo creating src/epaths.h
4580 ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
4581 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
4582
4583 AC_CONFIG_COMMANDS([gdbinit], [
4584 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
4585   echo creating src/.gdbinit
4586   echo "source $srcdir/src/.gdbinit" > src/.gdbinit
4587 fi
4588 ])
4589
4590 AC_OUTPUT