code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the 'configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2016 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 25.1.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in "$@" CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140
 141 case $host in
 142  *-mingw*)
 143
 144   if test -z "$host_alias"; then
 145
 146       # No --host argument was given to 'configure'; therefore $host
 147       # was set to a default value based on the build platform.  But
 148       # this default value may be wrong if we are building from a
 149       # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
 150       # Therefore, we'll try to get the right host platform from the
 151       # compiler's target.
 152
 153       AC_MSG_CHECKING([the compiler's target])
 154       if test -z "$CC"; then
 155           cc=gcc
 156       else
 157           cc=$CC
 158       fi
 159       cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
 160       case "$cc_target" in
 161           *-*) host=$cc_target
 162               ;;
 163           "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
 164 Please explicitly provide --host.])
 165               ;;
 166           *) AC_MSG_WARN([Compiler reported non-standard target.
 167 Defaulting to $host.])
 168               ;;
 169       esac
 170       AC_MSG_RESULT([$host])
 171   fi
 172
 173   . $srcdir/nt/mingw-cfg.site
 174
 175   case $srcdir in
 176     /* | ?:*)
 177       # srcdir is an absolute path.  In this case, force the format
 178       # "/c/foo/bar", to simplify later conversions to native Windows
 179       # format ("c:/foo/bar").
 180       srcdir=`cd "${srcdir}" && pwd -W`
 181       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
 182       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
 183       ;;
 184   esac;;
 185 esac
 186
 187 canonical=$host
 188 configuration=${host_alias-${build_alias-$host}}
 189
 190 dnl Support for --program-prefix, --program-suffix and
 191 dnl --program-transform-name options
 192 AC_ARG_PROGRAM
 193
 194 dnl It is important that variables on the RHS not be expanded here,
 195 dnl hence the single quotes.  This is per the GNU coding standards, see
 196 dnl (autoconf) Installation Directory Variables
 197 dnl See also epaths.h below.
 198 lispdir='${datadir}/emacs/${version}/lisp'
 199 standardlisppath='${lispdir}'
 200 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 201 '${datadir}/emacs/site-lisp'
 202 lisppath='${locallisppath}:${standardlisppath}'
 203 etcdir='${datadir}/emacs/${version}/etc'
 204 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 205 etcdocdir='${datadir}/emacs/${version}/etc'
 206 gamedir='${localstatedir}/games/emacs'
 207
 208 dnl Special option to disable the most of other options.
 209 AC_ARG_WITH(all,
 210 [AS_HELP_STRING([--without-all],
 211                 [omit almost all features and build
 212                 small executable with minimal dependencies])],
 213   [with_features=$withval],
 214   [with_features=yes])
 215
 216 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 217 dnl Create a new --with option that defaults to being disabled.
 218 dnl NAME is the base name of the option.  The shell variable with_NAME
 219 dnl   will be set to either the user's value (if the option is
 220 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 221 dnl   option is not specified).  Note that the shell variable name is
 222 dnl   constructed as autoconf does, by replacing non-alphanumeric
 223 dnl   characters with "_".
 224 dnl HELP-STRING is the help text for the option.
 225 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 226   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 227     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 228 ])dnl
 229
 230 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 231 dnl Create a new --with option that defaults to $with_features.
 232 dnl NAME is the base name of the option.  The shell variable with_NAME
 233 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 234 dnl   'yes' (if the option is not specified).  Note that the shell
 235 dnl   variable name is constructed as autoconf does, by replacing
 236 dnl   non-alphanumeric characters with "_".
 237 dnl HELP-STRING is the help text for the option.
 238 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 239   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 240    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 241 ])dnl
 242
 243 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 244 if test "$with_pop" = yes; then
 245    AC_DEFINE(MAIL_USE_POP)
 246 fi
 247 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 248
 249 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 250 if test "$with_kerberos" != no; then
 251    AC_DEFINE(KERBEROS)
 252 fi
 253 AH_TEMPLATE(KERBEROS,
 254             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 255
 256 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 257 if test "${with_kerberos5}" != no; then
 258   if test "${with_kerberos}" = no; then
 259     with_kerberos=yes
 260     AC_DEFINE(KERBEROS)
 261   fi
 262   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 263 fi
 264
 265 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 266 dnl FIXME hesiod support may not be present, so it seems like an error
 267 dnl to define, or at least use, this unconditionally.
 268 if test "$with_hesiod" != no; then
 269   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 270 fi
 271
 272 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 273 if test "$with_mail_unlink" != no; then
 274    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 275 fi
 276
 277 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 278     [string giving default POP mail host])],
 279     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 280
 281 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 282   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 283 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
 284   [ case "${withval}" in
 285       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 286       *) AC_MSG_ERROR(['--with-sound=$withval' is invalid;
 287 this option's value should be 'yes', 'no', 'alsa', 'oss', or 'bsd-ossaudio'.])
 288       ;;
 289     esac
 290     with_sound=$val
 291   ],
 292   [with_sound=$with_features])
 293
 294 dnl FIXME currently it is not the last.
 295 dnl This should be the last --with option, because --with-x is
 296 dnl added later on when we find the file name of X, and it's best to
 297 dnl keep them together visually.
 298 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 299  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 300 [         case "${withval}" in
 301             y | ye | yes )      val=gtk ;;
 302             n | no )            val=no  ;;
 303             l | lu | luc | luci | lucid )       val=lucid ;;
 304             a | at | ath | athe | athen | athena )      val=athena ;;
 305             m | mo | mot | moti | motif )       val=motif ;;
 306             g | gt | gtk  )     val=gtk ;;
 307             gtk2  )     val=gtk2 ;;
 308             gtk3  )     val=gtk3 ;;
 309             * )
 310 AC_MSG_ERROR(['--with-x-toolkit=$withval' is invalid;
 311 this option's value should be 'yes', 'no', 'lucid', 'athena', 'motif', 'gtk',
 312 'gtk2' or 'gtk3'.  'yes' and 'gtk' are synonyms.
 313 'athena' and 'lucid' are synonyms.])
 314             ;;
 315           esac
 316           with_x_toolkit=$val
 317 ])
 318
 319 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit); allows buffer and string size up to 2GB on 32-bit hosts, at the cost of 10% to 30% slowdown of Lisp interpreter and larger memory footprint])
 320 if test "$with_wide_int" = yes; then
 321   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 322 fi
 323
 324 dnl _ON results in a '--without' option in the --help output, so
 325 dnl the help text should refer to "don't compile", etc.
 326 with_xpm_set=${with_xpm+set}
 327 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 328 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 329 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 330 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 331 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 332 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 333 OPTION_DEFAULT_OFF([cairo],[compile with Cairo drawing (experimental)])
 334 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 335 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 336
 337 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 338 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 339 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 340
 341 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 342 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 343 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 344 AC_ARG_WITH([ns],[AS_HELP_STRING([--with-ns],
 345 [use Nextstep (OS X Cocoa or GNUstep) windowing system.
 346 On by default on Mac OS X.])],[],[with_ns=maybe])
 347 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 348
 349 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 350 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 351 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 352 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 353 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 354 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 355 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 356 OPTION_DEFAULT_OFF([modules],[compile with dynamic modules support])
 357
 358 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 359  [use a file notification library (LIB one of: yes, inotify, kqueue, gfile, w32, no)])],
 360  [ case "${withval}" in
 361     y | ye | yes )      val=yes ;;
 362     n | no )            val=no  ;;
 363     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 364     k | kq | kqu | kque | kqueu | kqueue )      val=kqueue ;;
 365     g | gf | gfi | gfil | gfile )       val=gfile ;;
 366     w | w3 | w32 )      val=w32 ;;
 367     * ) AC_MSG_ERROR(['--with-file-notification=$withval' is invalid;
 368 this option's value should be 'yes', 'no', 'inotify', 'kqueue', 'gfile' or 'w32'.
 369 'yes' is a synonym for 'w32' on MS-Windows, for 'no' on Nextstep,
 370 otherwise for the first of 'inotify', 'kqueue' or 'gfile' that is usable.])
 371     ;;
 372    esac
 373    with_file_notification=$val
 374  ],
 375  [with_file_notification=$with_features])
 376
 377 OPTION_DEFAULT_OFF([xwidgets],
 378   [enable use of some gtk widgets in Emacs buffers (requires gtk3)])
 379
 380 ## For the times when you want to build Emacs but don't have
 381 ## a suitable makeinfo, and can live without the manuals.
 382 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 383 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 384
 385 ## This might be a 'configure' arg.
 386 AC_SUBST([ACLOCAL_PATH])
 387
 388 ## Makefile.in needs the cache file name.
 389 AC_SUBST(cache_file)
 390
 391 ## This is an option because I do not know if all info/man support
 392 ## compressed files, nor how to test if they do so.
 393 OPTION_DEFAULT_ON([compress-install],
 394   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 395 make GZIP_PROG= install])
 396
 397 AC_ARG_WITH(gameuser,dnl
 398 [AS_HELP_STRING([--with-gameuser=USER_OR_GROUP],
 399                 [user for shared game score files.
 400                 An argument prefixed by ':' specifies a group instead.])])
 401 gameuser=
 402 gamegroup=
 403 # We don't test if we can actually chown/chgrp here, because configure
 404 # may run without root privileges.  lib-src/Makefile.in will handle
 405 # any errors due to missing user/group gracefully.
 406 case ${with_gameuser} in
 407   no) ;;
 408   "" | yes) gamegroup=games ;;
 409   :*) gamegroup=${with_gameuser#:} ;;
 410   *) gameuser=${with_gameuser} ;;
 411 esac
 412
 413 AC_ARG_WITH([gnustep-conf],dnl
 414 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 415    [name of GNUstep configuration file to use on systems where the command
 416     'gnustep-config' does not work; default $GNUSTEP_CONFIG_FILE, or
 417     /etc/GNUstep/GNUstep.conf])])
 418 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 419   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 420 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 421      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 422
 423 AC_ARG_ENABLE(ns-self-contained,
 424 [AS_HELP_STRING([--disable-ns-self-contained],
 425                 [disable self contained build under NeXTstep])],
 426    EN_NS_SELF_CONTAINED=$enableval,
 427    EN_NS_SELF_CONTAINED=yes)
 428
 429 locallisppathset=no
 430 AC_ARG_ENABLE(locallisppath,
 431 [AS_HELP_STRING([--enable-locallisppath=PATH],
 432                 [directories Emacs should search for lisp files specific
 433                  to this site])],
 434 if test "${enableval}" = "no"; then
 435   locallisppath=
 436 elif test "${enableval}" != "yes"; then
 437   locallisppath=${enableval} locallisppathset=yes
 438 fi)
 439
 440 AC_ARG_ENABLE(checking,
 441 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 442                 [enable expensive run-time checks.  With LIST,
 443                  enable only specific categories of checks.
 444                  Categories are: all,yes,no.
 445                  Flags are: stringbytes, stringoverrun, stringfreelist,
 446                  xmallocoverrun, conslist, glyphs])],
 447 [ac_checking_flags="${enableval}"],[])
 448 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 449 for check in $ac_checking_flags
 450 do
 451         case $check in
 452         # these set all the flags to specific states
 453         yes)            ac_enable_checking=1 ;;
 454         no)             ac_enable_checking= ;
 455                         ac_gc_check_stringbytes= ;
 456                         ac_gc_check_string_overrun= ;
 457                         ac_gc_check_string_free_list= ;
 458                         ac_xmalloc_overrun= ;
 459                         ac_gc_check_cons_list= ;
 460                         ac_glyphs_debug= ;;
 461         all)            ac_enable_checking=1 ;
 462                         ac_gc_check_stringbytes=1 ;
 463                         ac_gc_check_string_overrun=1 ;
 464                         ac_gc_check_string_free_list=1 ;
 465                         ac_xmalloc_overrun=1 ;
 466                         ac_gc_check_cons_list=1 ;
 467                         ac_glyphs_debug=1 ;;
 468         # these enable particular checks
 469         stringbytes)    ac_gc_check_stringbytes=1 ;;
 470         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 471         stringfreelist) ac_gc_check_string_free_list=1 ;;
 472         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 473         conslist)       ac_gc_check_cons_list=1 ;;
 474         glyphs)         ac_glyphs_debug=1 ;;
 475         *)      AC_MSG_ERROR(unknown check category $check) ;;
 476         esac
 477 done
 478 IFS="$ac_save_IFS"
 479
 480 if test x$ac_enable_checking != x ; then
 481   AC_DEFINE(ENABLE_CHECKING, 1,
 482 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 483 fi
 484 if test x$ac_gc_check_stringbytes != x ; then
 485   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 486 [Define this temporarily to hunt a bug.  If defined, the size of
 487    strings is redundantly recorded in sdata structures so that it can
 488    be compared to the sizes recorded in Lisp strings.])
 489 fi
 490 if test x$ac_gc_check_string_overrun != x ; then
 491   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 492 [Define this to check for short string overrun.])
 493 fi
 494 if test x$ac_gc_check_string_free_list != x ; then
 495   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 496 [Define this to check the string free list.])
 497 fi
 498 if test x$ac_xmalloc_overrun != x ; then
 499   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 500 [Define this to check for malloc buffer overrun.])
 501 fi
 502 if test x$ac_gc_check_cons_list != x ; then
 503   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 504 [Define this to check for errors in cons list.])
 505 fi
 506 if test x$ac_glyphs_debug != x ; then
 507   AC_DEFINE(GLYPH_DEBUG, 1,
 508 [Define this to enable glyphs debugging code.])
 509 fi
 510
 511 AC_ARG_ENABLE(check-lisp-object-type,
 512 [AS_HELP_STRING([--enable-check-lisp-object-type],
 513                 [enable compile time checks for the Lisp_Object data type.
 514                 This is useful for development for catching certain types of bugs.])],
 515 if test "${enableval}" != "no"; then
 516    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 517    [Define this to enable compile time checks for the Lisp_Object data type.])
 518 fi)
 519
 520
 521 dnl The name of this option is unfortunate.  It predates, and has no
 522 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 523 dnl Actually, it stops it working.
 524 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 525 AC_ARG_ENABLE(profiling,
 526 [AS_HELP_STRING([--enable-profiling],
 527                 [build emacs with low-level, gprof profiling support.
 528                 Mainly useful for debugging Emacs itself.  May not work on
 529                 all platforms.  Stops profiler.el working.])],
 530 [ac_enable_profiling="${enableval}"],[])
 531 if test x$ac_enable_profiling != x ; then
 532    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 533 else
 534    PROFILING_CFLAGS=
 535 fi
 536 AC_SUBST(PROFILING_CFLAGS)
 537
 538 AC_ARG_ENABLE(autodepend,
 539 [AS_HELP_STRING([--enable-autodepend],
 540                 [automatically generate dependencies to .h-files.
 541                  Requires gcc, enabled if found.])],
 542 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 543
 544 AC_ARG_ENABLE(gtk-deprecation-warnings,
 545 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 546                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 547 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 548
 549 dnl This used to use changequote, but, apart from 'changequote is evil'
 550 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 551 dnl the great gob of text.  Thus it's not processed for possible expansion.
 552 dnl Just make sure the brackets remain balanced.
 553 dnl
 554 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 555 dnl indicated by comments.
 556 dnl quotation begins
 557 [
 558
 559 ### If you add support for a new configuration, add code to this
 560 ### switch statement to recognize your configuration name and select
 561 ### the appropriate opsys.
 562
 563 ### As far as handling version numbers on operating systems is
 564 ### concerned, make sure things will fail in a fixable way.  If
 565 ### /etc/MACHINES doesn't say anything about version numbers, be
 566 ### prepared to handle anything reasonably.  If version numbers
 567 ### matter, be sure /etc/MACHINES says something about it.
 568
 569 opsys='' unported=no
 570 case "${canonical}" in
 571
 572   ## GNU/Linux and similar ports
 573   *-*-linux* )
 574     opsys=gnu-linux
 575   ;;
 576
 577   ## FreeBSD ports
 578   *-*-freebsd* )
 579     opsys=freebsd
 580   ;;
 581
 582   ## DragonFly ports
 583   *-*-dragonfly* )
 584     opsys=dragonfly
 585   ;;
 586
 587   ## FreeBSD kernel + glibc based userland
 588   *-*-kfreebsd*gnu* )
 589     opsys=gnu-kfreebsd
 590   ;;
 591
 592   ## NetBSD ports
 593   *-*-netbsd* )
 594     opsys=netbsd
 595   ;;
 596
 597   ## OpenBSD ports
 598   *-*-openbsd* | *-*-mirbsd* )
 599     opsys=openbsd
 600   ;;
 601
 602   ## Apple Darwin / Mac OS X
 603   *-apple-darwin* )
 604     case "${canonical}" in
 605       *-apple-darwin[0-9].*) unported=yes ;;
 606       i[3456]86-* | x86_64-* )  ;;
 607       * )            unported=yes ;;
 608     esac
 609     opsys=darwin
 610     ## Use fink packages if available.
 611     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 612 ##    if test -d /sw/include && test -d /sw/lib; then
 613 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 614 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 615 ##    fi
 616   ;;
 617
 618   ## Chromium Native Client
 619   *-nacl )
 620     opsys=nacl
 621   ;;
 622
 623   ## Cygwin ports
 624   *-*-cygwin )
 625     opsys=cygwin
 626   ;;
 627
 628   ## HP 9000 series 700 and 800, running HP/UX
 629   hppa*-hp-hpux10.2* )
 630     opsys=hpux10-20
 631   ;;
 632   hppa*-hp-hpux1[1-9]* )
 633     opsys=hpux11
 634     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 635   ;;
 636
 637   ## IBM machines
 638   rs6000-ibm-aix4.[23]* )
 639     opsys=aix4-2
 640   ;;
 641   powerpc-ibm-aix4.[23]*  )
 642     opsys=aix4-2
 643   ;;
 644   rs6000-ibm-aix[56]* )
 645     opsys=aix4-2
 646   ;;
 647   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 648     opsys=aix4-2
 649   ;;
 650
 651   ## Silicon Graphics machines
 652   ## Iris 4D
 653   mips-sgi-irix6.5 )
 654     opsys=irix6-5
 655     # Without defining _LANGUAGE_C, things get masked out in the headers
 656     # so that, for instance, grepping for 'free' in stdlib.h fails and
 657     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 658     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 659   ;;
 660
 661   ## Suns
 662   *-sun-solaris* \
 663     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 664     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 665     case "${canonical}" in
 666       i[3456]86-*-* )   ;;
 667       amd64-*-*|x86_64-*-*) ;;
 668       sparc* )          ;;
 669       * )               unported=yes ;;
 670     esac
 671     case "${canonical}" in
 672       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 673                 opsys=sol2-10
 674                 emacs_check_sunpro_c=yes
 675                 ;;
 676       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 677       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 678       *-sunos5.6* | *-solaris2.6* )
 679                 opsys=sol2-6
 680                 RANLIB="ar -ts"
 681                 ;;
 682       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 683       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 684                 opsys=sol2-6
 685                 emacs_check_sunpro_c=yes
 686                 ;;
 687     esac
 688     ## Watch out for a compiler that we know will not work.
 689     case "${canonical}" in
 690      *-solaris* | *-sunos5* )
 691                 if [ "x$CC" = x/usr/ucb/cc ]; then
 692                   ## /usr/ucb/cc doesn't work;
 693                   ## we should find some other compiler that does work.
 694                   unset CC
 695                 fi
 696                 ;;
 697       *) ;;
 698     esac
 699   ;;
 700
 701   ## Intel 386 machines where we don't care about the manufacturer.
 702   i[3456]86-*-* )
 703     case "${canonical}" in
 704       *-darwin* )               opsys=darwin ;;
 705       *-mingw* )
 706                 opsys=mingw32
 707                 # MinGW overrides and adds some system headers in nt/inc.
 708                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 709                 ;;
 710       *-sysv4.2uw* )            opsys=unixware ;;
 711       *-sysv5uw* )              opsys=unixware ;;
 712       *-sysv5OpenUNIX* )        opsys=unixware ;;
 713       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 714     esac
 715   ;;
 716
 717   # MinGW64
 718   x86_64-*-* )
 719     case "${canonical}" in
 720       *-mingw* )
 721                 opsys=mingw32
 722                 # MinGW overrides and adds some system headers in nt/inc.
 723                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 724                 ;;
 725       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 726     esac
 727   ;;
 728
 729   * )
 730     unported=yes
 731   ;;
 732 esac
 733
 734 ### If the code above didn't choose an operating system, just choose
 735 ### an operating system based on the configuration name.  You really
 736 ### only want to use this when you have no idea what the right
 737 ### operating system is; if you know what operating systems a machine
 738 ### runs, it's cleaner to make it explicit in the case statement
 739 ### above.
 740 if test x"${opsys}" = x; then
 741   case "${canonical}" in
 742     *-gnu* )                            opsys=gnu ;;
 743     * )
 744       unported=yes
 745     ;;
 746   esac
 747 fi
 748
 749 ]
 750 dnl quotation ends
 751
 752 if test $unported = yes; then
 753   AC_MSG_ERROR([Emacs does not support '${canonical}' systems.
 754 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 755 Check 'etc/MACHINES' for recognized configuration names.])
 756 fi
 757
 758 #### Choose a compiler.
 759
 760 dnl Don't bother to test for C89.
 761 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 762
 763 dnl Sets GCC=yes if using gcc.
 764 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 765 if test -n "$XCRUN"; then
 766   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 767   test -n "$AR" && export AR
 768 fi
 769
 770 dnl Emacs needs C99 or later.
 771 gl_PROG_CC_C99
 772
 773 AM_PROG_CC_C_O
 774
 775 if test x$GCC = xyes; then
 776   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 777 else
 778   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 779 fi
 780
 781 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 782 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 783 dnl that clash with MinGW.
 784 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 785
 786 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 787 AC_DEFUN([gl_CRYPTO_CHECK])
 788 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 789 # as we don't use them.
 790 AC_DEFUN([gl_FCNTL_O_FLAGS])
 791 # Avoid gnulib's test for pthread_sigmask.
 792 funcs=
 793 for func in $ac_func_list; do
 794   test $func = pthread_sigmask || AS_VAR_APPEND([funcs], [" $func"])
 795 done
 796 ac_func_list=$funcs
 797 # Use the system putenv even if it lacks GNU features, as we don't need them,
 798 # and the gnulib replacement runs afoul of a FreeBSD 10.1 bug; see Bug#19874.
 799 AC_CHECK_FUNCS_ONCE([putenv])
 800 AC_DEFUN([gl_FUNC_PUTENV],
 801   [test "$ac_cv_func_putenv" = yes || REPLACE_PUTENV=1])
 802
 803 # Initialize gnulib right after choosing the compiler.
 804 dnl Amongst other things, this sets AR and ARFLAGS.
 805 gl_EARLY
 806
 807 if test "$ac_test_CFLAGS" != set; then
 808   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 809   # if -g3 works and the user does not specify CFLAGS.
 810   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 811   case $CFLAGS in
 812     '-g')
 813       emacs_g3_CFLAGS='-g3';;
 814     '-g -O2')
 815       emacs_g3_CFLAGS='-g3 -O2';;
 816     *)
 817       emacs_g3_CFLAGS='';;
 818   esac
 819   if test -n "$emacs_g3_CFLAGS"; then
 820     emacs_save_CFLAGS=$CFLAGS
 821     CFLAGS=$emacs_g3_CFLAGS
 822     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 823       [emacs_cv_prog_cc_g3],
 824       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 825          [emacs_cv_prog_cc_g3=yes],
 826          [emacs_cv_prog_cc_g3=no])])
 827     if test $emacs_cv_prog_cc_g3 != yes; then
 828       CFLAGS=$emacs_save_CFLAGS
 829     fi
 830     if test $opsys = mingw32; then
 831       CFLAGS="$CFLAGS -gdwarf-2"
 832     fi
 833   fi
 834
 835   case $CFLAGS in
 836     *-O*) ;;
 837     *)
 838       # No optimization flag was inferred for this non-GCC compiler.
 839       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 840       emacs_save_CFLAGS=$CFLAGS
 841       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 842       CFLAGS=${CFLAGS}-O
 843       AC_CACHE_CHECK([whether $CC accepts -O],
 844         [emacs_cv_prog_cc_o],
 845         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 846            [emacs_cv_prog_cc_o=yes],
 847            [emacs_cv_prog_cc_o=no])])
 848       if test $emacs_cv_prog_cc_o != yes; then
 849         CFLAGS=$emacs_save_CFLAGS
 850       fi ;;
 851   esac
 852 fi
 853
 854 AC_ARG_ENABLE([gcc-warnings],
 855   [AS_HELP_STRING([--enable-gcc-warnings],
 856                   [turn on lots of GCC warnings/errors. This is intended for
 857                    developers, and may generate false alarms when used
 858                    with older or non-GNU development tools.])],
 859   [case $enableval in
 860      yes|no) ;;
 861      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 862    esac
 863    gl_gcc_warnings=$enableval],
 864   [gl_gcc_warnings=no]
 865 )
 866
 867 # clang is unduly picky about some things.
 868 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 869   [AC_COMPILE_IFELSE(
 870      [AC_LANG_PROGRAM([[
 871           #ifndef __clang__
 872             error "not clang";
 873           #endif
 874         ]])],
 875      [emacs_cv_clang=yes],
 876      [emacs_cv_clang=no])])
 877
 878 # When compiling with GCC, prefer -isystem to -I when including system
 879 # include files, to avoid generating useless diagnostics for the files.
 880 if test "$gl_gcc_warnings" != yes; then
 881   isystem='-I'
 882   if test "$emacs_cv_clang" = yes
 883   then
 884      # Turn off some warnings if supported.
 885      gl_WARN_ADD([-Wno-switch])
 886      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 887      gl_WARN_ADD([-Wno-pointer-sign])
 888      gl_WARN_ADD([-Wno-string-plus-int])
 889      gl_WARN_ADD([-Wno-unknown-attributes])
 890   fi
 891 else
 892   isystem='-isystem '
 893
 894   # This, $nw, is the list of warnings we disable.
 895   nw=
 896
 897   case $with_x_toolkit in
 898     lucid | athena | motif)
 899        # Old toolkits mishandle 'const'.
 900        nw="$nw -Wwrite-strings"
 901        ;;
 902     *)
 903        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 904        ;;
 905   esac
 906   AC_SUBST([WERROR_CFLAGS])
 907
 908   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 909   nw="$nw -Woverlength-strings"     # Not a problem these days
 910   nw="$nw -Wformat-nonliteral"      # we do this a lot
 911   nw="$nw -Wvla"                    # Emacs uses <vla.h>.
 912   nw="$nw -Wswitch-default"         # Too many warnings for now
 913   nw="$nw -Winline"                 # OK to ignore 'inline'
 914   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 915   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 916                                     # signed overflow has undefined behavior
 917   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 918   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 919   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 920
 921   # Emacs doesn't care about shadowing; see
 922   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 923   nw="$nw -Wshadow"
 924
 925   # Emacs's use of alloca inhibits protecting the stack.
 926   nw="$nw -Wstack-protector"
 927
 928   # Emacs's use of partly-const functions such as Fgnutls_available_p
 929   # make this option problematic.
 930   nw="$nw -Wsuggest-attribute=const"
 931
 932   # Emacs's use of partly-pure functions such as CHECK_TYPE make this
 933   # option problematic.
 934   nw="$nw -Wsuggest-attribute=pure"
 935
 936   # This part is merely for shortening the command line,
 937   # since -Wall implies -Wswitch.
 938   nw="$nw -Wswitch"
 939
 940   # This part is merely for shortening the command line,
 941   # since -Wno-FOO needs to be added below regardless.
 942   nw="$nw -Wmissing-field-initializers"
 943   nw="$nw -Wtype-limits"
 944   nw="$nw -Wunused-parameter"
 945
 946   if test $emacs_cv_clang = yes; then
 947     nw="$nw -Wcast-align"
 948   fi
 949
 950   gl_MANYWARN_ALL_GCC([ws])
 951   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 952   for w in $ws; do
 953     gl_WARN_ADD([$w])
 954   done
 955   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 956   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 957   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 958   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 959   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 960   gl_WARN_ADD([-Wno-format-nonliteral])
 961
 962   # More things that clang is unduly picky about.
 963   if test $emacs_cv_clang = yes; then
 964     gl_WARN_ADD([-Wno-format-extra-args])
 965     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 966     gl_WARN_ADD([-Wno-unused-command-line-argument])
 967     gl_WARN_ADD([-Wno-unused-value])
 968   fi
 969
 970   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 971   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 972   AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
 973   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 974       without upsetting glibc 2.15+. */
 975    #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
 976         && defined __OPTIMIZE__ && __OPTIMIZE__)
 977    # define _FORTIFY_SOURCE 2
 978    #endif
 979   ])
 980
 981   # We use a slightly smaller set of warning options for lib/.
 982   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 983   nw=
 984   nw="$nw -Wunused-macros"
 985
 986   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 987   AC_SUBST([GNULIB_WARN_CFLAGS])
 988 fi
 989
 990 edit_cflags="
 991   s,///*,/,g
 992   s/^/ /
 993   s/ -I/ $isystem/g
 994   s/^ //
 995 "
 996
 997 AC_ARG_ENABLE(link-time-optimization,
 998 [AS_HELP_STRING([--enable-link-time-optimization],
 999                 [build emacs with link-time optimization.
1000                  This requires GCC 4.5.0 or later, or clang.
1001                  (Note that clang support is experimental - see INSTALL.)
1002                  It also makes Emacs harder to debug, and when we tried it
1003                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
1004                  recommended for typical use.])],
1005 if test "${enableval}" != "no"; then
1006    ac_lto_supported=no
1007    if test $emacs_cv_clang = yes; then
1008       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
1009       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
1010       if test -x "$GOLD_PLUGIN"; then
1011          LTO="-flto"
1012       fi
1013    elif test x$GCC = xyes; then
1014       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
1015       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
1016       if test x$CPUS != x; then
1017          LTO="-flto=$CPUS"
1018       else
1019          LTO="-flto"
1020       fi
1021    else
1022       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
1023    fi
1024    if test -z "$LTO"; then
1025       ac_lto_supported=no
1026    else
1027       old_CFLAGS=$CFLAGS
1028       CFLAGS="$CFLAGS $LTO"
1029       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1030          [ac_lto_supported=yes], [ac_lto_supported=no])
1031          CFLAGS="$old_CFLAGS"
1032    fi
1033    AC_MSG_RESULT([$ac_lto_supported])
1034    if test "$ac_lto_supported" = "yes"; then
1035       CFLAGS="$CFLAGS $LTO"
1036       if test x$emacs_cv_clang = xyes; then
1037          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
1038          # WARNING: 'ar --plugin ...' doesn't work without
1039          # command, so plugin name is appended to ARFLAGS.
1040          ARFLAGS="cru --plugin $GOLD_PLUGIN"
1041          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
1042       else
1043         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
1044         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
1045         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
1046         dnl dump core on Fedora 20, so play it safe for now.
1047         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
1048           [CFLAGS="$CFLAGS -ffat-lto-objects"])
1049       fi
1050    fi
1051 fi)
1052
1053 dnl Prefer silent make output.  For verbose output, use
1054 dnl 'configure --disable-silent-rules' or 'make V=1' .
1055 AM_SILENT_RULES([yes])
1056 dnl Port to Automake 1.11.
1057 dnl This section can be removed once we assume Automake 1.14 or later.
1058 : ${AM_V=$AM_DEFAULT_VERBOSITY}
1059 : ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
1060 AC_SUBST([AM_V])
1061 AM_SUBST_NOTMAKE([AM_V])
1062 AC_SUBST([AM_DEFAULT_V])
1063 AM_SUBST_NOTMAKE([AM_DEFAULT_V])
1064 AC_SUBST([AM_DEFAULT_VERBOSITY])
1065
1066 dnl Some other nice autoconf tests.
1067 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
1068 dnl AC_PROG_INSTALL
1069 dnl AC_PROG_MKDIR_P
1070 dnl if test "x$RANLIB" = x; then
1071 dnl   AC_PROG_RANLIB
1072 dnl fi
1073
1074
1075 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
1076 dnl can be made to directories.  This is not relevant for our usage, and
1077 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1078 dnl hosted on AFS, both examples where simple links work, but links to
1079 dnl directories fail.  We use a cut-down version instead.
1080 dnl AC_PROG_LN_S
1081
1082 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1083 rm -f conf$$ conf$$.file
1084
1085 LN_S_FILEONLY='cp -p'
1086
1087 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1088 dnl random program in the current directory.
1089 if (echo >conf$$.file) 2>/dev/null; then
1090   if ln -s conf$$.file conf$$ 2>/dev/null; then
1091     if test "$opsys" = "mingw32"; then
1092       LN_S_FILEONLY='/bin/ln -s'
1093     else
1094       LN_S_FILEONLY='ln -s'
1095     fi
1096   elif ln conf$$.file conf$$ 2>/dev/null; then
1097     if test "$opsys" = "mingw32"; then
1098       LN_S_FILEONLY=/bin/ln
1099     else
1100       LN_S_FILEONLY=ln
1101     fi
1102   fi
1103 fi
1104
1105 rm -f conf$$ conf$$.file
1106
1107 if test "$LN_S_FILEONLY" = "ln -s"; then
1108    AC_MSG_RESULT([yes])
1109 else
1110    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1111 fi
1112
1113 AC_SUBST(LN_S_FILEONLY)
1114
1115
1116 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1117 dnl doesn't support links to directories, as in "ln file dir".  But that
1118 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1119 dnl executables at "make install" time.
1120 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1121 dnl for more details.
1122 if test "$opsys" = "mingw32"; then
1123   LN_S="/bin/ln"
1124 fi
1125
1126 dnl On some Debian versions, "install-info" prints irritating messages
1127 dnl "This is not dpkg install-info anymore, but GNU install-info"
1128 dnl if called via an absolute file name.
1129 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1130 dnl Sadly some people may have an old ginstall-info installed on
1131 dnl non-Debian systems, so we can't use this.
1132 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1133 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1134
1135 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1136   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1137 dnl Don't use GZIP, which is used by gzip for additional parameters.
1138 AC_PATH_PROG(GZIP_PROG, gzip)
1139
1140 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1141    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1142
1143 if test $opsys = gnu-linux; then
1144   AC_PATH_PROG(PAXCTL, paxctl,,
1145     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1146   if test "X$PAXCTL" != X; then
1147     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1148     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1149       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
1150       else AC_MSG_RESULT(no); PAXCTL=""; fi])
1151   fi
1152
1153   if test "${SETFATTR+set}" != set; then
1154     AC_CACHE_CHECK([for setfattr],
1155       [emacs_cv_prog_setfattr],
1156       [touch conftest.tmp
1157        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1158          emacs_cv_prog_setfattr=yes
1159        else
1160          emacs_cv_prog_setfattr=no
1161        fi])
1162     if test "$emacs_cv_prog_setfattr" = yes; then
1163       SETFATTR=setfattr
1164     else
1165       SETFATTR=
1166     fi
1167     rm -f conftest.tmp
1168     AC_SUBST([SETFATTR])
1169   fi
1170 fi
1171
1172 ## Need makeinfo >= 4.7 (?) to build the manuals.
1173 if test "$MAKEINFO" != "no"; then
1174   if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
1175     MAKEINFO=makeinfo
1176   fi
1177   case `($MAKEINFO --version) 2>/dev/null` in
1178     *' (GNU texinfo) '4.[[7-9]]* | \
1179     *' (GNU texinfo) '4.[[1-9][0-9]]* | \
1180     *' (GNU texinfo) '[[5-9]]* | \
1181     *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1182     *) MAKEINFO=no;;
1183   esac
1184 fi
1185
1186 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1187 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1188 ## therefore in the category of "special tools" not normally required, which
1189 ## configure does not have to check for (eg autoconf itself).
1190 ## In a repository checkout on the other hand, the manuals are not included.
1191 ## So makeinfo is a requirement to build from the repository, and configure
1192 ## should test for it as it does for any other build requirement.
1193 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1194 ## with pre-built manuals, from a repository checkout.
1195 HAVE_MAKEINFO=yes
1196
1197 if test "$MAKEINFO" = "no"; then
1198   MAKEINFO=makeinfo
1199   if test "x${with_makeinfo}" = "xno"; then
1200     HAVE_MAKEINFO=no
1201   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1202     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1203 source tree does not seem to have pre-built manuals in the 'info' directory.
1204 Either install a suitable version of makeinfo, or re-run configure
1205 with the '--without-makeinfo' option to build without the manuals.] )
1206   fi
1207 fi
1208 AC_SUBST(HAVE_MAKEINFO)
1209
1210 if test $opsys = mingw32; then
1211    DOCMISC_W32=efaq-w32
1212 else
1213    DOCMISC_W32=
1214 fi
1215 AC_SUBST(DOCMISC_W32)
1216
1217 dnl Add our options to ac_link now, after it is set up.
1218
1219 if test x$GCC = xyes; then
1220   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1221     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1222 else
1223   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1224     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1225 fi
1226
1227 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1228 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1229 dnl (Don't use '-z nocombreloc' as -z takes no arg on Irix.)
1230 dnl Treat GCC specially since it just gives a non-fatal 'unrecognized option'
1231 dnl if not built to support GNU ld.
1232
1233 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1234 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1235 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1236 dnl   Eg "make LDFLAGS=... all" could run into problems,
1237 dnl   http://bugs.debian.org/684788
1238 dnl * unnecessary, since temacs is the only thing that actually needs it.
1239 dnl   Indeed this is where it was originally, prior to:
1240 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1241 late_LDFLAGS="$LDFLAGS"
1242 if test x$GCC = xyes; then
1243   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1244 else
1245   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1246 fi
1247
1248 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1249
1250 AC_MSG_CHECKING([for -znocombreloc])
1251 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1252   [AC_MSG_RESULT(yes)],
1253   LDFLAGS_NOCOMBRELOC=
1254   [AC_MSG_RESULT(no)])
1255
1256 LDFLAGS="$late_LDFLAGS"
1257
1258 AC_CACHE_CHECK([whether addresses are sanitized],
1259   [emacs_cv_sanitize_address],
1260   [AC_COMPILE_IFELSE(
1261      [AC_LANG_PROGRAM(
1262         [[#ifndef __has_feature
1263           #define __has_feature(f) 0
1264           #endif
1265           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1266           #else
1267            error "Addresses are not sanitized.";
1268           #endif
1269         ]])],
1270      [emacs_cv_sanitize_address=yes],
1271      [emacs_cv_sanitize_address=no])])
1272
1273 dnl The function dump-emacs will not be defined and temacs will do
1274 dnl (load "loadup") automatically unless told otherwise.
1275 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1276 case "$opsys" in
1277   nacl) CANNOT_DUMP=yes ;;
1278 esac
1279
1280 if test "$CANNOT_DUMP" = "yes"; then
1281   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1282 elif test "$emacs_cv_sanitize_address" = yes; then
1283   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1284 fi
1285
1286 AC_SUBST(CANNOT_DUMP)
1287
1288
1289 UNEXEC_OBJ=unexelf.o
1290 case "$opsys" in
1291   # MSDOS uses unexcoff.o
1292   aix4-2)
1293    UNEXEC_OBJ=unexaix.o
1294    ;;
1295   cygwin)
1296    UNEXEC_OBJ=unexcw.o
1297    ;;
1298   darwin)
1299    UNEXEC_OBJ=unexmacosx.o
1300    ;;
1301   hpux10-20 | hpux11)
1302    UNEXEC_OBJ=unexhp9k800.o
1303    ;;
1304   mingw32)
1305    UNEXEC_OBJ=unexw32.o
1306    ;;
1307   sol2-10)
1308    # Use the Solaris dldump() function, called from unexsol.c, to dump
1309    # emacs, instead of the generic ELF dump code found in unexelf.c.
1310    # The resulting binary has a complete symbol table, and is better
1311    # for debugging and other observability tools (debuggers, pstack, etc).
1312    #
1313    # If you encounter a problem using dldump(), please consider sending
1314    # a message to the OpenSolaris tools-linking mailing list:
1315    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1316    #
1317    # It is likely that dldump() works with older Solaris too, but this has
1318    # not been tested, so for now this change is for Solaris 10 or newer.
1319    UNEXEC_OBJ=unexsol.o
1320    ;;
1321 esac
1322
1323 LD_SWITCH_SYSTEM=
1324 case "$opsys" in
1325   freebsd|dragonfly)
1326    ## Let 'ld' find image libs and similar things in /usr/local/lib.
1327    ## The system compiler, GCC, has apparently been modified to not
1328    ## look there, contrary to what a stock GCC would do.
1329 ### It's not our place to do this.  See bug#10313#17.
1330 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1331       :
1332    ;;
1333
1334   gnu-linux)
1335    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1336    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1337    ;;
1338
1339   netbsd)
1340 ### It's not our place to do this.  See bug#10313#17.
1341 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1342       :
1343    ;;
1344
1345   openbsd)
1346    ## Han Boetes <han@boetes.org> says this is necessary,
1347    ## otherwise Emacs dumps core on elf systems.
1348    LD_SWITCH_SYSTEM="-Z"
1349    ;;
1350 esac
1351 AC_SUBST(LD_SWITCH_SYSTEM)
1352
1353 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1354
1355 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1356 ## which has not been defined yet.  When this was handled with cpp,
1357 ## it was expanded to null when configure sourced the s/*.h file.
1358 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1359 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1360 ## (or somesuch), but because it is supposed to go at the _front_
1361 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1362 ## Compare with the gnu-linux case below, which added to the end
1363 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1364 ## LD_SWITCH_SYSTEM_TEMACS.
1365 case "$opsys" in
1366   netbsd|openbsd)
1367    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1368 esac
1369
1370
1371 C_SWITCH_MACHINE=
1372 case $canonical in
1373  alpha*)
1374   AC_CHECK_DECL([__ELF__])
1375   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1376     ## With ELF, make sure that all common symbols get allocated to in the
1377     ## data section.  Otherwise, the dump of temacs may miss variables in
1378     ## the shared library that have been initialized.  For example, with
1379     ## GNU libc, __malloc_initialized would normally be resolved to the
1380     ## shared library's .bss section, which is fatal.
1381     if test "x$GCC" = "xyes"; then
1382       C_SWITCH_MACHINE="-fno-common"
1383     else
1384       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1385     fi
1386   else
1387       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1388       dnl albeit under the mistaken assumption that said file
1389       dnl was no longer used.
1390       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1391   fi
1392   ;;
1393 esac
1394 AC_SUBST(C_SWITCH_MACHINE)
1395
1396 AC_SUBST(UNEXEC_OBJ)
1397
1398 C_SWITCH_SYSTEM=
1399 ## Some programs in src produce warnings saying certain subprograms
1400 ## are too complex and need a MAXMEM value greater than 2000 for
1401 ## additional optimization.  --nils@exp-math.uni-essen.de
1402 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1403   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1404 if test "$opsys" = "mingw32"; then
1405   case "$canonical" in
1406     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1407     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1408   esac
1409 fi
1410 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1411 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1412 AC_SUBST(C_SWITCH_SYSTEM)
1413
1414
1415 LIBS_SYSTEM=
1416 case "$opsys" in
1417   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1418   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1419
1420   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1421
1422   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1423
1424   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1425
1426   ## Motif needs -lgen.
1427   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1428 esac
1429
1430 AC_SUBST(LIBS_SYSTEM)
1431
1432 ### Make sure subsequent tests use flags consistent with the build flags.
1433
1434 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1435   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1436 else
1437   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1438 fi
1439
1440 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1441 AC_DEFUN([AC_TYPE_SIZE_T])
1442 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1443 AC_DEFUN([AC_TYPE_UID_T])
1444
1445 # sqrt and other floating-point functions such as fmod and frexp
1446 # are found in -lm on many systems.
1447 OLD_LIBS=$LIBS
1448 AC_SEARCH_LIBS([sqrt], [m])
1449 if test "X$LIBS" = "X$OLD_LIBS"; then
1450   LIB_MATH=
1451 else
1452   LIB_MATH=$ac_cv_search_sqrt
1453 fi
1454 LIBS=$OLD_LIBS
1455
1456 dnl Current possibilities handled by sed (aix4-2 -> aix,
1457 dnl gnu-linux -> gnu/linux, etc.):
1458 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1459 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1460 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1461
1462 case $opsys in
1463   cygwin )
1464     LIB_MATH=
1465     ;;
1466   darwin )
1467     ## Adding -lm confuses the dynamic linker, so omit it.
1468     LIB_MATH=
1469     ;;
1470   freebsd | dragonfly )
1471     SYSTEM_TYPE=berkeley-unix
1472     ;;
1473   gnu-linux | gnu-kfreebsd )
1474     ;;
1475   hpux10-20 | hpux11 )
1476     ;;
1477   mingw32 )
1478     LIB_MATH=
1479     SYSTEM_TYPE=windows-nt
1480     ;;
1481   dnl NB this may be adjusted below.
1482   netbsd | openbsd )
1483     SYSTEM_TYPE=berkeley-unix
1484     ;;
1485
1486   sol2* | unixware )
1487     SYSTEM_TYPE=usg-unix-v
1488     ;;
1489
1490 esac
1491
1492 AC_SUBST(LIB_MATH)
1493 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1494   [The type of system you are compiling for; sets 'system-type'.])
1495
1496
1497 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1498 pre_PKG_CONFIG_LIBS=$LIBS
1499
1500 PKG_PROG_PKG_CONFIG(0.9.0)
1501
1502 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1503 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1504 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1505 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1506 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1507 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1508 dnl actions.
1509 AC_DEFUN([EMACS_CHECK_MODULES],
1510   [PKG_CHECK_MODULES([$1], [$2],
1511      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1512       m4_default([$3], [HAVE_$1=yes])],
1513      [m4_default([$4], [HAVE_$1=no])])])
1514
1515 HAVE_SOUND=no
1516 if test "${with_sound}" != "no"; then
1517   # Sound support for GNU/Linux, the free BSDs, MinGW, and Cygwin.
1518   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1519     have_sound_header=yes, [], [
1520     #ifdef __MINGW32__
1521     #define WIN32_LEAN_AND_MEAN
1522     #include <windows.h>
1523     #endif
1524     ])
1525   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1526     AC_MSG_ERROR([OSS sound support requested but not found.])
1527
1528   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1529     # Emulation library used on NetBSD.
1530     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1531     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1532       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1533     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1534     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1535   fi
1536   AC_SUBST(LIBSOUND)
1537
1538   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1539     ALSA_REQUIRED=1.0.0
1540     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1541     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1542     if test $HAVE_ALSA = yes; then
1543       SAVE_CFLAGS="$CFLAGS"
1544       SAVE_LIBS="$LIBS"
1545       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1546       LIBS="$ALSA_LIBS $LIBS"
1547       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1548                       emacs_alsa_normal=yes,
1549                     emacs_alsa_normal=no)
1550       if test "$emacs_alsa_normal" != yes; then
1551         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1552                        [[snd_lib_error_set_handler (0);]])],
1553                        emacs_alsa_subdir=yes,
1554                      emacs_alsa_subdir=no)
1555         if test "$emacs_alsa_subdir" != yes; then
1556           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1557         fi
1558         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1559       fi
1560
1561       CFLAGS="$SAVE_CFLAGS"
1562       LIBS="$SAVE_LIBS"
1563       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1564       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1565       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1566     elif test "${with_sound}" = "alsa"; then
1567       AC_MSG_ERROR([ALSA sound support requested but not found.])
1568     fi
1569   fi                            dnl with_sound = alsa|yes
1570
1571   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1572   dnl compiles only on the specified platforms.  For others, it
1573   dnl probably doesn't make sense to try.
1574   dnl FIXME So surely we should bypass this whole section if not using
1575   dnl one of these platforms?
1576   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1577      case "$opsys" in
1578        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1579        dnl Adjust the --with-sound help text if you change this.
1580        gnu-linux|freebsd|netbsd|mingw32|cygwin)
1581          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1582          HAVE_SOUND=yes
1583          ;;
1584      esac
1585   fi
1586
1587   AC_SUBST(CFLAGS_SOUND)
1588 fi
1589
1590 dnl checks for header files
1591 AC_CHECK_HEADERS_ONCE(
1592   sys/systeminfo.h
1593   sys/sysinfo.h
1594   coff.h pty.h
1595   sys/resource.h
1596   sys/utsname.h pwd.h utmp.h util.h)
1597
1598 AC_MSG_CHECKING(if personality LINUX32 can be set)
1599 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1600                emacs_cv_personality_linux32=yes,
1601                emacs_cv_personality_linux32=no)
1602 AC_MSG_RESULT($emacs_cv_personality_linux32)
1603
1604 if test $emacs_cv_personality_linux32 = yes; then
1605   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1606             [Define to 1 if personality LINUX32 can be set.])
1607 fi
1608
1609 # Note that Solaris has sys/sysinfo.h which defines struct
1610 # sysinfo as well.  To make sure that we're using GNU/Linux
1611 # sysinfo, we explicitly set one of its fields.
1612 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1613   AC_MSG_CHECKING([if Linux sysinfo may be used])
1614   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1615                                      [[struct sysinfo si;
1616                                        si.totalram = 0;
1617                                        sysinfo (&si)]])],
1618     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1619   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1620   if test $emacs_cv_linux_sysinfo = yes; then
1621     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1622     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1623                                        [[struct sysinfo si; return si.mem_unit]])],
1624       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1625                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1626   fi
1627 fi
1628
1629 dnl On Solaris 8 there's a compilation warning for term.h because
1630 dnl it doesn't define 'bool'.
1631 AC_CHECK_HEADERS(term.h, , , -)
1632 AC_HEADER_TIME
1633 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1634                                       ]])
1635 if test $ac_cv_have_decl_sys_siglist != yes; then
1636   # For Tru64, at least:
1637   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1638                                           ]])
1639 fi
1640 AC_HEADER_SYS_WAIT
1641
1642 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1643 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1644 #if HAVE_SYS_SOCKET_H
1645 #include <sys/socket.h>
1646 #endif])
1647 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1648 #if HAVE_SYS_SOCKET_H
1649 #include <sys/socket.h>
1650 #endif])
1651 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1652 #if HAVE_SYS_SOCKET_H
1653 #include <sys/socket.h>
1654 #endif])
1655
1656 dnl checks for structure members
1657 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1658                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1659                   struct ifreq.ifr_addr,
1660                   struct ifreq.ifr_addr.sa_len], , ,
1661                  [AC_INCLUDES_DEFAULT
1662 #if HAVE_SYS_SOCKET_H
1663 #include <sys/socket.h>
1664 #endif
1665 #if HAVE_NET_IF_H
1666 #include <net/if.h>
1667 #endif])
1668
1669 dnl Check for endianness.
1670 dnl AC_C_BIGENDIAN is done by gnulib.
1671
1672 dnl check for Make feature
1673
1674 AUTO_DEPEND=no
1675 dnl check if we have GCC and autodepend is on.
1676 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1677    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1678    SAVE_CFLAGS="$CFLAGS"
1679    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1680    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1681    CFLAGS="$SAVE_CFLAGS"
1682    test -f deps.d || ac_enable_autodepend=no
1683    rm -rf deps.d
1684    AC_MSG_RESULT([$ac_enable_autodepend])
1685    if test $ac_enable_autodepend = yes; then
1686       AUTO_DEPEND=yes
1687    fi
1688 fi
1689 AC_SUBST(AUTO_DEPEND)
1690
1691 dnl checks for operating system services
1692 AC_SYS_LONG_FILE_NAMES
1693
1694 #### Choose a window system.
1695
1696 ## We leave window_system equal to none if
1697 ## we end up building without one.  Any new window system should
1698 ## set window_system to an appropriate value and add objects to
1699 ## window-system-specific substs.
1700
1701 window_system=none
1702 AC_PATH_X
1703 if test "$no_x" != yes; then
1704   window_system=x11
1705 fi
1706
1707 LD_SWITCH_X_SITE_RPATH=
1708 if test "${x_libraries}" != NONE; then
1709   if test -n "${x_libraries}"; then
1710     LD_SWITCH_X_SITE=-L`AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -L/g'`
1711     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`
1712       AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -Wl,-rpath,/g'
1713     `
1714   fi
1715   x_default_search_path=""
1716   x_search_path=${x_libraries}
1717   if test -z "${x_search_path}"; then
1718     x_search_path=/usr/lib
1719   fi
1720   for x_library in `AS_ECHO(["$x_search_path:"]) | \
1721                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1722     x_search_path="\
1723 ${x_library}/X11/%L/%T/%N%C%S:\
1724 ${x_library}/X11/%l/%T/%N%C%S:\
1725 ${x_library}/X11/%T/%N%C%S:\
1726 ${x_library}/X11/%L/%T/%N%S:\
1727 ${x_library}/X11/%l/%T/%N%S:\
1728 ${x_library}/X11/%T/%N%S"
1729     if test x"${x_default_search_path}" = x; then
1730       x_default_search_path=${x_search_path}
1731     else
1732       x_default_search_path="${x_search_path}:${x_default_search_path}"
1733     fi
1734   done
1735 fi
1736 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1737
1738 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1739   C_SWITCH_X_SITE=$isystem`AS_ECHO(["$x_includes"]) | sed -e "s/:/ $isystem/g"`
1740 fi
1741
1742 if test x"${x_includes}" = x; then
1743   bitmapdir=/usr/include/X11/bitmaps
1744 else
1745   # accumulate include directories that have X11 bitmap subdirectories
1746   bmd_acc=
1747   for bmd in `AS_ECHO(["$x_includes"]) | sed -e 's/:/ /g'`; do
1748     if test -d "${bmd}/X11/bitmaps"; then
1749       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1750     fi
1751     if test -d "${bmd}/bitmaps"; then
1752       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1753     fi
1754   done
1755   bitmapdir=${bmd_acc#:}
1756 fi
1757
1758 test "${with_ns}" = maybe && test "${opsys}" != darwin && with_ns=no
1759 HAVE_NS=no
1760 NS_GNUSTEP_CONFIG=no
1761 NS_IMPL_COCOA=no
1762 NS_IMPL_GNUSTEP=no
1763 tmp_CPPFLAGS="$CPPFLAGS"
1764 tmp_CFLAGS="$CFLAGS"
1765 CPPFLAGS="$CPPFLAGS -x objective-c"
1766 CFLAGS="$CFLAGS -x objective-c"
1767 GNU_OBJC_CFLAGS=
1768 LIBS_GNUSTEP=
1769 if test "${with_ns}" != no; then
1770   if test "${opsys}" = darwin; then
1771      NS_IMPL_COCOA=yes
1772      ns_appdir=`pwd`/nextstep/Emacs.app
1773      ns_appbindir=${ns_appdir}/Contents/MacOS
1774      ns_appresdir=${ns_appdir}/Contents/Resources
1775      ns_appsrc=Cocoa/Emacs.base
1776      ns_fontfile=macfont.o
1777   elif flags=$( (gnustep-config --objc-flags) 2>/dev/null); then
1778      NS_IMPL_GNUSTEP=yes
1779      NS_GNUSTEP_CONFIG=yes
1780      GNU_OBJC_CFLAGS=$flags
1781      LIBS_GNUSTEP=$(gnustep-config --gui-libs) || exit
1782   elif test -f $GNUSTEP_CONFIG_FILE; then
1783      NS_IMPL_GNUSTEP=yes
1784      dnl FIXME sourcing this several times in subshells seems inefficient.
1785      GNUSTEP_SYSTEM_HEADERS=$(
1786        . $GNUSTEP_CONFIG_FILE
1787        AS_ECHO(["$GNUSTEP_SYSTEM_HEADERS"])
1788      )
1789      GNUSTEP_SYSTEM_LIBRARIES=$(
1790        . $GNUSTEP_CONFIG_FILE
1791        AS_ECHO(["$GNUSTEP_SYSTEM_LIBRARIES"])
1792      )
1793      dnl I seemed to need these as well with GNUstep-startup 0.25.
1794      GNUSTEP_LOCAL_HEADERS=$(
1795        . $GNUSTEP_CONFIG_FILE
1796        AS_ECHO(["$GNUSTEP_LOCAL_HEADERS"])
1797      )
1798      GNUSTEP_LOCAL_LIBRARIES=$(
1799        . $GNUSTEP_CONFIG_FILE
1800        AS_ECHO(["$GNUSTEP_LOCAL_LIBRARIES"])
1801      )
1802      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1803        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1804      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1805        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1806      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1807      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1808      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1809      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1810      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1811      dnl If they had chosen to either define it or not, we could have
1812      dnl just used AC_CHECK_DECL here.
1813      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1814        emacs_cv_objc_exceptions,
1815 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1816 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1817 1;
1818 #else
1819 fail;
1820 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1821      if test $emacs_cv_objc_exceptions = yes; then
1822        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1823        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1824          [Define if GNUstep uses ObjC exceptions.])
1825        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1826      fi
1827   fi
1828   if test $NS_IMPL_GNUSTEP = yes; then
1829      ns_appdir=`pwd`/nextstep/Emacs.app
1830      ns_appbindir=${ns_appdir}
1831      ns_appresdir=${ns_appdir}/Resources
1832      ns_appsrc=GNUstep/Emacs.base
1833      ns_fontfile=nsfont.o
1834   fi
1835
1836   dnl This is only used while we test the NS headers, it gets reset below.
1837   CPPFLAGS="$CPPFLAGS $GNU_OBJC_CFLAGS"
1838   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1839
1840   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1841                   [AC_MSG_ERROR([The include files (AppKit/AppKit.h etc) that
1842 are required for a Nextstep build are missing or cannot be compiled.
1843 Either fix this, or re-configure with the option '--without-ns'.])])
1844
1845   macfont_file=""
1846   if test "${NS_IMPL_COCOA}" = "yes"; then
1847     AC_MSG_CHECKING([for OSX 10.6 or newer])
1848     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1849                                      [
1850 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1851 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1060
1852  ; /* OK */
1853 #else
1854  error "OSX 10.6 or newer required";
1855 #endif
1856 #endif
1857                     ])],
1858                     ns_osx_have_106=yes,
1859                     ns_osx_have_106=no)
1860     AC_MSG_RESULT([$ns_osx_have_106])
1861
1862     if test $ns_osx_have_106 = no; then
1863        AC_MSG_ERROR([OSX 10.6 or newer is required]);
1864     fi
1865   fi
1866 fi
1867
1868 AC_SUBST(LIBS_GNUSTEP)
1869
1870 INSTALL_ARCH_INDEP_EXTRA=install-etc
1871 ns_self_contained=no
1872 NS_OBJ=
1873 NS_OBJC_OBJ=
1874 if test "${HAVE_NS}" = yes; then
1875   if test "$with_toolkit_scroll_bars" = "no"; then
1876     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1877   fi
1878
1879   window_system=nextstep
1880   # set up packaging dirs
1881   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1882      ns_self_contained=yes
1883      prefix=${ns_appresdir}
1884      exec_prefix=${ns_appbindir}
1885      dnl This one isn't really used, only archlibdir is.
1886      libexecdir="\${ns_appbindir}/libexec"
1887      archlibdir="\${ns_appbindir}/libexec"
1888      etcdocdir="\${ns_appresdir}/etc"
1889      etcdir="\${ns_appresdir}/etc"
1890      dnl FIXME maybe set datarootdir instead.
1891      dnl That would also get applications, icons, man.
1892      infodir="\${ns_appresdir}/info"
1893      mandir="\${ns_appresdir}/man"
1894      lispdir="\${ns_appresdir}/lisp"
1895      test "$locallisppathset" = no && locallisppath=""
1896      INSTALL_ARCH_INDEP_EXTRA=
1897   fi
1898
1899   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o $ns_fontfile"
1900 fi
1901 CFLAGS="$tmp_CFLAGS"
1902 CPPFLAGS="$tmp_CPPFLAGS"
1903 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1904 AC_SUBST(ns_self_contained)
1905 AC_SUBST(NS_OBJ)
1906 AC_SUBST(NS_OBJC_OBJ)
1907
1908 HAVE_W32=no
1909 W32_OBJ=
1910 W32_LIBS=
1911 EMACSRES=
1912 CLIENTRES=
1913 CLIENTW=
1914 W32_RES_LINK=
1915 EMACS_MANIFEST=
1916 UPDATE_MANIFEST=
1917 if test "${with_w32}" != no; then
1918   case "${opsys}" in
1919     cygwin)
1920       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1921              [AC_MSG_ERROR(['--with-w32' was specified, but windows.h
1922                    cannot be found.])])
1923     ;;
1924     mingw32)
1925     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1926     ;;
1927     *)
1928       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1929     ;;
1930   esac
1931 fi
1932
1933 if test "${opsys}" = "mingw32"; then
1934   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1935   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1936      #include <windows.h>
1937      #include <usp10.h>]],
1938    [[PIMAGE_NT_HEADERS pHeader;
1939      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1940    [emacs_cv_w32api=yes
1941     HAVE_W32=yes],
1942    emacs_cv_w32api=no)
1943   AC_MSG_RESULT($emacs_cv_w32api)
1944   if test "${emacs_cv_w32api}" = "no"; then
1945     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1946   fi
1947 fi
1948
1949 FIRSTFILE_OBJ=
1950 NTDIR=
1951 LIBS_ECLIENT=
1952 LIB_WSOCK32=
1953 NTLIB=
1954 CM_OBJ="cm.o"
1955 XARGS_LIMIT=
1956 if test "${HAVE_W32}" = "yes"; then
1957   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1958   if test "$with_toolkit_scroll_bars" = "no"; then
1959     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for w32 build.])
1960   fi
1961   AC_CHECK_TOOL(WINDRES, [windres],
1962                 [AC_MSG_ERROR([No resource compiler found.])])
1963   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1964   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1965   EMACSRES="emacs.res"
1966   case "$canonical" in
1967     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1968     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1969   esac
1970   dnl Construct something of the form "24,4,0,0" with 4 components.
1971   comma_version=`echo "${PACKAGE_VERSION}.0.0" | sed -e 's/\./,/g' -e 's/^\([[^,]]*,[[^,]]*,[[^,]]*,[[^,]]*\).*/\1/'`
1972
1973   comma_space_version=`echo "$comma_version" | sed 's/,/, /g'`
1974   AC_SUBST(comma_version)
1975   AC_SUBST(comma_space_version)
1976   AC_CONFIG_FILES([nt/emacs.rc nt/emacsclient.rc])
1977   if test "${opsys}" = "cygwin"; then
1978     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1979     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1980     # Tell the linker that emacs.res is an object (which we compile from
1981     # the rc file), not a linker script.
1982     W32_RES_LINK="-Wl,emacs.res"
1983   else
1984     UPDATE_MANIFEST=update-game-score.exe.manifest
1985     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1986     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1987     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1988     W32_RES_LINK="\$(EMACSRES)"
1989     CLIENTRES="emacsclient.res"
1990     CLIENTW="emacsclientw\$(EXEEXT)"
1991     FIRSTFILE_OBJ=firstfile.o
1992     NTDIR=nt
1993     CM_OBJ=
1994     LIBS_ECLIENT="-lcomctl32"
1995     LIB_WSOCK32="-lwsock32"
1996     NTLIB="ntlib.$ac_objext"
1997     XARGS_LIMIT="-s 10000"
1998   fi
1999 fi
2000 AC_SUBST(W32_OBJ)
2001 AC_SUBST(W32_LIBS)
2002 AC_SUBST(EMACSRES)
2003 AC_SUBST(EMACS_MANIFEST)
2004 AC_SUBST(UPDATE_MANIFEST)
2005 AC_SUBST(CLIENTRES)
2006 AC_SUBST(CLIENTW)
2007 AC_SUBST(W32_RES_LINK)
2008 AC_SUBST(FIRSTFILE_OBJ)
2009 AC_SUBST(NTDIR)
2010 AC_SUBST(CM_OBJ)
2011 AC_SUBST(LIBS_ECLIENT)
2012 AC_SUBST(LIB_WSOCK32)
2013 AC_SUBST(NTLIB)
2014 AC_SUBST(XARGS_LIMIT)
2015
2016 if test "${HAVE_W32}" = "yes"; then
2017   window_system=w32
2018   with_xft=no
2019 fi
2020
2021 ## $window_system is now set to the window system we will
2022 ## ultimately use.
2023
2024 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
2025    # Too many warnings for now.
2026    nw=
2027    nw="$nw -Wsuggest-attribute=noreturn"
2028    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
2029
2030    gl_WARN_ADD([-Wno-unused-variable])
2031    gl_WARN_ADD([-Wno-unused-but-set-variable])
2032    gl_WARN_ADD([-Wno-unused-but-set-parameter])
2033 fi
2034
2035 term_header=
2036 HAVE_X_WINDOWS=no
2037 HAVE_X11=no
2038 USE_X_TOOLKIT=none
2039
2040 case "${window_system}" in
2041   x11 )
2042     HAVE_X_WINDOWS=yes
2043     HAVE_X11=yes
2044     term_header=xterm.h
2045     case "${with_x_toolkit}" in
2046       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
2047       motif ) USE_X_TOOLKIT=MOTIF ;;
2048       gtk ) with_gtk=yes
2049             term_header=gtkutil.h
2050 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
2051 dnl USE_X_TOOLKIT is set.
2052             USE_X_TOOLKIT=none ;;
2053       gtk2 ) with_gtk2=yes
2054              term_header=gtkutil.h
2055              USE_X_TOOLKIT=none ;;
2056       gtk3 ) with_gtk3=yes
2057              term_header=gtkutil.h
2058              USE_X_TOOLKIT=none ;;
2059       no ) USE_X_TOOLKIT=none ;;
2060 dnl If user did not say whether to use a toolkit, make this decision later:
2061 dnl use the toolkit if we have gtk, or X11R5 or newer.
2062       * ) USE_X_TOOLKIT=maybe ;;
2063     esac
2064   ;;
2065   nextstep )
2066     term_header=nsterm.h
2067   ;;
2068   w32 )
2069     term_header=w32term.h
2070   ;;
2071 esac
2072
2073 if test "$window_system" = none && test "X$with_x" != "Xno"; then
2074    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
2075    if test "$HAVE_XSERVER" = true ||
2076       test -n "$DISPLAY" ||
2077       {
2078         for emacs_libX11 in /usr/lib/libX11.*; do break; done
2079         test "$emacs_libX11" != '/usr/lib/libX11.*'
2080       }
2081    then
2082         AC_MSG_ERROR([You seem to be running X, but no X development libraries
2083 were found.  You should install the relevant development files for X
2084 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2085 sure you have development files for image handling, i.e.
2086 tiff, gif, jpeg, png and xpm.
2087 If you are sure you want Emacs compiled without X window support, pass
2088   --without-x
2089 to configure.])
2090    fi
2091 fi
2092
2093 # Does the opsystem file prohibit the use of the GNU malloc?
2094 # Assume not, until told otherwise.
2095 GNU_MALLOC=yes
2096
2097 AC_CACHE_CHECK(
2098   [whether malloc is Doug Lea style],
2099   [emacs_cv_var_doug_lea_malloc],
2100   [emacs_cv_var_doug_lea_malloc=no
2101    dnl Hooks do not work with address sanitization.
2102    if test "$emacs_cv_sanitize_address" != yes; then
2103      AC_LINK_IFELSE(
2104        [AC_LANG_PROGRAM(
2105           [[#include <malloc.h>
2106             static void hook (void) {}]],
2107           [[malloc_set_state (malloc_get_state ());
2108             __after_morecore_hook = hook;
2109             __malloc_initialize_hook = hook;]])],
2110        [emacs_cv_var_doug_lea_malloc=yes])
2111    fi])
2112 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2113
2114 system_malloc=$emacs_cv_sanitize_address
2115
2116 hybrid_malloc=
2117
2118 case "$opsys" in
2119   ## darwin ld insists on the use of malloc routines in the System framework.
2120   darwin | mingw32 | nacl | sol2-10) system_malloc=yes ;;
2121   cygwin) hybrid_malloc=yes;;
2122 esac
2123
2124 if test "${system_malloc}" != yes && test "${doug_lea_malloc}" != yes \
2125    && test "${UNEXEC_OBJ}" = unexelf.o && test "${hybrid_malloc}" != no; then
2126   hybrid_malloc=yes
2127 fi
2128
2129 GMALLOC_OBJ=
2130 SHEAP_OBJ=
2131 if test "${system_malloc}" = "yes"; then
2132   AC_DEFINE([SYSTEM_MALLOC], 1,
2133     [Define to 1 to use the system memory allocator, even if it is not
2134      Doug Lea style.])
2135   GNU_MALLOC=no
2136   GNU_MALLOC_reason="
2137     (The GNU allocators don't work with this system configuration.)"
2138   VMLIMIT_OBJ=
2139 elif test "$hybrid_malloc" = yes; then
2140   AC_DEFINE(HYBRID_MALLOC, 1,
2141     [Define to use gmalloc before dumping and the system malloc after.])
2142   GNU_MALLOC=
2143   GNU_MALLOC_reason="only before dumping"
2144   GMALLOC_OBJ=gmalloc.o
2145   SHEAP_OBJ=sheap.o
2146   VMLIMIT_OBJ=
2147 else
2148   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2149   VMLIMIT_OBJ=vm-limit.o
2150
2151   AC_CHECK_HEADERS([sys/vlimit.h])
2152   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2153     [AC_LINK_IFELSE(
2154        [AC_LANG_PROGRAM(
2155          [[extern char data_start[]; char ch;]],
2156          [[return data_start < &ch;]])],
2157        [emacs_cv_data_start=yes],
2158        [emacs_cv_data_start=no])])
2159   if test $emacs_cv_data_start = yes; then
2160     AC_DEFINE([HAVE_DATA_START], 1,
2161       [Define to 1 if data_start is the address of the start
2162        of the main data segment.])
2163   fi
2164 fi
2165 AC_SUBST(GMALLOC_OBJ)
2166 AC_SUBST(SHEAP_OBJ)
2167 AC_SUBST(VMLIMIT_OBJ)
2168
2169 if test "$doug_lea_malloc" = "yes" && test "$hybrid_malloc" != yes; then
2170   if test "$GNU_MALLOC" = yes ; then
2171     GNU_MALLOC_reason="
2172       (Using Doug Lea's new malloc from the GNU C Library.)"
2173   fi
2174   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2175     [Define to 1 if the system memory allocator is Doug Lea style,
2176      with malloc hooks and malloc_set_state.])
2177
2178   ## Use mmap directly for allocating larger buffers.
2179   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2180   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2181   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2182   case "$opsys" in
2183     mingw32|gnu*) REL_ALLOC=no ;;
2184   esac
2185 fi
2186
2187 if test x"${REL_ALLOC}" = x; then
2188   REL_ALLOC=${GNU_MALLOC}
2189 fi
2190
2191 use_mmap_for_buffers=no
2192 case "$opsys" in
2193   cygwin|mingw32|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
2194 esac
2195
2196 AC_FUNC_MMAP
2197 if test $use_mmap_for_buffers = yes; then
2198   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2199   REL_ALLOC=no
2200 fi
2201
2202 LIBS="$LIBS_SYSTEM $LIBS"
2203
2204 dnl FIXME replace main with a function we actually want from this library.
2205 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2206
2207 dnl Check for the POSIX thread library.
2208 LIB_PTHREAD=
2209 AC_CHECK_HEADERS_ONCE(pthread.h)
2210 if test "$ac_cv_header_pthread_h" && test "$opsys" != "mingw32"; then
2211   AC_CACHE_CHECK([for pthread library],
2212     [emacs_cv_pthread_lib],
2213     [emacs_cv_pthread_lib=no
2214      OLD_LIBS=$LIBS
2215      for emacs_pthread_lib in 'none needed' -lpthread; do
2216        case $emacs_pthread_lib in
2217          -*) LIBS="$OLD_LIBS $emacs_pthread_lib";;
2218        esac
2219        AC_LINK_IFELSE(
2220          [AC_LANG_PROGRAM(
2221             [[#include <pthread.h>
2222               #include <signal.h>
2223               sigset_t old_mask, new_mask;
2224               void noop (void) {}]],
2225             [[pthread_t th = pthread_self ();
2226               int status = 0;
2227               status += pthread_create (&th, 0, 0, 0);
2228               status += pthread_sigmask (SIG_BLOCK, &new_mask, &old_mask);
2229               status += pthread_kill (th, 0);
2230               #if ! (defined SYSTEM_MALLOC || defined HYBRID_MALLOC \
2231                      || defined DOUG_LEA_MALLOC)
2232               /* Test for pthread_atfork only if gmalloc uses it,
2233                  as older-style hosts like MirBSD 10 lack it.  */
2234               status += pthread_atfork (noop, noop, noop);
2235               #endif
2236               return status;]])],
2237          [emacs_cv_pthread_lib=$emacs_pthread_lib])
2238        LIBS=$OLD_LIBS
2239        if test "$emacs_cv_pthread_lib" != no; then
2240          break
2241        fi
2242      done])
2243   if test "$emacs_cv_pthread_lib" != no; then
2244     AC_DEFINE([HAVE_PTHREAD], 1, [Define to 1 if you have POSIX threads.])
2245     case $emacs_cv_pthread_lib in
2246       -*) LIB_PTHREAD=$emacs_cv_pthread_lib;;
2247     esac
2248     ac_cv_func_pthread_sigmask=yes
2249     # Some systems optimize for single-threaded programs by default, and
2250     # need special flags to disable these optimizations. For example, the
2251     # definition of 'errno' in <errno.h>.
2252     case $opsys in
2253       hpux* | sol*)
2254         AC_DEFINE([_REENTRANT], 1,
2255           [Define to 1 if your system requires this in multithreaded code.]);;
2256       aix4-2)
2257         AC_DEFINE([_THREAD_SAFE], 1,
2258           [Define to 1 if your system requires this in multithreaded code.]);;
2259     esac
2260   fi
2261 fi
2262 AC_SUBST([LIB_PTHREAD])
2263
2264 dnl Check for need for bigtoc support on IBM AIX
2265
2266 case ${host_os} in
2267 aix*)
2268   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2269     case $GCC in
2270     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2271     *) gdb_cv_bigtoc=-bbigtoc ;;
2272     esac
2273
2274     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2275     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2276   ])
2277   ;;
2278 esac
2279
2280 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2281 # is for the tests that follow.  We set them back later on.
2282
2283 REAL_CFLAGS="$CFLAGS"
2284 REAL_CPPFLAGS="$CPPFLAGS"
2285 REAL_LIBS="$LIBS"
2286
2287 if test "${HAVE_X11}" = "yes"; then
2288   DEFS="$C_SWITCH_X_SITE $DEFS"
2289   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2290   LIBS="-lX11 $LIBS"
2291   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2292   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2293
2294   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2295   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2296   # but it's more convenient here to set LD_RUN_PATH since this
2297   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2298   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2299     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2300     export LD_RUN_PATH
2301   fi
2302
2303   if test "${opsys}" = "gnu-linux"; then
2304     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2305     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2306      [[XOpenDisplay ("foo");]])],
2307      [xgnu_linux_first_failure=no],
2308      [xgnu_linux_first_failure=yes])
2309     if test "${xgnu_linux_first_failure}" = "yes"; then
2310       OLD_CPPFLAGS="$CPPFLAGS"
2311       OLD_LIBS="$LIBS"
2312       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2313       LIBS="$LIBS -b i486-linuxaout"
2314       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2315        [[XOpenDisplay ("foo");]])],
2316        [xgnu_linux_second_failure=no],
2317        [xgnu_linux_second_failure=yes])
2318       if test "${xgnu_linux_second_failure}" = "yes"; then
2319         # If we get the same failure with -b, there is no use adding -b.
2320         # So leave it out.  This plays safe.
2321         AC_MSG_RESULT(no)
2322       else
2323         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2324         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2325         AC_MSG_RESULT(yes)
2326       fi
2327       CPPFLAGS=$OLD_CPPFLAGS
2328       LIBS=$OLD_LIBS
2329     else
2330       AC_MSG_RESULT(no)
2331     fi
2332   fi
2333
2334   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2335   # header files included from there.
2336   AC_MSG_CHECKING(for Xkb)
2337   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2338 #include <X11/XKBlib.h>]],
2339         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2340         emacs_xkb=yes, emacs_xkb=no)
2341   AC_MSG_RESULT($emacs_xkb)
2342   if test $emacs_xkb = yes; then
2343     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2344   fi
2345
2346   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2347 XScreenNumberOfScreen)
2348 fi
2349
2350 if test "${window_system}" = "x11"; then
2351   AC_MSG_CHECKING(X11 version 6)
2352   AC_CACHE_VAL(emacs_cv_x11_version_6,
2353   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2354 [[#if XlibSpecificationRelease < 6
2355 fail;
2356 #endif
2357 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2358   if test $emacs_cv_x11_version_6 = yes; then
2359     AC_MSG_RESULT(6 or newer)
2360     AC_DEFINE(HAVE_X11R6, 1,
2361               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2362     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2363     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2364     ## XIM support.
2365     case "$opsys" in
2366       sol2-*) : ;;
2367       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2368            [Define if you have usable X11R6-style XIM support.])
2369          ;;
2370     esac
2371   else
2372     AC_MSG_RESULT(before 6)
2373   fi
2374 fi
2375
2376
2377 ### Use -lrsvg-2 if available, unless '--with-rsvg=no' is specified.
2378 HAVE_RSVG=no
2379 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2380   if test "${with_rsvg}" != "no"; then
2381     RSVG_REQUIRED=2.11.0
2382     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2383
2384     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2385     AC_SUBST(RSVG_CFLAGS)
2386     AC_SUBST(RSVG_LIBS)
2387
2388     if test $HAVE_RSVG = yes; then
2389       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2390       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2391       # Windows loads librsvg dynamically
2392       if test "${opsys}" = "mingw32"; then
2393         RSVG_LIBS=
2394       fi
2395     fi
2396   fi
2397 fi
2398
2399 HAVE_IMAGEMAGICK=no
2400 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2401   if test "${with_imagemagick}" != "no"; then
2402     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2403     ## 6.8.2 makes Emacs crash; see Bug#13867.
2404     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2405     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2406     AC_SUBST(IMAGEMAGICK_CFLAGS)
2407     AC_SUBST(IMAGEMAGICK_LIBS)
2408
2409     if test $HAVE_IMAGEMAGICK = yes; then
2410       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2411       OLD_CFLAGS=$CFLAGS
2412       OLD_LIBS=$LIBS
2413       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2414       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2415       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2416       CFLAGS=$OLD_CFLAGS
2417       LIBS=$OLD_LIBS
2418     fi
2419   fi
2420 fi
2421
2422
2423 HAVE_GTK=no
2424 GTK_OBJ=
2425 gtk_term_header=$term_header
2426 check_gtk2=no
2427 gtk3_pkg_errors=
2428 if test "${opsys}" != "mingw32"; then
2429   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2430     GLIB_REQUIRED=2.28
2431     GTK_REQUIRED=3.0
2432     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2433
2434     dnl Checks for libraries.
2435     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2436       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2437     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2438        AC_MSG_ERROR($GTK_PKG_ERRORS)
2439     fi
2440     if test "$pkg_check_gtk" = "yes"; then
2441        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2442        GTK_OBJ=emacsgtkfixed.o
2443        gtk_term_header=gtkutil.h
2444        USE_GTK_TOOLKIT="GTK3"
2445        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2446          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2447            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2448          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2449            [Define to 1 to disable Glib deprecation warnings.])
2450        fi
2451     else
2452        check_gtk2=yes
2453        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2454     fi
2455   fi
2456
2457   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2458     GLIB_REQUIRED=2.10
2459     GTK_REQUIRED=2.10
2460     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2461
2462     dnl Checks for libraries.
2463     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2464       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2465     if test "$pkg_check_gtk" = "no" &&
2466        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2467     then
2468       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2469     fi
2470     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2471   fi
2472 fi
2473
2474 OLD_CFLAGS=$CFLAGS
2475 OLD_LIBS=$LIBS
2476
2477 if test x"$pkg_check_gtk" = xyes; then
2478
2479   AC_SUBST(GTK_LIBS)
2480   CFLAGS="$CFLAGS $GTK_CFLAGS"
2481   LIBS="$GTK_LIBS $LIBS"
2482   dnl Try to compile a simple GTK program.
2483   AC_MSG_CHECKING([whether GTK compiles])
2484   GTK_COMPILES=no
2485   AC_LINK_IFELSE(
2486     [AC_LANG_PROGRAM(
2487        [[/* Check the Gtk and Glib APIs.  */
2488          #include <gtk/gtk.h>
2489          #include <glib-object.h>
2490          static void
2491          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2492          {}
2493        ]],
2494        [[
2495          GtkSettings *gs = 0;
2496          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2497             strict C prohibits this.  Use gtk_main_iteration to test that the
2498             libraries are there.  */
2499          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2500                                     0, 0, 0, G_CALLBACK (callback), 0))
2501            gtk_main_iteration ();
2502        ]])],
2503     [GTK_COMPILES=yes])
2504   AC_MSG_RESULT([$GTK_COMPILES])
2505   if test "${GTK_COMPILES}" != "yes"; then
2506     GTK_OBJ=
2507     if test "$USE_X_TOOLKIT" != "maybe"; then
2508       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2509     fi
2510   else
2511     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2512     HAVE_GTK=yes
2513     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2514     GTK_OBJ="gtkutil.o $GTK_OBJ"
2515     term_header=$gtk_term_header
2516     USE_X_TOOLKIT=none
2517     AC_MSG_WARN([[Your version of Gtk+ will have problems with
2518        closing open displays.  This is no problem if you just use
2519        one display, but if you use more than one and close one of them
2520        Emacs may crash.
2521        See http://bugzilla.gnome.org/show_bug.cgi?id=85715]])
2522     sleep 3
2523   fi
2524
2525 fi
2526 AC_SUBST(GTK_OBJ)
2527
2528
2529 if test "${HAVE_GTK}" = "yes"; then
2530
2531   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2532   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2533   if test "$with_toolkit_scroll_bars" != no; then
2534     with_toolkit_scroll_bars=yes
2535   fi
2536
2537   dnl  Check if we have the old file selection dialog declared and
2538   dnl  in the link library.  In 2.x it may be in the library,
2539   dnl  but not declared if deprecated featured has been selected out.
2540   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2541   HAVE_GTK_FILE_SELECTION=no
2542   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2543                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2544 #include <gtk/gtk.h>])
2545   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2546     AC_CHECK_FUNCS(gtk_file_selection_new)
2547   fi
2548
2549   dnl Same as above for gtk_handle_box.
2550   HAVE_GTK_HANDLE_BOX=no
2551   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2552                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2553 #include <gtk/gtk.h>])
2554   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2555     AC_CHECK_FUNCS(gtk_handle_box_new)
2556   fi
2557
2558   dnl Same as above for gtk_tearoff_menu_item.
2559   HAVE_GTK_TEAROFF_MENU_ITEM=no
2560   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2561                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2562 #include <gtk/gtk.h>])
2563   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2564     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2565   fi
2566
2567   dnl Check for functions introduced in 2.14 and later.
2568   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2569                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2570                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2571                  gtk_orientable_set_orientation \
2572                  gtk_window_set_has_resize_grip)
2573
2574  term_header=gtkutil.h
2575 fi
2576
2577
2578 dnl Enable xwidgets if GTK3 and WebKitGTK+ are available.
2579 HAVE_XWIDGETS=no
2580 XWIDGETS_OBJ=
2581 if test "$with_xwidgets" != "no"; then
2582   test "$USE_GTK_TOOLKIT" = "GTK3" && test "$window_system" != "none" ||
2583     AC_MSG_ERROR([xwidgets requested but gtk3 not used.])
2584
2585   WEBKIT_REQUIRED=1.4.0
2586   WEBKIT_MODULES="webkitgtk-3.0 >= $WEBKIT_REQUIRED"
2587   EMACS_CHECK_MODULES([WEBKIT], [$WEBKIT_MODULES])
2588   HAVE_XWIDGETS=$HAVE_WEBKIT
2589   test $HAVE_XWIDGETS = yes ||
2590     AC_MSG_ERROR([xwidgets requested but WebKitGTK+ not found.])
2591
2592   XWIDGETS_OBJ=xwidget.o
2593   AC_DEFINE([HAVE_XWIDGETS], 1, [Define to 1 if you have xwidgets support.])
2594 fi
2595 AC_SUBST(XWIDGETS_OBJ)
2596
2597 CFLAGS=$OLD_CFLAGS
2598 LIBS=$OLD_LIBS
2599
2600 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2601 dnl other platforms.
2602 HAVE_DBUS=no
2603 DBUS_OBJ=
2604 if test "${with_dbus}" = "yes"; then
2605    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2606    if test "$HAVE_DBUS" = yes; then
2607      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2608      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2609      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2610      dnl D-Bus 1.5.12.
2611      OLD_LIBS=$LIBS
2612      LIBS="$LIBS $DBUS_LIBS"
2613      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2614                     dbus_type_is_valid \
2615                     dbus_validate_bus_name \
2616                     dbus_validate_path \
2617                     dbus_validate_interface \
2618                     dbus_validate_member)
2619      LIBS=$OLD_LIBS
2620      DBUS_OBJ=dbusbind.o
2621    fi
2622 fi
2623 AC_SUBST(DBUS_CFLAGS)
2624 AC_SUBST(DBUS_LIBS)
2625 AC_SUBST(DBUS_OBJ)
2626
2627 dnl GSettings has been tested under GNU/Linux only.
2628 HAVE_GSETTINGS=no
2629 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2630    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2631    if test "$HAVE_GSETTINGS" = "yes"; then
2632       old_CFLAGS=$CFLAGS
2633       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2634       old_LIBS=$LIBS
2635       LIBS="$LIBS $GSETTINGS_LIBS"
2636       AC_MSG_CHECKING([whether GSettings is in gio])
2637       AC_LINK_IFELSE(
2638          [AC_LANG_PROGRAM(
2639              [[/* Check that gsettings really is present.  */
2640              #include <glib-object.h>
2641              #include <gio/gio.h>
2642              ]],
2643              [[
2644                GSettings *settings;
2645                GVariant *val = g_settings_get_value (settings, "");
2646              ]])],
2647          [], HAVE_GSETTINGS=no)
2648       AC_MSG_RESULT([$HAVE_GSETTINGS])
2649
2650       if test "$HAVE_GSETTINGS" = "yes"; then
2651         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2652         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2653         SETTINGS_LIBS="$GSETTINGS_LIBS"
2654       fi
2655       CFLAGS=$old_CFLAGS
2656       LIBS=$old_LIBS
2657    fi
2658 fi
2659
2660 dnl GConf has been tested under GNU/Linux only.
2661 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2662 HAVE_GCONF=no
2663 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2664    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2665    if test "$HAVE_GCONF" = yes; then
2666       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2667       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2668       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2669       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2670    fi
2671 fi
2672
2673 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2674     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2675     if test "$HAVE_GOBJECT" = "yes"; then
2676        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2677        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2678     fi
2679     SAVE_CFLAGS="$CFLAGS"
2680     SAVE_LIBS="$LIBS"
2681     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2682     LIBS="$SETTINGS_LIBS $LIBS"
2683     CFLAGS="$SAVE_CFLAGS"
2684     LIBS="$SAVE_LIBS"
2685 fi
2686 AC_SUBST(SETTINGS_CFLAGS)
2687 AC_SUBST(SETTINGS_LIBS)
2688
2689
2690 dnl SELinux is available for GNU/Linux only.
2691 HAVE_LIBSELINUX=no
2692 LIBSELINUX_LIBS=
2693 if test "${with_selinux}" = "yes"; then
2694    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2695    if test "$HAVE_LIBSELINUX" = yes; then
2696       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2697       LIBSELINUX_LIBS=-lselinux
2698    fi
2699 fi
2700 AC_SUBST(LIBSELINUX_LIBS)
2701
2702 HAVE_GNUTLS=no
2703 if test "${with_gnutls}" = "yes" ; then
2704   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2705     [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2706   if test "${HAVE_GNUTLS}" = "yes"; then
2707     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2708     EMACS_CHECK_MODULES([LIBGNUTLS3], [gnutls >= 3.0.0],
2709       [AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])], [])
2710   fi
2711
2712   # Windows loads GnuTLS dynamically
2713   if test "${opsys}" = "mingw32"; then
2714     LIBGNUTLS_LIBS=
2715   fi
2716 fi
2717
2718 AC_SUBST(LIBGNUTLS_LIBS)
2719 AC_SUBST(LIBGNUTLS_CFLAGS)
2720
2721 NOTIFY_OBJ=
2722 NOTIFY_SUMMARY=no
2723
2724 dnl MS Windows native file monitor is available for mingw32 only.
2725 case $with_file_notification,$opsys in
2726   w32,cygwin)
2727     AC_MSG_ERROR(['--with-file-notification=w32' was specified, but
2728     this is only supported on MS-Windows native and MinGW32 builds.
2729     Consider using gfile instead.])
2730     ;;
2731   w32,* | yes,mingw32)
2732     AC_CHECK_HEADER(windows.h)
2733     if test "$ac_cv_header_windows_h" = yes ; then
2734        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2735        NOTIFY_OBJ=w32notify.o
2736        NOTIFY_SUMMARY="yes (w32)"
2737     fi ;;
2738 esac
2739
2740 dnl inotify is available only on GNU/Linux.
2741 case $with_file_notification,$NOTIFY_OBJ in
2742   inotify, | yes,)
2743     AC_CHECK_HEADER(sys/inotify.h)
2744     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2745         AC_CHECK_FUNC(inotify_init1)
2746         if test "$ac_cv_func_inotify_init1" = yes; then
2747           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2748           NOTIFY_OBJ=inotify.o
2749           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2750        fi
2751     fi ;;
2752 esac
2753
2754 dnl kqueue is available on BSD-like systems.
2755 case $with_file_notification,$NOTIFY_OBJ in
2756   kqueue,* | yes,)
2757     EMACS_CHECK_MODULES([KQUEUE], [libkqueue])
2758     if test "$HAVE_KQUEUE" = "yes"; then
2759        AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2760        CPPFLAGS="$CPPFLAGS -I/usr/include/kqueue"
2761        NOTIFY_CFLAGS=$KQUEUE_CFLAGS
2762        NOTIFY_LIBS=$KQUEUE_LIBS
2763        NOTIFY_OBJ=kqueue.o
2764        NOTIFY_SUMMARY="yes -lkqueue"
2765     else
2766        AC_SEARCH_LIBS(kqueue, [])
2767        if test "$ac_cv_search_kqueue" != no; then
2768          AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2769          NOTIFY_OBJ=kqueue.o
2770          NOTIFY_SUMMARY="yes (kqueue)"
2771        fi
2772     fi ;;
2773 esac
2774
2775 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2776 dnl has been added in glib 2.24.  It has been tested under
2777 dnl GNU/Linux only.
2778 case $with_file_notification,$NOTIFY_OBJ in
2779   gfile,* | yes,)
2780     if test "${HAVE_NS}" = yes; then
2781        AC_MSG_ERROR(['--with-file-notification=gfile' is not supported in NextStep builds.
2782 Consider kqueue instead.])
2783     else
2784        EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2785        if test "$HAVE_GFILENOTIFY" = "yes"; then
2786           AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2787           NOTIFY_CFLAGS=$GFILENOTIFY_CFLAGS
2788           NOTIFY_LIBS=$GFILENOTIFY_LIBS
2789           NOTIFY_OBJ=gfilenotify.o
2790           NOTIFY_SUMMARY="yes -lgio (gfile)"
2791        fi
2792     fi ;;
2793 esac
2794
2795 case $with_file_notification,$NOTIFY_OBJ in
2796   yes,* | no,* | *,?*) ;;
2797   *) AC_MSG_ERROR([File notification '$with_file_notification' requested but requirements not found.]) ;;
2798 esac
2799
2800 if test -n "$NOTIFY_OBJ"; then
2801    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2802 fi
2803 AC_SUBST(NOTIFY_CFLAGS)
2804 AC_SUBST(NOTIFY_LIBS)
2805 AC_SUBST(NOTIFY_OBJ)
2806
2807 dnl Do not put whitespace before the #include statements below.
2808 dnl Older compilers (eg sunos4 cc) choke on it.
2809 HAVE_XAW3D=no
2810 LUCID_LIBW=
2811 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2812   if test "$with_xaw3d" != no; then
2813     AC_CACHE_VAL(emacs_cv_xaw3d,
2814     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2815 #include <X11/Intrinsic.h>
2816 #include <X11/Xaw3d/Simple.h>]],
2817       [[]])],
2818       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2819                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2820       emacs_cv_xaw3d=no)])
2821   else
2822     emacs_cv_xaw3d=no
2823   fi
2824   if test $emacs_cv_xaw3d = yes; then
2825     AC_MSG_CHECKING(for xaw3d)
2826     AC_MSG_RESULT([yes; using Lucid toolkit])
2827     USE_X_TOOLKIT=LUCID
2828     HAVE_XAW3D=yes
2829     LUCID_LIBW=-lXaw3d
2830     AC_DEFINE(HAVE_XAW3D, 1,
2831               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2832   else
2833     AC_MSG_CHECKING(for xaw3d)
2834     AC_MSG_RESULT(no)
2835     AC_MSG_CHECKING(for libXaw)
2836     AC_CACHE_VAL(emacs_cv_xaw,
2837     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2838 #include <X11/Intrinsic.h>
2839 #include <X11/Xaw/Simple.h>]],
2840       [[]])],
2841       emacs_cv_xaw=yes,
2842       emacs_cv_xaw=no)])
2843     if test $emacs_cv_xaw = yes; then
2844       AC_MSG_RESULT([yes; using Lucid toolkit])
2845       USE_X_TOOLKIT=LUCID
2846       LUCID_LIBW=-lXaw
2847     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2848       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2849     else
2850       AC_MSG_ERROR([No X toolkit could be found.
2851 If you are sure you want Emacs compiled without an X toolkit, pass
2852   --with-x-toolkit=no
2853 to configure.  Otherwise, install the development libraries for the toolkit
2854 that you want to use (e.g. Gtk+) and re-run configure.])
2855     fi
2856   fi
2857 fi
2858
2859 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2860
2861 LIBXTR6=
2862 LIBXMU=
2863 if test "${USE_X_TOOLKIT}" != "none"; then
2864   AC_MSG_CHECKING(X11 toolkit version)
2865   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2866   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2867 [[#if XtSpecificationRelease < 6
2868 fail;
2869 #endif
2870 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2871   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2872   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2873     AC_MSG_RESULT(6 or newer)
2874     AC_DEFINE(HAVE_X11XTR6, 1,
2875               [Define to 1 if you have the X11R6 or newer version of Xt.])
2876     LIBXTR6="-lSM -lICE"
2877     case "$opsys" in
2878       ## Use libw.a along with X11R6 Xt.
2879       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2880     esac
2881   else
2882     AC_MSG_RESULT(before 6)
2883   fi
2884
2885 dnl If using toolkit, check whether libXmu.a exists.
2886 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2887   OLDLIBS="$LIBS"
2888   if test x$HAVE_X11XTR6 = xyes; then
2889     OTHERLIBS='-lXt -lSM -lICE'
2890   else
2891     OTHERLIBS='-lXt'
2892   fi
2893   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2894   if test "X$LIBS" != "X$OLDLIBS"; then
2895     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2896   fi
2897   LIBS=$OLDLIBS
2898   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2899 fi
2900 AC_SUBST(LIBXTR6)
2901 AC_SUBST(LIBXMU)
2902
2903 LIBXP=
2904 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2905   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2906   if test -d /usr/include/openmotif; then
2907     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2908     emacs_cv_openmotif=yes
2909     case "$canonical" in
2910       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2911       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2912       ;;
2913       *)
2914       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2915     esac
2916   else
2917     emacs_cv_openmotif=no
2918   fi
2919   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2920   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2921     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2922 int x = 5;
2923 #else
2924 Motif version prior to 2.1.
2925 #endif]])],
2926     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2927   if test $emacs_cv_motif_version_2_1 = yes; then
2928     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2929     if test x$emacs_cv_openmotif = xyes; then
2930       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2931     fi
2932   else
2933     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2934     # We put this in CFLAGS temporarily to precede other -I options
2935     # that might be in CFLAGS temporarily.
2936     # We put this in CPPFLAGS where it precedes the other -I options.
2937     OLD_CPPFLAGS=$CPPFLAGS
2938     OLD_CFLAGS=$CFLAGS
2939     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2940     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2941     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2942       [[int x = 5;]])],
2943       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2944     if test $emacs_cv_lesstif = yes; then
2945       # Make sure this -I option remains in CPPFLAGS after it is set
2946       # back to REAL_CPPFLAGS.
2947       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2948       # have those other -I options anyway.  Ultimately, having this
2949       # directory ultimately in CPPFLAGS will be enough.
2950       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2951       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2952     else
2953       CFLAGS=$OLD_CFLAGS
2954       CPPFLAGS=$OLD_CPPFLAGS
2955     fi
2956   fi
2957   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2958     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2959 fi
2960
2961 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2962 dnl using Motif or Xaw3d is available, and unless
2963 dnl --with-toolkit-scroll-bars=no was specified.
2964
2965 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2966             [Define to 1 if we should use toolkit scroll bars.])dnl
2967 USE_TOOLKIT_SCROLL_BARS=no
2968 if test "${with_toolkit_scroll_bars}" != "no"; then
2969   if test "${USE_X_TOOLKIT}" != "none"; then
2970     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2971       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2972       HAVE_XAW3D=no
2973       USE_TOOLKIT_SCROLL_BARS=yes
2974     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2975       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2976       USE_TOOLKIT_SCROLL_BARS=yes
2977     fi
2978   elif test "${HAVE_GTK}" = "yes"; then
2979     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2980     USE_TOOLKIT_SCROLL_BARS=yes
2981   elif test "${HAVE_NS}" = "yes"; then
2982     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2983     USE_TOOLKIT_SCROLL_BARS=yes
2984   elif test "${HAVE_W32}" = "yes"; then
2985     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2986     USE_TOOLKIT_SCROLL_BARS=yes
2987   fi
2988 fi
2989
2990 dnl See if XIM is available.
2991 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2992           #include <X11/Xlib.h>
2993           #include <X11/Xresource.h>]],
2994          [[XIMProc  callback;]])],
2995          [HAVE_XIM=yes
2996          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2997          HAVE_XIM=no)
2998
2999 dnl '--with-xim' now controls only the initial value of use_xim at run time.
3000
3001 if test "${with_xim}" != "no"; then
3002   AC_DEFINE(USE_XIM, 1,
3003             [Define to 1 if we should use XIM, if it is available.])
3004 fi
3005
3006
3007 if test "${HAVE_XIM}" != "no"; then
3008   late_CFLAGS=$CFLAGS
3009   if test "$GCC" = yes; then
3010     CFLAGS="$CFLAGS --pedantic-errors"
3011   fi
3012   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3013 #include <X11/Xlib.h>
3014 #include <X11/Xresource.h>]],
3015 [[Display *display;
3016 XrmDatabase db;
3017 char *res_name;
3018 char *res_class;
3019 XIMProc  callback;
3020 XPointer *client_data;
3021 #ifndef __GNUC__
3022 /* If we're not using GCC, it's probably not XFree86, and this is
3023    probably right, but we can't use something like --pedantic-errors.  */
3024 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
3025                                            char*, XIMProc, XPointer*);
3026 #endif
3027 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
3028    client_data);]])],
3029     [emacs_cv_arg6_star=yes])
3030   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
3031          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
3032 either XPointer or XPointer*.])dnl
3033   if test "$emacs_cv_arg6_star" = yes; then
3034     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
3035   else
3036     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
3037   fi
3038   CFLAGS=$late_CFLAGS
3039 fi
3040
3041 ### Start of font-backend (under any platform) section.
3042 # (nothing here yet -- this is a placeholder)
3043 ### End of font-backend (under any platform) section.
3044
3045 ### Start of font-backend (under X11) section.
3046 if test "${HAVE_X11}" = "yes"; then
3047     ## Use -lXft if available, unless '--with-xft=no'.
3048     HAVE_XFT=maybe
3049     if test "x${with_x}" = "xno"; then
3050       with_xft="no";
3051     fi
3052
3053     if test "$with_xft" != no; then
3054       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
3055       with_xft=$HAVE_FONTCONFIG
3056     fi
3057
3058     if test "x${with_xft}" != "xno"; then
3059
3060       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
3061       ## Because xftfont.c uses XRenderQueryExtension, we also
3062       ## need to link to -lXrender.
3063       HAVE_XRENDER=no
3064       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
3065       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
3066         OLD_CPPFLAGS="$CPPFLAGS"
3067         OLD_CFLAGS="$CFLAGS"
3068         OLD_LIBS="$LIBS"
3069         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
3070         CFLAGS="$CFLAGS $XFT_CFLAGS"
3071         XFT_LIBS="-lXrender $XFT_LIBS"
3072         LIBS="$XFT_LIBS $LIBS"
3073         AC_CHECK_HEADER(X11/Xft/Xft.h,
3074           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
3075           [[#include <X11/X.h>]])
3076
3077         if test "${HAVE_XFT}" = "yes"; then
3078           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
3079             AC_SUBST(XFT_LIBS)
3080           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
3081         fi                        # "${HAVE_XFT}" = "yes"
3082         CPPFLAGS=$OLD_CPPFLAGS
3083         CFLAGS=$OLD_CFLAGS
3084         LIBS=$OLD_LIBS
3085       fi                          # "$HAVE_XFT" != no
3086     fi                            # "x${with_xft}" != "xno"
3087
3088     ## We used to allow building with FreeType and without Xft.
3089     ## However, the ftx font backend driver is not in good shape.
3090     if test "$HAVE_XFT" != "yes"; then
3091        dnl For the "Does Emacs use" message at the end.
3092        HAVE_XFT=no
3093        HAVE_FREETYPE=no
3094     else
3095        dnl Strict linkers fail with
3096        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
3097        dnl if -lfreetype is not specified.
3098        dnl The following is needed to set FREETYPE_LIBS.
3099        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
3100
3101        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
3102     fi
3103
3104     HAVE_LIBOTF=no
3105     if test "${HAVE_FREETYPE}" = "yes"; then
3106       AC_DEFINE(HAVE_FREETYPE, 1,
3107                 [Define to 1 if using the freetype and fontconfig libraries.])
3108       if test "${with_libotf}" != "no"; then
3109         EMACS_CHECK_MODULES([LIBOTF], [libotf])
3110         if test "$HAVE_LIBOTF" = "yes"; then
3111           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
3112           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
3113                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
3114                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
3115           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
3116             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
3117                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
3118           fi
3119         fi
3120       fi
3121     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
3122     dnl Does the new font backend require it, or can it work without it?
3123     fi
3124
3125     HAVE_M17N_FLT=no
3126     if test "${HAVE_LIBOTF}" = yes; then
3127       if test "${with_m17n_flt}" != "no"; then
3128         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
3129         if test "$HAVE_M17N_FLT" = "yes"; then
3130           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
3131         fi
3132       fi
3133     fi
3134 else
3135     HAVE_XFT=no
3136     HAVE_FREETYPE=no
3137     HAVE_LIBOTF=no
3138     HAVE_M17N_FLT=no
3139 fi
3140
3141 ### End of font-backend (under X11) section.
3142
3143 AC_SUBST(FREETYPE_CFLAGS)
3144 AC_SUBST(FREETYPE_LIBS)
3145 AC_SUBST(FONTCONFIG_CFLAGS)
3146 AC_SUBST(FONTCONFIG_LIBS)
3147 AC_SUBST(LIBOTF_CFLAGS)
3148 AC_SUBST(LIBOTF_LIBS)
3149 AC_SUBST(M17N_FLT_CFLAGS)
3150 AC_SUBST(M17N_FLT_LIBS)
3151
3152 HAVE_CAIRO=no
3153 if test "${HAVE_X11}" = "yes"; then
3154   if test "${with_cairo}" != "no"; then
3155     CAIRO_REQUIRED=1.12.0
3156     CAIRO_MODULE="cairo >= $CAIRO_REQUIRED"
3157     EMACS_CHECK_MODULES(CAIRO, $CAIRO_MODULE)
3158     if test $HAVE_CAIRO = yes; then
3159       AC_DEFINE(USE_CAIRO, 1, [Define to 1 if using cairo.])
3160     else
3161       AC_MSG_ERROR([cairo requested but not found.])
3162     fi
3163
3164     CFLAGS="$CFLAGS $CAIRO_CFLAGS"
3165     LIBS="$LIBS $CAIRO_LIBS"
3166     AC_SUBST(CAIRO_CFLAGS)
3167     AC_SUBST(CAIRO_LIBS)
3168   fi
3169 fi
3170
3171 if test "${HAVE_X11}" = "yes"; then
3172   AC_CHECK_HEADER(X11/Xlib-xcb.h,
3173     AC_CHECK_LIB(xcb, xcb_translate_coordinates, HAVE_XCB=yes))
3174   if test "${HAVE_XCB}" = "yes"; then
3175     AC_CHECK_LIB(X11-xcb, XGetXCBConnection, HAVE_X11_XCB=yes)
3176     if test "${HAVE_X11_XCB}" = "yes"; then
3177       AC_DEFINE(USE_XCB, 1,
3178 [Define to 1 if you have the XCB library and X11-XCB library for mixed
3179    X11/XCB programming.])
3180       XCB_LIBS="-lX11-xcb -lxcb"
3181       AC_SUBST(XCB_LIBS)
3182     fi
3183   fi
3184 fi
3185
3186 ### Use -lXpm if available, unless '--with-xpm=no'.
3187 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
3188 ### In the Cygwin-w32 build, we need to use /usr/include/noX/X11/xpm.h
3189 ### rather than /usr/include/X11/xpm.h, so we set CPPFLAGS (and
3190 ### LDFLAGS) accordingly.
3191 HAVE_XPM=no
3192 LIBXPM=
3193 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3194   if test "${with_xpm}" != "no"; then
3195     SAVE_CPPFLAGS="$CPPFLAGS"
3196     SAVE_LDFLAGS="$LDFLAGS"
3197     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
3198     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3199     AC_CHECK_HEADER(X11/xpm.h,
3200       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3201     if test "${HAVE_XPM}" = "yes"; then
3202       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3203       AC_EGREP_CPP(no_return_alloc_pixels,
3204       [#include "X11/xpm.h"
3205 #ifndef XpmReturnAllocPixels
3206 no_return_alloc_pixels
3207 #endif
3208       ], HAVE_XPM=no, HAVE_XPM=yes)
3209
3210       if test "${HAVE_XPM}" = "yes"; then
3211         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3212         AC_MSG_RESULT(yes)
3213       else
3214         AC_MSG_RESULT(no)
3215         CPPFLAGS="$SAVE_CPPFLAGS"
3216         LDFLAGS="$SAVE_LDFLAGS"
3217       fi
3218     fi
3219   fi
3220
3221   if test "${HAVE_XPM}" = "yes"; then
3222     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3223     LIBXPM=-lXpm
3224   fi
3225 fi
3226
3227 if test "${HAVE_X11}" = "yes"; then
3228   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3229   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3230
3231   if test "${with_xpm}" != "no"; then
3232     AC_CHECK_HEADER(X11/xpm.h,
3233       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3234     if test "${HAVE_XPM}" = "yes"; then
3235       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3236       AC_EGREP_CPP(no_return_alloc_pixels,
3237       [#include "X11/xpm.h"
3238 #ifndef XpmReturnAllocPixels
3239 no_return_alloc_pixels
3240 #endif
3241       ], HAVE_XPM=no, HAVE_XPM=yes)
3242
3243       if test "${HAVE_XPM}" = "yes"; then
3244         AC_MSG_RESULT(yes)
3245       else
3246         AC_MSG_RESULT(no)
3247       fi
3248     fi
3249   fi
3250
3251   if test "${HAVE_XPM}" = "yes"; then
3252     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3253     LIBXPM=-lXpm
3254   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3255     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3256     LIBXPM=-lXpm
3257   fi
3258 fi
3259
3260 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3261 ### slightly different requirements wrt image libraries (it doesn't
3262 ### use -lXpm because it loads the xpm shared library dynamically at
3263 ### run time).
3264 if test "${opsys}" = "mingw32"; then
3265   if test "${with_xpm}" != "no"; then
3266     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3267 #define FOR_MSW 1])
3268   fi
3269
3270   if test "${HAVE_XPM}" = "yes"; then
3271     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3272   fi
3273 fi
3274
3275 AC_SUBST(LIBXPM)
3276
3277 ### Use -ljpeg if available, unless '--with-jpeg=no'.
3278 HAVE_JPEG=no
3279 LIBJPEG=
3280 if test "${with_jpeg}" != "no"; then
3281   AC_CACHE_CHECK([for jpeglib 6b or later],
3282     [emacs_cv_jpeglib],
3283     [OLD_LIBS=$LIBS
3284      for emacs_cv_jpeglib in yes -ljpeg no; do
3285        case $emacs_cv_jpeglib in
3286          yes) ;;
3287          no) break;;
3288          *) LIBS="$LIBS $emacs_cv_jpeglib";;
3289        esac
3290        AC_LINK_IFELSE(
3291          [AC_LANG_PROGRAM(
3292             [[#undef HAVE_STDLIB_H /* Avoid config.h/jpeglib.h collision.  */
3293               #include <stdio.h> /* jpeglib.h needs FILE and size_t.  */
3294               #include <jpeglib.h>
3295               #include <jerror.h>
3296               char verify[JPEG_LIB_VERSION < 62 ? -1 : 1];
3297               struct jpeg_decompress_struct cinfo;
3298             ]],
3299             [[
3300               jpeg_create_decompress (&cinfo);
3301               WARNMS (&cinfo, JWRN_JPEG_EOF);
3302               jpeg_destroy_decompress (&cinfo);
3303             ]])],
3304          [emacs_link_ok=yes],
3305          [emacs_link_ok=no])
3306        LIBS=$OLD_LIBS
3307        test $emacs_link_ok = yes && break
3308      done])
3309   if test "$emacs_cv_jpeglib" != no; then
3310     HAVE_JPEG=yes
3311     AC_DEFINE([HAVE_JPEG], 1,
3312       [Define to 1 if you have the jpeg library (typically -ljpeg).])
3313     ### mingw32 doesn't use -ljpeg, since it loads the library
3314     ### dynamically when needed, and doesn't want a run-time
3315     ### dependency on the jpeglib DLL.
3316     test "$emacs_cv_jpeglib" != yes && test "${opsys}" != "mingw32" \
3317     && LIBJPEG=$emacs_cv_jpeglib
3318   fi
3319 fi
3320 AC_SUBST(LIBJPEG)
3321
3322 HAVE_ZLIB=no
3323 LIBZ=
3324 if test "${with_zlib}" != "no"; then
3325   OLIBS=$LIBS
3326   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3327   LIBS=$OLIBS
3328   case $ac_cv_search_inflateEnd in
3329     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3330   esac
3331 fi
3332 if test "${HAVE_ZLIB}" = "yes"; then
3333   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3334   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3335   if test "${opsys}" = "mingw32"; then
3336      LIBZ=
3337   fi
3338 fi
3339 AC_SUBST(LIBZ)
3340
3341 ### Dynamic modules support
3342 LIBMODULES=
3343 HAVE_MODULES=no
3344 MODULES_OBJ=
3345 MODULES_SUFFIX=
3346 if test "${with_modules}" != "no"; then
3347   if test "$opsys" = "gnu-linux"; then
3348     LIBMODULES="-ldl"
3349     MODULES_SUFFIX=".so"
3350     HAVE_MODULES=yes
3351   elif test "$opsys" = "cygwin"; then
3352     MODULES_SUFFIX=".dll"
3353     HAVE_MODULES=yes
3354   elif test "$opsys" = "darwin"; then
3355     MODULES_SUFFIX=".so"
3356     HAVE_MODULES=yes
3357   elif test "$opsys" = "mingw32"; then
3358     MODULES_SUFFIX=".dll"
3359     HAVE_MODULES=yes
3360   else
3361     # BSD system have dlopen in the libc
3362     AC_CHECK_FUNC(dlopen, [MODULES_SUFFIX=".so"]
3363                           [HAVE_MODULES=yes], [])
3364   fi
3365
3366   if test "${HAVE_MODULES}" = no; then
3367     AC_MSG_ERROR([Dynamic modules are not supported on your system])
3368   else
3369     SAVE_LIBS=$LIBS
3370     LIBS="$LIBS $LIBMODULES"
3371     AC_CHECK_FUNCS([dlfunc])
3372     LIBS=$SAVE_LIBS
3373   fi
3374 fi
3375
3376 if test "${HAVE_MODULES}" = yes; then
3377    MODULES_OBJ="dynlib.o emacs-module.o"
3378    AC_DEFINE(HAVE_MODULES, 1, [Define to 1 if dynamic modules are enabled])
3379    AC_DEFINE_UNQUOTED(MODULES_SUFFIX, "$MODULES_SUFFIX",
3380      [System extension for dynamic libraries])
3381 fi
3382 AC_SUBST(MODULES_OBJ)
3383 AC_SUBST(LIBMODULES)
3384 AC_CHECK_FUNCS(dladdr)
3385
3386 ### Use -lpng if available, unless '--with-png=no'.
3387 HAVE_PNG=no
3388 LIBPNG=
3389 PNG_CFLAGS=
3390 if test "${NS_IMPL_COCOA}" = yes; then
3391   : # Nothing to do
3392 elif test "${with_png}" != no; then
3393   # mingw32 loads the library dynamically.
3394   if test "$opsys" = mingw32; then
3395     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3396   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3397     AC_MSG_CHECKING([for png])
3398     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3399     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3400       # libpng-config does not work; configure by hand.
3401       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3402       # in /usr/include/libpng.
3403       if test -r /usr/include/libpng/png.h &&
3404          test ! -r /usr/include/png.h; then
3405         png_cflags=-I/usr/include/libpng
3406       else
3407         png_cflags=
3408       fi
3409       png_libs='-lpng'
3410     }
3411     SAVE_CFLAGS=$CFLAGS
3412     SAVE_LIBS=$LIBS
3413     CFLAGS="$CFLAGS $png_cflags"
3414     LIBS="$png_libs -lz -lm $LIBS"
3415     AC_LINK_IFELSE(
3416       [AC_LANG_PROGRAM([[#include <png.h>]],
3417          [[return !png_get_channels (0, 0);]])],
3418       [HAVE_PNG=yes
3419        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3420        LIBPNG=$png_libs
3421        # $LIBPNG requires explicit -lz in some cases.
3422        # We don't know what those cases are, exactly, so play it safe and
3423        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3424        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3425          LIBPNG="$LIBPNG -lz"
3426        fi])
3427     CFLAGS=$SAVE_CFLAGS
3428     LIBS=$SAVE_LIBS
3429     AC_MSG_RESULT([$HAVE_PNG])
3430   fi
3431 fi
3432 if test $HAVE_PNG = yes; then
3433   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3434
3435   SAVE_CFLAGS=$CFLAGS
3436   CFLAGS="$CFLAGS $PNG_CFLAGS"
3437   AC_CHECK_DECL([png_longjmp],
3438     [],
3439     [AC_DEFINE([PNG_DEPSTRUCT], [],
3440        [Define to empty to suppress deprecation warnings when building
3441         with --enable-gcc-warnings and with libpng versions before 1.5,
3442         which lack png_longjmp.])],
3443     [[#include <png.h>
3444     ]])
3445   CFLAGS=$SAVE_CFLAGS
3446 fi
3447 AC_SUBST(LIBPNG)
3448 AC_SUBST(PNG_CFLAGS)
3449
3450 ### Use -ltiff if available, unless '--with-tiff=no'.
3451 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3452 HAVE_TIFF=no
3453 LIBTIFF=
3454 if test "${opsys}" = "mingw32"; then
3455   if test "${with_tiff}" != "no"; then
3456     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3457   fi
3458   if test "${HAVE_TIFF}" = "yes"; then
3459     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3460   fi
3461 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3462   if test "${with_tiff}" != "no"; then
3463     AC_CHECK_HEADER(tiffio.h,
3464       [tifflibs="-lz -lm"
3465       # At least one tiff package requires the jpeg library.
3466       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3467       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3468   fi
3469
3470   if test "${HAVE_TIFF}" = "yes"; then
3471     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3472     dnl FIXME -lz -lm, as per libpng?
3473     LIBTIFF=-ltiff
3474   fi
3475 fi
3476 AC_SUBST(LIBTIFF)
3477
3478 ### Use -lgif or -lungif if available, unless '--with-gif=no'.
3479 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3480 HAVE_GIF=no
3481 LIBGIF=
3482 if test "${opsys}" = "mingw32"; then
3483   if test "${with_gif}" != "no"; then
3484     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3485   fi
3486   if test "${HAVE_GIF}" = "yes"; then
3487     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3488   fi
3489 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3490         || test "${HAVE_W32}" = "yes"; then
3491   AC_CHECK_HEADER(gif_lib.h,
3492 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3493 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3494     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3495         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3496
3497   if test "$HAVE_GIF" = yes; then
3498     LIBGIF=-lgif
3499   elif test "$HAVE_GIF" = maybe; then
3500 # If gif_lib.h but no libgif, try libungif.
3501     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3502     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3503   fi
3504
3505   if test "${HAVE_GIF}" = "yes"; then
3506     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3507   fi
3508 fi
3509 AC_SUBST(LIBGIF)
3510
3511 dnl Check for required libraries.
3512 if test "${HAVE_X11}" = "yes"; then
3513   MISSING=""
3514   WITH_NO=""
3515   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3516     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3517   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3518     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3519   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3520     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3521   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3522     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3523   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3524     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3525
3526   if test "X${MISSING}" != X; then
3527     AC_MSG_ERROR([The following required libraries were not found:
3528     $MISSING
3529 Maybe some development libraries/packages are missing?
3530 If you don't want to link with them give
3531     $WITH_NO
3532 as options to configure])
3533   fi
3534 fi
3535
3536 ### Use -lgpm if available, unless '--with-gpm=no'.
3537 HAVE_GPM=no
3538 LIBGPM=
3539 if test "${with_gpm}" != "no"; then
3540   AC_CHECK_HEADER(gpm.h,
3541     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3542
3543   if test "${HAVE_GPM}" = "yes"; then
3544     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3545     LIBGPM=-lgpm
3546   fi
3547 fi
3548 AC_SUBST(LIBGPM)
3549
3550 dnl Check for malloc/malloc.h on darwin
3551 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3552
3553 GNUSTEP_CFLAGS=
3554 ### Use NeXTstep API to implement GUI.
3555 if test "${HAVE_NS}" = "yes"; then
3556   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3557   if test "${NS_IMPL_COCOA}" = "yes"; then
3558     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3559   fi
3560   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3561     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3562     if test $NS_GNUSTEP_CONFIG != yes; then
3563       # See also .m.o rule in src/Makefile.in.  */
3564       # FIXME: are all these flags really needed?  Document here why.  */
3565       GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3566       ## Extra CFLAGS applied to src/*.m files.
3567       GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3568     fi
3569   fi
3570   OTHER_FILES=ns-app
3571 fi
3572
3573 ### Use session management (-lSM -lICE) if available
3574 HAVE_X_SM=no
3575 LIBXSM=
3576 if test "${HAVE_X11}" = "yes"; then
3577   AC_CHECK_HEADER(X11/SM/SMlib.h,
3578     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3579
3580   if test "${HAVE_X_SM}" = "yes"; then
3581     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3582     LIBXSM="-lSM -lICE"
3583   fi
3584 fi
3585 AC_SUBST(LIBXSM)
3586
3587 ### Use XRandr (-lXrandr) if available
3588 HAVE_XRANDR=no
3589 if test "${HAVE_X11}" = "yes"; then
3590   XRANDR_REQUIRED=1.2.2
3591   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3592   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3593   if test $HAVE_XRANDR = no; then
3594     # Test old way in case pkg-config doesn't have it (older machines).
3595     # Include Xrender.h by hand to work around bug in older Xrandr.h
3596     # (e.g. RHEL5) and silence (harmless) configure warning (bug#18465).
3597     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3598       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)],
3599       [], [AC_INCLUDES_DEFAULT
3600 #include <X11/extensions/Xrender.h>])
3601     if test $HAVE_XRANDR = yes; then
3602       XRANDR_LIBS=-lXrandr
3603     fi
3604   fi
3605   if test $HAVE_XRANDR = yes; then
3606     SAVE_CFLAGS="$CFLAGS"
3607     SAVE_LIBS="$LIBS"
3608     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3609     LIBS="$XRANDR_LIBS $LIBS"
3610     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3611     CFLAGS="$SAVE_CFLAGS"
3612     LIBS="$SAVE_LIBS"
3613
3614     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3615   fi
3616 fi
3617 AC_SUBST(XRANDR_CFLAGS)
3618 AC_SUBST(XRANDR_LIBS)
3619
3620 ### Use Xinerama (-lXinerama) if available
3621 HAVE_XINERAMA=no
3622 if test "${HAVE_X11}" = "yes"; then
3623   XINERAMA_REQUIRED=1.0.2
3624   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3625   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3626   if test $HAVE_XINERAMA = no; then
3627     # Test old way in case pkg-config doesn't have it (older machines).
3628     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3629       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3630     if test $HAVE_XINERAMA = yes; then
3631       XINERAMA_LIBS=-lXinerama
3632     fi
3633   fi
3634   if test $HAVE_XINERAMA = yes; then
3635     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3636   fi
3637 fi
3638 AC_SUBST(XINERAMA_CFLAGS)
3639 AC_SUBST(XINERAMA_LIBS)
3640
3641 ### Use Xfixes (-lXfixes) if available
3642 HAVE_XFIXES=no
3643 if test "${HAVE_X11}" = "yes"; then
3644   XFIXES_REQUIRED=4.0.0
3645   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3646   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3647   if test $HAVE_XFIXES = no; then
3648     # Test old way in case pkg-config doesn't have it (older machines).
3649     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3650       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3651     if test $HAVE_XFIXES = yes; then
3652       XFIXES_LIBS=-lXfixes
3653     fi
3654   fi
3655   if test $HAVE_XFIXES = yes; then
3656     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3657   fi
3658 fi
3659 AC_SUBST(XFIXES_CFLAGS)
3660 AC_SUBST(XFIXES_LIBS)
3661
3662 ### Use libxml (-lxml2) if available
3663 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3664 HAVE_LIBXML2=no
3665 if test "${with_xml2}" != "no"; then
3666   ### I'm not sure what the version number should be, so I just guessed.
3667   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3668   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3669   if test "${HAVE_LIBXML2}" != "yes" && test "$opsys" = "darwin"; then
3670     SAVE_CPPFLAGS="$CPPFLAGS"
3671     if test -z "$xcsdkdir" -a -n "$XCRUN" -a ! -d /usr/include; then
3672       dnl /usr/include is not found.  Try Xcode SDK dir if it is sane.
3673       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
3674       case $xcsdkdir in
3675         *[[\\\"\#\$\&\'\`$am_lf\ \      ]]*)
3676         xcsdkdir="" ;;
3677       esac
3678     fi
3679     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3680     AC_CHECK_HEADER(libxml/HTMLparser.h,
3681       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3682                      [#include <libxml/HTMLparser.h>])])
3683     CPPFLAGS="$SAVE_CPPFLAGS"
3684     if test "${HAVE_LIBXML2}" = "yes"; then
3685       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3686       LIBXML2_LIBS="-lxml2"
3687     fi
3688   fi
3689   if test "${HAVE_LIBXML2}" = "yes"; then
3690     if test "${opsys}" != "mingw32"; then
3691       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no,
3692         [$LIBXML2_LIBS])
3693     else
3694       LIBXML2_LIBS=""
3695     fi
3696     if test "${HAVE_LIBXML2}" = "yes"; then
3697       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3698     else
3699       LIBXML2_LIBS=""
3700       LIBXML2_CFLAGS=""
3701     fi
3702   fi
3703 fi
3704 AC_SUBST(LIBXML2_LIBS)
3705 AC_SUBST(LIBXML2_CFLAGS)
3706
3707 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3708 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3709 if test "${opsys}" = "mingw32"; then
3710   emacs_cv_netdb_declares_h_errno=yes
3711 fi
3712 AC_CACHE_CHECK(whether netdb declares h_errno,
3713                emacs_cv_netdb_declares_h_errno,
3714 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3715   [[return h_errno;]])],
3716   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3717 if test $emacs_cv_netdb_declares_h_errno = yes; then
3718   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3719 fi
3720
3721 # Check for mail-locking functions in a "mail" library.  Probably this should
3722 # have the same check as for liblockfile below.
3723 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3724 if test $have_mail = yes; then
3725   LIBS_MAIL=-lmail
3726   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the 'mail' library (-lmail).])
3727
3728   OLD_LIBS=$LIBS
3729   LIBS="$LIBS_MAIL $LIBS"
3730   AC_CHECK_FUNCS(touchlock)
3731   LIBS=$OLD_LIBS
3732 else
3733   LIBS_MAIL=
3734 fi
3735 dnl Debian, at least:
3736 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3737 if test $have_lockfile = yes; then
3738    LIBS_MAIL=-llockfile
3739    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the 'lockfile' library (-llockfile).])
3740 else
3741 # If we have the shared liblockfile, assume we must use it for mail
3742 # locking (e.g. Debian).  If we couldn't link against liblockfile
3743 # (no liblockfile.a installed), ensure that we don't need to.
3744   dnl This works for files generally, not just executables.
3745   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3746   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3747                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3748   if test $ac_cv_prog_liblockfile = yes; then
3749     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3750 This probably means that movemail could lose mail.
3751 There may be a 'development' package to install containing liblockfile.])
3752   fi
3753 fi
3754 AC_CHECK_HEADERS_ONCE(maillock.h)
3755 AC_SUBST(LIBS_MAIL)
3756
3757 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3758 ## interlock access to the mail spool.  The alternative is a lock file named
3759 ## /usr/spool/mail/$USER.lock.
3760 mail_lock=no
3761 case "$opsys" in
3762   aix4-2) mail_lock="lockf" ;;
3763
3764   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3765
3766   ## On GNU/Linux systems, both methods are used by various mail programs.
3767   ## I assume most people are using newer mailers that have heard of flock.
3768   ## Change this if you need to.
3769   ## Debian contains a patch which says: "On Debian/GNU/Linux systems,
3770   ## configure gets the right answers, and that means *NOT* using flock.
3771   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3772   ## for details." and then uses '#ifdef DEBIAN'.  Unfortunately the
3773   ## Debian maintainer hasn't provided a clean fix for Emacs.
3774   ## movemail.c will use 'maillock' when MAILDIR, HAVE_LIBMAIL and
3775   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3776   ## correct logic.  -- fx
3777   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3778   ## liblockfile is a Free Software replacement for libmail, used on
3779   ## Debian systems and elsewhere. -rfr.
3780   gnu-*)
3781     mail_lock="flock"
3782     if test $have_mail = yes || test $have_lockfile = yes; then
3783       test $ac_cv_header_maillock_h = yes && mail_lock=no
3784     fi
3785     ;;
3786
3787   mingw32)
3788     mail_lock="none-needed" ;;
3789 esac
3790
3791 BLESSMAIL_TARGET=
3792 case "$mail_lock" in
3793   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3794
3795   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3796
3797   none-needed) ;;
3798
3799   *) BLESSMAIL_TARGET="need-blessmail" ;;
3800 esac
3801 AC_SUBST(BLESSMAIL_TARGET)
3802
3803 OLD_LIBS=$LIBS
3804 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3805 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3806 getrusage get_current_dir_name \
3807 lrand48 random rint \
3808 select getpagesize setlocale newlocale \
3809 getrlimit setrlimit shutdown getaddrinfo \
3810 pthread_sigmask strsignal setitimer \
3811 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3812 gai_strerror sync \
3813 getpwent endpwent getgrent endgrent \
3814 cfmakeraw cfsetspeed copysign __executable_start log2)
3815 LIBS=$OLD_LIBS
3816
3817 dnl No need to check for aligned_alloc and posix_memalign if using
3818 dnl gmalloc.o, as it supplies them, unless we're using hybrid_malloc.
3819 dnl Don't use these functions on Darwin as they are incompatible with
3820 dnl unexmacosx.c.
3821 if (test -z "$GMALLOC_OBJ" || test "$hybrid_malloc" = yes) \
3822   && test "$opsys" != darwin; then
3823   AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3824 fi
3825
3826 dnl Cannot use AC_CHECK_FUNCS
3827 AC_CACHE_CHECK([for __builtin_unwind_init],
3828                emacs_cv_func___builtin_unwind_init,
3829 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3830                 emacs_cv_func___builtin_unwind_init=yes,
3831                 emacs_cv_func___builtin_unwind_init=no)])
3832 if test $emacs_cv_func___builtin_unwind_init = yes; then
3833   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3834             [Define to 1 if you have the '__builtin_unwind_init' function.])
3835 fi
3836
3837 AC_CHECK_HEADERS_ONCE(sys/un.h)
3838
3839 AC_FUNC_FSEEKO
3840
3841 # UNIX98 PTYs.
3842 AC_CHECK_FUNCS(grantpt)
3843
3844 # PTY-related GNU extensions.
3845 AC_CHECK_FUNCS(getpt posix_openpt)
3846
3847 # Check this now, so that we will NOT find the above functions in ncurses.
3848 # That is because we have not set up to link ncurses in lib-src.
3849 # It's better to believe a function is not available
3850 # than to expect to find it in ncurses.
3851 # Also we need tputs and friends to be able to build at all.
3852 AC_MSG_CHECKING([for library containing tputs])
3853 # Run a test program that contains a call to tputs, a call that is
3854 # never executed.  This tests whether a pre-'main' dynamic linker
3855 # works with the library.  It's too much trouble to actually call
3856 # tputs in the test program, due to portability hassles.  When
3857 # cross-compiling, assume the test program will run if it links.
3858 AC_DEFUN([tputs_link_source], [
3859   AC_LANG_SOURCE(
3860      [[extern void tputs (const char *, int, int (*)(int));
3861        int main (int argc, char **argv)
3862        {
3863           if (argc == 10000)
3864             tputs (argv[0], 0, 0);
3865           return 0;
3866        }]])
3867 ])
3868 if test "${opsys}" = "mingw32"; then
3869   msg='none required'
3870 else
3871   # Maybe curses should be tried earlier?
3872   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3873   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3874     OLIBS=$LIBS
3875     if test -z "$tputs_library"; then
3876       LIBS_TERMCAP=
3877       msg='none required'
3878     else
3879       LIBS_TERMCAP=-l$tputs_library
3880       msg=$LIBS_TERMCAP
3881       LIBS="$LIBS_TERMCAP $LIBS"
3882     fi
3883     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3884       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3885     LIBS=$OLIBS
3886     if test "X$msg" != Xno; then
3887       break
3888     fi
3889   done
3890 fi
3891 AC_MSG_RESULT([$msg])
3892 if test "X$msg" = Xno; then
3893   AC_MSG_ERROR([The required function 'tputs' was not found in any library.
3894 The following libraries were tried (in order):
3895   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3896 Please try installing whichever of these libraries is most appropriate
3897 for your system, together with its header files.
3898 For example, a libncurses-dev(el) or similar package.])
3899 fi
3900
3901 ## Use termcap instead of terminfo?
3902 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3903 TERMINFO=yes
3904 ## FIXME?  In the cases below where we unconditionally set
3905 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3906 ## if that was found above to have tputs.
3907 ## Should we use the gnu* logic everywhere?
3908 case "$opsys" in
3909   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3910   ##  The ncurses library has been moved out of the System framework in
3911   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3912   ##  option to use it.
3913   darwin) LIBS_TERMCAP="-lncurses" ;;
3914
3915   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3916
3917   freebsd)
3918     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3919     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3920     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3921 [[#if __FreeBSD_version < 400000
3922 fail;
3923 #endif
3924 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3925
3926     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3927
3928     if test $emacs_cv_freebsd_terminfo = yes; then
3929       LIBS_TERMCAP="-lncurses"
3930     else
3931       TERMINFO=no
3932       LIBS_TERMCAP="-ltermcap"
3933     fi
3934     ;;
3935
3936   mingw32)
3937     TERMINFO=no
3938     LIBS_TERMCAP=
3939     ;;
3940
3941   netbsd)
3942     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3943       TERMINFO=no
3944       LIBS_TERMCAP="-ltermcap"
3945     fi
3946     ;;
3947
3948   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3949
3950   ## hpux: Make sure we get select from libc rather than from libcurses
3951   ##  because libcurses on HPUX 10.10 has a broken version of select.
3952   ##  We used to use -lc -lcurses, but this may be cleaner.
3953   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3954   # set that way, now it uses the default).  Isn't this a contradiction?
3955   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3956
3957 esac
3958
3959 TERMCAP_OBJ=tparam.o
3960 if test $TERMINFO = yes; then
3961   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3962   TERMCAP_OBJ=terminfo.o
3963 fi
3964 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3965   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3966 fi
3967 AC_SUBST(LIBS_TERMCAP)
3968 AC_SUBST(TERMCAP_OBJ)
3969
3970 # GNU/Linux-specific timer functions.
3971 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
3972   [AC_COMPILE_IFELSE(
3973      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
3974                       ]],
3975                       [[timerfd_create (CLOCK_REALTIME,
3976                                         TFD_CLOEXEC | TFD_NONBLOCK);
3977                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
3978      [emacs_cv_have_timerfd=yes],
3979      [emacs_cv_have_timerfd=no])])
3980 if test "$emacs_cv_have_timerfd" = yes; then
3981   AC_DEFINE([HAVE_TIMERFD], 1,
3982     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
3983 fi
3984
3985 # Alternate stack for signal handlers.
3986 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
3987                [emacs_cv_alternate_stack],
3988   [AC_COMPILE_IFELSE(
3989      [AC_LANG_PROGRAM([[#include <signal.h>
3990                       ]],
3991                       [[stack_t ss;
3992                         struct sigaction sa;
3993                         ss.ss_sp = malloc (SIGSTKSZ);
3994                         ss.ss_size = SIGSTKSZ;
3995                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
3996                         sigaltstack (&ss, 0);
3997                         sigaction (SIGSEGV, &sa, 0);]])],
3998      [emacs_cv_alternate_stack=yes],
3999      [emacs_cv_alternate_stack=no])])
4000
4001 # Do we have res_init, for detecting changes in /etc/resolv.conf?
4002 # On Darwin, res_init appears not to be useful: see bug#562 and
4003 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
4004 resolv=no
4005
4006 if test $opsys != darwin; then
4007
4008   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
4009 #include <arpa/nameser.h>
4010 #include <resolv.h>]],
4011     [[return res_init();]])],
4012     have_res_init=yes, have_res_init=no)
4013   if test "$have_res_init" = no; then
4014     OLIBS="$LIBS"
4015     LIBS="$LIBS -lresolv"
4016     AC_MSG_CHECKING(for res_init with -lresolv)
4017     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
4018 #include <arpa/nameser.h>
4019 #include <resolv.h>]],
4020       [[return res_init();]])],
4021       have_res_init=yes, have_res_init=no)
4022     AC_MSG_RESULT($have_res_init)
4023     if test "$have_res_init" = yes ; then
4024       resolv=yes
4025     fi
4026     LIBS="$OLIBS"
4027   fi
4028
4029   if test "$have_res_init" = yes; then
4030     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
4031   fi
4032 fi                              dnl !darwin
4033
4034 # Do we need the Hesiod library to provide the support routines?
4035 dnl FIXME?  Should we be skipping this on Darwin too?
4036 LIBHESIOD=
4037 if test "$with_hesiod" != no ; then
4038   # Don't set $LIBS here -- see comments above.  FIXME which comments?
4039   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
4040      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
4041                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
4042   if test "$resolv" = yes ; then
4043     RESOLVLIB=-lresolv
4044   else
4045     RESOLVLIB=
4046   fi
4047   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
4048         hesiod=yes, :, $RESOLVLIB)])
4049
4050   if test x"$hesiod" = xyes; then
4051     LIBHESIOD=-lhesiod
4052   fi
4053 fi
4054 AC_SUBST(LIBHESIOD)
4055
4056 # Do we need libresolv (due to res_init or Hesiod)?
4057 if test "$resolv" = yes && test $opsys != darwin; then
4058   LIBRESOLV=-lresolv
4059 else
4060   LIBRESOLV=
4061 fi
4062 AC_SUBST(LIBRESOLV)
4063
4064 # These tell us which Kerberos-related libraries to use.
4065 COM_ERRLIB=
4066 CRYPTOLIB=
4067 KRB5LIB=
4068 DESLIB=
4069 KRB4LIB=
4070
4071 if test "${with_kerberos}" != no; then
4072   OLD_LIBS=$LIBS
4073   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
4074   if test $have_com_err = yes; then
4075     COM_ERRLIB=-lcom_err
4076     LIBS="$COM_ERRLIB $LIBS"
4077   fi
4078   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
4079   if test $have_crypto = yes; then
4080     CRYPTOLIB=-lcrypto
4081     LIBS="$CRYPTOLIB $LIBS"
4082   fi
4083   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
4084   if test $have_k5crypto = yes; then
4085     CRYPTOLIB=-lk5crypto
4086     LIBS="$CRYPTOLIB $LIBS"
4087   fi
4088   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
4089   if test $have_krb5=yes; then
4090     KRB5LIB=-lkrb5
4091     LIBS="$KRB5LIB $LIBS"
4092   fi
4093   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
4094   if test "${with_kerberos5}" = no; then
4095     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
4096     if test $have_des425 = yes; then
4097       DESLIB=-ldes425
4098       LIBS="$DESLIB $LIBS"
4099     else
4100       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
4101       if test $have_des = yes; then
4102         DESLIB=-ldes
4103         LIBS="$DESLIB $LIBS"
4104       fi
4105     fi
4106     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
4107     if test $have_krb4 = yes; then
4108       KRB4LIB=-lkrb4
4109       LIBS="$KRB4LIB $LIBS"
4110     else
4111       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
4112       if test $have_krb = yes; then
4113         KRB4LIB=-lkrb
4114         LIBS="$KRB4LIB $LIBS"
4115       fi
4116     fi
4117   fi
4118
4119   if test "${with_kerberos5}" != no; then
4120     AC_CHECK_HEADERS(krb5.h,
4121       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
4122                         [#include <krb5.h>])])
4123   else
4124     AC_CHECK_HEADERS(krb.h,,
4125                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
4126                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
4127   fi
4128   AC_CHECK_HEADERS(com_err.h)
4129   LIBS=$OLD_LIBS
4130 fi
4131
4132 AC_SUBST(COM_ERRLIB)
4133 AC_SUBST(CRYPTOLIB)
4134 AC_SUBST(KRB5LIB)
4135 AC_SUBST(DESLIB)
4136 AC_SUBST(KRB4LIB)
4137
4138 AC_CHECK_HEADERS(valgrind/valgrind.h)
4139
4140 AC_CHECK_MEMBERS([struct unipair.unicode], [], [], [[#include <linux/kd.h>]])
4141
4142 AC_CHECK_FUNCS_ONCE(tzset)
4143
4144 ok_so_far=yes
4145 AC_CHECK_FUNC(socket, , ok_so_far=no)
4146 if test $ok_so_far = yes; then
4147   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
4148 fi
4149 if test $ok_so_far = yes; then
4150   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
4151 fi
4152 if test $ok_so_far = yes; then
4153 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
4154   AC_DEFINE(HAVE_INET_SOCKETS, 1,
4155             [Define to 1 if you have inet sockets.])
4156 fi
4157
4158 AC_FUNC_FORK
4159
4160 AC_CHECK_FUNCS(snprintf)
4161
4162 dnl Check for glib.  This differs from other library checks in that
4163 dnl Emacs need not link to glib unless some other library is already
4164 dnl linking to glib.  Although glib provides no facilities that Emacs
4165 dnl needs for its own purposes, when glib is present Emacs needs to
4166 dnl use primitives like g_main_context_query to avoid clashing with
4167 dnl glib at a low level.
4168 dnl
4169 dnl Check this late, since it depends on $GTK_CFLAGS etc.
4170 XGSELOBJ=
4171 OLDCFLAGS="$CFLAGS"
4172 OLDLIBS="$LIBS"
4173 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
4174 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
4175 CFLAGS="$CFLAGS $NOTIFY_CFLAGS $CAIRO_CFLAGS"
4176 LIBS="$LIBS $NOTIFY_LIBS $CAIRO_LIBS"
4177 AC_MSG_CHECKING([whether GLib is linked in])
4178 AC_LINK_IFELSE([AC_LANG_PROGRAM(
4179         [[#include <glib.h>
4180         ]],
4181         [[g_print ("Hello world");]])],
4182      [links_glib=yes],
4183      [links_glib=no])
4184 AC_MSG_RESULT([$links_glib])
4185 if test "${links_glib}" = "yes"; then
4186   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
4187   if test "$HAVE_NS" = no;then
4188     XGSELOBJ=xgselect.o
4189   fi
4190 fi
4191 CFLAGS="$OLDCFLAGS"
4192 LIBS="$OLDLIBS"
4193 AC_SUBST(XGSELOBJ)
4194
4195 dnl Adapted from Haible's version.
4196 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
4197   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
4198     [[char* cs = nl_langinfo(CODESET);]])],
4199     emacs_cv_langinfo_codeset=yes,
4200     emacs_cv_langinfo_codeset=no)
4201   ])
4202 if test $emacs_cv_langinfo_codeset = yes; then
4203   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
4204     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
4205 fi
4206
4207 AC_TYPE_MBSTATE_T
4208
4209 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
4210 dnl how the tty code is related to POSIX and/or other versions of termios.
4211 dnl The following looks like a useful start.
4212 dnl
4213 dnl AC_SYS_POSIX_TERMIOS
4214 dnl if test $ac_cv_sys_posix_termios = yes; then
4215 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
4216 dnl                                and macros for terminal control.])
4217 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
4218 dnl fi
4219
4220 dnl Turned on June 1996 supposing nobody will mind it.
4221 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
4222 if test "${opsys}" != "mingw32"; then
4223    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
4224      in the full name stands for the login id.])
4225 fi
4226
4227 dnl Everybody supports this, except MS.
4228 dnl Seems like the kind of thing we should be testing for, though.
4229 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4230 if test "${opsys}" != "mingw32"; then
4231   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4232 fi
4233
4234 dnl Everybody supports this, except MS-DOS.
4235 dnl Seems like the kind of thing we should be testing for, though.
4236 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4237 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4238   4.2-compatible sockets.])
4239
4240 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4241
4242 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4243   a null file, or a data sink.])
4244 if test "${opsys}" = "mingw32"; then
4245   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4246 else
4247   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4248 fi
4249
4250 if test "${opsys}" = "mingw32"; then
4251   SEPCHAR=';'
4252 else
4253   SEPCHAR=':'
4254 fi
4255 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4256 dnl This is for MinGW, and is used in test/Makefile.in.
4257 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4258 dnl decides that a command-line argument to be passed to a MinGW program
4259 dnl is a PATH-style list of directories.  But that heuristics plays it
4260 dnl safe, and only does the replacement when it is _absolutely_ sure it
4261 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4262 dnl which breaks in-tree builds.  So we do this manually instead.
4263 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4264 dnl be computed as ':' in MSYS Bash.
4265 AC_SUBST(SEPCHAR)
4266
4267 dnl Everybody supports this, except MS-DOS.
4268 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4269
4270 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4271
4272
4273 AC_DEFINE(DIRECTORY_SEP, ['/'],
4274   [Character that separates directories in a file name.])
4275
4276 if test "${opsys}" = "mingw32"; then
4277   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4278     [Returns true if character is a device separator.])
4279
4280   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4281     [Returns true if character is a directory separator.])
4282
4283   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4284     [Returns true if character is any form of separator.])
4285 else
4286   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4287     [Returns true if character is a device separator.])
4288
4289   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4290     [Returns true if character is a directory separator.])
4291
4292   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4293     [Returns true if character is any form of separator.])
4294 fi
4295
4296 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4297
4298 case $opsys in
4299   aix4-2)
4300     dnl Unfortunately without libXmu we cannot support EditRes.
4301     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4302       AC_DEFINE(NO_EDITRES, 1)
4303     fi
4304     ;;
4305
4306   hpux*)
4307     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4308     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4309     AC_DEFINE(NO_EDITRES, 1)
4310     ;;
4311 esac
4312
4313
4314 case $opsys in
4315   irix6-5 | sol2* | unixware )
4316     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4317     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4318     dnl need the constant to dimension an array.  So wire in the appropriate
4319     dnl value here.
4320     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4321     ;;
4322 esac
4323
4324 emacs_broken_SIGIO=no
4325
4326 case $opsys in
4327   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4328   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4329   hpux* | irix6-5 | nacl | openbsd | sol2* | unixware )
4330     emacs_broken_SIGIO=yes
4331     ;;
4332
4333   aix4-2)
4334     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4335     dnl the way this system works, libc functions that return malloced
4336     dnl memory use the libc malloc implementation. Calling xfree or
4337     dnl xrealloc on the results of such functions results in a crash.
4338     dnl
4339     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4340     dnl but that does not currently work on this system.
4341     dnl
4342     dnl It is possible to completely override the malloc implementation on
4343     dnl AIX, but that involves putting the malloc functions in a shared
4344     dnl library and setting the MALLOCTYPE environment variable to point to
4345     dnl that shared library.
4346     dnl
4347     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4348     dnl to avoid a crash just use the Emacs implementation for that function.
4349     dnl
4350     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4351     dnl of this file, so that we do not check for get_current_dir_name
4352     dnl on AIX.  But that might be fragile if something else ends
4353     dnl up testing for get_current_dir_name as a dependency.
4354     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4355       get_current_dir_name should not be used.])
4356     ;;
4357
4358   freebsd)
4359     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4360     dnl writes/reads on a PTY, read(2) returns bogus data:
4361     dnl
4362     dnl write(2)  1022 bytes
4363     dnl write(2)   954 bytes, get EAGAIN
4364     dnl read(2)   1024 bytes in process_read_output
4365     dnl read(2)     11 bytes in process_read_output
4366     dnl
4367     dnl That is, read(2) returns more bytes than have ever been written
4368     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4369     dnl successfully after processing (for example with CRs added if the
4370     dnl terminal is set up that way which it is here).  The same bytes will
4371     dnl be seen again in a later read(2), without the CRs.
4372     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4373       work around an issue when reading from a PTY.])
4374     ;;
4375 esac
4376
4377 case $opsys in
4378   gnu-* | sol2-10 )
4379     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4380     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4381   ;;
4382 esac
4383
4384 case $opsys in
4385   darwin | dragonfly | freebsd | netbsd | openbsd )
4386     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4387       close a pty to make it a controlling terminal (it is already a
4388       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4389   ;;
4390 esac
4391
4392 dnl FIXME Surely we can test for this rather than hard-code it.
4393 case $opsys in
4394   netbsd | openbsd) sound_device="/dev/audio" ;;
4395   *) sound_device="/dev/dsp" ;;
4396 esac
4397
4398 dnl Used in sound.c
4399 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4400   [Name of the default sound device.])
4401
4402
4403 dnl Emacs can read input using SIGIO and buffering characters itself,
4404 dnl or using CBREAK mode and making C-g cause SIGINT.
4405 dnl The choice is controlled by the variable interrupt_input.
4406 dnl
4407 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4408 dnl
4409 dnl Emacs uses the presence of the USABLE_SIGIO macro
4410 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4411 dnl INTERRUPT_INPUT to decide whether to use it by default.
4412 dnl
4413 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4414 dnl CBREAK mode has two disadvantages
4415 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4416 dnl I hear that in system V this problem does not exist.
4417 dnl 2) Control-G causes output to be discarded.
4418 dnl I do not know whether this can be fixed in system V.
4419 dnl
4420 dnl Another method of doing input is planned but not implemented.
4421 dnl It would have Emacs fork off a separate process
4422 dnl to read the input and send it to the true Emacs process
4423 dnl through a pipe.
4424 case $opsys in
4425   darwin | gnu-linux | gnu-kfreebsd )
4426     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4427   ;;
4428 esac
4429
4430
4431 dnl If the system's imake configuration file defines 'NeedWidePrototypes'
4432 dnl as 'NO', we must define NARROWPROTO manually.  Such a define is
4433 dnl generated in the Makefile generated by 'xmkmf'.  If we don't define
4434 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4435 dnl taking float or double parameters.
4436 case $opsys in
4437   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4438     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4439       file defines 'NeedWidePrototypes' as 'NO'.])
4440   ;;
4441 esac
4442
4443
4444 dnl Used in process.c, this must be a loop, even if it only runs once.
4445 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4446 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4447 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4448 dnl trying suffixes 0-16.
4449 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4450   first PTY, if PTYs are supported.])
4451 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4452 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4453   end of a PTY, if non-standard.])
4454 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4455   end of a PTY, if non-standard.])
4456
4457 case $opsys in
4458   aix4-2 )
4459     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4460     dnl You allocate a pty by opening /dev/ptc to get the master side.
4461     dnl To get the name of the slave side, you just ttyname() the master side.
4462     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4463     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4464     ;;
4465
4466   cygwin )
4467     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4468     dnl multi-line AC_DEFINEs are hard. :(
4469     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4470     AC_DEFINE(PTY_NAME_SPRINTF, [])
4471     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4472     ;;
4473
4474   gnu | openbsd )
4475     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4476     ;;
4477
4478   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd | darwin | nacl )
4479     dnl if HAVE_GRANTPT
4480     if test "x$ac_cv_func_grantpt" = xyes; then
4481       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4482       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4483       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4484       dnl to prevent sigchld_handler from intercepting the child's death.
4485       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4486       dnl if HAVE_POSIX_OPENPT
4487       if test "x$ac_cv_func_posix_openpt" = xyes; then
4488         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4489         AC_DEFINE(PTY_NAME_SPRINTF, [])
4490       dnl if HAVE_GETPT
4491       elif test "x$ac_cv_func_getpt" = xyes; then
4492         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4493         AC_DEFINE(PTY_NAME_SPRINTF, [])
4494       else
4495         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4496       fi
4497     else
4498       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4499     fi
4500     ;;
4501
4502   hpux*)
4503     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4504     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4505     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4506     ;;
4507
4508   irix6-5 )
4509     dnl It looks like this cannot be right, because it is not a loop.
4510     dnl However, process.c actually does this:
4511     dnl # ifndef __sgi
4512     dnl   continue;
4513     dnl # else
4514     dnl   return -1;
4515     dnl # endif
4516     dnl which presumably makes it OK, since irix == sgi (?).
4517     dnl FIXME it seems like this special treatment is unnecessary?
4518     dnl Why can't irix use a single-trip loop like eg cygwin?
4519     AC_DEFINE(PTY_ITERATION, [])
4520     dnl Not used, because PTY_ITERATION is defined.
4521     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4522     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4523     dnl No need to get the pty name at all.
4524     AC_DEFINE(PTY_NAME_SPRINTF, [])
4525     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4526     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4527     ;;
4528
4529   sol2* )
4530     dnl On SysVr4, grantpt(3) forks a subprocess, so do not use
4531     dnl O_CLOEXEC when opening the pty, and keep the SIGCHLD handler
4532     dnl from intercepting that death.  If any child but grantpt's should die
4533     dnl within, it should be caught after sigrelse(2).
4534     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4535     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4536     ;;
4537
4538   unixware )
4539     dnl Comments are as per sol2*.
4540     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4541     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4542     ;;
4543 esac
4544
4545
4546 case $opsys in
4547   sol2* | unixware )
4548     dnl This change means that we don't loop through allocate_pty too
4549     dnl many times in the (rare) event of a failure.
4550     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4551     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4552     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4553     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (forkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (forkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (forkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4554     ;;
4555 esac
4556
4557
4558 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4559 "typing" a signal character on the pty.])
4560
4561 case $opsys in
4562   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4563   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4564   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4565     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4566     ;;
4567
4568   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4569   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4570   gnu-linux | gnu-kfreebsd )
4571
4572     AC_MSG_CHECKING([for signals via characters])
4573     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4574 #include <linux/version.h>
4575 #if LINUX_VERSION_CODE < 0x20400
4576 # error "Linux version too old"
4577 #endif
4578       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4579
4580     AC_MSG_RESULT([$emacs_signals_via_chars])
4581     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4582     ;;
4583 esac
4584
4585
4586 AH_TEMPLATE(TAB3, [Undocumented.])
4587
4588 case $opsys in
4589   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4590
4591   gnu | dragonfly | freebsd | netbsd | openbsd )
4592     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4593     AC_DEFINE(TAB3, OXTABS)
4594     ;;
4595
4596   gnu-linux | gnu-kfreebsd )
4597     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4598 #ifndef __ia64__
4599 # error "not ia64"
4600 #endif
4601       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4602         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4603         [Mark a secondary stack, like the register stack on the ia64.]), [])
4604     ;;
4605
4606   hpux*)
4607     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4608       run_time_remap; for HPUX.])
4609     ;;
4610 esac
4611
4612
4613 dnl This won't be used automatically yet.  We also need to know, at least,
4614 dnl that the stack is continuous.
4615 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4616   registers relevant for conservative garbage collection in the jmp_buf.])
4617
4618
4619 case $opsys in
4620   dnl Not all the architectures are tested, but there are Debian packages
4621   dnl for SCM and/or Guile on them, so the technique must work.  See also
4622   dnl comments in alloc.c concerning setjmp and gcc.
4623   dnl Fixme: it's probably safe to just use the GCC conditional below.
4624   gnu-linux | gnu-kfreebsd )
4625     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4626 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4627   || defined __alpha__ || defined __mips__ || defined __s390__ \
4628   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4629   || defined __ia64__ || defined __sh__
4630 /* ok */
4631 #else
4632 # error "setjmp not known to work on this arch"
4633 #endif
4634     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4635     ;;
4636 esac
4637
4638
4639 if test x$GCC = xyes; then
4640    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4641    AC_DEFINE(GC_SETJMP_WORKS, 1)
4642 else
4643   case $opsys in
4644     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4645     aix* | dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4646       AC_DEFINE(GC_SETJMP_WORKS, 1)
4647       ;;
4648   esac
4649 fi                              dnl GCC?
4650
4651 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4652 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4653   [AC_LINK_IFELSE(
4654      [AC_LANG_PROGRAM(
4655        [[#include <setjmp.h>
4656          #ifdef __MINGW32__
4657          # define _longjmp longjmp
4658          #endif
4659        ]],
4660        [[jmp_buf j;
4661          if (! _setjmp (j))
4662            _longjmp (j, 1);]])],
4663      [emacs_cv_func__setjmp=yes],
4664      [emacs_cv_func__setjmp=no])])
4665 if test $emacs_cv_func__setjmp = yes; then
4666   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4667 fi
4668
4669 # We need to preserve signal mask to handle C stack overflows.
4670 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4671   [AC_LINK_IFELSE(
4672      [AC_LANG_PROGRAM(
4673        [[#include <setjmp.h>
4674        ]],
4675        [[sigjmp_buf j;
4676          if (! sigsetjmp (j, 1))
4677            siglongjmp (j, 1);]])],
4678      [emacs_cv_func_sigsetjmp=yes],
4679      [emacs_cv_func_sigsetjmp=no])])
4680 if test $emacs_cv_func_sigsetjmp = yes; then
4681   AC_DEFINE([HAVE_SIGSETJMP], 1,
4682     [Define to 1 if sigsetjmp and siglongjmp work.])
4683 fi
4684
4685 case $emacs_cv_func_sigsetjmp,$emacs_cv_alternate_stack,$opsys in
4686   yes,yes,* | *,*,mingw32)
4687     AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4688       [Define to 1 if C stack overflow can be handled in some cases.]);;
4689 esac
4690
4691 case $opsys in
4692   sol2* | unixware )
4693     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4694     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4695     dnl and this is all we need.
4696     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4697     ;;
4698 esac
4699
4700
4701 case $opsys in
4702   hpux* | sol2* )
4703     dnl Used in xfaces.c.
4704     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4705       some systems, where it requires time.h.])
4706     ;;
4707 esac
4708
4709
4710 dnl Define symbols to identify the version of Unix this is.
4711 dnl Define all the symbols that apply correctly.
4712 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4713 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4714 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4715 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4716
4717 case $opsys in
4718   aix4-2)
4719     AC_DEFINE(USG, [])
4720     dnl This symbol should be defined on AIX Version 3  ???????
4721     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4722 #ifndef _AIX
4723 # error "_AIX not defined"
4724 #endif
4725     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4726     ;;
4727
4728   cygwin)
4729     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4730     ;;
4731
4732   darwin)
4733     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4734     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4735     dnl distinguish OS X from pure Darwin.
4736     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4737     ;;
4738
4739   gnu-linux | gnu-kfreebsd )
4740     AC_DEFINE(USG, [])
4741     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4742     ;;
4743
4744   hpux*)
4745     AC_DEFINE(USG, [])
4746     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4747     ;;
4748
4749   irix6-5)
4750     AC_DEFINE(USG, [])
4751     AC_DEFINE(USG5_4, [])
4752     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4753     ;;
4754
4755   mingw32)
4756     AC_DEFINE(DOS_NT, [])
4757     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4758     if test "x$ac_enable_checking" != "x" ; then
4759       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4760     fi
4761     ;;
4762
4763   sol2*)
4764     AC_DEFINE(USG, [])
4765     AC_DEFINE(USG5_4, [])
4766     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4767     ;;
4768
4769   unixware)
4770     AC_DEFINE(USG, [])
4771     AC_DEFINE(USG5_4, [])
4772     ;;
4773 esac
4774
4775 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4776   [case $opsys in
4777      aix4-2 | nacl)
4778        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4779        emacs_cv_usable_FIONREAD=no
4780        ;;
4781
4782      mingw32)
4783        emacs_cv_usable_FIONREAD=yes
4784        ;;
4785
4786      *)
4787        AC_COMPILE_IFELSE(
4788          [AC_LANG_PROGRAM([[#include <sys/types.h>
4789                             #include <sys/ioctl.h>
4790                             #ifdef USG5_4
4791                             # include <sys/filio.h>
4792                             #endif
4793                           ]],
4794                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4795          [emacs_cv_usable_FIONREAD=yes],
4796          [emacs_cv_usable_FIONREAD=no])
4797        ;;
4798    esac])
4799 if test $emacs_cv_usable_FIONREAD = yes; then
4800   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4801
4802   if test $emacs_broken_SIGIO = no; then
4803     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4804       [AC_COMPILE_IFELSE(
4805          [AC_LANG_PROGRAM([[#include <fcntl.h>
4806                             #include <signal.h>
4807                           ]],
4808                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4809          [emacs_cv_usable_SIGIO=yes],
4810          [emacs_cv_usable_SIGIO=no])],
4811       [emacs_cv_usable_SIGIO=yes],
4812       [emacs_cv_usable_SIGIO=no])
4813     if test $emacs_cv_usable_SIGIO = yes; then
4814       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4815     fi
4816   fi
4817 fi
4818
4819 case $opsys in
4820   hpux11)
4821     dnl It works to open the pty's tty in the parent (Emacs), then
4822     dnl close and reopen it in the child.
4823     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4824       works to open a pty's tty in the parent process, then close and
4825       reopen it in the child.])
4826     ;;
4827
4828   irix6-5)
4829     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4830       use VSUSP instead of VSWTCH.])
4831     ;;
4832
4833   sol2-10)
4834     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4835       on Solaris.])
4836     ;;
4837 esac
4838
4839 # Set up the CFLAGS for real compilation, so we can substitute it.
4840 CFLAGS="$REAL_CFLAGS"
4841 CPPFLAGS="$REAL_CPPFLAGS"
4842 LIBS="$REAL_LIBS"
4843
4844 ## Hack to detect a buggy GCC version.
4845 if test "$GCC" = yes && \
4846    $CC --version 2> /dev/null | grep 'gcc.* 4.5.0' >/dev/null; then
4847   case $CFLAGS in
4848     *-fno-optimize-sibling-calls*) ;;
4849     *-O@<:@23@:>@*)
4850       AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS.]);;
4851   esac
4852 fi
4853
4854 version=$PACKAGE_VERSION
4855
4856 copyright="Copyright (C) 2016 Free Software Foundation, Inc."
4857 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4858   [Short copyright string for this version of Emacs.])
4859 AC_SUBST(copyright)
4860
4861 ### Specify what sort of things we'll be editing into Makefile and config.h.
4862 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4863 AC_SUBST(version)
4864 AC_SUBST(configuration)
4865 ## Unused?
4866 AC_SUBST(canonical)
4867 AC_SUBST(srcdir)
4868 AC_SUBST(prefix)
4869 AC_SUBST(exec_prefix)
4870 AC_SUBST(bindir)
4871 AC_SUBST(datadir)
4872 AC_SUBST(sharedstatedir)
4873 AC_SUBST(libexecdir)
4874 AC_SUBST(mandir)
4875 AC_SUBST(infodir)
4876 AC_SUBST(lispdir)
4877 AC_SUBST(standardlisppath)
4878 AC_SUBST(locallisppath)
4879 AC_SUBST(lisppath)
4880 AC_SUBST(x_default_search_path)
4881 AC_SUBST(etcdir)
4882 AC_SUBST(archlibdir)
4883 AC_SUBST(etcdocdir)
4884 AC_SUBST(bitmapdir)
4885 AC_SUBST(gamedir)
4886 AC_SUBST(gameuser)
4887 AC_SUBST(gamegroup)
4888 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4889 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4890 ## end of LIBX_BASE, but nothing ever set it.
4891 AC_SUBST(LD_SWITCH_X_SITE)
4892 AC_SUBST(C_SWITCH_X_SITE)
4893 AC_SUBST(GNUSTEP_CFLAGS)
4894 AC_SUBST(CFLAGS)
4895 ## Used in lwlib/Makefile.in.
4896 AC_SUBST(X_TOOLKIT_TYPE)
4897 AC_SUBST(ns_appdir)
4898 AC_SUBST(ns_appbindir)
4899 AC_SUBST(ns_appresdir)
4900 AC_SUBST(ns_appsrc)
4901 AC_SUBST(GNU_OBJC_CFLAGS)
4902 AC_SUBST(OTHER_FILES)
4903
4904 if test -n "${term_header}"; then
4905     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4906         [Define to the header for the built-in window system.])
4907 fi
4908
4909 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4910                    [Define to the canonical Emacs configuration name.])
4911 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4912                    [Define to the options passed to configure.])
4913 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4914   define this to include extra configuration information.])
4915
4916 case $opsys in
4917   mingw32)
4918     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4919     ;;
4920 esac
4921
4922 XMENU_OBJ=
4923 XOBJ=
4924 FONT_OBJ=
4925 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4926   AC_DEFINE(HAVE_X_WINDOWS, 1,
4927             [Define to 1 if you want to use the X window system.])
4928   XMENU_OBJ=xmenu.o
4929   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4930   FONT_OBJ=xfont.o
4931   if test "$HAVE_CAIRO" = "yes"; then
4932     FONT_OBJ="ftfont.o ftcrfont.o"
4933   elif test "$HAVE_XFT" = "yes"; then
4934     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4935   elif test "$HAVE_FREETYPE" = "yes"; then
4936     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4937   fi
4938   AC_SUBST(FONT_OBJ)
4939 fi
4940 AC_SUBST(XMENU_OBJ)
4941 AC_SUBST(XOBJ)
4942 AC_SUBST(FONT_OBJ)
4943
4944 WIDGET_OBJ=
4945 MOTIF_LIBW=
4946 if test "${USE_X_TOOLKIT}" != "none" ; then
4947   WIDGET_OBJ=widget.o
4948   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4949   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4950     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4951   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4952     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4953     MOTIF_LIBW=-lXm
4954     case "$opsys" in
4955       gnu-linux)
4956         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4957         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4958         ;;
4959
4960       unixware)
4961         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4962         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4963         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4964         ;;
4965
4966       aix4-2)
4967         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4968         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4969         ;;
4970     esac
4971     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4972   fi
4973 fi
4974 AC_SUBST(WIDGET_OBJ)
4975
4976 TOOLKIT_LIBW=
4977 case "$USE_X_TOOLKIT" in
4978   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4979   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4980   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4981 esac
4982 if test "$HAVE_XWIDGETS" = "yes"; then
4983   TOOLKIT_LIBW="$TOOLKIT_LIBW -lXcomposite"
4984 fi
4985 AC_SUBST(TOOLKIT_LIBW)
4986
4987 if test "${opsys}" != "mingw32"; then
4988   if test "$USE_X_TOOLKIT" = "none"; then
4989     LIBXT_OTHER="\$(LIBXSM)"
4990   else
4991     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4992   fi
4993 fi
4994 AC_SUBST(LIBXT_OTHER)
4995
4996 if test "${HAVE_X11}" = "yes" ; then
4997   AC_DEFINE(HAVE_X11, 1,
4998             [Define to 1 if you want to use version 11 of X windows.])
4999   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
5000 else
5001   LIBX_OTHER=
5002 fi
5003 AC_SUBST(LIBX_OTHER)
5004
5005 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
5006   LIBXMENU=
5007 elif test "$USE_X_TOOLKIT" = none; then
5008   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
5009 else
5010   LIBXMENU='$(lwlibdir)/liblw.a'
5011 fi
5012 AC_SUBST(LIBXMENU)
5013
5014 AC_CACHE_CHECK([for struct alignment],
5015   [emacs_cv_struct_alignment],
5016   [AC_COMPILE_IFELSE(
5017      [AC_LANG_PROGRAM([[#include <stddef.h>
5018                         struct __attribute__ ((aligned (8))) s { char c; };
5019                         struct t { char c; struct s s; };
5020                         char verify[offsetof (struct t, s) == 8 ? 1 : -1];
5021                       ]])],
5022      [emacs_cv_struct_alignment=yes],
5023      [emacs_cv_struct_alignment=no])])
5024 if test "$emacs_cv_struct_alignment" = yes; then
5025   AC_DEFINE([HAVE_STRUCT_ATTRIBUTE_ALIGNED], 1,
5026     [Define to 1 if 'struct __attribute__ ((aligned (N)))' aligns the
5027      structure to an N-byte boundary.])
5028 fi
5029
5030 if test "${GNU_MALLOC}" = "yes" ; then
5031   AC_DEFINE(GNU_MALLOC, 1,
5032             [Define to 1 if you want to use the GNU memory allocator.])
5033 fi
5034
5035 RALLOC_OBJ=
5036 if test "${REL_ALLOC}" = "yes" ; then
5037   AC_DEFINE(REL_ALLOC, 1,
5038             [Define REL_ALLOC if you want to use the relocating allocator for
5039              buffer space.])
5040
5041   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
5042 fi
5043 AC_SUBST(RALLOC_OBJ)
5044
5045 if test "$opsys" = "cygwin"; then
5046   CYGWIN_OBJ="cygw32.o"
5047   ## Cygwin differs because of its unexec().
5048   PRE_ALLOC_OBJ=
5049   POST_ALLOC_OBJ=lastfile.o
5050 elif test "$opsys" = "mingw32"; then
5051   CYGWIN_OBJ=
5052   PRE_ALLOC_OBJ=
5053   POST_ALLOC_OBJ=lastfile.o
5054 else
5055   CYGWIN_OBJ=
5056   PRE_ALLOC_OBJ=lastfile.o
5057   POST_ALLOC_OBJ=
5058 fi
5059 AC_SUBST(CYGWIN_OBJ)
5060 AC_SUBST(PRE_ALLOC_OBJ)
5061 AC_SUBST(POST_ALLOC_OBJ)
5062
5063 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
5064 dnl verbatim defined above.  The tricky name is apropos, as this hack
5065 dnl makes Fortify go sour!
5066 AH_VERBATIM([FORTIFY_SOUR],
5067 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
5068    The workaround disables some useful run-time checking, so it
5069    should be conditional to the platforms with the performance bug.
5070    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
5071 #if defined __APPLE__ && defined __GNUC__
5072 # ifndef _DONT_USE_CTYPE_INLINE_
5073 #  define _DONT_USE_CTYPE_INLINE_
5074 # endif
5075 # ifndef _FORTIFY_SOURCE
5076 #  define _FORTIFY_SOURCE 0
5077 # endif
5078 #endif
5079 ])
5080
5081 # If user asks to omit features, disable optional features that gnulib
5082 # might otherwise enable.
5083 if test "$with_features" = no && test "$enable_acl" != yes; then
5084   enable_acl=no
5085 fi
5086
5087 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
5088 # it temporarily reverts them to their pre-pkg-config values,
5089 # because gnulib needs to work with both src (which uses the
5090 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
5091 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
5092 # and it therefore needs to run in an environment where LIBS does not
5093 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
5094 # for some package unrelated to lib-src.
5095 SAVE_CFLAGS=$CFLAGS
5096 SAVE_LIBS=$LIBS
5097 CFLAGS=$pre_PKG_CONFIG_CFLAGS
5098 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
5099 gl_ASSERT_NO_GNULIB_POSIXCHECK
5100 gl_ASSERT_NO_GNULIB_TESTS
5101 gl_INIT
5102 CFLAGS=$SAVE_CFLAGS
5103 LIBS=$SAVE_LIBS
5104
5105 if test "${opsys}" = "mingw32"; then
5106   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
5107   # Remove unneeded switches from the value of CC that goes to Makefiles
5108   CC=`AS_ECHO(["$CC"]) | sed -e "s,$GCC_TEST_OPTIONS,,"`
5109 fi
5110
5111 case "$opsys" in
5112   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
5113
5114   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
5115
5116   darwin)
5117    ## The -headerpad option tells ld (see man page) to leave room at the
5118    ## end of the header for adding load commands.  Needed for dumping.
5119    ## 0x1000 is enough for roughly 52 load commands on the x86_64
5120    ## architecture (where they are 78 bytes each). The actual number of
5121    ## load commands added is not consistent but normally ranges from
5122    ## about 14 to about 34. Setting it high gets us plenty of slop and
5123    ## only costs about 1.5K of wasted binary space.
5124    headerpad_extra=1000
5125    if test "$HAVE_NS" = "yes"; then
5126      libs_nsgui="-framework AppKit"
5127      if test "$NS_IMPL_COCOA" = "yes"; then
5128         libs_nsgui="$libs_nsgui -framework IOKit"
5129      fi
5130    else
5131      libs_nsgui=
5132    fi
5133    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
5134
5135    ## This is here because src/Makefile.in did some extra fiddling around
5136    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
5137    ## LD_SWITCH_SYSTEM_TEMACS instead,
5138    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
5139      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
5140    ;;
5141
5142   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
5143   ## find X at run-time.
5144   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
5145   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
5146   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
5147   ## had different values in configure (in ac_link) and src/Makefile.in.
5148   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
5149   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
5150
5151   mingw32)
5152    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
5153    case "$canonical" in
5154      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5155      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5156    esac
5157    ;;
5158
5159   *) LD_SWITCH_SYSTEM_TEMACS= ;;
5160 esac
5161
5162 # -nopie fixes a temacs segfault on Gentoo, OpenBSD, and other systems
5163 # with "hardened" GCC configurations for some reason (Bug#18784).
5164 # We don't know why -nopie works, but not segfaulting is better than
5165 # segfaulting.  Use ac_c_werror_flag=yes when trying -nopie, otherwise
5166 # clang keeps warning that it does not understand -nopie, and pre-4.6
5167 # GCC has a similar problem (Bug#20338).
5168 AC_CACHE_CHECK([whether $CC accepts -nopie],
5169   [emacs_cv_prog_cc_nopie],
5170   [emacs_save_c_werror_flag=$ac_c_werror_flag
5171    emacs_save_LDFLAGS=$LDFLAGS
5172    ac_c_werror_flag=yes
5173    LDFLAGS="$LDFLAGS -nopie"
5174    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
5175      [emacs_cv_prog_cc_nopie=yes],
5176      [emacs_cv_prog_cc_nopie=no])
5177    ac_c_werror_flag=$emacs_save_c_werror_flag
5178    LDFLAGS=$emacs_save_LDFLAGS])
5179 if test "$emacs_cv_prog_cc_nopie" = yes; then
5180   LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -nopie"
5181 fi
5182
5183 if test x$ac_enable_profiling != x ; then
5184   case $opsys in
5185     *freebsd | gnu-linux) ;;
5186     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
5187   esac
5188 fi
5189
5190 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
5191
5192 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
5193
5194 ## Common for all window systems
5195 if test "$window_system" != "none"; then
5196   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
5197   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
5198   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
5199 fi
5200
5201 AC_SUBST(WINDOW_SYSTEM_OBJ)
5202
5203 AH_TOP([/* GNU Emacs site configuration template file.
5204
5205 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2016
5206   Free Software Foundation, Inc.
5207
5208 This file is part of GNU Emacs.
5209
5210 GNU Emacs is free software: you can redistribute it and/or modify
5211 it under the terms of the GNU General Public License as published by
5212 the Free Software Foundation, either version 3 of the License, or
5213 (at your option) any later version.
5214
5215 GNU Emacs is distributed in the hope that it will be useful,
5216 but WITHOUT ANY WARRANTY; without even the implied warranty of
5217 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
5218 GNU General Public License for more details.
5219
5220 You should have received a copy of the GNU General Public License
5221 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
5222
5223
5224 /* No code in Emacs #includes config.h twice, but some bits of code
5225    intended to work with other packages as well (like gmalloc.c)
5226    think they can include it as many times as they like.  */
5227 #ifndef EMACS_CONFIG_H
5228 #define EMACS_CONFIG_H
5229 ])dnl
5230
5231 AH_BOTTOM([#include <conf_post.h>
5232
5233 #endif /* EMACS_CONFIG_H */
5234
5235 /*
5236 Local Variables:
5237 mode: c
5238 End:
5239 */
5240 ])dnl
5241
5242 #### Report on what we decided to do.
5243 #### Report GTK as a toolkit, even if it doesn't use Xt.
5244 #### It makes printing result more understandable as using GTK sets
5245 #### toolkit_scroll_bars to yes by default.
5246 if test "${HAVE_GTK}" = "yes"; then
5247   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5248 fi
5249
5250 if test $USE_ACL -ne 0; then
5251   ACL_SUMMARY="yes $LIB_ACL"
5252 else
5253   ACL_SUMMARY=no
5254 fi
5255
5256 emacs_standard_dirs='Standard dirs'
5257 AS_ECHO(["
5258 Configured for '${canonical}'.
5259
5260   Where should the build process find the source code?    ${srcdir}
5261   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5262   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5263   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5264   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5265   What window system should Emacs use?                    ${window_system}
5266   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}
5267   Where do we find X Windows header files?                ${x_includes:-$emacs_standard_dirs}
5268   Where do we find X Windows libraries?                   ${x_libraries:-$emacs_standard_dirs}"])
5269
5270 optsep=
5271 emacs_config_features=
5272 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG CAIRO IMAGEMAGICK SOUND GPM DBUS \
5273   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5274   LIBOTF XFT ZLIB TOOLKIT_SCROLL_BARS X_TOOLKIT X11 NS MODULES \
5275   XWIDGETS; do
5276
5277     case $opt in
5278       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5279       TOOLKIT_SCROLL_BARS|X_TOOLKIT) eval val=\${USE_$opt} ;;
5280       *) eval val=\${HAVE_$opt} ;;
5281     esac
5282     case x$val in
5283       xno|xnone|x) continue ;;
5284     esac
5285     case $opt in
5286       X_TOOLKIT)
5287         case $val in
5288           GTK*|LUCID|MOTIF) opt=$val ;;
5289           *) continue ;;
5290         esac
5291       ;;
5292     esac
5293     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5294     optsep=' '
5295 done
5296 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5297   [Summary of some of the main features enabled by configure.])
5298
5299 AS_ECHO(["  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}
5300   Does Emacs use -lXpm?                                   ${HAVE_XPM}
5301   Does Emacs use -ljpeg?                                  ${HAVE_JPEG}
5302   Does Emacs use -ltiff?                                  ${HAVE_TIFF}
5303   Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF
5304   Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG
5305   Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}
5306   Does Emacs use cairo?                                   ${HAVE_CAIRO}
5307   Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}
5308   Does Emacs support sound?                               ${HAVE_SOUND}
5309   Does Emacs use -lgpm?                                   ${HAVE_GPM}
5310   Does Emacs use -ldbus?                                  ${HAVE_DBUS}
5311   Does Emacs use -lgconf?                                 ${HAVE_GCONF}
5312   Does Emacs use GSettings?                               ${HAVE_GSETTINGS}
5313   Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}
5314   Does Emacs use access control lists?                    ${ACL_SUMMARY}
5315   Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}
5316   Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}
5317   Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}
5318   Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}
5319   Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}
5320   Does Emacs use -lotf?                                   ${HAVE_LIBOTF}
5321   Does Emacs use -lxft?                                   ${HAVE_XFT}
5322   Does Emacs directly use zlib?                           ${HAVE_ZLIB}
5323   Does Emacs have dynamic modules support?                ${HAVE_MODULES}
5324   Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}
5325   Does Emacs support Xwidgets (requires gtk3)?            ${HAVE_XWIDGETS}
5326 "])
5327
5328 if test -n "${EMACSDATA}"; then
5329    AS_ECHO(["  Environment variable EMACSDATA set to:                  $EMACSDATA"])
5330 fi
5331 if test -n "${EMACSDOC}"; then
5332    AS_ECHO(["  Environment variable EMACSDOC set to:                   $EMACSDOC"])
5333 fi
5334
5335 echo
5336
5337 if test "$HAVE_NS" = "yes"; then
5338    echo
5339    AS_ECHO(["You must run \"${MAKE-make} install\" in order to test the built application.
5340 The installed application will go to nextstep/Emacs.app and can be
5341 run or moved from there."])
5342    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5343       echo "The application will be fully self-contained."
5344     else
5345       AS_ECHO(["The lisp resources for the application will be installed under ${prefix}.
5346 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5347 to run if these resources are not installed."])
5348    fi
5349    echo
5350 fi
5351
5352 if test "${opsys}" = "cygwin"; then
5353   case `uname -r` in
5354     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5355            echo
5356            ;;
5357   esac
5358 fi
5359
5360 # Remove any trailing slashes in these variables.
5361 case $prefix in
5362   */) prefix=`AS_DIRNAME(["$prefix."])`;;
5363 esac
5364 case $exec_prefix in
5365   */) exec_prefix=`AS_DIRNAME(["$exec_prefix."])`;;
5366 esac
5367
5368 if test "$HAVE_NS" = "yes"; then
5369   if test "$NS_IMPL_GNUSTEP" = yes; then
5370     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5371       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5372     ns_check_file=Resources/Info-gnustep.plist
5373   else
5374     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5375       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5376     ns_check_file=Contents/Info.plist
5377   fi
5378   AC_SUBST(ns_check_file)
5379 fi
5380
5381 dnl config.status treats $srcdir specially, so I think this is ok...
5382 AC_CONFIG_FILES([$srcdir/doc/man/emacs.1])
5383
5384 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5385 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5386 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5387 dnl (else you get "no 'Makefile.am' found for any configure output").
5388 dnl This will work, but you get a config.status that is not quite right
5389 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5390 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5391 dnl it seems better to just live with the duplication.
5392 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5393
5394 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5395        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5396        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5397        leim/Makefile nextstep/Makefile nt/Makefile])
5398
5399 dnl test/ is not present in release tarfiles.
5400 opt_makefile=test/Makefile
5401
5402 if test -f "$srcdir/$opt_makefile.in"; then
5403   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5404   dnl Again, it's best not to use a variable.  Though you can add
5405   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5406   AC_CONFIG_FILES([test/Makefile])
5407 fi
5408
5409
5410 dnl The admin/ directory used to be excluded from tarfiles.
5411 if test -d $srcdir/admin; then
5412   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/charsets/Makefile admin/unidata/Makefile admin/grammars/Makefile"
5413   AC_CONFIG_FILES([admin/charsets/Makefile])
5414   AC_CONFIG_FILES([admin/unidata/Makefile])
5415   AC_CONFIG_FILES([admin/grammars/Makefile])
5416 fi                              dnl -d admin
5417
5418
5419 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5420
5421 AC_SUBST(SUBDIR_MAKEFILES_IN)
5422
5423 dnl You might wonder (I did) why epaths.h is generated by running make,
5424 dnl rather than just letting configure generate it from epaths.in.
5425 dnl One reason is that the various paths are not fully expanded (see above);
5426 dnl eg gamedir=${prefix}/var/games/emacs.
5427 dnl Secondly, the GNU Coding standards require that one should be able
5428 dnl to run 'make prefix=/some/where/else' and override the values set
5429 dnl by configure.  This also explains the 'move-if-change' test and
5430 dnl the use of force in the 'epaths-force' rule in Makefile.in.
5431 AC_CONFIG_COMMANDS([src/epaths.h], [
5432 if test "${opsys}" = "mingw32"; then
5433   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5434 else
5435   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5436 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5437 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5438
5439 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5440 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5441 dnl or a symlink?
5442 AC_CONFIG_COMMANDS([src/.gdbinit], [
5443 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5444   AS_ECHO(["source $ac_abs_top_srcdir/src/.gdbinit"]) > src/.gdbinit
5445 fi
5446 ])
5447
5448 dnl Perhaps this would be better named doc-emacs-emacsver.texi?
5449 dnl See comments for etc-refcards-emacsver.tex.
5450 dnl Since we get a doc/emacs directory generated anyway, for the Makefile,
5451 dnl it is not quite the same.  But we are generating in $srcdir.
5452 AC_CONFIG_COMMANDS([doc/emacs/emacsver.texi], [
5453 ${MAKE-make} -s --no-print-directory -C doc/emacs doc-emacsver || \
5454 AC_MSG_ERROR(['doc/emacs/emacsver.texi' could not be made.])
5455 ])
5456
5457 dnl If we give this the more natural name, etc/refcards/emacsver.texi,
5458 dnl then a directory etc/refcards is created in the build directory,
5459 dnl which is probably harmless, but confusing (in out-of-tree builds).
5460 dnl (If we were to generate etc/refcards/Makefile, this might change.)
5461 dnl It is really $srcdir/etc/refcards/emacsver.tex that we generate.
5462 AC_CONFIG_COMMANDS([etc-refcards-emacsver.tex], [
5463 ${MAKE-make} -s MAKEFILE_NAME=do-not-make-Makefile etc-emacsver || \
5464 AC_MSG_ERROR(['etc/refcards/emacsver.tex' could not be made.])
5465 ])
5466
5467 AC_OUTPUT
5468
5469 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])