code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 leimdir='${datadir}/emacs/${version}/leim'
  41 standardlisppath='${lispdir}:${leimdir}'
  42 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  43 '${datadir}/emacs/site-lisp'
  44 lisppath='${locallisppath}:${standardlisppath}'
  45 etcdir='${datadir}/emacs/${version}/etc'
  46 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  47 docdir='${datadir}/emacs/${version}/etc'
  48 gamedir='${localstatedir}/games/emacs'
  49
  50 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  51 dnl Create a new --with option that defaults to being disabled.
  52 dnl NAME is the base name of the option.  The shell variable with_NAME
  53 dnl   will be set to either the user's value (if the option is
  54 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  55 dnl   option is not specified).  Note that the shell variable name is
  56 dnl   constructed as autoconf does, by replacing non-alphanumeric
  57 dnl   characters with "_".
  58 dnl HELP-STRING is the help text for the option.
  59 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  60   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  61     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  62 ])dnl
  63
  64 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  65 dnl Create a new --with option that defaults to being enabled.  NAME
  66 dnl   is the base name of the option.  The shell variable with_NAME
  67 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  68 dnl   'yes' (if the option is not specified).  Note that the shell
  69 dnl   variable name is constructed as autoconf does, by replacing
  70 dnl   non-alphanumeric characters with "_".
  71 dnl HELP-STRING is the help text for the option.
  72 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  73   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  74    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  75 ])dnl
  76
  77 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  78 if test "$with_pop" = yes; then
  79    AC_DEFINE(MAIL_USE_POP)
  80 fi
  81 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  82
  83 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  84 if test "$with_kerberos" != no; then
  85    AC_DEFINE(KERBEROS)
  86 fi
  87 AH_TEMPLATE(KERBEROS,
  88             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  89
  90 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  91 if test "${with_kerberos5}" != no; then
  92   if test "${with_kerberos}" = no; then
  93     with_kerberos=yes
  94     AC_DEFINE(KERBEROS)
  95   fi
  96   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  97 fi
  98
  99 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 100 dnl FIXME hesiod support may not be present, so it seems like an error
 101 dnl to define, or at least use, this unconditionally.
 102 if test "$with_hesiod" != no; then
 103   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 104 fi
 105
 106 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 107 if test "$with_mmdf" != no; then
 108    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 109 fi
 110
 111 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 112 if test "$with_mail_unlink" != no; then
 113    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 114 fi
 115
 116 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 117     [string giving default POP mail host])],
 118     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 119
 120 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 121
 122 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 123 if test "$with_sync_input" = yes; then
 124    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 125 fi
 126
 127 dnl FIXME currently it is not the last.
 128 dnl This should be the last --with option, because --with-x is
 129 dnl added later on when we find the path of X, and it's best to
 130 dnl keep them together visually.
 131 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 132  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 133 [         case "${withval}" in
 134             y | ye | yes )      val=gtk ;;
 135             n | no )            val=no  ;;
 136             l | lu | luc | luci | lucid )       val=lucid ;;
 137             a | at | ath | athe | athen | athena )      val=athena ;;
 138             m | mo | mot | moti | motif )       val=motif ;;
 139             g | gt | gtk  )     val=gtk ;;
 140             gtk3  )     val=gtk3 ;;
 141             * )
 142 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 143 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 144 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 145             ;;
 146           esac
 147           with_x_toolkit=$val
 148 ])
 149
 150 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 151 if test "$with_wide_int" = yes; then
 152   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 153 fi
 154
 155 dnl _ON results in a '--without' option in the --help output, so
 156 dnl the help text should refer to "don't compile", etc.
 157 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 158 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 159 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 160 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 161 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 162 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 163 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 164 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 165
 166 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 167 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 168 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 169
 170 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 171 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 172 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 173 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 174
 175 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 176 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 177 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 178 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 179 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 180 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 181
 182 ## For the times when you want to build Emacs but don't have
 183 ## a suitable makeinfo, and can live without the manuals.
 184 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 185 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 186
 187 ## Makefile.in needs the cache file name.
 188 AC_SUBST(cache_file)
 189
 190 ## This is an option because I do not know if all info/man support
 191 ## compressed files, nor how to test if they do so.
 192 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 193 if test $with_compress_info = yes; then
 194    GZIP_INFO=yes
 195 else
 196    GZIP_INFO=
 197 fi
 198 AC_SUBST(GZIP_INFO)
 199
 200 AC_ARG_WITH([pkg-config-prog],dnl
 201 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 202                   [path to pkg-config for finding GTK and librsvg])])
 203 if test "X${with_pkg_config_prog}" != X; then
 204    if test "${with_pkg_config_prog}" != yes; then
 205       PKG_CONFIG="${with_pkg_config_prog}"
 206    fi
 207 fi
 208
 209 CRT_DIR=
 210 AC_ARG_WITH([crt-dir],dnl
 211 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 212 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 213 CRT_DIR="${with_crt_dir}"
 214
 215 AC_ARG_WITH(gameuser,dnl
 216 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 217 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 218   && gameuser="${with_gameuser}"
 219 test "X$gameuser" = X && gameuser=games
 220
 221 AC_ARG_WITH([gnustep-conf],dnl
 222 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 223 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 224   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 225 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 226      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 227
 228 AC_ARG_ENABLE(ns-self-contained,
 229 [AS_HELP_STRING([--disable-ns-self-contained],
 230                 [disable self contained build under NeXTstep])],
 231    EN_NS_SELF_CONTAINED=$enableval,
 232    EN_NS_SELF_CONTAINED=yes)
 233
 234 AC_ARG_ENABLE(locallisppath,
 235 [AS_HELP_STRING([--enable-locallisppath=PATH],
 236                 [directories Emacs should search for lisp files specific
 237                  to this site])],
 238 if test "${enableval}" = "no"; then
 239   locallisppath=
 240 elif test "${enableval}" != "yes"; then
 241   locallisppath=${enableval}
 242 fi)
 243
 244 AC_ARG_ENABLE(checking,
 245 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 246                 [enable expensive run-time checks.  With LIST,
 247                  enable only specific categories of checks.
 248                  Categories are: all,yes,no.
 249                  Flags are: stringbytes, stringoverrun, stringfreelist,
 250                  xmallocoverrun, conslist, glyphs])],
 251 [ac_checking_flags="${enableval}"],[])
 252 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 253 for check in $ac_checking_flags
 254 do
 255         case $check in
 256         # these set all the flags to specific states
 257         yes)            ac_enable_checking=1 ;;
 258         no)             ac_enable_checking= ;
 259                         ac_gc_check_stringbytes= ;
 260                         ac_gc_check_string_overrun= ;
 261                         ac_gc_check_string_free_list= ;
 262                         ac_xmalloc_overrun= ;
 263                         ac_gc_check_cons_list= ;
 264                         ac_glyphs_debug= ;;
 265         all)            ac_enable_checking=1 ;
 266                         ac_gc_check_stringbytes=1 ;
 267                         ac_gc_check_string_overrun=1 ;
 268                         ac_gc_check_string_free_list=1 ;
 269                         ac_xmalloc_overrun=1 ;
 270                         ac_gc_check_cons_list=1 ;
 271                         ac_glyphs_debug=1 ;;
 272         # these enable particular checks
 273         stringbytes)    ac_gc_check_stringbytes=1 ;;
 274         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 275         stringfreelist) ac_gc_check_string_free_list=1 ;;
 276         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 277         conslist)       ac_gc_check_cons_list=1 ;;
 278         glyphs)         ac_glyphs_debug=1 ;;
 279         *)      AC_MSG_ERROR(unknown check category $check) ;;
 280         esac
 281 done
 282 IFS="$ac_save_IFS"
 283
 284 if test x$ac_enable_checking != x ; then
 285   AC_DEFINE(ENABLE_CHECKING, 1,
 286 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 287 fi
 288 if test x$ac_gc_check_stringbytes != x ; then
 289   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 290 [Define this temporarily to hunt a bug.  If defined, the size of
 291    strings is redundantly recorded in sdata structures so that it can
 292    be compared to the sizes recorded in Lisp strings.])
 293 fi
 294 if test x$ac_gc_check_string_overrun != x ; then
 295   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 296 [Define this to check for short string overrun.])
 297 fi
 298 if test x$ac_gc_check_string_free_list != x ; then
 299   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 300 [Define this to check the string free list.])
 301 fi
 302 if test x$ac_xmalloc_overrun != x ; then
 303   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 304 [Define this to check for malloc buffer overrun.])
 305 fi
 306 if test x$ac_gc_check_cons_list != x ; then
 307   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 308 [Define this to check for errors in cons list.])
 309 fi
 310 if test x$ac_glyphs_debug != x ; then
 311   AC_DEFINE(GLYPH_DEBUG, 1,
 312 [Define this to enable glyphs debugging code.])
 313 fi
 314
 315 AC_ARG_ENABLE(check-lisp-object-type,
 316 [AS_HELP_STRING([--enable-check-lisp-object-type],
 317                 [enable compile time checks for the Lisp_Object data type.
 318                 This is useful for development for catching certain types of bugs.])],
 319 if test "${enableval}" != "no"; then
 320    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 321    [Define this to enable compile time checks for the Lisp_Object data type.])
 322 fi)
 323
 324
 325 AC_ARG_ENABLE(profiling,
 326 [AS_HELP_STRING([--enable-profiling],
 327                 [build emacs with profiling support.
 328                  This might not work on all platforms])],
 329 [ac_enable_profiling="${enableval}"],[])
 330 if test x$ac_enable_profiling != x ; then
 331    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 332 else
 333    PROFILING_CFLAGS=
 334 fi
 335 AC_SUBST(PROFILING_CFLAGS)
 336
 337 AC_ARG_ENABLE(autodepend,
 338 [AS_HELP_STRING([--enable-autodepend],
 339                 [automatically generate dependencies to .h-files.
 340                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 341                  found])],
 342 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 343
 344 #### Make srcdir absolute, if it isn't already.  It's important to
 345 #### avoid running the path through pwd unnecessarily, since pwd can
 346 #### give you automounter prefixes, which can go away.  We do all this
 347 #### so Emacs can find its files when run uninstalled.
 348 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 349 unset CDPATH
 350 case "${srcdir}" in
 351   /* ) ;;
 352   . )
 353     ## We may be able to use the $PWD environment variable to make this
 354     ## absolute.  But sometimes PWD is inaccurate.
 355     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 356     ## but that tested only for a well-formed and valid PWD,
 357     ## it did not object when PWD was well-formed and valid but just wrong.
 358     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 359     then
 360       srcdir="$PWD"
 361     else
 362       srcdir="`(cd ${srcdir}; pwd)`"
 363     fi
 364   ;;
 365   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 366 esac
 367
 368 ### Canonicalize the configuration name.
 369
 370 AC_CANONICAL_HOST
 371 canonical=$host
 372 configuration=${host_alias-${build_alias-$host}}
 373
 374 dnl This used to use changequote, but, apart from `changequote is evil'
 375 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 376 dnl the great gob of text.  Thus it's not processed for possible expansion.
 377 dnl Just make sure the brackets remain balanced.
 378 dnl
 379 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 380 dnl indicated by comments.
 381 dnl quotation begins
 382 [
 383
 384 ### If you add support for a new configuration, add code to this
 385 ### switch statement to recognize your configuration name and select
 386 ### the appropriate operating system file.
 387
 388 ### You would hope that you could choose an s/*.h
 389 ### file based on the operating system portion.  However, it turns out
 390 ### that each s/*.h file is pretty manufacturer-specific.
 391 ### So we basically have to have a special case for each
 392 ### configuration name.
 393 ###
 394 ### As far as handling version numbers on operating systems is
 395 ### concerned, make sure things will fail in a fixable way.  If
 396 ### /etc/MACHINES doesn't say anything about version numbers, be
 397 ### prepared to handle anything reasonably.  If version numbers
 398 ### matter, be sure /etc/MACHINES says something about it.
 399
 400 opsys='' unported=no
 401 case "${canonical}" in
 402
 403   ## GNU/Linux and similar ports
 404   *-*-linux* )
 405     opsys=gnu-linux
 406   ;;
 407
 408   ## FreeBSD ports
 409   *-*-freebsd* )
 410     opsys=freebsd
 411   ;;
 412
 413   ## FreeBSD kernel + glibc based userland
 414   *-*-kfreebsd*gnu* )
 415     opsys=gnu-kfreebsd
 416   ;;
 417
 418   ## NetBSD ports
 419   *-*-netbsd* )
 420     opsys=netbsd
 421   ;;
 422
 423   ## OpenBSD ports
 424   *-*-openbsd* )
 425     opsys=openbsd
 426   ;;
 427
 428   ## Apple Darwin / Mac OS X
 429   *-apple-darwin* )
 430     case "${canonical}" in
 431       i[3456]86-* )  ;;
 432       powerpc-* )    ;;
 433       x86_64-* )     ;;
 434       * )            unported=yes ;;
 435     esac
 436     opsys=darwin
 437     ## Use fink packages if available.
 438     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 439 ##    if test -d /sw/include && test -d /sw/lib; then
 440 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 441 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 442 ##    fi
 443   ;;
 444
 445   ## HP 9000 series 700 and 800, running HP/UX
 446   hppa*-hp-hpux10.2* )
 447     opsys=hpux10-20
 448   ;;
 449   hppa*-hp-hpux1[1-9]* )
 450     opsys=hpux11
 451     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 452   ;;
 453
 454   ## IBM machines
 455   rs6000-ibm-aix4.[23]* )
 456     opsys=aix4-2
 457   ;;
 458   powerpc-ibm-aix4.[23]*  )
 459     opsys=aix4-2
 460   ;;
 461   rs6000-ibm-aix[56]* )
 462     opsys=aix4-2
 463   ;;
 464   powerpc-ibm-aix[56]*  )
 465     opsys=aix4-2
 466   ;;
 467
 468   ## Silicon Graphics machines
 469   ## Iris 4D
 470   mips-sgi-irix6.5 )
 471     opsys=irix6-5
 472     # Without defining _LANGUAGE_C, things get masked out in the headers
 473     # so that, for instance, grepping for `free' in stdlib.h fails and
 474     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 475     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 476   ;;
 477
 478   ## Suns
 479   *-sun-solaris* \
 480     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 481     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 482     case "${canonical}" in
 483       i[3456]86-*-* )   ;;
 484       amd64-*-*|x86_64-*-*) ;;
 485       sparc* )          ;;
 486       * )               unported=yes ;;
 487     esac
 488     case "${canonical}" in
 489       *-sunos5.6* | *-solaris2.6* )
 490                 opsys=sol2-6
 491                 RANLIB="ar -ts"
 492                 ;;
 493       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 494                 opsys=sol2-6
 495                 emacs_check_sunpro_c=yes
 496                 ;;
 497       *-sunos5* | *-solaris* )
 498                 opsys=sol2-10
 499                 emacs_check_sunpro_c=yes
 500                 ;;
 501     esac
 502     ## Watch out for a compiler that we know will not work.
 503     case "${canonical}" in
 504      *-solaris* | *-sunos5* )
 505                 if [ "x$CC" = x/usr/ucb/cc ]; then
 506                   ## /usr/ucb/cc doesn't work;
 507                   ## we should find some other compiler that does work.
 508                   unset CC
 509                 fi
 510                 ;;
 511       *) ;;
 512     esac
 513   ;;
 514
 515   ## Intel 386 machines where we don't care about the manufacturer.
 516   i[3456]86-*-* )
 517     case "${canonical}" in
 518       *-cygwin )                opsys=cygwin ;;
 519       *-darwin* )               opsys=darwin ;;
 520       *-sysv4.2uw* )            opsys=unixware ;;
 521       *-sysv5uw* )              opsys=unixware ;;
 522       *-sysv5OpenUNIX* )        opsys=unixware ;;
 523       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 524     esac
 525   ;;
 526
 527   * )
 528     unported=yes
 529   ;;
 530 esac
 531
 532 ### If the code above didn't choose an operating system, just choose
 533 ### an operating system based on the configuration name.  You really
 534 ### only want to use this when you have no idea what the right
 535 ### operating system is; if you know what operating systems a machine
 536 ### runs, it's cleaner to make it explicit in the case statement
 537 ### above.
 538 if test x"${opsys}" = x; then
 539   case "${canonical}" in
 540     *-gnu* )                            opsys=gnu ;;
 541     * )
 542       unported=yes
 543     ;;
 544   esac
 545 fi
 546
 547 ]
 548 dnl quotation ends
 549
 550 if test $unported = yes; then
 551   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 552 Check `etc/MACHINES' for recognized configuration names.])
 553 fi
 554
 555
 556 #### Choose a compiler.
 557
 558 dnl Sets GCC=yes if using gcc.
 559 AC_PROG_CC
 560 AM_PROG_CC_C_O
 561
 562 if test x$GCC = xyes; then
 563   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 564 else
 565   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 566 fi
 567
 568 # Initialize gnulib right after choosing the compiler.
 569 gl_EARLY
 570
 571 AC_ARG_ENABLE([gcc-warnings],
 572   [AS_HELP_STRING([--enable-gcc-warnings],
 573                   [turn on lots of GCC warnings. This is intended for
 574                    developers, and may generate false alarms when used
 575                    with older or non-GNU development tools.])],
 576   [case $enableval in
 577      yes|no) ;;
 578      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 579    esac
 580    gl_gcc_warnings=$enableval],
 581   [gl_gcc_warnings=no]
 582 )
 583
 584 AC_ARG_ENABLE(link-time-optimization,
 585 [AS_HELP_STRING([--enable-link-time-optimization],
 586                 [build emacs with link-time optimization.
 587                  This is supported only for GCC since 4.5.0.])],
 588 if test "${enableval}" != "no"; then
 589    AC_MSG_CHECKING([whether link-time optimization is supported])
 590    ac_lto_supported=no
 591    if test x$GCC = xyes; then
 592       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 593       if test x$CPUS != x; then
 594          LTO="-flto=$CPUS"
 595       else
 596          LTO="-flto"
 597       fi
 598       old_CFLAGS=$CFLAGS
 599       CFLAGS="$CFLAGS $LTO"
 600       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 601         [ac_lto_supported=yes], [ac_lto_supported=no])
 602       CFLAGS="$old_CFLAGS"
 603    fi
 604    AC_MSG_RESULT([$ac_lto_supported])
 605    if test "$ac_lto_supported" = "yes"; then
 606       CFLAGS="$CFLAGS $LTO"
 607    fi
 608 fi)
 609
 610 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 611 # ------------------------------------------------
 612 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 613 # Otherwise, run RUN-IF-NOT-FOUND.
 614 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 615   [AC_PREPROC_IFELSE(
 616     [AC_LANG_PROGRAM(
 617       [[
 618 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 619 /* ok */
 620 #else
 621 # error "your version of gcc is older than $1.$2"
 622 #endif
 623       ]]),
 624     ], [$3], [$4])
 625   ]
 626 )
 627
 628 # When compiling with GCC, prefer -isystem to -I when including system
 629 # include files, to avoid generating useless diagnostics for the files.
 630 if test "$gl_gcc_warnings" != yes; then
 631   isystem='-I'
 632 else
 633   isystem='-isystem '
 634
 635   # This, $nw, is the list of warnings we disable.
 636   nw=
 637
 638   case $with_x_toolkit in
 639     lucid | athena | motif)
 640        # Old toolkits mishandle 'const'.
 641        nw="$nw -Wwrite-strings"
 642        ;;
 643     *)
 644        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 645        ;;
 646   esac
 647   AC_SUBST([WERROR_CFLAGS])
 648
 649   nw="$nw -Waggregate-return"       # anachronistic
 650   nw="$nw -Wlong-long"              # C90 is anachronistic
 651   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 652   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 653   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 654   nw="$nw -Wcast-qual"              # Too many warnings for now
 655   nw="$nw -Wconversion"             # Too many warnings for now
 656   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 657   nw="$nw -Wsign-conversion"        # Too many warnings for now
 658   nw="$nw -Woverlength-strings"     # Not a problem these days
 659   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 660   nw="$nw -Wunreachable-code"       # so buggy that it's now silently ignored
 661   nw="$nw -Wpadded"                 # Our structs are not padded
 662   nw="$nw -Wredundant-decls"        # we regularly (re)declare functions
 663   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 664   nw="$nw -Wformat-nonliteral"      # we do this a lot
 665   nw="$nw -Wvla"                    # warnings in gettext.h
 666   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 667   nw="$nw -Wswitch-enum"            # Too many warnings for now
 668   nw="$nw -Wswitch-default"         # Too many warnings for now
 669   nw="$nw -Wfloat-equal"            # warns about high-quality code
 670   nw="$nw -Winline"                 # OK to ignore 'inline'
 671   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 672   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 673
 674   # Emacs doesn't care about shadowing; see
 675   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 676   nw="$nw -Wshadow"
 677
 678   # The following lines should be removable at some point.
 679   nw="$nw -Wstack-protector"
 680   nw="$nw -Wstrict-overflow"
 681   nw="$nw -Wsuggest-attribute=pure"
 682
 683   gl_MANYWARN_ALL_GCC([ws])
 684   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 685   for w in $ws; do
 686     gl_WARN_ADD([$w])
 687   done
 688   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 689   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 690   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 691   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 692   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 693   gl_WARN_ADD([-Wno-format-nonliteral])
 694
 695   # In spite of excluding -Wlogical-op above, it is enabled, as of
 696   # gcc 4.5.0 20090517.
 697   gl_WARN_ADD([-Wno-logical-op])
 698
 699   gl_WARN_ADD([-fdiagnostics-show-option])
 700   gl_WARN_ADD([-funit-at-a-time])
 701
 702   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 703   AC_DEFINE([_FORTIFY_SOURCE], [2],
 704     [enable compile-time and run-time bounds-checking, and some warnings])
 705   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 706
 707   # We use a slightly smaller set of warning options for lib/.
 708   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 709   nw=
 710   nw="$nw -Wunused-macros"
 711
 712   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 713   AC_SUBST([GNULIB_WARN_CFLAGS])
 714 fi
 715
 716
 717
 718 dnl Some other nice autoconf tests.
 719 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 720 dnl AC_PROG_INSTALL
 721 dnl AC_PROG_MKDIR_P
 722 dnl if test "x$RANLIB" = x; then
 723 dnl   AC_PROG_RANLIB
 724 dnl fi
 725
 726 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 727   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 728 dnl Don't use GZIP, which is used by gzip for additional parameters.
 729 AC_PATH_PROG(GZIP_PROG, gzip)
 730
 731 if test $opsys = gnu-linux; then
 732   AC_PATH_PROG(PAXCTL, paxctl,,
 733     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 734 fi
 735
 736 ## Need makeinfo >= 4.7 (?) to build the manuals.
 737 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 738 dnl By this stage, configure has already checked for egrep and set EGREP,
 739 dnl or exited with an error if no egrep was found.
 740 if test "$MAKEINFO" != "no" && \
 741   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 742    MAKEINFO=no
 743 fi
 744
 745 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 746 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 747 ## therefore in the category of "special tools" not normally required, which
 748 ## configure does not have to check for (eg autoconf itself).
 749 ## In a Bazaar checkout on the other hand, the manuals are not included.
 750 ## So makeinfo is a requirement to build from Bazaar, and configure
 751 ## should test for it as it does for any other build requirement.
 752 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 753 ## with pre-built manuals, from a Bazaar checkout.
 754 HAVE_MAKEINFO=yes
 755
 756 if test "$MAKEINFO" = "no"; then
 757   MAKEINFO=makeinfo
 758   if test "x${with_makeinfo}" = "xno"; then
 759     HAVE_MAKEINFO=no
 760   elif test ! -e $srcdir/info/emacs; then
 761     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 762 source tree does not seem to have pre-built manuals in the `info' directory.
 763 Either install a suitable version of makeinfo, or re-run configure
 764 with the `--without-makeinfo' option to build without the manuals.] )
 765   fi
 766 fi
 767 AC_SUBST(HAVE_MAKEINFO)
 768
 769 dnl Just so that there is only a single place we need to edit.
 770 INFO_EXT=.info
 771 INFO_OPTS=--no-split
 772 AC_SUBST(INFO_EXT)
 773 AC_SUBST(INFO_OPTS)
 774
 775 dnl Add our options to ac_link now, after it is set up.
 776
 777 if test x$GCC = xyes; then
 778   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 779     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 780 else
 781   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 782     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 783 fi
 784
 785 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 786 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 787 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 788 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 789 dnl if not built to support GNU ld.
 790
 791 late_LDFLAGS=$LDFLAGS
 792 if test x$GCC = xyes; then
 793   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 794 else
 795   LDFLAGS="$LDFLAGS -znocombreloc"
 796 fi
 797
 798 AC_MSG_CHECKING([for -znocombreloc])
 799 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 800   [AC_MSG_RESULT(yes)],
 801   LDFLAGS=$late_LDFLAGS
 802   [AC_MSG_RESULT(no)])
 803
 804
 805 dnl The function dump-emacs will not be defined and temacs will do
 806 dnl (load "loadup") automatically unless told otherwise.
 807 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 808 case "$opsys" in
 809   your-opsys-here) CANNOT_DUMP=yes ;;
 810 esac
 811
 812 test "$CANNOT_DUMP" = "yes" && \
 813   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 814
 815 AC_SUBST(CANNOT_DUMP)
 816
 817
 818 UNEXEC_OBJ=unexelf.o
 819 case "$opsys" in
 820   # MSDOS uses unexcoff.o
 821   # MSWindows uses unexw32.o
 822   aix4-2)
 823    UNEXEC_OBJ=unexaix.o
 824    ;;
 825   cygwin)
 826    UNEXEC_OBJ=unexcw.o
 827    ;;
 828   darwin)
 829    UNEXEC_OBJ=unexmacosx.o
 830    ;;
 831   hpux10-20 | hpux11)
 832    UNEXEC_OBJ=unexhp9k800.o
 833    ;;
 834   sol2-10)
 835    # Use the Solaris dldump() function, called from unexsol.c, to dump
 836    # emacs, instead of the generic ELF dump code found in unexelf.c.
 837    # The resulting binary has a complete symbol table, and is better
 838    # for debugging and other observability tools (debuggers, pstack, etc).
 839    #
 840    # If you encounter a problem using dldump(), please consider sending
 841    # a message to the OpenSolaris tools-linking mailing list:
 842    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 843    #
 844    # It is likely that dldump() works with older Solaris too, but this has
 845    # not been tested, so for now this change is for Solaris 10 or newer.
 846    UNEXEC_OBJ=unexsol.o
 847    ;;
 848 esac
 849
 850 LD_SWITCH_SYSTEM=
 851 case "$opsys" in
 852   freebsd)
 853    ## Let `ld' find image libs and similar things in /usr/local/lib.
 854    ## The system compiler, GCC, has apparently been modified to not
 855    ## look there, contrary to what a stock GCC would do.
 856 ### It's not our place to do this.  See bug#10313#17.
 857 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 858       :
 859    ;;
 860
 861   gnu-linux)
 862    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 863    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 864    ;;
 865
 866   netbsd)
 867 ### It's not our place to do this.  See bug#10313#17.
 868 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 869       :
 870    ;;
 871
 872   openbsd)
 873    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 874    ## otherwise Emacs dumps core on elf systems.
 875    LD_SWITCH_SYSTEM="-Z"
 876    ;;
 877 esac
 878 AC_SUBST(LD_SWITCH_SYSTEM)
 879
 880 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 881
 882 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 883 ## which has not been defined yet.  When this was handled with cpp,
 884 ## it was expanded to null when configure sourced the s/*.h file.
 885 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 886 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 887 ## (or somesuch), but because it is supposed to go at the _front_
 888 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 889 ## Compare with the gnu-linux case below, which added to the end
 890 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 891 ## LD_SWITCH_SYSTEM_TEMACS.
 892 case "$opsys" in
 893   netbsd|openbsd)
 894    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 895 esac
 896
 897
 898 C_SWITCH_MACHINE=
 899 case $canonical in
 900  alpha*)
 901   AC_CHECK_DECL([__ELF__])
 902   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 903     ## With ELF, make sure that all common symbols get allocated to in the
 904     ## data section.  Otherwise, the dump of temacs may miss variables in
 905     ## the shared library that have been initialized.  For example, with
 906     ## GNU libc, __malloc_initialized would normally be resolved to the
 907     ## shared library's .bss section, which is fatal.
 908     if test "x$GCC" = "xyes"; then
 909       C_SWITCH_MACHINE="-fno-common"
 910     else
 911       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 912     fi
 913   else
 914     UNEXEC_OBJ=unexalpha.o
 915   fi
 916   ;;
 917 esac
 918 AC_SUBST(C_SWITCH_MACHINE)
 919
 920 AC_SUBST(UNEXEC_OBJ)
 921
 922 C_SWITCH_SYSTEM=
 923 ## Some programs in src produce warnings saying certain subprograms
 924 ## are too complex and need a MAXMEM value greater than 2000 for
 925 ## additional optimization.  --nils@exp-math.uni-essen.de
 926 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 927   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 928 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 929 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 930 AC_SUBST(C_SWITCH_SYSTEM)
 931
 932
 933 LIBS_SYSTEM=
 934 case "$opsys" in
 935   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 936   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 937
 938   freebsd) LIBS_SYSTEM="-lutil" ;;
 939
 940   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 941
 942   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 943
 944   ## Motif needs -lgen.
 945   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 946 esac
 947 AC_SUBST(LIBS_SYSTEM)
 948
 949
 950 ### Make sure subsequent tests use flags consistent with the build flags.
 951
 952 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 953   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 954 else
 955   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 956 fi
 957
 958 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 959 AC_DEFUN([AC_TYPE_SIZE_T])
 960 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 961 AC_DEFUN([AC_TYPE_UID_T])
 962
 963
 964 LIB_MATH=-lm
 965 LIB_STANDARD=
 966 START_FILES=
 967 dnl Current possibilities handled by sed (aix4-2 -> aix,
 968 dnl gnu-linux -> gnu/linux, etc.):
 969 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
 970 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
 971 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
 972
 973 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
 974 case $opsys in
 975   cygwin )
 976     LIB_MATH=
 977     START_FILES='pre-crt0.o'
 978     ;;
 979   darwin )
 980     ## Adding -lm confuses the dynamic linker, so omit it.
 981     LIB_MATH=
 982     START_FILES='pre-crt0.o'
 983     ;;
 984   freebsd )
 985     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
 986     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
 987     SYSTEM_TYPE=berkeley-unix
 988     ;;
 989   gnu-linux | gnu-kfreebsd )
 990     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
 991     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
 992     ;;
 993   hpux10-20 | hpux11 )
 994     LIB_STANDARD=-lc
 995     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
 996     ;;
 997   dnl NB this may be adjusted below.
 998   netbsd | openbsd )
 999     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1000     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1001     SYSTEM_TYPE=berkeley-unix
