code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the 'configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2015 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 25.0.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140
 141 case $host in
 142  *-mingw*)
 143
 144   if test -z "$host_alias"; then
 145
 146       # No --host argument was given to 'configure'; therefore $host
 147       # was set to a default value based on the build platform.  But
 148       # this default value may be wrong if we are building from a
 149       # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
 150       # Therefore, we'll try to get the right host platform from the
 151       # compiler's target.
 152
 153       AC_MSG_CHECKING([the compiler's target])
 154       if test -z "$CC"; then
 155           cc=gcc
 156       else
 157           cc=$CC
 158       fi
 159       cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
 160       case "$cc_target" in
 161           *-*) host=$cc_target
 162               ;;
 163           "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
 164 Please explicitly provide --host.])
 165               ;;
 166           *) AC_MSG_WARN([Compiler reported non-standard target.
 167 Defaulting to $host.])
 168               ;;
 169       esac
 170       AC_MSG_RESULT([$host])
 171   fi
 172
 173   . $srcdir/nt/mingw-cfg.site
 174
 175   case $srcdir in
 176     /* | ?:*)
 177       # srcdir is an absolute path.  In this case, force the format
 178       # "/c/foo/bar", to simplify later conversions to native Windows
 179       # format ("c:/foo/bar").
 180       srcdir=`cd "${srcdir}" && pwd -W`
 181       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
 182       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
 183       ;;
 184   esac;;
 185 esac
 186
 187 canonical=$host
 188 configuration=${host_alias-${build_alias-$host}}
 189
 190 dnl Support for --program-prefix, --program-suffix and
 191 dnl --program-transform-name options
 192 AC_ARG_PROGRAM
 193
 194 dnl It is important that variables on the RHS not be expanded here,
 195 dnl hence the single quotes.  This is per the GNU coding standards, see
 196 dnl (autoconf) Installation Directory Variables
 197 dnl See also epaths.h below.
 198 lispdir='${datadir}/emacs/${version}/lisp'
 199 standardlisppath='${lispdir}'
 200 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 201 '${datadir}/emacs/site-lisp'
 202 lisppath='${locallisppath}:${standardlisppath}'
 203 etcdir='${datadir}/emacs/${version}/etc'
 204 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 205 etcdocdir='${datadir}/emacs/${version}/etc'
 206 gamedir='${localstatedir}/games/emacs'
 207
 208 dnl Special option to disable the most of other options.
 209 AC_ARG_WITH(all,
 210 [AS_HELP_STRING([--without-all],
 211                 [omit almost all features and build
 212                 small executable with minimal dependencies])],
 213   [with_features=$withval],
 214   [with_features=yes])
 215
 216 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 217 dnl Create a new --with option that defaults to being disabled.
 218 dnl NAME is the base name of the option.  The shell variable with_NAME
 219 dnl   will be set to either the user's value (if the option is
 220 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 221 dnl   option is not specified).  Note that the shell variable name is
 222 dnl   constructed as autoconf does, by replacing non-alphanumeric
 223 dnl   characters with "_".
 224 dnl HELP-STRING is the help text for the option.
 225 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 226   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 227     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 228 ])dnl
 229
 230 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 231 dnl Create a new --with option that defaults to $with_features.
 232 dnl NAME is the base name of the option.  The shell variable with_NAME
 233 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 234 dnl   'yes' (if the option is not specified).  Note that the shell
 235 dnl   variable name is constructed as autoconf does, by replacing
 236 dnl   non-alphanumeric characters with "_".
 237 dnl HELP-STRING is the help text for the option.
 238 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 239   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 240    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 241 ])dnl
 242
 243 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 244 if test "$with_pop" = yes; then
 245    AC_DEFINE(MAIL_USE_POP)
 246 fi
 247 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 248
 249 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 250 if test "$with_kerberos" != no; then
 251    AC_DEFINE(KERBEROS)
 252 fi
 253 AH_TEMPLATE(KERBEROS,
 254             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 255
 256 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 257 if test "${with_kerberos5}" != no; then
 258   if test "${with_kerberos}" = no; then
 259     with_kerberos=yes
 260     AC_DEFINE(KERBEROS)
 261   fi
 262   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 263 fi
 264
 265 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 266 dnl FIXME hesiod support may not be present, so it seems like an error
 267 dnl to define, or at least use, this unconditionally.
 268 if test "$with_hesiod" != no; then
 269   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 270 fi
 271
 272 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 273 if test "$with_mail_unlink" != no; then
 274    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 275 fi
 276
 277 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 278     [string giving default POP mail host])],
 279     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 280
 281 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 282   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 283 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
 284   [ case "${withval}" in
 285       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 286       *) AC_MSG_ERROR(['--with-sound=$withval' is invalid;
 287 this option's value should be 'yes', 'no', 'alsa', 'oss', or 'bsd-ossaudio'.])
 288       ;;
 289     esac
 290     with_sound=$val
 291   ],
 292   [with_sound=$with_features])
 293
 294 dnl FIXME currently it is not the last.
 295 dnl This should be the last --with option, because --with-x is
 296 dnl added later on when we find the file name of X, and it's best to
 297 dnl keep them together visually.
 298 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 299  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 300 [         case "${withval}" in
 301             y | ye | yes )      val=gtk ;;
 302             n | no )            val=no  ;;
 303             l | lu | luc | luci | lucid )       val=lucid ;;
 304             a | at | ath | athe | athen | athena )      val=athena ;;
 305             m | mo | mot | moti | motif )       val=motif ;;
 306             g | gt | gtk  )     val=gtk ;;
 307             gtk2  )     val=gtk2 ;;
 308             gtk3  )     val=gtk3 ;;
 309             * )
 310 AC_MSG_ERROR(['--with-x-toolkit=$withval' is invalid;
 311 this option's value should be 'yes', 'no', 'lucid', 'athena', 'motif', 'gtk',
 312 'gtk2' or 'gtk3'.  'yes' and 'gtk' are synonyms.
 313 'athena' and 'lucid' are synonyms.])
 314             ;;
 315           esac
 316           with_x_toolkit=$val
 317 ])
 318
 319 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit); allows buffer and string size up to 2GB on 32-bit hosts, at the cost of 10% to 30% slowdown of Lisp interpreter and larger memory footprint])
 320 if test "$with_wide_int" = yes; then
 321   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 322 fi
 323
 324 dnl _ON results in a '--without' option in the --help output, so
 325 dnl the help text should refer to "don't compile", etc.
 326 with_xpm_set=${with_xpm+set}
 327 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 328 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 329 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 330 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 331 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 332 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 333 OPTION_DEFAULT_OFF([cairo],[compile with Cairo drawing])
 334 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 335 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 336
 337 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 338 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 339 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 340
 341 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 342 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 343 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 344 AC_ARG_WITH([ns],[AS_HELP_STRING([--with-ns],
 345 [use Nextstep (OS X Cocoa or GNUstep) windowing system.
 346 On by default on Mac OS X.])],[],[with_ns=maybe])
 347 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 348
 349 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 350 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 351 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 352 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 353 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 354 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 355 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 356 OPTION_DEFAULT_OFF([modules],[compile with dynamic modules support])
 357
 358 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 359  [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
 360  [ case "${withval}" in
 361     y | ye | yes )      val=yes ;;
 362     n | no )            val=no  ;;
 363     g | gf | gfi | gfil | gfile )       val=gfile ;;
 364     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 365     w | w3 | w32 )      val=w32 ;;
 366     * ) AC_MSG_ERROR(['--with-file-notification=$withval' is invalid;
 367 this option's value should be 'yes', 'no', 'gfile', 'inotify' or 'w32'.
 368 'yes' is a synonym for 'w32' on MS-Windows, for 'no' on Nextstep,
 369 otherwise for the first of 'inotify' or 'gfile' that is usable.])
 370     ;;
 371    esac
 372    with_file_notification=$val
 373  ],
 374  [with_file_notification=$with_features])
 375
 376 ## For the times when you want to build Emacs but don't have
 377 ## a suitable makeinfo, and can live without the manuals.
 378 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 379 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 380
 381 ## This might be a 'configure' arg.
 382 AC_SUBST([ACLOCAL_PATH])
 383
 384 ## Makefile.in needs the cache file name.
 385 AC_SUBST(cache_file)
 386
 387 ## This is an option because I do not know if all info/man support
 388 ## compressed files, nor how to test if they do so.
 389 OPTION_DEFAULT_ON([compress-install],
 390   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 391 make GZIP_PROG= install])
 392
 393 AC_ARG_WITH(gameuser,dnl
 394 [AS_HELP_STRING([--with-gameuser=USER_OR_GROUP],
 395                 [user for shared game score files.
 396                 An argument prefixed by ':' specifies a group instead.])])
 397 gameuser=
 398 gamegroup=
 399 # We don't test if we can actually chown/chgrp here, because configure
 400 # may run without root privileges.  lib-src/Makefile.in will handle
 401 # any errors due to missing user/group gracefully.
 402 case ${with_gameuser} in
 403   no) ;;
 404   "" | yes) gamegroup=games ;;
 405   :*) gamegroup=${with_gameuser#:} ;;
 406   *) gameuser=${with_gameuser} ;;
 407 esac
 408
 409 AC_ARG_WITH([gnustep-conf],dnl
 410 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 411    [name of GNUstep configuration file to use on systems where the command
 412     'gnustep-config' does not work; default $GNUSTEP_CONFIG_FILE, or
 413     /etc/GNUstep/GNUstep.conf])])
 414 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 415   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 416 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 417      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 418
 419 AC_ARG_ENABLE(ns-self-contained,
 420 [AS_HELP_STRING([--disable-ns-self-contained],
 421                 [disable self contained build under NeXTstep])],
 422    EN_NS_SELF_CONTAINED=$enableval,
 423    EN_NS_SELF_CONTAINED=yes)
 424
 425 locallisppathset=no
 426 AC_ARG_ENABLE(locallisppath,
 427 [AS_HELP_STRING([--enable-locallisppath=PATH],
 428                 [directories Emacs should search for lisp files specific
 429                  to this site])],
 430 if test "${enableval}" = "no"; then
 431   locallisppath=
 432 elif test "${enableval}" != "yes"; then
 433   locallisppath=${enableval} locallisppathset=yes
 434 fi)
 435
 436 AC_ARG_ENABLE(checking,
 437 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 438                 [enable expensive run-time checks.  With LIST,
 439                  enable only specific categories of checks.
 440                  Categories are: all,yes,no.
 441                  Flags are: stringbytes, stringoverrun, stringfreelist,
 442                  xmallocoverrun, conslist, glyphs])],
 443 [ac_checking_flags="${enableval}"],[])
 444 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 445 for check in $ac_checking_flags
 446 do
 447         case $check in
 448         # these set all the flags to specific states
 449         yes)            ac_enable_checking=1 ;;
 450         no)             ac_enable_checking= ;
 451                         ac_gc_check_stringbytes= ;
 452                         ac_gc_check_string_overrun= ;
 453                         ac_gc_check_string_free_list= ;
 454                         ac_xmalloc_overrun= ;
 455                         ac_gc_check_cons_list= ;
 456                         ac_glyphs_debug= ;;
 457         all)            ac_enable_checking=1 ;
 458                         ac_gc_check_stringbytes=1 ;
 459                         ac_gc_check_string_overrun=1 ;
 460                         ac_gc_check_string_free_list=1 ;
 461                         ac_xmalloc_overrun=1 ;
 462                         ac_gc_check_cons_list=1 ;
 463                         ac_glyphs_debug=1 ;;
 464         # these enable particular checks
 465         stringbytes)    ac_gc_check_stringbytes=1 ;;
 466         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 467         stringfreelist) ac_gc_check_string_free_list=1 ;;
 468         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 469         conslist)       ac_gc_check_cons_list=1 ;;
 470         glyphs)         ac_glyphs_debug=1 ;;
 471         *)      AC_MSG_ERROR(unknown check category $check) ;;
 472         esac
 473 done
 474 IFS="$ac_save_IFS"
 475
 476 if test x$ac_enable_checking != x ; then
 477   AC_DEFINE(ENABLE_CHECKING, 1,
 478 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 479 fi
 480 if test x$ac_gc_check_stringbytes != x ; then
 481   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 482 [Define this temporarily to hunt a bug.  If defined, the size of
 483    strings is redundantly recorded in sdata structures so that it can
 484    be compared to the sizes recorded in Lisp strings.])
 485 fi
 486 if test x$ac_gc_check_string_overrun != x ; then
 487   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 488 [Define this to check for short string overrun.])
 489 fi
 490 if test x$ac_gc_check_string_free_list != x ; then
 491   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 492 [Define this to check the string free list.])
 493 fi
 494 if test x$ac_xmalloc_overrun != x ; then
 495   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 496 [Define this to check for malloc buffer overrun.])
 497 fi
 498 if test x$ac_gc_check_cons_list != x ; then
 499   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 500 [Define this to check for errors in cons list.])
 501 fi
 502 if test x$ac_glyphs_debug != x ; then
 503   AC_DEFINE(GLYPH_DEBUG, 1,
 504 [Define this to enable glyphs debugging code.])
 505 fi
 506
 507 AC_ARG_ENABLE(check-lisp-object-type,
 508 [AS_HELP_STRING([--enable-check-lisp-object-type],
 509                 [enable compile time checks for the Lisp_Object data type.
 510                 This is useful for development for catching certain types of bugs.])],
 511 if test "${enableval}" != "no"; then
 512    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 513    [Define this to enable compile time checks for the Lisp_Object data type.])
 514 fi)
 515
 516
 517 dnl The name of this option is unfortunate.  It predates, and has no
 518 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 519 dnl Actually, it stops it working.
 520 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 521 AC_ARG_ENABLE(profiling,
 522 [AS_HELP_STRING([--enable-profiling],
 523                 [build emacs with low-level, gprof profiling support.
 524                 Mainly useful for debugging Emacs itself.  May not work on
 525                 all platforms.  Stops profiler.el working.])],
 526 [ac_enable_profiling="${enableval}"],[])
 527 if test x$ac_enable_profiling != x ; then
 528    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 529 else
 530    PROFILING_CFLAGS=
 531 fi
 532 AC_SUBST(PROFILING_CFLAGS)
 533
 534 AC_ARG_ENABLE(autodepend,
 535 [AS_HELP_STRING([--enable-autodepend],
 536                 [automatically generate dependencies to .h-files.
 537                  Requires gcc, enabled if found.])],
 538 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 539
 540 AC_ARG_ENABLE(gtk-deprecation-warnings,
 541 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 542                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 543 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 544
 545 dnl This used to use changequote, but, apart from 'changequote is evil'
 546 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 547 dnl the great gob of text.  Thus it's not processed for possible expansion.
 548 dnl Just make sure the brackets remain balanced.
 549 dnl
 550 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 551 dnl indicated by comments.
 552 dnl quotation begins
 553 [
 554
 555 ### If you add support for a new configuration, add code to this
 556 ### switch statement to recognize your configuration name and select
 557 ### the appropriate opsys.
 558
 559 ### As far as handling version numbers on operating systems is
 560 ### concerned, make sure things will fail in a fixable way.  If
 561 ### /etc/MACHINES doesn't say anything about version numbers, be
 562 ### prepared to handle anything reasonably.  If version numbers
 563 ### matter, be sure /etc/MACHINES says something about it.
 564
 565 opsys='' unported=no
 566 case "${canonical}" in
 567
 568   ## GNU/Linux and similar ports
 569   *-*-linux* )
 570     opsys=gnu-linux
 571   ;;
 572
 573   ## FreeBSD ports
 574   *-*-freebsd* )
 575     opsys=freebsd
 576   ;;
 577
 578   ## DragonFly ports
 579   *-*-dragonfly* )
 580     opsys=dragonfly
 581   ;;
 582
 583   ## FreeBSD kernel + glibc based userland
 584   *-*-kfreebsd*gnu* )
 585     opsys=gnu-kfreebsd
 586   ;;
 587
 588   ## NetBSD ports
 589   *-*-netbsd* )
 590     opsys=netbsd
 591   ;;
 592
 593   ## OpenBSD ports
 594   *-*-openbsd* | *-*-mirbsd* )
 595     opsys=openbsd
 596   ;;
 597
 598   ## Apple Darwin / Mac OS X
 599   *-apple-darwin* )
 600     case "${canonical}" in
 601       *-apple-darwin[0-9].*) unported=yes ;;
 602       i[3456]86-* | x86_64-* )  ;;
 603       * )            unported=yes ;;
 604     esac
 605     opsys=darwin
 606     ## Use fink packages if available.
 607     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 608 ##    if test -d /sw/include && test -d /sw/lib; then
 609 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 610 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 611 ##    fi
 612   ;;
 613
 614   ## Chromium Native Client
 615   *-nacl )
 616     opsys=nacl
 617   ;;
 618
 619   ## Cygwin ports
 620   *-*-cygwin )
 621     opsys=cygwin
 622   ;;
 623
 624   ## HP 9000 series 700 and 800, running HP/UX
 625   hppa*-hp-hpux10.2* )
 626     opsys=hpux10-20
 627   ;;
 628   hppa*-hp-hpux1[1-9]* )
 629     opsys=hpux11
 630     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 631   ;;
 632
 633   ## IBM machines
 634   rs6000-ibm-aix4.[23]* )
 635     opsys=aix4-2
 636   ;;
 637   powerpc-ibm-aix4.[23]*  )
 638     opsys=aix4-2
 639   ;;
 640   rs6000-ibm-aix[56]* )
 641     opsys=aix4-2
 642   ;;
 643   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 644     opsys=aix4-2
 645   ;;
 646
 647   ## Silicon Graphics machines
 648   ## Iris 4D
 649   mips-sgi-irix6.5 )
 650     opsys=irix6-5
 651     # Without defining _LANGUAGE_C, things get masked out in the headers
 652     # so that, for instance, grepping for 'free' in stdlib.h fails and
 653     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 654     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 655   ;;
 656
 657   ## Suns
 658   *-sun-solaris* \
 659     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 660     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 661     case "${canonical}" in
 662       i[3456]86-*-* )   ;;
 663       amd64-*-*|x86_64-*-*) ;;
 664       sparc* )          ;;
 665       * )               unported=yes ;;
 666     esac
 667     case "${canonical}" in
 668       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 669                 opsys=sol2-10
 670                 emacs_check_sunpro_c=yes
 671                 ;;
 672       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 673       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 674       *-sunos5.6* | *-solaris2.6* )
 675                 opsys=sol2-6
 676                 RANLIB="ar -ts"
 677                 ;;
 678       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 679       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 680                 opsys=sol2-6
 681                 emacs_check_sunpro_c=yes
 682                 ;;
 683     esac
 684     ## Watch out for a compiler that we know will not work.
 685     case "${canonical}" in
 686      *-solaris* | *-sunos5* )
 687                 if [ "x$CC" = x/usr/ucb/cc ]; then
 688                   ## /usr/ucb/cc doesn't work;
 689                   ## we should find some other compiler that does work.
 690                   unset CC
 691                 fi
 692                 ;;
 693       *) ;;
 694     esac
 695   ;;
 696
 697   ## Intel 386 machines where we don't care about the manufacturer.
 698   i[3456]86-*-* )
 699     case "${canonical}" in
 700       *-darwin* )               opsys=darwin ;;
 701       *-mingw* )
 702                 opsys=mingw32
 703                 # MinGW overrides and adds some system headers in nt/inc.
 704                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 705                 ;;
 706       *-sysv4.2uw* )            opsys=unixware ;;
 707       *-sysv5uw* )              opsys=unixware ;;
 708       *-sysv5OpenUNIX* )        opsys=unixware ;;
 709       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 710     esac
 711   ;;
 712
 713   # MinGW64
 714   x86_64-*-* )
 715     case "${canonical}" in
 716       *-mingw* )
 717                 opsys=mingw32
 718                 # MinGW overrides and adds some system headers in nt/inc.
 719                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 720                 ;;
 721       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 722     esac
 723   ;;
 724
 725   * )
 726     unported=yes
 727   ;;
 728 esac
 729
 730 ### If the code above didn't choose an operating system, just choose
 731 ### an operating system based on the configuration name.  You really
 732 ### only want to use this when you have no idea what the right
 733 ### operating system is; if you know what operating systems a machine
 734 ### runs, it's cleaner to make it explicit in the case statement
 735 ### above.
 736 if test x"${opsys}" = x; then
 737   case "${canonical}" in
 738     *-gnu* )                            opsys=gnu ;;
 739     * )
 740       unported=yes
 741     ;;
 742   esac
 743 fi
 744
 745 ]
 746 dnl quotation ends
 747
 748 if test $unported = yes; then
 749   AC_MSG_ERROR([Emacs does not support '${canonical}' systems.
 750 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 751 Check 'etc/MACHINES' for recognized configuration names.])
 752 fi
 753
 754 #### Choose a compiler.
 755
 756 dnl Don't bother to test for C89.
 757 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 758
 759 dnl Sets GCC=yes if using gcc.
 760 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 761 if test -n "$XCRUN"; then
 762   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 763   test -n "$AR" && export AR
 764 fi
 765
 766 dnl Emacs needs C99 or later.
 767 gl_PROG_CC_C99
 768
 769 AM_PROG_CC_C_O
 770
 771 if test x$GCC = xyes; then
 772   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 773 else
 774   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 775 fi
 776
 777 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 778 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 779 dnl that clash with MinGW.
 780 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 781
 782 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 783 AC_DEFUN([gl_CRYPTO_CHECK])
 784 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 785 # as we don't use them.
 786 AC_DEFUN([gl_FCNTL_O_FLAGS])
 787 # Avoid gnulib's test for pthread_sigmask.
 788 funcs=
 789 for func in $ac_func_list; do
 790   test $func = pthread_sigmask || AS_VAR_APPEND([funcs], [" $func"])
 791 done
 792 ac_func_list=$funcs
 793 # Use the system putenv even if it lacks GNU features, as we don't need them,
 794 # and the gnulib replacement runs afoul of a FreeBSD 10.1 bug; see Bug#19874.
 795 AC_CHECK_FUNCS_ONCE([putenv])
 796 AC_DEFUN([gl_FUNC_PUTENV],
 797   [test "$ac_cv_func_putenv" = yes || REPLACE_PUTENV=1])
 798
 799 # Initialize gnulib right after choosing the compiler.
 800 dnl Amongst other things, this sets AR and ARFLAGS.
 801 gl_EARLY
 802
 803 if test "$ac_test_CFLAGS" != set; then
 804   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 805   # if -g3 works and the user does not specify CFLAGS.
 806   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 807   case $CFLAGS in
 808     '-g')
 809       emacs_g3_CFLAGS='-g3';;
 810     '-g -O2')
 811       emacs_g3_CFLAGS='-g3 -O2';;
 812     *)
 813       emacs_g3_CFLAGS='';;
 814   esac
 815   if test -n "$emacs_g3_CFLAGS"; then
 816     emacs_save_CFLAGS=$CFLAGS
 817     CFLAGS=$emacs_g3_CFLAGS
 818     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 819       [emacs_cv_prog_cc_g3],
 820       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 821          [emacs_cv_prog_cc_g3=yes],
 822          [emacs_cv_prog_cc_g3=no])])
 823     if test $emacs_cv_prog_cc_g3 != yes; then
 824       CFLAGS=$emacs_save_CFLAGS
 825     fi
 826     if test $opsys = mingw32; then
 827       CFLAGS="$CFLAGS -gdwarf-2"
 828     fi
 829   fi
 830
 831   case $CFLAGS in
 832     *-O*) ;;
 833     *)
 834       # No optimization flag was inferred for this non-GCC compiler.
 835       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 836       emacs_save_CFLAGS=$CFLAGS
 837       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 838       CFLAGS=${CFLAGS}-O
 839       AC_CACHE_CHECK([whether $CC accepts -O],
 840         [emacs_cv_prog_cc_o],
 841         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 842            [emacs_cv_prog_cc_o=yes],
 843            [emacs_cv_prog_cc_o=no])])
 844       if test $emacs_cv_prog_cc_o != yes; then
 845         CFLAGS=$emacs_save_CFLAGS
 846       fi ;;
 847   esac
 848 fi
 849
 850 AC_ARG_ENABLE([gcc-warnings],
 851   [AS_HELP_STRING([--enable-gcc-warnings],
 852                   [turn on lots of GCC warnings/errors. This is intended for
 853                    developers, and may generate false alarms when used
 854                    with older or non-GNU development tools.])],
 855   [case $enableval in
 856      yes|no) ;;
 857      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 858    esac
 859    gl_gcc_warnings=$enableval],
 860   [gl_gcc_warnings=no]
 861 )
 862
 863 # clang is unduly picky about some things.
 864 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 865   [AC_COMPILE_IFELSE(
 866      [AC_LANG_PROGRAM([[
 867           #ifndef __clang__
 868             error "not clang";
 869           #endif
 870         ]])],
 871      [emacs_cv_clang=yes],
 872      [emacs_cv_clang=no])])
 873
 874 # When compiling with GCC, prefer -isystem to -I when including system
 875 # include files, to avoid generating useless diagnostics for the files.
 876 if test "$gl_gcc_warnings" != yes; then
 877   isystem='-I'
 878   if test "$emacs_cv_clang" = yes
 879   then
 880      # Turn off some warnings if supported.
 881      gl_WARN_ADD([-Wno-switch])
 882      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 883      gl_WARN_ADD([-Wno-pointer-sign])
 884      gl_WARN_ADD([-Wno-string-plus-int])
 885      gl_WARN_ADD([-Wno-unknown-attributes])
 886   fi
 887 else
 888   isystem='-isystem '
 889
 890   # This, $nw, is the list of warnings we disable.
 891   nw=
 892
 893   case $with_x_toolkit in
 894     lucid | athena | motif)
 895        # Old toolkits mishandle 'const'.
 896        nw="$nw -Wwrite-strings"
 897        ;;
 898     *)
 899        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 900        ;;
 901   esac
 902   AC_SUBST([WERROR_CFLAGS])
 903
 904   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 905   nw="$nw -Woverlength-strings"     # Not a problem these days
 906   nw="$nw -Wformat-nonliteral"      # we do this a lot
 907   nw="$nw -Wvla"                    # Emacs uses <vla.h>.
 908   nw="$nw -Wswitch-default"         # Too many warnings for now
 909   nw="$nw -Winline"                 # OK to ignore 'inline'
 910   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 911   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 912                                     # signed overflow has undefined behavior
 913   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 914   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 915   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 916
 917   # Emacs doesn't care about shadowing; see
 918   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 919   nw="$nw -Wshadow"
 920
 921   # Emacs's use of alloca inhibits protecting the stack.
 922   nw="$nw -Wstack-protector"
 923
 924   # Emacs's use of partly-const functions such as Fgnutls_available_p
 925   # make this option problematic.
 926   nw="$nw -Wsuggest-attribute=const"
 927
 928   # Emacs's use of partly-pure functions such as CHECK_TYPE make this
 929   # option problematic.
 930   nw="$nw -Wsuggest-attribute=pure"
 931
 932   # This part is merely for shortening the command line,
 933   # since -Wall implies -Wswitch.
 934   nw="$nw -Wswitch"
 935
 936   # This part is merely for shortening the command line,
 937   # since -Wno-FOO needs to be added below regardless.
 938   nw="$nw -Wmissing-field-initializers"
 939   nw="$nw -Wtype-limits"
 940   nw="$nw -Wunused-parameter"
 941
 942   if test $emacs_cv_clang = yes; then
 943     nw="$nw -Wcast-align"
 944   fi
 945
 946   gl_MANYWARN_ALL_GCC([ws])
 947   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 948   for w in $ws; do
 949     gl_WARN_ADD([$w])
 950   done
 951   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 952   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 953   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 954   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 955   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 956   gl_WARN_ADD([-Wno-format-nonliteral])
 957
 958   # More things that clang is unduly picky about.
 959   if test $emacs_cv_clang = yes; then
 960     gl_WARN_ADD([-Wno-format-extra-args])
 961     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 962     gl_WARN_ADD([-Wno-unused-command-line-argument])
 963     gl_WARN_ADD([-Wno-unused-value])
 964   fi
 965
 966   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 967   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 968   AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
 969   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 970       without upsetting glibc 2.15+. */
 971    #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
 972         && defined __OPTIMIZE__ && __OPTIMIZE__)
 973    # define _FORTIFY_SOURCE 2
 974    #endif
 975   ])
 976
 977   # We use a slightly smaller set of warning options for lib/.
 978   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 979   nw=
 980   nw="$nw -Wunused-macros"
 981
 982   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 983   AC_SUBST([GNULIB_WARN_CFLAGS])
 984 fi
 985
 986 edit_cflags="
 987   s,///*,/,g
 988   s/^/ /
 989   s/ -I/ $isystem/g
 990   s/^ //
 991 "
 992
 993 AC_ARG_ENABLE(link-time-optimization,
 994 [AS_HELP_STRING([--enable-link-time-optimization],
 995                 [build emacs with link-time optimization.
 996                  This requires GCC 4.5.0 or later, or clang.
 997                  (Note that clang support is experimental - see INSTALL.)
 998                  It also makes Emacs harder to debug, and when we tried it
 999                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
1000                  recommended for typical use.])],
1001 if test "${enableval}" != "no"; then
1002    ac_lto_supported=no
1003    if test $emacs_cv_clang = yes; then
1004       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
1005       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
1006       if test -x "$GOLD_PLUGIN"; then
1007          LTO="-flto"
1008       fi
1009    elif test x$GCC = xyes; then
1010       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
1011       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
1012       if test x$CPUS != x; then
1013          LTO="-flto=$CPUS"
1014       else
1015          LTO="-flto"
1016       fi
1017    else
1018       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
1019    fi
1020    if test -z "$LTO"; then
1021       ac_lto_supported=no
1022    else
1023       old_CFLAGS=$CFLAGS
1024       CFLAGS="$CFLAGS $LTO"
1025       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1026          [ac_lto_supported=yes], [ac_lto_supported=no])
1027          CFLAGS="$old_CFLAGS"
1028    fi
1029    AC_MSG_RESULT([$ac_lto_supported])
1030    if test "$ac_lto_supported" = "yes"; then
1031       CFLAGS="$CFLAGS $LTO"
1032       if test x$emacs_cv_clang = xyes; then
1033          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
1034          # WARNING: 'ar --plugin ...' doesn't work without
1035          # command, so plugin name is appended to ARFLAGS.
1036          ARFLAGS="cru --plugin $GOLD_PLUGIN"
1037          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
1038       else
1039         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
1040         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
1041         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
1042         dnl dump core on Fedora 20, so play it safe for now.
1043         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
1044           [CFLAGS="$CFLAGS -ffat-lto-objects"])
1045       fi
1046    fi
1047 fi)
1048
1049 dnl Prefer silent make output.  For verbose output, use
1050 dnl 'configure --disable-silent-rules' or 'make V=1' .
1051 AM_SILENT_RULES([yes])
1052 dnl Port to Automake 1.11.
1053 dnl This section can be removed once we assume Automake 1.14 or later.
1054 : ${AM_V=$AM_DEFAULT_VERBOSITY}
1055 : ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
1056 AC_SUBST([AM_V])
1057 AM_SUBST_NOTMAKE([AM_V])
1058 AC_SUBST([AM_DEFAULT_V])
1059 AM_SUBST_NOTMAKE([AM_DEFAULT_V])
1060 AC_SUBST([AM_DEFAULT_VERBOSITY])
1061
1062 dnl Some other nice autoconf tests.
1063 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
1064 dnl AC_PROG_INSTALL
1065 dnl AC_PROG_MKDIR_P
1066 dnl if test "x$RANLIB" = x; then
1067 dnl   AC_PROG_RANLIB
1068 dnl fi
1069
1070
1071 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
1072 dnl can be made to directories.  This is not relevant for our usage, and
1073 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1074 dnl hosted on AFS, both examples where simple links work, but links to
1075 dnl directories fail.  We use a cut-down version instead.
1076 dnl AC_PROG_LN_S
1077
1078 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1079 rm -f conf$$ conf$$.file
1080
1081 LN_S_FILEONLY='cp -p'
1082
1083 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1084 dnl random program in the current directory.
1085 if (echo >conf$$.file) 2>/dev/null; then
1086   if ln -s conf$$.file conf$$ 2>/dev/null; then
1087     if test "$opsys" = "mingw32"; then
1088       LN_S_FILEONLY='/bin/ln -s'
1089     else
1090       LN_S_FILEONLY='ln -s'
1091     fi
1092   elif ln conf$$.file conf$$ 2>/dev/null; then
1093     if test "$opsys" = "mingw32"; then
1094       LN_S_FILEONLY=/bin/ln
1095     else
1096       LN_S_FILEONLY=ln
1097     fi
1098   fi
1099 fi
1100
1101 rm -f conf$$ conf$$.file
1102
1103 if test "$LN_S_FILEONLY" = "ln -s"; then
1104    AC_MSG_RESULT([yes])
1105 else
1106    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1107 fi
1108
1109 AC_SUBST(LN_S_FILEONLY)
1110
1111
1112 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1113 dnl doesn't support links to directories, as in "ln file dir".  But that
1114 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1115 dnl executables at "make install" time.
1116 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1117 dnl for more details.
1118 if test "$opsys" = "mingw32"; then
1119   LN_S="/bin/ln"
1120 fi
1121
1122 dnl On some Debian versions, "install-info" prints irritating messages
1123 dnl "This is not dpkg install-info anymore, but GNU install-info"
1124 dnl if called via an absolute file name.
1125 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1126 dnl Sadly some people may have an old ginstall-info installed on
1127 dnl non-Debian systems, so we can't use this.
1128 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1129 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1130
1131 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1132   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1133 dnl Don't use GZIP, which is used by gzip for additional parameters.
1134 AC_PATH_PROG(GZIP_PROG, gzip)
1135
1136 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1137    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1138
1139 if test $opsys = gnu-linux; then
1140   AC_PATH_PROG(PAXCTL, paxctl,,
1141     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1142   if test "X$PAXCTL" != X; then
1143     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1144     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1145       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
1146       else AC_MSG_RESULT(no); PAXCTL=""; fi])
1147   fi
1148
1149   if test "${SETFATTR+set}" != set; then
1150     AC_CACHE_CHECK([for setfattr],
1151       [emacs_cv_prog_setfattr],
1152       [touch conftest.tmp
1153        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1154          emacs_cv_prog_setfattr=yes
1155        else
1156          emacs_cv_prog_setfattr=no
1157        fi])
1158     if test "$emacs_cv_prog_setfattr" = yes; then
1159       SETFATTR=setfattr
1160     else
1161       SETFATTR=
1162     fi
1163     rm -f conftest.tmp
1164     AC_SUBST([SETFATTR])
1165   fi
1166 fi
1167
1168 ## Need makeinfo >= 4.7 (?) to build the manuals.
1169 if test "$MAKEINFO" != "no"; then
1170   if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
1171     MAKEINFO=makeinfo
1172   fi
1173   case `($MAKEINFO --version) 2>/dev/null` in
1174     *' (GNU texinfo) '4.[[7-9]]* | \
1175     *' (GNU texinfo) '4.[[1-9][0-9]]* | \
1176     *' (GNU texinfo) '[[5-9]]* | \
1177     *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1178     *) MAKEINFO=no;;
1179   esac
1180 fi
1181
1182 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1183 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1184 ## therefore in the category of "special tools" not normally required, which
1185 ## configure does not have to check for (eg autoconf itself).
1186 ## In a repository checkout on the other hand, the manuals are not included.
1187 ## So makeinfo is a requirement to build from the repository, and configure
1188 ## should test for it as it does for any other build requirement.
1189 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1190 ## with pre-built manuals, from a repository checkout.
1191 HAVE_MAKEINFO=yes
1192
1193 if test "$MAKEINFO" = "no"; then
1194   MAKEINFO=makeinfo
1195   if test "x${with_makeinfo}" = "xno"; then
1196     HAVE_MAKEINFO=no
1197   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1198     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1199 source tree does not seem to have pre-built manuals in the 'info' directory.
1200 Either install a suitable version of makeinfo, or re-run configure
1201 with the '--without-makeinfo' option to build without the manuals.] )
1202   fi
1203 fi
1204 AC_SUBST(HAVE_MAKEINFO)
1205
1206 if test $opsys = mingw32; then
1207    DOCMISC_W32=efaq-w32
1208 else
1209    DOCMISC_W32=
1210 fi
1211 AC_SUBST(DOCMISC_W32)
1212
1213 dnl Add our options to ac_link now, after it is set up.
1214
1215 if test x$GCC = xyes; then
1216   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1217     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1218 else
1219   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1220     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1221 fi
1222
1223 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1224 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1225 dnl (Don't use '-z nocombreloc' as -z takes no arg on Irix.)
1226 dnl Treat GCC specially since it just gives a non-fatal 'unrecognized option'
1227 dnl if not built to support GNU ld.
1228
1229 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1230 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1231 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1232 dnl   Eg "make LDFLAGS=... all" could run into problems,
1233 dnl   http://bugs.debian.org/684788
1234 dnl * unnecessary, since temacs is the only thing that actually needs it.
1235 dnl   Indeed this is where it was originally, prior to:
1236 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1237 late_LDFLAGS="$LDFLAGS"
1238 if test x$GCC = xyes; then
1239   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1240 else
1241   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1242 fi
1243
1244 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1245
1246 AC_MSG_CHECKING([for -znocombreloc])
1247 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1248   [AC_MSG_RESULT(yes)],
1249   LDFLAGS_NOCOMBRELOC=
1250   [AC_MSG_RESULT(no)])
1251
1252 LDFLAGS="$late_LDFLAGS"
1253
1254 AC_CACHE_CHECK([whether addresses are sanitized],
1255   [emacs_cv_sanitize_address],
1256   [AC_COMPILE_IFELSE(
1257      [AC_LANG_PROGRAM(
1258         [[#ifndef __has_feature
1259           #define __has_feature(f) 0
1260           #endif
1261           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1262           #else
1263            error "Addresses are not sanitized.";
1264           #endif
1265         ]])],
1266      [emacs_cv_sanitize_address=yes],
1267      [emacs_cv_sanitize_address=no])])
1268
1269 dnl The function dump-emacs will not be defined and temacs will do
1270 dnl (load "loadup") automatically unless told otherwise.
1271 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1272 case "$opsys" in
1273   nacl) CANNOT_DUMP=yes ;;
1274 esac
1275
1276 if test "$CANNOT_DUMP" = "yes"; then
1277   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1278 elif test "$emacs_cv_sanitize_address" = yes; then
1279   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1280 fi
1281
1282 AC_SUBST(CANNOT_DUMP)
1283
1284
1285 UNEXEC_OBJ=unexelf.o
1286 case "$opsys" in
1287   # MSDOS uses unexcoff.o
1288   aix4-2)
1289    UNEXEC_OBJ=unexaix.o
1290    ;;
1291   cygwin)
1292    UNEXEC_OBJ=unexcw.o
1293    ;;
1294   darwin)
1295    UNEXEC_OBJ=unexmacosx.o
1296    ;;
1297   hpux10-20 | hpux11)
1298    UNEXEC_OBJ=unexhp9k800.o
1299    ;;
1300   mingw32)
1301    UNEXEC_OBJ=unexw32.o
1302    ;;
1303   sol2-10)
1304    # Use the Solaris dldump() function, called from unexsol.c, to dump
1305    # emacs, instead of the generic ELF dump code found in unexelf.c.
1306    # The resulting binary has a complete symbol table, and is better
1307    # for debugging and other observability tools (debuggers, pstack, etc).
1308    #
1309    # If you encounter a problem using dldump(), please consider sending
1310    # a message to the OpenSolaris tools-linking mailing list:
1311    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1312    #
1313    # It is likely that dldump() works with older Solaris too, but this has
1314    # not been tested, so for now this change is for Solaris 10 or newer.
1315    UNEXEC_OBJ=unexsol.o
1316    ;;
1317 esac
1318
1319 LD_SWITCH_SYSTEM=
1320 case "$opsys" in
1321   freebsd|dragonfly)
1322    ## Let 'ld' find image libs and similar things in /usr/local/lib.
1323    ## The system compiler, GCC, has apparently been modified to not
1324    ## look there, contrary to what a stock GCC would do.
1325 ### It's not our place to do this.  See bug#10313#17.
1326 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1327       :
1328    ;;
1329
1330   gnu-linux)
1331    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1332    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1333    ;;
1334
1335   netbsd)
1336 ### It's not our place to do this.  See bug#10313#17.
1337 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1338       :
1339    ;;
1340
1341   openbsd)
1342    ## Han Boetes <han@boetes.org> says this is necessary,
1343    ## otherwise Emacs dumps core on elf systems.
1344    LD_SWITCH_SYSTEM="-Z"
1345    ;;
1346 esac
1347 AC_SUBST(LD_SWITCH_SYSTEM)
1348
1349 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1350
1351 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1352 ## which has not been defined yet.  When this was handled with cpp,
1353 ## it was expanded to null when configure sourced the s/*.h file.
1354 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1355 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1356 ## (or somesuch), but because it is supposed to go at the _front_
1357 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1358 ## Compare with the gnu-linux case below, which added to the end
1359 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1360 ## LD_SWITCH_SYSTEM_TEMACS.
1361 case "$opsys" in
1362   netbsd|openbsd)
1363    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1364 esac
1365
1366
1367 C_SWITCH_MACHINE=
1368 case $canonical in
1369  alpha*)
1370   AC_CHECK_DECL([__ELF__])
1371   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1372     ## With ELF, make sure that all common symbols get allocated to in the
1373     ## data section.  Otherwise, the dump of temacs may miss variables in
1374     ## the shared library that have been initialized.  For example, with
1375     ## GNU libc, __malloc_initialized would normally be resolved to the
1376     ## shared library's .bss section, which is fatal.
1377     if test "x$GCC" = "xyes"; then
1378       C_SWITCH_MACHINE="-fno-common"
1379     else
1380       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1381     fi
1382   else
1383       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1384       dnl albeit under the mistaken assumption that said file
1385       dnl was no longer used.
1386       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1387   fi
1388   ;;
1389 esac
1390 AC_SUBST(C_SWITCH_MACHINE)
1391
1392 AC_SUBST(UNEXEC_OBJ)
1393
1394 C_SWITCH_SYSTEM=
1395 ## Some programs in src produce warnings saying certain subprograms
1396 ## are too complex and need a MAXMEM value greater than 2000 for
1397 ## additional optimization.  --nils@exp-math.uni-essen.de
1398 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1399   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1400 if test "$opsys" = "mingw32"; then
1401   case "$canonical" in
1402     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1403     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1404   esac
1405 fi
1406 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1407 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1408 AC_SUBST(C_SWITCH_SYSTEM)
1409
1410
1411 LIBS_SYSTEM=
1412 case "$opsys" in
1413   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1414   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1415
1416   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1417
1418   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1419
1420   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1421
1422   ## Motif needs -lgen.
1423   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1424 esac
1425
1426 AC_SUBST(LIBS_SYSTEM)
1427
1428 ### Make sure subsequent tests use flags consistent with the build flags.
1429
1430 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1431   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1432 else
1433   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1434 fi
1435
1436 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1437 AC_DEFUN([AC_TYPE_SIZE_T])
1438 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1439 AC_DEFUN([AC_TYPE_UID_T])
1440
1441 # sqrt and other floating-point functions such as fmod and frexp
1442 # are found in -lm on many systems.
1443 OLD_LIBS=$LIBS
1444 AC_SEARCH_LIBS([sqrt], [m])
1445 if test "X$LIBS" = "X$OLD_LIBS"; then
1446   LIB_MATH=
1447 else
1448   LIB_MATH=$ac_cv_search_sqrt
1449 fi
1450 LIBS=$OLD_LIBS
1451
1452 dnl Current possibilities handled by sed (aix4-2 -> aix,
1453 dnl gnu-linux -> gnu/linux, etc.):
1454 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1455 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1456 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1457
1458 case $opsys in
1459   cygwin )
1460     LIB_MATH=
1461     ;;
1462   darwin )
1463     ## Adding -lm confuses the dynamic linker, so omit it.
1464     LIB_MATH=
1465     ;;
1466   freebsd | dragonfly )
1467     SYSTEM_TYPE=berkeley-unix
1468     ;;
1469   gnu-linux | gnu-kfreebsd )
1470     ;;
1471   hpux10-20 | hpux11 )
1472     ;;
1473   mingw32 )
1474     LIB_MATH=
1475     SYSTEM_TYPE=windows-nt
1476     ;;
1477   dnl NB this may be adjusted below.
1478   netbsd | openbsd )
1479     SYSTEM_TYPE=berkeley-unix
1480     ;;
1481
1482   sol2* | unixware )
1483     SYSTEM_TYPE=usg-unix-v
1484     ;;
1485
1486 esac
1487
1488 AC_SUBST(LIB_MATH)
1489 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1490   [The type of system you are compiling for; sets 'system-type'.])
1491
1492
1493 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1494 pre_PKG_CONFIG_LIBS=$LIBS
1495
1496 PKG_PROG_PKG_CONFIG(0.9.0)
1497
1498 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1499 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1500 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1501 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1502 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1503 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1504 dnl actions.
1505 AC_DEFUN([EMACS_CHECK_MODULES],
1506   [PKG_CHECK_MODULES([$1], [$2],
1507      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1508       m4_default([$3], [HAVE_$1=yes])],
1509      [m4_default([$4], [HAVE_$1=no])])])
1510
1511 HAVE_SOUND=no
1512 if test "${with_sound}" != "no"; then
1513   # Sound support for GNU/Linux, the free BSDs, MinGW, and Cygwin.
1514   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1515     have_sound_header=yes, [], [
1516     #ifdef __MINGW32__
1517     #define WIN32_LEAN_AND_MEAN
1518     #include <windows.h>
1519     #endif
1520     ])
1521   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1522     AC_MSG_ERROR([OSS sound support requested but not found.])
1523
1524   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1525     # Emulation library used on NetBSD.
1526     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1527     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1528       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1529     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1530     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1531   fi
1532   AC_SUBST(LIBSOUND)
1533
1534   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1535     ALSA_REQUIRED=1.0.0
1536     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1537     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1538     if test $HAVE_ALSA = yes; then
1539       SAVE_CFLAGS="$CFLAGS"
1540       SAVE_LIBS="$LIBS"
1541       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1542       LIBS="$ALSA_LIBS $LIBS"
1543       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1544                       emacs_alsa_normal=yes,
1545                     emacs_alsa_normal=no)
1546       if test "$emacs_alsa_normal" != yes; then
1547         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1548                        [[snd_lib_error_set_handler (0);]])],
1549                        emacs_alsa_subdir=yes,
1550                      emacs_alsa_subdir=no)
1551         if test "$emacs_alsa_subdir" != yes; then
1552           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1553         fi
1554         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1555       fi
1556
1557       CFLAGS="$SAVE_CFLAGS"
1558       LIBS="$SAVE_LIBS"
1559       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1560       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1561       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1562     elif test "${with_sound}" = "alsa"; then
1563       AC_MSG_ERROR([ALSA sound support requested but not found.])
1564     fi
1565   fi                            dnl with_sound = alsa|yes
1566
1567   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1568   dnl compiles only on the specified platforms.  For others, it
1569   dnl probably doesn't make sense to try.
1570   dnl FIXME So surely we should bypass this whole section if not using
1571   dnl one of these platforms?
1572   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1573      case "$opsys" in
1574        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1575        dnl Adjust the --with-sound help text if you change this.
1576        gnu-linux|freebsd|netbsd|mingw32|cygwin)
1577          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1578          HAVE_SOUND=yes
1579          ;;
1580      esac
1581   fi
1582
1583   AC_SUBST(CFLAGS_SOUND)
1584 fi
1585
1586 dnl checks for header files
1587 AC_CHECK_HEADERS_ONCE(
1588   sys/systeminfo.h
1589   sys/sysinfo.h
1590   coff.h pty.h
1591   sys/resource.h
1592   sys/utsname.h pwd.h utmp.h util.h)
1593
1594 AC_MSG_CHECKING(if personality LINUX32 can be set)
1595 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1596                emacs_cv_personality_linux32=yes,
1597                emacs_cv_personality_linux32=no)
1598 AC_MSG_RESULT($emacs_cv_personality_linux32)
1599
1600 if test $emacs_cv_personality_linux32 = yes; then
1601   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1602             [Define to 1 if personality LINUX32 can be set.])
1603 fi
1604
1605 # Note that Solaris has sys/sysinfo.h which defines struct
1606 # sysinfo as well.  To make sure that we're using GNU/Linux
1607 # sysinfo, we explicitly set one of its fields.
1608 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1609   AC_MSG_CHECKING([if Linux sysinfo may be used])
1610   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1611                                      [[struct sysinfo si;
1612                                        si.totalram = 0;
1613                                        sysinfo (&si)]])],
1614     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1615   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1616   if test $emacs_cv_linux_sysinfo = yes; then
1617     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1618     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1619                                        [[struct sysinfo si; return si.mem_unit]])],
1620       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1621                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1622   fi
1623 fi
1624
1625 dnl On Solaris 8 there's a compilation warning for term.h because
1626 dnl it doesn't define 'bool'.
1627 AC_CHECK_HEADERS(term.h, , , -)
1628 AC_HEADER_TIME
1629 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1630                                       ]])
1631 if test $ac_cv_have_decl_sys_siglist != yes; then
1632   # For Tru64, at least:
1633   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1634                                           ]])
1635 fi
1636 AC_HEADER_SYS_WAIT
1637
1638 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1639 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1640 #if HAVE_SYS_SOCKET_H
1641 #include <sys/socket.h>
1642 #endif])
1643 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1644 #if HAVE_SYS_SOCKET_H
1645 #include <sys/socket.h>
1646 #endif])
1647 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1648 #if HAVE_SYS_SOCKET_H
1649 #include <sys/socket.h>
1650 #endif])
1651
1652 dnl checks for structure members
1653 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1654                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1655                   struct ifreq.ifr_addr,
1656                   struct ifreq.ifr_addr.sa_len], , ,
1657                  [AC_INCLUDES_DEFAULT
1658 #if HAVE_SYS_SOCKET_H
1659 #include <sys/socket.h>
1660 #endif
1661 #if HAVE_NET_IF_H
1662 #include <net/if.h>
1663 #endif])
1664
1665 dnl Check for endianness.
1666 dnl AC_C_BIGENDIAN is done by gnulib.
1667
1668 dnl check for Make feature
1669
1670 AUTO_DEPEND=no
1671 dnl check if we have GCC and autodepend is on.
1672 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1673    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1674    SAVE_CFLAGS="$CFLAGS"
1675    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1676    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1677    CFLAGS="$SAVE_CFLAGS"
1678    test -f deps.d || ac_enable_autodepend=no
1679    rm -rf deps.d
1680    AC_MSG_RESULT([$ac_enable_autodepend])
1681    if test $ac_enable_autodepend = yes; then
1682       AUTO_DEPEND=yes
1683    fi
1684 fi
1685 AC_SUBST(AUTO_DEPEND)
1686
1687 dnl checks for operating system services
1688 AC_SYS_LONG_FILE_NAMES
1689
1690 #### Choose a window system.
1691
1692 ## We leave window_system equal to none if
1693 ## we end up building without one.  Any new window system should
1694 ## set window_system to an appropriate value and add objects to
1695 ## window-system-specific substs.
1696
1697 window_system=none
1698 AC_PATH_X
1699 if test "$no_x" != yes; then
1700   window_system=x11
1701 fi
1702
1703 LD_SWITCH_X_SITE_RPATH=
1704 if test "${x_libraries}" != NONE; then
1705   if test -n "${x_libraries}"; then
1706     LD_SWITCH_X_SITE=-L`AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -L/g'`
1707     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`
1708       AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -Wl,-rpath,/g'
1709     `
1710   fi
1711   x_default_search_path=""
1712   x_search_path=${x_libraries}
1713   if test -z "${x_search_path}"; then
1714     x_search_path=/usr/lib
1715   fi
1716   for x_library in `AS_ECHO(["$x_search_path:"]) | \
1717                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1718     x_search_path="\
1719 ${x_library}/X11/%L/%T/%N%C%S:\
1720 ${x_library}/X11/%l/%T/%N%C%S:\
1721 ${x_library}/X11/%T/%N%C%S:\
1722 ${x_library}/X11/%L/%T/%N%S:\
1723 ${x_library}/X11/%l/%T/%N%S:\
1724 ${x_library}/X11/%T/%N%S"
1725     if test x"${x_default_search_path}" = x; then
1726       x_default_search_path=${x_search_path}
1727     else
1728       x_default_search_path="${x_search_path}:${x_default_search_path}"
1729     fi
1730   done
1731 fi
1732 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1733
1734 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1735   C_SWITCH_X_SITE=$isystem`AS_ECHO(["$x_includes"]) | sed -e "s/:/ $isystem/g"`
1736 fi
1737
1738 if test x"${x_includes}" = x; then
1739   bitmapdir=/usr/include/X11/bitmaps
1740 else
1741   # accumulate include directories that have X11 bitmap subdirectories
1742   bmd_acc=
1743   for bmd in `AS_ECHO(["$x_includes"]) | sed -e 's/:/ /g'`; do
1744     if test -d "${bmd}/X11/bitmaps"; then
1745       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1746     fi
1747     if test -d "${bmd}/bitmaps"; then
1748       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1749     fi
1750   done
1751   bitmapdir=${bmd_acc#:}
1752 fi
1753
1754 test "${with_ns}" = maybe && test "${opsys}" != darwin && with_ns=no
1755 HAVE_NS=no
1756 NS_GNUSTEP_CONFIG=no
1757 NS_IMPL_COCOA=no
1758 NS_IMPL_GNUSTEP=no
1759 tmp_CPPFLAGS="$CPPFLAGS"
1760 tmp_CFLAGS="$CFLAGS"
1761 CPPFLAGS="$CPPFLAGS -x objective-c"
1762 CFLAGS="$CFLAGS -x objective-c"
1763 GNU_OBJC_CFLAGS=
1764 LIBS_GNUSTEP=
1765 if test "${with_ns}" != no; then
1766   if test "${opsys}" = darwin; then
1767      NS_IMPL_COCOA=yes
1768      ns_appdir=`pwd`/nextstep/Emacs.app
1769      ns_appbindir=${ns_appdir}/Contents/MacOS
1770      ns_appresdir=${ns_appdir}/Contents/Resources
1771      ns_appsrc=Cocoa/Emacs.base
1772      ns_fontfile=macfont.o
1773   elif flags=$( (gnustep-config --objc-flags) 2>/dev/null); then
1774      NS_IMPL_GNUSTEP=yes
1775      NS_GNUSTEP_CONFIG=yes
1776      GNU_OBJC_CFLAGS=$flags
1777      LIBS_GNUSTEP=$(gnustep-config --gui-libs) || exit
1778   elif test -f $GNUSTEP_CONFIG_FILE; then
1779      NS_IMPL_GNUSTEP=yes
1780      dnl FIXME sourcing this several times in subshells seems inefficient.
1781      GNUSTEP_SYSTEM_HEADERS=$(
1782        . $GNUSTEP_CONFIG_FILE
1783        AS_ECHO(["$GNUSTEP_SYSTEM_HEADERS"])
1784      )
1785      GNUSTEP_SYSTEM_LIBRARIES=$(
1786        . $GNUSTEP_CONFIG_FILE
1787        AS_ECHO(["$GNUSTEP_SYSTEM_LIBRARIES"])
1788      )
1789      dnl I seemed to need these as well with GNUstep-startup 0.25.
1790      GNUSTEP_LOCAL_HEADERS=$(
1791        . $GNUSTEP_CONFIG_FILE
1792        AS_ECHO(["$GNUSTEP_LOCAL_HEADERS"])
1793      )
1794      GNUSTEP_LOCAL_LIBRARIES=$(
1795        . $GNUSTEP_CONFIG_FILE
1796        AS_ECHO(["$GNUSTEP_LOCAL_LIBRARIES"])
1797      )
1798      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1799        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1800      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1801        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1802      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1803      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1804      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1805      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1806      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1807      dnl If they had chosen to either define it or not, we could have
1808      dnl just used AC_CHECK_DECL here.
1809      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1810        emacs_cv_objc_exceptions,
1811 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1812 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1813 1;
1814 #else
1815 fail;
1816 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1817      if test $emacs_cv_objc_exceptions = yes; then
1818        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1819        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1820          [Define if GNUstep uses ObjC exceptions.])
1821        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1822      fi
1823   fi
1824   if test $NS_IMPL_GNUSTEP = yes; then
1825      ns_appdir=`pwd`/nextstep/Emacs.app
1826      ns_appbindir=${ns_appdir}
1827      ns_appresdir=${ns_appdir}/Resources
1828      ns_appsrc=GNUstep/Emacs.base
1829      ns_fontfile=nsfont.o
1830   fi
1831
1832   dnl This is only used while we test the NS headers, it gets reset below.
1833   CPPFLAGS="$CPPFLAGS $GNU_OBJC_CFLAGS"
1834   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1835
1836   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1837                   [AC_MSG_ERROR([The include files (AppKit/AppKit.h etc) that
1838 are required for a Nextstep build are missing or cannot be compiled.
1839 Either fix this, or re-configure with the option '--without-ns'.])])
1840
1841   macfont_file=""
1842   if test "${NS_IMPL_COCOA}" = "yes"; then
1843     AC_MSG_CHECKING([for OSX 10.6 or newer])
1844     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1845                                      [
1846 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1847 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1060
1848  ; /* OK */
1849 #else
1850  error "OSX 10.6 or newer required";
1851 #endif
1852 #endif
1853                     ])],
1854                     ns_osx_have_106=yes,
1855                     ns_osx_have_106=no)
1856     AC_MSG_RESULT([$ns_osx_have_106])
1857
1858     if test $ns_osx_have_106 = no; then
1859        AC_MSG_ERROR([OSX 10.6 or newer is required]);
1860     fi
1861   fi
1862 fi
1863
1864 AC_SUBST(LIBS_GNUSTEP)
1865
1866 INSTALL_ARCH_INDEP_EXTRA=install-etc
1867 ns_self_contained=no
1868 NS_OBJ=
1869 NS_OBJC_OBJ=
1870 if test "${HAVE_NS}" = yes; then
1871   if test "$with_toolkit_scroll_bars" = "no"; then
1872     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1873   fi
1874
1875   window_system=nextstep
1876   # set up packaging dirs
1877   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1878      ns_self_contained=yes
1879      prefix=${ns_appresdir}
1880      exec_prefix=${ns_appbindir}
1881      dnl This one isn't really used, only archlibdir is.
1882      libexecdir="\${ns_appbindir}/libexec"
1883      archlibdir="\${ns_appbindir}/libexec"
1884      etcdocdir="\${ns_appresdir}/etc"
1885      etcdir="\${ns_appresdir}/etc"
1886      dnl FIXME maybe set datarootdir instead.
1887      dnl That would also get applications, icons, man.
1888      infodir="\${ns_appresdir}/info"
1889      mandir="\${ns_appresdir}/man"
1890      lispdir="\${ns_appresdir}/lisp"
1891      test "$locallisppathset" = no && locallisppath=""
1892      INSTALL_ARCH_INDEP_EXTRA=
1893   fi
1894
1895   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o $ns_fontfile"
1896 fi
1897 CFLAGS="$tmp_CFLAGS"
1898 CPPFLAGS="$tmp_CPPFLAGS"
1899 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1900 AC_SUBST(ns_self_contained)
1901 AC_SUBST(NS_OBJ)
1902 AC_SUBST(NS_OBJC_OBJ)
1903
1904 HAVE_W32=no
1905 W32_OBJ=
1906 W32_LIBS=
1907 EMACSRES=
1908 CLIENTRES=
1909 CLIENTW=
1910 W32_RES_LINK=
1911 EMACS_MANIFEST=
1912 UPDATE_MANIFEST=
1913 if test "${with_w32}" != no; then
1914   case "${opsys}" in
1915     cygwin)
1916       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1917              [AC_MSG_ERROR(['--with-w32' was specified, but windows.h
1918                    cannot be found.])])
1919     ;;
1920     mingw32)
1921     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1922     ;;
1923     *)
1924       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1925     ;;
1926   esac
1927 fi
1928
1929 if test "${opsys}" = "mingw32"; then
1930   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1931   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1932      #include <windows.h>
1933      #include <usp10.h>]],
1934    [[PIMAGE_NT_HEADERS pHeader;
1935      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1936    [emacs_cv_w32api=yes
1937     HAVE_W32=yes],
1938    emacs_cv_w32api=no)
1939   AC_MSG_RESULT($emacs_cv_w32api)
1940   if test "${emacs_cv_w32api}" = "no"; then
1941     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1942   fi
1943 fi
1944
1945 FIRSTFILE_OBJ=
1946 NTDIR=
1947 LIBS_ECLIENT=
1948 LIB_WSOCK32=
1949 NTLIB=
1950 CM_OBJ="cm.o"
1951 XARGS_LIMIT=
1952 if test "${HAVE_W32}" = "yes"; then
1953   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1954   if test "$with_toolkit_scroll_bars" = "no"; then
1955     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for w32 build.])
1956   fi
1957   AC_CHECK_TOOL(WINDRES, [windres],
1958                 [AC_MSG_ERROR([No resource compiler found.])])
1959   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1960   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1961   EMACSRES="emacs.res"
1962   case "$canonical" in
1963     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1964     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1965   esac
1966   dnl Construct something of the form "24,4,0,0" with 4 components.
1967   comma_version=`echo "${PACKAGE_VERSION}.0.0" | sed -e 's/\./,/g' -e 's/^\([[^,]]*,[[^,]]*,[[^,]]*,[[^,]]*\).*/\1/'`
1968
1969   comma_space_version=`echo "$comma_version" | sed 's/,/, /g'`
1970   AC_SUBST(comma_version)
1971   AC_SUBST(comma_space_version)
1972   AC_CONFIG_FILES([nt/emacs.rc nt/emacsclient.rc])
1973   if test "${opsys}" = "cygwin"; then
1974     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1975     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1976     # Tell the linker that emacs.res is an object (which we compile from
1977     # the rc file), not a linker script.
1978     W32_RES_LINK="-Wl,emacs.res"
1979   else
1980     UPDATE_MANIFEST=update-game-score.exe.manifest
1981     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1982     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1983     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1984     W32_RES_LINK="\$(EMACSRES)"
1985     CLIENTRES="emacsclient.res"
1986     CLIENTW="emacsclientw\$(EXEEXT)"
1987     FIRSTFILE_OBJ=firstfile.o
1988     NTDIR=nt
1989     CM_OBJ=
1990     LIBS_ECLIENT="-lcomctl32"
1991     LIB_WSOCK32="-lwsock32"
1992     NTLIB="ntlib.$ac_objext"
1993     XARGS_LIMIT="-s 10000"
1994   fi
1995 fi
1996 AC_SUBST(W32_OBJ)
1997 AC_SUBST(W32_LIBS)
1998 AC_SUBST(EMACSRES)
1999 AC_SUBST(EMACS_MANIFEST)
2000 AC_SUBST(UPDATE_MANIFEST)
2001 AC_SUBST(CLIENTRES)
2002 AC_SUBST(CLIENTW)
2003 AC_SUBST(W32_RES_LINK)
2004 AC_SUBST(FIRSTFILE_OBJ)
2005 AC_SUBST(NTDIR)
2006 AC_SUBST(CM_OBJ)
2007 AC_SUBST(LIBS_ECLIENT)
2008 AC_SUBST(LIB_WSOCK32)
2009 AC_SUBST(NTLIB)
2010 AC_SUBST(XARGS_LIMIT)
2011
2012 if test "${HAVE_W32}" = "yes"; then
2013   window_system=w32
2014   with_xft=no
2015 fi
2016
2017 ## $window_system is now set to the window system we will
2018 ## ultimately use.
2019
2020 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
2021    # Too many warnings for now.
2022    nw=
2023    nw="$nw -Wsuggest-attribute=noreturn"
2024    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
2025
2026    gl_WARN_ADD([-Wno-unused-variable])
2027    gl_WARN_ADD([-Wno-unused-but-set-variable])
2028    gl_WARN_ADD([-Wno-unused-but-set-parameter])
2029 fi
2030
2031 term_header=
2032 HAVE_X_WINDOWS=no
2033 HAVE_X11=no
2034 USE_X_TOOLKIT=none
2035
2036 case "${window_system}" in
2037   x11 )
2038     HAVE_X_WINDOWS=yes
2039     HAVE_X11=yes
2040     term_header=xterm.h
2041     case "${with_x_toolkit}" in
2042       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
2043       motif ) USE_X_TOOLKIT=MOTIF ;;
2044       gtk ) with_gtk=yes
2045             term_header=gtkutil.h
2046 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
2047 dnl USE_X_TOOLKIT is set.
2048             USE_X_TOOLKIT=none ;;
2049       gtk2 ) with_gtk2=yes
2050              term_header=gtkutil.h
2051              USE_X_TOOLKIT=none ;;
2052       gtk3 ) with_gtk3=yes
2053              term_header=gtkutil.h
2054              USE_X_TOOLKIT=none ;;
2055       no ) USE_X_TOOLKIT=none ;;
2056 dnl If user did not say whether to use a toolkit, make this decision later:
2057 dnl use the toolkit if we have gtk, or X11R5 or newer.
2058       * ) USE_X_TOOLKIT=maybe ;;
2059     esac
2060   ;;
2061   nextstep )
2062     term_header=nsterm.h
2063   ;;
2064   w32 )
2065     term_header=w32term.h
2066   ;;
2067 esac
2068
2069 if test "$window_system" = none && test "X$with_x" != "Xno"; then
2070    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
2071    if test "$HAVE_XSERVER" = true ||
2072       test -n "$DISPLAY" ||
2073       {
2074         for emacs_libX11 in /usr/lib/libX11.*; do break; done
2075         test "$emacs_libX11" != '/usr/lib/libX11.*'
2076       }
2077    then
2078         AC_MSG_ERROR([You seem to be running X, but no X development libraries
2079 were found.  You should install the relevant development files for X
2080 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2081 sure you have development files for image handling, i.e.
2082 tiff, gif, jpeg, png and xpm.
2083 If you are sure you want Emacs compiled without X window support, pass
2084   --without-x
2085 to configure.])
2086    fi
2087 fi
2088
2089 # Does the opsystem file prohibit the use of the GNU malloc?
2090 # Assume not, until told otherwise.
2091 GNU_MALLOC=yes
2092
2093 AC_CACHE_CHECK(
2094   [whether malloc is Doug Lea style],
2095   [emacs_cv_var_doug_lea_malloc],
2096   [emacs_cv_var_doug_lea_malloc=no
2097    dnl Hooks do not work with address sanitization.
2098    if test "$emacs_cv_sanitize_address" != yes; then
2099      AC_LINK_IFELSE(
2100        [AC_LANG_PROGRAM(
2101           [[#include <malloc.h>
2102             static void hook (void) {}]],
2103           [[malloc_set_state (malloc_get_state ());
2104             __after_morecore_hook = hook;
2105             __malloc_initialize_hook = hook;]])],
2106        [emacs_cv_var_doug_lea_malloc=yes])])
2107    fi
2108 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2109
2110 system_malloc=$emacs_cv_sanitize_address
2111
2112 hybrid_malloc=
2113
2114 case "$opsys" in
2115   ## darwin ld insists on the use of malloc routines in the System framework.
2116   darwin | mingw32 | nacl | sol2-10) system_malloc=yes ;;
2117   cygwin) hybrid_malloc=yes;;
2118 esac
2119
2120 GMALLOC_OBJ=
2121 if test "${system_malloc}" = "yes"; then
2122   AC_DEFINE([SYSTEM_MALLOC], 1,
2123     [Define to 1 to use the system memory allocator, even if it is not
2124      Doug Lea style.])
2125   GNU_MALLOC=no
2126   GNU_MALLOC_reason="
2127     (The GNU allocators don't work with this system configuration.)"
2128   VMLIMIT_OBJ=
2129 elif test "$hybrid_malloc" = yes; then
2130   AC_DEFINE(HYBRID_MALLOC, 1,
2131     [Define to use gmalloc before dumping and the system malloc after.])
2132   GNU_MALLOC=
2133   GNU_MALLOC_reason="only before dumping"
2134   GMALLOC_OBJ=gmalloc.o
2135   VMLIMIT_OBJ=
2136 else
2137   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2138   VMLIMIT_OBJ=vm-limit.o
2139
2140   AC_CHECK_HEADERS([sys/vlimit.h])
2141   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2142     [AC_LINK_IFELSE(
2143        [AC_LANG_PROGRAM(
2144          [[extern char data_start[]; char ch;]],
2145          [[return data_start < &ch;]])],
2146        [emacs_cv_data_start=yes],
2147        [emacs_cv_data_start=no])])
2148   if test $emacs_cv_data_start = yes; then
2149     AC_DEFINE([HAVE_DATA_START], 1,
2150       [Define to 1 if data_start is the address of the start
2151        of the main data segment.])
2152   fi
2153 fi
2154 AC_SUBST(GMALLOC_OBJ)
2155 AC_SUBST(VMLIMIT_OBJ)
2156
2157 if test "$doug_lea_malloc" = "yes" ; then
2158   if test "$GNU_MALLOC" = yes ; then
2159     GNU_MALLOC_reason="
2160       (Using Doug Lea's new malloc from the GNU C Library.)"
2161   fi
2162   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2163     [Define to 1 if the system memory allocator is Doug Lea style,
2164      with malloc hooks and malloc_set_state.])
2165
2166   ## Use mmap directly for allocating larger buffers.
2167   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2168   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2169   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2170   case "$opsys" in
2171     mingw32|gnu*) REL_ALLOC=no ;;
2172   esac
2173 fi
2174
2175 if test x"${REL_ALLOC}" = x; then
2176   REL_ALLOC=${GNU_MALLOC}
2177 fi
2178
2179 use_mmap_for_buffers=no
2180 case "$opsys" in
2181   cygwin|mingw32|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
2182 esac
2183
2184 AC_FUNC_MMAP
2185 if test $use_mmap_for_buffers = yes; then
2186   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2187   REL_ALLOC=no
2188 fi
2189
2190 LIBS="$LIBS_SYSTEM $LIBS"
2191
2192 dnl FIXME replace main with a function we actually want from this library.
2193 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2194
2195 dnl Check for C11 threads.
2196 AC_CHECK_HEADERS_ONCE(threads.h)
2197
2198 dnl Check for the POSIX thread library.
2199 LIB_PTHREAD=
2200 AC_CHECK_HEADERS_ONCE(pthread.h)
2201 if test "$ac_cv_header_pthread_h" && test "$opsys" != "mingw32"; then
2202   AC_CACHE_CHECK([for pthread library],
2203     [emacs_cv_pthread_lib],
2204     [emacs_cv_pthread_lib=no
2205      OLD_CPPFLAGS=$CPPFLAGS
2206      OLD_LIBS=$LIBS
2207      for emacs_pthread_lib in 'none needed' -lpthread; do
2208        case $emacs_pthread_lib in
2209          -*) LIBS="$OLD_LIBS $emacs_pthread_lib";;
2210        esac
2211        AC_LINK_IFELSE(
2212          [AC_LANG_PROGRAM(
2213             [[#include <pthread.h>
2214               #include <signal.h>
2215               sigset_t old_mask, new_mask;
2216               void noop (void) {}]],
2217             [[pthread_t th = pthread_self ();
2218               int status = 0;
2219               status += pthread_create (&th, 0, 0, 0);
2220               status += pthread_sigmask (SIG_BLOCK, &new_mask, &old_mask);
2221               status += pthread_kill (th, 0);
2222               #if ! (defined SYSTEM_MALLOC || defined HYBRID_MALLOC \
2223                      || defined DOUG_LEA_MALLOC)
2224               /* Test for pthread_atfork only if gmalloc uses it,
2225                  as older-style hosts like MirBSD 10 lack it.  */
2226               status += pthread_atfork (noop, noop, noop);
2227               #endif
2228               return status;]])],
2229          [emacs_cv_pthread_lib=$emacs_pthread_lib])
2230        LIBS=$OLD_LIBS
2231        if test "$emacs_cv_pthread_lib" != no; then
2232          break
2233        fi
2234      done
2235      CPPFLAGS=$OLD_CPPFLAGS])
2236   if test "$emacs_cv_pthread_lib" != no; then
2237     AC_DEFINE([HAVE_PTHREAD], 1, [Define to 1 if you have POSIX threads.])
2238     case $emacs_cv_pthread_lib in
2239       -*) LIB_PTHREAD=$emacs_cv_pthread_lib;;
2240     esac
2241     ac_cv_func_pthread_sigmask=yes
2242     # Some systems optimize for single-threaded programs by default, and
2243     # need special flags to disable these optimizations. For example, the
2244     # definition of 'errno' in <errno.h>.
2245     case $opsys in
2246       hpux* | sol*)
2247         AC_DEFINE([_REENTRANT], 1,
2248           [Define to 1 if your system requires this in multithreaded code.]);;
2249       aix4-2)
2250         AC_DEFINE([_THREAD_SAFE], 1,
2251           [Define to 1 if your system requires this in multithreaded code.]);;
2252     esac
2253   fi
2254 fi
2255 AC_SUBST([LIB_PTHREAD])
2256
2257 dnl Check for need for bigtoc support on IBM AIX
2258
2259 case ${host_os} in
2260 aix*)
2261   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2262     case $GCC in
2263     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2264     *) gdb_cv_bigtoc=-bbigtoc ;;
2265     esac
2266
2267     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2268     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2269   ])
2270   ;;
2271 esac
2272
2273 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2274 # is for the tests that follow.  We set them back later on.
2275
2276 REAL_CFLAGS="$CFLAGS"
2277 REAL_CPPFLAGS="$CPPFLAGS"
2278 REAL_LIBS="$LIBS"
2279
2280 if test "${HAVE_X11}" = "yes"; then
2281   DEFS="$C_SWITCH_X_SITE $DEFS"
2282   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2283   LIBS="-lX11 $LIBS"
2284   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2285   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2286
2287   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2288   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2289   # but it's more convenient here to set LD_RUN_PATH since this
2290   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2291   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2292     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2293     export LD_RUN_PATH
2294   fi
2295
2296   if test "${opsys}" = "gnu-linux"; then
2297     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2298     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2299      [[XOpenDisplay ("foo");]])],
2300      [xgnu_linux_first_failure=no],
2301      [xgnu_linux_first_failure=yes])
2302     if test "${xgnu_linux_first_failure}" = "yes"; then
2303       OLD_CPPFLAGS="$CPPFLAGS"
2304       OLD_LIBS="$LIBS"
2305       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2306       LIBS="$LIBS -b i486-linuxaout"
2307       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2308        [[XOpenDisplay ("foo");]])],
2309        [xgnu_linux_second_failure=no],
2310        [xgnu_linux_second_failure=yes])
2311       if test "${xgnu_linux_second_failure}" = "yes"; then
2312         # If we get the same failure with -b, there is no use adding -b.
2313         # So leave it out.  This plays safe.
2314         AC_MSG_RESULT(no)
2315       else
2316         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2317         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2318         AC_MSG_RESULT(yes)
2319       fi
2320       CPPFLAGS=$OLD_CPPFLAGS
2321       LIBS=$OLD_LIBS
2322     else
2323       AC_MSG_RESULT(no)
2324     fi
2325   fi
2326
2327   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2328   # header files included from there.
2329   AC_MSG_CHECKING(for Xkb)
2330   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2331 #include <X11/XKBlib.h>]],
2332         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2333         emacs_xkb=yes, emacs_xkb=no)
2334   AC_MSG_RESULT($emacs_xkb)
2335   if test $emacs_xkb = yes; then
2336     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2337   fi
2338
2339   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2340 XScreenNumberOfScreen)
2341 fi
2342
2343 if test "${window_system}" = "x11"; then
2344   AC_MSG_CHECKING(X11 version 6)
2345   AC_CACHE_VAL(emacs_cv_x11_version_6,
2346   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2347 [[#if XlibSpecificationRelease < 6
2348 fail;
2349 #endif
2350 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2351   if test $emacs_cv_x11_version_6 = yes; then
2352     AC_MSG_RESULT(6 or newer)
2353     AC_DEFINE(HAVE_X11R6, 1,
2354               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2355     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2356     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2357     ## XIM support.
2358     case "$opsys" in
2359       sol2-*) : ;;
2360       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2361            [Define if you have usable X11R6-style XIM support.])
2362          ;;
2363     esac
2364   else
2365     AC_MSG_RESULT(before 6)
2366   fi
2367 fi
2368
2369
2370 ### Use -lrsvg-2 if available, unless '--with-rsvg=no' is specified.
2371 HAVE_RSVG=no
2372 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2373   if test "${with_rsvg}" != "no"; then
2374     RSVG_REQUIRED=2.11.0
2375     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2376
2377     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2378     AC_SUBST(RSVG_CFLAGS)
2379     AC_SUBST(RSVG_LIBS)
2380
2381     if test $HAVE_RSVG = yes; then
2382       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2383       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2384       # Windows loads librsvg dynamically
2385       if test "${opsys}" = "mingw32"; then
2386         RSVG_LIBS=
2387       fi
2388     fi
2389   fi
2390 fi
2391
2392 HAVE_IMAGEMAGICK=no
2393 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2394   if test "${with_imagemagick}" != "no"; then
2395     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2396     ## 6.8.2 makes Emacs crash; see Bug#13867.
2397     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2398     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2399     AC_SUBST(IMAGEMAGICK_CFLAGS)
2400     AC_SUBST(IMAGEMAGICK_LIBS)
2401
2402     if test $HAVE_IMAGEMAGICK = yes; then
2403       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2404       OLD_CFLAGS=$CFLAGS
2405       OLD_LIBS=$LIBS
2406       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2407       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2408       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2409       CFLAGS=$OLD_CFLAGS
2410       LIBS=$OLD_LIBS
2411     fi
2412   fi
2413 fi
2414
2415
2416 HAVE_GTK=no
2417 GTK_OBJ=
2418 gtk_term_header=$term_header
2419 check_gtk2=no
2420 gtk3_pkg_errors=
2421 if test "${opsys}" != "mingw32"; then
2422   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2423     GLIB_REQUIRED=2.28
2424     GTK_REQUIRED=3.0
2425     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2426
2427     dnl Checks for libraries.
2428     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2429       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2430     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2431        AC_MSG_ERROR($GTK_PKG_ERRORS)
2432     fi
2433     if test "$pkg_check_gtk" = "yes"; then
2434        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2435        GTK_OBJ=emacsgtkfixed.o
2436        gtk_term_header=gtkutil.h
2437        USE_GTK_TOOLKIT="GTK3"
2438        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2439          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2440            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2441          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2442            [Define to 1 to disable Glib deprecation warnings.])
2443        fi
2444     else
2445        check_gtk2=yes
2446        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2447     fi
2448   fi
2449
2450   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2451     GLIB_REQUIRED=2.10
2452     GTK_REQUIRED=2.10
2453     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2454
2455     dnl Checks for libraries.
2456     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2457       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2458     if test "$pkg_check_gtk" = "no" &&
2459        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2460     then
2461       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2462     fi
2463     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2464   fi
2465 fi
2466
2467 OLD_CFLAGS=$CFLAGS
2468 OLD_LIBS=$LIBS
2469
2470 if test x"$pkg_check_gtk" = xyes; then
2471
2472   AC_SUBST(GTK_LIBS)
2473   CFLAGS="$CFLAGS $GTK_CFLAGS"
2474   LIBS="$GTK_LIBS $LIBS"
2475   dnl Try to compile a simple GTK program.
2476   AC_MSG_CHECKING([whether GTK compiles])
2477   GTK_COMPILES=no
2478   AC_LINK_IFELSE(
2479     [AC_LANG_PROGRAM(
2480        [[/* Check the Gtk and Glib APIs.  */
2481          #include <gtk/gtk.h>
2482          #include <glib-object.h>
2483          static void
2484          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2485          {}
2486        ]],
2487        [[
2488          GtkSettings *gs = 0;
2489          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2490             strict C prohibits this.  Use gtk_main_iteration to test that the
2491             libraries are there.  */
2492          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2493                                     0, 0, 0, G_CALLBACK (callback), 0))
2494            gtk_main_iteration ();
2495        ]])],
2496     [GTK_COMPILES=yes])
2497   AC_MSG_RESULT([$GTK_COMPILES])
2498   if test "${GTK_COMPILES}" != "yes"; then
2499     GTK_OBJ=
2500     if test "$USE_X_TOOLKIT" != "maybe"; then
2501       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2502     fi
2503   else
2504     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2505     HAVE_GTK=yes
2506     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2507     GTK_OBJ="gtkutil.o $GTK_OBJ"
2508     term_header=$gtk_term_header
2509     USE_X_TOOLKIT=none
2510     AC_MSG_WARN([[Your version of Gtk+ will have problems with
2511        closing open displays.  This is no problem if you just use
2512        one display, but if you use more than one and close one of them
2513        Emacs may crash.
2514        See http://bugzilla.gnome.org/show_bug.cgi?id=85715]])
2515     sleep 3
2516   fi
2517
2518 fi
2519 AC_SUBST(GTK_OBJ)
2520
2521
2522 if test "${HAVE_GTK}" = "yes"; then
2523
2524   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2525   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2526   if test "$with_toolkit_scroll_bars" != no; then
2527     with_toolkit_scroll_bars=yes
2528   fi
2529
2530   dnl  Check if we have the old file selection dialog declared and
2531   dnl  in the link library.  In 2.x it may be in the library,
2532   dnl  but not declared if deprecated featured has been selected out.
2533   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2534   HAVE_GTK_FILE_SELECTION=no
2535   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2536                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2537 #include <gtk/gtk.h>])
2538   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2539     AC_CHECK_FUNCS(gtk_file_selection_new)
2540   fi
2541
2542   dnl Same as above for gtk_handle_box.
2543   HAVE_GTK_HANDLE_BOX=no
2544   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2545                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2546 #include <gtk/gtk.h>])
2547   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2548     AC_CHECK_FUNCS(gtk_handle_box_new)
2549   fi
2550
2551   dnl Same as above for gtk_tearoff_menu_item.
2552   HAVE_GTK_TEAROFF_MENU_ITEM=no
2553   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2554                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2555 #include <gtk/gtk.h>])
2556   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2557     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2558   fi
2559
2560   dnl Check for functions introduced in 2.14 and later.
2561   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2562                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2563                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2564                  gtk_orientable_set_orientation \
2565                  gtk_window_set_has_resize_grip)
2566
2567  term_header=gtkutil.h
2568 fi
2569
2570 CFLAGS=$OLD_CFLAGS
2571 LIBS=$OLD_LIBS
2572
2573 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2574 dnl other platforms.
2575 HAVE_DBUS=no
2576 DBUS_OBJ=
2577 if test "${with_dbus}" = "yes"; then
2578    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2579    if test "$HAVE_DBUS" = yes; then
2580      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2581      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2582      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2583      dnl D-Bus 1.5.12.
2584      OLD_LIBS=$LIBS
2585      LIBS="$LIBS $DBUS_LIBS"
2586      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2587                     dbus_type_is_valid \
2588                     dbus_validate_bus_name \
2589                     dbus_validate_path \
2590                     dbus_validate_interface \
2591                     dbus_validate_member)
2592      LIBS=$OLD_LIBS
2593      DBUS_OBJ=dbusbind.o
2594    fi
2595 fi
2596 AC_SUBST(DBUS_CFLAGS)
2597 AC_SUBST(DBUS_LIBS)
2598 AC_SUBST(DBUS_OBJ)
2599
2600 dnl GSettings has been tested under GNU/Linux only.
2601 HAVE_GSETTINGS=no
2602 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2603    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2604    if test "$HAVE_GSETTINGS" = "yes"; then
2605       old_CFLAGS=$CFLAGS
2606       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2607       old_LIBS=$LIBS
2608       LIBS="$LIBS $GSETTINGS_LIBS"
2609       AC_MSG_CHECKING([whether GSettings is in gio])
2610       AC_LINK_IFELSE(
2611          [AC_LANG_PROGRAM(
2612              [[/* Check that gsettings really is present.  */
2613              #include <glib-object.h>
2614              #include <gio/gio.h>
2615              ]],
2616              [[
2617                GSettings *settings;
2618                GVariant *val = g_settings_get_value (settings, "");
2619              ]])],
2620          [], HAVE_GSETTINGS=no)
2621       AC_MSG_RESULT([$HAVE_GSETTINGS])
2622
2623       if test "$HAVE_GSETTINGS" = "yes"; then
2624         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2625         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2626         SETTINGS_LIBS="$GSETTINGS_LIBS"
2627       fi
2628       CFLAGS=$old_CFLAGS
2629       LIBS=$old_LIBS
2630    fi
2631 fi
2632
2633 dnl GConf has been tested under GNU/Linux only.
2634 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2635 HAVE_GCONF=no
2636 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2637    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2638    if test "$HAVE_GCONF" = yes; then
2639       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2640       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2641       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2642       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2643    fi
2644 fi
2645
2646 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2647     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2648     if test "$HAVE_GOBJECT" = "yes"; then
2649        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2650        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2651     fi
2652     SAVE_CFLAGS="$CFLAGS"
2653     SAVE_LIBS="$LIBS"
2654     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2655     LIBS="$SETTINGS_LIBS $LIBS"
2656     CFLAGS="$SAVE_CFLAGS"
2657     LIBS="$SAVE_LIBS"
2658 fi
2659 AC_SUBST(SETTINGS_CFLAGS)
2660 AC_SUBST(SETTINGS_LIBS)
2661
2662
2663 dnl SELinux is available for GNU/Linux only.
2664 HAVE_LIBSELINUX=no
2665 LIBSELINUX_LIBS=
2666 if test "${with_selinux}" = "yes"; then
2667    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2668    if test "$HAVE_LIBSELINUX" = yes; then
2669       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2670       LIBSELINUX_LIBS=-lselinux
2671    fi
2672 fi
2673 AC_SUBST(LIBSELINUX_LIBS)
2674
2675 HAVE_GNUTLS=no
2676 if test "${with_gnutls}" = "yes" ; then
2677   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2678     [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2679   if test "${HAVE_GNUTLS}" = "yes"; then
2680     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2681     EMACS_CHECK_MODULES([LIBGNUTLS3], [gnutls >= 3.0.0],
2682       [AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])], [])
2683   fi
2684
2685   # Windows loads GnuTLS dynamically
2686   if test "${opsys}" = "mingw32"; then
2687     LIBGNUTLS_LIBS=
2688   fi
2689 fi
2690
2691 AC_SUBST(LIBGNUTLS_LIBS)
2692 AC_SUBST(LIBGNUTLS_CFLAGS)
2693
2694 NOTIFY_OBJ=
2695 NOTIFY_SUMMARY=no
2696
2697 dnl FIXME?  Don't auto-detect on NS, but do allow someone to specify
2698 dnl a particular library.  This doesn't make much sense?
2699 if test "${HAVE_NS}" = yes && test ${with_file_notification} = yes; then
2700   with_file_notification=no
2701 fi
2702
2703 dnl MS Windows native file monitor is available for mingw32 only.
2704 case $with_file_notification,$opsys in
2705   w32,cygwin)
2706     AC_MSG_ERROR(['--with-file-notification=w32' was specified, but
2707     this is only supported on MS-Windows native and MinGW32 builds.
2708     Consider using gfile instead.])
2709     ;;
2710   w32,* | yes,mingw32)
2711     AC_CHECK_HEADER(windows.h)
2712     if test "$ac_cv_header_windows_h" = yes ; then
2713        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2714        NOTIFY_OBJ=w32notify.o
2715        NOTIFY_SUMMARY="yes (w32)"
2716     fi ;;
2717 esac
2718
2719 dnl inotify is available only on GNU/Linux.
2720 case $with_file_notification,$NOTIFY_OBJ in
2721   inotify, | yes,)
2722     AC_CHECK_HEADER(sys/inotify.h)
2723     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2724         AC_CHECK_FUNC(inotify_init1)
2725         if test "$ac_cv_func_inotify_init1" = yes; then
2726           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2727           NOTIFY_OBJ=inotify.o
2728           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2729        fi
2730     fi ;;
2731 esac
2732
2733 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2734 dnl has been added in glib 2.24.  It has been tested under
2735 dnl GNU/Linux only.
2736 case $with_file_notification,$NOTIFY_OBJ in
2737   gfile,* | yes,)
2738     EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2739     if test "$HAVE_GFILENOTIFY" = "yes"; then
2740        AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2741        NOTIFY_OBJ=gfilenotify.o
2742        NOTIFY_SUMMARY="yes -lgio (gfile)"
2743     fi ;;
2744 esac
2745
2746 case $with_file_notification,$NOTIFY_OBJ in
2747   yes,* | no,* | *,?*) ;;
2748   *) AC_MSG_ERROR([File notification '$with_file_notification' requested but requirements not found.]) ;;
2749 esac
2750
2751 if test -n "$NOTIFY_OBJ"; then
2752    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2753 fi
2754 AC_SUBST(NOTIFY_OBJ)
2755 AC_SUBST(GFILENOTIFY_CFLAGS)
2756 AC_SUBST(GFILENOTIFY_LIBS)
2757
2758 dnl Do not put whitespace before the #include statements below.
2759 dnl Older compilers (eg sunos4 cc) choke on it.
2760 HAVE_XAW3D=no
2761 LUCID_LIBW=
2762 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2763   if test "$with_xaw3d" != no; then
2764     AC_CACHE_VAL(emacs_cv_xaw3d,
2765     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2766 #include <X11/Intrinsic.h>
2767 #include <X11/Xaw3d/Simple.h>]],
2768       [[]])],
2769       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2770                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2771       emacs_cv_xaw3d=no)])
2772   else
2773     emacs_cv_xaw3d=no
2774   fi
2775   if test $emacs_cv_xaw3d = yes; then
2776     AC_MSG_CHECKING(for xaw3d)
2777     AC_MSG_RESULT([yes; using Lucid toolkit])
2778     USE_X_TOOLKIT=LUCID
2779     HAVE_XAW3D=yes
2780     LUCID_LIBW=-lXaw3d
2781     AC_DEFINE(HAVE_XAW3D, 1,
2782               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2783   else
2784     AC_MSG_CHECKING(for xaw3d)
2785     AC_MSG_RESULT(no)
2786     AC_MSG_CHECKING(for libXaw)
2787     AC_CACHE_VAL(emacs_cv_xaw,
2788     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2789 #include <X11/Intrinsic.h>
2790 #include <X11/Xaw/Simple.h>]],
2791       [[]])],
2792       emacs_cv_xaw=yes,
2793       emacs_cv_xaw=no)])
2794     if test $emacs_cv_xaw = yes; then
2795       AC_MSG_RESULT([yes; using Lucid toolkit])
2796       USE_X_TOOLKIT=LUCID
2797       LUCID_LIBW=-lXaw
2798     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2799       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2800     else
2801       AC_MSG_ERROR([No X toolkit could be found.
2802 If you are sure you want Emacs compiled without an X toolkit, pass
2803   --with-x-toolkit=no
2804 to configure.  Otherwise, install the development libraries for the toolkit
2805 that you want to use (e.g. Gtk+) and re-run configure.])
2806     fi
2807   fi
2808 fi
2809
2810 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2811
2812 LIBXTR6=
2813 LIBXMU=
2814 if test "${USE_X_TOOLKIT}" != "none"; then
2815   AC_MSG_CHECKING(X11 toolkit version)
2816   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2817   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2818 [[#if XtSpecificationRelease < 6
2819 fail;
2820 #endif
2821 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2822   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2823   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2824     AC_MSG_RESULT(6 or newer)
2825     AC_DEFINE(HAVE_X11XTR6, 1,
2826               [Define to 1 if you have the X11R6 or newer version of Xt.])
2827     LIBXTR6="-lSM -lICE"
2828     case "$opsys" in
2829       ## Use libw.a along with X11R6 Xt.
2830       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2831     esac
2832   else
2833     AC_MSG_RESULT(before 6)
2834   fi
2835
2836 dnl If using toolkit, check whether libXmu.a exists.
2837 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2838   OLDLIBS="$LIBS"
2839   if test x$HAVE_X11XTR6 = xyes; then
2840     OTHERLIBS='-lXt -lSM -lICE'
2841   else
2842     OTHERLIBS='-lXt'
2843   fi
2844   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2845   if test "X$LIBS" != "X$OLDLIBS"; then
2846     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2847   fi
2848   LIBS=$OLDLIBS
2849   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2850 fi
2851 AC_SUBST(LIBXTR6)
2852 AC_SUBST(LIBXMU)
2853
2854 LIBXP=
2855 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2856   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2857   if test -d /usr/include/openmotif; then
2858     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2859     emacs_cv_openmotif=yes
2860     case "$canonical" in
2861       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2862       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2863       ;;
2864       *)
2865       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2866     esac
2867   else
2868     emacs_cv_openmotif=no
2869   fi
2870   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2871   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2872     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2873 int x = 5;
2874 #else
2875 Motif version prior to 2.1.
2876 #endif]])],
2877     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2878   if test $emacs_cv_motif_version_2_1 = yes; then
2879     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2880     if test x$emacs_cv_openmotif = xyes; then
2881       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2882     fi
2883   else
2884     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2885     # We put this in CFLAGS temporarily to precede other -I options
2886     # that might be in CFLAGS temporarily.
2887     # We put this in CPPFLAGS where it precedes the other -I options.
2888     OLD_CPPFLAGS=$CPPFLAGS
2889     OLD_CFLAGS=$CFLAGS
2890     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2891     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2892     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2893       [[int x = 5;]])],
2894       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2895     if test $emacs_cv_lesstif = yes; then
2896       # Make sure this -I option remains in CPPFLAGS after it is set
2897       # back to REAL_CPPFLAGS.
2898       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2899       # have those other -I options anyway.  Ultimately, having this
2900       # directory ultimately in CPPFLAGS will be enough.
2901       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2902       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2903     else
2904       CFLAGS=$OLD_CFLAGS
2905       CPPFLAGS=$OLD_CPPFLAGS
2906     fi
2907   fi
2908   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2909     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2910 fi
2911
2912 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2913 dnl using Motif or Xaw3d is available, and unless
2914 dnl --with-toolkit-scroll-bars=no was specified.
2915
2916 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2917             [Define to 1 if we should use toolkit scroll bars.])dnl
2918 USE_TOOLKIT_SCROLL_BARS=no
2919 if test "${with_toolkit_scroll_bars}" != "no"; then
2920   if test "${USE_X_TOOLKIT}" != "none"; then
2921     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2922       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2923       HAVE_XAW3D=no
2924       USE_TOOLKIT_SCROLL_BARS=yes
2925     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2926       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2927       USE_TOOLKIT_SCROLL_BARS=yes
2928     fi
2929   elif test "${HAVE_GTK}" = "yes"; then
2930     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2931     USE_TOOLKIT_SCROLL_BARS=yes
2932   elif test "${HAVE_NS}" = "yes"; then
2933     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2934     USE_TOOLKIT_SCROLL_BARS=yes
2935   elif test "${HAVE_W32}" = "yes"; then
2936     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2937     USE_TOOLKIT_SCROLL_BARS=yes
2938   fi
2939 fi
2940
2941 dnl See if XIM is available.
2942 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2943           #include <X11/Xlib.h>
2944           #include <X11/Xresource.h>]],
2945          [[XIMProc  callback;]])],
2946          [HAVE_XIM=yes
2947          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2948          HAVE_XIM=no)
2949
2950 dnl '--with-xim' now controls only the initial value of use_xim at run time.
2951
2952 if test "${with_xim}" != "no"; then
2953   AC_DEFINE(USE_XIM, 1,
2954             [Define to 1 if we should use XIM, if it is available.])
2955 fi
2956
2957
2958 if test "${HAVE_XIM}" != "no"; then
2959   late_CFLAGS=$CFLAGS
2960   if test "$GCC" = yes; then
2961     CFLAGS="$CFLAGS --pedantic-errors"
2962   fi
2963   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2964 #include <X11/Xlib.h>
2965 #include <X11/Xresource.h>]],
2966 [[Display *display;
2967 XrmDatabase db;
2968 char *res_name;
2969 char *res_class;
2970 XIMProc  callback;
2971 XPointer *client_data;
2972 #ifndef __GNUC__
2973 /* If we're not using GCC, it's probably not XFree86, and this is
2974    probably right, but we can't use something like --pedantic-errors.  */
2975 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2976                                            char*, XIMProc, XPointer*);
2977 #endif
2978 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2979    client_data);]])],
2980     [emacs_cv_arg6_star=yes])
2981   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2982          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2983 either XPointer or XPointer*.])dnl
2984   if test "$emacs_cv_arg6_star" = yes; then
2985     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2986   else
2987     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2988   fi
2989   CFLAGS=$late_CFLAGS
2990 fi
2991
2992 ### Start of font-backend (under any platform) section.
2993 # (nothing here yet -- this is a placeholder)
2994 ### End of font-backend (under any platform) section.
2995
2996 ### Start of font-backend (under X11) section.
2997 if test "${HAVE_X11}" = "yes"; then
2998     ## Use -lXft if available, unless '--with-xft=no'.
2999     HAVE_XFT=maybe
3000     if test "x${with_x}" = "xno"; then
3001       with_xft="no";
3002     fi
3003
3004     if test "$with_xft" != no; then
3005       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
3006       with_xft=$HAVE_FONTCONFIG
3007     fi
3008
3009     if test "x${with_xft}" != "xno"; then
3010
3011       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
3012       ## Because xftfont.c uses XRenderQueryExtension, we also
3013       ## need to link to -lXrender.
3014       HAVE_XRENDER=no
3015       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
3016       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
3017         OLD_CPPFLAGS="$CPPFLAGS"
3018         OLD_CFLAGS="$CFLAGS"
3019         OLD_LIBS="$LIBS"
3020         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
3021         CFLAGS="$CFLAGS $XFT_CFLAGS"
3022         XFT_LIBS="-lXrender $XFT_LIBS"
3023         LIBS="$XFT_LIBS $LIBS"
3024         AC_CHECK_HEADER(X11/Xft/Xft.h,
3025           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
3026           [[#include <X11/X.h>]])
3027
3028         if test "${HAVE_XFT}" = "yes"; then
3029           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
3030             AC_SUBST(XFT_LIBS)
3031           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
3032         fi                        # "${HAVE_XFT}" = "yes"
3033         CPPFLAGS=$OLD_CPPFLAGS
3034         CFLAGS=$OLD_CFLAGS
3035         LIBS=$OLD_LIBS
3036       fi                          # "$HAVE_XFT" != no
3037     fi                            # "x${with_xft}" != "xno"
3038
3039     ## We used to allow building with FreeType and without Xft.
3040     ## However, the ftx font backend driver is not in good shape.
3041     if test "$HAVE_XFT" != "yes"; then
3042        dnl For the "Does Emacs use" message at the end.
3043        HAVE_XFT=no
3044        HAVE_FREETYPE=no
3045     else
3046        dnl Strict linkers fail with
3047        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
3048        dnl if -lfreetype is not specified.
3049        dnl The following is needed to set FREETYPE_LIBS.
3050        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
3051
3052        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
3053     fi
3054
3055     HAVE_LIBOTF=no
3056     if test "${HAVE_FREETYPE}" = "yes"; then
3057       AC_DEFINE(HAVE_FREETYPE, 1,
3058                 [Define to 1 if using the freetype and fontconfig libraries.])
3059       if test "${with_libotf}" != "no"; then
3060         EMACS_CHECK_MODULES([LIBOTF], [libotf])
3061         if test "$HAVE_LIBOTF" = "yes"; then
3062           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
3063           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
3064                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
3065                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
3066           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
3067             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
3068                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
3069           fi
3070         fi
3071       fi
3072     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
3073     dnl Does the new font backend require it, or can it work without it?
3074     fi
3075
3076     HAVE_M17N_FLT=no
3077     if test "${HAVE_LIBOTF}" = yes; then
3078       if test "${with_m17n_flt}" != "no"; then
3079         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
3080         if test "$HAVE_M17N_FLT" = "yes"; then
3081           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
3082         fi
3083       fi
3084     fi
3085 else
3086     HAVE_XFT=no
3087     HAVE_FREETYPE=no
3088     HAVE_LIBOTF=no
3089     HAVE_M17N_FLT=no
3090 fi
3091
3092 ### End of font-backend (under X11) section.
3093
3094 AC_SUBST(FREETYPE_CFLAGS)
3095 AC_SUBST(FREETYPE_LIBS)
3096 AC_SUBST(FONTCONFIG_CFLAGS)
3097 AC_SUBST(FONTCONFIG_LIBS)
3098 AC_SUBST(LIBOTF_CFLAGS)
3099 AC_SUBST(LIBOTF_LIBS)
3100 AC_SUBST(M17N_FLT_CFLAGS)
3101 AC_SUBST(M17N_FLT_LIBS)
3102
3103 USE_CAIRO=no
3104 if test "${HAVE_X11}" = "yes"; then
3105   if test "${with_cairo}" != "no"; then
3106     CAIRO_REQUIRED=1.12.0
3107     CAIRO_MODULE="cairo >= $CAIRO_REQUIRED"
3108     PKG_CHECK_MODULES(CAIRO, $CAIRO_MODULE, USE_CAIRO=yes, :)
3109     if test $USE_CAIRO = yes; then
3110       AC_DEFINE(USE_CAIRO, 1, [Define to 1 if using cairo.])
3111     else
3112       AC_MSG_ERROR([cairo requested but not found.])
3113     fi
3114
3115     CFLAGS="$CFLAGS $CAIRO_CFLAGS"
3116     LIBS="$LIBS $CAIRO_LIBS"
3117     AC_SUBST(CAIRO_CFLAGS)
3118     AC_SUBST(CAIRO_LIBS)
3119   fi
3120 fi
3121
3122 if test "${HAVE_X11}" = "yes"; then
3123   AC_CHECK_HEADER(X11/Xlib-xcb.h,
3124     AC_CHECK_LIB(xcb, xcb_translate_coordinates, HAVE_XCB=yes))
3125   if test "${HAVE_XCB}" = "yes"; then
3126     AC_CHECK_LIB(X11-xcb, XGetXCBConnection, HAVE_X11_XCB=yes)
3127     if test "${HAVE_X11_XCB}" = "yes"; then
3128       AC_DEFINE(USE_XCB, 1,
3129 [Define to 1 if you have the XCB library and X11-XCB library for mixed
3130    X11/XCB programming.])
3131       XCB_LIBS="-lX11-xcb -lxcb"
3132       AC_SUBST(XCB_LIBS)
3133     fi
3134   fi
3135 fi
3136
3137 ### Use -lXpm if available, unless '--with-xpm=no'.
3138 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
3139 ### In the Cygwin-w32 build, we need to use /usr/include/noX/X11/xpm.h
3140 ### rather than /usr/include/X11/xpm.h, so we set CPPFLAGS (and
3141 ### LDFLAGS) accordingly.
3142 HAVE_XPM=no
3143 LIBXPM=
3144 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3145   if test "${with_xpm}" != "no"; then
3146     SAVE_CPPFLAGS="$CPPFLAGS"
3147     SAVE_LDFLAGS="$LDFLAGS"
3148     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
3149     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3150     AC_CHECK_HEADER(X11/xpm.h,
3151       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3152     if test "${HAVE_XPM}" = "yes"; then
3153       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3154       AC_EGREP_CPP(no_return_alloc_pixels,
3155       [#include "X11/xpm.h"
3156 #ifndef XpmReturnAllocPixels
3157 no_return_alloc_pixels
3158 #endif
3159       ], HAVE_XPM=no, HAVE_XPM=yes)
3160
3161       if test "${HAVE_XPM}" = "yes"; then
3162         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3163         AC_MSG_RESULT(yes)
3164       else
3165         AC_MSG_RESULT(no)
3166         CPPFLAGS="$SAVE_CPPFLAGS"
3167         LDFLAGS="$SAVE_LDFLAGS"
3168       fi
3169     fi
3170   fi
3171
3172   if test "${HAVE_XPM}" = "yes"; then
3173     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3174     LIBXPM=-lXpm
3175   fi
3176 fi
3177
3178 if test "${HAVE_X11}" = "yes"; then
3179   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3180   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3181
3182   if test "${with_xpm}" != "no"; then
3183     AC_CHECK_HEADER(X11/xpm.h,
3184       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3185     if test "${HAVE_XPM}" = "yes"; then
3186       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3187       AC_EGREP_CPP(no_return_alloc_pixels,
3188       [#include "X11/xpm.h"
3189 #ifndef XpmReturnAllocPixels
3190 no_return_alloc_pixels
3191 #endif
3192       ], HAVE_XPM=no, HAVE_XPM=yes)
3193
3194       if test "${HAVE_XPM}" = "yes"; then
3195         AC_MSG_RESULT(yes)
3196       else
3197         AC_MSG_RESULT(no)
3198       fi
3199     fi
3200   fi
3201
3202   if test "${HAVE_XPM}" = "yes"; then
3203     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3204     LIBXPM=-lXpm
3205   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3206     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3207     LIBXPM=-lXpm
3208   fi
3209 fi
3210
3211 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3212 ### slightly different requirements wrt image libraries (it doesn't
3213 ### use -lXpm because it loads the xpm shared library dynamically at
3214 ### run time).
3215 if test "${opsys}" = "mingw32"; then
3216   if test "${with_xpm}" != "no"; then
3217     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3218 #define FOR_MSW 1])
3219   fi
3220
3221   if test "${HAVE_XPM}" = "yes"; then
3222     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3223   fi
3224 fi
3225
3226 AC_SUBST(LIBXPM)
3227
3228 ### Use -ljpeg if available, unless '--with-jpeg=no'.
3229 HAVE_JPEG=no
3230 LIBJPEG=
3231 if test "${with_jpeg}" != "no"; then
3232   AC_CACHE_CHECK([for jpeglib 6b or later],
3233     [emacs_cv_jpeglib],
3234     [OLD_LIBS=$LIBS
3235      for emacs_cv_jpeglib in yes -ljpeg no; do
3236        case $emacs_cv_jpeglib in
3237          yes) ;;
3238          no) break;;
3239          *) LIBS="$LIBS $emacs_cv_jpeglib";;
3240        esac
3241        AC_LINK_IFELSE(
3242          [AC_LANG_PROGRAM(
3243             [[#undef HAVE_STDLIB_H /* Avoid config.h/jpeglib.h collision.  */
3244               #include <stdio.h> /* jpeglib.h needs FILE and size_t.  */
3245               #include <jpeglib.h>
3246               #include <jerror.h>
3247               char verify[JPEG_LIB_VERSION < 62 ? -1 : 1];
3248               struct jpeg_decompress_struct cinfo;
3249             ]],
3250             [[
3251               jpeg_create_decompress (&cinfo);
3252               WARNMS (&cinfo, JWRN_JPEG_EOF);
3253               jpeg_destroy_decompress (&cinfo);
3254             ]])],
3255          [emacs_link_ok=yes],
3256          [emacs_link_ok=no])
3257        LIBS=$OLD_LIBS
3258        test $emacs_link_ok = yes && break
3259      done])
3260   if test "$emacs_cv_jpeglib" != no; then
3261     HAVE_JPEG=yes
3262     AC_DEFINE([HAVE_JPEG], 1,
3263       [Define to 1 if you have the jpeg library (typically -ljpeg).])
3264     ### mingw32 doesn't use -ljpeg, since it loads the library
3265     ### dynamically when needed, and doesn't want a run-time
3266     ### dependency on the jpeglib DLL.
3267     test "$emacs_cv_jpeglib" != yes && test "${opsys}" != "mingw32" \
3268     && LIBJPEG=$emacs_cv_jpeglib
3269   fi
3270 fi
3271 AC_SUBST(LIBJPEG)
3272
3273 HAVE_ZLIB=no
3274 LIBZ=
3275 if test "${with_zlib}" != "no"; then
3276   OLIBS=$LIBS
3277   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3278   LIBS=$OLIBS
3279   case $ac_cv_search_inflateEnd in
3280     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3281   esac
3282 fi
3283 if test "${HAVE_ZLIB}" = "yes"; then
3284   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3285   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3286   if test "${opsys}" = "mingw32"; then
3287      LIBZ=
3288   fi
3289 fi
3290 AC_SUBST(LIBZ)
3291
3292 ### Dynamic modules support
3293 LIBMODULES=
3294 HAVE_MODULES=no
3295 MODULES_OBJ=
3296 MODULES_SUFFIX=
3297 if test "${with_modules}" != "no"; then
3298   if test "$opsys" = "gnu-linux"; then
3299     LIBMODULES="-ldl"
3300     MODULES_SUFFIX=".so"
3301     HAVE_MODULES=yes
3302   elif test "$opsys" = "cygwin"; then
3303     MODULES_SUFFIX=".dll"
3304     HAVE_MODULES=yes
3305   elif test "$opsys" = "darwin"; then
3306     MODULES_SUFFIX=".so"
3307     HAVE_MODULES=yes
3308   elif test "$opsys" = "mingw32"; then
3309     MODULES_SUFFIX=".dll"
3310     HAVE_MODULES=yes
3311   else
3312     # BSD system have dlopen in the libc
3313     AC_CHECK_FUNC(dlopen, [MODULES_SUFFIX=".so"]
3314                           [HAVE_MODULES=yes], [])
3315   fi
3316
3317   if test "${HAVE_MODULES}" = no; then
3318     AC_MSG_ERROR([Dynamic modules are not supported on your system])
3319   fi
3320 fi
3321
3322 if test "${HAVE_MODULES}" = yes; then
3323    MODULES_OBJ="dynlib.o module.o"
3324    AC_DEFINE(HAVE_MODULES, 1, [Define to 1 if dynamic modules are enabled])
3325    AC_DEFINE_UNQUOTED(MODULES_SUFFIX, "$MODULES_SUFFIX", [System extension for dynamic libraries])
3326 fi
3327 AC_SUBST(MODULES_OBJ)
3328 AC_SUBST(LIBMODULES)
3329 AX_GCC_VAR_ATTRIBUTE(cleanup)
3330 AC_CHECK_FUNCS(dladdr)
3331
3332 ### Use -lpng if available, unless '--with-png=no'.
3333 HAVE_PNG=no
3334 LIBPNG=
3335 PNG_CFLAGS=
3336 if test "${NS_IMPL_COCOA}" = yes; then
3337   : # Nothing to do
3338 elif test "${with_png}" != no; then
3339   # mingw32 loads the library dynamically.
3340   if test "$opsys" = mingw32; then
3341     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3342   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3343     AC_MSG_CHECKING([for png])
3344     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3345     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3346       # libpng-config does not work; configure by hand.
3347       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3348       # in /usr/include/libpng.
3349       if test -r /usr/include/libpng/png.h &&
3350          test ! -r /usr/include/png.h; then
3351         png_cflags=-I/usr/include/libpng
3352       else
3353         png_cflags=
3354       fi
3355       png_libs='-lpng'
3356     }
3357     SAVE_CFLAGS=$CFLAGS
3358     SAVE_LIBS=$LIBS
3359     CFLAGS="$CFLAGS $png_cflags"
3360     LIBS="$png_libs -lz -lm $LIBS"
3361     AC_LINK_IFELSE(
3362       [AC_LANG_PROGRAM([[#include <png.h>]],
3363          [[return !png_get_channels (0, 0);]])],
3364       [HAVE_PNG=yes
3365        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3366        LIBPNG=$png_libs
3367        # $LIBPNG requires explicit -lz in some cases.
3368        # We don't know what those cases are, exactly, so play it safe and
3369        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3370        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3371          LIBPNG="$LIBPNG -lz"
3372        fi])
3373     CFLAGS=$SAVE_CFLAGS
3374     LIBS=$SAVE_LIBS
3375     AC_MSG_RESULT([$HAVE_PNG])
3376   fi
3377 fi
3378 if test $HAVE_PNG = yes; then
3379   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3380
3381   SAVE_CFLAGS=$CFLAGS
3382   CFLAGS="$CFLAGS $PNG_CFLAGS"
3383   AC_CHECK_DECL([png_longjmp],
3384     [],
3385     [AC_DEFINE([PNG_DEPSTRUCT], [],
3386        [Define to empty to suppress deprecation warnings when building
3387         with --enable-gcc-warnings and with libpng versions before 1.5,
3388         which lack png_longjmp.])],
3389     [[#include <png.h>
3390     ]])
3391   CFLAGS=$SAVE_CFLAGS
3392 fi
3393 AC_SUBST(LIBPNG)
3394 AC_SUBST(PNG_CFLAGS)
3395
3396 ### Use -ltiff if available, unless '--with-tiff=no'.
3397 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3398 HAVE_TIFF=no
3399 LIBTIFF=
3400 if test "${opsys}" = "mingw32"; then
3401   if test "${with_tiff}" != "no"; then
3402     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3403   fi
3404   if test "${HAVE_TIFF}" = "yes"; then
3405     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3406   fi
3407 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3408   if test "${with_tiff}" != "no"; then
3409     AC_CHECK_HEADER(tiffio.h,
3410       [tifflibs="-lz -lm"
3411       # At least one tiff package requires the jpeg library.
3412       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3413       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3414   fi
3415
3416   if test "${HAVE_TIFF}" = "yes"; then
3417     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3418     dnl FIXME -lz -lm, as per libpng?
3419     LIBTIFF=-ltiff
3420   fi
3421 fi
3422 AC_SUBST(LIBTIFF)
3423
3424 ### Use -lgif or -lungif if available, unless '--with-gif=no'.
3425 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3426 HAVE_GIF=no
3427 LIBGIF=
3428 if test "${opsys}" = "mingw32"; then
3429   if test "${with_gif}" != "no"; then
3430     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3431   fi
3432   if test "${HAVE_GIF}" = "yes"; then
3433     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3434   fi
3435 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3436         || test "${HAVE_W32}" = "yes"; then
3437   AC_CHECK_HEADER(gif_lib.h,
3438 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3439 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3440     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3441         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3442
3443   if test "$HAVE_GIF" = yes; then
3444     LIBGIF=-lgif
3445   elif test "$HAVE_GIF" = maybe; then
3446 # If gif_lib.h but no libgif, try libungif.
3447     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3448     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3449   fi
3450
3451   if test "${HAVE_GIF}" = "yes"; then
3452     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3453   fi
3454 fi
3455 AC_SUBST(LIBGIF)
3456
3457 dnl Check for required libraries.
3458 if test "${HAVE_X11}" = "yes"; then
3459   MISSING=""
3460   WITH_NO=""
3461   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3462     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3463   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3464     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3465   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3466     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3467   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3468     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3469   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3470     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3471
3472   if test "X${MISSING}" != X; then
3473     AC_MSG_ERROR([The following required libraries were not found:
3474     $MISSING
3475 Maybe some development libraries/packages are missing?
3476 If you don't want to link with them give
3477     $WITH_NO
3478 as options to configure])
3479   fi
3480 fi
3481
3482 ### Use -lgpm if available, unless '--with-gpm=no'.
3483 HAVE_GPM=no
3484 LIBGPM=
3485 if test "${with_gpm}" != "no"; then
3486   AC_CHECK_HEADER(gpm.h,
3487     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3488
3489   if test "${HAVE_GPM}" = "yes"; then
3490     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3491     LIBGPM=-lgpm
3492   fi
3493 fi
3494 AC_SUBST(LIBGPM)
3495
3496 dnl Check for malloc/malloc.h on darwin
3497 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3498
3499 GNUSTEP_CFLAGS=
3500 ### Use NeXTstep API to implement GUI.
3501 if test "${HAVE_NS}" = "yes"; then
3502   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3503   if test "${NS_IMPL_COCOA}" = "yes"; then
3504     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3505   fi
3506   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3507     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3508     if test $NS_GNUSTEP_CONFIG != yes; then
3509       # See also .m.o rule in src/Makefile.in.  */
3510       # FIXME: are all these flags really needed?  Document here why.  */
3511       GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3512       ## Extra CFLAGS applied to src/*.m files.
3513       GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3514     fi
3515   fi
3516   OTHER_FILES=ns-app
3517 fi
3518
3519 ### Use session management (-lSM -lICE) if available
3520 HAVE_X_SM=no
3521 LIBXSM=
3522 if test "${HAVE_X11}" = "yes"; then
3523   AC_CHECK_HEADER(X11/SM/SMlib.h,
3524     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3525
3526   if test "${HAVE_X_SM}" = "yes"; then
3527     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3528     LIBXSM="-lSM -lICE"
3529   fi
3530 fi
3531 AC_SUBST(LIBXSM)
3532
3533 ### Use XRandr (-lXrandr) if available
3534 HAVE_XRANDR=no
3535 if test "${HAVE_X11}" = "yes"; then
3536   XRANDR_REQUIRED=1.2.2
3537   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3538   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3539   if test $HAVE_XRANDR = no; then
3540     # Test old way in case pkg-config doesn't have it (older machines).
3541     # Include Xrender.h by hand to work around bug in older Xrandr.h
3542     # (e.g. RHEL5) and silence (harmless) configure warning (bug#18465).
3543     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3544       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)],
3545       [], [AC_INCLUDES_DEFAULT
3546 #include <X11/extensions/Xrender.h>])
3547     if test $HAVE_XRANDR = yes; then
3548       XRANDR_LIBS=-lXrandr
3549     fi
3550   fi
3551   if test $HAVE_XRANDR = yes; then
3552     SAVE_CFLAGS="$CFLAGS"
3553     SAVE_LIBS="$LIBS"
3554     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3555     LIBS="$XRANDR_LIBS $LIBS"
3556     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3557     CFLAGS="$SAVE_CFLAGS"
3558     LIBS="$SAVE_LIBS"
3559
3560     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3561   fi
3562 fi
3563 AC_SUBST(XRANDR_CFLAGS)
3564 AC_SUBST(XRANDR_LIBS)
3565
3566 ### Use Xinerama (-lXinerama) if available
3567 HAVE_XINERAMA=no
3568 if test "${HAVE_X11}" = "yes"; then
3569   XINERAMA_REQUIRED=1.0.2
3570   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3571   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3572   if test $HAVE_XINERAMA = no; then
3573     # Test old way in case pkg-config doesn't have it (older machines).
3574     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3575       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3576     if test $HAVE_XINERAMA = yes; then
3577       XINERAMA_LIBS=-lXinerama
3578     fi
3579   fi
3580   if test $HAVE_XINERAMA = yes; then
3581     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3582   fi
3583 fi
3584 AC_SUBST(XINERAMA_CFLAGS)
3585 AC_SUBST(XINERAMA_LIBS)
3586
3587 ### Use Xfixes (-lXfixes) if available
3588 HAVE_XFIXES=no
3589 if test "${HAVE_X11}" = "yes"; then
3590   XFIXES_REQUIRED=4.0.0
3591   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3592   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3593   if test $HAVE_XFIXES = no; then
3594     # Test old way in case pkg-config doesn't have it (older machines).
3595     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3596       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3597     if test $HAVE_XFIXES = yes; then
3598       XFIXES_LIBS=-lXfixes
3599     fi
3600   fi
3601   if test $HAVE_XFIXES = yes; then
3602     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3603   fi
3604 fi
3605 AC_SUBST(XFIXES_CFLAGS)
3606 AC_SUBST(XFIXES_LIBS)
3607
3608 ### Use libxml (-lxml2) if available
3609 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3610 HAVE_LIBXML2=no
3611 if test "${with_xml2}" != "no"; then
3612   ### I'm not sure what the version number should be, so I just guessed.
3613   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3614   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3615   if test "${HAVE_LIBXML2}" != "yes" && test "$opsys" = "darwin"; then
3616     SAVE_CPPFLAGS="$CPPFLAGS"
3617     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3618     AC_CHECK_HEADER(libxml/HTMLparser.h,
3619       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3620                      [#include <libxml/HTMLparser.h>])])
3621     CPPFLAGS="$SAVE_CPPFLAGS"
3622     if test "${HAVE_LIBXML2}" = "yes"; then
3623       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3624       LIBXML2_LIBS="-lxml2"
3625     fi
3626   fi
3627   if test "${HAVE_LIBXML2}" = "yes"; then
3628     if test "${opsys}" != "mingw32"; then
3629       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no,
3630         [$LIBXML2_LIBS])
3631     else
3632       LIBXML2_LIBS=""
3633     fi
3634     if test "${HAVE_LIBXML2}" = "yes"; then
3635       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3636     else
3637       LIBXML2_LIBS=""
3638       LIBXML2_CFLAGS=""
3639     fi
3640   fi
3641 fi
3642 AC_SUBST(LIBXML2_LIBS)
3643 AC_SUBST(LIBXML2_CFLAGS)
3644
3645 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3646 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3647 if test "${opsys}" = "mingw32"; then
3648   emacs_cv_netdb_declares_h_errno=yes
3649 fi
3650 AC_CACHE_CHECK(whether netdb declares h_errno,
3651                emacs_cv_netdb_declares_h_errno,
3652 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3653   [[return h_errno;]])],
3654   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3655 if test $emacs_cv_netdb_declares_h_errno = yes; then
3656   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3657 fi
3658
3659 # Check for mail-locking functions in a "mail" library.  Probably this should
3660 # have the same check as for liblockfile below.
3661 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3662 if test $have_mail = yes; then
3663   LIBS_MAIL=-lmail
3664   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the 'mail' library (-lmail).])
3665
3666   OLD_LIBS=$LIBS
3667   LIBS="$LIBS_MAIL $LIBS"
3668   AC_CHECK_FUNCS(touchlock)
3669   LIBS=$OLD_LIBS
3670 else
3671   LIBS_MAIL=
3672 fi
3673 dnl Debian, at least:
3674 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3675 if test $have_lockfile = yes; then
3676    LIBS_MAIL=-llockfile
3677    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the 'lockfile' library (-llockfile).])
3678 else
3679 # If we have the shared liblockfile, assume we must use it for mail
3680 # locking (e.g. Debian).  If we couldn't link against liblockfile
3681 # (no liblockfile.a installed), ensure that we don't need to.
3682   dnl This works for files generally, not just executables.
3683   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3684   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3685                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3686   if test $ac_cv_prog_liblockfile = yes; then
3687     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3688 This probably means that movemail could lose mail.
3689 There may be a 'development' package to install containing liblockfile.])
3690   fi
3691 fi
3692 AC_CHECK_HEADERS_ONCE(maillock.h)
3693 AC_SUBST(LIBS_MAIL)
3694
3695 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3696 ## interlock access to the mail spool.  The alternative is a lock file named
3697 ## /usr/spool/mail/$USER.lock.
3698 mail_lock=no
3699 case "$opsys" in
3700   aix4-2) mail_lock="lockf" ;;
3701
3702   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3703
3704   ## On GNU/Linux systems, both methods are used by various mail programs.
3705   ## I assume most people are using newer mailers that have heard of flock.
3706   ## Change this if you need to.
3707   ## Debian contains a patch which says: "On Debian/GNU/Linux systems,
3708   ## configure gets the right answers, and that means *NOT* using flock.
3709   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3710   ## for details." and then uses '#ifdef DEBIAN'.  Unfortunately the
3711   ## Debian maintainer hasn't provided a clean fix for Emacs.
3712   ## movemail.c will use 'maillock' when MAILDIR, HAVE_LIBMAIL and
3713   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3714   ## correct logic.  -- fx
3715   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3716   ## liblockfile is a Free Software replacement for libmail, used on
3717   ## Debian systems and elsewhere. -rfr.
3718   gnu-*)
3719     mail_lock="flock"
3720     if test $have_mail = yes || test $have_lockfile = yes; then
3721       test $ac_cv_header_maillock_h = yes && mail_lock=no
3722     fi
3723     ;;
3724
3725   mingw32)
3726     mail_lock="none-needed" ;;
3727 esac
3728
3729 BLESSMAIL_TARGET=
3730 case "$mail_lock" in
3731   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3732
3733   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3734
3735   none-needed) ;;
3736
3737   *) BLESSMAIL_TARGET="need-blessmail" ;;
3738 esac
3739 AC_SUBST(BLESSMAIL_TARGET)
3740
3741 OLD_LIBS=$LIBS
3742 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3743 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3744 getrusage get_current_dir_name \
3745 lrand48 random rint \
3746 select getpagesize setlocale newlocale \
3747 getrlimit setrlimit shutdown getaddrinfo \
3748 pthread_sigmask strsignal setitimer \
3749 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3750 gai_strerror sync \
3751 getpwent endpwent getgrent endgrent \
3752 cfmakeraw cfsetspeed copysign __executable_start log2)
3753 LIBS=$OLD_LIBS
3754
3755 dnl No need to check for aligned_alloc and posix_memalign if using
3756 dnl gmalloc.o, as it supplies them, unless we're using hybrid_malloc.
3757 dnl Don't use these functions on Darwin as they are incompatible with
3758 dnl unexmacosx.c.
3759 if (test -z "$GMALLOC_OBJ" || test "$hybrid_malloc" = yes) \
3760   && test "$opsys" != darwin; then
3761   AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3762 fi
3763
3764 dnl Cannot use AC_CHECK_FUNCS
3765 AC_CACHE_CHECK([for __builtin_unwind_init],
3766                emacs_cv_func___builtin_unwind_init,
3767 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3768                 emacs_cv_func___builtin_unwind_init=yes,
3769                 emacs_cv_func___builtin_unwind_init=no)])
3770 if test $emacs_cv_func___builtin_unwind_init = yes; then
3771   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3772             [Define to 1 if you have the '__builtin_unwind_init' function.])
3773 fi
3774
3775 AC_CHECK_HEADERS_ONCE(sys/un.h)
3776
3777 AC_FUNC_FSEEKO
3778
3779 # UNIX98 PTYs.
3780 AC_CHECK_FUNCS(grantpt)
3781
3782 # PTY-related GNU extensions.
3783 AC_CHECK_FUNCS(getpt posix_openpt)
3784
3785 # Check this now, so that we will NOT find the above functions in ncurses.
3786 # That is because we have not set up to link ncurses in lib-src.
3787 # It's better to believe a function is not available
3788 # than to expect to find it in ncurses.
3789 # Also we need tputs and friends to be able to build at all.
3790 AC_MSG_CHECKING([for library containing tputs])
3791 # Run a test program that contains a call to tputs, a call that is
3792 # never executed.  This tests whether a pre-'main' dynamic linker
3793 # works with the library.  It's too much trouble to actually call
3794 # tputs in the test program, due to portability hassles.  When
3795 # cross-compiling, assume the test program will run if it links.
3796 AC_DEFUN([tputs_link_source], [
3797   AC_LANG_SOURCE(
3798      [[extern void tputs (const char *, int, int (*)(int));
3799        int main (int argc, char **argv)
3800        {
3801           if (argc == 10000)
3802             tputs (argv[0], 0, 0);
3803           return 0;
3804        }]])
3805 ])
3806 if test "${opsys}" = "mingw32"; then
3807   msg='none required'
3808 else
3809   # Maybe curses should be tried earlier?
3810   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3811   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3812     OLIBS=$LIBS
3813     if test -z "$tputs_library"; then
3814       LIBS_TERMCAP=
3815       msg='none required'
3816     else
3817       LIBS_TERMCAP=-l$tputs_library
3818       msg=$LIBS_TERMCAP
3819       LIBS="$LIBS_TERMCAP $LIBS"
3820     fi
3821     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3822       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3823     LIBS=$OLIBS
3824     if test "X$msg" != Xno; then
3825       break
3826     fi
3827   done
3828 fi
3829 AC_MSG_RESULT([$msg])
3830 if test "X$msg" = Xno; then
3831   AC_MSG_ERROR([The required function 'tputs' was not found in any library.
3832 The following libraries were tried (in order):
3833   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3834 Please try installing whichever of these libraries is most appropriate
3835 for your system, together with its header files.
3836 For example, a libncurses-dev(el) or similar package.])
3837 fi
3838
3839 ## Use termcap instead of terminfo?
3840 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3841 TERMINFO=yes
3842 ## FIXME?  In the cases below where we unconditionally set
3843 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3844 ## if that was found above to have tputs.
3845 ## Should we use the gnu* logic everywhere?
3846 case "$opsys" in
3847   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3848   ##  The ncurses library has been moved out of the System framework in
3849   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3850   ##  option to use it.
3851   darwin) LIBS_TERMCAP="-lncurses" ;;
3852
3853   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3854
3855   freebsd)
3856     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3857     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3858     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3859 [[#if __FreeBSD_version < 400000
3860 fail;
3861 #endif
3862 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3863
3864     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3865
3866     if test $emacs_cv_freebsd_terminfo = yes; then
3867       LIBS_TERMCAP="-lncurses"
3868     else
3869       TERMINFO=no
3870       LIBS_TERMCAP="-ltermcap"
3871     fi
3872     ;;
3873
3874   mingw32)
3875     TERMINFO=no
3876     LIBS_TERMCAP=
3877     ;;
3878
3879   netbsd)
3880     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3881       TERMINFO=no
3882       LIBS_TERMCAP="-ltermcap"
3883     fi
3884     ;;
3885
3886   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3887
3888   ## hpux: Make sure we get select from libc rather than from libcurses
3889   ##  because libcurses on HPUX 10.10 has a broken version of select.
3890   ##  We used to use -lc -lcurses, but this may be cleaner.
3891   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3892   # set that way, now it uses the default).  Isn't this a contradiction?
3893   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3894
3895 esac
3896
3897 TERMCAP_OBJ=tparam.o
3898 if test $TERMINFO = yes; then
3899   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3900   TERMCAP_OBJ=terminfo.o
3901 fi
3902 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3903   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3904 fi
3905 AC_SUBST(LIBS_TERMCAP)
3906 AC_SUBST(TERMCAP_OBJ)
3907
3908 # GNU/Linux-specific timer functions.
3909 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
3910   [AC_COMPILE_IFELSE(
3911      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
3912                       ]],
3913                       [[timerfd_create (CLOCK_REALTIME,
3914                                         TFD_CLOEXEC | TFD_NONBLOCK);
3915                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
3916      [emacs_cv_have_timerfd=yes],
3917      [emacs_cv_have_timerfd=no])])
3918 if test "$emacs_cv_have_timerfd" = yes; then
3919   AC_DEFINE([HAVE_TIMERFD], 1,
3920     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
3921 fi
3922
3923 # Alternate stack for signal handlers.
3924 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
3925                [emacs_cv_alternate_stack],
3926   [AC_COMPILE_IFELSE(
3927      [AC_LANG_PROGRAM([[#include <signal.h>
3928                       ]],
3929                       [[stack_t ss;
3930                         struct sigaction sa;
3931                         ss.ss_sp = malloc (SIGSTKSZ);
3932                         ss.ss_size = SIGSTKSZ;
3933                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
3934                         sigaltstack (&ss, 0);
3935                         sigaction (SIGSEGV, &sa, 0);]])],
3936      [emacs_cv_alternate_stack=yes],
3937      [emacs_cv_alternate_stack=no])])
3938
3939 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3940 # On Darwin, res_init appears not to be useful: see bug#562 and
3941 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3942 resolv=no
3943
3944 if test $opsys != darwin; then
3945
3946   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3947 #include <arpa/nameser.h>
3948 #include <resolv.h>]],
3949     [[return res_init();]])],
3950     have_res_init=yes, have_res_init=no)
3951   if test "$have_res_init" = no; then
3952     OLIBS="$LIBS"
3953     LIBS="$LIBS -lresolv"
3954     AC_MSG_CHECKING(for res_init with -lresolv)
3955     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3956 #include <arpa/nameser.h>
3957 #include <resolv.h>]],
3958       [[return res_init();]])],
3959       have_res_init=yes, have_res_init=no)
3960     AC_MSG_RESULT($have_res_init)
3961     if test "$have_res_init" = yes ; then
3962       resolv=yes
3963     fi
3964     LIBS="$OLIBS"
3965   fi
3966
3967   if test "$have_res_init" = yes; then
3968     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3969   fi
3970 fi                              dnl !darwin
3971
3972 # Do we need the Hesiod library to provide the support routines?
3973 dnl FIXME?  Should we be skipping this on Darwin too?
3974 LIBHESIOD=
3975 if test "$with_hesiod" != no ; then
3976   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3977   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3978      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3979                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3980   if test "$resolv" = yes ; then
3981     RESOLVLIB=-lresolv
3982   else
3983     RESOLVLIB=
3984   fi
3985   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3986         hesiod=yes, :, $RESOLVLIB)])
3987
3988   if test x"$hesiod" = xyes; then
3989     LIBHESIOD=-lhesiod
3990   fi
3991 fi
3992 AC_SUBST(LIBHESIOD)
3993
3994 # Do we need libresolv (due to res_init or Hesiod)?
3995 if test "$resolv" = yes && test $opsys != darwin; then
3996   LIBRESOLV=-lresolv
3997 else
3998   LIBRESOLV=
3999 fi
4000 AC_SUBST(LIBRESOLV)
4001
4002 # These tell us which Kerberos-related libraries to use.
4003 COM_ERRLIB=
4004 CRYPTOLIB=
4005 KRB5LIB=
4006 DESLIB=
4007 KRB4LIB=
4008
4009 if test "${with_kerberos}" != no; then
4010   OLD_LIBS=$LIBS
4011   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
4012   if test $have_com_err = yes; then
4013     COM_ERRLIB=-lcom_err
4014     LIBS="$COM_ERRLIB $LIBS"
4015   fi
4016   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
4017   if test $have_crypto = yes; then
4018     CRYPTOLIB=-lcrypto
4019     LIBS="$CRYPTOLIB $LIBS"
4020   fi
4021   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
4022   if test $have_k5crypto = yes; then
4023     CRYPTOLIB=-lk5crypto
4024     LIBS="$CRYPTOLIB $LIBS"
4025   fi
4026   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
4027   if test $have_krb5=yes; then
4028     KRB5LIB=-lkrb5
4029     LIBS="$KRB5LIB $LIBS"
4030   fi
4031   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
4032   if test "${with_kerberos5}" = no; then
4033     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
4034     if test $have_des425 = yes; then
4035       DESLIB=-ldes425
4036       LIBS="$DESLIB $LIBS"
4037     else
4038       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
4039       if test $have_des = yes; then
4040         DESLIB=-ldes
4041         LIBS="$DESLIB $LIBS"
4042       fi
4043     fi
4044     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
4045     if test $have_krb4 = yes; then
4046       KRB4LIB=-lkrb4
4047       LIBS="$KRB4LIB $LIBS"
4048     else
4049       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
4050       if test $have_krb = yes; then
4051         KRB4LIB=-lkrb
4052         LIBS="$KRB4LIB $LIBS"
4053       fi
4054     fi
4055   fi
4056
4057   if test "${with_kerberos5}" != no; then
4058     AC_CHECK_HEADERS(krb5.h,
4059       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
4060                         [#include <krb5.h>])])
4061   else
4062     AC_CHECK_HEADERS(krb.h,,
4063                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
4064                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
4065   fi
4066   AC_CHECK_HEADERS(com_err.h)
4067   LIBS=$OLD_LIBS
4068 fi
4069
4070 AC_SUBST(COM_ERRLIB)
4071 AC_SUBST(CRYPTOLIB)
4072 AC_SUBST(KRB5LIB)
4073 AC_SUBST(DESLIB)
4074 AC_SUBST(KRB4LIB)
4075
4076 AC_CHECK_HEADERS(valgrind/valgrind.h)
4077
4078 AC_CHECK_MEMBERS([struct unipair.unicode], [], [], [[#include <linux/kd.h>]])
4079
4080 AC_CHECK_FUNCS_ONCE(tzset)
4081
4082 ok_so_far=yes
4083 AC_CHECK_FUNC(socket, , ok_so_far=no)
4084 if test $ok_so_far = yes; then
4085   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
4086 fi
4087 if test $ok_so_far = yes; then
4088   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
4089 fi
4090 if test $ok_so_far = yes; then
4091 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
4092   AC_DEFINE(HAVE_INET_SOCKETS, 1,
4093             [Define to 1 if you have inet sockets.])
4094 fi
4095
4096 AC_FUNC_FORK
4097
4098 AC_CHECK_FUNCS(snprintf)
4099
4100 dnl Check for glib.  This differs from other library checks in that
4101 dnl Emacs need not link to glib unless some other library is already
4102 dnl linking to glib.  Although glib provides no facilities that Emacs
4103 dnl needs for its own purposes, when glib is present Emacs needs to
4104 dnl use primitives like g_main_context_query to avoid clashing with
4105 dnl glib at a low level.
4106 dnl
4107 dnl Check this late, since it depends on $GTK_CFLAGS etc.
4108 XGSELOBJ=
4109 OLDCFLAGS="$CFLAGS"
4110 OLDLIBS="$LIBS"
4111 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
4112 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
4113 CFLAGS="$CFLAGS $GFILENOTIFY_CFLAGS $CAIRO_CFLAGS"
4114 LIBS="$LIBS $GFILENOTIFY_LIBS $CAIRO_LIBS"
4115 AC_MSG_CHECKING([whether GLib is linked in])
4116 AC_LINK_IFELSE([AC_LANG_PROGRAM(
4117         [[#include <glib.h>
4118         ]],
4119         [[g_print ("Hello world");]])],
4120      [links_glib=yes],
4121      [links_glib=no])
4122 AC_MSG_RESULT([$links_glib])
4123 if test "${links_glib}" = "yes"; then
4124   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
4125   if test "$HAVE_NS" = no;then
4126     XGSELOBJ=xgselect.o
4127   fi
4128 fi
4129 CFLAGS="$OLDCFLAGS"
4130 LIBS="$OLDLIBS"
4131 AC_SUBST(XGSELOBJ)
4132
4133 dnl Adapted from Haible's version.
4134 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
4135   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
4136     [[char* cs = nl_langinfo(CODESET);]])],
4137     emacs_cv_langinfo_codeset=yes,
4138     emacs_cv_langinfo_codeset=no)
4139   ])
4140 if test $emacs_cv_langinfo_codeset = yes; then
4141   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
4142     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
4143 fi
4144
4145 AC_TYPE_MBSTATE_T
4146
4147 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
4148 dnl how the tty code is related to POSIX and/or other versions of termios.
4149 dnl The following looks like a useful start.
4150 dnl
4151 dnl AC_SYS_POSIX_TERMIOS
4152 dnl if test $ac_cv_sys_posix_termios = yes; then
4153 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
4154 dnl                                and macros for terminal control.])
4155 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
4156 dnl fi
4157
4158 dnl Turned on June 1996 supposing nobody will mind it.
4159 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
4160 if test "${opsys}" != "mingw32"; then
4161    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
4162      in the full name stands for the login id.])
4163 fi
4164
4165 dnl Everybody supports this, except MS.
4166 dnl Seems like the kind of thing we should be testing for, though.
4167 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4168 if test "${opsys}" != "mingw32"; then
4169   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4170 fi
4171
4172 dnl Everybody supports this, except MS-DOS.
4173 dnl Seems like the kind of thing we should be testing for, though.
4174 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4175 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4176   4.2-compatible sockets.])
4177
4178 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4179
4180 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4181   a null file, or a data sink.])
4182 if test "${opsys}" = "mingw32"; then
4183   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4184 else
4185   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4186 fi
4187
4188 if test "${opsys}" = "mingw32"; then
4189   SEPCHAR=';'
4190 else
4191   SEPCHAR=':'
4192 fi
4193 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4194 dnl This is for MinGW, and is used in test/automated/Makefile.in.
4195 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4196 dnl decides that a command-line argument to be passed to a MinGW program
4197 dnl is a PATH-style list of directories.  But that heuristics plays it
4198 dnl safe, and only does the replacement when it is _absolutely_ sure it
4199 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4200 dnl which breaks in-tree builds.  So we do this manually instead.
4201 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4202 dnl be computed as ':' in MSYS Bash.
4203 AC_SUBST(SEPCHAR)
4204
4205 dnl Everybody supports this, except MS-DOS.
4206 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4207
4208 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4209
4210
4211 AC_DEFINE(DIRECTORY_SEP, ['/'],
4212   [Character that separates directories in a file name.])
4213
4214 if test "${opsys}" = "mingw32"; then
4215   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4216     [Returns true if character is a device separator.])
4217
4218   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4219     [Returns true if character is a directory separator.])
4220
4221   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4222     [Returns true if character is any form of separator.])
4223 else
4224   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4225     [Returns true if character is a device separator.])
4226
4227   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4228     [Returns true if character is a directory separator.])
4229
4230   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4231     [Returns true if character is any form of separator.])
4232 fi
4233
4234 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4235
4236 case $opsys in
4237   aix4-2)
4238     dnl Unfortunately without libXmu we cannot support EditRes.
4239     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4240       AC_DEFINE(NO_EDITRES, 1)
4241     fi
4242     ;;
4243
4244   hpux*)
4245     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4246     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4247     AC_DEFINE(NO_EDITRES, 1)
4248     ;;
4249 esac
4250
4251
4252 case $opsys in
4253   irix6-5 | sol2* | unixware )
4254     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4255     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4256     dnl need the constant to dimension an array.  So wire in the appropriate
4257     dnl value here.
4258     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4259     ;;
4260 esac
4261
4262 emacs_broken_SIGIO=no
4263
4264 case $opsys in
4265   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4266   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4267   hpux* | irix6-5 | nacl | openbsd | sol2* | unixware )
4268     emacs_broken_SIGIO=yes
4269     ;;
4270
4271   aix4-2)
4272     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4273     dnl the way this system works, libc functions that return malloced
4274     dnl memory use the libc malloc implementation. Calling xfree or
4275     dnl xrealloc on the results of such functions results in a crash.
4276     dnl
4277     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4278     dnl but that does not currently work on this system.
4279     dnl
4280     dnl It is possible to completely override the malloc implementation on
4281     dnl AIX, but that involves putting the malloc functions in a shared
4282     dnl library and setting the MALLOCTYPE environment variable to point to
4283     dnl that shared library.
4284     dnl
4285     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4286     dnl to avoid a crash just use the Emacs implementation for that function.
4287     dnl
4288     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4289     dnl of this file, so that we do not check for get_current_dir_name
4290     dnl on AIX.  But that might be fragile if something else ends
4291     dnl up testing for get_current_dir_name as a dependency.
4292     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4293       get_current_dir_name should not be used.])
4294     ;;
4295
4296   freebsd)
4297     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4298     dnl writes/reads on a PTY, read(2) returns bogus data:
4299     dnl
4300     dnl write(2)  1022 bytes
4301     dnl write(2)   954 bytes, get EAGAIN
4302     dnl read(2)   1024 bytes in process_read_output
4303     dnl read(2)     11 bytes in process_read_output
4304     dnl
4305     dnl That is, read(2) returns more bytes than have ever been written
4306     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4307     dnl successfully after processing (for example with CRs added if the
4308     dnl terminal is set up that way which it is here).  The same bytes will
4309     dnl be seen again in a later read(2), without the CRs.
4310     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4311       work around an issue when reading from a PTY.])
4312     ;;
4313 esac
4314
4315 case $opsys in
4316   gnu-* | sol2-10 )
4317     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4318     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4319   ;;
4320 esac
4321
4322 case $opsys in
4323   darwin | dragonfly | freebsd | netbsd | openbsd )
4324     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4325       close a pty to make it a controlling terminal (it is already a
4326       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4327   ;;
4328 esac
4329
4330 dnl FIXME Surely we can test for this rather than hard-code it.
4331 case $opsys in
4332   netbsd | openbsd) sound_device="/dev/audio" ;;
4333   *) sound_device="/dev/dsp" ;;
4334 esac
4335
4336 dnl Used in sound.c
4337 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4338   [Name of the default sound device.])
4339
4340
4341 dnl Emacs can read input using SIGIO and buffering characters itself,
4342 dnl or using CBREAK mode and making C-g cause SIGINT.
4343 dnl The choice is controlled by the variable interrupt_input.
4344 dnl
4345 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4346 dnl
4347 dnl Emacs uses the presence of the USABLE_SIGIO macro
4348 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4349 dnl INTERRUPT_INPUT to decide whether to use it by default.
4350 dnl
4351 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4352 dnl CBREAK mode has two disadvantages
4353 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4354 dnl I hear that in system V this problem does not exist.
4355 dnl 2) Control-G causes output to be discarded.
4356 dnl I do not know whether this can be fixed in system V.
4357 dnl
4358 dnl Another method of doing input is planned but not implemented.
4359 dnl It would have Emacs fork off a separate process
4360 dnl to read the input and send it to the true Emacs process
4361 dnl through a pipe.
4362 case $opsys in
4363   darwin | gnu-linux | gnu-kfreebsd )
4364     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4365   ;;
4366 esac
4367
4368
4369 dnl If the system's imake configuration file defines 'NeedWidePrototypes'
4370 dnl as 'NO', we must define NARROWPROTO manually.  Such a define is
4371 dnl generated in the Makefile generated by 'xmkmf'.  If we don't define
4372 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4373 dnl taking float or double parameters.
4374 case $opsys in
4375   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4376     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4377       file defines 'NeedWidePrototypes' as 'NO'.])
4378   ;;
4379 esac
4380
4381
4382 dnl Used in process.c, this must be a loop, even if it only runs once.
4383 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4384 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4385 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4386 dnl trying suffixes 0-16.
4387 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4388   first PTY, if PTYs are supported.])
4389 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4390 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4391   end of a PTY, if non-standard.])
4392 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4393   end of a PTY, if non-standard.])
4394
4395 case $opsys in
4396   aix4-2 )
4397     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4398     dnl You allocate a pty by opening /dev/ptc to get the master side.
4399     dnl To get the name of the slave side, you just ttyname() the master side.
4400     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4401     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4402     ;;
4403
4404   cygwin )
4405     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4406     dnl multi-line AC_DEFINEs are hard. :(
4407     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4408     AC_DEFINE(PTY_NAME_SPRINTF, [])
4409     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4410     ;;
4411
4412   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
4413   darwin )
4414     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4415     dnl Not used, because PTY_ITERATION is defined.
4416     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4417     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
4418     dnl But we don't have to block SIGCHLD because it is blocked in the
4419     dnl implementation of grantpt.
4420     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (false)])
4421     AC_DEFINE(PTY_NAME_SPRINTF, [])
4422     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4423     ;;
4424
4425   gnu | openbsd )
4426     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4427     ;;
4428
4429   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd | nacl )
4430     dnl if HAVE_GRANTPT
4431     if test "x$ac_cv_func_grantpt" = xyes; then
4432       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4433       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4434       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4435       dnl to prevent sigchld_handler from intercepting the child's death.
4436       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4437       dnl if HAVE_POSIX_OPENPT
4438       if test "x$ac_cv_func_posix_openpt" = xyes; then
4439         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4440         AC_DEFINE(PTY_NAME_SPRINTF, [])
4441       dnl if HAVE_GETPT
4442       elif test "x$ac_cv_func_getpt" = xyes; then
4443         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4444         AC_DEFINE(PTY_NAME_SPRINTF, [])
4445       else
4446         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4447       fi
4448     else
4449       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4450     fi
4451     ;;
4452
4453   hpux*)
4454     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4455     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4456     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4457     ;;
4458
4459   irix6-5 )
4460     dnl It looks like this cannot be right, because it is not a loop.
4461     dnl However, process.c actually does this:
4462     dnl # ifndef __sgi
4463     dnl   continue;
4464     dnl # else
4465     dnl   return -1;
4466     dnl # endif
4467     dnl which presumably makes it OK, since irix == sgi (?).
4468     dnl FIXME it seems like this special treatment is unnecessary?
4469     dnl Why can't irix use a single-trip loop like eg cygwin?
4470     AC_DEFINE(PTY_ITERATION, [])
4471     dnl Not used, because PTY_ITERATION is defined.
4472     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4473     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4474     dnl No need to get the pty name at all.
4475     AC_DEFINE(PTY_NAME_SPRINTF, [])
4476     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4477     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4478     ;;
4479
4480   sol2* )
4481     dnl On SysVr4, grantpt(3) forks a subprocess, so do not use
4482     dnl O_CLOEXEC when opening the pty, and keep the SIGCHLD handler
4483     dnl from intercepting that death.  If any child but grantpt's should die
4484     dnl within, it should be caught after sigrelse(2).
4485     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4486     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4487     ;;
4488
4489   unixware )
4490     dnl Comments are as per sol2*.
4491     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4492     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4493     ;;
4494 esac
4495
4496
4497 case $opsys in
4498   sol2* | unixware )
4499     dnl This change means that we don't loop through allocate_pty too
4500     dnl many times in the (rare) event of a failure.
4501     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4502     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4503     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4504     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (forkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (forkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (forkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4505     ;;
4506 esac
4507
4508
4509 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4510 "typing" a signal character on the pty.])
4511
4512 case $opsys in
4513   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4514   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4515   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4516     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4517     ;;
4518
4519   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4520   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4521   gnu-linux | gnu-kfreebsd )
4522
4523     AC_MSG_CHECKING([for signals via characters])
4524     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4525 #include <linux/version.h>
4526 #if LINUX_VERSION_CODE < 0x20400
4527 # error "Linux version too old"
4528 #endif
4529       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4530
4531     AC_MSG_RESULT([$emacs_signals_via_chars])
4532     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4533     ;;
4534 esac
4535
4536
4537 AH_TEMPLATE(TAB3, [Undocumented.])
4538
4539 case $opsys in
4540   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4541
4542   gnu | dragonfly | freebsd | netbsd | openbsd )
4543     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4544     AC_DEFINE(TAB3, OXTABS)
4545     ;;
4546
4547   gnu-linux | gnu-kfreebsd )
4548     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4549 #ifndef __ia64__
4550 # error "not ia64"
4551 #endif
4552       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4553         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4554         [Mark a secondary stack, like the register stack on the ia64.]), [])
4555     ;;
4556
4557   hpux*)
4558     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4559       run_time_remap; for HPUX.])
4560     ;;
4561 esac
4562
4563
4564 dnl This won't be used automatically yet.  We also need to know, at least,
4565 dnl that the stack is continuous.
4566 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4567   registers relevant for conservative garbage collection in the jmp_buf.])
4568
4569
4570 case $opsys in
4571   dnl Not all the architectures are tested, but there are Debian packages
4572   dnl for SCM and/or Guile on them, so the technique must work.  See also
4573   dnl comments in alloc.c concerning setjmp and gcc.
4574   dnl Fixme: it's probably safe to just use the GCC conditional below.
4575   gnu-linux | gnu-kfreebsd )
4576     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4577 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4578   || defined __alpha__ || defined __mips__ || defined __s390__ \
4579   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4580   || defined __ia64__ || defined __sh__
4581 /* ok */
4582 #else
4583 # error "setjmp not known to work on this arch"
4584 #endif
4585     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4586     ;;
4587 esac
4588
4589
4590 if test x$GCC = xyes; then
4591    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4592    AC_DEFINE(GC_SETJMP_WORKS, 1)
4593 else
4594   case $opsys in
4595     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4596     aix* | dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4597       AC_DEFINE(GC_SETJMP_WORKS, 1)
4598       ;;
4599   esac
4600 fi                              dnl GCC?
4601
4602 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4603 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4604   [AC_LINK_IFELSE(
4605      [AC_LANG_PROGRAM(
4606        [[#include <setjmp.h>
4607          #ifdef __MINGW32__
4608          # define _longjmp longjmp
4609          #endif
4610        ]],
4611        [[jmp_buf j;
4612          if (! _setjmp (j))
4613            _longjmp (j, 1);]])],
4614      [emacs_cv_func__setjmp=yes],
4615      [emacs_cv_func__setjmp=no])])
4616 if test $emacs_cv_func__setjmp = yes; then
4617   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4618 fi
4619
4620 # We need to preserve signal mask to handle C stack overflows.
4621 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4622   [AC_LINK_IFELSE(
4623      [AC_LANG_PROGRAM(
4624        [[#include <setjmp.h>
4625        ]],
4626        [[sigjmp_buf j;
4627          if (! sigsetjmp (j, 1))
4628            siglongjmp (j, 1);]])],
4629      [emacs_cv_func_sigsetjmp=yes],
4630      [emacs_cv_func_sigsetjmp=no])])
4631 if test $emacs_cv_func_sigsetjmp = yes; then
4632   AC_DEFINE([HAVE_SIGSETJMP], 1,
4633     [Define to 1 if sigsetjmp and siglongjmp work.])
4634 fi
4635
4636 case $emacs_cv_func_sigsetjmp,$emacs_cv_alternate_stack,$opsys in
4637   yes,yes,* | *,*,mingw32)
4638     AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4639       [Define to 1 if C stack overflow can be handled in some cases.]);;
4640 esac
4641
4642 case $opsys in
4643   sol2* | unixware )
4644     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4645     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4646     dnl and this is all we need.
4647     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4648     ;;
4649 esac
4650
4651
4652 case $opsys in
4653   hpux* | sol2* )
4654     dnl Used in xfaces.c.
4655     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4656       some systems, where it requires time.h.])
4657     ;;
4658 esac
4659
4660
4661 dnl Define symbols to identify the version of Unix this is.
4662 dnl Define all the symbols that apply correctly.
4663 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4664 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4665 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4666 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4667
4668 case $opsys in
4669   aix4-2)
4670     AC_DEFINE(USG, [])
4671     dnl This symbol should be defined on AIX Version 3  ???????
4672     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4673 #ifndef _AIX
4674 # error "_AIX not defined"
4675 #endif
4676     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4677     ;;
4678
4679   cygwin)
4680     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4681     ;;
4682
4683   darwin)
4684     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4685     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4686     dnl distinguish OS X from pure Darwin.
4687     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4688     ;;
4689
4690   gnu-linux | gnu-kfreebsd )
4691     AC_DEFINE(USG, [])
4692     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4693     ;;
4694
4695   hpux*)
4696     AC_DEFINE(USG, [])
4697     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4698     ;;
4699
4700   irix6-5)
4701     AC_DEFINE(USG, [])
4702     AC_DEFINE(USG5_4, [])
4703     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4704     ;;
4705
4706   mingw32)
4707     AC_DEFINE(DOS_NT, [])
4708     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4709     if test "x$ac_enable_checking" != "x" ; then
4710       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4711     fi
4712     ;;
4713
4714   sol2*)
4715     AC_DEFINE(USG, [])
4716     AC_DEFINE(USG5_4, [])
4717     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4718     ;;
4719
4720   unixware)
4721     AC_DEFINE(USG, [])
4722     AC_DEFINE(USG5_4, [])
4723     ;;
4724 esac
4725
4726 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4727   [case $opsys in
4728      aix4-2 | nacl)
4729        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4730        emacs_cv_usable_FIONREAD=no
4731        ;;
4732
4733      mingw32)
4734        emacs_cv_usable_FIONREAD=yes
4735        ;;
4736
4737      *)
4738        AC_COMPILE_IFELSE(
4739          [AC_LANG_PROGRAM([[#include <sys/types.h>
4740                             #include <sys/ioctl.h>
4741                             #ifdef USG5_4
4742                             # include <sys/filio.h>
4743                             #endif
4744                           ]],
4745                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4746          [emacs_cv_usable_FIONREAD=yes],
4747          [emacs_cv_usable_FIONREAD=no])
4748        ;;
4749    esac])
4750 if test $emacs_cv_usable_FIONREAD = yes; then
4751   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4752
4753   if test $emacs_broken_SIGIO = no; then
4754     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4755       [AC_COMPILE_IFELSE(
4756          [AC_LANG_PROGRAM([[#include <fcntl.h>
4757                             #include <signal.h>
4758                           ]],
4759                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4760          [emacs_cv_usable_SIGIO=yes],
4761          [emacs_cv_usable_SIGIO=no])],
4762       [emacs_cv_usable_SIGIO=yes],
4763       [emacs_cv_usable_SIGIO=no])
4764     if test $emacs_cv_usable_SIGIO = yes; then
4765       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4766     fi
4767   fi
4768 fi
4769
4770 case $opsys in
4771   hpux11)
4772     dnl It works to open the pty's tty in the parent (Emacs), then
4773     dnl close and reopen it in the child.
4774     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4775       works to open a pty's tty in the parent process, then close and
4776       reopen it in the child.])
4777     ;;
4778
4779   irix6-5)
4780     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4781       use VSUSP instead of VSWTCH.])
4782     ;;
4783
4784   sol2-10)
4785     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4786       on Solaris.])
4787     ;;
4788 esac
4789
4790 # Set up the CFLAGS for real compilation, so we can substitute it.
4791 CFLAGS="$REAL_CFLAGS"
4792 CPPFLAGS="$REAL_CPPFLAGS"
4793 LIBS="$REAL_LIBS"
4794
4795 ## Hack to detect a buggy GCC version.
4796 if test "$GCC" = yes && \
4797    $CC --version 2> /dev/null | grep 'gcc.* 4.5.0' >/dev/null; then
4798   case $CFLAGS in
4799     *-fno-optimize-sibling-calls*) ;;
4800     *-O@<:@23@:>@*)
4801       AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS.]);;
4802   esac
4803 fi
4804
4805 version=$PACKAGE_VERSION
4806
4807 copyright="Copyright (C) 2015 Free Software Foundation, Inc."
4808 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4809   [Short copyright string for this version of Emacs.])
4810 AC_SUBST(copyright)
4811
4812 ### Specify what sort of things we'll be editing into Makefile and config.h.
4813 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4814 AC_SUBST(version)
4815 AC_SUBST(configuration)
4816 ## Unused?
4817 AC_SUBST(canonical)
4818 AC_SUBST(srcdir)
4819 AC_SUBST(prefix)
4820 AC_SUBST(exec_prefix)
4821 AC_SUBST(bindir)
4822 AC_SUBST(datadir)
4823 AC_SUBST(sharedstatedir)
4824 AC_SUBST(libexecdir)
4825 AC_SUBST(mandir)
4826 AC_SUBST(infodir)
4827 AC_SUBST(lispdir)
4828 AC_SUBST(standardlisppath)
4829 AC_SUBST(locallisppath)
4830 AC_SUBST(lisppath)
4831 AC_SUBST(x_default_search_path)
4832 AC_SUBST(etcdir)
4833 AC_SUBST(archlibdir)
4834 AC_SUBST(etcdocdir)
4835 AC_SUBST(bitmapdir)
4836 AC_SUBST(gamedir)
4837 AC_SUBST(gameuser)
4838 AC_SUBST(gamegroup)
4839 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4840 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4841 ## end of LIBX_BASE, but nothing ever set it.
4842 AC_SUBST(LD_SWITCH_X_SITE)
4843 AC_SUBST(C_SWITCH_X_SITE)
4844 AC_SUBST(GNUSTEP_CFLAGS)
4845 AC_SUBST(CFLAGS)
4846 ## Used in lwlib/Makefile.in.
4847 AC_SUBST(X_TOOLKIT_TYPE)
4848 AC_SUBST(ns_appdir)
4849 AC_SUBST(ns_appbindir)
4850 AC_SUBST(ns_appresdir)
4851 AC_SUBST(ns_appsrc)
4852 AC_SUBST(GNU_OBJC_CFLAGS)
4853 AC_SUBST(OTHER_FILES)
4854
4855 if test -n "${term_header}"; then
4856     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4857         [Define to the header for the built-in window system.])
4858 fi
4859
4860 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4861                    [Define to the canonical Emacs configuration name.])
4862 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4863                    [Define to the options passed to configure.])
4864 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4865   define this to include extra configuration information.])
4866
4867 case $opsys in
4868   mingw32)
4869     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4870     ;;
4871 esac
4872
4873 XMENU_OBJ=
4874 XOBJ=
4875 FONT_OBJ=
4876 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4877   AC_DEFINE(HAVE_X_WINDOWS, 1,
4878             [Define to 1 if you want to use the X window system.])
4879   XMENU_OBJ=xmenu.o
4880   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4881   FONT_OBJ=xfont.o
4882   if test "$USE_CAIRO" = "yes"; then
4883     FONT_OBJ="ftfont.o ftcrfont.o"
4884   elif test "$HAVE_XFT" = "yes"; then
4885     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4886   elif test "$HAVE_FREETYPE" = "yes"; then
4887     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4888   fi
4889   AC_SUBST(FONT_OBJ)
4890 fi
4891 AC_SUBST(XMENU_OBJ)
4892 AC_SUBST(XOBJ)
4893 AC_SUBST(FONT_OBJ)
4894
4895 WIDGET_OBJ=
4896 MOTIF_LIBW=
4897 if test "${USE_X_TOOLKIT}" != "none" ; then
4898   WIDGET_OBJ=widget.o
4899   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4900   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4901     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4902   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4903     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4904     MOTIF_LIBW=-lXm
4905     case "$opsys" in
4906       gnu-linux)
4907         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4908         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4909         ;;
4910
4911       unixware)
4912         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4913         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4914         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4915         ;;
4916
4917       aix4-2)
4918         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4919         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4920         ;;
4921     esac
4922     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4923   fi
4924 fi
4925 AC_SUBST(WIDGET_OBJ)
4926
4927 TOOLKIT_LIBW=
4928 case "$USE_X_TOOLKIT" in
4929   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4930   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4931   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4932 esac
4933 AC_SUBST(TOOLKIT_LIBW)
4934
4935 if test "${opsys}" != "mingw32"; then
4936   if test "$USE_X_TOOLKIT" = "none"; then
4937     LIBXT_OTHER="\$(LIBXSM)"
4938   else
4939     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4940   fi
4941 fi
4942 AC_SUBST(LIBXT_OTHER)
4943
4944 if test "${HAVE_X11}" = "yes" ; then
4945   AC_DEFINE(HAVE_X11, 1,
4946             [Define to 1 if you want to use version 11 of X windows.])
4947   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4948 else
4949   LIBX_OTHER=
4950 fi
4951 AC_SUBST(LIBX_OTHER)
4952
4953 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4954   LIBXMENU=
4955 elif test "$USE_X_TOOLKIT" = none; then
4956   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4957 else
4958   LIBXMENU='$(lwlibdir)/liblw.a'
4959 fi
4960 AC_SUBST(LIBXMENU)
4961
4962 AC_CACHE_CHECK([for struct alignment],
4963   [emacs_cv_struct_alignment],
4964   [AC_COMPILE_IFELSE(
4965      [AC_LANG_PROGRAM([[#include <stddef.h>
4966                         struct __attribute__ ((aligned (8))) s { char c; };
4967                         struct t { char c; struct s s; };
4968                         char verify[offsetof (struct t, s) == 8 ? 1 : -1];
4969                       ]])],
4970      [emacs_cv_struct_alignment=yes],
4971      [emacs_cv_struct_alignment=no])])
4972 if test "$emacs_cv_struct_alignment" = yes; then
4973   AC_DEFINE([HAVE_STRUCT_ATTRIBUTE_ALIGNED], 1,
4974     [Define to 1 if 'struct __attribute__ ((aligned (N)))' aligns the
4975      structure to an N-byte boundary.])
4976 fi
4977
4978 if test "${GNU_MALLOC}" = "yes" ; then
4979   AC_DEFINE(GNU_MALLOC, 1,
4980             [Define to 1 if you want to use the GNU memory allocator.])
4981 fi
4982
4983 RALLOC_OBJ=
4984 if test "${REL_ALLOC}" = "yes" ; then
4985   AC_DEFINE(REL_ALLOC, 1,
4986             [Define REL_ALLOC if you want to use the relocating allocator for
4987              buffer space.])
4988
4989   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4990 fi
4991 AC_SUBST(RALLOC_OBJ)
4992
4993 if test "$opsys" = "cygwin"; then
4994   CYGWIN_OBJ="sheap.o cygw32.o"
4995   ## Cygwin differs because of its unexec().
4996   PRE_ALLOC_OBJ=
4997   POST_ALLOC_OBJ=lastfile.o
4998 elif test "$opsys" = "mingw32"; then
4999   CYGWIN_OBJ=
5000   PRE_ALLOC_OBJ=
5001   POST_ALLOC_OBJ=lastfile.o
5002 else
5003   CYGWIN_OBJ=
5004   PRE_ALLOC_OBJ=lastfile.o
5005   POST_ALLOC_OBJ=
5006 fi
5007 AC_SUBST(CYGWIN_OBJ)
5008 AC_SUBST(PRE_ALLOC_OBJ)
5009 AC_SUBST(POST_ALLOC_OBJ)
5010
5011 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
5012 dnl verbatim defined above.  The tricky name is apropos, as this hack
5013 dnl makes Fortify go sour!
5014 AH_VERBATIM([FORTIFY_SOUR],
5015 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
5016    The workaround disables some useful run-time checking, so it
5017    should be conditional to the platforms with the performance bug.
5018    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
5019 #if defined __APPLE__ && defined __GNUC__
5020 # ifndef _DONT_USE_CTYPE_INLINE_
5021 #  define _DONT_USE_CTYPE_INLINE_
5022 # endif
5023 # ifndef _FORTIFY_SOURCE
5024 #  define _FORTIFY_SOURCE 0
5025 # endif
5026 #endif
5027 ])
5028
5029 # If user asks to omit features, disable optional features that gnulib
5030 # might otherwise enable.
5031 if test "$with_features" = no && test "$enable_acl" != yes; then
5032   enable_acl=no
5033 fi
5034
5035 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
5036 # it temporarily reverts them to their pre-pkg-config values,
5037 # because gnulib needs to work with both src (which uses the
5038 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
5039 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
5040 # and it therefore needs to run in an environment where LIBS does not
5041 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
5042 # for some package unrelated to lib-src.
5043 SAVE_CFLAGS=$CFLAGS
5044 SAVE_LIBS=$LIBS
5045 CFLAGS=$pre_PKG_CONFIG_CFLAGS
5046 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
5047 gl_ASSERT_NO_GNULIB_POSIXCHECK
5048 gl_ASSERT_NO_GNULIB_TESTS
5049 gl_INIT
5050 CFLAGS=$SAVE_CFLAGS
5051 LIBS=$SAVE_LIBS
5052
5053 if test "${opsys}" = "mingw32"; then
5054   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
5055   # Remove unneeded switches from the value of CC that goes to Makefiles
5056   CC=`AS_ECHO(["$CC"]) | sed -e "s,$GCC_TEST_OPTIONS,,"`
5057 fi
5058
5059 case "$opsys" in
5060   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
5061
5062   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
5063
5064   darwin)
5065    ## The -headerpad option tells ld (see man page) to leave room at the
5066    ## end of the header for adding load commands.  Needed for dumping.
5067    ## 0x1000 is enough for roughly 52 load commands on the x86_64
5068    ## architecture (where they are 78 bytes each). The actual number of
5069    ## load commands added is not consistent but normally ranges from
5070    ## about 14 to about 34. Setting it high gets us plenty of slop and
5071    ## only costs about 1.5K of wasted binary space.
5072    headerpad_extra=1000
5073    if test "$HAVE_NS" = "yes"; then
5074      libs_nsgui="-framework AppKit"
5075      if test "$NS_IMPL_COCOA" = "yes"; then
5076         libs_nsgui="$libs_nsgui -framework IOKit"
5077      fi
5078    else
5079      libs_nsgui=
5080    fi
5081    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
5082
5083    ## This is here because src/Makefile.in did some extra fiddling around
5084    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
5085    ## LD_SWITCH_SYSTEM_TEMACS instead,
5086    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
5087      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
5088    ;;
5089
5090   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
5091   ## find X at run-time.
5092   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
5093   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
5094   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
5095   ## had different values in configure (in ac_link) and src/Makefile.in.
5096   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
5097   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
5098
5099   mingw32)
5100    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
5101    case "$canonical" in
5102      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5103      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5104    esac
5105    ;;
5106
5107   *) LD_SWITCH_SYSTEM_TEMACS= ;;
5108 esac
5109
5110 # -nopie fixes a temacs segfault on Gentoo, OpenBSD, and other systems
5111 # with "hardened" GCC configurations for some reason (Bug#18784).
5112 # We don't know why -nopie works, but not segfaulting is better than
5113 # segfaulting.  Use ac_c_werror_flag=yes when trying -nopie, otherwise
5114 # clang keeps warning that it does not understand -nopie, and pre-4.6
5115 # GCC has a similar problem (Bug#20338).
5116 AC_CACHE_CHECK([whether $CC accepts -nopie],
5117   [emacs_cv_prog_cc_nopie],
5118   [emacs_save_c_werror_flag=$ac_c_werror_flag
5119    emacs_save_LDFLAGS=$LDFLAGS
5120    ac_c_werror_flag=yes
5121    LDFLAGS="$LDFLAGS -nopie"
5122    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
5123      [emacs_cv_prog_cc_nopie=yes],
5124      [emacs_cv_prog_cc_nopie=no])
5125    ac_c_werror_flag=$emacs_save_c_werror_flag
5126    LDFLAGS=$emacs_save_LDFLAGS])
5127 if test "$emacs_cv_prog_cc_nopie" = yes; then
5128   LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -nopie"
5129 fi
5130
5131 if test x$ac_enable_profiling != x ; then
5132   case $opsys in
5133     *freebsd | gnu-linux) ;;
5134     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
5135   esac
5136 fi
5137
5138 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
5139
5140 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
5141
5142 ## Common for all window systems
5143 if test "$window_system" != "none"; then
5144   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
5145   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
5146   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
5147 fi
5148
5149 AC_SUBST(WINDOW_SYSTEM_OBJ)
5150
5151 AH_TOP([/* GNU Emacs site configuration template file.
5152
5153 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2015
5154   Free Software Foundation, Inc.
5155
5156 This file is part of GNU Emacs.
5157
5158 GNU Emacs is free software: you can redistribute it and/or modify
5159 it under the terms of the GNU General Public License as published by
5160 the Free Software Foundation, either version 3 of the License, or
5161 (at your option) any later version.
5162
5163 GNU Emacs is distributed in the hope that it will be useful,
5164 but WITHOUT ANY WARRANTY; without even the implied warranty of
5165 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
5166 GNU General Public License for more details.
5167
5168 You should have received a copy of the GNU General Public License
5169 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
5170
5171
5172 /* No code in Emacs #includes config.h twice, but some bits of code
5173    intended to work with other packages as well (like gmalloc.c)
5174    think they can include it as many times as they like.  */
5175 #ifndef EMACS_CONFIG_H
5176 #define EMACS_CONFIG_H
5177 ])dnl
5178
5179 AH_BOTTOM([#include <conf_post.h>
5180
5181 #endif /* EMACS_CONFIG_H */
5182
5183 /*
5184 Local Variables:
5185 mode: c
5186 End:
5187 */
5188 ])dnl
5189
5190 #### Report on what we decided to do.
5191 #### Report GTK as a toolkit, even if it doesn't use Xt.
5192 #### It makes printing result more understandable as using GTK sets
5193 #### toolkit_scroll_bars to yes by default.
5194 if test "${HAVE_GTK}" = "yes"; then
5195   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5196 fi
5197
5198 if test $USE_ACL -ne 0; then
5199   ACL_SUMMARY="yes $LIB_ACL"
5200 else
5201   ACL_SUMMARY=no
5202 fi
5203
5204 emacs_standard_dirs='Standard dirs'
5205 AS_ECHO(["
5206 Configured for '${canonical}'.
5207
5208   Where should the build process find the source code?    ${srcdir}
5209   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5210   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5211   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5212   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5213   What window system should Emacs use?                    ${window_system}
5214   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}
5215   Where do we find X Windows header files?                ${x_includes:-$emacs_standard_dirs}
5216   Where do we find X Windows libraries?                   ${x_libraries:-$emacs_standard_dirs}"])
5217
5218 optsep=
5219 emacs_config_features=
5220 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG CAIRO IMAGEMAGICK SOUND GPM DBUS \
5221   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5222   LIBOTF XFT ZLIB TOOLKIT_SCROLL_BARS X_TOOLKIT X11 NS MODULES; do
5223
5224     case $opt in
5225       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5226       CAIRO|TOOLKIT_SCROLL_BARS|X_TOOLKIT) eval val=\${USE_$opt} ;;
5227       *) eval val=\${HAVE_$opt} ;;
5228     esac
5229     case x$val in
5230       xno|xnone|x) continue ;;
5231     esac
5232     case $opt in
5233       X_TOOLKIT)
5234         case $val in
5235           GTK*|LUCID|MOTIF) opt=$val ;;
5236           *) continue ;;
5237         esac
5238       ;;
5239     esac
5240     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5241     optsep=' '
5242 done
5243 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5244   [Summary of some of the main features enabled by configure.])
5245
5246 AS_ECHO(["  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}
5247   Does Emacs use -lXpm?                                   ${HAVE_XPM}
5248   Does Emacs use -ljpeg?                                  ${HAVE_JPEG}
5249   Does Emacs use -ltiff?                                  ${HAVE_TIFF}
5250   Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF
5251   Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG
5252   Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}
5253   Does Emacs use cairo?                                   ${USE_CAIRO}
5254   Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}
5255   Does Emacs support sound?                               ${HAVE_SOUND}
5256   Does Emacs use -lgpm?                                   ${HAVE_GPM}
5257   Does Emacs use -ldbus?                                  ${HAVE_DBUS}
5258   Does Emacs use -lgconf?                                 ${HAVE_GCONF}
5259   Does Emacs use GSettings?                               ${HAVE_GSETTINGS}
5260   Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}
5261   Does Emacs use access control lists?                    ${ACL_SUMMARY}
5262   Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}
5263   Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}
5264   Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}
5265   Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}
5266   Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}
5267   Does Emacs use -lotf?                                   ${HAVE_LIBOTF}
5268   Does Emacs use -lxft?                                   ${HAVE_XFT}
5269   Does Emacs directly use zlib?                           ${HAVE_ZLIB}
5270   Does Emacs have dynamic modules support?                ${HAVE_MODULES}
5271   Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}
5272 "])
5273
5274 if test -n "${EMACSDATA}"; then
5275    AS_ECHO(["  Environment variable EMACSDATA set to:                  $EMACSDATA"])
5276 fi
5277 if test -n "${EMACSDOC}"; then
5278    AS_ECHO(["  Environment variable EMACSDOC set to:                   $EMACSDOC"])
5279 fi
5280
5281 echo
5282
5283 if test "$HAVE_NS" = "yes"; then
5284    echo
5285    AS_ECHO(["You must run \"${MAKE-make} install\" in order to test the built application.
5286 The installed application will go to nextstep/Emacs.app and can be
5287 run or moved from there."])
5288    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5289       echo "The application will be fully self-contained."
5290     else
5291       AS_ECHO(["The lisp resources for the application will be installed under ${prefix}.
5292 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5293 to run if these resources are not installed."])
5294    fi
5295    echo
5296 fi
5297
5298 if test "${opsys}" = "cygwin"; then
5299   case `uname -r` in
5300     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5301            echo
5302            ;;
5303   esac
5304 fi
5305
5306 # Remove any trailing slashes in these variables.
5307 case $prefix in
5308   */) prefix=`AS_DIRNAME(["$prefix."])`;;
5309 esac
5310 case $exec_prefix in
5311   */) exec_prefix=`AS_DIRNAME(["$exec_prefix."])`;;
5312 esac
5313
5314 if test "$HAVE_NS" = "yes"; then
5315   if test "$NS_IMPL_GNUSTEP" = yes; then
5316     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5317       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5318     ns_check_file=Resources/Info-gnustep.plist
5319   else
5320     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5321       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5322     ns_check_file=Contents/Info.plist
5323   fi
5324   AC_SUBST(ns_check_file)
5325 fi
5326
5327 dnl config.status treats $srcdir specially, so I think this is ok...
5328 AC_CONFIG_FILES([$srcdir/doc/man/emacs.1])
5329
5330 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5331 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5332 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5333 dnl (else you get "no 'Makefile.am' found for any configure output").
5334 dnl This will work, but you get a config.status that is not quite right
5335 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5336 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5337 dnl it seems better to just live with the duplication.
5338 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5339
5340 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5341        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5342        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5343        leim/Makefile nextstep/Makefile nt/Makefile])
5344
5345 dnl test/ is not present in release tarfiles.
5346 opt_makefile=test/automated/Makefile
5347
5348 if test -f "$srcdir/$opt_makefile.in"; then
5349   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5350   dnl Again, it's best not to use a variable.  Though you can add
5351   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5352   AC_CONFIG_FILES([test/automated/Makefile])
5353 fi
5354
5355
5356 dnl The admin/ directory used to be excluded from tarfiles.
5357 if test -d $srcdir/admin; then
5358   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/charsets/Makefile admin/unidata/Makefile admin/grammars/Makefile"
5359   AC_CONFIG_FILES([admin/charsets/Makefile])
5360   AC_CONFIG_FILES([admin/unidata/Makefile])
5361   AC_CONFIG_FILES([admin/grammars/Makefile])
5362 fi                              dnl -d admin
5363
5364
5365 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5366
5367 AC_SUBST(SUBDIR_MAKEFILES_IN)
5368
5369 dnl You might wonder (I did) why epaths.h is generated by running make,
5370 dnl rather than just letting configure generate it from epaths.in.
5371 dnl One reason is that the various paths are not fully expanded (see above);
5372 dnl eg gamedir=${prefix}/var/games/emacs.
5373 dnl Secondly, the GNU Coding standards require that one should be able
5374 dnl to run 'make prefix=/some/where/else' and override the values set
5375 dnl by configure.  This also explains the 'move-if-change' test and
5376 dnl the use of force in the 'epaths-force' rule in Makefile.in.
5377 AC_CONFIG_COMMANDS([src/epaths.h], [
5378 if test "${opsys}" = "mingw32"; then
5379   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5380 else
5381   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5382 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5383 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5384
5385 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5386 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5387 dnl or a symlink?
5388 AC_CONFIG_COMMANDS([src/.gdbinit], [
5389 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5390   AS_ECHO(["source $ac_abs_top_srcdir/src/.gdbinit"]) > src/.gdbinit
5391 fi
5392 ])
5393
5394 dnl Perhaps this would be better named doc-emacs-emacsver.texi?
5395 dnl See comments for etc-refcards-emacsver.tex.
5396 dnl Since we get a doc/emacs directory generated anyway, for the Makefile,
5397 dnl it is not quite the same.  But we are generating in $srcdir.
5398 AC_CONFIG_COMMANDS([doc/emacs/emacsver.texi], [
5399 ${MAKE-make} -s --no-print-directory -C doc/emacs doc-emacsver || \
5400 AC_MSG_ERROR(['doc/emacs/emacsver.texi' could not be made.])
5401 ])
5402
5403 dnl If we give this the more natural name, etc/refcards/emacsver.texi,
5404 dnl then a directory etc/refcards is created in the build directory,
5405 dnl which is probably harmless, but confusing (in out-of-tree builds).
5406 dnl (If we were to generate etc/refcards/Makefile, this might change.)
5407 dnl It is really $srcdir/etc/refcards/emacsver.tex that we generate.
5408 AC_CONFIG_COMMANDS([etc-refcards-emacsver.tex], [
5409 ${MAKE-make} -s MAKEFILE_NAME=do-not-make-Makefile etc-emacsver || \
5410 AC_MSG_ERROR(['etc/refcards/emacsver.tex' could not be made.])
5411 ])
5412
5413 AC_OUTPUT
5414
5415 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])