code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the 'configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2016 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 25.1.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in "$@" CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140
 141 case $host in
 142  *-mingw*)
 143
 144   if test -z "$host_alias"; then
 145
 146       # No --host argument was given to 'configure'; therefore $host
 147       # was set to a default value based on the build platform.  But
 148       # this default value may be wrong if we are building from a
 149       # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
 150       # Therefore, we'll try to get the right host platform from the
 151       # compiler's target.
 152
 153       AC_MSG_CHECKING([the compiler's target])
 154       if test -z "$CC"; then
 155           cc=gcc
 156       else
 157           cc=$CC
 158       fi
 159       cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
 160       case "$cc_target" in
 161           *-*) host=$cc_target
 162               ;;
 163           "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
 164 Please explicitly provide --host.])
 165               ;;
 166           *) AC_MSG_WARN([Compiler reported non-standard target.
 167 Defaulting to $host.])
 168               ;;
 169       esac
 170       AC_MSG_RESULT([$host])
 171   fi
 172
 173   . $srcdir/nt/mingw-cfg.site
 174
 175   case $srcdir in
 176     /* | ?:*)
 177       # srcdir is an absolute path.  In this case, force the format
 178       # "/c/foo/bar", to simplify later conversions to native Windows
 179       # format ("c:/foo/bar").
 180       srcdir=`cd "${srcdir}" && pwd -W`
 181       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
 182       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
 183       ;;
 184   esac;;
 185 esac
 186
 187 canonical=$host
 188 configuration=${host_alias-${build_alias-$host}}
 189
 190 dnl Support for --program-prefix, --program-suffix and
 191 dnl --program-transform-name options
 192 AC_ARG_PROGRAM
 193
 194 dnl It is important that variables on the RHS not be expanded here,
 195 dnl hence the single quotes.  This is per the GNU coding standards, see
 196 dnl (autoconf) Installation Directory Variables
 197 dnl See also epaths.h below.
 198 lispdir='${datadir}/emacs/${version}/lisp'
 199 standardlisppath='${lispdir}'
 200 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 201 '${datadir}/emacs/site-lisp'
 202 lisppath='${locallisppath}:${standardlisppath}'
 203 etcdir='${datadir}/emacs/${version}/etc'
 204 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 205 etcdocdir='${datadir}/emacs/${version}/etc'
 206 gamedir='${localstatedir}/games/emacs'
 207
 208 dnl Special option to disable the most of other options.
 209 AC_ARG_WITH(all,
 210 [AS_HELP_STRING([--without-all],
 211                 [omit almost all features and build
 212                 small executable with minimal dependencies])],
 213   [with_features=$withval],
 214   [with_features=yes])
 215
 216 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 217 dnl Create a new --with option that defaults to being disabled.
 218 dnl NAME is the base name of the option.  The shell variable with_NAME
 219 dnl   will be set to either the user's value (if the option is
 220 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 221 dnl   option is not specified).  Note that the shell variable name is
 222 dnl   constructed as autoconf does, by replacing non-alphanumeric
 223 dnl   characters with "_".
 224 dnl HELP-STRING is the help text for the option.
 225 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 226   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 227     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 228 ])dnl
 229
 230 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 231 dnl Create a new --with option that defaults to $with_features.
 232 dnl NAME is the base name of the option.  The shell variable with_NAME
 233 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 234 dnl   'yes' (if the option is not specified).  Note that the shell
 235 dnl   variable name is constructed as autoconf does, by replacing
 236 dnl   non-alphanumeric characters with "_".
 237 dnl HELP-STRING is the help text for the option.
 238 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 239   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 240    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 241 ])dnl
 242
 243 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 244 if test "$with_pop" = yes; then
 245    AC_DEFINE(MAIL_USE_POP)
 246 fi
 247 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 248
 249 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 250 if test "$with_kerberos" != no; then
 251    AC_DEFINE(KERBEROS)
 252 fi
 253 AH_TEMPLATE(KERBEROS,
 254             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 255
 256 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 257 if test "${with_kerberos5}" != no; then
 258   if test "${with_kerberos}" = no; then
 259     with_kerberos=yes
 260     AC_DEFINE(KERBEROS)
 261   fi
 262   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 263 fi
 264
 265 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 266 dnl FIXME hesiod support may not be present, so it seems like an error
 267 dnl to define, or at least use, this unconditionally.
 268 if test "$with_hesiod" != no; then
 269   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 270 fi
 271
 272 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 273 if test "$with_mail_unlink" != no; then
 274    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 275 fi
 276
 277 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 278     [string giving default POP mail host])],
 279     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 280
 281 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 282   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 283 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
 284   [ case "${withval}" in
 285       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 286       *) AC_MSG_ERROR(['--with-sound=$withval' is invalid;
 287 this option's value should be 'yes', 'no', 'alsa', 'oss', or 'bsd-ossaudio'.])
 288       ;;
 289     esac
 290     with_sound=$val
 291   ],
 292   [with_sound=$with_features])
 293
 294 dnl FIXME currently it is not the last.
 295 dnl This should be the last --with option, because --with-x is
 296 dnl added later on when we find the file name of X, and it's best to
 297 dnl keep them together visually.
 298 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 299  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 300 [         case "${withval}" in
 301             y | ye | yes )      val=gtk ;;
 302             n | no )            val=no  ;;
 303             l | lu | luc | luci | lucid )       val=lucid ;;
 304             a | at | ath | athe | athen | athena )      val=athena ;;
 305             m | mo | mot | moti | motif )       val=motif ;;
 306             g | gt | gtk  )     val=gtk ;;
 307             gtk2  )     val=gtk2 ;;
 308             gtk3  )     val=gtk3 ;;
 309             * )
 310 AC_MSG_ERROR(['--with-x-toolkit=$withval' is invalid;
 311 this option's value should be 'yes', 'no', 'lucid', 'athena', 'motif', 'gtk',
 312 'gtk2' or 'gtk3'.  'yes' and 'gtk' are synonyms.
 313 'athena' and 'lucid' are synonyms.])
 314             ;;
 315           esac
 316           with_x_toolkit=$val
 317 ])
 318
 319 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit); allows buffer and string size up to 2GB on 32-bit hosts, at the cost of 10% to 30% slowdown of Lisp interpreter and larger memory footprint])
 320 if test "$with_wide_int" = yes; then
 321   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 322 fi
 323
 324 dnl _ON results in a '--without' option in the --help output, so
 325 dnl the help text should refer to "don't compile", etc.
 326 with_xpm_set=${with_xpm+set}
 327 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 328 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 329 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 330 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 331 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 332 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 333 OPTION_DEFAULT_OFF([cairo],[compile with Cairo drawing (experimental)])
 334 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 335 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 336
 337 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 338 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 339 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 340
 341 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 342 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 343 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 344 AC_ARG_WITH([ns],[AS_HELP_STRING([--with-ns],
 345 [use Nextstep (OS X Cocoa or GNUstep) windowing system.
 346 On by default on Mac OS X.])],[],[with_ns=maybe])
 347 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 348
 349 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 350 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 351 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 352 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 353 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 354 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 355 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 356 OPTION_DEFAULT_OFF([modules],[compile with dynamic modules support])
 357
 358 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 359  [use a file notification library (LIB one of: yes, inotify, kqueue, gfile, w32, no)])],
 360  [ case "${withval}" in
 361     y | ye | yes )      val=yes ;;
 362     n | no )            val=no  ;;
 363     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 364     k | kq | kqu | kque | kqueu | kqueue )      val=kqueue ;;
 365     g | gf | gfi | gfil | gfile )       val=gfile ;;
 366     w | w3 | w32 )      val=w32 ;;
 367     * ) AC_MSG_ERROR(['--with-file-notification=$withval' is invalid;
 368 this option's value should be 'yes', 'no', 'inotify', 'kqueue', 'gfile' or 'w32'.
 369 'yes' is a synonym for 'w32' on MS-Windows, for 'no' on Nextstep,
 370 otherwise for the first of 'inotify', 'kqueue' or 'gfile' that is usable.])
 371     ;;
 372    esac
 373    with_file_notification=$val
 374  ],
 375  [with_file_notification=$with_features])
 376
 377 OPTION_DEFAULT_OFF([xwidgets],
 378   [enable use of some gtk widgets in Emacs buffers (requires gtk3)])
 379
 380 ## For the times when you want to build Emacs but don't have
 381 ## a suitable makeinfo, and can live without the manuals.
 382 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 383 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 384
 385 ## This might be a 'configure' arg.
 386 AC_SUBST([ACLOCAL_PATH])
 387
 388 ## Makefile.in needs the cache file name.
 389 AC_SUBST(cache_file)
 390
 391 ## This is an option because I do not know if all info/man support
 392 ## compressed files, nor how to test if they do so.
 393 OPTION_DEFAULT_ON([compress-install],
 394   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 395 make GZIP_PROG= install])
 396
 397 AC_ARG_WITH(gameuser,dnl
 398 [AS_HELP_STRING([--with-gameuser=USER_OR_GROUP],
 399                 [user for shared game score files.
 400                 An argument prefixed by ':' specifies a group instead.])])
 401 gameuser=
 402 gamegroup=
 403 # We don't test if we can actually chown/chgrp here, because configure
 404 # may run without root privileges.  lib-src/Makefile.in will handle
 405 # any errors due to missing user/group gracefully.
 406 case ${with_gameuser} in
 407   no) ;;
 408   "" | yes) gamegroup=games ;;
 409   :*) gamegroup=${with_gameuser#:} ;;
 410   *) gameuser=${with_gameuser} ;;
 411 esac
 412
 413 AC_ARG_WITH([gnustep-conf],dnl
 414 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 415    [name of GNUstep configuration file to use on systems where the command
 416     'gnustep-config' does not work; default $GNUSTEP_CONFIG_FILE, or
 417     /etc/GNUstep/GNUstep.conf])])
 418 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 419   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 420 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 421      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 422
 423 AC_ARG_ENABLE(ns-self-contained,
 424 [AS_HELP_STRING([--disable-ns-self-contained],
 425                 [disable self contained build under NeXTstep])],
 426    EN_NS_SELF_CONTAINED=$enableval,
 427    EN_NS_SELF_CONTAINED=yes)
 428
 429 locallisppathset=no
 430 AC_ARG_ENABLE(locallisppath,
 431 [AS_HELP_STRING([--enable-locallisppath=PATH],
 432                 [directories Emacs should search for lisp files specific
 433                  to this site])],
 434 if test "${enableval}" = "no"; then
 435   locallisppath=
 436 elif test "${enableval}" != "yes"; then
 437   locallisppath=${enableval} locallisppathset=yes
 438 fi)
 439
 440 AC_ARG_ENABLE(checking,
 441 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 442                 [enable expensive run-time checks.  With LIST,
 443                  enable only specific categories of checks.
 444                  Categories are: all,yes,no.
 445                  Flags are: stringbytes, stringoverrun, stringfreelist,
 446                  xmallocoverrun, conslist, glyphs])],
 447 [ac_checking_flags="${enableval}"],[])
 448 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 449 for check in $ac_checking_flags
 450 do
 451         case $check in
 452         # these set all the flags to specific states
 453         yes)            ac_enable_checking=1 ;;
 454         no)             ac_enable_checking= ;
 455                         ac_gc_check_stringbytes= ;
 456                         ac_gc_check_string_overrun= ;
 457                         ac_gc_check_string_free_list= ;
 458                         ac_xmalloc_overrun= ;
 459                         ac_gc_check_cons_list= ;
 460                         ac_glyphs_debug= ;;
 461         all)            ac_enable_checking=1 ;
 462                         ac_gc_check_stringbytes=1 ;
 463                         ac_gc_check_string_overrun=1 ;
 464                         ac_gc_check_string_free_list=1 ;
 465                         ac_xmalloc_overrun=1 ;
 466                         ac_gc_check_cons_list=1 ;
 467                         ac_glyphs_debug=1 ;;
 468         # these enable particular checks
 469         stringbytes)    ac_gc_check_stringbytes=1 ;;
 470         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 471         stringfreelist) ac_gc_check_string_free_list=1 ;;
 472         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 473         conslist)       ac_gc_check_cons_list=1 ;;
 474         glyphs)         ac_glyphs_debug=1 ;;
 475         *)      AC_MSG_ERROR(unknown check category $check) ;;
 476         esac
 477 done
 478 IFS="$ac_save_IFS"
 479
 480 if test x$ac_enable_checking != x ; then
 481   AC_DEFINE(ENABLE_CHECKING, 1,
 482 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 483 fi
 484 if test x$ac_gc_check_stringbytes != x ; then
 485   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 486 [Define this temporarily to hunt a bug.  If defined, the size of
 487    strings is redundantly recorded in sdata structures so that it can
 488    be compared to the sizes recorded in Lisp strings.])
 489 fi
 490 if test x$ac_gc_check_string_overrun != x ; then
 491   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 492 [Define this to check for short string overrun.])
 493 fi
 494 if test x$ac_gc_check_string_free_list != x ; then
 495   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 496 [Define this to check the string free list.])
 497 fi
 498 if test x$ac_xmalloc_overrun != x ; then
 499   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 500 [Define this to check for malloc buffer overrun.])
 501 fi
 502 if test x$ac_gc_check_cons_list != x ; then
 503   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 504 [Define this to check for errors in cons list.])
 505 fi
 506 if test x$ac_glyphs_debug != x ; then
 507   AC_DEFINE(GLYPH_DEBUG, 1,
 508 [Define this to enable glyphs debugging code.])
 509 fi
 510
 511 AC_ARG_ENABLE(check-lisp-object-type,
 512 [AS_HELP_STRING([--enable-check-lisp-object-type],
 513                 [enable compile time checks for the Lisp_Object data type.
 514                 This is useful for development for catching certain types of bugs.])],
 515 if test "${enableval}" != "no"; then
 516    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 517    [Define this to enable compile time checks for the Lisp_Object data type.])
 518 fi)
 519
 520
 521 dnl The name of this option is unfortunate.  It predates, and has no
 522 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 523 dnl Actually, it stops it working.
 524 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 525 AC_ARG_ENABLE(profiling,
 526 [AS_HELP_STRING([--enable-profiling],
 527                 [build emacs with low-level, gprof profiling support.
 528                 Mainly useful for debugging Emacs itself.  May not work on
 529                 all platforms.  Stops profiler.el working.])],
 530 [ac_enable_profiling="${enableval}"],[])
 531 if test x$ac_enable_profiling != x ; then
 532    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 533 else
 534    PROFILING_CFLAGS=
 535 fi
 536 AC_SUBST(PROFILING_CFLAGS)
 537
 538 AC_ARG_ENABLE(autodepend,
 539 [AS_HELP_STRING([--enable-autodepend],
 540                 [automatically generate dependencies to .h-files.
 541                  Requires gcc, enabled if found.])],
 542 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 543
 544 AC_ARG_ENABLE(gtk-deprecation-warnings,
 545 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 546                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 547 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 548
 549 dnl This used to use changequote, but, apart from 'changequote is evil'
 550 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 551 dnl the great gob of text.  Thus it's not processed for possible expansion.
 552 dnl Just make sure the brackets remain balanced.
 553 dnl
 554 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 555 dnl indicated by comments.
 556 dnl quotation begins
 557 [
 558
 559 ### If you add support for a new configuration, add code to this
 560 ### switch statement to recognize your configuration name and select
 561 ### the appropriate opsys.
 562
 563 ### As far as handling version numbers on operating systems is
 564 ### concerned, make sure things will fail in a fixable way.  If
 565 ### /etc/MACHINES doesn't say anything about version numbers, be
 566 ### prepared to handle anything reasonably.  If version numbers
 567 ### matter, be sure /etc/MACHINES says something about it.
 568
 569 opsys='' unported=no
 570 case "${canonical}" in
 571
 572   ## GNU/Linux and similar ports
 573   *-*-linux* )
 574     opsys=gnu-linux
 575   ;;
 576
 577   ## FreeBSD ports
 578   *-*-freebsd* )
 579     opsys=freebsd
 580   ;;
 581
 582   ## DragonFly ports
 583   *-*-dragonfly* )
 584     opsys=dragonfly
 585   ;;
 586
 587   ## FreeBSD kernel + glibc based userland
 588   *-*-kfreebsd*gnu* )
 589     opsys=gnu-kfreebsd
 590   ;;
 591
 592   ## NetBSD ports
 593   *-*-netbsd* )
 594     opsys=netbsd
 595   ;;
 596
 597   ## OpenBSD ports
 598   *-*-openbsd* | *-*-mirbsd* )
 599     opsys=openbsd
 600   ;;
 601
 602   ## Apple Darwin / Mac OS X
 603   *-apple-darwin* )
 604     case "${canonical}" in
 605       *-apple-darwin[0-9].*) unported=yes ;;
 606       i[3456]86-* | x86_64-* )  ;;
 607       * )            unported=yes ;;
 608     esac
 609     opsys=darwin
 610     ## Use fink packages if available.
 611     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 612 ##    if test -d /sw/include && test -d /sw/lib; then
 613 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 614 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 615 ##    fi
 616   ;;
 617
 618   ## Chromium Native Client
 619   *-nacl )
 620     opsys=nacl
 621   ;;
 622
 623   ## Cygwin ports
 624   *-*-cygwin )
 625     opsys=cygwin
 626   ;;
 627
 628   ## HP 9000 series 700 and 800, running HP/UX
 629   hppa*-hp-hpux10.2* )
 630     opsys=hpux10-20
 631   ;;
 632   hppa*-hp-hpux1[1-9]* )
 633     opsys=hpux11
 634     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 635   ;;
 636
 637   ## IBM machines
 638   rs6000-ibm-aix4.[23]* )
 639     opsys=aix4-2
 640   ;;
 641   powerpc-ibm-aix4.[23]*  )
 642     opsys=aix4-2
 643   ;;
 644   rs6000-ibm-aix[56]* )
 645     opsys=aix4-2
 646   ;;
 647   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 648     opsys=aix4-2
 649   ;;
 650
 651   ## Silicon Graphics machines
 652   ## Iris 4D
 653   mips-sgi-irix6.5 )
 654     opsys=irix6-5
 655     # Without defining _LANGUAGE_C, things get masked out in the headers
 656     # so that, for instance, grepping for 'free' in stdlib.h fails and
 657     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 658     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 659   ;;
 660
 661   ## Suns
 662   *-sun-solaris* \
 663     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 664     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 665     case "${canonical}" in
 666       i[3456]86-*-* )   ;;
 667       amd64-*-*|x86_64-*-*) ;;
 668       sparc* )          ;;
 669       * )               unported=yes ;;
 670     esac
 671     case "${canonical}" in
 672       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 673                 opsys=sol2-10
 674                 emacs_check_sunpro_c=yes
 675                 ;;
 676       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 677       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 678       *-sunos5.6* | *-solaris2.6* )
 679                 opsys=sol2-6
 680                 RANLIB="ar -ts"
 681                 ;;
 682       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 683       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 684                 opsys=sol2-6
 685                 emacs_check_sunpro_c=yes
 686                 ;;
 687     esac
 688     ## Watch out for a compiler that we know will not work.
 689     case "${canonical}" in
 690      *-solaris* | *-sunos5* )
 691                 if [ "x$CC" = x/usr/ucb/cc ]; then
 692                   ## /usr/ucb/cc doesn't work;
 693                   ## we should find some other compiler that does work.
 694                   unset CC
 695                 fi
 696                 ;;
 697       *) ;;
 698     esac
 699   ;;
 700
 701   ## Intel 386 machines where we don't care about the manufacturer.
 702   i[3456]86-*-* )
 703     case "${canonical}" in
 704       *-darwin* )               opsys=darwin ;;
 705       *-mingw* )
 706                 opsys=mingw32
 707                 # MinGW overrides and adds some system headers in nt/inc.
 708                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 709                 ;;
 710       *-sysv4.2uw* )            opsys=unixware ;;
 711       *-sysv5uw* )              opsys=unixware ;;
 712       *-sysv5OpenUNIX* )        opsys=unixware ;;
 713       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 714     esac
 715   ;;
 716
 717   # MinGW64
 718   x86_64-*-* )
 719     case "${canonical}" in
 720       *-mingw* )
 721                 opsys=mingw32
 722                 # MinGW overrides and adds some system headers in nt/inc.
 723                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 724                 ;;
 725       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 726     esac
 727   ;;
 728
 729   * )
 730     unported=yes
 731   ;;
 732 esac
 733
 734 ### If the code above didn't choose an operating system, just choose
 735 ### an operating system based on the configuration name.  You really
 736 ### only want to use this when you have no idea what the right
 737 ### operating system is; if you know what operating systems a machine
 738 ### runs, it's cleaner to make it explicit in the case statement
 739 ### above.
 740 if test x"${opsys}" = x; then
 741   case "${canonical}" in
 742     *-gnu* )                            opsys=gnu ;;
 743     * )
 744       unported=yes
 745     ;;
 746   esac
 747 fi
 748
 749 ]
 750 dnl quotation ends
 751
 752 if test $unported = yes; then
 753   AC_MSG_ERROR([Emacs does not support '${canonical}' systems.
 754 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 755 Check 'etc/MACHINES' for recognized configuration names.])
 756 fi
 757
 758 #### Choose a compiler.
 759
 760 dnl Don't bother to test for C89.
 761 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 762
 763 dnl Sets GCC=yes if using gcc.
 764 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 765 if test -n "$XCRUN"; then
 766   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 767   test -n "$AR" && export AR
 768 fi
 769
 770 dnl Emacs needs C99 or later.
 771 gl_PROG_CC_C99
 772
 773 AM_PROG_CC_C_O
 774
 775 if test x$GCC = xyes; then
 776   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 777 else
 778   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 779 fi
 780
 781 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 782 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 783 dnl that clash with MinGW.
 784 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 785
 786 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 787 AC_DEFUN([gl_CRYPTO_CHECK])
 788 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 789 # as we don't use them.
 790 AC_DEFUN([gl_FCNTL_O_FLAGS])
 791 # Avoid gnulib's test for pthread_sigmask.
 792 funcs=
 793 for func in $ac_func_list; do
 794   test $func = pthread_sigmask || AS_VAR_APPEND([funcs], [" $func"])
 795 done
 796 ac_func_list=$funcs
 797 # Use the system putenv even if it lacks GNU features, as we don't need them,
 798 # and the gnulib replacement runs afoul of a FreeBSD 10.1 bug; see Bug#19874.
 799 AC_CHECK_FUNCS_ONCE([putenv])
 800 AC_DEFUN([gl_FUNC_PUTENV],
 801   [test "$ac_cv_func_putenv" = yes || REPLACE_PUTENV=1])
 802
 803 # Initialize gnulib right after choosing the compiler.
 804 dnl Amongst other things, this sets AR and ARFLAGS.
 805 gl_EARLY
 806
 807 if test "$ac_test_CFLAGS" != set; then
 808   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 809   # if -g3 works and the user does not specify CFLAGS.
 810   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 811   case $CFLAGS in
 812     '-g')
 813       emacs_g3_CFLAGS='-g3';;
 814     '-g -O2')
 815       emacs_g3_CFLAGS='-g3 -O2';;
 816     *)
 817       emacs_g3_CFLAGS='';;
 818   esac
 819   if test -n "$emacs_g3_CFLAGS"; then
 820     emacs_save_CFLAGS=$CFLAGS
 821     CFLAGS=$emacs_g3_CFLAGS
 822     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 823       [emacs_cv_prog_cc_g3],
 824       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 825          [emacs_cv_prog_cc_g3=yes],
 826          [emacs_cv_prog_cc_g3=no])])
 827     if test $emacs_cv_prog_cc_g3 != yes; then
 828       CFLAGS=$emacs_save_CFLAGS
 829     fi
 830     if test $opsys = mingw32; then
 831       CFLAGS="$CFLAGS -gdwarf-2"
 832     fi
 833   fi
 834
 835   case $CFLAGS in
 836     *-O*) ;;
 837     *)
 838       # No optimization flag was inferred for this non-GCC compiler.
 839       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 840       emacs_save_CFLAGS=$CFLAGS
 841       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 842       CFLAGS=${CFLAGS}-O
 843       AC_CACHE_CHECK([whether $CC accepts -O],
 844         [emacs_cv_prog_cc_o],
 845         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 846            [emacs_cv_prog_cc_o=yes],
 847            [emacs_cv_prog_cc_o=no])])
 848       if test $emacs_cv_prog_cc_o != yes; then
 849         CFLAGS=$emacs_save_CFLAGS
 850       fi ;;
 851   esac
 852 fi
 853
 854 AC_ARG_ENABLE([gcc-warnings],
 855   [AS_HELP_STRING([--enable-gcc-warnings],
 856                   [turn on lots of GCC warnings/errors. This is intended for
 857                    developers, and may generate false alarms when used
 858                    with older or non-GNU development tools.])],
 859   [case $enableval in
 860      yes|no) ;;
 861      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 862    esac
 863    gl_gcc_warnings=$enableval],
 864   [gl_gcc_warnings=no]
 865 )
 866
 867 # clang is unduly picky about some things.
 868 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 869   [AC_COMPILE_IFELSE(
 870      [AC_LANG_PROGRAM([[
 871           #ifndef __clang__
 872             error "not clang";
 873           #endif
 874         ]])],
 875      [emacs_cv_clang=yes],
 876      [emacs_cv_clang=no])])
 877
 878 # When compiling with GCC, prefer -isystem to -I when including system
 879 # include files, to avoid generating useless diagnostics for the files.
 880 if test "$gl_gcc_warnings" != yes; then
 881   isystem='-I'
 882   if test "$emacs_cv_clang" = yes
 883   then
 884      # Turn off some warnings if supported.
 885      gl_WARN_ADD([-Wno-switch])
 886      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 887      gl_WARN_ADD([-Wno-pointer-sign])
 888      gl_WARN_ADD([-Wno-string-plus-int])
 889      gl_WARN_ADD([-Wno-unknown-attributes])
 890   fi
 891 else
 892   isystem='-isystem '
 893
 894   # This, $nw, is the list of warnings we disable.
 895   nw=
 896
 897   case $with_x_toolkit in
 898     lucid | athena | motif)
 899        # Old toolkits mishandle 'const'.
 900        nw="$nw -Wwrite-strings"
 901        ;;
 902     *)
 903        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 904        ;;
 905   esac
 906   AC_SUBST([WERROR_CFLAGS])
 907
 908   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 909   nw="$nw -Woverlength-strings"     # Not a problem these days
 910   nw="$nw -Wformat-nonliteral"      # we do this a lot
 911   nw="$nw -Wvla"                    # Emacs uses <vla.h>.
 912   nw="$nw -Wswitch-default"         # Too many warnings for now
 913   nw="$nw -Winline"                 # OK to ignore 'inline'
 914   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 915                                     # signed overflow has undefined behavior
 916   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 917   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 918   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 919
 920   # Emacs doesn't care about shadowing; see
 921   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 922   nw="$nw -Wshadow"
 923
 924   # Emacs's use of alloca inhibits protecting the stack.
 925   nw="$nw -Wstack-protector"
 926
 927   # Emacs's use of partly-const functions such as Fgnutls_available_p
 928   # make this option problematic.
 929   nw="$nw -Wsuggest-attribute=const"
 930
 931   # Emacs's use of partly-pure functions such as CHECK_TYPE make this
 932   # option problematic.
 933   nw="$nw -Wsuggest-attribute=pure"
 934
 935   # This part is merely for shortening the command line,
 936   # since -Wall implies -Wswitch.
 937   nw="$nw -Wswitch"
 938
 939   # This part is merely for shortening the command line,
 940   # since -Wno-FOO needs to be added below regardless.
 941   nw="$nw -Wmissing-field-initializers"
 942   nw="$nw -Wtype-limits"
 943   nw="$nw -Wunused-parameter"
 944
 945   if test $emacs_cv_clang = yes; then
 946     nw="$nw -Wcast-align"
 947   fi
 948
 949   gl_MANYWARN_ALL_GCC([ws])
 950   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 951   for w in $ws; do
 952     gl_WARN_ADD([$w])
 953   done
 954   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 955   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 956   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 957   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 958   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 959   gl_WARN_ADD([-Wno-format-nonliteral])
 960
 961   # More things that clang is unduly picky about.
 962   if test $emacs_cv_clang = yes; then
 963     gl_WARN_ADD([-Wno-format-extra-args])
 964     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 965     gl_WARN_ADD([-Wno-unused-command-line-argument])
 966     gl_WARN_ADD([-Wno-unused-value])
 967   fi
 968
 969   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 970   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 971   AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
 972   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 973       without upsetting glibc 2.15+. */
 974    #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
 975         && defined __OPTIMIZE__ && __OPTIMIZE__)
 976    # define _FORTIFY_SOURCE 2
 977    #endif
 978   ])
 979
 980   # We use a slightly smaller set of warning options for lib/.
 981   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 982   nw=
 983   nw="$nw -Wunused-macros"
 984
 985   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 986   AC_SUBST([GNULIB_WARN_CFLAGS])
 987 fi
 988
 989 edit_cflags="
 990   s,///*,/,g
 991   s/^/ /
 992   s/ -I/ $isystem/g
 993   s/^ //
 994 "
 995
 996 AC_ARG_ENABLE(link-time-optimization,
 997 [AS_HELP_STRING([--enable-link-time-optimization],
 998                 [build emacs with link-time optimization.
 999                  This requires GCC 4.5.0 or later, or clang.
1000                  (Note that clang support is experimental - see INSTALL.)
1001                  It also makes Emacs harder to debug, and when we tried it
1002                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
1003                  recommended for typical use.])],
1004 if test "${enableval}" != "no"; then
1005    ac_lto_supported=no
1006    if test $emacs_cv_clang = yes; then
1007       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
1008       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
1009       if test -x "$GOLD_PLUGIN"; then
1010          LTO="-flto"
1011       fi
1012    elif test x$GCC = xyes; then
1013       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
1014       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
1015       if test x$CPUS != x; then
1016          LTO="-flto=$CPUS"
1017       else
1018          LTO="-flto"
1019       fi
1020    else
1021       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
1022    fi
1023    if test -z "$LTO"; then
1024       ac_lto_supported=no
1025    else
1026       old_CFLAGS=$CFLAGS
1027       CFLAGS="$CFLAGS $LTO"
1028       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1029          [ac_lto_supported=yes], [ac_lto_supported=no])
1030          CFLAGS="$old_CFLAGS"
1031    fi
1032    AC_MSG_RESULT([$ac_lto_supported])
1033    if test "$ac_lto_supported" = "yes"; then
1034       CFLAGS="$CFLAGS $LTO"
1035       if test x$emacs_cv_clang = xyes; then
1036          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
1037          # WARNING: 'ar --plugin ...' doesn't work without
1038          # command, so plugin name is appended to ARFLAGS.
1039          ARFLAGS="cru --plugin $GOLD_PLUGIN"
1040          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
1041       else
1042         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
1043         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
1044         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
1045         dnl dump core on Fedora 20, so play it safe for now.
1046         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
1047           [CFLAGS="$CFLAGS -ffat-lto-objects"])
1048       fi
1049    fi
1050 fi)
1051
1052 dnl Prefer silent make output.  For verbose output, use
1053 dnl 'configure --disable-silent-rules' or 'make V=1' .
1054 AM_SILENT_RULES([yes])
1055 dnl Port to Automake 1.11.
1056 dnl This section can be removed once we assume Automake 1.14 or later.
1057 : ${AM_V=$AM_DEFAULT_VERBOSITY}
1058 : ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
1059 AC_SUBST([AM_V])
1060 AM_SUBST_NOTMAKE([AM_V])
1061 AC_SUBST([AM_DEFAULT_V])
1062 AM_SUBST_NOTMAKE([AM_DEFAULT_V])
1063 AC_SUBST([AM_DEFAULT_VERBOSITY])
1064
1065 dnl Some other nice autoconf tests.
1066 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
1067 dnl AC_PROG_INSTALL
1068 dnl AC_PROG_MKDIR_P
1069 dnl if test "x$RANLIB" = x; then
1070 dnl   AC_PROG_RANLIB
1071 dnl fi
1072
1073
1074 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
1075 dnl can be made to directories.  This is not relevant for our usage, and
1076 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1077 dnl hosted on AFS, both examples where simple links work, but links to
1078 dnl directories fail.  We use a cut-down version instead.
1079 dnl AC_PROG_LN_S
1080
1081 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1082 rm -f conf$$ conf$$.file
1083
1084 LN_S_FILEONLY='cp -p'
1085
1086 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1087 dnl random program in the current directory.
1088 if (echo >conf$$.file) 2>/dev/null; then
1089   if ln -s conf$$.file conf$$ 2>/dev/null; then
1090     if test "$opsys" = "mingw32"; then
1091       LN_S_FILEONLY='/bin/ln -s'
1092     else
1093       LN_S_FILEONLY='ln -s'
1094     fi
1095   elif ln conf$$.file conf$$ 2>/dev/null; then
1096     if test "$opsys" = "mingw32"; then
1097       LN_S_FILEONLY=/bin/ln
1098     else
1099       LN_S_FILEONLY=ln
1100     fi
1101   fi
1102 fi
1103
1104 rm -f conf$$ conf$$.file
1105
1106 if test "$LN_S_FILEONLY" = "ln -s"; then
1107    AC_MSG_RESULT([yes])
1108 else
1109    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1110 fi
1111
1112 AC_SUBST(LN_S_FILEONLY)
1113
1114
1115 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1116 dnl doesn't support links to directories, as in "ln file dir".  But that
1117 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1118 dnl executables at "make install" time.
1119 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1120 dnl for more details.
1121 if test "$opsys" = "mingw32"; then
1122   LN_S="/bin/ln"
1123 fi
1124
1125 dnl On some Debian versions, "install-info" prints irritating messages
1126 dnl "This is not dpkg install-info anymore, but GNU install-info"
1127 dnl if called via an absolute file name.
1128 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1129 dnl Sadly some people may have an old ginstall-info installed on
1130 dnl non-Debian systems, so we can't use this.
1131 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1132 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1133
1134 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1135   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1136 dnl Don't use GZIP, which is used by gzip for additional parameters.
1137 AC_PATH_PROG(GZIP_PROG, gzip)
1138
1139 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1140    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1141
1142 if test $opsys = gnu-linux; then
1143   AC_PATH_PROG(PAXCTL, paxctl,,
1144     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1145   if test "X$PAXCTL" != X; then
1146     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1147     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1148       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
1149       else AC_MSG_RESULT(no); PAXCTL=""; fi])
1150   fi
1151
1152   if test "${SETFATTR+set}" != set; then
1153     AC_CACHE_CHECK([for setfattr],
1154       [emacs_cv_prog_setfattr],
1155       [touch conftest.tmp
1156        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1157          emacs_cv_prog_setfattr=yes
1158        else
1159          emacs_cv_prog_setfattr=no
1160        fi])
1161     if test "$emacs_cv_prog_setfattr" = yes; then
1162       SETFATTR=setfattr
1163     else
1164       SETFATTR=
1165     fi
1166     rm -f conftest.tmp
1167     AC_SUBST([SETFATTR])
1168   fi
1169 fi
1170
1171 ## Need makeinfo >= 4.7 (?) to build the manuals.
1172 if test "$MAKEINFO" != "no"; then
1173   if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
1174     MAKEINFO=makeinfo
1175   fi
1176   case `($MAKEINFO --version) 2>/dev/null` in
1177     *' (GNU texinfo) '4.[[7-9]]* | \
1178     *' (GNU texinfo) '4.[[1-9][0-9]]* | \
1179     *' (GNU texinfo) '[[5-9]]* | \
1180     *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1181     *) MAKEINFO=no;;
1182   esac
1183 fi
1184
1185 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1186 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1187 ## therefore in the category of "special tools" not normally required, which
1188 ## configure does not have to check for (eg autoconf itself).
1189 ## In a repository checkout on the other hand, the manuals are not included.
1190 ## So makeinfo is a requirement to build from the repository, and configure
1191 ## should test for it as it does for any other build requirement.
1192 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1193 ## with pre-built manuals, from a repository checkout.
1194 HAVE_MAKEINFO=yes
1195
1196 if test "$MAKEINFO" = "no"; then
1197   MAKEINFO=makeinfo
1198   if test "x${with_makeinfo}" = "xno"; then
1199     HAVE_MAKEINFO=no
1200   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1201     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1202 source tree does not seem to have pre-built manuals in the 'info' directory.
1203 Either install a suitable version of makeinfo, or re-run configure
1204 with the '--without-makeinfo' option to build without the manuals.] )
1205   fi
1206 fi
1207 AC_SUBST(HAVE_MAKEINFO)
1208
1209 if test $opsys = mingw32; then
1210    DOCMISC_W32=efaq-w32
1211 else
1212    DOCMISC_W32=
1213 fi
1214 AC_SUBST(DOCMISC_W32)
1215
1216 dnl Add our options to ac_link now, after it is set up.
1217
1218 if test x$GCC = xyes; then
1219   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1220     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1221 else
1222   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1223     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1224 fi
1225
1226 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1227 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1228 dnl (Don't use '-z nocombreloc' as -z takes no arg on Irix.)
1229 dnl Treat GCC specially since it just gives a non-fatal 'unrecognized option'
1230 dnl if not built to support GNU ld.
1231
1232 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1233 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1234 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1235 dnl   Eg "make LDFLAGS=... all" could run into problems,
1236 dnl   http://bugs.debian.org/684788
1237 dnl * unnecessary, since temacs is the only thing that actually needs it.
1238 dnl   Indeed this is where it was originally, prior to:
1239 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1240 late_LDFLAGS="$LDFLAGS"
1241 if test x$GCC = xyes; then
1242   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1243 else
1244   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1245 fi
1246
1247 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1248
1249 AC_MSG_CHECKING([for -znocombreloc])
1250 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1251   [AC_MSG_RESULT(yes)],
1252   LDFLAGS_NOCOMBRELOC=
1253   [AC_MSG_RESULT(no)])
1254
1255 LDFLAGS="$late_LDFLAGS"
1256
1257 AC_CACHE_CHECK([whether addresses are sanitized],
1258   [emacs_cv_sanitize_address],
1259   [AC_COMPILE_IFELSE(
1260      [AC_LANG_PROGRAM(
1261         [[#ifndef __has_feature
1262           #define __has_feature(f) 0
1263           #endif
1264           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1265           #else
1266            error "Addresses are not sanitized.";
1267           #endif
1268         ]])],
1269      [emacs_cv_sanitize_address=yes],
1270      [emacs_cv_sanitize_address=no])])
1271
1272 dnl The function dump-emacs will not be defined and temacs will do
1273 dnl (load "loadup") automatically unless told otherwise.
1274 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1275 case "$opsys" in
1276   nacl) CANNOT_DUMP=yes ;;
1277 esac
1278
1279 if test "$CANNOT_DUMP" = "yes"; then
1280   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1281 elif test "$emacs_cv_sanitize_address" = yes; then
1282   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1283 fi
1284
1285 AC_SUBST(CANNOT_DUMP)
1286
1287
1288 UNEXEC_OBJ=unexelf.o
1289 case "$opsys" in
1290   # MSDOS uses unexcoff.o
1291   aix4-2)
1292    UNEXEC_OBJ=unexaix.o
1293    ;;
1294   cygwin)
1295    UNEXEC_OBJ=unexcw.o
1296    ;;
1297   darwin)
1298    UNEXEC_OBJ=unexmacosx.o
1299    ;;
1300   hpux10-20 | hpux11)
1301    UNEXEC_OBJ=unexhp9k800.o
1302    ;;
1303   mingw32)
1304    UNEXEC_OBJ=unexw32.o
1305    ;;
1306   sol2-10)
1307    # Use the Solaris dldump() function, called from unexsol.c, to dump
1308    # emacs, instead of the generic ELF dump code found in unexelf.c.
1309    # The resulting binary has a complete symbol table, and is better
1310    # for debugging and other observability tools (debuggers, pstack, etc).
1311    #
1312    # If you encounter a problem using dldump(), please consider sending
1313    # a message to the OpenSolaris tools-linking mailing list:
1314    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1315    #
1316    # It is likely that dldump() works with older Solaris too, but this has
1317    # not been tested, so for now this change is for Solaris 10 or newer.
1318    UNEXEC_OBJ=unexsol.o
1319    ;;
1320 esac
1321
1322 LD_SWITCH_SYSTEM=
1323 case "$opsys" in
1324   freebsd|dragonfly)
1325    ## Let 'ld' find image libs and similar things in /usr/local/lib.
1326    ## The system compiler, GCC, has apparently been modified to not
1327    ## look there, contrary to what a stock GCC would do.
1328 ### It's not our place to do this.  See bug#10313#17.
1329 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1330       :
1331    ;;
1332
1333   gnu-linux)
1334    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1335    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1336    ;;
1337
1338   netbsd)
1339 ### It's not our place to do this.  See bug#10313#17.
1340 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1341       :
1342    ;;
1343
1344   openbsd)
1345    ## Han Boetes <han@boetes.org> says this is necessary,
1346    ## otherwise Emacs dumps core on elf systems.
1347    LD_SWITCH_SYSTEM="-Z"
1348    ;;
1349 esac
1350 AC_SUBST(LD_SWITCH_SYSTEM)
1351
1352 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1353
1354 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1355 ## which has not been defined yet.  When this was handled with cpp,
1356 ## it was expanded to null when configure sourced the s/*.h file.
1357 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1358 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1359 ## (or somesuch), but because it is supposed to go at the _front_
1360 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1361 ## Compare with the gnu-linux case below, which added to the end
1362 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1363 ## LD_SWITCH_SYSTEM_TEMACS.
1364 case "$opsys" in
1365   netbsd|openbsd)
1366    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1367 esac
1368
1369
1370 C_SWITCH_MACHINE=
1371 case $canonical in
1372  alpha*)
1373   AC_CHECK_DECL([__ELF__])
1374   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1375     ## With ELF, make sure that all common symbols get allocated to in the
1376     ## data section.  Otherwise, the dump of temacs may miss variables in
1377     ## the shared library that have been initialized.  For example, with
1378     ## GNU libc, __malloc_initialized would normally be resolved to the
1379     ## shared library's .bss section, which is fatal.
1380     if test "x$GCC" = "xyes"; then
1381       C_SWITCH_MACHINE="-fno-common"
1382     else
1383       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1384     fi
1385   else
1386       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1387       dnl albeit under the mistaken assumption that said file
1388       dnl was no longer used.
1389       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1390   fi
1391   ;;
1392 esac
1393 AC_SUBST(C_SWITCH_MACHINE)
1394
1395 AC_SUBST(UNEXEC_OBJ)
1396
1397 C_SWITCH_SYSTEM=
1398 ## Some programs in src produce warnings saying certain subprograms
1399 ## are too complex and need a MAXMEM value greater than 2000 for
1400 ## additional optimization.  --nils@exp-math.uni-essen.de
1401 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1402   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1403 if test "$opsys" = "mingw32"; then
1404   case "$canonical" in
1405     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1406     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1407   esac
1408 fi
1409 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1410 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1411 AC_SUBST(C_SWITCH_SYSTEM)
1412
1413
1414 LIBS_SYSTEM=
1415 case "$opsys" in
1416   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1417   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1418
1419   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1420
1421   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1422
1423   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1424
1425   ## Motif needs -lgen.
1426   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1427 esac
1428
1429 AC_SUBST(LIBS_SYSTEM)
1430
1431 ### Make sure subsequent tests use flags consistent with the build flags.
1432
1433 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1434   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1435 else
1436   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1437 fi
1438
1439 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1440 AC_DEFUN([AC_TYPE_SIZE_T])
1441 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1442 AC_DEFUN([AC_TYPE_UID_T])
1443
1444 # sqrt and other floating-point functions such as fmod and frexp
1445 # are found in -lm on many systems.
1446 OLD_LIBS=$LIBS
1447 AC_SEARCH_LIBS([sqrt], [m])
1448 if test "X$LIBS" = "X$OLD_LIBS"; then
1449   LIB_MATH=
1450 else
1451   LIB_MATH=$ac_cv_search_sqrt
1452 fi
1453 LIBS=$OLD_LIBS
1454
1455 dnl Current possibilities handled by sed (aix4-2 -> aix,
1456 dnl gnu-linux -> gnu/linux, etc.):
1457 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1458 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1459 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1460
1461 case $opsys in
1462   cygwin )
1463     LIB_MATH=
1464     ;;
1465   darwin )
1466     ## Adding -lm confuses the dynamic linker, so omit it.
1467     LIB_MATH=
1468     ;;
1469   freebsd | dragonfly )
1470     SYSTEM_TYPE=berkeley-unix
1471     ;;
1472   gnu-linux | gnu-kfreebsd )
1473     ;;
1474   hpux10-20 | hpux11 )
1475     ;;
1476   mingw32 )
1477     LIB_MATH=
1478     SYSTEM_TYPE=windows-nt
1479     ;;
1480   dnl NB this may be adjusted below.
1481   netbsd | openbsd )
1482     SYSTEM_TYPE=berkeley-unix
1483     ;;
1484
1485   sol2* | unixware )
1486     SYSTEM_TYPE=usg-unix-v
1487     ;;
1488
1489 esac
1490
1491 AC_SUBST(LIB_MATH)
1492 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1493   [The type of system you are compiling for; sets 'system-type'.])
1494
1495
1496 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1497 pre_PKG_CONFIG_LIBS=$LIBS
1498
1499 PKG_PROG_PKG_CONFIG(0.9.0)
1500
1501 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1502 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1503 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1504 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1505 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1506 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1507 dnl actions.
1508 AC_DEFUN([EMACS_CHECK_MODULES],
1509   [PKG_CHECK_MODULES([$1], [$2],
1510      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1511       m4_default([$3], [HAVE_$1=yes])],
1512      [m4_default([$4], [HAVE_$1=no])])])
1513
1514 HAVE_SOUND=no
1515 if test "${with_sound}" != "no"; then
1516   # Sound support for GNU/Linux, the free BSDs, MinGW, and Cygwin.
1517   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1518     have_sound_header=yes, [], [
1519     #ifdef __MINGW32__
1520     #define WIN32_LEAN_AND_MEAN
1521     #include <windows.h>
1522     #endif
1523     ])
1524   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1525     AC_MSG_ERROR([OSS sound support requested but not found.])
1526
1527   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1528     # Emulation library used on NetBSD.
1529     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1530     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1531       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1532     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1533     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1534   fi
1535   AC_SUBST(LIBSOUND)
1536
1537   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1538     ALSA_REQUIRED=1.0.0
1539     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1540     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1541     if test $HAVE_ALSA = yes; then
1542       SAVE_CFLAGS="$CFLAGS"
1543       SAVE_LIBS="$LIBS"
1544       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1545       LIBS="$ALSA_LIBS $LIBS"
1546       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1547                       emacs_alsa_normal=yes,
1548                     emacs_alsa_normal=no)
1549       if test "$emacs_alsa_normal" != yes; then
1550         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1551                        [[snd_lib_error_set_handler (0);]])],
1552                        emacs_alsa_subdir=yes,
1553                      emacs_alsa_subdir=no)
1554         if test "$emacs_alsa_subdir" != yes; then
1555           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1556         fi
1557         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1558       fi
1559
1560       CFLAGS="$SAVE_CFLAGS"
1561       LIBS="$SAVE_LIBS"
1562       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1563       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1564       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1565     elif test "${with_sound}" = "alsa"; then
1566       AC_MSG_ERROR([ALSA sound support requested but not found.])
1567     fi
1568   fi                            dnl with_sound = alsa|yes
1569
1570   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1571   dnl compiles only on the specified platforms.  For others, it
1572   dnl probably doesn't make sense to try.
1573   dnl FIXME So surely we should bypass this whole section if not using
1574   dnl one of these platforms?
1575   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1576      case "$opsys" in
1577        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1578        dnl Adjust the --with-sound help text if you change this.
1579        gnu-linux|freebsd|netbsd|mingw32|cygwin)
1580          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1581          HAVE_SOUND=yes
1582          ;;
1583      esac
1584   fi
1585
1586   AC_SUBST(CFLAGS_SOUND)
1587 fi
1588
1589 dnl checks for header files
1590 AC_CHECK_HEADERS_ONCE(
1591   malloc.h
1592   sys/systeminfo.h
1593   sys/sysinfo.h
1594   coff.h pty.h
1595   sys/resource.h
1596   sys/utsname.h pwd.h utmp.h util.h)
1597
1598 AC_MSG_CHECKING(if personality LINUX32 can be set)
1599 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1600                emacs_cv_personality_linux32=yes,
1601                emacs_cv_personality_linux32=no)
1602 AC_MSG_RESULT($emacs_cv_personality_linux32)
1603
1604 if test $emacs_cv_personality_linux32 = yes; then
1605   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1606             [Define to 1 if personality LINUX32 can be set.])
1607 fi
1608
1609 # Note that Solaris has sys/sysinfo.h which defines struct
1610 # sysinfo as well.  To make sure that we're using GNU/Linux
1611 # sysinfo, we explicitly set one of its fields.
1612 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1613   AC_MSG_CHECKING([if Linux sysinfo may be used])
1614   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1615                                      [[struct sysinfo si;
1616                                        si.totalram = 0;
1617                                        sysinfo (&si)]])],
1618     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1619   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1620   if test $emacs_cv_linux_sysinfo = yes; then
1621     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1622     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1623                                        [[struct sysinfo si; return si.mem_unit]])],
1624       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1625                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1626   fi
1627 fi
1628
1629 dnl On Solaris 8 there's a compilation warning for term.h because
1630 dnl it doesn't define 'bool'.
1631 AC_CHECK_HEADERS(term.h, , , -)
1632 AC_HEADER_TIME
1633 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1634                                       ]])
1635 if test $ac_cv_have_decl_sys_siglist != yes; then
1636   # For Tru64, at least:
1637   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1638                                           ]])
1639 fi
1640 AC_HEADER_SYS_WAIT
1641
1642 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1643 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1644 #if HAVE_SYS_SOCKET_H
1645 #include <sys/socket.h>
1646 #endif])
1647 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1648 #if HAVE_SYS_SOCKET_H
1649 #include <sys/socket.h>
1650 #endif])
1651 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1652 #if HAVE_SYS_SOCKET_H
1653 #include <sys/socket.h>
1654 #endif])
1655
1656 dnl checks for structure members
1657 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1658                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1659                   struct ifreq.ifr_addr,
1660                   struct ifreq.ifr_addr.sa_len], , ,
1661                  [AC_INCLUDES_DEFAULT
1662 #if HAVE_SYS_SOCKET_H
1663 #include <sys/socket.h>
1664 #endif
1665 #if HAVE_NET_IF_H
1666 #include <net/if.h>
1667 #endif])
1668
1669 dnl Check for endianness.
1670 dnl AC_C_BIGENDIAN is done by gnulib.
1671
1672 dnl check for Make feature
1673
1674 AUTO_DEPEND=no
1675 dnl check if we have GCC and autodepend is on.
1676 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1677    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1678    SAVE_CFLAGS="$CFLAGS"
1679    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1680    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1681    CFLAGS="$SAVE_CFLAGS"
1682    test -f deps.d || ac_enable_autodepend=no
1683    rm -rf deps.d
1684    AC_MSG_RESULT([$ac_enable_autodepend])
1685    if test $ac_enable_autodepend = yes; then
1686       AUTO_DEPEND=yes
1687    fi
1688 fi
1689 AC_SUBST(AUTO_DEPEND)
1690
1691 dnl checks for operating system services
1692 AC_SYS_LONG_FILE_NAMES
1693
1694 #### Choose a window system.
1695
1696 ## We leave window_system equal to none if
1697 ## we end up building without one.  Any new window system should
1698 ## set window_system to an appropriate value and add objects to
1699 ## window-system-specific substs.
1700
1701 window_system=none
1702 AC_PATH_X
1703 if test "$no_x" != yes; then
1704   window_system=x11
1705 fi
1706
1707 LD_SWITCH_X_SITE_RPATH=
1708 if test "${x_libraries}" != NONE; then
1709   if test -n "${x_libraries}"; then
1710     LD_SWITCH_X_SITE=-L`AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -L/g'`
1711     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`
1712       AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -Wl,-rpath,/g'
1713     `
1714   fi
1715   x_default_search_path=""
1716   x_search_path=${x_libraries}
1717   if test -z "${x_search_path}"; then
1718     x_search_path=/usr/lib
1719   fi
1720   for x_library in `AS_ECHO(["$x_search_path:"]) | \
1721                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1722     x_search_path="\
1723 ${x_library}/X11/%L/%T/%N%C%S:\
1724 ${x_library}/X11/%l/%T/%N%C%S:\
1725 ${x_library}/X11/%T/%N%C%S:\
1726 ${x_library}/X11/%L/%T/%N%S:\
1727 ${x_library}/X11/%l/%T/%N%S:\
1728 ${x_library}/X11/%T/%N%S"
1729     if test x"${x_default_search_path}" = x; then
1730       x_default_search_path=${x_search_path}
1731     else
1732       x_default_search_path="${x_search_path}:${x_default_search_path}"
1733     fi
1734   done
1735 fi
1736 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1737
1738 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1739   C_SWITCH_X_SITE=$isystem`AS_ECHO(["$x_includes"]) | sed -e "s/:/ $isystem/g"`
1740 fi
1741
1742 if test x"${x_includes}" = x; then
1743   bitmapdir=/usr/include/X11/bitmaps
1744 else
1745   # accumulate include directories that have X11 bitmap subdirectories
1746   bmd_acc=
1747   for bmd in `AS_ECHO(["$x_includes"]) | sed -e 's/:/ /g'`; do
1748     if test -d "${bmd}/X11/bitmaps"; then
1749       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1750     fi
1751     if test -d "${bmd}/bitmaps"; then
1752       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1753     fi
1754   done
1755   bitmapdir=${bmd_acc#:}
1756 fi
1757
1758 test "${with_ns}" = maybe && test "${opsys}" != darwin && with_ns=no
1759 HAVE_NS=no
1760 NS_GNUSTEP_CONFIG=no
1761 NS_IMPL_COCOA=no
1762 NS_IMPL_GNUSTEP=no
1763 tmp_CPPFLAGS="$CPPFLAGS"
1764 tmp_CFLAGS="$CFLAGS"
1765 CPPFLAGS="$CPPFLAGS -x objective-c"
1766 CFLAGS="$CFLAGS -x objective-c"
1767 GNU_OBJC_CFLAGS=
1768 LIBS_GNUSTEP=
1769 if test "${with_ns}" != no; then
1770   if test "${opsys}" = darwin; then
1771      NS_IMPL_COCOA=yes
1772      ns_appdir=`pwd`/nextstep/Emacs.app
1773      ns_appbindir=${ns_appdir}/Contents/MacOS
1774      ns_appresdir=${ns_appdir}/Contents/Resources
1775      ns_appsrc=Cocoa/Emacs.base
1776      ns_fontfile=macfont.o
1777   elif flags=$( (gnustep-config --objc-flags) 2>/dev/null); then
1778      NS_IMPL_GNUSTEP=yes
1779      NS_GNUSTEP_CONFIG=yes
1780      GNU_OBJC_CFLAGS=$flags
1781      LIBS_GNUSTEP=$(gnustep-config --gui-libs) || exit
1782   elif test -f $GNUSTEP_CONFIG_FILE; then
1783      NS_IMPL_GNUSTEP=yes
1784      dnl FIXME sourcing this several times in subshells seems inefficient.
1785      GNUSTEP_SYSTEM_HEADERS=$(
1786        . $GNUSTEP_CONFIG_FILE
1787        AS_ECHO(["$GNUSTEP_SYSTEM_HEADERS"])
1788      )
1789      GNUSTEP_SYSTEM_LIBRARIES=$(
1790        . $GNUSTEP_CONFIG_FILE
1791        AS_ECHO(["$GNUSTEP_SYSTEM_LIBRARIES"])
1792      )
1793      dnl I seemed to need these as well with GNUstep-startup 0.25.
1794      GNUSTEP_LOCAL_HEADERS=$(
1795        . $GNUSTEP_CONFIG_FILE
1796        AS_ECHO(["$GNUSTEP_LOCAL_HEADERS"])
1797      )
1798      GNUSTEP_LOCAL_LIBRARIES=$(
1799        . $GNUSTEP_CONFIG_FILE
1800        AS_ECHO(["$GNUSTEP_LOCAL_LIBRARIES"])
1801      )
1802      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1803        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1804      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1805        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1806      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1807      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1808      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1809      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1810      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1811      dnl If they had chosen to either define it or not, we could have
1812      dnl just used AC_CHECK_DECL here.
1813      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1814        emacs_cv_objc_exceptions,
1815 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1816 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1817 1;
1818 #else
1819 fail;
1820 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1821      if test $emacs_cv_objc_exceptions = yes; then
1822        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1823        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1824          [Define if GNUstep uses ObjC exceptions.])
1825        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1826      fi
1827   fi
1828   if test $NS_IMPL_GNUSTEP = yes; then
1829      ns_appdir=`pwd`/nextstep/Emacs.app
1830      ns_appbindir=${ns_appdir}
1831      ns_appresdir=${ns_appdir}/Resources
1832      ns_appsrc=GNUstep/Emacs.base
1833      ns_fontfile=nsfont.o
1834   fi
1835
1836   dnl This is only used while we test the NS headers, it gets reset below.
1837   CPPFLAGS="$CPPFLAGS $GNU_OBJC_CFLAGS"
1838   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1839
1840   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1841                   [AC_MSG_ERROR([The include files (AppKit/AppKit.h etc) that
1842 are required for a Nextstep build are missing or cannot be compiled.
1843 Either fix this, or re-configure with the option '--without-ns'.])])
1844
1845   macfont_file=""
1846   if test "${NS_IMPL_COCOA}" = "yes"; then
1847     AC_MSG_CHECKING([for OSX 10.6 or newer])
1848     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1849                                      [
1850 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1851 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1060
1852  ; /* OK */
1853 #else
1854  error "OSX 10.6 or newer required";
1855 #endif
1856 #endif
1857                     ])],
1858                     ns_osx_have_106=yes,
1859                     ns_osx_have_106=no)
1860     AC_MSG_RESULT([$ns_osx_have_106])
1861
1862     if test $ns_osx_have_106 = no; then
1863        AC_MSG_ERROR([OSX 10.6 or newer is required]);
1864     fi
1865   fi
1866 fi
1867
1868 AC_SUBST(LIBS_GNUSTEP)
1869
1870 INSTALL_ARCH_INDEP_EXTRA=install-etc
1871 ns_self_contained=no
1872 NS_OBJ=
1873 NS_OBJC_OBJ=
1874 if test "${HAVE_NS}" = yes; then
1875   if test "$with_toolkit_scroll_bars" = "no"; then
1876     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1877   fi
1878
1879   window_system=nextstep
1880   # set up packaging dirs
1881   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1882      ns_self_contained=yes
1883      prefix=${ns_appresdir}
1884      exec_prefix=${ns_appbindir}
1885      dnl This one isn't really used, only archlibdir is.
1886      libexecdir="\${ns_appbindir}/libexec"
1887      archlibdir="\${ns_appbindir}/libexec"
1888      etcdocdir="\${ns_appresdir}/etc"
1889      etcdir="\${ns_appresdir}/etc"
1890      dnl FIXME maybe set datarootdir instead.
1891      dnl That would also get applications, icons, man.
1892      infodir="\${ns_appresdir}/info"
1893      mandir="\${ns_appresdir}/man"
1894      lispdir="\${ns_appresdir}/lisp"
1895      test "$locallisppathset" = no && locallisppath=""
1896      INSTALL_ARCH_INDEP_EXTRA=
1897   fi
1898
1899   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o $ns_fontfile"
1900 fi
1901 CFLAGS="$tmp_CFLAGS"
1902 CPPFLAGS="$tmp_CPPFLAGS"
1903 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1904 AC_SUBST(ns_self_contained)
1905 AC_SUBST(NS_OBJ)
1906 AC_SUBST(NS_OBJC_OBJ)
1907
1908 HAVE_W32=no
1909 W32_OBJ=
1910 W32_LIBS=
1911 EMACSRES=
1912 CLIENTRES=
1913 CLIENTW=
1914 W32_RES_LINK=
1915 EMACS_MANIFEST=
1916 UPDATE_MANIFEST=
1917 if test "${with_w32}" != no; then
1918   case "${opsys}" in
1919     cygwin)
1920       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1921              [AC_MSG_ERROR(['--with-w32' was specified, but windows.h
1922                    cannot be found.])])
1923     ;;
1924     mingw32)
1925     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1926     ;;
1927     *)
1928       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1929     ;;
1930   esac
1931 fi
1932
1933 if test "${opsys}" = "mingw32"; then
1934   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1935   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1936      #include <windows.h>
1937      #include <usp10.h>]],
1938    [[PIMAGE_NT_HEADERS pHeader;
1939      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1940    [emacs_cv_w32api=yes
1941     HAVE_W32=yes],
1942    emacs_cv_w32api=no)
1943   AC_MSG_RESULT($emacs_cv_w32api)
1944   if test "${emacs_cv_w32api}" = "no"; then
1945     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1946   fi
1947 fi
1948
1949 FIRSTFILE_OBJ=
1950 NTDIR=
1951 LIBS_ECLIENT=
1952 LIB_WSOCK32=
1953 NTLIB=
1954 CM_OBJ="cm.o"
1955 XARGS_LIMIT=
1956 if test "${HAVE_W32}" = "yes"; then
1957   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1958   if test "$with_toolkit_scroll_bars" = "no"; then
1959     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for w32 build.])
1960   fi
1961   AC_CHECK_TOOL(WINDRES, [windres],
1962                 [AC_MSG_ERROR([No resource compiler found.])])
1963   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1964   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1965   EMACSRES="emacs.res"
1966   case "$canonical" in
1967     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1968     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1969   esac
1970   dnl Construct something of the form "24,4,0,0" with 4 components.
1971   comma_version=`echo "${PACKAGE_VERSION}.0.0" | sed -e 's/\./,/g' -e 's/^\([[^,]]*,[[^,]]*,[[^,]]*,[[^,]]*\).*/\1/'`
1972
1973   comma_space_version=`echo "$comma_version" | sed 's/,/, /g'`
1974   AC_SUBST(comma_version)
1975   AC_SUBST(comma_space_version)
1976   AC_CONFIG_FILES([nt/emacs.rc nt/emacsclient.rc])
1977   if test "${opsys}" = "cygwin"; then
1978     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1979     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1980     # Tell the linker that emacs.res is an object (which we compile from
1981     # the rc file), not a linker script.
1982     W32_RES_LINK="-Wl,emacs.res"
1983   else
1984     UPDATE_MANIFEST=update-game-score.exe.manifest
1985     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1986     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1987     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1988     W32_RES_LINK="\$(EMACSRES)"
1989     CLIENTRES="emacsclient.res"
1990     CLIENTW="emacsclientw\$(EXEEXT)"
1991     FIRSTFILE_OBJ=firstfile.o
1992     NTDIR=nt
1993     CM_OBJ=
1994     LIBS_ECLIENT="-lcomctl32"
1995     LIB_WSOCK32="-lwsock32"
1996     NTLIB="ntlib.$ac_objext"
1997     XARGS_LIMIT="-s 10000"
1998   fi
1999 fi
2000 AC_SUBST(W32_OBJ)
2001 AC_SUBST(W32_LIBS)
2002 AC_SUBST(EMACSRES)
2003 AC_SUBST(EMACS_MANIFEST)
2004 AC_SUBST(UPDATE_MANIFEST)
2005 AC_SUBST(CLIENTRES)
2006 AC_SUBST(CLIENTW)
2007 AC_SUBST(W32_RES_LINK)
2008 AC_SUBST(FIRSTFILE_OBJ)
2009 AC_SUBST(NTDIR)
2010 AC_SUBST(CM_OBJ)
2011 AC_SUBST(LIBS_ECLIENT)
2012 AC_SUBST(LIB_WSOCK32)
2013 AC_SUBST(NTLIB)
2014 AC_SUBST(XARGS_LIMIT)
2015
2016 if test "${HAVE_W32}" = "yes"; then
2017   window_system=w32
2018   with_xft=no
2019 fi
2020
2021 ## $window_system is now set to the window system we will
2022 ## ultimately use.
2023
2024 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
2025    # Too many warnings for now.
2026    nw=
2027    nw="$nw -Wsuggest-attribute=noreturn"
2028    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
2029
2030    gl_WARN_ADD([-Wno-unused-variable])
2031    gl_WARN_ADD([-Wno-unused-but-set-variable])
2032    gl_WARN_ADD([-Wno-unused-but-set-parameter])
2033 fi
2034
2035 term_header=
2036 HAVE_X_WINDOWS=no
2037 HAVE_X11=no
2038 USE_X_TOOLKIT=none
2039
2040 case "${window_system}" in
2041   x11 )
2042     HAVE_X_WINDOWS=yes
2043     HAVE_X11=yes
2044     term_header=xterm.h
2045     case "${with_x_toolkit}" in
2046       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
2047       motif ) USE_X_TOOLKIT=MOTIF ;;
2048       gtk ) with_gtk=yes
2049             term_header=gtkutil.h
2050 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
2051 dnl USE_X_TOOLKIT is set.
2052             USE_X_TOOLKIT=none ;;
2053       gtk2 ) with_gtk2=yes
2054              term_header=gtkutil.h
2055              USE_X_TOOLKIT=none ;;
2056       gtk3 ) with_gtk3=yes
2057              term_header=gtkutil.h
2058              USE_X_TOOLKIT=none ;;
2059       no ) USE_X_TOOLKIT=none ;;
2060 dnl If user did not say whether to use a toolkit, make this decision later:
2061 dnl use the toolkit if we have gtk, or X11R5 or newer.
2062       * ) USE_X_TOOLKIT=maybe ;;
2063     esac
2064   ;;
2065   nextstep )
2066     term_header=nsterm.h
2067   ;;
2068   w32 )
2069     term_header=w32term.h
2070   ;;
2071 esac
2072
2073 if test "$window_system" = none && test "X$with_x" != "Xno"; then
2074    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
2075    if test "$HAVE_XSERVER" = true ||
2076       test -n "$DISPLAY" ||
2077       {
2078         for emacs_libX11 in /usr/lib/libX11.*; do break; done
2079         test "$emacs_libX11" != '/usr/lib/libX11.*'
2080       }
2081    then
2082         AC_MSG_ERROR([You seem to be running X, but no X development libraries
2083 were found.  You should install the relevant development files for X
2084 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2085 sure you have development files for image handling, i.e.
2086 tiff, gif, jpeg, png and xpm.
2087 If you are sure you want Emacs compiled without X window support, pass
2088   --without-x
2089 to configure.])
2090    fi
2091 fi
2092
2093 # Does the opsystem file prohibit the use of the GNU malloc?
2094 # Assume not, until told otherwise.
2095 GNU_MALLOC=yes
2096
2097 AC_CACHE_CHECK(
2098   [whether malloc is Doug Lea style],
2099   [emacs_cv_var_doug_lea_malloc],
2100   [emacs_cv_var_doug_lea_malloc=no
2101    dnl Hooks do not work with address sanitization.
2102    if test "$emacs_cv_sanitize_address" != yes; then
2103      AC_LINK_IFELSE(
2104        [AC_LANG_PROGRAM(
2105           [[#include <malloc.h>
2106             static void hook (void) {}]],
2107           [[malloc_set_state (malloc_get_state ());
2108             __after_morecore_hook = hook;
2109             __malloc_initialize_hook = hook;]])],
2110        [emacs_cv_var_doug_lea_malloc=yes])
2111    fi])
2112 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2113
2114 system_malloc=$emacs_cv_sanitize_address
2115
2116 hybrid_malloc=
2117
2118 case "$opsys" in
2119   ## darwin ld insists on the use of malloc routines in the System framework.
2120   darwin | mingw32 | nacl | sol2-10) system_malloc=yes ;;
2121   cygwin) hybrid_malloc=yes;;
2122 esac
2123
2124 if test "${system_malloc}" != yes && test "${doug_lea_malloc}" != yes \
2125    && test "${UNEXEC_OBJ}" = unexelf.o; then
2126   hybrid_malloc=yes
2127 fi
2128
2129 GMALLOC_OBJ=
2130 HYBRID_MALLOC=
2131 if test "${system_malloc}" = "yes"; then
2132   AC_DEFINE([SYSTEM_MALLOC], 1,
2133     [Define to 1 to use the system memory allocator, even if it is not
2134      Doug Lea style.])
2135   GNU_MALLOC=no
2136   GNU_MALLOC_reason="
2137     (The GNU allocators don't work with this system configuration.)"
2138   VMLIMIT_OBJ=
2139 elif test "$hybrid_malloc" = yes; then
2140   AC_DEFINE(HYBRID_MALLOC, 1,
2141     [Define to use gmalloc before dumping and the system malloc after.])
2142   HYBRID_MALLOC=1
2143   GNU_MALLOC=
2144   GNU_MALLOC_reason="only before dumping"
2145   GMALLOC_OBJ=gmalloc.o
2146   VMLIMIT_OBJ=
2147 else
2148   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2149   VMLIMIT_OBJ=vm-limit.o
2150
2151   AC_CHECK_HEADERS([sys/vlimit.h])
2152   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2153     [AC_LINK_IFELSE(
2154        [AC_LANG_PROGRAM(
2155          [[extern char data_start[]; char ch;]],
2156          [[return data_start < &ch;]])],
2157        [emacs_cv_data_start=yes],
2158        [emacs_cv_data_start=no])])
2159   if test $emacs_cv_data_start = yes; then
2160     AC_DEFINE([HAVE_DATA_START], 1,
2161       [Define to 1 if data_start is the address of the start
2162        of the main data segment.])
2163   fi
2164 fi
2165 AC_SUBST([HYBRID_MALLOC])
2166 AM_CONDITIONAL([HYBRID_MALLOC_LIB], [test -n "$HYBRID_MALLOC"])
2167 AC_SUBST(GMALLOC_OBJ)
2168 AC_SUBST(VMLIMIT_OBJ)
2169
2170 if test "$doug_lea_malloc" = "yes" && test "$hybrid_malloc" != yes; then
2171   if test "$GNU_MALLOC" = yes ; then
2172     GNU_MALLOC_reason="
2173       (Using Doug Lea's new malloc from the GNU C Library.)"
2174   fi
2175   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2176     [Define to 1 if the system memory allocator is Doug Lea style,
2177      with malloc hooks and malloc_set_state.])
2178
2179   ## Use mmap directly for allocating larger buffers.
2180   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2181   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2182   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2183   case "$opsys" in
2184     mingw32|gnu*) REL_ALLOC=no ;;
2185   esac
2186 fi
2187
2188 if test x"${REL_ALLOC}" = x; then
2189   REL_ALLOC=${GNU_MALLOC}
2190 fi
2191
2192 use_mmap_for_buffers=no
2193 case "$opsys" in
2194   cygwin|mingw32|irix6-5) use_mmap_for_buffers=yes ;;
2195 esac
2196
2197 AC_FUNC_MMAP
2198 if test $use_mmap_for_buffers = yes; then
2199   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2200   REL_ALLOC=no
2201 fi
2202
2203 LIBS="$LIBS_SYSTEM $LIBS"
2204
2205 dnl FIXME replace main with a function we actually want from this library.
2206 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2207
2208 dnl Check for the POSIX thread library.
2209 LIB_PTHREAD=
2210 AC_CHECK_HEADERS_ONCE(pthread.h)
2211 if test "$ac_cv_header_pthread_h" && test "$opsys" != "mingw32"; then
2212   AC_CACHE_CHECK([for pthread library],
2213     [emacs_cv_pthread_lib],
2214     [emacs_cv_pthread_lib=no
2215      OLD_LIBS=$LIBS
2216      for emacs_pthread_lib in 'none needed' -lpthread; do
2217        case $emacs_pthread_lib in
2218          -*) LIBS="$OLD_LIBS $emacs_pthread_lib";;
2219        esac
2220        AC_LINK_IFELSE(
2221          [AC_LANG_PROGRAM(
2222             [[#include <pthread.h>
2223               #include <signal.h>
2224               sigset_t old_mask, new_mask;
2225               void noop (void) {}]],
2226             [[pthread_t th = pthread_self ();
2227               int status = 0;
2228               status += pthread_create (&th, 0, 0, 0);
2229               status += pthread_sigmask (SIG_BLOCK, &new_mask, &old_mask);
2230               status += pthread_kill (th, 0);
2231               #if ! (defined SYSTEM_MALLOC || defined HYBRID_MALLOC \
2232                      || defined DOUG_LEA_MALLOC)
2233               /* Test for pthread_atfork only if gmalloc uses it,
2234                  as older-style hosts like MirBSD 10 lack it.  */
2235               status += pthread_atfork (noop, noop, noop);
2236               #endif
2237               return status;]])],
2238          [emacs_cv_pthread_lib=$emacs_pthread_lib])
2239        LIBS=$OLD_LIBS
2240        if test "$emacs_cv_pthread_lib" != no; then
2241          break
2242        fi
2243      done])
2244   if test "$emacs_cv_pthread_lib" != no; then
2245     AC_DEFINE([HAVE_PTHREAD], 1, [Define to 1 if you have POSIX threads.])
2246     case $emacs_cv_pthread_lib in
2247       -*) LIB_PTHREAD=$emacs_cv_pthread_lib;;
2248     esac
2249     ac_cv_func_pthread_sigmask=yes
2250     # Some systems optimize for single-threaded programs by default, and
2251     # need special flags to disable these optimizations. For example, the
2252     # definition of 'errno' in <errno.h>.
2253     case $opsys in
2254       hpux* | sol*)
2255         AC_DEFINE([_REENTRANT], 1,
2256           [Define to 1 if your system requires this in multithreaded code.]);;
2257       aix4-2)
2258         AC_DEFINE([_THREAD_SAFE], 1,
2259           [Define to 1 if your system requires this in multithreaded code.]);;
2260     esac
2261   fi
2262 fi
2263 AC_SUBST([LIB_PTHREAD])
2264
2265 dnl Check for need for bigtoc support on IBM AIX
2266
2267 case ${host_os} in
2268 aix*)
2269   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2270     case $GCC in
2271     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2272     *) gdb_cv_bigtoc=-bbigtoc ;;
2273     esac
2274
2275     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2276     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2277   ])
2278   ;;
2279 esac
2280
2281 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2282 # is for the tests that follow.  We set them back later on.
2283
2284 REAL_CFLAGS="$CFLAGS"
2285 REAL_CPPFLAGS="$CPPFLAGS"
2286 REAL_LIBS="$LIBS"
2287
2288 if test "${HAVE_X11}" = "yes"; then
2289   DEFS="$C_SWITCH_X_SITE $DEFS"
2290   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2291   LIBS="-lX11 $LIBS"
2292   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2293   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2294
2295   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2296   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2297   # but it's more convenient here to set LD_RUN_PATH since this
2298   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2299   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2300     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2301     export LD_RUN_PATH
2302   fi
2303
2304   if test "${opsys}" = "gnu-linux"; then
2305     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2306     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2307      [[XOpenDisplay ("foo");]])],
2308      [xgnu_linux_first_failure=no],
2309      [xgnu_linux_first_failure=yes])
2310     if test "${xgnu_linux_first_failure}" = "yes"; then
2311       OLD_CPPFLAGS="$CPPFLAGS"
2312       OLD_LIBS="$LIBS"
2313       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2314       LIBS="$LIBS -b i486-linuxaout"
2315       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2316        [[XOpenDisplay ("foo");]])],
2317        [xgnu_linux_second_failure=no],
2318        [xgnu_linux_second_failure=yes])
2319       if test "${xgnu_linux_second_failure}" = "yes"; then
2320         # If we get the same failure with -b, there is no use adding -b.
2321         # So leave it out.  This plays safe.
2322         AC_MSG_RESULT(no)
2323       else
2324         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2325         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2326         AC_MSG_RESULT(yes)
2327       fi
2328       CPPFLAGS=$OLD_CPPFLAGS
2329       LIBS=$OLD_LIBS
2330     else
2331       AC_MSG_RESULT(no)
2332     fi
2333   fi
2334
2335   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2336   # header files included from there.
2337   AC_MSG_CHECKING(for Xkb)
2338   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2339 #include <X11/XKBlib.h>]],
2340         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2341         emacs_xkb=yes, emacs_xkb=no)
2342   AC_MSG_RESULT($emacs_xkb)
2343   if test $emacs_xkb = yes; then
2344     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2345   fi
2346
2347   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2348 XScreenNumberOfScreen)
2349 fi
2350
2351 if test "${window_system}" = "x11"; then
2352   AC_MSG_CHECKING(X11 version 6)
2353   AC_CACHE_VAL(emacs_cv_x11_version_6,
2354   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2355 [[#if XlibSpecificationRelease < 6
2356 fail;
2357 #endif
2358 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2359   if test $emacs_cv_x11_version_6 = yes; then
2360     AC_MSG_RESULT(6 or newer)
2361     AC_DEFINE(HAVE_X11R6, 1,
2362               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2363     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2364     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2365     ## XIM support.
2366     case "$opsys" in
2367       sol2-*) : ;;
2368       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2369            [Define if you have usable X11R6-style XIM support.])
2370          ;;
2371     esac
2372   else
2373     AC_MSG_RESULT(before 6)
2374   fi
2375 fi
2376
2377
2378 ### Use -lrsvg-2 if available, unless '--with-rsvg=no' is specified.
2379 HAVE_RSVG=no
2380 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2381   if test "${with_rsvg}" != "no"; then
2382     RSVG_REQUIRED=2.11.0
2383     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2384
2385     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2386     AC_SUBST(RSVG_CFLAGS)
2387     AC_SUBST(RSVG_LIBS)
2388
2389     if test $HAVE_RSVG = yes; then
2390       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2391       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2392       # Windows loads librsvg dynamically
2393       if test "${opsys}" = "mingw32"; then
2394         RSVG_LIBS=
2395       fi
2396     fi
2397   fi
2398 fi
2399
2400 HAVE_IMAGEMAGICK=no
2401 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2402   if test "${with_imagemagick}" != "no"; then
2403     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2404     ## 6.8.2 makes Emacs crash; see Bug#13867.
2405     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2406     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2407     AC_SUBST(IMAGEMAGICK_CFLAGS)
2408     AC_SUBST(IMAGEMAGICK_LIBS)
2409
2410     if test $HAVE_IMAGEMAGICK = yes; then
2411       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2412       OLD_CFLAGS=$CFLAGS
2413       OLD_LIBS=$LIBS
2414       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2415       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2416       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers MagickAutoOrientImage)
2417       CFLAGS=$OLD_CFLAGS
2418       LIBS=$OLD_LIBS
2419     fi
2420   fi
2421 fi
2422
2423 AC_CHECK_LIB(anl, getaddrinfo_a, HAVE_GETADDRINFO_A=yes)
2424 if test "${HAVE_GETADDRINFO_A}" = "yes"; then
2425   AC_DEFINE(HAVE_GETADDRINFO_A, 1,
2426 [Define to 1 if you have getaddrinfo_a for asynchronous DNS resolution.])
2427   GETADDRINFO_A_LIBS="-lanl"
2428   AC_SUBST(GETADDRINFO_A_LIBS)
2429 fi
2430
2431 HAVE_GTK=no
2432 GTK_OBJ=
2433 gtk_term_header=$term_header
2434 check_gtk2=no
2435 gtk3_pkg_errors=
2436 if test "${opsys}" != "mingw32"; then
2437   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2438     GLIB_REQUIRED=2.28
2439     GTK_REQUIRED=3.0
2440     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2441
2442     dnl Checks for libraries.
2443     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2444       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2445     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2446        AC_MSG_ERROR($GTK_PKG_ERRORS)
2447     fi
2448     if test "$pkg_check_gtk" = "yes"; then
2449        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2450        GTK_OBJ=emacsgtkfixed.o
2451        gtk_term_header=gtkutil.h
2452        USE_GTK_TOOLKIT="GTK3"
2453        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2454          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2455            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2456          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2457            [Define to 1 to disable Glib deprecation warnings.])
2458        fi
2459     else
2460        check_gtk2=yes
2461        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2462     fi
2463   fi
2464
2465   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2466     GLIB_REQUIRED=2.10
2467     GTK_REQUIRED=2.10
2468     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2469
2470     dnl Checks for libraries.
2471     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2472       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2473     if test "$pkg_check_gtk" = "no" &&
2474        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2475     then
2476       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2477     fi
2478     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2479   fi
2480 fi
2481
2482 OLD_CFLAGS=$CFLAGS
2483 OLD_LIBS=$LIBS
2484
2485 if test x"$pkg_check_gtk" = xyes; then
2486
2487   AC_SUBST(GTK_LIBS)
2488   CFLAGS="$CFLAGS $GTK_CFLAGS"
2489   LIBS="$GTK_LIBS $LIBS"
2490   dnl Try to compile a simple GTK program.
2491   AC_MSG_CHECKING([whether GTK compiles])
2492   GTK_COMPILES=no
2493   AC_LINK_IFELSE(
2494     [AC_LANG_PROGRAM(
2495        [[/* Check the Gtk and Glib APIs.  */
2496          #include <gtk/gtk.h>
2497          #include <glib-object.h>
2498          static void
2499          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2500          {}
2501        ]],
2502        [[
2503          GtkSettings *gs = 0;
2504          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2505             strict C prohibits this.  Use gtk_main_iteration to test that the
2506             libraries are there.  */
2507          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2508                                     0, 0, 0, G_CALLBACK (callback), 0))
2509            gtk_main_iteration ();
2510        ]])],
2511     [GTK_COMPILES=yes])
2512   AC_MSG_RESULT([$GTK_COMPILES])
2513   if test "${GTK_COMPILES}" != "yes"; then
2514     GTK_OBJ=
2515     if test "$USE_X_TOOLKIT" != "maybe"; then
2516       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2517     fi
2518   else
2519     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2520     HAVE_GTK=yes
2521     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2522     GTK_OBJ="gtkutil.o $GTK_OBJ"
2523     term_header=$gtk_term_header
2524     USE_X_TOOLKIT=none
2525     AC_MSG_WARN([[Your version of Gtk+ will have problems with
2526        closing open displays.  This is no problem if you just use
2527        one display, but if you use more than one and close one of them
2528        Emacs may crash.
2529        See http://bugzilla.gnome.org/show_bug.cgi?id=85715]])
2530     sleep 3
2531   fi
2532
2533 fi
2534 AC_SUBST(GTK_OBJ)
2535
2536
2537 if test "${HAVE_GTK}" = "yes"; then
2538
2539   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2540   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2541   if test "$with_toolkit_scroll_bars" != no; then
2542     with_toolkit_scroll_bars=yes
2543   fi
2544
2545   dnl  Check if we have the old file selection dialog declared and
2546   dnl  in the link library.  In 2.x it may be in the library,
2547   dnl  but not declared if deprecated featured has been selected out.
2548   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2549   HAVE_GTK_FILE_SELECTION=no
2550   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2551                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2552 #include <gtk/gtk.h>])
2553   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2554     AC_CHECK_FUNCS(gtk_file_selection_new)
2555   fi
2556
2557   dnl Same as above for gtk_handle_box.
2558   HAVE_GTK_HANDLE_BOX=no
2559   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2560                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2561 #include <gtk/gtk.h>])
2562   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2563     AC_CHECK_FUNCS(gtk_handle_box_new)
2564   fi
2565
2566   dnl Same as above for gtk_tearoff_menu_item.
2567   HAVE_GTK_TEAROFF_MENU_ITEM=no
2568   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2569                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2570 #include <gtk/gtk.h>])
2571   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2572     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2573   fi
2574
2575   dnl Check for functions introduced in 2.14 and later.
2576   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2577                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2578                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2579                  gtk_orientable_set_orientation \
2580                  gtk_window_set_has_resize_grip)
2581
2582  term_header=gtkutil.h
2583 fi
2584
2585
2586 dnl Enable xwidgets if GTK3 and WebKitGTK+ are available.
2587 HAVE_XWIDGETS=no
2588 XWIDGETS_OBJ=
2589 if test "$with_xwidgets" != "no"; then
2590   test "$USE_GTK_TOOLKIT" = "GTK3" && test "$window_system" != "none" ||
2591     AC_MSG_ERROR([xwidgets requested but gtk3 not used.])
2592
2593   WEBKIT_REQUIRED=1.4.0
2594   WEBKIT_MODULES="webkitgtk-3.0 >= $WEBKIT_REQUIRED"
2595   EMACS_CHECK_MODULES([WEBKIT], [$WEBKIT_MODULES])
2596   HAVE_XWIDGETS=$HAVE_WEBKIT
2597   test $HAVE_XWIDGETS = yes ||
2598     AC_MSG_ERROR([xwidgets requested but WebKitGTK+ not found.])
2599
2600   XWIDGETS_OBJ=xwidget.o
2601   AC_DEFINE([HAVE_XWIDGETS], 1, [Define to 1 if you have xwidgets support.])
2602 fi
2603 AC_SUBST(XWIDGETS_OBJ)
2604
2605 CFLAGS=$OLD_CFLAGS
2606 LIBS=$OLD_LIBS
2607
2608 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2609 dnl other platforms.
2610 HAVE_DBUS=no
2611 DBUS_OBJ=
2612 if test "${with_dbus}" = "yes"; then
2613    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2614    if test "$HAVE_DBUS" = yes; then
2615      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2616      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2617      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2618      dnl D-Bus 1.5.12.
2619      OLD_LIBS=$LIBS
2620      LIBS="$LIBS $DBUS_LIBS"
2621      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2622                     dbus_type_is_valid \
2623                     dbus_validate_bus_name \
2624                     dbus_validate_path \
2625                     dbus_validate_interface \
2626                     dbus_validate_member)
2627      LIBS=$OLD_LIBS
2628      DBUS_OBJ=dbusbind.o
2629    fi
2630 fi
2631 AC_SUBST(DBUS_CFLAGS)
2632 AC_SUBST(DBUS_LIBS)
2633 AC_SUBST(DBUS_OBJ)
2634
2635 dnl GSettings has been tested under GNU/Linux only.
2636 HAVE_GSETTINGS=no
2637 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2638    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2639    if test "$HAVE_GSETTINGS" = "yes"; then
2640       old_CFLAGS=$CFLAGS
2641       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2642       old_LIBS=$LIBS
2643       LIBS="$LIBS $GSETTINGS_LIBS"
2644       AC_MSG_CHECKING([whether GSettings is in gio])
2645       AC_LINK_IFELSE(
2646          [AC_LANG_PROGRAM(
2647              [[/* Check that gsettings really is present.  */
2648              #include <glib-object.h>
2649              #include <gio/gio.h>
2650              ]],
2651              [[
2652                GSettings *settings;
2653                GVariant *val = g_settings_get_value (settings, "");
2654              ]])],
2655          [], HAVE_GSETTINGS=no)
2656       AC_MSG_RESULT([$HAVE_GSETTINGS])
2657
2658       if test "$HAVE_GSETTINGS" = "yes"; then
2659         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2660         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2661         SETTINGS_LIBS="$GSETTINGS_LIBS"
2662       fi
2663       CFLAGS=$old_CFLAGS
2664       LIBS=$old_LIBS
2665    fi
2666 fi
2667
2668 dnl GConf has been tested under GNU/Linux only.
2669 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2670 HAVE_GCONF=no
2671 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2672    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2673    if test "$HAVE_GCONF" = yes; then
2674       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2675       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2676       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2677       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2678    fi
2679 fi
2680
2681 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2682     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2683     if test "$HAVE_GOBJECT" = "yes"; then
2684        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2685        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2686     fi
2687     SAVE_CFLAGS="$CFLAGS"
2688     SAVE_LIBS="$LIBS"
2689     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2690     LIBS="$SETTINGS_LIBS $LIBS"
2691     CFLAGS="$SAVE_CFLAGS"
2692     LIBS="$SAVE_LIBS"
2693 fi
2694 AC_SUBST(SETTINGS_CFLAGS)
2695 AC_SUBST(SETTINGS_LIBS)
2696
2697
2698 dnl SELinux is available for GNU/Linux only.
2699 HAVE_LIBSELINUX=no
2700 LIBSELINUX_LIBS=
2701 if test "${with_selinux}" = "yes"; then
2702    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2703    if test "$HAVE_LIBSELINUX" = yes; then
2704       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2705       LIBSELINUX_LIBS=-lselinux
2706    fi
2707 fi
2708 AC_SUBST(LIBSELINUX_LIBS)
2709
2710 HAVE_GNUTLS=no
2711 if test "${with_gnutls}" = "yes" ; then
2712   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2713     [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2714   if test "${HAVE_GNUTLS}" = "yes"; then
2715     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2716     EMACS_CHECK_MODULES([LIBGNUTLS3], [gnutls >= 3.0.0],
2717       [AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])], [])
2718   fi
2719
2720   # Windows loads GnuTLS dynamically
2721   if test "${opsys}" = "mingw32"; then
2722     LIBGNUTLS_LIBS=
2723   fi
2724 fi
2725
2726 AC_SUBST(LIBGNUTLS_LIBS)
2727 AC_SUBST(LIBGNUTLS_CFLAGS)
2728
2729 NOTIFY_OBJ=
2730 NOTIFY_SUMMARY=no
2731
2732 dnl MS Windows native file monitor is available for mingw32 only.
2733 case $with_file_notification,$opsys in
2734   w32,cygwin)
2735     AC_MSG_ERROR(['--with-file-notification=w32' was specified, but
2736     this is only supported on MS-Windows native and MinGW32 builds.
2737     Consider using gfile instead.])
2738     ;;
2739   w32,* | yes,mingw32)
2740     AC_CHECK_HEADER(windows.h)
2741     if test "$ac_cv_header_windows_h" = yes ; then
2742        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2743        NOTIFY_OBJ=w32notify.o
2744        NOTIFY_SUMMARY="yes (w32)"
2745     fi ;;
2746 esac
2747
2748 dnl inotify is available only on GNU/Linux.
2749 case $with_file_notification,$NOTIFY_OBJ in
2750   inotify, | yes,)
2751     AC_CHECK_HEADER(sys/inotify.h)
2752     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2753         AC_CHECK_FUNC(inotify_init1)
2754         if test "$ac_cv_func_inotify_init1" = yes; then
2755           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2756           NOTIFY_OBJ=inotify.o
2757           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2758        fi
2759     fi ;;
2760 esac
2761
2762 dnl kqueue is available on BSD-like systems.
2763 case $with_file_notification,$NOTIFY_OBJ in
2764   kqueue,* | yes,)
2765     EMACS_CHECK_MODULES([KQUEUE], [libkqueue])
2766     if test "$HAVE_KQUEUE" = "yes"; then
2767        AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2768        CPPFLAGS="$CPPFLAGS -I/usr/include/kqueue"
2769        NOTIFY_CFLAGS=$KQUEUE_CFLAGS
2770        NOTIFY_LIBS=$KQUEUE_LIBS
2771        NOTIFY_OBJ=kqueue.o
2772        NOTIFY_SUMMARY="yes -lkqueue"
2773     else
2774        AC_SEARCH_LIBS(kqueue, [])
2775        if test "$ac_cv_search_kqueue" != no; then
2776          AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2777          NOTIFY_OBJ=kqueue.o
2778          NOTIFY_SUMMARY="yes (kqueue)"
2779        fi
2780     fi ;;
2781 esac
2782
2783 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2784 dnl has been added in glib 2.24.  It has been tested under
2785 dnl GNU/Linux only.
2786 case $with_file_notification,$NOTIFY_OBJ in
2787   gfile,* | yes,)
2788     if test "${HAVE_NS}" = yes; then
2789        AC_MSG_ERROR(['--with-file-notification=gfile' is not supported in NextStep builds.
2790 Consider kqueue instead.])
2791     else
2792        EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2793        if test "$HAVE_GFILENOTIFY" = "yes"; then
2794           AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2795           NOTIFY_CFLAGS=$GFILENOTIFY_CFLAGS
2796           NOTIFY_LIBS=$GFILENOTIFY_LIBS
2797           NOTIFY_OBJ=gfilenotify.o
2798           NOTIFY_SUMMARY="yes -lgio (gfile)"
2799        fi
2800     fi ;;
2801 esac
2802
2803 case $with_file_notification,$NOTIFY_OBJ in
2804   yes,* | no,* | *,?*) ;;
2805   *) AC_MSG_ERROR([File notification '$with_file_notification' requested but requirements not found.]) ;;
2806 esac
2807
2808 if test -n "$NOTIFY_OBJ"; then
2809    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2810 fi
2811 AC_SUBST(NOTIFY_CFLAGS)
2812 AC_SUBST(NOTIFY_LIBS)
2813 AC_SUBST(NOTIFY_OBJ)
2814
2815 dnl Do not put whitespace before the #include statements below.
2816 dnl Older compilers (eg sunos4 cc) choke on it.
2817 HAVE_XAW3D=no
2818 LUCID_LIBW=
2819 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2820   if test "$with_xaw3d" != no; then
2821     AC_CACHE_VAL(emacs_cv_xaw3d,
2822     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2823 #include <X11/Intrinsic.h>
2824 #include <X11/Xaw3d/Simple.h>]],
2825       [[]])],
2826       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2827                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2828       emacs_cv_xaw3d=no)])
2829   else
2830     emacs_cv_xaw3d=no
2831   fi
2832   if test $emacs_cv_xaw3d = yes; then
2833     AC_MSG_CHECKING(for xaw3d)
2834     AC_MSG_RESULT([yes; using Lucid toolkit])
2835     USE_X_TOOLKIT=LUCID
2836     HAVE_XAW3D=yes
2837     LUCID_LIBW=-lXaw3d
2838     AC_DEFINE(HAVE_XAW3D, 1,
2839               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2840   else
2841     AC_MSG_CHECKING(for xaw3d)
2842     AC_MSG_RESULT(no)
2843     AC_MSG_CHECKING(for libXaw)
2844     AC_CACHE_VAL(emacs_cv_xaw,
2845     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2846 #include <X11/Intrinsic.h>
2847 #include <X11/Xaw/Simple.h>]],
2848       [[]])],
2849       emacs_cv_xaw=yes,
2850       emacs_cv_xaw=no)])
2851     if test $emacs_cv_xaw = yes; then
2852       AC_MSG_RESULT([yes; using Lucid toolkit])
2853       USE_X_TOOLKIT=LUCID
2854       LUCID_LIBW=-lXaw
2855     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2856       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2857     else
2858       AC_MSG_ERROR([No X toolkit could be found.
2859 If you are sure you want Emacs compiled without an X toolkit, pass
2860   --with-x-toolkit=no
2861 to configure.  Otherwise, install the development libraries for the toolkit
2862 that you want to use (e.g. Gtk+) and re-run configure.])
2863     fi
2864   fi
2865 fi
2866
2867 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2868
2869 LIBXTR6=
2870 LIBXMU=
2871 if test "${USE_X_TOOLKIT}" != "none"; then
2872   AC_MSG_CHECKING(X11 toolkit version)
2873   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2874   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2875 [[#if XtSpecificationRelease < 6
2876 fail;
2877 #endif
2878 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2879   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2880   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2881     AC_MSG_RESULT(6 or newer)
2882     AC_DEFINE(HAVE_X11XTR6, 1,
2883               [Define to 1 if you have the X11R6 or newer version of Xt.])
2884     LIBXTR6="-lSM -lICE"
2885     case "$opsys" in
2886       ## Use libw.a along with X11R6 Xt.
2887       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2888     esac
2889   else
2890     AC_MSG_RESULT(before 6)
2891   fi
2892
2893 dnl If using toolkit, check whether libXmu.a exists.
2894 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2895   OLDLIBS="$LIBS"
2896   if test x$HAVE_X11XTR6 = xyes; then
2897     OTHERLIBS='-lXt -lSM -lICE'
2898   else
2899     OTHERLIBS='-lXt'
2900   fi
2901   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2902   if test "X$LIBS" != "X$OLDLIBS"; then
2903     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2904   fi
2905   LIBS=$OLDLIBS
2906   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2907 fi
2908 AC_SUBST(LIBXTR6)
2909 AC_SUBST(LIBXMU)
2910
2911 LIBXP=
2912 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2913   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2914   if test -d /usr/include/openmotif; then
2915     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2916     emacs_cv_openmotif=yes
2917     case "$canonical" in
2918       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2919       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2920       ;;
2921       *)
2922       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2923     esac
2924   else
2925     emacs_cv_openmotif=no
2926   fi
2927   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2928   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2929     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2930 int x = 5;
2931 #else
2932 Motif version prior to 2.1.
2933 #endif]])],
2934     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2935   if test $emacs_cv_motif_version_2_1 = yes; then
2936     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2937     if test x$emacs_cv_openmotif = xyes; then
2938       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2939     fi
2940   else
2941     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2942     # We put this in CFLAGS temporarily to precede other -I options
2943     # that might be in CFLAGS temporarily.
2944     # We put this in CPPFLAGS where it precedes the other -I options.
2945     OLD_CPPFLAGS=$CPPFLAGS
2946     OLD_CFLAGS=$CFLAGS
2947     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2948     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2949     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2950       [[int x = 5;]])],
2951       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2952     if test $emacs_cv_lesstif = yes; then
2953       # Make sure this -I option remains in CPPFLAGS after it is set
2954       # back to REAL_CPPFLAGS.
2955       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2956       # have those other -I options anyway.  Ultimately, having this
2957       # directory ultimately in CPPFLAGS will be enough.
2958       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2959       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2960     else
2961       CFLAGS=$OLD_CFLAGS
2962       CPPFLAGS=$OLD_CPPFLAGS
2963     fi
2964   fi
2965   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2966     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2967 fi
2968
2969 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2970 dnl using Motif or Xaw3d is available, and unless
2971 dnl --with-toolkit-scroll-bars=no was specified.
2972
2973 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2974             [Define to 1 if we should use toolkit scroll bars.])dnl
2975 USE_TOOLKIT_SCROLL_BARS=no
2976 if test "${with_toolkit_scroll_bars}" != "no"; then
2977   if test "${USE_X_TOOLKIT}" != "none"; then
2978     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2979       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2980       HAVE_XAW3D=no
2981       USE_TOOLKIT_SCROLL_BARS=yes
2982     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2983       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2984       USE_TOOLKIT_SCROLL_BARS=yes
2985     fi
2986   elif test "${HAVE_GTK}" = "yes"; then
2987     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2988     USE_TOOLKIT_SCROLL_BARS=yes
2989   elif test "${HAVE_NS}" = "yes"; then
2990     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2991     USE_TOOLKIT_SCROLL_BARS=yes
2992   elif test "${HAVE_W32}" = "yes"; then
2993     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2994     USE_TOOLKIT_SCROLL_BARS=yes
2995   fi
2996 fi
2997
2998 dnl See if XIM is available.
2999 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3000           #include <X11/Xlib.h>
3001           #include <X11/Xresource.h>]],
3002          [[XIMProc  callback;]])],
3003          [HAVE_XIM=yes
3004          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
3005          HAVE_XIM=no)
3006
3007 dnl '--with-xim' now controls only the initial value of use_xim at run time.
3008
3009 if test "${with_xim}" != "no"; then
3010   AC_DEFINE(USE_XIM, 1,
3011             [Define to 1 if we should use XIM, if it is available.])
3012 fi
3013
3014
3015 if test "${HAVE_XIM}" != "no"; then
3016   late_CFLAGS=$CFLAGS
3017   if test "$GCC" = yes; then
3018     CFLAGS="$CFLAGS --pedantic-errors"
3019   fi
3020   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3021 #include <X11/Xlib.h>
3022 #include <X11/Xresource.h>]],
3023 [[Display *display;
3024 XrmDatabase db;
3025 char *res_name;
3026 char *res_class;
3027 XIMProc  callback;
3028 XPointer *client_data;
3029 #ifndef __GNUC__
3030 /* If we're not using GCC, it's probably not XFree86, and this is
3031    probably right, but we can't use something like --pedantic-errors.  */
3032 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
3033                                            char*, XIMProc, XPointer*);
3034 #endif
3035 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
3036    client_data);]])],
3037     [emacs_cv_arg6_star=yes])
3038   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
3039          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
3040 either XPointer or XPointer*.])dnl
3041   if test "$emacs_cv_arg6_star" = yes; then
3042     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
3043   else
3044     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
3045   fi
3046   CFLAGS=$late_CFLAGS
3047 fi
3048
3049 ### Start of font-backend (under any platform) section.
3050 # (nothing here yet -- this is a placeholder)
3051 ### End of font-backend (under any platform) section.
3052
3053 ### Start of font-backend (under X11) section.
3054 if test "${HAVE_X11}" = "yes"; then
3055     ## Use -lXft if available, unless '--with-xft=no'.
3056     HAVE_XFT=maybe
3057     if test "x${with_x}" = "xno"; then
3058       with_xft="no";
3059     fi
3060
3061     if test "$with_xft" != no; then
3062       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
3063       with_xft=$HAVE_FONTCONFIG
3064     fi
3065
3066     if test "x${with_xft}" != "xno"; then
3067
3068       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
3069       ## Because xftfont.c uses XRenderQueryExtension, we also
3070       ## need to link to -lXrender.
3071       HAVE_XRENDER=no
3072       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
3073       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
3074         OLD_CPPFLAGS="$CPPFLAGS"
3075         OLD_CFLAGS="$CFLAGS"
3076         OLD_LIBS="$LIBS"
3077         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
3078         CFLAGS="$CFLAGS $XFT_CFLAGS"
3079         XFT_LIBS="-lXrender $XFT_LIBS"
3080         LIBS="$XFT_LIBS $LIBS"
3081         AC_CHECK_HEADER(X11/Xft/Xft.h,
3082           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
3083           [[#include <X11/X.h>]])
3084
3085         if test "${HAVE_XFT}" = "yes"; then
3086           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
3087             AC_SUBST(XFT_LIBS)
3088           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
3089         fi                        # "${HAVE_XFT}" = "yes"
3090         CPPFLAGS=$OLD_CPPFLAGS
3091         CFLAGS=$OLD_CFLAGS
3092         LIBS=$OLD_LIBS
3093       fi                          # "$HAVE_XFT" != no
3094     fi                            # "x${with_xft}" != "xno"
3095
3096     ## We used to allow building with FreeType and without Xft.
3097     ## However, the ftx font backend driver is not in good shape.
3098     if test "$HAVE_XFT" != "yes"; then
3099        dnl For the "Does Emacs use" message at the end.
3100        HAVE_XFT=no
3101        HAVE_FREETYPE=no
3102     else
3103        dnl Strict linkers fail with
3104        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
3105        dnl if -lfreetype is not specified.
3106        dnl The following is needed to set FREETYPE_LIBS.
3107        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
3108
3109        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
3110     fi
3111
3112     HAVE_LIBOTF=no
3113     if test "${HAVE_FREETYPE}" = "yes"; then
3114       AC_DEFINE(HAVE_FREETYPE, 1,
3115                 [Define to 1 if using the freetype and fontconfig libraries.])
3116       if test "${with_libotf}" != "no"; then
3117         EMACS_CHECK_MODULES([LIBOTF], [libotf])
3118         if test "$HAVE_LIBOTF" = "yes"; then
3119           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
3120           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
3121                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
3122                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
3123           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
3124             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
3125                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
3126           fi
3127         fi
3128       fi
3129     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
3130     dnl Does the new font backend require it, or can it work without it?
3131     fi
3132
3133     HAVE_M17N_FLT=no
3134     if test "${HAVE_LIBOTF}" = yes; then
3135       if test "${with_m17n_flt}" != "no"; then
3136         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
3137         if test "$HAVE_M17N_FLT" = "yes"; then
3138           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
3139         fi
3140       fi
3141     fi
3142 else
3143     HAVE_XFT=no
3144     HAVE_FREETYPE=no
3145     HAVE_LIBOTF=no
3146     HAVE_M17N_FLT=no
3147 fi
3148
3149 ### End of font-backend (under X11) section.
3150
3151 AC_SUBST(FREETYPE_CFLAGS)
3152 AC_SUBST(FREETYPE_LIBS)
3153 AC_SUBST(FONTCONFIG_CFLAGS)
3154 AC_SUBST(FONTCONFIG_LIBS)
3155 AC_SUBST(LIBOTF_CFLAGS)
3156 AC_SUBST(LIBOTF_LIBS)
3157 AC_SUBST(M17N_FLT_CFLAGS)
3158 AC_SUBST(M17N_FLT_LIBS)
3159
3160 HAVE_CAIRO=no
3161 if test "${HAVE_X11}" = "yes"; then
3162   if test "${with_cairo}" != "no"; then
3163     CAIRO_REQUIRED=1.12.0
3164     CAIRO_MODULE="cairo >= $CAIRO_REQUIRED"
3165     EMACS_CHECK_MODULES(CAIRO, $CAIRO_MODULE)
3166     if test $HAVE_CAIRO = yes; then
3167       AC_DEFINE(USE_CAIRO, 1, [Define to 1 if using cairo.])
3168     else
3169       AC_MSG_ERROR([cairo requested but not found.])
3170     fi
3171
3172     CFLAGS="$CFLAGS $CAIRO_CFLAGS"
3173     LIBS="$LIBS $CAIRO_LIBS"
3174     AC_SUBST(CAIRO_CFLAGS)
3175     AC_SUBST(CAIRO_LIBS)
3176   fi
3177 fi
3178
3179 if test "${HAVE_X11}" = "yes"; then
3180   AC_CHECK_HEADER(X11/Xlib-xcb.h,
3181     AC_CHECK_LIB(xcb, xcb_translate_coordinates, HAVE_XCB=yes))
3182   if test "${HAVE_XCB}" = "yes"; then
3183     AC_CHECK_LIB(X11-xcb, XGetXCBConnection, HAVE_X11_XCB=yes)
3184     if test "${HAVE_X11_XCB}" = "yes"; then
3185       AC_DEFINE(USE_XCB, 1,
3186 [Define to 1 if you have the XCB library and X11-XCB library for mixed
3187    X11/XCB programming.])
3188       XCB_LIBS="-lX11-xcb -lxcb"
3189       AC_SUBST(XCB_LIBS)
3190     fi
3191   fi
3192 fi
3193
3194 ### Use -lXpm if available, unless '--with-xpm=no'.
3195 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
3196 ### In the Cygwin-w32 build, we need to use /usr/include/noX/X11/xpm.h
3197 ### rather than /usr/include/X11/xpm.h, so we set CPPFLAGS (and
3198 ### LDFLAGS) accordingly.
3199 HAVE_XPM=no
3200 LIBXPM=
3201 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3202   if test "${with_xpm}" != "no"; then
3203     SAVE_CPPFLAGS="$CPPFLAGS"
3204     SAVE_LDFLAGS="$LDFLAGS"
3205     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
3206     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3207     AC_CHECK_HEADER(X11/xpm.h,
3208       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3209     if test "${HAVE_XPM}" = "yes"; then
3210       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3211       AC_EGREP_CPP(no_return_alloc_pixels,
3212       [#include "X11/xpm.h"
3213 #ifndef XpmReturnAllocPixels
3214 no_return_alloc_pixels
3215 #endif
3216       ], HAVE_XPM=no, HAVE_XPM=yes)
3217
3218       if test "${HAVE_XPM}" = "yes"; then
3219         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3220         AC_MSG_RESULT(yes)
3221       else
3222         AC_MSG_RESULT(no)
3223         CPPFLAGS="$SAVE_CPPFLAGS"
3224         LDFLAGS="$SAVE_LDFLAGS"
3225       fi
3226     fi
3227   fi
3228
3229   if test "${HAVE_XPM}" = "yes"; then
3230     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3231     LIBXPM=-lXpm
3232   fi
3233 fi
3234
3235 if test "${HAVE_X11}" = "yes"; then
3236   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3237   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3238
3239   if test "${with_xpm}" != "no"; then
3240     AC_CHECK_HEADER(X11/xpm.h,
3241       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3242     if test "${HAVE_XPM}" = "yes"; then
3243       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3244       AC_EGREP_CPP(no_return_alloc_pixels,
3245       [#include "X11/xpm.h"
3246 #ifndef XpmReturnAllocPixels
3247 no_return_alloc_pixels
3248 #endif
3249       ], HAVE_XPM=no, HAVE_XPM=yes)
3250
3251       if test "${HAVE_XPM}" = "yes"; then
3252         AC_MSG_RESULT(yes)
3253       else
3254         AC_MSG_RESULT(no)
3255       fi
3256     fi
3257   fi
3258
3259   if test "${HAVE_XPM}" = "yes"; then
3260     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3261     LIBXPM=-lXpm
3262   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3263     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3264     LIBXPM=-lXpm
3265   fi
3266 fi
3267
3268 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3269 ### slightly different requirements wrt image libraries (it doesn't
3270 ### use -lXpm because it loads the xpm shared library dynamically at
3271 ### run time).
3272 if test "${opsys}" = "mingw32"; then
3273   if test "${with_xpm}" != "no"; then
3274     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3275 #define FOR_MSW 1])
3276   fi
3277
3278   if test "${HAVE_XPM}" = "yes"; then
3279     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3280   fi
3281 fi
3282
3283 AC_SUBST(LIBXPM)
3284
3285 ### Use -ljpeg if available, unless '--with-jpeg=no'.
3286 HAVE_JPEG=no
3287 LIBJPEG=
3288 if test "${with_jpeg}" != "no"; then
3289   AC_CACHE_CHECK([for jpeglib 6b or later],
3290     [emacs_cv_jpeglib],
3291     [OLD_LIBS=$LIBS
3292      for emacs_cv_jpeglib in yes -ljpeg no; do
3293        case $emacs_cv_jpeglib in
3294          yes) ;;
3295          no) break;;
3296          *) LIBS="$LIBS $emacs_cv_jpeglib";;
3297        esac
3298        AC_LINK_IFELSE(
3299          [AC_LANG_PROGRAM(
3300             [[#undef HAVE_STDLIB_H /* Avoid config.h/jpeglib.h collision.  */
3301               #include <stdio.h> /* jpeglib.h needs FILE and size_t.  */
3302               #include <jpeglib.h>
3303               #include <jerror.h>
3304               char verify[JPEG_LIB_VERSION < 62 ? -1 : 1];
3305               struct jpeg_decompress_struct cinfo;
3306             ]],
3307             [[
3308               jpeg_create_decompress (&cinfo);
3309               WARNMS (&cinfo, JWRN_JPEG_EOF);
3310               jpeg_destroy_decompress (&cinfo);
3311             ]])],
3312          [emacs_link_ok=yes],
3313          [emacs_link_ok=no])
3314        LIBS=$OLD_LIBS
3315        test $emacs_link_ok = yes && break
3316      done])
3317   if test "$emacs_cv_jpeglib" != no; then
3318     HAVE_JPEG=yes
3319     AC_DEFINE([HAVE_JPEG], 1,
3320       [Define to 1 if you have the jpeg library (typically -ljpeg).])
3321     ### mingw32 doesn't use -ljpeg, since it loads the library
3322     ### dynamically when needed, and doesn't want a run-time
3323     ### dependency on the jpeglib DLL.
3324     test "$emacs_cv_jpeglib" != yes && test "${opsys}" != "mingw32" \
3325     && LIBJPEG=$emacs_cv_jpeglib
3326   fi
3327 fi
3328 AC_SUBST(LIBJPEG)
3329
3330 HAVE_ZLIB=no
3331 LIBZ=
3332 if test "${with_zlib}" != "no"; then
3333   OLIBS=$LIBS
3334   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3335   LIBS=$OLIBS
3336   case $ac_cv_search_inflateEnd in
3337     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3338   esac
3339 fi
3340 if test "${HAVE_ZLIB}" = "yes"; then
3341   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3342   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3343   if test "${opsys}" = "mingw32"; then
3344      LIBZ=
3345   fi
3346 fi
3347 AC_SUBST(LIBZ)
3348
3349 ### Dynamic modules support
3350 LIBMODULES=
3351 HAVE_MODULES=no
3352 MODULES_OBJ=
3353 MODULES_SUFFIX=
3354 if test "${with_modules}" != "no"; then
3355   if test "$opsys" = "gnu-linux"; then
3356     LIBMODULES="-ldl"
3357     MODULES_SUFFIX=".so"
3358     HAVE_MODULES=yes
3359   elif test "$opsys" = "cygwin"; then
3360     MODULES_SUFFIX=".dll"
3361     HAVE_MODULES=yes
3362   elif test "$opsys" = "darwin"; then
3363     MODULES_SUFFIX=".so"
3364     HAVE_MODULES=yes
3365   elif test "$opsys" = "mingw32"; then
3366     MODULES_SUFFIX=".dll"
3367     HAVE_MODULES=yes
3368   else
3369     # BSD system have dlopen in the libc
3370     AC_CHECK_FUNC(dlopen, [MODULES_SUFFIX=".so"]
3371                           [HAVE_MODULES=yes], [])
3372   fi
3373
3374   if test "${HAVE_MODULES}" = no; then
3375     AC_MSG_ERROR([Dynamic modules are not supported on your system])
3376   else
3377     SAVE_LIBS=$LIBS
3378     LIBS="$LIBS $LIBMODULES"
3379     AC_CHECK_FUNCS([dladdr dlfunc])
3380     LIBS=$SAVE_LIBS
3381   fi
3382 fi
3383
3384 if test "${HAVE_MODULES}" = yes; then
3385    MODULES_OBJ="dynlib.o emacs-module.o"
3386    AC_DEFINE(HAVE_MODULES, 1, [Define to 1 if dynamic modules are enabled])
3387    AC_DEFINE_UNQUOTED(MODULES_SUFFIX, "$MODULES_SUFFIX",
3388      [System extension for dynamic libraries])
3389 fi
3390 AC_SUBST(MODULES_OBJ)
3391 AC_SUBST(LIBMODULES)
3392
3393 ### Use -lpng if available, unless '--with-png=no'.
3394 HAVE_PNG=no
3395 LIBPNG=
3396 PNG_CFLAGS=
3397 if test "${NS_IMPL_COCOA}" = yes; then
3398   : # Nothing to do
3399 elif test "${with_png}" != no; then
3400   # mingw32 loads the library dynamically.
3401   if test "$opsys" = mingw32; then
3402     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3403   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3404     AC_MSG_CHECKING([for png])
3405     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3406     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3407       # libpng-config does not work; configure by hand.
3408       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3409       # in /usr/include/libpng.
3410       if test -r /usr/include/libpng/png.h &&
3411          test ! -r /usr/include/png.h; then
3412         png_cflags=-I/usr/include/libpng
3413       else
3414         png_cflags=
3415       fi
3416       png_libs='-lpng'
3417     }
3418     SAVE_CFLAGS=$CFLAGS
3419     SAVE_LIBS=$LIBS
3420     CFLAGS="$CFLAGS $png_cflags"
3421     LIBS="$png_libs -lz -lm $LIBS"
3422     AC_LINK_IFELSE(
3423       [AC_LANG_PROGRAM([[#include <png.h>]],
3424          [[return !png_get_channels (0, 0);]])],
3425       [HAVE_PNG=yes
3426        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3427        LIBPNG=$png_libs
3428        # $LIBPNG requires explicit -lz in some cases.
3429        # We don't know what those cases are, exactly, so play it safe and
3430        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3431        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3432          LIBPNG="$LIBPNG -lz"
3433        fi])
3434     CFLAGS=$SAVE_CFLAGS
3435     LIBS=$SAVE_LIBS
3436     AC_MSG_RESULT([$HAVE_PNG])
3437   fi
3438 fi
3439 if test $HAVE_PNG = yes; then
3440   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3441
3442   SAVE_CFLAGS=$CFLAGS
3443   CFLAGS="$CFLAGS $PNG_CFLAGS"
3444   AC_CHECK_DECL([png_longjmp],
3445     [],
3446     [AC_DEFINE([PNG_DEPSTRUCT], [],
3447        [Define to empty to suppress deprecation warnings when building
3448         with --enable-gcc-warnings and with libpng versions before 1.5,
3449         which lack png_longjmp.])],
3450     [[#include <png.h>
3451     ]])
3452   CFLAGS=$SAVE_CFLAGS
3453 fi
3454 AC_SUBST(LIBPNG)
3455 AC_SUBST(PNG_CFLAGS)
3456
3457 ### Use -ltiff if available, unless '--with-tiff=no'.
3458 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3459 HAVE_TIFF=no
3460 LIBTIFF=
3461 if test "${opsys}" = "mingw32"; then
3462   if test "${with_tiff}" != "no"; then
3463     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3464   fi
3465   if test "${HAVE_TIFF}" = "yes"; then
3466     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3467   fi
3468 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3469   if test "${with_tiff}" != "no"; then
3470     AC_CHECK_HEADER(tiffio.h,
3471       [tifflibs="-lz -lm"
3472       # At least one tiff package requires the jpeg library.
3473       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3474       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3475   fi
3476
3477   if test "${HAVE_TIFF}" = "yes"; then
3478     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3479     dnl FIXME -lz -lm, as per libpng?
3480     LIBTIFF=-ltiff
3481   fi
3482 fi
3483 AC_SUBST(LIBTIFF)
3484
3485 ### Use -lgif or -lungif if available, unless '--with-gif=no'.
3486 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3487 HAVE_GIF=no
3488 LIBGIF=
3489 if test "${opsys}" = "mingw32"; then
3490   if test "${with_gif}" != "no"; then
3491     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3492   fi
3493   if test "${HAVE_GIF}" = "yes"; then
3494     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3495   fi
3496 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3497         || test "${HAVE_W32}" = "yes"; then
3498   AC_CHECK_HEADER(gif_lib.h,
3499 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3500 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3501     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3502         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3503
3504   if test "$HAVE_GIF" = yes; then
3505     LIBGIF=-lgif
3506   elif test "$HAVE_GIF" = maybe; then
3507 # If gif_lib.h but no libgif, try libungif.
3508     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3509     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3510   fi
3511
3512   if test "${HAVE_GIF}" = "yes"; then
3513     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3514   fi
3515 fi
3516 AC_SUBST(LIBGIF)
3517
3518 dnl Check for required libraries.
3519 if test "${HAVE_X11}" = "yes"; then
3520   MISSING=""
3521   WITH_NO=""
3522   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3523     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3524   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3525     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3526   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3527     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3528   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3529     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3530   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3531     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3532
3533   if test "X${MISSING}" != X; then
3534     AC_MSG_ERROR([The following required libraries were not found:
3535     $MISSING
3536 Maybe some development libraries/packages are missing?
3537 If you don't want to link with them give
3538     $WITH_NO
3539 as options to configure])
3540   fi
3541 fi
3542
3543 ### Use -lgpm if available, unless '--with-gpm=no'.
3544 HAVE_GPM=no
3545 LIBGPM=
3546 if test "${with_gpm}" != "no"; then
3547   AC_CHECK_HEADER(gpm.h,
3548     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3549
3550   if test "${HAVE_GPM}" = "yes"; then
3551     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3552     LIBGPM=-lgpm
3553   fi
3554 fi
3555 AC_SUBST(LIBGPM)
3556
3557 dnl Check for malloc/malloc.h on darwin
3558 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3559
3560 GNUSTEP_CFLAGS=
3561 ### Use NeXTstep API to implement GUI.
3562 if test "${HAVE_NS}" = "yes"; then
3563   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3564   if test "${NS_IMPL_COCOA}" = "yes"; then
3565     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3566   fi
3567   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3568     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3569     if test $NS_GNUSTEP_CONFIG != yes; then
3570       # See also .m.o rule in src/Makefile.in.  */
3571       # FIXME: are all these flags really needed?  Document here why.  */
3572       GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3573       ## Extra CFLAGS applied to src/*.m files.
3574       GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3575     fi
3576   fi
3577   OTHER_FILES=ns-app
3578 fi
3579
3580 ### Use session management (-lSM -lICE) if available
3581 HAVE_X_SM=no
3582 LIBXSM=
3583 if test "${HAVE_X11}" = "yes"; then
3584   AC_CHECK_HEADER(X11/SM/SMlib.h,
3585     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3586
3587   if test "${HAVE_X_SM}" = "yes"; then
3588     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3589     LIBXSM="-lSM -lICE"
3590   fi
3591 fi
3592 AC_SUBST(LIBXSM)
3593
3594 ### Use XRandr (-lXrandr) if available
3595 HAVE_XRANDR=no
3596 if test "${HAVE_X11}" = "yes"; then
3597   XRANDR_REQUIRED=1.2.2
3598   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3599   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3600   if test $HAVE_XRANDR = no; then
3601     # Test old way in case pkg-config doesn't have it (older machines).
3602     # Include Xrender.h by hand to work around bug in older Xrandr.h
3603     # (e.g. RHEL5) and silence (harmless) configure warning (bug#18465).
3604     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3605       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)],
3606       [], [AC_INCLUDES_DEFAULT
3607 #include <X11/extensions/Xrender.h>])
3608     if test $HAVE_XRANDR = yes; then
3609       XRANDR_LIBS=-lXrandr
3610     fi
3611   fi
3612   if test $HAVE_XRANDR = yes; then
3613     SAVE_CFLAGS="$CFLAGS"
3614     SAVE_LIBS="$LIBS"
3615     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3616     LIBS="$XRANDR_LIBS $LIBS"
3617     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3618     CFLAGS="$SAVE_CFLAGS"
3619     LIBS="$SAVE_LIBS"
3620
3621     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3622   fi
3623 fi
3624 AC_SUBST(XRANDR_CFLAGS)
3625 AC_SUBST(XRANDR_LIBS)
3626
3627 ### Use Xinerama (-lXinerama) if available
3628 HAVE_XINERAMA=no
3629 if test "${HAVE_X11}" = "yes"; then
3630   XINERAMA_REQUIRED=1.0.2
3631   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3632   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3633   if test $HAVE_XINERAMA = no; then
3634     # Test old way in case pkg-config doesn't have it (older machines).
3635     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3636       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3637     if test $HAVE_XINERAMA = yes; then
3638       XINERAMA_LIBS=-lXinerama
3639     fi
3640   fi
3641   if test $HAVE_XINERAMA = yes; then
3642     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3643   fi
3644 fi
3645 AC_SUBST(XINERAMA_CFLAGS)
3646 AC_SUBST(XINERAMA_LIBS)
3647
3648 ### Use Xfixes (-lXfixes) if available
3649 HAVE_XFIXES=no
3650 if test "${HAVE_X11}" = "yes"; then
3651   XFIXES_REQUIRED=4.0.0
3652   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3653   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3654   if test $HAVE_XFIXES = no; then
3655     # Test old way in case pkg-config doesn't have it (older machines).
3656     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3657       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3658     if test $HAVE_XFIXES = yes; then
3659       XFIXES_LIBS=-lXfixes
3660     fi
3661   fi
3662   if test $HAVE_XFIXES = yes; then
3663     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3664   fi
3665 fi
3666 AC_SUBST(XFIXES_CFLAGS)
3667 AC_SUBST(XFIXES_LIBS)
3668
3669 ### Use libxml (-lxml2) if available
3670 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3671 HAVE_LIBXML2=no
3672 if test "${with_xml2}" != "no"; then
3673   ### I'm not sure what the version number should be, so I just guessed.
3674   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3675   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3676   if test "${HAVE_LIBXML2}" != "yes" && test "$opsys" = "darwin"; then
3677     SAVE_CPPFLAGS="$CPPFLAGS"
3678     if test -z "$xcsdkdir" -a -n "$XCRUN" -a ! -d /usr/include; then
3679       dnl /usr/include is not found.  Try Xcode SDK dir if it is sane.
3680       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
3681       case $xcsdkdir in
3682         *[[\\\"\#\$\&\'\`$am_lf\ \      ]]*)
3683         xcsdkdir="" ;;
3684       esac
3685     fi
3686     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3687     AC_CHECK_HEADER(libxml/HTMLparser.h,
3688       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3689                      [#include <libxml/HTMLparser.h>])])
3690     CPPFLAGS="$SAVE_CPPFLAGS"
3691     if test "${HAVE_LIBXML2}" = "yes"; then
3692       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3693       LIBXML2_LIBS="-lxml2"
3694     fi
3695   fi
3696   if test "${HAVE_LIBXML2}" = "yes"; then
3697     if test "${opsys}" != "mingw32"; then
3698       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no,
3699         [$LIBXML2_LIBS])
3700     else
3701       LIBXML2_LIBS=""
3702     fi
3703     if test "${HAVE_LIBXML2}" = "yes"; then
3704       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3705     else
3706       LIBXML2_LIBS=""
3707       LIBXML2_CFLAGS=""
3708     fi
3709   fi
3710 fi
3711 AC_SUBST(LIBXML2_LIBS)
3712 AC_SUBST(LIBXML2_CFLAGS)
3713
3714 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3715 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3716 if test "${opsys}" = "mingw32"; then
3717   emacs_cv_netdb_declares_h_errno=yes
3718 fi
3719 AC_CACHE_CHECK(whether netdb declares h_errno,
3720                emacs_cv_netdb_declares_h_errno,
3721 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3722   [[return h_errno;]])],
3723   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3724 if test $emacs_cv_netdb_declares_h_errno = yes; then
3725   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3726 fi
3727
3728 # Check for mail-locking functions in a "mail" library.  Probably this should
3729 # have the same check as for liblockfile below.
3730 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3731 if test $have_mail = yes; then
3732   LIBS_MAIL=-lmail
3733   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the 'mail' library (-lmail).])
3734
3735   OLD_LIBS=$LIBS
3736   LIBS="$LIBS_MAIL $LIBS"
3737   AC_CHECK_FUNCS(touchlock)
3738   LIBS=$OLD_LIBS
3739 else
3740   LIBS_MAIL=
3741 fi
3742 dnl Debian, at least:
3743 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3744 if test $have_lockfile = yes; then
3745    LIBS_MAIL=-llockfile
3746    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the 'lockfile' library (-llockfile).])
3747 else
3748 # If we have the shared liblockfile, assume we must use it for mail
3749 # locking (e.g. Debian).  If we couldn't link against liblockfile
3750 # (no liblockfile.a installed), ensure that we don't need to.
3751   dnl This works for files generally, not just executables.
3752   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3753   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3754                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3755   if test $ac_cv_prog_liblockfile = yes; then
3756     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3757 This probably means that movemail could lose mail.
3758 There may be a 'development' package to install containing liblockfile.])
3759   fi
3760 fi
3761 AC_CHECK_HEADERS_ONCE(maillock.h)
3762 AC_SUBST(LIBS_MAIL)
3763
3764 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3765 ## interlock access to the mail spool.  The alternative is a lock file named
3766 ## /usr/spool/mail/$USER.lock.
3767 mail_lock=no
3768 case "$opsys" in
3769   aix4-2) mail_lock="lockf" ;;
3770
3771   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3772
3773   ## On GNU/Linux systems, both methods are used by various mail programs.
3774   ## I assume most people are using newer mailers that have heard of flock.
3775   ## Change this if you need to.
3776   ## Debian contains a patch which says: "On Debian/GNU/Linux systems,
3777   ## configure gets the right answers, and that means *NOT* using flock.
3778   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3779   ## for details." and then uses '#ifdef DEBIAN'.  Unfortunately the
3780   ## Debian maintainer hasn't provided a clean fix for Emacs.
3781   ## movemail.c will use 'maillock' when MAILDIR, HAVE_LIBMAIL and
3782   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3783   ## correct logic.  -- fx
3784   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3785   ## liblockfile is a Free Software replacement for libmail, used on
3786   ## Debian systems and elsewhere. -rfr.
3787   gnu-*)
3788     mail_lock="flock"
3789     if test $have_mail = yes || test $have_lockfile = yes; then
3790       test $ac_cv_header_maillock_h = yes && mail_lock=no
3791     fi
3792     ;;
3793
3794   mingw32)
3795     mail_lock="none-needed" ;;
3796 esac
3797
3798 BLESSMAIL_TARGET=
3799 case "$mail_lock" in
3800   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3801
3802   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3803
3804   none-needed) ;;
3805
3806   *) BLESSMAIL_TARGET="need-blessmail" ;;
3807 esac
3808 AC_SUBST(BLESSMAIL_TARGET)
3809
3810 OLD_LIBS=$LIBS
3811 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3812 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3813 getrusage get_current_dir_name \
3814 lrand48 random rint \
3815 select getpagesize setlocale newlocale \
3816 getrlimit setrlimit shutdown getaddrinfo \
3817 pthread_sigmask strsignal setitimer \
3818 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3819 gai_strerror sync \
3820 getpwent endpwent getgrent endgrent \
3821 cfmakeraw cfsetspeed copysign __executable_start log2)
3822 LIBS=$OLD_LIBS
3823
3824 dnl No need to check for posix_memalign if aligned_alloc works.
3825 AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3826 AC_CHECK_DECLS([aligned_alloc], [], [], [[#include <stdlib.h>]])
3827
3828 dnl Cannot use AC_CHECK_FUNCS
3829 AC_CACHE_CHECK([for __builtin_unwind_init],
3830                emacs_cv_func___builtin_unwind_init,
3831 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3832                 emacs_cv_func___builtin_unwind_init=yes,
3833                 emacs_cv_func___builtin_unwind_init=no)])
3834 if test $emacs_cv_func___builtin_unwind_init = yes; then
3835   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3836             [Define to 1 if you have the '__builtin_unwind_init' function.])
3837 fi
3838
3839 AC_CHECK_HEADERS_ONCE(sys/un.h)
3840
3841 AC_FUNC_FSEEKO
3842
3843 # UNIX98 PTYs.
3844 AC_CHECK_FUNCS(grantpt)
3845
3846 # PTY-related GNU extensions.
3847 AC_CHECK_FUNCS(getpt posix_openpt)
3848
3849 # Check this now, so that we will NOT find the above functions in ncurses.
3850 # That is because we have not set up to link ncurses in lib-src.
3851 # It's better to believe a function is not available
3852 # than to expect to find it in ncurses.
3853 # Also we need tputs and friends to be able to build at all.
3854 AC_MSG_CHECKING([for library containing tputs])
3855 # Run a test program that contains a call to tputs, a call that is
3856 # never executed.  This tests whether a pre-'main' dynamic linker
3857 # works with the library.  It's too much trouble to actually call
3858 # tputs in the test program, due to portability hassles.  When
3859 # cross-compiling, assume the test program will run if it links.
3860 AC_DEFUN([tputs_link_source], [
3861   AC_LANG_SOURCE(
3862      [[extern void tputs (const char *, int, int (*)(int));
3863        int main (int argc, char **argv)
3864        {
3865           if (argc == 10000)
3866             tputs (argv[0], 0, 0);
3867           return 0;
3868        }]])
3869 ])
3870 if test "${opsys}" = "mingw32"; then
3871   msg='none required'
3872 else
3873   # Maybe curses should be tried earlier?
3874   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3875   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3876     OLIBS=$LIBS
3877     if test -z "$tputs_library"; then
3878       LIBS_TERMCAP=
3879       msg='none required'
3880     else
3881       LIBS_TERMCAP=-l$tputs_library
3882       msg=$LIBS_TERMCAP
3883       LIBS="$LIBS_TERMCAP $LIBS"
3884     fi
3885     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3886       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3887     LIBS=$OLIBS
3888     if test "X$msg" != Xno; then
3889       break
3890     fi
3891   done
3892 fi
3893 AC_MSG_RESULT([$msg])
3894 if test "X$msg" = Xno; then
3895   AC_MSG_ERROR([The required function 'tputs' was not found in any library.
3896 The following libraries were tried (in order):
3897   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3898 Please try installing whichever of these libraries is most appropriate
3899 for your system, together with its header files.
3900 For example, a libncurses-dev(el) or similar package.])
3901 fi
3902
3903 ## Use termcap instead of terminfo?
3904 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3905 TERMINFO=yes
3906 ## FIXME?  In the cases below where we unconditionally set
3907 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3908 ## if that was found above to have tputs.
3909 ## Should we use the gnu* logic everywhere?
3910 case "$opsys" in
3911   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3912   ##  The ncurses library has been moved out of the System framework in
3913   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3914   ##  option to use it.
3915   darwin) LIBS_TERMCAP="-lncurses" ;;
3916
3917   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3918
3919   freebsd)
3920     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3921     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3922     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3923 [[#if __FreeBSD_version < 400000
3924 fail;
3925 #endif
3926 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3927
3928     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3929
3930     if test $emacs_cv_freebsd_terminfo = yes; then
3931       LIBS_TERMCAP="-lncurses"
3932     else
3933       TERMINFO=no
3934       LIBS_TERMCAP="-ltermcap"
3935     fi
3936     ;;
3937
3938   mingw32)
3939     TERMINFO=no
3940     LIBS_TERMCAP=
3941     ;;
3942
3943   netbsd)
3944     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3945       TERMINFO=no
3946       LIBS_TERMCAP="-ltermcap"
3947     fi
3948     ;;
3949
3950   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3951
3952   ## hpux: Make sure we get select from libc rather than from libcurses
3953   ##  because libcurses on HPUX 10.10 has a broken version of select.
3954   ##  We used to use -lc -lcurses, but this may be cleaner.
3955   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3956   # set that way, now it uses the default).  Isn't this a contradiction?
3957   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3958
3959 esac
3960
3961 TERMCAP_OBJ=tparam.o
3962 if test $TERMINFO = yes; then
3963   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3964   TERMCAP_OBJ=terminfo.o
3965 fi
3966 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3967   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3968 fi
3969 AC_SUBST(LIBS_TERMCAP)
3970 AC_SUBST(TERMCAP_OBJ)
3971
3972 # GNU/Linux-specific timer functions.
3973 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
3974   [AC_COMPILE_IFELSE(
3975      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
3976                       ]],
3977                       [[timerfd_create (CLOCK_REALTIME,
3978                                         TFD_CLOEXEC | TFD_NONBLOCK);
3979                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
3980      [emacs_cv_have_timerfd=yes],
3981      [emacs_cv_have_timerfd=no])])
3982 if test "$emacs_cv_have_timerfd" = yes; then
3983   AC_DEFINE([HAVE_TIMERFD], 1,
3984     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
3985 fi
3986
3987 # Alternate stack for signal handlers.
3988 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
3989                [emacs_cv_alternate_stack],
3990   [AC_COMPILE_IFELSE(
3991      [AC_LANG_PROGRAM([[#include <signal.h>
3992                       ]],
3993                       [[stack_t ss;
3994                         struct sigaction sa;
3995                         ss.ss_sp = malloc (SIGSTKSZ);
3996                         ss.ss_size = SIGSTKSZ;
3997                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
3998                         sigaltstack (&ss, 0);
3999                         sigaction (SIGSEGV, &sa, 0);]])],
4000      [emacs_cv_alternate_stack=yes],
4001      [emacs_cv_alternate_stack=no])])
4002
4003 # Do we have res_init, for detecting changes in /etc/resolv.conf?
4004 # On Darwin, res_init appears not to be useful: see bug#562 and
4005 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
4006 resolv=no
4007
4008 if test $opsys != darwin; then
4009
4010   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
4011 #include <arpa/nameser.h>
4012 #include <resolv.h>]],
4013     [[return res_init();]])],
4014     have_res_init=yes, have_res_init=no)
4015   if test "$have_res_init" = no; then
4016     OLIBS="$LIBS"
4017     LIBS="$LIBS -lresolv"
4018     AC_MSG_CHECKING(for res_init with -lresolv)
4019     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
4020 #include <arpa/nameser.h>
4021 #include <resolv.h>]],
4022       [[return res_init();]])],
4023       have_res_init=yes, have_res_init=no)
4024     AC_MSG_RESULT($have_res_init)
4025     if test "$have_res_init" = yes ; then
4026       resolv=yes
4027     fi
4028     LIBS="$OLIBS"
4029   fi
4030
4031   if test "$have_res_init" = yes; then
4032     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
4033   fi
4034 fi                              dnl !darwin
4035
4036 # Do we need the Hesiod library to provide the support routines?
4037 dnl FIXME?  Should we be skipping this on Darwin too?
4038 LIBHESIOD=
4039 if test "$with_hesiod" != no ; then
4040   # Don't set $LIBS here -- see comments above.  FIXME which comments?
4041   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
4042      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
4043                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
4044   if test "$resolv" = yes ; then
4045     RESOLVLIB=-lresolv
4046   else
4047     RESOLVLIB=
4048   fi
4049   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
4050         hesiod=yes, :, $RESOLVLIB)])
4051
4052   if test x"$hesiod" = xyes; then
4053     LIBHESIOD=-lhesiod
4054   fi
4055 fi
4056 AC_SUBST(LIBHESIOD)
4057
4058 # Do we need libresolv (due to res_init or Hesiod)?
4059 if test "$resolv" = yes && test $opsys != darwin; then
4060   LIBRESOLV=-lresolv
4061 else
4062   LIBRESOLV=
4063 fi
4064 AC_SUBST(LIBRESOLV)
4065
4066 # These tell us which Kerberos-related libraries to use.
4067 COM_ERRLIB=
4068 CRYPTOLIB=
4069 KRB5LIB=
4070 DESLIB=
4071 KRB4LIB=
4072
4073 if test "${with_kerberos}" != no; then
4074   OLD_LIBS=$LIBS
4075   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
4076   if test $have_com_err = yes; then
4077     COM_ERRLIB=-lcom_err
4078     LIBS="$COM_ERRLIB $LIBS"
4079   fi
4080   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
4081   if test $have_crypto = yes; then
4082     CRYPTOLIB=-lcrypto
4083     LIBS="$CRYPTOLIB $LIBS"
4084   fi
4085   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
4086   if test $have_k5crypto = yes; then
4087     CRYPTOLIB=-lk5crypto
4088     LIBS="$CRYPTOLIB $LIBS"
4089   fi
4090   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
4091   if test $have_krb5=yes; then
4092     KRB5LIB=-lkrb5
4093     LIBS="$KRB5LIB $LIBS"
4094   fi
4095   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
4096   if test "${with_kerberos5}" = no; then
4097     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
4098     if test $have_des425 = yes; then
4099       DESLIB=-ldes425
4100       LIBS="$DESLIB $LIBS"
4101     else
4102       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
4103       if test $have_des = yes; then
4104         DESLIB=-ldes
4105         LIBS="$DESLIB $LIBS"
4106       fi
4107     fi
4108     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
4109     if test $have_krb4 = yes; then
4110       KRB4LIB=-lkrb4
4111       LIBS="$KRB4LIB $LIBS"
4112     else
4113       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
4114       if test $have_krb = yes; then
4115         KRB4LIB=-lkrb
4116         LIBS="$KRB4LIB $LIBS"
4117       fi
4118     fi
4119   fi
4120
4121   if test "${with_kerberos5}" != no; then
4122     AC_CHECK_HEADERS(krb5.h,
4123       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
4124                         [#include <krb5.h>])])
4125   else
4126     AC_CHECK_HEADERS(krb.h,,
4127                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
4128                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
4129   fi
4130   AC_CHECK_HEADERS(com_err.h)
4131   LIBS=$OLD_LIBS
4132 fi
4133
4134 AC_SUBST(COM_ERRLIB)
4135 AC_SUBST(CRYPTOLIB)
4136 AC_SUBST(KRB5LIB)
4137 AC_SUBST(DESLIB)
4138 AC_SUBST(KRB4LIB)
4139
4140 AC_CHECK_HEADERS(valgrind/valgrind.h)
4141
4142 AC_CHECK_MEMBERS([struct unipair.unicode], [], [], [[#include <linux/kd.h>]])
4143
4144 AC_CHECK_FUNCS_ONCE(tzset)
4145
4146 ok_so_far=yes
4147 AC_CHECK_FUNC(socket, , ok_so_far=no)
4148 if test $ok_so_far = yes; then
4149   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
4150 fi
4151 if test $ok_so_far = yes; then
4152   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
4153 fi
4154 if test $ok_so_far = yes; then
4155 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
4156   AC_DEFINE(HAVE_INET_SOCKETS, 1,
4157             [Define to 1 if you have inet sockets.])
4158 fi
4159
4160 AC_FUNC_FORK
4161
4162 AC_CHECK_FUNCS(snprintf)
4163
4164 dnl Check for glib.  This differs from other library checks in that
4165 dnl Emacs need not link to glib unless some other library is already
4166 dnl linking to glib.  Although glib provides no facilities that Emacs
4167 dnl needs for its own purposes, when glib is present Emacs needs to
4168 dnl use primitives like g_main_context_query to avoid clashing with
4169 dnl glib at a low level.
4170 dnl
4171 dnl Check this late, since it depends on $GTK_CFLAGS etc.
4172 XGSELOBJ=
4173 OLDCFLAGS="$CFLAGS"
4174 OLDLIBS="$LIBS"
4175 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
4176 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
4177 CFLAGS="$CFLAGS $NOTIFY_CFLAGS $CAIRO_CFLAGS"
4178 LIBS="$LIBS $NOTIFY_LIBS $CAIRO_LIBS"
4179 AC_MSG_CHECKING([whether GLib is linked in])
4180 AC_LINK_IFELSE([AC_LANG_PROGRAM(
4181         [[#include <glib.h>
4182         ]],
4183         [[g_print ("Hello world");]])],
4184      [links_glib=yes],
4185      [links_glib=no])
4186 AC_MSG_RESULT([$links_glib])
4187 if test "${links_glib}" = "yes"; then
4188   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
4189   if test "$HAVE_NS" = no;then
4190     XGSELOBJ=xgselect.o
4191   fi
4192 fi
4193 CFLAGS="$OLDCFLAGS"
4194 LIBS="$OLDLIBS"
4195 AC_SUBST(XGSELOBJ)
4196
4197 dnl Adapted from Haible's version.
4198 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
4199   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
4200     [[char* cs = nl_langinfo(CODESET);]])],
4201     emacs_cv_langinfo_codeset=yes,
4202     emacs_cv_langinfo_codeset=no)
4203   ])
4204 if test $emacs_cv_langinfo_codeset = yes; then
4205   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
4206     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
4207 fi
4208
4209 AC_TYPE_MBSTATE_T
4210
4211 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
4212 dnl how the tty code is related to POSIX and/or other versions of termios.
4213 dnl The following looks like a useful start.
4214 dnl
4215 dnl AC_SYS_POSIX_TERMIOS
4216 dnl if test $ac_cv_sys_posix_termios = yes; then
4217 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
4218 dnl                                and macros for terminal control.])
4219 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
4220 dnl fi
4221
4222 dnl Turned on June 1996 supposing nobody will mind it.
4223 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
4224 if test "${opsys}" != "mingw32"; then
4225    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
4226      in the full name stands for the login id.])
4227 fi
4228
4229 dnl Everybody supports this, except MS.
4230 dnl Seems like the kind of thing we should be testing for, though.
4231 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4232 if test "${opsys}" != "mingw32"; then
4233   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4234 fi
4235
4236 dnl Everybody supports this, except MS-DOS.
4237 dnl Seems like the kind of thing we should be testing for, though.
4238 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4239 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4240   4.2-compatible sockets.])
4241
4242 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4243
4244 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4245   a null file, or a data sink.])
4246 if test "${opsys}" = "mingw32"; then
4247   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4248 else
4249   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4250 fi
4251
4252 if test "${opsys}" = "mingw32"; then
4253   SEPCHAR=';'
4254 else
4255   SEPCHAR=':'
4256 fi
4257 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4258 dnl This is for MinGW, and is used in test/Makefile.in.
4259 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4260 dnl decides that a command-line argument to be passed to a MinGW program
4261 dnl is a PATH-style list of directories.  But that heuristics plays it
4262 dnl safe, and only does the replacement when it is _absolutely_ sure it
4263 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4264 dnl which breaks in-tree builds.  So we do this manually instead.
4265 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4266 dnl be computed as ':' in MSYS Bash.
4267 AC_SUBST(SEPCHAR)
4268
4269 dnl Everybody supports this, except MS-DOS.
4270 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4271
4272 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4273
4274
4275 AC_DEFINE(DIRECTORY_SEP, ['/'],
4276   [Character that separates directories in a file name.])
4277
4278 if test "${opsys}" = "mingw32"; then
4279   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4280     [Returns true if character is a device separator.])
4281
4282   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4283     [Returns true if character is a directory separator.])
4284
4285   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4286     [Returns true if character is any form of separator.])
4287 else
4288   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4289     [Returns true if character is a device separator.])
4290
4291   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4292     [Returns true if character is a directory separator.])
4293
4294   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4295     [Returns true if character is any form of separator.])
4296 fi
4297
4298 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4299
4300 case $opsys in
4301   aix4-2)
4302     dnl Unfortunately without libXmu we cannot support EditRes.
4303     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4304       AC_DEFINE(NO_EDITRES, 1)
4305     fi
4306     ;;
4307
4308   hpux*)
4309     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4310     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4311     AC_DEFINE(NO_EDITRES, 1)
4312     ;;
4313 esac
4314
4315
4316 case $opsys in
4317   irix6-5 | sol2* | unixware )
4318     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4319     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4320     dnl need the constant to dimension an array.  So wire in the appropriate
4321     dnl value here.
4322     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4323     ;;
4324 esac
4325
4326 emacs_broken_SIGIO=no
4327
4328 case $opsys in
4329   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4330   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4331   hpux* | irix6-5 | nacl | openbsd | sol2* | unixware )
4332     emacs_broken_SIGIO=yes
4333     ;;
4334
4335   aix4-2)
4336     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4337     dnl the way this system works, libc functions that return malloced
4338     dnl memory use the libc malloc implementation. Calling xfree or
4339     dnl xrealloc on the results of such functions results in a crash.
4340     dnl
4341     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4342     dnl but that does not currently work on this system.
4343     dnl
4344     dnl It is possible to completely override the malloc implementation on
4345     dnl AIX, but that involves putting the malloc functions in a shared
4346     dnl library and setting the MALLOCTYPE environment variable to point to
4347     dnl that shared library.
4348     dnl
4349     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4350     dnl to avoid a crash just use the Emacs implementation for that function.
4351     dnl
4352     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4353     dnl of this file, so that we do not check for get_current_dir_name
4354     dnl on AIX.  But that might be fragile if something else ends
4355     dnl up testing for get_current_dir_name as a dependency.
4356     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4357       get_current_dir_name should not be used.])
4358     ;;
4359
4360   freebsd)
4361     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4362     dnl writes/reads on a PTY, read(2) returns bogus data:
4363     dnl
4364     dnl write(2)  1022 bytes
4365     dnl write(2)   954 bytes, get EAGAIN
4366     dnl read(2)   1024 bytes in process_read_output
4367     dnl read(2)     11 bytes in process_read_output
4368     dnl
4369     dnl That is, read(2) returns more bytes than have ever been written
4370     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4371     dnl successfully after processing (for example with CRs added if the
4372     dnl terminal is set up that way which it is here).  The same bytes will
4373     dnl be seen again in a later read(2), without the CRs.
4374     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4375       work around an issue when reading from a PTY.])
4376     ;;
4377 esac
4378
4379 case $opsys in
4380   gnu-* | sol2-10 )
4381     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4382     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4383   ;;
4384 esac
4385
4386 case $opsys in
4387   darwin | dragonfly | freebsd | netbsd | openbsd )
4388     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4389       close a pty to make it a controlling terminal (it is already a
4390       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4391   ;;
4392 esac
4393
4394 dnl FIXME Surely we can test for this rather than hard-code it.
4395 case $opsys in
4396   netbsd | openbsd) sound_device="/dev/audio" ;;
4397   *) sound_device="/dev/dsp" ;;
4398 esac
4399
4400 dnl Used in sound.c
4401 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4402   [Name of the default sound device.])
4403
4404
4405 dnl Emacs can read input using SIGIO and buffering characters itself,
4406 dnl or using CBREAK mode and making C-g cause SIGINT.
4407 dnl The choice is controlled by the variable interrupt_input.
4408 dnl
4409 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4410 dnl
4411 dnl Emacs uses the presence of the USABLE_SIGIO macro
4412 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4413 dnl INTERRUPT_INPUT to decide whether to use it by default.
4414 dnl
4415 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4416 dnl CBREAK mode has two disadvantages
4417 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4418 dnl I hear that in system V this problem does not exist.
4419 dnl 2) Control-G causes output to be discarded.
4420 dnl I do not know whether this can be fixed in system V.
4421 dnl
4422 dnl Another method of doing input is planned but not implemented.
4423 dnl It would have Emacs fork off a separate process
4424 dnl to read the input and send it to the true Emacs process
4425 dnl through a pipe.
4426 case $opsys in
4427   darwin | gnu-linux | gnu-kfreebsd )
4428     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4429   ;;
4430 esac
4431
4432
4433 dnl If the system's imake configuration file defines 'NeedWidePrototypes'
4434 dnl as 'NO', we must define NARROWPROTO manually.  Such a define is
4435 dnl generated in the Makefile generated by 'xmkmf'.  If we don't define
4436 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4437 dnl taking float or double parameters.
4438 case $opsys in
4439   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4440     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4441       file defines 'NeedWidePrototypes' as 'NO'.])
4442   ;;
4443 esac
4444
4445
4446 dnl Used in process.c, this must be a loop, even if it only runs once.
4447 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4448 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4449 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4450 dnl trying suffixes 0-16.
4451 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4452   first PTY, if PTYs are supported.])
4453 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4454 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4455   end of a PTY, if non-standard.])
4456 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4457   end of a PTY, if non-standard.])
4458
4459 case $opsys in
4460   aix4-2 )
4461     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4462     dnl You allocate a pty by opening /dev/ptc to get the master side.
4463     dnl To get the name of the slave side, you just ttyname() the master side.
4464     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4465     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4466     ;;
4467
4468   cygwin )
4469     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4470     dnl multi-line AC_DEFINEs are hard. :(
4471     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4472     AC_DEFINE(PTY_NAME_SPRINTF, [])
4473     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4474     ;;
4475
4476   gnu | openbsd )
4477     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4478     ;;
4479
4480   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd | darwin | nacl )
4481     dnl if HAVE_GRANTPT
4482     if test "x$ac_cv_func_grantpt" = xyes; then
4483       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4484       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4485       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4486       dnl to prevent sigchld_handler from intercepting the child's death.
4487       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4488       dnl if HAVE_POSIX_OPENPT
4489       if test "x$ac_cv_func_posix_openpt" = xyes; then
4490         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4491         AC_DEFINE(PTY_NAME_SPRINTF, [])
4492       dnl if HAVE_GETPT
4493       elif test "x$ac_cv_func_getpt" = xyes; then
4494         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4495         AC_DEFINE(PTY_NAME_SPRINTF, [])
4496       else
4497         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4498       fi
4499     else
4500       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4501     fi
4502     ;;
4503
4504   hpux*)
4505     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4506     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4507     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4508     ;;
4509
4510   irix6-5 )
4511     dnl It looks like this cannot be right, because it is not a loop.
4512     dnl However, process.c actually does this:
4513     dnl # ifndef __sgi
4514     dnl   continue;
4515     dnl # else
4516     dnl   return -1;
4517     dnl # endif
4518     dnl which presumably makes it OK, since irix == sgi (?).
4519     dnl FIXME it seems like this special treatment is unnecessary?
4520     dnl Why can't irix use a single-trip loop like eg cygwin?
4521     AC_DEFINE(PTY_ITERATION, [])
4522     dnl Not used, because PTY_ITERATION is defined.
4523     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4524     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4525     dnl No need to get the pty name at all.
4526     AC_DEFINE(PTY_NAME_SPRINTF, [])
4527     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4528     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4529     ;;
4530
4531   sol2* )
4532     dnl On SysVr4, grantpt(3) forks a subprocess, so do not use
4533     dnl O_CLOEXEC when opening the pty, and keep the SIGCHLD handler
4534     dnl from intercepting that death.  If any child but grantpt's should die
4535     dnl within, it should be caught after sigrelse(2).
4536     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4537     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4538     ;;
4539
4540   unixware )
4541     dnl Comments are as per sol2*.
4542     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4543     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4544     ;;
4545 esac
4546
4547
4548 case $opsys in
4549   sol2* | unixware )
4550     dnl This change means that we don't loop through allocate_pty too
4551     dnl many times in the (rare) event of a failure.
4552     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4553     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4554     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4555     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (forkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (forkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (forkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4556     ;;
4557 esac
4558
4559
4560 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4561 "typing" a signal character on the pty.])
4562
4563 case $opsys in
4564   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4565   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4566   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4567     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4568     ;;
4569
4570   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4571   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4572   gnu-linux | gnu-kfreebsd )
4573
4574     AC_MSG_CHECKING([for signals via characters])
4575     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4576 #include <linux/version.h>
4577 #if LINUX_VERSION_CODE < 0x20400
4578 # error "Linux version too old"
4579 #endif
4580       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4581
4582     AC_MSG_RESULT([$emacs_signals_via_chars])
4583     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4584     ;;
4585 esac
4586
4587
4588 AH_TEMPLATE(TAB3, [Undocumented.])
4589
4590 case $opsys in
4591   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4592
4593   gnu | dragonfly | freebsd | netbsd | openbsd )
4594     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4595     AC_DEFINE(TAB3, OXTABS)
4596     ;;
4597
4598   gnu-linux | gnu-kfreebsd )
4599     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4600 #ifndef __ia64__
4601 # error "not ia64"
4602 #endif
4603       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4604         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4605         [Mark a secondary stack, like the register stack on the ia64.]), [])
4606     ;;
4607
4608   hpux*)
4609     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4610       run_time_remap; for HPUX.])
4611     ;;
4612 esac
4613
4614
4615 dnl This won't be used automatically yet.  We also need to know, at least,
4616 dnl that the stack is continuous.
4617 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4618   registers relevant for conservative garbage collection in the jmp_buf.])
4619
4620
4621 case $opsys in
4622   dnl Not all the architectures are tested, but there are Debian packages
4623   dnl for SCM and/or Guile on them, so the technique must work.  See also
4624   dnl comments in alloc.c concerning setjmp and gcc.
4625   dnl Fixme: it's probably safe to just use the GCC conditional below.
4626   gnu-linux | gnu-kfreebsd )
4627     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4628 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4629   || defined __alpha__ || defined __mips__ || defined __s390__ \
4630   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4631   || defined __ia64__ || defined __sh__
4632 /* ok */
4633 #else
4634 # error "setjmp not known to work on this arch"
4635 #endif
4636     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4637     ;;
4638 esac
4639
4640
4641 if test x$GCC = xyes; then
4642    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4643    AC_DEFINE(GC_SETJMP_WORKS, 1)
4644 else
4645   case $opsys in
4646     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4647     aix* | dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4648       AC_DEFINE(GC_SETJMP_WORKS, 1)
4649       ;;
4650   esac
4651 fi                              dnl GCC?
4652
4653 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4654 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4655   [AC_LINK_IFELSE(
4656      [AC_LANG_PROGRAM(
4657        [[#include <setjmp.h>
4658          #ifdef __MINGW32__
4659          # define _longjmp longjmp
4660          #endif
4661        ]],
4662        [[jmp_buf j;
4663          if (! _setjmp (j))
4664            _longjmp (j, 1);]])],
4665      [emacs_cv_func__setjmp=yes],
4666      [emacs_cv_func__setjmp=no])])
4667 if test $emacs_cv_func__setjmp = yes; then
4668   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4669 fi
4670
4671 # We need to preserve signal mask to handle C stack overflows.
4672 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4673   [AC_LINK_IFELSE(
4674      [AC_LANG_PROGRAM(
4675        [[#include <setjmp.h>
4676        ]],
4677        [[sigjmp_buf j;
4678          if (! sigsetjmp (j, 1))
4679            siglongjmp (j, 1);]])],
4680      [emacs_cv_func_sigsetjmp=yes],
4681      [emacs_cv_func_sigsetjmp=no])])
4682 if test $emacs_cv_func_sigsetjmp = yes; then
4683   AC_DEFINE([HAVE_SIGSETJMP], 1,
4684     [Define to 1 if sigsetjmp and siglongjmp work.])
4685 fi
4686
4687 case $emacs_cv_func_sigsetjmp,$emacs_cv_alternate_stack,$opsys in
4688   yes,yes,* | *,*,mingw32)
4689     AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4690       [Define to 1 if C stack overflow can be handled in some cases.]);;
4691 esac
4692
4693 case $opsys in
4694   sol2* | unixware )
4695     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4696     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4697     dnl and this is all we need.
4698     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4699     ;;
4700 esac
4701
4702
4703 case $opsys in
4704   hpux* | sol2* )
4705     dnl Used in xfaces.c.
4706     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4707       some systems, where it requires time.h.])
4708     ;;
4709 esac
4710
4711
4712 dnl Define symbols to identify the version of Unix this is.
4713 dnl Define all the symbols that apply correctly.
4714 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4715 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4716 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4717 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4718
4719 case $opsys in
4720   aix4-2)
4721     AC_DEFINE(USG, [])
4722     dnl This symbol should be defined on AIX Version 3  ???????
4723     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4724 #ifndef _AIX
4725 # error "_AIX not defined"
4726 #endif
4727     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4728     ;;
4729
4730   cygwin)
4731     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4732     ;;
4733
4734   darwin)
4735     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4736     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4737     dnl distinguish OS X from pure Darwin.
4738     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4739     ;;
4740
4741   gnu-linux | gnu-kfreebsd )
4742     AC_DEFINE(USG, [])
4743     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4744     ;;
4745
4746   hpux*)
4747     AC_DEFINE(USG, [])
4748     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4749     ;;
4750
4751   irix6-5)
4752     AC_DEFINE(USG, [])
4753     AC_DEFINE(USG5_4, [])
4754     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4755     ;;
4756
4757   mingw32)
4758     AC_DEFINE(DOS_NT, [])
4759     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4760     if test "x$ac_enable_checking" != "x" ; then
4761       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4762     fi
4763     ;;
4764
4765   sol2*)
4766     AC_DEFINE(USG, [])
4767     AC_DEFINE(USG5_4, [])
4768     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4769     ;;
4770
4771   unixware)
4772     AC_DEFINE(USG, [])
4773     AC_DEFINE(USG5_4, [])
4774     ;;
4775 esac
4776
4777 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4778   [case $opsys in
4779      aix4-2 | nacl)
4780        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4781        emacs_cv_usable_FIONREAD=no
4782        ;;
4783
4784      mingw32)
4785        emacs_cv_usable_FIONREAD=yes
4786        ;;
4787
4788      *)
4789        AC_COMPILE_IFELSE(
4790          [AC_LANG_PROGRAM([[#include <sys/types.h>
4791                             #include <sys/ioctl.h>
4792                             #ifdef USG5_4
4793                             # include <sys/filio.h>
4794                             #endif
4795                           ]],
4796                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4797          [emacs_cv_usable_FIONREAD=yes],
4798          [emacs_cv_usable_FIONREAD=no])
4799        ;;
4800    esac])
4801 if test $emacs_cv_usable_FIONREAD = yes; then
4802   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4803
4804   if test $emacs_broken_SIGIO = no; then
4805     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4806       [AC_COMPILE_IFELSE(
4807          [AC_LANG_PROGRAM([[#include <fcntl.h>
4808                             #include <signal.h>
4809                           ]],
4810                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4811          [emacs_cv_usable_SIGIO=yes],
4812          [emacs_cv_usable_SIGIO=no])],
4813       [emacs_cv_usable_SIGIO=yes],
4814       [emacs_cv_usable_SIGIO=no])
4815     if test $emacs_cv_usable_SIGIO = yes; then
4816       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4817     fi
4818   fi
4819 fi
4820
4821 case $opsys in
4822   hpux11)
4823     dnl It works to open the pty's tty in the parent (Emacs), then
4824     dnl close and reopen it in the child.
4825     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4826       works to open a pty's tty in the parent process, then close and
4827       reopen it in the child.])
4828     ;;
4829
4830   irix6-5)
4831     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4832       use VSUSP instead of VSWTCH.])
4833     ;;
4834
4835   sol2-10)
4836     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4837       on Solaris.])
4838     ;;
4839 esac
4840
4841 # Set up the CFLAGS for real compilation, so we can substitute it.
4842 CFLAGS="$REAL_CFLAGS"
4843 CPPFLAGS="$REAL_CPPFLAGS"
4844 LIBS="$REAL_LIBS"
4845
4846 ## Hack to detect a buggy GCC version.
4847 if test "$GCC" = yes && \
4848    $CC --version 2> /dev/null | grep 'gcc.* 4.5.0' >/dev/null; then
4849   case $CFLAGS in
4850     *-fno-optimize-sibling-calls*) ;;
4851     *-O@<:@23@:>@*)
4852       AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS.]);;
4853   esac
4854 fi
4855
4856 version=$PACKAGE_VERSION
4857
4858 copyright="Copyright (C) 2016 Free Software Foundation, Inc."
4859 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4860   [Short copyright string for this version of Emacs.])
4861 AC_SUBST(copyright)
4862
4863 ### Specify what sort of things we'll be editing into Makefile and config.h.
4864 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4865 AC_SUBST(version)
4866 AC_SUBST(configuration)
4867 ## Unused?
4868 AC_SUBST(canonical)
4869 AC_SUBST(srcdir)
4870 AC_SUBST(prefix)
4871 AC_SUBST(exec_prefix)
4872 AC_SUBST(bindir)
4873 AC_SUBST(datadir)
4874 AC_SUBST(sharedstatedir)
4875 AC_SUBST(libexecdir)
4876 AC_SUBST(mandir)
4877 AC_SUBST(infodir)
4878 AC_SUBST(lispdir)
4879 AC_SUBST(standardlisppath)
4880 AC_SUBST(locallisppath)
4881 AC_SUBST(lisppath)
4882 AC_SUBST(x_default_search_path)
4883 AC_SUBST(etcdir)
4884 AC_SUBST(archlibdir)
4885 AC_SUBST(etcdocdir)
4886 AC_SUBST(bitmapdir)
4887 AC_SUBST(gamedir)
4888 AC_SUBST(gameuser)
4889 AC_SUBST(gamegroup)
4890 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4891 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4892 ## end of LIBX_BASE, but nothing ever set it.
4893 AC_SUBST(LD_SWITCH_X_SITE)
4894 AC_SUBST(C_SWITCH_X_SITE)
4895 AC_SUBST(GNUSTEP_CFLAGS)
4896 AC_SUBST(CFLAGS)
4897 ## Used in lwlib/Makefile.in.
4898 AC_SUBST(X_TOOLKIT_TYPE)
4899 AC_SUBST(ns_appdir)
4900 AC_SUBST(ns_appbindir)
4901 AC_SUBST(ns_appresdir)
4902 AC_SUBST(ns_appsrc)
4903 AC_SUBST(GNU_OBJC_CFLAGS)
4904 AC_SUBST(OTHER_FILES)
4905
4906 if test -n "${term_header}"; then
4907     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4908         [Define to the header for the built-in window system.])
4909 fi
4910
4911 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4912                    [Define to the canonical Emacs configuration name.])
4913 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4914                    [Define to the options passed to configure.])
4915 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4916   define this to include extra configuration information.])
4917
4918 case $opsys in
4919   mingw32)
4920     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4921     ;;
4922 esac
4923
4924 XMENU_OBJ=
4925 XOBJ=
4926 FONT_OBJ=
4927 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4928   AC_DEFINE(HAVE_X_WINDOWS, 1,
4929             [Define to 1 if you want to use the X window system.])
4930   XMENU_OBJ=xmenu.o
4931   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4932   FONT_OBJ=xfont.o
4933   if test "$HAVE_CAIRO" = "yes"; then
4934     FONT_OBJ="ftfont.o ftcrfont.o"
4935   elif test "$HAVE_XFT" = "yes"; then
4936     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4937   elif test "$HAVE_FREETYPE" = "yes"; then
4938     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4939   fi
4940   AC_SUBST(FONT_OBJ)
4941 fi
4942 AC_SUBST(XMENU_OBJ)
4943 AC_SUBST(XOBJ)
4944 AC_SUBST(FONT_OBJ)
4945
4946 WIDGET_OBJ=
4947 MOTIF_LIBW=
4948 if test "${USE_X_TOOLKIT}" != "none" ; then
4949   WIDGET_OBJ=widget.o
4950   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4951   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4952     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4953   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4954     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4955     MOTIF_LIBW=-lXm
4956     case "$opsys" in
4957       gnu-linux)
4958         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4959         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4960         ;;
4961
4962       unixware)
4963         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4964         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4965         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4966         ;;
4967
4968       aix4-2)
4969         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4970         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4971         ;;
4972     esac
4973     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4974   fi
4975 fi
4976 AC_SUBST(WIDGET_OBJ)
4977
4978 TOOLKIT_LIBW=
4979 case "$USE_X_TOOLKIT" in
4980   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4981   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4982   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4983 esac
4984 if test "$HAVE_XWIDGETS" = "yes"; then
4985   TOOLKIT_LIBW="$TOOLKIT_LIBW -lXcomposite"
4986 fi
4987 AC_SUBST(TOOLKIT_LIBW)
4988
4989 if test "${opsys}" != "mingw32"; then
4990   if test "$USE_X_TOOLKIT" = "none"; then
4991     LIBXT_OTHER="\$(LIBXSM)"
4992   else
4993     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4994   fi
4995 fi
4996 AC_SUBST(LIBXT_OTHER)
4997
4998 if test "${HAVE_X11}" = "yes" ; then
4999   AC_DEFINE(HAVE_X11, 1,
5000             [Define to 1 if you want to use version 11 of X windows.])
5001   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
5002 else
5003   LIBX_OTHER=
5004 fi
5005 AC_SUBST(LIBX_OTHER)
5006
5007 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
5008   LIBXMENU=
5009 elif test "$USE_X_TOOLKIT" = none; then
5010   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
5011 else
5012   LIBXMENU='$(lwlibdir)/liblw.a'
5013 fi
5014 AC_SUBST(LIBXMENU)
5015
5016 AC_CACHE_CHECK([for struct alignment],
5017   [emacs_cv_struct_alignment],
5018   [AC_COMPILE_IFELSE(
5019      [AC_LANG_PROGRAM([[#include <stddef.h>
5020                         struct __attribute__ ((aligned (8))) s { char c; };
5021                         struct t { char c; struct s s; };
5022                         char verify[offsetof (struct t, s) == 8 ? 1 : -1];
5023                       ]])],
5024      [emacs_cv_struct_alignment=yes],
5025      [emacs_cv_struct_alignment=no])])
5026 if test "$emacs_cv_struct_alignment" = yes; then
5027   AC_DEFINE([HAVE_STRUCT_ATTRIBUTE_ALIGNED], 1,
5028     [Define to 1 if 'struct __attribute__ ((aligned (N)))' aligns the
5029      structure to an N-byte boundary.])
5030 fi
5031
5032 if test "${GNU_MALLOC}" = "yes" ; then
5033   AC_DEFINE(GNU_MALLOC, 1,
5034             [Define to 1 if you want to use the GNU memory allocator.])
5035 fi
5036
5037 RALLOC_OBJ=
5038 if test "${REL_ALLOC}" = "yes" ; then
5039   AC_DEFINE(REL_ALLOC, 1,
5040             [Define REL_ALLOC if you want to use the relocating allocator for
5041              buffer space.])
5042
5043   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
5044 fi
5045 AC_SUBST(RALLOC_OBJ)
5046
5047 if test "$opsys" = "cygwin"; then
5048   CYGWIN_OBJ="cygw32.o"
5049   ## Cygwin differs because of its unexec().
5050   PRE_ALLOC_OBJ=
5051   POST_ALLOC_OBJ=lastfile.o
5052 elif test "$opsys" = "mingw32"; then
5053   CYGWIN_OBJ=
5054   PRE_ALLOC_OBJ=
5055   POST_ALLOC_OBJ=lastfile.o
5056 else
5057   CYGWIN_OBJ=
5058   PRE_ALLOC_OBJ=lastfile.o
5059   POST_ALLOC_OBJ=
5060 fi
5061 AC_SUBST(CYGWIN_OBJ)
5062 AC_SUBST(PRE_ALLOC_OBJ)
5063 AC_SUBST(POST_ALLOC_OBJ)
5064
5065 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
5066 dnl verbatim defined above.  The tricky name is apropos, as this hack
5067 dnl makes Fortify go sour!
5068 AH_VERBATIM([FORTIFY_SOUR],
5069 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
5070    The workaround disables some useful run-time checking, so it
5071    should be conditional to the platforms with the performance bug.
5072    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
5073 #if defined __APPLE__ && defined __GNUC__
5074 # ifndef _DONT_USE_CTYPE_INLINE_
5075 #  define _DONT_USE_CTYPE_INLINE_
5076 # endif
5077 # ifndef _FORTIFY_SOURCE
5078 #  define _FORTIFY_SOURCE 0
5079 # endif
5080 #endif
5081 ])
5082
5083 # If user asks to omit features, disable optional features that gnulib
5084 # might otherwise enable.
5085 if test "$with_features" = no && test "$enable_acl" != yes; then
5086   enable_acl=no
5087 fi
5088
5089 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
5090 # it temporarily reverts them to their pre-pkg-config values,
5091 # because gnulib needs to work with both src (which uses the
5092 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
5093 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
5094 # and it therefore needs to run in an environment where LIBS does not
5095 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
5096 # for some package unrelated to lib-src.
5097 SAVE_CFLAGS=$CFLAGS
5098 SAVE_LIBS=$LIBS
5099 CFLAGS=$pre_PKG_CONFIG_CFLAGS
5100 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
5101 gl_ASSERT_NO_GNULIB_POSIXCHECK
5102 gl_ASSERT_NO_GNULIB_TESTS
5103 gl_INIT
5104 CFLAGS=$SAVE_CFLAGS
5105 LIBS=$SAVE_LIBS
5106
5107 if test "${opsys}" = "mingw32"; then
5108   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
5109   # Remove unneeded switches from the value of CC that goes to Makefiles
5110   CC=`AS_ECHO(["$CC"]) | sed -e "s,$GCC_TEST_OPTIONS,,"`
5111 fi
5112
5113 case "$opsys" in
5114   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
5115
5116   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
5117
5118   darwin)
5119    ## The -headerpad option tells ld (see man page) to leave room at the
5120    ## end of the header for adding load commands.  Needed for dumping.
5121    ## 0x1000 is enough for roughly 52 load commands on the x86_64
5122    ## architecture (where they are 78 bytes each). The actual number of
5123    ## load commands added is not consistent but normally ranges from
5124    ## about 14 to about 34. Setting it high gets us plenty of slop and
5125    ## only costs about 1.5K of wasted binary space.
5126    headerpad_extra=1000
5127    if test "$HAVE_NS" = "yes"; then
5128      libs_nsgui="-framework AppKit"
5129      if test "$NS_IMPL_COCOA" = "yes"; then
5130         libs_nsgui="$libs_nsgui -framework IOKit"
5131      fi
5132    else
5133      libs_nsgui=
5134    fi
5135    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
5136
5137    ## This is here because src/Makefile.in did some extra fiddling around
5138    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
5139    ## LD_SWITCH_SYSTEM_TEMACS instead,
5140    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
5141      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
5142    ;;
5143
5144   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
5145   ## find X at run-time.
5146   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
5147   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
5148   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
5149   ## had different values in configure (in ac_link) and src/Makefile.in.
5150   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
5151   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
5152
5153   mingw32)
5154    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
5155    case "$canonical" in
5156      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5157      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5158    esac
5159    ;;
5160
5161   *) LD_SWITCH_SYSTEM_TEMACS= ;;
5162 esac
5163
5164 # -nopie fixes a temacs segfault on Gentoo, OpenBSD, and other systems
5165 # with "hardened" GCC configurations for some reason (Bug#18784).
5166 # We don't know why -nopie works, but not segfaulting is better than
5167 # segfaulting.  Use ac_c_werror_flag=yes when trying -nopie, otherwise
5168 # clang keeps warning that it does not understand -nopie, and pre-4.6
5169 # GCC has a similar problem (Bug#20338).
5170 AC_CACHE_CHECK([whether $CC accepts -nopie],
5171   [emacs_cv_prog_cc_nopie],
5172   [emacs_save_c_werror_flag=$ac_c_werror_flag
5173    emacs_save_LDFLAGS=$LDFLAGS
5174    ac_c_werror_flag=yes
5175    LDFLAGS="$LDFLAGS -nopie"
5176    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
5177      [emacs_cv_prog_cc_nopie=yes],
5178      [emacs_cv_prog_cc_nopie=no])
5179    ac_c_werror_flag=$emacs_save_c_werror_flag
5180    LDFLAGS=$emacs_save_LDFLAGS])
5181 if test "$emacs_cv_prog_cc_nopie" = yes; then
5182   LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -nopie"
5183 fi
5184
5185 if test x$ac_enable_profiling != x ; then
5186   case $opsys in
5187     *freebsd | gnu-linux) ;;
5188     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
5189   esac
5190 fi
5191
5192 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
5193
5194 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
5195
5196 ## Common for all window systems
5197 if test "$window_system" != "none"; then
5198   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
5199   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
5200   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
5201 fi
5202
5203 AC_SUBST(WINDOW_SYSTEM_OBJ)
5204
5205 AH_TOP([/* GNU Emacs site configuration template file.
5206
5207 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2016
5208   Free Software Foundation, Inc.
5209
5210 This file is part of GNU Emacs.
5211
5212 GNU Emacs is free software: you can redistribute it and/or modify
5213 it under the terms of the GNU General Public License as published by
5214 the Free Software Foundation, either version 3 of the License, or
5215 (at your option) any later version.
5216
5217 GNU Emacs is distributed in the hope that it will be useful,
5218 but WITHOUT ANY WARRANTY; without even the implied warranty of
5219 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
5220 GNU General Public License for more details.
5221
5222 You should have received a copy of the GNU General Public License
5223 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
5224
5225
5226 /* No code in Emacs #includes config.h twice, but some bits of code
5227    intended to work with other packages as well (like gmalloc.c)
5228    think they can include it as many times as they like.  */
5229 #ifndef EMACS_CONFIG_H
5230 #define EMACS_CONFIG_H
5231 ])dnl
5232
5233 AH_BOTTOM([#include <conf_post.h>
5234
5235 #endif /* EMACS_CONFIG_H */
5236
5237 /*
5238 Local Variables:
5239 mode: c
5240 End:
5241 */
5242 ])dnl
5243
5244 #### Report on what we decided to do.
5245 #### Report GTK as a toolkit, even if it doesn't use Xt.
5246 #### It makes printing result more understandable as using GTK sets
5247 #### toolkit_scroll_bars to yes by default.
5248 if test "${HAVE_GTK}" = "yes"; then
5249   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5250 fi
5251
5252 if test $USE_ACL -ne 0; then
5253   ACL_SUMMARY="yes $LIB_ACL"
5254 else
5255   ACL_SUMMARY=no
5256 fi
5257
5258 emacs_standard_dirs='Standard dirs'
5259 AS_ECHO(["
5260 Configured for '${canonical}'.
5261
5262   Where should the build process find the source code?    ${srcdir}
5263   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5264   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5265   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5266   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5267   What window system should Emacs use?                    ${window_system}
5268   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}
5269   Where do we find X Windows header files?                ${x_includes:-$emacs_standard_dirs}
5270   Where do we find X Windows libraries?                   ${x_libraries:-$emacs_standard_dirs}"])
5271
5272 optsep=
5273 emacs_config_features=
5274 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG CAIRO IMAGEMAGICK SOUND GPM DBUS \
5275   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5276   LIBOTF XFT ZLIB TOOLKIT_SCROLL_BARS X_TOOLKIT X11 NS MODULES \
5277   XWIDGETS; do
5278
5279     case $opt in
5280       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5281       TOOLKIT_SCROLL_BARS|X_TOOLKIT) eval val=\${USE_$opt} ;;
5282       *) eval val=\${HAVE_$opt} ;;
5283     esac
5284     case x$val in
5285       xno|xnone|x) continue ;;
5286     esac
5287     case $opt in
5288       X_TOOLKIT)
5289         case $val in
5290           GTK*|LUCID|MOTIF) opt=$val ;;
5291           *) continue ;;
5292         esac
5293       ;;
5294     esac
5295     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5296     optsep=' '
5297 done
5298 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5299   [Summary of some of the main features enabled by configure.])
5300
5301 AS_ECHO(["  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}
5302   Does Emacs use -lXpm?                                   ${HAVE_XPM}
5303   Does Emacs use -ljpeg?                                  ${HAVE_JPEG}
5304   Does Emacs use -ltiff?                                  ${HAVE_TIFF}
5305   Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF
5306   Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG
5307   Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}
5308   Does Emacs use cairo?                                   ${HAVE_CAIRO}
5309   Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}
5310   Does Emacs support sound?                               ${HAVE_SOUND}
5311   Does Emacs use -lgpm?                                   ${HAVE_GPM}
5312   Does Emacs use -ldbus?                                  ${HAVE_DBUS}
5313   Does Emacs use -lgconf?                                 ${HAVE_GCONF}
5314   Does Emacs use GSettings?                               ${HAVE_GSETTINGS}
5315   Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}
5316   Does Emacs use access control lists?                    ${ACL_SUMMARY}
5317   Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}
5318   Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}
5319   Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}
5320   Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}
5321   Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}
5322   Does Emacs use -lotf?                                   ${HAVE_LIBOTF}
5323   Does Emacs use -lxft?                                   ${HAVE_XFT}
5324   Does Emacs directly use zlib?                           ${HAVE_ZLIB}
5325   Does Emacs have dynamic modules support?                ${HAVE_MODULES}
5326   Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}
5327   Does Emacs support Xwidgets (requires gtk3)?            ${HAVE_XWIDGETS}
5328 "])
5329
5330 if test -n "${EMACSDATA}"; then
5331    AS_ECHO(["  Environment variable EMACSDATA set to:                  $EMACSDATA"])
5332 fi
5333 if test -n "${EMACSDOC}"; then
5334    AS_ECHO(["  Environment variable EMACSDOC set to:                   $EMACSDOC"])
5335 fi
5336
5337 echo
5338
5339 if test "$HAVE_NS" = "yes"; then
5340    echo
5341    AS_ECHO(["You must run \"${MAKE-make} install\" in order to test the built application.
5342 The installed application will go to nextstep/Emacs.app and can be
5343 run or moved from there."])
5344    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5345       echo "The application will be fully self-contained."
5346     else
5347       AS_ECHO(["The lisp resources for the application will be installed under ${prefix}.
5348 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5349 to run if these resources are not installed."])
5350    fi
5351    echo
5352 fi
5353
5354 if test "${opsys}" = "cygwin"; then
5355   case `uname -r` in
5356     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5357            echo
5358            ;;
5359   esac
5360 fi
5361
5362 # Remove any trailing slashes in these variables.
5363 case $prefix in
5364   */) prefix=`AS_DIRNAME(["$prefix."])`;;
5365 esac
5366 case $exec_prefix in
5367   */) exec_prefix=`AS_DIRNAME(["$exec_prefix."])`;;
5368 esac
5369
5370 if test "$HAVE_NS" = "yes"; then
5371   if test "$NS_IMPL_GNUSTEP" = yes; then
5372     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5373       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5374     ns_check_file=Resources/Info-gnustep.plist
5375   else
5376     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5377       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5378     ns_check_file=Contents/Info.plist
5379   fi
5380   AC_SUBST(ns_check_file)
5381 fi
5382
5383 dnl config.status treats $srcdir specially, so I think this is ok...
5384 AC_CONFIG_FILES([$srcdir/doc/man/emacs.1])
5385
5386 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5387 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5388 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5389 dnl (else you get "no 'Makefile.am' found for any configure output").
5390 dnl This will work, but you get a config.status that is not quite right
5391 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5392 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5393 dnl it seems better to just live with the duplication.
5394 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5395
5396 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5397        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5398        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5399        leim/Makefile nextstep/Makefile nt/Makefile])
5400
5401 dnl test/ is not present in release tarfiles.
5402 opt_makefile=test/Makefile
5403
5404 if test -f "$srcdir/$opt_makefile.in"; then
5405   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5406   dnl Again, it's best not to use a variable.  Though you can add
5407   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5408   AC_CONFIG_FILES([test/Makefile])
5409 fi
5410
5411
5412 dnl The admin/ directory used to be excluded from tarfiles.
5413 if test -d $srcdir/admin; then
5414   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/charsets/Makefile admin/unidata/Makefile admin/grammars/Makefile"
5415   AC_CONFIG_FILES([admin/charsets/Makefile])
5416   AC_CONFIG_FILES([admin/unidata/Makefile])
5417   AC_CONFIG_FILES([admin/grammars/Makefile])
5418 fi                              dnl -d admin
5419
5420
5421 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5422
5423 AC_SUBST(SUBDIR_MAKEFILES_IN)
5424
5425 dnl You might wonder (I did) why epaths.h is generated by running make,
5426 dnl rather than just letting configure generate it from epaths.in.
5427 dnl One reason is that the various paths are not fully expanded (see above);
5428 dnl eg gamedir=${prefix}/var/games/emacs.
5429 dnl Secondly, the GNU Coding standards require that one should be able
5430 dnl to run 'make prefix=/some/where/else' and override the values set
5431 dnl by configure.  This also explains the 'move-if-change' test and
5432 dnl the use of force in the 'epaths-force' rule in Makefile.in.
5433 AC_CONFIG_COMMANDS([src/epaths.h], [
5434 if test "${opsys}" = "mingw32"; then
5435   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5436 else
5437   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5438 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5439 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5440
5441 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5442 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5443 dnl or a symlink?
5444 AC_CONFIG_COMMANDS([src/.gdbinit], [
5445 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5446   AS_ECHO(["source $ac_abs_top_srcdir/src/.gdbinit"]) > src/.gdbinit
5447 fi
5448 ])
5449
5450 dnl Perhaps this would be better named doc-emacs-emacsver.texi?
5451 dnl See comments for etc-refcards-emacsver.tex.
5452 dnl Since we get a doc/emacs directory generated anyway, for the Makefile,
5453 dnl it is not quite the same.  But we are generating in $srcdir.
5454 AC_CONFIG_COMMANDS([doc/emacs/emacsver.texi], [
5455 ${MAKE-make} -s --no-print-directory -C doc/emacs doc-emacsver || \
5456 AC_MSG_ERROR(['doc/emacs/emacsver.texi' could not be made.])
5457 ])
5458
5459 dnl If we give this the more natural name, etc/refcards/emacsver.texi,
5460 dnl then a directory etc/refcards is created in the build directory,
5461 dnl which is probably harmless, but confusing (in out-of-tree builds).
5462 dnl (If we were to generate etc/refcards/Makefile, this might change.)
5463 dnl It is really $srcdir/etc/refcards/emacsver.tex that we generate.
5464 AC_CONFIG_COMMANDS([etc-refcards-emacsver.tex], [
5465 ${MAKE-make} -s MAKEFILE_NAME=do-not-make-Makefile etc-emacsver || \
5466 AC_MSG_ERROR(['etc/refcards/emacsver.tex' could not be made.])
5467 ])
5468
5469 AC_OUTPUT
5470
5471 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])