code.delx.au - gnu-emacs/blob - lisp/textmodes/flyspell.el

   1 ;;; flyspell.el --- On-the-fly spell checker
   2
   3 ;; Copyright (C) 1998 Free Software Foundation, Inc.
   4
   5 ;; Author: Manuel Serrano <Manuel.Serrano@unice.fr>
   6 ;; Keywords: convenience
   7
   8 ;;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; commentary:
  26 ;;
  27 ;; Flyspell is a minor Emacs mode performing on-the-fly spelling
  28 ;; checking.
  29 ;;
  30 ;; To enable Flyspell minor mode, type Meta-x flyspell-mode.
  31 ;; This applies only to the current buffer.
  32 ;;
  33 ;; Note: consider setting the variable ispell-parser to `tex' to
  34 ;; avoid TeX command checking; use `(setq ispell-parser 'tex)'
  35 ;; _before_ entering flyspell.
  36 ;;
  37 ;; Some user variables control the behavior of flyspell.  They are
  38 ;; those defined under the `User variables' comment.
  39 ;;
  40 ;; Note: as suggested by Yaron M. Minsky, if you use flyspell when
  41 ;; sending mails, you should add the following:
  42 ;;    (add-hook 'mail-send-hook 'flyspell-mode-off)
  43
  44 ;;; Code:
  45 (require 'ispell)
  46
  47 ;*---------------------------------------------------------------------*/
  48 ;*    Group ...                                                        */
  49 ;*---------------------------------------------------------------------*/
  50 (defgroup flyspell nil
  51   "Spellchecking on the fly."
  52   :tag "FlySpell"
  53   :prefix "flyspell-"
  54   :group 'processes
  55   :version "20.3")
  56
  57 ;*---------------------------------------------------------------------*/
  58 ;*    User variables ...                                               */
  59 ;*---------------------------------------------------------------------*/
  60 (defcustom flyspell-highlight-flag t
  61   "*How Flyspell should indicate misspelled words.
  62 Non-nil means use highlight, nil means use minibuffer messages."
  63   :group 'flyspell
  64   :type 'boolean)
  65
  66 (defcustom flyspell-mark-duplications-flag t
  67   "*Non-nil means Flyspell reports a repeated word as an error."
  68   :group 'flyspell
  69   :type 'boolean)
  70
  71 (defcustom flyspell-sort-corrections t
  72   "*Non-nil means, sort the corrections alphabetically before popping them."
  73   :group 'flyspell
  74   :type 'boolean)
  75
  76 (defcustom flyspell-duplicate-distance 10000
  77   "*The maximum distance for finding duplicates of unrecognized words.
  78 This applies to the feature that when a word is not found in the dictionary,
  79 if the same spelling occurs elsewhere in the buffer,
  80 Flyspell uses a different face (`flyspell-duplicate-face') to highlight it.
  81 This variable specifies how far to search to find such a duplicate.
  82 -1 means no limit (search the whole buffer).
  83 0 means do not search for duplicate unrecognized spellings."
  84   :group 'flyspell
  85   :type 'number)
  86
  87 (defcustom flyspell-delay 3
  88   "*The number of seconds to wait before checking, after a \"delayed\" command."
  89   :group 'flyspell
  90   :type 'number)
  91
  92 (defcustom flyspell-persistent-highlight t
  93   "*Non-nil means misspelled words remain highlighted until corrected.
  94 If this variable is nil, only the most recently detected misspelled word
  95 is highlighted."
  96   :group 'flyspell
  97   :type 'boolean)
  98
  99 (defcustom flyspell-highlight-properties t
 100   "*Non-nil means highlight incorrect words even if a property exists for this word."
 101   :group 'flyspell
 102   :type 'boolean)
 103
 104 (defcustom flyspell-default-delayed-commands
 105   '(self-insert-command
 106     delete-backward-char
 107     delete-char)
 108   "The standard list of delayed commands for Flyspell.
 109 See `flyspell-delayed-commands'."
 110   :group 'flyspell
 111   :type '(repeat (symbol)))
 112
 113 (defcustom flyspell-delayed-commands nil
 114   "List of commands that are \"delayed\" for Flyspell mode.
 115 After these commands, Flyspell checking is delayed for a short time,
 116 whose length is specified by `flyspell-delay'."
 117   :group 'flyspell
 118   :type '(repeat (symbol)))
 119
 120 (defcustom flyspell-issue-welcome-flag t
 121   "*Non-nil means that Flyspell should display a welcome message when started."
 122   :group 'flyspell
 123   :type 'boolean)
 124
 125 (defcustom flyspell-consider-dash-as-word-delimiter-flag nil
 126   "*Non-nil means that the `-' char is considered as a word delimiter."
 127   :group 'flyspell
 128   :type 'boolean)
 129
 130 (defcustom flyspell-incorrect-hook nil
 131   "*List of functions to be called when incorrect words are encountered.
 132 Each function is given two arguments: the beginning and the end
 133 of the incorrect region."
 134   :group 'flyspell)
 135
 136 (defcustom flyspell-multi-language-p nil
 137   "*Non-nil means that Flyspell can be used with multiple languages.
 138 This mode works by starting a separate Ispell process for each buffer,
 139 so that each buffer can use its own language."
 140   :group 'flyspell
 141   :type 'boolean)
 142
 143 ;*---------------------------------------------------------------------*/
 144 ;*    Mode specific options                                            */
 145 ;*    -------------------------------------------------------------    */
 146 ;*    Mode specific options enable users to disable flyspell on        */
 147 ;*    certain word depending of the emacs mode. For instance, when     */
 148 ;*    using flyspell with mail-mode add the following expression       */
 149 ;*    in your .emacs file:                                             */
 150 ;*       (add-hook 'mail-mode                                          */
 151 ;*           '(lambda () (setq flyspell-generic-check-word-p           */
 152 ;*                             'mail-mode-flyspell-verify)))           */
 153 ;*---------------------------------------------------------------------*/
 154 (defvar flyspell-generic-check-word-p nil
 155   "Function providing per-mode customization over which words are flyspelled.
 156 Returns t to continue checking, nil otherwise.
 157 Flyspell mode sets this variable to whatever is the `flyspell-mode-predicate'
 158 property of the major mode name.")
 159 (make-variable-buffer-local 'flyspell-generic-check-word-p)
 160
 161 (put 'mail-mode 'flyspell-mode-predicate 'mail-mode-flyspell-verify)
 162 (put 'message-mode 'flyspell-mode-predicate 'mail-mode-flyspell-verify)
 163 (defun mail-mode-flyspell-verify ()
 164   "This function is used for `flyspell-generic-check-word-p' in Mail mode."
 165   (save-excursion
 166     (or (progn
 167           (beginning-of-line)
 168           (looking-at "Subject:"))
 169         (not (or (re-search-forward mail-header-separator nil t)
 170                  (re-search-backward message-signature-separator nil t)
 171                  (progn
 172                    (beginning-of-line)
 173                    (looking-at "[>}|]")))))))
 174
 175 (put 'texinfo-mode 'flyspell-mode-predicate 'texinfo-mode-flyspell-verify)
 176 (defun texinfo-mode-flyspell-verify ()
 177   "This function is used for `flyspell-generic-check-word-p' in Texinfo mode."
 178   (save-excursion
 179     (forward-word -1)
 180     (not (looking-at "@"))))
 181
 182 ;*---------------------------------------------------------------------*/
 183 ;*    Overlay compatibility                                            */
 184 ;*---------------------------------------------------------------------*/
 185 (autoload 'make-overlay        "overlay" "" t)
 186 (autoload 'move-overlay        "overlay" "" t)
 187 (autoload 'overlayp            "overlay" "" t)
 188 (autoload 'overlay-properties  "overlay" "" t)
 189 (autoload 'overlays-in         "overlay" "" t)
 190 (autoload 'delete-overlay      "overlay" "" t)
 191 (autoload 'overlays-at         "overlay" "" t)
 192 (autoload 'overlay-put         "overlay" "" t)
 193 (autoload 'overlay-get         "overlay" "" t)
 194
 195 ;*---------------------------------------------------------------------*/
 196 ;*    Which emacs are we currently running                             */
 197 ;*---------------------------------------------------------------------*/
 198 (defvar flyspell-emacs
 199   (cond
 200    ((string-match "XEmacs" emacs-version)
 201     'xemacs)
 202    (t
 203     'emacs))
 204   "The type of Emacs we are currently running.")
 205
 206 (defvar flyspell-use-local-map
 207   (or (eq flyspell-emacs 'xemacs)
 208       (not (string< emacs-version "20"))))
 209
 210 ;*---------------------------------------------------------------------*/
 211 ;*    The minor mode declaration.                                      */
 212 ;*---------------------------------------------------------------------*/
 213 (defvar flyspell-mode nil)
 214 (make-variable-buffer-local 'flyspell-mode)
 215
 216 (defvar flyspell-mode-map (make-sparse-keymap))
 217 (defvar flyspell-mouse-map (make-sparse-keymap))
 218
 219 (or (assoc 'flyspell-mode minor-mode-alist)
 220     (setq minor-mode-alist
 221           (cons '(flyspell-mode " Fly") minor-mode-alist)))
 222
 223 ;; mouse or local-map bindings
 224 (cond
 225  ((eq flyspell-emacs 'xemacs)
 226   (define-key flyspell-mouse-map [(button2)]
 227     (function flyspell-correct-word/mouse-keymap))
 228   (define-key flyspell-mouse-map "\M-\t" 'flyspell-auto-correct-word))
 229  (flyspell-use-local-map
 230   (define-key flyspell-mouse-map [(mouse-2)]
 231     (function flyspell-correct-word/mouse-keymap))
 232   (define-key flyspell-mouse-map "\M-\t" 'flyspell-auto-correct-word))
 233  (t
 234   (or (assoc 'flyspell-mode minor-mode-map-alist)
 235       (setq minor-mode-map-alist
 236           (cons (cons 'flyspell-mode flyspell-mode-map)
 237                 minor-mode-map-alist)))
 238   (define-key flyspell-mode-map "\M-\t" 'flyspell-auto-correct-word)
 239   (define-key flyspell-mode-map [(mouse-2)]
 240     (function flyspell-correct-word/local-keymap))))
 241
 242 ;; the name of the overlay property that defines the keymap
 243 (defvar flyspell-overlay-keymap-property-name
 244   (if (string-match "19.*XEmacs" emacs-version)
 245       'keymap
 246     'local-map))
 247
 248 ;*---------------------------------------------------------------------*/
 249 ;*    Highlighting                                                     */
 250 ;*---------------------------------------------------------------------*/
 251 (defface flyspell-incorrect-face
 252   '((((class color)) (:foreground "OrangeRed" :bold t :underline t))
 253     (t (:bold t)))
 254   "Face used for marking a misspelled word in Flyspell."
 255   :group 'flyspell)
 256
 257 (defface flyspell-duplicate-face
 258   '((((class color)) (:foreground "Gold3" :bold t :underline t))
 259     (t (:bold t)))
 260   "Face used for marking a misspelled word that appears twice in the buffer.
 261 See also `flyspell-duplicate-distance'."
 262   :group 'flyspell)
 263
 264 (defvar flyspell-overlay nil)
 265
 266 ;*---------------------------------------------------------------------*/
 267 ;*    flyspell-mode ...                                                */
 268 ;*---------------------------------------------------------------------*/
 269 ;;;###autoload
 270 (defun flyspell-mode (&optional arg)
 271   "Minor mode performing on-the-fly spelling checking.
 272 Ispell is automatically spawned on background for each entered words.
 273 The default flyspell behavior is to highlight incorrect words.
 274 With no argument, this command toggles Flyspell mode.
 275 With a prefix argument ARG, turn Flyspell minor mode on iff ARG is positive.
 276
 277 Bindings:
 278 \\[ispell-word]: correct words (using Ispell).
 279 \\[flyspell-auto-correct-word]: automatically correct word.
 280 \\[flyspell-correct-word] (or mouse-2): popup correct words.
 281
 282 Hooks:
 283 flyspell-mode-hook is run after flyspell is entered.
 284
 285 Remark:
 286 `flyspell-mode' uses `ispell-mode'.  Thus all Ispell options are
 287 valid.  For instance, a personal dictionary can be used by
 288 invoking `ispell-change-dictionary'.
 289
 290 Consider using the `ispell-parser' to check your text.  For instance
 291 consider adding:
 292 \(add-hook 'tex-mode-hook (function (lambda () (setq ispell-parser 'tex))))
 293 in your .emacs file.
 294
 295 flyspell-region checks all words inside a region.
 296
 297 flyspell-buffer checks the whole buffer."
 298   (interactive "P")
 299   (let ((old-flyspell-mode flyspell-mode))
 300     ;; Mark the mode as on or off.
 301     (setq flyspell-mode (not (or (and (null arg) flyspell-mode)
 302                                  (<= (prefix-numeric-value arg) 0))))
 303     ;; Do the real work.
 304     (unless (eq flyspell-mode old-flyspell-mode)
 305       (if flyspell-mode
 306           (flyspell-mode-on)
 307         (flyspell-mode-off))
 308       ;; Force modeline redisplay.
 309       (set-buffer-modified-p (buffer-modified-p)))))
 310
 311 ;*---------------------------------------------------------------------*/
 312 ;*    flyspell-mode-on ...                                             */
 313 ;*---------------------------------------------------------------------*/
 314 (defun flyspell-mode-on ()
 315   "Turn Flyspell mode on.  Do not use this; use `flyspell-mode' instead."
 316   (setq ispell-highlight-face 'flyspell-incorrect-face)
 317   ;; ispell initialization
 318   (if flyspell-multi-language-p
 319       (progn
 320         (make-variable-buffer-local 'ispell-dictionary)
 321         (make-variable-buffer-local 'ispell-process)
 322         (make-variable-buffer-local 'ispell-filter)
 323         (make-variable-buffer-local 'ispell-filter-continue)
 324         (make-variable-buffer-local 'ispell-process-directory)
 325         (make-variable-buffer-local 'ispell-parser)
 326         (put 'ispell-dictionary 'permanent-local t)
 327         (put 'ispell-process 'permanent-local t)
 328         (put 'ispell-filter 'permanent-local t)
 329         (put 'ispell-filter-continue 'permanent-local t)
 330         (put 'ispell-process-directory 'permanent-local t)
 331         (put 'ispell-parser 'permanent-local t)))
 332   ;; We put the `flyspell-delayed' property on some commands.
 333   (flyspell-delay-commands)
 334   ;; we bound flyspell action to post-command hook
 335   (make-local-hook 'post-command-hook)
 336   (add-hook 'post-command-hook (function flyspell-post-command-hook) t t)
 337   ;; we bound flyspell action to pre-command hook
 338   (make-local-hook 'pre-command-hook)
 339   (add-hook 'pre-command-hook (function flyspell-pre-command-hook) t t)
 340
 341   ;; Set flyspell-generic-check-word-p based on the major mode.
 342   (let ((mode-predicate (get major-mode 'flyspell-mode-predicate)))
 343     (if mode-predicate
 344         (setq flyspell-generic-check-word-p mode-predicate)))
 345
 346   ;; the welcome message
 347   (if flyspell-issue-welcome-flag
 348       (let ((binding (where-is-internal 'flyspell-auto-correct-word
 349                                         nil 'non-ascii)))
 350         (message
 351          (if binding
 352              (format "Welcome to flyspell.  Use %s or Mouse-2 to correct words."
 353                      (key-description binding))
 354            "Welcome to flyspell.  Use Mouse-2 to correct words."))))
 355   ;; we have to kill the flyspell process when the buffer is deleted.
 356   ;; (thanks to Jeff Miller and Roland Rosenfeld who sent me this
 357   ;; improvement).
 358   (add-hook 'kill-buffer-hook
 359             '(lambda ()
 360                (if (and flyspell-multi-language-p ispell-process)
 361                    (ispell-kill-ispell t))))
 362   (make-local-hook 'change-major-mode-hook)
 363   (add-hook 'change-major-mode-hook 'flyspell-mode-off)
 364   ;; we end with the flyspell hooks
 365   (run-hooks 'flyspell-mode-hook))
 366
 367 ;*---------------------------------------------------------------------*/
 368 ;*    flyspell-delay-commands ...                                      */
 369 ;*---------------------------------------------------------------------*/
 370 (defun flyspell-delay-commands ()
 371   "Install the standard set of Flyspell delayed commands."
 372   (mapcar 'flyspell-delay-command flyspell-default-delayed-commands)
 373   (mapcar 'flyspell-delay-command flyspell-delayed-commands))
 374
 375 ;*---------------------------------------------------------------------*/
 376 ;*    flyspell-delay-command ...                                       */
 377 ;*---------------------------------------------------------------------*/
 378 (defun flyspell-delay-command (command)
 379   "Set COMMAND to be delayed, for Flyspell.
 380 When flyspell `post-command-hook' is invoked because a delayed command
 381 as been used the current word is not immediatly checked.
 382 It will be checked only after `flyspell-delay' seconds."
 383   (interactive "SDelay Flyspell after Command: ")
 384   (put command 'flyspell-delayed t))
 385
 386 ;*---------------------------------------------------------------------*/
 387 ;*    flyspell-ignore-commands ...                                     */
 388 ;*---------------------------------------------------------------------*/
 389 (defun flyspell-ignore-commands ()
 390   "This is an obsolete function, use `flyspell-delay-commands' instead."
 391   (flyspell-delay-commands))
 392
 393 ;*---------------------------------------------------------------------*/
 394 ;*    flyspell-ignore-command ...                                      */
 395 ;*---------------------------------------------------------------------*/
 396 (defun flyspell-ignore-command (command)
 397   "This is an obsolete function, use `flyspell-delay-command' instead.
 398 COMMAND is the name of the command to be delayed."
 399   (flyspell-delay-command command))
 400
 401 (make-obsolete 'flyspell-ignore-commands 'flyspell-delay-commands)
 402 (make-obsolete 'flyspell-ignore-command 'flyspell-delay-command)
 403
 404 ;*---------------------------------------------------------------------*/
 405 ;*    flyspell-word-cache ...                                          */
 406 ;*---------------------------------------------------------------------*/
 407 (defvar flyspell-word-cache-start  nil)
 408 (defvar flyspell-word-cache-end    nil)
 409 (defvar flyspell-word-cache-word   nil)
 410 (make-variable-buffer-local 'flyspell-word-cache-start)
 411 (make-variable-buffer-local 'flyspell-word-cache-end)
 412 (make-variable-buffer-local 'flyspell-word-cache-word)
 413
 414 ;*---------------------------------------------------------------------*/
 415 ;*    The flyspell pre-hook, store the current position. In the        */
 416 ;*    post command hook, we will check, if the word at this position   */
 417 ;*    has to be spell checked.                                         */
 418 ;*---------------------------------------------------------------------*/
 419 (defvar flyspell-pre-buffer nil)
 420 (defvar flyspell-pre-point  nil)
 421
 422 ;*---------------------------------------------------------------------*/
 423 ;*    flyspell-pre-command-hook ...                                    */
 424 ;*---------------------------------------------------------------------*/
 425 (defun flyspell-pre-command-hook ()
 426   "Save the current buffer and point for Flyspell's post-command hook."
 427   (interactive)
 428   (setq flyspell-pre-buffer (current-buffer))
 429   (setq flyspell-pre-point  (point)))
 430
 431 ;*---------------------------------------------------------------------*/
 432 ;*    flyspell-mode-off ...                                            */
 433 ;*---------------------------------------------------------------------*/
 434 ;;;###autoload
 435 (defun flyspell-mode-off ()
 436   "Turn Flyspell mode off."
 437   ;; If we have an Ispell process for each buffer,
 438   ;; kill the one for this buffer.
 439   (if flyspell-multi-language-p
 440       (ispell-kill-ispell t))
 441   ;; we remove the hooks
 442   (remove-hook 'post-command-hook (function flyspell-post-command-hook) t)
 443   (remove-hook 'pre-command-hook (function flyspell-pre-command-hook) t)
 444   ;; we remove all the flyspell hilightings
 445   (flyspell-delete-all-overlays)
 446   ;; we have to erase pre cache variables
 447   (setq flyspell-pre-buffer nil)
 448   (setq flyspell-pre-point  nil)
 449   ;; we mark the mode as killed
 450   (setq flyspell-mode nil))
 451
 452 ;*---------------------------------------------------------------------*/
 453 ;*    flyspell-check-word-p ...                                        */
 454 ;*---------------------------------------------------------------------*/
 455 (defun flyspell-check-word-p ()
 456   "Return t when the word at `point' has to be checked.
 457 The answer depends of several criteria.
 458 Mostly we check word delimiters."
 459   (cond
 460    ((<= (- (point-max) 1) (point-min))
 461     ;; the buffer is not filled enough
 462     nil)
 463    ((not (and (symbolp this-command) (get this-command 'flyspell-delayed)))
 464     ;; the current command is not delayed, that
 465     ;; is that we must check the word now
 466     t)
 467    ((and (> (point) (point-min))
 468          (save-excursion
 469            (backward-char 1)
 470            (and (looking-at (flyspell-get-not-casechars))
 471                 (or flyspell-consider-dash-as-word-delimiter-flag
 472                     (not (looking-at "\\-"))))))
 473     ;; yes because we have reached or typed a word delimiter.
 474     t)
 475    ((not (integerp flyspell-delay))
 476     ;; yes because the user had set up a no-delay configuration.
 477     t)
 478    (executing-kbd-macro
 479     ;; Don't delay inside a keyboard macro.
 480     t)
 481    (t
 482     (if (fboundp 'about-xemacs)
 483         (sit-for flyspell-delay nil)
 484       (sit-for flyspell-delay 0 nil)))))
 485
 486 ;*---------------------------------------------------------------------*/
 487 ;*    flyspell-check-pre-word-p ...                                    */
 488 ;*---------------------------------------------------------------------*/
 489 (defun flyspell-check-pre-word-p ()
 490   "Return non-nil if we should to check the word before point.
 491 More precisely, it applies to the word that was before point
 492 before the current command."
 493   (cond
 494    ((or (not (numberp flyspell-pre-point))
 495         (not (bufferp flyspell-pre-buffer))
 496         (not (buffer-live-p flyspell-pre-buffer)))
 497     nil)
 498    ((or (and (= flyspell-pre-point (- (point) 1))
 499              (eq (char-syntax (char-after flyspell-pre-point)) ?w))
 500         (= flyspell-pre-point (point))
 501         (= flyspell-pre-point (+ (point) 1)))
 502     nil)
 503    ((not (eq (current-buffer) flyspell-pre-buffer))
 504     t)
 505    ((not (and (numberp flyspell-word-cache-start)
 506               (numberp flyspell-word-cache-end)))
 507     t)
 508    (t
 509     (or (< flyspell-pre-point flyspell-word-cache-start)
 510         (> flyspell-pre-point flyspell-word-cache-end)))))
 511
 512 ;*---------------------------------------------------------------------*/
 513 ;*    flyspell-post-command-hook ...                                   */
 514 ;*---------------------------------------------------------------------*/
 515 (defun flyspell-post-command-hook ()
 516   "The `post-command-hook' used by flyspell to check a word in-the-fly."
 517   (interactive)
 518   (if (flyspell-check-word-p)
 519       (flyspell-word))
 520   (if (flyspell-check-pre-word-p)
 521       (save-excursion
 522         (set-buffer flyspell-pre-buffer)
 523         (save-excursion
 524           (goto-char flyspell-pre-point)
 525           (flyspell-word)))))
 526
 527 ;*---------------------------------------------------------------------*/
 528 ;*    flyspell-word ...                                                */
 529 ;*---------------------------------------------------------------------*/
 530 (defun flyspell-word (&optional following)
 531   "Spell check a word."
 532   (interactive (list current-prefix-arg))
 533   (if (interactive-p)
 534       (setq following ispell-following-word))
 535   (save-excursion
 536     (ispell-accept-buffer-local-defs)   ; use the correct dictionary
 537     (let ((cursor-location (point))     ; retain cursor location
 538           (word (flyspell-get-word following))
 539           start end poss)
 540       (if (or (eq word nil)
 541               (and (fboundp flyspell-generic-check-word-p)
 542                    (not (funcall flyspell-generic-check-word-p))))
 543           t
 544         (progn
 545           ;; destructure return word info list.
 546           (setq start (car (cdr word))
 547                 end (car (cdr (cdr word)))
 548                 word (car word))
 549           ;; before checking in the directory, we check for doublons.
 550           (cond
 551            ((and flyspell-mark-duplications-flag
 552                  (save-excursion
 553                    (goto-char start)
 554                    (word-search-backward word
 555                                          (- start
 556                                             (+ 1 (- end start)))
 557                                          t)))
 558             ;; yes, this is a doublon
 559             (flyspell-highlight-incorrect-region start end))
 560            ((and (eq flyspell-word-cache-start start)
 561                  (eq flyspell-word-cache-end end)
 562                  (string-equal flyspell-word-cache-word word))
 563             ;; this word had been already checked, we skip
 564             nil)
 565            ((and (eq ispell-parser 'tex)
 566                  (flyspell-tex-command-p word))
 567             ;; this is a correct word (because a tex command)
 568             (flyspell-unhighlight-at start)
 569             (if (> end start)
 570                 (flyspell-unhighlight-at (- end 1)))
 571             t)
 572            (t
 573             ;; we setup the cache
 574             (setq flyspell-word-cache-start start)
 575             (setq flyspell-word-cache-end end)
 576             (setq flyspell-word-cache-word word)
 577             ;; now check spelling of word.
 578             (process-send-string ispell-process "%\n")
 579             ;; put in verbose mode
 580             (process-send-string ispell-process
 581                                  (concat "^" word "\n"))
 582             ;; we mark the ispell process so it can be killed
 583             ;; when emacs is exited without query
 584             (if (fboundp 'process-kill-without-query)
 585                 (process-kill-without-query ispell-process))
 586             ;; wait until ispell has processed word
 587             (while (progn
 588                      (accept-process-output ispell-process)
 589                      (not (string= "" (car ispell-filter)))))
 590             ;; (process-send-string ispell-process "!\n")
 591             ;; back to terse mode.
 592             (setq ispell-filter (cdr ispell-filter))
 593             (if (listp ispell-filter)
 594                 (setq poss (ispell-parse-output (car ispell-filter))))
 595             (cond ((eq poss t)
 596                    ;; correct
 597                    (flyspell-unhighlight-at start)
 598                    (if (> end start)
 599                        (flyspell-unhighlight-at (- end 1)))
 600                    t)
 601                   ((and (stringp poss) flyspell-highlight-flag)
 602                    ;; correct
 603                    (flyspell-unhighlight-at start)
 604                    (if (> end start)
 605                        (flyspell-unhighlight-at (- end 1)))
 606                    t)
 607                   ((null poss)
 608                    (flyspell-unhighlight-at start)
 609                    (if (> end start)
 610                        (flyspell-unhighlight-at (- end 1)))
 611                    (message "Error in ispell process"))
 612                   ((or (and (< flyspell-duplicate-distance 0)
 613                             (or (save-excursion
 614                                   (goto-char start)
 615                                   (word-search-backward word
 616                                                         (point-min)
 617                                                         t))
 618                                 (save-excursion
 619                                   (goto-char end)
 620                                   (word-search-forward word
 621                                                        (point-max)
 622                                                        t))))
 623                        (and (> flyspell-duplicate-distance 0)
 624                             (or (save-excursion
 625                                   (goto-char start)
 626                                   (word-search-backward
 627                                    word
 628                                    (- start
 629                                       flyspell-duplicate-distance)
 630                                    t))
 631                                 (save-excursion
 632                                   (goto-char end)
 633                                   (word-search-forward
 634                                    word
 635                                    (+ end
 636                                       flyspell-duplicate-distance)
 637                                    t)))))
 638                    (if flyspell-highlight-flag
 639                        (flyspell-highlight-duplicate-region start end)
 640                      (message (format "duplicate `%s'" word))))
 641                   (t
 642                    ;; incorrect highlight the location
 643                    (if flyspell-highlight-flag
 644                        (flyspell-highlight-incorrect-region start end)
 645                      (message (format "mispelling `%s'" word)))))
 646             (goto-char cursor-location) ; return to original location
 647             (if ispell-quit (setq ispell-quit nil)))))))))
 648
 649 ;*---------------------------------------------------------------------*/
 650 ;*    flyspell-tex-command-p ...                                       */
 651 ;*---------------------------------------------------------------------*/
 652 (defun flyspell-tex-command-p (word)
 653   "Return t if WORD is a TeX command."
 654   (eq (aref word 0) ?\\))
 655
 656 ;*---------------------------------------------------------------------*/
 657 ;*    flyspell-casechars-cache ...                                     */
 658 ;*---------------------------------------------------------------------*/
 659 (defvar flyspell-casechars-cache nil)
 660 (defvar flyspell-ispell-casechars-cache nil)
 661 (make-variable-buffer-local 'flyspell-casechars-cache)
 662 (make-variable-buffer-local 'flyspell-ispell-casechars-cache)
 663
 664 ;*---------------------------------------------------------------------*/
 665 ;*    flyspell-get-casechars ...                                       */
 666 ;*---------------------------------------------------------------------*/
 667 (defun flyspell-get-casechars ()
 668   "This function builds a string that is the regexp of word chars.
 669 In order to avoid one useless string construction,
 670 this function changes the last char of the `ispell-casechars' string."
 671   (let ((ispell-casechars (ispell-get-casechars)))
 672     (cond
 673      ((eq ispell-casechars flyspell-ispell-casechars-cache)
 674       flyspell-casechars-cache)
 675      ((not (eq ispell-parser 'tex))
 676       (setq flyspell-ispell-casechars-cache ispell-casechars)
 677       (setq flyspell-casechars-cache
 678             (concat (substring ispell-casechars
 679                                0
 680                                (- (length ispell-casechars) 1))
 681                     "{}]"))
 682       flyspell-casechars-cache)
 683      (t
 684       (setq flyspell-ispell-casechars-cache ispell-casechars)
 685       (setq flyspell-casechars-cache ispell-casechars)
 686       flyspell-casechars-cache))))
 687
 688 ;*---------------------------------------------------------------------*/
 689 ;*    flyspell-get-not-casechars-cache ...                             */
 690 ;*---------------------------------------------------------------------*/
 691 (defvar flyspell-not-casechars-cache nil)
 692 (defvar flyspell-ispell-not-casechars-cache nil)
 693 (make-variable-buffer-local 'flyspell-not-casechars-cache)
 694 (make-variable-buffer-local 'flyspell-ispell-not-casechars-cache)
 695
 696 ;*---------------------------------------------------------------------*/
 697 ;*    flyspell-get-not-casechars ...                                   */
 698 ;*---------------------------------------------------------------------*/
 699 (defun flyspell-get-not-casechars ()
 700   "This function builds a string that is the regexp of non-word chars."
 701   (let ((ispell-not-casechars (ispell-get-not-casechars)))
 702     (cond
 703      ((eq ispell-not-casechars flyspell-ispell-not-casechars-cache)
 704       flyspell-not-casechars-cache)
 705      ((not (eq ispell-parser 'tex))
 706       (setq flyspell-ispell-not-casechars-cache ispell-not-casechars)
 707       (setq flyspell-not-casechars-cache
 708             (concat (substring ispell-not-casechars
 709                                0
 710                                (- (length ispell-not-casechars) 1))
 711                     "{}]"))
 712       flyspell-not-casechars-cache)
 713      (t
 714       (setq flyspell-ispell-not-casechars-cache ispell-not-casechars)
 715       (setq flyspell-not-casechars-cache ispell-not-casechars)
 716       flyspell-not-casechars-cache))))
 717
 718 ;*---------------------------------------------------------------------*/
 719 ;*    flyspell-get-word ...                                            */
 720 ;*---------------------------------------------------------------------*/
 721 (defun flyspell-get-word (following)
 722   "Return the word for spell-checking according to Ispell syntax.
 723 If optional argument FOLLOWING is non-nil or if `ispell-following-word'
 724 is non-nil when called interactively, then the following word
 725 \(rather than preceding\) is checked when the cursor is not over a word.
 726 Optional second argument contains otherchars that can be included in word
 727 many times.
 728
 729 Word syntax described by `ispell-dictionary-alist' (which see)."
 730   (let* ((flyspell-casechars (flyspell-get-casechars))
 731          (flyspell-not-casechars (flyspell-get-not-casechars))
 732          (ispell-otherchars (ispell-get-otherchars))
 733          (ispell-many-otherchars-p (ispell-get-many-otherchars-p))
 734          (word-regexp (concat flyspell-casechars
 735                               "+\\("
 736                               ispell-otherchars
 737                               "?"
 738                               flyspell-casechars
 739                               "+\\)"
 740                               (if ispell-many-otherchars-p
 741                                   "*" "?")))
 742          (tex-prelude "[\\\\{]")
 743          (tex-regexp  (if (eq ispell-parser 'tex)
 744                           (concat tex-prelude "?" word-regexp "}?")
 745                         word-regexp))
 746
 747          did-it-once
 748          start end word)
 749     ;; find the word
 750     (if (not (or (looking-at flyspell-casechars)
 751                  (and (eq ispell-parser 'tex)
 752                       (looking-at tex-prelude))))
 753         (if following
 754             (re-search-forward flyspell-casechars (point-max) t)
 755           (re-search-backward flyspell-casechars (point-min) t)))
 756     ;; move to front of word
 757     (re-search-backward flyspell-not-casechars (point-min) 'start)
 758     (let ((pos nil))
 759       (while (and (looking-at ispell-otherchars)
 760                   (not (bobp))
 761                   (or (not did-it-once)
 762                       ispell-many-otherchars-p)
 763                   (not (eq pos (point))))
 764         (setq pos (point))
 765         (setq did-it-once t)
 766         (backward-char 1)
 767         (if (looking-at flyspell-casechars)
 768             (re-search-backward flyspell-not-casechars (point-min) 'move)
 769           (backward-char -1))))
 770     ;; Now mark the word and save to string.
 771     (if (eq (re-search-forward tex-regexp (point-max) t) nil)
 772         nil
 773       (progn
 774         (setq start (match-beginning 0)
 775               end (point)
 776               word (buffer-substring start end))
 777         (list word start end)))))
 778
 779 ;*---------------------------------------------------------------------*/
 780 ;*    flyspell-region ...                                              */
 781 ;*---------------------------------------------------------------------*/
 782 (defun flyspell-region (beg end)
 783   "Flyspell text between BEG and END."
 784   (interactive "r")
 785   (save-excursion
 786   (if (> beg end)
 787       (let ((old beg))
 788         (setq beg end)
 789         (setq end old)))
 790     (goto-char beg)
 791     (let ((count 0))
 792       (while (< (point) end)
 793         (if (= count 100)
 794             (progn
 795               (message "Spell Checking...%d%%"
 796                        (* 100 (/ (float (- (point) beg)) (- end beg))))
 797               (setq count 0))
 798           (setq count (+ 1 count)))
 799         (flyspell-word)
 800         (let ((cur (point)))
 801           (forward-word 1)
 802           (if (and (< (point) end) (> (point) (+ cur 1)))
 803               (backward-char 1)))))
 804     (backward-char 1)
 805     (message "Spell Checking...done")
 806     (flyspell-word)))
 807
 808 ;*---------------------------------------------------------------------*/
 809 ;*    flyspell-buffer ...                                              */
 810 ;*---------------------------------------------------------------------*/
 811 (defun flyspell-buffer ()
 812   "Flyspell whole buffer."
 813   (interactive)
 814   (flyspell-region (point-min) (point-max)))
 815
 816 ;*---------------------------------------------------------------------*/
 817 ;*    flyspell-overlay-p ...                                           */
 818 ;*---------------------------------------------------------------------*/
 819 (defun flyspell-overlay-p (o)
 820   "A predicate that return true iff O is an overlay used by flyspell."
 821   (and (overlayp o) (overlay-get o 'flyspell-overlay)))
 822
 823 ;*---------------------------------------------------------------------*/
 824 ;*    flyspell-delete-all-overlays ...                                 */
 825 ;*    -------------------------------------------------------------    */
 826 ;*    Remove all the overlays introduced by flyspell.                  */
 827 ;*---------------------------------------------------------------------*/
 828 (defun flyspell-delete-all-overlays ()
 829   "Delete all the overlays used by flyspell."
 830   (let ((l (overlays-in (point-min) (point-max))))
 831     (while (consp l)
 832       (progn
 833         (if (flyspell-overlay-p (car l))
 834             (delete-overlay (car l)))
 835         (setq l (cdr l))))))
 836
 837 ;*---------------------------------------------------------------------*/
 838 ;*    flyspell-unhighlight-at ...                                      */
 839 ;*---------------------------------------------------------------------*/
 840 (defun flyspell-unhighlight-at (pos)
 841   "Remove the flyspell overlay that are located at POS."
 842   (if flyspell-persistent-highlight
 843       (let ((overlays (overlays-at pos)))
 844         (while (consp overlays)
 845           (if (flyspell-overlay-p (car overlays))
 846               (delete-overlay (car overlays)))
 847           (setq overlays (cdr overlays))))
 848     (delete-overlay flyspell-overlay)))
 849
 850 ;*---------------------------------------------------------------------*/
 851 ;*    flyspell-properties-at-p ...                                     */
 852 ;*    -------------------------------------------------------------    */
 853 ;*    Is there an highlight properties at position pos?                */
 854 ;*---------------------------------------------------------------------*/
 855 (defun flyspell-properties-at-p (pos)
 856   "Return t if there is a text property at POS, not counting `local-map'.
 857 If variable `flyspell-highlight-properties' is set to nil,
 858 text with properties are not checked.  This function is used to discover
 859 if the character at POS has any other property."
 860   (let ((prop (text-properties-at pos))
 861         (keep t))
 862     (while (and keep (consp prop))
 863       (if (and (eq (car prop) 'local-map) (consp (cdr prop)))
 864           (setq prop (cdr (cdr prop)))
 865         (setq keep nil)))
 866     (consp prop)))
 867
 868 ;*---------------------------------------------------------------------*/
 869 ;*    make-flyspell-overlay ...                                        */
 870 ;*---------------------------------------------------------------------*/
 871 (defun make-flyspell-overlay (beg end face mouse-face)
 872   "Allocate an overlay to highlight an incorrect word.
 873 BEG and END specify the range in the buffer of that word.
 874 FACE and MOUSE-FACE specify the `face' and `mouse-face' properties
 875 for the overlay."
 876   (let ((flyspell-overlay (make-overlay beg end nil t nil)))
 877     (overlay-put flyspell-overlay 'face face)
 878     (overlay-put flyspell-overlay 'mouse-face mouse-face)
 879     (overlay-put flyspell-overlay 'flyspell-overlay t)
 880     (if flyspell-use-local-map
 881         (overlay-put flyspell-overlay
 882                      flyspell-overlay-keymap-property-name
 883                      flyspell-mouse-map))))
 884
 885 ;*---------------------------------------------------------------------*/
 886 ;*    flyspell-highlight-incorrect-region ...                          */
 887 ;*---------------------------------------------------------------------*/
 888 (defun flyspell-highlight-incorrect-region (beg end)
 889   "Set up an overlay on a misspelled word, in the buffer from BEG to END."
 890   (run-hook-with-args 'flyspell-incorrect-hook beg end)
 891   (if (or flyspell-highlight-properties (not (flyspell-properties-at-p beg)))
 892       (progn
 893         ;; we cleanup current overlay at the same position
 894         (if (and (not flyspell-persistent-highlight)
 895                  (overlayp flyspell-overlay))
 896             (delete-overlay flyspell-overlay)
 897           (let ((overlays (overlays-at beg)))
 898             (while (consp overlays)
 899               (if (flyspell-overlay-p (car overlays))
 900                   (delete-overlay (car overlays)))
 901               (setq overlays (cdr overlays)))))
 902         ;; now we can use a new overlay
 903         (setq flyspell-overlay
 904               (make-flyspell-overlay beg end
 905                                      'flyspell-incorrect-face 'highlight)))))
 906
 907 ;*---------------------------------------------------------------------*/
 908 ;*    flyspell-highlight-duplicate-region ...                          */
 909 ;*---------------------------------------------------------------------*/
 910 (defun flyspell-highlight-duplicate-region (beg end)
 911   "Set up an overlay on a duplicated word, in the buffer from BEG to END."
 912   (if (or flyspell-highlight-properties (not (flyspell-properties-at-p beg)))
 913       (progn
 914         ;; we cleanup current overlay at the same position
 915         (if (and (not flyspell-persistent-highlight)
 916                  (overlayp flyspell-overlay))
 917             (delete-overlay flyspell-overlay)
 918           (let ((overlays (overlays-at beg)))
 919             (while (consp overlays)
 920               (if (flyspell-overlay-p (car overlays))
 921                   (delete-overlay (car overlays)))
 922               (setq overlays (cdr overlays)))))
 923         ;; now we can use a new overlay
 924         (setq flyspell-overlay
 925               (make-flyspell-overlay beg end
 926                                      'flyspell-duplicate-face 'highlight)))))
 927
 928 ;*---------------------------------------------------------------------*/
 929 ;*    flyspell-auto-correct-cache ...                                  */
 930 ;*---------------------------------------------------------------------*/
 931 (defvar flyspell-auto-correct-pos nil)
 932 (defvar flyspell-auto-correct-region nil)
 933 (defvar flyspell-auto-correct-ring nil)
 934
 935 ;*---------------------------------------------------------------------*/
 936 ;*    flyspell-auto-correct-word ...                                   */
 937 ;*---------------------------------------------------------------------*/
 938 (defun flyspell-auto-correct-word (pos)
 939   "Correct the word at POS.
 940 This command proposes various successive corrections for the word at POS.
 941 The variable `flyspell-auto-correct-binding' specifies the key to bind
 942 to this command."
 943   (interactive "d")
 944   ;; use the correct dictionary
 945   (ispell-accept-buffer-local-defs)
 946   (if (eq flyspell-auto-correct-pos pos)
 947       ;; we have already been using the function at the same location
 948       (progn
 949         (save-excursion
 950           (let ((start (car flyspell-auto-correct-region))
 951                 (len   (cdr flyspell-auto-correct-region)))
 952             (delete-region start (+ start len))
 953             (setq flyspell-auto-correct-ring (cdr flyspell-auto-correct-ring))
 954             (let* ((word (car flyspell-auto-correct-ring))
 955                    (len  (length word)))
 956               (rplacd flyspell-auto-correct-region len)
 957               (goto-char start)
 958               (insert word))))
 959         (setq flyspell-auto-correct-pos (point)))
 960     ;; retain cursor location
 961     (let ((cursor-location pos)
 962           (word (flyspell-get-word nil))
 963           start end poss)
 964       ;; destructure return word info list.
 965       (setq start (car (cdr word))
 966             end (car (cdr (cdr word)))
 967             word (car word))
 968       ;; now check spelling of word.
 969       (process-send-string ispell-process "%\n") ;put in verbose mode
 970       (process-send-string ispell-process (concat "^" word "\n"))
 971       ;; wait until ispell has processed word
 972       (while (progn
 973                (accept-process-output ispell-process)
 974                (not (string= "" (car ispell-filter)))))
 975       (setq ispell-filter (cdr ispell-filter))
 976       (if (listp ispell-filter)
 977           (setq poss (ispell-parse-output (car ispell-filter))))
 978       (cond ((or (eq poss t) (stringp poss))
 979              ;; don't correct word
 980              t)
 981             ((null poss)
 982              ;; ispell error
 983              (error "Ispell: error in Ispell process"))
 984             (t
 985              ;; the word is incorrect, we have to propose a replacement
 986              (let ((replacements (if flyspell-sort-corrections
 987                                      (sort (car (cdr (cdr poss))) 'string<)
 988                                    (car (cdr (cdr poss))))))
 989                (if (consp replacements)
 990                    (progn
 991                      (let ((replace (car replacements)))
 992                        (setq word replace)
 993                        (setq cursor-location (+ (- (length word) (- end start))
 994                                                 cursor-location))
 995                        (if (not (equal word (car poss)))
 996                            (progn
 997                              ;; the save the current replacements
 998                              (setq flyspell-auto-correct-pos cursor-location)
 999                              (setq flyspell-auto-correct-region
1000                                    (cons start (length word)))
1001                              (let ((l replacements))
1002                                (while (consp (cdr l))
1003                                  (setq l (cdr l)))
1004                                (rplacd l (cons (car poss) replacements)))
1005                              (setq flyspell-auto-correct-ring
1006                                    (cdr replacements))
1007                              (delete-region start end)
1008                              (insert word)))))))))
1009       ;; return to original location
1010       (goto-char cursor-location)
1011       (ispell-pdict-save t))))
1012
1013 ;*---------------------------------------------------------------------*/
1014 ;*    flyspell-correct-word ...                                        */
1015 ;*---------------------------------------------------------------------*/
1016 (defun flyspell-correct-word (event)
1017   "Check spelling of word under or before the cursor.
1018 If the word is not found in dictionary, display possible corrections
1019 in a popup menu allowing you to choose one.
1020
1021 Word syntax described by `ispell-dictionary-alist' (which see).
1022
1023 This will check or reload the dictionary.  Use \\[ispell-change-dictionary]
1024 or \\[ispell-region] to update the Ispell process."
1025   (interactive "e")
1026   (if flyspell-use-local-map
1027       (flyspell-correct-word/mouse-keymap event)
1028     (flyspell-correct-word/local-keymap event)))
1029
1030 ;*---------------------------------------------------------------------*/
1031 ;*    flyspell-correct-word/local-keymap ...                           */
1032 ;*---------------------------------------------------------------------*/
1033 (defun flyspell-correct-word/local-keymap (event)
1034   "emacs 19.xx seems to be buggous. Overlay keymap does not seems
1035 to work correctly with local map. That is, if a key is not
1036 defined for the overlay keymap, the current local map, is not
1037 checked. The binding is resolved with the global map. The
1038 consequence is that we can not use overlay map with flyspell."
1039   (interactive "e")
1040   (save-window-excursion
1041     (let ((save (point)))
1042       (mouse-set-point event)
1043       ;; we look for a flyspell overlay here
1044       (let ((overlays (overlays-at (point)))
1045             (overlay  nil))
1046         (while (consp overlays)
1047           (if (flyspell-overlay-p (car overlays))
1048               (progn
1049                 (setq overlay (car overlays))
1050                 (setq overlays nil))
1051             (setq overlays (cdr overlays))))
1052         ;; we return to the correct location
1053         (goto-char save)
1054         ;; we check to see if button2 has been used overlay a
1055         ;; flyspell overlay
1056         (if overlay
1057             ;; yes, so we use the flyspell function
1058             (flyspell-correct-word/mouse-keymap event)
1059           ;; no so we have to use the non flyspell binding
1060           (let ((flyspell-mode nil))
1061             (if (key-binding (this-command-keys))
1062                 (command-execute (key-binding (this-command-keys))))))))))
1063
1064 ;*---------------------------------------------------------------------*/
1065 ;*    flyspell-correct-word ...                                        */
1066 ;*---------------------------------------------------------------------*/
1067 (defun flyspell-correct-word/mouse-keymap (event)
1068   "Pop up a menu of possible corrections for a misspelled word.
1069 The word checked is the word at the mouse position."
1070   (interactive "e")
1071   ;; use the correct dictionary
1072   (ispell-accept-buffer-local-defs)
1073   ;; retain cursor location (I don't know why but save-excursion here fails).
1074   (let ((save (point)))
1075     (mouse-set-point event)
1076     (let ((cursor-location (point))
1077           (word (flyspell-get-word nil))
1078           start end poss replace)
1079       ;; destructure return word info list.
1080       (setq start (car (cdr word))
1081             end (car (cdr (cdr word)))
1082             word (car word))
1083       ;; now check spelling of word.
1084       (process-send-string ispell-process "%\n") ;put in verbose mode
1085       (process-send-string ispell-process (concat "^" word "\n"))
1086       ;; wait until ispell has processed word
1087       (while (progn
1088                (accept-process-output ispell-process)
1089                (not (string= "" (car ispell-filter)))))
1090       (setq ispell-filter (cdr ispell-filter))
1091       (if (listp ispell-filter)
1092           (setq poss (ispell-parse-output (car ispell-filter))))
1093       (cond ((or (eq poss t) (stringp poss))
1094              ;; don't correct word
1095              t)
1096             ((null poss)
1097              ;; ispell error
1098              (error "Ispell: error in Ispell process"))
1099             ((string-match "GNU" (emacs-version))
1100              ;; the word is incorrect, we have to propose a replacement
1101              (setq replace (flyspell-emacs-popup event poss word))
1102              (cond ((eq replace 'ignore)
1103                     nil)
1104                    ((eq replace 'save)
1105                     (process-send-string ispell-process (concat "*" word "\n"))
1106                     (flyspell-unhighlight-at cursor-location)
1107                     (setq ispell-pdict-modified-p '(t)))
1108                    ((or (eq replace 'buffer) (eq replace 'session))
1109                     (process-send-string ispell-process (concat "@" word "\n"))
1110                     (if (null ispell-pdict-modified-p)
1111                         (setq ispell-pdict-modified-p
1112                               (list ispell-pdict-modified-p)))
1113                     (flyspell-unhighlight-at cursor-location)
1114                     (if (eq replace 'buffer)
1115                         (ispell-add-per-file-word-list word)))
1116                    (replace
1117                     (setq word (if (atom replace) replace (car replace))
1118                           cursor-location (+ (- (length word) (- end start))
1119                                              cursor-location))
1120                     (if (not (equal word (car poss)))
1121                         (progn
1122                           (delete-region start end)
1123                           (insert word))))))
1124             ((string-match "XEmacs" (emacs-version))
1125              (flyspell-xemacs-popup
1126               event poss word cursor-location start end)))
1127       (ispell-pdict-save t))
1128     (if (< save (point-max))
1129         (goto-char save)
1130       (goto-char (point-max)))))
1131
1132 ;*---------------------------------------------------------------------*/
1133 ;*    flyspell-xemacs-correct ...                                      */
1134 ;*---------------------------------------------------------------------*/
1135 (defun flyspell-xemacs-correct (replace poss word cursor-location start end)
1136   "The xemacs popup menu callback."
1137   (cond ((eq replace 'ignore)
1138          nil)
1139         ((eq replace 'save)
1140          (process-send-string ispell-process (concat "*" word "\n"))
1141          (flyspell-unhighlight-at cursor-location)
1142          (setq ispell-pdict-modified-p '(t)))
1143         ((or (eq replace 'buffer) (eq replace 'session))
1144          (process-send-string ispell-process (concat "@" word "\n"))
1145          (flyspell-unhighlight-at cursor-location)
1146          (if (null ispell-pdict-modified-p)
1147              (setq ispell-pdict-modified-p
1148                    (list ispell-pdict-modified-p)))
1149          (if (eq replace 'buffer)
1150              (ispell-add-per-file-word-list word)))
1151         (replace
1152          (setq word (if (atom replace) replace (car replace))
1153                cursor-location (+ (- (length word) (- end start))
1154                                   cursor-location))
1155          (if (not (equal word (car poss)))
1156              (save-excursion
1157                (delete-region start end)
1158                (goto-char start)
1159                (insert word))))))
1160
1161 ;*---------------------------------------------------------------------*/
1162 ;*    flyspell-emacs-popup ...                                         */
1163 ;*---------------------------------------------------------------------*/
1164 (defun flyspell-emacs-popup (event poss word)
1165   "The Emacs popup menu."
1166   (if (not event)
1167       (let* ((mouse-pos  (mouse-position))
1168              (mouse-pos  (if (nth 1 mouse-pos)
1169                              mouse-pos
1170                            (set-mouse-position (car mouse-pos)
1171                                                (/ (frame-width) 2) 2)
1172                            (unfocus-frame)
1173                            (mouse-position))))
1174         (setq event (list (list (car (cdr mouse-pos))
1175                                 (1+ (cdr (cdr mouse-pos))))
1176                           (car mouse-pos)))))
1177   (let* ((corrects   (if flyspell-sort-corrections
1178                          (sort (car (cdr (cdr poss))) 'string<)
1179                        (car (cdr (cdr poss)))))
1180          (cor-menu   (if (consp corrects)
1181                          (mapcar (lambda (correct)
1182                                    (list correct correct))
1183                                  corrects)
1184                        '()))
1185          (affix      (car (cdr (cdr (cdr poss)))))
1186          (base-menu  (let ((save (if (consp affix)
1187                                      (list
1188                                       (list (concat "Save affix: " (car affix))
1189                                             'save)
1190                                       '("Accept (session)" accept)
1191                                       '("Accept (buffer)" buffer))
1192                                    '(("Save word" save)
1193                                      ("Accept (session)" session)
1194                                      ("Accept (buffer)" buffer)))))
1195                        (if (consp cor-menu)
1196                            (append cor-menu (cons "" save))
1197                          save)))
1198          (menu       (cons "flyspell correction menu" base-menu)))
1199     (car (x-popup-menu event
1200                        (list (format "%s [%s]" word (or ispell-local-dictionary
1201                                                         ispell-dictionary))
1202                              menu)))))
1203
1204 ;*---------------------------------------------------------------------*/
1205 ;*    flyspell-xemacs-popup ...                                        */
1206 ;*---------------------------------------------------------------------*/
1207 (defun flyspell-xemacs-popup (event poss word cursor-location start end)
1208   "The xemacs popup menu."
1209   (let* ((corrects   (if flyspell-sort-corrections
1210                          (sort (car (cdr (cdr poss))) 'string<)
1211                        (car (cdr (cdr poss)))))
1212          (cor-menu   (if (consp corrects)
1213                          (mapcar (lambda (correct)
1214                                    (vector correct
1215                                            (list 'flyspell-xemacs-correct
1216                                                  correct
1217                                                  (list 'quote poss)
1218                                                  word
1219                                                  cursor-location
1220                                                  start
1221                                                  end)
1222                                            t))
1223                                  corrects)
1224                        '()))
1225          (affix      (car (cdr (cdr (cdr poss)))))
1226          (menu       (let ((save (if (consp affix)
1227                                      (vector
1228                                       (concat "Save affix: " (car affix))
1229                                       (list 'flyspell-xemacs-correct
1230                                             ''save
1231                                             (list 'quote poss)
1232                                             word
1233                                             cursor-location
1234                                             start
1235                                             end)
1236                                       t)
1237                                    (vector
1238                                     "Save word"
1239                                     (list 'flyspell-xemacs-correct
1240                                           ''save
1241                                           (list 'quote poss)
1242                                           word
1243                                           cursor-location
1244                                           start
1245                                           end)
1246                                     t)))
1247                            (session (vector "Accept (session)"
1248                                             (list 'flyspell-xemacs-correct
1249                                                   ''session
1250                                                   (list 'quote poss)
1251                                                   word
1252                                                   cursor-location
1253                                                   start
1254                                                   end)
1255                                             t))
1256                            (buffer  (vector "Accept (buffer)"
1257                                             (list 'flyspell-xemacs-correct
1258                                                   ''buffer
1259                                                   (list 'quote poss)
1260                                                   word
1261                                                   cursor-location
1262                                                   start
1263                                                   end)
1264                                             t)))
1265                        (if (consp cor-menu)
1266                            (append cor-menu (list "-" save session buffer))
1267                          (list save session buffer)))))
1268     (popup-menu (cons (format "%s [%s]" word (or ispell-local-dictionary
1269                                                  ispell-dictionary))
1270                       menu))))
1271
1272 (provide 'flyspell)
1273
1274 ;;; flyspell.el ends here