code.delx.au - gnu-emacs/blob - lisp/emacs-lisp/derived.el

   1 ;;; derived.el --- allow inheritance of major modes
   2 ;; (formerly mode-clone.el)
   3
   4 ;; Copyright (C) 1993-1994, 1999, 2001-2016 Free Software Foundation,
   5 ;; Inc.
   6
   7 ;; Author: David Megginson (dmeggins@aix1.uottawa.ca)
   8 ;; Maintainer: emacs-devel@gnu.org
   9 ;; Keywords: extensions
  10 ;; Package: emacs
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26 \f
  27 ;;; Commentary:
  28
  29 ;; GNU Emacs is already, in a sense, object oriented -- each object
  30 ;; (buffer) belongs to a class (major mode), and that class defines
  31 ;; the relationship between messages (input events) and methods
  32 ;; (commands) by means of a keymap.
  33 ;;
  34 ;; The only thing missing is a good scheme of inheritance.  It is
  35 ;; possible to simulate a single level of inheritance with generous
  36 ;; use of hooks and a bit of work -- sgml-mode, for example, also runs
  37 ;; the hooks for text-mode, and keymaps can inherit from other keymaps
  38 ;; -- but generally, each major mode ends up reinventing the wheel.
  39 ;; Ideally, someone should redesign all of Emacs's major modes to
  40 ;; follow a more conventional object-oriented system: when defining a
  41 ;; new major mode, the user should need only to name the existing mode
  42 ;; it is most similar to, then list the (few) differences.
  43 ;;
  44 ;; In the mean time, this package offers most of the advantages of
  45 ;; full inheritance with the existing major modes.  The macro
  46 ;; `define-derived-mode' allows the user to make a variant of an existing
  47 ;; major mode, with its own keymap.  The new mode will inherit the key
  48 ;; bindings of its parent, and will, in fact, run its parent first
  49 ;; every time it is called.  For example, the commands
  50 ;;
  51 ;;  (define-derived-mode hypertext-mode text-mode "Hypertext"
  52 ;;    "Major mode for hypertext.\n\n\\{hypertext-mode-map}"
  53 ;;    (setq case-fold-search nil))
  54 ;;
  55 ;;  (define-key hypertext-mode-map [down-mouse-3] 'do-hyper-link)
  56 ;;
  57 ;; will create a function `hypertext-mode' with its own (sparse)
  58 ;; keymap `hypertext-mode-map.'  The command M-x hypertext-mode will
  59 ;; perform the following actions:
  60 ;;
  61 ;; - run the command (text-mode) to get its default setup
  62 ;; - replace the current keymap with 'hypertext-mode-map,' which will
  63 ;;   inherit from 'text-mode-map'.
  64 ;; - replace the current syntax table with
  65 ;;   'hypertext-mode-syntax-table', which will borrow its defaults
  66 ;;   from the current text-mode-syntax-table.
  67 ;; - replace the current abbrev table with
  68 ;;   'hypertext-mode-abbrev-table', which will borrow its defaults
  69 ;;   from the current text-mode-abbrev table
  70 ;; - change the mode line to read "Hypertext"
  71 ;; - assign the value 'hypertext-mode' to the 'major-mode' variable
  72 ;; - run the body of commands provided in the macro -- in this case,
  73 ;;   set the local variable `case-fold-search' to nil.
  74 ;;
  75 ;; The advantages of this system are threefold.  First, text mode is
  76 ;; untouched -- if you had added the new keystroke to `text-mode-map,'
  77 ;; possibly using hooks, you would have added it to all text buffers
  78 ;; -- here, it appears only in hypertext buffers, where it makes
  79 ;; sense.  Second, it is possible to build even further, and make
  80 ;; a derived mode from a derived mode.  The commands
  81 ;;
  82 ;;   (define-derived-mode html-mode hypertext-mode "HTML")
  83 ;;   [various key definitions]
  84 ;;
  85 ;; will add a new major mode for HTML with very little fuss.
  86 ;;
  87 ;; Note also the function `derived-mode-p' which can tell if the current
  88 ;; mode derives from another.  In a hypertext-mode, buffer, for example,
  89 ;; (derived-mode-p 'text-mode) would return non-nil.  This should always
  90 ;; be used in place of (eq major-mode 'text-mode).
  91 \f
  92 ;;; Code:
  93
  94 ;;; PRIVATE: defsubst must be defined before they are first used
  95
  96 (defsubst derived-mode-hook-name (mode)
  97   "Construct a mode-hook name based on a MODE name."
  98   (intern (concat (symbol-name mode) "-hook")))
  99
 100 (defsubst derived-mode-map-name (mode)
 101   "Construct a map name based on a MODE name."
 102   (intern (concat (symbol-name mode) "-map")))
 103
 104 (defsubst derived-mode-syntax-table-name (mode)
 105   "Construct a syntax-table name based on a MODE name."
 106   (intern (concat (symbol-name mode) "-syntax-table")))
 107
 108 (defsubst derived-mode-abbrev-table-name (mode)
 109   "Construct an abbrev-table name based on a MODE name."
 110   (intern (concat (symbol-name mode) "-abbrev-table")))
 111
 112 ;; PUBLIC: define a new major mode which inherits from an existing one.
 113
 114 ;;;###autoload
 115 (defmacro define-derived-mode (child parent name &optional docstring &rest body)
 116   "Create a new mode as a variant of an existing mode.
 117
 118 The arguments to this command are as follow:
 119
 120 CHILD:     the name of the command for the derived mode.
 121 PARENT:    the name of the command for the parent mode (e.g. `text-mode')
 122            or nil if there is no parent.
 123 NAME:      a string which will appear in the status line (e.g. \"Hypertext\")
 124 DOCSTRING: an optional documentation string--if you do not supply one,
 125            the function will attempt to invent something useful.
 126 BODY:      forms to execute just before running the
 127            hooks for the new mode.  Do not use `interactive' here.
 128
 129 BODY can start with a bunch of keyword arguments.  The following keyword
 130   arguments are currently understood:
 131 :group GROUP
 132         Declare the customization group that corresponds to this mode.
 133         The command `customize-mode' uses this.
 134 :syntax-table TABLE
 135         Use TABLE instead of the default (CHILD-syntax-table).
 136         A nil value means to simply use the same syntax-table as the parent.
 137 :abbrev-table TABLE
 138         Use TABLE instead of the default (CHILD-abbrev-table).
 139         A nil value means to simply use the same abbrev-table as the parent.
 140 :after-hook FORM
 141         A single lisp form which is evaluated after the mode hooks have been
 142         run.  It should not be quoted.
 143
 144 Here is how you could define LaTeX-Thesis mode as a variant of LaTeX mode:
 145
 146   (define-derived-mode LaTeX-thesis-mode LaTeX-mode \"LaTeX-Thesis\")
 147
 148 You could then make new key bindings for `LaTeX-thesis-mode-map'
 149 without changing regular LaTeX mode.  In this example, BODY is empty,
 150 and DOCSTRING is generated by default.
 151
 152 On a more complicated level, the following command uses `sgml-mode' as
 153 the parent, and then sets the variable `case-fold-search' to nil:
 154
 155   (define-derived-mode article-mode sgml-mode \"Article\"
 156     \"Major mode for editing technical articles.\"
 157     (setq case-fold-search nil))
 158
 159 Note that if the documentation string had been left out, it would have
 160 been generated automatically, with a reference to the keymap.
 161
 162 The new mode runs the hook constructed by the function
 163 `derived-mode-hook-name'.
 164
 165 See Info node `(elisp)Derived Modes' for more details."
 166   (declare (debug (&define name symbolp sexp [&optional stringp]
 167                            [&rest keywordp sexp] def-body))
 168            (doc-string 4)
 169            ;; Ask not what
 170            ;;(indent 3)
 171            ;; can do for you, ask what it can do to others. IOW, the
 172            ;; missing of indentation setting here is the indentation
 173            ;; setting and not an oversight.
 174            )
 175
 176   (when (and docstring (not (stringp docstring)))
 177     ;; Some trickiness, since what appears to be the docstring may really be
 178     ;; the first element of the body.
 179     (push docstring body)
 180     (setq docstring nil))
 181
 182   (when (eq parent 'fundamental-mode) (setq parent nil))
 183
 184   (let ((map (derived-mode-map-name child))
 185         (syntax (derived-mode-syntax-table-name child))
 186         (abbrev (derived-mode-abbrev-table-name child))
 187         (declare-abbrev t)
 188         (declare-syntax t)
 189         (hook (derived-mode-hook-name child))
 190         (group nil)
 191         (after-hook nil))
 192
 193     ;; Process the keyword args.
 194     (while (keywordp (car body))
 195       (pcase (pop body)
 196         (`:group (setq group (pop body)))
 197         (`:abbrev-table (setq abbrev (pop body)) (setq declare-abbrev nil))
 198         (`:syntax-table (setq syntax (pop body)) (setq declare-syntax nil))
 199         (`:after-hook (setq after-hook (pop body)))
 200         (_ (pop body))))
 201
 202     (setq docstring (derived-mode-make-docstring
 203                      parent child docstring syntax abbrev))
 204
 205     `(progn
 206        (defvar ,hook nil
 207          ,(format "Hook run after entering %s mode.
 208 No problems result if this variable is not bound.
 209 `add-hook' automatically binds it.  (This is true for all hook variables.)"
 210                   name))
 211        (unless (boundp ',map)
 212          (put ',map 'definition-name ',child))
 213        (with-no-warnings (defvar ,map (make-sparse-keymap)))
 214        (unless (get ',map 'variable-documentation)
 215          (put ',map 'variable-documentation
 216               (purecopy ,(format "Keymap for `%s'." child))))
 217        ,(if declare-syntax
 218             `(progn
 219                (unless (boundp ',syntax)
 220                  (put ',syntax 'definition-name ',child))
 221                (defvar ,syntax (make-syntax-table))
 222                (unless (get ',syntax 'variable-documentation)
 223                  (put ',syntax 'variable-documentation
 224                       (purecopy ,(format "Syntax table for `%s'." child))))))
 225        ,(if declare-abbrev
 226             `(progn
 227                (put ',abbrev 'definition-name ',child)
 228                (defvar ,abbrev
 229                  (progn (define-abbrev-table ',abbrev nil) ,abbrev))
 230                (unless (get ',abbrev 'variable-documentation)
 231                  (put ',abbrev 'variable-documentation
 232                       (purecopy ,(format "Abbrev table for `%s'." child))))))
 233        (put ',child 'derived-mode-parent ',parent)
 234        ,(if group `(put ',child 'custom-mode-group ,group))
 235
 236        (defun ,child ()
 237          ,docstring
 238          (interactive)
 239                                         ; Run the parent.
 240          (delay-mode-hooks
 241
 242           (,(or parent 'kill-all-local-variables))
 243                                         ; Identify the child mode.
 244           (setq major-mode (quote ,child))
 245           (setq mode-name ,name)
 246                                         ; Identify special modes.
 247           ,(when parent
 248              `(progn
 249                 (if (get (quote ,parent) 'mode-class)
 250                     (put (quote ,child) 'mode-class
 251                          (get (quote ,parent) 'mode-class)))
 252                                         ; Set up maps and tables.
 253                 (unless (keymap-parent ,map)
 254                   ;; It would probably be better to set the keymap's parent
 255                   ;; at the toplevel rather than inside the mode function,
 256                   ;; but this is not easy for at least the following reasons:
 257                   ;; - the parent (and its keymap) may not yet be loaded.
 258                   ;; - the parent's keymap name may be called something else
 259                   ;;   than <parent>-mode-map.
 260                   (set-keymap-parent ,map (current-local-map)))
 261                 ,(when declare-syntax
 262                    `(let ((parent (char-table-parent ,syntax)))
 263                       (unless (and parent
 264                                    (not (eq parent (standard-syntax-table))))
 265                         (set-char-table-parent ,syntax (syntax-table)))))
 266                 ,(when declare-abbrev
 267                    `(unless (or (abbrev-table-get ,abbrev :parents)
 268                                 ;; This can happen if the major mode defines
 269                                 ;; the abbrev-table to be its parent's.
 270                                 (eq ,abbrev local-abbrev-table))
 271                       (abbrev-table-put ,abbrev :parents
 272                                         (list local-abbrev-table))))))
 273           (use-local-map ,map)
 274           ,(when syntax `(set-syntax-table ,syntax))
 275           ,(when abbrev `(setq local-abbrev-table ,abbrev))
 276                                         ; Splice in the body (if any).
 277           ,@body
 278           )
 279          ;; Run the hooks, if any.
 280          (run-mode-hooks ',hook)
 281          ,@(when after-hook
 282              `((if delay-mode-hooks
 283                    (push ',after-hook delayed-after-hook-forms)
 284                  ,after-hook)))))))
 285
 286 ;; PUBLIC: find the ultimate class of a derived mode.
 287
 288 (defun derived-mode-class (mode)
 289   "Find the class of a major MODE.
 290 A mode's class is the first ancestor which is NOT a derived mode.
 291 Use the `derived-mode-parent' property of the symbol to trace backwards.
 292 Since major-modes might all derive from `fundamental-mode', this function
 293 is not very useful."
 294   (declare (obsolete derived-mode-p "22.1"))
 295   (while (get mode 'derived-mode-parent)
 296     (setq mode (get mode 'derived-mode-parent)))
 297   mode)
 298
 299 \f
 300 ;;; PRIVATE
 301
 302 (defun derived-mode-make-docstring (parent child &optional
 303                                            docstring syntax abbrev)
 304   "Construct a docstring for a new mode if none is provided."
 305
 306   (let ((map (derived-mode-map-name child))
 307         (hook (derived-mode-hook-name child)))
 308
 309     (unless (stringp docstring)
 310       ;; Use a default docstring.
 311       (setq docstring
 312             (if (null parent)
 313                 ;; FIXME filling.
 314                 (format "Major-mode.\nUses keymap `%s'%s%s." map
 315                         (if abbrev (format "%s abbrev table `%s'"
 316                                            (if syntax "," " and") abbrev) "")
 317                         (if syntax (format " and syntax-table `%s'" syntax) ""))
 318               (format "Major mode derived from `%s' by `define-derived-mode'.
 319 It inherits all of the parent's attributes, but has its own keymap%s:
 320
 321   `%s'%s
 322
 323 which more-or-less shadow%s %s's corresponding table%s."
 324                       parent
 325                       (cond ((and abbrev syntax)
 326                              ",\nabbrev table and syntax table")
 327                             (abbrev "\nand abbrev table")
 328                             (syntax "\nand syntax table")
 329                             (t ""))
 330                       map
 331                       (cond ((and abbrev syntax)
 332                              (format ", `%s' and `%s'" abbrev syntax))
 333                             ((or abbrev syntax)
 334                              (format " and `%s'" (or abbrev syntax)))
 335                             (t ""))
 336                       (if (or abbrev syntax) "" "s")
 337                       parent
 338                       (if (or abbrev syntax) "s" "")))))
 339
 340     (unless (string-match (regexp-quote (symbol-name hook)) docstring)
 341       ;; Make sure the docstring mentions the mode's hook.
 342       (setq docstring
 343             (concat docstring
 344                     (if (null parent)
 345                         "\n\nThis mode "
 346                       (concat
 347                        "\n\nIn addition to any hooks its parent mode "
 348                        (if (string-match (format "[`‘]%s['’]"
 349                                                  (regexp-quote
 350                                                   (symbol-name parent)))
 351                                          docstring)
 352                            nil
 353                          (format "`%s' " parent))
 354                        "might have run,\nthis mode "))
 355                     (format "runs the hook `%s'" hook)
 356                     ", as the final or penultimate step\nduring initialization.")))
 357
 358     (unless (string-match "\\\\[{[]" docstring)
 359       ;; And don't forget to put the mode's keymap.
 360       (setq docstring (concat docstring "\n\n\\{" (symbol-name map) "}")))
 361
 362     docstring))
 363
 364 \f
 365 ;;; OBSOLETE
 366 ;; The functions below are only provided for backward compatibility with
 367 ;; code byte-compiled with versions of derived.el prior to Emacs-21.
 368
 369 (defsubst derived-mode-setup-function-name (mode)
 370   "Construct a setup-function name based on a MODE name."
 371   (intern (concat (symbol-name mode) "-setup")))
 372
 373 \f
 374 ;; Utility functions for defining a derived mode.
 375
 376 ;;;###autoload
 377 (defun derived-mode-init-mode-variables (mode)
 378   "Initialize variables for a new MODE.
 379 Right now, if they don't already exist, set up a blank keymap, an
 380 empty syntax table, and an empty abbrev table -- these will be merged
 381 the first time the mode is used."
 382
 383   (if (boundp (derived-mode-map-name mode))
 384       t
 385     (eval `(defvar ,(derived-mode-map-name mode)
 386                (make-sparse-keymap)
 387                ,(format "Keymap for %s." mode)))
 388     (put (derived-mode-map-name mode) 'derived-mode-unmerged t))
 389
 390   (if (boundp (derived-mode-syntax-table-name mode))
 391       t
 392     (eval `(defvar ,(derived-mode-syntax-table-name mode)
 393              ;; Make a syntax table which doesn't specify anything
 394              ;; for any char.  Valid data will be merged in by
 395              ;; derived-mode-merge-syntax-tables.
 396              (make-char-table 'syntax-table nil)
 397              ,(format "Syntax table for %s." mode)))
 398     (put (derived-mode-syntax-table-name mode) 'derived-mode-unmerged t))
 399
 400   (if (boundp (derived-mode-abbrev-table-name mode))
 401       t
 402     (eval `(defvar ,(derived-mode-abbrev-table-name mode)
 403              (progn
 404                (define-abbrev-table (derived-mode-abbrev-table-name mode) nil)
 405                (make-abbrev-table))
 406              ,(format "Abbrev table for %s." mode)))))
 407 \f
 408 ;; Utility functions for running a derived mode.
 409
 410 (defun derived-mode-set-keymap (mode)
 411   "Set the keymap of the new MODE, maybe merging with the parent."
 412   (let* ((map-name (derived-mode-map-name mode))
 413          (new-map (eval map-name))
 414          (old-map (current-local-map)))
 415     (and old-map
 416          (get map-name 'derived-mode-unmerged)
 417          (derived-mode-merge-keymaps old-map new-map))
 418     (put map-name 'derived-mode-unmerged nil)
 419     (use-local-map new-map)))
 420
 421 (defun derived-mode-set-syntax-table (mode)
 422   "Set the syntax table of the new MODE, maybe merging with the parent."
 423   (let* ((table-name (derived-mode-syntax-table-name mode))
 424          (old-table (syntax-table))
 425          (new-table (eval table-name)))
 426     (if (get table-name 'derived-mode-unmerged)
 427         (derived-mode-merge-syntax-tables old-table new-table))
 428     (put table-name 'derived-mode-unmerged nil)
 429     (set-syntax-table new-table)))
 430
 431 (defun derived-mode-set-abbrev-table (mode)
 432   "Set the abbrev table for MODE if it exists.
 433 Always merge its parent into it, since the merge is non-destructive."
 434   (let* ((table-name (derived-mode-abbrev-table-name mode))
 435          (old-table local-abbrev-table)
 436          (new-table (eval table-name)))
 437     (derived-mode-merge-abbrev-tables old-table new-table)
 438     (setq local-abbrev-table new-table)))
 439
 440 (defun derived-mode-run-hooks (mode)
 441    "Run the mode hook for MODE."
 442    (let ((hooks-name (derived-mode-hook-name mode)))
 443      (if (boundp hooks-name)
 444          (run-hooks hooks-name))))
 445
 446 ;; Functions to merge maps and tables.
 447
 448 (defun derived-mode-merge-keymaps (old new)
 449   "Merge an OLD keymap into a NEW one.
 450 The old keymap is set to be the last cdr of the new one, so that there will
 451 be automatic inheritance."
 452   ;; ?? Can this just use `set-keymap-parent'?
 453   (let ((tail new))
 454     ;; Scan the NEW map for prefix keys.
 455     (while (consp tail)
 456       (and (consp (car tail))
 457            (let* ((key (vector (car (car tail))))
 458                   (subnew (lookup-key new key))
 459                   (subold (lookup-key old key)))
 460              ;; If KEY is a prefix key in both OLD and NEW, merge them.
 461              (and (keymapp subnew) (keymapp subold)
 462                   (derived-mode-merge-keymaps subold subnew))))
 463       (and (vectorp (car tail))
 464            ;; Search a vector of ASCII char bindings for prefix keys.
 465            (let ((i (1- (length (car tail)))))
 466              (while (>= i 0)
 467                (let* ((key (vector i))
 468                       (subnew (lookup-key new key))
 469                       (subold (lookup-key old key)))
 470                  ;; If KEY is a prefix key in both OLD and NEW, merge them.
 471                  (and (keymapp subnew) (keymapp subold)
 472                       (derived-mode-merge-keymaps subold subnew)))
 473                (setq i (1- i)))))
 474       (setq tail (cdr tail))))
 475   (setcdr (nthcdr (1- (length new)) new) old))
 476
 477 (defun derived-mode-merge-syntax-tables (old new)
 478   "Merge an OLD syntax table into a NEW one.
 479 Where the new table already has an entry, nothing is copied from the old one."
 480   (set-char-table-parent new old))
 481
 482 ;; Merge an old abbrev table into a new one.
 483 ;; This function requires internal knowledge of how abbrev tables work,
 484 ;; presuming that they are obarrays with the abbrev as the symbol, the expansion
 485 ;; as the value of the symbol, and the hook as the function definition.
 486 (defun derived-mode-merge-abbrev-tables (old new)
 487   (if old
 488       (mapatoms
 489        (lambda (symbol)
 490          (or (intern-soft (symbol-name symbol) new)
 491              (define-abbrev new (symbol-name symbol)
 492                (symbol-value symbol) (symbol-function symbol))))
 493        old)))
 494
 495 (provide 'derived)
 496
 497 ;;; derived.el ends here