code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.65)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 gameuser=games
  49
  50 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  51 dnl Create a new --with option that defaults to being disabled.
  52 dnl NAME is the base name of the option.  The shell variable with_NAME
  53 dnl   will be set to either the user's value (if the option is
  54 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  55 dnl   option is not specified).  Note that the shell variable name is
  56 dnl   constructed as autoconf does, by replacing non-alphanumeric
  57 dnl   characters with "_".
  58 dnl HELP-STRING is the help text for the option.
  59 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  60   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  61     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  62 ])dnl
  63
  64 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  65 dnl Create a new --with option that defaults to being enabled.  NAME
  66 dnl   is the base name of the option.  The shell variable with_NAME
  67 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  68 dnl   'yes' (if the option is not specified).  Note that the shell
  69 dnl   variable name is constructed as autoconf does, by replacing
  70 dnl   non-alphanumeric characters with "_".
  71 dnl HELP-STRING is the help text for the option.
  72 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  73   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  74    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  75 ])dnl
  76
  77 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  78 if test "$with_pop" = yes; then
  79    AC_DEFINE(MAIL_USE_POP)
  80 fi
  81 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  82
  83 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  84 if test "$with_kerberos" != no; then
  85    AC_DEFINE(KERBEROS)
  86 fi
  87 AH_TEMPLATE(KERBEROS,
  88             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  89
  90 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  91 if test "${with_kerberos5}" != no; then
  92   if test "${with_kerberos}" = no; then
  93     with_kerberos=yes
  94     AC_DEFINE(KERBEROS)
  95   fi
  96   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  97 fi
  98
  99 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 100 dnl FIXME hesiod support may not be present, so it seems like an error
 101 dnl to define, or at least use, this unconditionally.
 102 if test "$with_hesiod" != no; then
 103   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 104 fi
 105
 106 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 107 if test "$with_mmdf" != no; then
 108    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 109 fi
 110
 111 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 112 if test "$with_mail_unlink" != no; then
 113    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 114 fi
 115
 116 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 117     [string giving default POP mail host])],
 118     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 119
 120 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 121
 122 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 123 if test "$with_sync_input" = yes; then
 124    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 125 fi
 126
 127 dnl FIXME currently it is not the last.
 128 dnl This should be the last --with option, because --with-x is
 129 dnl added later on when we find the path of X, and it's best to
 130 dnl keep them together visually.
 131 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 132  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 133 [         case "${withval}" in
 134             y | ye | yes )      val=gtk ;;
 135             n | no )            val=no  ;;
 136             l | lu | luc | luci | lucid )       val=lucid ;;
 137             a | at | ath | athe | athen | athena )      val=athena ;;
 138             m | mo | mot | moti | motif )       val=motif ;;
 139             g | gt | gtk  )     val=gtk ;;
 140             gtk3  )     val=gtk3 ;;
 141             * )
 142 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 143 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 144 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 145             ;;
 146           esac
 147           with_x_toolkit=$val
 148 ])
 149
 150 dnl _ON results in a '--without' option in the --help output, so
 151 dnl the help text should refer to "don't compile", etc.
 152 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 153 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 154 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 155 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 156 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 157 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 158 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 159 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 160
 161 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 162 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 163 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 164
 165 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 166 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 167 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 168 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 169
 170 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 171 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 172 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 173 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 174 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 175
 176 ## For the times when you want to build Emacs but don't have
 177 ## a suitable makeinfo, and can live without the manuals.
 178 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 179 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 180
 181 ## This is an option because I do not know if all info/man support
 182 ## compressed files, nor how to test if they do so.
 183 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 184 if test $with_compress_info = yes; then
 185    GZIP_INFO=yes
 186 else
 187    GZIP_INFO=
 188 fi
 189 AC_SUBST(GZIP_INFO)
 190
 191 AC_ARG_WITH([pkg-config-prog],dnl
 192 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 193                   [path to pkg-config for finding GTK and librsvg])])
 194 if test "X${with_pkg_config_prog}" != X; then
 195    if test "${with_pkg_config_prog}" != yes; then
 196       PKG_CONFIG="${with_pkg_config_prog}"
 197    fi
 198 fi
 199
 200 CRT_DIR=
 201 AC_ARG_WITH([crt-dir],dnl
 202 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 203 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 204 CRT_DIR="${with_crt_dir}"
 205
 206 AC_ARG_WITH([gnustep-conf],dnl
 207 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 208 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 209   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 210 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 211      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 212
 213 AC_ARG_ENABLE(ns-self-contained,
 214 [AS_HELP_STRING([--disable-ns-self-contained],
 215                 [disable self contained build under NeXTstep])],
 216    EN_NS_SELF_CONTAINED=$enableval,
 217    EN_NS_SELF_CONTAINED=yes)
 218
 219 AC_ARG_ENABLE(asserts,
 220 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 221       USE_XASSERTS=$enableval,
 222       USE_XASSERTS=no)
 223
 224 AC_ARG_ENABLE(maintainer-mode,
 225 [AS_HELP_STRING([--enable-maintainer-mode],
 226                 [enable make rules and dependencies not useful (and sometimes
 227                  confusing) to the casual installer])],
 228       USE_MAINTAINER_MODE=$enableval,
 229       USE_MAINTAINER_MODE=no)
 230 if test $USE_MAINTAINER_MODE = yes; then
 231   MAINT=
 232 else
 233   MAINT=#
 234 fi
 235 AC_SUBST(MAINT)
 236
 237 AC_ARG_ENABLE(locallisppath,
 238 [AS_HELP_STRING([--enable-locallisppath=PATH],
 239                 [directories Emacs should search for lisp files specific
 240                  to this site])],
 241 if test "${enableval}" = "no"; then
 242   locallisppath=
 243 elif test "${enableval}" != "yes"; then
 244   locallisppath=${enableval}
 245 fi)
 246
 247 AC_ARG_ENABLE(checking,
 248 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 249                 [enable expensive run-time checks.  With LIST,
 250                  enable only specific categories of checks.
 251                  Categories are: all,yes,no.
 252                  Flags are: stringbytes, stringoverrun, stringfreelist,
 253                  xmallocoverrun, conslist])],
 254 [ac_checking_flags="${enableval}"],[])
 255 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 256 for check in $ac_checking_flags
 257 do
 258         case $check in
 259         # these set all the flags to specific states
 260         yes)            ac_enable_checking=1 ;;
 261         no)             ac_enable_checking= ;
 262                         ac_gc_check_stringbytes= ;
 263                         ac_gc_check_string_overrun= ;
 264                         ac_gc_check_string_free_list= ;
 265                         ac_xmalloc_overrun= ;
 266                         ac_gc_check_cons_list= ;;
 267         all)            ac_enable_checking=1 ;
 268                         ac_gc_check_stringbytes=1 ;
 269                         ac_gc_check_string_overrun=1 ;
 270                         ac_gc_check_string_free_list=1 ;
 271                         ac_xmalloc_overrun=1 ;
 272                         ac_gc_check_cons_list=1 ;;
 273         # these enable particular checks
 274         stringbytes)    ac_gc_check_stringbytes=1 ;;
 275         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 276         stringfreelist) ac_gc_check_string_free_list=1 ;;
 277         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 278         conslist)       ac_gc_check_cons_list=1 ;;
 279         *)      AC_MSG_ERROR(unknown check category $check) ;;
 280         esac
 281 done
 282 IFS="$ac_save_IFS"
 283
 284 if test x$ac_enable_checking != x ; then
 285   AC_DEFINE(ENABLE_CHECKING, 1,
 286 [Enable expensive run-time checking of data types?])
 287 fi
 288 if test x$ac_gc_check_stringbytes != x ; then
 289   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 290 [Define this temporarily to hunt a bug.  If defined, the size of
 291    strings is redundantly recorded in sdata structures so that it can
 292    be compared to the sizes recorded in Lisp strings.])
 293 fi
 294 if test x$ac_gc_check_stringoverrun != x ; then
 295   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 296 [Define this to check for short string overrun.])
 297 fi
 298 if test x$ac_gc_check_string_free_list != x ; then
 299   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 300 [Define this to check the string free list.])
 301 fi
 302 if test x$ac_xmalloc_overrun != x ; then
 303   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 304 [Define this to check for malloc buffer overrun.])
 305 fi
 306 if test x$ac_gc_check_cons_list != x ; then
 307   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 308 [Define this to check for errors in cons list.])
 309 fi
 310
 311 AC_ARG_ENABLE(use-lisp-union-type,
 312 [AS_HELP_STRING([--enable-use-lisp-union-type],
 313                 [use a union for the Lisp_Object data type.
 314                 This is only useful for development for catching certain types of bugs.])],
 315 if test "${enableval}" != "no"; then
 316    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 317    [Define this to use a lisp union for the Lisp_Object data type.])
 318 fi)
 319
 320
 321 AC_ARG_ENABLE(profiling,
 322 [AS_HELP_STRING([--enable-profiling],
 323                 [build emacs with profiling support.
 324                  This might not work on all platforms])],
 325 [ac_enable_profiling="${enableval}"],[])
 326 if test x$ac_enable_profiling != x ; then
 327    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 328 else
 329    PROFILING_CFLAGS=
 330 fi
 331 AC_SUBST(PROFILING_CFLAGS)
 332
 333 AC_ARG_ENABLE(autodepend,
 334 [AS_HELP_STRING([--enable-autodepend],
 335                 [automatically generate dependencies to .h-files.
 336                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 337                  found])],
 338 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 339
 340 #### Make srcdir absolute, if it isn't already.  It's important to
 341 #### avoid running the path through pwd unnecessarily, since pwd can
 342 #### give you automounter prefixes, which can go away.  We do all this
 343 #### so Emacs can find its files when run uninstalled.
 344 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 345 unset CDPATH
 346 case "${srcdir}" in
 347   /* ) ;;
 348   . )
 349     ## We may be able to use the $PWD environment variable to make this
 350     ## absolute.  But sometimes PWD is inaccurate.
 351     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 352     ## but that tested only for a well-formed and valid PWD,
 353     ## it did not object when PWD was well-formed and valid but just wrong.
 354     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 355     then
 356       srcdir="$PWD"
 357     else
 358       srcdir="`(cd ${srcdir}; pwd)`"
 359     fi
 360   ;;
 361   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 362 esac
 363
 364 #### Check if the source directory already has a configured system in it.
 365 if test `pwd` != `(cd ${srcdir} && pwd)` \
 366    && test -f "${srcdir}/src/config.h" ; then
 367   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 368    as a build directory right now; it has been configured in its own
 369    right.  To configure in another directory as well, you MUST
 370    use GNU make.  If you do not have GNU make, then you must
 371    now do `make distclean' in ${srcdir},
 372    and then run $0 again.]])
 373 fi
 374
 375 #### Given the configuration name, set machfile and opsysfile to the
 376 #### names of the m/*.h and s/*.h files we should use.
 377
 378 ### Canonicalize the configuration name.
 379
 380 AC_CANONICAL_HOST
 381 canonical=$host
 382 configuration=${host_alias-${build_alias-$host}}
 383
 384 dnl This used to use changequote, but, apart from `changequote is evil'
 385 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 386 dnl the great gob of text.  Thus it's not processed for possible expansion.
 387 dnl Just make sure the brackets remain balanced.
 388 dnl
 389 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 390 dnl indicated by comments.
 391 dnl quotation begins
 392 [
 393
 394 ### If you add support for a new configuration, add code to this
 395 ### switch statement to recognize your configuration name and select
 396 ### the appropriate operating system and machine description files.
 397
 398 ### You would hope that you could choose an m/*.h file pretty much
 399 ### based on the machine portion of the configuration name, and an s/*.h
 400 ### file based on the operating system portion.  However, it turns out
 401 ### that each m/*.h file is pretty manufacturer-specific - for
 402 ### example mips.h is MIPS
 403 ### So we basically have to have a special case for each
 404 ### configuration name.
 405 ###
 406 ### As far as handling version numbers on operating systems is
 407 ### concerned, make sure things will fail in a fixable way.  If
 408 ### /etc/MACHINES doesn't say anything about version numbers, be
 409 ### prepared to handle anything reasonably.  If version numbers
 410 ### matter, be sure /etc/MACHINES says something about it.
 411
 412 machine='' opsys='' unported=no
 413 case "${canonical}" in
 414
 415   ## FreeBSD ports
 416   *-*-freebsd* )
 417     opsys=freebsd
 418     case "${canonical}" in
 419       alpha*)           machine=alpha ;;
 420       amd64-*|x86_64-*) machine=amdx86-64 ;;
 421       arm*)             machine=arm ;;
 422       ia64-*)           machine=ia64 ;;
 423       i[3456]86-*)      machine=intel386 ;;
 424       powerpc-*)        machine=macppc ;;
 425       sparc-*)          machine=sparc ;;
 426       sparc64-*)        machine=sparc ;;
 427     esac
 428   ;;
 429
 430   ## FreeBSD kernel + glibc based userland
 431   *-*-kfreebsd*gnu* )
 432     opsys=gnu-kfreebsd
 433     case "${canonical}" in
 434       alpha*)           machine=alpha ;;
 435       amd64-*|x86_64-*) machine=amdx86-64 ;;
 436       ia64-*)           machine=ia64 ;;
 437       i[3456]86-*)      machine=intel386 ;;
 438       powerpc-*)        machine=macppc ;;
 439       sparc-*)          machine=sparc ;;
 440       sparc64-*)        machine=sparc ;;
 441     esac
 442   ;;
 443
 444   ## NetBSD ports
 445   *-*-netbsd* )
 446     opsys=netbsd
 447     case "${canonical}" in
 448       alpha*)      machine=alpha ;;
 449       x86_64-*)    machine=amdx86-64 ;;
 450       arm-*)       machine=arm ;;
 451       hppa-*)      machine=hp800 ;;
 452       i[3456]86-*) machine=intel386 ;;
 453       m68k-*)      machine=m68k ;;
 454       powerpc-*)   machine=macppc ;;
 455       mips-*)      machine=mips ;;
 456       mipse[bl]-*) machine=mips ;;
 457       sparc*-)     machine=sparc ;;
 458       vax-*)       machine=vax ;;
 459     esac
 460   ;;
 461
 462   ## OpenBSD ports
 463   *-*-openbsd* )
 464     opsys=openbsd
 465     case "${canonical}" in
 466       alpha*)    machine=alpha ;;
 467       x86_64-*)  machine=amdx86-64 ;;
 468       arm-*)     machine=arm ;;
 469       hppa-*)    machine=hp800 ;;
 470       i386-*)    machine=intel386 ;;
 471       powerpc-*) machine=macppc ;;
 472       sparc*)    machine=sparc ;;
 473       vax-*)     machine=vax ;;
 474     esac
 475   ;;
 476
 477   alpha*-*-linux-gnu* )
 478     machine=alpha opsys=gnu-linux
 479   ;;
 480
 481   arm*-*-linux-gnu* )
 482     machine=arm opsys=gnu-linux
 483   ;;
 484
 485   ## Apple Darwin / Mac OS X
 486   *-apple-darwin* )
 487     case "${canonical}" in
 488       i[3456]86-* )  machine=intel386 ;;
 489       powerpc-* )    machine=macppc ;;
 490       x86_64-* )     machine=amdx86-64 ;;
 491       * )            unported=yes ;;
 492     esac
 493     opsys=darwin
 494     # Define CPP as follows to make autoconf work correctly.
 495     CPP="${CC-cc} -E -no-cpp-precomp"
 496     # Use fink packages if available.
 497     if test -d /sw/include && test -d /sw/lib; then
 498       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 499       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 500       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 501     fi
 502   ;;
 503
 504   ## HP 9000 series 700 and 800, running HP/UX
 505   hppa*-hp-hpux10.2* )
 506     machine=hp800 opsys=hpux10-20
 507   ;;
 508   hppa*-hp-hpux1[1-9]* )
 509     machine=hp800 opsys=hpux11
 510     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 511   ;;
 512
 513   hppa*-*-linux-gnu* )
 514     machine=hp800 opsys=gnu-linux
 515   ;;
 516
 517   ## IBM machines
 518   s390-*-linux-gnu* )
 519     machine=ibms390 opsys=gnu-linux
 520   ;;
 521   s390x-*-linux-gnu* )
 522     machine=ibms390x opsys=gnu-linux
 523   ;;
 524   rs6000-ibm-aix4.[23]* )
 525     machine=ibmrs6000 opsys=aix4-2
 526   ;;
 527   powerpc-ibm-aix4.[23]*  )
 528     machine=ibmrs6000 opsys=aix4-2
 529   ;;
 530   rs6000-ibm-aix[56]* )
 531     machine=ibmrs6000 opsys=aix4-2
 532   ;;
 533   powerpc-ibm-aix[56]*  )
 534     machine=ibmrs6000 opsys=aix4-2
 535   ;;
 536
 537   ## Macintosh PowerPC
 538   powerpc*-*-linux-gnu* )
 539     machine=macppc opsys=gnu-linux
 540   ;;
 541
 542   ## Silicon Graphics machines
 543   ## Iris 4D
 544   mips-sgi-irix6.5 )
 545     machine=iris4d opsys=irix6-5
 546     # Without defining _LANGUAGE_C, things get masked out in the headers
 547     # so that, for instance, grepping for `free' in stdlib.h fails and
 548     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 549     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 550     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 551   ;;
 552
 553   ## Suns
 554   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 555     machine=sparc opsys=gnu-linux
 556   ;;
 557
 558   *-sun-solaris* \
 559     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 560     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 561     case "${canonical}" in
 562       i[3456]86-*-* )     machine=intel386 ;;
 563       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 564       sparc* )          machine=sparc ;;
 565       * )               unported=yes ;;
 566     esac
 567     case "${canonical}" in
 568       *-sunos5.6* | *-solaris2.6* )
 569                 opsys=sol2-6
 570                 NON_GNU_CPP=/usr/ccs/lib/cpp
 571                 RANLIB="ar -ts"
 572                 ;;
 573       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 574                 opsys=sol2-6
 575                 emacs_check_sunpro_c=yes
 576                 NON_GNU_CPP=/usr/ccs/lib/cpp
 577                 ;;
 578       *-sunos5* | *-solaris* )
 579                 opsys=sol2-10
 580                 emacs_check_sunpro_c=yes
 581                 NON_GNU_CPP=/usr/ccs/lib/cpp
 582                 ;;
 583     esac
 584     ## Watch out for a compiler that we know will not work.
 585     case "${canonical}" in
 586      *-solaris* | *-sunos5* )
 587                 if [ "x$CC" = x/usr/ucb/cc ]; then
 588                   ## /usr/ucb/cc doesn't work;
 589                   ## we should find some other compiler that does work.
 590                   unset CC
 591                 fi
 592                 ;;
 593       *) ;;
 594     esac
 595   ;;
 596
 597   ## IA-64
 598   ia64*-*-linux* )
 599     machine=ia64 opsys=gnu-linux
 600   ;;
 601
 602   ## Intel 386 machines where we don't care about the manufacturer.
 603   i[3456]86-*-* )
 604     machine=intel386
 605     case "${canonical}" in
 606       *-cygwin )                opsys=cygwin ;;
 607       *-darwin* )               opsys=darwin
 608                                 CPP="${CC-cc} -E -no-cpp-precomp"
 609                                 ;;
 610       *-linux-gnu* )            opsys=gnu-linux ;;
 611       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 612       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 613       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 614       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 615     esac
 616   ;;
 617
 618   ## m68k Linux-based GNU system
 619   m68k-*-linux-gnu* )
 620     machine=m68k opsys=gnu-linux
 621   ;;
 622
 623   ## Mips Linux-based GNU system
 624   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 625     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 626     machine=mips opsys=gnu-linux
 627   ;;
 628
 629   ## AMD x86-64 Linux-based GNU system
 630   x86_64-*-linux-gnu* )
 631     machine=amdx86-64 opsys=gnu-linux
 632   ;;
 633
 634   ## Tensilica Xtensa Linux-based GNU system
 635   xtensa*-*-linux-gnu* )
 636     machine=xtensa opsys=gnu-linux
 637     ;;
 638
 639   ## SuperH Linux-based GNU system
 640   sh[34]*-*-linux-gnu* )
 641     machine=sh3 opsys=gnu-linux
 642   ;;
 643
 644   * )
 645     unported=yes
 646   ;;
 647 esac
 648
 649 ### If the code above didn't choose an operating system, just choose
 650 ### an operating system based on the configuration name.  You really
 651 ### only want to use this when you have no idea what the right
 652 ### operating system is; if you know what operating systems a machine
 653 ### runs, it's cleaner to make it explicit in the case statement
 654 ### above.
 655 if test x"${opsys}" = x; then
 656   case "${canonical}" in
 657     *-gnu* )                            opsys=gnu ;;
 658     * )
 659       unported=yes
 660     ;;
 661   esac
 662 fi
 663
 664 ]
 665 dnl quotation ends
 666
 667 if test $unported = yes; then
 668   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 669 Check `etc/MACHINES' for recognized configuration names.])
 670 fi
 671
 672 machfile="m/${machine}.h"
 673 opsysfile="s/${opsys}.h"
 674
 675
 676 #### Choose a compiler.
 677 test -n "$CC" && cc_specified=yes
 678
 679 # Save the value of CFLAGS that the user specified.
 680 SPECIFIED_CFLAGS="$CFLAGS"
 681
 682 dnl Sets GCC=yes if using gcc.
 683 AC_PROG_CC
 684
 685 # On Suns, sometimes $CPP names a directory.
 686 if test -n "$CPP" && test -d "$CPP"; then
 687   CPP=
 688 fi
 689
 690 ## If not using gcc, and on Solaris, and no CPP specified, see if
 691 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 692 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 693  test x"$CPP" = x; then
 694   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 695   AC_CACHE_VAL(emacs_cv_sunpro_c,
 696   [AC_TRY_LINK([],
 697 [#ifndef __SUNPRO_C
 698 fail;
 699 #endif
 700 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 701   AC_MSG_RESULT($emacs_cv_sunpro_c)
 702
 703   if test x"$emacs_cv_sunpro_c" = xyes; then
 704     NON_GNU_CPP="$CC -E -Xs"
 705   fi
 706 fi
 707
 708 #### Some systems specify a CPP to use unless we are using GCC.
 709 #### Now that we know whether we are using GCC, we can decide whether
 710 #### to use that one.
 711 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 712 then
 713   CPP="$NON_GNU_CPP"
 714 fi
 715
 716 #### Some systems specify a CC to use unless we are using GCC.
 717 #### Now that we know whether we are using GCC, we can decide whether
 718 #### to use that one.
 719 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 720   test x$cc_specified != xyes
 721 then
 722   CC="$NON_GNU_CC"
 723 fi
 724
 725 if test x$GCC = xyes; then
 726   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 727 else
 728   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 729 fi
 730
 731 dnl checks for Unix variants
 732 AC_USE_SYSTEM_EXTENSIONS
 733
 734 ### Use -Wno-pointer-sign if the compiler supports it
 735 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 736 SAVE_CFLAGS="$CFLAGS"
 737 CFLAGS="$CFLAGS -Wno-pointer-sign"
 738 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 739 if test $has_option = yes; then
 740    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 741 fi
 742 AC_MSG_RESULT($has_option)
 743 CFLAGS="$SAVE_CFLAGS"
 744 unset has_option
 745 unset SAVE_CFLAGS
 746
 747 ### Use -Wdeclaration-after-statement if the compiler supports it
 748 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 749 SAVE_CFLAGS="$CFLAGS"
 750 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 751 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 752 if test $has_option = yes; then
 753    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 754 fi
 755 AC_MSG_RESULT($has_option)
 756 CFLAGS="$SAVE_CFLAGS"
 757 unset has_option
 758 unset SAVE_CFLAGS
 759
 760 ### Use -Wold-style-definition if the compiler supports it
 761 # This can be removed when conversion to standard C is finished.
 762 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 763 SAVE_CFLAGS="$CFLAGS"
 764 CFLAGS="$CFLAGS -Wold-style-definition"
 765 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 766 if test $has_option = yes; then
 767    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 768 fi
 769 AC_MSG_RESULT($has_option)
 770 CFLAGS="$SAVE_CFLAGS"
 771 unset has_option
 772 unset SAVE_CFLAGS
 773
 774 ### Use -Wimplicit-function-declaration if the compiler supports it
 775 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 776 SAVE_CFLAGS="$CFLAGS"
 777 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 778 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 779 if test $has_option = yes; then
 780    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 781 fi
 782 AC_MSG_RESULT($has_option)
 783 CFLAGS="$SAVE_CFLAGS"
 784 unset has_option
 785 unset SAVE_CFLAGS
 786
 787 AC_SUBST(C_WARNINGS_SWITCH)
 788
 789
 790 #### Some other nice autoconf tests.
 791
 792 dnl checks for programs
 793 AC_PROG_CPP
 794 AC_PROG_INSTALL
 795 if test "x$RANLIB" = x; then
 796   AC_PROG_RANLIB
 797 fi
 798
 799 ## Although we're running on an amd64 kernel, we're actually compiling for
 800 ## the x86 architecture.  The user should probably have provided an
 801 ## explicit --build to `configure', but if everything else than the kernel
 802 ## is running in i386 mode, we can help them out.
 803 if test "$machine" = "amdx86-64"; then
 804   AC_CHECK_DECL([i386])
 805   if test "$ac_cv_have_decl_i386" = "yes"; then
 806     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 807     machine=intel386
 808     machfile="m/${machine}.h"
 809   fi
 810 fi
 811
 812 AC_PATH_PROG(INSTALL_INFO, install-info)
 813 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 814 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 815 dnl Don't use GZIP, which is used by gzip for additional parameters.
 816 AC_PATH_PROG(GZIP_PROG, gzip)
 817
 818
 819 ## Need makeinfo >= 4.6 (?) to build the manuals.
 820 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 821 dnl By this stage, configure has already checked for egrep and set EGREP,
 822 dnl or exited with an error if no egrep was found.
 823 if test "$MAKEINFO" != "no" && \
 824   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 825    MAKEINFO=no
 826 fi
 827
 828 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 829 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 830 ## therefore in the category of "special tools" not normally required, which
 831 ## configure does not have to check for (eg autoconf itself).
 832 ## In a Bazaar checkout on the other hand, the manuals are not included.
 833 ## So makeinfo is a requirement to build from Bazaar, and configure
 834 ## should test for it as it does for any other build requirement.
 835 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 836 ## with pre-built manuals, from a Bazaar checkout.
 837 if test "$MAKEINFO" = "no"; then
 838   if test "x${with_makeinfo}" = "xno"; then
 839     MAKEINFO=off
 840   elif test ! -e $srcdir/info/emacs; then
 841     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 842 source tree does not seem to have pre-built manuals in the `info' directory.
 843 Either install a suitable version of makeinfo, or re-run configure
 844 with the `--without-makeinfo' option to build without the manuals.] )
 845   fi
 846 fi
 847
 848 dnl Add our options to ac_link now, after it is set up.
 849
 850 if test x$GCC = xyes; then
 851   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 852     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 853 else
 854   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 855     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 856 fi
 857
 858 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 859 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 860 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 861 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 862 dnl if not built to support GNU ld.
 863
 864 late_LDFLAGS=$LDFLAGS
 865 if test x$GCC = xyes; then
 866   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 867 else
 868   LDFLAGS="$LDFLAGS -znocombreloc"
 869 fi
 870
 871 AC_MSG_CHECKING([for -znocombreloc])
 872 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 873   [AC_MSG_RESULT(yes)],
 874   LDFLAGS=$late_LDFLAGS
 875   [AC_MSG_RESULT(no)])
 876
 877
 878 # The value of CPP is a quoted variable reference, so we need to do this
 879 # to get its actual value...
 880 CPP=`eval "echo $CPP"`
 881
 882
 883 dnl Not used by any currently supported platform.
 884 dnl The function dump-emacs will not be defined and temacs will do
 885 dnl (load "loadup") automatically unless told otherwise.
 886 CANNOT_DUMP=no
 887 case "$opsys" in
 888   your-opsys-here)
 889    CANNOT_DUMP=yes
 890    AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 891   ;;
 892 esac
 893 AC_SUBST(CANNOT_DUMP)
 894
 895
 896 UNEXEC_OBJ=unexelf.o
 897 case "$opsys" in
 898   # MSDOS uses unexcoff.o
 899   # MSWindows uses unexw32.o
 900   aix4-2)
 901    UNEXEC_OBJ=unexaix.o
 902    ;;
 903   cygwin)
 904    UNEXEC_OBJ=unexcw.o
 905    ;;
 906   darwin)
 907    UNEXEC_OBJ=unexmacosx.o
 908    ;;
 909   hpux10-20 | hpux11)
 910    UNEXEC_OBJ=unexhp9k800.o
 911    ;;
 912   sol2-10)
 913    # Use the Solaris dldump() function, called from unexsol.c, to dump
 914    # emacs, instead of the generic ELF dump code found in unexelf.c.
 915    # The resulting binary has a complete symbol table, and is better
 916    # for debugging and other observability tools (debuggers, pstack, etc).
 917    #
 918    # If you encounter a problem using dldump(), please consider sending
 919    # a message to the OpenSolaris tools-linking mailing list:
 920    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 921    #
 922    # It is likely that dldump() works with older Solaris too, but this has
 923    # not been tested, so for now this change is for Solaris 10 or newer.
 924    UNEXEC_OBJ=unexsol.o
 925    ;;
 926 esac
 927
 928 LD_SWITCH_SYSTEM=
 929 case "$opsys" in
 930   freebsd)
 931    ## Let `ld' find image libs and similar things in /usr/local/lib.
 932    ## The system compiler, GCC, has apparently been modified to not
 933    ## look there, contrary to what a stock GCC would do.
 934    LD_SWITCH_SYSTEM=-L/usr/local/lib
 935    ;;
 936
 937   gnu-linux)
 938    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 939    test "$machine" = "mips" && LD_SWITCH_SYSTEM="-G 0"
 940    ;;
 941
 942   netbsd)
 943    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 944    ;;
 945
 946   openbsd)
 947    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 948    ## otherwise Emacs dumps core on elf systems.
 949    LD_SWITCH_SYSTEM="-Z"
 950    ;;
 951 esac
 952 AC_SUBST(LD_SWITCH_SYSTEM)
 953
 954 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 955
 956 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 957 ## which has not been defined yet.  When this was handled with cpp,
 958 ## it was expanded to null when configure sourced the s/*.h file.
 959 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 960 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 961 ## (or somesuch), but because it is supposed to go at the _front_
 962 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 963 ## Compare with the gnu-linux case below, which added to the end
 964 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 965 ## LD_SWITCH_SYSTEM_TEMACS.
 966 case "$opsys" in
 967   netbsd|openbsd)
 968    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 969    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 970 esac
 971
 972
 973 C_SWITCH_MACHINE=
 974 if test "$machine" = "alpha"; then
 975   AC_CHECK_DECL([__ELF__])
 976   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 977     ## With ELF, make sure that all common symbols get allocated to in the
 978     ## data section.  Otherwise, the dump of temacs may miss variables in
 979     ## the shared library that have been initialized.  For example, with
 980     ## GNU libc, __malloc_initialized would normally be resolved to the
 981     ## shared library's .bss section, which is fatal.
 982     if test "x$GCC" = "xyes"; then
 983       C_SWITCH_MACHINE="-fno-common"
 984     else
 985       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 986     fi
 987   else
 988     UNEXEC_OBJ=unexalpha.o
 989   fi
 990 fi
 991 AC_SUBST(C_SWITCH_MACHINE)
 992
 993 AC_SUBST(UNEXEC_OBJ)
 994
 995 C_SWITCH_SYSTEM=
 996 ## Some programs in src produce warnings saying certain subprograms
 997 ## are too complex and need a MAXMEM value greater than 2000 for
 998 ## additional optimization.  --nils@exp-math.uni-essen.de
 999 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1000   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1001 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1002 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1003 AC_SUBST(C_SWITCH_SYSTEM)
1004
1005
1006 LIBS_SYSTEM=
1007 case "$opsys" in
1008   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1009   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1010
1011   freebsd) LIBS_SYSTEM="-lutil" ;;
1012
1013   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1014
1015   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
1016
1017   ## Motif needs -lgen.
1018   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1019 esac
1020 AC_SUBST(LIBS_SYSTEM)
1021
1022
1023 ### Make sure subsequent tests use flags consistent with the build flags.
1024
1025 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1026   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1027 else
1028   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1029 fi
1030
1031 dnl For AC_FUNC_GETLOADAVG, at least:
1032 AC_CONFIG_LIBOBJ_DIR(src)
1033
1034 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1035 AC_SYS_LARGEFILE
1036
1037
1038 ## If user specified a crt-dir, use that unconditionally.
1039 if test "X$CRT_DIR" = "X"; then
1040
1041   case "$canonical" in
1042     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1043     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1044     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1045     ## For anything else (eg /usr/lib32), it is up the user to specify
1046     ## the location (bug#5655).
1047     ## Test for crtn.o, not just the directory, because sometimes the
1048     ## directory exists but does not have the relevant files (bug#1287).
1049     ## FIXME better to test for binary compatibility somehow.
1050     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1051     ;;
1052
1053     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1054   esac
1055
1056   case "$opsys" in
1057     hpux10-20) CRT_DIR=/lib ;;
1058   esac
1059
1060   ## Default is /usr/lib.
1061   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1062
1063 else
1064
1065   ## Some platforms don't use any of these files, so it is not
1066   ## appropriate to put this test outside the if block.
1067   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1068     AC_MSG_ERROR([crt*.o not found in specified location.])
1069
1070 fi
1071
1072 AC_SUBST(CRT_DIR)
1073
1074 LIB_MATH=-lm
1075 LIB_STANDARD=
1076 START_FILES=
1077
1078 case $opsys in
1079   cygwin )
1080     LIB_MATH=
1081     START_FILES='pre-crt0.o'
1082     ;;
1083   darwin )
1084     ## Adding -lm confuses the dynamic linker, so omit it.
1085     LIB_MATH=
1086     START_FILES='pre-crt0.o'
1087     ;;
1088   freebsd )
1089     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1090     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1091     ;;
1092   gnu-linux | gnu-kfreebsd )
1093     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1094     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1095     ;;
1096   hpux10-20 | hpux11 )
1097     LIB_STANDARD=-lc
1098     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1099     ;;
1100   netbsd | openbsd )
1101     if test -f $CRT_DIR/crti.o; then
1102         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1103         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1104     else
1105         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1106         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1107     fi
1108     ;;
1109 esac
1110
1111 AC_SUBST(LIB_MATH)
1112 AC_SUBST(START_FILES)
1113
1114 dnl This function definition taken from Gnome 2.0
1115 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1116 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1117 dnl also defines GSTUFF_PKG_ERRORS on error
1118 AC_DEFUN([PKG_CHECK_MODULES], [
1119   succeeded=no
1120
1121   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1122
1123   if test "$PKG_CONFIG" = "no" ; then
1124      ifelse([$4], , [AC_MSG_ERROR([
1125       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1126   else
1127      PKG_CONFIG_MIN_VERSION=0.9.0
1128      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1129         AC_MSG_CHECKING(for $2)
1130
1131         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1132             AC_MSG_RESULT(yes)
1133             succeeded=yes
1134
1135             AC_MSG_CHECKING($1_CFLAGS)
1136             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1137             AC_MSG_RESULT($$1_CFLAGS)
1138
1139             AC_MSG_CHECKING($1_LIBS)
1140             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1141             AC_MSG_RESULT($$1_LIBS)
1142         else
1143             AC_MSG_RESULT(no)
1144             $1_CFLAGS=""
1145             $1_LIBS=""
1146             ## If we have a custom action on failure, don't print errors, but
1147             ## do set a variable so people can do so.
1148             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1149             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1150         fi
1151
1152         AC_SUBST($1_CFLAGS)
1153         AC_SUBST($1_LIBS)
1154      else
1155         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1156         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1157      fi
1158   fi
1159
1160   if test $succeeded = yes; then
1161      ifelse([$3], , :, [$3])
1162   else
1163      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1164   fi
1165 ])
1166
1167
1168 if test "${with_sound}" != "no"; then
1169   # Sound support for GNU/Linux and the free BSDs.
1170   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1171     have_sound_header=yes)
1172   # Emulation library used on NetBSD.
1173   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1174   AC_SUBST(LIBSOUND)
1175
1176   ALSA_REQUIRED=1.0.0
1177   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1178   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1179   if test $HAVE_ALSA = yes; then
1180     SAVE_CFLAGS="$CFLAGS"
1181     SAVE_LDFLAGS="$LDFLAGS"
1182     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1183     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1184     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1185                     emacs_alsa_normal=yes,
1186                     emacs_alsa_normal=no)
1187     if test "$emacs_alsa_normal" != yes; then
1188       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1189                      [snd_lib_error_set_handler (0);],
1190                      emacs_alsa_subdir=yes,
1191                      emacs_alsa_subdir=no)
1192       if test "$emacs_alsa_subdir" != yes; then
1193         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1194       fi
1195       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1196     fi
1197
1198     CFLAGS="$SAVE_CFLAGS"
1199     LDFLAGS="$SAVE_LDFLAGS"
1200     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1201     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1202     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1203   fi
1204
1205   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1206   dnl compiles only on the specified platforms.  For others, it
1207   dnl probably doesn't make sense to try.
1208   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1209      case "$opsys" in
1210        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1211        gnu-linux|freebsd|netbsd)
1212          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1213          ;;
1214      esac
1215   fi
1216
1217   AC_SUBST(CFLAGS_SOUND)
1218 fi
1219
1220 dnl checks for header files
1221 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1222   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1223   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1224   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1225   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1226
1227 AC_MSG_CHECKING(if personality LINUX32 can be set)
1228 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1229                emacs_cv_personality_linux32=yes,
1230                emacs_cv_personality_linux32=no)
1231 AC_MSG_RESULT($emacs_cv_personality_linux32)
1232
1233 if test $emacs_cv_personality_linux32 = yes; then
1234   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1235             [Define to 1 if personality LINUX32 can be set.])
1236 fi
1237
1238 dnl On Solaris 8 there's a compilation warning for term.h because
1239 dnl it doesn't define `bool'.
1240 AC_CHECK_HEADERS(term.h, , , -)
1241 AC_HEADER_STDC
1242 AC_HEADER_TIME
1243 AC_CHECK_DECLS([sys_siglist])
1244 if test $ac_cv_have_decl_sys_siglist != yes; then
1245   # For Tru64, at least:
1246   AC_CHECK_DECLS([__sys_siglist])
1247   if test $ac_cv_have_decl___sys_siglist = yes; then
1248     AC_DEFINE(sys_siglist, __sys_siglist,
1249               [Define to any substitute for sys_siglist.])
1250   fi
1251 fi
1252 AC_HEADER_SYS_WAIT
1253
1254 dnl Some systems have utime.h but don't declare the struct anyplace.
1255 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1256 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1257 #include <sys/time.h>
1258 #include <time.h>
1259 #else
1260 #ifdef HAVE_SYS_TIME_H
1261 #include <sys/time.h>
1262 #else
1263 #include <time.h>
1264 #endif
1265 #endif
1266 #ifdef HAVE_UTIME_H
1267 #include <utime.h>
1268 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1269   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1270 if test $emacs_cv_struct_utimbuf = yes; then
1271   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1272 fi
1273
1274 dnl checks for typedefs
1275 AC_TYPE_SIGNAL
1276
1277 dnl Check for speed_t typedef.
1278 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1279   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1280     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1281 if test $emacs_cv_speed_t = yes; then
1282   AC_DEFINE(HAVE_SPEED_T, 1,
1283            [Define to 1 if `speed_t' is declared by <termios.h>.])
1284 fi
1285
1286 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1287 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1288 #include <sys/time.h>
1289 #include <time.h>
1290 #else
1291 #ifdef HAVE_SYS_TIME_H
1292 #include <sys/time.h>
1293 #else
1294 #include <time.h>
1295 #endif
1296 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1297   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1298 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1299 if test $emacs_cv_struct_timeval = yes; then
1300   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1301 fi
1302
1303 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1304 AC_TRY_COMPILE([#include <math.h>],
1305 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1306   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1307 HAVE_EXCEPTION=$emacs_cv_struct_exception
1308 if test $emacs_cv_struct_exception != yes; then
1309   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1310 fi
1311
1312 AC_CHECK_HEADERS(sys/socket.h)
1313 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1314 #if HAVE_SYS_SOCKET_H
1315 #include <sys/socket.h>
1316 #endif])
1317
1318 dnl checks for structure members
1319 AC_STRUCT_TM
1320 AC_STRUCT_TIMEZONE
1321 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1322                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1323                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1324                 [#include <time.h>])
1325 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1326                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1327                   struct ifreq.ifr_addr], , ,
1328                  [AC_INCLUDES_DEFAULT
1329 #if HAVE_SYS_SOCKET_H
1330 #include <sys/socket.h>
1331 #endif
1332 #if HAVE_NET_IF_H
1333 #include <net/if.h>
1334 #endif])
1335
1336 dnl checks for compiler characteristics
1337
1338 dnl Testing __STDC__ to determine prototype support isn't good enough.
1339 dnl DEC C, for instance, doesn't define it with default options, and
1340 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1341 dnl and void *.
1342 AC_C_PROTOTYPES
1343 AC_C_VOLATILE
1344 AC_C_CONST
1345 dnl This isn't useful because we can't turn on use of `inline' unless
1346 dnl the compiler groks `extern inline'.
1347 dnl AC_C_INLINE
1348 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1349   [AC_TRY_COMPILE(, [void * foo;],
1350                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1351 if test $emacs_cv_void_star = yes; then
1352   AC_DEFINE(POINTER_TYPE, void)
1353 else
1354   AC_DEFINE(POINTER_TYPE, char)
1355 fi
1356 AH_TEMPLATE(POINTER_TYPE,
1357             [Define as `void' if your compiler accepts `void *'; otherwise
1358              define as `char'.])dnl
1359
1360 dnl Check for endianess
1361 AC_C_BIGENDIAN
1362
1363 dnl check for Make feature
1364 AC_PROG_MAKE_SET
1365
1366 DEPFLAGS=
1367 MKDEPDIR=":"
1368 deps_frag=deps.mk
1369 dnl check for GNU Make if we have GCC and autodepend is on.
1370 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1371    AC_MSG_CHECKING([whether we are using GNU Make])
1372    HAVE_GNU_MAKE=no
1373    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1374    if test "x$testval" != x; then
1375       HAVE_GNU_MAKE=yes
1376    else
1377       ac_enable_autodepend=no
1378    fi
1379    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1380    if test $HAVE_GNU_MAKE = yes; then
1381       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1382       SAVE_CFLAGS="$CFLAGS"
1383       CFLAGS="$CFLAGS -MMD -MF deps.d"
1384       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1385       CFLAGS="$SAVE_CFLAGS"
1386       test -f deps.d || ac_enable_autodepend=no
1387       rm -rf deps.d
1388       AC_MSG_RESULT([$ac_enable_autodepend])
1389    fi
1390    if test $ac_enable_autodepend = yes; then
1391       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1392       ## In parallel builds, another make might create depdir between
1393       ## the first test and mkdir, so stick another test on the end.
1394       ## Or use mkinstalldirs?  mkdir -p is not portable.
1395       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1396       deps_frag=autodeps.mk
1397    fi
1398 fi
1399 deps_frag=$srcdir/src/$deps_frag
1400 AC_SUBST(MKDEPDIR)
1401 AC_SUBST(DEPFLAGS)
1402 AC_SUBST_FILE(deps_frag)
1403
1404
1405 dnl checks for operating system services
1406 AC_SYS_LONG_FILE_NAMES
1407
1408 #### Choose a window system.
1409
1410 AC_PATH_X
1411 if test "$no_x" = yes; then
1412   window_system=none
1413 else
1414   window_system=x11
1415 fi
1416
1417 ## Workaround for bug in autoconf <= 2.62.
1418 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1419 ## No need to do anything special for these standard directories.
1420 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1421
1422    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1423
1424 fi
1425
1426 LD_SWITCH_X_SITE_AUX=
1427 LD_SWITCH_X_SITE_AUX_RPATH=
1428 if test "${x_libraries}" != NONE; then
1429   if test -n "${x_libraries}"; then
1430     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1431     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1432     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1433   fi
1434   x_default_search_path=""
1435   x_search_path=${x_libraries}
1436   if test -z "${x_search_path}"; then
1437     x_search_path=/usr/lib
1438   fi
1439   for x_library in `echo ${x_search_path}: | \
1440                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1441     x_search_path="\
1442 ${x_library}/X11/%L/%T/%N%C%S:\
1443 ${x_library}/X11/%l/%T/%N%C%S:\
1444 ${x_library}/X11/%T/%N%C%S:\
1445 ${x_library}/X11/%L/%T/%N%S:\
1446 ${x_library}/X11/%l/%T/%N%S:\
1447 ${x_library}/X11/%T/%N%S"
1448     if test x"${x_default_search_path}" = x; then
1449       x_default_search_path=${x_search_path}
1450     else
1451       x_default_search_path="${x_search_path}:${x_default_search_path}"
1452     fi
1453   done
1454 fi
1455 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1456 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1457
1458 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1459   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1460 fi
1461
1462 if test x"${x_includes}" = x; then
1463   bitmapdir=/usr/include/X11/bitmaps
1464 else
1465   # accumulate include directories that have X11 bitmap subdirectories
1466   bmd_acc="dummyval"
1467   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1468     if test -d "${bmd}/X11/bitmaps"; then
1469       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1470     fi
1471     if test -d "${bmd}/bitmaps"; then
1472       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1473     fi
1474   done
1475   if test ${bmd_acc} != "dummyval"; then
1476     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1477   fi
1478 fi
1479
1480 HAVE_NS=no
1481 NS_IMPL_COCOA=no
1482 NS_IMPL_GNUSTEP=no
1483 tmp_CPPFLAGS="$CPPFLAGS"
1484 tmp_CFLAGS="$CFLAGS"
1485 CPPFLAGS="$CPPFLAGS -x objective-c"
1486 CFLAGS="$CFLAGS -x objective-c"
1487 TEMACS_LDFLAGS2="\${LDFLAGS}"
1488 dnl I don't think it's especially important, but src/Makefile.in
1489 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1490 dnl trailing "/" to it, so now we do it here.
1491 if test "${with_ns}" != no; then
1492   if test "${opsys}" = darwin; then
1493      NS_IMPL_COCOA=yes
1494      ns_appdir=`pwd`/nextstep/Emacs.app
1495      ns_appbindir=${ns_appdir}/Contents/MacOS/
1496      ns_appresdir=${ns_appdir}/Contents/Resources
1497      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1498   elif test -f $GNUSTEP_CONFIG_FILE; then
1499      NS_IMPL_GNUSTEP=yes
1500      ns_appdir=`pwd`/nextstep/Emacs.app
1501      ns_appbindir=${ns_appdir}
1502      ns_appresdir=${ns_appdir}/Resources
1503      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1504      dnl FIXME sourcing this several times in subshells seems inefficient.
1505      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1506      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1507      dnl I seemed to need these as well with GNUstep-startup 0.25.
1508      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1509      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1510      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1511        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1512      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1513        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1514      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1515      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1516      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1517      LIB_STANDARD=
1518      START_FILES=
1519      TEMACS_LDFLAGS2=
1520   fi
1521   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1522                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1523   files are missing or cannot be compiled.])])
1524   NS_HAVE_NSINTEGER=yes
1525   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1526                                      [NSInteger i;])],
1527                     ns_have_nsinteger=yes,
1528                     ns_have_nsinteger=no)
1529   if test $ns_have_nsinteger = no; then
1530     NS_HAVE_NSINTEGER=no
1531   fi
1532 fi
1533 AC_SUBST(TEMACS_LDFLAGS2)
1534
1535 ns_frag=/dev/null
1536 NS_OBJ=
1537 NS_SUPPORT=
1538 if test "${HAVE_NS}" = yes; then
1539   window_system=nextstep
1540   with_xft=no
1541   # set up packaging dirs
1542   exec_prefix=${ns_appbindir}
1543   libexecdir=${ns_appbindir}/libexec
1544   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1545      prefix=${ns_appresdir}
1546   fi
1547   ns_frag=$srcdir/src/ns.mk
1548   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1549   NS_SUPPORT="\${lispsource}/emacs-lisp/easymenu.elc \${lispsource}/term/ns-win.elc"
1550 fi
1551 CFLAGS="$tmp_CFLAGS"
1552 CPPFLAGS="$tmp_CPPFLAGS"
1553 AC_SUBST(NS_OBJ)
1554 AC_SUBST(NS_SUPPORT)
1555 AC_SUBST(LIB_STANDARD)
1556 AC_SUBST_FILE(ns_frag)
1557
1558 case "${window_system}" in
1559   x11 )
1560     HAVE_X_WINDOWS=yes
1561     HAVE_X11=yes
1562     case "${with_x_toolkit}" in
1563       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1564       motif ) USE_X_TOOLKIT=MOTIF ;;
1565       gtk ) with_gtk=yes
1566 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1567 dnl USE_X_TOOLKIT is set.
1568             USE_X_TOOLKIT=none ;;
1569       gtk3 ) with_gtk3=yes
1570              USE_X_TOOLKIT=none ;;
1571       no ) USE_X_TOOLKIT=none ;;
1572 dnl If user did not say whether to use a toolkit, make this decision later:
1573 dnl use the toolkit if we have gtk, or X11R5 or newer.
1574       * ) USE_X_TOOLKIT=maybe ;;
1575     esac
1576   ;;
1577   nextstep | none )
1578     HAVE_X_WINDOWS=no
1579     HAVE_X11=no
1580     USE_X_TOOLKIT=none
1581   ;;
1582 esac
1583
1584 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1585    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1586    if test "$HAVE_XSERVER" = true ||
1587       test -n "$DISPLAY" ||
1588       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1589         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1590 were found.  You should install the relevant development files for X
1591 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1592 sure you have development files for image handling, i.e.
1593 tiff, gif, jpeg, png and xpm.
1594 If you are sure you want Emacs compiled without X window support, pass
1595   --without-x
1596 to configure.])
1597    fi
1598 fi
1599
1600 ### If we're using X11, we should use the X menu package.
1601 HAVE_MENUS=no
1602 case ${HAVE_X11} in
1603   yes ) HAVE_MENUS=yes ;;
1604 esac
1605
1606 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1607 # Assume not, until told otherwise.
1608 GNU_MALLOC=yes
1609 doug_lea_malloc=yes
1610 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1611 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1612 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1613                emacs_cv_var___after_morecore_hook,
1614 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1615   emacs_cv_var___after_morecore_hook=yes,
1616   emacs_cv_var___after_morecore_hook=no)])
1617 if test $emacs_cv_var___after_morecore_hook = no; then
1618   doug_lea_malloc=no
1619 fi
1620
1621
1622 dnl See comments in aix4-2.h about maybe using system malloc there.
1623 system_malloc=no
1624 case "$opsys" in
1625   ## darwin ld insists on the use of malloc routines in the System framework.
1626   darwin|sol2-10) system_malloc=yes ;;
1627 esac
1628
1629 if test "${system_malloc}" = "yes"; then
1630   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1631   GNU_MALLOC=no
1632   GNU_MALLOC_reason="
1633     (The GNU allocators don't work with this system configuration.)"
1634   GMALLOC_OBJ=
1635   VMLIMIT_OBJ=
1636 else
1637   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1638   VMLIMIT_OBJ=vm-limit.o
1639 fi
1640 AC_SUBST(GMALLOC_OBJ)
1641 AC_SUBST(VMLIMIT_OBJ)
1642
1643 if test "$doug_lea_malloc" = "yes" ; then
1644   if test "$GNU_MALLOC" = yes ; then
1645     GNU_MALLOC_reason="
1646       (Using Doug Lea's new malloc from the GNU C Library.)"
1647   fi
1648   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1649             [Define to 1 if you are using the GNU C Library.])
1650
1651   ## Use mmap directly for allocating larger buffers.
1652   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1653   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1654   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1655   case "$opsys" in
1656     gnu*) REL_ALLOC=no ;;
1657   esac
1658 fi
1659
1660 if test x"${REL_ALLOC}" = x; then
1661   REL_ALLOC=${GNU_MALLOC}
1662 fi
1663
1664 use_mmap_for_buffers=no
1665 case "$opsys" in
1666   freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1667 esac
1668
1669 AC_FUNC_MMAP
1670 if test $use_mmap_for_buffers = yes; then
1671   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1672   REL_ALLOC=no
1673 fi
1674
1675 LIBS="$LIBS_SYSTEM $LIBS"
1676
1677 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1678 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1679 AC_CHECK_LIB(dnet, dnet_ntoa)
1680 dnl This causes -lresolv to get used in subsequent tests,
1681 dnl which causes failures on some systems such as HPUX 9.
1682 dnl AC_CHECK_LIB(resolv, gethostbyname)
1683
1684 dnl FIXME replace main with a function we actually want from this library.
1685 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1686
1687 AC_CHECK_LIB(pthreads, cma_open)
1688
1689 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1690 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1691 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1692 ## added to LIBS in configure would never contain the pthreads part,
1693 ## but the value used in Makefiles might.  FIXME?
1694 ##
1695 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1696 ## be harmless on older versions of X where it happens to exist.
1697 test "$opsys" = "aix4-2" && \
1698   test $ac_cv_lib_pthreads_cma_open = yes && \
1699   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1700
1701 dnl Check for need for bigtoc support on IBM AIX
1702
1703 case ${host_os} in
1704 aix*)
1705   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1706     case $GCC in
1707     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1708     *) gdb_cv_bigtoc=-bbigtoc ;;
1709     esac
1710
1711     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1712     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1713   ])
1714   ;;
1715 esac
1716
1717 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1718 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1719 # REAL_CPPFLAGS later on.
1720
1721 REAL_CFLAGS="$CFLAGS"
1722 REAL_CPPFLAGS="$CPPFLAGS"
1723
1724 if test "${HAVE_X11}" = "yes"; then
1725   DEFS="$C_SWITCH_X_SITE $DEFS"
1726   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1727   LIBS="-lX11 $LIBS"
1728   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1729   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1730
1731   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1732   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1733   # but it's more convenient here to set LD_RUN_PATH
1734   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1735   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1736     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1737     export LD_RUN_PATH
1738   fi
1739
1740   if test "${opsys}" = "gnu-linux"; then
1741     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1742     AC_TRY_LINK([],
1743      [XOpenDisplay ("foo");],
1744      [xlinux_first_failure=no],
1745      [xlinux_first_failure=yes])
1746     if test "${xlinux_first_failure}" = "yes"; then
1747       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1748       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1749       OLD_CPPFLAGS="$CPPFLAGS"
1750       OLD_LIBS="$LIBS"
1751       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1752       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1753       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1754       LIBS="$LIBS -b i486-linuxaout"
1755       AC_TRY_LINK([],
1756        [XOpenDisplay ("foo");],
1757        [xlinux_second_failure=no],
1758        [xlinux_second_failure=yes])
1759       if test "${xlinux_second_failure}" = "yes"; then
1760         # If we get the same failure with -b, there is no use adding -b.
1761         # So take it out.  This plays safe.
1762         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1763         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1764         CPPFLAGS="$OLD_CPPFLAGS"
1765         LIBS="$OLD_LIBS"
1766         AC_MSG_RESULT(no)
1767       else
1768         AC_MSG_RESULT(yes)
1769       fi
1770     else
1771       AC_MSG_RESULT(no)
1772     fi
1773   fi
1774
1775   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1776   # header files included from there.
1777   AC_MSG_CHECKING(for Xkb)
1778   AC_TRY_LINK([#include <X11/Xlib.h>
1779 #include <X11/XKBlib.h>],
1780         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1781         emacs_xkb=yes, emacs_xkb=no)
1782   AC_MSG_RESULT($emacs_xkb)
1783   if test $emacs_xkb = yes; then
1784     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1785   fi
1786
1787   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1788 XScreenNumberOfScreen XSetWMProtocols)
1789 fi
1790
1791 if test "${window_system}" = "x11"; then
1792   AC_MSG_CHECKING(X11 version 6)
1793   AC_CACHE_VAL(emacs_cv_x11_version_6,
1794   [AC_TRY_LINK([#include <X11/Xlib.h>],
1795 [#if XlibSpecificationRelease < 6
1796 fail;
1797 #endif
1798 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1799   if test $emacs_cv_x11_version_6 = yes; then
1800     AC_MSG_RESULT(6 or newer)
1801     AC_DEFINE(HAVE_X11R6, 1,
1802               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1803     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1804     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1805     ## XIM support.
1806     case "$opsys" in
1807       sol2-*) : ;;
1808       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1809            [Define if you have usable X11R6-style XIM support.])
1810          ;;
1811     esac
1812   else
1813     AC_MSG_RESULT(before 6)
1814   fi
1815 fi
1816
1817
1818 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1819 HAVE_RSVG=no
1820 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1821   if test "${with_rsvg}" != "no"; then
1822     RSVG_REQUIRED=2.11.0
1823     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1824
1825     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1826     AC_SUBST(RSVG_CFLAGS)
1827     AC_SUBST(RSVG_LIBS)
1828
1829     if test $HAVE_RSVG = yes; then
1830       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1831       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1832       LIBS="$RSVG_LIBS $LIBS"
1833     fi
1834   fi
1835 fi
1836
1837 HAVE_IMAGEMAGICK=no
1838 if test "${HAVE_X11}" = "yes"; then
1839   if test "${with_imagemagick}" != "no"; then
1840     IMAGEMAGICK_MODULE="Wand"
1841     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1842     AC_SUBST(IMAGEMAGICK_CFLAGS)
1843     AC_SUBST(IMAGEMAGICK_LIBS)
1844
1845     if test $HAVE_IMAGEMAGICK = yes; then
1846       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1847       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1848       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1849       AC_CHECK_FUNCS(MagickExportImagePixels)
1850     fi
1851   fi
1852 fi
1853
1854
1855 HAVE_GTK=no
1856 if test "${with_gtk3}" = "yes"; then
1857   GLIB_REQUIRED=2.6
1858   GTK_REQUIRED=2.90
1859   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1860
1861   dnl Checks for libraries.
1862   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1863   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1864      AC_MSG_ERROR($GTK_PKG_ERRORS)
1865   fi
1866 fi
1867
1868 if test "$pkg_check_gtk" != "yes"; then
1869   HAVE_GTK=no
1870 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1871   GLIB_REQUIRED=2.6
1872   GTK_REQUIRED=2.6
1873   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1874
1875   dnl Checks for libraries.
1876   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1877   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1878      AC_MSG_ERROR($GTK_PKG_ERRORS)
1879   fi
1880 fi
1881 fi
1882
1883 GTK_OBJ=
1884 if test x"$pkg_check_gtk" = xyes; then
1885
1886   AC_SUBST(GTK_CFLAGS)
1887   AC_SUBST(GTK_LIBS)
1888   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1889   CFLAGS="$CFLAGS $GTK_CFLAGS"
1890   LIBS="$GTK_LIBS $LIBS"
1891   dnl Try to compile a simple GTK program.
1892   GTK_COMPILES=no
1893   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1894   if test "${GTK_COMPILES}" != "yes"; then
1895     if test "$USE_X_TOOLKIT" != "maybe"; then
1896       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1897     fi
1898   else
1899     HAVE_GTK=yes
1900     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1901     GTK_OBJ=gtkutil.o
1902     USE_X_TOOLKIT=none
1903     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1904       :
1905     else
1906       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1907        closing open displays.  This is no problem if you just use
1908        one display, but if you use more than one and close one of them
1909        Emacs may crash.]])
1910       sleep 3
1911     fi
1912   fi
1913
1914 fi
1915 AC_SUBST(GTK_OBJ)
1916
1917
1918 if test "${HAVE_GTK}" = "yes"; then
1919
1920   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1921   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1922   if test "$with_toolkit_scroll_bars" != no; then
1923     with_toolkit_scroll_bars=yes
1924   fi
1925
1926   dnl  Check if we have the old file selection dialog declared and
1927   dnl  in the link library.  In 2.x it may be in the library,
1928   dnl  but not declared if deprecated featured has been selected out.
1929   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1930   HAVE_GTK_FILE_SELECTION=no
1931   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1932                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1933 #include <gtk/gtk.h>])
1934   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1935     AC_CHECK_FUNCS(gtk_file_selection_new)
1936   fi
1937
1938   dnl Check if pthreads are available.  Emacs only needs this when using
1939   dnl gtk_file_chooser under Gnome.
1940     HAVE_GTK_AND_PTHREAD=no
1941     AC_CHECK_HEADERS(pthread.h)
1942     if test "$ac_cv_header_pthread_h"; then
1943       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1944     fi
1945     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1946       case "${canonical}" in
1947         *-hpux*) ;;
1948         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1949       esac
1950       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1951                [Define to 1 if you have GTK and pthread (-lpthread).])
1952     fi
1953
1954   dnl Check for functions introduced in 2.14 and later.
1955   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1956                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1957                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1958                  gtk_orientable_set_orientation)
1959
1960 fi
1961
1962 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1963 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1964 dnl also not configured.
1965 HAVE_DBUS=no
1966 DBUS_OBJ=
1967 if test "${with_dbus}" = "yes"; then
1968    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1969    if test "$HAVE_DBUS" = yes; then
1970      LIBS="$LIBS $DBUS_LIBS"
1971      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1972      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1973      DBUS_OBJ=dbusbind.o
1974    fi
1975 fi
1976 AC_SUBST(DBUS_OBJ)
1977
1978 dnl GConf has been tested under GNU/Linux only.
1979 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1980 HAVE_GCONF=no
1981 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1982    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1983    if test "$HAVE_GCONF" = yes; then
1984       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1985    fi
1986 fi
1987
1988 dnl SELinux is available for GNU/Linux only.
1989 HAVE_LIBSELINUX=no
1990 LIBSELINUX_LIBS=
1991 if test "${with_selinux}" = "yes"; then
1992    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1993    if test "$HAVE_LIBSELINUX" = yes; then
1994       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1995       LIBSELINUX_LIBS=-lselinux
1996    fi
1997 fi
1998 AC_SUBST(LIBSELINUX_LIBS)
1999
2000 HAVE_GNUTLS=no
2001 if test "${with_gnutls}" = "yes" ; then
2002   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.2.4], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2003   if test "${HAVE_GNUTLS}" = "yes"; then
2004     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2005   fi
2006 fi
2007 AC_SUBST(LIBGNUTLS_LIBS)
2008 AC_SUBST(LIBGNUTLS_CFLAGS)
2009
2010 dnl Do not put whitespace before the #include statements below.
2011 dnl Older compilers (eg sunos4 cc) choke on it.
2012 HAVE_XAW3D=no
2013 LUCID_LIBW=
2014 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2015   if test "$with_xaw3d" != no; then
2016     AC_MSG_CHECKING(for xaw3d)
2017     AC_CACHE_VAL(emacs_cv_xaw3d,
2018     [AC_TRY_LINK([
2019 #include <X11/Intrinsic.h>
2020 #include <X11/Xaw3d/Simple.h>],
2021       [],
2022       emacs_cv_xaw3d=yes,
2023       emacs_cv_xaw3d=no)])
2024   else
2025     emacs_cv_xaw3d=no
2026   fi
2027   if test $emacs_cv_xaw3d = yes; then
2028     AC_MSG_RESULT([yes; using Lucid toolkit])
2029     USE_X_TOOLKIT=LUCID
2030     HAVE_XAW3D=yes
2031     LUCID_LIBW=-lXaw3d
2032     AC_DEFINE(HAVE_XAW3D, 1,
2033               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2034   else
2035     AC_MSG_RESULT(no)
2036     AC_MSG_CHECKING(for libXaw)
2037     AC_CACHE_VAL(emacs_cv_xaw,
2038     [AC_TRY_LINK([
2039 #include <X11/Intrinsic.h>
2040 #include <X11/Xaw/Simple.h>],
2041       [],
2042       emacs_cv_xaw=yes,
2043       emacs_cv_xaw=no)])
2044     if test $emacs_cv_xaw = yes; then
2045       AC_MSG_RESULT([yes; using Lucid toolkit])
2046       USE_X_TOOLKIT=LUCID
2047       LUCID_LIBW=-lXaw
2048     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2049       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2050     else
2051       AC_MSG_RESULT([no; do not use toolkit by default])
2052       USE_X_TOOLKIT=none
2053     fi
2054   fi
2055 fi
2056
2057 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2058
2059 LIBXTR6=
2060 if test "${USE_X_TOOLKIT}" != "none"; then
2061   AC_MSG_CHECKING(X11 toolkit version)
2062   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2063   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2064 [#if XtSpecificationRelease < 6
2065 fail;
2066 #endif
2067 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2068   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2069   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2070     AC_MSG_RESULT(6 or newer)
2071     AC_DEFINE(HAVE_X11XTR6, 1,
2072               [Define to 1 if you have the X11R6 or newer version of Xt.])
2073     LIBXTR6="-lSM -lICE"
2074     case "$opsys" in
2075       ## Use libw.a along with X11R6 Xt.
2076       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2077     esac
2078   else
2079     AC_MSG_RESULT(before 6)
2080   fi
2081
2082 dnl If using toolkit, check whether libXmu.a exists.
2083 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2084   OLDLIBS="$LIBS"
2085   if test x$HAVE_X11XTR6 = xyes; then
2086     LIBS="-lXt -lSM -lICE $LIBS"
2087   else
2088     LIBS="-lXt $LIBS"
2089   fi
2090   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2091   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2092 fi
2093 AC_SUBST(LIBXTR6)
2094
2095 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2096 dnl Why not just test for libxmu in the normal way?
2097 LIBXMU=-lXmu
2098 case "$machine" in
2099   ## These machines don't supply Xmu.
2100   hpux* | aix4-2 )
2101     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2102     ;;
2103 esac
2104 AC_SUBST(LIBXMU)
2105
2106 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2107 if test "${HAVE_X11}" = "yes"; then
2108   if test "${USE_X_TOOLKIT}" != "none"; then
2109     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2110   fi
2111 fi
2112
2113 LIBXP=
2114 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2115   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2116   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2117     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2118 int x = 5;
2119 #else
2120 Motif version prior to 2.1.
2121 #endif],
2122     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2123   if test $emacs_cv_motif_version_2_1 = yes; then
2124     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2125   else
2126     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2127     # We put this in CFLAGS temporarily to precede other -I options
2128     # that might be in CFLAGS temporarily.
2129     # We put this in CPPFLAGS where it precedes the other -I options.
2130     OLD_CPPFLAGS=$CPPFLAGS
2131     OLD_CFLAGS=$CFLAGS
2132     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2133     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2134     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2135       [int x = 5;],
2136       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2137     if test $emacs_cv_lesstif = yes; then
2138       # Make sure this -I option remains in CPPFLAGS after it is set
2139       # back to REAL_CPPFLAGS.
2140       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2141       # have those other -I options anyway.  Ultimately, having this
2142       # directory ultimately in CPPFLAGS will be enough.
2143       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2144       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2145     else
2146       CFLAGS=$OLD_CFLAGS
2147       CPPFLAGS=$OLD_CPPFLAGS
2148     fi
2149   fi
2150 fi
2151
2152 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2153 dnl using Motif or Xaw3d is available, and unless
2154 dnl --with-toolkit-scroll-bars=no was specified.
2155
2156 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2157             [Define to 1 if we should use toolkit scroll bars.])dnl
2158 USE_TOOLKIT_SCROLL_BARS=no
2159 if test "${with_toolkit_scroll_bars}" != "no"; then
2160   if test "${USE_X_TOOLKIT}" != "none"; then
2161     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2162       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2163       HAVE_XAW3D=no
2164       USE_TOOLKIT_SCROLL_BARS=yes
2165     elif test "${HAVE_XAW3D}" = "yes"; then
2166       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2167       USE_TOOLKIT_SCROLL_BARS=yes
2168     fi
2169   elif test "${HAVE_GTK}" = "yes"; then
2170     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2171     USE_TOOLKIT_SCROLL_BARS=yes
2172   elif test "${HAVE_NS}" = "yes"; then
2173     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2174     USE_TOOLKIT_SCROLL_BARS=yes
2175   fi
2176 fi
2177
2178 dnl See if XIM is available.
2179 AC_TRY_COMPILE([
2180           #include <X11/Xlib.h>
2181           #include <X11/Xresource.h>],
2182          [XIMProc  callback;],
2183          [HAVE_XIM=yes
2184          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2185          HAVE_XIM=no)
2186
2187 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2188
2189 if test "${with_xim}" != "no"; then
2190   AC_DEFINE(USE_XIM, 1,
2191             [Define to 1 if we should use XIM, if it is available.])
2192 fi
2193
2194
2195 if test "${HAVE_XIM}" != "no"; then
2196   late_CFLAGS=$CFLAGS
2197   if test "$GCC" = yes; then
2198     CFLAGS="$CFLAGS --pedantic-errors"
2199   fi
2200   AC_TRY_COMPILE([
2201 #include <X11/Xlib.h>
2202 #include <X11/Xresource.h>],
2203 [Display *display;
2204 XrmDatabase db;
2205 char *res_name;
2206 char *res_class;
2207 XIMProc  callback;
2208 XPointer *client_data;
2209 #ifndef __GNUC__
2210 /* If we're not using GCC, it's probably not XFree86, and this is
2211    probably right, but we can't use something like --pedantic-errors.  */
2212 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2213                                            char*, XIMProc, XPointer*);
2214 #endif
2215 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2216    client_data);],
2217     [emacs_cv_arg6_star=yes])
2218   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2219          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2220 either XPointer or XPointer*.])dnl
2221   if test "$emacs_cv_arg6_star" = yes; then
2222     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2223   else
2224     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2225   fi
2226   CFLAGS=$late_CFLAGS
2227 fi
2228
2229 ### Start of font-backend (under any platform) section.
2230 # (nothing here yet -- this is a placeholder)
2231 ### End of font-backend (under any platform) section.
2232
2233 ### Start of font-backend (under X11) section.
2234 if test "${HAVE_X11}" = "yes"; then
2235    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2236
2237    ## Use -lXft if available, unless `--with-xft=no'.
2238    HAVE_XFT=maybe
2239     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2240       with_xft="no";
2241     fi
2242     if test "x${with_xft}" != "xno"; then
2243
2244       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2245       ## Because xftfont.c uses XRenderQueryExtension, we also
2246       ## need to link to -lXrender.
2247       HAVE_XRENDER=no
2248       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2249       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2250         OLD_CPPFLAGS="$CPPFLAGS"
2251         OLD_CFLAGS="$CFLAGS"
2252         OLD_LIBS="$LIBS"
2253         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2254         CFLAGS="$CFLAGS $XFT_CFLAGS"
2255         XFT_LIBS="-lXrender $XFT_LIBS"
2256         LIBS="$XFT_LIBS $LIBS"
2257         AC_CHECK_HEADER(X11/Xft/Xft.h,
2258           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2259
2260         if test "${HAVE_XFT}" = "yes"; then
2261           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2262             AC_SUBST(XFT_LIBS)
2263           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2264         else
2265           CPPFLAGS="$OLD_CPPFLAGS"
2266           CFLAGS="$OLD_CFLAGS"
2267           LIBS="$OLD_LIBS"
2268         fi                        # "${HAVE_XFT}" = "yes"
2269       fi                          # "$HAVE_XFT" != no
2270     fi                            # "x${with_xft}" != "xno"
2271
2272     dnl For the "Does Emacs use" message at the end.
2273     if test "$HAVE_XFT" != "yes"; then
2274        HAVE_XFT=no
2275     fi
2276
2277
2278     HAVE_FREETYPE=no
2279     ## We used to allow building with FreeType and without Xft.
2280     ## However, the ftx font backend driver is not in good shape.
2281     if test "${HAVE_XFT}" = "yes"; then
2282       dnl As we use Xft, we anyway use freetype.
2283       dnl There's no need for additional CFLAGS and LIBS.
2284       HAVE_FREETYPE=yes
2285       FONTCONFIG_CFLAGS=
2286       FONTCONFIG_LIBS=
2287     fi
2288
2289     HAVE_LIBOTF=no
2290     if test "${HAVE_FREETYPE}" = "yes"; then
2291       AC_DEFINE(HAVE_FREETYPE, 1,
2292                 [Define to 1 if using the freetype and fontconfig libraries.])
2293       if test "${with_libotf}" != "no"; then
2294         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2295                           HAVE_LIBOTF=no)
2296         if test "$HAVE_LIBOTF" = "yes"; then
2297           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2298           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2299                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2300                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2301           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2302             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2303                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2304           fi
2305         fi
2306       fi
2307     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2308     dnl Does the new font backend require it, or can it work without it?
2309     fi
2310
2311     HAVE_M17N_FLT=no
2312     if test "${HAVE_LIBOTF}" = yes; then
2313       if test "${with_m17n_flt}" != "no"; then
2314         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2315         if test "$HAVE_M17N_FLT" = "yes"; then
2316           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2317         fi
2318       fi
2319     fi
2320 else
2321     HAVE_XFT=no
2322     HAVE_FREETYPE=no
2323     HAVE_LIBOTF=no
2324     HAVE_M17N_FLT=no
2325 fi
2326
2327 ### End of font-backend (under X11) section.
2328
2329 AC_SUBST(FREETYPE_CFLAGS)
2330 AC_SUBST(FREETYPE_LIBS)
2331 AC_SUBST(FONTCONFIG_CFLAGS)
2332 AC_SUBST(FONTCONFIG_LIBS)
2333 AC_SUBST(LIBOTF_CFLAGS)
2334 AC_SUBST(LIBOTF_LIBS)
2335 AC_SUBST(M17N_FLT_CFLAGS)
2336 AC_SUBST(M17N_FLT_LIBS)
2337
2338 ### Use -lXpm if available, unless `--with-xpm=no'.
2339 HAVE_XPM=no
2340 LIBXPM=
2341 if test "${HAVE_X11}" = "yes"; then
2342   if test "${with_xpm}" != "no"; then
2343     AC_CHECK_HEADER(X11/xpm.h,
2344       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2345     if test "${HAVE_XPM}" = "yes"; then
2346       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2347       AC_EGREP_CPP(no_return_alloc_pixels,
2348       [#include "X11/xpm.h"
2349 #ifndef XpmReturnAllocPixels
2350 no_return_alloc_pixels
2351 #endif
2352       ], HAVE_XPM=no, HAVE_XPM=yes)
2353
2354       if test "${HAVE_XPM}" = "yes"; then
2355         AC_MSG_RESULT(yes)
2356       else
2357         AC_MSG_RESULT(no)
2358       fi
2359     fi
2360   fi
2361
2362   if test "${HAVE_XPM}" = "yes"; then
2363     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2364     LIBXPM=-lXpm
2365   fi
2366 fi
2367 AC_SUBST(LIBXPM)
2368
2369 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2370 HAVE_JPEG=no
2371 LIBJPEG=
2372 if test "${HAVE_X11}" = "yes"; then
2373   if test "${with_jpeg}" != "no"; then
2374     dnl Checking for jpeglib.h can lose because of a redefinition of
2375     dnl  HAVE_STDLIB_H.
2376     AC_CHECK_HEADER(jerror.h,
2377       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2378   fi
2379
2380   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2381   if test "${HAVE_JPEG}" = "yes"; then
2382     AC_DEFINE(HAVE_JPEG)
2383     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2384         [#include <jpeglib.h>
2385          version=JPEG_LIB_VERSION
2386 ],
2387         [AC_DEFINE(HAVE_JPEG)],
2388         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2389         HAVE_JPEG=no])
2390   fi
2391   if test "${HAVE_JPEG}" = "yes"; then
2392     LIBJPEG=-ljpeg
2393   fi
2394 fi
2395 AC_SUBST(LIBJPEG)
2396
2397 ### Use -lpng if available, unless `--with-png=no'.
2398 HAVE_PNG=no
2399 LIBPNG=
2400 if test "${HAVE_X11}" = "yes"; then
2401   if test "${with_png}" != "no"; then
2402     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2403     # in /usr/include/libpng.
2404     AC_CHECK_HEADERS(png.h libpng/png.h)
2405     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2406       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2407     fi
2408   fi
2409
2410   if test "${HAVE_PNG}" = "yes"; then
2411     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2412     LIBPNG="-lpng -lz -lm"
2413   fi
2414 fi
2415 AC_SUBST(LIBPNG)
2416
2417 ### Use -ltiff if available, unless `--with-tiff=no'.
2418 HAVE_TIFF=no
2419 LIBTIFF=
2420 if test "${HAVE_X11}" = "yes"; then
2421   if test "${with_tiff}" != "no"; then
2422     AC_CHECK_HEADER(tiffio.h,
2423       [tifflibs="-lz -lm"
2424       # At least one tiff package requires the jpeg library.
2425       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2426       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2427   fi
2428
2429   if test "${HAVE_TIFF}" = "yes"; then
2430     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2431     dnl FIXME -lz -lm, as per libpng?
2432     LIBTIFF=-ltiff
2433   fi
2434 fi
2435 AC_SUBST(LIBTIFF)
2436
2437 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2438 HAVE_GIF=no
2439 LIBGIF=
2440 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2441   AC_CHECK_HEADER(gif_lib.h,
2442 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2443 # Earlier versions can crash Emacs.
2444     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2445
2446   if test "$HAVE_GIF" = yes; then
2447     LIBGIF=-lgif
2448   elif test "$HAVE_GIF" = maybe; then
2449 # If gif_lib.h but no libgif, try libungif.
2450     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2451     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2452   fi
2453
2454   if test "${HAVE_GIF}" = "yes"; then
2455     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2456   fi
2457 fi
2458 AC_SUBST(LIBGIF)
2459
2460 dnl Check for required libraries.
2461 if test "${HAVE_X11}" = "yes"; then
2462   MISSING=""
2463   WITH_NO=""
2464   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2465     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2466   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2467     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2468   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2469     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2470   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2471     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2472   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2473     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2474
2475   if test "X${MISSING}" != X; then
2476     AC_MSG_ERROR([The following required libraries were not found:
2477     $MISSING
2478 Maybe some development libraries/packages are missing?
2479 If you don't want to link with them give
2480     $WITH_NO
2481 as options to configure])
2482   fi
2483 fi
2484
2485 ### Use -lgpm if available, unless `--with-gpm=no'.
2486 HAVE_GPM=no
2487 LIBGPM=
2488 MOUSE_SUPPORT=
2489 if test "${with_gpm}" != "no"; then
2490   AC_CHECK_HEADER(gpm.h,
2491     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2492
2493   if test "${HAVE_GPM}" = "yes"; then
2494     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2495     LIBGPM=-lgpm
2496     ## May be reset below.
2497     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2498   fi
2499 fi
2500 AC_SUBST(LIBGPM)
2501
2502 dnl Check for malloc/malloc.h on darwin
2503 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2504
2505 C_SWITCH_X_SYSTEM=
2506 ### Use NeXTstep API to implement GUI.
2507 if test "${HAVE_NS}" = "yes"; then
2508   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2509   if test "${NS_IMPL_COCOA}" = "yes"; then
2510     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2511     GNU_OBJC_CFLAGS=
2512   fi
2513   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2514     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2515     # See also .m.o rule in Makefile.in */
2516     # FIXME: are all these flags really needed?  Document here why.  */
2517     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2518     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2519   fi
2520   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2521     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2522   fi
2523   # We also have mouse menus.
2524   HAVE_MENUS=yes
2525   OTHER_FILES=ns-app
2526 fi
2527
2528
2529 ### Use session management (-lSM -lICE) if available
2530 HAVE_X_SM=no
2531 LIBXSM=
2532 if test "${HAVE_X11}" = "yes"; then
2533   AC_CHECK_HEADER(X11/SM/SMlib.h,
2534     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2535
2536   if test "${HAVE_X_SM}" = "yes"; then
2537     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2538     LIBXSM="-lSM -lICE"
2539     case "$LIBS" in
2540       *-lSM*) ;;
2541       *)      LIBS="$LIBXSM $LIBS" ;;
2542     esac
2543   fi
2544 fi
2545 AC_SUBST(LIBXSM)
2546
2547 ### Use libxml (-lxml2) if available
2548 if test "${with_xml2}" != "no"; then
2549   ### I'm not sure what the version number should be, so I just guessed.
2550   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.2.0, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2551   if test "${HAVE_LIBXML2}" = "yes"; then
2552     LIBS="$LIBXML2_LIBS $LIBS"
2553     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2554     if test "${HAVE_LIBXML2}" = "yes"; then
2555       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2556     else
2557       LIBXML2_LIBS=""
2558       LIBXML2_CFLAGS=""
2559     fi
2560   fi
2561 fi
2562 AC_SUBST(LIBXML2_LIBS)
2563 AC_SUBST(LIBXML2_CFLAGS)
2564
2565 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2566 AC_CACHE_CHECK(whether netdb declares h_errno,
2567                emacs_cv_netdb_declares_h_errno,
2568 [AC_TRY_LINK([#include <netdb.h>],
2569   [return h_errno;],
2570   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2571 if test $emacs_cv_netdb_declares_h_errno = yes; then
2572   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2573 fi
2574
2575 AC_FUNC_ALLOCA
2576
2577 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2578 dnl FIXME is there an autoconf test that does the right thing, without
2579 dnl needing to call A_M_E afterwards?
2580 if test x"$ac_cv_func_alloca_works" != xyes; then
2581    AC_MSG_ERROR( [a system implementation of alloca is required] )
2582 fi
2583
2584 # fmod, logb, and frexp are found in -lm on most systems.
2585 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2586 AC_CHECK_LIB(m, sqrt)
2587
2588 # Check for mail-locking functions in a "mail" library.  Probably this should
2589 # have the same check as for liblockfile below.
2590 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2591 if test $have_mail = yes; then
2592   LIBS_MAIL=-lmail
2593   LIBS="$LIBS_MAIL $LIBS"
2594   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2595 else
2596   LIBS_MAIL=
2597 fi
2598 dnl Debian, at least:
2599 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2600 if test $have_lockfile = yes; then
2601    LIBS_MAIL=-llockfile
2602    LIBS="$LIBS_MAIL $LIBS"
2603    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2604 else
2605 # If we have the shared liblockfile, assume we must use it for mail
2606 # locking (e.g. Debian).  If we couldn't link against liblockfile
2607 # (no liblockfile.a installed), ensure that we don't need to.
2608   dnl This works for files generally, not just executables.
2609   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2610   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2611                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2612   if test $ac_cv_prog_liblockfile = yes; then
2613     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2614 This probably means that movemail could lose mail.
2615 There may be a `development' package to install containing liblockfile.])
2616   fi
2617 fi
2618 AC_CHECK_FUNCS(touchlock)
2619 AC_CHECK_HEADERS(maillock.h)
2620 AC_SUBST(LIBS_MAIL)
2621
2622 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2623 ## interlock access to the mail spool.  The alternative is a lock file named
2624 ## /usr/spool/mail/$USER.lock.
2625 mail_lock=no
2626 case "$opsys" in
2627   aix4-2) mail_lock="lockf" ;;
2628
2629   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2630
2631   ## On GNU/Linux systems, both methods are used by various mail programs.
2632   ## I assume most people are using newer mailers that have heard of flock.
2633   ## Change this if you need to.
2634   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2635   ## configure gets the right answers, and that means *NOT* using flock.
2636   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2637   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2638   ## Debian maintainer hasn't provided a clean fix for Emacs.
2639   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2640   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2641   ## correct logic.  -- fx
2642   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2643   ## liblockfile is a Free Software replacement for libmail, used on
2644   ## Debian systems and elsewhere. -rfr.
2645   gnu-*)
2646     mail_lock="flock"
2647     if test $have_mail = yes || test $have_lockfile = yes; then
2648       test $ac_cv_header_maillock_h = yes && mail_lock=no
2649     fi
2650     ;;
2651 esac
2652
2653 BLESSMAIL_TARGET=
2654 case "$mail_lock" in
2655   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2656
2657   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2658
2659   *) BLESSMAIL_TARGET="need-blessmail" ;;
2660 esac
2661 AC_SUBST(BLESSMAIL_TARGET)
2662
2663
2664 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2665 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2666 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2667 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2668 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2669 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm strchr strrchr \
2670 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2671 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2672 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2673 cfmakeraw cfsetspeed isnan copysign __executable_start)
2674
2675 AC_CHECK_HEADERS(sys/un.h)
2676
2677 AC_FUNC_MKTIME
2678 if test "$ac_cv_func_working_mktime" = no; then
2679   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2680 fi
2681
2682 AC_FUNC_GETLOADAVG
2683
2684 AC_FUNC_FSEEKO
2685
2686 # Configure getopt.
2687 m4_include([m4/getopt.m4])
2688 gl_GETOPT_IFELSE([
2689   gl_GETOPT_SUBSTITUTE_HEADER
2690   gl_PREREQ_GETOPT
2691   GETOPTOBJS='getopt.o getopt1.o'
2692 ])
2693 AC_SUBST(GETOPTOBJS)
2694
2695 AC_FUNC_GETPGRP
2696
2697 AC_FUNC_STRFTIME
2698
2699 # UNIX98 PTYs.
2700 AC_CHECK_FUNCS(grantpt)
2701
2702 # PTY-related GNU extensions.
2703 AC_CHECK_FUNCS(getpt)
2704
2705 # Check this now, so that we will NOT find the above functions in ncurses.
2706 # That is because we have not set up to link ncurses in lib-src.
2707 # It's better to believe a function is not available
2708 # than to expect to find it in ncurses.
2709 # Also we need tputs and friends to be able to build at all.
2710 have_tputs_et_al=true
2711 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2712 if test "$have_tputs_et_al" != true; then
2713   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2714 Maybe some development libraries/packages are missing?  Try installing
2715 libncurses-dev(el), libterminfo-dev(el) or similar.])
2716 fi
2717 # Must define this when any termcap library is found.
2718 AC_DEFINE(HAVE_LIBNCURSES, 1,
2719           [Define to 1 if you have the `ncurses' library (-lncurses).])
2720 ## FIXME This was the cpp logic, but I am not sure it is right.
2721 ## The above test has not necessarily found libncurses.
2722 HAVE_LIBNCURSES=yes
2723
2724 ## Use terminfo instead of termcap?
2725 ## Note only system files NOT using terminfo are:
2726 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2727 ## darwin|gnu without ncurses.
2728 TERMINFO=no
2729 LIBS_TERMCAP=
2730 case "$opsys" in
2731   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2732   ## hpux10-20: Use the system provided termcap(3) library.
2733   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2734   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2735   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2736
2737   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2738   ##  The ncurses library has been moved out of the System framework in
2739   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2740   ##  option to use it.
2741   darwin|gnu*)
2742     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2743     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2744       TERMINFO=yes
2745       LIBS_TERMCAP="-lncurses"
2746     fi
2747     ;;
2748
2749   freebsd)
2750     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2751     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2752     [AC_TRY_LINK([#include <osreldate.h>],
2753 [#if __FreeBSD_version < 400000
2754 fail;
2755 #endif
2756 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2757
2758     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2759
2760     if test $emacs_cv_freebsd_terminfo = yes; then
2761       TERMINFO=yes
2762       LIBS_TERMCAP="-lncurses"
2763     else
2764       LIBS_TERMCAP="-ltermcap"
2765     fi
2766     ;;
2767
2768   netbsd)
2769     if test $ac_cv_search_tputs = -lterminfo; then
2770       TERMINFO=yes
2771       LIBS_TERMCAP="-lterminfo"
2772     else
2773       LIBS_TERMCAP="-ltermcap"
2774     fi
2775     ;;
2776
2777 esac
2778
2779 case "$opsys" in
2780   ## hpux: Make sure we get select from libc rather than from libcurses
2781   ##  because libcurses on HPUX 10.10 has a broken version of select.
2782   ##  We used to use -lc -lcurses, but this may be cleaner.
2783   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2784
2785   openbsd) LIBS_TERMCAP="-lncurses" ;;
2786
2787   ## Must use system termcap, if we use any termcap.  It does special things.
2788   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2789 esac
2790
2791 TERMCAP_OBJ=tparam.o
2792 if test $TERMINFO = yes; then
2793   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2794
2795   ## Default used to be -ltermcap.  Add a case above if need something else.
2796   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2797
2798   TERMCAP_OBJ=terminfo.o
2799 fi
2800 AC_SUBST(LIBS_TERMCAP)
2801 AC_SUBST(TERMCAP_OBJ)
2802
2803
2804 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2805 resolv=no
2806 AC_TRY_LINK([#include <netinet/in.h>
2807 #include <arpa/nameser.h>
2808 #include <resolv.h>],
2809     [return res_init();],
2810     have_res_init=yes, have_res_init=no)
2811 if test "$have_res_init" = no; then
2812   OLIBS="$LIBS"
2813   LIBS="$LIBS -lresolv"
2814   AC_MSG_CHECKING(for res_init with -lresolv)
2815   AC_TRY_LINK([#include <netinet/in.h>
2816 #include <arpa/nameser.h>
2817 #include <resolv.h>],
2818     [return res_init();],
2819     have_res_init=yes, have_res_init=no)
2820   AC_MSG_RESULT($have_res_init)
2821   if test "$have_res_init" = yes ; then
2822     resolv=yes
2823   fi
2824   LIBS="$OLIBS"
2825 fi
2826
2827 if test "$have_res_init" = yes; then
2828   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2829 fi
2830
2831 # Do we need the Hesiod library to provide the support routines?
2832 LIBHESIOD=
2833 if test "$with_hesiod" != no ; then
2834   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2835   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2836      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2837                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2838   if test "$resolv" = yes ; then
2839     RESOLVLIB=-lresolv
2840   else
2841     RESOLVLIB=
2842   fi
2843   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2844         hesiod=yes, :, $RESOLVLIB)])
2845
2846   if test x"$hesiod" = xyes; then
2847     AC_DEFINE(HAVE_LIBHESIOD, 1,
2848               [Define to 1 if you have the hesiod library (-lhesiod).])
2849     LIBHESIOD=-lhesiod
2850   fi
2851 fi
2852 AC_SUBST(LIBHESIOD)
2853
2854 # Do we need libresolv (due to res_init or Hesiod)?
2855 if test "$resolv" = yes ; then
2856   AC_DEFINE(HAVE_LIBRESOLV, 1,
2857             [Define to 1 if you have the resolv library (-lresolv).])
2858   LIBRESOLV=-lresolv
2859 else
2860   LIBRESOLV=
2861 fi
2862 AC_SUBST(LIBRESOLV)
2863
2864 # These tell us which Kerberos-related libraries to use.
2865 COM_ERRLIB=
2866 CRYPTOLIB=
2867 KRB5LIB=
2868 DESLIB=
2869 KRB4LIB=
2870
2871 if test "${with_kerberos}" != no; then
2872   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2873   if test $have_com_err = yes; then
2874     COM_ERRLIB=-lcom_err
2875     LIBS="$COM_ERRLIB $LIBS"
2876     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2877   fi
2878   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2879   if test $have_crypto = yes; then
2880     CRYPTOLIB=-lcrypto
2881     LIBS="$CRYPTOLIB $LIBS"
2882     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2883   fi
2884   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2885   if test $have_k5crypto = yes; then
2886     CRYPTOLIB=-lk5crypto
2887     LIBS="$CRYPTOLIB $LIBS"
2888     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2889   fi
2890   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2891   if test $have_krb5=yes; then
2892     KRB5LIB=-lkrb5
2893     LIBS="$KRB5LIB $LIBS"
2894     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2895   fi
2896   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2897   if test "${with_kerberos5}" = no; then
2898     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2899     if test $have_des425 = yes; then
2900       DESLIB=-ldes425
2901       LIBS="$DESLIB $LIBS"
2902       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2903     else
2904       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2905       if test $have_des = yes; then
2906         DESLIB=-ldes
2907         LIBS="$DESLIB $LIBS"
2908         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2909       fi
2910     fi
2911     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2912     if test $have_krb4 = yes; then
2913       KRB4LIB=-lkrb4
2914       LIBS="$KRB4LIB $LIBS"
2915       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2916     else
2917       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2918       if test $have_krb = yes; then
2919         KRB4LIB=-lkrb
2920         LIBS="$KRB4LIB $LIBS"
2921         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2922       fi
2923     fi
2924   fi
2925
2926   if test "${with_kerberos5}" != no; then
2927     AC_CHECK_HEADERS(krb5.h,
2928       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2929                         [#include <krb5.h>])])
2930   else
2931     AC_CHECK_HEADERS(des.h,,
2932                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2933                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2934     AC_CHECK_HEADERS(krb.h,,
2935                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2936                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2937   fi
2938   AC_CHECK_HEADERS(com_err.h)
2939 fi
2940
2941 AC_SUBST(COM_ERRLIB)
2942 AC_SUBST(CRYPTOLIB)
2943 AC_SUBST(KRB5LIB)
2944 AC_SUBST(DESLIB)
2945 AC_SUBST(KRB4LIB)
2946
2947 # Solaris requires -lintl if you want strerror (which calls dgettext)
2948 # to return localized messages.
2949 AC_CHECK_LIB(intl, dgettext)
2950
2951 AC_MSG_CHECKING(whether localtime caches TZ)
2952 AC_CACHE_VAL(emacs_cv_localtime_cache,
2953 [if test x$ac_cv_func_tzset = xyes; then
2954 AC_TRY_RUN([#include <time.h>
2955 char TZ_GMT0[] = "TZ=GMT0";
2956 char TZ_PST8[] = "TZ=PST8";
2957 main()
2958 {
2959   time_t now = time ((time_t *) 0);
2960   int hour_GMT0, hour_unset;
2961   if (putenv (TZ_GMT0) != 0)
2962     exit (1);
2963   hour_GMT0 = localtime (&now)->tm_hour;
2964   unsetenv("TZ");
2965   hour_unset = localtime (&now)->tm_hour;
2966   if (putenv (TZ_PST8) != 0)
2967     exit (1);
2968   if (localtime (&now)->tm_hour == hour_GMT0)
2969     exit (1);
2970   unsetenv("TZ");
2971   if (localtime (&now)->tm_hour != hour_unset)
2972     exit (1);
2973   exit (0);
2974 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2975 [# If we have tzset, assume the worst when cross-compiling.
2976 emacs_cv_localtime_cache=yes])
2977 else
2978         # If we lack tzset, report that localtime does not cache TZ,
2979         # since we can't invalidate the cache if we don't have tzset.
2980         emacs_cv_localtime_cache=no
2981 fi])dnl
2982 AC_MSG_RESULT($emacs_cv_localtime_cache)
2983 if test $emacs_cv_localtime_cache = yes; then
2984   AC_DEFINE(LOCALTIME_CACHE, 1,
2985             [Define to 1 if localtime caches TZ.])
2986 fi
2987
2988 if test "x$HAVE_TIMEVAL" = xyes; then
2989   AC_CHECK_FUNCS(gettimeofday)
2990   if test $ac_cv_func_gettimeofday = yes; then
2991     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2992                    emacs_cv_gettimeofday_two_arguments,
2993     [AC_TRY_COMPILE([
2994 #ifdef TIME_WITH_SYS_TIME
2995 #include <sys/time.h>
2996 #include <time.h>
2997 #else
2998 #ifdef HAVE_SYS_TIME_H
2999 #include <sys/time.h>
3000 #else
3001 #include <time.h>
3002 #endif
3003 #endif],
3004       [struct timeval time;
3005        gettimeofday (&time, 0);],
3006       emacs_cv_gettimeofday_two_arguments=yes,
3007       emacs_cv_gettimeofday_two_arguments=no)])
3008     if test $emacs_cv_gettimeofday_two_arguments = no; then
3009       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3010                 [Define to 1 if gettimeofday accepts only one argument.])
3011     fi
3012   fi
3013 fi
3014
3015 ok_so_far=yes
3016 AC_CHECK_FUNC(socket, , ok_so_far=no)
3017 if test $ok_so_far = yes; then
3018   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3019 fi
3020 if test $ok_so_far = yes; then
3021   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3022 fi
3023 if test $ok_so_far = yes; then
3024 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3025   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3026             [Define to 1 if you have inet sockets.])
3027 fi
3028
3029 AC_CHECK_HEADERS(sys/ioctl.h)
3030
3031 if test -f /usr/lpp/X11/bin/smt.exp; then
3032   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3033             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3034 fi
3035
3036 AC_MSG_CHECKING(whether system supports dynamic ptys)
3037 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3038   AC_MSG_RESULT(yes)
3039   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3040 else
3041   AC_MSG_RESULT(no)
3042 fi
3043
3044 AC_FUNC_FORK
3045
3046 dnl Adapted from Haible's version.
3047 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3048   [AC_TRY_LINK([#include <langinfo.h>],
3049     [char* cs = nl_langinfo(CODESET);],
3050     emacs_cv_langinfo_codeset=yes,
3051     emacs_cv_langinfo_codeset=no)
3052   ])
3053 if test $emacs_cv_langinfo_codeset = yes; then
3054   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3055     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3056 fi
3057
3058 AC_CHECK_TYPES(size_t)
3059
3060 AC_TYPE_MBSTATE_T
3061
3062 dnl Restrict could probably be used effectively other than in regex.c.
3063 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
3064   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
3065                   emacs_cv_c_restrict=yes,
3066                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
3067                                   emacs_cv_c_restrict=__restrict,
3068                                   emacs_cv_c_restrict=no)])])
3069 case "$emacs_cv_c_restrict" in
3070   yes) emacs_restrict=restrict;;
3071   no) emacs_restrict="";;
3072   *) emacs_restrict="$emacs_cv_c_restrict";;
3073 esac
3074 if test "$emacs_restrict" != __restrict; then
3075   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
3076     [Define to compiler's equivalent of C99 restrict keyword.
3077      Don't define if equivalent is `__restrict'.])
3078 fi
3079
3080 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3081   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3082                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3083 if test "$emacs_cv_c_restrict_arr" = yes; then
3084   AC_DEFINE(__restrict_arr, __restrict,
3085     [Define to compiler's equivalent of C99 restrict keyword in array
3086      declarations.  Define as empty for no equivalent.])
3087 fi
3088
3089 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3090 dnl how the tty code is related to POSIX and/or other versions of termios.
3091 dnl The following looks like a useful start.
3092 dnl
3093 dnl AC_SYS_POSIX_TERMIOS
3094 dnl if test $ac_cv_sys_posix_termios = yes; then
3095 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3096 dnl                                and macros for terminal control.])
3097 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3098 dnl fi
3099
3100 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3101
3102 # Set up the CFLAGS for real compilation, so we can substitute it.
3103 CFLAGS="$REAL_CFLAGS"
3104 CPPFLAGS="$REAL_CPPFLAGS"
3105
3106 ## Hack to detect a buggy GCC version.
3107 if test "x$GCC" = xyes \
3108    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3109    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3110    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3111    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3112 fi
3113
3114 #### Find out which version of Emacs this is.
3115 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3116          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3117 if test x"${version}" = x; then
3118   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3119 fi
3120 if test x"${version}" != x"$PACKAGE_VERSION"; then
3121   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3122 fi
3123
3124 ### Specify what sort of things we'll be editing into Makefile and config.h.
3125 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3126 AC_SUBST(version)
3127 AC_SUBST(configuration)
3128 ## Unused?
3129 AC_SUBST(canonical)
3130 AC_SUBST(srcdir)
3131 AC_SUBST(prefix)
3132 AC_SUBST(exec_prefix)
3133 AC_SUBST(bindir)
3134 AC_SUBST(datadir)
3135 AC_SUBST(sharedstatedir)
3136 AC_SUBST(libexecdir)
3137 AC_SUBST(mandir)
3138 AC_SUBST(infodir)
3139 AC_SUBST(lispdir)
3140 AC_SUBST(locallisppath)
3141 AC_SUBST(lisppath)
3142 AC_SUBST(x_default_search_path)
3143 AC_SUBST(etcdir)
3144 AC_SUBST(archlibdir)
3145 AC_SUBST(docdir)
3146 AC_SUBST(bitmapdir)
3147 AC_SUBST(gamedir)
3148 AC_SUBST(gameuser)
3149 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3150 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3151 ## end of LIBX_BASE, but nothing ever set it.
3152 AC_SUBST(LD_SWITCH_X_SITE)
3153 AC_SUBST(C_SWITCH_X_SITE)
3154 AC_SUBST(C_SWITCH_X_SYSTEM)
3155 AC_SUBST(CFLAGS)
3156 ## Used in lwlib/Makefile.in.
3157 AC_SUBST(X_TOOLKIT_TYPE)
3158 AC_SUBST(machfile)
3159 AC_SUBST(opsysfile)
3160 AC_SUBST(GETLOADAVG_LIBS)
3161 AC_SUBST(ns_appdir)
3162 AC_SUBST(ns_appbindir)
3163 AC_SUBST(ns_appresdir)
3164 AC_SUBST(ns_appsrc)
3165 AC_SUBST(GNU_OBJC_CFLAGS)
3166 AC_SUBST(OTHER_FILES)
3167
3168 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3169                    [Define to the canonical Emacs configuration name.])
3170 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3171                    [Define to the options passed to configure.])
3172 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3173                    [Define to the used machine dependent file.])
3174 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3175                    [Define to the used os dependent file.])
3176
3177 XMENU_OBJ=
3178 XOBJ=
3179 FONT_OBJ=
3180 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3181   AC_DEFINE(HAVE_X_WINDOWS, 1,
3182             [Define to 1 if you want to use the X window system.])
3183   XMENU_OBJ=xmenu.o
3184   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3185   FONT_OBJ=xfont.o
3186   if test "$HAVE_XFT" = "yes"; then
3187     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3188   elif test "$HAVE_FREETYPE" = "yes"; then
3189     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3190   fi
3191   AC_SUBST(FONT_OBJ)
3192 fi
3193 AC_SUBST(XMENU_OBJ)
3194 AC_SUBST(XOBJ)
3195 AC_SUBST(FONT_OBJ)
3196
3197 WIDGET_OBJ=
3198 MOTIF_LIBW=
3199 if test "${USE_X_TOOLKIT}" != "none" ; then
3200   WIDGET_OBJ=widget.o
3201   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3202   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3203     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3204   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3205     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3206     MOTIF_LIBW=-lXm
3207     case "$opsys" in
3208       gnu-linux)
3209         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3210         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3211         ;;
3212
3213       unixware)
3214         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3215         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3216         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3217         ;;
3218
3219       aix4-2)
3220         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3221         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3222         ;;
3223     esac
3224     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3225   fi
3226 fi
3227 AC_SUBST(WIDGET_OBJ)
3228
3229 TOOLKIT_LIBW=
3230 case "$USE_X_TOOLKIT" in
3231   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3232   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3233   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3234 esac
3235 AC_SUBST(TOOLKIT_LIBW)
3236
3237 if test "$USE_X_TOOLKIT" = "none"; then
3238   LIBXT_OTHER="\$(LIBXSM)"
3239   OLDXMENU_TARGET="really-oldXMenu"
3240 else
3241   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3242   OLDXMENU_TARGET="really-lwlib"
3243 fi
3244 AC_SUBST(LIBXT_OTHER)
3245
3246 ## The X Menu stuff is present in the X10 distribution, but missing
3247 ## from X11.  If we have X10, just use the installed library;
3248 ## otherwise, use our own copy.
3249 if test "${HAVE_X11}" = "yes" ; then
3250   AC_DEFINE(HAVE_X11, 1,
3251             [Define to 1 if you want to use version 11 of X windows.
3252              Otherwise, Emacs expects to use version 10.])
3253
3254   if test "$USE_X_TOOLKIT" = "none"; then
3255     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3256   else
3257     OLDXMENU="\${lwlibdir}/liblw.a"
3258   fi
3259   LIBXMENU="\$(OLDXMENU)"
3260   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3261   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3262 else
3263   ## For a syntactically valid Makefile; not actually used for anything.
3264   ## See comments in src/Makefile.in.
3265   OLDXMENU=nothing
3266   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3267   if test "${HAVE_X_WINDOWS}" = "yes"; then
3268     LIBXMENU="-lXMenu"
3269   else
3270     LIBXMENU=
3271   fi
3272   LIBX_OTHER=
3273   OLDXMENU_DEPS=
3274 fi
3275
3276 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3277   OLDXMENU_TARGET=
3278   OLDXMENU=nothing
3279   LIBXMENU=
3280   OLDXMENU_DEPS=
3281 fi
3282
3283 AC_SUBST(OLDXMENU_TARGET)
3284 AC_SUBST(OLDXMENU)
3285 AC_SUBST(LIBXMENU)
3286 AC_SUBST(LIBX_OTHER)
3287 AC_SUBST(OLDXMENU_DEPS)
3288
3289 if test "${HAVE_MENUS}" = "yes" ; then
3290   AC_DEFINE(HAVE_MENUS, 1,
3291             [Define to 1 if you have mouse menus.
3292              (This is automatic if you use X, but the option to specify it remains.)
3293              It is also defined with other window systems that support xmenu.c.])
3294 fi
3295
3296 if test "${GNU_MALLOC}" = "yes" ; then
3297   AC_DEFINE(GNU_MALLOC, 1,
3298             [Define to 1 if you want to use the GNU memory allocator.])
3299 fi
3300
3301 RALLOC_OBJ=
3302 if test "${REL_ALLOC}" = "yes" ; then
3303   AC_DEFINE(REL_ALLOC, 1,
3304             [Define REL_ALLOC if you want to use the relocating allocator for
3305              buffer space.])
3306
3307   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3308 fi
3309 AC_SUBST(RALLOC_OBJ)
3310
3311 if test "$opsys" = "cygwin"; then
3312   CYGWIN_OBJ="sheap.o"
3313   ## Cygwin differs because of its unexec().
3314   PRE_ALLOC_OBJ=
3315   POST_ALLOC_OBJ=lastfile.o
3316 else
3317   CYGWIN_OBJ=
3318   PRE_ALLOC_OBJ=lastfile.o
3319   POST_ALLOC_OBJ=
3320 fi
3321 AC_SUBST(CYGWIN_OBJ)
3322 AC_SUBST(PRE_ALLOC_OBJ)
3323 AC_SUBST(POST_ALLOC_OBJ)
3324
3325
3326 case "$opsys" in
3327   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3328
3329   darwin)
3330    ## The -headerpad option tells ld (see man page) to leave room at the
3331    ## end of the header for adding load commands.  Needed for dumping.
3332    ## 0x690 is the total size of 30 segment load commands (at 56
3333    ## each); under Cocoa 31 commands are required.
3334    if test "$HAVE_NS" = "yes"; then
3335      libs_nsgui="-framework AppKit"
3336      headerpad_extra=6C8
3337    else
3338      libs_nsgui=
3339      headerpad_extra=690
3340    fi
3341    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3342
3343    ## This is here because src/Makefile.in did some extra fiddling around
3344    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3345    ##   #ifndef LD_SWITCH_SYSTEM
3346    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3347    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3348    ## not using gcc, darwin system not on an alpha (ie darwin, since
3349    ## darwin + alpha does not occur).
3350    ## Because this was done in src/Makefile.in, the resulting part of
3351    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3352    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3353    ## rather than LD_SWITCH_SYSTEM.
3354    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3355      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3356    ;;
3357
3358   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3359   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3360   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3361   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3362   ## had different values in configure (in ac_link) and src/Makefile.in.
3363   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3364   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3365
3366   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3367 esac
3368
3369 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3370   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3371 fi
3372
3373 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3374
3375
3376 LD_FIRSTFLAG=
3377 ORDINARY_LINK=
3378 case "$opsys" in
3379   ## gnu: GNU needs its own crt0.
3380   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3381
3382   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3383   ## library search parth, i.e. it won't search /usr/lib for libc and
3384   ## friends.  Using -nostartfiles instead avoids this problem, and
3385   ## will also work on earlier NetBSD releases.
3386   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3387
3388   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3389   ##   MkLinux/LinuxPPC needs this.
3390   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3391   gnu-*)
3392     case "$machine" in
3393       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3394     esac
3395     ;;
3396 esac
3397
3398
3399 if test "x$ORDINARY_LINK" = "xyes"; then
3400
3401   LD_FIRSTFLAG=""
3402   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3403
3404 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3405 ## freebsd, gnu-* not on macppc|ibms390x.
3406 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3407
3408   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3409   ## places that are difficult to figure out at make time.  Fortunately,
3410   ## these same versions allow you to pass arbitrary flags on to the
3411   ## linker, so there is no reason not to use it as a linker.
3412   ##
3413   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3414   ## searching for libraries in its internal directories, so we have to
3415   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3416   LD_FIRSTFLAG="-nostdlib"
3417 fi
3418
3419 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3420 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3421
3422 AC_SUBST(LD_FIRSTFLAG)
3423
3424
3425 ## FIXME? The logic here is not precisely the same as that above.
3426 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3427 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3428 LIB_GCC=
3429 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3430
3431   case "$opsys" in
3432     freebsd|netbsd|openbsd) LIB_GCC= ;;
3433
3434     gnu-*)
3435       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3436       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3437       ## Note that m/arm.h never bothered to undefine LIB_GCC first.
3438       if test "$machine" = "arm"; then
3439         LIB_GCC="-lgcc_s"
3440       else
3441         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3442         ## immediately undefine it again and redefine it to empty.
3443         ## Was the C_SWITCH_X_SITE part really necessary?
3444 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3445         LIB_GCC=
3446       fi
3447       ;;
3448
3449     ## Ask GCC where to find libgcc.a.
3450     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3451   esac
3452 fi                              dnl if $GCC
3453 AC_SUBST(LIB_GCC)
3454
3455
3456 TOOLTIP_SUPPORT=
3457 WINDOW_SUPPORT=
3458 ## If we're using X11/GNUstep, define some consequences.
3459 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3460   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3461   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3462   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3463   TOOLTIP_SUPPORT="\${lispsource}/mouse.elc"
3464
3465   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3466   test "$HAVE_X_WINDOWS" = "yes" && \
3467     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3468
3469 fi
3470 AC_SUBST(MOUSE_SUPPORT)
3471 AC_SUBST(TOOLTIP_SUPPORT)
3472 AC_SUBST(WINDOW_SUPPORT)
3473
3474
3475 AH_TOP([/* GNU Emacs site configuration template file.
3476    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3477      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3478
3479 This file is part of GNU Emacs.
3480
3481 GNU Emacs is free software: you can redistribute it and/or modify
3482 it under the terms of the GNU General Public License as published by
3483 the Free Software Foundation, either version 3 of the License, or
3484 (at your option) any later version.
3485
3486 GNU Emacs is distributed in the hope that it will be useful,
3487 but WITHOUT ANY WARRANTY; without even the implied warranty of
3488 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3489 GNU General Public License for more details.
3490
3491 You should have received a copy of the GNU General Public License
3492 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3493
3494
3495 /* No code in Emacs #includes config.h twice, but some bits of code
3496    intended to work with other packages as well (like gmalloc.c)
3497    think they can include it as many times as they like.  */
3498 #ifndef EMACS_CONFIG_H
3499 #define EMACS_CONFIG_H
3500 ])dnl
3501
3502 AH_BOTTOM([
3503 /* Define AMPERSAND_FULL_NAME if you use the convention
3504    that & in the full name stands for the login id.  */
3505 /* Turned on June 1996 supposing nobody will mind it.  */
3506 #define AMPERSAND_FULL_NAME
3507
3508 /* If using GNU, then support inline function declarations.  */
3509 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3510    generally, because even if non-gcc compilers accept `inline', they
3511    may reject `extern inline'.  */
3512 #if defined (__GNUC__) && defined (OPTIMIZE)
3513 #define INLINE __inline__
3514 #else
3515 #define INLINE
3516 #endif
3517
3518 /* `subprocesses' should be defined if you want to
3519    have code for asynchronous subprocesses
3520    (as used in M-x compile and M-x shell).
3521    Only MSDOS does not support this (it overrides
3522    this in its config_opsysfile below).  */
3523
3524 #define subprocesses
3525
3526 /* Include the os and machine dependent files.  */
3527 #include config_opsysfile
3528 #include config_machfile
3529
3530 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3531    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3532   (There is probably a better place to do this, but right now the
3533    Cocoa side does this in s/darwin.h and we cannot parallel this
3534    exactly since GNUstep is multi-OS.  */
3535 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3536 #  define SYSTEM_PURESIZE_EXTRA 30000
3537 #endif
3538
3539 /* SIGTYPE is the macro we actually use.  */
3540 #ifndef SIGTYPE
3541 #define SIGTYPE RETSIGTYPE
3542 #endif
3543
3544 #ifdef emacs /* Don't do this for lib-src.  */
3545 /* Tell regex.c to use a type compatible with Emacs.  */
3546 #define RE_TRANSLATE_TYPE Lisp_Object
3547 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3548 #ifdef make_number
3549 /* If make_number is a macro, use it.  */
3550 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3551 #else
3552 /* If make_number is a function, avoid it.  */
3553 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3554 #endif
3555 #endif
3556
3557 /* Avoid link-time collision with system mktime if we will use our own.  */
3558 #if ! HAVE_MKTIME || BROKEN_MKTIME
3559 #define mktime emacs_mktime
3560 #endif
3561
3562 #define my_strftime nstrftime   /* for strftime.c */
3563
3564 /* These default definitions are good for almost all machines.
3565    The exceptions override them in m/MACHINE.h.  */
3566
3567 #ifndef BITS_PER_CHAR
3568 #define BITS_PER_CHAR 8
3569 #endif
3570
3571 #ifndef BITS_PER_SHORT
3572 #define BITS_PER_SHORT 16
3573 #endif
3574
3575 /* Note that lisp.h uses this in a preprocessor conditional, so it
3576    would not work to use sizeof.  That being so, we do all of them
3577    without sizeof, for uniformity's sake.  */
3578 #ifndef BITS_PER_INT
3579 #define BITS_PER_INT 32
3580 #endif
3581
3582 #ifndef BITS_PER_LONG
3583 #ifdef _LP64
3584 #define BITS_PER_LONG 64
3585 #else
3586 #define BITS_PER_LONG 32
3587 #endif
3588 #endif
3589
3590 /* Define if the compiler supports function prototypes.  It may do so but
3591    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3592 #undef PROTOTYPES
3593
3594 #include <string.h>
3595 #include <stdlib.h>
3596
3597 #ifdef HAVE_ALLOCA_H
3598 # include <alloca.h>
3599 #elif defined __GNUC__
3600 # define alloca __builtin_alloca
3601 #elif defined _AIX
3602 # define alloca __alloca
3603 #else
3604 # include <stddef.h>
3605 # ifdef  __cplusplus
3606 extern "C"
3607 # endif
3608 void *alloca (size_t);
3609 #endif
3610
3611 #ifndef HAVE_SIZE_T
3612 typedef unsigned size_t;
3613 #endif
3614
3615 #ifndef HAVE_STRCHR
3616 #define strchr(a, b) index (a, b)
3617 #endif
3618
3619 #ifndef HAVE_STRRCHR
3620 #define strrchr(a, b) rindex (a, b)
3621 #endif
3622
3623 #if defined __GNUC__ && (__GNUC__ > 2 \
3624                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3625 #define NO_RETURN       __attribute__ ((__noreturn__))
3626 #else
3627 #define NO_RETURN       /* nothing */
3628 #endif
3629
3630 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3631 #define NO_INLINE __attribute__((noinline))
3632 #else
3633 #define NO_INLINE
3634 #endif
3635
3636 /* Some versions of GNU/Linux define noinline in their headers.  */
3637 #ifdef noinline
3638 #undef noinline
3639 #endif
3640
3641 /* These won't be used automatically yet.  We also need to know, at least,
3642    that the stack is continuous.  */
3643 #ifdef __GNUC__
3644 #  ifndef GC_SETJMP_WORKS
3645   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3646 #    define GC_SETJMP_WORKS 1
3647 #  endif
3648 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3649 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3650 #  endif
3651 #endif
3652
3653 #endif /* EMACS_CONFIG_H */
3654
3655 /*
3656 Local Variables:
3657 mode: c
3658 End:
3659 */
3660 ])dnl
3661
3662 #### Report on what we decided to do.
3663 #### Report GTK as a toolkit, even if it doesn't use Xt.
3664 #### It makes printing result more understandable as using GTK sets
3665 #### toolkit_scroll_bars to yes by default.
3666 if test "${HAVE_GTK}" = "yes"; then
3667   USE_X_TOOLKIT=GTK
3668 fi
3669
3670 echo "
3671 Configured for \`${canonical}'.
3672
3673   Where should the build process find the source code?    ${srcdir}
3674   What operating system and machine description files should Emacs use?
3675         \`${opsysfile}' and \`${machfile}'
3676   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3677   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3678   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3679   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3680   What window system should Emacs use?                    ${window_system}
3681   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3682
3683 if test -n "${x_includes}"; then
3684 echo "  Where do we find X Windows header files?                ${x_includes}"
3685 else
3686 echo "  Where do we find X Windows header files?                Standard dirs"
3687 fi
3688 if test -n "${x_libraries}"; then
3689 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3690 else
3691 echo "  Where do we find X Windows libraries?                   Standard dirs"
3692 fi
3693
3694 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3695 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3696 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3697 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3698 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3699 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3700 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3701 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3702
3703 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3704 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3705 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3706 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3707 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3708 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3709
3710 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3711 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3712 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3713 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3714
3715 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3716 echo
3717
3718 if test $USE_XASSERTS = yes; then
3719    echo "  Compiling with asserts turned on."
3720    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3721 fi
3722
3723 echo
3724
3725 if test "$HAVE_NS" = "yes"; then
3726    echo
3727    echo "You must run \"make install\" in order to test the built application.
3728 The installed application will go to nextstep/Emacs.app and can be
3729 run or moved from there."
3730    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3731       echo "The application will be fully self-contained."
3732     else
3733       echo "The lisp resources for the application will be installed under ${prefix}.
3734 You may need to run \"make install\" with sudo.  The application will fail
3735 to run if these resources are not installed."
3736    fi
3737    echo
3738 fi
3739
3740
3741 # Remove any trailing slashes in these variables.
3742 [test "${prefix}" != NONE &&
3743   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3744 test "${exec_prefix}" != NONE &&
3745   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3746
3747 dnl You might wonder (I did) why epaths.h is generated by running make,
3748 dnl rather than just letting configure generate it from epaths.in.
3749 dnl One reason is that the various paths are not fully expanded (see above);
3750 dnl eg gamedir=${prefix}/var/games/emacs.
3751 dnl Secondly, the GNU Coding standards require that one should be able
3752 dnl to run `make prefix=/some/where/else' and override the values set
3753 dnl by configure.  This also explains the `move-if-change' test and
3754 dnl the use of force in the `epaths-force' rule in Makefile.in.
3755 AC_OUTPUT(Makefile lib-src/Makefile oldXMenu/Makefile \
3756         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3757         doc/lispref/Makefile src/Makefile \
3758         lwlib/Makefile lisp/Makefile leim/Makefile, [
3759
3760 ### Make the necessary directories, if they don't exist.
3761 for dir in etc lisp ; do
3762   test -d ${dir} || mkdir ${dir}
3763 done
3764
3765 echo creating src/epaths.h
3766 ${MAKE-make} epaths-force
3767
3768 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3769   echo creating src/.gdbinit
3770   echo source $srcdir/src/.gdbinit > src/.gdbinit
3771 fi
3772
3773 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3774