1002     ;;
1003
1004   sol2* | unixware )
1005     SYSTEM_TYPE=usg-unix-v
1006     ;;
1007
1008 esac
1009
1010 AC_SUBST(LIB_MATH)
1011 AC_SUBST(START_FILES)
1012 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1013   [The type of system you are compiling for; sets `system-type'.])
1014
1015 dnl Not all platforms use crtn.o files.  Check if the current one does.
1016 crt_files=
1017
1018 for file in x $LIB_STANDARD $START_FILES; do
1019   case "$file" in
1020     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1021   esac
1022 done
1023
1024 if test "x$crt_files" != x; then
1025
1026   ## If user specified a crt-dir, use that unconditionally.
1027   crt_gcc=no
1028
1029   if test "X$CRT_DIR" = "X"; then
1030
1031     CRT_DIR=/usr/lib            # default
1032
1033     case "$canonical" in
1034       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1035       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1036       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1037       ## For anything else (eg /usr/lib32), it is up the user to specify
1038       ## the location (bug#5655).
1039       ## Test for crtn.o, not just the directory, because sometimes the
1040       ## directory exists but does not have the relevant files (bug#1287).
1041       ## FIXME better to test for binary compatibility somehow.
1042       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1043       ;;
1044
1045       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1046     esac
1047
1048     case "$opsys" in
1049       hpux10-20) CRT_DIR=/lib ;;
1050     esac
1051
1052     test "x${GCC}" = xyes && crt_gcc=yes
1053
1054   fi                            # CRT_DIR = ""
1055
1056   crt_missing=
1057
1058   for file in $crt_files; do
1059
1060     ## If we're using gcc, try to determine it automatically by asking
1061     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1062     ## system-dependent default from above.]
1063     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1064
1065        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1066        case "$crt_file" in
1067          */*)
1068            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1069            ;;
1070        esac
1071     fi
1072
1073     dnl We expect all the files to be in a single directory, so after the
1074     dnl first there is no point asking gcc.
1075     crt_gcc=no
1076
1077     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1078   done                          # $crt_files
1079
1080   test "x$crt_missing" = x || \
1081     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1082 Try using the --with-crt-dir option.])
1083
1084 fi                              # crt_files != ""
1085
1086 AC_SUBST(CRT_DIR)
1087
1088 case $opsys in
1089   netbsd | openbsd )
1090     if test -f $CRT_DIR/crti.o; then
1091
1092         test -f $CRT_DIR/crtn.o || \
1093           AC_MSG_ERROR([Required file not found: crtn.o])
1094
1095         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1096         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1097     fi
1098     ;;
1099 esac
1100
1101
1102 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1103 pre_PKG_CONFIG_LIBS=$LIBS
1104
1105 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1106
1107 dnl This function definition taken from Gnome 2.0
1108 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1109 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1110 dnl also defines GSTUFF_PKG_ERRORS on error
1111 AC_DEFUN([PKG_CHECK_MODULES], [
1112   succeeded=no
1113
1114   if test "$PKG_CONFIG" = "no" ; then
1115      ifelse([$4], , [AC_MSG_ERROR([
1116       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1117   else
1118      PKG_CONFIG_MIN_VERSION=0.9.0
1119      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1120         AC_MSG_CHECKING(for $2)
1121
1122         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1123            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1124            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1125             edit_cflags="
1126               s,///*,/,g
1127               s/^/ /
1128               s/ -I/ $isystem/g
1129               s/^ //
1130             "
1131             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1132             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1133             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1134             succeeded=yes
1135         else
1136             AC_MSG_RESULT(no)
1137             $1_CFLAGS=""
1138             $1_LIBS=""
1139             ## If we have a custom action on failure, don't print errors, but
1140             ## do set a variable so people can do so.
1141             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1142             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1143         fi
1144
1145         AC_SUBST($1_CFLAGS)
1146         AC_SUBST($1_LIBS)
1147      else
1148         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1149         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1150      fi
1151   fi
1152
1153   if test $succeeded = yes; then
1154      ifelse([$3], , :, [$3])
1155   else
1156      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1157   fi
1158 ])
1159
1160
1161 if test "${with_sound}" != "no"; then
1162   # Sound support for GNU/Linux and the free BSDs.
1163   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1164     have_sound_header=yes)
1165   # Emulation library used on NetBSD.
1166   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1167   AC_SUBST(LIBSOUND)
1168
1169   ALSA_REQUIRED=1.0.0
1170   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1171   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1172   if test $HAVE_ALSA = yes; then
1173     SAVE_CFLAGS="$CFLAGS"
1174     SAVE_LIBS="$LIBS"
1175     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1176     LIBS="$ALSA_LIBS $LIBS"
1177     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1178                     emacs_alsa_normal=yes,
1179                     emacs_alsa_normal=no)
1180     if test "$emacs_alsa_normal" != yes; then
1181       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1182                      [[snd_lib_error_set_handler (0);]])],
1183                      emacs_alsa_subdir=yes,
1184                      emacs_alsa_subdir=no)
1185       if test "$emacs_alsa_subdir" != yes; then
1186         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1187       fi
1188       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1189     fi
1190
1191     CFLAGS="$SAVE_CFLAGS"
1192     LIBS="$SAVE_LIBS"
1193     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1194     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1195     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1196   fi
1197
1198   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1199   dnl compiles only on the specified platforms.  For others, it
1200   dnl probably doesn't make sense to try.
1201   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1202      case "$opsys" in
1203        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1204        gnu-linux|freebsd|netbsd)
1205          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1206          ;;
1207      esac
1208   fi
1209
1210   AC_SUBST(CFLAGS_SOUND)
1211 fi
1212
1213 dnl checks for header files
1214 AC_CHECK_HEADERS_ONCE(
1215   linux/version.h sys/systeminfo.h
1216   stdio_ext.h fcntl.h coff.h pty.h
1217   sys/vlimit.h sys/resource.h
1218   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1219
1220 AC_MSG_CHECKING(if personality LINUX32 can be set)
1221 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1222                emacs_cv_personality_linux32=yes,
1223                emacs_cv_personality_linux32=no)
1224 AC_MSG_RESULT($emacs_cv_personality_linux32)
1225
1226 if test $emacs_cv_personality_linux32 = yes; then
1227   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1228             [Define to 1 if personality LINUX32 can be set.])
1229 fi
1230
1231 dnl On Solaris 8 there's a compilation warning for term.h because
1232 dnl it doesn't define `bool'.
1233 AC_CHECK_HEADERS(term.h, , , -)
1234 AC_HEADER_TIME
1235 AC_CHECK_DECLS([sys_siglist])
1236 if test $ac_cv_have_decl_sys_siglist != yes; then
1237   # For Tru64, at least:
1238   AC_CHECK_DECLS([__sys_siglist])
1239   if test $ac_cv_have_decl___sys_siglist = yes; then
1240     AC_DEFINE(sys_siglist, __sys_siglist,
1241               [Define to any substitute for sys_siglist.])
1242   fi
1243 fi
1244 AC_HEADER_SYS_WAIT
1245
1246 dnl Check for speed_t typedef.
1247 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1248   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1249     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1250 if test $emacs_cv_speed_t = yes; then
1251   AC_DEFINE(HAVE_SPEED_T, 1,
1252            [Define to 1 if `speed_t' is declared by <termios.h>.])
1253 fi
1254
1255 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1256 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1257 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1258   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1259 HAVE_EXCEPTION=$emacs_cv_struct_exception
1260 dnl Define on Darwin so emacs symbols will not conflict with those
1261 dnl in the System framework.  Otherwise -prebind will not work.
1262 if test $emacs_cv_struct_exception != yes || test $opsys = darwin; then
1263   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1264 fi
1265
1266 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1267 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1268 #if HAVE_SYS_SOCKET_H
1269 #include <sys/socket.h>
1270 #endif])
1271 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1272 #if HAVE_SYS_SOCKET_H
1273 #include <sys/socket.h>
1274 #endif])
1275 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1276 #if HAVE_SYS_SOCKET_H
1277 #include <sys/socket.h>
1278 #endif])
1279
1280 dnl checks for structure members
1281 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1282                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1283                   struct ifreq.ifr_addr,
1284                   struct ifreq.ifr_addr.sa_len], , ,
1285                  [AC_INCLUDES_DEFAULT
1286 #if HAVE_SYS_SOCKET_H
1287 #include <sys/socket.h>
1288 #endif
1289 #if HAVE_NET_IF_H
1290 #include <net/if.h>
1291 #endif])
1292
1293 dnl Check for endianness.
1294 dnl AC_C_BIGENDIAN is done by gnulib.
1295
1296 dnl check for Make feature
1297 dnl AC_PROG_MAKE_SET is done by Automake.
1298
1299 DEPFLAGS=
1300 MKDEPDIR=":"
1301 deps_frag=deps.mk
1302 dnl check for GNU Make if we have GCC and autodepend is on.
1303 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1304    AC_MSG_CHECKING([whether we are using GNU Make])
1305    HAVE_GNU_MAKE=no
1306    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1307    if test "x$testval" != x; then
1308       HAVE_GNU_MAKE=yes
1309    else
1310       ac_enable_autodepend=no
1311    fi
1312    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1313    if test $HAVE_GNU_MAKE = yes; then
1314       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1315       SAVE_CFLAGS="$CFLAGS"
1316       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1317       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1318       CFLAGS="$SAVE_CFLAGS"
1319       test -f deps.d || ac_enable_autodepend=no
1320       rm -rf deps.d
1321       AC_MSG_RESULT([$ac_enable_autodepend])
1322    fi
1323    if test $ac_enable_autodepend = yes; then
1324       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1325       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1326       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1327       deps_frag=autodeps.mk
1328    fi
1329 fi
1330 deps_frag=$srcdir/src/$deps_frag
1331 AC_SUBST(MKDEPDIR)
1332 AC_SUBST(DEPFLAGS)
1333 AC_SUBST_FILE(deps_frag)
1334
1335
1336 lisp_frag=$srcdir/src/lisp.mk
1337 AC_SUBST_FILE(lisp_frag)
1338
1339
1340 dnl checks for operating system services
1341 AC_SYS_LONG_FILE_NAMES
1342
1343 #### Choose a window system.
1344
1345 AC_PATH_X
1346 if test "$no_x" = yes; then
1347   window_system=none
1348 else
1349   window_system=x11
1350 fi
1351
1352 LD_SWITCH_X_SITE_RPATH=
1353 if test "${x_libraries}" != NONE; then
1354   if test -n "${x_libraries}"; then
1355     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1356     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1357   fi
1358   x_default_search_path=""
1359   x_search_path=${x_libraries}
1360   if test -z "${x_search_path}"; then
1361     x_search_path=/usr/lib
1362   fi
1363   for x_library in `echo ${x_search_path}: | \
1364                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1365     x_search_path="\
1366 ${x_library}/X11/%L/%T/%N%C%S:\
1367 ${x_library}/X11/%l/%T/%N%C%S:\
1368 ${x_library}/X11/%T/%N%C%S:\
1369 ${x_library}/X11/%L/%T/%N%S:\
1370 ${x_library}/X11/%l/%T/%N%S:\
1371 ${x_library}/X11/%T/%N%S"
1372     if test x"${x_default_search_path}" = x; then
1373       x_default_search_path=${x_search_path}
1374     else
1375       x_default_search_path="${x_search_path}:${x_default_search_path}"
1376     fi
1377   done
1378 fi
1379 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1380
1381 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1382   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1383 fi
1384
1385 if test x"${x_includes}" = x; then
1386   bitmapdir=/usr/include/X11/bitmaps
1387 else
1388   # accumulate include directories that have X11 bitmap subdirectories
1389   bmd_acc="dummyval"
1390   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1391     if test -d "${bmd}/X11/bitmaps"; then
1392       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1393     fi
1394     if test -d "${bmd}/bitmaps"; then
1395       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1396     fi
1397   done
1398   if test ${bmd_acc} != "dummyval"; then
1399     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1400   fi
1401 fi
1402
1403 HAVE_NS=no
1404 NS_IMPL_COCOA=no
1405 NS_IMPL_GNUSTEP=no
1406 tmp_CPPFLAGS="$CPPFLAGS"
1407 tmp_CFLAGS="$CFLAGS"
1408 CPPFLAGS="$CPPFLAGS -x objective-c"
1409 CFLAGS="$CFLAGS -x objective-c"
1410 TEMACS_LDFLAGS2="\${LDFLAGS}"
1411 GNU_OBJC_CFLAGS=
1412 if test "${with_ns}" != no; then
1413   if test "${opsys}" = darwin; then
1414      NS_IMPL_COCOA=yes
1415      ns_appdir=`pwd`/nextstep/Emacs.app
1416      ns_appbindir=${ns_appdir}/Contents/MacOS
1417      ns_appresdir=${ns_appdir}/Contents/Resources
1418      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1419   elif test -f $GNUSTEP_CONFIG_FILE; then
1420      NS_IMPL_GNUSTEP=yes
1421      ns_appdir=`pwd`/nextstep/Emacs.app
1422      ns_appbindir=${ns_appdir}
1423      ns_appresdir=${ns_appdir}/Resources
1424      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1425      dnl FIXME sourcing this several times in subshells seems inefficient.
1426      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1427      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1428      dnl I seemed to need these as well with GNUstep-startup 0.25.
1429      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1430      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1431      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1432        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1433      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1434        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1435      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1436      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1437      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1438      LIB_STANDARD=
1439      START_FILES=
1440      TEMACS_LDFLAGS2=
1441      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1442      dnl If they had chosen to either define it or not, we could have
1443      dnl just used AC_CHECK_DECL here.
1444      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1445        emacs_cv_objc_exceptions,
1446 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1447 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1448 1;
1449 #else
1450 fail;
1451 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1452      if test $emacs_cv_objc_exceptions = yes; then
1453        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1454        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1455          [Define if GNUstep uses ObjC exceptions.])
1456        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1457      fi
1458   fi
1459
1460   dnl This is only used while we test the NS headers, it gets reset below.
1461   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1462
1463   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1464                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1465   files are missing or cannot be compiled.])])
1466   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1467                                      [NSInteger i;])],
1468                     ns_have_nsinteger=yes,
1469                     ns_have_nsinteger=no)
1470   if test $ns_have_nsinteger = yes; then
1471     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1472   fi
1473 fi
1474 AC_SUBST(TEMACS_LDFLAGS2)
1475
1476 INSTALL_ARCH_INDEP_EXTRA=install-etc
1477 ns_self_contained=no
1478 ns_frag=/dev/null
1479 NS_OBJ=
1480 NS_OBJC_OBJ=
1481 if test "${HAVE_NS}" = yes; then
1482   if test "$with_toolkit_scroll_bars" = "no"; then
1483     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1484   fi
1485
1486   window_system=nextstep
1487   with_xft=no
1488   # set up packaging dirs
1489   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1490      ns_self_contained=yes
1491      prefix=${ns_appresdir}
1492      exec_prefix=${ns_appbindir}
1493      dnl This one isn't really used, only archlibdir is.
1494      libexecdir="\${ns_appbindir}/libexec"
1495      archlibdir="\${ns_appbindir}/libexec"
1496      docdir="\${ns_appresdir}/etc"
1497      etcdir="\${ns_appresdir}/etc"
1498      dnl FIXME maybe set datarootdir instead.
1499      dnl That would also get applications, icons, man.
1500      infodir="\${ns_appresdir}/info"
1501      mandir="\${ns_appresdir}/man"
1502      lispdir="\${ns_appresdir}/lisp"
1503      leimdir="\${ns_appresdir}/leim"
1504      INSTALL_ARCH_INDEP_EXTRA=
1505   fi
1506   ns_frag=$srcdir/src/ns.mk
1507   NS_OBJ="fontset.o fringe.o image.o"
1508   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1509 fi
1510 CFLAGS="$tmp_CFLAGS"
1511 CPPFLAGS="$tmp_CPPFLAGS"
1512 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1513 AC_SUBST(ns_self_contained)
1514 AC_SUBST(NS_OBJ)
1515 AC_SUBST(NS_OBJC_OBJ)
1516 AC_SUBST(LIB_STANDARD)
1517 AC_SUBST_FILE(ns_frag)
1518
1519 case "${window_system}" in
1520   x11 )
1521     HAVE_X_WINDOWS=yes
1522     HAVE_X11=yes
1523     case "${with_x_toolkit}" in
1524       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1525       motif ) USE_X_TOOLKIT=MOTIF ;;
1526       gtk ) with_gtk=yes
1527 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1528 dnl USE_X_TOOLKIT is set.
1529             USE_X_TOOLKIT=none ;;
1530       gtk3 ) with_gtk3=yes
1531              USE_X_TOOLKIT=none ;;
1532       no ) USE_X_TOOLKIT=none ;;
1533 dnl If user did not say whether to use a toolkit, make this decision later:
1534 dnl use the toolkit if we have gtk, or X11R5 or newer.
1535       * ) USE_X_TOOLKIT=maybe ;;
1536     esac
1537   ;;
1538   nextstep | none )
1539     HAVE_X_WINDOWS=no
1540     HAVE_X11=no
1541     USE_X_TOOLKIT=none
1542   ;;
1543 esac
1544
1545 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1546    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1547    if test "$HAVE_XSERVER" = true ||
1548       test -n "$DISPLAY" ||
1549       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1550         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1551 were found.  You should install the relevant development files for X
1552 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1553 sure you have development files for image handling, i.e.
1554 tiff, gif, jpeg, png and xpm.
1555 If you are sure you want Emacs compiled without X window support, pass
1556   --without-x
1557 to configure.])
1558    fi
1559 fi
1560
1561 ### If we're using X11, we should use the X menu package.
1562 HAVE_MENUS=no
1563 case ${HAVE_X11} in
1564   yes ) HAVE_MENUS=yes ;;
1565 esac
1566
1567 # Does the opsystem file prohibit the use of the GNU malloc?
1568 # Assume not, until told otherwise.
1569 GNU_MALLOC=yes
1570
1571 AC_CACHE_CHECK(
1572   [whether malloc is Doug Lea style],
1573   [emacs_cv_var_doug_lea_malloc],
1574   [AC_LINK_IFELSE(
1575      [AC_LANG_PROGRAM(
1576         [[#include <malloc.h>
1577           static void hook (void) {}]],
1578         [[malloc_set_state (malloc_get_state ());
1579           __after_morecore_hook = hook;
1580           __malloc_initialize_hook = hook;]])],
1581      [emacs_cv_var_doug_lea_malloc=yes],
1582      [emacs_cv_var_doug_lea_malloc=no])])
1583 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1584
1585
1586 dnl See comments in aix4-2.h about maybe using system malloc there.
1587 system_malloc=no
1588 case "$opsys" in
1589   ## darwin ld insists on the use of malloc routines in the System framework.
1590   darwin|sol2-10) system_malloc=yes ;;
1591 esac
1592
1593 if test "${system_malloc}" = "yes"; then
1594   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1595   GNU_MALLOC=no
1596   GNU_MALLOC_reason="
1597     (The GNU allocators don't work with this system configuration.)"
1598   GMALLOC_OBJ=
1599   VMLIMIT_OBJ=
1600 else
1601   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1602   VMLIMIT_OBJ=vm-limit.o
1603 fi
1604 AC_SUBST(GMALLOC_OBJ)
1605 AC_SUBST(VMLIMIT_OBJ)
1606
1607 if test "$doug_lea_malloc" = "yes" ; then
1608   if test "$GNU_MALLOC" = yes ; then
1609     GNU_MALLOC_reason="
1610       (Using Doug Lea's new malloc from the GNU C Library.)"
1611   fi
1612   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1613             [Define to 1 if you are using the GNU C Library.])
1614
1615   ## Use mmap directly for allocating larger buffers.
1616   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1617   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1618   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1619   case "$opsys" in
1620     gnu*) REL_ALLOC=no ;;
1621   esac
1622 fi
1623
1624 if test x"${REL_ALLOC}" = x; then
1625   REL_ALLOC=${GNU_MALLOC}
1626 fi
1627
1628 use_mmap_for_buffers=no
1629 case "$opsys" in
1630   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1631 esac
1632
1633 AC_FUNC_MMAP
1634 if test $use_mmap_for_buffers = yes; then
1635   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1636   REL_ALLOC=no
1637 fi
1638
1639 LIBS="$LIBS_SYSTEM $LIBS"
1640
1641 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1642 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1643 AC_CHECK_LIB(dnet, dnet_ntoa)
1644 dnl This causes -lresolv to get used in subsequent tests,
1645 dnl which causes failures on some systems such as HPUX 9.
1646 dnl AC_CHECK_LIB(resolv, gethostbyname)
1647
1648 dnl FIXME replace main with a function we actually want from this library.
1649 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1650
1651 dnl Check if pthreads is available.
1652 LIB_PTHREAD=
1653 AC_CHECK_HEADERS_ONCE(pthread.h)
1654 if test "$ac_cv_header_pthread_h"; then
1655   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1656   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1657   dnl testing for pthread_self if Emacs uses gmalloc.c.
1658   if test "$GMALLOC_OBJ" = gmalloc.o; then
1659     emacs_pthread_function=pthread_atfork
1660   else
1661     emacs_pthread_function=pthread_self
1662   fi
1663   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1664 fi
1665 if test "$HAVE_PTHREAD" = yes; then
1666   case "${canonical}" in
1667     *-hpux*) ;;
1668     *) LIB_PTHREAD="-lpthread"
1669        LIBS="$LIB_PTHREAD $LIBS" ;;
1670   esac
1671   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1672 fi
1673 AC_SUBST([LIB_PTHREAD])
1674
1675 AC_CHECK_LIB(pthreads, cma_open)
1676
1677 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1678 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1679 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1680 ## added to LIBS in configure would never contain the pthreads part,
1681 ## but the value used in Makefiles might.  FIXME?
1682 ##
1683 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1684 ## be harmless on older versions of X where it happens to exist.
1685 test "$opsys" = "aix4-2" && \
1686   test $ac_cv_lib_pthreads_cma_open = yes && \
1687   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1688
1689 dnl Check for need for bigtoc support on IBM AIX
1690
1691 case ${host_os} in
1692 aix*)
1693   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1694     case $GCC in
1695     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1696     *) gdb_cv_bigtoc=-bbigtoc ;;
1697     esac
1698
1699     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1700     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1701   ])
1702   ;;
1703 esac
1704
1705 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1706 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1707 # REAL_CPPFLAGS later on.
1708
1709 REAL_CFLAGS="$CFLAGS"
1710 REAL_CPPFLAGS="$CPPFLAGS"
1711
1712 if test "${HAVE_X11}" = "yes"; then
1713   DEFS="$C_SWITCH_X_SITE $DEFS"
1714   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1715   LIBS="-lX11 $LIBS"
1716   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1717   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1718
1719   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1720   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1721   # but it's more convenient here to set LD_RUN_PATH since this
1722   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1723   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1724     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1725     export LD_RUN_PATH
1726   fi
1727
1728   if test "${opsys}" = "gnu-linux"; then
1729     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1730     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1731      [[XOpenDisplay ("foo");]])],
1732      [xgnu_linux_first_failure=no],
1733      [xgnu_linux_first_failure=yes])
1734     if test "${xgnu_linux_first_failure}" = "yes"; then
1735       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1736       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1737       OLD_CPPFLAGS="$CPPFLAGS"
1738       OLD_LIBS="$LIBS"
1739       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1740       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1741       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1742       LIBS="$LIBS -b i486-linuxaout"
1743       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1744        [[XOpenDisplay ("foo");]])],
1745        [xgnu_linux_second_failure=no],
1746        [xgnu_linux_second_failure=yes])
1747       if test "${xgnu_linux_second_failure}" = "yes"; then
1748         # If we get the same failure with -b, there is no use adding -b.
1749         # So take it out.  This plays safe.
1750         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1751         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1752         CPPFLAGS="$OLD_CPPFLAGS"
1753         LIBS="$OLD_LIBS"
1754         AC_MSG_RESULT(no)
1755       else
1756         AC_MSG_RESULT(yes)
1757       fi
1758     else
1759       AC_MSG_RESULT(no)
1760     fi
1761   fi
1762
1763   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1764   # header files included from there.
1765   AC_MSG_CHECKING(for Xkb)
1766   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1767 #include <X11/XKBlib.h>]],
1768         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1769         emacs_xkb=yes, emacs_xkb=no)
1770   AC_MSG_RESULT($emacs_xkb)
1771   if test $emacs_xkb = yes; then
1772     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1773   fi
1774
1775   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1776 XScreenNumberOfScreen)
1777 fi
1778
1779 if test "${window_system}" = "x11"; then
1780   AC_MSG_CHECKING(X11 version 6)
1781   AC_CACHE_VAL(emacs_cv_x11_version_6,
1782   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1783 [[#if XlibSpecificationRelease < 6
1784 fail;
1785 #endif
1786 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1787   if test $emacs_cv_x11_version_6 = yes; then
1788     AC_MSG_RESULT(6 or newer)
1789     AC_DEFINE(HAVE_X11R6, 1,
1790               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1791     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1792     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1793     ## XIM support.
1794     case "$opsys" in
1795       sol2-*) : ;;
1796       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1797            [Define if you have usable X11R6-style XIM support.])
1798          ;;
1799     esac
1800   else
1801     AC_MSG_RESULT(before 6)
1802   fi
1803 fi
1804
1805
1806 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1807 HAVE_RSVG=no
1808 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1809   if test "${with_rsvg}" != "no"; then
1810     RSVG_REQUIRED=2.11.0
1811     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1812
1813     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1814     AC_SUBST(RSVG_CFLAGS)
1815     AC_SUBST(RSVG_LIBS)
1816
1817     if test $HAVE_RSVG = yes; then
1818       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1819       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1820       LIBS="$RSVG_LIBS $LIBS"
1821     fi
1822   fi
1823 fi
1824
1825 HAVE_IMAGEMAGICK=no
1826 if test "${HAVE_X11}" = "yes"; then
1827   if test "${with_imagemagick}" != "no"; then
1828     ## 6.2.8 is the earliest version known to work, but earlier versions
1829     ## might work - let us know if you find one.
1830     ## 6.0.7 does not work.  See bug#7955.
1831     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1832     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1833     AC_SUBST(IMAGEMAGICK_CFLAGS)
1834     AC_SUBST(IMAGEMAGICK_LIBS)
1835
1836     if test $HAVE_IMAGEMAGICK = yes; then
1837       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1838       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1839       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1840       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
1841     fi
1842   fi
1843 fi
1844
1845
1846 HAVE_GTK=no
1847 GTK_OBJ=
1848 if test "${with_gtk3}" = "yes"; then
1849   GLIB_REQUIRED=2.28
1850   GTK_REQUIRED=3.0
1851   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1852
1853   dnl Checks for libraries.
1854   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1855   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1856      AC_MSG_ERROR($GTK_PKG_ERRORS)
1857   fi
1858   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1859   GTK_OBJ=emacsgtkfixed.o
1860 fi
1861
1862 if test "$pkg_check_gtk" != "yes"; then
1863   HAVE_GTK=no
1864 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1865   GLIB_REQUIRED=2.10
1866   GTK_REQUIRED=2.10
1867   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1868
1869   dnl Checks for libraries.
1870   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1871   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1872      AC_MSG_ERROR($GTK_PKG_ERRORS)
1873   fi
1874 fi
1875 fi
1876
1877 if test x"$pkg_check_gtk" = xyes; then
1878
1879   AC_SUBST(GTK_CFLAGS)
1880   AC_SUBST(GTK_LIBS)
1881   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1882   CFLAGS="$CFLAGS $GTK_CFLAGS"
1883   LIBS="$GTK_LIBS $LIBS"
1884   dnl Try to compile a simple GTK program.
1885   GTK_COMPILES=no
1886   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1887   if test "${GTK_COMPILES}" != "yes"; then
1888     if test "$USE_X_TOOLKIT" != "maybe"; then
1889       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1890     fi
1891   else
1892     HAVE_GTK=yes
1893     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1894     GTK_OBJ="gtkutil.o $GTK_OBJ"
1895     USE_X_TOOLKIT=none
1896     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1897       :
1898     else
1899       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1900        closing open displays.  This is no problem if you just use
1901        one display, but if you use more than one and close one of them
1902        Emacs may crash.]])
1903       sleep 3
1904     fi
1905   fi
1906
1907 fi
1908 AC_SUBST(GTK_OBJ)
1909
1910
1911 if test "${HAVE_GTK}" = "yes"; then
1912
1913   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1914   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1915   if test "$with_toolkit_scroll_bars" != no; then
1916     with_toolkit_scroll_bars=yes
1917   fi
1918
1919   dnl  Check if we have the old file selection dialog declared and
1920   dnl  in the link library.  In 2.x it may be in the library,
1921   dnl  but not declared if deprecated featured has been selected out.
1922   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1923   HAVE_GTK_FILE_SELECTION=no
1924   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1925                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1926 #include <gtk/gtk.h>])
1927   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1928     AC_CHECK_FUNCS(gtk_file_selection_new)
1929   fi
1930
1931
1932   dnl Check for functions introduced in 2.14 and later.
1933   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1934                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1935                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1936                  gtk_orientable_set_orientation \
1937                  gtk_window_set_has_resize_grip)
1938 fi
1939
1940 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1941 dnl other platforms.
1942 HAVE_DBUS=no
1943 DBUS_OBJ=
1944 if test "${with_dbus}" = "yes"; then
1945    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1946    if test "$HAVE_DBUS" = yes; then
1947      LIBS="$LIBS $DBUS_LIBS"
1948      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1949      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
1950      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
1951      dnl D-Bus 1.5.12.
1952      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
1953                     dbus_type_is_valid \
1954                     dbus_validate_bus_name \
1955                     dbus_validate_path \
1956                     dbus_validate_interface \
1957                     dbus_validate_member)
1958      DBUS_OBJ=dbusbind.o
1959    fi
1960 fi
1961 AC_SUBST(DBUS_OBJ)
1962
1963 dnl GSettings has been tested under GNU/Linux only.
1964 HAVE_GSETTINGS=no
1965 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
1966    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
1967    if test "$HAVE_GSETTINGS" = "yes"; then
1968       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
1969       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
1970       SETTINGS_LIBS="$GSETTINGS_LIBS"
1971    fi
1972 fi
1973
1974 dnl GConf has been tested under GNU/Linux only.
1975 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1976 HAVE_GCONF=no
1977 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1978    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1979    if test "$HAVE_GCONF" = yes; then
1980       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1981       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1982       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
1983       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
1984    fi
1985 fi
1986
1987 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
1988     SAVE_CFLAGS="$CFLAGS"
1989     SAVE_LIBS="$LIBS"
1990     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
1991     LIBS="$SETTINGS_LIBS $LIBS"
1992     AC_CHECK_FUNCS([g_type_init])
1993     CFLAGS="$SAVE_CFLAGS"
1994     LIBS="$SAVE_LIBS"
1995 fi
1996 AC_SUBST(SETTINGS_CFLAGS)
1997 AC_SUBST(SETTINGS_LIBS)
1998
1999
2000 dnl SELinux is available for GNU/Linux only.
2001 HAVE_LIBSELINUX=no
2002 LIBSELINUX_LIBS=
2003 if test "${with_selinux}" = "yes"; then
2004    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2005    if test "$HAVE_LIBSELINUX" = yes; then
2006       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2007       LIBSELINUX_LIBS=-lselinux
2008    fi
2009 fi
2010 AC_SUBST(LIBSELINUX_LIBS)
2011
2012 HAVE_GNUTLS=no
2013 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2014 if test "${with_gnutls}" = "yes" ; then
2015   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2016   if test "${HAVE_GNUTLS}" = "yes"; then
2017     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2018   fi
2019
2020   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2021   LIBS="$LIBGNUTLS_LIBS $LIBS"
2022   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2023
2024   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2025     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2026   fi
2027 fi
2028
2029 AC_SUBST(LIBGNUTLS_LIBS)
2030 AC_SUBST(LIBGNUTLS_CFLAGS)
2031
2032 dnl Do not put whitespace before the #include statements below.
2033 dnl Older compilers (eg sunos4 cc) choke on it.
2034 HAVE_XAW3D=no
2035 LUCID_LIBW=
2036 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2037   if test "$with_xaw3d" != no; then
2038     AC_MSG_CHECKING(for xaw3d)
2039     AC_CACHE_VAL(emacs_cv_xaw3d,
2040     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2041 #include <X11/Intrinsic.h>
2042 #include <X11/Xaw3d/Simple.h>]],
2043       [[]])],
2044       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2045                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2046       emacs_cv_xaw3d=no)])
2047   else
2048     emacs_cv_xaw3d=no
2049   fi
2050   if test $emacs_cv_xaw3d = yes; then
2051     AC_MSG_RESULT([yes; using Lucid toolkit])
2052     USE_X_TOOLKIT=LUCID
2053     HAVE_XAW3D=yes
2054     LUCID_LIBW=-lXaw3d
2055     AC_DEFINE(HAVE_XAW3D, 1,
2056               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2057   else
2058     AC_MSG_RESULT(no)
2059     AC_MSG_CHECKING(for libXaw)
2060     AC_CACHE_VAL(emacs_cv_xaw,
2061     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2062 #include <X11/Intrinsic.h>
2063 #include <X11/Xaw/Simple.h>]],
2064       [[]])],
2065       emacs_cv_xaw=yes,
2066       emacs_cv_xaw=no)])
2067     if test $emacs_cv_xaw = yes; then
2068       AC_MSG_RESULT([yes; using Lucid toolkit])
2069       USE_X_TOOLKIT=LUCID
2070       LUCID_LIBW=-lXaw
2071     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2072       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2073     else
2074       AC_MSG_ERROR([No X toolkit could be found.
2075 If you are sure you want Emacs compiled without an X toolkit, pass
2076   --with-x-toolkit=no
2077 to configure.  Otherwise, install the development libraries for the toolkit
2078 that you want to use (e.g. Gtk+) and re-run configure.])
2079     fi
2080   fi
2081 fi
2082
2083 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2084
2085 LIBXTR6=
2086 if test "${USE_X_TOOLKIT}" != "none"; then
2087   AC_MSG_CHECKING(X11 toolkit version)
2088   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2089   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2090 [[#if XtSpecificationRelease < 6
2091 fail;
2092 #endif
2093 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2094   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2095   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2096     AC_MSG_RESULT(6 or newer)
2097     AC_DEFINE(HAVE_X11XTR6, 1,
2098               [Define to 1 if you have the X11R6 or newer version of Xt.])
2099     LIBXTR6="-lSM -lICE"
2100     case "$opsys" in
2101       ## Use libw.a along with X11R6 Xt.
2102       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2103     esac
2104   else
2105     AC_MSG_RESULT(before 6)
2106   fi
2107
2108 dnl If using toolkit, check whether libXmu.a exists.
2109 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2110   OLDLIBS="$LIBS"
2111   if test x$HAVE_X11XTR6 = xyes; then
2112     LIBS="-lXt -lSM -lICE $LIBS"
2113   else
2114     LIBS="-lXt $LIBS"
2115   fi
2116   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2117   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2118   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2119 fi
2120 AC_SUBST(LIBXTR6)
2121
2122 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2123 dnl Why not just test for libxmu in the normal way?
2124 LIBXMU=-lXmu
2125 case $opsys in
2126   ## These systems don't supply Xmu.
2127   hpux* | aix4-2 )
2128     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2129     ;;
2130 esac
2131 AC_SUBST(LIBXMU)
2132
2133 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2134 if test "${HAVE_X11}" = "yes"; then
2135   if test "${USE_X_TOOLKIT}" != "none"; then
2136     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2137   fi
2138 fi
2139
2140 LIBXP=
2141 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2142   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2143   if test -d /usr/include/openmotif; then
2144     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2145     emacs_cv_openmotif=yes
2146     case "$canonical" in
2147       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2148       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2149       ;;
2150       *)
2151       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2152     esac
2153   else
2154     emacs_cv_openmotif=no
2155   fi
2156   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2157   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2158     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2159 int x = 5;
2160 #else
2161 Motif version prior to 2.1.
2162 #endif]])],
2163     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2164   if test $emacs_cv_motif_version_2_1 = yes; then
2165     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2166     if test x$emacs_cv_openmotif = xyes; then
2167       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2168     fi
2169   else
2170     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2171     # We put this in CFLAGS temporarily to precede other -I options
2172     # that might be in CFLAGS temporarily.
2173     # We put this in CPPFLAGS where it precedes the other -I options.
2174     OLD_CPPFLAGS=$CPPFLAGS
2175     OLD_CFLAGS=$CFLAGS
2176     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2177     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2178     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2179       [[int x = 5;]])],
2180       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2181     if test $emacs_cv_lesstif = yes; then
2182       # Make sure this -I option remains in CPPFLAGS after it is set
2183       # back to REAL_CPPFLAGS.
2184       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2185       # have those other -I options anyway.  Ultimately, having this
2186       # directory ultimately in CPPFLAGS will be enough.
2187       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2188       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2189     else
2190       CFLAGS=$OLD_CFLAGS
2191       CPPFLAGS=$OLD_CPPFLAGS
2192     fi
2193   fi
2194   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2195     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2196 fi
2197
2198 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2199 dnl using Motif or Xaw3d is available, and unless
2200 dnl --with-toolkit-scroll-bars=no was specified.
2201
2202 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2203             [Define to 1 if we should use toolkit scroll bars.])dnl
2204 USE_TOOLKIT_SCROLL_BARS=no
2205 if test "${with_toolkit_scroll_bars}" != "no"; then
2206   if test "${USE_X_TOOLKIT}" != "none"; then
2207     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2208       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2209       HAVE_XAW3D=no
2210       USE_TOOLKIT_SCROLL_BARS=yes
2211     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2212       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2213       USE_TOOLKIT_SCROLL_BARS=yes
2214     fi
2215   elif test "${HAVE_GTK}" = "yes"; then
2216     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2217     USE_TOOLKIT_SCROLL_BARS=yes
2218   elif test "${HAVE_NS}" = "yes"; then
2219     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2220     USE_TOOLKIT_SCROLL_BARS=yes
2221   fi
2222 fi
2223
2224 dnl See if XIM is available.
2225 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2226           #include <X11/Xlib.h>
2227           #include <X11/Xresource.h>]],
2228          [[XIMProc  callback;]])],
2229          [HAVE_XIM=yes
2230          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2231          HAVE_XIM=no)
2232
2233 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2234
2235 if test "${with_xim}" != "no"; then
2236   AC_DEFINE(USE_XIM, 1,
2237             [Define to 1 if we should use XIM, if it is available.])
2238 fi
2239
2240
2241 if test "${HAVE_XIM}" != "no"; then
2242   late_CFLAGS=$CFLAGS
2243   if test "$GCC" = yes; then
2244     CFLAGS="$CFLAGS --pedantic-errors"
2245   fi
2246   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2247 #include <X11/Xlib.h>
2248 #include <X11/Xresource.h>]],
2249 [[Display *display;
2250 XrmDatabase db;
2251 char *res_name;
2252 char *res_class;
2253 XIMProc  callback;
2254 XPointer *client_data;
2255 #ifndef __GNUC__
2256 /* If we're not using GCC, it's probably not XFree86, and this is
2257    probably right, but we can't use something like --pedantic-errors.  */
2258 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2259                                            char*, XIMProc, XPointer*);
2260 #endif
2261 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2262    client_data);]])],
2263     [emacs_cv_arg6_star=yes])
2264   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2265          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2266 either XPointer or XPointer*.])dnl
2267   if test "$emacs_cv_arg6_star" = yes; then
2268     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2269   else
2270     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2271   fi
2272   CFLAGS=$late_CFLAGS
2273 fi
2274
2275 ### Start of font-backend (under any platform) section.
2276 # (nothing here yet -- this is a placeholder)
2277 ### End of font-backend (under any platform) section.
2278
2279 ### Start of font-backend (under X11) section.
2280 if test "${HAVE_X11}" = "yes"; then
2281    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2282
2283    ## Use -lXft if available, unless `--with-xft=no'.
2284    HAVE_XFT=maybe
2285     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2286       with_xft="no";
2287     fi
2288     if test "x${with_xft}" != "xno"; then
2289
2290       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2291       ## Because xftfont.c uses XRenderQueryExtension, we also
2292       ## need to link to -lXrender.
2293       HAVE_XRENDER=no
2294       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2295       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2296         OLD_CPPFLAGS="$CPPFLAGS"
2297         OLD_CFLAGS="$CFLAGS"
2298         OLD_LIBS="$LIBS"
2299         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2300         CFLAGS="$CFLAGS $XFT_CFLAGS"
2301         XFT_LIBS="-lXrender $XFT_LIBS"
2302         LIBS="$XFT_LIBS $LIBS"
2303         AC_CHECK_HEADER(X11/Xft/Xft.h,
2304           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2305
2306         if test "${HAVE_XFT}" = "yes"; then
2307           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2308             AC_SUBST(XFT_LIBS)
2309           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2310         else
2311           CPPFLAGS="$OLD_CPPFLAGS"
2312           CFLAGS="$OLD_CFLAGS"
2313           LIBS="$OLD_LIBS"
2314         fi                        # "${HAVE_XFT}" = "yes"
2315       fi                          # "$HAVE_XFT" != no
2316     fi                            # "x${with_xft}" != "xno"
2317
2318     ## We used to allow building with FreeType and without Xft.
2319     ## However, the ftx font backend driver is not in good shape.
2320     if test "$HAVE_XFT" != "yes"; then
2321        dnl For the "Does Emacs use" message at the end.
2322        HAVE_XFT=no
2323        HAVE_FREETYPE=no
2324     else
2325        dnl Strict linkers fail with
2326        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2327        dnl if -lfreetype is not specified.
2328        dnl The following is needed to set FREETYPE_LIBS.
2329        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2330                          HAVE_FREETYPE=no)
2331
2332        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2333     fi
2334
2335     HAVE_LIBOTF=no
2336     if test "${HAVE_FREETYPE}" = "yes"; then
2337       AC_DEFINE(HAVE_FREETYPE, 1,
2338                 [Define to 1 if using the freetype and fontconfig libraries.])
2339       if test "${with_libotf}" != "no"; then
2340         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2341                           HAVE_LIBOTF=no)
2342         if test "$HAVE_LIBOTF" = "yes"; then
2343           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2344           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2345                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2346                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2347           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2348             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2349                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2350           fi
2351         fi
2352       fi
2353     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2354     dnl Does the new font backend require it, or can it work without it?
2355     fi
2356
2357     HAVE_M17N_FLT=no
2358     if test "${HAVE_LIBOTF}" = yes; then
2359       if test "${with_m17n_flt}" != "no"; then
2360         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2361         if test "$HAVE_M17N_FLT" = "yes"; then
2362           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2363         fi
2364       fi
2365     fi
2366 else
2367     HAVE_XFT=no
2368     HAVE_FREETYPE=no
2369     HAVE_LIBOTF=no
2370     HAVE_M17N_FLT=no
2371 fi
2372
2373 ### End of font-backend (under X11) section.
2374
2375 AC_SUBST(FREETYPE_CFLAGS)
2376 AC_SUBST(FREETYPE_LIBS)
2377 AC_SUBST(FONTCONFIG_CFLAGS)
2378 AC_SUBST(FONTCONFIG_LIBS)
2379 AC_SUBST(LIBOTF_CFLAGS)
2380 AC_SUBST(LIBOTF_LIBS)
2381 AC_SUBST(M17N_FLT_CFLAGS)
2382 AC_SUBST(M17N_FLT_LIBS)
2383
2384 ### Use -lXpm if available, unless `--with-xpm=no'.
2385 HAVE_XPM=no
2386 LIBXPM=
2387 if test "${HAVE_X11}" = "yes"; then
2388   if test "${with_xpm}" != "no"; then
2389     AC_CHECK_HEADER(X11/xpm.h,
2390       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2391     if test "${HAVE_XPM}" = "yes"; then
2392       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2393       AC_EGREP_CPP(no_return_alloc_pixels,
2394       [#include "X11/xpm.h"
2395 #ifndef XpmReturnAllocPixels
2396 no_return_alloc_pixels
2397 #endif
2398       ], HAVE_XPM=no, HAVE_XPM=yes)
2399
2400       if test "${HAVE_XPM}" = "yes"; then
2401         AC_MSG_RESULT(yes)
2402       else
2403         AC_MSG_RESULT(no)
2404       fi
2405     fi
2406   fi
2407
2408   if test "${HAVE_XPM}" = "yes"; then
2409     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2410     LIBXPM=-lXpm
2411   fi
2412 fi
2413 AC_SUBST(LIBXPM)
2414
2415 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2416 HAVE_JPEG=no
2417 LIBJPEG=
2418 if test "${HAVE_X11}" = "yes"; then
2419   if test "${with_jpeg}" != "no"; then
2420     dnl Checking for jpeglib.h can lose because of a redefinition of
2421     dnl  HAVE_STDLIB_H.
2422     AC_CHECK_HEADER(jerror.h,
2423       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2424   fi
2425
2426   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2427   if test "${HAVE_JPEG}" = "yes"; then
2428     AC_DEFINE(HAVE_JPEG)
2429     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2430         [#include <jpeglib.h>
2431          version=JPEG_LIB_VERSION
2432 ],
2433         [AC_DEFINE(HAVE_JPEG)],
2434         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2435         HAVE_JPEG=no])
2436   fi
2437   if test "${HAVE_JPEG}" = "yes"; then
2438     LIBJPEG=-ljpeg
2439   fi
2440 fi
2441 AC_SUBST(LIBJPEG)
2442
2443 ### Use -lpng if available, unless `--with-png=no'.
2444 HAVE_PNG=no
2445 LIBPNG=
2446 if test "${HAVE_X11}" = "yes"; then
2447   if test "${with_png}" != "no"; then
2448     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2449     # in /usr/include/libpng.
2450     AC_CHECK_HEADERS(png.h libpng/png.h, break)
2451     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2452       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2453     fi
2454   fi
2455
2456   if test "${HAVE_PNG}" = "yes"; then
2457     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2458     LIBPNG="-lpng -lz -lm"
2459
2460     AC_CHECK_DECL(png_longjmp,
2461       [],
2462       [AC_DEFINE(PNG_DEPSTRUCT, [],
2463          [Define to empty to suppress deprecation warnings when building
2464           with --enable-gcc-warnings and with libpng versions before 1.5,
2465           which lack png_longjmp.])],
2466       [[#ifdef HAVE_LIBPNG_PNG_H
2467         # include <libpng/png.h>
2468         #else
2469         # include <png.h>
2470         #endif
2471       ]])
2472   fi
2473 fi
2474 AC_SUBST(LIBPNG)
2475
2476 ### Use -ltiff if available, unless `--with-tiff=no'.
2477 HAVE_TIFF=no
2478 LIBTIFF=
2479 if test "${HAVE_X11}" = "yes"; then
2480   if test "${with_tiff}" != "no"; then
2481     AC_CHECK_HEADER(tiffio.h,
2482       [tifflibs="-lz -lm"
2483       # At least one tiff package requires the jpeg library.
2484       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2485       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2486   fi
2487
2488   if test "${HAVE_TIFF}" = "yes"; then
2489     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2490     dnl FIXME -lz -lm, as per libpng?
2491     LIBTIFF=-ltiff
2492   fi
2493 fi
2494 AC_SUBST(LIBTIFF)
2495
2496 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2497 HAVE_GIF=no
2498 LIBGIF=
2499 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2500   AC_CHECK_HEADER(gif_lib.h,
2501 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2502 # Earlier versions can crash Emacs.
2503     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2504
2505   if test "$HAVE_GIF" = yes; then
2506     LIBGIF=-lgif
2507   elif test "$HAVE_GIF" = maybe; then
2508 # If gif_lib.h but no libgif, try libungif.
2509     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2510     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2511   fi
2512
2513   if test "${HAVE_GIF}" = "yes"; then
2514     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2515   fi
2516 fi
2517 AC_SUBST(LIBGIF)
2518
2519 dnl Check for required libraries.
2520 if test "${HAVE_X11}" = "yes"; then
2521   MISSING=""
2522   WITH_NO=""
2523   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2524     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2525   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2526     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2527   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2528     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2529   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2530     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2531   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2532     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2533
2534   if test "X${MISSING}" != X; then
2535     AC_MSG_ERROR([The following required libraries were not found:
2536     $MISSING
2537 Maybe some development libraries/packages are missing?
2538 If you don't want to link with them give
2539     $WITH_NO
2540 as options to configure])
2541   fi
2542 fi
2543
2544 ### Use -lgpm if available, unless `--with-gpm=no'.
2545 HAVE_GPM=no
2546 LIBGPM=
2547 if test "${with_gpm}" != "no"; then
2548   AC_CHECK_HEADER(gpm.h,
2549     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2550
2551   if test "${HAVE_GPM}" = "yes"; then
2552     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2553     LIBGPM=-lgpm
2554   fi
2555 fi
2556 AC_SUBST(LIBGPM)
2557
2558 dnl Check for malloc/malloc.h on darwin
2559 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2560
2561 GNUSTEP_CFLAGS=
2562 ### Use NeXTstep API to implement GUI.
2563 if test "${HAVE_NS}" = "yes"; then
2564   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2565   if test "${NS_IMPL_COCOA}" = "yes"; then
2566     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2567   fi
2568   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2569     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2570     # See also .m.o rule in Makefile.in */
2571     # FIXME: are all these flags really needed?  Document here why.  */
2572     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2573     ## Extra CFLAGS applied to src/*.m files.
2574     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2575   fi
2576   # We also have mouse menus.
2577   HAVE_MENUS=yes
2578   OTHER_FILES=ns-app
2579 fi
2580
2581
2582 ### Use session management (-lSM -lICE) if available
2583 HAVE_X_SM=no
2584 LIBXSM=
2585 if test "${HAVE_X11}" = "yes"; then
2586   AC_CHECK_HEADER(X11/SM/SMlib.h,
2587     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2588
2589   if test "${HAVE_X_SM}" = "yes"; then
2590     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2591     LIBXSM="-lSM -lICE"
2592     case "$LIBS" in
2593       *-lSM*) ;;
2594       *)      LIBS="$LIBXSM $LIBS" ;;
2595     esac
2596   fi
2597 fi
2598 AC_SUBST(LIBXSM)
2599
2600 ### Use libxml (-lxml2) if available
2601 HAVE_LIBXML2=no
2602 if test "${with_xml2}" != "no"; then
2603   ### I'm not sure what the version number should be, so I just guessed.
2604   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2605   if test "${HAVE_LIBXML2}" = "yes"; then
2606     LIBS="$LIBXML2_LIBS $LIBS"
2607     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2608     if test "${HAVE_LIBXML2}" = "yes"; then
2609       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2610     else
2611       LIBXML2_LIBS=""
2612       LIBXML2_CFLAGS=""
2613     fi
2614   fi
2615 fi
2616 AC_SUBST(LIBXML2_LIBS)
2617 AC_SUBST(LIBXML2_CFLAGS)
2618
2619 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2620 AC_CACHE_CHECK(whether netdb declares h_errno,
2621                emacs_cv_netdb_declares_h_errno,
2622 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2623   [[return h_errno;]])],
2624   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2625 if test $emacs_cv_netdb_declares_h_errno = yes; then
2626   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2627 fi
2628
2629 # fmod, logb, and frexp are found in -lm on most systems.
2630 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2631 AC_CHECK_LIB(m, sqrt)
2632
2633 # Check for mail-locking functions in a "mail" library.  Probably this should
2634 # have the same check as for liblockfile below.
2635 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2636 if test $have_mail = yes; then
2637   LIBS_MAIL=-lmail
2638   LIBS="$LIBS_MAIL $LIBS"
2639   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2640 else
2641   LIBS_MAIL=
2642 fi
2643 dnl Debian, at least:
2644 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2645 if test $have_lockfile = yes; then
2646    LIBS_MAIL=-llockfile
2647    LIBS="$LIBS_MAIL $LIBS"
2648    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2649 else
2650 # If we have the shared liblockfile, assume we must use it for mail
2651 # locking (e.g. Debian).  If we couldn't link against liblockfile
2652 # (no liblockfile.a installed), ensure that we don't need to.
2653   dnl This works for files generally, not just executables.
2654   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2655   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2656                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2657   if test $ac_cv_prog_liblockfile = yes; then
2658     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2659 This probably means that movemail could lose mail.
2660 There may be a `development' package to install containing liblockfile.])
2661   fi
2662 fi
2663 AC_CHECK_HEADERS_ONCE(maillock.h)
2664 AC_SUBST(LIBS_MAIL)
2665
2666 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2667 ## interlock access to the mail spool.  The alternative is a lock file named
2668 ## /usr/spool/mail/$USER.lock.
2669 mail_lock=no
2670 case "$opsys" in
2671   aix4-2) mail_lock="lockf" ;;
2672
2673   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2674
2675   ## On GNU/Linux systems, both methods are used by various mail programs.
2676   ## I assume most people are using newer mailers that have heard of flock.
2677   ## Change this if you need to.
2678   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2679   ## configure gets the right answers, and that means *NOT* using flock.
2680   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2681   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2682   ## Debian maintainer hasn't provided a clean fix for Emacs.
2683   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2684   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2685   ## correct logic.  -- fx
2686   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2687   ## liblockfile is a Free Software replacement for libmail, used on
2688   ## Debian systems and elsewhere. -rfr.
2689   gnu-*)
2690     mail_lock="flock"
2691     if test $have_mail = yes || test $have_lockfile = yes; then
2692       test $ac_cv_header_maillock_h = yes && mail_lock=no
2693     fi
2694     ;;
2695 esac
2696
2697 BLESSMAIL_TARGET=
2698 case "$mail_lock" in
2699   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2700
2701   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2702
2703   *) BLESSMAIL_TARGET="need-blessmail" ;;
2704 esac
2705 AC_SUBST(BLESSMAIL_TARGET)
2706
2707
2708 AC_CHECK_FUNCS(gethostname \
2709 closedir getrusage get_current_dir_name \
2710 lrand48 logb frexp fmod cbrt setsid \
2711 fpathconf select euidaccess getpagesize setlocale \
2712 utimes getrlimit setrlimit setpgid getcwd shutdown getaddrinfo \
2713 __fpending strsignal setitimer \
2714 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
2715 gai_strerror mkstemp getline getdelim fsync sync \
2716 difftime posix_memalign \
2717 getpwent endpwent getgrent endgrent \
2718 touchlock \
2719 cfmakeraw cfsetspeed copysign __executable_start)
2720
2721 dnl FIXME Fragile: something else may test for getwd as a dependency.
2722 dnl Change to defining BROKEN_xxx ?
2723 dnl getwd appears to be buggy on SVR4.2, so we don't use it.
2724 if test $opsys != unixware; then
2725   AC_CHECK_FUNCS(getwd)
2726 fi
2727
2728 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
2729 ## has a broken `rint' in some library versions including math library
2730 ## version number A.09.05.
2731 ## You can fix the math library by installing patch number PHSS_4630.
2732 ## But we can fix it more reliably for Emacs by just not using rint.
2733 ## We also skip HAVE_RANDOM - see comments in src/conf_post.h.
2734 case $opsys in
2735    hpux*) : ;;
2736    *) AC_CHECK_FUNCS(random rint) ;;
2737 esac
2738
2739 dnl Cannot use AC_CHECK_FUNCS
2740 AC_CACHE_CHECK([for __builtin_unwind_init],
2741                emacs_cv_func___builtin_unwind_init,
2742 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2743                 emacs_cv_func___builtin_unwind_init=yes,
2744                 emacs_cv_func___builtin_unwind_init=no)])
2745 if test $emacs_cv_func___builtin_unwind_init = yes; then
2746   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2747             [Define to 1 if you have the `__builtin_unwind_init' function.])
2748 fi
2749
2750 AC_CHECK_HEADERS_ONCE(sys/un.h)
2751
2752 AC_FUNC_FSEEKO
2753
2754 AC_FUNC_GETPGRP
2755
2756 # UNIX98 PTYs.
2757 AC_CHECK_FUNCS(grantpt)
2758
2759 # PTY-related GNU extensions.
2760 AC_CHECK_FUNCS(getpt)
2761
2762 # Check this now, so that we will NOT find the above functions in ncurses.
2763 # That is because we have not set up to link ncurses in lib-src.
2764 # It's better to believe a function is not available
2765 # than to expect to find it in ncurses.
2766 # Also we need tputs and friends to be able to build at all.
2767 AC_MSG_CHECKING([for library containing tputs])
2768 # Run a test program that contains a call to tputs, a call that is
2769 # never executed.  This tests whether a pre-'main' dynamic linker
2770 # works with the library.  It's too much trouble to actually call
2771 # tputs in the test program, due to portability hassles.  When
2772 # cross-compiling, assume the test program will run if it links.
2773 AC_DEFUN([tputs_link_source], [
2774   AC_LANG_SOURCE(
2775      [[extern void tputs (const char *, int, int (*)(int));
2776        int main (int argc, char **argv)
2777        {
2778           if (argc == 10000)
2779             tputs (argv[0], 0, 0);
2780           return 0;
2781        }]])
2782 ])
2783 # Maybe curses should be tried earlier?
2784 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2785 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2786   OLIBS=$LIBS
2787   if test -z "$tputs_library"; then
2788     LIBS_TERMCAP=
2789     msg='none required'
2790   else
2791     LIBS_TERMCAP=-l$tputs_library
2792     msg=$LIBS_TERMCAP
2793     LIBS="$LIBS_TERMCAP $LIBS"
2794   fi
2795   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2796     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2797   LIBS=$OLIBS
2798   if test "X$msg" != Xno; then
2799     break
2800   fi
2801 done
2802 AC_MSG_RESULT([$msg])
2803 if test "X$msg" = Xno; then
2804   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2805 The following libraries were tried (in order):
2806   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2807 Please try installing whichever of these libraries is most appropriate
2808 for your system, together with its header files.
2809 For example, a libncurses-dev(el) or similar package.])
2810 fi
2811
2812 ## Use termcap instead of terminfo?
2813 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2814 TERMINFO=yes
2815 ## FIXME?  In the cases below where we unconditionally set
2816 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2817 ## if that was found above to have tputs.
2818 ## Should we use the gnu* logic everywhere?
2819 case "$opsys" in
2820   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2821   ##  The ncurses library has been moved out of the System framework in
2822   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2823   ##  option to use it.
2824   darwin) LIBS_TERMCAP="-lncurses" ;;
2825
2826   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2827
2828   freebsd)
2829     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2830     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2831     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2832 [[#if __FreeBSD_version < 400000
2833 fail;
2834 #endif
2835 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2836
2837     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2838
2839     if test $emacs_cv_freebsd_terminfo = yes; then
2840       LIBS_TERMCAP="-lncurses"
2841     else
2842       TERMINFO=no
2843       LIBS_TERMCAP="-ltermcap"
2844     fi
2845     ;;
2846
2847   netbsd)
2848     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2849       TERMINFO=no
2850       LIBS_TERMCAP="-ltermcap"
2851     fi
2852     ;;
2853
2854   openbsd) LIBS_TERMCAP="-lncurses" ;;
2855
2856   ## hpux: Make sure we get select from libc rather than from libcurses
2857   ##  because libcurses on HPUX 10.10 has a broken version of select.
2858   ##  We used to use -lc -lcurses, but this may be cleaner.
2859   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2860   # set that way, now it uses the default).  Isn't this a contradiction?
2861   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2862
2863 esac
2864
2865 TERMCAP_OBJ=tparam.o
2866 if test $TERMINFO = yes; then
2867   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2868   TERMCAP_OBJ=terminfo.o
2869 fi
2870 AC_SUBST(LIBS_TERMCAP)
2871 AC_SUBST(TERMCAP_OBJ)
2872
2873
2874 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2875 # On Darwin, res_init appears not to be useful: see bug#562 and
2876 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
2877 resolv=no
2878
2879 if test $opsys != darwin; then
2880
2881   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2882 #include <arpa/nameser.h>
2883 #include <resolv.h>]],
2884     [[return res_init();]])],
2885     have_res_init=yes, have_res_init=no)
2886   if test "$have_res_init" = no; then
2887     OLIBS="$LIBS"
2888     LIBS="$LIBS -lresolv"
2889     AC_MSG_CHECKING(for res_init with -lresolv)
2890     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2891 #include <arpa/nameser.h>
2892 #include <resolv.h>]],
2893       [[return res_init();]])],
2894       have_res_init=yes, have_res_init=no)
2895     AC_MSG_RESULT($have_res_init)
2896     if test "$have_res_init" = yes ; then
2897       resolv=yes
2898     fi
2899     LIBS="$OLIBS"
2900   fi
2901
2902   if test "$have_res_init" = yes; then
2903     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2904   fi
2905 fi                              dnl !darwin
2906
2907 # Do we need the Hesiod library to provide the support routines?
2908 dnl FIXME?  Should we be skipping this on Darwin too?
2909 LIBHESIOD=
2910 if test "$with_hesiod" != no ; then
2911   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2912   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2913      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2914                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2915   if test "$resolv" = yes ; then
2916     RESOLVLIB=-lresolv
2917   else
2918     RESOLVLIB=
2919   fi
2920   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2921         hesiod=yes, :, $RESOLVLIB)])
2922
2923   if test x"$hesiod" = xyes; then
2924     AC_DEFINE(HAVE_LIBHESIOD, 1,
2925               [Define to 1 if you have the hesiod library (-lhesiod).])
2926     LIBHESIOD=-lhesiod
2927   fi
2928 fi
2929 AC_SUBST(LIBHESIOD)
2930
2931 # Do we need libresolv (due to res_init or Hesiod)?
2932 if test "$resolv" = yes && test $opsys != darwin; then
2933   AC_DEFINE(HAVE_LIBRESOLV, 1,
2934             [Define to 1 if you have the resolv library (-lresolv).])
2935   LIBRESOLV=-lresolv
2936 else
2937   LIBRESOLV=
2938 fi
2939 AC_SUBST(LIBRESOLV)
2940
2941 # These tell us which Kerberos-related libraries to use.
2942 COM_ERRLIB=
2943 CRYPTOLIB=
2944 KRB5LIB=
2945 DESLIB=
2946 KRB4LIB=
2947
2948 if test "${with_kerberos}" != no; then
2949   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2950   if test $have_com_err = yes; then
2951     COM_ERRLIB=-lcom_err
2952     LIBS="$COM_ERRLIB $LIBS"
2953     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2954   fi
2955   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2956   if test $have_crypto = yes; then
2957     CRYPTOLIB=-lcrypto
2958     LIBS="$CRYPTOLIB $LIBS"
2959     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2960   fi
2961   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2962   if test $have_k5crypto = yes; then
2963     CRYPTOLIB=-lk5crypto
2964     LIBS="$CRYPTOLIB $LIBS"
2965     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2966   fi
2967   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2968   if test $have_krb5=yes; then
2969     KRB5LIB=-lkrb5
2970     LIBS="$KRB5LIB $LIBS"
2971     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2972   fi
2973   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2974   if test "${with_kerberos5}" = no; then
2975     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2976     if test $have_des425 = yes; then
2977       DESLIB=-ldes425
2978       LIBS="$DESLIB $LIBS"
2979       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2980     else
2981       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2982       if test $have_des = yes; then
2983         DESLIB=-ldes
2984         LIBS="$DESLIB $LIBS"
2985         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2986       fi
2987     fi
2988     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2989     if test $have_krb4 = yes; then
2990       KRB4LIB=-lkrb4
2991       LIBS="$KRB4LIB $LIBS"
2992       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2993     else
2994       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2995       if test $have_krb = yes; then
2996         KRB4LIB=-lkrb
2997         LIBS="$KRB4LIB $LIBS"
2998         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2999       fi
3000     fi
3001   fi
3002
3003   if test "${with_kerberos5}" != no; then
3004     AC_CHECK_HEADERS(krb5.h,
3005       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3006                         [#include <krb5.h>])])
3007   else
3008     AC_CHECK_HEADERS(des.h,,
3009                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3010                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3011     AC_CHECK_HEADERS(krb.h,,
3012                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3013                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3014   fi
3015   AC_CHECK_HEADERS(com_err.h)
3016 fi
3017
3018 AC_SUBST(COM_ERRLIB)
3019 AC_SUBST(CRYPTOLIB)
3020 AC_SUBST(KRB5LIB)
3021 AC_SUBST(DESLIB)
3022 AC_SUBST(KRB4LIB)
3023
3024 AC_CHECK_FUNCS_ONCE(tzset)
3025 AC_MSG_CHECKING(whether localtime caches TZ)
3026 AC_CACHE_VAL(emacs_cv_localtime_cache,
3027 [if test x$ac_cv_func_tzset = xyes; then
3028 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3029 char TZ_GMT0[] = "TZ=GMT0";
3030 char TZ_PST8[] = "TZ=PST8";
3031 main()
3032 {
3033   time_t now = time ((time_t *) 0);
3034   int hour_GMT0, hour_unset;
3035   if (putenv (TZ_GMT0) != 0)
3036     exit (1);
3037   hour_GMT0 = localtime (&now)->tm_hour;
3038   unsetenv("TZ");
3039   hour_unset = localtime (&now)->tm_hour;
3040   if (putenv (TZ_PST8) != 0)
3041     exit (1);
3042   if (localtime (&now)->tm_hour == hour_GMT0)
3043     exit (1);
3044   unsetenv("TZ");
3045   if (localtime (&now)->tm_hour != hour_unset)
3046     exit (1);
3047   exit (0);
3048 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3049 [# If we have tzset, assume the worst when cross-compiling.
3050 emacs_cv_localtime_cache=yes])
3051 else
3052         # If we lack tzset, report that localtime does not cache TZ,
3053         # since we can't invalidate the cache if we don't have tzset.
3054         emacs_cv_localtime_cache=no
3055 fi])dnl
3056 AC_MSG_RESULT($emacs_cv_localtime_cache)
3057 if test $emacs_cv_localtime_cache = yes; then
3058   AC_DEFINE(LOCALTIME_CACHE, 1,
3059             [Define to 1 if localtime caches TZ.])
3060 fi
3061
3062 ok_so_far=yes
3063 AC_CHECK_FUNC(socket, , ok_so_far=no)
3064 if test $ok_so_far = yes; then
3065   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3066 fi
3067 if test $ok_so_far = yes; then
3068   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3069 fi
3070 if test $ok_so_far = yes; then
3071 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3072   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3073             [Define to 1 if you have inet sockets.])
3074 fi
3075
3076 if test -f /usr/lpp/X11/bin/smt.exp; then
3077   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3078             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3079 fi
3080
3081 AC_MSG_CHECKING(whether system supports dynamic ptys)
3082 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3083   AC_MSG_RESULT(yes)
3084   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3085 else
3086   AC_MSG_RESULT(no)
3087 fi
3088
3089 AC_FUNC_FORK
3090
3091 AC_CHECK_FUNCS(snprintf)
3092
3093 dnl Adapted from Haible's version.
3094 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3095   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3096     [[char* cs = nl_langinfo(CODESET);]])],
3097     emacs_cv_langinfo_codeset=yes,
3098     emacs_cv_langinfo_codeset=no)
3099   ])
3100 if test $emacs_cv_langinfo_codeset = yes; then
3101   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3102     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3103 fi
3104
3105 AC_TYPE_MBSTATE_T
3106
3107 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3108   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3109                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3110 if test "$emacs_cv_c_restrict_arr" = yes; then
3111   AC_DEFINE(__restrict_arr, __restrict,
3112     [Define to compiler's equivalent of C99 restrict keyword in array
3113      declarations.  Define as empty for no equivalent.])
3114 fi
3115
3116 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3117 dnl how the tty code is related to POSIX and/or other versions of termios.
3118 dnl The following looks like a useful start.
3119 dnl
3120 dnl AC_SYS_POSIX_TERMIOS
3121 dnl if test $ac_cv_sys_posix_termios = yes; then
3122 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3123 dnl                                and macros for terminal control.])
3124 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3125 dnl fi
3126
3127 dnl Turned on June 1996 supposing nobody will mind it.
3128 AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3129   in the full name stands for the login id.])
3130
3131 dnl Every platform that uses configure (ie every non-MS platform)
3132 dnl supports this.  There is a create-lockfiles option you can
3133 dnl customize if you do not want the lock files to be written.
3134 dnl So it is not clear that this #define still needs to exist.
3135 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3136   so that Emacs can tell instantly when you try to modify a file that
3137   someone else has modified in his/her Emacs.])
3138
3139 AH_TEMPLATE(FLOAT_CHECK_DOMAIN, [Define if the float library doesn't
3140   handle errors by either setting errno, or signaling SIGFPE/SIGILL.])
3141
3142 AH_TEMPLATE(HAVE_INVERSE_HYPERBOLIC, [Define if you have the functions
3143   acosh, asinh, and atanh.])
3144
3145 dnl Everybody supports this, except MS.
3146 dnl Seems like the kind of thing we should be testing for, though.
3147 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3148 AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3149
3150 dnl Everybody supports this, except MS-DOS.
3151 dnl Seems like the kind of thing we should be testing for, though.
3152 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3153 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3154   4.2-compatible sockets.])
3155
3156 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3157
3158 AC_DEFINE(NULL_DEVICE, ["/dev/null"], [Name of the file to open to get
3159   a null file, or a data sink.])
3160
3161 AC_DEFINE(SEPCHAR, [':'], [Character that separates PATH elements.])
3162
3163 dnl Everybody supports this, except MS-DOS.
3164 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
3165
3166 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
3167
3168
3169 dnl Only used on MS platforms.
3170 AH_TEMPLATE(DEVICE_SEP, [Character that separates a device in a file name.])
3171
3172 AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
3173   [Returns true if character is a device separator.])
3174
3175 AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
3176   [Returns true if character is a directory separator.])
3177
3178 dnl On MS, this also accepts IS_DEVICE_SEP.
3179 AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
3180   [Returns true if character is any form of separator.])
3181
3182
3183 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3184
3185 case $opsys in
3186   aix4-2)
3187     dnl Unfortunately without libXmu we cannot support EditRes.
3188     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
3189       AC_DEFINE(NO_EDITRES, 1)
3190     fi
3191     ;;
3192
3193   hpux*)
3194     dnl Assar Westerlund <assar@sics.se> says this is necessary for
3195     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
3196     AC_DEFINE(NO_EDITRES, 1)
3197     ;;
3198 esac
3199
3200
3201 case $opsys in
3202   darwin | gnu | hpux* | *bsd )
3203     AC_DEFINE(NO_TERMIO, 1, [Define if termio.h should not be included.])
3204     ;;
3205
3206   irix6-5 | sol2* | unixware )
3207     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
3208     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
3209     dnl need the constant to dimension an array.  So wire in the appropriate
3210     dnl value here.
3211     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
3212     ;;
3213 esac
3214
3215
3216 case $opsys in
3217   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3218   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3219   hpux* | irix6-5 | openbsd | sol2* | unixware )
3220     AC_DEFINE(BROKEN_SIGIO, 1, [Define if SIGIO should not be used.])
3221     ;;
3222
3223   aix4-2)
3224     dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
3225     AC_DEFINE(BROKEN_FIONREAD, 1, [Define if FIONREAD should not be used.])
3226     dnl As we define BROKEN_FIONREAD, SIGIO will be undefined in systty.h.
3227     dnl But, on AIX, SIGAIO, SIGPTY, and SIGPOLL are defined as SIGIO,
3228     dnl which causes compilation error at init_signals in sysdep.c.
3229     dnl So, we define these macros so that syssignal.h detects them
3230     dnl and undefine SIGAIO, SIGPTY and SIGPOLL.
3231     AC_DEFINE(BROKEN_SIGAIO, 1, [Define if SIGAIO should not be used.])
3232     AC_DEFINE(BROKEN_SIGPOLL,1, [Define if SIGPOLL should not be used.])
3233     AC_DEFINE(BROKEN_SIGPTY, 1, [Define if SIGPTY should not be used.])
3234
3235     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
3236     dnl the way this system works, libc functions that return malloced
3237     dnl memory use the libc malloc implementation. Calling xfree or
3238     dnl xrealloc on the results of such functions results in a crash.
3239     dnl
3240     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
3241     dnl but that does not currently work on this system.
3242     dnl
3243     dnl It is possible to completely override the malloc implementation on
3244     dnl AIX, but that involves putting the malloc functions in a shared
3245     dnl library and setting the MALLOCTYPE environment variable to point to
3246     dnl that shared library.
3247     dnl
3248     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
3249     dnl to avoid a crash just use the Emacs implementation for that function.
3250     dnl
3251     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
3252     dnl of this file, so that we do not check for get_current_dir_name
3253     dnl on AIX.  But that might be fragile if something else ends
3254     dnl up testing for get_current_dir_name as a dependency.
3255     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
3256       get_current_dir_name should not be used.])
3257     ;;
3258
3259   freebsd)
3260     dnl Circumvent a bug in FreeBSD.  In the following sequence of
3261     dnl writes/reads on a PTY, read(2) returns bogus data:
3262     dnl
3263     dnl write(2)  1022 bytes
3264     dnl write(2)   954 bytes, get EAGAIN
3265     dnl read(2)   1024 bytes in process_read_output
3266     dnl read(2)     11 bytes in process_read_output
3267     dnl
3268     dnl That is, read(2) returns more bytes than have ever been written
3269     dnl successfully.  The 1033 bytes read are the 1022 bytes written
3270     dnl successfully after processing (for example with CRs added if the
3271     dnl terminal is set up that way which it is here).  The same bytes will
3272     dnl be seen again in a later read(2), without the CRs.
3273     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
3274       work around an issue when reading from a PTY.])
3275     ;;
3276
3277   dnl Define the following so emacs symbols will not conflict with those
3278   dnl in the System framework.  Otherwise -prebind will not work.
3279   darwin)
3280     AC_DEFINE(NO_ABORT, 1, [Do not define abort in emacs.c.])
3281     ;;
3282 esac
3283
3284 case $opsys in
3285   gnu-* | sol2-10 )
3286     dnl FIXME Can't we test if this exists (eg /proc/$$)?
3287     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3288   ;;
3289 esac
3290
3291 case $opsys in
3292   darwin | freebsd | netbsd | openbsd )
3293     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
3294       close a pty to make it a controlling terminal (it is already a
3295       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
3296   ;;
3297 esac
3298
3299 dnl FIXME Surely we can test for this rather than hard-code it.
3300 case $opsys in
3301   netbsd | openbsd) sound_device="/dev/audio" ;;
3302   *) sound_device="/dev/dsp" ;;
3303 esac
3304
3305 dnl Used in sound.c
3306 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
3307   [Name of the default sound device.])
3308
3309
3310 dnl Emacs can read input using SIGIO and buffering characters itself,
3311 dnl or using CBREAK mode and making C-g cause SIGINT.
3312 dnl The choice is controlled by the variable interrupt_input.
3313 dnl
3314 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
3315 dnl
3316 dnl Emacs uses the presence or absence of the SIGIO and BROKEN_SIGIO macros
3317 dnl to indicate whether or not signal-driven I/O is possible.  It uses
3318 dnl INTERRUPT_INPUT to decide whether to use it by default.
3319 dnl
3320 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
3321 dnl CBREAK mode has two disadvantages
3322 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
3323 dnl I hear that in system V this problem does not exist.
3324 dnl 2) Control-G causes output to be discarded.
3325 dnl I do not know whether this can be fixed in system V.
3326 dnl
3327 dnl Another method of doing input is planned but not implemented.
3328 dnl It would have Emacs fork off a separate process
3329 dnl to read the input and send it to the true Emacs process
3330 dnl through a pipe.
3331 case $opsys in
3332   darwin | gnu-linux | gnu-kfreebsd )
3333     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
3334   ;;
3335 esac
3336
3337
3338 dnl If the system's imake configuration file defines `NeedWidePrototypes'
3339 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
3340 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
3341 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
3342 dnl taking float or double parameters.
3343 case $opsys in
3344   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
3345     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
3346       file defines `NeedWidePrototypes' as `NO'.])
3347   ;;
3348 esac
3349
3350
3351 dnl Used in process.c, this must be a loop, even if it only runs once.
3352 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
3353 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
3354 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
3355 dnl trying suffixes 0-16.
3356 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
3357   first PTY, if PTYs are supported.])
3358 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
3359 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
3360   end of a PTY, if non-standard.])
3361 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
3362   end of a PTY, if non-standard.])
3363
3364 case $opsys in
3365   aix4-2 )
3366     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
3367     dnl You allocate a pty by opening /dev/ptc to get the master side.
3368     dnl To get the name of the slave side, you just ttyname() the master side.
3369     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
3370     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
3371     ;;
3372
3373   cygwin )
3374     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3375     dnl multi-line AC_DEFINEs are hard. :(
3376     AC_DEFINE(PTY_OPEN, [ do { int dummy; SIGMASKTYPE mask; mask = sigblock (sigmask (SIGCHLD)); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; sigsetmask (mask); if (fd >= 0) emacs_close (dummy); } while (0)])
3377     AC_DEFINE(PTY_NAME_SPRINTF, [])
3378     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3379     ;;
3380
3381   darwin )
3382     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3383     dnl Not used, because PTY_ITERATION is defined.
3384     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3385     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
3386     dnl But we don't have to block SIGCHLD because it is blocked in the
3387     dnl implementation of grantpt.
3388     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (0)])
3389     AC_DEFINE(PTY_NAME_SPRINTF, [])
3390     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3391     ;;
3392
3393   gnu | freebsd | netbsd | openbsd )
3394     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3395     ;;
3396
3397   gnu-linux | gnu-kfreebsd )
3398     dnl if HAVE_GRANTPT
3399     if test "x$ac_cv_func_grantpt" = xyes; then
3400       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
3401       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3402       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
3403       dnl to prevent sigchld_handler from intercepting the child's death.
3404       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname; sigblock (sigmask (SIGCHLD)); if (grantpt (fd) == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname(fd))) { sigunblock (sigmask (SIGCHLD)); close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); sigunblock (sigmask (SIGCHLD)); }])
3405       dnl if HAVE_GETPT
3406       if test "x$ac_cv_func_getpt" = xyes; then
3407         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
3408         AC_DEFINE(PTY_NAME_SPRINTF, [])
3409       else
3410         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3411       fi
3412     else
3413       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3414     fi
3415     ;;
3416
3417   hpux*)
3418     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3419     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
3420     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
3421     ;;
3422
3423   irix6-5 )
3424     dnl It looks like this cannot be right, because it is not a loop.
3425     dnl However, process.c actually does this:
3426     dnl # ifndef __sgi
3427     dnl   continue;
3428     dnl # else
3429     dnl   return -1;
3430     dnl # endif
3431     dnl which presumably makes it OK, since irix == sgi (?).
3432     dnl FIXME it seems like this special treatment is unnecessary?
3433     dnl Why can't irix use a single-trip loop like eg cygwin?
3434     AC_DEFINE(PTY_ITERATION, [])
3435     dnl Not used, because PTY_ITERATION is defined.
3436     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
3437     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
3438     dnl No need to get the pty name at all.
3439     AC_DEFINE(PTY_NAME_SPRINTF, [])
3440     dnl No need to use sprintf to get the tty name--we get that from _getpty.
3441     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3442     ;;
3443
3444   sol2* )
3445     dnl Uses sigblock/sigunblock rather than sighold/sigrelse,
3446     dnl which appear to be BSD4.1 specific.  It may also be appropriate
3447     dnl for SVR4.x (x<2) but I'm not sure.   fnf@cygnus.com
3448     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
3449     dnl from intercepting that death.  If any child but grantpt's should die
3450     dnl within, it should be caught after sigrelse(2).
3451     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; sigblock (sigmask (SIGCLD)); if (grantpt (fd) == -1) { emacs_close (fd); return -1; } sigunblock (sigmask (SIGCLD)); if (unlockpt (fd) == -1) { emacs_close (fd); return -1; } if (!(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3452     ;;
3453
3454   unixware )
3455     dnl Comments are as per sol2*.
3456     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; sigblock(sigmask(SIGCLD)); if (grantpt(fd) == -1) fatal("could not grant slave pty"); sigunblock(sigmask(SIGCLD)); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3457     ;;
3458 esac
3459
3460
3461 case $opsys in
3462   sol2* | unixware )
3463     dnl This change means that we don't loop through allocate_pty too
3464     dnl many times in the (rare) event of a failure.
3465     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
3466     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3467     dnl Push various streams modules onto a PTY channel.  Used in process.c.
3468     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
3469     ;;
3470 esac
3471
3472
3473 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
3474 "typing" a signal character on the pty.])
3475
3476 case $opsys in
3477   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
3478   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
3479   aix4-2 | cygwin | gnu | irix6-5 | freebsd | netbsd | openbsd )
3480     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3481     ;;
3482
3483   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
3484   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
3485   gnu-linux | gnu-kfreebsd )
3486
3487     AC_MSG_CHECKING([for signals via characters])
3488     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3489 #include <linux/version.h>
3490 #if LINUX_VERSION_CODE < 0x20400
3491 # error "Linux version too old"
3492 #endif
3493       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
3494
3495     AC_MSG_RESULT([$emacs_signals_via_chars])
3496     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3497     ;;
3498 esac
3499
3500
3501 dnl Used in dispnew.c
3502 AH_TEMPLATE(PENDING_OUTPUT_COUNT, [Number of chars of output in the
3503 buffer of a stdio stream.])
3504
3505 dnl FIXME just PENDING_OUTPUT_COUNT should suffice.
3506 AH_TEMPLATE(GNU_LIBRARY_PENDING_OUTPUT_COUNT, [Value of
3507 PENDING_OUTPUT_COUNT if using the GNU C library.])
3508
3509 case $opsys in
3510   cygwin | darwin | freebsd | netbsd | openbsd )
3511     AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->_p - (FILE)->_bf._base)])
3512     ;;
3513
3514   unixware)
3515     AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->__ptr - (FILE)->__base)])
3516     ;;
3517
3518   gnu | gnu-linux | gnu-kfreebsd )
3519     AC_MSG_CHECKING([for style of pending output formalism])
3520     dnl In autoconf 2.67 and later, we could use a single test
3521     dnl since the preprocessed output is accessible in "conftest.i".
3522     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3523 #include <stdio.h>
3524 #if !defined (_IO_STDIO_H) && !defined (_STDIO_USES_IOSTREAM)
3525 # error "stdio definitions not found"
3526 #endif
3527       ]], [[]])], emacs_pending_output=new, emacs_pending_output=unknown)
3528
3529       if test $emacs_pending_output = unknown; then
3530         case $opsys in
3531           gnu-linux | gnu-kfreebsd)
3532             AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3533 #include <stdio.h>
3534 #ifndef __UCLIBC__
3535 # error "not using uclibc"
3536 #endif
3537             ]], [[]])], emacs_pending_output=uclibc, emacs_pending_output=old)
3538             ;;
3539         esac
3540       fi
3541
3542       AC_MSG_RESULT([$emacs_pending_output])
3543
3544       case $emacs_pending_output in
3545         new)
3546           dnl New C libio names.
3547           AC_DEFINE(GNU_LIBRARY_PENDING_OUTPUT_COUNT(FILE),
3548             [((FILE)->_IO_write_ptr - (FILE)->_IO_write_base)])
3549           ;;
3550         uclibc)
3551           dnl Using the uClibc library.
3552           AC_DEFINE(GNU_LIBRARY_PENDING_OUTPUT_COUNT(FILE),
3553             [((FILE)->__bufpos - (FILE)->__bufstart)])
3554           ;;
3555         old)
3556           dnl Old C++ iostream names.
3557           AC_DEFINE(GNU_LIBRARY_PENDING_OUTPUT_COUNT(FILE),
3558             [((FILE)->_pptr - (FILE)->_pbase)])
3559           ;;
3560       esac
3561     ;;
3562 esac
3563
3564
3565 dnl Used in vm-limit.c
3566 AH_TEMPLATE(DATA_START, [Address of the start of the data segment.])
3567 dnl Used in lisp.h, emacs.c, mem-limits.h
3568 dnl NEWS.18 describes this as "a number which contains
3569 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
3570 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
3571 stored in a Lisp_Object.])
3572 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
3573
3574 case $opsys in
3575   gnu)
3576     dnl libc defines data_start.
3577     AC_DEFINE(DATA_START, [({ extern int data_start; (char *) &data_start; })])
3578     ;;
3579
3580   hpux*)
3581     dnl The data segment on this machine always starts at address 0x40000000.
3582     AC_DEFINE(DATA_START, [0x40000000])
3583     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
3584     ;;
3585   irix6-5)
3586     AC_DEFINE(DATA_START, [0x10000000])
3587     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
3588     ;;
3589 esac
3590
3591
3592 AH_TEMPLATE(ULIMIT_BREAK_VALUE, [Undocumented.])
3593 AH_TEMPLATE(TAB3, [Undocumented.])
3594
3595 case $opsys in
3596   darwin) AC_DEFINE(TAB3, OXTABS) ;;
3597
3598   gnu | freebsd | netbsd | openbsd )
3599     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
3600     AC_DEFINE(TAB3, OXTABS)
3601     ;;
3602
3603   gnu-linux | gnu-kfreebsd )
3604     dnl libc-linux/sysdeps/linux/i386/ulimit.c says that due to shared
3605     dnl library, we cannot get the maximum address for brk.
3606     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3607 #ifndef __i386__
3608 # error "not i386"
3609 #endif
3610       ]], [[]])], AC_DEFINE(ULIMIT_BREAK_VALUE, [(32*1024*1024)]), [])
3611
3612     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3613 #ifndef __ia64__
3614 # error "not ia64"
3615 #endif
3616       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
3617         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (0)],
3618         [Mark a secondary stack, like the register stack on the ia64.]), [])
3619     ;;
3620
3621   hpux*)
3622     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
3623       run_time_remap; for HPUX.])
3624     ;;
3625
3626   irix6-5)
3627     dnl Ulimit(UL_GMEMLIM) is busted...
3628     AC_DEFINE(ULIMIT_BREAK_VALUE, [0x14000000])
3629     ;;
3630 esac
3631
3632
3633 dnl These won't be used automatically yet.  We also need to know, at least,
3634 dnl that the stack is continuous.
3635 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
3636   registers relevant for conservative garbage collection in the jmp_buf.])
3637
3638 AH_TEMPLATE(GC_MARK_STACK, [Define to GC_USE_GCPROS_AS_BEFORE if
3639   conservative garbage collection is not known to work.])
3640
3641
3642 case $opsys in
3643   aix4-2 | hpux* | unixware)
3644     dnl Conservative garbage collection has not been tested, so for now
3645     dnl play it safe and stick with the old-fashioned way of marking.
3646     AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE])
3647     ;;
3648
3649   dnl Not all the architectures are tested, but there are Debian packages
3650   dnl for SCM and/or Guile on them, so the technique must work.  See also
3651   dnl comments in alloc.c concerning setjmp and gcc.
3652   dnl Fixme: it's probably safe to just use the GCC conditional below.
3653   gnu-linux | gnu-kfreebsd )
3654     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3655 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
3656   || defined __alpha__ || defined __mips__ || defined __s390__ \
3657   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
3658   || defined __ia64__ || defined __sh__
3659 /* ok */
3660 #else
3661 # error "setjmp not known to work on this arch"
3662 #endif
3663     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1),
3664       AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE]) )
3665     ;;
3666 esac
3667
3668
3669 if test x$GCC = xyes; then
3670    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
3671    AC_DEFINE(GC_SETJMP_WORKS, 1)
3672 else
3673   case $opsys in
3674     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
3675     freebsd | netbsd | openbsd | irix6-5 | sol2* )
3676       AC_DEFINE(GC_SETJMP_WORKS, 1)
3677       ;;
3678   esac
3679 fi                              dnl GCC?
3680
3681
3682 case $opsys in
3683   sol2* | unixware )
3684     dnl setjmp and longjmp can safely replace _setjmp and _longjmp,
3685     dnl but they will run more slowly.
3686     AC_DEFINE(_setjmp, setjmp, [Some platforms redefine this.])
3687     AC_DEFINE(_longjmp, longjmp, [Some platforms redefine this.])
3688     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
3689     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
3690     dnl and this is all we need.
3691     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
3692     ;;
3693 esac
3694
3695
3696 case $opsys in
3697   hpux* | sol2* )
3698     dnl Used in xfaces.c.
3699     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
3700       some systems, where it requires time.h.])
3701     ;;
3702
3703   netbsd | openbsd )
3704     dnl Greg A. Woods <woods@weird.com> says we must include signal.h
3705     dnl before syssignal.h is included, to work around interface conflicts
3706     dnl that are handled with CPP __RENAME() macro in signal.h.
3707     AC_DEFINE(SIGNAL_H_AHB, 1, [Define if AH_BOTTOM should include signal.h.])
3708     ;;
3709 esac
3710
3711
3712 dnl Define symbols to identify the version of Unix this is.
3713 dnl Define all the symbols that apply correctly.
3714 AH_TEMPLATE(BSD4_2, [Define if the system is compatible with BSD 4.2.])
3715 AH_TEMPLATE(BSD_SYSTEM, [Define if the system is compatible with BSD 4.2.])
3716 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
3717 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
3718 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
3719 AH_TEMPLATE(USG5, [Define if the system is compatible with System V.])
3720 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
3721
3722 case $opsys in
3723   aix4-2)
3724     AC_DEFINE(USG, [])
3725     AC_DEFINE(USG5, [])
3726     dnl This symbol should be defined on AIX Version 3  ???????
3727     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3728 #ifndef _AIX
3729 # error "_AIX not defined"
3730 #endif
3731     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
3732     ;;
3733
3734   cygwin)
3735     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
3736     ;;
3737
3738   darwin)
3739     dnl BSD4_3 and BSD4_4 are already defined in sys/param.h.
3740     AC_DEFINE(BSD4_2, [])
3741     AC_DEFINE(BSD_SYSTEM, [])
3742     dnl More specific than the above two.  We cannot use __APPLE__ as this
3743     dnl may not be defined on non-OSX Darwin, and we cannot define DARWIN
3744     dnl here because Panther and lower CoreFoundation.h uses DARWIN to
3745     dnl distinguish OS X from pure Darwin.
3746     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
3747     ;;
3748
3749   freebsd)
3750     AC_DEFINE(BSD4_2, [])
3751     dnl Hack to avoid calling AC_PREPROC_IFELSE multiple times.
3752     dnl Would not be needed with autoconf >= 2.67, where the
3753     dnl preprocessed output is accessible in "conftest.i".
3754     AC_DEFINE(BSD_SYSTEM_AHB, 1, [Define if AH_BOTTOM should change BSD_SYSTEM.])
3755     ;;
3756
3757   gnu | netbsd | openbsd )
3758     AC_DEFINE(BSD4_2, [])
3759     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3760 #ifndef BSD_SYSTEM
3761 # error "BSD_SYSTEM not defined"
3762 #endif
3763     ]], [[]])], [], AC_DEFINE(BSD_SYSTEM, 43) )
3764     ;;
3765
3766   gnu-linux | gnu-kfreebsd )
3767     AC_DEFINE(USG, [])
3768     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
3769     ;;
3770
3771   hpux*)
3772     AC_DEFINE(USG, [])
3773     AC_DEFINE(USG5, [])
3774     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
3775     ;;
3776
3777   irix6-5)
3778     AC_DEFINE(USG, [])
3779     AC_DEFINE(USG5, [])
3780     AC_DEFINE(USG5_4, [])
3781     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
3782     ;;
3783
3784   sol2*)
3785     AC_DEFINE(USG, [])
3786     AC_DEFINE(USG5, [])
3787     AC_DEFINE(USG5_4, [])
3788     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
3789     ;;
3790
3791   unixware)
3792     AC_DEFINE(USG, [])
3793     AC_DEFINE(USG5, [])
3794     AC_DEFINE(USG5_4, [])
3795     ;;
3796 esac
3797
3798
3799 case $opsys in
3800   dnl Emacs supplies its own malloc, but glib (part of Gtk+) calls
3801   dnl memalign and on Cygwin, that becomes the Cygwin-supplied memalign.
3802   dnl As malloc is not the Cygwin malloc, the Cygwin memalign always
3803   dnl returns ENOSYS.  A workaround is to set G_SLICE=always-malloc. */
3804   cygwin)
3805     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
3806       G_SLICE environment variable to "always-malloc" at startup, if
3807       using GTK.])
3808     ;;
3809
3810   hpux11)
3811     dnl See comments in sysdep.c:sys_signal.
3812     dnl SA_RESTART resets the timeout of `select' on hpux11.
3813     dnl Defining BROKEN_SA_RESTART is not the same as undef'ing SA_RESTART.
3814     AC_DEFINE(BROKEN_SA_RESTART, 1, [Define if SA_RESTART should only
3815       be used in batch mode.])
3816     dnl It works to open the pty's tty in the parent (Emacs), then
3817     dnl close and reopen it in the child.
3818     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
3819       works to open a pty's tty in the parent process, then close and
3820       reopen it in the child.])
3821     ;;
3822
3823   irix6-5)
3824     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
3825       use VSUSP instead of VSWTCH.])
3826     AC_DEFINE(SETPGRP_RELEASES_CTTY, 1, [Define if process.c:child_setup
3827       should not call setpgrp.])
3828     ;;
3829
3830   sol2-10)
3831     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
3832       on Solaris.])
3833     ;;
3834 esac
3835
3836 # Set up the CFLAGS for real compilation, so we can substitute it.
3837 CFLAGS="$REAL_CFLAGS"
3838 CPPFLAGS="$REAL_CPPFLAGS"
3839
3840 ## Hack to detect a buggy GCC version.
3841 if test "x$GCC" = xyes \
3842    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3843    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3844    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3845    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3846 fi
3847
3848 version=$PACKAGE_VERSION
3849
3850 ### Specify what sort of things we'll be editing into Makefile and config.h.
3851 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3852 AC_SUBST(version)
3853 AC_SUBST(configuration)
3854 ## Unused?
3855 AC_SUBST(canonical)
3856 AC_SUBST(srcdir)
3857 AC_SUBST(prefix)
3858 AC_SUBST(exec_prefix)
3859 AC_SUBST(bindir)
3860 AC_SUBST(datadir)
3861 AC_SUBST(sharedstatedir)
3862 AC_SUBST(libexecdir)
3863 AC_SUBST(mandir)
3864 AC_SUBST(infodir)
3865 AC_SUBST(lispdir)
3866 AC_SUBST(leimdir)
3867 AC_SUBST(standardlisppath)
3868 AC_SUBST(locallisppath)
3869 AC_SUBST(lisppath)
3870 AC_SUBST(x_default_search_path)
3871 AC_SUBST(etcdir)
3872 AC_SUBST(archlibdir)
3873 AC_SUBST(docdir)
3874 AC_SUBST(bitmapdir)
3875 AC_SUBST(gamedir)
3876 AC_SUBST(gameuser)
3877 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3878 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3879 ## end of LIBX_BASE, but nothing ever set it.
3880 AC_SUBST(LD_SWITCH_X_SITE)
3881 AC_SUBST(C_SWITCH_X_SITE)
3882 AC_SUBST(GNUSTEP_CFLAGS)
3883 AC_SUBST(CFLAGS)
3884 ## Used in lwlib/Makefile.in.
3885 AC_SUBST(X_TOOLKIT_TYPE)
3886 AC_SUBST(ns_appdir)
3887 AC_SUBST(ns_appbindir)
3888 AC_SUBST(ns_appresdir)
3889 AC_SUBST(ns_appsrc)
3890 AC_SUBST(GNU_OBJC_CFLAGS)
3891 AC_SUBST(OTHER_FILES)
3892
3893 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3894                    [Define to the canonical Emacs configuration name.])
3895 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3896                    [Define to the options passed to configure.])
3897 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
3898   define this to include extra configuration information.])
3899
3900 XMENU_OBJ=
3901 XOBJ=
3902 FONT_OBJ=
3903 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3904   AC_DEFINE(HAVE_X_WINDOWS, 1,
3905             [Define to 1 if you want to use the X window system.])
3906   XMENU_OBJ=xmenu.o
3907   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3908   FONT_OBJ=xfont.o
3909   if test "$HAVE_XFT" = "yes"; then
3910     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3911   elif test "$HAVE_FREETYPE" = "yes"; then
3912     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3913   fi
3914   AC_SUBST(FONT_OBJ)
3915 fi
3916 AC_SUBST(XMENU_OBJ)
3917 AC_SUBST(XOBJ)
3918 AC_SUBST(FONT_OBJ)
3919
3920 WIDGET_OBJ=
3921 MOTIF_LIBW=
3922 if test "${USE_X_TOOLKIT}" != "none" ; then
3923   WIDGET_OBJ=widget.o
3924   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3925   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3926     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3927   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3928     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3929     MOTIF_LIBW=-lXm
3930     case "$opsys" in
3931       gnu-linux)
3932         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3933         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3934         ;;
3935
3936       unixware)
3937         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3938         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3939         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3940         ;;
3941
3942       aix4-2)
3943         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3944         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3945         ;;
3946     esac
3947     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3948   fi
3949 fi
3950 AC_SUBST(WIDGET_OBJ)
3951
3952 TOOLKIT_LIBW=
3953 case "$USE_X_TOOLKIT" in
3954   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3955   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3956   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3957 esac
3958 AC_SUBST(TOOLKIT_LIBW)
3959
3960 if test "$USE_X_TOOLKIT" = "none"; then
3961   LIBXT_OTHER="\$(LIBXSM)"
3962   OLDXMENU_TARGET="really-oldXMenu"
3963 else
3964   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3965   OLDXMENU_TARGET="really-lwlib"
3966 fi
3967 AC_SUBST(LIBXT_OTHER)
3968
3969 ## The X Menu stuff is present in the X10 distribution, but missing
3970 ## from X11.  If we have X10, just use the installed library;
3971 ## otherwise, use our own copy.
3972 if test "${HAVE_X11}" = "yes" ; then
3973   AC_DEFINE(HAVE_X11, 1,
3974             [Define to 1 if you want to use version 11 of X windows.
3975              Otherwise, Emacs expects to use version 10.])
3976
3977   if test "$USE_X_TOOLKIT" = "none"; then
3978     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3979   else
3980     OLDXMENU="\${lwlibdir}/liblw.a"
3981   fi
3982   LIBXMENU="\$(OLDXMENU)"
3983   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3984   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3985 else
3986   ## For a syntactically valid Makefile; not actually used for anything.
3987   ## See comments in src/Makefile.in.
3988   OLDXMENU=nothing
3989   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3990   if test "${HAVE_X_WINDOWS}" = "yes"; then
3991     LIBXMENU="-lXMenu"
3992   else
3993     LIBXMENU=
3994   fi
3995   LIBX_OTHER=
3996   OLDXMENU_DEPS=
3997 fi
3998
3999 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
4000   OLDXMENU_TARGET=
4001   OLDXMENU=nothing
4002   LIBXMENU=
4003   OLDXMENU_DEPS=
4004 fi
4005
4006 AC_SUBST(OLDXMENU_TARGET)
4007 AC_SUBST(OLDXMENU)
4008 AC_SUBST(LIBXMENU)
4009 AC_SUBST(LIBX_OTHER)
4010 AC_SUBST(OLDXMENU_DEPS)
4011
4012 if test "${HAVE_MENUS}" = "yes" ; then
4013   AC_DEFINE(HAVE_MENUS, 1,
4014             [Define to 1 if you have mouse menus.
4015              (This is automatic if you use X, but the option to specify it remains.)
4016              It is also defined with other window systems that support xmenu.c.])
4017 fi
4018
4019 if test "${GNU_MALLOC}" = "yes" ; then
4020   AC_DEFINE(GNU_MALLOC, 1,
4021             [Define to 1 if you want to use the GNU memory allocator.])
4022 fi
4023
4024 RALLOC_OBJ=
4025 if test "${REL_ALLOC}" = "yes" ; then
4026   AC_DEFINE(REL_ALLOC, 1,
4027             [Define REL_ALLOC if you want to use the relocating allocator for
4028              buffer space.])
4029
4030   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4031 fi
4032 AC_SUBST(RALLOC_OBJ)
4033
4034 if test "$opsys" = "cygwin"; then
4035   CYGWIN_OBJ="sheap.o"
4036   ## Cygwin differs because of its unexec().
4037   PRE_ALLOC_OBJ=
4038   POST_ALLOC_OBJ=lastfile.o
4039 else
4040   CYGWIN_OBJ=
4041   PRE_ALLOC_OBJ=lastfile.o
4042   POST_ALLOC_OBJ=
4043 fi
4044 AC_SUBST(CYGWIN_OBJ)
4045 AC_SUBST(PRE_ALLOC_OBJ)
4046 AC_SUBST(POST_ALLOC_OBJ)
4047
4048 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4049 # it temporarily reverts them to their pre-pkg-config values,
4050 # because gnulib needs to work with both src (which uses the
4051 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4052 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4053 # and it therefore needs to run in an environment where LIBS does not
4054 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4055 # for some package unrelated to lib-src.
4056 SAVE_CFLAGS=$CFLAGS
4057 SAVE_LIBS=$LIBS
4058 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4059 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4060 gl_ASSERT_NO_GNULIB_POSIXCHECK
4061 gl_ASSERT_NO_GNULIB_TESTS
4062 gl_INIT
4063 CFLAGS=$SAVE_CFLAGS
4064 LIBS=$SAVE_LIBS
4065
4066 case "$opsys" in
4067   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4068
4069   darwin)
4070    ## The -headerpad option tells ld (see man page) to leave room at the
4071    ## end of the header for adding load commands.  Needed for dumping.
4072    ## 0x690 is the total size of 30 segment load commands (at 56
4073    ## each); under Cocoa 31 commands are required.
4074    if test "$HAVE_NS" = "yes"; then
4075      libs_nsgui="-framework AppKit"
4076      headerpad_extra=6C8
4077    else
4078      libs_nsgui=
4079      headerpad_extra=690
4080    fi
4081    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4082
4083    ## This is here because src/Makefile.in did some extra fiddling around
4084    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
4085    ##   #ifndef LD_SWITCH_SYSTEM
4086    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
4087    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
4088    ## not using gcc, darwin.
4089    ## Because this was done in src/Makefile.in, the resulting part of
4090    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
4091    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
4092    ## rather than LD_SWITCH_SYSTEM.
4093    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4094      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4095    ;;
4096
4097   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4098   ## find X at run-time.
4099   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4100   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4101   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4102   ## had different values in configure (in ac_link) and src/Makefile.in.
4103   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4104   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4105
4106   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4107 esac
4108
4109 if test "$NS_IMPL_GNUSTEP" = "yes"; then
4110   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
4111 fi
4112
4113 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4114
4115
4116 LD_FIRSTFLAG=
4117 ORDINARY_LINK=
4118 case "$opsys" in
4119   ## gnu: GNU needs its own crt0.
4120   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
4121
4122   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
4123   ## library search parth, i.e. it won't search /usr/lib for libc and
4124   ## friends.  Using -nostartfiles instead avoids this problem, and
4125   ## will also work on earlier NetBSD releases.
4126   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
4127
4128   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
4129   ##   MkLinux/LinuxPPC needs this.
4130   ## s390x-* only supports opsys = gnu-linux so it can be added here.
4131   gnu-*)
4132     case "$canonical" in
4133       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
4134     esac
4135     ;;
4136 esac
4137
4138
4139 if test "x$ORDINARY_LINK" = "xyes"; then
4140
4141   LD_FIRSTFLAG=""
4142   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
4143
4144 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
4145 ## freebsd, gnu-* not on powerpc*|s390x*.
4146 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
4147
4148   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
4149   ## places that are difficult to figure out at make time.  Fortunately,
4150   ## these same versions allow you to pass arbitrary flags on to the
4151   ## linker, so there is no reason not to use it as a linker.
4152   ##
4153   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
4154   ## searching for libraries in its internal directories, so we have to
4155   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
4156   LD_FIRSTFLAG="-nostdlib"
4157 fi
4158
4159 ## FIXME? What setting of EDIT_LDFLAGS should this have?
4160 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
4161
4162 AC_SUBST(LD_FIRSTFLAG)
4163
4164
4165 ## FIXME? The logic here is not precisely the same as that above.
4166 ## There is no check here for a pre-defined LD_FIRSTFLAG.
4167 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
4168 LIB_GCC=
4169 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
4170
4171   case "$opsys" in
4172     freebsd|netbsd|openbsd) LIB_GCC= ;;
4173
4174     gnu-*)
4175       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
4176       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
4177       case $host_cpu in
4178       arm*)
4179         LIB_GCC="-lgcc_s"
4180         ;;
4181       *)
4182         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
4183         ## immediately undefine it again and redefine it to empty.
4184         ## Was the C_SWITCH_X_SITE part really necessary?
4185 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
4186         LIB_GCC=
4187         ;;
4188       esac
4189       ;;
4190
4191     ## Ask GCC where to find libgcc.a.
4192     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
4193   esac
4194 fi                              dnl if $GCC
4195 AC_SUBST(LIB_GCC)
4196
4197
4198 ## If we're using X11/GNUstep, define some consequences.
4199 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
4200   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4201   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
4202 fi
4203
4204
4205 AH_TOP([/* GNU Emacs site configuration template file.
4206
4207 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
4208   Free Software Foundation, Inc.
4209
4210 This file is part of GNU Emacs.
4211
4212 GNU Emacs is free software: you can redistribute it and/or modify
4213 it under the terms of the GNU General Public License as published by
4214 the Free Software Foundation, either version 3 of the License, or
4215 (at your option) any later version.
4216
4217 GNU Emacs is distributed in the hope that it will be useful,
4218 but WITHOUT ANY WARRANTY; without even the implied warranty of
4219 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4220 GNU General Public License for more details.
4221
4222 You should have received a copy of the GNU General Public License
4223 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4224
4225
4226 /* No code in Emacs #includes config.h twice, but some bits of code
4227    intended to work with other packages as well (like gmalloc.c)
4228    think they can include it as many times as they like.  */
4229 #ifndef EMACS_CONFIG_H
4230 #define EMACS_CONFIG_H
4231 ])dnl
4232
4233 AH_BOTTOM([#include <conf_post.h>
4234
4235 #endif /* EMACS_CONFIG_H */
4236
4237 /*
4238 Local Variables:
4239 mode: c
4240 End:
4241 */
4242 ])dnl
4243
4244 #### Report on what we decided to do.
4245 #### Report GTK as a toolkit, even if it doesn't use Xt.
4246 #### It makes printing result more understandable as using GTK sets
4247 #### toolkit_scroll_bars to yes by default.
4248 if test "${HAVE_GTK}" = "yes"; then
4249   if test "${with_gtk3}" = "yes"; then
4250     USE_X_TOOLKIT=GTK3
4251   else
4252     USE_X_TOOLKIT=GTK
4253   fi
4254 fi
4255
4256 echo "
4257 Configured for \`${canonical}'.
4258
4259   Where should the build process find the source code?    ${srcdir}
4260   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4261   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4262   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4263   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4264   What window system should Emacs use?                    ${window_system}
4265   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4266
4267 if test -n "${x_includes}"; then
4268 echo "  Where do we find X Windows header files?                ${x_includes}"
4269 else
4270 echo "  Where do we find X Windows header files?                Standard dirs"
4271 fi
4272 if test -n "${x_libraries}"; then
4273 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4274 else
4275 echo "  Where do we find X Windows libraries?                   Standard dirs"
4276 fi
4277
4278 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4279 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4280 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4281 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4282 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
4283 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
4284 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
4285 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
4286
4287 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
4288 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
4289 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
4290 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
4291 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
4292 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
4293 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
4294
4295 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
4296 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
4297 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
4298 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
4299
4300 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
4301 echo
4302
4303 if test -n "${EMACSDATA}"; then
4304    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
4305 fi
4306 if test -n "${EMACSDOC}"; then
4307    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
4308 fi
4309
4310 echo
4311
4312 if test "$HAVE_NS" = "yes"; then
4313    echo
4314    echo "You must run \"${MAKE-make} install\" in order to test the built application.
4315 The installed application will go to nextstep/Emacs.app and can be
4316 run or moved from there."
4317    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
4318       echo "The application will be fully self-contained."
4319     else
4320       echo "The lisp resources for the application will be installed under ${prefix}.
4321 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
4322 to run if these resources are not installed."
4323    fi
4324    echo
4325 fi
4326
4327 if test "${opsys}" = "cygwin"; then
4328   case `uname -r` in
4329     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
4330            echo
4331            ;;
4332   esac
4333 fi
4334
4335 # Remove any trailing slashes in these variables.
4336 [test "${prefix}" != NONE &&
4337   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
4338 test "${exec_prefix}" != NONE &&
4339   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
4340
4341 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
4342 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
4343 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
4344 dnl (else you get "no `Makefile.am' found for any configure output").
4345 dnl This will work, but you get a config.status that is not quite right
4346 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
4347 dnl That doesn't have any obvious consequences for Emacs, but on the whole
4348 dnl it seems better to just live with the duplication.
4349 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
4350
4351 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
4352        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
4353        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
4354        leim/Makefile])
4355
4356 dnl test/ is not present in release tarfiles.
4357 opt_makefile=test/automated/Makefile
4358
4359 if test -f $srcdir/${opt_makefile}.in; then
4360   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4361   dnl Again, it's best not to use a variable.  Though you can add
4362   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
4363   AC_CONFIG_FILES([test/automated/Makefile])
4364 fi
4365
4366
4367 dnl admin/ may or may not be present.
4368 opt_makefile=admin/unidata/Makefile
4369
4370 if test -f $srcdir/${opt_makefile}.in; then
4371   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4372   AC_CONFIG_FILES([admin/unidata/Makefile])
4373 fi
4374
4375
4376 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
4377
4378 AC_SUBST(SUBDIR_MAKEFILES_IN)
4379
4380 dnl Make the necessary directories, if they don't exist.
4381 AC_CONFIG_COMMANDS([mkdirs], [
4382 for dir in etc lisp ; do
4383   test -d ${dir} || mkdir ${dir}
4384 done
4385 ])
4386
4387 dnl You might wonder (I did) why epaths.h is generated by running make,
4388 dnl rather than just letting configure generate it from epaths.in.
4389 dnl One reason is that the various paths are not fully expanded (see above);
4390 dnl eg gamedir=${prefix}/var/games/emacs.
4391 dnl Secondly, the GNU Coding standards require that one should be able
4392 dnl to run `make prefix=/some/where/else' and override the values set
4393 dnl by configure.  This also explains the `move-if-change' test and
4394 dnl the use of force in the `epaths-force' rule in Makefile.in.
4395 AC_CONFIG_COMMANDS([epaths], [
4396 echo creating src/epaths.h
4397 ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
4398 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
4399
4400 AC_CONFIG_COMMANDS([gdbinit], [
4401 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
4402   echo creating src/.gdbinit
4403   echo source $srcdir/src/.gdbinit > src/.gdbinit
4404 fi
4405 ])
4406
4407 AC_OUTPUT