code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.2.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 dnl Fairly arbitrary, older versions might work too.
  30 AM_INIT_AUTOMAKE(1.11)
  31
  32 dnl Support for --program-prefix, --program-suffix and
  33 dnl --program-transform-name options
  34 AC_ARG_PROGRAM
  35
  36 dnl It is important that variables on the RHS not be expanded here,
  37 dnl hence the single quotes.  This is per the GNU coding standards, see
  38 dnl (autoconf) Installation Directory Variables
  39 dnl See also epaths.h below.
  40 lispdir='${datadir}/emacs/${version}/lisp'
  41 leimdir='${datadir}/emacs/${version}/leim'
  42 standardlisppath='${lispdir}:${leimdir}'
  43 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  44 '${datadir}/emacs/site-lisp'
  45 lisppath='${locallisppath}:${standardlisppath}'
  46 etcdir='${datadir}/emacs/${version}/etc'
  47 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  48 docdir='${datadir}/emacs/${version}/etc'
  49 gamedir='${localstatedir}/games/emacs'
  50
  51 dnl Special option to disable the most of other options.
  52 AC_ARG_WITH(all,
  53 [AS_HELP_STRING([--without-all],
  54                 [omit almost all features and build
  55                 small executable with minimal dependencies])],
  56   with_features=$withval,
  57   with_features=yes)
  58
  59 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  60 dnl Create a new --with option that defaults to being disabled.
  61 dnl NAME is the base name of the option.  The shell variable with_NAME
  62 dnl   will be set to either the user's value (if the option is
  63 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  64 dnl   option is not specified).  Note that the shell variable name is
  65 dnl   constructed as autoconf does, by replacing non-alphanumeric
  66 dnl   characters with "_".
  67 dnl HELP-STRING is the help text for the option.
  68 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  69   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  70     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  71 ])dnl
  72
  73 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  74 dnl Create a new --with option that defaults to $enable_features.
  75 dnl NAME is the base name of the option.  The shell variable with_NAME
  76 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  77 dnl   'yes' (if the option is not specified).  Note that the shell
  78 dnl   variable name is constructed as autoconf does, by replacing
  79 dnl   non-alphanumeric characters with "_".
  80 dnl HELP-STRING is the help text for the option.
  81 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  82   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  83    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
  84 ])dnl
  85
  86 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  87 if test "$with_pop" = yes; then
  88    AC_DEFINE(MAIL_USE_POP)
  89 fi
  90 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  91
  92 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  93 if test "$with_kerberos" != no; then
  94    AC_DEFINE(KERBEROS)
  95 fi
  96 AH_TEMPLATE(KERBEROS,
  97             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  98
  99 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 100 if test "${with_kerberos5}" != no; then
 101   if test "${with_kerberos}" = no; then
 102     with_kerberos=yes
 103     AC_DEFINE(KERBEROS)
 104   fi
 105   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 106 fi
 107
 108 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 109 dnl FIXME hesiod support may not be present, so it seems like an error
 110 dnl to define, or at least use, this unconditionally.
 111 if test "$with_hesiod" != no; then
 112   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 113 fi
 114
 115 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 116 if test "$with_mmdf" != no; then
 117    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 118 fi
 119
 120 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 121 if test "$with_mail_unlink" != no; then
 122    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 123 fi
 124
 125 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 126     [string giving default POP mail host])],
 127     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 128
 129 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 130
 131 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 132 if test "$with_sync_input" = yes; then
 133    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 134 fi
 135
 136 dnl FIXME currently it is not the last.
 137 dnl This should be the last --with option, because --with-x is
 138 dnl added later on when we find the path of X, and it's best to
 139 dnl keep them together visually.
 140 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 141  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 142 [         case "${withval}" in
 143             y | ye | yes )      val=gtk ;;
 144             n | no )            val=no  ;;
 145             l | lu | luc | luci | lucid )       val=lucid ;;
 146             a | at | ath | athe | athen | athena )      val=athena ;;
 147             m | mo | mot | moti | motif )       val=motif ;;
 148             g | gt | gtk  )     val=gtk ;;
 149             gtk3  )     val=gtk3 ;;
 150             * )
 151 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 152 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 153 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 154             ;;
 155           esac
 156           with_x_toolkit=$val
 157 ])
 158
 159 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 160 if test "$with_wide_int" = yes; then
 161   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 162 fi
 163
 164 dnl _ON results in a '--without' option in the --help output, so
 165 dnl the help text should refer to "don't compile", etc.
 166 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 167 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 168 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 169 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 170 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 171 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 172 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 173 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 174
 175 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 176 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 177 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 178
 179 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 180 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 181 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 182 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 183
 184 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 185 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 186 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 187 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 188 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 189 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 190
 191 ## For the times when you want to build Emacs but don't have
 192 ## a suitable makeinfo, and can live without the manuals.
 193 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 194 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 195
 196 ## Makefile.in needs the cache file name.
 197 AC_SUBST(cache_file)
 198
 199 ## This is an option because I do not know if all info/man support
 200 ## compressed files, nor how to test if they do so.
 201 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 202 if test $with_compress_info = yes; then
 203    GZIP_INFO=yes
 204 else
 205    GZIP_INFO=
 206 fi
 207 AC_SUBST(GZIP_INFO)
 208
 209 AC_ARG_WITH([pkg-config-prog],dnl
 210 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 211                   [path to pkg-config for finding GTK and librsvg])])
 212 if test "X${with_pkg_config_prog}" != X; then
 213    if test "${with_pkg_config_prog}" != yes; then
 214       PKG_CONFIG="${with_pkg_config_prog}"
 215    fi
 216 fi
 217
 218 CRT_DIR=
 219 AC_ARG_WITH([crt-dir],dnl
 220 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 221 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 222 CRT_DIR="${with_crt_dir}"
 223
 224 AC_ARG_WITH(gameuser,dnl
 225 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 226 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 227   && gameuser="${with_gameuser}"
 228 test "X$gameuser" = X && gameuser=games
 229
 230 AC_ARG_WITH([gnustep-conf],dnl
 231 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 232 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 233   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 234 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 235      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 236
 237 AC_ARG_ENABLE(ns-self-contained,
 238 [AS_HELP_STRING([--disable-ns-self-contained],
 239                 [disable self contained build under NeXTstep])],
 240    EN_NS_SELF_CONTAINED=$enableval,
 241    EN_NS_SELF_CONTAINED=yes)
 242
 243 AC_ARG_ENABLE(locallisppath,
 244 [AS_HELP_STRING([--enable-locallisppath=PATH],
 245                 [directories Emacs should search for lisp files specific
 246                  to this site])],
 247 if test "${enableval}" = "no"; then
 248   locallisppath=
 249 elif test "${enableval}" != "yes"; then
 250   locallisppath=${enableval}
 251 fi)
 252
 253 AC_ARG_ENABLE(checking,
 254 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 255                 [enable expensive run-time checks.  With LIST,
 256                  enable only specific categories of checks.
 257                  Categories are: all,yes,no.
 258                  Flags are: stringbytes, stringoverrun, stringfreelist,
 259                  xmallocoverrun, conslist, glyphs])],
 260 [ac_checking_flags="${enableval}"],[])
 261 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 262 for check in $ac_checking_flags
 263 do
 264         case $check in
 265         # these set all the flags to specific states
 266         yes)            ac_enable_checking=1 ;;
 267         no)             ac_enable_checking= ;
 268                         ac_gc_check_stringbytes= ;
 269                         ac_gc_check_string_overrun= ;
 270                         ac_gc_check_string_free_list= ;
 271                         ac_xmalloc_overrun= ;
 272                         ac_gc_check_cons_list= ;
 273                         ac_glyphs_debug= ;;
 274         all)            ac_enable_checking=1 ;
 275                         ac_gc_check_stringbytes=1 ;
 276                         ac_gc_check_string_overrun=1 ;
 277                         ac_gc_check_string_free_list=1 ;
 278                         ac_xmalloc_overrun=1 ;
 279                         ac_gc_check_cons_list=1 ;
 280                         ac_glyphs_debug=1 ;;
 281         # these enable particular checks
 282         stringbytes)    ac_gc_check_stringbytes=1 ;;
 283         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 284         stringfreelist) ac_gc_check_string_free_list=1 ;;
 285         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 286         conslist)       ac_gc_check_cons_list=1 ;;
 287         glyphs)         ac_glyphs_debug=1 ;;
 288         *)      AC_MSG_ERROR(unknown check category $check) ;;
 289         esac
 290 done
 291 IFS="$ac_save_IFS"
 292
 293 if test x$ac_enable_checking != x ; then
 294   AC_DEFINE(ENABLE_CHECKING, 1,
 295 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 296 fi
 297 if test x$ac_gc_check_stringbytes != x ; then
 298   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 299 [Define this temporarily to hunt a bug.  If defined, the size of
 300    strings is redundantly recorded in sdata structures so that it can
 301    be compared to the sizes recorded in Lisp strings.])
 302 fi
 303 if test x$ac_gc_check_string_overrun != x ; then
 304   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 305 [Define this to check for short string overrun.])
 306 fi
 307 if test x$ac_gc_check_string_free_list != x ; then
 308   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 309 [Define this to check the string free list.])
 310 fi
 311 if test x$ac_xmalloc_overrun != x ; then
 312   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 313 [Define this to check for malloc buffer overrun.])
 314 fi
 315 if test x$ac_gc_check_cons_list != x ; then
 316   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 317 [Define this to check for errors in cons list.])
 318 fi
 319 if test x$ac_glyphs_debug != x ; then
 320   AC_DEFINE(GLYPH_DEBUG, 1,
 321 [Define this to enable glyphs debugging code.])
 322 fi
 323
 324 AC_ARG_ENABLE(check-lisp-object-type,
 325 [AS_HELP_STRING([--enable-check-lisp-object-type],
 326                 [enable compile time checks for the Lisp_Object data type.
 327                 This is useful for development for catching certain types of bugs.])],
 328 if test "${enableval}" != "no"; then
 329    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 330    [Define this to enable compile time checks for the Lisp_Object data type.])
 331 fi)
 332
 333
 334 AC_ARG_ENABLE(profiling,
 335 [AS_HELP_STRING([--enable-profiling],
 336                 [build emacs with profiling support.
 337                  This might not work on all platforms])],
 338 [ac_enable_profiling="${enableval}"],[])
 339 if test x$ac_enable_profiling != x ; then
 340    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 341 else
 342    PROFILING_CFLAGS=
 343 fi
 344 AC_SUBST(PROFILING_CFLAGS)
 345
 346 AC_ARG_ENABLE(autodepend,
 347 [AS_HELP_STRING([--enable-autodepend],
 348                 [automatically generate dependencies to .h-files.
 349                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 350                  found])],
 351 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 352
 353 #### Make srcdir absolute, if it isn't already.  It's important to
 354 #### avoid running the path through pwd unnecessarily, since pwd can
 355 #### give you automounter prefixes, which can go away.  We do all this
 356 #### so Emacs can find its files when run uninstalled.
 357 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 358 unset CDPATH
 359 case "${srcdir}" in
 360   /* ) ;;
 361   . )
 362     ## We may be able to use the $PWD environment variable to make this
 363     ## absolute.  But sometimes PWD is inaccurate.
 364     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 365     ## but that tested only for a well-formed and valid PWD,
 366     ## it did not object when PWD was well-formed and valid but just wrong.
 367     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 368     then
 369       srcdir="$PWD"
 370     else
 371       srcdir="`(cd ${srcdir}; pwd)`"
 372     fi
 373   ;;
 374   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 375 esac
 376
 377 ### Canonicalize the configuration name.
 378
 379 AC_CANONICAL_HOST
 380 canonical=$host
 381 configuration=${host_alias-${build_alias-$host}}
 382
 383 dnl This used to use changequote, but, apart from `changequote is evil'
 384 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 385 dnl the great gob of text.  Thus it's not processed for possible expansion.
 386 dnl Just make sure the brackets remain balanced.
 387 dnl
 388 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 389 dnl indicated by comments.
 390 dnl quotation begins
 391 [
 392
 393 ### If you add support for a new configuration, add code to this
 394 ### switch statement to recognize your configuration name and select
 395 ### the appropriate operating system file.
 396
 397 ### You would hope that you could choose an s/*.h
 398 ### file based on the operating system portion.  However, it turns out
 399 ### that each s/*.h file is pretty manufacturer-specific.
 400 ### So we basically have to have a special case for each
 401 ### configuration name.
 402 ###
 403 ### As far as handling version numbers on operating systems is
 404 ### concerned, make sure things will fail in a fixable way.  If
 405 ### /etc/MACHINES doesn't say anything about version numbers, be
 406 ### prepared to handle anything reasonably.  If version numbers
 407 ### matter, be sure /etc/MACHINES says something about it.
 408
 409 opsys='' unported=no
 410 case "${canonical}" in
 411
 412   ## GNU/Linux and similar ports
 413   *-*-linux* )
 414     opsys=gnu-linux
 415   ;;
 416
 417   ## FreeBSD ports
 418   *-*-freebsd* )
 419     opsys=freebsd
 420   ;;
 421
 422   ## FreeBSD kernel + glibc based userland
 423   *-*-kfreebsd*gnu* )
 424     opsys=gnu-kfreebsd
 425   ;;
 426
 427   ## NetBSD ports
 428   *-*-netbsd* )
 429     opsys=netbsd
 430   ;;
 431
 432   ## OpenBSD ports
 433   *-*-openbsd* )
 434     opsys=openbsd
 435   ;;
 436
 437   ## Apple Darwin / Mac OS X
 438   *-apple-darwin* )
 439     case "${canonical}" in
 440       i[3456]86-* )  ;;
 441       powerpc-* )    ;;
 442       x86_64-* )     ;;
 443       * )            unported=yes ;;
 444     esac
 445     opsys=darwin
 446     ## Use fink packages if available.
 447     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 448 ##    if test -d /sw/include && test -d /sw/lib; then
 449 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 450 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 451 ##    fi
 452   ;;
 453
 454   ## HP 9000 series 700 and 800, running HP/UX
 455   hppa*-hp-hpux10.2* )
 456     opsys=hpux10-20
 457   ;;
 458   hppa*-hp-hpux1[1-9]* )
 459     opsys=hpux11
 460     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 461   ;;
 462
 463   ## IBM machines
 464   rs6000-ibm-aix4.[23]* )
 465     opsys=aix4-2
 466   ;;
 467   powerpc-ibm-aix4.[23]*  )
 468     opsys=aix4-2
 469   ;;
 470   rs6000-ibm-aix[56]* )
 471     opsys=aix4-2
 472   ;;
 473   powerpc-ibm-aix[56]*  )
 474     opsys=aix4-2
 475   ;;
 476
 477   ## Silicon Graphics machines
 478   ## Iris 4D
 479   mips-sgi-irix6.5 )
 480     opsys=irix6-5
 481     # Without defining _LANGUAGE_C, things get masked out in the headers
 482     # so that, for instance, grepping for `free' in stdlib.h fails and
 483     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 484     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 485   ;;
 486
 487   ## Suns
 488   *-sun-solaris* \
 489     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 490     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 491     case "${canonical}" in
 492       i[3456]86-*-* )   ;;
 493       amd64-*-*|x86_64-*-*) ;;
 494       sparc* )          ;;
 495       * )               unported=yes ;;
 496     esac
 497     case "${canonical}" in
 498       *-sunos5.6* | *-solaris2.6* )
 499                 opsys=sol2-6
 500                 RANLIB="ar -ts"
 501                 ;;
 502       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 503                 opsys=sol2-6
 504                 emacs_check_sunpro_c=yes
 505                 ;;
 506       *-sunos5* | *-solaris* )
 507                 opsys=sol2-10
 508                 emacs_check_sunpro_c=yes
 509                 ;;
 510     esac
 511     ## Watch out for a compiler that we know will not work.
 512     case "${canonical}" in
 513      *-solaris* | *-sunos5* )
 514                 if [ "x$CC" = x/usr/ucb/cc ]; then
 515                   ## /usr/ucb/cc doesn't work;
 516                   ## we should find some other compiler that does work.
 517                   unset CC
 518                 fi
 519                 ;;
 520       *) ;;
 521     esac
 522   ;;
 523
 524   ## Intel 386 machines where we don't care about the manufacturer.
 525   i[3456]86-*-* )
 526     case "${canonical}" in
 527       *-cygwin )                opsys=cygwin ;;
 528       *-darwin* )               opsys=darwin ;;
 529       *-sysv4.2uw* )            opsys=unixware ;;
 530       *-sysv5uw* )              opsys=unixware ;;
 531       *-sysv5OpenUNIX* )        opsys=unixware ;;
 532       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 533     esac
 534   ;;
 535
 536   * )
 537     unported=yes
 538   ;;
 539 esac
 540
 541 ### If the code above didn't choose an operating system, just choose
 542 ### an operating system based on the configuration name.  You really
 543 ### only want to use this when you have no idea what the right
 544 ### operating system is; if you know what operating systems a machine
 545 ### runs, it's cleaner to make it explicit in the case statement
 546 ### above.
 547 if test x"${opsys}" = x; then
 548   case "${canonical}" in
 549     *-gnu* )                            opsys=gnu ;;
 550     * )
 551       unported=yes
 552     ;;
 553   esac
 554 fi
 555
 556 ]
 557 dnl quotation ends
 558
 559 if test $unported = yes; then
 560   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 561 Check `etc/MACHINES' for recognized configuration names.])
 562 fi
 563
 564
 565 #### Choose a compiler.
 566
 567 dnl Sets GCC=yes if using gcc.
 568 AC_PROG_CC
 569 AM_PROG_CC_C_O
 570
 571 if test x$GCC = xyes; then
 572   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 573 else
 574   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 575 fi
 576
 577 # Initialize gnulib right after choosing the compiler.
 578 gl_EARLY
 579
 580 # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 581 # if -g3 works and the user does not specify CFLAGS.
 582 # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 583 if test "$ac_test_CFLAGS" != set; then
 584   case $CFLAGS in
 585     '-g')
 586       emacs_g3_CFLAGS='-g3';;
 587     '-g -O2')
 588       emacs_g3_CFLAGS='-g3 -O2';;
 589     *)
 590       emacs_g3_CFLAGS='';;
 591   esac
 592   if test -n "$emacs_g3_CFLAGS"; then
 593     emacs_save_CFLAGS=$CFLAGS
 594     CFLAGS=$emacs_g3_CFLAGS
 595     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 596       [emacs_cv_prog_cc_g3],
 597       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 598          [emacs_cv_prog_cc_g3=yes],
 599          [emacs_cv_prog_cc_g3=no])])
 600     if test $emacs_cv_prog_cc_g3 = yes; then
 601       CFLAGS=$emacs_g3_CFLAGS
 602     else
 603       CFLAGS=$emacs_save_CFLAGS
 604     fi
 605   fi
 606 fi
 607
 608 AC_ARG_ENABLE([gcc-warnings],
 609   [AS_HELP_STRING([--enable-gcc-warnings],
 610                   [turn on lots of GCC warnings. This is intended for
 611                    developers, and may generate false alarms when used
 612                    with older or non-GNU development tools.])],
 613   [case $enableval in
 614      yes|no) ;;
 615      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 616    esac
 617    gl_gcc_warnings=$enableval],
 618   [gl_gcc_warnings=no]
 619 )
 620
 621 AC_ARG_ENABLE(link-time-optimization,
 622 [AS_HELP_STRING([--enable-link-time-optimization],
 623                 [build emacs with link-time optimization.
 624                  This is supported only for GCC since 4.5.0.])],
 625 if test "${enableval}" != "no"; then
 626    AC_MSG_CHECKING([whether link-time optimization is supported])
 627    ac_lto_supported=no
 628    if test x$GCC = xyes; then
 629       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 630       if test x$CPUS != x; then
 631          LTO="-flto=$CPUS"
 632       else
 633          LTO="-flto"
 634       fi
 635       old_CFLAGS=$CFLAGS
 636       CFLAGS="$CFLAGS $LTO"
 637       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 638         [ac_lto_supported=yes], [ac_lto_supported=no])
 639       CFLAGS="$old_CFLAGS"
 640    fi
 641    AC_MSG_RESULT([$ac_lto_supported])
 642    if test "$ac_lto_supported" = "yes"; then
 643       CFLAGS="$CFLAGS $LTO"
 644    fi
 645 fi)
 646
 647 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 648 # ------------------------------------------------
 649 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 650 # Otherwise, run RUN-IF-NOT-FOUND.
 651 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 652   [AC_PREPROC_IFELSE(
 653     [AC_LANG_PROGRAM(
 654       [[
 655 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 656 /* ok */
 657 #else
 658 # error "your version of gcc is older than $1.$2"
 659 #endif
 660       ]]),
 661     ], [$3], [$4])
 662   ]
 663 )
 664
 665 # When compiling with GCC, prefer -isystem to -I when including system
 666 # include files, to avoid generating useless diagnostics for the files.
 667 if test "$gl_gcc_warnings" != yes; then
 668   isystem='-I'
 669 else
 670   isystem='-isystem '
 671
 672   # This, $nw, is the list of warnings we disable.
 673   nw=
 674
 675   case $with_x_toolkit in
 676     lucid | athena | motif)
 677        # Old toolkits mishandle 'const'.
 678        nw="$nw -Wwrite-strings"
 679        ;;
 680     *)
 681        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 682        ;;
 683   esac
 684   AC_SUBST([WERROR_CFLAGS])
 685
 686   nw="$nw -Waggregate-return"       # anachronistic
 687   nw="$nw -Wlong-long"              # C90 is anachronistic
 688   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 689   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 690   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 691   nw="$nw -Wcast-qual"              # Too many warnings for now
 692   nw="$nw -Wconversion"             # Too many warnings for now
 693   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 694   nw="$nw -Wsign-conversion"        # Too many warnings for now
 695   nw="$nw -Woverlength-strings"     # Not a problem these days
 696   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 697   nw="$nw -Wunreachable-code"       # so buggy that it's now silently ignored
 698   nw="$nw -Wpadded"                 # Our structs are not padded
 699   nw="$nw -Wredundant-decls"        # we regularly (re)declare functions
 700   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 701   nw="$nw -Wformat-nonliteral"      # we do this a lot
 702   nw="$nw -Wvla"                    # warnings in gettext.h
 703   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 704   nw="$nw -Wswitch-enum"            # Too many warnings for now
 705   nw="$nw -Wswitch-default"         # Too many warnings for now
 706   nw="$nw -Wfloat-equal"            # warns about high-quality code
 707   nw="$nw -Winline"                 # OK to ignore 'inline'
 708   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 709   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 710
 711   # Emacs doesn't care about shadowing; see
 712   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 713   nw="$nw -Wshadow"
 714
 715   # The following lines should be removable at some point.
 716   nw="$nw -Wstack-protector"
 717   nw="$nw -Wstrict-overflow"
 718   nw="$nw -Wsuggest-attribute=pure"
 719
 720   gl_MANYWARN_ALL_GCC([ws])
 721   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 722   for w in $ws; do
 723     gl_WARN_ADD([$w])
 724   done
 725   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 726   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 727   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 728   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 729   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 730   gl_WARN_ADD([-Wno-format-nonliteral])
 731
 732   # In spite of excluding -Wlogical-op above, it is enabled, as of
 733   # gcc 4.5.0 20090517.
 734   gl_WARN_ADD([-Wno-logical-op])
 735
 736   gl_WARN_ADD([-fdiagnostics-show-option])
 737   gl_WARN_ADD([-funit-at-a-time])
 738
 739   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 740   AC_DEFINE([_FORTIFY_SOURCE], [2],
 741     [enable compile-time and run-time bounds-checking, and some warnings])
 742   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 743
 744   # We use a slightly smaller set of warning options for lib/.
 745   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 746   nw=
 747   nw="$nw -Wunused-macros"
 748
 749   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 750   AC_SUBST([GNULIB_WARN_CFLAGS])
 751 fi
 752
 753
 754
 755 dnl Some other nice autoconf tests.
 756 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 757 dnl AC_PROG_INSTALL
 758 dnl AC_PROG_MKDIR_P
 759 dnl if test "x$RANLIB" = x; then
 760 dnl   AC_PROG_RANLIB
 761 dnl fi
 762 AC_PROG_LN_S
 763
 764 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 765   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 766 dnl Don't use GZIP, which is used by gzip for additional parameters.
 767 AC_PATH_PROG(GZIP_PROG, gzip)
 768
 769 if test $opsys = gnu-linux; then
 770   AC_PATH_PROG(PAXCTL, paxctl,,
 771     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 772   if test "X$PAXCTL" != X; then
 773     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
 774     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 775       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
 776       else AC_MSG_RESULT(no); PAXCTL=""; fi])
 777   fi
 778 fi
 779
 780 ## Need makeinfo >= 4.7 (?) to build the manuals.
 781 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 782 dnl By this stage, configure has already checked for egrep and set EGREP,
 783 dnl or exited with an error if no egrep was found.
 784 if test "$MAKEINFO" != "no" && \
 785   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 786    MAKEINFO=no
 787 fi
 788
 789 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 790 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 791 ## therefore in the category of "special tools" not normally required, which
 792 ## configure does not have to check for (eg autoconf itself).
 793 ## In a Bazaar checkout on the other hand, the manuals are not included.
 794 ## So makeinfo is a requirement to build from Bazaar, and configure
 795 ## should test for it as it does for any other build requirement.
 796 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 797 ## with pre-built manuals, from a Bazaar checkout.
 798 HAVE_MAKEINFO=yes
 799
 800 if test "$MAKEINFO" = "no"; then
 801   MAKEINFO=makeinfo
 802   if test "x${with_makeinfo}" = "xno"; then
 803     HAVE_MAKEINFO=no
 804   elif test ! -e $srcdir/info/emacs; then
 805     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 806 source tree does not seem to have pre-built manuals in the `info' directory.
 807 Either install a suitable version of makeinfo, or re-run configure
 808 with the `--without-makeinfo' option to build without the manuals.] )
 809   fi
 810 fi
 811 AC_SUBST(HAVE_MAKEINFO)
 812
 813 dnl Just so that there is only a single place we need to edit.
 814 INFO_EXT=.info
 815 INFO_OPTS=--no-split
 816 AC_SUBST(INFO_EXT)
 817 AC_SUBST(INFO_OPTS)
 818
 819 dnl Add our options to ac_link now, after it is set up.
 820
 821 if test x$GCC = xyes; then
 822   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 823     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 824 else
 825   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 826     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 827 fi
 828
 829 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 830 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 831 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 832 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 833 dnl if not built to support GNU ld.
 834
 835 late_LDFLAGS=$LDFLAGS
 836 if test x$GCC = xyes; then
 837   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 838 else
 839   LDFLAGS="$LDFLAGS -znocombreloc"
 840 fi
 841
 842 AC_MSG_CHECKING([for -znocombreloc])
 843 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 844   [AC_MSG_RESULT(yes)],
 845   LDFLAGS=$late_LDFLAGS
 846   [AC_MSG_RESULT(no)])
 847
 848
 849 dnl The function dump-emacs will not be defined and temacs will do
 850 dnl (load "loadup") automatically unless told otherwise.
 851 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 852 case "$opsys" in
 853   your-opsys-here) CANNOT_DUMP=yes ;;
 854 esac
 855
 856 test "$CANNOT_DUMP" = "yes" && \
 857   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 858
 859 AC_SUBST(CANNOT_DUMP)
 860
 861
 862 UNEXEC_OBJ=unexelf.o
 863 case "$opsys" in
 864   # MSDOS uses unexcoff.o
 865   # MSWindows uses unexw32.o
 866   aix4-2)
 867    UNEXEC_OBJ=unexaix.o
 868    ;;
 869   cygwin)
 870    UNEXEC_OBJ=unexcw.o
 871    ;;
 872   darwin)
 873    UNEXEC_OBJ=unexmacosx.o
 874    ;;
 875   hpux10-20 | hpux11)
 876    UNEXEC_OBJ=unexhp9k800.o
 877    ;;
 878   sol2-10)
 879    # Use the Solaris dldump() function, called from unexsol.c, to dump
 880    # emacs, instead of the generic ELF dump code found in unexelf.c.
 881    # The resulting binary has a complete symbol table, and is better
 882    # for debugging and other observability tools (debuggers, pstack, etc).
 883    #
 884    # If you encounter a problem using dldump(), please consider sending
 885    # a message to the OpenSolaris tools-linking mailing list:
 886    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 887    #
 888    # It is likely that dldump() works with older Solaris too, but this has
 889    # not been tested, so for now this change is for Solaris 10 or newer.
 890    UNEXEC_OBJ=unexsol.o
 891    ;;
 892 esac
 893
 894 LD_SWITCH_SYSTEM=
 895 case "$opsys" in
 896   freebsd)
 897    ## Let `ld' find image libs and similar things in /usr/local/lib.
 898    ## The system compiler, GCC, has apparently been modified to not
 899    ## look there, contrary to what a stock GCC would do.
 900 ### It's not our place to do this.  See bug#10313#17.
 901 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 902       :
 903    ;;
 904
 905   gnu-linux)
 906    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 907    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 908    ;;
 909
 910   netbsd)
 911 ### It's not our place to do this.  See bug#10313#17.
 912 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 913       :
 914    ;;
 915
 916   openbsd)
 917    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 918    ## otherwise Emacs dumps core on elf systems.
 919    LD_SWITCH_SYSTEM="-Z"
 920    ;;
 921 esac
 922 AC_SUBST(LD_SWITCH_SYSTEM)
 923
 924 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 925
 926 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 927 ## which has not been defined yet.  When this was handled with cpp,
 928 ## it was expanded to null when configure sourced the s/*.h file.
 929 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 930 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 931 ## (or somesuch), but because it is supposed to go at the _front_
 932 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 933 ## Compare with the gnu-linux case below, which added to the end
 934 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 935 ## LD_SWITCH_SYSTEM_TEMACS.
 936 case "$opsys" in
 937   netbsd|openbsd)
 938    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 939 esac
 940
 941
 942 C_SWITCH_MACHINE=
 943 case $canonical in
 944  alpha*)
 945   AC_CHECK_DECL([__ELF__])
 946   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 947     ## With ELF, make sure that all common symbols get allocated to in the
 948     ## data section.  Otherwise, the dump of temacs may miss variables in
 949     ## the shared library that have been initialized.  For example, with
 950     ## GNU libc, __malloc_initialized would normally be resolved to the
 951     ## shared library's .bss section, which is fatal.
 952     if test "x$GCC" = "xyes"; then
 953       C_SWITCH_MACHINE="-fno-common"
 954     else
 955       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 956     fi
 957   else
 958     UNEXEC_OBJ=unexalpha.o
 959   fi
 960   ;;
 961 esac
 962 AC_SUBST(C_SWITCH_MACHINE)
 963
 964 AC_SUBST(UNEXEC_OBJ)
 965
 966 C_SWITCH_SYSTEM=
 967 ## Some programs in src produce warnings saying certain subprograms
 968 ## are too complex and need a MAXMEM value greater than 2000 for
 969 ## additional optimization.  --nils@exp-math.uni-essen.de
 970 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 971   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 972 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 973 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 974 AC_SUBST(C_SWITCH_SYSTEM)
 975
 976
 977 LIBS_SYSTEM=
 978 case "$opsys" in
 979   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 980   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 981
 982   freebsd) LIBS_SYSTEM="-lutil" ;;
 983
 984   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 985
 986   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 987
 988   ## Motif needs -lgen.
 989   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 990 esac
 991 AC_SUBST(LIBS_SYSTEM)
 992
 993
 994 ### Make sure subsequent tests use flags consistent with the build flags.
 995
 996 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 997   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 998 else
 999   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1000 fi
