code.delx.au - gnu-emacs/blob - lisp/net/tramp-gvfs.el

   1 ;;; tramp-gvfs.el --- Tramp access functions for GVFS daemon
   2
   3 ;; Copyright (C) 2009-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Michael Albinus <michael.albinus@gmx.de>
   6 ;; Keywords: comm, processes
   7 ;; Package: tramp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Access functions for the GVFS daemon from Tramp.  Tested with GVFS
  27 ;; 1.0 (Ubuntu 8.10, Gnome 2.24).  It has been reported also to run
  28 ;; with GVFS 0.2.5 (Ubuntu 8.04, Gnome 2.22), but there is an
  29 ;; incompatibility with the mount_info structure, which has been
  30 ;; worked around.
  31
  32 ;; It has also been tested with GVFS 1.6 (Ubuntu 10.04, Gnome 2.30),
  33 ;; where the default_location has been added to mount_info (see
  34 ;; <https://bugzilla.gnome.org/show_bug.cgi?id=561998>.
  35
  36 ;; With GVFS 1.14 (Ubuntu 12.10, Gnome 3.6) the interfaces have been
  37 ;; changed, again.  So we must introspect the D-Bus interfaces.
  38
  39 ;; All actions to mount a remote location, and to retrieve mount
  40 ;; information, are performed by D-Bus messages.  File operations
  41 ;; themselves are performed via the mounted filesystem in ~/.gvfs.
  42 ;; Consequently, GNU Emacs 23.1 with enabled D-Bus bindings is a
  43 ;; precondition.
  44
  45 ;; The GVFS D-Bus interface is said to be unstable.  There were even
  46 ;; no introspection data before GVFS 1.14.  The interface, as
  47 ;; discovered during development time, is given in respective
  48 ;; comments.
  49
  50 ;; The customer option `tramp-gvfs-methods' contains the list of
  51 ;; supported connection methods.  Per default, these are "dav",
  52 ;; "davs", "obex", "sftp" and "synce".  Note that with "obex" it might
  53 ;; be necessary to pair with the other bluetooth device, if it hasn't
  54 ;; been done already.  There might be also some few seconds delay in
  55 ;; discovering available bluetooth devices.
  56
  57 ;; Other possible connection methods are "ftp" and "smb".  When one of
  58 ;; these methods is added to the list, the remote access for that
  59 ;; method is performed via GVFS instead of the native Tramp
  60 ;; implementation.
  61
  62 ;; GVFS offers even more connection methods.  The complete list of
  63 ;; connection methods of the actual GVFS implementation can be
  64 ;; retrieved by:
  65 ;;
  66 ;; (message
  67 ;;  "%s"
  68 ;;  (mapcar
  69 ;;   'car
  70 ;;   (dbus-call-method
  71 ;;    :session tramp-gvfs-service-daemon tramp-gvfs-path-mounttracker
  72 ;;    tramp-gvfs-interface-mounttracker "listMountableInfo")))
  73
  74 ;; Note that all other connection methods are not tested, beside the
  75 ;; ones offered for customization in `tramp-gvfs-methods'.  If you
  76 ;; request an additional connection method to be supported, please
  77 ;; drop me a note.
  78
  79 ;; For hostname completion, information is retrieved either from the
  80 ;; bluez daemon (for the "obex" method), the hal daemon (for the
  81 ;; "synce" method), or from the zeroconf daemon (for the "dav",
  82 ;; "davs", and "sftp" methods).  The zeroconf daemon is pre-configured
  83 ;; to discover services in the "local" domain.  If another domain
  84 ;; shall be used for discovering services, the customer option
  85 ;; `tramp-gvfs-zeroconf-domain' can be set accordingly.
  86
  87 ;; Restrictions:
  88
  89 ;; * The current GVFS implementation does not allow to write on the
  90 ;;   remote bluetooth device via OBEX.
  91 ;;
  92 ;; * Two shares of the same SMB server cannot be mounted in parallel.
  93
  94 ;;; Code:
  95
  96 ;; D-Bus support in the Emacs core can be disabled with configuration
  97 ;; option "--without-dbus".  Declare used subroutines and variables.
  98 (declare-function dbus-get-unique-name "dbusbind.c")
  99
 100 (require 'tramp)
 101
 102 (require 'dbus)
 103 (require 'url-parse)
 104 (require 'url-util)
 105 (require 'zeroconf)
 106
 107 ;; Pacify byte-compiler.
 108 (eval-when-compile
 109   (require 'cl)
 110   (require 'custom))
 111
 112 ;;;###tramp-autoload
 113 (defcustom tramp-gvfs-methods '("dav" "davs" "obex" "sftp" "synce")
 114   "List of methods for remote files, accessed with GVFS."
 115   :group 'tramp
 116   :version "23.2"
 117   :type '(repeat (choice (const "dav")
 118                          (const "davs")
 119                          (const "ftp")
 120                          (const "obex")
 121                          (const "sftp")
 122                          (const "smb")
 123                          (const "synce"))))
 124
 125 ;; Add a default for `tramp-default-user-alist'.  Rule: For the SYNCE
 126 ;; method, no user is chosen.
 127 ;;;###tramp-autoload
 128 (add-to-list 'tramp-default-user-alist '("\\`synce\\'" nil nil))
 129
 130 (defcustom tramp-gvfs-zeroconf-domain "local"
 131   "Zeroconf domain to be used for discovering services, like host names."
 132   :group 'tramp
 133   :version "23.2"
 134   :type 'string)
 135
 136 ;; Add the methods to `tramp-methods', in order to allow minibuffer
 137 ;; completion.
 138 ;;;###tramp-autoload
 139 (when (featurep 'dbusbind)
 140   (dolist (elt tramp-gvfs-methods)
 141     (unless (assoc elt tramp-methods)
 142       (add-to-list 'tramp-methods (cons elt nil)))))
 143
 144 (defconst tramp-gvfs-path-tramp (concat dbus-path-emacs "/Tramp")
 145   "The preceding object path for own objects.")
 146
 147 (defconst tramp-gvfs-service-daemon "org.gtk.vfs.Daemon"
 148   "The well known name of the GVFS daemon.")
 149
 150 ;; D-Bus integration is available since Emacs 23 on some system types.
 151 ;; We don't call `dbus-ping', because this would load dbus.el.
 152 (defconst tramp-gvfs-enabled
 153   (ignore-errors
 154     (and (featurep 'dbusbind)
 155          (tramp-compat-funcall 'dbus-get-unique-name :system)
 156          (tramp-compat-funcall 'dbus-get-unique-name :session)
 157          (or (tramp-compat-process-running-p "gvfs-fuse-daemon")
 158              (tramp-compat-process-running-p "gvfsd-fuse"))))
 159   "Non-nil when GVFS is available.")
 160
 161 (defconst tramp-gvfs-path-mounttracker "/org/gtk/vfs/mounttracker"
 162   "The object path of the GVFS daemon.")
 163
 164 (defconst tramp-gvfs-interface-mounttracker "org.gtk.vfs.MountTracker"
 165   "The mount tracking interface in the GVFS daemon.")
 166
 167 ;; Introspection data exist since GVFS 1.14.  If there are no such
 168 ;; data, we expect an earlier interface.
 169 (defconst tramp-gvfs-methods-mounttracker
 170   (dbus-introspect-get-method-names
 171    :session tramp-gvfs-service-daemon tramp-gvfs-path-mounttracker
 172    tramp-gvfs-interface-mounttracker)
 173   "The list of supported methods of the mount tracking interface.")
 174
 175 (defconst tramp-gvfs-listmounts
 176   (if (member "ListMounts" tramp-gvfs-methods-mounttracker)
 177       "ListMounts"
 178     "listMounts")
 179   "The name of the \"listMounts\" method.
 180 It has been changed in GVFS 1.14.")
 181
 182 (defconst tramp-gvfs-mountlocation
 183   (if (member "MountLocation" tramp-gvfs-methods-mounttracker)
 184       "MountLocation"
 185     "mountLocation")
 186   "The name of the \"mountLocation\" method.
 187 It has been changed in GVFS 1.14.")
 188
 189 (defconst tramp-gvfs-mountlocation-signature
 190   (dbus-introspect-get-signature
 191    :session tramp-gvfs-service-daemon tramp-gvfs-path-mounttracker
 192    tramp-gvfs-interface-mounttracker tramp-gvfs-mountlocation)
 193   "The D-Bus signature of the \"mountLocation\" method.
 194 It has been changed in GVFS 1.14.")
 195
 196 ;; <interface name='org.gtk.vfs.MountTracker'>
 197 ;;   <method name='listMounts'>
 198 ;;     <arg name='mount_info_list'
 199 ;;          type='a{sosssssbay{aya{say}}ay}'
 200 ;;          direction='out'/>
 201 ;;   </method>
 202 ;;   <method name='mountLocation'>
 203 ;;     <arg name='mount_spec'  type='{aya{say}}' direction='in'/>
 204 ;;     <arg name='dbus_id'     type='s'          direction='in'/>
 205 ;;     <arg name='object_path' type='o'          direction='in'/>
 206 ;;   </method>
 207 ;;   <signal name='mounted'>
 208 ;;     <arg name='mount_info'
 209 ;;          type='{sosssssbay{aya{say}}ay}'/>
 210 ;;   </signal>
 211 ;;   <signal name='unmounted'>
 212 ;;     <arg name='mount_info'
 213 ;;          type='{sosssssbay{aya{say}}ay}'/>
 214 ;;   </signal>
 215 ;; </interface>
 216 ;;
 217 ;; STRUCT               mount_info
 218 ;;   STRING               dbus_id
 219 ;;   OBJECT_PATH          object_path
 220 ;;   STRING               display_name
 221 ;;   STRING               stable_name
 222 ;;   STRING               x_content_types       Since GVFS 1.0 only !!!
 223 ;;   STRING               icon
 224 ;;   STRING               preferred_filename_encoding
 225 ;;   BOOLEAN              user_visible
 226 ;;   ARRAY BYTE           fuse_mountpoint
 227 ;;   STRUCT               mount_spec
 228 ;;     ARRAY BYTE           mount_prefix
 229 ;;     ARRAY
 230 ;;       STRUCT             mount_spec_item
 231 ;;         STRING             key (server, share, type, user, host, port)
 232 ;;         ARRAY BYTE         value
 233 ;;   ARRAY BYTE           default_location      Since GVFS 1.5 only !!!
 234
 235 (defconst tramp-gvfs-interface-mountoperation "org.gtk.vfs.MountOperation"
 236   "Used by the dbus-proxying implementation of GMountOperation.")
 237
 238 ;; <interface name='org.gtk.vfs.MountOperation'>
 239 ;;   <method name='askPassword'>
 240 ;;     <arg name='message'        type='s' direction='in'/>
 241 ;;     <arg name='default_user'   type='s' direction='in'/>
 242 ;;     <arg name='default_domain' type='s' direction='in'/>
 243 ;;     <arg name='flags'          type='u' direction='in'/>
 244 ;;     <arg name='handled'        type='b' direction='out'/>
 245 ;;     <arg name='aborted'        type='b' direction='out'/>
 246 ;;     <arg name='password'       type='s' direction='out'/>
 247 ;;     <arg name='username'       type='s' direction='out'/>
 248 ;;     <arg name='domain'         type='s' direction='out'/>
 249 ;;     <arg name='anonymous'      type='b' direction='out'/>
 250 ;;     <arg name='password_save'  type='u' direction='out'/>
 251 ;;   </method>
 252 ;;   <method name='askQuestion'>
 253 ;;     <arg name='message' type='s'  direction='in'/>
 254 ;;     <arg name='choices' type='as' direction='in'/>
 255 ;;     <arg name='handled' type='b'  direction='out'/>
 256 ;;     <arg name='aborted' type='b'  direction='out'/>
 257 ;;     <arg name='choice'  type='u'  direction='out'/>
 258 ;;   </method>
 259 ;; </interface>
 260
 261 ;; The following flags are used in "askPassword".  They are defined in
 262 ;; /usr/include/glib-2.0/gio/gioenums.h.
 263
 264 (defconst tramp-gvfs-password-need-password 1
 265   "Operation requires a password.")
 266
 267 (defconst tramp-gvfs-password-need-username 2
 268   "Operation requires a username.")
 269
 270 (defconst tramp-gvfs-password-need-domain 4
 271   "Operation requires a domain.")
 272
 273 (defconst tramp-gvfs-password-saving-supported 8
 274   "Operation supports saving settings.")
 275
 276 (defconst tramp-gvfs-password-anonymous-supported 16
 277   "Operation supports anonymous users.")
 278
 279 (defconst tramp-bluez-service "org.bluez"
 280   "The well known name of the BLUEZ service.")
 281
 282 (defconst tramp-bluez-interface-manager "org.bluez.Manager"
 283   "The manager interface of the BLUEZ daemon.")
 284
 285 ;; <interface name='org.bluez.Manager'>
 286 ;;   <method name='DefaultAdapter'>
 287 ;;     <arg type='o' direction='out'/>
 288 ;;   </method>
 289 ;;   <method name='FindAdapter'>
 290 ;;     <arg type='s' direction='in'/>
 291 ;;     <arg type='o' direction='out'/>
 292 ;;   </method>
 293 ;;   <method name='ListAdapters'>
 294 ;;     <arg type='ao' direction='out'/>
 295 ;;   </method>
 296 ;;   <signal name='AdapterAdded'>
 297 ;;     <arg type='o'/>
 298 ;;   </signal>
 299 ;;   <signal name='AdapterRemoved'>
 300 ;;     <arg type='o'/>
 301 ;;   </signal>
 302 ;;   <signal name='DefaultAdapterChanged'>
 303 ;;     <arg type='o'/>
 304 ;;   </signal>
 305 ;; </interface>
 306
 307 (defconst tramp-bluez-interface-adapter "org.bluez.Adapter"
 308   "The adapter interface of the BLUEZ daemon.")
 309
 310 ;; <interface name='org.bluez.Adapter'>
 311 ;;   <method name='GetProperties'>
 312 ;;     <arg type='a{sv}' direction='out'/>
 313 ;;   </method>
 314 ;;   <method name='SetProperty'>
 315 ;;     <arg type='s' direction='in'/>
 316 ;;     <arg type='v' direction='in'/>
 317 ;;   </method>
 318 ;;   <method name='RequestMode'>
 319 ;;     <arg type='s' direction='in'/>
 320 ;;   </method>
 321 ;;   <method name='ReleaseMode'/>
 322 ;;   <method name='RequestSession'/>
 323 ;;   <method name='ReleaseSession'/>
 324 ;;   <method name='StartDiscovery'/>
 325 ;;   <method name='StopDiscovery'/>
 326 ;;   <method name='ListDevices'>
 327 ;;     <arg type='ao' direction='out'/>
 328 ;;   </method>
 329 ;;   <method name='CreateDevice'>
 330 ;;     <arg type='s' direction='in'/>
 331 ;;     <arg type='o' direction='out'/>
 332 ;;   </method>
 333 ;;   <method name='CreatePairedDevice'>
 334 ;;     <arg type='s' direction='in'/>
 335 ;;     <arg type='o' direction='in'/>
 336 ;;     <arg type='s' direction='in'/>
 337 ;;     <arg type='o' direction='out'/>
 338 ;;   </method>
 339 ;;   <method name='CancelDeviceCreation'>
 340 ;;     <arg type='s' direction='in'/>
 341 ;;   </method>
 342 ;;   <method name='RemoveDevice'>
 343 ;;     <arg type='o' direction='in'/>
 344 ;;   </method>
 345 ;;   <method name='FindDevice'>
 346 ;;     <arg type='s' direction='in'/>
 347 ;;     <arg type='o' direction='out'/>
 348 ;;   </method>
 349 ;;   <method name='RegisterAgent'>
 350 ;;     <arg type='o' direction='in'/>
 351 ;;     <arg type='s' direction='in'/>
 352 ;;   </method>
 353 ;;   <method name='UnregisterAgent'>
 354 ;;     <arg type='o' direction='in'/>
 355 ;;   </method>
 356 ;;   <signal name='DeviceCreated'>
 357 ;;     <arg type='o'/>
 358 ;;   </signal>
 359 ;;   <signal name='DeviceRemoved'>
 360 ;;     <arg type='o'/>
 361 ;;   </signal>
 362 ;;   <signal name='DeviceFound'>
 363 ;;     <arg type='s'/>
 364 ;;     <arg type='a{sv}'/>
 365 ;;   </signal>
 366 ;;   <signal name='PropertyChanged'>
 367 ;;     <arg type='s'/>
 368 ;;     <arg type='v'/>
 369 ;;   </signal>
 370 ;;   <signal name='DeviceDisappeared'>
 371 ;;     <arg type='s'/>
 372 ;;   </signal>
 373 ;; </interface>
 374
 375 (defcustom tramp-bluez-discover-devices-timeout 60
 376   "Defines seconds since last bluetooth device discovery before rescanning.
 377 A value of 0 would require an immediate discovery during hostname
 378 completion, nil means to use always cached values for discovered
 379 devices."
 380   :group 'tramp
 381   :version "23.2"
 382   :type '(choice (const nil) integer))
 383
 384 (defvar tramp-bluez-discovery nil
 385   "Indicator for a running bluetooth device discovery.
 386 It keeps the timestamp of last discovery.")
 387
 388 (defvar tramp-bluez-devices nil
 389   "Alist of detected bluetooth devices.
 390 Every entry is a list (NAME ADDRESS).")
 391
 392 (defconst tramp-hal-service "org.freedesktop.Hal"
 393   "The well known name of the HAL service.")
 394
 395 (defconst tramp-hal-path-manager "/org/freedesktop/Hal/Manager"
 396   "The object path of the HAL daemon manager.")
 397
 398 (defconst tramp-hal-interface-manager "org.freedesktop.Hal.Manager"
 399   "The manager interface of the HAL daemon.")
 400
 401 (defconst tramp-hal-interface-device "org.freedesktop.Hal.Device"
 402   "The device interface of the HAL daemon.")
 403
 404 \f
 405 ;; New handlers should be added here.
 406 (defconst tramp-gvfs-file-name-handler-alist
 407   '((access-file . ignore)
 408     (add-name-to-file . tramp-gvfs-handle-copy-file)
 409     ;; `byte-compiler-base-file-name' performed by default handler.
 410     ;; `copy-directory' performed by default handler.
 411     (copy-file . tramp-gvfs-handle-copy-file)
 412     (delete-directory . tramp-gvfs-handle-delete-directory)
 413     (delete-file . tramp-gvfs-handle-delete-file)
 414     ;; `diff-latest-backup-file' performed by default handler.
 415     (directory-file-name . tramp-handle-directory-file-name)
 416     (directory-files . tramp-handle-directory-files)
 417     (directory-files-and-attributes
 418      . tramp-handle-directory-files-and-attributes)
 419     (dired-call-process . ignore)
 420     (dired-compress-file . ignore)
 421     (dired-uncache . tramp-handle-dired-uncache)
 422     (expand-file-name . tramp-gvfs-handle-expand-file-name)
 423     (file-accessible-directory-p . tramp-handle-file-accessible-directory-p)
 424     (file-acl . ignore)
 425     (file-attributes . tramp-gvfs-handle-file-attributes)
 426     (file-directory-p . tramp-gvfs-handle-file-directory-p)
 427     ;; `file-equal-p' performed by default handler.
 428     (file-executable-p . tramp-gvfs-handle-file-executable-p)
 429     (file-exists-p . tramp-handle-file-exists-p)
 430     ;; `file-in-directory-p' performed by default handler.
 431     (file-local-copy . tramp-gvfs-handle-file-local-copy)
 432     (file-modes . tramp-handle-file-modes)
 433     (file-name-all-completions . tramp-gvfs-handle-file-name-all-completions)
 434     (file-name-as-directory . tramp-handle-file-name-as-directory)
 435     (file-name-completion . tramp-handle-file-name-completion)
 436     (file-name-directory . tramp-handle-file-name-directory)
 437     (file-name-nondirectory . tramp-handle-file-name-nondirectory)
 438     ;; `file-name-sans-versions' performed by default handler.
 439     (file-newer-than-file-p . tramp-handle-file-newer-than-file-p)
 440     (file-notify-add-watch . tramp-gvfs-handle-file-notify-add-watch)
 441     (file-notify-rm-watch . tramp-handle-file-notify-rm-watch)
 442     (file-ownership-preserved-p . ignore)
 443     (file-readable-p . tramp-gvfs-handle-file-readable-p)
 444     (file-regular-p . tramp-handle-file-regular-p)
 445     (file-remote-p . tramp-handle-file-remote-p)
 446     (file-selinux-context . ignore)
 447     (file-symlink-p . tramp-handle-file-symlink-p)
 448     ;; `file-truename' performed by default handler.
 449     (file-writable-p . tramp-gvfs-handle-file-writable-p)
 450     (find-backup-file-name . tramp-handle-find-backup-file-name)
 451     ;; `find-file-noselect' performed by default handler.
 452     ;; `get-file-buffer' performed by default handler.
 453     (insert-directory . tramp-handle-insert-directory)
 454     (insert-file-contents . tramp-handle-insert-file-contents)
 455     (load . tramp-handle-load)
 456     (make-auto-save-file-name . tramp-handle-make-auto-save-file-name)
 457     (make-directory . tramp-gvfs-handle-make-directory)
 458     (make-directory-internal . ignore)
 459     (make-symbolic-link . tramp-handle-make-symbolic-link)
 460     (process-file . ignore)
 461     (rename-file . tramp-gvfs-handle-rename-file)
 462     (set-file-acl . ignore)
 463     (set-file-modes . ignore)
 464     (set-file-selinux-context . ignore)
 465     (set-file-times . ignore)
 466     (set-visited-file-modtime . tramp-handle-set-visited-file-modtime)
 467     (shell-command . ignore)
 468     (start-file-process . ignore)
 469     (substitute-in-file-name . tramp-handle-substitute-in-file-name)
 470     (unhandled-file-name-directory . tramp-handle-unhandled-file-name-directory)
 471     (vc-registered . ignore)
 472     (verify-visited-file-modtime . tramp-handle-verify-visited-file-modtime)
 473     (write-region . tramp-gvfs-handle-write-region))
 474   "Alist of handler functions for Tramp GVFS method.
 475 Operations not mentioned here will be handled by the default Emacs primitives.")
 476
 477 ;; It must be a `defsubst' in order to push the whole code into
 478 ;; tramp-loaddefs.el.  Otherwise, there would be recursive autoloading.
 479 ;;;###tramp-autoload
 480 (defsubst tramp-gvfs-file-name-p (filename)
 481   "Check if it's a filename handled by the GVFS daemon."
 482   (and (tramp-tramp-file-p filename)
 483        (let ((method
 484               (tramp-file-name-method (tramp-dissect-file-name filename))))
 485          (and (stringp method) (member method tramp-gvfs-methods)))))
 486
 487 ;;;###tramp-autoload
 488 (defun tramp-gvfs-file-name-handler (operation &rest args)
 489   "Invoke the GVFS related OPERATION.
 490 First arg specifies the OPERATION, second arg is a list of arguments to
 491 pass to the OPERATION."
 492   (unless tramp-gvfs-enabled
 493     (tramp-user-error nil "Package `tramp-gvfs' not supported"))
 494   (let ((fn (assoc operation tramp-gvfs-file-name-handler-alist)))
 495     (if fn
 496         (save-match-data (apply (cdr fn) args))
 497       (tramp-run-real-handler operation args))))
 498
 499 ;; This might be moved to tramp.el.  It shall be the first file name
 500 ;; handler.
 501 ;;;###tramp-autoload
 502 (when (featurep 'dbusbind)
 503   (add-to-list 'tramp-foreign-file-name-handler-alist
 504                (cons 'tramp-gvfs-file-name-p 'tramp-gvfs-file-name-handler)))
 505
 506 \f
 507 ;; D-Bus helper function.
 508
 509 (defun tramp-gvfs-dbus-string-to-byte-array (string)
 510   "Like `dbus-string-to-byte-array' but add trailing \\0 if needed."
 511   (dbus-string-to-byte-array
 512    (if (string-match "^(aya{sv})" tramp-gvfs-mountlocation-signature)
 513        (concat string (string 0)) string)))
 514
 515 (defun tramp-gvfs-dbus-byte-array-to-string (byte-array)
 516   "Like `dbus-byte-array-to-string' but remove trailing \\0 if exists."
 517   ;; The byte array could be a variant.  Take care.
 518   (let ((byte-array
 519          (if (and (consp byte-array) (atom (car byte-array)))
 520              byte-array (car byte-array))))
 521     (dbus-byte-array-to-string
 522      (if (and (consp byte-array) (zerop (car (last byte-array))))
 523          (butlast byte-array) byte-array))))
 524
 525 (defun tramp-gvfs-stringify-dbus-message (message)
 526   "Convert a D-Bus message into readable UTF8 strings, used for traces."
 527   (cond
 528    ((and (consp message) (characterp (car message)))
 529     (format "%S" (tramp-gvfs-dbus-byte-array-to-string message)))
 530    ((consp message)
 531     (mapcar 'tramp-gvfs-stringify-dbus-message message))
 532    ((stringp message)
 533     (format "%S" message))
 534    (t message)))
 535
 536 (defmacro with-tramp-dbus-call-method
 537   (vec synchronous bus service path interface method &rest args)
 538   "Apply a D-Bus call on bus BUS.
 539
 540 If SYNCHRONOUS is non-nil, the call is synchronously.  Otherwise,
 541 it is an asynchronous call, with `ignore' as callback function.
 542
 543 The other arguments have the same meaning as with `dbus-call-method'
 544 or `dbus-call-method-asynchronously'.  Additionally, the call
 545 will be traced by Tramp with trace level 6."
 546   `(let ((func (if ,synchronous
 547                    'dbus-call-method 'dbus-call-method-asynchronously))
 548          (args (append (list ,bus ,service ,path ,interface ,method)
 549                        (if ,synchronous (list ,@args) (list 'ignore ,@args))))
 550          result)
 551      (tramp-message ,vec 6 "%s %s" func args)
 552      (setq result (apply func args))
 553      (tramp-message ,vec 6 "%s" (tramp-gvfs-stringify-dbus-message result))
 554      result))
 555
 556 (put 'with-tramp-dbus-call-method 'lisp-indent-function 2)
 557 (put 'with-tramp-dbus-call-method 'edebug-form-spec '(form symbolp body))
 558 (tramp-compat-font-lock-add-keywords
 559  'emacs-lisp-mode '("\\<with-tramp-dbus-call-method\\>"))
 560
 561 (defvar tramp-gvfs-dbus-event-vector nil
 562   "Current Tramp file name to be used, as vector.
 563 It is needed when D-Bus signals or errors arrive, because there
 564 is no information where to trace the message.")
 565
 566 (defun tramp-gvfs-dbus-event-error (event err)
 567   "Called when a D-Bus error message arrives, see `dbus-event-error-functions'."
 568   (when tramp-gvfs-dbus-event-vector
 569     (tramp-message tramp-gvfs-dbus-event-vector 10 "%S" event)
 570     (tramp-error tramp-gvfs-dbus-event-vector 'file-error "%s" (cadr err))))
 571
 572 ;; `dbus-event-error-hooks' has been renamed to `dbus-event-error-functions'.
 573 (add-hook
 574  (if (boundp 'dbus-event-error-functions)
 575      'dbus-event-error-functions 'dbus-event-error-hooks)
 576  'tramp-gvfs-dbus-event-error)
 577
 578 \f
 579 ;; File name primitives.
 580
 581 (defun tramp-gvfs-handle-copy-file
 582   (filename newname &optional ok-if-already-exists keep-date
 583             preserve-uid-gid preserve-extended-attributes)
 584   "Like `copy-file' for Tramp files."
 585   (with-parsed-tramp-file-name
 586       (if (tramp-tramp-file-p filename) filename newname) nil
 587
 588     (when (and (not ok-if-already-exists) (file-exists-p newname))
 589       (tramp-error
 590        v 'file-already-exists "File %s already exists" newname))
 591
 592     (if (or (and (tramp-tramp-file-p filename)
 593                  (not (tramp-gvfs-file-name-p filename)))
 594             (and (tramp-tramp-file-p newname)
 595                  (not (tramp-gvfs-file-name-p newname))))
 596
 597         ;; We cannot call `copy-file' directly.  Use
 598         ;; `tramp-compat-funcall' for backward compatibility (number
 599         ;; of arguments).
 600         (let ((tmpfile (tramp-compat-make-temp-file filename)))
 601           (cond
 602            (preserve-extended-attributes
 603             (tramp-compat-funcall
 604              'copy-file
 605              filename tmpfile t keep-date preserve-uid-gid
 606              preserve-extended-attributes))
 607            (preserve-uid-gid
 608             (tramp-compat-funcall
 609              'copy-file filename tmpfile t keep-date preserve-uid-gid))
 610            (t
 611             (copy-file filename tmpfile t keep-date)))
 612           (rename-file tmpfile newname ok-if-already-exists))
 613
 614       ;; Direct copy.
 615       (with-tramp-progress-reporter
 616           v 0 (format "Copying %s to %s" filename newname)
 617         (unless
 618             (let ((args
 619                    (append (if (or keep-date preserve-uid-gid)
 620                                (list "--preserve")
 621                              nil)
 622                            (list
 623                             (tramp-gvfs-url-file-name filename)
 624                             (tramp-gvfs-url-file-name newname)))))
 625               (apply 'tramp-gvfs-send-command v "gvfs-copy" args))
 626           ;; Propagate the error.
 627           (with-current-buffer (tramp-get-connection-buffer v)
 628             (goto-char (point-min))
 629             (tramp-error-with-buffer
 630              nil v 'file-error
 631              "Copying failed, see buffer `%s' for details." (buffer-name)))))
 632
 633       (when (tramp-tramp-file-p newname)
 634         (with-parsed-tramp-file-name newname nil
 635           (tramp-flush-file-property v (file-name-directory localname))
 636           (tramp-flush-file-property v localname))))))
 637
 638 (defun tramp-gvfs-handle-delete-directory (directory &optional recursive trash)
 639   "Like `delete-directory' for Tramp files."
 640   (when (and recursive (not (file-symlink-p directory)))
 641     (mapc (lambda (file)
 642             (if (eq t (car (file-attributes file)))
 643                 (tramp-compat-delete-directory file recursive trash)
 644               (tramp-compat-delete-file file trash)))
 645           (directory-files
 646            directory 'full "^\\([^.]\\|\\.\\([^.]\\|\\..\\)\\).*")))
 647   (with-parsed-tramp-file-name directory nil
 648     (tramp-flush-file-property v (file-name-directory localname))
 649     (tramp-flush-directory-property v localname)
 650     (unless
 651         (tramp-gvfs-send-command
 652          v (if (and trash delete-by-moving-to-trash) "gvfs-trash" "gvfs-rm")
 653          (tramp-gvfs-url-file-name directory))
 654       ;; Propagate the error.
 655       (with-current-buffer (tramp-get-connection-buffer v)
 656         (goto-char (point-min))
 657         (tramp-error-with-buffer
 658          nil v 'file-error "Couldn't delete %s" directory)))))
 659
 660 (defun tramp-gvfs-handle-delete-file (filename &optional trash)
 661   "Like `delete-file' for Tramp files."
 662   (with-parsed-tramp-file-name filename nil
 663     (tramp-flush-file-property v (file-name-directory localname))
 664     (tramp-flush-file-property v localname)
 665     (unless
 666         (tramp-gvfs-send-command
 667          v (if (and trash delete-by-moving-to-trash) "gvfs-trash" "gvfs-rm")
 668          (tramp-gvfs-url-file-name filename))
 669       ;; Propagate the error.
 670       (with-current-buffer (tramp-get-connection-buffer v)
 671         (goto-char (point-min))
 672         (tramp-error-with-buffer
 673          nil v 'file-error "Couldn't delete %s" filename)))))
 674
 675 (defun tramp-gvfs-handle-expand-file-name (name &optional dir)
 676   "Like `expand-file-name' for Tramp files."
 677   ;; If DIR is not given, use DEFAULT-DIRECTORY or "/".
 678   (setq dir (or dir default-directory "/"))
 679   ;; Unless NAME is absolute, concat DIR and NAME.
 680   (unless (file-name-absolute-p name)
 681     (setq name (concat (file-name-as-directory dir) name)))
 682   ;; If NAME is not a Tramp file, run the real handler.
 683   (if (not (tramp-tramp-file-p name))
 684       (tramp-run-real-handler 'expand-file-name (list name nil))
 685     ;; Dissect NAME.
 686     (with-parsed-tramp-file-name name nil
 687       ;; If there is a default location, expand tilde.
 688       (when (string-match "\\`\\(~\\)\\(/\\|\\'\\)" localname)
 689         (save-match-data
 690           (tramp-gvfs-maybe-open-connection (vector method user host "/" hop)))
 691         (setq localname
 692               (replace-match
 693                (tramp-get-file-property  v "/" "default-location" "~")
 694                nil t localname 1)))
 695       ;; Tilde expansion is not possible.
 696       (when (string-match "\\`\\(~[^/]*\\)\\(.*\\)\\'" localname)
 697         (tramp-error
 698          v 'file-error
 699          "Cannot expand tilde in file `%s'" name))
 700       (unless (tramp-run-real-handler 'file-name-absolute-p (list localname))
 701         (setq localname (concat "/" localname)))
 702       ;; We do not pass "/..".
 703       (if (string-equal "smb" method)
 704           (when (string-match "^/[^/]+\\(/\\.\\./?\\)" localname)
 705             (setq localname (replace-match "/" t t localname 1)))
 706         (when (string-match "^/\\.\\./?" localname)
 707           (setq localname (replace-match "/" t t localname))))
 708       ;; There might be a double slash.  Remove this.
 709       (while (string-match "//" localname)
 710         (setq localname (replace-match "/" t t localname)))
 711       ;; No tilde characters in file name, do normal
 712       ;; `expand-file-name' (this does "/./" and "/../").
 713       (tramp-make-tramp-file-name
 714        method user host
 715        (tramp-run-real-handler
 716         'expand-file-name (list localname))))))
 717
 718 (defun tramp-gvfs-handle-file-attributes (filename &optional id-format)
 719   "Like `file-attributes' for Tramp files."
 720   (unless id-format (setq id-format 'integer))
 721   ;; Don't modify `last-coding-system-used' by accident.
 722   (let ((last-coding-system-used last-coding-system-used)
 723         dirp res-symlink-target res-numlinks res-uid res-gid res-access
 724         res-mod res-change res-size res-filemodes res-inode res-device)
 725     (with-parsed-tramp-file-name filename nil
 726       (with-tramp-file-property
 727           v localname (format "file-attributes-%s" id-format)
 728         (tramp-message v 5 "file attributes: %s" localname)
 729         (tramp-gvfs-send-command
 730          v "gvfs-info" (tramp-gvfs-url-file-name filename))
 731         ;; Parse output ...
 732         (with-current-buffer (tramp-get-connection-buffer v)
 733           (goto-char (point-min))
 734           (when (re-search-forward "attributes:" nil t)
 735             ;; ... directory or symlink
 736             (goto-char (point-min))
 737             (setq dirp (if (re-search-forward "type:\\s-+directory" nil t) t))
 738             (goto-char (point-min))
 739             (setq res-symlink-target
 740                   (if (re-search-forward
 741                        "standard::symlink-target:\\s-+\\(\\S-+\\)" nil t)
 742                       (match-string 1)))
 743             ;; ... number links
 744             (goto-char (point-min))
 745             (setq res-numlinks
 746                   (if (re-search-forward "unix::nlink:\\s-+\\([0-9]+\\)" nil t)
 747                       (string-to-number (match-string 1)) 0))
 748             ;; ... uid and gid
 749             (goto-char (point-min))
 750             (setq res-uid
 751                   (or (if (eq id-format 'integer)
 752                           (if (re-search-forward
 753                                "unix::uid:\\s-+\\([0-9]+\\)" nil t)
 754                               (string-to-number (match-string 1)))
 755                         (if (re-search-forward
 756                              "owner::user:\\s-+\\(\\S-+\\)" nil t)
 757                             (match-string 1)))
 758                       (tramp-get-local-uid id-format)))
 759             (setq res-gid
 760                   (or (if (eq id-format 'integer)
 761                           (if (re-search-forward
 762                                "unix::gid:\\s-+\\([0-9]+\\)" nil t)
 763                               (string-to-number (match-string 1)))
 764                         (if (re-search-forward
 765                              "owner::group:\\s-+\\(\\S-+\\)" nil t)
 766                             (match-string 1)))
 767                       (tramp-get-local-gid id-format)))
 768             ;; ... last access, modification and change time
 769             (goto-char (point-min))
 770             (setq res-access
 771                   (if (re-search-forward
 772                        "time::access:\\s-+\\([0-9]+\\)" nil t)
 773                       (seconds-to-time (string-to-number (match-string 1)))
 774                     '(0 0)))
 775             (goto-char (point-min))
 776             (setq res-mod
 777                   (if (re-search-forward
 778                        "time::modified:\\s-+\\([0-9]+\\)" nil t)
 779                       (seconds-to-time (string-to-number (match-string 1)))
 780                     '(0 0)))
 781             (goto-char (point-min))
 782             (setq res-change
 783                   (if (re-search-forward
 784                        "time::changed:\\s-+\\([0-9]+\\)" nil t)
 785                       (seconds-to-time (string-to-number (match-string 1)))
 786                     '(0 0)))
 787             ;; ... size
 788             (goto-char (point-min))
 789             (setq res-size
 790                   (if (re-search-forward
 791                        "standard::size:\\s-+\\([0-9]+\\)" nil t)
 792                       (string-to-number (match-string 1)) 0))
 793             ;; ... file mode flags
 794             (goto-char (point-min))
 795             (setq res-filemodes
 796                   (if (re-search-forward "unix::mode:\\s-+\\([0-9]+\\)" nil t)
 797                       (tramp-file-mode-from-int
 798                        (string-to-number (match-string 1)))
 799                     (if dirp "drwx------" "-rwx------")))
 800             ;; ... inode and device
 801             (goto-char (point-min))
 802             (setq res-inode
 803                   (if (re-search-forward "unix::inode:\\s-+\\([0-9]+\\)" nil t)
 804                       (string-to-number (match-string 1))
 805                     (tramp-get-inode v)))
 806             (goto-char (point-min))
 807             (setq res-device
 808                   (if (re-search-forward "unix::device:\\s-+\\([0-9]+\\)" nil t)
 809                       (string-to-number (match-string 1))
 810                     (tramp-get-device v)))
 811
 812             ;; Return data gathered.
 813             (list
 814              ;; 0. t for directory, string (name linked to) for
 815              ;; symbolic link, or nil.
 816              (or dirp res-symlink-target)
 817              ;; 1. Number of links to file.
 818              res-numlinks
 819              ;; 2. File uid.
 820              res-uid
 821              ;; 3. File gid.
 822              res-gid
 823              ;; 4. Last access time, as a list of integers.
 824              ;; 5. Last modification time, likewise.
 825              ;; 6. Last status change time, likewise.
 826              res-access res-mod res-change
 827              ;; 7. Size in bytes (-1, if number is out of range).
 828              res-size
 829              ;; 8. File modes.
 830              res-filemodes
 831              ;; 9. t if file's gid would change if file were deleted
 832              ;; and recreated.
 833              nil
 834              ;; 10. Inode number.
 835              res-inode
 836              ;; 11. Device number.
 837              res-device
 838              )))))))
 839
 840 (defun tramp-gvfs-handle-file-directory-p (filename)
 841   "Like `file-directory-p' for Tramp files."
 842   (eq t (car (file-attributes filename))))
 843
 844 (defun tramp-gvfs-handle-file-executable-p (filename)
 845   "Like `file-executable-p' for Tramp files."
 846   (with-parsed-tramp-file-name filename nil
 847     (with-tramp-file-property v localname "file-executable-p"
 848       (tramp-check-cached-permissions v ?x))))
 849
 850 (defun tramp-gvfs-handle-file-local-copy (filename)
 851   "Like `file-local-copy' for Tramp files."
 852   (with-parsed-tramp-file-name filename nil
 853     (let ((tmpfile (tramp-compat-make-temp-file filename)))
 854       (unless (file-exists-p filename)
 855         (tramp-error
 856          v 'file-error
 857          "Cannot make local copy of non-existing file `%s'" filename))
 858       (copy-file filename tmpfile t t)
 859       tmpfile)))
 860
 861 (defun tramp-gvfs-handle-file-name-all-completions (filename directory)
 862   "Like `file-name-all-completions' for Tramp files."
 863   (unless (save-match-data (string-match "/" filename))
 864     (with-parsed-tramp-file-name (expand-file-name directory) nil
 865
 866       (all-completions
 867        filename
 868        (mapcar
 869         'list
 870         (or
 871          ;; Try cache entries for filename, filename with last
 872          ;; character removed, filename with last two characters
 873          ;; removed, ..., and finally the empty string - all
 874          ;; concatenated to the local directory name.
 875          (let ((remote-file-name-inhibit-cache
 876                 (or remote-file-name-inhibit-cache
 877                     tramp-completion-reread-directory-timeout)))
 878
 879            ;; This is inefficient for very long filenames, pity
 880            ;; `reduce' is not available...
 881            (car
 882             (apply
 883              'append
 884              (mapcar
 885               (lambda (x)
 886                 (let ((cache-hit
 887                        (tramp-get-file-property
 888                         v
 889                         (concat localname (substring filename 0 x))
 890                         "file-name-all-completions"
 891                         nil)))
 892                   (when cache-hit (list cache-hit))))
 893               ;; We cannot use a length of 0, because file properties
 894               ;; for "foo" and "foo/" are identical.
 895               (tramp-compat-number-sequence (length filename) 1 -1)))))
 896
 897          ;; Cache expired or no matching cache entry found so we need
 898          ;; to perform a remote operation.
 899          (let ((result '("." ".."))
 900                entry)
 901            ;; Get a list of directories and files.
 902            (tramp-gvfs-send-command
 903             v "gvfs-ls" "-h" (tramp-gvfs-url-file-name directory))
 904
 905            ;; Now grab the output.
 906            (with-temp-buffer
 907              (insert-buffer-substring (tramp-get-connection-buffer v))
 908              (goto-char (point-max))
 909              (while (zerop (forward-line -1))
 910                (setq entry (buffer-substring (point) (point-at-eol)))
 911                (when (string-match filename entry)
 912                  (if (file-directory-p (expand-file-name entry directory))
 913                      (push (concat entry "/") result)
 914                    (push entry result)))))
 915
 916            ;; Because the remote op went through OK we know the
 917            ;; directory we `cd'-ed to exists.
 918            (tramp-set-file-property v localname "file-exists-p" t)
 919
 920            ;; Because the remote op went through OK we know every
 921            ;; file listed by `ls' exists.
 922            (mapc (lambda (entry)
 923                    (tramp-set-file-property
 924                     v (concat localname entry) "file-exists-p" t))
 925                  result)
 926
 927            ;; Store result in the cache.
 928            (tramp-set-file-property
 929             v (concat localname filename)
 930             "file-name-all-completions" result))))))))
 931
 932 (defun tramp-gvfs-handle-file-notify-add-watch (file-name _flags _callback)
 933   "Like `file-notify-add-watch' for Tramp files."
 934   (setq file-name (expand-file-name file-name))
 935   (with-parsed-tramp-file-name file-name nil
 936     (let ((p (start-process
 937               "gvfs-monitor-file" (generate-new-buffer " *gvfs-monitor-file*")
 938               "gvfs-monitor-file" (tramp-gvfs-url-file-name file-name))))
 939       (if (not (processp p))
 940           (tramp-error
 941            v 'file-notify-error "gvfs-monitor-file failed to start")
 942         (tramp-message
 943          v 6 "Run `%s', %S" (mapconcat 'identity (process-command p) " ") p)
 944         (tramp-set-connection-property p "vector" v)
 945         (tramp-compat-set-process-query-on-exit-flag p nil)
 946         (set-process-filter p 'tramp-gvfs-file-gvfs-monitor-file-process-filter)
 947         (with-current-buffer (process-buffer p)
 948           (setq default-directory (file-name-directory file-name)))
 949         p))))
 950
 951 (defun tramp-gvfs-file-gvfs-monitor-file-process-filter (proc string)
 952   "Read output from \"gvfs-monitor-file\" and add corresponding file-notify events."
 953   (let* ((rest-string (tramp-compat-process-get proc 'rest-string))
 954          (dd (with-current-buffer (process-buffer proc) default-directory))
 955          (ddu (regexp-quote (tramp-gvfs-url-file-name dd))))
 956     (when rest-string
 957       (tramp-message proc 10 "Previous string:\n%s" rest-string))
 958     (tramp-message proc 6 "%S\n%s" proc string)
 959     (setq string (concat rest-string string)
 960           ;; Attribute change is returned in unused wording.
 961           string (tramp-compat-replace-regexp-in-string
 962                   "ATTRIB CHANGED" "ATTRIBUTE_CHANGED" string))
 963
 964     (while (string-match
 965             (concat "^[\n\r]*"
 966                     "File Monitor Event:[\n\r]+"
 967                     "File = \\([^\n\r]+\\)[\n\r]+"
 968                     "Event = \\([^[:blank:]]+\\)[\n\r]+")
 969             string)
 970       (let ((action (intern-soft
 971                      (tramp-compat-replace-regexp-in-string
 972                       "_" "-" (downcase (match-string 2 string)))))
 973             (file (match-string 1 string)))
 974         (setq string (replace-match "" nil nil string))
 975         ;; File names are returned as URL paths.  We must convert them.
 976         (when (string-match ddu file)
 977           (setq file (replace-match dd nil nil file)))
 978         (while (string-match "%\\([0-9A-F]\\{2\\}\\)" file)
 979           (setq file
 980                 (replace-match
 981                  (char-to-string (string-to-number (match-string 1 file) 16))
 982                  nil nil file)))
 983         ;; Usually, we would add an Emacs event now.  Unfortunately,
 984         ;; `unread-command-events' does not accept several events at
 985         ;; once.  Therefore, we apply the callback directly.
 986         (tramp-compat-funcall 'file-notify-callback (list proc action file))))
 987
 988     ;; Save rest of the string.
 989     (when (zerop (length string)) (setq string nil))
 990     (when string (tramp-message proc 10 "Rest string:\n%s" string))
 991     (tramp-compat-process-put proc 'rest-string string)))
 992
 993 (defun tramp-gvfs-handle-file-readable-p (filename)
 994   "Like `file-readable-p' for Tramp files."
 995   (with-parsed-tramp-file-name filename nil
 996     (with-tramp-file-property v localname "file-executable-p"
 997       (tramp-check-cached-permissions v ?r))))
 998
 999 (defun tramp-gvfs-handle-file-writable-p (filename)
1000   "Like `file-writable-p' for Tramp files."
1001   (with-parsed-tramp-file-name filename nil
1002     (with-tramp-file-property v localname "file-writable-p"
1003       (if (file-exists-p filename)
1004           (tramp-check-cached-permissions v ?w)
1005         ;; If file doesn't exist, check if directory is writable.
1006         (and (file-directory-p (file-name-directory filename))
1007              (file-writable-p (file-name-directory filename)))))))
1008
1009 (defun tramp-gvfs-handle-make-directory (dir &optional parents)
1010   "Like `make-directory' for Tramp files."
1011   (with-parsed-tramp-file-name dir nil
1012     (unless
1013         (apply
1014          'tramp-gvfs-send-command v "gvfs-mkdir"
1015          (if parents
1016              (list "-p" (tramp-gvfs-url-file-name dir))
1017            (list (tramp-gvfs-url-file-name dir))))
1018       ;; Propagate the error.
1019       (tramp-error v 'file-error "Couldn't make directory %s" dir))))
1020
1021 (defun tramp-gvfs-handle-rename-file
1022   (filename newname &optional ok-if-already-exists)
1023   "Like `rename-file' for Tramp files."
1024   (with-parsed-tramp-file-name
1025       (if (tramp-tramp-file-p filename) filename newname) nil
1026
1027     (when (and (not ok-if-already-exists) (file-exists-p newname))
1028       (tramp-error
1029        v 'file-already-exists "File %s already exists" newname))
1030
1031     (if (or (and (tramp-tramp-file-p filename)
1032                  (not (tramp-gvfs-file-name-p filename)))
1033             (and (tramp-tramp-file-p newname)
1034                  (not (tramp-gvfs-file-name-p newname))))
1035
1036         ;; We cannot move directly.
1037         (let ((tmpfile (tramp-compat-make-temp-file filename)))
1038           (rename-file filename tmpfile t)
1039           (rename-file tmpfile newname ok-if-already-exists))
1040
1041       ;; Direct move.
1042       (with-tramp-progress-reporter
1043           v 0 (format "Renaming %s to %s" filename newname)
1044         (unless
1045             (tramp-gvfs-send-command
1046              v "gvfs-move"
1047              (tramp-gvfs-url-file-name filename)
1048              (tramp-gvfs-url-file-name newname))
1049           ;; Propagate the error.
1050           (with-current-buffer (tramp-get-buffer v)
1051             (goto-char (point-min))
1052             (tramp-error-with-buffer
1053              nil v 'file-error
1054              "Renaming failed, see buffer `%s' for details." (buffer-name)))))
1055
1056       (when (tramp-tramp-file-p filename)
1057         (with-parsed-tramp-file-name filename nil
1058           (tramp-flush-file-property v (file-name-directory localname))
1059           (tramp-flush-file-property v localname)))
1060
1061       (when (tramp-tramp-file-p newname)
1062         (with-parsed-tramp-file-name newname nil
1063           (tramp-flush-file-property v (file-name-directory localname))
1064           (tramp-flush-file-property v localname))))))
1065
1066 (defun tramp-gvfs-handle-write-region
1067   (start end filename &optional append visit lockname confirm)
1068   "Like `write-region' for Tramp files."
1069   (with-parsed-tramp-file-name filename nil
1070     ;; XEmacs takes a coding system as the seventh argument, not `confirm'.
1071     (when (and (not (featurep 'xemacs)) confirm (file-exists-p filename))
1072       (unless (y-or-n-p (format "File %s exists; overwrite anyway? " filename))
1073         (tramp-error v 'file-error "File not overwritten")))
1074
1075     (let ((tmpfile (tramp-compat-make-temp-file filename)))
1076       (when (and append (file-exists-p filename))
1077         (copy-file filename tmpfile 'ok))
1078       ;; We say `no-message' here because we don't want the visited file
1079       ;; modtime data to be clobbered from the temp file.  We call
1080       ;; `set-visited-file-modtime' ourselves later on.
1081       (tramp-run-real-handler
1082        'write-region
1083        (if confirm ; don't pass this arg unless defined for backward compat.
1084            (list start end tmpfile append 'no-message lockname confirm)
1085          (list start end tmpfile append 'no-message lockname)))
1086       (condition-case nil
1087           (rename-file tmpfile filename 'ok-if-already-exists)
1088         (error
1089          (delete-file tmpfile)
1090          (tramp-error
1091           v 'file-error "Couldn't write region to `%s'" filename))))
1092
1093     (tramp-flush-file-property v (file-name-directory localname))
1094     (tramp-flush-file-property v localname)
1095
1096     ;; Set file modification time.
1097     (when (or (eq visit t) (stringp visit))
1098       (set-visited-file-modtime (nth 5 (file-attributes filename))))
1099
1100     ;; The end.
1101     (when (or (eq visit t) (null visit) (stringp visit))
1102       (tramp-message v 0 "Wrote %s" filename))
1103     (run-hooks 'tramp-handle-write-region-hook)))
1104
1105 \f
1106 ;; File name conversions.
1107
1108 (defun tramp-gvfs-url-file-name (filename)
1109   "Return FILENAME in URL syntax."
1110   ;; "/" must NOT be hexlified.
1111   (let ((url-unreserved-chars (append '(?/) url-unreserved-chars))
1112         result)
1113     (setq
1114      result
1115      (url-recreate-url
1116       (if (tramp-tramp-file-p filename)
1117           (with-parsed-tramp-file-name filename nil
1118             (when (and user (string-match tramp-user-with-domain-regexp user))
1119               (setq user
1120                     (concat (match-string 2 user) ";" (match-string 1 user))))
1121             (url-parse-make-urlobj
1122              method (and user (url-hexify-string user)) nil
1123              (tramp-file-name-real-host v) (tramp-file-name-port v)
1124              (and localname (url-hexify-string localname)) nil nil t))
1125         (url-parse-make-urlobj
1126          "file" nil nil nil nil
1127          (url-hexify-string (file-truename filename)) nil nil t))))
1128     (when (tramp-tramp-file-p filename)
1129       (with-parsed-tramp-file-name filename nil
1130         (tramp-message v 10 "remote file `%s' is URL `%s'" filename result)))
1131     result))
1132
1133 (defun tramp-gvfs-object-path (filename)
1134   "Create a D-Bus object path from FILENAME."
1135   (expand-file-name (dbus-escape-as-identifier filename) tramp-gvfs-path-tramp))
1136
1137 (defun tramp-gvfs-file-name (object-path)
1138   "Retrieve file name from D-Bus OBJECT-PATH."
1139   (dbus-unescape-from-identifier
1140    (tramp-compat-replace-regexp-in-string
1141     "^.*/\\([^/]+\\)$" "\\1" object-path)))
1142
1143 (defun tramp-bluez-address (device)
1144   "Return bluetooth device address from a given bluetooth DEVICE name."
1145   (when (stringp device)
1146     (if (string-match tramp-ipv6-regexp device)
1147         (match-string 0 device)
1148       (cadr (assoc device (tramp-bluez-list-devices))))))
1149
1150 (defun tramp-bluez-device (address)
1151   "Return bluetooth device name from a given bluetooth device ADDRESS.
1152 ADDRESS can have the form \"xx:xx:xx:xx:xx:xx\" or \"[xx:xx:xx:xx:xx:xx]\"."
1153   (when (stringp address)
1154     (while (string-match "[][]" address)
1155       (setq address (replace-match "" t t address)))
1156     (let (result)
1157       (dolist (item (tramp-bluez-list-devices) result)
1158         (when (string-match address (cadr item))
1159           (setq result (car item)))))))
1160
1161 \f
1162 ;; D-Bus GVFS functions.
1163
1164 (defun tramp-gvfs-handler-askpassword (message user domain flags)
1165   "Implementation for the \"org.gtk.vfs.MountOperation.askPassword\" method."
1166   (let* ((filename
1167           (tramp-gvfs-file-name (dbus-event-path-name last-input-event)))
1168          (pw-prompt
1169           (format
1170            "%s for %s "
1171            (if (string-match "\\([pP]assword\\|[pP]assphrase\\)" message)
1172                (capitalize (match-string 1 message))
1173              "Password")
1174            filename))
1175          password)
1176
1177     (condition-case nil
1178         (with-parsed-tramp-file-name filename l
1179           (when (and (zerop (length user))
1180                      (not
1181                       (zerop (logand flags tramp-gvfs-password-need-username))))
1182             (setq user (read-string "User name: ")))
1183           (when (and (zerop (length domain))
1184                      (not
1185                       (zerop (logand flags tramp-gvfs-password-need-domain))))
1186             (setq domain (read-string "Domain name: ")))
1187
1188           (tramp-message l 6 "%S %S %S %d" message user domain flags)
1189           (unless (tramp-get-connection-property l "first-password-request" nil)
1190             (tramp-clear-passwd l))
1191
1192           (setq tramp-current-method l-method
1193                 tramp-current-user user
1194                 tramp-current-host l-host
1195                 password (tramp-read-passwd
1196                           (tramp-get-connection-process l) pw-prompt))
1197
1198           ;; Return result.
1199           (if (stringp password)
1200               (list
1201                t ;; password handled.
1202                nil ;; no abort of D-Bus.
1203                password
1204                (tramp-file-name-real-user l)
1205                domain
1206                nil ;; not anonymous.
1207                0) ;; no password save.
1208             ;; No password provided.
1209             (list nil t "" (tramp-file-name-real-user l) domain nil 0)))
1210
1211       ;; When QUIT is raised, we shall return this information to D-Bus.
1212       (quit (list nil t "" "" "" nil 0)))))
1213
1214 (defun tramp-gvfs-handler-askquestion (message choices)
1215   "Implementation for the \"org.gtk.vfs.MountOperation.askQuestion\" method."
1216   (save-window-excursion
1217     (let ((enable-recursive-minibuffers t)
1218           choice)
1219
1220       (condition-case nil
1221           (with-parsed-tramp-file-name
1222               (tramp-gvfs-file-name (dbus-event-path-name last-input-event)) nil
1223             (tramp-message v 6 "%S %S" message choices)
1224
1225             ;; In theory, there can be several choices.  Until now,
1226             ;; there is only the question whether to accept an unknown
1227             ;; host signature.
1228             (with-temp-buffer
1229               ;; Preserve message for `progress-reporter'.
1230               (tramp-compat-with-temp-message ""
1231                 (insert message)
1232                 (pop-to-buffer (current-buffer))
1233                 (setq choice (if (yes-or-no-p (concat (car choices) " ")) 0 1))
1234                 (tramp-message v 6 "%d" choice)))
1235
1236             ;; When the choice is "no", we set a dummy fuse-mountpoint
1237             ;; in order to leave the timeout.
1238             (unless (zerop choice)
1239               (tramp-set-file-property v "/" "fuse-mountpoint" "/"))
1240
1241             (list
1242              t ;; handled.
1243              nil ;; no abort of D-Bus.
1244              choice))
1245
1246         ;; When QUIT is raised, we shall return this information to D-Bus.
1247         (quit (list nil t 0))))))
1248
1249 (defun tramp-gvfs-handler-mounted-unmounted (mount-info)
1250   "Signal handler for the \"org.gtk.vfs.MountTracker.mounted\" and
1251 \"org.gtk.vfs.MountTracker.unmounted\" signals."
1252   (ignore-errors
1253     (let ((signal-name (dbus-event-member-name last-input-event))
1254           (elt mount-info))
1255       ;; Jump over the first elements of the mount info. Since there
1256       ;; were changes in the entries, we cannot access dedicated
1257       ;; elements.
1258       (while (stringp (car elt)) (setq elt (cdr elt)))
1259       (let* ((fuse-mountpoint (tramp-gvfs-dbus-byte-array-to-string (cadr elt)))
1260              (mount-spec (caddr elt))
1261              (default-location (tramp-gvfs-dbus-byte-array-to-string
1262                                 (cadddr elt)))
1263              (method (tramp-gvfs-dbus-byte-array-to-string
1264                       (cadr (assoc "type" (cadr mount-spec)))))
1265              (user (tramp-gvfs-dbus-byte-array-to-string
1266                     (cadr (assoc "user" (cadr mount-spec)))))
1267              (domain (tramp-gvfs-dbus-byte-array-to-string
1268                       (cadr (assoc "domain" (cadr mount-spec)))))
1269              (host (tramp-gvfs-dbus-byte-array-to-string
1270                     (cadr (or (assoc "host" (cadr mount-spec))
1271                               (assoc "server" (cadr mount-spec))))))
1272              (port (tramp-gvfs-dbus-byte-array-to-string
1273                     (cadr (assoc "port" (cadr mount-spec)))))
1274              (ssl (tramp-gvfs-dbus-byte-array-to-string
1275                    (cadr (assoc "ssl" (cadr mount-spec)))))
1276              (prefix (concat (tramp-gvfs-dbus-byte-array-to-string
1277                               (car mount-spec))
1278                              (tramp-gvfs-dbus-byte-array-to-string
1279                               (cadr (assoc "share" (cadr mount-spec)))))))
1280         (when (string-match "^smb" method)
1281           (setq method "smb"))
1282         (when (string-equal "obex" method)
1283           (setq host (tramp-bluez-device host)))
1284         (when (and (string-equal "dav" method) (string-equal "true" ssl))
1285           (setq method "davs"))
1286         (unless (zerop (length domain))
1287           (setq user (concat user tramp-prefix-domain-format domain)))
1288         (unless (zerop (length port))
1289           (setq host (concat host tramp-prefix-port-format port)))
1290         (with-parsed-tramp-file-name
1291             (tramp-make-tramp-file-name method user host "") nil
1292           (tramp-message
1293            v 6 "%s %s"
1294            signal-name (tramp-gvfs-stringify-dbus-message mount-info))
1295           (tramp-set-file-property v "/" "list-mounts" 'undef)
1296           (if (string-equal (downcase signal-name) "unmounted")
1297               (tramp-set-file-property v "/" "fuse-mountpoint" nil)
1298             ;; Set prefix, mountpoint and location.
1299             (unless (string-equal prefix "/")
1300               (tramp-set-file-property v "/" "prefix" prefix))
1301             (tramp-set-file-property v "/" "fuse-mountpoint" fuse-mountpoint)
1302             (tramp-set-file-property
1303              v "/" "default-location" default-location)))))))
1304
1305 (when tramp-gvfs-enabled
1306   (dbus-register-signal
1307    :session nil tramp-gvfs-path-mounttracker
1308    tramp-gvfs-interface-mounttracker "mounted"
1309    'tramp-gvfs-handler-mounted-unmounted)
1310   (dbus-register-signal
1311    :session nil tramp-gvfs-path-mounttracker
1312    tramp-gvfs-interface-mounttracker "Mounted"
1313    'tramp-gvfs-handler-mounted-unmounted)
1314
1315   (dbus-register-signal
1316    :session nil tramp-gvfs-path-mounttracker
1317    tramp-gvfs-interface-mounttracker "unmounted"
1318    'tramp-gvfs-handler-mounted-unmounted)
1319   (dbus-register-signal
1320    :session nil tramp-gvfs-path-mounttracker
1321    tramp-gvfs-interface-mounttracker "Unmounted"
1322    'tramp-gvfs-handler-mounted-unmounted))
1323
1324 (defun tramp-gvfs-connection-mounted-p (vec)
1325   "Check, whether the location is already mounted."
1326   (or
1327    (tramp-get-file-property vec "/" "fuse-mountpoint" nil)
1328    (catch 'mounted
1329      (dolist
1330          (elt
1331           (with-tramp-file-property vec "/" "list-mounts"
1332             (with-tramp-dbus-call-method vec t
1333               :session tramp-gvfs-service-daemon tramp-gvfs-path-mounttracker
1334               tramp-gvfs-interface-mounttracker tramp-gvfs-listmounts))
1335           nil)
1336        ;; Jump over the first elements of the mount info. Since there
1337        ;; were changes in the entries, we cannot access dedicated
1338        ;; elements.
1339        (while (stringp (car elt)) (setq elt (cdr elt)))
1340        (let* ((fuse-mountpoint (tramp-gvfs-dbus-byte-array-to-string
1341                                 (cadr elt)))
1342               (mount-spec (caddr elt))
1343               (default-location (tramp-gvfs-dbus-byte-array-to-string
1344                                  (cadddr elt)))
1345               (method (tramp-gvfs-dbus-byte-array-to-string
1346                        (cadr (assoc "type" (cadr mount-spec)))))
1347               (user (tramp-gvfs-dbus-byte-array-to-string
1348                      (cadr (assoc "user" (cadr mount-spec)))))
1349               (domain (tramp-gvfs-dbus-byte-array-to-string
1350                        (cadr (assoc "domain" (cadr mount-spec)))))
1351               (host (tramp-gvfs-dbus-byte-array-to-string
1352                      (cadr (or (assoc "host" (cadr mount-spec))
1353                                (assoc "server" (cadr mount-spec))))))
1354               (port (tramp-gvfs-dbus-byte-array-to-string
1355                      (cadr (assoc "port" (cadr mount-spec)))))
1356               (ssl (tramp-gvfs-dbus-byte-array-to-string
1357                     (cadr (assoc "ssl" (cadr mount-spec)))))
1358               (prefix (concat (tramp-gvfs-dbus-byte-array-to-string
1359                                (car mount-spec))
1360                               (tramp-gvfs-dbus-byte-array-to-string
1361                                (cadr (assoc "share" (cadr mount-spec)))))))
1362          (when (string-match "^smb" method)
1363            (setq method "smb"))
1364          (when (string-equal "obex" method)
1365            (setq host (tramp-bluez-device host)))
1366          (when (and (string-equal "dav" method) (string-equal "true" ssl))
1367            (setq method "davs"))
1368          (when (and (string-equal "synce" method) (zerop (length user)))
1369            (setq user (or (tramp-file-name-user vec) "")))
1370          (unless (zerop (length domain))
1371            (setq user (concat user tramp-prefix-domain-format domain)))
1372          (unless (zerop (length port))
1373            (setq host (concat host tramp-prefix-port-format port)))
1374          (when (and
1375                 (string-equal method (tramp-file-name-method vec))
1376                 (string-equal user (or (tramp-file-name-user vec) ""))
1377                 (string-equal host (tramp-file-name-host vec))
1378                 (string-match (concat "^" (regexp-quote prefix))
1379                               (tramp-file-name-localname vec)))
1380            ;; Set prefix, mountpoint and location.
1381            (unless (string-equal prefix "/")
1382              (tramp-set-file-property vec "/" "prefix" prefix))
1383            (tramp-set-file-property vec "/" "fuse-mountpoint" fuse-mountpoint)
1384            (tramp-set-file-property vec "/" "default-location" default-location)
1385            (throw 'mounted t)))))))
1386
1387 (defun tramp-gvfs-mount-spec-entry (key value)
1388   "Construct a mount-spec entry to be used in a mount_spec.
1389 It was \"a(say)\", but has changed to \"a{sv})\"."
1390   (if (string-match "^(aya{sv})" tramp-gvfs-mountlocation-signature)
1391       (list :dict-entry key
1392             (list :variant (tramp-gvfs-dbus-string-to-byte-array value)))
1393     (list :struct key (tramp-gvfs-dbus-string-to-byte-array value))))
1394
1395 (defun tramp-gvfs-mount-spec (vec)
1396   "Return a mount-spec for \"org.gtk.vfs.MountTracker.mountLocation\"."
1397   (let* ((method (tramp-file-name-method vec))
1398          (user (tramp-file-name-real-user vec))
1399          (domain (tramp-file-name-domain vec))
1400          (host (tramp-file-name-real-host vec))
1401          (port (tramp-file-name-port vec))
1402          (localname (tramp-file-name-localname vec))
1403          (ssl (if (string-match "^davs" method) "true" "false"))
1404          (mount-spec
1405           `(:array
1406             ,@(cond
1407                ((string-equal "smb" method)
1408                 (string-match "^/?\\([^/]+\\)" localname)
1409                 (list (tramp-gvfs-mount-spec-entry "type" "smb-share")
1410                       (tramp-gvfs-mount-spec-entry "server" host)
1411                       (tramp-gvfs-mount-spec-entry
1412                        "share" (match-string 1 localname))))
1413                ((string-equal "obex" method)
1414                 (list (tramp-gvfs-mount-spec-entry "type" method)
1415                       (tramp-gvfs-mount-spec-entry
1416                        "host" (concat "[" (tramp-bluez-address host) "]"))))
1417                ((string-match "\\`dav" method)
1418                 (list (tramp-gvfs-mount-spec-entry "type" "dav")
1419                       (tramp-gvfs-mount-spec-entry "host" host)
1420                       (tramp-gvfs-mount-spec-entry "ssl" ssl)))
1421                (t
1422                 (list (tramp-gvfs-mount-spec-entry "type" method)
1423                       (tramp-gvfs-mount-spec-entry "host" host))))
1424             ,@(when user
1425                 (list (tramp-gvfs-mount-spec-entry "user" user)))
1426             ,@(when domain
1427                 (list (tramp-gvfs-mount-spec-entry "domain" domain)))
1428             ,@(when port
1429                 (list (tramp-gvfs-mount-spec-entry
1430                        "port" (number-to-string port))))))
1431          (mount-pref
1432           (if (and (string-match "\\`dav" method)
1433                    (string-match "^/?[^/]+" localname))
1434               (match-string 0 localname)
1435             "/")))
1436
1437     ;; Return.
1438     `(:struct ,(tramp-gvfs-dbus-string-to-byte-array mount-pref) ,mount-spec)))
1439
1440 \f
1441 ;; Connection functions.
1442
1443 (defun tramp-gvfs-maybe-open-connection (vec)
1444   "Maybe open a connection VEC.
1445 Does not do anything if a connection is already open, but re-opens the
1446 connection if a previous connection has died for some reason."
1447   (tramp-check-proper-method-and-host vec)
1448
1449   ;; We set the file name, in case there are incoming D-Bus signals or
1450   ;; D-Bus errors.
1451   (setq tramp-gvfs-dbus-event-vector vec)
1452
1453   ;; For password handling, we need a process bound to the connection
1454   ;; buffer.  Therefore, we create a dummy process.  Maybe there is a
1455   ;; better solution?
1456   (unless (get-buffer-process (tramp-get-connection-buffer vec))
1457     (let ((p (make-network-process
1458               :name (tramp-buffer-name vec)
1459               :buffer (tramp-get-connection-buffer vec)
1460               :server t :host 'local :service t)))
1461       (tramp-compat-set-process-query-on-exit-flag p nil)))
1462
1463   (unless (tramp-gvfs-connection-mounted-p vec)
1464     (let* ((method (tramp-file-name-method vec))
1465            (user (tramp-file-name-user vec))
1466            (host (tramp-file-name-host vec))
1467            (localname (tramp-file-name-localname vec))
1468            (object-path
1469             (tramp-gvfs-object-path
1470              (tramp-make-tramp-file-name method user host ""))))
1471
1472       (when (and (string-equal method "smb")
1473                  (string-equal localname "/"))
1474         (tramp-error vec 'file-error "Filename must contain a Windows share"))
1475
1476       (with-tramp-progress-reporter
1477           vec 3
1478           (if (zerop (length user))
1479               (format "Opening connection for %s using %s" host method)
1480             (format "Opening connection for %s@%s using %s" user host method))
1481
1482         ;; Enable `auth-source'.
1483         (tramp-set-connection-property vec "first-password-request" t)
1484
1485         ;; There will be a callback of "askPassword" when a password is
1486         ;; needed.
1487         (dbus-register-method
1488          :session dbus-service-emacs object-path
1489          tramp-gvfs-interface-mountoperation "askPassword"
1490          'tramp-gvfs-handler-askpassword)
1491         (dbus-register-method
1492          :session dbus-service-emacs object-path
1493          tramp-gvfs-interface-mountoperation "AskPassword"
1494          'tramp-gvfs-handler-askpassword)
1495
1496         ;; There could be a callback of "askQuestion" when adding fingerprint.
1497         (dbus-register-method
1498          :session dbus-service-emacs object-path
1499          tramp-gvfs-interface-mountoperation "askQuestion"
1500          'tramp-gvfs-handler-askquestion)
1501         (dbus-register-method
1502          :session dbus-service-emacs object-path
1503          tramp-gvfs-interface-mountoperation "AskQuestion"
1504          'tramp-gvfs-handler-askquestion)
1505
1506         ;; The call must be asynchronously, because of the "askPassword"
1507         ;; or "askQuestion"callbacks.
1508         (if (string-match "(so)$" tramp-gvfs-mountlocation-signature)
1509             (with-tramp-dbus-call-method vec nil
1510               :session tramp-gvfs-service-daemon tramp-gvfs-path-mounttracker
1511               tramp-gvfs-interface-mounttracker tramp-gvfs-mountlocation
1512               (tramp-gvfs-mount-spec vec)
1513               `(:struct :string ,(dbus-get-unique-name :session)
1514                         :object-path ,object-path))
1515           (with-tramp-dbus-call-method vec nil
1516             :session tramp-gvfs-service-daemon tramp-gvfs-path-mounttracker
1517             tramp-gvfs-interface-mounttracker tramp-gvfs-mountlocation
1518             (tramp-gvfs-mount-spec vec)
1519             :string (dbus-get-unique-name :session) :object-path object-path))
1520
1521         ;; We must wait, until the mount is applied.  This will be
1522         ;; indicated by the "mounted" signal, i.e. the "fuse-mountpoint"
1523         ;; file property.
1524         (with-timeout
1525             ((or (tramp-get-method-parameter method 'tramp-connection-timeout)
1526                  tramp-connection-timeout)
1527              (if (zerop (length (tramp-file-name-user vec)))
1528                  (tramp-error
1529                   vec 'file-error
1530                   "Timeout reached mounting %s using %s" host method)
1531                (tramp-error
1532                 vec 'file-error
1533                 "Timeout reached mounting %s@%s using %s" user host method)))
1534           (while (not (tramp-get-file-property vec "/" "fuse-mountpoint" nil))
1535             (read-event nil nil 0.1)))
1536
1537         ;; If `tramp-gvfs-handler-askquestion' has returned "No", it
1538         ;; is marked with the fuse-mountpoint "/".  We shall react.
1539         (when (string-equal
1540                (tramp-get-file-property vec "/" "fuse-mountpoint" "") "/")
1541           (tramp-error vec 'file-error "FUSE mount denied")))))
1542
1543   ;; In `tramp-check-cached-permissions', the connection properties
1544   ;; {uig,gid}-{integer,string} are used.  We set them to their local
1545   ;; counterparts.
1546   (with-tramp-connection-property
1547    vec "uid-integer" (tramp-get-local-uid 'integer))
1548   (with-tramp-connection-property
1549    vec "gid-integer" (tramp-get-local-gid 'integer))
1550   (with-tramp-connection-property
1551    vec "uid-string" (tramp-get-local-uid 'string))
1552   (with-tramp-connection-property
1553    vec "gid-string" (tramp-get-local-gid 'string)))
1554
1555 (defun tramp-gvfs-send-command (vec command &rest args)
1556   "Send the COMMAND with its ARGS to connection VEC.
1557 COMMAND is usually a command from the gvfs-* utilities.
1558 `call-process' is applied, and it returns `t' if the return code is zero."
1559   (with-current-buffer (tramp-get-connection-buffer vec)
1560     (tramp-gvfs-maybe-open-connection vec)
1561     (erase-buffer)
1562     (zerop (apply 'tramp-call-process vec command nil t nil args))))
1563
1564 \f
1565 ;; D-Bus BLUEZ functions.
1566
1567 (defun tramp-bluez-list-devices ()
1568   "Return all discovered bluetooth devices as list.
1569 Every entry is a list (NAME ADDRESS).
1570
1571 If `tramp-bluez-discover-devices-timeout' is an integer, and the last
1572 discovery happened more time before indicated there, a rescan will be
1573 started, which lasts some ten seconds.  Otherwise, cached results will
1574 be used."
1575   ;; Reset the scanned devices list if time has passed.
1576   (and (integerp tramp-bluez-discover-devices-timeout)
1577        (integerp tramp-bluez-discovery)
1578        (> (tramp-time-diff (current-time) tramp-bluez-discovery)
1579           tramp-bluez-discover-devices-timeout)
1580        (setq tramp-bluez-devices nil))
1581
1582   ;; Rescan if needed.
1583   (unless tramp-bluez-devices
1584     (let ((object-path
1585            (with-tramp-dbus-call-method tramp-gvfs-dbus-event-vector t
1586              :system tramp-bluez-service "/"
1587              tramp-bluez-interface-manager "DefaultAdapter")))
1588       (setq tramp-bluez-devices nil
1589             tramp-bluez-discovery t)
1590       (with-tramp-dbus-call-method tramp-gvfs-dbus-event-vector nil
1591         :system tramp-bluez-service object-path
1592         tramp-bluez-interface-adapter "StartDiscovery")
1593       (while tramp-bluez-discovery
1594         (read-event nil nil 0.1))))
1595   (setq tramp-bluez-discovery (current-time))
1596   (tramp-message tramp-gvfs-dbus-event-vector 10 "%s" tramp-bluez-devices)
1597   tramp-bluez-devices)
1598
1599 (defun tramp-bluez-property-changed (property value)
1600   "Signal handler for the \"org.bluez.Adapter.PropertyChanged\" signal."
1601   (tramp-message tramp-gvfs-dbus-event-vector 6 "%s %s" property value)
1602   (cond
1603    ((string-equal property "Discovering")
1604     (unless (car value)
1605       ;; "Discovering" FALSE means discovery run has been completed.
1606       ;; We stop it, because we don't need another run.
1607       (setq tramp-bluez-discovery nil)
1608       (with-tramp-dbus-call-method tramp-gvfs-dbus-event-vector t
1609         :system tramp-bluez-service (dbus-event-path-name last-input-event)
1610         tramp-bluez-interface-adapter "StopDiscovery")))))
1611
1612 (when tramp-gvfs-enabled
1613   (dbus-register-signal
1614    :system nil nil tramp-bluez-interface-adapter "PropertyChanged"
1615    'tramp-bluez-property-changed))
1616
1617 (defun tramp-bluez-device-found (device args)
1618   "Signal handler for the \"org.bluez.Adapter.DeviceFound\" signal."
1619   (tramp-message tramp-gvfs-dbus-event-vector 6 "%s %s" device args)
1620   (let ((alias (car (cadr (assoc "Alias" args))))
1621         (address (car (cadr (assoc "Address" args)))))
1622     ;; Maybe we shall check the device class for being a proper
1623     ;; device, and call also SDP in order to find the obex service.
1624     (add-to-list 'tramp-bluez-devices (list alias address))))
1625
1626 (when tramp-gvfs-enabled
1627   (dbus-register-signal
1628    :system nil nil tramp-bluez-interface-adapter "DeviceFound"
1629    'tramp-bluez-device-found))
1630
1631 (defun tramp-bluez-parse-device-names (_ignore)
1632   "Return a list of (nil host) tuples allowed to access."
1633   (mapcar
1634    (lambda (x) (list nil (car x)))
1635    (tramp-bluez-list-devices)))
1636
1637 ;; Add completion function for OBEX method.
1638 (when (and tramp-gvfs-enabled
1639            (member tramp-bluez-service (dbus-list-known-names :system)))
1640   (tramp-set-completion-function
1641    "obex" '((tramp-bluez-parse-device-names ""))))
1642
1643 \f
1644 ;; D-Bus zeroconf functions.
1645
1646 (defun tramp-zeroconf-parse-workstation-device-names (_ignore)
1647   "Return a list of (user host) tuples allowed to access."
1648   (mapcar
1649    (lambda (x)
1650      (list nil (zeroconf-service-host x)))
1651    (zeroconf-list-services "_workstation._tcp")))
1652
1653 (defun tramp-zeroconf-parse-webdav-device-names (_ignore)
1654   "Return a list of (user host) tuples allowed to access."
1655   (mapcar
1656    (lambda (x)
1657      (let ((host (zeroconf-service-host x))
1658            (port (zeroconf-service-port x))
1659            (text (zeroconf-service-txt x))
1660            user)
1661        (when port
1662          (setq host (format "%s%s%d" host tramp-prefix-port-regexp port)))
1663        ;; A user is marked in a TXT field like "u=guest".
1664        (while text
1665          (when (string-match "u=\\(.+\\)$" (car text))
1666            (setq user (match-string 1 (car text))))
1667          (setq text (cdr text)))
1668        (list user host)))
1669    (zeroconf-list-services "_webdav._tcp")))
1670
1671 ;; Add completion function for SFTP, DAV and DAVS methods.
1672 (when (and tramp-gvfs-enabled
1673            (member zeroconf-service-avahi (dbus-list-known-names :system)))
1674   (zeroconf-init tramp-gvfs-zeroconf-domain)
1675   (tramp-set-completion-function
1676    "sftp" '((tramp-zeroconf-parse-workstation-device-names "")))
1677   (tramp-set-completion-function
1678    "dav" '((tramp-zeroconf-parse-webdav-device-names "")))
1679   (tramp-set-completion-function
1680    "davs" '((tramp-zeroconf-parse-webdav-device-names ""))))
1681
1682 \f
1683 ;; D-Bus SYNCE functions.
1684
1685 (defun tramp-synce-list-devices ()
1686   "Return all discovered synce devices as list.
1687 They are retrieved from the hal daemon."
1688   (let (tramp-synce-devices)
1689     (dolist (device
1690              (with-tramp-dbus-call-method tramp-gvfs-dbus-event-vector t
1691                :system tramp-hal-service tramp-hal-path-manager
1692                tramp-hal-interface-manager "GetAllDevices"))
1693       (when (with-tramp-dbus-call-method tramp-gvfs-dbus-event-vector t
1694               :system tramp-hal-service device tramp-hal-interface-device
1695               "PropertyExists" "sync.plugin")
1696         (let ((prop
1697                (with-tramp-dbus-call-method
1698                 tramp-gvfs-dbus-event-vector t
1699                 :system tramp-hal-service device tramp-hal-interface-device
1700                 "GetPropertyString" "pda.pocketpc.name")))
1701           (unless (member prop tramp-synce-devices)
1702             (push prop tramp-synce-devices)))))
1703     (tramp-message tramp-gvfs-dbus-event-vector 10 "%s" tramp-synce-devices)
1704     tramp-synce-devices))
1705
1706 (defun tramp-synce-parse-device-names (_ignore)
1707   "Return a list of (nil host) tuples allowed to access."
1708   (mapcar
1709    (lambda (x) (list nil x))
1710    (tramp-synce-list-devices)))
1711
1712 ;; Add completion function for SYNCE method.
1713 (when tramp-gvfs-enabled
1714   (tramp-set-completion-function
1715    "synce" '((tramp-synce-parse-device-names ""))))
1716
1717 (add-hook 'tramp-unload-hook
1718           (lambda ()
1719             (unload-feature 'tramp-gvfs 'force)))
1720
1721 (provide 'tramp-gvfs)
1722
1723 ;;; TODO:
1724
1725 ;; * Host name completion via smb-server or smb-network.
1726 ;; * Check how two shares of the same SMB server can be mounted in
1727 ;;   parallel.
1728 ;; * Apply SDP on bluetooth devices, in order to filter out obex
1729 ;;   capability.
1730 ;; * Implement obex for other serial communication but bluetooth.
1731
1732 ;;; tramp-gvfs.el ends here