code.delx.au - gnu-emacs/blob - lisp/progmodes/compile.el

   1 ;;; compile.el --- run compiler as inferior of Emacs, parse error messages
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4 ;;   2001, 2002, 2003, 2004, 2005  Free Software Foundation, Inc.
   5
   6 ;; Authors: Roland McGrath <roland@gnu.org>,
   7 ;;          Daniel Pfeiffer <occitan@esperanto.org>
   8 ;; Maintainer: FSF
   9 ;; Keywords: tools, processes
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package provides the compile facilities documented in the Emacs user's
  31 ;; manual.
  32
  33 ;; This mode uses some complex data-structures:
  34
  35 ;;   LOC (or location) is a list of (COLUMN LINE FILE-STRUCTURE)
  36
  37 ;; COLUMN and LINE are numbers parsed from an error message.  COLUMN and maybe
  38 ;; LINE will be nil for a message that doesn't contain them.  Then the
  39 ;; location refers to a indented beginning of line or beginning of file.
  40 ;; Once any location in some file has been jumped to, the list is extended to
  41 ;; (COLUMN LINE FILE-STRUCTURE MARKER . VISITED) for all LOCs pertaining to
  42 ;; that file.
  43 ;; MARKER initially points to LINE and COLUMN in a buffer visiting that file.
  44 ;; Being a marker it sticks to some text, when the buffer grows or shrinks
  45 ;; before that point.  VISITED is t if we have jumped there, else nil.
  46
  47 ;;   FILE-STRUCTURE is a list of
  48 ;;   ((FILENAME . DIRECTORY) FORMATS (LINE LOC ...) ...)
  49
  50 ;; FILENAME is a string parsed from an error message.  DIRECTORY is a string
  51 ;; obtained by following directory change messages.  DIRECTORY will be nil for
  52 ;; an absolute filename.  FORMATS is a list of formats to apply to FILENAME if
  53 ;; a file of that name can't be found.
  54 ;; The rest of the list is an alist of elements with LINE as key.  The keys
  55 ;; are either nil or line numbers.  If present, nil comes first, followed by
  56 ;; the numbers in decreasing order.  The LOCs for each line are again an alist
  57 ;; ordered the same way.  Note that the whole file structure is referenced in
  58 ;; every LOC.
  59
  60 ;;   MESSAGE is a list of (LOC TYPE END-LOC)
  61
  62 ;; TYPE is 0 for info or 1 for warning if the message matcher identified it as
  63 ;; such, 2 otherwise (for a real error).  END-LOC is a LOC pointing to the
  64 ;; other end, if the parsed message contained a range.  If the end of the
  65 ;; range didn't specify a COLUMN, it defaults to -1, meaning end of line.
  66 ;; These are the value of the `message' text-properties in the compilation
  67 ;; buffer.
  68
  69 ;;; Code:
  70
  71 (eval-when-compile (require 'cl))
  72
  73 (defvar font-lock-extra-managed-props)
  74 (defvar font-lock-keywords)
  75 (defvar font-lock-maximum-size)
  76 (defvar font-lock-support-mode)
  77
  78
  79 (defgroup compilation nil
  80   "Run compiler as inferior of Emacs, parse error messages."
  81   :group 'tools
  82   :group 'processes)
  83
  84
  85 ;;;###autoload
  86 (defcustom compilation-mode-hook nil
  87   "*List of hook functions run by `compilation-mode' (see `run-mode-hooks')."
  88   :type 'hook
  89   :group 'compilation)
  90
  91 ;;;###autoload
  92 (defcustom compilation-window-height nil
  93   "*Number of lines in a compilation window.  If nil, use Emacs default."
  94   :type '(choice (const :tag "Default" nil)
  95                  integer)
  96   :group 'compilation)
  97
  98 (defvar compilation-first-column 1
  99   "*This is how compilers number the first column, usually 1 or 0.")
 100
 101 (defvar compilation-parse-errors-filename-function nil
 102   "Function to call to post-process filenames while parsing error messages.
 103 It takes one arg FILENAME which is the name of a file as found
 104 in the compilation output, and should return a transformed file name.")
 105
 106 ;;;###autoload
 107 (defvar compilation-process-setup-function nil
 108   "*Function to call to customize the compilation process.
 109 This function is called immediately before the compilation process is
 110 started.  It can be used to set any variables or functions that are used
 111 while processing the output of the compilation process.  The function
 112 is called with variables `compilation-buffer' and `compilation-window'
 113 bound to the compilation buffer and window, respectively.")
 114
 115 ;;;###autoload
 116 (defvar compilation-buffer-name-function nil
 117   "Function to compute the name of a compilation buffer.
 118 The function receives one argument, the name of the major mode of the
 119 compilation buffer.  It should return a string.
 120 nil means compute the name with `(concat \"*\" (downcase major-mode) \"*\")'.")
 121
 122 ;;;###autoload
 123 (defvar compilation-finish-function nil
 124   "Function to call when a compilation process finishes.
 125 It is called with two arguments: the compilation buffer, and a string
 126 describing how the process finished.")
 127
 128 (make-obsolete-variable 'compilation-finish-function
 129   "Use `compilation-finish-functions', but it works a little differently."
 130   "22.1")
 131
 132 ;;;###autoload
 133 (defvar compilation-finish-functions nil
 134   "Functions to call when a compilation process finishes.
 135 Each function is called with two arguments: the compilation buffer,
 136 and a string describing how the process finished.")
 137
 138 (defvar compilation-in-progress nil
 139   "List of compilation processes now running.")
 140 (or (assq 'compilation-in-progress minor-mode-alist)
 141     (setq minor-mode-alist (cons '(compilation-in-progress " Compiling")
 142                                  minor-mode-alist)))
 143
 144 (defvar compilation-error "error"
 145   "Stem of message to print when no matches are found.")
 146
 147 (defvar compilation-arguments nil
 148   "Arguments that were given to `compilation-start'.")
 149
 150 (defvar compilation-num-errors-found)
 151
 152 (defconst compilation-error-regexp-alist-alist
 153   '((absoft
 154      "^\\(?:[Ee]rror on \\|[Ww]arning on\\( \\)\\)?[Ll]ine[ \t]+\\([0-9]+\\)[ \t]+\
 155 of[ \t]+\"?\\([a-zA-Z]?:?[^\":\n]+\\)\"?:" 3 2 nil (1))
 156
 157     (ada
 158      "\\(warning: .*\\)? at \\([^ \n]+\\):\\([0-9]+\\)$" 2 3 nil (1))
 159
 160     (aix
 161      " in line \\([0-9]+\\) of file \\([^ \n]+[^. \n]\\)\\.? " 2 1)
 162
 163     (ant
 164      "^[ \t]*\\[[^] \n]+\\][ \t]*\\([^: \n]+\\):\\([0-9]+\\):\\(?:\\([0-9]+\\):[0-9]+:[0-9]+:\\)?\
 165 \\( warning\\)?" 1 2 3 (4))
 166
 167     (bash
 168      "^\\([^: \n\t]+\\): line \\([0-9]+\\):" 1 2)
 169
 170     (borland
 171      "^\\(?:Error\\|Warnin\\(g\\)\\) \\(?:[FEW][0-9]+ \\)?\
 172 \\([a-zA-Z]?:?[^:( \t\n]+\\)\
 173  \\([0-9]+\\)\\(?:[) \t]\\|:[^0-9\n]\\)" 2 3 nil (1))
 174
 175     (caml
 176      "^ *File \\(\"?\\)\\([^,\" \n\t<>]+\\)\\1, lines? \\([0-9]+\\)-?\\([0-9]+\\)?\\(?:$\\|,\
 177 \\(?: characters? \\([0-9]+\\)-?\\([0-9]+\\)?:\\)?\\([ \n]Warning:\\)?\\)"
 178      2 (3 . 4) (5 . 6) (7))
 179
 180     (comma
 181      "^\"\\([^,\" \n\t]+\\)\", line \\([0-9]+\\)\
 182 \\(?:[(. pos]+\\([0-9]+\\))?\\)?[:.,; (-]\\( warning:\\|[-0-9 ]*(W)\\)?" 1 2 3 (4))
 183
 184     (edg-1
 185      "^\\([^ \n]+\\)(\\([0-9]+\\)): \\(?:error\\|warnin\\(g\\)\\|remar\\(k\\)\\)"
 186      1 2 nil (3 . 4))
 187     (edg-2
 188      "at line \\([0-9]+\\) of \"\\([^ \n]+\\)\"$"
 189      2 1 nil 0)
 190
 191     (epc
 192      "^Error [0-9]+ at (\\([0-9]+\\):\\([^)\n]+\\))" 2 1)
 193
 194     (ftnchek
 195      "\\(^Warning .*\\)? line[ \n]\\([0-9]+\\)[ \n]\\(?:col \\([0-9]+\\)[ \n]\\)?file \\([^ :;\n]+\\)"
 196      4 2 3 (1))
 197
 198     (iar
 199      "^\"\\(.*\\)\",\\([0-9]+\\)\\s-+\\(?:Error\\|Warnin\\(g\\)\\)\\[[0-9]+\\]:"
 200      1 2 nil (3))
 201
 202     (ibm
 203      "^\\([^( \n\t]+\\)(\\([0-9]+\\):\\([0-9]+\\)) :\
 204  \\(?:warnin\\(g\\)\\|informationa\\(l\\)\\)?" 1 2 3 (4 . 5))
 205
 206     ;; fixme: should be `mips'
 207     (irix
 208      "^[-[:alnum:]_/ ]+: \\(?:\\(?:[sS]evere\\|[eE]rror\\|[wW]arnin\\(g\\)\\|[iI]nf\\(o\\)\\)[0-9 ]*: \\)?\
 209 \\([^,\" \n\t]+\\)\\(?:, line\\|:\\) \\([0-9]+\\):" 3 4 nil (1 . 2))
 210
 211     (java
 212      "^\\(?:[ \t]+at \\|==[0-9]+== +\\(?:at\\|b\\(y\\)\\)\\).+(\\([^()\n]+\\):\\([0-9]+\\))$" 2 3 nil (1))
 213
 214     (jikes-file
 215      "^\\(?:Found\\|Issued\\) .* compiling \"\\(.+\\)\":$" 1 nil nil 0)
 216     (jikes-line
 217      "^ *\\([0-9]+\\)\\.[ \t]+.*\n +\\(<-*>\n\\*\\*\\* \\(?:Error\\|Warnin\\(g\\)\\)\\)"
 218      nil 1 nil 2 0
 219      (2 (compilation-face '(3))))
 220
 221     (gcc-include
 222      "^\\(?:In file included\\|                \\) from \
 223 \\(.+\\):\\([0-9]+\\)\\(?:\\(:\\)\\|\\(,\\)\\)?" 1 2 nil (3 . 4))
 224
 225     (gnu
 226      "^\\(?:[[:alpha:]][-[:alnum:].]+: ?\\)?\
 227 \\([/.]*[a-zA-Z]:?[^ \t\n:]*\\|{standard input}\\): ?\
 228 \\([0-9]+\\)\\([.:]?\\)\\([0-9]+\\)?\
 229 \\(?:-\\(?:\\([0-9]+\\)\\3\\)?\\.?\\([0-9]+\\)?\\)?:\
 230 \\(?: *\\(\\(?:Future\\|Runtime\\)?[Ww]arning\\|W:\\)\\|\
 231  *\\([Ii]nfo\\(?:\\>\\|rmationa?l?\\)\\|I:\\)\\)?"
 232      1 (2 . 5) (4 . 6) (7 . 8))
 233
 234     (lcc
 235      "^\\(?:E\\|\\(W\\)\\), \\([^(\n]+\\)(\\([0-9]+\\),[ \t]*\\([0-9]+\\)"
 236      2 3 4 (1))
 237
 238     (makepp
 239      "^makepp: \\(?:\\(?:warning\\(:\\).*?\\|\\(Scanning\\|[LR]e?l?oading makefile\\) \\|.*?\\)\
 240 `\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)['(]\\)"
 241      4 5 nil (1 . 2) 3
 242      ("`\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)['(]" nil nil
 243       (2 compilation-info-face)
 244       (3 compilation-line-face nil t)
 245       (1 (compilation-error-properties 2 3 nil nil nil 0 nil)
 246          append)))
 247
 248     ;; Should be lint-1, lint-2 (SysV lint)
 249     (mips-1
 250      " (\\([0-9]+\\)) in \\([^ \n]+\\)" 2 1)
 251     (mips-2
 252      " in \\([^()\n ]+\\)(\\([0-9]+\\))$" 1 2)
 253
 254     (msft
 255      "^\\([0-9]+>\\)?\\(\\(?:[a-zA-Z]:\\)?[^:(\t\n]+\\)(\\([0-9]+\\)) \
 256 : \\(?:error\\|warnin\\(g\\)\\) C[0-9]+:" 2 3 nil (4))
 257
 258     (oracle
 259      "^\\(?:Semantic error\\|Error\\|PCC-[0-9]+:\\).* line \\([0-9]+\\)\
 260 \\(?:\\(?:,\\| at\\)? column \\([0-9]+\\)\\)?\
 261 \\(?:,\\| in\\| of\\)? file \\(.*?\\):?$"
 262      3 1 2)
 263
 264     (perl
 265      " at \\([^ \n]+\\) line \\([0-9]+\\)\\(?:[,.]\\|$\\)" 1 2)
 266
 267     (rxp
 268      "^\\(?:Error\\|Warnin\\(g\\)\\):.*\n.* line \\([0-9]+\\) char\
 269  \\([0-9]+\\) of file://\\(.+\\)"
 270      4 2 3 (1))
 271
 272     (sparc-pascal-file
 273      "^\\w\\w\\w \\w\\w\\w +[0-3]?[0-9] +[0-2][0-9]:[0-5][0-9]:[0-5][0-9]\
 274  [12][09][0-9][0-9] +\\(.*\\):$"
 275      1 nil nil 0)
 276     (sparc-pascal-line
 277      "^\\(\\(?:E\\|\\(w\\)\\) +[0-9]+\\) line \\([0-9]+\\) -  "
 278      nil 3 nil (2) nil (1 (compilation-face '(2))))
 279     (sparc-pascal-example
 280      "^ +\\([0-9]+\\) +.*\n\\(\\(?:e\\|\\(w\\)\\) [0-9]+\\)-+"
 281      nil 1 nil (3) nil (2 (compilation-face '(3))))
 282
 283     (sun
 284      ": \\(?:ERROR\\|WARNIN\\(G\\)\\|REMAR\\(K\\)\\) \\(?:[[:alnum:] ]+, \\)?\
 285 File = \\(.+\\), Line = \\([0-9]+\\)\\(?:, Column = \\([0-9]+\\)\\)?"
 286      3 4 5 (1 . 2))
 287
 288     (sun-ada
 289      "^\\([^, \n\t]+\\), line \\([0-9]+\\), char \\([0-9]+\\)[:., \(-]" 1 2 3)
 290
 291     (4bsd
 292      "\\(?:^\\|::  \\|\\S ( \\)\\(/[^ \n\t()]+\\)(\\([0-9]+\\))\
 293 \\(?:: \\(warning:\\)?\\|$\\| ),\\)" 1 2 nil (3))
 294
 295     (gcov-file
 296      "^ +-:    \\(0\\):Source:\\(.+\\)$" 2 1 nil 0)
 297     (gcov-bb-file
 298      "^ +-:    \\(0\\):Object:\\(?:.+\\)$" nil 1 nil 0)
 299     (gcov-never-called-line
 300      "^ +\\(#####\\): +\\([0-9]+\\):.+$" nil 2 nil 2 nil
 301      (1 compilation-error-face))
 302     (gcov-called-line
 303      "^ +[-0-9]+: +\\([1-9]\\|[0-9]\\{2,\\}\\):.*$" nil 1 nil 0)
 304 )
 305   "Alist of values for `compilation-error-regexp-alist'.")
 306
 307 (defcustom compilation-error-regexp-alist
 308   (mapcar 'car compilation-error-regexp-alist-alist)
 309   "Alist that specifies how to match errors in compiler output.
 310 On GNU and Unix, any string is a valid filename, so these
 311 matchers must make some common sense assumptions, which catch
 312 normal cases.  A shorter list will be lighter on resource usage.
 313
 314 Instead of an alist element, you can use a symbol, which is
 315 looked up in `compilation-error-regexp-alist-alist'.  You can see
 316 the predefined symbols and their effects in the file
 317 `etc/compilation.txt' (linked below if you are customizing this).
 318
 319 Each elt has the form (REGEXP FILE [LINE COLUMN TYPE HYPERLINK
 320 HIGHLIGHT...]).  If REGEXP matches, the FILE'th subexpression
 321 gives the file name, and the LINE'th subexpression gives the line
 322 number.  The COLUMN'th subexpression gives the column number on
 323 that line.
 324
 325 If FILE, LINE or COLUMN are nil or that index didn't match, that
 326 information is not present on the matched line.  In that case the
 327 file name is assumed to be the same as the previous one in the
 328 buffer, line number defaults to 1 and column defaults to
 329 beginning of line's indentation.
 330
 331 FILE can also have the form (FILE FORMAT...), where the FORMATs
 332 \(e.g. \"%s.c\") will be applied in turn to the recognized file
 333 name, until a file of that name is found.  Or FILE can also be a
 334 function to return the filename.
 335
 336 LINE can also be of the form (LINE . END-LINE) meaning a range
 337 of lines.  COLUMN can also be of the form (COLUMN . END-COLUMN)
 338 meaning a range of columns starting on LINE and ending on
 339 END-LINE, if that matched.
 340
 341 TYPE is 2 or nil for a real error or 1 for warning or 0 for info.
 342 TYPE can also be of the form (WARNING . INFO).  In that case this
 343 will be equivalent to 1 if the WARNING'th subexpression matched
 344 or else equivalent to 0 if the INFO'th subexpression matched.
 345 See `compilation-error-face', `compilation-warning-face',
 346 `compilation-info-face' and `compilation-skip-threshold'.
 347
 348 What matched the HYPERLINK'th subexpression has `mouse-face' and
 349 `compilation-message-face' applied.  If this is nil, the text
 350 matched by the whole REGEXP becomes the hyperlink.
 351
 352 Additional HIGHLIGHTs as described under `font-lock-keywords' can
 353 be added."
 354   :type `(set :menu-tag "Pick"
 355               ,@(mapcar (lambda (elt)
 356                           (list 'const (car elt)))
 357                         compilation-error-regexp-alist-alist))
 358   :link `(file-link :tag "example file"
 359                     ,(expand-file-name "compilation.txt" data-directory))
 360   :group 'compilation)
 361
 362 (defvar compilation-directory nil
 363   "Directory to restore to when doing `recompile'.")
 364
 365 (defvar compilation-directory-matcher
 366   '("\\(?:Entering\\|Leavin\\(g\\)\\) directory `\\(.+\\)'$" (2 . 1))
 367   "A list for tracking when directories are entered or left.
 368 Nil means not to track directories, e.g. if all file names are absolute.  The
 369 first element is the REGEXP matching these messages.  It can match any number
 370 of variants, e.g. different languages.  The remaining elements are all of the
 371 form (DIR .  LEAVE).  If for any one of these the DIR'th subexpression
 372 matches, that is a directory name.  If LEAVE is nil or the corresponding
 373 LEAVE'th subexpression doesn't match, this message is about going into another
 374 directory.  If it does match anything, this message is about going back to the
 375 directory we were in before the last entering message.  If you change this,
 376 you may also want to change `compilation-page-delimiter'.")
 377
 378 (defvar compilation-page-delimiter
 379   "^\\(?:\f\\|.*\\(?:Entering\\|Leaving\\) directory `.+'\n\\)+"
 380   "Value of `page-delimiter' in Compilation mode.")
 381
 382 (defvar compilation-mode-font-lock-keywords
 383    '(;; configure output lines.
 384      ("^[Cc]hecking \\(?:[Ff]or \\|[Ii]f \\|[Ww]hether \\(?:to \\)?\\)?\\(.+\\)\\.\\.\\. *\\(?:(cached) *\\)?\\(\\(yes\\(?: .+\\)?\\)\\|no\\|\\(.*\\)\\)$"
 385       (1 font-lock-variable-name-face)
 386       (2 (compilation-face '(4 . 3))))
 387      ;; Command output lines.  Recognize `make[n]:' lines too.
 388      ("^\\([[:alnum:]_/.+-]+\\)\\(\\[\\([0-9]+\\)\\]\\)?[ \t]*:"
 389       (1 font-lock-function-name-face) (3 compilation-line-face nil t))
 390      (" --?o\\(?:utfile\\|utput\\)?[= ]?\\(\\S +\\)" . 1)
 391      ("^Compilation \\(finished\\)"
 392       (1 compilation-info-face))
 393      ("^Compilation \\(exited abnormally\\|interrupt\\|killed\\|terminated\\)\\(?:.*with code \\([0-9]+\\)\\)?"
 394       (1 compilation-error-face)
 395       (2 compilation-error-face nil t)))
 396    "Additional things to highlight in Compilation mode.
 397 This gets tacked on the end of the generated expressions.")
 398
 399 (defvar compilation-highlight-regexp t
 400   "Regexp matching part of visited source lines to highlight temporarily.
 401 Highlight entire line if t; don't highlight source lines if nil.")
 402
 403 (defvar compilation-highlight-overlay nil
 404   "Overlay used to temporarily highlight compilation matches.")
 405
 406 (defcustom compilation-error-screen-columns t
 407   "*If non-nil, column numbers in error messages are screen columns.
 408 Otherwise they are interpreted as character positions, with
 409 each character occupying one column.
 410 The default is to use screen columns, which requires that the compilation
 411 program and Emacs agree about the display width of the characters,
 412 especially the TAB character."
 413   :type 'boolean
 414   :group 'compilation
 415   :version "20.4")
 416
 417 (defcustom compilation-read-command t
 418   "*Non-nil means \\[compile] reads the compilation command to use.
 419 Otherwise, \\[compile] just uses the value of `compile-command'."
 420   :type 'boolean
 421   :group 'compilation)
 422
 423 ;;;###autoload
 424 (defcustom compilation-ask-about-save t
 425   "*Non-nil means \\[compile] asks which buffers to save before compiling.
 426 Otherwise, it saves all modified buffers without asking."
 427   :type 'boolean
 428   :group 'compilation)
 429
 430 ;;;###autoload
 431 (defcustom compilation-search-path '(nil)
 432   "*List of directories to search for source files named in error messages.
 433 Elements should be directory names, not file names of directories.
 434 nil as an element means to try the default directory."
 435   :type '(repeat (choice (const :tag "Default" nil)
 436                          (string :tag "Directory")))
 437   :group 'compilation)
 438
 439 ;;;###autoload
 440 (defcustom compile-command "make -k "
 441   "*Last shell command used to do a compilation; default for next compilation.
 442
 443 Sometimes it is useful for files to supply local values for this variable.
 444 You might also use mode hooks to specify it in certain modes, like this:
 445
 446     (add-hook 'c-mode-hook
 447        (lambda ()
 448          (unless (or (file-exists-p \"makefile\")
 449                      (file-exists-p \"Makefile\"))
 450            (set (make-local-variable 'compile-command)
 451                 (concat \"make -k \"
 452                         (file-name-sans-extension buffer-file-name))))))"
 453   :type 'string
 454   :group 'compilation)
 455
 456 ;;;###autoload
 457 (defcustom compilation-disable-input nil
 458   "*If non-nil, send end-of-file as compilation process input.
 459 This only affects platforms that support asynchronous processes (see
 460 `start-process'); synchronous compilation processes never accept input."
 461   :type 'boolean
 462   :group 'compilation
 463   :version "22.1")
 464
 465 ;; A weak per-compilation-buffer hash indexed by (FILENAME . DIRECTORY).  Each
 466 ;; value is a FILE-STRUCTURE as described above, with the car eq to the hash
 467 ;; key.  This holds the tree seen from root, for storing new nodes.
 468 (defvar compilation-locs ())
 469
 470 (defvar compilation-debug nil
 471   "*Set this to t before creating a *compilation* buffer.
 472 Then every error line will have a debug text property with the matcher that
 473 fit this line and the match data.  Use `describe-text-properties'.")
 474
 475 (defvar compilation-exit-message-function nil "\
 476 If non-nil, called when a compilation process dies to return a status message.
 477 This should be a function of three arguments: process status, exit status,
 478 and exit message; it returns a cons (MESSAGE . MODELINE) of the strings to
 479 write into the compilation buffer, and to put in its mode line.")
 480
 481 (defvar compilation-environment nil
 482   "*List of environment variables for compilation to inherit.
 483 Each element should be a string of the form ENVVARNAME=VALUE.
 484 This list is temporarily prepended to `process-environment' prior to
 485 starting the compilation process.")
 486
 487 ;; History of compile commands.
 488 (defvar compile-history nil)
 489
 490 (defface compilation-error
 491   '((t :inherit font-lock-warning-face))
 492   "Face used to highlight compiler errors."
 493   :group 'compilation
 494   :version "22.1")
 495
 496 (defface compilation-warning
 497   '((((class color) (min-colors 16)) (:foreground "Orange" :weight bold))
 498     (((class color)) (:foreground "cyan" :weight bold))
 499     (t (:weight bold)))
 500   "Face used to highlight compiler warnings."
 501   :group 'compilation
 502   :version "22.1")
 503
 504 (defface compilation-info
 505   '((((class color) (min-colors 16) (background light))
 506      (:foreground "Green3" :weight bold))
 507     (((class color) (min-colors 88) (background dark))
 508      (:foreground "Green1" :weight bold))
 509     (((class color) (min-colors 16) (background dark))
 510      (:foreground "Green" :weight bold))
 511     (((class color)) (:foreground "green" :weight bold))
 512     (t (:weight bold)))
 513   "Face used to highlight compiler information."
 514   :group 'compilation
 515   :version "22.1")
 516
 517 (defface compilation-line-number
 518   '((t :inherit font-lock-variable-name-face))
 519   "Face for displaying line numbers in compiler messages."
 520   :group 'compilation
 521   :version "22.1")
 522
 523 (defface compilation-column-number
 524   '((t :inherit font-lock-type-face))
 525   "Face for displaying column numbers in compiler messages."
 526   :group 'compilation
 527   :version "22.1")
 528
 529 (defvar compilation-message-face 'underline
 530   "Face name to use for whole messages.
 531 Faces `compilation-error-face', `compilation-warning-face',
 532 `compilation-info-face', `compilation-line-face' and
 533 `compilation-column-face' get prepended to this, when applicable.")
 534
 535 (defvar compilation-error-face 'compilation-error
 536   "Face name to use for file name in error messages.")
 537
 538 (defvar compilation-warning-face 'compilation-warning
 539   "Face name to use for file name in warning messages.")
 540
 541 (defvar compilation-info-face 'compilation-info
 542   "Face name to use for file name in informational messages.")
 543
 544 (defvar compilation-line-face 'compilation-line-number
 545   "Face name to use for line numbers in compiler messages.")
 546
 547 (defvar compilation-column-face 'compilation-column-number
 548   "Face name to use for column numbers in compiler messages.")
 549
 550 ;; same faces as dired uses
 551 (defvar compilation-enter-directory-face 'font-lock-function-name-face
 552   "Face name to use for entering directory messages.")
 553
 554 (defvar compilation-leave-directory-face 'font-lock-type-face
 555   "Face name to use for leaving directory messages.")
 556
 557
 558
 559 ;; Used for compatibility with the old compile.el.
 560 (defvaralias 'compilation-last-buffer 'next-error-last-buffer)
 561 (defvar compilation-parsing-end (make-marker))
 562 (defvar compilation-parse-errors-function nil)
 563 (defvar compilation-error-list nil)
 564 (defvar compilation-old-error-list nil)
 565
 566 (defun compilation-face (type)
 567   (or (and (car type) (match-end (car type)) compilation-warning-face)
 568       (and (cdr type) (match-end (cdr type)) compilation-info-face)
 569       compilation-error-face))
 570
 571 ;; Internal function for calculating the text properties of a directory
 572 ;; change message.  The directory property is important, because it is
 573 ;; the stack of nested enter-messages.  Relative filenames on the following
 574 ;; lines are relative to the top of the stack.
 575 (defun compilation-directory-properties (idx leave)
 576   (if leave (setq leave (match-end leave)))
 577   ;; find previous stack, and push onto it, or if `leave' pop it
 578   (let ((dir (previous-single-property-change (point) 'directory)))
 579     (setq dir (if dir (or (get-text-property (1- dir) 'directory)
 580                           (get-text-property dir 'directory))))
 581     `(face ,(if leave
 582                 compilation-leave-directory-face
 583               compilation-enter-directory-face)
 584       directory ,(if leave
 585                      (or (cdr dir)
 586                          '(nil))        ; nil only isn't a property-change
 587                    (cons (match-string-no-properties idx) dir))
 588       mouse-face highlight
 589       keymap compilation-button-map
 590       help-echo "mouse-2: visit current directory")))
 591
 592 ;; Data type `reverse-ordered-alist' retriever.  This function retrieves the
 593 ;; KEY element from the ALIST, creating it in the right position if not already
 594 ;; present. ALIST structure is
 595 ;; '(ANCHOR (KEY1 ...) (KEY2 ...)... (KEYn ALIST ...))
 596 ;; ANCHOR is ignored, but necessary so that elements can be inserted.  KEY1
 597 ;; may be nil.  The other KEYs are ordered backwards so that growing line
 598 ;; numbers can be inserted in front and searching can abort after half the
 599 ;; list on average.
 600 (eval-when-compile                  ;Don't keep it at runtime if not needed.
 601 (defmacro compilation-assq (key alist)
 602   `(let* ((l1 ,alist)
 603           (l2 (cdr l1)))
 604      (car (if (if (null ,key)
 605                   (if l2 (null (caar l2)))
 606                 (while (if l2 (if (caar l2) (< ,key (caar l2)) t))
 607                   (setq l1 l2
 608                         l2 (cdr l1)))
 609                 (if l2 (eq ,key (caar l2))))
 610               l2
 611             (setcdr l1 (cons (list ,key) l2)))))))
 612
 613
 614 ;; This function is the central driver, called when font-locking to gather
 615 ;; all information needed to later jump to corresponding source code.
 616 ;; Return a property list with all meta information on this error location.
 617
 618 (defun compilation-error-properties (file line end-line col end-col type fmt)
 619   (unless (< (next-single-property-change (match-beginning 0) 'directory nil (point))
 620              (point))
 621     (if file
 622         (if (functionp file)
 623             (setq file (funcall file))
 624           (let (dir)
 625             (setq file (match-string-no-properties file))
 626             (unless (file-name-absolute-p file)
 627               (setq dir (previous-single-property-change (point) 'directory)
 628                     dir (if dir (or (get-text-property (1- dir) 'directory)
 629                                     (get-text-property dir 'directory)))))
 630             (setq file (cons file (car dir)))))
 631       ;; This message didn't mention one, get it from previous
 632       (let ((prev-pos
 633              ;; Find the previous message.
 634              (previous-single-property-change (point) 'message)))
 635         (if prev-pos
 636             ;; Get the file structure that belongs to it.
 637             (let* ((prev
 638                     (or (get-text-property (1- prev-pos) 'message)
 639                         (get-text-property prev-pos 'message)))
 640                    (prev-struct
 641                     (car (nth 2 (car prev)))))
 642               ;; Construct FILE . DIR from that.
 643               (if prev-struct
 644                   (setq file (cons (car prev-struct)
 645                                    (cadr prev-struct))))))
 646         (unless file
 647           (setq file '("*unknown*")))))
 648     ;; All of these fields are optional, get them only if we have an index, and
 649     ;; it matched some part of the message.
 650     (and line
 651          (setq line (match-string-no-properties line))
 652          (setq line (string-to-number line)))
 653     (and end-line
 654          (setq end-line (match-string-no-properties end-line))
 655          (setq end-line (string-to-number end-line)))
 656     (if col
 657         (if (functionp col)
 658             (setq col (funcall col))
 659           (and
 660            (setq col (match-string-no-properties col))
 661            (setq col (- (string-to-number col) compilation-first-column)))))
 662     (if (and end-col (functionp end-col))
 663         (setq end-col (funcall end-col))
 664       (if (and end-col (setq end-col (match-string-no-properties end-col)))
 665           (setq end-col (- (string-to-number end-col) compilation-first-column -1))
 666         (if end-line (setq end-col -1))))
 667     (if (consp type)                    ; not a static type, check what it is.
 668         (setq type (or (and (car type) (match-end (car type)) 1)
 669                        (and (cdr type) (match-end (cdr type)) 0)
 670                        2)))
 671     (compilation-internal-error-properties file line end-line col end-col type fmt)))
 672
 673 (defun compilation-move-to-column (col screen)
 674   "Go to column COL on the current line.
 675 If SCREEN is non-nil, columns are screen columns, otherwise, they are
 676 just char-counts."
 677   (if screen
 678       (move-to-column col)
 679     (goto-char (min (+ (line-beginning-position) col) (line-end-position)))))
 680
 681 (defun compilation-internal-error-properties (file line end-line col end-col type fmts)
 682   "Get the meta-info that will be added as text-properties.
 683 LINE, END-LINE, COL, END-COL are integers or nil.
 684 TYPE can be 0, 1, or 2, meaning error, warning, or just info.
 685 FILE should be (FILENAME) or (RELATIVE-FILENAME . DIRNAME) or nil.
 686 FMTS is a list of format specs for transforming the file name.
 687  (See `compilation-error-regexp-alist'.)"
 688   (unless file (setq file '("*unknown*")))
 689   (let* ((file-struct (compilation-get-file-structure file fmts))
 690          ;; Get first already existing marker (if any has one, all have one).
 691          ;; Do this first, as the compilation-assq`s may create new nodes.
 692          (marker-line (car (cddr file-struct))) ; a line structure
 693          (marker (nth 3 (cadr marker-line)))    ; its marker
 694          (compilation-error-screen-columns compilation-error-screen-columns)
 695          end-marker loc end-loc)
 696     (if (not (and marker (marker-buffer marker)))
 697         (setq marker nil)               ; no valid marker for this file
 698       (setq loc (or line 1))            ; normalize no linenumber to line 1
 699       (catch 'marker                    ; find nearest loc, at least one exists
 700         (dolist (x (nthcdr 3 file-struct))      ; loop over remaining lines
 701           (if (> (car x) loc)           ; still bigger
 702               (setq marker-line x)
 703             (if (> (- (or (car marker-line) 1) loc)
 704                    (- loc (car x)))     ; current line is nearer
 705                 (setq marker-line x))
 706             (throw 'marker t))))
 707       (setq marker (nth 3 (cadr marker-line))
 708             marker-line (or (car marker-line) 1))
 709       (with-current-buffer (marker-buffer marker)
 710         (save-restriction
 711           (widen)
 712           (goto-char (marker-position marker))
 713           (when (or end-col end-line)
 714             (beginning-of-line (- (or end-line line) marker-line -1))
 715             (if (or (null end-col) (< end-col 0))
 716                 (end-of-line)
 717               (compilation-move-to-column
 718                end-col compilation-error-screen-columns))
 719             (setq end-marker (list (point-marker))))
 720           (beginning-of-line (if end-line
 721                                  (- line end-line -1)
 722                                (- loc marker-line -1)))
 723           (if col
 724               (compilation-move-to-column
 725                col compilation-error-screen-columns)
 726             (forward-to-indentation 0))
 727           (setq marker (list (point-marker))))))
 728
 729     (setq loc (compilation-assq line (cdr file-struct)))
 730     (if end-line
 731         (setq end-loc (compilation-assq end-line (cdr file-struct))
 732               end-loc (compilation-assq end-col end-loc))
 733       (if end-col                       ; use same line element
 734           (setq end-loc (compilation-assq end-col loc))))
 735     (setq loc (compilation-assq col loc))
 736     ;; If they are new, make the loc(s) reference the file they point to.
 737     (or (cdr loc) (setcdr loc `(,line ,file-struct ,@marker)))
 738     (if end-loc
 739         (or (cdr end-loc)
 740             (setcdr end-loc `(,(or end-line line) ,file-struct ,@end-marker))))
 741
 742     ;; Must start with face
 743     `(face ,compilation-message-face
 744            message (,loc ,type ,end-loc)
 745            ,@(if compilation-debug
 746                  `(debug (,(assoc (with-no-warnings matcher) font-lock-keywords)
 747                           ,@(match-data))))
 748            help-echo ,(if col
 749                           "mouse-2: visit this file, line and column"
 750                         (if line
 751                             "mouse-2: visit this file and line"
 752                           "mouse-2: visit this file"))
 753            keymap compilation-button-map
 754            mouse-face highlight)))
 755
 756 (defun compilation-mode-font-lock-keywords ()
 757   "Return expressions to highlight in Compilation mode."
 758   (if compilation-parse-errors-function
 759       ;; An old package!  Try the compatibility code.
 760       '((compilation-compat-parse-errors))
 761     (append
 762      ;; make directory tracking
 763      (if compilation-directory-matcher
 764          `((,(car compilation-directory-matcher)
 765             ,@(mapcar (lambda (elt)
 766                         `(,(car elt)
 767                           (compilation-directory-properties
 768                            ,(car elt) ,(cdr elt))
 769                           t t))
 770                       (cdr compilation-directory-matcher)))))
 771
 772      ;; Compiler warning/error lines.
 773      (mapcar
 774       (lambda (item)
 775         (if (symbolp item)
 776             (setq item (cdr (assq item
 777                                   compilation-error-regexp-alist-alist))))
 778         (let ((file (nth 1 item))
 779               (line (nth 2 item))
 780               (col (nth 3 item))
 781               (type (nth 4 item))
 782               end-line end-col fmt)
 783           (if (consp file)      (setq fmt (cdr file)      file (car file)))
 784           (if (consp line)      (setq end-line (cdr line) line (car line)))
 785           (if (consp col)       (setq end-col (cdr col)   col (car col)))
 786
 787           (if (functionp line)
 788               ;; The old compile.el had here an undocumented hook that
 789               ;; allowed `line' to be a function that computed the actual
 790               ;; error location.  Let's do our best.
 791               `(,(car item)
 792                 (0 (save-match-data
 793                      (compilation-compat-error-properties
 794                       (funcall ',line (cons (match-string ,file)
 795                                             (cons default-directory
 796                                                   ',(nthcdr 4 item)))
 797                                ,(if col `(match-string ,col))))))
 798                 (,file compilation-error-face t))
 799
 800             (unless (or (null (nth 5 item)) (integerp (nth 5 item)))
 801               (error "HYPERLINK should be an integer: %s" (nth 5 item)))
 802
 803             `(,(nth 0 item)
 804
 805               ,@(when (integerp file)
 806                   `((,file ,(if (consp type)
 807                                 `(compilation-face ',type)
 808                               (aref [compilation-info-face
 809                                      compilation-warning-face
 810                                      compilation-error-face]
 811                                     (or type 2))))))
 812
 813               ,@(when line
 814                   `((,line compilation-line-face nil t)))
 815               ,@(when end-line
 816                   `((,end-line compilation-line-face nil t)))
 817
 818               ,@(when (integerp col)
 819                   `((,col compilation-column-face nil t)))
 820               ,@(when (integerp end-col)
 821                   `((,end-col compilation-column-face nil t)))
 822
 823               ,@(nthcdr 6 item)
 824               (,(or (nth 5 item) 0)
 825                (compilation-error-properties ',file ,line ,end-line
 826                                              ,col ,end-col ',(or type 2)
 827                                              ',fmt)
 828                append)))))              ; for compilation-message-face
 829       compilation-error-regexp-alist)
 830
 831      compilation-mode-font-lock-keywords)))
 832
 833 \f
 834 ;;;###autoload
 835 (defun compile (command &optional comint)
 836   "Compile the program including the current buffer.  Default: run `make'.
 837 Runs COMMAND, a shell command, in a separate process asynchronously
 838 with output going to the buffer `*compilation*'.
 839
 840 If optional second arg COMINT is t the buffer will be in Comint mode with
 841 `compilation-shell-minor-mode'.
 842
 843 You can then use the command \\[next-error] to find the next error message
 844 and move to the source code that caused it.
 845
 846 Interactively, prompts for the command if `compilation-read-command' is
 847 non-nil; otherwise uses `compile-command'.  With prefix arg, always prompts.
 848 Additionally, with universal prefix arg, compilation buffer will be in
 849 comint mode, i.e. interactive.
 850
 851 To run more than one compilation at once, start one and rename
 852 the \`*compilation*' buffer to some other name with
 853 \\[rename-buffer].  Then start the next one.  On most systems,
 854 termination of the main compilation process kills its
 855 subprocesses.
 856
 857 The name used for the buffer is actually whatever is returned by
 858 the function in `compilation-buffer-name-function', so you can set that
 859 to a function that generates a unique name."
 860   (interactive
 861    (list
 862     (let ((command (eval compile-command)))
 863       (if (or compilation-read-command current-prefix-arg)
 864           (read-from-minibuffer "Compile command: "
 865                                 command nil nil
 866                                 (if (equal (car compile-history) command)
 867                                     '(compile-history . 1)
 868                                   'compile-history))
 869         command))
 870     (consp current-prefix-arg)))
 871   (unless (equal command (eval compile-command))
 872     (setq compile-command command))
 873   (save-some-buffers (not compilation-ask-about-save) nil)
 874   (setq compilation-directory default-directory)
 875   (compilation-start command comint))
 876
 877 ;; run compile with the default command line
 878 (defun recompile ()
 879   "Re-compile the program including the current buffer.
 880 If this is run in a Compilation mode buffer, re-use the arguments from the
 881 original use.  Otherwise, recompile using `compile-command'."
 882   (interactive)
 883   (save-some-buffers (not compilation-ask-about-save) nil)
 884   (let ((default-directory
 885           (or (and (not (eq major-mode (nth 1 compilation-arguments)))
 886                    compilation-directory)
 887               default-directory)))
 888     (apply 'compilation-start (or compilation-arguments
 889                                   `(,(eval compile-command))))))
 890
 891 (defcustom compilation-scroll-output nil
 892   "*Non-nil to scroll the *compilation* buffer window as output appears.
 893
 894 Setting it causes the Compilation mode commands to put point at the
 895 end of their output window so that the end of the output is always
 896 visible rather than the beginning."
 897   :type 'boolean
 898   :version "20.3"
 899   :group 'compilation)
 900
 901
 902 (defun compilation-buffer-name (mode-name name-function)
 903   "Return the name of a compilation buffer to use.
 904 If NAME-FUNCTION is non-nil, call it with one argument MODE-NAME
 905 to determine the buffer name.
 906 Likewise if `compilation-buffer-name-function' is non-nil.
 907 If current buffer is in Compilation mode for the same mode name
 908 return the name of the current buffer, so that it gets reused.
 909 Otherwise, construct a buffer name from MODE-NAME."
 910   (cond (name-function
 911          (funcall name-function mode-name))
 912         (compilation-buffer-name-function
 913          (funcall compilation-buffer-name-function mode-name))
 914         ((eq major-mode (nth 1 compilation-arguments))
 915          (buffer-name))
 916         (t
 917          (concat "*" (downcase mode-name) "*"))))
 918
 919 ;; This is a rough emulation of the old hack, until the transition to new
 920 ;; compile is complete.
 921 (defun compile-internal (command error-message
 922                                  &optional name-of-mode parser
 923                                  error-regexp-alist name-function
 924                                  enter-regexp-alist leave-regexp-alist
 925                                  file-regexp-alist nomessage-regexp-alist
 926                                  no-async highlight-regexp local-map)
 927   (if parser
 928       (error "Compile now works very differently, see `compilation-error-regexp-alist'"))
 929   (let ((compilation-error-regexp-alist
 930          (append file-regexp-alist (or error-regexp-alist
 931                                        compilation-error-regexp-alist)))
 932         (compilation-error (replace-regexp-in-string "^No more \\(.+\\)s\\.?"
 933                                                      "\\1" error-message)))
 934     (compilation-start command nil name-function highlight-regexp)))
 935 (make-obsolete 'compile-internal 'compilation-start)
 936
 937 ;;;###autoload
 938 (defun compilation-start (command &optional mode name-function highlight-regexp)
 939   "Run compilation command COMMAND (low level interface).
 940 If COMMAND starts with a cd command, that becomes the `default-directory'.
 941 The rest of the arguments are optional; for them, nil means use the default.
 942
 943 MODE is the major mode to set in the compilation buffer.  Mode
 944 may also be t meaning use `compilation-shell-minor-mode' under `comint-mode'.
 945 If NAME-FUNCTION is non-nil, call it with one argument (the mode name)
 946 to determine the buffer name.
 947
 948 If HIGHLIGHT-REGEXP is non-nil, `next-error' will temporarily highlight
 949 the matching section of the visited source line; the default is to use the
 950 global value of `compilation-highlight-regexp'.
 951
 952 Returns the compilation buffer created."
 953   (or mode (setq mode 'compilation-mode))
 954   (let* ((name-of-mode
 955           (if (eq mode t)
 956               (prog1 "compilation" (require 'comint))
 957             (replace-regexp-in-string "-mode$" "" (symbol-name mode))))
 958          (thisdir default-directory)
 959          outwin outbuf)
 960     (with-current-buffer
 961         (setq outbuf
 962               (get-buffer-create
 963                (compilation-buffer-name name-of-mode name-function)))
 964       (let ((comp-proc (get-buffer-process (current-buffer))))
 965         (if comp-proc
 966             (if (or (not (eq (process-status comp-proc) 'run))
 967                     (yes-or-no-p
 968                      (format "A %s process is running; kill it? "
 969                              name-of-mode)))
 970                 (condition-case ()
 971                     (progn
 972                       (interrupt-process comp-proc)
 973                       (sit-for 1)
 974                       (delete-process comp-proc))
 975                   (error nil))
 976               (error "Cannot have two processes in `%s' at once"
 977                      (buffer-name)))))
 978       (buffer-disable-undo (current-buffer))
 979       ;; first transfer directory from where M-x compile was called
 980       (setq default-directory thisdir)
 981       ;; Make compilation buffer read-only.  The filter can still write it.
 982       ;; Clear out the compilation buffer.
 983       (let ((inhibit-read-only t)
 984             (default-directory thisdir))
 985         ;; Then evaluate a cd command if any, but don't perform it yet, else start-command
 986         ;; would do it again through the shell: (cd "..") AND sh -c "cd ..; make"
 987         (cd (if (string-match "^\\s *cd\\(?:\\s +\\(\\S +?\\)\\)?\\s *[;&\n]" command)
 988                 (if (match-end 1)
 989                     (substitute-env-vars (match-string 1 command))
 990                   "~")
 991               default-directory))
 992         (erase-buffer)
 993         ;; Select the desired mode.
 994         (if (not (eq mode t))
 995             (funcall mode)
 996           (setq buffer-read-only nil)
 997           (with-no-warnings (comint-mode))
 998           (compilation-shell-minor-mode))
 999         (if highlight-regexp
1000             (set (make-local-variable 'compilation-highlight-regexp)
1001                  highlight-regexp))
1002         ;; Output a mode setter, for saving and later reloading this buffer.
1003         (insert "-*- mode: " name-of-mode
1004                 "; default-directory: " (prin1-to-string default-directory)
1005                 " -*-\n"
1006                 (format "%s started at %s\n\n"
1007                         mode-name
1008                         (substring (current-time-string) 0 19))
1009                 command "\n")
1010         (setq thisdir default-directory))
1011       (set-buffer-modified-p nil))
1012     ;; If we're already in the compilation buffer, go to the end
1013     ;; of the buffer, so point will track the compilation output.
1014     (if (eq outbuf (current-buffer))
1015         (goto-char (point-max)))
1016     ;; Pop up the compilation buffer.
1017     (setq outwin (display-buffer outbuf nil t))
1018     (with-current-buffer outbuf
1019       (let ((process-environment
1020              (append
1021               compilation-environment
1022               (if (if (boundp 'system-uses-terminfo) ; `if' for compiler warning
1023                       system-uses-terminfo)
1024                   (list "TERM=dumb" "TERMCAP="
1025                         (format "COLUMNS=%d" (window-width)))
1026                 (list "TERM=emacs"
1027                       (format "TERMCAP=emacs:co#%d:tc=unknown:"
1028                               (window-width))))
1029               ;; Set the EMACS variable, but
1030               ;; don't override users' setting of $EMACS.
1031               (unless (getenv "EMACS") '("EMACS=t"))
1032               (copy-sequence process-environment))))
1033         (set (make-local-variable 'compilation-arguments)
1034              (list command mode name-function highlight-regexp))
1035         (set (make-local-variable 'revert-buffer-function)
1036              'compilation-revert-buffer)
1037         (set-window-start outwin (point-min))
1038         (or (eq outwin (selected-window))
1039             (set-window-point outwin (if compilation-scroll-output
1040                                          (point)
1041                                        (point-min))))
1042         ;; The setup function is called before compilation-set-window-height
1043         ;; so it can set the compilation-window-height buffer locally.
1044         (if compilation-process-setup-function
1045             (funcall compilation-process-setup-function))
1046         (compilation-set-window-height outwin)
1047         ;; Start the compilation.
1048         (if (fboundp 'start-process)
1049             (let ((proc (if (eq mode t)
1050                             (get-buffer-process
1051                              (with-no-warnings
1052                               (comint-exec outbuf (downcase mode-name)
1053                                            shell-file-name nil `("-c" ,command))))
1054                           (start-process-shell-command (downcase mode-name)
1055                                                        outbuf command))))
1056               ;; Make the buffer's mode line show process state.
1057               (setq mode-line-process '(":%s"))
1058               (set-process-sentinel proc 'compilation-sentinel)
1059               (set-process-filter proc 'compilation-filter)
1060               (set-marker (process-mark proc) (point) outbuf)
1061               (when compilation-disable-input
1062                 (condition-case nil
1063                     (process-send-eof proc)
1064                   ;; The process may have exited already.
1065                   (error nil)))
1066               (setq compilation-in-progress
1067                     (cons proc compilation-in-progress)))
1068           ;; No asynchronous processes available.
1069           (message "Executing `%s'..." command)
1070           ;; Fake modeline display as if `start-process' were run.
1071           (setq mode-line-process ":run")
1072           (force-mode-line-update)
1073           (sit-for 0)                   ; Force redisplay
1074           (let* ((buffer-read-only nil) ; call-process needs to modify outbuf
1075                  (status (call-process shell-file-name nil outbuf nil "-c"
1076                                        command)))
1077             (cond ((numberp status)
1078                    (compilation-handle-exit 'exit status
1079                                             (if (zerop status)
1080                                                 "finished\n"
1081                                               (format "\
1082 exited abnormally with code %d\n"
1083                                                       status))))
1084                   ((stringp status)
1085                    (compilation-handle-exit 'signal status
1086                                             (concat status "\n")))
1087                   (t
1088                    (compilation-handle-exit 'bizarre status status))))
1089           ;; Without async subprocesses, the buffer is not yet
1090           ;; fontified, so fontify it now.
1091           (let ((font-lock-verbose nil)) ; shut up font-lock messages
1092             (font-lock-fontify-buffer))
1093           (set-buffer-modified-p nil)
1094           (message "Executing `%s'...done" command)))
1095       ;; Now finally cd to where the shell started make/grep/...
1096       (setq default-directory thisdir))
1097     (if (buffer-local-value 'compilation-scroll-output outbuf)
1098         (save-selected-window
1099           (select-window outwin)
1100           (goto-char (point-max))))
1101     ;; Make it so the next C-x ` will use this buffer.
1102     (setq next-error-last-buffer outbuf)))
1103
1104 (defun compilation-set-window-height (window)
1105   "Set the height of WINDOW according to `compilation-window-height'."
1106   (let ((height (buffer-local-value 'compilation-window-height (window-buffer window))))
1107     (and height
1108          (= (window-width window) (frame-width (window-frame window)))
1109          ;; If window is alone in its frame, aside from a minibuffer,
1110          ;; don't change its height.
1111          (not (eq window (frame-root-window (window-frame window))))
1112          ;; Stef said that doing the saves in this order is safer:
1113          (save-excursion
1114            (save-selected-window
1115              (select-window window)
1116              (enlarge-window (- height (window-height))))))))
1117
1118 (defvar compilation-menu-map
1119   (let ((map (make-sparse-keymap "Errors")))
1120     (define-key map [stop-subjob]
1121       '("Stop Compilation" . kill-compilation))
1122     (define-key map [compilation-mode-separator2]
1123       '("----" . nil))
1124     (define-key map [compilation-first-error]
1125       '("First Error" . first-error))
1126     (define-key map [compilation-previous-error]
1127       '("Previous Error" . previous-error))
1128     (define-key map [compilation-next-error]
1129       '("Next Error" . next-error))
1130     map))
1131
1132 (defvar compilation-minor-mode-map
1133   (let ((map (make-sparse-keymap)))
1134     (define-key map [mouse-2] 'compile-goto-error)
1135     (define-key map [follow-link] 'mouse-face)
1136     (define-key map "\C-c\C-c" 'compile-goto-error)
1137     (define-key map "\C-m" 'compile-goto-error)
1138     (define-key map "\C-c\C-k" 'kill-compilation)
1139     (define-key map "\M-n" 'compilation-next-error)
1140     (define-key map "\M-p" 'compilation-previous-error)
1141     (define-key map "\M-{" 'compilation-previous-file)
1142     (define-key map "\M-}" 'compilation-next-file)
1143     ;; Set up the menu-bar
1144     (define-key map [menu-bar compilation]
1145       (cons "Errors" compilation-menu-map))
1146     map)
1147   "Keymap for `compilation-minor-mode'.")
1148
1149 (defvar compilation-shell-minor-mode-map
1150   (let ((map (make-sparse-keymap)))
1151     (define-key map "\M-\C-m" 'compile-goto-error)
1152     (define-key map "\M-\C-n" 'compilation-next-error)
1153     (define-key map "\M-\C-p" 'compilation-previous-error)
1154     (define-key map "\M-{" 'compilation-previous-file)
1155     (define-key map "\M-}" 'compilation-next-file)
1156     ;; Set up the menu-bar
1157     (define-key map [menu-bar compilation]
1158       (cons "Errors" compilation-menu-map))
1159     map)
1160   "Keymap for `compilation-shell-minor-mode'.")
1161
1162 (defvar compilation-button-map
1163   (let ((map (make-sparse-keymap)))
1164     (define-key map [mouse-2] 'compile-goto-error)
1165     (define-key map [follow-link] 'mouse-face)
1166     (define-key map "\C-m" 'compile-goto-error)
1167     map)
1168   "Keymap for compilation-message buttons.")
1169 (fset 'compilation-button-map compilation-button-map)
1170
1171 (defvar compilation-mode-map
1172   (let ((map (make-sparse-keymap)))
1173     ;; Don't inherit from compilation-minor-mode-map,
1174     ;; because that introduces a menu bar item we don't want.
1175     ;; That confuses C-down-mouse-3.
1176     (define-key map [mouse-2] 'compile-goto-error)
1177     (define-key map [follow-link] 'mouse-face)
1178     (define-key map "\C-c\C-c" 'compile-goto-error)
1179     (define-key map "\C-m" 'compile-goto-error)
1180     (define-key map "\C-c\C-k" 'kill-compilation)
1181     (define-key map "\M-n" 'compilation-next-error)
1182     (define-key map "\M-p" 'compilation-previous-error)
1183     (define-key map "\M-{" 'compilation-previous-file)
1184     (define-key map "\M-}" 'compilation-next-file)
1185     (define-key map "\t" 'compilation-next-error)
1186     (define-key map [backtab] 'compilation-previous-error)
1187
1188     (define-key map " " 'scroll-up)
1189     (define-key map "\^?" 'scroll-down)
1190     (define-key map "\C-c\C-f" 'next-error-follow-minor-mode)
1191
1192     ;; Set up the menu-bar
1193     (let ((submap (make-sparse-keymap "Compile")))
1194       (define-key map [menu-bar compilation]
1195         (cons "Compile" submap))
1196       (set-keymap-parent submap compilation-menu-map))
1197     (define-key map [menu-bar compilation compilation-separator2]
1198       '("----" . nil))
1199     (define-key map [menu-bar compilation compilation-grep]
1200       '("Search Files (grep)..." . grep))
1201     (define-key map [menu-bar compilation compilation-recompile]
1202       '("Recompile" . recompile))
1203     (define-key map [menu-bar compilation compilation-compile]
1204       '("Compile..." . compile))
1205     map)
1206   "Keymap for compilation log buffers.
1207 `compilation-minor-mode-map' is a parent of this.")
1208
1209 (put 'compilation-mode 'mode-class 'special)
1210
1211 (defvar compilation-skip-to-next-location t
1212   "*If non-nil, skip multiple error messages for the same source location.")
1213
1214 (defcustom compilation-skip-threshold 1
1215   "*Compilation motion commands skip less important messages.
1216 The value can be either 2 -- skip anything less than error, 1 --
1217 skip anything less than warning or 0 -- don't skip any messages.
1218 Note that all messages not positively identified as warning or
1219 info, are considered errors."
1220   :type '(choice (const :tag "Warnings and info" 2)
1221                  (const :tag "Info" 1)
1222                  (const :tag "None" 0))
1223   :group 'compilation
1224   :version "22.1")
1225
1226 (defcustom compilation-skip-visited nil
1227   "*Compilation motion commands skip visited messages if this is t.
1228 Visited messages are ones for which the file, line and column have been jumped
1229 to from the current content in the current compilation buffer, even if it was
1230 from a different message."
1231   :type 'boolean
1232   :group 'compilation
1233   :version "22.1")
1234
1235 ;;;###autoload
1236 (defun compilation-mode (&optional name-of-mode)
1237   "Major mode for compilation log buffers.
1238 \\<compilation-mode-map>To visit the source for a line-numbered error,
1239 move point to the error message line and type \\[compile-goto-error].
1240 To kill the compilation, type \\[kill-compilation].
1241
1242 Runs `compilation-mode-hook' with `run-mode-hooks' (which see).
1243
1244 \\{compilation-mode-map}"
1245   (interactive)
1246   (kill-all-local-variables)
1247   (use-local-map compilation-mode-map)
1248   (setq major-mode 'compilation-mode
1249         mode-name (or name-of-mode "Compilation"))
1250   (set (make-local-variable 'page-delimiter)
1251        compilation-page-delimiter)
1252   (compilation-setup)
1253   (setq buffer-read-only t)
1254   (run-mode-hooks 'compilation-mode-hook))
1255
1256 (defmacro define-compilation-mode (mode name doc &rest body)
1257   "This is like `define-derived-mode' without the PARENT argument.
1258 The parent is always `compilation-mode' and the customizable `compilation-...'
1259 variables are also set from the name of the mode you have chosen,
1260 by replacing the first word, e.g `compilation-scroll-output' from
1261 `grep-scroll-output' if that variable exists."
1262   (let ((mode-name (replace-regexp-in-string "-mode\\'" "" (symbol-name mode))))
1263     `(define-derived-mode ,mode compilation-mode ,name
1264        ,doc
1265        ,@(mapcar (lambda (v)
1266                    (setq v (cons v
1267                                  (intern-soft (replace-regexp-in-string
1268                                                "^compilation" mode-name
1269                                                (symbol-name v)))))
1270                    (and (cdr v)
1271                         (or (boundp (cdr v))
1272                             (if (boundp 'byte-compile-bound-variables)
1273                                 (memq (cdr v) byte-compile-bound-variables)))
1274                         `(set (make-local-variable ',(car v)) ,(cdr v))))
1275                  '(compilation-buffer-name-function
1276                    compilation-directory-matcher
1277                    compilation-error
1278                    compilation-error-regexp-alist
1279                    compilation-error-regexp-alist-alist
1280                    compilation-error-screen-columns
1281                    compilation-finish-function
1282                    compilation-finish-functions
1283                    compilation-first-column
1284                    compilation-mode-font-lock-keywords
1285                    compilation-page-delimiter
1286                    compilation-parse-errors-filename-function
1287                    compilation-process-setup-function
1288                    compilation-scroll-output
1289                    compilation-search-path
1290                    compilation-skip-threshold
1291                    compilation-window-height))
1292        ,@body)))
1293
1294 (defun compilation-revert-buffer (ignore-auto noconfirm)
1295   (if buffer-file-name
1296       (let (revert-buffer-function)
1297         (revert-buffer ignore-auto noconfirm))
1298     (if (or noconfirm (yes-or-no-p (format "Restart compilation? ")))
1299         (apply 'compilation-start compilation-arguments))))
1300
1301 (defvar compilation-current-error nil
1302   "Marker to the location from where the next error will be found.
1303 The global commands next/previous/first-error/goto-error use this.")
1304
1305 (defvar compilation-messages-start nil
1306   "Buffer position of the beginning of the compilation messages.
1307 If nil, use the beginning of buffer.")
1308
1309 ;; A function name can't be a hook, must be something with a value.
1310 (defconst compilation-turn-on-font-lock 'turn-on-font-lock)
1311
1312 (defun compilation-setup (&optional minor)
1313   "Prepare the buffer for the compilation parsing commands to work.
1314 Optional argument MINOR indicates this is called from
1315 `compilation-minor-mode'."
1316   (make-local-variable 'compilation-current-error)
1317   (make-local-variable 'compilation-messages-start)
1318   (make-local-variable 'compilation-error-screen-columns)
1319   (make-local-variable 'overlay-arrow-position)
1320   (set (make-local-variable 'overlay-arrow-string) "")
1321   (setq next-error-overlay-arrow-position nil)
1322   (add-hook 'kill-buffer-hook
1323             (lambda () (setq next-error-overlay-arrow-position nil)) nil t)
1324   ;; Note that compilation-next-error-function is for interfacing
1325   ;; with the next-error function in simple.el, and it's only
1326   ;; coincidentally named similarly to compilation-next-error.
1327   (setq next-error-function 'compilation-next-error-function)
1328   (set (make-local-variable 'font-lock-extra-managed-props)
1329        '(directory message help-echo mouse-face debug))
1330   (set (make-local-variable 'compilation-locs)
1331        (make-hash-table :test 'equal :weakness 'value))
1332   ;; lazy-lock would never find the message unless it's scrolled to.
1333   ;; jit-lock might fontify some things too late.
1334   (set (make-local-variable 'font-lock-support-mode) nil)
1335   (set (make-local-variable 'font-lock-maximum-size) nil)
1336   (let ((fld font-lock-defaults))
1337     (if (and minor fld)
1338         (font-lock-add-keywords nil (compilation-mode-font-lock-keywords))
1339       (setq font-lock-defaults '(compilation-mode-font-lock-keywords t)))
1340     (if minor
1341         (if font-lock-mode
1342             (if fld
1343                 (font-lock-fontify-buffer)
1344               (font-lock-change-mode)
1345               (turn-on-font-lock))
1346           (turn-on-font-lock))
1347       ;; maybe defer font-lock till after derived mode is set up
1348       (run-mode-hooks 'compilation-turn-on-font-lock))))
1349
1350 ;;;###autoload
1351 (define-minor-mode compilation-shell-minor-mode
1352   "Toggle compilation shell minor mode.
1353 With arg, turn compilation mode on if and only if arg is positive.
1354 In this minor mode, all the error-parsing commands of the
1355 Compilation major mode are available but bound to keys that don't
1356 collide with Shell mode.  See `compilation-mode'.
1357 Turning the mode on runs the normal hook `compilation-shell-minor-mode-hook'."
1358   nil " Shell-Compile"
1359   :group 'compilation
1360   (if compilation-shell-minor-mode
1361       (compilation-setup t)
1362     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1363     (font-lock-fontify-buffer)))
1364
1365 ;;;###autoload
1366 (define-minor-mode compilation-minor-mode
1367   "Toggle compilation minor mode.
1368 With arg, turn compilation mode on if and only if arg is positive.
1369 In this minor mode, all the error-parsing commands of the
1370 Compilation major mode are available.  See `compilation-mode'.
1371 Turning the mode on runs the normal hook `compilation-minor-mode-hook'."
1372   nil " Compilation"
1373   :group 'compilation
1374   (if compilation-minor-mode
1375       (compilation-setup t)
1376     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1377     (font-lock-fontify-buffer)))
1378
1379 (defun compilation-handle-exit (process-status exit-status msg)
1380   "Write MSG in the current buffer and hack its mode-line-process."
1381   (let ((inhibit-read-only t)
1382         (status (if compilation-exit-message-function
1383                     (funcall compilation-exit-message-function
1384                              process-status exit-status msg)
1385                   (cons msg exit-status)))
1386         (omax (point-max))
1387         (opoint (point)))
1388     ;; Record where we put the message, so we can ignore it later on.
1389     (goto-char omax)
1390     (insert ?\n mode-name " " (car status))
1391     (if (and (numberp compilation-window-height)
1392              (zerop compilation-window-height))
1393         (message "%s" (cdr status)))
1394     (if (bolp)
1395         (forward-char -1))
1396     (insert " at " (substring (current-time-string) 0 19))
1397     (goto-char (point-max))
1398     ;; Prevent that message from being recognized as a compilation error.
1399     (add-text-properties omax (point)
1400                          (append '(compilation-handle-exit t) nil))
1401     (setq mode-line-process (format ":%s [%s]" process-status (cdr status)))
1402     ;; Force mode line redisplay soon.
1403     (force-mode-line-update)
1404     (if (and opoint (< opoint omax))
1405         (goto-char opoint))
1406     (with-no-warnings
1407       (if compilation-finish-function
1408           (funcall compilation-finish-function (current-buffer) msg)))
1409     (let ((functions compilation-finish-functions))
1410       (while functions
1411         (funcall (car functions) (current-buffer) msg)
1412         (setq functions (cdr functions))))))
1413
1414 ;; Called when compilation process changes state.
1415 (defun compilation-sentinel (proc msg)
1416   "Sentinel for compilation buffers."
1417   (if (memq (process-status proc) '(exit signal))
1418       (let ((buffer (process-buffer proc)))
1419         (if (null (buffer-name buffer))
1420             ;; buffer killed
1421             (set-process-buffer proc nil)
1422           (with-current-buffer buffer
1423             ;; Write something in the compilation buffer
1424             ;; and hack its mode line.
1425             (compilation-handle-exit (process-status proc)
1426                                      (process-exit-status proc)
1427                                      msg)
1428             ;; Since the buffer and mode line will show that the
1429             ;; process is dead, we can delete it now.  Otherwise it
1430             ;; will stay around until M-x list-processes.
1431             (delete-process proc)))
1432         (setq compilation-in-progress (delq proc compilation-in-progress)))))
1433
1434 (defun compilation-filter (proc string)
1435   "Process filter for compilation buffers.
1436 Just inserts the text, but uses `insert-before-markers'."
1437   (if (buffer-name (process-buffer proc))
1438       (with-current-buffer (process-buffer proc)
1439         (let ((inhibit-read-only t))
1440           (save-excursion
1441             (goto-char (process-mark proc))
1442             (insert-before-markers string)
1443             (run-hooks 'compilation-filter-hook))))))
1444
1445 ;;; test if a buffer is a compilation buffer, assuming we're in the buffer
1446 (defsubst compilation-buffer-internal-p ()
1447   "Test if inside a compilation buffer."
1448   (local-variable-p 'compilation-locs))
1449
1450 ;;; test if a buffer is a compilation buffer, using compilation-buffer-internal-p
1451 (defsubst compilation-buffer-p (buffer)
1452   "Test if BUFFER is a compilation buffer."
1453   (with-current-buffer buffer
1454     (compilation-buffer-internal-p)))
1455
1456 (defmacro compilation-loop (< property-change 1+ error)
1457   `(while (,< n 0)
1458       (or (setq pt (,property-change pt 'message))
1459           (error ,error compilation-error))
1460       ;; prop 'message usually has 2 changes, on and off, so re-search if off
1461       (or (setq msg (get-text-property pt 'message))
1462           (if (setq pt (,property-change pt 'message))
1463               (setq msg (get-text-property pt 'message)))
1464           (error ,error compilation-error))
1465       (or (< (cadr msg) compilation-skip-threshold)
1466           (if different-file
1467               (eq (prog1 last (setq last (nth 2 (car msg))))
1468                   last))
1469           (if compilation-skip-visited
1470               (nthcdr 4 (car msg)))
1471           (if compilation-skip-to-next-location
1472               (eq (car msg) loc))
1473           ;; count this message only if none of the above are true
1474           (setq n (,1+ n)))))
1475
1476 (defun compilation-next-error (n &optional different-file pt)
1477   "Move point to the next error in the compilation buffer.
1478 Prefix arg N says how many error messages to move forwards (or
1479 backwards, if negative).
1480 Does NOT find the source line like \\[next-error]."
1481   (interactive "p")
1482   (or (compilation-buffer-p (current-buffer))
1483       (error "Not in a compilation buffer"))
1484   (or pt (setq pt (point)))
1485   (let* ((msg (get-text-property pt 'message))
1486          (loc (car msg))
1487          last)
1488     (if (zerop n)
1489         (unless (or msg                 ; find message near here
1490                     (setq msg (get-text-property (max (1- pt) (point-min))
1491                                                  'message)))
1492           (setq pt (previous-single-property-change pt 'message nil
1493                                                     (line-beginning-position)))
1494           (unless (setq msg (get-text-property (max (1- pt) (point-min)) 'message))
1495             (setq pt (next-single-property-change pt 'message nil
1496                                                   (line-end-position)))
1497             (or (setq msg (get-text-property pt 'message))
1498                 (setq pt (point)))))
1499       (setq last (nth 2 (car msg)))
1500       (if (>= n 0)
1501           (compilation-loop > next-single-property-change 1-
1502                             (if (get-buffer-process (current-buffer))
1503                                 "No more %ss yet"
1504                               "Moved past last %s"))
1505         ;; Don't move "back" to message at or before point.
1506         ;; Pass an explicit (point-min) to make sure pt is non-nil.
1507         (setq pt (previous-single-property-change pt 'message nil (point-min)))
1508         (compilation-loop < previous-single-property-change 1+
1509                           "Moved back before first %s")))
1510     (goto-char pt)
1511     (or msg
1512         (error "No %s here" compilation-error))))
1513
1514 (defun compilation-previous-error (n)
1515   "Move point to the previous error in the compilation buffer.
1516 Prefix arg N says how many error messages to move backwards (or
1517 forwards, if negative).
1518 Does NOT find the source line like \\[previous-error]."
1519   (interactive "p")
1520   (compilation-next-error (- n)))
1521
1522 (defun compilation-next-file (n)
1523   "Move point to the next error for a different file than the current one.
1524 Prefix arg N says how many files to move forwards (or backwards, if negative)."
1525   (interactive "p")
1526   (compilation-next-error n t))
1527
1528 (defun compilation-previous-file (n)
1529   "Move point to the previous error for a different file than the current one.
1530 Prefix arg N says how many files to move backwards (or forwards, if negative)."
1531   (interactive "p")
1532   (compilation-next-file (- n)))
1533
1534 (defun kill-compilation ()
1535   "Kill the process made by the \\[compile] or \\[grep] commands."
1536   (interactive)
1537   (let ((buffer (compilation-find-buffer)))
1538     (if (get-buffer-process buffer)
1539         (interrupt-process (get-buffer-process buffer))
1540       (error "The %s process is not running" (downcase mode-name)))))
1541
1542 (defalias 'compile-mouse-goto-error 'compile-goto-error)
1543
1544 (defun compile-goto-error (&optional event)
1545   "Visit the source for the error message at point.
1546 Use this command in a compilation log buffer.  Sets the mark at point there."
1547   (interactive (list last-input-event))
1548   (if event (posn-set-point (event-end event)))
1549   (or (compilation-buffer-p (current-buffer))
1550       (error "Not in a compilation buffer"))
1551   (if (get-text-property (point) 'directory)
1552       (dired-other-window (car (get-text-property (point) 'directory)))
1553     (push-mark)
1554     (setq compilation-current-error (point))
1555     (next-error 0)))
1556
1557 ;; Return a compilation buffer.
1558 ;; If the current buffer is a compilation buffer, return it.
1559 ;; Otherwise, look for a compilation buffer and signal an error
1560 ;; if there are none.
1561 (defun compilation-find-buffer (&optional avoid-current)
1562   (next-error-find-buffer avoid-current 'compilation-buffer-internal-p))
1563
1564 ;;;###autoload
1565 (defun compilation-next-error-function (n &optional reset)
1566   "Advance to the next error message and visit the file where the error was.
1567 This is the value of `next-error-function' in Compilation buffers."
1568   (interactive "p")
1569   (when reset
1570     (setq compilation-current-error nil))
1571   (let* ((columns compilation-error-screen-columns) ; buffer's local value
1572          (last 1)
1573          (loc (compilation-next-error (or n 1) nil
1574                                       (or compilation-current-error
1575                                           compilation-messages-start
1576                                           (point-min))))
1577          (end-loc (nth 2 loc))
1578          (marker (point-marker)))
1579     (setq compilation-current-error (point-marker)
1580           overlay-arrow-position
1581             (if (bolp)
1582                 compilation-current-error
1583               (copy-marker (line-beginning-position)))
1584           loc (car loc))
1585     ;; If loc contains no marker, no error in that file has been visited.  If
1586     ;; the marker is invalid the buffer has been killed.  So, recalculate all
1587     ;; markers for that file.
1588     (unless (and (nth 3 loc) (marker-buffer (nth 3 loc)))
1589       (with-current-buffer (compilation-find-file marker (caar (nth 2 loc))
1590                                                   (cadr (car (nth 2 loc))))
1591         (save-restriction
1592           (widen)
1593           (goto-char (point-min))
1594           ;; Treat file's found lines in forward order, 1 by 1.
1595           (dolist (line (reverse (cddr (nth 2 loc))))
1596             (when (car line)            ; else this is a filename w/o a line#
1597               (beginning-of-line (- (car line) last -1))
1598               (setq last (car line)))
1599             ;; Treat line's found columns and store/update a marker for each.
1600             (dolist (col (cdr line))
1601               (if (car col)
1602                   (if (eq (car col) -1) ; special case for range end
1603                       (end-of-line)
1604                     (compilation-move-to-column (car col) columns))
1605                 (beginning-of-line)
1606                 (skip-chars-forward " \t"))
1607               (if (nth 3 col)
1608                   (set-marker (nth 3 col) (point))
1609                 (setcdr (nthcdr 2 col) `(,(point-marker)))))))))
1610     (compilation-goto-locus marker (nth 3 loc) (nth 3 end-loc))
1611     (setcdr (nthcdr 3 loc) t)))         ; Set this one as visited.
1612
1613 (defvar compilation-gcpro nil
1614   "Internal variable used to keep some values from being GC'd.")
1615 (make-variable-buffer-local 'compilation-gcpro)
1616
1617 (defun compilation-fake-loc (marker file &optional line col)
1618   "Preassociate MARKER with FILE.
1619 FILE should be ABSOLUTE-FILENAME or (RELATIVE-FILENAME . DIRNAME).
1620 This is useful when you compile temporary files, but want
1621 automatic translation of the messages to the real buffer from
1622 which the temporary file came.  This only works if done before a
1623 message about FILE appears!
1624
1625 Optional args LINE and COL default to 1 and beginning of
1626 indentation respectively.  The marker is expected to reflect
1627 this.  In the simplest case the marker points to the first line
1628 of the region that was saved to the temp file.
1629
1630 If you concatenate several regions into the temp file (e.g. a
1631 header with variable assignments and a code region), you must
1632 call this several times, once each for the last line of one
1633 region and the first line of the next region."
1634   (or (consp file) (setq file (list file)))
1635   (setq file (compilation-get-file-structure file))
1636   ;; Between the current call to compilation-fake-loc and the first occurrence
1637   ;; of an error message referring to `file', the data is only kept is the
1638   ;; weak hash-table compilation-locs, so we need to prevent this entry
1639   ;; in compilation-locs from being GC'd away.  --Stef
1640   (push file compilation-gcpro)
1641   (let ((loc (compilation-assq (or line 1) (cdr file))))
1642     (setq loc (compilation-assq col loc))
1643     (if (cdr loc)
1644         (setcdr (cddr loc) (list marker))
1645       (setcdr loc (list line file marker)))
1646     loc))
1647
1648 (defcustom compilation-context-lines nil
1649   "Display this many lines of leading context before the current message.
1650 If nil and the left fringe is displayed, don't scroll the
1651 compilation output window; an arrow in the left fringe points to
1652 the current message.  If nil and there is no left fringe, the message
1653 displays at the top of the window; there is no arrow."
1654   :type '(choice integer (const :tag "No window scrolling" nil))
1655   :group 'compilation
1656   :version "22.1")
1657
1658 (defsubst compilation-set-window (w mk)
1659   "Align the compilation output window W with marker MK near top."
1660   (if (integerp compilation-context-lines)
1661       (set-window-start w (save-excursion
1662                             (goto-char mk)
1663                             (beginning-of-line
1664                              (- 1 compilation-context-lines))
1665                             (point)))
1666     ;; If there is no left fringe.
1667     (if (equal (car (window-fringes)) 0)
1668         (set-window-start w (save-excursion
1669                               (goto-char mk)
1670                             (beginning-of-line 1)
1671                             (point)))))
1672     (set-window-point w mk))
1673
1674 (defvar next-error-highlight-timer)
1675
1676 (defun compilation-goto-locus (msg mk end-mk)
1677   "Jump to an error corresponding to MSG at MK.
1678 All arguments are markers.  If END-MK is non-nil, mark is set there
1679 and overlay is highlighted between MK and END-MK."
1680   (if (eq (window-buffer (selected-window))
1681           (marker-buffer msg))
1682       ;; If the compilation buffer window is selected,
1683       ;; keep the compilation buffer in this window;
1684       ;; display the source in another window.
1685       (let ((pop-up-windows t))
1686         (pop-to-buffer (marker-buffer mk)))
1687     (if (window-dedicated-p (selected-window))
1688         (pop-to-buffer (marker-buffer mk))
1689       (switch-to-buffer (marker-buffer mk))))
1690   ;; If narrowing gets in the way of going to the right place, widen.
1691   (unless (eq (goto-char mk) (point))
1692     (widen)
1693     (goto-char mk))
1694   (if end-mk
1695       (push-mark end-mk t)
1696     (if mark-active (setq mark-active)))
1697   ;; If hideshow got in the way of
1698   ;; seeing the right place, open permanently.
1699   (dolist (ov (overlays-at (point)))
1700     (when (eq 'hs (overlay-get ov 'invisible))
1701       (delete-overlay ov)
1702       (goto-char mk)))
1703
1704   ;; Show compilation buffer in other window, scrolled to this error.
1705   (let* ((pop-up-windows t)
1706          ;; Use an existing window if it is in a visible frame.
1707          (pre-existing (get-buffer-window (marker-buffer msg) 0))
1708          (w (let ((display-buffer-reuse-frames t))
1709               ;; Pop up a window.
1710               (display-buffer (marker-buffer msg))))
1711          (highlight-regexp (with-current-buffer (marker-buffer msg)
1712                              ;; also do this while we change buffer
1713                              (compilation-set-window w msg)
1714                              compilation-highlight-regexp)))
1715     ;; Ideally, the window-size should be passed to `display-buffer' (via
1716     ;; something like special-display-buffer) so it's only used when
1717     ;; creating a new window.
1718     (unless pre-existing (compilation-set-window-height w))
1719
1720     (when highlight-regexp
1721       (if (timerp next-error-highlight-timer)
1722           (cancel-timer next-error-highlight-timer))
1723       (unless compilation-highlight-overlay
1724         (setq compilation-highlight-overlay
1725               (make-overlay (point-min) (point-min)))
1726         (overlay-put compilation-highlight-overlay 'face 'next-error))
1727       (with-current-buffer (marker-buffer mk)
1728         (save-excursion
1729           (if end-mk (goto-char end-mk) (end-of-line))
1730           (let ((end (point)))
1731             (if mk (goto-char mk) (beginning-of-line))
1732             (if (and (stringp highlight-regexp)
1733                      (re-search-forward highlight-regexp end t))
1734                 (progn
1735                   (goto-char (match-beginning 0))
1736                   (move-overlay compilation-highlight-overlay
1737                                 (match-beginning 0) (match-end 0)
1738                                 (current-buffer)))
1739               (move-overlay compilation-highlight-overlay
1740                             (point) end (current-buffer)))
1741             (if (numberp next-error-highlight)
1742                 (setq next-error-highlight-timer
1743                       (run-at-time next-error-highlight nil 'delete-overlay
1744                                    compilation-highlight-overlay)))
1745             (if (not (or (eq next-error-highlight t)
1746                          (numberp next-error-highlight)))
1747                 (delete-overlay compilation-highlight-overlay))))))
1748     (when (and (eq next-error-highlight 'fringe-arrow))
1749       (setq next-error-overlay-arrow-position
1750             (copy-marker (line-beginning-position))))))
1751
1752 \f
1753 (defun compilation-find-file (marker filename directory &rest formats)
1754   "Find a buffer for file FILENAME.
1755 Search the directories in `compilation-search-path'.
1756 A nil in `compilation-search-path' means to try the
1757 \"current\" directory, which is passed in DIRECTORY.
1758 If DIRECTORY. is relative, it is combined with `default-directory'.
1759 If DIRECTORY. is nil, that means use `default-directory'.
1760 If FILENAME is not found at all, ask the user where to find it.
1761 Pop up the buffer containing MARKER and scroll to MARKER if we ask the user."
1762   (or formats (setq formats '("%s")))
1763   (save-excursion
1764     (let ((dirs compilation-search-path)
1765           (spec-dir (if directory
1766                         (expand-file-name directory)
1767                       default-directory))
1768           buffer thisdir fmts name)
1769       (if (file-name-absolute-p filename)
1770           ;; The file name is absolute.  Use its explicit directory as
1771           ;; the first in the search path, and strip it from FILENAME.
1772           (setq filename (abbreviate-file-name (expand-file-name filename))
1773                 dirs (cons (file-name-directory filename) dirs)
1774                 filename (file-name-nondirectory filename)))
1775       ;; Now search the path.
1776       (while (and dirs (null buffer))
1777         (setq thisdir (or (car dirs) spec-dir)
1778               fmts formats)
1779         ;; For each directory, try each format string.
1780         (while (and fmts (null buffer))
1781           (setq name (expand-file-name (format (car fmts) filename) thisdir)
1782                 buffer (and (file-exists-p name)
1783                             (find-file-noselect name))
1784                 fmts (cdr fmts)))
1785         (setq dirs (cdr dirs)))
1786       (or buffer
1787           ;; The file doesn't exist.  Ask the user where to find it.
1788           (let ((pop-up-windows t))
1789             (compilation-set-window (display-buffer (marker-buffer marker))
1790                                     marker)
1791             (let ((name (expand-file-name
1792                          (read-file-name
1793                           (format "Find this %s in (default %s): "
1794                                   compilation-error filename)
1795                           spec-dir filename t))))
1796               (if (file-directory-p name)
1797                   (setq name (expand-file-name filename name)))
1798               (setq buffer (and (file-exists-p name)
1799                                 (find-file name))))))
1800       ;; Make intangible overlays tangible.
1801       (mapcar (function (lambda (ov)
1802                           (when (overlay-get ov 'intangible)
1803                             (overlay-put ov 'intangible nil))))
1804               (overlays-in (point-min) (point-max)))
1805       buffer)))
1806
1807 (defun compilation-get-file-structure (file &optional fmt)
1808   "Retrieve FILE's file-structure or create a new one.
1809 FILE should be (FILENAME) or (RELATIVE-FILENAME . DIRNAME).
1810 In the former case, FILENAME may be relative or absolute.
1811
1812 The file-structure looks like this:
1813   (list (list FILENAME [DIR-FROM-PREV-MSG]) FMT LINE-STRUCT...)
1814 "
1815   (or (gethash file compilation-locs)
1816       ;; File was not previously encountered, at least not in the form passed.
1817       ;; Let's normalize it and look again.
1818       (let ((filename (car file))
1819             ;; Get the specified directory from FILE.
1820             (spec-directory (if (cdr file)
1821                                 (file-truename (cdr file)))))
1822
1823         ;; Check for a comint-file-name-prefix and prepend it if appropriate.
1824         ;; (This is very useful for compilation-minor-mode in an rlogin-mode
1825         ;; buffer.)
1826         (when (and (boundp 'comint-file-name-prefix)
1827                    (not (equal comint-file-name-prefix "")))
1828           (if (file-name-absolute-p filename)
1829               (setq filename
1830                     (concat comint-file-name-prefix filename))
1831             (if spec-directory
1832                 (setq spec-directory
1833                       (file-truename
1834                        (concat comint-file-name-prefix spec-directory))))))
1835
1836         ;; If compilation-parse-errors-filename-function is
1837         ;; defined, use it to process the filename.
1838         (when compilation-parse-errors-filename-function
1839           (setq filename
1840                 (funcall compilation-parse-errors-filename-function
1841                          filename)))
1842
1843         ;; Some compilers (e.g. Sun's java compiler, reportedly) produce bogus
1844         ;; file names like "./bar//foo.c" for file "bar/foo.c";
1845         ;; expand-file-name will collapse these into "/foo.c" and fail to find
1846         ;; the appropriate file.  So we look for doubled slashes in the file
1847         ;; name and fix them.
1848         (setq filename (command-line-normalize-file-name filename))
1849
1850         ;; Store it for the possibly unnormalized name
1851         (puthash file
1852                  ;; Retrieve or create file-structure for normalized name
1853                  (or (gethash (list filename) compilation-locs)
1854                      (puthash (list filename)
1855                               (list (list filename spec-directory) fmt)
1856                               compilation-locs))
1857                  compilation-locs))))
1858
1859 (add-to-list 'debug-ignored-errors "^No more [-a-z ]+s yet$")
1860
1861 ;;; Compatibility with the old compile.el.
1862
1863 (defun compile-buffer-substring (n) (if n (match-string n)))
1864
1865 (defun compilation-compat-error-properties (err)
1866   "Map old-style error ERR to new-style message."
1867   ;; Old-style structure is (MARKER (FILE DIR) LINE COL) or
1868   ;; (MARKER . MARKER).
1869   (let ((dst (cdr err)))
1870     (if (markerp dst)
1871         ;; Must start with a face, for font-lock.
1872         `(face nil
1873           message ,(list (list nil nil nil dst) 2)
1874           help-echo "mouse-2: visit the source location"
1875           keymap compilation-button-map
1876           mouse-face highlight)
1877       ;; Too difficult to do it by hand: dispatch to the normal code.
1878       (let* ((file (pop dst))
1879              (line (pop dst))
1880              (col (pop dst))
1881              (filename (pop file))
1882              (dirname (pop file))
1883              (fmt (pop file)))
1884         (compilation-internal-error-properties
1885          (cons filename dirname) line nil col nil 2 fmt)))))
1886
1887 (defun compilation-compat-parse-errors (limit)
1888   (when compilation-parse-errors-function
1889     ;; FIXME: We should remove the rest of the compilation keywords
1890     ;; but we can't do that from here because font-lock is using
1891     ;; the value right now.  --stef
1892     (save-excursion
1893       (setq compilation-error-list nil)
1894       ;; Reset compilation-parsing-end each time because font-lock
1895       ;; might force us the re-parse many times (typically because
1896       ;; some code adds some text-property to the output that we
1897       ;; already parsed).  You might say "why reparse", well:
1898       ;; because font-lock has just removed the `message' property so
1899       ;; have to do it all over again.
1900       (if compilation-parsing-end
1901           (set-marker compilation-parsing-end (point))
1902         (setq compilation-parsing-end (point-marker)))
1903       (condition-case nil
1904           ;; Ignore any error: we're calling this function earlier than
1905           ;; in the old compile.el so things might not all be setup yet.
1906           (funcall compilation-parse-errors-function limit nil)
1907         (error nil))
1908       (dolist (err (if (listp compilation-error-list) compilation-error-list))
1909         (let* ((src (car err))
1910                (dst (cdr err))
1911                (loc (cond ((markerp dst) (list nil nil nil dst))
1912                           ((consp dst)
1913                            (list (nth 2 dst) (nth 1 dst)
1914                                  (cons (cdar dst) (caar dst)))))))
1915           (when loc
1916             (goto-char src)
1917             ;; (put-text-property src (line-end-position) 'font-lock-face 'font-lock-warning-face)
1918             (put-text-property src (line-end-position)
1919                                'message (list loc 2)))))))
1920   (goto-char limit)
1921   nil)
1922
1923 ;; Beware: this is not only compatiblity code.  New code stil uses it.  --Stef
1924 (defun compilation-forget-errors ()
1925   ;; In case we hit the same file/line specs, we want to recompute a new
1926   ;; marker for them, so flush our cache.
1927   (setq compilation-locs (make-hash-table :test 'equal :weakness 'value))
1928   (setq compilation-gcpro nil)
1929   ;; FIXME: the old code reset the directory-stack, so maybe we should
1930   ;; put a `directory change' marker of some sort, but where?  -stef
1931   ;;
1932   ;; FIXME: The old code moved compilation-current-error (which was
1933   ;; virtually represented by a mix of compilation-parsing-end and
1934   ;; compilation-error-list) to point-min, but that was only meaningful for
1935   ;; the internal uses of compilation-forget-errors: all calls from external
1936   ;; packages seem to be followed by a move of compilation-parsing-end to
1937   ;; something equivalent to point-max.  So we speculatively move
1938   ;; compilation-current-error to point-max (since the external package
1939   ;; won't know that it should do it).  --stef
1940   (setq compilation-current-error nil)
1941   (let* ((proc (get-buffer-process (current-buffer)))
1942          (mark (if proc (process-mark proc)))
1943          (pos (or mark (point-max))))
1944     (setq compilation-messages-start
1945           ;; In the future, ignore the text already present in the buffer.
1946           ;; Since many process filter functions insert before markers,
1947           ;; we need to put ours just before the insertion point rather
1948           ;; than at the insertion point.  If that's not possible, then
1949           ;; don't use a marker.  --Stef
1950           (if (> pos (point-min)) (copy-marker (1- pos)) pos))))
1951
1952 ;;;###autoload
1953 (add-to-list 'auto-mode-alist '("\\.gcov\\'" . compilation-mode))
1954
1955 (provide 'compile)
1956
1957 ;; arch-tag: 12465727-7382-4f72-b234-79855a00dd8c
1958 ;;; compile.el ends here