1001
1002 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1003 AC_DEFUN([AC_TYPE_SIZE_T])
1004 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1005 AC_DEFUN([AC_TYPE_UID_T])
1006
1007
1008 LIB_MATH=-lm
1009 LIB_STANDARD=
1010 START_FILES=
1011 dnl Current possibilities handled by sed (aix4-2 -> aix,
1012 dnl gnu-linux -> gnu/linux, etc.):
1013 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1014 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1015 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1016
1017 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
1018 case $opsys in
1019   cygwin )
1020     LIB_MATH=
1021     START_FILES='pre-crt0.o'
1022     ;;
1023   darwin )
1024     ## Adding -lm confuses the dynamic linker, so omit it.
1025     LIB_MATH=
1026     START_FILES='pre-crt0.o'
1027     ;;
1028   freebsd )
1029     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1030     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1031     SYSTEM_TYPE=berkeley-unix
1032     ;;
1033   gnu-linux | gnu-kfreebsd )
1034     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1035     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1036     ;;
1037   hpux10-20 | hpux11 )
1038     LIB_STANDARD=-lc
1039     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1040     ;;
1041   dnl NB this may be adjusted below.
1042   netbsd | openbsd )
1043     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1044     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1045     SYSTEM_TYPE=berkeley-unix
1046     ;;
1047
1048   sol2* | unixware )
1049     SYSTEM_TYPE=usg-unix-v
1050     ;;
1051
1052 esac
1053
1054 AC_SUBST(LIB_MATH)
1055 AC_SUBST(START_FILES)
1056 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1057   [The type of system you are compiling for; sets `system-type'.])
1058
1059 dnl Not all platforms use crtn.o files.  Check if the current one does.
1060 crt_files=
1061
1062 for file in x $LIB_STANDARD $START_FILES; do
1063   case "$file" in
1064     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1065   esac
1066 done
1067
1068 if test "x$crt_files" != x; then
1069
1070   ## If user specified a crt-dir, use that unconditionally.
1071   crt_gcc=no
1072
1073   if test "X$CRT_DIR" = "X"; then
1074
1075     CRT_DIR=/usr/lib            # default
1076
1077     case "$canonical" in
1078       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1079       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1080       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1081       ## For anything else (eg /usr/lib32), it is up the user to specify
1082       ## the location (bug#5655).
1083       ## Test for crtn.o, not just the directory, because sometimes the
1084       ## directory exists but does not have the relevant files (bug#1287).
1085       ## FIXME better to test for binary compatibility somehow.
1086       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1087       ;;
1088
1089       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1090     esac
1091
1092     case "$opsys" in
1093       hpux10-20) CRT_DIR=/lib ;;
1094     esac
1095
1096     test "x${GCC}" = xyes && crt_gcc=yes
1097
1098   fi                            # CRT_DIR = ""
1099
1100   crt_missing=
1101
1102   for file in $crt_files; do
1103
1104     ## If we're using gcc, try to determine it automatically by asking
1105     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1106     ## system-dependent default from above.]
1107     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1108
1109        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1110        case "$crt_file" in
1111          */*)
1112            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1113            ;;
1114        esac
1115     fi
1116
1117     dnl We expect all the files to be in a single directory, so after the
1118     dnl first there is no point asking gcc.
1119     crt_gcc=no
1120
1121     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1122   done                          # $crt_files
1123
1124   test "x$crt_missing" = x || \
1125     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1126 Try using the --with-crt-dir option.])
1127
1128 fi                              # crt_files != ""
1129
1130 AC_SUBST(CRT_DIR)
1131
1132 case $opsys in
1133   netbsd | openbsd )
1134     if test -f $CRT_DIR/crti.o; then
1135
1136         test -f $CRT_DIR/crtn.o || \
1137           AC_MSG_ERROR([Required file not found: crtn.o])
1138
1139         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1140         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1141     fi
1142     ;;
1143 esac
1144
1145
1146 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1147 pre_PKG_CONFIG_LIBS=$LIBS
1148
1149 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1150
1151 dnl This function definition taken from Gnome 2.0
1152 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1153 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1154 dnl also defines GSTUFF_PKG_ERRORS on error
1155 AC_DEFUN([PKG_CHECK_MODULES], [
1156   succeeded=no
1157
1158   if test "$PKG_CONFIG" = "no" ; then
1159      ifelse([$4], , [AC_MSG_ERROR([
1160       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1161   else
1162      PKG_CONFIG_MIN_VERSION=0.9.0
1163      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1164         AC_MSG_CHECKING(for $2)
1165
1166         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1167            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1168            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1169             edit_cflags="
1170               s,///*,/,g
1171               s/^/ /
1172               s/ -I/ $isystem/g
1173               s/^ //
1174             "
1175             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1176             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1177             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1178             succeeded=yes
1179         else
1180             AC_MSG_RESULT(no)
1181             $1_CFLAGS=""
1182             $1_LIBS=""
1183             ## If we have a custom action on failure, don't print errors, but
1184             ## do set a variable so people can do so.
1185             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1186             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1187         fi
1188
1189         AC_SUBST($1_CFLAGS)
1190         AC_SUBST($1_LIBS)
1191      else
1192         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1193         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1194      fi
1195   fi
1196
1197   if test $succeeded = yes; then
1198      ifelse([$3], , :, [$3])
1199   else
1200      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1201   fi
1202 ])
1203
1204
1205 if test "${with_sound}" != "no"; then
1206   # Sound support for GNU/Linux and the free BSDs.
1207   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1208     have_sound_header=yes)
1209   # Emulation library used on NetBSD.
1210   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1211   AC_SUBST(LIBSOUND)
1212
1213   ALSA_REQUIRED=1.0.0
1214   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1215   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1216   if test $HAVE_ALSA = yes; then
1217     SAVE_CFLAGS="$CFLAGS"
1218     SAVE_LIBS="$LIBS"
1219     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1220     LIBS="$ALSA_LIBS $LIBS"
1221     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1222                     emacs_alsa_normal=yes,
1223                     emacs_alsa_normal=no)
1224     if test "$emacs_alsa_normal" != yes; then
1225       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1226                      [[snd_lib_error_set_handler (0);]])],
1227                      emacs_alsa_subdir=yes,
1228                      emacs_alsa_subdir=no)
1229       if test "$emacs_alsa_subdir" != yes; then
1230         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1231       fi
1232       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1233     fi
1234
1235     CFLAGS="$SAVE_CFLAGS"
1236     LIBS="$SAVE_LIBS"
1237     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1238     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1239     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1240   fi
1241
1242   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1243   dnl compiles only on the specified platforms.  For others, it
1244   dnl probably doesn't make sense to try.
1245   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1246      case "$opsys" in
1247        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1248        gnu-linux|freebsd|netbsd)
1249          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1250          ;;
1251      esac
1252   fi
1253
1254   AC_SUBST(CFLAGS_SOUND)
1255 fi
1256
1257 dnl checks for header files
1258 AC_CHECK_HEADERS_ONCE(
1259   linux/version.h sys/systeminfo.h
1260   stdio_ext.h fcntl.h coff.h pty.h
1261   sys/vlimit.h sys/resource.h
1262   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1263
1264 AC_MSG_CHECKING(if personality LINUX32 can be set)
1265 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1266                emacs_cv_personality_linux32=yes,
1267                emacs_cv_personality_linux32=no)
1268 AC_MSG_RESULT($emacs_cv_personality_linux32)
1269
1270 if test $emacs_cv_personality_linux32 = yes; then
1271   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1272             [Define to 1 if personality LINUX32 can be set.])
1273 fi
1274
1275 dnl On Solaris 8 there's a compilation warning for term.h because
1276 dnl it doesn't define `bool'.
1277 AC_CHECK_HEADERS(term.h, , , -)
1278 AC_HEADER_TIME
1279 AC_CHECK_DECLS([sys_siglist])
1280 if test $ac_cv_have_decl_sys_siglist != yes; then
1281   # For Tru64, at least:
1282   AC_CHECK_DECLS([__sys_siglist])
1283   if test $ac_cv_have_decl___sys_siglist = yes; then
1284     AC_DEFINE(sys_siglist, __sys_siglist,
1285               [Define to any substitute for sys_siglist.])
1286   fi
1287 fi
1288 AC_HEADER_SYS_WAIT
1289
1290 dnl Check for speed_t typedef.
1291 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1292   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1293     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1294 if test $emacs_cv_speed_t = yes; then
1295   AC_DEFINE(HAVE_SPEED_T, 1,
1296            [Define to 1 if `speed_t' is declared by <termios.h>.])
1297 fi
1298
1299 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1300 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1301 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1302   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1303 HAVE_EXCEPTION=$emacs_cv_struct_exception
1304 dnl Define on Darwin so emacs symbols will not conflict with those
1305 dnl in the System framework.  Otherwise -prebind will not work.
1306 if test $emacs_cv_struct_exception != yes || test $opsys = darwin; then
1307   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1308 fi
1309
1310 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1311 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1312 #if HAVE_SYS_SOCKET_H
1313 #include <sys/socket.h>
1314 #endif])
1315 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1316 #if HAVE_SYS_SOCKET_H
1317 #include <sys/socket.h>
1318 #endif])
1319 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1320 #if HAVE_SYS_SOCKET_H
1321 #include <sys/socket.h>
1322 #endif])
1323
1324 dnl checks for structure members
1325 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1326                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1327                   struct ifreq.ifr_addr,
1328                   struct ifreq.ifr_addr.sa_len], , ,
1329                  [AC_INCLUDES_DEFAULT
1330 #if HAVE_SYS_SOCKET_H
1331 #include <sys/socket.h>
1332 #endif
1333 #if HAVE_NET_IF_H
1334 #include <net/if.h>
1335 #endif])
1336
1337 dnl Check for endianness.
1338 dnl AC_C_BIGENDIAN is done by gnulib.
1339
1340 dnl check for Make feature
1341 dnl AC_PROG_MAKE_SET is done by Automake.
1342
1343 DEPFLAGS=
1344 MKDEPDIR=":"
1345 deps_frag=deps.mk
1346 dnl check for GNU Make if we have GCC and autodepend is on.
1347 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1348    AC_MSG_CHECKING([whether we are using GNU Make])
1349    HAVE_GNU_MAKE=no
1350    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1351    if test "x$testval" != x; then
1352       HAVE_GNU_MAKE=yes
1353    else
1354       ac_enable_autodepend=no
1355    fi
1356    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1357    if test $HAVE_GNU_MAKE = yes; then
1358       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1359       SAVE_CFLAGS="$CFLAGS"
1360       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1361       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1362       CFLAGS="$SAVE_CFLAGS"
1363       test -f deps.d || ac_enable_autodepend=no
1364       rm -rf deps.d
1365       AC_MSG_RESULT([$ac_enable_autodepend])
1366    fi
1367    if test $ac_enable_autodepend = yes; then
1368       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1369       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1370       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1371       deps_frag=autodeps.mk
1372    fi
1373 fi
1374 deps_frag=$srcdir/src/$deps_frag
1375 AC_SUBST(MKDEPDIR)
1376 AC_SUBST(DEPFLAGS)
1377 AC_SUBST_FILE(deps_frag)
1378
1379
1380 lisp_frag=$srcdir/src/lisp.mk
1381 AC_SUBST_FILE(lisp_frag)
1382
1383
1384 dnl checks for operating system services
1385 AC_SYS_LONG_FILE_NAMES
1386
1387 #### Choose a window system.
1388
1389 AC_PATH_X
1390 if test "$no_x" = yes; then
1391   window_system=none
1392 else
1393   window_system=x11
1394 fi
1395
1396 LD_SWITCH_X_SITE_RPATH=
1397 if test "${x_libraries}" != NONE; then
1398   if test -n "${x_libraries}"; then
1399     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1400     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1401   fi
1402   x_default_search_path=""
1403   x_search_path=${x_libraries}
1404   if test -z "${x_search_path}"; then
1405     x_search_path=/usr/lib
1406   fi
1407   for x_library in `echo ${x_search_path}: | \
1408                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1409     x_search_path="\
1410 ${x_library}/X11/%L/%T/%N%C%S:\
1411 ${x_library}/X11/%l/%T/%N%C%S:\
1412 ${x_library}/X11/%T/%N%C%S:\
1413 ${x_library}/X11/%L/%T/%N%S:\
1414 ${x_library}/X11/%l/%T/%N%S:\
1415 ${x_library}/X11/%T/%N%S"
1416     if test x"${x_default_search_path}" = x; then
1417       x_default_search_path=${x_search_path}
1418     else
1419       x_default_search_path="${x_search_path}:${x_default_search_path}"
1420     fi
1421   done
1422 fi
1423 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1424
1425 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1426   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1427 fi
1428
1429 if test x"${x_includes}" = x; then
1430   bitmapdir=/usr/include/X11/bitmaps
1431 else
1432   # accumulate include directories that have X11 bitmap subdirectories
1433   bmd_acc="dummyval"
1434   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1435     if test -d "${bmd}/X11/bitmaps"; then
1436       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1437     fi
1438     if test -d "${bmd}/bitmaps"; then
1439       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1440     fi
1441   done
1442   if test ${bmd_acc} != "dummyval"; then
1443     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1444   fi
1445 fi
1446
1447 HAVE_NS=no
1448 NS_IMPL_COCOA=no
1449 NS_IMPL_GNUSTEP=no
1450 tmp_CPPFLAGS="$CPPFLAGS"
1451 tmp_CFLAGS="$CFLAGS"
1452 CPPFLAGS="$CPPFLAGS -x objective-c"
1453 CFLAGS="$CFLAGS -x objective-c"
1454 TEMACS_LDFLAGS2="\${LDFLAGS}"
1455 GNU_OBJC_CFLAGS=
1456 if test "${with_ns}" != no; then
1457   if test "${opsys}" = darwin; then
1458      NS_IMPL_COCOA=yes
1459      ns_appdir=`pwd`/nextstep/Emacs.app
1460      ns_appbindir=${ns_appdir}/Contents/MacOS
1461      ns_appresdir=${ns_appdir}/Contents/Resources
1462      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1463   elif test -f $GNUSTEP_CONFIG_FILE; then
1464      NS_IMPL_GNUSTEP=yes
1465      ns_appdir=`pwd`/nextstep/Emacs.app
1466      ns_appbindir=${ns_appdir}
1467      ns_appresdir=${ns_appdir}/Resources
1468      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1469      dnl FIXME sourcing this several times in subshells seems inefficient.
1470      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1471      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1472      dnl I seemed to need these as well with GNUstep-startup 0.25.
1473      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1474      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1475      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1476        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1477      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1478        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1479      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1480      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1481      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1482      LIB_STANDARD=
1483      START_FILES=
1484      TEMACS_LDFLAGS2=
1485      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1486      dnl If they had chosen to either define it or not, we could have
1487      dnl just used AC_CHECK_DECL here.
1488      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1489        emacs_cv_objc_exceptions,
1490 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1491 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1492 1;
1493 #else
1494 fail;
1495 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1496      if test $emacs_cv_objc_exceptions = yes; then
1497        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1498        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1499          [Define if GNUstep uses ObjC exceptions.])
1500        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1501      fi
1502   fi
1503
1504   dnl This is only used while we test the NS headers, it gets reset below.
1505   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1506
1507   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1508                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1509   files are missing or cannot be compiled.])])
1510   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1511                                      [NSInteger i;])],
1512                     ns_have_nsinteger=yes,
1513                     ns_have_nsinteger=no)
1514   if test $ns_have_nsinteger = yes; then
1515     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1516   fi
1517 fi
1518 AC_SUBST(TEMACS_LDFLAGS2)
1519
1520 INSTALL_ARCH_INDEP_EXTRA=install-etc
1521 ns_self_contained=no
1522 ns_frag=/dev/null
1523 NS_OBJ=
1524 NS_OBJC_OBJ=
1525 if test "${HAVE_NS}" = yes; then
1526   if test "$with_toolkit_scroll_bars" = "no"; then
1527     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1528   fi
1529
1530   window_system=nextstep
1531   with_xft=no
1532   # set up packaging dirs
1533   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1534      ns_self_contained=yes
1535      prefix=${ns_appresdir}
1536      exec_prefix=${ns_appbindir}
1537      dnl This one isn't really used, only archlibdir is.
1538      libexecdir="\${ns_appbindir}/libexec"
1539      archlibdir="\${ns_appbindir}/libexec"
1540      docdir="\${ns_appresdir}/etc"
1541      etcdir="\${ns_appresdir}/etc"
1542      dnl FIXME maybe set datarootdir instead.
1543      dnl That would also get applications, icons, man.
1544      infodir="\${ns_appresdir}/info"
1545      mandir="\${ns_appresdir}/man"
1546      lispdir="\${ns_appresdir}/lisp"
1547      leimdir="\${ns_appresdir}/leim"
1548      INSTALL_ARCH_INDEP_EXTRA=
1549   fi
1550   ns_frag=$srcdir/src/ns.mk
1551   NS_OBJ="fontset.o fringe.o image.o"
1552   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1553 fi
1554 CFLAGS="$tmp_CFLAGS"
1555 CPPFLAGS="$tmp_CPPFLAGS"
1556 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1557 AC_SUBST(ns_self_contained)
1558 AC_SUBST(NS_OBJ)
1559 AC_SUBST(NS_OBJC_OBJ)
1560 AC_SUBST(LIB_STANDARD)
1561 AC_SUBST_FILE(ns_frag)
1562
1563 case "${window_system}" in
1564   x11 )
1565     HAVE_X_WINDOWS=yes
1566     HAVE_X11=yes
1567     case "${with_x_toolkit}" in
1568       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1569       motif ) USE_X_TOOLKIT=MOTIF ;;
1570       gtk ) with_gtk=yes
1571 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1572 dnl USE_X_TOOLKIT is set.
1573             USE_X_TOOLKIT=none ;;
1574       gtk3 ) with_gtk3=yes
1575              USE_X_TOOLKIT=none ;;
1576       no ) USE_X_TOOLKIT=none ;;
1577 dnl If user did not say whether to use a toolkit, make this decision later:
1578 dnl use the toolkit if we have gtk, or X11R5 or newer.
1579       * ) USE_X_TOOLKIT=maybe ;;
1580     esac
1581   ;;
1582   nextstep | none )
1583     HAVE_X_WINDOWS=no
1584     HAVE_X11=no
1585     USE_X_TOOLKIT=none
1586   ;;
1587 esac
1588
1589 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1590    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1591    if test "$HAVE_XSERVER" = true ||
1592       test -n "$DISPLAY" ||
1593       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1594         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1595 were found.  You should install the relevant development files for X
1596 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1597 sure you have development files for image handling, i.e.
1598 tiff, gif, jpeg, png and xpm.
1599 If you are sure you want Emacs compiled without X window support, pass
1600   --without-x
1601 to configure.])
1602    fi
1603 fi
1604
1605 ### If we're using X11, we should use the X menu package.
1606 HAVE_MENUS=no
1607 case ${HAVE_X11} in
1608   yes ) HAVE_MENUS=yes ;;
1609 esac
1610
1611 # Does the opsystem file prohibit the use of the GNU malloc?
1612 # Assume not, until told otherwise.
1613 GNU_MALLOC=yes
1614
1615 AC_CACHE_CHECK(
1616   [whether malloc is Doug Lea style],
1617   [emacs_cv_var_doug_lea_malloc],
1618   [AC_LINK_IFELSE(
1619      [AC_LANG_PROGRAM(
1620         [[#include <malloc.h>
1621           static void hook (void) {}]],
1622         [[malloc_set_state (malloc_get_state ());
1623           __after_morecore_hook = hook;
1624           __malloc_initialize_hook = hook;]])],
1625      [emacs_cv_var_doug_lea_malloc=yes],
1626      [emacs_cv_var_doug_lea_malloc=no])])
1627 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1628
1629
1630 dnl See comments in aix4-2.h about maybe using system malloc there.
1631 system_malloc=no
1632 case "$opsys" in
1633   ## darwin ld insists on the use of malloc routines in the System framework.
1634   darwin|sol2-10) system_malloc=yes ;;
1635 esac
1636
1637 if test "${system_malloc}" = "yes"; then
1638   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1639   GNU_MALLOC=no
1640   GNU_MALLOC_reason="
1641     (The GNU allocators don't work with this system configuration.)"
1642   GMALLOC_OBJ=
1643   VMLIMIT_OBJ=
1644 else
1645   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1646   VMLIMIT_OBJ=vm-limit.o
1647 fi
1648 AC_SUBST(GMALLOC_OBJ)
1649 AC_SUBST(VMLIMIT_OBJ)
1650
1651 if test "$doug_lea_malloc" = "yes" ; then
1652   if test "$GNU_MALLOC" = yes ; then
1653     GNU_MALLOC_reason="
1654       (Using Doug Lea's new malloc from the GNU C Library.)"
1655   fi
1656   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1657             [Define to 1 if you are using the GNU C Library.])
1658
1659   ## Use mmap directly for allocating larger buffers.
1660   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1661   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1662   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1663   case "$opsys" in
1664     gnu*) REL_ALLOC=no ;;
1665   esac
1666 fi
1667
1668 if test x"${REL_ALLOC}" = x; then
1669   REL_ALLOC=${GNU_MALLOC}
1670 fi
1671
1672 use_mmap_for_buffers=no
1673 case "$opsys" in
1674   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1675 esac
1676
1677 AC_FUNC_MMAP
1678 if test $use_mmap_for_buffers = yes; then
1679   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1680   REL_ALLOC=no
1681 fi
1682
1683 LIBS="$LIBS_SYSTEM $LIBS"
1684
1685 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1686 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1687 AC_CHECK_LIB(dnet, dnet_ntoa)
1688 dnl This causes -lresolv to get used in subsequent tests,
1689 dnl which causes failures on some systems such as HPUX 9.
1690 dnl AC_CHECK_LIB(resolv, gethostbyname)
1691
1692 dnl FIXME replace main with a function we actually want from this library.
1693 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1694
1695 dnl Check if pthreads is available.
1696 LIB_PTHREAD=
1697 AC_CHECK_HEADERS_ONCE(pthread.h)
1698 if test "$ac_cv_header_pthread_h"; then
1699   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1700   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1701   dnl testing for pthread_self if Emacs uses gmalloc.c.
1702   if test "$GMALLOC_OBJ" = gmalloc.o; then
1703     emacs_pthread_function=pthread_atfork
1704   else
1705     emacs_pthread_function=pthread_self
1706   fi
1707   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1708 fi
1709 if test "$HAVE_PTHREAD" = yes; then
1710   case "${canonical}" in
1711     *-hpux*) ;;
1712     *) LIB_PTHREAD="-lpthread"
1713        LIBS="$LIB_PTHREAD $LIBS" ;;
1714   esac
1715   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1716 fi
1717 AC_SUBST([LIB_PTHREAD])
1718
1719 AC_CHECK_LIB(pthreads, cma_open)
1720
1721 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1722 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1723 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1724 ## added to LIBS in configure would never contain the pthreads part,
1725 ## but the value used in Makefiles might.  FIXME?
1726 ##
1727 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1728 ## be harmless on older versions of X where it happens to exist.
1729 test "$opsys" = "aix4-2" && \
1730   test $ac_cv_lib_pthreads_cma_open = yes && \
1731   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1732
1733 dnl Check for need for bigtoc support on IBM AIX
1734
1735 case ${host_os} in
1736 aix*)
1737   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1738     case $GCC in
1739     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1740     *) gdb_cv_bigtoc=-bbigtoc ;;
1741     esac
1742
1743     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1744     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1745   ])
1746   ;;
1747 esac
1748
1749 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1750 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1751 # REAL_CPPFLAGS later on.
1752
1753 REAL_CFLAGS="$CFLAGS"
1754 REAL_CPPFLAGS="$CPPFLAGS"
1755
1756 if test "${HAVE_X11}" = "yes"; then
1757   DEFS="$C_SWITCH_X_SITE $DEFS"
1758   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1759   LIBS="-lX11 $LIBS"
1760   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1761   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1762
1763   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1764   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1765   # but it's more convenient here to set LD_RUN_PATH since this
1766   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1767   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1768     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1769     export LD_RUN_PATH
1770   fi
1771
1772   if test "${opsys}" = "gnu-linux"; then
1773     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1774     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1775      [[XOpenDisplay ("foo");]])],
1776      [xgnu_linux_first_failure=no],
1777      [xgnu_linux_first_failure=yes])
1778     if test "${xgnu_linux_first_failure}" = "yes"; then
1779       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1780       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1781       OLD_CPPFLAGS="$CPPFLAGS"
1782       OLD_LIBS="$LIBS"
1783       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1784       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1785       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1786       LIBS="$LIBS -b i486-linuxaout"
1787       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1788        [[XOpenDisplay ("foo");]])],
1789        [xgnu_linux_second_failure=no],
1790        [xgnu_linux_second_failure=yes])
1791       if test "${xgnu_linux_second_failure}" = "yes"; then
1792         # If we get the same failure with -b, there is no use adding -b.
1793         # So take it out.  This plays safe.
1794         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1795         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1796         CPPFLAGS="$OLD_CPPFLAGS"
1797         LIBS="$OLD_LIBS"
1798         AC_MSG_RESULT(no)
1799       else
1800         AC_MSG_RESULT(yes)
1801       fi
1802     else
1803       AC_MSG_RESULT(no)
1804     fi
1805   fi
1806
1807   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1808   # header files included from there.
1809   AC_MSG_CHECKING(for Xkb)
1810   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1811 #include <X11/XKBlib.h>]],
1812         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1813         emacs_xkb=yes, emacs_xkb=no)
1814   AC_MSG_RESULT($emacs_xkb)
1815   if test $emacs_xkb = yes; then
1816     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1817   fi
1818
1819   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1820 XScreenNumberOfScreen)
1821 fi
1822
1823 if test "${window_system}" = "x11"; then
1824   AC_MSG_CHECKING(X11 version 6)
1825   AC_CACHE_VAL(emacs_cv_x11_version_6,
1826   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1827 [[#if XlibSpecificationRelease < 6
1828 fail;
1829 #endif
1830 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1831   if test $emacs_cv_x11_version_6 = yes; then
1832     AC_MSG_RESULT(6 or newer)
1833     AC_DEFINE(HAVE_X11R6, 1,
1834               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1835     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1836     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1837     ## XIM support.
1838     case "$opsys" in
1839       sol2-*) : ;;
1840       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1841            [Define if you have usable X11R6-style XIM support.])
1842          ;;
1843     esac
1844   else
1845     AC_MSG_RESULT(before 6)
1846   fi
1847 fi
1848
1849
1850 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1851 HAVE_RSVG=no
1852 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1853   if test "${with_rsvg}" != "no"; then
1854     RSVG_REQUIRED=2.11.0
1855     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1856
1857     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1858     AC_SUBST(RSVG_CFLAGS)
1859     AC_SUBST(RSVG_LIBS)
1860
1861     if test $HAVE_RSVG = yes; then
1862       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1863       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1864       LIBS="$RSVG_LIBS $LIBS"
1865     fi
1866   fi
1867 fi
1868
1869 HAVE_IMAGEMAGICK=no
1870 if test "${HAVE_X11}" = "yes"; then
1871   if test "${with_imagemagick}" != "no"; then
1872     ## 6.2.8 is the earliest version known to work, but earlier versions
1873     ## might work - let us know if you find one.
1874     ## 6.0.7 does not work.  See bug#7955.
1875     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1876     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1877     AC_SUBST(IMAGEMAGICK_CFLAGS)
1878     AC_SUBST(IMAGEMAGICK_LIBS)
1879
1880     if test $HAVE_IMAGEMAGICK = yes; then
1881       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1882       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1883       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1884       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
1885     fi
1886   fi
1887 fi
1888
1889
1890 HAVE_GTK=no
1891 GTK_OBJ=
1892 if test "${with_gtk3}" = "yes"; then
1893   GLIB_REQUIRED=2.28
1894   GTK_REQUIRED=3.0
1895   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1896
1897   dnl Checks for libraries.
1898   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1899   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1900      AC_MSG_ERROR($GTK_PKG_ERRORS)
1901   fi
1902   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1903   GTK_OBJ=emacsgtkfixed.o
1904 fi
1905
1906 if test "$pkg_check_gtk" != "yes"; then
1907   HAVE_GTK=no
1908 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1909   GLIB_REQUIRED=2.10
1910   GTK_REQUIRED=2.10
1911   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1912
1913   dnl Checks for libraries.
1914   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1915   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1916      AC_MSG_ERROR($GTK_PKG_ERRORS)
1917   fi
1918 fi
1919 fi
1920
1921 if test x"$pkg_check_gtk" = xyes; then
1922
1923   AC_SUBST(GTK_CFLAGS)
1924   AC_SUBST(GTK_LIBS)
1925   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1926   CFLAGS="$CFLAGS $GTK_CFLAGS"
1927   LIBS="$GTK_LIBS $LIBS"
1928   dnl Try to compile a simple GTK program.
1929   GTK_COMPILES=no
1930   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1931   if test "${GTK_COMPILES}" != "yes"; then
1932     if test "$USE_X_TOOLKIT" != "maybe"; then
1933       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1934     fi
1935   else
1936     HAVE_GTK=yes
1937     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1938     GTK_OBJ="gtkutil.o $GTK_OBJ"
1939     USE_X_TOOLKIT=none
1940     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1941       :
1942     else
1943       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1944        closing open displays.  This is no problem if you just use
1945        one display, but if you use more than one and close one of them
1946        Emacs may crash.]])
1947       sleep 3
1948     fi
1949   fi
1950
1951 fi
1952 AC_SUBST(GTK_OBJ)
1953
1954
1955 if test "${HAVE_GTK}" = "yes"; then
1956
1957   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1958   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1959   if test "$with_toolkit_scroll_bars" != no; then
1960     with_toolkit_scroll_bars=yes
1961   fi
1962
1963   dnl  Check if we have the old file selection dialog declared and
1964   dnl  in the link library.  In 2.x it may be in the library,
1965   dnl  but not declared if deprecated featured has been selected out.
1966   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1967   HAVE_GTK_FILE_SELECTION=no
1968   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1969                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1970 #include <gtk/gtk.h>])
1971   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1972     AC_CHECK_FUNCS(gtk_file_selection_new)
1973   fi
1974
1975
1976   dnl Check for functions introduced in 2.14 and later.
1977   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1978                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1979                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1980                  gtk_orientable_set_orientation \
1981                  gtk_window_set_has_resize_grip)
1982 fi
1983
1984 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1985 dnl other platforms.
1986 HAVE_DBUS=no
1987 DBUS_OBJ=
1988 if test "${with_dbus}" = "yes"; then
1989    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1990    if test "$HAVE_DBUS" = yes; then
1991      LIBS="$LIBS $DBUS_LIBS"
1992      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1993      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
1994      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
1995      dnl D-Bus 1.5.12.
1996      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
1997                     dbus_type_is_valid \
1998                     dbus_validate_bus_name \
1999                     dbus_validate_path \
2000                     dbus_validate_interface \
2001                     dbus_validate_member)
2002      DBUS_OBJ=dbusbind.o
2003    fi
2004 fi
2005 AC_SUBST(DBUS_OBJ)
2006
2007 dnl GSettings has been tested under GNU/Linux only.
2008 HAVE_GSETTINGS=no
2009 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2010    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2011    if test "$HAVE_GSETTINGS" = "yes"; then
2012       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2013       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2014       SETTINGS_LIBS="$GSETTINGS_LIBS"
2015    fi
2016 fi
2017
2018 dnl GConf has been tested under GNU/Linux only.
2019 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2020 HAVE_GCONF=no
2021 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2022    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2023    if test "$HAVE_GCONF" = yes; then
2024       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2025       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2026       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2027       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2028    fi
2029 fi
2030
2031 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2032     SAVE_CFLAGS="$CFLAGS"
2033     SAVE_LIBS="$LIBS"
2034     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2035     LIBS="$SETTINGS_LIBS $LIBS"
2036     AC_CHECK_FUNCS([g_type_init])
2037     CFLAGS="$SAVE_CFLAGS"
2038     LIBS="$SAVE_LIBS"
2039 fi
2040 AC_SUBST(SETTINGS_CFLAGS)
2041 AC_SUBST(SETTINGS_LIBS)
2042
2043
2044 dnl SELinux is available for GNU/Linux only.
2045 HAVE_LIBSELINUX=no
2046 LIBSELINUX_LIBS=
2047 if test "${with_selinux}" = "yes"; then
2048    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2049    if test "$HAVE_LIBSELINUX" = yes; then
2050       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2051       LIBSELINUX_LIBS=-lselinux
2052    fi
2053 fi
2054 AC_SUBST(LIBSELINUX_LIBS)
2055
2056 HAVE_GNUTLS=no
2057 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2058 if test "${with_gnutls}" = "yes" ; then
2059   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2060   if test "${HAVE_GNUTLS}" = "yes"; then
2061     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2062   fi
2063
2064   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2065   LIBS="$LIBGNUTLS_LIBS $LIBS"
2066   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2067
2068   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2069     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2070   fi
2071 fi
2072
2073 AC_SUBST(LIBGNUTLS_LIBS)
2074 AC_SUBST(LIBGNUTLS_CFLAGS)
2075
2076 dnl Do not put whitespace before the #include statements below.
2077 dnl Older compilers (eg sunos4 cc) choke on it.
2078 HAVE_XAW3D=no
2079 LUCID_LIBW=
2080 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2081   if test "$with_xaw3d" != no; then
2082     AC_MSG_CHECKING(for xaw3d)
2083     AC_CACHE_VAL(emacs_cv_xaw3d,
2084     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2085 #include <X11/Intrinsic.h>
2086 #include <X11/Xaw3d/Simple.h>]],
2087       [[]])],
2088       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2089                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2090       emacs_cv_xaw3d=no)])
2091   else
2092     emacs_cv_xaw3d=no
2093   fi
2094   if test $emacs_cv_xaw3d = yes; then
2095     AC_MSG_RESULT([yes; using Lucid toolkit])
2096     USE_X_TOOLKIT=LUCID
2097     HAVE_XAW3D=yes
2098     LUCID_LIBW=-lXaw3d
2099     AC_DEFINE(HAVE_XAW3D, 1,
2100               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2101   else
2102     AC_MSG_RESULT(no)
2103     AC_MSG_CHECKING(for libXaw)
2104     AC_CACHE_VAL(emacs_cv_xaw,
2105     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2106 #include <X11/Intrinsic.h>
2107 #include <X11/Xaw/Simple.h>]],
2108       [[]])],
2109       emacs_cv_xaw=yes,
2110       emacs_cv_xaw=no)])
2111     if test $emacs_cv_xaw = yes; then
2112       AC_MSG_RESULT([yes; using Lucid toolkit])
2113       USE_X_TOOLKIT=LUCID
2114       LUCID_LIBW=-lXaw
2115     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2116       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2117     else
2118       AC_MSG_ERROR([No X toolkit could be found.
2119 If you are sure you want Emacs compiled without an X toolkit, pass
2120   --with-x-toolkit=no
2121 to configure.  Otherwise, install the development libraries for the toolkit
2122 that you want to use (e.g. Gtk+) and re-run configure.])
2123     fi
2124   fi
2125 fi
2126
2127 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2128
2129 LIBXTR6=
2130 if test "${USE_X_TOOLKIT}" != "none"; then
2131   AC_MSG_CHECKING(X11 toolkit version)
2132   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2133   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2134 [[#if XtSpecificationRelease < 6
2135 fail;
2136 #endif
2137 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2138   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2139   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2140     AC_MSG_RESULT(6 or newer)
2141     AC_DEFINE(HAVE_X11XTR6, 1,
2142               [Define to 1 if you have the X11R6 or newer version of Xt.])
2143     LIBXTR6="-lSM -lICE"
2144     case "$opsys" in
2145       ## Use libw.a along with X11R6 Xt.
2146       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2147     esac
2148   else
2149     AC_MSG_RESULT(before 6)
2150   fi
2151
2152 dnl If using toolkit, check whether libXmu.a exists.
2153 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2154   OLDLIBS="$LIBS"
2155   if test x$HAVE_X11XTR6 = xyes; then
2156     LIBS="-lXt -lSM -lICE $LIBS"
2157   else
2158     LIBS="-lXt $LIBS"
2159   fi
2160   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2161   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2162   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2163 fi
2164 AC_SUBST(LIBXTR6)
2165
2166 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2167 dnl Why not just test for libxmu in the normal way?
2168 LIBXMU=-lXmu
2169 case $opsys in
2170   ## These systems don't supply Xmu.
2171   hpux* | aix4-2 )
2172     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2173     ;;
2174 esac
2175 AC_SUBST(LIBXMU)
2176
2177 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2178 if test "${HAVE_X11}" = "yes"; then
2179   if test "${USE_X_TOOLKIT}" != "none"; then
2180     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2181   fi
2182 fi
2183
2184 LIBXP=
2185 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2186   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2187   if test -d /usr/include/openmotif; then
2188     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2189     emacs_cv_openmotif=yes
2190     case "$canonical" in
2191       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2192       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2193       ;;
2194       *)
2195       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2196     esac
2197   else
2198     emacs_cv_openmotif=no
2199   fi
2200   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2201   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2202     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2203 int x = 5;
2204 #else
2205 Motif version prior to 2.1.
2206 #endif]])],
2207     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2208   if test $emacs_cv_motif_version_2_1 = yes; then
2209     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2210     if test x$emacs_cv_openmotif = xyes; then
2211       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2212     fi
2213   else
2214     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2215     # We put this in CFLAGS temporarily to precede other -I options
2216     # that might be in CFLAGS temporarily.
2217     # We put this in CPPFLAGS where it precedes the other -I options.
2218     OLD_CPPFLAGS=$CPPFLAGS
2219     OLD_CFLAGS=$CFLAGS
2220     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2221     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2222     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2223       [[int x = 5;]])],
2224       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2225     if test $emacs_cv_lesstif = yes; then
2226       # Make sure this -I option remains in CPPFLAGS after it is set
2227       # back to REAL_CPPFLAGS.
2228       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2229       # have those other -I options anyway.  Ultimately, having this
2230       # directory ultimately in CPPFLAGS will be enough.
2231       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2232       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2233     else
2234       CFLAGS=$OLD_CFLAGS
2235       CPPFLAGS=$OLD_CPPFLAGS
2236     fi
2237   fi
2238   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2239     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2240 fi
2241
2242 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2243 dnl using Motif or Xaw3d is available, and unless
2244 dnl --with-toolkit-scroll-bars=no was specified.
2245
2246 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2247             [Define to 1 if we should use toolkit scroll bars.])dnl
2248 USE_TOOLKIT_SCROLL_BARS=no
2249 if test "${with_toolkit_scroll_bars}" != "no"; then
2250   if test "${USE_X_TOOLKIT}" != "none"; then
2251     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2252       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2253       HAVE_XAW3D=no
2254       USE_TOOLKIT_SCROLL_BARS=yes
2255     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2256       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2257       USE_TOOLKIT_SCROLL_BARS=yes
2258     fi
2259   elif test "${HAVE_GTK}" = "yes"; then
2260     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2261     USE_TOOLKIT_SCROLL_BARS=yes
2262   elif test "${HAVE_NS}" = "yes"; then
2263     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2264     USE_TOOLKIT_SCROLL_BARS=yes
2265   fi
2266 fi
2267
2268 dnl See if XIM is available.
2269 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2270           #include <X11/Xlib.h>
2271           #include <X11/Xresource.h>]],
2272          [[XIMProc  callback;]])],
2273          [HAVE_XIM=yes
2274          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2275          HAVE_XIM=no)
2276
2277 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2278
2279 if test "${with_xim}" != "no"; then
2280   AC_DEFINE(USE_XIM, 1,
2281             [Define to 1 if we should use XIM, if it is available.])
2282 fi
2283
2284
2285 if test "${HAVE_XIM}" != "no"; then
2286   late_CFLAGS=$CFLAGS
2287   if test "$GCC" = yes; then
2288     CFLAGS="$CFLAGS --pedantic-errors"
2289   fi
2290   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2291 #include <X11/Xlib.h>
2292 #include <X11/Xresource.h>]],
2293 [[Display *display;
2294 XrmDatabase db;
2295 char *res_name;
2296 char *res_class;
2297 XIMProc  callback;
2298 XPointer *client_data;
2299 #ifndef __GNUC__
2300 /* If we're not using GCC, it's probably not XFree86, and this is
2301    probably right, but we can't use something like --pedantic-errors.  */
2302 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2303                                            char*, XIMProc, XPointer*);
2304 #endif
2305 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2306    client_data);]])],
2307     [emacs_cv_arg6_star=yes])
2308   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2309          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2310 either XPointer or XPointer*.])dnl
2311   if test "$emacs_cv_arg6_star" = yes; then
2312     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2313   else
2314     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2315   fi
2316   CFLAGS=$late_CFLAGS
2317 fi
2318
2319 ### Start of font-backend (under any platform) section.
2320 # (nothing here yet -- this is a placeholder)
2321 ### End of font-backend (under any platform) section.
2322
2323 ### Start of font-backend (under X11) section.
2324 if test "${HAVE_X11}" = "yes"; then
2325    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2326
2327    ## Use -lXft if available, unless `--with-xft=no'.
2328    HAVE_XFT=maybe
2329     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2330       with_xft="no";
2331     fi
2332     if test "x${with_xft}" != "xno"; then
2333
2334       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2335       ## Because xftfont.c uses XRenderQueryExtension, we also
2336       ## need to link to -lXrender.
2337       HAVE_XRENDER=no
2338       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2339       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2340         OLD_CPPFLAGS="$CPPFLAGS"
2341         OLD_CFLAGS="$CFLAGS"
2342         OLD_LIBS="$LIBS"
2343         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2344         CFLAGS="$CFLAGS $XFT_CFLAGS"
2345         XFT_LIBS="-lXrender $XFT_LIBS"
2346         LIBS="$XFT_LIBS $LIBS"
2347         AC_CHECK_HEADER(X11/Xft/Xft.h,
2348           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2349
2350         if test "${HAVE_XFT}" = "yes"; then
2351           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2352             AC_SUBST(XFT_LIBS)
2353           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2354         else
2355           CPPFLAGS="$OLD_CPPFLAGS"
2356           CFLAGS="$OLD_CFLAGS"
2357           LIBS="$OLD_LIBS"
2358         fi                        # "${HAVE_XFT}" = "yes"
2359       fi                          # "$HAVE_XFT" != no
2360     fi                            # "x${with_xft}" != "xno"
2361
2362     ## We used to allow building with FreeType and without Xft.
2363     ## However, the ftx font backend driver is not in good shape.
2364     if test "$HAVE_XFT" != "yes"; then
2365        dnl For the "Does Emacs use" message at the end.
2366        HAVE_XFT=no
2367        HAVE_FREETYPE=no
2368     else
2369        dnl Strict linkers fail with
2370        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2371        dnl if -lfreetype is not specified.
2372        dnl The following is needed to set FREETYPE_LIBS.
2373        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2374                          HAVE_FREETYPE=no)
2375
2376        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2377     fi
2378
2379     HAVE_LIBOTF=no
2380     if test "${HAVE_FREETYPE}" = "yes"; then
2381       AC_DEFINE(HAVE_FREETYPE, 1,
2382                 [Define to 1 if using the freetype and fontconfig libraries.])
2383       if test "${with_libotf}" != "no"; then
2384         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2385                           HAVE_LIBOTF=no)
2386         if test "$HAVE_LIBOTF" = "yes"; then
2387           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2388           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2389                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2390                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2391           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2392             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2393                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2394           fi
2395         fi
2396       fi
2397     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2398     dnl Does the new font backend require it, or can it work without it?
2399     fi
2400
2401     HAVE_M17N_FLT=no
2402     if test "${HAVE_LIBOTF}" = yes; then
2403       if test "${with_m17n_flt}" != "no"; then
2404         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2405         if test "$HAVE_M17N_FLT" = "yes"; then
2406           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2407         fi
2408       fi
2409     fi
2410 else
2411     HAVE_XFT=no
2412     HAVE_FREETYPE=no
2413     HAVE_LIBOTF=no
2414     HAVE_M17N_FLT=no
2415 fi
2416
2417 ### End of font-backend (under X11) section.
2418
2419 AC_SUBST(FREETYPE_CFLAGS)
2420 AC_SUBST(FREETYPE_LIBS)
2421 AC_SUBST(FONTCONFIG_CFLAGS)
2422 AC_SUBST(FONTCONFIG_LIBS)
2423 AC_SUBST(LIBOTF_CFLAGS)
2424 AC_SUBST(LIBOTF_LIBS)
2425 AC_SUBST(M17N_FLT_CFLAGS)
2426 AC_SUBST(M17N_FLT_LIBS)
2427
2428 ### Use -lXpm if available, unless `--with-xpm=no'.
2429 HAVE_XPM=no
2430 LIBXPM=
2431 if test "${HAVE_X11}" = "yes"; then
2432   if test "${with_xpm}" != "no"; then
2433     AC_CHECK_HEADER(X11/xpm.h,
2434       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2435     if test "${HAVE_XPM}" = "yes"; then
2436       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2437       AC_EGREP_CPP(no_return_alloc_pixels,
2438       [#include "X11/xpm.h"
2439 #ifndef XpmReturnAllocPixels
2440 no_return_alloc_pixels
2441 #endif
2442       ], HAVE_XPM=no, HAVE_XPM=yes)
2443
2444       if test "${HAVE_XPM}" = "yes"; then
2445         AC_MSG_RESULT(yes)
2446       else
2447         AC_MSG_RESULT(no)
2448       fi
2449     fi
2450   fi
2451
2452   if test "${HAVE_XPM}" = "yes"; then
2453     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2454     LIBXPM=-lXpm
2455   fi
2456 fi
2457 AC_SUBST(LIBXPM)
2458
2459 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2460 HAVE_JPEG=no
2461 LIBJPEG=
2462 if test "${HAVE_X11}" = "yes"; then
2463   if test "${with_jpeg}" != "no"; then
2464     dnl Checking for jpeglib.h can lose because of a redefinition of
2465     dnl  HAVE_STDLIB_H.
2466     AC_CHECK_HEADER(jerror.h,
2467       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2468   fi
2469
2470   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2471   if test "${HAVE_JPEG}" = "yes"; then
2472     AC_DEFINE(HAVE_JPEG)
2473     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2474         [#include <jpeglib.h>
2475          version=JPEG_LIB_VERSION
2476 ],
2477         [AC_DEFINE(HAVE_JPEG)],
2478         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2479         HAVE_JPEG=no])
2480   fi
2481   if test "${HAVE_JPEG}" = "yes"; then
2482     LIBJPEG=-ljpeg
2483   fi
2484 fi
2485 AC_SUBST(LIBJPEG)
2486
2487 ### Use -lpng if available, unless `--with-png=no'.
2488 HAVE_PNG=no
2489 LIBPNG=
2490 if test "${HAVE_X11}" = "yes"; then
2491   if test "${with_png}" != "no"; then
2492     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2493     # in /usr/include/libpng.
2494     AC_CHECK_HEADERS(png.h libpng/png.h, break)
2495     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2496       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2497     fi
2498   fi
2499
2500   if test "${HAVE_PNG}" = "yes"; then
2501     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2502     LIBPNG="-lpng -lz -lm"
2503
2504     AC_CHECK_DECL(png_longjmp,
2505       [],
2506       [AC_DEFINE(PNG_DEPSTRUCT, [],
2507          [Define to empty to suppress deprecation warnings when building
2508           with --enable-gcc-warnings and with libpng versions before 1.5,
2509           which lack png_longjmp.])],
2510       [[#ifdef HAVE_LIBPNG_PNG_H
2511         # include <libpng/png.h>
2512         #else
2513         # include <png.h>
2514         #endif
2515       ]])
2516   fi
2517 fi
2518 AC_SUBST(LIBPNG)
2519
2520 ### Use -ltiff if available, unless `--with-tiff=no'.
2521 HAVE_TIFF=no
2522 LIBTIFF=
2523 if test "${HAVE_X11}" = "yes"; then
2524   if test "${with_tiff}" != "no"; then
2525     AC_CHECK_HEADER(tiffio.h,
2526       [tifflibs="-lz -lm"
2527       # At least one tiff package requires the jpeg library.
2528       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2529       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2530   fi
2531
2532   if test "${HAVE_TIFF}" = "yes"; then
2533     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2534     dnl FIXME -lz -lm, as per libpng?
2535     LIBTIFF=-ltiff
2536   fi
2537 fi
2538 AC_SUBST(LIBTIFF)
2539
2540 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2541 HAVE_GIF=no
2542 LIBGIF=
2543 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2544   AC_CHECK_HEADER(gif_lib.h,
2545 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2546 # Earlier versions can crash Emacs.
2547     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2548
2549   if test "$HAVE_GIF" = yes; then
2550     LIBGIF=-lgif
2551   elif test "$HAVE_GIF" = maybe; then
2552 # If gif_lib.h but no libgif, try libungif.
2553     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2554     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2555   fi
2556
2557   if test "${HAVE_GIF}" = "yes"; then
2558     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2559   fi
2560 fi
2561 AC_SUBST(LIBGIF)
2562
2563 dnl Check for required libraries.
2564 if test "${HAVE_X11}" = "yes"; then
2565   MISSING=""
2566   WITH_NO=""
2567   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2568     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2569   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2570     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2571   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2572     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2573   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2574     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2575   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2576     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2577
2578   if test "X${MISSING}" != X; then
2579     AC_MSG_ERROR([The following required libraries were not found:
2580     $MISSING
2581 Maybe some development libraries/packages are missing?
2582 If you don't want to link with them give
2583     $WITH_NO
2584 as options to configure])
2585   fi
2586 fi
2587
2588 ### Use -lgpm if available, unless `--with-gpm=no'.
2589 HAVE_GPM=no
2590 LIBGPM=
2591 if test "${with_gpm}" != "no"; then
2592   AC_CHECK_HEADER(gpm.h,
2593     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2594
2595   if test "${HAVE_GPM}" = "yes"; then
2596     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2597     LIBGPM=-lgpm
2598   fi
2599 fi
2600 AC_SUBST(LIBGPM)
2601
2602 dnl Check for malloc/malloc.h on darwin
2603 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2604
2605 GNUSTEP_CFLAGS=
2606 ### Use NeXTstep API to implement GUI.
2607 if test "${HAVE_NS}" = "yes"; then
2608   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2609   if test "${NS_IMPL_COCOA}" = "yes"; then
2610     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2611   fi
2612   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2613     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2614     # See also .m.o rule in Makefile.in */
2615     # FIXME: are all these flags really needed?  Document here why.  */
2616     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2617     ## Extra CFLAGS applied to src/*.m files.
2618     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2619   fi
2620   # We also have mouse menus.
2621   HAVE_MENUS=yes
2622   OTHER_FILES=ns-app
2623 fi
2624
2625
2626 ### Use session management (-lSM -lICE) if available
2627 HAVE_X_SM=no
2628 LIBXSM=
2629 if test "${HAVE_X11}" = "yes"; then
2630   AC_CHECK_HEADER(X11/SM/SMlib.h,
2631     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2632
2633   if test "${HAVE_X_SM}" = "yes"; then
2634     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2635     LIBXSM="-lSM -lICE"
2636     case "$LIBS" in
2637       *-lSM*) ;;
2638       *)      LIBS="$LIBXSM $LIBS" ;;
2639     esac
2640   fi
2641 fi
2642 AC_SUBST(LIBXSM)
2643
2644 ### Use libxml (-lxml2) if available
2645 HAVE_LIBXML2=no
2646 if test "${with_xml2}" != "no"; then
2647   ### I'm not sure what the version number should be, so I just guessed.
2648   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2649   if test "${HAVE_LIBXML2}" = "yes"; then
2650     LIBS="$LIBXML2_LIBS $LIBS"
2651     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2652     if test "${HAVE_LIBXML2}" = "yes"; then
2653       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2654     else
2655       LIBXML2_LIBS=""
2656       LIBXML2_CFLAGS=""
2657     fi
2658   fi
2659 fi
2660 AC_SUBST(LIBXML2_LIBS)
2661 AC_SUBST(LIBXML2_CFLAGS)
2662
2663 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2664 AC_CACHE_CHECK(whether netdb declares h_errno,
2665                emacs_cv_netdb_declares_h_errno,
2666 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2667   [[return h_errno;]])],
2668   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2669 if test $emacs_cv_netdb_declares_h_errno = yes; then
2670   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2671 fi
2672
2673 # fmod, logb, and frexp are found in -lm on most systems.
2674 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2675 AC_CHECK_LIB(m, sqrt)
2676
2677 # Check for mail-locking functions in a "mail" library.  Probably this should
2678 # have the same check as for liblockfile below.
2679 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2680 if test $have_mail = yes; then
2681   LIBS_MAIL=-lmail
2682   LIBS="$LIBS_MAIL $LIBS"
2683   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2684 else
2685   LIBS_MAIL=
2686 fi
2687 dnl Debian, at least:
2688 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2689 if test $have_lockfile = yes; then
2690    LIBS_MAIL=-llockfile
2691    LIBS="$LIBS_MAIL $LIBS"
2692    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2693 else
2694 # If we have the shared liblockfile, assume we must use it for mail
2695 # locking (e.g. Debian).  If we couldn't link against liblockfile
2696 # (no liblockfile.a installed), ensure that we don't need to.
2697   dnl This works for files generally, not just executables.
2698   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2699   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2700                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2701   if test $ac_cv_prog_liblockfile = yes; then
2702     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2703 This probably means that movemail could lose mail.
2704 There may be a `development' package to install containing liblockfile.])
2705   fi
2706 fi
2707 AC_CHECK_HEADERS_ONCE(maillock.h)
2708 AC_SUBST(LIBS_MAIL)
2709
2710 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2711 ## interlock access to the mail spool.  The alternative is a lock file named
2712 ## /usr/spool/mail/$USER.lock.
2713 mail_lock=no
2714 case "$opsys" in
2715   aix4-2) mail_lock="lockf" ;;
2716
2717   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2718
2719   ## On GNU/Linux systems, both methods are used by various mail programs.
2720   ## I assume most people are using newer mailers that have heard of flock.
2721   ## Change this if you need to.
2722   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2723   ## configure gets the right answers, and that means *NOT* using flock.
2724   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2725   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2726   ## Debian maintainer hasn't provided a clean fix for Emacs.
2727   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2728   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2729   ## correct logic.  -- fx
2730   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2731   ## liblockfile is a Free Software replacement for libmail, used on
2732   ## Debian systems and elsewhere. -rfr.
2733   gnu-*)
2734     mail_lock="flock"
2735     if test $have_mail = yes || test $have_lockfile = yes; then
2736       test $ac_cv_header_maillock_h = yes && mail_lock=no
2737     fi
2738     ;;
2739 esac
2740
2741 BLESSMAIL_TARGET=
2742 case "$mail_lock" in
2743   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2744
2745   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2746
2747   *) BLESSMAIL_TARGET="need-blessmail" ;;
2748 esac
2749 AC_SUBST(BLESSMAIL_TARGET)
2750
2751
2752 AC_CHECK_FUNCS(gethostname \
2753 closedir getrusage get_current_dir_name \
2754 lrand48 logb frexp fmod cbrt setsid \
2755 fpathconf select euidaccess getpagesize setlocale \
2756 utimes getrlimit setrlimit setpgid getcwd shutdown getaddrinfo \
2757 __fpending strsignal setitimer \
2758 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
2759 gai_strerror mkstemp getline getdelim fsync sync \
2760 difftime posix_memalign \
2761 getpwent endpwent getgrent endgrent \
2762 touchlock \
2763 cfmakeraw cfsetspeed copysign __executable_start)
2764
2765 dnl getwd appears to be buggy on SVR4.2, so we don't use it.
2766 if test $opsys = unixware; then
2767   dnl In case some other test ends up checking for getwd.
2768   AC_DEFINE(BROKEN_GETWD, 1, [Define if getwd should not be used.])
2769 else
2770   AC_CHECK_FUNCS(getwd)
2771 fi
2772
2773 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
2774 ## has a broken `rint' in some library versions including math library
2775 ## version number A.09.05.
2776 ## You can fix the math library by installing patch number PHSS_4630.
2777 ## But we can fix it more reliably for Emacs by just not using rint.
2778 ## We also skip HAVE_RANDOM - see comments in src/conf_post.h.
2779 case $opsys in
2780    hpux*) : ;;
2781    *) AC_CHECK_FUNCS(random rint) ;;
2782 esac
2783
2784 dnl Cannot use AC_CHECK_FUNCS
2785 AC_CACHE_CHECK([for __builtin_unwind_init],
2786                emacs_cv_func___builtin_unwind_init,
2787 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2788                 emacs_cv_func___builtin_unwind_init=yes,
2789                 emacs_cv_func___builtin_unwind_init=no)])
2790 if test $emacs_cv_func___builtin_unwind_init = yes; then
2791   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2792             [Define to 1 if you have the `__builtin_unwind_init' function.])
2793 fi
2794
2795 AC_CHECK_HEADERS_ONCE(sys/un.h)
2796
2797 AC_FUNC_FSEEKO
2798
2799 AC_FUNC_GETPGRP
2800
2801 # UNIX98 PTYs.
2802 AC_CHECK_FUNCS(grantpt)
2803
2804 # PTY-related GNU extensions.
2805 AC_CHECK_FUNCS(getpt posix_openpt)
2806
2807 # Check this now, so that we will NOT find the above functions in ncurses.
2808 # That is because we have not set up to link ncurses in lib-src.
2809 # It's better to believe a function is not available
2810 # than to expect to find it in ncurses.
2811 # Also we need tputs and friends to be able to build at all.
2812 AC_MSG_CHECKING([for library containing tputs])
2813 # Run a test program that contains a call to tputs, a call that is
2814 # never executed.  This tests whether a pre-'main' dynamic linker
2815 # works with the library.  It's too much trouble to actually call
2816 # tputs in the test program, due to portability hassles.  When
2817 # cross-compiling, assume the test program will run if it links.
2818 AC_DEFUN([tputs_link_source], [
2819   AC_LANG_SOURCE(
2820      [[extern void tputs (const char *, int, int (*)(int));
2821        int main (int argc, char **argv)
2822        {
2823           if (argc == 10000)
2824             tputs (argv[0], 0, 0);
2825           return 0;
2826        }]])
2827 ])
2828 # Maybe curses should be tried earlier?
2829 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2830 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2831   OLIBS=$LIBS
2832   if test -z "$tputs_library"; then
2833     LIBS_TERMCAP=
2834     msg='none required'
2835   else
2836     LIBS_TERMCAP=-l$tputs_library
2837     msg=$LIBS_TERMCAP
2838     LIBS="$LIBS_TERMCAP $LIBS"
2839   fi
2840   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2841     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2842   LIBS=$OLIBS
2843   if test "X$msg" != Xno; then
2844     break
2845   fi
2846 done
2847 AC_MSG_RESULT([$msg])
2848 if test "X$msg" = Xno; then
2849   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2850 The following libraries were tried (in order):
2851   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2852 Please try installing whichever of these libraries is most appropriate
2853 for your system, together with its header files.
2854 For example, a libncurses-dev(el) or similar package.])
2855 fi
2856
2857 ## Use termcap instead of terminfo?
2858 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2859 TERMINFO=yes
2860 ## FIXME?  In the cases below where we unconditionally set
2861 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2862 ## if that was found above to have tputs.
2863 ## Should we use the gnu* logic everywhere?
2864 case "$opsys" in
2865   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2866   ##  The ncurses library has been moved out of the System framework in
2867   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2868   ##  option to use it.
2869   darwin) LIBS_TERMCAP="-lncurses" ;;
2870
2871   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2872
2873   freebsd)
2874     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2875     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2876     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2877 [[#if __FreeBSD_version < 400000
2878 fail;
2879 #endif
2880 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2881
2882     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2883
2884     if test $emacs_cv_freebsd_terminfo = yes; then
2885       LIBS_TERMCAP="-lncurses"
2886     else
2887       TERMINFO=no
2888       LIBS_TERMCAP="-ltermcap"
2889     fi
2890     ;;
2891
2892   netbsd)
2893     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2894       TERMINFO=no
2895       LIBS_TERMCAP="-ltermcap"
2896     fi
2897     ;;
2898
2899   openbsd) LIBS_TERMCAP="-lncurses" ;;
2900
2901   ## hpux: Make sure we get select from libc rather than from libcurses
2902   ##  because libcurses on HPUX 10.10 has a broken version of select.
2903   ##  We used to use -lc -lcurses, but this may be cleaner.
2904   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2905   # set that way, now it uses the default).  Isn't this a contradiction?
2906   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2907
2908 esac
2909
2910 TERMCAP_OBJ=tparam.o
2911 if test $TERMINFO = yes; then
2912   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2913   TERMCAP_OBJ=terminfo.o
2914 fi
2915 AC_SUBST(LIBS_TERMCAP)
2916 AC_SUBST(TERMCAP_OBJ)
2917
2918
2919 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2920 # On Darwin, res_init appears not to be useful: see bug#562 and
2921 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
2922 resolv=no
2923
2924 if test $opsys != darwin; then
2925
2926   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2927 #include <arpa/nameser.h>
2928 #include <resolv.h>]],
2929     [[return res_init();]])],
2930     have_res_init=yes, have_res_init=no)
2931   if test "$have_res_init" = no; then
2932     OLIBS="$LIBS"
2933     LIBS="$LIBS -lresolv"
2934     AC_MSG_CHECKING(for res_init with -lresolv)
2935     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2936 #include <arpa/nameser.h>
2937 #include <resolv.h>]],
2938       [[return res_init();]])],
2939       have_res_init=yes, have_res_init=no)
2940     AC_MSG_RESULT($have_res_init)
2941     if test "$have_res_init" = yes ; then
2942       resolv=yes
2943     fi
2944     LIBS="$OLIBS"
2945   fi
2946
2947   if test "$have_res_init" = yes; then
2948     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2949   fi
2950 fi                              dnl !darwin
2951
2952 # Do we need the Hesiod library to provide the support routines?
2953 dnl FIXME?  Should we be skipping this on Darwin too?
2954 LIBHESIOD=
2955 if test "$with_hesiod" != no ; then
2956   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2957   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2958      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2959                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2960   if test "$resolv" = yes ; then
2961     RESOLVLIB=-lresolv
2962   else
2963     RESOLVLIB=
2964   fi
2965   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2966         hesiod=yes, :, $RESOLVLIB)])
2967
2968   if test x"$hesiod" = xyes; then
2969     AC_DEFINE(HAVE_LIBHESIOD, 1,
2970               [Define to 1 if you have the hesiod library (-lhesiod).])
2971     LIBHESIOD=-lhesiod
2972   fi
2973 fi
2974 AC_SUBST(LIBHESIOD)
2975
2976 # Do we need libresolv (due to res_init or Hesiod)?
2977 if test "$resolv" = yes && test $opsys != darwin; then
2978   AC_DEFINE(HAVE_LIBRESOLV, 1,
2979             [Define to 1 if you have the resolv library (-lresolv).])
2980   LIBRESOLV=-lresolv
2981 else
2982   LIBRESOLV=
2983 fi
2984 AC_SUBST(LIBRESOLV)
2985
2986 # These tell us which Kerberos-related libraries to use.
2987 COM_ERRLIB=
2988 CRYPTOLIB=
2989 KRB5LIB=
2990 DESLIB=
2991 KRB4LIB=
2992
2993 if test "${with_kerberos}" != no; then
2994   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2995   if test $have_com_err = yes; then
2996     COM_ERRLIB=-lcom_err
2997     LIBS="$COM_ERRLIB $LIBS"
2998     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2999   fi
3000   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3001   if test $have_crypto = yes; then
3002     CRYPTOLIB=-lcrypto
3003     LIBS="$CRYPTOLIB $LIBS"
3004     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
3005   fi
3006   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3007   if test $have_k5crypto = yes; then
3008     CRYPTOLIB=-lk5crypto
3009     LIBS="$CRYPTOLIB $LIBS"
3010     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
3011   fi
3012   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3013   if test $have_krb5=yes; then
3014     KRB5LIB=-lkrb5
3015     LIBS="$KRB5LIB $LIBS"
3016     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
3017   fi
3018   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3019   if test "${with_kerberos5}" = no; then
3020     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3021     if test $have_des425 = yes; then
3022       DESLIB=-ldes425
3023       LIBS="$DESLIB $LIBS"
3024       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
3025     else
3026       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3027       if test $have_des = yes; then
3028         DESLIB=-ldes
3029         LIBS="$DESLIB $LIBS"
3030         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
3031       fi
3032     fi
3033     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3034     if test $have_krb4 = yes; then
3035       KRB4LIB=-lkrb4
3036       LIBS="$KRB4LIB $LIBS"
3037       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
3038     else
3039       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3040       if test $have_krb = yes; then
3041         KRB4LIB=-lkrb
3042         LIBS="$KRB4LIB $LIBS"
3043         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
3044       fi
3045     fi
3046   fi
3047
3048   if test "${with_kerberos5}" != no; then
3049     AC_CHECK_HEADERS(krb5.h,
3050       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3051                         [#include <krb5.h>])])
3052   else
3053     AC_CHECK_HEADERS(des.h,,
3054                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3055                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3056     AC_CHECK_HEADERS(krb.h,,
3057                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3058                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3059   fi
3060   AC_CHECK_HEADERS(com_err.h)
3061 fi
3062
3063 AC_SUBST(COM_ERRLIB)
3064 AC_SUBST(CRYPTOLIB)
3065 AC_SUBST(KRB5LIB)
3066 AC_SUBST(DESLIB)
3067 AC_SUBST(KRB4LIB)
3068
3069 AC_CHECK_FUNCS_ONCE(tzset)
3070 AC_MSG_CHECKING(whether localtime caches TZ)
3071 AC_CACHE_VAL(emacs_cv_localtime_cache,
3072 [if test x$ac_cv_func_tzset = xyes; then
3073 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3074 char TZ_GMT0[] = "TZ=GMT0";
3075 char TZ_PST8[] = "TZ=PST8";
3076 main()
3077 {
3078   time_t now = time ((time_t *) 0);
3079   int hour_GMT0, hour_unset;
3080   if (putenv (TZ_GMT0) != 0)
3081     exit (1);
3082   hour_GMT0 = localtime (&now)->tm_hour;
3083   unsetenv("TZ");
3084   hour_unset = localtime (&now)->tm_hour;
3085   if (putenv (TZ_PST8) != 0)
3086     exit (1);
3087   if (localtime (&now)->tm_hour == hour_GMT0)
3088     exit (1);
3089   unsetenv("TZ");
3090   if (localtime (&now)->tm_hour != hour_unset)
3091     exit (1);
3092   exit (0);
3093 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3094 [# If we have tzset, assume the worst when cross-compiling.
3095 emacs_cv_localtime_cache=yes])
3096 else
3097         # If we lack tzset, report that localtime does not cache TZ,
3098         # since we can't invalidate the cache if we don't have tzset.
3099         emacs_cv_localtime_cache=no
3100 fi])dnl
3101 AC_MSG_RESULT($emacs_cv_localtime_cache)
3102 if test $emacs_cv_localtime_cache = yes; then
3103   AC_DEFINE(LOCALTIME_CACHE, 1,
3104             [Define to 1 if localtime caches TZ.])
3105 fi
3106
3107 ok_so_far=yes
3108 AC_CHECK_FUNC(socket, , ok_so_far=no)
3109 if test $ok_so_far = yes; then
3110   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3111 fi
3112 if test $ok_so_far = yes; then
3113   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3114 fi
3115 if test $ok_so_far = yes; then
3116 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3117   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3118             [Define to 1 if you have inet sockets.])
3119 fi
3120
3121 if test -f /usr/lpp/X11/bin/smt.exp; then
3122   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3123             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3124 fi
3125
3126 AC_MSG_CHECKING(whether system supports dynamic ptys)
3127 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3128   AC_MSG_RESULT(yes)
3129   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3130 else
3131   AC_MSG_RESULT(no)
3132 fi
3133
3134 AC_FUNC_FORK
3135
3136 AC_CHECK_FUNCS(snprintf)
3137
3138 dnl Adapted from Haible's version.
3139 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3140   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3141     [[char* cs = nl_langinfo(CODESET);]])],
3142     emacs_cv_langinfo_codeset=yes,
3143     emacs_cv_langinfo_codeset=no)
3144   ])
3145 if test $emacs_cv_langinfo_codeset = yes; then
3146   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3147     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3148 fi
3149
3150 AC_TYPE_MBSTATE_T
3151
3152 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3153   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3154                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3155 if test "$emacs_cv_c_restrict_arr" = yes; then
3156   AC_DEFINE(__restrict_arr, __restrict,
3157     [Define to compiler's equivalent of C99 restrict keyword in array
3158      declarations.  Define as empty for no equivalent.])
3159 fi
3160
3161 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3162 dnl how the tty code is related to POSIX and/or other versions of termios.
3163 dnl The following looks like a useful start.
3164 dnl
3165 dnl AC_SYS_POSIX_TERMIOS
3166 dnl if test $ac_cv_sys_posix_termios = yes; then
3167 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3168 dnl                                and macros for terminal control.])
3169 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3170 dnl fi
3171
3172 dnl Turned on June 1996 supposing nobody will mind it.
3173 AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3174   in the full name stands for the login id.])
3175
3176 dnl Every platform that uses configure (ie every non-MS platform)
3177 dnl supports this.  There is a create-lockfiles option you can
3178 dnl customize if you do not want the lock files to be written.
3179 dnl So it is not clear that this #define still needs to exist.
3180 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3181   so that Emacs can tell instantly when you try to modify a file that
3182   someone else has modified in his/her Emacs.])
3183
3184 AH_TEMPLATE(FLOAT_CHECK_DOMAIN, [Define if the float library doesn't
3185   handle errors by either setting errno, or signaling SIGFPE/SIGILL.])
3186
3187 AH_TEMPLATE(HAVE_INVERSE_HYPERBOLIC, [Define if you have the functions
3188   acosh, asinh, and atanh.])
3189
3190 dnl Everybody supports this, except MS.
3191 dnl Seems like the kind of thing we should be testing for, though.
3192 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3193 AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3194
3195 dnl Everybody supports this, except MS-DOS.
3196 dnl Seems like the kind of thing we should be testing for, though.
3197 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3198 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3199   4.2-compatible sockets.])
3200
3201 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3202
3203 AC_DEFINE(NULL_DEVICE, ["/dev/null"], [Name of the file to open to get
3204   a null file, or a data sink.])
3205
3206 AC_DEFINE(SEPCHAR, [':'], [Character that separates PATH elements.])
3207
3208 dnl Everybody supports this, except MS-DOS.
3209 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
3210
3211 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
3212
3213
3214 AC_DEFINE(DIRECTORY_SEP, ['/'],
3215   [Character that separates directories in a file name.])
3216
3217 dnl Only used on MS platforms.
3218 AH_TEMPLATE(DEVICE_SEP, [Character that separates a device in a file name.])
3219
3220 AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
3221   [Returns true if character is a device separator.])
3222
3223 AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
3224   [Returns true if character is a directory separator.])
3225
3226 dnl On MS, this also accepts IS_DEVICE_SEP.
3227 AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
3228   [Returns true if character is any form of separator.])
3229
3230
3231 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3232
3233 case $opsys in
3234   aix4-2)
3235     dnl Unfortunately without libXmu we cannot support EditRes.
3236     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
3237       AC_DEFINE(NO_EDITRES, 1)
3238     fi
3239     ;;
3240
3241   hpux*)
3242     dnl Assar Westerlund <assar@sics.se> says this is necessary for
3243     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
3244     AC_DEFINE(NO_EDITRES, 1)
3245     ;;
3246 esac
3247
3248
3249 case $opsys in
3250   darwin | gnu | hpux* | *bsd )
3251     AC_DEFINE(NO_TERMIO, 1, [Define if termio.h should not be included.])
3252     ;;
3253
3254   irix6-5 | sol2* | unixware )
3255     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
3256     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
3257     dnl need the constant to dimension an array.  So wire in the appropriate
3258     dnl value here.
3259     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
3260     ;;
3261 esac
3262
3263
3264 case $opsys in
3265   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3266   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3267   hpux* | irix6-5 | openbsd | sol2* | unixware )
3268     AC_DEFINE(BROKEN_SIGIO, 1, [Define if SIGIO should not be used.])
3269     ;;
3270
3271   aix4-2)
3272     dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
3273     AC_DEFINE(BROKEN_FIONREAD, 1, [Define if FIONREAD should not be used.])
3274     dnl As we define BROKEN_FIONREAD, SIGIO will be undefined in systty.h.
3275     dnl But, on AIX, SIGAIO, SIGPTY, and SIGPOLL are defined as SIGIO,
3276     dnl which causes compilation error at init_signals in sysdep.c.
3277     dnl So, we define these macros so that syssignal.h detects them
3278     dnl and undefine SIGAIO, SIGPTY and SIGPOLL.
3279     AC_DEFINE(BROKEN_SIGAIO, 1, [Define if SIGAIO should not be used.])
3280     AC_DEFINE(BROKEN_SIGPOLL,1, [Define if SIGPOLL should not be used.])
3281     AC_DEFINE(BROKEN_SIGPTY, 1, [Define if SIGPTY should not be used.])
3282
3283     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
3284     dnl the way this system works, libc functions that return malloced
3285     dnl memory use the libc malloc implementation. Calling xfree or
3286     dnl xrealloc on the results of such functions results in a crash.
3287     dnl
3288     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
3289     dnl but that does not currently work on this system.
3290     dnl
3291     dnl It is possible to completely override the malloc implementation on
3292     dnl AIX, but that involves putting the malloc functions in a shared
3293     dnl library and setting the MALLOCTYPE environment variable to point to
3294     dnl that shared library.
3295     dnl
3296     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
3297     dnl to avoid a crash just use the Emacs implementation for that function.
3298     dnl
3299     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
3300     dnl of this file, so that we do not check for get_current_dir_name
3301     dnl on AIX.  But that might be fragile if something else ends
3302     dnl up testing for get_current_dir_name as a dependency.
3303     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
3304       get_current_dir_name should not be used.])
3305     ;;
3306
3307   freebsd)
3308     dnl Circumvent a bug in FreeBSD.  In the following sequence of
3309     dnl writes/reads on a PTY, read(2) returns bogus data:
3310     dnl
3311     dnl write(2)  1022 bytes
3312     dnl write(2)   954 bytes, get EAGAIN
3313     dnl read(2)   1024 bytes in process_read_output
3314     dnl read(2)     11 bytes in process_read_output
3315     dnl
3316     dnl That is, read(2) returns more bytes than have ever been written
3317     dnl successfully.  The 1033 bytes read are the 1022 bytes written
3318     dnl successfully after processing (for example with CRs added if the
3319     dnl terminal is set up that way which it is here).  The same bytes will
3320     dnl be seen again in a later read(2), without the CRs.
3321     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
3322       work around an issue when reading from a PTY.])
3323     ;;
3324
3325   dnl Define the following so emacs symbols will not conflict with those
3326   dnl in the System framework.  Otherwise -prebind will not work.
3327   darwin)
3328     AC_DEFINE(NO_ABORT, 1, [Do not define abort in emacs.c.])
3329     ;;
3330 esac
3331
3332 case $opsys in
3333   gnu-* | sol2-10 )
3334     dnl FIXME Can't we test if this exists (eg /proc/$$)?
3335     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3336   ;;
3337 esac
3338
3339 case $opsys in
3340   darwin | freebsd | netbsd | openbsd )
3341     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
3342       close a pty to make it a controlling terminal (it is already a
3343       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
3344   ;;
3345 esac
3346
3347 dnl FIXME Surely we can test for this rather than hard-code it.
3348 case $opsys in
3349   netbsd | openbsd) sound_device="/dev/audio" ;;
3350   *) sound_device="/dev/dsp" ;;
3351 esac
3352
3353 dnl Used in sound.c
3354 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
3355   [Name of the default sound device.])
3356
3357
3358 dnl Emacs can read input using SIGIO and buffering characters itself,
3359 dnl or using CBREAK mode and making C-g cause SIGINT.
3360 dnl The choice is controlled by the variable interrupt_input.
3361 dnl
3362 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
3363 dnl
3364 dnl Emacs uses the presence or absence of the SIGIO and BROKEN_SIGIO macros
3365 dnl to indicate whether or not signal-driven I/O is possible.  It uses
3366 dnl INTERRUPT_INPUT to decide whether to use it by default.
3367 dnl
3368 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
3369 dnl CBREAK mode has two disadvantages
3370 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
3371 dnl I hear that in system V this problem does not exist.
3372 dnl 2) Control-G causes output to be discarded.
3373 dnl I do not know whether this can be fixed in system V.
3374 dnl
3375 dnl Another method of doing input is planned but not implemented.
3376 dnl It would have Emacs fork off a separate process
3377 dnl to read the input and send it to the true Emacs process
3378 dnl through a pipe.
3379 case $opsys in
3380   darwin | gnu-linux | gnu-kfreebsd )
3381     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
3382   ;;
3383 esac
3384
3385
3386 dnl If the system's imake configuration file defines `NeedWidePrototypes'
3387 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
3388 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
3389 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
3390 dnl taking float or double parameters.
3391 case $opsys in
3392   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
3393     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
3394       file defines `NeedWidePrototypes' as `NO'.])
3395   ;;
3396 esac
3397
3398
3399 dnl Used in process.c, this must be a loop, even if it only runs once.
3400 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
3401 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
3402 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
3403 dnl trying suffixes 0-16.
3404 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
3405   first PTY, if PTYs are supported.])
3406 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
3407 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
3408   end of a PTY, if non-standard.])
3409 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
3410   end of a PTY, if non-standard.])
3411
3412 case $opsys in
3413   aix4-2 )
3414     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
3415     dnl You allocate a pty by opening /dev/ptc to get the master side.
3416     dnl To get the name of the slave side, you just ttyname() the master side.
3417     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
3418     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
3419     ;;
3420
3421   cygwin )
3422     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3423     dnl multi-line AC_DEFINEs are hard. :(
3424     AC_DEFINE(PTY_OPEN, [ do { int dummy; SIGMASKTYPE mask; mask = sigblock (sigmask (SIGCHLD)); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; sigsetmask (mask); if (fd >= 0) emacs_close (dummy); } while (0)])
3425     AC_DEFINE(PTY_NAME_SPRINTF, [])
3426     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3427     ;;
3428
3429   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
3430   darwin )
3431     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3432     dnl Not used, because PTY_ITERATION is defined.
3433     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3434     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
3435     dnl But we don't have to block SIGCHLD because it is blocked in the
3436     dnl implementation of grantpt.
3437     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (0)])
3438     AC_DEFINE(PTY_NAME_SPRINTF, [])
3439     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3440     ;;
3441
3442   gnu | openbsd )
3443     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3444     ;;
3445
3446   gnu-linux | gnu-kfreebsd | freebsd | netbsd )
3447     dnl if HAVE_GRANTPT
3448     if test "x$ac_cv_func_grantpt" = xyes; then
3449       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
3450       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3451       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
3452       dnl to prevent sigchld_handler from intercepting the child's death.
3453       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname; sigblock (sigmask (SIGCHLD)); if (grantpt (fd) == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname(fd))) { sigunblock (sigmask (SIGCHLD)); close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); sigunblock (sigmask (SIGCHLD)); }])
3454       dnl if HAVE_POSIX_OPENPT
3455       if test "x$ac_cv_func_posix_openpt" = xyes; then
3456         AC_DEFINE(PTY_OPEN, [fd = posix_openpt (O_RDWR | O_NOCTTY)])
3457         AC_DEFINE(PTY_NAME_SPRINTF, [])
3458       dnl if HAVE_GETPT
3459       elif test "x$ac_cv_func_getpt" = xyes; then
3460         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
3461         AC_DEFINE(PTY_NAME_SPRINTF, [])
3462       else
3463         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3464       fi
3465     else
3466       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3467     fi
3468     ;;
3469
3470   hpux*)
3471     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3472     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
3473     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
3474     ;;
3475
3476   irix6-5 )
3477     dnl It looks like this cannot be right, because it is not a loop.
3478     dnl However, process.c actually does this:
3479     dnl # ifndef __sgi
3480     dnl   continue;
3481     dnl # else
3482     dnl   return -1;
3483     dnl # endif
3484     dnl which presumably makes it OK, since irix == sgi (?).
3485     dnl FIXME it seems like this special treatment is unnecessary?
3486     dnl Why can't irix use a single-trip loop like eg cygwin?
3487     AC_DEFINE(PTY_ITERATION, [])
3488     dnl Not used, because PTY_ITERATION is defined.
3489     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
3490     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
3491     dnl No need to get the pty name at all.
3492     AC_DEFINE(PTY_NAME_SPRINTF, [])
3493     dnl No need to use sprintf to get the tty name--we get that from _getpty.
3494     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3495     ;;
3496
3497   sol2* )
3498     dnl Uses sigblock/sigunblock rather than sighold/sigrelse,
3499     dnl which appear to be BSD4.1 specific.  It may also be appropriate
3500     dnl for SVR4.x (x<2) but I'm not sure.   fnf@cygnus.com
3501     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
3502     dnl from intercepting that death.  If any child but grantpt's should die
3503     dnl within, it should be caught after sigrelse(2).
3504     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; sigblock (sigmask (SIGCLD)); if (grantpt (fd) == -1) { emacs_close (fd); return -1; } sigunblock (sigmask (SIGCLD)); if (unlockpt (fd) == -1) { emacs_close (fd); return -1; } if (!(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3505     ;;
3506
3507   unixware )
3508     dnl Comments are as per sol2*.
3509     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; sigblock(sigmask(SIGCLD)); if (grantpt(fd) == -1) fatal("could not grant slave pty"); sigunblock(sigmask(SIGCLD)); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3510     ;;
3511 esac
3512
3513
3514 case $opsys in
3515   sol2* | unixware )
3516     dnl This change means that we don't loop through allocate_pty too
3517     dnl many times in the (rare) event of a failure.
3518     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
3519     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3520     dnl Push various streams modules onto a PTY channel.  Used in process.c.
3521     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
3522     ;;
3523 esac
3524
3525
3526 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
3527 "typing" a signal character on the pty.])
3528
3529 case $opsys in
3530   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
3531   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
3532   aix4-2 | cygwin | gnu | irix6-5 | freebsd | netbsd | openbsd )
3533     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3534     ;;
3535
3536   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
3537   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
3538   gnu-linux | gnu-kfreebsd )
3539
3540     AC_MSG_CHECKING([for signals via characters])
3541     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3542 #include <linux/version.h>
3543 #if LINUX_VERSION_CODE < 0x20400
3544 # error "Linux version too old"
3545 #endif
3546       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
3547
3548     AC_MSG_RESULT([$emacs_signals_via_chars])
3549     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3550     ;;
3551 esac
3552
3553
3554 dnl Used in dispnew.c
3555 AH_TEMPLATE(PENDING_OUTPUT_COUNT, [Number of chars of output in the
3556   buffer of a stdio stream.])
3557
3558 AC_MSG_CHECKING([whether we are using the GNU C library])
3559 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3560 #include <features.h>
3561 #ifndef __GNU_LIBRARY__
3562 # error "this is not the GNU C library"
3563 #endif
3564   ]], [[]])], emacs_glibc=yes, emacs_glibc=no)
3565 AC_MSG_RESULT([$emacs_glibc])
3566
3567 if test $emacs_glibc = yes; then
3568
3569   emacs_pending_output=unknown
3570
3571   case $opsys in
3572     gnu | gnu-linux | gnu-kfreebsd )
3573       AC_MSG_CHECKING([for style of pending output formalism])
3574       dnl In autoconf 2.67 and later, we could use a single test
3575       dnl since the preprocessed output is accessible in "conftest.i".
3576       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3577 #include <stdio.h>
3578 #if !defined (_IO_STDIO_H) && !defined (_STDIO_USES_IOSTREAM)
3579 # error "stdio definitions not found"
3580 #endif
3581         ]], [[]])], emacs_pending_output=new, [])
3582
3583       if test $emacs_pending_output = unknown; then
3584         case $opsys in
3585           gnu-linux | gnu-kfreebsd)
3586             AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3587 #include <stdio.h>
3588 #ifndef __UCLIBC__
3589 # error "not using uclibc"
3590 #endif
3591             ]], [[]])], emacs_pending_output=uclibc, emacs_pending_output=old)
3592             ;;
3593         esac
3594       fi
3595
3596       AC_MSG_RESULT([$emacs_pending_output])
3597
3598       case $emacs_pending_output in
3599         new)
3600           dnl New C libio names.
3601           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3602             [((FILE)->_IO_write_ptr - (FILE)->_IO_write_base)])
3603           ;;
3604         uclibc)
3605           dnl Using the uClibc library.
3606           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3607             [((FILE)->__bufpos - (FILE)->__bufstart)])
3608           ;;
3609         old)
3610           dnl Old C++ iostream names.
3611           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3612             [((FILE)->_pptr - (FILE)->_pbase)])
3613           ;;
3614       esac
3615     ;;
3616   esac                          dnl opsys
3617
3618   if test $emacs_pending_output = unknown; then
3619     AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->__bufp - (FILE)->__buffer)])
3620   fi
3621
3622 else                            dnl !emacs_glibc
3623
3624   case $opsys in
3625     cygwin | darwin | freebsd | netbsd | openbsd )
3626       AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->_p - (FILE)->_bf._base)])
3627       ;;
3628
3629     unixware)
3630       AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->__ptr - (FILE)->__base)])
3631       ;;
3632
3633     *)
3634       dnl HAVE_STDIO_EXT_H && HAVE___FPENDING
3635       if test x$ac_cv_header_stdio_ext_h = xyes && \
3636         test x$ac_cv_func___fpending = xyes; then
3637         AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [__fpending (FILE)])
3638         AC_DEFINE(DISPNEW_NEEDS_STDIO_EXT, 1,
3639           [Define if dispnew.c should include stdio_ext.h.])
3640       else
3641         AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->_ptr - (FILE)->_base)])
3642       fi
3643       ;;
3644   esac
3645 fi                              dnl emacs_glibc
3646
3647
3648 dnl Used in vm-limit.c
3649 AH_TEMPLATE(DATA_START, [Address of the start of the data segment.])
3650 dnl Used in lisp.h, emacs.c, mem-limits.h
3651 dnl NEWS.18 describes this as "a number which contains
3652 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
3653 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
3654 stored in a Lisp_Object.])
3655 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
3656
3657 case $opsys in
3658   gnu)
3659     dnl libc defines data_start.
3660     AC_DEFINE(DATA_START, [({ extern int data_start; (char *) &data_start; })])
3661     ;;
3662
3663   hpux*)
3664     dnl The data segment on this machine always starts at address 0x40000000.
3665     AC_DEFINE(DATA_START, [0x40000000])
3666     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
3667     ;;
3668   irix6-5)
3669     AC_DEFINE(DATA_START, [0x10000000])
3670     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
3671     ;;
3672 esac
3673
3674
3675 AH_TEMPLATE(ULIMIT_BREAK_VALUE, [Undocumented.])
3676 AH_TEMPLATE(TAB3, [Undocumented.])
3677
3678 case $opsys in
3679   darwin) AC_DEFINE(TAB3, OXTABS) ;;
3680
3681   gnu | freebsd | netbsd | openbsd )
3682     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
3683     AC_DEFINE(TAB3, OXTABS)
3684     ;;
3685
3686   gnu-linux | gnu-kfreebsd )
3687     dnl libc-linux/sysdeps/linux/i386/ulimit.c says that due to shared
3688     dnl library, we cannot get the maximum address for brk.
3689     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3690 #ifndef __i386__
3691 # error "not i386"
3692 #endif
3693       ]], [[]])], AC_DEFINE(ULIMIT_BREAK_VALUE, [(32*1024*1024)]), [])
3694
3695     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3696 #ifndef __ia64__
3697 # error "not ia64"
3698 #endif
3699       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
3700         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (0)],
3701         [Mark a secondary stack, like the register stack on the ia64.]), [])
3702     ;;
3703
3704   hpux*)
3705     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
3706       run_time_remap; for HPUX.])
3707     ;;
3708
3709   irix6-5)
3710     dnl Ulimit(UL_GMEMLIM) is busted...
3711     AC_DEFINE(ULIMIT_BREAK_VALUE, [0x14000000])
3712     ;;
3713 esac
3714
3715
3716 dnl These won't be used automatically yet.  We also need to know, at least,
3717 dnl that the stack is continuous.
3718 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
3719   registers relevant for conservative garbage collection in the jmp_buf.])
3720
3721 AH_TEMPLATE(GC_MARK_STACK, [Define to GC_USE_GCPROS_AS_BEFORE if
3722   conservative garbage collection is not known to work.])
3723
3724
3725 case $opsys in
3726   aix4-2 | hpux* | unixware)
3727     dnl Conservative garbage collection has not been tested, so for now
3728     dnl play it safe and stick with the old-fashioned way of marking.
3729     AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE])
3730     ;;
3731
3732   dnl Not all the architectures are tested, but there are Debian packages
3733   dnl for SCM and/or Guile on them, so the technique must work.  See also
3734   dnl comments in alloc.c concerning setjmp and gcc.
3735   dnl Fixme: it's probably safe to just use the GCC conditional below.
3736   gnu-linux | gnu-kfreebsd )
3737     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3738 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
3739   || defined __alpha__ || defined __mips__ || defined __s390__ \
3740   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
3741   || defined __ia64__ || defined __sh__
3742 /* ok */
3743 #else
3744 # error "setjmp not known to work on this arch"
3745 #endif
3746     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1),
3747       AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE]) )
3748     ;;
3749 esac
3750
3751
3752 if test x$GCC = xyes; then
3753    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
3754    AC_DEFINE(GC_SETJMP_WORKS, 1)
3755 else
3756   case $opsys in
3757     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
3758     freebsd | netbsd | openbsd | irix6-5 | sol2* )
3759       AC_DEFINE(GC_SETJMP_WORKS, 1)
3760       ;;
3761   esac
3762 fi                              dnl GCC?
3763
3764
3765 case $opsys in
3766   sol2* | unixware )
3767     dnl setjmp and longjmp can safely replace _setjmp and _longjmp,
3768     dnl but they will run more slowly.
3769     AC_DEFINE(_setjmp, setjmp, [Some platforms redefine this.])
3770     AC_DEFINE(_longjmp, longjmp, [Some platforms redefine this.])
3771     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
3772     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
3773     dnl and this is all we need.
3774     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
3775     ;;
3776 esac
3777
3778
3779 case $opsys in
3780   hpux* | sol2* )
3781     dnl Used in xfaces.c.
3782     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
3783       some systems, where it requires time.h.])
3784     ;;
3785
3786   netbsd | openbsd )
3787     dnl Greg A. Woods <woods@weird.com> says we must include signal.h
3788     dnl before syssignal.h is included, to work around interface conflicts
3789     dnl that are handled with CPP __RENAME() macro in signal.h.
3790     AC_DEFINE(SIGNAL_H_AHB, 1, [Define if AH_BOTTOM should include signal.h.])
3791     ;;
3792 esac
3793
3794
3795 dnl Define symbols to identify the version of Unix this is.
3796 dnl Define all the symbols that apply correctly.
3797 AH_TEMPLATE(BSD4_2, [Define if the system is compatible with BSD 4.2.])
3798 AH_TEMPLATE(BSD_SYSTEM, [Define if the system is compatible with BSD 4.2.])
3799 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
3800 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
3801 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
3802 AH_TEMPLATE(USG5, [Define if the system is compatible with System V.])
3803 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
3804
3805 case $opsys in
3806   aix4-2)
3807     AC_DEFINE(USG, [])
3808     AC_DEFINE(USG5, [])
3809     dnl This symbol should be defined on AIX Version 3  ???????
3810     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3811 #ifndef _AIX
3812 # error "_AIX not defined"
3813 #endif
3814     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
3815     ;;
3816
3817   cygwin)
3818     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
3819     ;;
3820
3821   darwin)
3822     dnl BSD4_3 and BSD4_4 are already defined in sys/param.h.
3823     AC_DEFINE(BSD4_2, [])
3824     AC_DEFINE(BSD_SYSTEM, [])
3825     dnl More specific than the above two.  We cannot use __APPLE__ as this
3826     dnl may not be defined on non-OSX Darwin, and we cannot define DARWIN
3827     dnl here because Panther and lower CoreFoundation.h uses DARWIN to
3828     dnl distinguish OS X from pure Darwin.
3829     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
3830     ;;
3831
3832   freebsd)
3833     AC_DEFINE(BSD4_2, [])
3834     dnl Hack to avoid calling AC_PREPROC_IFELSE multiple times.
3835     dnl Would not be needed with autoconf >= 2.67, where the
3836     dnl preprocessed output is accessible in "conftest.i".
3837     AC_DEFINE(BSD_SYSTEM_AHB, 1, [Define if AH_BOTTOM should change BSD_SYSTEM.])
3838     ;;
3839
3840   gnu | netbsd | openbsd )
3841     AC_DEFINE(BSD4_2, [])
3842     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3843 #ifndef BSD_SYSTEM
3844 # error "BSD_SYSTEM not defined"
3845 #endif
3846     ]], [[]])], [], AC_DEFINE(BSD_SYSTEM, 43) )
3847     ;;
3848
3849   gnu-linux | gnu-kfreebsd )
3850     AC_DEFINE(USG, [])
3851     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
3852     ;;
3853
3854   hpux*)
3855     AC_DEFINE(USG, [])
3856     AC_DEFINE(USG5, [])
3857     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
3858     ;;
3859
3860   irix6-5)
3861     AC_DEFINE(USG, [])
3862     AC_DEFINE(USG5, [])
3863     AC_DEFINE(USG5_4, [])
3864     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
3865     ;;
3866
3867   sol2*)
3868     AC_DEFINE(USG, [])
3869     AC_DEFINE(USG5, [])
3870     AC_DEFINE(USG5_4, [])
3871     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
3872     ;;
3873
3874   unixware)
3875     AC_DEFINE(USG, [])
3876     AC_DEFINE(USG5, [])
3877     AC_DEFINE(USG5_4, [])
3878     ;;
3879 esac
3880
3881
3882 case $opsys in
3883   dnl Emacs supplies its own malloc, but glib (part of Gtk+) calls
3884   dnl memalign and on Cygwin, that becomes the Cygwin-supplied memalign.
3885   dnl As malloc is not the Cygwin malloc, the Cygwin memalign always
3886   dnl returns ENOSYS.  A workaround is to set G_SLICE=always-malloc. */
3887   cygwin)
3888     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
3889       G_SLICE environment variable to "always-malloc" at startup, if
3890       using GTK.])
3891     ;;
3892
3893   hpux11)
3894     dnl See comments in sysdep.c:sys_signal.
3895     dnl SA_RESTART resets the timeout of `select' on hpux11.
3896     dnl Defining BROKEN_SA_RESTART is not the same as undef'ing SA_RESTART.
3897     AC_DEFINE(BROKEN_SA_RESTART, 1, [Define if SA_RESTART should only
3898       be used in batch mode.])
3899     dnl It works to open the pty's tty in the parent (Emacs), then
3900     dnl close and reopen it in the child.
3901     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
3902       works to open a pty's tty in the parent process, then close and
3903       reopen it in the child.])
3904     ;;
3905
3906   irix6-5)
3907     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
3908       use VSUSP instead of VSWTCH.])
3909     AC_DEFINE(SETPGRP_RELEASES_CTTY, 1, [Define if process.c:child_setup
3910       should not call setpgrp.])
3911     ;;
3912
3913   sol2-10)
3914     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
3915       on Solaris.])
3916     ;;
3917 esac
3918
3919 # Set up the CFLAGS for real compilation, so we can substitute it.
3920 CFLAGS="$REAL_CFLAGS"
3921 CPPFLAGS="$REAL_CPPFLAGS"
3922
3923 ## Hack to detect a buggy GCC version.
3924 if test "x$GCC" = xyes \
3925    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3926    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3927    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3928    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3929 fi
3930
3931 version=$PACKAGE_VERSION
3932
3933 ### Specify what sort of things we'll be editing into Makefile and config.h.
3934 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3935 AC_SUBST(version)
3936 AC_SUBST(configuration)
3937 ## Unused?
3938 AC_SUBST(canonical)
3939 AC_SUBST(srcdir)
3940 AC_SUBST(prefix)
3941 AC_SUBST(exec_prefix)
3942 AC_SUBST(bindir)
3943 AC_SUBST(datadir)
3944 AC_SUBST(sharedstatedir)
3945 AC_SUBST(libexecdir)
3946 AC_SUBST(mandir)
3947 AC_SUBST(infodir)
3948 AC_SUBST(lispdir)
3949 AC_SUBST(leimdir)
3950 AC_SUBST(standardlisppath)
3951 AC_SUBST(locallisppath)
3952 AC_SUBST(lisppath)
3953 AC_SUBST(x_default_search_path)
3954 AC_SUBST(etcdir)
3955 AC_SUBST(archlibdir)
3956 AC_SUBST(docdir)
3957 AC_SUBST(bitmapdir)
3958 AC_SUBST(gamedir)
3959 AC_SUBST(gameuser)
3960 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3961 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3962 ## end of LIBX_BASE, but nothing ever set it.
3963 AC_SUBST(LD_SWITCH_X_SITE)
3964 AC_SUBST(C_SWITCH_X_SITE)
3965 AC_SUBST(GNUSTEP_CFLAGS)
3966 AC_SUBST(CFLAGS)
3967 ## Used in lwlib/Makefile.in.
3968 AC_SUBST(X_TOOLKIT_TYPE)
3969 AC_SUBST(ns_appdir)
3970 AC_SUBST(ns_appbindir)
3971 AC_SUBST(ns_appresdir)
3972 AC_SUBST(ns_appsrc)
3973 AC_SUBST(GNU_OBJC_CFLAGS)
3974 AC_SUBST(OTHER_FILES)
3975
3976 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3977                    [Define to the canonical Emacs configuration name.])
3978 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3979                    [Define to the options passed to configure.])
3980 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
3981   define this to include extra configuration information.])
3982
3983 XMENU_OBJ=
3984 XOBJ=
3985 FONT_OBJ=
3986 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3987   AC_DEFINE(HAVE_X_WINDOWS, 1,
3988             [Define to 1 if you want to use the X window system.])
3989   XMENU_OBJ=xmenu.o
3990   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3991   FONT_OBJ=xfont.o
3992   if test "$HAVE_XFT" = "yes"; then
3993     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3994   elif test "$HAVE_FREETYPE" = "yes"; then
3995     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3996   fi
3997   AC_SUBST(FONT_OBJ)
3998 fi
3999 AC_SUBST(XMENU_OBJ)
4000 AC_SUBST(XOBJ)
4001 AC_SUBST(FONT_OBJ)
4002
4003 WIDGET_OBJ=
4004 MOTIF_LIBW=
4005 if test "${USE_X_TOOLKIT}" != "none" ; then
4006   WIDGET_OBJ=widget.o
4007   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4008   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4009     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4010   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4011     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4012     MOTIF_LIBW=-lXm
4013     case "$opsys" in
4014       gnu-linux)
4015         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4016         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4017         ;;
4018
4019       unixware)
4020         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4021         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4022         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4023         ;;
4024
4025       aix4-2)
4026         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4027         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4028         ;;
4029     esac
4030     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4031   fi
4032 fi
4033 AC_SUBST(WIDGET_OBJ)
4034
4035 TOOLKIT_LIBW=
4036 case "$USE_X_TOOLKIT" in
4037   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4038   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4039   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4040 esac
4041 AC_SUBST(TOOLKIT_LIBW)
4042
4043 if test "$USE_X_TOOLKIT" = "none"; then
4044   LIBXT_OTHER="\$(LIBXSM)"
4045   OLDXMENU_TARGET="really-oldXMenu"
4046 else
4047   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4048   OLDXMENU_TARGET="really-lwlib"
4049 fi
4050 AC_SUBST(LIBXT_OTHER)
4051
4052 ## The X Menu stuff is present in the X10 distribution, but missing
4053 ## from X11.  If we have X10, just use the installed library;
4054 ## otherwise, use our own copy.
4055 if test "${HAVE_X11}" = "yes" ; then
4056   AC_DEFINE(HAVE_X11, 1,
4057             [Define to 1 if you want to use version 11 of X windows.
4058              Otherwise, Emacs expects to use version 10.])
4059
4060   if test "$USE_X_TOOLKIT" = "none"; then
4061     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
4062   else
4063     OLDXMENU="\${lwlibdir}/liblw.a"
4064   fi
4065   LIBXMENU="\$(OLDXMENU)"
4066   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4067   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
4068 else
4069   ## For a syntactically valid Makefile; not actually used for anything.
4070   ## See comments in src/Makefile.in.
4071   OLDXMENU=nothing
4072   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
4073   if test "${HAVE_X_WINDOWS}" = "yes"; then
4074     LIBXMENU="-lXMenu"
4075   else
4076     LIBXMENU=
4077   fi
4078   LIBX_OTHER=
4079   OLDXMENU_DEPS=
4080 fi
4081
4082 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
4083   OLDXMENU_TARGET=
4084   OLDXMENU=nothing
4085   LIBXMENU=
4086   OLDXMENU_DEPS=
4087 fi
4088
4089 AC_SUBST(OLDXMENU_TARGET)
4090 AC_SUBST(OLDXMENU)
4091 AC_SUBST(LIBXMENU)
4092 AC_SUBST(LIBX_OTHER)
4093 AC_SUBST(OLDXMENU_DEPS)
4094
4095 if test "${HAVE_MENUS}" = "yes" ; then
4096   AC_DEFINE(HAVE_MENUS, 1,
4097             [Define to 1 if you have mouse menus.
4098              (This is automatic if you use X, but the option to specify it remains.)
4099              It is also defined with other window systems that support xmenu.c.])
4100 fi
4101
4102 if test "${GNU_MALLOC}" = "yes" ; then
4103   AC_DEFINE(GNU_MALLOC, 1,
4104             [Define to 1 if you want to use the GNU memory allocator.])
4105 fi
4106
4107 RALLOC_OBJ=
4108 if test "${REL_ALLOC}" = "yes" ; then
4109   AC_DEFINE(REL_ALLOC, 1,
4110             [Define REL_ALLOC if you want to use the relocating allocator for
4111              buffer space.])
4112
4113   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4114 fi
4115 AC_SUBST(RALLOC_OBJ)
4116
4117 if test "$opsys" = "cygwin"; then
4118   CYGWIN_OBJ="sheap.o"
4119   ## Cygwin differs because of its unexec().
4120   PRE_ALLOC_OBJ=
4121   POST_ALLOC_OBJ=lastfile.o
4122 else
4123   CYGWIN_OBJ=
4124   PRE_ALLOC_OBJ=lastfile.o
4125   POST_ALLOC_OBJ=
4126 fi
4127 AC_SUBST(CYGWIN_OBJ)
4128 AC_SUBST(PRE_ALLOC_OBJ)
4129 AC_SUBST(POST_ALLOC_OBJ)
4130
4131 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4132 # it temporarily reverts them to their pre-pkg-config values,
4133 # because gnulib needs to work with both src (which uses the
4134 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4135 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4136 # and it therefore needs to run in an environment where LIBS does not
4137 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4138 # for some package unrelated to lib-src.
4139 SAVE_CFLAGS=$CFLAGS
4140 SAVE_LIBS=$LIBS
4141 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4142 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4143 gl_ASSERT_NO_GNULIB_POSIXCHECK
4144 gl_ASSERT_NO_GNULIB_TESTS
4145 gl_INIT
4146 CFLAGS=$SAVE_CFLAGS
4147 LIBS=$SAVE_LIBS
4148
4149 case "$opsys" in
4150   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4151
4152   darwin)
4153    ## The -headerpad option tells ld (see man page) to leave room at the
4154    ## end of the header for adding load commands.  Needed for dumping.
4155    ## 0x690 is the total size of 30 segment load commands (at 56
4156    ## each); under Cocoa 31 commands are required.
4157    if test "$HAVE_NS" = "yes"; then
4158      libs_nsgui="-framework AppKit"
4159      headerpad_extra=6C8
4160    else
4161      libs_nsgui=
4162      headerpad_extra=690
4163    fi
4164    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4165
4166    ## This is here because src/Makefile.in did some extra fiddling around
4167    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
4168    ##   #ifndef LD_SWITCH_SYSTEM
4169    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
4170    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
4171    ## not using gcc, darwin.
4172    ## Because this was done in src/Makefile.in, the resulting part of
4173    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
4174    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
4175    ## rather than LD_SWITCH_SYSTEM.
4176    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4177      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4178    ;;
4179
4180   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4181   ## find X at run-time.
4182   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4183   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4184   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4185   ## had different values in configure (in ac_link) and src/Makefile.in.
4186   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4187   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4188
4189   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4190 esac
4191
4192 if test "$NS_IMPL_GNUSTEP" = "yes"; then
4193   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
4194 fi
4195
4196 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4197
4198
4199 LD_FIRSTFLAG=
4200 ORDINARY_LINK=
4201 case "$opsys" in
4202   ## gnu: GNU needs its own crt0.
4203   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
4204
4205   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
4206   ## library search parth, i.e. it won't search /usr/lib for libc and
4207   ## friends.  Using -nostartfiles instead avoids this problem, and
4208   ## will also work on earlier NetBSD releases.
4209   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
4210
4211   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
4212   ##   MkLinux/LinuxPPC needs this.
4213   ## s390x-* only supports opsys = gnu-linux so it can be added here.
4214   gnu-*)
4215     case "$canonical" in
4216       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
4217     esac
4218     ;;
4219 esac
4220
4221
4222 if test "x$ORDINARY_LINK" = "xyes"; then
4223
4224   LD_FIRSTFLAG=""
4225   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
4226
4227 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
4228 ## freebsd, gnu-* not on powerpc*|s390x*.
4229 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
4230
4231   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
4232   ## places that are difficult to figure out at make time.  Fortunately,
4233   ## these same versions allow you to pass arbitrary flags on to the
4234   ## linker, so there is no reason not to use it as a linker.
4235   ##
4236   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
4237   ## searching for libraries in its internal directories, so we have to
4238   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
4239   LD_FIRSTFLAG="-nostdlib"
4240 fi
4241
4242 ## FIXME? What setting of EDIT_LDFLAGS should this have?
4243 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
4244
4245 AC_SUBST(LD_FIRSTFLAG)
4246
4247
4248 ## FIXME? The logic here is not precisely the same as that above.
4249 ## There is no check here for a pre-defined LD_FIRSTFLAG.
4250 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
4251 LIB_GCC=
4252 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
4253
4254   case "$opsys" in
4255     freebsd|netbsd|openbsd) LIB_GCC= ;;
4256
4257     gnu-*)
4258       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
4259       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
4260       case $host_cpu in
4261       arm*)
4262         LIB_GCC="-lgcc_s"
4263         ;;
4264       *)
4265         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
4266         ## immediately undefine it again and redefine it to empty.
4267         ## Was the C_SWITCH_X_SITE part really necessary?
4268 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
4269         LIB_GCC=
4270         ;;
4271       esac
4272       ;;
4273
4274     ## Ask GCC where to find libgcc.a.
4275     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
4276   esac
4277 fi                              dnl if $GCC
4278 AC_SUBST(LIB_GCC)
4279
4280
4281 ## If we're using X11/GNUstep, define some consequences.
4282 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
4283   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4284   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
4285 fi
4286
4287
4288 AH_TOP([/* GNU Emacs site configuration template file.
4289
4290 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
4291   Free Software Foundation, Inc.
4292
4293 This file is part of GNU Emacs.
4294
4295 GNU Emacs is free software: you can redistribute it and/or modify
4296 it under the terms of the GNU General Public License as published by
4297 the Free Software Foundation, either version 3 of the License, or
4298 (at your option) any later version.
4299
4300 GNU Emacs is distributed in the hope that it will be useful,
4301 but WITHOUT ANY WARRANTY; without even the implied warranty of
4302 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4303 GNU General Public License for more details.
4304
4305 You should have received a copy of the GNU General Public License
4306 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4307
4308
4309 /* No code in Emacs #includes config.h twice, but some bits of code
4310    intended to work with other packages as well (like gmalloc.c)
4311    think they can include it as many times as they like.  */
4312 #ifndef EMACS_CONFIG_H
4313 #define EMACS_CONFIG_H
4314 ])dnl
4315
4316 AH_BOTTOM([#include <conf_post.h>
4317
4318 #endif /* EMACS_CONFIG_H */
4319
4320 /*
4321 Local Variables:
4322 mode: c
4323 End:
4324 */
4325 ])dnl
4326
4327 #### Report on what we decided to do.
4328 #### Report GTK as a toolkit, even if it doesn't use Xt.
4329 #### It makes printing result more understandable as using GTK sets
4330 #### toolkit_scroll_bars to yes by default.
4331 if test "${HAVE_GTK}" = "yes"; then
4332   if test "${with_gtk3}" = "yes"; then
4333     USE_X_TOOLKIT=GTK3
4334   else
4335     USE_X_TOOLKIT=GTK
4336   fi
4337 fi
4338
4339 echo "
4340 Configured for \`${canonical}'.
4341
4342   Where should the build process find the source code?    ${srcdir}
4343   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4344   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4345   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4346   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4347   What window system should Emacs use?                    ${window_system}
4348   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4349
4350 if test -n "${x_includes}"; then
4351 echo "  Where do we find X Windows header files?                ${x_includes}"
4352 else
4353 echo "  Where do we find X Windows header files?                Standard dirs"
4354 fi
4355 if test -n "${x_libraries}"; then
4356 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4357 else
4358 echo "  Where do we find X Windows libraries?                   Standard dirs"
4359 fi
4360
4361 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4362 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4363 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4364 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4365 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
4366 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
4367 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
4368 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
4369
4370 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
4371 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
4372 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
4373 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
4374 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
4375 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
4376 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
4377
4378 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
4379 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
4380 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
4381 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
4382
4383 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
4384 echo
4385
4386 if test -n "${EMACSDATA}"; then
4387    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
4388 fi
4389 if test -n "${EMACSDOC}"; then
4390    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
4391 fi
4392
4393 echo
4394
4395 if test "$HAVE_NS" = "yes"; then
4396    echo
4397    echo "You must run \"${MAKE-make} install\" in order to test the built application.
4398 The installed application will go to nextstep/Emacs.app and can be
4399 run or moved from there."
4400    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
4401       echo "The application will be fully self-contained."
4402     else
4403       echo "The lisp resources for the application will be installed under ${prefix}.
4404 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
4405 to run if these resources are not installed."
4406    fi
4407    echo
4408 fi
4409
4410 if test "${opsys}" = "cygwin"; then
4411   case `uname -r` in
4412     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
4413            echo
4414            ;;
4415   esac
4416 fi
4417
4418 # Remove any trailing slashes in these variables.
4419 [test "${prefix}" != NONE &&
4420   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
4421 test "${exec_prefix}" != NONE &&
4422   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
4423
4424 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
4425 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
4426 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
4427 dnl (else you get "no `Makefile.am' found for any configure output").
4428 dnl This will work, but you get a config.status that is not quite right
4429 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
4430 dnl That doesn't have any obvious consequences for Emacs, but on the whole
4431 dnl it seems better to just live with the duplication.
4432 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
4433
4434 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
4435        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
4436        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
4437        leim/Makefile])
4438
4439 dnl test/ is not present in release tarfiles.
4440 opt_makefile=test/automated/Makefile
4441
4442 if test -f $srcdir/${opt_makefile}.in; then
4443   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4444   dnl Again, it's best not to use a variable.  Though you can add
4445   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
4446   AC_CONFIG_FILES([test/automated/Makefile])
4447 fi
4448
4449
4450 dnl admin/ may or may not be present.
4451 opt_makefile=admin/unidata/Makefile
4452
4453 if test -f $srcdir/${opt_makefile}.in; then
4454   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4455   AC_CONFIG_FILES([admin/unidata/Makefile])
4456 fi
4457
4458
4459 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
4460
4461 AC_SUBST(SUBDIR_MAKEFILES_IN)
4462
4463 dnl Make the necessary directories, if they don't exist.
4464 AC_CONFIG_COMMANDS([mkdirs], [
4465 for dir in etc lisp ; do
4466   test -d ${dir} || mkdir ${dir}
4467 done
4468 ])
4469
4470 dnl You might wonder (I did) why epaths.h is generated by running make,
4471 dnl rather than just letting configure generate it from epaths.in.
4472 dnl One reason is that the various paths are not fully expanded (see above);
4473 dnl eg gamedir=${prefix}/var/games/emacs.
4474 dnl Secondly, the GNU Coding standards require that one should be able
4475 dnl to run `make prefix=/some/where/else' and override the values set
4476 dnl by configure.  This also explains the `move-if-change' test and
4477 dnl the use of force in the `epaths-force' rule in Makefile.in.
4478 AC_CONFIG_COMMANDS([epaths], [
4479 echo creating src/epaths.h
4480 ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
4481 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
4482
4483 AC_CONFIG_COMMANDS([gdbinit], [
4484 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
4485   echo creating src/.gdbinit
4486   echo source $srcdir/src/.gdbinit > src/.gdbinit
4487 fi
4488 ])
4489
4490 AC_OUTPUT