code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.61)
  25 AC_INIT(emacs, 23.0.94)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 if test "$with_hesiod" != no; then
  95   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  96 fi
  97
  98 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
  99
 100 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 101 if test "$with_sync_input" = yes; then
 102    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 103 fi
 104
 105 dnl FIXME currently it is not the last.
 106 dnl This should be the last --with option, because --with-x is
 107 dnl added later on when we find the path of X, and it's best to
 108 dnl keep them together visually.
 109 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 110  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 111 [         case "${withval}" in
 112             y | ye | yes )      val=gtk ;;
 113             n | no )            val=no  ;;
 114             l | lu | luc | luci | lucid )       val=lucid ;;
 115             a | at | ath | athe | athen | athena )      val=athena ;;
 116             m | mo | mot | moti | motif )       val=motif ;;
 117             g | gt | gtk  )     val=gtk ;;
 118             * )
 119 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 120 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 121 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 122             ;;
 123           esac
 124           with_x_toolkit=$val
 125 ])
 126
 127 dnl _ON results in a '--without' option in the --help output, so
 128 dnl the help text should refer to "don't compile", etc.
 129 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 130 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 131 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 132 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 133 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 134 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 135
 136 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 137 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 138 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 139
 140 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 141 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 142 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 143 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 144
 145 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 146 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 147
 148 ## For the times when you want to build Emacs but don't have
 149 ## a suitable makeinfo, and can live without the manuals.
 150 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 151 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 152
 153 dnl Can remove these in Emacs 24.
 154 AC_ARG_WITH([gtk],,
 155   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 156 specify a toolkit.])],,)
 157
 158 AC_ARG_WITH([gcc],,
 159   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 160 variable to specify a compiler.])],,)
 161
 162 AC_ARG_WITH([pkg-config-prog],dnl
 163 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 164                   [path to pkg-config for finding GTK and librsvg])])
 165 if test "X${with_pkg_config_prog}" != X; then
 166    if test "${with_pkg_config_prog}" != yes; then
 167       PKG_CONFIG="${with_pkg_config_prog}"
 168    fi
 169 fi
 170
 171 AC_ARG_WITH([gnustep-conf],dnl
 172 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 173 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 174   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 175 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 176      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 177
 178 AC_ARG_ENABLE(ns-self-contained,
 179 [AS_HELP_STRING([--disable-ns-self-contained],
 180                 [disable self contained build under NeXTstep])],
 181    EN_NS_SELF_CONTAINED=$enableval,
 182    EN_NS_SELF_CONTAINED=yes)
 183
 184 AC_ARG_ENABLE(asserts,
 185 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 186       USE_XASSERTS=$enableval,
 187       USE_XASSERTS=no)
 188
 189 AC_ARG_ENABLE(maintainer-mode,
 190 [AS_HELP_STRING([--enable-maintainer-mode],
 191                 [enable make rules and dependencies not useful (and sometimes
 192                  confusing) to the casual installer])],
 193       USE_MAINTAINER_MODE=$enableval,
 194       USE_MAINTAINER_MODE=no)
 195 if test $USE_MAINTAINER_MODE = yes; then
 196   MAINT=
 197 else
 198   MAINT=#
 199 fi
 200 AC_SUBST(MAINT)
 201
 202 AC_ARG_ENABLE(locallisppath,
 203 [AS_HELP_STRING([--enable-locallisppath=PATH],
 204                 [directories Emacs should search for lisp files specific
 205                  to this site])],
 206 if test "${enableval}" = "no"; then
 207   locallisppath=
 208 elif test "${enableval}" != "yes"; then
 209   locallisppath=${enableval}
 210 fi)
 211
 212 #### Make srcdir absolute, if it isn't already.  It's important to
 213 #### avoid running the path through pwd unnecessarily, since pwd can
 214 #### give you automounter prefixes, which can go away.  We do all this
 215 #### so Emacs can find its files when run uninstalled.
 216 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 217 unset CDPATH
 218 case "${srcdir}" in
 219   /* ) ;;
 220   . )
 221     ## We may be able to use the $PWD environment variable to make this
 222     ## absolute.  But sometimes PWD is inaccurate.
 223     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 224     ## but that tested only for a well-formed and valid PWD,
 225     ## it did not object when PWD was well-formed and valid but just wrong.
 226     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 227     then
 228       srcdir="$PWD"
 229     else
 230       srcdir="`(cd ${srcdir}; pwd)`"
 231     fi
 232   ;;
 233   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 234 esac
 235
 236 #### Check if the source directory already has a configured system in it.
 237 if test `pwd` != `(cd ${srcdir} && pwd)` \
 238    && test -f "${srcdir}/src/config.h" ; then
 239   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 240    as a build directory right now; it has been configured in its own
 241    right.  To configure in another directory as well, you MUST
 242    use GNU make.  If you do not have GNU make, then you must
 243    now do `make distclean' in ${srcdir},
 244    and then run $0 again.]])
 245 fi
 246
 247 #### Given the configuration name, set machfile and opsysfile to the
 248 #### names of the m/*.h and s/*.h files we should use.
 249
 250 ### Canonicalize the configuration name.
 251
 252 AC_CANONICAL_HOST
 253 canonical=$host
 254 configuration=${host_alias-${build_alias-$host}}
 255
 256 dnl This used to use changequote, but, apart from `changequote is evil'
 257 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 258 dnl the great gob of text.  Thus it's not processed for possible expansion.
 259 dnl Just make sure the brackets remain balanced.
 260 dnl
 261 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 262 dnl indicated by comments.
 263 dnl quotation begins
 264 [
 265
 266 ### If you add support for a new configuration, add code to this
 267 ### switch statement to recognize your configuration name and select
 268 ### the appropriate operating system and machine description files.
 269
 270 ### You would hope that you could choose an m/*.h file pretty much
 271 ### based on the machine portion of the configuration name, and an s-
 272 ### file based on the operating system portion.  However, it turns out
 273 ### that each m/*.h file is pretty manufacturer-specific - for
 274 ### example mips.h is MIPS
 275 ### So we basically have to have a special case for each
 276 ### configuration name.
 277 ###
 278 ### As far as handling version numbers on operating systems is
 279 ### concerned, make sure things will fail in a fixable way.  If
 280 ### /etc/MACHINES doesn't say anything about version numbers, be
 281 ### prepared to handle anything reasonably.  If version numbers
 282 ### matter, be sure /etc/MACHINES says something about it.
 283 ###
 284 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 285 ### "System V Release 4"; he writes, "The old convention encouraged
 286 ### confusion between `system' and `release' levels'."
 287
 288 machine='' opsys='' unported=no
 289 case "${canonical}" in
 290
 291   ## FreeBSD ports
 292   *-*-freebsd* )
 293     opsys=freebsd
 294     case "${canonical}" in
 295       alpha*-*-freebsd*)        machine=alpha ;;
 296       arm*-*-freebsd*)          machine=arm ;;
 297       ia64-*-freebsd*)          machine=ia64 ;;
 298       sparc-*-freebsd*)         machine=sparc ;;
 299       sparc64-*-freebsd*)       machine=sparc ;;
 300       powerpc-*-freebsd*)       machine=macppc ;;
 301       i[3456]86-*-freebsd*)     machine=intel386 ;;
 302       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 303     esac
 304   ;;
 305
 306   ## FreeBSD kernel + glibc based userland
 307   *-*-kfreebsd*gnu* )
 308     opsys=gnu-kfreebsd
 309     case "${canonical}" in
 310       alpha*-*-kfreebsd*)       machine=alpha ;;
 311       ia64-*-kfreebsd*)         machine=ia64 ;;
 312       sparc-*-kfreebsd*)        machine=sparc ;;
 313       sparc64-*-kfreebsd*)      machine=sparc ;;
 314       powerpc-*-kfreebsd*)      machine=macppc ;;
 315       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 316       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 317     esac
 318   ;;
 319
 320   ## NetBSD ports
 321   *-*-netbsd* )
 322     opsys=netbsd
 323     if test -f /usr/lib/crti.o; then]
 324 dnl The close and open brackets here are because this section is quoted --
 325 dnl see the `changequote' comment above.
 326       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 327 [   fi
 328
 329     case "${canonical}" in
 330       alpha*-*-netbsd*) machine=alpha ;;
 331       i[3456]86-*-netbsd*) machine=intel386 ;;
 332       powerpc-*-netbsd*) machine=macppc ;;
 333       sparc*-*-netbsd*) machine=sparc ;;
 334       vax-*-netbsd*)    machine=vax ;;
 335       arm-*-netbsd*)    machine=arm ;;
 336       x86_64-*-netbsd*) machine=amdx86-64 ;;
 337       hppa-*-netbsd*)   machine=hp800 ;;
 338       m68k-*-netbsd*)   machine=m68k ;;
 339     esac
 340   ;;
 341
 342   ## OpenBSD ports
 343   *-*-openbsd* )
 344     opsys=openbsd
 345     case "${canonical}" in
 346       alpha*-*-openbsd*)        machine=alpha ;;
 347       arm-*-openbsd*)          machine=arm ;;
 348       i386-*-openbsd*)         machine=intel386 ;;
 349       powerpc-*-openbsd*)      machine=macppc ;;
 350       sparc*-*-openbsd*)       machine=sparc ;;
 351       vax-*-openbsd*)          machine=vax ;;
 352       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 353       hppa-*-openbsd*)         machine=hp800 ;;
 354     esac
 355   ;;
 356
 357   ## LynxOS ports
 358   *-*-lynxos* )
 359     opsys=lynxos
 360     case "${canonical}" in
 361       i[3456]86-*-lynxos*) machine=intel386 ;;
 362       powerpc-*-lynxos*) machine=powerpc ;;
 363     esac
 364   ;;
 365
 366   alpha*-*-linux-gnu* )
 367     machine=alpha opsys=gnu-linux
 368   ;;
 369
 370   arm*-*-linux-gnu* )
 371     machine=arm opsys=gnu-linux
 372   ;;
 373
 374   ## Apple Darwin / Mac OS X
 375   *-apple-darwin* )
 376     case "${canonical}" in
 377       i[3456]86-* )  machine=intel386 ;;
 378       powerpc-* )    machine=macppc ;;
 379       * )            unported=yes ;;
 380     esac
 381     opsys=darwin
 382     # Define CPP as follows to make autoconf work correctly.
 383     CPP="${CC-cc} -E -no-cpp-precomp"
 384     # Use fink packages if available.
 385     if test -d /sw/include && test -d /sw/lib; then
 386       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 387       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 388       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 389     fi
 390   ;;
 391
 392   ## HP 9000 series 700 and 800, running HP/UX
 393   hppa*-hp-hpux10.2* )
 394     machine=hp800 opsys=hpux10-20
 395   ;;
 396   hppa*-hp-hpux1[1-9]* )
 397     machine=hp800 opsys=hpux11
 398     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 399   ;;
 400
 401   hppa*-*-linux-gnu* )
 402     machine=hp800 opsys=gnu-linux
 403   ;;
 404
 405   ## IBM machines
 406   s390-*-linux-gnu* )
 407     machine=ibms390 opsys=gnu-linux
 408   ;;
 409   s390x-*-linux-gnu* )
 410     machine=ibms390x opsys=gnu-linux
 411   ;;
 412   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 413     machine=ibmrs6000 opsys=aix4-2
 414   ;;
 415   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 416     machine=ibmrs6000 opsys=aix4-2
 417   ;;
 418   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 419     machine=ibmrs6000 opsys=aix4-2
 420   ;;
 421   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 422     machine=ibmrs6000 opsys=aix4-2
 423   ;;
 424
 425   ## Macintosh PowerPC
 426   powerpc*-*-linux-gnu* )
 427     machine=macppc opsys=gnu-linux
 428   ;;
 429
 430   ## Silicon Graphics machines
 431   ## Iris 4D
 432   mips-sgi-irix6.5 )
 433     machine=iris4d opsys=irix6-5
 434     # Without defining _LANGUAGE_C, things get masked out in the headers
 435     # so that, for instance, grepping for `free' in stdlib.h fails and
 436     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 437     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 438     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 439   ;;
 440
 441   ## Suns
 442   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 443     machine=sparc opsys=gnu-linux
 444   ;;
 445
 446   *-sun-solaris* \
 447     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 448     | x86_64-*-solaris2*    | x86_64-*-sunos5*    \
 449     | powerpc*-*-solaris2*  | rs6000-*-solaris2*)
 450     case "${canonical}" in
 451       i[3456]86-*-* )     machine=intel386 ;;
 452       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 453       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 454       sparc* )          machine=sparc ;;
 455       * )               unported=yes ;;
 456     esac
 457     case "${canonical}" in
 458       *-sunos5.3* | *-solaris2.3* )
 459                 opsys=sol2-3
 460                 NON_GNU_CPP=/usr/ccs/lib/cpp
 461                 ;;
 462       *-sunos5.4* | *-solaris2.4* )
 463                 opsys=sol2-4
 464                 NON_GNU_CPP=/usr/ccs/lib/cpp
 465                 RANLIB="ar -ts"
 466                 ;;
 467       *-sunos5.5* | *-solaris2.5* )
 468                 opsys=sol2-5
 469                 NON_GNU_CPP=/usr/ccs/lib/cpp
 470                 RANLIB="ar -ts"
 471                 ;;
 472       *-sunos5.6* | *-solaris2.6* )
 473                 opsys=sol2-6
 474                 NON_GNU_CPP=/usr/ccs/lib/cpp
 475                 RANLIB="ar -ts"
 476                 ;;
 477       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 478                 opsys=sol2-6
 479                 emacs_check_sunpro_c=yes
 480                 NON_GNU_CPP=/usr/ccs/lib/cpp
 481                 ;;
 482       *-sunos5* | *-solaris* )
 483                 opsys=sol2-10
 484                 emacs_check_sunpro_c=yes
 485                 NON_GNU_CPP=/usr/ccs/lib/cpp
 486                 ;;
 487     esac
 488     ## Watch out for a compiler that we know will not work.
 489     case "${canonical}" in
 490      *-solaris* | *-sunos5* )
 491                 if [ "x$CC" = x/usr/ucb/cc ]; then
 492                   ## /usr/ucb/cc doesn't work;
 493                   ## we should find some other compiler that does work.
 494                   unset CC
 495                 fi
 496                 ;;
 497       *) ;;
 498     esac
 499   ;;
 500
 501   ## Vaxen.
 502   vax-dec-* )
 503     machine=vax
 504     case "${canonical}" in
 505       *-vms* )                                          opsys=vms ;;
 506       * )                                               unported=yes
 507     esac
 508   ;;
 509
 510   ## IA-64
 511   ia64*-*-linux* )
 512     machine=ia64 opsys=gnu-linux
 513   ;;
 514
 515   ## Intel 386 machines where we don't care about the manufacturer
 516   i[3456]86-*-* )
 517     machine=intel386
 518     case "${canonical}" in
 519       *-cygwin )                opsys=cygwin ;;
 520       *-darwin* )               opsys=darwin
 521                                 CPP="${CC-cc} -E -no-cpp-precomp"
 522                                 ;;
 523       *-linux-gnu* )            opsys=gnu-linux ;;
 524       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 525       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 526       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 527       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 528     esac
 529   ;;
 530
 531   ## m68k Linux-based GNU system
 532   m68k-*-linux-gnu* )
 533     machine=m68k opsys=gnu-linux
 534   ;;
 535
 536   ## Mips Linux-based GNU system
 537   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 538     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 539     machine=mips opsys=gnu-linux
 540   ;;
 541
 542   ## AMD x86-64 Linux-based GNU system
 543   x86_64-*-linux-gnu* )
 544     machine=amdx86-64 opsys=gnu-linux
 545   ;;
 546
 547   ## Tensilica Xtensa Linux-based GNU system
 548   xtensa*-*-linux-gnu* )
 549     machine=xtensa opsys=gnu-linux
 550     ;;
 551
 552   ## SuperH Linux-based GNU system
 553   sh[34]*-*-linux-gnu* )
 554     machine=sh3 opsys=gnu-linux
 555   ;;
 556
 557   * )
 558     unported=yes
 559   ;;
 560 esac
 561
 562 ### If the code above didn't choose an operating system, just choose
 563 ### an operating system based on the configuration name.  You really
 564 ### only want to use this when you have no idea what the right
 565 ### operating system is; if you know what operating systems a machine
 566 ### runs, it's cleaner to make it explicit in the case statement
 567 ### above.
 568 if test x"${opsys}" = x; then
 569   case "${canonical}" in
 570     *-gnu* )                            opsys=gnu ;;
 571     *-sysv4.2uw* )                      opsys=unixware ;;
 572     *-sysv5uw* )                        opsys=unixware ;;
 573     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 574     *-sysv4.1* | *-sysvr4.1* )
 575         NON_GNU_CPP=/usr/lib/cpp
 576         opsys=usg5-4 ;;
 577     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 578         if [ x$NON_GNU_CPP = x ]; then
 579           if [ -f /usr/ccs/lib/cpp ]; then
 580             NON_GNU_CPP=/usr/ccs/lib/cpp
 581           else
 582             NON_GNU_CPP=/lib/cpp
 583           fi
 584         fi
 585         opsys=usg5-4-2 ;;
 586     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 587     * )
 588       unported=yes
 589     ;;
 590   esac
 591 fi
 592
 593 ]
 594 dnl quotation ends
 595
 596 if test $unported = yes; then
 597   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 598 Check `etc/MACHINES' for recognized configuration names.])
 599 fi
 600
 601 machfile="m/${machine}.h"
 602 opsysfile="s/${opsys}.h"
 603
 604
 605 #### Choose a compiler.
 606 test -n "$CC" && cc_specified=yes
 607
 608 # Save the value of CFLAGS that the user specified.
 609 SPECIFIED_CFLAGS="$CFLAGS"
 610
 611 dnl Sets GCC=yes if using gcc.
 612 AC_PROG_CC
 613
 614 # On Suns, sometimes $CPP names a directory.
 615 if test -n "$CPP" && test -d "$CPP"; then
 616   CPP=
 617 fi
 618
 619 ## If not using gcc, and on Solaris, and no CPP specified, see if
 620 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 621 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 622  test x"$CPP" = x; then
 623   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 624   AC_CACHE_VAL(emacs_cv_sunpro_c,
 625   [AC_TRY_LINK([],
 626 [#ifndef __SUNPRO_C
 627 fail;
 628 #endif
 629 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 630   AC_MSG_RESULT($emacs_cv_sunpro_c)
 631
 632   if test x"$emacs_cv_sunpro_c" = xyes; then
 633     NON_GNU_CPP="$CC -E -Xs"
 634   fi
 635 fi
 636
 637 #### Some systems specify a CPP to use unless we are using GCC.
 638 #### Now that we know whether we are using GCC, we can decide whether
 639 #### to use that one.
 640 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 641 then
 642   CPP="$NON_GNU_CPP"
 643 fi
 644
 645 #### Some systems specify a CC to use unless we are using GCC.
 646 #### Now that we know whether we are using GCC, we can decide whether
 647 #### to use that one.
 648 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 649   test x$cc_specified != xyes
 650 then
 651   CC="$NON_GNU_CC"
 652 fi
 653
 654 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 655 then
 656   CC="$CC $GCC_TEST_OPTIONS"
 657 fi
 658
 659 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 660 then
 661   CC="$CC $NON_GCC_TEST_OPTIONS"
 662 fi
 663
 664 dnl checks for Unix variants
 665 AC_USE_SYSTEM_EXTENSIONS
 666
 667 ### Use -Wno-pointer-sign if the compiler supports it
 668 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 669 SAVE_CFLAGS="$CFLAGS"
 670 CFLAGS="$CFLAGS -Wno-pointer-sign"
 671 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 672 if test $has_option = yes; then
 673    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 674 fi
 675 AC_MSG_RESULT($has_option)
 676 CFLAGS="$SAVE_CFLAGS"
 677 unset has_option
 678 unset SAVE_CFLAGS
 679
 680 #### Some other nice autoconf tests.
 681
 682 dnl checks for programs
 683 AC_PROG_LN_S
 684 AC_PROG_CPP
 685 AC_PROG_INSTALL
 686 if test "x$RANLIB" = x; then
 687   AC_PROG_RANLIB
 688 fi
 689 AC_PATH_PROG(INSTALL_INFO, install-info)
 690 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 691 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 692 dnl Don't use GZIP, which is used by gzip for additional parameters.
 693 AC_PATH_PROG(GZIP_PROG, gzip)
 694
 695
 696 ## Need makeinfo >= 4.6 (?) to build the manuals.
 697 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 698 dnl By this stage, configure has already checked for egrep and set EGREP,
 699 dnl or exited with an error if no egrep was found.
 700 if test "$MAKEINFO" != "no" && \
 701   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 702    MAKEINFO=no
 703 fi
 704
 705 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 706 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 707 ## therefore in the category of "special tools" not normally required, which
 708 ## configure does not have to check for (eg autoconf itself).
 709 ## In a CVS checkout on the other hand, the manuals are not included.
 710 ## So makeinfo is a requirement to build from CVS, and configure
 711 ## should test for it as it does for any other build requirement.
 712 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 713 ## with pre-built manuals, from a CVS checkout.
 714 if test "$MAKEINFO" = "no"; then
 715   if test "x${with_makeinfo}" = "xno"; then
 716     MAKEINFO=off
 717   elif ! test -e $srcdir/info/emacs; then
 718     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 719 source tree does not seem to have pre-built manuals in the `info' directory.
 720 Either install a suitable version of makeinfo, or re-run configure
 721 with the `--without-makeinfo' option to build without the manuals.] )
 722   fi
 723 fi
 724
 725 dnl Add our options to ac_link now, after it is set up.
 726
 727 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 728 then
 729   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 730 fi
 731
 732 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 733 then
 734   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 735 fi
 736
 737 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 738 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 739 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 740 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 741 dnl if not built to support GNU ld.
 742
 743 late_LDFLAGS=$LDFLAGS
 744 if test "$GCC" = yes; then
 745   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 746 else
 747   LDFLAGS="$LDFLAGS -znocombreloc"
 748 fi
 749
 750 AC_MSG_CHECKING([for -znocombreloc])
 751 AC_LINK_IFELSE([main(){return 0;}],
 752   [AC_MSG_RESULT(yes)],
 753   LDFLAGS=$late_LDFLAGS
 754   [AC_MSG_RESULT(no)])
 755
 756 #### Extract some information from the operating system and machine files.
 757
 758 AC_CHECKING([the machine- and system-dependent files to find out
 759  - which libraries the lib-src programs will want, and
 760  - whether the GNU malloc routines are usable])
 761
 762 ### First figure out CFLAGS (which we use for running the compiler here)
 763 ### and REAL_CFLAGS (which we use for real compilation).
 764 ### The two are the same except on a few systems, where they are made
 765 ### different to work around various lossages.  For example,
 766 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 767 ### as implying static linking.
 768
 769 ### If the CFLAGS env var is specified, we use that value
 770 ### instead of the default.
 771
 772 ### It's not important that this name contain the PID; you can't run
 773 ### two configures in the same directory and have anything work
 774 ### anyway.
 775 tempcname="conftest.c"
 776
 777 echo '
 778 #include "'${srcdir}'/src/'${opsysfile}'"
 779 #include "'${srcdir}'/src/'${machfile}'"
 780 #ifndef LIBS_MACHINE
 781 #define LIBS_MACHINE
 782 #endif
 783 #ifndef LIBS_SYSTEM
 784 #define LIBS_SYSTEM
 785 #endif
 786 #ifndef C_SWITCH_SYSTEM
 787 #define C_SWITCH_SYSTEM
 788 #endif
 789 #ifndef C_SWITCH_MACHINE
 790 #define C_SWITCH_MACHINE
 791 #endif
 792 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 793 configure___ c_switch_system=C_SWITCH_SYSTEM
 794 configure___ c_switch_machine=C_SWITCH_MACHINE
 795
 796 #ifndef LIB_X11_LIB
 797 #define LIB_X11_LIB -lX11
 798 #endif
 799
 800 #ifndef LIBX11_SYSTEM
 801 #define LIBX11_SYSTEM
 802 #endif
 803 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 804
 805 #ifdef UNEXEC
 806 configure___ unexec=UNEXEC
 807 #else
 808 configure___ unexec=unexec.o
 809 #endif
 810
 811 #ifdef SYSTEM_MALLOC
 812 configure___ system_malloc=yes
 813 #else
 814 configure___ system_malloc=no
 815 #endif
 816
 817 #ifdef USE_MMAP_FOR_BUFFERS
 818 configure___ use_mmap_for_buffers=yes
 819 #else
 820 configure___ use_mmap_for_buffers=no
 821 #endif
 822
 823 #ifndef C_DEBUG_SWITCH
 824 #define C_DEBUG_SWITCH -g
 825 #endif
 826
 827 #ifndef C_OPTIMIZE_SWITCH
 828 #ifdef __GNUC__
 829 #define C_OPTIMIZE_SWITCH -O2
 830 #else
 831 #define C_OPTIMIZE_SWITCH -O
 832 #endif
 833 #endif
 834
 835 #ifndef C_WARNINGS_SWITCH
 836 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 837 #endif
 838
 839 #ifndef LD_SWITCH_MACHINE
 840 #define LD_SWITCH_MACHINE
 841 #endif
 842
 843 #ifndef LD_SWITCH_SYSTEM
 844 #define LD_SWITCH_SYSTEM
 845 #endif
 846
 847 #ifndef LD_SWITCH_X_SITE_AUX
 848 #define LD_SWITCH_X_SITE_AUX
 849 #endif
 850
 851 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 852 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 853
 854 #ifdef THIS_IS_CONFIGURE
 855
 856 /* Get the CFLAGS for tests in configure.  */
 857 #ifdef __GNUC__
 858 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 859 #else
 860 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 861 #endif
 862
 863 #else /* not THIS_IS_CONFIGURE */
 864
 865 /* Get the CFLAGS for real compilation.  */
 866 #ifdef __GNUC__
 867 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
 868 #else
 869 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 870 #endif
 871
 872 #endif /* not THIS_IS_CONFIGURE */
 873 ' > ${tempcname}
 874
 875 # The value of CPP is a quoted variable reference, so we need to do this
 876 # to get its actual value...
 877 CPP=`eval "echo $CPP"`
 878 [eval `${CPP} -Isrc ${tempcname} \
 879        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 880 if test "x$SPECIFIED_CFLAGS" = x; then
 881   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 882          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 883 else
 884   REAL_CFLAGS="$CFLAGS"
 885 fi]
 886 rm ${tempcname}
 887
 888 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 889
 890 ### Make sure subsequent tests use flags consistent with the build flags.
 891
 892 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 893   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 894 else
 895   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 896 fi
 897
 898 dnl For AC_FUNC_GETLOADAVG, at least:
 899 AC_CONFIG_LIBOBJ_DIR(src)
 900
 901 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 902 AC_SYS_LARGEFILE
 903
 904
 905 ### The standard library on x86-64 and s390x GNU/Linux distributions can
 906 ### be located in either /usr/lib64 or /usr/lib.
 907 ### In some rare cases, /usr/lib64 exists but does not contain the
 908 ### relevant files (bug#1287).  Hence test for crtn.o.
 909 case "${canonical}" in
 910   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
 911     if test -e /usr/lib64/crtn.o; then
 912       AC_DEFINE(HAVE_LIB64_DIR, 1,
 913         [Define to 1 if the directory /usr/lib64 exists.])
 914 fi
 915 esac
 916
 917 dnl This function defintion taken from Gnome 2.0
 918 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
 919 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
 920 dnl also defines GSTUFF_PKG_ERRORS on error
 921 AC_DEFUN([PKG_CHECK_MODULES], [
 922   succeeded=no
 923
 924   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 925
 926   if test "$PKG_CONFIG" = "no" ; then
 927      ifelse([$4], , [AC_MSG_ERROR([
 928       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
 929   else
 930      PKG_CONFIG_MIN_VERSION=0.9.0
 931      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
 932         AC_MSG_CHECKING(for $2)
 933
 934         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
 935             AC_MSG_RESULT(yes)
 936             succeeded=yes
 937
 938             AC_MSG_CHECKING($1_CFLAGS)
 939             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
 940             AC_MSG_RESULT($$1_CFLAGS)
 941
 942             AC_MSG_CHECKING($1_LIBS)
 943             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
 944             AC_MSG_RESULT($$1_LIBS)
 945         else
 946             AC_MSG_RESULT(no)
 947             $1_CFLAGS=""
 948             $1_LIBS=""
 949             ## If we have a custom action on failure, don't print errors, but
 950             ## do set a variable so people can do so.
 951             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
 952             ifelse([$4], ,echo $$1_PKG_ERRORS,)
 953         fi
 954
 955         AC_SUBST($1_CFLAGS)
 956         AC_SUBST($1_LIBS)
 957      else
 958         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
 959         echo "*** See http://www.freedesktop.org/software/pkgconfig"
 960      fi
 961   fi
 962
 963   if test $succeeded = yes; then
 964      ifelse([$3], , :, [$3])
 965   else
 966      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
 967   fi
 968 ])
 969
 970
 971 if test "${with_sound}" != "no"; then
 972   # Sound support for GNU/Linux and the free BSDs.
 973   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
 974   # Emulation library used on NetBSD.
 975   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
 976   AC_SUBST(LIBSOUND)
 977
 978   ALSA_REQUIRED=1.0.0
 979   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
 980   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
 981   if test $HAVE_ALSA = yes; then
 982     SAVE_CFLAGS="$CFLAGS"
 983     SAVE_LDFLAGS="$LDFLAGS"
 984     CFLAGS="$ALSA_CFLAGS $CFLAGS"
 985     LDFLAGS="$ALSA_LIBS $LDFLAGS"
 986     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
 987                     emacs_alsa_normal=yes,
 988                     emacs_alsa_normal=no)
 989     if test "$emacs_alsa_normal" != yes; then
 990       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
 991                      [snd_lib_error_set_handler (0);],
 992                      emacs_alsa_subdir=yes,
 993                      emacs_alsa_subdir=no)
 994       if test "$emacs_alsa_subdir" != yes; then
 995         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
 996       fi
 997       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
 998     fi
 999
1000     CFLAGS="$SAVE_CFLAGS"
1001     LDFLAGS="$SAVE_LDFLAGS"
1002     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1003     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1004     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1005   fi
1006   AC_SUBST(CFLAGS_SOUND)
1007 fi
1008
1009 dnl checks for header files
1010 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1011   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1012   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1013   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1014   sys/utsname.h pwd.h)
1015
1016 AC_MSG_CHECKING(if personality LINUX32 can be set)
1017 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1018                emacs_cv_personality_linux32=yes,
1019                emacs_cv_personality_linux32=no)
1020 AC_MSG_RESULT($emacs_cv_personality_linux32)
1021
1022 if test $emacs_cv_personality_linux32 = yes; then
1023   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1024             [Define to 1 if personality LINUX32 can be set.])
1025 fi
1026
1027 dnl On Solaris 8 there's a compilation warning for term.h because
1028 dnl it doesn't define `bool'.
1029 AC_CHECK_HEADERS(term.h, , , -)
1030 AC_HEADER_STDC
1031 AC_HEADER_TIME
1032 AC_CHECK_DECLS([sys_siglist])
1033 if test $ac_cv_have_decl_sys_siglist != yes; then
1034   # For Tru64, at least:
1035   AC_CHECK_DECLS([__sys_siglist])
1036   if test $ac_cv_have_decl___sys_siglist = yes; then
1037     AC_DEFINE(sys_siglist, __sys_siglist,
1038               [Define to any substitute for sys_siglist.])
1039   fi
1040 fi
1041 AC_HEADER_SYS_WAIT
1042
1043 dnl Some systems have utime.h but don't declare the struct anyplace.
1044 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1045 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1046 #include <sys/time.h>
1047 #include <time.h>
1048 #else
1049 #ifdef HAVE_SYS_TIME_H
1050 #include <sys/time.h>
1051 #else
1052 #include <time.h>
1053 #endif
1054 #endif
1055 #ifdef HAVE_UTIME_H
1056 #include <utime.h>
1057 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1058   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1059 if test $emacs_cv_struct_utimbuf = yes; then
1060   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1061 fi
1062
1063 dnl checks for typedefs
1064 AC_TYPE_SIGNAL
1065
1066 dnl Check for speed_t typedef.
1067 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1068   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1069     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1070 if test $emacs_cv_speed_t = yes; then
1071   AC_DEFINE(HAVE_SPEED_T, 1,
1072            [Define to 1 if `speed_t' is declared by <termios.h>.])
1073 fi
1074
1075 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1076 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1077 #include <sys/time.h>
1078 #include <time.h>
1079 #else
1080 #ifdef HAVE_SYS_TIME_H
1081 #include <sys/time.h>
1082 #else
1083 #include <time.h>
1084 #endif
1085 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1086   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1087 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1088 if test $emacs_cv_struct_timeval = yes; then
1089   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1090 fi
1091
1092 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1093 AC_TRY_COMPILE([#include <math.h>],
1094 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1095   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1096 HAVE_EXCEPTION=$emacs_cv_struct_exception
1097 if test $emacs_cv_struct_exception != yes; then
1098   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1099 fi
1100
1101 AC_CHECK_HEADERS(sys/socket.h)
1102 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1103 #if HAVE_SYS_SOCKET_H
1104 #include <sys/socket.h>
1105 #endif])
1106
1107 dnl checks for structure members
1108 AC_STRUCT_TM
1109 AC_STRUCT_TIMEZONE
1110 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1111                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1112                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1113                 [#include <time.h>])
1114 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1115                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1116                   struct ifreq.ifr_addr], , ,
1117                  [AC_INCLUDES_DEFAULT
1118 #if HAVE_SYS_SOCKET_H
1119 #include <sys/socket.h>
1120 #endif
1121 #if HAVE_NET_IF_H
1122 #include <net/if.h>
1123 #endif])
1124
1125 dnl checks for compiler characteristics
1126
1127 dnl Testing __STDC__ to determine prototype support isn't good enough.
1128 dnl DEC C, for instance, doesn't define it with default options, and
1129 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1130 dnl and void *.
1131 AC_C_PROTOTYPES
1132 AC_C_VOLATILE
1133 AC_C_CONST
1134 dnl This isn't useful because we can't turn on use of `inline' unless
1135 dnl the compiler groks `extern inline'.
1136 dnl AC_C_INLINE
1137 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1138   [AC_TRY_COMPILE(, [void * foo;],
1139                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1140 if test $emacs_cv_void_star = yes; then
1141   AC_DEFINE(POINTER_TYPE, void)
1142 else
1143   AC_DEFINE(POINTER_TYPE, char)
1144 fi
1145 AH_TEMPLATE(POINTER_TYPE,
1146             [Define as `void' if your compiler accepts `void *'; otherwise
1147              define as `char'.])dnl
1148
1149
1150
1151 dnl This could be used for targets which can have both byte sexes.
1152 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1153 dnl AC_C_BIGENDIAN
1154
1155 dnl check for Make feature
1156 AC_PROG_MAKE_SET
1157
1158 dnl checks for operating system services
1159 AC_SYS_LONG_FILE_NAMES
1160
1161 #### Choose a window system.
1162
1163 AC_PATH_X
1164 if test "$no_x" = yes; then
1165   window_system=none
1166 else
1167   window_system=x11
1168 fi
1169
1170 ## Workaround for bug in autoconf <= 2.62.
1171 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1172 ## No need to do anything special for these standard directories.
1173 ## This is an experiment, take it out if it causes problems.
1174 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1175
1176    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1177
1178 fi
1179
1180 if test "${x_libraries}" != NONE; then
1181   if test -n "${x_libraries}"; then
1182     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1183     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1184   fi
1185   x_default_search_path=""
1186   x_search_path=${x_libraries}
1187   if test -z "${x_search_path}"; then
1188     x_search_path=/usr/lib
1189   fi
1190   for x_library in `echo ${x_search_path}: | \
1191                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1192     x_search_path="\
1193 ${x_library}/X11/%L/%T/%N%C%S:\
1194 ${x_library}/X11/%l/%T/%N%C%S:\
1195 ${x_library}/X11/%T/%N%C%S:\
1196 ${x_library}/X11/%L/%T/%N%S:\
1197 ${x_library}/X11/%l/%T/%N%S:\
1198 ${x_library}/X11/%T/%N%S"
1199     if test x"${x_default_search_path}" = x; then
1200       x_default_search_path=${x_search_path}
1201     else
1202       x_default_search_path="${x_search_path}:${x_default_search_path}"
1203     fi
1204   done
1205 fi
1206 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1207   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1208 fi
1209
1210 if test x"${x_includes}" = x; then
1211   bitmapdir=/usr/include/X11/bitmaps
1212 else
1213   # accumulate include directories that have X11 bitmap subdirectories
1214   bmd_acc="dummyval"
1215   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1216     if test -d "${bmd}/X11/bitmaps"; then
1217       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1218     fi
1219     if test -d "${bmd}/bitmaps"; then
1220       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1221     fi
1222   done
1223   if test ${bmd_acc} != "dummyval"; then
1224     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1225   fi
1226 fi
1227
1228 HAVE_NS=no
1229 NS_IMPL_COCOA=no
1230 NS_IMPL_GNUSTEP=no
1231 tmp_CPPFLAGS="$CPPFLAGS"
1232 tmp_CFLAGS="$CFLAGS"
1233 CPPFLAGS="$CPPFLAGS -x objective-c"
1234 CFLAGS="$CFLAGS -x objective-c"
1235 if test "${with_ns}" != no; then
1236   if test "${opsys}" = darwin; then
1237      NS_IMPL_COCOA=yes
1238      ns_appdir=`pwd`/nextstep/Emacs.app
1239      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1240      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1241      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1242   elif test -f $GNUSTEP_CONFIG_FILE; then
1243      NS_IMPL_GNUSTEP=yes
1244      ns_appdir=`pwd`/nextstep/Emacs.app
1245      ns_appbindir=`pwd`/nextstep/Emacs.app
1246      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1247      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1248      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1249      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1250      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1251      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1252      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1253      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1254      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1255      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1256   fi
1257   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1258                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1259   files are missing or cannot be compiled.])])
1260   NS_HAVE_NSINTEGER=yes
1261   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1262                                      [NSInteger i;])],
1263                     ns_have_nsinteger=yes,
1264                     ns_have_nsinteger=no)
1265   if test $ns_have_nsinteger = no; then
1266     NS_HAVE_NSINTEGER=no
1267   fi
1268 fi
1269 if test "${HAVE_NS}" = yes; then
1270   window_system=nextstep
1271   with_xft=no
1272   # set up packaging dirs
1273   exec_prefix=${ns_appbindir}
1274   libexecdir=${ns_appbindir}/libexec
1275   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1276      prefix=${ns_appresdir}
1277   fi
1278 fi
1279 CFLAGS="$tmp_CFLAGS"
1280 CPPFLAGS="$tmp_CPPFLAGS"
1281
1282 case "${window_system}" in
1283   x11 )
1284     HAVE_X_WINDOWS=yes
1285     HAVE_X11=yes
1286     case "${with_x_toolkit}" in
1287       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1288       motif ) USE_X_TOOLKIT=MOTIF ;;
1289       gtk ) with_gtk=yes
1290 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1291 dnl USE_X_TOOLKIT is set.
1292             USE_X_TOOLKIT=none ;;
1293       no ) USE_X_TOOLKIT=none ;;
1294 dnl If user did not say whether to use a toolkit, make this decision later:
1295 dnl use the toolkit if we have gtk, or X11R5 or newer.
1296       * ) USE_X_TOOLKIT=maybe ;;
1297     esac
1298   ;;
1299   nextstep | none )
1300     HAVE_X_WINDOWS=no
1301     HAVE_X11=no
1302     USE_X_TOOLKIT=none
1303   ;;
1304 esac
1305
1306 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1307    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1308    if test "$HAVE_XSERVER" = true ||
1309       test -n "$DISPLAY" ||
1310       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1311         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1312 were found.  You should install the relevant development files for X
1313 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1314 sure you have development files for image handling, i.e.
1315 tiff, gif, jpeg, png and xpm.
1316 If you are sure you want Emacs compiled without X window support, pass
1317   --without-x
1318 to configure.])
1319    fi
1320 fi
1321
1322 ### If we're using X11, we should use the X menu package.
1323 HAVE_MENUS=no
1324 case ${HAVE_X11} in
1325   yes ) HAVE_MENUS=yes ;;
1326 esac
1327
1328 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1329 # Assume not, until told otherwise.
1330 GNU_MALLOC=yes
1331 doug_lea_malloc=yes
1332 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1333 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1334 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1335                emacs_cv_var___after_morecore_hook,
1336 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1337   emacs_cv_var___after_morecore_hook=yes,
1338   emacs_cv_var___after_morecore_hook=no)])
1339 if test $emacs_cv_var___after_morecore_hook = no; then
1340   doug_lea_malloc=no
1341 fi
1342 if test "${system_malloc}" = "yes"; then
1343   GNU_MALLOC=no
1344   GNU_MALLOC_reason="
1345     (The GNU allocators don't work with this system configuration.)"
1346 fi
1347 if test "$doug_lea_malloc" = "yes" ; then
1348   if test "$GNU_MALLOC" = yes ; then
1349     GNU_MALLOC_reason="
1350       (Using Doug Lea's new malloc from the GNU C Library.)"
1351   fi
1352   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1353             [Define to 1 if you are using the GNU C Library.])
1354 fi
1355
1356 if test x"${REL_ALLOC}" = x; then
1357   REL_ALLOC=${GNU_MALLOC}
1358 fi
1359
1360 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1361 dnl the system configuration file (s/*.h) to turn the use of mmap
1362 dnl in the relocating allocator on.
1363
1364 AC_FUNC_MMAP
1365 if test $use_mmap_for_buffers = yes; then
1366   REL_ALLOC=no
1367 fi
1368
1369 LIBS="$libsrc_libs $LIBS"
1370
1371 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1372 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1373 AC_CHECK_LIB(dnet, dnet_ntoa)
1374 dnl This causes -lresolv to get used in subsequent tests,
1375 dnl which causes failures on some systems such as HPUX 9.
1376 dnl AC_CHECK_LIB(resolv, gethostbyname)
1377
1378 dnl FIXME replace main with a function we actually want from this library.
1379 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1380
1381 AC_CHECK_LIB(pthreads, cma_open)
1382
1383 dnl Check for need for bigtoc support on IBM AIX
1384
1385 case ${host_os} in
1386 aix*)
1387   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1388     case $GCC in
1389     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1390     *) gdb_cv_bigtoc=-bbigtoc ;;
1391     esac
1392
1393     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1394     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1395   ])
1396   ;;
1397 esac
1398
1399 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1400 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1401 # REAL_CPPFLAGS later on.
1402
1403 REAL_CPPFLAGS="$CPPFLAGS"
1404
1405 if test "${HAVE_X11}" = "yes"; then
1406   DEFS="$C_SWITCH_X_SITE $DEFS"
1407   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1408   LIBS="$LIBX $LIBS"
1409   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1410   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1411
1412   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1413   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1414   # but it's more convenient here to set LD_RUN_PATH
1415   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1416   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1417     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1418     export LD_RUN_PATH
1419   fi
1420
1421   if test "${opsys}" = "gnu-linux"; then
1422     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1423     AC_TRY_LINK([],
1424      [XOpenDisplay ("foo");],
1425      [xlinux_first_failure=no],
1426      [xlinux_first_failure=yes])
1427     if test "${xlinux_first_failure}" = "yes"; then
1428       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1429       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1430       OLD_CPPFLAGS="$CPPFLAGS"
1431       OLD_LIBS="$LIBS"
1432       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1433       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1434       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1435       LIBS="$LIBS -b i486-linuxaout"
1436       AC_TRY_LINK([],
1437        [XOpenDisplay ("foo");],
1438        [xlinux_second_failure=no],
1439        [xlinux_second_failure=yes])
1440       if test "${xlinux_second_failure}" = "yes"; then
1441         # If we get the same failure with -b, there is no use adding -b.
1442         # So take it out.  This plays safe.
1443         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1444         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1445         CPPFLAGS="$OLD_CPPFLAGS"
1446         LIBS="$OLD_LIBS"
1447         AC_MSG_RESULT(no)
1448       else
1449         AC_MSG_RESULT(yes)
1450       fi
1451     else
1452       AC_MSG_RESULT(no)
1453     fi
1454   fi
1455
1456   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1457   # header files included from there.
1458   AC_MSG_CHECKING(for Xkb)
1459   AC_TRY_LINK([#include <X11/Xlib.h>
1460 #include <X11/XKBlib.h>],
1461         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1462         emacs_xkb=yes, emacs_xkb=no)
1463   AC_MSG_RESULT($emacs_xkb)
1464   if test $emacs_xkb = yes; then
1465     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1466   fi
1467
1468   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1469 XScreenNumberOfScreen XSetWMProtocols)
1470 fi
1471
1472 if test "${window_system}" = "x11"; then
1473   AC_MSG_CHECKING(X11 version 6)
1474   AC_CACHE_VAL(emacs_cv_x11_version_6,
1475   [AC_TRY_LINK([#include <X11/Xlib.h>],
1476 [#if XlibSpecificationRelease < 6
1477 fail;
1478 #endif
1479 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1480   if test $emacs_cv_x11_version_6 = yes; then
1481     AC_MSG_RESULT(6 or newer)
1482     AC_DEFINE(HAVE_X11R6, 1,
1483               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1484   else
1485     AC_MSG_RESULT(before 6)
1486   fi
1487 fi
1488
1489
1490 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1491 HAVE_RSVG=no
1492 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1493   if test "${with_rsvg}" != "no"; then
1494     RSVG_REQUIRED=2.11.0
1495     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1496
1497     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1498     AC_SUBST(RSVG_CFLAGS)
1499     AC_SUBST(RSVG_LIBS)
1500
1501     if test ".${RSVG_CFLAGS}" != "."; then
1502       HAVE_RSVG=yes
1503       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1504       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1505       LIBS="$RSVG_LIBS $LIBS"
1506     fi
1507   fi
1508 fi
1509
1510
1511 HAVE_GTK=no
1512 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1513   GLIB_REQUIRED=2.6
1514   GTK_REQUIRED=2.6
1515   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1516
1517   dnl Checks for libraries.
1518   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1519   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1520      AC_MSG_ERROR($GTK_PKG_ERRORS)
1521   fi
1522 fi
1523
1524
1525 if test x"$pkg_check_gtk" = xyes; then
1526
1527   AC_SUBST(GTK_CFLAGS)
1528   AC_SUBST(GTK_LIBS)
1529   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1530   CFLAGS="$CFLAGS $GTK_CFLAGS"
1531   LIBS="$GTK_LIBS $LIBS"
1532   dnl Try to compile a simple GTK program.
1533   GTK_COMPILES=no
1534   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1535   if test "${GTK_COMPILES}" != "yes"; then
1536     if test "$USE_X_TOOLKIT" != "maybe"; then
1537       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1538     fi
1539   else
1540     HAVE_GTK=yes
1541     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1542     USE_X_TOOLKIT=none
1543     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1544       :
1545     else
1546       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1547        closing open displays.  This is no problem if you just use
1548        one display, but if you use more than one and close one of them
1549        Emacs may crash.]])
1550       sleep 3
1551     fi
1552   fi
1553
1554 fi
1555
1556
1557 if test "${HAVE_GTK}" = "yes"; then
1558
1559   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1560   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1561   if test "$with_toolkit_scroll_bars" != no; then
1562     with_toolkit_scroll_bars=yes
1563   fi
1564
1565   dnl  Check if we can use multiple displays with this GTK version.
1566   dnl  If gdk_display_open exists, assume all others are there also.
1567   HAVE_GTK_MULTIDISPLAY=no
1568   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1569   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1570     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1571               [Define to 1 if GTK can handle more than one display.])
1572   fi
1573
1574   dnl  Check if we have the old file selection dialog declared and
1575   dnl  in the link library.  In 2.x it may be in the library,
1576   dnl  but not declared if deprecated featured has been selected out.
1577   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1578   HAVE_GTK_FILE_SELECTION=no
1579   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1580                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1581 #include <gtk/gtk.h>])
1582   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1583     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1584                    HAVE_GTK_FILE_SELECTION=no)
1585   fi
1586
1587   dnl  Check if we have the new file chooser dialog
1588   HAVE_GTK_FILE_CHOOSER=no
1589   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1590                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1591 #include <gtk/gtk.h>])
1592   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1593     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1594                    HAVE_GTK_FILE_CHOOSER=no)
1595   fi
1596
1597   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1598      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1599     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1600               [Define to 1 if GTK has both file selection and chooser dialog.])
1601   fi
1602
1603   dnl Check if pthreads are available.  Emacs only needs this when using
1604   dnl gtk_file_chooser under Gnome.
1605   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1606     HAVE_GTK_AND_PTHREAD=no
1607     AC_CHECK_HEADERS(pthread.h)
1608     if test "$ac_cv_header_pthread_h"; then
1609       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1610     fi
1611     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1612       case "${canonical}" in
1613         *-hpux*) ;;
1614         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1615       esac
1616       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1617                [Define to 1 if you have GTK and pthread (-lpthread).])
1618     fi
1619   fi
1620 fi
1621
1622 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1623 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1624 dnl also not configured.
1625 HAVE_DBUS=no
1626 if test "${with_dbus}" = "yes"; then
1627    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1628    if test "$HAVE_DBUS" = yes; then
1629       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1630    fi
1631 fi
1632
1633 dnl Do not put whitespace before the #include statements below.
1634 dnl Older compilers (eg sunos4 cc) choke on it.
1635 HAVE_XAW3D=no
1636 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1637   if test "$with_xaw3d" != no; then
1638     AC_MSG_CHECKING(for xaw3d)
1639     AC_CACHE_VAL(emacs_cv_xaw3d,
1640     [AC_TRY_LINK([
1641 #include <X11/Intrinsic.h>
1642 #include <X11/Xaw3d/Simple.h>],
1643       [],
1644       emacs_cv_xaw3d=yes,
1645       emacs_cv_xaw3d=no)])
1646   else
1647     emacs_cv_xaw3d=no
1648   fi
1649   if test $emacs_cv_xaw3d = yes; then
1650     AC_MSG_RESULT([yes; using Lucid toolkit])
1651     USE_X_TOOLKIT=LUCID
1652     HAVE_XAW3D=yes
1653     AC_DEFINE(HAVE_XAW3D, 1,
1654               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1655   else
1656     AC_MSG_RESULT(no)
1657     AC_MSG_CHECKING(for libXaw)
1658     AC_CACHE_VAL(emacs_cv_xaw,
1659     [AC_TRY_LINK([
1660 #include <X11/Intrinsic.h>
1661 #include <X11/Xaw/Simple.h>],
1662       [],
1663       emacs_cv_xaw=yes,
1664       emacs_cv_xaw=no)])
1665     if test $emacs_cv_xaw = yes; then
1666       AC_MSG_RESULT([yes; using Lucid toolkit])
1667       USE_X_TOOLKIT=LUCID
1668     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1669       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1670     else
1671       AC_MSG_RESULT([no; do not use toolkit by default])
1672       USE_X_TOOLKIT=none
1673     fi
1674   fi
1675 fi
1676
1677 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1678
1679 if test "${USE_X_TOOLKIT}" != "none"; then
1680   AC_MSG_CHECKING(X11 toolkit version)
1681   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1682   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1683 [#if XtSpecificationRelease < 6
1684 fail;
1685 #endif
1686 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1687   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1688   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1689     AC_MSG_RESULT(6 or newer)
1690     AC_DEFINE(HAVE_X11XTR6, 1,
1691               [Define to 1 if you have the X11R6 or newer version of Xt.])
1692   else
1693     AC_MSG_RESULT(before 6)
1694   fi
1695
1696 dnl If using toolkit, check whether libXmu.a exists.
1697 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1698   OLDLIBS="$LIBS"
1699   if test x$HAVE_X11XTR6 = xyes; then
1700     LIBS="-lXt -lSM -lICE $LIBS"
1701   else
1702     LIBS="-lXt $LIBS"
1703   fi
1704   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1705   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1706 fi
1707
1708 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1709 if test "${HAVE_X11}" = "yes"; then
1710   if test "${USE_X_TOOLKIT}" != "none"; then
1711     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1712   fi
1713 fi
1714
1715 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1716   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1717   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1718     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1719 int x = 5;
1720 #else
1721 Motif version prior to 2.1.
1722 #endif],
1723     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1724   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1725   if test $emacs_cv_motif_version_2_1 = yes; then
1726     HAVE_LIBXP=no
1727     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1728               [Define to 1 if you have Motif 2.1 or newer.])
1729     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1730     if test ${HAVE_LIBXP} = yes; then
1731       AC_DEFINE(HAVE_LIBXP, 1,
1732                 [Define to 1 if you have the Xp library (-lXp).])
1733     fi
1734   else
1735     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1736     # We put this in CFLAGS temporarily to precede other -I options
1737     # that might be in CFLAGS temporarily.
1738     # We put this in CPPFLAGS where it precedes the other -I options.
1739     OLD_CPPFLAGS=$CPPFLAGS
1740     OLD_CFLAGS=$CFLAGS
1741     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1742     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1743     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1744       [int x = 5;],
1745       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1746     if test $emacs_cv_lesstif = yes; then
1747       # Make sure this -I option remains in CPPFLAGS after it is set
1748       # back to REAL_CPPFLAGS.
1749       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1750       # have those other -I options anyway.  Ultimately, having this
1751       # directory ultimately in CPPFLAGS will be enough.
1752       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1753       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1754     else
1755       CFLAGS=$OLD_CFLAGS
1756       CPPFLAGS=$OLD_CPPFLAGS
1757     fi
1758   fi
1759 fi
1760
1761 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1762 dnl using Motif or Xaw3d is available, and unless
1763 dnl --with-toolkit-scroll-bars=no was specified.
1764
1765 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1766             [Define to 1 if we should use toolkit scroll bars.])dnl
1767 USE_TOOLKIT_SCROLL_BARS=no
1768 if test "${with_toolkit_scroll_bars}" != "no"; then
1769   if test "${USE_X_TOOLKIT}" != "none"; then
1770     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1771       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1772       HAVE_XAW3D=no
1773       USE_TOOLKIT_SCROLL_BARS=yes
1774     elif test "${HAVE_XAW3D}" = "yes"; then
1775       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1776       USE_TOOLKIT_SCROLL_BARS=yes
1777     fi
1778   elif test "${HAVE_GTK}" = "yes"; then
1779     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1780     USE_TOOLKIT_SCROLL_BARS=yes
1781   elif test "${HAVE_NS}" = "yes"; then
1782     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1783     USE_TOOLKIT_SCROLL_BARS=yes
1784   fi
1785 fi
1786
1787 dnl See if XIM is available.
1788 AC_TRY_COMPILE([
1789           #include <X11/Xlib.h>
1790           #include <X11/Xresource.h>],
1791          [XIMProc  callback;],
1792          [HAVE_XIM=yes
1793          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1794          HAVE_XIM=no)
1795
1796 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1797
1798 if test "${with_xim}" != "no"; then
1799   AC_DEFINE(USE_XIM, 1,
1800             [Define to 1 if we should use XIM, if it is available.])
1801 fi
1802
1803
1804 if test "${HAVE_XIM}" != "no"; then
1805   late_CFLAGS=$CFLAGS
1806   if test "$GCC" = yes; then
1807     CFLAGS="$CFLAGS --pedantic-errors"
1808   fi
1809   AC_TRY_COMPILE([
1810 #include <X11/Xlib.h>
1811 #include <X11/Xresource.h>],
1812 [Display *display;
1813 XrmDatabase db;
1814 char *res_name;
1815 char *res_class;
1816 XIMProc  callback;
1817 XPointer *client_data;
1818 #ifndef __GNUC__
1819 /* If we're not using GCC, it's probably not XFree86, and this is
1820    probably right, but we can't use something like --pedantic-errors.  */
1821 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1822                                            char*, XIMProc, XPointer*);
1823 #endif
1824 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1825    client_data);],
1826     [emacs_cv_arg6_star=yes])
1827   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1828          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1829 either XPointer or XPointer*.])dnl
1830   if test "$emacs_cv_arg6_star" = yes; then
1831     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1832   else
1833     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1834   fi
1835   CFLAGS=$late_CFLAGS
1836 fi
1837
1838 ### Start of font-backend (under any platform) section.
1839 # (nothing here yet -- this is a placeholder)
1840 ### End of font-backend (under any platform) section.
1841
1842 ### Start of font-backend (under X11) section.
1843 if test "${HAVE_X11}" = "yes"; then
1844    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
1845
1846    ## Use -lXft if available, unless `--with-xft=no'.
1847    HAVE_XFT=maybe
1848     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
1849       with_xft="no";
1850     fi
1851     if test "x${with_xft}" != "xno"; then
1852
1853       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1854       if test "$HAVE_XFT" != no; then
1855         OLD_CPPFLAGS="$CPPFLAGS"
1856         OLD_CFLAGS="$CFLAGS"
1857         OLD_LIBS="$LIBS"
1858         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1859         CFLAGS="$CFLAGS $XFT_CFLAGS"
1860         LIBS="$XFT_LIBS $LIBS"
1861         AC_CHECK_HEADER(X11/Xft/Xft.h,
1862           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1863
1864         if test "${HAVE_XFT}" = "yes"; then
1865           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1866             AC_SUBST(XFT_LIBS)
1867           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1868         else
1869           CPPFLAGS="$OLD_CPPFLAGS"
1870           CFLAGS="$OLD_CFLAGS"
1871           LIBS="$OLD_LIBS"
1872         fi                        # "${HAVE_XFT}" = "yes"
1873       fi                          # "$HAVE_XFT" != no
1874     fi                            # "x${with_xft}" != "xno"
1875
1876     dnl For the "Does Emacs use" message at the end.
1877     if test "$HAVE_XFT" != "yes"; then
1878        HAVE_XFT=no
1879     fi
1880
1881
1882     HAVE_FREETYPE=no
1883     ## We used to allow building with FreeType and without Xft.
1884     ## However, the ftx font backend driver is not in good shape.
1885     if test "${HAVE_XFT}" = "yes"; then
1886       dnl As we use Xft, we anyway use freetype.
1887       dnl There's no need for additional CFLAGS and LIBS.
1888       HAVE_FREETYPE=yes
1889       FONTCONFIG_CFLAGS=
1890       FONTCONFIG_LIBS=
1891     fi
1892
1893     HAVE_LIBOTF=no
1894     if test "${HAVE_FREETYPE}" = "yes"; then
1895       AC_DEFINE(HAVE_FREETYPE, 1,
1896                 [Define to 1 if using the freetype and fontconfig libraries.])
1897       if test "${with_libotf}" != "no"; then
1898         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
1899                           HAVE_LIBOTF=no)
1900         if test "$HAVE_LIBOTF" = "yes"; then
1901           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
1902           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
1903                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
1904                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
1905           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
1906             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
1907                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
1908           fi
1909         fi
1910       fi
1911     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
1912     dnl Does the new font backend require it, or can it work without it?
1913     fi
1914
1915     HAVE_M17N_FLT=no
1916     if test "${HAVE_LIBOTF}" = yes; then
1917       if test "${with_m17n_flt}" != "no"; then
1918         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
1919         if test "$HAVE_M17N_FLT" = "yes"; then
1920           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
1921         fi
1922       fi
1923     fi
1924 else
1925     HAVE_XFT=no
1926     HAVE_FREETYPE=no
1927     HAVE_LIBOTF=no
1928     HAVE_M17N_FLT=no
1929 fi
1930 ### End of font-backend (under X11) section.
1931
1932 AC_SUBST(FREETYPE_CFLAGS)
1933 AC_SUBST(FREETYPE_LIBS)
1934 AC_SUBST(FONTCONFIG_CFLAGS)
1935 AC_SUBST(FONTCONFIG_LIBS)
1936 AC_SUBST(LIBOTF_CFLAGS)
1937 AC_SUBST(LIBOTF_LIBS)
1938 AC_SUBST(M17N_FLT_CFLAGS)
1939 AC_SUBST(M17N_FLT_LIBS)
1940
1941 ### Use -lXpm if available, unless `--with-xpm=no'.
1942 HAVE_XPM=no
1943 if test "${HAVE_X11}" = "yes"; then
1944   if test "${with_xpm}" != "no"; then
1945     AC_CHECK_HEADER(X11/xpm.h,
1946       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
1947     if test "${HAVE_XPM}" = "yes"; then
1948       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
1949       AC_EGREP_CPP(no_return_alloc_pixels,
1950       [#include "X11/xpm.h"
1951 #ifndef XpmReturnAllocPixels
1952 no_return_alloc_pixels
1953 #endif
1954       ], HAVE_XPM=no, HAVE_XPM=yes)
1955
1956       if test "${HAVE_XPM}" = "yes"; then
1957         AC_MSG_RESULT(yes)
1958       else
1959         AC_MSG_RESULT(no)
1960       fi
1961     fi
1962   fi
1963
1964   if test "${HAVE_XPM}" = "yes"; then
1965     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
1966   fi
1967 fi
1968
1969 ### Use -ljpeg if available, unless `--with-jpeg=no'.
1970 HAVE_JPEG=no
1971 if test "${HAVE_X11}" = "yes"; then
1972   if test "${with_jpeg}" != "no"; then
1973     dnl Checking for jpeglib.h can lose because of a redefinition of
1974     dnl  HAVE_STDLIB_H.
1975     AC_CHECK_HEADER(jerror.h,
1976       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
1977   fi
1978
1979   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
1980   if test "${HAVE_JPEG}" = "yes"; then
1981     AC_DEFINE(HAVE_JPEG)
1982     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
1983         [#include <jpeglib.h>
1984          version=JPEG_LIB_VERSION
1985 ],
1986         [AC_DEFINE(HAVE_JPEG)],
1987         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
1988         HAVE_JPEG=no])
1989   fi
1990 fi
1991
1992 ### Use -lpng if available, unless `--with-png=no'.
1993 HAVE_PNG=no
1994 if test "${HAVE_X11}" = "yes"; then
1995   if test "${with_png}" != "no"; then
1996     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
1997     # in /usr/include/libpng.
1998     AC_CHECK_HEADERS(png.h libpng/png.h)
1999     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2000       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2001     fi
2002   fi
2003
2004   if test "${HAVE_PNG}" = "yes"; then
2005     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2006   fi
2007 fi
2008
2009 ### Use -ltiff if available, unless `--with-tiff=no'.
2010 HAVE_TIFF=no
2011 if test "${HAVE_X11}" = "yes"; then
2012   if test "${with_tiff}" != "no"; then
2013     AC_CHECK_HEADER(tiffio.h,
2014       [tifflibs="-lz -lm"
2015       # At least one tiff package requires the jpeg library.
2016       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2017       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2018   fi
2019
2020   if test "${HAVE_TIFF}" = "yes"; then
2021     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2022   fi
2023 fi
2024
2025 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2026 HAVE_GIF=no
2027 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2028   AC_CHECK_HEADER(gif_lib.h,
2029 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2030 # Earlier versions can crash Emacs.
2031     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2032
2033   if test "$HAVE_GIF" = yes; then
2034       ac_gif_lib_name="-lgif"
2035   fi
2036
2037 # If gif_lib.h but no libgif, try libungif.
2038   if test x"$try_libungif" = xyes; then
2039     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2040
2041     if test "$HAVE_GIF" = yes; then
2042       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2043       ac_gif_lib_name="-lungif"
2044     fi
2045   fi
2046
2047   if test "${HAVE_GIF}" = "yes"; then
2048     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2049   fi
2050 fi
2051
2052 dnl Check for required libraries.
2053 if test "${HAVE_X11}" = "yes"; then
2054   MISSING=""
2055   WITH_NO=""
2056   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2057     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2058   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2059     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2060   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2061     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2062   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2063     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2064   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2065     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2066
2067   if test "X${MISSING}" != X; then
2068     AC_MSG_ERROR([The following required libraries were not found:
2069     $MISSING
2070 Maybe some development libraries/packages are missing?
2071 If you don't want to link with them give
2072     $WITH_NO
2073 as options to configure])
2074   fi
2075 fi
2076
2077 ### Use -lgpm if available, unless `--with-gpm=no'.
2078 HAVE_GPM=no
2079 if test "${with_gpm}" != "no"; then
2080   AC_CHECK_HEADER(gpm.h,
2081     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2082 fi
2083
2084 if test "${HAVE_GPM}" = "yes"; then
2085   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2086 fi
2087
2088 dnl Check for malloc/malloc.h on darwin
2089 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2090
2091 ### Use NeXTstep API to implement GUI.
2092 if test "${HAVE_NS}" = "yes"; then
2093   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2094   if test "${NS_IMPL_COCOA}" = "yes"; then
2095     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2096     GNU_OBJC_CFLAGS=
2097     LIB_SRC_EXTRA_INSTALLABLES=mac-fix-env
2098   fi
2099   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2100     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2101     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2102   fi
2103   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2104     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2105   fi
2106   # We also have mouse menus.
2107   HAVE_MENUS=yes
2108 fi
2109
2110
2111 ### Use session management (-lSM -lICE) if available
2112 HAVE_X_SM=no
2113 if test "${HAVE_X11}" = "yes"; then
2114   AC_CHECK_HEADER(X11/SM/SMlib.h,
2115     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2116
2117   if test "${HAVE_X_SM}" = "yes"; then
2118     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2119     case "$LIBS" in
2120       *-lSM*) ;;
2121       *)      LIBS="-lSM -lICE $LIBS" ;;
2122     esac
2123   fi
2124 fi
2125
2126 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2127 AC_CACHE_CHECK(whether netdb declares h_errno,
2128                emacs_cv_netdb_declares_h_errno,
2129 [AC_TRY_LINK([#include <netdb.h>],
2130   [return h_errno;],
2131   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2132 if test $emacs_cv_netdb_declares_h_errno = yes; then
2133   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2134 fi
2135
2136 AC_FUNC_ALLOCA
2137
2138 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2139 dnl FIXME is there an autoconf test that does the right thing, without
2140 dnl needing to call A_M_E afterwards?
2141 if test x"$ac_cv_func_alloca_works" != xyes; then
2142    AC_MSG_ERROR( [a system implementation of alloca is required] )
2143 fi
2144
2145 # fmod, logb, and frexp are found in -lm on most systems.
2146 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2147 AC_CHECK_LIB(m, sqrt)
2148
2149 # Check for mail-locking functions in a "mail" library.  Probably this should
2150 # have the same check as for liblockfile below.
2151 AC_CHECK_LIB(mail, maillock)
2152 dnl Debian, at least:
2153 AC_CHECK_LIB(lockfile, maillock)
2154 # If we have the shared liblockfile, assume we must use it for mail
2155 # locking (e.g. Debian).  If we couldn't link against liblockfile
2156 # (no liblockfile.a installed), ensure that we don't need to.
2157 if test "$ac_cv_lib_lockfile_maillock" = no; then
2158   dnl This works for files generally, not just executables.
2159   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2160   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2161                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2162   if test $ac_cv_prog_liblockfile = yes; then
2163     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2164 This probably means that movemail could lose mail.
2165 There may be a `development' package to install containing liblockfile.])
2166   else :
2167   fi
2168 fi
2169 AC_CHECK_FUNCS(touchlock)
2170 AC_CHECK_HEADERS(maillock.h)
2171
2172 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2173 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2174 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2175 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2176 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2177 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2178 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2179 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2180 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2181 cfmakeraw cfsetspeed)
2182
2183 AC_CHECK_HEADERS(sys/un.h)
2184
2185 AC_FUNC_MKTIME
2186 if test "$ac_cv_func_working_mktime" = no; then
2187   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2188 fi
2189
2190 AC_FUNC_GETLOADAVG
2191
2192 AC_FUNC_FSEEKO
2193
2194 # Configure getopt.
2195 m4_include([m4/getopt.m4])
2196 gl_GETOPT_IFELSE([
2197   gl_GETOPT_SUBSTITUTE_HEADER
2198   gl_PREREQ_GETOPT
2199   GETOPTOBJS='getopt.o getopt1.o'
2200 ])
2201 AC_SUBST(GETOPTOBJS)
2202
2203 AC_FUNC_GETPGRP
2204
2205 AC_FUNC_STRFTIME
2206
2207 # UNIX98 PTYs.
2208 AC_CHECK_FUNCS(grantpt)
2209
2210 # PTY-related GNU extensions.
2211 AC_CHECK_FUNCS(getpt)
2212
2213 # Check this now, so that we will NOT find the above functions in ncurses.
2214 # That is because we have not set up to link ncurses in lib-src.
2215 # It's better to believe a function is not available
2216 # than to expect to find it in ncurses.
2217 AC_CHECK_LIB(ncurses, tparm)
2218
2219 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2220
2221 resolv=no
2222 AC_TRY_LINK([#include <netinet/in.h>
2223 #include <arpa/nameser.h>
2224 #include <resolv.h>],
2225     [return res_init();],
2226     have_res_init=yes, have_res_init=no)
2227 if test "$have_res_init" = no; then
2228   OLIBS="$LIBS"
2229   LIBS="$LIBS -lresolv"
2230   AC_MSG_CHECKING(for res_init with -lresolv)
2231   AC_TRY_LINK([#include <netinet/in.h>
2232 #include <arpa/nameser.h>
2233 #include <resolv.h>],
2234     [return res_init();],
2235     have_res_init=yes, have_res_init=no)
2236   AC_MSG_RESULT($have_res_init)
2237   if test "$have_res_init" = yes ; then
2238     resolv=yes
2239   fi
2240   LIBS="$OLIBS"
2241 fi
2242
2243 if test "$have_res_init" = yes; then
2244   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2245 fi
2246
2247 # Do we need the Hesiod library to provide the support routines?
2248 if test "$with_hesiod" != no ; then
2249   # Don't set $LIBS here -- see comments above.
2250   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2251      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2252                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2253   if test "$resolv" = yes ; then
2254     RESOLVLIB=-lresolv
2255   else
2256     RESOLVLIB=
2257   fi
2258   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2259         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2260                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2261         :, $RESOLVLIB)])
2262 fi
2263
2264 # Do we need libresolv (due to res_init or Hesiod)?
2265 if test "$resolv" = yes ; then
2266   AC_DEFINE(HAVE_LIBRESOLV, 1,
2267             [Define to 1 if you have the resolv library (-lresolv).])
2268 fi
2269
2270 # These tell us which Kerberos-related libraries to use.
2271 if test "${with_kerberos}" != no; then
2272   AC_CHECK_LIB(com_err, com_err)
2273   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2274   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2275   AC_CHECK_LIB(krb5, krb5_init_context)
2276   if test "${with_kerberos5}" = no; then
2277     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2278                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2279     AC_CHECK_LIB(krb4, krb_get_cred,,
2280                  [AC_CHECK_LIB(krb, krb_get_cred)])
2281   fi
2282
2283   if test "${with_kerberos5}" != no; then
2284     AC_CHECK_HEADERS(krb5.h,
2285       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2286                         [#include <krb5.h>])])
2287   else
2288     AC_CHECK_HEADERS(des.h,,
2289                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2290                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2291     AC_CHECK_HEADERS(krb.h,,
2292                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2293                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2294   fi
2295   AC_CHECK_HEADERS(com_err.h)
2296 fi
2297
2298 # Solaris requires -lintl if you want strerror (which calls dgettext)
2299 # to return localized messages.
2300 AC_CHECK_LIB(intl, dgettext)
2301
2302 AC_MSG_CHECKING(whether localtime caches TZ)
2303 AC_CACHE_VAL(emacs_cv_localtime_cache,
2304 [if test x$ac_cv_func_tzset = xyes; then
2305 AC_TRY_RUN([#include <time.h>
2306 extern char **environ;
2307 unset_TZ ()
2308 {
2309   char **from, **to;
2310   for (to = from = environ; (*to = *from); from++)
2311     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2312       to++;
2313 }
2314 char TZ_GMT0[] = "TZ=GMT0";
2315 char TZ_PST8[] = "TZ=PST8";
2316 main()
2317 {
2318   time_t now = time ((time_t *) 0);
2319   int hour_GMT0, hour_unset;
2320   if (putenv (TZ_GMT0) != 0)
2321     exit (1);
2322   hour_GMT0 = localtime (&now)->tm_hour;
2323   unset_TZ ();
2324   hour_unset = localtime (&now)->tm_hour;
2325   if (putenv (TZ_PST8) != 0)
2326     exit (1);
2327   if (localtime (&now)->tm_hour == hour_GMT0)
2328     exit (1);
2329   unset_TZ ();
2330   if (localtime (&now)->tm_hour != hour_unset)
2331     exit (1);
2332   exit (0);
2333 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2334 [# If we have tzset, assume the worst when cross-compiling.
2335 emacs_cv_localtime_cache=yes])
2336 else
2337         # If we lack tzset, report that localtime does not cache TZ,
2338         # since we can't invalidate the cache if we don't have tzset.
2339         emacs_cv_localtime_cache=no
2340 fi])dnl
2341 AC_MSG_RESULT($emacs_cv_localtime_cache)
2342 if test $emacs_cv_localtime_cache = yes; then
2343   AC_DEFINE(LOCALTIME_CACHE, 1,
2344             [Define to 1 if localtime caches TZ.])
2345 fi
2346
2347 if test "x$HAVE_TIMEVAL" = xyes; then
2348   AC_CHECK_FUNCS(gettimeofday)
2349   if test $ac_cv_func_gettimeofday = yes; then
2350     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2351                    emacs_cv_gettimeofday_two_arguments,
2352     [AC_TRY_COMPILE([
2353 #ifdef TIME_WITH_SYS_TIME
2354 #include <sys/time.h>
2355 #include <time.h>
2356 #else
2357 #ifdef HAVE_SYS_TIME_H
2358 #include <sys/time.h>
2359 #else
2360 #include <time.h>
2361 #endif
2362 #endif],
2363       [struct timeval time;
2364        gettimeofday (&time, 0);],
2365       emacs_cv_gettimeofday_two_arguments=yes,
2366       emacs_cv_gettimeofday_two_arguments=no)])
2367     if test $emacs_cv_gettimeofday_two_arguments = no; then
2368       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2369                 [Define to 1 if gettimeofday accepts only one argument.])
2370     fi
2371   fi
2372 fi
2373
2374 ok_so_far=yes
2375 AC_CHECK_FUNC(socket, , ok_so_far=no)
2376 if test $ok_so_far = yes; then
2377   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2378 fi
2379 if test $ok_so_far = yes; then
2380   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2381 fi
2382 if test $ok_so_far = yes; then
2383 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2384   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2385             [Define to 1 if you have inet sockets.])
2386 fi
2387
2388 AC_CHECK_HEADERS(sys/ioctl.h)
2389
2390 if test -f /usr/lpp/X11/bin/smt.exp; then
2391   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2392             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2393 fi
2394
2395 AC_MSG_CHECKING(whether system supports dynamic ptys)
2396 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2397   AC_MSG_RESULT(yes)
2398   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2399 else
2400   AC_MSG_RESULT(no)
2401 fi
2402
2403 AC_FUNC_FORK
2404
2405 dnl Adapted from Haible's version.
2406 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2407   [AC_TRY_LINK([#include <langinfo.h>],
2408     [char* cs = nl_langinfo(CODESET);],
2409     emacs_cv_langinfo_codeset=yes,
2410     emacs_cv_langinfo_codeset=no)
2411   ])
2412 if test $emacs_cv_langinfo_codeset = yes; then
2413   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2414     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2415 fi
2416
2417 AC_CHECK_TYPES(size_t)
2418
2419 AC_TYPE_MBSTATE_T
2420
2421 dnl Restrict could probably be used effectively other than in regex.c.
2422 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2423   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2424                   emacs_cv_c_restrict=yes,
2425                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2426                                   emacs_cv_c_restrict=__restrict,
2427                                   emacs_cv_c_restrict=no)])])
2428 case "$emacs_cv_c_restrict" in
2429   yes) emacs_restrict=restrict;;
2430   no) emacs_restrict="";;
2431   *) emacs_restrict="$emacs_cv_c_restrict";;
2432 esac
2433 if test "$emacs_restrict" != __restrict; then
2434   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2435     [Define to compiler's equivalent of C99 restrict keyword.
2436      Don't define if equivalent is `__restrict'.])
2437 fi
2438
2439 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2440   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2441                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2442 if test "$emacs_cv_c_restrict_arr" = yes; then
2443   AC_DEFINE(__restrict_arr, __restrict,
2444     [Define to compiler's equivalent of C99 restrict keyword in array
2445      declarations.  Define as empty for no equivalent.])
2446 fi
2447
2448 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2449 dnl how the tty code is related to POSIX and/or other versions of termios.
2450 dnl The following looks like a useful start.
2451 dnl
2452 dnl AC_SYS_POSIX_TERMIOS
2453 dnl if test $ac_cv_sys_posix_termios = yes; then
2454 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2455 dnl                                and macros for terminal control.])
2456 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2457 dnl fi
2458
2459 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2460
2461 # Set up the CFLAGS for real compilation, so we can substitute it.
2462 CFLAGS="$REAL_CFLAGS"
2463 CPPFLAGS="$REAL_CPPFLAGS"
2464
2465 #### Find out which version of Emacs this is.
2466 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2467          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2468 if test x"${version}" = x; then
2469   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2470 fi
2471
2472 ### Specify what sort of things we'll be editing into Makefile and config.h.
2473 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2474 AC_SUBST(version)
2475 AC_SUBST(configuration)
2476 AC_SUBST(canonical)
2477 AC_SUBST(srcdir)
2478 AC_SUBST(prefix)
2479 AC_SUBST(exec_prefix)
2480 AC_SUBST(bindir)
2481 AC_SUBST(datadir)
2482 AC_SUBST(sharedstatedir)
2483 AC_SUBST(libexecdir)
2484 AC_SUBST(mandir)
2485 AC_SUBST(infodir)
2486 AC_SUBST(lispdir)
2487 AC_SUBST(locallisppath)
2488 AC_SUBST(lisppath)
2489 AC_SUBST(x_default_search_path)
2490 AC_SUBST(etcdir)
2491 AC_SUBST(archlibdir)
2492 AC_SUBST(docdir)
2493 AC_SUBST(bitmapdir)
2494 AC_SUBST(gamedir)
2495 AC_SUBST(gameuser)
2496 AC_SUBST(c_switch_system)
2497 AC_SUBST(c_switch_machine)
2498 AC_SUBST(LD_SWITCH_X_SITE)
2499 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2500 AC_SUBST(C_SWITCH_X_SITE)
2501 AC_SUBST(CFLAGS)
2502 AC_SUBST(X_TOOLKIT_TYPE)
2503 AC_SUBST(machfile)
2504 AC_SUBST(opsysfile)
2505 AC_SUBST(GETLOADAVG_LIBS)
2506 AC_SUBST(ns_appdir)
2507 AC_SUBST(ns_appbindir)
2508 AC_SUBST(ns_appresdir)
2509 AC_SUBST(ns_appsrc)
2510 AC_SUBST(GNUSTEP_MAKEFILES)
2511 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2512 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2513 AC_SUBST(GNU_OBJC_CFLAGS)
2514 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2515
2516 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2517                    [Define to the canonical Emacs configuration name.])
2518 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2519                    [Define to the options passed to configure.])
2520 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2521                    [Define to the used machine dependent file.])
2522 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2523                    [Define to the used os dependent file.])
2524 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2525 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2526  may need to deal with X Windows.  For instance, if you've defined
2527  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2528  your loader can find on its own, you might want to add "-L/..." or
2529  something similar.])
2530 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2531                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2532                     in case it's needed (for Solaris, for example).])
2533 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2534 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2535  may need to deal with X Windows.  For instance, if you've defined
2536  HAVE_X_WINDOWS above and your X include files aren't in a place
2537  that your compiler can find on its own, you might want to add
2538  "-I/..." or something similar.])
2539 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2540                    [Define to the unexec source file name.])
2541
2542 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2543   AC_DEFINE(HAVE_X_WINDOWS, 1,
2544             [Define to 1 if you want to use the X window system.])
2545 fi
2546 if test "${USE_X_TOOLKIT}" != "none" ; then
2547   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2548   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2549     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2550   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2551     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2552   fi
2553 fi
2554 if test "${HAVE_X11}" = "yes" ; then
2555   AC_DEFINE(HAVE_X11, 1,
2556             [Define to 1 if you want to use version 11 of X windows.
2557              Otherwise, Emacs expects to use version 10.])
2558 fi
2559 if test "${HAVE_MENUS}" = "yes" ; then
2560   AC_DEFINE(HAVE_MENUS, 1,
2561             [Define to 1 if you have mouse menus.
2562              (This is automatic if you use X, but the option to specify it remains.)
2563              It is also defined with other window systems that support xmenu.c.])
2564 fi
2565 if test "${GNU_MALLOC}" = "yes" ; then
2566   AC_DEFINE(GNU_MALLOC, 1,
2567             [Define to 1 if you want to use the GNU memory allocator.])
2568 fi
2569 if test "${REL_ALLOC}" = "yes" ; then
2570   AC_DEFINE(REL_ALLOC, 1,
2571             [Define REL_ALLOC if you want to use the relocating allocator for
2572              buffer space.])
2573 fi
2574
2575
2576 AH_TOP([/* GNU Emacs site configuration template file.
2577    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2578      2006, 2007, 2008, 2009  Free Software Foundation, Inc.
2579
2580 This file is part of GNU Emacs.
2581
2582 GNU Emacs is free software: you can redistribute it and/or modify
2583 it under the terms of the GNU General Public License as published by
2584 the Free Software Foundation, either version 3 of the License, or
2585 (at your option) any later version.
2586
2587 GNU Emacs is distributed in the hope that it will be useful,
2588 but WITHOUT ANY WARRANTY; without even the implied warranty of
2589 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2590 GNU General Public License for more details.
2591
2592 You should have received a copy of the GNU General Public License
2593 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2594
2595
2596 /* No code in Emacs #includes config.h twice, but some bits of code
2597    intended to work with other packages as well (like gmalloc.c)
2598    think they can include it as many times as they like.  */
2599 #ifndef EMACS_CONFIG_H
2600 #define EMACS_CONFIG_H
2601 ])dnl
2602
2603 AH_BOTTOM([
2604 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2605 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2606 #define HAVE_WINDOW_SYSTEM
2607 #define HAVE_MOUSE
2608 #endif
2609
2610 /* Define AMPERSAND_FULL_NAME if you use the convention
2611    that & in the full name stands for the login id.  */
2612 /* Turned on June 1996 supposing nobody will mind it.  */
2613 #define AMPERSAND_FULL_NAME
2614
2615 /* Define HAVE_SOUND if we have sound support.  We know it works
2616    and compiles only on the specified platforms.   For others,
2617    it probably doesn't make sense to try.  */
2618
2619 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2620 #ifdef HAVE_MACHINE_SOUNDCARD_H
2621 #define HAVE_SOUND 1
2622 #endif
2623 #ifdef HAVE_SYS_SOUNDCARD_H
2624 #define HAVE_SOUND 1
2625 #endif
2626 #ifdef HAVE_SOUNDCARD_H
2627 #define HAVE_SOUND 1
2628 #endif
2629 #ifdef HAVE_ALSA
2630 #define HAVE_SOUND 1
2631 #endif
2632 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2633
2634 /* If using GNU, then support inline function declarations. */
2635 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2636    generally, because even if non-gcc compilers accept `inline', they
2637    may reject `extern inline'.  */
2638 #if defined (__GNUC__) && defined (OPTIMIZE)
2639 #define INLINE __inline__
2640 #else
2641 #define INLINE
2642 #endif
2643
2644 /* `subprocesses' should be defined if you want to
2645    have code for asynchronous subprocesses
2646    (as used in M-x compile and M-x shell).
2647    Only MSDOS does not support this (it overrides
2648    this in its config_opsysfile below).  */
2649
2650 #define subprocesses
2651
2652 /* Include the os and machine dependent files.  */
2653 #include config_opsysfile
2654 #include config_machfile
2655
2656 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2657   (There is probably a better place to do this, but right now the Cocoa
2658    side does this in s/darwin.h and we cannot
2659    parallel this exactly since GNUstep is multi-OS. */
2660 #ifdef HAVE_NS
2661 #define OTHER_FILES ns-app
2662 # ifdef NS_IMPL_GNUSTEP
2663 /* See also .m.o rule in Makefile.in */
2664 /* FIXME: are all these flags really needed?  Document here why.  */
2665 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2666 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2667 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2668 #  define SYSTEM_PURESIZE_EXTRA 30000
2669 # endif /* NS_IMPL_GNUSTEP */
2670 #endif /* HAVE_NS */
2671
2672 /* SIGTYPE is the macro we actually use.  */
2673 #ifndef SIGTYPE
2674 #define SIGTYPE RETSIGTYPE
2675 #endif
2676
2677 #ifdef emacs /* Don't do this for lib-src.  */
2678 /* Tell regex.c to use a type compatible with Emacs.  */
2679 #define RE_TRANSLATE_TYPE Lisp_Object
2680 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2681 #ifdef make_number
2682 /* If make_number is a macro, use it.  */
2683 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2684 #else
2685 /* If make_number is a function, avoid it.  */
2686 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2687 #endif
2688 #endif
2689
2690 /* Avoid link-time collision with system mktime if we will use our own.  */
2691 #if ! HAVE_MKTIME || BROKEN_MKTIME
2692 #define mktime emacs_mktime
2693 #endif
2694
2695 #define my_strftime nstrftime   /* for strftime.c */
2696
2697 /* The rest of the code currently tests the CPP symbol BSTRING.
2698    Override any claims made by the system-description files.
2699    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2700 #undef BSTRING
2701 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2702 #define BSTRING
2703 #endif
2704
2705 /* Some of the files of Emacs which are intended for use with other
2706    programs assume that if you have a config.h file, you must declare
2707    the type of getenv.
2708
2709    This declaration shouldn't appear when alloca.s or Makefile.in
2710    includes config.h.  */
2711 #ifndef NOT_C_CODE
2712 extern char *getenv ();
2713 #endif
2714
2715 /* These default definitions are good for almost all machines.
2716    The exceptions override them in m/MACHINE.h.  */
2717
2718 #ifndef BITS_PER_CHAR
2719 #define BITS_PER_CHAR 8
2720 #endif
2721
2722 #ifndef BITS_PER_SHORT
2723 #define BITS_PER_SHORT 16
2724 #endif
2725
2726 /* Note that lisp.h uses this in a preprocessor conditional, so it
2727    would not work to use sizeof.  That being so, we do all of them
2728    without sizeof, for uniformity's sake.  */
2729 #ifndef BITS_PER_INT
2730 #define BITS_PER_INT 32
2731 #endif
2732
2733 #ifndef BITS_PER_LONG
2734 #ifdef _LP64
2735 #define BITS_PER_LONG 64
2736 #else
2737 #define BITS_PER_LONG 32
2738 #endif
2739 #endif
2740
2741 /* Define if the compiler supports function prototypes.  It may do so
2742    but not define __STDC__ (e.g. DEC C by default) or may define it as
2743    zero.  */
2744 #undef PROTOTYPES
2745 /* For mktime.c:  */
2746 #ifndef __P
2747 # if defined PROTOTYPES
2748 #  define __P(args) args
2749 # else
2750 #  define __P(args) ()
2751 # endif  /* GCC.  */
2752 #endif /* __P */
2753
2754 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2755 #ifndef NOT_C_CODE
2756 #ifdef HAVE_STRING_H
2757 #include "string.h"
2758 #endif
2759 #ifdef HAVE_STRINGS_H
2760 #include "strings.h"  /* May be needed for bcopy & al. */
2761 #endif
2762 #ifdef HAVE_STDLIB_H
2763 #include <stdlib.h>
2764 #endif
2765 #ifndef __GNUC__
2766 # ifdef HAVE_ALLOCA_H
2767 #  include <alloca.h>
2768 # else /* AIX files deal with #pragma.  */
2769 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2770 char *alloca ();
2771 #  endif
2772 # endif /* HAVE_ALLOCA_H */
2773 #endif /* __GNUC__ */
2774 #ifndef HAVE_SIZE_T
2775 typedef unsigned size_t;
2776 #endif
2777 #endif /* NOT_C_CODE */
2778
2779 /* Define HAVE_X_I18N if we have usable i18n support.  */
2780
2781 #ifdef HAVE_X11R6
2782 #define HAVE_X_I18N
2783 #elif !defined X11R5_INHIBIT_I18N
2784 #define HAVE_X_I18N
2785 #endif
2786
2787 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2788
2789 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2790 #define HAVE_X11R6_XIM
2791 #endif
2792
2793 /* Should we enable expensive run-time checking of data types?  */
2794 #undef ENABLE_CHECKING
2795
2796 #if defined __GNUC__ && (__GNUC__ > 2 \
2797                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2798 #define NO_RETURN       __attribute__ ((__noreturn__))
2799 #else
2800 #define NO_RETURN       /* nothing */
2801 #endif
2802
2803 /* These won't be used automatically yet.  We also need to know, at least,
2804    that the stack is continuous.  */
2805 #ifdef __GNUC__
2806 #  ifndef GC_SETJMP_WORKS
2807   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2808      see NON_SAVING_SETJMP in the target descriptions.  */
2809   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2810      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2811      Fixme: Deal with SVR3.  */
2812 #    define GC_SETJMP_WORKS 1
2813 #  endif
2814 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2815 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2816 #  endif
2817 #endif
2818
2819 #ifndef HAVE_BCOPY
2820 #define bcopy(a,b,s) memcpy (b,a,s)
2821 #endif
2822 #ifndef HAVE_BZERO
2823 #define bzero(a,s) memset (a,0,s)
2824 #endif
2825 #ifndef HAVE_BCMP
2826 #define BCMP memcmp
2827 #endif
2828
2829 #endif /* EMACS_CONFIG_H */
2830
2831 /*
2832 Local Variables:
2833 mode: c
2834 End:
2835 */
2836 ])dnl
2837
2838 #### Report on what we decided to do.
2839 #### Report GTK as a toolkit, even if it doesn't use Xt.
2840 #### It makes printing result more understandable as using GTK sets
2841 #### toolkit_scroll_bars to yes by default.
2842 if test "${HAVE_GTK}" = "yes"; then
2843   USE_X_TOOLKIT=GTK
2844 fi
2845
2846 echo "
2847 Configured for \`${canonical}'.
2848
2849   Where should the build process find the source code?    ${srcdir}
2850   What operating system and machine description files should Emacs use?
2851         \`${opsysfile}' and \`${machfile}'
2852   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2853   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2854   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2855   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2856   What window system should Emacs use?                    ${window_system}
2857   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2858
2859 if test -n "${x_includes}"; then
2860 echo "  Where do we find X Windows header files?                ${x_includes}"
2861 else
2862 echo "  Where do we find X Windows header files?                Standard dirs"
2863 fi
2864 if test -n "${x_libraries}"; then
2865 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2866 else
2867 echo "  Where do we find X Windows libraries?                   Standard dirs"
2868 fi
2869
2870 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2871 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2872 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2873 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2874 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
2875 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2876 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
2877 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
2878 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
2879
2880 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
2881 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
2882 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
2883 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
2884
2885 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
2886 echo
2887
2888 if test $USE_XASSERTS = yes; then
2889    echo "  Compiling with asserts turned on."
2890    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
2891 fi
2892
2893 echo
2894
2895 if test "$USE_X_TOOLKIT" = GTK; then
2896   case "$canonical" in
2897   *cygwin*)
2898     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
2899   will probably get a crash on startup.  If this happens, please use another
2900   toolkit for Emacs.  See etc/PROBLEMS for more information."
2901   ;;
2902   esac
2903 fi
2904
2905 if test "$HAVE_NS" = "yes"; then
2906    echo
2907    echo "You must run \"make install\" in order to test the built application.
2908 The installed application will go to nextstep/Emacs.app and can be
2909 run or moved from there."
2910    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
2911       echo "The application will be fully self-contained."
2912     else
2913       echo "The lisp resources for the application will be installed under ${prefix}.
2914 You may need to run \"make install\" with sudo.  The application will fail
2915 to run if these resources are not installed."
2916    fi
2917    echo
2918 fi
2919
2920 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
2921   echo "D-Bus integration has been tested for GNU/Linux only."
2922   echo
2923 fi
2924
2925
2926 # Remove any trailing slashes in these variables.
2927 [test "${prefix}" != NONE &&
2928   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2929 test "${exec_prefix}" != NONE &&
2930   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
2931
2932 # Now get this: Some word that is part of the ${srcdir} directory name
2933 # or the ${configuration} value might, just might, happen to be an
2934 # identifier like `sun4' or `i386' or something, and be predefined by
2935 # the C preprocessor to some helpful value like 1, or maybe the empty
2936 # string.  Needless to say consequent macro substitutions are less
2937 # than conducive to the makefile finding the correct directory.
2938 [cpp_undefs="`echo $srcdir $configuration $canonical |
2939   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
2940   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
2941
2942 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
2943 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
2944 ## from Makefile.c can correctly provide the arg `-traditional' to the
2945 ## C preprocessor.
2946
2947 AC_EGREP_CPP(yes..yes,
2948         [yes..yes],
2949         CPP_NEED_TRADITIONAL=no,
2950         CPP_NEED_TRADITIONAL=yes)
2951
2952 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2953         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
2954         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
2955         lwlib/Makefile lisp/Makefile leim/Makefile, [
2956
2957 ### Make the necessary directories, if they don't exist.
2958 for dir in etc lisp ; do
2959   test -d ${dir} || mkdir ${dir}
2960 done
2961
2962 # Build src/Makefile from ${srcdir}/src/Makefile.c
2963 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2964 # This must be done after src/config.h is built, since we rely on that file.
2965
2966 echo creating src/epaths.h
2967 ${MAKE-make} epaths-force
2968
2969 # As of 2000-11-19, newest development versions of GNU cpp preprocess
2970 # `..' to `. .'  unless invoked with -traditional
2971
2972 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
2973   CPPFLAGS="$CPPFLAGS -traditional"
2974 fi
2975
2976 echo creating lib-src/Makefile
2977 ( cd lib-src
2978   rm -f junk.c junk1.c junk2.c
2979   sed -e '/start of cpp stuff/q' \
2980       < Makefile.c > junk1.c
2981   sed -e '1,/start of cpp stuff/d'\
2982       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2983       < Makefile.c > junk.c
2984   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2985       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2986   cat junk1.c junk2.c > Makefile.new
2987   rm -f junk.c junk1.c junk2.c
2988   chmod 444 Makefile.new
2989   mv -f Makefile.new Makefile
2990 )
2991
2992 echo creating src/Makefile
2993 ( cd src
2994   rm -f junk.c junk1.c junk2.c
2995   sed -e '/start of cpp stuff/q' \
2996       < Makefile.c > junk1.c
2997   sed -e '1,/start of cpp stuff/d'\
2998       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2999       < Makefile.c > junk.c
3000   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3001       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3002   cat junk1.c junk2.c > Makefile.new
3003   rm -f junk.c junk1.c junk2.c
3004   chmod 444 Makefile.new
3005   mv -f Makefile.new Makefile
3006 )
3007
3008 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3009   echo creating src/.gdbinit
3010   echo source $srcdir/src/.gdbinit > src/.gdbinit
3011 fi
3012
3013 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3014
3015 m4_if(dnl       Do not change this comment
3016    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3017 )dnl