code.delx.au - gnu-emacs/blob - lisp/progmodes/compile.el

   1 ;;; compile.el --- run compiler as inferior of Emacs, parse error messages
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4 ;;   2001, 2003, 2004, 2005  Free Software Foundation, Inc.
   5
   6 ;; Authors: Roland McGrath <roland@gnu.org>,
   7 ;;          Daniel Pfeiffer <occitan@esperanto.org>
   8 ;; Maintainer: FSF
   9 ;; Keywords: tools, processes
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package provides the compile facilities documented in the Emacs user's
  31 ;; manual.
  32
  33 ;; This mode uses some complex data-structures:
  34
  35 ;;   LOC (or location) is a list of (COLUMN LINE FILE-STRUCTURE)
  36
  37 ;; COLUMN and LINE are numbers parsed from an error message.  COLUMN and maybe
  38 ;; LINE will be nil for a message that doesn't contain them.  Then the
  39 ;; location refers to a indented beginning of line or beginning of file.
  40 ;; Once any location in some file has been jumped to, the list is extended to
  41 ;; (COLUMN LINE FILE-STRUCTURE MARKER . VISITED) for all LOCs pertaining to
  42 ;; that file.
  43 ;; MARKER initially points to LINE and COLUMN in a buffer visiting that file.
  44 ;; Being a marker it sticks to some text, when the buffer grows or shrinks
  45 ;; before that point.  VISITED is t if we have jumped there, else nil.
  46
  47 ;;   FILE-STRUCTURE is a list of
  48 ;;   ((FILENAME . DIRECTORY) FORMATS (LINE LOC ...) ...)
  49
  50 ;; FILENAME is a string parsed from an error message.  DIRECTORY is a string
  51 ;; obtained by following directory change messages.  DIRECTORY will be nil for
  52 ;; an absolute filename.  FORMATS is a list of formats to apply to FILENAME if
  53 ;; a file of that name can't be found.
  54 ;; The rest of the list is an alist of elements with LINE as key.  The keys
  55 ;; are either nil or line numbers.  If present, nil comes first, followed by
  56 ;; the numbers in decreasing order.  The LOCs for each line are again an alist
  57 ;; ordered the same way.  Note that the whole file structure is referenced in
  58 ;; every LOC.
  59
  60 ;;   MESSAGE is a list of (LOC TYPE END-LOC)
  61
  62 ;; TYPE is 0 for info or 1 for warning if the message matcher identified it as
  63 ;; such, 2 otherwise (for a real error).  END-LOC is a LOC pointing to the
  64 ;; other end, if the parsed message contained a range.  If the end of the
  65 ;; range didn't specify a COLUMN, it defaults to -1, meaning end of line.
  66 ;; These are the value of the `message' text-properties in the compilation
  67 ;; buffer.
  68
  69 ;;; Code:
  70
  71 (eval-when-compile (require 'cl))
  72
  73 (defgroup compilation nil
  74   "Run compiler as inferior of Emacs, parse error messages."
  75   :group 'tools
  76   :group 'processes)
  77
  78
  79 ;;;###autoload
  80 (defcustom compilation-mode-hook nil
  81   "*List of hook functions run by `compilation-mode' (see `run-hooks')."
  82   :type 'hook
  83   :group 'compilation)
  84
  85 ;;;###autoload
  86 (defcustom compilation-window-height nil
  87   "*Number of lines in a compilation window.  If nil, use Emacs default."
  88   :type '(choice (const :tag "Default" nil)
  89                  integer)
  90   :group 'compilation)
  91
  92 (defvar compilation-first-column 1
  93   "*This is how compilers number the first column, usually 1 or 0.")
  94
  95 (defvar compilation-parse-errors-filename-function nil
  96   "Function to call to post-process filenames while parsing error messages.
  97 It takes one arg FILENAME which is the name of a file as found
  98 in the compilation output, and should return a transformed file name.")
  99
 100 ;;;###autoload
 101 (defvar compilation-process-setup-function nil
 102   "*Function to call to customize the compilation process.
 103 This function is called immediately before the compilation process is
 104 started.  It can be used to set any variables or functions that are used
 105 while processing the output of the compilation process.  The function
 106 is called with variables `compilation-buffer' and `compilation-window'
 107 bound to the compilation buffer and window, respectively.")
 108
 109 ;;;###autoload
 110 (defvar compilation-buffer-name-function nil
 111   "Function to compute the name of a compilation buffer.
 112 The function receives one argument, the name of the major mode of the
 113 compilation buffer.  It should return a string.
 114 nil means compute the name with `(concat \"*\" (downcase major-mode) \"*\")'.")
 115
 116 ;;;###autoload
 117 (defvar compilation-finish-function nil
 118   "Function to call when a compilation process finishes.
 119 It is called with two arguments: the compilation buffer, and a string
 120 describing how the process finished.")
 121
 122 ;;;###autoload
 123 (defvar compilation-finish-functions nil
 124   "Functions to call when a compilation process finishes.
 125 Each function is called with two arguments: the compilation buffer,
 126 and a string describing how the process finished.")
 127
 128 (defvar compilation-in-progress nil
 129   "List of compilation processes now running.")
 130 (or (assq 'compilation-in-progress minor-mode-alist)
 131     (setq minor-mode-alist (cons '(compilation-in-progress " Compiling")
 132                                  minor-mode-alist)))
 133
 134 (defvar compilation-error "error"
 135   "Stem of message to print when no matches are found.")
 136
 137 (defvar compilation-arguments nil
 138   "Arguments that were given to `compilation-start'.")
 139
 140 (defvar compilation-num-errors-found)
 141
 142 (defconst compilation-error-regexp-alist-alist
 143   '((absoft
 144      "^\\(?:[Ee]rror on \\|[Ww]arning on\\( \\)\\)?[Ll]ine[ \t]+\\([0-9]+\\)[ \t]+\
 145 of[ \t]+\"?\\([a-zA-Z]?:?[^\":\n]+\\)\"?:" 3 2 nil (1))
 146
 147     (ada
 148      "\\(warning: .*\\)? at \\([^ \n]+\\):\\([0-9]+\\)$" 2 3 nil (1))
 149
 150     (aix
 151      " in line \\([0-9]+\\) of file \\([^ \n]+[^. \n]\\)\\.? " 2 1)
 152
 153     (ant
 154      "^[ \t]*\\[[^] \n]+\\][ \t]*\\([^: \n]+\\):\\([0-9]+\\):\\(?:\\([0-9]+\\):[0-9]+:[0-9]+:\\)?\
 155 \\( warning\\)?" 1 2 3 (4))
 156
 157     (bash
 158      "^\\([^: \n\t]+\\): line \\([0-9]+\\):" 1 2)
 159
 160     (borland
 161      "^\\(?:Error\\|Warnin\\(g\\)\\) \\(?:[FEW][0-9]+ \\)?\
 162 \\([a-zA-Z]?:?[^:( \t\n]+\\)\
 163  \\([0-9]+\\)\\(?:[) \t]\\|:[^0-9\n]\\)" 2 3 nil (1))
 164
 165     (caml
 166      "^ *File \\(\"?\\)\\([^,\" \n\t<>]+\\)\\1, lines? \\([0-9]+\\)-?\\([0-9]+\\)?\\(?:$\\|,\
 167 \\(?: characters? \\([0-9]+\\)-?\\([0-9]+\\)?:\\)?\\([ \n]Warning:\\)?\\)"
 168      2 (3 . 4) (5 . 6) (7))
 169
 170     (comma
 171      "^\"\\([^,\" \n\t]+\\)\", line \\([0-9]+\\)\
 172 \\(?:[(. pos]+\\([0-9]+\\))?\\)?[:.,; (-]\\( warning:\\|[-0-9 ]*(W)\\)?" 1 2 3 (4))
 173
 174     (edg-1
 175      "^\\([^ \n]+\\)(\\([0-9]+\\)): \\(?:error\\|warnin\\(g\\)\\|remar\\(k\\)\\)"
 176      1 2 nil (3 . 4))
 177     (edg-2
 178      "at line \\([0-9]+\\) of \"\\([^ \n]+\\)\"$"
 179      2 1 nil 0)
 180
 181     (epc
 182      "^Error [0-9]+ at (\\([0-9]+\\):\\([^)\n]+\\))" 2 1)
 183
 184     (ftnchek
 185      "\\(^Warning .*\\)? line[ \n]\\([0-9]+\\)[ \n]\\(?:col \\([0-9]+\\)[ \n]\\)?file \\([^ :;\n]+\\)"
 186      4 2 3 (1))
 187
 188     (iar
 189      "^\"\\(.*\\)\",\\([0-9]+\\)\\s-+\\(?:Error\\|Warnin\\(g\\)\\)\\[[0-9]+\\]:"
 190      1 2 nil (3))
 191
 192     (ibm
 193      "^\\([^( \n\t]+\\)(\\([0-9]+\\):\\([0-9]+\\)) :\
 194  \\(?:warnin\\(g\\)\\|informationa\\(l\\)\\)?" 1 2 3 (4 . 5))
 195
 196     ;; fixme: should be `mips'
 197     (irix
 198      "^[-[:alnum:]_/ ]+: \\(?:\\(?:[sS]evere\\|[eE]rror\\|[wW]arnin\\(g\\)\\|[iI]nf\\(o\\)\\)[0-9 ]*: \\)?\
 199 \\([^,\" \n\t]+\\)\\(?:, line\\|:\\) \\([0-9]+\\):" 3 4 nil (1 . 2))
 200
 201     (java
 202      "^\\(?:[ \t]+at \\|==[0-9]+== +\\(?:at\\|b\\(y\\)\\)\\).+(\\([^()\n]+\\):\\([0-9]+\\))$" 2 3 nil (1))
 203
 204     (jikes-file
 205      "^\\(?:Found\\|Issued\\) .* compiling \"\\(.+\\)\":$" 1 nil nil 0)
 206     (jikes-line
 207      "^ *\\([0-9]+\\)\\.[ \t]+.*\n +\\(<-*>\n\\*\\*\\* \\(?:Error\\|Warnin\\(g\\)\\)\\)"
 208      nil 1 nil 2 0
 209      (2 (compilation-face '(3))))
 210
 211     (gcc-include
 212      "^\\(?:In file included\\|                \\) from \
 213 \\(.+\\):\\([0-9]+\\)\\(?:\\(:\\)\\|\\(,\\)\\)?" 1 2 nil (3 . 4))
 214
 215     (gnu
 216      "^\\(?:[[:alpha:]][-[:alnum:].]+: ?\\)?\
 217 \\([/.]*[a-zA-Z]:?[^ \t\n:]*\\|{standard input}\\): ?\
 218 \\([0-9]+\\)\\([.:]?\\)\\([0-9]+\\)?\
 219 \\(?:-\\(?:\\([0-9]+\\)\\3\\)?\\.?\\([0-9]+\\)?\\)?:\
 220 \\(?: *\\(\\(?:Future\\|Runtime\\)?[Ww]arning\\|W:\\)\\|\
 221  *\\([Ii]nfo\\(?:\\>\\|rmationa?l?\\)\\|I:\\)\\)?"
 222      1 (2 . 5) (4 . 6) (7 . 8))
 223
 224     (lcc
 225      "^\\(?:E\\|\\(W\\)\\), \\([^(\n]+\\)(\\([0-9]+\\),[ \t]*\\([0-9]+\\)"
 226      2 3 4 (1))
 227
 228     (makepp
 229      "^makepp: \\(?:\\(?:warning\\(:\\).*?\\|\\(Scanning\\|[LR]e?l?oading makefile\\) \\|.*?\\)\
 230 `\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)'\\)"
 231      4 5 nil (1 . 2) 3
 232      ("`\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)'" nil nil
 233       (2 compilation-info-face)
 234       (3 compilation-line-face nil t)
 235       (1 (compilation-error-properties 2 3 nil nil nil 0 nil)
 236          append)))
 237
 238     ;; Should be lint-1, lint-2 (SysV lint)
 239     (mips-1
 240      " (\\([0-9]+\\)) in \\([^ \n]+\\)" 2 1)
 241     (mips-2
 242      " in \\([^()\n ]+\\)(\\([0-9]+\\))$" 1 2)
 243
 244     (msft
 245      "^\\(\\(?:[a-zA-Z]:\\)?[^:(\t\n]+\\)(\\([0-9]+\\)) \
 246 : \\(?:error\\|warnin\\(g\\)\\) C[0-9]+:" 1 2 nil (3))
 247
 248     (oracle
 249      "^\\(?:Semantic error\\|Error\\|PCC-[0-9]+:\\).* line \\([0-9]+\\)\
 250 \\(?:\\(?:,\\| at\\)? column \\([0-9]+\\)\\)?\
 251 \\(?:,\\| in\\| of\\)? file \\(.*?\\):?$"
 252      3 1 2)
 253
 254     (perl
 255      " at \\([^ \n]+\\) line \\([0-9]+\\)\\(?:[,.]\\|$\\)" 1 2)
 256
 257     (rxp
 258      "^\\(?:Error\\|Warnin\\(g\\)\\):.*\n.* line \\([0-9]+\\) char\
 259  \\([0-9]+\\) of file://\\(.+\\)"
 260      4 2 3 (1))
 261
 262     (sparc-pascal-file
 263      "^\\w\\w\\w \\w\\w\\w +[0-3]?[0-9] +[0-2][0-9]:[0-5][0-9]:[0-5][0-9]\
 264  [12][09][0-9][0-9] +\\(.*\\):$"
 265      1 nil nil 0)
 266     (sparc-pascal-line
 267      "^\\(\\(?:E\\|\\(w\\)\\) +[0-9]+\\) line \\([0-9]+\\) -  "
 268      nil 3 nil (2) nil (1 (compilation-face '(2))))
 269     (sparc-pascal-example
 270      "^ +\\([0-9]+\\) +.*\n\\(\\(?:e\\|\\(w\\)\\) [0-9]+\\)-+"
 271      nil 1 nil (3) nil (2 (compilation-face '(3))))
 272
 273     (sun
 274      ": \\(?:ERROR\\|WARNIN\\(G\\)\\|REMAR\\(K\\)\\) \\(?:[[:alnum:] ]+, \\)?\
 275 File = \\(.+\\), Line = \\([0-9]+\\)\\(?:, Column = \\([0-9]+\\)\\)?"
 276      3 4 5 (1 . 2))
 277
 278     (sun-ada
 279      "^\\([^, \n\t]+\\), line \\([0-9]+\\), char \\([0-9]+\\)[:., \(-]" 1 2 3)
 280
 281     (4bsd
 282      "\\(?:^\\|::  \\|\\S ( \\)\\(/[^ \n\t()]+\\)(\\([0-9]+\\))\
 283 \\(?:: \\(warning:\\)?\\|$\\| ),\\)" 1 2 nil (3)))
 284   "Alist of values for `compilation-error-regexp-alist'.")
 285
 286 (defcustom compilation-error-regexp-alist
 287   (mapcar 'car compilation-error-regexp-alist-alist)
 288   "Alist that specifies how to match errors in compiler output.
 289 Note that on Unix everything is a valid filename, so these
 290 matchers must make some common sense assumptions, which catch
 291 normal cases.  A shorter list will be lighter on resource usage.
 292
 293 Instead of an alist element, you can use a symbol, which is
 294 looked up in `compilation-error-regexp-alist-alist'.  You can see
 295 the predefined symbols and their effects in the file
 296 `etc/compilation.txt' (linked below if you are customizing this).
 297
 298 Each elt has the form (REGEXP FILE [LINE COLUMN TYPE HYPERLINK
 299 HIGHLIGHT...]).  If REGEXP matches, the FILE'th subexpression
 300 gives the file name, and the LINE'th subexpression gives the line
 301 number.  The COLUMN'th subexpression gives the column number on
 302 that line.
 303
 304 If FILE, LINE or COLUMN are nil or that index didn't match, that
 305 information is not present on the matched line.  In that case the
 306 file name is assumed to be the same as the previous one in the
 307 buffer, line number defaults to 1 and column defaults to
 308 beginning of line's indentation.
 309
 310 FILE can also have the form (FILE FORMAT...), where the FORMATs
 311 \(e.g. \"%s.c\") will be applied in turn to the recognized file
 312 name, until a file of that name is found.  Or FILE can also be a
 313 function to return the filename.
 314
 315 LINE can also be of the form (LINE . END-LINE) meaning a range
 316 of lines.  COLUMN can also be of the form (COLUMN . END-COLUMN)
 317 meaning a range of columns starting on LINE and ending on
 318 END-LINE, if that matched.
 319
 320 TYPE is 2 or nil for a real error or 1 for warning or 0 for info.
 321 TYPE can also be of the form (WARNING . INFO).  In that case this
 322 will be equivalent to 1 if the WARNING'th subexpression matched
 323 or else equivalent to 0 if the INFO'th subexpression matched.
 324 See `compilation-error-face', `compilation-warning-face',
 325 `compilation-info-face' and `compilation-skip-threshold'.
 326
 327 What matched the HYPERLINK'th subexpression has `mouse-face' and
 328 `compilation-message-face' applied.  If this is nil, the text
 329 matched by the whole REGEXP becomes the hyperlink.
 330
 331 Additional HIGHLIGHTs as described under `font-lock-keywords' can
 332 be added."
 333   :type `(set :menu-tag "Pick"
 334               ,@(mapcar (lambda (elt)
 335                           (list 'const (car elt)))
 336                         compilation-error-regexp-alist-alist))
 337   :link `(file-link :tag "example file"
 338                     ,(expand-file-name "compilation.txt" data-directory))
 339   :group 'compilation)
 340
 341 (defvar compilation-directory nil
 342   "Directory to restore to when doing `recompile'.")
 343
 344 (defvar compilation-directory-matcher
 345   '("\\(?:Entering\\|Leavin\\(g\\)\\) directory `\\(.+\\)'$" (2 . 1))
 346   "A list for tracking when directories are entered or left.
 347 Nil means not to track directories, e.g. if all file names are absolute.  The
 348 first element is the REGEXP matching these messages.  It can match any number
 349 of variants, e.g. different languages.  The remaining elements are all of the
 350 form (DIR .  LEAVE).  If for any one of these the DIR'th subexpression
 351 matches, that is a directory name.  If LEAVE is nil or the corresponding
 352 LEAVE'th subexpression doesn't match, this message is about going into another
 353 directory.  If it does match anything, this message is about going back to the
 354 directory we were in before the last entering message.  If you change this,
 355 you may also want to change `compilation-page-delimiter'.")
 356
 357 (defvar compilation-page-delimiter
 358   "^\\(?:\f\\|.*\\(?:Entering\\|Leaving\\) directory `.+'\n\\)+"
 359   "Value of `page-delimiter' in Compilation mode.")
 360
 361 (defvar compilation-mode-font-lock-keywords
 362    '(;; configure output lines.
 363      ("^[Cc]hecking \\(?:[Ff]or \\|[Ii]f \\|[Ww]hether \\(?:to \\)?\\)?\\(.+\\)\\.\\.\\. *\\(?:(cached) *\\)?\\(\\(yes\\(?: .+\\)?\\)\\|no\\|\\(.*\\)\\)$"
 364       (1 font-lock-variable-name-face)
 365       (2 (compilation-face '(4 . 3))))
 366      ;; Command output lines.  Recognize `make[n]:' lines too.
 367      ("^\\([[:alnum:]_/.+-]+\\)\\(\\[\\([0-9]+\\)\\]\\)?[ \t]*:"
 368       (1 font-lock-function-name-face) (3 compilation-line-face nil t))
 369      (" --?o\\(?:utfile\\|utput\\)?[= ]?\\(\\S +\\)" . 1)
 370      ("^Compilation finished" . compilation-info-face)
 371      ("^Compilation exited abnormally" . compilation-error-face))
 372    "Additional things to highlight in Compilation mode.
 373 This gets tacked on the end of the generated expressions.")
 374
 375 (defvar compilation-highlight-regexp t
 376   "Regexp matching part of visited source lines to highlight temporarily.
 377 Highlight entire line if t; don't highlight source lines if nil.")
 378
 379 (defvar compilation-highlight-overlay nil
 380   "Overlay used to temporarily highlight compilation matches.")
 381
 382 (defcustom compilation-error-screen-columns t
 383   "*If non-nil, column numbers in error messages are screen columns.
 384 Otherwise they are interpreted as character positions, with
 385 each character occupying one column.
 386 The default is to use screen columns, which requires that the compilation
 387 program and Emacs agree about the display width of the characters,
 388 especially the TAB character."
 389   :type 'boolean
 390   :group 'compilation
 391   :version "20.4")
 392
 393 (defcustom compilation-read-command t
 394   "*Non-nil means \\[compile] reads the compilation command to use.
 395 Otherwise, \\[compile] just uses the value of `compile-command'."
 396   :type 'boolean
 397   :group 'compilation)
 398
 399 ;;;###autoload
 400 (defcustom compilation-ask-about-save t
 401   "*Non-nil means \\[compile] asks which buffers to save before compiling.
 402 Otherwise, it saves all modified buffers without asking."
 403   :type 'boolean
 404   :group 'compilation)
 405
 406 ;;;###autoload
 407 (defcustom compilation-search-path '(nil)
 408   "*List of directories to search for source files named in error messages.
 409 Elements should be directory names, not file names of directories.
 410 nil as an element means to try the default directory."
 411   :type '(repeat (choice (const :tag "Default" nil)
 412                          (string :tag "Directory")))
 413   :group 'compilation)
 414
 415 (defcustom compile-command "make -k "
 416   "*Last shell command used to do a compilation; default for next compilation.
 417
 418 Sometimes it is useful for files to supply local values for this variable.
 419 You might also use mode hooks to specify it in certain modes, like this:
 420
 421     (add-hook 'c-mode-hook
 422        (lambda ()
 423          (unless (or (file-exists-p \"makefile\")
 424                      (file-exists-p \"Makefile\"))
 425            (set (make-local-variable 'compile-command)
 426                 (concat \"make -k \"
 427                         (file-name-sans-extension buffer-file-name))))))"
 428   :type 'string
 429   :group 'compilation)
 430
 431 ;; A weak per-compilation-buffer hash indexed by (FILENAME . DIRECTORY).  Each
 432 ;; value is a FILE-STRUCTURE as described above, with the car eq to the hash
 433 ;; key.  This holds the tree seen from root, for storing new nodes.
 434 (defvar compilation-locs ())
 435
 436 (defvar compilation-debug nil
 437   "*Set this to t before creating a *compilation* buffer.
 438 Then every error line will have a debug text property with the matcher that
 439 fit this line and the match data.  Use `describe-text-properties'.")
 440
 441 (defvar compilation-exit-message-function nil "\
 442 If non-nil, called when a compilation process dies to return a status message.
 443 This should be a function of three arguments: process status, exit status,
 444 and exit message; it returns a cons (MESSAGE . MODELINE) of the strings to
 445 write into the compilation buffer, and to put in its mode line.")
 446
 447 (defvar compilation-environment nil
 448   "*List of environment variables for compilation to inherit.
 449 Each element should be a string of the form ENVVARNAME=VALUE.
 450 This list is temporarily prepended to `process-environment' prior to
 451 starting the compilation process.")
 452
 453 ;; History of compile commands.
 454 (defvar compile-history nil)
 455
 456 (defface compilation-warning-face
 457   '((((class color) (min-colors 16)) (:foreground "Orange" :weight bold))
 458     (((class color)) (:foreground "cyan" :weight bold))
 459     (t (:weight bold)))
 460   "Face used to highlight compiler warnings."
 461   :group 'font-lock-highlighting-faces
 462   :version "22.1")
 463
 464 (defface compilation-info-face
 465   '((((class color) (min-colors 16) (background light))
 466      (:foreground "Green3" :weight bold))
 467     (((class color) (min-colors 88) (background dark))
 468      (:foreground "Green1" :weight bold))
 469     (((class color) (min-colors 16) (background dark))
 470      (:foreground "Green" :weight bold))
 471     (((class color)) (:foreground "green" :weight bold))
 472     (t (:weight bold)))
 473   "Face used to highlight compiler warnings."
 474   :group 'font-lock-highlighting-faces
 475   :version "22.1")
 476
 477 (defvar compilation-message-face nil
 478   "Face name to use for whole messages.
 479 Faces `compilation-error-face', `compilation-warning-face',
 480 `compilation-info-face', `compilation-line-face' and
 481 `compilation-column-face' get prepended to this, when applicable.")
 482
 483 (defvar compilation-error-face 'font-lock-warning-face
 484   "Face name to use for file name in error messages.")
 485
 486 (defvar compilation-warning-face 'compilation-warning-face
 487   "Face name to use for file name in warning messages.")
 488
 489 (defvar compilation-info-face 'compilation-info-face
 490   "Face name to use for file name in informational messages.")
 491
 492 (defvar compilation-line-face 'font-lock-variable-name-face
 493   "Face name to use for line number in message.")
 494
 495 (defvar compilation-column-face 'font-lock-type-face
 496   "Face name to use for column number in message.")
 497
 498 ;; same faces as dired uses
 499 (defvar compilation-enter-directory-face 'font-lock-function-name-face
 500   "Face name to use for column number in message.")
 501
 502 (defvar compilation-leave-directory-face 'font-lock-type-face
 503   "Face name to use for column number in message.")
 504
 505
 506
 507 ;; Used for compatibility with the old compile.el.
 508 (defvaralias 'compilation-last-buffer 'next-error-last-buffer)
 509 (defvar compilation-parsing-end (make-marker))
 510 (defvar compilation-parse-errors-function nil)
 511 (defvar compilation-error-list nil)
 512 (defvar compilation-old-error-list nil)
 513
 514 (defun compilation-face (type)
 515   (or (and (car type) (match-end (car type)) compilation-warning-face)
 516       (and (cdr type) (match-end (cdr type)) compilation-info-face)
 517       compilation-error-face))
 518
 519 ;; Internal function for calculating the text properties of a directory
 520 ;; change message.  The directory property is important, because it is
 521 ;; the stack of nested enter-messages.  Relative filenames on the following
 522 ;; lines are relative to the top of the stack.
 523 (defun compilation-directory-properties (idx leave)
 524   (if leave (setq leave (match-end leave)))
 525   ;; find previous stack, and push onto it, or if `leave' pop it
 526   (let ((dir (previous-single-property-change (point) 'directory)))
 527     (setq dir (if dir (or (get-text-property (1- dir) 'directory)
 528                           (get-text-property dir 'directory))))
 529     `(face ,(if leave
 530                 compilation-leave-directory-face
 531               compilation-enter-directory-face)
 532       directory ,(if leave
 533                      (or (cdr dir)
 534                          '(nil))        ; nil only isn't a property-change
 535                    (cons (match-string-no-properties idx) dir))
 536       mouse-face highlight
 537       keymap compilation-button-map
 538       help-echo "mouse-2: visit current directory")))
 539
 540 ;; Data type `reverse-ordered-alist' retriever.  This function retrieves the
 541 ;; KEY element from the ALIST, creating it in the right position if not already
 542 ;; present. ALIST structure is
 543 ;; '(ANCHOR (KEY1 ...) (KEY2 ...)... (KEYn ALIST ...))
 544 ;; ANCHOR is ignored, but necessary so that elements can be inserted.  KEY1
 545 ;; may be nil.  The other KEYs are ordered backwards so that growing line
 546 ;; numbers can be inserted in front and searching can abort after half the
 547 ;; list on average.
 548 (eval-when-compile                  ;Don't keep it at runtime if not needed.
 549 (defmacro compilation-assq (key alist)
 550   `(let* ((l1 ,alist)
 551           (l2 (cdr l1)))
 552      (car (if (if (null ,key)
 553                   (if l2 (null (caar l2)))
 554                 (while (if l2 (if (caar l2) (< ,key (caar l2)) t))
 555                   (setq l1 l2
 556                         l2 (cdr l1)))
 557                 (if l2 (eq ,key (caar l2))))
 558               l2
 559             (setcdr l1 (cons (list ,key) l2)))))))
 560
 561
 562 ;; This function is the central driver, called when font-locking to gather
 563 ;; all information needed to later jump to corresponding source code.
 564 ;; Return a property list with all meta information on this error location.
 565 (defun compilation-error-properties (file line end-line col end-col type fmt)
 566   (unless (< (next-single-property-change (match-beginning 0) 'directory nil (point))
 567              (point))
 568     (if file
 569         (if (functionp file)
 570             (setq file (funcall file))
 571           (let (dir)
 572             (setq file (match-string-no-properties file))
 573             (unless (file-name-absolute-p file)
 574               (setq dir (previous-single-property-change (point) 'directory)
 575                     dir (if dir (or (get-text-property (1- dir) 'directory)
 576                                     (get-text-property dir 'directory)))))
 577             (setq file (cons file (car dir)))))
 578       ;; This message didn't mention one, get it from previous
 579       (setq file (previous-single-property-change (point) 'message)
 580             file (or (if file
 581                          (car (nth 2 (car (or (get-text-property (1- file) 'message)
 582                                          (get-text-property file 'message))))))
 583                      '("*unknown*"))))
 584     ;; All of these fields are optional, get them only if we have an index, and
 585     ;; it matched some part of the message.
 586     (and line
 587          (setq line (match-string-no-properties line))
 588          (setq line (string-to-number line)))
 589     (and end-line
 590          (setq end-line (match-string-no-properties end-line))
 591          (setq end-line (string-to-number end-line)))
 592     (if col
 593         (if (functionp col)
 594             (setq col (funcall col))
 595           (and
 596            (setq col (match-string-no-properties col))
 597            (setq col (- (string-to-number col) compilation-first-column)))))
 598     (if (and end-col (functionp end-col))
 599         (setq end-col (funcall end-col))
 600       (if (and end-col (setq end-col (match-string-no-properties end-col)))
 601           (setq end-col (- (string-to-number end-col) compilation-first-column -1))
 602         (if end-line (setq end-col -1))))
 603     (if (consp type)                    ; not a static type, check what it is.
 604         (setq type (or (and (car type) (match-end (car type)) 1)
 605                        (and (cdr type) (match-end (cdr type)) 0)
 606                        2)))
 607     (compilation-internal-error-properties file line end-line col end-col type fmt)))
 608
 609 (defun compilation-move-to-column (col screen)
 610   "Go to column COL on the current line.
 611 If SCREEN is non-nil, columns are screen columns, otherwise, they are
 612 just char-counts."
 613   (if screen
 614       (move-to-column col)
 615     (goto-char (min (+ (line-beginning-position) col) (line-end-position)))))
 616
 617 (defun compilation-internal-error-properties (file line end-line col end-col type fmt)
 618   "Get the meta-info that will be added as text-properties.
 619 LINE, END-LINE, COL, END-COL are integers or nil.
 620 TYPE can be 0, 1, or 2.
 621 FILE should be (ABSOLUTE-FILENAME) or (RELATIVE-FILENAME . DIRNAME) or nil."
 622   (unless file (setq file '("*unknown*")))
 623   (setq file (compilation-get-file-structure file fmt))
 624   ;; Get first already existing marker (if any has one, all have one).
 625   ;; Do this first, as the compilation-assq`s may create new nodes.
 626   (let* ((marker-line (car (cddr file)))        ; a line structure
 627          (marker (nth 3 (cadr marker-line)))    ; its marker
 628          (compilation-error-screen-columns compilation-error-screen-columns)
 629          end-marker loc end-loc)
 630     (if (not (and marker (marker-buffer marker)))
 631         (setq marker)                   ; no valid marker for this file
 632       (setq loc (or line 1))            ; normalize no linenumber to line 1
 633       (catch 'marker                    ; find nearest loc, at least one exists
 634         (dolist (x (nthcdr 3 file))     ; loop over remaining lines
 635           (if (> (car x) loc)           ; still bigger
 636               (setq marker-line x)
 637             (if (> (- (or (car marker-line) 1) loc)
 638                    (- loc (car x)))     ; current line is nearer
 639                 (setq marker-line x))
 640             (throw 'marker t))))
 641       (setq marker (nth 3 (cadr marker-line))
 642             marker-line (or (car marker-line) 1))
 643       (with-current-buffer (marker-buffer marker)
 644         (save-restriction
 645           (widen)
 646           (goto-char (marker-position marker))
 647           (when (or end-col end-line)
 648             (beginning-of-line (- (or end-line line) marker-line -1))
 649             (if (or (null end-col) (< end-col 0))
 650                 (end-of-line)
 651               (compilation-move-to-column
 652                end-col compilation-error-screen-columns))
 653             (setq end-marker (list (point-marker))))
 654           (beginning-of-line (if end-line
 655                                  (- line end-line -1)
 656                                (- loc marker-line -1)))
 657           (if col
 658               (compilation-move-to-column
 659                col compilation-error-screen-columns)
 660             (forward-to-indentation 0))
 661           (setq marker (list (point-marker))))))
 662
 663     (setq loc (compilation-assq line (cdr file)))
 664     (if end-line
 665         (setq end-loc (compilation-assq end-line (cdr file))
 666               end-loc (compilation-assq end-col end-loc))
 667       (if end-col                       ; use same line element
 668           (setq end-loc (compilation-assq end-col loc))))
 669     (setq loc (compilation-assq col loc))
 670     ;; If they are new, make the loc(s) reference the file they point to.
 671     (or (cdr loc) (setcdr loc `(,line ,file ,@marker)))
 672     (if end-loc
 673         (or (cdr end-loc) (setcdr end-loc `(,(or end-line line) ,file ,@end-marker))))
 674
 675     ;; Must start with face
 676     `(face ,compilation-message-face
 677            message (,loc ,type ,end-loc)
 678            ,@(if compilation-debug
 679                  `(debug (,(assoc (with-no-warnings matcher) font-lock-keywords)
 680                           ,@(match-data))))
 681            help-echo ,(if col
 682                           "mouse-2: visit this file, line and column"
 683                         (if line
 684                             "mouse-2: visit this file and line"
 685                           "mouse-2: visit this file"))
 686            keymap compilation-button-map
 687            mouse-face highlight)))
 688
 689 (defun compilation-mode-font-lock-keywords ()
 690   "Return expressions to highlight in Compilation mode."
 691   (if compilation-parse-errors-function
 692       ;; An old package!  Try the compatibility code.
 693       '((compilation-compat-parse-errors))
 694     (append
 695      ;; make directory tracking
 696      (if compilation-directory-matcher
 697          `((,(car compilation-directory-matcher)
 698             ,@(mapcar (lambda (elt)
 699                         `(,(car elt)
 700                           (compilation-directory-properties
 701                            ,(car elt) ,(cdr elt))
 702                           t))
 703                       (cdr compilation-directory-matcher)))))
 704
 705      ;; Compiler warning/error lines.
 706      (mapcar
 707       (lambda (item)
 708         (if (symbolp item)
 709             (setq item (cdr (assq item
 710                                   compilation-error-regexp-alist-alist))))
 711         (let ((file (nth 1 item))
 712               (line (nth 2 item))
 713               (col (nth 3 item))
 714               (type (nth 4 item))
 715               end-line end-col fmt)
 716           (if (consp file)      (setq fmt (cdr file)      file (car file)))
 717           (if (consp line)      (setq end-line (cdr line) line (car line)))
 718           (if (consp col)       (setq end-col (cdr col)   col (car col)))
 719
 720           (if (functionp line)
 721               ;; The old compile.el had here an undocumented hook that
 722               ;; allowed `line' to be a function that computed the actual
 723               ;; error location.  Let's do our best.
 724               `(,(car item)
 725                 (0 (compilation-compat-error-properties
 726                     (funcall ',line (cons (match-string ,file)
 727                                           (cons default-directory
 728                                                 ',(nthcdr 4 item)))
 729                              ,(if col `(match-string ,col)))))
 730                 (,file compilation-error-face t))
 731
 732             (unless (or (null (nth 5 item)) (integerp (nth 5 item)))
 733               (error "HYPERLINK should be an integer: %s" (nth 5 item)))
 734
 735             `(,(nth 0 item)
 736
 737               ,@(when (integerp file)
 738                   `((,file ,(if (consp type)
 739                                 `(compilation-face ',type)
 740                               (aref [compilation-info-face
 741                                      compilation-warning-face
 742                                      compilation-error-face]
 743                                     (or type 2))))))
 744
 745               ,@(when line
 746                   `((,line compilation-line-face nil t)))
 747               ,@(when end-line
 748                   `((,end-line compilation-line-face nil t)))
 749
 750               ,@(when (integerp col)
 751                   `((,col compilation-column-face nil t)))
 752               ,@(when (integerp end-col)
 753                   `((,end-col compilation-column-face nil t)))
 754
 755               ,@(nthcdr 6 item)
 756               (,(or (nth 5 item) 0)
 757                (compilation-error-properties ',file ,line ,end-line
 758                                              ,col ,end-col ',(or type 2)
 759                                              ',fmt)
 760                append)))))              ; for compilation-message-face
 761       compilation-error-regexp-alist)
 762
 763      compilation-mode-font-lock-keywords)))
 764
 765 \f
 766 ;;;###autoload
 767 (defun compile (command &optional comint)
 768   "Compile the program including the current buffer.  Default: run `make'.
 769 Runs COMMAND, a shell command, in a separate process asynchronously
 770 with output going to the buffer `*compilation*'.
 771
 772 If optional second arg COMINT is t the buffer will be in Comint mode with
 773 `compilation-shell-minor-mode'.
 774
 775 You can then use the command \\[next-error] to find the next error message
 776 and move to the source code that caused it.
 777
 778 Interactively, prompts for the command if `compilation-read-command' is
 779 non-nil; otherwise uses `compile-command'.  With prefix arg, always prompts.
 780 Additionally, with universal prefix arg, compilation buffer will be in
 781 comint mode, i.e. interactive.
 782
 783 To run more than one compilation at once, start one and rename
 784 the \`*compilation*' buffer to some other name with
 785 \\[rename-buffer].  Then start the next one.  On most systems,
 786 termination of the main compilation process kills its
 787 subprocesses.
 788
 789 The name used for the buffer is actually whatever is returned by
 790 the function in `compilation-buffer-name-function', so you can set that
 791 to a function that generates a unique name."
 792   (interactive
 793    (list
 794     (let ((command (eval compile-command)))
 795       (if (or compilation-read-command current-prefix-arg)
 796           (read-from-minibuffer "Compile command: "
 797                                 command nil nil
 798                                 (if (equal (car compile-history) command)
 799                                     '(compile-history . 1)
 800                                   'compile-history))
 801         command))
 802     (consp current-prefix-arg)))
 803   (unless (equal command (eval compile-command))
 804     (setq compile-command command))
 805   (save-some-buffers (not compilation-ask-about-save) nil)
 806   (setq compilation-directory default-directory)
 807   (compilation-start command comint))
 808
 809 ;; run compile with the default command line
 810 (defun recompile ()
 811   "Re-compile the program including the current buffer.
 812 If this is run in a Compilation mode buffer, re-use the arguments from the
 813 original use.  Otherwise, recompile using `compile-command'."
 814   (interactive)
 815   (save-some-buffers (not compilation-ask-about-save) nil)
 816   (let ((default-directory
 817           (or (and (not (eq major-mode (nth 1 compilation-arguments)))
 818                    compilation-directory)
 819               default-directory)))
 820     (apply 'compilation-start (or compilation-arguments
 821                                   `(,(eval compile-command))))))
 822
 823 (defcustom compilation-scroll-output nil
 824   "*Non-nil to scroll the *compilation* buffer window as output appears.
 825
 826 Setting it causes the Compilation mode commands to put point at the
 827 end of their output window so that the end of the output is always
 828 visible rather than the beginning."
 829   :type 'boolean
 830   :version "20.3"
 831   :group 'compilation)
 832
 833
 834 (defun compilation-buffer-name (mode-name name-function)
 835   "Return the name of a compilation buffer to use.
 836 If NAME-FUNCTION is non-nil, call it with one argument MODE-NAME
 837 to determine the buffer name.
 838 Likewise if `compilation-buffer-name-function' is non-nil.
 839 If current buffer is in Compilation mode for the same mode name
 840 return the name of the current buffer, so that it gets reused.
 841 Otherwise, construct a buffer name from MODE-NAME."
 842   (cond (name-function
 843          (funcall name-function mode-name))
 844         (compilation-buffer-name-function
 845          (funcall compilation-buffer-name-function mode-name))
 846         ((eq major-mode (nth 1 compilation-arguments))
 847          (buffer-name))
 848         (t
 849          (concat "*" (downcase mode-name) "*"))))
 850
 851 ;; This is a rough emulation of the old hack, until the transition to new
 852 ;; compile is complete.
 853 (defun compile-internal (command error-message
 854                                  &optional name-of-mode parser
 855                                  error-regexp-alist name-function
 856                                  enter-regexp-alist leave-regexp-alist
 857                                  file-regexp-alist nomessage-regexp-alist
 858                                  no-async highlight-regexp local-map)
 859   (if parser
 860       (error "Compile now works very differently, see `compilation-error-regexp-alist'"))
 861   (let ((compilation-error-regexp-alist
 862          (append file-regexp-alist (or error-regexp-alist
 863                                        compilation-error-regexp-alist)))
 864         (compilation-error (replace-regexp-in-string "^No more \\(.+\\)s\\.?"
 865                                                      "\\1" error-message)))
 866     (compilation-start command nil name-function highlight-regexp)))
 867 (make-obsolete 'compile-internal 'compilation-start)
 868
 869 (defun compilation-start (command &optional mode name-function highlight-regexp)
 870   "Run compilation command COMMAND (low level interface).
 871 If COMMAND starts with a cd command, that becomes the `default-directory'.
 872 The rest of the arguments are optional; for them, nil means use the default.
 873
 874 MODE is the major mode to set in the compilation buffer.  Mode
 875 may also be t meaning use `compilation-shell-minor-mode' under `comint-mode'.
 876 NAME-FUNCTION is a function called to name the buffer.
 877
 878 If HIGHLIGHT-REGEXP is non-nil, `next-error' will temporarily highlight
 879 the matching section of the visited source line; the default is to use the
 880 global value of `compilation-highlight-regexp'.
 881
 882 Returns the compilation buffer created."
 883   (or mode (setq mode 'compilation-mode))
 884   (let* ((name-of-mode
 885           (if (eq mode t)
 886               (prog1 "compilation" (require 'comint))
 887             (replace-regexp-in-string "-mode$" "" (symbol-name mode))))
 888          (thisdir default-directory)
 889          outwin outbuf)
 890     (with-current-buffer
 891         (setq outbuf
 892               (get-buffer-create
 893                (compilation-buffer-name name-of-mode name-function)))
 894       (let ((comp-proc (get-buffer-process (current-buffer))))
 895         (if comp-proc
 896             (if (or (not (eq (process-status comp-proc) 'run))
 897                     (yes-or-no-p
 898                      (format "A %s process is running; kill it? "
 899                              name-of-mode)))
 900                 (condition-case ()
 901                     (progn
 902                       (interrupt-process comp-proc)
 903                       (sit-for 1)
 904                       (delete-process comp-proc))
 905                   (error nil))
 906               (error "Cannot have two processes in `%s' at once"
 907                      (buffer-name)))))
 908       (buffer-disable-undo (current-buffer))
 909       ;; first transfer directory from where M-x compile was called
 910       (setq default-directory thisdir)
 911       ;; Make compilation buffer read-only.  The filter can still write it.
 912       ;; Clear out the compilation buffer.
 913       (let ((inhibit-read-only t)
 914             (default-directory thisdir))
 915         ;; Then evaluate a cd command if any, but don't perform it yet, else start-command
 916         ;; would do it again through the shell: (cd "..") AND sh -c "cd ..; make"
 917         (cd (if (string-match "^\\s *cd\\(?:\\s +\\(\\S +?\\)\\)?\\s *[;&\n]" command)
 918                 (if (match-end 1)
 919                     (substitute-env-vars (match-string 1 command))
 920                   "~")
 921               default-directory))
 922         (erase-buffer)
 923         ;; output a mode setter, for saving and later reloading this buffer
 924         (insert "-*- mode: " name-of-mode
 925                 "; default-directory: " (prin1-to-string default-directory)
 926                 " -*-\n" command "\n")
 927         (setq thisdir default-directory))
 928       (set-buffer-modified-p nil))
 929     ;; If we're already in the compilation buffer, go to the end
 930     ;; of the buffer, so point will track the compilation output.
 931     (if (eq outbuf (current-buffer))
 932         (goto-char (point-max)))
 933     ;; Pop up the compilation buffer.
 934     (setq outwin (display-buffer outbuf nil t))
 935     (with-current-buffer outbuf
 936       (let ((process-environment
 937              (append
 938               compilation-environment
 939               (if (if (boundp 'system-uses-terminfo) ; `if' for compiler warning
 940                       system-uses-terminfo)
 941                   (list "TERM=dumb" "TERMCAP="
 942                         (format "COLUMNS=%d" (window-width)))
 943                 (list "TERM=emacs"
 944                       (format "TERMCAP=emacs:co#%d:tc=unknown:"
 945                               (window-width))))
 946               ;; Set the EMACS variable, but
 947               ;; don't override users' setting of $EMACS.
 948               (unless (getenv "EMACS") '("EMACS=t"))
 949               (copy-sequence process-environment))))
 950         (if (not (eq mode t))
 951             (funcall mode)
 952           (setq buffer-read-only nil)
 953           (with-no-warnings (comint-mode))
 954           (compilation-shell-minor-mode))
 955         (if highlight-regexp
 956             (set (make-local-variable 'compilation-highlight-regexp)
 957                  highlight-regexp))
 958         (set (make-local-variable 'compilation-arguments)
 959              (list command mode name-function highlight-regexp))
 960         (set (make-local-variable 'revert-buffer-function)
 961              'compilation-revert-buffer)
 962         (set-window-start outwin (point-min))
 963         (or (eq outwin (selected-window))
 964             (set-window-point outwin (if compilation-scroll-output
 965                                          (point)
 966                                        (point-min))))
 967         ;; The setup function is called before compilation-set-window-height
 968         ;; so it can set the compilation-window-height buffer locally.
 969         (if compilation-process-setup-function
 970             (funcall compilation-process-setup-function))
 971         (compilation-set-window-height outwin)
 972         ;; Start the compilation.
 973         (if (fboundp 'start-process)
 974             (let ((proc (if (eq mode t)
 975                             (get-buffer-process
 976                              (with-no-warnings
 977                               (comint-exec outbuf (downcase mode-name)
 978                                            shell-file-name nil `("-c" ,command))))
 979                           (start-process-shell-command (downcase mode-name)
 980                                                        outbuf command))))
 981               ;; Make the buffer's mode line show process state.
 982               (setq mode-line-process '(":%s"))
 983               (set-process-sentinel proc 'compilation-sentinel)
 984               (set-process-filter proc 'compilation-filter)
 985               (set-marker (process-mark proc) (point) outbuf)
 986               (setq compilation-in-progress
 987                     (cons proc compilation-in-progress)))
 988           ;; No asynchronous processes available.
 989           (message "Executing `%s'..." command)
 990           ;; Fake modeline display as if `start-process' were run.
 991           (setq mode-line-process ":run")
 992           (force-mode-line-update)
 993           (sit-for 0)                   ; Force redisplay
 994           (let* ((buffer-read-only nil) ; call-process needs to modify outbuf
 995                  (status (call-process shell-file-name nil outbuf nil "-c"
 996                                        command)))
 997             (cond ((numberp status)
 998                    (compilation-handle-exit 'exit status
 999                                             (if (zerop status)
1000                                                 "finished\n"
1001                                               (format "\
1002 exited abnormally with code %d\n"
1003                                                       status))))
1004                   ((stringp status)
1005                    (compilation-handle-exit 'signal status
1006                                             (concat status "\n")))
1007                   (t
1008                    (compilation-handle-exit 'bizarre status status))))
1009           ;; Without async subprocesses, the buffer is not yet
1010           ;; fontified, so fontify it now.
1011           (let ((font-lock-verbose nil)) ; shut up font-lock messages
1012             (font-lock-fontify-buffer))
1013           (set-buffer-modified-p nil)
1014           (message "Executing `%s'...done" command)))
1015       ;; Now finally cd to where the shell started make/grep/...
1016       (setq default-directory thisdir))
1017     (if (buffer-local-value 'compilation-scroll-output outbuf)
1018         (save-selected-window
1019           (select-window outwin)
1020           (goto-char (point-max))))
1021     ;; Make it so the next C-x ` will use this buffer.
1022     (setq next-error-last-buffer outbuf)))
1023
1024 (defun compilation-set-window-height (window)
1025   "Set the height of WINDOW according to `compilation-window-height'."
1026   (let ((height (buffer-local-value 'compilation-window-height (window-buffer window))))
1027     (and height
1028          (= (window-width window) (frame-width (window-frame window)))
1029          ;; If window is alone in its frame, aside from a minibuffer,
1030          ;; don't change its height.
1031          (not (eq window (frame-root-window (window-frame window))))
1032          ;; Stef said that doing the saves in this order is safer:
1033          (save-excursion
1034            (save-selected-window
1035              (select-window window)
1036              (enlarge-window (- height (window-height))))))))
1037
1038 (defvar compilation-menu-map
1039   (let ((map (make-sparse-keymap "Errors")))
1040     (define-key map [stop-subjob]
1041       '("Stop Compilation" . kill-compilation))
1042     (define-key map [compilation-mode-separator2]
1043       '("----" . nil))
1044     (define-key map [compilation-first-error]
1045       '("First Error" . first-error))
1046     (define-key map [compilation-previous-error]
1047       '("Previous Error" . previous-error))
1048     (define-key map [compilation-next-error]
1049       '("Next Error" . next-error))
1050     map))
1051
1052 (defvar compilation-minor-mode-map
1053   (let ((map (make-sparse-keymap)))
1054     (define-key map [mouse-2] 'compile-goto-error)
1055     (define-key map [follow-link] 'mouse-face)
1056     (define-key map "\C-c\C-c" 'compile-goto-error)
1057     (define-key map "\C-m" 'compile-goto-error)
1058     (define-key map "\C-c\C-k" 'kill-compilation)
1059     (define-key map "\M-n" 'compilation-next-error)
1060     (define-key map "\M-p" 'compilation-previous-error)
1061     (define-key map "\M-{" 'compilation-previous-file)
1062     (define-key map "\M-}" 'compilation-next-file)
1063     ;; Set up the menu-bar
1064     (define-key map [menu-bar compilation]
1065       (cons "Errors" compilation-menu-map))
1066     map)
1067   "Keymap for `compilation-minor-mode'.")
1068
1069 (defvar compilation-shell-minor-mode-map
1070   (let ((map (make-sparse-keymap)))
1071     (define-key map "\M-\C-m" 'compile-goto-error)
1072     (define-key map "\M-\C-n" 'compilation-next-error)
1073     (define-key map "\M-\C-p" 'compilation-previous-error)
1074     (define-key map "\M-{" 'compilation-previous-file)
1075     (define-key map "\M-}" 'compilation-next-file)
1076     ;; Set up the menu-bar
1077     (define-key map [menu-bar compilation]
1078       (cons "Errors" compilation-menu-map))
1079     map)
1080   "Keymap for `compilation-shell-minor-mode'.")
1081
1082 (defvar compilation-button-map
1083   (let ((map (make-sparse-keymap)))
1084     (define-key map [mouse-2] 'compile-goto-error)
1085     (define-key map [follow-link] 'mouse-face)
1086     (define-key map "\C-m" 'compile-goto-error)
1087     map)
1088   "Keymap for compilation-message buttons.")
1089 (fset 'compilation-button-map compilation-button-map)
1090
1091 (defvar compilation-mode-map
1092   (let ((map (make-sparse-keymap)))
1093     ;; Don't inherit from compilation-minor-mode-map,
1094     ;; because that introduces a menu bar item we don't want.
1095     ;; That confuses C-down-mouse-3.
1096     (define-key map [mouse-2] 'compile-goto-error)
1097     (define-key map [follow-link] 'mouse-face)
1098     (define-key map "\C-c\C-c" 'compile-goto-error)
1099     (define-key map "\C-m" 'compile-goto-error)
1100     (define-key map "\C-c\C-k" 'kill-compilation)
1101     (define-key map "\M-n" 'compilation-next-error)
1102     (define-key map "\M-p" 'compilation-previous-error)
1103     (define-key map "\M-{" 'compilation-previous-file)
1104     (define-key map "\M-}" 'compilation-next-file)
1105
1106     (define-key map " " 'scroll-up)
1107     (define-key map "\^?" 'scroll-down)
1108     (define-key map "\C-c\C-f" 'next-error-follow-minor-mode)
1109
1110     ;; Set up the menu-bar
1111     (let ((submap (make-sparse-keymap "Compile")))
1112       (define-key map [menu-bar compilation]
1113         (cons "Compile" submap))
1114       (set-keymap-parent submap compilation-menu-map))
1115     (define-key map [menu-bar compilation compilation-separator2]
1116       '("----" . nil))
1117     (define-key map [menu-bar compilation compilation-grep]
1118       '("Search Files (grep)" . grep))
1119     (define-key map [menu-bar compilation compilation-recompile]
1120       '("Recompile" . recompile))
1121     (define-key map [menu-bar compilation compilation-compile]
1122       '("Compile..." . compile))
1123     map)
1124   "Keymap for compilation log buffers.
1125 `compilation-minor-mode-map' is a parent of this.")
1126
1127 (put 'compilation-mode 'mode-class 'special)
1128
1129 (defvar compilation-skip-to-next-location t
1130   "*If non-nil, skip multiple error messages for the same source location.")
1131
1132 (defcustom compilation-skip-threshold 1
1133   "*Compilation motion commands skip less important messages.
1134 The value can be either 2 -- skip anything less than error, 1 --
1135 skip anything less than warning or 0 -- don't skip any messages.
1136 Note that all messages not positively identified as warning or
1137 info, are considered errors."
1138   :type '(choice (const :tag "Warnings and info" 2)
1139                  (const :tag "Info" 1)
1140                  (const :tag "None" 0))
1141   :group 'compilation
1142   :version "22.1")
1143
1144 (defcustom compilation-skip-visited nil
1145   "*Compilation motion commands skip visited messages if this is t.
1146 Visited messages are ones for which the file, line and column have been jumped
1147 to from the current content in the current compilation buffer, even if it was
1148 from a different message."
1149   :type 'boolean
1150   :group 'compilation
1151   :version "22.1")
1152
1153 ;;;###autoload
1154 (defun compilation-mode (&optional name-of-mode)
1155   "Major mode for compilation log buffers.
1156 \\<compilation-mode-map>To visit the source for a line-numbered error,
1157 move point to the error message line and type \\[compile-goto-error].
1158 To kill the compilation, type \\[kill-compilation].
1159
1160 Runs `compilation-mode-hook' with `run-hooks' (which see).
1161
1162 \\{compilation-mode-map}"
1163   (interactive)
1164   (kill-all-local-variables)
1165   (use-local-map compilation-mode-map)
1166   (setq major-mode 'compilation-mode
1167         mode-name (or name-of-mode "Compilation"))
1168   (set (make-local-variable 'page-delimiter)
1169        compilation-page-delimiter)
1170   (compilation-setup)
1171   (setq buffer-read-only t)
1172   (run-mode-hooks 'compilation-mode-hook))
1173
1174 (defmacro define-compilation-mode (mode name doc &rest body)
1175   "This is like `define-derived-mode' without the PARENT argument.
1176 The parent is always `compilation-mode' and the customizable `compilation-...'
1177 variables are also set from the name of the mode you have chosen, by replacing
1178 the fist word, e.g `compilation-scroll-output' from `grep-scroll-output' if that
1179 variable exists."
1180   (let ((mode-name (replace-regexp-in-string "-mode\\'" "" (symbol-name mode))))
1181     `(define-derived-mode ,mode compilation-mode ,name
1182        ,doc
1183        ,@(mapcar (lambda (v)
1184                    (setq v (cons v
1185                                  (intern-soft (replace-regexp-in-string
1186                                                "^compilation" mode-name
1187                                                (symbol-name v)))))
1188                    (and (cdr v)
1189                         (or (boundp (cdr v))
1190                             (if (boundp 'byte-compile-bound-variables)
1191                                 (memq (cdr v) byte-compile-bound-variables)))
1192                         `(set (make-local-variable ',(car v)) ,(cdr v))))
1193                  '(compilation-buffer-name-function
1194                    compilation-directory-matcher
1195                    compilation-error
1196                    compilation-error-regexp-alist
1197                    compilation-error-regexp-alist-alist
1198                    compilation-error-screen-columns
1199                    compilation-finish-function
1200                    compilation-finish-functions
1201                    compilation-first-column
1202                    compilation-mode-font-lock-keywords
1203                    compilation-page-delimiter
1204                    compilation-parse-errors-filename-function
1205                    compilation-process-setup-function
1206                    compilation-scroll-output
1207                    compilation-search-path
1208                    compilation-skip-threshold
1209                    compilation-window-height))
1210        ,@body)))
1211
1212 (defun compilation-revert-buffer (ignore-auto noconfirm)
1213   (if buffer-file-name
1214       (let (revert-buffer-function)
1215         (revert-buffer ignore-auto noconfirm))
1216     (if (or noconfirm (yes-or-no-p (format "Restart compilation? ")))
1217         (apply 'compilation-start compilation-arguments))))
1218
1219 (defvar compilation-current-error nil
1220   "Marker to the location from where the next error will be found.
1221 The global commands next/previous/first-error/goto-error use this.")
1222
1223 (defvar compilation-messages-start nil
1224   "Buffer position of the beginning of the compilation messages.
1225 If nil, use the beginning of buffer.")
1226
1227 ;; A function name can't be a hook, must be something with a value.
1228 (defconst compilation-turn-on-font-lock 'turn-on-font-lock)
1229
1230 (defun compilation-setup (&optional minor)
1231   "Prepare the buffer for the compilation parsing commands to work.
1232 Optional argument MINOR indicates this is called from
1233 `compilation-minor-mode'."
1234   (make-local-variable 'compilation-current-error)
1235   (make-local-variable 'compilation-messages-start)
1236   (make-local-variable 'compilation-error-screen-columns)
1237   (make-local-variable 'overlay-arrow-position)
1238   (set (make-local-variable 'overlay-arrow-string) "=>")
1239   (setq next-error-overlay-arrow-position nil)
1240   (add-hook 'kill-buffer-hook
1241             (lambda () (setq next-error-overlay-arrow-position nil)) nil t)
1242   ;; Note that compilation-next-error-function is for interfacing
1243   ;; with the next-error function in simple.el, and it's only
1244   ;; coincidentally named similarly to compilation-next-error.
1245   (setq next-error-function 'compilation-next-error-function)
1246   (set (make-local-variable 'font-lock-extra-managed-props)
1247        '(directory message help-echo mouse-face debug))
1248   (set (make-local-variable 'compilation-locs)
1249        (make-hash-table :test 'equal :weakness 'value))
1250   ;; lazy-lock would never find the message unless it's scrolled to.
1251   ;; jit-lock might fontify some things too late.
1252   (set (make-local-variable 'font-lock-support-mode) nil)
1253   (set (make-local-variable 'font-lock-maximum-size) nil)
1254   (let ((fld font-lock-defaults))
1255     (if (and minor fld)
1256         (font-lock-add-keywords nil (compilation-mode-font-lock-keywords))
1257       (setq font-lock-defaults '(compilation-mode-font-lock-keywords t)))
1258     (if minor
1259         (if font-lock-mode
1260             (if fld
1261                 (font-lock-fontify-buffer)
1262               (font-lock-change-mode)
1263               (turn-on-font-lock))
1264           (turn-on-font-lock))
1265       ;; maybe defer font-lock till after derived mode is set up
1266       (run-mode-hooks 'compilation-turn-on-font-lock))))
1267
1268 ;;;###autoload
1269 (define-minor-mode compilation-shell-minor-mode
1270   "Toggle compilation shell minor mode.
1271 With arg, turn compilation mode on if and only if arg is positive.
1272 In this minor mode, all the error-parsing commands of the
1273 Compilation major mode are available but bound to keys that don't
1274 collide with Shell mode.  See `compilation-mode'.
1275 Turning the mode on runs the normal hook `compilation-shell-minor-mode-hook'."
1276   nil " Shell-Compile"
1277   :group 'compilation
1278   (if compilation-shell-minor-mode
1279       (compilation-setup t)
1280     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1281     (font-lock-fontify-buffer)))
1282
1283 ;;;###autoload
1284 (define-minor-mode compilation-minor-mode
1285   "Toggle compilation minor mode.
1286 With arg, turn compilation mode on if and only if arg is positive.
1287 In this minor mode, all the error-parsing commands of the
1288 Compilation major mode are available.  See `compilation-mode'.
1289 Turning the mode on runs the normal hook `compilation-minor-mode-hook'."
1290   nil " Compilation"
1291   :group 'compilation
1292   (if compilation-minor-mode
1293       (compilation-setup t)
1294     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1295     (font-lock-fontify-buffer)))
1296
1297 (defun compilation-handle-exit (process-status exit-status msg)
1298   "Write MSG in the current buffer and hack its mode-line-process."
1299   (let ((inhibit-read-only t)
1300         (status (if compilation-exit-message-function
1301                     (funcall compilation-exit-message-function
1302                              process-status exit-status msg)
1303                   (cons msg exit-status)))
1304         (omax (point-max))
1305         (opoint (point)))
1306     ;; Record where we put the message, so we can ignore it later on.
1307     (goto-char omax)
1308     (insert ?\n mode-name " " (car status))
1309     (if (and (numberp compilation-window-height)
1310              (zerop compilation-window-height))
1311         (message "%s" (cdr status)))
1312     (if (bolp)
1313         (forward-char -1))
1314     (insert " at " (substring (current-time-string) 0 19))
1315     (goto-char (point-max))
1316     ;; Prevent that message from being recognized as a compilation error.
1317     (add-text-properties omax (point)
1318                          (append '(compilation-handle-exit t) nil))
1319     (setq mode-line-process (format ":%s [%s]" process-status (cdr status)))
1320     ;; Force mode line redisplay soon.
1321     (force-mode-line-update)
1322     (if (and opoint (< opoint omax))
1323         (goto-char opoint))
1324     (if compilation-finish-function
1325         (funcall compilation-finish-function (current-buffer) msg))
1326     (let ((functions compilation-finish-functions))
1327       (while functions
1328         (funcall (car functions) (current-buffer) msg)
1329         (setq functions (cdr functions))))))
1330
1331 ;; Called when compilation process changes state.
1332 (defun compilation-sentinel (proc msg)
1333   "Sentinel for compilation buffers."
1334   (if (memq (process-status proc) '(exit signal))
1335       (let ((buffer (process-buffer proc)))
1336         (if (null (buffer-name buffer))
1337             ;; buffer killed
1338             (set-process-buffer proc nil)
1339           (with-current-buffer buffer
1340             ;; Write something in the compilation buffer
1341             ;; and hack its mode line.
1342             (compilation-handle-exit (process-status proc)
1343                                      (process-exit-status proc)
1344                                      msg)
1345             ;; Since the buffer and mode line will show that the
1346             ;; process is dead, we can delete it now.  Otherwise it
1347             ;; will stay around until M-x list-processes.
1348             (delete-process proc)))
1349         (setq compilation-in-progress (delq proc compilation-in-progress)))))
1350
1351 (defun compilation-filter (proc string)
1352   "Process filter for compilation buffers.
1353 Just inserts the text, but uses `insert-before-markers'."
1354   (if (buffer-name (process-buffer proc))
1355       (with-current-buffer (process-buffer proc)
1356         (let ((inhibit-read-only t))
1357           (save-excursion
1358             (goto-char (process-mark proc))
1359             (insert-before-markers string)
1360             (run-hooks 'compilation-filter-hook))))))
1361
1362 ;;; test if a buffer is a compilation buffer, assuming we're in the buffer
1363 (defsubst compilation-buffer-internal-p ()
1364   "Test if inside a compilation buffer."
1365   (local-variable-p 'compilation-locs))
1366
1367 ;;; test if a buffer is a compilation buffer, using compilation-buffer-internal-p
1368 (defsubst compilation-buffer-p (buffer)
1369   "Test if BUFFER is a compilation buffer."
1370   (with-current-buffer buffer
1371     (compilation-buffer-internal-p)))
1372
1373 (defmacro compilation-loop (< property-change 1+ error)
1374   `(while (,< n 0)
1375       (or (setq pt (,property-change pt 'message))
1376           (error ,error compilation-error))
1377       ;; prop 'message usually has 2 changes, on and off, so re-search if off
1378       (or (setq msg (get-text-property pt 'message))
1379           (if (setq pt (,property-change pt 'message))
1380               (setq msg (get-text-property pt 'message)))
1381           (error ,error compilation-error))
1382       (or (< (cadr msg) compilation-skip-threshold)
1383           (if different-file
1384               (eq (prog1 last (setq last (nth 2 (car msg))))
1385                   last))
1386           (if compilation-skip-visited
1387               (nthcdr 4 (car msg)))
1388           (if compilation-skip-to-next-location
1389               (eq (car msg) loc))
1390           ;; count this message only if none of the above are true
1391           (setq n (,1+ n)))))
1392
1393 (defun compilation-next-error (n &optional different-file pt)
1394   "Move point to the next error in the compilation buffer.
1395 Prefix arg N says how many error messages to move forwards (or
1396 backwards, if negative).
1397 Does NOT find the source line like \\[next-error]."
1398   (interactive "p")
1399   (or (compilation-buffer-p (current-buffer))
1400       (error "Not in a compilation buffer"))
1401   (or pt (setq pt (point)))
1402   (let* ((msg (get-text-property pt 'message))
1403          (loc (car msg))
1404          last)
1405     (if (zerop n)
1406         (unless (or msg                 ; find message near here
1407                     (setq msg (get-text-property (max (1- pt) (point-min))
1408                                                  'message)))
1409           (setq pt (previous-single-property-change pt 'message nil
1410                                                     (line-beginning-position)))
1411           (unless (setq msg (get-text-property (max (1- pt) (point-min)) 'message))
1412             (setq pt (next-single-property-change pt 'message nil
1413                                                   (line-end-position)))
1414             (or (setq msg (get-text-property pt 'message))
1415                 (setq pt (point)))))
1416       (setq last (nth 2 (car msg)))
1417       (if (>= n 0)
1418           (compilation-loop > next-single-property-change 1-
1419                             (if (get-buffer-process (current-buffer))
1420                                 "No more %ss yet"
1421                               "Moved past last %s"))
1422         ;; Don't move "back" to message at or before point.
1423         ;; Pass an explicit (point-min) to make sure pt is non-nil.
1424         (setq pt (previous-single-property-change pt 'message nil (point-min)))
1425         (compilation-loop < previous-single-property-change 1+
1426                           "Moved back before first %s")))
1427     (goto-char pt)
1428     (or msg
1429         (error "No %s here" compilation-error))))
1430
1431 (defun compilation-previous-error (n)
1432   "Move point to the previous error in the compilation buffer.
1433 Prefix arg N says how many error messages to move backwards (or
1434 forwards, if negative).
1435 Does NOT find the source line like \\[previous-error]."
1436   (interactive "p")
1437   (compilation-next-error (- n)))
1438
1439 (defun compilation-next-file (n)
1440   "Move point to the next error for a different file than the current one.
1441 Prefix arg N says how many files to move forwards (or backwards, if negative)."
1442   (interactive "p")
1443   (compilation-next-error n t))
1444
1445 (defun compilation-previous-file (n)
1446   "Move point to the previous error for a different file than the current one.
1447 Prefix arg N says how many files to move backwards (or forwards, if negative)."
1448   (interactive "p")
1449   (compilation-next-file (- n)))
1450
1451 (defun kill-compilation ()
1452   "Kill the process made by the \\[compile] or \\[grep] commands."
1453   (interactive)
1454   (let ((buffer (compilation-find-buffer)))
1455     (if (get-buffer-process buffer)
1456         (interrupt-process (get-buffer-process buffer))
1457       (error "The compilation process is not running"))))
1458
1459 (defalias 'compile-mouse-goto-error 'compile-goto-error)
1460
1461 (defun compile-goto-error (&optional event)
1462   "Visit the source for the error message at point.
1463 Use this command in a compilation log buffer.  Sets the mark at point there."
1464   (interactive (list last-input-event))
1465   (if event (posn-set-point (event-end event)))
1466   (or (compilation-buffer-p (current-buffer))
1467       (error "Not in a compilation buffer"))
1468   (if (get-text-property (point) 'directory)
1469       (dired-other-window (car (get-text-property (point) 'directory)))
1470     (push-mark)
1471     (setq compilation-current-error (point))
1472     (next-error 0)))
1473
1474 ;; Return a compilation buffer.
1475 ;; If the current buffer is a compilation buffer, return it.
1476 ;; Otherwise, look for a compilation buffer and signal an error
1477 ;; if there are none.
1478 (defun compilation-find-buffer (&optional avoid-current)
1479   (next-error-find-buffer avoid-current 'compilation-buffer-internal-p))
1480
1481 ;;;###autoload
1482 (defun compilation-next-error-function (n &optional reset)
1483   (interactive "p")
1484   (set-buffer (compilation-find-buffer))
1485   (when reset
1486     (setq compilation-current-error nil))
1487   (let* ((columns compilation-error-screen-columns) ; buffer's local value
1488          (last 1)
1489          (loc (compilation-next-error (or n 1) nil
1490                                       (or compilation-current-error
1491                                           compilation-messages-start
1492                                           (point-min))))
1493          (end-loc (nth 2 loc))
1494          (marker (point-marker)))
1495     (setq compilation-current-error (point-marker)
1496           overlay-arrow-position
1497             (if (bolp)
1498                 compilation-current-error
1499               (copy-marker (line-beginning-position)))
1500           loc (car loc))
1501     ;; If loc contains no marker, no error in that file has been visited.  If
1502     ;; the marker is invalid the buffer has been killed.  So, recalculate all
1503     ;; markers for that file.
1504     (unless (and (nth 3 loc) (marker-buffer (nth 3 loc)))
1505       (with-current-buffer (compilation-find-file marker (caar (nth 2 loc))
1506                                                   (or (cdar (nth 2 loc))
1507                                                       default-directory))
1508         (save-restriction
1509           (widen)
1510           (goto-char (point-min))
1511           ;; Treat file's found lines in forward order, 1 by 1.
1512           (dolist (line (reverse (cddr (nth 2 loc))))
1513             (when (car line)            ; else this is a filename w/o a line#
1514               (beginning-of-line (- (car line) last -1))
1515               (setq last (car line)))
1516             ;; Treat line's found columns and store/update a marker for each.
1517             (dolist (col (cdr line))
1518               (if (car col)
1519                   (if (eq (car col) -1) ; special case for range end
1520                       (end-of-line)
1521                     (compilation-move-to-column (car col) columns))
1522                 (beginning-of-line)
1523                 (skip-chars-forward " \t"))
1524               (if (nth 3 col)
1525                   (set-marker (nth 3 col) (point))
1526                 (setcdr (nthcdr 2 col) `(,(point-marker)))))))))
1527     (compilation-goto-locus marker (nth 3 loc) (nth 3 end-loc))
1528     (setcdr (nthcdr 3 loc) t)))         ; Set this one as visited.
1529
1530 (defvar compilation-gcpro nil
1531   "Internal variable used to keep some values from being GC'd.")
1532 (make-variable-buffer-local 'compilation-gcpro)
1533
1534 (defun compilation-fake-loc (marker file &optional line col)
1535   "Preassociate MARKER with FILE.
1536 FILE should be ABSOLUTE-FILENAME or (RELATIVE-FILENAME . DIRNAME).
1537 This is useful when you compile temporary files, but want
1538 automatic translation of the messages to the real buffer from
1539 which the temporary file came.  This only works if done before a
1540 message about FILE appears!
1541
1542 Optional args LINE and COL default to 1 and beginning of
1543 indentation respectively.  The marker is expected to reflect
1544 this.  In the simplest case the marker points to the first line
1545 of the region that was saved to the temp file.
1546
1547 If you concatenate several regions into the temp file (e.g. a
1548 header with variable assignments and a code region), you must
1549 call this several times, once each for the last line of one
1550 region and the first line of the next region."
1551   (or (consp file) (setq file (list file)))
1552   (setq file (compilation-get-file-structure file))
1553   ;; Between the current call to compilation-fake-loc and the first occurrence
1554   ;; of an error message referring to `file', the data is only kept is the
1555   ;; weak hash-table compilation-locs, so we need to prevent this entry
1556   ;; in compilation-locs from being GC'd away.  --Stef
1557   (push file compilation-gcpro)
1558   (let ((loc (compilation-assq (or line 1) (cdr file))))
1559     (setq loc (compilation-assq col loc))
1560     (if (cdr loc)
1561         (setcdr (cddr loc) (list marker))
1562       (setcdr loc (list line file marker)))
1563     loc))
1564
1565 (defcustom compilation-context-lines 0
1566   "*Display this many lines of leading context before message.
1567 If nil, don't scroll the compilation output window."
1568   :type '(choice integer (const :tag "No window scrolling" nil))
1569   :group 'compilation
1570   :version "22.1")
1571
1572 (defsubst compilation-set-window (w mk)
1573   "Align the compilation output window W with marker MK near top."
1574   (if (integerp compilation-context-lines)
1575       (set-window-start w (save-excursion
1576                             (goto-char mk)
1577                             (beginning-of-line (- 1 compilation-context-lines))
1578                             (point))))
1579   (set-window-point w mk))
1580
1581 (defun compilation-goto-locus (msg mk end-mk)
1582   "Jump to an error corresponding to MSG at MK.
1583 All arguments are markers.  If END-MK is non-nil, mark is set there
1584 and overlay is highlighted between MK and END-MK."
1585   (if (eq (window-buffer (selected-window))
1586           (marker-buffer msg))
1587       ;; If the compilation buffer window is selected,
1588       ;; keep the compilation buffer in this window;
1589       ;; display the source in another window.
1590       (let ((pop-up-windows t))
1591         (pop-to-buffer (marker-buffer mk)))
1592     (if (window-dedicated-p (selected-window))
1593         (pop-to-buffer (marker-buffer mk))
1594       (switch-to-buffer (marker-buffer mk))))
1595   ;; If narrowing gets in the way of going to the right place, widen.
1596   (unless (eq (goto-char mk) (point))
1597     (widen)
1598     (goto-char mk))
1599   (if end-mk
1600       (push-mark end-mk t)
1601     (if mark-active (setq mark-active)))
1602   ;; If hideshow got in the way of
1603   ;; seeing the right place, open permanently.
1604   (dolist (ov (overlays-at (point)))
1605     (when (eq 'hs (overlay-get ov 'invisible))
1606       (delete-overlay ov)
1607       (goto-char mk)))
1608
1609   ;; Show compilation buffer in other window, scrolled to this error.
1610   (let* ((pop-up-windows t)
1611          ;; Use an existing window if it is in a visible frame.
1612          (w (or (get-buffer-window (marker-buffer msg) 'visible)
1613                 ;; Pop up a window.
1614                 (display-buffer (marker-buffer msg))))
1615          (highlight-regexp (with-current-buffer (marker-buffer msg)
1616                              ;; also do this while we change buffer
1617                              (compilation-set-window w msg)
1618                              compilation-highlight-regexp)))
1619     (compilation-set-window-height w)
1620
1621     (when highlight-regexp
1622       (if (timerp next-error-highlight-timer)
1623           (cancel-timer next-error-highlight-timer))
1624       (unless compilation-highlight-overlay
1625         (setq compilation-highlight-overlay
1626               (make-overlay (point-min) (point-min)))
1627         (overlay-put compilation-highlight-overlay 'face 'next-error))
1628       (with-current-buffer (marker-buffer mk)
1629         (save-excursion
1630           (if end-mk (goto-char end-mk) (end-of-line))
1631           (let ((end (point)))
1632             (if mk (goto-char mk) (beginning-of-line))
1633             (if (and (stringp highlight-regexp)
1634                      (re-search-forward highlight-regexp end t))
1635                 (progn
1636                   (goto-char (match-beginning 0))
1637                   (move-overlay compilation-highlight-overlay
1638                                 (match-beginning 0) (match-end 0)
1639                                 (current-buffer)))
1640               (move-overlay compilation-highlight-overlay
1641                             (point) end (current-buffer)))
1642             (if (numberp next-error-highlight)
1643                 (setq next-error-highlight-timer
1644                       (run-at-time next-error-highlight nil 'delete-overlay
1645                                    compilation-highlight-overlay)))
1646             (if (not (or (eq next-error-highlight t)
1647                          (numberp next-error-highlight)))
1648                 (delete-overlay compilation-highlight-overlay))))))
1649     (when (and (eq next-error-highlight 'fringe-arrow))
1650       (setq next-error-overlay-arrow-position
1651             (copy-marker (line-beginning-position))))))
1652
1653 \f
1654 (defun compilation-find-file (marker filename dir &rest formats)
1655   "Find a buffer for file FILENAME.
1656 Search the directories in `compilation-search-path'.
1657 A nil in `compilation-search-path' means to try the
1658 current directory, which is passed in DIR.
1659 If FILENAME is not found at all, ask the user where to find it.
1660 Pop up the buffer containing MARKER and scroll to MARKER if we ask the user."
1661   (or formats (setq formats '("%s")))
1662   (save-excursion
1663     (let ((dirs compilation-search-path)
1664           buffer thisdir fmts name)
1665       (if (file-name-absolute-p filename)
1666           ;; The file name is absolute.  Use its explicit directory as
1667           ;; the first in the search path, and strip it from FILENAME.
1668           (setq filename (abbreviate-file-name (expand-file-name filename))
1669                 dirs (cons (file-name-directory filename) dirs)
1670                 filename (file-name-nondirectory filename)))
1671       ;; Now search the path.
1672       (while (and dirs (null buffer))
1673         (setq thisdir (or (car dirs) dir)
1674               fmts formats)
1675         ;; For each directory, try each format string.
1676         (while (and fmts (null buffer))
1677           (setq name (expand-file-name (format (car fmts) filename) thisdir)
1678                 buffer (and (file-exists-p name)
1679                             (find-file-noselect name))
1680                 fmts (cdr fmts)))
1681         (setq dirs (cdr dirs)))
1682       (or buffer
1683           ;; The file doesn't exist.  Ask the user where to find it.
1684           (let ((pop-up-windows t))
1685             (compilation-set-window (display-buffer (marker-buffer marker))
1686                                     marker)
1687             (let ((name (expand-file-name
1688                          (read-file-name
1689                           (format "Find this error in: (default %s) "
1690                                   filename)
1691                           dir filename t))))
1692               (if (file-directory-p name)
1693                   (setq name (expand-file-name filename name)))
1694               (setq buffer (and (file-exists-p name)
1695                                 (find-file name))))))
1696       ;; Make intangible overlays tangible.
1697       (mapcar (function (lambda (ov)
1698                           (when (overlay-get ov 'intangible)
1699                             (overlay-put ov 'intangible nil))))
1700               (overlays-in (point-min) (point-max)))
1701       buffer)))
1702
1703 (defun compilation-get-file-structure (file &optional fmt)
1704   "Retrieve FILE's file-structure or create a new one.
1705 FILE should be (ABSOLUTE-FILENAME) or (RELATIVE-FILENAME . DIRNAME)."
1706
1707   (or (gethash file compilation-locs)
1708       ;; File was not previously encountered, at least not in the form passed.
1709       ;; Let's normalize it and look again.
1710       (let ((filename (car file))
1711             (default-directory (if (cdr file)
1712                                    (file-truename (cdr file))
1713                                  default-directory)))
1714
1715         ;; Check for a comint-file-name-prefix and prepend it if appropriate.
1716         ;; (This is very useful for compilation-minor-mode in an rlogin-mode
1717         ;; buffer.)
1718         (if (boundp 'comint-file-name-prefix)
1719             (if (file-name-absolute-p filename)
1720                 (setq filename
1721                       (concat (with-no-warnings comint-file-name-prefix) filename))
1722               (setq default-directory
1723                     (file-truename
1724                      (concat (with-no-warnings comint-file-name-prefix) default-directory)))))
1725
1726         ;; If compilation-parse-errors-filename-function is
1727         ;; defined, use it to process the filename.
1728         (when compilation-parse-errors-filename-function
1729           (setq filename
1730                 (funcall compilation-parse-errors-filename-function
1731                          filename)))
1732
1733         ;; Some compilers (e.g. Sun's java compiler, reportedly) produce bogus
1734         ;; file names like "./bar//foo.c" for file "bar/foo.c";
1735         ;; expand-file-name will collapse these into "/foo.c" and fail to find
1736         ;; the appropriate file.  So we look for doubled slashes in the file
1737         ;; name and fix them.
1738         (setq filename (command-line-normalize-file-name filename))
1739
1740         ;; Now eliminate any "..", because find-file would get them wrong.
1741         ;; Make relative and absolute filenames, with or without links, the
1742         ;; same.
1743         (setq filename
1744               (list (abbreviate-file-name
1745                      (file-truename (if (cdr file)
1746                                         (expand-file-name filename)
1747                                       filename)))))
1748
1749         ;; Store it for the possibly unnormalized name
1750         (puthash file
1751                  ;; Retrieve or create file-structure for normalized name
1752                  (or (gethash filename compilation-locs)
1753                      (puthash filename (list filename fmt) compilation-locs))
1754                  compilation-locs))))
1755
1756 (add-to-list 'debug-ignored-errors "^No more [-a-z ]+s yet$")
1757
1758 ;;; Compatibility with the old compile.el.
1759
1760 (defun compile-buffer-substring (n) (if n (match-string n)))
1761
1762 (defun compilation-compat-error-properties (err)
1763   "Map old-style error ERR to new-style message."
1764   ;; Old-style structure is (MARKER (FILE DIR) LINE COL) or
1765   ;; (MARKER . MARKER).
1766   (let ((dst (cdr err)))
1767     (if (markerp dst)
1768         ;; Must start with a face, for font-lock.
1769         `(face nil
1770           message ,(list (list nil nil nil dst) 2)
1771           help-echo "mouse-2: visit the source location"
1772           keymap compilation-button-map
1773           mouse-face highlight)
1774       ;; Too difficult to do it by hand: dispatch to the normal code.
1775       (let* ((file (pop dst))
1776              (line (pop dst))
1777              (col (pop dst))
1778              (filename (pop file))
1779              (dirname (pop file))
1780              (fmt (pop file)))
1781         (compilation-internal-error-properties
1782          (cons filename dirname) line nil col nil 2 fmt)))))
1783
1784 (defun compilation-compat-parse-errors (limit)
1785   (when compilation-parse-errors-function
1786     ;; FIXME: We should remove the rest of the compilation keywords
1787     ;; but we can't do that from here because font-lock is using
1788     ;; the value right now.  --stef
1789     (save-excursion
1790       (setq compilation-error-list nil)
1791       ;; Reset compilation-parsing-end each time because font-lock
1792       ;; might force us the re-parse many times (typically because
1793       ;; some code adds some text-property to the output that we
1794       ;; already parsed).  You might say "why reparse", well:
1795       ;; because font-lock has just removed the `message' property so
1796       ;; have to do it all over again.
1797       (if compilation-parsing-end
1798           (set-marker compilation-parsing-end (point))
1799         (setq compilation-parsing-end (point-marker)))
1800       (condition-case nil
1801           ;; Ignore any error: we're calling this function earlier than
1802           ;; in the old compile.el so things might not all be setup yet.
1803           (funcall compilation-parse-errors-function limit nil)
1804         (error nil))
1805       (dolist (err (if (listp compilation-error-list) compilation-error-list))
1806         (let* ((src (car err))
1807                (dst (cdr err))
1808                (loc (cond ((markerp dst) (list nil nil nil dst))
1809                           ((consp dst)
1810                            (list (nth 2 dst) (nth 1 dst)
1811                                  (cons (cdar dst) (caar dst)))))))
1812           (when loc
1813             (goto-char src)
1814             ;; (put-text-property src (line-end-position) 'font-lock-face 'font-lock-warning-face)
1815             (put-text-property src (line-end-position)
1816                                'message (list loc 2)))))))
1817   (goto-char limit)
1818   nil)
1819
1820 ;; Beware: this is not only compatiblity code.  New code stil uses it.  --Stef
1821 (defun compilation-forget-errors ()
1822   ;; In case we hit the same file/line specs, we want to recompute a new
1823   ;; marker for them, so flush our cache.
1824   (setq compilation-locs (make-hash-table :test 'equal :weakness 'value))
1825   (setq compilation-gcpro nil)
1826   ;; FIXME: the old code reset the directory-stack, so maybe we should
1827   ;; put a `directory change' marker of some sort, but where?  -stef
1828   ;;
1829   ;; FIXME: The old code moved compilation-current-error (which was
1830   ;; virtually represented by a mix of compilation-parsing-end and
1831   ;; compilation-error-list) to point-min, but that was only meaningful for
1832   ;; the internal uses of compilation-forget-errors: all calls from external
1833   ;; packages seem to be followed by a move of compilation-parsing-end to
1834   ;; something equivalent to point-max.  So we speculatively move
1835   ;; compilation-current-error to point-max (since the external package
1836   ;; won't know that it should do it).  --stef
1837   (setq compilation-current-error nil)
1838   (let* ((proc (get-buffer-process (current-buffer)))
1839          (mark (if proc (process-mark proc)))
1840          (pos (or mark (point-max))))
1841     (setq compilation-messages-start
1842           ;; In the future, ignore the text already present in the buffer.
1843           ;; Since many process filter functions insert before markers,
1844           ;; we need to put ours just before the insertion point rather
1845           ;; than at the insertion point.  If that's not possible, then
1846           ;; don't use a marker.  --Stef
1847           (if (> pos (point-min)) (copy-marker (1- pos)) pos))))
1848
1849 (provide 'compile)
1850
1851 ;; arch-tag: 12465727-7382-4f72-b234-79855a00dd8c
1852 ;;; compile.el ends here